git.oblomov.eu Git - git/blob - contrib/buildsystems/CMakeLists.txt

   1 #
   2 #       Copyright (c) 2020 Sibi Siddharthan
   3 #
   4
   5 #[[
   6
   7 Instructions to run CMake:
   8
   9 cmake `relative-path-to-CMakeLists.txt` -DCMAKE_BUILD_TYPE=Release
  10 Eg.
  11 From the root of git source tree
  12         `cmake contrib/buildsystems/ `
  13 This will build the git binaries at the root
  14
  15 For out of source builds, say build in 'git/git-build/'
  16         `mkdir git-build;cd git-build; cmake ../contrib/buildsystems/`
  17 This will build the git binaries in git-build directory
  18
  19 Possible build configurations(-DCMAKE_BUILD_TYPE) with corresponding
  20 compiler flags
  21 Debug : -g
  22 Release: -O3
  23 RelWithDebInfo : -O2 -g
  24 MinSizeRel : -Os
  25 empty(default) :
  26
  27 NOTE: -DCMAKE_BUILD_TYPE is optional. For multi-config generators like Visual Studio
  28 this option is ignored
  29
  30 This process generates a Makefile(Linux/*BSD/MacOS) , Visual Studio solution(Windows) by default.
  31 Run `make` to build Git on Linux/*BSD/MacOS.
  32 Open git.sln on Windows and build Git.
  33
  34 NOTE: By default CMake uses Makefile as the build tool on Linux and Visual Studio in Windows,
  35 to use another tool say `ninja` add this to the command line when configuring.
  36 `-G Ninja`
  37
  38 ]]
  39 cmake_minimum_required(VERSION 3.14)
  40
  41 #set the source directory to root of git
  42 set(CMAKE_SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/../..)
  43
  44 find_program(SH_EXE sh)
  45
  46 #Create GIT-VERSION-FILE using GIT-VERSION-GEN
  47 if(NOT EXISTS ${CMAKE_SOURCE_DIR}/GIT-VERSION-FILE)
  48         message("Generating GIT-VERSION-FILE")
  49         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/GIT-VERSION-GEN
  50                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
  51 endif()
  52
  53 #Parse GIT-VERSION-FILE to get the version
  54 file(STRINGS ${CMAKE_SOURCE_DIR}/GIT-VERSION-FILE git_version REGEX "GIT_VERSION = (.*)")
  55 string(REPLACE "GIT_VERSION = " "" git_version ${git_version})
  56 string(FIND ${git_version} "GIT" location)
  57 if(location EQUAL -1)
  58         string(REGEX MATCH "[0-9]*\\.[0-9]*\\.[0-9]*" git_version ${git_version})
  59 else()
  60         string(REGEX MATCH "[0-9]*\\.[0-9]*" git_version ${git_version})
  61         string(APPEND git_version ".0") #for building from a snapshot
  62 endif()
  63
  64 project(git
  65         VERSION ${git_version}
  66         LANGUAGES C)
  67
  68 #TODO gitk git-gui gitweb
  69 #TODO Add pcre support
  70
  71 #macros for parsing the Makefile for sources and scripts
  72 macro(parse_makefile_for_sources list_var regex)
  73         file(STRINGS ${CMAKE_SOURCE_DIR}/Makefile ${list_var} REGEX "^${regex} \\+=(.*)")
  74         string(REPLACE "${regex} +=" "" ${list_var} ${${list_var}})
  75         string(REPLACE "$(COMPAT_OBJS)" "" ${list_var} ${${list_var}}) #remove "$(COMPAT_OBJS)" This is only for libgit.
  76         string(STRIP ${${list_var}} ${list_var}) #remove trailing/leading whitespaces
  77         string(REPLACE ".o" ".c;" ${list_var} ${${list_var}}) #change .o to .c, ; is for converting the string into a list
  78         list(TRANSFORM ${list_var} STRIP) #remove trailing/leading whitespaces for each element in list
  79         list(REMOVE_ITEM ${list_var} "") #remove empty list elements
  80 endmacro()
  81
  82 macro(parse_makefile_for_scripts list_var regex lang)
  83         file(STRINGS ${CMAKE_SOURCE_DIR}/Makefile ${list_var} REGEX "^${regex} \\+=(.*)")
  84         string(REPLACE "${regex} +=" "" ${list_var} ${${list_var}})
  85         string(STRIP ${${list_var}} ${list_var}) #remove trailing/leading whitespaces
  86         string(REPLACE " " ";" ${list_var} ${${list_var}}) #convert string to a list
  87         if(NOT ${lang}) #exclude for SCRIPT_LIB
  88                 list(TRANSFORM ${list_var} REPLACE "${lang}" "") #do the replacement
  89         endif()
  90 endmacro()
  91
  92 include(CheckTypeSize)
  93 include(CheckCSourceRuns)
  94 include(CheckCSourceCompiles)
  95 include(CheckIncludeFile)
  96 include(CheckFunctionExists)
  97 include(CheckSymbolExists)
  98 include(CheckStructHasMember)
  99 include(CTest)
 100
 101 find_package(ZLIB REQUIRED)
 102 find_package(CURL)
 103 find_package(EXPAT)
 104 find_package(Iconv)
 105 find_package(Intl)
 106
 107 if(NOT Intl_FOUND)
 108         add_compile_definitions(NO_GETTEXT)
 109         if(NOT Iconv_FOUND)
 110                 add_compile_definitions(NO_ICONV)
 111         endif()
 112 endif()
 113
 114 include_directories(SYSTEM ${ZLIB_INCLUDE_DIRS})
 115 if(CURL_FOUND)
 116         include_directories(SYSTEM ${CURL_INCLUDE_DIRS})
 117 endif()
 118 if(EXPAT_FOUND)
 119         include_directories(SYSTEM ${EXPAT_INCLUDE_DIRS})
 120 endif()
 121 if(Iconv_FOUND)
 122         include_directories(SYSTEM ${Iconv_INCLUDE_DIRS})
 123 endif()
 124 if(Intl_FOUND)
 125         include_directories(SYSTEM ${Intl_INCLUDE_DIRS})
 126 endif()
 127
 128 find_program(MSGFMT_EXE msgfmt)
 129 if(NOT MSGFMT_EXE)
 130         message(WARNING "Text Translations won't be build")
 131 endif()
 132
 133 #default behaviour
 134 include_directories(${CMAKE_SOURCE_DIR})
 135 add_compile_definitions(GIT_HOST_CPU="${CMAKE_SYSTEM_PROCESSOR}")
 136 add_compile_definitions(SHA256_BLK INTERNAL_QSORT RUNTIME_PREFIX)
 137 add_compile_definitions(NO_OPENSSL SHA1_DC SHA1DC_NO_STANDARD_INCLUDES
 138                         SHA1DC_INIT_SAFE_HASH_DEFAULT=0
 139                         SHA1DC_CUSTOM_INCLUDE_SHA1_C="cache.h"
 140                         SHA1DC_CUSTOM_INCLUDE_UBC_CHECK_C="git-compat-util.h" )
 141 list(APPEND compat_SOURCES sha1dc_git.c sha1dc/sha1.c sha1dc/ubc_check.c block-sha1/sha1.c sha256/block/sha256.c compat/qsort_s.c)
 142
 143
 144 add_compile_definitions(PAGER_ENV="LESS=FRX LV=-c"
 145                         ETC_GITATTRIBUTES="etc/gitattributes"
 146                         ETC_GITCONFIG="etc/gitconfig"
 147                         GIT_EXEC_PATH="libexec/git-core"
 148                         GIT_LOCALE_PATH="share/locale"
 149                         GIT_MAN_PATH="share/man"
 150                         GIT_INFO_PATH="share/info"
 151                         GIT_HTML_PATH="share/doc/git-doc"
 152                         DEFAULT_HELP_FORMAT="html"
 153                         DEFAULT_GIT_TEMPLATE_DIR="share/git-core/templates"
 154                         GIT_VERSION="${PROJECT_VERSION}.GIT"
 155                         GIT_USER_AGENT="git/${PROJECT_VERSION}.GIT"
 156                         BINDIR="bin"
 157                         GIT_BUILT_FROM_COMMIT="")
 158
 159 set(FALLBACK_RUNTIME_PREFIX /home/$ENV{USER})
 160 add_compile_definitions(FALLBACK_RUNTIME_PREFIX="${FALLBACK_RUNTIME_PREFIX}")
 161
 162 add_compile_definitions(PROCFS_EXECUTABLE_PATH="/proc/self/exe" HAVE_DEV_TTY )
 163 list(APPEND compat_SOURCES unix-socket.c)
 164
 165 #header checks
 166 check_include_file(libgen.h HAVE_LIBGEN_H)
 167 if(NOT HAVE_LIBGEN_H)
 168         add_compile_definitions(NO_LIBGEN_H)
 169         list(APPEND compat_SOURCES compat/basename.c)
 170 endif()
 171
 172 check_include_file(sys/sysinfo.h HAVE_SYSINFO)
 173 if(HAVE_SYSINFO)
 174         add_compile_definitions(HAVE_SYSINFO)
 175 endif()
 176
 177 check_c_source_compiles("
 178 #include <alloca.h>
 179
 180 int main(void)
 181 {
 182         char *p = (char *) alloca(2 * sizeof(int));
 183
 184         if (p)
 185                 return 0;
 186         return 0;
 187 }"
 188 HAVE_ALLOCA_H)
 189 if(HAVE_ALLOCA_H)
 190         add_compile_definitions(HAVE_ALLOCA_H)
 191 endif()
 192
 193 check_include_file(strings.h HAVE_STRINGS_H)
 194 if(HAVE_STRINGS_H)
 195         add_compile_definitions(HAVE_STRINGS_H)
 196 endif()
 197
 198 check_include_file(sys/select.h HAVE_SYS_SELECT_H)
 199 if(NOT HAVE_SYS_SELECT_H)
 200         add_compile_definitions(NO_SYS_SELECT_H)
 201 endif()
 202
 203 check_include_file(sys/poll.h HAVE_SYS_POLL_H)
 204 if(NOT HAVE_SYS_POLL_H)
 205         add_compile_definitions(NO_SYS_POLL_H)
 206 endif()
 207
 208 check_include_file(poll.h HAVE_POLL_H)
 209 if(NOT HAVE_POLL_H)
 210         add_compile_definitions(NO_POLL_H)
 211 endif()
 212
 213 check_include_file(inttypes.h HAVE_INTTYPES_H)
 214 if(NOT HAVE_INTTYPES_H)
 215         add_compile_definitions(NO_INTTYPES_H)
 216 endif()
 217
 218 check_include_file(paths.h HAVE_PATHS_H)
 219 if(HAVE_PATHS_H)
 220         add_compile_definitions(HAVE_PATHS_H)
 221 endif()
 222
 223 #function checks
 224 set(function_checks
 225         strcasestr memmem strlcpy strtoimax strtoumax strtoull
 226         setenv mkdtemp poll pread memmem unsetenv hstrerror)
 227
 228 foreach(f ${function_checks})
 229         string(TOUPPER ${f} uf)
 230         check_function_exists(${f} HAVE_${uf})
 231         if(NOT HAVE_${uf})
 232                 add_compile_definitions(NO_${uf})
 233         endif()
 234 endforeach()
 235
 236 if(NOT HAVE_POLL_H OR NOT HAVE_SYS_POLL_H OR NOT HAVE_POLL)
 237         include_directories(${CMAKE_SOURCE_DIR}/compat/poll)
 238         add_compile_definitions(NO_POLL)
 239         list(APPEND compat_SOURCES compat/poll/poll.c)
 240 endif()
 241
 242 if(NOT HAVE_STRCASESTR)
 243         list(APPEND compat_SOURCES compat/strcasestr.c)
 244 endif()
 245
 246 if(NOT HAVE_STRLCPY)
 247         list(APPEND compat_SOURCES compat/strlcpy.c)
 248 endif()
 249
 250 if(NOT HAVE_STRTOUMAX)
 251         list(APPEND compat_SOURCES compat/strtoumax.c compat/strtoimax.c)
 252 endif()
 253
 254 if(NOT HAVE_SETENV)
 255         list(APPEND compat_SOURCES compat/setenv.c)
 256 endif()
 257
 258 if(NOT HAVE_MKDTEMP)
 259         list(APPEND compat_SOURCES compat/mkdtemp.c)
 260 endif()
 261
 262 if(NOT HAVE_PREAD)
 263         list(APPEND compat_SOURCES compat/pread.c)
 264 endif()
 265
 266 if(NOT HAVE_MEMMEM)
 267         list(APPEND compat_SOURCES compat/memmem.c)
 268 endif()
 269
 270 if(NOT WIN32)
 271         if(NOT HAVE_UNSETENV)
 272                 list(APPEND compat_SOURCES compat/unsetenv.c)
 273         endif()
 274
 275         if(NOT HAVE_HSTRERROR)
 276                 list(APPEND compat_SOURCES compat/hstrerror.c)
 277         endif()
 278 endif()
 279
 280 check_function_exists(getdelim HAVE_GETDELIM)
 281 if(HAVE_GETDELIM)
 282         add_compile_definitions(HAVE_GETDELIM)
 283 endif()
 284
 285 check_function_exists(clock_gettime HAVE_CLOCK_GETTIME)
 286 check_symbol_exists(CLOCK_MONOTONIC "time.h" HAVE_CLOCK_MONOTONIC)
 287 if(HAVE_CLOCK_GETTIME)
 288         add_compile_definitions(HAVE_CLOCK_GETTIME)
 289 endif()
 290 if(HAVE_CLOCK_MONOTONIC)
 291         add_compile_definitions(HAVE_CLOCK_MONOTONIC)
 292 endif()
 293
 294 #check for st_blocks in struct stat
 295 check_struct_has_member("struct stat" st_blocks "sys/stat.h" STRUCT_STAT_HAS_ST_BLOCKS)
 296 if(NOT STRUCT_STAT_HAS_ST_BLOCKS)
 297         add_compile_definitions(NO_ST_BLOCKS_IN_STRUCT_STAT)
 298 endif()
 299
 300 #compile checks
 301 check_c_source_runs("
 302 #include<stdio.h>
 303 #include<stdarg.h>
 304 #include<string.h>
 305 #include<stdlib.h>
 306
 307 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 308 {
 309         int ret;
 310         va_list ap;
 311
 312         va_start(ap, format);
 313         ret = vsnprintf(str, maxsize, format, ap);
 314         va_end(ap);
 315         return ret;
 316 }
 317
 318 int main(void)
 319 {
 320         char buf[6];
 321
 322         if (test_vsnprintf(buf, 3, \"%s\", \"12345\") != 5
 323                 || strcmp(buf, \"12\"))
 324                         return 1;
 325         if (snprintf(buf, 3, \"%s\", \"12345\") != 5
 326                 || strcmp(buf, \"12\"))
 327                         return 1;
 328         return 0;
 329 }"
 330 SNPRINTF_OK)
 331 if(NOT SNPRINTF_OK)
 332         add_compile_definitions(SNPRINTF_RETURNS_BOGUS)
 333         list(APPEND compat_SOURCES compat/snprintf.c)
 334 endif()
 335
 336 check_c_source_runs("
 337 #include<stdio.h>
 338
 339 int main(void)
 340 {
 341         FILE *f = fopen(\".\", \"r\");
 342
 343         return f != NULL;
 344 }"
 345 FREAD_READS_DIRECTORIES_NO)
 346 if(NOT FREAD_READS_DIRECTORIES_NO)
 347         add_compile_definitions(FREAD_READS_DIRECTORIES)
 348         list(APPEND compat_SOURCES compat/fopen.c)
 349 endif()
 350
 351 check_c_source_compiles("
 352 #include <regex.h>
 353 #ifndef REG_STARTEND
 354 #error oops we dont have it
 355 #endif
 356
 357 int main(void)
 358 {
 359         return 0;
 360 }"
 361 HAVE_REGEX)
 362 if(NOT HAVE_REGEX)
 363         include_directories(${CMAKE_SOURCE_DIR}/compat/regex)
 364         list(APPEND compat_SOURCES compat/regex/regex.c )
 365         add_compile_definitions(NO_REGEX NO_MBSUPPORT GAWK)
 366 endif()
 367
 368
 369 check_c_source_compiles("
 370 #include <stddef.h>
 371 #include <sys/types.h>
 372 #include <sys/sysctl.h>
 373
 374 int main(void)
 375 {
 376         int val, mib[2];
 377         size_t len;
 378
 379         mib[0] = CTL_HW;
 380         mib[1] = 1;
 381         len = sizeof(val);
 382         return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
 383 }"
 384 HAVE_BSD_SYSCTL)
 385 if(HAVE_BSD_SYSCTL)
 386         add_compile_definitions(HAVE_BSD_SYSCTL)
 387 endif()
 388
 389 set(CMAKE_REQUIRED_LIBRARIES ${Iconv_LIBRARIES})
 390 set(CMAKE_REQUIRED_INCLUDES ${Iconv_INCLUDE_DIRS})
 391
 392 check_c_source_compiles("
 393 #include <iconv.h>
 394
 395 extern size_t iconv(iconv_t cd,
 396                 char **inbuf, size_t *inbytesleft,
 397                 char **outbuf, size_t *outbytesleft);
 398
 399 int main(void)
 400 {
 401         return 0;
 402 }"
 403 HAVE_NEW_ICONV)
 404 if(HAVE_NEW_ICONV)
 405         set(HAVE_OLD_ICONV 0)
 406 else()
 407         set(HAVE_OLD_ICONV 1)
 408 endif()
 409
 410 check_c_source_runs("
 411 #include <iconv.h>
 412 #if ${HAVE_OLD_ICONV}
 413 typedef const char *iconv_ibp;
 414 #else
 415 typedef char *iconv_ibp;
 416 #endif
 417
 418 int main(void)
 419 {
 420         int v;
 421         iconv_t conv;
 422         char in[] = \"a\";
 423         iconv_ibp pin = in;
 424         char out[20] = \"\";
 425         char *pout = out;
 426         size_t isz = sizeof(in);
 427         size_t osz = sizeof(out);
 428
 429         conv = iconv_open(\"UTF-16\", \"UTF-8\");
 430         iconv(conv, &pin, &isz, &pout, &osz);
 431         iconv_close(conv);
 432         v = (unsigned char)(out[0]) + (unsigned char)(out[1]);
 433         return v != 0xfe + 0xff;
 434 }"
 435 ICONV_DOESNOT_OMIT_BOM)
 436 if(NOT ICONV_DOESNOT_OMIT_BOM)
 437         add_compile_definitions(ICONV_OMITS_BOM)
 438 endif()
 439
 440 unset(CMAKE_REQUIRED_LIBRARIES)
 441 unset(CMAKE_REQUIRED_INCLUDES)
 442
 443
 444 #programs
 445 set(PROGRAMS_BUILT
 446         git git-bugreport git-credential-store git-daemon git-fast-import git-http-backend git-sh-i18n--envsubst
 447         git-shell git-remote-testsvn git-credential-cache git-credential-cache--daemon)
 448
 449 if(NOT CURL_FOUND)
 450         list(APPEND excluded_progs git-http-fetch git-http-push)
 451         add_compile_definitions(NO_CURL)
 452         message(WARNING "git-http-push and git-http-fetch will not be built")
 453 else()
 454         list(APPEND PROGRAMS_BUILT git-http-fetch git-http-push git-imap-send git-remote-http)
 455         if(CURL_VERSION_STRING VERSION_GREATER_EQUAL 7.34.0)
 456                 add_compile_definitions(USE_CURL_FOR_IMAP_SEND)
 457         endif()
 458 endif()
 459
 460 if(NOT EXPAT_FOUND)
 461         list(APPEND excluded_progs git-http-push)
 462         add_compile_definitions(NO_EXPAT)
 463 else()
 464         list(APPEND PROGRAMS_BUILT git-http-push)
 465         if(EXPAT_VERSION_STRING VERSION_LESS_EQUAL 1.2)
 466                 add_compile_definitions(EXPAT_NEEDS_XMLPARSE_H)
 467         endif()
 468 endif()
 469
 470 list(REMOVE_DUPLICATES excluded_progs)
 471 list(REMOVE_DUPLICATES PROGRAMS_BUILT)
 472
 473
 474 foreach(p ${excluded_progs})
 475         list(APPEND EXCLUSION_PROGS --exclude-program ${p} )
 476 endforeach()
 477
 478 #for comparing null values
 479 list(APPEND EXCLUSION_PROGS empty)
 480 set(EXCLUSION_PROGS_CACHE ${EXCLUSION_PROGS} CACHE STRING "Programs not built" FORCE)
 481
 482 if(NOT EXISTS ${CMAKE_BINARY_DIR}/command-list.h OR NOT EXCLUSION_PROGS_CACHE STREQUAL EXCLUSION_PROGS)
 483         list(REMOVE_ITEM EXCLUSION_PROGS empty)
 484         message("Generating command-list.h")
 485         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/generate-cmdlist.sh ${EXCLUSION_PROGS} command-list.txt
 486                         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 487                         OUTPUT_FILE ${CMAKE_BINARY_DIR}/command-list.h)
 488 endif()
 489
 490 if(NOT EXISTS ${CMAKE_BINARY_DIR}/config-list.h)
 491         message("Generating config-list.h")
 492         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/generate-configlist.sh
 493                         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 494                         OUTPUT_FILE ${CMAKE_BINARY_DIR}/config-list.h)
 495 endif()
 496
 497 include_directories(${CMAKE_BINARY_DIR})
 498
 499 #build
 500 #libgit
 501 parse_makefile_for_sources(libgit_SOURCES "LIB_OBJS")
 502
 503 list(TRANSFORM libgit_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 504 list(TRANSFORM compat_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 505 add_library(libgit ${libgit_SOURCES} ${compat_SOURCES})
 506
 507 #libxdiff
 508 parse_makefile_for_sources(libxdiff_SOURCES "XDIFF_OBJS")
 509
 510 list(TRANSFORM libxdiff_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 511 add_library(xdiff STATIC ${libxdiff_SOURCES})
 512
 513 #libvcs-svn
 514 parse_makefile_for_sources(libvcs-svn_SOURCES "VCSSVN_OBJS")
 515
 516 list(TRANSFORM libvcs-svn_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 517 add_library(vcs-svn STATIC ${libvcs-svn_SOURCES})
 518
 519 #link all required libraries to common-main
 520 add_library(common-main OBJECT ${CMAKE_SOURCE_DIR}/common-main.c)
 521 target_link_libraries(common-main libgit xdiff ${ZLIB_LIBRARIES} pthread rt)
 522 if(Intl_FOUND)
 523         target_link_libraries(common-main ${Intl_LIBRARIES})
 524 endif()
 525 if(Iconv_FOUND)
 526         target_link_libraries(common-main ${Iconv_LIBRARIES})
 527 endif()
 528
 529 #git
 530 parse_makefile_for_sources(git_SOURCES "BUILTIN_OBJS")
 531
 532 list(TRANSFORM git_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 533 add_executable(git ${CMAKE_SOURCE_DIR}/git.c ${git_SOURCES})
 534 target_link_libraries(git common-main)
 535
 536 add_executable(git-bugreport ${CMAKE_SOURCE_DIR}/bugreport.c)
 537 target_link_libraries(git-bugreport common-main)
 538
 539 add_executable(git-credential-store ${CMAKE_SOURCE_DIR}/credential-store.c)
 540 target_link_libraries(git-credential-store common-main)
 541
 542 add_executable(git-daemon ${CMAKE_SOURCE_DIR}/daemon.c)
 543 target_link_libraries(git-daemon common-main)
 544
 545 add_executable(git-fast-import ${CMAKE_SOURCE_DIR}/fast-import.c)
 546 target_link_libraries(git-fast-import common-main)
 547
 548 add_executable(git-http-backend ${CMAKE_SOURCE_DIR}/http-backend.c)
 549 target_link_libraries(git-http-backend common-main)
 550
 551 add_executable(git-sh-i18n--envsubst ${CMAKE_SOURCE_DIR}/sh-i18n--envsubst.c)
 552 target_link_libraries(git-sh-i18n--envsubst common-main)
 553
 554 add_executable(git-shell ${CMAKE_SOURCE_DIR}/shell.c)
 555 target_link_libraries(git-shell common-main)
 556
 557 if(CURL_FOUND)
 558         add_library(http_obj OBJECT ${CMAKE_SOURCE_DIR}/http.c)
 559
 560         add_executable(git-imap-send ${CMAKE_SOURCE_DIR}/imap-send.c)
 561         target_link_libraries(git-imap-send http_obj common-main ${CURL_LIBRARIES})
 562
 563         add_executable(git-http-fetch ${CMAKE_SOURCE_DIR}/http-walker.c ${CMAKE_SOURCE_DIR}/http-fetch.c)
 564         target_link_libraries(git-http-fetch http_obj common-main ${CURL_LIBRARIES})
 565
 566         add_executable(git-remote-http ${CMAKE_SOURCE_DIR}/http-walker.c ${CMAKE_SOURCE_DIR}/remote-curl.c)
 567         target_link_libraries(git-remote-http http_obj common-main ${CURL_LIBRARIES} )
 568
 569         if(EXPAT_FOUND)
 570                 add_executable(git-http-push ${CMAKE_SOURCE_DIR}/http-push.c)
 571                 target_link_libraries(git-http-push http_obj common-main ${CURL_LIBRARIES} ${EXPAT_LIBRARIES})
 572         endif()
 573 endif()
 574
 575 add_executable(git-remote-testsvn ${CMAKE_SOURCE_DIR}/remote-testsvn.c)
 576 target_link_libraries(git-remote-testsvn common-main vcs-svn)
 577
 578 add_executable(git-credential-cache ${CMAKE_SOURCE_DIR}/credential-cache.c)
 579 target_link_libraries(git-credential-cache common-main)
 580
 581 add_executable(git-credential-cache--daemon ${CMAKE_SOURCE_DIR}/credential-cache--daemon.c)
 582 target_link_libraries(git-credential-cache--daemon common-main)
 583
 584
 585 set(git_builtin_extra
 586         cherry cherry-pick format-patch fsck-objects
 587         init merge-subtree restore show
 588         stage status switch whatchanged)
 589
 590 #Creating hardlinks
 591 foreach(s ${git_SOURCES} ${git_builtin_extra})
 592         string(REPLACE "${CMAKE_SOURCE_DIR}/builtin/" "" s ${s})
 593         string(REPLACE ".c" "" s ${s})
 594         file(APPEND ${CMAKE_BINARY_DIR}/CreateLinks.cmake "file(CREATE_LINK git git-${s})\n")
 595         list(APPEND git_links ${CMAKE_BINARY_DIR}/git-${s})
 596 endforeach()
 597
 598 if(CURL_FOUND)
 599         set(remote_exes
 600                 git-remote-https git-remote-ftp git-remote-ftps)
 601         foreach(s ${remote_exes})
 602                 file(APPEND ${CMAKE_BINARY_DIR}/CreateLinks.cmake "file(CREATE_LINK git-remote-http ${s})\n")
 603                 list(APPEND git_http_links ${CMAKE_BINARY_DIR}/${s})
 604         endforeach()
 605 endif()
 606
 607 add_custom_command(OUTPUT ${git_links} ${git_http_links}
 608                 COMMAND ${CMAKE_COMMAND} -P ${CMAKE_BINARY_DIR}/CreateLinks.cmake
 609                 DEPENDS git git-remote-http)
 610 add_custom_target(git-links ALL DEPENDS ${git_links} ${git_http_links})
 611
 612
 613 #creating required scripts
 614 set(SHELL_PATH /bin/sh)
 615 set(PERL_PATH /usr/bin/perl)
 616 set(LOCALEDIR ${FALLBACK_RUNTIME_PREFIX}/share/locale)
 617 set(GITWEBDIR ${FALLBACK_RUNTIME_PREFIX}/share/locale)
 618 set(INSTLIBDIR ${FALLBACK_RUNTIME_PREFIX}/share/perl5)
 619
 620 #shell scripts
 621 parse_makefile_for_scripts(git_sh_scripts "SCRIPT_SH" ".sh")
 622 parse_makefile_for_scripts(git_shlib_scripts "SCRIPT_LIB" "")
 623 set(git_shell_scripts
 624         ${git_sh_scripts} ${git_shlib_scripts} git-instaweb)
 625
 626 foreach(script ${git_shell_scripts})
 627         file(STRINGS ${CMAKE_SOURCE_DIR}/${script}.sh content NEWLINE_CONSUME)
 628         string(REPLACE "@SHELL_PATH@" "${SHELL_PATH}" content "${content}")
 629         string(REPLACE "@@DIFF@@" "diff" content "${content}")
 630         string(REPLACE "@LOCALEDIR@" "${LOCALEDIR}" content "${content}")
 631         string(REPLACE "@GITWEBDIR@" "${GITWEBDIR}" content "${content}")
 632         string(REPLACE "@@NO_CURL@@" "" content "${content}")
 633         string(REPLACE "@@USE_GETTEXT_SCHEME@@" "" content "${content}")
 634         string(REPLACE "# @@BROKEN_PATH_FIX@@" "" content "${content}")
 635         string(REPLACE "@@PERL@@" "${PERL_PATH}" content "${content}")
 636         string(REPLACE "@@SANE_TEXT_GREP@@" "-a" content "${content}")
 637         string(REPLACE "@@PAGER_ENV@@" "LESS=FRX LV=-c" content "${content}")
 638         file(WRITE ${CMAKE_BINARY_DIR}/${script} ${content})
 639 endforeach()
 640
 641 #perl scripts
 642 parse_makefile_for_scripts(git_perl_scripts "SCRIPT_PERL" ".perl")
 643
 644 #create perl header
 645 file(STRINGS ${CMAKE_SOURCE_DIR}/perl/header_templates/fixed_prefix.template.pl perl_header )
 646 string(REPLACE "@@PATHSEP@@" ":" perl_header "${perl_header}")
 647 string(REPLACE "@@INSTLIBDIR@@" "${INSTLIBDIR}" perl_header "${perl_header}")
 648
 649 foreach(script ${git_perl_scripts})
 650         file(STRINGS ${CMAKE_SOURCE_DIR}/${script}.perl content NEWLINE_CONSUME)
 651         string(REPLACE "#!/usr/bin/perl" "#!/usr/bin/perl\n${perl_header}\n" content "${content}")
 652         string(REPLACE "@@GIT_VERSION@@" "${PROJECT_VERSION}" content "${content}")
 653         file(WRITE ${CMAKE_BINARY_DIR}/${script} ${content})
 654 endforeach()
 655
 656 #python script
 657 file(STRINGS ${CMAKE_SOURCE_DIR}/git-p4.py content NEWLINE_CONSUME)
 658 string(REPLACE "#!/usr/bin/env python" "#!/usr/bin/python" content "${content}")
 659 file(WRITE ${CMAKE_BINARY_DIR}/git-p4 ${content})
 660
 661 #perl modules
 662 file(GLOB_RECURSE perl_modules "${CMAKE_SOURCE_DIR}/perl/*.pm")
 663
 664 foreach(pm ${perl_modules})
 665         string(REPLACE "${CMAKE_SOURCE_DIR}/perl/" "" file_path ${pm})
 666         file(STRINGS ${pm} content NEWLINE_CONSUME)
 667         string(REPLACE "@@LOCALEDIR@@" "${LOCALEDIR}" content "${content}")
 668         string(REPLACE "@@NO_PERL_CPAN_FALLBACKS@@" "" content "${content}")
 669         file(WRITE ${CMAKE_BINARY_DIR}/perl/build/lib/${file_path} ${content})
 670 #test-lib.sh requires perl/build/lib to be the build directory of perl modules
 671 endforeach()
 672
 673
 674 #templates
 675 file(GLOB templates "${CMAKE_SOURCE_DIR}/templates/*")
 676 list(TRANSFORM templates REPLACE "${CMAKE_SOURCE_DIR}/templates/" "")
 677 list(REMOVE_ITEM templates ".gitignore")
 678 list(REMOVE_ITEM templates "Makefile")
 679 list(REMOVE_ITEM templates "blt")# Prevents an error when reconfiguring for in source builds
 680
 681 list(REMOVE_ITEM templates "branches--")
 682 file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/templates/blt/branches) #create branches
 683
 684 #templates have @.*@ replacement so use configure_file instead
 685 foreach(tm ${templates})
 686         string(REPLACE "--" "/" blt_tm ${tm})
 687         string(REPLACE "this" "" blt_tm ${blt_tm})# for this--
 688         configure_file(${CMAKE_SOURCE_DIR}/templates/${tm} ${CMAKE_BINARY_DIR}/templates/blt/${blt_tm} @ONLY)
 689 endforeach()
 690
 691
 692 #translations
 693 if(MSGFMT_EXE)
 694         file(GLOB po_files "${CMAKE_SOURCE_DIR}/po/*.po")
 695         list(TRANSFORM po_files REPLACE "${CMAKE_SOURCE_DIR}/po/" "")
 696         list(TRANSFORM po_files REPLACE ".po" "")
 697         foreach(po ${po_files})
 698                 file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES)
 699                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo
 700                                 COMMAND ${MSGFMT_EXE} --check --statistics -o ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo ${CMAKE_SOURCE_DIR}/po/${po}.po)
 701                 list(APPEND po_gen ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo)
 702         endforeach()
 703         add_custom_target(po-gen ALL DEPENDS ${po_gen})
 704 endif()
 705
 706
 707 #to help with the install
 708 list(TRANSFORM git_shell_scripts PREPEND "${CMAKE_BINARY_DIR}/")
 709 list(TRANSFORM git_perl_scripts PREPEND "${CMAKE_BINARY_DIR}/")
 710
 711 #install
 712 install(TARGETS git git-shell
 713         RUNTIME DESTINATION bin)
 714 install(PROGRAMS ${CMAKE_BINARY_DIR}/git-cvsserver
 715         DESTINATION bin)
 716
 717 list(REMOVE_ITEM PROGRAMS_BUILT git git-shell)
 718 install(TARGETS ${PROGRAMS_BUILT}
 719         RUNTIME DESTINATION libexec/git-core)
 720
 721 set(bin_links
 722         git-receive-pack git-upload-archive git-upload-pack)
 723
 724 foreach(b ${bin_links})
 725 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git ${CMAKE_INSTALL_PREFIX}/bin/${b})")
 726 endforeach()
 727
 728 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git)")
 729 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git-shell ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git-shell)")
 730
 731 foreach(b ${git_links})
 732         string(REPLACE "${CMAKE_BINARY_DIR}" "" b ${b})
 733         install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git ${CMAKE_INSTALL_PREFIX}/libexec/git-core/${b})")
 734 endforeach()
 735
 736 foreach(b ${git_http_links})
 737         string(REPLACE "${CMAKE_BINARY_DIR}" "" b ${b})
 738         install(CODE "file(CREATE_LINK  ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git-remote-http ${CMAKE_INSTALL_PREFIX}/libexec/git-core/${b})")
 739 endforeach()
 740
 741 install(PROGRAMS ${git_shell_scripts} ${git_perl_scripts} ${CMAKE_BINARY_DIR}/git-p4
 742         DESTINATION libexec/git-core)
 743
 744 install(DIRECTORY ${CMAKE_SOURCE_DIR}/mergetools DESTINATION libexec/git-core)
 745 install(DIRECTORY ${CMAKE_BINARY_DIR}/perl/build/lib/ DESTINATION share/perl5
 746         FILES_MATCHING PATTERN "*.pm")
 747 install(DIRECTORY ${CMAKE_BINARY_DIR}/templates/blt/ DESTINATION share/git-core/templates)
 748
 749 if(MSGFMT_EXE)
 750         install(DIRECTORY ${CMAKE_BINARY_DIR}/po/build/locale DESTINATION share)
 751 endif()
 752
 753
 754 if(BUILD_TESTING)
 755
 756 #tests-helpers
 757 add_executable(test-fake-ssh ${CMAKE_SOURCE_DIR}/t/helper/test-fake-ssh.c)
 758 target_link_libraries(test-fake-ssh common-main)
 759
 760 add_executable(test-line-buffer ${CMAKE_SOURCE_DIR}/t/helper/test-line-buffer.c)
 761 target_link_libraries(test-line-buffer common-main vcs-svn)
 762
 763 add_executable(test-svn-fe ${CMAKE_SOURCE_DIR}/t/helper/test-svn-fe.c)
 764 target_link_libraries(test-svn-fe common-main vcs-svn)
 765
 766 #test-tool
 767 parse_makefile_for_sources(test-tool_SOURCES "TEST_BUILTINS_OBJS")
 768
 769 list(TRANSFORM test-tool_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/t/helper/")
 770 add_executable(test-tool ${CMAKE_SOURCE_DIR}/t/helper/test-tool.c ${test-tool_SOURCES})
 771 target_link_libraries(test-tool common-main)
 772
 773 set_target_properties(test-fake-ssh test-line-buffer test-svn-fe test-tool
 774                         PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/t/helper)
 775
 776 #wrapper scripts
 777 set(wrapper_scripts
 778         git git-upload-pack git-receive-pack git-upload-archive git-shell git-remote-ext)
 779
 780 set(wrapper_test_scripts
 781         test-fake-ssh test-line-buffer test-svn-fe test-tool)
 782
 783
 784 foreach(script ${wrapper_scripts})
 785         file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
 786         string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
 787         string(REPLACE "@@PROG@@" "${script}" content "${content}")
 788         file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/${script} ${content})
 789 endforeach()
 790
 791 foreach(script ${wrapper_test_scripts})
 792         file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
 793         string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
 794         string(REPLACE "@@PROG@@" "t/helper/${script}" content "${content}")
 795         file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/${script} ${content})
 796 endforeach()
 797
 798 file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
 799 string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
 800 string(REPLACE "@@PROG@@" "git-cvsserver" content "${content}")
 801 file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/git-cvsserver ${content})
 802
 803 #options for configuring test options
 804 option(PERL_TESTS "Perform tests that use perl" ON)
 805 option(PYTHON_TESTS "Perform tests that use python" ON)
 806
 807 #GIT-BUILD-OPTIONS
 808 set(TEST_SHELL_PATH ${SHELL_PATH})
 809 set(DIFF diff)
 810 set(PYTHON_PATH /usr/bin/python)
 811 set(TAR tar)
 812 set(NO_CURL )
 813 set(NO_EXPAT )
 814 set(USE_LIBPCRE1 )
 815 set(USE_LIBPCRE2 )
 816 set(NO_LIBPCRE1_JIT )
 817 set(NO_PERL )
 818 set(NO_PTHREADS )
 819 set(NO_PYTHON )
 820 set(PAGER_ENV "LESS=FRX LV=-c")
 821 set(DC_SHA1 YesPlease)
 822 set(RUNTIME_PREFIX true)
 823 set(NO_GETTEXT )
 824
 825 if(NOT CURL_FOUND)
 826         set(NO_CURL 1)
 827 endif()
 828
 829 if(NOT EXPAT_FOUND)
 830         set(NO_EXPAT 1)
 831 endif()
 832
 833 if(NOT Intl_FOUND)
 834         set(NO_GETTEXT 1)
 835 endif()
 836
 837 if(NOT PERL_TESTS)
 838         set(NO_PERL 1)
 839 endif()
 840
 841 if(NOT PYTHON_TESTS)
 842         set(NO_PYTHON 1)
 843 endif()
 844
 845 file(WRITE ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "SHELL_PATH='${SHELL_PATH}'\n")
 846 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "TEST_SHELL_PATH='${TEST_SHELL_PATH}'\n")
 847 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PERL_PATH='${PERL_PATH}'\n")
 848 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "DIFF='${DIFF}'\n")
 849 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PYTHON_PATH='${PYTHON_PATH}'\n")
 850 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "TAR='${TAR}'\n")
 851 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_CURL='${NO_CURL}'\n")
 852 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_EXPAT='${NO_EXPAT}'\n")
 853 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "USE_LIBPCRE1='${USE_LIBPCRE1}'\n")
 854 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_LIBPCRE1_JIT='${NO_LIBPCRE1_JIT}'\n")
 855 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PERL='${NO_PERL}'\n")
 856 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PTHREADS='${NO_PTHREADS}'\n")
 857 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_UNIX_SOCKETS='${NO_UNIX_SOCKETS}'\n")
 858 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PAGER_ENV='${PAGER_ENV}'\n")
 859 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "DC_SHA1='${DC_SHA1}'\n")
 860 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "X=''\n")
 861 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_GETTEXT='${NO_GETTEXT}'\n")
 862 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "RUNTIME_PREFIX='${RUNTIME_PREFIX}'\n")
 863 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PYTHON='${NO_PYTHON}'\n")
 864
 865 #Make the tests work when building out of the source tree
 866 get_filename_component(CACHE_PATH ${CMAKE_CURRENT_LIST_DIR}/../../CMakeCache.txt ABSOLUTE)
 867 if(NOT ${CMAKE_BINARY_DIR}/CMakeCache.txt STREQUAL ${CACHE_PATH})
 868         file(RELATIVE_PATH BUILD_DIR_RELATIVE ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/CMakeCache.txt)
 869         string(REPLACE "/CMakeCache.txt" "" BUILD_DIR_RELATIVE ${BUILD_DIR_RELATIVE})
 870         #Setting the build directory in test-lib.sh before running tests
 871         file(WRITE ${CMAKE_BINARY_DIR}/CTestCustom.cmake
 872                 "file(STRINGS ${CMAKE_SOURCE_DIR}/t/test-lib.sh GIT_BUILD_DIR_REPL REGEX \"GIT_BUILD_DIR=(.*)\")\n"
 873                 "file(STRINGS ${CMAKE_SOURCE_DIR}/t/test-lib.sh content NEWLINE_CONSUME)\n"
 874                 "string(REPLACE \"\${GIT_BUILD_DIR_REPL}\" \"GIT_BUILD_DIR=\\\"$TEST_DIRECTORY\\\"/../${BUILD_DIR_RELATIVE}\" content \"\${content}\")\n"
 875                 "file(WRITE ${CMAKE_SOURCE_DIR}/t/test-lib.sh \${content})")
 876         #misc copies
 877         file(COPY ${CMAKE_SOURCE_DIR}/t/chainlint.sed DESTINATION ${CMAKE_BINARY_DIR}/t/)
 878         file(COPY ${CMAKE_SOURCE_DIR}/po/is.po DESTINATION ${CMAKE_BINARY_DIR}/po/)
 879         file(COPY ${CMAKE_SOURCE_DIR}/mergetools/tkdiff DESTINATION ${CMAKE_BINARY_DIR}/mergetools/)
 880         file(COPY ${CMAKE_SOURCE_DIR}/contrib/completion/git-prompt.sh DESTINATION ${CMAKE_BINARY_DIR}/contrib/completion/)
 881         file(COPY ${CMAKE_SOURCE_DIR}/contrib/completion/git-completion.bash DESTINATION ${CMAKE_BINARY_DIR}/contrib/completion/)
 882         file(COPY ${CMAKE_SOURCE_DIR}/contrib/svn-fe/svnrdump_sim.py DESTINATION ${CMAKE_BINARY_DIR}/contrib/svn-fe/)
 883 endif()
 884
 885 file(GLOB test_scipts "${CMAKE_SOURCE_DIR}/t/t[0-9]*.sh")
 886
 887 #test
 888 foreach(tsh ${test_scipts})
 889         add_test(NAME ${tsh}
 890                 COMMAND ${SH_EXE} ${tsh}
 891                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/t)
 892 endforeach()
 893
 894 endif()#BUILD_TESTING