git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]annotate                * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --compose-encoding      <str>  * Encoding to assume for introduction.
  60     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  61
  62   Sending:
  63     --envelope-sender       <str>  * Email envelope sender.
  64     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  65                                      is optional. Default 'localhost'.
  66     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  67     --smtp-server-port      <int>  * Outgoing SMTP server port.
  68     --smtp-user             <str>  * Username for SMTP-AUTH.
  69     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  70     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  71     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  72     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  73                                      Pass an empty string to disable certificate
  74                                      verification.
  75     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  76     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  77
  78   Automating:
  79     --identity              <str>  * Use the sendemail.<id> options.
  80     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  81     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  82     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  83     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  84     --[no-]suppress-from           * Send to self. Default off.
  85     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  86     --[no-]thread                  * Use In-Reply-To: field. Default on.
  87
  88   Administering:
  89     --confirm               <str>  * Confirm recipients before sending;
  90                                      auto, cc, compose, always, or never.
  91     --quiet                        * Output one line of info per email.
  92     --dry-run                      * Don't actually send the emails.
  93     --[no-]validate                * Perform patch sanity checks. Default on.
  94     --[no-]format-patch            * understand any non optional arguments as
  95                                      `git format-patch` ones.
  96     --force                        * Send even if safety checks would prevent it.
  97
  98 EOT
  99         exit(1);
 100 }
 101
 102 # most mail servers generate the Date: header, but not all...
 103 sub format_2822_time {
 104         my ($time) = @_;
 105         my @localtm = localtime($time);
 106         my @gmttm = gmtime($time);
 107         my $localmin = $localtm[1] + $localtm[2] * 60;
 108         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 109         if ($localtm[0] != $gmttm[0]) {
 110                 die "local zone differs from GMT by a non-minute interval\n";
 111         }
 112         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 113                 $localmin += 1440;
 114         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 115                 $localmin -= 1440;
 116         } elsif ($gmttm[6] != $localtm[6]) {
 117                 die "local time offset greater than or equal to 24 hours\n";
 118         }
 119         my $offset = $localmin - $gmtmin;
 120         my $offhour = $offset / 60;
 121         my $offmin = abs($offset % 60);
 122         if (abs($offhour) >= 24) {
 123                 die ("local time offset greater than or equal to 24 hours\n");
 124         }
 125
 126         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 127                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 128                        $localtm[3],
 129                        qw(Jan Feb Mar Apr May Jun
 130                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 131                        $localtm[5]+1900,
 132                        $localtm[2],
 133                        $localtm[1],
 134                        $localtm[0],
 135                        ($offset >= 0) ? '+' : '-',
 136                        abs($offhour),
 137                        $offmin,
 138                        );
 139 }
 140
 141 my $have_email_valid = eval { require Email::Valid; 1 };
 142 my $have_mail_address = eval { require Mail::Address; 1 };
 143 my $smtp;
 144 my $auth;
 145
 146 # Variables we fill in automatically, or via prompting:
 147 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 148         $initial_reply_to,$initial_subject,@files,
 149         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 150
 151 my $envelope_sender;
 152
 153 # Example reply to:
 154 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 155
 156 my $repo = eval { Git->repository() };
 157 my @repo = $repo ? ($repo) : ();
 158 my $term = eval {
 159         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 160                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 161                 : new Term::ReadLine 'git-send-email';
 162 };
 163 if ($@) {
 164         $term = new FakeTerm "$@: going non-interactive";
 165 }
 166
 167 # Behavior modification variables
 168 my ($quiet, $dry_run) = (0, 0);
 169 my $format_patch;
 170 my $compose_filename;
 171 my $force = 0;
 172
 173 # Handle interactive edition of files.
 174 my $multiedit;
 175 my $editor;
 176
 177 sub do_edit {
 178         if (!defined($editor)) {
 179                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 180         }
 181         if (defined($multiedit) && !$multiedit) {
 182                 map {
 183                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 184                         if (($? & 127) || ($? >> 8)) {
 185                                 die("the editor exited uncleanly, aborting everything");
 186                         }
 187                 } @_;
 188         } else {
 189                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 190                 if (($? & 127) || ($? >> 8)) {
 191                         die("the editor exited uncleanly, aborting everything");
 192                 }
 193         }
 194 }
 195
 196 # Variables with corresponding config settings
 197 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 198 my ($to_cmd, $cc_cmd);
 199 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 200 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 201 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 202 my ($validate, $confirm);
 203 my (@suppress_cc);
 204 my ($auto_8bit_encoding);
 205 my ($compose_encoding);
 206
 207 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 208
 209 my %config_bool_settings = (
 210     "thread" => [\$thread, 1],
 211     "chainreplyto" => [\$chain_reply_to, 0],
 212     "suppressfrom" => [\$suppress_from, undef],
 213     "signedoffbycc" => [\$signed_off_by_cc, undef],
 214     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 215     "validate" => [\$validate, 1],
 216     "multiedit" => [\$multiedit, undef],
 217     "annotate" => [\$annotate, undef]
 218 );
 219
 220 my %config_settings = (
 221     "smtpserver" => \$smtp_server,
 222     "smtpserverport" => \$smtp_server_port,
 223     "smtpserveroption" => \@smtp_server_options,
 224     "smtpuser" => \$smtp_authuser,
 225     "smtppass" => \$smtp_authpass,
 226     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 227     "smtpdomain" => \$smtp_domain,
 228     "to" => \@initial_to,
 229     "tocmd" => \$to_cmd,
 230     "cc" => \@initial_cc,
 231     "cccmd" => \$cc_cmd,
 232     "aliasfiletype" => \$aliasfiletype,
 233     "bcc" => \@bcclist,
 234     "suppresscc" => \@suppress_cc,
 235     "envelopesender" => \$envelope_sender,
 236     "confirm"   => \$confirm,
 237     "from" => \$sender,
 238     "assume8bitencoding" => \$auto_8bit_encoding,
 239     "composeencoding" => \$compose_encoding,
 240 );
 241
 242 my %config_path_settings = (
 243     "aliasesfile" => \@alias_files,
 244 );
 245
 246 # Handle Uncouth Termination
 247 sub signal_handler {
 248
 249         # Make text normal
 250         print color("reset"), "\n";
 251
 252         # SMTP password masked
 253         system "stty echo";
 254
 255         # tmp files from --compose
 256         if (defined $compose_filename) {
 257                 if (-e $compose_filename) {
 258                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 259                 }
 260                 if (-e ($compose_filename . ".final")) {
 261                         print "'$compose_filename.final' contains the composed email.\n"
 262                 }
 263         }
 264
 265         exit;
 266 };
 267
 268 $SIG{TERM} = \&signal_handler;
 269 $SIG{INT}  = \&signal_handler;
 270
 271 # Begin by accumulating all the variables (defined above), that we will end up
 272 # needing, first, from the command line:
 273
 274 my $help;
 275 my $rc = GetOptions("h" => \$help,
 276                     "sender|from=s" => \$sender,
 277                     "in-reply-to=s" => \$initial_reply_to,
 278                     "subject=s" => \$initial_subject,
 279                     "to=s" => \@initial_to,
 280                     "to-cmd=s" => \$to_cmd,
 281                     "no-to" => \$no_to,
 282                     "cc=s" => \@initial_cc,
 283                     "no-cc" => \$no_cc,
 284                     "bcc=s" => \@bcclist,
 285                     "no-bcc" => \$no_bcc,
 286                     "chain-reply-to!" => \$chain_reply_to,
 287                     "smtp-server=s" => \$smtp_server,
 288                     "smtp-server-option=s" => \@smtp_server_options,
 289                     "smtp-server-port=s" => \$smtp_server_port,
 290                     "smtp-user=s" => \$smtp_authuser,
 291                     "smtp-pass:s" => \$smtp_authpass,
 292                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 293                     "smtp-encryption=s" => \$smtp_encryption,
 294                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 295                     "smtp-debug:i" => \$debug_net_smtp,
 296                     "smtp-domain:s" => \$smtp_domain,
 297                     "identity=s" => \$identity,
 298                     "annotate!" => \$annotate,
 299                     "compose" => \$compose,
 300                     "quiet" => \$quiet,
 301                     "cc-cmd=s" => \$cc_cmd,
 302                     "suppress-from!" => \$suppress_from,
 303                     "suppress-cc=s" => \@suppress_cc,
 304                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 305                     "confirm=s" => \$confirm,
 306                     "dry-run" => \$dry_run,
 307                     "envelope-sender=s" => \$envelope_sender,
 308                     "thread!" => \$thread,
 309                     "validate!" => \$validate,
 310                     "format-patch!" => \$format_patch,
 311                     "8bit-encoding=s" => \$auto_8bit_encoding,
 312                     "compose-encoding=s" => \$compose_encoding,
 313                     "force" => \$force,
 314          );
 315
 316 usage() if $help;
 317 unless ($rc) {
 318     usage();
 319 }
 320
 321 die "Cannot run git format-patch from outside a repository\n"
 322         if $format_patch and not $repo;
 323
 324 # Now, let's fill any that aren't set in with defaults:
 325
 326 sub read_config {
 327         my ($prefix) = @_;
 328
 329         foreach my $setting (keys %config_bool_settings) {
 330                 my $target = $config_bool_settings{$setting}->[0];
 331                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 332         }
 333
 334         foreach my $setting (keys %config_path_settings) {
 335                 my $target = $config_path_settings{$setting};
 336                 if (ref($target) eq "ARRAY") {
 337                         unless (@$target) {
 338                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 339                                 @$target = @values if (@values && defined $values[0]);
 340                         }
 341                 }
 342                 else {
 343                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 344                 }
 345         }
 346
 347         foreach my $setting (keys %config_settings) {
 348                 my $target = $config_settings{$setting};
 349                 next if $setting eq "to" and defined $no_to;
 350                 next if $setting eq "cc" and defined $no_cc;
 351                 next if $setting eq "bcc" and defined $no_bcc;
 352                 if (ref($target) eq "ARRAY") {
 353                         unless (@$target) {
 354                                 my @values = Git::config(@repo, "$prefix.$setting");
 355                                 @$target = @values if (@values && defined $values[0]);
 356                         }
 357                 }
 358                 else {
 359                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 360                 }
 361         }
 362
 363         if (!defined $smtp_encryption) {
 364                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 365                 if (defined $enc) {
 366                         $smtp_encryption = $enc;
 367                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 368                         $smtp_encryption = 'ssl';
 369                 }
 370         }
 371 }
 372
 373 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 374 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 375 read_config("sendemail.$identity") if (defined $identity);
 376 read_config("sendemail");
 377
 378 # fall back on builtin bool defaults
 379 foreach my $setting (values %config_bool_settings) {
 380         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 381 }
 382
 383 # 'default' encryption is none -- this only prevents a warning
 384 $smtp_encryption = '' unless (defined $smtp_encryption);
 385
 386 # Set CC suppressions
 387 my(%suppress_cc);
 388 if (@suppress_cc) {
 389         foreach my $entry (@suppress_cc) {
 390                 die "Unknown --suppress-cc field: '$entry'\n"
 391                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 392                 $suppress_cc{$entry} = 1;
 393         }
 394 }
 395
 396 if ($suppress_cc{'all'}) {
 397         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 398                 $suppress_cc{$entry} = 1;
 399         }
 400         delete $suppress_cc{'all'};
 401 }
 402
 403 # If explicit old-style ones are specified, they trump --suppress-cc.
 404 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 405 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 406
 407 if ($suppress_cc{'body'}) {
 408         foreach my $entry (qw (sob bodycc)) {
 409                 $suppress_cc{$entry} = 1;
 410         }
 411         delete $suppress_cc{'body'};
 412 }
 413
 414 # Set confirm's default value
 415 my $confirm_unconfigured = !defined $confirm;
 416 if ($confirm_unconfigured) {
 417         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 418 };
 419 die "Unknown --confirm setting: '$confirm'\n"
 420         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 421
 422 # Debugging, print out the suppressions.
 423 if (0) {
 424         print "suppressions:\n";
 425         foreach my $entry (keys %suppress_cc) {
 426                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 427         }
 428 }
 429
 430 my ($repoauthor, $repocommitter);
 431 ($repoauthor) = Git::ident_person(@repo, 'author');
 432 ($repocommitter) = Git::ident_person(@repo, 'committer');
 433
 434 # Verify the user input
 435
 436 foreach my $entry (@initial_to) {
 437         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 438 }
 439
 440 foreach my $entry (@initial_cc) {
 441         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 442 }
 443
 444 foreach my $entry (@bcclist) {
 445         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 446 }
 447
 448 sub parse_address_line {
 449         if ($have_mail_address) {
 450                 return map { $_->format } Mail::Address->parse($_[0]);
 451         } else {
 452                 return split_addrs($_[0]);
 453         }
 454 }
 455
 456 sub split_addrs {
 457         return quotewords('\s*,\s*', 1, @_);
 458 }
 459
 460 my %aliases;
 461 my %parse_alias = (
 462         # multiline formats can be supported in the future
 463         mutt => sub { my $fh = shift; while (<$fh>) {
 464                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 465                         my ($alias, $addr) = ($1, $2);
 466                         $addr =~ s/#.*$//; # mutt allows # comments
 467                          # commas delimit multiple addresses
 468                         $aliases{$alias} = [ split_addrs($addr) ];
 469                 }}},
 470         mailrc => sub { my $fh = shift; while (<$fh>) {
 471                 if (/^alias\s+(\S+)\s+(.*)$/) {
 472                         # spaces delimit multiple addresses
 473                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 474                 }}},
 475         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 476                 for (my $x = ''; defined($x); $x = $_) {
 477                         chomp $x;
 478                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 479                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 480                         $aliases{$1} = [ split_addrs($2) ];
 481                 }},
 482         elm => sub  { my $fh = shift;
 483                       while (<$fh>) {
 484                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 485                               my ($alias, $addr) = ($1, $2);
 486                                $aliases{$alias} = [ split_addrs($addr) ];
 487                           }
 488                       } },
 489
 490         gnus => sub { my $fh = shift; while (<$fh>) {
 491                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 492                         $aliases{$1} = [ $2 ];
 493                 }}}
 494 );
 495
 496 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 497         foreach my $file (@alias_files) {
 498                 open my $fh, '<', $file or die "opening $file: $!\n";
 499                 $parse_alias{$aliasfiletype}->($fh);
 500                 close $fh;
 501         }
 502 }
 503
 504 ($sender) = expand_aliases($sender) if defined $sender;
 505
 506 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 507 # $f is a revision list specification to be passed to format-patch.
 508 sub is_format_patch_arg {
 509         return unless $repo;
 510         my $f = shift;
 511         try {
 512                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 513                 if (defined($format_patch)) {
 514                         return $format_patch;
 515                 }
 516                 die(<<EOF);
 517 File '$f' exists but it could also be the range of commits
 518 to produce patches for.  Please disambiguate by...
 519
 520     * Saying "./$f" if you mean a file; or
 521     * Giving --format-patch option if you mean a range.
 522 EOF
 523         } catch Git::Error::Command with {
 524                 # Not a valid revision.  Treat it as a filename.
 525                 return 0;
 526         }
 527 }
 528
 529 # Now that all the defaults are set, process the rest of the command line
 530 # arguments and collect up the files that need to be processed.
 531 my @rev_list_opts;
 532 while (defined(my $f = shift @ARGV)) {
 533         if ($f eq "--") {
 534                 push @rev_list_opts, "--", @ARGV;
 535                 @ARGV = ();
 536         } elsif (-d $f and !is_format_patch_arg($f)) {
 537                 opendir my $dh, $f
 538                         or die "Failed to opendir $f: $!";
 539
 540                 push @files, grep { -f $_ } map { catfile($f, $_) }
 541                                 sort readdir $dh;
 542                 closedir $dh;
 543         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 544                 push @files, $f;
 545         } else {
 546                 push @rev_list_opts, $f;
 547         }
 548 }
 549
 550 if (@rev_list_opts) {
 551         die "Cannot run git format-patch from outside a repository\n"
 552                 unless $repo;
 553         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 554 }
 555
 556 if ($validate) {
 557         foreach my $f (@files) {
 558                 unless (-p $f) {
 559                         my $error = validate_patch($f);
 560                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 561                 }
 562         }
 563 }
 564
 565 if (@files) {
 566         unless ($quiet) {
 567                 print $_,"\n" for (@files);
 568         }
 569 } else {
 570         print STDERR "\nNo patch files specified!\n\n";
 571         usage();
 572 }
 573
 574 sub get_patch_subject {
 575         my $fn = shift;
 576         open (my $fh, '<', $fn);
 577         while (my $line = <$fh>) {
 578                 next unless ($line =~ /^Subject: (.*)$/);
 579                 close $fh;
 580                 return "GIT: $1\n";
 581         }
 582         close $fh;
 583         die "No subject line in $fn ?";
 584 }
 585
 586 if ($compose) {
 587         # Note that this does not need to be secure, but we will make a small
 588         # effort to have it be unique
 589         $compose_filename = ($repo ?
 590                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 591                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 592         open my $c, ">", $compose_filename
 593                 or die "Failed to open for writing $compose_filename: $!";
 594
 595
 596         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 597         my $tpl_subject = $initial_subject || '';
 598         my $tpl_reply_to = $initial_reply_to || '';
 599
 600         print $c <<EOT;
 601 From $tpl_sender # This line is ignored.
 602 GIT: Lines beginning in "GIT:" will be removed.
 603 GIT: Consider including an overall diffstat or table of contents
 604 GIT: for the patch you are writing.
 605 GIT:
 606 GIT: Clear the body content if you don't wish to send a summary.
 607 From: $tpl_sender
 608 Subject: $tpl_subject
 609 In-Reply-To: $tpl_reply_to
 610
 611 EOT
 612         for my $f (@files) {
 613                 print $c get_patch_subject($f);
 614         }
 615         close $c;
 616
 617         if ($annotate) {
 618                 do_edit($compose_filename, @files);
 619         } else {
 620                 do_edit($compose_filename);
 621         }
 622
 623         open my $c2, ">", $compose_filename . ".final"
 624                 or die "Failed to open $compose_filename.final : " . $!;
 625
 626         open $c, "<", $compose_filename
 627                 or die "Failed to open $compose_filename : " . $!;
 628
 629         my $need_8bit_cte = file_has_nonascii($compose_filename);
 630         my $in_body = 0;
 631         my $summary_empty = 1;
 632         if (!defined $compose_encoding) {
 633                 $compose_encoding = "UTF-8";
 634         }
 635         while(<$c>) {
 636                 next if m/^GIT:/;
 637                 if ($in_body) {
 638                         $summary_empty = 0 unless (/^\n$/);
 639                 } elsif (/^\n$/) {
 640                         $in_body = 1;
 641                         if ($need_8bit_cte) {
 642                                 print $c2 "MIME-Version: 1.0\n",
 643                                          "Content-Type: text/plain; ",
 644                                            "charset=$compose_encoding\n",
 645                                          "Content-Transfer-Encoding: 8bit\n";
 646                         }
 647                 } elsif (/^MIME-Version:/i) {
 648                         $need_8bit_cte = 0;
 649                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 650                         $initial_subject = $1;
 651                         my $subject = $initial_subject;
 652                         $_ = "Subject: " .
 653                                 quote_subject($subject, $compose_encoding) .
 654                                 "\n";
 655                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 656                         $initial_reply_to = $1;
 657                         next;
 658                 } elsif (/^From:\s*(.+)\s*$/i) {
 659                         $sender = $1;
 660                         next;
 661                 } elsif (/^(?:To|Cc|Bcc):/i) {
 662                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 663                         next;
 664                 }
 665                 print $c2 $_;
 666         }
 667         close $c;
 668         close $c2;
 669
 670         if ($summary_empty) {
 671                 print "Summary email is empty, skipping it\n";
 672                 $compose = -1;
 673         }
 674 } elsif ($annotate) {
 675         do_edit(@files);
 676 }
 677
 678 sub ask {
 679         my ($prompt, %arg) = @_;
 680         my $valid_re = $arg{valid_re};
 681         my $default = $arg{default};
 682         my $confirm_only = $arg{confirm_only};
 683         my $resp;
 684         my $i = 0;
 685         return defined $default ? $default : undef
 686                 unless defined $term->IN and defined fileno($term->IN) and
 687                        defined $term->OUT and defined fileno($term->OUT);
 688         while ($i++ < 10) {
 689                 $resp = $term->readline($prompt);
 690                 if (!defined $resp) { # EOF
 691                         print "\n";
 692                         return defined $default ? $default : undef;
 693                 }
 694                 if ($resp eq '' and defined $default) {
 695                         return $default;
 696                 }
 697                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 698                         return $resp;
 699                 }
 700                 if ($confirm_only) {
 701                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 702                         if (defined $yesno && $yesno =~ /y/i) {
 703                                 return $resp;
 704                         }
 705                 }
 706         }
 707         return;
 708 }
 709
 710 my %broken_encoding;
 711
 712 sub file_declares_8bit_cte {
 713         my $fn = shift;
 714         open (my $fh, '<', $fn);
 715         while (my $line = <$fh>) {
 716                 last if ($line =~ /^$/);
 717                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 718         }
 719         close $fh;
 720         return 0;
 721 }
 722
 723 foreach my $f (@files) {
 724         next unless (body_or_subject_has_nonascii($f)
 725                      && !file_declares_8bit_cte($f));
 726         $broken_encoding{$f} = 1;
 727 }
 728
 729 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 730         print "The following files are 8bit, but do not declare " .
 731                 "a Content-Transfer-Encoding.\n";
 732         foreach my $f (sort keys %broken_encoding) {
 733                 print "    $f\n";
 734         }
 735         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 736                                   default => "UTF-8");
 737 }
 738
 739 if (!$force) {
 740         for my $f (@files) {
 741                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 742                         die "Refusing to send because the patch\n\t$f\n"
 743                                 . "has the template subject '*** SUBJECT HERE ***'. "
 744                                 . "Pass --force if you really want to send.\n";
 745                 }
 746         }
 747 }
 748
 749 if (!defined $sender) {
 750         $sender = $repoauthor || $repocommitter || '';
 751 }
 752
 753 # $sender could be an already sanitized address
 754 # (e.g. sendemail.from could be manually sanitized by user).
 755 # But it's a no-op to run sanitize_address on an already sanitized address.
 756 $sender = sanitize_address($sender);
 757
 758 my $prompting = 0;
 759 if (!@initial_to && !defined $to_cmd) {
 760         my $to = ask("Who should the emails be sent to (if any)? ",
 761                      default => "",
 762                      valid_re => qr/\@.*\./, confirm_only => 1);
 763         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 764         $prompting++;
 765 }
 766
 767 sub expand_aliases {
 768         return map { expand_one_alias($_) } @_;
 769 }
 770
 771 my %EXPANDED_ALIASES;
 772 sub expand_one_alias {
 773         my $alias = shift;
 774         if ($EXPANDED_ALIASES{$alias}) {
 775                 die "fatal: alias '$alias' expands to itself\n";
 776         }
 777         local $EXPANDED_ALIASES{$alias} = 1;
 778         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 779 }
 780
 781 @initial_to = expand_aliases(@initial_to);
 782 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 783 @initial_cc = expand_aliases(@initial_cc);
 784 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 785 @bcclist = expand_aliases(@bcclist);
 786 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 787
 788 if ($thread && !defined $initial_reply_to && $prompting) {
 789         $initial_reply_to = ask(
 790                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 791                 default => "",
 792                 valid_re => qr/\@.*\./, confirm_only => 1);
 793 }
 794 if (defined $initial_reply_to) {
 795         $initial_reply_to =~ s/^\s*<?//;
 796         $initial_reply_to =~ s/>?\s*$//;
 797         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 798 }
 799
 800 if (!defined $smtp_server) {
 801         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 802                 if (-x $_) {
 803                         $smtp_server = $_;
 804                         last;
 805                 }
 806         }
 807         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 808 }
 809
 810 if ($compose && $compose > 0) {
 811         @files = ($compose_filename . ".final", @files);
 812 }
 813
 814 # Variables we set as part of the loop over files
 815 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 816         $needs_confirm, $message_num, $ask_default);
 817
 818 sub extract_valid_address {
 819         my $address = shift;
 820         my $local_part_regexp = qr/[^<>"\s@]+/;
 821         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 822
 823         # check for a local address:
 824         return $address if ($address =~ /^($local_part_regexp)$/);
 825
 826         $address =~ s/^\s*<(.*)>\s*$/$1/;
 827         if ($have_email_valid) {
 828                 return scalar Email::Valid->address($address);
 829         }
 830
 831         # less robust/correct than the monster regexp in Email::Valid,
 832         # but still does a 99% job, and one less dependency
 833         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 834         return;
 835 }
 836
 837 sub extract_valid_address_or_die {
 838         my $address = shift;
 839         $address = extract_valid_address($address);
 840         die "error: unable to extract a valid address from: $address\n"
 841                 if !$address;
 842         return $address;
 843 }
 844
 845 sub validate_address {
 846         my $address = shift;
 847         while (!extract_valid_address($address)) {
 848                 print STDERR "error: unable to extract a valid address from: $address\n";
 849                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 850                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 851                         default => 'q');
 852                 if (/^d/i) {
 853                         return undef;
 854                 } elsif (/^q/i) {
 855                         cleanup_compose_files();
 856                         exit(0);
 857                 }
 858                 $address = ask("Who should the email be sent to (if any)? ",
 859                         default => "",
 860                         valid_re => qr/\@.*\./, confirm_only => 1);
 861         }
 862         return $address;
 863 }
 864
 865 sub validate_address_list {
 866         return (grep { defined $_ }
 867                 map { validate_address($_) } @_);
 868 }
 869
 870 # Usually don't need to change anything below here.
 871
 872 # we make a "fake" message id by taking the current number
 873 # of seconds since the beginning of Unix time and tacking on
 874 # a random number to the end, in case we are called quicker than
 875 # 1 second since the last time we were called.
 876
 877 # We'll setup a template for the message id, using the "from" address:
 878
 879 my ($message_id_stamp, $message_id_serial);
 880 sub make_message_id {
 881         my $uniq;
 882         if (!defined $message_id_stamp) {
 883                 $message_id_stamp = sprintf("%s-%s", time, $$);
 884                 $message_id_serial = 0;
 885         }
 886         $message_id_serial++;
 887         $uniq = "$message_id_stamp-$message_id_serial";
 888
 889         my $du_part;
 890         for ($sender, $repocommitter, $repoauthor) {
 891                 $du_part = extract_valid_address(sanitize_address($_));
 892                 last if (defined $du_part and $du_part ne '');
 893         }
 894         if (not defined $du_part or $du_part eq '') {
 895                 require Sys::Hostname;
 896                 $du_part = 'user@' . Sys::Hostname::hostname();
 897         }
 898         my $message_id_template = "<%s-git-send-email-%s>";
 899         $message_id = sprintf($message_id_template, $uniq, $du_part);
 900         #print "new message id = $message_id\n"; # Was useful for debugging
 901 }
 902
 903
 904
 905 $time = time - scalar $#files;
 906
 907 sub unquote_rfc2047 {
 908         local ($_) = @_;
 909         my $encoding;
 910         s{=\?([^?]+)\?q\?(.*?)\?=}{
 911                 $encoding = $1;
 912                 my $e = $2;
 913                 $e =~ s/_/ /g;
 914                 $e =~ s/=([0-9A-F]{2})/chr(hex($1))/eg;
 915                 $e;
 916         }eg;
 917         return wantarray ? ($_, $encoding) : $_;
 918 }
 919
 920 sub quote_rfc2047 {
 921         local $_ = shift;
 922         my $encoding = shift || 'UTF-8';
 923         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 924         s/(.*)/=\?$encoding\?q\?$1\?=/;
 925         return $_;
 926 }
 927
 928 sub is_rfc2047_quoted {
 929         my $s = shift;
 930         my $token = qr/[^][()<>@,;:"\/?.= \000-\037\177-\377]+/;
 931         my $encoded_text = qr/[!->@-~]+/;
 932         length($s) <= 75 &&
 933         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 934 }
 935
 936 sub subject_needs_rfc2047_quoting {
 937         my $s = shift;
 938
 939         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 940 }
 941
 942 sub quote_subject {
 943         local $subject = shift;
 944         my $encoding = shift || 'UTF-8';
 945
 946         if (subject_needs_rfc2047_quoting($subject)) {
 947                 return quote_rfc2047($subject, $encoding);
 948         }
 949         return $subject;
 950 }
 951
 952 # use the simplest quoting being able to handle the recipient
 953 sub sanitize_address {
 954         my ($recipient) = @_;
 955
 956         # remove garbage after email address
 957         $recipient =~ s/(.*>).*$/$1/;
 958
 959         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 960
 961         if (not $recipient_name) {
 962                 return $recipient;
 963         }
 964
 965         # if recipient_name is already quoted, do nothing
 966         if (is_rfc2047_quoted($recipient_name)) {
 967                 return $recipient;
 968         }
 969
 970         # rfc2047 is needed if a non-ascii char is included
 971         if ($recipient_name =~ /[^[:ascii:]]/) {
 972                 $recipient_name =~ s/^"(.*)"$/$1/;
 973                 $recipient_name = quote_rfc2047($recipient_name);
 974         }
 975
 976         # double quotes are needed if specials or CTLs are included
 977         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 978                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 979                 $recipient_name = qq["$recipient_name"];
 980         }
 981
 982         return "$recipient_name $recipient_addr";
 983
 984 }
 985
 986 sub sanitize_address_list {
 987         return (map { sanitize_address($_) } @_);
 988 }
 989
 990 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 991 #
 992 # Tightly configured MTAa require that a caller sends a real DNS
 993 # domain name that corresponds the IP address in the HELO/EHLO
 994 # handshake. This is used to verify the connection and prevent
 995 # spammers from trying to hide their identity. If the DNS and IP don't
 996 # match, the receiveing MTA may deny the connection.
 997 #
 998 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
 999 #
