git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 package FakeTerm;
  28 sub new {
  29         my ($class, $reason) = @_;
  30         return bless \$reason, shift;
  31 }
  32 sub readline {
  33         my $self = shift;
  34         die "Cannot use readline on FakeTerm: $$self";
  35 }
  36 package main;
  37
  38
  39 sub usage {
  40         print <<EOT;
  41 git-send-email [options] <file | directory>...
  42 Options:
  43    --from         Specify the "From:" line of the email to be sent.
  44
  45    --to           Specify the primary "To:" line of the email.
  46
  47    --cc           Specify an initial "Cc:" list for the entire series
  48                   of emails.
  49
  50    --cc-cmd       Specify a command to execute per file which adds
  51                   per file specific cc address entries
  52
  53    --bcc          Specify a list of email addresses that should be Bcc:
  54                   on all the emails.
  55
  56    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  57                   an introductory message for the patch series.
  58
  59    --subject      Specify the initial "Subject:" line.
  60                   Only necessary if --compose is also set.  If --compose
  61                   is not set, this will be prompted for.
  62
  63    --in-reply-to  Specify the first "In-Reply-To:" header line.
  64                   Only used if --compose is also set.  If --compose is not
  65                   set, this will be prompted for.
  66
  67    --chain-reply-to If set, the replies will all be to the previous
  68                   email sent, rather than to the first email sent.
  69                   Defaults to on.
  70
  71    --signed-off-cc Automatically add email addresses that appear in
  72                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  73
  74    --identity     The configuration identity, a subsection to prioritise over
  75                   the default section.
  76
  77    --smtp-server  If set, specifies the outgoing SMTP server to use.
  78                   Defaults to localhost.  Port number can be specified here with
  79                   hostname:port format or by using --smtp-server-port option.
  80
  81    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  82
  83    --smtp-user    The username for SMTP-AUTH.
  84
  85    --smtp-pass    The password for SMTP-AUTH.
  86
  87    --smtp-ssl     If set, connects to the SMTP server using SSL.
  88
  89    --suppress-cc  Suppress the specified category of auto-CC.  The category
  90                   can be one of 'author' for the patch author, 'self' to
  91                   avoid copying yourself, 'sob' for Signed-off-by lines,
  92                   'cccmd' for the output of the cccmd, or 'all' to suppress
  93                   all of these.
  94
  95    --suppress-from Suppress sending emails to yourself. Defaults to off.
  96
  97    --thread       Specify that the "In-Reply-To:" header should be set on all
  98                   emails. Defaults to on.
  99
 100    --quiet        Make git-send-email less verbose.  One line per email
 101                   should be all that is output.
 102
 103    --dry-run      Do everything except actually send the emails.
 104
 105    --envelope-sender    Specify the envelope sender used to send the emails.
 106
 107    --no-validate        Don't perform any sanity checks on patches.
 108
 109 EOT
 110         exit(1);
 111 }
 112
 113 # most mail servers generate the Date: header, but not all...
 114 sub format_2822_time {
 115         my ($time) = @_;
 116         my @localtm = localtime($time);
 117         my @gmttm = gmtime($time);
 118         my $localmin = $localtm[1] + $localtm[2] * 60;
 119         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 120         if ($localtm[0] != $gmttm[0]) {
 121                 die "local zone differs from GMT by a non-minute interval\n";
 122         }
 123         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 124                 $localmin += 1440;
 125         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 126                 $localmin -= 1440;
 127         } elsif ($gmttm[6] != $localtm[6]) {
 128                 die "local time offset greater than or equal to 24 hours\n";
 129         }
 130         my $offset = $localmin - $gmtmin;
 131         my $offhour = $offset / 60;
 132         my $offmin = abs($offset % 60);
 133         if (abs($offhour) >= 24) {
 134                 die ("local time offset greater than or equal to 24 hours\n");
 135         }
 136
 137         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 138                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 139                        $localtm[3],
 140                        qw(Jan Feb Mar Apr May Jun
 141                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 142                        $localtm[5]+1900,
 143                        $localtm[2],
 144                        $localtm[1],
 145                        $localtm[0],
 146                        ($offset >= 0) ? '+' : '-',
 147                        abs($offhour),
 148                        $offmin,
 149                        );
 150 }
 151
 152 my $have_email_valid = eval { require Email::Valid; 1 };
 153 my $smtp;
 154 my $auth;
 155
 156 sub unique_email_list(@);
 157 sub cleanup_compose_files();
 158
 159 # Constants (essentially)
 160 my $compose_filename = ".msg.$$";
 161
 162 # Variables we fill in automatically, or via prompting:
 163 my (@to,@cc,@initial_cc,@bcclist,@xh,
 164         $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
 165
 166 my $envelope_sender;
 167
 168 # Example reply to:
 169 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 170
 171 my $repo = eval { Git->repository() };
 172 my @repo = $repo ? ($repo) : ();
 173 my $term = eval {
 174         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 175                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 176                 : new Term::ReadLine 'git-send-email';
 177 };
 178 if ($@) {
 179         $term = new FakeTerm "$@: going non-interactive";
 180 }
 181
 182 # Behavior modification variables
 183 my ($quiet, $dry_run) = (0, 0);
 184
 185 # Variables with corresponding config settings
 186 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 187 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_ssl);
 188 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 189 my ($no_validate);
 190 my (@suppress_cc);
 191
 192 my %config_bool_settings = (
 193     "thread" => [\$thread, 1],
 194     "chainreplyto" => [\$chain_reply_to, 1],
 195     "suppressfrom" => [\$suppress_from, undef],
 196     "signedoffcc" => [\$signed_off_cc, undef],
 197     "smtpssl" => [\$smtp_ssl, 0],
 198 );
 199
 200 my %config_settings = (
 201     "smtpserver" => \$smtp_server,
 202     "smtpserverport" => \$smtp_server_port,
 203     "smtpuser" => \$smtp_authuser,
 204     "smtppass" => \$smtp_authpass,
 205     "to" => \@to,
 206     "cc" => \@initial_cc,
 207     "cccmd" => \$cc_cmd,
 208     "aliasfiletype" => \$aliasfiletype,
 209     "bcc" => \@bcclist,
 210     "aliasesfile" => \@alias_files,
 211     "suppresscc" => \@suppress_cc,
 212 );
 213
 214 # Handle Uncouth Termination
 215 sub signal_handler {
 216
 217         # Make text normal
 218         print color("reset"), "\n";
 219
 220         # SMTP password masked
 221         system "stty echo";
 222
 223         # tmp files from --compose
 224         if (-e $compose_filename) {
 225                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 226         }
 227         if (-e ($compose_filename . ".final")) {
 228                 print "'$compose_filename.final' contains the composed email.\n"
 229         }
 230
 231         exit;
 232 };
 233
 234 $SIG{TERM} = \&signal_handler;
 235 $SIG{INT}  = \&signal_handler;
 236
 237 # Begin by accumulating all the variables (defined above), that we will end up
 238 # needing, first, from the command line:
 239
 240 my $rc = GetOptions("sender|from=s" => \$sender,
 241                     "in-reply-to=s" => \$initial_reply_to,
 242                     "subject=s" => \$initial_subject,
 243                     "to=s" => \@to,
 244                     "cc=s" => \@initial_cc,
 245                     "bcc=s" => \@bcclist,
 246                     "chain-reply-to!" => \$chain_reply_to,
 247                     "smtp-server=s" => \$smtp_server,
 248                     "smtp-server-port=s" => \$smtp_server_port,
 249                     "smtp-user=s" => \$smtp_authuser,
 250                     "smtp-pass:s" => \$smtp_authpass,
 251                     "smtp-ssl!" => \$smtp_ssl,
 252                     "identity=s" => \$identity,
 253                     "compose" => \$compose,
 254                     "quiet" => \$quiet,
 255                     "cc-cmd=s" => \$cc_cmd,
 256                     "suppress-from!" => \$suppress_from,
 257                     "suppress-cc=s" => \@suppress_cc,
 258                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 259                     "dry-run" => \$dry_run,
 260                     "envelope-sender=s" => \$envelope_sender,
 261                     "thread!" => \$thread,
 262                     "no-validate" => \$no_validate,
 263          );
 264
 265 unless ($rc) {
 266     usage();
 267 }
 268
 269 # Now, let's fill any that aren't set in with defaults:
 270
 271 sub read_config {
 272         my ($prefix) = @_;
 273
 274         foreach my $setting (keys %config_bool_settings) {
 275                 my $target = $config_bool_settings{$setting}->[0];
 276                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 277         }
 278
 279         foreach my $setting (keys %config_settings) {
 280                 my $target = $config_settings{$setting};
 281                 if (ref($target) eq "ARRAY") {
 282                         unless (@$target) {
 283                                 my @values = Git::config(@repo, "$prefix.$setting");
 284                                 @$target = @values if (@values && defined $values[0]);
 285                         }
 286                 }
 287                 else {
 288                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 289                 }
 290         }
 291 }
 292
 293 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 294 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 295 read_config("sendemail.$identity") if (defined $identity);
 296 read_config("sendemail");
 297
 298 # fall back on builtin bool defaults
 299 foreach my $setting (values %config_bool_settings) {
 300         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 301 }
 302
 303 # Set CC suppressions
 304 my(%suppress_cc);
 305 if (@suppress_cc) {
 306         foreach my $entry (@suppress_cc) {
 307                 die "Unknown --suppress-cc field: '$entry'\n"
 308                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 309                 $suppress_cc{$entry} = 1;
 310         }
 311 }
 312
 313 if ($suppress_cc{'all'}) {
 314         foreach my $entry (qw (ccmd cc author self sob)) {
 315                 $suppress_cc{$entry} = 1;
 316         }
 317         delete $suppress_cc{'all'};
 318 }
 319
 320 # If explicit old-style ones are specified, they trump --suppress-cc.
 321 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 322 $suppress_cc{'sob'} = !$signed_off_cc if defined $signed_off_cc;
 323
 324 # Debugging, print out the suppressions.
 325 if (0) {
 326         print "suppressions:\n";
 327         foreach my $entry (keys %suppress_cc) {
 328                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 329         }
 330 }
 331
 332 my ($repoauthor, $repocommitter);
 333 ($repoauthor) = Git::ident_person(@repo, 'author');
 334 ($repocommitter) = Git::ident_person(@repo, 'committer');
 335
 336 # Verify the user input
 337
 338 foreach my $entry (@to) {
 339         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 340 }
 341
 342 foreach my $entry (@initial_cc) {
 343         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 344 }
 345
 346 foreach my $entry (@bcclist) {
 347         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 348 }
 349
 350 my %aliases;
 351 my %parse_alias = (
 352         # multiline formats can be supported in the future
 353         mutt => sub { my $fh = shift; while (<$fh>) {
 354                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 355                         my ($alias, $addr) = ($1, $2);
 356                         $addr =~ s/#.*$//; # mutt allows # comments
 357                          # commas delimit multiple addresses
 358                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 359                 }}},
 360         mailrc => sub { my $fh = shift; while (<$fh>) {
 361                 if (/^alias\s+(\S+)\s+(.*)$/) {
 362                         # spaces delimit multiple addresses
 363                         $aliases{$1} = [ split(/\s+/, $2) ];
 364                 }}},
 365         pine => sub { my $fh = shift; while (<$fh>) {
 366                 if (/^(\S+)\t.*\t(.*)$/) {
 367                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 368                 }}},
 369         gnus => sub { my $fh = shift; while (<$fh>) {
 370                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 371                         $aliases{$1} = [ $2 ];
 372                 }}}
 373 );
 374
 375 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 376         foreach my $file (@alias_files) {
 377                 open my $fh, '<', $file or die "opening $file: $!\n";
 378                 $parse_alias{$aliasfiletype}->($fh);
 379                 close $fh;
 380         }
 381 }
 382
 383 ($sender) = expand_aliases($sender) if defined $sender;
 384
 385 # Now that all the defaults are set, process the rest of the command line
 386 # arguments and collect up the files that need to be processed.
 387 for my $f (@ARGV) {
 388         if (-d $f) {
 389                 opendir(DH,$f)
 390                         or die "Failed to opendir $f: $!";
 391
 392                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 393                                 sort readdir(DH);
 394
 395         } elsif (-f $f) {
 396                 push @files, $f;
 397
 398         } else {
 399                 print STDERR "Skipping $f - not found.\n";
 400         }
 401 }
 402
 403 if (!$no_validate) {
 404         foreach my $f (@files) {
 405                 my $error = validate_patch($f);
 406                 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 407         }
 408 }
 409
 410 if (@files) {
 411         unless ($quiet) {
 412                 print $_,"\n" for (@files);
 413         }
 414 } else {
 415         print STDERR "\nNo patch files specified!\n\n";
 416         usage();
 417 }
 418
 419 my $prompting = 0;
 420 if (!defined $sender) {
 421         $sender = $repoauthor || $repocommitter || '';
 422
 423         while (1) {
 424                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 425                 last if defined $_;
 426                 print "\n";
 427         }
 428
 429         $sender = $_ if ($_);
 430         print "Emails will be sent from: ", $sender, "\n";
 431         $prompting++;
 432 }
 433
 434 if (!@to) {
 435
 436
 437         while (1) {
 438                 $_ = $term->readline("Who should the emails be sent to? ", "");
 439                 last if defined $_;
 440                 print "\n";
 441         }
 442
 443         my $to = $_;
 444         push @to, split /,/, $to;
 445         $prompting++;
 446 }
 447
 448 sub expand_aliases {
 449         my @cur = @_;
 450         my @last;
 451         do {
 452                 @last = @cur;
 453                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 454         } while (join(',',@cur) ne join(',',@last));
 455         return @cur;
 456 }
 457
 458 @to = expand_aliases(@to);
 459 @to = (map { sanitize_address($_) } @to);
 460 @initial_cc = expand_aliases(@initial_cc);
 461 @bcclist = expand_aliases(@bcclist);
 462
 463 if (!defined $initial_subject && $compose) {
 464         while (1) {
 465                 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
 466                 last if defined $_;
 467                 print "\n";
 468         }
 469
 470         $initial_subject = $_;
 471         $prompting++;
 472 }
 473
 474 if ($thread && !defined $initial_reply_to && $prompting) {
 475         while (1) {
 476                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 477                 last if defined $_;
 478                 print "\n";
 479         }
 480
 481         $initial_reply_to = $_;
 482 }
 483 if (defined $initial_reply_to) {
 484         $initial_reply_to =~ s/^\s*<?//;
 485         $initial_reply_to =~ s/>?\s*$//;
 486         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 487 }
 488
 489 if (!defined $smtp_server) {
 490         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 491                 if (-x $_) {
 492                         $smtp_server = $_;
 493                         last;
 494                 }
 495         }
 496         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 497 }
 498
 499 if ($compose) {
 500         # Note that this does not need to be secure, but we will make a small
 501         # effort to have it be unique
 502         open(C,">",$compose_filename)
 503                 or die "Failed to open for writing $compose_filename: $!";
 504         print C "From $sender # This line is ignored.\n";
 505         printf C "Subject: %s\n\n", $initial_subject;
 506         printf C <<EOT;
 507 GIT: Please enter your email below.
 508 GIT: Lines beginning in "GIT: " will be removed.
 509 GIT: Consider including an overall diffstat or table of contents
 510 GIT: for the patch you are writing.
 511
 512 EOT
 513         close(C);
 514
 515         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 516         system('sh', '-c', $editor.' "$@"', $editor, $compose_filename);
 517
 518         open(C2,">",$compose_filename . ".final")
 519                 or die "Failed to open $compose_filename.final : " . $!;
 520
 521         open(C,"<",$compose_filename)
 522                 or die "Failed to open $compose_filename : " . $!;
 523
 524         while(<C>) {
 525                 next if m/^GIT: /;
 526                 print C2 $_;
 527         }
 528         close(C);
 529         close(C2);
 530
 531         while (1) {
 532                 $_ = $term->readline("Send this email? (y|n) ");
 533                 last if defined $_;
 534                 print "\n";
 535         }
 536
 537         if (uc substr($_,0,1) ne 'Y') {
 538                 cleanup_compose_files();
 539                 exit(0);
 540         }
 541
 542         @files = ($compose_filename . ".final", @files);
 543 }
 544
 545 # Variables we set as part of the loop over files
 546 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 547
 548 sub extract_valid_address {
 549         my $address = shift;
 550         my $local_part_regexp = '[^<>"\s@]+';
 551         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 552
 553         # check for a local address:
 554         return $address if ($address =~ /^($local_part_regexp)$/);
 555
 556         $address =~ s/^\s*<(.*)>\s*$/$1/;
 557         if ($have_email_valid) {
 558                 return scalar Email::Valid->address($address);
 559         } else {
 560                 # less robust/correct than the monster regexp in Email::Valid,
 561                 # but still does a 99% job, and one less dependency
 562                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 563                 return $1;
 564         }
 565 }
 566
 567 # Usually don't need to change anything below here.
 568
 569 # we make a "fake" message id by taking the current number
 570 # of seconds since the beginning of Unix time and tacking on
 571 # a random number to the end, in case we are called quicker than
 572 # 1 second since the last time we were called.
 573
 574 # We'll setup a template for the message id, using the "from" address:
 575
 576 my ($message_id_stamp, $message_id_serial);
 577 sub make_message_id
 578 {
 579         my $uniq;
 580         if (!defined $message_id_stamp) {
 581                 $message_id_stamp = sprintf("%s-%s", time, $$);
 582                 $message_id_serial = 0;
 583         }
 584         $message_id_serial++;
 585         $uniq = "$message_id_stamp-$message_id_serial";
 586
 587         my $du_part;
 588         for ($sender, $repocommitter, $repoauthor) {
 589                 $du_part = extract_valid_address(sanitize_address($_));
 590                 last if (defined $du_part and $du_part ne '');
 591         }
 592         if (not defined $du_part or $du_part eq '') {
 593                 use Sys::Hostname qw();
 594                 $du_part = 'user@' . Sys::Hostname::hostname();
 595         }
 596         my $message_id_template = "<%s-git-send-email-%s>";
 597         $message_id = sprintf($message_id_template, $uniq, $du_part);
 598         #print "new message id = $message_id\n"; # Was useful for debugging
 599 }
 600
 601
 602
 603 $time = time - scalar $#files;
 604
 605 sub unquote_rfc2047 {
 606         local ($_) = @_;
 607         my $encoding;
 608         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 609                 $encoding = $1;
 610                 s/_/ /g;
 611                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 612         }
 613         return wantarray ? ($_, $encoding) : $_;
 614 }
 615
 616 # use the simplest quoting being able to handle the recipient
 617 sub sanitize_address
 618 {
 619         my ($recipient) = @_;
 620         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 621
 622         if (not $recipient_name) {
 623                 return "$recipient";
 624         }
 625
 626         # if recipient_name is already quoted, do nothing
 627         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 628                 return $recipient;
 629         }
 630
 631         # rfc2047 is needed if a non-ascii char is included
 632         if ($recipient_name =~ /[^[:ascii:]]/) {
 633                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 634                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 635         }
 636
 637         # double quotes are needed if specials or CTLs are included
 638         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 639                 $recipient_name =~ s/(["\\\r])/\\$1/;
 640                 $recipient_name = "\"$recipient_name\"";
 641         }
 642
 643         return "$recipient_name $recipient_addr";
 644
 645 }
 646
 647 sub send_message
 648 {
 649         my @recipients = unique_email_list(@to);
 650         @cc = (grep { my $cc = extract_valid_address($_);
 651                       not grep { $cc eq $_ } @recipients
 652                     }
 653                map { sanitize_address($_) }
 654                @cc);
 655         my $to = join (",\n\t", @recipients);
 656         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 657         @recipients = (map { extract_valid_address($_) } @recipients);
 658         my $date = format_2822_time($time++);
 659         my $gitversion = '@@GIT_VERSION@@';
 660         if ($gitversion =~ m/..GIT_VERSION../) {
 661             $gitversion = Git::version();
 662         }
 663
 664         my $cc = join(", ", unique_email_list(@cc));
 665         my $ccline = "";
 666         if ($cc ne '') {
 667                 $ccline = "\nCc: $cc";
 668         }
 669         my $sanitized_sender = sanitize_address($sender);
 670         make_message_id() unless defined($message_id);
 671
 672         my $header = "From: $sanitized_sender
 673 To: $to${ccline}
 674 Subject: $subject
 675 Date: $date
 676 Message-Id: $message_id
 677 X-Mailer: git-send-email $gitversion
 678 ";
 679         if ($thread && $reply_to) {
 680
 681                 $header .= "In-Reply-To: $reply_to\n";
 682                 $header .= "References: $references\n";
 683         }
 684         if (@xh) {
 685                 $header .= join("\n", @xh) . "\n";
 686         }
 687
 688         my @sendmail_parameters = ('-i', @recipients);
 689         my $raw_from = $sanitized_sender;
 690         $raw_from = $envelope_sender if (defined $envelope_sender);
 691         $raw_from = extract_valid_address($raw_from);
 692         unshift (@sendmail_parameters,
 693                         '-f', $raw_from) if(defined $envelope_sender);
 694
 695         if ($dry_run) {
 696                 # We don't want to send the email.
 697         } elsif ($smtp_server =~ m#^/#) {
 698                 my $pid = open my $sm, '|-';
 699                 defined $pid or die $!;
 700                 if (!$pid) {
 701                         exec($smtp_server, @sendmail_parameters) or die $!;
 702                 }
 703                 print $sm "$header\n$message";
 704                 close $sm or die $?;
 705         } else {
 706
 707                 if (!defined $smtp_server) {
 708                         die "The required SMTP server is not properly defined."
 709                 }
 710
 711                 if ($smtp_ssl) {
 712                         $smtp_server_port ||= 465; # ssmtp
 713                         require Net::SMTP::SSL;
 714                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 715                 }
 716                 else {
 717                         require Net::SMTP;
 718                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 719                                                  ? "$smtp_server:$smtp_server_port"
 720                                                  : $smtp_server);
 721                 }
 722
 723                 if (!$smtp) {
 724                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 725                 }
 726
 727                 if (defined $smtp_authuser) {
 728
 729                         if (!defined $smtp_authpass) {
 730
 731                                 system "stty -echo";
 732
 733                                 do {
 734                                         print "Password: ";
 735                                         $_ = <STDIN>;
 736                                         print "\n";
 737                                 } while (!defined $_);
 738
 739                                 chomp($smtp_authpass = $_);
 740
 741                                 system "stty echo";
 742                         }
 743
 744                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 745                 }
 746
 747                 $smtp->mail( $raw_from ) or die $smtp->message;
 748                 $smtp->to( @recipients ) or die $smtp->message;
 749                 $smtp->data or die $smtp->message;
 750                 $smtp->datasend("$header\n$message") or die $smtp->message;
 751                 $smtp->dataend() or die $smtp->message;
 752                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 753         }
 754         if ($quiet) {
 755                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 756         } else {
 757                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 758                 if ($smtp_server !~ m#^/#) {
 759                         print "Server: $smtp_server\n";
 760                         print "MAIL FROM:<$raw_from>\n";
 761                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 762                 } else {
 763                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 764                 }
 765                 print $header, "\n";
 766                 if ($smtp) {
 767                         print "Result: ", $smtp->code, ' ',
 768                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 769                 } else {
 770                         print "Result: OK\n";
 771                 }
 772         }
 773 }
 774
 775 $reply_to = $initial_reply_to;
 776 $references = $initial_reply_to || '';
 777 $subject = $initial_subject;
 778
 779 foreach my $t (@files) {
 780         open(F,"<",$t) or die "can't open file $t";
 781
 782         my $author = undef;
 783         my $author_encoding;
 784         my $has_content_type;
 785         my $body_encoding;
 786         @cc = @initial_cc;
 787         @xh = ();
 788         my $input_format = undef;
 789         my $header_done = 0;
 790         $message = "";
 791         while(<F>) {
 792                 if (!$header_done) {
 793                         if (/^From /) {
 794                                 $input_format = 'mbox';
 795                                 next;
 796                         }
 797                         chomp;
 798                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 799                                 $input_format = 'mbox';
 800                         }
 801
 802                         if (defined $input_format && $input_format eq 'mbox') {
 803                                 if (/^Subject:\s+(.*)$/) {
 804                                         $subject = $1;
 805
 806                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 807                                         if (unquote_rfc2047($2) eq $sender) {
 808                                                 next if ($suppress_cc{'self'});
 809                                         }
 810                                         elsif ($1 eq 'From') {
 811                                                 ($author, $author_encoding)
 812                                                   = unquote_rfc2047($2);
 813                                                 next if ($suppress_cc{'author'});
 814                                         } else {
 815                                                 next if ($suppress_cc{'cc'});
 816                                         }
 817                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 818                                                 $2, $_) unless $quiet;
 819                                         push @cc, $2;
 820                                 }
 821                                 elsif (/^Content-type:/i) {
 822                                         $has_content_type = 1;
 823                                         if (/charset="?[^ "]+/) {
 824                                                 $body_encoding = $1;
 825                                         }
 826                                         push @xh, $_;
 827                                 }
 828                                 elsif (/^Message-Id: (.*)/i) {
 829                                         $message_id = $1;
 830                                 }
 831                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 832                                         push @xh, $_;
 833                                 }
 834
 835                         } else {
 836                                 # In the traditional
 837                                 # "send lots of email" format,
 838                                 # line 1 = cc
 839                                 # line 2 = subject
 840                                 # So let's support that, too.
 841                                 $input_format = 'lots';
 842                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 843                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 844                                                 $_, $_) unless $quiet;
 845
 846                                         push @cc, $_;
 847
 848                                 } elsif (!defined $subject) {
 849                                         $subject = $_;
 850                                 }
 851                         }
 852
 853                         # A whitespace line will terminate the headers
 854                         if (m/^\s*$/) {
 855                                 $header_done = 1;
 856                         }
 857                 } else {
 858                         $message .=  $_;
 859                         if (/^(Signed-off-by|Cc): (.*)$/i) {
 860                                 next if ($suppress_cc{'sob'});
 861                                 chomp;
 862                                 my $c = $2;
 863                                 chomp $c;
 864                                 next if ($c eq $sender and $suppress_cc{'self'});
 865                                 push @cc, $c;
 866                                 printf("(sob) Adding cc: %s from line '%s'\n",
 867                                         $c, $_) unless $quiet;
 868                         }
 869                 }
 870         }
 871         close F;
 872
 873         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
 874                 open(F, "$cc_cmd $t |")
 875                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 876                 while(<F>) {
 877                         my $c = $_;
 878                         $c =~ s/^\s*//g;
 879                         $c =~ s/\n$//g;
 880                         next if ($c eq $sender and $suppress_from);
 881                         push @cc, $c;
 882                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 883                                 $c, $cc_cmd) unless $quiet;
 884                 }
 885                 close F
 886                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 887         }
 888
 889         if (defined $author) {
 890                 $message = "From: $author\n\n$message";
 891                 if (defined $author_encoding) {
 892                         if ($has_content_type) {
 893                                 if ($body_encoding eq $author_encoding) {
 894                                         # ok, we already have the right encoding
 895                                 }
 896                                 else {
 897                                         # uh oh, we should re-encode
 898                                 }
 899                         }
 900                         else {
 901                                 push @xh,
 902                                   'MIME-Version: 1.0',
 903                                   "Content-Type: text/plain; charset=$author_encoding",
 904                                   'Content-Transfer-Encoding: 8bit';
 905                         }
 906                 }
 907         }
 908
 909         send_message();
 910
 911         # set up for the next message
 912         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 913                 $reply_to = $message_id;
 914                 if (length $references > 0) {
 915                         $references .= "\n $message_id";
 916                 } else {
 917                         $references = "$message_id";
 918                 }
 919         }
 920         $message_id = undef;
 921 }
 922
 923 if ($compose) {
 924         cleanup_compose_files();
 925 }
 926
 927 sub cleanup_compose_files() {
 928         unlink($compose_filename, $compose_filename . ".final");
 929
 930 }
 931
 932 $smtp->quit if $smtp;
 933
 934 sub unique_email_list(@) {
 935         my %seen;
 936         my @emails;
 937
 938         foreach my $entry (@_) {
 939                 if (my $clean = extract_valid_address($entry)) {
 940                         $seen{$clean} ||= 0;
 941                         next if $seen{$clean}++;
 942                         push @emails, $entry;
 943                 } else {
 944                         print STDERR "W: unable to extract a valid address",
 945                                         " from: $entry\n";
 946                 }
 947         }
 948         return @emails;
 949 }
 950
 951 sub validate_patch {
 952         my $fn = shift;
 953         open(my $fh, '<', $fn)
 954                 or die "unable to open $fn: $!\n";
 955         while (my $line = <$fh>) {
 956                 if (length($line) > 998) {
 957                         return "$.: patch contains a line longer than 998 characters";
 958                 }
 959         }
 960         return undef;
 961 }