git.oblomov.eu Git - git/blob - git-gui/lib/blame.tcl

   1 # git-gui blame viewer
   2 # Copyright (C) 2006, 2007 Shawn Pearce
   3
   4 class blame {
   5
   6 image create photo ::blame::img_back_arrow -data {R0lGODlhGAAYAIUAAPwCBEzKXFTSZIz+nGzmhGzqfGTidIT+nEzGXHTqhGzmfGzifFzadETCVES+VARWDFzWbHzyjAReDGTadFTOZDSyRDyyTCymPARaFGTedFzSbDy2TCyqRCyqPARaDAyCHES6VDy6VCyiPAR6HCSeNByWLARyFARiDARqFGTifARiFAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAYABgAAAajQIBwSCwaj8ikcsk0BppJwRPqHEypQwHBis0WDAdEFyBIKBaMAKLBdjQeSkFBYTBAIvgEoS6JmhUTEwIUDQ4VFhcMGEhyCgoZExoUaxsWHB0THkgfAXUGAhoBDSAVFR0XBnCbDRmgog0hpSIiDJpJIyEQhBUcJCIlwA22SSYVogknEg8eD82qSigdDSknY0IqJQXPYxIl1dZCGNvWw+Dm510GQQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
   7
   8 # Persistent data (survives loads)
   9 #
  10 field history {}; # viewer history: {commit path}
  11 field header    ; # array commit,key -> header field
  12
  13 # Tk UI control paths
  14 #
  15 field w          ; # top window in this viewer
  16 field w_back     ; # our back button
  17 field w_path     ; # label showing the current file path
  18 field w_columns  ; # list of all column widgets in the viewer
  19 field w_line     ; # text column: all line numbers
  20 field w_amov     ; # text column: annotations + move tracking
  21 field w_asim     ; # text column: annotations (simple computation)
  22 field w_file     ; # text column: actual file data
  23 field w_cviewer  ; # pane showing commit message
  24 field finder     ; # find mini-dialog frame
  25 field gotoline   ; # line goto mini-dialog frame
  26 field status     ; # status mega-widget instance
  27 field old_height ; # last known height of $w.file_pane
  28
  29
  30 # Tk UI colors
  31 #
  32 variable active_color #c0edc5
  33 variable group_colors {
  34         #d6d6d6
  35         #e1e1e1
  36         #ececec
  37 }
  38
  39 # Current blame data; cleared/reset on each load
  40 #
  41 field commit               ; # input commit to blame
  42 field path                 ; # input filename to view in $commit
  43
  44 field current_fd        {} ; # background process running
  45 field highlight_line    -1 ; # current line selected
  46 field highlight_column  {} ; # current commit column selected
  47 field highlight_commit  {} ; # sha1 of commit selected
  48
  49 field total_lines       0  ; # total length of file
  50 field blame_lines       0  ; # number of lines computed
  51 field amov_data            ; # list of {commit origfile origline}
  52 field asim_data            ; # list of {commit origfile origline}
  53
  54 field r_commit             ; # commit currently being parsed
  55 field r_orig_line          ; # original line number
  56 field r_final_line         ; # final line number
  57 field r_line_count         ; # lines in this region
  58
  59 field tooltip_wm        {} ; # Current tooltip toplevel, if open
  60 field tooltip_t         {} ; # Text widget in $tooltip_wm
  61 field tooltip_timer     {} ; # Current timer event for our tooltip
  62 field tooltip_commit    {} ; # Commit(s) in tooltip
  63
  64 constructor new {i_commit i_path i_jump} {
  65         global cursor_ptr M1B M1T have_tk85 use_ttk NS
  66         variable active_color
  67         variable group_colors
  68
  69         set commit $i_commit
  70         set path   $i_path
  71
  72         make_toplevel top w
  73         wm title $top [append "[appname] ([reponame]): " [mc "File Viewer"]]
  74
  75         set font_w [font measure font_diff "0"]
  76
  77         gold_frame $w.header
  78         tlabel $w.header.commit_l \
  79                 -text [mc "Commit:"] \
  80                 -background gold \
  81                 -foreground black \
  82                 -anchor w \
  83                 -justify left
  84         set w_back $w.header.commit_b
  85         tlabel $w_back \
  86                 -image ::blame::img_back_arrow \
  87                 -borderwidth 0 \
  88                 -relief flat \
  89                 -state disabled \
  90                 -background gold \
  91                 -foreground black \
  92                 -activebackground gold
  93         bind $w_back <Button-1> "
  94                 if {\[$w_back cget -state\] eq {normal}} {
  95                         [cb _history_menu]
  96                 }
  97                 "
  98         tlabel $w.header.commit \
  99                 -textvariable @commit \
 100                 -background gold \
 101                 -foreground black \
 102                 -anchor w \
 103                 -justify left
 104         tlabel $w.header.path_l \
 105                 -text [mc "File:"] \
 106                 -background gold \
 107                 -foreground black \
 108                 -anchor w \
 109                 -justify left
 110         set w_path $w.header.path
 111         tlabel $w_path \
 112                 -background gold \
 113                 -foreground black \
 114                 -anchor w \
 115                 -justify left
 116         pack $w.header.commit_l -side left
 117         pack $w_back -side left
 118         pack $w.header.commit -side left
 119         pack $w_path -fill x -side right
 120         pack $w.header.path_l -side right
 121
 122         panedwindow $w.file_pane -orient vertical -borderwidth 0 -sashwidth 3
 123         frame $w.file_pane.out -relief flat -borderwidth 1
 124         frame $w.file_pane.cm -relief sunken -borderwidth 1
 125         $w.file_pane add $w.file_pane.out \
 126                 -sticky nsew \
 127                 -minsize 100 \
 128                 -height 100 \
 129                 -width 100
 130         $w.file_pane add $w.file_pane.cm \
 131                 -sticky nsew \
 132                 -minsize 25 \
 133                 -height 25 \
 134                 -width 100
 135
 136         set w_line $w.file_pane.out.linenumber_t
 137         text $w_line \
 138                 -takefocus 0 \
 139                 -highlightthickness 0 \
 140                 -padx 0 -pady 0 \
 141                 -background white \
 142                 -foreground black \
 143                 -borderwidth 0 \
 144                 -state disabled \
 145                 -wrap none \
 146                 -height 40 \
 147                 -width 6 \
 148                 -font font_diff
 149         $w_line tag conf linenumber -justify right -rmargin 5
 150
 151         set w_amov $w.file_pane.out.amove_t
 152         text $w_amov \
 153                 -takefocus 0 \
 154                 -highlightthickness 0 \
 155                 -padx 0 -pady 0 \
 156                 -background white \
 157                 -foreground black \
 158                 -borderwidth 0 \
 159                 -state disabled \
 160                 -wrap none \
 161                 -height 40 \
 162                 -width 5 \
 163                 -font font_diff
 164         $w_amov tag conf author_abbr -justify right -rmargin 5
 165         $w_amov tag conf curr_commit
 166         $w_amov tag conf prior_commit -foreground blue -underline 1
 167         $w_amov tag bind prior_commit \
 168                 <Button-1> \
 169                 "[cb _load_commit $w_amov @amov_data @%x,%y];break"
 170
 171         set w_asim $w.file_pane.out.asimple_t
 172         text $w_asim \
 173                 -takefocus 0 \
 174                 -highlightthickness 0 \
 175                 -padx 0 -pady 0 \
 176                 -background white \
 177                 -foreground black \
 178                 -borderwidth 0 \
 179                 -state disabled \
 180                 -wrap none \
 181                 -height 40 \
 182                 -width 4 \
 183                 -font font_diff
 184         $w_asim tag conf author_abbr -justify right
 185         $w_asim tag conf curr_commit
 186         $w_asim tag conf prior_commit -foreground blue -underline 1
 187         $w_asim tag bind prior_commit \
 188                 <Button-1> \
 189                 "[cb _load_commit $w_asim @asim_data @%x,%y];break"
 190
 191         set w_file $w.file_pane.out.file_t
 192         text $w_file \
 193                 -takefocus 0 \
 194                 -highlightthickness 0 \
 195                 -padx 0 -pady 0 \
 196                 -background white \
 197                 -foreground black \
 198                 -borderwidth 0 \
 199                 -state disabled \
 200                 -wrap none \
 201                 -height 40 \
 202                 -width 80 \
 203                 -xscrollcommand [list $w.file_pane.out.sbx set] \
 204                 -font font_diff
 205         if {$have_tk85} {
 206                 $w_file configure -inactiveselectbackground darkblue
 207         }
 208         $w_file tag conf found \
 209                 -background yellow
 210
 211         set w_columns [list $w_amov $w_asim $w_line $w_file]
 212
 213         ${NS}::scrollbar $w.file_pane.out.sbx \
 214                 -orient h \
 215                 -command [list $w_file xview]
 216         ${NS}::scrollbar $w.file_pane.out.sby \
 217                 -orient v \
 218                 -command [list scrollbar2many $w_columns yview]
 219         eval grid $w_columns $w.file_pane.out.sby -sticky nsew
 220         grid conf \
 221                 $w.file_pane.out.sbx \
 222                 -column 0 \
 223                 -columnspan [expr {[llength $w_columns] + 1}] \
 224                 -sticky we
 225         grid columnconfigure \
 226                 $w.file_pane.out \
 227                 [expr {[llength $w_columns] - 1}] \
 228                 -weight 1
 229         grid rowconfigure $w.file_pane.out 0 -weight 1
 230
 231         set finder [::searchbar::new \
 232                 $w.file_pane.out.ff $w_file \
 233                 -column 0 \
 234                 -columnspan [expr {[llength $w_columns] + 1}] \
 235                 ]
 236
 237         set gotoline [::linebar::new \
 238                 $w.file_pane.out.lf $w_file \
 239                 -column 0 \
 240                 -columnspan [expr {[llength $w_columns] + 1}] \
 241                 ]
 242
 243         set w_cviewer $w.file_pane.cm.t
 244         text $w_cviewer \
 245                 -background white \
 246                 -foreground black \
 247                 -borderwidth 0 \
 248                 -state disabled \
 249                 -wrap none \
 250                 -height 10 \
 251                 -width 80 \
 252                 -xscrollcommand [list $w.file_pane.cm.sbx set] \
 253                 -yscrollcommand [list $w.file_pane.cm.sby set] \
 254                 -font font_diff
 255         $w_cviewer tag conf still_loading \
 256                 -font font_uiitalic \
 257                 -justify center
 258         $w_cviewer tag conf header_key \
 259                 -tabs {3c} \
 260                 -background $active_color \
 261                 -font font_uibold
 262         $w_cviewer tag conf header_val \
 263                 -background $active_color \
 264                 -font font_ui
 265         $w_cviewer tag raise sel
 266         ${NS}::scrollbar $w.file_pane.cm.sbx \
 267                 -orient h \
 268                 -command [list $w_cviewer xview]
 269         ${NS}::scrollbar $w.file_pane.cm.sby \
 270                 -orient v \
 271                 -command [list $w_cviewer yview]
 272         pack $w.file_pane.cm.sby -side right -fill y
 273         pack $w.file_pane.cm.sbx -side bottom -fill x
 274         pack $w_cviewer -expand 1 -fill both
 275
 276         set status [::status_bar::new $w.status]
 277
 278         menu $w.ctxm -tearoff 0
 279         $w.ctxm add command \
 280                 -label [mc "Copy Commit"] \
 281                 -command [cb _copycommit]
 282         $w.ctxm add separator
 283         $w.ctxm add command \
 284                 -label [mc "Find Text..."] \
 285                 -accelerator F7 \
 286                 -command [cb _show_finder]
 287         $w.ctxm add command \
 288                 -label [mc "Goto Line..."] \
 289                 -accelerator "Ctrl-G" \
 290                 -command [cb _show_linebar]
 291         menu $w.ctxm.enc
 292         build_encoding_menu $w.ctxm.enc [cb _setencoding]
 293         $w.ctxm add cascade \
 294                 -label [mc "Encoding"] \
 295                 -menu $w.ctxm.enc
 296         $w.ctxm add command \
 297                 -label [mc "Do Full Copy Detection"] \
 298                 -command [cb _fullcopyblame]
 299         $w.ctxm add separator
 300         $w.ctxm add command \
 301                 -label [mc "Show History Context"] \
 302                 -command [cb _gitkcommit]
 303         $w.ctxm add command \
 304                 -label [mc "Blame Parent Commit"] \
 305                 -command [cb _blameparent]
 306
 307         foreach i $w_columns {
 308                 for {set g 0} {$g < [llength $group_colors]} {incr g} {
 309                         $i tag conf color$g -background [lindex $group_colors $g]
 310                 }
 311
 312                 if {$i eq $w_file} {
 313                         $w_file tag raise found
 314                 }
 315                 $i tag raise sel
 316
 317                 $i conf -cursor $cursor_ptr
 318                 $i conf -yscrollcommand \
 319                         "[list ::searchbar::scrolled $finder]
 320                          [list many2scrollbar $w_columns yview $w.file_pane.out.sby]"
 321                 bind $i <Button-1> "
 322                         [cb _hide_tooltip]
 323                         [cb _click $i @%x,%y]
 324                         focus $i
 325                 "
 326                 bind $i <Any-Motion>  [cb _show_tooltip $i @%x,%y]
 327                 bind $i <Any-Enter>   [cb _hide_tooltip]
 328                 bind $i <Any-Leave>   [cb _hide_tooltip]
 329                 bind_button3 $i "
 330                         [cb _hide_tooltip]
 331                         set cursorX %x
 332                         set cursorY %y
 333                         set cursorW %W
 334                         tk_popup $w.ctxm %X %Y
 335                 "
 336                 bind $i <Shift-Tab> "[list focus $w_cviewer];break"
 337                 bind $i <Tab>       "[cb _focus_search $w_cviewer];break"
 338         }
 339
 340         foreach i [concat $w_columns $w_cviewer] {
 341                 bind $i <Key-Up>        {catch {%W yview scroll -1 units};break}
 342                 bind $i <Key-Down>      {catch {%W yview scroll  1 units};break}
 343                 bind $i <Key-Left>      {catch {%W xview scroll -1 units};break}
 344                 bind $i <Key-Right>     {catch {%W xview scroll  1 units};break}
 345                 bind $i <Key-k>         {catch {%W yview scroll -1 units};break}
 346                 bind $i <Key-j>         {catch {%W yview scroll  1 units};break}
 347                 bind $i <Key-h>         {catch {%W xview scroll -1 units};break}
 348                 bind $i <Key-l>         {catch {%W xview scroll  1 units};break}
 349                 bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
 350                 bind $i <Control-Key-f> {catch {%W yview scroll  1 pages};break}
 351         }
 352
 353         bind $w_cviewer <Shift-Tab> "[cb _focus_search $w_file];break"
 354         bind $w_cviewer <Tab>       "[list focus $w_file];break"
 355         bind $w_cviewer <Button-1>   [list focus $w_cviewer]
 356         bind $w_file    <Visibility> [cb _focus_search $w_file]
 357         bind $top       <F7>         [cb _show_finder]
 358         bind $top       <Key-slash>  [cb _show_finder]
 359         bind $top    <Control-Key-s> [cb _show_finder]
 360         bind $top       <Escape>     [list searchbar::hide $finder]
 361         bind $top       <F3>         [list searchbar::find_next $finder]
 362         bind $top       <Shift-F3>   [list searchbar::find_prev $finder]
 363         bind $top    <Control-Key-g> [cb _show_linebar]
 364         catch { bind $top <Shift-Key-XF86_Switch_VT_3> [list searchbar::find_prev $finder] }
 365
 366         grid configure $w.header -sticky ew
 367         grid configure $w.file_pane -sticky nsew
 368         grid configure $w.status -sticky ew
 369         grid columnconfigure $top 0 -weight 1
 370         grid rowconfigure $top 0 -weight 0
 371         grid rowconfigure $top 1 -weight 1
 372         grid rowconfigure $top 2 -weight 0
 373
 374         set req_w [winfo reqwidth  $top]
 375         set req_h [winfo reqheight $top]
 376         set scr_w [expr {[winfo screenwidth $top] - 40}]
 377         set scr_h [expr {[winfo screenheight $top] - 120}]
 378         set opt_w [expr {$font_w * (80 + 5*3 + 3)}]
 379         if {$req_w < $opt_w} {set req_w $opt_w}
 380         if {$req_w > $scr_w} {set req_w $scr_w}
 381         set opt_h [expr {$req_w*4/3}]
 382         if {$req_h < $scr_h} {set req_h $scr_h}
 383         if {$req_h > $opt_h} {set req_h $opt_h}
 384         set g "${req_w}x${req_h}"
 385         wm geometry $top $g
 386         update
 387
 388         set old_height [winfo height $w.file_pane]
 389         $w.file_pane sash place 0 \
 390                 [lindex [$w.file_pane sash coord 0] 0] \
 391                 [expr {int($old_height * 0.80)}]
 392         bind $w.file_pane <Configure> \
 393         "if {{$w.file_pane} eq {%W}} {[cb _resize %h]}"
 394
 395         wm protocol $top WM_DELETE_WINDOW "destroy $top"
 396         bind $top <Destroy> [cb _handle_destroy %W]
 397
 398         _load $this $i_jump
 399 }
 400
 401 method _focus_search {win} {
 402         if {[searchbar::visible $finder]} {
 403                 focus [searchbar::editor $finder]
 404         } else {
 405                 focus $win
 406         }
 407 }
 408
 409 method _handle_destroy {win} {
 410         if {$win eq $w} {
 411                 _kill $this
 412                 delete_this
 413         }
 414 }
 415
 416 method _kill {} {
 417         if {$current_fd ne {}} {
 418                 kill_file_process $current_fd
 419                 catch {close $current_fd}
 420                 set current_fd {}
 421         }
 422 }
 423
 424 method _load {jump} {
 425         variable group_colors
 426
 427         _hide_tooltip $this
 428
 429         if {$total_lines != 0 || $current_fd ne {}} {
 430                 _kill $this
 431
 432                 foreach i $w_columns {
 433                         $i conf -state normal
 434                         $i delete 0.0 end
 435                         foreach g [$i tag names] {
 436                                 if {[regexp {^g[0-9a-f]{40}$} $g]} {
 437                                         $i tag delete $g
 438                                 }
 439                         }
 440                         $i conf -state disabled
 441                 }
 442
 443                 $w_cviewer conf -state normal
 444                 $w_cviewer delete 0.0 end
 445                 $w_cviewer conf -state disabled
 446
 447                 set highlight_line -1
 448                 set highlight_column {}
 449                 set highlight_commit {}
 450                 set total_lines 0
 451         }
 452
 453         if {$history eq {}} {
 454                 $w_back conf -state disabled
 455         } else {
 456                 $w_back conf -state normal
 457         }
 458
 459         # Index 0 is always empty.  There is never line 0 as
 460         # we use only 1 based lines, as that matches both with
 461         # git-blame output and with Tk's text widget.
 462         #
 463         set amov_data [list [list]]
 464         set asim_data [list [list]]
 465
 466         $status show [mc "Reading %s..." "$commit:[escape_path $path]"]
 467         $w_path conf -text [escape_path $path]
 468
 469         set do_textconv 0
 470         if {![is_config_false gui.textconv] && [git-version >= 1.7.2]} {
 471                 set filter [gitattr $path diff set]
 472                 set textconv [get_config [join [list diff $filter textconv] .]]
 473                 if {$filter ne {set} && $textconv ne {}} {
 474                         set do_textconv 1
 475                 }
 476         }
 477         if {$commit eq {}} {
 478                 if {$do_textconv ne 0} {
 479                         set fd [open_cmd_pipe $textconv $path]
 480                 } else {
 481                         set fd [open $path r]
 482                 }
 483                 fconfigure $fd -eofchar {}
 484         } else {
 485                 if {$do_textconv ne 0} {
 486                         set fd [git_read cat-file --textconv "$commit:$path"]
 487                 } else {
 488                         set fd [git_read cat-file blob "$commit:$path"]
 489                 }
 490         }
 491         fconfigure $fd \
 492                 -blocking 0 \
 493                 -translation lf \
 494                 -encoding [get_path_encoding $path]
 495         fileevent $fd readable [cb _read_file $fd $jump]
 496         set current_fd $fd
 497 }
 498
 499 method _history_menu {} {
 500         set m $w.backmenu
 501         if {[winfo exists $m]} {
 502                 $m delete 0 end
 503         } else {
 504                 menu $m -tearoff 0
 505         }
 506
 507         for {set i [expr {[llength $history] - 1}]
 508                 } {$i >= 0} {incr i -1} {
 509                 set e [lindex $history $i]
 510                 set c [lindex $e 0]
 511                 set f [lindex $e 1]
 512
 513                 if {[regexp {^[0-9a-f]{40}$} $c]} {
 514                         set t [string range $c 0 8]...
 515                 } elseif {$c eq {}} {
 516                         set t {Working Directory}
 517                 } else {
 518                         set t $c
 519                 }
 520                 if {![catch {set summary $header($c,summary)}]} {
 521                         append t " $summary"
 522                         if {[string length $t] > 70} {
 523                                 set t [string range $t 0 66]...
 524                         }
 525                 }
 526
 527                 $m add command -label $t -command [cb _goback $i]
 528         }
 529         set X [winfo rootx $w_back]
 530         set Y [expr {[winfo rooty $w_back] + [winfo height $w_back]}]
 531         tk_popup $m $X $Y
 532 }
 533
 534 method _goback {i} {
 535         set dat [lindex $history $i]
 536         set history [lrange $history 0 [expr {$i - 1}]]
 537         set commit [lindex $dat 0]
 538         set path [lindex $dat 1]
 539         _load $this [lrange $dat 2 5]
 540 }
 541
 542 method _read_file {fd jump} {
 543         if {$fd ne $current_fd} {
 544                 catch {close $fd}
 545                 return
 546         }
 547
 548         foreach i $w_columns {$i conf -state normal}
 549         while {[gets $fd line] >= 0} {
 550                 regsub "\r\$" $line {} line
 551                 incr total_lines
 552                 lappend amov_data {}
 553                 lappend asim_data {}
 554
 555                 if {$total_lines > 1} {
 556                         foreach i $w_columns {$i insert end "\n"}
 557                 }
 558
 559                 $w_line insert end "$total_lines" linenumber
 560                 $w_file insert end "$line"
 561         }
 562
 563         set ln_wc [expr {[string length $total_lines] + 2}]
 564         if {[$w_line cget -width] < $ln_wc} {
 565                 $w_line conf -width $ln_wc
 566         }
 567
 568         foreach i $w_columns {$i conf -state disabled}
 569
 570         if {[eof $fd]} {
 571                 fconfigure $fd -blocking 1; # enable error reporting on close
 572                 if {[catch {close $fd} err]} {
 573                         tk_messageBox -icon error -title [mc Error] \
 574                                 -message $err
 575                 }
 576
 577                 # If we don't force Tk to update the widgets *right now*
 578                 # none of our jump commands will cause a change in the UI.
 579                 #
 580                 update
 581
 582                 if {[llength $jump] == 1} {
 583                         set highlight_line [lindex $jump 0]
 584                         $w_file see "$highlight_line.0"
 585                 } elseif {[llength $jump] == 4} {
 586                         set highlight_column [lindex $jump 0]
 587                         set highlight_line [lindex $jump 1]
 588                         $w_file xview moveto [lindex $jump 2]
 589                         $w_file yview moveto [lindex $jump 3]
 590                 }
 591
 592                 _exec_blame $this $w_asim @asim_data \
 593                         [list] \
 594                         [mc "Loading copy/move tracking annotations..."]
 595         }
 596 } ifdeleted { catch {close $fd} }
 597
 598 method _exec_blame {cur_w cur_d options cur_s} {
 599         lappend options --incremental --encoding=utf-8
 600         if {$commit eq {}} {
 601                 lappend options --contents $path
 602         } else {
 603                 lappend options $commit
 604         }
 605         lappend options -- $path
 606         set fd [eval git_read --nice blame $options]
 607         fconfigure $fd -blocking 0 -translation lf -encoding utf-8
 608         fileevent $fd readable [cb _read_blame $fd $cur_w $cur_d]
 609         set current_fd $fd
 610         set blame_lines 0
 611
 612         $status start \
 613                 $cur_s \
 614                 [mc "lines annotated"]
 615 }
 616
 617 method _read_blame {fd cur_w cur_d} {
 618         upvar #0 $cur_d line_data
 619         variable group_colors
 620
 621         if {$fd ne $current_fd} {
 622                 catch {close $fd}
 623                 return
 624         }
 625
 626         $cur_w conf -state normal
 627         while {[gets $fd line] >= 0} {
 628                 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
 629                         cmit original_line final_line line_count]} {
 630                         set r_commit     $cmit
 631                         set r_orig_line  $original_line
 632                         set r_final_line $final_line
 633                         set r_line_count $line_count
 634                 } elseif {[string match {filename *} $line]} {
 635                         set file [string range $line 9 end]
 636                         set n    $r_line_count
 637                         set lno  $r_final_line
 638                         set oln  $r_orig_line
 639                         set cmit $r_commit
 640
 641                         if {[regexp {^0{40}$} $cmit]} {
 642                                 set commit_abbr work
 643                                 set commit_type curr_commit
 644                         } elseif {$cmit eq $commit} {
 645                                 set commit_abbr this
 646                                 set commit_type curr_commit
 647                         } else {
 648                                 set commit_type prior_commit
 649                                 set commit_abbr [string range $cmit 0 3]
 650                         }
 651
 652                         set author_abbr {}
 653                         set a_name {}
 654                         catch {set a_name $header($cmit,author)}
 655                         while {$a_name ne {}} {
 656                                 if {$author_abbr ne {}
 657                                         && [string index $a_name 0] eq {'}} {
 658                                         regsub {^'[^']+'\s+} $a_name {} a_name
 659                                 }
 660                                 if {![regexp {^([[:upper:]])} $a_name _a]} break
 661                                 append author_abbr $_a
 662                                 unset _a
 663                                 if {![regsub \
 664                                         {^[[:upper:]][^\s]*\s+} \
 665                                         $a_name {} a_name ]} break
 666                         }
 667                         if {$author_abbr eq {}} {
 668                                 set author_abbr { |}
 669                         } else {
 670                                 set author_abbr [string range $author_abbr 0 3]
 671                         }
 672                         unset a_name
 673
 674                         set first_lno $lno
 675                         while {
 676                            $first_lno > 1
 677                         && $cmit eq [lindex $line_data [expr {$first_lno - 1}] 0]
 678                         && $file eq [lindex $line_data [expr {$first_lno - 1}] 1]
 679                         } {
 680                                 incr first_lno -1
 681                         }
 682
 683                         set color {}
 684                         if {$first_lno < $lno} {
 685                                 foreach g [$w_file tag names $first_lno.0] {
 686                                         if {[regexp {^color[0-9]+$} $g]} {
 687                                                 set color $g
 688                                                 break
 689                                         }
 690                                 }
 691                         } else {
 692                                 set i [lsort [concat \
 693                                         [$w_file tag names "[expr {$first_lno - 1}].0"] \
 694                                         [$w_file tag names "[expr {$lno + $n}].0"] \
 695                                         ]]
 696                                 for {set g 0} {$g < [llength $group_colors]} {incr g} {
 697                                         if {[lsearch -sorted -exact $i color$g] == -1} {
 698                                                 set color color$g
 699                                                 break
 700                                         }
 701                                 }
 702                         }
 703                         if {$color eq {}} {
 704                                 set color color0
 705                         }
 706
 707                         while {$n > 0} {
 708                                 set lno_e "$lno.0 lineend + 1c"
 709                                 if {[lindex $line_data $lno] ne {}} {
 710                                         set g [lindex $line_data $lno 0]
 711                                         foreach i $w_columns {
 712                                                 $i tag remove g$g $lno.0 $lno_e
 713                                         }
 714                                 }
 715                                 lset line_data $lno [list $cmit $file $oln]
 716
 717                                 $cur_w delete $lno.0 "$lno.0 lineend"
 718                                 if {$lno == $first_lno} {
 719                                         $cur_w insert $lno.0 $commit_abbr $commit_type
 720                                 } elseif {$lno == [expr {$first_lno + 1}]} {
 721                                         $cur_w insert $lno.0 $author_abbr author_abbr
 722                                 } else {
 723                                         $cur_w insert $lno.0 { |}
 724                                 }
 725
 726                                 foreach i $w_columns {
 727                                         if {$cur_w eq $w_amov} {
 728                                                 for {set g 0} \
 729                                                         {$g < [llength $group_colors]} \
 730                                                         {incr g} {
 731                                                         $i tag remove color$g $lno.0 $lno_e
 732                                                 }
 733                                                 $i tag add $color $lno.0 $lno_e
 734                                         }
 735                                         $i tag add g$cmit $lno.0 $lno_e
 736                                 }
 737
 738                                 if {$highlight_column eq $cur_w} {
 739                                         if {$highlight_line == -1
 740                                          && [lindex [$w_file yview] 0] == 0} {
 741                                                 $w_file see $lno.0
 742                                                 set highlight_line $lno
 743                                         }
 744                                         if {$highlight_line == $lno} {
 745                                                 _showcommit $this $cur_w $lno
 746                                         }
 747                                 }
 748
 749                                 incr n -1
 750                                 incr lno
 751                                 incr oln
 752                                 incr blame_lines
 753                         }
 754
 755                         while {
 756                            $cmit eq [lindex $line_data $lno 0]
 757                         && $file eq [lindex $line_data $lno 1]
 758                         } {
 759                                 $cur_w delete $lno.0 "$lno.0 lineend"
 760
 761                                 if {$lno == $first_lno} {
 762                                         $cur_w insert $lno.0 $commit_abbr $commit_type
 763                                 } elseif {$lno == [expr {$first_lno + 1}]} {
 764                                         $cur_w insert $lno.0 $author_abbr author_abbr
 765                                 } else {
 766                                         $cur_w insert $lno.0 { |}
 767                                 }
 768
 769                                 if {$cur_w eq $w_amov} {
 770                                         foreach i $w_columns {
 771                                                 for {set g 0} \
 772                                                         {$g < [llength $group_colors]} \
 773                                                         {incr g} {
 774                                                         $i tag remove color$g $lno.0 $lno_e
 775                                                 }
 776                                                 $i tag add $color $lno.0 $lno_e
 777                                         }
 778                                 }
 779
 780                                 incr lno
 781                         }
 782
 783                 } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
 784                         set header($r_commit,$key) $data
 785                 }
 786         }
 787         $cur_w conf -state disabled
 788
 789         if {[eof $fd]} {
 790                 close $fd
 791                 if {$cur_w eq $w_asim} {
 792                         # Switches for original location detection
 793                         set threshold [get_config gui.copyblamethreshold]
 794                         set original_options [list "-C$threshold"]
 795
 796                         if {![is_config_true gui.fastcopyblame]} {
 797                                 # thorough copy search; insert before the threshold
 798                                 set original_options [linsert $original_options 0 -C]
 799                         }
 800                         if {[git-version >= 1.5.3]} {
 801                                 lappend original_options -w ; # ignore indentation changes
 802                         }
 803
 804                         _exec_blame $this $w_amov @amov_data \
 805                                 $original_options \
 806                                 [mc "Loading original location annotations..."]
 807                 } else {
 808                         set current_fd {}
 809                         $status stop [mc "Annotation complete."]
 810                 }
 811         } else {
 812                 $status update $blame_lines $total_lines
 813         }
 814 } ifdeleted { catch {close $fd} }
 815
 816 method _find_commit_bound {data_list start_idx delta} {
 817         upvar #0 $data_list line_data
 818         set pos $start_idx
 819         set limit       [expr {[llength $line_data] - 1}]
 820         set base_commit [lindex $line_data $pos 0]
 821
 822         while {$pos > 0 && $pos < $limit} {
 823                 set new_pos [expr {$pos + $delta}]
 824                 if {[lindex $line_data $new_pos 0] ne $base_commit} {
 825                         return $pos
 826                 }
 827
 828                 set pos $new_pos
 829         }
 830
 831         return $pos
 832 }
 833
 834 method _fullcopyblame {} {
 835         if {$current_fd ne {}} {
 836                 tk_messageBox \
 837                         -icon error \
 838                         -type ok \
 839                         -title [mc "Busy"] \
 840                         -message [mc "Annotation process is already running."]
 841
 842                 return
 843         }
 844
 845         # Switches for original location detection
 846         set threshold [get_config gui.copyblamethreshold]
 847         set original_options [list -C -C "-C$threshold"]
 848
 849         if {[git-version >= 1.5.3]} {
 850                 lappend original_options -w ; # ignore indentation changes
 851         }
 852
 853         # Find the line range
 854         set pos @$::cursorX,$::cursorY
 855         set lno [lindex [split [$::cursorW index $pos] .] 0]
 856         set min_amov_lno [_find_commit_bound $this @amov_data $lno -1]
 857         set max_amov_lno [_find_commit_bound $this @amov_data $lno 1]
 858         set min_asim_lno [_find_commit_bound $this @asim_data $lno -1]
 859         set max_asim_lno [_find_commit_bound $this @asim_data $lno 1]
 860
 861         if {$min_asim_lno < $min_amov_lno} {
 862                 set min_amov_lno $min_asim_lno
 863         }
 864
 865         if {$max_asim_lno > $max_amov_lno} {
 866                 set max_amov_lno $max_asim_lno
 867         }
 868
 869         lappend original_options -L "$min_amov_lno,$max_amov_lno"
 870
 871         # Clear lines
 872         for {set i $min_amov_lno} {$i <= $max_amov_lno} {incr i} {
 873                 lset amov_data $i [list ]
 874         }
 875
 876         # Start the back-end process
 877         _exec_blame $this $w_amov @amov_data \
 878                 $original_options \
 879                 [mc "Running thorough copy detection..."]
 880 }
 881
 882 method _click {cur_w pos} {
 883         set lno [lindex [split [$cur_w index $pos] .] 0]
 884         _showcommit $this $cur_w $lno
 885 }
 886
 887 method _setencoding {enc} {
 888         force_path_encoding $path $enc
 889         _load $this [list \
 890                 $highlight_column \
 891                 $highlight_line \
 892                 [lindex [$w_file xview] 0] \
 893                 [lindex [$w_file yview] 0] \
 894                 ]
 895 }
 896
 897 method _load_commit {cur_w cur_d pos} {
 898         upvar #0 $cur_d line_data
 899         set lno [lindex [split [$cur_w index $pos] .] 0]
 900         set dat [lindex $line_data $lno]
 901         if {$dat ne {}} {
 902                 _load_new_commit $this  \
 903                         [lindex $dat 0] \
 904                         [lindex $dat 1] \
 905                         [list [lindex $dat 2]]
 906         }
 907 }
 908
 909 method _load_new_commit {new_commit new_path jump} {
 910         lappend history [list \
 911                 $commit $path \
 912                 $highlight_column \
 913                 $highlight_line \
 914                 [lindex [$w_file xview] 0] \
 915                 [lindex [$w_file yview] 0] \
 916                 ]
 917
 918         set commit $new_commit
 919         set path   $new_path
 920         _load $this $jump
 921 }
 922
 923 method _showcommit {cur_w lno} {
 924         global repo_config
 925         variable active_color
 926
 927         if {$highlight_commit ne {}} {
 928                 foreach i $w_columns {
 929                         $i tag conf g$highlight_commit -background {}
 930                         $i tag lower g$highlight_commit
 931                 }
 932         }
 933
 934         if {$cur_w eq $w_asim} {
 935                 set dat [lindex $asim_data $lno]
 936                 set highlight_column $w_asim
 937         } else {
 938                 set dat [lindex $amov_data $lno]
 939                 set highlight_column $w_amov
 940         }
 941
 942         $w_cviewer conf -state normal
 943         $w_cviewer delete 0.0 end
 944
 945         if {$dat eq {}} {
 946                 set cmit {}
 947                 $w_cviewer insert end [mc "Loading annotation..."] still_loading
 948         } else {
 949                 set cmit [lindex $dat 0]
 950                 set file [lindex $dat 1]
 951
 952                 foreach i $w_columns {
 953                         $i tag conf g$cmit -background $active_color
 954                         $i tag raise g$cmit
 955                         if {$i eq $w_file} {
 956                                 $w_file tag raise found
 957                         }
 958                         $i tag raise sel
 959                 }
 960
 961                 set author_name {}
 962                 set author_email {}
 963                 set author_time {}
 964                 catch {set author_name $header($cmit,author)}
 965                 catch {set author_email $header($cmit,author-mail)}
 966                 catch {set author_time [format_date $header($cmit,author-time)]}
 967
 968                 set committer_name {}
 969                 set committer_email {}
 970                 set committer_time {}
 971                 catch {set committer_name $header($cmit,committer)}
 972                 catch {set committer_email $header($cmit,committer-mail)}
 973                 catch {set committer_time [format_date $header($cmit,committer-time)]}
 974
 975                 if {[catch {set msg $header($cmit,message)}]} {
 976                         set msg {}
 977                         catch {
 978                                 set fd [git_read cat-file commit $cmit]
 979                                 fconfigure $fd -encoding binary -translation lf
 980                                 # By default commits are assumed to be in utf-8
 981                                 set enc utf-8
 982                                 while {[gets $fd line] > 0} {
 983                                         if {[string match {encoding *} $line]} {
 984                                                 set enc [string tolower [string range $line 9 end]]
 985                                         }
 986                                 }
 987                                 set msg [read $fd]
 988                                 close $fd
 989
 990                                 set enc [tcl_encoding $enc]
 991                                 if {$enc ne {}} {
 992                                         set msg [encoding convertfrom $enc $msg]
 993                                 }
 994                                 set msg [string trim $msg]
 995                         }
 996                         set header($cmit,message) $msg
 997                 }
 998
 999                 $w_cviewer insert end "commit $cmit\n" header_key
1000                 $w_cviewer insert end [strcat [mc "Author:"] "\t"] header_key
1001                 $w_cviewer insert end "$author_name $author_email" header_val
1002                 $w_cviewer insert end "  $author_time\n" header_val
1003
1004                 $w_cviewer insert end [strcat [mc "Committer:"] "\t"] header_key
1005                 $w_cviewer insert end "$committer_name $committer_email" header_val
1006                 $w_cviewer insert end "  $committer_time\n" header_val
1007
1008                 if {$file ne $path} {
1009                         $w_cviewer insert end [strcat [mc "Original File:"] "\t"] header_key
1010                         $w_cviewer insert end "[escape_path $file]\n" header_val
1011                 }
1012
1013                 $w_cviewer insert end "\n$msg"
1014         }
1015         $w_cviewer conf -state disabled
1016
1017         set highlight_line $lno
1018         set highlight_commit $cmit
1019
1020         if {[lsearch -exact $tooltip_commit $highlight_commit] != -1} {
1021                 _hide_tooltip $this
1022         }
1023 }
1024
1025 method _get_click_amov_info {} {
1026         set pos @$::cursorX,$::cursorY
1027         set lno [lindex [split [$::cursorW index $pos] .] 0]
1028         return [lindex $amov_data $lno]
1029 }
1030
1031 method _copycommit {} {
1032         set dat [_get_click_amov_info $this]
1033         if {$dat ne {}} {
1034                 clipboard clear
1035                 clipboard append \
1036                         -format STRING \
1037                         -type STRING \
1038                         -- [lindex $dat 0]
1039         }
1040 }
1041
1042 method _format_offset_date {base offset} {
1043         set exval [expr {$base + $offset*24*60*60}]
1044         return [clock format $exval -format {%Y-%m-%d}]
1045 }
1046
1047 method _gitkcommit {} {
1048         global nullid
1049
1050         set dat [_get_click_amov_info $this]
1051         if {$dat ne {}} {
1052                 set cmit [lindex $dat 0]
1053
1054                 # If the line belongs to the working copy, use HEAD instead
1055                 if {$cmit eq $nullid} {
1056                         if {[catch {set cmit [git rev-parse --verify HEAD]} err]} {
1057                                 error_popup [strcat [mc "Cannot find HEAD commit:"] "\n\n$err"]
1058                                 return;
1059                         }
1060                 }
1061
1062                 set radius [get_config gui.blamehistoryctx]
1063                 set cmdline [list --select-commit=$cmit]
1064
1065                 if {$radius > 0} {
1066                         set author_time {}
1067                         set committer_time {}
1068
1069                         catch {set author_time $header($cmit,author-time)}
1070                         catch {set committer_time $header($cmit,committer-time)}
1071
1072                         if {$committer_time eq {}} {
1073                                 set committer_time $author_time
1074                         }
1075
1076                         set after_time [_format_offset_date $this $committer_time [expr {-$radius}]]
1077                         set before_time [_format_offset_date $this $committer_time $radius]
1078
1079                         lappend cmdline --after=$after_time --before=$before_time
1080                 }
1081
1082                 lappend cmdline $cmit
1083
1084                 set base_rev "HEAD"
1085                 if {$commit ne {}} {
1086                         set base_rev $commit
1087                 }
1088
1089                 if {$base_rev ne $cmit} {
1090                         lappend cmdline $base_rev
1091                 }
1092
1093                 do_gitk $cmdline
1094         }
1095 }
1096
1097 method _blameparent {} {
1098         global nullid
1099
1100         set dat [_get_click_amov_info $this]
1101         if {$dat ne {}} {
1102                 set cmit [lindex $dat 0]
1103                 set new_path [lindex $dat 1]
1104
1105                 # Allow using Blame Parent on lines modified in the working copy
1106                 if {$cmit eq $nullid} {
1107                         set parent_ref "HEAD"
1108                 } else {
1109                         set parent_ref "$cmit^"
1110                 }
1111                 if {[catch {set cparent [git rev-parse --verify $parent_ref]} err]} {
1112                         error_popup [strcat [mc "Cannot find parent commit:"] "\n\n$err"]
1113                         return;
1114                 }
1115
1116                 _kill $this
1117
1118                 # Generate a diff between the commit and its parent,
1119                 # and use the hunks to update the line number.
1120                 # Request zero context to simplify calculations.
1121                 if {$cmit eq $nullid} {
1122                         set diffcmd [list diff-index --unified=0 $cparent -- $new_path]
1123                 } else {
1124                         set diffcmd [list diff-tree --unified=0 $cparent $cmit -- $new_path]
1125                 }
1126                 if {[catch {set fd [eval git_read $diffcmd]} err]} {
1127                         $status stop [mc "Unable to display parent"]
1128                         error_popup [strcat [mc "Error loading diff:"] "\n\n$err"]
1129                         return
1130                 }
1131
1132                 set r_orig_line [lindex $dat 2]
1133
1134                 fconfigure $fd \
1135                         -blocking 0 \
1136                         -encoding binary \
1137                         -translation binary
1138                 fileevent $fd readable [cb _read_diff_load_commit \
1139                         $fd $cparent $new_path $r_orig_line]
1140                 set current_fd $fd
1141         }
1142 }
1143
1144 method _read_diff_load_commit {fd cparent new_path tline} {
1145         if {$fd ne $current_fd} {
1146                 catch {close $fd}
1147                 return
1148         }
1149
1150         while {[gets $fd line] >= 0} {
1151                 if {[regexp {^@@ -(\d+)(,(\d+))? \+(\d+)(,(\d+))? @@} $line line \
1152                         old_line osz old_size new_line nsz new_size]} {
1153
1154                         if {$osz eq {}} { set old_size 1 }
1155                         if {$nsz eq {}} { set new_size 1 }
1156
1157                         if {$new_line <= $tline} {
1158                                 if {[expr {$new_line + $new_size}] > $tline} {
1159                                         # Target line within the hunk
1160                                         set line_shift [expr {
1161                                                 ($new_size-$old_size)*($tline-$new_line)/$new_size
1162                                                 }]
1163                                 } else {
1164                                         set line_shift [expr {$new_size-$old_size}]
1165                                 }
1166
1167                                 set r_orig_line [expr {$r_orig_line - $line_shift}]
1168                         }
1169                 }
1170         }
1171
1172         if {[eof $fd]} {
1173                 close $fd
1174                 set current_fd {}
1175
1176                 _load_new_commit $this  \
1177                         $cparent        \
1178                         $new_path       \
1179                         [list $r_orig_line]
1180         }
1181 } ifdeleted { catch {close $fd} }
1182
1183 method _show_tooltip {cur_w pos} {
1184         if {$tooltip_wm ne {}} {
1185                 _open_tooltip $this $cur_w
1186         } elseif {$tooltip_timer eq {}} {
1187                 set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
1188         }
1189 }
1190
1191 method _open_tooltip {cur_w} {
1192         set tooltip_timer {}
1193         set pos_x [winfo pointerx $cur_w]
1194         set pos_y [winfo pointery $cur_w]
1195         if {[winfo containing $pos_x $pos_y] ne $cur_w} {
1196                 _hide_tooltip $this
1197                 return
1198         }
1199
1200         if {$tooltip_wm ne "$cur_w.tooltip"} {
1201                 _hide_tooltip $this
1202
1203                 set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
1204                 catch {wm attributes $tooltip_wm -type tooltip}
1205                 wm overrideredirect $tooltip_wm 1
1206                 wm transient $tooltip_wm [winfo toplevel $cur_w]
1207                 set tooltip_t $tooltip_wm.label
1208                 text $tooltip_t \
1209                         -takefocus 0 \
1210                         -highlightthickness 0 \
1211                         -relief flat \
1212                         -borderwidth 0 \
1213                         -wrap none \
1214                         -background lightyellow \
1215                         -foreground black
1216                 $tooltip_t tag conf section_header -font font_uibold
1217                 pack $tooltip_t
1218         } else {
1219                 $tooltip_t conf -state normal
1220                 $tooltip_t delete 0.0 end
1221         }
1222
1223         set pos @[join [list \
1224                 [expr {$pos_x - [winfo rootx $cur_w]}] \
1225                 [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
1226         set lno [lindex [split [$cur_w index $pos] .] 0]
1227         if {$cur_w eq $w_amov} {
1228                 set dat [lindex $amov_data $lno]
1229                 set org {}
1230         } else {
1231                 set dat [lindex $asim_data $lno]
1232                 set org [lindex $amov_data $lno]
1233         }
1234
1235         if {$dat eq {}} {
1236                 _hide_tooltip $this
1237                 return
1238         }
1239
1240         set cmit [lindex $dat 0]
1241         set tooltip_commit [list $cmit]
1242
1243         set author_name {}
1244         set summary     {}
1245         set author_time {}
1246         catch {set author_name $header($cmit,author)}
1247         catch {set summary     $header($cmit,summary)}
1248         catch {set author_time [format_date $header($cmit,author-time)]}
1249
1250         $tooltip_t insert end "commit $cmit\n"
1251         $tooltip_t insert end "$author_name  $author_time\n"
1252         $tooltip_t insert end "$summary"
1253
1254         if {$org ne {} && [lindex $org 0] ne $cmit} {
1255                 set save [$tooltip_t get 0.0 end]
1256                 $tooltip_t delete 0.0 end
1257
1258                 set cmit [lindex $org 0]
1259                 set file [lindex $org 1]
1260                 lappend tooltip_commit $cmit
1261
1262                 set author_name {}
1263                 set summary     {}
1264                 set author_time {}
1265                 catch {set author_name $header($cmit,author)}
1266                 catch {set summary     $header($cmit,summary)}
1267                 catch {set author_time [format_date $header($cmit,author-time)]}
1268
1269                 $tooltip_t insert end [strcat [mc "Originally By:"] "\n"] section_header
1270                 $tooltip_t insert end "commit $cmit\n"
1271                 $tooltip_t insert end "$author_name  $author_time\n"
1272                 $tooltip_t insert end "$summary\n"
1273
1274                 if {$file ne $path} {
1275                         $tooltip_t insert end [strcat [mc "In File:"] " "] section_header
1276                         $tooltip_t insert end "$file\n"
1277                 }
1278
1279                 $tooltip_t insert end "\n"
1280                 $tooltip_t insert end [strcat [mc "Copied Or Moved Here By:"] "\n"] section_header
1281                 $tooltip_t insert end $save
1282         }
1283
1284         $tooltip_t conf -state disabled
1285         _position_tooltip $this
1286
1287         # On MacOS raising a window causes it to acquire focus.
1288         # Tk 8.5 on MacOS seems to properly support wm transient,
1289         # so we can safely counter the effect there.
1290         if {$::have_tk85 && [is_MacOSX]} {
1291                 update
1292                 if {$w eq {}} {
1293                         raise .
1294                 } else {
1295                         raise $w
1296                 }
1297         }
1298 }
1299
1300 method _position_tooltip {} {
1301         set max_h [lindex [split [$tooltip_t index end] .] 0]
1302         set max_w 0
1303         for {set i 1} {$i <= $max_h} {incr i} {
1304                 set c [lindex [split [$tooltip_t index "$i.0 lineend"] .] 1]
1305                 if {$c > $max_w} {set max_w $c}
1306         }
1307         $tooltip_t conf -width $max_w -height $max_h
1308
1309         set req_w [winfo reqwidth  $tooltip_t]
1310         set req_h [winfo reqheight $tooltip_t]
1311         set pos_x [expr {[winfo pointerx .] +  5}]
1312         set pos_y [expr {[winfo pointery .] + 10}]
1313
1314         set g "${req_w}x${req_h}"
1315         if {[tk windowingsystem] eq "win32" || $pos_x >= 0} {append g +}
1316         append g $pos_x
1317         if {[tk windowingsystem] eq "win32" || $pos_y >= 0} {append g +}
1318         append g $pos_y
1319
1320         wm geometry $tooltip_wm $g
1321         if {![is_MacOSX]} {
1322                 raise $tooltip_wm
1323         }
1324 }
1325
1326 method _hide_tooltip {} {
1327         if {$tooltip_wm ne {}} {
1328                 destroy $tooltip_wm
1329                 set tooltip_wm {}
1330                 set tooltip_commit {}
1331         }
1332         if {$tooltip_timer ne {}} {
1333                 after cancel $tooltip_timer
1334                 set tooltip_timer {}
1335         }
1336 }
1337
1338 method _resize {new_height} {
1339         set diff [expr {$new_height - $old_height}]
1340         if {$diff == 0} return
1341
1342         set my [expr {[winfo height $w.file_pane] - 25}]
1343         set o [$w.file_pane sash coord 0]
1344         set ox [lindex $o 0]
1345         set oy [expr {[lindex $o 1] + $diff}]
1346         if {$oy < 0}   {set oy 0}
1347         if {$oy > $my} {set oy $my}
1348         $w.file_pane sash place 0 $ox $oy
1349
1350         set old_height $new_height
1351 }
1352
1353 method _show_finder {} {
1354         linebar::hide $gotoline
1355         searchbar::show $finder
1356 }
1357
1358 method _show_linebar {} {
1359         searchbar::hide $finder
1360         linebar::show $gotoline
1361 }
1362
1363 }