git.oblomov.eu Git - git/blob - git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [string map [list (c) \u00a9] {
  14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title "git-gui: fatal error" \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 if { [info exists ::env(GIT_GUI_LIB_DIR) ] } {
  53         set oguilib $::env(GIT_GUI_LIB_DIR)
  54 } else {
  55         set oguilib {@@GITGUI_LIBDIR@@}
  56 }
  57 set oguirel {@@GITGUI_RELATIVE@@}
  58 if {$oguirel eq {1}} {
  59         set oguilib [file dirname [file normalize $argv0]]
  60         if {[file tail $oguilib] eq {git-core}} {
  61                 set oguilib [file dirname $oguilib]
  62         }
  63         set oguilib [file dirname $oguilib]
  64         set oguilib [file join $oguilib share git-gui lib]
  65         set oguimsg [file join $oguilib msgs]
  66 } elseif {[string match @@* $oguirel]} {
  67         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  68         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  69 } else {
  70         set oguimsg [file join $oguilib msgs]
  71 }
  72 unset oguirel
  73
  74 ######################################################################
  75 ##
  76 ## enable verbose loading?
  77
  78 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  79         unset _verbose
  80         rename auto_load real__auto_load
  81         proc auto_load {name args} {
  82                 puts stderr "auto_load $name"
  83                 return [uplevel 1 real__auto_load $name $args]
  84         }
  85         rename source real__source
  86         proc source {args} {
  87                 puts stderr "source    $args"
  88                 uplevel 1 [linsert $args 0 real__source]
  89         }
  90         if {[tk windowingsystem] eq "win32"} { console show }
  91 }
  92
  93 ######################################################################
  94 ##
  95 ## Internationalization (i18n) through msgcat and gettext. See
  96 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  97
  98 package require msgcat
  99
 100 # Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
 101 if {[tk windowingsystem] eq "win32"
 102         && [package vcompare [package provide msgcat] 1.4.4] < 0
 103 } then {
 104         proc _mc_update_locale {} {
 105                 set key {HKEY_CURRENT_USER\Control Panel\Desktop}
 106                 if {![catch {
 107                         package require registry
 108                         set uilocale [registry get $key "PreferredUILanguages"]
 109                         msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
 110                 } uilocale]} {
 111                         if {[string length $uilocale] > 0} {
 112                                 msgcat::mclocale $uilocale
 113                         }
 114                 }
 115         }
 116         _mc_update_locale
 117 }
 118
 119 proc _mc_trim {fmt} {
 120         set cmk [string first @@ $fmt]
 121         if {$cmk > 0} {
 122                 return [string range $fmt 0 [expr {$cmk - 1}]]
 123         }
 124         return $fmt
 125 }
 126
 127 proc mc {en_fmt args} {
 128         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 129         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 130                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 131         }
 132         return $msg
 133 }
 134
 135 proc strcat {args} {
 136         return [join $args {}]
 137 }
 138
 139 ::msgcat::mcload $oguimsg
 140 unset oguimsg
 141
 142 ######################################################################
 143 ##
 144 ## On Mac, bring the current Wish process window to front
 145
 146 if {[tk windowingsystem] eq "aqua"} {
 147         catch {
 148                 exec osascript -e [format {
 149                         tell application "System Events"
 150                                 set frontmost of processes whose unix id is %d to true
 151                         end tell
 152                 } [pid]]
 153         }
 154 }
 155
 156 ######################################################################
 157 ##
 158 ## read only globals
 159
 160 set _appname {Git Gui}
 161 set _gitdir {}
 162 set _gitworktree {}
 163 set _isbare {}
 164 set _gitexec {}
 165 set _githtmldir {}
 166 set _reponame {}
 167 set _iscygwin {}
 168 set _search_path {}
 169 set _shellpath {@@SHELL_PATH@@}
 170
 171 set _trace [lsearch -exact $argv --trace]
 172 if {$_trace >= 0} {
 173         set argv [lreplace $argv $_trace $_trace]
 174         set _trace 1
 175         if {[tk windowingsystem] eq "win32"} { console show }
 176 } else {
 177         set _trace 0
 178 }
 179
 180 # variable for the last merged branch (useful for a default when deleting
 181 # branches).
 182 set _last_merged_branch {}
 183
 184 proc shellpath {} {
 185         global _shellpath env
 186         if {[string match @@* $_shellpath]} {
 187                 if {[info exists env(SHELL)]} {
 188                         return $env(SHELL)
 189                 } else {
 190                         return /bin/sh
 191                 }
 192         }
 193         return $_shellpath
 194 }
 195
 196 proc appname {} {
 197         global _appname
 198         return $_appname
 199 }
 200
 201 proc gitdir {args} {
 202         global _gitdir
 203         if {$args eq {}} {
 204                 return $_gitdir
 205         }
 206         return [eval [list file join $_gitdir] $args]
 207 }
 208
 209 proc gitexec {args} {
 210         global _gitexec
 211         if {$_gitexec eq {}} {
 212                 if {[catch {set _gitexec [git --exec-path]} err]} {
 213                         error "Git not installed?\n\n$err"
 214                 }
 215                 if {[is_Cygwin]} {
 216                         set _gitexec [exec cygpath \
 217                                 --windows \
 218                                 --absolute \
 219                                 $_gitexec]
 220                 } else {
 221                         set _gitexec [file normalize $_gitexec]
 222                 }
 223         }
 224         if {$args eq {}} {
 225                 return $_gitexec
 226         }
 227         return [eval [list file join $_gitexec] $args]
 228 }
 229
 230 proc githtmldir {args} {
 231         global _githtmldir
 232         if {$_githtmldir eq {}} {
 233                 if {[catch {set _githtmldir [git --html-path]}]} {
 234                         # Git not installed or option not yet supported
 235                         return {}
 236                 }
 237                 if {[is_Cygwin]} {
 238                         set _githtmldir [exec cygpath \
 239                                 --windows \
 240                                 --absolute \
 241                                 $_githtmldir]
 242                 } else {
 243                         set _githtmldir [file normalize $_githtmldir]
 244                 }
 245         }
 246         if {$args eq {}} {
 247                 return $_githtmldir
 248         }
 249         return [eval [list file join $_githtmldir] $args]
 250 }
 251
 252 proc reponame {} {
 253         return $::_reponame
 254 }
 255
 256 proc is_MacOSX {} {
 257         if {[tk windowingsystem] eq {aqua}} {
 258                 return 1
 259         }
 260         return 0
 261 }
 262
 263 proc is_Windows {} {
 264         if {$::tcl_platform(platform) eq {windows}} {
 265                 return 1
 266         }
 267         return 0
 268 }
 269
 270 proc is_Cygwin {} {
 271         global _iscygwin
 272         if {$_iscygwin eq {}} {
 273                 if {$::tcl_platform(platform) eq {windows}} {
 274                         if {[catch {set p [exec cygpath --windir]} err]} {
 275                                 set _iscygwin 0
 276                         } else {
 277                                 set _iscygwin 1
 278                                 # Handle MSys2 which is only cygwin when MSYSTEM is MSYS.
 279                                 if {[info exists ::env(MSYSTEM)] && $::env(MSYSTEM) ne "MSYS"} {
 280                                         set _iscygwin 0
 281                                 }
 282                         }
 283                 } else {
 284                         set _iscygwin 0
 285                 }
 286         }
 287         return $_iscygwin
 288 }
 289
 290 proc is_enabled {option} {
 291         global enabled_options
 292         if {[catch {set on $enabled_options($option)}]} {return 0}
 293         return $on
 294 }
 295
 296 proc enable_option {option} {
 297         global enabled_options
 298         set enabled_options($option) 1
 299 }
 300
 301 proc disable_option {option} {
 302         global enabled_options
 303         set enabled_options($option) 0
 304 }
 305
 306 ######################################################################
 307 ##
 308 ## config
 309
 310 proc is_many_config {name} {
 311         switch -glob -- $name {
 312         gui.recentrepo -
 313         remote.*.fetch -
 314         remote.*.push
 315                 {return 1}
 316         *
 317                 {return 0}
 318         }
 319 }
 320
 321 proc is_config_true {name} {
 322         global repo_config
 323         if {[catch {set v $repo_config($name)}]} {
 324                 return 0
 325         }
 326         set v [string tolower $v]
 327         if {$v eq {} || $v eq {true} || $v eq {1} || $v eq {yes} || $v eq {on}} {
 328                 return 1
 329         } else {
 330                 return 0
 331         }
 332 }
 333
 334 proc is_config_false {name} {
 335         global repo_config
 336         if {[catch {set v $repo_config($name)}]} {
 337                 return 0
 338         }
 339         set v [string tolower $v]
 340         if {$v eq {false} || $v eq {0} || $v eq {no} || $v eq {off}} {
 341                 return 1
 342         } else {
 343                 return 0
 344         }
 345 }
 346
 347 proc get_config {name} {
 348         global repo_config
 349         if {[catch {set v $repo_config($name)}]} {
 350                 return {}
 351         } else {
 352                 return $v
 353         }
 354 }
 355
 356 proc is_bare {} {
 357         global _isbare
 358         global _gitdir
 359         global _gitworktree
 360
 361         if {$_isbare eq {}} {
 362                 if {[catch {
 363                         set _bare [git rev-parse --is-bare-repository]
 364                         switch  -- $_bare {
 365                         true { set _isbare 1 }
 366                         false { set _isbare 0}
 367                         default { throw }
 368                         }
 369                 }]} {
 370                         if {[is_config_true core.bare]
 371                                 || ($_gitworktree eq {}
 372                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 373                                 set _isbare 1
 374                         } else {
 375                                 set _isbare 0
 376                         }
 377                 }
 378         }
 379         return $_isbare
 380 }
 381
 382 ######################################################################
 383 ##
 384 ## handy utils
 385
 386 proc _trace_exec {cmd} {
 387         if {!$::_trace} return
 388         set d {}
 389         foreach v $cmd {
 390                 if {$d ne {}} {
 391                         append d { }
 392                 }
 393                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 394                         set v [sq $v]
 395                 }
 396                 append d $v
 397         }
 398         puts stderr $d
 399 }
 400
 401 #'"  fix poor old emacs font-lock mode
 402
 403 proc _git_cmd {name} {
 404         global _git_cmd_path
 405
 406         if {[catch {set v $_git_cmd_path($name)}]} {
 407                 switch -- $name {
 408                   version   -
 409                 --version   -
 410                 --exec-path { return [list $::_git $name] }
 411                 }
 412
 413                 set p [gitexec git-$name$::_search_exe]
 414                 if {[file exists $p]} {
 415                         set v [list $p]
 416                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 417                         # Try to determine what sort of magic will make
 418                         # git-$name go and do its thing, because native
 419                         # Tcl on Windows doesn't know it.
 420                         #
 421                         set p [gitexec git-$name]
 422                         set f [open $p r]
 423                         set s [gets $f]
 424                         close $f
 425
 426                         switch -glob -- [lindex $s 0] {
 427                         #!*sh     { set i sh     }
 428                         #!*perl   { set i perl   }
 429                         #!*python { set i python }
 430                         default   { error "git-$name is not supported: $s" }
 431                         }
 432
 433                         upvar #0 _$i interp
 434                         if {![info exists interp]} {
 435                                 set interp [_which $i]
 436                         }
 437                         if {$interp eq {}} {
 438                                 error "git-$name requires $i (not in PATH)"
 439                         }
 440                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 441                 } else {
 442                         # Assume it is builtin to git somehow and we
 443                         # aren't actually able to see a file for it.
 444                         #
 445                         set v [list $::_git $name]
 446                 }
 447                 set _git_cmd_path($name) $v
 448         }
 449         return $v
 450 }
 451
 452 proc _which {what args} {
 453         global env _search_exe _search_path
 454
 455         if {$_search_path eq {}} {
 456                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 457                         set _search_path [split [exec cygpath \
 458                                 --windows \
 459                                 --path \
 460                                 --absolute \
 461                                 $env(PATH)] {;}]
 462                         set _search_exe .exe
 463                 } elseif {[is_Windows]} {
 464                         set gitguidir [file dirname [info script]]
 465                         regsub -all ";" $gitguidir "\\;" gitguidir
 466                         set env(PATH) "$gitguidir;$env(PATH)"
 467                         set _search_path [split $env(PATH) {;}]
 468                         set _search_exe .exe
 469                 } else {
 470                         set _search_path [split $env(PATH) :]
 471                         set _search_exe {}
 472                 }
 473         }
 474
 475         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 476                 set suffix {}
 477         } else {
 478                 set suffix $_search_exe
 479         }
 480
 481         foreach p $_search_path {
 482                 set p [file join $p $what$suffix]
 483                 if {[file exists $p]} {
 484                         return [file normalize $p]
 485                 }
 486         }
 487         return {}
 488 }
 489
 490 # Test a file for a hashbang to identify executable scripts on Windows.
 491 proc is_shellscript {filename} {
 492         if {![file exists $filename]} {return 0}
 493         set f [open $filename r]
 494         fconfigure $f -encoding binary
 495         set magic [read $f 2]
 496         close $f
 497         return [expr {$magic eq "#!"}]
 498 }
 499
 500 # Run a command connected via pipes on stdout.
 501 # This is for use with textconv filters and uses sh -c "..." to allow it to
 502 # contain a command with arguments. On windows we must check for shell
 503 # scripts specifically otherwise just call the filter command.
 504 proc open_cmd_pipe {cmd path} {
 505         global env
 506         if {![file executable [shellpath]]} {
 507                 set exe [auto_execok [lindex $cmd 0]]
 508                 if {[is_shellscript [lindex $exe 0]]} {
 509                         set run [linsert [auto_execok sh] end -c "$cmd \"\$0\"" $path]
 510                 } else {
 511                         set run [concat $exe [lrange $cmd 1 end] $path]
 512                 }
 513         } else {
 514                 set run [list [shellpath] -c "$cmd \"\$0\"" $path]
 515         }
 516         return [open |$run r]
 517 }
 518
 519 proc _lappend_nice {cmd_var} {
 520         global _nice
 521         upvar $cmd_var cmd
 522
 523         if {![info exists _nice]} {
 524                 set _nice [_which nice]
 525                 if {[catch {exec $_nice git version}]} {
 526                         set _nice {}
 527                 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 528                         set _nice {}
 529                 }
 530         }
 531         if {$_nice ne {}} {
 532                 lappend cmd $_nice
 533         }
 534 }
 535
 536 proc git {args} {
 537         set opt [list]
 538
 539         while {1} {
 540                 switch -- [lindex $args 0] {
 541                 --nice {
 542                         _lappend_nice opt
 543                 }
 544
 545                 default {
 546                         break
 547                 }
 548
 549                 }
 550
 551                 set args [lrange $args 1 end]
 552         }
 553
 554         set cmdp [_git_cmd [lindex $args 0]]
 555         set args [lrange $args 1 end]
 556
 557         _trace_exec [concat $opt $cmdp $args]
 558         set result [eval exec $opt $cmdp $args]
 559         if {$::_trace} {
 560                 puts stderr "< $result"
 561         }
 562         return $result
 563 }
 564
 565 proc _open_stdout_stderr {cmd} {
 566         _trace_exec $cmd
 567         if {[catch {
 568                         set fd [open [concat [list | ] $cmd] r]
 569                 } err]} {
 570                 if {   [lindex $cmd end] eq {2>@1}
 571                     && $err eq {can not find channel named "1"}
 572                         } {
 573                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 574                         # redirect operator.  Fallback to |& cat for those.
 575                         # The command was not actually started, so its safe
 576                         # to try to start it a second time.
 577                         #
 578                         set fd [open [concat \
 579                                 [list | ] \
 580                                 [lrange $cmd 0 end-1] \
 581                                 [list |& cat] \
 582                                 ] r]
 583                 } else {
 584                         error $err
 585                 }
 586         }
 587         fconfigure $fd -eofchar {}
 588         return $fd
 589 }
 590
 591 proc git_read {args} {
 592         set opt [list]
 593
 594         while {1} {
 595                 switch -- [lindex $args 0] {
 596                 --nice {
 597                         _lappend_nice opt
 598                 }
 599
 600                 --stderr {
 601                         lappend args 2>@1
 602                 }
 603
 604                 default {
 605                         break
 606                 }
 607
 608                 }
 609
 610                 set args [lrange $args 1 end]
 611         }
 612
 613         set cmdp [_git_cmd [lindex $args 0]]
 614         set args [lrange $args 1 end]
 615
 616         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 617 }
 618
 619 proc git_write {args} {
 620         set opt [list]
 621
 622         while {1} {
 623                 switch -- [lindex $args 0] {
 624                 --nice {
 625                         _lappend_nice opt
 626                 }
 627
 628                 default {
 629                         break
 630                 }
 631
 632                 }
 633
 634                 set args [lrange $args 1 end]
 635         }
 636
 637         set cmdp [_git_cmd [lindex $args 0]]
 638         set args [lrange $args 1 end]
 639
 640         _trace_exec [concat $opt $cmdp $args]
 641         return [open [concat [list | ] $opt $cmdp $args] w]
 642 }
 643
 644 proc githook_read {hook_name args} {
 645         set pchook [gitdir hooks $hook_name]
 646         lappend args 2>@1
 647
 648         # On Windows [file executable] might lie so we need to ask
 649         # the shell if the hook is executable.  Yes that's annoying.
 650         #
 651         if {[is_Windows]} {
 652                 upvar #0 _sh interp
 653                 if {![info exists interp]} {
 654                         set interp [_which sh]
 655                 }
 656                 if {$interp eq {}} {
 657                         error "hook execution requires sh (not in PATH)"
 658                 }
 659
 660                 set scr {if test -x "$1";then exec "$@";fi}
 661                 set sh_c [list $interp -c $scr $interp $pchook]
 662                 return [_open_stdout_stderr [concat $sh_c $args]]
 663         }
 664
 665         if {[file executable $pchook]} {
 666                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 667         }
 668
 669         return {}
 670 }
 671
 672 proc kill_file_process {fd} {
 673         set process [pid $fd]
 674
 675         catch {
 676                 if {[is_Windows]} {
 677                         exec taskkill /pid $process
 678                 } else {
 679                         exec kill $process
 680                 }
 681         }
 682 }
 683
 684 proc gitattr {path attr default} {
 685         if {[catch {set r [git check-attr $attr -- $path]}]} {
 686                 set r unspecified
 687         } else {
 688                 set r [join [lrange [split $r :] 2 end] :]
 689                 regsub {^ } $r {} r
 690         }
 691         if {$r eq {unspecified}} {
 692                 return $default
 693         }
 694         return $r
 695 }
 696
 697 proc sq {value} {
 698         regsub -all ' $value "'\\''" value
 699         return "'$value'"
 700 }
 701
 702 proc load_current_branch {} {
 703         global current_branch is_detached
 704
 705         set fd [open [gitdir HEAD] r]
 706         if {[gets $fd ref] < 1} {
 707                 set ref {}
 708         }
 709         close $fd
 710
 711         set pfx {ref: refs/heads/}
 712         set len [string length $pfx]
 713         if {[string equal -length $len $pfx $ref]} {
 714                 # We're on a branch.  It might not exist.  But
 715                 # HEAD looks good enough to be a branch.
 716                 #
 717                 set current_branch [string range $ref $len end]
 718                 set is_detached 0
 719         } else {
 720                 # Assume this is a detached head.
 721                 #
 722                 set current_branch HEAD
 723                 set is_detached 1
 724         }
 725 }
 726
 727 auto_load tk_optionMenu
 728 rename tk_optionMenu real__tkOptionMenu
 729 proc tk_optionMenu {w varName args} {
 730         set m [eval real__tkOptionMenu $w $varName $args]
 731         $m configure -font font_ui
 732         $w configure -font font_ui
 733         return $m
 734 }
 735
 736 proc rmsel_tag {text} {
 737         $text tag conf sel \
 738                 -background [$text cget -background] \
 739                 -foreground [$text cget -foreground] \
 740                 -borderwidth 0
 741         $text tag conf in_sel -background lightgray
 742         bind $text <Motion> break
 743         return $text
 744 }
 745
 746 wm withdraw .
 747 set root_exists 0
 748 bind . <Visibility> {
 749         bind . <Visibility> {}
 750         set root_exists 1
 751 }
 752
 753 if {[is_Windows]} {
 754         wm iconbitmap . -default $oguilib/git-gui.ico
 755         set ::tk::AlwaysShowSelection 1
 756         bind . <Control-F2> {console show}
 757
 758         # Spoof an X11 display for SSH
 759         if {![info exists env(DISPLAY)]} {
 760                 set env(DISPLAY) :9999
 761         }
 762 } else {
 763         catch {
 764                 image create photo gitlogo -width 16 -height 16
 765
 766                 gitlogo put #33CC33 -to  7  0  9  2
 767                 gitlogo put #33CC33 -to  4  2 12  4
 768                 gitlogo put #33CC33 -to  7  4  9  6
 769                 gitlogo put #CC3333 -to  4  6 12  8
 770                 gitlogo put gray26  -to  4  9  6 10
 771                 gitlogo put gray26  -to  3 10  6 12
 772                 gitlogo put gray26  -to  8  9 13 11
 773                 gitlogo put gray26  -to  8 11 10 12
 774                 gitlogo put gray26  -to 11 11 13 14
 775                 gitlogo put gray26  -to  3 12  5 14
 776                 gitlogo put gray26  -to  5 13
 777                 gitlogo put gray26  -to 10 13
 778                 gitlogo put gray26  -to  4 14 12 15
 779                 gitlogo put gray26  -to  5 15 11 16
 780                 gitlogo redither
 781
 782                 image create photo gitlogo32 -width 32 -height 32
 783                 gitlogo32 copy gitlogo -zoom 2 2
 784
 785                 wm iconphoto . -default gitlogo gitlogo32
 786         }
 787 }
 788
 789 ######################################################################
 790 ##
 791 ## config defaults
 792
 793 set cursor_ptr arrow
 794 font create font_ui
 795 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 796         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 797         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 798 } else {
 799         font create font_diff -family Courier -size 10
 800         catch {
 801                 label .dummy
 802                 eval font configure font_ui [font actual [.dummy cget -font]]
 803                 destroy .dummy
 804         }
 805 }
 806
 807 font create font_uiitalic
 808 font create font_uibold
 809 font create font_diffbold
 810 font create font_diffitalic
 811
 812 foreach class {Button Checkbutton Entry Label
 813                 Labelframe Listbox Message
 814                 Radiobutton Spinbox Text} {
 815         option add *$class.font font_ui
 816 }
 817 if {![is_MacOSX]} {
 818         option add *Menu.font font_ui
 819         option add *Entry.borderWidth 1 startupFile
 820         option add *Entry.relief sunken startupFile
 821         option add *RadioButton.anchor w startupFile
 822 }
 823 unset class
 824
 825 if {[is_Windows] || [is_MacOSX]} {
 826         option add *Menu.tearOff 0
 827 }
 828
 829 if {[is_MacOSX]} {
 830         set M1B M1
 831         set M1T Cmd
 832 } else {
 833         set M1B Control
 834         set M1T Ctrl
 835 }
 836
 837 proc bind_button3 {w cmd} {
 838         bind $w <Any-Button-3> $cmd
 839         if {[is_MacOSX]} {
 840                 # Mac OS X sends Button-2 on right click through three-button mouse,
 841                 # or through trackpad right-clicking (two-finger touch + click).
 842                 bind $w <Any-Button-2> $cmd
 843                 bind $w <Control-Button-1> $cmd
 844         }
 845 }
 846
 847 proc apply_config {} {
 848         global repo_config font_descs
 849
 850         foreach option $font_descs {
 851                 set name [lindex $option 0]
 852                 set font [lindex $option 1]
 853                 if {[catch {
 854                         set need_weight 1
 855                         foreach {cn cv} $repo_config(gui.$name) {
 856                                 if {$cn eq {-weight}} {
 857                                         set need_weight 0
 858                                 }
 859                                 font configure $font $cn $cv
 860                         }
 861                         if {$need_weight} {
 862                                 font configure $font -weight normal
 863                         }
 864                         } err]} {
 865                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 866                 }
 867                 foreach {cn cv} [font configure $font] {
 868                         font configure ${font}bold $cn $cv
 869                         font configure ${font}italic $cn $cv
 870                 }
 871                 font configure ${font}bold -weight bold
 872                 font configure ${font}italic -slant italic
 873         }
 874
 875         global use_ttk NS
 876         set use_ttk 0
 877         set NS {}
 878         if {$repo_config(gui.usettk)} {
 879                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 880                 if {$use_ttk} {
 881                         set NS ttk
 882                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 883                         pave_toplevel .
 884                 }
 885         }
 886 }
 887
 888 set default_config(branch.autosetupmerge) true
 889 set default_config(merge.tool) {}
 890 set default_config(mergetool.keepbackup) true
 891 set default_config(merge.diffstat) true
 892 set default_config(merge.summary) false
 893 set default_config(merge.verbosity) 2
 894 set default_config(user.name) {}
 895 set default_config(user.email) {}
 896
 897 set default_config(gui.encoding) [encoding system]
 898 set default_config(gui.matchtrackingbranch) false
 899 set default_config(gui.textconv) true
 900 set default_config(gui.pruneduringfetch) false
 901 set default_config(gui.trustmtime) false
 902 set default_config(gui.fastcopyblame) false
 903 set default_config(gui.maxrecentrepo) 10
 904 set default_config(gui.copyblamethreshold) 40
 905 set default_config(gui.blamehistoryctx) 7
 906 set default_config(gui.diffcontext) 5
 907 set default_config(gui.diffopts) {}
 908 set default_config(gui.commitmsgwidth) 75
 909 set default_config(gui.newbranchtemplate) {}
 910 set default_config(gui.spellingdictionary) {}
 911 set default_config(gui.fontui) [font configure font_ui]
 912 set default_config(gui.fontdiff) [font configure font_diff]
 913 # TODO: this option should be added to the git-config documentation
 914 set default_config(gui.maxfilesdisplayed) 5000
 915 set default_config(gui.usettk) 1
 916 set default_config(gui.warndetachedcommit) 1
 917 set default_config(gui.tabsize) 8
 918 set font_descs {
 919         {fontui   font_ui   {mc "Main Font"}}
 920         {fontdiff font_diff {mc "Diff/Console Font"}}
 921 }
 922 set default_config(gui.stageuntracked) ask
 923 set default_config(gui.displayuntracked) true
 924
 925 ######################################################################
 926 ##
 927 ## find git
 928
 929 set _git  [_which git]
 930 if {$_git eq {}} {
 931         catch {wm withdraw .}
 932         tk_messageBox \
 933                 -icon error \
 934                 -type ok \
 935                 -title [mc "git-gui: fatal error"] \
 936                 -message [mc "Cannot find git in PATH."]
 937         exit 1
 938 }
 939
 940 ######################################################################
 941 ##
 942 ## version check
 943
 944 if {[catch {set _git_version [git --version]} err]} {
 945         catch {wm withdraw .}
 946         tk_messageBox \
 947                 -icon error \
 948                 -type ok \
 949                 -title [mc "git-gui: fatal error"] \
 950                 -message "Cannot determine Git version:
 951
 952 $err
 953
 954 [appname] requires Git 1.5.0 or later."
 955         exit 1
 956 }
 957 if {![regsub {^git version } $_git_version {} _git_version]} {
 958         catch {wm withdraw .}
 959         tk_messageBox \
 960                 -icon error \
 961                 -type ok \
 962                 -title [mc "git-gui: fatal error"] \
 963                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 964         exit 1
 965 }
 966
 967 proc get_trimmed_version {s} {
 968     set r {}
 969     foreach x [split $s -._] {
 970         if {[string is integer -strict $x]} {
 971             lappend r $x
 972         } else {
 973             break
 974         }
 975     }
 976     return [join $r .]
 977 }
 978 set _real_git_version $_git_version
 979 set _git_version [get_trimmed_version $_git_version]
 980
 981 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 982         catch {wm withdraw .}
 983         if {[tk_messageBox \
 984                 -icon warning \
 985                 -type yesno \
 986                 -default no \
 987                 -title "[appname]: warning" \
 988                  -message [mc "Git version cannot be determined.
 989
 990 %s claims it is version '%s'.
 991
 992 %s requires at least Git 1.5.0 or later.
 993
 994 Assume '%s' is version 1.5.0?
 995 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 996                 set _git_version 1.5.0
 997         } else {
 998                 exit 1
 999         }
1000 }
1001 unset _real_git_version
1002
1003 proc git-version {args} {
1004         global _git_version
1005
1006         switch [llength $args] {
1007         0 {
1008                 return $_git_version
1009         }
1010
1011         2 {
1012                 set op [lindex $args 0]
1013                 set vr [lindex $args 1]
1014                 set cm [package vcompare $_git_version $vr]
1015                 return [expr $cm $op 0]
1016         }
1017
1018         4 {
1019                 set type [lindex $args 0]
1020                 set name [lindex $args 1]
1021                 set parm [lindex $args 2]
1022                 set body [lindex $args 3]
1023
1024                 if {($type ne {proc} && $type ne {method})} {
1025                         error "Invalid arguments to git-version"
1026                 }
1027                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
1028                         error "Last arm of $type $name must be default"
1029                 }
1030
1031                 foreach {op vr cb} [lrange $body 0 end-2] {
1032                         if {[git-version $op $vr]} {
1033                                 return [uplevel [list $type $name $parm $cb]]
1034                         }
1035                 }
1036
1037                 return [uplevel [list $type $name $parm [lindex $body end]]]
1038         }
1039
1040         default {
1041                 error "git-version >= x"
1042         }
1043
1044         }
1045 }
1046
1047 if {[git-version < 1.5]} {
1048         catch {wm withdraw .}
1049         tk_messageBox \
1050                 -icon error \
1051                 -type ok \
1052                 -title [mc "git-gui: fatal error"] \
1053                 -message "[appname] requires Git 1.5.0 or later.
1054
1055 You are using [git-version]:
1056
1057 [git --version]"
1058         exit 1
1059 }
1060
1061 ######################################################################
1062 ##
1063 ## configure our library
1064
1065 set idx [file join $oguilib tclIndex]
1066 if {[catch {set fd [open $idx r]} err]} {
1067         catch {wm withdraw .}
1068         tk_messageBox \
1069                 -icon error \
1070                 -type ok \
1071                 -title [mc "git-gui: fatal error"] \
1072                 -message $err
1073         exit 1
1074 }
1075 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1076         set idx [list]
1077         while {[gets $fd n] >= 0} {
1078                 if {$n ne {} && ![string match #* $n]} {
1079                         lappend idx $n
1080                 }
1081         }
1082 } else {
1083         set idx {}
1084 }
1085 close $fd
1086
1087 if {$idx ne {}} {
1088         set loaded [list]
1089         foreach p $idx {
1090                 if {[lsearch -exact $loaded $p] >= 0} continue
1091                 source [file join $oguilib $p]
1092                 lappend loaded $p
1093         }
1094         unset loaded p
1095 } else {
1096         set auto_path [concat [list $oguilib] $auto_path]
1097 }
1098 unset -nocomplain idx fd
1099
1100 ######################################################################
1101 ##
1102 ## config file parsing
1103
1104 git-version proc _parse_config {arr_name args} {
1105         >= 1.5.3 {
1106                 upvar $arr_name arr
1107                 array unset arr
1108                 set buf {}
1109                 catch {
1110                         set fd_rc [eval \
1111                                 [list git_read config] \
1112                                 $args \
1113                                 [list --null --list]]
1114                         fconfigure $fd_rc -translation binary
1115                         set buf [read $fd_rc]
1116                         close $fd_rc
1117                 }
1118                 foreach line [split $buf "\0"] {
1119                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1120                                 if {[is_many_config $name]} {
1121                                         lappend arr($name) $value
1122                                 } else {
1123                                         set arr($name) $value
1124                                 }
1125                         } elseif {[regexp {^([^\n]+)$} $line line name]} {
1126                                 # no value given, but interpreting them as
1127                                 # boolean will be handled as true
1128                                 set arr($name) {}
1129                         }
1130                 }
1131         }
1132         default {
1133                 upvar $arr_name arr
1134                 array unset arr
1135                 catch {
1136                         set fd_rc [eval [list git_read config --list] $args]
1137                         while {[gets $fd_rc line] >= 0} {
1138                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1139                                         if {[is_many_config $name]} {
1140                                                 lappend arr($name) $value
1141                                         } else {
1142                                                 set arr($name) $value
1143                                         }
1144                                 } elseif {[regexp {^([^=]+)$} $line line name]} {
1145                                         # no value given, but interpreting them as
1146                                         # boolean will be handled as true
1147                                         set arr($name) {}
1148                                 }
1149                         }
1150                         close $fd_rc
1151                 }
1152         }
1153 }
1154
1155 proc load_config {include_global} {
1156         global repo_config global_config system_config default_config
1157
1158         if {$include_global} {
1159                 _parse_config system_config --system
1160                 _parse_config global_config --global
1161         }
1162         _parse_config repo_config
1163
1164         foreach name [array names default_config] {
1165                 if {[catch {set v $system_config($name)}]} {
1166                         set system_config($name) $default_config($name)
1167                 }
1168         }
1169         foreach name [array names system_config] {
1170                 if {[catch {set v $global_config($name)}]} {
1171                         set global_config($name) $system_config($name)
1172                 }
1173                 if {[catch {set v $repo_config($name)}]} {
1174                         set repo_config($name) $system_config($name)
1175                 }
1176         }
1177 }
1178
1179 ######################################################################
1180 ##
1181 ## feature option selection
1182
1183 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1184         unset _junk
1185 } else {
1186         set subcommand gui
1187 }
1188 if {$subcommand eq {gui.sh}} {
1189         set subcommand gui
1190 }
1191 if {$subcommand eq {gui} && [llength $argv] > 0} {
1192         set subcommand [lindex $argv 0]
1193         set argv [lrange $argv 1 end]
1194 }
1195
1196 enable_option multicommit
1197 enable_option branch
1198 enable_option transport
1199 disable_option bare
1200
1201 switch -- $subcommand {
1202 browser -
1203 blame {
1204         enable_option bare
1205
1206         disable_option multicommit
1207         disable_option branch
1208         disable_option transport
1209 }
1210 citool {
1211         enable_option singlecommit
1212         enable_option retcode
1213
1214         disable_option multicommit
1215         disable_option branch
1216         disable_option transport
1217
1218         while {[llength $argv] > 0} {
1219                 set a [lindex $argv 0]
1220                 switch -- $a {
1221                 --amend {
1222                         enable_option initialamend
1223                 }
1224                 --nocommit {
1225                         enable_option nocommit
1226                         enable_option nocommitmsg
1227                 }
1228                 --commitmsg {
1229                         disable_option nocommitmsg
1230                 }
1231                 default {
1232                         break
1233                 }
1234                 }
1235
1236                 set argv [lrange $argv 1 end]
1237         }
1238 }
1239 }
1240
1241 ######################################################################
1242 ##
1243 ## execution environment
1244
1245 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1246
1247 # Suggest our implementation of askpass, if none is set
1248 if {![info exists env(SSH_ASKPASS)]} {
1249         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1250 }
1251
1252 ######################################################################
1253 ##
1254 ## repository setup
1255
1256 set picked 0
1257 if {[catch {
1258                 set _gitdir $env(GIT_DIR)
1259                 set _prefix {}
1260                 }]
1261         && [catch {
1262                 # beware that from the .git dir this sets _gitdir to .
1263                 # and _prefix to the empty string
1264                 set _gitdir [git rev-parse --git-dir]
1265                 set _prefix [git rev-parse --show-prefix]
1266         } err]} {
1267         load_config 1
1268         apply_config
1269         choose_repository::pick
1270         set picked 1
1271 }
1272
1273 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1274 # run from the .git dir itself) lest the routines to find the worktree
1275 # get confused
1276 if {$_gitdir eq "."} {
1277         set _gitdir [pwd]
1278 }
1279
1280 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1281         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1282 }
1283 if {![file isdirectory $_gitdir]} {
1284         catch {wm withdraw .}
1285         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1286         exit 1
1287 }
1288 # _gitdir exists, so try loading the config
1289 load_config 0
1290 apply_config
1291
1292 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1293 if {[package vcompare $_git_version 1.7.0] >= 0} {
1294         if { [is_Cygwin] } {
1295                 catch {set _gitworktree [exec cygpath --windows [git rev-parse --show-toplevel]]}
1296         } else {
1297                 set _gitworktree [git rev-parse --show-toplevel]
1298         }
1299 } else {
1300         # try to set work tree from environment, core.worktree or use
1301         # cdup to obtain a relative path to the top of the worktree. If
1302         # run from the top, the ./ prefix ensures normalize expands pwd.
1303         if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1304                 set _gitworktree [get_config core.worktree]
1305                 if {$_gitworktree eq ""} {
1306                         set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1307                 }
1308         }
1309 }
1310
1311 if {$_prefix ne {}} {
1312         if {$_gitworktree eq {}} {
1313                 regsub -all {[^/]+/} $_prefix ../ cdup
1314         } else {
1315                 set cdup $_gitworktree
1316         }
1317         if {[catch {cd $cdup} err]} {
1318                 catch {wm withdraw .}
1319                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1320                 exit 1
1321         }
1322         set _gitworktree [pwd]
1323         unset cdup
1324 } elseif {![is_enabled bare]} {
1325         if {[is_bare]} {
1326                 catch {wm withdraw .}
1327                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1328                 exit 1
1329         }
1330         if {$_gitworktree eq {}} {
1331                 set _gitworktree [file dirname $_gitdir]
1332         }
1333         if {[catch {cd $_gitworktree} err]} {
1334                 catch {wm withdraw .}
1335                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1336                 exit 1
1337         }
1338         set _gitworktree [pwd]
1339 }
1340 set _reponame [file split [file normalize $_gitdir]]
1341 if {[lindex $_reponame end] eq {.git}} {
1342         set _reponame [lindex $_reponame end-1]
1343 } else {
1344         set _reponame [lindex $_reponame end]
1345 }
1346
1347 set env(GIT_DIR) $_gitdir
1348 set env(GIT_WORK_TREE) $_gitworktree
1349
1350 ######################################################################
1351 ##
1352 ## global init
1353
1354 set current_diff_path {}
1355 set current_diff_side {}
1356 set diff_actions [list]
1357
1358 set HEAD {}
1359 set PARENT {}
1360 set MERGE_HEAD [list]
1361 set commit_type {}
1362 set empty_tree {}
1363 set current_branch {}
1364 set is_detached 0
1365 set current_diff_path {}
1366 set is_3way_diff 0
1367 set is_submodule_diff 0
1368 set is_conflict_diff 0
1369 set selected_commit_type new
1370 set diff_empty_count 0
1371
1372 set nullid "0000000000000000000000000000000000000000"
1373 set nullid2 "0000000000000000000000000000000000000001"
1374
1375 ######################################################################
1376 ##
1377 ## task management
1378
1379 set rescan_active 0
1380 set diff_active 0
1381 set last_clicked {}
1382
1383 set disable_on_lock [list]
1384 set index_lock_type none
1385
1386 proc lock_index {type} {
1387         global index_lock_type disable_on_lock
1388
1389         if {$index_lock_type eq {none}} {
1390                 set index_lock_type $type
1391                 foreach w $disable_on_lock {
1392                         uplevel #0 $w disabled
1393                 }
1394                 return 1
1395         } elseif {$index_lock_type eq "begin-$type"} {
1396                 set index_lock_type $type
1397                 return 1
1398         }
1399         return 0
1400 }
1401
1402 proc unlock_index {} {
1403         global index_lock_type disable_on_lock
1404
1405         set index_lock_type none
1406         foreach w $disable_on_lock {
1407                 uplevel #0 $w normal
1408         }
1409 }
1410
1411 ######################################################################
1412 ##
1413 ## status
1414
1415 proc repository_state {ctvar hdvar mhvar} {
1416         global current_branch
1417         upvar $ctvar ct $hdvar hd $mhvar mh
1418
1419         set mh [list]
1420
1421         load_current_branch
1422         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1423                 set hd {}
1424                 set ct initial
1425                 return
1426         }
1427
1428         set merge_head [gitdir MERGE_HEAD]
1429         if {[file exists $merge_head]} {
1430                 set ct merge
1431                 set fd_mh [open $merge_head r]
1432                 while {[gets $fd_mh line] >= 0} {
1433                         lappend mh $line
1434                 }
1435                 close $fd_mh
1436                 return
1437         }
1438
1439         set ct normal
1440 }
1441
1442 proc PARENT {} {
1443         global PARENT empty_tree
1444
1445         set p [lindex $PARENT 0]
1446         if {$p ne {}} {
1447                 return $p
1448         }
1449         if {$empty_tree eq {}} {
1450                 set empty_tree [git mktree << {}]
1451         }
1452         return $empty_tree
1453 }
1454
1455 proc force_amend {} {
1456         global selected_commit_type
1457         global HEAD PARENT MERGE_HEAD commit_type
1458
1459         repository_state newType newHEAD newMERGE_HEAD
1460         set HEAD $newHEAD
1461         set PARENT $newHEAD
1462         set MERGE_HEAD $newMERGE_HEAD
1463         set commit_type $newType
1464
1465         set selected_commit_type amend
1466         do_select_commit_type
1467 }
1468
1469 proc rescan {after {honor_trustmtime 1}} {
1470         global HEAD PARENT MERGE_HEAD commit_type
1471         global ui_index ui_workdir ui_comm
1472         global rescan_active file_states
1473         global repo_config
1474
1475         if {$rescan_active > 0 || ![lock_index read]} return
1476
1477         repository_state newType newHEAD newMERGE_HEAD
1478         if {[string match amend* $commit_type]
1479                 && $newType eq {normal}
1480                 && $newHEAD eq $HEAD} {
1481         } else {
1482                 set HEAD $newHEAD
1483                 set PARENT $newHEAD
1484                 set MERGE_HEAD $newMERGE_HEAD
1485                 set commit_type $newType
1486         }
1487
1488         array unset file_states
1489
1490         if {!$::GITGUI_BCK_exists &&
1491                 (![$ui_comm edit modified]
1492                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1493                 if {[string match amend* $commit_type]} {
1494                 } elseif {[load_message GITGUI_MSG utf-8]} {
1495                 } elseif {[run_prepare_commit_msg_hook]} {
1496                 } elseif {[load_message MERGE_MSG]} {
1497                 } elseif {[load_message SQUASH_MSG]} {
1498                 }
1499                 $ui_comm edit reset
1500                 $ui_comm edit modified false
1501         }
1502
1503         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1504                 rescan_stage2 {} $after
1505         } else {
1506                 set rescan_active 1
1507                 ui_status [mc "Refreshing file status..."]
1508                 set fd_rf [git_read update-index \
1509                         -q \
1510                         --unmerged \
1511                         --ignore-missing \
1512                         --refresh \
1513                         ]
1514                 fconfigure $fd_rf -blocking 0 -translation binary
1515                 fileevent $fd_rf readable \
1516                         [list rescan_stage2 $fd_rf $after]
1517         }
1518 }
1519
1520 if {[is_Cygwin]} {
1521         set is_git_info_exclude {}
1522         proc have_info_exclude {} {
1523                 global is_git_info_exclude
1524
1525                 if {$is_git_info_exclude eq {}} {
1526                         if {[catch {exec test -f [gitdir info exclude]}]} {
1527                                 set is_git_info_exclude 0
1528                         } else {
1529                                 set is_git_info_exclude 1
1530                         }
1531                 }
1532                 return $is_git_info_exclude
1533         }
1534 } else {
1535         proc have_info_exclude {} {
1536                 return [file readable [gitdir info exclude]]
1537         }
1538 }
1539
1540 proc rescan_stage2 {fd after} {
1541         global rescan_active buf_rdi buf_rdf buf_rlo
1542
1543         if {$fd ne {}} {
1544                 read $fd
1545                 if {![eof $fd]} return
1546                 close $fd
1547         }
1548
1549         if {[package vcompare $::_git_version 1.6.3] >= 0} {
1550                 set ls_others [list --exclude-standard]
1551         } else {
1552                 set ls_others [list --exclude-per-directory=.gitignore]
1553                 if {[have_info_exclude]} {
1554                         lappend ls_others "--exclude-from=[gitdir info exclude]"
1555                 }
1556                 set user_exclude [get_config core.excludesfile]
1557                 if {$user_exclude ne {} && [file readable $user_exclude]} {
1558                         lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1559                 }
1560         }
1561
1562         set buf_rdi {}
1563         set buf_rdf {}
1564         set buf_rlo {}
1565
1566         set rescan_active 2
1567         ui_status [mc "Scanning for modified files ..."]
1568         if {[git-version >= "1.7.2"]} {
1569                 set fd_di [git_read diff-index --cached --ignore-submodules=dirty -z [PARENT]]
1570         } else {
1571                 set fd_di [git_read diff-index --cached -z [PARENT]]
1572         }
1573         set fd_df [git_read diff-files -z]
1574
1575         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1576         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1577
1578         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1579         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1580
1581         if {[is_config_true gui.displayuntracked]} {
1582                 set fd_lo [eval git_read ls-files --others -z $ls_others]
1583                 fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1584                 fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1585                 incr rescan_active
1586         }
1587 }
1588
1589 proc load_message {file {encoding {}}} {
1590         global ui_comm
1591
1592         set f [gitdir $file]
1593         if {[file isfile $f]} {
1594                 if {[catch {set fd [open $f r]}]} {
1595                         return 0
1596                 }
1597                 fconfigure $fd -eofchar {}
1598                 if {$encoding ne {}} {
1599                         fconfigure $fd -encoding $encoding
1600                 }
1601                 set content [string trim [read $fd]]
1602                 close $fd
1603                 regsub -all -line {[ \r\t]+$} $content {} content
1604                 $ui_comm delete 0.0 end
1605                 $ui_comm insert end $content
1606                 return 1
1607         }
1608         return 0
1609 }
1610
1611 proc run_prepare_commit_msg_hook {} {
1612         global pch_error
1613
1614         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1615         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1616         # empty file but existent file.
1617
1618         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1619
1620         if {[file isfile [gitdir MERGE_MSG]]} {
1621                 set pcm_source "merge"
1622                 set fd_mm [open [gitdir MERGE_MSG] r]
1623                 puts -nonewline $fd_pcm [read $fd_mm]
1624                 close $fd_mm
1625         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1626                 set pcm_source "squash"
1627                 set fd_sm [open [gitdir SQUASH_MSG] r]
1628                 puts -nonewline $fd_pcm [read $fd_sm]
1629                 close $fd_sm
1630         } else {
1631                 set pcm_source ""
1632         }
1633
1634         close $fd_pcm
1635
1636         set fd_ph [githook_read prepare-commit-msg \
1637                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1638         if {$fd_ph eq {}} {
1639                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1640                 return 0;
1641         }
1642
1643         ui_status [mc "Calling prepare-commit-msg hook..."]
1644         set pch_error {}
1645
1646         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1647         fileevent $fd_ph readable \
1648                 [list prepare_commit_msg_hook_wait $fd_ph]
1649
1650         return 1;
1651 }
1652
1653 proc prepare_commit_msg_hook_wait {fd_ph} {
1654         global pch_error
1655
1656         append pch_error [read $fd_ph]
1657         fconfigure $fd_ph -blocking 1
1658         if {[eof $fd_ph]} {
1659                 if {[catch {close $fd_ph}]} {
1660                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1661                         hook_failed_popup prepare-commit-msg $pch_error
1662                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1663                         exit 1
1664                 } else {
1665                         load_message PREPARE_COMMIT_MSG
1666                 }
1667                 set pch_error {}
1668                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1669                 return
1670         }
1671         fconfigure $fd_ph -blocking 0
1672         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1673 }
1674
1675 proc read_diff_index {fd after} {
1676         global buf_rdi
1677
1678         append buf_rdi [read $fd]
1679         set c 0
1680         set n [string length $buf_rdi]
1681         while {$c < $n} {
1682                 set z1 [string first "\0" $buf_rdi $c]
1683                 if {$z1 == -1} break
1684                 incr z1
1685                 set z2 [string first "\0" $buf_rdi $z1]
1686                 if {$z2 == -1} break
1687
1688                 incr c
1689                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1690                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1691                 merge_state \
1692                         [encoding convertfrom $p] \
1693                         [lindex $i 4]? \
1694                         [list [lindex $i 0] [lindex $i 2]] \
1695                         [list]
1696                 set c $z2
1697                 incr c
1698         }
1699         if {$c < $n} {
1700                 set buf_rdi [string range $buf_rdi $c end]
1701         } else {
1702                 set buf_rdi {}
1703         }
1704
1705         rescan_done $fd buf_rdi $after
1706 }
1707
1708 proc read_diff_files {fd after} {
1709         global buf_rdf
1710
1711         append buf_rdf [read $fd]
1712         set c 0
1713         set n [string length $buf_rdf]
1714         while {$c < $n} {
1715                 set z1 [string first "\0" $buf_rdf $c]
1716                 if {$z1 == -1} break
1717                 incr z1
1718                 set z2 [string first "\0" $buf_rdf $z1]
1719                 if {$z2 == -1} break
1720
1721                 incr c
1722                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1723                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1724                 merge_state \
1725                         [encoding convertfrom $p] \
1726                         ?[lindex $i 4] \
1727                         [list] \
1728                         [list [lindex $i 0] [lindex $i 2]]
1729                 set c $z2
1730                 incr c
1731         }
1732         if {$c < $n} {
1733                 set buf_rdf [string range $buf_rdf $c end]
1734         } else {
1735                 set buf_rdf {}
1736         }
1737
1738         rescan_done $fd buf_rdf $after
1739 }
1740
1741 proc read_ls_others {fd after} {
1742         global buf_rlo
1743
1744         append buf_rlo [read $fd]
1745         set pck [split $buf_rlo "\0"]
1746         set buf_rlo [lindex $pck end]
1747         foreach p [lrange $pck 0 end-1] {
1748                 set p [encoding convertfrom $p]
1749                 if {[string index $p end] eq {/}} {
1750                         set p [string range $p 0 end-1]
1751                 }
1752                 merge_state $p ?O
1753         }
1754         rescan_done $fd buf_rlo $after
1755 }
1756
1757 proc rescan_done {fd buf after} {
1758         global rescan_active current_diff_path
1759         global file_states repo_config
1760         upvar $buf to_clear
1761
1762         if {![eof $fd]} return
1763         set to_clear {}
1764         close $fd
1765         if {[incr rescan_active -1] > 0} return
1766
1767         prune_selection
1768         unlock_index
1769         display_all_files
1770         if {$current_diff_path ne {}} { reshow_diff $after }
1771         if {$current_diff_path eq {}} { select_first_diff $after }
1772 }
1773
1774 proc prune_selection {} {
1775         global file_states selected_paths
1776
1777         foreach path [array names selected_paths] {
1778                 if {[catch {set still_here $file_states($path)}]} {
1779                         unset selected_paths($path)
1780                 }
1781         }
1782 }
1783
1784 ######################################################################
1785 ##
1786 ## ui helpers
1787
1788 proc mapicon {w state path} {
1789         global all_icons
1790
1791         if {[catch {set r $all_icons($state$w)}]} {
1792                 puts "error: no icon for $w state={$state} $path"
1793                 return file_plain
1794         }
1795         return $r
1796 }
1797
1798 proc mapdesc {state path} {
1799         global all_descs
1800
1801         if {[catch {set r $all_descs($state)}]} {
1802                 puts "error: no desc for state={$state} $path"
1803                 return $state
1804         }
1805         return $r
1806 }
1807
1808 proc ui_status {msg} {
1809         global main_status
1810         if {[info exists main_status]} {
1811                 $main_status show $msg
1812         }
1813 }
1814
1815 proc ui_ready {{test {}}} {
1816         global main_status
1817         if {[info exists main_status]} {
1818                 $main_status show [mc "Ready."] $test
1819         }
1820 }
1821
1822 proc escape_path {path} {
1823         regsub -all {\\} $path "\\\\" path
1824         regsub -all "\n" $path "\\n" path
1825         return $path
1826 }
1827
1828 proc short_path {path} {
1829         return [escape_path [lindex [file split $path] end]]
1830 }
1831
1832 set next_icon_id 0
1833 set null_sha1 [string repeat 0 40]
1834
1835 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1836         global file_states next_icon_id null_sha1
1837
1838         set s0 [string index $new_state 0]
1839         set s1 [string index $new_state 1]
1840
1841         if {[catch {set info $file_states($path)}]} {
1842                 set state __
1843                 set icon n[incr next_icon_id]
1844         } else {
1845                 set state [lindex $info 0]
1846                 set icon [lindex $info 1]
1847                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1848                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1849         }
1850
1851         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1852         elseif {$s0 eq {_}} {set s0 _}
1853
1854         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1855         elseif {$s1 eq {_}} {set s1 _}
1856
1857         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1858                 set head_info [list 0 $null_sha1]
1859         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1860                 && $head_info eq {}} {
1861                 set head_info $index_info
1862         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1863                 set index_info $head_info
1864                 set head_info {}
1865         }
1866
1867         set file_states($path) [list $s0$s1 $icon \
1868                 $head_info $index_info \
1869                 ]
1870         return $state
1871 }
1872
1873 proc display_file_helper {w path icon_name old_m new_m} {
1874         global file_lists
1875
1876         if {$new_m eq {_}} {
1877                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1878                 if {$lno >= 0} {
1879                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1880                         incr lno
1881                         $w conf -state normal
1882                         $w delete $lno.0 [expr {$lno + 1}].0
1883                         $w conf -state disabled
1884                 }
1885         } elseif {$old_m eq {_} && $new_m ne {_}} {
1886                 lappend file_lists($w) $path
1887                 set file_lists($w) [lsort -unique $file_lists($w)]
1888                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1889                 incr lno
1890                 $w conf -state normal
1891                 $w image create $lno.0 \
1892                         -align center -padx 5 -pady 1 \
1893                         -name $icon_name \
1894                         -image [mapicon $w $new_m $path]
1895                 $w insert $lno.1 "[escape_path $path]\n"
1896                 $w conf -state disabled
1897         } elseif {$old_m ne $new_m} {
1898                 $w conf -state normal
1899                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1900                 $w conf -state disabled
1901         }
1902 }
1903
1904 proc display_file {path state} {
1905         global file_states selected_paths
1906         global ui_index ui_workdir
1907
1908         set old_m [merge_state $path $state]
1909         set s $file_states($path)
1910         set new_m [lindex $s 0]
1911         set icon_name [lindex $s 1]
1912
1913         set o [string index $old_m 0]
1914         set n [string index $new_m 0]
1915         if {$o eq {U}} {
1916                 set o _
1917         }
1918         if {$n eq {U}} {
1919                 set n _
1920         }
1921         display_file_helper     $ui_index $path $icon_name $o $n
1922
1923         if {[string index $old_m 0] eq {U}} {
1924                 set o U
1925         } else {
1926                 set o [string index $old_m 1]
1927         }
1928         if {[string index $new_m 0] eq {U}} {
1929                 set n U
1930         } else {
1931                 set n [string index $new_m 1]
1932         }
1933         display_file_helper     $ui_workdir $path $icon_name $o $n
1934
1935         if {$new_m eq {__}} {
1936                 unset file_states($path)
1937                 catch {unset selected_paths($path)}
1938         }
1939 }
1940
1941 proc display_all_files_helper {w path icon_name m} {
1942         global file_lists
1943
1944         lappend file_lists($w) $path
1945         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1946         $w image create end \
1947                 -align center -padx 5 -pady 1 \
1948                 -name $icon_name \
1949                 -image [mapicon $w $m $path]
1950         $w insert end "[escape_path $path]\n"
1951 }
1952
1953 set files_warning 0
1954 proc display_all_files {} {
1955         global ui_index ui_workdir
1956         global file_states file_lists
1957         global last_clicked
1958         global files_warning
1959
1960         $ui_index conf -state normal
1961         $ui_workdir conf -state normal
1962
1963         $ui_index delete 0.0 end
1964         $ui_workdir delete 0.0 end
1965         set last_clicked {}
1966
1967         set file_lists($ui_index) [list]
1968         set file_lists($ui_workdir) [list]
1969
1970         set to_display [lsort [array names file_states]]
1971         set display_limit [get_config gui.maxfilesdisplayed]
1972         set displayed 0
1973         foreach path $to_display {
1974                 set s $file_states($path)
1975                 set m [lindex $s 0]
1976                 set icon_name [lindex $s 1]
1977
1978                 if {$displayed > $display_limit && [string index $m 1] eq {O} } {
1979                         if {!$files_warning} {
1980                                 # do not repeatedly warn:
1981                                 set files_warning 1
1982                                 info_popup [mc "Display limit (gui.maxfilesdisplayed = %s) reached, not showing all %s files." \
1983                                         $display_limit [llength $to_display]]
1984                         }
1985                         continue
1986                 }
1987
1988                 set s [string index $m 0]
1989                 if {$s ne {U} && $s ne {_}} {
1990                         display_all_files_helper $ui_index $path \
1991                                 $icon_name $s
1992                 }
1993
1994                 if {[string index $m 0] eq {U}} {
1995                         set s U
1996                 } else {
1997                         set s [string index $m 1]
1998                 }
1999                 if {$s ne {_}} {
2000                         display_all_files_helper $ui_workdir $path \
2001                                 $icon_name $s
2002                         incr displayed
2003                 }
2004         }
2005
2006         $ui_index conf -state disabled
2007         $ui_workdir conf -state disabled
2008 }
2009
2010 ######################################################################
2011 ##
2012 ## icons
2013
2014 set filemask {
2015 #define mask_width 14
2016 #define mask_height 15
2017 static unsigned char mask_bits[] = {
2018    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2019    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2020    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2021 }
2022
2023 image create bitmap file_plain -background white -foreground black -data {
2024 #define plain_width 14
2025 #define plain_height 15
2026 static unsigned char plain_bits[] = {
2027    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2028    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2029    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2030 } -maskdata $filemask
2031
2032 image create bitmap file_mod -background white -foreground blue -data {
2033 #define mod_width 14
2034 #define mod_height 15
2035 static unsigned char mod_bits[] = {
2036    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2037    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2038    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2039 } -maskdata $filemask
2040
2041 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2042 #define file_fulltick_width 14
2043 #define file_fulltick_height 15
2044 static unsigned char file_fulltick_bits[] = {
2045    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2046    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2047    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2048 } -maskdata $filemask
2049
2050 image create bitmap file_question -background white -foreground black -data {
2051 #define file_question_width 14
2052 #define file_question_height 15
2053 static unsigned char file_question_bits[] = {
2054    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2055    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2056    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2057 } -maskdata $filemask
2058
2059 image create bitmap file_removed -background white -foreground red -data {
2060 #define file_removed_width 14
2061 #define file_removed_height 15
2062 static unsigned char file_removed_bits[] = {
2063    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2064    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2065    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2066 } -maskdata $filemask
2067
2068 image create bitmap file_merge -background white -foreground blue -data {
2069 #define file_merge_width 14
2070 #define file_merge_height 15
2071 static unsigned char file_merge_bits[] = {
2072    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2073    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2074    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2075 } -maskdata $filemask
2076
2077 image create bitmap file_statechange -background white -foreground green -data {
2078 #define file_statechange_width 14
2079 #define file_statechange_height 15
2080 static unsigned char file_statechange_bits[] = {
2081    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
2082    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
2083    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2084 } -maskdata $filemask
2085
2086 set ui_index .vpane.files.index.list
2087 set ui_workdir .vpane.files.workdir.list
2088
2089 set all_icons(_$ui_index)   file_plain
2090 set all_icons(A$ui_index)   file_plain
2091 set all_icons(M$ui_index)   file_fulltick
2092 set all_icons(D$ui_index)   file_removed
2093 set all_icons(U$ui_index)   file_merge
2094 set all_icons(T$ui_index)   file_statechange
2095
2096 set all_icons(_$ui_workdir) file_plain
2097 set all_icons(M$ui_workdir) file_mod
2098 set all_icons(D$ui_workdir) file_question
2099 set all_icons(U$ui_workdir) file_merge
2100 set all_icons(O$ui_workdir) file_plain
2101 set all_icons(T$ui_workdir) file_statechange
2102
2103 set max_status_desc 0
2104 foreach i {
2105                 {__ {mc "Unmodified"}}
2106
2107                 {_M {mc "Modified, not staged"}}
2108                 {M_ {mc "Staged for commit"}}
2109                 {MM {mc "Portions staged for commit"}}
2110                 {MD {mc "Staged for commit, missing"}}
2111
2112                 {_T {mc "File type changed, not staged"}}
2113                 {MT {mc "File type changed, old type staged for commit"}}
2114                 {AT {mc "File type changed, old type staged for commit"}}
2115                 {T_ {mc "File type changed, staged"}}
2116                 {TM {mc "File type change staged, modification not staged"}}
2117                 {TD {mc "File type change staged, file missing"}}
2118
2119                 {_O {mc "Untracked, not staged"}}
2120                 {A_ {mc "Staged for commit"}}
2121                 {AM {mc "Portions staged for commit"}}
2122                 {AD {mc "Staged for commit, missing"}}
2123
2124                 {_D {mc "Missing"}}
2125                 {D_ {mc "Staged for removal"}}
2126                 {DO {mc "Staged for removal, still present"}}
2127
2128                 {_U {mc "Requires merge resolution"}}
2129                 {U_ {mc "Requires merge resolution"}}
2130                 {UU {mc "Requires merge resolution"}}
2131                 {UM {mc "Requires merge resolution"}}
2132                 {UD {mc "Requires merge resolution"}}
2133                 {UT {mc "Requires merge resolution"}}
2134         } {
2135         set text [eval [lindex $i 1]]
2136         if {$max_status_desc < [string length $text]} {
2137                 set max_status_desc [string length $text]
2138         }
2139         set all_descs([lindex $i 0]) $text
2140 }
2141 unset i
2142
2143 ######################################################################
2144 ##
2145 ## util
2146
2147 proc scrollbar2many {list mode args} {
2148         foreach w $list {eval $w $mode $args}
2149 }
2150
2151 proc many2scrollbar {list mode sb top bottom} {
2152         $sb set $top $bottom
2153         foreach w $list {$w $mode moveto $top}
2154 }
2155
2156 proc incr_font_size {font {amt 1}} {
2157         set sz [font configure $font -size]
2158         incr sz $amt
2159         font configure $font -size $sz
2160         font configure ${font}bold -size $sz
2161         font configure ${font}italic -size $sz
2162 }
2163
2164 ######################################################################
2165 ##
2166 ## ui commands
2167
2168 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2169
2170 proc do_gitk {revs {is_submodule false}} {
2171         global current_diff_path file_states current_diff_side ui_index
2172         global _gitdir _gitworktree
2173
2174         # -- Always start gitk through whatever we were loaded with.  This
2175         #    lets us bypass using shell process on Windows systems.
2176         #
2177         set exe [_which gitk -script]
2178         set cmd [list [info nameofexecutable] $exe]
2179         if {$exe eq {}} {
2180                 error_popup [mc "Couldn't find gitk in PATH"]
2181         } else {
2182                 global env
2183
2184                 set pwd [pwd]
2185
2186                 if {!$is_submodule} {
2187                         if {![is_bare]} {
2188                                 cd $_gitworktree
2189                         }
2190                 } else {
2191                         cd $current_diff_path
2192                         if {$revs eq {--}} {
2193                                 set s $file_states($current_diff_path)
2194                                 set old_sha1 {}
2195                                 set new_sha1 {}
2196                                 switch -glob -- [lindex $s 0] {
2197                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2198                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2199                                 MM {
2200                                         if {$current_diff_side eq $ui_index} {
2201                                                 set old_sha1 [lindex [lindex $s 2] 1]
2202                                                 set new_sha1 [lindex [lindex $s 3] 1]
2203                                         } else {
2204                                                 set old_sha1 [lindex [lindex $s 3] 1]
2205                                         }
2206                                 }
2207                                 }
2208                                 set revs $old_sha1...$new_sha1
2209                         }
2210                         # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2211                         # we've been using for the main repository, so unset them.
2212                         # TODO we could make life easier (start up faster?) for gitk
2213                         # by setting these to the appropriate values to allow gitk
2214                         # to skip the heuristics to find their proper value
2215                         unset env(GIT_DIR)
2216                         unset env(GIT_WORK_TREE)
2217                 }
2218                 eval exec $cmd $revs "--" "--" &
2219
2220                 set env(GIT_DIR) $_gitdir
2221                 set env(GIT_WORK_TREE) $_gitworktree
2222                 cd $pwd
2223
2224                 ui_status $::starting_gitk_msg
2225                 after 10000 {
2226                         ui_ready $starting_gitk_msg
2227                 }
2228         }
2229 }
2230
2231 proc do_git_gui {} {
2232         global current_diff_path
2233
2234         # -- Always start git gui through whatever we were loaded with.  This
2235         #    lets us bypass using shell process on Windows systems.
2236         #
2237         set exe [list [_which git]]
2238         if {$exe eq {}} {
2239                 error_popup [mc "Couldn't find git gui in PATH"]
2240         } else {
2241                 global env
2242                 global _gitdir _gitworktree
2243
2244                 # see note in do_gitk about unsetting these vars when
2245                 # running tools in a submodule
2246                 unset env(GIT_DIR)
2247                 unset env(GIT_WORK_TREE)
2248
2249                 set pwd [pwd]
2250                 cd $current_diff_path
2251
2252                 eval exec $exe gui &
2253
2254                 set env(GIT_DIR) $_gitdir
2255                 set env(GIT_WORK_TREE) $_gitworktree
2256                 cd $pwd
2257
2258                 ui_status $::starting_gitk_msg
2259                 after 10000 {
2260                         ui_ready $starting_gitk_msg
2261                 }
2262         }
2263 }
2264
2265 proc do_explore {} {
2266         global _gitworktree
2267         set explorer {}
2268         if {[is_Cygwin] || [is_Windows]} {
2269                 set explorer "explorer.exe"
2270         } elseif {[is_MacOSX]} {
2271                 set explorer "open"
2272         } else {
2273                 # freedesktop.org-conforming system is our best shot
2274                 set explorer "xdg-open"
2275         }
2276         eval exec $explorer [list [file nativename $_gitworktree]] &
2277 }
2278
2279 set is_quitting 0
2280 set ret_code    1
2281
2282 proc terminate_me {win} {
2283         global ret_code
2284         if {$win ne {.}} return
2285         exit $ret_code
2286 }
2287
2288 proc do_quit {{rc {1}}} {
2289         global ui_comm is_quitting repo_config commit_type
2290         global GITGUI_BCK_exists GITGUI_BCK_i
2291         global ui_comm_spell
2292         global ret_code use_ttk
2293
2294         if {$is_quitting} return
2295         set is_quitting 1
2296
2297         if {[winfo exists $ui_comm]} {
2298                 # -- Stash our current commit buffer.
2299                 #
2300                 set save [gitdir GITGUI_MSG]
2301                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2302                         file rename -force [gitdir GITGUI_BCK] $save
2303                         set GITGUI_BCK_exists 0
2304                 } else {
2305                         set msg [string trim [$ui_comm get 0.0 end]]
2306                         regsub -all -line {[ \r\t]+$} $msg {} msg
2307                         if {(![string match amend* $commit_type]
2308                                 || [$ui_comm edit modified])
2309                                 && $msg ne {}} {
2310                                 catch {
2311                                         set fd [open $save w]
2312                                         fconfigure $fd -encoding utf-8
2313                                         puts -nonewline $fd $msg
2314                                         close $fd
2315                                 }
2316                         } else {
2317                                 catch {file delete $save}
2318                         }
2319                 }
2320
2321                 # -- Cancel our spellchecker if its running.
2322                 #
2323                 if {[info exists ui_comm_spell]} {
2324                         $ui_comm_spell stop
2325                 }
2326
2327                 # -- Remove our editor backup, its not needed.
2328                 #
2329                 after cancel $GITGUI_BCK_i
2330                 if {$GITGUI_BCK_exists} {
2331                         catch {file delete [gitdir GITGUI_BCK]}
2332                 }
2333
2334                 # -- Stash our current window geometry into this repository.
2335                 #
2336                 set cfg_wmstate [wm state .]
2337                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2338                         set rc_wmstate {}
2339                 }
2340                 if {$cfg_wmstate ne $rc_wmstate} {
2341                         catch {git config gui.wmstate $cfg_wmstate}
2342                 }
2343                 if {$cfg_wmstate eq {zoomed}} {
2344                         # on Windows wm geometry will lie about window
2345                         # position (but not size) when window is zoomed
2346                         # restore the window before querying wm geometry
2347                         wm state . normal
2348                 }
2349                 set cfg_geometry [list]
2350                 lappend cfg_geometry [wm geometry .]
2351                 if {$use_ttk} {
2352                         lappend cfg_geometry [.vpane sashpos 0]
2353                         lappend cfg_geometry [.vpane.files sashpos 0]
2354                 } else {
2355                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2356                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2357                 }
2358                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2359                         set rc_geometry {}
2360                 }
2361                 if {$cfg_geometry ne $rc_geometry} {
2362                         catch {git config gui.geometry $cfg_geometry}
2363                 }
2364         }
2365
2366         set ret_code $rc
2367
2368         # Briefly enable send again, working around Tk bug
2369         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2370         tk appname [appname]
2371
2372         destroy .
2373 }
2374
2375 proc do_rescan {} {
2376         rescan ui_ready
2377 }
2378
2379 proc ui_do_rescan {} {
2380         rescan {force_first_diff ui_ready}
2381 }
2382
2383 proc do_commit {} {
2384         commit_tree
2385 }
2386
2387 proc next_diff {{after {}}} {
2388         global next_diff_p next_diff_w next_diff_i
2389         show_diff $next_diff_p $next_diff_w {} {} $after
2390 }
2391
2392 proc find_anchor_pos {lst name} {
2393         set lid [lsearch -sorted -exact $lst $name]
2394
2395         if {$lid == -1} {
2396                 set lid 0
2397                 foreach lname $lst {
2398                         if {$lname >= $name} break
2399                         incr lid
2400                 }
2401         }
2402
2403         return $lid
2404 }
2405
2406 proc find_file_from {flist idx delta path mmask} {
2407         global file_states
2408
2409         set len [llength $flist]
2410         while {$idx >= 0 && $idx < $len} {
2411                 set name [lindex $flist $idx]
2412
2413                 if {$name ne $path && [info exists file_states($name)]} {
2414                         set state [lindex $file_states($name) 0]
2415
2416                         if {$mmask eq {} || [regexp $mmask $state]} {
2417                                 return $idx
2418                         }
2419                 }
2420
2421                 incr idx $delta
2422         }
2423
2424         return {}
2425 }
2426
2427 proc find_next_diff {w path {lno {}} {mmask {}}} {
2428         global next_diff_p next_diff_w next_diff_i
2429         global file_lists ui_index ui_workdir
2430
2431         set flist $file_lists($w)
2432         if {$lno eq {}} {
2433                 set lno [find_anchor_pos $flist $path]
2434         } else {
2435                 incr lno -1
2436         }
2437
2438         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2439                 if {$w eq $ui_index} {
2440                         set mmask "^$mmask"
2441                 } else {
2442                         set mmask "$mmask\$"
2443                 }
2444         }
2445
2446         set idx [find_file_from $flist $lno 1 $path $mmask]
2447         if {$idx eq {}} {
2448                 incr lno -1
2449                 set idx [find_file_from $flist $lno -1 $path $mmask]
2450         }
2451
2452         if {$idx ne {}} {
2453                 set next_diff_w $w
2454                 set next_diff_p [lindex $flist $idx]
2455                 set next_diff_i [expr {$idx+1}]
2456                 return 1
2457         } else {
2458                 return 0
2459         }
2460 }
2461
2462 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2463         global current_diff_path
2464
2465         if {$path ne $current_diff_path} {
2466                 return {}
2467         } elseif {[find_next_diff $w $path $lno $mmask]} {
2468                 return {next_diff;}
2469         } else {
2470                 return {reshow_diff;}
2471         }
2472 }
2473
2474 proc select_first_diff {after} {
2475         global ui_workdir
2476
2477         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2478             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2479                 next_diff $after
2480         } else {
2481                 uplevel #0 $after
2482         }
2483 }
2484
2485 proc force_first_diff {after} {
2486         global ui_workdir current_diff_path file_states
2487
2488         if {[info exists file_states($current_diff_path)]} {
2489                 set state [lindex $file_states($current_diff_path) 0]
2490         } else {
2491                 set state {OO}
2492         }
2493
2494         set reselect 0
2495         if {[string first {U} $state] >= 0} {
2496                 # Already a conflict, do nothing
2497         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2498                 set reselect 1
2499         } elseif {[string index $state 1] ne {O}} {
2500                 # Already a diff & no conflicts, do nothing
2501         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2502                 set reselect 1
2503         }
2504
2505         if {$reselect} {
2506                 next_diff $after
2507         } else {
2508                 uplevel #0 $after
2509         }
2510 }
2511
2512 proc toggle_or_diff {w x y} {
2513         global file_states file_lists current_diff_path ui_index ui_workdir
2514         global last_clicked selected_paths
2515
2516         set pos [split [$w index @$x,$y] .]
2517         set lno [lindex $pos 0]
2518         set col [lindex $pos 1]
2519         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2520         if {$path eq {}} {
2521                 set last_clicked {}
2522                 return
2523         }
2524
2525         set last_clicked [list $w $lno]
2526         array unset selected_paths
2527         $ui_index tag remove in_sel 0.0 end
2528         $ui_workdir tag remove in_sel 0.0 end
2529
2530         # Determine the state of the file
2531         if {[info exists file_states($path)]} {
2532                 set state [lindex $file_states($path) 0]
2533         } else {
2534                 set state {__}
2535         }
2536
2537         # Restage the file, or simply show the diff
2538         if {$col == 0 && $y > 1} {
2539                 # Conflicts need special handling
2540                 if {[string first {U} $state] >= 0} {
2541                         # $w must always be $ui_workdir, but...
2542                         if {$w ne $ui_workdir} { set lno {} }
2543                         merge_stage_workdir $path $lno
2544                         return
2545                 }
2546
2547                 if {[string index $state 1] eq {O}} {
2548                         set mmask {}
2549                 } else {
2550                         set mmask {[^O]}
2551                 }
2552
2553                 set after [next_diff_after_action $w $path $lno $mmask]
2554
2555                 if {$w eq $ui_index} {
2556                         update_indexinfo \
2557                                 "Unstaging [short_path $path] from commit" \
2558                                 [list $path] \
2559                                 [concat $after [list ui_ready]]
2560                 } elseif {$w eq $ui_workdir} {
2561                         update_index \
2562                                 "Adding [short_path $path]" \
2563                                 [list $path] \
2564                                 [concat $after [list ui_ready]]
2565                 }
2566         } else {
2567                 set selected_paths($path) 1
2568                 show_diff $path $w $lno
2569         }
2570 }
2571
2572 proc add_one_to_selection {w x y} {
2573         global file_lists last_clicked selected_paths
2574
2575         set lno [lindex [split [$w index @$x,$y] .] 0]
2576         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2577         if {$path eq {}} {
2578                 set last_clicked {}
2579                 return
2580         }
2581
2582         if {$last_clicked ne {}
2583                 && [lindex $last_clicked 0] ne $w} {
2584                 array unset selected_paths
2585                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2586         }
2587
2588         set last_clicked [list $w $lno]
2589         if {[catch {set in_sel $selected_paths($path)}]} {
2590                 set in_sel 0
2591         }
2592         if {$in_sel} {
2593                 unset selected_paths($path)
2594                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2595         } else {
2596                 set selected_paths($path) 1
2597                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2598         }
2599 }
2600
2601 proc add_range_to_selection {w x y} {
2602         global file_lists last_clicked selected_paths
2603
2604         if {[lindex $last_clicked 0] ne $w} {
2605                 toggle_or_diff $w $x $y
2606                 return
2607         }
2608
2609         set lno [lindex [split [$w index @$x,$y] .] 0]
2610         set lc [lindex $last_clicked 1]
2611         if {$lc < $lno} {
2612                 set begin $lc
2613                 set end $lno
2614         } else {
2615                 set begin $lno
2616                 set end $lc
2617         }
2618
2619         foreach path [lrange $file_lists($w) \
2620                 [expr {$begin - 1}] \
2621                 [expr {$end - 1}]] {
2622                 set selected_paths($path) 1
2623         }
2624         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2625 }
2626
2627 proc show_more_context {} {
2628         global repo_config
2629         if {$repo_config(gui.diffcontext) < 99} {
2630                 incr repo_config(gui.diffcontext)
2631                 reshow_diff
2632         }
2633 }
2634
2635 proc show_less_context {} {
2636         global repo_config
2637         if {$repo_config(gui.diffcontext) > 1} {
2638                 incr repo_config(gui.diffcontext) -1
2639                 reshow_diff
2640         }
2641 }
2642
2643 ######################################################################
2644 ##
2645 ## ui construction
2646
2647 set ui_comm {}
2648
2649 # -- Menu Bar
2650 #
2651 menu .mbar -tearoff 0
2652 if {[is_MacOSX]} {
2653         # -- Apple Menu (Mac OS X only)
2654         #
2655         .mbar add cascade -label Apple -menu .mbar.apple
2656         menu .mbar.apple
2657 }
2658 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2659 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2660 if {[is_enabled branch]} {
2661         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2662 }
2663 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2664         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2665 }
2666 if {[is_enabled transport]} {
2667         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2668         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2669 }
2670 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2671         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2672 }
2673
2674 # -- Repository Menu
2675 #
2676 menu .mbar.repository
2677
2678 if {![is_bare]} {
2679         .mbar.repository add command \
2680                 -label [mc "Explore Working Copy"] \
2681                 -command {do_explore}
2682 }
2683
2684 if {[is_Windows]} {
2685         .mbar.repository add command \
2686                 -label [mc "Git Bash"] \
2687                 -command {eval exec [auto_execok start] \
2688                                           [list "Git Bash" bash --login -l &]}
2689 }
2690
2691 if {[is_Windows] || ![is_bare]} {
2692         .mbar.repository add separator
2693 }
2694
2695 .mbar.repository add command \
2696         -label [mc "Browse Current Branch's Files"] \
2697         -command {browser::new $current_branch}
2698 set ui_browse_current [.mbar.repository index last]
2699 .mbar.repository add command \
2700         -label [mc "Browse Branch Files..."] \
2701         -command browser_open::dialog
2702 .mbar.repository add separator
2703
2704 .mbar.repository add command \
2705         -label [mc "Visualize Current Branch's History"] \
2706         -command {do_gitk $current_branch}
2707 set ui_visualize_current [.mbar.repository index last]
2708 .mbar.repository add command \
2709         -label [mc "Visualize All Branch History"] \
2710         -command {do_gitk --all}
2711 .mbar.repository add separator
2712
2713 proc current_branch_write {args} {
2714         global current_branch
2715         .mbar.repository entryconf $::ui_browse_current \
2716                 -label [mc "Browse %s's Files" $current_branch]
2717         .mbar.repository entryconf $::ui_visualize_current \
2718                 -label [mc "Visualize %s's History" $current_branch]
2719 }
2720 trace add variable current_branch write current_branch_write
2721
2722 if {[is_enabled multicommit]} {
2723         .mbar.repository add command -label [mc "Database Statistics"] \
2724                 -command do_stats
2725
2726         .mbar.repository add command -label [mc "Compress Database"] \
2727                 -command do_gc
2728
2729         .mbar.repository add command -label [mc "Verify Database"] \
2730                 -command do_fsck_objects
2731
2732         .mbar.repository add separator
2733
2734         if {[is_Cygwin]} {
2735                 .mbar.repository add command \
2736                         -label [mc "Create Desktop Icon"] \
2737                         -command do_cygwin_shortcut
2738         } elseif {[is_Windows]} {
2739                 .mbar.repository add command \
2740                         -label [mc "Create Desktop Icon"] \
2741                         -command do_windows_shortcut
2742         } elseif {[is_MacOSX]} {
2743                 .mbar.repository add command \
2744                         -label [mc "Create Desktop Icon"] \
2745                         -command do_macosx_app
2746         }
2747 }
2748
2749 if {[is_MacOSX]} {
2750         proc ::tk::mac::Quit {args} { do_quit }
2751 } else {
2752         .mbar.repository add command -label [mc Quit] \
2753                 -command do_quit \
2754                 -accelerator $M1T-Q
2755 }
2756
2757 # -- Edit Menu
2758 #
2759 menu .mbar.edit
2760 .mbar.edit add command -label [mc Undo] \
2761         -command {catch {[focus] edit undo}} \
2762         -accelerator $M1T-Z
2763 .mbar.edit add command -label [mc Redo] \
2764         -command {catch {[focus] edit redo}} \
2765         -accelerator $M1T-Y
2766 .mbar.edit add separator
2767 .mbar.edit add command -label [mc Cut] \
2768         -command {catch {tk_textCut [focus]}} \
2769         -accelerator $M1T-X
2770 .mbar.edit add command -label [mc Copy] \
2771         -command {catch {tk_textCopy [focus]}} \
2772         -accelerator $M1T-C
2773 .mbar.edit add command -label [mc Paste] \
2774         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2775         -accelerator $M1T-V
2776 .mbar.edit add command -label [mc Delete] \
2777         -command {catch {[focus] delete sel.first sel.last}} \
2778         -accelerator Del
2779 .mbar.edit add separator
2780 .mbar.edit add command -label [mc "Select All"] \
2781         -command {catch {[focus] tag add sel 0.0 end}} \
2782         -accelerator $M1T-A
2783
2784 # -- Branch Menu
2785 #
2786 if {[is_enabled branch]} {
2787         menu .mbar.branch
2788
2789         .mbar.branch add command -label [mc "Create..."] \
2790                 -command branch_create::dialog \
2791                 -accelerator $M1T-N
2792         lappend disable_on_lock [list .mbar.branch entryconf \
2793                 [.mbar.branch index last] -state]
2794
2795         .mbar.branch add command -label [mc "Checkout..."] \
2796                 -command branch_checkout::dialog \
2797                 -accelerator $M1T-O
2798         lappend disable_on_lock [list .mbar.branch entryconf \
2799                 [.mbar.branch index last] -state]
2800
2801         .mbar.branch add command -label [mc "Rename..."] \
2802                 -command branch_rename::dialog
2803         lappend disable_on_lock [list .mbar.branch entryconf \
2804                 [.mbar.branch index last] -state]
2805
2806         .mbar.branch add command -label [mc "Delete..."] \
2807                 -command branch_delete::dialog
2808         lappend disable_on_lock [list .mbar.branch entryconf \
2809                 [.mbar.branch index last] -state]
2810
2811         .mbar.branch add command -label [mc "Reset..."] \
2812                 -command merge::reset_hard
2813         lappend disable_on_lock [list .mbar.branch entryconf \
2814                 [.mbar.branch index last] -state]
2815 }
2816
2817 # -- Commit Menu
2818 #
2819 proc commit_btn_caption {} {
2820         if {[is_enabled nocommit]} {
2821                 return [mc "Done"]
2822         } else {
2823                 return [mc Commit@@verb]
2824         }
2825 }
2826
2827 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2828         menu .mbar.commit
2829
2830         if {![is_enabled nocommit]} {
2831                 .mbar.commit add radiobutton \
2832                         -label [mc "New Commit"] \
2833                         -command do_select_commit_type \
2834                         -variable selected_commit_type \
2835                         -value new
2836                 lappend disable_on_lock \
2837                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2838
2839                 .mbar.commit add radiobutton \
2840                         -label [mc "Amend Last Commit"] \
2841                         -command do_select_commit_type \
2842                         -variable selected_commit_type \
2843                         -value amend
2844                 lappend disable_on_lock \
2845                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2846
2847                 .mbar.commit add separator
2848         }
2849
2850         .mbar.commit add command -label [mc Rescan] \
2851                 -command ui_do_rescan \
2852                 -accelerator F5
2853         lappend disable_on_lock \
2854                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2855
2856         .mbar.commit add command -label [mc "Stage To Commit"] \
2857                 -command do_add_selection \
2858                 -accelerator $M1T-T
2859         lappend disable_on_lock \
2860                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2861
2862         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2863                 -command do_add_all \
2864                 -accelerator $M1T-I
2865         lappend disable_on_lock \
2866                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2867
2868         .mbar.commit add command -label [mc "Unstage From Commit"] \
2869                 -command do_unstage_selection \
2870                 -accelerator $M1T-U
2871         lappend disable_on_lock \
2872                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2873
2874         .mbar.commit add command -label [mc "Revert Changes"] \
2875                 -command do_revert_selection \
2876                 -accelerator $M1T-J
2877         lappend disable_on_lock \
2878                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2879
2880         .mbar.commit add separator
2881
2882         .mbar.commit add command -label [mc "Show Less Context"] \
2883                 -command show_less_context \
2884                 -accelerator $M1T-\-
2885
2886         .mbar.commit add command -label [mc "Show More Context"] \
2887                 -command show_more_context \
2888                 -accelerator $M1T-=
2889
2890         .mbar.commit add separator
2891
2892         if {![is_enabled nocommitmsg]} {
2893                 .mbar.commit add command -label [mc "Sign Off"] \
2894                         -command do_signoff \
2895                         -accelerator $M1T-S
2896         }
2897
2898         .mbar.commit add command -label [commit_btn_caption] \
2899                 -command do_commit \
2900                 -accelerator $M1T-Return
2901         lappend disable_on_lock \
2902                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2903 }
2904
2905 # -- Merge Menu
2906 #
2907 if {[is_enabled branch]} {
2908         menu .mbar.merge
2909         .mbar.merge add command -label [mc "Local Merge..."] \
2910                 -command merge::dialog \
2911                 -accelerator $M1T-M
2912         lappend disable_on_lock \
2913                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2914         .mbar.merge add command -label [mc "Abort Merge..."] \
2915                 -command merge::reset_hard
2916         lappend disable_on_lock \
2917                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2918 }
2919
2920 # -- Transport Menu
2921 #
2922 if {[is_enabled transport]} {
2923         menu .mbar.remote
2924
2925         .mbar.remote add command \
2926                 -label [mc "Add..."] \
2927                 -command remote_add::dialog \
2928                 -accelerator $M1T-A
2929         .mbar.remote add command \
2930                 -label [mc "Push..."] \
2931                 -command do_push_anywhere \
2932                 -accelerator $M1T-P
2933         .mbar.remote add command \
2934                 -label [mc "Delete Branch..."] \
2935                 -command remote_branch_delete::dialog
2936 }
2937
2938 if {[is_MacOSX]} {
2939         proc ::tk::mac::ShowPreferences {} {do_options}
2940 } else {
2941         # -- Edit Menu
2942         #
2943         .mbar.edit add separator
2944         .mbar.edit add command -label [mc "Options..."] \
2945                 -command do_options
2946 }
2947
2948 # -- Tools Menu
2949 #
2950 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2951         set tools_menubar .mbar.tools
2952         menu $tools_menubar
2953         $tools_menubar add separator
2954         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2955         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2956         set tools_tailcnt 3
2957         if {[array names repo_config guitool.*.cmd] ne {}} {
2958                 tools_populate_all
2959         }
2960 }
2961
2962 # -- Help Menu
2963 #
2964 .mbar add cascade -label [mc Help] -menu .mbar.help
2965 menu .mbar.help
2966
2967 if {[is_MacOSX]} {
2968         .mbar.apple add command -label [mc "About %s" [appname]] \
2969                 -command do_about
2970         .mbar.apple add separator
2971 } else {
2972         .mbar.help add command -label [mc "About %s" [appname]] \
2973                 -command do_about
2974 }
2975 . configure -menu .mbar
2976
2977 set doc_path [githtmldir]
2978 if {$doc_path ne {}} {
2979         set doc_path [file join $doc_path index.html]
2980
2981         if {[is_Cygwin]} {
2982                 set doc_path [exec cygpath --mixed $doc_path]
2983         }
2984 }
2985
2986 if {[file isfile $doc_path]} {
2987         set doc_url "file:$doc_path"
2988 } else {
2989         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2990 }
2991
2992 proc start_browser {url} {
2993         git "web--browse" $url
2994 }
2995
2996 .mbar.help add command -label [mc "Online Documentation"] \
2997         -command [list start_browser $doc_url]
2998
2999 .mbar.help add command -label [mc "Show SSH Key"] \
3000         -command do_ssh_key
3001
3002 unset doc_path doc_url
3003
3004 # -- Standard bindings
3005 #
3006 wm protocol . WM_DELETE_WINDOW do_quit
3007 bind all <$M1B-Key-q> do_quit
3008 bind all <$M1B-Key-Q> do_quit
3009 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3010 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3011
3012 set subcommand_args {}
3013 proc usage {} {
3014         set s "usage: $::argv0 $::subcommand $::subcommand_args"
3015         if {[tk windowingsystem] eq "win32"} {
3016                 wm withdraw .
3017                 tk_messageBox -icon info -message $s \
3018                         -title [mc "Usage"]
3019         } else {
3020                 puts stderr $s
3021         }
3022         exit 1
3023 }
3024
3025 proc normalize_relpath {path} {
3026         set elements {}
3027         foreach item [file split $path] {
3028                 if {$item eq {.}} continue
3029                 if {$item eq {..} && [llength $elements] > 0
3030                     && [lindex $elements end] ne {..}} {
3031                         set elements [lrange $elements 0 end-1]
3032                         continue
3033                 }
3034                 lappend elements $item
3035         }
3036         return [eval file join $elements]
3037 }
3038
3039 # -- Not a normal commit type invocation?  Do that instead!
3040 #
3041 switch -- $subcommand {
3042 browser -
3043 blame {
3044         if {$subcommand eq "blame"} {
3045                 set subcommand_args {[--line=<num>] rev? path}
3046         } else {
3047                 set subcommand_args {rev? path}
3048         }
3049         if {$argv eq {}} usage
3050         set head {}
3051         set path {}
3052         set jump_spec {}
3053         set is_path 0
3054         foreach a $argv {
3055                 set p [file join $_prefix $a]
3056
3057                 if {$is_path || [file exists $p]} {
3058                         if {$path ne {}} usage
3059                         set path [normalize_relpath $p]
3060                         break
3061                 } elseif {$a eq {--}} {
3062                         if {$path ne {}} {
3063                                 if {$head ne {}} usage
3064                                 set head $path
3065                                 set path {}
3066                         }
3067                         set is_path 1
3068                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
3069                         if {$jump_spec ne {} || $head ne {}} usage
3070                         set jump_spec [list $lnum]
3071                 } elseif {$head eq {}} {
3072                         if {$head ne {}} usage
3073                         set head $a
3074                         set is_path 1
3075                 } else {
3076                         usage
3077                 }
3078         }
3079         unset is_path
3080
3081         if {$head ne {} && $path eq {}} {
3082                 if {[string index $head 0] eq {/}} {
3083                         set path [normalize_relpath $head]
3084                         set head {}
3085                 } else {
3086                         set path [normalize_relpath $_prefix$head]
3087                         set head {}
3088                 }
3089         }
3090
3091         if {$head eq {}} {
3092                 load_current_branch
3093         } else {
3094                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
3095                         if {[catch {
3096                                         set head [git rev-parse --verify $head]
3097                                 } err]} {
3098                                 if {[tk windowingsystem] eq "win32"} {
3099                                         tk_messageBox -icon error -title [mc Error] -message $err
3100                                 } else {
3101                                         puts stderr $err
3102                                 }
3103                                 exit 1
3104                         }
3105                 }
3106                 set current_branch $head
3107         }
3108
3109         wm deiconify .
3110         switch -- $subcommand {
3111         browser {
3112                 if {$jump_spec ne {}} usage
3113                 if {$head eq {}} {
3114                         if {$path ne {} && [file isdirectory $path]} {
3115                                 set head $current_branch
3116                         } else {
3117                                 set head $path
3118                                 set path {}
3119                         }
3120                 }
3121                 browser::new $head $path
3122         }
3123         blame   {
3124                 if {$head eq {} && ![file exists $path]} {
3125                         catch {wm withdraw .}
3126                         tk_messageBox \
3127                                 -icon error \
3128                                 -type ok \
3129                                 -title [mc "git-gui: fatal error"] \
3130                                 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3131                         exit 1
3132                 }
3133                 blame::new $head $path $jump_spec
3134         }
3135         }
3136         return
3137 }
3138 citool -
3139 gui {
3140         if {[llength $argv] != 0} {
3141                 usage
3142         }
3143         # fall through to setup UI for commits
3144 }
3145 default {
3146         set err "usage: $argv0 \[{blame|browser|citool}\]"
3147         if {[tk windowingsystem] eq "win32"} {
3148                 wm withdraw .
3149                 tk_messageBox -icon error -message $err \
3150                         -title [mc "Usage"]
3151         } else {
3152                 puts stderr $err
3153         }
3154         exit 1
3155 }
3156 }
3157
3158 # -- Branch Control
3159 #
3160 ${NS}::frame .branch
3161 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3162 ${NS}::label .branch.l1 \
3163         -text [mc "Current Branch:"] \
3164         -anchor w \
3165         -justify left
3166 ${NS}::label .branch.cb \
3167         -textvariable current_branch \
3168         -anchor w \
3169         -justify left
3170 pack .branch.l1 -side left
3171 pack .branch.cb -side left -fill x
3172 pack .branch -side top -fill x
3173
3174 # -- Main Window Layout
3175 #
3176 ${NS}::panedwindow .vpane -orient horizontal
3177 ${NS}::panedwindow .vpane.files -orient vertical
3178 if {$use_ttk} {
3179         .vpane add .vpane.files
3180 } else {
3181         .vpane add .vpane.files -sticky nsew -height 100 -width 200
3182 }
3183 pack .vpane -anchor n -side top -fill both -expand 1
3184
3185 # -- Index File List
3186 #
3187 ${NS}::frame .vpane.files.index -height 100 -width 200
3188 tlabel .vpane.files.index.title \
3189         -text [mc "Staged Changes (Will Commit)"] \
3190         -background lightgreen -foreground black
3191 text $ui_index -background white -foreground black \
3192         -borderwidth 0 \
3193         -width 20 -height 10 \
3194         -wrap none \
3195         -cursor $cursor_ptr \
3196         -xscrollcommand {.vpane.files.index.sx set} \
3197         -yscrollcommand {.vpane.files.index.sy set} \
3198         -state disabled
3199 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3200 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3201 pack .vpane.files.index.title -side top -fill x
3202 pack .vpane.files.index.sx -side bottom -fill x
3203 pack .vpane.files.index.sy -side right -fill y
3204 pack $ui_index -side left -fill both -expand 1
3205
3206 # -- Working Directory File List
3207 #
3208 ${NS}::frame .vpane.files.workdir -height 100 -width 200
3209 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3210         -background lightsalmon -foreground black
3211 text $ui_workdir -background white -foreground black \
3212         -borderwidth 0 \
3213         -width 20 -height 10 \
3214         -wrap none \
3215         -cursor $cursor_ptr \
3216         -xscrollcommand {.vpane.files.workdir.sx set} \
3217         -yscrollcommand {.vpane.files.workdir.sy set} \
3218         -state disabled
3219 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3220 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3221 pack .vpane.files.workdir.title -side top -fill x
3222 pack .vpane.files.workdir.sx -side bottom -fill x
3223 pack .vpane.files.workdir.sy -side right -fill y
3224 pack $ui_workdir -side left -fill both -expand 1
3225
3226 .vpane.files add .vpane.files.workdir
3227 .vpane.files add .vpane.files.index
3228 if {!$use_ttk} {
3229         .vpane.files paneconfigure .vpane.files.workdir -sticky news
3230         .vpane.files paneconfigure .vpane.files.index -sticky news
3231 }
3232
3233 foreach i [list $ui_index $ui_workdir] {
3234         rmsel_tag $i
3235         $i tag conf in_diff -background [$i tag cget in_sel -background]
3236 }
3237 unset i
3238
3239 # -- Diff and Commit Area
3240 #
3241 if {$have_tk85} {
3242         ${NS}::panedwindow .vpane.lower -orient vertical
3243         ${NS}::frame .vpane.lower.commarea
3244         ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1 -height 500
3245         .vpane.lower add .vpane.lower.diff
3246         .vpane.lower add .vpane.lower.commarea
3247         .vpane add .vpane.lower
3248         if {$use_ttk} {
3249                 .vpane.lower pane .vpane.lower.diff -weight 1
3250                 .vpane.lower pane .vpane.lower.commarea -weight 0
3251         } else {
3252                 .vpane.lower paneconfigure .vpane.lower.diff -stretch always
3253                 .vpane.lower paneconfigure .vpane.lower.commarea -stretch never
3254         }
3255 } else {
3256         frame .vpane.lower -height 300 -width 400
3257         frame .vpane.lower.commarea
3258         frame .vpane.lower.diff -relief sunken -borderwidth 1
3259         pack .vpane.lower.diff -fill both -expand 1
3260         pack .vpane.lower.commarea -side bottom -fill x
3261         .vpane add .vpane.lower
3262         .vpane paneconfigure .vpane.lower -sticky nsew
3263 }
3264
3265 # -- Commit Area Buttons
3266 #
3267 ${NS}::frame .vpane.lower.commarea.buttons
3268 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3269         -anchor w \
3270         -justify left
3271 pack .vpane.lower.commarea.buttons.l -side top -fill x
3272 pack .vpane.lower.commarea.buttons -side left -fill y
3273
3274 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3275         -command ui_do_rescan
3276 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3277 lappend disable_on_lock \
3278         {.vpane.lower.commarea.buttons.rescan conf -state}
3279
3280 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3281         -command do_add_all
3282 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3283 lappend disable_on_lock \
3284         {.vpane.lower.commarea.buttons.incall conf -state}
3285
3286 if {![is_enabled nocommitmsg]} {
3287         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3288                 -command do_signoff
3289         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3290 }
3291
3292 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3293         -command do_commit
3294 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3295 lappend disable_on_lock \
3296         {.vpane.lower.commarea.buttons.commit conf -state}
3297
3298 if {![is_enabled nocommit]} {
3299         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3300                 -command do_push_anywhere
3301         pack .vpane.lower.commarea.buttons.push -side top -fill x
3302 }
3303
3304 # -- Commit Message Buffer
3305 #
3306 ${NS}::frame .vpane.lower.commarea.buffer
3307 ${NS}::frame .vpane.lower.commarea.buffer.header
3308 set ui_comm .vpane.lower.commarea.buffer.t
3309 set ui_coml .vpane.lower.commarea.buffer.header.l
3310
3311 if {![is_enabled nocommit]} {
3312         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3313                 -text [mc "New Commit"] \
3314                 -command do_select_commit_type \
3315                 -variable selected_commit_type \
3316                 -value new
3317         lappend disable_on_lock \
3318                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3319         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3320                 -text [mc "Amend Last Commit"] \
3321                 -command do_select_commit_type \
3322                 -variable selected_commit_type \
3323                 -value amend
3324         lappend disable_on_lock \
3325                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3326 }
3327
3328 ${NS}::label $ui_coml \
3329         -anchor w \
3330         -justify left
3331 proc trace_commit_type {varname args} {
3332         global ui_coml commit_type
3333         switch -glob -- $commit_type {
3334         initial       {set txt [mc "Initial Commit Message:"]}
3335         amend         {set txt [mc "Amended Commit Message:"]}
3336         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3337         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3338         merge         {set txt [mc "Merge Commit Message:"]}
3339         *             {set txt [mc "Commit Message:"]}
3340         }
3341         $ui_coml conf -text $txt
3342 }
3343 trace add variable commit_type write trace_commit_type
3344 pack $ui_coml -side left -fill x
3345
3346 if {![is_enabled nocommit]} {
3347         pack .vpane.lower.commarea.buffer.header.amend -side right
3348         pack .vpane.lower.commarea.buffer.header.new -side right
3349 }
3350
3351 text $ui_comm -background white -foreground black \
3352         -borderwidth 1 \
3353         -undo true \
3354         -maxundo 20 \
3355         -autoseparators true \
3356         -relief sunken \
3357         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3358         -font font_diff \
3359         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3360 ${NS}::scrollbar .vpane.lower.commarea.buffer.sby \
3361         -command [list $ui_comm yview]
3362 pack .vpane.lower.commarea.buffer.header -side top -fill x
3363 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3364 pack $ui_comm -side left -fill y
3365 pack .vpane.lower.commarea.buffer -side left -fill y
3366
3367 # -- Commit Message Buffer Context Menu
3368 #
3369 set ctxm .vpane.lower.commarea.buffer.ctxm
3370 menu $ctxm -tearoff 0
3371 $ctxm add command \
3372         -label [mc Cut] \
3373         -command {tk_textCut $ui_comm}
3374 $ctxm add command \
3375         -label [mc Copy] \
3376         -command {tk_textCopy $ui_comm}
3377 $ctxm add command \
3378         -label [mc Paste] \
3379         -command {tk_textPaste $ui_comm}
3380 $ctxm add command \
3381         -label [mc Delete] \
3382         -command {catch {$ui_comm delete sel.first sel.last}}
3383 $ctxm add separator
3384 $ctxm add command \
3385         -label [mc "Select All"] \
3386         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3387 $ctxm add command \
3388         -label [mc "Copy All"] \
3389         -command {
3390                 $ui_comm tag add sel 0.0 end
3391                 tk_textCopy $ui_comm
3392                 $ui_comm tag remove sel 0.0 end
3393         }
3394 $ctxm add separator
3395 $ctxm add command \
3396         -label [mc "Sign Off"] \
3397         -command do_signoff
3398 set ui_comm_ctxm $ctxm
3399
3400 # -- Diff Header
3401 #
3402 proc trace_current_diff_path {varname args} {
3403         global current_diff_path diff_actions file_states
3404         if {$current_diff_path eq {}} {
3405                 set s {}
3406                 set f {}
3407                 set p {}
3408                 set o disabled
3409         } else {
3410                 set p $current_diff_path
3411                 set s [mapdesc [lindex $file_states($p) 0] $p]
3412                 set f [mc "File:"]
3413                 set p [escape_path $p]
3414                 set o normal
3415         }
3416
3417         .vpane.lower.diff.header.status configure -text $s
3418         .vpane.lower.diff.header.file configure -text $f
3419         .vpane.lower.diff.header.path configure -text $p
3420         foreach w $diff_actions {
3421                 uplevel #0 $w $o
3422         }
3423 }
3424 trace add variable current_diff_path write trace_current_diff_path
3425
3426 gold_frame .vpane.lower.diff.header
3427 tlabel .vpane.lower.diff.header.status \
3428         -background gold \
3429         -foreground black \
3430         -width $max_status_desc \
3431         -anchor w \
3432         -justify left
3433 tlabel .vpane.lower.diff.header.file \
3434         -background gold \
3435         -foreground black \
3436         -anchor w \
3437         -justify left
3438 tlabel .vpane.lower.diff.header.path \
3439         -background gold \
3440         -foreground black \
3441         -anchor w \
3442         -justify left
3443 pack .vpane.lower.diff.header.status -side left
3444 pack .vpane.lower.diff.header.file -side left
3445 pack .vpane.lower.diff.header.path -fill x
3446 set ctxm .vpane.lower.diff.header.ctxm
3447 menu $ctxm -tearoff 0
3448 $ctxm add command \
3449         -label [mc Copy] \
3450         -command {
3451                 clipboard clear
3452                 clipboard append \
3453                         -format STRING \
3454                         -type STRING \
3455                         -- $current_diff_path
3456         }
3457 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3458 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3459
3460 # -- Diff Body
3461 #
3462 ${NS}::frame .vpane.lower.diff.body
3463 set ui_diff .vpane.lower.diff.body.t
3464 text $ui_diff -background white -foreground black \
3465         -borderwidth 0 \
3466         -width 80 -height 5 -wrap none \
3467         -font font_diff \
3468         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3469         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3470         -state disabled
3471 catch {$ui_diff configure -tabstyle wordprocessor}
3472 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3473         -command [list $ui_diff xview]
3474 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3475         -command [list $ui_diff yview]
3476 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3477 pack .vpane.lower.diff.body.sby -side right -fill y
3478 pack $ui_diff -side left -fill both -expand 1
3479 pack .vpane.lower.diff.header -side top -fill x
3480 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3481
3482 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3483         $ui_diff tag configure clr4$n -background $c
3484         $ui_diff tag configure clri4$n -foreground $c
3485         $ui_diff tag configure clr3$n -foreground $c
3486         $ui_diff tag configure clri3$n -background $c
3487 }
3488 $ui_diff tag configure clr1 -font font_diffbold
3489 $ui_diff tag configure clr4 -underline 1
3490
3491 $ui_diff tag conf d_info -foreground blue -font font_diffbold
3492
3493 $ui_diff tag conf d_cr -elide true
3494 $ui_diff tag conf d_@ -font font_diffbold
3495 $ui_diff tag conf d_+ -foreground {#00a000}
3496 $ui_diff tag conf d_- -foreground red
3497
3498 $ui_diff tag conf d_++ -foreground {#00a000}
3499 $ui_diff tag conf d_-- -foreground red
3500 $ui_diff tag conf d_+s \
3501         -foreground {#00a000} \
3502         -background {#e2effa}
3503 $ui_diff tag conf d_-s \
3504         -foreground red \
3505         -background {#e2effa}
3506 $ui_diff tag conf d_s+ \
3507         -foreground {#00a000} \
3508         -background ivory1
3509 $ui_diff tag conf d_s- \
3510         -foreground red \
3511         -background ivory1
3512
3513 $ui_diff tag conf d< \
3514         -foreground orange \
3515         -font font_diffbold
3516 $ui_diff tag conf d= \
3517         -foreground orange \
3518         -font font_diffbold
3519 $ui_diff tag conf d> \
3520         -foreground orange \
3521         -font font_diffbold
3522
3523 $ui_diff tag raise sel
3524
3525 # -- Diff Body Context Menu
3526 #
3527
3528 proc create_common_diff_popup {ctxm} {
3529         $ctxm add command \
3530                 -label [mc Refresh] \
3531                 -command reshow_diff
3532         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3533         $ctxm add command \
3534                 -label [mc Copy] \
3535                 -command {tk_textCopy $ui_diff}
3536         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3537         $ctxm add command \
3538                 -label [mc "Select All"] \
3539                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3540         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3541         $ctxm add command \
3542                 -label [mc "Copy All"] \
3543                 -command {
3544                         $ui_diff tag add sel 0.0 end
3545                         tk_textCopy $ui_diff
3546                         $ui_diff tag remove sel 0.0 end
3547                 }
3548         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3549         $ctxm add separator
3550         $ctxm add command \
3551                 -label [mc "Decrease Font Size"] \
3552                 -command {incr_font_size font_diff -1}
3553         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3554         $ctxm add command \
3555                 -label [mc "Increase Font Size"] \
3556                 -command {incr_font_size font_diff 1}
3557         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3558         $ctxm add separator
3559         set emenu $ctxm.enc
3560         menu $emenu
3561         build_encoding_menu $emenu [list force_diff_encoding]
3562         $ctxm add cascade \
3563                 -label [mc "Encoding"] \
3564                 -menu $emenu
3565         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3566         $ctxm add separator
3567         $ctxm add command -label [mc "Options..."] \
3568                 -command do_options
3569 }
3570
3571 set ctxm .vpane.lower.diff.body.ctxm
3572 menu $ctxm -tearoff 0
3573 $ctxm add command \
3574         -label [mc "Apply/Reverse Hunk"] \
3575         -command {apply_hunk $cursorX $cursorY}
3576 set ui_diff_applyhunk [$ctxm index last]
3577 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3578 $ctxm add command \
3579         -label [mc "Apply/Reverse Line"] \
3580         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3581 set ui_diff_applyline [$ctxm index last]
3582 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3583 $ctxm add separator
3584 $ctxm add command \
3585         -label [mc "Show Less Context"] \
3586         -command show_less_context
3587 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3588 $ctxm add command \
3589         -label [mc "Show More Context"] \
3590         -command show_more_context
3591 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3592 $ctxm add separator
3593 create_common_diff_popup $ctxm
3594
3595 set ctxmmg .vpane.lower.diff.body.ctxmmg
3596 menu $ctxmmg -tearoff 0
3597 $ctxmmg add command \
3598         -label [mc "Run Merge Tool"] \
3599         -command {merge_resolve_tool}
3600 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3601 $ctxmmg add separator
3602 $ctxmmg add command \
3603         -label [mc "Use Remote Version"] \
3604         -command {merge_resolve_one 3}
3605 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3606 $ctxmmg add command \
3607         -label [mc "Use Local Version"] \
3608         -command {merge_resolve_one 2}
3609 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3610 $ctxmmg add command \
3611         -label [mc "Revert To Base"] \
3612         -command {merge_resolve_one 1}
3613 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3614 $ctxmmg add separator
3615 $ctxmmg add command \
3616         -label [mc "Show Less Context"] \
3617         -command show_less_context
3618 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3619 $ctxmmg add command \
3620         -label [mc "Show More Context"] \
3621         -command show_more_context
3622 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3623 $ctxmmg add separator
3624 create_common_diff_popup $ctxmmg
3625
3626 set ctxmsm .vpane.lower.diff.body.ctxmsm
3627 menu $ctxmsm -tearoff 0
3628 $ctxmsm add command \
3629         -label [mc "Visualize These Changes In The Submodule"] \
3630         -command {do_gitk -- true}
3631 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3632 $ctxmsm add command \
3633         -label [mc "Visualize Current Branch History In The Submodule"] \
3634         -command {do_gitk {} true}
3635 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3636 $ctxmsm add command \
3637         -label [mc "Visualize All Branch History In The Submodule"] \
3638         -command {do_gitk --all true}
3639 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3640 $ctxmsm add separator
3641 $ctxmsm add command \
3642         -label [mc "Start git gui In The Submodule"] \
3643         -command {do_git_gui}
3644 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3645 $ctxmsm add separator
3646 create_common_diff_popup $ctxmsm
3647
3648 proc has_textconv {path} {
3649         if {[is_config_false gui.textconv]} {
3650                 return 0
3651         }
3652         set filter [gitattr $path diff set]
3653         set textconv [get_config [join [list diff $filter textconv] .]]
3654         if {$filter ne {set} && $textconv ne {}} {
3655                 return 1
3656         } else {
3657                 return 0
3658         }
3659 }
3660
3661 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3662         global current_diff_path file_states
3663         set ::cursorX $x
3664         set ::cursorY $y
3665         if {[info exists file_states($current_diff_path)]} {
3666                 set state [lindex $file_states($current_diff_path) 0]
3667         } else {
3668                 set state {__}
3669         }
3670         if {[string first {U} $state] >= 0} {
3671                 tk_popup $ctxmmg $X $Y
3672         } elseif {$::is_submodule_diff} {
3673                 tk_popup $ctxmsm $X $Y
3674         } else {
3675                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3676                 if {$::ui_index eq $::current_diff_side} {
3677                         set l [mc "Unstage Hunk From Commit"]
3678                         if {$has_range} {
3679                                 set t [mc "Unstage Lines From Commit"]
3680                         } else {
3681                                 set t [mc "Unstage Line From Commit"]
3682                         }
3683                 } else {
3684                         set l [mc "Stage Hunk For Commit"]
3685                         if {$has_range} {
3686                                 set t [mc "Stage Lines For Commit"]
3687                         } else {
3688                                 set t [mc "Stage Line For Commit"]
3689                         }
3690                 }
3691                 if {$::is_3way_diff
3692                         || $current_diff_path eq {}
3693                         || {__} eq $state
3694                         || {_O} eq $state
3695                         || [string match {?T} $state]
3696                         || [string match {T?} $state]
3697                         || [has_textconv $current_diff_path]} {
3698                         set s disabled
3699                 } else {
3700                         set s normal
3701                 }
3702                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3703                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3704                 tk_popup $ctxm $X $Y
3705         }
3706 }
3707 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3708
3709 # -- Status Bar
3710 #
3711 set main_status [::status_bar::new .status]
3712 pack .status -anchor w -side bottom -fill x
3713 $main_status show [mc "Initializing..."]
3714
3715 # -- Load geometry
3716 #
3717 proc on_ttk_pane_mapped {w pane pos} {
3718         bind $w <Map> {}
3719         after 0 [list after idle [list $w sashpos $pane $pos]]
3720 }
3721 proc on_tk_pane_mapped {w pane x y} {
3722         bind $w <Map> {}
3723         after 0 [list after idle [list $w sash place $pane $x $y]]
3724 }
3725 proc on_application_mapped {} {
3726         global repo_config use_ttk
3727         bind . <Map> {}
3728         set gm $repo_config(gui.geometry)
3729         if {$use_ttk} {
3730                 bind .vpane <Map> \
3731                     [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3732                 bind .vpane.files <Map> \
3733                     [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3734         } else {
3735                 bind .vpane <Map> \
3736                     [list on_tk_pane_mapped %W 0 \
3737                          [lindex $gm 1] \
3738                          [lindex [.vpane sash coord 0] 1]]
3739                 bind .vpane.files <Map> \
3740                     [list on_tk_pane_mapped %W 0 \
3741                          [lindex [.vpane.files sash coord 0] 0] \
3742                          [lindex $gm 2]]
3743         }
3744         wm geometry . [lindex $gm 0]
3745 }
3746 if {[info exists repo_config(gui.geometry)]} {
3747         bind . <Map> [list on_application_mapped]
3748         wm geometry . [lindex $repo_config(gui.geometry) 0]
3749 }
3750
3751 # -- Load window state
3752 #
3753 if {[info exists repo_config(gui.wmstate)]} {
3754         catch {wm state . $repo_config(gui.wmstate)}
3755 }
3756
3757 # -- Key Bindings
3758 #
3759 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3760 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3761 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3762 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3763 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3764 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3765 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3766 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3767 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3768 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3769 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3770 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3771 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3772 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3773 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3774 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3775 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3776 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3777 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3778 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3779 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3780 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3781
3782 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3783 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3784 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3785 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3786 bind $ui_diff <$M1B-Key-v> {break}
3787 bind $ui_diff <$M1B-Key-V> {break}
3788 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3789 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3790 bind $ui_diff <$M1B-Key-j> {do_revert_selection;break}
3791 bind $ui_diff <$M1B-Key-J> {do_revert_selection;break}
3792 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3793 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3794 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3795 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3796 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3797 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3798 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3799 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3800 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3801 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3802 bind $ui_diff <Button-1>   {focus %W}
3803
3804 if {[is_enabled branch]} {
3805         bind . <$M1B-Key-n> branch_create::dialog
3806         bind . <$M1B-Key-N> branch_create::dialog
3807         bind . <$M1B-Key-o> branch_checkout::dialog
3808         bind . <$M1B-Key-O> branch_checkout::dialog
3809         bind . <$M1B-Key-m> merge::dialog
3810         bind . <$M1B-Key-M> merge::dialog
3811 }
3812 if {[is_enabled transport]} {
3813         bind . <$M1B-Key-p> do_push_anywhere
3814         bind . <$M1B-Key-P> do_push_anywhere
3815 }
3816
3817 bind .   <Key-F5>     ui_do_rescan
3818 bind .   <$M1B-Key-r> ui_do_rescan
3819 bind .   <$M1B-Key-R> ui_do_rescan
3820 bind .   <$M1B-Key-s> do_signoff
3821 bind .   <$M1B-Key-S> do_signoff
3822 bind .   <$M1B-Key-t> do_add_selection
3823 bind .   <$M1B-Key-T> do_add_selection
3824 bind .   <$M1B-Key-u> do_unstage_selection
3825 bind .   <$M1B-Key-U> do_unstage_selection
3826 bind .   <$M1B-Key-j> do_revert_selection
3827 bind .   <$M1B-Key-J> do_revert_selection
3828 bind .   <$M1B-Key-i> do_add_all
3829 bind .   <$M1B-Key-I> do_add_all
3830 bind .   <$M1B-Key-minus> {show_less_context;break}
3831 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3832 bind .   <$M1B-Key-equal> {show_more_context;break}
3833 bind .   <$M1B-Key-plus> {show_more_context;break}
3834 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3835 bind .   <$M1B-Key-Return> do_commit
3836 foreach i [list $ui_index $ui_workdir] {
3837         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3838         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3839         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3840 }
3841 unset i
3842
3843 set file_lists($ui_index) [list]
3844 set file_lists($ui_workdir) [list]
3845
3846 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3847 focus -force $ui_comm
3848
3849 # -- Warn the user about environmental problems.  Cygwin's Tcl
3850 #    does *not* pass its env array onto any processes it spawns.
3851 #    This means that git processes get none of our environment.
3852 #
3853 if {[is_Cygwin]} {
3854         set ignored_env 0
3855         set suggest_user {}
3856         set msg [mc "Possible environment issues exist.
3857
3858 The following environment variables are probably
3859 going to be ignored by any Git subprocess run
3860 by %s:
3861
3862 " [appname]]
3863         foreach name [array names env] {
3864                 switch -regexp -- $name {
3865                 {^GIT_INDEX_FILE$} -
3866                 {^GIT_OBJECT_DIRECTORY$} -
3867                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3868                 {^GIT_DIFF_OPTS$} -
3869                 {^GIT_EXTERNAL_DIFF$} -
3870                 {^GIT_PAGER$} -
3871                 {^GIT_TRACE$} -
3872                 {^GIT_CONFIG$} -
3873                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3874                         append msg " - $name\n"
3875                         incr ignored_env
3876                 }
3877                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3878                         append msg " - $name\n"
3879                         incr ignored_env
3880                         set suggest_user $name
3881                 }
3882                 }
3883         }
3884         if {$ignored_env > 0} {
3885                 append msg [mc "
3886 This is due to a known issue with the
3887 Tcl binary distributed by Cygwin."]
3888
3889                 if {$suggest_user ne {}} {
3890                         append msg [mc "
3891
3892 A good replacement for %s
3893 is placing values for the user.name and
3894 user.email settings into your personal
3895 ~/.gitconfig file.
3896 " $suggest_user]
3897                 }
3898                 warn_popup $msg
3899         }
3900         unset ignored_env msg suggest_user name
3901 }
3902
3903 # -- Only initialize complex UI if we are going to stay running.
3904 #
3905 if {[is_enabled transport]} {
3906         load_all_remotes
3907
3908         set n [.mbar.remote index end]
3909         populate_remotes_menu
3910         set n [expr {[.mbar.remote index end] - $n}]
3911         if {$n > 0} {
3912                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3913                 .mbar.remote insert $n separator
3914         }
3915         unset n
3916 }
3917
3918 if {[winfo exists $ui_comm]} {
3919         set GITGUI_BCK_exists [load_message GITGUI_BCK utf-8]
3920
3921         # -- If both our backup and message files exist use the
3922         #    newer of the two files to initialize the buffer.
3923         #
3924         if {$GITGUI_BCK_exists} {
3925                 set m [gitdir GITGUI_MSG]
3926                 if {[file isfile $m]} {
3927                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3928                                 catch {file delete [gitdir GITGUI_MSG]}
3929                         } else {
3930                                 $ui_comm delete 0.0 end
3931                                 $ui_comm edit reset
3932                                 $ui_comm edit modified false
3933                                 catch {file delete [gitdir GITGUI_BCK]}
3934                                 set GITGUI_BCK_exists 0
3935                         }
3936                 }
3937                 unset m
3938         }
3939
3940         proc backup_commit_buffer {} {
3941                 global ui_comm GITGUI_BCK_exists
3942
3943                 set m [$ui_comm edit modified]
3944                 if {$m || $GITGUI_BCK_exists} {
3945                         set msg [string trim [$ui_comm get 0.0 end]]
3946                         regsub -all -line {[ \r\t]+$} $msg {} msg
3947
3948                         if {$msg eq {}} {
3949                                 if {$GITGUI_BCK_exists} {
3950                                         catch {file delete [gitdir GITGUI_BCK]}
3951                                         set GITGUI_BCK_exists 0
3952                                 }
3953                         } elseif {$m} {
3954                                 catch {
3955                                         set fd [open [gitdir GITGUI_BCK] w]
3956                                         fconfigure $fd -encoding utf-8
3957                                         puts -nonewline $fd $msg
3958                                         close $fd
3959                                         set GITGUI_BCK_exists 1
3960                                 }
3961                         }
3962
3963                         $ui_comm edit modified false
3964                 }
3965
3966                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3967         }
3968
3969         backup_commit_buffer
3970
3971         # -- If the user has aspell available we can drive it
3972         #    in pipe mode to spellcheck the commit message.
3973         #
3974         set spell_cmd [list |]
3975         set spell_dict [get_config gui.spellingdictionary]
3976         lappend spell_cmd aspell
3977         if {$spell_dict ne {}} {
3978                 lappend spell_cmd --master=$spell_dict
3979         }
3980         lappend spell_cmd --mode=none
3981         lappend spell_cmd --encoding=utf-8
3982         lappend spell_cmd pipe
3983         if {$spell_dict eq {none}
3984          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3985                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3986         } else {
3987                 set ui_comm_spell [spellcheck::init \
3988                         $spell_fd \
3989                         $ui_comm \
3990                         $ui_comm_ctxm \
3991                 ]
3992         }
3993         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3994 }
3995
3996 lock_index begin-read
3997 if {![winfo ismapped .]} {
3998         wm deiconify .
3999 }
4000 after 1 {
4001         if {[is_enabled initialamend]} {
4002                 force_amend
4003         } else {
4004                 do_rescan
4005         }
4006
4007         if {[is_enabled nocommitmsg]} {
4008                 $ui_comm configure -state disabled -background gray
4009         }
4010 }
4011 if {[is_enabled multicommit] && ![is_config_false gui.gcwarning]} {
4012         after 1000 hint_gc
4013 }
4014 if {[is_enabled retcode]} {
4015         bind . <Destroy> {+terminate_me %W}
4016 }
4017 if {$picked && [is_config_true gui.autoexplore]} {
4018         do_explore
4019 }
4020
4021 # Local variables:
4022 # mode: tcl
4023 # indent-tabs-mode: t
4024 # tab-width: 4
4025 # End: