git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $SVN_URL
   8                 $GIT_SVN_INDEX $GIT_SVN
   9                 $GIT_DIR $GIT_SVN_DIR $REVDB
  10                 $_follow_parent $sha1 $sha1_short $_revision
  11                 $_cp_remote $_upgrade $_rmdir $_q $_cp_similarity
  12                 $_find_copies_harder $_l $_authors %users/;
  13 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  14 $VERSION = '@@GIT_VERSION@@';
  15
  16 $ENV{GIT_DIR} ||= '.git';
  17 $Git::SVN::default_repo_id = 'git-svn';
  18 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  19
  20 my $LC_ALL = $ENV{LC_ALL};
  21 $Git::SVN::Log::TZ = $ENV{TZ};
  22 # make sure the svn binary gives consistent output between locales and TZs:
  23 $ENV{TZ} = 'UTC';
  24 $ENV{LC_ALL} = 'C';
  25 $| = 1; # unbuffer STDOUT
  26
  27 sub fatal (@) { print STDERR @_; exit 1 }
  28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  29 require SVN::Ra;
  30 require SVN::Delta;
  31 if ($SVN::Core::VERSION lt '1.1.0') {
  32         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
  33 }
  34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  37 use Carp qw/croak/;
  38 use IO::File qw//;
  39 use File::Basename qw/dirname basename/;
  40 use File::Path qw/mkpath/;
  41 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev pass_through/;
  42 use IPC::Open3;
  43 use Git;
  44
  45 BEGIN {
  46         my $s;
  47         foreach (qw/command command_oneline command_noisy command_output_pipe
  48                     command_input_pipe command_close_pipe/) {
  49                 $s .= "*SVN::Git::Editor::$_ = *SVN::Git::Fetcher::$_ = ".
  50                       "*Git::SVN::Migration::$_ = ".
  51                       "*Git::SVN::Log::$_ = *Git::SVN::$_ = *$_ = *Git::$_; ";
  52         }
  53         eval $s;
  54 }
  55
  56 my ($SVN);
  57
  58 my $_optimize_commits = 1 unless $ENV{GIT_SVN_NO_OPTIMIZE_COMMITS};
  59 $sha1 = qr/[a-f\d]{40}/;
  60 $sha1_short = qr/[a-f\d]{4,40}/;
  61 my ($_stdin, $_help, $_edit,
  62         $_repack, $_repack_nr, $_repack_flags,
  63         $_message, $_file, $_no_metadata,
  64         $_template, $_shared,
  65         $_version, $_upgrade,
  66         $_merge, $_strategy, $_dry_run,
  67         $_prefix);
  68
  69 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  70                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  71                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  72 my %fc_opts = ( 'follow-parent|follow' => \$_follow_parent,
  73                 'authors-file|A=s' => \$_authors,
  74                 'repack:i' => \$_repack,
  75                 'no-metadata' => \$_no_metadata,
  76                 'quiet|q' => \$_q,
  77                 'repack-flags|repack-args|repack-opts=s' => \$_repack_flags,
  78                 %remote_opts );
  79
  80 my ($_trunk, $_tags, $_branches);
  81 my %multi_opts = ( 'trunk|T=s' => \$_trunk,
  82                 'tags|t=s' => \$_tags,
  83                 'branches|b=s' => \$_branches );
  84 my %init_opts = ( 'template=s' => \$_template, 'shared' => \$_shared );
  85 my %cmt_opts = ( 'edit|e' => \$_edit,
  86                 'rmdir' => \$_rmdir,
  87                 'find-copies-harder' => \$_find_copies_harder,
  88                 'l=i' => \$_l,
  89                 'copy-similarity|C=i'=> \$_cp_similarity
  90 );
  91
  92 my %cmd = (
  93         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
  94                         { 'revision|r=s' => \$_revision, %fc_opts } ],
  95         init => [ \&cmd_init, "Initialize a repo for tracking" .
  96                           " (requires URL argument)",
  97                           \%init_opts ],
  98         dcommit => [ \&cmd_dcommit,
  99                      'Commit several diffs to merge with upstream',
 100                         { 'merge|m|M' => \$_merge,
 101                           'strategy|s=s' => \$_strategy,
 102                           'dry-run|n' => \$_dry_run,
 103                         %cmt_opts, %fc_opts } ],
 104         'set-tree' => [ \&cmd_set_tree,
 105                         "Set an SVN repository to a git tree-ish",
 106                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 107         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 108                         { 'revision|r=i' => \$_revision } ],
 109         rebuild => [ \&cmd_rebuild, "Rebuild git-svn metadata (after git clone)",
 110                         { 'copy-remote|remote=s' => \$_cp_remote,
 111                           'upgrade' => \$_upgrade } ],
 112         'multi-init' => [ \&cmd_multi_init,
 113                         'Initialize multiple trees (like git-svnimport)',
 114                         { %multi_opts, %init_opts, %remote_opts,
 115                          'revision|r=i' => \$_revision,
 116                          'prefix=s' => \$_prefix,
 117                         } ],
 118         'multi-fetch' => [ \&cmd_multi_fetch,
 119                         'Fetch multiple trees (like git-svnimport)',
 120                         \%fc_opts ],
 121         'migrate' => [ sub { },
 122                        # no-op, we automatically run this anyways,
 123                        'Migrate configuration/metadata/layout from
 124                         previous versions of git-svn',
 125                         \%remote_opts ],
 126         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 127                         { 'limit=i' => \$Git::SVN::Log::limit,
 128                           'revision|r=s' => \$_revision,
 129                           'verbose|v' => \$Git::SVN::Log::verbose,
 130                           'incremental' => \$Git::SVN::Log::incremental,
 131                           'oneline' => \$Git::SVN::Log::oneline,
 132                           'show-commit' => \$Git::SVN::Log::show_commit,
 133                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 134                           'authors-file|A=s' => \$_authors,
 135                           'color' => \$Git::SVN::Log::color,
 136                           'pager=s' => \$Git::SVN::Log::pager,
 137                         } ],
 138         'commit-diff' => [ \&cmd_commit_diff,
 139                            'Commit a diff between two trees',
 140                         { 'message|m=s' => \$_message,
 141                           'file|F=s' => \$_file,
 142                           'revision|r=s' => \$_revision,
 143                         %cmt_opts } ],
 144 );
 145
 146 my $cmd;
 147 for (my $i = 0; $i < @ARGV; $i++) {
 148         if (defined $cmd{$ARGV[$i]}) {
 149                 $cmd = $ARGV[$i];
 150                 splice @ARGV, $i, 1;
 151                 last;
 152         }
 153 };
 154
 155 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 156
 157 read_repo_config(\%opts);
 158 my $rv = GetOptions(%opts, 'help|H|h' => \$_help,
 159                                 'version|V' => \$_version,
 160                                 'minimize-connections' =>
 161                                   \$Git::SVN::Migration::_minimize,
 162                                 'id|i=s' => \$Git::SVN::default_ref_id);
 163 exit 1 if (!$rv && $cmd ne 'log');
 164
 165 usage(0) if $_help;
 166 version() if $_version;
 167 usage(1) unless defined $cmd;
 168 load_authors() if $_authors;
 169 unless ($cmd =~ /^(?:init|rebuild|multi-init|commit-diff)$/) {
 170         Git::SVN::Migration::migration_check();
 171 }
 172 eval {
 173         Git::SVN::verify_remotes_sanity();
 174         $cmd{$cmd}->[0]->(@ARGV);
 175 };
 176 fatal $@ if $@;
 177 exit 0;
 178
 179 ####################### primary functions ######################
 180 sub usage {
 181         my $exit = shift || 0;
 182         my $fd = $exit ? \*STDERR : \*STDOUT;
 183         print $fd <<"";
 184 git-svn - bidirectional operations between a single Subversion tree and git
 185 Usage: $0 <command> [options] [arguments]\n
 186
 187         print $fd "Available commands:\n" unless $cmd;
 188
 189         foreach (sort keys %cmd) {
 190                 next if $cmd && $cmd ne $_;
 191                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 192                 foreach (keys %{$cmd{$_}->[2]}) {
 193                         # prints out arguments as they should be passed:
 194                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 195                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 196                                                         "--$_" : "-$_" }
 197                                                 split /\|/,$_)," $x\n";
 198                 }
 199         }
 200         print $fd <<"";
 201 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 202 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 203 one git repository and want to keep them separate.  See git-svn(1) for more
 204 information.
 205
 206         exit $exit;
 207 }
 208
 209 sub version {
 210         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 211         exit 0;
 212 }
 213
 214 sub cmd_rebuild {
 215         my $url = shift;
 216         my $gs = $url ? Git::SVN->init($url)
 217                       : eval { Git::SVN->new };
 218         $gs ||= Git::SVN->_new;
 219         if (!verify_ref($gs->refname.'^0')) {
 220                 $gs->copy_remote_ref;
 221         }
 222
 223         my ($rev_list, $ctx) = command_output_pipe("rev-list", $gs->refname);
 224         my $latest;
 225         my $svn_uuid;
 226         while (<$rev_list>) {
 227                 chomp;
 228                 my $c = $_;
 229                 fatal "Non-SHA1: $c\n" unless $c =~ /^$sha1$/o;
 230                 my ($url, $rev, $uuid) = cmt_metadata($c);
 231
 232                 # ignore merges (from set-tree)
 233                 next if (!defined $rev || !$uuid);
 234
 235                 # if we merged or otherwise started elsewhere, this is
 236                 # how we break out of it
 237                 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
 238                     ($gs->{url} && $url && ($url ne $gs->{url}))) {
 239                         next;
 240                 }
 241
 242                 unless (defined $latest) {
 243                         if (!$gs->{url} && !$url) {
 244                                 fatal "SVN repository location required\n";
 245                         }
 246                         $gs = Git::SVN->init($url);
 247                         $latest = $rev;
 248                 }
 249                 $gs->rev_db_set($rev, $c);
 250                 print "r$rev = $c\n";
 251         }
 252         command_close_pipe($rev_list, $ctx);
 253 }
 254
 255 sub do_git_init_db {
 256         unless (-d $ENV{GIT_DIR}) {
 257                 my @init_db = ('init');
 258                 push @init_db, "--template=$_template" if defined $_template;
 259                 push @init_db, "--shared" if defined $_shared;
 260                 command_noisy(@init_db);
 261         }
 262 }
 263
 264 sub cmd_init {
 265         my $url = shift or die "SVN repository location required " .
 266                                 "as a command-line argument\n";
 267         if (my $repo_path = shift) {
 268                 unless (-d $repo_path) {
 269                         mkpath([$repo_path]);
 270                 }
 271                 chdir $repo_path or croak $!;
 272                 $ENV{GIT_DIR} = $repo_path . "/.git";
 273         }
 274         do_git_init_db();
 275
 276         Git::SVN->init($url);
 277 }
 278
 279 sub cmd_fetch {
 280         if (@_) {
 281                 die "Additional fetch arguments are no longer supported.\n",
 282                     "Use --follow-parent if you have moved/copied directories
 283                     instead.\n";
 284         }
 285         my $gs = Git::SVN->new;
 286         $gs->fetch;
 287         if ($gs->{last_commit} && !verify_ref('refs/heads/master^0')) {
 288                 command_noisy(qw(update-ref refs/heads/master),
 289                               $gs->{last_commit});
 290         }
 291 }
 292
 293 sub cmd_set_tree {
 294         my (@commits) = @_;
 295         if ($_stdin || !@commits) {
 296                 print "Reading from stdin...\n";
 297                 @commits = ();
 298                 while (<STDIN>) {
 299                         if (/\b($sha1_short)\b/o) {
 300                                 unshift @commits, $1;
 301                         }
 302                 }
 303         }
 304         my @revs;
 305         foreach my $c (@commits) {
 306                 my @tmp = command('rev-parse',$c);
 307                 if (scalar @tmp == 1) {
 308                         push @revs, $tmp[0];
 309                 } elsif (scalar @tmp > 1) {
 310                         push @revs, reverse(command('rev-list',@tmp));
 311                 } else {
 312                         fatal "Failed to rev-parse $c\n";
 313                 }
 314         }
 315         my $gs = Git::SVN->new;
 316         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 317         $gs->fetch;
 318         if ($r_last != $gs->{last_rev}) {
 319                 fatal "There are new revisions that were fetched ",
 320                       "and need to be merged (or acknowledged) ",
 321                       "before committing.\nlast rev: $r_last\n",
 322                       " current: $gs->{last_rev}\n";
 323         }
 324         $gs->set_tree($_) foreach @revs;
 325         print "Done committing ",scalar @revs," revisions to SVN\n";
 326 }
 327
 328 sub cmd_dcommit {
 329         my $head = shift;
 330         my $gs = Git::SVN->new;
 331         $head ||= 'HEAD';
 332         my @refs = command(qw/rev-list --no-merges/, $gs->refname."..$head");
 333         my $last_rev;
 334         foreach my $d (reverse @refs) {
 335                 if (!verify_ref("$d~1")) {
 336                         fatal "Commit $d\n",
 337                               "has no parent commit, and therefore ",
 338                               "nothing to diff against.\n",
 339                               "You should be working from a repository ",
 340                               "originally created by git-svn\n";
 341                 }
 342                 unless (defined $last_rev) {
 343                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 344                         unless (defined $last_rev) {
 345                                 fatal "Unable to extract revision information ",
 346                                       "from commit $d~1\n";
 347                         }
 348                 }
 349                 if ($_dry_run) {
 350                         print "diff-tree $d~1 $d\n";
 351                 } else {
 352                         my $log = get_commit_entry($d)->{log};
 353                         my $ra = $gs->ra;
 354                         my $pool = SVN::Pool->new;
 355                         my %ed_opts = ( r => $last_rev,
 356                                         ra => $ra->dup,
 357                                         svn_path => $ra->{svn_path} );
 358                         my $ed = SVN::Git::Editor->new(\%ed_opts,
 359                                          $ra->get_commit_editor($log,
 360                                          sub { print "Committed r$_[0]\n";
 361                                                $last_rev = $_[0]; }),
 362                                          $pool);
 363                         my $mods = $ed->apply_diff("$d~1", $d);
 364                         if (@$mods == 0) {
 365                                 print "No changes\n$d~1 == $d\n";
 366                         }
 367                 }
 368         }
 369         return if $_dry_run;
 370         $gs->fetch;
 371         # we always want to rebase against the current HEAD, not any
 372         # head that was passed to us
 373         my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
 374         my @finish;
 375         if (@diff) {
 376                 @finish = qw/rebase/;
 377                 push @finish, qw/--merge/ if $_merge;
 378                 push @finish, "--strategy=$_strategy" if $_strategy;
 379                 print STDERR "W: HEAD and ", $gs->refname, " differ, ",
 380                              "using @finish:\n", "@diff";
 381         } else {
 382                 print "No changes between current HEAD and ",
 383                       $gs->refname, "\nResetting to the latest ",
 384                       $gs->refname, "\n";
 385                 @finish = qw/reset --mixed/;
 386         }
 387         command_noisy(@finish, $gs->refname);
 388 }
 389
 390 sub cmd_show_ignore {
 391         my $gs = Git::SVN->new;
 392         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 393         $gs->traverse_ignore(\*STDOUT, '', $r);
 394 }
 395
 396 sub cmd_multi_init {
 397         my $url = shift;
 398         unless (defined $_trunk || defined $_branches || defined $_tags) {
 399                 usage(1);
 400         }
 401         do_git_init_db();
 402         $_prefix = '' unless defined $_prefix;
 403         $url =~ s#/+$## if defined $url;
 404         if (defined $_trunk) {
 405                 my $trunk_ref = $_prefix . 'trunk';
 406                 # try both old-style and new-style lookups:
 407                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 408                 unless ($gs_trunk) {
 409                         my ($trunk_url, $trunk_path) =
 410                                               complete_svn_url($url, $_trunk);
 411                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 412                                                    undef, $trunk_ref);
 413                 }
 414         }
 415         return unless defined $_branches || defined $_tags;
 416         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 417         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 418         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 419 }
 420
 421 sub cmd_multi_fetch {
 422         my @gs;
 423         foreach (command(qw/config -l/)) {
 424                 next unless m!^svn-remote\.(.+)\.fetch=
 425                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
 426                 my ($repo_id, $path, $ref_id) = ($1, $2, $3);
 427                 push @gs, Git::SVN->new($ref_id, $repo_id, $path);
 428         }
 429         foreach (@gs) {
 430                 $_->fetch;
 431         }
 432 }
 433
 434 # this command is special because it requires no metadata
 435 sub cmd_commit_diff {
 436         my ($ta, $tb, $url) = @_;
 437         my $usage = "Usage: $0 commit-diff -r<revision> ".
 438                     "<tree-ish> <tree-ish> [<URL>]\n";
 439         fatal($usage) if (!defined $ta || !defined $tb);
 440         if (!defined $url) {
 441                 my $gs = eval { Git::SVN->new };
 442                 if (!$gs) {
 443                         fatal("Needed URL or usable git-svn --id in ",
 444                               "the command-line\n", $usage);
 445                 }
 446                 $url = $gs->{url};
 447         }
 448         unless (defined $_revision) {
 449                 fatal("-r|--revision is a required argument\n", $usage);
 450         }
 451         if (defined $_message && defined $_file) {
 452                 fatal("Both --message/-m and --file/-F specified ",
 453                       "for the commit message.\n",
 454                       "I have no idea what you mean\n");
 455         }
 456         if (defined $_file) {
 457                 $_message = file_to_s($_file);
 458         } else {
 459                 $_message ||= get_commit_entry($tb)->{log};
 460         }
 461         my $ra ||= Git::SVN::Ra->new($url);
 462         my $r = $_revision;
 463         if ($r eq 'HEAD') {
 464                 $r = $ra->get_latest_revnum;
 465         } elsif ($r !~ /^\d+$/) {
 466                 die "revision argument: $r not understood by git-svn\n";
 467         }
 468         my $pool = SVN::Pool->new;
 469         my %ed_opts = ( r => $r,
 470                         ra => $ra->dup,
 471                         svn_path => $ra->{svn_path} );
 472         my $ed = SVN::Git::Editor->new(\%ed_opts,
 473                                        $ra->get_commit_editor($_message,
 474                                          sub { print "Committed r$_[0]\n" }),
 475                                        $pool);
 476         my $mods = $ed->apply_diff($ta, $tb);
 477         if (@$mods == 0) {
 478                 print "No changes\n$ta == $tb\n";
 479         }
 480         $pool->clear;
 481 }
 482
 483 ########################### utility functions #########################
 484
 485 sub complete_svn_url {
 486         my ($url, $path) = @_;
 487         $path =~ s#/+$##;
 488         if ($path !~ m#^[a-z\+]+://#) {
 489                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
 490                         fatal("E: '$path' is not a complete URL ",
 491                               "and a separate URL is not specified\n");
 492                 }
 493                 return ($url, $path);
 494         }
 495         return ($path, '');
 496 }
 497
 498 sub complete_url_ls_init {
 499         my ($ra, $repo_path, $switch, $pfx) = @_;
 500         unless ($repo_path) {
 501                 print STDERR "W: $switch not specified\n";
 502                 return;
 503         }
 504         $repo_path =~ s#/+$##;
 505         if ($repo_path =~ m#^[a-z\+]+://#) {
 506                 $ra = Git::SVN::Ra->new($repo_path);
 507                 $repo_path = '';
 508         } else {
 509                 $repo_path =~ s#^/+##;
 510                 unless ($ra) {
 511                         fatal("E: '$repo_path' is not a complete URL ",
 512                               "and a separate URL is not specified\n");
 513                 }
 514         }
 515         my $r = defined $_revision ? $_revision : $ra->get_latest_revnum;
 516         my ($dirent, undef, undef) = $ra->get_dir($repo_path, $r);
 517         my $url = $ra->{url};
 518         foreach my $d (sort keys %$dirent) {
 519                 next if ($dirent->{$d}->kind != $SVN::Node::dir);
 520                 my $path =  "$repo_path/$d";
 521                 my $ref = "$pfx$d";
 522                 my $gs = eval { Git::SVN->new($ref) };
 523                 # don't try to init already existing refs
 524                 unless ($gs) {
 525                         print "init $url/$path => $ref\n";
 526                         Git::SVN->init($url, $path, undef, $ref);
 527                 }
 528         }
 529 }
 530
 531 sub verify_ref {
 532         my ($ref) = @_;
 533         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
 534                                { STDERR => 0 }); };
 535 }
 536
 537 sub get_tree_from_treeish {
 538         my ($treeish) = @_;
 539         # $treeish can be a symbolic ref, too:
 540         my $type = command_oneline(qw/cat-file -t/, $treeish);
 541         my $expected;
 542         while ($type eq 'tag') {
 543                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
 544         }
 545         if ($type eq 'commit') {
 546                 $expected = (grep /^tree /, command(qw/cat-file commit/,
 547                                                     $treeish))[0];
 548                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
 549                 die "Unable to get tree from $treeish\n" unless $expected;
 550         } elsif ($type eq 'tree') {
 551                 $expected = $treeish;
 552         } else {
 553                 die "$treeish is a $type, expected tree, tag or commit\n";
 554         }
 555         return $expected;
 556 }
 557
 558 sub get_commit_entry {
 559         my ($treeish) = shift;
 560         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
 561         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
 562         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
 563         open my $log_fh, '>', $commit_editmsg or croak $!;
 564
 565         my $type = command_oneline(qw/cat-file -t/, $treeish);
 566         if ($type eq 'commit' || $type eq 'tag') {
 567                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
 568                                                          $type, $treeish);
 569                 my $in_msg = 0;
 570                 while (<$msg_fh>) {
 571                         if (!$in_msg) {
 572                                 $in_msg = 1 if (/^\s*$/);
 573                         } elsif (/^git-svn-id: /) {
 574                                 # skip this for now, we regenerate the
 575                                 # correct one on re-fetch anyways
 576                                 # TODO: set *:merge properties or like...
 577                         } else {
 578                                 print $log_fh $_ or croak $!;
 579                         }
 580                 }
 581                 command_close_pipe($msg_fh, $ctx);
 582         }
 583         close $log_fh or croak $!;
 584
 585         if ($_edit || ($type eq 'tree')) {
 586                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
 587                 # TODO: strip out spaces, comments, like git-commit.sh
 588                 system($editor, $commit_editmsg);
 589         }
 590         rename $commit_editmsg, $commit_msg or croak $!;
 591         open $log_fh, '<', $commit_msg or croak $!;
 592         { local $/; chomp($log_entry{log} = <$log_fh>); }
 593         close $log_fh or croak $!;
 594         unlink $commit_msg;
 595         \%log_entry;
 596 }
 597
 598 sub s_to_file {
 599         my ($str, $file, $mode) = @_;
 600         open my $fd,'>',$file or croak $!;
 601         print $fd $str,"\n" or croak $!;
 602         close $fd or croak $!;
 603         chmod ($mode &~ umask, $file) if (defined $mode);
 604 }
 605
 606 sub file_to_s {
 607         my $file = shift;
 608         open my $fd,'<',$file or croak "$!: file: $file\n";
 609         local $/;
 610         my $ret = <$fd>;
 611         close $fd or croak $!;
 612         $ret =~ s/\s*$//s;
 613         return $ret;
 614 }
 615
 616 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
 617 sub load_authors {
 618         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
 619         my $log = $cmd eq 'log';
 620         while (<$authors>) {
 621                 chomp;
 622                 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
 623                 my ($user, $name, $email) = ($1, $2, $3);
 624                 if ($log) {
 625                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
 626                 } else {
 627                         $users{$user} = [$name, $email];
 628                 }
 629         }
 630         close $authors or croak $!;
 631 }
 632
 633 # convert GetOpt::Long specs for use by git-config
 634 sub read_repo_config {
 635         return unless -d $ENV{GIT_DIR};
 636         my $opts = shift;
 637         foreach my $o (keys %$opts) {
 638                 my $v = $opts->{$o};
 639                 my ($key) = ($o =~ /^([a-z\-]+)/);
 640                 $key =~ s/-//g;
 641                 my $arg = 'git-config';
 642                 $arg .= ' --int' if ($o =~ /[:=]i$/);
 643                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
 644                 if (ref $v eq 'ARRAY') {
 645                         chomp(my @tmp = `$arg --get-all svn.$key`);
 646                         @$v = @tmp if @tmp;
 647                 } else {
 648                         chomp(my $tmp = `$arg --get svn.$key`);
 649                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
 650                                 $$v = $tmp;
 651                         }
 652                 }
 653         }
 654 }
 655
 656 sub extract_metadata {
 657         my $id = shift or return (undef, undef, undef);
 658         my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
 659                                                         \s([a-f\d\-]+)$/x);
 660         if (!defined $rev || !$uuid || !$url) {
 661                 # some of the original repositories I made had
 662                 # identifiers like this:
 663                 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
 664         }
 665         return ($url, $rev, $uuid);
 666 }
 667
 668 sub cmt_metadata {
 669         return extract_metadata((grep(/^git-svn-id: /,
 670                 command(qw/cat-file commit/, shift)))[-1]);
 671 }
 672
 673 sub get_commit_time {
 674         my $cmt = shift;
 675         my $fh = command_output_pipe(qw/rev-list --pretty=raw -n1/, $cmt);
 676         while (<$fh>) {
 677                 /^committer\s(?:.+) (\d+) ([\-\+]?\d+)$/ or next;
 678                 my ($s, $tz) = ($1, $2);
 679                 if ($tz =~ s/^\+//) {
 680                         $s += tz_to_s_offset($tz);
 681                 } elsif ($tz =~ s/^\-//) {
 682                         $s -= tz_to_s_offset($tz);
 683                 }
 684                 close $fh;
 685                 return $s;
 686         }
 687         die "Can't get commit time for commit: $cmt\n";
 688 }
 689
 690 sub tz_to_s_offset {
 691         my ($tz) = @_;
 692         $tz =~ s/(\d\d)$//;
 693         return ($1 * 60) + ($tz * 3600);
 694 }
 695
 696 package Git::SVN;
 697 use strict;
 698 use warnings;
 699 use vars qw/$default_repo_id $default_ref_id/;
 700 use Carp qw/croak/;
 701 use File::Path qw/mkpath/;
 702 use IPC::Open3;
 703
 704 # properties that we do not log:
 705 my %SKIP_PROP;
 706 BEGIN {
 707         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
 708                                         svn:special svn:executable
 709                                         svn:entry:committed-rev
 710                                         svn:entry:last-author
 711                                         svn:entry:uuid
 712                                         svn:entry:committed-date/;
 713 }
 714
 715 sub read_all_remotes {
 716         my $r = {};
 717         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
 718                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
 719                         $r->{$1}->{fetch}->{$2} = $3;
 720                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
 721                         $r->{$1}->{url} = $2;
 722                 }
 723         }
 724         $r;
 725 }
 726
 727 sub verify_remotes_sanity {
 728         return unless -d $ENV{GIT_DIR};
 729         my %seen;
 730         foreach (command(qw/config -l/)) {
 731                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
 732                         if ($seen{$1}) {
 733                                 die "Remote ref refs/remote/$1 is tracked by",
 734                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
 735                                     "Please resolve this ambiguity in ",
 736                                     "your git configuration file before ",
 737                                     "continuing\n";
 738                         }
 739                         $seen{$1} = $_;
 740                 }
 741         }
 742 }
 743
 744 # we allow more chars than remotes2config.sh...
 745 sub sanitize_remote_name {
 746         my ($name) = @_;
 747         $name =~ tr{A-Za-z0-9:,/+-}{.}c;
 748         $name;
 749 }
 750
 751 sub init {
 752         my ($class, $url, $path, $repo_id, $ref_id) = @_;
 753         my $self = _new($class, $repo_id, $ref_id, $path);
 754         if (defined $url) {
 755                 $url =~ s!/+$!!; # strip trailing slash
 756
 757                 # verify that we aren't overwriting anything:
 758                 my $orig_url = eval {
 759                         command_oneline('config', '--get',
 760                                         "svn-remote.$repo_id.url")
 761                 };
 762                 if ($orig_url && ($orig_url ne $url)) {
 763                         die "svn-remote.$repo_id.url already set: ",
 764                             "$orig_url\nwanted to set to: $url\n";
 765                 }
 766                 my ($xrepo_id, $xpath) = find_ref($self->refname);
 767                 if (defined $xpath) {
 768                         die "svn-remote.$xrepo_id.fetch already set to track ",
 769                             "$xpath:refs/remotes/", $self->refname, "\n";
 770                 }
 771                 if (!$orig_url) {
 772                         command_noisy('config',
 773                                       "svn-remote.$repo_id.url", $url);
 774                 }
 775                 command_noisy('config', '--add',
 776                               "svn-remote.$repo_id.fetch",
 777                               "$path:".$self->refname);
 778         }
 779         $self->{url} = $url;
 780         $self;
 781 }
 782
 783 sub find_ref {
 784         my ($ref_id) = @_;
 785         foreach (command(qw/config -l/)) {
 786                 next unless m!^svn-remote\.(.+)\.fetch=
 787                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
 788                 my ($repo_id, $path, $ref) = ($1, $2, $3);
 789                 if ($ref eq $ref_id) {
 790                         $path = '' if ($path =~ m#^\./?#);
 791                         return ($repo_id, $path);
 792                 }
 793         }
 794         (undef, undef, undef);
 795 }
 796
 797 sub new {
 798         my ($class, $ref_id, $repo_id, $path) = @_;
 799         if (defined $ref_id && !defined $repo_id && !defined $path) {
 800                 ($repo_id, $path) = find_ref($ref_id);
 801                 if (!defined $repo_id) {
 802                         die "Could not find a \"svn-remote.*.fetch\" key ",
 803                             "in the repository configuration matching: ",
 804                             "refs/remotes/$ref_id\n";
 805                 }
 806         }
 807         my $self = _new($class, $repo_id, $ref_id, $path);
 808         if (!defined $self->{path} || !length $self->{path}) {
 809                 my $fetch = command_oneline('config', '--get',
 810                                             "svn-remote.$repo_id.fetch",
 811                                             ":refs/remotes/$ref_id\$") or
 812                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
 813                          "\":refs/remotes/$ref_id\$\" in config\n";
 814                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
 815         }
 816         $self->{url} = command_oneline('config', '--get',
 817                                        "svn-remote.$repo_id.url") or
 818                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
 819         $self;
 820 }
 821
 822 sub refname { "refs/remotes/$_[0]->{ref_id}" }
 823
 824 sub ra {
 825         my ($self) = shift;
 826         $self->{ra} ||= Git::SVN::Ra->new($self->{url});
 827 }
 828
 829 sub rel_path {
 830         my ($self) = @_;
 831         my $repos_root = $self->ra->{repos_root};
 832         return $self->{path} if ($self->{url} eq $repos_root);
 833         my $url = $self->{url} .
 834                   (length $self->{path} ? "/$self->{path}" : $self->{path});
 835         $url =~ s!^\Q$repos_root\E/*!!g;
 836         $url;
 837 }
 838
 839 sub copy_remote_ref {
 840         my ($self) = @_;
 841         my $origin = $::_cp_remote ? $::_cp_remote : 'origin';
 842         my $ref = $self->refname;
 843         if (command('ls-remote', $origin, $ref)) {
 844                 command_noisy('fetch', $origin, "$ref:$ref");
 845         } elsif ($::_cp_remote && !$::_upgrade) {
 846                 die "Unable to find remote reference: $ref on $origin\n";
 847         }
 848 }
 849
 850 sub traverse_ignore {
 851         my ($self, $fh, $path, $r) = @_;
 852         $path =~ s#^/+##g;
 853         my ($dirent, undef, $props) = $self->ra->get_dir($path, $r);
 854         my $p = $path;
 855         $p =~ s#^\Q$self->{ra}->{svn_path}\E/##;
 856         print $fh length $p ? "\n# $p\n" : "\n# /\n";
 857         if (my $s = $props->{'svn:ignore'}) {
 858                 $s =~ s/[\r\n]+/\n/g;
 859                 chomp $s;
 860                 if (length $p == 0) {
 861                         $s =~ s#\n#\n/$p#g;
 862                         print $fh "/$s\n";
 863                 } else {
 864                         $s =~ s#\n#\n/$p/#g;
 865                         print $fh "/$p/$s\n";
 866                 }
 867         }
 868         foreach (sort keys %$dirent) {
 869                 next if $dirent->{$_}->kind != $SVN::Node::dir;
 870                 $self->traverse_ignore($fh, "$path/$_", $r);
 871         }
 872 }
 873
 874 # returns the newest SVN revision number and newest commit SHA1
 875 sub last_rev_commit {
 876         my ($self) = @_;
 877         if (defined $self->{last_rev} && defined $self->{last_commit}) {
 878                 return ($self->{last_rev}, $self->{last_commit});
 879         }
 880         my $c = ::verify_ref($self->refname.'^0');
 881         if ($c) {
 882                 my $rev = (::cmt_metadata($c))[1];
 883                 if (defined $rev) {
 884                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 885                         return ($rev, $c);
 886                 }
 887         }
 888         my $offset = -41; # from tail
 889         my $rl;
 890         open my $fh, '<', $self->{db_path} or
 891                                  croak "$self->{db_path} not readable: $!\n";
 892         seek $fh, $offset, 2;
 893         $rl = readline $fh;
 894         defined $rl or return (undef, undef);
 895         chomp $rl;
 896         while ($c ne $rl && tell $fh != 0) {
 897                 $offset -= 41;
 898                 seek $fh, $offset, 2;
 899                 $rl = readline $fh;
 900                 defined $rl or return (undef, undef);
 901                 chomp $rl;
 902         }
 903         my $rev = tell $fh;
 904         croak $! if ($rev < 0);
 905         $rev =  ($rev - 41) / 41;
 906         close $fh or croak $!;
 907         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 908         return ($rev, $c);
 909 }
 910
 911 sub parse_revision {
 912         my ($self, $base) = @_;
 913         my $head = $self->ra->get_latest_revnum;
 914         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
 915                 return ($base + 1, $head) if (defined $base);
 916                 return (0, $head);
 917         }
 918         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
 919         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
 920         if ($::_revision =~ /^BASE:(\d+)$/) {
 921                 return ($base + 1, $1) if (defined $base);
 922                 return (0, $head);
 923         }
 924         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
 925         die "revision argument: $::_revision not understood by git-svn\n",
 926                 "Try using the command-line svn client instead\n";
 927 }
 928
 929 sub tmp_index_do {
 930         my ($self, $sub) = @_;
 931         my $old_index = $ENV{GIT_INDEX_FILE};
 932         $ENV{GIT_INDEX_FILE} = $self->{index};
 933         my @ret = &$sub;
 934         if ($old_index) {
 935                 $ENV{GIT_INDEX_FILE} = $old_index;
 936         } else {
 937                 delete $ENV{GIT_INDEX_FILE};
 938         }
 939         wantarray ? @ret : $ret[0];
 940 }
 941
 942 sub assert_index_clean {
 943         my ($self, $treeish) = @_;
 944
 945         $self->tmp_index_do(sub {
 946                 command_noisy('read-tree', $treeish) unless -e $self->{index};
 947                 my $x = command_oneline('write-tree');
 948                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
 949                            /^tree ($::sha1)/mo);
 950                 if ($y ne $x) {
 951                         unlink $self->{index} or croak $!;
 952                         command_noisy('read-tree', $treeish);
 953                 }
 954                 $x = command_oneline('write-tree');
 955                 if ($y ne $x) {
 956                         ::fatal "trees ($treeish) $y != $x\n",
 957                                 "Something is seriously wrong...\n";
 958                 }
 959         });
 960 }
 961
 962 sub get_commit_parents {
 963         my ($self, $log_entry, @parents) = @_;
 964         my (%seen, @ret, @tmp);
 965         # commit parents can be conditionally bound to a particular
 966         # svn revision via: "svn_revno=commit_sha1", filter them out here:
 967         foreach my $p (@parents) {
 968                 next unless defined $p;
 969                 if ($p =~ /^(\d+)=($::sha1_short)$/o) {
 970                         push @tmp, $2 if $1 == $log_entry->{revision};
 971                 } else {
 972                         push @tmp, $p if $p =~ /^$::sha1_short$/o;
 973                 }
 974         }
 975         if (my $cur = ::verify_ref($self->refname.'^0')) {
 976                 push @tmp, $cur;
 977         }
 978         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
 979         while (my $p = shift @tmp) {
 980                 next if $seen{$p};
 981                 $seen{$p} = 1;
 982                 push @ret, $p;
 983                 # MAXPARENT is defined to 16 in commit-tree.c:
 984                 last if @ret >= 16;
 985         }
 986         if (@tmp) {
 987                 die "r$log_entry->{revision}: No room for parents:\n\t",
 988                     join("\n\t", @tmp), "\n";
 989         }
 990         @ret;
 991 }
 992
 993 sub full_url {
 994         my ($self) = @_;
 995         $self->ra->{url} . (length $self->{path} ? '/' . $self->{path} : '');
 996 }
 997
 998 sub do_git_commit {
 999         my ($self, $log_entry, @parents) = @_;
1000         if (my $c = $self->rev_db_get($log_entry->{revision})) {
1001                 croak "$log_entry->{revision} = $c already exists! ",
1002                       "Why are we refetching it?\n";
1003         }
1004         my $author = $log_entry->{author};
1005         my ($name, $email) = (defined $::users{$author} ? @{$::users{$author}}
1006                            : ($author, "$author\@".$self->ra->uuid));
1007         $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $name;
1008         $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} = $email;
1009         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1010
1011         my $tree = $log_entry->{tree};
1012         if (!defined $tree) {
1013                 $tree = $self->tmp_index_do(sub {
1014                                             command_oneline('write-tree') });
1015         }
1016         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1017
1018         my @exec = ('git-commit-tree', $tree);
1019         foreach ($self->get_commit_parents($log_entry, @parents)) {
1020                 push @exec, '-p', $_;
1021         }
1022         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1023                                                                    or croak $!;
1024         print $msg_fh $log_entry->{log} or croak $!;
1025         print $msg_fh "\ngit-svn-id: ", $self->full_url, '@',
1026                       $log_entry->{revision}, ' ',
1027                       $self->ra->uuid, "\n" or croak $!;
1028         $msg_fh->flush == 0 or croak $!;
1029         close $msg_fh or croak $!;
1030         chomp(my $commit = do { local $/; <$out_fh> });
1031         close $out_fh or croak $!;
1032         waitpid $pid, 0;
1033         croak $? if $?;
1034         if ($commit !~ /^$::sha1$/o) {
1035                 die "Failed to commit, invalid sha1: $commit\n";
1036         }
1037
1038         command_noisy('update-ref',$self->refname, $commit);
1039         $self->rev_db_set($log_entry->{revision}, $commit);
1040
1041         $self->{last_rev} = $log_entry->{revision};
1042         $self->{last_commit} = $commit;
1043         print "r$log_entry->{revision} = $commit\n";
1044         return $commit;
1045 }
1046
1047 sub revisions_eq {
1048         my ($self, $r0, $r1) = @_;
1049         return 1 if $r0 == $r1;
1050         my $nr = 0;
1051         $self->ra->get_log([$self->{path}], $r0, $r1,
1052                            0, 0, 1, sub { $nr++ });
1053         return 0 if ($nr > 1);
1054         return 1;
1055 }
1056
1057 sub find_parent_branch {
1058         my ($self, $paths, $rev) = @_;
1059
1060         # look for a parent from another branch:
1061         my $i = $paths->{'/'.$self->rel_path} or return;
1062         my $branch_from = $i->copyfrom_path or return;
1063         my $r = $i->copyfrom_rev;
1064         my $repos_root = $self->ra->{repos_root};
1065         my $url = $self->ra->{url};
1066         my $new_url = $repos_root . $branch_from;
1067         print STDERR  "Found possible branch point: ",
1068                       "$new_url => ", $self->full_url, ", $r\n";
1069         $branch_from =~ s#^/##;
1070         my $remotes = read_all_remotes();
1071         my $gs;
1072         foreach my $repo_id (keys %$remotes) {
1073                 my $u = $remotes->{$repo_id}->{url} or next;
1074                 next if $url ne $u;
1075                 my $fetch = $remotes->{$repo_id}->{fetch};
1076                 foreach my $f (keys %$fetch) {
1077                         next if $f ne $branch_from;
1078                         $gs = Git::SVN->new($fetch->{$f}, $repo_id, $f);
1079                         last;
1080                 }
1081                 last if $gs;
1082         }
1083         unless ($gs) {
1084                 my $ref_id = $branch_from;
1085                 $ref_id .= "\@$r" if find_ref($ref_id);
1086                 # just grow a tail if we're not unique enough :x
1087                 $ref_id .= '-' while find_ref($ref_id);
1088                 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id);
1089         }
1090         my ($r0, $parent) = $gs->find_rev_before($r, 1);
1091         if ($::_follow_parent && (!defined $r0 || !defined $parent)) {
1092                 foreach (0 .. $r) {
1093                         my $log_entry = eval { $gs->do_fetch(undef, $_) };
1094                         $gs->do_git_commit($log_entry) if $log_entry;
1095                 }
1096                 ($r0, $parent) = $gs->last_rev_commit;
1097         }
1098         if (defined $r0 && defined $parent && $gs->revisions_eq($r0, $r)) {
1099                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1100                 $self->assert_index_clean($parent);
1101                 my $ed;
1102                 if ($self->ra->can_do_switch) {
1103                         print STDERR "Following parent with do_switch\n";
1104                         # do_switch works with svn/trunk >= r22312, but that
1105                         # is not included with SVN 1.4.2 (the latest version
1106                         # at the moment), so we can't rely on it
1107                         $self->{last_commit} = $parent;
1108                         $ed = SVN::Git::Fetcher->new($self);
1109                         $gs->ra->gs_do_switch($r0, $rev, $gs->{path}, 1,
1110                                               $self->full_url, $ed)
1111                           or die "SVN connection failed somewhere...\n";
1112                 } else {
1113                         print STDERR "Following parent with do_update\n";
1114                         $ed = SVN::Git::Fetcher->new($self);
1115                         $self->ra->gs_do_update($rev, $rev, $self->{path},
1116                                                 1, $ed)
1117                           or die "SVN connection failed somewhere...\n";
1118                 }
1119                 return $self->make_log_entry($rev, [$parent], $ed);
1120         }
1121         print STDERR "Branch parent not found...\n";
1122         return undef;
1123 }
1124
1125 sub do_fetch {
1126         my ($self, $paths, $rev) = @_;
1127         my $ed;
1128         my ($last_rev, @parents);
1129         if ($self->{last_commit}) {
1130                 $ed = SVN::Git::Fetcher->new($self);
1131                 $last_rev = $self->{last_rev};
1132                 $ed->{c} = $self->{last_commit};
1133                 @parents = ($self->{last_commit});
1134         } else {
1135                 $last_rev = $rev;
1136                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1137                         return $log_entry;
1138                 }
1139                 $ed = SVN::Git::Fetcher->new($self);
1140         }
1141         unless ($self->ra->gs_do_update($last_rev, $rev,
1142                                         $self->{path}, 1, $ed)) {
1143                 die "SVN connection failed somewhere...\n";
1144         }
1145         $self->make_log_entry($rev, \@parents, $ed);
1146 }
1147
1148 sub write_untracked {
1149         my ($self, $rev, $fh, $untracked) = @_;
1150         my $h;
1151         print $fh "r$rev\n" or croak $!;
1152         $h = $untracked->{empty};
1153         foreach (sort keys %$h) {
1154                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1155                 print $fh "  $act: ", uri_encode($_), "\n" or croak $!;
1156                 warn "W: $act: $_\n";
1157         }
1158         foreach my $t (qw/dir_prop file_prop/) {
1159                 $h = $untracked->{$t} or next;
1160                 foreach my $path (sort keys %$h) {
1161                         my $ppath = $path eq '' ? '.' : $path;
1162                         foreach my $prop (sort keys %{$h->{$path}}) {
1163                                 next if $SKIP_PROP{$prop};
1164                                 my $v = $h->{$path}->{$prop};
1165                                 if (defined $v) {
1166                                         print $fh "  +$t: ",
1167                                                   uri_encode($ppath), ' ',
1168                                                   uri_encode($prop), ' ',
1169                                                   uri_encode($v), "\n"
1170                                                   or croak $!;
1171                                 } else {
1172                                         print $fh "  -$t: ",
1173                                                   uri_encode($ppath), ' ',
1174                                                   uri_encode($prop), "\n"
1175                                                   or croak $!;
1176                                 }
1177                         }
1178                 }
1179         }
1180         foreach my $t (qw/absent_file absent_directory/) {
1181                 $h = $untracked->{$t} or next;
1182                 foreach my $parent (sort keys %$h) {
1183                         foreach my $path (sort @{$h->{$parent}}) {
1184                                 print $fh "  $t: ",
1185                                       uri_encode("$parent/$path"), "\n"
1186                                       or croak $!;
1187                                 warn "W: $t: $parent/$path ",
1188                                      "Insufficient permissions?\n";
1189                         }
1190                 }
1191         }
1192 }
1193
1194 sub parse_svn_date {
1195         my $date = shift || return '+0000 1970-01-01 00:00:00';
1196         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1197                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1198                                          croak "Unable to parse date: $date\n";
1199         "+0000 $Y-$m-$d $H:$M:$S";
1200 }
1201
1202 sub check_author {
1203         my ($author) = @_;
1204         if (!defined $author || length $author == 0) {
1205                 $author = '(no author)';
1206         }
1207         if (defined $::_authors && ! defined $::users{$author}) {
1208                 die "Author: $author not defined in $::_authors file\n";
1209         }
1210         $author;
1211 }
1212
1213 sub make_log_entry {
1214         my ($self, $rev, $parents, $untracked) = @_;
1215         my $rp = $self->ra->rev_proplist($rev);
1216         my %log_entry = ( parents => $parents || [], revision => $rev,
1217                           revprops => $rp, log => '');
1218         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1219         $self->write_untracked($rev, $un, $untracked);
1220         foreach (sort keys %$rp) {
1221                 my $v = $rp->{$_};
1222                 if (/^svn:(author|date|log)$/) {
1223                         $log_entry{$1} = $v;
1224                 } else {
1225                         print $un "  rev_prop: ", uri_encode($_), ' ',
1226                                   uri_encode($v), "\n";
1227                 }
1228         }
1229         close $un or croak $!;
1230         $log_entry{date} = parse_svn_date($log_entry{date});
1231         $log_entry{author} = check_author($log_entry{author});
1232         $log_entry{log} .= "\n";
1233         \%log_entry;
1234 }
1235
1236 sub fetch {
1237         my ($self, @parents) = @_;
1238         my ($last_rev, $last_commit) = $self->last_rev_commit;
1239         my ($base, $head) = $self->parse_revision($last_rev);
1240         return if ($base > $head);
1241         if (defined $last_commit) {
1242                 $self->assert_index_clean($last_commit);
1243         }
1244         my $inc = 1000;
1245         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
1246         my $err_handler = $SVN::Error::handler;
1247         $SVN::Error::handler = \&skip_unknown_revs;
1248         while (1) {
1249                 my @revs;
1250                 $self->ra->get_log([$self->{path}], $min, $max, 0, 1, 1, sub {
1251                         my ($paths, $rev, $author, $date, $log) = @_;
1252                         push @revs, [ $paths, $rev ] });
1253                 foreach (@revs) {
1254                         my $log_entry = $self->do_fetch(@$_);
1255                         $self->do_git_commit($log_entry, @parents);
1256                 }
1257                 last if $max >= $head;
1258                 $min = $max + 1;
1259                 $max += $inc;
1260                 $max = $head if ($max > $head);
1261         }
1262         $SVN::Error::handler = $err_handler;
1263 }
1264
1265 sub set_tree_cb {
1266         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1267         # TODO: enable and test optimized commits:
1268         if (0 && $rev == ($self->{last_rev} + 1)) {
1269                 $log_entry->{revision} = $rev;
1270                 $log_entry->{author} = $author;
1271                 $self->do_git_commit($log_entry, "$rev=$tree");
1272         } else {
1273                 $self->fetch("$rev=$tree");
1274         }
1275 }
1276
1277 sub set_tree {
1278         my ($self, $tree) = (shift, shift);
1279         my $log_entry = ::get_commit_entry($tree);
1280         unless ($self->{last_rev}) {
1281                 fatal("Must have an existing revision to commit\n");
1282         }
1283         my $pool = SVN::Pool->new;
1284         my $ed = SVN::Git::Editor->new({ r => $self->{last_rev},
1285                                          ra => $self->ra->dup,
1286                                          svn_path => $self->ra->{svn_path}
1287                                        },
1288                                        $self->ra->get_commit_editor(
1289                                          $log_entry->{log}, sub {
1290                                            $self->set_tree_cb($log_entry,
1291                                                               $tree, @_);
1292                                        }),
1293                                        $pool);
1294         my $mods = $ed->apply_diff($self->{last_commit}, $tree);
1295         if (@$mods == 0) {
1296                 print "No changes\nr$self->{last_rev} = $tree\n";
1297         }
1298         $pool->clear;
1299 }
1300
1301 sub skip_unknown_revs {
1302         my ($err) = @_;
1303         my $errno = $err->apr_err();
1304         # Maybe the branch we're tracking didn't
1305         # exist when the repo started, so it's
1306         # not an error if it doesn't, just continue
1307         #
1308         # Wonderfully consistent library, eh?
1309         # 160013 - svn:// and file://
1310         # 175002 - http(s)://
1311         # 175007 - http(s):// (this repo required authorization, too...)
1312         #   More codes may be discovered later...
1313         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
1314                 return;
1315         }
1316         croak "Error from SVN, ($errno): ", $err->expanded_message,"\n";
1317 }
1318
1319 # rev_db:
1320 # Tie::File seems to be prone to offset errors if revisions get sparse,
1321 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
1322 # one of my favorite modules is out :<  Next up would be one of the DBM
1323 # modules, but I'm not sure which is most portable...  So I'll just
1324 # go with something that's plain-text, but still capable of
1325 # being randomly accessed.  So here's my ultra-simple fixed-width
1326 # database.  All records are 40 characters + "\n", so it's easy to seek
1327 # to a revision: (41 * rev) is the byte offset.
1328 # A record of 40 0s denotes an empty revision.
1329 # And yes, it's still pretty fast (faster than Tie::File).
1330
1331 sub rev_db_set {
1332         my ($self, $rev, $commit) = @_;
1333         length $commit == 40 or croak "arg3 must be a full SHA1 hexsum\n";
1334         open my $fh, '+<', $self->{db_path} or croak $!;
1335         my $offset = $rev * 41;
1336         # assume that append is the common case:
1337         seek $fh, 0, 2 or croak $!;
1338         my $pos = tell $fh;
1339         if ($pos < $offset) {
1340                 print $fh (('0' x 40),"\n") x (($offset - $pos) / 41)
1341                   or croak $!;
1342         }
1343         seek $fh, $offset, 0 or croak $!;
1344         print $fh $commit,"\n" or croak $!;
1345         close $fh or croak $!;
1346 }
1347
1348 sub rev_db_get {
1349         my ($self, $rev) = @_;
1350         my $ret;
1351         my $offset = $rev * 41;
1352         open my $fh, '<', $self->{db_path} or croak $!;
1353         if (seek $fh, $offset, 0) {
1354                 $ret = readline $fh;
1355                 if (defined $ret) {
1356                         chomp $ret;
1357                         $ret = undef if ($ret =~ /^0{40}$/);
1358                 }
1359         }
1360         close $fh or croak $!;
1361         $ret;
1362 }
1363
1364 sub find_rev_before {
1365         my ($self, $rev, $eq_ok) = @_;
1366         --$rev unless $eq_ok;
1367         while ($rev > 0) {
1368                 if (my $c = $self->rev_db_get($rev)) {
1369                         return ($rev, $c);
1370                 }
1371                 --$rev;
1372         }
1373         return (undef, undef);
1374 }
1375
1376 sub _new {
1377         my ($class, $repo_id, $ref_id, $path) = @_;
1378         unless (defined $repo_id && length $repo_id) {
1379                 $repo_id = $Git::SVN::default_repo_id;
1380         }
1381         unless (defined $ref_id && length $ref_id) {
1382                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
1383         }
1384         $_[1] = $repo_id = sanitize_remote_name($repo_id);
1385         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
1386         $_[3] = $path = '' unless (defined $path);
1387         mkpath([$dir]);
1388         unless (-f "$dir/.rev_db") {
1389                 open my $fh, '>>', "$dir/.rev_db" or croak $!;
1390                 close $fh or croak $!;
1391         }
1392         bless { ref_id => $ref_id, dir => $dir, index => "$dir/index",
1393                 path => $path,
1394                 db_path => "$dir/.rev_db", repo_id => $repo_id }, $class;
1395 }
1396
1397 sub uri_encode {
1398         my ($f) = @_;
1399         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1400         $f
1401 }
1402
1403 package Git::SVN::Prompt;
1404 use strict;
1405 use warnings;
1406 require SVN::Core;
1407 use vars qw/$_no_auth_cache $_username/;
1408
1409 sub simple {
1410         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
1411         $may_save = undef if $_no_auth_cache;
1412         $default_username = $_username if defined $_username;
1413         if (defined $default_username && length $default_username) {
1414                 if (defined $realm && length $realm) {
1415                         print STDERR "Authentication realm: $realm\n";
1416                         STDERR->flush;
1417                 }
1418                 $cred->username($default_username);
1419         } else {
1420                 username($cred, $realm, $may_save, $pool);
1421         }
1422         $cred->password(_read_password("Password for '" .
1423                                        $cred->username . "': ", $realm));
1424         $cred->may_save($may_save);
1425         $SVN::_Core::SVN_NO_ERROR;
1426 }
1427
1428 sub ssl_server_trust {
1429         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
1430         $may_save = undef if $_no_auth_cache;
1431         print STDERR "Error validating server certificate for '$realm':\n";
1432         if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
1433                 print STDERR " - The certificate is not issued by a trusted ",
1434                       "authority. Use the\n",
1435                       "   fingerprint to validate the certificate manually!\n";
1436         }
1437         if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
1438                 print STDERR " - The certificate hostname does not match.\n";
1439         }
1440         if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
1441                 print STDERR " - The certificate is not yet valid.\n";
1442         }
1443         if ($failures & $SVN::Auth::SSL::EXPIRED) {
1444                 print STDERR " - The certificate has expired.\n";
1445         }
1446         if ($failures & $SVN::Auth::SSL::OTHER) {
1447                 print STDERR " - The certificate has an unknown error.\n";
1448         }
1449         printf STDERR
1450                 "Certificate information:\n".
1451                 " - Hostname: %s\n".
1452                 " - Valid: from %s until %s\n".
1453                 " - Issuer: %s\n".
1454                 " - Fingerprint: %s\n",
1455                 map $cert_info->$_, qw(hostname valid_from valid_until
1456                                        issuer_dname fingerprint);
1457         my $choice;
1458 prompt:
1459         print STDERR $may_save ?
1460               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
1461               "(R)eject or accept (t)emporarily? ";
1462         STDERR->flush;
1463         $choice = lc(substr(<STDIN> || 'R', 0, 1));
1464         if ($choice =~ /^t$/i) {
1465                 $cred->may_save(undef);
1466         } elsif ($choice =~ /^r$/i) {
1467                 return -1;
1468         } elsif ($may_save && $choice =~ /^p$/i) {
1469                 $cred->may_save($may_save);
1470         } else {
1471                 goto prompt;
1472         }
1473         $cred->accepted_failures($failures);
1474         $SVN::_Core::SVN_NO_ERROR;
1475 }
1476
1477 sub ssl_client_cert {
1478         my ($cred, $realm, $may_save, $pool) = @_;
1479         $may_save = undef if $_no_auth_cache;
1480         print STDERR "Client certificate filename: ";
1481         STDERR->flush;
1482         chomp(my $filename = <STDIN>);
1483         $cred->cert_file($filename);
1484         $cred->may_save($may_save);
1485         $SVN::_Core::SVN_NO_ERROR;
1486 }
1487
1488 sub ssl_client_cert_pw {
1489         my ($cred, $realm, $may_save, $pool) = @_;
1490         $may_save = undef if $_no_auth_cache;
1491         $cred->password(_read_password("Password: ", $realm));
1492         $cred->may_save($may_save);
1493         $SVN::_Core::SVN_NO_ERROR;
1494 }
1495
1496 sub username {
1497         my ($cred, $realm, $may_save, $pool) = @_;
1498         $may_save = undef if $_no_auth_cache;
1499         if (defined $realm && length $realm) {
1500                 print STDERR "Authentication realm: $realm\n";
1501         }
1502         my $username;
1503         if (defined $_username) {
1504                 $username = $_username;
1505         } else {
1506                 print STDERR "Username: ";
1507                 STDERR->flush;
1508                 chomp($username = <STDIN>);
1509         }
1510         $cred->username($username);
1511         $cred->may_save($may_save);
1512         $SVN::_Core::SVN_NO_ERROR;
1513 }
1514
1515 sub _read_password {
1516         my ($prompt, $realm) = @_;
1517         print STDERR $prompt;
1518         STDERR->flush;
1519         require Term::ReadKey;
1520         Term::ReadKey::ReadMode('noecho');
1521         my $password = '';
1522         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
1523                 last if $key =~ /[\012\015]/; # \n\r
1524                 $password .= $key;
1525         }
1526         Term::ReadKey::ReadMode('restore');
1527         print STDERR "\n";
1528         STDERR->flush;
1529         $password;
1530 }
1531
1532 package main;
1533
1534 sub uri_encode {
1535         my ($f) = @_;
1536         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1537         $f
1538 }
1539
1540 sub uri_decode {
1541         my ($f) = @_;
1542         $f =~ tr/+/ /;
1543         $f =~ s/%([A-F0-9]{2})/chr hex($1)/ge;
1544         $f
1545 }
1546
1547 {
1548         my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
1549                                 $SVN::Node::dir.$SVN::Node::unknown.
1550                                 $SVN::Node::none.$SVN::Node::file.
1551                                 $SVN::Node::dir.$SVN::Node::unknown.
1552                                 $SVN::Auth::SSL::CNMISMATCH.
1553                                 $SVN::Auth::SSL::NOTYETVALID.
1554                                 $SVN::Auth::SSL::EXPIRED.
1555                                 $SVN::Auth::SSL::UNKNOWNCA.
1556                                 $SVN::Auth::SSL::OTHER;
1557 }
1558
1559 package SVN::Git::Fetcher;
1560 use vars qw/@ISA/;
1561 use strict;
1562 use warnings;
1563 use Carp qw/croak/;
1564 use IO::File qw//;
1565
1566 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
1567 sub new {
1568         my ($class, $git_svn) = @_;
1569         my $self = SVN::Delta::Editor->new;
1570         bless $self, $class;
1571         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
1572         $self->{empty} = {};
1573         $self->{dir_prop} = {};
1574         $self->{file_prop} = {};
1575         $self->{absent_dir} = {};
1576         $self->{absent_file} = {};
1577         ($self->{gui}, $self->{ctx}) = $git_svn->tmp_index_do(
1578                sub { command_input_pipe(qw/update-index -z --index-info/) } );
1579         require Digest::MD5;
1580         $self;
1581 }
1582
1583 sub set_path_strip {
1584         my ($self, $path) = @_;
1585         $self->{path_strip} = qr/^\Q$path\E\/?/;
1586 }
1587
1588 sub open_root {
1589         { path => '' };
1590 }
1591
1592 sub open_directory {
1593         my ($self, $path, $pb, $rev) = @_;
1594         { path => $path };
1595 }
1596
1597 sub git_path {
1598         my ($self, $path) = @_;
1599         $path =~ s!$self->{path_strip}!! if $self->{path_strip};
1600         $path;
1601 }
1602
1603 sub delete_entry {
1604         my ($self, $path, $rev, $pb) = @_;
1605         my $gui = $self->{gui};
1606
1607         my $gpath = $self->git_path($path);
1608         # remove entire directories.
1609         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
1610                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
1611                                                      -r --name-only -z/,
1612                                                      $self->{c}, '--', $gpath);
1613                 local $/ = "\0";
1614                 while (<$ls>) {
1615                         print $gui '0 ',0 x 40,"\t",$_ or croak $!;
1616                         print "\tD\t$_\n" unless $self->{q};
1617                 }
1618                 print "\tD\t$gpath/\n" unless $self->{q};
1619                 command_close_pipe($ls, $ctx);
1620                 $self->{empty}->{$path} = 0
1621         } else {
1622                 print $gui '0 ',0 x 40,"\t",$gpath,"\0" or croak $!;
1623                 print "\tD\t$gpath\n" unless $self->{q};
1624         }
1625         undef;
1626 }
1627
1628 sub open_file {
1629         my ($self, $path, $pb, $rev) = @_;
1630         my $gpath = $self->git_path($path);
1631         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
1632                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
1633         unless (defined $mode && defined $blob) {
1634                 die "$path was not found in commit $self->{c} (r$rev)\n";
1635         }
1636         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
1637           pool => SVN::Pool->new, action => 'M' };
1638 }
1639
1640 sub add_file {
1641         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
1642         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1643         delete $self->{empty}->{$dir};
1644         { path => $path, mode_a => 100644, mode_b => 100644,
1645           pool => SVN::Pool->new, action => 'A' };
1646 }
1647
1648 sub add_directory {
1649         my ($self, $path, $cp_path, $cp_rev) = @_;
1650         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1651         delete $self->{empty}->{$dir};
1652         $self->{empty}->{$path} = 1;
1653         { path => $path };
1654 }
1655
1656 sub change_dir_prop {
1657         my ($self, $db, $prop, $value) = @_;
1658         $self->{dir_prop}->{$db->{path}} ||= {};
1659         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
1660         undef;
1661 }
1662
1663 sub absent_directory {
1664         my ($self, $path, $pb) = @_;
1665         $self->{absent_dir}->{$pb->{path}} ||= [];
1666         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
1667         undef;
1668 }
1669
1670 sub absent_file {
1671         my ($self, $path, $pb) = @_;
1672         $self->{absent_file}->{$pb->{path}} ||= [];
1673         push @{$self->{absent_file}->{$pb->{path}}}, $path;
1674         undef;
1675 }
1676
1677 sub change_file_prop {
1678         my ($self, $fb, $prop, $value) = @_;
1679         if ($prop eq 'svn:executable') {
1680                 if ($fb->{mode_b} != 120000) {
1681                         $fb->{mode_b} = defined $value ? 100755 : 100644;
1682                 }
1683         } elsif ($prop eq 'svn:special') {
1684                 $fb->{mode_b} = defined $value ? 120000 : 100644;
1685         } else {
1686                 $self->{file_prop}->{$fb->{path}} ||= {};
1687                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
1688         }
1689         undef;
1690 }
1691
1692 sub apply_textdelta {
1693         my ($self, $fb, $exp) = @_;
1694         my $fh = IO::File->new_tmpfile;
1695         $fh->autoflush(1);
1696         # $fh gets auto-closed() by SVN::TxDelta::apply(),
1697         # (but $base does not,) so dup() it for reading in close_file
1698         open my $dup, '<&', $fh or croak $!;
1699         my $base = IO::File->new_tmpfile;
1700         $base->autoflush(1);
1701         if ($fb->{blob}) {
1702                 defined (my $pid = fork) or croak $!;
1703                 if (!$pid) {
1704                         open STDOUT, '>&', $base or croak $!;
1705                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
1706                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
1707                 }
1708                 waitpid $pid, 0;
1709                 croak $? if $?;
1710
1711                 if (defined $exp) {
1712                         seek $base, 0, 0 or croak $!;
1713                         my $md5 = Digest::MD5->new;
1714                         $md5->addfile($base);
1715                         my $got = $md5->hexdigest;
1716                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
1717                             "expected: $exp\n",
1718                             "     got: $got\n" if ($got ne $exp);
1719                 }
1720         }
1721         seek $base, 0, 0 or croak $!;
1722         $fb->{fh} = $dup;
1723         $fb->{base} = $base;
1724         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
1725 }
1726
1727 sub close_file {
1728         my ($self, $fb, $exp) = @_;
1729         my $hash;
1730         my $path = $self->git_path($fb->{path});
1731         if (my $fh = $fb->{fh}) {
1732                 seek($fh, 0, 0) or croak $!;
1733                 my $md5 = Digest::MD5->new;
1734                 $md5->addfile($fh);
1735                 my $got = $md5->hexdigest;
1736                 die "Checksum mismatch: $path\n",
1737                     "expected: $exp\n    got: $got\n" if ($got ne $exp);
1738                 seek($fh, 0, 0) or croak $!;
1739                 if ($fb->{mode_b} == 120000) {
1740                         read($fh, my $buf, 5) == 5 or croak $!;
1741                         $buf eq 'link ' or die "$path has mode 120000",
1742                                                "but is not a link\n";
1743                 }
1744                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
1745                 if (!$pid) {
1746                         open STDIN, '<&', $fh or croak $!;
1747                         exec qw/git-hash-object -w --stdin/ or croak $!;
1748                 }
1749                 chomp($hash = do { local $/; <$out> });
1750                 close $out or croak $!;
1751                 close $fh or croak $!;
1752                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
1753                 close $fb->{base} or croak $!;
1754         } else {
1755                 $hash = $fb->{blob} or die "no blob information\n";
1756         }
1757         $fb->{pool}->clear;
1758         my $gui = $self->{gui};
1759         print $gui "$fb->{mode_b} $hash\t$path\0" or croak $!;
1760         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $self->{q};
1761         undef;
1762 }
1763
1764 sub abort_edit {
1765         my $self = shift;
1766         eval { command_close_pipe($self->{gui}, $self->{ctx}) };
1767         $self->SUPER::abort_edit(@_);
1768 }
1769
1770 sub close_edit {
1771         my $self = shift;
1772         command_close_pipe($self->{gui}, $self->{ctx});
1773         $self->{git_commit_ok} = 1;
1774         $self->SUPER::close_edit(@_);
1775 }
1776
1777 package SVN::Git::Editor;
1778 use vars qw/@ISA/;
1779 use strict;
1780 use warnings;
1781 use Carp qw/croak/;
1782 use IO::File;
1783
1784 sub new {
1785         my $class = shift;
1786         my $git_svn = shift;
1787         my $self = SVN::Delta::Editor->new(@_);
1788         bless $self, $class;
1789         foreach (qw/svn_path r ra/) {
1790                 die "$_ required!\n" unless (defined $git_svn->{$_});
1791                 $self->{$_} = $git_svn->{$_};
1792         }
1793         $self->{pool} = SVN::Pool->new;
1794         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
1795         $self->{rm} = { };
1796         require Digest::MD5;
1797         return $self;
1798 }
1799
1800 sub split_path {
1801         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
1802 }
1803
1804 sub repo_path {
1805         (defined $_[1] && length $_[1]) ? $_[1] : ''
1806 }
1807
1808 sub url_path {
1809         my ($self, $path) = @_;
1810         $self->{ra}->{url} . '/' . $self->repo_path($path);
1811 }
1812
1813 sub rmdirs {
1814         my ($self, $tree_b) = @_;
1815         my $rm = $self->{rm};
1816         delete $rm->{''}; # we never delete the url we're tracking
1817         return unless %$rm;
1818
1819         foreach (keys %$rm) {
1820                 my @d = split m#/#, $_;
1821                 my $c = shift @d;
1822                 $rm->{$c} = 1;
1823                 while (@d) {
1824                         $c .= '/' . shift @d;
1825                         $rm->{$c} = 1;
1826                 }
1827         }
1828         delete $rm->{$self->{svn_path}};
1829         delete $rm->{''}; # we never delete the url we're tracking
1830         return unless %$rm;
1831
1832         my ($fh, $ctx) = command_output_pipe(
1833                                    qw/ls-tree --name-only -r -z/, $tree_b);
1834         local $/ = "\0";
1835         while (<$fh>) {
1836                 chomp;
1837                 my @dn = split m#/#, $_;
1838                 while (pop @dn) {
1839                         delete $rm->{join '/', @dn};
1840                 }
1841                 unless (%$rm) {
1842                         close $fh;
1843                         return;
1844                 }
1845         }
1846         command_close_pipe($fh, $ctx);
1847
1848         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
1849         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
1850                 $self->close_directory($bat->{$d}, $p);
1851                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
1852                 print "\tD+\t$d/\n" unless $::_q;
1853                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
1854                 delete $bat->{$d};
1855         }
1856 }
1857
1858 sub open_or_add_dir {
1859         my ($self, $full_path, $baton) = @_;
1860         my $t = $self->{ra}->check_path($full_path, $self->{r});
1861         if ($t == $SVN::Node::none) {
1862                 return $self->add_directory($full_path, $baton,
1863                                                 undef, -1, $self->{pool});
1864         } elsif ($t == $SVN::Node::dir) {
1865                 return $self->open_directory($full_path, $baton,
1866                                                 $self->{r}, $self->{pool});
1867         }
1868         print STDERR "$full_path already exists in repository at ",
1869                 "r$self->{r} and it is not a directory (",
1870                 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
1871         exit 1;
1872 }
1873
1874 sub ensure_path {
1875         my ($self, $path) = @_;
1876         my $bat = $self->{bat};
1877         $path = $self->repo_path($path);
1878         return $bat->{''} unless (length $path);
1879         my @p = split m#/+#, $path;
1880         my $c = shift @p;
1881         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
1882         while (@p) {
1883                 my $c0 = $c;
1884                 $c .= '/' . shift @p;
1885                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
1886         }
1887         return $bat->{$c};
1888 }
1889
1890 sub A {
1891         my ($self, $m) = @_;
1892         my ($dir, $file) = split_path($m->{file_b});
1893         my $pbat = $self->ensure_path($dir);
1894         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
1895                                         undef, -1);
1896         print "\tA\t$m->{file_b}\n" unless $::_q;
1897         $self->chg_file($fbat, $m);
1898         $self->close_file($fbat,undef,$self->{pool});
1899 }
1900
1901 sub C {
1902         my ($self, $m) = @_;
1903         my ($dir, $file) = split_path($m->{file_b});
1904         my $pbat = $self->ensure_path($dir);
1905         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
1906                                 $self->url_path($m->{file_a}), $self->{r});
1907         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
1908         $self->chg_file($fbat, $m);
1909         $self->close_file($fbat,undef,$self->{pool});
1910 }
1911
1912 sub delete_entry {
1913         my ($self, $path, $pbat) = @_;
1914         my $rpath = $self->repo_path($path);
1915         my ($dir, $file) = split_path($rpath);
1916         $self->{rm}->{$dir} = 1;
1917         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
1918 }
1919
1920 sub R {
1921         my ($self, $m) = @_;
1922         my ($dir, $file) = split_path($m->{file_b});
1923         my $pbat = $self->ensure_path($dir);
1924         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
1925                                 $self->url_path($m->{file_a}), $self->{r});
1926         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
1927         $self->chg_file($fbat, $m);
1928         $self->close_file($fbat,undef,$self->{pool});
1929
1930         ($dir, $file) = split_path($m->{file_a});
1931         $pbat = $self->ensure_path($dir);
1932         $self->delete_entry($m->{file_a}, $pbat);
1933 }
1934
1935 sub M {
1936         my ($self, $m) = @_;
1937         my ($dir, $file) = split_path($m->{file_b});
1938         my $pbat = $self->ensure_path($dir);
1939         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
1940                                 $pbat,$self->{r},$self->{pool});
1941         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
1942         $self->chg_file($fbat, $m);
1943         $self->close_file($fbat,undef,$self->{pool});
1944 }
1945
1946 sub T { shift->M(@_) }
1947
1948 sub change_file_prop {
1949         my ($self, $fbat, $pname, $pval) = @_;
1950         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
1951 }
1952
1953 sub chg_file {
1954         my ($self, $fbat, $m) = @_;
1955         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
1956                 $self->change_file_prop($fbat,'svn:executable','*');
1957         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
1958                 $self->change_file_prop($fbat,'svn:executable',undef);
1959         }
1960         my $fh = IO::File->new_tmpfile or croak $!;
1961         if ($m->{mode_b} =~ /^120/) {
1962                 print $fh 'link ' or croak $!;
1963                 $self->change_file_prop($fbat,'svn:special','*');
1964         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
1965                 $self->change_file_prop($fbat,'svn:special',undef);
1966         }
1967         defined(my $pid = fork) or croak $!;
1968         if (!$pid) {
1969                 open STDOUT, '>&', $fh or croak $!;
1970                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
1971         }
1972         waitpid $pid, 0;
1973         croak $? if $?;
1974         $fh->flush == 0 or croak $!;
1975         seek $fh, 0, 0 or croak $!;
1976
1977         my $md5 = Digest::MD5->new;
1978         $md5->addfile($fh) or croak $!;
1979         seek $fh, 0, 0 or croak $!;
1980
1981         my $exp = $md5->hexdigest;
1982         my $pool = SVN::Pool->new;
1983         my $atd = $self->apply_textdelta($fbat, undef, $pool);
1984         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
1985         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
1986         $pool->clear;
1987
1988         close $fh or croak $!;
1989 }
1990
1991 sub D {
1992         my ($self, $m) = @_;
1993         my ($dir, $file) = split_path($m->{file_b});
1994         my $pbat = $self->ensure_path($dir);
1995         print "\tD\t$m->{file_b}\n" unless $::_q;
1996         $self->delete_entry($m->{file_b}, $pbat);
1997 }
1998
1999 sub close_edit {
2000         my ($self) = @_;
2001         my ($p,$bat) = ($self->{pool}, $self->{bat});
2002         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2003                 $self->close_directory($bat->{$_}, $p);
2004         }
2005         $self->SUPER::close_edit($p);
2006         $p->clear;
2007 }
2008
2009 sub abort_edit {
2010         my ($self) = @_;
2011         $self->SUPER::abort_edit($self->{pool});
2012         $self->{pool}->clear;
2013 }
2014
2015 # this drives the editor
2016 sub apply_diff {
2017         my ($self, $tree_a, $tree_b) = @_;
2018         my @diff_tree = qw(diff-tree -z -r);
2019         if ($::_cp_similarity) {
2020                 push @diff_tree, "-C$::_cp_similarity";
2021         } else {
2022                 push @diff_tree, '-C';
2023         }
2024         push @diff_tree, '--find-copies-harder' if $::_find_copies_harder;
2025         push @diff_tree, "-l$::_l" if defined $::_l;
2026         push @diff_tree, $tree_a, $tree_b;
2027         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
2028         my $nl = $/;
2029         local $/ = "\0";
2030         my $state = 'meta';
2031         my @mods;
2032         while (<$diff_fh>) {
2033                 chomp $_; # this gets rid of the trailing "\0"
2034                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
2035                                         $::sha1\s($::sha1)\s
2036                                         ([MTCRAD])\d*$/xo) {
2037                         push @mods, {   mode_a => $1, mode_b => $2,
2038                                         sha1_b => $3, chg => $4 };
2039                         if ($4 =~ /^(?:C|R)$/) {
2040                                 $state = 'file_a';
2041                         } else {
2042                                 $state = 'file_b';
2043                         }
2044                 } elsif ($state eq 'file_a') {
2045                         my $x = $mods[$#mods] or croak "Empty array\n";
2046                         if ($x->{chg} !~ /^(?:C|R)$/) {
2047                                 croak "Error parsing $_, $x->{chg}\n";
2048                         }
2049                         $x->{file_a} = $_;
2050                         $state = 'file_b';
2051                 } elsif ($state eq 'file_b') {
2052                         my $x = $mods[$#mods] or croak "Empty array\n";
2053                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
2054                                 croak "Error parsing $_, $x->{chg}\n";
2055                         }
2056                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
2057                                 croak "Error parsing $_, $x->{chg}\n";
2058                         }
2059                         $x->{file_b} = $_;
2060                         $state = 'meta';
2061                 } else {
2062                         croak "Error parsing $_\n";
2063                 }
2064         }
2065         command_close_pipe($diff_fh, $ctx);
2066         $/ = $nl;
2067
2068         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2069         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @mods) {
2070                 my $f = $m->{chg};
2071                 if (defined $o{$f}) {
2072                         $self->$f($m);
2073                 } else {
2074                         fatal("Invalid change type: $f\n");
2075                 }
2076         }
2077         $self->rmdirs($tree_b) if $::_rmdir;
2078         if (@mods == 0) {
2079                 $self->abort_edit;
2080         } else {
2081                 $self->close_edit;
2082         }
2083         \@mods;
2084 }
2085
2086 package Git::SVN::Ra;
2087 use vars qw/@ISA $config_dir/;
2088 use strict;
2089 use warnings;
2090 my ($can_do_switch);
2091 my %RA;
2092
2093 BEGIN {
2094         # enforce temporary pool usage for some simple functions
2095         my $e;
2096         foreach (qw/get_latest_revnum rev_proplist get_file
2097                     check_path get_dir get_uuid get_repos_root/) {
2098                 $e .= "sub $_ {
2099                         my \$self = shift;
2100                         my \$pool = SVN::Pool->new;
2101                         my \@ret = \$self->SUPER::$_(\@_,\$pool);
2102                         \$pool->clear;
2103                         wantarray ? \@ret : \$ret[0]; }\n";
2104         }
2105         eval $e;
2106 }
2107
2108 sub new {
2109         my ($class, $url) = @_;
2110         $url =~ s!/+$!!;
2111         return $RA{$url} if $RA{$url};
2112
2113         SVN::_Core::svn_config_ensure($config_dir, undef);
2114         my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2115             SVN::Client::get_simple_provider(),
2116             SVN::Client::get_ssl_server_trust_file_provider(),
2117             SVN::Client::get_simple_prompt_provider(
2118               \&Git::SVN::Prompt::simple, 2),
2119             SVN::Client::get_ssl_client_cert_prompt_provider(
2120               \&Git::SVN::Prompt::ssl_client_cert, 2),
2121             SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2122               \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
2123             SVN::Client::get_username_provider(),
2124             SVN::Client::get_ssl_server_trust_prompt_provider(
2125               \&Git::SVN::Prompt::ssl_server_trust),
2126             SVN::Client::get_username_prompt_provider(
2127               \&Git::SVN::Prompt::username, 2),
2128           ]);
2129         my $config = SVN::Core::config_get_config($config_dir);
2130         my $self = SVN::Ra->new(url => $url, auth => $baton,
2131                               config => $config,
2132                               pool => SVN::Pool->new,
2133                               auth_provider_callbacks => $callbacks);
2134         $self->{svn_path} = $url;
2135         $self->{repos_root} = $self->get_repos_root;
2136         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E/*##;
2137         $RA{$url} = bless $self, $class;
2138 }
2139
2140 sub DESTROY {
2141         # do not call the real DESTROY since we store ourselves in %RA
2142 }
2143
2144 sub dup {
2145         my ($self) = @_;
2146         my $dup = SVN::Ra->new(pool => SVN::Pool->new,
2147                                 map { $_ => $self->{$_} } qw/config url
2148                      auth auth_provider_callbacks repos_root svn_path/);
2149         bless $dup, ref $self;
2150 }
2151
2152 sub get_log {
2153         my ($self, @args) = @_;
2154         my $pool = SVN::Pool->new;
2155         $args[4]-- if $args[4] && ! $::_follow_parent;
2156         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
2157         my $ret = $self->SUPER::get_log(@args, $pool);
2158         $pool->clear;
2159         $ret;
2160 }
2161
2162 sub get_commit_editor {
2163         my ($self, $log, $cb, $pool) = @_;
2164         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
2165         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
2166 }
2167
2168 sub uuid {
2169         my ($self) = @_;
2170         $self->{uuid} ||= $self->get_uuid;
2171 }
2172
2173 sub gs_do_update {
2174         my ($self, $rev_a, $rev_b, $path, $recurse, $editor) = @_;
2175         my $pool = SVN::Pool->new;
2176         $editor->set_path_strip($path);
2177         my $reporter = $self->do_update($rev_b, $path, $recurse,
2178                                         $editor, $pool);
2179         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2180         my $new = ($rev_a == $rev_b);
2181         $reporter->set_path('', $rev_a, $new, @lock, $pool);
2182         $reporter->finish_report($pool);
2183         $pool->clear;
2184         $editor->{git_commit_ok};
2185 }
2186
2187 sub gs_do_switch {
2188         my ($self, $rev_a, $rev_b, $path, $recurse, $url_b, $editor) = @_;
2189         my $pool = SVN::Pool->new;
2190         $editor->set_path_strip($path);
2191         my $reporter = $self->do_switch($rev_b, $path, $recurse,
2192                                         $url_b, $editor, $pool);
2193         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2194         $reporter->set_path('', $rev_a, 0, @lock, $pool);
2195         $reporter->finish_report($pool);
2196         $pool->clear;
2197         $editor->{git_commit_ok};
2198 }
2199
2200 sub can_do_switch {
2201         my $self = shift;
2202         unless (defined $can_do_switch) {
2203                 my $pool = SVN::Pool->new;
2204                 my $rep = eval {
2205                         $self->do_switch(1, '', 0, $self->{url},
2206                                          SVN::Delta::Editor->new, $pool);
2207                 };
2208                 if ($@) {
2209                         $can_do_switch = 0;
2210                 } else {
2211                         $rep->abort_report($pool);
2212                         $can_do_switch = 1;
2213                 }
2214                 $pool->clear;
2215         }
2216         $can_do_switch;
2217 }
2218
2219 package Git::SVN::Log;
2220 use strict;
2221 use warnings;
2222 use POSIX qw/strftime/;
2223 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
2224             %rusers $show_commit $incremental/;
2225 my $l_fmt;
2226
2227 sub cmt_showable {
2228         my ($c) = @_;
2229         return 1 if defined $c->{r};
2230         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
2231                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
2232                 my @log = command(qw/cat-file commit/, $c->{c});
2233                 shift @log while ($log[0] ne "\n");
2234                 shift @log;
2235                 @{$c->{l}} = grep !/^git-svn-id: /, @log;
2236
2237                 (undef, $c->{r}, undef) = ::extract_metadata(
2238                                 (grep(/^git-svn-id: /, @log))[-1]);
2239         }
2240         return defined $c->{r};
2241 }
2242
2243 sub log_use_color {
2244         return 1 if $color;
2245         my ($dc, $dcvar);
2246         $dcvar = 'color.diff';
2247         $dc = `git-config --get $dcvar`;
2248         if ($dc eq '') {
2249                 # nothing at all; fallback to "diff.color"
2250                 $dcvar = 'diff.color';
2251                 $dc = `git-config --get $dcvar`;
2252         }
2253         chomp($dc);
2254         if ($dc eq 'auto') {
2255                 my $pc;
2256                 $pc = `git-config --get color.pager`;
2257                 if ($pc eq '') {
2258                         # does not have it -- fallback to pager.color
2259                         $pc = `git-config --bool --get pager.color`;
2260                 }
2261                 else {
2262                         $pc = `git-config --bool --get color.pager`;
2263                         if ($?) {
2264                                 $pc = 'false';
2265                         }
2266                 }
2267                 chomp($pc);
2268                 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
2269                         return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
2270                 }
2271                 return 0;
2272         }
2273         return 0 if $dc eq 'never';
2274         return 1 if $dc eq 'always';
2275         chomp($dc = `git-config --bool --get $dcvar`);
2276         return ($dc eq 'true');
2277 }
2278
2279 sub git_svn_log_cmd {
2280         my ($r_min, $r_max) = @_;
2281         my $gs = Git::SVN->_new;
2282         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
2283                    $gs->refname);
2284         push @cmd, '-r' unless $non_recursive;
2285         push @cmd, qw/--raw --name-status/ if $verbose;
2286         push @cmd, '--color' if log_use_color();
2287         return @cmd unless defined $r_max;
2288         if ($r_max == $r_min) {
2289                 push @cmd, '--max-count=1';
2290                 if (my $c = $gs->rev_db_get($r_max)) {
2291                         push @cmd, $c;
2292                 }
2293         } else {
2294                 my ($c_min, $c_max);
2295                 $c_max = $gs->rev_db_get($r_max);
2296                 $c_min = $gs->rev_db_get($r_min);
2297                 if (defined $c_min && defined $c_max) {
2298                         if ($r_max > $r_max) {
2299                                 push @cmd, "$c_min..$c_max";
2300                         } else {
2301                                 push @cmd, "$c_max..$c_min";
2302                         }
2303                 } elsif ($r_max > $r_min) {
2304                         push @cmd, $c_max;
2305                 } else {
2306                         push @cmd, $c_min;
2307                 }
2308         }
2309         return @cmd;
2310 }
2311
2312 # adapted from pager.c
2313 sub config_pager {
2314         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
2315         if (!defined $pager) {
2316                 $pager = 'less';
2317         } elsif (length $pager == 0 || $pager eq 'cat') {
2318                 $pager = undef;
2319         }
2320 }
2321
2322 sub run_pager {
2323         return unless -t *STDOUT;
2324         pipe my $rfd, my $wfd or return;
2325         defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
2326         if (!$pid) {
2327                 open STDOUT, '>&', $wfd or
2328                                      ::fatal "Can't redirect to stdout: $!\n";
2329                 return;
2330         }
2331         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
2332         $ENV{LESS} ||= 'FRSX';
2333         exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
2334 }
2335
2336 sub get_author_info {
2337         my ($dest, $author, $t, $tz) = @_;
2338         $author =~ s/(?:^\s*|\s*$)//g;
2339         $dest->{a_raw} = $author;
2340         my $au;
2341         if ($::_authors) {
2342                 $au = $rusers{$author} || undef;
2343         }
2344         if (!$au) {
2345                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
2346         }
2347         $dest->{t} = $t;
2348         $dest->{tz} = $tz;
2349         $dest->{a} = $au;
2350         # Date::Parse isn't in the standard Perl distro :(
2351         if ($tz =~ s/^\+//) {
2352                 $t += ::tz_to_s_offset($tz);
2353         } elsif ($tz =~ s/^\-//) {
2354                 $t -= ::tz_to_s_offset($tz);
2355         }
2356         $dest->{t_utc} = $t;
2357 }
2358
2359 sub process_commit {
2360         my ($c, $r_min, $r_max, $defer) = @_;
2361         if (defined $r_min && defined $r_max) {
2362                 if ($r_min == $c->{r} && $r_min == $r_max) {
2363                         show_commit($c);
2364                         return 0;
2365                 }
2366                 return 1 if $r_min == $r_max;
2367                 if ($r_min < $r_max) {
2368                         # we need to reverse the print order
2369                         return 0 if (defined $limit && --$limit < 0);
2370                         push @$defer, $c;
2371                         return 1;
2372                 }
2373                 if ($r_min != $r_max) {
2374                         return 1 if ($r_min < $c->{r});
2375                         return 1 if ($r_max > $c->{r});
2376                 }
2377         }
2378         return 0 if (defined $limit && --$limit < 0);
2379         show_commit($c);
2380         return 1;
2381 }
2382
2383 sub show_commit {
2384         my $c = shift;
2385         if ($oneline) {
2386                 my $x = "\n";
2387                 if (my $l = $c->{l}) {
2388                         while ($l->[0] =~ /^\s*$/) { shift @$l }
2389                         $x = $l->[0];
2390                 }
2391                 $l_fmt ||= 'A' . length($c->{r});
2392                 print 'r',pack($l_fmt, $c->{r}),' | ';
2393                 print "$c->{c} | " if $show_commit;
2394                 print $x;
2395         } else {
2396                 show_commit_normal($c);
2397         }
2398 }
2399
2400 sub show_commit_changed_paths {
2401         my ($c) = @_;
2402         return unless $c->{changed};
2403         print "Changed paths:\n", @{$c->{changed}};
2404 }
2405
2406 sub show_commit_normal {
2407         my ($c) = @_;
2408         print '-' x72, "\nr$c->{r} | ";
2409         print "$c->{c} | " if $show_commit;
2410         print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
2411                                  localtime($c->{t_utc})), ' | ';
2412         my $nr_line = 0;
2413
2414         if (my $l = $c->{l}) {
2415                 while ($l->[$#$l] eq "\n" && $#$l > 0
2416                                           && $l->[($#$l - 1)] eq "\n") {
2417                         pop @$l;
2418                 }
2419                 $nr_line = scalar @$l;
2420                 if (!$nr_line) {
2421                         print "1 line\n\n\n";
2422                 } else {
2423                         if ($nr_line == 1) {
2424                                 $nr_line = '1 line';
2425                         } else {
2426                                 $nr_line .= ' lines';
2427                         }
2428                         print $nr_line, "\n";
2429                         show_commit_changed_paths($c);
2430                         print "\n";
2431                         print $_ foreach @$l;
2432                 }
2433         } else {
2434                 print "1 line\n";
2435                 show_commit_changed_paths($c);
2436                 print "\n";
2437
2438         }
2439         foreach my $x (qw/raw diff/) {
2440                 if ($c->{$x}) {
2441                         print "\n";
2442                         print $_ foreach @{$c->{$x}}
2443                 }
2444         }
2445 }
2446
2447 sub cmd_show_log {
2448         my (@args) = @_;
2449         my ($r_min, $r_max);
2450         my $r_last = -1; # prevent dupes
2451         if (defined $TZ) {
2452                 $ENV{TZ} = $TZ;
2453         } else {
2454                 delete $ENV{TZ};
2455         }
2456         if (defined $::_revision) {
2457                 if ($::_revision =~ /^(\d+):(\d+)$/) {
2458                         ($r_min, $r_max) = ($1, $2);
2459                 } elsif ($::_revision =~ /^\d+$/) {
2460                         $r_min = $r_max = $::_revision;
2461                 } else {
2462                         ::fatal "-r$::_revision is not supported, use ",
2463                                 "standard \'git log\' arguments instead\n";
2464                 }
2465         }
2466
2467         config_pager();
2468         @args = (git_svn_log_cmd($r_min, $r_max), @args);
2469         my $log = command_output_pipe(@args);
2470         run_pager();
2471         my (@k, $c, $d);
2472         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
2473         while (<$log>) {
2474                 if (/^${esc_color}commit ($::sha1_short)/o) {
2475                         my $cmt = $1;
2476                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
2477                                 $r_last = $c->{r};
2478                                 process_commit($c, $r_min, $r_max, \@k) or
2479                                                                 goto out;
2480                         }
2481                         $d = undef;
2482                         $c = { c => $cmt };
2483                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
2484                         get_author_info($c, $1, $2, $3);
2485                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
2486                         # ignore
2487                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
2488                         push @{$c->{raw}}, $_;
2489                 } elsif (/^${esc_color}[ACRMDT]\t/) {
2490                         # we could add $SVN->{svn_path} here, but that requires
2491                         # remote access at the moment (repo_path_split)...
2492                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
2493                         push @{$c->{changed}}, $_;
2494                 } elsif (/^${esc_color}diff /o) {
2495                         $d = 1;
2496                         push @{$c->{diff}}, $_;
2497                 } elsif ($d) {
2498                         push @{$c->{diff}}, $_;
2499                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
2500                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
2501                 } elsif (s/^${esc_color}    //o) {
2502                         push @{$c->{l}}, $_;
2503                 }
2504         }
2505         if ($c && defined $c->{r} && $c->{r} != $r_last) {
2506                 $r_last = $c->{r};
2507                 process_commit($c, $r_min, $r_max, \@k);
2508         }
2509         if (@k) {
2510                 my $swap = $r_max;
2511                 $r_max = $r_min;
2512                 $r_min = $swap;
2513                 process_commit($_, $r_min, $r_max) foreach reverse @k;
2514         }
2515 out:
2516         close $log;
2517         print '-' x72,"\n" unless $incremental || $oneline;
2518 }
2519
2520 package Git::SVN::Migration;
2521 # these version numbers do NOT correspond to actual version numbers
2522 # of git nor git-svn.  They are just relative.
2523 #
2524 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
2525 #
2526 # v1 layout: .git/$id/info/url, refs/remotes/$id
2527 #
2528 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
2529 #
2530 # v3 layout: .git/svn/$id, refs/remotes/$id
2531 #            - info/url may remain for backwards compatibility
2532 #            - this is what we migrate up to this layout automatically,
2533 #            - this will be used by git svn init on single branches
2534 #
2535 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
2536 #            - this is only created for newly multi-init-ed
2537 #              repositories.  Similar in spirit to the
2538 #              --use-separate-remotes option in git-clone (now default)
2539 #            - we do not automatically migrate to this (following
2540 #              the example set by core git)
2541 use strict;
2542 use warnings;
2543 use Carp qw/croak/;
2544 use File::Path qw/mkpath/;
2545 use File::Basename qw/dirname basename/;
2546 use vars qw/$_minimize/;
2547
2548 sub migrate_from_v0 {
2549         my $git_dir = $ENV{GIT_DIR};
2550         return undef unless -d $git_dir;
2551         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2552         my $migrated = 0;
2553         while (<$fh>) {
2554                 chomp;
2555                 my ($id, $orig_ref) = ($_, $_);
2556                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
2557                 next unless -f "$git_dir/$id/info/url";
2558                 my $new_ref = "refs/remotes/$id";
2559                 if (::verify_ref("$new_ref^0")) {
2560                         print STDERR "W: $orig_ref is probably an old ",
2561                                      "branch used by an ancient version of ",
2562                                      "git-svn.\n",
2563                                      "However, $new_ref also exists.\n",
2564                                      "We will not be able ",
2565                                      "to use this branch until this ",
2566                                      "ambiguity is resolved.\n";
2567                         next;
2568                 }
2569                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
2570                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
2571                 command_noisy('update-ref', $new_ref, $orig_ref);
2572                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
2573                 $migrated++;
2574         }
2575         command_close_pipe($fh, $ctx);
2576         print STDERR "Done migrating from v0 layout...\n" if $migrated;
2577         $migrated;
2578 }
2579
2580 sub migrate_from_v1 {
2581         my $git_dir = $ENV{GIT_DIR};
2582         my $migrated = 0;
2583         return $migrated unless -d $git_dir;
2584         my $svn_dir = "$git_dir/svn";
2585
2586         # just in case somebody used 'svn' as their $id at some point...
2587         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
2588
2589         print STDERR "Migrating from a git-svn v1 layout...\n";
2590         mkpath([$svn_dir]);
2591         print STDERR "Data from a previous version of git-svn exists, but\n\t",
2592                      "$svn_dir\n\t(required for this version ",
2593                      "($::VERSION) of git-svn) does not. exist\n";
2594         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2595         while (<$fh>) {
2596                 my $x = $_;
2597                 next unless $x =~ s#^refs/remotes/##;
2598                 chomp $x;
2599                 next unless -f "$git_dir/$x/info/url";
2600                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
2601                 next unless $u;
2602                 my $dn = dirname("$git_dir/svn/$x");
2603                 mkpath([$dn]) unless -d $dn;
2604                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
2605                         mkpath(["$git_dir/svn/svn"]);
2606                         print STDERR " - $git_dir/$x/info => ",
2607                                         "$git_dir/svn/$x/info\n";
2608                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
2609                                croak "$!: $x";
2610                         # don't worry too much about these, they probably
2611                         # don't exist with repos this old (save for index,
2612                         # and we can easily regenerate that)
2613                         foreach my $f (qw/unhandled.log index .rev_db/) {
2614                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
2615                         }
2616                 } else {
2617                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
2618                         rename "$git_dir/$x", "$git_dir/svn/$x" or
2619                                croak "$!: $x";
2620                 }
2621                 $migrated++;
2622         }
2623         command_close_pipe($fh, $ctx);
2624         print STDERR "Done migrating from a git-svn v1 layout\n";
2625         $migrated;
2626 }
2627
2628 sub read_old_urls {
2629         my ($l_map, $pfx, $path) = @_;
2630         my @dir;
2631         foreach (<$path/*>) {
2632                 if (-r "$_/info/url") {
2633                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
2634                         my $ref_id = $pfx . basename $_;
2635                         my $url = ::file_to_s("$_/info/url");
2636                         $l_map->{$ref_id} = $url;
2637                 } elsif (-d $_) {
2638                         push @dir, $_;
2639                 }
2640         }
2641         foreach (@dir) {
2642                 my $x = $_;
2643                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
2644                 read_old_urls($l_map, $x, $_);
2645         }
2646 }
2647
2648 sub migrate_from_v2 {
2649         my @cfg = command(qw/config -l/);
2650         return if grep /^svn-remote\..+\.url=/, @cfg;
2651         my %l_map;
2652         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
2653         my $migrated = 0;
2654
2655         foreach my $ref_id (sort keys %l_map) {
2656                 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
2657                 $migrated++;
2658         }
2659         $migrated;
2660 }
2661
2662 sub minimize_connections {
2663         my $r = Git::SVN::read_all_remotes();
2664         my $new_urls = {};
2665         my $root_repos = {};
2666         foreach my $repo_id (keys %$r) {
2667                 my $url = $r->{$repo_id}->{url} or next;
2668                 my $fetch = $r->{$repo_id}->{fetch} or next;
2669                 my $ra = Git::SVN::Ra->new($url);
2670
2671                 # skip existing cases where we already connect to the root
2672                 if (($ra->{url} eq $ra->{repos_root}) ||
2673                     (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
2674                      $repo_id)) {
2675                         $root_repos->{$ra->{url}} = $repo_id;
2676                         next;
2677                 }
2678
2679                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
2680                 my $root_path = $ra->{url};
2681                 $root_path =~ s#^\Q$ra->{repos_root}\E/*##;
2682                 foreach my $path (keys %$fetch) {
2683                         my $ref_id = $fetch->{$path};
2684                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
2685
2686                         # make sure we can read when connecting to
2687                         # a higher level of a repository
2688                         my ($last_rev, undef) = $gs->last_rev_commit;
2689                         if (!defined $last_rev) {
2690                                 $last_rev = eval {
2691                                         $root_ra->get_latest_revnum;
2692                                 };
2693                                 next if $@;
2694                         }
2695                         my $new = $root_path;
2696                         $new .= length $path ? "/$path" : '';
2697                         eval {
2698                                 $root_ra->get_log([$new], $last_rev, $last_rev,
2699                                                   0, 0, 1, sub { });
2700                         };
2701                         next if $@;
2702                         $new_urls->{$ra->{repos_root}}->{$new} =
2703                                 { ref_id => $ref_id,
2704                                   old_repo_id => $repo_id,
2705                                   old_path => $path };
2706                 }
2707         }
2708
2709         my @emptied;
2710         foreach my $url (keys %$new_urls) {
2711                 # see if we can re-use an existing [svn-remote "repo_id"]
2712                 # instead of creating a(n ugly) new section:
2713                 my $repo_id = $root_repos->{$url} ||
2714                               Git::SVN::sanitize_remote_name($url);
2715
2716                 my $fetch = $new_urls->{$url};
2717                 foreach my $path (keys %$fetch) {
2718                         my $x = $fetch->{$path};
2719                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
2720                         my $pfx = "svn-remote.$x->{old_repo_id}";
2721
2722                         my $old_fetch = quotemeta("$x->{old_path}:".
2723                                                   "refs/remotes/$x->{ref_id}");
2724                         command_noisy(qw/config --unset/,
2725                                       "$pfx.fetch", '^'. $old_fetch . '$');
2726                         delete $r->{$x->{old_repo_id}}->
2727                                {fetch}->{$x->{old_path}};
2728                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
2729                                 command_noisy(qw/config --unset/,
2730                                               "$pfx.url");
2731                                 push @emptied, $x->{old_repo_id}
2732                         }
2733                 }
2734         }
2735         if (@emptied) {
2736                 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
2737                            "$ENV{GIT_DIR}/config";
2738                 print STDERR <<EOF;
2739 The following [svn-remote] sections in your config file ($file) are empty
2740 and can be safely removed:
2741 EOF
2742                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
2743         }
2744 }
2745
2746 sub migration_check {
2747         migrate_from_v0();
2748         migrate_from_v1();
2749         migrate_from_v2();
2750         minimize_connections() if $_minimize;
2751 }
2752
2753 __END__
2754
2755 Data structures:
2756
2757 $log_entry hashref as returned by libsvn_log_entry()
2758 {
2759         log => 'whitespace-formatted log entry
2760 ',                                              # trailing newline is preserved
2761         revision => '8',                        # integer
2762         date => '2004-02-24T17:01:44.108345Z',  # commit date
2763         author => 'committer name'
2764 };
2765
2766 @mods = array of diff-index line hashes, each element represents one line
2767         of diff-index output
2768
2769 diff-index line ($m hash)
2770 {
2771         mode_a => first column of diff-index output, no leading ':',
2772         mode_b => second column of diff-index output,
2773         sha1_b => sha1sum of the final blob,
2774         chg => change type [MCRADT],
2775         file_a => original file name of a file (iff chg is 'C' or 'R')
2776         file_b => new/current file name of a file (any chg)
2777 }
2778 ;
2779
2780 # retval of read_url_paths{,_all}();
2781 $l_map = {
2782         # repository root url
2783         'https://svn.musicpd.org' => {
2784                 # repository path               # GIT_SVN_ID
2785                 'mpd/trunk'             =>      'trunk',
2786                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2787         },
2788 }
2789
2790 Notes:
2791         I don't trust the each() function on unless I created %hash myself
2792         because the internal iterator may not have started at base.