git.oblomov.eu Git - git/blob - t/t7519/fsmonitor-watchman

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use IPC::Open2;
   6
   7 # An example hook script to integrate Watchman
   8 # (https://facebook.github.io/watchman/) with git to speed up detecting
   9 # new and modified files.
  10 #
  11 # The hook is passed a version (currently 1) and a time in nanoseconds
  12 # formatted as a string and outputs to stdout all files that have been
  13 # modified since the given time. Paths must be relative to the root of
  14 # the working tree and separated by a single NUL.
  15 #
  16 # To enable this hook, rename this file to "query-watchman" and set
  17 # 'git config core.fsmonitor .git/hooks/query-watchman'
  18 #
  19 my ($version, $time) = @ARGV;
  20 #print STDERR "$0 $version $time\n";
  21
  22 # Check the hook interface version
  23
  24 if ($version == 1) {
  25         # convert nanoseconds to seconds
  26         $time = int $time / 1000000000;
  27 } else {
  28         die "Unsupported query-fsmonitor hook version '$version'.\n" .
  29             "Falling back to scanning...\n";
  30 }
  31
  32 # Convert unix style paths to escaped Windows style paths when running
  33 # in Windows command prompt
  34
  35 my $system = `uname -s`;
  36 $system =~ s/[\r\n]+//g;
  37 my $git_work_tree;
  38
  39 if ($system =~ m/^MSYS_NT/ || $system =~ m/^MINGW/) {
  40         $git_work_tree = `cygpath -aw "\$PWD"`;
  41         $git_work_tree =~ s/[\r\n]+//g;
  42         $git_work_tree =~ s,\\,/,g;
  43 } else {
  44         require Cwd;
  45         $git_work_tree = Cwd::cwd();
  46 }
  47
  48 my $retry = 1;
  49
  50 launch_watchman();
  51
  52 sub launch_watchman {
  53
  54         my $pid = open2(\*CHLD_OUT, \*CHLD_IN, 'watchman -j')
  55             or die "open2() failed: $!\n" .
  56             "Falling back to scanning...\n";
  57
  58         # In the query expression below we're asking for names of files that
  59         # changed since $time but were not transient (ie created after
  60         # $time but no longer exist).
  61         #
  62         # To accomplish this, we're using the "since" generator to use the
  63         # recency index to select candidate nodes and "fields" to limit the
  64         # output to file names only. Then we're using the "expression" term to
  65         # further constrain the results.
  66         #
  67         # The category of transient files that we want to ignore will have a
  68         # creation clock (cclock) newer than $time_t value and will also not
  69         # currently exist.
  70
  71         my $query = <<" END";
  72                 ["query", "$git_work_tree", {
  73                         "since": $time,
  74                         "fields": ["name"],
  75                         "expression": ["not", ["allof", ["since", $time, "cclock"], ["not", "exists"]]]
  76                 }]
  77         END
  78
  79         open (my $fh, ">", ".git/watchman-query.json");
  80         print $fh $query;
  81         close $fh;
  82
  83         print CHLD_IN $query;
  84         close CHLD_IN;
  85         my $response = do {local $/; <CHLD_OUT>};
  86
  87         open ($fh, ">", ".git/watchman-response.json");
  88         print $fh $response;
  89         close $fh;
  90
  91         die "Watchman: command returned no output.\n" .
  92             "Falling back to scanning...\n" if $response eq "";
  93         die "Watchman: command returned invalid output: $response\n" .
  94             "Falling back to scanning...\n" unless $response =~ /^\{/;
  95
  96         my $json_pkg;
  97         eval {
  98                 require JSON::XS;
  99                 $json_pkg = "JSON::XS";
 100                 1;
 101         } or do {
 102                 require JSON::PP;
 103                 $json_pkg = "JSON::PP";
 104         };
 105
 106         my $o = $json_pkg->new->utf8->decode($response);
 107
 108         if ($retry > 0 and $o->{error} and $o->{error} =~ m/unable to resolve root .* directory (.*) is not watched/) {
 109                 print STDERR "Adding '$git_work_tree' to watchman's watch list.\n";
 110                 $retry--;
 111                 qx/watchman watch "$git_work_tree"/;
 112                 die "Failed to make watchman watch '$git_work_tree'.\n" .
 113                     "Falling back to scanning...\n" if $? != 0;
 114
 115                 # Watchman will always return all files on the first query so
 116                 # return the fast "everything is dirty" flag to git and do the
 117                 # Watchman query just to get it over with now so we won't pay
 118                 # the cost in git to look up each individual file.
 119
 120                 open ($fh, ">", ".git/watchman-output.out");
 121                 print "/\0";
 122                 close $fh;
 123
 124                 print "/\0";
 125                 eval { launch_watchman() };
 126                 exit 0;
 127         }
 128
 129         die "Watchman: $o->{error}.\n" .
 130             "Falling back to scanning...\n" if $o->{error};
 131
 132         open ($fh, ">", ".git/watchman-output.out");
 133         binmode $fh, ":utf8";
 134         print $fh @{$o->{files}};
 135         close $fh;
 136
 137         binmode STDOUT, ":utf8";
 138         local $, = "\0";
 139         print @{$o->{files}};
 140 }