git.oblomov.eu Git - git/blob - git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent . \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary
 414         fconfigure $fd_df -blocking 0 -translation binary
 415         fconfigure $fd_lo -blocking 0 -translation binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 $ui_comm delete 0.0 end
 432                 $ui_comm insert end $content
 433                 return 1
 434         }
 435         return 0
 436 }
 437
 438 proc read_diff_index {fd after} {
 439         global buf_rdi
 440
 441         append buf_rdi [read $fd]
 442         set c 0
 443         set n [string length $buf_rdi]
 444         while {$c < $n} {
 445                 set z1 [string first "\0" $buf_rdi $c]
 446                 if {$z1 == -1} break
 447                 incr z1
 448                 set z2 [string first "\0" $buf_rdi $z1]
 449                 if {$z2 == -1} break
 450
 451                 incr c
 452                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 453                 merge_state \
 454                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 455                         [lindex $i 4]? \
 456                         [list [lindex $i 0] [lindex $i 2]] \
 457                         [list]
 458                 set c $z2
 459                 incr c
 460         }
 461         if {$c < $n} {
 462                 set buf_rdi [string range $buf_rdi $c end]
 463         } else {
 464                 set buf_rdi {}
 465         }
 466
 467         rescan_done $fd buf_rdi $after
 468 }
 469
 470 proc read_diff_files {fd after} {
 471         global buf_rdf
 472
 473         append buf_rdf [read $fd]
 474         set c 0
 475         set n [string length $buf_rdf]
 476         while {$c < $n} {
 477                 set z1 [string first "\0" $buf_rdf $c]
 478                 if {$z1 == -1} break
 479                 incr z1
 480                 set z2 [string first "\0" $buf_rdf $z1]
 481                 if {$z2 == -1} break
 482
 483                 incr c
 484                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 485                 merge_state \
 486                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 487                         ?[lindex $i 4] \
 488                         [list] \
 489                         [list [lindex $i 0] [lindex $i 2]]
 490                 set c $z2
 491                 incr c
 492         }
 493         if {$c < $n} {
 494                 set buf_rdf [string range $buf_rdf $c end]
 495         } else {
 496                 set buf_rdf {}
 497         }
 498
 499         rescan_done $fd buf_rdf $after
 500 }
 501
 502 proc read_ls_others {fd after} {
 503         global buf_rlo
 504
 505         append buf_rlo [read $fd]
 506         set pck [split $buf_rlo "\0"]
 507         set buf_rlo [lindex $pck end]
 508         foreach p [lrange $pck 0 end-1] {
 509                 merge_state $p ?O
 510         }
 511         rescan_done $fd buf_rlo $after
 512 }
 513
 514 proc rescan_done {fd buf after} {
 515         global rescan_active
 516         global file_states repo_config
 517         upvar $buf to_clear
 518
 519         if {![eof $fd]} return
 520         set to_clear {}
 521         close $fd
 522         if {[incr rescan_active -1] > 0} return
 523
 524         prune_selection
 525         unlock_index
 526         display_all_files
 527         reshow_diff
 528         uplevel #0 $after
 529 }
 530
 531 proc prune_selection {} {
 532         global file_states selected_paths
 533
 534         foreach path [array names selected_paths] {
 535                 if {[catch {set still_here $file_states($path)}]} {
 536                         unset selected_paths($path)
 537                 }
 538         }
 539 }
 540
 541 ######################################################################
 542 ##
 543 ## diff
 544
 545 proc clear_diff {} {
 546         global ui_diff current_diff_path ui_index ui_workdir
 547
 548         $ui_diff conf -state normal
 549         $ui_diff delete 0.0 end
 550         $ui_diff conf -state disabled
 551
 552         set current_diff_path {}
 553
 554         $ui_index tag remove in_diff 0.0 end
 555         $ui_workdir tag remove in_diff 0.0 end
 556 }
 557
 558 proc reshow_diff {} {
 559         global ui_status_value file_states file_lists
 560         global current_diff_path current_diff_side
 561
 562         set p $current_diff_path
 563         if {$p eq {}
 564                 || $current_diff_side eq {}
 565                 || [catch {set s $file_states($p)}]
 566                 || [lsearch -sorted $file_lists($current_diff_side) $p] == -1} {
 567                 clear_diff
 568         } else {
 569                 show_diff $p $current_diff_side
 570         }
 571 }
 572
 573 proc handle_empty_diff {} {
 574         global current_diff_path file_states file_lists
 575
 576         set path $current_diff_path
 577         set s $file_states($path)
 578         if {[lindex $s 0] ne {_M}} return
 579
 580         info_popup "No differences detected.
 581
 582 [short_path $path] has no changes.
 583
 584 The modification date of this file was updated
 585 by another application and you currently have
 586 the Trust File Modification Timestamps option
 587 enabled, so Git did not automatically detect
 588 that there are no content differences in this
 589 file.
 590
 591 This file will now be removed from the modified
 592 files list, to prevent possible confusion.
 593 "
 594         if {[catch {exec git update-index -- $path} err]} {
 595                 error_popup "Failed to refresh index:\n\n$err"
 596         }
 597
 598         clear_diff
 599         display_file $path __
 600 }
 601
 602 proc show_diff {path w {lno {}}} {
 603         global file_states file_lists
 604         global is_3way_diff diff_active repo_config
 605         global ui_diff ui_status_value ui_index ui_workdir
 606         global current_diff_path current_diff_side
 607
 608         if {$diff_active || ![lock_index read]} return
 609
 610         clear_diff
 611         if {$w eq {} || $lno == {}} {
 612                 foreach w [array names file_lists] {
 613                         set lno [lsearch -sorted $file_lists($w) $path]
 614                         if {$lno >= 0} {
 615                                 incr lno
 616                                 break
 617                         }
 618                 }
 619         }
 620         if {$w ne {} && $lno >= 1} {
 621                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 622         }
 623
 624         set s $file_states($path)
 625         set m [lindex $s 0]
 626         set is_3way_diff 0
 627         set diff_active 1
 628         set current_diff_path $path
 629         set current_diff_side $w
 630         set ui_status_value "Loading diff of [escape_path $path]..."
 631
 632         # - Git won't give us the diff, there's nothing to compare to!
 633         #
 634         if {$m eq {_O}} {
 635                 if {[catch {
 636                                 set fd [open $path r]
 637                                 set content [read $fd]
 638                                 close $fd
 639                         } err ]} {
 640                         set diff_active 0
 641                         unlock_index
 642                         set ui_status_value "Unable to display [escape_path $path]"
 643                         error_popup "Error loading file:\n\n$err"
 644                         return
 645                 }
 646                 $ui_diff conf -state normal
 647                 $ui_diff insert end $content
 648                 $ui_diff conf -state disabled
 649                 set diff_active 0
 650                 unlock_index
 651                 set ui_status_value {Ready.}
 652                 return
 653         }
 654
 655         set cmd [list | git]
 656         if {$w eq $ui_index} {
 657                 lappend cmd diff-index
 658                 lappend cmd --cached
 659         } elseif {$w eq $ui_workdir} {
 660                 if {[string index $m 0] eq {U}} {
 661                         lappend cmd diff
 662                 } else {
 663                         lappend cmd diff-files
 664                 }
 665         }
 666
 667         lappend cmd -p
 668         lappend cmd --no-color
 669         if {$repo_config(gui.diffcontext) > 0} {
 670                 lappend cmd "-U$repo_config(gui.diffcontext)"
 671         }
 672         if {$w eq $ui_index} {
 673                 lappend cmd [PARENT]
 674         }
 675         lappend cmd --
 676         lappend cmd $path
 677
 678         if {[catch {set fd [open $cmd r]} err]} {
 679                 set diff_active 0
 680                 unlock_index
 681                 set ui_status_value "Unable to display [escape_path $path]"
 682                 error_popup "Error loading diff:\n\n$err"
 683                 return
 684         }
 685
 686         fconfigure $fd -blocking 0 -translation auto
 687         fileevent $fd readable [list read_diff $fd]
 688 }
 689
 690 proc read_diff {fd} {
 691         global ui_diff ui_status_value is_3way_diff diff_active
 692         global repo_config
 693
 694         $ui_diff conf -state normal
 695         while {[gets $fd line] >= 0} {
 696                 # -- Cleanup uninteresting diff header lines.
 697                 #
 698                 if {[string match {diff --git *}      $line]} continue
 699                 if {[string match {diff --cc *}       $line]} continue
 700                 if {[string match {diff --combined *} $line]} continue
 701                 if {[string match {--- *}             $line]} continue
 702                 if {[string match {+++ *}             $line]} continue
 703                 if {$line eq {deleted file mode 120000}} {
 704                         set line "deleted symlink"
 705                 }
 706
 707                 # -- Automatically detect if this is a 3 way diff.
 708                 #
 709                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 710
 711                 if {[string match {index *} $line]} {
 712                         set tags {}
 713                 } elseif {$is_3way_diff} {
 714                         set op [string range $line 0 1]
 715                         switch -- $op {
 716                         {  } {set tags {}}
 717                         {@@} {set tags d_@}
 718                         { +} {set tags d_s+}
 719                         { -} {set tags d_s-}
 720                         {+ } {set tags d_+s}
 721                         {- } {set tags d_-s}
 722                         {--} {set tags d_--}
 723                         {++} {
 724                                 if {[regexp {^\+\+([<>]{7} |={7})} $line _g op]} {
 725                                         set line [string replace $line 0 1 {  }]
 726                                         set tags d$op
 727                                 } else {
 728                                         set tags d_++
 729                                 }
 730                         }
 731                         default {
 732                                 puts "error: Unhandled 3 way diff marker: {$op}"
 733                                 set tags {}
 734                         }
 735                         }
 736                 } else {
 737                         set op [string index $line 0]
 738                         switch -- $op {
 739                         { } {set tags {}}
 740                         {@} {set tags d_@}
 741                         {-} {set tags d_-}
 742                         {+} {
 743                                 if {[regexp {^\+([<>]{7} |={7})} $line _g op]} {
 744                                         set line [string replace $line 0 0 { }]
 745                                         set tags d$op
 746                                 } else {
 747                                         set tags d_+
 748                                 }
 749                         }
 750                         default {
 751                                 puts "error: Unhandled 2 way diff marker: {$op}"
 752                                 set tags {}
 753                         }
 754                         }
 755                 }
 756                 $ui_diff insert end $line $tags
 757                 $ui_diff insert end "\n" $tags
 758         }
 759         $ui_diff conf -state disabled
 760
 761         if {[eof $fd]} {
 762                 close $fd
 763                 set diff_active 0
 764                 unlock_index
 765                 set ui_status_value {Ready.}
 766
 767                 if {$repo_config(gui.trustmtime) eq {true}
 768                         && [$ui_diff index end] eq {2.0}} {
 769                         handle_empty_diff
 770                 }
 771         }
 772 }
 773
 774 ######################################################################
 775 ##
 776 ## commit
 777
 778 proc load_last_commit {} {
 779         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 780
 781         if {[llength $PARENT] == 0} {
 782                 error_popup {There is nothing to amend.
 783
 784 You are about to create the initial commit.
 785 There is no commit before this to amend.
 786 }
 787                 return
 788         }
 789
 790         repository_state curType curHEAD curMERGE_HEAD
 791         if {$curType eq {merge}} {
 792                 error_popup {Cannot amend while merging.
 793
 794 You are currently in the middle of a merge that
 795 has not been fully completed.  You cannot amend
 796 the prior commit unless you first abort the
 797 current merge activity.
 798 }
 799                 return
 800         }
 801
 802         set msg {}
 803         set parents [list]
 804         if {[catch {
 805                         set fd [open "| git cat-file commit $curHEAD" r]
 806                         while {[gets $fd line] > 0} {
 807                                 if {[string match {parent *} $line]} {
 808                                         lappend parents [string range $line 7 end]
 809                                 }
 810                         }
 811                         set msg [string trim [read $fd]]
 812                         close $fd
 813                 } err]} {
 814                 error_popup "Error loading commit data for amend:\n\n$err"
 815                 return
 816         }
 817
 818         set HEAD $curHEAD
 819         set PARENT $parents
 820         set MERGE_HEAD [list]
 821         switch -- [llength $parents] {
 822         0       {set commit_type amend-initial}
 823         1       {set commit_type amend}
 824         default {set commit_type amend-merge}
 825         }
 826
 827         $ui_comm delete 0.0 end
 828         $ui_comm insert end $msg
 829         $ui_comm edit reset
 830         $ui_comm edit modified false
 831         rescan {set ui_status_value {Ready.}}
 832 }
 833
 834 proc create_new_commit {} {
 835         global commit_type ui_comm
 836
 837         set commit_type normal
 838         $ui_comm delete 0.0 end
 839         $ui_comm edit reset
 840         $ui_comm edit modified false
 841         rescan {set ui_status_value {Ready.}}
 842 }
 843
 844 set GIT_COMMITTER_IDENT {}
 845
 846 proc committer_ident {} {
 847         global GIT_COMMITTER_IDENT
 848
 849         if {$GIT_COMMITTER_IDENT eq {}} {
 850                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 851                         error_popup "Unable to obtain your identity:\n\n$err"
 852                         return {}
 853                 }
 854                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 855                         $me me GIT_COMMITTER_IDENT]} {
 856                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 857                         return {}
 858                 }
 859         }
 860
 861         return $GIT_COMMITTER_IDENT
 862 }
 863
 864 proc commit_tree {} {
 865         global HEAD commit_type file_states ui_comm repo_config
 866         global ui_status_value pch_error
 867
 868         if {![lock_index update]} return
 869         if {[committer_ident] eq {}} return
 870
 871         # -- Our in memory state should match the repository.
 872         #
 873         repository_state curType curHEAD curMERGE_HEAD
 874         if {[string match amend* $commit_type]
 875                 && $curType eq {normal}
 876                 && $curHEAD eq $HEAD} {
 877         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 878                 info_popup {Last scanned state does not match repository state.
 879
 880 Another Git program has modified this repository
 881 since the last scan.  A rescan must be performed
 882 before another commit can be created.
 883
 884 The rescan will be automatically started now.
 885 }
 886                 unlock_index
 887                 rescan {set ui_status_value {Ready.}}
 888                 return
 889         }
 890
 891         # -- At least one file should differ in the index.
 892         #
 893         set files_ready 0
 894         foreach path [array names file_states] {
 895                 switch -glob -- [lindex $file_states($path) 0] {
 896                 _? {continue}
 897                 A? -
 898                 D? -
 899                 M? {set files_ready 1}
 900                 U? {
 901                         error_popup "Unmerged files cannot be committed.
 902
 903 File [short_path $path] has merge conflicts.
 904 You must resolve them and add the file before committing.
 905 "
 906                         unlock_index
 907                         return
 908                 }
 909                 default {
 910                         error_popup "Unknown file state [lindex $s 0] detected.
 911
 912 File [short_path $path] cannot be committed by this program.
 913 "
 914                 }
 915                 }
 916         }
 917         if {!$files_ready} {
 918                 info_popup {No changes to commit.
 919
 920 You must add at least 1 file before you can commit.
 921 }
 922                 unlock_index
 923                 return
 924         }
 925
 926         # -- A message is required.
 927         #
 928         set msg [string trim [$ui_comm get 1.0 end]]
 929         if {$msg eq {}} {
 930                 error_popup {Please supply a commit message.
 931
 932 A good commit message has the following format:
 933
 934 - First line: Describe in one sentance what you did.
 935 - Second line: Blank
 936 - Remaining lines: Describe why this change is good.
 937 }
 938                 unlock_index
 939                 return
 940         }
 941
 942         # -- Run the pre-commit hook.
 943         #
 944         set pchook [gitdir hooks pre-commit]
 945
 946         # On Cygwin [file executable] might lie so we need to ask
 947         # the shell if the hook is executable.  Yes that's annoying.
 948         #
 949         if {[is_Windows] && [file isfile $pchook]} {
 950                 set pchook [list sh -c [concat \
 951                         "if test -x \"$pchook\";" \
 952                         "then exec \"$pchook\" 2>&1;" \
 953                         "fi"]]
 954         } elseif {[file executable $pchook]} {
 955                 set pchook [list $pchook |& cat]
 956         } else {
 957                 commit_writetree $curHEAD $msg
 958                 return
 959         }
 960
 961         set ui_status_value {Calling pre-commit hook...}
 962         set pch_error {}
 963         set fd_ph [open "| $pchook" r]
 964         fconfigure $fd_ph -blocking 0 -translation binary
 965         fileevent $fd_ph readable \
 966                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 967 }
 968
 969 proc commit_prehook_wait {fd_ph curHEAD msg} {
 970         global pch_error ui_status_value
 971
 972         append pch_error [read $fd_ph]
 973         fconfigure $fd_ph -blocking 1
 974         if {[eof $fd_ph]} {
 975                 if {[catch {close $fd_ph}]} {
 976                         set ui_status_value {Commit declined by pre-commit hook.}
 977                         hook_failed_popup pre-commit $pch_error
 978                         unlock_index
 979                 } else {
 980                         commit_writetree $curHEAD $msg
 981                 }
 982                 set pch_error {}
 983                 return
 984         }
 985         fconfigure $fd_ph -blocking 0
 986 }
 987
 988 proc commit_writetree {curHEAD msg} {
 989         global ui_status_value
 990
 991         set ui_status_value {Committing changes...}
 992         set fd_wt [open "| git write-tree" r]
 993         fileevent $fd_wt readable \
 994                 [list commit_committree $fd_wt $curHEAD $msg]
 995 }
 996
 997 proc commit_committree {fd_wt curHEAD msg} {
 998         global HEAD PARENT MERGE_HEAD commit_type
 999         global single_commit
1000         global ui_status_value ui_comm selected_commit_type
1001         global file_states selected_paths rescan_active
1002
1003         gets $fd_wt tree_id
1004         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
1005                 error_popup "write-tree failed:\n\n$err"
1006                 set ui_status_value {Commit failed.}
1007                 unlock_index
1008                 return
1009         }
1010
1011         # -- Create the commit.
1012         #
1013         set cmd [list git commit-tree $tree_id]
1014         set parents [concat $PARENT $MERGE_HEAD]
1015         if {[llength $parents] > 0} {
1016                 foreach p $parents {
1017                         lappend cmd -p $p
1018                 }
1019         } else {
1020                 # git commit-tree writes to stderr during initial commit.
1021                 lappend cmd 2>/dev/null
1022         }
1023         lappend cmd << $msg
1024         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1025                 error_popup "commit-tree failed:\n\n$err"
1026                 set ui_status_value {Commit failed.}
1027                 unlock_index
1028                 return
1029         }
1030
1031         # -- Update the HEAD ref.
1032         #
1033         set reflogm commit
1034         if {$commit_type ne {normal}} {
1035                 append reflogm " ($commit_type)"
1036         }
1037         set i [string first "\n" $msg]
1038         if {$i >= 0} {
1039                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1040         } else {
1041                 append reflogm {: } $msg
1042         }
1043         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1044         if {[catch {eval exec $cmd} err]} {
1045                 error_popup "update-ref failed:\n\n$err"
1046                 set ui_status_value {Commit failed.}
1047                 unlock_index
1048                 return
1049         }
1050
1051         # -- Cleanup after ourselves.
1052         #
1053         catch {file delete [gitdir MERGE_HEAD]}
1054         catch {file delete [gitdir MERGE_MSG]}
1055         catch {file delete [gitdir SQUASH_MSG]}
1056         catch {file delete [gitdir GITGUI_MSG]}
1057
1058         # -- Let rerere do its thing.
1059         #
1060         if {[file isdirectory [gitdir rr-cache]]} {
1061                 catch {exec git rerere}
1062         }
1063
1064         # -- Run the post-commit hook.
1065         #
1066         set pchook [gitdir hooks post-commit]
1067         if {[is_Windows] && [file isfile $pchook]} {
1068                 set pchook [list sh -c [concat \
1069                         "if test -x \"$pchook\";" \
1070                         "then exec \"$pchook\";" \
1071                         "fi"]]
1072         } elseif {![file executable $pchook]} {
1073                 set pchook {}
1074         }
1075         if {$pchook ne {}} {
1076                 catch {exec $pchook &}
1077         }
1078
1079         $ui_comm delete 0.0 end
1080         $ui_comm edit reset
1081         $ui_comm edit modified false
1082
1083         if {$single_commit} do_quit
1084
1085         # -- Update in memory status
1086         #
1087         set selected_commit_type new
1088         set commit_type normal
1089         set HEAD $cmt_id
1090         set PARENT $cmt_id
1091         set MERGE_HEAD [list]
1092
1093         foreach path [array names file_states] {
1094                 set s $file_states($path)
1095                 set m [lindex $s 0]
1096                 switch -glob -- $m {
1097                 _O -
1098                 _M -
1099                 _D {continue}
1100                 __ -
1101                 A_ -
1102                 M_ -
1103                 D_ {
1104                         unset file_states($path)
1105                         catch {unset selected_paths($path)}
1106                 }
1107                 DO {
1108                         set file_states($path) [list _O [lindex $s 1] {} {}]
1109                 }
1110                 AM -
1111                 AD -
1112                 MM -
1113                 MD {
1114                         set file_states($path) [list \
1115                                 _[string index $m 1] \
1116                                 [lindex $s 1] \
1117                                 [lindex $s 3] \
1118                                 {}]
1119                 }
1120                 }
1121         }
1122
1123         display_all_files
1124         unlock_index
1125         reshow_diff
1126         set ui_status_value \
1127                 "Changes committed as [string range $cmt_id 0 7]."
1128 }
1129
1130 ######################################################################
1131 ##
1132 ## fetch pull push
1133
1134 proc fetch_from {remote} {
1135         set w [new_console "fetch $remote" \
1136                 "Fetching new changes from $remote"]
1137         set cmd [list git fetch]
1138         lappend cmd $remote
1139         console_exec $w $cmd
1140 }
1141
1142 proc pull_remote {remote branch} {
1143         global HEAD commit_type file_states repo_config
1144
1145         if {![lock_index update]} return
1146
1147         # -- Our in memory state should match the repository.
1148         #
1149         repository_state curType curHEAD curMERGE_HEAD
1150         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1151                 info_popup {Last scanned state does not match repository state.
1152
1153 Another Git program has modified this repository
1154 since the last scan.  A rescan must be performed
1155 before a pull operation can be started.
1156
1157 The rescan will be automatically started now.
1158 }
1159                 unlock_index
1160                 rescan {set ui_status_value {Ready.}}
1161                 return
1162         }
1163
1164         # -- No differences should exist before a pull.
1165         #
1166         if {[array size file_states] != 0} {
1167                 error_popup {Uncommitted but modified files are present.
1168
1169 You should not perform a pull with unmodified
1170 files in your working directory as Git will be
1171 unable to recover from an incorrect merge.
1172
1173 You should commit or revert all changes before
1174 starting a pull operation.
1175 }
1176                 unlock_index
1177                 return
1178         }
1179
1180         set w [new_console "pull $remote $branch" \
1181                 "Pulling new changes from branch $branch in $remote"]
1182         set cmd [list git pull]
1183         if {$repo_config(gui.pullsummary) eq {false}} {
1184                 lappend cmd --no-summary
1185         }
1186         lappend cmd $remote
1187         lappend cmd $branch
1188         console_exec $w $cmd [list post_pull_remote $remote $branch]
1189 }
1190
1191 proc post_pull_remote {remote branch success} {
1192         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1193         global ui_status_value
1194
1195         unlock_index
1196         if {$success} {
1197                 repository_state commit_type HEAD MERGE_HEAD
1198                 set PARENT $HEAD
1199                 set selected_commit_type new
1200                 set ui_status_value "Pulling $branch from $remote complete."
1201         } else {
1202                 rescan [list set ui_status_value \
1203                         "Conflicts detected while pulling $branch from $remote."]
1204         }
1205 }
1206
1207 proc push_to {remote} {
1208         set w [new_console "push $remote" \
1209                 "Pushing changes to $remote"]
1210         set cmd [list git push]
1211         lappend cmd $remote
1212         console_exec $w $cmd
1213 }
1214
1215 ######################################################################
1216 ##
1217 ## ui helpers
1218
1219 proc mapicon {w state path} {
1220         global all_icons
1221
1222         if {[catch {set r $all_icons($state$w)}]} {
1223                 puts "error: no icon for $w state={$state} $path"
1224                 return file_plain
1225         }
1226         return $r
1227 }
1228
1229 proc mapdesc {state path} {
1230         global all_descs
1231
1232         if {[catch {set r $all_descs($state)}]} {
1233                 puts "error: no desc for state={$state} $path"
1234                 return $state
1235         }
1236         return $r
1237 }
1238
1239 proc escape_path {path} {
1240         regsub -all "\n" $path "\\n" path
1241         return $path
1242 }
1243
1244 proc short_path {path} {
1245         return [escape_path [lindex [file split $path] end]]
1246 }
1247
1248 set next_icon_id 0
1249 set null_sha1 [string repeat 0 40]
1250
1251 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1252         global file_states next_icon_id null_sha1
1253
1254         set s0 [string index $new_state 0]
1255         set s1 [string index $new_state 1]
1256
1257         if {[catch {set info $file_states($path)}]} {
1258                 set state __
1259                 set icon n[incr next_icon_id]
1260         } else {
1261                 set state [lindex $info 0]
1262                 set icon [lindex $info 1]
1263                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1264                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1265         }
1266
1267         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1268         elseif {$s0 eq {_}} {set s0 _}
1269
1270         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1271         elseif {$s1 eq {_}} {set s1 _}
1272
1273         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1274                 set head_info [list 0 $null_sha1]
1275         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1276                 && $head_info eq {}} {
1277                 set head_info $index_info
1278         }
1279
1280         set file_states($path) [list $s0$s1 $icon \
1281                 $head_info $index_info \
1282                 ]
1283         return $state
1284 }
1285
1286 proc display_file_helper {w path icon_name old_m new_m} {
1287         global file_lists
1288
1289         if {$new_m eq {_}} {
1290                 set lno [lsearch -sorted $file_lists($w) $path]
1291                 if {$lno >= 0} {
1292                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1293                         incr lno
1294                         $w conf -state normal
1295                         $w delete $lno.0 [expr {$lno + 1}].0
1296                         $w conf -state disabled
1297                 }
1298         } elseif {$old_m eq {_} && $new_m ne {_}} {
1299                 lappend file_lists($w) $path
1300                 set file_lists($w) [lsort -unique $file_lists($w)]
1301                 set lno [lsearch -sorted $file_lists($w) $path]
1302                 incr lno
1303                 $w conf -state normal
1304                 $w image create $lno.0 \
1305                         -align center -padx 5 -pady 1 \
1306                         -name $icon_name \
1307                         -image [mapicon $w $new_m $path]
1308                 $w insert $lno.1 "[escape_path $path]\n"
1309                 $w conf -state disabled
1310         } elseif {$old_m ne $new_m} {
1311                 $w conf -state normal
1312                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1313                 $w conf -state disabled
1314         }
1315 }
1316
1317 proc display_file {path state} {
1318         global file_states selected_paths
1319         global ui_index ui_workdir
1320
1321         set old_m [merge_state $path $state]
1322         set s $file_states($path)
1323         set new_m [lindex $s 0]
1324         set icon_name [lindex $s 1]
1325
1326         set o [string index $old_m 0]
1327         set n [string index $new_m 0]
1328         if {$o eq {U}} {
1329                 set o _
1330         }
1331         if {$n eq {U}} {
1332                 set n _
1333         }
1334         display_file_helper     $ui_index $path $icon_name $o $n
1335
1336         if {[string index $old_m 0] eq {U}} {
1337                 set o U
1338         } else {
1339                 set o [string index $old_m 1]
1340         }
1341         if {[string index $new_m 0] eq {U}} {
1342                 set n U
1343         } else {
1344                 set n [string index $new_m 1]
1345         }
1346         display_file_helper     $ui_workdir $path $icon_name $o $n
1347
1348         if {$new_m eq {__}} {
1349                 unset file_states($path)
1350                 catch {unset selected_paths($path)}
1351         }
1352 }
1353
1354 proc display_all_files_helper {w path icon_name m} {
1355         global file_lists
1356
1357         lappend file_lists($w) $path
1358         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1359         $w image create end \
1360                 -align center -padx 5 -pady 1 \
1361                 -name $icon_name \
1362                 -image [mapicon $w $m $path]
1363         $w insert end "[escape_path $path]\n"
1364 }
1365
1366 proc display_all_files {} {
1367         global ui_index ui_workdir
1368         global file_states file_lists
1369         global last_clicked
1370
1371         $ui_index conf -state normal
1372         $ui_workdir conf -state normal
1373
1374         $ui_index delete 0.0 end
1375         $ui_workdir delete 0.0 end
1376         set last_clicked {}
1377
1378         set file_lists($ui_index) [list]
1379         set file_lists($ui_workdir) [list]
1380
1381         foreach path [lsort [array names file_states]] {
1382                 set s $file_states($path)
1383                 set m [lindex $s 0]
1384                 set icon_name [lindex $s 1]
1385
1386                 set s [string index $m 0]
1387                 if {$s ne {U} && $s ne {_}} {
1388                         display_all_files_helper $ui_index $path \
1389                                 $icon_name $s
1390                 }
1391
1392                 if {[string index $m 0] eq {U}} {
1393                         set s U
1394                 } else {
1395                         set s [string index $m 1]
1396                 }
1397                 if {$s ne {_}} {
1398                         display_all_files_helper $ui_workdir $path \
1399                                 $icon_name $s
1400                 }
1401         }
1402
1403         $ui_index conf -state disabled
1404         $ui_workdir conf -state disabled
1405 }
1406
1407 proc update_indexinfo {msg pathList after} {
1408         global update_index_cp ui_status_value
1409
1410         if {![lock_index update]} return
1411
1412         set update_index_cp 0
1413         set pathList [lsort $pathList]
1414         set totalCnt [llength $pathList]
1415         set batch [expr {int($totalCnt * .01) + 1}]
1416         if {$batch > 25} {set batch 25}
1417
1418         set ui_status_value [format \
1419                 "$msg... %i/%i files (%.2f%%)" \
1420                 $update_index_cp \
1421                 $totalCnt \
1422                 0.0]
1423         set fd [open "| git update-index -z --index-info" w]
1424         fconfigure $fd \
1425                 -blocking 0 \
1426                 -buffering full \
1427                 -buffersize 512 \
1428                 -translation binary
1429         fileevent $fd writable [list \
1430                 write_update_indexinfo \
1431                 $fd \
1432                 $pathList \
1433                 $totalCnt \
1434                 $batch \
1435                 $msg \
1436                 $after \
1437                 ]
1438 }
1439
1440 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1441         global update_index_cp ui_status_value
1442         global file_states current_diff_path
1443
1444         if {$update_index_cp >= $totalCnt} {
1445                 close $fd
1446                 unlock_index
1447                 uplevel #0 $after
1448                 return
1449         }
1450
1451         for {set i $batch} \
1452                 {$update_index_cp < $totalCnt && $i > 0} \
1453                 {incr i -1} {
1454                 set path [lindex $pathList $update_index_cp]
1455                 incr update_index_cp
1456
1457                 set s $file_states($path)
1458                 switch -glob -- [lindex $s 0] {
1459                 A? {set new _O}
1460                 M? {set new _M}
1461                 D_ {set new _D}
1462                 D? {set new _?}
1463                 ?? {continue}
1464                 }
1465                 set info [lindex $s 2]
1466                 if {$info eq {}} continue
1467
1468                 puts -nonewline $fd "$info\t$path\0"
1469                 display_file $path $new
1470         }
1471
1472         set ui_status_value [format \
1473                 "$msg... %i/%i files (%.2f%%)" \
1474                 $update_index_cp \
1475                 $totalCnt \
1476                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1477 }
1478
1479 proc update_index {msg pathList after} {
1480         global update_index_cp ui_status_value
1481
1482         if {![lock_index update]} return
1483
1484         set update_index_cp 0
1485         set pathList [lsort $pathList]
1486         set totalCnt [llength $pathList]
1487         set batch [expr {int($totalCnt * .01) + 1}]
1488         if {$batch > 25} {set batch 25}
1489
1490         set ui_status_value [format \
1491                 "$msg... %i/%i files (%.2f%%)" \
1492                 $update_index_cp \
1493                 $totalCnt \
1494                 0.0]
1495         set fd [open "| git update-index --add --remove -z --stdin" w]
1496         fconfigure $fd \
1497                 -blocking 0 \
1498                 -buffering full \
1499                 -buffersize 512 \
1500                 -translation binary
1501         fileevent $fd writable [list \
1502                 write_update_index \
1503                 $fd \
1504                 $pathList \
1505                 $totalCnt \
1506                 $batch \
1507                 $msg \
1508                 $after \
1509                 ]
1510 }
1511
1512 proc write_update_index {fd pathList totalCnt batch msg after} {
1513         global update_index_cp ui_status_value
1514         global file_states current_diff_path
1515
1516         if {$update_index_cp >= $totalCnt} {
1517                 close $fd
1518                 unlock_index
1519                 uplevel #0 $after
1520                 return
1521         }
1522
1523         for {set i $batch} \
1524                 {$update_index_cp < $totalCnt && $i > 0} \
1525                 {incr i -1} {
1526                 set path [lindex $pathList $update_index_cp]
1527                 incr update_index_cp
1528
1529                 switch -glob -- [lindex $file_states($path) 0] {
1530                 AD {set new __}
1531                 ?D {set new D_}
1532                 _O -
1533                 AM {set new A_}
1534                 U? {
1535                         if {[file exists $path]} {
1536                                 set new M_
1537                         } else {
1538                                 set new D_
1539                         }
1540                 }
1541                 ?M {set new M_}
1542                 ?? {continue}
1543                 }
1544                 puts -nonewline $fd "$path\0"
1545                 display_file $path $new
1546         }
1547
1548         set ui_status_value [format \
1549                 "$msg... %i/%i files (%.2f%%)" \
1550                 $update_index_cp \
1551                 $totalCnt \
1552                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1553 }
1554
1555 proc checkout_index {msg pathList after} {
1556         global update_index_cp ui_status_value
1557
1558         if {![lock_index update]} return
1559
1560         set update_index_cp 0
1561         set pathList [lsort $pathList]
1562         set totalCnt [llength $pathList]
1563         set batch [expr {int($totalCnt * .01) + 1}]
1564         if {$batch > 25} {set batch 25}
1565
1566         set ui_status_value [format \
1567                 "$msg... %i/%i files (%.2f%%)" \
1568                 $update_index_cp \
1569                 $totalCnt \
1570                 0.0]
1571         set cmd [list git checkout-index]
1572         lappend cmd --index
1573         lappend cmd --quiet
1574         lappend cmd --force
1575         lappend cmd -z
1576         lappend cmd --stdin
1577         set fd [open "| $cmd " w]
1578         fconfigure $fd \
1579                 -blocking 0 \
1580                 -buffering full \
1581                 -buffersize 512 \
1582                 -translation binary
1583         fileevent $fd writable [list \
1584                 write_checkout_index \
1585                 $fd \
1586                 $pathList \
1587                 $totalCnt \
1588                 $batch \
1589                 $msg \
1590                 $after \
1591                 ]
1592 }
1593
1594 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1595         global update_index_cp ui_status_value
1596         global file_states current_diff_path
1597
1598         if {$update_index_cp >= $totalCnt} {
1599                 close $fd
1600                 unlock_index
1601                 uplevel #0 $after
1602                 return
1603         }
1604
1605         for {set i $batch} \
1606                 {$update_index_cp < $totalCnt && $i > 0} \
1607                 {incr i -1} {
1608                 set path [lindex $pathList $update_index_cp]
1609                 incr update_index_cp
1610                 switch -glob -- [lindex $file_states($path) 0] {
1611                 U? {continue}
1612                 ?M -
1613                 ?D {
1614                         puts -nonewline $fd "$path\0"
1615                         display_file $path ?_
1616                 }
1617                 }
1618         }
1619
1620         set ui_status_value [format \
1621                 "$msg... %i/%i files (%.2f%%)" \
1622                 $update_index_cp \
1623                 $totalCnt \
1624                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1625 }
1626
1627 ######################################################################
1628 ##
1629 ## branch management
1630
1631 proc load_all_heads {} {
1632         global all_heads tracking_branches
1633
1634         set all_heads [list]
1635         set cmd [list git for-each-ref]
1636         lappend cmd --format=%(refname)
1637         lappend cmd refs/heads
1638         set fd [open "| $cmd" r]
1639         while {[gets $fd line] > 0} {
1640                 if {![catch {set info $tracking_branches($line)}]} continue
1641                 if {![regsub ^refs/heads/ $line {} name]} continue
1642                 lappend all_heads $name
1643         }
1644         close $fd
1645
1646         set all_heads [lsort $all_heads]
1647 }
1648
1649 proc populate_branch_menu {} {
1650         global all_heads disable_on_lock
1651
1652         set m .mbar.branch
1653         set last [$m index last]
1654         for {set i 0} {$i <= $last} {incr i} {
1655                 if {[$m type $i] eq {separator}} {
1656                         $m delete $i last
1657                         set new_dol [list]
1658                         foreach a $disable_on_lock {
1659                                 if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
1660                                         lappend new_dol $a
1661                                 }
1662                         }
1663                         set disable_on_lock $new_dol
1664                         break
1665                 }
1666         }
1667
1668         $m add separator
1669         foreach b $all_heads {
1670                 $m add radiobutton \
1671                         -label $b \
1672                         -command [list switch_branch $b] \
1673                         -variable current_branch \
1674                         -value $b \
1675                         -font font_ui
1676                 lappend disable_on_lock \
1677                         [list $m entryconf [$m index last] -state]
1678         }
1679 }
1680
1681 proc do_create_branch_action {w} {
1682         global all_heads null_sha1
1683         global create_branch_checkout create_branch_revtype
1684         global create_branch_head create_branch_trackinghead
1685
1686         set newbranch [string trim [$w.desc.name_t get 0.0 end]]
1687         if {![catch {exec git show-ref --verify -- "refs/heads/$newbranch"}]} {
1688                 tk_messageBox \
1689                         -icon error \
1690                         -type ok \
1691                         -title [wm title $w] \
1692                         -parent $w \
1693                         -message "Branch '$newbranch' already exists."
1694                 focus $w.desc.name_t
1695                 return
1696         }
1697         if {[catch {exec git check-ref-format "heads/$newbranch"}]} {
1698                 tk_messageBox \
1699                         -icon error \
1700                         -type ok \
1701                         -title [wm title $w] \
1702                         -parent $w \
1703                         -message "We do not like '$newbranch' as a branch name."
1704                 focus $w.desc.name_t
1705                 return
1706         }
1707
1708         set rev {}
1709         switch -- $create_branch_revtype {
1710         head {set rev $create_branch_head}
1711         tracking {set rev $create_branch_trackinghead}
1712         expression {set rev [string trim [$w.from.exp_t get 0.0 end]]}
1713         }
1714         if {[catch {set cmt [exec git rev-parse --verify "${rev}^0"]}]} {
1715                 tk_messageBox \
1716                         -icon error \
1717                         -type ok \
1718                         -title [wm title $w] \
1719                         -parent $w \
1720                         -message "Invalid starting revision: $rev"
1721                 return
1722         }
1723         set cmd [list git update-ref]
1724         lappend cmd -m
1725         lappend cmd "branch: Created from $rev"
1726         lappend cmd "refs/heads/$newbranch"
1727         lappend cmd $cmt
1728         lappend cmd $null_sha1
1729         if {[catch {eval exec $cmd} err]} {
1730                 tk_messageBox \
1731                         -icon error \
1732                         -type ok \
1733                         -title [wm title $w] \
1734                         -parent $w \
1735                         -message "Failed to create '$newbranch'.\n\n$err"
1736                 return
1737         }
1738
1739         lappend all_heads $newbranch
1740         set all_heads [lsort $all_heads]
1741         populate_branch_menu
1742         destroy $w
1743         if {$create_branch_checkout} {
1744                 switch_branch $newbranch
1745         }
1746 }
1747
1748 proc do_create_branch {} {
1749         global all_heads current_branch tracking_branches
1750         global create_branch_checkout create_branch_revtype
1751         global create_branch_head create_branch_trackinghead
1752
1753         set create_branch_checkout 1
1754         set create_branch_revtype head
1755         set create_branch_head $current_branch
1756         set create_branch_trackinghead {}
1757
1758         set w .branch_editor
1759         toplevel $w
1760         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1761
1762         label $w.header -text {Create New Branch} \
1763                 -font font_uibold
1764         pack $w.header -side top -fill x
1765
1766         frame $w.buttons
1767         button $w.buttons.create -text Create \
1768                 -font font_ui \
1769                 -default active \
1770                 -command [list do_create_branch_action $w]
1771         pack $w.buttons.create -side right
1772         button $w.buttons.cancel -text {Cancel} \
1773                 -font font_ui \
1774                 -command [list destroy $w]
1775         pack $w.buttons.cancel -side right -padx 5
1776         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1777
1778         labelframe $w.desc \
1779                 -text {Branch Description} \
1780                 -font font_ui
1781         label $w.desc.name_l -text {Name:} -font font_ui
1782         text $w.desc.name_t \
1783                 -borderwidth 1 \
1784                 -relief sunken \
1785                 -height 1 \
1786                 -width 40 \
1787                 -font font_ui
1788         grid $w.desc.name_l $w.desc.name_t -stick we -padx {0 5}
1789         bind $w.desc.name_t <Shift-Key-Tab> "focus $w.postActions.checkout;break"
1790         bind $w.desc.name_t <Key-Tab> "focus $w.from.exp_t;break"
1791         bind $w.desc.name_t <Key-Return> "do_create_branch_action $w;break"
1792         bind $w.desc.name_t <Key> {
1793                 if {{%K} ne {BackSpace}
1794                         && {%K} ne {Tab}
1795                         && {%K} ne {Escape}
1796                         && {%K} ne {Return}} {
1797                         if {%k <= 32} break
1798                         if {[string first %A {~^:?*[}] >= 0} break
1799                 }
1800         }
1801         grid columnconfigure $w.desc 1 -weight 1
1802         pack $w.desc -anchor nw -fill x -pady 5 -padx 5
1803
1804         set all_trackings [list]
1805         foreach b [array names tracking_branches] {
1806                 regsub ^refs/(heads|remotes)/ $b {} b
1807                 lappend all_trackings $b
1808         }
1809         set all_trackings [lsort -unique $all_trackings]
1810         if {$all_trackings ne {}} {
1811                 set create_branch_trackinghead [lindex $all_trackings 0]
1812         }
1813
1814         labelframe $w.from \
1815                 -text {Starting Revision} \
1816                 -font font_ui
1817         radiobutton $w.from.head_r \
1818                 -text {Local Branch:} \
1819                 -value head \
1820                 -variable create_branch_revtype \
1821                 -font font_ui
1822         eval tk_optionMenu $w.from.head_m create_branch_head $all_heads
1823         grid $w.from.head_r $w.from.head_m -sticky w
1824         radiobutton $w.from.tracking_r \
1825                 -text {Tracking Branch:} \
1826                 -value tracking \
1827                 -variable create_branch_revtype \
1828                 -font font_ui
1829         eval tk_optionMenu $w.from.tracking_m \
1830                 create_branch_trackinghead \
1831                 $all_trackings
1832         grid $w.from.tracking_r $w.from.tracking_m -sticky w
1833         radiobutton $w.from.exp_r \
1834                 -text {Revision Expression:} \
1835                 -value expression \
1836                 -variable create_branch_revtype \
1837                 -font font_ui
1838         text $w.from.exp_t \
1839                 -borderwidth 1 \
1840                 -relief sunken \
1841                 -height 1 \
1842                 -width 50 \
1843                 -font font_ui
1844         grid $w.from.exp_r $w.from.exp_t -stick we -padx {0 5}
1845         bind $w.from.exp_t <Shift-Key-Tab> "focus $w.desc.name_t;break"
1846         bind $w.from.exp_t <Key-Tab> "focus $w.postActions.checkout;break"
1847         bind $w.from.exp_t <Key-Return> "do_create_branch_action $w;break"
1848         grid columnconfigure $w.from 1 -weight 1
1849         pack $w.from -anchor nw -fill x -pady 5 -padx 5
1850
1851         labelframe $w.postActions \
1852                 -text {Post Creation Actions} \
1853                 -font font_ui
1854         checkbutton $w.postActions.checkout \
1855                 -text {Checkout after creation} \
1856                 -variable create_branch_checkout \
1857                 -font font_ui
1858         pack $w.postActions.checkout -anchor nw
1859         pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
1860
1861         bind $w <Visibility> "grab $w; focus $w.desc.name_t"
1862         bind $w <Key-Escape> "destroy $w"
1863         bind $w <Key-Return> "do_create_branch_action $w;break"
1864         wm title $w "[appname] ([reponame]): Create Branch"
1865         tkwait window $w
1866 }
1867
1868 proc do_delete_branch_action {w} {
1869         global all_heads
1870         global delete_branch_checktype delete_branch_head delete_branch_trackinghead
1871
1872         set check_rev {}
1873         switch -- $delete_branch_checktype {
1874         head {set check_rev $delete_branch_head}
1875         tracking {set check_rev $delete_branch_trackinghead}
1876         always {set check_rev {:none}}
1877         }
1878         if {$check_rev eq {:none}} {
1879                 set check_cmt {}
1880         } elseif {[catch {set check_cmt [exec git rev-parse --verify "${check_rev}^0"]}]} {
1881                 tk_messageBox \
1882                         -icon error \
1883                         -type ok \
1884                         -title [wm title $w] \
1885                         -parent $w \
1886                         -message "Invalid check revision: $check_rev"
1887                 return
1888         }
1889
1890         set to_delete [list]
1891         set not_merged [list]
1892         foreach i [$w.list.l curselection] {
1893                 set b [$w.list.l get $i]
1894                 if {[catch {set o [exec git rev-parse --verify $b]}]} continue
1895                 if {$check_cmt ne {}} {
1896                         if {$b eq $check_rev} continue
1897                         if {[catch {set m [exec git merge-base $o $check_cmt]}]} continue
1898                         if {$o ne $m} {
1899                                 lappend not_merged $b
1900                                 continue
1901                         }
1902                 }
1903                 lappend to_delete [list $b $o]
1904         }
1905         if {$not_merged ne {}} {
1906                 set msg "The following branches are not completely merged into $check_rev:
1907
1908  - [join $not_merged "\n - "]"
1909                 tk_messageBox \
1910                         -icon info \
1911                         -type ok \
1912                         -title [wm title $w] \
1913                         -parent $w \
1914                         -message $msg
1915         }
1916         if {$to_delete eq {}} return
1917         if {$delete_branch_checktype eq {always}} {
1918                 set msg {Recovering deleted branches is difficult.
1919
1920 Delete the selected branches?}
1921                 if {[tk_messageBox \
1922                         -icon warning \
1923                         -type yesno \
1924                         -title [wm title $w] \
1925                         -parent $w \
1926                         -message $msg] ne yes} {
1927                         return
1928                 }
1929         }
1930
1931         set failed {}
1932         foreach i $to_delete {
1933                 set b [lindex $i 0]
1934                 set o [lindex $i 1]
1935                 if {[catch {exec git update-ref -d "refs/heads/$b" $o} err]} {
1936                         append failed " - $b: $err\n"
1937                 } else {
1938                         set x [lsearch -sorted $all_heads $b]
1939                         if {$x >= 0} {
1940                                 set all_heads [lreplace $all_heads $x $x]
1941                         }
1942                 }
1943         }
1944
1945         if {$failed ne {}} {
1946                 tk_messageBox \
1947                         -icon error \
1948                         -type ok \
1949                         -title [wm title $w] \
1950                         -parent $w \
1951                         -message "Failed to delete branches:\n$failed"
1952         }
1953
1954         set all_heads [lsort $all_heads]
1955         populate_branch_menu
1956         destroy $w
1957 }
1958
1959 proc do_delete_branch {} {
1960         global all_heads tracking_branches current_branch
1961         global delete_branch_checktype delete_branch_head delete_branch_trackinghead
1962
1963         set delete_branch_checktype head
1964         set delete_branch_head $current_branch
1965         set delete_branch_trackinghead {}
1966
1967         set w .branch_editor
1968         toplevel $w
1969         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1970
1971         label $w.header -text {Delete Local Branch} \
1972                 -font font_uibold
1973         pack $w.header -side top -fill x
1974
1975         frame $w.buttons
1976         button $w.buttons.create -text Delete \
1977                 -font font_ui \
1978                 -command [list do_delete_branch_action $w]
1979         pack $w.buttons.create -side right
1980         button $w.buttons.cancel -text {Cancel} \
1981                 -font font_ui \
1982                 -command [list destroy $w]
1983         pack $w.buttons.cancel -side right -padx 5
1984         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1985
1986         labelframe $w.list \
1987                 -text {Local Branches} \
1988                 -font font_ui
1989         listbox $w.list.l \
1990                 -height 10 \
1991                 -width 50 \
1992                 -selectmode extended \
1993                 -font font_ui
1994         foreach h $all_heads {
1995                 if {$h ne $current_branch} {
1996                         $w.list.l insert end $h
1997                 }
1998         }
1999         pack $w.list.l -fill both -pady 5 -padx 5
2000         pack $w.list -fill both -pady 5 -padx 5
2001
2002         set all_trackings [list]
2003         foreach b [array names tracking_branches] {
2004                 regsub ^refs/(heads|remotes)/ $b {} b
2005                 lappend all_trackings $b
2006         }
2007         set all_trackings [lsort -unique $all_trackings]
2008         if {$all_trackings ne {} && $delete_branch_trackinghead eq {}} {
2009                 set delete_branch_trackinghead [lindex $all_trackings 0]
2010         }
2011
2012         labelframe $w.validate \
2013                 -text {Delete Only If} \
2014                 -font font_ui
2015         radiobutton $w.validate.head_r \
2016                 -text {Merged Into Local Branch:} \
2017                 -value head \
2018                 -variable delete_branch_checktype \
2019                 -font font_ui
2020         eval tk_optionMenu $w.validate.head_m delete_branch_head $all_heads
2021         grid $w.validate.head_r $w.validate.head_m -sticky w
2022         radiobutton $w.validate.tracking_r \
2023                 -text {Merged Into Tracking Branch:} \
2024                 -value tracking \
2025                 -variable delete_branch_checktype \
2026                 -font font_ui
2027         eval tk_optionMenu $w.validate.tracking_m \
2028                 delete_branch_trackinghead \
2029                 $all_trackings
2030         grid $w.validate.tracking_r $w.validate.tracking_m -sticky w
2031         radiobutton $w.validate.always_r \
2032                 -text {Always (Do not perform merge checks)} \
2033                 -value always \
2034                 -variable delete_branch_checktype \
2035                 -font font_ui
2036         grid $w.validate.always_r -columnspan 2 -sticky w
2037         grid columnconfigure $w.validate 1 -weight 1
2038         pack $w.validate -anchor nw -fill x -pady 5 -padx 5
2039
2040         bind $w <Visibility> "grab $w; focus $w"
2041         bind $w <Key-Escape> "destroy $w"
2042         wm title $w "[appname] ([reponame]): Delete Branch"
2043         tkwait window $w
2044 }
2045
2046 proc switch_branch {b} {
2047         global HEAD commit_type file_states current_branch
2048         global selected_commit_type ui_comm
2049
2050         if {![lock_index switch]} return
2051
2052         # -- Backup the selected branch (repository_state resets it)
2053         #
2054         set new_branch $current_branch
2055
2056         # -- Our in memory state should match the repository.
2057         #
2058         repository_state curType curHEAD curMERGE_HEAD
2059         if {[string match amend* $commit_type]
2060                 && $curType eq {normal}
2061                 && $curHEAD eq $HEAD} {
2062         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
2063                 info_popup {Last scanned state does not match repository state.
2064
2065 Another Git program has modified this repository
2066 since the last scan.  A rescan must be performed
2067 before the current branch can be changed.
2068
2069 The rescan will be automatically started now.
2070 }
2071                 unlock_index
2072                 rescan {set ui_status_value {Ready.}}
2073                 return
2074         }
2075
2076         # -- Toss the message buffer if we are in amend mode.
2077         #
2078         if {[string match amend* $curType]} {
2079                 $ui_comm delete 0.0 end
2080                 $ui_comm edit reset
2081                 $ui_comm edit modified false
2082         }
2083
2084         set selected_commit_type new
2085         set current_branch $new_branch
2086
2087         unlock_index
2088         error "NOT FINISHED"
2089 }
2090
2091 ######################################################################
2092 ##
2093 ## remote management
2094
2095 proc load_all_remotes {} {
2096         global repo_config
2097         global all_remotes tracking_branches
2098
2099         set all_remotes [list]
2100         array unset tracking_branches
2101
2102         set rm_dir [gitdir remotes]
2103         if {[file isdirectory $rm_dir]} {
2104                 set all_remotes [glob \
2105                         -types f \
2106                         -tails \
2107                         -nocomplain \
2108                         -directory $rm_dir *]
2109
2110                 foreach name $all_remotes {
2111                         catch {
2112                                 set fd [open [file join $rm_dir $name] r]
2113                                 while {[gets $fd line] >= 0} {
2114                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
2115                                                 $line line src dst]} continue
2116                                         if {![regexp ^refs/ $dst]} {
2117                                                 set dst "refs/heads/$dst"
2118                                         }
2119                                         set tracking_branches($dst) [list $name $src]
2120                                 }
2121                                 close $fd
2122                         }
2123                 }
2124         }
2125
2126         foreach line [array names repo_config remote.*.url] {
2127                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
2128                 lappend all_remotes $name
2129
2130                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
2131                         set fl {}
2132                 }
2133                 foreach line $fl {
2134                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
2135                         if {![regexp ^refs/ $dst]} {
2136                                 set dst "refs/heads/$dst"
2137                         }
2138                         set tracking_branches($dst) [list $name $src]
2139                 }
2140         }
2141
2142         set all_remotes [lsort -unique $all_remotes]
2143 }
2144
2145 proc populate_fetch_menu {m} {
2146         global all_remotes repo_config
2147
2148         foreach r $all_remotes {
2149                 set enable 0
2150                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2151                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
2152                                 set enable 1
2153                         }
2154                 } else {
2155                         catch {
2156                                 set fd [open [gitdir remotes $r] r]
2157                                 while {[gets $fd n] >= 0} {
2158                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
2159                                                 set enable 1
2160                                                 break
2161                                         }
2162                                 }
2163                                 close $fd
2164                         }
2165                 }
2166
2167                 if {$enable} {
2168                         $m add command \
2169                                 -label "Fetch from $r..." \
2170                                 -command [list fetch_from $r] \
2171                                 -font font_ui
2172                 }
2173         }
2174 }
2175
2176 proc populate_push_menu {m} {
2177         global all_remotes repo_config
2178
2179         foreach r $all_remotes {
2180                 set enable 0
2181                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2182                         if {![catch {set a $repo_config(remote.$r.push)}]} {
2183                                 set enable 1
2184                         }
2185                 } else {
2186                         catch {
2187                                 set fd [open [gitdir remotes $r] r]
2188                                 while {[gets $fd n] >= 0} {
2189                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
2190                                                 set enable 1
2191                                                 break
2192                                         }
2193                                 }
2194                                 close $fd
2195                         }
2196                 }
2197
2198                 if {$enable} {
2199                         $m add command \
2200                                 -label "Push to $r..." \
2201                                 -command [list push_to $r] \
2202                                 -font font_ui
2203                 }
2204         }
2205 }
2206
2207 proc populate_pull_menu {m} {
2208         global repo_config all_remotes disable_on_lock
2209
2210         foreach remote $all_remotes {
2211                 set rb_list [list]
2212                 if {[array get repo_config remote.$remote.url] ne {}} {
2213                         if {[array get repo_config remote.$remote.fetch] ne {}} {
2214                                 foreach line $repo_config(remote.$remote.fetch) {
2215                                         if {[regexp {^([^:]+):} $line line rb]} {
2216                                                 lappend rb_list $rb
2217                                         }
2218                                 }
2219                         }
2220                 } else {
2221                         catch {
2222                                 set fd [open [gitdir remotes $remote] r]
2223                                 while {[gets $fd line] >= 0} {
2224                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
2225                                                 lappend rb_list $rb
2226                                         }
2227                                 }
2228                                 close $fd
2229                         }
2230                 }
2231
2232                 foreach rb $rb_list {
2233                         regsub ^refs/heads/ $rb {} rb_short
2234                         $m add command \
2235                                 -label "Branch $rb_short from $remote..." \
2236                                 -command [list pull_remote $remote $rb] \
2237                                 -font font_ui
2238                         lappend disable_on_lock \
2239                                 [list $m entryconf [$m index last] -state]
2240                 }
2241         }
2242 }
2243
2244 ######################################################################
2245 ##
2246 ## icons
2247
2248 set filemask {
2249 #define mask_width 14
2250 #define mask_height 15
2251 static unsigned char mask_bits[] = {
2252    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2253    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2254    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2255 }
2256
2257 image create bitmap file_plain -background white -foreground black -data {
2258 #define plain_width 14
2259 #define plain_height 15
2260 static unsigned char plain_bits[] = {
2261    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2262    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2263    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2264 } -maskdata $filemask
2265
2266 image create bitmap file_mod -background white -foreground blue -data {
2267 #define mod_width 14
2268 #define mod_height 15
2269 static unsigned char mod_bits[] = {
2270    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2271    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2272    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2273 } -maskdata $filemask
2274
2275 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2276 #define file_fulltick_width 14
2277 #define file_fulltick_height 15
2278 static unsigned char file_fulltick_bits[] = {
2279    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2280    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2281    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2282 } -maskdata $filemask
2283
2284 image create bitmap file_parttick -background white -foreground "#005050" -data {
2285 #define parttick_width 14
2286 #define parttick_height 15
2287 static unsigned char parttick_bits[] = {
2288    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2289    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
2290    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2291 } -maskdata $filemask
2292
2293 image create bitmap file_question -background white -foreground black -data {
2294 #define file_question_width 14
2295 #define file_question_height 15
2296 static unsigned char file_question_bits[] = {
2297    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2298    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2299    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2300 } -maskdata $filemask
2301
2302 image create bitmap file_removed -background white -foreground red -data {
2303 #define file_removed_width 14
2304 #define file_removed_height 15
2305 static unsigned char file_removed_bits[] = {
2306    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2307    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2308    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2309 } -maskdata $filemask
2310
2311 image create bitmap file_merge -background white -foreground blue -data {
2312 #define file_merge_width 14
2313 #define file_merge_height 15
2314 static unsigned char file_merge_bits[] = {
2315    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2316    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2317    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2318 } -maskdata $filemask
2319
2320 set ui_index .vpane.files.index.list
2321 set ui_workdir .vpane.files.workdir.list
2322
2323 set all_icons(_$ui_index)   file_plain
2324 set all_icons(A$ui_index)   file_fulltick
2325 set all_icons(M$ui_index)   file_fulltick
2326 set all_icons(D$ui_index)   file_removed
2327 set all_icons(U$ui_index)   file_merge
2328
2329 set all_icons(_$ui_workdir) file_plain
2330 set all_icons(M$ui_workdir) file_mod
2331 set all_icons(D$ui_workdir) file_question
2332 set all_icons(U$ui_workdir) file_merge
2333 set all_icons(O$ui_workdir) file_plain
2334
2335 set max_status_desc 0
2336 foreach i {
2337                 {__ "Unmodified"}
2338
2339                 {_M "Modified, not staged"}
2340                 {M_ "Staged for commit"}
2341                 {MM "Portions staged for commit"}
2342                 {MD "Staged for commit, missing"}
2343
2344                 {_O "Untracked, not staged"}
2345                 {A_ "Staged for commit"}
2346                 {AM "Portions staged for commit"}
2347                 {AD "Staged for commit, missing"}
2348
2349                 {_D "Missing"}
2350                 {D_ "Staged for removal"}
2351                 {DO "Staged for removal, still present"}
2352
2353                 {U_ "Requires merge resolution"}
2354                 {UU "Requires merge resolution"}
2355                 {UM "Requires merge resolution"}
2356                 {UD "Requires merge resolution"}
2357         } {
2358         if {$max_status_desc < [string length [lindex $i 1]]} {
2359                 set max_status_desc [string length [lindex $i 1]]
2360         }
2361         set all_descs([lindex $i 0]) [lindex $i 1]
2362 }
2363 unset i
2364
2365 ######################################################################
2366 ##
2367 ## util
2368
2369 proc is_MacOSX {} {
2370         global tcl_platform tk_library
2371         if {[tk windowingsystem] eq {aqua}} {
2372                 return 1
2373         }
2374         return 0
2375 }
2376
2377 proc is_Windows {} {
2378         global tcl_platform
2379         if {$tcl_platform(platform) eq {windows}} {
2380                 return 1
2381         }
2382         return 0
2383 }
2384
2385 proc bind_button3 {w cmd} {
2386         bind $w <Any-Button-3> $cmd
2387         if {[is_MacOSX]} {
2388                 bind $w <Control-Button-1> $cmd
2389         }
2390 }
2391
2392 proc incr_font_size {font {amt 1}} {
2393         set sz [font configure $font -size]
2394         incr sz $amt
2395         font configure $font -size $sz
2396         font configure ${font}bold -size $sz
2397 }
2398
2399 proc hook_failed_popup {hook msg} {
2400         set w .hookfail
2401         toplevel $w
2402
2403         frame $w.m
2404         label $w.m.l1 -text "$hook hook failed:" \
2405                 -anchor w \
2406                 -justify left \
2407                 -font font_uibold
2408         text $w.m.t \
2409                 -background white -borderwidth 1 \
2410                 -relief sunken \
2411                 -width 80 -height 10 \
2412                 -font font_diff \
2413                 -yscrollcommand [list $w.m.sby set]
2414         label $w.m.l2 \
2415                 -text {You must correct the above errors before committing.} \
2416                 -anchor w \
2417                 -justify left \
2418                 -font font_uibold
2419         scrollbar $w.m.sby -command [list $w.m.t yview]
2420         pack $w.m.l1 -side top -fill x
2421         pack $w.m.l2 -side bottom -fill x
2422         pack $w.m.sby -side right -fill y
2423         pack $w.m.t -side left -fill both -expand 1
2424         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2425
2426         $w.m.t insert 1.0 $msg
2427         $w.m.t conf -state disabled
2428
2429         button $w.ok -text OK \
2430                 -width 15 \
2431                 -font font_ui \
2432                 -command "destroy $w"
2433         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2434
2435         bind $w <Visibility> "grab $w; focus $w"
2436         bind $w <Key-Return> "destroy $w"
2437         wm title $w "[appname] ([reponame]): error"
2438         tkwait window $w
2439 }
2440
2441 set next_console_id 0
2442
2443 proc new_console {short_title long_title} {
2444         global next_console_id console_data
2445         set w .console[incr next_console_id]
2446         set console_data($w) [list $short_title $long_title]
2447         return [console_init $w]
2448 }
2449
2450 proc console_init {w} {
2451         global console_cr console_data M1B
2452
2453         set console_cr($w) 1.0
2454         toplevel $w
2455         frame $w.m
2456         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2457                 -anchor w \
2458                 -justify left \
2459                 -font font_uibold
2460         text $w.m.t \
2461                 -background white -borderwidth 1 \
2462                 -relief sunken \
2463                 -width 80 -height 10 \
2464                 -font font_diff \
2465                 -state disabled \
2466                 -yscrollcommand [list $w.m.sby set]
2467         label $w.m.s -text {Working... please wait...} \
2468                 -anchor w \
2469                 -justify left \
2470                 -font font_uibold
2471         scrollbar $w.m.sby -command [list $w.m.t yview]
2472         pack $w.m.l1 -side top -fill x
2473         pack $w.m.s -side bottom -fill x
2474         pack $w.m.sby -side right -fill y
2475         pack $w.m.t -side left -fill both -expand 1
2476         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2477
2478         menu $w.ctxm -tearoff 0
2479         $w.ctxm add command -label "Copy" \
2480                 -font font_ui \
2481                 -command "tk_textCopy $w.m.t"
2482         $w.ctxm add command -label "Select All" \
2483                 -font font_ui \
2484                 -command "$w.m.t tag add sel 0.0 end"
2485         $w.ctxm add command -label "Copy All" \
2486                 -font font_ui \
2487                 -command "
2488                         $w.m.t tag add sel 0.0 end
2489                         tk_textCopy $w.m.t
2490                         $w.m.t tag remove sel 0.0 end
2491                 "
2492
2493         button $w.ok -text {Close} \
2494                 -font font_ui \
2495                 -state disabled \
2496                 -command "destroy $w"
2497         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2498
2499         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2500         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2501         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2502         bind $w <Visibility> "focus $w"
2503         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
2504         return $w
2505 }
2506
2507 proc console_exec {w cmd {after {}}} {
2508         # -- Windows tosses the enviroment when we exec our child.
2509         #    But most users need that so we have to relogin. :-(
2510         #
2511         if {[is_Windows]} {
2512                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2513         }
2514
2515         # -- Tcl won't let us redirect both stdout and stderr to
2516         #    the same pipe.  So pass it through cat...
2517         #
2518         set cmd [concat | $cmd |& cat]
2519
2520         set fd_f [open $cmd r]
2521         fconfigure $fd_f -blocking 0 -translation binary
2522         fileevent $fd_f readable [list console_read $w $fd_f $after]
2523 }
2524
2525 proc console_read {w fd after} {
2526         global console_cr console_data
2527
2528         set buf [read $fd]
2529         if {$buf ne {}} {
2530                 if {![winfo exists $w]} {console_init $w}
2531                 $w.m.t conf -state normal
2532                 set c 0
2533                 set n [string length $buf]
2534                 while {$c < $n} {
2535                         set cr [string first "\r" $buf $c]
2536                         set lf [string first "\n" $buf $c]
2537                         if {$cr < 0} {set cr [expr {$n + 1}]}
2538                         if {$lf < 0} {set lf [expr {$n + 1}]}
2539
2540                         if {$lf < $cr} {
2541                                 $w.m.t insert end [string range $buf $c $lf]
2542                                 set console_cr($w) [$w.m.t index {end -1c}]
2543                                 set c $lf
2544                                 incr c
2545                         } else {
2546                                 $w.m.t delete $console_cr($w) end
2547                                 $w.m.t insert end "\n"
2548                                 $w.m.t insert end [string range $buf $c $cr]
2549                                 set c $cr
2550                                 incr c
2551                         }
2552                 }
2553                 $w.m.t conf -state disabled
2554                 $w.m.t see end
2555         }
2556
2557         fconfigure $fd -blocking 1
2558         if {[eof $fd]} {
2559                 if {[catch {close $fd}]} {
2560                         if {![winfo exists $w]} {console_init $w}
2561                         $w.m.s conf -background red -text {Error: Command Failed}
2562                         $w.ok conf -state normal
2563                         set ok 0
2564                 } elseif {[winfo exists $w]} {
2565                         $w.m.s conf -background green -text {Success}
2566                         $w.ok conf -state normal
2567                         set ok 1
2568                 }
2569                 array unset console_cr $w
2570                 array unset console_data $w
2571                 if {$after ne {}} {
2572                         uplevel #0 $after $ok
2573                 }
2574                 return
2575         }
2576         fconfigure $fd -blocking 0
2577 }
2578
2579 ######################################################################
2580 ##
2581 ## ui commands
2582
2583 set starting_gitk_msg {Starting gitk... please wait...}
2584
2585 proc do_gitk {revs} {
2586         global ui_status_value starting_gitk_msg
2587
2588         set cmd gitk
2589         if {$revs ne {}} {
2590                 append cmd { }
2591                 append cmd $revs
2592         }
2593         if {[is_Windows]} {
2594                 set cmd "sh -c \"exec $cmd\""
2595         }
2596         append cmd { &}
2597
2598         if {[catch {eval exec $cmd} err]} {
2599                 error_popup "Failed to start gitk:\n\n$err"
2600         } else {
2601                 set ui_status_value $starting_gitk_msg
2602                 after 10000 {
2603                         if {$ui_status_value eq $starting_gitk_msg} {
2604                                 set ui_status_value {Ready.}
2605                         }
2606                 }
2607         }
2608 }
2609
2610 proc do_gc {} {
2611         set w [new_console {gc} {Compressing the object database}]
2612         console_exec $w {git gc}
2613 }
2614
2615 proc do_fsck_objects {} {
2616         set w [new_console {fsck-objects} \
2617                 {Verifying the object database with fsck-objects}]
2618         set cmd [list git fsck-objects]
2619         lappend cmd --full
2620         lappend cmd --cache
2621         lappend cmd --strict
2622         console_exec $w $cmd
2623 }
2624
2625 set is_quitting 0
2626
2627 proc do_quit {} {
2628         global ui_comm is_quitting repo_config commit_type
2629
2630         if {$is_quitting} return
2631         set is_quitting 1
2632
2633         # -- Stash our current commit buffer.
2634         #
2635         set save [gitdir GITGUI_MSG]
2636         set msg [string trim [$ui_comm get 0.0 end]]
2637         if {![string match amend* $commit_type]
2638                 && [$ui_comm edit modified]
2639                 && $msg ne {}} {
2640                 catch {
2641                         set fd [open $save w]
2642                         puts $fd [string trim [$ui_comm get 0.0 end]]
2643                         close $fd
2644                 }
2645         } else {
2646                 catch {file delete $save}
2647         }
2648
2649         # -- Stash our current window geometry into this repository.
2650         #
2651         set cfg_geometry [list]
2652         lappend cfg_geometry [wm geometry .]
2653         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2654         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2655         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2656                 set rc_geometry {}
2657         }
2658         if {$cfg_geometry ne $rc_geometry} {
2659                 catch {exec git repo-config gui.geometry $cfg_geometry}
2660         }
2661
2662         destroy .
2663 }
2664
2665 proc do_rescan {} {
2666         rescan {set ui_status_value {Ready.}}
2667 }
2668
2669 proc unstage_helper {txt paths} {
2670         global file_states current_diff_path
2671
2672         if {![lock_index begin-update]} return
2673
2674         set pathList [list]
2675         set after {}
2676         foreach path $paths {
2677                 switch -glob -- [lindex $file_states($path) 0] {
2678                 A? -
2679                 M? -
2680                 D? {
2681                         lappend pathList $path
2682                         if {$path eq $current_diff_path} {
2683                                 set after {reshow_diff;}
2684                         }
2685                 }
2686                 }
2687         }
2688         if {$pathList eq {}} {
2689                 unlock_index
2690         } else {
2691                 update_indexinfo \
2692                         $txt \
2693                         $pathList \
2694                         [concat $after {set ui_status_value {Ready.}}]
2695         }
2696 }
2697
2698 proc do_unstage_selection {} {
2699         global current_diff_path selected_paths
2700
2701         if {[array size selected_paths] > 0} {
2702                 unstage_helper \
2703                         {Unstaging selected files from commit} \
2704                         [array names selected_paths]
2705         } elseif {$current_diff_path ne {}} {
2706                 unstage_helper \
2707                         "Unstaging [short_path $current_diff_path] from commit" \
2708                         [list $current_diff_path]
2709         }
2710 }
2711
2712 proc add_helper {txt paths} {
2713         global file_states current_diff_path
2714
2715         if {![lock_index begin-update]} return
2716
2717         set pathList [list]
2718         set after {}
2719         foreach path $paths {
2720                 switch -glob -- [lindex $file_states($path) 0] {
2721                 _O -
2722                 ?M -
2723                 ?D -
2724                 U? {
2725                         lappend pathList $path
2726                         if {$path eq $current_diff_path} {
2727                                 set after {reshow_diff;}
2728                         }
2729                 }
2730                 }
2731         }
2732         if {$pathList eq {}} {
2733                 unlock_index
2734         } else {
2735                 update_index \
2736                         $txt \
2737                         $pathList \
2738                         [concat $after {set ui_status_value {Ready to commit.}}]
2739         }
2740 }
2741
2742 proc do_add_selection {} {
2743         global current_diff_path selected_paths
2744
2745         if {[array size selected_paths] > 0} {
2746                 add_helper \
2747                         {Adding selected files} \
2748                         [array names selected_paths]
2749         } elseif {$current_diff_path ne {}} {
2750                 add_helper \
2751                         "Adding [short_path $current_diff_path]" \
2752                         [list $current_diff_path]
2753         }
2754 }
2755
2756 proc do_add_all {} {
2757         global file_states
2758
2759         set paths [list]
2760         foreach path [array names file_states] {
2761                 switch -glob -- [lindex $file_states($path) 0] {
2762                 U? {continue}
2763                 ?M -
2764                 ?D {lappend paths $path}
2765                 }
2766         }
2767         add_helper {Adding all changed files} $paths
2768 }
2769
2770 proc revert_helper {txt paths} {
2771         global file_states current_diff_path
2772
2773         if {![lock_index begin-update]} return
2774
2775         set pathList [list]
2776         set after {}
2777         foreach path $paths {
2778                 switch -glob -- [lindex $file_states($path) 0] {
2779                 U? {continue}
2780                 ?M -
2781                 ?D {
2782                         lappend pathList $path
2783                         if {$path eq $current_diff_path} {
2784                                 set after {reshow_diff;}
2785                         }
2786                 }
2787                 }
2788         }
2789
2790         set n [llength $pathList]
2791         if {$n == 0} {
2792                 unlock_index
2793                 return
2794         } elseif {$n == 1} {
2795                 set s "[short_path [lindex $pathList]]"
2796         } else {
2797                 set s "these $n files"
2798         }
2799
2800         set reply [tk_dialog \
2801                 .confirm_revert \
2802                 "[appname] ([reponame])" \
2803                 "Revert changes in $s?
2804
2805 Any unadded changes will be permanently lost by the revert." \
2806                 question \
2807                 1 \
2808                 {Do Nothing} \
2809                 {Revert Changes} \
2810                 ]
2811         if {$reply == 1} {
2812                 checkout_index \
2813                         $txt \
2814                         $pathList \
2815                         [concat $after {set ui_status_value {Ready.}}]
2816         } else {
2817                 unlock_index
2818         }
2819 }
2820
2821 proc do_revert_selection {} {
2822         global current_diff_path selected_paths
2823
2824         if {[array size selected_paths] > 0} {
2825                 revert_helper \
2826                         {Reverting selected files} \
2827                         [array names selected_paths]
2828         } elseif {$current_diff_path ne {}} {
2829                 revert_helper \
2830                         "Reverting [short_path $current_diff_path]" \
2831                         [list $current_diff_path]
2832         }
2833 }
2834
2835 proc do_signoff {} {
2836         global ui_comm
2837
2838         set me [committer_ident]
2839         if {$me eq {}} return
2840
2841         set sob "Signed-off-by: $me"
2842         set last [$ui_comm get {end -1c linestart} {end -1c}]
2843         if {$last ne $sob} {
2844                 $ui_comm edit separator
2845                 if {$last ne {}
2846                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2847                         $ui_comm insert end "\n"
2848                 }
2849                 $ui_comm insert end "\n$sob"
2850                 $ui_comm edit separator
2851                 $ui_comm see end
2852         }
2853 }
2854
2855 proc do_select_commit_type {} {
2856         global commit_type selected_commit_type
2857
2858         if {$selected_commit_type eq {new}
2859                 && [string match amend* $commit_type]} {
2860                 create_new_commit
2861         } elseif {$selected_commit_type eq {amend}
2862                 && ![string match amend* $commit_type]} {
2863                 load_last_commit
2864
2865                 # The amend request was rejected...
2866                 #
2867                 if {![string match amend* $commit_type]} {
2868                         set selected_commit_type new
2869                 }
2870         }
2871 }
2872
2873 proc do_commit {} {
2874         commit_tree
2875 }
2876
2877 proc do_about {} {
2878         global appvers copyright
2879         global tcl_patchLevel tk_patchLevel
2880
2881         set w .about_dialog
2882         toplevel $w
2883         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2884
2885         label $w.header -text "About [appname]" \
2886                 -font font_uibold
2887         pack $w.header -side top -fill x
2888
2889         frame $w.buttons
2890         button $w.buttons.close -text {Close} \
2891                 -font font_ui \
2892                 -command [list destroy $w]
2893         pack $w.buttons.close -side right
2894         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2895
2896         label $w.desc \
2897                 -text "[appname] - a commit creation tool for Git.
2898 $copyright" \
2899                 -padx 5 -pady 5 \
2900                 -justify left \
2901                 -anchor w \
2902                 -borderwidth 1 \
2903                 -relief solid \
2904                 -font font_ui
2905         pack $w.desc -side top -fill x -padx 5 -pady 5
2906
2907         set v {}
2908         append v "[appname] version $appvers\n"
2909         append v "[exec git version]\n"
2910         append v "\n"
2911         if {$tcl_patchLevel eq $tk_patchLevel} {
2912                 append v "Tcl/Tk version $tcl_patchLevel"
2913         } else {
2914                 append v "Tcl version $tcl_patchLevel"
2915                 append v ", Tk version $tk_patchLevel"
2916         }
2917
2918         label $w.vers \
2919                 -text $v \
2920                 -padx 5 -pady 5 \
2921                 -justify left \
2922                 -anchor w \
2923                 -borderwidth 1 \
2924                 -relief solid \
2925                 -font font_ui
2926         pack $w.vers -side top -fill x -padx 5 -pady 5
2927
2928         menu $w.ctxm -tearoff 0
2929         $w.ctxm add command \
2930                 -label {Copy} \
2931                 -font font_ui \
2932                 -command "
2933                 clipboard clear
2934                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
2935         "
2936
2937         bind $w <Visibility> "grab $w; focus $w"
2938         bind $w <Key-Escape> "destroy $w"
2939         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
2940         wm title $w "About [appname]"
2941         tkwait window $w
2942 }
2943
2944 proc do_options {} {
2945         global repo_config global_config font_descs
2946         global repo_config_new global_config_new
2947
2948         array unset repo_config_new
2949         array unset global_config_new
2950         foreach name [array names repo_config] {
2951                 set repo_config_new($name) $repo_config($name)
2952         }
2953         load_config 1
2954         foreach name [array names repo_config] {
2955                 switch -- $name {
2956                 gui.diffcontext {continue}
2957                 }
2958                 set repo_config_new($name) $repo_config($name)
2959         }
2960         foreach name [array names global_config] {
2961                 set global_config_new($name) $global_config($name)
2962         }
2963
2964         set w .options_editor
2965         toplevel $w
2966         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2967
2968         label $w.header -text "[appname] Options" \
2969                 -font font_uibold
2970         pack $w.header -side top -fill x
2971
2972         frame $w.buttons
2973         button $w.buttons.restore -text {Restore Defaults} \
2974                 -font font_ui \
2975                 -command do_restore_defaults
2976         pack $w.buttons.restore -side left
2977         button $w.buttons.save -text Save \
2978                 -font font_ui \
2979                 -command [list do_save_config $w]
2980         pack $w.buttons.save -side right
2981         button $w.buttons.cancel -text {Cancel} \
2982                 -font font_ui \
2983                 -command [list destroy $w]
2984         pack $w.buttons.cancel -side right -padx 5
2985         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2986
2987         labelframe $w.repo -text "[reponame] Repository" \
2988                 -font font_ui \
2989                 -relief raised -borderwidth 2
2990         labelframe $w.global -text {Global (All Repositories)} \
2991                 -font font_ui \
2992                 -relief raised -borderwidth 2
2993         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2994         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2995
2996         foreach option {
2997                 {b pullsummary {Show Pull Summary}}
2998                 {b trustmtime  {Trust File Modification Timestamps}}
2999                 {i diffcontext {Number of Diff Context Lines}}
3000                 } {
3001                 set type [lindex $option 0]
3002                 set name [lindex $option 1]
3003                 set text [lindex $option 2]
3004                 foreach f {repo global} {
3005                         switch $type {
3006                         b {
3007                                 checkbutton $w.$f.$name -text $text \
3008                                         -variable ${f}_config_new(gui.$name) \
3009                                         -onvalue true \
3010                                         -offvalue false \
3011                                         -font font_ui
3012                                 pack $w.$f.$name -side top -anchor w
3013                         }
3014                         i {
3015                                 frame $w.$f.$name
3016                                 label $w.$f.$name.l -text "$text:" -font font_ui
3017                                 pack $w.$f.$name.l -side left -anchor w -fill x
3018                                 spinbox $w.$f.$name.v \
3019                                         -textvariable ${f}_config_new(gui.$name) \
3020                                         -from 1 -to 99 -increment 1 \
3021                                         -width 3 \
3022                                         -font font_ui
3023                                 pack $w.$f.$name.v -side right -anchor e
3024                                 pack $w.$f.$name -side top -anchor w -fill x
3025                         }
3026                         }
3027                 }
3028         }
3029
3030         set all_fonts [lsort [font families]]
3031         foreach option $font_descs {
3032                 set name [lindex $option 0]
3033                 set font [lindex $option 1]
3034                 set text [lindex $option 2]
3035
3036                 set global_config_new(gui.$font^^family) \
3037                         [font configure $font -family]
3038                 set global_config_new(gui.$font^^size) \
3039                         [font configure $font -size]
3040
3041                 frame $w.global.$name
3042                 label $w.global.$name.l -text "$text:" -font font_ui
3043                 pack $w.global.$name.l -side left -anchor w -fill x
3044                 eval tk_optionMenu $w.global.$name.family \
3045                         global_config_new(gui.$font^^family) \
3046                         $all_fonts
3047                 spinbox $w.global.$name.size \
3048                         -textvariable global_config_new(gui.$font^^size) \
3049                         -from 2 -to 80 -increment 1 \
3050                         -width 3 \
3051                         -font font_ui
3052                 pack $w.global.$name.size -side right -anchor e
3053                 pack $w.global.$name.family -side right -anchor e
3054                 pack $w.global.$name -side top -anchor w -fill x
3055         }
3056
3057         bind $w <Visibility> "grab $w; focus $w"
3058         bind $w <Key-Escape> "destroy $w"
3059         wm title $w "[appname] ([reponame]): Options"
3060         tkwait window $w
3061 }
3062
3063 proc do_restore_defaults {} {
3064         global font_descs default_config repo_config
3065         global repo_config_new global_config_new
3066
3067         foreach name [array names default_config] {
3068                 set repo_config_new($name) $default_config($name)
3069                 set global_config_new($name) $default_config($name)
3070         }
3071
3072         foreach option $font_descs {
3073                 set name [lindex $option 0]
3074                 set repo_config(gui.$name) $default_config(gui.$name)
3075         }
3076         apply_config
3077
3078         foreach option $font_descs {
3079                 set name [lindex $option 0]
3080                 set font [lindex $option 1]
3081                 set global_config_new(gui.$font^^family) \
3082                         [font configure $font -family]
3083                 set global_config_new(gui.$font^^size) \
3084                         [font configure $font -size]
3085         }
3086 }
3087
3088 proc do_save_config {w} {
3089         if {[catch {save_config} err]} {
3090                 error_popup "Failed to completely save options:\n\n$err"
3091         }
3092         reshow_diff
3093         destroy $w
3094 }
3095
3096 proc do_windows_shortcut {} {
3097         global argv0
3098
3099         if {[catch {
3100                 set desktop [exec cygpath \
3101                         --windows \
3102                         --absolute \
3103                         --long-name \
3104                         --desktop]
3105                 }]} {
3106                         set desktop .
3107         }
3108         set fn [tk_getSaveFile \
3109                 -parent . \
3110                 -title "[appname] ([reponame]): Create Desktop Icon" \
3111                 -initialdir $desktop \
3112                 -initialfile "Git [reponame].bat"]
3113         if {$fn != {}} {
3114                 if {[catch {
3115                                 set fd [open $fn w]
3116                                 set sh [exec cygpath \
3117                                         --windows \
3118                                         --absolute \
3119                                         /bin/sh]
3120                                 set me [exec cygpath \
3121                                         --unix \
3122                                         --absolute \
3123                                         $argv0]
3124                                 set gd [exec cygpath \
3125                                         --unix \
3126                                         --absolute \
3127                                         [gitdir]]
3128                                 set gw [exec cygpath \
3129                                         --windows \
3130                                         --absolute \
3131                                         [file dirname [gitdir]]]
3132                                 regsub -all ' $me "'\\''" me
3133                                 regsub -all ' $gd "'\\''" gd
3134                                 puts $fd "@ECHO Entering $gw"
3135                                 puts $fd "@ECHO Starting git-gui... please wait..."
3136                                 puts -nonewline $fd "@\"$sh\" --login -c \""
3137                                 puts -nonewline $fd "GIT_DIR='$gd'"
3138                                 puts -nonewline $fd " '$me'"
3139                                 puts $fd "&\""
3140                                 close $fd
3141                         } err]} {
3142                         error_popup "Cannot write script:\n\n$err"
3143                 }
3144         }
3145 }
3146
3147 proc do_macosx_app {} {
3148         global argv0 env
3149
3150         set fn [tk_getSaveFile \
3151                 -parent . \
3152                 -title "[appname] ([reponame]): Create Desktop Icon" \
3153                 -initialdir [file join $env(HOME) Desktop] \
3154                 -initialfile "Git [reponame].app"]
3155         if {$fn != {}} {
3156                 if {[catch {
3157                                 set Contents [file join $fn Contents]
3158                                 set MacOS [file join $Contents MacOS]
3159                                 set exe [file join $MacOS git-gui]
3160
3161                                 file mkdir $MacOS
3162
3163                                 set fd [open [file join $Contents Info.plist] w]
3164                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
3165 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
3166 <plist version="1.0">
3167 <dict>
3168         <key>CFBundleDevelopmentRegion</key>
3169         <string>English</string>
3170         <key>CFBundleExecutable</key>
3171         <string>git-gui</string>
3172         <key>CFBundleIdentifier</key>
3173         <string>org.spearce.git-gui</string>
3174         <key>CFBundleInfoDictionaryVersion</key>
3175         <string>6.0</string>
3176         <key>CFBundlePackageType</key>
3177         <string>APPL</string>
3178         <key>CFBundleSignature</key>
3179         <string>????</string>
3180         <key>CFBundleVersion</key>
3181         <string>1.0</string>
3182         <key>NSPrincipalClass</key>
3183         <string>NSApplication</string>
3184 </dict>
3185 </plist>}
3186                                 close $fd
3187
3188                                 set fd [open $exe w]
3189                                 set gd [file normalize [gitdir]]
3190                                 set ep [file normalize [exec git --exec-path]]
3191                                 regsub -all ' $gd "'\\''" gd
3192                                 regsub -all ' $ep "'\\''" ep
3193                                 puts $fd "#!/bin/sh"
3194                                 foreach name [array names env] {
3195                                         if {[string match GIT_* $name]} {
3196                                                 regsub -all ' $env($name) "'\\''" v
3197                                                 puts $fd "export $name='$v'"
3198                                         }
3199                                 }
3200                                 puts $fd "export PATH='$ep':\$PATH"
3201                                 puts $fd "export GIT_DIR='$gd'"
3202                                 puts $fd "exec [file normalize $argv0]"
3203                                 close $fd
3204
3205                                 file attributes $exe -permissions u+x,g+x,o+x
3206                         } err]} {
3207                         error_popup "Cannot write icon:\n\n$err"
3208                 }
3209         }
3210 }
3211
3212 proc toggle_or_diff {w x y} {
3213         global file_states file_lists current_diff_path ui_index ui_workdir
3214         global last_clicked selected_paths
3215
3216         set pos [split [$w index @$x,$y] .]
3217         set lno [lindex $pos 0]
3218         set col [lindex $pos 1]
3219         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3220         if {$path eq {}} {
3221                 set last_clicked {}
3222                 return
3223         }
3224
3225         set last_clicked [list $w $lno]
3226         array unset selected_paths
3227         $ui_index tag remove in_sel 0.0 end
3228         $ui_workdir tag remove in_sel 0.0 end
3229
3230         if {$col == 0} {
3231                 if {$current_diff_path eq $path} {
3232                         set after {reshow_diff;}
3233                 } else {
3234                         set after {}
3235                 }
3236                 if {$w eq $ui_index} {
3237                         update_indexinfo \
3238                                 "Unstaging [short_path $path] from commit" \
3239                                 [list $path] \
3240                                 [concat $after {set ui_status_value {Ready.}}]
3241                 } elseif {$w eq $ui_workdir} {
3242                         update_index \
3243                                 "Adding [short_path $path]" \
3244                                 [list $path] \
3245                                 [concat $after {set ui_status_value {Ready.}}]
3246                 }
3247         } else {
3248                 show_diff $path $w $lno
3249         }
3250 }
3251
3252 proc add_one_to_selection {w x y} {
3253         global file_lists last_clicked selected_paths
3254
3255         set lno [lindex [split [$w index @$x,$y] .] 0]
3256         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3257         if {$path eq {}} {
3258                 set last_clicked {}
3259                 return
3260         }
3261
3262         if {$last_clicked ne {}
3263                 && [lindex $last_clicked 0] ne $w} {
3264                 array unset selected_paths
3265                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
3266         }
3267
3268         set last_clicked [list $w $lno]
3269         if {[catch {set in_sel $selected_paths($path)}]} {
3270                 set in_sel 0
3271         }
3272         if {$in_sel} {
3273                 unset selected_paths($path)
3274                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
3275         } else {
3276                 set selected_paths($path) 1
3277                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
3278         }
3279 }
3280
3281 proc add_range_to_selection {w x y} {
3282         global file_lists last_clicked selected_paths
3283
3284         if {[lindex $last_clicked 0] ne $w} {
3285                 toggle_or_diff $w $x $y
3286                 return
3287         }
3288
3289         set lno [lindex [split [$w index @$x,$y] .] 0]
3290         set lc [lindex $last_clicked 1]
3291         if {$lc < $lno} {
3292                 set begin $lc
3293                 set end $lno
3294         } else {
3295                 set begin $lno
3296                 set end $lc
3297         }
3298
3299         foreach path [lrange $file_lists($w) \
3300                 [expr {$begin - 1}] \
3301                 [expr {$end - 1}]] {
3302                 set selected_paths($path) 1
3303         }
3304         $w tag add in_sel $begin.0 [expr {$end + 1}].0
3305 }
3306
3307 ######################################################################
3308 ##
3309 ## config defaults
3310
3311 set cursor_ptr arrow
3312 font create font_diff -family Courier -size 10
3313 font create font_ui
3314 catch {
3315         label .dummy
3316         eval font configure font_ui [font actual [.dummy cget -font]]
3317         destroy .dummy
3318 }
3319
3320 font create font_uibold
3321 font create font_diffbold
3322
3323 if {[is_Windows]} {
3324         set M1B Control
3325         set M1T Ctrl
3326 } elseif {[is_MacOSX]} {
3327         set M1B M1
3328         set M1T Cmd
3329 } else {
3330         set M1B M1
3331         set M1T M1
3332 }
3333
3334 proc apply_config {} {
3335         global repo_config font_descs
3336
3337         foreach option $font_descs {
3338                 set name [lindex $option 0]
3339                 set font [lindex $option 1]
3340                 if {[catch {
3341                         foreach {cn cv} $repo_config(gui.$name) {
3342                                 font configure $font $cn $cv
3343                         }
3344                         } err]} {
3345                         error_popup "Invalid font specified in gui.$name:\n\n$err"
3346                 }
3347                 foreach {cn cv} [font configure $font] {
3348                         font configure ${font}bold $cn $cv
3349                 }
3350                 font configure ${font}bold -weight bold
3351         }
3352 }
3353
3354 set default_config(gui.trustmtime) false
3355 set default_config(gui.pullsummary) true
3356 set default_config(gui.diffcontext) 5
3357 set default_config(gui.fontui) [font configure font_ui]
3358 set default_config(gui.fontdiff) [font configure font_diff]
3359 set font_descs {
3360         {fontui   font_ui   {Main Font}}
3361         {fontdiff font_diff {Diff/Console Font}}
3362 }
3363 load_config 0
3364 apply_config
3365
3366 ######################################################################
3367 ##
3368 ## ui construction
3369
3370 # -- Menu Bar
3371 #
3372 menu .mbar -tearoff 0
3373 .mbar add cascade -label Repository -menu .mbar.repository
3374 .mbar add cascade -label Edit -menu .mbar.edit
3375 if {!$single_commit} {
3376         .mbar add cascade -label Branch -menu .mbar.branch
3377 }
3378 .mbar add cascade -label Commit -menu .mbar.commit
3379 if {!$single_commit} {
3380         .mbar add cascade -label Fetch -menu .mbar.fetch
3381         .mbar add cascade -label Pull -menu .mbar.pull
3382         .mbar add cascade -label Push -menu .mbar.push
3383 }
3384 . configure -menu .mbar
3385
3386 # -- Repository Menu
3387 #
3388 menu .mbar.repository
3389 .mbar.repository add command \
3390         -label {Visualize Current Branch} \
3391         -command {do_gitk {}} \
3392         -font font_ui
3393 if {![is_MacOSX]} {
3394         .mbar.repository add command \
3395                 -label {Visualize All Branches} \
3396                 -command {do_gitk {--all}} \
3397                 -font font_ui
3398 }
3399 .mbar.repository add separator
3400
3401 if {!$single_commit} {
3402         .mbar.repository add command -label {Compress Database} \
3403                 -command do_gc \
3404                 -font font_ui
3405
3406         .mbar.repository add command -label {Verify Database} \
3407                 -command do_fsck_objects \
3408                 -font font_ui
3409
3410         .mbar.repository add separator
3411
3412         if {[is_Windows]} {
3413                 .mbar.repository add command \
3414                         -label {Create Desktop Icon} \
3415                         -command do_windows_shortcut \
3416                         -font font_ui
3417         } elseif {[is_MacOSX]} {
3418                 .mbar.repository add command \
3419                         -label {Create Desktop Icon} \
3420                         -command do_macosx_app \
3421                         -font font_ui
3422         }
3423 }
3424
3425 .mbar.repository add command -label Quit \
3426         -command do_quit \
3427         -accelerator $M1T-Q \
3428         -font font_ui
3429
3430 # -- Edit Menu
3431 #
3432 menu .mbar.edit
3433 .mbar.edit add command -label Undo \
3434         -command {catch {[focus] edit undo}} \
3435         -accelerator $M1T-Z \
3436         -font font_ui
3437 .mbar.edit add command -label Redo \
3438         -command {catch {[focus] edit redo}} \
3439         -accelerator $M1T-Y \
3440         -font font_ui
3441 .mbar.edit add separator
3442 .mbar.edit add command -label Cut \
3443         -command {catch {tk_textCut [focus]}} \
3444         -accelerator $M1T-X \
3445         -font font_ui
3446 .mbar.edit add command -label Copy \
3447         -command {catch {tk_textCopy [focus]}} \
3448         -accelerator $M1T-C \
3449         -font font_ui
3450 .mbar.edit add command -label Paste \
3451         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3452         -accelerator $M1T-V \
3453         -font font_ui
3454 .mbar.edit add command -label Delete \
3455         -command {catch {[focus] delete sel.first sel.last}} \
3456         -accelerator Del \
3457         -font font_ui
3458 .mbar.edit add separator
3459 .mbar.edit add command -label {Select All} \
3460         -command {catch {[focus] tag add sel 0.0 end}} \
3461         -accelerator $M1T-A \
3462         -font font_ui
3463
3464 # -- Branch Menu
3465 #
3466 if {!$single_commit} {
3467         menu .mbar.branch
3468
3469         .mbar.branch add command -label {Create...} \
3470                 -command do_create_branch \
3471                 -accelerator $M1T-N \
3472                 -font font_ui
3473         lappend disable_on_lock [list .mbar.branch entryconf \
3474                 [.mbar.branch index last] -state]
3475
3476         .mbar.branch add command -label {Delete...} \
3477                 -command do_delete_branch \
3478                 -font font_ui
3479         lappend disable_on_lock [list .mbar.branch entryconf \
3480                 [.mbar.branch index last] -state]
3481 }
3482
3483 # -- Commit Menu
3484 #
3485 menu .mbar.commit
3486
3487 .mbar.commit add radiobutton \
3488         -label {New Commit} \
3489         -command do_select_commit_type \
3490         -variable selected_commit_type \
3491         -value new \
3492         -font font_ui
3493 lappend disable_on_lock \
3494         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3495
3496 .mbar.commit add radiobutton \
3497         -label {Amend Last Commit} \
3498         -command do_select_commit_type \
3499         -variable selected_commit_type \
3500         -value amend \
3501         -font font_ui
3502 lappend disable_on_lock \
3503         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3504
3505 .mbar.commit add separator
3506
3507 .mbar.commit add command -label Rescan \
3508         -command do_rescan \
3509         -accelerator F5 \
3510         -font font_ui
3511 lappend disable_on_lock \
3512         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3513
3514 .mbar.commit add command -label {Add To Commit} \
3515         -command do_add_selection \
3516         -font font_ui
3517 lappend disable_on_lock \
3518         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3519
3520 .mbar.commit add command -label {Add All To Commit} \
3521         -command do_add_all \
3522         -accelerator $M1T-I \
3523         -font font_ui
3524 lappend disable_on_lock \
3525         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3526
3527 .mbar.commit add command -label {Unstage From Commit} \
3528         -command do_unstage_selection \
3529         -font font_ui
3530 lappend disable_on_lock \
3531         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3532
3533 .mbar.commit add command -label {Revert Changes} \
3534         -command do_revert_selection \
3535         -font font_ui
3536 lappend disable_on_lock \
3537         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3538
3539 .mbar.commit add separator
3540
3541 .mbar.commit add command -label {Sign Off} \
3542         -command do_signoff \
3543         -accelerator $M1T-S \
3544         -font font_ui
3545
3546 .mbar.commit add command -label Commit \
3547         -command do_commit \
3548         -accelerator $M1T-Return \
3549         -font font_ui
3550 lappend disable_on_lock \
3551         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3552
3553 # -- Transport menus
3554 #
3555 if {!$single_commit} {
3556         menu .mbar.fetch
3557         menu .mbar.pull
3558         menu .mbar.push
3559 }
3560
3561 if {[is_MacOSX]} {
3562         # -- Apple Menu (Mac OS X only)
3563         #
3564         .mbar add cascade -label Apple -menu .mbar.apple
3565         menu .mbar.apple
3566
3567         .mbar.apple add command -label "About [appname]" \
3568                 -command do_about \
3569                 -font font_ui
3570         .mbar.apple add command -label "[appname] Options..." \
3571                 -command do_options \
3572                 -font font_ui
3573 } else {
3574         # -- Edit Menu
3575         #
3576         .mbar.edit add separator
3577         .mbar.edit add command -label {Options...} \
3578                 -command do_options \
3579                 -font font_ui
3580
3581         # -- Tools Menu
3582         #
3583         if {[file exists /usr/local/miga/lib/gui-miga]
3584                 && [file exists .pvcsrc]} {
3585         proc do_miga {} {
3586                 global ui_status_value
3587                 if {![lock_index update]} return
3588                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3589                 set miga_fd [open "|$cmd" r]
3590                 fconfigure $miga_fd -blocking 0
3591                 fileevent $miga_fd readable [list miga_done $miga_fd]
3592                 set ui_status_value {Running miga...}
3593         }
3594         proc miga_done {fd} {
3595                 read $fd 512
3596                 if {[eof $fd]} {
3597                         close $fd
3598                         unlock_index
3599                         rescan [list set ui_status_value {Ready.}]
3600                 }
3601         }
3602         .mbar add cascade -label Tools -menu .mbar.tools
3603         menu .mbar.tools
3604         .mbar.tools add command -label "Migrate" \
3605                 -command do_miga \
3606                 -font font_ui
3607         lappend disable_on_lock \
3608                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3609         }
3610
3611         # -- Help Menu
3612         #
3613         .mbar add cascade -label Help -menu .mbar.help
3614         menu .mbar.help
3615
3616         .mbar.help add command -label "About [appname]" \
3617                 -command do_about \
3618                 -font font_ui
3619 }
3620
3621
3622 # -- Branch Control
3623 #
3624 frame .branch \
3625         -borderwidth 1 \
3626         -relief sunken
3627 label .branch.l1 \
3628         -text {Current Branch:} \
3629         -anchor w \
3630         -justify left \
3631         -font font_ui
3632 label .branch.cb \
3633         -textvariable current_branch \
3634         -anchor w \
3635         -justify left \
3636         -font font_ui
3637 pack .branch.l1 -side left
3638 pack .branch.cb -side left -fill x
3639 pack .branch -side top -fill x
3640
3641 # -- Main Window Layout
3642 #
3643 panedwindow .vpane -orient vertical
3644 panedwindow .vpane.files -orient horizontal
3645 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3646 pack .vpane -anchor n -side top -fill both -expand 1
3647
3648 # -- Index File List
3649 #
3650 frame .vpane.files.index -height 100 -width 400
3651 label .vpane.files.index.title -text {Changes To Be Committed} \
3652         -background green \
3653         -font font_ui
3654 text $ui_index -background white -borderwidth 0 \
3655         -width 40 -height 10 \
3656         -font font_ui \
3657         -cursor $cursor_ptr \
3658         -yscrollcommand {.vpane.files.index.sb set} \
3659         -state disabled
3660 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3661 pack .vpane.files.index.title -side top -fill x
3662 pack .vpane.files.index.sb -side right -fill y
3663 pack $ui_index -side left -fill both -expand 1
3664 .vpane.files add .vpane.files.index -sticky nsew
3665
3666 # -- Working Directory File List
3667 #
3668 frame .vpane.files.workdir -height 100 -width 100
3669 label .vpane.files.workdir.title -text {Changed But Not Updated} \
3670         -background red \
3671         -font font_ui
3672 text $ui_workdir -background white -borderwidth 0 \
3673         -width 40 -height 10 \
3674         -font font_ui \
3675         -cursor $cursor_ptr \
3676         -yscrollcommand {.vpane.files.workdir.sb set} \
3677         -state disabled
3678 scrollbar .vpane.files.workdir.sb -command [list $ui_workdir yview]
3679 pack .vpane.files.workdir.title -side top -fill x
3680 pack .vpane.files.workdir.sb -side right -fill y
3681 pack $ui_workdir -side left -fill both -expand 1
3682 .vpane.files add .vpane.files.workdir -sticky nsew
3683
3684 foreach i [list $ui_index $ui_workdir] {
3685         $i tag conf in_diff -font font_uibold
3686         $i tag conf in_sel \
3687                 -background [$i cget -foreground] \
3688                 -foreground [$i cget -background]
3689 }
3690 unset i
3691
3692 # -- Diff and Commit Area
3693 #
3694 frame .vpane.lower -height 300 -width 400
3695 frame .vpane.lower.commarea
3696 frame .vpane.lower.diff -relief sunken -borderwidth 1
3697 pack .vpane.lower.commarea -side top -fill x
3698 pack .vpane.lower.diff -side bottom -fill both -expand 1
3699 .vpane add .vpane.lower -stick nsew
3700
3701 # -- Commit Area Buttons
3702 #
3703 frame .vpane.lower.commarea.buttons
3704 label .vpane.lower.commarea.buttons.l -text {} \
3705         -anchor w \
3706         -justify left \
3707         -font font_ui
3708 pack .vpane.lower.commarea.buttons.l -side top -fill x
3709 pack .vpane.lower.commarea.buttons -side left -fill y
3710
3711 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3712         -command do_rescan \
3713         -font font_ui
3714 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3715 lappend disable_on_lock \
3716         {.vpane.lower.commarea.buttons.rescan conf -state}
3717
3718 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3719         -command do_add_all \
3720         -font font_ui
3721 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3722 lappend disable_on_lock \
3723         {.vpane.lower.commarea.buttons.incall conf -state}
3724
3725 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3726         -command do_signoff \
3727         -font font_ui
3728 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3729
3730 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3731         -command do_commit \
3732         -font font_ui
3733 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3734 lappend disable_on_lock \
3735         {.vpane.lower.commarea.buttons.commit conf -state}
3736
3737 # -- Commit Message Buffer
3738 #
3739 frame .vpane.lower.commarea.buffer
3740 frame .vpane.lower.commarea.buffer.header
3741 set ui_comm .vpane.lower.commarea.buffer.t
3742 set ui_coml .vpane.lower.commarea.buffer.header.l
3743 radiobutton .vpane.lower.commarea.buffer.header.new \
3744         -text {New Commit} \
3745         -command do_select_commit_type \
3746         -variable selected_commit_type \
3747         -value new \
3748         -font font_ui
3749 lappend disable_on_lock \
3750         [list .vpane.lower.commarea.buffer.header.new conf -state]
3751 radiobutton .vpane.lower.commarea.buffer.header.amend \
3752         -text {Amend Last Commit} \
3753         -command do_select_commit_type \
3754         -variable selected_commit_type \
3755         -value amend \
3756         -font font_ui
3757 lappend disable_on_lock \
3758         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3759 label $ui_coml \
3760         -anchor w \
3761         -justify left \
3762         -font font_ui
3763 proc trace_commit_type {varname args} {
3764         global ui_coml commit_type
3765         switch -glob -- $commit_type {
3766         initial       {set txt {Initial Commit Message:}}
3767         amend         {set txt {Amended Commit Message:}}
3768         amend-initial {set txt {Amended Initial Commit Message:}}
3769         amend-merge   {set txt {Amended Merge Commit Message:}}
3770         merge         {set txt {Merge Commit Message:}}
3771         *             {set txt {Commit Message:}}
3772         }
3773         $ui_coml conf -text $txt
3774 }
3775 trace add variable commit_type write trace_commit_type
3776 pack $ui_coml -side left -fill x
3777 pack .vpane.lower.commarea.buffer.header.amend -side right
3778 pack .vpane.lower.commarea.buffer.header.new -side right
3779
3780 text $ui_comm -background white -borderwidth 1 \
3781         -undo true \
3782         -maxundo 20 \
3783         -autoseparators true \
3784         -relief sunken \
3785         -width 75 -height 9 -wrap none \
3786         -font font_diff \
3787         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3788 scrollbar .vpane.lower.commarea.buffer.sby \
3789         -command [list $ui_comm yview]
3790 pack .vpane.lower.commarea.buffer.header -side top -fill x
3791 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3792 pack $ui_comm -side left -fill y
3793 pack .vpane.lower.commarea.buffer -side left -fill y
3794
3795 # -- Commit Message Buffer Context Menu
3796 #
3797 set ctxm .vpane.lower.commarea.buffer.ctxm
3798 menu $ctxm -tearoff 0
3799 $ctxm add command \
3800         -label {Cut} \
3801         -font font_ui \
3802         -command {tk_textCut $ui_comm}
3803 $ctxm add command \
3804         -label {Copy} \
3805         -font font_ui \
3806         -command {tk_textCopy $ui_comm}
3807 $ctxm add command \
3808         -label {Paste} \
3809         -font font_ui \
3810         -command {tk_textPaste $ui_comm}
3811 $ctxm add command \
3812         -label {Delete} \
3813         -font font_ui \
3814         -command {$ui_comm delete sel.first sel.last}
3815 $ctxm add separator
3816 $ctxm add command \
3817         -label {Select All} \
3818         -font font_ui \
3819         -command {$ui_comm tag add sel 0.0 end}
3820 $ctxm add command \
3821         -label {Copy All} \
3822         -font font_ui \
3823         -command {
3824                 $ui_comm tag add sel 0.0 end
3825                 tk_textCopy $ui_comm
3826                 $ui_comm tag remove sel 0.0 end
3827         }
3828 $ctxm add separator
3829 $ctxm add command \
3830         -label {Sign Off} \
3831         -font font_ui \
3832         -command do_signoff
3833 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3834
3835 # -- Diff Header
3836 #
3837 set current_diff_path {}
3838 set diff_actions [list]
3839 proc trace_current_diff_path {varname args} {
3840         global current_diff_path diff_actions file_states
3841         if {$current_diff_path eq {}} {
3842                 set s {}
3843                 set f {}
3844                 set p {}
3845                 set o disabled
3846         } else {
3847                 set p $current_diff_path
3848                 set s [mapdesc [lindex $file_states($p) 0] $p]
3849                 set f {File:}
3850                 set p [escape_path $p]
3851                 set o normal
3852         }
3853
3854         .vpane.lower.diff.header.status configure -text $s
3855         .vpane.lower.diff.header.file configure -text $f
3856         .vpane.lower.diff.header.path configure -text $p
3857         foreach w $diff_actions {
3858                 uplevel #0 $w $o
3859         }
3860 }
3861 trace add variable current_diff_path write trace_current_diff_path
3862
3863 frame .vpane.lower.diff.header -background orange
3864 label .vpane.lower.diff.header.status \
3865         -background orange \
3866         -width $max_status_desc \
3867         -anchor w \
3868         -justify left \
3869         -font font_ui
3870 label .vpane.lower.diff.header.file \
3871         -background orange \
3872         -anchor w \
3873         -justify left \
3874         -font font_ui
3875 label .vpane.lower.diff.header.path \
3876         -background orange \
3877         -anchor w \
3878         -justify left \
3879         -font font_ui
3880 pack .vpane.lower.diff.header.status -side left
3881 pack .vpane.lower.diff.header.file -side left
3882 pack .vpane.lower.diff.header.path -fill x
3883 set ctxm .vpane.lower.diff.header.ctxm
3884 menu $ctxm -tearoff 0
3885 $ctxm add command \
3886         -label {Copy} \
3887         -font font_ui \
3888         -command {
3889                 clipboard clear
3890                 clipboard append \
3891                         -format STRING \
3892                         -type STRING \
3893                         -- $current_diff_path
3894         }
3895 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3896 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3897
3898 # -- Diff Body
3899 #
3900 frame .vpane.lower.diff.body
3901 set ui_diff .vpane.lower.diff.body.t
3902 text $ui_diff -background white -borderwidth 0 \
3903         -width 80 -height 15 -wrap none \
3904         -font font_diff \
3905         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3906         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3907         -state disabled
3908 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3909         -command [list $ui_diff xview]
3910 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3911         -command [list $ui_diff yview]
3912 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3913 pack .vpane.lower.diff.body.sby -side right -fill y
3914 pack $ui_diff -side left -fill both -expand 1
3915 pack .vpane.lower.diff.header -side top -fill x
3916 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3917
3918 $ui_diff tag conf d_@ -font font_diffbold
3919 $ui_diff tag conf d_+ -foreground blue
3920 $ui_diff tag conf d_- -foreground red
3921
3922 $ui_diff tag conf d_++ -foreground blue
3923 $ui_diff tag conf d_-- -foreground red
3924 $ui_diff tag conf d_+s \
3925         -foreground blue \
3926         -background azure2
3927 $ui_diff tag conf d_-s \
3928         -foreground red \
3929         -background azure2
3930 $ui_diff tag conf d_s+ \
3931         -foreground blue \
3932         -background {light goldenrod yellow}
3933 $ui_diff tag conf d_s- \
3934         -foreground red \
3935         -background {light goldenrod yellow}
3936
3937 $ui_diff tag conf d<<<<<<< \
3938         -foreground orange \
3939         -font font_diffbold
3940 $ui_diff tag conf d======= \
3941         -foreground orange \
3942         -font font_diffbold
3943 $ui_diff tag conf d>>>>>>> \
3944         -foreground orange \
3945         -font font_diffbold
3946
3947 # -- Diff Body Context Menu
3948 #
3949 set ctxm .vpane.lower.diff.body.ctxm
3950 menu $ctxm -tearoff 0
3951 $ctxm add command \
3952         -label {Refresh} \
3953         -font font_ui \
3954         -command reshow_diff
3955 $ctxm add command \
3956         -label {Copy} \
3957         -font font_ui \
3958         -command {tk_textCopy $ui_diff}
3959 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3960 $ctxm add command \
3961         -label {Select All} \
3962         -font font_ui \
3963         -command {$ui_diff tag add sel 0.0 end}
3964 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3965 $ctxm add command \
3966         -label {Copy All} \
3967         -font font_ui \
3968         -command {
3969                 $ui_diff tag add sel 0.0 end
3970                 tk_textCopy $ui_diff
3971                 $ui_diff tag remove sel 0.0 end
3972         }
3973 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3974 $ctxm add separator
3975 $ctxm add command \
3976         -label {Decrease Font Size} \
3977         -font font_ui \
3978         -command {incr_font_size font_diff -1}
3979 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3980 $ctxm add command \
3981         -label {Increase Font Size} \
3982         -font font_ui \
3983         -command {incr_font_size font_diff 1}
3984 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3985 $ctxm add separator
3986 $ctxm add command \
3987         -label {Show Less Context} \
3988         -font font_ui \
3989         -command {if {$repo_config(gui.diffcontext) >= 2} {
3990                 incr repo_config(gui.diffcontext) -1
3991                 reshow_diff
3992         }}
3993 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3994 $ctxm add command \
3995         -label {Show More Context} \
3996         -font font_ui \
3997         -command {
3998                 incr repo_config(gui.diffcontext)
3999                 reshow_diff
4000         }
4001 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
4002 $ctxm add separator
4003 $ctxm add command -label {Options...} \
4004         -font font_ui \
4005         -command do_options
4006 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
4007
4008 # -- Status Bar
4009 #
4010 set ui_status_value {Initializing...}
4011 label .status -textvariable ui_status_value \
4012         -anchor w \
4013         -justify left \
4014         -borderwidth 1 \
4015         -relief sunken \
4016         -font font_ui
4017 pack .status -anchor w -side bottom -fill x
4018
4019 # -- Load geometry
4020 #
4021 catch {
4022 set gm $repo_config(gui.geometry)
4023 wm geometry . [lindex $gm 0]
4024 .vpane sash place 0 \
4025         [lindex [.vpane sash coord 0] 0] \
4026         [lindex $gm 1]
4027 .vpane.files sash place 0 \
4028         [lindex $gm 2] \
4029         [lindex [.vpane.files sash coord 0] 1]
4030 unset gm
4031 }
4032
4033 # -- Key Bindings
4034 #
4035 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
4036 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
4037 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
4038 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
4039 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
4040 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
4041 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
4042 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
4043 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
4044 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
4045 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
4046
4047 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
4048 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
4049 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
4050 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
4051 bind $ui_diff <$M1B-Key-v> {break}
4052 bind $ui_diff <$M1B-Key-V> {break}
4053 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
4054 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
4055 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
4056 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
4057 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
4058 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
4059
4060 if {!$single_commit} {
4061         bind . <$M1B-Key-n> do_create_branch
4062         bind . <$M1B-Key-N> do_create_branch
4063 }
4064
4065 bind .   <Destroy> do_quit
4066 bind all <Key-F5> do_rescan
4067 bind all <$M1B-Key-r> do_rescan
4068 bind all <$M1B-Key-R> do_rescan
4069 bind .   <$M1B-Key-s> do_signoff
4070 bind .   <$M1B-Key-S> do_signoff
4071 bind .   <$M1B-Key-i> do_add_all
4072 bind .   <$M1B-Key-I> do_add_all
4073 bind .   <$M1B-Key-Return> do_commit
4074 bind all <$M1B-Key-q> do_quit
4075 bind all <$M1B-Key-Q> do_quit
4076 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
4077 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
4078 foreach i [list $ui_index $ui_workdir] {
4079         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
4080         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
4081         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
4082 }
4083 unset i
4084
4085 set file_lists($ui_index) [list]
4086 set file_lists($ui_workdir) [list]
4087
4088 set HEAD {}
4089 set PARENT {}
4090 set MERGE_HEAD [list]
4091 set commit_type {}
4092 set empty_tree {}
4093 set current_branch {}
4094 set current_diff_path {}
4095 set selected_commit_type new
4096
4097 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
4098 focus -force $ui_comm
4099
4100 # -- Warn the user about environmental problems.  Cygwin's Tcl
4101 #    does *not* pass its env array onto any processes it spawns.
4102 #    This means that git processes get none of our environment.
4103 #
4104 if {[is_Windows]} {
4105         set ignored_env 0
4106         set suggest_user {}
4107         set msg "Possible environment issues exist.
4108
4109 The following environment variables are probably
4110 going to be ignored by any Git subprocess run
4111 by [appname]:
4112
4113 "
4114         foreach name [array names env] {
4115                 switch -regexp -- $name {
4116                 {^GIT_INDEX_FILE$} -
4117                 {^GIT_OBJECT_DIRECTORY$} -
4118                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
4119                 {^GIT_DIFF_OPTS$} -
4120                 {^GIT_EXTERNAL_DIFF$} -
4121                 {^GIT_PAGER$} -
4122                 {^GIT_TRACE$} -
4123                 {^GIT_CONFIG$} -
4124                 {^GIT_CONFIG_LOCAL$} -
4125                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
4126                         append msg " - $name\n"
4127                         incr ignored_env
4128                 }
4129                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
4130                         append msg " - $name\n"
4131                         incr ignored_env
4132                         set suggest_user $name
4133                 }
4134                 }
4135         }
4136         if {$ignored_env > 0} {
4137                 append msg "
4138 This is due to a known issue with the
4139 Tcl binary distributed by Cygwin."
4140
4141                 if {$suggest_user ne {}} {
4142                         append msg "
4143
4144 A good replacement for $suggest_user
4145 is placing values for the user.name and
4146 user.email settings into your personal
4147 ~/.gitconfig file.
4148 "
4149                 }
4150                 warn_popup $msg
4151         }
4152         unset ignored_env msg suggest_user name
4153 }
4154
4155 # -- Only initialize complex UI if we are going to stay running.
4156 #
4157 if {!$single_commit} {
4158         load_all_remotes
4159         load_all_heads
4160
4161         populate_branch_menu
4162         populate_fetch_menu .mbar.fetch
4163         populate_pull_menu .mbar.pull
4164         populate_push_menu .mbar.push
4165 }
4166
4167 # -- Only suggest a gc run if we are going to stay running.
4168 #
4169 if {!$single_commit} {
4170         set object_limit 2000
4171         if {[is_Windows]} {set object_limit 200}
4172         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
4173         if {$objects_current >= $object_limit} {
4174                 if {[ask_popup \
4175                         "This repository currently has $objects_current loose objects.
4176
4177 To maintain optimal performance it is strongly
4178 recommended that you compress the database
4179 when more than $object_limit loose objects exist.
4180
4181 Compress the database now?"] eq yes} {
4182                         do_gc
4183                 }
4184         }
4185         unset object_limit _junk objects_current
4186 }
4187
4188 lock_index begin-read
4189 after 1 do_rescan