git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --annotate                     * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --compose-encoding      <str>  * Encoding to assume for introduction.
  60     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  61
  62   Sending:
  63     --envelope-sender       <str>  * Email envelope sender.
  64     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  65                                      is optional. Default 'localhost'.
  66     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  67     --smtp-server-port      <int>  * Outgoing SMTP server port.
  68     --smtp-user             <str>  * Username for SMTP-AUTH.
  69     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  70     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  71     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  72     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  73     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  74
  75   Automating:
  76     --identity              <str>  * Use the sendemail.<id> options.
  77     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  78     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  79     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  80     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  81     --[no-]suppress-from           * Send to self. Default off.
  82     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  83     --[no-]thread                  * Use In-Reply-To: field. Default on.
  84
  85   Administering:
  86     --confirm               <str>  * Confirm recipients before sending;
  87                                      auto, cc, compose, always, or never.
  88     --quiet                        * Output one line of info per email.
  89     --dry-run                      * Don't actually send the emails.
  90     --[no-]validate                * Perform patch sanity checks. Default on.
  91     --[no-]format-patch            * understand any non optional arguments as
  92                                      `git format-patch` ones.
  93     --force                        * Send even if safety checks would prevent it.
  94
  95 EOT
  96         exit(1);
  97 }
  98
  99 # most mail servers generate the Date: header, but not all...
 100 sub format_2822_time {
 101         my ($time) = @_;
 102         my @localtm = localtime($time);
 103         my @gmttm = gmtime($time);
 104         my $localmin = $localtm[1] + $localtm[2] * 60;
 105         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 106         if ($localtm[0] != $gmttm[0]) {
 107                 die "local zone differs from GMT by a non-minute interval\n";
 108         }
 109         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 110                 $localmin += 1440;
 111         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 112                 $localmin -= 1440;
 113         } elsif ($gmttm[6] != $localtm[6]) {
 114                 die "local time offset greater than or equal to 24 hours\n";
 115         }
 116         my $offset = $localmin - $gmtmin;
 117         my $offhour = $offset / 60;
 118         my $offmin = abs($offset % 60);
 119         if (abs($offhour) >= 24) {
 120                 die ("local time offset greater than or equal to 24 hours\n");
 121         }
 122
 123         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 124                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 125                        $localtm[3],
 126                        qw(Jan Feb Mar Apr May Jun
 127                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 128                        $localtm[5]+1900,
 129                        $localtm[2],
 130                        $localtm[1],
 131                        $localtm[0],
 132                        ($offset >= 0) ? '+' : '-',
 133                        abs($offhour),
 134                        $offmin,
 135                        );
 136 }
 137
 138 my $have_email_valid = eval { require Email::Valid; 1 };
 139 my $have_mail_address = eval { require Mail::Address; 1 };
 140 my $smtp;
 141 my $auth;
 142
 143 # Variables we fill in automatically, or via prompting:
 144 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 145         $initial_reply_to,$initial_subject,@files,
 146         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 147
 148 my $envelope_sender;
 149
 150 # Example reply to:
 151 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 152
 153 my $repo = eval { Git->repository() };
 154 my @repo = $repo ? ($repo) : ();
 155 my $term = eval {
 156         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 157                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 158                 : new Term::ReadLine 'git-send-email';
 159 };
 160 if ($@) {
 161         $term = new FakeTerm "$@: going non-interactive";
 162 }
 163
 164 # Behavior modification variables
 165 my ($quiet, $dry_run) = (0, 0);
 166 my $format_patch;
 167 my $compose_filename;
 168 my $force = 0;
 169
 170 # Handle interactive edition of files.
 171 my $multiedit;
 172 my $editor;
 173
 174 sub do_edit {
 175         if (!defined($editor)) {
 176                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 177         }
 178         if (defined($multiedit) && !$multiedit) {
 179                 map {
 180                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 181                         if (($? & 127) || ($? >> 8)) {
 182                                 die("the editor exited uncleanly, aborting everything");
 183                         }
 184                 } @_;
 185         } else {
 186                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 187                 if (($? & 127) || ($? >> 8)) {
 188                         die("the editor exited uncleanly, aborting everything");
 189                 }
 190         }
 191 }
 192
 193 # Variables with corresponding config settings
 194 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 195 my ($to_cmd, $cc_cmd);
 196 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 197 my ($smtp_authuser, $smtp_encryption);
 198 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 199 my ($validate, $confirm);
 200 my (@suppress_cc);
 201 my ($auto_8bit_encoding);
 202 my ($compose_encoding);
 203
 204 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 205
 206 my $not_set_by_user = "true but not set by the user";
 207
 208 my %config_bool_settings = (
 209     "thread" => [\$thread, 1],
 210     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 211     "suppressfrom" => [\$suppress_from, undef],
 212     "signedoffbycc" => [\$signed_off_by_cc, undef],
 213     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 214     "validate" => [\$validate, 1],
 215     "multiedit" => [\$multiedit, undef]
 216 );
 217
 218 my %config_settings = (
 219     "smtpserver" => \$smtp_server,
 220     "smtpserverport" => \$smtp_server_port,
 221     "smtpserveroption" => \@smtp_server_options,
 222     "smtpuser" => \$smtp_authuser,
 223     "smtppass" => \$smtp_authpass,
 224     "smtpdomain" => \$smtp_domain,
 225     "to" => \@initial_to,
 226     "tocmd" => \$to_cmd,
 227     "cc" => \@initial_cc,
 228     "cccmd" => \$cc_cmd,
 229     "aliasfiletype" => \$aliasfiletype,
 230     "bcc" => \@bcclist,
 231     "suppresscc" => \@suppress_cc,
 232     "envelopesender" => \$envelope_sender,
 233     "confirm"   => \$confirm,
 234     "from" => \$sender,
 235     "assume8bitencoding" => \$auto_8bit_encoding,
 236     "composeencoding" => \$compose_encoding,
 237 );
 238
 239 my %config_path_settings = (
 240     "aliasesfile" => \@alias_files,
 241 );
 242
 243 # Help users prepare for 1.7.0
 244 sub chain_reply_to {
 245         if (defined $chain_reply_to &&
 246             $chain_reply_to eq $not_set_by_user) {
 247                 print STDERR
 248                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 249                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 250                     "you want to keep --chain-reply-to as your default.\n";
 251                 $chain_reply_to = 0;
 252         }
 253         return $chain_reply_to;
 254 }
 255
 256 # Handle Uncouth Termination
 257 sub signal_handler {
 258
 259         # Make text normal
 260         print color("reset"), "\n";
 261
 262         # SMTP password masked
 263         system "stty echo";
 264
 265         # tmp files from --compose
 266         if (defined $compose_filename) {
 267                 if (-e $compose_filename) {
 268                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 269                 }
 270                 if (-e ($compose_filename . ".final")) {
 271                         print "'$compose_filename.final' contains the composed email.\n"
 272                 }
 273         }
 274
 275         exit;
 276 };
 277
 278 $SIG{TERM} = \&signal_handler;
 279 $SIG{INT}  = \&signal_handler;
 280
 281 # Begin by accumulating all the variables (defined above), that we will end up
 282 # needing, first, from the command line:
 283
 284 my $help;
 285 my $rc = GetOptions("h" => \$help,
 286                     "sender|from=s" => \$sender,
 287                     "in-reply-to=s" => \$initial_reply_to,
 288                     "subject=s" => \$initial_subject,
 289                     "to=s" => \@initial_to,
 290                     "to-cmd=s" => \$to_cmd,
 291                     "no-to" => \$no_to,
 292                     "cc=s" => \@initial_cc,
 293                     "no-cc" => \$no_cc,
 294                     "bcc=s" => \@bcclist,
 295                     "no-bcc" => \$no_bcc,
 296                     "chain-reply-to!" => \$chain_reply_to,
 297                     "smtp-server=s" => \$smtp_server,
 298                     "smtp-server-option=s" => \@smtp_server_options,
 299                     "smtp-server-port=s" => \$smtp_server_port,
 300                     "smtp-user=s" => \$smtp_authuser,
 301                     "smtp-pass:s" => \$smtp_authpass,
 302                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 303                     "smtp-encryption=s" => \$smtp_encryption,
 304                     "smtp-debug:i" => \$debug_net_smtp,
 305                     "smtp-domain:s" => \$smtp_domain,
 306                     "identity=s" => \$identity,
 307                     "annotate" => \$annotate,
 308                     "compose" => \$compose,
 309                     "quiet" => \$quiet,
 310                     "cc-cmd=s" => \$cc_cmd,
 311                     "suppress-from!" => \$suppress_from,
 312                     "suppress-cc=s" => \@suppress_cc,
 313                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 314                     "confirm=s" => \$confirm,
 315                     "dry-run" => \$dry_run,
 316                     "envelope-sender=s" => \$envelope_sender,
 317                     "thread!" => \$thread,
 318                     "validate!" => \$validate,
 319                     "format-patch!" => \$format_patch,
 320                     "8bit-encoding=s" => \$auto_8bit_encoding,
 321                     "compose-encoding=s" => \$compose_encoding,
 322                     "force" => \$force,
 323          );
 324
 325 usage() if $help;
 326 unless ($rc) {
 327     usage();
 328 }
 329
 330 die "Cannot run git format-patch from outside a repository\n"
 331         if $format_patch and not $repo;
 332
 333 # Now, let's fill any that aren't set in with defaults:
 334
 335 sub read_config {
 336         my ($prefix) = @_;
 337
 338         foreach my $setting (keys %config_bool_settings) {
 339                 my $target = $config_bool_settings{$setting}->[0];
 340                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 341         }
 342
 343         foreach my $setting (keys %config_path_settings) {
 344                 my $target = $config_path_settings{$setting};
 345                 if (ref($target) eq "ARRAY") {
 346                         unless (@$target) {
 347                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 348                                 @$target = @values if (@values && defined $values[0]);
 349                         }
 350                 }
 351                 else {
 352                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 353                 }
 354         }
 355
 356         foreach my $setting (keys %config_settings) {
 357                 my $target = $config_settings{$setting};
 358                 next if $setting eq "to" and defined $no_to;
 359                 next if $setting eq "cc" and defined $no_cc;
 360                 next if $setting eq "bcc" and defined $no_bcc;
 361                 if (ref($target) eq "ARRAY") {
 362                         unless (@$target) {
 363                                 my @values = Git::config(@repo, "$prefix.$setting");
 364                                 @$target = @values if (@values && defined $values[0]);
 365                         }
 366                 }
 367                 else {
 368                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 369                 }
 370         }
 371
 372         if (!defined $smtp_encryption) {
 373                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 374                 if (defined $enc) {
 375                         $smtp_encryption = $enc;
 376                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 377                         $smtp_encryption = 'ssl';
 378                 }
 379         }
 380 }
 381
 382 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 383 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 384 read_config("sendemail.$identity") if (defined $identity);
 385 read_config("sendemail");
 386
 387 # fall back on builtin bool defaults
 388 foreach my $setting (values %config_bool_settings) {
 389         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 390 }
 391
 392 # 'default' encryption is none -- this only prevents a warning
 393 $smtp_encryption = '' unless (defined $smtp_encryption);
 394
 395 # Set CC suppressions
 396 my(%suppress_cc);
 397 if (@suppress_cc) {
 398         foreach my $entry (@suppress_cc) {
 399                 die "Unknown --suppress-cc field: '$entry'\n"
 400                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 401                 $suppress_cc{$entry} = 1;
 402         }
 403 }
 404
 405 if ($suppress_cc{'all'}) {
 406         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 407                 $suppress_cc{$entry} = 1;
 408         }
 409         delete $suppress_cc{'all'};
 410 }
 411
 412 # If explicit old-style ones are specified, they trump --suppress-cc.
 413 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 414 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 415
 416 if ($suppress_cc{'body'}) {
 417         foreach my $entry (qw (sob bodycc)) {
 418                 $suppress_cc{$entry} = 1;
 419         }
 420         delete $suppress_cc{'body'};
 421 }
 422
 423 # Set confirm's default value
 424 my $confirm_unconfigured = !defined $confirm;
 425 if ($confirm_unconfigured) {
 426         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 427 };
 428 die "Unknown --confirm setting: '$confirm'\n"
 429         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 430
 431 # Debugging, print out the suppressions.
 432 if (0) {
 433         print "suppressions:\n";
 434         foreach my $entry (keys %suppress_cc) {
 435                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 436         }
 437 }
 438
 439 my ($repoauthor, $repocommitter);
 440 ($repoauthor) = Git::ident_person(@repo, 'author');
 441 ($repocommitter) = Git::ident_person(@repo, 'committer');
 442
 443 # Verify the user input
 444
 445 foreach my $entry (@initial_to) {
 446         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 447 }
 448
 449 foreach my $entry (@initial_cc) {
 450         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 451 }
 452
 453 foreach my $entry (@bcclist) {
 454         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 455 }
 456
 457 sub parse_address_line {
 458         if ($have_mail_address) {
 459                 return map { $_->format } Mail::Address->parse($_[0]);
 460         } else {
 461                 return split_addrs($_[0]);
 462         }
 463 }
 464
 465 sub split_addrs {
 466         return quotewords('\s*,\s*', 1, @_);
 467 }
 468
 469 my %aliases;
 470 my %parse_alias = (
 471         # multiline formats can be supported in the future
 472         mutt => sub { my $fh = shift; while (<$fh>) {
 473                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 474                         my ($alias, $addr) = ($1, $2);
 475                         $addr =~ s/#.*$//; # mutt allows # comments
 476                          # commas delimit multiple addresses
 477                         $aliases{$alias} = [ split_addrs($addr) ];
 478                 }}},
 479         mailrc => sub { my $fh = shift; while (<$fh>) {
 480                 if (/^alias\s+(\S+)\s+(.*)$/) {
 481                         # spaces delimit multiple addresses
 482                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 483                 }}},
 484         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 485                 for (my $x = ''; defined($x); $x = $_) {
 486                         chomp $x;
 487                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 488                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 489                         $aliases{$1} = [ split_addrs($2) ];
 490                 }},
 491         elm => sub  { my $fh = shift;
 492                       while (<$fh>) {
 493                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 494                               my ($alias, $addr) = ($1, $2);
 495                                $aliases{$alias} = [ split_addrs($addr) ];
 496                           }
 497                       } },
 498
 499         gnus => sub { my $fh = shift; while (<$fh>) {
 500                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 501                         $aliases{$1} = [ $2 ];
 502                 }}}
 503 );
 504
 505 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 506         foreach my $file (@alias_files) {
 507                 open my $fh, '<', $file or die "opening $file: $!\n";
 508                 $parse_alias{$aliasfiletype}->($fh);
 509                 close $fh;
 510         }
 511 }
 512
 513 ($sender) = expand_aliases($sender) if defined $sender;
 514
 515 # returns 1 if the conflict must be solved using it as a format-patch argument
 516 sub check_file_rev_conflict($) {
 517         return unless $repo;
 518         my $f = shift;
 519         try {
 520                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 521                 if (defined($format_patch)) {
 522                         return $format_patch;
 523                 }
 524                 die(<<EOF);
 525 File '$f' exists but it could also be the range of commits
 526 to produce patches for.  Please disambiguate by...
 527
 528     * Saying "./$f" if you mean a file; or
 529     * Giving --format-patch option if you mean a range.
 530 EOF
 531         } catch Git::Error::Command with {
 532                 return 0;
 533         }
 534 }
 535
 536 # Now that all the defaults are set, process the rest of the command line
 537 # arguments and collect up the files that need to be processed.
 538 my @rev_list_opts;
 539 while (defined(my $f = shift @ARGV)) {
 540         if ($f eq "--") {
 541                 push @rev_list_opts, "--", @ARGV;
 542                 @ARGV = ();
 543         } elsif (-d $f and !check_file_rev_conflict($f)) {
 544                 opendir my $dh, $f
 545                         or die "Failed to opendir $f: $!";
 546
 547                 push @files, grep { -f $_ } map { catfile($f, $_) }
 548                                 sort readdir $dh;
 549                 closedir $dh;
 550         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 551                 push @files, $f;
 552         } else {
 553                 push @rev_list_opts, $f;
 554         }
 555 }
 556
 557 if (@rev_list_opts) {
 558         die "Cannot run git format-patch from outside a repository\n"
 559                 unless $repo;
 560         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 561 }
 562
 563 if ($validate) {
 564         foreach my $f (@files) {
 565                 unless (-p $f) {
 566                         my $error = validate_patch($f);
 567                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 568                 }
 569         }
 570 }
 571
 572 if (@files) {
 573         unless ($quiet) {
 574                 print $_,"\n" for (@files);
 575         }
 576 } else {
 577         print STDERR "\nNo patch files specified!\n\n";
 578         usage();
 579 }
 580
 581 sub get_patch_subject {
 582         my $fn = shift;
 583         open (my $fh, '<', $fn);
 584         while (my $line = <$fh>) {
 585                 next unless ($line =~ /^Subject: (.*)$/);
 586                 close $fh;
 587                 return "GIT: $1\n";
 588         }
 589         close $fh;
 590         die "No subject line in $fn ?";
 591 }
 592
 593 if ($compose) {
 594         # Note that this does not need to be secure, but we will make a small
 595         # effort to have it be unique
 596         $compose_filename = ($repo ?
 597                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 598                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 599         open my $c, ">", $compose_filename
 600                 or die "Failed to open for writing $compose_filename: $!";
 601
 602
 603         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 604         my $tpl_subject = $initial_subject || '';
 605         my $tpl_reply_to = $initial_reply_to || '';
 606
 607         print $c <<EOT;
 608 From $tpl_sender # This line is ignored.
 609 GIT: Lines beginning in "GIT:" will be removed.
 610 GIT: Consider including an overall diffstat or table of contents
 611 GIT: for the patch you are writing.
 612 GIT:
 613 GIT: Clear the body content if you don't wish to send a summary.
 614 From: $tpl_sender
 615 Subject: $tpl_subject
 616 In-Reply-To: $tpl_reply_to
 617
 618 EOT
 619         for my $f (@files) {
 620                 print $c get_patch_subject($f);
 621         }
 622         close $c;
 623
 624         if ($annotate) {
 625                 do_edit($compose_filename, @files);
 626         } else {
 627                 do_edit($compose_filename);
 628         }
 629
 630         open my $c2, ">", $compose_filename . ".final"
 631                 or die "Failed to open $compose_filename.final : " . $!;
 632
 633         open $c, "<", $compose_filename
 634                 or die "Failed to open $compose_filename : " . $!;
 635
 636         my $need_8bit_cte = file_has_nonascii($compose_filename);
 637         my $in_body = 0;
 638         my $summary_empty = 1;
 639         if (!defined $compose_encoding) {
 640                 $compose_encoding = "UTF-8";
 641         }
 642         while(<$c>) {
 643                 next if m/^GIT:/;
 644                 if ($in_body) {
 645                         $summary_empty = 0 unless (/^\n$/);
 646                 } elsif (/^\n$/) {
 647                         $in_body = 1;
 648                         if ($need_8bit_cte) {
 649                                 print $c2 "MIME-Version: 1.0\n",
 650                                          "Content-Type: text/plain; ",
 651                                            "charset=$compose_encoding\n",
 652                                          "Content-Transfer-Encoding: 8bit\n";
 653                         }
 654                 } elsif (/^MIME-Version:/i) {
 655                         $need_8bit_cte = 0;
 656                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 657                         $initial_subject = $1;
 658                         my $subject = $initial_subject;
 659                         $_ = "Subject: " .
 660                                 quote_subject($subject, $compose_encoding) .
 661                                 "\n";
 662                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 663                         $initial_reply_to = $1;
 664                         next;
 665                 } elsif (/^From:\s*(.+)\s*$/i) {
 666                         $sender = $1;
 667                         next;
 668                 } elsif (/^(?:To|Cc|Bcc):/i) {
 669                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 670                         next;
 671                 }
 672                 print $c2 $_;
 673         }
 674         close $c;
 675         close $c2;
 676
 677         if ($summary_empty) {
 678                 print "Summary email is empty, skipping it\n";
 679                 $compose = -1;
 680         }
 681 } elsif ($annotate) {
 682         do_edit(@files);
 683 }
 684
 685 sub ask {
 686         my ($prompt, %arg) = @_;
 687         my $valid_re = $arg{valid_re};
 688         my $default = $arg{default};
 689         my $confirm_only = $arg{confirm_only};
 690         my $resp;
 691         my $i = 0;
 692         return defined $default ? $default : undef
 693                 unless defined $term->IN and defined fileno($term->IN) and
 694                        defined $term->OUT and defined fileno($term->OUT);
 695         while ($i++ < 10) {
 696                 $resp = $term->readline($prompt);
 697                 if (!defined $resp) { # EOF
 698                         print "\n";
 699                         return defined $default ? $default : undef;
 700                 }
 701                 if ($resp eq '' and defined $default) {
 702                         return $default;
 703                 }
 704                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 705                         return $resp;
 706                 }
 707                 if ($confirm_only) {
 708                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 709                         if (defined $yesno && $yesno =~ /y/i) {
 710                                 return $resp;
 711                         }
 712                 }
 713         }
 714         return undef;
 715 }
 716
 717 my %broken_encoding;
 718
 719 sub file_declares_8bit_cte {
 720         my $fn = shift;
 721         open (my $fh, '<', $fn);
 722         while (my $line = <$fh>) {
 723                 last if ($line =~ /^$/);
 724                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 725         }
 726         close $fh;
 727         return 0;
 728 }
 729
 730 foreach my $f (@files) {
 731         next unless (body_or_subject_has_nonascii($f)
 732                      && !file_declares_8bit_cte($f));
 733         $broken_encoding{$f} = 1;
 734 }
 735
 736 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 737         print "The following files are 8bit, but do not declare " .
 738                 "a Content-Transfer-Encoding.\n";
 739         foreach my $f (sort keys %broken_encoding) {
 740                 print "    $f\n";
 741         }
 742         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 743                                   default => "UTF-8");
 744 }
 745
 746 if (!$force) {
 747         for my $f (@files) {
 748                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 749                         die "Refusing to send because the patch\n\t$f\n"
 750                                 . "has the template subject '*** SUBJECT HERE ***'. "
 751                                 . "Pass --force if you really want to send.\n";
 752                 }
 753         }
 754 }
 755
 756 my $prompting = 0;
 757 if (!defined $sender) {
 758         $sender = $repoauthor || $repocommitter || '';
 759         $sender = ask("Who should the emails appear to be from? [$sender] ",
 760                       default => $sender,
 761                       valid_re => qr/\@.*\./, confirm_only => 1);
 762         print "Emails will be sent from: ", $sender, "\n";
 763         $prompting++;
 764 }
 765
 766 if (!@initial_to && !defined $to_cmd) {
 767         my $to = ask("Who should the emails be sent to (if any)? ",
 768                      default => "",
 769                      valid_re => qr/\@.*\./, confirm_only => 1);
 770         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 771         $prompting++;
 772 }
 773
 774 sub expand_aliases {
 775         return map { expand_one_alias($_) } @_;
 776 }
 777
 778 my %EXPANDED_ALIASES;
 779 sub expand_one_alias {
 780         my $alias = shift;
 781         if ($EXPANDED_ALIASES{$alias}) {
 782                 die "fatal: alias '$alias' expands to itself\n";
 783         }
 784         local $EXPANDED_ALIASES{$alias} = 1;
 785         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 786 }
 787
 788 @initial_to = expand_aliases(@initial_to);
 789 @initial_to = (map { sanitize_address($_) } @initial_to);
 790 @initial_cc = expand_aliases(@initial_cc);
 791 @bcclist = expand_aliases(@bcclist);
 792
 793 if ($thread && !defined $initial_reply_to && $prompting) {
 794         $initial_reply_to = ask(
 795                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 796                 default => "",
 797                 valid_re => qr/\@.*\./, confirm_only => 1);
 798 }
 799 if (defined $initial_reply_to) {
 800         $initial_reply_to =~ s/^\s*<?//;
 801         $initial_reply_to =~ s/>?\s*$//;
 802         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 803 }
 804
 805 if (!defined $smtp_server) {
 806         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 807                 if (-x $_) {
 808                         $smtp_server = $_;
 809                         last;
 810                 }
 811         }
 812         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 813 }
 814
 815 if ($compose && $compose > 0) {
 816         @files = ($compose_filename . ".final", @files);
 817 }
 818
 819 # Variables we set as part of the loop over files
 820 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 821         $needs_confirm, $message_num, $ask_default);
 822
 823 sub extract_valid_address {
 824         my $address = shift;
 825         my $local_part_regexp = qr/[^<>"\s@]+/;
 826         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 827
 828         # check for a local address:
 829         return $address if ($address =~ /^($local_part_regexp)$/);
 830
 831         $address =~ s/^\s*<(.*)>\s*$/$1/;
 832         if ($have_email_valid) {
 833                 return scalar Email::Valid->address($address);
 834         } else {
 835                 # less robust/correct than the monster regexp in Email::Valid,
 836                 # but still does a 99% job, and one less dependency
 837                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 838                 return $1;
 839         }
 840 }
 841
 842 # Usually don't need to change anything below here.
 843
 844 # we make a "fake" message id by taking the current number
 845 # of seconds since the beginning of Unix time and tacking on
 846 # a random number to the end, in case we are called quicker than
 847 # 1 second since the last time we were called.
 848
 849 # We'll setup a template for the message id, using the "from" address:
 850
 851 my ($message_id_stamp, $message_id_serial);
 852 sub make_message_id {
 853         my $uniq;
 854         if (!defined $message_id_stamp) {
 855                 $message_id_stamp = sprintf("%s-%s", time, $$);
 856                 $message_id_serial = 0;
 857         }
 858         $message_id_serial++;
 859         $uniq = "$message_id_stamp-$message_id_serial";
 860
 861         my $du_part;
 862         for ($sender, $repocommitter, $repoauthor) {
 863                 $du_part = extract_valid_address(sanitize_address($_));
 864                 last if (defined $du_part and $du_part ne '');
 865         }
 866         if (not defined $du_part or $du_part eq '') {
 867                 require Sys::Hostname;
 868                 $du_part = 'user@' . Sys::Hostname::hostname();
 869         }
 870         my $message_id_template = "<%s-git-send-email-%s>";
 871         $message_id = sprintf($message_id_template, $uniq, $du_part);
 872         #print "new message id = $message_id\n"; # Was useful for debugging
 873 }
 874
 875
 876
 877 $time = time - scalar $#files;
 878
 879 sub unquote_rfc2047 {
 880         local ($_) = @_;
 881         my $encoding;
 882         s{=\?([^?]+)\?q\?(.*?)\?=}{
 883                 $encoding = $1;
 884                 my $e = $2;
 885                 $e =~ s/_/ /g;
 886                 $e =~ s/=([0-9A-F]{2})/chr(hex($1))/eg;
 887                 $e;
 888         }eg;
 889         return wantarray ? ($_, $encoding) : $_;
 890 }
 891
 892 sub quote_rfc2047 {
 893         local $_ = shift;
 894         my $encoding = shift || 'UTF-8';
 895         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 896         s/(.*)/=\?$encoding\?q\?$1\?=/;
 897         return $_;
 898 }
 899
 900 sub is_rfc2047_quoted {
 901         my $s = shift;
 902         my $token = qr/[^][()<>@,;:"\/?.= \000-\037\177-\377]+/;
 903         my $encoded_text = qr/[!->@-~]+/;
 904         length($s) <= 75 &&
 905         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 906 }
 907
 908 sub subject_needs_rfc2047_quoting {
 909         my $s = shift;
 910
 911         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 912 }
 913
 914 sub quote_subject {
 915         local $subject = shift;
 916         my $encoding = shift || 'UTF-8';
 917
 918         if (subject_needs_rfc2047_quoting($subject)) {
 919                 return quote_rfc2047($subject, $encoding);
 920         }
 921         return $subject;
 922 }
 923
 924 # use the simplest quoting being able to handle the recipient
 925 sub sanitize_address {
 926         my ($recipient) = @_;
 927
 928         # remove garbage after email address
 929         $recipient =~ s/(.*>).*$/$1/;
 930
 931         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 932
 933         if (not $recipient_name) {
 934                 return $recipient;
 935         }
 936
 937         # if recipient_name is already quoted, do nothing
 938         if (is_rfc2047_quoted($recipient_name)) {
 939                 return $recipient;
 940         }
 941
 942         # rfc2047 is needed if a non-ascii char is included
 943         if ($recipient_name =~ /[^[:ascii:]]/) {
 944                 $recipient_name =~ s/^"(.*)"$/$1/;
 945                 $recipient_name = quote_rfc2047($recipient_name);
 946         }
 947
 948         # double quotes are needed if specials or CTLs are included
 949         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 950                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 951                 $recipient_name = qq["$recipient_name"];
 952         }
 953
 954         return "$recipient_name $recipient_addr";
 955
 956 }
 957
 958 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 959 #
 960 # Tightly configured MTAa require that a caller sends a real DNS
 961 # domain name that corresponds the IP address in the HELO/EHLO
 962 # handshake. This is used to verify the connection and prevent
 963 # spammers from trying to hide their identity. If the DNS and IP don't
 964 # match, the receiveing MTA may deny the connection.
 965 #
 966 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
 967 #
 968 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
 969 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
 970 #
 971 # This maildomain*() code is based on ideas in Perl library Test::Reporter
 972 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
 973
 974 sub valid_fqdn {
 975         my $domain = shift;
 976         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
 977 }
 978
 979 sub maildomain_net {
 980         my $maildomain;
 981
 982         if (eval { require Net::Domain; 1 }) {
 983                 my $domain = Net::Domain::domainname();
 984                 $maildomain = $domain if valid_fqdn($domain);
 985         }
 986
 987         return $maildomain;
 988 }
 989
 990 sub maildomain_mta {
 991         my $maildomain;
 992
 993         if (eval { require Net::SMTP; 1 }) {
 994                 for my $host (qw(mailhost localhost)) {
 995                         my $smtp = Net::SMTP->new($host);
 996                         if (defined $smtp) {
 997                                 my $domain = $smtp->domain;
 998                                 $smtp->quit;
 999
1000                                 $maildomain = $domain if valid_fqdn($domain);
1001
1002                                 last if $maildomain;
1003                         }
1004                 }
1005         }
1006
1007         return $maildomain;
1008 }
1009
1010 sub maildomain {
1011         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1012 }
1013
1014 # Returns 1 if the message was sent, and 0 otherwise.
1015 # In actuality, the whole program dies when there
1016 # is an error sending a message.
1017
1018 sub send_message {
1019         my @recipients = unique_email_list(@to);
1020         @cc = (grep { my $cc = extract_valid_address($_);
1021                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1022                     }
1023                map { sanitize_address($_) }
1024                @cc);
1025         my $to = join (",\n\t", @recipients);
1026         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1027         @recipients = (map { extract_valid_address($_) } @recipients);
1028         my $date = format_2822_time($time++);
1029         my $gitversion = '@@GIT_VERSION@@';
1030         if ($gitversion =~ m/..GIT_VERSION../) {
1031             $gitversion = Git::version();
1032         }
1033
1034         my $cc = join(",\n\t", unique_email_list(@cc));
1035         my $ccline = "";
1036         if ($cc ne '') {
1037                 $ccline = "\nCc: $cc";
1038         }
1039         my $sanitized_sender = sanitize_address($sender);
1040         make_message_id() unless defined($message_id);
1041
1042         my $header = "From: $sanitized_sender
1043 To: $to${ccline}
1044 Subject: $subject
1045 Date: $date
1046 Message-Id: $message_id
1047 X-Mailer: git-send-email $gitversion
1048 ";
1049         if ($reply_to) {
1050
1051                 $header .= "In-Reply-To: $reply_to\n";
1052                 $header .= "References: $references\n";
1053         }
1054         if (@xh) {
1055                 $header .= join("\n", @xh) . "\n";
1056         }
1057
1058         my @sendmail_parameters = ('-i', @recipients);
1059         my $raw_from = $sanitized_sender;
1060         if (defined $envelope_sender && $envelope_sender ne "auto") {
1061                 $raw_from = $envelope_sender;
1062         }
1063         $raw_from = extract_valid_address($raw_from);
1064         unshift (@sendmail_parameters,
1065                         '-f', $raw_from) if(defined $envelope_sender);
1066
1067         if ($needs_confirm && !$dry_run) {
1068                 print "\n$header\n";
1069                 if ($needs_confirm eq "inform") {
1070                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1071                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1072                         print "    The Cc list above has been expanded by additional\n";
1073                         print "    addresses found in the patch commit message. By default\n";
1074                         print "    send-email prompts before sending whenever this occurs.\n";
1075                         print "    This behavior is controlled by the sendemail.confirm\n";
1076                         print "    configuration setting.\n";
1077                         print "\n";
1078                         print "    For additional information, run 'git send-email --help'.\n";
1079                         print "    To retain the current behavior, but squelch this message,\n";
1080                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1081                 }
1082                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1083                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1084                          default => $ask_default);
1085                 die "Send this email reply required" unless defined $_;
1086                 if (/^n/i) {
1087                         return 0;
1088                 } elsif (/^q/i) {
1089                         cleanup_compose_files();
1090                         exit(0);
1091                 } elsif (/^a/i) {
1092                         $confirm = 'never';
1093                 }
1094         }
1095
1096         unshift (@sendmail_parameters, @smtp_server_options);
1097
1098         if ($dry_run) {
1099                 # We don't want to send the email.
1100         } elsif ($smtp_server =~ m#^/#) {
1101                 my $pid = open my $sm, '|-';
1102                 defined $pid or die $!;
1103                 if (!$pid) {
1104                         exec($smtp_server, @sendmail_parameters) or die $!;
1105                 }
1106                 print $sm "$header\n$message";
1107                 close $sm or die $!;
1108         } else {
1109
1110                 if (!defined $smtp_server) {
1111                         die "The required SMTP server is not properly defined."
1112                 }
1113
1114                 if ($smtp_encryption eq 'ssl') {
1115                         $smtp_server_port ||= 465; # ssmtp
1116                         require Net::SMTP::SSL;
1117                         $smtp_domain ||= maildomain();
1118                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1119                                                       Hello => $smtp_domain,
1120                                                       Port => $smtp_server_port);
1121                 }
1122                 else {
1123                         require Net::SMTP;
1124                         $smtp_domain ||= maildomain();
1125                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1126                                                  ? "$smtp_server:$smtp_server_port"
1127                                                  : $smtp_server,
1128                                                  Hello => $smtp_domain,
1129                                                  Debug => $debug_net_smtp);
1130                         if ($smtp_encryption eq 'tls' && $smtp) {
1131                                 require Net::SMTP::SSL;
1132                                 $smtp->command('STARTTLS');
1133                                 $smtp->response();
1134                                 if ($smtp->code == 220) {
1135                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1136                                                 or die "STARTTLS failed! ".$smtp->message;
1137                                         $smtp_encryption = '';
1138                                         # Send EHLO again to receive fresh
1139                                         # supported commands
1140                                         $smtp->hello($smtp_domain);
1141                                 } else {
1142                                         die "Server does not support STARTTLS! ".$smtp->message;
1143                                 }
1144                         }
1145                 }
1146
1147                 if (!$smtp) {
1148                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1149                             "VALUES: server=$smtp_server ",
1150                             "encryption=$smtp_encryption ",
1151                             "hello=$smtp_domain",
1152                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1153                 }
1154
1155                 if (defined $smtp_authuser) {
1156                         # Workaround AUTH PLAIN/LOGIN interaction defect
1157                         # with Authen::SASL::Cyrus
1158                         eval {
1159                                 require Authen::SASL;
1160                                 Authen::SASL->import(qw(Perl));
1161                         };
1162
1163                         if (!defined $smtp_authpass) {
1164
1165                                 system "stty -echo";
1166
1167                                 do {
1168                                         print "Password: ";
1169                                         $_ = <STDIN>;
1170                                         print "\n";
1171                                 } while (!defined $_);
1172
1173                                 chomp($smtp_authpass = $_);
1174
1175                                 system "stty echo";
1176                         }
1177
1178                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1179                 }
1180
1181                 $smtp->mail( $raw_from ) or die $smtp->message;
1182                 $smtp->to( @recipients ) or die $smtp->message;
1183                 $smtp->data or die $smtp->message;
1184                 $smtp->datasend("$header\n$message") or die $smtp->message;
1185                 $smtp->dataend() or die $smtp->message;
1186                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1187         }
1188         if ($quiet) {
1189                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1190         } else {
1191                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1192                 if ($smtp_server !~ m#^/#) {
1193                         print "Server: $smtp_server\n";
1194                         print "MAIL FROM:<$raw_from>\n";
1195                         foreach my $entry (@recipients) {
1196                             print "RCPT TO:<$entry>\n";
1197                         }
1198                 } else {
1199                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1200                 }
1201                 print $header, "\n";
1202                 if ($smtp) {
1203                         print "Result: ", $smtp->code, ' ',
1204                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1205                 } else {
1206                         print "Result: OK\n";
1207                 }
1208         }
1209
1210         return 1;
1211 }
1212
1213 $reply_to = $initial_reply_to;
1214 $references = $initial_reply_to || '';
1215 $subject = $initial_subject;
1216 $message_num = 0;
1217
1218 foreach my $t (@files) {
1219         open my $fh, "<", $t or die "can't open file $t";
1220
1221         my $author = undef;
1222         my $author_encoding;
1223         my $has_content_type;
1224         my $body_encoding;
1225         @to = ();
1226         @cc = ();
1227         @xh = ();
1228         my $input_format = undef;
1229         my @header = ();
1230         $message = "";
1231         $message_num++;
1232         # First unfold multiline header fields
1233         while(<$fh>) {
1234                 last if /^\s*$/;
1235                 if (/^\s+\S/ and @header) {
1236                         chomp($header[$#header]);
1237                         s/^\s+/ /;
1238                         $header[$#header] .= $_;
1239             } else {
1240                         push(@header, $_);
1241                 }
1242         }
1243         # Now parse the header
1244         foreach(@header) {
1245                 if (/^From /) {
1246                         $input_format = 'mbox';
1247                         next;
1248                 }
1249                 chomp;
1250                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1251                         $input_format = 'mbox';
1252                 }
1253
1254                 if (defined $input_format && $input_format eq 'mbox') {
1255                         if (/^Subject:\s+(.*)$/) {
1256                                 $subject = $1;
1257                         }
1258                         elsif (/^From:\s+(.*)$/) {
1259                                 ($author, $author_encoding) = unquote_rfc2047($1);
1260                                 next if $suppress_cc{'author'};
1261                                 next if $suppress_cc{'self'} and $author eq $sender;
1262                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1263                                         $1, $_) unless $quiet;
1264                                 push @cc, $1;
1265                         }
1266                         elsif (/^To:\s+(.*)$/) {
1267                                 foreach my $addr (parse_address_line($1)) {
1268                                         printf("(mbox) Adding to: %s from line '%s'\n",
1269                                                 $addr, $_) unless $quiet;
1270                                         push @to, sanitize_address($addr);
1271                                 }
1272                         }
1273                         elsif (/^Cc:\s+(.*)$/) {
1274                                 foreach my $addr (parse_address_line($1)) {
1275                                         if (unquote_rfc2047($addr) eq $sender) {
1276                                                 next if ($suppress_cc{'self'});
1277                                         } else {
1278                                                 next if ($suppress_cc{'cc'});
1279                                         }
1280                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1281                                                 $addr, $_) unless $quiet;
1282                                         push @cc, $addr;
1283                                 }
1284                         }
1285                         elsif (/^Content-type:/i) {
1286                                 $has_content_type = 1;
1287                                 if (/charset="?([^ "]+)/) {
1288                                         $body_encoding = $1;
1289                                 }
1290                                 push @xh, $_;
1291                         }
1292                         elsif (/^Message-Id: (.*)/i) {
1293                                 $message_id = $1;
1294                         }
1295                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1296                                 push @xh, $_;
1297                         }
1298
1299                 } else {
1300                         # In the traditional
1301                         # "send lots of email" format,
1302                         # line 1 = cc
1303                         # line 2 = subject
1304                         # So let's support that, too.
1305                         $input_format = 'lots';
1306                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1307                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1308                                         $_, $_) unless $quiet;
1309                                 push @cc, $_;
1310                         } elsif (!defined $subject) {
1311                                 $subject = $_;
1312                         }
1313                 }
1314         }
1315         # Now parse the message body
1316         while(<$fh>) {
1317                 $message .=  $_;
1318                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1319                         chomp;
1320                         my ($what, $c) = ($1, $2);
1321                         chomp $c;
1322                         if ($c eq $sender) {
1323                                 next if ($suppress_cc{'self'});
1324                         } else {
1325                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1326                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1327                         }
1328                         push @cc, $c;
1329                         printf("(body) Adding cc: %s from line '%s'\n",
1330                                 $c, $_) unless $quiet;
1331                 }
1332         }
1333         close $fh;
1334
1335         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1336                 if defined $to_cmd;
1337         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1338                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1339
1340         if ($broken_encoding{$t} && !$has_content_type) {
1341                 $has_content_type = 1;
1342                 push @xh, "MIME-Version: 1.0",
1343                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1344                         "Content-Transfer-Encoding: 8bit";
1345                 $body_encoding = $auto_8bit_encoding;
1346         }
1347
1348         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1349                 $subject = quote_subject($subject, $auto_8bit_encoding);
1350         }
1351
1352         if (defined $author and $author ne $sender) {
1353                 $message = "From: $author\n\n$message";
1354                 if (defined $author_encoding) {
1355                         if ($has_content_type) {
1356                                 if ($body_encoding eq $author_encoding) {
1357                                         # ok, we already have the right encoding
1358                                 }
1359                                 else {
1360                                         # uh oh, we should re-encode
1361                                 }
1362                         }
1363                         else {
1364                                 $has_content_type = 1;
1365                                 push @xh,
1366                                   'MIME-Version: 1.0',
1367                                   "Content-Type: text/plain; charset=$author_encoding",
1368                                   'Content-Transfer-Encoding: 8bit';
1369                         }
1370                 }
1371         }
1372
1373         $needs_confirm = (
1374                 $confirm eq "always" or
1375                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1376                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1377         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1378
1379         @to = (@initial_to, @to);
1380         @cc = (@initial_cc, @cc);
1381
1382         my $message_was_sent = send_message();
1383
1384         # set up for the next message
1385         if ($thread && $message_was_sent &&
1386                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0 ||
1387                 $message_num == 1)) {
1388                 $reply_to = $message_id;
1389                 if (length $references > 0) {
1390                         $references .= "\n $message_id";
1391                 } else {
1392                         $references = "$message_id";
1393                 }
1394         }
1395         $message_id = undef;
1396 }
1397
1398 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1399 # and return a results array
1400 sub recipients_cmd {
1401         my ($prefix, $what, $cmd, $file) = @_;
1402
1403         my $sanitized_sender = sanitize_address($sender);
1404         my @addresses = ();
1405         open my $fh, "$cmd \Q$file\E |"
1406             or die "($prefix) Could not execute '$cmd'";
1407         while (my $address = <$fh>) {
1408                 $address =~ s/^\s*//g;
1409                 $address =~ s/\s*$//g;
1410                 $address = sanitize_address($address);
1411                 next if ($address eq $sanitized_sender and $suppress_from);
1412                 push @addresses, $address;
1413                 printf("($prefix) Adding %s: %s from: '%s'\n",
1414                        $what, $address, $cmd) unless $quiet;
1415                 }
1416         close $fh
1417             or die "($prefix) failed to close pipe to '$cmd'";
1418         return @addresses;
1419 }
1420
1421 cleanup_compose_files();
1422
1423 sub cleanup_compose_files {
1424         unlink($compose_filename, $compose_filename . ".final") if $compose;
1425 }
1426
1427 $smtp->quit if $smtp;
1428
1429 sub unique_email_list {
1430         my %seen;
1431         my @emails;
1432
1433         foreach my $entry (@_) {
1434                 if (my $clean = extract_valid_address($entry)) {
1435                         $seen{$clean} ||= 0;
1436                         next if $seen{$clean}++;
1437                         push @emails, $entry;
1438                 } else {
1439                         print STDERR "W: unable to extract a valid address",
1440                                         " from: $entry\n";
1441                 }
1442         }
1443         return @emails;
1444 }
1445
1446 sub validate_patch {
1447         my $fn = shift;
1448         open(my $fh, '<', $fn)
1449                 or die "unable to open $fn: $!\n";
1450         while (my $line = <$fh>) {
1451                 if (length($line) > 998) {
1452                         return "$.: patch contains a line longer than 998 characters";
1453                 }
1454         }
1455         return undef;
1456 }
1457
1458 sub file_has_nonascii {
1459         my $fn = shift;
1460         open(my $fh, '<', $fn)
1461                 or die "unable to open $fn: $!\n";
1462         while (my $line = <$fh>) {
1463                 return 1 if $line =~ /[^[:ascii:]]/;
1464         }
1465         return 0;
1466 }
1467
1468 sub body_or_subject_has_nonascii {
1469         my $fn = shift;
1470         open(my $fh, '<', $fn)
1471                 or die "unable to open $fn: $!\n";
1472         while (my $line = <$fh>) {
1473                 last if $line =~ /^$/;
1474                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1475         }
1476         while (my $line = <$fh>) {
1477                 return 1 if $line =~ /[^[:ascii:]]/;
1478         }
1479         return 0;
1480 }