git.oblomov.eu Git - git/blob - contrib/mw-to-git/git-remote-mediawiki.perl

   1 #! /usr/bin/perl
   2
   3 # Copyright (C) 2011
   4 #     Jérémie Nikaes <jeremie.nikaes@ensimag.imag.fr>
   5 #     Arnaud Lacurie <arnaud.lacurie@ensimag.imag.fr>
   6 #     Claire Fousse <claire.fousse@ensimag.imag.fr>
   7 #     David Amouyal <david.amouyal@ensimag.imag.fr>
   8 #     Matthieu Moy <matthieu.moy@grenoble-inp.fr>
   9 # License: GPL v2 or later
  10
  11 # Gateway between Git and MediaWiki.
  12 # Documentation & bugtracker: https://github.com/Git-Mediawiki/Git-Mediawiki
  13
  14 use strict;
  15 use MediaWiki::API;
  16 use Git;
  17 use Git::Mediawiki qw(clean_filename smudge_filename connect_maybe
  18                                         EMPTY HTTP_CODE_OK);
  19 use DateTime::Format::ISO8601;
  20 use warnings;
  21
  22 # By default, use UTF-8 to communicate with Git and the user
  23 binmode STDERR, ':encoding(UTF-8)';
  24 binmode STDOUT, ':encoding(UTF-8)';
  25
  26 use URI::Escape;
  27
  28 # It's not always possible to delete pages (may require some
  29 # privileges). Deleted pages are replaced with this content.
  30 use constant DELETED_CONTENT => "[[Category:Deleted]]\n";
  31
  32 # It's not possible to create empty pages. New empty files in Git are
  33 # sent with this content instead.
  34 use constant EMPTY_CONTENT => "<!-- empty page -->\n";
  35
  36 # used to reflect file creation or deletion in diff.
  37 use constant NULL_SHA1 => '0000000000000000000000000000000000000000';
  38
  39 # Used on Git's side to reflect empty edit messages on the wiki
  40 use constant EMPTY_MESSAGE => '*Empty MediaWiki Message*';
  41
  42 # Number of pages taken into account at once in submodule get_mw_page_list
  43 use constant SLICE_SIZE => 50;
  44
  45 # Number of linked mediafile to get at once in get_linked_mediafiles
  46 # The query is split in small batches because of the MW API limit of
  47 # the number of links to be returned (500 links max).
  48 use constant BATCH_SIZE => 10;
  49
  50 if (@ARGV != 2) {
  51         exit_error_usage();
  52 }
  53
  54 my $remotename = $ARGV[0];
  55 my $url = $ARGV[1];
  56
  57 # Accept both space-separated and multiple keys in config file.
  58 # Spaces should be written as _ anyway because we'll use chomp.
  59 my @tracked_pages = split(/[ \n]/, run_git_quoted(["config", "--get-all", "remote.${remotename}.pages"]));
  60 chomp(@tracked_pages);
  61
  62 # Just like @tracked_pages, but for MediaWiki categories.
  63 my @tracked_categories = split(/[ \n]/, run_git_quoted(["config", "--get-all", "remote.${remotename}.categories"]));
  64 chomp(@tracked_categories);
  65
  66 # Just like @tracked_categories, but for MediaWiki namespaces.
  67 my @tracked_namespaces = split(/[ \n]/, run_git_quoted(["config", "--get-all", "remote.${remotename}.namespaces"]));
  68 for (@tracked_namespaces) { s/_/ /g; }
  69 chomp(@tracked_namespaces);
  70
  71 # Import media files on pull
  72 my $import_media = run_git_quoted(["config", "--get", "--bool", "remote.${remotename}.mediaimport"]);
  73 chomp($import_media);
  74 $import_media = ($import_media eq 'true');
  75
  76 # Export media files on push
  77 my $export_media = run_git_quoted(["config", "--get", "--bool", "remote.${remotename}.mediaexport"]);
  78 chomp($export_media);
  79 $export_media = !($export_media eq 'false');
  80
  81 my $wiki_login = run_git_quoted(["config", "--get", "remote.${remotename}.mwLogin"]);
  82 # Note: mwPassword is discouraged. Use the credential system instead.
  83 my $wiki_passwd = run_git_quoted(["config", "--get", "remote.${remotename}.mwPassword"]);
  84 my $wiki_domain = run_git_quoted(["config", "--get", "remote.${remotename}.mwDomain"]);
  85 chomp($wiki_login);
  86 chomp($wiki_passwd);
  87 chomp($wiki_domain);
  88
  89 # Import only last revisions (both for clone and fetch)
  90 my $shallow_import = run_git_quoted(["config", "--get", "--bool", "remote.${remotename}.shallow"]);
  91 chomp($shallow_import);
  92 $shallow_import = ($shallow_import eq 'true');
  93
  94 # Fetch (clone and pull) by revisions instead of by pages. This behavior
  95 # is more efficient when we have a wiki with lots of pages and we fetch
  96 # the revisions quite often so that they concern only few pages.
  97 # Possible values:
  98 # - by_rev: perform one query per new revision on the remote wiki
  99 # - by_page: query each tracked page for new revision
 100 my $fetch_strategy = run_git_quoted(["config", "--get", "remote.${remotename}.fetchStrategy"]);
 101 if (!$fetch_strategy) {
 102         $fetch_strategy = run_git_quoted(["config", "--get", "mediawiki.fetchStrategy"]);
 103 }
 104 chomp($fetch_strategy);
 105 if (!$fetch_strategy) {
 106         $fetch_strategy = 'by_page';
 107 }
 108
 109 # Remember the timestamp corresponding to a revision id.
 110 my %basetimestamps;
 111
 112 # Dumb push: don't update notes and mediawiki ref to reflect the last push.
 113 #
 114 # Configurable with mediawiki.dumbPush, or per-remote with
 115 # remote.<remotename>.dumbPush.
 116 #
 117 # This means the user will have to re-import the just-pushed
 118 # revisions. On the other hand, this means that the Git revisions
 119 # corresponding to MediaWiki revisions are all imported from the wiki,
 120 # regardless of whether they were initially created in Git or from the
 121 # web interface, hence all users will get the same history (i.e. if
 122 # the push from Git to MediaWiki loses some information, everybody
 123 # will get the history with information lost). If the import is
 124 # deterministic, this means everybody gets the same sha1 for each
 125 # MediaWiki revision.
 126 my $dumb_push = run_git_quoted(["config", "--get", "--bool", "remote.${remotename}.dumbPush"]);
 127 if (!$dumb_push) {
 128         $dumb_push = run_git_quoted(["config", "--get", "--bool", "mediawiki.dumbPush"]);
 129 }
 130 chomp($dumb_push);
 131 $dumb_push = ($dumb_push eq 'true');
 132
 133 my $wiki_name = $url;
 134 $wiki_name =~ s{[^/]*://}{};
 135 # If URL is like http://user:password@example.com/, we clearly don't
 136 # want the password in $wiki_name. While we're there, also remove user
 137 # and '@' sign, to avoid author like MWUser@HTTPUser@host.com
 138 $wiki_name =~ s/^.*@//;
 139
 140 # Commands parser
 141 while (<STDIN>) {
 142         chomp;
 143
 144         if (!parse_command($_)) {
 145                 last;
 146         }
 147
 148         BEGIN { $| = 1 } # flush STDOUT, to make sure the previous
 149                          # command is fully processed.
 150 }
 151
 152 ########################## Functions ##############################
 153
 154 ## error handling
 155 sub exit_error_usage {
 156         die "ERROR: git-remote-mediawiki module was not called with a correct number of\n" .
 157             "parameters\n" .
 158             "You may obtain this error because you attempted to run the git-remote-mediawiki\n" .
 159             "module directly.\n" .
 160             "This module can be used the following way:\n" .
 161             "\tgit clone mediawiki://<address of a mediawiki>\n" .
 162             "Then, use git commit, push and pull as with every normal git repository.\n";
 163 }
 164
 165 sub parse_command {
 166         my ($line) = @_;
 167         my @cmd = split(/ /, $line);
 168         if (!defined $cmd[0]) {
 169                 return 0;
 170         }
 171         if ($cmd[0] eq 'capabilities') {
 172                 die("Too many arguments for capabilities\n")
 173                     if (defined($cmd[1]));
 174                 mw_capabilities();
 175         } elsif ($cmd[0] eq 'list') {
 176                 die("Too many arguments for list\n") if (defined($cmd[2]));
 177                 mw_list($cmd[1]);
 178         } elsif ($cmd[0] eq 'import') {
 179                 die("Invalid argument for import\n")
 180                     if ($cmd[1] eq EMPTY);
 181                 die("Too many arguments for import\n")
 182                     if (defined($cmd[2]));
 183                 mw_import($cmd[1]);
 184         } elsif ($cmd[0] eq 'option') {
 185                 die("Invalid arguments for option\n")
 186                     if ($cmd[1] eq EMPTY || $cmd[2] eq EMPTY);
 187                 die("Too many arguments for option\n")
 188                     if (defined($cmd[3]));
 189                 mw_option($cmd[1],$cmd[2]);
 190         } elsif ($cmd[0] eq 'push') {
 191                 mw_push($cmd[1]);
 192         } else {
 193                 print {*STDERR} "Unknown command. Aborting...\n";
 194                 return 0;
 195         }
 196         return 1;
 197 }
 198
 199 # MediaWiki API instance, created lazily.
 200 my $mediawiki;
 201
 202 sub fatal_mw_error {
 203         my $action = shift;
 204         print STDERR "fatal: could not $action.\n";
 205         print STDERR "fatal: '$url' does not appear to be a mediawiki\n";
 206         if ($url =~ /^https/) {
 207                 print STDERR "fatal: make sure '$url/api.php' is a valid page\n";
 208                 print STDERR "fatal: and the SSL certificate is correct.\n";
 209         } else {
 210                 print STDERR "fatal: make sure '$url/api.php' is a valid page.\n";
 211         }
 212         print STDERR "fatal: (error " .
 213             $mediawiki->{error}->{code} . ': ' .
 214             $mediawiki->{error}->{details} . ")\n";
 215         exit 1;
 216 }
 217
 218 ## Functions for listing pages on the remote wiki
 219 sub get_mw_tracked_pages {
 220         my $pages = shift;
 221         get_mw_page_list(\@tracked_pages, $pages);
 222         return;
 223 }
 224
 225 sub get_mw_page_list {
 226         my $page_list = shift;
 227         my $pages = shift;
 228         my @some_pages = @{$page_list};
 229         while (@some_pages) {
 230                 my $last_page = SLICE_SIZE;
 231                 if ($#some_pages < $last_page) {
 232                         $last_page = $#some_pages;
 233                 }
 234                 my @slice = @some_pages[0..$last_page];
 235                 get_mw_first_pages(\@slice, $pages);
 236                 @some_pages = @some_pages[(SLICE_SIZE + 1)..$#some_pages];
 237         }
 238         return;
 239 }
 240
 241 sub get_mw_tracked_categories {
 242         my $pages = shift;
 243         foreach my $category (@tracked_categories) {
 244                 if (index($category, ':') < 0) {
 245                         # Mediawiki requires the Category
 246                         # prefix, but let's not force the user
 247                         # to specify it.
 248                         $category = "Category:${category}";
 249                 }
 250                 my $mw_pages = $mediawiki->list( {
 251                         action => 'query',
 252                         list => 'categorymembers',
 253                         cmtitle => $category,
 254                         cmlimit => 'max' } )
 255                         || die $mediawiki->{error}->{code} . ': '
 256                                 . $mediawiki->{error}->{details} . "\n";
 257                 foreach my $page (@{$mw_pages}) {
 258                         $pages->{$page->{title}} = $page;
 259                 }
 260         }
 261         return;
 262 }
 263
 264 sub get_mw_tracked_namespaces {
 265     my $pages = shift;
 266     foreach my $local_namespace (sort @tracked_namespaces) {
 267         my $namespace_id;
 268         if ($local_namespace eq "(Main)") {
 269             $namespace_id = 0;
 270         } else {
 271             $namespace_id = get_mw_namespace_id($local_namespace);
 272         }
 273         # virtual namespaces don't support allpages
 274         next if !defined($namespace_id) || $namespace_id < 0;
 275         my $mw_pages = $mediawiki->list( {
 276             action => 'query',
 277             list => 'allpages',
 278             apnamespace => $namespace_id,
 279             aplimit => 'max' } )
 280             || die $mediawiki->{error}->{code} . ': '
 281                 . $mediawiki->{error}->{details} . "\n";
 282         print {*STDERR} "$#{$mw_pages} found in namespace $local_namespace ($namespace_id)\n";
 283         foreach my $page (@{$mw_pages}) {
 284             $pages->{$page->{title}} = $page;
 285         }
 286     }
 287     return;
 288 }
 289
 290 sub get_mw_all_pages {
 291         my $pages = shift;
 292         # No user-provided list, get the list of pages from the API.
 293         my $mw_pages = $mediawiki->list({
 294                 action => 'query',
 295                 list => 'allpages',
 296                 aplimit => 'max'
 297         });
 298         if (!defined($mw_pages)) {
 299                 fatal_mw_error("get the list of wiki pages");
 300         }
 301         foreach my $page (@{$mw_pages}) {
 302                 $pages->{$page->{title}} = $page;
 303         }
 304         return;
 305 }
 306
 307 # queries the wiki for a set of pages. Meant to be used within a loop
 308 # querying the wiki for slices of page list.
 309 sub get_mw_first_pages {
 310         my $some_pages = shift;
 311         my @some_pages = @{$some_pages};
 312
 313         my $pages = shift;
 314
 315         # pattern 'page1|page2|...' required by the API
 316         my $titles = join('|', @some_pages);
 317
 318         my $mw_pages = $mediawiki->api({
 319                 action => 'query',
 320                 titles => $titles,
 321         });
 322         if (!defined($mw_pages)) {
 323                 fatal_mw_error("query the list of wiki pages");
 324         }
 325         while (my ($id, $page) = each(%{$mw_pages->{query}->{pages}})) {
 326                 if ($id < 0) {
 327                         print {*STDERR} "Warning: page $page->{title} not found on wiki\n";
 328                 } else {
 329                         $pages->{$page->{title}} = $page;
 330                 }
 331         }
 332         return;
 333 }
 334
 335 # Get the list of pages to be fetched according to configuration.
 336 sub get_mw_pages {
 337         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 338
 339         print {*STDERR} "Listing pages on remote wiki...\n";
 340
 341         my %pages; # hash on page titles to avoid duplicates
 342         my $user_defined;
 343         if (@tracked_pages) {
 344                 $user_defined = 1;
 345                 # The user provided a list of pages titles, but we
 346                 # still need to query the API to get the page IDs.
 347                 get_mw_tracked_pages(\%pages);
 348         }
 349         if (@tracked_categories) {
 350                 $user_defined = 1;
 351                 get_mw_tracked_categories(\%pages);
 352         }
 353         if (@tracked_namespaces) {
 354                 $user_defined = 1;
 355                 get_mw_tracked_namespaces(\%pages);
 356         }
 357         if (!$user_defined) {
 358                 get_mw_all_pages(\%pages);
 359         }
 360         if ($import_media) {
 361                 print {*STDERR} "Getting media files for selected pages...\n";
 362                 if ($user_defined) {
 363                         get_linked_mediafiles(\%pages);
 364                 } else {
 365                         get_all_mediafiles(\%pages);
 366                 }
 367         }
 368         print {*STDERR} (scalar keys %pages) . " pages found.\n";
 369         return %pages;
 370 }
 371
 372 # usage: $out = run_git_quoted(["command", "args", ...]);
 373 #        $out = run_git_quoted(["command", "args", ...], "raw"); # don't interpret output as UTF-8.
 374 #        $out = run_git_unquoted(["command args"); # don't quote arguments
 375 #        $out = run_git_unquoted(["command args", "raw"); # ditto but raw instead of UTF-8 as above
 376 sub _run_git {
 377         my $args = shift;
 378         my $encoding = (shift || 'encoding(UTF-8)');
 379         open(my $git, "-|:${encoding}", @$args)
 380             or die "Unable to fork: $!\n";
 381         my $res = do {
 382                 local $/ = undef;
 383                 <$git>
 384         };
 385         close($git);
 386
 387         return $res;
 388 }
 389
 390 sub run_git_quoted {
 391     _run_git(["git", @{$_[0]}], $_[1]);
 392 }
 393
 394 sub run_git_unquoted {
 395     _run_git(["git $_[0]"], $_[1]);
 396 }
 397
 398 sub get_all_mediafiles {
 399         my $pages = shift;
 400         # Attach list of all pages for media files from the API,
 401         # they are in a different namespace, only one namespace
 402         # can be queried at the same moment
 403         my $mw_pages = $mediawiki->list({
 404                 action => 'query',
 405                 list => 'allpages',
 406                 apnamespace => get_mw_namespace_id('File'),
 407                 aplimit => 'max'
 408         });
 409         if (!defined($mw_pages)) {
 410                 print {*STDERR} "fatal: could not get the list of pages for media files.\n";
 411                 print {*STDERR} "fatal: '$url' does not appear to be a mediawiki\n";
 412                 print {*STDERR} "fatal: make sure '$url/api.php' is a valid page.\n";
 413                 exit 1;
 414         }
 415         foreach my $page (@{$mw_pages}) {
 416                 $pages->{$page->{title}} = $page;
 417         }
 418         return;
 419 }
 420
 421 sub get_linked_mediafiles {
 422         my $pages = shift;
 423         my @titles = map { $_->{title} } values(%{$pages});
 424
 425         my $batch = BATCH_SIZE;
 426         while (@titles) {
 427                 if ($#titles < $batch) {
 428                         $batch = $#titles;
 429                 }
 430                 my @slice = @titles[0..$batch];
 431
 432                 # pattern 'page1|page2|...' required by the API
 433                 my $mw_titles = join('|', @slice);
 434
 435                 # Media files could be included or linked from
 436                 # a page, get all related
 437                 my $query = {
 438                         action => 'query',
 439                         prop => 'links|images',
 440                         titles => $mw_titles,
 441                         plnamespace => get_mw_namespace_id('File'),
 442                         pllimit => 'max'
 443                 };
 444                 my $result = $mediawiki->api($query);
 445
 446                 while (my ($id, $page) = each(%{$result->{query}->{pages}})) {
 447                         my @media_titles;
 448                         if (defined($page->{links})) {
 449                                 my @link_titles
 450                                     = map { $_->{title} } @{$page->{links}};
 451                                 push(@media_titles, @link_titles);
 452                         }
 453                         if (defined($page->{images})) {
 454                                 my @image_titles
 455                                     = map { $_->{title} } @{$page->{images}};
 456                                 push(@media_titles, @image_titles);
 457                         }
 458                         if (@media_titles) {
 459                                 get_mw_page_list(\@media_titles, $pages);
 460                         }
 461                 }
 462
 463                 @titles = @titles[($batch+1)..$#titles];
 464         }
 465         return;
 466 }
 467
 468 sub get_mw_mediafile_for_page_revision {
 469         # Name of the file on Wiki, with the prefix.
 470         my $filename = shift;
 471         my $timestamp = shift;
 472         my %mediafile;
 473
 474         # Search if on a media file with given timestamp exists on
 475         # MediaWiki. In that case download the file.
 476         my $query = {
 477                 action => 'query',
 478                 prop => 'imageinfo',
 479                 titles => "File:${filename}",
 480                 iistart => $timestamp,
 481                 iiend => $timestamp,
 482                 iiprop => 'timestamp|archivename|url',
 483                 iilimit => 1
 484         };
 485         my $result = $mediawiki->api($query);
 486
 487         my ($fileid, $file) = each( %{$result->{query}->{pages}} );
 488         # If not defined it means there is no revision of the file for
 489         # given timestamp.
 490         if (defined($file->{imageinfo})) {
 491                 $mediafile{title} = $filename;
 492
 493                 my $fileinfo = pop(@{$file->{imageinfo}});
 494                 $mediafile{timestamp} = $fileinfo->{timestamp};
 495                 # Mediawiki::API's download function doesn't support https URLs
 496                 # and can't download old versions of files.
 497                 print {*STDERR} "\tDownloading file $mediafile{title}, version $mediafile{timestamp}\n";
 498                 $mediafile{content} = download_mw_mediafile($fileinfo->{url});
 499         }
 500         return %mediafile;
 501 }
 502
 503 sub download_mw_mediafile {
 504         my $download_url = shift;
 505
 506         my $response = $mediawiki->{ua}->get($download_url);
 507         if ($response->code == HTTP_CODE_OK) {
 508                 # It is tempting to return
 509                 # $response->decoded_content({charset => "none"}), but
 510                 # when doing so, utf8::downgrade($content) fails with
 511                 # "Wide character in subroutine entry".
 512                 $response->decode();
 513                 return $response->content();
 514         } else {
 515                 print {*STDERR} "Error downloading mediafile from :\n";
 516                 print {*STDERR} "URL: ${download_url}\n";
 517                 print {*STDERR} 'Server response: ' . $response->code . q{ } . $response->message . "\n";
 518                 exit 1;
 519         }
 520 }
 521
 522 sub get_last_local_revision {
 523         # Get note regarding last mediawiki revision.
 524         #
 525         # It's OK to use run_git_unquoted() here because $remotename is
 526         # supplied by the local git itself.
 527         my $note = run_git_unquoted("notes --ref=${remotename}/mediawiki show refs/mediawiki/${remotename}/master 2>/dev/null");
 528         my @note_info = split(/ /, $note);
 529
 530         my $lastrevision_number;
 531         if (!(defined($note_info[0]) && $note_info[0] eq 'mediawiki_revision:')) {
 532                 print {*STDERR} 'No previous mediawiki revision found';
 533                 $lastrevision_number = 0;
 534         } else {
 535                 # Notes are formatted : mediawiki_revision: #number
 536                 $lastrevision_number = $note_info[1];
 537                 chomp($lastrevision_number);
 538                 print {*STDERR} "Last local mediawiki revision found is ${lastrevision_number}";
 539         }
 540         return $lastrevision_number;
 541 }
 542
 543 # Get the last remote revision without taking in account which pages are
 544 # tracked or not. This function makes a single request to the wiki thus
 545 # avoid a loop onto all tracked pages. This is useful for the fetch-by-rev
 546 # option.
 547 sub get_last_global_remote_rev {
 548         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 549
 550         my $query = {
 551                 action => 'query',
 552                 list => 'recentchanges',
 553                 prop => 'revisions',
 554                 rclimit => '1',
 555                 rcdir => 'older',
 556         };
 557         my $result = $mediawiki->api($query);
 558         return $result->{query}->{recentchanges}[0]->{revid};
 559 }
 560
 561 # Get the last remote revision concerning the tracked pages and the tracked
 562 # categories.
 563 sub get_last_remote_revision {
 564         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 565
 566         my %pages_hash = get_mw_pages();
 567         my @pages = values(%pages_hash);
 568
 569         my $max_rev_num = 0;
 570
 571         print {*STDERR} "Getting last revision id on tracked pages...\n";
 572
 573         foreach my $page (@pages) {
 574                 my $id = $page->{pageid};
 575
 576                 my $query = {
 577                         action => 'query',
 578                         prop => 'revisions',
 579                         rvprop => 'ids|timestamp',
 580                         pageids => $id,
 581                 };
 582
 583                 my $result = $mediawiki->api($query);
 584
 585                 my $lastrev = pop(@{$result->{query}->{pages}->{$id}->{revisions}});
 586
 587                 $basetimestamps{$lastrev->{revid}} = $lastrev->{timestamp};
 588
 589                 $max_rev_num = ($lastrev->{revid} > $max_rev_num ? $lastrev->{revid} : $max_rev_num);
 590         }
 591
 592         print {*STDERR} "Last remote revision found is $max_rev_num.\n";
 593         return $max_rev_num;
 594 }
 595
 596 # Clean content before sending it to MediaWiki
 597 sub mediawiki_clean {
 598         my $string = shift;
 599         my $page_created = shift;
 600         # Mediawiki does not allow blank space at the end of a page and ends with a single \n.
 601         # This function right trims a string and adds a \n at the end to follow this rule
 602         $string =~ s/\s+$//;
 603         if ($string eq EMPTY && $page_created) {
 604                 # Creating empty pages is forbidden.
 605                 $string = EMPTY_CONTENT;
 606         }
 607         return $string."\n";
 608 }
 609
 610 # Filter applied on MediaWiki data before adding them to Git
 611 sub mediawiki_smudge {
 612         my $string = shift;
 613         if ($string eq EMPTY_CONTENT) {
 614                 $string = EMPTY;
 615         }
 616         # This \n is important. This is due to mediawiki's way to handle end of files.
 617         return "${string}\n";
 618 }
 619
 620 sub literal_data {
 621         my ($content) = @_;
 622         print {*STDOUT} 'data ', bytes::length($content), "\n", $content;
 623         return;
 624 }
 625
 626 sub literal_data_raw {
 627         # Output possibly binary content.
 628         my ($content) = @_;
 629         # Avoid confusion between size in bytes and in characters
 630         utf8::downgrade($content);
 631         binmode STDOUT, ':raw';
 632         print {*STDOUT} 'data ', bytes::length($content), "\n", $content;
 633         binmode STDOUT, ':encoding(UTF-8)';
 634         return;
 635 }
 636
 637 sub mw_capabilities {
 638         # Revisions are imported to the private namespace
 639         # refs/mediawiki/$remotename/ by the helper and fetched into
 640         # refs/remotes/$remotename later by fetch.
 641         print {*STDOUT} "refspec refs/heads/*:refs/mediawiki/${remotename}/*\n";
 642         print {*STDOUT} "import\n";
 643         print {*STDOUT} "list\n";
 644         print {*STDOUT} "push\n";
 645         if ($dumb_push) {
 646                 print {*STDOUT} "no-private-update\n";
 647         }
 648         print {*STDOUT} "\n";
 649         return;
 650 }
 651
 652 sub mw_list {
 653         # MediaWiki do not have branches, we consider one branch arbitrarily
 654         # called master, and HEAD pointing to it.
 655         print {*STDOUT} "? refs/heads/master\n";
 656         print {*STDOUT} "\@refs/heads/master HEAD\n";
 657         print {*STDOUT} "\n";
 658         return;
 659 }
 660
 661 sub mw_option {
 662         print {*STDERR} "remote-helper command 'option $_[0]' not yet implemented\n";
 663         print {*STDOUT} "unsupported\n";
 664         return;
 665 }
 666
 667 sub fetch_mw_revisions_for_page {
 668         my $page = shift;
 669         my $id = shift;
 670         my $fetch_from = shift;
 671         my @page_revs = ();
 672         my $query = {
 673                 action => 'query',
 674                 prop => 'revisions',
 675                 rvprop => 'ids',
 676                 rvdir => 'newer',
 677                 rvstartid => $fetch_from,
 678                 rvlimit => 500,
 679                 pageids => $id,
 680
 681                 # Let MediaWiki know that we support the latest API.
 682                 continue => '',
 683         };
 684
 685         my $revnum = 0;
 686         # Get 500 revisions at a time due to the mediawiki api limit
 687         while (1) {
 688                 my $result = $mediawiki->api($query);
 689
 690                 # Parse each of those 500 revisions
 691                 foreach my $revision (@{$result->{query}->{pages}->{$id}->{revisions}}) {
 692                         my $page_rev_ids;
 693                         $page_rev_ids->{pageid} = $page->{pageid};
 694                         $page_rev_ids->{revid} = $revision->{revid};
 695                         push(@page_revs, $page_rev_ids);
 696                         $revnum++;
 697                 }
 698
 699                 if ($result->{'query-continue'}) { # For legacy APIs
 700                         $query->{rvstartid} = $result->{'query-continue'}->{revisions}->{rvstartid};
 701                 } elsif ($result->{continue}) { # For newer APIs
 702                         $query->{rvstartid} = $result->{continue}->{rvcontinue};
 703                         $query->{continue} = $result->{continue}->{continue};
 704                 } else {
 705                         last;
 706                 }
 707         }
 708         if ($shallow_import && @page_revs) {
 709                 print {*STDERR} "  Found 1 revision (shallow import).\n";
 710                 @page_revs = sort {$b->{revid} <=> $a->{revid}} (@page_revs);
 711                 return $page_revs[0];
 712         }
 713         print {*STDERR} "  Found ${revnum} revision(s).\n";
 714         return @page_revs;
 715 }
 716
 717 sub fetch_mw_revisions {
 718         my $pages = shift; my @pages = @{$pages};
 719         my $fetch_from = shift;
 720
 721         my @revisions = ();
 722         my $n = 1;
 723         foreach my $page (@pages) {
 724                 my $id = $page->{pageid};
 725                 print {*STDERR} "page ${n}/", scalar(@pages), ': ', $page->{title}, "\n";
 726                 $n++;
 727                 my @page_revs = fetch_mw_revisions_for_page($page, $id, $fetch_from);
 728                 @revisions = (@page_revs, @revisions);
 729         }
 730
 731         return ($n, @revisions);
 732 }
 733
 734 sub fe_escape_path {
 735     my $path = shift;
 736     $path =~ s/\\/\\\\/g;
 737     $path =~ s/"/\\"/g;
 738     $path =~ s/\n/\\n/g;
 739     return qq("${path}");
 740 }
 741
 742 sub import_file_revision {
 743         my $commit = shift;
 744         my %commit = %{$commit};
 745         my $full_import = shift;
 746         my $n = shift;
 747         my $mediafile = shift;
 748         my %mediafile;
 749         if ($mediafile) {
 750                 %mediafile = %{$mediafile};
 751         }
 752
 753         my $title = $commit{title};
 754         my $comment = $commit{comment};
 755         my $content = $commit{content};
 756         my $author = $commit{author};
 757         my $date = $commit{date};
 758
 759         print {*STDOUT} "commit refs/mediawiki/${remotename}/master\n";
 760         print {*STDOUT} "mark :${n}\n";
 761         print {*STDOUT} "committer ${author} <${author}\@${wiki_name}> " . $date->epoch . " +0000\n";
 762         literal_data($comment);
 763
 764         # If it's not a clone, we need to know where to start from
 765         if (!$full_import && $n == 1) {
 766                 print {*STDOUT} "from refs/mediawiki/${remotename}/master^0\n";
 767         }
 768         if ($content ne DELETED_CONTENT) {
 769                 print {*STDOUT} 'M 644 inline ' .
 770                     fe_escape_path("${title}.mw") . "\n";
 771                 literal_data($content);
 772                 if (%mediafile) {
 773                         print {*STDOUT} 'M 644 inline '
 774                             . fe_escape_path($mediafile{title}) . "\n";
 775                         literal_data_raw($mediafile{content});
 776                 }
 777                 print {*STDOUT} "\n\n";
 778         } else {
 779                 print {*STDOUT} 'D ' . fe_escape_path("${title}.mw") . "\n";
 780         }
 781
 782         # mediawiki revision number in the git note
 783         if ($full_import && $n == 1) {
 784                 print {*STDOUT} "reset refs/notes/${remotename}/mediawiki\n";
 785         }
 786         print {*STDOUT} "commit refs/notes/${remotename}/mediawiki\n";
 787         print {*STDOUT} "committer ${author} <${author}\@${wiki_name}> " . $date->epoch . " +0000\n";
 788         literal_data('Note added by git-mediawiki during import');
 789         if (!$full_import && $n == 1) {
 790                 print {*STDOUT} "from refs/notes/${remotename}/mediawiki^0\n";
 791         }
 792         print {*STDOUT} "N inline :${n}\n";
 793         literal_data("mediawiki_revision: $commit{mw_revision}");
 794         print {*STDOUT} "\n\n";
 795         return;
 796 }
 797
 798 # parse a sequence of
 799 # <cmd> <arg1>
 800 # <cmd> <arg2>
 801 # \n
 802 # (like batch sequence of import and sequence of push statements)
 803 sub get_more_refs {
 804         my $cmd = shift;
 805         my @refs;
 806         while (1) {
 807                 my $line = <STDIN>;
 808                 if ($line =~ /^$cmd (.*)$/) {
 809                         push(@refs, $1);
 810                 } elsif ($line eq "\n") {
 811                         return @refs;
 812                 } else {
 813                         die("Invalid command in a '$cmd' batch: $_\n");
 814                 }
 815         }
 816         return;
 817 }
 818
 819 sub mw_import {
 820         # multiple import commands can follow each other.
 821         my @refs = (shift, get_more_refs('import'));
 822         my $processedRefs;
 823         foreach my $ref (@refs) {
 824                 next if $processedRefs->{$ref}; # skip duplicates: "import refs/heads/master" being issued twice; TODO: why?
 825                 $processedRefs->{$ref} = 1;
 826                 mw_import_ref($ref);
 827         }
 828         print {*STDOUT} "done\n";
 829         return;
 830 }
 831
 832 sub mw_import_ref {
 833         my $ref = shift;
 834         # The remote helper will call "import HEAD" and
 835         # "import refs/heads/master".
 836         # Since HEAD is a symbolic ref to master (by convention,
 837         # followed by the output of the command "list" that we gave),
 838         # we don't need to do anything in this case.
 839         if ($ref eq 'HEAD') {
 840                 return;
 841         }
 842
 843         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
 844
 845         print {*STDERR} "Searching revisions...\n";
 846         my $last_local = get_last_local_revision();
 847         my $fetch_from = $last_local + 1;
 848         if ($fetch_from == 1) {
 849                 print {*STDERR} ", fetching from beginning.\n";
 850         } else {
 851                 print {*STDERR} ", fetching from here.\n";
 852         }
 853
 854         my $n = 0;
 855         if ($fetch_strategy eq 'by_rev') {
 856                 print {*STDERR} "Fetching & writing export data by revs...\n";
 857                 $n = mw_import_ref_by_revs($fetch_from);
 858         } elsif ($fetch_strategy eq 'by_page') {
 859                 print {*STDERR} "Fetching & writing export data by pages...\n";
 860                 $n = mw_import_ref_by_pages($fetch_from);
 861         } else {
 862                 print {*STDERR} qq(fatal: invalid fetch strategy "${fetch_strategy}".\n);
 863                 print {*STDERR} "Check your configuration variables remote.${remotename}.fetchStrategy and mediawiki.fetchStrategy\n";
 864                 exit 1;
 865         }
 866
 867         if ($fetch_from == 1 && $n == 0) {
 868                 print {*STDERR} "You appear to have cloned an empty MediaWiki.\n";
 869                 # Something has to be done remote-helper side. If nothing is done, an error is
 870                 # thrown saying that HEAD is referring to unknown object 0000000000000000000
 871                 # and the clone fails.
 872         }
 873         return;
 874 }
 875
 876 sub mw_import_ref_by_pages {
 877
 878         my $fetch_from = shift;
 879         my %pages_hash = get_mw_pages();
 880         my @pages = values(%pages_hash);
 881
 882         my ($n, @revisions) = fetch_mw_revisions(\@pages, $fetch_from);
 883
 884         @revisions = sort {$a->{revid} <=> $b->{revid}} @revisions;
 885         my @revision_ids = map { $_->{revid} } @revisions;
 886
 887         return mw_import_revids($fetch_from, \@revision_ids, \%pages_hash);
 888 }
 889
 890 sub mw_import_ref_by_revs {
 891
 892         my $fetch_from = shift;
 893         my %pages_hash = get_mw_pages();
 894
 895         my $last_remote = get_last_global_remote_rev();
 896         my @revision_ids = $fetch_from..$last_remote;
 897         return mw_import_revids($fetch_from, \@revision_ids, \%pages_hash);
 898 }
 899
 900 # Import revisions given in second argument (array of integers).
 901 # Only pages appearing in the third argument (hash indexed by page titles)
 902 # will be imported.
 903 sub mw_import_revids {
 904         my $fetch_from = shift;
 905         my $revision_ids = shift;
 906         my $pages = shift;
 907
 908         my $n = 0;
 909         my $n_actual = 0;
 910         my $last_timestamp = 0; # Placeholder in case $rev->timestamp is undefined
 911
 912         foreach my $pagerevid (@{$revision_ids}) {
 913                 # Count page even if we skip it, since we display
 914                 # $n/$total and $total includes skipped pages.
 915                 $n++;
 916
 917                 # fetch the content of the pages
 918                 my $query = {
 919                         action => 'query',
 920                         prop => 'revisions',
 921                         rvprop => 'content|timestamp|comment|user|ids',
 922                         revids => $pagerevid,
 923                 };
 924
 925                 my $result = $mediawiki->api($query);
 926
 927                 if (!$result) {
 928                         die "Failed to retrieve modified page for revision $pagerevid\n";
 929                 }
 930
 931                 if (defined($result->{query}->{badrevids}->{$pagerevid})) {
 932                         # The revision id does not exist on the remote wiki.
 933                         next;
 934                 }
 935
 936                 if (!defined($result->{query}->{pages})) {
 937                         die "Invalid revision ${pagerevid}.\n";
 938                 }
 939
 940                 my @result_pages = values(%{$result->{query}->{pages}});
 941                 my $result_page = $result_pages[0];
 942                 my $rev = $result_pages[0]->{revisions}->[0];
 943
 944                 my $page_title = $result_page->{title};
 945
 946                 if (!exists($pages->{$page_title})) {
 947                         print {*STDERR} "${n}/", scalar(@{$revision_ids}),
 948                                 ": Skipping revision #$rev->{revid} of ${page_title}\n";
 949                         next;
 950                 }
 951
 952                 $n_actual++;
 953
 954                 my %commit;
 955                 $commit{author} = $rev->{user} || 'Anonymous';
 956                 $commit{comment} = $rev->{comment} || EMPTY_MESSAGE;
 957                 $commit{title} = smudge_filename($page_title);
 958                 $commit{mw_revision} = $rev->{revid};
 959                 $commit{content} = mediawiki_smudge($rev->{'*'});
 960
 961                 if (!defined($rev->{timestamp})) {
 962                         $last_timestamp++;
 963                 } else {
 964                         $last_timestamp = $rev->{timestamp};
 965                 }
 966                 $commit{date} = DateTime::Format::ISO8601->parse_datetime($last_timestamp);
 967
 968                 # Differentiates classic pages and media files.
 969                 my ($namespace, $filename) = $page_title =~ /^([^:]*):(.*)$/;
 970                 my %mediafile;
 971                 if ($namespace) {
 972                         my $id = get_mw_namespace_id($namespace);
 973                         if ($id && $id == get_mw_namespace_id('File')) {
 974                                 %mediafile = get_mw_mediafile_for_page_revision($filename, $rev->{timestamp});
 975                         }
 976                 }
 977                 # If this is a revision of the media page for new version
 978                 # of a file do one common commit for both file and media page.
 979                 # Else do commit only for that page.
 980                 print {*STDERR} "${n}/", scalar(@{$revision_ids}), ": Revision #$rev->{revid} of $commit{title}\n";
 981                 import_file_revision(\%commit, ($fetch_from == 1), $n_actual, \%mediafile);
 982         }
 983
 984         return $n_actual;
 985 }
 986
 987 sub error_non_fast_forward {
 988         my $advice = run_git_quoted(["config", "--bool", "advice.pushNonFastForward"]);
 989         chomp($advice);
 990         if ($advice ne 'false') {
 991                 # Native git-push would show this after the summary.
 992                 # We can't ask it to display it cleanly, so print it
 993                 # ourselves before.
 994                 print {*STDERR} "To prevent you from losing history, non-fast-forward updates were rejected\n";
 995                 print {*STDERR} "Merge the remote changes (e.g. 'git pull') before pushing again. See the\n";
 996                 print {*STDERR} "'Note about fast-forwards' section of 'git push --help' for details.\n";
 997         }
 998         print {*STDOUT} qq(error $_[0] "non-fast-forward"\n);
 999         return 0;
1000 }
1001
1002 sub mw_upload_file {
1003         my $complete_file_name = shift;
1004         my $new_sha1 = shift;
1005         my $extension = shift;
1006         my $file_deleted = shift;
1007         my $summary = shift;
1008         my $newrevid;
1009         my $path = "File:${complete_file_name}";
1010         my %hashFiles = get_allowed_file_extensions();
1011         if (!exists($hashFiles{$extension})) {
1012                 print {*STDERR} "${complete_file_name} is not a permitted file on this wiki.\n";
1013                 print {*STDERR} "Check the configuration of file uploads in your mediawiki.\n";
1014                 return $newrevid;
1015         }
1016         # Deleting and uploading a file requires a privileged user
1017         if ($file_deleted) {
1018                 $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1019                 my $query = {
1020                         action => 'delete',
1021                         title => $path,
1022                         reason => $summary
1023                 };
1024                 if (!$mediawiki->edit($query)) {
1025                         print {*STDERR} "Failed to delete file on remote wiki\n";
1026                         print {*STDERR} "Check your permissions on the remote site. Error code:\n";
1027                         print {*STDERR} $mediawiki->{error}->{code} . ':' . $mediawiki->{error}->{details};
1028                         exit 1;
1029                 }
1030         } else {
1031                 # Don't let perl try to interpret file content as UTF-8 => use "raw"
1032                 my $content = run_git_quoted(["cat-file", "blob", $new_sha1], 'raw');
1033                 if ($content ne EMPTY) {
1034                         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1035                         $mediawiki->{config}->{upload_url} =
1036                                 "${url}/index.php/Special:Upload";
1037                         $mediawiki->edit({
1038                                 action => 'upload',
1039                                 filename => $complete_file_name,
1040                                 comment => $summary,
1041                                 file => [undef,
1042                                          $complete_file_name,
1043                                          Content => $content],
1044                                 ignorewarnings => 1,
1045                         }, {
1046                                 skip_encoding => 1
1047                         } ) || die $mediawiki->{error}->{code} . ':'
1048                                  . $mediawiki->{error}->{details} . "\n";
1049                         my $last_file_page = $mediawiki->get_page({title => $path});
1050                         $newrevid = $last_file_page->{revid};
1051                         print {*STDERR} "Pushed file: ${new_sha1} - ${complete_file_name}.\n";
1052                 } else {
1053                         print {*STDERR} "Empty file ${complete_file_name} not pushed.\n";
1054                 }
1055         }
1056         return $newrevid;
1057 }
1058
1059 sub mw_push_file {
1060         my $diff_info = shift;
1061         # $diff_info contains a string in this format:
1062         # 100644 100644 <sha1_of_blob_before_commit> <sha1_of_blob_now> <status>
1063         my @diff_info_split = split(/[ \t]/, $diff_info);
1064
1065         # Filename, including .mw extension
1066         my $complete_file_name = shift;
1067         # Commit message
1068         my $summary = shift;
1069         # MediaWiki revision number. Keep the previous one by default,
1070         # in case there's no edit to perform.
1071         my $oldrevid = shift;
1072         my $newrevid;
1073
1074         if ($summary eq EMPTY_MESSAGE) {
1075                 $summary = EMPTY;
1076         }
1077
1078         my $new_sha1 = $diff_info_split[3];
1079         my $old_sha1 = $diff_info_split[2];
1080         my $page_created = ($old_sha1 eq NULL_SHA1);
1081         my $page_deleted = ($new_sha1 eq NULL_SHA1);
1082         $complete_file_name = clean_filename($complete_file_name);
1083
1084         my ($title, $extension) = $complete_file_name =~ /^(.*)\.([^\.]*)$/;
1085         if (!defined($extension)) {
1086                 $extension = EMPTY;
1087         }
1088         if ($extension eq 'mw') {
1089                 my $ns = get_mw_namespace_id_for_page($complete_file_name);
1090                 if ($ns && $ns == get_mw_namespace_id('File') && (!$export_media)) {
1091                         print {*STDERR} "Ignoring media file related page: ${complete_file_name}\n";
1092                         return ($oldrevid, 'ok');
1093                 }
1094                 my $file_content;
1095                 if ($page_deleted) {
1096                         # Deleting a page usually requires
1097                         # special privileges. A common
1098                         # convention is to replace the page
1099                         # with this content instead:
1100                         $file_content = DELETED_CONTENT;
1101                 } else {
1102                         $file_content = run_git_quoted(["cat-file", "blob", $new_sha1]);
1103                 }
1104
1105                 $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1106
1107                 my $result = $mediawiki->edit( {
1108                         action => 'edit',
1109                         summary => $summary,
1110                         title => $title,
1111                         basetimestamp => $basetimestamps{$oldrevid},
1112                         text => mediawiki_clean($file_content, $page_created),
1113                                   }, {
1114                                           skip_encoding => 1 # Helps with names with accentuated characters
1115                                   });
1116                 if (!$result) {
1117                         if ($mediawiki->{error}->{code} == 3) {
1118                                 # edit conflicts, considered as non-fast-forward
1119                                 print {*STDERR} 'Warning: Error ' .
1120                                     $mediawiki->{error}->{code} .
1121                                     ' from mediawiki: ' . $mediawiki->{error}->{details} .
1122                                     ".\n";
1123                                 return ($oldrevid, 'non-fast-forward');
1124                         } else {
1125                                 # Other errors. Shouldn't happen => just die()
1126                                 die 'Fatal: Error ' .
1127                                     $mediawiki->{error}->{code} .
1128                                     ' from mediawiki: ' . $mediawiki->{error}->{details} . "\n";
1129                         }
1130                 }
1131                 $newrevid = $result->{edit}->{newrevid};
1132                 print {*STDERR} "Pushed file: ${new_sha1} - ${title}\n";
1133         } elsif ($export_media) {
1134                 $newrevid = mw_upload_file($complete_file_name, $new_sha1,
1135                                            $extension, $page_deleted,
1136                                            $summary);
1137         } else {
1138                 print {*STDERR} "Ignoring media file ${title}\n";
1139         }
1140         $newrevid = ($newrevid or $oldrevid);
1141         return ($newrevid, 'ok');
1142 }
1143
1144 sub mw_push {
1145         # multiple push statements can follow each other
1146         my @refsspecs = (shift, get_more_refs('push'));
1147         my $pushed;
1148         for my $refspec (@refsspecs) {
1149                 my ($force, $local, $remote) = $refspec =~ /^(\+)?([^:]*):([^:]*)$/
1150                     or die("Invalid refspec for push. Expected <src>:<dst> or +<src>:<dst>\n");
1151                 if ($force) {
1152                         print {*STDERR} "Warning: forced push not allowed on a MediaWiki.\n";
1153                 }
1154                 if ($local eq EMPTY) {
1155                         print {*STDERR} "Cannot delete remote branch on a MediaWiki\n";
1156                         print {*STDOUT} "error ${remote} cannot delete\n";
1157                         next;
1158                 }
1159                 if ($remote ne 'refs/heads/master') {
1160                         print {*STDERR} "Only push to the branch 'master' is supported on a MediaWiki\n";
1161                         print {*STDOUT} "error ${remote} only master allowed\n";
1162                         next;
1163                 }
1164                 if (mw_push_revision($local, $remote)) {
1165                         $pushed = 1;
1166                 }
1167         }
1168
1169         # Notify Git that the push is done
1170         print {*STDOUT} "\n";
1171
1172         if ($pushed && $dumb_push) {
1173                 print {*STDERR} "Just pushed some revisions to MediaWiki.\n";
1174                 print {*STDERR} "The pushed revisions now have to be re-imported, and your current branch\n";
1175                 print {*STDERR} "needs to be updated with these re-imported commits. You can do this with\n";
1176                 print {*STDERR} "\n";
1177                 print {*STDERR} "  git pull --rebase\n";
1178                 print {*STDERR} "\n";
1179         }
1180         return;
1181 }
1182
1183 sub mw_push_revision {
1184         my $local = shift;
1185         my $remote = shift; # actually, this has to be "refs/heads/master" at this point.
1186         my $last_local_revid = get_last_local_revision();
1187         print {*STDERR} ".\n"; # Finish sentence started by get_last_local_revision()
1188         my $last_remote_revid = get_last_remote_revision();
1189         my $mw_revision = $last_remote_revid;
1190
1191         # Get sha1 of commit pointed by local HEAD
1192         #
1193         # It's OK to use run_git_unquoted() because $local is supplied
1194         # by the local git itself.
1195         my $HEAD_sha1 = run_git_unquoted("rev-parse ${local} 2>/dev/null");
1196         chomp($HEAD_sha1);
1197         # Get sha1 of commit pointed by remotes/$remotename/master
1198         #
1199         # It's OK to use run_git_unquoted() here because $remotename is
1200         # supplied by the local git itself.
1201         my $remoteorigin_sha1 = run_git_unquoted("rev-parse refs/remotes/${remotename}/master 2>/dev/null");
1202         chomp($remoteorigin_sha1);
1203
1204         if ($last_local_revid > 0 &&
1205             $last_local_revid < $last_remote_revid) {
1206                 return error_non_fast_forward($remote);
1207         }
1208
1209         if ($HEAD_sha1 eq $remoteorigin_sha1) {
1210                 # nothing to push
1211                 return 0;
1212         }
1213
1214         # Get every commit in between HEAD and refs/remotes/origin/master,
1215         # including HEAD and refs/remotes/origin/master
1216         my @commit_pairs = ();
1217         if ($last_local_revid > 0) {
1218                 my $parsed_sha1 = $remoteorigin_sha1;
1219                 # Find a path from last MediaWiki commit to pushed commit
1220                 print {*STDERR} "Computing path from local to remote ...\n";
1221                 my @local_ancestry = split(/\n/, run_git_quoted(["rev-list", "--boundary", "--parents", $local, "^${parsed_sha1}"]));
1222                 my %local_ancestry;
1223                 foreach my $line (@local_ancestry) {
1224                         if (my ($child, $parents) = $line =~ /^-?([a-f0-9]+) ([a-f0-9 ]+)/) {
1225                                 foreach my $parent (split(/ /, $parents)) {
1226                                         $local_ancestry{$parent} = $child;
1227                                 }
1228                         } elsif (!$line =~ /^([a-f0-9]+)/) {
1229                                 die "Unexpected output from git rev-list: ${line}\n";
1230                         }
1231                 }
1232                 while ($parsed_sha1 ne $HEAD_sha1) {
1233                         my $child = $local_ancestry{$parsed_sha1};
1234                         if (!$child) {
1235                                 print {*STDERR} "Cannot find a path in history from remote commit to last commit\n";
1236                                 return error_non_fast_forward($remote);
1237                         }
1238                         push(@commit_pairs, [$parsed_sha1, $child]);
1239                         $parsed_sha1 = $child;
1240                 }
1241         } else {
1242                 # No remote mediawiki revision. Export the whole
1243                 # history (linearized with --first-parent)
1244                 print {*STDERR} "Warning: no common ancestor, pushing complete history\n";
1245                 my $history = run_git_quoted(["rev-list", "--first-parent", "--children", $local]);
1246                 my @history = split(/\n/, $history);
1247                 @history = @history[1..$#history];
1248                 foreach my $line (reverse @history) {
1249                         my @commit_info_split = split(/[ \n]/, $line);
1250                         push(@commit_pairs, \@commit_info_split);
1251                 }
1252         }
1253
1254         foreach my $commit_info_split (@commit_pairs) {
1255                 my $sha1_child = @{$commit_info_split}[0];
1256                 my $sha1_commit = @{$commit_info_split}[1];
1257                 my $diff_infos = run_git_quoted(["diff-tree", "-r", "--raw", "-z", $sha1_child, $sha1_commit]);
1258                 # TODO: we could detect rename, and encode them with a #redirect on the wiki.
1259                 # TODO: for now, it's just a delete+add
1260                 my @diff_info_list = split(/\0/, $diff_infos);
1261                 # Keep the subject line of the commit message as mediawiki comment for the revision
1262                 my $commit_msg = run_git_quoted(["log", "--no-walk", '--format="%s"', $sha1_commit]);
1263                 chomp($commit_msg);
1264                 # Push every blob
1265                 while (@diff_info_list) {
1266                         my $status;
1267                         # git diff-tree -z gives an output like
1268                         # <metadata>\0<filename1>\0
1269                         # <metadata>\0<filename2>\0
1270                         # and we've split on \0.
1271                         my $info = shift(@diff_info_list);
1272                         my $file = shift(@diff_info_list);
1273                         ($mw_revision, $status) = mw_push_file($info, $file, $commit_msg, $mw_revision);
1274                         if ($status eq 'non-fast-forward') {
1275                                 # we may already have sent part of the
1276                                 # commit to MediaWiki, but it's too
1277                                 # late to cancel it. Stop the push in
1278                                 # the middle, but still give an
1279                                 # accurate error message.
1280                                 return error_non_fast_forward($remote);
1281                         }
1282                         if ($status ne 'ok') {
1283                                 die("Unknown error from mw_push_file()\n");
1284                         }
1285                 }
1286                 if (!$dumb_push) {
1287                         run_git_quoted(["notes", "--ref=${remotename}/mediawiki",
1288                                         "add", "-f", "-m",
1289                                         "mediawiki_revision: ${mw_revision}",
1290                                         $sha1_commit]);
1291                 }
1292         }
1293
1294         print {*STDOUT} "ok ${remote}\n";
1295         return 1;
1296 }
1297
1298 sub get_allowed_file_extensions {
1299         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1300
1301         my $query = {
1302                 action => 'query',
1303                 meta => 'siteinfo',
1304                 siprop => 'fileextensions'
1305                 };
1306         my $result = $mediawiki->api($query);
1307         my @file_extensions = map { $_->{ext}} @{$result->{query}->{fileextensions}};
1308         my %hashFile = map { $_ => 1 } @file_extensions;
1309
1310         return %hashFile;
1311 }
1312
1313 # In memory cache for MediaWiki namespace ids.
1314 my %namespace_id;
1315
1316 # Namespaces whose id is cached in the configuration file
1317 # (to avoid duplicates)
1318 my %cached_mw_namespace_id;
1319
1320 # Return MediaWiki id for a canonical namespace name.
1321 # Ex.: "File", "Project".
1322 sub get_mw_namespace_id {
1323         $mediawiki = connect_maybe($mediawiki, $remotename, $url);
1324         my $name = shift;
1325
1326         if (!exists $namespace_id{$name}) {
1327                 # Look at configuration file, if the record for that namespace is
1328                 # already cached. Namespaces are stored in form:
1329                 # "Name_of_namespace:Id_namespace", ex.: "File:6".
1330                 my @temp = split(/\n/,
1331                                  run_git_quoted(["config", "--get-all", "remote.${remotename}.namespaceCache"]));
1332                 chomp(@temp);
1333                 foreach my $ns (@temp) {
1334                         my ($n, $id) = split(/:/, $ns);
1335                         if ($id eq 'notANameSpace') {
1336                                 $namespace_id{$n} = {is_namespace => 0};
1337                         } else {
1338                                 $namespace_id{$n} = {is_namespace => 1, id => $id};
1339                         }
1340                         $cached_mw_namespace_id{$n} = 1;
1341                 }
1342         }
1343
1344         if (!exists $namespace_id{$name}) {
1345                 print {*STDERR} "Namespace ${name} not found in cache, querying the wiki ...\n";
1346                 # NS not found => get namespace id from MW and store it in
1347                 # configuration file.
1348                 my $query = {
1349                         action => 'query',
1350                         meta => 'siteinfo',
1351                         siprop => 'namespaces'
1352                 };
1353                 my $result = $mediawiki->api($query);
1354
1355                 while (my ($id, $ns) = each(%{$result->{query}->{namespaces}})) {
1356                         if (defined($ns->{id}) && defined($ns->{canonical})) {
1357                                 $namespace_id{$ns->{canonical}} = {is_namespace => 1, id => $ns->{id}};
1358                                 if ($ns->{'*'}) {
1359                                         # alias (e.g. french Fichier: as alias for canonical File:)
1360                                         $namespace_id{$ns->{'*'}} = {is_namespace => 1, id => $ns->{id}};
1361                                 }
1362                         }
1363                 }
1364         }
1365
1366         my $ns = $namespace_id{$name};
1367         my $id;
1368
1369         if (!defined $ns) {
1370                 my @namespaces = map { s/ /_/g; $_; } sort keys %namespace_id;
1371                 print {*STDERR} "No such namespace ${name} on MediaWiki, known namespaces: @namespaces\n";
1372                 $ns = {is_namespace => 0};
1373                 $namespace_id{$name} = $ns;
1374         }
1375
1376         if ($ns->{is_namespace}) {
1377                 $id = $ns->{id};
1378         }
1379
1380         # Store "notANameSpace" as special value for inexisting namespaces
1381         my $store_id = ($id || 'notANameSpace');
1382
1383         # Store explicitly requested namespaces on disk
1384         if (!exists $cached_mw_namespace_id{$name}) {
1385                 run_git_quoted(["config", "--add", "remote.${remotename}.namespaceCache", "${name}:${store_id}"]);
1386                 $cached_mw_namespace_id{$name} = 1;
1387         }
1388         return $id;
1389 }
1390
1391 sub get_mw_namespace_id_for_page {
1392         my $namespace = shift;
1393         if ($namespace =~ /^([^:]*):/) {
1394                 return get_mw_namespace_id($namespace);
1395         } else {
1396                 return;
1397         }
1398 }