git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49 git send-email --dump-aliases
  50
  51   Composing:
  52     --from                  <str>  * Email From:
  53     --[no-]to               <str>  * Email To:
  54     --[no-]cc               <str>  * Email Cc:
  55     --[no-]bcc              <str>  * Email Bcc:
  56     --subject               <str>  * Email "Subject:"
  57     --in-reply-to           <str>  * Email "In-Reply-To:"
  58     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  59     --[no-]annotate                * Review each patch that will be sent in an editor.
  60     --compose                      * Open an editor for introduction.
  61     --compose-encoding      <str>  * Encoding to assume for introduction.
  62     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  63     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  64
  65   Sending:
  66     --envelope-sender       <str>  * Email envelope sender.
  67     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  68                                      is optional. Default 'localhost'.
  69     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  70     --smtp-server-port      <int>  * Outgoing SMTP server port.
  71     --smtp-user             <str>  * Username for SMTP-AUTH.
  72     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  73     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  74     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  75     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  76                                      Pass an empty string to disable certificate
  77                                      verification.
  78     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  79     --smtp-auth             <str>  * Space-separated list of allowed AUTH mechanisms.
  80                                      This setting forces to use one of the listed mechanisms.
  81     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  82
  83   Automating:
  84     --identity              <str>  * Use the sendemail.<id> options.
  85     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  86     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  87     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  88     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  89     --[no-]to-cover                * Email To: addresses in the cover letter.
  90     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  91     --[no-]suppress-from           * Send to self. Default off.
  92     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  93     --[no-]thread                  * Use In-Reply-To: field. Default on.
  94
  95   Administering:
  96     --confirm               <str>  * Confirm recipients before sending;
  97                                      auto, cc, compose, always, or never.
  98     --quiet                        * Output one line of info per email.
  99     --dry-run                      * Don't actually send the emails.
 100     --[no-]validate                * Perform patch sanity checks. Default on.
 101     --[no-]format-patch            * understand any non optional arguments as
 102                                      `git format-patch` ones.
 103     --force                        * Send even if safety checks would prevent it.
 104
 105   Information:
 106     --dump-aliases                 * Dump configured aliases and exit.
 107
 108 EOT
 109         exit(1);
 110 }
 111
 112 # most mail servers generate the Date: header, but not all...
 113 sub format_2822_time {
 114         my ($time) = @_;
 115         my @localtm = localtime($time);
 116         my @gmttm = gmtime($time);
 117         my $localmin = $localtm[1] + $localtm[2] * 60;
 118         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 119         if ($localtm[0] != $gmttm[0]) {
 120                 die "local zone differs from GMT by a non-minute interval\n";
 121         }
 122         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 123                 $localmin += 1440;
 124         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 125                 $localmin -= 1440;
 126         } elsif ($gmttm[6] != $localtm[6]) {
 127                 die "local time offset greater than or equal to 24 hours\n";
 128         }
 129         my $offset = $localmin - $gmtmin;
 130         my $offhour = $offset / 60;
 131         my $offmin = abs($offset % 60);
 132         if (abs($offhour) >= 24) {
 133                 die ("local time offset greater than or equal to 24 hours\n");
 134         }
 135
 136         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 137                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 138                        $localtm[3],
 139                        qw(Jan Feb Mar Apr May Jun
 140                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 141                        $localtm[5]+1900,
 142                        $localtm[2],
 143                        $localtm[1],
 144                        $localtm[0],
 145                        ($offset >= 0) ? '+' : '-',
 146                        abs($offhour),
 147                        $offmin,
 148                        );
 149 }
 150
 151 my $have_email_valid = eval { require Email::Valid; 1 };
 152 my $have_mail_address = eval { require Mail::Address; 1 };
 153 my $smtp;
 154 my $auth;
 155
 156 # Regexes for RFC 2047 productions.
 157 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 158 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 159 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 160
 161 # Variables we fill in automatically, or via prompting:
 162 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 163         $initial_reply_to,$initial_subject,@files,
 164         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 165
 166 my $envelope_sender;
 167
 168 # Example reply to:
 169 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 170
 171 my $repo = eval { Git->repository() };
 172 my @repo = $repo ? ($repo) : ();
 173 my $term = eval {
 174         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 175                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 176                 : new Term::ReadLine 'git-send-email';
 177 };
 178 if ($@) {
 179         $term = new FakeTerm "$@: going non-interactive";
 180 }
 181
 182 # Behavior modification variables
 183 my ($quiet, $dry_run) = (0, 0);
 184 my $format_patch;
 185 my $compose_filename;
 186 my $force = 0;
 187 my $dump_aliases = 0;
 188
 189 # Handle interactive edition of files.
 190 my $multiedit;
 191 my $editor;
 192
 193 sub do_edit {
 194         if (!defined($editor)) {
 195                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 196         }
 197         if (defined($multiedit) && !$multiedit) {
 198                 map {
 199                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 200                         if (($? & 127) || ($? >> 8)) {
 201                                 die("the editor exited uncleanly, aborting everything");
 202                         }
 203                 } @_;
 204         } else {
 205                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 206                 if (($? & 127) || ($? >> 8)) {
 207                         die("the editor exited uncleanly, aborting everything");
 208                 }
 209         }
 210 }
 211
 212 # Variables with corresponding config settings
 213 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 214 my ($cover_cc, $cover_to);
 215 my ($to_cmd, $cc_cmd);
 216 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 217 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 218 my ($identity, $aliasfiletype, @alias_files, $smtp_domain, $smtp_auth);
 219 my ($validate, $confirm);
 220 my (@suppress_cc);
 221 my ($auto_8bit_encoding);
 222 my ($compose_encoding);
 223 my ($target_xfer_encoding);
 224
 225 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 226
 227 my %config_bool_settings = (
 228     "thread" => [\$thread, 1],
 229     "chainreplyto" => [\$chain_reply_to, 0],
 230     "suppressfrom" => [\$suppress_from, undef],
 231     "signedoffbycc" => [\$signed_off_by_cc, undef],
 232     "cccover" => [\$cover_cc, undef],
 233     "tocover" => [\$cover_to, undef],
 234     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 235     "validate" => [\$validate, 1],
 236     "multiedit" => [\$multiedit, undef],
 237     "annotate" => [\$annotate, undef],
 238     "xmailer" => [\$use_xmailer, 1]
 239 );
 240
 241 my %config_settings = (
 242     "smtpserver" => \$smtp_server,
 243     "smtpserverport" => \$smtp_server_port,
 244     "smtpserveroption" => \@smtp_server_options,
 245     "smtpuser" => \$smtp_authuser,
 246     "smtppass" => \$smtp_authpass,
 247     "smtpdomain" => \$smtp_domain,
 248     "smtpauth" => \$smtp_auth,
 249     "to" => \@initial_to,
 250     "tocmd" => \$to_cmd,
 251     "cc" => \@initial_cc,
 252     "cccmd" => \$cc_cmd,
 253     "aliasfiletype" => \$aliasfiletype,
 254     "bcc" => \@bcclist,
 255     "suppresscc" => \@suppress_cc,
 256     "envelopesender" => \$envelope_sender,
 257     "confirm"   => \$confirm,
 258     "from" => \$sender,
 259     "assume8bitencoding" => \$auto_8bit_encoding,
 260     "composeencoding" => \$compose_encoding,
 261     "transferencoding" => \$target_xfer_encoding,
 262 );
 263
 264 my %config_path_settings = (
 265     "aliasesfile" => \@alias_files,
 266     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 267 );
 268
 269 # Handle Uncouth Termination
 270 sub signal_handler {
 271
 272         # Make text normal
 273         print color("reset"), "\n";
 274
 275         # SMTP password masked
 276         system "stty echo";
 277
 278         # tmp files from --compose
 279         if (defined $compose_filename) {
 280                 if (-e $compose_filename) {
 281                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 282                 }
 283                 if (-e ($compose_filename . ".final")) {
 284                         print "'$compose_filename.final' contains the composed email.\n"
 285                 }
 286         }
 287
 288         exit;
 289 };
 290
 291 $SIG{TERM} = \&signal_handler;
 292 $SIG{INT}  = \&signal_handler;
 293
 294 # Begin by accumulating all the variables (defined above), that we will end up
 295 # needing, first, from the command line:
 296
 297 my $help;
 298 my $rc = GetOptions("h" => \$help,
 299                     "dump-aliases" => \$dump_aliases);
 300 usage() unless $rc;
 301 die "--dump-aliases incompatible with other options\n"
 302     if !$help and $dump_aliases and @ARGV;
 303 $rc = GetOptions(
 304                     "sender|from=s" => \$sender,
 305                     "in-reply-to=s" => \$initial_reply_to,
 306                     "subject=s" => \$initial_subject,
 307                     "to=s" => \@initial_to,
 308                     "to-cmd=s" => \$to_cmd,
 309                     "no-to" => \$no_to,
 310                     "cc=s" => \@initial_cc,
 311                     "no-cc" => \$no_cc,
 312                     "bcc=s" => \@bcclist,
 313                     "no-bcc" => \$no_bcc,
 314                     "chain-reply-to!" => \$chain_reply_to,
 315                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 316                     "smtp-server=s" => \$smtp_server,
 317                     "smtp-server-option=s" => \@smtp_server_options,
 318                     "smtp-server-port=s" => \$smtp_server_port,
 319                     "smtp-user=s" => \$smtp_authuser,
 320                     "smtp-pass:s" => \$smtp_authpass,
 321                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 322                     "smtp-encryption=s" => \$smtp_encryption,
 323                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 324                     "smtp-debug:i" => \$debug_net_smtp,
 325                     "smtp-domain:s" => \$smtp_domain,
 326                     "smtp-auth=s" => \$smtp_auth,
 327                     "identity=s" => \$identity,
 328                     "annotate!" => \$annotate,
 329                     "no-annotate" => sub {$annotate = 0},
 330                     "compose" => \$compose,
 331                     "quiet" => \$quiet,
 332                     "cc-cmd=s" => \$cc_cmd,
 333                     "suppress-from!" => \$suppress_from,
 334                     "no-suppress-from" => sub {$suppress_from = 0},
 335                     "suppress-cc=s" => \@suppress_cc,
 336                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 337                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 338                     "cc-cover|cc-cover!" => \$cover_cc,
 339                     "no-cc-cover" => sub {$cover_cc = 0},
 340                     "to-cover|to-cover!" => \$cover_to,
 341                     "no-to-cover" => sub {$cover_to = 0},
 342                     "confirm=s" => \$confirm,
 343                     "dry-run" => \$dry_run,
 344                     "envelope-sender=s" => \$envelope_sender,
 345                     "thread!" => \$thread,
 346                     "no-thread" => sub {$thread = 0},
 347                     "validate!" => \$validate,
 348                     "no-validate" => sub {$validate = 0},
 349                     "transfer-encoding=s" => \$target_xfer_encoding,
 350                     "format-patch!" => \$format_patch,
 351                     "no-format-patch" => sub {$format_patch = 0},
 352                     "8bit-encoding=s" => \$auto_8bit_encoding,
 353                     "compose-encoding=s" => \$compose_encoding,
 354                     "force" => \$force,
 355                     "xmailer!" => \$use_xmailer,
 356                     "no-xmailer" => sub {$use_xmailer = 0},
 357          );
 358
 359 usage() if $help;
 360 unless ($rc) {
 361     usage();
 362 }
 363
 364 die "Cannot run git format-patch from outside a repository\n"
 365         if $format_patch and not $repo;
 366
 367 # Now, let's fill any that aren't set in with defaults:
 368
 369 sub read_config {
 370         my ($prefix) = @_;
 371
 372         foreach my $setting (keys %config_bool_settings) {
 373                 my $target = $config_bool_settings{$setting}->[0];
 374                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 375         }
 376
 377         foreach my $setting (keys %config_path_settings) {
 378                 my $target = $config_path_settings{$setting};
 379                 if (ref($target) eq "ARRAY") {
 380                         unless (@$target) {
 381                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 382                                 @$target = @values if (@values && defined $values[0]);
 383                         }
 384                 }
 385                 else {
 386                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 387                 }
 388         }
 389
 390         foreach my $setting (keys %config_settings) {
 391                 my $target = $config_settings{$setting};
 392                 next if $setting eq "to" and defined $no_to;
 393                 next if $setting eq "cc" and defined $no_cc;
 394                 next if $setting eq "bcc" and defined $no_bcc;
 395                 if (ref($target) eq "ARRAY") {
 396                         unless (@$target) {
 397                                 my @values = Git::config(@repo, "$prefix.$setting");
 398                                 @$target = @values if (@values && defined $values[0]);
 399                         }
 400                 }
 401                 else {
 402                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 403                 }
 404         }
 405
 406         if (!defined $smtp_encryption) {
 407                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 408                 if (defined $enc) {
 409                         $smtp_encryption = $enc;
 410                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 411                         $smtp_encryption = 'ssl';
 412                 }
 413         }
 414 }
 415
 416 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 417 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 418 read_config("sendemail.$identity") if (defined $identity);
 419 read_config("sendemail");
 420
 421 # fall back on builtin bool defaults
 422 foreach my $setting (values %config_bool_settings) {
 423         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 424 }
 425
 426 # 'default' encryption is none -- this only prevents a warning
 427 $smtp_encryption = '' unless (defined $smtp_encryption);
 428
 429 # Set CC suppressions
 430 my(%suppress_cc);
 431 if (@suppress_cc) {
 432         foreach my $entry (@suppress_cc) {
 433                 die "Unknown --suppress-cc field: '$entry'\n"
 434                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 435                 $suppress_cc{$entry} = 1;
 436         }
 437 }
 438
 439 if ($suppress_cc{'all'}) {
 440         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 441                 $suppress_cc{$entry} = 1;
 442         }
 443         delete $suppress_cc{'all'};
 444 }
 445
 446 # If explicit old-style ones are specified, they trump --suppress-cc.
 447 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 448 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 449
 450 if ($suppress_cc{'body'}) {
 451         foreach my $entry (qw (sob bodycc)) {
 452                 $suppress_cc{$entry} = 1;
 453         }
 454         delete $suppress_cc{'body'};
 455 }
 456
 457 # Set confirm's default value
 458 my $confirm_unconfigured = !defined $confirm;
 459 if ($confirm_unconfigured) {
 460         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 461 };
 462 die "Unknown --confirm setting: '$confirm'\n"
 463         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 464
 465 # Debugging, print out the suppressions.
 466 if (0) {
 467         print "suppressions:\n";
 468         foreach my $entry (keys %suppress_cc) {
 469                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 470         }
 471 }
 472
 473 my ($repoauthor, $repocommitter);
 474 ($repoauthor) = Git::ident_person(@repo, 'author');
 475 ($repocommitter) = Git::ident_person(@repo, 'committer');
 476
 477 sub parse_address_line {
 478         if ($have_mail_address) {
 479                 return map { $_->format } Mail::Address->parse($_[0]);
 480         } else {
 481                 return Git::parse_mailboxes($_[0]);
 482         }
 483 }
 484
 485 sub split_addrs {
 486         return quotewords('\s*,\s*', 1, @_);
 487 }
 488
 489 my %aliases;
 490
 491 sub parse_sendmail_alias {
 492         local $_ = shift;
 493         if (/"/) {
 494                 print STDERR "warning: sendmail alias with quotes is not supported: $_\n";
 495         } elsif (/:include:/) {
 496                 print STDERR "warning: `:include:` not supported: $_\n";
 497         } elsif (/[\/|]/) {
 498                 print STDERR "warning: `/file` or `|pipe` redirection not supported: $_\n";
 499         } elsif (/^(\S+?)\s*:\s*(.+)$/) {
 500                 my ($alias, $addr) = ($1, $2);
 501                 $aliases{$alias} = [ split_addrs($addr) ];
 502         } else {
 503                 print STDERR "warning: sendmail line is not recognized: $_\n";
 504         }
 505 }
 506
 507 sub parse_sendmail_aliases {
 508         my $fh = shift;
 509         my $s = '';
 510         while (<$fh>) {
 511                 chomp;
 512                 next if /^\s*$/ || /^\s*#/;
 513                 $s .= $_, next if $s =~ s/\\$// || s/^\s+//;
 514                 parse_sendmail_alias($s) if $s;
 515                 $s = $_;
 516         }
 517         $s =~ s/\\$//; # silently tolerate stray '\' on last line
 518         parse_sendmail_alias($s) if $s;
 519 }
 520
 521 my %parse_alias = (
 522         # multiline formats can be supported in the future
 523         mutt => sub { my $fh = shift; while (<$fh>) {
 524                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 525                         my ($alias, $addr) = ($1, $2);
 526                         $addr =~ s/#.*$//; # mutt allows # comments
 527                         # commas delimit multiple addresses
 528                         my @addr = split_addrs($addr);
 529
 530                         # quotes may be escaped in the file,
 531                         # unescape them so we do not double-escape them later.
 532                         s/\\"/"/g foreach @addr;
 533                         $aliases{$alias} = \@addr
 534                 }}},
 535         mailrc => sub { my $fh = shift; while (<$fh>) {
 536                 if (/^alias\s+(\S+)\s+(.*)$/) {
 537                         # spaces delimit multiple addresses
 538                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 539                 }}},
 540         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 541                 for (my $x = ''; defined($x); $x = $_) {
 542                         chomp $x;
 543                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 544                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 545                         $aliases{$1} = [ split_addrs($2) ];
 546                 }},
 547         elm => sub  { my $fh = shift;
 548                       while (<$fh>) {
 549                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 550                               my ($alias, $addr) = ($1, $2);
 551                                $aliases{$alias} = [ split_addrs($addr) ];
 552                           }
 553                       } },
 554         sendmail => \&parse_sendmail_aliases,
 555         gnus => sub { my $fh = shift; while (<$fh>) {
 556                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 557                         $aliases{$1} = [ $2 ];
 558                 }}}
 559 );
 560
 561 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 562         foreach my $file (@alias_files) {
 563                 open my $fh, '<', $file or die "opening $file: $!\n";
 564                 $parse_alias{$aliasfiletype}->($fh);
 565                 close $fh;
 566         }
 567 }
 568
 569 if ($dump_aliases) {
 570     print "$_\n" for (sort keys %aliases);
 571     exit(0);
 572 }
 573
 574 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 575 # $f is a revision list specification to be passed to format-patch.
 576 sub is_format_patch_arg {
 577         return unless $repo;
 578         my $f = shift;
 579         try {
 580                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 581                 if (defined($format_patch)) {
 582                         return $format_patch;
 583                 }
 584                 die(<<EOF);
 585 File '$f' exists but it could also be the range of commits
 586 to produce patches for.  Please disambiguate by...
 587
 588     * Saying "./$f" if you mean a file; or
 589     * Giving --format-patch option if you mean a range.
 590 EOF
 591         } catch Git::Error::Command with {
 592                 # Not a valid revision.  Treat it as a filename.
 593                 return 0;
 594         }
 595 }
 596
 597 # Now that all the defaults are set, process the rest of the command line
 598 # arguments and collect up the files that need to be processed.
 599 my @rev_list_opts;
 600 while (defined(my $f = shift @ARGV)) {
 601         if ($f eq "--") {
 602                 push @rev_list_opts, "--", @ARGV;
 603                 @ARGV = ();
 604         } elsif (-d $f and !is_format_patch_arg($f)) {
 605                 opendir my $dh, $f
 606                         or die "Failed to opendir $f: $!";
 607
 608                 push @files, grep { -f $_ } map { catfile($f, $_) }
 609                                 sort readdir $dh;
 610                 closedir $dh;
 611         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 612                 push @files, $f;
 613         } else {
 614                 push @rev_list_opts, $f;
 615         }
 616 }
 617
 618 if (@rev_list_opts) {
 619         die "Cannot run git format-patch from outside a repository\n"
 620                 unless $repo;
 621         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 622 }
 623
 624 @files = handle_backup_files(@files);
 625
 626 if ($validate) {
 627         foreach my $f (@files) {
 628                 unless (-p $f) {
 629                         my $error = validate_patch($f);
 630                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 631                 }
 632         }
 633 }
 634
 635 if (@files) {
 636         unless ($quiet) {
 637                 print $_,"\n" for (@files);
 638         }
 639 } else {
 640         print STDERR "\nNo patch files specified!\n\n";
 641         usage();
 642 }
 643
 644 sub get_patch_subject {
 645         my $fn = shift;
 646         open (my $fh, '<', $fn);
 647         while (my $line = <$fh>) {
 648                 next unless ($line =~ /^Subject: (.*)$/);
 649                 close $fh;
 650                 return "GIT: $1\n";
 651         }
 652         close $fh;
 653         die "No subject line in $fn ?";
 654 }
 655
 656 if ($compose) {
 657         # Note that this does not need to be secure, but we will make a small
 658         # effort to have it be unique
 659         $compose_filename = ($repo ?
 660                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 661                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 662         open my $c, ">", $compose_filename
 663                 or die "Failed to open for writing $compose_filename: $!";
 664
 665
 666         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 667         my $tpl_subject = $initial_subject || '';
 668         my $tpl_reply_to = $initial_reply_to || '';
 669
 670         print $c <<EOT;
 671 From $tpl_sender # This line is ignored.
 672 GIT: Lines beginning in "GIT:" will be removed.
 673 GIT: Consider including an overall diffstat or table of contents
 674 GIT: for the patch you are writing.
 675 GIT:
 676 GIT: Clear the body content if you don't wish to send a summary.
 677 From: $tpl_sender
 678 Subject: $tpl_subject
 679 In-Reply-To: $tpl_reply_to
 680
 681 EOT
 682         for my $f (@files) {
 683                 print $c get_patch_subject($f);
 684         }
 685         close $c;
 686
 687         if ($annotate) {
 688                 do_edit($compose_filename, @files);
 689         } else {
 690                 do_edit($compose_filename);
 691         }
 692
 693         open my $c2, ">", $compose_filename . ".final"
 694                 or die "Failed to open $compose_filename.final : " . $!;
 695
 696         open $c, "<", $compose_filename
 697                 or die "Failed to open $compose_filename : " . $!;
 698
 699         my $need_8bit_cte = file_has_nonascii($compose_filename);
 700         my $in_body = 0;
 701         my $summary_empty = 1;
 702         if (!defined $compose_encoding) {
 703                 $compose_encoding = "UTF-8";
 704         }
 705         while(<$c>) {
 706                 next if m/^GIT:/;
 707                 if ($in_body) {
 708                         $summary_empty = 0 unless (/^\n$/);
 709                 } elsif (/^\n$/) {
 710                         $in_body = 1;
 711                         if ($need_8bit_cte) {
 712                                 print $c2 "MIME-Version: 1.0\n",
 713                                          "Content-Type: text/plain; ",
 714                                            "charset=$compose_encoding\n",
 715                                          "Content-Transfer-Encoding: 8bit\n";
 716                         }
 717                 } elsif (/^MIME-Version:/i) {
 718                         $need_8bit_cte = 0;
 719                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 720                         $initial_subject = $1;
 721                         my $subject = $initial_subject;
 722                         $_ = "Subject: " .
 723                                 quote_subject($subject, $compose_encoding) .
 724                                 "\n";
 725                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 726                         $initial_reply_to = $1;
 727                         next;
 728                 } elsif (/^From:\s*(.+)\s*$/i) {
 729                         $sender = $1;
 730                         next;
 731                 } elsif (/^(?:To|Cc|Bcc):/i) {
 732                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 733                         next;
 734                 }
 735                 print $c2 $_;
 736         }
 737         close $c;
 738         close $c2;
 739
 740         if ($summary_empty) {
 741                 print "Summary email is empty, skipping it\n";
 742                 $compose = -1;
 743         }
 744 } elsif ($annotate) {
 745         do_edit(@files);
 746 }
 747
 748 sub ask {
 749         my ($prompt, %arg) = @_;
 750         my $valid_re = $arg{valid_re};
 751         my $default = $arg{default};
 752         my $confirm_only = $arg{confirm_only};
 753         my $resp;
 754         my $i = 0;
 755         return defined $default ? $default : undef
 756                 unless defined $term->IN and defined fileno($term->IN) and
 757                        defined $term->OUT and defined fileno($term->OUT);
 758         while ($i++ < 10) {
 759                 $resp = $term->readline($prompt);
 760                 if (!defined $resp) { # EOF
 761                         print "\n";
 762                         return defined $default ? $default : undef;
 763                 }
 764                 if ($resp eq '' and defined $default) {
 765                         return $default;
 766                 }
 767                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 768                         return $resp;
 769                 }
 770                 if ($confirm_only) {
 771                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 772                         if (defined $yesno && $yesno =~ /y/i) {
 773                                 return $resp;
 774                         }
 775                 }
 776         }
 777         return;
 778 }
 779
 780 my %broken_encoding;
 781
 782 sub file_declares_8bit_cte {
 783         my $fn = shift;
 784         open (my $fh, '<', $fn);
 785         while (my $line = <$fh>) {
 786                 last if ($line =~ /^$/);
 787                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 788         }
 789         close $fh;
 790         return 0;
 791 }
 792
 793 foreach my $f (@files) {
 794         next unless (body_or_subject_has_nonascii($f)
 795                      && !file_declares_8bit_cte($f));
 796         $broken_encoding{$f} = 1;
 797 }
 798
 799 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 800         print "The following files are 8bit, but do not declare " .
 801                 "a Content-Transfer-Encoding.\n";
 802         foreach my $f (sort keys %broken_encoding) {
 803                 print "    $f\n";
 804         }
 805         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 806                                   valid_re => qr/.{4}/, confirm_only => 1,
 807                                   default => "UTF-8");
 808 }
 809
 810 if (!$force) {
 811         for my $f (@files) {
 812                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 813                         die "Refusing to send because the patch\n\t$f\n"
 814                                 . "has the template subject '*** SUBJECT HERE ***'. "
 815                                 . "Pass --force if you really want to send.\n";
 816                 }
 817         }
 818 }
 819
 820 if (defined $sender) {
 821         $sender =~ s/^\s+|\s+$//g;
 822         ($sender) = expand_aliases($sender);
 823 } else {
 824         $sender = $repoauthor || $repocommitter || '';
 825 }
 826
 827 # $sender could be an already sanitized address
 828 # (e.g. sendemail.from could be manually sanitized by user).
 829 # But it's a no-op to run sanitize_address on an already sanitized address.
 830 $sender = sanitize_address($sender);
 831
 832 my $prompting = 0;
 833 if (!@initial_to && !defined $to_cmd) {
 834         my $to = ask("Who should the emails be sent to (if any)? ",
 835                      default => "",
 836                      valid_re => qr/\@.*\./, confirm_only => 1);
 837         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 838         $prompting++;
 839 }
 840
 841 sub expand_aliases {
 842         return map { expand_one_alias($_) } @_;
 843 }
 844
 845 my %EXPANDED_ALIASES;
 846 sub expand_one_alias {
 847         my $alias = shift;
 848         if ($EXPANDED_ALIASES{$alias}) {
 849                 die "fatal: alias '$alias' expands to itself\n";
 850         }
 851         local $EXPANDED_ALIASES{$alias} = 1;
 852         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 853 }
 854
 855 @initial_to = process_address_list(@initial_to);
 856 @initial_cc = process_address_list(@initial_cc);
 857 @bcclist = process_address_list(@bcclist);
 858
 859 if ($thread && !defined $initial_reply_to && $prompting) {
 860         $initial_reply_to = ask(
 861                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 862                 default => "",
 863                 valid_re => qr/\@.*\./, confirm_only => 1);
 864 }
 865 if (defined $initial_reply_to) {
 866         $initial_reply_to =~ s/^\s*<?//;
 867         $initial_reply_to =~ s/>?\s*$//;
 868         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 869 }
 870
 871 if (!defined $smtp_server) {
 872         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 873                 if (-x $_) {
 874                         $smtp_server = $_;
 875                         last;
 876                 }
 877         }
 878         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 879 }
 880
 881 if ($compose && $compose > 0) {
 882         @files = ($compose_filename . ".final", @files);
 883 }
 884
 885 # Variables we set as part of the loop over files
 886 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 887         $needs_confirm, $message_num, $ask_default);
 888
 889 sub extract_valid_address {
 890         my $address = shift;
 891         my $local_part_regexp = qr/[^<>"\s@]+/;
 892         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 893
 894         # check for a local address:
 895         return $address if ($address =~ /^($local_part_regexp)$/);
 896
 897         $address =~ s/^\s*<(.*)>\s*$/$1/;
 898         if ($have_email_valid) {
 899                 return scalar Email::Valid->address($address);
 900         }
 901
 902         # less robust/correct than the monster regexp in Email::Valid,
 903         # but still does a 99% job, and one less dependency
 904         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 905         return;
 906 }
 907
 908 sub extract_valid_address_or_die {
 909         my $address = shift;
 910         $address = extract_valid_address($address);
 911         die "error: unable to extract a valid address from: $address\n"
 912                 if !$address;
 913         return $address;
 914 }
 915
 916 sub validate_address {
 917         my $address = shift;
 918         while (!extract_valid_address($address)) {
 919                 print STDERR "error: unable to extract a valid address from: $address\n";
 920                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 921                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 922                         default => 'q');
 923                 if (/^d/i) {
 924                         return undef;
 925                 } elsif (/^q/i) {
 926                         cleanup_compose_files();
 927                         exit(0);
 928                 }
 929                 $address = ask("Who should the email be sent to (if any)? ",
 930                         default => "",
 931                         valid_re => qr/\@.*\./, confirm_only => 1);
 932         }
 933         return $address;
 934 }
 935
 936 sub validate_address_list {
 937         return (grep { defined $_ }
 938                 map { validate_address($_) } @_);
 939 }
 940
 941 # Usually don't need to change anything below here.
 942
 943 # we make a "fake" message id by taking the current number
 944 # of seconds since the beginning of Unix time and tacking on
 945 # a random number to the end, in case we are called quicker than
 946 # 1 second since the last time we were called.
 947
 948 # We'll setup a template for the message id, using the "from" address:
 949
 950 my ($message_id_stamp, $message_id_serial);
 951 sub make_message_id {
 952         my $uniq;
 953         if (!defined $message_id_stamp) {
 954                 $message_id_stamp = sprintf("%s-%s", time, $$);
 955                 $message_id_serial = 0;
 956         }
 957         $message_id_serial++;
 958         $uniq = "$message_id_stamp-$message_id_serial";
 959
 960         my $du_part;
 961         for ($sender, $repocommitter, $repoauthor) {
 962                 $du_part = extract_valid_address(sanitize_address($_));
 963                 last if (defined $du_part and $du_part ne '');
 964         }
 965         if (not defined $du_part or $du_part eq '') {
 966                 require Sys::Hostname;
 967                 $du_part = 'user@' . Sys::Hostname::hostname();
 968         }
 969         my $message_id_template = "<%s-git-send-email-%s>";
 970         $message_id = sprintf($message_id_template, $uniq, $du_part);
 971         #print "new message id = $message_id\n"; # Was useful for debugging
 972 }
 973
 974
 975
 976 $time = time - scalar $#files;
 977
 978 sub unquote_rfc2047 {
 979         local ($_) = @_;
 980         my $charset;
 981         my $sep = qr/[ \t]+/;
 982         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 983                 my @words = split $sep, $&;
 984                 foreach (@words) {
 985                         m/$re_encoded_word/;
 986                         $charset = $1;
 987                         my $encoding = $2;
 988                         my $text = $3;
 989                         if ($encoding eq 'q' || $encoding eq 'Q') {
 990                                 $_ = $text;
 991                                 s/_/ /g;
 992                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 993                         } else {
 994                                 # other encodings not supported yet
 995                         }
 996                 }
 997                 join '', @words;
 998         }eg;
 999         return wantarray ? ($_, $charset) : $_;
