git.oblomov.eu Git - git/blob - compat/vcbuild/scripts/clink.pl

   1 #!/usr/bin/perl -w
   2 ######################################################################
   3 # Compiles or links files
   4 #
   5 # This is a wrapper to facilitate the compilation of Git with MSVC
   6 # using GNU Make as the build system. So, instead of manipulating the
   7 # Makefile into something nasty, just to support non-space arguments
   8 # etc, we use this wrapper to fix the command line options
   9 #
  10 # Copyright (C) 2009 Marius Storm-Olsen <mstormo@gmail.com>
  11 ######################################################################
  12 use strict;
  13 my @args = ();
  14 my @cflags = ();
  15 my @lflags = ();
  16 my $is_linking = 0;
  17 my $is_debug = 0;
  18 while (@ARGV) {
  19         my $arg = shift @ARGV;
  20         if ("$arg" eq "-DDEBUG") {
  21             # Some vcpkg-based libraries have different names for release
  22             # and debug versions.  This hack assumes that -DDEBUG comes
  23             # before any "-l*" flags.
  24             $is_debug = 1;
  25         }
  26         if ("$arg" =~ /^-I\/mingw(32|64)/) {
  27                 # eat
  28         } elsif ("$arg" =~ /^-[DIMGOZ]/) {
  29                 push(@cflags, $arg);
  30         } elsif ("$arg" eq "-o") {
  31                 my $file_out = shift @ARGV;
  32                 if ("$file_out" =~ /exe$/) {
  33                         $is_linking = 1;
  34                         # Create foo.exe and foo.pdb
  35                         push(@args, "-OUT:$file_out");
  36                 } else {
  37                         # Create foo.o and foo.o.pdb
  38                         push(@args, "-Fo$file_out");
  39                         push(@args, "-Fd$file_out.pdb");
  40                 }
  41         } elsif ("$arg" eq "-lz") {
  42             if ($is_debug) {
  43                 push(@args, "zlibd.lib");
  44             } else{
  45                 push(@args, "zlib.lib");
  46             }
  47         } elsif ("$arg" eq "-liconv") {
  48                 push(@args, "libiconv.lib");
  49         } elsif ("$arg" eq "-lcrypto") {
  50                 push(@args, "libcrypto.lib");
  51         } elsif ("$arg" eq "-lssl") {
  52                 push(@args, "libssl.lib");
  53         } elsif ("$arg" eq "-lcurl") {
  54                 my $lib = "";
  55                 # Newer vcpkg definitions call this libcurl_imp.lib; Do we
  56                 # need to use that instead?
  57                 foreach my $flag (@lflags) {
  58                         if ($flag =~ /^-LIBPATH:(.*)/) {
  59                                 foreach my $l ("libcurl_imp.lib", "libcurl.lib") {
  60                                         if (-f "$1/$l") {
  61                                                 $lib = $l;
  62                                                 last;
  63                                         }
  64                                 }
  65                         }
  66                 }
  67                 push(@args, $lib);
  68         } elsif ("$arg" eq "-lexpat") {
  69                 push(@args, "expat.lib");
  70         } elsif ("$arg" =~ /^-L/ && "$arg" ne "-LTCG") {
  71                 $arg =~ s/^-L/-LIBPATH:/;
  72                 push(@lflags, $arg);
  73         } elsif ("$arg" =~ /^-[Rl]/) {
  74                 # eat
  75         } elsif ("$arg" eq "-Werror") {
  76                 push(@cflags, "-WX");
  77         } elsif ("$arg" eq "-Wall") {
  78                 # cl.exe understands -Wall, but it is really overzealous
  79                 push(@cflags, "-W4");
  80                 # disable the "signed/unsigned mismatch" warnings; our source code violates that
  81                 push(@cflags, "-wd4018");
  82                 push(@cflags, "-wd4245");
  83                 push(@cflags, "-wd4389");
  84                 # disable the "unreferenced formal parameter" warning; our source code violates that
  85                 push(@cflags, "-wd4100");
  86                 # disable the "conditional expression is constant" warning; our source code violates that
  87                 push(@cflags, "-wd4127");
  88                 # disable the "const object should be initialized" warning; these warnings affect only objects that are `static`
  89                 push(@cflags, "-wd4132");
  90                 # disable the "function/data pointer conversion in expression" warning; our source code violates that
  91                 push(@cflags, "-wd4152");
  92                 # disable the "non-constant aggregate initializer" warning; our source code violates that
  93                 push(@cflags, "-wd4204");
  94                 # disable the "cannot be initialized using address of automatic variable" warning; our source code violates that
  95                 push(@cflags, "-wd4221");
  96                 # disable the "possible loss of data" warnings; our source code violates that
  97                 push(@cflags, "-wd4244");
  98                 push(@cflags, "-wd4267");
  99                 # disable the "array is too small to include a terminating null character" warning; we ab-use strings to initialize OIDs
 100                 push(@cflags, "-wd4295");
 101                 # disable the "'<<': result of 32-bit shift implicitly converted to 64 bits" warning; our source code violates that
 102                 push(@cflags, "-wd4334");
 103                 # disable the "declaration hides previous local declaration" warning; our source code violates that
 104                 push(@cflags, "-wd4456");
 105                 # disable the "declaration hides function parameter" warning; our source code violates that
 106                 push(@cflags, "-wd4457");
 107                 # disable the "declaration hides global declaration" warning; our source code violates that
 108                 push(@cflags, "-wd4459");
 109                 # disable the "potentially uninitialized local variable '<name>' used" warning; our source code violates that
 110                 push(@cflags, "-wd4701");
 111                 # disable the "unreachable code" warning; our source code violates that
 112                 push(@cflags, "-wd4702");
 113                 # disable the "potentially uninitialized local pointer variable used" warning; our source code violates that
 114                 push(@cflags, "-wd4703");
 115                 # disable the "assignment within conditional expression" warning; our source code violates that
 116                 push(@cflags, "-wd4706");
 117                 # disable the "'inet_ntoa': Use inet_ntop() or InetNtop() instead" warning; our source code violates that
 118                 push(@cflags, "-wd4996");
 119         } elsif ("$arg" =~ /^-W[a-z]/) {
 120                 # let's ignore those
 121         } else {
 122                 push(@args, $arg);
 123         }
 124 }
 125 if ($is_linking) {
 126         push(@args, @lflags);
 127         unshift(@args, "link.exe");
 128 } else {
 129         unshift(@args, "cl.exe");
 130         push(@args, @cflags);
 131 }
 132 printf(STDERR "**** @args\n\n\n") if (!defined($ENV{'QUIET_GEN'}));
 133 exit (system(@args) != 0);