git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cccmd, all.
  72     --[no-]signed-off-by-cc        * Send to Cc: and Signed-off-by:
  73                                      addresses. Default on.
  74     --[no-]suppress-from           * Send to self. Default off.
  75     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  76     --[no-]thread                  * Use In-Reply-To: field. Default on.
  77
  78   Administering:
  79     --quiet                        * Output one line of info per email.
  80     --dry-run                      * Don't actually send the emails.
  81     --[no-]validate                * Perform patch sanity checks. Default on.
  82     --[no-]format-patch            * understand any non optional arguments as
  83                                      `git format-patch` ones.
  84
  85 EOT
  86         exit(1);
  87 }
  88
  89 # most mail servers generate the Date: header, but not all...
  90 sub format_2822_time {
  91         my ($time) = @_;
  92         my @localtm = localtime($time);
  93         my @gmttm = gmtime($time);
  94         my $localmin = $localtm[1] + $localtm[2] * 60;
  95         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  96         if ($localtm[0] != $gmttm[0]) {
  97                 die "local zone differs from GMT by a non-minute interval\n";
  98         }
  99         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 100                 $localmin += 1440;
 101         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 102                 $localmin -= 1440;
 103         } elsif ($gmttm[6] != $localtm[6]) {
 104                 die "local time offset greater than or equal to 24 hours\n";
 105         }
 106         my $offset = $localmin - $gmtmin;
 107         my $offhour = $offset / 60;
 108         my $offmin = abs($offset % 60);
 109         if (abs($offhour) >= 24) {
 110                 die ("local time offset greater than or equal to 24 hours\n");
 111         }
 112
 113         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 114                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 115                        $localtm[3],
 116                        qw(Jan Feb Mar Apr May Jun
 117                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 118                        $localtm[5]+1900,
 119                        $localtm[2],
 120                        $localtm[1],
 121                        $localtm[0],
 122                        ($offset >= 0) ? '+' : '-',
 123                        abs($offhour),
 124                        $offmin,
 125                        );
 126 }
 127
 128 my $have_email_valid = eval { require Email::Valid; 1 };
 129 my $smtp;
 130 my $auth;
 131
 132 sub unique_email_list(@);
 133 sub cleanup_compose_files();
 134
 135 # Variables we fill in automatically, or via prompting:
 136 my (@to,@cc,@initial_cc,@bcclist,@xh,
 137         $initial_reply_to,$initial_subject,@files,
 138         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 139
 140 my $envelope_sender;
 141
 142 # Example reply to:
 143 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 144
 145 my $repo = eval { Git->repository() };
 146 my @repo = $repo ? ($repo) : ();
 147 my $term = eval {
 148         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 149                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 150                 : new Term::ReadLine 'git-send-email';
 151 };
 152 if ($@) {
 153         $term = new FakeTerm "$@: going non-interactive";
 154 }
 155
 156 # Behavior modification variables
 157 my ($quiet, $dry_run) = (0, 0);
 158 my $format_patch;
 159 my $compose_filename = $repo->repo_path() . "/.gitsendemail.msg.$$";
 160
 161 # Handle interactive edition of files.
 162 my $multiedit;
 163 my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 164 sub do_edit {
 165         if (defined($multiedit) && !$multiedit) {
 166                 map {
 167                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 168                         if (($? & 127) || ($? >> 8)) {
 169                                 die("the editor exited uncleanly, aborting everything");
 170                         }
 171                 } @_;
 172         } else {
 173                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 174                 if (($? & 127) || ($? >> 8)) {
 175                         die("the editor exited uncleanly, aborting everything");
 176                 }
 177         }
 178 }
 179
 180 # Variables with corresponding config settings
 181 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 182 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 183 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 184 my ($validate);
 185 my (@suppress_cc);
 186
 187 my %config_bool_settings = (
 188     "thread" => [\$thread, 1],
 189     "chainreplyto" => [\$chain_reply_to, 1],
 190     "suppressfrom" => [\$suppress_from, undef],
 191     "signedoffbycc" => [\$signed_off_by_cc, undef],
 192     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 193     "validate" => [\$validate, 1],
 194 );
 195
 196 my %config_settings = (
 197     "smtpserver" => \$smtp_server,
 198     "smtpserverport" => \$smtp_server_port,
 199     "smtpuser" => \$smtp_authuser,
 200     "smtppass" => \$smtp_authpass,
 201     "to" => \@to,
 202     "cc" => \@initial_cc,
 203     "cccmd" => \$cc_cmd,
 204     "aliasfiletype" => \$aliasfiletype,
 205     "bcc" => \@bcclist,
 206     "aliasesfile" => \@alias_files,
 207     "suppresscc" => \@suppress_cc,
 208     "envelopesender" => \$envelope_sender,
 209     "multiedit" => \$multiedit,
 210 );
 211
 212 # Handle Uncouth Termination
 213 sub signal_handler {
 214
 215         # Make text normal
 216         print color("reset"), "\n";
 217
 218         # SMTP password masked
 219         system "stty echo";
 220
 221         # tmp files from --compose
 222         if (-e $compose_filename) {
 223                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 224         }
 225         if (-e ($compose_filename . ".final")) {
 226                 print "'$compose_filename.final' contains the composed email.\n"
 227         }
 228
 229         exit;
 230 };
 231
 232 $SIG{TERM} = \&signal_handler;
 233 $SIG{INT}  = \&signal_handler;
 234
 235 # Begin by accumulating all the variables (defined above), that we will end up
 236 # needing, first, from the command line:
 237
 238 my $rc = GetOptions("sender|from=s" => \$sender,
 239                     "in-reply-to=s" => \$initial_reply_to,
 240                     "subject=s" => \$initial_subject,
 241                     "to=s" => \@to,
 242                     "cc=s" => \@initial_cc,
 243                     "bcc=s" => \@bcclist,
 244                     "chain-reply-to!" => \$chain_reply_to,
 245                     "smtp-server=s" => \$smtp_server,
 246                     "smtp-server-port=s" => \$smtp_server_port,
 247                     "smtp-user=s" => \$smtp_authuser,
 248                     "smtp-pass:s" => \$smtp_authpass,
 249                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 250                     "smtp-encryption=s" => \$smtp_encryption,
 251                     "identity=s" => \$identity,
 252                     "annotate" => \$annotate,
 253                     "compose" => \$compose,
 254                     "quiet" => \$quiet,
 255                     "cc-cmd=s" => \$cc_cmd,
 256                     "suppress-from!" => \$suppress_from,
 257                     "suppress-cc=s" => \@suppress_cc,
 258                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 259                     "dry-run" => \$dry_run,
 260                     "envelope-sender=s" => \$envelope_sender,
 261                     "thread!" => \$thread,
 262                     "validate!" => \$validate,
 263                     "format-patch!" => \$format_patch,
 264          );
 265
 266 unless ($rc) {
 267     usage();
 268 }
 269
 270 # Now, let's fill any that aren't set in with defaults:
 271
 272 sub read_config {
 273         my ($prefix) = @_;
 274
 275         foreach my $setting (keys %config_bool_settings) {
 276                 my $target = $config_bool_settings{$setting}->[0];
 277                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 278         }
 279
 280         foreach my $setting (keys %config_settings) {
 281                 my $target = $config_settings{$setting};
 282                 if (ref($target) eq "ARRAY") {
 283                         unless (@$target) {
 284                                 my @values = Git::config(@repo, "$prefix.$setting");
 285                                 @$target = @values if (@values && defined $values[0]);
 286                         }
 287                 }
 288                 else {
 289                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 290                 }
 291         }
 292
 293         if (!defined $smtp_encryption) {
 294                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 295                 if (defined $enc) {
 296                         $smtp_encryption = $enc;
 297                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 298                         $smtp_encryption = 'ssl';
 299                 }
 300         }
 301 }
 302
 303 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 304 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 305 read_config("sendemail.$identity") if (defined $identity);
 306 read_config("sendemail");
 307
 308 # fall back on builtin bool defaults
 309 foreach my $setting (values %config_bool_settings) {
 310         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 311 }
 312
 313 # 'default' encryption is none -- this only prevents a warning
 314 $smtp_encryption = '' unless (defined $smtp_encryption);
 315
 316 # Set CC suppressions
 317 my(%suppress_cc);
 318 if (@suppress_cc) {
 319         foreach my $entry (@suppress_cc) {
 320                 die "Unknown --suppress-cc field: '$entry'\n"
 321                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 322                 $suppress_cc{$entry} = 1;
 323         }
 324 }
 325
 326 if ($suppress_cc{'all'}) {
 327         foreach my $entry (qw (ccmd cc author self sob)) {
 328                 $suppress_cc{$entry} = 1;
 329         }
 330         delete $suppress_cc{'all'};
 331 }
 332
 333 # If explicit old-style ones are specified, they trump --suppress-cc.
 334 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 335 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 336
 337 # Debugging, print out the suppressions.
 338 if (0) {
 339         print "suppressions:\n";
 340         foreach my $entry (keys %suppress_cc) {
 341                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 342         }
 343 }
 344
 345 my ($repoauthor, $repocommitter);
 346 ($repoauthor) = Git::ident_person(@repo, 'author');
 347 ($repocommitter) = Git::ident_person(@repo, 'committer');
 348
 349 # Verify the user input
 350
 351 foreach my $entry (@to) {
 352         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 353 }
 354
 355 foreach my $entry (@initial_cc) {
 356         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 357 }
 358
 359 foreach my $entry (@bcclist) {
 360         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 361 }
 362
 363 sub split_addrs {
 364         return quotewords('\s*,\s*', 1, @_);
 365 }
 366
 367 my %aliases;
 368 my %parse_alias = (
 369         # multiline formats can be supported in the future
 370         mutt => sub { my $fh = shift; while (<$fh>) {
 371                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 372                         my ($alias, $addr) = ($1, $2);
 373                         $addr =~ s/#.*$//; # mutt allows # comments
 374                          # commas delimit multiple addresses
 375                         $aliases{$alias} = [ split_addrs($addr) ];
 376                 }}},
 377         mailrc => sub { my $fh = shift; while (<$fh>) {
 378                 if (/^alias\s+(\S+)\s+(.*)$/) {
 379                         # spaces delimit multiple addresses
 380                         $aliases{$1} = [ split(/\s+/, $2) ];
 381                 }}},
 382         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 383                 for (my $x = ''; defined($x); $x = $_) {
 384                         chomp $x;
 385                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 386                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 387                         $aliases{$1} = [ split_addrs($2) ];
 388                 }},
 389         gnus => sub { my $fh = shift; while (<$fh>) {
 390                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 391                         $aliases{$1} = [ $2 ];
 392                 }}}
 393 );
 394
 395 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 396         foreach my $file (@alias_files) {
 397                 open my $fh, '<', $file or die "opening $file: $!\n";
 398                 $parse_alias{$aliasfiletype}->($fh);
 399                 close $fh;
 400         }
 401 }
 402
 403 ($sender) = expand_aliases($sender) if defined $sender;
 404
 405 # returns 1 if the conflict must be solved using it as a format-patch argument
 406 sub check_file_rev_conflict($) {
 407         my $f = shift;
 408         try {
 409                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 410                 if (defined($format_patch)) {
 411                         print "foo\n";
 412                         return $format_patch;
 413                 }
 414                 die(<<EOF);
 415 File '$f' exists but it could also be the range of commits
 416 to produce patches for.  Please disambiguate by...
 417
 418     * Saying "./$f" if you mean a file; or
 419     * Giving --format-patch option if you mean a range.
 420 EOF
 421         } catch Git::Error::Command with {
 422                 return 0;
 423         }
 424 }
 425
 426 # Now that all the defaults are set, process the rest of the command line
 427 # arguments and collect up the files that need to be processed.
 428 my @rev_list_opts;
 429 while (defined(my $f = shift @ARGV)) {
 430         if ($f eq "--") {
 431                 push @rev_list_opts, "--", @ARGV;
 432                 @ARGV = ();
 433         } elsif (-d $f and !check_file_rev_conflict($f)) {
 434                 opendir(DH,$f)
 435                         or die "Failed to opendir $f: $!";
 436
 437                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 438                                 sort readdir(DH);
 439                 closedir(DH);
 440         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 441                 push @files, $f;
 442         } else {
 443                 push @rev_list_opts, $f;
 444         }
 445 }
 446
 447 if (@rev_list_opts) {
 448         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 449 }
 450
 451 if ($validate) {
 452         foreach my $f (@files) {
 453                 unless (-p $f) {
 454                         my $error = validate_patch($f);
 455                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 456                 }
 457         }
 458 }
 459
 460 if (@files) {
 461         unless ($quiet) {
 462                 print $_,"\n" for (@files);
 463         }
 464 } else {
 465         print STDERR "\nNo patch files specified!\n\n";
 466         usage();
 467 }
 468
 469 sub get_patch_subject($) {
 470         my $fn = shift;
 471         open (my $fh, '<', $fn);
 472         while (my $line = <$fh>) {
 473                 next unless ($line =~ /^Subject: (.*)$/);
 474                 close $fh;
 475                 return "GIT: $1\n";
 476         }
 477         close $fh;
 478         die "No subject line in $fn ?";
 479 }
 480
 481 if ($compose) {
 482         # Note that this does not need to be secure, but we will make a small
 483         # effort to have it be unique
 484         open(C,">",$compose_filename)
 485                 or die "Failed to open for writing $compose_filename: $!";
 486
 487
 488         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 489         my $tpl_subject = $initial_subject || '';
 490         my $tpl_reply_to = $initial_reply_to || '';
 491
 492         print C <<EOT;
 493 From $tpl_sender # This line is ignored.
 494 GIT: Lines beginning in "GIT: " will be removed.
 495 GIT: Consider including an overall diffstat or table of contents
 496 GIT: for the patch you are writing.
 497 GIT:
 498 GIT: Clear the body content if you don't wish to send a summary.
 499 From: $tpl_sender
 500 Subject: $tpl_subject
 501 In-Reply-To: $tpl_reply_to
 502
 503 EOT
 504         for my $f (@files) {
 505                 print C get_patch_subject($f);
 506         }
 507         close(C);
 508
 509         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 510
 511         if ($annotate) {
 512                 do_edit($compose_filename, @files);
 513         } else {
 514                 do_edit($compose_filename);
 515         }
 516
 517         open(C2,">",$compose_filename . ".final")
 518                 or die "Failed to open $compose_filename.final : " . $!;
 519
 520         open(C,"<",$compose_filename)
 521                 or die "Failed to open $compose_filename : " . $!;
 522
 523         my $need_8bit_cte = file_has_nonascii($compose_filename);
 524         my $in_body = 0;
 525         my $summary_empty = 1;
 526         while(<C>) {
 527                 next if m/^GIT: /;
 528                 if ($in_body) {
 529                         $summary_empty = 0 unless (/^\n$/);
 530                 } elsif (/^\n$/) {
 531                         $in_body = 1;
 532                         if ($need_8bit_cte) {
 533                                 print C2 "MIME-Version: 1.0\n",
 534                                          "Content-Type: text/plain; ",
 535                                            "charset=utf-8\n",
 536                                          "Content-Transfer-Encoding: 8bit\n";
 537                         }
 538                 } elsif (/^MIME-Version:/i) {
 539                         $need_8bit_cte = 0;
 540                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 541                         $initial_subject = $1;
 542                         my $subject = $initial_subject;
 543                         $_ = "Subject: " .
 544                                 ($subject =~ /[^[:ascii:]]/ ?
 545                                  quote_rfc2047($subject) :
 546                                  $subject) .
 547                                 "\n";
 548                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 549                         $initial_reply_to = $1;
 550                         next;
 551                 } elsif (/^From:\s*(.+)\s*$/i) {
 552                         $sender = $1;
 553                         next;
 554                 } elsif (/^(?:To|Cc|Bcc):/i) {
 555                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 556                         next;
 557                 }
 558                 print C2 $_;
 559         }
 560         close(C);
 561         close(C2);
 562
 563         if ($summary_empty) {
 564                 print "Summary email is empty, skipping it\n";
 565                 $compose = -1;
 566         }
 567 } elsif ($annotate) {
 568         do_edit(@files);
 569 }
 570
 571 my $prompting = 0;
 572 if (!defined $sender) {
 573         $sender = $repoauthor || $repocommitter || '';
 574
 575         while (1) {
 576                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 577                 last if defined $_;
 578                 print "\n";
 579         }
 580
 581         $sender = $_ if ($_);
 582         print "Emails will be sent from: ", $sender, "\n";
 583         $prompting++;
 584 }
 585
 586 if (!@to) {
 587
 588
 589         while (1) {
 590                 $_ = $term->readline("Who should the emails be sent to? ", "");
 591                 last if defined $_;
 592                 print "\n";
 593         }
 594
 595         my $to = $_;
 596         push @to, split_addrs($to);
 597         $prompting++;
 598 }
 599
 600 sub expand_aliases {
 601         my @cur = @_;
 602         my @last;
 603         do {
 604                 @last = @cur;
 605                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 606         } while (join(',',@cur) ne join(',',@last));
 607         return @cur;
 608 }
 609
 610 @to = expand_aliases(@to);
 611 @to = (map { sanitize_address($_) } @to);
 612 @initial_cc = expand_aliases(@initial_cc);
 613 @bcclist = expand_aliases(@bcclist);
 614
 615 if ($thread && !defined $initial_reply_to && $prompting) {
 616         while (1) {
 617                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 618                 last if defined $_;
 619                 print "\n";
 620         }
 621
 622         $initial_reply_to = $_;
 623 }
 624 if (defined $initial_reply_to) {
 625         $initial_reply_to =~ s/^\s*<?//;
 626         $initial_reply_to =~ s/>?\s*$//;
 627         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 628 }
 629
 630 if (!defined $smtp_server) {
 631         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 632                 if (-x $_) {
 633                         $smtp_server = $_;
 634                         last;
 635                 }
 636         }
 637         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 638 }
 639
 640 if ($compose) {
 641         while (1) {
 642                 $_ = $term->readline("Send this email? (y|n) ");
 643                 last if defined $_;
 644                 print "\n";
 645         }
 646
 647         if (uc substr($_,0,1) ne 'Y') {
 648                 cleanup_compose_files();
 649                 exit(0);
 650         }
 651
 652         if ($compose > 0) {
 653                 @files = ($compose_filename . ".final", @files);
 654         }
 655 }
 656
 657 # Variables we set as part of the loop over files
 658 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 659
 660 sub extract_valid_address {
 661         my $address = shift;
 662         my $local_part_regexp = '[^<>"\s@]+';
 663         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 664
 665         # check for a local address:
 666         return $address if ($address =~ /^($local_part_regexp)$/);
 667
 668         $address =~ s/^\s*<(.*)>\s*$/$1/;
 669         if ($have_email_valid) {
 670                 return scalar Email::Valid->address($address);
 671         } else {
 672                 # less robust/correct than the monster regexp in Email::Valid,
 673                 # but still does a 99% job, and one less dependency
 674                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 675                 return $1;
 676         }
 677 }
 678
 679 # Usually don't need to change anything below here.
 680
 681 # we make a "fake" message id by taking the current number
 682 # of seconds since the beginning of Unix time and tacking on
 683 # a random number to the end, in case we are called quicker than
 684 # 1 second since the last time we were called.
 685
 686 # We'll setup a template for the message id, using the "from" address:
 687
 688 my ($message_id_stamp, $message_id_serial);
 689 sub make_message_id
 690 {
 691         my $uniq;
 692         if (!defined $message_id_stamp) {
 693                 $message_id_stamp = sprintf("%s-%s", time, $$);
 694                 $message_id_serial = 0;
 695         }
 696         $message_id_serial++;
 697         $uniq = "$message_id_stamp-$message_id_serial";
 698
 699         my $du_part;
 700         for ($sender, $repocommitter, $repoauthor) {
 701                 $du_part = extract_valid_address(sanitize_address($_));
 702                 last if (defined $du_part and $du_part ne '');
 703         }
 704         if (not defined $du_part or $du_part eq '') {
 705                 use Sys::Hostname qw();
 706                 $du_part = 'user@' . Sys::Hostname::hostname();
 707         }
 708         my $message_id_template = "<%s-git-send-email-%s>";
 709         $message_id = sprintf($message_id_template, $uniq, $du_part);
 710         #print "new message id = $message_id\n"; # Was useful for debugging
 711 }
 712
 713
 714
 715 $time = time - scalar $#files;
 716
 717 sub unquote_rfc2047 {
 718         local ($_) = @_;
 719         my $encoding;
 720         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 721                 $encoding = $1;
 722                 s/_/ /g;
 723                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 724         }
 725         return wantarray ? ($_, $encoding) : $_;
 726 }
 727
 728 sub quote_rfc2047 {
 729         local $_ = shift;
 730         my $encoding = shift || 'utf-8';
 731         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 732         s/(.*)/=\?$encoding\?q\?$1\?=/;
 733         return $_;
 734 }
 735
 736 # use the simplest quoting being able to handle the recipient
 737 sub sanitize_address
 738 {
 739         my ($recipient) = @_;
 740         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 741
 742         if (not $recipient_name) {
 743                 return "$recipient";
 744         }
 745
 746         # if recipient_name is already quoted, do nothing
 747         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 748                 return $recipient;
 749         }
 750
 751         # rfc2047 is needed if a non-ascii char is included
 752         if ($recipient_name =~ /[^[:ascii:]]/) {
 753                 $recipient_name = quote_rfc2047($recipient_name);
 754         }
 755
 756         # double quotes are needed if specials or CTLs are included
 757         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 758                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 759                 $recipient_name = "\"$recipient_name\"";
 760         }
 761
 762         return "$recipient_name $recipient_addr";
 763
 764 }
 765
 766 sub send_message
 767 {
 768         my @recipients = unique_email_list(@to);
 769         @cc = (grep { my $cc = extract_valid_address($_);
 770                       not grep { $cc eq $_ } @recipients
 771                     }
 772                map { sanitize_address($_) }
 773                @cc);
 774         my $to = join (",\n\t", @recipients);
 775         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 776         @recipients = (map { extract_valid_address($_) } @recipients);
 777         my $date = format_2822_time($time++);
 778         my $gitversion = '@@GIT_VERSION@@';
 779         if ($gitversion =~ m/..GIT_VERSION../) {
 780             $gitversion = Git::version();
 781         }
 782
 783         my $cc = join(", ", unique_email_list(@cc));
 784         my $ccline = "";
 785         if ($cc ne '') {
 786                 $ccline = "\nCc: $cc";
 787         }
 788         my $sanitized_sender = sanitize_address($sender);
 789         make_message_id() unless defined($message_id);
 790
 791         my $header = "From: $sanitized_sender
 792 To: $to${ccline}
 793 Subject: $subject
 794 Date: $date
 795 Message-Id: $message_id
 796 X-Mailer: git-send-email $gitversion
 797 ";
 798         if ($thread && $reply_to) {
 799
 800                 $header .= "In-Reply-To: $reply_to\n";
 801                 $header .= "References: $references\n";
 802         }
 803         if (@xh) {
 804                 $header .= join("\n", @xh) . "\n";
 805         }
 806
 807         my @sendmail_parameters = ('-i', @recipients);
 808         my $raw_from = $sanitized_sender;
 809         $raw_from = $envelope_sender if (defined $envelope_sender);
 810         $raw_from = extract_valid_address($raw_from);
 811         unshift (@sendmail_parameters,
 812                         '-f', $raw_from) if(defined $envelope_sender);
 813
 814         if ($dry_run) {
 815                 # We don't want to send the email.
 816         } elsif ($smtp_server =~ m#^/#) {
 817                 my $pid = open my $sm, '|-';
 818                 defined $pid or die $!;
 819                 if (!$pid) {
 820                         exec($smtp_server, @sendmail_parameters) or die $!;
 821                 }
 822                 print $sm "$header\n$message";
 823                 close $sm or die $?;
 824         } else {
 825
 826                 if (!defined $smtp_server) {
 827                         die "The required SMTP server is not properly defined."
 828                 }
 829
 830                 if ($smtp_encryption eq 'ssl') {
 831                         $smtp_server_port ||= 465; # ssmtp
 832                         require Net::SMTP::SSL;
 833                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 834                 }
 835                 else {
 836                         require Net::SMTP;
 837                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 838                                                  ? "$smtp_server:$smtp_server_port"
 839                                                  : $smtp_server);
 840                         if ($smtp_encryption eq 'tls') {
 841                                 require Net::SMTP::SSL;
 842                                 $smtp->command('STARTTLS');
 843                                 $smtp->response();
 844                                 if ($smtp->code == 220) {
 845                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 846                                                 or die "STARTTLS failed! ".$smtp->message;
 847                                         $smtp_encryption = '';
 848                                         # Send EHLO again to receive fresh
 849                                         # supported commands
 850                                         $smtp->hello();
 851                                 } else {
 852                                         die "Server does not support STARTTLS! ".$smtp->message;
 853                                 }
 854                         }
 855                 }
 856
 857                 if (!$smtp) {
 858                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 859                 }
 860
 861                 if (defined $smtp_authuser) {
 862
 863                         if (!defined $smtp_authpass) {
 864
 865                                 system "stty -echo";
 866
 867                                 do {
 868                                         print "Password: ";
 869                                         $_ = <STDIN>;
 870                                         print "\n";
 871                                 } while (!defined $_);
 872
 873                                 chomp($smtp_authpass = $_);
 874
 875                                 system "stty echo";
 876                         }
 877
 878                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 879                 }
 880
 881                 $smtp->mail( $raw_from ) or die $smtp->message;
 882                 $smtp->to( @recipients ) or die $smtp->message;
 883                 $smtp->data or die $smtp->message;
 884                 $smtp->datasend("$header\n$message") or die $smtp->message;
 885                 $smtp->dataend() or die $smtp->message;
 886                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 887         }
 888         if ($quiet) {
 889                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 890         } else {
 891                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 892                 if ($smtp_server !~ m#^/#) {
 893                         print "Server: $smtp_server\n";
 894                         print "MAIL FROM:<$raw_from>\n";
 895                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 896                 } else {
 897                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 898                 }
 899                 print $header, "\n";
 900                 if ($smtp) {
 901                         print "Result: ", $smtp->code, ' ',
 902                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 903                 } else {
 904                         print "Result: OK\n";
 905                 }
 906         }
 907 }
 908
 909 $reply_to = $initial_reply_to;
 910 $references = $initial_reply_to || '';
 911 $subject = $initial_subject;
 912
 913 foreach my $t (@files) {
 914         open(F,"<",$t) or die "can't open file $t";
 915
 916         my $author = undef;
 917         my $author_encoding;
 918         my $has_content_type;
 919         my $body_encoding;
 920         @cc = @initial_cc;
 921         @xh = ();
 922         my $input_format = undef;
 923         my $header_done = 0;
 924         $message = "";
 925         while(<F>) {
 926                 if (!$header_done) {
 927                         if (/^From /) {
 928                                 $input_format = 'mbox';
 929                                 next;
 930                         }
 931                         chomp;
 932                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 933                                 $input_format = 'mbox';
 934                         }
 935
 936                         if (defined $input_format && $input_format eq 'mbox') {
 937                                 if (/^Subject:\s+(.*)$/) {
 938                                         $subject = $1;
 939
 940                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 941                                         if (unquote_rfc2047($2) eq $sender) {
 942                                                 next if ($suppress_cc{'self'});
 943                                         }
 944                                         elsif ($1 eq 'From') {
 945                                                 ($author, $author_encoding)
 946                                                   = unquote_rfc2047($2);
 947                                                 next if ($suppress_cc{'author'});
 948                                         } else {
 949                                                 next if ($suppress_cc{'cc'});
 950                                         }
 951                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 952                                                 $2, $_) unless $quiet;
 953                                         push @cc, $2;
 954                                 }
 955                                 elsif (/^Content-type:/i) {
 956                                         $has_content_type = 1;
 957                                         if (/charset="?([^ "]+)/) {
 958                                                 $body_encoding = $1;
 959                                         }
 960                                         push @xh, $_;
 961                                 }
 962                                 elsif (/^Message-Id: (.*)/i) {
 963                                         $message_id = $1;
 964                                 }
 965                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 966                                         push @xh, $_;
 967                                 }
 968
 969                         } else {
 970                                 # In the traditional
 971                                 # "send lots of email" format,
 972                                 # line 1 = cc
 973                                 # line 2 = subject
 974                                 # So let's support that, too.
 975                                 $input_format = 'lots';
 976                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 977                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 978                                                 $_, $_) unless $quiet;
 979
 980                                         push @cc, $_;
 981
 982                                 } elsif (!defined $subject) {
 983                                         $subject = $_;
 984                                 }
 985                         }
 986
 987                         # A whitespace line will terminate the headers
 988                         if (m/^\s*$/) {
 989                                 $header_done = 1;
 990                         }
 991                 } else {
 992                         $message .=  $_;
 993                         if (/^(Signed-off-by|Cc): (.*)$/i) {
 994                                 next if ($suppress_cc{'sob'});
 995                                 chomp;
 996                                 my $c = $2;
 997                                 chomp $c;
 998                                 next if ($c eq $sender and $suppress_cc{'self'});
 999                                 push @cc, $c;
1000                                 printf("(sob) Adding cc: %s from line '%s'\n",
1001                                         $c, $_) unless $quiet;
1002                         }
1003                 }
1004         }
1005         close F;
1006
1007         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1008                 open(F, "$cc_cmd $t |")
1009                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1010                 while(<F>) {
1011                         my $c = $_;
1012                         $c =~ s/^\s*//g;
1013                         $c =~ s/\n$//g;
1014                         next if ($c eq $sender and $suppress_from);
1015                         push @cc, $c;
1016                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1017                                 $c, $cc_cmd) unless $quiet;
1018                 }
1019                 close F
1020                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1021         }
1022
1023         if (defined $author) {
1024                 $message = "From: $author\n\n$message";
1025                 if (defined $author_encoding) {
1026                         if ($has_content_type) {
1027                                 if ($body_encoding eq $author_encoding) {
1028                                         # ok, we already have the right encoding
1029                                 }
1030                                 else {
1031                                         # uh oh, we should re-encode
1032                                 }
1033                         }
1034                         else {
1035                                 push @xh,
1036                                   'MIME-Version: 1.0',
1037                                   "Content-Type: text/plain; charset=$author_encoding",
1038                                   'Content-Transfer-Encoding: 8bit';
1039                         }
1040                 }
1041         }
1042
1043         send_message();
1044
1045         # set up for the next message
1046         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
1047                 $reply_to = $message_id;
1048                 if (length $references > 0) {
1049                         $references .= "\n $message_id";
1050                 } else {
1051                         $references = "$message_id";
1052                 }
1053         }
1054         $message_id = undef;
1055 }
1056
1057 if ($compose) {
1058         cleanup_compose_files();
1059 }
1060
1061 sub cleanup_compose_files() {
1062         unlink($compose_filename, $compose_filename . ".final");
1063
1064 }
1065
1066 $smtp->quit if $smtp;
1067
1068 sub unique_email_list(@) {
1069         my %seen;
1070         my @emails;
1071
1072         foreach my $entry (@_) {
1073                 if (my $clean = extract_valid_address($entry)) {
1074                         $seen{$clean} ||= 0;
1075                         next if $seen{$clean}++;
1076                         push @emails, $entry;
1077                 } else {
1078                         print STDERR "W: unable to extract a valid address",
1079                                         " from: $entry\n";
1080                 }
1081         }
1082         return @emails;
1083 }
1084
1085 sub validate_patch {
1086         my $fn = shift;
1087         open(my $fh, '<', $fn)
1088                 or die "unable to open $fn: $!\n";
1089         while (my $line = <$fh>) {
1090                 if (length($line) > 998) {
1091                         return "$.: patch contains a line longer than 998 characters";
1092                 }
1093         }
1094         return undef;
1095 }
1096
1097 sub file_has_nonascii {
1098         my $fn = shift;
1099         open(my $fh, '<', $fn)
1100                 or die "unable to open $fn: $!\n";
1101         while (my $line = <$fh>) {
1102                 return 1 if $line =~ /[^[:ascii:]]/;
1103         }
1104         return 0;
1105 }