git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 # From which subdir have we been invoked?
  14 my $cmd_dir_prefix = eval {
  15         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  16 } || '';
  17
  18 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  19 $ENV{GIT_DIR} ||= '.git';
  20 $Git::SVN::default_repo_id = 'svn';
  21 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  22 $Git::SVN::Ra::_log_window_size = 100;
  23 $Git::SVN::_minimize_url = 'unset';
  24
  25 if (! exists $ENV{SVN_SSH}) {
  26         if (exists $ENV{GIT_SSH}) {
  27                 $ENV{SVN_SSH} = $ENV{GIT_SSH};
  28                 if ($^O eq 'msys') {
  29                         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  30                         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  31                 }
  32         }
  33 }
  34
  35 $Git::SVN::Log::TZ = $ENV{TZ};
  36 $ENV{TZ} = 'UTC';
  37 $| = 1; # unbuffer STDOUT
  38
  39 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  40 sub _req_svn {
  41         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  42         require SVN::Ra;
  43         require SVN::Delta;
  44         if ($SVN::Core::VERSION lt '1.1.0') {
  45                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  46         }
  47 }
  48 my $can_compress = eval { require Compress::Zlib; 1};
  49 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  50 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  51 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  52 use Carp qw/croak/;
  53 use Digest::MD5;
  54 use IO::File qw//;
  55 use File::Basename qw/dirname basename/;
  56 use File::Path qw/mkpath/;
  57 use File::Spec;
  58 use File::Find;
  59 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  60 use IPC::Open3;
  61 use Git;
  62
  63 BEGIN {
  64         # import functions from Git into our packages, en masse
  65         no strict 'refs';
  66         foreach (qw/command command_oneline command_noisy command_output_pipe
  67                     command_input_pipe command_close_pipe
  68                     command_bidi_pipe command_close_bidi_pipe/) {
  69                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  70                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  71                         __PACKAGE__) {
  72                         *{"${package}::$_"} = \&{"Git::$_"};
  73                 }
  74         }
  75 }
  76
  77 my ($SVN);
  78
  79 $sha1 = qr/[a-f\d]{40}/;
  80 $sha1_short = qr/[a-f\d]{4,40}/;
  81 my ($_stdin, $_help, $_edit,
  82         $_message, $_file, $_branch_dest,
  83         $_template, $_shared,
  84         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
  85         $_merge, $_strategy, $_dry_run, $_local,
  86         $_prefix, $_no_checkout, $_url, $_verbose,
  87         $_git_format, $_commit_url, $_tag, $_merge_info);
  88 $Git::SVN::_follow_parent = 1;
  89 $_q ||= 0;
  90 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  91                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  92                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  93                     'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
  94 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  95                 'authors-file|A=s' => \$_authors,
  96                 'authors-prog=s' => \$_authors_prog,
  97                 'repack:i' => \$Git::SVN::_repack,
  98                 'noMetadata' => \$Git::SVN::_no_metadata,
  99                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 100                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 101                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 102                 'no-checkout' => \$_no_checkout,
 103                 'quiet|q+' => \$_q,
 104                 'repack-flags|repack-args|repack-opts=s' =>
 105                    \$Git::SVN::_repack_flags,
 106                 'use-log-author' => \$Git::SVN::_use_log_author,
 107                 'add-author-from' => \$Git::SVN::_add_author_from,
 108                 'localtime' => \$Git::SVN::_localtime,
 109                 %remote_opts );
 110
 111 my ($_trunk, @_tags, @_branches, $_stdlayout);
 112 my %icv;
 113 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 114                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 115                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 116                   'stdlayout|s' => \$_stdlayout,
 117                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 118                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 119                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 120                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 121                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 122                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 123                   %remote_opts );
 124 my %cmt_opts = ( 'edit|e' => \$_edit,
 125                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 126                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 127                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 128                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 129 );
 130
 131 my %cmd = (
 132         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 133                         { 'revision|r=s' => \$_revision,
 134                           'fetch-all|all' => \$_fetch_all,
 135                           'parent|p' => \$_fetch_parent,
 136                            %fc_opts } ],
 137         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 138                         { 'revision|r=s' => \$_revision,
 139                            %fc_opts, %init_opts } ],
 140         init => [ \&cmd_init, "Initialize a repo for tracking" .
 141                           " (requires URL argument)",
 142                           \%init_opts ],
 143         'multi-init' => [ \&cmd_multi_init,
 144                           "Deprecated alias for ".
 145                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 146                           \%init_opts ],
 147         dcommit => [ \&cmd_dcommit,
 148                      'Commit several diffs to merge with upstream',
 149                         { 'merge|m|M' => \$_merge,
 150                           'strategy|s=s' => \$_strategy,
 151                           'verbose|v' => \$_verbose,
 152                           'dry-run|n' => \$_dry_run,
 153                           'fetch-all|all' => \$_fetch_all,
 154                           'commit-url=s' => \$_commit_url,
 155                           'revision|r=i' => \$_revision,
 156                           'no-rebase' => \$_no_rebase,
 157                           'mergeinfo=s' => \$_merge_info,
 158                         %cmt_opts, %fc_opts } ],
 159         branch => [ \&cmd_branch,
 160                     'Create a branch in the SVN repository',
 161                     { 'message|m=s' => \$_message,
 162                       'destination|d=s' => \$_branch_dest,
 163                       'dry-run|n' => \$_dry_run,
 164                       'tag|t' => \$_tag,
 165                       'username=s' => \$Git::SVN::Prompt::_username,
 166                       'commit-url=s' => \$_commit_url } ],
 167         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 168                  'Create a tag in the SVN repository',
 169                  { 'message|m=s' => \$_message,
 170                    'destination|d=s' => \$_branch_dest,
 171                    'dry-run|n' => \$_dry_run,
 172                    'username=s' => \$Git::SVN::Prompt::_username,
 173                    'commit-url=s' => \$_commit_url } ],
 174         'set-tree' => [ \&cmd_set_tree,
 175                         "Set an SVN repository to a git tree-ish",
 176                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 177         'create-ignore' => [ \&cmd_create_ignore,
 178                              'Create a .gitignore per svn:ignore',
 179                              { 'revision|r=i' => \$_revision
 180                              } ],
 181         'mkdirs' => [ \&cmd_mkdirs ,
 182                       "recreate empty directories after a checkout",
 183                       { 'revision|r=i' => \$_revision } ],
 184         'propget' => [ \&cmd_propget,
 185                        'Print the value of a property on a file or directory',
 186                        { 'revision|r=i' => \$_revision } ],
 187         'proplist' => [ \&cmd_proplist,
 188                        'List all properties of a file or directory',
 189                        { 'revision|r=i' => \$_revision } ],
 190         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 191                         { 'revision|r=i' => \$_revision
 192                         } ],
 193         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 194                         { 'revision|r=i' => \$_revision
 195                         } ],
 196         'multi-fetch' => [ \&cmd_multi_fetch,
 197                            "Deprecated alias for $0 fetch --all",
 198                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 199         'migrate' => [ sub { },
 200                        # no-op, we automatically run this anyways,
 201                        'Migrate configuration/metadata/layout from
 202                         previous versions of git-svn',
 203                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 204                          %remote_opts } ],
 205         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 206                         { 'limit=i' => \$Git::SVN::Log::limit,
 207                           'revision|r=s' => \$_revision,
 208                           'verbose|v' => \$Git::SVN::Log::verbose,
 209                           'incremental' => \$Git::SVN::Log::incremental,
 210                           'oneline' => \$Git::SVN::Log::oneline,
 211                           'show-commit' => \$Git::SVN::Log::show_commit,
 212                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 213                           'authors-file|A=s' => \$_authors,
 214                           'color' => \$Git::SVN::Log::color,
 215                           'pager=s' => \$Git::SVN::Log::pager
 216                         } ],
 217         'find-rev' => [ \&cmd_find_rev,
 218                         "Translate between SVN revision numbers and tree-ish",
 219                         {} ],
 220         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 221                         { 'merge|m|M' => \$_merge,
 222                           'verbose|v' => \$_verbose,
 223                           'strategy|s=s' => \$_strategy,
 224                           'local|l' => \$_local,
 225                           'fetch-all|all' => \$_fetch_all,
 226                           'dry-run|n' => \$_dry_run,
 227                           %fc_opts } ],
 228         'commit-diff' => [ \&cmd_commit_diff,
 229                            'Commit a diff between two trees',
 230                         { 'message|m=s' => \$_message,
 231                           'file|F=s' => \$_file,
 232                           'revision|r=s' => \$_revision,
 233                         %cmt_opts } ],
 234         'info' => [ \&cmd_info,
 235                     "Show info about the latest SVN revision
 236                      on the current branch",
 237                     { 'url' => \$_url, } ],
 238         'blame' => [ \&Git::SVN::Log::cmd_blame,
 239                     "Show what revision and author last modified each line of a file",
 240                     { 'git-format' => \$_git_format } ],
 241         'reset' => [ \&cmd_reset,
 242                      "Undo fetches back to the specified SVN revision",
 243                      { 'revision|r=s' => \$_revision,
 244                        'parent|p' => \$_fetch_parent } ],
 245         'gc' => [ \&cmd_gc,
 246                   "Compress unhandled.log files in .git/svn and remove " .
 247                   "index files in .git/svn",
 248                 {} ],
 249 );
 250
 251 my $cmd;
 252 for (my $i = 0; $i < @ARGV; $i++) {
 253         if (defined $cmd{$ARGV[$i]}) {
 254                 $cmd = $ARGV[$i];
 255                 splice @ARGV, $i, 1;
 256                 last;
 257         } elsif ($ARGV[$i] eq 'help') {
 258                 $cmd = $ARGV[$i+1];
 259                 usage(0);
 260         }
 261 };
 262
 263 # make sure we're always running at the top-level working directory
 264 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 265         unless (-d $ENV{GIT_DIR}) {
 266                 if ($git_dir_user_set) {
 267                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 268                             "but it is not a directory\n";
 269                 }
 270                 my $git_dir = delete $ENV{GIT_DIR};
 271                 my $cdup = undef;
 272                 git_cmd_try {
 273                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 274                         $git_dir = '.' unless ($cdup);
 275                         chomp $cdup if ($cdup);
 276                         $cdup = "." unless ($cdup && length $cdup);
 277                 } "Already at toplevel, but $git_dir not found\n";
 278                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 279                 unless (-d $git_dir) {
 280                         die "$git_dir still not found after going to ",
 281                             "'$cdup'\n";
 282                 }
 283                 $ENV{GIT_DIR} = $git_dir;
 284         }
 285         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 286 }
 287
 288 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 289
 290 read_git_config(\%opts);
 291 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 292         Getopt::Long::Configure('pass_through');
 293 }
 294 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 295                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 296                     'id|i=s' => \$Git::SVN::default_ref_id,
 297                     'svn-remote|remote|R=s' => sub {
 298                        $Git::SVN::no_reuse_existing = 1;
 299                        $Git::SVN::default_repo_id = $_[1] });
 300 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 301
 302 usage(0) if $_help;
 303 version() if $_version;
 304 usage(1) unless defined $cmd;
 305 load_authors() if $_authors;
 306 if (defined $_authors_prog) {
 307         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 308 }
 309
 310 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 311         Git::SVN::Migration::migration_check();
 312 }
 313 Git::SVN::init_vars();
 314 eval {
 315         Git::SVN::verify_remotes_sanity();
 316         $cmd{$cmd}->[0]->(@ARGV);
 317 };
 318 fatal $@ if $@;
 319 post_fetch_checkout();
 320 exit 0;
 321
 322 ####################### primary functions ######################
 323 sub usage {
 324         my $exit = shift || 0;
 325         my $fd = $exit ? \*STDERR : \*STDOUT;
 326         print $fd <<"";
 327 git-svn - bidirectional operations between a single Subversion tree and git
 328 Usage: git svn <command> [options] [arguments]\n
 329
 330         print $fd "Available commands:\n" unless $cmd;
 331
 332         foreach (sort keys %cmd) {
 333                 next if $cmd && $cmd ne $_;
 334                 next if /^multi-/; # don't show deprecated commands
 335                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 336                 foreach (sort keys %{$cmd{$_}->[2]}) {
 337                         # mixed-case options are for .git/config only
 338                         next if /[A-Z]/ && /^[a-z]+$/i;
 339                         # prints out arguments as they should be passed:
 340                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 341                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 342                                                         "--$_" : "-$_" }
 343                                                 split /\|/,$_)," $x\n";
 344                 }
 345         }
 346         print $fd <<"";
 347 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 348 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 349 one git repository and want to keep them separate.  See git-svn(1) for more
 350 information.
 351
 352         exit $exit;
 353 }
 354
 355 sub version {
 356         ::_req_svn();
 357         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 358         exit 0;
 359 }
 360
 361 sub do_git_init_db {
 362         unless (-d $ENV{GIT_DIR}) {
 363                 my @init_db = ('init');
 364                 push @init_db, "--template=$_template" if defined $_template;
 365                 if (defined $_shared) {
 366                         if ($_shared =~ /[a-z]/) {
 367                                 push @init_db, "--shared=$_shared";
 368                         } else {
 369                                 push @init_db, "--shared";
 370                         }
 371                 }
 372                 command_noisy(@init_db);
 373                 $_repository = Git->repository(Repository => ".git");
 374         }
 375         my $set;
 376         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 377         foreach my $i (keys %icv) {
 378                 die "'$set' and '$i' cannot both be set\n" if $set;
 379                 next unless defined $icv{$i};
 380                 command_noisy('config', "$pfx.$i", $icv{$i});
 381                 $set = $i;
 382         }
 383         my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
 384         command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
 385                 if defined $$ignore_regex;
 386 }
 387
 388 sub init_subdir {
 389         my $repo_path = shift or return;
 390         mkpath([$repo_path]) unless -d $repo_path;
 391         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 392         $ENV{GIT_DIR} = '.git';
 393         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 394 }
 395
 396 sub cmd_clone {
 397         my ($url, $path) = @_;
 398         if (!defined $path &&
 399             (defined $_trunk || @_branches || @_tags ||
 400              defined $_stdlayout) &&
 401             $url !~ m#^[a-z\+]+://#) {
 402                 $path = $url;
 403         }
 404         $path = basename($url) if !defined $path || !length $path;
 405         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 406         cmd_init($url, $path);
 407         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 408             if $_authors;
 409         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 410 }
 411
 412 sub cmd_init {
 413         if (defined $_stdlayout) {
 414                 $_trunk = 'trunk' if (!defined $_trunk);
 415                 @_tags = 'tags' if (! @_tags);
 416                 @_branches = 'branches' if (! @_branches);
 417         }
 418         if (defined $_trunk || @_branches || @_tags) {
 419                 return cmd_multi_init(@_);
 420         }
 421         my $url = shift or die "SVN repository location required ",
 422                                "as a command-line argument\n";
 423         $url = canonicalize_url($url);
 424         init_subdir(@_);
 425         do_git_init_db();
 426
 427         if ($Git::SVN::_minimize_url eq 'unset') {
 428                 $Git::SVN::_minimize_url = 0;
 429         }
 430
 431         Git::SVN->init($url);
 432 }
 433
 434 sub cmd_fetch {
 435         if (grep /^\d+=./, @_) {
 436                 die "'<rev>=<commit>' fetch arguments are ",
 437                     "no longer supported.\n";
 438         }
 439         my ($remote) = @_;
 440         if (@_ > 1) {
 441                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 442         }
 443         $Git::SVN::no_reuse_existing = undef;
 444         if ($_fetch_parent) {
 445                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 446                 unless ($gs) {
 447                         die "Unable to determine upstream SVN information from ",
 448                             "working tree history\n";
 449                 }
 450                 # just fetch, don't checkout.
 451                 $_no_checkout = 'true';
 452                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 453         } elsif ($_fetch_all) {
 454                 cmd_multi_fetch();
 455         } else {
 456                 $remote ||= $Git::SVN::default_repo_id;
 457                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 458         }
 459 }
 460
 461 sub cmd_set_tree {
 462         my (@commits) = @_;
 463         if ($_stdin || !@commits) {
 464                 print "Reading from stdin...\n";
 465                 @commits = ();
 466                 while (<STDIN>) {
 467                         if (/\b($sha1_short)\b/o) {
 468                                 unshift @commits, $1;
 469                         }
 470                 }
 471         }
 472         my @revs;
 473         foreach my $c (@commits) {
 474                 my @tmp = command('rev-parse',$c);
 475                 if (scalar @tmp == 1) {
 476                         push @revs, $tmp[0];
 477                 } elsif (scalar @tmp > 1) {
 478                         push @revs, reverse(command('rev-list',@tmp));
 479                 } else {
 480                         fatal "Failed to rev-parse $c";
 481                 }
 482         }
 483         my $gs = Git::SVN->new;
 484         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 485         $gs->fetch;
 486         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 487                 fatal "There are new revisions that were fetched ",
 488                       "and need to be merged (or acknowledged) ",
 489                       "before committing.\nlast rev: $r_last\n",
 490                       " current: $gs->{last_rev}";
 491         }
 492         $gs->set_tree($_) foreach @revs;
 493         print "Done committing ",scalar @revs," revisions to SVN\n";
 494         unlink $gs->{index};
 495 }
 496
 497 sub cmd_dcommit {
 498         my $head = shift;
 499         command_noisy(qw/update-index --refresh/);
 500         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 501                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 502                 . "or stash them with `git stash'.\n";
 503         $head ||= 'HEAD';
 504
 505         my $old_head;
 506         if ($head ne 'HEAD') {
 507                 $old_head = eval {
 508                         command_oneline([qw/symbolic-ref -q HEAD/])
 509                 };
 510                 if ($old_head) {
 511                         $old_head =~ s{^refs/heads/}{};
 512                 } else {
 513                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 514                 }
 515                 command(['checkout', $head], STDERR => 0);
 516         }
 517
 518         my @refs;
 519         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 520         unless ($gs) {
 521                 die "Unable to determine upstream SVN information from ",
 522                     "$head history.\nPerhaps the repository is empty.";
 523         }
 524
 525         if (defined $_commit_url) {
 526                 $url = $_commit_url;
 527         } else {
 528                 $url = eval { command_oneline('config', '--get',
 529                               "svn-remote.$gs->{repo_id}.commiturl") };
 530                 if (!$url) {
 531                         $url = $gs->full_url
 532                 }
 533         }
 534
 535         my $last_rev = $_revision if defined $_revision;
 536         if ($url) {
 537                 print "Committing to $url ...\n";
 538         }
 539         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 540         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 541                 warn "Attempting to commit more than one change while ",
 542                      "--no-rebase is enabled.\n",
 543                      "If these changes depend on each other, re-running ",
 544                      "without --no-rebase may be required."
 545         }
 546         my $expect_url = $url;
 547         Git::SVN::remove_username($expect_url);
 548         while (1) {
 549                 my $d = shift @$linear_refs or last;
 550                 unless (defined $last_rev) {
 551                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 552                         unless (defined $last_rev) {
 553                                 fatal "Unable to extract revision information ",
 554                                       "from commit $d~1";
 555                         }
 556                 }
 557                 if ($_dry_run) {
 558                         print "diff-tree $d~1 $d\n";
 559                 } else {
 560                         my $cmt_rev;
 561                         my %ed_opts = ( r => $last_rev,
 562                                         log => get_commit_entry($d)->{log},
 563                                         ra => Git::SVN::Ra->new($url),
 564                                         config => SVN::Core::config_get_config(
 565                                                 $Git::SVN::Ra::config_dir
 566                                         ),
 567                                         tree_a => "$d~1",
 568                                         tree_b => $d,
 569                                         editor_cb => sub {
 570                                                print "Committed r$_[0]\n";
 571                                                $cmt_rev = $_[0];
 572                                         },
 573                                         mergeinfo => $_merge_info,
 574                                         svn_path => '');
 575                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 576                                 print "No changes\n$d~1 == $d\n";
 577                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 578                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 579                                                                $parents->{$d};
 580                         }
 581                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 582                         $last_rev = $cmt_rev;
 583                         next if $_no_rebase;
 584
 585                         # we always want to rebase against the current HEAD,
 586                         # not any head that was passed to us
 587                         my @diff = command('diff-tree', $d,
 588                                            $gs->refname, '--');
 589                         my @finish;
 590                         if (@diff) {
 591                                 @finish = rebase_cmd();
 592                                 print STDERR "W: $d and ", $gs->refname,
 593                                              " differ, using @finish:\n",
 594                                              join("\n", @diff), "\n";
 595                         } else {
 596                                 print "No changes between current HEAD and ",
 597                                       $gs->refname,
 598                                       "\nResetting to the latest ",
 599                                       $gs->refname, "\n";
 600                                 @finish = qw/reset --mixed/;
 601                         }
 602                         command_noisy(@finish, $gs->refname);
 603                         if (@diff) {
 604                                 @refs = ();
 605                                 my ($url_, $rev_, $uuid_, $gs_) =
 606                                               working_head_info('HEAD', \@refs);
 607                                 my ($linear_refs_, $parents_) =
 608                                               linearize_history($gs_, \@refs);
 609                                 if (scalar(@$linear_refs) !=
 610                                     scalar(@$linear_refs_)) {
 611                                         fatal "# of revisions changed ",
 612                                           "\nbefore:\n",
 613                                           join("\n", @$linear_refs),
 614                                           "\n\nafter:\n",
 615                                           join("\n", @$linear_refs_), "\n",
 616                                           'If you are attempting to commit ',
 617                                           "merges, try running:\n\t",
 618                                           'git rebase --interactive',
 619                                           '--preserve-merges ',
 620                                           $gs->refname,
 621                                           "\nBefore dcommitting";
 622                                 }
 623                                 if ($url_ ne $expect_url) {
 624                                         if ($url_ eq $gs->metadata_url) {
 625                                                 print
 626                                                   "Accepting rewritten URL:",
 627                                                   " $url_\n";
 628                                         } else {
 629                                                 fatal
 630                                                   "URL mismatch after rebase:",
 631                                                   " $url_ != $expect_url";
 632                                         }
 633                                 }
 634                                 if ($uuid_ ne $uuid) {
 635                                         fatal "uuid mismatch after rebase: ",
 636                                               "$uuid_ != $uuid";
 637                                 }
 638                                 # remap parents
 639                                 my (%p, @l, $i);
 640                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 641                                         my $new = $linear_refs_->[$i] or next;
 642                                         $p{$new} =
 643                                                 $parents->{$linear_refs->[$i]};
 644                                         push @l, $new;
 645                                 }
 646                                 $parents = \%p;
 647                                 $linear_refs = \@l;
 648                         }
 649                 }
 650         }
 651
 652         if ($old_head) {
 653                 my $new_head = command_oneline(qw/rev-parse HEAD/);
 654                 my $new_is_symbolic = eval {
 655                         command_oneline(qw/symbolic-ref -q HEAD/);
 656                 };
 657                 if ($new_is_symbolic) {
 658                         print "dcommitted the branch ", $head, "\n";
 659                 } else {
 660                         print "dcommitted on a detached HEAD because you gave ",
 661                               "a revision argument.\n",
 662                               "The rewritten commit is: ", $new_head, "\n";
 663                 }
 664                 command(['checkout', $old_head], STDERR => 0);
 665         }
 666
 667         unlink $gs->{index};
 668 }
 669
 670 sub cmd_branch {
 671         my ($branch_name, $head) = @_;
 672
 673         unless (defined $branch_name && length $branch_name) {
 674                 die(($_tag ? "tag" : "branch") . " name required\n");
 675         }
 676         $head ||= 'HEAD';
 677
 678         my (undef, $rev, undef, $gs) = working_head_info($head);
 679         my $src = $gs->full_url;
 680
 681         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 682         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
 683         my $glob;
 684         if ($#{$allglobs} == 0) {
 685                 $glob = $allglobs->[0];
 686         } else {
 687                 unless(defined $_branch_dest) {
 688                         die "Multiple ",
 689                             $_tag ? "tag" : "branch",
 690                             " paths defined for Subversion repository.\n",
 691                             "You must specify where you want to create the ",
 692                             $_tag ? "tag" : "branch",
 693                             " with the --destination argument.\n";
 694                 }
 695                 foreach my $g (@{$allglobs}) {
 696                         # SVN::Git::Editor could probably be moved to Git.pm..
 697                         my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
 698                         if ($_branch_dest =~ /$re/) {
 699                                 $glob = $g;
 700                                 last;
 701                         }
 702                 }
 703                 unless (defined $glob) {
 704                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
 705                         foreach my $g (@{$allglobs}) {
 706                                 $g->{path}->{left} =~ /$dest_re/ or next;
 707                                 if (defined $glob) {
 708                                         die "Ambiguous destination: ",
 709                                             $_branch_dest, "\nmatches both '",
 710                                             $glob->{path}->{left}, "' and '",
 711                                             $g->{path}->{left}, "'\n";
 712                                 }
 713                                 $glob = $g;
 714                         }
 715                         unless (defined $glob) {
 716                                 die "Unknown ",
 717                                     $_tag ? "tag" : "branch",
 718                                     " destination $_branch_dest\n";
 719                         }
 720                 }
 721         }
 722         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 723         my $url;
 724         if (defined $_commit_url) {
 725                 $url = $_commit_url;
 726         } else {
 727                 $url = eval { command_oneline('config', '--get',
 728                         "svn-remote.$gs->{repo_id}.commiturl") };
 729                 if (!$url) {
 730                         $url = $remote->{url};
 731                 }
 732         }
 733         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
 734
 735         if ($dst =~ /^https:/ && $src =~ /^http:/) {
 736                 $src=~s/^http:/https:/;
 737         }
 738
 739         ::_req_svn();
 740
 741         my $ctx = SVN::Client->new(
 742                 auth    => Git::SVN::Ra::_auth_providers(),
 743                 log_msg => sub {
 744                         ${ $_[0] } = defined $_message
 745                                 ? $_message
 746                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 747                                 . $branch_name;
 748                 },
 749         );
 750
 751         eval {
 752                 $ctx->ls($dst, 'HEAD', 0);
 753         } and die "branch ${branch_name} already exists\n";
 754
 755         print "Copying ${src} at r${rev} to ${dst}...\n";
 756         $ctx->copy($src, $rev, $dst)
 757                 unless $_dry_run;
 758
 759         $gs->fetch_all;
 760 }
 761
 762 sub cmd_find_rev {
 763         my $revision_or_hash = shift or die "SVN or git revision required ",
 764                                             "as a command-line argument\n";
 765         my $result;
 766         if ($revision_or_hash =~ /^r\d+$/) {
 767                 my $head = shift;
 768                 $head ||= 'HEAD';
 769                 my @refs;
 770                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 771                 unless ($gs) {
 772                         die "Unable to determine upstream SVN information from ",
 773                             "$head history\n";
 774                 }
 775                 my $desired_revision = substr($revision_or_hash, 1);
 776                 $result = $gs->rev_map_get($desired_revision, $uuid);
 777         } else {
 778                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 779                 $result = $rev;
 780         }
 781         print "$result\n" if $result;
 782 }
 783
 784 sub cmd_rebase {
 785         command_noisy(qw/update-index --refresh/);
 786         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 787         unless ($gs) {
 788                 die "Unable to determine upstream SVN information from ",
 789                     "working tree history\n";
 790         }
 791         if ($_dry_run) {
 792                 print "Remote Branch: " . $gs->refname . "\n";
 793                 print "SVN URL: " . $url . "\n";
 794                 return;
 795         }
 796         if (command(qw/diff-index HEAD --/)) {
 797                 print STDERR "Cannot rebase with uncommited changes:\n";
 798                 command_noisy('status');
 799                 exit 1;
 800         }
 801         unless ($_local) {
 802                 # rebase will checkout for us, so no need to do it explicitly
 803                 $_no_checkout = 'true';
 804                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 805         }
 806         command_noisy(rebase_cmd(), $gs->refname);
 807         $gs->mkemptydirs;
 808 }
 809
 810 sub cmd_show_ignore {
 811         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 812         $gs ||= Git::SVN->new;
 813         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 814         $gs->prop_walk($gs->{path}, $r, sub {
 815                 my ($gs, $path, $props) = @_;
 816                 print STDOUT "\n# $path\n";
 817                 my $s = $props->{'svn:ignore'} or return;
 818                 $s =~ s/[\r\n]+/\n/g;
 819                 $s =~ s/^\n+//;
 820                 chomp $s;
 821                 $s =~ s#^#$path#gm;
 822                 print STDOUT "$s\n";
 823         });
 824 }
 825
 826 sub cmd_show_externals {
 827         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 828         $gs ||= Git::SVN->new;
 829         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 830         $gs->prop_walk($gs->{path}, $r, sub {
 831                 my ($gs, $path, $props) = @_;
 832                 print STDOUT "\n# $path\n";
 833                 my $s = $props->{'svn:externals'} or return;
 834                 $s =~ s/[\r\n]+/\n/g;
 835                 chomp $s;
 836                 $s =~ s#^#$path#gm;
 837                 print STDOUT "$s\n";
 838         });
 839 }
 840
 841 sub cmd_create_ignore {
 842         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 843         $gs ||= Git::SVN->new;
 844         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 845         $gs->prop_walk($gs->{path}, $r, sub {
 846                 my ($gs, $path, $props) = @_;
 847                 # $path is of the form /path/to/dir/
 848                 $path = '.' . $path;
 849                 # SVN can have attributes on empty directories,
 850                 # which git won't track
 851                 mkpath([$path]) unless -d $path;
 852                 my $ignore = $path . '.gitignore';
 853                 my $s = $props->{'svn:ignore'} or return;
 854                 open(GITIGNORE, '>', $ignore)
 855                   or fatal("Failed to open `$ignore' for writing: $!");
 856                 $s =~ s/[\r\n]+/\n/g;
 857                 $s =~ s/^\n+//;
 858                 chomp $s;
 859                 # Prefix all patterns so that the ignore doesn't apply
 860                 # to sub-directories.
 861                 $s =~ s#^#/#gm;
 862                 print GITIGNORE "$s\n";
 863                 close(GITIGNORE)
 864                   or fatal("Failed to close `$ignore': $!");
 865                 command_noisy('add', '-f', $ignore);
 866         });
 867 }
 868
 869 sub cmd_mkdirs {
 870         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 871         $gs ||= Git::SVN->new;
 872         $gs->mkemptydirs($_revision);
 873 }
 874
 875 sub canonicalize_path {
 876         my ($path) = @_;
 877         my $dot_slash_added = 0;
 878         if (substr($path, 0, 1) ne "/") {
 879                 $path = "./" . $path;
 880                 $dot_slash_added = 1;
 881         }
 882         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 883         # good reason), so let's do this manually.
 884         $path =~ s#/+#/#g;
 885         $path =~ s#/\.(?:/|$)#/#g;
 886         $path =~ s#/[^/]+/\.\.##g;
 887         $path =~ s#/$##g;
 888         $path =~ s#^\./## if $dot_slash_added;
 889         $path =~ s#^/##;
 890         $path =~ s#^\.$##;
 891         return $path;
 892 }
 893
 894 sub canonicalize_url {
 895         my ($url) = @_;
 896         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 897         return $url;
 898 }
 899
 900 # get_svnprops(PATH)
 901 # ------------------
 902 # Helper for cmd_propget and cmd_proplist below.
 903 sub get_svnprops {
 904         my $path = shift;
 905         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 906         $gs ||= Git::SVN->new;
 907
 908         # prefix THE PATH by the sub-directory from which the user
 909         # invoked us.
 910         $path = $cmd_dir_prefix . $path;
 911         fatal("No such file or directory: $path") unless -e $path;
 912         my $is_dir = -d $path ? 1 : 0;
 913         $path = $gs->{path} . '/' . $path;
 914
 915         # canonicalize the path (otherwise libsvn will abort or fail to
 916         # find the file)
 917         $path = canonicalize_path($path);
 918
 919         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 920         my $props;
 921         if ($is_dir) {
 922                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 923         }
 924         else {
 925                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 926         }
 927         return $props;
 928 }
 929
 930 # cmd_propget (PROP, PATH)
 931 # ------------------------
 932 # Print the SVN property PROP for PATH.
 933 sub cmd_propget {
 934         my ($prop, $path) = @_;
 935         $path = '.' if not defined $path;
 936         usage(1) if not defined $prop;
 937         my $props = get_svnprops($path);
 938         if (not defined $props->{$prop}) {
 939                 fatal("`$path' does not have a `$prop' SVN property.");
 940         }
 941         print $props->{$prop} . "\n";
 942 }
 943
 944 # cmd_proplist (PATH)
 945 # -------------------
 946 # Print the list of SVN properties for PATH.
 947 sub cmd_proplist {
 948         my $path = shift;
 949         $path = '.' if not defined $path;
 950         my $props = get_svnprops($path);
 951         print "Properties on '$path':\n";
 952         foreach (sort keys %{$props}) {
 953                 print "  $_\n";
 954         }
 955 }
 956
 957 sub cmd_multi_init {
 958         my $url = shift;
 959         unless (defined $_trunk || @_branches || @_tags) {
 960                 usage(1);
 961         }
 962
 963         $_prefix = '' unless defined $_prefix;
 964         if (defined $url) {
 965                 $url = canonicalize_url($url);
 966                 init_subdir(@_);
 967         }
 968         do_git_init_db();
 969         if (defined $_trunk) {
 970                 $_trunk =~ s#^/+##;
 971                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
 972                 # try both old-style and new-style lookups:
 973                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 974                 unless ($gs_trunk) {
 975                         my ($trunk_url, $trunk_path) =
 976                                               complete_svn_url($url, $_trunk);
 977                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 978                                                    undef, $trunk_ref);
 979                 }
 980         }
 981         return unless @_branches || @_tags;
 982         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 983         foreach my $path (@_branches) {
 984                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
 985         }
 986         foreach my $path (@_tags) {
 987                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
 988         }
 989 }
 990
 991 sub cmd_multi_fetch {
 992         $Git::SVN::no_reuse_existing = undef;
 993         my $remotes = Git::SVN::read_all_remotes();
 994         foreach my $repo_id (sort keys %$remotes) {
 995                 if ($remotes->{$repo_id}->{url}) {
 996                         Git::SVN::fetch_all($repo_id, $remotes);
 997                 }
 998         }
 999 }
