git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  58     --[no-]annotate                * Review each patch that will be sent in an editor.
  59     --compose                      * Open an editor for introduction.
  60     --compose-encoding      <str>  * Encoding to assume for introduction.
  61     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  62     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  63
  64   Sending:
  65     --envelope-sender       <str>  * Email envelope sender.
  66     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  67                                      is optional. Default 'localhost'.
  68     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  69     --smtp-server-port      <int>  * Outgoing SMTP server port.
  70     --smtp-user             <str>  * Username for SMTP-AUTH.
  71     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  72     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  73     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  74     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  75                                      Pass an empty string to disable certificate
  76                                      verification.
  77     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  78     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  79
  80   Automating:
  81     --identity              <str>  * Use the sendemail.<id> options.
  82     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  83     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  84     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  85     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  86     --[no-]to-cover                * Email To: addresses in the cover letter.
  87     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  88     --[no-]suppress-from           * Send to self. Default off.
  89     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  90     --[no-]thread                  * Use In-Reply-To: field. Default on.
  91
  92   Administering:
  93     --confirm               <str>  * Confirm recipients before sending;
  94                                      auto, cc, compose, always, or never.
  95     --quiet                        * Output one line of info per email.
  96     --dry-run                      * Don't actually send the emails.
  97     --[no-]validate                * Perform patch sanity checks. Default on.
  98     --[no-]format-patch            * understand any non optional arguments as
  99                                      `git format-patch` ones.
 100     --force                        * Send even if safety checks would prevent it.
 101
 102 EOT
 103         exit(1);
 104 }
 105
 106 # most mail servers generate the Date: header, but not all...
 107 sub format_2822_time {
 108         my ($time) = @_;
 109         my @localtm = localtime($time);
 110         my @gmttm = gmtime($time);
 111         my $localmin = $localtm[1] + $localtm[2] * 60;
 112         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 113         if ($localtm[0] != $gmttm[0]) {
 114                 die "local zone differs from GMT by a non-minute interval\n";
 115         }
 116         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 117                 $localmin += 1440;
 118         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 119                 $localmin -= 1440;
 120         } elsif ($gmttm[6] != $localtm[6]) {
 121                 die "local time offset greater than or equal to 24 hours\n";
 122         }
 123         my $offset = $localmin - $gmtmin;
 124         my $offhour = $offset / 60;
 125         my $offmin = abs($offset % 60);
 126         if (abs($offhour) >= 24) {
 127                 die ("local time offset greater than or equal to 24 hours\n");
 128         }
 129
 130         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 131                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 132                        $localtm[3],
 133                        qw(Jan Feb Mar Apr May Jun
 134                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 135                        $localtm[5]+1900,
 136                        $localtm[2],
 137                        $localtm[1],
 138                        $localtm[0],
 139                        ($offset >= 0) ? '+' : '-',
 140                        abs($offhour),
 141                        $offmin,
 142                        );
 143 }
 144
 145 my $have_email_valid = eval { require Email::Valid; 1 };
 146 my $have_mail_address = eval { require Mail::Address; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 # Regexes for RFC 2047 productions.
 151 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 152 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 153 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 154
 155 # Variables we fill in automatically, or via prompting:
 156 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 157         $initial_reply_to,$initial_subject,@files,
 158         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = eval { Git->repository() };
 166 my @repo = $repo ? ($repo) : ();
 167 my $term = eval {
 168         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 169                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 170                 : new Term::ReadLine 'git-send-email';
 171 };
 172 if ($@) {
 173         $term = new FakeTerm "$@: going non-interactive";
 174 }
 175
 176 # Behavior modification variables
 177 my ($quiet, $dry_run) = (0, 0);
 178 my $format_patch;
 179 my $compose_filename;
 180 my $force = 0;
 181
 182 # Handle interactive edition of files.
 183 my $multiedit;
 184 my $editor;
 185
 186 sub do_edit {
 187         if (!defined($editor)) {
 188                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 189         }
 190         if (defined($multiedit) && !$multiedit) {
 191                 map {
 192                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 193                         if (($? & 127) || ($? >> 8)) {
 194                                 die("the editor exited uncleanly, aborting everything");
 195                         }
 196                 } @_;
 197         } else {
 198                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 199                 if (($? & 127) || ($? >> 8)) {
 200                         die("the editor exited uncleanly, aborting everything");
 201                 }
 202         }
 203 }
 204
 205 # Variables with corresponding config settings
 206 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 207 my ($cover_cc, $cover_to);
 208 my ($to_cmd, $cc_cmd);
 209 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 210 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 211 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 212 my ($validate, $confirm);
 213 my (@suppress_cc);
 214 my ($auto_8bit_encoding);
 215 my ($compose_encoding);
 216 my ($target_xfer_encoding);
 217
 218 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 219
 220 my %config_bool_settings = (
 221     "thread" => [\$thread, 1],
 222     "chainreplyto" => [\$chain_reply_to, 0],
 223     "suppressfrom" => [\$suppress_from, undef],
 224     "signedoffbycc" => [\$signed_off_by_cc, undef],
 225     "cccover" => [\$cover_cc, undef],
 226     "tocover" => [\$cover_to, undef],
 227     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 228     "validate" => [\$validate, 1],
 229     "multiedit" => [\$multiedit, undef],
 230     "annotate" => [\$annotate, undef],
 231     "xmailer" => [\$use_xmailer, 1]
 232 );
 233
 234 my %config_settings = (
 235     "smtpserver" => \$smtp_server,
 236     "smtpserverport" => \$smtp_server_port,
 237     "smtpserveroption" => \@smtp_server_options,
 238     "smtpuser" => \$smtp_authuser,
 239     "smtppass" => \$smtp_authpass,
 240     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 241     "smtpdomain" => \$smtp_domain,
 242     "to" => \@initial_to,
 243     "tocmd" => \$to_cmd,
 244     "cc" => \@initial_cc,
 245     "cccmd" => \$cc_cmd,
 246     "aliasfiletype" => \$aliasfiletype,
 247     "bcc" => \@bcclist,
 248     "suppresscc" => \@suppress_cc,
 249     "envelopesender" => \$envelope_sender,
 250     "confirm"   => \$confirm,
 251     "from" => \$sender,
 252     "assume8bitencoding" => \$auto_8bit_encoding,
 253     "composeencoding" => \$compose_encoding,
 254     "transferencoding" => \$target_xfer_encoding,
 255 );
 256
 257 my %config_path_settings = (
 258     "aliasesfile" => \@alias_files,
 259 );
 260
 261 # Handle Uncouth Termination
 262 sub signal_handler {
 263
 264         # Make text normal
 265         print color("reset"), "\n";
 266
 267         # SMTP password masked
 268         system "stty echo";
 269
 270         # tmp files from --compose
 271         if (defined $compose_filename) {
 272                 if (-e $compose_filename) {
 273                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 274                 }
 275                 if (-e ($compose_filename . ".final")) {
 276                         print "'$compose_filename.final' contains the composed email.\n"
 277                 }
 278         }
 279
 280         exit;
 281 };
 282
 283 $SIG{TERM} = \&signal_handler;
 284 $SIG{INT}  = \&signal_handler;
 285
 286 # Begin by accumulating all the variables (defined above), that we will end up
 287 # needing, first, from the command line:
 288
 289 my $help;
 290 my $rc = GetOptions("h" => \$help,
 291                     "sender|from=s" => \$sender,
 292                     "in-reply-to=s" => \$initial_reply_to,
 293                     "subject=s" => \$initial_subject,
 294                     "to=s" => \@initial_to,
 295                     "to-cmd=s" => \$to_cmd,
 296                     "no-to" => \$no_to,
 297                     "cc=s" => \@initial_cc,
 298                     "no-cc" => \$no_cc,
 299                     "bcc=s" => \@bcclist,
 300                     "no-bcc" => \$no_bcc,
 301                     "chain-reply-to!" => \$chain_reply_to,
 302                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 303                     "smtp-server=s" => \$smtp_server,
 304                     "smtp-server-option=s" => \@smtp_server_options,
 305                     "smtp-server-port=s" => \$smtp_server_port,
 306                     "smtp-user=s" => \$smtp_authuser,
 307                     "smtp-pass:s" => \$smtp_authpass,
 308                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 309                     "smtp-encryption=s" => \$smtp_encryption,
 310                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 311                     "smtp-debug:i" => \$debug_net_smtp,
 312                     "smtp-domain:s" => \$smtp_domain,
 313                     "identity=s" => \$identity,
 314                     "annotate!" => \$annotate,
 315                     "no-annotate" => sub {$annotate = 0},
 316                     "compose" => \$compose,
 317                     "quiet" => \$quiet,
 318                     "cc-cmd=s" => \$cc_cmd,
 319                     "suppress-from!" => \$suppress_from,
 320                     "no-suppress-from" => sub {$suppress_from = 0},
 321                     "suppress-cc=s" => \@suppress_cc,
 322                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 323                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 324                     "cc-cover|cc-cover!" => \$cover_cc,
 325                     "no-cc-cover" => sub {$cover_cc = 0},
 326                     "to-cover|to-cover!" => \$cover_to,
 327                     "no-to-cover" => sub {$cover_to = 0},
 328                     "confirm=s" => \$confirm,
 329                     "dry-run" => \$dry_run,
 330                     "envelope-sender=s" => \$envelope_sender,
 331                     "thread!" => \$thread,
 332                     "no-thread" => sub {$thread = 0},
 333                     "validate!" => \$validate,
 334                     "no-validate" => sub {$validate = 0},
 335                     "transfer-encoding=s" => \$target_xfer_encoding,
 336                     "format-patch!" => \$format_patch,
 337                     "no-format-patch" => sub {$format_patch = 0},
 338                     "8bit-encoding=s" => \$auto_8bit_encoding,
 339                     "compose-encoding=s" => \$compose_encoding,
 340                     "force" => \$force,
 341                     "xmailer!" => \$use_xmailer,
 342                     "no-xmailer" => sub {$use_xmailer = 0},
 343          );
 344
 345 usage() if $help;
 346 unless ($rc) {
 347     usage();
 348 }
 349
 350 die "Cannot run git format-patch from outside a repository\n"
 351         if $format_patch and not $repo;
 352
 353 # Now, let's fill any that aren't set in with defaults:
 354
 355 sub read_config {
 356         my ($prefix) = @_;
 357
 358         foreach my $setting (keys %config_bool_settings) {
 359                 my $target = $config_bool_settings{$setting}->[0];
 360                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 361         }
 362
 363         foreach my $setting (keys %config_path_settings) {
 364                 my $target = $config_path_settings{$setting};
 365                 if (ref($target) eq "ARRAY") {
 366                         unless (@$target) {
 367                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 368                                 @$target = @values if (@values && defined $values[0]);
 369                         }
 370                 }
 371                 else {
 372                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 373                 }
 374         }
 375
 376         foreach my $setting (keys %config_settings) {
 377                 my $target = $config_settings{$setting};
 378                 next if $setting eq "to" and defined $no_to;
 379                 next if $setting eq "cc" and defined $no_cc;
 380                 next if $setting eq "bcc" and defined $no_bcc;
 381                 if (ref($target) eq "ARRAY") {
 382                         unless (@$target) {
 383                                 my @values = Git::config(@repo, "$prefix.$setting");
 384                                 @$target = @values if (@values && defined $values[0]);
 385                         }
 386                 }
 387                 else {
 388                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 389                 }
 390         }
 391
 392         if (!defined $smtp_encryption) {
 393                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 394                 if (defined $enc) {
 395                         $smtp_encryption = $enc;
 396                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 397                         $smtp_encryption = 'ssl';
 398                 }
 399         }
 400 }
 401
 402 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 403 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 404 read_config("sendemail.$identity") if (defined $identity);
 405 read_config("sendemail");
 406
 407 # fall back on builtin bool defaults
 408 foreach my $setting (values %config_bool_settings) {
 409         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 410 }
 411
 412 # 'default' encryption is none -- this only prevents a warning
 413 $smtp_encryption = '' unless (defined $smtp_encryption);
 414
 415 # Set CC suppressions
 416 my(%suppress_cc);
 417 if (@suppress_cc) {
 418         foreach my $entry (@suppress_cc) {
 419                 die "Unknown --suppress-cc field: '$entry'\n"
 420                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 421                 $suppress_cc{$entry} = 1;
 422         }
 423 }
 424
 425 if ($suppress_cc{'all'}) {
 426         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 427                 $suppress_cc{$entry} = 1;
 428         }
 429         delete $suppress_cc{'all'};
 430 }
 431
 432 # If explicit old-style ones are specified, they trump --suppress-cc.
 433 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 434 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 435
 436 if ($suppress_cc{'body'}) {
 437         foreach my $entry (qw (sob bodycc)) {
 438                 $suppress_cc{$entry} = 1;
 439         }
 440         delete $suppress_cc{'body'};
 441 }
 442
 443 # Set confirm's default value
 444 my $confirm_unconfigured = !defined $confirm;
 445 if ($confirm_unconfigured) {
 446         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 447 };
 448 die "Unknown --confirm setting: '$confirm'\n"
 449         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 450
 451 # Debugging, print out the suppressions.
 452 if (0) {
 453         print "suppressions:\n";
 454         foreach my $entry (keys %suppress_cc) {
 455                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 456         }
 457 }
 458
 459 my ($repoauthor, $repocommitter);
 460 ($repoauthor) = Git::ident_person(@repo, 'author');
 461 ($repocommitter) = Git::ident_person(@repo, 'committer');
 462
 463 sub parse_address_line {
 464         if ($have_mail_address) {
 465                 return map { $_->format } Mail::Address->parse($_[0]);
 466         } else {
 467                 return Git::parse_mailboxes($_[0]);
 468         }
 469 }
 470
 471 sub split_addrs {
 472         return quotewords('\s*,\s*', 1, @_);
 473 }
 474
 475 my %aliases;
 476
 477 sub parse_sendmail_alias {
 478         local $_ = shift;
 479         if (/"/) {
 480                 print STDERR "warning: sendmail alias with quotes is not supported: $_\n";
 481         } elsif (/:include:/) {
 482                 print STDERR "warning: `:include:` not supported: $_\n";
 483         } elsif (/[\/|]/) {
 484                 print STDERR "warning: `/file` or `|pipe` redirection not supported: $_\n";
 485         } elsif (/^(\S+?)\s*:\s*(.+)$/) {
 486                 my ($alias, $addr) = ($1, $2);
 487                 $aliases{$alias} = [ split_addrs($addr) ];
 488         } else {
 489                 print STDERR "warning: sendmail line is not recognized: $_\n";
 490         }
 491 }
 492
 493 sub parse_sendmail_aliases {
 494         my $fh = shift;
 495         my $s = '';
 496         while (<$fh>) {
 497                 chomp;
 498                 next if /^\s*$/ || /^\s*#/;
 499                 $s .= $_, next if $s =~ s/\\$// || s/^\s+//;
 500                 parse_sendmail_alias($s) if $s;
 501                 $s = $_;
 502         }
 503         $s =~ s/\\$//; # silently tolerate stray '\' on last line
 504         parse_sendmail_alias($s) if $s;
 505 }
 506
 507 my %parse_alias = (
 508         # multiline formats can be supported in the future
 509         mutt => sub { my $fh = shift; while (<$fh>) {
 510                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 511                         my ($alias, $addr) = ($1, $2);
 512                         $addr =~ s/#.*$//; # mutt allows # comments
 513                          # commas delimit multiple addresses
 514                         $aliases{$alias} = [ split_addrs($addr) ];
 515                 }}},
 516         mailrc => sub { my $fh = shift; while (<$fh>) {
 517                 if (/^alias\s+(\S+)\s+(.*)$/) {
 518                         # spaces delimit multiple addresses
 519                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 520                 }}},
 521         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 522                 for (my $x = ''; defined($x); $x = $_) {
 523                         chomp $x;
 524                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 525                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 526                         $aliases{$1} = [ split_addrs($2) ];
 527                 }},
 528         elm => sub  { my $fh = shift;
 529                       while (<$fh>) {
 530                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 531                               my ($alias, $addr) = ($1, $2);
 532                                $aliases{$alias} = [ split_addrs($addr) ];
 533                           }
 534                       } },
 535         sendmail => \&parse_sendmail_aliases,
 536         gnus => sub { my $fh = shift; while (<$fh>) {
 537                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 538                         $aliases{$1} = [ $2 ];
 539                 }}}
 540 );
 541
 542 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 543         foreach my $file (@alias_files) {
 544                 open my $fh, '<', $file or die "opening $file: $!\n";
 545                 $parse_alias{$aliasfiletype}->($fh);
 546                 close $fh;
 547         }
 548 }
 549
 550 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 551 # $f is a revision list specification to be passed to format-patch.
 552 sub is_format_patch_arg {
 553         return unless $repo;
 554         my $f = shift;
 555         try {
 556                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 557                 if (defined($format_patch)) {
 558                         return $format_patch;
 559                 }
 560                 die(<<EOF);
 561 File '$f' exists but it could also be the range of commits
 562 to produce patches for.  Please disambiguate by...
 563
 564     * Saying "./$f" if you mean a file; or
 565     * Giving --format-patch option if you mean a range.
 566 EOF
 567         } catch Git::Error::Command with {
 568                 # Not a valid revision.  Treat it as a filename.
 569                 return 0;
 570         }
 571 }
 572
 573 # Now that all the defaults are set, process the rest of the command line
 574 # arguments and collect up the files that need to be processed.
 575 my @rev_list_opts;
 576 while (defined(my $f = shift @ARGV)) {
 577         if ($f eq "--") {
 578                 push @rev_list_opts, "--", @ARGV;
 579                 @ARGV = ();
 580         } elsif (-d $f and !is_format_patch_arg($f)) {
 581                 opendir my $dh, $f
 582                         or die "Failed to opendir $f: $!";
 583
 584                 push @files, grep { -f $_ } map { catfile($f, $_) }
 585                                 sort readdir $dh;
 586                 closedir $dh;
 587         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 588                 push @files, $f;
 589         } else {
 590                 push @rev_list_opts, $f;
 591         }
 592 }
 593
 594 if (@rev_list_opts) {
 595         die "Cannot run git format-patch from outside a repository\n"
 596                 unless $repo;
 597         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 598 }
 599
 600 if ($validate) {
 601         foreach my $f (@files) {
 602                 unless (-p $f) {
 603                         my $error = validate_patch($f);
 604                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 605                 }
 606         }
 607 }
 608
 609 if (@files) {
 610         unless ($quiet) {
 611                 print $_,"\n" for (@files);
 612         }
 613 } else {
 614         print STDERR "\nNo patch files specified!\n\n";
 615         usage();
 616 }
 617
 618 sub get_patch_subject {
 619         my $fn = shift;
 620         open (my $fh, '<', $fn);
 621         while (my $line = <$fh>) {
 622                 next unless ($line =~ /^Subject: (.*)$/);
 623                 close $fh;
 624                 return "GIT: $1\n";
 625         }
 626         close $fh;
 627         die "No subject line in $fn ?";
 628 }
 629
 630 if ($compose) {
 631         # Note that this does not need to be secure, but we will make a small
 632         # effort to have it be unique
 633         $compose_filename = ($repo ?
 634                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 635                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 636         open my $c, ">", $compose_filename
 637                 or die "Failed to open for writing $compose_filename: $!";
 638
 639
 640         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 641         my $tpl_subject = $initial_subject || '';
 642         my $tpl_reply_to = $initial_reply_to || '';
 643
 644         print $c <<EOT;
 645 From $tpl_sender # This line is ignored.
 646 GIT: Lines beginning in "GIT:" will be removed.
 647 GIT: Consider including an overall diffstat or table of contents
 648 GIT: for the patch you are writing.
 649 GIT:
 650 GIT: Clear the body content if you don't wish to send a summary.
 651 From: $tpl_sender
 652 Subject: $tpl_subject
 653 In-Reply-To: $tpl_reply_to
 654
 655 EOT
 656         for my $f (@files) {
 657                 print $c get_patch_subject($f);
 658         }
 659         close $c;
 660
 661         if ($annotate) {
 662                 do_edit($compose_filename, @files);
 663         } else {
 664                 do_edit($compose_filename);
 665         }
 666
 667         open my $c2, ">", $compose_filename . ".final"
 668                 or die "Failed to open $compose_filename.final : " . $!;
 669
 670         open $c, "<", $compose_filename
 671                 or die "Failed to open $compose_filename : " . $!;
 672
 673         my $need_8bit_cte = file_has_nonascii($compose_filename);
 674         my $in_body = 0;
 675         my $summary_empty = 1;
 676         if (!defined $compose_encoding) {
 677                 $compose_encoding = "UTF-8";
 678         }
 679         while(<$c>) {
 680                 next if m/^GIT:/;
 681                 if ($in_body) {
 682                         $summary_empty = 0 unless (/^\n$/);
 683                 } elsif (/^\n$/) {
 684                         $in_body = 1;
 685                         if ($need_8bit_cte) {
 686                                 print $c2 "MIME-Version: 1.0\n",
 687                                          "Content-Type: text/plain; ",
 688                                            "charset=$compose_encoding\n",
 689                                          "Content-Transfer-Encoding: 8bit\n";
 690                         }
 691                 } elsif (/^MIME-Version:/i) {
 692                         $need_8bit_cte = 0;
 693                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 694                         $initial_subject = $1;
 695                         my $subject = $initial_subject;
 696                         $_ = "Subject: " .
 697                                 quote_subject($subject, $compose_encoding) .
 698                                 "\n";
 699                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 700                         $initial_reply_to = $1;
 701                         next;
 702                 } elsif (/^From:\s*(.+)\s*$/i) {
 703                         $sender = $1;
 704                         next;
 705                 } elsif (/^(?:To|Cc|Bcc):/i) {
 706                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 707                         next;
 708                 }
 709                 print $c2 $_;
 710         }
 711         close $c;
 712         close $c2;
 713
 714         if ($summary_empty) {
 715                 print "Summary email is empty, skipping it\n";
 716                 $compose = -1;
 717         }
 718 } elsif ($annotate) {
 719         do_edit(@files);
 720 }
 721
 722 sub ask {
 723         my ($prompt, %arg) = @_;
 724         my $valid_re = $arg{valid_re};
 725         my $default = $arg{default};
 726         my $confirm_only = $arg{confirm_only};
 727         my $resp;
 728         my $i = 0;
 729         return defined $default ? $default : undef
 730                 unless defined $term->IN and defined fileno($term->IN) and
 731                        defined $term->OUT and defined fileno($term->OUT);
 732         while ($i++ < 10) {
 733                 $resp = $term->readline($prompt);
 734                 if (!defined $resp) { # EOF
 735                         print "\n";
 736                         return defined $default ? $default : undef;
 737                 }
 738                 if ($resp eq '' and defined $default) {
 739                         return $default;
 740                 }
 741                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 742                         return $resp;
 743                 }
 744                 if ($confirm_only) {
 745                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 746                         if (defined $yesno && $yesno =~ /y/i) {
 747                                 return $resp;
 748                         }
 749                 }
 750         }
 751         return;
 752 }
 753
 754 my %broken_encoding;
 755
 756 sub file_declares_8bit_cte {
 757         my $fn = shift;
 758         open (my $fh, '<', $fn);
 759         while (my $line = <$fh>) {
 760                 last if ($line =~ /^$/);
 761                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 762         }
 763         close $fh;
 764         return 0;
 765 }
 766
 767 foreach my $f (@files) {
 768         next unless (body_or_subject_has_nonascii($f)
 769                      && !file_declares_8bit_cte($f));
 770         $broken_encoding{$f} = 1;
 771 }
 772
 773 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 774         print "The following files are 8bit, but do not declare " .
 775                 "a Content-Transfer-Encoding.\n";
 776         foreach my $f (sort keys %broken_encoding) {
 777                 print "    $f\n";
 778         }
 779         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 780                                   valid_re => qr/.{4}/, confirm_only => 1,
 781                                   default => "UTF-8");
 782 }
 783
 784 if (!$force) {
 785         for my $f (@files) {
 786                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 787                         die "Refusing to send because the patch\n\t$f\n"
 788                                 . "has the template subject '*** SUBJECT HERE ***'. "
 789                                 . "Pass --force if you really want to send.\n";
 790                 }
 791         }
 792 }
 793
 794 if (defined $sender) {
 795         $sender =~ s/^\s+|\s+$//g;
 796         ($sender) = expand_aliases($sender);
 797 } else {
 798         $sender = $repoauthor || $repocommitter || '';
 799 }
 800
 801 # $sender could be an already sanitized address
 802 # (e.g. sendemail.from could be manually sanitized by user).
 803 # But it's a no-op to run sanitize_address on an already sanitized address.
 804 $sender = sanitize_address($sender);
 805
 806 my $prompting = 0;
 807 if (!@initial_to && !defined $to_cmd) {
 808         my $to = ask("Who should the emails be sent to (if any)? ",
 809                      default => "",
 810                      valid_re => qr/\@.*\./, confirm_only => 1);
 811         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 812         $prompting++;
 813 }
 814
 815 sub expand_aliases {
 816         return map { expand_one_alias($_) } @_;
 817 }
 818
 819 my %EXPANDED_ALIASES;
 820 sub expand_one_alias {
 821         my $alias = shift;
 822         if ($EXPANDED_ALIASES{$alias}) {
 823                 die "fatal: alias '$alias' expands to itself\n";
 824         }
 825         local $EXPANDED_ALIASES{$alias} = 1;
 826         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 827 }
 828
 829 @initial_to = process_address_list(@initial_to);
 830 @initial_cc = process_address_list(@initial_cc);
 831 @bcclist = process_address_list(@bcclist);
 832
 833 if ($thread && !defined $initial_reply_to && $prompting) {
 834         $initial_reply_to = ask(
 835                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 836                 default => "",
 837                 valid_re => qr/\@.*\./, confirm_only => 1);
 838 }
 839 if (defined $initial_reply_to) {
 840         $initial_reply_to =~ s/^\s*<?//;
 841         $initial_reply_to =~ s/>?\s*$//;
 842         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 843 }
 844
 845 if (!defined $smtp_server) {
 846         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 847                 if (-x $_) {
 848                         $smtp_server = $_;
 849                         last;
 850                 }
 851         }
 852         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 853 }
 854
 855 if ($compose && $compose > 0) {
 856         @files = ($compose_filename . ".final", @files);
 857 }
 858
 859 # Variables we set as part of the loop over files
 860 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 861         $needs_confirm, $message_num, $ask_default);
 862
 863 sub extract_valid_address {
 864         my $address = shift;
 865         my $local_part_regexp = qr/[^<>"\s@]+/;
 866         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 867
 868         # check for a local address:
 869         return $address if ($address =~ /^($local_part_regexp)$/);
 870
 871         $address =~ s/^\s*<(.*)>\s*$/$1/;
 872         if ($have_email_valid) {
 873                 return scalar Email::Valid->address($address);
 874         }
 875
 876         # less robust/correct than the monster regexp in Email::Valid,
 877         # but still does a 99% job, and one less dependency
 878         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 879         return;
 880 }
 881
 882 sub extract_valid_address_or_die {
 883         my $address = shift;
 884         $address = extract_valid_address($address);
 885         die "error: unable to extract a valid address from: $address\n"
 886                 if !$address;
 887         return $address;
 888 }
 889
 890 sub validate_address {
 891         my $address = shift;
 892         while (!extract_valid_address($address)) {
 893                 print STDERR "error: unable to extract a valid address from: $address\n";
 894                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 895                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 896                         default => 'q');
 897                 if (/^d/i) {
 898                         return undef;
 899                 } elsif (/^q/i) {
 900                         cleanup_compose_files();
 901                         exit(0);
 902                 }
 903                 $address = ask("Who should the email be sent to (if any)? ",
 904                         default => "",
 905                         valid_re => qr/\@.*\./, confirm_only => 1);
 906         }
 907         return $address;
 908 }
 909
 910 sub validate_address_list {
 911         return (grep { defined $_ }
 912                 map { validate_address($_) } @_);
 913 }
 914
 915 # Usually don't need to change anything below here.
 916
 917 # we make a "fake" message id by taking the current number
 918 # of seconds since the beginning of Unix time and tacking on
 919 # a random number to the end, in case we are called quicker than
 920 # 1 second since the last time we were called.
 921
 922 # We'll setup a template for the message id, using the "from" address:
 923
 924 my ($message_id_stamp, $message_id_serial);
 925 sub make_message_id {
 926         my $uniq;
 927         if (!defined $message_id_stamp) {
 928                 $message_id_stamp = sprintf("%s-%s", time, $$);
 929                 $message_id_serial = 0;
 930         }
 931         $message_id_serial++;
 932         $uniq = "$message_id_stamp-$message_id_serial";
 933
 934         my $du_part;
 935         for ($sender, $repocommitter, $repoauthor) {
 936                 $du_part = extract_valid_address(sanitize_address($_));
 937                 last if (defined $du_part and $du_part ne '');
 938         }
 939         if (not defined $du_part or $du_part eq '') {
 940                 require Sys::Hostname;
 941                 $du_part = 'user@' . Sys::Hostname::hostname();
 942         }
 943         my $message_id_template = "<%s-git-send-email-%s>";
 944         $message_id = sprintf($message_id_template, $uniq, $du_part);
 945         #print "new message id = $message_id\n"; # Was useful for debugging
 946 }
 947
 948
 949
 950 $time = time - scalar $#files;
 951
 952 sub unquote_rfc2047 {
 953         local ($_) = @_;
 954         my $charset;
 955         my $sep = qr/[ \t]+/;
 956         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 957                 my @words = split $sep, $&;
 958                 foreach (@words) {
 959                         m/$re_encoded_word/;
 960                         $charset = $1;
 961                         my $encoding = $2;
 962                         my $text = $3;
 963                         if ($encoding eq 'q' || $encoding eq 'Q') {
 964                                 $_ = $text;
 965                                 s/_/ /g;
 966                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 967                         } else {
 968                                 # other encodings not supported yet
 969                         }
 970                 }
 971                 join '', @words;
 972         }eg;
 973         return wantarray ? ($_, $charset) : $_;
 974 }
 975
 976 sub quote_rfc2047 {
 977         local $_ = shift;
 978         my $encoding = shift || 'UTF-8';
 979         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 980         s/(.*)/=\?$encoding\?q\?$1\?=/;
 981         return $_;
 982 }
 983
 984 sub is_rfc2047_quoted {
 985         my $s = shift;
 986         length($s) <= 75 &&
 987         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
 988 }
 989
 990 sub subject_needs_rfc2047_quoting {
 991         my $s = shift;
 992
 993         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 994 }
 995
 996 sub quote_subject {
 997         local $subject = shift;
 998         my $encoding = shift || 'UTF-8';
 999
1000         if (subject_needs_rfc2047_quoting($subject)) {
1001                 return quote_rfc2047($subject, $encoding);
1002         }
1003         return $subject;
1004 }
1005
1006 # use the simplest quoting being able to handle the recipient
1007 sub sanitize_address {
1008         my ($recipient) = @_;
1009
1010         # remove garbage after email address
1011         $recipient =~ s/(.*>).*$/$1/;
1012
1013         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
1014
1015         if (not $recipient_name) {
1016                 return $recipient;
1017         }
1018
1019         # if recipient_name is already quoted, do nothing
1020         if (is_rfc2047_quoted($recipient_name)) {
1021                 return $recipient;
1022         }
1023
1024         # remove non-escaped quotes
1025         $recipient_name =~ s/(^|[^\\])"/$1/g;
1026
1027         # rfc2047 is needed if a non-ascii char is included
1028         if ($recipient_name =~ /[^[:ascii:]]/) {
1029                 $recipient_name = quote_rfc2047($recipient_name);
1030         }
1031
1032         # double quotes are needed if specials or CTLs are included
1033         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1034                 $recipient_name =~ s/([\\\r])/\\$1/g;
1035                 $recipient_name = qq["$recipient_name"];
1036         }
1037
1038         return "$recipient_name $recipient_addr";
1039
1040 }
1041
1042 sub sanitize_address_list {
1043         return (map { sanitize_address($_) } @_);
1044 }
1045
1046 sub process_address_list {
1047         my @addr_list = map { parse_address_line($_) } @_;
1048         @addr_list = expand_aliases(@addr_list);
1049         @addr_list = sanitize_address_list(@addr_list);
1050         @addr_list = validate_address_list(@addr_list);
1051         return @addr_list;
1052 }
1053
1054 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1055 #
1056 # Tightly configured MTAa require that a caller sends a real DNS
1057 # domain name that corresponds the IP address in the HELO/EHLO
1058 # handshake. This is used to verify the connection and prevent
1059 # spammers from trying to hide their identity. If the DNS and IP don't
1060 # match, the receiveing MTA may deny the connection.
1061 #
1062 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1063 #
1064 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1065 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1066 #
1067 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1068 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1069
1070 sub valid_fqdn {
1071         my $domain = shift;
1072         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1073 }
1074
1075 sub maildomain_net {
1076         my $maildomain;
1077
1078         if (eval { require Net::Domain; 1 }) {
1079                 my $domain = Net::Domain::domainname();
1080                 $maildomain = $domain if valid_fqdn($domain);
1081         }
1082
1083         return $maildomain;
1084 }
1085
1086 sub maildomain_mta {
1087         my $maildomain;
1088
1089         if (eval { require Net::SMTP; 1 }) {
1090                 for my $host (qw(mailhost localhost)) {
1091                         my $smtp = Net::SMTP->new($host);
1092                         if (defined $smtp) {
1093                                 my $domain = $smtp->domain;
1094                                 $smtp->quit;
1095
1096                                 $maildomain = $domain if valid_fqdn($domain);
1097
1098                                 last if $maildomain;
1099                         }
1100                 }
1101         }
1102
1103         return $maildomain;
1104 }
1105
1106 sub maildomain {
1107         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1108 }
1109
1110 sub smtp_host_string {
1111         if (defined $smtp_server_port) {
1112                 return "$smtp_server:$smtp_server_port";
1113         } else {
1114                 return $smtp_server;
1115         }
1116 }
1117
1118 # Returns 1 if authentication succeeded or was not necessary
1119 # (smtp_user was not specified), and 0 otherwise.
1120
1121 sub smtp_auth_maybe {
1122         if (!defined $smtp_authuser || $auth) {
1123                 return 1;
1124         }
1125
1126         # Workaround AUTH PLAIN/LOGIN interaction defect
1127         # with Authen::SASL::Cyrus
1128         eval {
1129                 require Authen::SASL;
1130                 Authen::SASL->import(qw(Perl));
1131         };
1132
1133         # TODO: Authentication may fail not because credentials were
1134         # invalid but due to other reasons, in which we should not
1135         # reject credentials.
1136         $auth = Git::credential({
1137                 'protocol' => 'smtp',
1138                 'host' => smtp_host_string(),
1139                 'username' => $smtp_authuser,
1140                 # if there's no password, "git credential fill" will
1141                 # give us one, otherwise it'll just pass this one.
1142                 'password' => $smtp_authpass
1143         }, sub {
1144                 my $cred = shift;
1145                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1146         });
1147
1148         return $auth;
1149 }
1150
1151 sub ssl_verify_params {
1152         eval {
1153                 require IO::Socket::SSL;
1154                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1155         };
1156         if ($@) {
1157                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1158                 return;
1159         }
1160
1161         if (!defined $smtp_ssl_cert_path) {
1162                 # use the OpenSSL defaults
1163                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1164         }
1165
1166         if ($smtp_ssl_cert_path eq "") {
1167                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1168         } elsif (-d $smtp_ssl_cert_path) {
1169                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1170                         SSL_ca_path => $smtp_ssl_cert_path);
1171         } elsif (-f $smtp_ssl_cert_path) {
1172                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1173                         SSL_ca_file => $smtp_ssl_cert_path);
1174         } else {
1175                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1176                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1177         }
1178 }
1179
1180 sub file_name_is_absolute {
1181         my ($path) = @_;
1182
1183         # msys does not grok DOS drive-prefixes
1184         if ($^O eq 'msys') {
1185                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1186         }
1187
1188         require File::Spec::Functions;
1189         return File::Spec::Functions::file_name_is_absolute($path);
1190 }
1191
1192 # Returns 1 if the message was sent, and 0 otherwise.
1193 # In actuality, the whole program dies when there
1194 # is an error sending a message.
1195
1196 sub send_message {
1197         my @recipients = unique_email_list(@to);
1198         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1199                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1200                     }
1201                @cc);
1202         my $to = join (",\n\t", @recipients);
1203         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1204         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1205         my $date = format_2822_time($time++);
1206         my $gitversion = '@@GIT_VERSION@@';
1207         if ($gitversion =~ m/..GIT_VERSION../) {
1208             $gitversion = Git::version();
1209         }
1210
1211         my $cc = join(",\n\t", unique_email_list(@cc));
1212         my $ccline = "";
1213         if ($cc ne '') {
1214                 $ccline = "\nCc: $cc";
1215         }
1216         make_message_id() unless defined($message_id);
1217
1218         my $header = "From: $sender
1219 To: $to${ccline}
1220 Subject: $subject
1221 Date: $date
1222 Message-Id: $message_id
1223 ";
1224         if ($use_xmailer) {
1225                 $header .= "X-Mailer: git-send-email $gitversion\n";
1226         }
1227         if ($reply_to) {
1228
1229                 $header .= "In-Reply-To: $reply_to\n";
1230                 $header .= "References: $references\n";
1231         }
1232         if (@xh) {
1233                 $header .= join("\n", @xh) . "\n";
1234         }
1235
1236         my @sendmail_parameters = ('-i', @recipients);
1237         my $raw_from = $sender;
1238         if (defined $envelope_sender && $envelope_sender ne "auto") {
1239                 $raw_from = $envelope_sender;
1240         }
1241         $raw_from = extract_valid_address($raw_from);
1242         unshift (@sendmail_parameters,
1243                         '-f', $raw_from) if(defined $envelope_sender);
1244
1245         if ($needs_confirm && !$dry_run) {
1246                 print "\n$header\n";
1247                 if ($needs_confirm eq "inform") {
1248                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1249                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1250                         print "    The Cc list above has been expanded by additional\n";
1251                         print "    addresses found in the patch commit message. By default\n";
1252                         print "    send-email prompts before sending whenever this occurs.\n";
1253                         print "    This behavior is controlled by the sendemail.confirm\n";
1254                         print "    configuration setting.\n";
1255                         print "\n";
1256                         print "    For additional information, run 'git send-email --help'.\n";
1257                         print "    To retain the current behavior, but squelch this message,\n";
1258                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1259                 }
1260                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1261                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1262                          default => $ask_default);
1263                 die "Send this email reply required" unless defined $_;
1264                 if (/^n/i) {
1265                         return 0;
1266                 } elsif (/^q/i) {
1267                         cleanup_compose_files();
1268                         exit(0);
1269                 } elsif (/^a/i) {
1270                         $confirm = 'never';
1271                 }
1272         }
1273
1274         unshift (@sendmail_parameters, @smtp_server_options);
1275
1276         if ($dry_run) {
1277                 # We don't want to send the email.
1278         } elsif (file_name_is_absolute($smtp_server)) {
1279                 my $pid = open my $sm, '|-';
1280                 defined $pid or die $!;
1281                 if (!$pid) {
1282                         exec($smtp_server, @sendmail_parameters) or die $!;
1283                 }
1284                 print $sm "$header\n$message";
1285                 close $sm or die $!;
1286         } else {
1287
1288                 if (!defined $smtp_server) {
1289                         die "The required SMTP server is not properly defined."
1290                 }
1291
1292                 if ($smtp_encryption eq 'ssl') {
1293                         $smtp_server_port ||= 465; # ssmtp
1294                         require Net::SMTP::SSL;
1295                         $smtp_domain ||= maildomain();
1296                         require IO::Socket::SSL;
1297                         # Net::SMTP::SSL->new() does not forward any SSL options
1298                         IO::Socket::SSL::set_client_defaults(
1299                                 ssl_verify_params());
1300                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1301                                                       Hello => $smtp_domain,
1302                                                       Port => $smtp_server_port,
1303                                                       Debug => $debug_net_smtp);
1304                 }
1305                 else {
1306                         require Net::SMTP;
1307                         $smtp_domain ||= maildomain();
1308                         $smtp_server_port ||= 25;
1309                         $smtp ||= Net::SMTP->new($smtp_server,
1310                                                  Hello => $smtp_domain,
1311                                                  Debug => $debug_net_smtp,
1312                                                  Port => $smtp_server_port);
1313                         if ($smtp_encryption eq 'tls' && $smtp) {
1314                                 require Net::SMTP::SSL;
1315                                 $smtp->command('STARTTLS');
1316                                 $smtp->response();
1317                                 if ($smtp->code == 220) {
1318                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1319                                                                           ssl_verify_params())
1320                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1321                                         $smtp_encryption = '';
1322                                         # Send EHLO again to receive fresh
1323                                         # supported commands
1324                                         $smtp->hello($smtp_domain);
1325                                 } else {
1326                                         die "Server does not support STARTTLS! ".$smtp->message;
1327                                 }
1328                         }
1329                 }
1330
1331                 if (!$smtp) {
1332                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1333                             "VALUES: server=$smtp_server ",
1334                             "encryption=$smtp_encryption ",
1335                             "hello=$smtp_domain",
1336                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1337                 }
1338
1339                 smtp_auth_maybe or die $smtp->message;
1340
1341                 $smtp->mail( $raw_from ) or die $smtp->message;
1342                 $smtp->to( @recipients ) or die $smtp->message;
1343                 $smtp->data or die $smtp->message;
1344                 $smtp->datasend("$header\n$message") or die $smtp->message;
1345                 $smtp->dataend() or die $smtp->message;
1346                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1347         }
1348         if ($quiet) {
1349                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1350         } else {
1351                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1352                 if (!file_name_is_absolute($smtp_server)) {
1353                         print "Server: $smtp_server\n";
1354                         print "MAIL FROM:<$raw_from>\n";
1355                         foreach my $entry (@recipients) {
1356                             print "RCPT TO:<$entry>\n";
1357                         }
1358                 } else {
1359                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1360                 }
1361                 print $header, "\n";
1362                 if ($smtp) {
1363                         print "Result: ", $smtp->code, ' ',
1364                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1365                 } else {
1366                         print "Result: OK\n";
1367                 }
1368         }
1369
1370         return 1;
1371 }
1372
1373 $reply_to = $initial_reply_to;
1374 $references = $initial_reply_to || '';
1375 $subject = $initial_subject;
1376 $message_num = 0;
1377
1378 foreach my $t (@files) {
1379         open my $fh, "<", $t or die "can't open file $t";
1380
1381         my $author = undef;
1382         my $sauthor = undef;
1383         my $author_encoding;
1384         my $has_content_type;
1385         my $body_encoding;
1386         my $xfer_encoding;
1387         my $has_mime_version;
1388         @to = ();
1389         @cc = ();
1390         @xh = ();
1391         my $input_format = undef;
1392         my @header = ();
1393         $message = "";
1394         $message_num++;
1395         # First unfold multiline header fields
1396         while(<$fh>) {
1397                 last if /^\s*$/;
1398                 if (/^\s+\S/ and @header) {
1399                         chomp($header[$#header]);
1400                         s/^\s+/ /;
1401                         $header[$#header] .= $_;
1402             } else {
1403                         push(@header, $_);
1404                 }
1405         }
1406         # Now parse the header
1407         foreach(@header) {
1408                 if (/^From /) {
1409                         $input_format = 'mbox';
1410                         next;
1411                 }
1412                 chomp;
1413                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1414                         $input_format = 'mbox';
1415                 }
1416
1417                 if (defined $input_format && $input_format eq 'mbox') {
1418                         if (/^Subject:\s+(.*)$/i) {
1419                                 $subject = $1;
1420                         }
1421                         elsif (/^From:\s+(.*)$/i) {
1422                                 ($author, $author_encoding) = unquote_rfc2047($1);
1423                                 $sauthor = sanitize_address($author);
1424                                 next if $suppress_cc{'author'};
1425                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1426                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1427                                         $1, $_) unless $quiet;
1428                                 push @cc, $1;
1429                         }
1430                         elsif (/^To:\s+(.*)$/i) {
1431                                 foreach my $addr (parse_address_line($1)) {
1432                                         printf("(mbox) Adding to: %s from line '%s'\n",
1433                                                 $addr, $_) unless $quiet;
1434                                         push @to, $addr;
1435                                 }
1436                         }
1437                         elsif (/^Cc:\s+(.*)$/i) {
1438                                 foreach my $addr (parse_address_line($1)) {
1439                                         my $qaddr = unquote_rfc2047($addr);
1440                                         my $saddr = sanitize_address($qaddr);
1441                                         if ($saddr eq $sender) {
1442                                                 next if ($suppress_cc{'self'});
1443                                         } else {
1444                                                 next if ($suppress_cc{'cc'});
1445                                         }
1446                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1447                                                 $addr, $_) unless $quiet;
1448                                         push @cc, $addr;
1449                                 }
1450                         }
1451                         elsif (/^Content-type:/i) {
1452                                 $has_content_type = 1;
1453                                 if (/charset="?([^ "]+)/) {
1454                                         $body_encoding = $1;
1455                                 }
1456                                 push @xh, $_;
1457                         }
1458                         elsif (/^MIME-Version/i) {
1459                                 $has_mime_version = 1;
1460                                 push @xh, $_;
1461                         }
1462                         elsif (/^Message-Id: (.*)/i) {
1463                                 $message_id = $1;
1464                         }
1465                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1466                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1467                         }
1468                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1469                                 push @xh, $_;
1470                         }
1471
1472                 } else {
1473                         # In the traditional
1474                         # "send lots of email" format,
1475                         # line 1 = cc
1476                         # line 2 = subject
1477                         # So let's support that, too.
1478                         $input_format = 'lots';
1479                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1480                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1481                                         $_, $_) unless $quiet;
1482                                 push @cc, $_;
1483                         } elsif (!defined $subject) {
1484                                 $subject = $_;
1485                         }
1486                 }
1487         }
1488         # Now parse the message body
1489         while(<$fh>) {
1490                 $message .=  $_;
1491                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1492                         chomp;
1493                         my ($what, $c) = ($1, $2);
1494                         chomp $c;
1495                         my $sc = sanitize_address($c);
1496                         if ($sc eq $sender) {
1497                                 next if ($suppress_cc{'self'});
1498                         } else {
1499                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1500                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1501                         }
1502                         push @cc, $c;
1503                         printf("(body) Adding cc: %s from line '%s'\n",
1504                                 $c, $_) unless $quiet;
1505                 }
1506         }
1507         close $fh;
1508
1509         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1510                 if defined $to_cmd;
1511         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1512                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1513
1514         if ($broken_encoding{$t} && !$has_content_type) {
1515                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1516                 $has_content_type = 1;
1517                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1518                 $body_encoding = $auto_8bit_encoding;
1519         }
1520
1521         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1522                 $subject = quote_subject($subject, $auto_8bit_encoding);
1523         }
1524
1525         if (defined $sauthor and $sauthor ne $sender) {
1526                 $message = "From: $author\n\n$message";
1527                 if (defined $author_encoding) {
1528                         if ($has_content_type) {
1529                                 if ($body_encoding eq $author_encoding) {
1530                                         # ok, we already have the right encoding
1531                                 }
1532                                 else {
1533                                         # uh oh, we should re-encode
1534                                 }
1535                         }
1536                         else {
1537                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1538                                 $has_content_type = 1;
1539                                 push @xh,
1540                                   "Content-Type: text/plain; charset=$author_encoding";
1541                         }
1542                 }
1543         }
1544         if (defined $target_xfer_encoding) {
1545                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1546                 $message = apply_transfer_encoding(
1547                         $message, $xfer_encoding, $target_xfer_encoding);
1548                 $xfer_encoding = $target_xfer_encoding;
1549         }
1550         if (defined $xfer_encoding) {
1551                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1552         }
1553         if (defined $xfer_encoding or $has_content_type) {
1554                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1555         }
1556
1557         $needs_confirm = (
1558                 $confirm eq "always" or
1559                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1560                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1561         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1562
1563         @to = process_address_list(@to);
1564         @cc = process_address_list(@cc);
1565
1566         @to = (@initial_to, @to);
1567         @cc = (@initial_cc, @cc);
1568
1569         if ($message_num == 1) {
1570                 if (defined $cover_cc and $cover_cc) {
1571                         @initial_cc = @cc;
1572                 }
1573                 if (defined $cover_to and $cover_to) {
1574                         @initial_to = @to;
1575                 }
1576         }
1577
1578         my $message_was_sent = send_message();
1579
1580         # set up for the next message
1581         if ($thread && $message_was_sent &&
1582                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1583                 $message_num == 1)) {
1584                 $reply_to = $message_id;
1585                 if (length $references > 0) {
1586                         $references .= "\n $message_id";
1587                 } else {
1588                         $references = "$message_id";
1589                 }
1590         }
1591         $message_id = undef;
1592 }
1593
1594 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1595 # and return a results array
1596 sub recipients_cmd {
1597         my ($prefix, $what, $cmd, $file) = @_;
1598
1599         my @addresses = ();
1600         open my $fh, "-|", "$cmd \Q$file\E"
1601             or die "($prefix) Could not execute '$cmd'";
1602         while (my $address = <$fh>) {
1603                 $address =~ s/^\s*//g;
1604                 $address =~ s/\s*$//g;
1605                 $address = sanitize_address($address);
1606                 next if ($address eq $sender and $suppress_cc{'self'});
1607                 push @addresses, $address;
1608                 printf("($prefix) Adding %s: %s from: '%s'\n",
1609                        $what, $address, $cmd) unless $quiet;
1610                 }
1611         close $fh
1612             or die "($prefix) failed to close pipe to '$cmd'";
1613         return @addresses;
1614 }
1615
1616 cleanup_compose_files();
1617
1618 sub cleanup_compose_files {
1619         unlink($compose_filename, $compose_filename . ".final") if $compose;
1620 }
1621
1622 $smtp->quit if $smtp;
1623
1624 sub apply_transfer_encoding {
1625         my $message = shift;
1626         my $from = shift;
1627         my $to = shift;
1628
1629         return $message if ($from eq $to and $from ne '7bit');
1630
1631         require MIME::QuotedPrint;
1632         require MIME::Base64;
1633
1634         $message = MIME::QuotedPrint::decode($message)
1635                 if ($from eq 'quoted-printable');
1636         $message = MIME::Base64::decode($message)
1637                 if ($from eq 'base64');
1638
1639         die "cannot send message as 7bit"
1640                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1641         return $message
1642                 if ($to eq '7bit' or $to eq '8bit');
1643         return MIME::QuotedPrint::encode($message, "\n", 0)
1644                 if ($to eq 'quoted-printable');
1645         return MIME::Base64::encode($message, "\n")
1646                 if ($to eq 'base64');
1647         die "invalid transfer encoding";
1648 }
1649
1650 sub unique_email_list {
1651         my %seen;
1652         my @emails;
1653
1654         foreach my $entry (@_) {
1655                 my $clean = extract_valid_address_or_die($entry);
1656                 $seen{$clean} ||= 0;
1657                 next if $seen{$clean}++;
1658                 push @emails, $entry;
1659         }
1660         return @emails;
1661 }
1662
1663 sub validate_patch {
1664         my $fn = shift;
1665         open(my $fh, '<', $fn)
1666                 or die "unable to open $fn: $!\n";
1667         while (my $line = <$fh>) {
1668                 if (length($line) > 998) {
1669                         return "$.: patch contains a line longer than 998 characters";
1670                 }
1671         }
1672         return;
1673 }
1674
1675 sub file_has_nonascii {
1676         my $fn = shift;
1677         open(my $fh, '<', $fn)
1678                 or die "unable to open $fn: $!\n";
1679         while (my $line = <$fh>) {
1680                 return 1 if $line =~ /[^[:ascii:]]/;
1681         }
1682         return 0;
1683 }
1684
1685 sub body_or_subject_has_nonascii {
1686         my $fn = shift;
1687         open(my $fh, '<', $fn)
1688                 or die "unable to open $fn: $!\n";
1689         while (my $line = <$fh>) {
1690                 last if $line =~ /^$/;
1691                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1692         }
1693         while (my $line = <$fh>) {
1694                 return 1 if $line =~ /[^[:ascii:]]/;
1695         }
1696         return 0;
1697 }