1000 }
1001
1002 sub quote_rfc2047 {
1003         local $_ = shift;
1004         my $encoding = shift || 'UTF-8';
1005         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
1006         s/(.*)/=\?$encoding\?q\?$1\?=/;
1007         return $_;
1008 }
1009
1010 sub is_rfc2047_quoted {
1011         my $s = shift;
1012         length($s) <= 75 &&
1013         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
1014 }
1015
1016 sub subject_needs_rfc2047_quoting {
1017         my $s = shift;
1018
1019         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
1020 }
1021
1022 sub quote_subject {
1023         local $subject = shift;
1024         my $encoding = shift || 'UTF-8';
1025
1026         if (subject_needs_rfc2047_quoting($subject)) {
1027                 return quote_rfc2047($subject, $encoding);
1028         }
1029         return $subject;
1030 }
1031
1032 # use the simplest quoting being able to handle the recipient
1033 sub sanitize_address {
1034         my ($recipient) = @_;
1035
1036         # remove garbage after email address
1037         $recipient =~ s/(.*>).*$/$1/;
1038
1039         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
1040
1041         if (not $recipient_name) {
1042                 return $recipient;
1043         }
1044
1045         # if recipient_name is already quoted, do nothing
1046         if (is_rfc2047_quoted($recipient_name)) {
1047                 return $recipient;
1048         }
1049
1050         # remove non-escaped quotes
1051         $recipient_name =~ s/(^|[^\\])"/$1/g;
1052
1053         # rfc2047 is needed if a non-ascii char is included
1054         if ($recipient_name =~ /[^[:ascii:]]/) {
1055                 $recipient_name = quote_rfc2047($recipient_name);
1056         }
1057
1058         # double quotes are needed if specials or CTLs are included
1059         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1060                 $recipient_name =~ s/([\\\r])/\\$1/g;
1061                 $recipient_name = qq["$recipient_name"];
1062         }
1063
1064         return "$recipient_name $recipient_addr";
1065
1066 }
1067
1068 sub sanitize_address_list {
1069         return (map { sanitize_address($_) } @_);
1070 }
1071
1072 sub process_address_list {
1073         my @addr_list = map { parse_address_line($_) } @_;
1074         @addr_list = expand_aliases(@addr_list);
1075         @addr_list = sanitize_address_list(@addr_list);
1076         @addr_list = validate_address_list(@addr_list);
1077         return @addr_list;
1078 }
1079
1080 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1081 #
1082 # Tightly configured MTAa require that a caller sends a real DNS
1083 # domain name that corresponds the IP address in the HELO/EHLO
1084 # handshake. This is used to verify the connection and prevent
1085 # spammers from trying to hide their identity. If the DNS and IP don't
1086 # match, the receiveing MTA may deny the connection.
1087 #
1088 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1089 #
1090 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1091 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1092 #
1093 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1094 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1095
1096 sub valid_fqdn {
1097         my $domain = shift;
1098         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1099 }
1100
1101 sub maildomain_net {
1102         my $maildomain;
1103
1104         if (eval { require Net::Domain; 1 }) {
1105                 my $domain = Net::Domain::domainname();
1106                 $maildomain = $domain if valid_fqdn($domain);
1107         }
1108
1109         return $maildomain;
1110 }
1111
1112 sub maildomain_mta {
1113         my $maildomain;
1114
1115         if (eval { require Net::SMTP; 1 }) {
1116                 for my $host (qw(mailhost localhost)) {
1117                         my $smtp = Net::SMTP->new($host);
1118                         if (defined $smtp) {
1119                                 my $domain = $smtp->domain;
1120                                 $smtp->quit;
1121
1122                                 $maildomain = $domain if valid_fqdn($domain);
1123
1124                                 last if $maildomain;
1125                         }
1126                 }
1127         }
1128
1129         return $maildomain;
1130 }
1131
1132 sub maildomain {
1133         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1134 }
1135
1136 sub smtp_host_string {
1137         if (defined $smtp_server_port) {
1138                 return "$smtp_server:$smtp_server_port";
1139         } else {
1140                 return $smtp_server;
1141         }
1142 }
1143
1144 # Returns 1 if authentication succeeded or was not necessary
1145 # (smtp_user was not specified), and 0 otherwise.
1146
1147 sub smtp_auth_maybe {
1148         if (!defined $smtp_authuser || $auth) {
1149                 return 1;
1150         }
1151
1152         # Workaround AUTH PLAIN/LOGIN interaction defect
1153         # with Authen::SASL::Cyrus
1154         eval {
1155                 require Authen::SASL;
1156                 Authen::SASL->import(qw(Perl));
1157         };
1158
1159         # Check mechanism naming as defined in:
1160         # https://tools.ietf.org/html/rfc4422#page-8
1161         if ($smtp_auth && $smtp_auth !~ /^(\b[A-Z0-9-_]{1,20}\s*)*$/) {
1162                 die "invalid smtp auth: '${smtp_auth}'";
1163         }
1164
1165         # TODO: Authentication may fail not because credentials were
1166         # invalid but due to other reasons, in which we should not
1167         # reject credentials.
1168         $auth = Git::credential({
1169                 'protocol' => 'smtp',
1170                 'host' => smtp_host_string(),
1171                 'username' => $smtp_authuser,
1172                 # if there's no password, "git credential fill" will
1173                 # give us one, otherwise it'll just pass this one.
1174                 'password' => $smtp_authpass
1175         }, sub {
1176                 my $cred = shift;
1177
1178                 if ($smtp_auth) {
1179                         my $sasl = Authen::SASL->new(
1180                                 mechanism => $smtp_auth,
1181                                 callback => {
1182                                         user => $cred->{'username'},
1183                                         pass => $cred->{'password'},
1184                                         authname => $cred->{'username'},
1185                                 }
1186                         );
1187
1188                         return !!$smtp->auth($sasl);
1189                 }
1190
1191                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1192         });
1193
1194         return $auth;
1195 }
1196
1197 sub ssl_verify_params {
1198         eval {
1199                 require IO::Socket::SSL;
1200                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1201         };
1202         if ($@) {
1203                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1204                 return;
1205         }
1206
1207         if (!defined $smtp_ssl_cert_path) {
1208                 # use the OpenSSL defaults
1209                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1210         }
1211
1212         if ($smtp_ssl_cert_path eq "") {
1213                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1214         } elsif (-d $smtp_ssl_cert_path) {
1215                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1216                         SSL_ca_path => $smtp_ssl_cert_path);
1217         } elsif (-f $smtp_ssl_cert_path) {
1218                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1219                         SSL_ca_file => $smtp_ssl_cert_path);
1220         } else {
1221                 die "CA path \"$smtp_ssl_cert_path\" does not exist";
1222         }
1223 }
1224
1225 sub file_name_is_absolute {
1226         my ($path) = @_;
1227
1228         # msys does not grok DOS drive-prefixes
1229         if ($^O eq 'msys') {
1230                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1231         }
1232
1233         require File::Spec::Functions;
1234         return File::Spec::Functions::file_name_is_absolute($path);
1235 }
1236
1237 # Returns 1 if the message was sent, and 0 otherwise.
1238 # In actuality, the whole program dies when there
1239 # is an error sending a message.
1240
1241 sub send_message {
1242         my @recipients = unique_email_list(@to);
1243         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1244                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1245                     }
1246                @cc);
1247         my $to = join (",\n\t", @recipients);
1248         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1249         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1250         my $date = format_2822_time($time++);
1251         my $gitversion = '@@GIT_VERSION@@';
1252         if ($gitversion =~ m/..GIT_VERSION../) {
1253             $gitversion = Git::version();
1254         }
1255
1256         my $cc = join(",\n\t", unique_email_list(@cc));
1257         my $ccline = "";
1258         if ($cc ne '') {
1259                 $ccline = "\nCc: $cc";
1260         }
1261         make_message_id() unless defined($message_id);
1262
1263         my $header = "From: $sender
1264 To: $to${ccline}
1265 Subject: $subject
1266 Date: $date
1267 Message-Id: $message_id
1268 ";
1269         if ($use_xmailer) {
1270                 $header .= "X-Mailer: git-send-email $gitversion\n";
1271         }
1272         if ($reply_to) {
1273
1274                 $header .= "In-Reply-To: $reply_to\n";
1275                 $header .= "References: $references\n";
1276         }
1277         if (@xh) {
1278                 $header .= join("\n", @xh) . "\n";
1279         }
1280
1281         my @sendmail_parameters = ('-i', @recipients);
1282         my $raw_from = $sender;
1283         if (defined $envelope_sender && $envelope_sender ne "auto") {
1284                 $raw_from = $envelope_sender;
1285         }
1286         $raw_from = extract_valid_address($raw_from);
1287         unshift (@sendmail_parameters,
1288                         '-f', $raw_from) if(defined $envelope_sender);
1289
1290         if ($needs_confirm && !$dry_run) {
1291                 print "\n$header\n";
1292                 if ($needs_confirm eq "inform") {
1293                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1294                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1295                         print "    The Cc list above has been expanded by additional\n";
1296                         print "    addresses found in the patch commit message. By default\n";
1297                         print "    send-email prompts before sending whenever this occurs.\n";
1298                         print "    This behavior is controlled by the sendemail.confirm\n";
1299                         print "    configuration setting.\n";
1300                         print "\n";
1301                         print "    For additional information, run 'git send-email --help'.\n";
1302                         print "    To retain the current behavior, but squelch this message,\n";
1303                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1304                 }
1305                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1306                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1307                          default => $ask_default);
1308                 die "Send this email reply required" unless defined $_;
1309                 if (/^n/i) {
1310                         return 0;
1311                 } elsif (/^q/i) {
1312                         cleanup_compose_files();
1313                         exit(0);
1314                 } elsif (/^a/i) {
1315                         $confirm = 'never';
1316                 }
1317         }
1318
1319         unshift (@sendmail_parameters, @smtp_server_options);
1320
1321         if ($dry_run) {
1322                 # We don't want to send the email.
1323         } elsif (file_name_is_absolute($smtp_server)) {
1324                 my $pid = open my $sm, '|-';
1325                 defined $pid or die $!;
1326                 if (!$pid) {
1327                         exec($smtp_server, @sendmail_parameters) or die $!;
1328                 }
1329                 print $sm "$header\n$message";
1330                 close $sm or die $!;
1331         } else {
1332
1333                 if (!defined $smtp_server) {
1334                         die "The required SMTP server is not properly defined."
1335                 }
1336
1337                 if ($smtp_encryption eq 'ssl') {
1338                         $smtp_server_port ||= 465; # ssmtp
1339                         require Net::SMTP::SSL;
1340                         $smtp_domain ||= maildomain();
1341                         require IO::Socket::SSL;
1342
1343                         # Suppress "variable accessed once" warning.
1344                         {
1345                                 no warnings 'once';
1346                                 $IO::Socket::SSL::DEBUG = 1;
1347                         }
1348
1349                         # Net::SMTP::SSL->new() does not forward any SSL options
1350                         IO::Socket::SSL::set_client_defaults(
1351                                 ssl_verify_params());
1352                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1353                                                       Hello => $smtp_domain,
1354                                                       Port => $smtp_server_port,
1355                                                       Debug => $debug_net_smtp);
1356                 }
1357                 else {
1358                         require Net::SMTP;
1359                         $smtp_domain ||= maildomain();
1360                         $smtp_server_port ||= 25;
1361                         $smtp ||= Net::SMTP->new($smtp_server,
1362                                                  Hello => $smtp_domain,
1363                                                  Debug => $debug_net_smtp,
1364                                                  Port => $smtp_server_port);
1365                         if ($smtp_encryption eq 'tls' && $smtp) {
1366                                 require Net::SMTP::SSL;
1367                                 $smtp->command('STARTTLS');
1368                                 $smtp->response();
1369                                 if ($smtp->code == 220) {
1370                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1371                                                                           ssl_verify_params())
1372                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1373                                         $smtp_encryption = '';
1374                                         # Send EHLO again to receive fresh
1375                                         # supported commands
1376                                         $smtp->hello($smtp_domain);
1377                                 } else {
1378                                         die "Server does not support STARTTLS! ".$smtp->message;
1379                                 }
1380                         }
1381                 }
1382
1383                 if (!$smtp) {
1384                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1385                             "VALUES: server=$smtp_server ",
1386                             "encryption=$smtp_encryption ",
1387                             "hello=$smtp_domain",
1388                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1389                 }
1390
1391                 smtp_auth_maybe or die $smtp->message;
1392
1393                 $smtp->mail( $raw_from ) or die $smtp->message;
1394                 $smtp->to( @recipients ) or die $smtp->message;
1395                 $smtp->data or die $smtp->message;
1396                 $smtp->datasend("$header\n") or die $smtp->message;
1397                 my @lines = split /^/, $message;
1398                 foreach my $line (@lines) {
1399                         $smtp->datasend("$line") or die $smtp->message;
1400                 }
1401                 $smtp->dataend() or die $smtp->message;
1402                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1403         }
1404         if ($quiet) {
1405                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1406         } else {
1407                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1408                 if (!file_name_is_absolute($smtp_server)) {
1409                         print "Server: $smtp_server\n";
1410                         print "MAIL FROM:<$raw_from>\n";
1411                         foreach my $entry (@recipients) {
1412                             print "RCPT TO:<$entry>\n";
1413                         }
1414                 } else {
1415                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1416                 }
1417                 print $header, "\n";
1418                 if ($smtp) {
1419                         print "Result: ", $smtp->code, ' ',
1420                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1421                 } else {
1422                         print "Result: OK\n";
1423                 }
1424         }
1425
1426         return 1;
1427 }
1428
1429 $reply_to = $initial_reply_to;
1430 $references = $initial_reply_to || '';
1431 $subject = $initial_subject;
1432 $message_num = 0;
1433
1434 foreach my $t (@files) {
1435         open my $fh, "<", $t or die "can't open file $t";
1436
1437         my $author = undef;
1438         my $sauthor = undef;
1439         my $author_encoding;
1440         my $has_content_type;
1441         my $body_encoding;
1442         my $xfer_encoding;
1443         my $has_mime_version;
1444         @to = ();
1445         @cc = ();
1446         @xh = ();
1447         my $input_format = undef;
1448         my @header = ();
1449         $message = "";
1450         $message_num++;
1451         # First unfold multiline header fields
1452         while(<$fh>) {
1453                 last if /^\s*$/;
1454                 if (/^\s+\S/ and @header) {
1455                         chomp($header[$#header]);
1456                         s/^\s+/ /;
1457                         $header[$#header] .= $_;
1458             } else {
1459                         push(@header, $_);
1460                 }
1461         }
1462         # Now parse the header
1463         foreach(@header) {
1464                 if (/^From /) {
1465                         $input_format = 'mbox';
1466                         next;
1467                 }
1468                 chomp;
1469                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1470                         $input_format = 'mbox';
1471                 }
1472
1473                 if (defined $input_format && $input_format eq 'mbox') {
1474                         if (/^Subject:\s+(.*)$/i) {
1475                                 $subject = $1;
1476                         }
1477                         elsif (/^From:\s+(.*)$/i) {
1478                                 ($author, $author_encoding) = unquote_rfc2047($1);
1479                                 $sauthor = sanitize_address($author);
1480                                 next if $suppress_cc{'author'};
1481                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1482                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1483                                         $1, $_) unless $quiet;
1484                                 push @cc, $1;
1485                         }
1486                         elsif (/^To:\s+(.*)$/i) {
1487                                 foreach my $addr (parse_address_line($1)) {
1488                                         printf("(mbox) Adding to: %s from line '%s'\n",
1489                                                 $addr, $_) unless $quiet;
1490                                         push @to, $addr;
1491                                 }
1492                         }
1493                         elsif (/^Cc:\s+(.*)$/i) {
1494                                 foreach my $addr (parse_address_line($1)) {
1495                                         my $qaddr = unquote_rfc2047($addr);
1496                                         my $saddr = sanitize_address($qaddr);
1497                                         if ($saddr eq $sender) {
1498                                                 next if ($suppress_cc{'self'});
1499                                         } else {
1500                                                 next if ($suppress_cc{'cc'});
1501                                         }
1502                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1503                                                 $addr, $_) unless $quiet;
1504                                         push @cc, $addr;
1505                                 }
1506                         }
1507                         elsif (/^Content-type:/i) {
1508                                 $has_content_type = 1;
1509                                 if (/charset="?([^ "]+)/) {
1510                                         $body_encoding = $1;
1511                                 }
1512                                 push @xh, $_;
1513                         }
1514                         elsif (/^MIME-Version/i) {
1515                                 $has_mime_version = 1;
1516                                 push @xh, $_;
1517                         }
1518                         elsif (/^Message-Id: (.*)/i) {
1519                                 $message_id = $1;
1520                         }
1521                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1522                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1523                         }
1524                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1525                                 push @xh, $_;
1526                         }
1527
1528                 } else {
1529                         # In the traditional
1530                         # "send lots of email" format,
1531                         # line 1 = cc
1532                         # line 2 = subject
1533                         # So let's support that, too.
1534                         $input_format = 'lots';
1535                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1536                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1537                                         $_, $_) unless $quiet;
1538                                 push @cc, $_;
1539                         } elsif (!defined $subject) {
1540                                 $subject = $_;
1541                         }
1542                 }
1543         }
1544         # Now parse the message body
1545         while(<$fh>) {
1546                 $message .=  $_;
1547                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1548                         chomp;
1549                         my ($what, $c) = ($1, $2);
1550                         chomp $c;
1551                         my $sc = sanitize_address($c);
1552                         if ($sc eq $sender) {
1553                                 next if ($suppress_cc{'self'});
1554                         } else {
1555                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1556                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1557                         }
1558                         push @cc, $c;
1559                         printf("(body) Adding cc: %s from line '%s'\n",
1560                                 $c, $_) unless $quiet;
1561                 }
1562         }
1563         close $fh;
1564
1565         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1566                 if defined $to_cmd;
1567         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1568                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1569
1570         if ($broken_encoding{$t} && !$has_content_type) {
1571                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1572                 $has_content_type = 1;
1573                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1574                 $body_encoding = $auto_8bit_encoding;
1575         }
1576
1577         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1578                 $subject = quote_subject($subject, $auto_8bit_encoding);
1579         }
1580
1581         if (defined $sauthor and $sauthor ne $sender) {
1582                 $message = "From: $author\n\n$message";
1583                 if (defined $author_encoding) {
1584                         if ($has_content_type) {
1585                                 if ($body_encoding eq $author_encoding) {
1586                                         # ok, we already have the right encoding
1587                                 }
1588                                 else {
1589                                         # uh oh, we should re-encode
1590                                 }
1591                         }
1592                         else {
1593                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1594                                 $has_content_type = 1;
1595                                 push @xh,
1596                                   "Content-Type: text/plain; charset=$author_encoding";
1597                         }
1598                 }
1599         }
1600         if (defined $target_xfer_encoding) {
1601                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1602                 $message = apply_transfer_encoding(
1603                         $message, $xfer_encoding, $target_xfer_encoding);
1604                 $xfer_encoding = $target_xfer_encoding;
1605         }
1606         if (defined $xfer_encoding) {
1607                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1608         }
1609         if (defined $xfer_encoding or $has_content_type) {
1610                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1611         }
1612
1613         $needs_confirm = (
1614                 $confirm eq "always" or
1615                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1616                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1617         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1618
1619         @to = process_address_list(@to);
1620         @cc = process_address_list(@cc);
1621
1622         @to = (@initial_to, @to);
1623         @cc = (@initial_cc, @cc);
1624
1625         if ($message_num == 1) {
1626                 if (defined $cover_cc and $cover_cc) {
1627                         @initial_cc = @cc;
1628                 }
1629                 if (defined $cover_to and $cover_to) {
1630                         @initial_to = @to;
1631                 }
1632         }
1633
1634         my $message_was_sent = send_message();
1635
1636         # set up for the next message
1637         if ($thread && $message_was_sent &&
1638                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1639                 $message_num == 1)) {
1640                 $reply_to = $message_id;
1641                 if (length $references > 0) {
1642                         $references .= "\n $message_id";
1643                 } else {
1644                         $references = "$message_id";
1645                 }
1646         }
1647         $message_id = undef;
1648 }
1649
1650 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1651 # and return a results array
1652 sub recipients_cmd {
1653         my ($prefix, $what, $cmd, $file) = @_;
1654
1655         my @addresses = ();
1656         open my $fh, "-|", "$cmd \Q$file\E"
1657             or die "($prefix) Could not execute '$cmd'";
1658         while (my $address = <$fh>) {
1659                 $address =~ s/^\s*//g;
1660                 $address =~ s/\s*$//g;
1661                 $address = sanitize_address($address);
1662                 next if ($address eq $sender and $suppress_cc{'self'});
1663                 push @addresses, $address;
1664                 printf("($prefix) Adding %s: %s from: '%s'\n",
1665                        $what, $address, $cmd) unless $quiet;
1666                 }
1667         close $fh
1668             or die "($prefix) failed to close pipe to '$cmd'";
1669         return @addresses;
1670 }
1671
1672 cleanup_compose_files();
1673
1674 sub cleanup_compose_files {
1675         unlink($compose_filename, $compose_filename . ".final") if $compose;
1676 }
1677
1678 $smtp->quit if $smtp;
1679
1680 sub apply_transfer_encoding {
1681         my $message = shift;
1682         my $from = shift;
1683         my $to = shift;
1684
1685         return $message if ($from eq $to and $from ne '7bit');
1686
1687         require MIME::QuotedPrint;
1688         require MIME::Base64;
1689
1690         $message = MIME::QuotedPrint::decode($message)
1691                 if ($from eq 'quoted-printable');
1692         $message = MIME::Base64::decode($message)
1693                 if ($from eq 'base64');
1694
1695         die "cannot send message as 7bit"
1696                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1697         return $message
1698                 if ($to eq '7bit' or $to eq '8bit');
1699         return MIME::QuotedPrint::encode($message, "\n", 0)
1700                 if ($to eq 'quoted-printable');
1701         return MIME::Base64::encode($message, "\n")
1702                 if ($to eq 'base64');
1703         die "invalid transfer encoding";
1704 }
1705
1706 sub unique_email_list {
1707         my %seen;
1708         my @emails;
1709
1710         foreach my $entry (@_) {
1711                 my $clean = extract_valid_address_or_die($entry);
1712                 $seen{$clean} ||= 0;
1713                 next if $seen{$clean}++;
1714                 push @emails, $entry;
1715         }
1716         return @emails;
1717 }
1718
1719 sub validate_patch {
1720         my $fn = shift;
1721         open(my $fh, '<', $fn)
1722                 or die "unable to open $fn: $!\n";
1723         while (my $line = <$fh>) {
1724                 if (length($line) > 998) {
1725                         return "$.: patch contains a line longer than 998 characters";
1726                 }
1727         }
1728         return;
1729 }
1730
1731 sub handle_backup {
1732         my ($last, $lastlen, $file, $known_suffix) = @_;
1733         my ($suffix, $skip);
1734
1735         $skip = 0;
1736         if (defined $last &&
1737             ($lastlen < length($file)) &&
1738             (substr($file, 0, $lastlen) eq $last) &&
1739             ($suffix = substr($file, $lastlen)) !~ /^[a-z0-9]/i) {
1740                 if (defined $known_suffix && $suffix eq $known_suffix) {
1741                         print "Skipping $file with backup suffix '$known_suffix'.\n";
1742                         $skip = 1;
1743                 } else {
1744                         my $answer = ask("Do you really want to send $file? (y|N): ",
1745                                          valid_re => qr/^(?:y|n)/i,
1746                                          default => 'n');
1747                         $skip = ($answer ne 'y');
1748                         if ($skip) {
1749                                 $known_suffix = $suffix;
1750                         }
1751                 }
1752         }
1753         return ($skip, $known_suffix);
1754 }
1755
1756 sub handle_backup_files {
1757         my @file = @_;
1758         my ($last, $lastlen, $known_suffix, $skip, @result);
1759         for my $file (@file) {
1760                 ($skip, $known_suffix) = handle_backup($last, $lastlen,
1761                                                        $file, $known_suffix);
1762                 push @result, $file unless $skip;
1763                 $last = $file;
1764                 $lastlen = length($file);
1765         }
1766         return @result;
1767 }
1768
1769 sub file_has_nonascii {
1770         my $fn = shift;
1771         open(my $fh, '<', $fn)
1772                 or die "unable to open $fn: $!\n";
1773         while (my $line = <$fh>) {
1774                 return 1 if $line =~ /[^[:ascii:]]/;
1775         }
1776         return 0;
1777 }
1778
1779 sub body_or_subject_has_nonascii {
1780         my $fn = shift;
1781         open(my $fh, '<', $fn)
1782                 or die "unable to open $fn: $!\n";
1783         while (my $line = <$fh>) {
1784                 last if $line =~ /^$/;
1785                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1786         }
1787         while (my $line = <$fh>) {
1788                 return 1 if $line =~ /[^[:ascii:]]/;
1789         }
1790         return 0;
1791 }