git.oblomov.eu Git - git/blob - contrib/completion/git-completion.zsh

   1 #compdef git gitk
   2
   3 # zsh completion wrapper for git
   4 #
   5 # Copyright (c) 2012-2020 Felipe Contreras <felipe.contreras@gmail.com>
   6 #
   7 # The recommended way to install this script is to make a copy of it as a
   8 # file named '_git' inside any directory in your fpath.
   9 #
  10 # For example, create a directory '~/.zsh/', copy this file to '~/.zsh/_git',
  11 # and then add the following to your ~/.zshrc file:
  12 #
  13 #  fpath=(~/.zsh $fpath)
  14 #
  15 # You need git's bash completion script installed. By default bash-completion's
  16 # location will be used (e.g. pkg-config --variable=completionsdir bash-completion).
  17 #
  18 # If your bash completion script is somewhere else, you can specify the
  19 # location in your ~/.zshrc:
  20 #
  21 #  zstyle ':completion:*:*:git:*' script ~/.git-completion.bash
  22 #
  23
  24 zstyle -T ':completion:*:*:git:*' tag-order && \
  25         zstyle ':completion:*:*:git:*' tag-order 'common-commands'
  26
  27 zstyle -s ":completion:*:*:git:*" script script
  28 if [ -z "$script" ]; then
  29         local -a locations
  30         local e bash_completion
  31
  32         bash_completion=$(pkg-config --variable=completionsdir bash-completion 2>/dev/null) ||
  33                 bash_completion='/usr/share/bash-completion/completions/'
  34
  35         locations=(
  36                 "$(dirname ${funcsourcetrace[1]%:*})"/git-completion.bash
  37                 "$HOME/.local/share/bash-completion/completions/git"
  38                 "$bash_completion/git"
  39                 '/etc/bash_completion.d/git' # old debian
  40                 )
  41         for e in $locations; do
  42                 test -f $e && script="$e" && break
  43         done
  44 fi
  45
  46 local old_complete="$functions[complete]"
  47 functions[complete]=:
  48 GIT_SOURCING_ZSH_COMPLETION=y . "$script"
  49 functions[complete]="$old_complete"
  50
  51 __gitcomp ()
  52 {
  53         emulate -L zsh
  54
  55         local cur_="${3-$cur}"
  56
  57         case "$cur_" in
  58         --*=)
  59                 ;;
  60         --no-*)
  61                 local c IFS=$' \t\n'
  62                 local -a array
  63                 for c in ${=1}; do
  64                         if [[ $c == "--" ]]; then
  65                                 continue
  66                         fi
  67                         c="$c${4-}"
  68                         case $c in
  69                         --*=|*.) ;;
  70                         *) c="$c " ;;
  71                         esac
  72                         array+=("$c")
  73                 done
  74                 compset -P '*[=:]'
  75                 compadd -Q -S '' -p "${2-}" -a -- array && _ret=0
  76                 ;;
  77         *)
  78                 local c IFS=$' \t\n'
  79                 local -a array
  80                 for c in ${=1}; do
  81                         if [[ $c == "--" ]]; then
  82                                 c="--no-...${4-}"
  83                                 array+=("$c ")
  84                                 break
  85                         fi
  86                         c="$c${4-}"
  87                         case $c in
  88                         --*=|*.) ;;
  89                         *) c="$c " ;;
  90                         esac
  91                         array+=("$c")
  92                 done
  93                 compset -P '*[=:]'
  94                 compadd -Q -S '' -p "${2-}" -a -- array && _ret=0
  95                 ;;
  96         esac
  97 }
  98
  99 __gitcomp_direct ()
 100 {
 101         emulate -L zsh
 102
 103         compset -P '*[=:]'
 104         compadd -Q -S '' -- ${(f)1} && _ret=0
 105 }
 106
 107 __gitcomp_nl ()
 108 {
 109         emulate -L zsh
 110
 111         compset -P '*[=:]'
 112         compadd -Q -S "${4- }" -p "${2-}" -- ${(f)1} && _ret=0
 113 }
 114
 115 __gitcomp_file ()
 116 {
 117         emulate -L zsh
 118
 119         compadd -f -p "${2-}" -- ${(f)1} && _ret=0
 120 }
 121
 122 __gitcomp_direct_append ()
 123 {
 124         __gitcomp_direct "$@"
 125 }
 126
 127 __gitcomp_nl_append ()
 128 {
 129         __gitcomp_nl "$@"
 130 }
 131
 132 __gitcomp_file_direct ()
 133 {
 134         __gitcomp_file "$1" ""
 135 }
 136
 137 _git_zsh ()
 138 {
 139         __gitcomp "v1.1"
 140 }
 141
 142 __git_complete_command ()
 143 {
 144         emulate -L zsh
 145
 146         local command="$1"
 147         local completion_func="_git_${command//-/_}"
 148         if (( $+functions[$completion_func] )); then
 149                 emulate ksh -c $completion_func
 150                 return 0
 151         else
 152                 return 1
 153         fi
 154 }
 155
 156 __git_zsh_bash_func ()
 157 {
 158         emulate -L ksh
 159
 160         local command=$1
 161
 162         __git_complete_command "$command" && return
 163
 164         local expansion=$(__git_aliased_command "$command")
 165         if [ -n "$expansion" ]; then
 166                 words[1]=$expansion
 167                 __git_complete_command "$expansion"
 168         fi
 169 }
 170
 171 __git_zsh_cmd_common ()
 172 {
 173         local -a list
 174         list=(
 175         add:'add file contents to the index'
 176         bisect:'find by binary search the change that introduced a bug'
 177         branch:'list, create, or delete branches'
 178         checkout:'checkout a branch or paths to the working tree'
 179         clone:'clone a repository into a new directory'
 180         commit:'record changes to the repository'
 181         diff:'show changes between commits, commit and working tree, etc'
 182         fetch:'download objects and refs from another repository'
 183         grep:'print lines matching a pattern'
 184         init:'create an empty Git repository or reinitialize an existing one'
 185         log:'show commit logs'
 186         merge:'join two or more development histories together'
 187         mv:'move or rename a file, a directory, or a symlink'
 188         pull:'fetch from and merge with another repository or a local branch'
 189         push:'update remote refs along with associated objects'
 190         rebase:'forward-port local commits to the updated upstream head'
 191         reset:'reset current HEAD to the specified state'
 192         restore:'restore working tree files'
 193         rm:'remove files from the working tree and from the index'
 194         show:'show various types of objects'
 195         status:'show the working tree status'
 196         switch:'switch branches'
 197         tag:'create, list, delete or verify a tag object signed with GPG')
 198         _describe -t common-commands 'common commands' list && _ret=0
 199 }
 200
 201 __git_zsh_cmd_alias ()
 202 {
 203         local -a list
 204         list=(${${(0)"$(git config -z --get-regexp '^alias\.*')"}#alias.})
 205         list=(${(f)"$(printf "%s:alias for '%s'\n" ${(f@)list})"})
 206         _describe -t alias-commands 'aliases' list && _ret=0
 207 }
 208
 209 __git_zsh_cmd_all ()
 210 {
 211         local -a list
 212         emulate ksh -c __git_compute_all_commands
 213         list=( ${=__git_all_commands} )
 214         _describe -t all-commands 'all commands' list && _ret=0
 215 }
 216
 217 __git_zsh_main ()
 218 {
 219         local curcontext="$curcontext" state state_descr line
 220         typeset -A opt_args
 221         local -a orig_words
 222
 223         orig_words=( ${words[@]} )
 224
 225         _arguments -C \
 226                 '(-p --paginate --no-pager)'{-p,--paginate}'[pipe all output into ''less'']' \
 227                 '(-p --paginate)--no-pager[do not pipe git output into a pager]' \
 228                 '--git-dir=-[set the path to the repository]: :_directories' \
 229                 '--bare[treat the repository as a bare repository]' \
 230                 '(- :)--version[prints the git suite version]' \
 231                 '--exec-path=-[path to where your core git programs are installed]:: :_directories' \
 232                 '--html-path[print the path where git''s HTML documentation is installed]' \
 233                 '--info-path[print the path where the Info files are installed]' \
 234                 '--man-path[print the manpath (see `man(1)`) for the man pages]' \
 235                 '--work-tree=-[set the path to the working tree]: :_directories' \
 236                 '--namespace=-[set the git namespace]' \
 237                 '--no-replace-objects[do not use replacement refs to replace git objects]' \
 238                 '(- :)--help[prints the synopsis and a list of the most commonly used commands]: :->arg' \
 239                 '(-): :->command' \
 240                 '(-)*:: :->arg' && return
 241
 242         case $state in
 243         (command)
 244                 _tags common-commands alias-commands all-commands
 245                 while _tags; do
 246                         _requested common-commands && __git_zsh_cmd_common
 247                         _requested alias-commands && __git_zsh_cmd_alias
 248                         _requested all-commands && __git_zsh_cmd_all
 249                         let _ret || break
 250                 done
 251                 ;;
 252         (arg)
 253                 local command="${words[1]}" __git_dir
 254
 255                 if (( $+opt_args[--bare] )); then
 256                         __git_dir='.'
 257                 else
 258                         __git_dir=${opt_args[--git-dir]}
 259                 fi
 260
 261                 (( $+opt_args[--help] )) && command='help'
 262
 263                 words=( ${orig_words[@]} )
 264
 265                 __git_zsh_bash_func $command
 266                 ;;
 267         esac
 268 }
 269
 270 _git ()
 271 {
 272         local _ret=1
 273         local cur cword prev
 274
 275         cur=${words[CURRENT]}
 276         prev=${words[CURRENT-1]}
 277         let cword=CURRENT-1
 278
 279         if (( $+functions[__${service}_zsh_main] )); then
 280                 __${service}_zsh_main
 281         elif (( $+functions[__${service}_main] )); then
 282                 emulate ksh -c __${service}_main
 283         elif (( $+functions[_${service}] )); then
 284                 emulate ksh -c _${service}
 285         elif (( $+functions[_${service//-/_}] )); then
 286                 emulate ksh -c _${service//-/_}
 287         fi
 288
 289         let _ret && _default && _ret=0
 290         return _ret
 291 }
 292
 293 _git