git.oblomov.eu Git - git/blob - gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101 # URI of GIT logo (72x27 size)
 102 our $logo = "++GITWEB_LOGO++";
 103 # URI of GIT favicon, assumed to be image/png type
 104 our $favicon = "++GITWEB_FAVICON++";
 105 # URI of gitweb.js (JavaScript code for gitweb)
 106 our $javascript = "++GITWEB_JS++";
 107
 108 # URI and label (title) of GIT logo link
 109 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 110 #our $logo_label = "git documentation";
 111 our $logo_url = "http://git-scm.com/";
 112 our $logo_label = "git homepage";
 113
 114 # source of projects list
 115 our $projects_list = "++GITWEB_LIST++";
 116
 117 # the width (in characters) of the projects list "Description" column
 118 our $projects_list_description_width = 25;
 119
 120 # group projects by category on the projects list
 121 # (enabled if this variable evaluates to true)
 122 our $projects_list_group_categories = 0;
 123
 124 # default category if none specified
 125 # (leave the empty string for no category)
 126 our $project_list_default_category = "";
 127
 128 # default order of projects list
 129 # valid values are none, project, descr, owner, and age
 130 our $default_projects_order = "project";
 131
 132 # show repository only if this file exists
 133 # (only effective if this variable evaluates to true)
 134 our $export_ok = "++GITWEB_EXPORT_OK++";
 135
 136 # show repository only if this subroutine returns true
 137 # when given the path to the project, for example:
 138 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 139 our $export_auth_hook = undef;
 140
 141 # only allow viewing of repositories also shown on the overview page
 142 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 143
 144 # list of git base URLs used for URL to where fetch project from,
 145 # i.e. full URL is "$git_base_url/$project"
 146 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 147
 148 # default blob_plain mimetype and default charset for text/plain blob
 149 our $default_blob_plain_mimetype = 'text/plain';
 150 our $default_text_plain_charset  = undef;
 151
 152 # file to use for guessing MIME types before trying /etc/mime.types
 153 # (relative to the current git repository)
 154 our $mimetypes_file = undef;
 155
 156 # assume this charset if line contains non-UTF-8 characters;
 157 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 158 # for which encoding all byte sequences are valid, for example
 159 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 160 # could be even 'utf-8' for the old behavior)
 161 our $fallback_encoding = 'latin1';
 162
 163 # rename detection options for git-diff and git-diff-tree
 164 # - default is '-M', with the cost proportional to
 165 #   (number of removed files) * (number of new files).
 166 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 167 #   (number of changed files + number of removed files) * (number of new files)
 168 # - even more costly is '-C', '--find-copies-harder' with cost
 169 #   (number of files in the original tree) * (number of new files)
 170 # - one might want to include '-B' option, e.g. '-B', '-M'
 171 our @diff_opts = ('-M'); # taken from git_commit
 172
 173 # Disables features that would allow repository owners to inject script into
 174 # the gitweb domain.
 175 our $prevent_xss = 0;
 176
 177 # Path to the highlight executable to use (must be the one from
 178 # http://www.andre-simon.de due to assumptions about parameters and output).
 179 # Useful if highlight is not installed on your webserver's PATH.
 180 # [Default: highlight]
 181 our $highlight_bin = "++HIGHLIGHT_BIN++";
 182
 183 # information about snapshot formats that gitweb is capable of serving
 184 our %known_snapshot_formats = (
 185         # name => {
 186         #       'display' => display name,
 187         #       'type' => mime type,
 188         #       'suffix' => filename suffix,
 189         #       'format' => --format for git-archive,
 190         #       'compressor' => [compressor command and arguments]
 191         #                       (array reference, optional)
 192         #       'disabled' => boolean (optional)}
 193         #
 194         'tgz' => {
 195                 'display' => 'tar.gz',
 196                 'type' => 'application/x-gzip',
 197                 'suffix' => '.tar.gz',
 198                 'format' => 'tar',
 199                 'compressor' => ['gzip', '-n']},
 200
 201         'tbz2' => {
 202                 'display' => 'tar.bz2',
 203                 'type' => 'application/x-bzip2',
 204                 'suffix' => '.tar.bz2',
 205                 'format' => 'tar',
 206                 'compressor' => ['bzip2']},
 207
 208         'txz' => {
 209                 'display' => 'tar.xz',
 210                 'type' => 'application/x-xz',
 211                 'suffix' => '.tar.xz',
 212                 'format' => 'tar',
 213                 'compressor' => ['xz'],
 214                 'disabled' => 1},
 215
 216         'zip' => {
 217                 'display' => 'zip',
 218                 'type' => 'application/x-zip',
 219                 'suffix' => '.zip',
 220                 'format' => 'zip'},
 221 );
 222
 223 # Aliases so we understand old gitweb.snapshot values in repository
 224 # configuration.
 225 our %known_snapshot_format_aliases = (
 226         'gzip'  => 'tgz',
 227         'bzip2' => 'tbz2',
 228         'xz'    => 'txz',
 229
 230         # backward compatibility: legacy gitweb config support
 231         'x-gzip' => undef, 'gz' => undef,
 232         'x-bzip2' => undef, 'bz2' => undef,
 233         'x-zip' => undef, '' => undef,
 234 );
 235
 236 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 237 # are changed, it may be appropriate to change these values too via
 238 # $GITWEB_CONFIG.
 239 our %avatar_size = (
 240         'default' => 16,
 241         'double'  => 32
 242 );
 243
 244 # Used to set the maximum load that we will still respond to gitweb queries.
 245 # If server load exceed this value then return "503 server busy" error.
 246 # If gitweb cannot determined server load, it is taken to be 0.
 247 # Leave it undefined (or set to 'undef') to turn off load checking.
 248 our $maxload = 300;
 249
 250 # configuration for 'highlight' (http://www.andre-simon.de/)
 251 # match by basename
 252 our %highlight_basename = (
 253         #'Program' => 'py',
 254         #'Library' => 'py',
 255         'SConstruct' => 'py', # SCons equivalent of Makefile
 256         'Makefile' => 'make',
 257 );
 258 # match by extension
 259 our %highlight_ext = (
 260         # main extensions, defining name of syntax;
 261         # see files in /usr/share/highlight/langDefs/ directory
 262         map { $_ => $_ }
 263                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 264         # alternate extensions, see /etc/highlight/filetypes.conf
 265         'h' => 'c',
 266         map { $_ => 'sh'  } qw(bash zsh ksh),
 267         map { $_ => 'cpp' } qw(cxx c++ cc),
 268         map { $_ => 'php' } qw(php3 php4 php5 phps),
 269         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 270         map { $_ => 'make'} qw(mak mk),
 271         map { $_ => 'xml' } qw(xhtml html htm),
 272 );
 273
 274 # You define site-wide feature defaults here; override them with
 275 # $GITWEB_CONFIG as necessary.
 276 our %feature = (
 277         # feature => {
 278         #       'sub' => feature-sub (subroutine),
 279         #       'override' => allow-override (boolean),
 280         #       'default' => [ default options...] (array reference)}
 281         #
 282         # if feature is overridable (it means that allow-override has true value),
 283         # then feature-sub will be called with default options as parameters;
 284         # return value of feature-sub indicates if to enable specified feature
 285         #
 286         # if there is no 'sub' key (no feature-sub), then feature cannot be
 287         # overridden
 288         #
 289         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 290         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 291         # is enabled
 292
 293         # Enable the 'blame' blob view, showing the last commit that modified
 294         # each line in the file. This can be very CPU-intensive.
 295
 296         # To enable system wide have in $GITWEB_CONFIG
 297         # $feature{'blame'}{'default'} = [1];
 298         # To have project specific config enable override in $GITWEB_CONFIG
 299         # $feature{'blame'}{'override'} = 1;
 300         # and in project config gitweb.blame = 0|1;
 301         'blame' => {
 302                 'sub' => sub { feature_bool('blame', @_) },
 303                 'override' => 0,
 304                 'default' => [0]},
 305
 306         # Enable the 'snapshot' link, providing a compressed archive of any
 307         # tree. This can potentially generate high traffic if you have large
 308         # project.
 309
 310         # Value is a list of formats defined in %known_snapshot_formats that
 311         # you wish to offer.
 312         # To disable system wide have in $GITWEB_CONFIG
 313         # $feature{'snapshot'}{'default'} = [];
 314         # To have project specific config enable override in $GITWEB_CONFIG
 315         # $feature{'snapshot'}{'override'} = 1;
 316         # and in project config, a comma-separated list of formats or "none"
 317         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 318         'snapshot' => {
 319                 'sub' => \&feature_snapshot,
 320                 'override' => 0,
 321                 'default' => ['tgz']},
 322
 323         # Enable text search, which will list the commits which match author,
 324         # committer or commit text to a given string.  Enabled by default.
 325         # Project specific override is not supported.
 326         #
 327         # Note that this controls all search features, which means that if
 328         # it is disabled, then 'grep' and 'pickaxe' search would also be
 329         # disabled.
 330         'search' => {
 331                 'override' => 0,
 332                 'default' => [1]},
 333
 334         # Enable grep search, which will list the files in currently selected
 335         # tree containing the given string. Enabled by default. This can be
 336         # potentially CPU-intensive, of course.
 337         # Note that you need to have 'search' feature enabled too.
 338
 339         # To enable system wide have in $GITWEB_CONFIG
 340         # $feature{'grep'}{'default'} = [1];
 341         # To have project specific config enable override in $GITWEB_CONFIG
 342         # $feature{'grep'}{'override'} = 1;
 343         # and in project config gitweb.grep = 0|1;
 344         'grep' => {
 345                 'sub' => sub { feature_bool('grep', @_) },
 346                 'override' => 0,
 347                 'default' => [1]},
 348
 349         # Enable the pickaxe search, which will list the commits that modified
 350         # a given string in a file. This can be practical and quite faster
 351         # alternative to 'blame', but still potentially CPU-intensive.
 352         # Note that you need to have 'search' feature enabled too.
 353
 354         # To enable system wide have in $GITWEB_CONFIG
 355         # $feature{'pickaxe'}{'default'} = [1];
 356         # To have project specific config enable override in $GITWEB_CONFIG
 357         # $feature{'pickaxe'}{'override'} = 1;
 358         # and in project config gitweb.pickaxe = 0|1;
 359         'pickaxe' => {
 360                 'sub' => sub { feature_bool('pickaxe', @_) },
 361                 'override' => 0,
 362                 'default' => [1]},
 363
 364         # Enable showing size of blobs in a 'tree' view, in a separate
 365         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 366
 367         # To disable system wide have in $GITWEB_CONFIG
 368         # $feature{'show-sizes'}{'default'} = [0];
 369         # To have project specific config enable override in $GITWEB_CONFIG
 370         # $feature{'show-sizes'}{'override'} = 1;
 371         # and in project config gitweb.showsizes = 0|1;
 372         'show-sizes' => {
 373                 'sub' => sub { feature_bool('showsizes', @_) },
 374                 'override' => 0,
 375                 'default' => [1]},
 376
 377         # Make gitweb use an alternative format of the URLs which can be
 378         # more readable and natural-looking: project name is embedded
 379         # directly in the path and the query string contains other
 380         # auxiliary information. All gitweb installations recognize
 381         # URL in either format; this configures in which formats gitweb
 382         # generates links.
 383
 384         # To enable system wide have in $GITWEB_CONFIG
 385         # $feature{'pathinfo'}{'default'} = [1];
 386         # Project specific override is not supported.
 387
 388         # Note that you will need to change the default location of CSS,
 389         # favicon, logo and possibly other files to an absolute URL. Also,
 390         # if gitweb.cgi serves as your indexfile, you will need to force
 391         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 392         'pathinfo' => {
 393                 'override' => 0,
 394                 'default' => [0]},
 395
 396         # Make gitweb consider projects in project root subdirectories
 397         # to be forks of existing projects. Given project $projname.git,
 398         # projects matching $projname/*.git will not be shown in the main
 399         # projects list, instead a '+' mark will be added to $projname
 400         # there and a 'forks' view will be enabled for the project, listing
 401         # all the forks. If project list is taken from a file, forks have
 402         # to be listed after the main project.
 403
 404         # To enable system wide have in $GITWEB_CONFIG
 405         # $feature{'forks'}{'default'} = [1];
 406         # Project specific override is not supported.
 407         'forks' => {
 408                 'override' => 0,
 409                 'default' => [0]},
 410
 411         # Insert custom links to the action bar of all project pages.
 412         # This enables you mainly to link to third-party scripts integrating
 413         # into gitweb; e.g. git-browser for graphical history representation
 414         # or custom web-based repository administration interface.
 415
 416         # The 'default' value consists of a list of triplets in the form
 417         # (label, link, position) where position is the label after which
 418         # to insert the link and link is a format string where %n expands
 419         # to the project name, %f to the project path within the filesystem,
 420         # %h to the current hash (h gitweb parameter) and %b to the current
 421         # hash base (hb gitweb parameter); %% expands to %.
 422
 423         # To enable system wide have in $GITWEB_CONFIG e.g.
 424         # $feature{'actions'}{'default'} = [('graphiclog',
 425         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 426         # Project specific override is not supported.
 427         'actions' => {
 428                 'override' => 0,
 429                 'default' => []},
 430
 431         # Allow gitweb scan project content tags of project repository,
 432         # and display the popular Web 2.0-ish "tag cloud" near the projects
 433         # list.  Note that this is something COMPLETELY different from the
 434         # normal Git tags.
 435
 436         # gitweb by itself can show existing tags, but it does not handle
 437         # tagging itself; you need to do it externally, outside gitweb.
 438         # The format is described in git_get_project_ctags() subroutine.
 439         # You may want to install the HTML::TagCloud Perl module to get
 440         # a pretty tag cloud instead of just a list of tags.
 441
 442         # To enable system wide have in $GITWEB_CONFIG
 443         # $feature{'ctags'}{'default'} = [1];
 444         # Project specific override is not supported.
 445
 446         # In the future whether ctags editing is enabled might depend
 447         # on the value, but using 1 should always mean no editing of ctags.
 448         'ctags' => {
 449                 'override' => 0,
 450                 'default' => [0]},
 451
 452         # The maximum number of patches in a patchset generated in patch
 453         # view. Set this to 0 or undef to disable patch view, or to a
 454         # negative number to remove any limit.
 455
 456         # To disable system wide have in $GITWEB_CONFIG
 457         # $feature{'patches'}{'default'} = [0];
 458         # To have project specific config enable override in $GITWEB_CONFIG
 459         # $feature{'patches'}{'override'} = 1;
 460         # and in project config gitweb.patches = 0|n;
 461         # where n is the maximum number of patches allowed in a patchset.
 462         'patches' => {
 463                 'sub' => \&feature_patches,
 464                 'override' => 0,
 465                 'default' => [16]},
 466
 467         # Avatar support. When this feature is enabled, views such as
 468         # shortlog or commit will display an avatar associated with
 469         # the email of the committer(s) and/or author(s).
 470
 471         # Currently available providers are gravatar and picon.
 472         # If an unknown provider is specified, the feature is disabled.
 473
 474         # Gravatar depends on Digest::MD5.
 475         # Picon currently relies on the indiana.edu database.
 476
 477         # To enable system wide have in $GITWEB_CONFIG
 478         # $feature{'avatar'}{'default'} = ['<provider>'];
 479         # where <provider> is either gravatar or picon.
 480         # To have project specific config enable override in $GITWEB_CONFIG
 481         # $feature{'avatar'}{'override'} = 1;
 482         # and in project config gitweb.avatar = <provider>;
 483         'avatar' => {
 484                 'sub' => \&feature_avatar,
 485                 'override' => 0,
 486                 'default' => ['']},
 487
 488         # Enable displaying how much time and how many git commands
 489         # it took to generate and display page.  Disabled by default.
 490         # Project specific override is not supported.
 491         'timed' => {
 492                 'override' => 0,
 493                 'default' => [0]},
 494
 495         # Enable turning some links into links to actions which require
 496         # JavaScript to run (like 'blame_incremental').  Not enabled by
 497         # default.  Project specific override is currently not supported.
 498         'javascript-actions' => {
 499                 'override' => 0,
 500                 'default' => [0]},
 501
 502         # Enable and configure ability to change common timezone for dates
 503         # in gitweb output via JavaScript.  Enabled by default.
 504         # Project specific override is not supported.
 505         'javascript-timezone' => {
 506                 'override' => 0,
 507                 'default' => [
 508                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 509                                      # or undef to turn off this feature
 510                         'gitweb_tz', # name of cookie where to store selected timezone
 511                         'datetime',  # CSS class used to mark up dates for manipulation
 512                 ]},
 513
 514         # Syntax highlighting support. This is based on Daniel Svensson's
 515         # and Sham Chukoury's work in gitweb-xmms2.git.
 516         # It requires the 'highlight' program present in $PATH,
 517         # and therefore is disabled by default.
 518
 519         # To enable system wide have in $GITWEB_CONFIG
 520         # $feature{'highlight'}{'default'} = [1];
 521
 522         'highlight' => {
 523                 'sub' => sub { feature_bool('highlight', @_) },
 524                 'override' => 0,
 525                 'default' => [0]},
 526
 527         # Enable displaying of remote heads in the heads list
 528
 529         # To enable system wide have in $GITWEB_CONFIG
 530         # $feature{'remote_heads'}{'default'} = [1];
 531         # To have project specific config enable override in $GITWEB_CONFIG
 532         # $feature{'remote_heads'}{'override'} = 1;
 533         # and in project config gitweb.remote_heads = 0|1;
 534         'remote_heads' => {
 535                 'sub' => sub { feature_bool('remote_heads', @_) },
 536                 'override' => 0,
 537                 'default' => [0]},
 538 );
 539
 540 sub gitweb_get_feature {
 541         my ($name) = @_;
 542         return unless exists $feature{$name};
 543         my ($sub, $override, @defaults) = (
 544                 $feature{$name}{'sub'},
 545                 $feature{$name}{'override'},
 546                 @{$feature{$name}{'default'}});
 547         # project specific override is possible only if we have project
 548         our $git_dir; # global variable, declared later
 549         if (!$override || !defined $git_dir) {
 550                 return @defaults;
 551         }
 552         if (!defined $sub) {
 553                 warn "feature $name is not overridable";
 554                 return @defaults;
 555         }
 556         return $sub->(@defaults);
 557 }
 558
 559 # A wrapper to check if a given feature is enabled.
 560 # With this, you can say
 561 #
 562 #   my $bool_feat = gitweb_check_feature('bool_feat');
 563 #   gitweb_check_feature('bool_feat') or somecode;
 564 #
 565 # instead of
 566 #
 567 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 568 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 569 #
 570 sub gitweb_check_feature {
 571         return (gitweb_get_feature(@_))[0];
 572 }
 573
 574
 575 sub feature_bool {
 576         my $key = shift;
 577         my ($val) = git_get_project_config($key, '--bool');
 578
 579         if (!defined $val) {
 580                 return ($_[0]);
 581         } elsif ($val eq 'true') {
 582                 return (1);
 583         } elsif ($val eq 'false') {
 584                 return (0);
 585         }
 586 }
 587
 588 sub feature_snapshot {
 589         my (@fmts) = @_;
 590
 591         my ($val) = git_get_project_config('snapshot');
 592
 593         if ($val) {
 594                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 595         }
 596
 597         return @fmts;
 598 }
 599
 600 sub feature_patches {
 601         my @val = (git_get_project_config('patches', '--int'));
 602
 603         if (@val) {
 604                 return @val;
 605         }
 606
 607         return ($_[0]);
 608 }
 609
 610 sub feature_avatar {
 611         my @val = (git_get_project_config('avatar'));
 612
 613         return @val ? @val : @_;
 614 }
 615
 616 # checking HEAD file with -e is fragile if the repository was
 617 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 618 # and then pruned.
 619 sub check_head_link {
 620         my ($dir) = @_;
 621         my $headfile = "$dir/HEAD";
 622         return ((-e $headfile) ||
 623                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 624 }
 625
 626 sub check_export_ok {
 627         my ($dir) = @_;
 628         return (check_head_link($dir) &&
 629                 (!$export_ok || -e "$dir/$export_ok") &&
 630                 (!$export_auth_hook || $export_auth_hook->($dir)));
 631 }
 632
 633 # process alternate names for backward compatibility
 634 # filter out unsupported (unknown) snapshot formats
 635 sub filter_snapshot_fmts {
 636         my @fmts = @_;
 637
 638         @fmts = map {
 639                 exists $known_snapshot_format_aliases{$_} ?
 640                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 641         @fmts = grep {
 642                 exists $known_snapshot_formats{$_} &&
 643                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 644 }
 645
 646 # If it is set to code reference, it is code that it is to be run once per
 647 # request, allowing updating configurations that change with each request,
 648 # while running other code in config file only once.
 649 #
 650 # Otherwise, if it is false then gitweb would process config file only once;
 651 # if it is true then gitweb config would be run for each request.
 652 our $per_request_config = 1;
 653
 654 # read and parse gitweb config file given by its parameter.
 655 # returns true on success, false on recoverable error, allowing
 656 # to chain this subroutine, using first file that exists.
 657 # dies on errors during parsing config file, as it is unrecoverable.
 658 sub read_config_file {
 659         my $filename = shift;
 660         return unless defined $filename;
 661         # die if there are errors parsing config file
 662         if (-e $filename) {
 663                 do $filename;
 664                 die $@ if $@;
 665                 return 1;
 666         }
 667         return;
 668 }
 669
 670 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 671 sub evaluate_gitweb_config {
 672         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 673         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 674         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 675
 676         # Protect agains duplications of file names, to not read config twice.
 677         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 678         # there possibility of duplication of filename there doesn't matter.
 679         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 680         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 681
 682         # Common system-wide settings for convenience.
 683         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 684         read_config_file($GITWEB_CONFIG_COMMON);
 685
 686         # Use first config file that exists.  This means use the per-instance
 687         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 688         read_config_file($GITWEB_CONFIG) and return;
 689         read_config_file($GITWEB_CONFIG_SYSTEM);
 690 }
 691
 692 # Get loadavg of system, to compare against $maxload.
 693 # Currently it requires '/proc/loadavg' present to get loadavg;
 694 # if it is not present it returns 0, which means no load checking.
 695 sub get_loadavg {
 696         if( -e '/proc/loadavg' ){
 697                 open my $fd, '<', '/proc/loadavg'
 698                         or return 0;
 699                 my @load = split(/\s+/, scalar <$fd>);
 700                 close $fd;
 701
 702                 # The first three columns measure CPU and IO utilization of the last one,
 703                 # five, and 10 minute periods.  The fourth column shows the number of
 704                 # currently running processes and the total number of processes in the m/n
 705                 # format.  The last column displays the last process ID used.
 706                 return $load[0] || 0;
 707         }
 708         # additional checks for load average should go here for things that don't export
 709         # /proc/loadavg
 710
 711         return 0;
 712 }
 713
 714 # version of the core git binary
 715 our $git_version;
 716 sub evaluate_git_version {
 717         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 718         $number_of_git_cmds++;
 719 }
 720
 721 sub check_loadavg {
 722         if (defined $maxload && get_loadavg() > $maxload) {
 723                 die_error(503, "The load average on the server is too high");
 724         }
 725 }
 726
 727 # ======================================================================
 728 # input validation and dispatch
 729
 730 # input parameters can be collected from a variety of sources (presently, CGI
 731 # and PATH_INFO), so we define an %input_params hash that collects them all
 732 # together during validation: this allows subsequent uses (e.g. href()) to be
 733 # agnostic of the parameter origin
 734
 735 our %input_params = ();
 736
 737 # input parameters are stored with the long parameter name as key. This will
 738 # also be used in the href subroutine to convert parameters to their CGI
 739 # equivalent, and since the href() usage is the most frequent one, we store
 740 # the name -> CGI key mapping here, instead of the reverse.
 741 #
 742 # XXX: Warning: If you touch this, check the search form for updating,
 743 # too.
 744
 745 our @cgi_param_mapping = (
 746         project => "p",
 747         action => "a",
 748         file_name => "f",
 749         file_parent => "fp",
 750         hash => "h",
 751         hash_parent => "hp",
 752         hash_base => "hb",
 753         hash_parent_base => "hpb",
 754         page => "pg",
 755         order => "o",
 756         searchtext => "s",
 757         searchtype => "st",
 758         snapshot_format => "sf",
 759         extra_options => "opt",
 760         search_use_regexp => "sr",
 761         ctag => "by_tag",
 762         diff_style => "ds",
 763         # this must be last entry (for manipulation from JavaScript)
 764         javascript => "js"
 765 );
 766 our %cgi_param_mapping = @cgi_param_mapping;
 767
 768 # we will also need to know the possible actions, for validation
 769 our %actions = (
 770         "blame" => \&git_blame,
 771         "blame_incremental" => \&git_blame_incremental,
 772         "blame_data" => \&git_blame_data,
 773         "blobdiff" => \&git_blobdiff,
 774         "blobdiff_plain" => \&git_blobdiff_plain,
 775         "blob" => \&git_blob,
 776         "blob_plain" => \&git_blob_plain,
 777         "commitdiff" => \&git_commitdiff,
 778         "commitdiff_plain" => \&git_commitdiff_plain,
 779         "commit" => \&git_commit,
 780         "forks" => \&git_forks,
 781         "heads" => \&git_heads,
 782         "history" => \&git_history,
 783         "log" => \&git_log,
 784         "patch" => \&git_patch,
 785         "patches" => \&git_patches,
 786         "remotes" => \&git_remotes,
 787         "rss" => \&git_rss,
 788         "atom" => \&git_atom,
 789         "search" => \&git_search,
 790         "search_help" => \&git_search_help,
 791         "shortlog" => \&git_shortlog,
 792         "summary" => \&git_summary,
 793         "tag" => \&git_tag,
 794         "tags" => \&git_tags,
 795         "tree" => \&git_tree,
 796         "snapshot" => \&git_snapshot,
 797         "object" => \&git_object,
 798         # those below don't need $project
 799         "opml" => \&git_opml,
 800         "project_list" => \&git_project_list,
 801         "project_index" => \&git_project_index,
 802 );
 803
 804 # finally, we have the hash of allowed extra_options for the commands that
 805 # allow them
 806 our %allowed_options = (
 807         "--no-merges" => [ qw(rss atom log shortlog history) ],
 808 );
 809
 810 # fill %input_params with the CGI parameters. All values except for 'opt'
 811 # should be single values, but opt can be an array. We should probably
 812 # build an array of parameters that can be multi-valued, but since for the time
 813 # being it's only this one, we just single it out
 814 sub evaluate_query_params {
 815         our $cgi;
 816
 817         while (my ($name, $symbol) = each %cgi_param_mapping) {
 818                 if ($symbol eq 'opt') {
 819                         $input_params{$name} = [ $cgi->param($symbol) ];
 820                 } else {
 821                         $input_params{$name} = $cgi->param($symbol);
 822                 }
 823         }
 824 }
 825
 826 # now read PATH_INFO and update the parameter list for missing parameters
 827 sub evaluate_path_info {
 828         return if defined $input_params{'project'};
 829         return if !$path_info;
 830         $path_info =~ s,^/+,,;
 831         return if !$path_info;
 832
 833         # find which part of PATH_INFO is project
 834         my $project = $path_info;
 835         $project =~ s,/+$,,;
 836         while ($project && !check_head_link("$projectroot/$project")) {
 837                 $project =~ s,/*[^/]*$,,;
 838         }
 839         return unless $project;
 840         $input_params{'project'} = $project;
 841
 842         # do not change any parameters if an action is given using the query string
 843         return if $input_params{'action'};
 844         $path_info =~ s,^\Q$project\E/*,,;
 845
 846         # next, check if we have an action
 847         my $action = $path_info;
 848         $action =~ s,/.*$,,;
 849         if (exists $actions{$action}) {
 850                 $path_info =~ s,^$action/*,,;
 851                 $input_params{'action'} = $action;
 852         }
 853
 854         # list of actions that want hash_base instead of hash, but can have no
 855         # pathname (f) parameter
 856         my @wants_base = (
 857                 'tree',
 858                 'history',
 859         );
 860
 861         # we want to catch, among others
 862         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 863         my ($parentrefname, $parentpathname, $refname, $pathname) =
 864                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 865
 866         # first, analyze the 'current' part
 867         if (defined $pathname) {
 868                 # we got "branch:filename" or "branch:dir/"
 869                 # we could use git_get_type(branch:pathname), but:
 870                 # - it needs $git_dir
 871                 # - it does a git() call
 872                 # - the convention of terminating directories with a slash
 873                 #   makes it superfluous
 874                 # - embedding the action in the PATH_INFO would make it even
 875                 #   more superfluous
 876                 $pathname =~ s,^/+,,;
 877                 if (!$pathname || substr($pathname, -1) eq "/") {
 878                         $input_params{'action'} ||= "tree";
 879                         $pathname =~ s,/$,,;
 880                 } else {
 881                         # the default action depends on whether we had parent info
 882                         # or not
 883                         if ($parentrefname) {
 884                                 $input_params{'action'} ||= "blobdiff_plain";
 885                         } else {
 886                                 $input_params{'action'} ||= "blob_plain";
 887                         }
 888                 }
 889                 $input_params{'hash_base'} ||= $refname;
 890                 $input_params{'file_name'} ||= $pathname;
 891         } elsif (defined $refname) {
 892                 # we got "branch". In this case we have to choose if we have to
 893                 # set hash or hash_base.
 894                 #
 895                 # Most of the actions without a pathname only want hash to be
 896                 # set, except for the ones specified in @wants_base that want
 897                 # hash_base instead. It should also be noted that hand-crafted
 898                 # links having 'history' as an action and no pathname or hash
 899                 # set will fail, but that happens regardless of PATH_INFO.
 900                 if (defined $parentrefname) {
 901                         # if there is parent let the default be 'shortlog' action
 902                         # (for http://git.example.com/repo.git/A..B links); if there
 903                         # is no parent, dispatch will detect type of object and set
 904                         # action appropriately if required (if action is not set)
 905                         $input_params{'action'} ||= "shortlog";
 906                 }
 907                 if ($input_params{'action'} &&
 908                     grep { $_ eq $input_params{'action'} } @wants_base) {
 909                         $input_params{'hash_base'} ||= $refname;
 910                 } else {
 911                         $input_params{'hash'} ||= $refname;
 912                 }
 913         }
 914
 915         # next, handle the 'parent' part, if present
 916         if (defined $parentrefname) {
 917                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 918                 # someproject/blobdiff/oldrev..newrev:/filename
 919                 if ($parentpathname) {
 920                         $parentpathname =~ s,^/+,,;
 921                         $parentpathname =~ s,/$,,;
 922                         $input_params{'file_parent'} ||= $parentpathname;
 923                 } else {
 924                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 925                 }
 926                 # we assume that hash_parent_base is wanted if a path was specified,
 927                 # or if the action wants hash_base instead of hash
 928                 if (defined $input_params{'file_parent'} ||
 929                         grep { $_ eq $input_params{'action'} } @wants_base) {
 930                         $input_params{'hash_parent_base'} ||= $parentrefname;
 931                 } else {
 932                         $input_params{'hash_parent'} ||= $parentrefname;
 933                 }
 934         }
 935
 936         # for the snapshot action, we allow URLs in the form
 937         # $project/snapshot/$hash.ext
 938         # where .ext determines the snapshot and gets removed from the
 939         # passed $refname to provide the $hash.
 940         #
 941         # To be able to tell that $refname includes the format extension, we
 942         # require the following two conditions to be satisfied:
 943         # - the hash input parameter MUST have been set from the $refname part
 944         #   of the URL (i.e. they must be equal)
 945         # - the snapshot format MUST NOT have been defined already (e.g. from
 946         #   CGI parameter sf)
 947         # It's also useless to try any matching unless $refname has a dot,
 948         # so we check for that too
 949         if (defined $input_params{'action'} &&
 950                 $input_params{'action'} eq 'snapshot' &&
 951                 defined $refname && index($refname, '.') != -1 &&
 952                 $refname eq $input_params{'hash'} &&
 953                 !defined $input_params{'snapshot_format'}) {
 954                 # We loop over the known snapshot formats, checking for
 955                 # extensions. Allowed extensions are both the defined suffix
 956                 # (which includes the initial dot already) and the snapshot
 957                 # format key itself, with a prepended dot
 958                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 959                         my $hash = $refname;
 960                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 961                                 next;
 962                         }
 963                         my $sfx = $1;
 964                         # a valid suffix was found, so set the snapshot format
 965                         # and reset the hash parameter
 966                         $input_params{'snapshot_format'} = $fmt;
 967                         $input_params{'hash'} = $hash;
 968                         # we also set the format suffix to the one requested
 969                         # in the URL: this way a request for e.g. .tgz returns
 970                         # a .tgz instead of a .tar.gz
 971                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 972                         last;
 973                 }
 974         }
 975 }
 976
 977 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 978      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 979      $searchtext, $search_regexp);
 980 sub evaluate_and_validate_params {
 981         our $action = $input_params{'action'};
 982         if (defined $action) {
 983                 if (!validate_action($action)) {
 984                         die_error(400, "Invalid action parameter");
 985                 }
 986         }
 987
 988         # parameters which are pathnames
 989         our $project = $input_params{'project'};
 990         if (defined $project) {
 991                 if (!validate_project($project)) {
 992                         undef $project;
 993                         die_error(404, "No such project");
 994                 }
 995         }
 996
 997         our $file_name = $input_params{'file_name'};
 998         if (defined $file_name) {
 999                 if (!validate_pathname($file_name)) {
1000                         die_error(400, "Invalid file parameter");
1001                 }
1002         }
1003
1004         our $file_parent = $input_params{'file_parent'};
1005         if (defined $file_parent) {
1006                 if (!validate_pathname($file_parent)) {
1007                         die_error(400, "Invalid file parent parameter");
1008                 }
1009         }
1010
1011         # parameters which are refnames
1012         our $hash = $input_params{'hash'};
1013         if (defined $hash) {
1014                 if (!validate_refname($hash)) {
1015                         die_error(400, "Invalid hash parameter");
1016                 }
1017         }
1018
1019         our $hash_parent = $input_params{'hash_parent'};
1020         if (defined $hash_parent) {
1021                 if (!validate_refname($hash_parent)) {
1022                         die_error(400, "Invalid hash parent parameter");
1023                 }
1024         }
1025
1026         our $hash_base = $input_params{'hash_base'};
1027         if (defined $hash_base) {
1028                 if (!validate_refname($hash_base)) {
1029                         die_error(400, "Invalid hash base parameter");
1030                 }
1031         }
1032
1033         our @extra_options = @{$input_params{'extra_options'}};
1034         # @extra_options is always defined, since it can only be (currently) set from
1035         # CGI, and $cgi->param() returns the empty array in array context if the param
1036         # is not set
1037         foreach my $opt (@extra_options) {
1038                 if (not exists $allowed_options{$opt}) {
1039                         die_error(400, "Invalid option parameter");
1040                 }
1041                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1042                         die_error(400, "Invalid option parameter for this action");
1043                 }
1044         }
1045
1046         our $hash_parent_base = $input_params{'hash_parent_base'};
1047         if (defined $hash_parent_base) {
1048                 if (!validate_refname($hash_parent_base)) {
1049                         die_error(400, "Invalid hash parent base parameter");
1050                 }
1051         }
1052
1053         # other parameters
1054         our $page = $input_params{'page'};
1055         if (defined $page) {
1056                 if ($page =~ m/[^0-9]/) {
1057                         die_error(400, "Invalid page parameter");
1058                 }
1059         }
1060
1061         our $searchtype = $input_params{'searchtype'};
1062         if (defined $searchtype) {
1063                 if ($searchtype =~ m/[^a-z]/) {
1064                         die_error(400, "Invalid searchtype parameter");
1065                 }
1066         }
1067
1068         our $search_use_regexp = $input_params{'search_use_regexp'};
1069
1070         our $searchtext = $input_params{'searchtext'};
1071         our $search_regexp;
1072         if (defined $searchtext) {
1073                 if (length($searchtext) < 2) {
1074                         die_error(403, "At least two characters are required for search parameter");
1075                 }
1076                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1077         }
1078 }
1079
1080 # path to the current git repository
1081 our $git_dir;
1082 sub evaluate_git_dir {
1083         our $git_dir = "$projectroot/$project" if $project;
1084 }
1085
1086 our (@snapshot_fmts, $git_avatar);
1087 sub configure_gitweb_features {
1088         # list of supported snapshot formats
1089         our @snapshot_fmts = gitweb_get_feature('snapshot');
1090         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1091
1092         # check that the avatar feature is set to a known provider name,
1093         # and for each provider check if the dependencies are satisfied.
1094         # if the provider name is invalid or the dependencies are not met,
1095         # reset $git_avatar to the empty string.
1096         our ($git_avatar) = gitweb_get_feature('avatar');
1097         if ($git_avatar eq 'gravatar') {
1098                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1099         } elsif ($git_avatar eq 'picon') {
1100                 # no dependencies
1101         } else {
1102                 $git_avatar = '';
1103         }
1104 }
1105
1106 # custom error handler: 'die <message>' is Internal Server Error
1107 sub handle_errors_html {
1108         my $msg = shift; # it is already HTML escaped
1109
1110         # to avoid infinite loop where error occurs in die_error,
1111         # change handler to default handler, disabling handle_errors_html
1112         set_message("Error occured when inside die_error:\n$msg");
1113
1114         # you cannot jump out of die_error when called as error handler;
1115         # the subroutine set via CGI::Carp::set_message is called _after_
1116         # HTTP headers are already written, so it cannot write them itself
1117         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1118 }
1119 set_message(\&handle_errors_html);
1120
1121 # dispatch
1122 sub dispatch {
1123         if (!defined $action) {
1124                 if (defined $hash) {
1125                         $action = git_get_type($hash);
1126                 } elsif (defined $hash_base && defined $file_name) {
1127                         $action = git_get_type("$hash_base:$file_name");
1128                 } elsif (defined $project) {
1129                         $action = 'summary';
1130                 } else {
1131                         $action = 'project_list';
1132                 }
1133         }
1134         if (!defined($actions{$action})) {
1135                 die_error(400, "Unknown action");
1136         }
1137         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1138             !$project) {
1139                 die_error(400, "Project needed");
1140         }
1141         $actions{$action}->();
1142 }
1143
1144 sub reset_timer {
1145         our $t0 = [ gettimeofday() ]
1146                 if defined $t0;
1147         our $number_of_git_cmds = 0;
1148 }
1149
1150 our $first_request = 1;
1151 sub run_request {
1152         reset_timer();
1153
1154         evaluate_uri();
1155         if ($first_request) {
1156                 evaluate_gitweb_config();
1157                 evaluate_git_version();
1158         }
1159         if ($per_request_config) {
1160                 if (ref($per_request_config) eq 'CODE') {
1161                         $per_request_config->();
1162                 } elsif (!$first_request) {
1163                         evaluate_gitweb_config();
1164                 }
1165         }
1166         check_loadavg();
1167
1168         # $projectroot and $projects_list might be set in gitweb config file
1169         $projects_list ||= $projectroot;
1170
1171         evaluate_query_params();
1172         evaluate_path_info();
1173         evaluate_and_validate_params();
1174         evaluate_git_dir();
1175
1176         configure_gitweb_features();
1177
1178         dispatch();
1179 }
1180
1181 our $is_last_request = sub { 1 };
1182 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1183 our $CGI = 'CGI';
1184 our $cgi;
1185 sub configure_as_fcgi {
1186         require CGI::Fast;
1187         our $CGI = 'CGI::Fast';
1188
1189         my $request_number = 0;
1190         # let each child service 100 requests
1191         our $is_last_request = sub { ++$request_number > 100 };
1192 }
1193 sub evaluate_argv {
1194         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1195         configure_as_fcgi()
1196                 if $script_name =~ /\.fcgi$/;
1197
1198         return unless (@ARGV);
1199
1200         require Getopt::Long;
1201         Getopt::Long::GetOptions(
1202                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1203                 'nproc|n=i' => sub {
1204                         my ($arg, $val) = @_;
1205                         return unless eval { require FCGI::ProcManager; 1; };
1206                         my $proc_manager = FCGI::ProcManager->new({
1207                                 n_processes => $val,
1208                         });
1209                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1210                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1211                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1212                 },
1213         );
1214 }
1215
1216 sub run {
1217         evaluate_argv();
1218
1219         $first_request = 1;
1220         $pre_listen_hook->()
1221                 if $pre_listen_hook;
1222
1223  REQUEST:
1224         while ($cgi = $CGI->new()) {
1225                 $pre_dispatch_hook->()
1226                         if $pre_dispatch_hook;
1227
1228                 run_request();
1229
1230                 $post_dispatch_hook->()
1231                         if $post_dispatch_hook;
1232                 $first_request = 0;
1233
1234                 last REQUEST if ($is_last_request->());
1235         }
1236
1237  DONE_GITWEB:
1238         1;
1239 }
1240
1241 run();
1242
1243 if (defined caller) {
1244         # wrapped in a subroutine processing requests,
1245         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1246         return;
1247 } else {
1248         # pure CGI script, serving single request
1249         exit;
1250 }
1251
1252 ## ======================================================================
1253 ## action links
1254
1255 # possible values of extra options
1256 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1257 # -replay => 1      - start from a current view (replay with modifications)
1258 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1259 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1260 sub href {
1261         my %params = @_;
1262         # default is to use -absolute url() i.e. $my_uri
1263         my $href = $params{-full} ? $my_url : $my_uri;
1264
1265         # implicit -replay, must be first of implicit params
1266         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1267
1268         $params{'project'} = $project unless exists $params{'project'};
1269
1270         if ($params{-replay}) {
1271                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1272                         if (!exists $params{$name}) {
1273                                 $params{$name} = $input_params{$name};
1274                         }
1275                 }
1276         }
1277
1278         my $use_pathinfo = gitweb_check_feature('pathinfo');
1279         if (defined $params{'project'} &&
1280             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1281                 # try to put as many parameters as possible in PATH_INFO:
1282                 #   - project name
1283                 #   - action
1284                 #   - hash_parent or hash_parent_base:/file_parent
1285                 #   - hash or hash_base:/filename
1286                 #   - the snapshot_format as an appropriate suffix
1287
1288                 # When the script is the root DirectoryIndex for the domain,
1289                 # $href here would be something like http://gitweb.example.com/
1290                 # Thus, we strip any trailing / from $href, to spare us double
1291                 # slashes in the final URL
1292                 $href =~ s,/$,,;
1293
1294                 # Then add the project name, if present
1295                 $href .= "/".esc_path_info($params{'project'});
1296                 delete $params{'project'};
1297
1298                 # since we destructively absorb parameters, we keep this
1299                 # boolean that remembers if we're handling a snapshot
1300                 my $is_snapshot = $params{'action'} eq 'snapshot';
1301
1302                 # Summary just uses the project path URL, any other action is
1303                 # added to the URL
1304                 if (defined $params{'action'}) {
1305                         $href .= "/".esc_path_info($params{'action'})
1306                                 unless $params{'action'} eq 'summary';
1307                         delete $params{'action'};
1308                 }
1309
1310                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1311                 # stripping nonexistent or useless pieces
1312                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1313                         || $params{'hash_parent'} || $params{'hash'});
1314                 if (defined $params{'hash_base'}) {
1315                         if (defined $params{'hash_parent_base'}) {
1316                                 $href .= esc_path_info($params{'hash_parent_base'});
1317                                 # skip the file_parent if it's the same as the file_name
1318                                 if (defined $params{'file_parent'}) {
1319                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1320                                                 delete $params{'file_parent'};
1321                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1322                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1323                                                 delete $params{'file_parent'};
1324                                         }
1325                                 }
1326                                 $href .= "..";
1327                                 delete $params{'hash_parent'};
1328                                 delete $params{'hash_parent_base'};
1329                         } elsif (defined $params{'hash_parent'}) {
1330                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1331                                 delete $params{'hash_parent'};
1332                         }
1333
1334                         $href .= esc_path_info($params{'hash_base'});
1335                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1336                                 $href .= ":/".esc_path_info($params{'file_name'});
1337                                 delete $params{'file_name'};
1338                         }
1339                         delete $params{'hash'};
1340                         delete $params{'hash_base'};
1341                 } elsif (defined $params{'hash'}) {
1342                         $href .= esc_path_info($params{'hash'});
1343                         delete $params{'hash'};
1344                 }
1345
1346                 # If the action was a snapshot, we can absorb the
1347                 # snapshot_format parameter too
1348                 if ($is_snapshot) {
1349                         my $fmt = $params{'snapshot_format'};
1350                         # snapshot_format should always be defined when href()
1351                         # is called, but just in case some code forgets, we
1352                         # fall back to the default
1353                         $fmt ||= $snapshot_fmts[0];
1354                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1355                         delete $params{'snapshot_format'};
1356                 }
1357         }
1358
1359         # now encode the parameters explicitly
1360         my @result = ();
1361         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1362                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1363                 if (defined $params{$name}) {
1364                         if (ref($params{$name}) eq "ARRAY") {
1365                                 foreach my $par (@{$params{$name}}) {
1366                                         push @result, $symbol . "=" . esc_param($par);
1367                                 }
1368                         } else {
1369                                 push @result, $symbol . "=" . esc_param($params{$name});
1370                         }
1371                 }
1372         }
1373         $href .= "?" . join(';', @result) if scalar @result;
1374
1375         # final transformation: trailing spaces must be escaped (URI-encoded)
1376         $href =~ s/(\s+)$/CGI::escape($1)/e;
1377
1378         if ($params{-anchor}) {
1379                 $href .= "#".esc_param($params{-anchor});
1380         }
1381
1382         return $href;
1383 }
1384
1385
1386 ## ======================================================================
1387 ## validation, quoting/unquoting and escaping
1388
1389 sub validate_action {
1390         my $input = shift || return undef;
1391         return undef unless exists $actions{$input};
1392         return $input;
1393 }
1394
1395 sub validate_project {
1396         my $input = shift || return undef;
1397         if (!validate_pathname($input) ||
1398                 !(-d "$projectroot/$input") ||
1399                 !check_export_ok("$projectroot/$input") ||
1400                 ($strict_export && !project_in_list($input))) {
1401                 return undef;
1402         } else {
1403                 return $input;
1404         }
1405 }
1406
1407 sub validate_pathname {
1408         my $input = shift || return undef;
1409
1410         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1411         # at the beginning, at the end, and between slashes.
1412         # also this catches doubled slashes
1413         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1414                 return undef;
1415         }
1416         # no null characters
1417         if ($input =~ m!\0!) {
1418                 return undef;
1419         }
1420         return $input;
1421 }
1422
1423 sub validate_refname {
1424         my $input = shift || return undef;
1425
1426         # textual hashes are O.K.
1427         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1428                 return $input;
1429         }
1430         # it must be correct pathname
1431         $input = validate_pathname($input)
1432                 or return undef;
1433         # restrictions on ref name according to git-check-ref-format
1434         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1435                 return undef;
1436         }
1437         return $input;
1438 }
1439
1440 # decode sequences of octets in utf8 into Perl's internal form,
1441 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1442 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1443 sub to_utf8 {
1444         my $str = shift;
1445         return undef unless defined $str;
1446         if (utf8::valid($str)) {
1447                 utf8::decode($str);
1448                 return $str;
1449         } else {
1450                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1451         }
1452 }
1453
1454 # quote unsafe chars, but keep the slash, even when it's not
1455 # correct, but quoted slashes look too horrible in bookmarks
1456 sub esc_param {
1457         my $str = shift;
1458         return undef unless defined $str;
1459         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1460         $str =~ s/ /\+/g;
1461         return $str;
1462 }
1463
1464 # the quoting rules for path_info fragment are slightly different
1465 sub esc_path_info {
1466         my $str = shift;
1467         return undef unless defined $str;
1468
1469         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1470         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1471
1472         return $str;
1473 }
1474
1475 # quote unsafe chars in whole URL, so some characters cannot be quoted
1476 sub esc_url {
1477         my $str = shift;
1478         return undef unless defined $str;
1479         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1480         $str =~ s/ /\+/g;
1481         return $str;
1482 }
1483
1484 # quote unsafe characters in HTML attributes
1485 sub esc_attr {
1486
1487         # for XHTML conformance escaping '"' to '&quot;' is not enough
1488         return esc_html(@_);
1489 }
1490
1491 # replace invalid utf8 character with SUBSTITUTION sequence
1492 sub esc_html {
1493         my $str = shift;
1494         my %opts = @_;
1495
1496         return undef unless defined $str;
1497
1498         $str = to_utf8($str);
1499         $str = $cgi->escapeHTML($str);
1500         if ($opts{'-nbsp'}) {
1501                 $str =~ s/ /&nbsp;/g;
1502         }
1503         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1504         return $str;
1505 }
1506
1507 # quote control characters and escape filename to HTML
1508 sub esc_path {
1509         my $str = shift;
1510         my %opts = @_;
1511
1512         return undef unless defined $str;
1513
1514         $str = to_utf8($str);
1515         $str = $cgi->escapeHTML($str);
1516         if ($opts{'-nbsp'}) {
1517                 $str =~ s/ /&nbsp;/g;
1518         }
1519         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1520         return $str;
1521 }
1522
1523 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1524 sub sanitize {
1525         my $str = shift;
1526
1527         return undef unless defined $str;
1528
1529         $str = to_utf8($str);
1530         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1531         return $str;
1532 }
1533
1534 # Make control characters "printable", using character escape codes (CEC)
1535 sub quot_cec {
1536         my $cntrl = shift;
1537         my %opts = @_;
1538         my %es = ( # character escape codes, aka escape sequences
1539                 "\t" => '\t',   # tab            (HT)
1540                 "\n" => '\n',   # line feed      (LF)
1541                 "\r" => '\r',   # carrige return (CR)
1542                 "\f" => '\f',   # form feed      (FF)
1543                 "\b" => '\b',   # backspace      (BS)
1544                 "\a" => '\a',   # alarm (bell)   (BEL)
1545                 "\e" => '\e',   # escape         (ESC)
1546                 "\013" => '\v', # vertical tab   (VT)
1547                 "\000" => '\0', # nul character  (NUL)
1548         );
1549         my $chr = ( (exists $es{$cntrl})
1550                     ? $es{$cntrl}
1551                     : sprintf('\%2x', ord($cntrl)) );
1552         if ($opts{-nohtml}) {
1553                 return $chr;
1554         } else {
1555                 return "<span class=\"cntrl\">$chr</span>";
1556         }
1557 }
1558
1559 # Alternatively use unicode control pictures codepoints,
1560 # Unicode "printable representation" (PR)
1561 sub quot_upr {
1562         my $cntrl = shift;
1563         my %opts = @_;
1564
1565         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1566         if ($opts{-nohtml}) {
1567                 return $chr;
1568         } else {
1569                 return "<span class=\"cntrl\">$chr</span>";
1570         }
1571 }
1572
1573 # git may return quoted and escaped filenames
1574 sub unquote {
1575         my $str = shift;
1576
1577         sub unq {
1578                 my $seq = shift;
1579                 my %es = ( # character escape codes, aka escape sequences
1580                         't' => "\t",   # tab            (HT, TAB)
1581                         'n' => "\n",   # newline        (NL)
1582                         'r' => "\r",   # return         (CR)
1583                         'f' => "\f",   # form feed      (FF)
1584                         'b' => "\b",   # backspace      (BS)
1585                         'a' => "\a",   # alarm (bell)   (BEL)
1586                         'e' => "\e",   # escape         (ESC)
1587                         'v' => "\013", # vertical tab   (VT)
1588                 );
1589
1590                 if ($seq =~ m/^[0-7]{1,3}$/) {
1591                         # octal char sequence
1592                         return chr(oct($seq));
1593                 } elsif (exists $es{$seq}) {
1594                         # C escape sequence, aka character escape code
1595                         return $es{$seq};
1596                 }
1597                 # quoted ordinary character
1598                 return $seq;
1599         }
1600
1601         if ($str =~ m/^"(.*)"$/) {
1602                 # needs unquoting
1603                 $str = $1;
1604                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1605         }
1606         return $str;
1607 }
1608
1609 # escape tabs (convert tabs to spaces)
1610 sub untabify {
1611         my $line = shift;
1612
1613         while ((my $pos = index($line, "\t")) != -1) {
1614                 if (my $count = (8 - ($pos % 8))) {
1615                         my $spaces = ' ' x $count;
1616                         $line =~ s/\t/$spaces/;
1617                 }
1618         }
1619
1620         return $line;
1621 }
1622
1623 sub project_in_list {
1624         my $project = shift;
1625         my @list = git_get_projects_list();
1626         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1627 }
1628
1629 ## ----------------------------------------------------------------------
1630 ## HTML aware string manipulation
1631
1632 # Try to chop given string on a word boundary between position
1633 # $len and $len+$add_len. If there is no word boundary there,
1634 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1635 # (marking chopped part) would be longer than given string.
1636 sub chop_str {
1637         my $str = shift;
1638         my $len = shift;
1639         my $add_len = shift || 10;
1640         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1641
1642         # Make sure perl knows it is utf8 encoded so we don't
1643         # cut in the middle of a utf8 multibyte char.
1644         $str = to_utf8($str);
1645
1646         # allow only $len chars, but don't cut a word if it would fit in $add_len
1647         # if it doesn't fit, cut it if it's still longer than the dots we would add
1648         # remove chopped character entities entirely
1649
1650         # when chopping in the middle, distribute $len into left and right part
1651         # return early if chopping wouldn't make string shorter
1652         if ($where eq 'center') {
1653                 return $str if ($len + 5 >= length($str)); # filler is length 5
1654                 $len = int($len/2);
1655         } else {
1656                 return $str if ($len + 4 >= length($str)); # filler is length 4
1657         }
1658
1659         # regexps: ending and beginning with word part up to $add_len
1660         my $endre = qr/.{$len}\w{0,$add_len}/;
1661         my $begre = qr/\w{0,$add_len}.{$len}/;
1662
1663         if ($where eq 'left') {
1664                 $str =~ m/^(.*?)($begre)$/;
1665                 my ($lead, $body) = ($1, $2);
1666                 if (length($lead) > 4) {
1667                         $lead = " ...";
1668                 }
1669                 return "$lead$body";
1670
1671         } elsif ($where eq 'center') {
1672                 $str =~ m/^($endre)(.*)$/;
1673                 my ($left, $str)  = ($1, $2);
1674                 $str =~ m/^(.*?)($begre)$/;
1675                 my ($mid, $right) = ($1, $2);
1676                 if (length($mid) > 5) {
1677                         $mid = " ... ";
1678                 }
1679                 return "$left$mid$right";
1680
1681         } else {
1682                 $str =~ m/^($endre)(.*)$/;
1683                 my $body = $1;
1684                 my $tail = $2;
1685                 if (length($tail) > 4) {
1686                         $tail = "... ";
1687                 }
1688                 return "$body$tail";
1689         }
1690 }
1691
1692 # takes the same arguments as chop_str, but also wraps a <span> around the
1693 # result with a title attribute if it does get chopped. Additionally, the
1694 # string is HTML-escaped.
1695 sub chop_and_escape_str {
1696         my ($str) = @_;
1697
1698         my $chopped = chop_str(@_);
1699         if ($chopped eq $str) {
1700                 return esc_html($chopped);
1701         } else {
1702                 $str =~ s/[[:cntrl:]]/?/g;
1703                 return $cgi->span({-title=>$str}, esc_html($chopped));
1704         }
1705 }
1706
1707 ## ----------------------------------------------------------------------
1708 ## functions returning short strings
1709
1710 # CSS class for given age value (in seconds)
1711 sub age_class {
1712         my $age = shift;
1713
1714         if (!defined $age) {
1715                 return "noage";
1716         } elsif ($age < 60*60*2) {
1717                 return "age0";
1718         } elsif ($age < 60*60*24*2) {
1719                 return "age1";
1720         } else {
1721                 return "age2";
1722         }
1723 }
1724
1725 # convert age in seconds to "nn units ago" string
1726 sub age_string {
1727         my $age = shift;
1728         my $age_str;
1729
1730         if ($age > 60*60*24*365*2) {
1731                 $age_str = (int $age/60/60/24/365);
1732                 $age_str .= " years ago";
1733         } elsif ($age > 60*60*24*(365/12)*2) {
1734                 $age_str = int $age/60/60/24/(365/12);
1735                 $age_str .= " months ago";
1736         } elsif ($age > 60*60*24*7*2) {
1737                 $age_str = int $age/60/60/24/7;
1738                 $age_str .= " weeks ago";
1739         } elsif ($age > 60*60*24*2) {
1740                 $age_str = int $age/60/60/24;
1741                 $age_str .= " days ago";
1742         } elsif ($age > 60*60*2) {
1743                 $age_str = int $age/60/60;
1744                 $age_str .= " hours ago";
1745         } elsif ($age > 60*2) {
1746                 $age_str = int $age/60;
1747                 $age_str .= " min ago";
1748         } elsif ($age > 2) {
1749                 $age_str = int $age;
1750                 $age_str .= " sec ago";
1751         } else {
1752                 $age_str .= " right now";
1753         }
1754         return $age_str;
1755 }
1756
1757 use constant {
1758         S_IFINVALID => 0030000,
1759         S_IFGITLINK => 0160000,
1760 };
1761
1762 # submodule/subproject, a commit object reference
1763 sub S_ISGITLINK {
1764         my $mode = shift;
1765
1766         return (($mode & S_IFMT) == S_IFGITLINK)
1767 }
1768
1769 # convert file mode in octal to symbolic file mode string
1770 sub mode_str {
1771         my $mode = oct shift;
1772
1773         if (S_ISGITLINK($mode)) {
1774                 return 'm---------';
1775         } elsif (S_ISDIR($mode & S_IFMT)) {
1776                 return 'drwxr-xr-x';
1777         } elsif (S_ISLNK($mode)) {
1778                 return 'lrwxrwxrwx';
1779         } elsif (S_ISREG($mode)) {
1780                 # git cares only about the executable bit
1781                 if ($mode & S_IXUSR) {
1782                         return '-rwxr-xr-x';
1783                 } else {
1784                         return '-rw-r--r--';
1785                 };
1786         } else {
1787                 return '----------';
1788         }
1789 }
1790
1791 # convert file mode in octal to file type string
1792 sub file_type {
1793         my $mode = shift;
1794
1795         if ($mode !~ m/^[0-7]+$/) {
1796                 return $mode;
1797         } else {
1798                 $mode = oct $mode;
1799         }
1800
1801         if (S_ISGITLINK($mode)) {
1802                 return "submodule";
1803         } elsif (S_ISDIR($mode & S_IFMT)) {
1804                 return "directory";
1805         } elsif (S_ISLNK($mode)) {
1806                 return "symlink";
1807         } elsif (S_ISREG($mode)) {
1808                 return "file";
1809         } else {
1810                 return "unknown";
1811         }
1812 }
1813
1814 # convert file mode in octal to file type description string
1815 sub file_type_long {
1816         my $mode = shift;
1817
1818         if ($mode !~ m/^[0-7]+$/) {
1819                 return $mode;
1820         } else {
1821                 $mode = oct $mode;
1822         }
1823
1824         if (S_ISGITLINK($mode)) {
1825                 return "submodule";
1826         } elsif (S_ISDIR($mode & S_IFMT)) {
1827                 return "directory";
1828         } elsif (S_ISLNK($mode)) {
1829                 return "symlink";
1830         } elsif (S_ISREG($mode)) {
1831                 if ($mode & S_IXUSR) {
1832                         return "executable";
1833                 } else {
1834                         return "file";
1835                 };
1836         } else {
1837                 return "unknown";
1838         }
1839 }
1840
1841
1842 ## ----------------------------------------------------------------------
1843 ## functions returning short HTML fragments, or transforming HTML fragments
1844 ## which don't belong to other sections
1845
1846 # format line of commit message.
1847 sub format_log_line_html {
1848         my $line = shift;
1849
1850         $line = esc_html($line, -nbsp=>1);
1851         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1852                 $cgi->a({-href => href(action=>"object", hash=>$1),
1853                                         -class => "text"}, $1);
1854         }eg;
1855
1856         return $line;
1857 }
1858
1859 # format marker of refs pointing to given object
1860
1861 # the destination action is chosen based on object type and current context:
1862 # - for annotated tags, we choose the tag view unless it's the current view
1863 #   already, in which case we go to shortlog view
1864 # - for other refs, we keep the current view if we're in history, shortlog or
1865 #   log view, and select shortlog otherwise
1866 sub format_ref_marker {
1867         my ($refs, $id) = @_;
1868         my $markers = '';
1869
1870         if (defined $refs->{$id}) {
1871                 foreach my $ref (@{$refs->{$id}}) {
1872                         # this code exploits the fact that non-lightweight tags are the
1873                         # only indirect objects, and that they are the only objects for which
1874                         # we want to use tag instead of shortlog as action
1875                         my ($type, $name) = qw();
1876                         my $indirect = ($ref =~ s/\^\{\}$//);
1877                         # e.g. tags/v2.6.11 or heads/next
1878                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1879                                 $type = $1;
1880                                 $name = $2;
1881                         } else {
1882                                 $type = "ref";
1883                                 $name = $ref;
1884                         }
1885
1886                         my $class = $type;
1887                         $class .= " indirect" if $indirect;
1888
1889                         my $dest_action = "shortlog";
1890
1891                         if ($indirect) {
1892                                 $dest_action = "tag" unless $action eq "tag";
1893                         } elsif ($action =~ /^(history|(short)?log)$/) {
1894                                 $dest_action = $action;
1895                         }
1896
1897                         my $dest = "";
1898                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1899                         $dest .= $ref;
1900
1901                         my $link = $cgi->a({
1902                                 -href => href(
1903                                         action=>$dest_action,
1904                                         hash=>$dest
1905                                 )}, $name);
1906
1907                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1908                                 $link . "</span>";
1909                 }
1910         }
1911
1912         if ($markers) {
1913                 return ' <span class="refs">'. $markers . '</span>';
1914         } else {
1915                 return "";
1916         }
1917 }
1918
1919 # format, perhaps shortened and with markers, title line
1920 sub format_subject_html {
1921         my ($long, $short, $href, $extra) = @_;
1922         $extra = '' unless defined($extra);
1923
1924         if (length($short) < length($long)) {
1925                 $long =~ s/[[:cntrl:]]/?/g;
1926                 return $cgi->a({-href => $href, -class => "list subject",
1927                                 -title => to_utf8($long)},
1928                        esc_html($short)) . $extra;
1929         } else {
1930                 return $cgi->a({-href => $href, -class => "list subject"},
1931                        esc_html($long)) . $extra;
1932         }
1933 }
1934
1935 # Rather than recomputing the url for an email multiple times, we cache it
1936 # after the first hit. This gives a visible benefit in views where the avatar
1937 # for the same email is used repeatedly (e.g. shortlog).
1938 # The cache is shared by all avatar engines (currently gravatar only), which
1939 # are free to use it as preferred. Since only one avatar engine is used for any
1940 # given page, there's no risk for cache conflicts.
1941 our %avatar_cache = ();
1942
1943 # Compute the picon url for a given email, by using the picon search service over at
1944 # http://www.cs.indiana.edu/picons/search.html
1945 sub picon_url {
1946         my $email = lc shift;
1947         if (!$avatar_cache{$email}) {
1948                 my ($user, $domain) = split('@', $email);
1949                 $avatar_cache{$email} =
1950                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1951                         "$domain/$user/" .
1952                         "users+domains+unknown/up/single";
1953         }
1954         return $avatar_cache{$email};
1955 }
1956
1957 # Compute the gravatar url for a given email, if it's not in the cache already.
1958 # Gravatar stores only the part of the URL before the size, since that's the
1959 # one computationally more expensive. This also allows reuse of the cache for
1960 # different sizes (for this particular engine).
1961 sub gravatar_url {
1962         my $email = lc shift;
1963         my $size = shift;
1964         $avatar_cache{$email} ||=
1965                 "http://www.gravatar.com/avatar/" .
1966                         Digest::MD5::md5_hex($email) . "?s=";
1967         return $avatar_cache{$email} . $size;
1968 }
1969
1970 # Insert an avatar for the given $email at the given $size if the feature
1971 # is enabled.
1972 sub git_get_avatar {
1973         my ($email, %opts) = @_;
1974         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1975         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1976         $opts{-size} ||= 'default';
1977         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1978         my $url = "";
1979         if ($git_avatar eq 'gravatar') {
1980                 $url = gravatar_url($email, $size);
1981         } elsif ($git_avatar eq 'picon') {
1982                 $url = picon_url($email);
1983         }
1984         # Other providers can be added by extending the if chain, defining $url
1985         # as needed. If no variant puts something in $url, we assume avatars
1986         # are completely disabled/unavailable.
1987         if ($url) {
1988                 return $pre_white .
1989                        "<img width=\"$size\" " .
1990                             "class=\"avatar\" " .
1991                             "src=\"".esc_url($url)."\" " .
1992                             "alt=\"\" " .
1993                        "/>" . $post_white;
1994         } else {
1995                 return "";
1996         }
1997 }
1998
1999 sub format_search_author {
2000         my ($author, $searchtype, $displaytext) = @_;
2001         my $have_search = gitweb_check_feature('search');
2002
2003         if ($have_search) {
2004                 my $performed = "";
2005                 if ($searchtype eq 'author') {
2006                         $performed = "authored";
2007                 } elsif ($searchtype eq 'committer') {
2008                         $performed = "committed";
2009                 }
2010
2011                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2012                                 searchtext=>$author,
2013                                 searchtype=>$searchtype), class=>"list",
2014                                 title=>"Search for commits $performed by $author"},
2015                                 $displaytext);
2016
2017         } else {
2018                 return $displaytext;
2019         }
2020 }
2021
2022 # format the author name of the given commit with the given tag
2023 # the author name is chopped and escaped according to the other
2024 # optional parameters (see chop_str).
2025 sub format_author_html {
2026         my $tag = shift;
2027         my $co = shift;
2028         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2029         return "<$tag class=\"author\">" .
2030                format_search_author($co->{'author_name'}, "author",
2031                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2032                        $author) .
2033                "</$tag>";
2034 }
2035
2036 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2037 sub format_git_diff_header_line {
2038         my $line = shift;
2039         my $diffinfo = shift;
2040         my ($from, $to) = @_;
2041
2042         if ($diffinfo->{'nparents'}) {
2043                 # combined diff
2044                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2045                 if ($to->{'href'}) {
2046                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2047                                          esc_path($to->{'file'}));
2048                 } else { # file was deleted (no href)
2049                         $line .= esc_path($to->{'file'});
2050                 }
2051         } else {
2052                 # "ordinary" diff
2053                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2054                 if ($from->{'href'}) {
2055                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2056                                          'a/' . esc_path($from->{'file'}));
2057                 } else { # file was added (no href)
2058                         $line .= 'a/' . esc_path($from->{'file'});
2059                 }
2060                 $line .= ' ';
2061                 if ($to->{'href'}) {
2062                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2063                                          'b/' . esc_path($to->{'file'}));
2064                 } else { # file was deleted
2065                         $line .= 'b/' . esc_path($to->{'file'});
2066                 }
2067         }
2068
2069         return "<div class=\"diff header\">$line</div>\n";
2070 }
2071
2072 # format extended diff header line, before patch itself
2073 sub format_extended_diff_header_line {
2074         my $line = shift;
2075         my $diffinfo = shift;
2076         my ($from, $to) = @_;
2077
2078         # match <path>
2079         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2080                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2081                                        esc_path($from->{'file'}));
2082         }
2083         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2084                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2085                                  esc_path($to->{'file'}));
2086         }
2087         # match single <mode>
2088         if ($line =~ m/\s(\d{6})$/) {
2089                 $line .= '<span class="info"> (' .
2090                          file_type_long($1) .
2091                          ')</span>';
2092         }
2093         # match <hash>
2094         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2095                 # can match only for combined diff
2096                 $line = 'index ';
2097                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2098                         if ($from->{'href'}[$i]) {
2099                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2100                                                   -class=>"hash"},
2101                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2102                         } else {
2103                                 $line .= '0' x 7;
2104                         }
2105                         # separator
2106                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2107                 }
2108                 $line .= '..';
2109                 if ($to->{'href'}) {
2110                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2111                                          substr($diffinfo->{'to_id'},0,7));
2112                 } else {
2113                         $line .= '0' x 7;
2114                 }
2115
2116         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2117                 # can match only for ordinary diff
2118                 my ($from_link, $to_link);
2119                 if ($from->{'href'}) {
2120                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2121                                              substr($diffinfo->{'from_id'},0,7));
2122                 } else {
2123                         $from_link = '0' x 7;
2124                 }
2125                 if ($to->{'href'}) {
2126                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2127                                            substr($diffinfo->{'to_id'},0,7));
2128                 } else {
2129                         $to_link = '0' x 7;
2130                 }
2131                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2132                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2133         }
2134
2135         return $line . "<br/>\n";
2136 }
2137
2138 # format from-file/to-file diff header
2139 sub format_diff_from_to_header {
2140         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2141         my $line;
2142         my $result = '';
2143
2144         $line = $from_line;
2145         #assert($line =~ m/^---/) if DEBUG;
2146         # no extra formatting for "^--- /dev/null"
2147         if (! $diffinfo->{'nparents'}) {
2148                 # ordinary (single parent) diff
2149                 if ($line =~ m!^--- "?a/!) {
2150                         if ($from->{'href'}) {
2151                                 $line = '--- a/' .
2152                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2153                                                 esc_path($from->{'file'}));
2154                         } else {
2155                                 $line = '--- a/' .
2156                                         esc_path($from->{'file'});
2157                         }
2158                 }
2159                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2160
2161         } else {
2162                 # combined diff (merge commit)
2163                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2164                         if ($from->{'href'}[$i]) {
2165                                 $line = '--- ' .
2166                                         $cgi->a({-href=>href(action=>"blobdiff",
2167                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2168                                                              hash_parent_base=>$parents[$i],
2169                                                              file_parent=>$from->{'file'}[$i],
2170                                                              hash=>$diffinfo->{'to_id'},
2171                                                              hash_base=>$hash,
2172                                                              file_name=>$to->{'file'}),
2173                                                  -class=>"path",
2174                                                  -title=>"diff" . ($i+1)},
2175                                                 $i+1) .
2176                                         '/' .
2177                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2178                                                 esc_path($from->{'file'}[$i]));
2179                         } else {
2180                                 $line = '--- /dev/null';
2181                         }
2182                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2183                 }
2184         }
2185
2186         $line = $to_line;
2187         #assert($line =~ m/^\+\+\+/) if DEBUG;
2188         # no extra formatting for "^+++ /dev/null"
2189         if ($line =~ m!^\+\+\+ "?b/!) {
2190                 if ($to->{'href'}) {
2191                         $line = '+++ b/' .
2192                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2193                                         esc_path($to->{'file'}));
2194                 } else {
2195                         $line = '+++ b/' .
2196                                 esc_path($to->{'file'});
2197                 }
2198         }
2199         $result .= qq!<div class="diff to_file">$line</div>\n!;
2200
2201         return $result;
2202 }
2203
2204 # create note for patch simplified by combined diff
2205 sub format_diff_cc_simplified {
2206         my ($diffinfo, @parents) = @_;
2207         my $result = '';
2208
2209         $result .= "<div class=\"diff header\">" .
2210                    "diff --cc ";
2211         if (!is_deleted($diffinfo)) {
2212                 $result .= $cgi->a({-href => href(action=>"blob",
2213                                                   hash_base=>$hash,
2214                                                   hash=>$diffinfo->{'to_id'},
2215                                                   file_name=>$diffinfo->{'to_file'}),
2216                                     -class => "path"},
2217                                    esc_path($diffinfo->{'to_file'}));
2218         } else {
2219                 $result .= esc_path($diffinfo->{'to_file'});
2220         }
2221         $result .= "</div>\n" . # class="diff header"
2222                    "<div class=\"diff nodifferences\">" .
2223                    "Simple merge" .
2224                    "</div>\n"; # class="diff nodifferences"
2225
2226         return $result;
2227 }
2228
2229 sub diff_line_class {
2230         my ($line, $from, $to) = @_;
2231
2232         # ordinary diff
2233         my $num_sign = 1;
2234         # combined diff
2235         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2236                 $num_sign = scalar @{$from->{'href'}};
2237         }
2238
2239         my @diff_line_classifier = (
2240                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2241                 { regexp => qr/^\\/,               class => "incomplete"  },
2242                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2243                 # classifier for context must come before classifier add/rem,
2244                 # or we would have to use more complicated regexp, for example
2245                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2246                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2247                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2248         );
2249         for my $clsfy (@diff_line_classifier) {
2250                 return $clsfy->{'class'}
2251                         if ($line =~ $clsfy->{'regexp'});
2252         }
2253
2254         # fallback
2255         return "";
2256 }
2257
2258 # assumes that $from and $to are defined and correctly filled,
2259 # and that $line holds a line of chunk header for unified diff
2260 sub format_unidiff_chunk_header {
2261         my ($line, $from, $to) = @_;
2262
2263         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2264                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2265
2266         $from_lines = 0 unless defined $from_lines;
2267         $to_lines   = 0 unless defined $to_lines;
2268
2269         if ($from->{'href'}) {
2270                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2271                                      -class=>"list"}, $from_text);
2272         }
2273         if ($to->{'href'}) {
2274                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2275                                      -class=>"list"}, $to_text);
2276         }
2277         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2278                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2279         return $line;
2280 }
2281
2282 # assumes that $from and $to are defined and correctly filled,
2283 # and that $line holds a line of chunk header for combined diff
2284 sub format_cc_diff_chunk_header {
2285         my ($line, $from, $to) = @_;
2286
2287         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2288         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2289
2290         @from_text = split(' ', $ranges);
2291         for (my $i = 0; $i < @from_text; ++$i) {
2292                 ($from_start[$i], $from_nlines[$i]) =
2293                         (split(',', substr($from_text[$i], 1)), 0);
2294         }
2295
2296         $to_text   = pop @from_text;
2297         $to_start  = pop @from_start;
2298         $to_nlines = pop @from_nlines;
2299
2300         $line = "<span class=\"chunk_info\">$prefix ";
2301         for (my $i = 0; $i < @from_text; ++$i) {
2302                 if ($from->{'href'}[$i]) {
2303                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2304                                           -class=>"list"}, $from_text[$i]);
2305                 } else {
2306                         $line .= $from_text[$i];
2307                 }
2308                 $line .= " ";
2309         }
2310         if ($to->{'href'}) {
2311                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2312                                   -class=>"list"}, $to_text);
2313         } else {
2314                 $line .= $to_text;
2315         }
2316         $line .= " $prefix</span>" .
2317                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2318         return $line;
2319 }
2320
2321 # process patch (diff) line (not to be used for diff headers),
2322 # returning class and HTML-formatted (but not wrapped) line
2323 sub process_diff_line {
2324         my $line = shift;
2325         my ($from, $to) = @_;
2326
2327         my $diff_class = diff_line_class($line, $from, $to);
2328
2329         chomp $line;
2330         $line = untabify($line);
2331
2332         if ($from && $to && $line =~ m/^\@{2} /) {
2333                 $line = format_unidiff_chunk_header($line, $from, $to);
2334                 return $diff_class, $line;
2335
2336         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2337                 $line = format_cc_diff_chunk_header($line, $from, $to);
2338                 return $diff_class, $line;
2339
2340         }
2341         return $diff_class, esc_html($line, -nbsp=>1);
2342 }
2343
2344 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2345 # linked.  Pass the hash of the tree/commit to snapshot.
2346 sub format_snapshot_links {
2347         my ($hash) = @_;
2348         my $num_fmts = @snapshot_fmts;
2349         if ($num_fmts > 1) {
2350                 # A parenthesized list of links bearing format names.
2351                 # e.g. "snapshot (_tar.gz_ _zip_)"
2352                 return "snapshot (" . join(' ', map
2353                         $cgi->a({
2354                                 -href => href(
2355                                         action=>"snapshot",
2356                                         hash=>$hash,
2357                                         snapshot_format=>$_
2358                                 )
2359                         }, $known_snapshot_formats{$_}{'display'})
2360                 , @snapshot_fmts) . ")";
2361         } elsif ($num_fmts == 1) {
2362                 # A single "snapshot" link whose tooltip bears the format name.
2363                 # i.e. "_snapshot_"
2364                 my ($fmt) = @snapshot_fmts;
2365                 return
2366                         $cgi->a({
2367                                 -href => href(
2368                                         action=>"snapshot",
2369                                         hash=>$hash,
2370                                         snapshot_format=>$fmt
2371                                 ),
2372                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2373                         }, "snapshot");
2374         } else { # $num_fmts == 0
2375                 return undef;
2376         }
2377 }
2378
2379 ## ......................................................................
2380 ## functions returning values to be passed, perhaps after some
2381 ## transformation, to other functions; e.g. returning arguments to href()
2382
2383 # returns hash to be passed to href to generate gitweb URL
2384 # in -title key it returns description of link
2385 sub get_feed_info {
2386         my $format = shift || 'Atom';
2387         my %res = (action => lc($format));
2388
2389         # feed links are possible only for project views
2390         return unless (defined $project);
2391         # some views should link to OPML, or to generic project feed,
2392         # or don't have specific feed yet (so they should use generic)
2393         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2394
2395         my $branch;
2396         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2397         # from tag links; this also makes possible to detect branch links
2398         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2399             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2400                 $branch = $1;
2401         }
2402         # find log type for feed description (title)
2403         my $type = 'log';
2404         if (defined $file_name) {
2405                 $type  = "history of $file_name";
2406                 $type .= "/" if ($action eq 'tree');
2407                 $type .= " on '$branch'" if (defined $branch);
2408         } else {
2409                 $type = "log of $branch" if (defined $branch);
2410         }
2411
2412         $res{-title} = $type;
2413         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2414         $res{'file_name'} = $file_name;
2415
2416         return %res;
2417 }
2418
2419 ## ----------------------------------------------------------------------
2420 ## git utility subroutines, invoking git commands
2421
2422 # returns path to the core git executable and the --git-dir parameter as list
2423 sub git_cmd {
2424         $number_of_git_cmds++;
2425         return $GIT, '--git-dir='.$git_dir;
2426 }
2427
2428 # quote the given arguments for passing them to the shell
2429 # quote_command("command", "arg 1", "arg with ' and ! characters")
2430 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2431 # Try to avoid using this function wherever possible.
2432 sub quote_command {
2433         return join(' ',
2434                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2435 }
2436
2437 # get HEAD ref of given project as hash
2438 sub git_get_head_hash {
2439         return git_get_full_hash(shift, 'HEAD');
2440 }
2441
2442 sub git_get_full_hash {
2443         return git_get_hash(@_);
2444 }
2445
2446 sub git_get_short_hash {
2447         return git_get_hash(@_, '--short=7');
2448 }
2449
2450 sub git_get_hash {
2451         my ($project, $hash, @options) = @_;
2452         my $o_git_dir = $git_dir;
2453         my $retval = undef;
2454         $git_dir = "$projectroot/$project";
2455         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2456             '--verify', '-q', @options, $hash) {
2457                 $retval = <$fd>;
2458                 chomp $retval if defined $retval;
2459                 close $fd;
2460         }
2461         if (defined $o_git_dir) {
2462                 $git_dir = $o_git_dir;
2463         }
2464         return $retval;
2465 }
2466
2467 # get type of given object
2468 sub git_get_type {
2469         my $hash = shift;
2470
2471         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2472         my $type = <$fd>;
2473         close $fd or return;
2474         chomp $type;
2475         return $type;
2476 }
2477
2478 # repository configuration
2479 our $config_file = '';
2480 our %config;
2481
2482 # store multiple values for single key as anonymous array reference
2483 # single values stored directly in the hash, not as [ <value> ]
2484 sub hash_set_multi {
2485         my ($hash, $key, $value) = @_;
2486
2487         if (!exists $hash->{$key}) {
2488                 $hash->{$key} = $value;
2489         } elsif (!ref $hash->{$key}) {
2490                 $hash->{$key} = [ $hash->{$key}, $value ];
2491         } else {
2492                 push @{$hash->{$key}}, $value;
2493         }
2494 }
2495
2496 # return hash of git project configuration
2497 # optionally limited to some section, e.g. 'gitweb'
2498 sub git_parse_project_config {
2499         my $section_regexp = shift;
2500         my %config;
2501
2502         local $/ = "\0";
2503
2504         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2505                 or return;
2506
2507         while (my $keyval = <$fh>) {
2508                 chomp $keyval;
2509                 my ($key, $value) = split(/\n/, $keyval, 2);
2510
2511                 hash_set_multi(\%config, $key, $value)
2512                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2513         }
2514         close $fh;
2515
2516         return %config;
2517 }
2518
2519 # convert config value to boolean: 'true' or 'false'
2520 # no value, number > 0, 'true' and 'yes' values are true
2521 # rest of values are treated as false (never as error)
2522 sub config_to_bool {
2523         my $val = shift;
2524
2525         return 1 if !defined $val;             # section.key
2526
2527         # strip leading and trailing whitespace
2528         $val =~ s/^\s+//;
2529         $val =~ s/\s+$//;
2530
2531         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2532                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2533 }
2534
2535 # convert config value to simple decimal number
2536 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2537 # to be multiplied by 1024, 1048576, or 1073741824
2538 sub config_to_int {
2539         my $val = shift;
2540
2541         # strip leading and trailing whitespace
2542         $val =~ s/^\s+//;
2543         $val =~ s/\s+$//;
2544
2545         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2546                 $unit = lc($unit);
2547                 # unknown unit is treated as 1
2548                 return $num * ($unit eq 'g' ? 1073741824 :
2549                                $unit eq 'm' ?    1048576 :
2550                                $unit eq 'k' ?       1024 : 1);
2551         }
2552         return $val;
2553 }
2554
2555 # convert config value to array reference, if needed
2556 sub config_to_multi {
2557         my $val = shift;
2558
2559         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2560 }
2561
2562 sub git_get_project_config {
2563         my ($key, $type) = @_;
2564
2565         return unless defined $git_dir;
2566
2567         # key sanity check
2568         return unless ($key);
2569         # only subsection, if exists, is case sensitive,
2570         # and not lowercased by 'git config -z -l'
2571         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2572                 $key = join(".", lc($hi), $mi, lc($lo));
2573         } else {
2574                 $key = lc($key);
2575         }
2576         $key =~ s/^gitweb\.//;
2577         return if ($key =~ m/\W/);
2578
2579         # type sanity check
2580         if (defined $type) {
2581                 $type =~ s/^--//;
2582                 $type = undef
2583                         unless ($type eq 'bool' || $type eq 'int');
2584         }
2585
2586         # get config
2587         if (!defined $config_file ||
2588             $config_file ne "$git_dir/config") {
2589                 %config = git_parse_project_config('gitweb');
2590                 $config_file = "$git_dir/config";
2591         }
2592
2593         # check if config variable (key) exists
2594         return unless exists $config{"gitweb.$key"};
2595
2596         # ensure given type
2597         if (!defined $type) {
2598                 return $config{"gitweb.$key"};
2599         } elsif ($type eq 'bool') {
2600                 # backward compatibility: 'git config --bool' returns true/false
2601                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2602         } elsif ($type eq 'int') {
2603                 return config_to_int($config{"gitweb.$key"});
2604         }
2605         return $config{"gitweb.$key"};
2606 }
2607
2608 # get hash of given path at given ref
2609 sub git_get_hash_by_path {
2610         my $base = shift;
2611         my $path = shift || return undef;
2612         my $type = shift;
2613
2614         $path =~ s,/+$,,;
2615
2616         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2617                 or die_error(500, "Open git-ls-tree failed");
2618         my $line = <$fd>;
2619         close $fd or return undef;
2620
2621         if (!defined $line) {
2622                 # there is no tree or hash given by $path at $base
2623                 return undef;
2624         }
2625
2626         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2627         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2628         if (defined $type && $type ne $2) {
2629                 # type doesn't match
2630                 return undef;
2631         }
2632         return $3;
2633 }
2634
2635 # get path of entry with given hash at given tree-ish (ref)
2636 # used to get 'from' filename for combined diff (merge commit) for renames
2637 sub git_get_path_by_hash {
2638         my $base = shift || return;
2639         my $hash = shift || return;
2640
2641         local $/ = "\0";
2642
2643         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2644                 or return undef;
2645         while (my $line = <$fd>) {
2646                 chomp $line;
2647
2648                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2649                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2650                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2651                         close $fd;
2652                         return $1;
2653                 }
2654         }
2655         close $fd;
2656         return undef;
2657 }
2658
2659 ## ......................................................................
2660 ## git utility functions, directly accessing git repository
2661
2662 # get the value of config variable either from file named as the variable
2663 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2664 # configuration variable in the repository config file.
2665 sub git_get_file_or_project_config {
2666         my ($path, $name) = @_;
2667
2668         $git_dir = "$projectroot/$path";
2669         open my $fd, '<', "$git_dir/$name"
2670                 or return git_get_project_config($name);
2671         my $conf = <$fd>;
2672         close $fd;
2673         if (defined $conf) {
2674                 chomp $conf;
2675         }
2676         return $conf;
2677 }
2678
2679 sub git_get_project_description {
2680         my $path = shift;
2681         return git_get_file_or_project_config($path, 'description');
2682 }
2683
2684 sub git_get_project_category {
2685         my $path = shift;
2686         return git_get_file_or_project_config($path, 'category');
2687 }
2688
2689
2690 # supported formats:
2691 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2692 #   - if its contents is a number, use it as tag weight,
2693 #   - otherwise add a tag with weight 1
2694 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2695 #   the same value multiple times increases tag weight
2696 # * `gitweb.ctag' multi-valued repo config variable
2697 sub git_get_project_ctags {
2698         my $project = shift;
2699         my $ctags = {};
2700
2701         $git_dir = "$projectroot/$project";
2702         if (opendir my $dh, "$git_dir/ctags") {
2703                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2704                 foreach my $tagfile (@files) {
2705                         open my $ct, '<', $tagfile
2706                                 or next;
2707                         my $val = <$ct>;
2708                         chomp $val if $val;
2709                         close $ct;
2710
2711                         (my $ctag = $tagfile) =~ s#.*/##;
2712                         if ($val =~ /^\d+$/) {
2713                                 $ctags->{$ctag} = $val;
2714                         } else {
2715                                 $ctags->{$ctag} = 1;
2716                         }
2717                 }
2718                 closedir $dh;
2719
2720         } elsif (open my $fh, '<', "$git_dir/ctags") {
2721                 while (my $line = <$fh>) {
2722                         chomp $line;
2723                         $ctags->{$line}++ if $line;
2724                 }
2725                 close $fh;
2726
2727         } else {
2728                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2729                 foreach my $tag (@$taglist) {
2730                         $ctags->{$tag}++;
2731                 }
2732         }
2733
2734         return $ctags;
2735 }
2736
2737 # return hash, where keys are content tags ('ctags'),
2738 # and values are sum of weights of given tag in every project
2739 sub git_gather_all_ctags {
2740         my $projects = shift;
2741         my $ctags = {};
2742
2743         foreach my $p (@$projects) {
2744                 foreach my $ct (keys %{$p->{'ctags'}}) {
2745                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2746                 }
2747         }
2748
2749         return $ctags;
2750 }
2751
2752 sub git_populate_project_tagcloud {
2753         my $ctags = shift;
2754
2755         # First, merge different-cased tags; tags vote on casing
2756         my %ctags_lc;
2757         foreach (keys %$ctags) {
2758                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2759                 if (not $ctags_lc{lc $_}->{topcount}
2760                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2761                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2762                         $ctags_lc{lc $_}->{topname} = $_;
2763                 }
2764         }
2765
2766         my $cloud;
2767         my $matched = $cgi->param('by_tag');
2768         if (eval { require HTML::TagCloud; 1; }) {
2769                 $cloud = HTML::TagCloud->new;
2770                 foreach my $ctag (sort keys %ctags_lc) {
2771                         # Pad the title with spaces so that the cloud looks
2772                         # less crammed.
2773                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2774                         $title =~ s/ /&nbsp;/g;
2775                         $title =~ s/^/&nbsp;/g;
2776                         $title =~ s/$/&nbsp;/g;
2777                         if (defined $matched && $matched eq $ctag) {
2778                                 $title = qq(<span class="match">$title</span>);
2779                         }
2780                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2781                                     $ctags_lc{$ctag}->{count});
2782                 }
2783         } else {
2784                 $cloud = {};
2785                 foreach my $ctag (keys %ctags_lc) {
2786                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2787                         if (defined $matched && $matched eq $ctag) {
2788                                 $title = qq(<span class="match">$title</span>);
2789                         }
2790                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2791                         $cloud->{$ctag}{ctag} =
2792                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2793                 }
2794         }
2795         return $cloud;
2796 }
2797
2798 sub git_show_project_tagcloud {
2799         my ($cloud, $count) = @_;
2800         if (ref $cloud eq 'HTML::TagCloud') {
2801                 return $cloud->html_and_css($count);
2802         } else {
2803                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2804                 return
2805                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2806                         join (', ', map {
2807                                 $cloud->{$_}->{'ctag'}
2808                         } splice(@tags, 0, $count)) .
2809                         '</div>';
2810         }
2811 }
2812
2813 sub git_get_project_url_list {
2814         my $path = shift;
2815
2816         $git_dir = "$projectroot/$path";
2817         open my $fd, '<', "$git_dir/cloneurl"
2818                 or return wantarray ?
2819                 @{ config_to_multi(git_get_project_config('url')) } :
2820                    config_to_multi(git_get_project_config('url'));
2821         my @git_project_url_list = map { chomp; $_ } <$fd>;
2822         close $fd;
2823
2824         return wantarray ? @git_project_url_list : \@git_project_url_list;
2825 }
2826
2827 sub git_get_projects_list {
2828         my $filter = shift || '';
2829         my @list;
2830
2831         $filter =~ s/\.git$//;
2832
2833         if (-d $projects_list) {
2834                 # search in directory
2835                 my $dir = $projects_list;
2836                 # remove the trailing "/"
2837                 $dir =~ s!/+$!!;
2838                 my $pfxlen = length("$projects_list");
2839                 my $pfxdepth = ($projects_list =~ tr!/!!);
2840                 # when filtering, search only given subdirectory
2841                 if ($filter) {
2842                         $dir .= "/$filter";
2843                         $dir =~ s!/+$!!;
2844                 }
2845
2846                 File::Find::find({
2847                         follow_fast => 1, # follow symbolic links
2848                         follow_skip => 2, # ignore duplicates
2849                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2850                         wanted => sub {
2851                                 # global variables
2852                                 our $project_maxdepth;
2853                                 our $projectroot;
2854                                 # skip project-list toplevel, if we get it.
2855                                 return if (m!^[/.]$!);
2856                                 # only directories can be git repositories
2857                                 return unless (-d $_);
2858                                 # don't traverse too deep (Find is super slow on os x)
2859                                 # $project_maxdepth excludes depth of $projectroot
2860                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2861                                         $File::Find::prune = 1;
2862                                         return;
2863                                 }
2864
2865                                 my $path = substr($File::Find::name, $pfxlen + 1);
2866                                 # we check related file in $projectroot
2867                                 if (check_export_ok("$projectroot/$path")) {
2868                                         push @list, { path => $path };
2869                                         $File::Find::prune = 1;
2870                                 }
2871                         },
2872                 }, "$dir");
2873
2874         } elsif (-f $projects_list) {
2875                 # read from file(url-encoded):
2876                 # 'git%2Fgit.git Linus+Torvalds'
2877                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2878                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2879                 open my $fd, '<', $projects_list or return;
2880         PROJECT:
2881                 while (my $line = <$fd>) {
2882                         chomp $line;
2883                         my ($path, $owner) = split ' ', $line;
2884                         $path = unescape($path);
2885                         $owner = unescape($owner);
2886                         if (!defined $path) {
2887                                 next;
2888                         }
2889                         # if $filter is rpovided, check if $path begins with $filter
2890                         if ($filter && $path !~ m!^\Q$filter\E/!) {
2891                                 next;
2892                         }
2893                         if (check_export_ok("$projectroot/$path")) {
2894                                 my $pr = {
2895                                         path => $path,
2896                                         owner => to_utf8($owner),
2897                                 };
2898                                 push @list, $pr;
2899                         }
2900                 }
2901                 close $fd;
2902         }
2903         return @list;
2904 }
2905
2906 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
2907 # as side effects it sets 'forks' field to list of forks for forked projects
2908 sub filter_forks_from_projects_list {
2909         my $projects = shift;
2910
2911         my %trie; # prefix tree of directories (path components)
2912         # generate trie out of those directories that might contain forks
2913         foreach my $pr (@$projects) {
2914                 my $path = $pr->{'path'};
2915                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
2916                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
2917                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
2918                 next unless (-d "$projectroot/$path"); # containing directory exists
2919                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
2920
2921                 # add to trie
2922                 my @dirs = split('/', $path);
2923                 # walk the trie, until either runs out of components or out of trie
2924                 my $ref = \%trie;
2925                 while (scalar @dirs &&
2926                        exists($ref->{$dirs[0]})) {
2927                         $ref = $ref->{shift @dirs};
2928                 }
2929                 # create rest of trie structure from rest of components
2930                 foreach my $dir (@dirs) {
2931                         $ref = $ref->{$dir} = {};
2932                 }
2933                 # create end marker, store $pr as a data
2934                 $ref->{''} = $pr if (!exists $ref->{''});
2935         }
2936
2937         # filter out forks, by finding shortest prefix match for paths
2938         my @filtered;
2939  PROJECT:
2940         foreach my $pr (@$projects) {
2941                 # trie lookup
2942                 my $ref = \%trie;
2943         DIR:
2944                 foreach my $dir (split('/', $pr->{'path'})) {
2945                         if (exists $ref->{''}) {
2946                                 # found [shortest] prefix, is a fork - skip it
2947                                 push @{$ref->{''}{'forks'}}, $pr;
2948                                 next PROJECT;
2949                         }
2950                         if (!exists $ref->{$dir}) {
2951                                 # not in trie, cannot have prefix, not a fork
2952                                 push @filtered, $pr;
2953                                 next PROJECT;
2954                         }
2955                         # If the dir is there, we just walk one step down the trie.
2956                         $ref = $ref->{$dir};
2957                 }
2958                 # we ran out of trie
2959                 # (shouldn't happen: it's either no match, or end marker)
2960                 push @filtered, $pr;
2961         }
2962
2963         return @filtered;
2964 }
2965
2966 # note: fill_project_list_info must be run first,
2967 # for 'descr_long' and 'ctags' to be filled
2968 sub search_projects_list {
2969         my ($projlist, %opts) = @_;
2970         my $tagfilter  = $opts{'tagfilter'};
2971         my $searchtext = $opts{'searchtext'};
2972
2973         return @$projlist
2974                 unless ($tagfilter || $searchtext);
2975
2976         my @projects;
2977  PROJECT:
2978         foreach my $pr (@$projlist) {
2979
2980                 if ($tagfilter) {
2981                         next unless ref($pr->{'ctags'}) eq 'HASH';
2982                         next unless
2983                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
2984                 }
2985
2986                 if ($searchtext) {
2987                         next unless
2988                                 $pr->{'path'} =~ /$searchtext/ ||
2989                                 $pr->{'descr_long'} =~ /$searchtext/;
2990                 }
2991
2992                 push @projects, $pr;
2993         }
2994
2995         return @projects;
2996 }
2997
2998 our $gitweb_project_owner = undef;
2999 sub git_get_project_list_from_file {
3000
3001         return if (defined $gitweb_project_owner);
3002
3003         $gitweb_project_owner = {};
3004         # read from file (url-encoded):
3005         # 'git%2Fgit.git Linus+Torvalds'
3006         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3007         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3008         if (-f $projects_list) {
3009                 open(my $fd, '<', $projects_list);
3010                 while (my $line = <$fd>) {
3011                         chomp $line;
3012                         my ($pr, $ow) = split ' ', $line;
3013                         $pr = unescape($pr);
3014                         $ow = unescape($ow);
3015                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3016                 }
3017                 close $fd;
3018         }
3019 }
3020
3021 sub git_get_project_owner {
3022         my $project = shift;
3023         my $owner;
3024
3025         return undef unless $project;
3026         $git_dir = "$projectroot/$project";
3027
3028         if (!defined $gitweb_project_owner) {
3029                 git_get_project_list_from_file();
3030         }
3031
3032         if (exists $gitweb_project_owner->{$project}) {
3033                 $owner = $gitweb_project_owner->{$project};
3034         }
3035         if (!defined $owner){
3036                 $owner = git_get_project_config('owner');
3037         }
3038         if (!defined $owner) {
3039                 $owner = get_file_owner("$git_dir");
3040         }
3041
3042         return $owner;
3043 }
3044
3045 sub git_get_last_activity {
3046         my ($path) = @_;
3047         my $fd;
3048
3049         $git_dir = "$projectroot/$path";
3050         open($fd, "-|", git_cmd(), 'for-each-ref',
3051              '--format=%(committer)',
3052              '--sort=-committerdate',
3053              '--count=1',
3054              'refs/heads') or return;
3055         my $most_recent = <$fd>;
3056         close $fd or return;
3057         if (defined $most_recent &&
3058             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3059                 my $timestamp = $1;
3060                 my $age = time - $timestamp;
3061                 return ($age, age_string($age));
3062         }
3063         return (undef, undef);
3064 }
3065
3066 # Implementation note: when a single remote is wanted, we cannot use 'git
3067 # remote show -n' because that command always work (assuming it's a remote URL
3068 # if it's not defined), and we cannot use 'git remote show' because that would
3069 # try to make a network roundtrip. So the only way to find if that particular
3070 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3071 # and when we find what we want.
3072 sub git_get_remotes_list {
3073         my $wanted = shift;
3074         my %remotes = ();
3075
3076         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3077         return unless $fd;
3078         while (my $remote = <$fd>) {
3079                 chomp $remote;
3080                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3081                 next if $wanted and not $remote eq $wanted;
3082                 my ($url, $key) = ($1, $2);
3083
3084                 $remotes{$remote} ||= { 'heads' => () };
3085                 $remotes{$remote}{$key} = $url;
3086         }
3087         close $fd or return;
3088         return wantarray ? %remotes : \%remotes;
3089 }
3090
3091 # Takes a hash of remotes as first parameter and fills it by adding the
3092 # available remote heads for each of the indicated remotes.
3093 sub fill_remote_heads {
3094         my $remotes = shift;
3095         my @heads = map { "remotes/$_" } keys %$remotes;
3096         my @remoteheads = git_get_heads_list(undef, @heads);
3097         foreach my $remote (keys %$remotes) {
3098                 $remotes->{$remote}{'heads'} = [ grep {
3099                         $_->{'name'} =~ s!^$remote/!!
3100                         } @remoteheads ];
3101         }
3102 }
3103
3104 sub git_get_references {
3105         my $type = shift || "";
3106         my %refs;
3107         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3108         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3109         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3110                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3111                 or return;
3112
3113         while (my $line = <$fd>) {
3114                 chomp $line;
3115                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3116                         if (defined $refs{$1}) {
3117                                 push @{$refs{$1}}, $2;
3118                         } else {
3119                                 $refs{$1} = [ $2 ];
3120                         }
3121                 }
3122         }
3123         close $fd or return;
3124         return \%refs;
3125 }
3126
3127 sub git_get_rev_name_tags {
3128         my $hash = shift || return undef;
3129
3130         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3131                 or return;
3132         my $name_rev = <$fd>;
3133         close $fd;
3134
3135         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3136                 return $1;
3137         } else {
3138                 # catches also '$hash undefined' output
3139                 return undef;
3140         }
3141 }
3142
3143 ## ----------------------------------------------------------------------
3144 ## parse to hash functions
3145
3146 sub parse_date {
3147         my $epoch = shift;
3148         my $tz = shift || "-0000";
3149
3150         my %date;
3151         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3152         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3153         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3154         $date{'hour'} = $hour;
3155         $date{'minute'} = $min;
3156         $date{'mday'} = $mday;
3157         $date{'day'} = $days[$wday];
3158         $date{'month'} = $months[$mon];
3159         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3160                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3161         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3162                              $mday, $months[$mon], $hour ,$min;
3163         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3164                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3165
3166         my ($tz_sign, $tz_hour, $tz_min) =
3167                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3168         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3169         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3170         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3171         $date{'hour_local'} = $hour;
3172         $date{'minute_local'} = $min;
3173         $date{'tz_local'} = $tz;
3174         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3175                                   1900+$year, $mon+1, $mday,
3176                                   $hour, $min, $sec, $tz);
3177         return %date;
3178 }
3179
3180 sub parse_tag {
3181         my $tag_id = shift;
3182         my %tag;
3183         my @comment;
3184
3185         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3186         $tag{'id'} = $tag_id;
3187         while (my $line = <$fd>) {
3188                 chomp $line;
3189                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3190                         $tag{'object'} = $1;
3191                 } elsif ($line =~ m/^type (.+)$/) {
3192                         $tag{'type'} = $1;
3193                 } elsif ($line =~ m/^tag (.+)$/) {
3194                         $tag{'name'} = $1;
3195                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3196                         $tag{'author'} = $1;
3197                         $tag{'author_epoch'} = $2;
3198                         $tag{'author_tz'} = $3;
3199                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3200                                 $tag{'author_name'}  = $1;
3201                                 $tag{'author_email'} = $2;
3202                         } else {
3203                                 $tag{'author_name'} = $tag{'author'};
3204                         }
3205                 } elsif ($line =~ m/--BEGIN/) {
3206                         push @comment, $line;
3207                         last;
3208                 } elsif ($line eq "") {
3209                         last;
3210                 }
3211         }
3212         push @comment, <$fd>;
3213         $tag{'comment'} = \@comment;
3214         close $fd or return;
3215         if (!defined $tag{'name'}) {
3216                 return
3217         };
3218         return %tag
3219 }
3220
3221 sub parse_commit_text {
3222         my ($commit_text, $withparents) = @_;
3223         my @commit_lines = split '\n', $commit_text;
3224         my %co;
3225
3226         pop @commit_lines; # Remove '\0'
3227
3228         if (! @commit_lines) {
3229                 return;
3230         }
3231
3232         my $header = shift @commit_lines;
3233         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3234                 return;
3235         }
3236         ($co{'id'}, my @parents) = split ' ', $header;
3237         while (my $line = shift @commit_lines) {
3238                 last if $line eq "\n";
3239                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3240                         $co{'tree'} = $1;
3241                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3242                         push @parents, $1;
3243                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3244                         $co{'author'} = to_utf8($1);
3245                         $co{'author_epoch'} = $2;
3246                         $co{'author_tz'} = $3;
3247                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3248                                 $co{'author_name'}  = $1;
3249                                 $co{'author_email'} = $2;
3250                         } else {
3251                                 $co{'author_name'} = $co{'author'};
3252                         }
3253                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3254                         $co{'committer'} = to_utf8($1);
3255                         $co{'committer_epoch'} = $2;
3256                         $co{'committer_tz'} = $3;
3257                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3258                                 $co{'committer_name'}  = $1;
3259                                 $co{'committer_email'} = $2;
3260                         } else {
3261                                 $co{'committer_name'} = $co{'committer'};
3262                         }
3263                 }
3264         }
3265         if (!defined $co{'tree'}) {
3266                 return;
3267         };
3268         $co{'parents'} = \@parents;
3269         $co{'parent'} = $parents[0];
3270
3271         foreach my $title (@commit_lines) {
3272                 $title =~ s/^    //;
3273                 if ($title ne "") {
3274                         $co{'title'} = chop_str($title, 80, 5);
3275                         # remove leading stuff of merges to make the interesting part visible
3276                         if (length($title) > 50) {
3277                                 $title =~ s/^Automatic //;
3278                                 $title =~ s/^merge (of|with) /Merge ... /i;
3279                                 if (length($title) > 50) {
3280                                         $title =~ s/(http|rsync):\/\///;
3281                                 }
3282                                 if (length($title) > 50) {
3283                                         $title =~ s/(master|www|rsync)\.//;
3284                                 }
3285                                 if (length($title) > 50) {
3286                                         $title =~ s/kernel.org:?//;
3287                                 }
3288                                 if (length($title) > 50) {
3289                                         $title =~ s/\/pub\/scm//;
3290                                 }
3291                         }
3292                         $co{'title_short'} = chop_str($title, 50, 5);
3293                         last;
3294                 }
3295         }
3296         if (! defined $co{'title'} || $co{'title'} eq "") {
3297                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3298         }
3299         # remove added spaces
3300         foreach my $line (@commit_lines) {
3301                 $line =~ s/^    //;
3302         }
3303         $co{'comment'} = \@commit_lines;
3304
3305         my $age = time - $co{'committer_epoch'};
3306         $co{'age'} = $age;
3307         $co{'age_string'} = age_string($age);
3308         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3309         if ($age > 60*60*24*7*2) {
3310                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3311                 $co{'age_string_age'} = $co{'age_string'};
3312         } else {
3313                 $co{'age_string_date'} = $co{'age_string'};
3314                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3315         }
3316         return %co;
3317 }
3318
3319 sub parse_commit {
3320         my ($commit_id) = @_;
3321         my %co;
3322
3323         local $/ = "\0";
3324
3325         open my $fd, "-|", git_cmd(), "rev-list",
3326                 "--parents",
3327                 "--header",
3328                 "--max-count=1",
3329                 $commit_id,
3330                 "--",
3331                 or die_error(500, "Open git-rev-list failed");
3332         %co = parse_commit_text(<$fd>, 1);
3333         close $fd;
3334
3335         return %co;
3336 }
3337
3338 sub parse_commits {
3339         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3340         my @cos;
3341
3342         $maxcount ||= 1;
3343         $skip ||= 0;
3344
3345         local $/ = "\0";
3346
3347         open my $fd, "-|", git_cmd(), "rev-list",
3348                 "--header",
3349                 @args,
3350                 ("--max-count=" . $maxcount),
3351                 ("--skip=" . $skip),
3352                 @extra_options,
3353                 $commit_id,
3354                 "--",
3355                 ($filename ? ($filename) : ())
3356                 or die_error(500, "Open git-rev-list failed");
3357         while (my $line = <$fd>) {
3358                 my %co = parse_commit_text($line);
3359                 push @cos, \%co;
3360         }
3361         close $fd;
3362
3363         return wantarray ? @cos : \@cos;
3364 }
3365
3366 # parse line of git-diff-tree "raw" output
3367 sub parse_difftree_raw_line {
3368         my $line = shift;
3369         my %res;
3370
3371         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3372         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3373         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3374                 $res{'from_mode'} = $1;
3375                 $res{'to_mode'} = $2;
3376                 $res{'from_id'} = $3;
3377                 $res{'to_id'} = $4;
3378                 $res{'status'} = $5;
3379                 $res{'similarity'} = $6;
3380                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3381                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3382                 } else {
3383                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3384                 }
3385         }
3386         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3387         # combined diff (for merge commit)
3388         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3389                 $res{'nparents'}  = length($1);
3390                 $res{'from_mode'} = [ split(' ', $2) ];
3391                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3392                 $res{'from_id'} = [ split(' ', $3) ];
3393                 $res{'to_id'} = pop @{$res{'from_id'}};
3394                 $res{'status'} = [ split('', $4) ];
3395                 $res{'to_file'} = unquote($5);
3396         }
3397         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3398         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3399                 $res{'commit'} = $1;
3400         }
3401
3402         return wantarray ? %res : \%res;
3403 }
3404
3405 # wrapper: return parsed line of git-diff-tree "raw" output
3406 # (the argument might be raw line, or parsed info)
3407 sub parsed_difftree_line {
3408         my $line_or_ref = shift;
3409
3410         if (ref($line_or_ref) eq "HASH") {
3411                 # pre-parsed (or generated by hand)
3412                 return $line_or_ref;
3413         } else {
3414                 return parse_difftree_raw_line($line_or_ref);
3415         }
3416 }
3417
3418 # parse line of git-ls-tree output
3419 sub parse_ls_tree_line {
3420         my $line = shift;
3421         my %opts = @_;
3422         my %res;
3423
3424         if ($opts{'-l'}) {
3425                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3426                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3427
3428                 $res{'mode'} = $1;
3429                 $res{'type'} = $2;
3430                 $res{'hash'} = $3;
3431                 $res{'size'} = $4;
3432                 if ($opts{'-z'}) {
3433                         $res{'name'} = $5;
3434                 } else {
3435                         $res{'name'} = unquote($5);
3436                 }
3437         } else {
3438                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3439                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3440
3441                 $res{'mode'} = $1;
3442                 $res{'type'} = $2;
3443                 $res{'hash'} = $3;
3444                 if ($opts{'-z'}) {
3445                         $res{'name'} = $4;
3446                 } else {
3447                         $res{'name'} = unquote($4);
3448                 }
3449         }
3450
3451         return wantarray ? %res : \%res;
3452 }
3453
3454 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3455 sub parse_from_to_diffinfo {
3456         my ($diffinfo, $from, $to, @parents) = @_;
3457
3458         if ($diffinfo->{'nparents'}) {
3459                 # combined diff
3460                 $from->{'file'} = [];
3461                 $from->{'href'} = [];
3462                 fill_from_file_info($diffinfo, @parents)
3463                         unless exists $diffinfo->{'from_file'};
3464                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3465                         $from->{'file'}[$i] =
3466                                 defined $diffinfo->{'from_file'}[$i] ?
3467                                         $diffinfo->{'from_file'}[$i] :
3468                                         $diffinfo->{'to_file'};
3469                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3470                                 $from->{'href'}[$i] = href(action=>"blob",
3471                                                            hash_base=>$parents[$i],
3472                                                            hash=>$diffinfo->{'from_id'}[$i],
3473                                                            file_name=>$from->{'file'}[$i]);
3474                         } else {
3475                                 $from->{'href'}[$i] = undef;
3476                         }
3477                 }
3478         } else {
3479                 # ordinary (not combined) diff
3480                 $from->{'file'} = $diffinfo->{'from_file'};
3481                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3482                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3483                                                hash=>$diffinfo->{'from_id'},
3484                                                file_name=>$from->{'file'});
3485                 } else {
3486                         delete $from->{'href'};
3487                 }
3488         }
3489
3490         $to->{'file'} = $diffinfo->{'to_file'};
3491         if (!is_deleted($diffinfo)) { # file exists in result
3492                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3493                                      hash=>$diffinfo->{'to_id'},
3494                                      file_name=>$to->{'file'});
3495         } else {
3496                 delete $to->{'href'};
3497         }
3498 }
3499
3500 ## ......................................................................
3501 ## parse to array of hashes functions
3502
3503 sub git_get_heads_list {
3504         my ($limit, @classes) = @_;
3505         @classes = ('heads') unless @classes;
3506         my @patterns = map { "refs/$_" } @classes;
3507         my @headslist;
3508
3509         open my $fd, '-|', git_cmd(), 'for-each-ref',
3510                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3511                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3512                 @patterns
3513                 or return;
3514         while (my $line = <$fd>) {
3515                 my %ref_item;
3516
3517                 chomp $line;
3518                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3519                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3520                 my ($committer, $epoch, $tz) =
3521                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3522                 $ref_item{'fullname'}  = $name;
3523                 $name =~ s!^refs/(?:head|remote)s/!!;
3524
3525                 $ref_item{'name'}  = $name;
3526                 $ref_item{'id'}    = $hash;
3527                 $ref_item{'title'} = $title || '(no commit message)';
3528                 $ref_item{'epoch'} = $epoch;
3529                 if ($epoch) {
3530                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3531                 } else {
3532                         $ref_item{'age'} = "unknown";
3533                 }
3534
3535                 push @headslist, \%ref_item;
3536         }
3537         close $fd;
3538
3539         return wantarray ? @headslist : \@headslist;
3540 }
3541
3542 sub git_get_tags_list {
3543         my $limit = shift;
3544         my @tagslist;
3545
3546         open my $fd, '-|', git_cmd(), 'for-each-ref',
3547                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3548                 '--format=%(objectname) %(objecttype) %(refname) '.
3549                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3550                 'refs/tags'
3551                 or return;
3552         while (my $line = <$fd>) {
3553                 my %ref_item;
3554
3555                 chomp $line;
3556                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3557                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3558                 my ($creator, $epoch, $tz) =
3559                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3560                 $ref_item{'fullname'} = $name;
3561                 $name =~ s!^refs/tags/!!;
3562
3563                 $ref_item{'type'} = $type;
3564                 $ref_item{'id'} = $id;
3565                 $ref_item{'name'} = $name;
3566                 if ($type eq "tag") {
3567                         $ref_item{'subject'} = $title;
3568                         $ref_item{'reftype'} = $reftype;
3569                         $ref_item{'refid'}   = $refid;
3570                 } else {
3571                         $ref_item{'reftype'} = $type;
3572                         $ref_item{'refid'}   = $id;
3573                 }
3574
3575                 if ($type eq "tag" || $type eq "commit") {
3576                         $ref_item{'epoch'} = $epoch;
3577                         if ($epoch) {
3578                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3579                         } else {
3580                                 $ref_item{'age'} = "unknown";
3581                         }
3582                 }
3583
3584                 push @tagslist, \%ref_item;
3585         }
3586         close $fd;
3587
3588         return wantarray ? @tagslist : \@tagslist;
3589 }
3590
3591 ## ----------------------------------------------------------------------
3592 ## filesystem-related functions
3593
3594 sub get_file_owner {
3595         my $path = shift;
3596
3597         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3598         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3599         if (!defined $gcos) {
3600                 return undef;
3601         }
3602         my $owner = $gcos;
3603         $owner =~ s/[,;].*$//;
3604         return to_utf8($owner);
3605 }
3606
3607 # assume that file exists
3608 sub insert_file {
3609         my $filename = shift;
3610
3611         open my $fd, '<', $filename;
3612         print map { to_utf8($_) } <$fd>;
3613         close $fd;
3614 }
3615
3616 ## ......................................................................
3617 ## mimetype related functions
3618
3619 sub mimetype_guess_file {
3620         my $filename = shift;
3621         my $mimemap = shift;
3622         -r $mimemap or return undef;
3623
3624         my %mimemap;
3625         open(my $mh, '<', $mimemap) or return undef;
3626         while (<$mh>) {
3627                 next if m/^#/; # skip comments
3628                 my ($mimetype, @exts) = split(/\s+/);
3629                 foreach my $ext (@exts) {
3630                         $mimemap{$ext} = $mimetype;
3631                 }
3632         }
3633         close($mh);
3634
3635         $filename =~ /\.([^.]*)$/;
3636         return $mimemap{$1};
3637 }
3638
3639 sub mimetype_guess {
3640         my $filename = shift;
3641         my $mime;
3642         $filename =~ /\./ or return undef;
3643
3644         if ($mimetypes_file) {
3645                 my $file = $mimetypes_file;
3646                 if ($file !~ m!^/!) { # if it is relative path
3647                         # it is relative to project
3648                         $file = "$projectroot/$project/$file";
3649                 }
3650                 $mime = mimetype_guess_file($filename, $file);
3651         }
3652         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3653         return $mime;
3654 }
3655
3656 sub blob_mimetype {
3657         my $fd = shift;
3658         my $filename = shift;
3659
3660         if ($filename) {
3661                 my $mime = mimetype_guess($filename);
3662                 $mime and return $mime;
3663         }
3664
3665         # just in case
3666         return $default_blob_plain_mimetype unless $fd;
3667
3668         if (-T $fd) {
3669                 return 'text/plain';
3670         } elsif (! $filename) {
3671                 return 'application/octet-stream';
3672         } elsif ($filename =~ m/\.png$/i) {
3673                 return 'image/png';
3674         } elsif ($filename =~ m/\.gif$/i) {
3675                 return 'image/gif';
3676         } elsif ($filename =~ m/\.jpe?g$/i) {
3677                 return 'image/jpeg';
3678         } else {
3679                 return 'application/octet-stream';
3680         }
3681 }
3682
3683 sub blob_contenttype {
3684         my ($fd, $file_name, $type) = @_;
3685
3686         $type ||= blob_mimetype($fd, $file_name);
3687         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3688                 $type .= "; charset=$default_text_plain_charset";
3689         }
3690
3691         return $type;
3692 }
3693
3694 # guess file syntax for syntax highlighting; return undef if no highlighting
3695 # the name of syntax can (in the future) depend on syntax highlighter used
3696 sub guess_file_syntax {
3697         my ($highlight, $mimetype, $file_name) = @_;
3698         return undef unless ($highlight && defined $file_name);
3699         my $basename = basename($file_name, '.in');
3700         return $highlight_basename{$basename}
3701                 if exists $highlight_basename{$basename};
3702
3703         $basename =~ /\.([^.]*)$/;
3704         my $ext = $1 or return undef;
3705         return $highlight_ext{$ext}
3706                 if exists $highlight_ext{$ext};
3707
3708         return undef;
3709 }
3710
3711 # run highlighter and return FD of its output,
3712 # or return original FD if no highlighting
3713 sub run_highlighter {
3714         my ($fd, $highlight, $syntax) = @_;
3715         return $fd unless ($highlight && defined $syntax);
3716
3717         close $fd;
3718         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3719                   quote_command($highlight_bin).
3720                   " --replace-tabs=8 --fragment --syntax $syntax |"
3721                 or die_error(500, "Couldn't open file or run syntax highlighter");
3722         return $fd;
3723 }
3724
3725 ## ======================================================================
3726 ## functions printing HTML: header, footer, error page
3727
3728 sub get_page_title {
3729         my $title = to_utf8($site_name);
3730
3731         return $title unless (defined $project);
3732         $title .= " - " . to_utf8($project);
3733
3734         return $title unless (defined $action);
3735         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3736
3737         return $title unless (defined $file_name);
3738         $title .= " - " . esc_path($file_name);
3739         if ($action eq "tree" && $file_name !~ m|/$|) {
3740                 $title .= "/";
3741         }
3742
3743         return $title;
3744 }
3745
3746 sub get_content_type_html {
3747         # require explicit support from the UA if we are to send the page as
3748         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3749         # we have to do this because MSIE sometimes globs '*/*', pretending to
3750         # support xhtml+xml but choking when it gets what it asked for.
3751         if (defined $cgi->http('HTTP_ACCEPT') &&
3752             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3753             $cgi->Accept('application/xhtml+xml') != 0) {
3754                 return 'application/xhtml+xml';
3755         } else {
3756                 return 'text/html';
3757         }
3758 }
3759
3760 sub print_feed_meta {
3761         if (defined $project) {
3762                 my %href_params = get_feed_info();
3763                 if (!exists $href_params{'-title'}) {
3764                         $href_params{'-title'} = 'log';
3765                 }
3766
3767                 foreach my $format (qw(RSS Atom)) {
3768                         my $type = lc($format);
3769                         my %link_attr = (
3770                                 '-rel' => 'alternate',
3771                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3772                                 '-type' => "application/$type+xml"
3773                         );
3774
3775                         $href_params{'action'} = $type;
3776                         $link_attr{'-href'} = href(%href_params);
3777                         print "<link ".
3778                               "rel=\"$link_attr{'-rel'}\" ".
3779                               "title=\"$link_attr{'-title'}\" ".
3780                               "href=\"$link_attr{'-href'}\" ".
3781                               "type=\"$link_attr{'-type'}\" ".
3782                               "/>\n";
3783
3784                         $href_params{'extra_options'} = '--no-merges';
3785                         $link_attr{'-href'} = href(%href_params);
3786                         $link_attr{'-title'} .= ' (no merges)';
3787                         print "<link ".
3788                               "rel=\"$link_attr{'-rel'}\" ".
3789                               "title=\"$link_attr{'-title'}\" ".
3790                               "href=\"$link_attr{'-href'}\" ".
3791                               "type=\"$link_attr{'-type'}\" ".
3792                               "/>\n";
3793                 }
3794
3795         } else {
3796                 printf('<link rel="alternate" title="%s projects list" '.
3797                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3798                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3799                 printf('<link rel="alternate" title="%s projects feeds" '.
3800                        'href="%s" type="text/x-opml" />'."\n",
3801                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3802         }
3803 }
3804
3805 sub print_header_links {
3806         my $status = shift;
3807
3808         # print out each stylesheet that exist, providing backwards capability
3809         # for those people who defined $stylesheet in a config file
3810         if (defined $stylesheet) {
3811                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3812         } else {
3813                 foreach my $stylesheet (@stylesheets) {
3814                         next unless $stylesheet;
3815                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3816                 }
3817         }
3818         print_feed_meta()
3819                 if ($status eq '200 OK');
3820         if (defined $favicon) {
3821                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3822         }
3823 }
3824
3825 sub print_nav_breadcrumbs {
3826         my %opts = @_;
3827
3828         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3829         if (defined $project) {
3830                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3831                 if (defined $action) {
3832                         my $action_print = $action ;
3833                         if (defined $opts{-action_extra}) {
3834                                 $action_print = $cgi->a({-href => href(action=>$action)},
3835                                         $action);
3836                         }
3837                         print " / $action_print";
3838                 }
3839                 if (defined $opts{-action_extra}) {
3840                         print " / $opts{-action_extra}";
3841                 }
3842                 print "\n";
3843         }
3844 }
3845
3846 sub print_search_form {
3847         if (!defined $searchtext) {
3848                 $searchtext = "";
3849         }
3850         my $search_hash;
3851         if (defined $hash_base) {
3852                 $search_hash = $hash_base;
3853         } elsif (defined $hash) {
3854                 $search_hash = $hash;
3855         } else {
3856                 $search_hash = "HEAD";
3857         }
3858         my $action = $my_uri;
3859         my $use_pathinfo = gitweb_check_feature('pathinfo');
3860         if ($use_pathinfo) {
3861                 $action .= "/".esc_url($project);
3862         }
3863         print $cgi->startform(-method => "get", -action => $action) .
3864               "<div class=\"search\">\n" .
3865               (!$use_pathinfo &&
3866               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3867               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3868               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3869               $cgi->popup_menu(-name => 'st', -default => 'commit',
3870                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3871               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3872               " search:\n",
3873               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3874               "<span title=\"Extended regular expression\">" .
3875               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3876                              -checked => $search_use_regexp) .
3877               "</span>" .
3878               "</div>" .
3879               $cgi->end_form() . "\n";
3880 }
3881
3882 sub git_header_html {
3883         my $status = shift || "200 OK";
3884         my $expires = shift;
3885         my %opts = @_;
3886
3887         my $title = get_page_title();
3888         my $content_type = get_content_type_html();
3889         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3890                            -status=> $status, -expires => $expires)
3891                 unless ($opts{'-no_http_header'});
3892         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3893         print <<EOF;
3894 <?xml version="1.0" encoding="utf-8"?>
3895 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3896 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3897 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3898 <!-- git core binaries version $git_version -->
3899 <head>
3900 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3901 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3902 <meta name="robots" content="index, nofollow"/>
3903 <title>$title</title>
3904 EOF
3905         # the stylesheet, favicon etc urls won't work correctly with path_info
3906         # unless we set the appropriate base URL
3907         if ($ENV{'PATH_INFO'}) {
3908                 print "<base href=\"".esc_url($base_url)."\" />\n";
3909         }
3910         print_header_links($status);
3911
3912         if (defined $site_html_head_string) {
3913                 print to_utf8($site_html_head_string);
3914         }
3915
3916         print "</head>\n" .
3917               "<body>\n";
3918
3919         if (defined $site_header && -f $site_header) {
3920                 insert_file($site_header);
3921         }
3922
3923         print "<div class=\"page_header\">\n";
3924         if (defined $logo) {
3925                 print $cgi->a({-href => esc_url($logo_url),
3926                                -title => $logo_label},
3927                               $cgi->img({-src => esc_url($logo),
3928                                          -width => 72, -height => 27,
3929                                          -alt => "git",
3930                                          -class => "logo"}));
3931         }
3932         print_nav_breadcrumbs(%opts);
3933         print "</div>\n";
3934
3935         my $have_search = gitweb_check_feature('search');
3936         if (defined $project && $have_search) {
3937                 print_search_form();
3938         }
3939 }
3940
3941 sub git_footer_html {
3942         my $feed_class = 'rss_logo';
3943
3944         print "<div class=\"page_footer\">\n";
3945         if (defined $project) {
3946                 my $descr = git_get_project_description($project);
3947                 if (defined $descr) {
3948                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3949                 }
3950
3951                 my %href_params = get_feed_info();
3952                 if (!%href_params) {
3953                         $feed_class .= ' generic';
3954                 }
3955                 $href_params{'-title'} ||= 'log';
3956
3957                 foreach my $format (qw(RSS Atom)) {
3958                         $href_params{'action'} = lc($format);
3959                         print $cgi->a({-href => href(%href_params),
3960                                       -title => "$href_params{'-title'} $format feed",
3961                                       -class => $feed_class}, $format)."\n";
3962                 }
3963
3964         } else {
3965                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3966                               -class => $feed_class}, "OPML") . " ";
3967                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3968                               -class => $feed_class}, "TXT") . "\n";
3969         }
3970         print "</div>\n"; # class="page_footer"
3971
3972         if (defined $t0 && gitweb_check_feature('timed')) {
3973                 print "<div id=\"generating_info\">\n";
3974                 print 'This page took '.
3975                       '<span id="generating_time" class="time_span">'.
3976                       tv_interval($t0, [ gettimeofday() ]).
3977                       ' seconds </span>'.
3978                       ' and '.
3979                       '<span id="generating_cmd">'.
3980                       $number_of_git_cmds.
3981                       '</span> git commands '.
3982                       " to generate.\n";
3983                 print "</div>\n"; # class="page_footer"
3984         }
3985
3986         if (defined $site_footer && -f $site_footer) {
3987                 insert_file($site_footer);
3988         }
3989
3990         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
3991         if (defined $action &&
3992             $action eq 'blame_incremental') {
3993                 print qq!<script type="text/javascript">\n!.
3994                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3995                       qq!           "!. href() .qq!");\n!.
3996                       qq!</script>\n!;
3997         } else {
3998                 my ($jstimezone, $tz_cookie, $datetime_class) =
3999                         gitweb_get_feature('javascript-timezone');
4000
4001                 print qq!<script type="text/javascript">\n!.
4002                       qq!window.onload = function () {\n!;
4003                 if (gitweb_check_feature('javascript-actions')) {
4004                         print qq!       fixLinks();\n!;
4005                 }
4006                 if ($jstimezone && $tz_cookie && $datetime_class) {
4007                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4008                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4009                 }
4010                 print qq!};\n!.
4011                       qq!</script>\n!;
4012         }
4013
4014         print "</body>\n" .
4015               "</html>";
4016 }
4017
4018 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4019 # Example: die_error(404, 'Hash not found')
4020 # By convention, use the following status codes (as defined in RFC 2616):
4021 # 400: Invalid or missing CGI parameters, or
4022 #      requested object exists but has wrong type.
4023 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4024 #      this server or project.
4025 # 404: Requested object/revision/project doesn't exist.
4026 # 500: The server isn't configured properly, or
4027 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4028 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4029 # 503: The server is currently unavailable (because it is overloaded,
4030 #      or down for maintenance).  Generally, this is a temporary state.
4031 sub die_error {
4032         my $status = shift || 500;
4033         my $error = esc_html(shift) || "Internal Server Error";
4034         my $extra = shift;
4035         my %opts = @_;
4036
4037         my %http_responses = (
4038                 400 => '400 Bad Request',
4039                 403 => '403 Forbidden',
4040                 404 => '404 Not Found',
4041                 500 => '500 Internal Server Error',
4042                 503 => '503 Service Unavailable',
4043         );
4044         git_header_html($http_responses{$status}, undef, %opts);
4045         print <<EOF;
4046 <div class="page_body">
4047 <br /><br />
4048 $status - $error
4049 <br />
4050 EOF
4051         if (defined $extra) {
4052                 print "<hr />\n" .
4053                       "$extra\n";
4054         }
4055         print "</div>\n";
4056
4057         git_footer_html();
4058         goto DONE_GITWEB
4059                 unless ($opts{'-error_handler'});
4060 }
4061
4062 ## ----------------------------------------------------------------------
4063 ## functions printing or outputting HTML: navigation
4064
4065 sub git_print_page_nav {
4066         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4067         $extra = '' if !defined $extra; # pager or formats
4068
4069         my @navs = qw(summary shortlog log commit commitdiff tree);
4070         if ($suppress) {
4071                 @navs = grep { $_ ne $suppress } @navs;
4072         }
4073
4074         my %arg = map { $_ => {action=>$_} } @navs;
4075         if (defined $head) {
4076                 for (qw(commit commitdiff)) {
4077                         $arg{$_}{'hash'} = $head;
4078                 }
4079                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4080                         for (qw(shortlog log)) {
4081                                 $arg{$_}{'hash'} = $head;
4082                         }
4083                 }
4084         }
4085
4086         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4087         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4088
4089         my @actions = gitweb_get_feature('actions');
4090         my %repl = (
4091                 '%' => '%',
4092                 'n' => $project,         # project name
4093                 'f' => $git_dir,         # project path within filesystem
4094                 'h' => $treehead || '',  # current hash ('h' parameter)
4095                 'b' => $treebase || '',  # hash base ('hb' parameter)
4096         );
4097         while (@actions) {
4098                 my ($label, $link, $pos) = splice(@actions,0,3);
4099                 # insert
4100                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4101                 # munch munch
4102                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4103                 $arg{$label}{'_href'} = $link;
4104         }
4105
4106         print "<div class=\"page_nav\">\n" .
4107                 (join " | ",
4108                  map { $_ eq $current ?
4109                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4110                  } @navs);
4111         print "<br/>\n$extra<br/>\n" .
4112               "</div>\n";
4113 }
4114
4115 # returns a submenu for the nagivation of the refs views (tags, heads,
4116 # remotes) with the current view disabled and the remotes view only
4117 # available if the feature is enabled
4118 sub format_ref_views {
4119         my ($current) = @_;
4120         my @ref_views = qw{tags heads};
4121         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4122         return join " | ", map {
4123                 $_ eq $current ? $_ :
4124                 $cgi->a({-href => href(action=>$_)}, $_)
4125         } @ref_views
4126 }
4127
4128 sub format_paging_nav {
4129         my ($action, $page, $has_next_link) = @_;
4130         my $paging_nav;
4131
4132
4133         if ($page > 0) {
4134                 $paging_nav .=
4135                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4136                         " &sdot; " .
4137                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4138                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4139         } else {
4140                 $paging_nav .= "first &sdot; prev";
4141         }
4142
4143         if ($has_next_link) {
4144                 $paging_nav .= " &sdot; " .
4145                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4146                                  -accesskey => "n", -title => "Alt-n"}, "next");
4147         } else {
4148                 $paging_nav .= " &sdot; next";
4149         }
4150
4151         return $paging_nav;
4152 }
4153
4154 ## ......................................................................
4155 ## functions printing or outputting HTML: div
4156
4157 sub git_print_header_div {
4158         my ($action, $title, $hash, $hash_base) = @_;
4159         my %args = ();
4160
4161         $args{'action'} = $action;
4162         $args{'hash'} = $hash if $hash;
4163         $args{'hash_base'} = $hash_base if $hash_base;
4164
4165         print "<div class=\"header\">\n" .
4166               $cgi->a({-href => href(%args), -class => "title"},
4167               $title ? $title : $action) .
4168               "\n</div>\n";
4169 }
4170
4171 sub format_repo_url {
4172         my ($name, $url) = @_;
4173         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4174 }
4175
4176 # Group output by placing it in a DIV element and adding a header.
4177 # Options for start_div() can be provided by passing a hash reference as the
4178 # first parameter to the function.
4179 # Options to git_print_header_div() can be provided by passing an array
4180 # reference. This must follow the options to start_div if they are present.
4181 # The content can be a scalar, which is output as-is, a scalar reference, which
4182 # is output after html escaping, an IO handle passed either as *handle or
4183 # *handle{IO}, or a function reference. In the latter case all following
4184 # parameters will be taken as argument to the content function call.
4185 sub git_print_section {
4186         my ($div_args, $header_args, $content);
4187         my $arg = shift;
4188         if (ref($arg) eq 'HASH') {
4189                 $div_args = $arg;
4190                 $arg = shift;
4191         }
4192         if (ref($arg) eq 'ARRAY') {
4193                 $header_args = $arg;
4194                 $arg = shift;
4195         }
4196         $content = $arg;
4197
4198         print $cgi->start_div($div_args);
4199         git_print_header_div(@$header_args);
4200
4201         if (ref($content) eq 'CODE') {
4202                 $content->(@_);
4203         } elsif (ref($content) eq 'SCALAR') {
4204                 print esc_html($$content);
4205         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4206                 print <$content>;
4207         } elsif (!ref($content) && defined($content)) {
4208                 print $content;
4209         }
4210
4211         print $cgi->end_div;
4212 }
4213
4214 sub format_timestamp_html {
4215         my $date = shift;
4216         my $strtime = $date->{'rfc2822'};
4217
4218         my (undef, undef, $datetime_class) =
4219                 gitweb_get_feature('javascript-timezone');
4220         if ($datetime_class) {
4221                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4222         }
4223
4224         my $localtime_format = '(%02d:%02d %s)';
4225         if ($date->{'hour_local'} < 6) {
4226                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4227         }
4228         $strtime .= ' ' .
4229                     sprintf($localtime_format,
4230                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4231
4232         return $strtime;
4233 }
4234
4235 # Outputs the author name and date in long form
4236 sub git_print_authorship {
4237         my $co = shift;
4238         my %opts = @_;
4239         my $tag = $opts{-tag} || 'div';
4240         my $author = $co->{'author_name'};
4241
4242         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4243         print "<$tag class=\"author_date\">" .
4244               format_search_author($author, "author", esc_html($author)) .
4245               " [".format_timestamp_html(\%ad)."]".
4246               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4247               "</$tag>\n";
4248 }
4249
4250 # Outputs table rows containing the full author or committer information,
4251 # in the format expected for 'commit' view (& similar).
4252 # Parameters are a commit hash reference, followed by the list of people
4253 # to output information for. If the list is empty it defaults to both
4254 # author and committer.
4255 sub git_print_authorship_rows {
4256         my $co = shift;
4257         # too bad we can't use @people = @_ || ('author', 'committer')
4258         my @people = @_;
4259         @people = ('author', 'committer') unless @people;
4260         foreach my $who (@people) {
4261                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4262                 print "<tr><td>$who</td><td>" .
4263                       format_search_author($co->{"${who}_name"}, $who,
4264                                            esc_html($co->{"${who}_name"})) . " " .
4265                       format_search_author($co->{"${who}_email"}, $who,
4266                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4267                       "</td><td rowspan=\"2\">" .
4268                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4269                       "</td></tr>\n" .
4270                       "<tr>" .
4271                       "<td></td><td>" .
4272                       format_timestamp_html(\%wd) .
4273                       "</td>" .
4274                       "</tr>\n";
4275         }
4276 }
4277
4278 sub git_print_page_path {
4279         my $name = shift;
4280         my $type = shift;
4281         my $hb = shift;
4282
4283
4284         print "<div class=\"page_path\">";
4285         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4286                       -title => 'tree root'}, to_utf8("[$project]"));
4287         print " / ";
4288         if (defined $name) {
4289                 my @dirname = split '/', $name;
4290                 my $basename = pop @dirname;
4291                 my $fullname = '';
4292
4293                 foreach my $dir (@dirname) {
4294                         $fullname .= ($fullname ? '/' : '') . $dir;
4295                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4296                                                      hash_base=>$hb),
4297                                       -title => $fullname}, esc_path($dir));
4298                         print " / ";
4299                 }
4300                 if (defined $type && $type eq 'blob') {
4301                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4302                                                      hash_base=>$hb),
4303                                       -title => $name}, esc_path($basename));
4304                 } elsif (defined $type && $type eq 'tree') {
4305                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4306                                                      hash_base=>$hb),
4307                                       -title => $name}, esc_path($basename));
4308                         print " / ";
4309                 } else {
4310                         print esc_path($basename);
4311                 }
4312         }
4313         print "<br/></div>\n";
4314 }
4315
4316 sub git_print_log {
4317         my $log = shift;
4318         my %opts = @_;
4319
4320         if ($opts{'-remove_title'}) {
4321                 # remove title, i.e. first line of log
4322                 shift @$log;
4323         }
4324         # remove leading empty lines
4325         while (defined $log->[0] && $log->[0] eq "") {
4326                 shift @$log;
4327         }
4328
4329         # print log
4330         my $signoff = 0;
4331         my $empty = 0;
4332         foreach my $line (@$log) {
4333                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4334                         $signoff = 1;
4335                         $empty = 0;
4336                         if (! $opts{'-remove_signoff'}) {
4337                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4338                                 next;
4339                         } else {
4340                                 # remove signoff lines
4341                                 next;
4342                         }
4343                 } else {
4344                         $signoff = 0;
4345                 }
4346
4347                 # print only one empty line
4348                 # do not print empty line after signoff
4349                 if ($line eq "") {
4350                         next if ($empty || $signoff);
4351                         $empty = 1;
4352                 } else {
4353                         $empty = 0;
4354                 }
4355
4356                 print format_log_line_html($line) . "<br/>\n";
4357         }
4358
4359         if ($opts{'-final_empty_line'}) {
4360                 # end with single empty line
4361                 print "<br/>\n" unless $empty;
4362         }
4363 }
4364
4365 # return link target (what link points to)
4366 sub git_get_link_target {
4367         my $hash = shift;
4368         my $link_target;
4369
4370         # read link
4371         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4372                 or return;
4373         {
4374                 local $/ = undef;
4375                 $link_target = <$fd>;
4376         }
4377         close $fd
4378                 or return;
4379
4380         return $link_target;
4381 }
4382
4383 # given link target, and the directory (basedir) the link is in,
4384 # return target of link relative to top directory (top tree);
4385 # return undef if it is not possible (including absolute links).
4386 sub normalize_link_target {
4387         my ($link_target, $basedir) = @_;
4388
4389         # absolute symlinks (beginning with '/') cannot be normalized
4390         return if (substr($link_target, 0, 1) eq '/');
4391
4392         # normalize link target to path from top (root) tree (dir)
4393         my $path;
4394         if ($basedir) {
4395                 $path = $basedir . '/' . $link_target;
4396         } else {
4397                 # we are in top (root) tree (dir)
4398                 $path = $link_target;
4399         }
4400
4401         # remove //, /./, and /../
4402         my @path_parts;
4403         foreach my $part (split('/', $path)) {
4404                 # discard '.' and ''
4405                 next if (!$part || $part eq '.');
4406                 # handle '..'
4407                 if ($part eq '..') {
4408                         if (@path_parts) {
4409                                 pop @path_parts;
4410                         } else {
4411                                 # link leads outside repository (outside top dir)
4412                                 return;
4413                         }
4414                 } else {
4415                         push @path_parts, $part;
4416                 }
4417         }
4418         $path = join('/', @path_parts);
4419
4420         return $path;
4421 }
4422
4423 # print tree entry (row of git_tree), but without encompassing <tr> element
4424 sub git_print_tree_entry {
4425         my ($t, $basedir, $hash_base, $have_blame) = @_;
4426
4427         my %base_key = ();
4428         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4429
4430         # The format of a table row is: mode list link.  Where mode is
4431         # the mode of the entry, list is the name of the entry, an href,
4432         # and link is the action links of the entry.
4433
4434         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4435         if (exists $t->{'size'}) {
4436                 print "<td class=\"size\">$t->{'size'}</td>\n";
4437         }
4438         if ($t->{'type'} eq "blob") {
4439                 print "<td class=\"list\">" .
4440                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4441                                                file_name=>"$basedir$t->{'name'}", %base_key),
4442                                 -class => "list"}, esc_path($t->{'name'}));
4443                 if (S_ISLNK(oct $t->{'mode'})) {
4444                         my $link_target = git_get_link_target($t->{'hash'});
4445                         if ($link_target) {
4446                                 my $norm_target = normalize_link_target($link_target, $basedir);
4447                                 if (defined $norm_target) {
4448                                         print " -> " .
4449                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4450                                                                      file_name=>$norm_target),
4451                                                        -title => $norm_target}, esc_path($link_target));
4452                                 } else {
4453                                         print " -> " . esc_path($link_target);
4454                                 }
4455                         }
4456                 }
4457                 print "</td>\n";
4458                 print "<td class=\"link\">";
4459                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4460                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4461                               "blob");
4462                 if ($have_blame) {
4463                         print " | " .
4464                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4465                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4466                                       "blame");
4467                 }
4468                 if (defined $hash_base) {
4469                         print " | " .
4470                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4471                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4472                                       "history");
4473                 }
4474                 print " | " .
4475                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4476                                                file_name=>"$basedir$t->{'name'}")},
4477                                 "raw");
4478                 print "</td>\n";
4479
4480         } elsif ($t->{'type'} eq "tree") {
4481                 print "<td class=\"list\">";
4482                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4483                                              file_name=>"$basedir$t->{'name'}",
4484                                              %base_key)},
4485                               esc_path($t->{'name'}));
4486                 print "</td>\n";
4487                 print "<td class=\"link\">";
4488                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4489                                              file_name=>"$basedir$t->{'name'}",
4490                                              %base_key)},
4491                               "tree");
4492                 if (defined $hash_base) {
4493                         print " | " .
4494                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4495                                                      file_name=>"$basedir$t->{'name'}")},
4496                                       "history");
4497                 }
4498                 print "</td>\n";
4499         } else {
4500                 # unknown object: we can only present history for it
4501                 # (this includes 'commit' object, i.e. submodule support)
4502                 print "<td class=\"list\">" .
4503                       esc_path($t->{'name'}) .
4504                       "</td>\n";
4505                 print "<td class=\"link\">";
4506                 if (defined $hash_base) {
4507                         print $cgi->a({-href => href(action=>"history",
4508                                                      hash_base=>$hash_base,
4509                                                      file_name=>"$basedir$t->{'name'}")},
4510                                       "history");
4511                 }
4512                 print "</td>\n";
4513         }
4514 }
4515
4516 ## ......................................................................
4517 ## functions printing large fragments of HTML
4518
4519 # get pre-image filenames for merge (combined) diff
4520 sub fill_from_file_info {
4521         my ($diff, @parents) = @_;
4522
4523         $diff->{'from_file'} = [ ];
4524         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4525         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4526                 if ($diff->{'status'}[$i] eq 'R' ||
4527                     $diff->{'status'}[$i] eq 'C') {
4528                         $diff->{'from_file'}[$i] =
4529                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4530                 }
4531         }
4532
4533         return $diff;
4534 }
4535
4536 # is current raw difftree line of file deletion
4537 sub is_deleted {
4538         my $diffinfo = shift;
4539
4540         return $diffinfo->{'to_id'} eq ('0' x 40);
4541 }
4542
4543 # does patch correspond to [previous] difftree raw line
4544 # $diffinfo  - hashref of parsed raw diff format
4545 # $patchinfo - hashref of parsed patch diff format
4546 #              (the same keys as in $diffinfo)
4547 sub is_patch_split {
4548         my ($diffinfo, $patchinfo) = @_;
4549
4550         return defined $diffinfo && defined $patchinfo
4551                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4552 }
4553
4554
4555 sub git_difftree_body {
4556         my ($difftree, $hash, @parents) = @_;
4557         my ($parent) = $parents[0];
4558         my $have_blame = gitweb_check_feature('blame');
4559         print "<div class=\"list_head\">\n";
4560         if ($#{$difftree} > 10) {
4561                 print(($#{$difftree} + 1) . " files changed:\n");
4562         }
4563         print "</div>\n";
4564
4565         print "<table class=\"" .
4566               (@parents > 1 ? "combined " : "") .
4567               "diff_tree\">\n";
4568
4569         # header only for combined diff in 'commitdiff' view
4570         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4571         if ($has_header) {
4572                 # table header
4573                 print "<thead><tr>\n" .
4574                        "<th></th><th></th>\n"; # filename, patchN link
4575                 for (my $i = 0; $i < @parents; $i++) {
4576                         my $par = $parents[$i];
4577                         print "<th>" .
4578                               $cgi->a({-href => href(action=>"commitdiff",
4579                                                      hash=>$hash, hash_parent=>$par),
4580                                        -title => 'commitdiff to parent number ' .
4581                                                   ($i+1) . ': ' . substr($par,0,7)},
4582                                       $i+1) .
4583                               "&nbsp;</th>\n";
4584                 }
4585                 print "</tr></thead>\n<tbody>\n";
4586         }
4587
4588         my $alternate = 1;
4589         my $patchno = 0;
4590         foreach my $line (@{$difftree}) {
4591                 my $diff = parsed_difftree_line($line);
4592
4593                 if ($alternate) {
4594                         print "<tr class=\"dark\">\n";
4595                 } else {
4596                         print "<tr class=\"light\">\n";
4597                 }
4598                 $alternate ^= 1;
4599
4600                 if (exists $diff->{'nparents'}) { # combined diff
4601
4602                         fill_from_file_info($diff, @parents)
4603                                 unless exists $diff->{'from_file'};
4604
4605                         if (!is_deleted($diff)) {
4606                                 # file exists in the result (child) commit
4607                                 print "<td>" .
4608                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4609                                                              file_name=>$diff->{'to_file'},
4610                                                              hash_base=>$hash),
4611                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4612                                       "</td>\n";
4613                         } else {
4614                                 print "<td>" .
4615                                       esc_path($diff->{'to_file'}) .
4616                                       "</td>\n";
4617                         }
4618
4619                         if ($action eq 'commitdiff') {
4620                                 # link to patch
4621                                 $patchno++;
4622                                 print "<td class=\"link\">" .
4623                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4624                                               "patch") .
4625                                       " | " .
4626                                       "</td>\n";
4627                         }
4628
4629                         my $has_history = 0;
4630                         my $not_deleted = 0;
4631                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4632                                 my $hash_parent = $parents[$i];
4633                                 my $from_hash = $diff->{'from_id'}[$i];
4634                                 my $from_path = $diff->{'from_file'}[$i];
4635                                 my $status = $diff->{'status'}[$i];
4636
4637                                 $has_history ||= ($status ne 'A');
4638                                 $not_deleted ||= ($status ne 'D');
4639
4640                                 if ($status eq 'A') {
4641                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4642                                 } elsif ($status eq 'D') {
4643                                         print "<td class=\"link\">" .
4644                                               $cgi->a({-href => href(action=>"blob",
4645                                                                      hash_base=>$hash,
4646                                                                      hash=>$from_hash,
4647                                                                      file_name=>$from_path)},
4648                                                       "blob" . ($i+1)) .
4649                                               " | </td>\n";
4650                                 } else {
4651                                         if ($diff->{'to_id'} eq $from_hash) {
4652                                                 print "<td class=\"link nochange\">";
4653                                         } else {
4654                                                 print "<td class=\"link\">";
4655                                         }
4656                                         print $cgi->a({-href => href(action=>"blobdiff",
4657                                                                      hash=>$diff->{'to_id'},
4658                                                                      hash_parent=>$from_hash,
4659                                                                      hash_base=>$hash,
4660                                                                      hash_parent_base=>$hash_parent,
4661                                                                      file_name=>$diff->{'to_file'},
4662                                                                      file_parent=>$from_path)},
4663                                                       "diff" . ($i+1)) .
4664                                               " | </td>\n";
4665                                 }
4666                         }
4667
4668                         print "<td class=\"link\">";
4669                         if ($not_deleted) {
4670                                 print $cgi->a({-href => href(action=>"blob",
4671                                                              hash=>$diff->{'to_id'},
4672                                                              file_name=>$diff->{'to_file'},
4673                                                              hash_base=>$hash)},
4674                                               "blob");
4675                                 print " | " if ($has_history);
4676                         }
4677                         if ($has_history) {
4678                                 print $cgi->a({-href => href(action=>"history",
4679                                                              file_name=>$diff->{'to_file'},
4680                                                              hash_base=>$hash)},
4681                                               "history");
4682                         }
4683                         print "</td>\n";
4684
4685                         print "</tr>\n";
4686                         next; # instead of 'else' clause, to avoid extra indent
4687                 }
4688                 # else ordinary diff
4689
4690                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4691                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4692                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4693                         $to_mode_oct = oct $diff->{'to_mode'};
4694                         if (S_ISREG($to_mode_oct)) { # only for regular file
4695                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4696                         }
4697                         $to_file_type = file_type($diff->{'to_mode'});
4698                 }
4699                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4700                         $from_mode_oct = oct $diff->{'from_mode'};
4701                         if (S_ISREG($from_mode_oct)) { # only for regular file
4702                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4703                         }
4704                         $from_file_type = file_type($diff->{'from_mode'});
4705                 }
4706
4707                 if ($diff->{'status'} eq "A") { # created
4708                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4709                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4710                         $mode_chng   .= "]</span>";
4711                         print "<td>";
4712                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4713                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4714                                       -class => "list"}, esc_path($diff->{'file'}));
4715                         print "</td>\n";
4716                         print "<td>$mode_chng</td>\n";
4717                         print "<td class=\"link\">";
4718                         if ($action eq 'commitdiff') {
4719                                 # link to patch
4720                                 $patchno++;
4721                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4722                                               "patch") .
4723                                       " | ";
4724                         }
4725                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4726                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4727                                       "blob");
4728                         print "</td>\n";
4729
4730                 } elsif ($diff->{'status'} eq "D") { # deleted
4731                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4732                         print "<td>";
4733                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4734                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4735                                        -class => "list"}, esc_path($diff->{'file'}));
4736                         print "</td>\n";
4737                         print "<td>$mode_chng</td>\n";
4738                         print "<td class=\"link\">";
4739                         if ($action eq 'commitdiff') {
4740                                 # link to patch
4741                                 $patchno++;
4742                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4743                                               "patch") .
4744                                       " | ";
4745                         }
4746                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4747                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4748                                       "blob") . " | ";
4749                         if ($have_blame) {
4750                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4751                                                              file_name=>$diff->{'file'})},
4752                                               "blame") . " | ";
4753                         }
4754                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4755                                                      file_name=>$diff->{'file'})},
4756                                       "history");
4757                         print "</td>\n";
4758
4759                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4760                         my $mode_chnge = "";
4761                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4762                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4763                                 if ($from_file_type ne $to_file_type) {
4764                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4765                                 }
4766                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4767                                         if ($from_mode_str && $to_mode_str) {
4768                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4769                                         } elsif ($to_mode_str) {
4770                                                 $mode_chnge .= " mode: $to_mode_str";
4771                                         }
4772                                 }
4773                                 $mode_chnge .= "]</span>\n";
4774                         }
4775                         print "<td>";
4776                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4777                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4778                                       -class => "list"}, esc_path($diff->{'file'}));
4779                         print "</td>\n";
4780                         print "<td>$mode_chnge</td>\n";
4781                         print "<td class=\"link\">";
4782                         if ($action eq 'commitdiff') {
4783                                 # link to patch
4784                                 $patchno++;
4785                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4786                                               "patch") .
4787                                       " | ";
4788                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4789                                 # "commit" view and modified file (not onlu mode changed)
4790                                 print $cgi->a({-href => href(action=>"blobdiff",
4791                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4792                                                              hash_base=>$hash, hash_parent_base=>$parent,
4793                                                              file_name=>$diff->{'file'})},
4794                                               "diff") .
4795                                       " | ";
4796                         }
4797                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4798                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4799                                        "blob") . " | ";
4800                         if ($have_blame) {
4801                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4802                                                              file_name=>$diff->{'file'})},
4803                                               "blame") . " | ";
4804                         }
4805                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4806                                                      file_name=>$diff->{'file'})},
4807                                       "history");
4808                         print "</td>\n";
4809
4810                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4811                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4812                         my $nstatus = $status_name{$diff->{'status'}};
4813                         my $mode_chng = "";
4814                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4815                                 # mode also for directories, so we cannot use $to_mode_str
4816                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4817                         }
4818                         print "<td>" .
4819                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4820                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4821                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4822                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4823                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4824                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4825                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4826                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4827                               "<td class=\"link\">";
4828                         if ($action eq 'commitdiff') {
4829                                 # link to patch
4830                                 $patchno++;
4831                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4832                                               "patch") .
4833                                       " | ";
4834                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4835                                 # "commit" view and modified file (not only pure rename or copy)
4836                                 print $cgi->a({-href => href(action=>"blobdiff",
4837                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4838                                                              hash_base=>$hash, hash_parent_base=>$parent,
4839                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4840                                               "diff") .
4841                                       " | ";
4842                         }
4843                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4844                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4845                                       "blob") . " | ";
4846                         if ($have_blame) {
4847                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4848                                                              file_name=>$diff->{'to_file'})},
4849                                               "blame") . " | ";
4850                         }
4851                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4852                                                     file_name=>$diff->{'to_file'})},
4853                                       "history");
4854                         print "</td>\n";
4855
4856                 } # we should not encounter Unmerged (U) or Unknown (X) status
4857                 print "</tr>\n";
4858         }
4859         print "</tbody>" if $has_header;
4860         print "</table>\n";
4861 }
4862
4863 sub print_sidebyside_diff_chunk {
4864         my @chunk = @_;
4865         my (@ctx, @rem, @add);
4866
4867         return unless @chunk;
4868
4869         # incomplete last line might be among removed or added lines,
4870         # or both, or among context lines: find which
4871         for (my $i = 1; $i < @chunk; $i++) {
4872                 if ($chunk[$i][0] eq 'incomplete') {
4873                         $chunk[$i][0] = $chunk[$i-1][0];
4874                 }
4875         }
4876
4877         # guardian
4878         push @chunk, ["", ""];
4879
4880         foreach my $line_info (@chunk) {
4881                 my ($class, $line) = @$line_info;
4882
4883                 # print chunk headers
4884                 if ($class && $class eq 'chunk_header') {
4885                         print $line;
4886                         next;
4887                 }
4888
4889                 ## print from accumulator when type of class of lines change
4890                 # empty contents block on start rem/add block, or end of chunk
4891                 if (@ctx && (!$class || $class eq 'rem' || $class eq 'add')) {
4892                         print join '',
4893                                 '<div class="chunk_block">',
4894                                         '<div class="old">',
4895                                         @ctx,
4896                                         '</div>',
4897                                         '<div class="new">',
4898                                         @ctx,
4899                                         '</div>',
4900                                 '</div>';
4901                         @ctx = ();
4902                 }
4903                 # empty add/rem block on start context block, or end of chunk
4904                 if ((@rem || @add) && (!$class || $class eq 'ctx')) {
4905                         print join '',
4906                                 '<div class="chunk_block">',
4907                                         '<div class="old">',
4908                                         @rem,
4909                                         '</div>',
4910                                         '<div class="new">',
4911                                         @add,
4912                                         '</div>',
4913                                 '</div>';
4914                         @rem = @add = ();
4915                 }
4916
4917                 ## adding lines to accumulator
4918                 # guardian value
4919                 last unless $line;
4920                 # rem, add or change
4921                 if ($class eq 'rem') {
4922                         push @rem, $line;
4923                 } elsif ($class eq 'add') {
4924                         push @add, $line;
4925                 }
4926                 # context line
4927                 if ($class eq 'ctx') {
4928                         push @ctx, $line;
4929                 }
4930         }
4931 }
4932
4933 sub git_patchset_body {
4934         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
4935         my ($hash_parent) = $hash_parents[0];
4936
4937         my $is_combined = (@hash_parents > 1);
4938         my $patch_idx = 0;
4939         my $patch_number = 0;
4940         my $patch_line;
4941         my $diffinfo;
4942         my $to_name;
4943         my (%from, %to);
4944         my @chunk; # for side-by-side diff
4945
4946         print "<div class=\"patchset\">\n";
4947
4948         # skip to first patch
4949         while ($patch_line = <$fd>) {
4950                 chomp $patch_line;
4951
4952                 last if ($patch_line =~ m/^diff /);
4953         }
4954
4955  PATCH:
4956         while ($patch_line) {
4957
4958                 # parse "git diff" header line
4959                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4960                         # $1 is from_name, which we do not use
4961                         $to_name = unquote($2);
4962                         $to_name =~ s!^b/!!;
4963                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4964                         # $1 is 'cc' or 'combined', which we do not use
4965                         $to_name = unquote($2);
4966                 } else {
4967                         $to_name = undef;
4968                 }
4969
4970                 # check if current patch belong to current raw line
4971                 # and parse raw git-diff line if needed
4972                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4973                         # this is continuation of a split patch
4974                         print "<div class=\"patch cont\">\n";
4975                 } else {
4976                         # advance raw git-diff output if needed
4977                         $patch_idx++ if defined $diffinfo;
4978
4979                         # read and prepare patch information
4980                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4981
4982                         # compact combined diff output can have some patches skipped
4983                         # find which patch (using pathname of result) we are at now;
4984                         if ($is_combined) {
4985                                 while ($to_name ne $diffinfo->{'to_file'}) {
4986                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4987                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4988                                               "</div>\n";  # class="patch"
4989
4990                                         $patch_idx++;
4991                                         $patch_number++;
4992
4993                                         last if $patch_idx > $#$difftree;
4994                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4995                                 }
4996                         }
4997
4998                         # modifies %from, %to hashes
4999                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5000
5001                         # this is first patch for raw difftree line with $patch_idx index
5002                         # we index @$difftree array from 0, but number patches from 1
5003                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5004                 }
5005
5006                 # git diff header
5007                 #assert($patch_line =~ m/^diff /) if DEBUG;
5008                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5009                 $patch_number++;
5010                 # print "git diff" header
5011                 print format_git_diff_header_line($patch_line, $diffinfo,
5012                                                   \%from, \%to);
5013
5014                 # print extended diff header
5015                 print "<div class=\"diff extended_header\">\n";
5016         EXTENDED_HEADER:
5017                 while ($patch_line = <$fd>) {
5018                         chomp $patch_line;
5019
5020                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5021
5022                         print format_extended_diff_header_line($patch_line, $diffinfo,
5023                                                                \%from, \%to);
5024                 }
5025                 print "</div>\n"; # class="diff extended_header"
5026
5027                 # from-file/to-file diff header
5028                 if (! $patch_line) {
5029                         print "</div>\n"; # class="patch"
5030                         last PATCH;
5031                 }
5032                 next PATCH if ($patch_line =~ m/^diff /);
5033                 #assert($patch_line =~ m/^---/) if DEBUG;
5034
5035                 my $last_patch_line = $patch_line;
5036                 $patch_line = <$fd>;
5037                 chomp $patch_line;
5038                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5039
5040                 print format_diff_from_to_header($last_patch_line, $patch_line,
5041                                                  $diffinfo, \%from, \%to,
5042                                                  @hash_parents);
5043
5044                 # the patch itself
5045         LINE:
5046                 while ($patch_line = <$fd>) {
5047                         chomp $patch_line;
5048
5049                         next PATCH if ($patch_line =~ m/^diff /);
5050
5051                         my ($class, $line) = process_diff_line($patch_line, \%from, \%to);
5052                         my $diff_classes = "diff";
5053                         $diff_classes .= " $class" if ($class);
5054                         $line = "<div class=\"$diff_classes\">$line</div>\n";
5055
5056                         if ($diff_style eq 'sidebyside' && !$is_combined) {
5057                                 if ($class eq 'chunk_header') {
5058                                         print_sidebyside_diff_chunk(@chunk);
5059                                         @chunk = ( [ $class, $line ] );
5060                                 } else {
5061                                         push @chunk, [ $class, $line ];
5062                                 }
5063                         } else {
5064                                 # default 'inline' style and unknown styles
5065                                 print $line;
5066                         }
5067                 }
5068
5069         } continue {
5070                 if (@chunk) {
5071                         print_sidebyside_diff_chunk(@chunk);
5072                         @chunk = ();
5073                 }
5074                 print "</div>\n"; # class="patch"
5075         }
5076
5077         # for compact combined (--cc) format, with chunk and patch simplification
5078         # the patchset might be empty, but there might be unprocessed raw lines
5079         for (++$patch_idx if $patch_number > 0;
5080              $patch_idx < @$difftree;
5081              ++$patch_idx) {
5082                 # read and prepare patch information
5083                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5084
5085                 # generate anchor for "patch" links in difftree / whatchanged part
5086                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5087                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5088                       "</div>\n";  # class="patch"
5089
5090                 $patch_number++;
5091         }
5092
5093         if ($patch_number == 0) {
5094                 if (@hash_parents > 1) {
5095                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5096                 } else {
5097                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5098                 }
5099         }
5100
5101         print "</div>\n"; # class="patchset"
5102 }
5103
5104 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5105
5106 # fills project list info (age, description, owner, category, forks)
5107 # for each project in the list, removing invalid projects from
5108 # returned list
5109 # NOTE: modifies $projlist, but does not remove entries from it
5110 sub fill_project_list_info {
5111         my $projlist = shift;
5112         my @projects;
5113
5114         my $show_ctags = gitweb_check_feature('ctags');
5115  PROJECT:
5116         foreach my $pr (@$projlist) {
5117                 my (@activity) = git_get_last_activity($pr->{'path'});
5118                 unless (@activity) {
5119                         next PROJECT;
5120                 }
5121                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5122                 if (!defined $pr->{'descr'}) {
5123                         my $descr = git_get_project_description($pr->{'path'}) || "";
5124                         $descr = to_utf8($descr);
5125                         $pr->{'descr_long'} = $descr;
5126                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5127                 }
5128                 if (!defined $pr->{'owner'}) {
5129                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5130                 }
5131                 if ($show_ctags) {
5132                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5133                 }
5134                 if ($projects_list_group_categories && !defined $pr->{'category'}) {
5135                         my $cat = git_get_project_category($pr->{'path'}) ||
5136                                                            $project_list_default_category;
5137                         $pr->{'category'} = to_utf8($cat);
5138                 }
5139
5140                 push @projects, $pr;
5141         }
5142
5143         return @projects;
5144 }
5145
5146 sub sort_projects_list {
5147         my ($projlist, $order) = @_;
5148         my @projects;
5149
5150         my %order_info = (
5151                 project => { key => 'path', type => 'str' },
5152                 descr => { key => 'descr_long', type => 'str' },
5153                 owner => { key => 'owner', type => 'str' },
5154                 age => { key => 'age', type => 'num' }
5155         );
5156         my $oi = $order_info{$order};
5157         return @$projlist unless defined $oi;
5158         if ($oi->{'type'} eq 'str') {
5159                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5160         } else {
5161                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5162         }
5163
5164         return @projects;
5165 }
5166
5167 # returns a hash of categories, containing the list of project
5168 # belonging to each category
5169 sub build_projlist_by_category {
5170         my ($projlist, $from, $to) = @_;
5171         my %categories;
5172
5173         $from = 0 unless defined $from;
5174         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5175
5176         for (my $i = $from; $i <= $to; $i++) {
5177                 my $pr = $projlist->[$i];
5178                 push @{$categories{ $pr->{'category'} }}, $pr;
5179         }
5180
5181         return wantarray ? %categories : \%categories;
5182 }
5183
5184 # print 'sort by' <th> element, generating 'sort by $name' replay link
5185 # if that order is not selected
5186 sub print_sort_th {
5187         print format_sort_th(@_);
5188 }
5189
5190 sub format_sort_th {
5191         my ($name, $order, $header) = @_;
5192         my $sort_th = "";
5193         $header ||= ucfirst($name);
5194
5195         if ($order eq $name) {
5196                 $sort_th .= "<th>$header</th>\n";
5197         } else {
5198                 $sort_th .= "<th>" .
5199                             $cgi->a({-href => href(-replay=>1, order=>$name),
5200                                      -class => "header"}, $header) .
5201                             "</th>\n";
5202         }
5203
5204         return $sort_th;
5205 }
5206
5207 sub git_project_list_rows {
5208         my ($projlist, $from, $to, $check_forks) = @_;
5209
5210         $from = 0 unless defined $from;
5211         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5212
5213         my $alternate = 1;
5214         for (my $i = $from; $i <= $to; $i++) {
5215                 my $pr = $projlist->[$i];
5216
5217                 if ($alternate) {
5218                         print "<tr class=\"dark\">\n";
5219                 } else {
5220                         print "<tr class=\"light\">\n";
5221                 }
5222                 $alternate ^= 1;
5223
5224                 if ($check_forks) {
5225                         print "<td>";
5226                         if ($pr->{'forks'}) {
5227                                 my $nforks = scalar @{$pr->{'forks'}};
5228                                 if ($nforks > 0) {
5229                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5230                                                        -title => "$nforks forks"}, "+");
5231                                 } else {
5232                                         print $cgi->span({-title => "$nforks forks"}, "+");
5233                                 }
5234                         }
5235                         print "</td>\n";
5236                 }
5237                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5238                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
5239                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5240                                         -class => "list", -title => $pr->{'descr_long'}},
5241                                         esc_html($pr->{'descr'})) . "</td>\n" .
5242                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5243                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5244                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5245                       "<td class=\"link\">" .
5246                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5247                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5248                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5249                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5250                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5251                       "</td>\n" .
5252                       "</tr>\n";
5253         }
5254 }
5255
5256 sub git_project_list_body {
5257         # actually uses global variable $project
5258         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5259         my @projects = @$projlist;
5260
5261         my $check_forks = gitweb_check_feature('forks');
5262         my $show_ctags  = gitweb_check_feature('ctags');
5263         my $tagfilter = $show_ctags ? $cgi->param('by_tag') : undef;
5264         $check_forks = undef
5265                 if ($tagfilter || $searchtext);
5266
5267         # filtering out forks before filling info allows to do less work
5268         @projects = filter_forks_from_projects_list(\@projects)
5269                 if ($check_forks);
5270         @projects = fill_project_list_info(\@projects);
5271         # searching projects require filling to be run before it
5272         @projects = search_projects_list(\@projects,
5273                                          'searchtext' => $searchtext,
5274                                          'tagfilter'  => $tagfilter)
5275                 if ($tagfilter || $searchtext);
5276
5277         $order ||= $default_projects_order;
5278         $from = 0 unless defined $from;
5279         $to = $#projects if (!defined $to || $#projects < $to);
5280
5281         # short circuit
5282         if ($from > $to) {
5283                 print "<center>\n".
5284                       "<b>No such projects found</b><br />\n".
5285                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5286                       "</center>\n<br />\n";
5287                 return;
5288         }
5289
5290         @projects = sort_projects_list(\@projects, $order);
5291
5292         if ($show_ctags) {
5293                 my $ctags = git_gather_all_ctags(\@projects);
5294                 my $cloud = git_populate_project_tagcloud($ctags);
5295                 print git_show_project_tagcloud($cloud, 64);
5296         }
5297
5298         print "<table class=\"project_list\">\n";
5299         unless ($no_header) {
5300                 print "<tr>\n";
5301                 if ($check_forks) {
5302                         print "<th></th>\n";
5303                 }
5304                 print_sort_th('project', $order, 'Project');
5305                 print_sort_th('descr', $order, 'Description');
5306                 print_sort_th('owner', $order, 'Owner');
5307                 print_sort_th('age', $order, 'Last Change');
5308                 print "<th></th>\n" . # for links
5309                       "</tr>\n";
5310         }
5311
5312         if ($projects_list_group_categories) {
5313                 # only display categories with projects in the $from-$to window
5314                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5315                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5316                 foreach my $cat (sort keys %categories) {
5317                         unless ($cat eq "") {
5318                                 print "<tr>\n";
5319                                 if ($check_forks) {
5320                                         print "<td></td>\n";
5321                                 }
5322                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5323                                 print "</tr>\n";
5324                         }
5325
5326                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5327                 }
5328         } else {
5329                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5330         }
5331
5332         if (defined $extra) {
5333                 print "<tr>\n";
5334                 if ($check_forks) {
5335                         print "<td></td>\n";
5336                 }
5337                 print "<td colspan=\"5\">$extra</td>\n" .
5338                       "</tr>\n";
5339         }
5340         print "</table>\n";
5341 }
5342
5343 sub git_log_body {
5344         # uses global variable $project
5345         my ($commitlist, $from, $to, $refs, $extra) = @_;
5346
5347         $from = 0 unless defined $from;
5348         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5349
5350         for (my $i = 0; $i <= $to; $i++) {
5351                 my %co = %{$commitlist->[$i]};
5352                 next if !%co;
5353                 my $commit = $co{'id'};
5354                 my $ref = format_ref_marker($refs, $commit);
5355                 git_print_header_div('commit',
5356                                "<span class=\"age\">$co{'age_string'}</span>" .
5357                                esc_html($co{'title'}) . $ref,
5358                                $commit);
5359                 print "<div class=\"title_text\">\n" .
5360                       "<div class=\"log_link\">\n" .
5361                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5362                       " | " .
5363                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5364                       " | " .
5365                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5366                       "<br/>\n" .
5367                       "</div>\n";
5368                       git_print_authorship(\%co, -tag => 'span');
5369                       print "<br/>\n</div>\n";
5370
5371                 print "<div class=\"log_body\">\n";
5372                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5373                 print "</div>\n";
5374         }
5375         if ($extra) {
5376                 print "<div class=\"page_nav\">\n";
5377                 print "$extra\n";
5378                 print "</div>\n";
5379         }
5380 }
5381
5382 sub git_shortlog_body {
5383         # uses global variable $project
5384         my ($commitlist, $from, $to, $refs, $extra) = @_;
5385
5386         $from = 0 unless defined $from;
5387         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5388
5389         print "<table class=\"shortlog\">\n";
5390         my $alternate = 1;
5391         for (my $i = $from; $i <= $to; $i++) {
5392                 my %co = %{$commitlist->[$i]};
5393                 my $commit = $co{'id'};
5394                 my $ref = format_ref_marker($refs, $commit);
5395                 if ($alternate) {
5396                         print "<tr class=\"dark\">\n";
5397                 } else {
5398                         print "<tr class=\"light\">\n";
5399                 }
5400                 $alternate ^= 1;
5401                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5402                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5403                       format_author_html('td', \%co, 10) . "<td>";
5404                 print format_subject_html($co{'title'}, $co{'title_short'},
5405                                           href(action=>"commit", hash=>$commit), $ref);
5406                 print "</td>\n" .
5407                       "<td class=\"link\">" .
5408                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5409                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5410                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5411                 my $snapshot_links = format_snapshot_links($commit);
5412                 if (defined $snapshot_links) {
5413                         print " | " . $snapshot_links;
5414                 }
5415                 print "</td>\n" .
5416                       "</tr>\n";
5417         }
5418         if (defined $extra) {
5419                 print "<tr>\n" .
5420                       "<td colspan=\"4\">$extra</td>\n" .
5421                       "</tr>\n";
5422         }
5423         print "</table>\n";
5424 }
5425
5426 sub git_history_body {
5427         # Warning: assumes constant type (blob or tree) during history
5428         my ($commitlist, $from, $to, $refs, $extra,
5429             $file_name, $file_hash, $ftype) = @_;
5430
5431         $from = 0 unless defined $from;
5432         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5433
5434         print "<table class=\"history\">\n";
5435         my $alternate = 1;
5436         for (my $i = $from; $i <= $to; $i++) {
5437                 my %co = %{$commitlist->[$i]};
5438                 if (!%co) {
5439                         next;
5440                 }
5441                 my $commit = $co{'id'};
5442
5443                 my $ref = format_ref_marker($refs, $commit);
5444
5445                 if ($alternate) {
5446                         print "<tr class=\"dark\">\n";
5447                 } else {
5448                         print "<tr class=\"light\">\n";
5449                 }
5450                 $alternate ^= 1;
5451                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5452         # shortlog:   format_author_html('td', \%co, 10)
5453                       format_author_html('td', \%co, 15, 3) . "<td>";
5454                 # originally git_history used chop_str($co{'title'}, 50)
5455                 print format_subject_html($co{'title'}, $co{'title_short'},
5456                                           href(action=>"commit", hash=>$commit), $ref);
5457                 print "</td>\n" .
5458                       "<td class=\"link\">" .
5459                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5460                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5461
5462                 if ($ftype eq 'blob') {
5463                         my $blob_current = $file_hash;
5464                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5465                         if (defined $blob_current && defined $blob_parent &&
5466                                         $blob_current ne $blob_parent) {
5467                                 print " | " .
5468                                         $cgi->a({-href => href(action=>"blobdiff",
5469                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5470                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5471                                                                file_name=>$file_name)},
5472                                                 "diff to current");
5473                         }
5474                 }
5475                 print "</td>\n" .
5476                       "</tr>\n";
5477         }
5478         if (defined $extra) {
5479                 print "<tr>\n" .
5480                       "<td colspan=\"4\">$extra</td>\n" .
5481                       "</tr>\n";
5482         }
5483         print "</table>\n";
5484 }
5485
5486 sub git_tags_body {
5487         # uses global variable $project
5488         my ($taglist, $from, $to, $extra) = @_;
5489         $from = 0 unless defined $from;
5490         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5491
5492         print "<table class=\"tags\">\n";
5493         my $alternate = 1;
5494         for (my $i = $from; $i <= $to; $i++) {
5495                 my $entry = $taglist->[$i];
5496                 my %tag = %$entry;
5497                 my $comment = $tag{'subject'};
5498                 my $comment_short;
5499                 if (defined $comment) {
5500                         $comment_short = chop_str($comment, 30, 5);
5501                 }
5502                 if ($alternate) {
5503                         print "<tr class=\"dark\">\n";
5504                 } else {
5505                         print "<tr class=\"light\">\n";
5506                 }
5507                 $alternate ^= 1;
5508                 if (defined $tag{'age'}) {
5509                         print "<td><i>$tag{'age'}</i></td>\n";
5510                 } else {
5511                         print "<td></td>\n";
5512                 }
5513                 print "<td>" .
5514                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5515                                -class => "list name"}, esc_html($tag{'name'})) .
5516                       "</td>\n" .
5517                       "<td>";
5518                 if (defined $comment) {
5519                         print format_subject_html($comment, $comment_short,
5520                                                   href(action=>"tag", hash=>$tag{'id'}));
5521                 }
5522                 print "</td>\n" .
5523                       "<td class=\"selflink\">";
5524                 if ($tag{'type'} eq "tag") {
5525                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5526                 } else {
5527                         print "&nbsp;";
5528                 }
5529                 print "</td>\n" .
5530                       "<td class=\"link\">" . " | " .
5531                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5532                 if ($tag{'reftype'} eq "commit") {
5533                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5534                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5535                 } elsif ($tag{'reftype'} eq "blob") {
5536                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5537                 }
5538                 print "</td>\n" .
5539                       "</tr>";
5540         }
5541         if (defined $extra) {
5542                 print "<tr>\n" .
5543                       "<td colspan=\"5\">$extra</td>\n" .
5544                       "</tr>\n";
5545         }
5546         print "</table>\n";
5547 }
5548
5549 sub git_heads_body {
5550         # uses global variable $project
5551         my ($headlist, $head, $from, $to, $extra) = @_;
5552         $from = 0 unless defined $from;
5553         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5554
5555         print "<table class=\"heads\">\n";
5556         my $alternate = 1;
5557         for (my $i = $from; $i <= $to; $i++) {
5558                 my $entry = $headlist->[$i];
5559                 my %ref = %$entry;
5560                 my $curr = $ref{'id'} eq $head;
5561                 if ($alternate) {
5562                         print "<tr class=\"dark\">\n";
5563                 } else {
5564                         print "<tr class=\"light\">\n";
5565                 }
5566                 $alternate ^= 1;
5567                 print "<td><i>$ref{'age'}</i></td>\n" .
5568                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5569                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5570                                -class => "list name"},esc_html($ref{'name'})) .
5571                       "</td>\n" .
5572                       "<td class=\"link\">" .
5573                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5574                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5575                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5576                       "</td>\n" .
5577                       "</tr>";
5578         }
5579         if (defined $extra) {
5580                 print "<tr>\n" .
5581                       "<td colspan=\"3\">$extra</td>\n" .
5582                       "</tr>\n";
5583         }
5584         print "</table>\n";
5585 }
5586
5587 # Display a single remote block
5588 sub git_remote_block {
5589         my ($remote, $rdata, $limit, $head) = @_;
5590
5591         my $heads = $rdata->{'heads'};
5592         my $fetch = $rdata->{'fetch'};
5593         my $push = $rdata->{'push'};
5594
5595         my $urls_table = "<table class=\"projects_list\">\n" ;
5596
5597         if (defined $fetch) {
5598                 if ($fetch eq $push) {
5599                         $urls_table .= format_repo_url("URL", $fetch);
5600                 } else {
5601                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5602                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5603                 }
5604         } elsif (defined $push) {
5605                 $urls_table .= format_repo_url("Push URL", $push);
5606         } else {
5607                 $urls_table .= format_repo_url("", "No remote URL");
5608         }
5609
5610         $urls_table .= "</table>\n";
5611
5612         my $dots;
5613         if (defined $limit && $limit < @$heads) {
5614                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5615         }
5616
5617         print $urls_table;
5618         git_heads_body($heads, $head, 0, $limit, $dots);
5619 }
5620
5621 # Display a list of remote names with the respective fetch and push URLs
5622 sub git_remotes_list {
5623         my ($remotedata, $limit) = @_;
5624         print "<table class=\"heads\">\n";
5625         my $alternate = 1;
5626         my @remotes = sort keys %$remotedata;
5627
5628         my $limited = $limit && $limit < @remotes;
5629
5630         $#remotes = $limit - 1 if $limited;
5631
5632         while (my $remote = shift @remotes) {
5633                 my $rdata = $remotedata->{$remote};
5634                 my $fetch = $rdata->{'fetch'};
5635                 my $push = $rdata->{'push'};
5636                 if ($alternate) {
5637                         print "<tr class=\"dark\">\n";
5638                 } else {
5639                         print "<tr class=\"light\">\n";
5640                 }
5641                 $alternate ^= 1;
5642                 print "<td>" .
5643                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5644                                -class=> "list name"},esc_html($remote)) .
5645                       "</td>";
5646                 print "<td class=\"link\">" .
5647                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5648                       " | " .
5649                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5650                       "</td>";
5651
5652                 print "</tr>\n";
5653         }
5654
5655         if ($limited) {
5656                 print "<tr>\n" .
5657                       "<td colspan=\"3\">" .
5658                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5659                       "</td>\n" . "</tr>\n";
5660         }
5661
5662         print "</table>";
5663 }
5664
5665 # Display remote heads grouped by remote, unless there are too many
5666 # remotes, in which case we only display the remote names
5667 sub git_remotes_body {
5668         my ($remotedata, $limit, $head) = @_;
5669         if ($limit and $limit < keys %$remotedata) {
5670                 git_remotes_list($remotedata, $limit);
5671         } else {
5672                 fill_remote_heads($remotedata);
5673                 while (my ($remote, $rdata) = each %$remotedata) {
5674                         git_print_section({-class=>"remote", -id=>$remote},
5675                                 ["remotes", $remote, $remote], sub {
5676                                         git_remote_block($remote, $rdata, $limit, $head);
5677                                 });
5678                 }
5679         }
5680 }
5681
5682 sub git_search_message {
5683         my %co = @_;
5684
5685         my $greptype;
5686         if ($searchtype eq 'commit') {
5687                 $greptype = "--grep=";
5688         } elsif ($searchtype eq 'author') {
5689                 $greptype = "--author=";
5690         } elsif ($searchtype eq 'committer') {
5691                 $greptype = "--committer=";
5692         }
5693         $greptype .= $searchtext;
5694         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5695                                        $greptype, '--regexp-ignore-case',
5696                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5697
5698         my $paging_nav = '';
5699         if ($page > 0) {
5700                 $paging_nav .=
5701                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5702                                 "first") .
5703                         " &sdot; " .
5704                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5705                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5706         } else {
5707                 $paging_nav .= "first &sdot; prev";
5708         }
5709         my $next_link = '';
5710         if ($#commitlist >= 100) {
5711                 $next_link =
5712                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5713                                  -accesskey => "n", -title => "Alt-n"}, "next");
5714                 $paging_nav .= " &sdot; $next_link";
5715         } else {
5716                 $paging_nav .= " &sdot; next";
5717         }
5718
5719         git_header_html();
5720
5721         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5722         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5723         if ($page == 0 && !@commitlist) {
5724                 print "<p>No match.</p>\n";
5725         } else {
5726                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5727         }
5728
5729         git_footer_html();
5730 }
5731
5732 sub git_search_changes {
5733         my %co = @_;
5734
5735         local $/ = "\n";
5736         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5737                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5738                 ($search_use_regexp ? '--pickaxe-regex' : ())
5739                         or die_error(500, "Open git-log failed");
5740
5741         git_header_html();
5742
5743         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5744         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5745
5746         print "<table class=\"pickaxe search\">\n";
5747         my $alternate = 1;
5748         undef %co;
5749         my @files;
5750         while (my $line = <$fd>) {
5751                 chomp $line;
5752                 next unless $line;
5753
5754                 my %set = parse_difftree_raw_line($line);
5755                 if (defined $set{'commit'}) {
5756                         # finish previous commit
5757                         if (%co) {
5758                                 print "</td>\n" .
5759                                       "<td class=\"link\">" .
5760                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5761                                               "commit") .
5762                                       " | " .
5763                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5764                                                              hash_base=>$co{'id'})},
5765                                               "tree") .
5766                                       "</td>\n" .
5767                                       "</tr>\n";
5768                         }
5769
5770                         if ($alternate) {
5771                                 print "<tr class=\"dark\">\n";
5772                         } else {
5773                                 print "<tr class=\"light\">\n";
5774                         }
5775                         $alternate ^= 1;
5776                         %co = parse_commit($set{'commit'});
5777                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
5778                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5779                               "<td><i>$author</i></td>\n" .
5780                               "<td>" .
5781                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5782                                       -class => "list subject"},
5783                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
5784                 } elsif (defined $set{'to_id'}) {
5785                         next if ($set{'to_id'} =~ m/^0{40}$/);
5786
5787                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
5788                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
5789                                       -class => "list"},
5790                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
5791                               "<br/>\n";
5792                 }
5793         }
5794         close $fd;
5795
5796         # finish last commit (warning: repetition!)
5797         if (%co) {
5798                 print "</td>\n" .
5799                       "<td class=\"link\">" .
5800                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5801                               "commit") .
5802                       " | " .
5803                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5804                                              hash_base=>$co{'id'})},
5805                               "tree") .
5806                       "</td>\n" .
5807                       "</tr>\n";
5808         }
5809
5810         print "</table>\n";
5811
5812         git_footer_html();
5813 }
5814
5815 sub git_search_files {
5816         my %co = @_;
5817
5818         local $/ = "\n";
5819         open my $fd, "-|", git_cmd(), 'grep', '-n',
5820                 $search_use_regexp ? ('-E', '-i') : '-F',
5821                 $searchtext, $co{'tree'}
5822                         or die_error(500, "Open git-grep failed");
5823
5824         git_header_html();
5825
5826         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5827         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5828
5829         print "<table class=\"grep_search\">\n";
5830         my $alternate = 1;
5831         my $matches = 0;
5832         my $lastfile = '';
5833         while (my $line = <$fd>) {
5834                 chomp $line;
5835                 my ($file, $lno, $ltext, $binary);
5836                 last if ($matches++ > 1000);
5837                 if ($line =~ /^Binary file (.+) matches$/) {
5838                         $file = $1;
5839                         $binary = 1;
5840                 } else {
5841                         (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
5842                 }
5843                 if ($file ne $lastfile) {
5844                         $lastfile and print "</td></tr>\n";
5845                         if ($alternate++) {
5846                                 print "<tr class=\"dark\">\n";
5847                         } else {
5848                                 print "<tr class=\"light\">\n";
5849                         }
5850                         print "<td class=\"list\">".
5851                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5852                                                        file_name=>"$file"),
5853                                         -class => "list"}, esc_path($file));
5854                         print "</td><td>\n";
5855                         $lastfile = $file;
5856                 }
5857                 if ($binary) {
5858                         print "<div class=\"binary\">Binary file</div>\n";
5859                 } else {
5860                         $ltext = untabify($ltext);
5861                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
5862                                 $ltext = esc_html($1, -nbsp=>1);
5863                                 $ltext .= '<span class="match">';
5864                                 $ltext .= esc_html($2, -nbsp=>1);
5865                                 $ltext .= '</span>';
5866                                 $ltext .= esc_html($3, -nbsp=>1);
5867                         } else {
5868                                 $ltext = esc_html($ltext, -nbsp=>1);
5869                         }
5870                         print "<div class=\"pre\">" .
5871                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5872                                                        file_name=>"$file").'#l'.$lno,
5873                                         -class => "linenr"}, sprintf('%4i', $lno))
5874                                 . ' ' .  $ltext . "</div>\n";
5875                 }
5876         }
5877         if ($lastfile) {
5878                 print "</td></tr>\n";
5879                 if ($matches > 1000) {
5880                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
5881                 }
5882         } else {
5883                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
5884         }
5885         close $fd;
5886
5887         print "</table>\n";
5888
5889         git_footer_html();
5890 }
5891
5892 sub git_search_grep_body {
5893         my ($commitlist, $from, $to, $extra) = @_;
5894         $from = 0 unless defined $from;
5895         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5896
5897         print "<table class=\"commit_search\">\n";
5898         my $alternate = 1;
5899         for (my $i = $from; $i <= $to; $i++) {
5900                 my %co = %{$commitlist->[$i]};
5901                 if (!%co) {
5902                         next;
5903                 }
5904                 my $commit = $co{'id'};
5905                 if ($alternate) {
5906                         print "<tr class=\"dark\">\n";
5907                 } else {
5908                         print "<tr class=\"light\">\n";
5909                 }
5910                 $alternate ^= 1;
5911                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5912                       format_author_html('td', \%co, 15, 5) .
5913                       "<td>" .
5914                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5915                                -class => "list subject"},
5916                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5917                 my $comment = $co{'comment'};
5918                 foreach my $line (@$comment) {
5919                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5920                                 my ($lead, $match, $trail) = ($1, $2, $3);
5921                                 $match = chop_str($match, 70, 5, 'center');
5922                                 my $contextlen = int((80 - length($match))/2);
5923                                 $contextlen = 30 if ($contextlen > 30);
5924                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5925                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5926
5927                                 $lead  = esc_html($lead);
5928                                 $match = esc_html($match);
5929                                 $trail = esc_html($trail);
5930
5931                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5932                         }
5933                 }
5934                 print "</td>\n" .
5935                       "<td class=\"link\">" .
5936                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5937                       " | " .
5938                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5939                       " | " .
5940                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5941                 print "</td>\n" .
5942                       "</tr>\n";
5943         }
5944         if (defined $extra) {
5945                 print "<tr>\n" .
5946                       "<td colspan=\"3\">$extra</td>\n" .
5947                       "</tr>\n";
5948         }
5949         print "</table>\n";
5950 }
5951
5952 ## ======================================================================
5953 ## ======================================================================
5954 ## actions
5955
5956 sub git_project_list {
5957         my $order = $input_params{'order'};
5958         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5959                 die_error(400, "Unknown order parameter");
5960         }
5961
5962         my @list = git_get_projects_list();
5963         if (!@list) {
5964                 die_error(404, "No projects found");
5965         }
5966
5967         git_header_html();
5968         if (defined $home_text && -f $home_text) {
5969                 print "<div class=\"index_include\">\n";
5970                 insert_file($home_text);
5971                 print "</div>\n";
5972         }
5973         print $cgi->startform(-method => "get") .
5974               "<p class=\"projsearch\">Search:\n" .
5975               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5976               "</p>" .
5977               $cgi->end_form() . "\n";
5978         git_project_list_body(\@list, $order);
5979         git_footer_html();
5980 }
5981
5982 sub git_forks {
5983         my $order = $input_params{'order'};
5984         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5985                 die_error(400, "Unknown order parameter");
5986         }
5987
5988         my @list = git_get_projects_list($project);
5989         if (!@list) {
5990                 die_error(404, "No forks found");
5991         }
5992
5993         git_header_html();
5994         git_print_page_nav('','');
5995         git_print_header_div('summary', "$project forks");
5996         git_project_list_body(\@list, $order);
5997         git_footer_html();
5998 }
5999
6000 sub git_project_index {
6001         my @projects = git_get_projects_list();
6002         if (!@projects) {
6003                 die_error(404, "No projects found");
6004         }
6005
6006         print $cgi->header(
6007                 -type => 'text/plain',
6008                 -charset => 'utf-8',
6009                 -content_disposition => 'inline; filename="index.aux"');
6010
6011         foreach my $pr (@projects) {
6012                 if (!exists $pr->{'owner'}) {
6013                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6014                 }
6015
6016                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6017                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6018                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6019                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6020                 $path  =~ s/ /\+/g;
6021                 $owner =~ s/ /\+/g;
6022
6023                 print "$path $owner\n";
6024         }
6025 }
6026
6027 sub git_summary {
6028         my $descr = git_get_project_description($project) || "none";
6029         my %co = parse_commit("HEAD");
6030         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6031         my $head = $co{'id'};
6032         my $remote_heads = gitweb_check_feature('remote_heads');
6033
6034         my $owner = git_get_project_owner($project);
6035
6036         my $refs = git_get_references();
6037         # These get_*_list functions return one more to allow us to see if
6038         # there are more ...
6039         my @taglist  = git_get_tags_list(16);
6040         my @headlist = git_get_heads_list(16);
6041         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6042         my @forklist;
6043         my $check_forks = gitweb_check_feature('forks');
6044
6045         if ($check_forks) {
6046                 # find forks of a project
6047                 @forklist = git_get_projects_list($project);
6048                 # filter out forks of forks
6049                 @forklist = filter_forks_from_projects_list(\@forklist)
6050                         if (@forklist);
6051         }
6052
6053         git_header_html();
6054         git_print_page_nav('summary','', $head);
6055
6056         print "<div class=\"title\">&nbsp;</div>\n";
6057         print "<table class=\"projects_list\">\n" .
6058               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
6059               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6060         if (defined $cd{'rfc2822'}) {
6061                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6062                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6063         }
6064
6065         # use per project git URL list in $projectroot/$project/cloneurl
6066         # or make project git URL from git base URL and project name
6067         my $url_tag = "URL";
6068         my @url_list = git_get_project_url_list($project);
6069         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6070         foreach my $git_url (@url_list) {
6071                 next unless $git_url;
6072                 print format_repo_url($url_tag, $git_url);
6073                 $url_tag = "";
6074         }
6075
6076         # Tag cloud
6077         my $show_ctags = gitweb_check_feature('ctags');
6078         if ($show_ctags) {
6079                 my $ctags = git_get_project_ctags($project);
6080                 if (%$ctags) {
6081                         # without ability to add tags, don't show if there are none
6082                         my $cloud = git_populate_project_tagcloud($ctags);
6083                         print "<tr id=\"metadata_ctags\">" .
6084                               "<td>content tags</td>" .
6085                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6086                               "</tr>\n";
6087                 }
6088         }
6089
6090         print "</table>\n";
6091
6092         # If XSS prevention is on, we don't include README.html.
6093         # TODO: Allow a readme in some safe format.
6094         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6095                 print "<div class=\"title\">readme</div>\n" .
6096                       "<div class=\"readme\">\n";
6097                 insert_file("$projectroot/$project/README.html");
6098                 print "\n</div>\n"; # class="readme"
6099         }
6100
6101         # we need to request one more than 16 (0..15) to check if
6102         # those 16 are all
6103         my @commitlist = $head ? parse_commits($head, 17) : ();
6104         if (@commitlist) {
6105                 git_print_header_div('shortlog');
6106                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6107                                   $#commitlist <=  15 ? undef :
6108                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6109         }
6110
6111         if (@taglist) {
6112                 git_print_header_div('tags');
6113                 git_tags_body(\@taglist, 0, 15,
6114                               $#taglist <=  15 ? undef :
6115                               $cgi->a({-href => href(action=>"tags")}, "..."));
6116         }
6117
6118         if (@headlist) {
6119                 git_print_header_div('heads');
6120                 git_heads_body(\@headlist, $head, 0, 15,
6121                                $#headlist <= 15 ? undef :
6122                                $cgi->a({-href => href(action=>"heads")}, "..."));
6123         }
6124
6125         if (%remotedata) {
6126                 git_print_header_div('remotes');
6127                 git_remotes_body(\%remotedata, 15, $head);
6128         }
6129
6130         if (@forklist) {
6131                 git_print_header_div('forks');
6132                 git_project_list_body(\@forklist, 'age', 0, 15,
6133                                       $#forklist <= 15 ? undef :
6134                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6135                                       'no_header');
6136         }
6137
6138         git_footer_html();
6139 }
6140
6141 sub git_tag {
6142         my %tag = parse_tag($hash);
6143
6144         if (! %tag) {
6145                 die_error(404, "Unknown tag object");
6146         }
6147
6148         my $head = git_get_head_hash($project);
6149         git_header_html();
6150         git_print_page_nav('','', $head,undef,$head);
6151         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6152         print "<div class=\"title_text\">\n" .
6153               "<table class=\"object_header\">\n" .
6154               "<tr>\n" .
6155               "<td>object</td>\n" .
6156               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6157                                $tag{'object'}) . "</td>\n" .
6158               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6159                                               $tag{'type'}) . "</td>\n" .
6160               "</tr>\n";
6161         if (defined($tag{'author'})) {
6162                 git_print_authorship_rows(\%tag, 'author');
6163         }
6164         print "</table>\n\n" .
6165               "</div>\n";
6166         print "<div class=\"page_body\">";
6167         my $comment = $tag{'comment'};
6168         foreach my $line (@$comment) {
6169                 chomp $line;
6170                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6171         }
6172         print "</div>\n";
6173         git_footer_html();
6174 }
6175
6176 sub git_blame_common {
6177         my $format = shift || 'porcelain';
6178         if ($format eq 'porcelain' && $cgi->param('js')) {
6179                 $format = 'incremental';
6180                 $action = 'blame_incremental'; # for page title etc
6181         }
6182
6183         # permissions
6184         gitweb_check_feature('blame')
6185                 or die_error(403, "Blame view not allowed");
6186
6187         # error checking
6188         die_error(400, "No file name given") unless $file_name;
6189         $hash_base ||= git_get_head_hash($project);
6190         die_error(404, "Couldn't find base commit") unless $hash_base;
6191         my %co = parse_commit($hash_base)
6192                 or die_error(404, "Commit not found");
6193         my $ftype = "blob";
6194         if (!defined $hash) {
6195                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6196                         or die_error(404, "Error looking up file");
6197         } else {
6198                 $ftype = git_get_type($hash);
6199                 if ($ftype !~ "blob") {
6200                         die_error(400, "Object is not a blob");
6201                 }
6202         }
6203
6204         my $fd;
6205         if ($format eq 'incremental') {
6206                 # get file contents (as base)
6207                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6208                         or die_error(500, "Open git-cat-file failed");
6209         } elsif ($format eq 'data') {
6210                 # run git-blame --incremental
6211                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6212                         $hash_base, "--", $file_name
6213                         or die_error(500, "Open git-blame --incremental failed");
6214         } else {
6215                 # run git-blame --porcelain
6216                 open $fd, "-|", git_cmd(), "blame", '-p',
6217                         $hash_base, '--', $file_name
6218                         or die_error(500, "Open git-blame --porcelain failed");
6219         }
6220
6221         # incremental blame data returns early
6222         if ($format eq 'data') {
6223                 print $cgi->header(
6224                         -type=>"text/plain", -charset => "utf-8",
6225                         -status=> "200 OK");
6226                 local $| = 1; # output autoflush
6227                 print while <$fd>;
6228                 close $fd
6229                         or print "ERROR $!\n";
6230
6231                 print 'END';
6232                 if (defined $t0 && gitweb_check_feature('timed')) {
6233                         print ' '.
6234                               tv_interval($t0, [ gettimeofday() ]).
6235                               ' '.$number_of_git_cmds;
6236                 }
6237                 print "\n";
6238
6239                 return;
6240         }
6241
6242         # page header
6243         git_header_html();
6244         my $formats_nav =
6245                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6246                         "blob") .
6247                 " | ";
6248         if ($format eq 'incremental') {
6249                 $formats_nav .=
6250                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6251                                 "blame") . " (non-incremental)";
6252         } else {
6253                 $formats_nav .=
6254                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6255                                 "blame") . " (incremental)";
6256         }
6257         $formats_nav .=
6258                 " | " .
6259                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6260                         "history") .
6261                 " | " .
6262                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6263                         "HEAD");
6264         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6265         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6266         git_print_page_path($file_name, $ftype, $hash_base);
6267
6268         # page body
6269         if ($format eq 'incremental') {
6270                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6271                       "This page requires JavaScript to run.\n Use ".
6272                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6273                               'this page').
6274                       " instead.\n".
6275                       "</b></center></div>\n</noscript>\n";
6276
6277                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6278         }
6279
6280         print qq!<div class="page_body">\n!;
6281         print qq!<div id="progress_info">... / ...</div>\n!
6282                 if ($format eq 'incremental');
6283         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6284               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6285               qq!<thead>\n!.
6286               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6287               qq!</thead>\n!.
6288               qq!<tbody>\n!;
6289
6290         my @rev_color = qw(light dark);
6291         my $num_colors = scalar(@rev_color);
6292         my $current_color = 0;
6293
6294         if ($format eq 'incremental') {
6295                 my $color_class = $rev_color[$current_color];
6296
6297                 #contents of a file
6298                 my $linenr = 0;
6299         LINE:
6300                 while (my $line = <$fd>) {
6301                         chomp $line;
6302                         $linenr++;
6303
6304                         print qq!<tr id="l$linenr" class="$color_class">!.
6305                               qq!<td class="sha1"><a href=""> </a></td>!.
6306                               qq!<td class="linenr">!.
6307                               qq!<a class="linenr" href="">$linenr</a></td>!;
6308                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6309                         print qq!</tr>\n!;
6310                 }
6311
6312         } else { # porcelain, i.e. ordinary blame
6313                 my %metainfo = (); # saves information about commits
6314
6315                 # blame data
6316         LINE:
6317                 while (my $line = <$fd>) {
6318                         chomp $line;
6319                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6320                         # no <lines in group> for subsequent lines in group of lines
6321                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6322                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6323                         if (!exists $metainfo{$full_rev}) {
6324                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6325                         }
6326                         my $meta = $metainfo{$full_rev};
6327                         my $data;
6328                         while ($data = <$fd>) {
6329                                 chomp $data;
6330                                 last if ($data =~ s/^\t//); # contents of line
6331                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6332                                         $meta->{$1} = $2 unless exists $meta->{$1};
6333                                 }
6334                                 if ($data =~ /^previous /) {
6335                                         $meta->{'nprevious'}++;
6336                                 }
6337                         }
6338                         my $short_rev = substr($full_rev, 0, 8);
6339                         my $author = $meta->{'author'};
6340                         my %date =
6341                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6342                         my $date = $date{'iso-tz'};
6343                         if ($group_size) {
6344                                 $current_color = ($current_color + 1) % $num_colors;
6345                         }
6346                         my $tr_class = $rev_color[$current_color];
6347                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6348                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6349                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6350                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6351                         if ($group_size) {
6352                                 print "<td class=\"sha1\"";
6353                                 print " title=\"". esc_html($author) . ", $date\"";
6354                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6355                                 print ">";
6356                                 print $cgi->a({-href => href(action=>"commit",
6357                                                              hash=>$full_rev,
6358                                                              file_name=>$file_name)},
6359                                               esc_html($short_rev));
6360                                 if ($group_size >= 2) {
6361                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6362                                         if (@author_initials) {
6363                                                 print "<br />" .
6364                                                       esc_html(join('', @author_initials));
6365                                                 #           or join('.', ...)
6366                                         }
6367                                 }
6368                                 print "</td>\n";
6369                         }
6370                         # 'previous' <sha1 of parent commit> <filename at commit>
6371                         if (exists $meta->{'previous'} &&
6372                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6373                                 $meta->{'parent'} = $1;
6374                                 $meta->{'file_parent'} = unquote($2);
6375                         }
6376                         my $linenr_commit =
6377                                 exists($meta->{'parent'}) ?
6378                                 $meta->{'parent'} : $full_rev;
6379                         my $linenr_filename =
6380                                 exists($meta->{'file_parent'}) ?
6381                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6382                         my $blamed = href(action => 'blame',
6383                                           file_name => $linenr_filename,
6384                                           hash_base => $linenr_commit);
6385                         print "<td class=\"linenr\">";
6386                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6387                                         -class => "linenr" },
6388                                       esc_html($lineno));
6389                         print "</td>";
6390                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6391                         print "</tr>\n";
6392                 } # end while
6393
6394         }
6395
6396         # footer
6397         print "</tbody>\n".
6398               "</table>\n"; # class="blame"
6399         print "</div>\n";   # class="blame_body"
6400         close $fd
6401                 or print "Reading blob failed\n";
6402
6403         git_footer_html();
6404 }
6405
6406 sub git_blame {
6407         git_blame_common();
6408 }
6409
6410 sub git_blame_incremental {
6411         git_blame_common('incremental');
6412 }
6413
6414 sub git_blame_data {
6415         git_blame_common('data');
6416 }
6417
6418 sub git_tags {
6419         my $head = git_get_head_hash($project);
6420         git_header_html();
6421         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6422         git_print_header_div('summary', $project);
6423
6424         my @tagslist = git_get_tags_list();
6425         if (@tagslist) {
6426                 git_tags_body(\@tagslist);
6427         }
6428         git_footer_html();
6429 }
6430
6431 sub git_heads {
6432         my $head = git_get_head_hash($project);
6433         git_header_html();
6434         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6435         git_print_header_div('summary', $project);
6436
6437         my @headslist = git_get_heads_list();
6438         if (@headslist) {
6439                 git_heads_body(\@headslist, $head);
6440         }
6441         git_footer_html();
6442 }
6443
6444 # used both for single remote view and for list of all the remotes
6445 sub git_remotes {
6446         gitweb_check_feature('remote_heads')
6447                 or die_error(403, "Remote heads view is disabled");
6448
6449         my $head = git_get_head_hash($project);
6450         my $remote = $input_params{'hash'};
6451
6452         my $remotedata = git_get_remotes_list($remote);
6453         die_error(500, "Unable to get remote information") unless defined $remotedata;
6454
6455         unless (%$remotedata) {
6456                 die_error(404, defined $remote ?
6457                         "Remote $remote not found" :
6458                         "No remotes found");
6459         }
6460
6461         git_header_html(undef, undef, -action_extra => $remote);
6462         git_print_page_nav('', '',  $head, undef, $head,
6463                 format_ref_views($remote ? '' : 'remotes'));
6464
6465         fill_remote_heads($remotedata);
6466         if (defined $remote) {
6467                 git_print_header_div('remotes', "$remote remote for $project");
6468                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6469         } else {
6470                 git_print_header_div('summary', "$project remotes");
6471                 git_remotes_body($remotedata, undef, $head);
6472         }
6473
6474         git_footer_html();
6475 }
6476
6477 sub git_blob_plain {
6478         my $type = shift;
6479         my $expires;
6480
6481         if (!defined $hash) {
6482                 if (defined $file_name) {
6483                         my $base = $hash_base || git_get_head_hash($project);
6484                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6485                                 or die_error(404, "Cannot find file");
6486                 } else {
6487                         die_error(400, "No file name defined");
6488                 }
6489         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6490                 # blobs defined by non-textual hash id's can be cached
6491                 $expires = "+1d";
6492         }
6493
6494         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6495                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6496
6497         # content-type (can include charset)
6498         $type = blob_contenttype($fd, $file_name, $type);
6499
6500         # "save as" filename, even when no $file_name is given
6501         my $save_as = "$hash";
6502         if (defined $file_name) {
6503                 $save_as = $file_name;
6504         } elsif ($type =~ m/^text\//) {
6505                 $save_as .= '.txt';
6506         }
6507
6508         # With XSS prevention on, blobs of all types except a few known safe
6509         # ones are served with "Content-Disposition: attachment" to make sure
6510         # they don't run in our security domain.  For certain image types,
6511         # blob view writes an <img> tag referring to blob_plain view, and we
6512         # want to be sure not to break that by serving the image as an
6513         # attachment (though Firefox 3 doesn't seem to care).
6514         my $sandbox = $prevent_xss &&
6515                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6516
6517         # serve text/* as text/plain
6518         if ($prevent_xss &&
6519             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6520              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6521                 my $rest = $1;
6522                 $rest = defined $rest ? $rest : '';
6523                 $type = "text/plain$rest";
6524         }
6525
6526         print $cgi->header(
6527                 -type => $type,
6528                 -expires => $expires,
6529                 -content_disposition =>
6530                         ($sandbox ? 'attachment' : 'inline')
6531                         . '; filename="' . $save_as . '"');
6532         local $/ = undef;
6533         binmode STDOUT, ':raw';
6534         print <$fd>;
6535         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6536         close $fd;
6537 }
6538
6539 sub git_blob {
6540         my $expires;
6541
6542         if (!defined $hash) {
6543                 if (defined $file_name) {
6544                         my $base = $hash_base || git_get_head_hash($project);
6545                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6546                                 or die_error(404, "Cannot find file");
6547                 } else {
6548                         die_error(400, "No file name defined");
6549                 }
6550         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6551                 # blobs defined by non-textual hash id's can be cached
6552                 $expires = "+1d";
6553         }
6554
6555         my $have_blame = gitweb_check_feature('blame');
6556         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6557                 or die_error(500, "Couldn't cat $file_name, $hash");
6558         my $mimetype = blob_mimetype($fd, $file_name);
6559         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6560         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6561                 close $fd;
6562                 return git_blob_plain($mimetype);
6563         }
6564         # we can have blame only for text/* mimetype
6565         $have_blame &&= ($mimetype =~ m!^text/!);
6566
6567         my $highlight = gitweb_check_feature('highlight');
6568         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6569         $fd = run_highlighter($fd, $highlight, $syntax)
6570                 if $syntax;
6571
6572         git_header_html(undef, $expires);
6573         my $formats_nav = '';
6574         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6575                 if (defined $file_name) {
6576                         if ($have_blame) {
6577                                 $formats_nav .=
6578                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6579                                                 "blame") .
6580                                         " | ";
6581                         }
6582                         $formats_nav .=
6583                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6584                                         "history") .
6585                                 " | " .
6586                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6587                                         "raw") .
6588                                 " | " .
6589                                 $cgi->a({-href => href(action=>"blob",
6590                                                        hash_base=>"HEAD", file_name=>$file_name)},
6591                                         "HEAD");
6592                 } else {
6593                         $formats_nav .=
6594                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6595                                         "raw");
6596                 }
6597                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6598                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6599         } else {
6600                 print "<div class=\"page_nav\">\n" .
6601                       "<br/><br/></div>\n" .
6602                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6603         }
6604         git_print_page_path($file_name, "blob", $hash_base);
6605         print "<div class=\"page_body\">\n";
6606         if ($mimetype =~ m!^image/!) {
6607                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6608                 if ($file_name) {
6609                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6610                 }
6611                 print qq! src="! .
6612                       href(action=>"blob_plain", hash=>$hash,
6613                            hash_base=>$hash_base, file_name=>$file_name) .
6614                       qq!" />\n!;
6615         } else {
6616                 my $nr;
6617                 while (my $line = <$fd>) {
6618                         chomp $line;
6619                         $nr++;
6620                         $line = untabify($line);
6621                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6622                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6623                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6624                 }
6625         }
6626         close $fd
6627                 or print "Reading blob failed.\n";
6628         print "</div>";
6629         git_footer_html();
6630 }
6631
6632 sub git_tree {
6633         if (!defined $hash_base) {
6634                 $hash_base = "HEAD";
6635         }
6636         if (!defined $hash) {
6637                 if (defined $file_name) {
6638                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6639                 } else {
6640                         $hash = $hash_base;
6641                 }
6642         }
6643         die_error(404, "No such tree") unless defined($hash);
6644
6645         my $show_sizes = gitweb_check_feature('show-sizes');
6646         my $have_blame = gitweb_check_feature('blame');
6647
6648         my @entries = ();
6649         {
6650                 local $/ = "\0";
6651                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6652                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6653                         or die_error(500, "Open git-ls-tree failed");
6654                 @entries = map { chomp; $_ } <$fd>;
6655                 close $fd
6656                         or die_error(404, "Reading tree failed");
6657         }
6658
6659         my $refs = git_get_references();
6660         my $ref = format_ref_marker($refs, $hash_base);
6661         git_header_html();
6662         my $basedir = '';
6663         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6664                 my @views_nav = ();
6665                 if (defined $file_name) {
6666                         push @views_nav,
6667                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6668                                         "history"),
6669                                 $cgi->a({-href => href(action=>"tree",
6670                                                        hash_base=>"HEAD", file_name=>$file_name)},
6671                                         "HEAD"),
6672                 }
6673                 my $snapshot_links = format_snapshot_links($hash);
6674                 if (defined $snapshot_links) {
6675                         # FIXME: Should be available when we have no hash base as well.
6676                         push @views_nav, $snapshot_links;
6677                 }
6678                 git_print_page_nav('tree','', $hash_base, undef, undef,
6679                                    join(' | ', @views_nav));
6680                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6681         } else {
6682                 undef $hash_base;
6683                 print "<div class=\"page_nav\">\n";
6684                 print "<br/><br/></div>\n";
6685                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6686         }
6687         if (defined $file_name) {
6688                 $basedir = $file_name;
6689                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6690                         $basedir .= '/';
6691                 }
6692                 git_print_page_path($file_name, 'tree', $hash_base);
6693         }
6694         print "<div class=\"page_body\">\n";
6695         print "<table class=\"tree\">\n";
6696         my $alternate = 1;
6697         # '..' (top directory) link if possible
6698         if (defined $hash_base &&
6699             defined $file_name && $file_name =~ m![^/]+$!) {
6700                 if ($alternate) {
6701                         print "<tr class=\"dark\">\n";
6702                 } else {
6703                         print "<tr class=\"light\">\n";
6704                 }
6705                 $alternate ^= 1;
6706
6707                 my $up = $file_name;
6708                 $up =~ s!/?[^/]+$!!;
6709                 undef $up unless $up;
6710                 # based on git_print_tree_entry
6711                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6712                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6713                 print '<td class="list">';
6714                 print $cgi->a({-href => href(action=>"tree",
6715                                              hash_base=>$hash_base,
6716                                              file_name=>$up)},
6717                               "..");
6718                 print "</td>\n";
6719                 print "<td class=\"link\"></td>\n";
6720
6721                 print "</tr>\n";
6722         }
6723         foreach my $line (@entries) {
6724                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6725
6726                 if ($alternate) {
6727                         print "<tr class=\"dark\">\n";
6728                 } else {
6729                         print "<tr class=\"light\">\n";
6730                 }
6731                 $alternate ^= 1;
6732
6733                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6734
6735                 print "</tr>\n";
6736         }
6737         print "</table>\n" .
6738               "</div>";
6739         git_footer_html();
6740 }
6741
6742 sub snapshot_name {
6743         my ($project, $hash) = @_;
6744
6745         # path/to/project.git  -> project
6746         # path/to/project/.git -> project
6747         my $name = to_utf8($project);
6748         $name =~ s,([^/])/*\.git$,$1,;
6749         $name = basename($name);
6750         # sanitize name
6751         $name =~ s/[[:cntrl:]]/?/g;
6752
6753         my $ver = $hash;
6754         if ($hash =~ /^[0-9a-fA-F]+$/) {
6755                 # shorten SHA-1 hash
6756                 my $full_hash = git_get_full_hash($project, $hash);
6757                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6758                         $ver = git_get_short_hash($project, $hash);
6759                 }
6760         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6761                 # tags don't need shortened SHA-1 hash
6762                 $ver = $1;
6763         } else {
6764                 # branches and other need shortened SHA-1 hash
6765                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6766                         $ver = $1;
6767                 }
6768                 $ver .= '-' . git_get_short_hash($project, $hash);
6769         }
6770         # in case of hierarchical branch names
6771         $ver =~ s!/!.!g;
6772
6773         # name = project-version_string
6774         $name = "$name-$ver";
6775
6776         return wantarray ? ($name, $name) : $name;
6777 }
6778
6779 sub git_snapshot {
6780         my $format = $input_params{'snapshot_format'};
6781         if (!@snapshot_fmts) {
6782                 die_error(403, "Snapshots not allowed");
6783         }
6784         # default to first supported snapshot format
6785         $format ||= $snapshot_fmts[0];
6786         if ($format !~ m/^[a-z0-9]+$/) {
6787                 die_error(400, "Invalid snapshot format parameter");
6788         } elsif (!exists($known_snapshot_formats{$format})) {
6789                 die_error(400, "Unknown snapshot format");
6790         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6791                 die_error(403, "Snapshot format not allowed");
6792         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6793                 die_error(403, "Unsupported snapshot format");
6794         }
6795
6796         my $type = git_get_type("$hash^{}");
6797         if (!$type) {
6798                 die_error(404, 'Object does not exist');
6799         }  elsif ($type eq 'blob') {
6800                 die_error(400, 'Object is not a tree-ish');
6801         }
6802
6803         my ($name, $prefix) = snapshot_name($project, $hash);
6804         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6805         my $cmd = quote_command(
6806                 git_cmd(), 'archive',
6807                 "--format=$known_snapshot_formats{$format}{'format'}",
6808                 "--prefix=$prefix/", $hash);
6809         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6810                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6811         }
6812
6813         $filename =~ s/(["\\])/\\$1/g;
6814         print $cgi->header(
6815                 -type => $known_snapshot_formats{$format}{'type'},
6816                 -content_disposition => 'inline; filename="' . $filename . '"',
6817                 -status => '200 OK');
6818
6819         open my $fd, "-|", $cmd
6820                 or die_error(500, "Execute git-archive failed");
6821         binmode STDOUT, ':raw';
6822         print <$fd>;
6823         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6824         close $fd;
6825 }
6826
6827 sub git_log_generic {
6828         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
6829
6830         my $head = git_get_head_hash($project);
6831         if (!defined $base) {
6832                 $base = $head;
6833         }
6834         if (!defined $page) {
6835                 $page = 0;
6836         }
6837         my $refs = git_get_references();
6838
6839         my $commit_hash = $base;
6840         if (defined $parent) {
6841                 $commit_hash = "$parent..$base";
6842         }
6843         my @commitlist =
6844                 parse_commits($commit_hash, 101, (100 * $page),
6845                               defined $file_name ? ($file_name, "--full-history") : ());
6846
6847         my $ftype;
6848         if (!defined $file_hash && defined $file_name) {
6849                 # some commits could have deleted file in question,
6850                 # and not have it in tree, but one of them has to have it
6851                 for (my $i = 0; $i < @commitlist; $i++) {
6852                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
6853                         last if defined $file_hash;
6854                 }
6855         }
6856         if (defined $file_hash) {
6857                 $ftype = git_get_type($file_hash);
6858         }
6859         if (defined $file_name && !defined $ftype) {
6860                 die_error(500, "Unknown type of object");
6861         }
6862         my %co;
6863         if (defined $file_name) {
6864                 %co = parse_commit($base)
6865                         or die_error(404, "Unknown commit object");
6866         }
6867
6868
6869         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
6870         my $next_link = '';
6871         if ($#commitlist >= 100) {
6872                 $next_link =
6873                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6874                                  -accesskey => "n", -title => "Alt-n"}, "next");
6875         }
6876         my $patch_max = gitweb_get_feature('patches');
6877         if ($patch_max && !defined $file_name) {
6878                 if ($patch_max < 0 || @commitlist <= $patch_max) {
6879                         $paging_nav .= " &sdot; " .
6880                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
6881                                         "patches");
6882                 }
6883         }
6884
6885         git_header_html();
6886         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
6887         if (defined $file_name) {
6888                 git_print_header_div('commit', esc_html($co{'title'}), $base);
6889         } else {
6890                 git_print_header_div('summary', $project)
6891         }
6892         git_print_page_path($file_name, $ftype, $hash_base)
6893                 if (defined $file_name);
6894
6895         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
6896                      $file_name, $file_hash, $ftype);
6897
6898         git_footer_html();
6899 }
6900
6901 sub git_log {
6902         git_log_generic('log', \&git_log_body,
6903                         $hash, $hash_parent);
6904 }
6905
6906 sub git_commit {
6907         $hash ||= $hash_base || "HEAD";
6908         my %co = parse_commit($hash)
6909             or die_error(404, "Unknown commit object");
6910
6911         my $parent  = $co{'parent'};
6912         my $parents = $co{'parents'}; # listref
6913
6914         # we need to prepare $formats_nav before any parameter munging
6915         my $formats_nav;
6916         if (!defined $parent) {
6917                 # --root commitdiff
6918                 $formats_nav .= '(initial)';
6919         } elsif (@$parents == 1) {
6920                 # single parent commit
6921                 $formats_nav .=
6922                         '(parent: ' .
6923                         $cgi->a({-href => href(action=>"commit",
6924                                                hash=>$parent)},
6925                                 esc_html(substr($parent, 0, 7))) .
6926                         ')';
6927         } else {
6928                 # merge commit
6929                 $formats_nav .=
6930                         '(merge: ' .
6931                         join(' ', map {
6932                                 $cgi->a({-href => href(action=>"commit",
6933                                                        hash=>$_)},
6934                                         esc_html(substr($_, 0, 7)));
6935                         } @$parents ) .
6936                         ')';
6937         }
6938         if (gitweb_check_feature('patches') && @$parents <= 1) {
6939                 $formats_nav .= " | " .
6940                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6941                                 "patch");
6942         }
6943
6944         if (!defined $parent) {
6945                 $parent = "--root";
6946         }
6947         my @difftree;
6948         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6949                 @diff_opts,
6950                 (@$parents <= 1 ? $parent : '-c'),
6951                 $hash, "--"
6952                 or die_error(500, "Open git-diff-tree failed");
6953         @difftree = map { chomp; $_ } <$fd>;
6954         close $fd or die_error(404, "Reading git-diff-tree failed");
6955
6956         # non-textual hash id's can be cached
6957         my $expires;
6958         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6959                 $expires = "+1d";
6960         }
6961         my $refs = git_get_references();
6962         my $ref = format_ref_marker($refs, $co{'id'});
6963
6964         git_header_html(undef, $expires);
6965         git_print_page_nav('commit', '',
6966                            $hash, $co{'tree'}, $hash,
6967                            $formats_nav);
6968
6969         if (defined $co{'parent'}) {
6970                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
6971         } else {
6972                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
6973         }
6974         print "<div class=\"title_text\">\n" .
6975               "<table class=\"object_header\">\n";
6976         git_print_authorship_rows(\%co);
6977         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6978         print "<tr>" .
6979               "<td>tree</td>" .
6980               "<td class=\"sha1\">" .
6981               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
6982                        class => "list"}, $co{'tree'}) .
6983               "</td>" .
6984               "<td class=\"link\">" .
6985               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
6986                       "tree");
6987         my $snapshot_links = format_snapshot_links($hash);
6988         if (defined $snapshot_links) {
6989                 print " | " . $snapshot_links;
6990         }
6991         print "</td>" .
6992               "</tr>\n";
6993
6994         foreach my $par (@$parents) {
6995                 print "<tr>" .
6996                       "<td>parent</td>" .
6997                       "<td class=\"sha1\">" .
6998                       $cgi->a({-href => href(action=>"commit", hash=>$par),
6999                                class => "list"}, $par) .
7000                       "</td>" .
7001                       "<td class=\"link\">" .
7002                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7003                       " | " .
7004                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7005                       "</td>" .
7006                       "</tr>\n";
7007         }
7008         print "</table>".
7009               "</div>\n";
7010
7011         print "<div class=\"page_body\">\n";
7012         git_print_log($co{'comment'});
7013         print "</div>\n";
7014
7015         git_difftree_body(\@difftree, $hash, @$parents);
7016
7017         git_footer_html();
7018 }
7019
7020 sub git_object {
7021         # object is defined by:
7022         # - hash or hash_base alone
7023         # - hash_base and file_name
7024         my $type;
7025
7026         # - hash or hash_base alone
7027         if ($hash || ($hash_base && !defined $file_name)) {
7028                 my $object_id = $hash || $hash_base;
7029
7030                 open my $fd, "-|", quote_command(
7031                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7032                         or die_error(404, "Object does not exist");
7033                 $type = <$fd>;
7034                 chomp $type;
7035                 close $fd
7036                         or die_error(404, "Object does not exist");
7037
7038         # - hash_base and file_name
7039         } elsif ($hash_base && defined $file_name) {
7040                 $file_name =~ s,/+$,,;
7041
7042                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7043                         or die_error(404, "Base object does not exist");
7044
7045                 # here errors should not hapen
7046                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7047                         or die_error(500, "Open git-ls-tree failed");
7048                 my $line = <$fd>;
7049                 close $fd;
7050
7051                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7052                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7053                         die_error(404, "File or directory for given base does not exist");
7054                 }
7055                 $type = $2;
7056                 $hash = $3;
7057         } else {
7058                 die_error(400, "Not enough information to find object");
7059         }
7060
7061         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7062                                           hash=>$hash, hash_base=>$hash_base,
7063                                           file_name=>$file_name),
7064                              -status => '302 Found');
7065 }
7066
7067 sub git_blobdiff {
7068         my $format = shift || 'html';
7069         my $diff_style = $input_params{'diff_style'} || 'inline';
7070
7071         my $fd;
7072         my @difftree;
7073         my %diffinfo;
7074         my $expires;
7075
7076         # preparing $fd and %diffinfo for git_patchset_body
7077         # new style URI
7078         if (defined $hash_base && defined $hash_parent_base) {
7079                 if (defined $file_name) {
7080                         # read raw output
7081                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7082                                 $hash_parent_base, $hash_base,
7083                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7084                                 or die_error(500, "Open git-diff-tree failed");
7085                         @difftree = map { chomp; $_ } <$fd>;
7086                         close $fd
7087                                 or die_error(404, "Reading git-diff-tree failed");
7088                         @difftree
7089                                 or die_error(404, "Blob diff not found");
7090
7091                 } elsif (defined $hash &&
7092                          $hash =~ /[0-9a-fA-F]{40}/) {
7093                         # try to find filename from $hash
7094
7095                         # read filtered raw output
7096                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7097                                 $hash_parent_base, $hash_base, "--"
7098                                 or die_error(500, "Open git-diff-tree failed");
7099                         @difftree =
7100                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7101                                 # $hash == to_id
7102                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7103                                 map { chomp; $_ } <$fd>;
7104                         close $fd
7105                                 or die_error(404, "Reading git-diff-tree failed");
7106                         @difftree
7107                                 or die_error(404, "Blob diff not found");
7108
7109                 } else {
7110                         die_error(400, "Missing one of the blob diff parameters");
7111                 }
7112
7113                 if (@difftree > 1) {
7114                         die_error(400, "Ambiguous blob diff specification");
7115                 }
7116
7117                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7118                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7119                 $file_name   ||= $diffinfo{'to_file'};
7120
7121                 $hash_parent ||= $diffinfo{'from_id'};
7122                 $hash        ||= $diffinfo{'to_id'};
7123
7124                 # non-textual hash id's can be cached
7125                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7126                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7127                         $expires = '+1d';
7128                 }
7129
7130                 # open patch output
7131                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7132                         '-p', ($format eq 'html' ? "--full-index" : ()),
7133                         $hash_parent_base, $hash_base,
7134                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7135                         or die_error(500, "Open git-diff-tree failed");
7136         }
7137
7138         # old/legacy style URI -- not generated anymore since 1.4.3.
7139         if (!%diffinfo) {
7140                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7141         }
7142
7143         # header
7144         if ($format eq 'html') {
7145                 my $formats_nav =
7146                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7147                                 "raw");
7148                 git_header_html(undef, $expires);
7149                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7150                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7151                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7152                 } else {
7153                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7154                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7155                 }
7156                 if (defined $file_name) {
7157                         git_print_page_path($file_name, "blob", $hash_base);
7158                 } else {
7159                         print "<div class=\"page_path\"></div>\n";
7160                 }
7161
7162         } elsif ($format eq 'plain') {
7163                 print $cgi->header(
7164                         -type => 'text/plain',
7165                         -charset => 'utf-8',
7166                         -expires => $expires,
7167                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7168
7169                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7170
7171         } else {
7172                 die_error(400, "Unknown blobdiff format");
7173         }
7174
7175         # patch
7176         if ($format eq 'html') {
7177                 print "<div class=\"page_body\">\n";
7178
7179                 git_patchset_body($fd, $diff_style,
7180                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7181                 close $fd;
7182
7183                 print "</div>\n"; # class="page_body"
7184                 git_footer_html();
7185
7186         } else {
7187                 while (my $line = <$fd>) {
7188                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7189                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7190
7191                         print $line;
7192
7193                         last if $line =~ m!^\+\+\+!;
7194                 }
7195                 local $/ = undef;
7196                 print <$fd>;
7197                 close $fd;
7198         }
7199 }
7200
7201 sub git_blobdiff_plain {
7202         git_blobdiff('plain');
7203 }
7204
7205 sub git_commitdiff {
7206         my %params = @_;
7207         my $format = $params{-format} || 'html';
7208         my $diff_style = $input_params{'diff_style'} || 'inline';
7209
7210         my ($patch_max) = gitweb_get_feature('patches');
7211         if ($format eq 'patch') {
7212                 die_error(403, "Patch view not allowed") unless $patch_max;
7213         }
7214
7215         $hash ||= $hash_base || "HEAD";
7216         my %co = parse_commit($hash)
7217             or die_error(404, "Unknown commit object");
7218
7219         # choose format for commitdiff for merge
7220         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7221                 $hash_parent = '--cc';
7222         }
7223         # we need to prepare $formats_nav before almost any parameter munging
7224         my $formats_nav;
7225         if ($format eq 'html') {
7226                 $formats_nav =
7227                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7228                                 "raw");
7229                 if ($patch_max && @{$co{'parents'}} <= 1) {
7230                         $formats_nav .= " | " .
7231                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7232                                         "patch");
7233                 }
7234
7235                 if (defined $hash_parent &&
7236                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7237                         # commitdiff with two commits given
7238                         my $hash_parent_short = $hash_parent;
7239                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7240                                 $hash_parent_short = substr($hash_parent, 0, 7);
7241                         }
7242                         $formats_nav .=
7243                                 ' (from';
7244                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7245                                 if ($co{'parents'}[$i] eq $hash_parent) {
7246                                         $formats_nav .= ' parent ' . ($i+1);
7247                                         last;
7248                                 }
7249                         }
7250                         $formats_nav .= ': ' .
7251                                 $cgi->a({-href => href(action=>"commitdiff",
7252                                                        hash=>$hash_parent)},
7253                                         esc_html($hash_parent_short)) .
7254                                 ')';
7255                 } elsif (!$co{'parent'}) {
7256                         # --root commitdiff
7257                         $formats_nav .= ' (initial)';
7258                 } elsif (scalar @{$co{'parents'}} == 1) {
7259                         # single parent commit
7260                         $formats_nav .=
7261                                 ' (parent: ' .
7262                                 $cgi->a({-href => href(action=>"commitdiff",
7263                                                        hash=>$co{'parent'})},
7264                                         esc_html(substr($co{'parent'}, 0, 7))) .
7265                                 ')';
7266                 } else {
7267                         # merge commit
7268                         if ($hash_parent eq '--cc') {
7269                                 $formats_nav .= ' | ' .
7270                                         $cgi->a({-href => href(action=>"commitdiff",
7271                                                                hash=>$hash, hash_parent=>'-c')},
7272                                                 'combined');
7273                         } else { # $hash_parent eq '-c'
7274                                 $formats_nav .= ' | ' .
7275                                         $cgi->a({-href => href(action=>"commitdiff",
7276                                                                hash=>$hash, hash_parent=>'--cc')},
7277                                                 'compact');
7278                         }
7279                         $formats_nav .=
7280                                 ' (merge: ' .
7281                                 join(' ', map {
7282                                         $cgi->a({-href => href(action=>"commitdiff",
7283                                                                hash=>$_)},
7284                                                 esc_html(substr($_, 0, 7)));
7285                                 } @{$co{'parents'}} ) .
7286                                 ')';
7287                 }
7288         }
7289
7290         my $hash_parent_param = $hash_parent;
7291         if (!defined $hash_parent_param) {
7292                 # --cc for multiple parents, --root for parentless
7293                 $hash_parent_param =
7294                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7295         }
7296
7297         # read commitdiff
7298         my $fd;
7299         my @difftree;
7300         if ($format eq 'html') {
7301                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7302                         "--no-commit-id", "--patch-with-raw", "--full-index",
7303                         $hash_parent_param, $hash, "--"
7304                         or die_error(500, "Open git-diff-tree failed");
7305
7306                 while (my $line = <$fd>) {
7307                         chomp $line;
7308                         # empty line ends raw part of diff-tree output
7309                         last unless $line;
7310                         push @difftree, scalar parse_difftree_raw_line($line);
7311                 }
7312
7313         } elsif ($format eq 'plain') {
7314                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7315                         '-p', $hash_parent_param, $hash, "--"
7316                         or die_error(500, "Open git-diff-tree failed");
7317         } elsif ($format eq 'patch') {
7318                 # For commit ranges, we limit the output to the number of
7319                 # patches specified in the 'patches' feature.
7320                 # For single commits, we limit the output to a single patch,
7321                 # diverging from the git-format-patch default.
7322                 my @commit_spec = ();
7323                 if ($hash_parent) {
7324                         if ($patch_max > 0) {
7325                                 push @commit_spec, "-$patch_max";
7326                         }
7327                         push @commit_spec, '-n', "$hash_parent..$hash";
7328                 } else {
7329                         if ($params{-single}) {
7330                                 push @commit_spec, '-1';
7331                         } else {
7332                                 if ($patch_max > 0) {
7333                                         push @commit_spec, "-$patch_max";
7334                                 }
7335                                 push @commit_spec, "-n";
7336                         }
7337                         push @commit_spec, '--root', $hash;
7338                 }
7339                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7340                         '--encoding=utf8', '--stdout', @commit_spec
7341                         or die_error(500, "Open git-format-patch failed");
7342         } else {
7343                 die_error(400, "Unknown commitdiff format");
7344         }
7345
7346         # non-textual hash id's can be cached
7347         my $expires;
7348         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7349                 $expires = "+1d";
7350         }
7351
7352         # write commit message
7353         if ($format eq 'html') {
7354                 my $refs = git_get_references();
7355                 my $ref = format_ref_marker($refs, $co{'id'});
7356
7357                 git_header_html(undef, $expires);
7358                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7359                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7360                 print "<div class=\"title_text\">\n" .
7361                       "<table class=\"object_header\">\n";
7362                 git_print_authorship_rows(\%co);
7363                 print "</table>".
7364                       "</div>\n";
7365                 print "<div class=\"page_body\">\n";
7366                 if (@{$co{'comment'}} > 1) {
7367                         print "<div class=\"log\">\n";
7368                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7369                         print "</div>\n"; # class="log"
7370                 }
7371
7372         } elsif ($format eq 'plain') {
7373                 my $refs = git_get_references("tags");
7374                 my $tagname = git_get_rev_name_tags($hash);
7375                 my $filename = basename($project) . "-$hash.patch";
7376
7377                 print $cgi->header(
7378                         -type => 'text/plain',
7379                         -charset => 'utf-8',
7380                         -expires => $expires,
7381                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7382                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7383                 print "From: " . to_utf8($co{'author'}) . "\n";
7384                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7385                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7386
7387                 print "X-Git-Tag: $tagname\n" if $tagname;
7388                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7389
7390                 foreach my $line (@{$co{'comment'}}) {
7391                         print to_utf8($line) . "\n";
7392                 }
7393                 print "---\n\n";
7394         } elsif ($format eq 'patch') {
7395                 my $filename = basename($project) . "-$hash.patch";
7396
7397                 print $cgi->header(
7398                         -type => 'text/plain',
7399                         -charset => 'utf-8',
7400                         -expires => $expires,
7401                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7402         }
7403
7404         # write patch
7405         if ($format eq 'html') {
7406                 my $use_parents = !defined $hash_parent ||
7407                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7408                 git_difftree_body(\@difftree, $hash,
7409                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7410                 print "<br/>\n";
7411
7412                 git_patchset_body($fd, $diff_style,
7413                                   \@difftree, $hash,
7414                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7415                 close $fd;
7416                 print "</div>\n"; # class="page_body"
7417                 git_footer_html();
7418
7419         } elsif ($format eq 'plain') {
7420                 local $/ = undef;
7421                 print <$fd>;
7422                 close $fd
7423                         or print "Reading git-diff-tree failed\n";
7424         } elsif ($format eq 'patch') {
7425                 local $/ = undef;
7426                 print <$fd>;
7427                 close $fd
7428                         or print "Reading git-format-patch failed\n";
7429         }
7430 }
7431
7432 sub git_commitdiff_plain {
7433         git_commitdiff(-format => 'plain');
7434 }
7435
7436 # format-patch-style patches
7437 sub git_patch {
7438         git_commitdiff(-format => 'patch', -single => 1);
7439 }
7440
7441 sub git_patches {
7442         git_commitdiff(-format => 'patch');
7443 }
7444
7445 sub git_history {
7446         git_log_generic('history', \&git_history_body,
7447                         $hash_base, $hash_parent_base,
7448                         $file_name, $hash);
7449 }
7450
7451 sub git_search {
7452         $searchtype ||= 'commit';
7453
7454         # check if appropriate features are enabled
7455         gitweb_check_feature('search')
7456                 or die_error(403, "Search is disabled");
7457         if ($searchtype eq 'pickaxe') {
7458                 # pickaxe may take all resources of your box and run for several minutes
7459                 # with every query - so decide by yourself how public you make this feature
7460                 gitweb_check_feature('pickaxe')
7461                         or die_error(403, "Pickaxe search is disabled");
7462         }
7463         if ($searchtype eq 'grep') {
7464                 # grep search might be potentially CPU-intensive, too
7465                 gitweb_check_feature('grep')
7466                         or die_error(403, "Grep search is disabled");
7467         }
7468
7469         if (!defined $searchtext) {
7470                 die_error(400, "Text field is empty");
7471         }
7472         if (!defined $hash) {
7473                 $hash = git_get_head_hash($project);
7474         }
7475         my %co = parse_commit($hash);
7476         if (!%co) {
7477                 die_error(404, "Unknown commit object");
7478         }
7479         if (!defined $page) {
7480                 $page = 0;
7481         }
7482
7483         if ($searchtype eq 'commit' ||
7484             $searchtype eq 'author' ||
7485             $searchtype eq 'committer') {
7486                 git_search_message(%co);
7487         } elsif ($searchtype eq 'pickaxe') {
7488                 git_search_changes(%co);
7489         } elsif ($searchtype eq 'grep') {
7490                 git_search_files(%co);
7491         } else {
7492                 die_error(400, "Unknown search type");
7493         }
7494 }
7495
7496 sub git_search_help {
7497         git_header_html();
7498         git_print_page_nav('','', $hash,$hash,$hash);
7499         print <<EOT;
7500 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7501 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7502 the pattern entered is recognized as the POSIX extended
7503 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7504 insensitive).</p>
7505 <dl>
7506 <dt><b>commit</b></dt>
7507 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7508 EOT
7509         my $have_grep = gitweb_check_feature('grep');
7510         if ($have_grep) {
7511                 print <<EOT;
7512 <dt><b>grep</b></dt>
7513 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7514     a different one) are searched for the given pattern. On large trees, this search can take
7515 a while and put some strain on the server, so please use it with some consideration. Note that
7516 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7517 case-sensitive.</dd>
7518 EOT
7519         }
7520         print <<EOT;
7521 <dt><b>author</b></dt>
7522 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7523 <dt><b>committer</b></dt>
7524 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7525 EOT
7526         my $have_pickaxe = gitweb_check_feature('pickaxe');
7527         if ($have_pickaxe) {
7528                 print <<EOT;
7529 <dt><b>pickaxe</b></dt>
7530 <dd>All commits that caused the string to appear or disappear from any file (changes that
7531 added, removed or "modified" the string) will be listed. This search can take a while and
7532 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7533 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7534 EOT
7535         }
7536         print "</dl>\n";
7537         git_footer_html();
7538 }
7539
7540 sub git_shortlog {
7541         git_log_generic('shortlog', \&git_shortlog_body,
7542                         $hash, $hash_parent);
7543 }
7544
7545 ## ......................................................................
7546 ## feeds (RSS, Atom; OPML)
7547
7548 sub git_feed {
7549         my $format = shift || 'atom';
7550         my $have_blame = gitweb_check_feature('blame');
7551
7552         # Atom: http://www.atomenabled.org/developers/syndication/
7553         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7554         if ($format ne 'rss' && $format ne 'atom') {
7555                 die_error(400, "Unknown web feed format");
7556         }
7557
7558         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7559         my $head = $hash || 'HEAD';
7560         my @commitlist = parse_commits($head, 150, 0, $file_name);
7561
7562         my %latest_commit;
7563         my %latest_date;
7564         my $content_type = "application/$format+xml";
7565         if (defined $cgi->http('HTTP_ACCEPT') &&
7566                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7567                 # browser (feed reader) prefers text/xml
7568                 $content_type = 'text/xml';
7569         }
7570         if (defined($commitlist[0])) {
7571                 %latest_commit = %{$commitlist[0]};
7572                 my $latest_epoch = $latest_commit{'committer_epoch'};
7573                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7574                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7575                 if (defined $if_modified) {
7576                         my $since;
7577                         if (eval { require HTTP::Date; 1; }) {
7578                                 $since = HTTP::Date::str2time($if_modified);
7579                         } elsif (eval { require Time::ParseDate; 1; }) {
7580                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7581                         }
7582                         if (defined $since && $latest_epoch <= $since) {
7583                                 print $cgi->header(
7584                                         -type => $content_type,
7585                                         -charset => 'utf-8',
7586                                         -last_modified => $latest_date{'rfc2822'},
7587                                         -status => '304 Not Modified');
7588                                 return;
7589                         }
7590                 }
7591                 print $cgi->header(
7592                         -type => $content_type,
7593                         -charset => 'utf-8',
7594                         -last_modified => $latest_date{'rfc2822'});
7595         } else {
7596                 print $cgi->header(
7597                         -type => $content_type,
7598                         -charset => 'utf-8');
7599         }
7600
7601         # Optimization: skip generating the body if client asks only
7602         # for Last-Modified date.
7603         return if ($cgi->request_method() eq 'HEAD');
7604
7605         # header variables
7606         my $title = "$site_name - $project/$action";
7607         my $feed_type = 'log';
7608         if (defined $hash) {
7609                 $title .= " - '$hash'";
7610                 $feed_type = 'branch log';
7611                 if (defined $file_name) {
7612                         $title .= " :: $file_name";
7613                         $feed_type = 'history';
7614                 }
7615         } elsif (defined $file_name) {
7616                 $title .= " - $file_name";
7617                 $feed_type = 'history';
7618         }
7619         $title .= " $feed_type";
7620         my $descr = git_get_project_description($project);
7621         if (defined $descr) {
7622                 $descr = esc_html($descr);
7623         } else {
7624                 $descr = "$project " .
7625                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7626                          " feed";
7627         }
7628         my $owner = git_get_project_owner($project);
7629         $owner = esc_html($owner);
7630
7631         #header
7632         my $alt_url;
7633         if (defined $file_name) {
7634                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7635         } elsif (defined $hash) {
7636                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7637         } else {
7638                 $alt_url = href(-full=>1, action=>"summary");
7639         }
7640         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7641         if ($format eq 'rss') {
7642                 print <<XML;
7643 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7644 <channel>
7645 XML
7646                 print "<title>$title</title>\n" .
7647                       "<link>$alt_url</link>\n" .
7648                       "<description>$descr</description>\n" .
7649                       "<language>en</language>\n" .
7650                       # project owner is responsible for 'editorial' content
7651                       "<managingEditor>$owner</managingEditor>\n";
7652                 if (defined $logo || defined $favicon) {
7653                         # prefer the logo to the favicon, since RSS
7654                         # doesn't allow both
7655                         my $img = esc_url($logo || $favicon);
7656                         print "<image>\n" .
7657                               "<url>$img</url>\n" .
7658                               "<title>$title</title>\n" .
7659                               "<link>$alt_url</link>\n" .
7660                               "</image>\n";
7661                 }
7662                 if (%latest_date) {
7663                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7664                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7665                 }
7666                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7667         } elsif ($format eq 'atom') {
7668                 print <<XML;
7669 <feed xmlns="http://www.w3.org/2005/Atom">
7670 XML
7671                 print "<title>$title</title>\n" .
7672                       "<subtitle>$descr</subtitle>\n" .
7673                       '<link rel="alternate" type="text/html" href="' .
7674                       $alt_url . '" />' . "\n" .
7675                       '<link rel="self" type="' . $content_type . '" href="' .
7676                       $cgi->self_url() . '" />' . "\n" .
7677                       "<id>" . href(-full=>1) . "</id>\n" .
7678                       # use project owner for feed author
7679                       "<author><name>$owner</name></author>\n";
7680                 if (defined $favicon) {
7681                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7682                 }
7683                 if (defined $logo) {
7684                         # not twice as wide as tall: 72 x 27 pixels
7685                         print "<logo>" . esc_url($logo) . "</logo>\n";
7686                 }
7687                 if (! %latest_date) {
7688                         # dummy date to keep the feed valid until commits trickle in:
7689                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7690                 } else {
7691                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7692                 }
7693                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7694         }
7695
7696         # contents
7697         for (my $i = 0; $i <= $#commitlist; $i++) {
7698                 my %co = %{$commitlist[$i]};
7699                 my $commit = $co{'id'};
7700                 # we read 150, we always show 30 and the ones more recent than 48 hours
7701                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7702                         last;
7703                 }
7704                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7705
7706                 # get list of changed files
7707                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7708                         $co{'parent'} || "--root",
7709                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7710                         or next;
7711                 my @difftree = map { chomp; $_ } <$fd>;
7712                 close $fd
7713                         or next;
7714
7715                 # print element (entry, item)
7716                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7717                 if ($format eq 'rss') {
7718                         print "<item>\n" .
7719                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7720                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7721                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7722                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7723                               "<link>$co_url</link>\n" .
7724                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7725                               "<content:encoded>" .
7726                               "<![CDATA[\n";
7727                 } elsif ($format eq 'atom') {
7728                         print "<entry>\n" .
7729                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7730                               "<updated>$cd{'iso-8601'}</updated>\n" .
7731                               "<author>\n" .
7732                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7733                         if ($co{'author_email'}) {
7734                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7735                         }
7736                         print "</author>\n" .
7737                               # use committer for contributor
7738                               "<contributor>\n" .
7739                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7740                         if ($co{'committer_email'}) {
7741                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7742                         }
7743                         print "</contributor>\n" .
7744                               "<published>$cd{'iso-8601'}</published>\n" .
7745                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7746                               "<id>$co_url</id>\n" .
7747                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7748                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7749                 }
7750                 my $comment = $co{'comment'};
7751                 print "<pre>\n";
7752                 foreach my $line (@$comment) {
7753                         $line = esc_html($line);
7754                         print "$line\n";
7755                 }
7756                 print "</pre><ul>\n";
7757                 foreach my $difftree_line (@difftree) {
7758                         my %difftree = parse_difftree_raw_line($difftree_line);
7759                         next if !$difftree{'from_id'};
7760
7761                         my $file = $difftree{'file'} || $difftree{'to_file'};
7762
7763                         print "<li>" .
7764                               "[" .
7765                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7766                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7767                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7768                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7769                                       -title => "diff"}, 'D');
7770                         if ($have_blame) {
7771                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7772                                                              file_name=>$file, hash_base=>$commit),
7773                                               -title => "blame"}, 'B');
7774                         }
7775                         # if this is not a feed of a file history
7776                         if (!defined $file_name || $file_name ne $file) {
7777                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7778                                                              file_name=>$file, hash=>$commit),
7779                                               -title => "history"}, 'H');
7780                         }
7781                         $file = esc_path($file);
7782                         print "] ".
7783                               "$file</li>\n";
7784                 }
7785                 if ($format eq 'rss') {
7786                         print "</ul>]]>\n" .
7787                               "</content:encoded>\n" .
7788                               "</item>\n";
7789                 } elsif ($format eq 'atom') {
7790                         print "</ul>\n</div>\n" .
7791                               "</content>\n" .
7792                               "</entry>\n";
7793                 }
7794         }
7795
7796         # end of feed
7797         if ($format eq 'rss') {
7798                 print "</channel>\n</rss>\n";
7799         } elsif ($format eq 'atom') {
7800                 print "</feed>\n";
7801         }
7802 }
7803
7804 sub git_rss {
7805         git_feed('rss');
7806 }
7807
7808 sub git_atom {
7809         git_feed('atom');
7810 }
7811
7812 sub git_opml {
7813         my @list = git_get_projects_list();
7814         if (!@list) {
7815                 die_error(404, "No projects found");
7816         }
7817
7818         print $cgi->header(
7819                 -type => 'text/xml',
7820                 -charset => 'utf-8',
7821                 -content_disposition => 'inline; filename="opml.xml"');
7822
7823         print <<XML;
7824 <?xml version="1.0" encoding="utf-8"?>
7825 <opml version="1.0">
7826 <head>
7827   <title>$site_name OPML Export</title>
7828 </head>
7829 <body>
7830 <outline text="git RSS feeds">
7831 XML
7832
7833         foreach my $pr (@list) {
7834                 my %proj = %$pr;
7835                 my $head = git_get_head_hash($proj{'path'});
7836                 if (!defined $head) {
7837                         next;
7838                 }
7839                 $git_dir = "$projectroot/$proj{'path'}";
7840                 my %co = parse_commit($head);
7841                 if (!%co) {
7842                         next;
7843                 }
7844
7845                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7846                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7847                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7848                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7849         }
7850         print <<XML;
7851 </outline>
7852 </body>
7853 </opml>
7854 XML
7855 }