git.oblomov.eu Git - git/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  27 # --without-PROGRAM version used.
  28 AC_DEFUN([GIT_ARG_SET_PATH],
  29 [AC_ARG_WITH([$1],
  30  [AS_HELP_STRING([--with-$1=PATH],
  31                  [provide PATH to $1])],
  32  [GIT_CONF_APPEND_PATH($1,$2)],[])
  33 ])# GIT_ARG_SET_PATH
  34 #
  35 # GIT_CONF_APPEND_PATH(PROGRAM)
  36 # ------------------------------
  37 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  38 # Used by GIT_ARG_SET_PATH(PROGRAM)
  39 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  40 # --without-PROGRAM is used.
  41 AC_DEFUN([GIT_CONF_APPEND_PATH],
  42 [PROGRAM=m4_toupper($1); \
  43 if test "$withval" = "no"; then \
  44         if test -n "$2"; then \
  45                 m4_toupper($1)_PATH=$withval; \
  46                 AC_MSG_NOTICE([Disabling use of ${PROGRAM}]); \
  47                 GIT_CONF_APPEND_LINE(NO_${PROGRAM}=YesPlease); \
  48                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=); \
  49         else \
  50                 AC_MSG_ERROR([You cannot use git without $1]); \
  51         fi; \
  52 else \
  53         if test "$withval" = "yes"; then \
  54                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  55         else \
  56                 m4_toupper($1)_PATH=$withval; \
  57                 AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  58                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  59         fi; \
  60 fi; \
  61 ]) # GIT_CONF_APPEND_PATH
  62 #
  63 # GIT_PARSE_WITH(PACKAGE)
  64 # -----------------------
  65 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  66 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  67 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  68 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  69 AC_DEFUN([GIT_PARSE_WITH],
  70 [PACKAGE=m4_toupper($1); \
  71 if test "$withval" = "no"; then \
  72         m4_toupper(NO_$1)=YesPlease; \
  73 elif test "$withval" = "yes"; then \
  74         m4_toupper(NO_$1)=; \
  75 else \
  76         m4_toupper(NO_$1)=; \
  77         m4_toupper($1)DIR=$withval; \
  78         AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  79         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  80 fi \
  81 ])# GIT_PARSE_WITH
  82 #
  83 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  84 # ---------------------
  85 # Set VAR to the value specied by --with-WITHNAME.
  86 # No verification of arguments is performed, but warnings are issued
  87 # if either 'yes' or 'no' is specified.
  88 # HELP_TEXT is presented when --help is called.
  89 # This is a direct way to allow setting variables in the Makefile.
  90 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  91 [AC_ARG_WITH([$1],
  92  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  93  if test -n "$withval"; then \
  94   if test "$withval" = "yes" -o "$withval" = "no"; then \
  95     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  96                      [a value for $1 ($2).  Maybe you do...?]); \
  97   fi; \
  98   \
  99   AC_MSG_NOTICE([Setting $2 to $withval]); \
 100   GIT_CONF_APPEND_LINE($2=$withval); \
 101  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 102
 103 dnl
 104 dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 105 dnl -----------------------------------------
 106 dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
 107 dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
 108 dnl -Wall), it does not work.  By looking for function definition in
 109 dnl libraries, this problem can be worked around.
 110 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 111   AC_SEARCH_LIBS([$1],,
 112   [$2],[$3])
 113 ],[$3])])
 114
 115 dnl
 116 dnl GIT_STASH_FLAGS(BASEPATH_VAR)
 117 dnl -----------------------------
 118 dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 119 dnl tests that may want to take user settings into account.
 120 AC_DEFUN([GIT_STASH_FLAGS],[
 121 if test -n "$1"; then
 122    old_CPPFLAGS="$CPPFLAGS"
 123    old_LDFLAGS="$LDFLAGS"
 124    CPPFLAGS="-I$1/include $CPPFLAGS"
 125    LDFLAGS="-L$1/$lib $LDFLAGS"
 126 fi
 127 ])
 128
 129 dnl
 130 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 131 dnl -----------------------------
 132 dnl Restore the stashed *FLAGS values.
 133 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 134 if test -n "$1"; then
 135    CPPFLAGS="$old_CPPFLAGS"
 136    LDFLAGS="$old_LDFLAGS"
 137 fi
 138 ])
 139
 140 ## Site configuration related to programs (before tests)
 141 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 142 #
 143 # Set lib to alternative name of lib directory (e.g. lib64)
 144 AC_ARG_WITH([lib],
 145  [AS_HELP_STRING([--with-lib=ARG],
 146                  [ARG specifies alternative name for lib directory])],
 147  [if test "$withval" = "no" || test "$withval" = "yes"; then \
 148         AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 149 else \
 150         lib=$withval; \
 151         AC_MSG_NOTICE([Setting lib to '$lib']); \
 152         GIT_CONF_APPEND_LINE(lib=$withval); \
 153 fi; \
 154 ],[])
 155
 156 if test -z "$lib"; then
 157    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 158    lib=lib
 159 fi
 160
 161 AC_ARG_ENABLE([pthreads],
 162  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 163   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 164   [The default if FLAGS is not specified is to try first -pthread]
 165   [and then -lpthread.]
 166   [--without-pthreads will disable threading.])],
 167 [
 168 if test "x$enableval" = "xyes"; then
 169    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 170 elif test "x$enableval" != "xno"; then
 171    PTHREAD_CFLAGS=$enableval
 172    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 173 else
 174    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 175    NO_PTHREADS=YesPlease
 176    USER_NOPTHREAD=1
 177 fi],
 178 [
 179    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 180 ])
 181
 182 # Define option to enable JavaScript minification
 183 AC_ARG_ENABLE([jsmin],
 184 [AS_HELP_STRING([--enable-jsmin=PATH],
 185   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 186 [
 187   JSMIN=$enableval;
 188   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 189   GIT_CONF_APPEND_LINE(JSMIN=$enableval);
 190 ])
 191
 192 # Define option to enable CSS minification
 193 AC_ARG_ENABLE([cssmin],
 194 [AS_HELP_STRING([--enable-cssmin=PATH],
 195   [PATH is the name of a CSS minifier or the absolute path to one.])],
 196 [
 197   CSSMIN=$enableval;
 198   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 199   GIT_CONF_APPEND_LINE(CSSMIN=$enableval);
 200 ])
 201
 202 ## Site configuration (override autodetection)
 203 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 204 AC_MSG_NOTICE([CHECKS for site configuration])
 205 #
 206 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 207 # tests.  These tests take up a significant amount of the total test time
 208 # but are not needed unless you plan to talk to SVN repos.
 209 #
 210 # Define PPC_SHA1 environment variable when running make to make use of
 211 # a bundled SHA1 routine optimized for PowerPC.
 212 #
 213 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 214 # This also implies BLK_SHA1.
 215 #
 216 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 217 # /foo/bar/include and /foo/bar/lib directories.
 218 AC_ARG_WITH(openssl,
 219 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 220 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 221 GIT_PARSE_WITH(openssl))
 222 #
 223 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 224 # git-http-push are not built, and you cannot use http:// and https://
 225 # transports.
 226 #
 227 # Define CURLDIR=/foo/bar if your curl header and library files are in
 228 # /foo/bar/include and /foo/bar/lib directories.
 229 AC_ARG_WITH(curl,
 230 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 231 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 232 GIT_PARSE_WITH(curl))
 233 #
 234 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 235 # not built, and you cannot push using http:// and https:// transports.
 236 #
 237 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 238 # /foo/bar/include and /foo/bar/lib directories.
 239 AC_ARG_WITH(expat,
 240 AS_HELP_STRING([--with-expat],
 241 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 242 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 243 GIT_PARSE_WITH(expat))
 244 #
 245 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 246 # installed in /sw, but don't want GIT to link against any libraries
 247 # installed there.  If defined you may specify your own (or Fink's)
 248 # include directories and library directories by defining CFLAGS
 249 # and LDFLAGS appropriately.
 250 #
 251 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 252 # have DarwinPorts installed in /opt/local, but don't want GIT to
 253 # link against any libraries installed there.  If defined you may
 254 # specify your own (or DarwinPort's) include directories and
 255 # library directories by defining CFLAGS and LDFLAGS appropriately.
 256 #
 257 # Define NO_MMAP if you want to avoid mmap.
 258 #
 259 # Define NO_ICONV if your libc does not properly support iconv.
 260 AC_ARG_WITH(iconv,
 261 AS_HELP_STRING([--without-iconv],
 262 [if your architecture doesn't properly support iconv])
 263 AS_HELP_STRING([--with-iconv=PATH],
 264 [PATH is prefix for libiconv library and headers])
 265 AS_HELP_STRING([],
 266 [used only if you need linking with libiconv]),
 267 GIT_PARSE_WITH(iconv))
 268
 269 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 270 #
 271 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 272 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 273 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 274 # randomly break unless your underlying filesystem supports those sub-second
 275 # times (my ext3 doesn't).
 276 #
 277 # Define USE_STDEV below if you want git to care about the underlying device
 278 # change being considered an inode change from the update-index perspective.
 279
 280 #
 281 # Allow user to set ETC_GITCONFIG variable
 282 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 283                         Use VALUE instead of /etc/gitconfig as the
 284                         global git configuration file.
 285                         If VALUE is not fully qualified it will be interpretted
 286                         as a path relative to the computed prefix at runtime.)
 287
 288 #
 289 # Allow user to set the default pager
 290 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 291                         Use VALUE as the fall-back pager instead of 'less'.
 292                         This is used by things like 'git log' when the user
 293                         does not specify a pager to use through alternate
 294                         methods. eg: /usr/bin/pager)
 295 #
 296 # Allow user to set the default editor
 297 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 298                         Use VALUE as the fall-back editor instead of 'vi'.
 299                         This is used by things like 'git commit' when the user
 300                         does not specify a preferred editor through other
 301                         methods. eg: /usr/bin/editor)
 302
 303 #
 304 # Define SHELL_PATH to provide path to shell.
 305 GIT_ARG_SET_PATH(shell)
 306 #
 307 # Define PERL_PATH to provide path to Perl.
 308 GIT_ARG_SET_PATH(perl)
 309 #
 310 # Define PYTHON_PATH to provide path to Python.
 311 GIT_ARG_SET_PATH(python, allow-without)
 312 #
 313 # Define ZLIB_PATH to provide path to zlib.
 314 GIT_ARG_SET_PATH(zlib)
 315 #
 316 # Declare the with-tcltk/without-tcltk options.
 317 AC_ARG_WITH(tcltk,
 318 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 319 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 320 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 321 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 322 GIT_PARSE_WITH(tcltk))
 323 #
 324
 325
 326 ## Checks for programs.
 327 AC_MSG_NOTICE([CHECKS for programs])
 328 #
 329 AC_PROG_CC([cc gcc])
 330 # which switch to pass runtime path to dynamic libraries to the linker
 331 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 332    SAVE_LDFLAGS="${LDFLAGS}"
 333    LDFLAGS="${SAVE_LDFLAGS} -R /"
 334    AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 335    LDFLAGS="${SAVE_LDFLAGS}"
 336 ])
 337 if test "$git_cv_ld_dashr" = "yes"; then
 338    AC_SUBST(CC_LD_DYNPATH, [-R])
 339 else
 340    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 341       SAVE_LDFLAGS="${LDFLAGS}"
 342       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 343       AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 344       LDFLAGS="${SAVE_LDFLAGS}"
 345    ])
 346    if test "$git_cv_ld_wl_rpath" = "yes"; then
 347       AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 348    else
 349       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 350          SAVE_LDFLAGS="${LDFLAGS}"
 351          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 352          AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 353          LDFLAGS="${SAVE_LDFLAGS}"
 354       ])
 355       if test "$git_cv_ld_rpath" = "yes"; then
 356          AC_SUBST(CC_LD_DYNPATH, [-rpath])
 357       else
 358          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 359       fi
 360    fi
 361 fi
 362 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 363 AC_CHECK_TOOLS(AR, [gar ar], :)
 364 AC_CHECK_PROGS(TAR, [gtar tar])
 365 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 366 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 367 # or will be empty otherwise.
 368 if test -z "$NO_TCLTK"; then
 369   if test "$with_tcltk" = ""; then
 370   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 371     TCLTK_PATH=wish
 372     AC_SUBST(TCLTK_PATH)
 373   elif test "$with_tcltk" = "yes"; then
 374   # Tcl/Tk check requested.
 375     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 376   else
 377     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 378     TCLTK_PATH="$with_tcltk"
 379     AC_SUBST(TCLTK_PATH)
 380   fi
 381 fi
 382 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 383 if test -n "$ASCIIDOC"; then
 384         AC_MSG_CHECKING([for asciidoc version])
 385         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 386         case "${asciidoc_version}" in
 387         asciidoc' '8*)
 388                 ASCIIDOC8=YesPlease
 389                 AC_MSG_RESULT([${asciidoc_version} > 7])
 390                 ;;
 391         asciidoc' '7*)
 392                 ASCIIDOC8=
 393                 AC_MSG_RESULT([${asciidoc_version}])
 394                 ;;
 395         *)
 396                 ASCIIDOC8=
 397                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 398                 ;;
 399         esac
 400 fi
 401 AC_SUBST(ASCIIDOC8)
 402
 403
 404 ## Checks for libraries.
 405 AC_MSG_NOTICE([CHECKS for libraries])
 406 #
 407 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 408 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 409
 410 GIT_STASH_FLAGS($OPENSSLDIR)
 411
 412 AC_CHECK_LIB([crypto], [SHA1_Init],
 413 [NEEDS_SSL_WITH_CRYPTO=],
 414 [AC_CHECK_LIB([ssl], [SHA1_Init],
 415  [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 416  [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 417
 418 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 419
 420 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 421 AC_SUBST(NO_OPENSSL)
 422
 423 #
 424 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 425 # git-http-push are not built, and you cannot use http:// and https://
 426 # transports.
 427
 428 GIT_STASH_FLAGS($CURLDIR)
 429
 430 AC_CHECK_LIB([curl], [curl_global_init],
 431 [NO_CURL=],
 432 [NO_CURL=YesPlease])
 433
 434 GIT_UNSTASH_FLAGS($CURLDIR)
 435
 436 AC_SUBST(NO_CURL)
 437
 438 #
 439 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 440 # not built, and you cannot push using http:// and https:// transports.
 441
 442 GIT_STASH_FLAGS($EXPATDIR)
 443
 444 AC_CHECK_LIB([expat], [XML_ParserCreate],
 445 [NO_EXPAT=],
 446 [NO_EXPAT=YesPlease])
 447
 448 GIT_UNSTASH_FLAGS($EXPATDIR)
 449
 450 AC_SUBST(NO_EXPAT)
 451
 452 #
 453 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 454 # some Solaris installations).
 455 # Define NO_ICONV if neither libc nor libiconv support iconv.
 456
 457 if test -z "$NO_ICONV"; then
 458
 459 GIT_STASH_FLAGS($ICONVDIR)
 460
 461 AC_DEFUN([ICONVTEST_SRC], [
 462 #include <iconv.h>
 463
 464 int main(void)
 465 {
 466         iconv_open("", "");
 467         return 0;
 468 }
 469 ])
 470
 471 if test -n "$ICONVDIR"; then
 472    lib_order="-liconv -lc"
 473 else
 474    lib_order="-lc -liconv"
 475 fi
 476
 477 NO_ICONV=YesPlease
 478
 479 for l in $lib_order; do
 480     if test "$l" = "-liconv"; then
 481        NEEDS_LIBICONV=YesPlease
 482     else
 483        NEEDS_LIBICONV=
 484     fi
 485
 486     old_LIBS="$LIBS"
 487     LIBS="$LIBS $l"
 488     AC_MSG_CHECKING([for iconv in $l])
 489     AC_LINK_IFELSE(ICONVTEST_SRC,
 490         [AC_MSG_RESULT([yes])
 491         NO_ICONV=
 492         break],
 493         [AC_MSG_RESULT([no])])
 494     LIBS="$old_LIBS"
 495 done
 496
 497 #in case of break
 498 LIBS="$old_LIBS"
 499
 500 GIT_UNSTASH_FLAGS($ICONVDIR)
 501
 502 AC_SUBST(NEEDS_LIBICONV)
 503 AC_SUBST(NO_ICONV)
 504
 505 if test -n "$NO_ICONV"; then
 506     NEEDS_LIBICONV=
 507 fi
 508
 509 fi
 510
 511 #
 512 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 513
 514 GIT_STASH_FLAGS($ZLIB_PATH)
 515
 516 AC_DEFUN([ZLIBTEST_SRC], [
 517 #include <zlib.h>
 518
 519 int main(void)
 520 {
 521         deflateBound(0, 0);
 522         return 0;
 523 }
 524 ])
 525 AC_MSG_CHECKING([for deflateBound in -lz])
 526 old_LIBS="$LIBS"
 527 LIBS="$LIBS -lz"
 528 AC_LINK_IFELSE(ZLIBTEST_SRC,
 529         [AC_MSG_RESULT([yes])],
 530         [AC_MSG_RESULT([no])
 531         NO_DEFLATE_BOUND=yes])
 532 LIBS="$old_LIBS"
 533
 534 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 535
 536 AC_SUBST(NO_DEFLATE_BOUND)
 537
 538 #
 539 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 540 # Patrick Mauritz).
 541 AC_CHECK_LIB([c], [socket],
 542 [NEEDS_SOCKET=],
 543 [NEEDS_SOCKET=YesPlease])
 544 AC_SUBST(NEEDS_SOCKET)
 545 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 546
 547 #
 548 # The next few tests will define NEEDS_RESOLV if linking with
 549 # libresolv provides some of the functions we would normally get
 550 # from libc.
 551 NEEDS_RESOLV=
 552 AC_SUBST(NEEDS_RESOLV)
 553 #
 554 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 555 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 556 NO_INET_NTOP=
 557 AC_SUBST(NO_INET_NTOP)
 558 AC_CHECK_FUNC([inet_ntop],
 559         [],
 560     [AC_CHECK_LIB([resolv], [inet_ntop],
 561             [NEEDS_RESOLV=YesPlease],
 562         [NO_INET_NTOP=YesPlease])
 563 ])
 564 #
 565 # Define NO_INET_PTON if linking with -lresolv is not enough.
 566 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 567 NO_INET_PTON=
 568 AC_SUBST(NO_INET_PTON)
 569 AC_CHECK_FUNC([inet_pton],
 570         [],
 571     [AC_CHECK_LIB([resolv], [inet_pton],
 572             [NEEDS_RESOLV=YesPlease],
 573         [NO_INET_PTON=YesPlease])
 574 ])
 575 #
 576 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 577 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 578 NO_HSTRERROR=
 579 AC_CHECK_FUNC([hstrerror],
 580         [],
 581     [AC_CHECK_LIB([resolv], [hstrerror],
 582             [NEEDS_RESOLV=YesPlease],
 583         [NO_HSTRERROR=YesPlease])
 584 ])
 585 AC_SUBST(NO_HSTRERROR)
 586 #
 587 # If any of the above tests determined that -lresolv is needed at
 588 # build-time, also set it here for remaining configure-time checks.
 589 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 590
 591 AC_CHECK_LIB([c], [basename],
 592 [NEEDS_LIBGEN=],
 593 [NEEDS_LIBGEN=YesPlease])
 594 AC_SUBST(NEEDS_LIBGEN)
 595 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 596
 597 ## Checks for header files.
 598 AC_MSG_NOTICE([CHECKS for header files])
 599 #
 600 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 601 AC_CHECK_HEADER([sys/select.h],
 602 [NO_SYS_SELECT_H=],
 603 [NO_SYS_SELECT_H=UnfortunatelyYes])
 604 AC_SUBST(NO_SYS_SELECT_H)
 605 #
 606 # Define OLD_ICONV if your library has an old iconv(), where the second
 607 # (input buffer pointer) parameter is declared with type (const char **).
 608 AC_DEFUN([OLDICONVTEST_SRC], [[
 609 #include <iconv.h>
 610
 611 extern size_t iconv(iconv_t cd,
 612                     char **inbuf, size_t *inbytesleft,
 613                     char **outbuf, size_t *outbytesleft);
 614
 615 int main(void)
 616 {
 617         return 0;
 618 }
 619 ]])
 620
 621 GIT_STASH_FLAGS($ICONVDIR)
 622
 623 AC_MSG_CHECKING([for old iconv()])
 624 AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 625         [AC_MSG_RESULT([no])],
 626         [AC_MSG_RESULT([yes])
 627         OLD_ICONV=UnfortunatelyYes])
 628
 629 GIT_UNSTASH_FLAGS($ICONVDIR)
 630
 631 AC_SUBST(OLD_ICONV)
 632
 633 ## Checks for typedefs, structures, and compiler characteristics.
 634 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 635 #
 636 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 637 AC_CHECK_MEMBER(struct dirent.d_ino,
 638 [NO_D_INO_IN_DIRENT=],
 639 [NO_D_INO_IN_DIRENT=YesPlease],
 640 [#include <dirent.h>])
 641 AC_SUBST(NO_D_INO_IN_DIRENT)
 642 #
 643 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 644 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 645 AC_CHECK_MEMBER(struct dirent.d_type,
 646 [NO_D_TYPE_IN_DIRENT=],
 647 [NO_D_TYPE_IN_DIRENT=YesPlease],
 648 [#include <dirent.h>])
 649 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 650 #
 651 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 652 # sockaddr_storage.
 653 AC_CHECK_TYPE(struct sockaddr_storage,
 654 [NO_SOCKADDR_STORAGE=],
 655 [NO_SOCKADDR_STORAGE=YesPlease],[
 656 #include <sys/types.h>
 657 #include <sys/socket.h>
 658 ])
 659 AC_SUBST(NO_SOCKADDR_STORAGE)
 660 #
 661 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 662 AC_CHECK_TYPE([struct addrinfo],[
 663  GIT_CHECK_FUNC([getaddrinfo],
 664   [NO_IPV6=],
 665   [NO_IPV6=YesPlease])
 666 ],[NO_IPV6=YesPlease],[
 667 #include <sys/types.h>
 668 #include <sys/socket.h>
 669 #include <netdb.h>
 670 ])
 671 AC_SUBST(NO_IPV6)
 672 #
 673 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 674 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 675 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 676 # some C compilers supported these specifiers prior to C99 as an extension.
 677 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 678  [ac_cv_c_c99_format],
 679 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 680 AC_RUN_IFELSE(
 681         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 682                 [[char buf[64];
 683                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 684                   return 1;
 685                 else if (strcmp(buf, "12345"))
 686                   return 2;]])],
 687         [ac_cv_c_c99_format=yes],
 688         [ac_cv_c_c99_format=no])
 689 ])
 690 if test $ac_cv_c_c99_format = no; then
 691         NO_C99_FORMAT=YesPlease
 692 else
 693         NO_C99_FORMAT=
 694 fi
 695 AC_SUBST(NO_C99_FORMAT)
 696 #
 697 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 698 # when attempting to read from an fopen'ed directory.
 699 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 700  [ac_cv_fread_reads_directories],
 701 [
 702 AC_RUN_IFELSE(
 703         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 704                 [[char c;
 705                 FILE *f = fopen(".", "r");
 706                 return f && fread(&c, 1, 1, f)]])],
 707         [ac_cv_fread_reads_directories=no],
 708         [ac_cv_fread_reads_directories=yes])
 709 ])
 710 if test $ac_cv_fread_reads_directories = yes; then
 711         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 712 else
 713         FREAD_READS_DIRECTORIES=
 714 fi
 715 AC_SUBST(FREAD_READS_DIRECTORIES)
 716 #
 717 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 718 # or vsnprintf() return -1 instead of number of characters which would
 719 # have been written to the final string if enough space had been available.
 720 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 721  [ac_cv_snprintf_returns_bogus],
 722 [
 723 AC_RUN_IFELSE(
 724         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 725                 #include "stdarg.h"
 726
 727                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 728                 {
 729                   int ret;
 730                   va_list ap;
 731                   va_start(ap, format);
 732                   ret = vsnprintf(str, maxsize, format, ap);
 733                   va_end(ap);
 734                   return ret;
 735                 }],
 736                 [[char buf[6];
 737                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 738                       || strcmp(buf, "12")) return 1;
 739                   if (snprintf(buf, 3, "%s", "12345") != 5
 740                       || strcmp(buf, "12")) return 1]])],
 741         [ac_cv_snprintf_returns_bogus=no],
 742         [ac_cv_snprintf_returns_bogus=yes])
 743 ])
 744 if test $ac_cv_snprintf_returns_bogus = yes; then
 745         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 746 else
 747         SNPRINTF_RETURNS_BOGUS=
 748 fi
 749 AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 750
 751
 752 ## Checks for library functions.
 753 ## (in default C library and libraries checked by AC_CHECK_LIB)
 754 AC_MSG_NOTICE([CHECKS for library functions])
 755 #
 756 # Define NO_LIBGEN_H if you don't have libgen.h.
 757 AC_CHECK_HEADER([libgen.h],
 758 [NO_LIBGEN_H=],
 759 [NO_LIBGEN_H=YesPlease])
 760 AC_SUBST(NO_LIBGEN_H)
 761 #
 762 # Define NO_STRCASESTR if you don't have strcasestr.
 763 GIT_CHECK_FUNC(strcasestr,
 764 [NO_STRCASESTR=],
 765 [NO_STRCASESTR=YesPlease])
 766 AC_SUBST(NO_STRCASESTR)
 767 #
 768 # Define NO_MEMMEM if you don't have memmem.
 769 GIT_CHECK_FUNC(memmem,
 770 [NO_MEMMEM=],
 771 [NO_MEMMEM=YesPlease])
 772 AC_SUBST(NO_MEMMEM)
 773 #
 774 # Define NO_STRLCPY if you don't have strlcpy.
 775 GIT_CHECK_FUNC(strlcpy,
 776 [NO_STRLCPY=],
 777 [NO_STRLCPY=YesPlease])
 778 AC_SUBST(NO_STRLCPY)
 779 #
 780 # Define NO_UINTMAX_T if your platform does not have uintmax_t
 781 AC_CHECK_TYPE(uintmax_t,
 782 [NO_UINTMAX_T=],
 783 [NO_UINTMAX_T=YesPlease],[
 784 #include <inttypes.h>
 785 ])
 786 AC_SUBST(NO_UINTMAX_T)
 787 #
 788 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 789 GIT_CHECK_FUNC(strtoumax,
 790 [NO_STRTOUMAX=],
 791 [NO_STRTOUMAX=YesPlease])
 792 AC_SUBST(NO_STRTOUMAX)
 793 #
 794 # Define NO_SETENV if you don't have setenv in the C library.
 795 GIT_CHECK_FUNC(setenv,
 796 [NO_SETENV=],
 797 [NO_SETENV=YesPlease])
 798 AC_SUBST(NO_SETENV)
 799 #
 800 # Define NO_UNSETENV if you don't have unsetenv in the C library.
 801 GIT_CHECK_FUNC(unsetenv,
 802 [NO_UNSETENV=],
 803 [NO_UNSETENV=YesPlease])
 804 AC_SUBST(NO_UNSETENV)
 805 #
 806 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 807 GIT_CHECK_FUNC(mkdtemp,
 808 [NO_MKDTEMP=],
 809 [NO_MKDTEMP=YesPlease])
 810 AC_SUBST(NO_MKDTEMP)
 811 #
 812 # Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 813 GIT_CHECK_FUNC(mkstemps,
 814 [NO_MKSTEMPS=],
 815 [NO_MKSTEMPS=YesPlease])
 816 AC_SUBST(NO_MKSTEMPS)
 817 #
 818 #
 819 # Define NO_MMAP if you want to avoid mmap.
 820 #
 821 # Define NO_ICONV if your libc does not properly support iconv.
 822
 823
 824 ## Other checks.
 825 # Define USE_PIC if you need the main git objects to be built with -fPIC
 826 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 827 #
 828 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 829 # Enable it on Windows.  By default, symrefs are still used.
 830 #
 831 # Define NO_PTHREADS if we do not have pthreads.
 832 #
 833 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
 834 AC_DEFUN([PTHREADTEST_SRC], [
 835 #include <pthread.h>
 836
 837 int main(void)
 838 {
 839         pthread_mutex_t test_mutex;
 840         int retcode = 0;
 841         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
 842         retcode |= pthread_mutex_lock(&test_mutex);
 843         retcode |= pthread_mutex_unlock(&test_mutex);
 844         return retcode;
 845 }
 846 ])
 847
 848 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 849 dnl   [[#include <pthread.h>]],
 850 dnl   [[pthread_mutex_t test_mutex;]]
 851 dnl )])
 852
 853 NO_PTHREADS=UnfortunatelyYes
 854 PTHREAD_LIBS=
 855
 856 if test -n "$USER_NOPTHREAD"; then
 857    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 858 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 859 # -D_REENTRANT' or some such.
 860 elif test -z "$PTHREAD_CFLAGS"; then
 861   threads_found=no
 862   for opt in -mt -pthread -lpthread; do
 863      old_CFLAGS="$CFLAGS"
 864      CFLAGS="$opt $CFLAGS"
 865      AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 866      AC_LINK_IFELSE(PTHREADTEST_SRC,
 867         [AC_MSG_RESULT([yes])
 868                 NO_PTHREADS=
 869                 PTHREAD_LIBS="$opt"
 870                 PTHREAD_CFLAGS="$opt"
 871                 threads_found=yes
 872                 break
 873         ],
 874         [AC_MSG_RESULT([no])])
 875       CFLAGS="$old_CFLAGS"
 876   done
 877   if test $threads_found != yes; then
 878     AC_CHECK_LIB([pthread], [pthread_create],
 879         [PTHREAD_LIBS="-lpthread"],
 880         [NO_PTHREADS=UnfortunatelyYes])
 881   fi
 882 else
 883   old_CFLAGS="$CFLAGS"
 884   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 885   AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 886   AC_LINK_IFELSE(PTHREADTEST_SRC,
 887         [AC_MSG_RESULT([yes])
 888                 NO_PTHREADS=
 889                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
 890         ],
 891         [AC_MSG_RESULT([no])])
 892
 893   CFLAGS="$old_CFLAGS"
 894 fi
 895
 896 CFLAGS="$old_CFLAGS"
 897
 898 AC_SUBST(PTHREAD_CFLAGS)
 899 AC_SUBST(PTHREAD_LIBS)
 900 AC_SUBST(NO_PTHREADS)
 901
 902 ## Output files
 903 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 904 AC_OUTPUT
 905
 906
 907 ## Cleanup
 908 rm -f "${config_append}"