git.oblomov.eu Git - git/blob - gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 binmode STDOUT, ':utf8';
  21
  22 our $t0;
  23 if (eval { require Time::HiRes; 1; }) {
  24         $t0 = [Time::HiRes::gettimeofday()];
  25 }
  26 our $number_of_git_cmds = 0;
  27
  28 BEGIN {
  29         CGI->compile() if $ENV{'MOD_PERL'};
  30 }
  31
  32 our $version = "++GIT_VERSION++";
  33
  34 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  35 sub evaluate_uri {
  36         our $cgi;
  37
  38         our $my_url = $cgi->url();
  39         our $my_uri = $cgi->url(-absolute => 1);
  40
  41         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  42         # needed and used only for URLs with nonempty PATH_INFO
  43         our $base_url = $my_url;
  44
  45         # When the script is used as DirectoryIndex, the URL does not contain the name
  46         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  47         # have to do it ourselves. We make $path_info global because it's also used
  48         # later on.
  49         #
  50         # Another issue with the script being the DirectoryIndex is that the resulting
  51         # $my_url data is not the full script URL: this is good, because we want
  52         # generated links to keep implying the script name if it wasn't explicitly
  53         # indicated in the URL we're handling, but it means that $my_url cannot be used
  54         # as base URL.
  55         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  56         # to build the base URL ourselves:
  57         our $path_info = $ENV{"PATH_INFO"};
  58         if ($path_info) {
  59                 if ($my_url =~ s,\Q$path_info\E$,, &&
  60                     $my_uri =~ s,\Q$path_info\E$,, &&
  61                     defined $ENV{'SCRIPT_NAME'}) {
  62                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  63                 }
  64         }
  65
  66         # target of the home link on top of all pages
  67         our $home_link = $my_uri || "/";
  68 }
  69
  70 # core git executable to use
  71 # this can just be "git" if your webserver has a sensible PATH
  72 our $GIT = "++GIT_BINDIR++/git";
  73
  74 # absolute fs-path which will be prepended to the project path
  75 #our $projectroot = "/pub/scm";
  76 our $projectroot = "++GITWEB_PROJECTROOT++";
  77
  78 # fs traversing limit for getting project list
  79 # the number is relative to the projectroot
  80 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  81
  82 # string of the home link on top of all pages
  83 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  84
  85 # name of your site or organization to appear in page titles
  86 # replace this with something more descriptive for clearer bookmarks
  87 our $site_name = "++GITWEB_SITENAME++"
  88                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  89
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101 # URI of GIT logo (72x27 size)
 102 our $logo = "++GITWEB_LOGO++";
 103 # URI of GIT favicon, assumed to be image/png type
 104 our $favicon = "++GITWEB_FAVICON++";
 105 # URI of gitweb.js (JavaScript code for gitweb)
 106 our $javascript = "++GITWEB_JS++";
 107
 108 # URI and label (title) of GIT logo link
 109 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 110 #our $logo_label = "git documentation";
 111 our $logo_url = "http://git-scm.com/";
 112 our $logo_label = "git homepage";
 113
 114 # source of projects list
 115 our $projects_list = "++GITWEB_LIST++";
 116
 117 # the width (in characters) of the projects list "Description" column
 118 our $projects_list_description_width = 25;
 119
 120 # default order of projects list
 121 # valid values are none, project, descr, owner, and age
 122 our $default_projects_order = "project";
 123
 124 # show repository only if this file exists
 125 # (only effective if this variable evaluates to true)
 126 our $export_ok = "++GITWEB_EXPORT_OK++";
 127
 128 # show repository only if this subroutine returns true
 129 # when given the path to the project, for example:
 130 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 131 our $export_auth_hook = undef;
 132
 133 # only allow viewing of repositories also shown on the overview page
 134 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 135
 136 # list of git base URLs used for URL to where fetch project from,
 137 # i.e. full URL is "$git_base_url/$project"
 138 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 139
 140 # default blob_plain mimetype and default charset for text/plain blob
 141 our $default_blob_plain_mimetype = 'text/plain';
 142 our $default_text_plain_charset  = undef;
 143
 144 # file to use for guessing MIME types before trying /etc/mime.types
 145 # (relative to the current git repository)
 146 our $mimetypes_file = undef;
 147
 148 # assume this charset if line contains non-UTF-8 characters;
 149 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 150 # for which encoding all byte sequences are valid, for example
 151 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 152 # could be even 'utf-8' for the old behavior)
 153 our $fallback_encoding = 'latin1';
 154
 155 # rename detection options for git-diff and git-diff-tree
 156 # - default is '-M', with the cost proportional to
 157 #   (number of removed files) * (number of new files).
 158 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 159 #   (number of changed files + number of removed files) * (number of new files)
 160 # - even more costly is '-C', '--find-copies-harder' with cost
 161 #   (number of files in the original tree) * (number of new files)
 162 # - one might want to include '-B' option, e.g. '-B', '-M'
 163 our @diff_opts = ('-M'); # taken from git_commit
 164
 165 # Disables features that would allow repository owners to inject script into
 166 # the gitweb domain.
 167 our $prevent_xss = 0;
 168
 169 # information about snapshot formats that gitweb is capable of serving
 170 our %known_snapshot_formats = (
 171         # name => {
 172         #       'display' => display name,
 173         #       'type' => mime type,
 174         #       'suffix' => filename suffix,
 175         #       'format' => --format for git-archive,
 176         #       'compressor' => [compressor command and arguments]
 177         #                       (array reference, optional)
 178         #       'disabled' => boolean (optional)}
 179         #
 180         'tgz' => {
 181                 'display' => 'tar.gz',
 182                 'type' => 'application/x-gzip',
 183                 'suffix' => '.tar.gz',
 184                 'format' => 'tar',
 185                 'compressor' => ['gzip']},
 186
 187         'tbz2' => {
 188                 'display' => 'tar.bz2',
 189                 'type' => 'application/x-bzip2',
 190                 'suffix' => '.tar.bz2',
 191                 'format' => 'tar',
 192                 'compressor' => ['bzip2']},
 193
 194         'txz' => {
 195                 'display' => 'tar.xz',
 196                 'type' => 'application/x-xz',
 197                 'suffix' => '.tar.xz',
 198                 'format' => 'tar',
 199                 'compressor' => ['xz'],
 200                 'disabled' => 1},
 201
 202         'zip' => {
 203                 'display' => 'zip',
 204                 'type' => 'application/x-zip',
 205                 'suffix' => '.zip',
 206                 'format' => 'zip'},
 207 );
 208
 209 # Aliases so we understand old gitweb.snapshot values in repository
 210 # configuration.
 211 our %known_snapshot_format_aliases = (
 212         'gzip'  => 'tgz',
 213         'bzip2' => 'tbz2',
 214         'xz'    => 'txz',
 215
 216         # backward compatibility: legacy gitweb config support
 217         'x-gzip' => undef, 'gz' => undef,
 218         'x-bzip2' => undef, 'bz2' => undef,
 219         'x-zip' => undef, '' => undef,
 220 );
 221
 222 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 223 # are changed, it may be appropriate to change these values too via
 224 # $GITWEB_CONFIG.
 225 our %avatar_size = (
 226         'default' => 16,
 227         'double'  => 32
 228 );
 229
 230 # Used to set the maximum load that we will still respond to gitweb queries.
 231 # If server load exceed this value then return "503 server busy" error.
 232 # If gitweb cannot determined server load, it is taken to be 0.
 233 # Leave it undefined (or set to 'undef') to turn off load checking.
 234 our $maxload = 300;
 235
 236 # configuration for 'highlight' (http://www.andre-simon.de/)
 237 # match by basename
 238 our %highlight_basename = (
 239         #'Program' => 'py',
 240         #'Library' => 'py',
 241         'SConstruct' => 'py', # SCons equivalent of Makefile
 242         'Makefile' => 'make',
 243 );
 244 # match by extension
 245 our %highlight_ext = (
 246         # main extensions, defining name of syntax;
 247         # see files in /usr/share/highlight/langDefs/ directory
 248         map { $_ => $_ }
 249                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl),
 250         # alternate extensions, see /etc/highlight/filetypes.conf
 251         'h' => 'c',
 252         map { $_ => 'cpp' } qw(cxx c++ cc),
 253         map { $_ => 'php' } qw(php3 php4),
 254         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 255         'mak' => 'make',
 256         map { $_ => 'xml' } qw(xhtml html htm),
 257 );
 258
 259 # You define site-wide feature defaults here; override them with
 260 # $GITWEB_CONFIG as necessary.
 261 our %feature = (
 262         # feature => {
 263         #       'sub' => feature-sub (subroutine),
 264         #       'override' => allow-override (boolean),
 265         #       'default' => [ default options...] (array reference)}
 266         #
 267         # if feature is overridable (it means that allow-override has true value),
 268         # then feature-sub will be called with default options as parameters;
 269         # return value of feature-sub indicates if to enable specified feature
 270         #
 271         # if there is no 'sub' key (no feature-sub), then feature cannot be
 272         # overridden
 273         #
 274         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 275         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 276         # is enabled
 277
 278         # Enable the 'blame' blob view, showing the last commit that modified
 279         # each line in the file. This can be very CPU-intensive.
 280
 281         # To enable system wide have in $GITWEB_CONFIG
 282         # $feature{'blame'}{'default'} = [1];
 283         # To have project specific config enable override in $GITWEB_CONFIG
 284         # $feature{'blame'}{'override'} = 1;
 285         # and in project config gitweb.blame = 0|1;
 286         'blame' => {
 287                 'sub' => sub { feature_bool('blame', @_) },
 288                 'override' => 0,
 289                 'default' => [0]},
 290
 291         # Enable the 'snapshot' link, providing a compressed archive of any
 292         # tree. This can potentially generate high traffic if you have large
 293         # project.
 294
 295         # Value is a list of formats defined in %known_snapshot_formats that
 296         # you wish to offer.
 297         # To disable system wide have in $GITWEB_CONFIG
 298         # $feature{'snapshot'}{'default'} = [];
 299         # To have project specific config enable override in $GITWEB_CONFIG
 300         # $feature{'snapshot'}{'override'} = 1;
 301         # and in project config, a comma-separated list of formats or "none"
 302         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 303         'snapshot' => {
 304                 'sub' => \&feature_snapshot,
 305                 'override' => 0,
 306                 'default' => ['tgz']},
 307
 308         # Enable text search, which will list the commits which match author,
 309         # committer or commit text to a given string.  Enabled by default.
 310         # Project specific override is not supported.
 311         'search' => {
 312                 'override' => 0,
 313                 'default' => [1]},
 314
 315         # Enable grep search, which will list the files in currently selected
 316         # tree containing the given string. Enabled by default. This can be
 317         # potentially CPU-intensive, of course.
 318
 319         # To enable system wide have in $GITWEB_CONFIG
 320         # $feature{'grep'}{'default'} = [1];
 321         # To have project specific config enable override in $GITWEB_CONFIG
 322         # $feature{'grep'}{'override'} = 1;
 323         # and in project config gitweb.grep = 0|1;
 324         'grep' => {
 325                 'sub' => sub { feature_bool('grep', @_) },
 326                 'override' => 0,
 327                 'default' => [1]},
 328
 329         # Enable the pickaxe search, which will list the commits that modified
 330         # a given string in a file. This can be practical and quite faster
 331         # alternative to 'blame', but still potentially CPU-intensive.
 332
 333         # To enable system wide have in $GITWEB_CONFIG
 334         # $feature{'pickaxe'}{'default'} = [1];
 335         # To have project specific config enable override in $GITWEB_CONFIG
 336         # $feature{'pickaxe'}{'override'} = 1;
 337         # and in project config gitweb.pickaxe = 0|1;
 338         'pickaxe' => {
 339                 'sub' => sub { feature_bool('pickaxe', @_) },
 340                 'override' => 0,
 341                 'default' => [1]},
 342
 343         # Enable showing size of blobs in a 'tree' view, in a separate
 344         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 345
 346         # To disable system wide have in $GITWEB_CONFIG
 347         # $feature{'show-sizes'}{'default'} = [0];
 348         # To have project specific config enable override in $GITWEB_CONFIG
 349         # $feature{'show-sizes'}{'override'} = 1;
 350         # and in project config gitweb.showsizes = 0|1;
 351         'show-sizes' => {
 352                 'sub' => sub { feature_bool('showsizes', @_) },
 353                 'override' => 0,
 354                 'default' => [1]},
 355
 356         # Make gitweb use an alternative format of the URLs which can be
 357         # more readable and natural-looking: project name is embedded
 358         # directly in the path and the query string contains other
 359         # auxiliary information. All gitweb installations recognize
 360         # URL in either format; this configures in which formats gitweb
 361         # generates links.
 362
 363         # To enable system wide have in $GITWEB_CONFIG
 364         # $feature{'pathinfo'}{'default'} = [1];
 365         # Project specific override is not supported.
 366
 367         # Note that you will need to change the default location of CSS,
 368         # favicon, logo and possibly other files to an absolute URL. Also,
 369         # if gitweb.cgi serves as your indexfile, you will need to force
 370         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 371         'pathinfo' => {
 372                 'override' => 0,
 373                 'default' => [0]},
 374
 375         # Make gitweb consider projects in project root subdirectories
 376         # to be forks of existing projects. Given project $projname.git,
 377         # projects matching $projname/*.git will not be shown in the main
 378         # projects list, instead a '+' mark will be added to $projname
 379         # there and a 'forks' view will be enabled for the project, listing
 380         # all the forks. If project list is taken from a file, forks have
 381         # to be listed after the main project.
 382
 383         # To enable system wide have in $GITWEB_CONFIG
 384         # $feature{'forks'}{'default'} = [1];
 385         # Project specific override is not supported.
 386         'forks' => {
 387                 'override' => 0,
 388                 'default' => [0]},
 389
 390         # Insert custom links to the action bar of all project pages.
 391         # This enables you mainly to link to third-party scripts integrating
 392         # into gitweb; e.g. git-browser for graphical history representation
 393         # or custom web-based repository administration interface.
 394
 395         # The 'default' value consists of a list of triplets in the form
 396         # (label, link, position) where position is the label after which
 397         # to insert the link and link is a format string where %n expands
 398         # to the project name, %f to the project path within the filesystem,
 399         # %h to the current hash (h gitweb parameter) and %b to the current
 400         # hash base (hb gitweb parameter); %% expands to %.
 401
 402         # To enable system wide have in $GITWEB_CONFIG e.g.
 403         # $feature{'actions'}{'default'} = [('graphiclog',
 404         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 405         # Project specific override is not supported.
 406         'actions' => {
 407                 'override' => 0,
 408                 'default' => []},
 409
 410         # Allow gitweb scan project content tags described in ctags/
 411         # of project repository, and display the popular Web 2.0-ish
 412         # "tag cloud" near the project list. Note that this is something
 413         # COMPLETELY different from the normal Git tags.
 414
 415         # gitweb by itself can show existing tags, but it does not handle
 416         # tagging itself; you need an external application for that.
 417         # For an example script, check Girocco's cgi/tagproj.cgi.
 418         # You may want to install the HTML::TagCloud Perl module to get
 419         # a pretty tag cloud instead of just a list of tags.
 420
 421         # To enable system wide have in $GITWEB_CONFIG
 422         # $feature{'ctags'}{'default'} = ['path_to_tag_script'];
 423         # Project specific override is not supported.
 424         'ctags' => {
 425                 'override' => 0,
 426                 'default' => [0]},
 427
 428         # The maximum number of patches in a patchset generated in patch
 429         # view. Set this to 0 or undef to disable patch view, or to a
 430         # negative number to remove any limit.
 431
 432         # To disable system wide have in $GITWEB_CONFIG
 433         # $feature{'patches'}{'default'} = [0];
 434         # To have project specific config enable override in $GITWEB_CONFIG
 435         # $feature{'patches'}{'override'} = 1;
 436         # and in project config gitweb.patches = 0|n;
 437         # where n is the maximum number of patches allowed in a patchset.
 438         'patches' => {
 439                 'sub' => \&feature_patches,
 440                 'override' => 0,
 441                 'default' => [16]},
 442
 443         # Avatar support. When this feature is enabled, views such as
 444         # shortlog or commit will display an avatar associated with
 445         # the email of the committer(s) and/or author(s).
 446
 447         # Currently available providers are gravatar and picon.
 448         # If an unknown provider is specified, the feature is disabled.
 449
 450         # Gravatar depends on Digest::MD5.
 451         # Picon currently relies on the indiana.edu database.
 452
 453         # To enable system wide have in $GITWEB_CONFIG
 454         # $feature{'avatar'}{'default'} = ['<provider>'];
 455         # where <provider> is either gravatar or picon.
 456         # To have project specific config enable override in $GITWEB_CONFIG
 457         # $feature{'avatar'}{'override'} = 1;
 458         # and in project config gitweb.avatar = <provider>;
 459         'avatar' => {
 460                 'sub' => \&feature_avatar,
 461                 'override' => 0,
 462                 'default' => ['']},
 463
 464         # Enable displaying how much time and how many git commands
 465         # it took to generate and display page.  Disabled by default.
 466         # Project specific override is not supported.
 467         'timed' => {
 468                 'override' => 0,
 469                 'default' => [0]},
 470
 471         # Enable turning some links into links to actions which require
 472         # JavaScript to run (like 'blame_incremental').  Not enabled by
 473         # default.  Project specific override is currently not supported.
 474         'javascript-actions' => {
 475                 'override' => 0,
 476                 'default' => [0]},
 477
 478         # Syntax highlighting support. This is based on Daniel Svensson's
 479         # and Sham Chukoury's work in gitweb-xmms2.git.
 480         # It requires the 'highlight' program present in $PATH,
 481         # and therefore is disabled by default.
 482
 483         # To enable system wide have in $GITWEB_CONFIG
 484         # $feature{'highlight'}{'default'} = [1];
 485
 486         'highlight' => {
 487                 'sub' => sub { feature_bool('highlight', @_) },
 488                 'override' => 0,
 489                 'default' => [0]},
 490 );
 491
 492 sub gitweb_get_feature {
 493         my ($name) = @_;
 494         return unless exists $feature{$name};
 495         my ($sub, $override, @defaults) = (
 496                 $feature{$name}{'sub'},
 497                 $feature{$name}{'override'},
 498                 @{$feature{$name}{'default'}});
 499         # project specific override is possible only if we have project
 500         our $git_dir; # global variable, declared later
 501         if (!$override || !defined $git_dir) {
 502                 return @defaults;
 503         }
 504         if (!defined $sub) {
 505                 warn "feature $name is not overridable";
 506                 return @defaults;
 507         }
 508         return $sub->(@defaults);
 509 }
 510
 511 # A wrapper to check if a given feature is enabled.
 512 # With this, you can say
 513 #
 514 #   my $bool_feat = gitweb_check_feature('bool_feat');
 515 #   gitweb_check_feature('bool_feat') or somecode;
 516 #
 517 # instead of
 518 #
 519 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 520 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 521 #
 522 sub gitweb_check_feature {
 523         return (gitweb_get_feature(@_))[0];
 524 }
 525
 526
 527 sub feature_bool {
 528         my $key = shift;
 529         my ($val) = git_get_project_config($key, '--bool');
 530
 531         if (!defined $val) {
 532                 return ($_[0]);
 533         } elsif ($val eq 'true') {
 534                 return (1);
 535         } elsif ($val eq 'false') {
 536                 return (0);
 537         }
 538 }
 539
 540 sub feature_snapshot {
 541         my (@fmts) = @_;
 542
 543         my ($val) = git_get_project_config('snapshot');
 544
 545         if ($val) {
 546                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 547         }
 548
 549         return @fmts;
 550 }
 551
 552 sub feature_patches {
 553         my @val = (git_get_project_config('patches', '--int'));
 554
 555         if (@val) {
 556                 return @val;
 557         }
 558
 559         return ($_[0]);
 560 }
 561
 562 sub feature_avatar {
 563         my @val = (git_get_project_config('avatar'));
 564
 565         return @val ? @val : @_;
 566 }
 567
 568 # checking HEAD file with -e is fragile if the repository was
 569 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 570 # and then pruned.
 571 sub check_head_link {
 572         my ($dir) = @_;
 573         my $headfile = "$dir/HEAD";
 574         return ((-e $headfile) ||
 575                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 576 }
 577
 578 sub check_export_ok {
 579         my ($dir) = @_;
 580         return (check_head_link($dir) &&
 581                 (!$export_ok || -e "$dir/$export_ok") &&
 582                 (!$export_auth_hook || $export_auth_hook->($dir)));
 583 }
 584
 585 # process alternate names for backward compatibility
 586 # filter out unsupported (unknown) snapshot formats
 587 sub filter_snapshot_fmts {
 588         my @fmts = @_;
 589
 590         @fmts = map {
 591                 exists $known_snapshot_format_aliases{$_} ?
 592                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 593         @fmts = grep {
 594                 exists $known_snapshot_formats{$_} &&
 595                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 596 }
 597
 598 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM);
 599 sub evaluate_gitweb_config {
 600         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 601         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 602         # die if there are errors parsing config file
 603         if (-e $GITWEB_CONFIG) {
 604                 do $GITWEB_CONFIG;
 605                 die $@ if $@;
 606         } elsif (-e $GITWEB_CONFIG_SYSTEM) {
 607                 do $GITWEB_CONFIG_SYSTEM;
 608                 die $@ if $@;
 609         }
 610 }
 611
 612 # Get loadavg of system, to compare against $maxload.
 613 # Currently it requires '/proc/loadavg' present to get loadavg;
 614 # if it is not present it returns 0, which means no load checking.
 615 sub get_loadavg {
 616         if( -e '/proc/loadavg' ){
 617                 open my $fd, '<', '/proc/loadavg'
 618                         or return 0;
 619                 my @load = split(/\s+/, scalar <$fd>);
 620                 close $fd;
 621
 622                 # The first three columns measure CPU and IO utilization of the last one,
 623                 # five, and 10 minute periods.  The fourth column shows the number of
 624                 # currently running processes and the total number of processes in the m/n
 625                 # format.  The last column displays the last process ID used.
 626                 return $load[0] || 0;
 627         }
 628         # additional checks for load average should go here for things that don't export
 629         # /proc/loadavg
 630
 631         return 0;
 632 }
 633
 634 # version of the core git binary
 635 our $git_version;
 636 sub evaluate_git_version {
 637         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 638         $number_of_git_cmds++;
 639 }
 640
 641 sub check_loadavg {
 642         if (defined $maxload && get_loadavg() > $maxload) {
 643                 die_error(503, "The load average on the server is too high");
 644         }
 645 }
 646
 647 # ======================================================================
 648 # input validation and dispatch
 649
 650 # input parameters can be collected from a variety of sources (presently, CGI
 651 # and PATH_INFO), so we define an %input_params hash that collects them all
 652 # together during validation: this allows subsequent uses (e.g. href()) to be
 653 # agnostic of the parameter origin
 654
 655 our %input_params = ();
 656
 657 # input parameters are stored with the long parameter name as key. This will
 658 # also be used in the href subroutine to convert parameters to their CGI
 659 # equivalent, and since the href() usage is the most frequent one, we store
 660 # the name -> CGI key mapping here, instead of the reverse.
 661 #
 662 # XXX: Warning: If you touch this, check the search form for updating,
 663 # too.
 664
 665 our @cgi_param_mapping = (
 666         project => "p",
 667         action => "a",
 668         file_name => "f",
 669         file_parent => "fp",
 670         hash => "h",
 671         hash_parent => "hp",
 672         hash_base => "hb",
 673         hash_parent_base => "hpb",
 674         page => "pg",
 675         order => "o",
 676         searchtext => "s",
 677         searchtype => "st",
 678         snapshot_format => "sf",
 679         extra_options => "opt",
 680         search_use_regexp => "sr",
 681         # this must be last entry (for manipulation from JavaScript)
 682         javascript => "js"
 683 );
 684 our %cgi_param_mapping = @cgi_param_mapping;
 685
 686 # we will also need to know the possible actions, for validation
 687 our %actions = (
 688         "blame" => \&git_blame,
 689         "blame_incremental" => \&git_blame_incremental,
 690         "blame_data" => \&git_blame_data,
 691         "blobdiff" => \&git_blobdiff,
 692         "blobdiff_plain" => \&git_blobdiff_plain,
 693         "blob" => \&git_blob,
 694         "blob_plain" => \&git_blob_plain,
 695         "commitdiff" => \&git_commitdiff,
 696         "commitdiff_plain" => \&git_commitdiff_plain,
 697         "commit" => \&git_commit,
 698         "forks" => \&git_forks,
 699         "heads" => \&git_heads,
 700         "history" => \&git_history,
 701         "log" => \&git_log,
 702         "patch" => \&git_patch,
 703         "patches" => \&git_patches,
 704         "rss" => \&git_rss,
 705         "atom" => \&git_atom,
 706         "search" => \&git_search,
 707         "search_help" => \&git_search_help,
 708         "shortlog" => \&git_shortlog,
 709         "summary" => \&git_summary,
 710         "tag" => \&git_tag,
 711         "tags" => \&git_tags,
 712         "tree" => \&git_tree,
 713         "snapshot" => \&git_snapshot,
 714         "object" => \&git_object,
 715         # those below don't need $project
 716         "opml" => \&git_opml,
 717         "project_list" => \&git_project_list,
 718         "project_index" => \&git_project_index,
 719 );
 720
 721 # finally, we have the hash of allowed extra_options for the commands that
 722 # allow them
 723 our %allowed_options = (
 724         "--no-merges" => [ qw(rss atom log shortlog history) ],
 725 );
 726
 727 # fill %input_params with the CGI parameters. All values except for 'opt'
 728 # should be single values, but opt can be an array. We should probably
 729 # build an array of parameters that can be multi-valued, but since for the time
 730 # being it's only this one, we just single it out
 731 sub evaluate_query_params {
 732         our $cgi;
 733
 734         while (my ($name, $symbol) = each %cgi_param_mapping) {
 735                 if ($symbol eq 'opt') {
 736                         $input_params{$name} = [ $cgi->param($symbol) ];
 737                 } else {
 738                         $input_params{$name} = $cgi->param($symbol);
 739                 }
 740         }
 741 }
 742
 743 # now read PATH_INFO and update the parameter list for missing parameters
 744 sub evaluate_path_info {
 745         return if defined $input_params{'project'};
 746         return if !$path_info;
 747         $path_info =~ s,^/+,,;
 748         return if !$path_info;
 749
 750         # find which part of PATH_INFO is project
 751         my $project = $path_info;
 752         $project =~ s,/+$,,;
 753         while ($project && !check_head_link("$projectroot/$project")) {
 754                 $project =~ s,/*[^/]*$,,;
 755         }
 756         return unless $project;
 757         $input_params{'project'} = $project;
 758
 759         # do not change any parameters if an action is given using the query string
 760         return if $input_params{'action'};
 761         $path_info =~ s,^\Q$project\E/*,,;
 762
 763         # next, check if we have an action
 764         my $action = $path_info;
 765         $action =~ s,/.*$,,;
 766         if (exists $actions{$action}) {
 767                 $path_info =~ s,^$action/*,,;
 768                 $input_params{'action'} = $action;
 769         }
 770
 771         # list of actions that want hash_base instead of hash, but can have no
 772         # pathname (f) parameter
 773         my @wants_base = (
 774                 'tree',
 775                 'history',
 776         );
 777
 778         # we want to catch
 779         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 780         my ($parentrefname, $parentpathname, $refname, $pathname) =
 781                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?(.+?)(?::(.+))?$/);
 782
 783         # first, analyze the 'current' part
 784         if (defined $pathname) {
 785                 # we got "branch:filename" or "branch:dir/"
 786                 # we could use git_get_type(branch:pathname), but:
 787                 # - it needs $git_dir
 788                 # - it does a git() call
 789                 # - the convention of terminating directories with a slash
 790                 #   makes it superfluous
 791                 # - embedding the action in the PATH_INFO would make it even
 792                 #   more superfluous
 793                 $pathname =~ s,^/+,,;
 794                 if (!$pathname || substr($pathname, -1) eq "/") {
 795                         $input_params{'action'} ||= "tree";
 796                         $pathname =~ s,/$,,;
 797                 } else {
 798                         # the default action depends on whether we had parent info
 799                         # or not
 800                         if ($parentrefname) {
 801                                 $input_params{'action'} ||= "blobdiff_plain";
 802                         } else {
 803                                 $input_params{'action'} ||= "blob_plain";
 804                         }
 805                 }
 806                 $input_params{'hash_base'} ||= $refname;
 807                 $input_params{'file_name'} ||= $pathname;
 808         } elsif (defined $refname) {
 809                 # we got "branch". In this case we have to choose if we have to
 810                 # set hash or hash_base.
 811                 #
 812                 # Most of the actions without a pathname only want hash to be
 813                 # set, except for the ones specified in @wants_base that want
 814                 # hash_base instead. It should also be noted that hand-crafted
 815                 # links having 'history' as an action and no pathname or hash
 816                 # set will fail, but that happens regardless of PATH_INFO.
 817                 $input_params{'action'} ||= "shortlog";
 818                 if (grep { $_ eq $input_params{'action'} } @wants_base) {
 819                         $input_params{'hash_base'} ||= $refname;
 820                 } else {
 821                         $input_params{'hash'} ||= $refname;
 822                 }
 823         }
 824
 825         # next, handle the 'parent' part, if present
 826         if (defined $parentrefname) {
 827                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 828                 # someproject/blobdiff/oldrev..newrev:/filename
 829                 if ($parentpathname) {
 830                         $parentpathname =~ s,^/+,,;
 831                         $parentpathname =~ s,/$,,;
 832                         $input_params{'file_parent'} ||= $parentpathname;
 833                 } else {
 834                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 835                 }
 836                 # we assume that hash_parent_base is wanted if a path was specified,
 837                 # or if the action wants hash_base instead of hash
 838                 if (defined $input_params{'file_parent'} ||
 839                         grep { $_ eq $input_params{'action'} } @wants_base) {
 840                         $input_params{'hash_parent_base'} ||= $parentrefname;
 841                 } else {
 842                         $input_params{'hash_parent'} ||= $parentrefname;
 843                 }
 844         }
 845
 846         # for the snapshot action, we allow URLs in the form
 847         # $project/snapshot/$hash.ext
 848         # where .ext determines the snapshot and gets removed from the
 849         # passed $refname to provide the $hash.
 850         #
 851         # To be able to tell that $refname includes the format extension, we
 852         # require the following two conditions to be satisfied:
 853         # - the hash input parameter MUST have been set from the $refname part
 854         #   of the URL (i.e. they must be equal)
 855         # - the snapshot format MUST NOT have been defined already (e.g. from
 856         #   CGI parameter sf)
 857         # It's also useless to try any matching unless $refname has a dot,
 858         # so we check for that too
 859         if (defined $input_params{'action'} &&
 860                 $input_params{'action'} eq 'snapshot' &&
 861                 defined $refname && index($refname, '.') != -1 &&
 862                 $refname eq $input_params{'hash'} &&
 863                 !defined $input_params{'snapshot_format'}) {
 864                 # We loop over the known snapshot formats, checking for
 865                 # extensions. Allowed extensions are both the defined suffix
 866                 # (which includes the initial dot already) and the snapshot
 867                 # format key itself, with a prepended dot
 868                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 869                         my $hash = $refname;
 870                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 871                                 next;
 872                         }
 873                         my $sfx = $1;
 874                         # a valid suffix was found, so set the snapshot format
 875                         # and reset the hash parameter
 876                         $input_params{'snapshot_format'} = $fmt;
 877                         $input_params{'hash'} = $hash;
 878                         # we also set the format suffix to the one requested
 879                         # in the URL: this way a request for e.g. .tgz returns
 880                         # a .tgz instead of a .tar.gz
 881                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 882                         last;
 883                 }
 884         }
 885 }
 886
 887 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 888      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 889      $searchtext, $search_regexp);
 890 sub evaluate_and_validate_params {
 891         our $action = $input_params{'action'};
 892         if (defined $action) {
 893                 if (!validate_action($action)) {
 894                         die_error(400, "Invalid action parameter");
 895                 }
 896         }
 897
 898         # parameters which are pathnames
 899         our $project = $input_params{'project'};
 900         if (defined $project) {
 901                 if (!validate_project($project)) {
 902                         undef $project;
 903                         die_error(404, "No such project");
 904                 }
 905         }
 906
 907         our $file_name = $input_params{'file_name'};
 908         if (defined $file_name) {
 909                 if (!validate_pathname($file_name)) {
 910                         die_error(400, "Invalid file parameter");
 911                 }
 912         }
 913
 914         our $file_parent = $input_params{'file_parent'};
 915         if (defined $file_parent) {
 916                 if (!validate_pathname($file_parent)) {
 917                         die_error(400, "Invalid file parent parameter");
 918                 }
 919         }
 920
 921         # parameters which are refnames
 922         our $hash = $input_params{'hash'};
 923         if (defined $hash) {
 924                 if (!validate_refname($hash)) {
 925                         die_error(400, "Invalid hash parameter");
 926                 }
 927         }
 928
 929         our $hash_parent = $input_params{'hash_parent'};
 930         if (defined $hash_parent) {
 931                 if (!validate_refname($hash_parent)) {
 932                         die_error(400, "Invalid hash parent parameter");
 933                 }
 934         }
 935
 936         our $hash_base = $input_params{'hash_base'};
 937         if (defined $hash_base) {
 938                 if (!validate_refname($hash_base)) {
 939                         die_error(400, "Invalid hash base parameter");
 940                 }
 941         }
 942
 943         our @extra_options = @{$input_params{'extra_options'}};
 944         # @extra_options is always defined, since it can only be (currently) set from
 945         # CGI, and $cgi->param() returns the empty array in array context if the param
 946         # is not set
 947         foreach my $opt (@extra_options) {
 948                 if (not exists $allowed_options{$opt}) {
 949                         die_error(400, "Invalid option parameter");
 950                 }
 951                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
 952                         die_error(400, "Invalid option parameter for this action");
 953                 }
 954         }
 955
 956         our $hash_parent_base = $input_params{'hash_parent_base'};
 957         if (defined $hash_parent_base) {
 958                 if (!validate_refname($hash_parent_base)) {
 959                         die_error(400, "Invalid hash parent base parameter");
 960                 }
 961         }
 962
 963         # other parameters
 964         our $page = $input_params{'page'};
 965         if (defined $page) {
 966                 if ($page =~ m/[^0-9]/) {
 967                         die_error(400, "Invalid page parameter");
 968                 }
 969         }
 970
 971         our $searchtype = $input_params{'searchtype'};
 972         if (defined $searchtype) {
 973                 if ($searchtype =~ m/[^a-z]/) {
 974                         die_error(400, "Invalid searchtype parameter");
 975                 }
 976         }
 977
 978         our $search_use_regexp = $input_params{'search_use_regexp'};
 979
 980         our $searchtext = $input_params{'searchtext'};
 981         our $search_regexp;
 982         if (defined $searchtext) {
 983                 if (length($searchtext) < 2) {
 984                         die_error(403, "At least two characters are required for search parameter");
 985                 }
 986                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
 987         }
 988 }
 989
 990 # path to the current git repository
 991 our $git_dir;
 992 sub evaluate_git_dir {
 993         our $git_dir = "$projectroot/$project" if $project;
 994 }
 995
 996 our (@snapshot_fmts, $git_avatar);
 997 sub configure_gitweb_features {
 998         # list of supported snapshot formats
 999         our @snapshot_fmts = gitweb_get_feature('snapshot');
1000         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1001
1002         # check that the avatar feature is set to a known provider name,
1003         # and for each provider check if the dependencies are satisfied.
1004         # if the provider name is invalid or the dependencies are not met,
1005         # reset $git_avatar to the empty string.
1006         our ($git_avatar) = gitweb_get_feature('avatar');
1007         if ($git_avatar eq 'gravatar') {
1008                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1009         } elsif ($git_avatar eq 'picon') {
1010                 # no dependencies
1011         } else {
1012                 $git_avatar = '';
1013         }
1014 }
1015
1016 # custom error handler: 'die <message>' is Internal Server Error
1017 sub handle_errors_html {
1018         my $msg = shift; # it is already HTML escaped
1019
1020         # to avoid infinite loop where error occurs in die_error,
1021         # change handler to default handler, disabling handle_errors_html
1022         set_message("Error occured when inside die_error:\n$msg");
1023
1024         # you cannot jump out of die_error when called as error handler;
1025         # the subroutine set via CGI::Carp::set_message is called _after_
1026         # HTTP headers are already written, so it cannot write them itself
1027         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1028 }
1029 set_message(\&handle_errors_html);
1030
1031 # dispatch
1032 sub dispatch {
1033         if (!defined $action) {
1034                 if (defined $hash) {
1035                         $action = git_get_type($hash);
1036                 } elsif (defined $hash_base && defined $file_name) {
1037                         $action = git_get_type("$hash_base:$file_name");
1038                 } elsif (defined $project) {
1039                         $action = 'summary';
1040                 } else {
1041                         $action = 'project_list';
1042                 }
1043         }
1044         if (!defined($actions{$action})) {
1045                 die_error(400, "Unknown action");
1046         }
1047         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1048             !$project) {
1049                 die_error(400, "Project needed");
1050         }
1051         $actions{$action}->();
1052 }
1053
1054 sub reset_timer {
1055         our $t0 = [Time::HiRes::gettimeofday()]
1056                 if defined $t0;
1057         our $number_of_git_cmds = 0;
1058 }
1059
1060 sub run_request {
1061         reset_timer();
1062
1063         evaluate_uri();
1064         evaluate_gitweb_config();
1065         check_loadavg();
1066
1067         # $projectroot and $projects_list might be set in gitweb config file
1068         $projects_list ||= $projectroot;
1069
1070         evaluate_query_params();
1071         evaluate_path_info();
1072         evaluate_and_validate_params();
1073         evaluate_git_dir();
1074
1075         configure_gitweb_features();
1076
1077         dispatch();
1078 }
1079
1080 our $is_last_request = sub { 1 };
1081 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1082 our $CGI = 'CGI';
1083 our $cgi;
1084 sub configure_as_fcgi {
1085         require CGI::Fast;
1086         our $CGI = 'CGI::Fast';
1087
1088         my $request_number = 0;
1089         # let each child service 100 requests
1090         our $is_last_request = sub { ++$request_number > 100 };
1091 }
1092 sub evaluate_argv {
1093         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1094         configure_as_fcgi()
1095                 if $script_name =~ /\.fcgi$/;
1096
1097         return unless (@ARGV);
1098
1099         require Getopt::Long;
1100         Getopt::Long::GetOptions(
1101                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1102                 'nproc|n=i' => sub {
1103                         my ($arg, $val) = @_;
1104                         return unless eval { require FCGI::ProcManager; 1; };
1105                         my $proc_manager = FCGI::ProcManager->new({
1106                                 n_processes => $val,
1107                         });
1108                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1109                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1110                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1111                 },
1112         );
1113 }
1114
1115 sub run {
1116         evaluate_argv();
1117         evaluate_git_version();
1118
1119         $pre_listen_hook->()
1120                 if $pre_listen_hook;
1121
1122  REQUEST:
1123         while ($cgi = $CGI->new()) {
1124                 $pre_dispatch_hook->()
1125                         if $pre_dispatch_hook;
1126
1127                 run_request();
1128
1129                 $post_dispatch_hook->()
1130                         if $post_dispatch_hook;
1131
1132                 last REQUEST if ($is_last_request->());
1133         }
1134
1135  DONE_GITWEB:
1136         1;
1137 }
1138
1139 run();
1140
1141 if (defined caller) {
1142         # wrapped in a subroutine processing requests,
1143         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1144         return;
1145 } else {
1146         # pure CGI script, serving single request
1147         exit;
1148 }
1149
1150 ## ======================================================================
1151 ## action links
1152
1153 # possible values of extra options
1154 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1155 # -replay => 1      - start from a current view (replay with modifications)
1156 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1157 sub href {
1158         my %params = @_;
1159         # default is to use -absolute url() i.e. $my_uri
1160         my $href = $params{-full} ? $my_url : $my_uri;
1161
1162         $params{'project'} = $project unless exists $params{'project'};
1163
1164         if ($params{-replay}) {
1165                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1166                         if (!exists $params{$name}) {
1167                                 $params{$name} = $input_params{$name};
1168                         }
1169                 }
1170         }
1171
1172         my $use_pathinfo = gitweb_check_feature('pathinfo');
1173         if (defined $params{'project'} &&
1174             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1175                 # try to put as many parameters as possible in PATH_INFO:
1176                 #   - project name
1177                 #   - action
1178                 #   - hash_parent or hash_parent_base:/file_parent
1179                 #   - hash or hash_base:/filename
1180                 #   - the snapshot_format as an appropriate suffix
1181
1182                 # When the script is the root DirectoryIndex for the domain,
1183                 # $href here would be something like http://gitweb.example.com/
1184                 # Thus, we strip any trailing / from $href, to spare us double
1185                 # slashes in the final URL
1186                 $href =~ s,/$,,;
1187
1188                 # Then add the project name, if present
1189                 $href .= "/".esc_path_info($params{'project'});
1190                 delete $params{'project'};
1191
1192                 # since we destructively absorb parameters, we keep this
1193                 # boolean that remembers if we're handling a snapshot
1194                 my $is_snapshot = $params{'action'} eq 'snapshot';
1195
1196                 # Summary just uses the project path URL, any other action is
1197                 # added to the URL
1198                 if (defined $params{'action'}) {
1199                         $href .= "/".esc_path_info($params{'action'})
1200                                 unless $params{'action'} eq 'summary';
1201                         delete $params{'action'};
1202                 }
1203
1204                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1205                 # stripping nonexistent or useless pieces
1206                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1207                         || $params{'hash_parent'} || $params{'hash'});
1208                 if (defined $params{'hash_base'}) {
1209                         if (defined $params{'hash_parent_base'}) {
1210                                 $href .= esc_path_info($params{'hash_parent_base'});
1211                                 # skip the file_parent if it's the same as the file_name
1212                                 if (defined $params{'file_parent'}) {
1213                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1214                                                 delete $params{'file_parent'};
1215                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1216                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1217                                                 delete $params{'file_parent'};
1218                                         }
1219                                 }
1220                                 $href .= "..";
1221                                 delete $params{'hash_parent'};
1222                                 delete $params{'hash_parent_base'};
1223                         } elsif (defined $params{'hash_parent'}) {
1224                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1225                                 delete $params{'hash_parent'};
1226                         }
1227
1228                         $href .= esc_path_info($params{'hash_base'});
1229                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1230                                 $href .= ":/".esc_path_info($params{'file_name'});
1231                                 delete $params{'file_name'};
1232                         }
1233                         delete $params{'hash'};
1234                         delete $params{'hash_base'};
1235                 } elsif (defined $params{'hash'}) {
1236                         $href .= esc_path_info($params{'hash'});
1237                         delete $params{'hash'};
1238                 }
1239
1240                 # If the action was a snapshot, we can absorb the
1241                 # snapshot_format parameter too
1242                 if ($is_snapshot) {
1243                         my $fmt = $params{'snapshot_format'};
1244                         # snapshot_format should always be defined when href()
1245                         # is called, but just in case some code forgets, we
1246                         # fall back to the default
1247                         $fmt ||= $snapshot_fmts[0];
1248                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1249                         delete $params{'snapshot_format'};
1250                 }
1251         }
1252
1253         # now encode the parameters explicitly
1254         my @result = ();
1255         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1256                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1257                 if (defined $params{$name}) {
1258                         if (ref($params{$name}) eq "ARRAY") {
1259                                 foreach my $par (@{$params{$name}}) {
1260                                         push @result, $symbol . "=" . esc_param($par);
1261                                 }
1262                         } else {
1263                                 push @result, $symbol . "=" . esc_param($params{$name});
1264                         }
1265                 }
1266         }
1267         $href .= "?" . join(';', @result) if scalar @result;
1268
1269         # final transformation: trailing spaces must be escaped (URI-encoded)
1270         $href =~ s/(\s+)$/CGI::escape($1)/e;
1271
1272         return $href;
1273 }
1274
1275
1276 ## ======================================================================
1277 ## validation, quoting/unquoting and escaping
1278
1279 sub validate_action {
1280         my $input = shift || return undef;
1281         return undef unless exists $actions{$input};
1282         return $input;
1283 }
1284
1285 sub validate_project {
1286         my $input = shift || return undef;
1287         if (!validate_pathname($input) ||
1288                 !(-d "$projectroot/$input") ||
1289                 !check_export_ok("$projectroot/$input") ||
1290                 ($strict_export && !project_in_list($input))) {
1291                 return undef;
1292         } else {
1293                 return $input;
1294         }
1295 }
1296
1297 sub validate_pathname {
1298         my $input = shift || return undef;
1299
1300         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1301         # at the beginning, at the end, and between slashes.
1302         # also this catches doubled slashes
1303         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1304                 return undef;
1305         }
1306         # no null characters
1307         if ($input =~ m!\0!) {
1308                 return undef;
1309         }
1310         return $input;
1311 }
1312
1313 sub validate_refname {
1314         my $input = shift || return undef;
1315
1316         # textual hashes are O.K.
1317         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1318                 return $input;
1319         }
1320         # it must be correct pathname
1321         $input = validate_pathname($input)
1322                 or return undef;
1323         # restrictions on ref name according to git-check-ref-format
1324         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1325                 return undef;
1326         }
1327         return $input;
1328 }
1329
1330 # decode sequences of octets in utf8 into Perl's internal form,
1331 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1332 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1333 sub to_utf8 {
1334         my $str = shift;
1335         return undef unless defined $str;
1336         if (utf8::valid($str)) {
1337                 utf8::decode($str);
1338                 return $str;
1339         } else {
1340                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1341         }
1342 }
1343
1344 # quote unsafe chars, but keep the slash, even when it's not
1345 # correct, but quoted slashes look too horrible in bookmarks
1346 sub esc_param {
1347         my $str = shift;
1348         return undef unless defined $str;
1349         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1350         $str =~ s/ /\+/g;
1351         return $str;
1352 }
1353
1354 # the quoting rules for path_info fragment are slightly different
1355 sub esc_path_info {
1356         my $str = shift;
1357         return undef unless defined $str;
1358
1359         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1360         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1361
1362         return $str;
1363 }
1364
1365 # quote unsafe chars in whole URL, so some characters cannot be quoted
1366 sub esc_url {
1367         my $str = shift;
1368         return undef unless defined $str;
1369         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1370         $str =~ s/ /\+/g;
1371         return $str;
1372 }
1373
1374 # replace invalid utf8 character with SUBSTITUTION sequence
1375 sub esc_html {
1376         my $str = shift;
1377         my %opts = @_;
1378
1379         return undef unless defined $str;
1380
1381         $str = to_utf8($str);
1382         $str = $cgi->escapeHTML($str);
1383         if ($opts{'-nbsp'}) {
1384                 $str =~ s/ /&nbsp;/g;
1385         }
1386         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1387         return $str;
1388 }
1389
1390 # quote control characters and escape filename to HTML
1391 sub esc_path {
1392         my $str = shift;
1393         my %opts = @_;
1394
1395         return undef unless defined $str;
1396
1397         $str = to_utf8($str);
1398         $str = $cgi->escapeHTML($str);
1399         if ($opts{'-nbsp'}) {
1400                 $str =~ s/ /&nbsp;/g;
1401         }
1402         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1403         return $str;
1404 }
1405
1406 # Make control characters "printable", using character escape codes (CEC)
1407 sub quot_cec {
1408         my $cntrl = shift;
1409         my %opts = @_;
1410         my %es = ( # character escape codes, aka escape sequences
1411                 "\t" => '\t',   # tab            (HT)
1412                 "\n" => '\n',   # line feed      (LF)
1413                 "\r" => '\r',   # carrige return (CR)
1414                 "\f" => '\f',   # form feed      (FF)
1415                 "\b" => '\b',   # backspace      (BS)
1416                 "\a" => '\a',   # alarm (bell)   (BEL)
1417                 "\e" => '\e',   # escape         (ESC)
1418                 "\013" => '\v', # vertical tab   (VT)
1419                 "\000" => '\0', # nul character  (NUL)
1420         );
1421         my $chr = ( (exists $es{$cntrl})
1422                     ? $es{$cntrl}
1423                     : sprintf('\%2x', ord($cntrl)) );
1424         if ($opts{-nohtml}) {
1425                 return $chr;
1426         } else {
1427                 return "<span class=\"cntrl\">$chr</span>";
1428         }
1429 }
1430
1431 # Alternatively use unicode control pictures codepoints,
1432 # Unicode "printable representation" (PR)
1433 sub quot_upr {
1434         my $cntrl = shift;
1435         my %opts = @_;
1436
1437         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1438         if ($opts{-nohtml}) {
1439                 return $chr;
1440         } else {
1441                 return "<span class=\"cntrl\">$chr</span>";
1442         }
1443 }
1444
1445 # git may return quoted and escaped filenames
1446 sub unquote {
1447         my $str = shift;
1448
1449         sub unq {
1450                 my $seq = shift;
1451                 my %es = ( # character escape codes, aka escape sequences
1452                         't' => "\t",   # tab            (HT, TAB)
1453                         'n' => "\n",   # newline        (NL)
1454                         'r' => "\r",   # return         (CR)
1455                         'f' => "\f",   # form feed      (FF)
1456                         'b' => "\b",   # backspace      (BS)
1457                         'a' => "\a",   # alarm (bell)   (BEL)
1458                         'e' => "\e",   # escape         (ESC)
1459                         'v' => "\013", # vertical tab   (VT)
1460                 );
1461
1462                 if ($seq =~ m/^[0-7]{1,3}$/) {
1463                         # octal char sequence
1464                         return chr(oct($seq));
1465                 } elsif (exists $es{$seq}) {
1466                         # C escape sequence, aka character escape code
1467                         return $es{$seq};
1468                 }
1469                 # quoted ordinary character
1470                 return $seq;
1471         }
1472
1473         if ($str =~ m/^"(.*)"$/) {
1474                 # needs unquoting
1475                 $str = $1;
1476                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1477         }
1478         return $str;
1479 }
1480
1481 # escape tabs (convert tabs to spaces)
1482 sub untabify {
1483         my $line = shift;
1484
1485         while ((my $pos = index($line, "\t")) != -1) {
1486                 if (my $count = (8 - ($pos % 8))) {
1487                         my $spaces = ' ' x $count;
1488                         $line =~ s/\t/$spaces/;
1489                 }
1490         }
1491
1492         return $line;
1493 }
1494
1495 sub project_in_list {
1496         my $project = shift;
1497         my @list = git_get_projects_list();
1498         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1499 }
1500
1501 ## ----------------------------------------------------------------------
1502 ## HTML aware string manipulation
1503
1504 # Try to chop given string on a word boundary between position
1505 # $len and $len+$add_len. If there is no word boundary there,
1506 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1507 # (marking chopped part) would be longer than given string.
1508 sub chop_str {
1509         my $str = shift;
1510         my $len = shift;
1511         my $add_len = shift || 10;
1512         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1513
1514         # Make sure perl knows it is utf8 encoded so we don't
1515         # cut in the middle of a utf8 multibyte char.
1516         $str = to_utf8($str);
1517
1518         # allow only $len chars, but don't cut a word if it would fit in $add_len
1519         # if it doesn't fit, cut it if it's still longer than the dots we would add
1520         # remove chopped character entities entirely
1521
1522         # when chopping in the middle, distribute $len into left and right part
1523         # return early if chopping wouldn't make string shorter
1524         if ($where eq 'center') {
1525                 return $str if ($len + 5 >= length($str)); # filler is length 5
1526                 $len = int($len/2);
1527         } else {
1528                 return $str if ($len + 4 >= length($str)); # filler is length 4
1529         }
1530
1531         # regexps: ending and beginning with word part up to $add_len
1532         my $endre = qr/.{$len}\w{0,$add_len}/;
1533         my $begre = qr/\w{0,$add_len}.{$len}/;
1534
1535         if ($where eq 'left') {
1536                 $str =~ m/^(.*?)($begre)$/;
1537                 my ($lead, $body) = ($1, $2);
1538                 if (length($lead) > 4) {
1539                         $lead = " ...";
1540                 }
1541                 return "$lead$body";
1542
1543         } elsif ($where eq 'center') {
1544                 $str =~ m/^($endre)(.*)$/;
1545                 my ($left, $str)  = ($1, $2);
1546                 $str =~ m/^(.*?)($begre)$/;
1547                 my ($mid, $right) = ($1, $2);
1548                 if (length($mid) > 5) {
1549                         $mid = " ... ";
1550                 }
1551                 return "$left$mid$right";
1552
1553         } else {
1554                 $str =~ m/^($endre)(.*)$/;
1555                 my $body = $1;
1556                 my $tail = $2;
1557                 if (length($tail) > 4) {
1558                         $tail = "... ";
1559                 }
1560                 return "$body$tail";
1561         }
1562 }
1563
1564 # takes the same arguments as chop_str, but also wraps a <span> around the
1565 # result with a title attribute if it does get chopped. Additionally, the
1566 # string is HTML-escaped.
1567 sub chop_and_escape_str {
1568         my ($str) = @_;
1569
1570         my $chopped = chop_str(@_);
1571         if ($chopped eq $str) {
1572                 return esc_html($chopped);
1573         } else {
1574                 $str =~ s/[[:cntrl:]]/?/g;
1575                 return $cgi->span({-title=>$str}, esc_html($chopped));
1576         }
1577 }
1578
1579 ## ----------------------------------------------------------------------
1580 ## functions returning short strings
1581
1582 # CSS class for given age value (in seconds)
1583 sub age_class {
1584         my $age = shift;
1585
1586         if (!defined $age) {
1587                 return "noage";
1588         } elsif ($age < 60*60*2) {
1589                 return "age0";
1590         } elsif ($age < 60*60*24*2) {
1591                 return "age1";
1592         } else {
1593                 return "age2";
1594         }
1595 }
1596
1597 # convert age in seconds to "nn units ago" string
1598 sub age_string {
1599         my $age = shift;
1600         my $age_str;
1601
1602         if ($age > 60*60*24*365*2) {
1603                 $age_str = (int $age/60/60/24/365);
1604                 $age_str .= " years ago";
1605         } elsif ($age > 60*60*24*(365/12)*2) {
1606                 $age_str = int $age/60/60/24/(365/12);
1607                 $age_str .= " months ago";
1608         } elsif ($age > 60*60*24*7*2) {
1609                 $age_str = int $age/60/60/24/7;
1610                 $age_str .= " weeks ago";
1611         } elsif ($age > 60*60*24*2) {
1612                 $age_str = int $age/60/60/24;
1613                 $age_str .= " days ago";
1614         } elsif ($age > 60*60*2) {
1615                 $age_str = int $age/60/60;
1616                 $age_str .= " hours ago";
1617         } elsif ($age > 60*2) {
1618                 $age_str = int $age/60;
1619                 $age_str .= " min ago";
1620         } elsif ($age > 2) {
1621                 $age_str = int $age;
1622                 $age_str .= " sec ago";
1623         } else {
1624                 $age_str .= " right now";
1625         }
1626         return $age_str;
1627 }
1628
1629 use constant {
1630         S_IFINVALID => 0030000,
1631         S_IFGITLINK => 0160000,
1632 };
1633
1634 # submodule/subproject, a commit object reference
1635 sub S_ISGITLINK {
1636         my $mode = shift;
1637
1638         return (($mode & S_IFMT) == S_IFGITLINK)
1639 }
1640
1641 # convert file mode in octal to symbolic file mode string
1642 sub mode_str {
1643         my $mode = oct shift;
1644
1645         if (S_ISGITLINK($mode)) {
1646                 return 'm---------';
1647         } elsif (S_ISDIR($mode & S_IFMT)) {
1648                 return 'drwxr-xr-x';
1649         } elsif (S_ISLNK($mode)) {
1650                 return 'lrwxrwxrwx';
1651         } elsif (S_ISREG($mode)) {
1652                 # git cares only about the executable bit
1653                 if ($mode & S_IXUSR) {
1654                         return '-rwxr-xr-x';
1655                 } else {
1656                         return '-rw-r--r--';
1657                 };
1658         } else {
1659                 return '----------';
1660         }
1661 }
1662
1663 # convert file mode in octal to file type string
1664 sub file_type {
1665         my $mode = shift;
1666
1667         if ($mode !~ m/^[0-7]+$/) {
1668                 return $mode;
1669         } else {
1670                 $mode = oct $mode;
1671         }
1672
1673         if (S_ISGITLINK($mode)) {
1674                 return "submodule";
1675         } elsif (S_ISDIR($mode & S_IFMT)) {
1676                 return "directory";
1677         } elsif (S_ISLNK($mode)) {
1678                 return "symlink";
1679         } elsif (S_ISREG($mode)) {
1680                 return "file";
1681         } else {
1682                 return "unknown";
1683         }
1684 }
1685
1686 # convert file mode in octal to file type description string
1687 sub file_type_long {
1688         my $mode = shift;
1689
1690         if ($mode !~ m/^[0-7]+$/) {
1691                 return $mode;
1692         } else {
1693                 $mode = oct $mode;
1694         }
1695
1696         if (S_ISGITLINK($mode)) {
1697                 return "submodule";
1698         } elsif (S_ISDIR($mode & S_IFMT)) {
1699                 return "directory";
1700         } elsif (S_ISLNK($mode)) {
1701                 return "symlink";
1702         } elsif (S_ISREG($mode)) {
1703                 if ($mode & S_IXUSR) {
1704                         return "executable";
1705                 } else {
1706                         return "file";
1707                 };
1708         } else {
1709                 return "unknown";
1710         }
1711 }
1712
1713
1714 ## ----------------------------------------------------------------------
1715 ## functions returning short HTML fragments, or transforming HTML fragments
1716 ## which don't belong to other sections
1717
1718 # format line of commit message.
1719 sub format_log_line_html {
1720         my $line = shift;
1721
1722         $line = esc_html($line, -nbsp=>1);
1723         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1724                 $cgi->a({-href => href(action=>"object", hash=>$1),
1725                                         -class => "text"}, $1);
1726         }eg;
1727
1728         return $line;
1729 }
1730
1731 # format marker of refs pointing to given object
1732
1733 # the destination action is chosen based on object type and current context:
1734 # - for annotated tags, we choose the tag view unless it's the current view
1735 #   already, in which case we go to shortlog view
1736 # - for other refs, we keep the current view if we're in history, shortlog or
1737 #   log view, and select shortlog otherwise
1738 sub format_ref_marker {
1739         my ($refs, $id) = @_;
1740         my $markers = '';
1741
1742         if (defined $refs->{$id}) {
1743                 foreach my $ref (@{$refs->{$id}}) {
1744                         # this code exploits the fact that non-lightweight tags are the
1745                         # only indirect objects, and that they are the only objects for which
1746                         # we want to use tag instead of shortlog as action
1747                         my ($type, $name) = qw();
1748                         my $indirect = ($ref =~ s/\^\{\}$//);
1749                         # e.g. tags/v2.6.11 or heads/next
1750                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1751                                 $type = $1;
1752                                 $name = $2;
1753                         } else {
1754                                 $type = "ref";
1755                                 $name = $ref;
1756                         }
1757
1758                         my $class = $type;
1759                         $class .= " indirect" if $indirect;
1760
1761                         my $dest_action = "shortlog";
1762
1763                         if ($indirect) {
1764                                 $dest_action = "tag" unless $action eq "tag";
1765                         } elsif ($action =~ /^(history|(short)?log)$/) {
1766                                 $dest_action = $action;
1767                         }
1768
1769                         my $dest = "";
1770                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1771                         $dest .= $ref;
1772
1773                         my $link = $cgi->a({
1774                                 -href => href(
1775                                         action=>$dest_action,
1776                                         hash=>$dest
1777                                 )}, $name);
1778
1779                         $markers .= " <span class=\"$class\" title=\"$ref\">" .
1780                                 $link . "</span>";
1781                 }
1782         }
1783
1784         if ($markers) {
1785                 return ' <span class="refs">'. $markers . '</span>';
1786         } else {
1787                 return "";
1788         }
1789 }
1790
1791 # format, perhaps shortened and with markers, title line
1792 sub format_subject_html {
1793         my ($long, $short, $href, $extra) = @_;
1794         $extra = '' unless defined($extra);
1795
1796         if (length($short) < length($long)) {
1797                 $long =~ s/[[:cntrl:]]/?/g;
1798                 return $cgi->a({-href => $href, -class => "list subject",
1799                                 -title => to_utf8($long)},
1800                        esc_html($short)) . $extra;
1801         } else {
1802                 return $cgi->a({-href => $href, -class => "list subject"},
1803                        esc_html($long)) . $extra;
1804         }
1805 }
1806
1807 # Rather than recomputing the url for an email multiple times, we cache it
1808 # after the first hit. This gives a visible benefit in views where the avatar
1809 # for the same email is used repeatedly (e.g. shortlog).
1810 # The cache is shared by all avatar engines (currently gravatar only), which
1811 # are free to use it as preferred. Since only one avatar engine is used for any
1812 # given page, there's no risk for cache conflicts.
1813 our %avatar_cache = ();
1814
1815 # Compute the picon url for a given email, by using the picon search service over at
1816 # http://www.cs.indiana.edu/picons/search.html
1817 sub picon_url {
1818         my $email = lc shift;
1819         if (!$avatar_cache{$email}) {
1820                 my ($user, $domain) = split('@', $email);
1821                 $avatar_cache{$email} =
1822                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1823                         "$domain/$user/" .
1824                         "users+domains+unknown/up/single";
1825         }
1826         return $avatar_cache{$email};
1827 }
1828
1829 # Compute the gravatar url for a given email, if it's not in the cache already.
1830 # Gravatar stores only the part of the URL before the size, since that's the
1831 # one computationally more expensive. This also allows reuse of the cache for
1832 # different sizes (for this particular engine).
1833 sub gravatar_url {
1834         my $email = lc shift;
1835         my $size = shift;
1836         $avatar_cache{$email} ||=
1837                 "http://www.gravatar.com/avatar/" .
1838                         Digest::MD5::md5_hex($email) . "?s=";
1839         return $avatar_cache{$email} . $size;
1840 }
1841
1842 # Insert an avatar for the given $email at the given $size if the feature
1843 # is enabled.
1844 sub git_get_avatar {
1845         my ($email, %opts) = @_;
1846         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1847         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1848         $opts{-size} ||= 'default';
1849         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1850         my $url = "";
1851         if ($git_avatar eq 'gravatar') {
1852                 $url = gravatar_url($email, $size);
1853         } elsif ($git_avatar eq 'picon') {
1854                 $url = picon_url($email);
1855         }
1856         # Other providers can be added by extending the if chain, defining $url
1857         # as needed. If no variant puts something in $url, we assume avatars
1858         # are completely disabled/unavailable.
1859         if ($url) {
1860                 return $pre_white .
1861                        "<img width=\"$size\" " .
1862                             "class=\"avatar\" " .
1863                             "src=\"$url\" " .
1864                             "alt=\"\" " .
1865                        "/>" . $post_white;
1866         } else {
1867                 return "";
1868         }
1869 }
1870
1871 sub format_search_author {
1872         my ($author, $searchtype, $displaytext) = @_;
1873         my $have_search = gitweb_check_feature('search');
1874
1875         if ($have_search) {
1876                 my $performed = "";
1877                 if ($searchtype eq 'author') {
1878                         $performed = "authored";
1879                 } elsif ($searchtype eq 'committer') {
1880                         $performed = "committed";
1881                 }
1882
1883                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
1884                                 searchtext=>$author,
1885                                 searchtype=>$searchtype), class=>"list",
1886                                 title=>"Search for commits $performed by $author"},
1887                                 $displaytext);
1888
1889         } else {
1890                 return $displaytext;
1891         }
1892 }
1893
1894 # format the author name of the given commit with the given tag
1895 # the author name is chopped and escaped according to the other
1896 # optional parameters (see chop_str).
1897 sub format_author_html {
1898         my $tag = shift;
1899         my $co = shift;
1900         my $author = chop_and_escape_str($co->{'author_name'}, @_);
1901         return "<$tag class=\"author\">" .
1902                format_search_author($co->{'author_name'}, "author",
1903                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
1904                        $author) .
1905                "</$tag>";
1906 }
1907
1908 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
1909 sub format_git_diff_header_line {
1910         my $line = shift;
1911         my $diffinfo = shift;
1912         my ($from, $to) = @_;
1913
1914         if ($diffinfo->{'nparents'}) {
1915                 # combined diff
1916                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
1917                 if ($to->{'href'}) {
1918                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1919                                          esc_path($to->{'file'}));
1920                 } else { # file was deleted (no href)
1921                         $line .= esc_path($to->{'file'});
1922                 }
1923         } else {
1924                 # "ordinary" diff
1925                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
1926                 if ($from->{'href'}) {
1927                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
1928                                          'a/' . esc_path($from->{'file'}));
1929                 } else { # file was added (no href)
1930                         $line .= 'a/' . esc_path($from->{'file'});
1931                 }
1932                 $line .= ' ';
1933                 if ($to->{'href'}) {
1934                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1935                                          'b/' . esc_path($to->{'file'}));
1936                 } else { # file was deleted
1937                         $line .= 'b/' . esc_path($to->{'file'});
1938                 }
1939         }
1940
1941         return "<div class=\"diff header\">$line</div>\n";
1942 }
1943
1944 # format extended diff header line, before patch itself
1945 sub format_extended_diff_header_line {
1946         my $line = shift;
1947         my $diffinfo = shift;
1948         my ($from, $to) = @_;
1949
1950         # match <path>
1951         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
1952                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
1953                                        esc_path($from->{'file'}));
1954         }
1955         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
1956                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
1957                                  esc_path($to->{'file'}));
1958         }
1959         # match single <mode>
1960         if ($line =~ m/\s(\d{6})$/) {
1961                 $line .= '<span class="info"> (' .
1962                          file_type_long($1) .
1963                          ')</span>';
1964         }
1965         # match <hash>
1966         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
1967                 # can match only for combined diff
1968                 $line = 'index ';
1969                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
1970                         if ($from->{'href'}[$i]) {
1971                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
1972                                                   -class=>"hash"},
1973                                                  substr($diffinfo->{'from_id'}[$i],0,7));
1974                         } else {
1975                                 $line .= '0' x 7;
1976                         }
1977                         # separator
1978                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
1979                 }
1980                 $line .= '..';
1981                 if ($to->{'href'}) {
1982                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
1983                                          substr($diffinfo->{'to_id'},0,7));
1984                 } else {
1985                         $line .= '0' x 7;
1986                 }
1987
1988         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
1989                 # can match only for ordinary diff
1990                 my ($from_link, $to_link);
1991                 if ($from->{'href'}) {
1992                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
1993                                              substr($diffinfo->{'from_id'},0,7));
1994                 } else {
1995                         $from_link = '0' x 7;
1996                 }
1997                 if ($to->{'href'}) {
1998                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
1999                                            substr($diffinfo->{'to_id'},0,7));
2000                 } else {
2001                         $to_link = '0' x 7;
2002                 }
2003                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2004                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2005         }
2006
2007         return $line . "<br/>\n";
2008 }
2009
2010 # format from-file/to-file diff header
2011 sub format_diff_from_to_header {
2012         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2013         my $line;
2014         my $result = '';
2015
2016         $line = $from_line;
2017         #assert($line =~ m/^---/) if DEBUG;
2018         # no extra formatting for "^--- /dev/null"
2019         if (! $diffinfo->{'nparents'}) {
2020                 # ordinary (single parent) diff
2021                 if ($line =~ m!^--- "?a/!) {
2022                         if ($from->{'href'}) {
2023                                 $line = '--- a/' .
2024                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2025                                                 esc_path($from->{'file'}));
2026                         } else {
2027                                 $line = '--- a/' .
2028                                         esc_path($from->{'file'});
2029                         }
2030                 }
2031                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2032
2033         } else {
2034                 # combined diff (merge commit)
2035                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2036                         if ($from->{'href'}[$i]) {
2037                                 $line = '--- ' .
2038                                         $cgi->a({-href=>href(action=>"blobdiff",
2039                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2040                                                              hash_parent_base=>$parents[$i],
2041                                                              file_parent=>$from->{'file'}[$i],
2042                                                              hash=>$diffinfo->{'to_id'},
2043                                                              hash_base=>$hash,
2044                                                              file_name=>$to->{'file'}),
2045                                                  -class=>"path",
2046                                                  -title=>"diff" . ($i+1)},
2047                                                 $i+1) .
2048                                         '/' .
2049                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2050                                                 esc_path($from->{'file'}[$i]));
2051                         } else {
2052                                 $line = '--- /dev/null';
2053                         }
2054                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2055                 }
2056         }
2057
2058         $line = $to_line;
2059         #assert($line =~ m/^\+\+\+/) if DEBUG;
2060         # no extra formatting for "^+++ /dev/null"
2061         if ($line =~ m!^\+\+\+ "?b/!) {
2062                 if ($to->{'href'}) {
2063                         $line = '+++ b/' .
2064                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2065                                         esc_path($to->{'file'}));
2066                 } else {
2067                         $line = '+++ b/' .
2068                                 esc_path($to->{'file'});
2069                 }
2070         }
2071         $result .= qq!<div class="diff to_file">$line</div>\n!;
2072
2073         return $result;
2074 }
2075
2076 # create note for patch simplified by combined diff
2077 sub format_diff_cc_simplified {
2078         my ($diffinfo, @parents) = @_;
2079         my $result = '';
2080
2081         $result .= "<div class=\"diff header\">" .
2082                    "diff --cc ";
2083         if (!is_deleted($diffinfo)) {
2084                 $result .= $cgi->a({-href => href(action=>"blob",
2085                                                   hash_base=>$hash,
2086                                                   hash=>$diffinfo->{'to_id'},
2087                                                   file_name=>$diffinfo->{'to_file'}),
2088                                     -class => "path"},
2089                                    esc_path($diffinfo->{'to_file'}));
2090         } else {
2091                 $result .= esc_path($diffinfo->{'to_file'});
2092         }
2093         $result .= "</div>\n" . # class="diff header"
2094                    "<div class=\"diff nodifferences\">" .
2095                    "Simple merge" .
2096                    "</div>\n"; # class="diff nodifferences"
2097
2098         return $result;
2099 }
2100
2101 # format patch (diff) line (not to be used for diff headers)
2102 sub format_diff_line {
2103         my $line = shift;
2104         my ($from, $to) = @_;
2105         my $diff_class = "";
2106
2107         chomp $line;
2108
2109         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2110                 # combined diff
2111                 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
2112                 if ($line =~ m/^\@{3}/) {
2113                         $diff_class = " chunk_header";
2114                 } elsif ($line =~ m/^\\/) {
2115                         $diff_class = " incomplete";
2116                 } elsif ($prefix =~ tr/+/+/) {
2117                         $diff_class = " add";
2118                 } elsif ($prefix =~ tr/-/-/) {
2119                         $diff_class = " rem";
2120                 }
2121         } else {
2122                 # assume ordinary diff
2123                 my $char = substr($line, 0, 1);
2124                 if ($char eq '+') {
2125                         $diff_class = " add";
2126                 } elsif ($char eq '-') {
2127                         $diff_class = " rem";
2128                 } elsif ($char eq '@') {
2129                         $diff_class = " chunk_header";
2130                 } elsif ($char eq "\\") {
2131                         $diff_class = " incomplete";
2132                 }
2133         }
2134         $line = untabify($line);
2135         if ($from && $to && $line =~ m/^\@{2} /) {
2136                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2137                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2138
2139                 $from_lines = 0 unless defined $from_lines;
2140                 $to_lines   = 0 unless defined $to_lines;
2141
2142                 if ($from->{'href'}) {
2143                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2144                                              -class=>"list"}, $from_text);
2145                 }
2146                 if ($to->{'href'}) {
2147                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2148                                              -class=>"list"}, $to_text);
2149                 }
2150                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2151                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2152                 return "<div class=\"diff$diff_class\">$line</div>\n";
2153         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2154                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2155                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2156
2157                 @from_text = split(' ', $ranges);
2158                 for (my $i = 0; $i < @from_text; ++$i) {
2159                         ($from_start[$i], $from_nlines[$i]) =
2160                                 (split(',', substr($from_text[$i], 1)), 0);
2161                 }
2162
2163                 $to_text   = pop @from_text;
2164                 $to_start  = pop @from_start;
2165                 $to_nlines = pop @from_nlines;
2166
2167                 $line = "<span class=\"chunk_info\">$prefix ";
2168                 for (my $i = 0; $i < @from_text; ++$i) {
2169                         if ($from->{'href'}[$i]) {
2170                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2171                                                   -class=>"list"}, $from_text[$i]);
2172                         } else {
2173                                 $line .= $from_text[$i];
2174                         }
2175                         $line .= " ";
2176                 }
2177                 if ($to->{'href'}) {
2178                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2179                                           -class=>"list"}, $to_text);
2180                 } else {
2181                         $line .= $to_text;
2182                 }
2183                 $line .= " $prefix</span>" .
2184                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2185                 return "<div class=\"diff$diff_class\">$line</div>\n";
2186         }
2187         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2188 }
2189
2190 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2191 # linked.  Pass the hash of the tree/commit to snapshot.
2192 sub format_snapshot_links {
2193         my ($hash) = @_;
2194         my $num_fmts = @snapshot_fmts;
2195         if ($num_fmts > 1) {
2196                 # A parenthesized list of links bearing format names.
2197                 # e.g. "snapshot (_tar.gz_ _zip_)"
2198                 return "snapshot (" . join(' ', map
2199                         $cgi->a({
2200                                 -href => href(
2201                                         action=>"snapshot",
2202                                         hash=>$hash,
2203                                         snapshot_format=>$_
2204                                 )
2205                         }, $known_snapshot_formats{$_}{'display'})
2206                 , @snapshot_fmts) . ")";
2207         } elsif ($num_fmts == 1) {
2208                 # A single "snapshot" link whose tooltip bears the format name.
2209                 # i.e. "_snapshot_"
2210                 my ($fmt) = @snapshot_fmts;
2211                 return
2212                         $cgi->a({
2213                                 -href => href(
2214                                         action=>"snapshot",
2215                                         hash=>$hash,
2216                                         snapshot_format=>$fmt
2217                                 ),
2218                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2219                         }, "snapshot");
2220         } else { # $num_fmts == 0
2221                 return undef;
2222         }
2223 }
2224
2225 ## ......................................................................
2226 ## functions returning values to be passed, perhaps after some
2227 ## transformation, to other functions; e.g. returning arguments to href()
2228
2229 # returns hash to be passed to href to generate gitweb URL
2230 # in -title key it returns description of link
2231 sub get_feed_info {
2232         my $format = shift || 'Atom';
2233         my %res = (action => lc($format));
2234
2235         # feed links are possible only for project views
2236         return unless (defined $project);
2237         # some views should link to OPML, or to generic project feed,
2238         # or don't have specific feed yet (so they should use generic)
2239         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2240
2241         my $branch;
2242         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2243         # from tag links; this also makes possible to detect branch links
2244         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2245             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2246                 $branch = $1;
2247         }
2248         # find log type for feed description (title)
2249         my $type = 'log';
2250         if (defined $file_name) {
2251                 $type  = "history of $file_name";
2252                 $type .= "/" if ($action eq 'tree');
2253                 $type .= " on '$branch'" if (defined $branch);
2254         } else {
2255                 $type = "log of $branch" if (defined $branch);
2256         }
2257
2258         $res{-title} = $type;
2259         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2260         $res{'file_name'} = $file_name;
2261
2262         return %res;
2263 }
2264
2265 ## ----------------------------------------------------------------------
2266 ## git utility subroutines, invoking git commands
2267
2268 # returns path to the core git executable and the --git-dir parameter as list
2269 sub git_cmd {
2270         $number_of_git_cmds++;
2271         return $GIT, '--git-dir='.$git_dir;
2272 }
2273
2274 # quote the given arguments for passing them to the shell
2275 # quote_command("command", "arg 1", "arg with ' and ! characters")
2276 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2277 # Try to avoid using this function wherever possible.
2278 sub quote_command {
2279         return join(' ',
2280                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2281 }
2282
2283 # get HEAD ref of given project as hash
2284 sub git_get_head_hash {
2285         return git_get_full_hash(shift, 'HEAD');
2286 }
2287
2288 sub git_get_full_hash {
2289         return git_get_hash(@_);
2290 }
2291
2292 sub git_get_short_hash {
2293         return git_get_hash(@_, '--short=7');
2294 }
2295
2296 sub git_get_hash {
2297         my ($project, $hash, @options) = @_;
2298         my $o_git_dir = $git_dir;
2299         my $retval = undef;
2300         $git_dir = "$projectroot/$project";
2301         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2302             '--verify', '-q', @options, $hash) {
2303                 $retval = <$fd>;
2304                 chomp $retval if defined $retval;
2305                 close $fd;
2306         }
2307         if (defined $o_git_dir) {
2308                 $git_dir = $o_git_dir;
2309         }
2310         return $retval;
2311 }
2312
2313 # get type of given object
2314 sub git_get_type {
2315         my $hash = shift;
2316
2317         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2318         my $type = <$fd>;
2319         close $fd or return;
2320         chomp $type;
2321         return $type;
2322 }
2323
2324 # repository configuration
2325 our $config_file = '';
2326 our %config;
2327
2328 # store multiple values for single key as anonymous array reference
2329 # single values stored directly in the hash, not as [ <value> ]
2330 sub hash_set_multi {
2331         my ($hash, $key, $value) = @_;
2332
2333         if (!exists $hash->{$key}) {
2334                 $hash->{$key} = $value;
2335         } elsif (!ref $hash->{$key}) {
2336                 $hash->{$key} = [ $hash->{$key}, $value ];
2337         } else {
2338                 push @{$hash->{$key}}, $value;
2339         }
2340 }
2341
2342 # return hash of git project configuration
2343 # optionally limited to some section, e.g. 'gitweb'
2344 sub git_parse_project_config {
2345         my $section_regexp = shift;
2346         my %config;
2347
2348         local $/ = "\0";
2349
2350         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2351                 or return;
2352
2353         while (my $keyval = <$fh>) {
2354                 chomp $keyval;
2355                 my ($key, $value) = split(/\n/, $keyval, 2);
2356
2357                 hash_set_multi(\%config, $key, $value)
2358                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2359         }
2360         close $fh;
2361
2362         return %config;
2363 }
2364
2365 # convert config value to boolean: 'true' or 'false'
2366 # no value, number > 0, 'true' and 'yes' values are true
2367 # rest of values are treated as false (never as error)
2368 sub config_to_bool {
2369         my $val = shift;
2370
2371         return 1 if !defined $val;             # section.key
2372
2373         # strip leading and trailing whitespace
2374         $val =~ s/^\s+//;
2375         $val =~ s/\s+$//;
2376
2377         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2378                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2379 }
2380
2381 # convert config value to simple decimal number
2382 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2383 # to be multiplied by 1024, 1048576, or 1073741824
2384 sub config_to_int {
2385         my $val = shift;
2386
2387         # strip leading and trailing whitespace
2388         $val =~ s/^\s+//;
2389         $val =~ s/\s+$//;
2390
2391         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2392                 $unit = lc($unit);
2393                 # unknown unit is treated as 1
2394                 return $num * ($unit eq 'g' ? 1073741824 :
2395                                $unit eq 'm' ?    1048576 :
2396                                $unit eq 'k' ?       1024 : 1);
2397         }
2398         return $val;
2399 }
2400
2401 # convert config value to array reference, if needed
2402 sub config_to_multi {
2403         my $val = shift;
2404
2405         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2406 }
2407
2408 sub git_get_project_config {
2409         my ($key, $type) = @_;
2410
2411         return unless defined $git_dir;
2412
2413         # key sanity check
2414         return unless ($key);
2415         $key =~ s/^gitweb\.//;
2416         return if ($key =~ m/\W/);
2417
2418         # type sanity check
2419         if (defined $type) {
2420                 $type =~ s/^--//;
2421                 $type = undef
2422                         unless ($type eq 'bool' || $type eq 'int');
2423         }
2424
2425         # get config
2426         if (!defined $config_file ||
2427             $config_file ne "$git_dir/config") {
2428                 %config = git_parse_project_config('gitweb');
2429                 $config_file = "$git_dir/config";
2430         }
2431
2432         # check if config variable (key) exists
2433         return unless exists $config{"gitweb.$key"};
2434
2435         # ensure given type
2436         if (!defined $type) {
2437                 return $config{"gitweb.$key"};
2438         } elsif ($type eq 'bool') {
2439                 # backward compatibility: 'git config --bool' returns true/false
2440                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2441         } elsif ($type eq 'int') {
2442                 return config_to_int($config{"gitweb.$key"});
2443         }
2444         return $config{"gitweb.$key"};
2445 }
2446
2447 # get hash of given path at given ref
2448 sub git_get_hash_by_path {
2449         my $base = shift;
2450         my $path = shift || return undef;
2451         my $type = shift;
2452
2453         $path =~ s,/+$,,;
2454
2455         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2456                 or die_error(500, "Open git-ls-tree failed");
2457         my $line = <$fd>;
2458         close $fd or return undef;
2459
2460         if (!defined $line) {
2461                 # there is no tree or hash given by $path at $base
2462                 return undef;
2463         }
2464
2465         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2466         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2467         if (defined $type && $type ne $2) {
2468                 # type doesn't match
2469                 return undef;
2470         }
2471         return $3;
2472 }
2473
2474 # get path of entry with given hash at given tree-ish (ref)
2475 # used to get 'from' filename for combined diff (merge commit) for renames
2476 sub git_get_path_by_hash {
2477         my $base = shift || return;
2478         my $hash = shift || return;
2479
2480         local $/ = "\0";
2481
2482         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2483                 or return undef;
2484         while (my $line = <$fd>) {
2485                 chomp $line;
2486
2487                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2488                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2489                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2490                         close $fd;
2491                         return $1;
2492                 }
2493         }
2494         close $fd;
2495         return undef;
2496 }
2497
2498 ## ......................................................................
2499 ## git utility functions, directly accessing git repository
2500
2501 sub git_get_project_description {
2502         my $path = shift;
2503
2504         $git_dir = "$projectroot/$path";
2505         open my $fd, '<', "$git_dir/description"
2506                 or return git_get_project_config('description');
2507         my $descr = <$fd>;
2508         close $fd;
2509         if (defined $descr) {
2510                 chomp $descr;
2511         }
2512         return $descr;
2513 }
2514
2515 sub git_get_project_ctags {
2516         my $path = shift;
2517         my $ctags = {};
2518
2519         $git_dir = "$projectroot/$path";
2520         opendir my $dh, "$git_dir/ctags"
2521                 or return $ctags;
2522         foreach (grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh)) {
2523                 open my $ct, '<', $_ or next;
2524                 my $val = <$ct>;
2525                 chomp $val;
2526                 close $ct;
2527                 my $ctag = $_; $ctag =~ s#.*/##;
2528                 $ctags->{$ctag} = $val;
2529         }
2530         closedir $dh;
2531         $ctags;
2532 }
2533
2534 sub git_populate_project_tagcloud {
2535         my $ctags = shift;
2536
2537         # First, merge different-cased tags; tags vote on casing
2538         my %ctags_lc;
2539         foreach (keys %$ctags) {
2540                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2541                 if (not $ctags_lc{lc $_}->{topcount}
2542                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2543                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2544                         $ctags_lc{lc $_}->{topname} = $_;
2545                 }
2546         }
2547
2548         my $cloud;
2549         if (eval { require HTML::TagCloud; 1; }) {
2550                 $cloud = HTML::TagCloud->new;
2551                 foreach (sort keys %ctags_lc) {
2552                         # Pad the title with spaces so that the cloud looks
2553                         # less crammed.
2554                         my $title = $ctags_lc{$_}->{topname};
2555                         $title =~ s/ /&nbsp;/g;
2556                         $title =~ s/^/&nbsp;/g;
2557                         $title =~ s/$/&nbsp;/g;
2558                         $cloud->add($title, $home_link."?by_tag=".$_, $ctags_lc{$_}->{count});
2559                 }
2560         } else {
2561                 $cloud = \%ctags_lc;
2562         }
2563         $cloud;
2564 }
2565
2566 sub git_show_project_tagcloud {
2567         my ($cloud, $count) = @_;
2568         print STDERR ref($cloud)."..\n";
2569         if (ref $cloud eq 'HTML::TagCloud') {
2570                 return $cloud->html_and_css($count);
2571         } else {
2572                 my @tags = sort { $cloud->{$a}->{count} <=> $cloud->{$b}->{count} } keys %$cloud;
2573                 return '<p align="center">' . join (', ', map {
2574                         "<a href=\"$home_link?by_tag=$_\">$cloud->{$_}->{topname}</a>"
2575                 } splice(@tags, 0, $count)) . '</p>';
2576         }
2577 }
2578
2579 sub git_get_project_url_list {
2580         my $path = shift;
2581
2582         $git_dir = "$projectroot/$path";
2583         open my $fd, '<', "$git_dir/cloneurl"
2584                 or return wantarray ?
2585                 @{ config_to_multi(git_get_project_config('url')) } :
2586                    config_to_multi(git_get_project_config('url'));
2587         my @git_project_url_list = map { chomp; $_ } <$fd>;
2588         close $fd;
2589
2590         return wantarray ? @git_project_url_list : \@git_project_url_list;
2591 }
2592
2593 sub git_get_projects_list {
2594         my ($filter) = @_;
2595         my @list;
2596
2597         $filter ||= '';
2598         $filter =~ s/\.git$//;
2599
2600         my $check_forks = gitweb_check_feature('forks');
2601
2602         if (-d $projects_list) {
2603                 # search in directory
2604                 my $dir = $projects_list . ($filter ? "/$filter" : '');
2605                 # remove the trailing "/"
2606                 $dir =~ s!/+$!!;
2607                 my $pfxlen = length("$dir");
2608                 my $pfxdepth = ($dir =~ tr!/!!);
2609
2610                 File::Find::find({
2611                         follow_fast => 1, # follow symbolic links
2612                         follow_skip => 2, # ignore duplicates
2613                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2614                         wanted => sub {
2615                                 # global variables
2616                                 our $project_maxdepth;
2617                                 our $projectroot;
2618                                 # skip project-list toplevel, if we get it.
2619                                 return if (m!^[/.]$!);
2620                                 # only directories can be git repositories
2621                                 return unless (-d $_);
2622                                 # don't traverse too deep (Find is super slow on os x)
2623                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2624                                         $File::Find::prune = 1;
2625                                         return;
2626                                 }
2627
2628                                 my $subdir = substr($File::Find::name, $pfxlen + 1);
2629                                 # we check related file in $projectroot
2630                                 my $path = ($filter ? "$filter/" : '') . $subdir;
2631                                 if (check_export_ok("$projectroot/$path")) {
2632                                         push @list, { path => $path };
2633                                         $File::Find::prune = 1;
2634                                 }
2635                         },
2636                 }, "$dir");
2637
2638         } elsif (-f $projects_list) {
2639                 # read from file(url-encoded):
2640                 # 'git%2Fgit.git Linus+Torvalds'
2641                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2642                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2643                 my %paths;
2644                 open my $fd, '<', $projects_list or return;
2645         PROJECT:
2646                 while (my $line = <$fd>) {
2647                         chomp $line;
2648                         my ($path, $owner) = split ' ', $line;
2649                         $path = unescape($path);
2650                         $owner = unescape($owner);
2651                         if (!defined $path) {
2652                                 next;
2653                         }
2654                         if ($filter ne '') {
2655                                 # looking for forks;
2656                                 my $pfx = substr($path, 0, length($filter));
2657                                 if ($pfx ne $filter) {
2658                                         next PROJECT;
2659                                 }
2660                                 my $sfx = substr($path, length($filter));
2661                                 if ($sfx !~ /^\/.*\.git$/) {
2662                                         next PROJECT;
2663                                 }
2664                         } elsif ($check_forks) {
2665                         PATH:
2666                                 foreach my $filter (keys %paths) {
2667                                         # looking for forks;
2668                                         my $pfx = substr($path, 0, length($filter));
2669                                         if ($pfx ne $filter) {
2670                                                 next PATH;
2671                                         }
2672                                         my $sfx = substr($path, length($filter));
2673                                         if ($sfx !~ /^\/.*\.git$/) {
2674                                                 next PATH;
2675                                         }
2676                                         # is a fork, don't include it in
2677                                         # the list
2678                                         next PROJECT;
2679                                 }
2680                         }
2681                         if (check_export_ok("$projectroot/$path")) {
2682                                 my $pr = {
2683                                         path => $path,
2684                                         owner => to_utf8($owner),
2685                                 };
2686                                 push @list, $pr;
2687                                 (my $forks_path = $path) =~ s/\.git$//;
2688                                 $paths{$forks_path}++;
2689                         }
2690                 }
2691                 close $fd;
2692         }
2693         return @list;
2694 }
2695
2696 our $gitweb_project_owner = undef;
2697 sub git_get_project_list_from_file {
2698
2699         return if (defined $gitweb_project_owner);
2700
2701         $gitweb_project_owner = {};
2702         # read from file (url-encoded):
2703         # 'git%2Fgit.git Linus+Torvalds'
2704         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2705         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2706         if (-f $projects_list) {
2707                 open(my $fd, '<', $projects_list);
2708                 while (my $line = <$fd>) {
2709                         chomp $line;
2710                         my ($pr, $ow) = split ' ', $line;
2711                         $pr = unescape($pr);
2712                         $ow = unescape($ow);
2713                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2714                 }
2715                 close $fd;
2716         }
2717 }
2718
2719 sub git_get_project_owner {
2720         my $project = shift;
2721         my $owner;
2722
2723         return undef unless $project;
2724         $git_dir = "$projectroot/$project";
2725
2726         if (!defined $gitweb_project_owner) {
2727                 git_get_project_list_from_file();
2728         }
2729
2730         if (exists $gitweb_project_owner->{$project}) {
2731                 $owner = $gitweb_project_owner->{$project};
2732         }
2733         if (!defined $owner){
2734                 $owner = git_get_project_config('owner');
2735         }
2736         if (!defined $owner) {
2737                 $owner = get_file_owner("$git_dir");
2738         }
2739
2740         return $owner;
2741 }
2742
2743 sub git_get_last_activity {
2744         my ($path) = @_;
2745         my $fd;
2746
2747         $git_dir = "$projectroot/$path";
2748         open($fd, "-|", git_cmd(), 'for-each-ref',
2749              '--format=%(committer)',
2750              '--sort=-committerdate',
2751              '--count=1',
2752              'refs/heads') or return;
2753         my $most_recent = <$fd>;
2754         close $fd or return;
2755         if (defined $most_recent &&
2756             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
2757                 my $timestamp = $1;
2758                 my $age = time - $timestamp;
2759                 return ($age, age_string($age));
2760         }
2761         return (undef, undef);
2762 }
2763
2764 sub git_get_references {
2765         my $type = shift || "";
2766         my %refs;
2767         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
2768         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
2769         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
2770                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
2771                 or return;
2772
2773         while (my $line = <$fd>) {
2774                 chomp $line;
2775                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
2776                         if (defined $refs{$1}) {
2777                                 push @{$refs{$1}}, $2;
2778                         } else {
2779                                 $refs{$1} = [ $2 ];
2780                         }
2781                 }
2782         }
2783         close $fd or return;
2784         return \%refs;
2785 }
2786
2787 sub git_get_rev_name_tags {
2788         my $hash = shift || return undef;
2789
2790         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
2791                 or return;
2792         my $name_rev = <$fd>;
2793         close $fd;
2794
2795         if ($name_rev =~ m|^$hash tags/(.*)$|) {
2796                 return $1;
2797         } else {
2798                 # catches also '$hash undefined' output
2799                 return undef;
2800         }
2801 }
2802
2803 ## ----------------------------------------------------------------------
2804 ## parse to hash functions
2805
2806 sub parse_date {
2807         my $epoch = shift;
2808         my $tz = shift || "-0000";
2809
2810         my %date;
2811         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
2812         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
2813         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
2814         $date{'hour'} = $hour;
2815         $date{'minute'} = $min;
2816         $date{'mday'} = $mday;
2817         $date{'day'} = $days[$wday];
2818         $date{'month'} = $months[$mon];
2819         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
2820                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
2821         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
2822                              $mday, $months[$mon], $hour ,$min;
2823         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
2824                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
2825
2826         $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
2827         my $local = $epoch + ((int $1 + ($2/60)) * 3600);
2828         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
2829         $date{'hour_local'} = $hour;
2830         $date{'minute_local'} = $min;
2831         $date{'tz_local'} = $tz;
2832         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
2833                                   1900+$year, $mon+1, $mday,
2834                                   $hour, $min, $sec, $tz);
2835         return %date;
2836 }
2837
2838 sub parse_tag {
2839         my $tag_id = shift;
2840         my %tag;
2841         my @comment;
2842
2843         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
2844         $tag{'id'} = $tag_id;
2845         while (my $line = <$fd>) {
2846                 chomp $line;
2847                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
2848                         $tag{'object'} = $1;
2849                 } elsif ($line =~ m/^type (.+)$/) {
2850                         $tag{'type'} = $1;
2851                 } elsif ($line =~ m/^tag (.+)$/) {
2852                         $tag{'name'} = $1;
2853                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
2854                         $tag{'author'} = $1;
2855                         $tag{'author_epoch'} = $2;
2856                         $tag{'author_tz'} = $3;
2857                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2858                                 $tag{'author_name'}  = $1;
2859                                 $tag{'author_email'} = $2;
2860                         } else {
2861                                 $tag{'author_name'} = $tag{'author'};
2862                         }
2863                 } elsif ($line =~ m/--BEGIN/) {
2864                         push @comment, $line;
2865                         last;
2866                 } elsif ($line eq "") {
2867                         last;
2868                 }
2869         }
2870         push @comment, <$fd>;
2871         $tag{'comment'} = \@comment;
2872         close $fd or return;
2873         if (!defined $tag{'name'}) {
2874                 return
2875         };
2876         return %tag
2877 }
2878
2879 sub parse_commit_text {
2880         my ($commit_text, $withparents) = @_;
2881         my @commit_lines = split '\n', $commit_text;
2882         my %co;
2883
2884         pop @commit_lines; # Remove '\0'
2885
2886         if (! @commit_lines) {
2887                 return;
2888         }
2889
2890         my $header = shift @commit_lines;
2891         if ($header !~ m/^[0-9a-fA-F]{40}/) {
2892                 return;
2893         }
2894         ($co{'id'}, my @parents) = split ' ', $header;
2895         while (my $line = shift @commit_lines) {
2896                 last if $line eq "\n";
2897                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
2898                         $co{'tree'} = $1;
2899                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
2900                         push @parents, $1;
2901                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
2902                         $co{'author'} = to_utf8($1);
2903                         $co{'author_epoch'} = $2;
2904                         $co{'author_tz'} = $3;
2905                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2906                                 $co{'author_name'}  = $1;
2907                                 $co{'author_email'} = $2;
2908                         } else {
2909                                 $co{'author_name'} = $co{'author'};
2910                         }
2911                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
2912                         $co{'committer'} = to_utf8($1);
2913                         $co{'committer_epoch'} = $2;
2914                         $co{'committer_tz'} = $3;
2915                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
2916                                 $co{'committer_name'}  = $1;
2917                                 $co{'committer_email'} = $2;
2918                         } else {
2919                                 $co{'committer_name'} = $co{'committer'};
2920                         }
2921                 }
2922         }
2923         if (!defined $co{'tree'}) {
2924                 return;
2925         };
2926         $co{'parents'} = \@parents;
2927         $co{'parent'} = $parents[0];
2928
2929         foreach my $title (@commit_lines) {
2930                 $title =~ s/^    //;
2931                 if ($title ne "") {
2932                         $co{'title'} = chop_str($title, 80, 5);
2933                         # remove leading stuff of merges to make the interesting part visible
2934                         if (length($title) > 50) {
2935                                 $title =~ s/^Automatic //;
2936                                 $title =~ s/^merge (of|with) /Merge ... /i;
2937                                 if (length($title) > 50) {
2938                                         $title =~ s/(http|rsync):\/\///;
2939                                 }
2940                                 if (length($title) > 50) {
2941                                         $title =~ s/(master|www|rsync)\.//;
2942                                 }
2943                                 if (length($title) > 50) {
2944                                         $title =~ s/kernel.org:?//;
2945                                 }
2946                                 if (length($title) > 50) {
2947                                         $title =~ s/\/pub\/scm//;
2948                                 }
2949                         }
2950                         $co{'title_short'} = chop_str($title, 50, 5);
2951                         last;
2952                 }
2953         }
2954         if (! defined $co{'title'} || $co{'title'} eq "") {
2955                 $co{'title'} = $co{'title_short'} = '(no commit message)';
2956         }
2957         # remove added spaces
2958         foreach my $line (@commit_lines) {
2959                 $line =~ s/^    //;
2960         }
2961         $co{'comment'} = \@commit_lines;
2962
2963         my $age = time - $co{'committer_epoch'};
2964         $co{'age'} = $age;
2965         $co{'age_string'} = age_string($age);
2966         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
2967         if ($age > 60*60*24*7*2) {
2968                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
2969                 $co{'age_string_age'} = $co{'age_string'};
2970         } else {
2971                 $co{'age_string_date'} = $co{'age_string'};
2972                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
2973         }
2974         return %co;
2975 }
2976
2977 sub parse_commit {
2978         my ($commit_id) = @_;
2979         my %co;
2980
2981         local $/ = "\0";
2982
2983         open my $fd, "-|", git_cmd(), "rev-list",
2984                 "--parents",
2985                 "--header",
2986                 "--max-count=1",
2987                 $commit_id,
2988                 "--",
2989                 or die_error(500, "Open git-rev-list failed");
2990         %co = parse_commit_text(<$fd>, 1);
2991         close $fd;
2992
2993         return %co;
2994 }
2995
2996 sub parse_commits {
2997         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
2998         my @cos;
2999
3000         $maxcount ||= 1;
3001         $skip ||= 0;
3002
3003         local $/ = "\0";
3004
3005         open my $fd, "-|", git_cmd(), "rev-list",
3006                 "--header",
3007                 @args,
3008                 ("--max-count=" . $maxcount),
3009                 ("--skip=" . $skip),
3010                 @extra_options,
3011                 $commit_id,
3012                 "--",
3013                 ($filename ? ($filename) : ())
3014                 or die_error(500, "Open git-rev-list failed");
3015         while (my $line = <$fd>) {
3016                 my %co = parse_commit_text($line);
3017                 push @cos, \%co;
3018         }
3019         close $fd;
3020
3021         return wantarray ? @cos : \@cos;
3022 }
3023
3024 # parse line of git-diff-tree "raw" output
3025 sub parse_difftree_raw_line {
3026         my $line = shift;
3027         my %res;
3028
3029         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3030         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3031         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3032                 $res{'from_mode'} = $1;
3033                 $res{'to_mode'} = $2;
3034                 $res{'from_id'} = $3;
3035                 $res{'to_id'} = $4;
3036                 $res{'status'} = $5;
3037                 $res{'similarity'} = $6;
3038                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3039                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3040                 } else {
3041                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3042                 }
3043         }
3044         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3045         # combined diff (for merge commit)
3046         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3047                 $res{'nparents'}  = length($1);
3048                 $res{'from_mode'} = [ split(' ', $2) ];
3049                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3050                 $res{'from_id'} = [ split(' ', $3) ];
3051                 $res{'to_id'} = pop @{$res{'from_id'}};
3052                 $res{'status'} = [ split('', $4) ];
3053                 $res{'to_file'} = unquote($5);
3054         }
3055         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3056         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3057                 $res{'commit'} = $1;
3058         }
3059
3060         return wantarray ? %res : \%res;
3061 }
3062
3063 # wrapper: return parsed line of git-diff-tree "raw" output
3064 # (the argument might be raw line, or parsed info)
3065 sub parsed_difftree_line {
3066         my $line_or_ref = shift;
3067
3068         if (ref($line_or_ref) eq "HASH") {
3069                 # pre-parsed (or generated by hand)
3070                 return $line_or_ref;
3071         } else {
3072                 return parse_difftree_raw_line($line_or_ref);
3073         }
3074 }
3075
3076 # parse line of git-ls-tree output
3077 sub parse_ls_tree_line {
3078         my $line = shift;
3079         my %opts = @_;
3080         my %res;
3081
3082         if ($opts{'-l'}) {
3083                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3084                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3085
3086                 $res{'mode'} = $1;
3087                 $res{'type'} = $2;
3088                 $res{'hash'} = $3;
3089                 $res{'size'} = $4;
3090                 if ($opts{'-z'}) {
3091                         $res{'name'} = $5;
3092                 } else {
3093                         $res{'name'} = unquote($5);
3094                 }
3095         } else {
3096                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3097                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3098
3099                 $res{'mode'} = $1;
3100                 $res{'type'} = $2;
3101                 $res{'hash'} = $3;
3102                 if ($opts{'-z'}) {
3103                         $res{'name'} = $4;
3104                 } else {
3105                         $res{'name'} = unquote($4);
3106                 }
3107         }
3108
3109         return wantarray ? %res : \%res;
3110 }
3111
3112 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3113 sub parse_from_to_diffinfo {
3114         my ($diffinfo, $from, $to, @parents) = @_;
3115
3116         if ($diffinfo->{'nparents'}) {
3117                 # combined diff
3118                 $from->{'file'} = [];
3119                 $from->{'href'} = [];
3120                 fill_from_file_info($diffinfo, @parents)
3121                         unless exists $diffinfo->{'from_file'};
3122                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3123                         $from->{'file'}[$i] =
3124                                 defined $diffinfo->{'from_file'}[$i] ?
3125                                         $diffinfo->{'from_file'}[$i] :
3126                                         $diffinfo->{'to_file'};
3127                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3128                                 $from->{'href'}[$i] = href(action=>"blob",
3129                                                            hash_base=>$parents[$i],
3130                                                            hash=>$diffinfo->{'from_id'}[$i],
3131                                                            file_name=>$from->{'file'}[$i]);
3132                         } else {
3133                                 $from->{'href'}[$i] = undef;
3134                         }
3135                 }
3136         } else {
3137                 # ordinary (not combined) diff
3138                 $from->{'file'} = $diffinfo->{'from_file'};
3139                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3140                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3141                                                hash=>$diffinfo->{'from_id'},
3142                                                file_name=>$from->{'file'});
3143                 } else {
3144                         delete $from->{'href'};
3145                 }
3146         }
3147
3148         $to->{'file'} = $diffinfo->{'to_file'};
3149         if (!is_deleted($diffinfo)) { # file exists in result
3150                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3151                                      hash=>$diffinfo->{'to_id'},
3152                                      file_name=>$to->{'file'});
3153         } else {
3154                 delete $to->{'href'};
3155         }
3156 }
3157
3158 ## ......................................................................
3159 ## parse to array of hashes functions
3160
3161 sub git_get_heads_list {
3162         my $limit = shift;
3163         my @headslist;
3164
3165         open my $fd, '-|', git_cmd(), 'for-each-ref',
3166                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3167                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3168                 'refs/heads'
3169                 or return;
3170         while (my $line = <$fd>) {
3171                 my %ref_item;
3172
3173                 chomp $line;
3174                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3175                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3176                 my ($committer, $epoch, $tz) =
3177                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3178                 $ref_item{'fullname'}  = $name;
3179                 $name =~ s!^refs/heads/!!;
3180
3181                 $ref_item{'name'}  = $name;
3182                 $ref_item{'id'}    = $hash;
3183                 $ref_item{'title'} = $title || '(no commit message)';
3184                 $ref_item{'epoch'} = $epoch;
3185                 if ($epoch) {
3186                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3187                 } else {
3188                         $ref_item{'age'} = "unknown";
3189                 }
3190
3191                 push @headslist, \%ref_item;
3192         }
3193         close $fd;
3194
3195         return wantarray ? @headslist : \@headslist;
3196 }
3197
3198 sub git_get_tags_list {
3199         my $limit = shift;
3200         my @tagslist;
3201
3202         open my $fd, '-|', git_cmd(), 'for-each-ref',
3203                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3204                 '--format=%(objectname) %(objecttype) %(refname) '.
3205                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3206                 'refs/tags'
3207                 or return;
3208         while (my $line = <$fd>) {
3209                 my %ref_item;
3210
3211                 chomp $line;
3212                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3213                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3214                 my ($creator, $epoch, $tz) =
3215                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3216                 $ref_item{'fullname'} = $name;
3217                 $name =~ s!^refs/tags/!!;
3218
3219                 $ref_item{'type'} = $type;
3220                 $ref_item{'id'} = $id;
3221                 $ref_item{'name'} = $name;
3222                 if ($type eq "tag") {
3223                         $ref_item{'subject'} = $title;
3224                         $ref_item{'reftype'} = $reftype;
3225                         $ref_item{'refid'}   = $refid;
3226                 } else {
3227                         $ref_item{'reftype'} = $type;
3228                         $ref_item{'refid'}   = $id;
3229                 }
3230
3231                 if ($type eq "tag" || $type eq "commit") {
3232                         $ref_item{'epoch'} = $epoch;
3233                         if ($epoch) {
3234                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3235                         } else {
3236                                 $ref_item{'age'} = "unknown";
3237                         }
3238                 }
3239
3240                 push @tagslist, \%ref_item;
3241         }
3242         close $fd;
3243
3244         return wantarray ? @tagslist : \@tagslist;
3245 }
3246
3247 ## ----------------------------------------------------------------------
3248 ## filesystem-related functions
3249
3250 sub get_file_owner {
3251         my $path = shift;
3252
3253         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3254         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3255         if (!defined $gcos) {
3256                 return undef;
3257         }
3258         my $owner = $gcos;
3259         $owner =~ s/[,;].*$//;
3260         return to_utf8($owner);
3261 }
3262
3263 # assume that file exists
3264 sub insert_file {
3265         my $filename = shift;
3266
3267         open my $fd, '<', $filename;
3268         print map { to_utf8($_) } <$fd>;
3269         close $fd;
3270 }
3271
3272 ## ......................................................................
3273 ## mimetype related functions
3274
3275 sub mimetype_guess_file {
3276         my $filename = shift;
3277         my $mimemap = shift;
3278         -r $mimemap or return undef;
3279
3280         my %mimemap;
3281         open(my $mh, '<', $mimemap) or return undef;
3282         while (<$mh>) {
3283                 next if m/^#/; # skip comments
3284                 my ($mimetype, $exts) = split(/\t+/);
3285                 if (defined $exts) {
3286                         my @exts = split(/\s+/, $exts);
3287                         foreach my $ext (@exts) {
3288                                 $mimemap{$ext} = $mimetype;
3289                         }
3290                 }
3291         }
3292         close($mh);
3293
3294         $filename =~ /\.([^.]*)$/;
3295         return $mimemap{$1};
3296 }
3297
3298 sub mimetype_guess {
3299         my $filename = shift;
3300         my $mime;
3301         $filename =~ /\./ or return undef;
3302
3303         if ($mimetypes_file) {
3304                 my $file = $mimetypes_file;
3305                 if ($file !~ m!^/!) { # if it is relative path
3306                         # it is relative to project
3307                         $file = "$projectroot/$project/$file";
3308                 }
3309                 $mime = mimetype_guess_file($filename, $file);
3310         }
3311         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3312         return $mime;
3313 }
3314
3315 sub blob_mimetype {
3316         my $fd = shift;
3317         my $filename = shift;
3318
3319         if ($filename) {
3320                 my $mime = mimetype_guess($filename);
3321                 $mime and return $mime;
3322         }
3323
3324         # just in case
3325         return $default_blob_plain_mimetype unless $fd;
3326
3327         if (-T $fd) {
3328                 return 'text/plain';
3329         } elsif (! $filename) {
3330                 return 'application/octet-stream';
3331         } elsif ($filename =~ m/\.png$/i) {
3332                 return 'image/png';
3333         } elsif ($filename =~ m/\.gif$/i) {
3334                 return 'image/gif';
3335         } elsif ($filename =~ m/\.jpe?g$/i) {
3336                 return 'image/jpeg';
3337         } else {
3338                 return 'application/octet-stream';
3339         }
3340 }
3341
3342 sub blob_contenttype {
3343         my ($fd, $file_name, $type) = @_;
3344
3345         $type ||= blob_mimetype($fd, $file_name);
3346         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3347                 $type .= "; charset=$default_text_plain_charset";
3348         }
3349
3350         return $type;
3351 }
3352
3353 # guess file syntax for syntax highlighting; return undef if no highlighting
3354 # the name of syntax can (in the future) depend on syntax highlighter used
3355 sub guess_file_syntax {
3356         my ($highlight, $mimetype, $file_name) = @_;
3357         return undef unless ($highlight && defined $file_name);
3358         my $basename = basename($file_name, '.in');
3359         return $highlight_basename{$basename}
3360                 if exists $highlight_basename{$basename};
3361
3362         $basename =~ /\.([^.]*)$/;
3363         my $ext = $1 or return undef;
3364         return $highlight_ext{$ext}
3365                 if exists $highlight_ext{$ext};
3366
3367         return undef;
3368 }
3369
3370 # run highlighter and return FD of its output,
3371 # or return original FD if no highlighting
3372 sub run_highlighter {
3373         my ($fd, $highlight, $syntax) = @_;
3374         return $fd unless ($highlight && defined $syntax);
3375
3376         close $fd
3377                 or die_error(404, "Reading blob failed");
3378         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3379                   "highlight --xhtml --fragment --syntax $syntax |"
3380                 or die_error(500, "Couldn't open file or run syntax highlighter");
3381         return $fd;
3382 }
3383
3384 ## ======================================================================
3385 ## functions printing HTML: header, footer, error page
3386
3387 sub get_page_title {
3388         my $title = to_utf8($site_name);
3389
3390         return $title unless (defined $project);
3391         $title .= " - " . to_utf8($project);
3392
3393         return $title unless (defined $action);
3394         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3395
3396         return $title unless (defined $file_name);
3397         $title .= " - " . esc_path($file_name);
3398         if ($action eq "tree" && $file_name !~ m|/$|) {
3399                 $title .= "/";
3400         }
3401
3402         return $title;
3403 }
3404
3405 sub git_header_html {
3406         my $status = shift || "200 OK";
3407         my $expires = shift;
3408         my %opts = @_;
3409
3410         my $title = get_page_title();
3411         my $content_type;
3412         # require explicit support from the UA if we are to send the page as
3413         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3414         # we have to do this because MSIE sometimes globs '*/*', pretending to
3415         # support xhtml+xml but choking when it gets what it asked for.
3416         if (defined $cgi->http('HTTP_ACCEPT') &&
3417             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3418             $cgi->Accept('application/xhtml+xml') != 0) {
3419                 $content_type = 'application/xhtml+xml';
3420         } else {
3421                 $content_type = 'text/html';
3422         }
3423         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3424                            -status=> $status, -expires => $expires)
3425                 unless ($opts{'-no_http_header'});
3426         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3427         print <<EOF;
3428 <?xml version="1.0" encoding="utf-8"?>
3429 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3430 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3431 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3432 <!-- git core binaries version $git_version -->
3433 <head>
3434 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3435 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3436 <meta name="robots" content="index, nofollow"/>
3437 <title>$title</title>
3438 EOF
3439         # the stylesheet, favicon etc urls won't work correctly with path_info
3440         # unless we set the appropriate base URL
3441         if ($ENV{'PATH_INFO'}) {
3442                 print "<base href=\"".esc_url($base_url)."\" />\n";
3443         }
3444         # print out each stylesheet that exist, providing backwards capability
3445         # for those people who defined $stylesheet in a config file
3446         if (defined $stylesheet) {
3447                 print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
3448         } else {
3449                 foreach my $stylesheet (@stylesheets) {
3450                         next unless $stylesheet;
3451                         print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
3452                 }
3453         }
3454         if (defined $project) {
3455                 my %href_params = get_feed_info();
3456                 if (!exists $href_params{'-title'}) {
3457                         $href_params{'-title'} = 'log';
3458                 }
3459
3460                 foreach my $format qw(RSS Atom) {
3461                         my $type = lc($format);
3462                         my %link_attr = (
3463                                 '-rel' => 'alternate',
3464                                 '-title' => "$project - $href_params{'-title'} - $format feed",
3465                                 '-type' => "application/$type+xml"
3466                         );
3467
3468                         $href_params{'action'} = $type;
3469                         $link_attr{'-href'} = href(%href_params);
3470                         print "<link ".
3471                               "rel=\"$link_attr{'-rel'}\" ".
3472                               "title=\"$link_attr{'-title'}\" ".
3473                               "href=\"$link_attr{'-href'}\" ".
3474                               "type=\"$link_attr{'-type'}\" ".
3475                               "/>\n";
3476
3477                         $href_params{'extra_options'} = '--no-merges';
3478                         $link_attr{'-href'} = href(%href_params);
3479                         $link_attr{'-title'} .= ' (no merges)';
3480                         print "<link ".
3481                               "rel=\"$link_attr{'-rel'}\" ".
3482                               "title=\"$link_attr{'-title'}\" ".
3483                               "href=\"$link_attr{'-href'}\" ".
3484                               "type=\"$link_attr{'-type'}\" ".
3485                               "/>\n";
3486                 }
3487
3488         } else {
3489                 printf('<link rel="alternate" title="%s projects list" '.
3490                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3491                        $site_name, href(project=>undef, action=>"project_index"));
3492                 printf('<link rel="alternate" title="%s projects feeds" '.
3493                        'href="%s" type="text/x-opml" />'."\n",
3494                        $site_name, href(project=>undef, action=>"opml"));
3495         }
3496         if (defined $favicon) {
3497                 print qq(<link rel="shortcut icon" href="$favicon" type="image/png" />\n);
3498         }
3499
3500         print "</head>\n" .
3501               "<body>\n";
3502
3503         if (defined $site_header && -f $site_header) {
3504                 insert_file($site_header);
3505         }
3506
3507         print "<div class=\"page_header\">\n" .
3508               $cgi->a({-href => esc_url($logo_url),
3509                        -title => $logo_label},
3510                       qq(<img src="$logo" width="72" height="27" alt="git" class="logo"/>));
3511         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3512         if (defined $project) {
3513                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3514                 if (defined $action) {
3515                         print " / $action";
3516                 }
3517                 print "\n";
3518         }
3519         print "</div>\n";
3520
3521         my $have_search = gitweb_check_feature('search');
3522         if (defined $project && $have_search) {
3523                 if (!defined $searchtext) {
3524                         $searchtext = "";
3525                 }
3526                 my $search_hash;
3527                 if (defined $hash_base) {
3528                         $search_hash = $hash_base;
3529                 } elsif (defined $hash) {
3530                         $search_hash = $hash;
3531                 } else {
3532                         $search_hash = "HEAD";
3533                 }
3534                 my $action = $my_uri;
3535                 my $use_pathinfo = gitweb_check_feature('pathinfo');
3536                 if ($use_pathinfo) {
3537                         $action .= "/".esc_url($project);
3538                 }
3539                 print $cgi->startform(-method => "get", -action => $action) .
3540                       "<div class=\"search\">\n" .
3541                       (!$use_pathinfo &&
3542                       $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3543                       $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3544                       $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3545                       $cgi->popup_menu(-name => 'st', -default => 'commit',
3546                                        -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3547                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3548                       " search:\n",
3549                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3550                       "<span title=\"Extended regular expression\">" .
3551                       $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3552                                      -checked => $search_use_regexp) .
3553                       "</span>" .
3554                       "</div>" .
3555                       $cgi->end_form() . "\n";
3556         }
3557 }
3558
3559 sub git_footer_html {
3560         my $feed_class = 'rss_logo';
3561
3562         print "<div class=\"page_footer\">\n";
3563         if (defined $project) {
3564                 my $descr = git_get_project_description($project);
3565                 if (defined $descr) {
3566                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3567                 }
3568
3569                 my %href_params = get_feed_info();
3570                 if (!%href_params) {
3571                         $feed_class .= ' generic';
3572                 }
3573                 $href_params{'-title'} ||= 'log';
3574
3575                 foreach my $format qw(RSS Atom) {
3576                         $href_params{'action'} = lc($format);
3577                         print $cgi->a({-href => href(%href_params),
3578                                       -title => "$href_params{'-title'} $format feed",
3579                                       -class => $feed_class}, $format)."\n";
3580                 }
3581
3582         } else {
3583                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3584                               -class => $feed_class}, "OPML") . " ";
3585                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3586                               -class => $feed_class}, "TXT") . "\n";
3587         }
3588         print "</div>\n"; # class="page_footer"
3589
3590         if (defined $t0 && gitweb_check_feature('timed')) {
3591                 print "<div id=\"generating_info\">\n";
3592                 print 'This page took '.
3593                       '<span id="generating_time" class="time_span">'.
3594                       Time::HiRes::tv_interval($t0, [Time::HiRes::gettimeofday()]).
3595                       ' seconds </span>'.
3596                       ' and '.
3597                       '<span id="generating_cmd">'.
3598                       $number_of_git_cmds.
3599                       '</span> git commands '.
3600                       " to generate.\n";
3601                 print "</div>\n"; # class="page_footer"
3602         }
3603
3604         if (defined $site_footer && -f $site_footer) {
3605                 insert_file($site_footer);
3606         }
3607
3608         print qq!<script type="text/javascript" src="$javascript"></script>\n!;
3609         if (defined $action &&
3610             $action eq 'blame_incremental') {
3611                 print qq!<script type="text/javascript">\n!.
3612                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3613                       qq!           "!. href() .qq!");\n!.
3614                       qq!</script>\n!;
3615         } elsif (gitweb_check_feature('javascript-actions')) {
3616                 print qq!<script type="text/javascript">\n!.
3617                       qq!window.onload = fixLinks;\n!.
3618                       qq!</script>\n!;
3619         }
3620
3621         print "</body>\n" .
3622               "</html>";
3623 }
3624
3625 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
3626 # Example: die_error(404, 'Hash not found')
3627 # By convention, use the following status codes (as defined in RFC 2616):
3628 # 400: Invalid or missing CGI parameters, or
3629 #      requested object exists but has wrong type.
3630 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
3631 #      this server or project.
3632 # 404: Requested object/revision/project doesn't exist.
3633 # 500: The server isn't configured properly, or
3634 #      an internal error occurred (e.g. failed assertions caused by bugs), or
3635 #      an unknown error occurred (e.g. the git binary died unexpectedly).
3636 # 503: The server is currently unavailable (because it is overloaded,
3637 #      or down for maintenance).  Generally, this is a temporary state.
3638 sub die_error {
3639         my $status = shift || 500;
3640         my $error = esc_html(shift) || "Internal Server Error";
3641         my $extra = shift;
3642         my %opts = @_;
3643
3644         my %http_responses = (
3645                 400 => '400 Bad Request',
3646                 403 => '403 Forbidden',
3647                 404 => '404 Not Found',
3648                 500 => '500 Internal Server Error',
3649                 503 => '503 Service Unavailable',
3650         );
3651         git_header_html($http_responses{$status}, undef, %opts);
3652         print <<EOF;
3653 <div class="page_body">
3654 <br /><br />
3655 $status - $error
3656 <br />
3657 EOF
3658         if (defined $extra) {
3659                 print "<hr />\n" .
3660                       "$extra\n";
3661         }
3662         print "</div>\n";
3663
3664         git_footer_html();
3665         goto DONE_GITWEB
3666                 unless ($opts{'-error_handler'});
3667 }
3668
3669 ## ----------------------------------------------------------------------
3670 ## functions printing or outputting HTML: navigation
3671
3672 sub git_print_page_nav {
3673         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
3674         $extra = '' if !defined $extra; # pager or formats
3675
3676         my @navs = qw(summary shortlog log commit commitdiff tree);
3677         if ($suppress) {
3678                 @navs = grep { $_ ne $suppress } @navs;
3679         }
3680
3681         my %arg = map { $_ => {action=>$_} } @navs;
3682         if (defined $head) {
3683                 for (qw(commit commitdiff)) {
3684                         $arg{$_}{'hash'} = $head;
3685                 }
3686                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
3687                         for (qw(shortlog log)) {
3688                                 $arg{$_}{'hash'} = $head;
3689                         }
3690                 }
3691         }
3692
3693         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
3694         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
3695
3696         my @actions = gitweb_get_feature('actions');
3697         my %repl = (
3698                 '%' => '%',
3699                 'n' => $project,         # project name
3700                 'f' => $git_dir,         # project path within filesystem
3701                 'h' => $treehead || '',  # current hash ('h' parameter)
3702                 'b' => $treebase || '',  # hash base ('hb' parameter)
3703         );
3704         while (@actions) {
3705                 my ($label, $link, $pos) = splice(@actions,0,3);
3706                 # insert
3707                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
3708                 # munch munch
3709                 $link =~ s/%([%nfhb])/$repl{$1}/g;
3710                 $arg{$label}{'_href'} = $link;
3711         }
3712
3713         print "<div class=\"page_nav\">\n" .
3714                 (join " | ",
3715                  map { $_ eq $current ?
3716                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
3717                  } @navs);
3718         print "<br/>\n$extra<br/>\n" .
3719               "</div>\n";
3720 }
3721
3722 sub format_paging_nav {
3723         my ($action, $page, $has_next_link) = @_;
3724         my $paging_nav;
3725
3726
3727         if ($page > 0) {
3728                 $paging_nav .=
3729                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
3730                         " &sdot; " .
3731                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
3732                                  -accesskey => "p", -title => "Alt-p"}, "prev");
3733         } else {
3734                 $paging_nav .= "first &sdot; prev";
3735         }
3736
3737         if ($has_next_link) {
3738                 $paging_nav .= " &sdot; " .
3739                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
3740                                  -accesskey => "n", -title => "Alt-n"}, "next");
3741         } else {
3742                 $paging_nav .= " &sdot; next";
3743         }
3744
3745         return $paging_nav;
3746 }
3747
3748 ## ......................................................................
3749 ## functions printing or outputting HTML: div
3750
3751 sub git_print_header_div {
3752         my ($action, $title, $hash, $hash_base) = @_;
3753         my %args = ();
3754
3755         $args{'action'} = $action;
3756         $args{'hash'} = $hash if $hash;
3757         $args{'hash_base'} = $hash_base if $hash_base;
3758
3759         print "<div class=\"header\">\n" .
3760               $cgi->a({-href => href(%args), -class => "title"},
3761               $title ? $title : $action) .
3762               "\n</div>\n";
3763 }
3764
3765 sub print_local_time {
3766         print format_local_time(@_);
3767 }
3768
3769 sub format_local_time {
3770         my $localtime = '';
3771         my %date = @_;
3772         if ($date{'hour_local'} < 6) {
3773                 $localtime .= sprintf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
3774                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3775         } else {
3776                 $localtime .= sprintf(" (%02d:%02d %s)",
3777                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3778         }
3779
3780         return $localtime;
3781 }
3782
3783 # Outputs the author name and date in long form
3784 sub git_print_authorship {
3785         my $co = shift;
3786         my %opts = @_;
3787         my $tag = $opts{-tag} || 'div';
3788         my $author = $co->{'author_name'};
3789
3790         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
3791         print "<$tag class=\"author_date\">" .
3792               format_search_author($author, "author", esc_html($author)) .
3793               " [$ad{'rfc2822'}";
3794         print_local_time(%ad) if ($opts{-localtime});
3795         print "]" . git_get_avatar($co->{'author_email'}, -pad_before => 1)
3796                   . "</$tag>\n";
3797 }
3798
3799 # Outputs table rows containing the full author or committer information,
3800 # in the format expected for 'commit' view (& similar).
3801 # Parameters are a commit hash reference, followed by the list of people
3802 # to output information for. If the list is empty it defaults to both
3803 # author and committer.
3804 sub git_print_authorship_rows {
3805         my $co = shift;
3806         # too bad we can't use @people = @_ || ('author', 'committer')
3807         my @people = @_;
3808         @people = ('author', 'committer') unless @people;
3809         foreach my $who (@people) {
3810                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
3811                 print "<tr><td>$who</td><td>" .
3812                       format_search_author($co->{"${who}_name"}, $who,
3813                                esc_html($co->{"${who}_name"})) . " " .
3814                       format_search_author($co->{"${who}_email"}, $who,
3815                                esc_html("<" . $co->{"${who}_email"} . ">")) .
3816                       "</td><td rowspan=\"2\">" .
3817                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
3818                       "</td></tr>\n" .
3819                       "<tr>" .
3820                       "<td></td><td> $wd{'rfc2822'}";
3821                 print_local_time(%wd);
3822                 print "</td>" .
3823                       "</tr>\n";
3824         }
3825 }
3826
3827 sub git_print_page_path {
3828         my $name = shift;
3829         my $type = shift;
3830         my $hb = shift;
3831
3832
3833         print "<div class=\"page_path\">";
3834         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
3835                       -title => 'tree root'}, to_utf8("[$project]"));
3836         print " / ";
3837         if (defined $name) {
3838                 my @dirname = split '/', $name;
3839                 my $basename = pop @dirname;
3840                 my $fullname = '';
3841
3842                 foreach my $dir (@dirname) {
3843                         $fullname .= ($fullname ? '/' : '') . $dir;
3844                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
3845                                                      hash_base=>$hb),
3846                                       -title => $fullname}, esc_path($dir));
3847                         print " / ";
3848                 }
3849                 if (defined $type && $type eq 'blob') {
3850                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
3851                                                      hash_base=>$hb),
3852                                       -title => $name}, esc_path($basename));
3853                 } elsif (defined $type && $type eq 'tree') {
3854                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
3855                                                      hash_base=>$hb),
3856                                       -title => $name}, esc_path($basename));
3857                         print " / ";
3858                 } else {
3859                         print esc_path($basename);
3860                 }
3861         }
3862         print "<br/></div>\n";
3863 }
3864
3865 sub git_print_log {
3866         my $log = shift;
3867         my %opts = @_;
3868
3869         if ($opts{'-remove_title'}) {
3870                 # remove title, i.e. first line of log
3871                 shift @$log;
3872         }
3873         # remove leading empty lines
3874         while (defined $log->[0] && $log->[0] eq "") {
3875                 shift @$log;
3876         }
3877
3878         # print log
3879         my $signoff = 0;
3880         my $empty = 0;
3881         foreach my $line (@$log) {
3882                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
3883                         $signoff = 1;
3884                         $empty = 0;
3885                         if (! $opts{'-remove_signoff'}) {
3886                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
3887                                 next;
3888                         } else {
3889                                 # remove signoff lines
3890                                 next;
3891                         }
3892                 } else {
3893                         $signoff = 0;
3894                 }
3895
3896                 # print only one empty line
3897                 # do not print empty line after signoff
3898                 if ($line eq "") {
3899                         next if ($empty || $signoff);
3900                         $empty = 1;
3901                 } else {
3902                         $empty = 0;
3903                 }
3904
3905                 print format_log_line_html($line) . "<br/>\n";
3906         }
3907
3908         if ($opts{'-final_empty_line'}) {
3909                 # end with single empty line
3910                 print "<br/>\n" unless $empty;
3911         }
3912 }
3913
3914 # return link target (what link points to)
3915 sub git_get_link_target {
3916         my $hash = shift;
3917         my $link_target;
3918
3919         # read link
3920         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
3921                 or return;
3922         {
3923                 local $/ = undef;
3924                 $link_target = <$fd>;
3925         }
3926         close $fd
3927                 or return;
3928
3929         return $link_target;
3930 }
3931
3932 # given link target, and the directory (basedir) the link is in,
3933 # return target of link relative to top directory (top tree);
3934 # return undef if it is not possible (including absolute links).
3935 sub normalize_link_target {
3936         my ($link_target, $basedir) = @_;
3937
3938         # absolute symlinks (beginning with '/') cannot be normalized
3939         return if (substr($link_target, 0, 1) eq '/');
3940
3941         # normalize link target to path from top (root) tree (dir)
3942         my $path;
3943         if ($basedir) {
3944                 $path = $basedir . '/' . $link_target;
3945         } else {
3946                 # we are in top (root) tree (dir)
3947                 $path = $link_target;
3948         }
3949
3950         # remove //, /./, and /../
3951         my @path_parts;
3952         foreach my $part (split('/', $path)) {
3953                 # discard '.' and ''
3954                 next if (!$part || $part eq '.');
3955                 # handle '..'
3956                 if ($part eq '..') {
3957                         if (@path_parts) {
3958                                 pop @path_parts;
3959                         } else {
3960                                 # link leads outside repository (outside top dir)
3961                                 return;
3962                         }
3963                 } else {
3964                         push @path_parts, $part;
3965                 }
3966         }
3967         $path = join('/', @path_parts);
3968
3969         return $path;
3970 }
3971
3972 # print tree entry (row of git_tree), but without encompassing <tr> element
3973 sub git_print_tree_entry {
3974         my ($t, $basedir, $hash_base, $have_blame) = @_;
3975
3976         my %base_key = ();
3977         $base_key{'hash_base'} = $hash_base if defined $hash_base;
3978
3979         # The format of a table row is: mode list link.  Where mode is
3980         # the mode of the entry, list is the name of the entry, an href,
3981         # and link is the action links of the entry.
3982
3983         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
3984         if (exists $t->{'size'}) {
3985                 print "<td class=\"size\">$t->{'size'}</td>\n";
3986         }
3987         if ($t->{'type'} eq "blob") {
3988                 print "<td class=\"list\">" .
3989                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
3990                                                file_name=>"$basedir$t->{'name'}", %base_key),
3991                                 -class => "list"}, esc_path($t->{'name'}));
3992                 if (S_ISLNK(oct $t->{'mode'})) {
3993                         my $link_target = git_get_link_target($t->{'hash'});
3994                         if ($link_target) {
3995                                 my $norm_target = normalize_link_target($link_target, $basedir);
3996                                 if (defined $norm_target) {
3997                                         print " -> " .
3998                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
3999                                                                      file_name=>$norm_target),
4000                                                        -title => $norm_target}, esc_path($link_target));
4001                                 } else {
4002                                         print " -> " . esc_path($link_target);
4003                                 }
4004                         }
4005                 }
4006                 print "</td>\n";
4007                 print "<td class=\"link\">";
4008                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4009                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4010                               "blob");
4011                 if ($have_blame) {
4012                         print " | " .
4013                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4014                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4015                                       "blame");
4016                 }
4017                 if (defined $hash_base) {
4018                         print " | " .
4019                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4020                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4021                                       "history");
4022                 }
4023                 print " | " .
4024                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4025                                                file_name=>"$basedir$t->{'name'}")},
4026                                 "raw");
4027                 print "</td>\n";
4028
4029         } elsif ($t->{'type'} eq "tree") {
4030                 print "<td class=\"list\">";
4031                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4032                                              file_name=>"$basedir$t->{'name'}",
4033                                              %base_key)},
4034                               esc_path($t->{'name'}));
4035                 print "</td>\n";
4036                 print "<td class=\"link\">";
4037                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4038                                              file_name=>"$basedir$t->{'name'}",
4039                                              %base_key)},
4040                               "tree");
4041                 if (defined $hash_base) {
4042                         print " | " .
4043                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4044                                                      file_name=>"$basedir$t->{'name'}")},
4045                                       "history");
4046                 }
4047                 print "</td>\n";
4048         } else {
4049                 # unknown object: we can only present history for it
4050                 # (this includes 'commit' object, i.e. submodule support)
4051                 print "<td class=\"list\">" .
4052                       esc_path($t->{'name'}) .
4053                       "</td>\n";
4054                 print "<td class=\"link\">";
4055                 if (defined $hash_base) {
4056                         print $cgi->a({-href => href(action=>"history",
4057                                                      hash_base=>$hash_base,
4058                                                      file_name=>"$basedir$t->{'name'}")},
4059                                       "history");
4060                 }
4061                 print "</td>\n";
4062         }
4063 }
4064
4065 ## ......................................................................
4066 ## functions printing large fragments of HTML
4067
4068 # get pre-image filenames for merge (combined) diff
4069 sub fill_from_file_info {
4070         my ($diff, @parents) = @_;
4071
4072         $diff->{'from_file'} = [ ];
4073         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4074         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4075                 if ($diff->{'status'}[$i] eq 'R' ||
4076                     $diff->{'status'}[$i] eq 'C') {
4077                         $diff->{'from_file'}[$i] =
4078                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4079                 }
4080         }
4081
4082         return $diff;
4083 }
4084
4085 # is current raw difftree line of file deletion
4086 sub is_deleted {
4087         my $diffinfo = shift;
4088
4089         return $diffinfo->{'to_id'} eq ('0' x 40);
4090 }
4091
4092 # does patch correspond to [previous] difftree raw line
4093 # $diffinfo  - hashref of parsed raw diff format
4094 # $patchinfo - hashref of parsed patch diff format
4095 #              (the same keys as in $diffinfo)
4096 sub is_patch_split {
4097         my ($diffinfo, $patchinfo) = @_;
4098
4099         return defined $diffinfo && defined $patchinfo
4100                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4101 }
4102
4103
4104 sub git_difftree_body {
4105         my ($difftree, $hash, @parents) = @_;
4106         my ($parent) = $parents[0];
4107         my $have_blame = gitweb_check_feature('blame');
4108         print "<div class=\"list_head\">\n";
4109         if ($#{$difftree} > 10) {
4110                 print(($#{$difftree} + 1) . " files changed:\n");
4111         }
4112         print "</div>\n";
4113
4114         print "<table class=\"" .
4115               (@parents > 1 ? "combined " : "") .
4116               "diff_tree\">\n";
4117
4118         # header only for combined diff in 'commitdiff' view
4119         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4120         if ($has_header) {
4121                 # table header
4122                 print "<thead><tr>\n" .
4123                        "<th></th><th></th>\n"; # filename, patchN link
4124                 for (my $i = 0; $i < @parents; $i++) {
4125                         my $par = $parents[$i];
4126                         print "<th>" .
4127                               $cgi->a({-href => href(action=>"commitdiff",
4128                                                      hash=>$hash, hash_parent=>$par),
4129                                        -title => 'commitdiff to parent number ' .
4130                                                   ($i+1) . ': ' . substr($par,0,7)},
4131                                       $i+1) .
4132                               "&nbsp;</th>\n";
4133                 }
4134                 print "</tr></thead>\n<tbody>\n";
4135         }
4136
4137         my $alternate = 1;
4138         my $patchno = 0;
4139         foreach my $line (@{$difftree}) {
4140                 my $diff = parsed_difftree_line($line);
4141
4142                 if ($alternate) {
4143                         print "<tr class=\"dark\">\n";
4144                 } else {
4145                         print "<tr class=\"light\">\n";
4146                 }
4147                 $alternate ^= 1;
4148
4149                 if (exists $diff->{'nparents'}) { # combined diff
4150
4151                         fill_from_file_info($diff, @parents)
4152                                 unless exists $diff->{'from_file'};
4153
4154                         if (!is_deleted($diff)) {
4155                                 # file exists in the result (child) commit
4156                                 print "<td>" .
4157                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4158                                                              file_name=>$diff->{'to_file'},
4159                                                              hash_base=>$hash),
4160                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4161                                       "</td>\n";
4162                         } else {
4163                                 print "<td>" .
4164                                       esc_path($diff->{'to_file'}) .
4165                                       "</td>\n";
4166                         }
4167
4168                         if ($action eq 'commitdiff') {
4169                                 # link to patch
4170                                 $patchno++;
4171                                 print "<td class=\"link\">" .
4172                                       $cgi->a({-href => "#patch$patchno"}, "patch") .
4173                                       " | " .
4174                                       "</td>\n";
4175                         }
4176
4177                         my $has_history = 0;
4178                         my $not_deleted = 0;
4179                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4180                                 my $hash_parent = $parents[$i];
4181                                 my $from_hash = $diff->{'from_id'}[$i];
4182                                 my $from_path = $diff->{'from_file'}[$i];
4183                                 my $status = $diff->{'status'}[$i];
4184
4185                                 $has_history ||= ($status ne 'A');
4186                                 $not_deleted ||= ($status ne 'D');
4187
4188                                 if ($status eq 'A') {
4189                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4190                                 } elsif ($status eq 'D') {
4191                                         print "<td class=\"link\">" .
4192                                               $cgi->a({-href => href(action=>"blob",
4193                                                                      hash_base=>$hash,
4194                                                                      hash=>$from_hash,
4195                                                                      file_name=>$from_path)},
4196                                                       "blob" . ($i+1)) .
4197                                               " | </td>\n";
4198                                 } else {
4199                                         if ($diff->{'to_id'} eq $from_hash) {
4200                                                 print "<td class=\"link nochange\">";
4201                                         } else {
4202                                                 print "<td class=\"link\">";
4203                                         }
4204                                         print $cgi->a({-href => href(action=>"blobdiff",
4205                                                                      hash=>$diff->{'to_id'},
4206                                                                      hash_parent=>$from_hash,
4207                                                                      hash_base=>$hash,
4208                                                                      hash_parent_base=>$hash_parent,
4209                                                                      file_name=>$diff->{'to_file'},
4210                                                                      file_parent=>$from_path)},
4211                                                       "diff" . ($i+1)) .
4212                                               " | </td>\n";
4213                                 }
4214                         }
4215
4216                         print "<td class=\"link\">";
4217                         if ($not_deleted) {
4218                                 print $cgi->a({-href => href(action=>"blob",
4219                                                              hash=>$diff->{'to_id'},
4220                                                              file_name=>$diff->{'to_file'},
4221                                                              hash_base=>$hash)},
4222                                               "blob");
4223                                 print " | " if ($has_history);
4224                         }
4225                         if ($has_history) {
4226                                 print $cgi->a({-href => href(action=>"history",
4227                                                              file_name=>$diff->{'to_file'},
4228                                                              hash_base=>$hash)},
4229                                               "history");
4230                         }
4231                         print "</td>\n";
4232
4233                         print "</tr>\n";
4234                         next; # instead of 'else' clause, to avoid extra indent
4235                 }
4236                 # else ordinary diff
4237
4238                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4239                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4240                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4241                         $to_mode_oct = oct $diff->{'to_mode'};
4242                         if (S_ISREG($to_mode_oct)) { # only for regular file
4243                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4244                         }
4245                         $to_file_type = file_type($diff->{'to_mode'});
4246                 }
4247                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4248                         $from_mode_oct = oct $diff->{'from_mode'};
4249                         if (S_ISREG($to_mode_oct)) { # only for regular file
4250                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4251                         }
4252                         $from_file_type = file_type($diff->{'from_mode'});
4253                 }
4254
4255                 if ($diff->{'status'} eq "A") { # created
4256                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4257                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4258                         $mode_chng   .= "]</span>";
4259                         print "<td>";
4260                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4261                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4262                                       -class => "list"}, esc_path($diff->{'file'}));
4263                         print "</td>\n";
4264                         print "<td>$mode_chng</td>\n";
4265                         print "<td class=\"link\">";
4266                         if ($action eq 'commitdiff') {
4267                                 # link to patch
4268                                 $patchno++;
4269                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4270                                 print " | ";
4271                         }
4272                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4273                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4274                                       "blob");
4275                         print "</td>\n";
4276
4277                 } elsif ($diff->{'status'} eq "D") { # deleted
4278                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4279                         print "<td>";
4280                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4281                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4282                                        -class => "list"}, esc_path($diff->{'file'}));
4283                         print "</td>\n";
4284                         print "<td>$mode_chng</td>\n";
4285                         print "<td class=\"link\">";
4286                         if ($action eq 'commitdiff') {
4287                                 # link to patch
4288                                 $patchno++;
4289                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4290                                 print " | ";
4291                         }
4292                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4293                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4294                                       "blob") . " | ";
4295                         if ($have_blame) {
4296                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4297                                                              file_name=>$diff->{'file'})},
4298                                               "blame") . " | ";
4299                         }
4300                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4301                                                      file_name=>$diff->{'file'})},
4302                                       "history");
4303                         print "</td>\n";
4304
4305                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4306                         my $mode_chnge = "";
4307                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4308                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4309                                 if ($from_file_type ne $to_file_type) {
4310                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4311                                 }
4312                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4313                                         if ($from_mode_str && $to_mode_str) {
4314                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4315                                         } elsif ($to_mode_str) {
4316                                                 $mode_chnge .= " mode: $to_mode_str";
4317                                         }
4318                                 }
4319                                 $mode_chnge .= "]</span>\n";
4320                         }
4321                         print "<td>";
4322                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4323                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4324                                       -class => "list"}, esc_path($diff->{'file'}));
4325                         print "</td>\n";
4326                         print "<td>$mode_chnge</td>\n";
4327                         print "<td class=\"link\">";
4328                         if ($action eq 'commitdiff') {
4329                                 # link to patch
4330                                 $patchno++;
4331                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4332                                       " | ";
4333                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4334                                 # "commit" view and modified file (not onlu mode changed)
4335                                 print $cgi->a({-href => href(action=>"blobdiff",
4336                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4337                                                              hash_base=>$hash, hash_parent_base=>$parent,
4338                                                              file_name=>$diff->{'file'})},
4339                                               "diff") .
4340                                       " | ";
4341                         }
4342                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4343                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4344                                        "blob") . " | ";
4345                         if ($have_blame) {
4346                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4347                                                              file_name=>$diff->{'file'})},
4348                                               "blame") . " | ";
4349                         }
4350                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4351                                                      file_name=>$diff->{'file'})},
4352                                       "history");
4353                         print "</td>\n";
4354
4355                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4356                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4357                         my $nstatus = $status_name{$diff->{'status'}};
4358                         my $mode_chng = "";
4359                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4360                                 # mode also for directories, so we cannot use $to_mode_str
4361                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4362                         }
4363                         print "<td>" .
4364                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4365                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4366                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4367                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4368                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4369                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4370                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4371                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4372                               "<td class=\"link\">";
4373                         if ($action eq 'commitdiff') {
4374                                 # link to patch
4375                                 $patchno++;
4376                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4377                                       " | ";
4378                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4379                                 # "commit" view and modified file (not only pure rename or copy)
4380                                 print $cgi->a({-href => href(action=>"blobdiff",
4381                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4382                                                              hash_base=>$hash, hash_parent_base=>$parent,
4383                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4384                                               "diff") .
4385                                       " | ";
4386                         }
4387                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4388                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4389                                       "blob") . " | ";
4390                         if ($have_blame) {
4391                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4392                                                              file_name=>$diff->{'to_file'})},
4393                                               "blame") . " | ";
4394                         }
4395                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4396                                                     file_name=>$diff->{'to_file'})},
4397                                       "history");
4398                         print "</td>\n";
4399
4400                 } # we should not encounter Unmerged (U) or Unknown (X) status
4401                 print "</tr>\n";
4402         }
4403         print "</tbody>" if $has_header;
4404         print "</table>\n";
4405 }
4406
4407 sub git_patchset_body {
4408         my ($fd, $difftree, $hash, @hash_parents) = @_;
4409         my ($hash_parent) = $hash_parents[0];
4410
4411         my $is_combined = (@hash_parents > 1);
4412         my $patch_idx = 0;
4413         my $patch_number = 0;
4414         my $patch_line;
4415         my $diffinfo;
4416         my $to_name;
4417         my (%from, %to);
4418
4419         print "<div class=\"patchset\">\n";
4420
4421         # skip to first patch
4422         while ($patch_line = <$fd>) {
4423                 chomp $patch_line;
4424
4425                 last if ($patch_line =~ m/^diff /);
4426         }
4427
4428  PATCH:
4429         while ($patch_line) {
4430
4431                 # parse "git diff" header line
4432                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4433                         # $1 is from_name, which we do not use
4434                         $to_name = unquote($2);
4435                         $to_name =~ s!^b/!!;
4436                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4437                         # $1 is 'cc' or 'combined', which we do not use
4438                         $to_name = unquote($2);
4439                 } else {
4440                         $to_name = undef;
4441                 }
4442
4443                 # check if current patch belong to current raw line
4444                 # and parse raw git-diff line if needed
4445                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4446                         # this is continuation of a split patch
4447                         print "<div class=\"patch cont\">\n";
4448                 } else {
4449                         # advance raw git-diff output if needed
4450                         $patch_idx++ if defined $diffinfo;
4451
4452                         # read and prepare patch information
4453                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4454
4455                         # compact combined diff output can have some patches skipped
4456                         # find which patch (using pathname of result) we are at now;
4457                         if ($is_combined) {
4458                                 while ($to_name ne $diffinfo->{'to_file'}) {
4459                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4460                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4461                                               "</div>\n";  # class="patch"
4462
4463                                         $patch_idx++;
4464                                         $patch_number++;
4465
4466                                         last if $patch_idx > $#$difftree;
4467                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4468                                 }
4469                         }
4470
4471                         # modifies %from, %to hashes
4472                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
4473
4474                         # this is first patch for raw difftree line with $patch_idx index
4475                         # we index @$difftree array from 0, but number patches from 1
4476                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
4477                 }
4478
4479                 # git diff header
4480                 #assert($patch_line =~ m/^diff /) if DEBUG;
4481                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
4482                 $patch_number++;
4483                 # print "git diff" header
4484                 print format_git_diff_header_line($patch_line, $diffinfo,
4485                                                   \%from, \%to);
4486
4487                 # print extended diff header
4488                 print "<div class=\"diff extended_header\">\n";
4489         EXTENDED_HEADER:
4490                 while ($patch_line = <$fd>) {
4491                         chomp $patch_line;
4492
4493                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
4494
4495                         print format_extended_diff_header_line($patch_line, $diffinfo,
4496                                                                \%from, \%to);
4497                 }
4498                 print "</div>\n"; # class="diff extended_header"
4499
4500                 # from-file/to-file diff header
4501                 if (! $patch_line) {
4502                         print "</div>\n"; # class="patch"
4503                         last PATCH;
4504                 }
4505                 next PATCH if ($patch_line =~ m/^diff /);
4506                 #assert($patch_line =~ m/^---/) if DEBUG;
4507
4508                 my $last_patch_line = $patch_line;
4509                 $patch_line = <$fd>;
4510                 chomp $patch_line;
4511                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
4512
4513                 print format_diff_from_to_header($last_patch_line, $patch_line,
4514                                                  $diffinfo, \%from, \%to,
4515                                                  @hash_parents);
4516
4517                 # the patch itself
4518         LINE:
4519                 while ($patch_line = <$fd>) {
4520                         chomp $patch_line;
4521
4522                         next PATCH if ($patch_line =~ m/^diff /);
4523
4524                         print format_diff_line($patch_line, \%from, \%to);
4525                 }
4526
4527         } continue {
4528                 print "</div>\n"; # class="patch"
4529         }
4530
4531         # for compact combined (--cc) format, with chunk and patch simplification
4532         # the patchset might be empty, but there might be unprocessed raw lines
4533         for (++$patch_idx if $patch_number > 0;
4534              $patch_idx < @$difftree;
4535              ++$patch_idx) {
4536                 # read and prepare patch information
4537                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4538
4539                 # generate anchor for "patch" links in difftree / whatchanged part
4540                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4541                       format_diff_cc_simplified($diffinfo, @hash_parents) .
4542                       "</div>\n";  # class="patch"
4543
4544                 $patch_number++;
4545         }
4546
4547         if ($patch_number == 0) {
4548                 if (@hash_parents > 1) {
4549                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
4550                 } else {
4551                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
4552                 }
4553         }
4554
4555         print "</div>\n"; # class="patchset"
4556 }
4557
4558 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
4559
4560 # fills project list info (age, description, owner, forks) for each
4561 # project in the list, removing invalid projects from returned list
4562 # NOTE: modifies $projlist, but does not remove entries from it
4563 sub fill_project_list_info {
4564         my ($projlist, $check_forks) = @_;
4565         my @projects;
4566
4567         my $show_ctags = gitweb_check_feature('ctags');
4568  PROJECT:
4569         foreach my $pr (@$projlist) {
4570                 my (@activity) = git_get_last_activity($pr->{'path'});
4571                 unless (@activity) {
4572                         next PROJECT;
4573                 }
4574                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
4575                 if (!defined $pr->{'descr'}) {
4576                         my $descr = git_get_project_description($pr->{'path'}) || "";
4577                         $descr = to_utf8($descr);
4578                         $pr->{'descr_long'} = $descr;
4579                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
4580                 }
4581                 if (!defined $pr->{'owner'}) {
4582                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
4583                 }
4584                 if ($check_forks) {
4585                         my $pname = $pr->{'path'};
4586                         if (($pname =~ s/\.git$//) &&
4587                             ($pname !~ /\/$/) &&
4588                             (-d "$projectroot/$pname")) {
4589                                 $pr->{'forks'} = "-d $projectroot/$pname";
4590                         } else {
4591                                 $pr->{'forks'} = 0;
4592                         }
4593                 }
4594                 $show_ctags and $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
4595                 push @projects, $pr;
4596         }
4597
4598         return @projects;
4599 }
4600
4601 # print 'sort by' <th> element, generating 'sort by $name' replay link
4602 # if that order is not selected
4603 sub print_sort_th {
4604         print format_sort_th(@_);
4605 }
4606
4607 sub format_sort_th {
4608         my ($name, $order, $header) = @_;
4609         my $sort_th = "";
4610         $header ||= ucfirst($name);
4611
4612         if ($order eq $name) {
4613                 $sort_th .= "<th>$header</th>\n";
4614         } else {
4615                 $sort_th .= "<th>" .
4616                             $cgi->a({-href => href(-replay=>1, order=>$name),
4617                                      -class => "header"}, $header) .
4618                             "</th>\n";
4619         }
4620
4621         return $sort_th;
4622 }
4623
4624 sub git_project_list_body {
4625         # actually uses global variable $project
4626         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
4627
4628         my $check_forks = gitweb_check_feature('forks');
4629         my @projects = fill_project_list_info($projlist, $check_forks);
4630
4631         $order ||= $default_projects_order;
4632         $from = 0 unless defined $from;
4633         $to = $#projects if (!defined $to || $#projects < $to);
4634
4635         my %order_info = (
4636                 project => { key => 'path', type => 'str' },
4637                 descr => { key => 'descr_long', type => 'str' },
4638                 owner => { key => 'owner', type => 'str' },
4639                 age => { key => 'age', type => 'num' }
4640         );
4641         my $oi = $order_info{$order};
4642         if ($oi->{'type'} eq 'str') {
4643                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @projects;
4644         } else {
4645                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @projects;
4646         }
4647
4648         my $show_ctags = gitweb_check_feature('ctags');
4649         if ($show_ctags) {
4650                 my %ctags;
4651                 foreach my $p (@projects) {
4652                         foreach my $ct (keys %{$p->{'ctags'}}) {
4653                                 $ctags{$ct} += $p->{'ctags'}->{$ct};
4654                         }
4655                 }
4656                 my $cloud = git_populate_project_tagcloud(\%ctags);
4657                 print git_show_project_tagcloud($cloud, 64);
4658         }
4659
4660         print "<table class=\"project_list\">\n";
4661         unless ($no_header) {
4662                 print "<tr>\n";
4663                 if ($check_forks) {
4664                         print "<th></th>\n";
4665                 }
4666                 print_sort_th('project', $order, 'Project');
4667                 print_sort_th('descr', $order, 'Description');
4668                 print_sort_th('owner', $order, 'Owner');
4669                 print_sort_th('age', $order, 'Last Change');
4670                 print "<th></th>\n" . # for links
4671                       "</tr>\n";
4672         }
4673         my $alternate = 1;
4674         my $tagfilter = $cgi->param('by_tag');
4675         for (my $i = $from; $i <= $to; $i++) {
4676                 my $pr = $projects[$i];
4677
4678                 next if $tagfilter and $show_ctags and not grep { lc $_ eq lc $tagfilter } keys %{$pr->{'ctags'}};
4679                 next if $searchtext and not $pr->{'path'} =~ /$searchtext/
4680                         and not $pr->{'descr_long'} =~ /$searchtext/;
4681                 # Weed out forks or non-matching entries of search
4682                 if ($check_forks) {
4683                         my $forkbase = $project; $forkbase ||= ''; $forkbase =~ s#\.git$#/#;
4684                         $forkbase="^$forkbase" if $forkbase;
4685                         next if not $searchtext and not $tagfilter and $show_ctags
4686                                 and $pr->{'path'} =~ m#$forkbase.*/.*#; # regexp-safe
4687                 }
4688
4689                 if ($alternate) {
4690                         print "<tr class=\"dark\">\n";
4691                 } else {
4692                         print "<tr class=\"light\">\n";
4693                 }
4694                 $alternate ^= 1;
4695                 if ($check_forks) {
4696                         print "<td>";
4697                         if ($pr->{'forks'}) {
4698                                 print "<!-- $pr->{'forks'} -->\n";
4699                                 print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "+");
4700                         }
4701                         print "</td>\n";
4702                 }
4703                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4704                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
4705                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4706                                         -class => "list", -title => $pr->{'descr_long'}},
4707                                         esc_html($pr->{'descr'})) . "</td>\n" .
4708                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
4709                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
4710                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
4711                       "<td class=\"link\">" .
4712                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
4713                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
4714                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
4715                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
4716                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
4717                       "</td>\n" .
4718                       "</tr>\n";
4719         }
4720         if (defined $extra) {
4721                 print "<tr>\n";
4722                 if ($check_forks) {
4723                         print "<td></td>\n";
4724                 }
4725                 print "<td colspan=\"5\">$extra</td>\n" .
4726                       "</tr>\n";
4727         }
4728         print "</table>\n";
4729 }
4730
4731 sub git_log_body {
4732         # uses global variable $project
4733         my ($commitlist, $from, $to, $refs, $extra) = @_;
4734
4735         $from = 0 unless defined $from;
4736         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4737
4738         for (my $i = 0; $i <= $to; $i++) {
4739                 my %co = %{$commitlist->[$i]};
4740                 next if !%co;
4741                 my $commit = $co{'id'};
4742                 my $ref = format_ref_marker($refs, $commit);
4743                 my %ad = parse_date($co{'author_epoch'});
4744                 git_print_header_div('commit',
4745                                "<span class=\"age\">$co{'age_string'}</span>" .
4746                                esc_html($co{'title'}) . $ref,
4747                                $commit);
4748                 print "<div class=\"title_text\">\n" .
4749                       "<div class=\"log_link\">\n" .
4750                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
4751                       " | " .
4752                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
4753                       " | " .
4754                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
4755                       "<br/>\n" .
4756                       "</div>\n";
4757                       git_print_authorship(\%co, -tag => 'span');
4758                       print "<br/>\n</div>\n";
4759
4760                 print "<div class=\"log_body\">\n";
4761                 git_print_log($co{'comment'}, -final_empty_line=> 1);
4762                 print "</div>\n";
4763         }
4764         if ($extra) {
4765                 print "<div class=\"page_nav\">\n";
4766                 print "$extra\n";
4767                 print "</div>\n";
4768         }
4769 }
4770
4771 sub git_shortlog_body {
4772         # uses global variable $project
4773         my ($commitlist, $from, $to, $refs, $extra) = @_;
4774
4775         $from = 0 unless defined $from;
4776         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4777
4778         print "<table class=\"shortlog\">\n";
4779         my $alternate = 1;
4780         for (my $i = $from; $i <= $to; $i++) {
4781                 my %co = %{$commitlist->[$i]};
4782                 my $commit = $co{'id'};
4783                 my $ref = format_ref_marker($refs, $commit);
4784                 if ($alternate) {
4785                         print "<tr class=\"dark\">\n";
4786                 } else {
4787                         print "<tr class=\"light\">\n";
4788                 }
4789                 $alternate ^= 1;
4790                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
4791                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4792                       format_author_html('td', \%co, 10) . "<td>";
4793                 print format_subject_html($co{'title'}, $co{'title_short'},
4794                                           href(action=>"commit", hash=>$commit), $ref);
4795                 print "</td>\n" .
4796                       "<td class=\"link\">" .
4797                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
4798                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
4799                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
4800                 my $snapshot_links = format_snapshot_links($commit);
4801                 if (defined $snapshot_links) {
4802                         print " | " . $snapshot_links;
4803                 }
4804                 print "</td>\n" .
4805                       "</tr>\n";
4806         }
4807         if (defined $extra) {
4808                 print "<tr>\n" .
4809                       "<td colspan=\"4\">$extra</td>\n" .
4810                       "</tr>\n";
4811         }
4812         print "</table>\n";
4813 }
4814
4815 sub git_history_body {
4816         # Warning: assumes constant type (blob or tree) during history
4817         my ($commitlist, $from, $to, $refs, $extra,
4818             $file_name, $file_hash, $ftype) = @_;
4819
4820         $from = 0 unless defined $from;
4821         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
4822
4823         print "<table class=\"history\">\n";
4824         my $alternate = 1;
4825         for (my $i = $from; $i <= $to; $i++) {
4826                 my %co = %{$commitlist->[$i]};
4827                 if (!%co) {
4828                         next;
4829                 }
4830                 my $commit = $co{'id'};
4831
4832                 my $ref = format_ref_marker($refs, $commit);
4833
4834                 if ($alternate) {
4835                         print "<tr class=\"dark\">\n";
4836                 } else {
4837                         print "<tr class=\"light\">\n";
4838                 }
4839                 $alternate ^= 1;
4840                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4841         # shortlog:   format_author_html('td', \%co, 10)
4842                       format_author_html('td', \%co, 15, 3) . "<td>";
4843                 # originally git_history used chop_str($co{'title'}, 50)
4844                 print format_subject_html($co{'title'}, $co{'title_short'},
4845                                           href(action=>"commit", hash=>$commit), $ref);
4846                 print "</td>\n" .
4847                       "<td class=\"link\">" .
4848                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
4849                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
4850
4851                 if ($ftype eq 'blob') {
4852                         my $blob_current = $file_hash;
4853                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
4854                         if (defined $blob_current && defined $blob_parent &&
4855                                         $blob_current ne $blob_parent) {
4856                                 print " | " .
4857                                         $cgi->a({-href => href(action=>"blobdiff",
4858                                                                hash=>$blob_current, hash_parent=>$blob_parent,
4859                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
4860                                                                file_name=>$file_name)},
4861                                                 "diff to current");
4862                         }
4863                 }
4864                 print "</td>\n" .
4865                       "</tr>\n";
4866         }
4867         if (defined $extra) {
4868                 print "<tr>\n" .
4869                       "<td colspan=\"4\">$extra</td>\n" .
4870                       "</tr>\n";
4871         }
4872         print "</table>\n";
4873 }
4874
4875 sub git_tags_body {
4876         # uses global variable $project
4877         my ($taglist, $from, $to, $extra) = @_;
4878         $from = 0 unless defined $from;
4879         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
4880
4881         print "<table class=\"tags\">\n";
4882         my $alternate = 1;
4883         for (my $i = $from; $i <= $to; $i++) {
4884                 my $entry = $taglist->[$i];
4885                 my %tag = %$entry;
4886                 my $comment = $tag{'subject'};
4887                 my $comment_short;
4888                 if (defined $comment) {
4889                         $comment_short = chop_str($comment, 30, 5);
4890                 }
4891                 if ($alternate) {
4892                         print "<tr class=\"dark\">\n";
4893                 } else {
4894                         print "<tr class=\"light\">\n";
4895                 }
4896                 $alternate ^= 1;
4897                 if (defined $tag{'age'}) {
4898                         print "<td><i>$tag{'age'}</i></td>\n";
4899                 } else {
4900                         print "<td></td>\n";
4901                 }
4902                 print "<td>" .
4903                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
4904                                -class => "list name"}, esc_html($tag{'name'})) .
4905                       "</td>\n" .
4906                       "<td>";
4907                 if (defined $comment) {
4908                         print format_subject_html($comment, $comment_short,
4909                                                   href(action=>"tag", hash=>$tag{'id'}));
4910                 }
4911                 print "</td>\n" .
4912                       "<td class=\"selflink\">";
4913                 if ($tag{'type'} eq "tag") {
4914                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
4915                 } else {
4916                         print "&nbsp;";
4917                 }
4918                 print "</td>\n" .
4919                       "<td class=\"link\">" . " | " .
4920                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
4921                 if ($tag{'reftype'} eq "commit") {
4922                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
4923                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
4924                 } elsif ($tag{'reftype'} eq "blob") {
4925                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
4926                 }
4927                 print "</td>\n" .
4928                       "</tr>";
4929         }
4930         if (defined $extra) {
4931                 print "<tr>\n" .
4932                       "<td colspan=\"5\">$extra</td>\n" .
4933                       "</tr>\n";
4934         }
4935         print "</table>\n";
4936 }
4937
4938 sub git_heads_body {
4939         # uses global variable $project
4940         my ($headlist, $head, $from, $to, $extra) = @_;
4941         $from = 0 unless defined $from;
4942         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
4943
4944         print "<table class=\"heads\">\n";
4945         my $alternate = 1;
4946         for (my $i = $from; $i <= $to; $i++) {
4947                 my $entry = $headlist->[$i];
4948                 my %ref = %$entry;
4949                 my $curr = $ref{'id'} eq $head;
4950                 if ($alternate) {
4951                         print "<tr class=\"dark\">\n";
4952                 } else {
4953                         print "<tr class=\"light\">\n";
4954                 }
4955                 $alternate ^= 1;
4956                 print "<td><i>$ref{'age'}</i></td>\n" .
4957                       ($curr ? "<td class=\"current_head\">" : "<td>") .
4958                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
4959                                -class => "list name"},esc_html($ref{'name'})) .
4960                       "</td>\n" .
4961                       "<td class=\"link\">" .
4962                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
4963                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
4964                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'name'})}, "tree") .
4965                       "</td>\n" .
4966                       "</tr>";
4967         }
4968         if (defined $extra) {
4969                 print "<tr>\n" .
4970                       "<td colspan=\"3\">$extra</td>\n" .
4971                       "</tr>\n";
4972         }
4973         print "</table>\n";
4974 }
4975
4976 sub git_search_grep_body {
4977         my ($commitlist, $from, $to, $extra) = @_;
4978         $from = 0 unless defined $from;
4979         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4980
4981         print "<table class=\"commit_search\">\n";
4982         my $alternate = 1;
4983         for (my $i = $from; $i <= $to; $i++) {
4984                 my %co = %{$commitlist->[$i]};
4985                 if (!%co) {
4986                         next;
4987                 }
4988                 my $commit = $co{'id'};
4989                 if ($alternate) {
4990                         print "<tr class=\"dark\">\n";
4991                 } else {
4992                         print "<tr class=\"light\">\n";
4993                 }
4994                 $alternate ^= 1;
4995                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4996                       format_author_html('td', \%co, 15, 5) .
4997                       "<td>" .
4998                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
4999                                -class => "list subject"},
5000                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5001                 my $comment = $co{'comment'};
5002                 foreach my $line (@$comment) {
5003                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5004                                 my ($lead, $match, $trail) = ($1, $2, $3);
5005                                 $match = chop_str($match, 70, 5, 'center');
5006                                 my $contextlen = int((80 - length($match))/2);
5007                                 $contextlen = 30 if ($contextlen > 30);
5008                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5009                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5010
5011                                 $lead  = esc_html($lead);
5012                                 $match = esc_html($match);
5013                                 $trail = esc_html($trail);
5014
5015                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5016                         }
5017                 }
5018                 print "</td>\n" .
5019                       "<td class=\"link\">" .
5020                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5021                       " | " .
5022                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5023                       " | " .
5024                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5025                 print "</td>\n" .
5026                       "</tr>\n";
5027         }
5028         if (defined $extra) {
5029                 print "<tr>\n" .
5030                       "<td colspan=\"3\">$extra</td>\n" .
5031                       "</tr>\n";
5032         }
5033         print "</table>\n";
5034 }
5035
5036 ## ======================================================================
5037 ## ======================================================================
5038 ## actions
5039
5040 sub git_project_list {
5041         my $order = $input_params{'order'};
5042         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5043                 die_error(400, "Unknown order parameter");
5044         }
5045
5046         my @list = git_get_projects_list();
5047         if (!@list) {
5048                 die_error(404, "No projects found");
5049         }
5050
5051         git_header_html();
5052         if (defined $home_text && -f $home_text) {
5053                 print "<div class=\"index_include\">\n";
5054                 insert_file($home_text);
5055                 print "</div>\n";
5056         }
5057         print $cgi->startform(-method => "get") .
5058               "<p class=\"projsearch\">Search:\n" .
5059               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5060               "</p>" .
5061               $cgi->end_form() . "\n";
5062         git_project_list_body(\@list, $order);
5063         git_footer_html();
5064 }
5065
5066 sub git_forks {
5067         my $order = $input_params{'order'};
5068         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5069                 die_error(400, "Unknown order parameter");
5070         }
5071
5072         my @list = git_get_projects_list($project);
5073         if (!@list) {
5074                 die_error(404, "No forks found");
5075         }
5076
5077         git_header_html();
5078         git_print_page_nav('','');
5079         git_print_header_div('summary', "$project forks");
5080         git_project_list_body(\@list, $order);
5081         git_footer_html();
5082 }
5083
5084 sub git_project_index {
5085         my @projects = git_get_projects_list($project);
5086
5087         print $cgi->header(
5088                 -type => 'text/plain',
5089                 -charset => 'utf-8',
5090                 -content_disposition => 'inline; filename="index.aux"');
5091
5092         foreach my $pr (@projects) {
5093                 if (!exists $pr->{'owner'}) {
5094                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
5095                 }
5096
5097                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
5098                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
5099                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5100                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5101                 $path  =~ s/ /\+/g;
5102                 $owner =~ s/ /\+/g;
5103
5104                 print "$path $owner\n";
5105         }
5106 }
5107
5108 sub git_summary {
5109         my $descr = git_get_project_description($project) || "none";
5110         my %co = parse_commit("HEAD");
5111         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
5112         my $head = $co{'id'};
5113
5114         my $owner = git_get_project_owner($project);
5115
5116         my $refs = git_get_references();
5117         # These get_*_list functions return one more to allow us to see if
5118         # there are more ...
5119         my @taglist  = git_get_tags_list(16);
5120         my @headlist = git_get_heads_list(16);
5121         my @forklist;
5122         my $check_forks = gitweb_check_feature('forks');
5123
5124         if ($check_forks) {
5125                 @forklist = git_get_projects_list($project);
5126         }
5127
5128         git_header_html();
5129         git_print_page_nav('summary','', $head);
5130
5131         print "<div class=\"title\">&nbsp;</div>\n";
5132         print "<table class=\"projects_list\">\n" .
5133               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
5134               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
5135         if (defined $cd{'rfc2822'}) {
5136                 print "<tr id=\"metadata_lchange\"><td>last change</td><td>$cd{'rfc2822'}</td></tr>\n";
5137         }
5138
5139         # use per project git URL list in $projectroot/$project/cloneurl
5140         # or make project git URL from git base URL and project name
5141         my $url_tag = "URL";
5142         my @url_list = git_get_project_url_list($project);
5143         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
5144         foreach my $git_url (@url_list) {
5145                 next unless $git_url;
5146                 print "<tr class=\"metadata_url\"><td>$url_tag</td><td>$git_url</td></tr>\n";
5147                 $url_tag = "";
5148         }
5149
5150         # Tag cloud
5151         my $show_ctags = gitweb_check_feature('ctags');
5152         if ($show_ctags) {
5153                 my $ctags = git_get_project_ctags($project);
5154                 my $cloud = git_populate_project_tagcloud($ctags);
5155                 print "<tr id=\"metadata_ctags\"><td>Content tags:<br />";
5156                 print "</td>\n<td>" unless %$ctags;
5157                 print "<form action=\"$show_ctags\" method=\"post\"><input type=\"hidden\" name=\"p\" value=\"$project\" />Add: <input type=\"text\" name=\"t\" size=\"8\" /></form>";
5158                 print "</td>\n<td>" if %$ctags;
5159                 print git_show_project_tagcloud($cloud, 48);
5160                 print "</td></tr>";
5161         }
5162
5163         print "</table>\n";
5164
5165         # If XSS prevention is on, we don't include README.html.
5166         # TODO: Allow a readme in some safe format.
5167         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
5168                 print "<div class=\"title\">readme</div>\n" .
5169                       "<div class=\"readme\">\n";
5170                 insert_file("$projectroot/$project/README.html");
5171                 print "\n</div>\n"; # class="readme"
5172         }
5173
5174         # we need to request one more than 16 (0..15) to check if
5175         # those 16 are all
5176         my @commitlist = $head ? parse_commits($head, 17) : ();
5177         if (@commitlist) {
5178                 git_print_header_div('shortlog');
5179                 git_shortlog_body(\@commitlist, 0, 15, $refs,
5180                                   $#commitlist <=  15 ? undef :
5181                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
5182         }
5183
5184         if (@taglist) {
5185                 git_print_header_div('tags');
5186                 git_tags_body(\@taglist, 0, 15,
5187                               $#taglist <=  15 ? undef :
5188                               $cgi->a({-href => href(action=>"tags")}, "..."));
5189         }
5190
5191         if (@headlist) {
5192                 git_print_header_div('heads');
5193                 git_heads_body(\@headlist, $head, 0, 15,
5194                                $#headlist <= 15 ? undef :
5195                                $cgi->a({-href => href(action=>"heads")}, "..."));
5196         }
5197
5198         if (@forklist) {
5199                 git_print_header_div('forks');
5200                 git_project_list_body(\@forklist, 'age', 0, 15,
5201                                       $#forklist <= 15 ? undef :
5202                                       $cgi->a({-href => href(action=>"forks")}, "..."),
5203                                       'no_header');
5204         }
5205
5206         git_footer_html();
5207 }
5208
5209 sub git_tag {
5210         my %tag = parse_tag($hash);
5211
5212         if (! %tag) {
5213                 die_error(404, "Unknown tag object");
5214         }
5215
5216         my $head = git_get_head_hash($project);
5217         git_header_html();
5218         git_print_page_nav('','', $head,undef,$head);
5219         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
5220         print "<div class=\"title_text\">\n" .
5221               "<table class=\"object_header\">\n" .
5222               "<tr>\n" .
5223               "<td>object</td>\n" .
5224               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5225                                $tag{'object'}) . "</td>\n" .
5226               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5227                                               $tag{'type'}) . "</td>\n" .
5228               "</tr>\n";
5229         if (defined($tag{'author'})) {
5230                 git_print_authorship_rows(\%tag, 'author');
5231         }
5232         print "</table>\n\n" .
5233               "</div>\n";
5234         print "<div class=\"page_body\">";
5235         my $comment = $tag{'comment'};
5236         foreach my $line (@$comment) {
5237                 chomp $line;
5238                 print esc_html($line, -nbsp=>1) . "<br/>\n";
5239         }
5240         print "</div>\n";
5241         git_footer_html();
5242 }
5243
5244 sub git_blame_common {
5245         my $format = shift || 'porcelain';
5246         if ($format eq 'porcelain' && $cgi->param('js')) {
5247                 $format = 'incremental';
5248                 $action = 'blame_incremental'; # for page title etc
5249         }
5250
5251         # permissions
5252         gitweb_check_feature('blame')
5253                 or die_error(403, "Blame view not allowed");
5254
5255         # error checking
5256         die_error(400, "No file name given") unless $file_name;
5257         $hash_base ||= git_get_head_hash($project);
5258         die_error(404, "Couldn't find base commit") unless $hash_base;
5259         my %co = parse_commit($hash_base)
5260                 or die_error(404, "Commit not found");
5261         my $ftype = "blob";
5262         if (!defined $hash) {
5263                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
5264                         or die_error(404, "Error looking up file");
5265         } else {
5266                 $ftype = git_get_type($hash);
5267                 if ($ftype !~ "blob") {
5268                         die_error(400, "Object is not a blob");
5269                 }
5270         }
5271
5272         my $fd;
5273         if ($format eq 'incremental') {
5274                 # get file contents (as base)
5275                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
5276                         or die_error(500, "Open git-cat-file failed");
5277         } elsif ($format eq 'data') {
5278                 # run git-blame --incremental
5279                 open $fd, "-|", git_cmd(), "blame", "--incremental",
5280                         $hash_base, "--", $file_name
5281                         or die_error(500, "Open git-blame --incremental failed");
5282         } else {
5283                 # run git-blame --porcelain
5284                 open $fd, "-|", git_cmd(), "blame", '-p',
5285                         $hash_base, '--', $file_name
5286                         or die_error(500, "Open git-blame --porcelain failed");
5287         }
5288
5289         # incremental blame data returns early
5290         if ($format eq 'data') {
5291                 print $cgi->header(
5292                         -type=>"text/plain", -charset => "utf-8",
5293                         -status=> "200 OK");
5294                 local $| = 1; # output autoflush
5295                 print while <$fd>;
5296                 close $fd
5297                         or print "ERROR $!\n";
5298
5299                 print 'END';
5300                 if (defined $t0 && gitweb_check_feature('timed')) {
5301                         print ' '.
5302                               Time::HiRes::tv_interval($t0, [Time::HiRes::gettimeofday()]).
5303                               ' '.$number_of_git_cmds;
5304                 }
5305                 print "\n";
5306
5307                 return;
5308         }
5309
5310         # page header
5311         git_header_html();
5312         my $formats_nav =
5313                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
5314                         "blob") .
5315                 " | ";
5316         if ($format eq 'incremental') {
5317                 $formats_nav .=
5318                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
5319                                 "blame") . " (non-incremental)";
5320         } else {
5321                 $formats_nav .=
5322                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
5323                                 "blame") . " (incremental)";
5324         }
5325         $formats_nav .=
5326                 " | " .
5327                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5328                         "history") .
5329                 " | " .
5330                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
5331                         "HEAD");
5332         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5333         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5334         git_print_page_path($file_name, $ftype, $hash_base);
5335
5336         # page body
5337         if ($format eq 'incremental') {
5338                 print "<noscript>\n<div class=\"error\"><center><b>\n".
5339                       "This page requires JavaScript to run.\n Use ".
5340                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
5341                               'this page').
5342                       " instead.\n".
5343                       "</b></center></div>\n</noscript>\n";
5344
5345                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
5346         }
5347
5348         print qq!<div class="page_body">\n!;
5349         print qq!<div id="progress_info">... / ...</div>\n!
5350                 if ($format eq 'incremental');
5351         print qq!<table id="blame_table" class="blame" width="100%">\n!.
5352               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
5353               qq!<thead>\n!.
5354               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
5355               qq!</thead>\n!.
5356               qq!<tbody>\n!;
5357
5358         my @rev_color = qw(light dark);
5359         my $num_colors = scalar(@rev_color);
5360         my $current_color = 0;
5361
5362         if ($format eq 'incremental') {
5363                 my $color_class = $rev_color[$current_color];
5364
5365                 #contents of a file
5366                 my $linenr = 0;
5367         LINE:
5368                 while (my $line = <$fd>) {
5369                         chomp $line;
5370                         $linenr++;
5371
5372                         print qq!<tr id="l$linenr" class="$color_class">!.
5373                               qq!<td class="sha1"><a href=""> </a></td>!.
5374                               qq!<td class="linenr">!.
5375                               qq!<a class="linenr" href="">$linenr</a></td>!;
5376                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
5377                         print qq!</tr>\n!;
5378                 }
5379
5380         } else { # porcelain, i.e. ordinary blame
5381                 my %metainfo = (); # saves information about commits
5382
5383                 # blame data
5384         LINE:
5385                 while (my $line = <$fd>) {
5386                         chomp $line;
5387                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
5388                         # no <lines in group> for subsequent lines in group of lines
5389                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
5390                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
5391                         if (!exists $metainfo{$full_rev}) {
5392                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
5393                         }
5394                         my $meta = $metainfo{$full_rev};
5395                         my $data;
5396                         while ($data = <$fd>) {
5397                                 chomp $data;
5398                                 last if ($data =~ s/^\t//); # contents of line
5399                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
5400                                         $meta->{$1} = $2 unless exists $meta->{$1};
5401                                 }
5402                                 if ($data =~ /^previous /) {
5403                                         $meta->{'nprevious'}++;
5404                                 }
5405                         }
5406                         my $short_rev = substr($full_rev, 0, 8);
5407                         my $author = $meta->{'author'};
5408                         my %date =
5409                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
5410                         my $date = $date{'iso-tz'};
5411                         if ($group_size) {
5412                                 $current_color = ($current_color + 1) % $num_colors;
5413                         }
5414                         my $tr_class = $rev_color[$current_color];
5415                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
5416                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
5417                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
5418                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
5419                         if ($group_size) {
5420                                 print "<td class=\"sha1\"";
5421                                 print " title=\"". esc_html($author) . ", $date\"";
5422                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
5423                                 print ">";
5424                                 print $cgi->a({-href => href(action=>"commit",
5425                                                              hash=>$full_rev,
5426                                                              file_name=>$file_name)},
5427                                               esc_html($short_rev));
5428                                 if ($group_size >= 2) {
5429                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
5430                                         if (@author_initials) {
5431                                                 print "<br />" .
5432                                                       esc_html(join('', @author_initials));
5433                                                 #           or join('.', ...)
5434                                         }
5435                                 }
5436                                 print "</td>\n";
5437                         }
5438                         # 'previous' <sha1 of parent commit> <filename at commit>
5439                         if (exists $meta->{'previous'} &&
5440                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
5441                                 $meta->{'parent'} = $1;
5442                                 $meta->{'file_parent'} = unquote($2);
5443                         }
5444                         my $linenr_commit =
5445                                 exists($meta->{'parent'}) ?
5446                                 $meta->{'parent'} : $full_rev;
5447                         my $linenr_filename =
5448                                 exists($meta->{'file_parent'}) ?
5449                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
5450                         my $blamed = href(action => 'blame',
5451                                           file_name => $linenr_filename,
5452                                           hash_base => $linenr_commit);
5453                         print "<td class=\"linenr\">";
5454                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
5455                                         -class => "linenr" },
5456                                       esc_html($lineno));
5457                         print "</td>";
5458                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
5459                         print "</tr>\n";
5460                 } # end while
5461
5462         }
5463
5464         # footer
5465         print "</tbody>\n".
5466               "</table>\n"; # class="blame"
5467         print "</div>\n";   # class="blame_body"
5468         close $fd
5469                 or print "Reading blob failed\n";
5470
5471         git_footer_html();
5472 }
5473
5474 sub git_blame {
5475         git_blame_common();
5476 }
5477
5478 sub git_blame_incremental {
5479         git_blame_common('incremental');
5480 }
5481
5482 sub git_blame_data {
5483         git_blame_common('data');
5484 }
5485
5486 sub git_tags {
5487         my $head = git_get_head_hash($project);
5488         git_header_html();
5489         git_print_page_nav('','', $head,undef,$head);
5490         git_print_header_div('summary', $project);
5491
5492         my @tagslist = git_get_tags_list();
5493         if (@tagslist) {
5494                 git_tags_body(\@tagslist);
5495         }
5496         git_footer_html();
5497 }
5498
5499 sub git_heads {
5500         my $head = git_get_head_hash($project);
5501         git_header_html();
5502         git_print_page_nav('','', $head,undef,$head);
5503         git_print_header_div('summary', $project);
5504
5505         my @headslist = git_get_heads_list();
5506         if (@headslist) {
5507                 git_heads_body(\@headslist, $head);
5508         }
5509         git_footer_html();
5510 }
5511
5512 sub git_blob_plain {
5513         my $type = shift;
5514         my $expires;
5515
5516         if (!defined $hash) {
5517                 if (defined $file_name) {
5518                         my $base = $hash_base || git_get_head_hash($project);
5519                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5520                                 or die_error(404, "Cannot find file");
5521                 } else {
5522                         die_error(400, "No file name defined");
5523                 }
5524         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5525                 # blobs defined by non-textual hash id's can be cached
5526                 $expires = "+1d";
5527         }
5528
5529         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5530                 or die_error(500, "Open git-cat-file blob '$hash' failed");
5531
5532         # content-type (can include charset)
5533         $type = blob_contenttype($fd, $file_name, $type);
5534
5535         # "save as" filename, even when no $file_name is given
5536         my $save_as = "$hash";
5537         if (defined $file_name) {
5538                 $save_as = $file_name;
5539         } elsif ($type =~ m/^text\//) {
5540                 $save_as .= '.txt';
5541         }
5542
5543         # With XSS prevention on, blobs of all types except a few known safe
5544         # ones are served with "Content-Disposition: attachment" to make sure
5545         # they don't run in our security domain.  For certain image types,
5546         # blob view writes an <img> tag referring to blob_plain view, and we
5547         # want to be sure not to break that by serving the image as an
5548         # attachment (though Firefox 3 doesn't seem to care).
5549         my $sandbox = $prevent_xss &&
5550                 $type !~ m!^(?:text/plain|image/(?:gif|png|jpeg))$!;
5551
5552         print $cgi->header(
5553                 -type => $type,
5554                 -expires => $expires,
5555                 -content_disposition =>
5556                         ($sandbox ? 'attachment' : 'inline')
5557                         . '; filename="' . $save_as . '"');
5558         local $/ = undef;
5559         binmode STDOUT, ':raw';
5560         print <$fd>;
5561         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
5562         close $fd;
5563 }
5564
5565 sub git_blob {
5566         my $expires;
5567
5568         if (!defined $hash) {
5569                 if (defined $file_name) {
5570                         my $base = $hash_base || git_get_head_hash($project);
5571                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5572                                 or die_error(404, "Cannot find file");
5573                 } else {
5574                         die_error(400, "No file name defined");
5575                 }
5576         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5577                 # blobs defined by non-textual hash id's can be cached
5578                 $expires = "+1d";
5579         }
5580
5581         my $have_blame = gitweb_check_feature('blame');
5582         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5583                 or die_error(500, "Couldn't cat $file_name, $hash");
5584         my $mimetype = blob_mimetype($fd, $file_name);
5585         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
5586         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
5587                 close $fd;
5588                 return git_blob_plain($mimetype);
5589         }
5590         # we can have blame only for text/* mimetype
5591         $have_blame &&= ($mimetype =~ m!^text/!);
5592
5593         my $highlight = gitweb_check_feature('highlight');
5594         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
5595         $fd = run_highlighter($fd, $highlight, $syntax)
5596                 if $syntax;
5597
5598         git_header_html(undef, $expires);
5599         my $formats_nav = '';
5600         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5601                 if (defined $file_name) {
5602                         if ($have_blame) {
5603                                 $formats_nav .=
5604                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
5605                                                 "blame") .
5606                                         " | ";
5607                         }
5608                         $formats_nav .=
5609                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5610                                         "history") .
5611                                 " | " .
5612                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5613                                         "raw") .
5614                                 " | " .
5615                                 $cgi->a({-href => href(action=>"blob",
5616                                                        hash_base=>"HEAD", file_name=>$file_name)},
5617                                         "HEAD");
5618                 } else {
5619                         $formats_nav .=
5620                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5621                                         "raw");
5622                 }
5623                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5624                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5625         } else {
5626                 print "<div class=\"page_nav\">\n" .
5627                       "<br/><br/></div>\n" .
5628                       "<div class=\"title\">$hash</div>\n";
5629         }
5630         git_print_page_path($file_name, "blob", $hash_base);
5631         print "<div class=\"page_body\">\n";
5632         if ($mimetype =~ m!^image/!) {
5633                 print qq!<img type="$mimetype"!;
5634                 if ($file_name) {
5635                         print qq! alt="$file_name" title="$file_name"!;
5636                 }
5637                 print qq! src="! .
5638                       href(action=>"blob_plain", hash=>$hash,
5639                            hash_base=>$hash_base, file_name=>$file_name) .
5640                       qq!" />\n!;
5641         } else {
5642                 my $nr;
5643                 while (my $line = <$fd>) {
5644                         chomp $line;
5645                         $nr++;
5646                         $line = untabify($line);
5647                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
5648                                $nr, href(-replay => 1), $nr, $nr, $syntax ? $line : esc_html($line, -nbsp=>1);
5649                 }
5650         }
5651         close $fd
5652                 or print "Reading blob failed.\n";
5653         print "</div>";
5654         git_footer_html();
5655 }
5656
5657 sub git_tree {
5658         if (!defined $hash_base) {
5659                 $hash_base = "HEAD";
5660         }
5661         if (!defined $hash) {
5662                 if (defined $file_name) {
5663                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
5664                 } else {
5665                         $hash = $hash_base;
5666                 }
5667         }
5668         die_error(404, "No such tree") unless defined($hash);
5669
5670         my $show_sizes = gitweb_check_feature('show-sizes');
5671         my $have_blame = gitweb_check_feature('blame');
5672
5673         my @entries = ();
5674         {
5675                 local $/ = "\0";
5676                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
5677                         ($show_sizes ? '-l' : ()), @extra_options, $hash
5678                         or die_error(500, "Open git-ls-tree failed");
5679                 @entries = map { chomp; $_ } <$fd>;
5680                 close $fd
5681                         or die_error(404, "Reading tree failed");
5682         }
5683
5684         my $refs = git_get_references();
5685         my $ref = format_ref_marker($refs, $hash_base);
5686         git_header_html();
5687         my $basedir = '';
5688         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5689                 my @views_nav = ();
5690                 if (defined $file_name) {
5691                         push @views_nav,
5692                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5693                                         "history"),
5694                                 $cgi->a({-href => href(action=>"tree",
5695                                                        hash_base=>"HEAD", file_name=>$file_name)},
5696                                         "HEAD"),
5697                 }
5698                 my $snapshot_links = format_snapshot_links($hash);
5699                 if (defined $snapshot_links) {
5700                         # FIXME: Should be available when we have no hash base as well.
5701                         push @views_nav, $snapshot_links;
5702                 }
5703                 git_print_page_nav('tree','', $hash_base, undef, undef,
5704                                    join(' | ', @views_nav));
5705                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
5706         } else {
5707                 undef $hash_base;
5708                 print "<div class=\"page_nav\">\n";
5709                 print "<br/><br/></div>\n";
5710                 print "<div class=\"title\">$hash</div>\n";
5711         }
5712         if (defined $file_name) {
5713                 $basedir = $file_name;
5714                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
5715                         $basedir .= '/';
5716                 }
5717                 git_print_page_path($file_name, 'tree', $hash_base);
5718         }
5719         print "<div class=\"page_body\">\n";
5720         print "<table class=\"tree\">\n";
5721         my $alternate = 1;
5722         # '..' (top directory) link if possible
5723         if (defined $hash_base &&
5724             defined $file_name && $file_name =~ m![^/]+$!) {
5725                 if ($alternate) {
5726                         print "<tr class=\"dark\">\n";
5727                 } else {
5728                         print "<tr class=\"light\">\n";
5729                 }
5730                 $alternate ^= 1;
5731
5732                 my $up = $file_name;
5733                 $up =~ s!/?[^/]+$!!;
5734                 undef $up unless $up;
5735                 # based on git_print_tree_entry
5736                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
5737                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
5738                 print '<td class="list">';
5739                 print $cgi->a({-href => href(action=>"tree",
5740                                              hash_base=>$hash_base,
5741                                              file_name=>$up)},
5742                               "..");
5743                 print "</td>\n";
5744                 print "<td class=\"link\"></td>\n";
5745
5746                 print "</tr>\n";
5747         }
5748         foreach my $line (@entries) {
5749                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
5750
5751                 if ($alternate) {
5752                         print "<tr class=\"dark\">\n";
5753                 } else {
5754                         print "<tr class=\"light\">\n";
5755                 }
5756                 $alternate ^= 1;
5757
5758                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
5759
5760                 print "</tr>\n";
5761         }
5762         print "</table>\n" .
5763               "</div>";
5764         git_footer_html();
5765 }
5766
5767 sub snapshot_name {
5768         my ($project, $hash) = @_;
5769
5770         # path/to/project.git  -> project
5771         # path/to/project/.git -> project
5772         my $name = to_utf8($project);
5773         $name =~ s,([^/])/*\.git$,$1,;
5774         $name = basename($name);
5775         # sanitize name
5776         $name =~ s/[[:cntrl:]]/?/g;
5777
5778         my $ver = $hash;
5779         if ($hash =~ /^[0-9a-fA-F]+$/) {
5780                 # shorten SHA-1 hash
5781                 my $full_hash = git_get_full_hash($project, $hash);
5782                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
5783                         $ver = git_get_short_hash($project, $hash);
5784                 }
5785         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
5786                 # tags don't need shortened SHA-1 hash
5787                 $ver = $1;
5788         } else {
5789                 # branches and other need shortened SHA-1 hash
5790                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
5791                         $ver = $1;
5792                 }
5793                 $ver .= '-' . git_get_short_hash($project, $hash);
5794         }
5795         # in case of hierarchical branch names
5796         $ver =~ s!/!.!g;
5797
5798         # name = project-version_string
5799         $name = "$name-$ver";
5800
5801         return wantarray ? ($name, $name) : $name;
5802 }
5803
5804 sub git_snapshot {
5805         my $format = $input_params{'snapshot_format'};
5806         if (!@snapshot_fmts) {
5807                 die_error(403, "Snapshots not allowed");
5808         }
5809         # default to first supported snapshot format
5810         $format ||= $snapshot_fmts[0];
5811         if ($format !~ m/^[a-z0-9]+$/) {
5812                 die_error(400, "Invalid snapshot format parameter");
5813         } elsif (!exists($known_snapshot_formats{$format})) {
5814                 die_error(400, "Unknown snapshot format");
5815         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
5816                 die_error(403, "Snapshot format not allowed");
5817         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
5818                 die_error(403, "Unsupported snapshot format");
5819         }
5820
5821         my $type = git_get_type("$hash^{}");
5822         if (!$type) {
5823                 die_error(404, 'Object does not exist');
5824         }  elsif ($type eq 'blob') {
5825                 die_error(400, 'Object is not a tree-ish');
5826         }
5827
5828         my ($name, $prefix) = snapshot_name($project, $hash);
5829         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
5830         my $cmd = quote_command(
5831                 git_cmd(), 'archive',
5832                 "--format=$known_snapshot_formats{$format}{'format'}",
5833                 "--prefix=$prefix/", $hash);
5834         if (exists $known_snapshot_formats{$format}{'compressor'}) {
5835                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
5836         }
5837
5838         $filename =~ s/(["\\])/\\$1/g;
5839         print $cgi->header(
5840                 -type => $known_snapshot_formats{$format}{'type'},
5841                 -content_disposition => 'inline; filename="' . $filename . '"',
5842                 -status => '200 OK');
5843
5844         open my $fd, "-|", $cmd
5845                 or die_error(500, "Execute git-archive failed");
5846         binmode STDOUT, ':raw';
5847         print <$fd>;
5848         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
5849         close $fd;
5850 }
5851
5852 sub git_log_generic {
5853         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
5854
5855         my $head = git_get_head_hash($project);
5856         if (!defined $base) {
5857                 $base = $head;
5858         }
5859         if (!defined $page) {
5860                 $page = 0;
5861         }
5862         my $refs = git_get_references();
5863
5864         my $commit_hash = $base;
5865         if (defined $parent) {
5866                 $commit_hash = "$parent..$base";
5867         }
5868         my @commitlist =
5869                 parse_commits($commit_hash, 101, (100 * $page),
5870                               defined $file_name ? ($file_name, "--full-history") : ());
5871
5872         my $ftype;
5873         if (!defined $file_hash && defined $file_name) {
5874                 # some commits could have deleted file in question,
5875                 # and not have it in tree, but one of them has to have it
5876                 for (my $i = 0; $i < @commitlist; $i++) {
5877                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
5878                         last if defined $file_hash;
5879                 }
5880         }
5881         if (defined $file_hash) {
5882                 $ftype = git_get_type($file_hash);
5883         }
5884         if (defined $file_name && !defined $ftype) {
5885                 die_error(500, "Unknown type of object");
5886         }
5887         my %co;
5888         if (defined $file_name) {
5889                 %co = parse_commit($base)
5890                         or die_error(404, "Unknown commit object");
5891         }
5892
5893
5894         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
5895         my $next_link = '';
5896         if ($#commitlist >= 100) {
5897                 $next_link =
5898                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5899                                  -accesskey => "n", -title => "Alt-n"}, "next");
5900         }
5901         my $patch_max = gitweb_get_feature('patches');
5902         if ($patch_max && !defined $file_name) {
5903                 if ($patch_max < 0 || @commitlist <= $patch_max) {
5904                         $paging_nav .= " &sdot; " .
5905                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
5906                                         "patches");
5907                 }
5908         }
5909
5910         git_header_html();
5911         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
5912         if (defined $file_name) {
5913                 git_print_header_div('commit', esc_html($co{'title'}), $base);
5914         } else {
5915                 git_print_header_div('summary', $project)
5916         }
5917         git_print_page_path($file_name, $ftype, $hash_base)
5918                 if (defined $file_name);
5919
5920         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
5921                      $file_name, $file_hash, $ftype);
5922
5923         git_footer_html();
5924 }
5925
5926 sub git_log {
5927         git_log_generic('log', \&git_log_body,
5928                         $hash, $hash_parent);
5929 }
5930
5931 sub git_commit {
5932         $hash ||= $hash_base || "HEAD";
5933         my %co = parse_commit($hash)
5934             or die_error(404, "Unknown commit object");
5935
5936         my $parent  = $co{'parent'};
5937         my $parents = $co{'parents'}; # listref
5938
5939         # we need to prepare $formats_nav before any parameter munging
5940         my $formats_nav;
5941         if (!defined $parent) {
5942                 # --root commitdiff
5943                 $formats_nav .= '(initial)';
5944         } elsif (@$parents == 1) {
5945                 # single parent commit
5946                 $formats_nav .=
5947                         '(parent: ' .
5948                         $cgi->a({-href => href(action=>"commit",
5949                                                hash=>$parent)},
5950                                 esc_html(substr($parent, 0, 7))) .
5951                         ')';
5952         } else {
5953                 # merge commit
5954                 $formats_nav .=
5955                         '(merge: ' .
5956                         join(' ', map {
5957                                 $cgi->a({-href => href(action=>"commit",
5958                                                        hash=>$_)},
5959                                         esc_html(substr($_, 0, 7)));
5960                         } @$parents ) .
5961                         ')';
5962         }
5963         if (gitweb_check_feature('patches') && @$parents <= 1) {
5964                 $formats_nav .= " | " .
5965                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
5966                                 "patch");
5967         }
5968
5969         if (!defined $parent) {
5970                 $parent = "--root";
5971         }
5972         my @difftree;
5973         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
5974                 @diff_opts,
5975                 (@$parents <= 1 ? $parent : '-c'),
5976                 $hash, "--"
5977                 or die_error(500, "Open git-diff-tree failed");
5978         @difftree = map { chomp; $_ } <$fd>;
5979         close $fd or die_error(404, "Reading git-diff-tree failed");
5980
5981         # non-textual hash id's can be cached
5982         my $expires;
5983         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5984                 $expires = "+1d";
5985         }
5986         my $refs = git_get_references();
5987         my $ref = format_ref_marker($refs, $co{'id'});
5988
5989         git_header_html(undef, $expires);
5990         git_print_page_nav('commit', '',
5991                            $hash, $co{'tree'}, $hash,
5992                            $formats_nav);
5993
5994         if (defined $co{'parent'}) {
5995                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
5996         } else {
5997                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
5998         }
5999         print "<div class=\"title_text\">\n" .
6000               "<table class=\"object_header\">\n";
6001         git_print_authorship_rows(\%co);
6002         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6003         print "<tr>" .
6004               "<td>tree</td>" .
6005               "<td class=\"sha1\">" .
6006               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
6007                        class => "list"}, $co{'tree'}) .
6008               "</td>" .
6009               "<td class=\"link\">" .
6010               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
6011                       "tree");
6012         my $snapshot_links = format_snapshot_links($hash);
6013         if (defined $snapshot_links) {
6014                 print " | " . $snapshot_links;
6015         }
6016         print "</td>" .
6017               "</tr>\n";
6018
6019         foreach my $par (@$parents) {
6020                 print "<tr>" .
6021                       "<td>parent</td>" .
6022                       "<td class=\"sha1\">" .
6023                       $cgi->a({-href => href(action=>"commit", hash=>$par),
6024                                class => "list"}, $par) .
6025                       "</td>" .
6026                       "<td class=\"link\">" .
6027                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
6028                       " | " .
6029                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
6030                       "</td>" .
6031                       "</tr>\n";
6032         }
6033         print "</table>".
6034               "</div>\n";
6035
6036         print "<div class=\"page_body\">\n";
6037         git_print_log($co{'comment'});
6038         print "</div>\n";
6039
6040         git_difftree_body(\@difftree, $hash, @$parents);
6041
6042         git_footer_html();
6043 }
6044
6045 sub git_object {
6046         # object is defined by:
6047         # - hash or hash_base alone
6048         # - hash_base and file_name
6049         my $type;
6050
6051         # - hash or hash_base alone
6052         if ($hash || ($hash_base && !defined $file_name)) {
6053                 my $object_id = $hash || $hash_base;
6054
6055                 open my $fd, "-|", quote_command(
6056                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
6057                         or die_error(404, "Object does not exist");
6058                 $type = <$fd>;
6059                 chomp $type;
6060                 close $fd
6061                         or die_error(404, "Object does not exist");
6062
6063         # - hash_base and file_name
6064         } elsif ($hash_base && defined $file_name) {
6065                 $file_name =~ s,/+$,,;
6066
6067                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
6068                         or die_error(404, "Base object does not exist");
6069
6070                 # here errors should not hapen
6071                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
6072                         or die_error(500, "Open git-ls-tree failed");
6073                 my $line = <$fd>;
6074                 close $fd;
6075
6076                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
6077                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
6078                         die_error(404, "File or directory for given base does not exist");
6079                 }
6080                 $type = $2;
6081                 $hash = $3;
6082         } else {
6083                 die_error(400, "Not enough information to find object");
6084         }
6085
6086         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
6087                                           hash=>$hash, hash_base=>$hash_base,
6088                                           file_name=>$file_name),
6089                              -status => '302 Found');
6090 }
6091
6092 sub git_blobdiff {
6093         my $format = shift || 'html';
6094
6095         my $fd;
6096         my @difftree;
6097         my %diffinfo;
6098         my $expires;
6099
6100         # preparing $fd and %diffinfo for git_patchset_body
6101         # new style URI
6102         if (defined $hash_base && defined $hash_parent_base) {
6103                 if (defined $file_name) {
6104                         # read raw output
6105                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6106                                 $hash_parent_base, $hash_base,
6107                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
6108                                 or die_error(500, "Open git-diff-tree failed");
6109                         @difftree = map { chomp; $_ } <$fd>;
6110                         close $fd
6111                                 or die_error(404, "Reading git-diff-tree failed");
6112                         @difftree
6113                                 or die_error(404, "Blob diff not found");
6114
6115                 } elsif (defined $hash &&
6116                          $hash =~ /[0-9a-fA-F]{40}/) {
6117                         # try to find filename from $hash
6118
6119                         # read filtered raw output
6120                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6121                                 $hash_parent_base, $hash_base, "--"
6122                                 or die_error(500, "Open git-diff-tree failed");
6123                         @difftree =
6124                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
6125                                 # $hash == to_id
6126                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
6127                                 map { chomp; $_ } <$fd>;
6128                         close $fd
6129                                 or die_error(404, "Reading git-diff-tree failed");
6130                         @difftree
6131                                 or die_error(404, "Blob diff not found");
6132
6133                 } else {
6134                         die_error(400, "Missing one of the blob diff parameters");
6135                 }
6136
6137                 if (@difftree > 1) {
6138                         die_error(400, "Ambiguous blob diff specification");
6139                 }
6140
6141                 %diffinfo = parse_difftree_raw_line($difftree[0]);
6142                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
6143                 $file_name   ||= $diffinfo{'to_file'};
6144
6145                 $hash_parent ||= $diffinfo{'from_id'};
6146                 $hash        ||= $diffinfo{'to_id'};
6147
6148                 # non-textual hash id's can be cached
6149                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
6150                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
6151                         $expires = '+1d';
6152                 }
6153
6154                 # open patch output
6155                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6156                         '-p', ($format eq 'html' ? "--full-index" : ()),
6157                         $hash_parent_base, $hash_base,
6158                         "--", (defined $file_parent ? $file_parent : ()), $file_name
6159                         or die_error(500, "Open git-diff-tree failed");
6160         }
6161
6162         # old/legacy style URI -- not generated anymore since 1.4.3.
6163         if (!%diffinfo) {
6164                 die_error('404 Not Found', "Missing one of the blob diff parameters")
6165         }
6166
6167         # header
6168         if ($format eq 'html') {
6169                 my $formats_nav =
6170                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
6171                                 "raw");
6172                 git_header_html(undef, $expires);
6173                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6174                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6175                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6176                 } else {
6177                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
6178                         print "<div class=\"title\">$hash vs $hash_parent</div>\n";
6179                 }
6180                 if (defined $file_name) {
6181                         git_print_page_path($file_name, "blob", $hash_base);
6182                 } else {
6183                         print "<div class=\"page_path\"></div>\n";
6184                 }
6185
6186         } elsif ($format eq 'plain') {
6187                 print $cgi->header(
6188                         -type => 'text/plain',
6189                         -charset => 'utf-8',
6190                         -expires => $expires,
6191                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
6192
6193                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6194
6195         } else {
6196                 die_error(400, "Unknown blobdiff format");
6197         }
6198
6199         # patch
6200         if ($format eq 'html') {
6201                 print "<div class=\"page_body\">\n";
6202
6203                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
6204                 close $fd;
6205
6206                 print "</div>\n"; # class="page_body"
6207                 git_footer_html();
6208
6209         } else {
6210                 while (my $line = <$fd>) {
6211                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
6212                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
6213
6214                         print $line;
6215
6216                         last if $line =~ m!^\+\+\+!;
6217                 }
6218                 local $/ = undef;
6219                 print <$fd>;
6220                 close $fd;
6221         }
6222 }
6223
6224 sub git_blobdiff_plain {
6225         git_blobdiff('plain');
6226 }
6227
6228 sub git_commitdiff {
6229         my %params = @_;
6230         my $format = $params{-format} || 'html';
6231
6232         my ($patch_max) = gitweb_get_feature('patches');
6233         if ($format eq 'patch') {
6234                 die_error(403, "Patch view not allowed") unless $patch_max;
6235         }
6236
6237         $hash ||= $hash_base || "HEAD";
6238         my %co = parse_commit($hash)
6239             or die_error(404, "Unknown commit object");
6240
6241         # choose format for commitdiff for merge
6242         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
6243                 $hash_parent = '--cc';
6244         }
6245         # we need to prepare $formats_nav before almost any parameter munging
6246         my $formats_nav;
6247         if ($format eq 'html') {
6248                 $formats_nav =
6249                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
6250                                 "raw");
6251                 if ($patch_max && @{$co{'parents'}} <= 1) {
6252                         $formats_nav .= " | " .
6253                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
6254                                         "patch");
6255                 }
6256
6257                 if (defined $hash_parent &&
6258                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
6259                         # commitdiff with two commits given
6260                         my $hash_parent_short = $hash_parent;
6261                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
6262                                 $hash_parent_short = substr($hash_parent, 0, 7);
6263                         }
6264                         $formats_nav .=
6265                                 ' (from';
6266                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
6267                                 if ($co{'parents'}[$i] eq $hash_parent) {
6268                                         $formats_nav .= ' parent ' . ($i+1);
6269                                         last;
6270                                 }
6271                         }
6272                         $formats_nav .= ': ' .
6273                                 $cgi->a({-href => href(action=>"commitdiff",
6274                                                        hash=>$hash_parent)},
6275                                         esc_html($hash_parent_short)) .
6276                                 ')';
6277                 } elsif (!$co{'parent'}) {
6278                         # --root commitdiff
6279                         $formats_nav .= ' (initial)';
6280                 } elsif (scalar @{$co{'parents'}} == 1) {
6281                         # single parent commit
6282                         $formats_nav .=
6283                                 ' (parent: ' .
6284                                 $cgi->a({-href => href(action=>"commitdiff",
6285                                                        hash=>$co{'parent'})},
6286                                         esc_html(substr($co{'parent'}, 0, 7))) .
6287                                 ')';
6288                 } else {
6289                         # merge commit
6290                         if ($hash_parent eq '--cc') {
6291                                 $formats_nav .= ' | ' .
6292                                         $cgi->a({-href => href(action=>"commitdiff",
6293                                                                hash=>$hash, hash_parent=>'-c')},
6294                                                 'combined');
6295                         } else { # $hash_parent eq '-c'
6296                                 $formats_nav .= ' | ' .
6297                                         $cgi->a({-href => href(action=>"commitdiff",
6298                                                                hash=>$hash, hash_parent=>'--cc')},
6299                                                 'compact');
6300                         }
6301                         $formats_nav .=
6302                                 ' (merge: ' .
6303                                 join(' ', map {
6304                                         $cgi->a({-href => href(action=>"commitdiff",
6305                                                                hash=>$_)},
6306                                                 esc_html(substr($_, 0, 7)));
6307                                 } @{$co{'parents'}} ) .
6308                                 ')';
6309                 }
6310         }
6311
6312         my $hash_parent_param = $hash_parent;
6313         if (!defined $hash_parent_param) {
6314                 # --cc for multiple parents, --root for parentless
6315                 $hash_parent_param =
6316                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
6317         }
6318
6319         # read commitdiff
6320         my $fd;
6321         my @difftree;
6322         if ($format eq 'html') {
6323                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6324                         "--no-commit-id", "--patch-with-raw", "--full-index",
6325                         $hash_parent_param, $hash, "--"
6326                         or die_error(500, "Open git-diff-tree failed");
6327
6328                 while (my $line = <$fd>) {
6329                         chomp $line;
6330                         # empty line ends raw part of diff-tree output
6331                         last unless $line;
6332                         push @difftree, scalar parse_difftree_raw_line($line);
6333                 }
6334
6335         } elsif ($format eq 'plain') {
6336                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6337                         '-p', $hash_parent_param, $hash, "--"
6338                         or die_error(500, "Open git-diff-tree failed");
6339         } elsif ($format eq 'patch') {
6340                 # For commit ranges, we limit the output to the number of
6341                 # patches specified in the 'patches' feature.
6342                 # For single commits, we limit the output to a single patch,
6343                 # diverging from the git-format-patch default.
6344                 my @commit_spec = ();
6345                 if ($hash_parent) {
6346                         if ($patch_max > 0) {
6347                                 push @commit_spec, "-$patch_max";
6348                         }
6349                         push @commit_spec, '-n', "$hash_parent..$hash";
6350                 } else {
6351                         if ($params{-single}) {
6352                                 push @commit_spec, '-1';
6353                         } else {
6354                                 if ($patch_max > 0) {
6355                                         push @commit_spec, "-$patch_max";
6356                                 }
6357                                 push @commit_spec, "-n";
6358                         }
6359                         push @commit_spec, '--root', $hash;
6360                 }
6361                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
6362                         '--encoding=utf8', '--stdout', @commit_spec
6363                         or die_error(500, "Open git-format-patch failed");
6364         } else {
6365                 die_error(400, "Unknown commitdiff format");
6366         }
6367
6368         # non-textual hash id's can be cached
6369         my $expires;
6370         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6371                 $expires = "+1d";
6372         }
6373
6374         # write commit message
6375         if ($format eq 'html') {
6376                 my $refs = git_get_references();
6377                 my $ref = format_ref_marker($refs, $co{'id'});
6378
6379                 git_header_html(undef, $expires);
6380                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
6381                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
6382                 print "<div class=\"title_text\">\n" .
6383                       "<table class=\"object_header\">\n";
6384                 git_print_authorship_rows(\%co);
6385                 print "</table>".
6386                       "</div>\n";
6387                 print "<div class=\"page_body\">\n";
6388                 if (@{$co{'comment'}} > 1) {
6389                         print "<div class=\"log\">\n";
6390                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
6391                         print "</div>\n"; # class="log"
6392                 }
6393
6394         } elsif ($format eq 'plain') {
6395                 my $refs = git_get_references("tags");
6396                 my $tagname = git_get_rev_name_tags($hash);
6397                 my $filename = basename($project) . "-$hash.patch";
6398
6399                 print $cgi->header(
6400                         -type => 'text/plain',
6401                         -charset => 'utf-8',
6402                         -expires => $expires,
6403                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6404                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
6405                 print "From: " . to_utf8($co{'author'}) . "\n";
6406                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
6407                 print "Subject: " . to_utf8($co{'title'}) . "\n";
6408
6409                 print "X-Git-Tag: $tagname\n" if $tagname;
6410                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6411
6412                 foreach my $line (@{$co{'comment'}}) {
6413                         print to_utf8($line) . "\n";
6414                 }
6415                 print "---\n\n";
6416         } elsif ($format eq 'patch') {
6417                 my $filename = basename($project) . "-$hash.patch";
6418
6419                 print $cgi->header(
6420                         -type => 'text/plain',
6421                         -charset => 'utf-8',
6422                         -expires => $expires,
6423                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6424         }
6425
6426         # write patch
6427         if ($format eq 'html') {
6428                 my $use_parents = !defined $hash_parent ||
6429                         $hash_parent eq '-c' || $hash_parent eq '--cc';
6430                 git_difftree_body(\@difftree, $hash,
6431                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6432                 print "<br/>\n";
6433
6434                 git_patchset_body($fd, \@difftree, $hash,
6435                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6436                 close $fd;
6437                 print "</div>\n"; # class="page_body"
6438                 git_footer_html();
6439
6440         } elsif ($format eq 'plain') {
6441                 local $/ = undef;
6442                 print <$fd>;
6443                 close $fd
6444                         or print "Reading git-diff-tree failed\n";
6445         } elsif ($format eq 'patch') {
6446                 local $/ = undef;
6447                 print <$fd>;
6448                 close $fd
6449                         or print "Reading git-format-patch failed\n";
6450         }
6451 }
6452
6453 sub git_commitdiff_plain {
6454         git_commitdiff(-format => 'plain');
6455 }
6456
6457 # format-patch-style patches
6458 sub git_patch {
6459         git_commitdiff(-format => 'patch', -single => 1);
6460 }
6461
6462 sub git_patches {
6463         git_commitdiff(-format => 'patch');
6464 }
6465
6466 sub git_history {
6467         git_log_generic('history', \&git_history_body,
6468                         $hash_base, $hash_parent_base,
6469                         $file_name, $hash);
6470 }
6471
6472 sub git_search {
6473         gitweb_check_feature('search') or die_error(403, "Search is disabled");
6474         if (!defined $searchtext) {
6475                 die_error(400, "Text field is empty");
6476         }
6477         if (!defined $hash) {
6478                 $hash = git_get_head_hash($project);
6479         }
6480         my %co = parse_commit($hash);
6481         if (!%co) {
6482                 die_error(404, "Unknown commit object");
6483         }
6484         if (!defined $page) {
6485                 $page = 0;
6486         }
6487
6488         $searchtype ||= 'commit';
6489         if ($searchtype eq 'pickaxe') {
6490                 # pickaxe may take all resources of your box and run for several minutes
6491                 # with every query - so decide by yourself how public you make this feature
6492                 gitweb_check_feature('pickaxe')
6493                     or die_error(403, "Pickaxe is disabled");
6494         }
6495         if ($searchtype eq 'grep') {
6496                 gitweb_check_feature('grep')
6497                     or die_error(403, "Grep is disabled");
6498         }
6499
6500         git_header_html();
6501
6502         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
6503                 my $greptype;
6504                 if ($searchtype eq 'commit') {
6505                         $greptype = "--grep=";
6506                 } elsif ($searchtype eq 'author') {
6507                         $greptype = "--author=";
6508                 } elsif ($searchtype eq 'committer') {
6509                         $greptype = "--committer=";
6510                 }
6511                 $greptype .= $searchtext;
6512                 my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6513                                                $greptype, '--regexp-ignore-case',
6514                                                $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6515
6516                 my $paging_nav = '';
6517                 if ($page > 0) {
6518                         $paging_nav .=
6519                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
6520                                                        searchtext=>$searchtext,
6521                                                        searchtype=>$searchtype)},
6522                                         "first");
6523                         $paging_nav .= " &sdot; " .
6524                                 $cgi->a({-href => href(-replay=>1, page=>$page-1),
6525                                          -accesskey => "p", -title => "Alt-p"}, "prev");
6526                 } else {
6527                         $paging_nav .= "first";
6528                         $paging_nav .= " &sdot; prev";
6529                 }
6530                 my $next_link = '';
6531                 if ($#commitlist >= 100) {
6532                         $next_link =
6533                                 $cgi->a({-href => href(-replay=>1, page=>$page+1),
6534                                          -accesskey => "n", -title => "Alt-n"}, "next");
6535                         $paging_nav .= " &sdot; $next_link";
6536                 } else {
6537                         $paging_nav .= " &sdot; next";
6538                 }
6539
6540                 git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6541                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6542                 if ($page == 0 && !@commitlist) {
6543                         print "<p>No match.</p>\n";
6544                 } else {
6545                         git_search_grep_body(\@commitlist, 0, 99, $next_link);
6546                 }
6547         }
6548
6549         if ($searchtype eq 'pickaxe') {
6550                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6551                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6552
6553                 print "<table class=\"pickaxe search\">\n";
6554                 my $alternate = 1;
6555                 local $/ = "\n";
6556                 open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6557                         '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6558                         ($search_use_regexp ? '--pickaxe-regex' : ());
6559                 undef %co;
6560                 my @files;
6561                 while (my $line = <$fd>) {
6562                         chomp $line;
6563                         next unless $line;
6564
6565                         my %set = parse_difftree_raw_line($line);
6566                         if (defined $set{'commit'}) {
6567                                 # finish previous commit
6568                                 if (%co) {
6569                                         print "</td>\n" .
6570                                               "<td class=\"link\">" .
6571                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6572                                               " | " .
6573                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6574                                         print "</td>\n" .
6575                                               "</tr>\n";
6576                                 }
6577
6578                                 if ($alternate) {
6579                                         print "<tr class=\"dark\">\n";
6580                                 } else {
6581                                         print "<tr class=\"light\">\n";
6582                                 }
6583                                 $alternate ^= 1;
6584                                 %co = parse_commit($set{'commit'});
6585                                 my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6586                                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6587                                       "<td><i>$author</i></td>\n" .
6588                                       "<td>" .
6589                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6590                                               -class => "list subject"},
6591                                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6592                         } elsif (defined $set{'to_id'}) {
6593                                 next if ($set{'to_id'} =~ m/^0{40}$/);
6594
6595                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6596                                                              hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6597                                               -class => "list"},
6598                                               "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6599                                       "<br/>\n";
6600                         }
6601                 }
6602                 close $fd;
6603
6604                 # finish last commit (warning: repetition!)
6605                 if (%co) {
6606                         print "</td>\n" .
6607                               "<td class=\"link\">" .
6608                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6609                               " | " .
6610                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6611                         print "</td>\n" .
6612                               "</tr>\n";
6613                 }
6614
6615                 print "</table>\n";
6616         }
6617
6618         if ($searchtype eq 'grep') {
6619                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6620                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6621
6622                 print "<table class=\"grep_search\">\n";
6623                 my $alternate = 1;
6624                 my $matches = 0;
6625                 local $/ = "\n";
6626                 open my $fd, "-|", git_cmd(), 'grep', '-n',
6627                         $search_use_regexp ? ('-E', '-i') : '-F',
6628                         $searchtext, $co{'tree'};
6629                 my $lastfile = '';
6630                 while (my $line = <$fd>) {
6631                         chomp $line;
6632                         my ($file, $lno, $ltext, $binary);
6633                         last if ($matches++ > 1000);
6634                         if ($line =~ /^Binary file (.+) matches$/) {
6635                                 $file = $1;
6636                                 $binary = 1;
6637                         } else {
6638                                 (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
6639                         }
6640                         if ($file ne $lastfile) {
6641                                 $lastfile and print "</td></tr>\n";
6642                                 if ($alternate++) {
6643                                         print "<tr class=\"dark\">\n";
6644                                 } else {
6645                                         print "<tr class=\"light\">\n";
6646                                 }
6647                                 print "<td class=\"list\">".
6648                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6649                                                                file_name=>"$file"),
6650                                                 -class => "list"}, esc_path($file));
6651                                 print "</td><td>\n";
6652                                 $lastfile = $file;
6653                         }
6654                         if ($binary) {
6655                                 print "<div class=\"binary\">Binary file</div>\n";
6656                         } else {
6657                                 $ltext = untabify($ltext);
6658                                 if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6659                                         $ltext = esc_html($1, -nbsp=>1);
6660                                         $ltext .= '<span class="match">';
6661                                         $ltext .= esc_html($2, -nbsp=>1);
6662                                         $ltext .= '</span>';
6663                                         $ltext .= esc_html($3, -nbsp=>1);
6664                                 } else {
6665                                         $ltext = esc_html($ltext, -nbsp=>1);
6666                                 }
6667                                 print "<div class=\"pre\">" .
6668                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6669                                                                file_name=>"$file").'#l'.$lno,
6670                                                 -class => "linenr"}, sprintf('%4i', $lno))
6671                                         . ' ' .  $ltext . "</div>\n";
6672                         }
6673                 }
6674                 if ($lastfile) {
6675                         print "</td></tr>\n";
6676                         if ($matches > 1000) {
6677                                 print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6678                         }
6679                 } else {
6680                         print "<div class=\"diff nodifferences\">No matches found</div>\n";
6681                 }
6682                 close $fd;
6683
6684                 print "</table>\n";
6685         }
6686         git_footer_html();
6687 }
6688
6689 sub git_search_help {
6690         git_header_html();
6691         git_print_page_nav('','', $hash,$hash,$hash);
6692         print <<EOT;
6693 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
6694 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
6695 the pattern entered is recognized as the POSIX extended
6696 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
6697 insensitive).</p>
6698 <dl>
6699 <dt><b>commit</b></dt>
6700 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
6701 EOT
6702         my $have_grep = gitweb_check_feature('grep');
6703         if ($have_grep) {
6704                 print <<EOT;
6705 <dt><b>grep</b></dt>
6706 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
6707     a different one) are searched for the given pattern. On large trees, this search can take
6708 a while and put some strain on the server, so please use it with some consideration. Note that
6709 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
6710 case-sensitive.</dd>
6711 EOT
6712         }
6713         print <<EOT;
6714 <dt><b>author</b></dt>
6715 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
6716 <dt><b>committer</b></dt>
6717 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
6718 EOT
6719         my $have_pickaxe = gitweb_check_feature('pickaxe');
6720         if ($have_pickaxe) {
6721                 print <<EOT;
6722 <dt><b>pickaxe</b></dt>
6723 <dd>All commits that caused the string to appear or disappear from any file (changes that
6724 added, removed or "modified" the string) will be listed. This search can take a while and
6725 takes a lot of strain on the server, so please use it wisely. Note that since you may be
6726 interested even in changes just changing the case as well, this search is case sensitive.</dd>
6727 EOT
6728         }
6729         print "</dl>\n";
6730         git_footer_html();
6731 }
6732
6733 sub git_shortlog {
6734         git_log_generic('shortlog', \&git_shortlog_body,
6735                         $hash, $hash_parent);
6736 }
6737
6738 ## ......................................................................
6739 ## feeds (RSS, Atom; OPML)
6740
6741 sub git_feed {
6742         my $format = shift || 'atom';
6743         my $have_blame = gitweb_check_feature('blame');
6744
6745         # Atom: http://www.atomenabled.org/developers/syndication/
6746         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
6747         if ($format ne 'rss' && $format ne 'atom') {
6748                 die_error(400, "Unknown web feed format");
6749         }
6750
6751         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
6752         my $head = $hash || 'HEAD';
6753         my @commitlist = parse_commits($head, 150, 0, $file_name);
6754
6755         my %latest_commit;
6756         my %latest_date;
6757         my $content_type = "application/$format+xml";
6758         if (defined $cgi->http('HTTP_ACCEPT') &&
6759                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
6760                 # browser (feed reader) prefers text/xml
6761                 $content_type = 'text/xml';
6762         }
6763         if (defined($commitlist[0])) {
6764                 %latest_commit = %{$commitlist[0]};
6765                 my $latest_epoch = $latest_commit{'committer_epoch'};
6766                 %latest_date   = parse_date($latest_epoch);
6767                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
6768                 if (defined $if_modified) {
6769                         my $since;
6770                         if (eval { require HTTP::Date; 1; }) {
6771                                 $since = HTTP::Date::str2time($if_modified);
6772                         } elsif (eval { require Time::ParseDate; 1; }) {
6773                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
6774                         }
6775                         if (defined $since && $latest_epoch <= $since) {
6776                                 print $cgi->header(
6777                                         -type => $content_type,
6778                                         -charset => 'utf-8',
6779                                         -last_modified => $latest_date{'rfc2822'},
6780                                         -status => '304 Not Modified');
6781                                 return;
6782                         }
6783                 }
6784                 print $cgi->header(
6785                         -type => $content_type,
6786                         -charset => 'utf-8',
6787                         -last_modified => $latest_date{'rfc2822'});
6788         } else {
6789                 print $cgi->header(
6790                         -type => $content_type,
6791                         -charset => 'utf-8');
6792         }
6793
6794         # Optimization: skip generating the body if client asks only
6795         # for Last-Modified date.
6796         return if ($cgi->request_method() eq 'HEAD');
6797
6798         # header variables
6799         my $title = "$site_name - $project/$action";
6800         my $feed_type = 'log';
6801         if (defined $hash) {
6802                 $title .= " - '$hash'";
6803                 $feed_type = 'branch log';
6804                 if (defined $file_name) {
6805                         $title .= " :: $file_name";
6806                         $feed_type = 'history';
6807                 }
6808         } elsif (defined $file_name) {
6809                 $title .= " - $file_name";
6810                 $feed_type = 'history';
6811         }
6812         $title .= " $feed_type";
6813         my $descr = git_get_project_description($project);
6814         if (defined $descr) {
6815                 $descr = esc_html($descr);
6816         } else {
6817                 $descr = "$project " .
6818                          ($format eq 'rss' ? 'RSS' : 'Atom') .
6819                          " feed";
6820         }
6821         my $owner = git_get_project_owner($project);
6822         $owner = esc_html($owner);
6823
6824         #header
6825         my $alt_url;
6826         if (defined $file_name) {
6827                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
6828         } elsif (defined $hash) {
6829                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
6830         } else {
6831                 $alt_url = href(-full=>1, action=>"summary");
6832         }
6833         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
6834         if ($format eq 'rss') {
6835                 print <<XML;
6836 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
6837 <channel>
6838 XML
6839                 print "<title>$title</title>\n" .
6840                       "<link>$alt_url</link>\n" .
6841                       "<description>$descr</description>\n" .
6842                       "<language>en</language>\n" .
6843                       # project owner is responsible for 'editorial' content
6844                       "<managingEditor>$owner</managingEditor>\n";
6845                 if (defined $logo || defined $favicon) {
6846                         # prefer the logo to the favicon, since RSS
6847                         # doesn't allow both
6848                         my $img = esc_url($logo || $favicon);
6849                         print "<image>\n" .
6850                               "<url>$img</url>\n" .
6851                               "<title>$title</title>\n" .
6852                               "<link>$alt_url</link>\n" .
6853                               "</image>\n";
6854                 }
6855                 if (%latest_date) {
6856                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
6857                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
6858                 }
6859                 print "<generator>gitweb v.$version/$git_version</generator>\n";
6860         } elsif ($format eq 'atom') {
6861                 print <<XML;
6862 <feed xmlns="http://www.w3.org/2005/Atom">
6863 XML
6864                 print "<title>$title</title>\n" .
6865                       "<subtitle>$descr</subtitle>\n" .
6866                       '<link rel="alternate" type="text/html" href="' .
6867                       $alt_url . '" />' . "\n" .
6868                       '<link rel="self" type="' . $content_type . '" href="' .
6869                       $cgi->self_url() . '" />' . "\n" .
6870                       "<id>" . href(-full=>1) . "</id>\n" .
6871                       # use project owner for feed author
6872                       "<author><name>$owner</name></author>\n";
6873                 if (defined $favicon) {
6874                         print "<icon>" . esc_url($favicon) . "</icon>\n";
6875                 }
6876                 if (defined $logo_url) {
6877                         # not twice as wide as tall: 72 x 27 pixels
6878                         print "<logo>" . esc_url($logo) . "</logo>\n";
6879                 }
6880                 if (! %latest_date) {
6881                         # dummy date to keep the feed valid until commits trickle in:
6882                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
6883                 } else {
6884                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
6885                 }
6886                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
6887         }
6888
6889         # contents
6890         for (my $i = 0; $i <= $#commitlist; $i++) {
6891                 my %co = %{$commitlist[$i]};
6892                 my $commit = $co{'id'};
6893                 # we read 150, we always show 30 and the ones more recent than 48 hours
6894                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
6895                         last;
6896                 }
6897                 my %cd = parse_date($co{'author_epoch'});
6898
6899                 # get list of changed files
6900                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6901                         $co{'parent'} || "--root",
6902                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
6903                         or next;
6904                 my @difftree = map { chomp; $_ } <$fd>;
6905                 close $fd
6906                         or next;
6907
6908                 # print element (entry, item)
6909                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
6910                 if ($format eq 'rss') {
6911                         print "<item>\n" .
6912                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
6913                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
6914                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
6915                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
6916                               "<link>$co_url</link>\n" .
6917                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
6918                               "<content:encoded>" .
6919                               "<![CDATA[\n";
6920                 } elsif ($format eq 'atom') {
6921                         print "<entry>\n" .
6922                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
6923                               "<updated>$cd{'iso-8601'}</updated>\n" .
6924                               "<author>\n" .
6925                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
6926                         if ($co{'author_email'}) {
6927                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
6928                         }
6929                         print "</author>\n" .
6930                               # use committer for contributor
6931                               "<contributor>\n" .
6932                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
6933                         if ($co{'committer_email'}) {
6934                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
6935                         }
6936                         print "</contributor>\n" .
6937                               "<published>$cd{'iso-8601'}</published>\n" .
6938                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
6939                               "<id>$co_url</id>\n" .
6940                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
6941                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
6942                 }
6943                 my $comment = $co{'comment'};
6944                 print "<pre>\n";
6945                 foreach my $line (@$comment) {
6946                         $line = esc_html($line);
6947                         print "$line\n";
6948                 }
6949                 print "</pre><ul>\n";
6950                 foreach my $difftree_line (@difftree) {
6951                         my %difftree = parse_difftree_raw_line($difftree_line);
6952                         next if !$difftree{'from_id'};
6953
6954                         my $file = $difftree{'file'} || $difftree{'to_file'};
6955
6956                         print "<li>" .
6957                               "[" .
6958                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
6959                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
6960                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
6961                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
6962                                       -title => "diff"}, 'D');
6963                         if ($have_blame) {
6964                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
6965                                                              file_name=>$file, hash_base=>$commit),
6966                                               -title => "blame"}, 'B');
6967                         }
6968                         # if this is not a feed of a file history
6969                         if (!defined $file_name || $file_name ne $file) {
6970                                 print $cgi->a({-href => href(-full=>1, action=>"history",
6971                                                              file_name=>$file, hash=>$commit),
6972                                               -title => "history"}, 'H');
6973                         }
6974                         $file = esc_path($file);
6975                         print "] ".
6976                               "$file</li>\n";
6977                 }
6978                 if ($format eq 'rss') {
6979                         print "</ul>]]>\n" .
6980                               "</content:encoded>\n" .
6981                               "</item>\n";
6982                 } elsif ($format eq 'atom') {
6983                         print "</ul>\n</div>\n" .
6984                               "</content>\n" .
6985                               "</entry>\n";
6986                 }
6987         }
6988
6989         # end of feed
6990         if ($format eq 'rss') {
6991                 print "</channel>\n</rss>\n";
6992         } elsif ($format eq 'atom') {
6993                 print "</feed>\n";
6994         }
6995 }
6996
6997 sub git_rss {
6998         git_feed('rss');
6999 }
7000
7001 sub git_atom {
7002         git_feed('atom');
7003 }
7004
7005 sub git_opml {
7006         my @list = git_get_projects_list();
7007
7008         print $cgi->header(
7009                 -type => 'text/xml',
7010                 -charset => 'utf-8',
7011                 -content_disposition => 'inline; filename="opml.xml"');
7012
7013         print <<XML;
7014 <?xml version="1.0" encoding="utf-8"?>
7015 <opml version="1.0">
7016 <head>
7017   <title>$site_name OPML Export</title>
7018 </head>
7019 <body>
7020 <outline text="git RSS feeds">
7021 XML
7022
7023         foreach my $pr (@list) {
7024                 my %proj = %$pr;
7025                 my $head = git_get_head_hash($proj{'path'});
7026                 if (!defined $head) {
7027                         next;
7028                 }
7029                 $git_dir = "$projectroot/$proj{'path'}";
7030                 my %co = parse_commit($head);
7031                 if (!%co) {
7032                         next;
7033                 }
7034
7035                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7036                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7037                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7038                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7039         }
7040         print <<XML;
7041 </outline>
7042 </body>
7043 </opml>
7044 XML
7045 }