1000
1001 # this command is special because it requires no metadata
1002 sub cmd_commit_diff {
1003         my ($ta, $tb, $url) = @_;
1004         my $usage = "Usage: $0 commit-diff -r<revision> ".
1005                     "<tree-ish> <tree-ish> [<URL>]";
1006         fatal($usage) if (!defined $ta || !defined $tb);
1007         my $svn_path = '';
1008         if (!defined $url) {
1009                 my $gs = eval { Git::SVN->new };
1010                 if (!$gs) {
1011                         fatal("Needed URL or usable git-svn --id in ",
1012                               "the command-line\n", $usage);
1013                 }
1014                 $url = $gs->{url};
1015                 $svn_path = $gs->{path};
1016         }
1017         unless (defined $_revision) {
1018                 fatal("-r|--revision is a required argument\n", $usage);
1019         }
1020         if (defined $_message && defined $_file) {
1021                 fatal("Both --message/-m and --file/-F specified ",
1022                       "for the commit message.\n",
1023                       "I have no idea what you mean");
1024         }
1025         if (defined $_file) {
1026                 $_message = file_to_s($_file);
1027         } else {
1028                 $_message ||= get_commit_entry($tb)->{log};
1029         }
1030         my $ra ||= Git::SVN::Ra->new($url);
1031         my $r = $_revision;
1032         if ($r eq 'HEAD') {
1033                 $r = $ra->get_latest_revnum;
1034         } elsif ($r !~ /^\d+$/) {
1035                 die "revision argument: $r not understood by git-svn\n";
1036         }
1037         my %ed_opts = ( r => $r,
1038                         log => $_message,
1039                         ra => $ra,
1040                         tree_a => $ta,
1041                         tree_b => $tb,
1042                         editor_cb => sub { print "Committed r$_[0]\n" },
1043                         svn_path => $svn_path );
1044         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1045                 print "No changes\n$ta == $tb\n";
1046         }
1047 }
1048
1049 sub escape_uri_only {
1050         my ($uri) = @_;
1051         my @tmp;
1052         foreach (split m{/}, $uri) {
1053                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1054                 push @tmp, $_;
1055         }
1056         join('/', @tmp);
1057 }
1058
1059 sub escape_url {
1060         my ($url) = @_;
1061         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1062                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1063                 $url = "$scheme://$domain$uri";
1064         }
1065         $url;
1066 }
1067
1068 sub cmd_info {
1069         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1070         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1071         if (exists $_[1]) {
1072                 die "Too many arguments specified\n";
1073         }
1074
1075         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1076
1077         if (!$file_type && !$diff_status) {
1078                 print STDERR "svn: '$path' is not under version control\n";
1079                 exit 1;
1080         }
1081
1082         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1083         unless ($gs) {
1084                 die "Unable to determine upstream SVN information from ",
1085                     "working tree history\n";
1086         }
1087
1088         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1089         $path = "." if $path eq "";
1090
1091         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1092
1093         if ($_url) {
1094                 print escape_url($full_url), "\n";
1095                 return;
1096         }
1097
1098         my $result = "Path: $path\n";
1099         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1100         $result .= "URL: " . escape_url($full_url) . "\n";
1101
1102         eval {
1103                 my $repos_root = $gs->repos_root;
1104                 Git::SVN::remove_username($repos_root);
1105                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1106         };
1107         if ($@) {
1108                 $result .= "Repository Root: (offline)\n";
1109         }
1110         ::_req_svn();
1111         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1112                 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1113         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1114
1115         $result .= "Node Kind: " .
1116                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1117
1118         my $schedule = $diff_status eq "A"
1119                        ? "add"
1120                        : ($diff_status eq "D" ? "delete" : "normal");
1121         $result .= "Schedule: $schedule\n";
1122
1123         if ($diff_status eq "A") {
1124                 print $result, "\n";
1125                 return;
1126         }
1127
1128         my ($lc_author, $lc_rev, $lc_date_utc);
1129         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1130         my $log = command_output_pipe(@args);
1131         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1132         while (<$log>) {
1133                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1134                         $lc_author = $1;
1135                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1136                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1137                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1138                 }
1139         }
1140         close $log;
1141
1142         Git::SVN::Log::set_local_timezone();
1143
1144         $result .= "Last Changed Author: $lc_author\n";
1145         $result .= "Last Changed Rev: $lc_rev\n";
1146         $result .= "Last Changed Date: " .
1147                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1148
1149         if ($file_type ne "dir") {
1150                 my $text_last_updated_date =
1151                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1152                 $result .=
1153                     "Text Last Updated: " .
1154                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1155                     "\n";
1156                 my $checksum;
1157                 if ($diff_status eq "D") {
1158                         my ($fh, $ctx) =
1159                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1160                         if ($file_type eq "link") {
1161                                 my $file_name = <$fh>;
1162                                 $checksum = md5sum("link $file_name");
1163                         } else {
1164                                 $checksum = md5sum($fh);
1165                         }
1166                         command_close_pipe($fh, $ctx);
1167                 } elsif ($file_type eq "link") {
1168                         my $file_name =
1169                             command(qw(cat-file blob), "HEAD:$path");
1170                         $checksum =
1171                             md5sum("link " . $file_name);
1172                 } else {
1173                         open FILE, "<", $path or die $!;
1174                         $checksum = md5sum(\*FILE);
1175                         close FILE or die $!;
1176                 }
1177                 $result .= "Checksum: " . $checksum . "\n";
1178         }
1179
1180         print $result, "\n";
1181 }
1182
1183 sub cmd_reset {
1184         my $target = shift || $_revision or die "SVN revision required\n";
1185         $target = $1 if $target =~ /^r(\d+)$/;
1186         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1187         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1188         unless ($gs) {
1189                 die "Unable to determine upstream SVN information from ".
1190                     "history\n";
1191         }
1192         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1193         die "Cannot find SVN revision $target\n" unless defined($c);
1194         $gs->rev_map_set($r, $c, 'reset', $uuid);
1195         print "r$r = $c ($gs->{ref_id})\n";
1196 }
1197
1198 sub cmd_gc {
1199         if (!$can_compress) {
1200                 warn "Compress::Zlib could not be found; unhandled.log " .
1201                      "files will not be compressed.\n";
1202         }
1203         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1204 }
1205
1206 ########################### utility functions #########################
1207
1208 sub rebase_cmd {
1209         my @cmd = qw/rebase/;
1210         push @cmd, '-v' if $_verbose;
1211         push @cmd, qw/--merge/ if $_merge;
1212         push @cmd, "--strategy=$_strategy" if $_strategy;
1213         @cmd;
1214 }
1215
1216 sub post_fetch_checkout {
1217         return if $_no_checkout;
1218         my $gs = $Git::SVN::_head or return;
1219         return if verify_ref('refs/heads/master^0');
1220
1221         # look for "trunk" ref if it exists
1222         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1223         my $fetch = $remote->{fetch};
1224         if ($fetch) {
1225                 foreach my $p (keys %$fetch) {
1226                         basename($fetch->{$p}) eq 'trunk' or next;
1227                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1228                         last;
1229                 }
1230         }
1231
1232         my $valid_head = verify_ref('HEAD^0');
1233         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1234         return if ($valid_head || !verify_ref('HEAD^0'));
1235
1236         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1237         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1238         return if -f $index;
1239
1240         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1241         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1242         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1243         print STDERR "Checked out HEAD:\n  ",
1244                      $gs->full_url, " r", $gs->last_rev, "\n";
1245         $gs->mkemptydirs($gs->last_rev);
1246 }
1247
1248 sub complete_svn_url {
1249         my ($url, $path) = @_;
1250         $path =~ s#/+$##;
1251         if ($path !~ m#^[a-z\+]+://#) {
1252                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1253                         fatal("E: '$path' is not a complete URL ",
1254                               "and a separate URL is not specified");
1255                 }
1256                 return ($url, $path);
1257         }
1258         return ($path, '');
1259 }
1260
1261 sub complete_url_ls_init {
1262         my ($ra, $repo_path, $switch, $pfx) = @_;
1263         unless ($repo_path) {
1264                 print STDERR "W: $switch not specified\n";
1265                 return;
1266         }
1267         $repo_path =~ s#/+$##;
1268         if ($repo_path =~ m#^[a-z\+]+://#) {
1269                 $ra = Git::SVN::Ra->new($repo_path);
1270                 $repo_path = '';
1271         } else {
1272                 $repo_path =~ s#^/+##;
1273                 unless ($ra) {
1274                         fatal("E: '$repo_path' is not a complete URL ",
1275                               "and a separate URL is not specified");
1276                 }
1277         }
1278         my $url = $ra->{url};
1279         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1280         my $k = "svn-remote.$gs->{repo_id}.url";
1281         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1282         if ($orig_url && ($orig_url ne $gs->{url})) {
1283                 die "$k already set: $orig_url\n",
1284                     "wanted to set to: $gs->{url}\n";
1285         }
1286         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1287         my $remote_path = "$gs->{path}/$repo_path";
1288         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1289         $remote_path =~ s#/+#/#g;
1290         $remote_path =~ s#^/##g;
1291         $remote_path .= "/*" if $remote_path !~ /\*/;
1292         my ($n) = ($switch =~ /^--(\w+)/);
1293         if (length $pfx && $pfx !~ m#/$#) {
1294                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1295         }
1296         command_noisy('config',
1297                       '--add',
1298                       "svn-remote.$gs->{repo_id}.$n",
1299                       "$remote_path:refs/remotes/$pfx*" .
1300                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1301 }
1302
1303 sub verify_ref {
1304         my ($ref) = @_;
1305         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1306                                { STDERR => 0 }); };
1307 }
1308
1309 sub get_tree_from_treeish {
1310         my ($treeish) = @_;
1311         # $treeish can be a symbolic ref, too:
1312         my $type = command_oneline(qw/cat-file -t/, $treeish);
1313         my $expected;
1314         while ($type eq 'tag') {
1315                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1316         }
1317         if ($type eq 'commit') {
1318                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1319                                                     $treeish))[0];
1320                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1321                 die "Unable to get tree from $treeish\n" unless $expected;
1322         } elsif ($type eq 'tree') {
1323                 $expected = $treeish;
1324         } else {
1325                 die "$treeish is a $type, expected tree, tag or commit\n";
1326         }
1327         return $expected;
1328 }
1329
1330 sub get_commit_entry {
1331         my ($treeish) = shift;
1332         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1333         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1334         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1335         open my $log_fh, '>', $commit_editmsg or croak $!;
1336
1337         my $type = command_oneline(qw/cat-file -t/, $treeish);
1338         if ($type eq 'commit' || $type eq 'tag') {
1339                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1340                                                          $type, $treeish);
1341                 my $in_msg = 0;
1342                 my $author;
1343                 my $saw_from = 0;
1344                 my $msgbuf = "";
1345                 while (<$msg_fh>) {
1346                         if (!$in_msg) {
1347                                 $in_msg = 1 if (/^\s*$/);
1348                                 $author = $1 if (/^author (.*>)/);
1349                         } elsif (/^git-svn-id: /) {
1350                                 # skip this for now, we regenerate the
1351                                 # correct one on re-fetch anyways
1352                                 # TODO: set *:merge properties or like...
1353                         } else {
1354                                 if (/^From:/ || /^Signed-off-by:/) {
1355                                         $saw_from = 1;
1356                                 }
1357                                 $msgbuf .= $_;
1358                         }
1359                 }
1360                 $msgbuf =~ s/\s+$//s;
1361                 if ($Git::SVN::_add_author_from && defined($author)
1362                     && !$saw_from) {
1363                         $msgbuf .= "\n\nFrom: $author";
1364                 }
1365                 print $log_fh $msgbuf or croak $!;
1366                 command_close_pipe($msg_fh, $ctx);
1367         }
1368         close $log_fh or croak $!;
1369
1370         if ($_edit || ($type eq 'tree')) {
1371                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1372                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1373         }
1374         rename $commit_editmsg, $commit_msg or croak $!;
1375         {
1376                 require Encode;
1377                 # SVN requires messages to be UTF-8 when entering the repo
1378                 local $/;
1379                 open $log_fh, '<', $commit_msg or croak $!;
1380                 binmode $log_fh;
1381                 chomp($log_entry{log} = <$log_fh>);
1382
1383                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1384                 my $msg = $log_entry{log};
1385
1386                 eval { $msg = Encode::decode($enc, $msg, 1) };
1387                 if ($@) {
1388                         die "Could not decode as $enc:\n", $msg,
1389                             "\nPerhaps you need to set i18n.commitencoding\n";
1390                 }
1391
1392                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1393                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1394
1395                 $log_entry{log} = $msg;
1396
1397                 close $log_fh or croak $!;
1398         }
1399         unlink $commit_msg;
1400         \%log_entry;
1401 }
1402
1403 sub s_to_file {
1404         my ($str, $file, $mode) = @_;
1405         open my $fd,'>',$file or croak $!;
1406         print $fd $str,"\n" or croak $!;
1407         close $fd or croak $!;
1408         chmod ($mode &~ umask, $file) if (defined $mode);
1409 }
1410
1411 sub file_to_s {
1412         my $file = shift;
1413         open my $fd,'<',$file or croak "$!: file: $file\n";
1414         local $/;
1415         my $ret = <$fd>;
1416         close $fd or croak $!;
1417         $ret =~ s/\s*$//s;
1418         return $ret;
1419 }
1420
1421 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1422 sub load_authors {
1423         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1424         my $log = $cmd eq 'log';
1425         while (<$authors>) {
1426                 chomp;
1427                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1428                 my ($user, $name, $email) = ($1, $2, $3);
1429                 if ($log) {
1430                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1431                 } else {
1432                         $users{$user} = [$name, $email];
1433                 }
1434         }
1435         close $authors or croak $!;
1436 }
1437
1438 # convert GetOpt::Long specs for use by git-config
1439 sub read_git_config {
1440         my $opts = shift;
1441         my @config_only;
1442         foreach my $o (keys %$opts) {
1443                 # if we have mixedCase and a long option-only, then
1444                 # it's a config-only variable that we don't need for
1445                 # the command-line.
1446                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1447                 my $v = $opts->{$o};
1448                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1449                 $key =~ s/-//g;
1450                 my $arg = 'git config';
1451                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1452                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1453                 if (ref $v eq 'ARRAY') {
1454                         chomp(my @tmp = `$arg --get-all svn.$key`);
1455                         @$v = @tmp if @tmp;
1456                 } else {
1457                         chomp(my $tmp = `$arg --get svn.$key`);
1458                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1459                                 $$v = $tmp;
1460                         }
1461                 }
1462         }
1463         delete @$opts{@config_only} if @config_only;
1464 }
1465
1466 sub extract_metadata {
1467         my $id = shift or return (undef, undef, undef);
1468         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1469                                                         \s([a-f\d\-]+)$/ix);
1470         if (!defined $rev || !$uuid || !$url) {
1471                 # some of the original repositories I made had
1472                 # identifiers like this:
1473                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1474         }
1475         return ($url, $rev, $uuid);
1476 }
1477
1478 sub cmt_metadata {
1479         return extract_metadata((grep(/^git-svn-id: /,
1480                 command(qw/cat-file commit/, shift)))[-1]);
1481 }
1482
1483 sub cmt_sha2rev_batch {
1484         my %s2r;
1485         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1486         my $list = shift;
1487
1488         foreach my $sha (@{$list}) {
1489                 my $first = 1;
1490                 my $size = 0;
1491                 print $out $sha, "\n";
1492
1493                 while (my $line = <$in>) {
1494                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1495                                 last;
1496                         } elsif ($first &&
1497                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1498                                 $first = 0;
1499                                 $size = $1;
1500                                 next;
1501                         } elsif ($line =~ /^(git-svn-id: )/) {
1502                                 my (undef, $rev, undef) =
1503                                                       extract_metadata($line);
1504                                 $s2r{$sha} = $rev;
1505                         }
1506
1507                         $size -= length($line);
1508                         last if ($size == 0);
1509                 }
1510         }
1511
1512         command_close_bidi_pipe($pid, $in, $out, $ctx);
1513
1514         return \%s2r;
1515 }
1516
1517 sub working_head_info {
1518         my ($head, $refs) = @_;
1519         my @args = qw/log --no-color --no-decorate --first-parent
1520                       --pretty=medium/;
1521         my ($fh, $ctx) = command_output_pipe(@args, $head);
1522         my $hash;
1523         my %max;
1524         while (<$fh>) {
1525                 if ( m{^commit ($::sha1)$} ) {
1526                         unshift @$refs, $hash if $hash and $refs;
1527                         $hash = $1;
1528                         next;
1529                 }
1530                 next unless s{^\s*(git-svn-id:)}{$1};
1531                 my ($url, $rev, $uuid) = extract_metadata($_);
1532                 if (defined $url && defined $rev) {
1533                         next if $max{$url} and $max{$url} < $rev;
1534                         if (my $gs = Git::SVN->find_by_url($url)) {
1535                                 my $c = $gs->rev_map_get($rev, $uuid);
1536                                 if ($c && $c eq $hash) {
1537                                         close $fh; # break the pipe
1538                                         return ($url, $rev, $uuid, $gs);
1539                                 } else {
1540                                         $max{$url} ||= $gs->rev_map_max;
1541                                 }
1542                         }
1543                 }
1544         }
1545         command_close_pipe($fh, $ctx);
1546         (undef, undef, undef, undef);
1547 }
1548
1549 sub read_commit_parents {
1550         my ($parents, $c) = @_;
1551         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1552         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1553         @{$parents->{$c}} = split(/ /, $p);
1554 }
1555
1556 sub linearize_history {
1557         my ($gs, $refs) = @_;
1558         my %parents;
1559         foreach my $c (@$refs) {
1560                 read_commit_parents(\%parents, $c);
1561         }
1562
1563         my @linear_refs;
1564         my %skip = ();
1565         my $last_svn_commit = $gs->last_commit;
1566         foreach my $c (reverse @$refs) {
1567                 next if $c eq $last_svn_commit;
1568                 last if $skip{$c};
1569
1570                 unshift @linear_refs, $c;
1571                 $skip{$c} = 1;
1572
1573                 # we only want the first parent to diff against for linear
1574                 # history, we save the rest to inject when we finalize the
1575                 # svn commit
1576                 my $fp_a = verify_ref("$c~1");
1577                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1578                 if (!$fp_a || !$fp_b) {
1579                         die "Commit $c\n",
1580                             "has no parent commit, and therefore ",
1581                             "nothing to diff against.\n",
1582                             "You should be working from a repository ",
1583                             "originally created by git-svn\n";
1584                 }
1585                 if ($fp_a ne $fp_b) {
1586                         die "$c~1 = $fp_a, however parsing commit $c ",
1587                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1588                 }
1589
1590                 foreach my $p (@{$parents{$c}}) {
1591                         $skip{$p} = 1;
1592                 }
1593         }
1594         (\@linear_refs, \%parents);
1595 }
1596
1597 sub find_file_type_and_diff_status {
1598         my ($path) = @_;
1599         return ('dir', '') if $path eq '';
1600
1601         my $diff_output =
1602             command_oneline(qw(diff --cached --name-status --), $path) || "";
1603         my $diff_status = (split(' ', $diff_output))[0] || "";
1604
1605         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1606
1607         return (undef, undef) if !$diff_status && !$ls_tree;
1608
1609         if ($diff_status eq "A") {
1610                 return ("link", $diff_status) if -l $path;
1611                 return ("dir", $diff_status) if -d $path;
1612                 return ("file", $diff_status);
1613         }
1614
1615         my $mode = (split(' ', $ls_tree))[0] || "";
1616
1617         return ("link", $diff_status) if $mode eq "120000";
1618         return ("dir", $diff_status) if $mode eq "040000";
1619         return ("file", $diff_status);
1620 }
1621
1622 sub md5sum {
1623         my $arg = shift;
1624         my $ref = ref $arg;
1625         my $md5 = Digest::MD5->new();
1626         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1627                 $md5->addfile($arg) or croak $!;
1628         } elsif ($ref eq 'SCALAR') {
1629                 $md5->add($$arg) or croak $!;
1630         } elsif (!$ref) {
1631                 $md5->add($arg) or croak $!;
1632         } else {
1633                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1634         }
1635         return $md5->hexdigest();
1636 }
1637
1638 sub gc_directory {
1639         if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1640                 my $out_filename = $_ . ".gz";
1641                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1642                 binmode $in_fh;
1643                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1644                                 die "Unable to open $out_filename: $!\n";
1645
1646                 my $res;
1647                 while ($res = sysread($in_fh, my $str, 1024)) {
1648                         $gz->gzwrite($str) or
1649                                 die "Unable to write: ".$gz->gzerror()."!\n";
1650                 }
1651                 unlink $_ or die "unlink $File::Find::name: $!\n";
1652         } elsif (-f $_ && basename($_) eq "index") {
1653                 unlink $_ or die "unlink $_: $!\n";
1654         }
1655 }
1656
1657 package Git::SVN;
1658 use strict;
1659 use warnings;
1660 use Fcntl qw/:DEFAULT :seek/;
1661 use constant rev_map_fmt => 'NH40';
1662 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1663             $_repack $_repack_flags $_use_svm_props $_head
1664             $_use_svnsync_props $no_reuse_existing $_minimize_url
1665             $_use_log_author $_add_author_from $_localtime/;
1666 use Carp qw/croak/;
1667 use File::Path qw/mkpath/;
1668 use File::Copy qw/copy/;
1669 use IPC::Open3;
1670 use Memoize;  # core since 5.8.0, Jul 2002
1671 use Memoize::Storable;
1672
1673 my ($_gc_nr, $_gc_period);
1674
1675 # properties that we do not log:
1676 my %SKIP_PROP;
1677 BEGIN {
1678         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1679                                         svn:special svn:executable
1680                                         svn:entry:committed-rev
1681                                         svn:entry:last-author
1682                                         svn:entry:uuid
1683                                         svn:entry:committed-date/;
1684
1685         # some options are read globally, but can be overridden locally
1686         # per [svn-remote "..."] section.  Command-line options will *NOT*
1687         # override options set in an [svn-remote "..."] section
1688         no strict 'refs';
1689         for my $option (qw/follow_parent no_metadata use_svm_props
1690                            use_svnsync_props/) {
1691                 my $key = $option;
1692                 $key =~ tr/_//d;
1693                 my $prop = "-$option";
1694                 *$option = sub {
1695                         my ($self) = @_;
1696                         return $self->{$prop} if exists $self->{$prop};
1697                         my $k = "svn-remote.$self->{repo_id}.$key";
1698                         eval { command_oneline(qw/config --get/, $k) };
1699                         if ($@) {
1700                                 $self->{$prop} = ${"Git::SVN::_$option"};
1701                         } else {
1702                                 my $v = command_oneline(qw/config --bool/,$k);
1703                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1704                         }
1705                         return $self->{$prop};
1706                 }
1707         }
1708 }
1709
1710
1711 my (%LOCKFILES, %INDEX_FILES);
1712 END {
1713         unlink keys %LOCKFILES if %LOCKFILES;
1714         unlink keys %INDEX_FILES if %INDEX_FILES;
1715 }
1716
1717 sub resolve_local_globs {
1718         my ($url, $fetch, $glob_spec) = @_;
1719         return unless defined $glob_spec;
1720         my $ref = $glob_spec->{ref};
1721         my $path = $glob_spec->{path};
1722         foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
1723                 next unless m#^$ref->{regex}$#;
1724                 my $p = $1;
1725                 my $pathname = desanitize_refname($path->full_path($p));
1726                 my $refname = desanitize_refname($ref->full_path($p));
1727                 if (my $existing = $fetch->{$pathname}) {
1728                         if ($existing ne $refname) {
1729                                 die "Refspec conflict:\n",
1730                                     "existing: $existing\n",
1731                                     " globbed: $refname\n";
1732                         }
1733                         my $u = (::cmt_metadata("$refname"))[0];
1734                         $u =~ s!^\Q$url\E(/|$)!! or die
1735                           "$refname: '$url' not found in '$u'\n";
1736                         if ($pathname ne $u) {
1737                                 warn "W: Refspec glob conflict ",
1738                                      "(ref: $refname):\n",
1739                                      "expected path: $pathname\n",
1740                                      "    real path: $u\n",
1741                                      "Continuing ahead with $u\n";
1742                                 next;
1743                         }
1744                 } else {
1745                         $fetch->{$pathname} = $refname;
1746                 }
1747         }
1748 }
1749
1750 sub parse_revision_argument {
1751         my ($base, $head) = @_;
1752         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1753                 return ($base, $head);
1754         }
1755         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1756         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1757         return ($head, $head) if ($::_revision eq 'HEAD');
1758         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1759         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1760         die "revision argument: $::_revision not understood by git-svn\n";
1761 }
1762
1763 sub fetch_all {
1764         my ($repo_id, $remotes) = @_;
1765         if (ref $repo_id) {
1766                 my $gs = $repo_id;
1767                 $repo_id = undef;
1768                 $repo_id = $gs->{repo_id};
1769         }
1770         $remotes ||= read_all_remotes();
1771         my $remote = $remotes->{$repo_id} or
1772                      die "[svn-remote \"$repo_id\"] unknown\n";
1773         my $fetch = $remote->{fetch};
1774         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1775         my (@gs, @globs);
1776         my $ra = Git::SVN::Ra->new($url);
1777         my $uuid = $ra->get_uuid;
1778         my $head = $ra->get_latest_revnum;
1779
1780         # ignore errors, $head revision may not even exist anymore
1781         eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
1782         warn "W: $@\n" if $@;
1783
1784         my $base = defined $fetch ? $head : 0;
1785
1786         # read the max revs for wildcard expansion (branches/*, tags/*)
1787         foreach my $t (qw/branches tags/) {
1788                 defined $remote->{$t} or next;
1789                 push @globs, @{$remote->{$t}};
1790
1791                 my $max_rev = eval { tmp_config(qw/--int --get/,
1792                                          "svn-remote.$repo_id.${t}-maxRev") };
1793                 if (defined $max_rev && ($max_rev < $base)) {
1794                         $base = $max_rev;
1795                 } elsif (!defined $max_rev) {
1796                         $base = 0;
1797                 }
1798         }
1799
1800         if ($fetch) {
1801                 foreach my $p (sort keys %$fetch) {
1802                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1803                         my $lr = $gs->rev_map_max;
1804                         if (defined $lr) {
1805                                 $base = $lr if ($lr < $base);
1806                         }
1807                         push @gs, $gs;
1808                 }
1809         }
1810
1811         ($base, $head) = parse_revision_argument($base, $head);
1812         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1813 }
1814
1815 sub read_all_remotes {
1816         my $r = {};
1817         my $use_svm_props = eval { command_oneline(qw/config --bool
1818             svn.useSvmProps/) };
1819         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1820         my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
1821         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1822                 if (m!^(.+)\.fetch=$svn_refspec$!) {
1823                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1824                         die("svn-remote.$remote: remote ref '$remote_ref' "
1825                             . "must start with 'refs/'\n")
1826                                 unless $remote_ref =~ m{^refs/};
1827                         $local_ref = uri_decode($local_ref);
1828                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1829                         $r->{$remote}->{svm} = {} if $use_svm_props;
1830                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1831                         $r->{$1}->{svm} = {};
1832                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1833                         $r->{$1}->{url} = $2;
1834                 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
1835                         my ($remote, $t, $local_ref, $remote_ref) =
1836                                                              ($1, $2, $3, $4);
1837                         die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
1838                             . "must start with 'refs/'\n")
1839                                 unless $remote_ref =~ m{^refs/};
1840                         $local_ref = uri_decode($local_ref);
1841                         my $rs = {
1842                             t => $t,
1843                             remote => $remote,
1844                             path => Git::SVN::GlobSpec->new($local_ref, 1),
1845                             ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
1846                         if (length($rs->{ref}->{right}) != 0) {
1847                                 die "The '*' glob character must be the last ",
1848                                     "character of '$remote_ref'\n";
1849                         }
1850                         push @{ $r->{$remote}->{$t} }, $rs;
1851                 }
1852         }
1853
1854         map {
1855                 if (defined $r->{$_}->{svm}) {
1856                         my $svm;
1857                         eval {
1858                                 my $section = "svn-remote.$_";
1859                                 $svm = {
1860                                         source => tmp_config('--get',
1861                                             "$section.svm-source"),
1862                                         replace => tmp_config('--get',
1863                                             "$section.svm-replace"),
1864                                 }
1865                         };
1866                         $r->{$_}->{svm} = $svm;
1867                 }
1868         } keys %$r;
1869
1870         $r;
1871 }
1872
1873 sub init_vars {
1874         $_gc_nr = $_gc_period = 1000;
1875         if (defined $_repack || defined $_repack_flags) {
1876                warn "Repack options are obsolete; they have no effect.\n";
1877         }
1878 }
1879
1880 sub verify_remotes_sanity {
1881         return unless -d $ENV{GIT_DIR};
1882         my %seen;
1883         foreach (command(qw/config -l/)) {
1884                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1885                         if ($seen{$1}) {
1886                                 die "Remote ref refs/remote/$1 is tracked by",
1887                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1888                                     "Please resolve this ambiguity in ",
1889                                     "your git configuration file before ",
1890                                     "continuing\n";
1891                         }
1892                         $seen{$1} = $_;
1893                 }
1894         }
1895 }
1896
1897 sub find_existing_remote {
1898         my ($url, $remotes) = @_;
1899         return undef if $no_reuse_existing;
1900         my $existing;
1901         foreach my $repo_id (keys %$remotes) {
1902                 my $u = $remotes->{$repo_id}->{url} or next;
1903                 next if $u ne $url;
1904                 $existing = $repo_id;
1905                 last;
1906         }
1907         $existing;
1908 }
1909
1910 sub init_remote_config {
1911         my ($self, $url, $no_write) = @_;
1912         $url =~ s!/+$!!; # strip trailing slash
1913         my $r = read_all_remotes();
1914         my $existing = find_existing_remote($url, $r);
1915         if ($existing) {
1916                 unless ($no_write) {
1917                         print STDERR "Using existing ",
1918                                      "[svn-remote \"$existing\"]\n";
1919                 }
1920                 $self->{repo_id} = $existing;
1921         } elsif ($_minimize_url) {
1922                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1923                 $existing = find_existing_remote($min_url, $r);
1924                 if ($existing) {
1925                         unless ($no_write) {
1926                                 print STDERR "Using existing ",
1927                                              "[svn-remote \"$existing\"]\n";
1928                         }
1929                         $self->{repo_id} = $existing;
1930                 }
1931                 if ($min_url ne $url) {
1932                         unless ($no_write) {
1933                                 print STDERR "Using higher level of URL: ",
1934                                              "$url => $min_url\n";
1935                         }
1936                         my $old_path = $self->{path};
1937                         $self->{path} = $url;
1938                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1939                         if (length $old_path) {
1940                                 $self->{path} .= "/$old_path";
1941                         }
1942                         $url = $min_url;
1943                 }
1944         }
1945         my $orig_url;
1946         if (!$existing) {
1947                 # verify that we aren't overwriting anything:
1948                 $orig_url = eval {
1949                         command_oneline('config', '--get',
1950                                         "svn-remote.$self->{repo_id}.url")
1951                 };
1952                 if ($orig_url && ($orig_url ne $url)) {
1953                         die "svn-remote.$self->{repo_id}.url already set: ",
1954                             "$orig_url\nwanted to set to: $url\n";
1955                 }
1956         }
1957         my ($xrepo_id, $xpath) = find_ref($self->refname);
1958         if (!$no_write && defined $xpath) {
1959                 die "svn-remote.$xrepo_id.fetch already set to track ",
1960                     "$xpath:", $self->refname, "\n";
1961         }
1962         unless ($no_write) {
1963                 command_noisy('config',
1964                               "svn-remote.$self->{repo_id}.url", $url);
1965                 $self->{path} =~ s{^/}{};
1966                 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1967                 command_noisy('config', '--add',
1968                               "svn-remote.$self->{repo_id}.fetch",
1969                               "$self->{path}:".$self->refname);
1970         }
1971         $self->{url} = $url;
1972 }
1973
1974 sub find_by_url { # repos_root and, path are optional
1975         my ($class, $full_url, $repos_root, $path) = @_;
1976
1977         return undef unless defined $full_url;
1978         remove_username($full_url);
1979         remove_username($repos_root) if defined $repos_root;
1980         my $remotes = read_all_remotes();
1981         if (defined $full_url && defined $repos_root && !defined $path) {
1982                 $path = $full_url;
1983                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1984         }
1985         foreach my $repo_id (keys %$remotes) {
1986                 my $u = $remotes->{$repo_id}->{url} or next;
1987                 remove_username($u);
1988                 next if defined $repos_root && $repos_root ne $u;
1989
1990                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1991                 foreach my $t (qw/branches tags/) {
1992                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1993                                 resolve_local_globs($u, $fetch, $globspec);
1994                         }
1995                 }
1996                 my $p = $path;
1997                 my $rwr = rewrite_root({repo_id => $repo_id});
1998                 my $svm = $remotes->{$repo_id}->{svm}
1999                         if defined $remotes->{$repo_id}->{svm};
2000                 unless (defined $p) {
2001                         $p = $full_url;
2002                         my $z = $u;
2003                         my $prefix = '';
2004                         if ($rwr) {
2005                                 $z = $rwr;
2006                                 remove_username($z);
2007                         } elsif (defined $svm) {
2008                                 $z = $svm->{source};
2009                                 $prefix = $svm->{replace};
2010                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
2011                                 $prefix =~ s#/$##;
2012                         }
2013                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
2014                 }
2015                 foreach my $f (keys %$fetch) {
2016                         next if $f ne $p;
2017                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
2018                 }
2019         }
2020         undef;
2021 }
2022
2023 sub init {
2024         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
2025         my $self = _new($class, $repo_id, $ref_id, $path);
2026         if (defined $url) {
2027                 $self->init_remote_config($url, $no_write);
2028         }
2029         $self;
2030 }
2031
2032 sub find_ref {
2033         my ($ref_id) = @_;
2034         foreach (command(qw/config -l/)) {
2035                 next unless m!^svn-remote\.(.+)\.fetch=
2036                               \s*(.*?)\s*:\s*(.+?)\s*$!x;
2037                 my ($repo_id, $path, $ref) = ($1, $2, $3);
2038                 if ($ref eq $ref_id) {
2039                         $path = '' if ($path =~ m#^\./?#);
2040                         return ($repo_id, $path);
2041                 }
2042         }
2043         (undef, undef, undef);
2044 }
2045
2046 sub new {
2047         my ($class, $ref_id, $repo_id, $path) = @_;
2048         if (defined $ref_id && !defined $repo_id && !defined $path) {
2049                 ($repo_id, $path) = find_ref($ref_id);
2050                 if (!defined $repo_id) {
2051                         die "Could not find a \"svn-remote.*.fetch\" key ",
2052                             "in the repository configuration matching: ",
2053                             "$ref_id\n";
2054                 }
2055         }
2056         my $self = _new($class, $repo_id, $ref_id, $path);
2057         if (!defined $self->{path} || !length $self->{path}) {
2058                 my $fetch = command_oneline('config', '--get',
2059                                             "svn-remote.$repo_id.fetch",
2060                                             ":$ref_id\$") or
2061                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
2062                          "\":$ref_id\$\" in config\n";
2063                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
2064         }
2065         $self->{path} =~ s{/+}{/}g;
2066         $self->{path} =~ s{\A/}{};
2067         $self->{path} =~ s{/\z}{};
2068         $self->{url} = command_oneline('config', '--get',
2069                                        "svn-remote.$repo_id.url") or
2070                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
2071         $self->rebuild;
2072         $self;
2073 }
2074
2075 sub refname {
2076         my ($refname) = $_[0]->{ref_id} ;
2077
2078         # It cannot end with a slash /, we'll throw up on this because
2079         # SVN can't have directories with a slash in their name, either:
2080         if ($refname =~ m{/$}) {
2081                 die "ref: '$refname' ends with a trailing slash, this is ",
2082                     "not permitted by git nor Subversion\n";
2083         }
2084
2085         # It cannot have ASCII control character space, tilde ~, caret ^,
2086         # colon :, question-mark ?, asterisk *, space, or open bracket [
2087         # anywhere.
2088         #
2089         # Additionally, % must be escaped because it is used for escaping
2090         # and we want our escaped refname to be reversible
2091         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2092
2093         # no slash-separated component can begin with a dot .
2094         # /.* becomes /%2E*
2095         $refname =~ s{/\.}{/%2E}g;
2096
2097         # It cannot have two consecutive dots .. anywhere
2098         # .. becomes %2E%2E
2099         $refname =~ s{\.\.}{%2E%2E}g;
2100
2101         # trailing dots and .lock are not allowed
2102         # .$ becomes %2E and .lock becomes %2Elock
2103         $refname =~ s{\.(?=$|lock$)}{%2E};
2104
2105         # the sequence @{ is used to access the reflog
2106         # @{ becomes %40{
2107         $refname =~ s{\@\{}{%40\{}g;
2108
2109         return $refname;
2110 }
2111
2112 sub desanitize_refname {
2113         my ($refname) = @_;
2114         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2115         return $refname;
2116 }
2117
2118 sub svm_uuid {
2119         my ($self) = @_;
2120         return $self->{svm}->{uuid} if $self->svm;
2121         $self->ra;
2122         unless ($self->{svm}) {
2123                 die "SVM UUID not cached, and reading remotely failed\n";
2124         }
2125         $self->{svm}->{uuid};
2126 }
2127
2128 sub svm {
2129         my ($self) = @_;
2130         return $self->{svm} if $self->{svm};
2131         my $svm;
2132         # see if we have it in our config, first:
2133         eval {
2134                 my $section = "svn-remote.$self->{repo_id}";
2135                 $svm = {
2136                   source => tmp_config('--get', "$section.svm-source"),
2137                   uuid => tmp_config('--get', "$section.svm-uuid"),
2138                   replace => tmp_config('--get', "$section.svm-replace"),
2139                 }
2140         };
2141         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2142                 $self->{svm} = $svm;
2143         }
2144         $self->{svm};
2145 }
2146
2147 sub _set_svm_vars {
2148         my ($self, $ra) = @_;
2149         return $ra if $self->svm;
2150
2151         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2152                     "(svm:source, svm:uuid) ",
2153                     "from the following URLs:\n" );
2154         sub read_svm_props {
2155                 my ($self, $ra, $path, $r) = @_;
2156                 my $props = ($ra->get_dir($path, $r))[2];
2157                 my $src = $props->{'svm:source'};
2158                 my $uuid = $props->{'svm:uuid'};
2159                 return undef if (!$src || !$uuid);
2160
2161                 chomp($src, $uuid);
2162
2163                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2164                     or die "doesn't look right - svm:uuid is '$uuid'\n";
2165
2166                 # the '!' is used to mark the repos_root!/relative/path
2167                 $src =~ s{/?!/?}{/};
2168                 $src =~ s{/+$}{}; # no trailing slashes please
2169                 # username is of no interest
2170                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2171
2172                 my $replace = $ra->{url};
2173                 $replace .= "/$path" if length $path;
2174
2175                 my $section = "svn-remote.$self->{repo_id}";
2176                 tmp_config("$section.svm-source", $src);
2177                 tmp_config("$section.svm-replace", $replace);
2178                 tmp_config("$section.svm-uuid", $uuid);
2179                 $self->{svm} = {
2180                         source => $src,
2181                         uuid => $uuid,
2182                         replace => $replace
2183                 };
2184         }
2185
2186         my $r = $ra->get_latest_revnum;
2187         my $path = $self->{path};
2188         my %tried;
2189         while (length $path) {
2190                 unless ($tried{"$self->{url}/$path"}) {
2191                         return $ra if $self->read_svm_props($ra, $path, $r);
2192                         $tried{"$self->{url}/$path"} = 1;
2193                 }
2194                 $path =~ s#/?[^/]+$##;
2195         }
2196         die "Path: '$path' should be ''\n" if $path ne '';
2197         return $ra if $self->read_svm_props($ra, $path, $r);
2198         $tried{"$self->{url}/$path"} = 1;
2199
2200         if ($ra->{repos_root} eq $self->{url}) {
2201                 die @err, (map { "  $_\n" } keys %tried), "\n";
2202         }
2203
2204         # nope, make sure we're connected to the repository root:
2205         my $ok;
2206         my @tried_b;
2207         $path = $ra->{svn_path};
2208         $ra = Git::SVN::Ra->new($ra->{repos_root});
2209         while (length $path) {
2210                 unless ($tried{"$ra->{url}/$path"}) {
2211                         $ok = $self->read_svm_props($ra, $path, $r);
2212                         last if $ok;
2213                         $tried{"$ra->{url}/$path"} = 1;
2214                 }
2215                 $path =~ s#/?[^/]+$##;
2216         }
2217         die "Path: '$path' should be ''\n" if $path ne '';
2218         $ok ||= $self->read_svm_props($ra, $path, $r);
2219         $tried{"$ra->{url}/$path"} = 1;
2220         if (!$ok) {
2221                 die @err, (map { "  $_\n" } keys %tried), "\n";
2222         }
2223         Git::SVN::Ra->new($self->{url});
2224 }
2225
2226 sub svnsync {
2227         my ($self) = @_;
2228         return $self->{svnsync} if $self->{svnsync};
2229
2230         if ($self->no_metadata) {
2231                 die "Can't have both 'noMetadata' and ",
2232                     "'useSvnsyncProps' options set!\n";
2233         }
2234         if ($self->rewrite_root) {
2235                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2236                     "options set!\n";
2237         }
2238         if ($self->rewrite_uuid) {
2239                 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
2240                     "options set!\n";
2241         }
2242
2243         my $svnsync;
2244         # see if we have it in our config, first:
2245         eval {
2246                 my $section = "svn-remote.$self->{repo_id}";
2247
2248                 my $url = tmp_config('--get', "$section.svnsync-url");
2249                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2250                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2251
2252                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2253                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2254                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2255
2256                 $svnsync = { url => $url, uuid => $uuid }
2257         };
2258         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2259                 return $self->{svnsync} = $svnsync;
2260         }
2261
2262         my $err = "useSvnsyncProps set, but failed to read " .
2263                   "svnsync property: svn:sync-from-";
2264         my $rp = $self->ra->rev_proplist(0);
2265
2266         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2267         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2268                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2269
2270         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2271         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2272                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2273
2274         my $section = "svn-remote.$self->{repo_id}";
2275         tmp_config('--add', "$section.svnsync-uuid", $uuid);
2276         tmp_config('--add', "$section.svnsync-url", $url);
2277         return $self->{svnsync} = { url => $url, uuid => $uuid };
2278 }
2279
2280 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2281 # remote lookup (useful for 'git svn log').
2282 sub ra_uuid {
2283         my ($self) = @_;
2284         unless ($self->{ra_uuid}) {
2285                 my $key = "svn-remote.$self->{repo_id}.uuid";
2286                 my $uuid = eval { tmp_config('--get', $key) };
2287                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2288                         $self->{ra_uuid} = $uuid;
2289                 } else {
2290                         die "ra_uuid called without URL\n" unless $self->{url};
2291                         $self->{ra_uuid} = $self->ra->get_uuid;
2292                         tmp_config('--add', $key, $self->{ra_uuid});
2293                 }
2294         }
2295         $self->{ra_uuid};
2296 }
2297
2298 sub _set_repos_root {
2299         my ($self, $repos_root) = @_;
2300         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2301         $repos_root ||= $self->ra->{repos_root};
2302         tmp_config($k, $repos_root);
2303         $repos_root;
2304 }
2305
2306 sub repos_root {
2307         my ($self) = @_;
2308         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2309         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2310 }
2311
2312 sub ra {
2313         my ($self) = shift;
2314         my $ra = Git::SVN::Ra->new($self->{url});
2315         $self->_set_repos_root($ra->{repos_root});
2316         if ($self->use_svm_props && !$self->{svm}) {
2317                 if ($self->no_metadata) {
2318                         die "Can't have both 'noMetadata' and ",
2319                             "'useSvmProps' options set!\n";
2320                 } elsif ($self->use_svnsync_props) {
2321                         die "Can't have both 'useSvnsyncProps' and ",
2322                             "'useSvmProps' options set!\n";
2323                 }
2324                 $ra = $self->_set_svm_vars($ra);
2325                 $self->{-want_revprops} = 1;
2326         }
2327         $ra;
2328 }
2329
2330 # prop_walk(PATH, REV, SUB)
2331 # -------------------------
2332 # Recursively traverse PATH at revision REV and invoke SUB for each
2333 # directory that contains a SVN property.  SUB will be invoked as
2334 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2335 # Git::SVN, `path' the path to the directory where the properties
2336 # `props' were found.  The `path' will be relative to point of checkout,
2337 # that is, if url://repo/trunk is the current Git branch, and that
2338 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2339 # as `path' (note the trailing `/').
2340 sub prop_walk {
2341         my ($self, $path, $rev, $sub) = @_;
2342
2343         $path =~ s#^/##;
2344         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2345         $path =~ s#^/*#/#g;
2346         my $p = $path;
2347         # Strip the irrelevant part of the path.
2348         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2349         # Ensure the path is terminated by a `/'.
2350         $p =~ s#/*$#/#;
2351
2352         # The properties contain all the internal SVN stuff nobody
2353         # (usually) cares about.
2354         my $interesting_props = 0;
2355         foreach (keys %{$props}) {
2356                 # If it doesn't start with `svn:', it must be a
2357                 # user-defined property.
2358                 ++$interesting_props and next if $_ !~ /^svn:/;
2359                 # FIXME: Fragile, if SVN adds new public properties,
2360                 # this needs to be updated.
2361                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2362                                                  |eol-style|mime-type
2363                                                  |externals|needs-lock)$/x;
2364         }
2365         &$sub($self, $p, $props) if $interesting_props;
2366
2367         foreach (sort keys %$dirent) {
2368                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2369                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2370         }
2371 }
2372
2373 sub last_rev { ($_[0]->last_rev_commit)[0] }
2374 sub last_commit { ($_[0]->last_rev_commit)[1] }
2375
2376 # returns the newest SVN revision number and newest commit SHA1
2377 sub last_rev_commit {
2378         my ($self) = @_;
2379         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2380                 return ($self->{last_rev}, $self->{last_commit});
2381         }
2382         my $c = ::verify_ref($self->refname.'^0');
2383         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2384                 my $rev = (::cmt_metadata($c))[1];
2385                 if (defined $rev) {
2386                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2387                         return ($rev, $c);
2388                 }
2389         }
2390         my $map_path = $self->map_path;
2391         unless (-e $map_path) {
2392                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2393                 return (undef, undef);
2394         }
2395         my ($rev, $commit) = $self->rev_map_max(1);
2396         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2397         return ($rev, $commit);
2398 }
2399
2400 sub get_fetch_range {
2401         my ($self, $min, $max) = @_;
2402         $max ||= $self->ra->get_latest_revnum;
2403         $min ||= $self->rev_map_max;
2404         (++$min, $max);
2405 }
2406
2407 sub tmp_config {
2408         my (@args) = @_;
2409         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2410         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2411         if (! -f $config && -f $old_def_config) {
2412                 rename $old_def_config, $config or
2413                        die "Failed rename $old_def_config => $config: $!\n";
2414         }
2415         my $old_config = $ENV{GIT_CONFIG};
2416         $ENV{GIT_CONFIG} = $config;
2417         $@ = undef;
2418         my @ret = eval {
2419                 unless (-f $config) {
2420                         mkfile($config);
2421                         open my $fh, '>', $config or
2422                             die "Can't open $config: $!\n";
2423                         print $fh "; This file is used internally by ",
2424                                   "git-svn\n" or die
2425                                   "Couldn't write to $config: $!\n";
2426                         print $fh "; You should not have to edit it\n" or
2427                               die "Couldn't write to $config: $!\n";
2428                         close $fh or die "Couldn't close $config: $!\n";
2429                 }
2430                 command('config', @args);
2431         };
2432         my $err = $@;
2433         if (defined $old_config) {
2434                 $ENV{GIT_CONFIG} = $old_config;
2435         } else {
2436                 delete $ENV{GIT_CONFIG};
2437         }
2438         die $err if $err;
2439         wantarray ? @ret : $ret[0];
2440 }
2441
2442 sub tmp_index_do {
2443         my ($self, $sub) = @_;
2444         my $old_index = $ENV{GIT_INDEX_FILE};
2445         $ENV{GIT_INDEX_FILE} = $self->{index};
2446         $@ = undef;
2447         my @ret = eval {
2448                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2449                 mkpath([$dir]) unless -d $dir;
2450                 &$sub;
2451         };
2452         my $err = $@;
2453         if (defined $old_index) {
2454                 $ENV{GIT_INDEX_FILE} = $old_index;
2455         } else {
2456                 delete $ENV{GIT_INDEX_FILE};
2457         }
2458         die $err if $err;
2459         wantarray ? @ret : $ret[0];
2460 }
2461
2462 sub assert_index_clean {
2463         my ($self, $treeish) = @_;
2464
2465         $self->tmp_index_do(sub {
2466                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2467                 my $x = command_oneline('write-tree');
2468                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2469                            /^tree ($::sha1)/mo);
2470                 return if $y eq $x;
2471
2472                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2473                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2474                 command_noisy('read-tree', $treeish);
2475                 $x = command_oneline('write-tree');
2476                 if ($y ne $x) {
2477                         ::fatal "trees ($treeish) $y != $x\n",
2478                                 "Something is seriously wrong...";
2479                 }
2480         });
2481 }
2482
2483 sub get_commit_parents {
2484         my ($self, $log_entry) = @_;
2485         my (%seen, @ret, @tmp);
2486         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2487         if (my $ip = $self->{inject_parents}) {
2488                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2489                         push @tmp, $commit;
2490                 }
2491         }
2492         if (my $cur = ::verify_ref($self->refname.'^0')) {
2493                 push @tmp, $cur;
2494         }
2495         if (my $ipd = $self->{inject_parents_dcommit}) {
2496                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2497                         push @tmp, @$commit;
2498                 }
2499         }
2500         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2501         while (my $p = shift @tmp) {
2502                 next if $seen{$p};
2503                 $seen{$p} = 1;
2504                 push @ret, $p;
2505         }
2506         @ret;
2507 }
2508
2509 sub rewrite_root {
2510         my ($self) = @_;
2511         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2512         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2513         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2514         if ($rwr) {
2515                 $rwr =~ s#/+$##;
2516                 if ($rwr !~ m#^[a-z\+]+://#) {
2517                         die "$rwr is not a valid URL (key: $k)\n";
2518                 }
2519         }
2520         $self->{-rewrite_root} = $rwr;
2521 }
2522
2523 sub rewrite_uuid {
2524         my ($self) = @_;
2525         return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
2526         my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
2527         my $rwid = eval { command_oneline(qw/config --get/, $k) };
2528         if ($rwid) {
2529                 $rwid =~ s#/+$##;
2530                 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
2531                         die "$rwid is not a valid UUID (key: $k)\n";
2532                 }
2533         }
2534         $self->{-rewrite_uuid} = $rwid;
2535 }
2536
2537 sub metadata_url {
2538         my ($self) = @_;
2539         ($self->rewrite_root || $self->{url}) .
2540            (length $self->{path} ? '/' . $self->{path} : '');
2541 }
2542
2543 sub full_url {
2544         my ($self) = @_;
2545         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2546 }
2547
2548
2549 sub set_commit_header_env {
2550         my ($log_entry) = @_;
2551         my %env;
2552         foreach my $ned (qw/NAME EMAIL DATE/) {
2553                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2554                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2555                 }
2556         }
2557
2558         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2559         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2560         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2561
2562         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2563                                                 ? $log_entry->{commit_name}
2564                                                 : $log_entry->{name};
2565         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2566                                                 ? $log_entry->{commit_email}
2567                                                 : $log_entry->{email};
2568         \%env;
2569 }
2570
2571 sub restore_commit_header_env {
2572         my ($env) = @_;
2573         foreach my $ned (qw/NAME EMAIL DATE/) {
2574                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2575                         my $k = "GIT_${ac}_${ned}";
2576                         if (defined $env->{$k}) {
2577                                 $ENV{$k} = $env->{$k};
2578                         } else {
2579                                 delete $ENV{$k};
2580                         }
2581                 }
2582         }
2583 }
2584
2585 sub gc {
2586         command_noisy('gc', '--auto');
2587 };
2588
2589 sub do_git_commit {
2590         my ($self, $log_entry) = @_;
2591         my $lr = $self->last_rev;
2592         if (defined $lr && $lr >= $log_entry->{revision}) {
2593                 die "Last fetched revision of ", $self->refname,
2594                     " was r$lr, but we are about to fetch: ",
2595                     "r$log_entry->{revision}!\n";
2596         }
2597         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2598                 croak "$log_entry->{revision} = $c already exists! ",
2599                       "Why are we refetching it?\n";
2600         }
2601         my $old_env = set_commit_header_env($log_entry);
2602         my $tree = $log_entry->{tree};
2603         if (!defined $tree) {
2604                 $tree = $self->tmp_index_do(sub {
2605                                             command_oneline('write-tree') });
2606         }
2607         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2608
2609         my @exec = ('git', 'commit-tree', $tree);
2610         foreach ($self->get_commit_parents($log_entry)) {
2611                 push @exec, '-p', $_;
2612         }
2613         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2614                                                                    or croak $!;
2615         binmode $msg_fh;
2616
2617         # we always get UTF-8 from SVN, but we may want our commits in
2618         # a different encoding.
2619         if (my $enc = Git::config('i18n.commitencoding')) {
2620                 require Encode;
2621                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2622         }
2623         print $msg_fh $log_entry->{log} or croak $!;
2624         restore_commit_header_env($old_env);
2625         unless ($self->no_metadata) {
2626                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2627                               or croak $!;
2628         }
2629         $msg_fh->flush == 0 or croak $!;
2630         close $msg_fh or croak $!;
2631         chomp(my $commit = do { local $/; <$out_fh> });
2632         close $out_fh or croak $!;
2633         waitpid $pid, 0;
2634         croak $? if $?;
2635         if ($commit !~ /^$::sha1$/o) {
2636                 die "Failed to commit, invalid sha1: $commit\n";
2637         }
2638
2639         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2640
2641         $self->{last_rev} = $log_entry->{revision};
2642         $self->{last_commit} = $commit;
2643         print "r$log_entry->{revision}" unless $::_q > 1;
2644         if (defined $log_entry->{svm_revision}) {
2645                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2646                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2647                                    0, $self->svm_uuid);
2648         }
2649         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2650         if (--$_gc_nr == 0) {
2651                 $_gc_nr = $_gc_period;
2652                 gc();
2653         }
2654         return $commit;
2655 }
2656
2657 sub match_paths {
2658         my ($self, $paths, $r) = @_;
2659         return 1 if $self->{path} eq '';
2660         if (my $path = $paths->{"/$self->{path}"}) {
2661                 return ($path->{action} eq 'D') ? 0 : 1;
2662         }
2663         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2664         if (grep /$self->{path_regex}/, keys %$paths) {
2665                 return 1;
2666         }
2667         my $c = '';
2668         foreach (split m#/#, $self->{path}) {
2669                 $c .= "/$_";
2670                 next unless ($paths->{$c} &&
2671                              ($paths->{$c}->{action} =~ /^[AR]$/));
2672                 if ($self->ra->check_path($self->{path}, $r) ==
2673                     $SVN::Node::dir) {
2674                         return 1;
2675                 }
2676         }
2677         return 0;
2678 }
2679
2680 sub find_parent_branch {
2681         my ($self, $paths, $rev) = @_;
2682         return undef unless $self->follow_parent;
2683         unless (defined $paths) {
2684                 my $err_handler = $SVN::Error::handler;
2685                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2686                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2687                                    sub { $paths = $_[0] });
2688                 $SVN::Error::handler = $err_handler;
2689         }
2690         return undef unless defined $paths;
2691
2692         # look for a parent from another branch:
2693         my @b_path_components = split m#/#, $self->{path};
2694         my @a_path_components;
2695         my $i;
2696         while (@b_path_components) {
2697                 $i = $paths->{'/'.join('/', @b_path_components)};
2698                 last if $i && defined $i->{copyfrom_path};
2699                 unshift(@a_path_components, pop(@b_path_components));
2700         }
2701         return undef unless defined $i && defined $i->{copyfrom_path};
2702         my $branch_from = $i->{copyfrom_path};
2703         if (@a_path_components) {
2704                 print STDERR "branch_from: $branch_from => ";
2705                 $branch_from .= '/'.join('/', @a_path_components);
2706                 print STDERR $branch_from, "\n";
2707         }
2708         my $r = $i->{copyfrom_rev};
2709         my $repos_root = $self->ra->{repos_root};
2710         my $url = $self->ra->{url};
2711         my $new_url = $url . $branch_from;
2712         print STDERR  "Found possible branch point: ",
2713                       "$new_url => ", $self->full_url, ", $r\n"
2714                       unless $::_q > 1;
2715         $branch_from =~ s#^/##;
2716         my $gs = $self->other_gs($new_url, $url,
2717                                  $branch_from, $r, $self->{ref_id});
2718         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2719         {
2720                 my ($base, $head);
2721                 if (!defined $r0 || !defined $parent) {
2722                         ($base, $head) = parse_revision_argument(0, $r);
2723                 } else {
2724                         if ($r0 < $r) {
2725                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2726                                         0, 1, sub { $base = $_[1] - 1 });
2727                         }
2728                 }
2729                 if (defined $base && $base <= $r) {
2730                         $gs->fetch($base, $r);
2731                 }
2732                 ($r0, $parent) = $gs->find_rev_before($r, 1);
2733         }
2734         if (defined $r0 && defined $parent) {
2735                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
2736                              unless $::_q > 1;
2737                 my $ed;
2738                 if ($self->ra->can_do_switch) {
2739                         $self->assert_index_clean($parent);
2740                         print STDERR "Following parent with do_switch\n"
2741                                      unless $::_q > 1;
2742                         # do_switch works with svn/trunk >= r22312, but that
2743                         # is not included with SVN 1.4.3 (the latest version
2744                         # at the moment), so we can't rely on it
2745                         $self->{last_rev} = $r0;
2746                         $self->{last_commit} = $parent;
2747                         $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2748                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2749                                               $self->full_url, $ed)
2750                           or die "SVN connection failed somewhere...\n";
2751                 } elsif ($self->ra->trees_match($new_url, $r0,
2752                                                 $self->full_url, $rev)) {
2753                         print STDERR "Trees match:\n",
2754                                      "  $new_url\@$r0\n",
2755                                      "  ${\$self->full_url}\@$rev\n",
2756                                      "Following parent with no changes\n"
2757                                      unless $::_q > 1;
2758                         $self->tmp_index_do(sub {
2759                             command_noisy('read-tree', $parent);
2760                         });
2761                         $self->{last_commit} = $parent;
2762                 } else {
2763                         print STDERR "Following parent with do_update\n"
2764                                      unless $::_q > 1;
2765                         $ed = SVN::Git::Fetcher->new($self);
2766                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2767                           or die "SVN connection failed somewhere...\n";
2768                 }
2769                 print STDERR "Successfully followed parent\n" unless $::_q > 1;
2770                 return $self->make_log_entry($rev, [$parent], $ed);
2771         }
2772         return undef;
2773 }
2774
2775 sub do_fetch {
2776         my ($self, $paths, $rev) = @_;
2777         my $ed;
2778         my ($last_rev, @parents);
2779         if (my $lc = $self->last_commit) {
2780                 # we can have a branch that was deleted, then re-added
2781                 # under the same name but copied from another path, in
2782                 # which case we'll have multiple parents (we don't
2783                 # want to break the original ref, nor lose copypath info):
2784                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2785                         push @{$log_entry->{parents}}, $lc;
2786                         return $log_entry;
2787                 }
2788                 $ed = SVN::Git::Fetcher->new($self);
2789                 $last_rev = $self->{last_rev};
2790                 $ed->{c} = $lc;
2791                 @parents = ($lc);
2792         } else {
2793                 $last_rev = $rev;
2794                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2795                         return $log_entry;
2796                 }
2797                 $ed = SVN::Git::Fetcher->new($self);
2798         }
2799         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2800                 die "SVN connection failed somewhere...\n";
2801         }
2802         $self->make_log_entry($rev, \@parents, $ed);
2803 }
2804
2805 sub mkemptydirs {
2806         my ($self, $r) = @_;
2807
2808         sub scan {
2809                 my ($r, $empty_dirs, $line) = @_;
2810                 if (defined $r && $line =~ /^r(\d+)$/) {
2811                         return 0 if $1 > $r;
2812                 } elsif ($line =~ /^  \+empty_dir: (.+)$/) {
2813                         $empty_dirs->{$1} = 1;
2814                 } elsif ($line =~ /^  \-empty_dir: (.+)$/) {
2815                         my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
2816                         delete @$empty_dirs{@d};
2817                 }
2818                 1; # continue
2819         };
2820
2821         my %empty_dirs = ();
2822         my $gz_file = "$self->{dir}/unhandled.log.gz";
2823         if (-f $gz_file) {
2824                 if (!$can_compress) {
2825                         warn "Compress::Zlib could not be found; ",
2826                              "empty directories in $gz_file will not be read\n";
2827                 } else {
2828                         my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
2829                                 die "Unable to open $gz_file: $!\n";
2830                         my $line;
2831                         while ($gz->gzreadline($line) > 0) {
2832                                 scan($r, \%empty_dirs, $line) or last;
2833                         }
2834                         $gz->gzclose;
2835                 }
2836         }
2837
2838         if (open my $fh, '<', "$self->{dir}/unhandled.log") {
2839                 binmode $fh or croak "binmode: $!";
2840                 while (<$fh>) {
2841                         scan($r, \%empty_dirs, $_) or last;
2842                 }
2843                 close $fh;
2844         }
2845
2846         my $strip = qr/\A\Q$self->{path}\E(?:\/|$)/;
2847         foreach my $d (sort keys %empty_dirs) {
2848                 $d = uri_decode($d);
2849                 $d =~ s/$strip//;
2850                 next unless length($d);
2851                 next if -d $d;
2852                 if (-e $d) {
2853                         warn "$d exists but is not a directory\n";
2854                 } else {
2855                         print "creating empty directory: $d\n";
2856                         mkpath([$d]);
2857                 }
2858         }
2859 }
2860
2861 sub get_untracked {
2862         my ($self, $ed) = @_;
2863         my @out;
2864         my $h = $ed->{empty};
2865         foreach (sort keys %$h) {
2866                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2867                 push @out, "  $act: " . uri_encode($_);
2868                 warn "W: $act: $_\n";
2869         }
2870         foreach my $t (qw/dir_prop file_prop/) {
2871                 $h = $ed->{$t} or next;
2872                 foreach my $path (sort keys %$h) {
2873                         my $ppath = $path eq '' ? '.' : $path;
2874                         foreach my $prop (sort keys %{$h->{$path}}) {
2875                                 next if $SKIP_PROP{$prop};
2876                                 my $v = $h->{$path}->{$prop};
2877                                 my $t_ppath_prop = "$t: " .
2878                                                     uri_encode($ppath) . ' ' .
2879                                                     uri_encode($prop);
2880                                 if (defined $v) {
2881                                         push @out, "  +$t_ppath_prop " .
2882                                                    uri_encode($v);
2883                                 } else {
2884                                         push @out, "  -$t_ppath_prop";
2885                                 }
2886                         }
2887                 }
2888         }
2889         foreach my $t (qw/absent_file absent_directory/) {
2890                 $h = $ed->{$t} or next;
2891                 foreach my $parent (sort keys %$h) {
2892                         foreach my $path (sort @{$h->{$parent}}) {
2893                                 push @out, "  $t: " .
2894                                            uri_encode("$parent/$path");
2895                                 warn "W: $t: $parent/$path ",
2896                                      "Insufficient permissions?\n";
2897                         }
2898                 }
2899         }
2900         \@out;
2901 }
2902
2903 # parse_svn_date(DATE)
2904 # --------------------
2905 # Given a date (in UTC) from Subversion, return a string in the format
2906 # "<TZ Offset> <local date/time>" that Git will use.
2907 #
2908 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2909 # is true we'll convert it to the local timezone instead.
2910 sub parse_svn_date {
2911         my $date = shift || return '+0000 1970-01-01 00:00:00';
2912         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2913                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2914                                          croak "Unable to parse date: $date\n";
2915         my $parsed_date;    # Set next.
2916
2917         if ($Git::SVN::_localtime) {
2918                 # Translate the Subversion datetime to an epoch time.
2919                 # Begin by switching ourselves to $date's timezone, UTC.
2920                 my $old_env_TZ = $ENV{TZ};
2921                 $ENV{TZ} = 'UTC';
2922
2923                 my $epoch_in_UTC =
2924                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2925
2926                 # Determine our local timezone (including DST) at the
2927                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
2928                 # value of TZ, if any, at the time we were run.
2929                 if (defined $Git::SVN::Log::TZ) {
2930                         $ENV{TZ} = $Git::SVN::Log::TZ;
2931                 } else {
2932                         delete $ENV{TZ};
2933                 }
2934
2935                 my $our_TZ =
2936                     POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2937
2938                 # This converts $epoch_in_UTC into our local timezone.
2939                 my ($sec, $min, $hour, $mday, $mon, $year,
2940                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2941
2942                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2943                                        $our_TZ, $year + 1900, $mon + 1,
2944                                        $mday, $hour, $min, $sec);
2945
2946                 # Reset us to the timezone in effect when we entered
2947                 # this routine.
2948                 if (defined $old_env_TZ) {
2949                         $ENV{TZ} = $old_env_TZ;
2950                 } else {
2951                         delete $ENV{TZ};
2952                 }
2953         } else {
2954                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2955         }
2956
2957         return $parsed_date;
2958 }
2959
2960 sub other_gs {
2961         my ($self, $new_url, $url,
2962             $branch_from, $r, $old_ref_id) = @_;
2963         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2964         unless ($gs) {
2965                 my $ref_id = $old_ref_id;
2966                 $ref_id =~ s/\@\d+-*$//;
2967                 $ref_id .= "\@$r";
2968                 # just grow a tail if we're not unique enough :x
2969                 $ref_id .= '-' while find_ref($ref_id);
2970                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2971                 if ($u =~ s#^\Q$url\E(/|$)##) {
2972                         $p = $u;
2973                         $u = $url;
2974                         $repo_id = $self->{repo_id};
2975                 }
2976                 while (1) {
2977                         # It is possible to tag two different subdirectories at
2978                         # the same revision.  If the url for an existing ref
2979                         # does not match, we must either find a ref with a
2980                         # matching url or create a new ref by growing a tail.
2981                         $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2982                         my (undef, $max_commit) = $gs->rev_map_max(1);
2983                         last if (!$max_commit);
2984                         my ($url) = ::cmt_metadata($max_commit);
2985                         last if ($url eq $gs->full_url);
2986                         $ref_id .= '-';
2987                 }
2988                 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
2989         }
2990         $gs
2991 }
2992
2993 sub call_authors_prog {
2994         my ($orig_author) = @_;
2995         $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
2996         my $author = `$::_authors_prog $orig_author`;
2997         if ($? != 0) {
2998                 die "$::_authors_prog failed with exit code $?\n"
2999         }
3000         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
3001                 my ($name, $email) = ($1, $2);
3002                 $email = undef if length $2 == 0;
3003                 return [$name, $email];
3004         } else {
3005                 die "Author: $orig_author: $::_authors_prog returned "
3006                         . "invalid author format: $author\n";
3007         }
3008 }
3009
3010 sub check_author {
3011         my ($author) = @_;
3012         if (!defined $author || length $author == 0) {
3013                 $author = '(no author)';
3014         }
3015         if (!defined $::users{$author}) {
3016                 if (defined $::_authors_prog) {
3017                         $::users{$author} = call_authors_prog($author);
3018                 } elsif (defined $::_authors) {
3019                         die "Author: $author not defined in $::_authors file\n";
3020                 }
3021         }
3022         $author;
3023 }
3024
3025 sub find_extra_svk_parents {
3026         my ($self, $ed, $tickets, $parents) = @_;
3027         # aha!  svk:merge property changed...
3028         my @tickets = split "\n", $tickets;
3029         my @known_parents;
3030         for my $ticket ( @tickets ) {
3031                 my ($uuid, $path, $rev) = split /:/, $ticket;
3032                 if ( $uuid eq $self->ra_uuid ) {
3033                         my $url = $self->{url};
3034                         my $repos_root = $url;
3035                         my $branch_from = $path;
3036                         $branch_from =~ s{^/}{};
3037                         my $gs = $self->other_gs($repos_root."/".$branch_from,
3038                                                  $url,
3039                                                  $branch_from,
3040                                                  $rev,
3041                                                  $self->{ref_id});
3042                         if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
3043                                 # wahey!  we found it, but it might be
3044                                 # an old one (!)
3045                                 push @known_parents, [ $rev, $commit ];
3046                         }
3047                 }
3048         }
3049         # Ordering matters; highest-numbered commit merge tickets
3050         # first, as they may account for later merge ticket additions
3051         # or changes.
3052         @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
3053         for my $parent ( @known_parents ) {
3054                 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
3055                 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3056                 my $new;
3057                 while ( <$msg_fh> ) {
3058                         $new=1;last;
3059                 }
3060                 command_close_pipe($msg_fh, $ctx);
3061                 if ( $new ) {
3062                         print STDERR
3063                             "Found merge parent (svk:merge ticket): $parent\n";
3064                         push @$parents, $parent;
3065                 }
3066         }
3067 }
3068
3069 sub lookup_svn_merge {
3070         my $uuid = shift;
3071         my $url = shift;
3072         my $merge = shift;
3073
3074         my ($source, $revs) = split ":", $merge;
3075         my $path = $source;
3076         $path =~ s{^/}{};
3077         my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
3078         if ( !$gs ) {
3079                 warn "Couldn't find revmap for $url$source\n";
3080                 return;
3081         }
3082         my @ranges = split ",", $revs;
3083         my ($tip, $tip_commit);
3084         my @merged_commit_ranges;
3085         # find the tip
3086         for my $range ( @ranges ) {
3087                 my ($bottom, $top) = split "-", $range;
3088                 $top ||= $bottom;
3089                 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
3090                 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
3091
3092                 unless ($top_commit and $bottom_commit) {
3093                         warn "W:unknown path/rev in svn:mergeinfo "
3094                                 ."dirprop: $source:$range\n";
3095                         next;
3096                 }
3097
3098                 push @merged_commit_ranges,
3099                         "$bottom_commit^..$top_commit";
3100
3101                 if ( !defined $tip or $top > $tip ) {
3102                         $tip = $top;
3103                         $tip_commit = $top_commit;
3104                 }
3105         }
3106         return ($tip_commit, @merged_commit_ranges);
3107 }
3108
3109 sub _rev_list {
3110         my ($msg_fh, $ctx) = command_output_pipe(
3111                 "rev-list", @_,
3112                );
3113         my @rv;
3114         while ( <$msg_fh> ) {
3115                 chomp;
3116                 push @rv, $_;
3117         }
3118         command_close_pipe($msg_fh, $ctx);
3119         @rv;
3120 }
3121
3122 sub check_cherry_pick {
3123         my $base = shift;
3124         my $tip = shift;
3125         my $parents = shift;
3126         my @ranges = @_;
3127         my %commits = map { $_ => 1 }
3128                 _rev_list("--no-merges", $tip, "--not", $base, @$parents);
3129         for my $range ( @ranges ) {
3130                 delete @commits{_rev_list($range)};
3131         }
3132         for my $commit (keys %commits) {
3133                 if (has_no_changes($commit)) {
3134                         delete $commits{$commit};
3135                 }
3136         }
3137         return (keys %commits);
3138 }
3139
3140 sub has_no_changes {
3141         my $commit = shift;
3142
3143         my @revs = split / /, command_oneline(
3144                 qw(rev-list --parents -1 -m), $commit);
3145
3146         # Commits with no parents, e.g. the start of a partial branch,
3147         # have changes by definition.
3148         return 1 if (@revs < 2);
3149
3150         # Commits with multiple parents, e.g a merge, have no changes
3151         # by definition.
3152         return 0 if (@revs > 2);
3153
3154         return (command_oneline("rev-parse", "$commit^{tree}") eq
3155                 command_oneline("rev-parse", "$commit~1^{tree}"));
3156 }
3157
3158 # The GIT_DIR environment variable is not always set until after the command
3159 # line arguments are processed, so we can't memoize in a BEGIN block.
3160 {
3161         my $memoized = 0;
3162
3163         sub memoize_svn_mergeinfo_functions {
3164                 return if $memoized;
3165                 $memoized = 1;
3166
3167                 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
3168                 mkpath([$cache_path]) unless -d $cache_path;
3169
3170                 tie my %lookup_svn_merge_cache => 'Memoize::Storable',
3171                     "$cache_path/lookup_svn_merge.db", 'nstore';
3172                 memoize 'lookup_svn_merge',
3173                         SCALAR_CACHE => 'FAULT',
3174                         LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
3175                 ;
3176
3177                 tie my %check_cherry_pick_cache => 'Memoize::Storable',
3178                     "$cache_path/check_cherry_pick.db", 'nstore';
3179                 memoize 'check_cherry_pick',
3180                         SCALAR_CACHE => 'FAULT',
3181                         LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
3182                 ;
3183
3184                 tie my %has_no_changes_cache => 'Memoize::Storable',
3185                     "$cache_path/has_no_changes.db", 'nstore';
3186                 memoize 'has_no_changes',
3187                         SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
3188                         LIST_CACHE => 'FAULT',
3189                 ;
3190         }
3191
3192         sub unmemoize_svn_mergeinfo_functions {
3193                 return if not $memoized;
3194                 $memoized = 0;
3195
3196                 Memoize::unmemoize 'lookup_svn_merge';
3197                 Memoize::unmemoize 'check_cherry_pick';
3198                 Memoize::unmemoize 'has_no_changes';
3199         }
3200 }
3201
3202 END {
3203         # Force cache writeout explicitly instead of waiting for
3204         # global destruction to avoid segfault in Storable:
3205         # http://rt.cpan.org/Public/Bug/Display.html?id=36087
3206         unmemoize_svn_mergeinfo_functions();
3207 }
3208
3209 sub parents_exclude {
3210         my $parents = shift;
3211         my @commits = @_;
3212         return unless @commits;
3213
3214         my @excluded;
3215         my $excluded;
3216         do {
3217                 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
3218                 $excluded = command_oneline(@cmd);
3219                 if ( $excluded ) {
3220                         my @new;
3221                         my $found;
3222                         for my $commit ( @commits ) {
3223                                 if ( $commit eq $excluded ) {
3224                                         push @excluded, $commit;
3225                                         $found++;
3226                                         last;
3227                                 }
3228                                 else {
3229                                         push @new, $commit;
3230                                 }
3231                         }
3232                         die "saw commit '$excluded' in rev-list output, "
3233                                 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
3234                                         unless $found;
3235                         @commits = @new;
3236                 }
3237         }
3238                 while ($excluded and @commits);
3239
3240         return @excluded;
3241 }
3242
3243
3244 # note: this function should only be called if the various dirprops
3245 # have actually changed
3246 sub find_extra_svn_parents {
3247         my ($self, $ed, $mergeinfo, $parents) = @_;
3248         # aha!  svk:merge property changed...
3249
3250         memoize_svn_mergeinfo_functions();
3251
3252         # We first search for merged tips which are not in our
3253         # history.  Then, we figure out which git revisions are in
3254         # that tip, but not this revision.  If all of those revisions
3255         # are now marked as merge, we can add the tip as a parent.
3256         my @merges = split "\n", $mergeinfo;
3257         my @merge_tips;
3258         my $url = $self->{url};
3259         my $uuid = $self->ra_uuid;
3260         my %ranges;
3261         for my $merge ( @merges ) {
3262                 my ($tip_commit, @ranges) =
3263                         lookup_svn_merge( $uuid, $url, $merge );
3264                 unless (!$tip_commit or
3265                                 grep { $_ eq $tip_commit } @$parents ) {
3266                         push @merge_tips, $tip_commit;
3267                         $ranges{$tip_commit} = \@ranges;
3268                 } else {
3269                         push @merge_tips, undef;
3270                 }
3271         }
3272
3273         my %excluded = map { $_ => 1 }
3274                 parents_exclude($parents, grep { defined } @merge_tips);
3275
3276         # check merge tips for new parents
3277         my @new_parents;
3278         for my $merge_tip ( @merge_tips ) {
3279                 my $spec = shift @merges;
3280                 next unless $merge_tip and $excluded{$merge_tip};
3281
3282                 my $ranges = $ranges{$merge_tip};
3283
3284                 # check out 'new' tips
3285                 my $merge_base;
3286                 eval {
3287                         $merge_base = command_oneline(
3288                                 "merge-base",
3289                                 @$parents, $merge_tip,
3290                         );
3291                 };
3292                 if ($@) {
3293                         die "An error occurred during merge-base"
3294                                 unless $@->isa("Git::Error::Command");
3295
3296                         warn "W: Cannot find common ancestor between ".
3297                              "@$parents and $merge_tip. Ignoring merge info.\n";
3298                         next;
3299                 }
3300
3301                 # double check that there are no missing non-merge commits
3302                 my (@incomplete) = check_cherry_pick(
3303                         $merge_base, $merge_tip,
3304                         $parents,
3305                         @$ranges,
3306                        );
3307
3308                 if ( @incomplete ) {
3309                         warn "W:svn cherry-pick ignored ($spec) - missing "
3310                                 .@incomplete." commit(s) (eg $incomplete[0])\n";
3311                 } else {
3312                         warn
3313                                 "Found merge parent (svn:mergeinfo prop): ",
3314                                         $merge_tip, "\n";
3315                         push @new_parents, $merge_tip;
3316                 }
3317         }
3318
3319         # cater for merges which merge commits from multiple branches
3320         if ( @new_parents > 1 ) {
3321                 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
3322                         for ( my $j = 0; $j <= $#new_parents; $j++ ) {
3323                                 next if $i == $j;
3324                                 next unless $new_parents[$i];
3325                                 next unless $new_parents[$j];
3326                                 my $revs = command_oneline(
3327                                         "rev-list", "-1",
3328                                         "$new_parents[$i]..$new_parents[$j]",
3329                                        );
3330                                 if ( !$revs ) {
3331                                         undef($new_parents[$j]);
3332                                 }
3333                         }
3334                 }
3335         }
3336         push @$parents, grep { defined } @new_parents;
3337 }
3338
3339 sub make_log_entry {
3340         my ($self, $rev, $parents, $ed) = @_;
3341         my $untracked = $self->get_untracked($ed);
3342
3343         my @parents = @$parents;
3344         my $ps = $ed->{path_strip} || "";
3345         for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
3346                 my $props = $ed->{dir_prop}{$path};
3347                 if ( $props->{"svk:merge"} ) {
3348                         $self->find_extra_svk_parents
3349                                 ($ed, $props->{"svk:merge"}, \@parents);
3350                 }
3351                 if ( $props->{"svn:mergeinfo"} ) {
3352                         $self->find_extra_svn_parents
3353                                 ($ed,
3354                                  $props->{"svn:mergeinfo"},
3355                                  \@parents);
3356                 }
3357         }
3358
3359         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
3360         print $un "r$rev\n" or croak $!;
3361         print $un $_, "\n" foreach @$untracked;
3362         my %log_entry = ( parents => \@parents, revision => $rev,
3363                           log => '');
3364
3365         my $headrev;
3366         my $logged = delete $self->{logged_rev_props};
3367         if (!$logged || $self->{-want_revprops}) {
3368                 my $rp = $self->ra->rev_proplist($rev);
3369                 foreach (sort keys %$rp) {
3370                         my $v = $rp->{$_};
3371                         if (/^svn:(author|date|log)$/) {
3372                                 $log_entry{$1} = $v;
3373                         } elsif ($_ eq 'svm:headrev') {
3374                                 $headrev = $v;
3375                         } else {
3376                                 print $un "  rev_prop: ", uri_encode($_), ' ',
3377                                           uri_encode($v), "\n";
3378                         }
3379                 }
3380         } else {
3381                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
3382         }
3383         close $un or croak $!;
3384
3385         $log_entry{date} = parse_svn_date($log_entry{date});
3386         $log_entry{log} .= "\n";
3387         my $author = $log_entry{author} = check_author($log_entry{author});
3388         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
3389                                                        : ($author, undef);
3390
3391         my ($commit_name, $commit_email) = ($name, $email);
3392         if ($_use_log_author) {
3393                 my $name_field;
3394                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
3395                         $name_field = $1;
3396                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
3397                         $name_field = $1;
3398                 }
3399                 if (!defined $name_field) {
3400                         if (!defined $email) {
3401                                 $email = $name;
3402                         }
3403                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
3404                         ($name, $email) = ($1, $2);
3405                 } elsif ($name_field =~ /(.*)@/) {
3406                         ($name, $email) = ($1, $name_field);
3407                 } else {
3408                         ($name, $email) = ($name_field, $name_field);
3409                 }
3410         }
3411         if (defined $headrev && $self->use_svm_props) {
3412                 if ($self->rewrite_root) {
3413                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
3414                             "options set!\n";
3415                 }
3416                 if ($self->rewrite_uuid) {
3417                         die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
3418                             "options set!\n";
3419                 }
3420                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
3421                 # we don't want "SVM: initializing mirror for junk" ...
3422                 return undef if $r == 0;
3423                 my $svm = $self->svm;
3424                 if ($uuid ne $svm->{uuid}) {
3425                         die "UUID mismatch on SVM path:\n",
3426                             "expected: $svm->{uuid}\n",
3427                             "     got: $uuid\n";
3428                 }
3429                 my $full_url = $self->full_url;
3430                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
3431                              die "Failed to replace '$svm->{replace}' with ",
3432                                  "'$svm->{source}' in $full_url\n";
3433                 # throw away username for storing in records
3434                 remove_username($full_url);
3435                 $log_entry{metadata} = "$full_url\@$r $uuid";
3436                 $log_entry{svm_revision} = $r;
3437                 $email ||= "$author\@$uuid";
3438                 $commit_email ||= "$author\@$uuid";
3439         } elsif ($self->use_svnsync_props) {
3440                 my $full_url = $self->svnsync->{url};
3441                 $full_url .= "/$self->{path}" if length $self->{path};
3442                 remove_username($full_url);
3443                 my $uuid = $self->svnsync->{uuid};
3444                 $log_entry{metadata} = "$full_url\@$rev $uuid";
3445                 $email ||= "$author\@$uuid";
3446                 $commit_email ||= "$author\@$uuid";
3447         } else {
3448                 my $url = $self->metadata_url;
3449                 remove_username($url);
3450                 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
3451                 $log_entry{metadata} = "$url\@$rev " . $uuid;
3452                 $email ||= "$author\@" . $uuid;
3453                 $commit_email ||= "$author\@" . $uuid;
3454         }
3455         $log_entry{name} = $name;
3456         $log_entry{email} = $email;
3457         $log_entry{commit_name} = $commit_name;
3458         $log_entry{commit_email} = $commit_email;
3459         \%log_entry;
3460 }
3461
3462 sub fetch {
3463         my ($self, $min_rev, $max_rev, @parents) = @_;
3464         my ($last_rev, $last_commit) = $self->last_rev_commit;
3465         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
3466         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
3467 }
3468
3469 sub set_tree_cb {
3470         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
3471         $self->{inject_parents} = { $rev => $tree };
3472         $self->fetch(undef, undef);
3473 }
3474
3475 sub set_tree {
3476         my ($self, $tree) = (shift, shift);
3477         my $log_entry = ::get_commit_entry($tree);
3478         unless ($self->{last_rev}) {
3479                 ::fatal("Must have an existing revision to commit");
3480         }
3481         my %ed_opts = ( r => $self->{last_rev},
3482                         log => $log_entry->{log},
3483                         ra => $self->ra,
3484                         tree_a => $self->{last_commit},
3485                         tree_b => $tree,
3486                         editor_cb => sub {
3487                                $self->set_tree_cb($log_entry, $tree, @_) },
3488                         svn_path => $self->{path} );
3489         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
3490                 print "No changes\nr$self->{last_rev} = $tree\n";
3491         }
3492 }
3493
3494 sub rebuild_from_rev_db {
3495         my ($self, $path) = @_;
3496         my $r = -1;
3497         open my $fh, '<', $path or croak "open: $!";
3498         binmode $fh or croak "binmode: $!";
3499         while (<$fh>) {
3500                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3501                 chomp($_);
3502                 ++$r;
3503                 next if $_ eq ('0' x 40);
3504                 $self->rev_map_set($r, $_);
3505                 print "r$r = $_\n";
3506         }
3507         close $fh or croak "close: $!";
3508         unlink $path or croak "unlink: $!";
3509 }
3510
3511 sub rebuild {
3512         my ($self) = @_;
3513         my $map_path = $self->map_path;
3514         my $partial = (-e $map_path && ! -z $map_path);
3515         return unless ::verify_ref($self->refname.'^0');
3516         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3517                 my $rev_db = $self->rev_db_path;
3518                 $self->rebuild_from_rev_db($rev_db);
3519                 if ($self->use_svm_props) {
3520                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3521                         $self->rebuild_from_rev_db($svm_rev_db);
3522                 }
3523                 $self->unlink_rev_db_symlink;
3524                 return;
3525         }
3526         print "Rebuilding $map_path ...\n" if (!$partial);
3527         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3528                 (undef, undef));
3529         my ($log, $ctx) =
3530             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3531                                 ($head ? "$head.." : "") . $self->refname,
3532                                 '--');
3533         my $metadata_url = $self->metadata_url;
3534         remove_username($metadata_url);
3535         my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
3536         my $c;
3537         while (<$log>) {
3538                 if ( m{^commit ($::sha1)$} ) {
3539                         $c = $1;
3540                         next;
3541                 }
3542                 next unless s{^\s*(git-svn-id:)}{$1};
3543                 my ($url, $rev, $uuid) = ::extract_metadata($_);
3544                 remove_username($url);
3545
3546                 # ignore merges (from set-tree)
3547                 next if (!defined $rev || !$uuid);
3548
3549                 # if we merged or otherwise started elsewhere, this is
3550                 # how we break out of it
3551                 if (($uuid ne $svn_uuid) ||
3552                     ($metadata_url && $url && ($url ne $metadata_url))) {
3553                         next;
3554                 }
3555                 if ($partial && $head) {
3556                         print "Partial-rebuilding $map_path ...\n";
3557                         print "Currently at $base_rev = $head\n";
3558                         $head = undef;
3559                 }
3560
3561                 $self->rev_map_set($rev, $c);
3562                 print "r$rev = $c\n";
3563         }
3564         command_close_pipe($log, $ctx);
3565         print "Done rebuilding $map_path\n" if (!$partial || !$head);
3566         my $rev_db_path = $self->rev_db_path;
3567         if (-f $self->rev_db_path) {
3568                 unlink $self->rev_db_path or croak "unlink: $!";
3569         }
3570         $self->unlink_rev_db_symlink;
3571 }
3572
3573 # rev_map:
3574 # Tie::File seems to be prone to offset errors if revisions get sparse,
3575 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
3576 # one of my favorite modules is out :<  Next up would be one of the DBM
3577 # modules, but I'm not sure which is most portable...
3578 #
3579 # This is the replacement for the rev_db format, which was too big
3580 # and inefficient for large repositories with a lot of sparse history
3581 # (mainly tags)
3582 #
3583 # The format is this:
3584 #   - 24 bytes for every record,
3585 #     * 4 bytes for the integer representing an SVN revision number
3586 #     * 20 bytes representing the sha1 of a git commit
3587 #   - No empty padding records like the old format
3588 #     (except the last record, which can be overwritten)
3589 #   - new records are written append-only since SVN revision numbers
3590 #     increase monotonically
3591 #   - lookups on SVN revision number are done via a binary search
3592 #   - Piping the file to xxd -c24 is a good way of dumping it for
3593 #     viewing or editing (piped back through xxd -r), should the need
3594 #     ever arise.
3595 #   - The last record can be padding revision with an all-zero sha1
3596 #     This is used to optimize fetch performance when using multiple
3597 #     "fetch" directives in .git/config
3598 #
3599 # These files are disposable unless noMetadata or useSvmProps is set
3600
3601 sub _rev_map_set {
3602         my ($fh, $rev, $commit) = @_;
3603
3604         binmode $fh or croak "binmode: $!";
3605         my $size = (stat($fh))[7];
3606         ($size % 24) == 0 or croak "inconsistent size: $size";
3607
3608         my $wr_offset = 0;
3609         if ($size > 0) {
3610                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3611                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3612                 $read == 24 or croak "read only $read bytes (!= 24)";
3613                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3614                 if ($last_commit eq ('0' x40)) {
3615                         if ($size >= 48) {
3616                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3617                                 $read = sysread($fh, $buf, 24) or
3618                                     croak "read: $!";
3619                                 $read == 24 or
3620                                     croak "read only $read bytes (!= 24)";
3621                                 ($last_rev, $last_commit) =
3622                                     unpack(rev_map_fmt, $buf);
3623                                 if ($last_commit eq ('0' x40)) {
3624                                         croak "inconsistent .rev_map\n";
3625                                 }
3626                         }
3627                         if ($last_rev >= $rev) {
3628                                 croak "last_rev is higher!: $last_rev >= $rev";
3629                         }
3630                         $wr_offset = -24;
3631                 }
3632         }
3633         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3634         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3635           croak "write: $!";
3636 }
3637
3638 sub _rev_map_reset {
3639         my ($fh, $rev, $commit) = @_;
3640         my $c = _rev_map_get($fh, $rev);
3641         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3642         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3643         truncate $fh, $offset or croak "truncate: $!";
3644 }
3645
3646 sub mkfile {
3647         my ($path) = @_;
3648         unless (-e $path) {
3649                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3650                 mkpath([$dir]) unless -d $dir;
3651                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3652                 close $fh or die "Couldn't close (create) $path: $!\n";
3653         }
3654 }
3655
3656 sub rev_map_set {
3657         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3658         defined $commit or die "missing arg3\n";
3659         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3660         my $db = $self->map_path($uuid);
3661         my $db_lock = "$db.lock";
3662         my $sig;
3663         $update_ref ||= 0;
3664         if ($update_ref) {
3665                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3666                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3667         }
3668         mkfile($db);
3669
3670         $LOCKFILES{$db_lock} = 1;
3671         my $sync;
3672         # both of these options make our .rev_db file very, very important
3673         # and we can't afford to lose it because rebuild() won't work
3674         if ($self->use_svm_props || $self->no_metadata) {
3675                 $sync = 1;
3676                 copy($db, $db_lock) or die "rev_map_set(@_): ",
3677                                            "Failed to copy: ",
3678                                            "$db => $db_lock ($!)\n";
3679         } else {
3680                 rename $db, $db_lock or die "rev_map_set(@_): ",
3681                                             "Failed to rename: ",
3682                                             "$db => $db_lock ($!)\n";
3683         }
3684
3685         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3686              or croak "Couldn't open $db_lock: $!\n";
3687         $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3688                                  _rev_map_set($fh, $rev, $commit);
3689         if ($sync) {
3690                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3691                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3692         }
3693         close $fh or croak $!;
3694         if ($update_ref) {
3695                 $_head = $self;
3696                 my $note = "";
3697                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3698                 command_noisy('update-ref', '-m', "r$rev$note",
3699                               $self->refname, $commit);
3700         }
3701         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3702                                     "$db_lock => $db ($!)\n";
3703         delete $LOCKFILES{$db_lock};
3704         if ($update_ref) {
3705                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3706                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3707                 kill $sig, $$ if defined $sig;
3708         }
3709 }
3710
3711 # If want_commit, this will return an array of (rev, commit) where
3712 # commit _must_ be a valid commit in the archive.
3713 # Otherwise, it'll return the max revision (whether or not the
3714 # commit is valid or just a 0x40 placeholder).
3715 sub rev_map_max {
3716         my ($self, $want_commit) = @_;
3717         $self->rebuild;
3718         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3719         $want_commit ? ($r, $c) : $r;
3720 }
3721
3722 sub rev_map_max_norebuild {
3723         my ($self, $want_commit) = @_;
3724         my $map_path = $self->map_path;
3725         stat $map_path or return $want_commit ? (0, undef) : 0;
3726         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3727         binmode $fh or croak "binmode: $!";
3728         my $size = (stat($fh))[7];
3729         ($size % 24) == 0 or croak "inconsistent size: $size";
3730
3731         if ($size == 0) {
3732                 close $fh or croak "close: $!";
3733                 return $want_commit ? (0, undef) : 0;
3734         }
3735
3736         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3737         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3738         my ($r, $c) = unpack(rev_map_fmt, $buf);
3739         if ($want_commit && $c eq ('0' x40)) {
3740                 if ($size < 48) {
3741                         return $want_commit ? (0, undef) : 0;
3742                 }
3743                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3744                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3745                 ($r, $c) = unpack(rev_map_fmt, $buf);
3746                 if ($c eq ('0'x40)) {
3747                         croak "Penultimate record is all-zeroes in $map_path";
3748                 }
3749         }
3750         close $fh or croak "close: $!";
3751         $want_commit ? ($r, $c) : $r;
3752 }
3753
3754 sub rev_map_get {
3755         my ($self, $rev, $uuid) = @_;
3756         my $map_path = $self->map_path($uuid);
3757         return undef unless -e $map_path;
3758
3759         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3760         my $c = _rev_map_get($fh, $rev);
3761         close($fh) or croak "close: $!";
3762         $c
3763 }
3764
3765 sub _rev_map_get {
3766         my ($fh, $rev) = @_;
3767
3768         binmode $fh or croak "binmode: $!";
3769         my $size = (stat($fh))[7];
3770         ($size % 24) == 0 or croak "inconsistent size: $size";
3771
3772         if ($size == 0) {
3773                 return undef;
3774         }
3775
3776         my ($l, $u) = (0, $size - 24);
3777         my ($r, $c, $buf);
3778
3779         while ($l <= $u) {
3780                 my $i = int(($l/24 + $u/24) / 2) * 24;
3781                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3782                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3783                 my ($r, $c) = unpack(rev_map_fmt, $buf);
3784
3785                 if ($r < $rev) {
3786                         $l = $i + 24;
3787                 } elsif ($r > $rev) {
3788                         $u = $i - 24;
3789                 } else { # $r == $rev
3790                         return $c eq ('0' x 40) ? undef : $c;
3791                 }
3792         }
3793         undef;
3794 }
3795
3796 # Finds the first svn revision that exists on (if $eq_ok is true) or
3797 # before $rev for the current branch.  It will not search any lower
3798 # than $min_rev.  Returns the git commit hash and svn revision number
3799 # if found, else (undef, undef).
3800 sub find_rev_before {
3801         my ($self, $rev, $eq_ok, $min_rev) = @_;
3802         --$rev unless $eq_ok;
3803         $min_rev ||= 1;
3804         my $max_rev = $self->rev_map_max;
3805         $rev = $max_rev if ($rev > $max_rev);
3806         while ($rev >= $min_rev) {
3807                 if (my $c = $self->rev_map_get($rev)) {
3808                         return ($rev, $c);
3809                 }
3810                 --$rev;
3811         }
3812         return (undef, undef);
3813 }
3814
3815 # Finds the first svn revision that exists on (if $eq_ok is true) or
3816 # after $rev for the current branch.  It will not search any higher
3817 # than $max_rev.  Returns the git commit hash and svn revision number
3818 # if found, else (undef, undef).
3819 sub find_rev_after {
3820         my ($self, $rev, $eq_ok, $max_rev) = @_;
3821         ++$rev unless $eq_ok;
3822         $max_rev ||= $self->rev_map_max;
3823         while ($rev <= $max_rev) {
3824                 if (my $c = $self->rev_map_get($rev)) {
3825                         return ($rev, $c);
3826                 }
3827                 ++$rev;
3828         }
3829         return (undef, undef);
3830 }
3831
3832 sub _new {
3833         my ($class, $repo_id, $ref_id, $path) = @_;
3834         unless (defined $repo_id && length $repo_id) {
3835                 $repo_id = $Git::SVN::default_repo_id;
3836         }
3837         unless (defined $ref_id && length $ref_id) {
3838                 $_prefix = '' unless defined($_prefix);
3839                 $_[2] = $ref_id =
3840                              "refs/remotes/$_prefix$Git::SVN::default_ref_id";
3841         }
3842         $_[1] = $repo_id;
3843         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3844
3845         # Older repos imported by us used $GIT_DIR/svn/foo instead of
3846         # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
3847         if ($ref_id =~ m{^refs/remotes/(.*)}) {
3848                 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
3849                 if (-d $old_dir && ! -d $dir) {
3850                         $dir = $old_dir;
3851                 }
3852         }
3853
3854         $_[3] = $path = '' unless (defined $path);
3855         mkpath([$dir]);
3856         bless {
3857                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3858                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3859                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3860 }
3861
3862 # for read-only access of old .rev_db formats
3863 sub unlink_rev_db_symlink {
3864         my ($self) = @_;
3865         my $link = $self->rev_db_path;
3866         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3867         if (-l $link) {
3868                 unlink $link or croak "unlink: $link failed!";
3869         }
3870 }
3871
3872 sub rev_db_path {
3873         my ($self, $uuid) = @_;
3874         my $db_path = $self->map_path($uuid);
3875         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3876             or croak "map_path: $db_path does not contain '/.rev_map.' !";
3877         $db_path;
3878 }
3879
3880 # the new replacement for .rev_db
3881 sub map_path {
3882         my ($self, $uuid) = @_;
3883         $uuid ||= $self->ra_uuid;
3884         "$self->{map_root}.$uuid";
3885 }
3886
3887 sub uri_encode {
3888         my ($f) = @_;
3889         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3890         $f
3891 }
3892
3893 sub uri_decode {
3894         my ($f) = @_;
3895         $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
3896         $f
3897 }
3898
3899 sub remove_username {
3900         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3901 }
3902
3903 package Git::SVN::Prompt;
3904 use strict;
3905 use warnings;
3906 require SVN::Core;
3907 use vars qw/$_no_auth_cache $_username/;
3908
3909 sub simple {
3910         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3911         $may_save = undef if $_no_auth_cache;
3912         $default_username = $_username if defined $_username;
3913         if (defined $default_username && length $default_username) {
3914                 if (defined $realm && length $realm) {
3915                         print STDERR "Authentication realm: $realm\n";
3916                         STDERR->flush;
3917                 }
3918                 $cred->username($default_username);
3919         } else {
3920                 username($cred, $realm, $may_save, $pool);
3921         }
3922         $cred->password(_read_password("Password for '" .
3923                                        $cred->username . "': ", $realm));
3924         $cred->may_save($may_save);
3925         $SVN::_Core::SVN_NO_ERROR;
3926 }
3927
3928 sub ssl_server_trust {
3929         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3930         $may_save = undef if $_no_auth_cache;
3931         print STDERR "Error validating server certificate for '$realm':\n";
3932         {
3933                 no warnings 'once';
3934                 # All variables SVN::Auth::SSL::* are used only once,
3935                 # so we're shutting up Perl warnings about this.
3936                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3937                         print STDERR " - The certificate is not issued ",
3938                             "by a trusted authority. Use the\n",
3939                             "   fingerprint to validate ",
3940                             "the certificate manually!\n";
3941                 }
3942                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3943                         print STDERR " - The certificate hostname ",
3944                             "does not match.\n";
3945                 }
3946                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3947                         print STDERR " - The certificate is not yet valid.\n";
3948                 }
3949                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3950                         print STDERR " - The certificate has expired.\n";
3951                 }
3952                 if ($failures & $SVN::Auth::SSL::OTHER) {
3953                         print STDERR " - The certificate has ",
3954                             "an unknown error.\n";
3955                 }
3956         } # no warnings 'once'
3957         printf STDERR
3958                 "Certificate information:\n".
3959                 " - Hostname: %s\n".
3960                 " - Valid: from %s until %s\n".
3961                 " - Issuer: %s\n".
3962                 " - Fingerprint: %s\n",
3963                 map $cert_info->$_, qw(hostname valid_from valid_until
3964                                        issuer_dname fingerprint);
3965         my $choice;
3966 prompt:
3967         print STDERR $may_save ?
3968               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3969               "(R)eject or accept (t)emporarily? ";
3970         STDERR->flush;
3971         $choice = lc(substr(<STDIN> || 'R', 0, 1));
3972         if ($choice =~ /^t$/i) {
3973                 $cred->may_save(undef);
3974         } elsif ($choice =~ /^r$/i) {
3975                 return -1;
3976         } elsif ($may_save && $choice =~ /^p$/i) {
3977                 $cred->may_save($may_save);
3978         } else {
3979                 goto prompt;
3980         }
3981         $cred->accepted_failures($failures);
3982         $SVN::_Core::SVN_NO_ERROR;
3983 }
3984
3985 sub ssl_client_cert {
3986         my ($cred, $realm, $may_save, $pool) = @_;
3987         $may_save = undef if $_no_auth_cache;
3988         print STDERR "Client certificate filename: ";
3989         STDERR->flush;
3990         chomp(my $filename = <STDIN>);
3991         $cred->cert_file($filename);
3992         $cred->may_save($may_save);
3993         $SVN::_Core::SVN_NO_ERROR;
3994 }
3995
3996 sub ssl_client_cert_pw {
3997         my ($cred, $realm, $may_save, $pool) = @_;
3998         $may_save = undef if $_no_auth_cache;
3999         $cred->password(_read_password("Password: ", $realm));
4000         $cred->may_save($may_save);
4001         $SVN::_Core::SVN_NO_ERROR;
4002 }
4003
4004 sub username {
4005         my ($cred, $realm, $may_save, $pool) = @_;
4006         $may_save = undef if $_no_auth_cache;
4007         if (defined $realm && length $realm) {
4008                 print STDERR "Authentication realm: $realm\n";
4009         }
4010         my $username;
4011         if (defined $_username) {
4012                 $username = $_username;
4013         } else {
4014                 print STDERR "Username: ";
4015                 STDERR->flush;
4016                 chomp($username = <STDIN>);
4017         }
4018         $cred->username($username);
4019         $cred->may_save($may_save);
4020         $SVN::_Core::SVN_NO_ERROR;
4021 }
4022
4023 sub _read_password {
4024         my ($prompt, $realm) = @_;
4025         my $password = '';
4026         if (exists $ENV{GIT_ASKPASS}) {
4027                 open(PH, "-|", $ENV{GIT_ASKPASS}, $prompt);
4028                 $password = <PH>;
4029                 $password =~ s/[\012\015]//; # \n\r
4030                 close(PH);
4031         } else {
4032                 print STDERR $prompt;
4033                 STDERR->flush;
4034                 require Term::ReadKey;
4035                 Term::ReadKey::ReadMode('noecho');
4036                 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
4037                         last if $key =~ /[\012\015]/; # \n\r
4038                         $password .= $key;
4039                 }
4040                 Term::ReadKey::ReadMode('restore');
4041                 print STDERR "\n";
4042                 STDERR->flush;
4043         }
4044         $password;
4045 }
4046
4047 package SVN::Git::Fetcher;
4048 use vars qw/@ISA/;
4049 use strict;
4050 use warnings;
4051 use Carp qw/croak/;
4052 use IO::File qw//;
4053 use vars qw/$_ignore_regex/;
4054
4055 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
4056 sub new {
4057         my ($class, $git_svn, $switch_path) = @_;
4058         my $self = SVN::Delta::Editor->new;
4059         bless $self, $class;
4060         if (exists $git_svn->{last_commit}) {
4061                 $self->{c} = $git_svn->{last_commit};
4062                 $self->{empty_symlinks} =
4063                                   _mark_empty_symlinks($git_svn, $switch_path);
4064         }
4065         $self->{ignore_regex} = eval { command_oneline('config', '--get',
4066                              "svn-remote.$git_svn->{repo_id}.ignore-paths") };
4067         $self->{empty} = {};
4068         $self->{dir_prop} = {};
4069         $self->{file_prop} = {};
4070         $self->{absent_dir} = {};
4071         $self->{absent_file} = {};
4072         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
4073         $self->{pathnameencoding} = Git::config('svn.pathnameencoding');
4074         $self;
4075 }
4076
4077 # this uses the Ra object, so it must be called before do_{switch,update},
4078 # not inside them (when the Git::SVN::Fetcher object is passed) to
4079 # do_{switch,update}
4080 sub _mark_empty_symlinks {
4081         my ($git_svn, $switch_path) = @_;
4082         my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
4083         return {} if (!defined($bool)) || (defined($bool) && ! $bool);
4084
4085         my %ret;
4086         my ($rev, $cmt) = $git_svn->last_rev_commit;
4087         return {} unless ($rev && $cmt);
4088
4089         # allow the warning to be printed for each revision we fetch to
4090         # ensure the user sees it.  The user can also disable the workaround
4091         # on the repository even while git svn is running and the next
4092         # revision fetched will skip this expensive function.
4093         my $printed_warning;
4094         chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
4095         my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
4096         local $/ = "\0";
4097         my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
4098         $pfx .= '/' if length($pfx);
4099         while (<$ls>) {
4100                 chomp;
4101                 s/\A100644 blob $empty_blob\t//o or next;
4102                 unless ($printed_warning) {
4103                         print STDERR "Scanning for empty symlinks, ",
4104                                      "this may take a while if you have ",
4105                                      "many empty files\n",
4106                                      "You may disable this with `",
4107                                      "git config svn.brokenSymlinkWorkaround ",
4108                                      "false'.\n",
4109                                      "This may be done in a different ",
4110                                      "terminal without restarting ",
4111                                      "git svn\n";
4112                         $printed_warning = 1;
4113                 }
4114                 my $path = $_;
4115                 my (undef, $props) =
4116                                $git_svn->ra->get_file($pfx.$path, $rev, undef);
4117                 if ($props->{'svn:special'}) {
4118                         $ret{$path} = 1;
4119                 }
4120         }
4121         command_close_pipe($ls, $ctx);
4122         \%ret;
4123 }
4124
4125 # returns true if a given path is inside a ".git" directory
4126 sub in_dot_git {
4127         $_[0] =~ m{(?:^|/)\.git(?:/|$)};
4128 }
4129
4130 # return value: 0 -- don't ignore, 1 -- ignore
4131 sub is_path_ignored {
4132         my ($self, $path) = @_;
4133         return 1 if in_dot_git($path);
4134         return 1 if defined($self->{ignore_regex}) &&
4135                     $path =~ m!$self->{ignore_regex}!;
4136         return 0 unless defined($_ignore_regex);
4137         return 1 if $path =~ m!$_ignore_regex!o;
4138         return 0;
4139 }
4140
4141 sub set_path_strip {
4142         my ($self, $path) = @_;
4143         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
4144 }
4145
4146 sub open_root {
4147         { path => '' };
4148 }
4149
4150 sub open_directory {
4151         my ($self, $path, $pb, $rev) = @_;
4152         { path => $path };
4153 }
4154
4155 sub git_path {
4156         my ($self, $path) = @_;
4157         if (my $enc = $self->{pathnameencoding}) {
4158                 require Encode;
4159                 Encode::from_to($path, 'UTF-8', $enc);
4160         }
4161         if ($self->{path_strip}) {
4162                 $path =~ s!$self->{path_strip}!! or
4163                   die "Failed to strip path '$path' ($self->{path_strip})\n";
4164         }
4165         $path;
4166 }
4167
4168 sub delete_entry {
4169         my ($self, $path, $rev, $pb) = @_;
4170         return undef if $self->is_path_ignored($path);
4171
4172         my $gpath = $self->git_path($path);
4173         return undef if ($gpath eq '');
4174
4175         # remove entire directories.
4176         my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4177                          =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
4178         if ($tree) {
4179                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4180                                                      -r --name-only -z/,
4181                                                      $tree);
4182                 local $/ = "\0";
4183                 while (<$ls>) {
4184                         chomp;
4185                         my $rmpath = "$gpath/$_";
4186                         $self->{gii}->remove($rmpath);
4187                         print "\tD\t$rmpath\n" unless $::_q;
4188                 }
4189                 print "\tD\t$gpath/\n" unless $::_q;
4190                 command_close_pipe($ls, $ctx);
4191         } else {
4192                 $self->{gii}->remove($gpath);
4193                 print "\tD\t$gpath\n" unless $::_q;
4194         }
4195         $self->{empty}->{$path} = 0;
4196         undef;
4197 }
4198
4199 sub open_file {
4200         my ($self, $path, $pb, $rev) = @_;
4201         my ($mode, $blob);
4202
4203         goto out if $self->is_path_ignored($path);
4204
4205         my $gpath = $self->git_path($path);
4206         ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4207                              =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
4208         unless (defined $mode && defined $blob) {
4209                 die "$path was not found in commit $self->{c} (r$rev)\n";
4210         }
4211         if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
4212                 $mode = '120000';
4213         }
4214 out:
4215         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
4216           pool => SVN::Pool->new, action => 'M' };
4217 }
4218
4219 sub add_file {
4220         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
4221         my $mode;
4222
4223         if (!$self->is_path_ignored($path)) {
4224                 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4225                 delete $self->{empty}->{$dir};
4226                 $mode = '100644';
4227         }
4228         { path => $path, mode_a => $mode, mode_b => $mode,
4229           pool => SVN::Pool->new, action => 'A' };
4230 }
4231
4232 sub add_directory {
4233         my ($self, $path, $cp_path, $cp_rev) = @_;
4234         goto out if $self->is_path_ignored($path);
4235         my $gpath = $self->git_path($path);
4236         if ($gpath eq '') {
4237                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4238                                                      -r --name-only -z/,
4239                                                      $self->{c});
4240                 local $/ = "\0";
4241                 while (<$ls>) {
4242                         chomp;
4243                         $self->{gii}->remove($_);
4244                         print "\tD\t$_\n" unless $::_q;
4245                 }
4246                 command_close_pipe($ls, $ctx);
4247                 $self->{empty}->{$path} = 0;
4248         }
4249         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4250         delete $self->{empty}->{$dir};
4251         $self->{empty}->{$path} = 1;
4252 out:
4253         { path => $path };
4254 }
4255
4256 sub change_dir_prop {
4257         my ($self, $db, $prop, $value) = @_;
4258         return undef if $self->is_path_ignored($db->{path});
4259         $self->{dir_prop}->{$db->{path}} ||= {};
4260         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
4261         undef;
4262 }
4263
4264 sub absent_directory {
4265         my ($self, $path, $pb) = @_;
4266         return undef if $self->is_path_ignored($path);
4267         $self->{absent_dir}->{$pb->{path}} ||= [];
4268         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
4269         undef;
4270 }
4271
4272 sub absent_file {
4273         my ($self, $path, $pb) = @_;
4274         return undef if $self->is_path_ignored($path);
4275         $self->{absent_file}->{$pb->{path}} ||= [];
4276         push @{$self->{absent_file}->{$pb->{path}}}, $path;
4277         undef;
4278 }
4279
4280 sub change_file_prop {
4281         my ($self, $fb, $prop, $value) = @_;
4282         return undef if $self->is_path_ignored($fb->{path});
4283         if ($prop eq 'svn:executable') {
4284                 if ($fb->{mode_b} != 120000) {
4285                         $fb->{mode_b} = defined $value ? 100755 : 100644;
4286                 }
4287         } elsif ($prop eq 'svn:special') {
4288                 $fb->{mode_b} = defined $value ? 120000 : 100644;
4289         } else {
4290                 $self->{file_prop}->{$fb->{path}} ||= {};
4291                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
4292         }
4293         undef;
4294 }
4295
4296 sub apply_textdelta {
4297         my ($self, $fb, $exp) = @_;
4298         return undef if $self->is_path_ignored($fb->{path});
4299         my $fh = $::_repository->temp_acquire('svn_delta');
4300         # $fh gets auto-closed() by SVN::TxDelta::apply(),
4301         # (but $base does not,) so dup() it for reading in close_file
4302         open my $dup, '<&', $fh or croak $!;
4303         my $base = $::_repository->temp_acquire('git_blob');
4304
4305         if ($fb->{blob}) {
4306                 my ($base_is_link, $size);
4307
4308                 if ($fb->{mode_a} eq '120000' &&
4309                     ! $self->{empty_symlinks}->{$fb->{path}}) {
4310                         print $base 'link ' or die "print $!\n";
4311                         $base_is_link = 1;
4312                 }
4313         retry:
4314                 $size = $::_repository->cat_blob($fb->{blob}, $base);
4315                 die "Failed to read object $fb->{blob}" if ($size < 0);
4316
4317                 if (defined $exp) {
4318                         seek $base, 0, 0 or croak $!;
4319                         my $got = ::md5sum($base);
4320                         if ($got ne $exp) {
4321                                 my $err = "Checksum mismatch: ".
4322                                        "$fb->{path} $fb->{blob}\n" .
4323                                        "expected: $exp\n" .
4324                                        "     got: $got\n";
4325                                 if ($base_is_link) {
4326                                         warn $err,
4327                                              "Retrying... (possibly ",
4328                                              "a bad symlink from SVN)\n";
4329                                         $::_repository->temp_reset($base);
4330                                         $base_is_link = 0;
4331                                         goto retry;
4332                                 }
4333                                 die $err;
4334                         }
4335                 }
4336         }
4337         seek $base, 0, 0 or croak $!;
4338         $fb->{fh} = $fh;
4339         $fb->{base} = $base;
4340         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
4341 }
4342
4343 sub close_file {
4344         my ($self, $fb, $exp) = @_;
4345         return undef if $self->is_path_ignored($fb->{path});
4346
4347         my $hash;
4348         my $path = $self->git_path($fb->{path});
4349         if (my $fh = $fb->{fh}) {
4350                 if (defined $exp) {
4351                         seek($fh, 0, 0) or croak $!;
4352                         my $got = ::md5sum($fh);
4353                         if ($got ne $exp) {
4354                                 die "Checksum mismatch: $path\n",
4355                                     "expected: $exp\n    got: $got\n";
4356                         }
4357                 }
4358                 if ($fb->{mode_b} == 120000) {
4359                         sysseek($fh, 0, 0) or croak $!;
4360                         my $rd = sysread($fh, my $buf, 5);
4361
4362                         if (!defined $rd) {
4363                                 croak "sysread: $!\n";
4364                         } elsif ($rd == 0) {
4365                                 warn "$path has mode 120000",
4366                                      " but it points to nothing\n",
4367                                      "converting to an empty file with mode",
4368                                      " 100644\n";
4369                                 $fb->{mode_b} = '100644';
4370                         } elsif ($buf ne 'link ') {
4371                                 warn "$path has mode 120000",
4372                                      " but is not a link\n";
4373                         } else {
4374                                 my $tmp_fh = $::_repository->temp_acquire(
4375                                         'svn_hash');
4376                                 my $res;
4377                                 while ($res = sysread($fh, my $str, 1024)) {
4378                                         my $out = syswrite($tmp_fh, $str, $res);
4379                                         defined($out) && $out == $res
4380                                                 or croak("write ",
4381                                                         Git::temp_path($tmp_fh),
4382                                                         ": $!\n");
4383                                 }
4384                                 defined $res or croak $!;
4385
4386                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
4387                                 Git::temp_release($tmp_fh, 1);
4388                         }
4389                 }
4390
4391                 $hash = $::_repository->hash_and_insert_object(
4392                                 Git::temp_path($fh));
4393                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
4394
4395                 Git::temp_release($fb->{base}, 1);
4396                 Git::temp_release($fh, 1);
4397         } else {
4398                 $hash = $fb->{blob} or die "no blob information\n";
4399         }
4400         $fb->{pool}->clear;
4401         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
4402         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
4403         undef;
4404 }
4405
4406 sub abort_edit {
4407         my $self = shift;
4408         $self->{nr} = $self->{gii}->{nr};
4409         delete $self->{gii};
4410         $self->SUPER::abort_edit(@_);
4411 }
4412
4413 sub close_edit {
4414         my $self = shift;
4415         $self->{git_commit_ok} = 1;
4416         $self->{nr} = $self->{gii}->{nr};
4417         delete $self->{gii};
4418         $self->SUPER::close_edit(@_);
4419 }
4420
4421 package SVN::Git::Editor;
4422 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
4423 use strict;
4424 use warnings;
4425 use Carp qw/croak/;
4426 use IO::File;
4427
4428 sub new {
4429         my ($class, $opts) = @_;
4430         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
4431                 die "$_ required!\n" unless (defined $opts->{$_});
4432         }
4433
4434         my $pool = SVN::Pool->new;
4435         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
4436         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
4437                                      $opts->{r}, $mods);
4438
4439         # $opts->{ra} functions should not be used after this:
4440         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
4441                                                 $opts->{editor_cb}, $pool);
4442         my $self = SVN::Delta::Editor->new(@ce, $pool);
4443         bless $self, $class;
4444         foreach (qw/svn_path r tree_a tree_b/) {
4445                 $self->{$_} = $opts->{$_};
4446         }
4447         $self->{url} = $opts->{ra}->{url};
4448         $self->{mods} = $mods;
4449         $self->{types} = $types;
4450         $self->{pool} = $pool;
4451         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
4452         $self->{rm} = { };
4453         $self->{path_prefix} = length $self->{svn_path} ?
4454                                "$self->{svn_path}/" : '';
4455         $self->{config} = $opts->{config};
4456         $self->{mergeinfo} = $opts->{mergeinfo};
4457         return $self;
4458 }
4459
4460 sub generate_diff {
4461         my ($tree_a, $tree_b) = @_;
4462         my @diff_tree = qw(diff-tree -z -r);
4463         if ($_cp_similarity) {
4464                 push @diff_tree, "-C$_cp_similarity";
4465         } else {
4466                 push @diff_tree, '-C';
4467         }
4468         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
4469         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
4470         push @diff_tree, $tree_a, $tree_b;
4471         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
4472         local $/ = "\0";
4473         my $state = 'meta';
4474         my @mods;
4475         while (<$diff_fh>) {
4476                 chomp $_; # this gets rid of the trailing "\0"
4477                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
4478                                         ($::sha1)\s($::sha1)\s
4479                                         ([MTCRAD])\d*$/xo) {
4480                         push @mods, {   mode_a => $1, mode_b => $2,
4481                                         sha1_a => $3, sha1_b => $4,
4482                                         chg => $5 };
4483                         if ($5 =~ /^(?:C|R)$/) {
4484                                 $state = 'file_a';
4485                         } else {
4486                                 $state = 'file_b';
4487                         }
4488                 } elsif ($state eq 'file_a') {
4489                         my $x = $mods[$#mods] or croak "Empty array\n";
4490                         if ($x->{chg} !~ /^(?:C|R)$/) {
4491                                 croak "Error parsing $_, $x->{chg}\n";
4492                         }
4493                         $x->{file_a} = $_;
4494                         $state = 'file_b';
4495                 } elsif ($state eq 'file_b') {
4496                         my $x = $mods[$#mods] or croak "Empty array\n";
4497                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
4498                                 croak "Error parsing $_, $x->{chg}\n";
4499                         }
4500                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
4501                                 croak "Error parsing $_, $x->{chg}\n";
4502                         }
4503                         $x->{file_b} = $_;
4504                         $state = 'meta';
4505                 } else {
4506                         croak "Error parsing $_\n";
4507                 }
4508         }
4509         command_close_pipe($diff_fh, $ctx);
4510         \@mods;
4511 }
4512
4513 sub check_diff_paths {
4514         my ($ra, $pfx, $rev, $mods) = @_;
4515         my %types;
4516         $pfx .= '/' if length $pfx;
4517
4518         sub type_diff_paths {
4519                 my ($ra, $types, $path, $rev) = @_;
4520                 my @p = split m#/+#, $path;
4521                 my $c = shift @p;
4522                 unless (defined $types->{$c}) {
4523                         $types->{$c} = $ra->check_path($c, $rev);
4524                 }
4525                 while (@p) {
4526                         $c .= '/' . shift @p;
4527                         next if defined $types->{$c};
4528                         $types->{$c} = $ra->check_path($c, $rev);
4529                 }
4530         }
4531
4532         foreach my $m (@$mods) {
4533                 foreach my $f (qw/file_a file_b/) {
4534                         next unless defined $m->{$f};
4535                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
4536                         if (length $pfx.$dir && ! defined $types{$dir}) {
4537                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
4538                         }
4539                 }
4540         }
4541         \%types;
4542 }
4543
4544 sub split_path {
4545         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
4546 }
4547
4548 sub repo_path {
4549         my ($self, $path) = @_;
4550         if (my $enc = $self->{pathnameencoding}) {
4551                 require Encode;
4552                 Encode::from_to($path, $enc, 'UTF-8');
4553         }
4554         $self->{path_prefix}.(defined $path ? $path : '');
4555 }
4556
4557 sub url_path {
4558         my ($self, $path) = @_;
4559         if ($self->{url} =~ m#^https?://#) {
4560                 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4561         }
4562         $self->{url} . '/' . $self->repo_path($path);
4563 }
4564
4565 sub rmdirs {
4566         my ($self) = @_;
4567         my $rm = $self->{rm};
4568         delete $rm->{''}; # we never delete the url we're tracking
4569         return unless %$rm;
4570
4571         foreach (keys %$rm) {
4572                 my @d = split m#/#, $_;
4573                 my $c = shift @d;
4574                 $rm->{$c} = 1;
4575                 while (@d) {
4576                         $c .= '/' . shift @d;
4577                         $rm->{$c} = 1;
4578                 }
4579         }
4580         delete $rm->{$self->{svn_path}};
4581         delete $rm->{''}; # we never delete the url we're tracking
4582         return unless %$rm;
4583
4584         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4585                                              $self->{tree_b});
4586         local $/ = "\0";
4587         while (<$fh>) {
4588                 chomp;
4589                 my @dn = split m#/#, $_;
4590                 while (pop @dn) {
4591                         delete $rm->{join '/', @dn};
4592                 }
4593                 unless (%$rm) {
4594                         close $fh;
4595                         return;
4596                 }
4597         }
4598         command_close_pipe($fh, $ctx);
4599
4600         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4601         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4602                 $self->close_directory($bat->{$d}, $p);
4603                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4604                 print "\tD+\t$d/\n" unless $::_q;
4605                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4606                 delete $bat->{$d};
4607         }
4608 }
4609
4610 sub open_or_add_dir {
4611         my ($self, $full_path, $baton) = @_;
4612         my $t = $self->{types}->{$full_path};
4613         if (!defined $t) {
4614                 die "$full_path not known in r$self->{r} or we have a bug!\n";
4615         }
4616         {
4617                 no warnings 'once';
4618                 # SVN::Node::none and SVN::Node::file are used only once,
4619                 # so we're shutting up Perl's warnings about them.
4620                 if ($t == $SVN::Node::none) {
4621                         return $self->add_directory($full_path, $baton,
4622                             undef, -1, $self->{pool});
4623                 } elsif ($t == $SVN::Node::dir) {
4624                         return $self->open_directory($full_path, $baton,
4625                             $self->{r}, $self->{pool});
4626                 } # no warnings 'once'
4627                 print STDERR "$full_path already exists in repository at ",
4628                     "r$self->{r} and it is not a directory (",
4629                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4630         } # no warnings 'once'
4631         exit 1;
4632 }
4633
4634 sub ensure_path {
4635         my ($self, $path) = @_;
4636         my $bat = $self->{bat};
4637         my $repo_path = $self->repo_path($path);
4638         return $bat->{''} unless (length $repo_path);
4639         my @p = split m#/+#, $repo_path;
4640         my $c = shift @p;
4641         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4642         while (@p) {
4643                 my $c0 = $c;
4644                 $c .= '/' . shift @p;
4645                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4646         }
4647         return $bat->{$c};
4648 }
4649
4650 # Subroutine to convert a globbing pattern to a regular expression.
4651 # From perl cookbook.
4652 sub glob2pat {
4653         my $globstr = shift;
4654         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4655         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4656         return '^' . $globstr . '$';
4657 }
4658
4659 sub check_autoprop {
4660         my ($self, $pattern, $properties, $file, $fbat) = @_;
4661         # Convert the globbing pattern to a regular expression.
4662         my $regex = glob2pat($pattern);
4663         # Check if the pattern matches the file name.
4664         if($file =~ m/($regex)/) {
4665                 # Parse the list of properties to set.
4666                 my @props = split(/;/, $properties);
4667                 foreach my $prop (@props) {
4668                         # Parse 'name=value' syntax and set the property.
4669                         if ($prop =~ /([^=]+)=(.*)/) {
4670                                 my ($n,$v) = ($1,$2);
4671                                 for ($n, $v) {
4672                                         s/^\s+//; s/\s+$//;
4673                                 }
4674                                 $self->change_file_prop($fbat, $n, $v);
4675                         }
4676                 }
4677         }
4678 }
4679
4680 sub apply_autoprops {
4681         my ($self, $file, $fbat) = @_;
4682         my $conf_t = ${$self->{config}}{'config'};
4683         no warnings 'once';
4684         # Check [miscellany]/enable-auto-props in svn configuration.
4685         if (SVN::_Core::svn_config_get_bool(
4686                 $conf_t,
4687                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4688                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4689                 0)) {
4690                 # Auto-props are enabled.  Enumerate them to look for matches.
4691                 my $callback = sub {
4692                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
4693                 };
4694                 SVN::_Core::svn_config_enumerate(
4695                         $conf_t,
4696                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4697                         $callback);
4698         }
4699 }
4700
4701 sub A {
4702         my ($self, $m) = @_;
4703         my ($dir, $file) = split_path($m->{file_b});
4704         my $pbat = $self->ensure_path($dir);
4705         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4706                                         undef, -1);
4707         print "\tA\t$m->{file_b}\n" unless $::_q;
4708         $self->apply_autoprops($file, $fbat);
4709         $self->chg_file($fbat, $m);
4710         $self->close_file($fbat,undef,$self->{pool});
4711 }
4712
4713 sub C {
4714         my ($self, $m) = @_;
4715         my ($dir, $file) = split_path($m->{file_b});
4716         my $pbat = $self->ensure_path($dir);
4717         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4718                                 $self->url_path($m->{file_a}), $self->{r});
4719         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4720         $self->chg_file($fbat, $m);
4721         $self->close_file($fbat,undef,$self->{pool});
4722 }
4723
4724 sub delete_entry {
4725         my ($self, $path, $pbat) = @_;
4726         my $rpath = $self->repo_path($path);
4727         my ($dir, $file) = split_path($rpath);
4728         $self->{rm}->{$dir} = 1;
4729         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4730 }
4731
4732 sub R {
4733         my ($self, $m) = @_;
4734         my ($dir, $file) = split_path($m->{file_b});
4735         my $pbat = $self->ensure_path($dir);
4736         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4737                                 $self->url_path($m->{file_a}), $self->{r});
4738         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4739         $self->apply_autoprops($file, $fbat);
4740         $self->chg_file($fbat, $m);
4741         $self->close_file($fbat,undef,$self->{pool});
4742
4743         ($dir, $file) = split_path($m->{file_a});
4744         $pbat = $self->ensure_path($dir);
4745         $self->delete_entry($m->{file_a}, $pbat);
4746 }
4747
4748 sub M {
4749         my ($self, $m) = @_;
4750         my ($dir, $file) = split_path($m->{file_b});
4751         my $pbat = $self->ensure_path($dir);
4752         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4753                                 $pbat,$self->{r},$self->{pool});
4754         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4755         $self->chg_file($fbat, $m);
4756         $self->close_file($fbat,undef,$self->{pool});
4757 }
4758
4759 sub T { shift->M(@_) }
4760
4761 sub change_file_prop {
4762         my ($self, $fbat, $pname, $pval) = @_;
4763         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4764 }
4765
4766 sub change_dir_prop {
4767         my ($self, $pbat, $pname, $pval) = @_;
4768         $self->SUPER::change_dir_prop($pbat, $pname, $pval, $self->{pool});
4769 }
4770
4771 sub _chg_file_get_blob ($$$$) {
4772         my ($self, $fbat, $m, $which) = @_;
4773         my $fh = $::_repository->temp_acquire("git_blob_$which");
4774         if ($m->{"mode_$which"} =~ /^120/) {
4775                 print $fh 'link ' or croak $!;
4776                 $self->change_file_prop($fbat,'svn:special','*');
4777         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4778                 $self->change_file_prop($fbat,'svn:special',undef);
4779         }
4780         my $blob = $m->{"sha1_$which"};
4781         return ($fh,) if ($blob =~ /^0{40}$/);
4782         my $size = $::_repository->cat_blob($blob, $fh);
4783         croak "Failed to read object $blob" if ($size < 0);
4784         $fh->flush == 0 or croak $!;
4785         seek $fh, 0, 0 or croak $!;
4786
4787         my $exp = ::md5sum($fh);
4788         seek $fh, 0, 0 or croak $!;
4789         return ($fh, $exp);
4790 }
4791
4792 sub chg_file {
4793         my ($self, $fbat, $m) = @_;
4794         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4795                 $self->change_file_prop($fbat,'svn:executable','*');
4796         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4797                 $self->change_file_prop($fbat,'svn:executable',undef);
4798         }
4799         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4800         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4801         my $pool = SVN::Pool->new;
4802         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4803         if (-s $fh_a) {
4804                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4805                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4806                 if (defined $res) {
4807                         die "Unexpected result from send_txstream: $res\n",
4808                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4809                 }
4810         } else {
4811                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4812                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4813                     if ($got ne $exp_b);
4814         }
4815         Git::temp_release($fh_b, 1);
4816         Git::temp_release($fh_a, 1);
4817         $pool->clear;
4818 }
4819
4820 sub D {
4821         my ($self, $m) = @_;
4822         my ($dir, $file) = split_path($m->{file_b});
4823         my $pbat = $self->ensure_path($dir);
4824         print "\tD\t$m->{file_b}\n" unless $::_q;
4825         $self->delete_entry($m->{file_b}, $pbat);
4826 }
4827
4828 sub close_edit {
4829         my ($self) = @_;
4830         my ($p,$bat) = ($self->{pool}, $self->{bat});
4831         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4832                 next if $_ eq '';
4833                 $self->close_directory($bat->{$_}, $p);
4834         }
4835         $self->close_directory($bat->{''}, $p);
4836         $self->SUPER::close_edit($p);
4837         $p->clear;
4838 }
4839
4840 sub abort_edit {
4841         my ($self) = @_;
4842         $self->SUPER::abort_edit($self->{pool});
4843 }
4844
4845 sub DESTROY {
4846         my $self = shift;
4847         $self->SUPER::DESTROY(@_);
4848         $self->{pool}->clear;
4849 }
4850
4851 # this drives the editor
4852 sub apply_diff {
4853         my ($self) = @_;
4854         my $mods = $self->{mods};
4855         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4856         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4857                 my $f = $m->{chg};
4858                 if (defined $o{$f}) {
4859                         $self->$f($m);
4860                 } else {
4861                         fatal("Invalid change type: $f");
4862                 }
4863         }
4864
4865         if (defined($self->{mergeinfo})) {
4866                 $self->change_dir_prop($self->{bat}{''}, "svn:mergeinfo",
4867                                        $self->{mergeinfo});
4868         }
4869         $self->rmdirs if $_rmdir;
4870         if (@$mods == 0) {
4871                 $self->abort_edit;
4872         } else {
4873                 $self->close_edit;
4874         }
4875         return scalar @$mods;
4876 }
4877
4878 package Git::SVN::Ra;
4879 use vars qw/@ISA $config_dir $_log_window_size/;
4880 use strict;
4881 use warnings;
4882 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4883
4884 BEGIN {
4885         # enforce temporary pool usage for some simple functions
4886         no strict 'refs';
4887         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4888                       get_file/) {
4889                 my $SUPER = "SUPER::$f";
4890                 *$f = sub {
4891                         my $self = shift;
4892                         my $pool = SVN::Pool->new;
4893                         my @ret = $self->$SUPER(@_,$pool);
4894                         $pool->clear;
4895                         wantarray ? @ret : $ret[0];
4896                 };
4897         }
4898 }
4899
4900 sub _auth_providers () {
4901         [
4902           SVN::Client::get_simple_provider(),
4903           SVN::Client::get_ssl_server_trust_file_provider(),
4904           SVN::Client::get_simple_prompt_provider(
4905             \&Git::SVN::Prompt::simple, 2),
4906           SVN::Client::get_ssl_client_cert_file_provider(),
4907           SVN::Client::get_ssl_client_cert_prompt_provider(
4908             \&Git::SVN::Prompt::ssl_client_cert, 2),
4909           SVN::Client::get_ssl_client_cert_pw_file_provider(),
4910           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4911             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4912           SVN::Client::get_username_provider(),
4913           SVN::Client::get_ssl_server_trust_prompt_provider(
4914             \&Git::SVN::Prompt::ssl_server_trust),
4915           SVN::Client::get_username_prompt_provider(
4916             \&Git::SVN::Prompt::username, 2)
4917         ]
4918 }
4919
4920 sub escape_uri_only {
4921         my ($uri) = @_;
4922         my @tmp;
4923         foreach (split m{/}, $uri) {
4924                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4925                 push @tmp, $_;
4926         }
4927         join('/', @tmp);
4928 }
4929
4930 sub escape_url {
4931         my ($url) = @_;
4932         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4933                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4934                 $url = "$scheme://$domain$uri";
4935         }
4936         $url;
4937 }
4938
4939 sub new {
4940         my ($class, $url) = @_;
4941         $url =~ s!/+$!!;
4942         return $RA if ($RA && $RA->{url} eq $url);
4943
4944         ::_req_svn();
4945
4946         SVN::_Core::svn_config_ensure($config_dir, undef);
4947         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4948         my $config = SVN::Core::config_get_config($config_dir);
4949         $RA = undef;
4950         my $dont_store_passwords = 1;
4951         my $conf_t = ${$config}{'config'};
4952         {
4953                 no warnings 'once';
4954                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4955                 # produces warnings that variables are used only once.
4956                 # I had not found the better way to shut them up, so
4957                 # the warnings of type 'once' are disabled in this block.
4958                 if (SVN::_Core::svn_config_get_bool($conf_t,
4959                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4960                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4961                     1) == 0) {
4962                         SVN::_Core::svn_auth_set_parameter($baton,
4963                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4964                             bless (\$dont_store_passwords, "_p_void"));
4965                 }
4966                 if (SVN::_Core::svn_config_get_bool($conf_t,
4967                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4968                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4969                     1) == 0) {
4970                         $Git::SVN::Prompt::_no_auth_cache = 1;
4971                 }
4972         } # no warnings 'once'
4973         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4974                               config => $config,
4975                               pool => SVN::Pool->new,
4976                               auth_provider_callbacks => $callbacks);
4977         $self->{url} = $url;
4978         $self->{svn_path} = $url;
4979         $self->{repos_root} = $self->get_repos_root;
4980         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4981         $self->{cache} = { check_path => { r => 0, data => {} },
4982                            get_dir => { r => 0, data => {} } };
4983         $RA = bless $self, $class;
4984 }
4985
4986 sub check_path {
4987         my ($self, $path, $r) = @_;
4988         my $cache = $self->{cache}->{check_path};
4989         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4990                 return $cache->{data}->{$path};
4991         }
4992         my $pool = SVN::Pool->new;
4993         my $t = $self->SUPER::check_path($path, $r, $pool);
4994         $pool->clear;
4995         if ($r != $cache->{r}) {
4996                 %{$cache->{data}} = ();
4997                 $cache->{r} = $r;
4998         }
4999         $cache->{data}->{$path} = $t;
5000 }
5001
5002 sub get_dir {
5003         my ($self, $dir, $r) = @_;
5004         my $cache = $self->{cache}->{get_dir};
5005         if ($r == $cache->{r}) {
5006                 if (my $x = $cache->{data}->{$dir}) {
5007                         return wantarray ? @$x : $x->[0];
5008                 }
5009         }
5010         my $pool = SVN::Pool->new;
5011         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
5012         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
5013         $pool->clear;
5014         if ($r != $cache->{r}) {
5015                 %{$cache->{data}} = ();
5016                 $cache->{r} = $r;
5017         }
5018         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
5019         wantarray ? (\%dirents, $r, $props) : \%dirents;
5020 }
5021
5022 sub DESTROY {
5023         # do not call the real DESTROY since we store ourselves in $RA
5024 }
5025
5026 # get_log(paths, start, end, limit,
5027 #         discover_changed_paths, strict_node_history, receiver)
5028 sub get_log {
5029         my ($self, @args) = @_;
5030         my $pool = SVN::Pool->new;
5031
5032         # svn_log_changed_path_t objects passed to get_log are likely to be
5033         # overwritten even if only the refs are copied to an external variable,
5034         # so we should dup the structures in their entirety.  Using an
5035         # externally passed pool (instead of our temporary and quickly cleared
5036         # pool in Git::SVN::Ra) does not help matters at all...
5037         my $receiver = pop @args;
5038         my $prefix = "/".$self->{svn_path};
5039         $prefix =~ s#/+($)##;
5040         my $prefix_regex = qr#^\Q$prefix\E#;
5041         push(@args, sub {
5042                 my ($paths) = $_[0];
5043                 return &$receiver(@_) unless $paths;
5044                 $_[0] = ();
5045                 foreach my $p (keys %$paths) {
5046                         my $i = $paths->{$p};
5047                         # Make path relative to our url, not repos_root
5048                         $p =~ s/$prefix_regex//;
5049                         my %s = map { $_ => $i->$_; }
5050                                 qw/copyfrom_path copyfrom_rev action/;
5051                         if ($s{'copyfrom_path'}) {
5052                                 $s{'copyfrom_path'} =~ s/$prefix_regex//;
5053                         }
5054                         $_[0]{$p} = \%s;
5055                 }
5056                 &$receiver(@_);
5057         });
5058
5059
5060         # the limit parameter was not supported in SVN 1.1.x, so we
5061         # drop it.  Therefore, the receiver callback passed to it
5062         # is made aware of this limitation by being wrapped if
5063         # the limit passed to is being wrapped.
5064         if ($SVN::Core::VERSION le '1.2.0') {
5065                 my $limit = splice(@args, 3, 1);
5066                 if ($limit > 0) {
5067                         my $receiver = pop @args;
5068                         push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
5069                 }
5070         }
5071         my $ret = $self->SUPER::get_log(@args, $pool);
5072         $pool->clear;
5073         $ret;
5074 }
5075
5076 sub trees_match {
5077         my ($self, $url1, $rev1, $url2, $rev2) = @_;
5078         my $ctx = SVN::Client->new(auth => _auth_providers);
5079         my $out = IO::File->new_tmpfile;
5080
5081         # older SVN (1.1.x) doesn't take $pool as the last parameter for
5082         # $ctx->diff(), so we'll create a default one
5083         my $pool = SVN::Pool->new_default_sub;
5084
5085         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
5086         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
5087         $out->flush;
5088         my $ret = (($out->stat)[7] == 0);
5089         close $out or croak $!;
5090
5091         $ret;
5092 }
5093
5094 sub get_commit_editor {
5095         my ($self, $log, $cb, $pool) = @_;
5096         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
5097         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
5098 }
5099
5100 sub gs_do_update {
5101         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
5102         my $new = ($rev_a == $rev_b);
5103         my $path = $gs->{path};
5104
5105         if ($new && -e $gs->{index}) {
5106                 unlink $gs->{index} or die
5107                   "Couldn't unlink index: $gs->{index}: $!\n";
5108         }
5109         my $pool = SVN::Pool->new;
5110         $editor->set_path_strip($path);
5111         my (@pc) = split m#/#, $path;
5112         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
5113                                         1, $editor, $pool);
5114         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5115
5116         # Since we can't rely on svn_ra_reparent being available, we'll
5117         # just have to do some magic with set_path to make it so
5118         # we only want a partial path.
5119         my $sp = '';
5120         my $final = join('/', @pc);
5121         while (@pc) {
5122                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
5123                 $sp .= '/' if length $sp;
5124                 $sp .= shift @pc;
5125         }
5126         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
5127
5128         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
5129
5130         $reporter->finish_report($pool);
5131         $pool->clear;
5132         $editor->{git_commit_ok};
5133 }
5134
5135 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
5136 # svn_ra_reparent didn't work before 1.4)
5137 sub gs_do_switch {
5138         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
5139         my $path = $gs->{path};
5140         my $pool = SVN::Pool->new;
5141
5142         my $full_url = $self->{url};
5143         my $old_url = $full_url;
5144         $full_url .= '/' . $path if length $path;
5145         my ($ra, $reparented);
5146
5147         if ($old_url =~ m#^svn(\+ssh)?://# ||
5148             ($full_url =~ m#^https?://# &&
5149              escape_url($full_url) ne $full_url)) {
5150                 $_[0] = undef;
5151                 $self = undef;
5152                 $RA = undef;
5153                 $ra = Git::SVN::Ra->new($full_url);
5154                 $ra_invalid = 1;
5155         } elsif ($old_url ne $full_url) {
5156                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
5157                 $self->{url} = $full_url;
5158                 $reparented = 1;
5159         }
5160
5161         $ra ||= $self;
5162         $url_b = escape_url($url_b);
5163         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
5164         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5165         $reporter->set_path('', $rev_a, 0, @lock, $pool);
5166         $reporter->finish_report($pool);
5167
5168         if ($reparented) {
5169                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
5170                 $self->{url} = $old_url;
5171         }
5172
5173         $pool->clear;
5174         $editor->{git_commit_ok};
5175 }
5176
5177 sub longest_common_path {
5178         my ($gsv, $globs) = @_;
5179         my %common;
5180         my $common_max = scalar @$gsv;
5181
5182         foreach my $gs (@$gsv) {
5183                 my @tmp = split m#/#, $gs->{path};
5184                 my $p = '';
5185                 foreach (@tmp) {
5186                         $p .= length($p) ? "/$_" : $_;
5187                         $common{$p} ||= 0;
5188                         $common{$p}++;
5189                 }
5190         }
5191         $globs ||= [];
5192         $common_max += scalar @$globs;
5193         foreach my $glob (@$globs) {
5194                 my @tmp = split m#/#, $glob->{path}->{left};
5195                 my $p = '';
5196                 foreach (@tmp) {
5197                         $p .= length($p) ? "/$_" : $_;
5198                         $common{$p} ||= 0;
5199                         $common{$p}++;
5200                 }
5201         }
5202
5203         my $longest_path = '';
5204         foreach (sort {length $b <=> length $a} keys %common) {
5205                 if ($common{$_} == $common_max) {
5206                         $longest_path = $_;
5207                         last;
5208                 }
5209         }
5210         $longest_path;
5211 }
5212
5213 sub gs_fetch_loop_common {
5214         my ($self, $base, $head, $gsv, $globs) = @_;
5215         return if ($base > $head);
5216         my $inc = $_log_window_size;
5217         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
5218         my $longest_path = longest_common_path($gsv, $globs);
5219         my $ra_url = $self->{url};
5220         my $find_trailing_edge;
5221         while (1) {
5222                 my %revs;
5223                 my $err;
5224                 my $err_handler = $SVN::Error::handler;
5225                 $SVN::Error::handler = sub {
5226                         ($err) = @_;
5227                         skip_unknown_revs($err);
5228                 };
5229                 sub _cb {
5230                         my ($paths, $r, $author, $date, $log) = @_;
5231                         [ $paths,
5232                           { author => $author, date => $date, log => $log } ];
5233                 }
5234                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
5235                                sub { $revs{$_[1]} = _cb(@_) });
5236                 if ($err) {
5237                         print "Checked through r$max\r";
5238                 } else {
5239                         $find_trailing_edge = 1;
5240                 }
5241                 if ($err and $find_trailing_edge) {
5242                         print STDERR "Path '$longest_path' ",
5243                                      "was probably deleted:\n",
5244                                      $err->expanded_message,
5245                                      "\nWill attempt to follow ",
5246                                      "revisions r$min .. r$max ",
5247                                      "committed before the deletion\n";
5248                         my $hi = $max;
5249                         while (--$hi >= $min) {
5250                                 my $ok;
5251                                 $self->get_log([$longest_path], $min, $hi,
5252                                                0, 1, 1, sub {
5253                                                $ok = $_[1];
5254                                                $revs{$_[1]} = _cb(@_) });
5255                                 if ($ok) {
5256                                         print STDERR "r$min .. r$ok OK\n";
5257                                         last;
5258                                 }
5259                         }
5260                         $find_trailing_edge = 0;
5261                 }
5262                 $SVN::Error::handler = $err_handler;
5263
5264                 my %exists = map { $_->{path} => $_ } @$gsv;
5265                 foreach my $r (sort {$a <=> $b} keys %revs) {
5266                         my ($paths, $logged) = @{$revs{$r}};
5267
5268                         foreach my $gs ($self->match_globs(\%exists, $paths,
5269                                                            $globs, $r)) {
5270                                 if ($gs->rev_map_max >= $r) {
5271                                         next;
5272                                 }
5273                                 next unless $gs->match_paths($paths, $r);
5274                                 $gs->{logged_rev_props} = $logged;
5275                                 if (my $last_commit = $gs->last_commit) {
5276                                         $gs->assert_index_clean($last_commit);
5277                                 }
5278                                 my $log_entry = $gs->do_fetch($paths, $r);
5279                                 if ($log_entry) {
5280                                         $gs->do_git_commit($log_entry);
5281                                 }
5282                                 $INDEX_FILES{$gs->{index}} = 1;
5283                         }
5284                         foreach my $g (@$globs) {
5285                                 my $k = "svn-remote.$g->{remote}." .
5286                                         "$g->{t}-maxRev";
5287                                 Git::SVN::tmp_config($k, $r);
5288                         }
5289                         if ($ra_invalid) {
5290                                 $_[0] = undef;
5291                                 $self = undef;
5292                                 $RA = undef;
5293                                 $self = Git::SVN::Ra->new($ra_url);
5294                                 $ra_invalid = undef;
5295                         }
5296                 }
5297                 # pre-fill the .rev_db since it'll eventually get filled in
5298                 # with '0' x40 if something new gets committed
5299                 foreach my $gs (@$gsv) {
5300                         next if $gs->rev_map_max >= $max;
5301                         next if defined $gs->rev_map_get($max);
5302                         $gs->rev_map_set($max, 0 x40);
5303                 }
5304                 foreach my $g (@$globs) {
5305                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
5306                         Git::SVN::tmp_config($k, $max);
5307                 }
5308                 last if $max >= $head;
5309                 $min = $max + 1;
5310                 $max += $inc;
5311                 $max = $head if ($max > $head);
5312         }
5313         Git::SVN::gc();
5314 }
5315
5316 sub get_dir_globbed {
5317         my ($self, $left, $depth, $r) = @_;
5318
5319         my @x = eval { $self->get_dir($left, $r) };
5320         return unless scalar @x == 3;
5321         my $dirents = $x[0];
5322         my @finalents;
5323         foreach my $de (keys %$dirents) {
5324                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
5325                 if ($depth > 1) {
5326                         my @args = ("$left/$de", $depth - 1, $r);
5327                         foreach my $dir ($self->get_dir_globbed(@args)) {
5328                                 push @finalents, "$de/$dir";
5329                         }
5330                 } else {
5331                         push @finalents, $de;
5332                 }
5333         }
5334         @finalents;
5335 }
5336
5337 sub match_globs {
5338         my ($self, $exists, $paths, $globs, $r) = @_;
5339
5340         sub get_dir_check {
5341                 my ($self, $exists, $g, $r) = @_;
5342
5343                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
5344                                                   $g->{path}->{depth},
5345                                                   $r);
5346
5347                 foreach my $de (@dirs) {
5348                         my $p = $g->{path}->full_path($de);
5349                         next if $exists->{$p};
5350                         next if (length $g->{path}->{right} &&
5351                                  ($self->check_path($p, $r) !=
5352                                   $SVN::Node::dir));
5353                         next unless $p =~ /$g->{path}->{regex}/;
5354                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
5355                                          $g->{ref}->full_path($de), 1);
5356                 }
5357         }
5358         foreach my $g (@$globs) {
5359                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
5360                         if ($path->{action} =~ /^[AR]$/) {
5361                                 get_dir_check($self, $exists, $g, $r);
5362                         }
5363                 }
5364                 foreach (keys %$paths) {
5365                         if (/$g->{path}->{left_regex}/ &&
5366                             !/$g->{path}->{regex}/) {
5367                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
5368                                 get_dir_check($self, $exists, $g, $r);
5369                         }
5370                         next unless /$g->{path}->{regex}/;
5371                         my $p = $1;
5372                         my $pathname = $g->{path}->full_path($p);
5373                         next if $exists->{$pathname};
5374                         next if ($self->check_path($pathname, $r) !=
5375                                  $SVN::Node::dir);
5376                         $exists->{$pathname} = Git::SVN->init(
5377                                               $self->{url}, $pathname, undef,
5378                                               $g->{ref}->full_path($p), 1);
5379                 }
5380                 my $c = '';
5381                 foreach (split m#/#, $g->{path}->{left}) {
5382                         $c .= "/$_";
5383                         next unless ($paths->{$c} &&
5384                                      ($paths->{$c}->{action} =~ /^[AR]$/));
5385                         get_dir_check($self, $exists, $g, $r);
5386                 }
5387         }
5388         values %$exists;
5389 }
5390
5391 sub minimize_url {
5392         my ($self) = @_;
5393         return $self->{url} if ($self->{url} eq $self->{repos_root});
5394         my $url = $self->{repos_root};
5395         my @components = split(m!/!, $self->{svn_path});
5396         my $c = '';
5397         do {
5398                 $url .= "/$c" if length $c;
5399                 eval {
5400                         my $ra = (ref $self)->new($url);
5401                         my $latest = $ra->get_latest_revnum;
5402                         $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
5403                 };
5404         } while ($@ && ($c = shift @components));
5405         $url;
5406 }
5407
5408 sub can_do_switch {
5409         my $self = shift;
5410         unless (defined $can_do_switch) {
5411                 my $pool = SVN::Pool->new;
5412                 my $rep = eval {
5413                         $self->do_switch(1, '', 0, $self->{url},
5414                                          SVN::Delta::Editor->new, $pool);
5415                 };
5416                 if ($@) {
5417                         $can_do_switch = 0;
5418                 } else {
5419                         $rep->abort_report($pool);
5420                         $can_do_switch = 1;
5421                 }
5422                 $pool->clear;
5423         }
5424         $can_do_switch;
5425 }
5426
5427 sub skip_unknown_revs {
5428         my ($err) = @_;
5429         my $errno = $err->apr_err();
5430         # Maybe the branch we're tracking didn't
5431         # exist when the repo started, so it's
5432         # not an error if it doesn't, just continue
5433         #
5434         # Wonderfully consistent library, eh?
5435         # 160013 - svn:// and file://
5436         # 175002 - http(s)://
5437         # 175007 - http(s):// (this repo required authorization, too...)
5438         #   More codes may be discovered later...
5439         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
5440                 my $err_key = $err->expanded_message;
5441                 # revision numbers change every time, filter them out
5442                 $err_key =~ s/\d+/\0/g;
5443                 $err_key = "$errno\0$err_key";
5444                 unless ($ignored_err{$err_key}) {
5445                         warn "W: Ignoring error from SVN, path probably ",
5446                              "does not exist: ($errno): ",
5447                              $err->expanded_message,"\n";
5448                         warn "W: Do not be alarmed at the above message ",
5449                              "git-svn is just searching aggressively for ",
5450                              "old history.\n",
5451                              "This may take a while on large repositories\n";
5452                         $ignored_err{$err_key} = 1;
5453                 }
5454                 return;
5455         }
5456         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
5457 }
5458
5459 package Git::SVN::Log;
5460 use strict;
5461 use warnings;
5462 use POSIX qw/strftime/;
5463 use Time::Local;
5464 use constant commit_log_separator => ('-' x 72) . "\n";
5465 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
5466             %rusers $show_commit $incremental/;
5467 my $l_fmt;
5468
5469 sub cmt_showable {
5470         my ($c) = @_;
5471         return 1 if defined $c->{r};
5472
5473         # big commit message got truncated by the 16k pretty buffer in rev-list
5474         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
5475                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
5476                 @{$c->{l}} = ();
5477                 my @log = command(qw/cat-file commit/, $c->{c});
5478
5479                 # shift off the headers
5480                 shift @log while ($log[0] ne '');
5481                 shift @log;
5482
5483                 # TODO: make $c->{l} not have a trailing newline in the future
5484                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
5485
5486                 (undef, $c->{r}, undef) = ::extract_metadata(
5487                                 (grep(/^git-svn-id: /, @log))[-1]);
5488         }
5489         return defined $c->{r};
5490 }
5491
5492 sub log_use_color {
5493         return $color || Git->repository->get_colorbool('color.diff');
5494 }
5495
5496 sub git_svn_log_cmd {
5497         my ($r_min, $r_max, @args) = @_;
5498         my $head = 'HEAD';
5499         my (@files, @log_opts);
5500         foreach my $x (@args) {
5501                 if ($x eq '--' || @files) {
5502                         push @files, $x;
5503                 } else {
5504                         if (::verify_ref("$x^0")) {
5505                                 $head = $x;
5506                         } else {
5507                                 push @log_opts, $x;
5508                         }
5509                 }
5510         }
5511
5512         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
5513         $gs ||= Git::SVN->_new;
5514         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
5515                    $gs->refname);
5516         push @cmd, '-r' unless $non_recursive;
5517         push @cmd, qw/--raw --name-status/ if $verbose;
5518         push @cmd, '--color' if log_use_color();
5519         push @cmd, @log_opts;
5520         if (defined $r_max && $r_max == $r_min) {
5521                 push @cmd, '--max-count=1';
5522                 if (my $c = $gs->rev_map_get($r_max)) {
5523                         push @cmd, $c;
5524                 }
5525         } elsif (defined $r_max) {
5526                 if ($r_max < $r_min) {
5527                         ($r_min, $r_max) = ($r_max, $r_min);
5528                 }
5529                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
5530                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
5531                 # If there are no commits in the range, both $c_max and $c_min
5532                 # will be undefined.  If there is at least 1 commit in the
5533                 # range, both will be defined.
5534                 return () if !defined $c_min || !defined $c_max;
5535                 if ($c_min eq $c_max) {
5536                         push @cmd, '--max-count=1', $c_min;
5537                 } else {
5538                         push @cmd, '--boundary', "$c_min..$c_max";
5539                 }
5540         }
5541         return (@cmd, @files);
5542 }
5543
5544 # adapted from pager.c
5545 sub config_pager {
5546         if (! -t *STDOUT) {
5547                 $ENV{GIT_PAGER_IN_USE} = 'false';
5548                 $pager = undef;
5549                 return;
5550         }
5551         chomp($pager = command_oneline(qw(var GIT_PAGER)));
5552         if ($pager eq 'cat') {
5553                 $pager = undef;
5554         }
5555         $ENV{GIT_PAGER_IN_USE} = defined($pager);
5556 }
5557
5558 sub run_pager {
5559         return unless defined $pager;
5560         pipe my ($rfd, $wfd) or return;
5561         defined(my $pid = fork) or ::fatal "Can't fork: $!";
5562         if (!$pid) {
5563                 open STDOUT, '>&', $wfd or
5564                                      ::fatal "Can't redirect to stdout: $!";
5565                 return;
5566         }
5567         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5568         $ENV{LESS} ||= 'FRSX';
5569         exec $pager or ::fatal "Can't run pager: $! ($pager)";
5570 }
5571
5572 sub format_svn_date {
5573         # some systmes don't handle or mishandle %z, so be creative.
5574         my $t = shift || time;
5575         my $gm = timelocal(gmtime($t));
5576         my $sign = qw( + + - )[ $t <=> $gm ];
5577         my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5578         return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5579 }
5580
5581 sub parse_git_date {
5582         my ($t, $tz) = @_;
5583         # Date::Parse isn't in the standard Perl distro :(
5584         if ($tz =~ s/^\+//) {
5585                 $t += tz_to_s_offset($tz);
5586         } elsif ($tz =~ s/^\-//) {
5587                 $t -= tz_to_s_offset($tz);
5588         }
5589         return $t;
5590 }
5591
5592 sub set_local_timezone {
5593         if (defined $TZ) {
5594                 $ENV{TZ} = $TZ;
5595         } else {
5596                 delete $ENV{TZ};
5597         }
5598 }
5599
5600 sub tz_to_s_offset {
5601         my ($tz) = @_;
5602         $tz =~ s/(\d\d)$//;
5603         return ($1 * 60) + ($tz * 3600);
5604 }
5605
5606 sub get_author_info {
5607         my ($dest, $author, $t, $tz) = @_;
5608         $author =~ s/(?:^\s*|\s*$)//g;
5609         $dest->{a_raw} = $author;
5610         my $au;
5611         if ($::_authors) {
5612                 $au = $rusers{$author} || undef;
5613         }
5614         if (!$au) {
5615                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5616         }
5617         $dest->{t} = $t;
5618         $dest->{tz} = $tz;
5619         $dest->{a} = $au;
5620         $dest->{t_utc} = parse_git_date($t, $tz);
5621 }
5622
5623 sub process_commit {
5624         my ($c, $r_min, $r_max, $defer) = @_;
5625         if (defined $r_min && defined $r_max) {
5626                 if ($r_min == $c->{r} && $r_min == $r_max) {
5627                         show_commit($c);
5628                         return 0;
5629                 }
5630                 return 1 if $r_min == $r_max;
5631                 if ($r_min < $r_max) {
5632                         # we need to reverse the print order
5633                         return 0 if (defined $limit && --$limit < 0);
5634                         push @$defer, $c;
5635                         return 1;
5636                 }
5637                 if ($r_min != $r_max) {
5638                         return 1 if ($r_min < $c->{r});
5639                         return 1 if ($r_max > $c->{r});
5640                 }
5641         }
5642         return 0 if (defined $limit && --$limit < 0);
5643         show_commit($c);
5644         return 1;
5645 }
5646
5647 sub show_commit {
5648         my $c = shift;
5649         if ($oneline) {
5650                 my $x = "\n";
5651                 if (my $l = $c->{l}) {
5652                         while ($l->[0] =~ /^\s*$/) { shift @$l }
5653                         $x = $l->[0];
5654                 }
5655                 $l_fmt ||= 'A' . length($c->{r});
5656                 print 'r',pack($l_fmt, $c->{r}),' | ';
5657                 print "$c->{c} | " if $show_commit;
5658                 print $x;
5659         } else {
5660                 show_commit_normal($c);
5661         }
5662 }
5663
5664 sub show_commit_changed_paths {
5665         my ($c) = @_;
5666         return unless $c->{changed};
5667         print "Changed paths:\n", @{$c->{changed}};
5668 }
5669
5670 sub show_commit_normal {
5671         my ($c) = @_;
5672         print commit_log_separator, "r$c->{r} | ";
5673         print "$c->{c} | " if $show_commit;
5674         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5675         my $nr_line = 0;
5676
5677         if (my $l = $c->{l}) {
5678                 while ($l->[$#$l] eq "\n" && $#$l > 0
5679                                           && $l->[($#$l - 1)] eq "\n") {
5680                         pop @$l;
5681                 }
5682                 $nr_line = scalar @$l;
5683                 if (!$nr_line) {
5684                         print "1 line\n\n\n";
5685                 } else {
5686                         if ($nr_line == 1) {
5687                                 $nr_line = '1 line';
5688                         } else {
5689                                 $nr_line .= ' lines';
5690                         }
5691                         print $nr_line, "\n";
5692                         show_commit_changed_paths($c);
5693                         print "\n";
5694                         print $_ foreach @$l;
5695                 }
5696         } else {
5697                 print "1 line\n";
5698                 show_commit_changed_paths($c);
5699                 print "\n";
5700
5701         }
5702         foreach my $x (qw/raw stat diff/) {
5703                 if ($c->{$x}) {
5704                         print "\n";
5705                         print $_ foreach @{$c->{$x}}
5706                 }
5707         }
5708 }
5709
5710 sub cmd_show_log {
5711         my (@args) = @_;
5712         my ($r_min, $r_max);
5713         my $r_last = -1; # prevent dupes
5714         set_local_timezone();
5715         if (defined $::_revision) {
5716                 if ($::_revision =~ /^(\d+):(\d+)$/) {
5717                         ($r_min, $r_max) = ($1, $2);
5718                 } elsif ($::_revision =~ /^\d+$/) {
5719                         $r_min = $r_max = $::_revision;
5720                 } else {
5721                         ::fatal "-r$::_revision is not supported, use ",
5722                                 "standard 'git log' arguments instead";
5723                 }
5724         }
5725
5726         config_pager();
5727         @args = git_svn_log_cmd($r_min, $r_max, @args);
5728         if (!@args) {
5729                 print commit_log_separator unless $incremental || $oneline;
5730                 return;
5731         }
5732         my $log = command_output_pipe(@args);
5733         run_pager();
5734         my (@k, $c, $d, $stat);
5735         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5736         while (<$log>) {
5737                 if (/^${esc_color}commit -?($::sha1_short)/o) {
5738                         my $cmt = $1;
5739                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5740                                 $r_last = $c->{r};
5741                                 process_commit($c, $r_min, $r_max, \@k) or
5742                                                                 goto out;
5743                         }
5744                         $d = undef;
5745                         $c = { c => $cmt };
5746                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5747                         get_author_info($c, $1, $2, $3);
5748                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5749                         # ignore
5750                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5751                         push @{$c->{raw}}, $_;
5752                 } elsif (/^${esc_color}[ACRMDT]\t/) {
5753                         # we could add $SVN->{svn_path} here, but that requires
5754                         # remote access at the moment (repo_path_split)...
5755                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
5756                         push @{$c->{changed}}, $_;
5757                 } elsif (/^${esc_color}diff /o) {
5758                         $d = 1;
5759                         push @{$c->{diff}}, $_;
5760                 } elsif ($d) {
5761                         push @{$c->{diff}}, $_;
5762                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5763                           $esc_color*[\+\-]*$esc_color$/x) {
5764                         $stat = 1;
5765                         push @{$c->{stat}}, $_;
5766                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5767                         push @{$c->{stat}}, $_;
5768                         $stat = undef;
5769                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
5770                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5771                 } elsif (s/^${esc_color}    //o) {
5772                         push @{$c->{l}}, $_;
5773                 }
5774         }
5775         if ($c && defined $c->{r} && $c->{r} != $r_last) {
5776                 $r_last = $c->{r};
5777                 process_commit($c, $r_min, $r_max, \@k);
5778         }
5779         if (@k) {
5780                 ($r_min, $r_max) = ($r_max, $r_min);
5781                 process_commit($_, $r_min, $r_max) foreach reverse @k;
5782         }
5783 out:
5784         close $log;
5785         print commit_log_separator unless $incremental || $oneline;
5786 }
5787
5788 sub cmd_blame {
5789         my $path = pop;
5790
5791         config_pager();
5792         run_pager();
5793
5794         my ($fh, $ctx, $rev);
5795
5796         if ($_git_format) {
5797                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5798                 while (my $line = <$fh>) {
5799                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5800                                 # Uncommitted edits show up as a rev ID of
5801                                 # all zeros, which we can't look up with
5802                                 # cmt_metadata
5803                                 if ($1 !~ /^0+$/) {
5804                                         (undef, $rev, undef) =
5805                                                 ::cmt_metadata($1);
5806                                         $rev = '0' if (!$rev);
5807                                 } else {
5808                                         $rev = '0';
5809                                 }
5810                                 $rev = sprintf('%-10s', $rev);
5811                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5812                         }
5813                         print $line;
5814                 }
5815         } else {
5816                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5817                                                   '--', $path);
5818                 my ($sha1);
5819                 my %authors;
5820                 my @buffer;
5821                 my %dsha; #distinct sha keys
5822
5823                 while (my $line = <$fh>) {
5824                         push @buffer, $line;
5825                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5826                                 $dsha{$1} = 1;
5827                         }
5828                 }
5829
5830                 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5831
5832                 foreach my $line (@buffer) {
5833                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5834                                 $rev = $s2r->{$1};
5835                                 $rev = '0' if (!$rev)
5836                         }
5837                         elsif ($line =~ /^author (.*)/) {
5838                                 $authors{$rev} = $1;
5839                                 $authors{$rev} =~ s/\s/_/g;
5840                         }
5841                         elsif ($line =~ /^\t(.*)$/) {
5842                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5843                         }
5844                 }
5845         }
5846         command_close_pipe($fh, $ctx);
5847 }
5848
5849 package Git::SVN::Migration;
5850 # these version numbers do NOT correspond to actual version numbers
5851 # of git nor git-svn.  They are just relative.
5852 #
5853 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5854 #
5855 # v1 layout: .git/$id/info/url, refs/remotes/$id
5856 #
5857 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5858 #
5859 # v3 layout: .git/svn/$id, refs/remotes/$id
5860 #            - info/url may remain for backwards compatibility
5861 #            - this is what we migrate up to this layout automatically,
5862 #            - this will be used by git svn init on single branches
5863 # v3.1 layout (auto migrated):
5864 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5865 #              for backwards compatibility
5866 #
5867 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5868 #            - this is only created for newly multi-init-ed
5869 #              repositories.  Similar in spirit to the
5870 #              --use-separate-remotes option in git-clone (now default)
5871 #            - we do not automatically migrate to this (following
5872 #              the example set by core git)
5873 #
5874 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5875 #            - newer, more-efficient format that uses 24-bytes per record
5876 #              with no filler space.
5877 #            - use xxd -c24 < .rev_map.$UUID to view and debug
5878 #            - This is a one-way migration, repositories updated to the
5879 #              new format will not be able to use old git-svn without
5880 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
5881 #              possible if noMetadata or useSvmProps are set; but should
5882 #              be no problem for users that use the (sensible) defaults.
5883 use strict;
5884 use warnings;
5885 use Carp qw/croak/;
5886 use File::Path qw/mkpath/;
5887 use File::Basename qw/dirname basename/;
5888 use vars qw/$_minimize/;
5889
5890 sub migrate_from_v0 {
5891         my $git_dir = $ENV{GIT_DIR};
5892         return undef unless -d $git_dir;
5893         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5894         my $migrated = 0;
5895         while (<$fh>) {
5896                 chomp;
5897                 my ($id, $orig_ref) = ($_, $_);
5898                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5899                 next unless -f "$git_dir/$id/info/url";
5900                 my $new_ref = "refs/remotes/$id";
5901                 if (::verify_ref("$new_ref^0")) {
5902                         print STDERR "W: $orig_ref is probably an old ",
5903                                      "branch used by an ancient version of ",
5904                                      "git-svn.\n",
5905                                      "However, $new_ref also exists.\n",
5906                                      "We will not be able ",
5907                                      "to use this branch until this ",
5908                                      "ambiguity is resolved.\n";
5909                         next;
5910                 }
5911                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5912                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5913                 command_noisy('update-ref', $new_ref, $orig_ref);
5914                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5915                 $migrated++;
5916         }
5917         command_close_pipe($fh, $ctx);
5918         print STDERR "Done migrating from v0 layout...\n" if $migrated;
5919         $migrated;
5920 }
5921
5922 sub migrate_from_v1 {
5923         my $git_dir = $ENV{GIT_DIR};
5924         my $migrated = 0;
5925         return $migrated unless -d $git_dir;
5926         my $svn_dir = "$git_dir/svn";
5927
5928         # just in case somebody used 'svn' as their $id at some point...
5929         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5930
5931         print STDERR "Migrating from a git-svn v1 layout...\n";
5932         mkpath([$svn_dir]);
5933         print STDERR "Data from a previous version of git-svn exists, but\n\t",
5934                      "$svn_dir\n\t(required for this version ",
5935                      "($::VERSION) of git-svn) does not exist.\n";
5936         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5937         while (<$fh>) {
5938                 my $x = $_;
5939                 next unless $x =~ s#^refs/remotes/##;
5940                 chomp $x;
5941                 next unless -f "$git_dir/$x/info/url";
5942                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5943                 next unless $u;
5944                 my $dn = dirname("$git_dir/svn/$x");
5945                 mkpath([$dn]) unless -d $dn;
5946                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5947                         mkpath(["$git_dir/svn/svn"]);
5948                         print STDERR " - $git_dir/$x/info => ",
5949                                         "$git_dir/svn/$x/info\n";
5950                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5951                                croak "$!: $x";
5952                         # don't worry too much about these, they probably
5953                         # don't exist with repos this old (save for index,
5954                         # and we can easily regenerate that)
5955                         foreach my $f (qw/unhandled.log index .rev_db/) {
5956                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5957                         }
5958                 } else {
5959                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5960                         rename "$git_dir/$x", "$git_dir/svn/$x" or
5961                                croak "$!: $x";
5962                 }
5963                 $migrated++;
5964         }
5965         command_close_pipe($fh, $ctx);
5966         print STDERR "Done migrating from a git-svn v1 layout\n";
5967         $migrated;
5968 }
5969
5970 sub read_old_urls {
5971         my ($l_map, $pfx, $path) = @_;
5972         my @dir;
5973         foreach (<$path/*>) {
5974                 if (-r "$_/info/url") {
5975                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5976                         my $ref_id = $pfx . basename $_;
5977                         my $url = ::file_to_s("$_/info/url");
5978                         $l_map->{$ref_id} = $url;
5979                 } elsif (-d $_) {
5980                         push @dir, $_;
5981                 }
5982         }
5983         foreach (@dir) {
5984                 my $x = $_;
5985                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5986                 read_old_urls($l_map, $x, $_);
5987         }
5988 }
5989
5990 sub migrate_from_v2 {
5991         my @cfg = command(qw/config -l/);
5992         return if grep /^svn-remote\..+\.url=/, @cfg;
5993         my %l_map;
5994         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5995         my $migrated = 0;
5996
5997         foreach my $ref_id (sort keys %l_map) {
5998                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5999                 if ($@) {
6000                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
6001                 }
6002                 $migrated++;
6003         }
6004         $migrated;
6005 }
6006
6007 sub minimize_connections {
6008         my $r = Git::SVN::read_all_remotes();
6009         my $new_urls = {};
6010         my $root_repos = {};
6011         foreach my $repo_id (keys %$r) {
6012                 my $url = $r->{$repo_id}->{url} or next;
6013                 my $fetch = $r->{$repo_id}->{fetch} or next;
6014                 my $ra = Git::SVN::Ra->new($url);
6015
6016                 # skip existing cases where we already connect to the root
6017                 if (($ra->{url} eq $ra->{repos_root}) ||
6018                     ($ra->{repos_root} eq $repo_id)) {
6019                         $root_repos->{$ra->{url}} = $repo_id;
6020                         next;
6021                 }
6022
6023                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
6024                 my $root_path = $ra->{url};
6025                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
6026                 foreach my $path (keys %$fetch) {
6027                         my $ref_id = $fetch->{$path};
6028                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
6029
6030                         # make sure we can read when connecting to
6031                         # a higher level of a repository
6032                         my ($last_rev, undef) = $gs->last_rev_commit;
6033                         if (!defined $last_rev) {
6034                                 $last_rev = eval {
6035                                         $root_ra->get_latest_revnum;
6036                                 };
6037                                 next if $@;
6038                         }
6039                         my $new = $root_path;
6040                         $new .= length $path ? "/$path" : '';
6041                         eval {
6042                                 $root_ra->get_log([$new], $last_rev, $last_rev,
6043                                                   0, 0, 1, sub { });
6044                         };
6045                         next if $@;
6046                         $new_urls->{$ra->{repos_root}}->{$new} =
6047                                 { ref_id => $ref_id,
6048                                   old_repo_id => $repo_id,
6049                                   old_path => $path };
6050                 }
6051         }
6052
6053         my @emptied;
6054         foreach my $url (keys %$new_urls) {
6055                 # see if we can re-use an existing [svn-remote "repo_id"]
6056                 # instead of creating a(n ugly) new section:
6057                 my $repo_id = $root_repos->{$url} || $url;
6058
6059                 my $fetch = $new_urls->{$url};
6060                 foreach my $path (keys %$fetch) {
6061                         my $x = $fetch->{$path};
6062                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
6063                         my $pfx = "svn-remote.$x->{old_repo_id}";
6064
6065                         my $old_fetch = quotemeta("$x->{old_path}:".
6066                                                   "$x->{ref_id}");
6067                         command_noisy(qw/config --unset/,
6068                                       "$pfx.fetch", '^'. $old_fetch . '$');
6069                         delete $r->{$x->{old_repo_id}}->
6070                                {fetch}->{$x->{old_path}};
6071                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
6072                                 command_noisy(qw/config --unset/,
6073                                               "$pfx.url");
6074                                 push @emptied, $x->{old_repo_id}
6075                         }
6076                 }
6077         }
6078         if (@emptied) {
6079                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
6080                 print STDERR <<EOF;
6081 The following [svn-remote] sections in your config file ($file) are empty
6082 and can be safely removed:
6083 EOF
6084                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
6085         }
6086 }
6087
6088 sub migration_check {
6089         migrate_from_v0();
6090         migrate_from_v1();
6091         migrate_from_v2();
6092         minimize_connections() if $_minimize;
6093 }
6094
6095 package Git::IndexInfo;
6096 use strict;
6097 use warnings;
6098 use Git qw/command_input_pipe command_close_pipe/;
6099
6100 sub new {
6101         my ($class) = @_;
6102         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
6103         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
6104 }
6105
6106 sub remove {
6107         my ($self, $path) = @_;
6108         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
6109                 return ++$self->{nr};
6110         }
6111         undef;
6112 }
6113
6114 sub update {
6115         my ($self, $mode, $hash, $path) = @_;
6116         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
6117                 return ++$self->{nr};
6118         }
6119         undef;
6120 }
6121
6122 sub DESTROY {
6123         my ($self) = @_;
6124         command_close_pipe($self->{gui}, $self->{ctx});
6125 }
6126
6127 package Git::SVN::GlobSpec;
6128 use strict;
6129 use warnings;
6130
6131 sub new {
6132         my ($class, $glob, $pattern_ok) = @_;
6133         my $re = $glob;
6134         $re =~ s!/+$!!g; # no need for trailing slashes
6135         my (@left, @right, @patterns);
6136         my $state = "left";
6137         my $die_msg = "Only one set of wildcard directories " .
6138                                 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
6139         for my $part (split(m|/|, $glob)) {
6140                 if ($part =~ /\*/ && $part ne "*") {
6141                         die "Invalid pattern in '$glob': $part\n";
6142                 } elsif ($pattern_ok && $part =~ /[{}]/ &&
6143                          $part !~ /^\{[^{}]+\}/) {
6144                         die "Invalid pattern in '$glob': $part\n";
6145                 }
6146                 if ($part eq "*") {
6147                         die $die_msg if $state eq "right";
6148                         $state = "pattern";
6149                         push(@patterns, "[^/]*");
6150                 } elsif ($pattern_ok && $part =~ /^\{(.*)\}$/) {
6151                         die $die_msg if $state eq "right";
6152                         $state = "pattern";
6153                         my $p = quotemeta($1);
6154                         $p =~ s/\\,/|/g;
6155                         push(@patterns, "(?:$p)");
6156                 } else {
6157                         if ($state eq "left") {
6158                                 push(@left, $part);
6159                         } else {
6160                                 push(@right, $part);
6161                                 $state = "right";
6162                         }
6163                 }
6164         }
6165         my $depth = @patterns;
6166         if ($depth == 0) {
6167                 die "One '*' is needed in glob: '$glob'\n";
6168         }
6169         my $left = join('/', @left);
6170         my $right = join('/', @right);
6171         $re = join('/', @patterns);
6172         $re = join('\/',
6173                    grep(length, quotemeta($left), "($re)", quotemeta($right)));
6174         my $left_re = qr/^\/\Q$left\E(\/|$)/;
6175         bless { left => $left, right => $right, left_regex => $left_re,
6176                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
6177 }
6178
6179 sub full_path {
6180         my ($self, $path) = @_;
6181         return (length $self->{left} ? "$self->{left}/" : '') .
6182                $path . (length $self->{right} ? "/$self->{right}" : '');
6183 }
6184
6185 __END__
6186
6187 Data structures:
6188
6189
6190 $remotes = { # returned by read_all_remotes()
6191         'svn' => {
6192                 # svn-remote.svn.url=https://svn.musicpd.org
6193                 url => 'https://svn.musicpd.org',
6194                 # svn-remote.svn.fetch=mpd/trunk:trunk
6195                 fetch => {
6196                         'mpd/trunk' => 'trunk',
6197                 },
6198                 # svn-remote.svn.tags=mpd/tags/*:tags/*
6199                 tags => {
6200                         path => {
6201                                 left => 'mpd/tags',
6202                                 right => '',
6203                                 regex => qr!mpd/tags/([^/]+)$!,
6204                                 glob => 'tags/*',
6205                         },
6206                         ref => {
6207                                 left => 'tags',
6208                                 right => '',
6209                                 regex => qr!tags/([^/]+)$!,
6210                                 glob => 'tags/*',
6211                         },
6212                 }
6213         }
6214 };
6215
6216 $log_entry hashref as returned by libsvn_log_entry()
6217 {
6218         log => 'whitespace-formatted log entry
6219 ',                                              # trailing newline is preserved
6220         revision => '8',                        # integer
6221         date => '2004-02-24T17:01:44.108345Z',  # commit date
6222         author => 'committer name'
6223 };
6224
6225
6226 # this is generated by generate_diff();
6227 @mods = array of diff-index line hashes, each element represents one line
6228         of diff-index output
6229
6230 diff-index line ($m hash)
6231 {
6232         mode_a => first column of diff-index output, no leading ':',
6233         mode_b => second column of diff-index output,
6234         sha1_b => sha1sum of the final blob,
6235         chg => change type [MCRADT],
6236         file_a => original file name of a file (iff chg is 'C' or 'R')
6237         file_b => new/current file name of a file (any chg)
6238 }
6239 ;
6240
6241 # retval of read_url_paths{,_all}();
6242 $l_map = {
6243         # repository root url
6244         'https://svn.musicpd.org' => {
6245                 # repository path               # GIT_SVN_ID
6246                 'mpd/trunk'             =>      'trunk',
6247                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
6248         },
6249 }
6250
6251 Notes:
6252         I don't trust the each() function on unless I created %hash myself
6253         because the internal iterator may not have started at base.