git.oblomov.eu Git - git/blob - contrib/mw-to-git/git-remote-mediawiki.perl

   1 #! /usr/bin/perl
   2
   3 # Copyright (C) 2011
   4 #     Jérémie Nikaes <jeremie.nikaes@ensimag.imag.fr>
   5 #     Arnaud Lacurie <arnaud.lacurie@ensimag.imag.fr>
   6 #     Claire Fousse <claire.fousse@ensimag.imag.fr>
   7 #     David Amouyal <david.amouyal@ensimag.imag.fr>
   8 #     Matthieu Moy <matthieu.moy@grenoble-inp.fr>
   9 # License: GPL v2 or later
  10
  11 # Gateway between Git and MediaWiki.
  12 # Documentation & bugtracker: https://github.com/moy/Git-Mediawiki/
  13
  14 use strict;
  15 use MediaWiki::API;
  16 use Git;
  17 use Git::Mediawiki qw(clean_filename smudge_filename connect_maybe
  18                                         EMPTY HTTP_CODE_OK);
  19 use DateTime::Format::ISO8601;
  20 use warnings;
  21
  22 # By default, use UTF-8 to communicate with Git and the user
  23 binmode STDERR, ':encoding(UTF-8)';
  24 binmode STDOUT, ':encoding(UTF-8)';
  25
  26 use URI::Escape;
  27
  28 # It's not always possible to delete pages (may require some
  29 # privileges). Deleted pages are replaced with this content.
  30 use constant DELETED_CONTENT => "[[Category:Deleted]]\n";
  31
  32 # It's not possible to create empty pages. New empty files in Git are
  33 # sent with this content instead.
  34 use constant EMPTY_CONTENT => "<!-- empty page -->\n";
  35
  36 # used to reflect file creation or deletion in diff.
  37 use constant NULL_SHA1 => '0000000000000000000000000000000000000000';
  38
  39 # Used on Git's side to reflect empty edit messages on the wiki
  40 use constant EMPTY_MESSAGE => '*Empty MediaWiki Message*';
  41
  42 # Number of pages taken into account at once in submodule get_mw_page_list
  43 use constant SLICE_SIZE => 50;
  44
  45 # Number of linked mediafile to get at once in get_linked_mediafiles
  46 # The query is split in small batches because of the MW API limit of
  47 # the number of links to be returned (500 links max).
  48 use constant BATCH_SIZE => 10;
  49
  50 if (@ARGV != 2) {
  51         exit_error_usage();
  52 }
  53
  54 my $remotename = $ARGV[0];
  55 my $url = $ARGV[1];
  56
  57 # Accept both space-separated and multiple keys in config file.
  58 # Spaces should be written as _ anyway because we'll use chomp.
  59 my @tracked_pages = split(/[ \n]/, run_git("config --get-all remote.${remotename}.pages"));
  60 chomp(@tracked_pages);
  61
  62 # Just like @tracked_pages, but for MediaWiki categories.
  63 my @tracked_categories = split(/[ \n]/, run_git("config --get-all remote.${remotename}.categories"));
  64 chomp(@tracked_categories);
  65
  66 # Just like @tracked_categories, but for MediaWiki namespaces.
  67 my @tracked_namespaces = split(/[ \n]/, run_git("config --get-all remote.${remotename}.namespaces"));
  68 for (@tracked_namespaces) { s/_/ /g; }
  69 chomp(@tracked_namespaces);
  70
  71 # Import media files on pull
  72 my $import_media = run_git("config --get --bool remote.${remotename}.mediaimport");
  73 chomp($import_media);
  74 $import_media = ($import_media eq 'true');
  75
  76 # Export media files on push
  77 my $export_media = run_git("config --get --bool remote.${remotename}.mediaexport");
  78 chomp($export_media);
  79 $export_media = !($export_media eq 'false');
  80
  81 my $wiki_login = run_git("config --get remote.${remotename}.mwLogin");
  82 # Note: mwPassword is discourraged. Use the credential system instead.
  83 my $wiki_passwd = run_git("config --get remote.${remotename}.mwPassword");
  84 my $wiki_domain = run_git("config --get remote.${remotename}.mwDomain");
  85 chomp($wiki_login);
  86 chomp($wiki_passwd);
  87 chomp($wiki_domain);
  88
  89 # Import only last revisions (both for clone and fetch)
  90 my $shallow_import = run_git("config --get --bool remote.${remotename}.shallow");
  91 chomp($shallow_import);
  92 $shallow_import = ($shallow_import eq 'true');
  93
  94 # Fetch (clone and pull) by revisions instead of by pages. This behavior
  95 # is more efficient when we have a wiki with lots of pages and we fetch
  96 # the revisions quite often so that they concern only few pages.
  97 # Possible values:
  98 # - by_rev: perform one query per new revision on the remote wiki
  99 # - by_page: query each tracked page for new revision
 100 my $fetch_strategy = run_git("config --get remote.${remotename}.fetchStrategy");
 101 if (!$fetch_strategy) {
 102         $fetch_strategy = run_git('config --get mediawiki.fetchStrategy');
 103 }
 104 chomp($fetch_strategy);
 105 if (!$fetch_strategy) {
 106         $fetch_strategy = 'by_page';
 107 }
 108
 109 # Remember the timestamp corresponding to a revision id.
 110 my %basetimestamps;
 111
 112 # Dumb push: don't update notes and mediawiki ref to reflect the last push.
 113 #
 114 # Configurable with mediawiki.dumbPush, or per-remote with
 115 # remote.<remotename>.dumbPush.
 116 #
 117 # This means the user will have to re-import the just-pushed
 118 # revisions. On the other hand, this means that the Git revisions
 119 # corresponding to MediaWiki revisions are all imported from the wiki,
 120 # regardless of whether they were initially created in Git or from the
 121 # web interface, hence all users will get the same history (i.e. if
 122 # the push from Git to MediaWiki loses some information, everybody
 123 # will get the history with information lost). If the import is
 124 # deterministic, this means everybody gets the same sha1 for each
 125 # MediaWiki revision.
 126 my $dumb_push = run_git("config --get --bool remote.${remotename}.dumbPush");
 127 if (!$dumb_push) {
 128         $dumb_push = run_git('config --get --bool mediawiki.dumbPush');
 129 }
 130 chomp($dumb_push);
 131 $dumb_push = ($dumb_push eq 'true');
 132
 133 my $wiki_name = $url;
 134 $wiki_name =~ s{[^/]*://}{};
 135 # If URL is like http://user:password@example.com/, we clearly don't
 136 # want the password in $wiki_name. While we're there, also remove user
 137 # and '@' sign, to avoid author like MWUser@HTTPUser@host.com
 138 $wiki_name =~ s/^.*@//;
 139
 140 # Commands parser
 141 while (<STDIN>) {
 142         chomp;
 143
 144         if (!parse_command($_)) {
 145                 last;
 146         }
 147
 148         BEGIN { $| = 1 } # flush STDOUT, to make sure the previous
 149                          # command is fully processed.
 150 }
 151
 152 ########################## Functions ##############################
 153
 154 ## error handling
 155 sub exit_error_usage {
 156         die "ERROR: git-remote-mediawiki module was not called with a correct number of\n" .
 157             "parameters\n" .
 158             "You may obtain this error because you attempted to run the git-remote-mediawiki\n" .
 159             "module directly.\n" .
 160             "This module can be used the following way:\n" .
 161             "\tgit clone mediawiki://<address of a mediawiki>\n" .
 162             "Then, use git commit, push and pull as with every normal git repository.\n";
 163 }
 164
 165 sub parse_command {
 166         my ($line) = @_;
 167         my @cmd = split(/ /, $line);
 168         if (!defined $cmd[0]) {
 169                 return 0;
 170         }
 171         if ($cmd[0] eq 'capabilities') {
 172                 die("Too many arguments for capabilities\n")
 173                     if (defined($cmd[1]));
 174                 mw_capabilities();
 175         } elsif ($cmd[0] eq 'list') {
 176                 die("Too many arguments for list\n") if (defined($cmd[2]));
 177                 mw_list($cmd[1]);
 178         } elsif ($cmd[0] eq 'import') {
 179                 die("Invalid argument for import\n")
 180                     if ($cmd[1] eq EMPTY);
 181                 die("Too many arguments for import\n")
 182                     if (defined($cmd[2]));
 183                 mw_import($cmd[1]);
 184         } elsif ($cmd[0] eq 'option') {
 185                 die("Invalid arguments for option\n")
 186                     if ($cmd[1] eq EMPTY || $cmd[2] eq EMPTY);
 187                 die("Too many arguments for option\n")
 188                     if (defined($cmd[3]));
 189                 mw_option($cmd[1],$cmd[2]);
 190         } elsif ($cmd[0] eq 'push') {
 191                 mw_push($cmd[1]);
 192         } else {
 193                 print {*STDERR} "Unknown command. Aborting...\n";
 194                 return 0;
 195         }
 196         return 1;
 197 }
 198
 199 # MediaWiki API instance, created lazily.
 200 my $mediawiki;
 201
 202 sub fatal_mw_error {
 203         my $action = shift;
 204         print STDERR "fatal: could not $action.\n";
 205         print STDERR "fatal: '$url' does not appear to be a mediawiki\n";
 206         if ($url =~ /^https/) {
 207                 print STDERR "fatal: make sure '$url/api.php' is a valid page\n";
 208                 print STDERR "fatal: and the SSL certificate is correct.\n";
 209         } else {
 210                 print STDERR "fatal: make sure '$url/api.php' is a valid page.\n";
 211         }
 212         print STDERR "fatal: (error " .
 213             $mediawiki->{error}->{code} . ': ' .
 214             $mediawiki->{error}->{details} . ")\n";
 215         exit 1;
 216 }
 217
 218 ## Functions for listing pages on the remote wiki
 219 sub get_mw_tracked_pages {
 220         my $pages = shift;
 221         get_mw_page_list(\@tracked_pages, $pages);
 222         return;
 223 }
 224
 225 sub get_mw_page_list {
 226         my $page_list = shift;
 227         my $pages = shift;
 228         my @some_pages = @{$page_list};
 229         while (@some_pages) {
 230                 my $last_page = SLICE_SIZE;
 231                 if ($#some_pages < $last_page) {
 232                         $last_page = $#some_pages;
 233                 }
 234                 my @slice = @some_pages[0..$last_page];
 235                 get_mw_first_pages(\@slice, $pages);
 236                 @some_pages = @some_pages[(SLICE_SIZE + 1)..$#some_pages];
 237         }
 238         return;
 239 }
 240
 241 sub get_mw_tracked_categories {
 242         my $pages = shift;
 243         foreach my $category (@tracked_categories) {
 244                 if (index($category, ':') < 0) {
 245                         # Mediawiki requires the Category
 246                         # prefix, but let's not force the user
 247                         # to specify it.
 248                         $category = "Category:${category}";
 249                 }
 250                 my $mw_pages = $mediawiki->list( {
 251                         action => 'query',
 252                         list => 'categorymembers',
 253                         cmtitle => $category,
 254                         cmlimit => 'max' } )
 255                         || die $mediawiki->{error}->{code} . ': '
 256                                 . $mediawiki->{error}->{details} . "\n";
 257                 foreach my $page (@{$mw_pages}) {
 258                         $pages->{$page->{title}} = $page;
 259                 }
 260         }
 261         return;
 262 }
 263
 264 sub get_mw_tracked_namespaces {
 265     my $pages = shift;
 266     foreach my $local_namespace (sort @tracked_namespaces) {
 267         my $namespace_id;
 268         if ($local_namespace eq "(Main)") {
 269             $namespace_id = 0;
 270         } else {
 271             $namespace_id = get_mw_namespace_id($local_namespace);
 272         }
 273         # virtual namespaces don't support allpages
 274         next if !defined($namespace_id) || $namespace_id < 0;
 275         my $mw_pages = $mediawiki->list( {
 276             action => 'query',
 277             list => 'allpages',
 278             apnamespace => $namespace_id,
 279             aplimit => 'max' } )
 280             || die $mediawiki->{error}->{code} . ': '
 281                 . $mediawiki->{error}->{details} . "\n";
 282         foreach my $page (@{$mw_pages}) {
 283             $pages->{$page->{title}} = $page;
 284         }
 285     }
 286     return;
 287 }
 288
 289 sub get_mw_all_pages {
 290         my $pages = shift;
 291         # No user-provided list, get the list of pages from the API.
 292         my $mw_pages = $mediawiki->list({
 293                 action => 'query',
 294                 list => 'allpages',
 295                 aplimit => 'max'
 296         });
 297         if (!defined($mw_pages)) {
 298                 fatal_mw_error("get the list of wiki pages");
 299         }
 300         foreach my $page (@{$mw_pages}) {
 301                 $pages->{$page->{title}} = $page;
 302         }
 303         return;
 304 }
 305
 306 # queries the wiki for a set of pages. Meant to be used within a loop
 307 # querying the wiki for slices of page list.
 308 sub get_mw_first_pages {
 309         my $some_pages = shift;
 310         my @some_pages = @{$some_pages};
 311
 312         my $pages = shift;
 313
 314         # pattern 'page1|page2|...' required by the API
 315         my $titles = join('|', @some_pages);
 316
 317         my $mw_pages = $mediawiki->api({
 318                 action => 'query',
 319                 titles => $titles,
 320         });
 321         if (!defined($mw_pages)) {
 322                 fatal_mw_error("query the list of wiki pages");
 323         }
 324         while (my ($id, $page) = each(%{$mw_pages->{query}->{pages}})) {
 325                 if ($id < 0) {
 326                         print {*STDERR} "Warning: page $page->{title} not found on wiki\n";
 327                 } else {
 328                         $pages->{$page->{title}} = $page;
 329                 }
 330         }
 331         return;
 332 }
 333
 334 # Get the list of pages to be fetched according to configuration.
 335 sub get_mw_pages {
 336         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 337
 338         print {*STDERR} "Listing pages on remote wiki...\n";
 339
 340         my %pages; # hash on page titles to avoid duplicates
 341         my $user_defined;
 342         if (@tracked_pages) {
 343                 $user_defined = 1;
 344                 # The user provided a list of pages titles, but we
 345                 # still need to query the API to get the page IDs.
 346                 get_mw_tracked_pages(\%pages);
 347         }
 348         if (@tracked_categories) {
 349                 $user_defined = 1;
 350                 get_mw_tracked_categories(\%pages);
 351         }
 352         if (@tracked_namespaces) {
 353                 $user_defined = 1;
 354                 get_mw_tracked_namespaces(\%pages);
 355         }
 356         if (!$user_defined) {
 357                 get_mw_all_pages(\%pages);
 358         }
 359         if ($import_media) {
 360                 print {*STDERR} "Getting media files for selected pages...\n";
 361                 if ($user_defined) {
 362                         get_linked_mediafiles(\%pages);
 363                 } else {
 364                         get_all_mediafiles(\%pages);
 365                 }
 366         }
 367         print {*STDERR} (scalar keys %pages) . " pages found.\n";
 368         return %pages;
 369 }
 370
 371 # usage: $out = run_git("command args");
 372 #        $out = run_git("command args", "raw"); # don't interpret output as UTF-8.
 373 sub run_git {
 374         my $args = shift;
 375         my $encoding = (shift || 'encoding(UTF-8)');
 376         open(my $git, "-|:${encoding}", "git ${args}")
 377             or die "Unable to fork: $!\n";
 378         my $res = do {
 379                 local $/ = undef;
 380                 <$git>
 381         };
 382         close($git);
 383
 384         return $res;
 385 }
 386
 387
 388 sub get_all_mediafiles {
 389         my $pages = shift;
 390         # Attach list of all pages for media files from the API,
 391         # they are in a different namespace, only one namespace
 392         # can be queried at the same moment
 393         my $mw_pages = $mediawiki->list({
 394                 action => 'query',
 395                 list => 'allpages',
 396                 apnamespace => get_mw_namespace_id('File'),
 397                 aplimit => 'max'
 398         });
 399         if (!defined($mw_pages)) {
 400                 print {*STDERR} "fatal: could not get the list of pages for media files.\n";
 401                 print {*STDERR} "fatal: '$url' does not appear to be a mediawiki\n";
 402                 print {*STDERR} "fatal: make sure '$url/api.php' is a valid page.\n";
 403                 exit 1;
 404         }
 405         foreach my $page (@{$mw_pages}) {
 406                 $pages->{$page->{title}} = $page;
 407         }
 408         return;
 409 }
 410
 411 sub get_linked_mediafiles {
 412         my $pages = shift;
 413         my @titles = map { $_->{title} } values(%{$pages});
 414
 415         my $batch = BATCH_SIZE;
 416         while (@titles) {
 417                 if ($#titles < $batch) {
 418                         $batch = $#titles;
 419                 }
 420                 my @slice = @titles[0..$batch];
 421
 422                 # pattern 'page1|page2|...' required by the API
 423                 my $mw_titles = join('|', @slice);
 424
 425                 # Media files could be included or linked from
 426                 # a page, get all related
 427                 my $query = {
 428                         action => 'query',
 429                         prop => 'links|images',
 430                         titles => $mw_titles,
 431                         plnamespace => get_mw_namespace_id('File'),
 432                         pllimit => 'max'
 433                 };
 434                 my $result = $mediawiki->api($query);
 435
 436                 while (my ($id, $page) = each(%{$result->{query}->{pages}})) {
 437                         my @media_titles;
 438                         if (defined($page->{links})) {
 439                                 my @link_titles
 440                                     = map { $_->{title} } @{$page->{links}};
 441                                 push(@media_titles, @link_titles);
 442                         }
 443                         if (defined($page->{images})) {
 444                                 my @image_titles
 445                                     = map { $_->{title} } @{$page->{images}};
 446                                 push(@media_titles, @image_titles);
 447                         }
 448                         if (@media_titles) {
 449                                 get_mw_page_list(\@media_titles, $pages);
 450                         }
 451                 }
 452
 453                 @titles = @titles[($batch+1)..$#titles];
 454         }
 455         return;
 456 }
 457
 458 sub get_mw_mediafile_for_page_revision {
 459         # Name of the file on Wiki, with the prefix.
 460         my $filename = shift;
 461         my $timestamp = shift;
 462         my %mediafile;
 463
 464         # Search if on a media file with given timestamp exists on
 465         # MediaWiki. In that case download the file.
 466         my $query = {
 467                 action => 'query',
 468                 prop => 'imageinfo',
 469                 titles => "File:${filename}",
 470                 iistart => $timestamp,
 471                 iiend => $timestamp,
 472                 iiprop => 'timestamp|archivename|url',
 473                 iilimit => 1
 474         };
 475         my $result = $mediawiki->api($query);
 476
 477         my ($fileid, $file) = each( %{$result->{query}->{pages}} );
 478         # If not defined it means there is no revision of the file for
 479         # given timestamp.
 480         if (defined($file->{imageinfo})) {
 481                 $mediafile{title} = $filename;
 482
 483                 my $fileinfo = pop(@{$file->{imageinfo}});
 484                 $mediafile{timestamp} = $fileinfo->{timestamp};
 485                 # Mediawiki::API's download function doesn't support https URLs
 486                 # and can't download old versions of files.
 487                 print {*STDERR} "\tDownloading file $mediafile{title}, version $mediafile{timestamp}\n";
 488                 $mediafile{content} = download_mw_mediafile($fileinfo->{url});
 489         }
 490         return %mediafile;
 491 }
 492
 493 sub download_mw_mediafile {
 494         my $download_url = shift;
 495
 496         my $response = $mediawiki->{ua}->get($download_url);
 497         if ($response->code == HTTP_CODE_OK) {
 498                 # It is tempting to return
 499                 # $response->decoded_content({charset => "none"}), but
 500                 # when doing so, utf8::downgrade($content) fails with
 501                 # "Wide character in subroutine entry".
 502                 $response->decode();
 503                 return $response->content();
 504         } else {
 505                 print {*STDERR} "Error downloading mediafile from :\n";
 506                 print {*STDERR} "URL: ${download_url}\n";
 507                 print {*STDERR} 'Server response: ' . $response->code . q{ } . $response->message . "\n";
 508                 exit 1;
 509         }
 510 }
 511
 512 sub get_last_local_revision {
 513         # Get note regarding last mediawiki revision
 514         my $note = run_git("notes --ref=${remotename}/mediawiki show refs/mediawiki/${remotename}/master 2>/dev/null");
 515         my @note_info = split(/ /, $note);
 516
 517         my $lastrevision_number;
 518         if (!(defined($note_info[0]) && $note_info[0] eq 'mediawiki_revision:')) {
 519                 print {*STDERR} 'No previous mediawiki revision found';
 520                 $lastrevision_number = 0;
 521         } else {
 522                 # Notes are formatted : mediawiki_revision: #number
 523                 $lastrevision_number = $note_info[1];
 524                 chomp($lastrevision_number);
 525                 print {*STDERR} "Last local mediawiki revision found is ${lastrevision_number}";
 526         }
 527         return $lastrevision_number;
 528 }
 529
 530 # Get the last remote revision without taking in account which pages are
 531 # tracked or not. This function makes a single request to the wiki thus
 532 # avoid a loop onto all tracked pages. This is useful for the fetch-by-rev
 533 # option.
 534 sub get_last_global_remote_rev {
 535         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 536
 537         my $query = {
 538                 action => 'query',
 539                 list => 'recentchanges',
 540                 prop => 'revisions',
 541                 rclimit => '1',
 542                 rcdir => 'older',
 543         };
 544         my $result = $mediawiki->api($query);
 545         return $result->{query}->{recentchanges}[0]->{revid};
 546 }
 547
 548 # Get the last remote revision concerning the tracked pages and the tracked
 549 # categories.
 550 sub get_last_remote_revision {
 551         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 552
 553         my %pages_hash = get_mw_pages();
 554         my @pages = values(%pages_hash);
 555
 556         my $max_rev_num = 0;
 557
 558         print {*STDERR} "Getting last revision id on tracked pages...\n";
 559
 560         foreach my $page (@pages) {
 561                 my $id = $page->{pageid};
 562
 563                 my $query = {
 564                         action => 'query',
 565                         prop => 'revisions',
 566                         rvprop => 'ids|timestamp',
 567                         pageids => $id,
 568                 };
 569
 570                 my $result = $mediawiki->api($query);
 571
 572                 my $lastrev = pop(@{$result->{query}->{pages}->{$id}->{revisions}});
 573
 574                 $basetimestamps{$lastrev->{revid}} = $lastrev->{timestamp};
 575
 576                 $max_rev_num = ($lastrev->{revid} > $max_rev_num ? $lastrev->{revid} : $max_rev_num);
 577         }
 578
 579         print {*STDERR} "Last remote revision found is $max_rev_num.\n";
 580         return $max_rev_num;
 581 }
 582
 583 # Clean content before sending it to MediaWiki
 584 sub mediawiki_clean {
 585         my $string = shift;
 586         my $page_created = shift;
 587         # Mediawiki does not allow blank space at the end of a page and ends with a single \n.
 588         # This function right trims a string and adds a \n at the end to follow this rule
 589         $string =~ s/\s+$//;
 590         if ($string eq EMPTY && $page_created) {
 591                 # Creating empty pages is forbidden.
 592                 $string = EMPTY_CONTENT;
 593         }
 594         return $string."\n";
 595 }
 596
 597 # Filter applied on MediaWiki data before adding them to Git
 598 sub mediawiki_smudge {
 599         my $string = shift;
 600         if ($string eq EMPTY_CONTENT) {
 601                 $string = EMPTY;
 602         }
 603         # This \n is important. This is due to mediawiki's way to handle end of files.
 604         return "${string}\n";
 605 }
 606
 607 sub literal_data {
 608         my ($content) = @_;
 609         print {*STDOUT} 'data ', bytes::length($content), "\n", $content;
 610         return;
 611 }
 612
 613 sub literal_data_raw {
 614         # Output possibly binary content.
 615         my ($content) = @_;
 616         # Avoid confusion between size in bytes and in characters
 617         utf8::downgrade($content);
 618         binmode STDOUT, ':raw';
 619         print {*STDOUT} 'data ', bytes::length($content), "\n", $content;
 620         binmode STDOUT, ':encoding(UTF-8)';
 621         return;
 622 }
 623
 624 sub mw_capabilities {
 625         # Revisions are imported to the private namespace
 626         # refs/mediawiki/$remotename/ by the helper and fetched into
 627         # refs/remotes/$remotename later by fetch.
 628         print {*STDOUT} "refspec refs/heads/*:refs/mediawiki/${remotename}/*\n";
 629         print {*STDOUT} "import\n";
 630         print {*STDOUT} "list\n";
 631         print {*STDOUT} "push\n";
 632         if ($dumb_push) {
 633                 print {*STDOUT} "no-private-update\n";
 634         }
 635         print {*STDOUT} "\n";
 636         return;
 637 }
 638
 639 sub mw_list {
 640         # MediaWiki do not have branches, we consider one branch arbitrarily
 641         # called master, and HEAD pointing to it.
 642         print {*STDOUT} "? refs/heads/master\n";
 643         print {*STDOUT} "\@refs/heads/master HEAD\n";
 644         print {*STDOUT} "\n";
 645         return;
 646 }
 647
 648 sub mw_option {
 649         print {*STDERR} "remote-helper command 'option $_[0]' not yet implemented\n";
 650         print {*STDOUT} "unsupported\n";
 651         return;
 652 }
 653
 654 sub fetch_mw_revisions_for_page {
 655         my $page = shift;
 656         my $id = shift;
 657         my $fetch_from = shift;
 658         my @page_revs = ();
 659         my $query = {
 660                 action => 'query',
 661                 prop => 'revisions',
 662                 rvprop => 'ids',
 663                 rvdir => 'newer',
 664                 rvstartid => $fetch_from,
 665                 rvlimit => 500,
 666                 pageids => $id,
 667
 668                 # Let MediaWiki know that we support the latest API.
 669                 continue => '',
 670         };
 671
 672         my $revnum = 0;
 673         # Get 500 revisions at a time due to the mediawiki api limit
 674         while (1) {
 675                 my $result = $mediawiki->api($query);
 676
 677                 # Parse each of those 500 revisions
 678                 foreach my $revision (@{$result->{query}->{pages}->{$id}->{revisions}}) {
 679                         my $page_rev_ids;
 680                         $page_rev_ids->{pageid} = $page->{pageid};
 681                         $page_rev_ids->{revid} = $revision->{revid};
 682                         push(@page_revs, $page_rev_ids);
 683                         $revnum++;
 684                 }
 685
 686                 if ($result->{'query-continue'}) { # For legacy APIs
 687                         $query->{rvstartid} = $result->{'query-continue'}->{revisions}->{rvstartid};
 688                 } elsif ($result->{continue}) { # For newer APIs
 689                         $query->{rvstartid} = $result->{continue}->{rvcontinue};
 690                         $query->{continue} = $result->{continue}->{continue};
 691                 } else {
 692                         last;
 693                 }
 694         }
 695         if ($shallow_import && @page_revs) {
 696                 print {*STDERR} "  Found 1 revision (shallow import).\n";
 697                 @page_revs = sort {$b->{revid} <=> $a->{revid}} (@page_revs);
 698                 return $page_revs[0];
 699         }
 700         print {*STDERR} "  Found ${revnum} revision(s).\n";
 701         return @page_revs;
 702 }
 703
 704 sub fetch_mw_revisions {
 705         my $pages = shift; my @pages = @{$pages};
 706         my $fetch_from = shift;
 707
 708         my @revisions = ();
 709         my $n = 1;
 710         foreach my $page (@pages) {
 711                 my $id = $page->{pageid};
 712                 print {*STDERR} "page ${n}/", scalar(@pages), ': ', $page->{title}, "\n";
 713                 $n++;
 714                 my @page_revs = fetch_mw_revisions_for_page($page, $id, $fetch_from);
 715                 @revisions = (@page_revs, @revisions);
 716         }
 717
 718         return ($n, @revisions);
 719 }
 720
 721 sub fe_escape_path {
 722     my $path = shift;
 723     $path =~ s/\\/\\\\/g;
 724     $path =~ s/"/\\"/g;
 725     $path =~ s/\n/\\n/g;
 726     return qq("${path}");
 727 }
 728
 729 sub import_file_revision {
 730         my $commit = shift;
 731         my %commit = %{$commit};
 732         my $full_import = shift;
 733         my $n = shift;
 734         my $mediafile = shift;
 735         my %mediafile;
 736         if ($mediafile) {
 737                 %mediafile = %{$mediafile};
 738         }
 739
 740         my $title = $commit{title};
 741         my $comment = $commit{comment};
 742         my $content = $commit{content};
 743         my $author = $commit{author};
 744         my $date = $commit{date};
 745
 746         print {*STDOUT} "commit refs/mediawiki/${remotename}/master\n";
 747         print {*STDOUT} "mark :${n}\n";
 748         print {*STDOUT} "committer ${author} <${author}\@${wiki_name}> " . $date->epoch . " +0000\n";
 749         literal_data($comment);
 750
 751         # If it's not a clone, we need to know where to start from
 752         if (!$full_import && $n == 1) {
 753                 print {*STDOUT} "from refs/mediawiki/${remotename}/master^0\n";
 754         }
 755         if ($content ne DELETED_CONTENT) {
 756                 print {*STDOUT} 'M 644 inline ' .
 757                     fe_escape_path("${title}.mw") . "\n";
 758                 literal_data($content);
 759                 if (%mediafile) {
 760                         print {*STDOUT} 'M 644 inline '
 761                             . fe_escape_path($mediafile{title}) . "\n";
 762                         literal_data_raw($mediafile{content});
 763                 }
 764                 print {*STDOUT} "\n\n";
 765         } else {
 766                 print {*STDOUT} 'D ' . fe_escape_path("${title}.mw") . "\n";
 767         }
 768
 769         # mediawiki revision number in the git note
 770         if ($full_import && $n == 1) {
 771                 print {*STDOUT} "reset refs/notes/${remotename}/mediawiki\n";
 772         }
 773         print {*STDOUT} "commit refs/notes/${remotename}/mediawiki\n";
 774         print {*STDOUT} "committer ${author} <${author}\@${wiki_name}> " . $date->epoch . " +0000\n";
 775         literal_data('Note added by git-mediawiki during import');
 776         if (!$full_import && $n == 1) {
 777                 print {*STDOUT} "from refs/notes/${remotename}/mediawiki^0\n";
 778         }
 779         print {*STDOUT} "N inline :${n}\n";
 780         literal_data("mediawiki_revision: $commit{mw_revision}");
 781         print {*STDOUT} "\n\n";
 782         return;
 783 }
 784
 785 # parse a sequence of
 786 # <cmd> <arg1>
 787 # <cmd> <arg2>
 788 # \n
 789 # (like batch sequence of import and sequence of push statements)
 790 sub get_more_refs {
 791         my $cmd = shift;
 792         my @refs;
 793         while (1) {
 794                 my $line = <STDIN>;
 795                 if ($line =~ /^$cmd (.*)$/) {
 796                         push(@refs, $1);
 797                 } elsif ($line eq "\n") {
 798                         return @refs;
 799                 } else {
 800                         die("Invalid command in a '$cmd' batch: $_\n");
 801                 }
 802         }
 803         return;
 804 }
 805
 806 sub mw_import {
 807         # multiple import commands can follow each other.
 808         my @refs = (shift, get_more_refs('import'));
 809         foreach my $ref (@refs) {
 810                 mw_import_ref($ref);
 811         }
 812         print {*STDOUT} "done\n";
 813         return;
 814 }
 815
 816 sub mw_import_ref {
 817         my $ref = shift;
 818         # The remote helper will call "import HEAD" and
 819         # "import refs/heads/master".
 820         # Since HEAD is a symbolic ref to master (by convention,
 821         # followed by the output of the command "list" that we gave),
 822         # we don't need to do anything in this case.
 823         if ($ref eq 'HEAD') {
 824                 return;
 825         }
 826
 827         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 828
 829         print {*STDERR} "Searching revisions...\n";
 830         my $last_local = get_last_local_revision();
 831         my $fetch_from = $last_local + 1;
 832         if ($fetch_from == 1) {
 833                 print {*STDERR} ", fetching from beginning.\n";
 834         } else {
 835                 print {*STDERR} ", fetching from here.\n";
 836         }
 837
 838         my $n = 0;
 839         if ($fetch_strategy eq 'by_rev') {
 840                 print {*STDERR} "Fetching & writing export data by revs...\n";
 841                 $n = mw_import_ref_by_revs($fetch_from);
 842         } elsif ($fetch_strategy eq 'by_page') {
 843                 print {*STDERR} "Fetching & writing export data by pages...\n";
 844                 $n = mw_import_ref_by_pages($fetch_from);
 845         } else {
 846                 print {*STDERR} qq(fatal: invalid fetch strategy "${fetch_strategy}".\n);
 847                 print {*STDERR} "Check your configuration variables remote.${remotename}.fetchStrategy and mediawiki.fetchStrategy\n";
 848                 exit 1;
 849         }
 850
 851         if ($fetch_from == 1 && $n == 0) {
 852                 print {*STDERR} "You appear to have cloned an empty MediaWiki.\n";
 853                 # Something has to be done remote-helper side. If nothing is done, an error is
 854                 # thrown saying that HEAD is referring to unknown object 0000000000000000000
 855                 # and the clone fails.
 856         }
 857         return;
 858 }
 859
 860 sub mw_import_ref_by_pages {
 861
 862         my $fetch_from = shift;
 863         my %pages_hash = get_mw_pages();
 864         my @pages = values(%pages_hash);
 865
 866         my ($n, @revisions) = fetch_mw_revisions(\@pages, $fetch_from);
 867
 868         @revisions = sort {$a->{revid} <=> $b->{revid}} @revisions;
 869         my @revision_ids = map { $_->{revid} } @revisions;
 870
 871         return mw_import_revids($fetch_from, \@revision_ids, \%pages_hash);
 872 }
 873
 874 sub mw_import_ref_by_revs {
 875
 876         my $fetch_from = shift;
 877         my %pages_hash = get_mw_pages();
 878
 879         my $last_remote = get_last_global_remote_rev();
 880         my @revision_ids = $fetch_from..$last_remote;
 881         return mw_import_revids($fetch_from, \@revision_ids, \%pages_hash);
 882 }
 883
 884 # Import revisions given in second argument (array of integers).
 885 # Only pages appearing in the third argument (hash indexed by page titles)
 886 # will be imported.
 887 sub mw_import_revids {
 888         my $fetch_from = shift;
 889         my $revision_ids = shift;
 890         my $pages = shift;
 891
 892         my $n = 0;
 893         my $n_actual = 0;
 894         my $last_timestamp = 0; # Placeholder in case $rev->timestamp is undefined
 895
 896         foreach my $pagerevid (@{$revision_ids}) {
 897                 # Count page even if we skip it, since we display
 898                 # $n/$total and $total includes skipped pages.
 899                 $n++;
 900
 901                 # fetch the content of the pages
 902                 my $query = {
 903                         action => 'query',
 904                         prop => 'revisions',
 905                         rvprop => 'content|timestamp|comment|user|ids',
 906                         revids => $pagerevid,
 907                 };
 908
 909                 my $result = $mediawiki->api($query);
 910
 911                 if (!$result) {
 912                         die "Failed to retrieve modified page for revision $pagerevid\n";
 913                 }
 914
 915                 if (defined($result->{query}->{badrevids}->{$pagerevid})) {
 916                         # The revision id does not exist on the remote wiki.
 917                         next;
 918                 }
 919
 920                 if (!defined($result->{query}->{pages})) {
 921                         die "Invalid revision ${pagerevid}.\n";
 922                 }
 923
 924                 my @result_pages = values(%{$result->{query}->{pages}});
 925                 my $result_page = $result_pages[0];
 926                 my $rev = $result_pages[0]->{revisions}->[0];
 927
 928                 my $page_title = $result_page->{title};
 929
 930                 if (!exists($pages->{$page_title})) {
 931                         print {*STDERR} "${n}/", scalar(@{$revision_ids}),
 932                                 ": Skipping revision #$rev->{revid} of ${page_title}\n";
 933                         next;
 934                 }
 935
 936                 $n_actual++;
 937
 938                 my %commit;
 939                 $commit{author} = $rev->{user} || 'Anonymous';
 940                 $commit{comment} = $rev->{comment} || EMPTY_MESSAGE;
 941                 $commit{title} = smudge_filename($page_title);
 942                 $commit{mw_revision} = $rev->{revid};
 943                 $commit{content} = mediawiki_smudge($rev->{'*'});
 944
 945                 if (!defined($rev->{timestamp})) {
 946                         $last_timestamp++;
 947                 } else {
 948                         $last_timestamp = $rev->{timestamp};
 949                 }
 950                 $commit{date} = DateTime::Format::ISO8601->parse_datetime($last_timestamp);
 951
 952                 # Differentiates classic pages and media files.
 953                 my ($namespace, $filename) = $page_title =~ /^([^:]*):(.*)$/;
 954                 my %mediafile;
 955                 if ($namespace) {
 956                         my $id = get_mw_namespace_id($namespace);
 957                         if ($id && $id == get_mw_namespace_id('File')) {
 958                                 %mediafile = get_mw_mediafile_for_page_revision($filename, $rev->{timestamp});
 959                         }
 960                 }
 961                 # If this is a revision of the media page for new version
 962                 # of a file do one common commit for both file and media page.
 963                 # Else do commit only for that page.
 964                 print {*STDERR} "${n}/", scalar(@{$revision_ids}), ": Revision #$rev->{revid} of $commit{title}\n";
 965                 import_file_revision(\%commit, ($fetch_from == 1), $n_actual, \%mediafile);
 966         }
 967
 968         return $n_actual;
 969 }
 970
 971 sub error_non_fast_forward {
 972         my $advice = run_git('config --bool advice.pushNonFastForward');
 973         chomp($advice);
 974         if ($advice ne 'false') {
 975                 # Native git-push would show this after the summary.
 976                 # We can't ask it to display it cleanly, so print it
 977                 # ourselves before.
 978                 print {*STDERR} "To prevent you from losing history, non-fast-forward updates were rejected\n";
 979                 print {*STDERR} "Merge the remote changes (e.g. 'git pull') before pushing again. See the\n";
 980                 print {*STDERR} "'Note about fast-forwards' section of 'git push --help' for details.\n";
 981         }
 982         print {*STDOUT} qq(error $_[0] "non-fast-forward"\n);
 983         return 0;
 984 }
 985
 986 sub mw_upload_file {
 987         my $complete_file_name = shift;
 988         my $new_sha1 = shift;
 989         my $extension = shift;
 990         my $file_deleted = shift;
 991         my $summary = shift;
 992         my $newrevid;
 993         my $path = "File:${complete_file_name}";
 994         my %hashFiles = get_allowed_file_extensions();
 995         if (!exists($hashFiles{$extension})) {
 996                 print {*STDERR} "${complete_file_name} is not a permitted file on this wiki.\n";
 997                 print {*STDERR} "Check the configuration of file uploads in your mediawiki.\n";
 998                 return $newrevid;
 999         }
1000         # Deleting and uploading a file requires a privileged user
1001         if ($file_deleted) {
1002                 $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1003                 my $query = {
1004                         action => 'delete',
1005                         title => $path,
1006                         reason => $summary
1007                 };
1008                 if (!$mediawiki->edit($query)) {
1009                         print {*STDERR} "Failed to delete file on remote wiki\n";
1010                         print {*STDERR} "Check your permissions on the remote site. Error code:\n";
1011                         print {*STDERR} $mediawiki->{error}->{code} . ':' . $mediawiki->{error}->{details};
1012                         exit 1;
1013                 }
1014         } else {
1015                 # Don't let perl try to interpret file content as UTF-8 => use "raw"
1016                 my $content = run_git("cat-file blob ${new_sha1}", 'raw');
1017                 if ($content ne EMPTY) {
1018                         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1019                         $mediawiki->{config}->{upload_url} =
1020                                 "${url}/index.php/Special:Upload";
1021                         $mediawiki->edit({
1022                                 action => 'upload',
1023                                 filename => $complete_file_name,
1024                                 comment => $summary,
1025                                 file => [undef,
1026                                          $complete_file_name,
1027                                          Content => $content],
1028                                 ignorewarnings => 1,
1029                         }, {
1030                                 skip_encoding => 1
1031                         } ) || die $mediawiki->{error}->{code} . ':'
1032                                  . $mediawiki->{error}->{details} . "\n";
1033                         my $last_file_page = $mediawiki->get_page({title => $path});
1034                         $newrevid = $last_file_page->{revid};
1035                         print {*STDERR} "Pushed file: ${new_sha1} - ${complete_file_name}.\n";
1036                 } else {
1037                         print {*STDERR} "Empty file ${complete_file_name} not pushed.\n";
1038                 }
1039         }
1040         return $newrevid;
1041 }
1042
1043 sub mw_push_file {
1044         my $diff_info = shift;
1045         # $diff_info contains a string in this format:
1046         # 100644 100644 <sha1_of_blob_before_commit> <sha1_of_blob_now> <status>
1047         my @diff_info_split = split(/[ \t]/, $diff_info);
1048
1049         # Filename, including .mw extension
1050         my $complete_file_name = shift;
1051         # Commit message
1052         my $summary = shift;
1053         # MediaWiki revision number. Keep the previous one by default,
1054         # in case there's no edit to perform.
1055         my $oldrevid = shift;
1056         my $newrevid;
1057
1058         if ($summary eq EMPTY_MESSAGE) {
1059                 $summary = EMPTY;
1060         }
1061
1062         my $new_sha1 = $diff_info_split[3];
1063         my $old_sha1 = $diff_info_split[2];
1064         my $page_created = ($old_sha1 eq NULL_SHA1);
1065         my $page_deleted = ($new_sha1 eq NULL_SHA1);
1066         $complete_file_name = clean_filename($complete_file_name);
1067
1068         my ($title, $extension) = $complete_file_name =~ /^(.*)\.([^\.]*)$/;
1069         if (!defined($extension)) {
1070                 $extension = EMPTY;
1071         }
1072         if ($extension eq 'mw') {
1073                 my $ns = get_mw_namespace_id_for_page($complete_file_name);
1074                 if ($ns && $ns == get_mw_namespace_id('File') && (!$export_media)) {
1075                         print {*STDERR} "Ignoring media file related page: ${complete_file_name}\n";
1076                         return ($oldrevid, 'ok');
1077                 }
1078                 my $file_content;
1079                 if ($page_deleted) {
1080                         # Deleting a page usually requires
1081                         # special privileges. A common
1082                         # convention is to replace the page
1083                         # with this content instead:
1084                         $file_content = DELETED_CONTENT;
1085                 } else {
1086                         $file_content = run_git("cat-file blob ${new_sha1}");
1087                 }
1088
1089                 $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1090
1091                 my $result = $mediawiki->edit( {
1092                         action => 'edit',
1093                         summary => $summary,
1094                         title => $title,
1095                         basetimestamp => $basetimestamps{$oldrevid},
1096                         text => mediawiki_clean($file_content, $page_created),
1097                                   }, {
1098                                           skip_encoding => 1 # Helps with names with accentuated characters
1099                                   });
1100                 if (!$result) {
1101                         if ($mediawiki->{error}->{code} == 3) {
1102                                 # edit conflicts, considered as non-fast-forward
1103                                 print {*STDERR} 'Warning: Error ' .
1104                                     $mediawiki->{error}->{code} .
1105                                     ' from mediawiki: ' . $mediawiki->{error}->{details} .
1106                                     ".\n";
1107                                 return ($oldrevid, 'non-fast-forward');
1108                         } else {
1109                                 # Other errors. Shouldn't happen => just die()
1110                                 die 'Fatal: Error ' .
1111                                     $mediawiki->{error}->{code} .
1112                                     ' from mediawiki: ' . $mediawiki->{error}->{details} . "\n";
1113                         }
1114                 }
1115                 $newrevid = $result->{edit}->{newrevid};
1116                 print {*STDERR} "Pushed file: ${new_sha1} - ${title}\n";
1117         } elsif ($export_media) {
1118                 $newrevid = mw_upload_file($complete_file_name, $new_sha1,
1119                                            $extension, $page_deleted,
1120                                            $summary);
1121         } else {
1122                 print {*STDERR} "Ignoring media file ${title}\n";
1123         }
1124         $newrevid = ($newrevid or $oldrevid);
1125         return ($newrevid, 'ok');
1126 }
1127
1128 sub mw_push {
1129         # multiple push statements can follow each other
1130         my @refsspecs = (shift, get_more_refs('push'));
1131         my $pushed;
1132         for my $refspec (@refsspecs) {
1133                 my ($force, $local, $remote) = $refspec =~ /^(\+)?([^:]*):([^:]*)$/
1134                     or die("Invalid refspec for push. Expected <src>:<dst> or +<src>:<dst>\n");
1135                 if ($force) {
1136                         print {*STDERR} "Warning: forced push not allowed on a MediaWiki.\n";
1137                 }
1138                 if ($local eq EMPTY) {
1139                         print {*STDERR} "Cannot delete remote branch on a MediaWiki\n";
1140                         print {*STDOUT} "error ${remote} cannot delete\n";
1141                         next;
1142                 }
1143                 if ($remote ne 'refs/heads/master') {
1144                         print {*STDERR} "Only push to the branch 'master' is supported on a MediaWiki\n";
1145                         print {*STDOUT} "error ${remote} only master allowed\n";
1146                         next;
1147                 }
1148                 if (mw_push_revision($local, $remote)) {
1149                         $pushed = 1;
1150                 }
1151         }
1152
1153         # Notify Git that the push is done
1154         print {*STDOUT} "\n";
1155
1156         if ($pushed && $dumb_push) {
1157                 print {*STDERR} "Just pushed some revisions to MediaWiki.\n";
1158                 print {*STDERR} "The pushed revisions now have to be re-imported, and your current branch\n";
1159                 print {*STDERR} "needs to be updated with these re-imported commits. You can do this with\n";
1160                 print {*STDERR} "\n";
1161                 print {*STDERR} "  git pull --rebase\n";
1162                 print {*STDERR} "\n";
1163         }
1164         return;
1165 }
1166
1167 sub mw_push_revision {
1168         my $local = shift;
1169         my $remote = shift; # actually, this has to be "refs/heads/master" at this point.
1170         my $last_local_revid = get_last_local_revision();
1171         print {*STDERR} ".\n"; # Finish sentence started by get_last_local_revision()
1172         my $last_remote_revid = get_last_remote_revision();
1173         my $mw_revision = $last_remote_revid;
1174
1175         # Get sha1 of commit pointed by local HEAD
1176         my $HEAD_sha1 = run_git("rev-parse ${local} 2>/dev/null");
1177         chomp($HEAD_sha1);
1178         # Get sha1 of commit pointed by remotes/$remotename/master
1179         my $remoteorigin_sha1 = run_git("rev-parse refs/remotes/${remotename}/master 2>/dev/null");
1180         chomp($remoteorigin_sha1);
1181
1182         if ($last_local_revid > 0 &&
1183             $last_local_revid < $last_remote_revid) {
1184                 return error_non_fast_forward($remote);
1185         }
1186
1187         if ($HEAD_sha1 eq $remoteorigin_sha1) {
1188                 # nothing to push
1189                 return 0;
1190         }
1191
1192         # Get every commit in between HEAD and refs/remotes/origin/master,
1193         # including HEAD and refs/remotes/origin/master
1194         my @commit_pairs = ();
1195         if ($last_local_revid > 0) {
1196                 my $parsed_sha1 = $remoteorigin_sha1;
1197                 # Find a path from last MediaWiki commit to pushed commit
1198                 print {*STDERR} "Computing path from local to remote ...\n";
1199                 my @local_ancestry = split(/\n/, run_git("rev-list --boundary --parents ${local} ^${parsed_sha1}"));
1200                 my %local_ancestry;
1201                 foreach my $line (@local_ancestry) {
1202                         if (my ($child, $parents) = $line =~ /^-?([a-f0-9]+) ([a-f0-9 ]+)/) {
1203                                 foreach my $parent (split(/ /, $parents)) {
1204                                         $local_ancestry{$parent} = $child;
1205                                 }
1206                         } elsif (!$line =~ /^([a-f0-9]+)/) {
1207                                 die "Unexpected output from git rev-list: ${line}\n";
1208                         }
1209                 }
1210                 while ($parsed_sha1 ne $HEAD_sha1) {
1211                         my $child = $local_ancestry{$parsed_sha1};
1212                         if (!$child) {
1213                                 print {*STDERR} "Cannot find a path in history from remote commit to last commit\n";
1214                                 return error_non_fast_forward($remote);
1215                         }
1216                         push(@commit_pairs, [$parsed_sha1, $child]);
1217                         $parsed_sha1 = $child;
1218                 }
1219         } else {
1220                 # No remote mediawiki revision. Export the whole
1221                 # history (linearized with --first-parent)
1222                 print {*STDERR} "Warning: no common ancestor, pushing complete history\n";
1223                 my $history = run_git("rev-list --first-parent --children ${local}");
1224                 my @history = split(/\n/, $history);
1225                 @history = @history[1..$#history];
1226                 foreach my $line (reverse @history) {
1227                         my @commit_info_split = split(/[ \n]/, $line);
1228                         push(@commit_pairs, \@commit_info_split);
1229                 }
1230         }
1231
1232         foreach my $commit_info_split (@commit_pairs) {
1233                 my $sha1_child = @{$commit_info_split}[0];
1234                 my $sha1_commit = @{$commit_info_split}[1];
1235                 my $diff_infos = run_git("diff-tree -r --raw -z ${sha1_child} ${sha1_commit}");
1236                 # TODO: we could detect rename, and encode them with a #redirect on the wiki.
1237                 # TODO: for now, it's just a delete+add
1238                 my @diff_info_list = split(/\0/, $diff_infos);
1239                 # Keep the subject line of the commit message as mediawiki comment for the revision
1240                 my $commit_msg = run_git(qq(log --no-walk --format="%s" ${sha1_commit}));
1241                 chomp($commit_msg);
1242                 # Push every blob
1243                 while (@diff_info_list) {
1244                         my $status;
1245                         # git diff-tree -z gives an output like
1246                         # <metadata>\0<filename1>\0
1247                         # <metadata>\0<filename2>\0
1248                         # and we've split on \0.
1249                         my $info = shift(@diff_info_list);
1250                         my $file = shift(@diff_info_list);
1251                         ($mw_revision, $status) = mw_push_file($info, $file, $commit_msg, $mw_revision);
1252                         if ($status eq 'non-fast-forward') {
1253                                 # we may already have sent part of the
1254                                 # commit to MediaWiki, but it's too
1255                                 # late to cancel it. Stop the push in
1256                                 # the middle, but still give an
1257                                 # accurate error message.
1258                                 return error_non_fast_forward($remote);
1259                         }
1260                         if ($status ne 'ok') {
1261                                 die("Unknown error from mw_push_file()\n");
1262                         }
1263                 }
1264                 if (!$dumb_push) {
1265                         run_git(qq(notes --ref=${remotename}/mediawiki add -f -m "mediawiki_revision: ${mw_revision}" ${sha1_commit}));
1266                 }
1267         }
1268
1269         print {*STDOUT} "ok ${remote}\n";
1270         return 1;
1271 }
1272
1273 sub get_allowed_file_extensions {
1274         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1275
1276         my $query = {
1277                 action => 'query',
1278                 meta => 'siteinfo',
1279                 siprop => 'fileextensions'
1280                 };
1281         my $result = $mediawiki->api($query);
1282         my @file_extensions = map { $_->{ext}} @{$result->{query}->{fileextensions}};
1283         my %hashFile = map { $_ => 1 } @file_extensions;
1284
1285         return %hashFile;
1286 }
1287
1288 # In memory cache for MediaWiki namespace ids.
1289 my %namespace_id;
1290
1291 # Namespaces whose id is cached in the configuration file
1292 # (to avoid duplicates)
1293 my %cached_mw_namespace_id;
1294
1295 # Return MediaWiki id for a canonical namespace name.
1296 # Ex.: "File", "Project".
1297 sub get_mw_namespace_id {
1298         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1299         my $name = shift;
1300
1301         if (!exists $namespace_id{$name}) {
1302                 # Look at configuration file, if the record for that namespace is
1303                 # already cached. Namespaces are stored in form:
1304                 # "Name_of_namespace:Id_namespace", ex.: "File:6".
1305                 my @temp = split(/\n/,
1306                                  run_git("config --get-all remote.${remotename}.namespaceCache"));
1307                 chomp(@temp);
1308                 foreach my $ns (@temp) {
1309                         my ($n, $id) = split(/:/, $ns);
1310                         if ($id eq 'notANameSpace') {
1311                                 $namespace_id{$n} = {is_namespace => 0};
1312                         } else {
1313                                 $namespace_id{$n} = {is_namespace => 1, id => $id};
1314                         }
1315                         $cached_mw_namespace_id{$n} = 1;
1316                 }
1317         }
1318
1319         if (!exists $namespace_id{$name}) {
1320                 print {*STDERR} "Namespace ${name} not found in cache, querying the wiki ...\n";
1321                 # NS not found => get namespace id from MW and store it in
1322                 # configuration file.
1323                 my $query = {
1324                         action => 'query',
1325                         meta => 'siteinfo',
1326                         siprop => 'namespaces'
1327                 };
1328                 my $result = $mediawiki->api($query);
1329
1330                 while (my ($id, $ns) = each(%{$result->{query}->{namespaces}})) {
1331                         if (defined($ns->{id}) && defined($ns->{canonical})) {
1332                                 $namespace_id{$ns->{canonical}} = {is_namespace => 1, id => $ns->{id}};
1333                                 if ($ns->{'*'}) {
1334                                         # alias (e.g. french Fichier: as alias for canonical File:)
1335                                         $namespace_id{$ns->{'*'}} = {is_namespace => 1, id => $ns->{id}};
1336                                 }
1337                         }
1338                 }
1339         }
1340
1341         my $ns = $namespace_id{$name};
1342         my $id;
1343
1344         if (!defined $ns) {
1345                 my @namespaces = map { s/ /_/g; $_; } sort keys %namespace_id;
1346                 print {*STDERR} "No such namespace ${name} on MediaWiki, known namespaces: @namespaces\n";
1347                 $ns = {is_namespace => 0};
1348                 $namespace_id{$name} = $ns;
1349         }
1350
1351         if ($ns->{is_namespace}) {
1352                 $id = $ns->{id};
1353         }
1354
1355         # Store "notANameSpace" as special value for inexisting namespaces
1356         my $store_id = ($id || 'notANameSpace');
1357
1358         # Store explicitly requested namespaces on disk
1359         if (!exists $cached_mw_namespace_id{$name}) {
1360                 run_git(qq(config --add remote.${remotename}.namespaceCache "${name}:${store_id}"));
1361                 $cached_mw_namespace_id{$name} = 1;
1362         }
1363         return $id;
1364 }
1365
1366 sub get_mw_namespace_id_for_page {
1367         my $namespace = shift;
1368         if ($namespace =~ /^([^:]*):/) {
1369                 return get_mw_namespace_id($namespace);
1370         } else {
1371                 return;
1372         }
1373 }