1000 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1001 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1002 #
1003 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1004 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1005
1006 sub valid_fqdn {
1007         my $domain = shift;
1008         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1009 }
1010
1011 sub maildomain_net {
1012         my $maildomain;
1013
1014         if (eval { require Net::Domain; 1 }) {
1015                 my $domain = Net::Domain::domainname();
1016                 $maildomain = $domain if valid_fqdn($domain);
1017         }
1018
1019         return $maildomain;
1020 }
1021
1022 sub maildomain_mta {
1023         my $maildomain;
1024
1025         if (eval { require Net::SMTP; 1 }) {
1026                 for my $host (qw(mailhost localhost)) {
1027                         my $smtp = Net::SMTP->new($host);
1028                         if (defined $smtp) {
1029                                 my $domain = $smtp->domain;
1030                                 $smtp->quit;
1031
1032                                 $maildomain = $domain if valid_fqdn($domain);
1033
1034                                 last if $maildomain;
1035                         }
1036                 }
1037         }
1038
1039         return $maildomain;
1040 }
1041
1042 sub maildomain {
1043         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1044 }
1045
1046 sub smtp_host_string {
1047         if (defined $smtp_server_port) {
1048                 return "$smtp_server:$smtp_server_port";
1049         } else {
1050                 return $smtp_server;
1051         }
1052 }
1053
1054 # Returns 1 if authentication succeeded or was not necessary
1055 # (smtp_user was not specified), and 0 otherwise.
1056
1057 sub smtp_auth_maybe {
1058         if (!defined $smtp_authuser || $auth) {
1059                 return 1;
1060         }
1061
1062         # Workaround AUTH PLAIN/LOGIN interaction defect
1063         # with Authen::SASL::Cyrus
1064         eval {
1065                 require Authen::SASL;
1066                 Authen::SASL->import(qw(Perl));
1067         };
1068
1069         # TODO: Authentication may fail not because credentials were
1070         # invalid but due to other reasons, in which we should not
1071         # reject credentials.
1072         $auth = Git::credential({
1073                 'protocol' => 'smtp',
1074                 'host' => smtp_host_string(),
1075                 'username' => $smtp_authuser,
1076                 # if there's no password, "git credential fill" will
1077                 # give us one, otherwise it'll just pass this one.
1078                 'password' => $smtp_authpass
1079         }, sub {
1080                 my $cred = shift;
1081                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1082         });
1083
1084         return $auth;
1085 }
1086
1087 sub ssl_verify_params {
1088         eval {
1089                 require IO::Socket::SSL;
1090                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1091         };
1092         if ($@) {
1093                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1094                 return;
1095         }
1096
1097         if (!defined $smtp_ssl_cert_path) {
1098                 # use the OpenSSL defaults
1099                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1100         }
1101
1102         if ($smtp_ssl_cert_path eq "") {
1103                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1104         } elsif (-d $smtp_ssl_cert_path) {
1105                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1106                         SSL_ca_path => $smtp_ssl_cert_path);
1107         } elsif (-f $smtp_ssl_cert_path) {
1108                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1109                         SSL_ca_file => $smtp_ssl_cert_path);
1110         } else {
1111                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1112                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1113         }
1114 }
1115
1116 sub file_name_is_absolute {
1117         my ($path) = @_;
1118
1119         # msys does not grok DOS drive-prefixes
1120         if ($^O eq 'msys') {
1121                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1122         }
1123
1124         require File::Spec::Functions;
1125         return File::Spec::Functions::file_name_is_absolute($path);
1126 }
1127
1128 # Returns 1 if the message was sent, and 0 otherwise.
1129 # In actuality, the whole program dies when there
1130 # is an error sending a message.
1131
1132 sub send_message {
1133         my @recipients = unique_email_list(@to);
1134         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1135                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1136                     }
1137                @cc);
1138         my $to = join (",\n\t", @recipients);
1139         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1140         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1141         my $date = format_2822_time($time++);
1142         my $gitversion = '@@GIT_VERSION@@';
1143         if ($gitversion =~ m/..GIT_VERSION../) {
1144             $gitversion = Git::version();
1145         }
1146
1147         my $cc = join(",\n\t", unique_email_list(@cc));
1148         my $ccline = "";
1149         if ($cc ne '') {
1150                 $ccline = "\nCc: $cc";
1151         }
1152         make_message_id() unless defined($message_id);
1153
1154         my $header = "From: $sender
1155 To: $to${ccline}
1156 Subject: $subject
1157 Date: $date
1158 Message-Id: $message_id
1159 X-Mailer: git-send-email $gitversion
1160 ";
1161         if ($reply_to) {
1162
1163                 $header .= "In-Reply-To: $reply_to\n";
1164                 $header .= "References: $references\n";
1165         }
1166         if (@xh) {
1167                 $header .= join("\n", @xh) . "\n";
1168         }
1169
1170         my @sendmail_parameters = ('-i', @recipients);
1171         my $raw_from = $sender;
1172         if (defined $envelope_sender && $envelope_sender ne "auto") {
1173                 $raw_from = $envelope_sender;
1174         }
1175         $raw_from = extract_valid_address($raw_from);
1176         unshift (@sendmail_parameters,
1177                         '-f', $raw_from) if(defined $envelope_sender);
1178
1179         if ($needs_confirm && !$dry_run) {
1180                 print "\n$header\n";
1181                 if ($needs_confirm eq "inform") {
1182                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1183                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1184                         print "    The Cc list above has been expanded by additional\n";
1185                         print "    addresses found in the patch commit message. By default\n";
1186                         print "    send-email prompts before sending whenever this occurs.\n";
1187                         print "    This behavior is controlled by the sendemail.confirm\n";
1188                         print "    configuration setting.\n";
1189                         print "\n";
1190                         print "    For additional information, run 'git send-email --help'.\n";
1191                         print "    To retain the current behavior, but squelch this message,\n";
1192                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1193                 }
1194                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1195                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1196                          default => $ask_default);
1197                 die "Send this email reply required" unless defined $_;
1198                 if (/^n/i) {
1199                         return 0;
1200                 } elsif (/^q/i) {
1201                         cleanup_compose_files();
1202                         exit(0);
1203                 } elsif (/^a/i) {
1204                         $confirm = 'never';
1205                 }
1206         }
1207
1208         unshift (@sendmail_parameters, @smtp_server_options);
1209
1210         if ($dry_run) {
1211                 # We don't want to send the email.
1212         } elsif (file_name_is_absolute($smtp_server)) {
1213                 my $pid = open my $sm, '|-';
1214                 defined $pid or die $!;
1215                 if (!$pid) {
1216                         exec($smtp_server, @sendmail_parameters) or die $!;
1217                 }
1218                 print $sm "$header\n$message";
1219                 close $sm or die $!;
1220         } else {
1221
1222                 if (!defined $smtp_server) {
1223                         die "The required SMTP server is not properly defined."
1224                 }
1225
1226                 if ($smtp_encryption eq 'ssl') {
1227                         $smtp_server_port ||= 465; # ssmtp
1228                         require Net::SMTP::SSL;
1229                         $smtp_domain ||= maildomain();
1230                         require IO::Socket::SSL;
1231                         # Net::SMTP::SSL->new() does not forward any SSL options
1232                         IO::Socket::SSL::set_client_defaults(
1233                                 ssl_verify_params());
1234                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1235                                                       Hello => $smtp_domain,
1236                                                       Port => $smtp_server_port,
1237                                                       Debug => $debug_net_smtp);
1238                 }
1239                 else {
1240                         require Net::SMTP;
1241                         $smtp_domain ||= maildomain();
1242                         $smtp_server_port ||= 25;
1243                         $smtp ||= Net::SMTP->new($smtp_server,
1244                                                  Hello => $smtp_domain,
1245                                                  Debug => $debug_net_smtp,
1246                                                  Port => $smtp_server_port);
1247                         if ($smtp_encryption eq 'tls' && $smtp) {
1248                                 require Net::SMTP::SSL;
1249                                 $smtp->command('STARTTLS');
1250                                 $smtp->response();
1251                                 if ($smtp->code == 220) {
1252                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1253                                                                           ssl_verify_params())
1254                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1255                                         $smtp_encryption = '';
1256                                         # Send EHLO again to receive fresh
1257                                         # supported commands
1258                                         $smtp->hello($smtp_domain);
1259                                 } else {
1260                                         die "Server does not support STARTTLS! ".$smtp->message;
1261                                 }
1262                         }
1263                 }
1264
1265                 if (!$smtp) {
1266                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1267                             "VALUES: server=$smtp_server ",
1268                             "encryption=$smtp_encryption ",
1269                             "hello=$smtp_domain",
1270                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1271                 }
1272
1273                 smtp_auth_maybe or die $smtp->message;
1274
1275                 $smtp->mail( $raw_from ) or die $smtp->message;
1276                 $smtp->to( @recipients ) or die $smtp->message;
1277                 $smtp->data or die $smtp->message;
1278                 $smtp->datasend("$header\n$message") or die $smtp->message;
1279                 $smtp->dataend() or die $smtp->message;
1280                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1281         }
1282         if ($quiet) {
1283                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1284         } else {
1285                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1286                 if (!file_name_is_absolute($smtp_server)) {
1287                         print "Server: $smtp_server\n";
1288                         print "MAIL FROM:<$raw_from>\n";
1289                         foreach my $entry (@recipients) {
1290                             print "RCPT TO:<$entry>\n";
1291                         }
1292                 } else {
1293                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1294                 }
1295                 print $header, "\n";
1296                 if ($smtp) {
1297                         print "Result: ", $smtp->code, ' ',
1298                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1299                 } else {
1300                         print "Result: OK\n";
1301                 }
1302         }
1303
1304         return 1;
1305 }
1306
1307 $reply_to = $initial_reply_to;
1308 $references = $initial_reply_to || '';
1309 $subject = $initial_subject;
1310 $message_num = 0;
1311
1312 foreach my $t (@files) {
1313         open my $fh, "<", $t or die "can't open file $t";
1314
1315         my $author = undef;
1316         my $sauthor = undef;
1317         my $author_encoding;
1318         my $has_content_type;
1319         my $body_encoding;
1320         @to = ();
1321         @cc = ();
1322         @xh = ();
1323         my $input_format = undef;
1324         my @header = ();
1325         $message = "";
1326         $message_num++;
1327         # First unfold multiline header fields
1328         while(<$fh>) {
1329                 last if /^\s*$/;
1330                 if (/^\s+\S/ and @header) {
1331                         chomp($header[$#header]);
1332                         s/^\s+/ /;
1333                         $header[$#header] .= $_;
1334             } else {
1335                         push(@header, $_);
1336                 }
1337         }
1338         # Now parse the header
1339         foreach(@header) {
1340                 if (/^From /) {
1341                         $input_format = 'mbox';
1342                         next;
1343                 }
1344                 chomp;
1345                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1346                         $input_format = 'mbox';
1347                 }
1348
1349                 if (defined $input_format && $input_format eq 'mbox') {
1350                         if (/^Subject:\s+(.*)$/i) {
1351                                 $subject = $1;
1352                         }
1353                         elsif (/^From:\s+(.*)$/i) {
1354                                 ($author, $author_encoding) = unquote_rfc2047($1);
1355                                 $sauthor = sanitize_address($author);
1356                                 next if $suppress_cc{'author'};
1357                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1358                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1359                                         $1, $_) unless $quiet;
1360                                 push @cc, $1;
1361                         }
1362                         elsif (/^To:\s+(.*)$/i) {
1363                                 foreach my $addr (parse_address_line($1)) {
1364                                         printf("(mbox) Adding to: %s from line '%s'\n",
1365                                                 $addr, $_) unless $quiet;
1366                                         push @to, $addr;
1367                                 }
1368                         }
1369                         elsif (/^Cc:\s+(.*)$/i) {
1370                                 foreach my $addr (parse_address_line($1)) {
1371                                         my $qaddr = unquote_rfc2047($addr);
1372                                         my $saddr = sanitize_address($qaddr);
1373                                         if ($saddr eq $sender) {
1374                                                 next if ($suppress_cc{'self'});
1375                                         } else {
1376                                                 next if ($suppress_cc{'cc'});
1377                                         }
1378                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1379                                                 $addr, $_) unless $quiet;
1380                                         push @cc, $addr;
1381                                 }
1382                         }
1383                         elsif (/^Content-type:/i) {
1384                                 $has_content_type = 1;
1385                                 if (/charset="?([^ "]+)/) {
1386                                         $body_encoding = $1;
1387                                 }
1388                                 push @xh, $_;
1389                         }
1390                         elsif (/^Message-Id: (.*)/i) {
1391                                 $message_id = $1;
1392                         }
1393                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1394                                 push @xh, $_;
1395                         }
1396
1397                 } else {
1398                         # In the traditional
1399                         # "send lots of email" format,
1400                         # line 1 = cc
1401                         # line 2 = subject
1402                         # So let's support that, too.
1403                         $input_format = 'lots';
1404                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1405                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1406                                         $_, $_) unless $quiet;
1407                                 push @cc, $_;
1408                         } elsif (!defined $subject) {
1409                                 $subject = $_;
1410                         }
1411                 }
1412         }
1413         # Now parse the message body
1414         while(<$fh>) {
1415                 $message .=  $_;
1416                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1417                         chomp;
1418                         my ($what, $c) = ($1, $2);
1419                         chomp $c;
1420                         my $sc = sanitize_address($c);
1421                         if ($sc eq $sender) {
1422                                 next if ($suppress_cc{'self'});
1423                         } else {
1424                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1425                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1426                         }
1427                         push @cc, $c;
1428                         printf("(body) Adding cc: %s from line '%s'\n",
1429                                 $c, $_) unless $quiet;
1430                 }
1431         }
1432         close $fh;
1433
1434         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1435                 if defined $to_cmd;
1436         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1437                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1438
1439         if ($broken_encoding{$t} && !$has_content_type) {
1440                 $has_content_type = 1;
1441                 push @xh, "MIME-Version: 1.0",
1442                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1443                         "Content-Transfer-Encoding: 8bit";
1444                 $body_encoding = $auto_8bit_encoding;
1445         }
1446
1447         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1448                 $subject = quote_subject($subject, $auto_8bit_encoding);
1449         }
1450
1451         if (defined $sauthor and $sauthor ne $sender) {
1452                 $message = "From: $author\n\n$message";
1453                 if (defined $author_encoding) {
1454                         if ($has_content_type) {
1455                                 if ($body_encoding eq $author_encoding) {
1456                                         # ok, we already have the right encoding
1457                                 }
1458                                 else {
1459                                         # uh oh, we should re-encode
1460                                 }
1461                         }
1462                         else {
1463                                 $has_content_type = 1;
1464                                 push @xh,
1465                                   'MIME-Version: 1.0',
1466                                   "Content-Type: text/plain; charset=$author_encoding",
1467                                   'Content-Transfer-Encoding: 8bit';
1468                         }
1469                 }
1470         }
1471
1472         $needs_confirm = (
1473                 $confirm eq "always" or
1474                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1475                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1476         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1477
1478         @to = validate_address_list(sanitize_address_list(@to));
1479         @cc = validate_address_list(sanitize_address_list(@cc));
1480
1481         @to = (@initial_to, @to);
1482         @cc = (@initial_cc, @cc);
1483
1484         my $message_was_sent = send_message();
1485
1486         # set up for the next message
1487         if ($thread && $message_was_sent &&
1488                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1489                 $message_num == 1)) {
1490                 $reply_to = $message_id;
1491                 if (length $references > 0) {
1492                         $references .= "\n $message_id";
1493                 } else {
1494                         $references = "$message_id";
1495                 }
1496         }
1497         $message_id = undef;
1498 }
1499
1500 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1501 # and return a results array
1502 sub recipients_cmd {
1503         my ($prefix, $what, $cmd, $file) = @_;
1504
1505         my @addresses = ();
1506         open my $fh, "-|", "$cmd \Q$file\E"
1507             or die "($prefix) Could not execute '$cmd'";
1508         while (my $address = <$fh>) {
1509                 $address =~ s/^\s*//g;
1510                 $address =~ s/\s*$//g;
1511                 $address = sanitize_address($address);
1512                 next if ($address eq $sender and $suppress_cc{'self'});
1513                 push @addresses, $address;
1514                 printf("($prefix) Adding %s: %s from: '%s'\n",
1515                        $what, $address, $cmd) unless $quiet;
1516                 }
1517         close $fh
1518             or die "($prefix) failed to close pipe to '$cmd'";
1519         return @addresses;
1520 }
1521
1522 cleanup_compose_files();
1523
1524 sub cleanup_compose_files {
1525         unlink($compose_filename, $compose_filename . ".final") if $compose;
1526 }
1527
1528 $smtp->quit if $smtp;
1529
1530 sub unique_email_list {
1531         my %seen;
1532         my @emails;
1533
1534         foreach my $entry (@_) {
1535                 my $clean = extract_valid_address_or_die($entry);
1536                 $seen{$clean} ||= 0;
1537                 next if $seen{$clean}++;
1538                 push @emails, $entry;
1539         }
1540         return @emails;
1541 }
1542
1543 sub validate_patch {
1544         my $fn = shift;
1545         open(my $fh, '<', $fn)
1546                 or die "unable to open $fn: $!\n";
1547         while (my $line = <$fh>) {
1548                 if (length($line) > 998) {
1549                         return "$.: patch contains a line longer than 998 characters";
1550                 }
1551         }
1552         return;
1553 }
1554
1555 sub file_has_nonascii {
1556         my $fn = shift;
1557         open(my $fh, '<', $fn)
1558                 or die "unable to open $fn: $!\n";
1559         while (my $line = <$fh>) {
1560                 return 1 if $line =~ /[^[:ascii:]]/;
1561         }
1562         return 0;
1563 }
1564
1565 sub body_or_subject_has_nonascii {
1566         my $fn = shift;
1567         open(my $fh, '<', $fn)
1568                 or die "unable to open $fn: $!\n";
1569         while (my $line = <$fh>) {
1570                 last if $line =~ /^$/;
1571                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1572         }
1573         while (my $line = <$fh>) {
1574                 return 1 if $line =~ /[^[:ascii:]]/;
1575         }
1576         return 0;
1577 }