git.oblomov.eu Git - git/blob - git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _gitexec {}
  30 set _reponame {}
  31 set _iscygwin {}
  32
  33 proc appname {} {
  34         global _appname
  35         return $_appname
  36 }
  37
  38 proc gitdir {args} {
  39         global _gitdir
  40         if {$args eq {}} {
  41                 return $_gitdir
  42         }
  43         return [eval [concat [list file join $_gitdir] $args]]
  44 }
  45
  46 proc gitexec {args} {
  47         global _gitexec
  48         if {$_gitexec eq {}} {
  49                 if {[catch {set _gitexec [exec git --exec-path]} err]} {
  50                         error "Git not installed?\n\n$err"
  51                 }
  52         }
  53         if {$args eq {}} {
  54                 return $_gitexec
  55         }
  56         return [eval [concat [list file join $_gitexec] $args]]
  57 }
  58
  59 proc reponame {} {
  60         global _reponame
  61         return $_reponame
  62 }
  63
  64 proc is_MacOSX {} {
  65         global tcl_platform tk_library
  66         if {[tk windowingsystem] eq {aqua}} {
  67                 return 1
  68         }
  69         return 0
  70 }
  71
  72 proc is_Windows {} {
  73         global tcl_platform
  74         if {$tcl_platform(platform) eq {windows}} {
  75                 return 1
  76         }
  77         return 0
  78 }
  79
  80 proc is_Cygwin {} {
  81         global tcl_platform _iscygwin
  82         if {$_iscygwin eq {}} {
  83                 if {$tcl_platform(platform) eq {windows}} {
  84                         if {[catch {set p [exec cygpath --windir]} err]} {
  85                                 set _iscygwin 0
  86                         } else {
  87                                 set _iscygwin 1
  88                         }
  89                 } else {
  90                         set _iscygwin 0
  91                 }
  92         }
  93         return $_iscygwin
  94 }
  95
  96 ######################################################################
  97 ##
  98 ## config
  99
 100 proc is_many_config {name} {
 101         switch -glob -- $name {
 102         remote.*.fetch -
 103         remote.*.push
 104                 {return 1}
 105         *
 106                 {return 0}
 107         }
 108 }
 109
 110 proc is_config_true {name} {
 111         global repo_config
 112         if {[catch {set v $repo_config($name)}]} {
 113                 return 0
 114         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 115                 return 1
 116         } else {
 117                 return 0
 118         }
 119 }
 120
 121 proc load_config {include_global} {
 122         global repo_config global_config default_config
 123
 124         array unset global_config
 125         if {$include_global} {
 126                 catch {
 127                         set fd_rc [open "| git repo-config --global --list" r]
 128                         while {[gets $fd_rc line] >= 0} {
 129                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 130                                         if {[is_many_config $name]} {
 131                                                 lappend global_config($name) $value
 132                                         } else {
 133                                                 set global_config($name) $value
 134                                         }
 135                                 }
 136                         }
 137                         close $fd_rc
 138                 }
 139         }
 140
 141         array unset repo_config
 142         catch {
 143                 set fd_rc [open "| git repo-config --list" r]
 144                 while {[gets $fd_rc line] >= 0} {
 145                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 146                                 if {[is_many_config $name]} {
 147                                         lappend repo_config($name) $value
 148                                 } else {
 149                                         set repo_config($name) $value
 150                                 }
 151                         }
 152                 }
 153                 close $fd_rc
 154         }
 155
 156         foreach name [array names default_config] {
 157                 if {[catch {set v $global_config($name)}]} {
 158                         set global_config($name) $default_config($name)
 159                 }
 160                 if {[catch {set v $repo_config($name)}]} {
 161                         set repo_config($name) $default_config($name)
 162                 }
 163         }
 164 }
 165
 166 proc save_config {} {
 167         global default_config font_descs
 168         global repo_config global_config
 169         global repo_config_new global_config_new
 170
 171         foreach option $font_descs {
 172                 set name [lindex $option 0]
 173                 set font [lindex $option 1]
 174                 font configure $font \
 175                         -family $global_config_new(gui.$font^^family) \
 176                         -size $global_config_new(gui.$font^^size)
 177                 font configure ${font}bold \
 178                         -family $global_config_new(gui.$font^^family) \
 179                         -size $global_config_new(gui.$font^^size)
 180                 set global_config_new(gui.$name) [font configure $font]
 181                 unset global_config_new(gui.$font^^family)
 182                 unset global_config_new(gui.$font^^size)
 183         }
 184
 185         foreach name [array names default_config] {
 186                 set value $global_config_new($name)
 187                 if {$value ne $global_config($name)} {
 188                         if {$value eq $default_config($name)} {
 189                                 catch {exec git repo-config --global --unset $name}
 190                         } else {
 191                                 regsub -all "\[{}\]" $value {"} value
 192                                 exec git repo-config --global $name $value
 193                         }
 194                         set global_config($name) $value
 195                         if {$value eq $repo_config($name)} {
 196                                 catch {exec git repo-config --unset $name}
 197                                 set repo_config($name) $value
 198                         }
 199                 }
 200         }
 201
 202         foreach name [array names default_config] {
 203                 set value $repo_config_new($name)
 204                 if {$value ne $repo_config($name)} {
 205                         if {$value eq $global_config($name)} {
 206                                 catch {exec git repo-config --unset $name}
 207                         } else {
 208                                 regsub -all "\[{}\]" $value {"} value
 209                                 exec git repo-config $name $value
 210                         }
 211                         set repo_config($name) $value
 212                 }
 213         }
 214 }
 215
 216 proc error_popup {msg} {
 217         set title [appname]
 218         if {[reponame] ne {}} {
 219                 append title " ([reponame])"
 220         }
 221         set cmd [list tk_messageBox \
 222                 -icon error \
 223                 -type ok \
 224                 -title "$title: error" \
 225                 -message $msg]
 226         if {[winfo ismapped .]} {
 227                 lappend cmd -parent .
 228         }
 229         eval $cmd
 230 }
 231
 232 proc warn_popup {msg} {
 233         set title [appname]
 234         if {[reponame] ne {}} {
 235                 append title " ([reponame])"
 236         }
 237         set cmd [list tk_messageBox \
 238                 -icon warning \
 239                 -type ok \
 240                 -title "$title: warning" \
 241                 -message $msg]
 242         if {[winfo ismapped .]} {
 243                 lappend cmd -parent .
 244         }
 245         eval $cmd
 246 }
 247
 248 proc info_popup {msg {parent .}} {
 249         set title [appname]
 250         if {[reponame] ne {}} {
 251                 append title " ([reponame])"
 252         }
 253         tk_messageBox \
 254                 -parent $parent \
 255                 -icon info \
 256                 -type ok \
 257                 -title $title \
 258                 -message $msg
 259 }
 260
 261 proc ask_popup {msg} {
 262         set title [appname]
 263         if {[reponame] ne {}} {
 264                 append title " ([reponame])"
 265         }
 266         return [tk_messageBox \
 267                 -parent . \
 268                 -icon question \
 269                 -type yesno \
 270                 -title $title \
 271                 -message $msg]
 272 }
 273
 274 ######################################################################
 275 ##
 276 ## repository setup
 277
 278 if {   [catch {set _gitdir $env(GIT_DIR)}]
 279         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 280         catch {wm withdraw .}
 281         error_popup "Cannot find the git directory:\n\n$err"
 282         exit 1
 283 }
 284 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 285         catch {set _gitdir [exec cygpath --unix $_gitdir]}
 286 }
 287 if {![file isdirectory $_gitdir]} {
 288         catch {wm withdraw .}
 289         error_popup "Git directory not found:\n\n$_gitdir"
 290         exit 1
 291 }
 292 if {[lindex [file split $_gitdir] end] ne {.git}} {
 293         catch {wm withdraw .}
 294         error_popup "Cannot use funny .git directory:\n\n$_gitdir"
 295         exit 1
 296 }
 297 if {[catch {cd [file dirname $_gitdir]} err]} {
 298         catch {wm withdraw .}
 299         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 300         exit 1
 301 }
 302 set _reponame [lindex [file split \
 303         [file normalize [file dirname $_gitdir]]] \
 304         end]
 305
 306 set single_commit 0
 307 if {[appname] eq {git-citool}} {
 308         set single_commit 1
 309 }
 310
 311 ######################################################################
 312 ##
 313 ## task management
 314
 315 set rescan_active 0
 316 set diff_active 0
 317 set last_clicked {}
 318
 319 set disable_on_lock [list]
 320 set index_lock_type none
 321
 322 proc lock_index {type} {
 323         global index_lock_type disable_on_lock
 324
 325         if {$index_lock_type eq {none}} {
 326                 set index_lock_type $type
 327                 foreach w $disable_on_lock {
 328                         uplevel #0 $w disabled
 329                 }
 330                 return 1
 331         } elseif {$index_lock_type eq "begin-$type"} {
 332                 set index_lock_type $type
 333                 return 1
 334         }
 335         return 0
 336 }
 337
 338 proc unlock_index {} {
 339         global index_lock_type disable_on_lock
 340
 341         set index_lock_type none
 342         foreach w $disable_on_lock {
 343                 uplevel #0 $w normal
 344         }
 345 }
 346
 347 ######################################################################
 348 ##
 349 ## status
 350
 351 proc repository_state {ctvar hdvar mhvar} {
 352         global current_branch
 353         upvar $ctvar ct $hdvar hd $mhvar mh
 354
 355         set mh [list]
 356
 357         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 358                 set current_branch {}
 359         } else {
 360                 regsub ^refs/((heads|tags|remotes)/)? \
 361                         $current_branch \
 362                         {} \
 363                         current_branch
 364         }
 365
 366         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 367                 set hd {}
 368                 set ct initial
 369                 return
 370         }
 371
 372         set merge_head [gitdir MERGE_HEAD]
 373         if {[file exists $merge_head]} {
 374                 set ct merge
 375                 set fd_mh [open $merge_head r]
 376                 while {[gets $fd_mh line] >= 0} {
 377                         lappend mh $line
 378                 }
 379                 close $fd_mh
 380                 return
 381         }
 382
 383         set ct normal
 384 }
 385
 386 proc PARENT {} {
 387         global PARENT empty_tree
 388
 389         set p [lindex $PARENT 0]
 390         if {$p ne {}} {
 391                 return $p
 392         }
 393         if {$empty_tree eq {}} {
 394                 set empty_tree [exec git mktree << {}]
 395         }
 396         return $empty_tree
 397 }
 398
 399 proc rescan {after {honor_trustmtime 1}} {
 400         global HEAD PARENT MERGE_HEAD commit_type
 401         global ui_index ui_workdir ui_status_value ui_comm
 402         global rescan_active file_states
 403         global repo_config
 404
 405         if {$rescan_active > 0 || ![lock_index read]} return
 406
 407         repository_state newType newHEAD newMERGE_HEAD
 408         if {[string match amend* $commit_type]
 409                 && $newType eq {normal}
 410                 && $newHEAD eq $HEAD} {
 411         } else {
 412                 set HEAD $newHEAD
 413                 set PARENT $newHEAD
 414                 set MERGE_HEAD $newMERGE_HEAD
 415                 set commit_type $newType
 416         }
 417
 418         array unset file_states
 419
 420         if {![$ui_comm edit modified]
 421                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 422                 if {[load_message GITGUI_MSG]} {
 423                 } elseif {[load_message MERGE_MSG]} {
 424                 } elseif {[load_message SQUASH_MSG]} {
 425                 }
 426                 $ui_comm edit reset
 427                 $ui_comm edit modified false
 428         }
 429
 430         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
 431                 rescan_stage2 {} $after
 432         } else {
 433                 set rescan_active 1
 434                 set ui_status_value {Refreshing file status...}
 435                 set cmd [list git update-index]
 436                 lappend cmd -q
 437                 lappend cmd --unmerged
 438                 lappend cmd --ignore-missing
 439                 lappend cmd --refresh
 440                 set fd_rf [open "| $cmd" r]
 441                 fconfigure $fd_rf -blocking 0 -translation binary
 442                 fileevent $fd_rf readable \
 443                         [list rescan_stage2 $fd_rf $after]
 444         }
 445 }
 446
 447 proc rescan_stage2 {fd after} {
 448         global ui_status_value
 449         global rescan_active buf_rdi buf_rdf buf_rlo
 450
 451         if {$fd ne {}} {
 452                 read $fd
 453                 if {![eof $fd]} return
 454                 close $fd
 455         }
 456
 457         set ls_others [list | git ls-files --others -z \
 458                 --exclude-per-directory=.gitignore]
 459         set info_exclude [gitdir info exclude]
 460         if {[file readable $info_exclude]} {
 461                 lappend ls_others "--exclude-from=$info_exclude"
 462         }
 463
 464         set buf_rdi {}
 465         set buf_rdf {}
 466         set buf_rlo {}
 467
 468         set rescan_active 3
 469         set ui_status_value {Scanning for modified files ...}
 470         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 471         set fd_df [open "| git diff-files -z" r]
 472         set fd_lo [open $ls_others r]
 473
 474         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
 475         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
 476         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
 477         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 478         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 479         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 480 }
 481
 482 proc load_message {file} {
 483         global ui_comm
 484
 485         set f [gitdir $file]
 486         if {[file isfile $f]} {
 487                 if {[catch {set fd [open $f r]}]} {
 488                         return 0
 489                 }
 490                 set content [string trim [read $fd]]
 491                 close $fd
 492                 regsub -all -line {[ \r\t]+$} $content {} content
 493                 $ui_comm delete 0.0 end
 494                 $ui_comm insert end $content
 495                 return 1
 496         }
 497         return 0
 498 }
 499
 500 proc read_diff_index {fd after} {
 501         global buf_rdi
 502
 503         append buf_rdi [read $fd]
 504         set c 0
 505         set n [string length $buf_rdi]
 506         while {$c < $n} {
 507                 set z1 [string first "\0" $buf_rdi $c]
 508                 if {$z1 == -1} break
 509                 incr z1
 510                 set z2 [string first "\0" $buf_rdi $z1]
 511                 if {$z2 == -1} break
 512
 513                 incr c
 514                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 515                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
 516                 merge_state \
 517                         [encoding convertfrom $p] \
 518                         [lindex $i 4]? \
 519                         [list [lindex $i 0] [lindex $i 2]] \
 520                         [list]
 521                 set c $z2
 522                 incr c
 523         }
 524         if {$c < $n} {
 525                 set buf_rdi [string range $buf_rdi $c end]
 526         } else {
 527                 set buf_rdi {}
 528         }
 529
 530         rescan_done $fd buf_rdi $after
 531 }
 532
 533 proc read_diff_files {fd after} {
 534         global buf_rdf
 535
 536         append buf_rdf [read $fd]
 537         set c 0
 538         set n [string length $buf_rdf]
 539         while {$c < $n} {
 540                 set z1 [string first "\0" $buf_rdf $c]
 541                 if {$z1 == -1} break
 542                 incr z1
 543                 set z2 [string first "\0" $buf_rdf $z1]
 544                 if {$z2 == -1} break
 545
 546                 incr c
 547                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 548                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
 549                 merge_state \
 550                         [encoding convertfrom $p] \
 551                         ?[lindex $i 4] \
 552                         [list] \
 553                         [list [lindex $i 0] [lindex $i 2]]
 554                 set c $z2
 555                 incr c
 556         }
 557         if {$c < $n} {
 558                 set buf_rdf [string range $buf_rdf $c end]
 559         } else {
 560                 set buf_rdf {}
 561         }
 562
 563         rescan_done $fd buf_rdf $after
 564 }
 565
 566 proc read_ls_others {fd after} {
 567         global buf_rlo
 568
 569         append buf_rlo [read $fd]
 570         set pck [split $buf_rlo "\0"]
 571         set buf_rlo [lindex $pck end]
 572         foreach p [lrange $pck 0 end-1] {
 573                 merge_state [encoding convertfrom $p] ?O
 574         }
 575         rescan_done $fd buf_rlo $after
 576 }
 577
 578 proc rescan_done {fd buf after} {
 579         global rescan_active
 580         global file_states repo_config
 581         upvar $buf to_clear
 582
 583         if {![eof $fd]} return
 584         set to_clear {}
 585         close $fd
 586         if {[incr rescan_active -1] > 0} return
 587
 588         prune_selection
 589         unlock_index
 590         display_all_files
 591         reshow_diff
 592         uplevel #0 $after
 593 }
 594
 595 proc prune_selection {} {
 596         global file_states selected_paths
 597
 598         foreach path [array names selected_paths] {
 599                 if {[catch {set still_here $file_states($path)}]} {
 600                         unset selected_paths($path)
 601                 }
 602         }
 603 }
 604
 605 ######################################################################
 606 ##
 607 ## diff
 608
 609 proc clear_diff {} {
 610         global ui_diff current_diff_path current_diff_header
 611         global ui_index ui_workdir
 612
 613         $ui_diff conf -state normal
 614         $ui_diff delete 0.0 end
 615         $ui_diff conf -state disabled
 616
 617         set current_diff_path {}
 618         set current_diff_header {}
 619
 620         $ui_index tag remove in_diff 0.0 end
 621         $ui_workdir tag remove in_diff 0.0 end
 622 }
 623
 624 proc reshow_diff {} {
 625         global ui_status_value file_states file_lists
 626         global current_diff_path current_diff_side
 627
 628         set p $current_diff_path
 629         if {$p eq {}
 630                 || $current_diff_side eq {}
 631                 || [catch {set s $file_states($p)}]
 632                 || [lsearch -sorted -exact $file_lists($current_diff_side) $p] == -1} {
 633                 clear_diff
 634         } else {
 635                 show_diff $p $current_diff_side
 636         }
 637 }
 638
 639 proc handle_empty_diff {} {
 640         global current_diff_path file_states file_lists
 641
 642         set path $current_diff_path
 643         set s $file_states($path)
 644         if {[lindex $s 0] ne {_M}} return
 645
 646         info_popup "No differences detected.
 647
 648 [short_path $path] has no changes.
 649
 650 The modification date of this file was updated
 651 by another application, but the content within
 652 the file was not changed.
 653
 654 A rescan will be automatically started to find
 655 other files which may have the same state."
 656
 657         clear_diff
 658         display_file $path __
 659         rescan {set ui_status_value {Ready.}} 0
 660 }
 661
 662 proc show_diff {path w {lno {}}} {
 663         global file_states file_lists
 664         global is_3way_diff diff_active repo_config
 665         global ui_diff ui_status_value ui_index ui_workdir
 666         global current_diff_path current_diff_side current_diff_header
 667
 668         if {$diff_active || ![lock_index read]} return
 669
 670         clear_diff
 671         if {$lno == {}} {
 672                 set lno [lsearch -sorted -exact $file_lists($w) $path]
 673                 if {$lno >= 0} {
 674                         incr lno
 675                 }
 676         }
 677         if {$lno >= 1} {
 678                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 679         }
 680
 681         set s $file_states($path)
 682         set m [lindex $s 0]
 683         set is_3way_diff 0
 684         set diff_active 1
 685         set current_diff_path $path
 686         set current_diff_side $w
 687         set current_diff_header {}
 688         set ui_status_value "Loading diff of [escape_path $path]..."
 689
 690         # - Git won't give us the diff, there's nothing to compare to!
 691         #
 692         if {$m eq {_O}} {
 693                 set max_sz [expr {128 * 1024}]
 694                 if {[catch {
 695                                 set fd [open $path r]
 696                                 set content [read $fd $max_sz]
 697                                 close $fd
 698                                 set sz [file size $path]
 699                         } err ]} {
 700                         set diff_active 0
 701                         unlock_index
 702                         set ui_status_value "Unable to display [escape_path $path]"
 703                         error_popup "Error loading file:\n\n$err"
 704                         return
 705                 }
 706                 $ui_diff conf -state normal
 707                 if {![catch {set type [exec file $path]}]} {
 708                         set n [string length $path]
 709                         if {[string equal -length $n $path $type]} {
 710                                 set type [string range $type $n end]
 711                                 regsub {^:?\s*} $type {} type
 712                         }
 713                         $ui_diff insert end "* $type\n" d_@
 714                 }
 715                 if {[string first "\0" $content] != -1} {
 716                         $ui_diff insert end \
 717                                 "* Binary file (not showing content)." \
 718                                 d_@
 719                 } else {
 720                         if {$sz > $max_sz} {
 721                                 $ui_diff insert end \
 722 "* Untracked file is $sz bytes.
 723 * Showing only first $max_sz bytes.
 724 " d_@
 725                         }
 726                         $ui_diff insert end $content
 727                         if {$sz > $max_sz} {
 728                                 $ui_diff insert end "
 729 * Untracked file clipped here by [appname].
 730 * To see the entire file, use an external editor.
 731 " d_@
 732                         }
 733                 }
 734                 $ui_diff conf -state disabled
 735                 set diff_active 0
 736                 unlock_index
 737                 set ui_status_value {Ready.}
 738                 return
 739         }
 740
 741         set cmd [list | git]
 742         if {$w eq $ui_index} {
 743                 lappend cmd diff-index
 744                 lappend cmd --cached
 745         } elseif {$w eq $ui_workdir} {
 746                 if {[string index $m 0] eq {U}} {
 747                         lappend cmd diff
 748                 } else {
 749                         lappend cmd diff-files
 750                 }
 751         }
 752
 753         lappend cmd -p
 754         lappend cmd --no-color
 755         if {$repo_config(gui.diffcontext) > 0} {
 756                 lappend cmd "-U$repo_config(gui.diffcontext)"
 757         }
 758         if {$w eq $ui_index} {
 759                 lappend cmd [PARENT]
 760         }
 761         lappend cmd --
 762         lappend cmd $path
 763
 764         if {[catch {set fd [open $cmd r]} err]} {
 765                 set diff_active 0
 766                 unlock_index
 767                 set ui_status_value "Unable to display [escape_path $path]"
 768                 error_popup "Error loading diff:\n\n$err"
 769                 return
 770         }
 771
 772         fconfigure $fd \
 773                 -blocking 0 \
 774                 -encoding binary \
 775                 -translation binary
 776         fileevent $fd readable [list read_diff $fd]
 777 }
 778
 779 proc read_diff {fd} {
 780         global ui_diff ui_status_value diff_active
 781         global is_3way_diff current_diff_header
 782
 783         $ui_diff conf -state normal
 784         while {[gets $fd line] >= 0} {
 785                 # -- Cleanup uninteresting diff header lines.
 786                 #
 787                 if {   [string match {diff --git *}      $line]
 788                         || [string match {diff --cc *}       $line]
 789                         || [string match {diff --combined *} $line]
 790                         || [string match {--- *}             $line]
 791                         || [string match {+++ *}             $line]} {
 792                         append current_diff_header $line "\n"
 793                         continue
 794                 }
 795                 if {[string match {index *} $line]} continue
 796                 if {$line eq {deleted file mode 120000}} {
 797                         set line "deleted symlink"
 798                 }
 799
 800                 # -- Automatically detect if this is a 3 way diff.
 801                 #
 802                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 803
 804                 if {[string match {mode *} $line]
 805                         || [string match {new file *} $line]
 806                         || [string match {deleted file *} $line]
 807                         || [string match {Binary files * and * differ} $line]
 808                         || $line eq {\ No newline at end of file}
 809                         || [regexp {^\* Unmerged path } $line]} {
 810                         set tags {}
 811                 } elseif {$is_3way_diff} {
 812                         set op [string range $line 0 1]
 813                         switch -- $op {
 814                         {  } {set tags {}}
 815                         {@@} {set tags d_@}
 816                         { +} {set tags d_s+}
 817                         { -} {set tags d_s-}
 818                         {+ } {set tags d_+s}
 819                         {- } {set tags d_-s}
 820                         {--} {set tags d_--}
 821                         {++} {
 822                                 if {[regexp {^\+\+([<>]{7} |={7})} $line _g op]} {
 823                                         set line [string replace $line 0 1 {  }]
 824                                         set tags d$op
 825                                 } else {
 826                                         set tags d_++
 827                                 }
 828                         }
 829                         default {
 830                                 puts "error: Unhandled 3 way diff marker: {$op}"
 831                                 set tags {}
 832                         }
 833                         }
 834                 } else {
 835                         set op [string index $line 0]
 836                         switch -- $op {
 837                         { } {set tags {}}
 838                         {@} {set tags d_@}
 839                         {-} {set tags d_-}
 840                         {+} {
 841                                 if {[regexp {^\+([<>]{7} |={7})} $line _g op]} {
 842                                         set line [string replace $line 0 0 { }]
 843                                         set tags d$op
 844                                 } else {
 845                                         set tags d_+
 846                                 }
 847                         }
 848                         default {
 849                                 puts "error: Unhandled 2 way diff marker: {$op}"
 850                                 set tags {}
 851                         }
 852                         }
 853                 }
 854                 $ui_diff insert end $line $tags
 855                 if {[string index $line end] eq "\r"} {
 856                         $ui_diff tag add d_cr {end - 2c}
 857                 }
 858                 $ui_diff insert end "\n" $tags
 859         }
 860         $ui_diff conf -state disabled
 861
 862         if {[eof $fd]} {
 863                 close $fd
 864                 set diff_active 0
 865                 unlock_index
 866                 set ui_status_value {Ready.}
 867
 868                 if {[$ui_diff index end] eq {2.0}} {
 869                         handle_empty_diff
 870                 }
 871         }
 872 }
 873
 874 proc apply_hunk {x y} {
 875         global current_diff_path current_diff_header current_diff_side
 876         global ui_diff ui_index file_states
 877
 878         if {$current_diff_path eq {} || $current_diff_header eq {}} return
 879         if {![lock_index apply_hunk]} return
 880
 881         set apply_cmd {git apply --cached --whitespace=nowarn}
 882         set mi [lindex $file_states($current_diff_path) 0]
 883         if {$current_diff_side eq $ui_index} {
 884                 set mode unstage
 885                 lappend apply_cmd --reverse
 886                 if {[string index $mi 0] ne {M}} {
 887                         unlock_index
 888                         return
 889                 }
 890         } else {
 891                 set mode stage
 892                 if {[string index $mi 1] ne {M}} {
 893                         unlock_index
 894                         return
 895                 }
 896         }
 897
 898         set s_lno [lindex [split [$ui_diff index @$x,$y] .] 0]
 899         set s_lno [$ui_diff search -backwards -regexp ^@@ $s_lno.0 0.0]
 900         if {$s_lno eq {}} {
 901                 unlock_index
 902                 return
 903         }
 904
 905         set e_lno [$ui_diff search -forwards -regexp ^@@ "$s_lno + 1 lines" end]
 906         if {$e_lno eq {}} {
 907                 set e_lno end
 908         }
 909
 910         if {[catch {
 911                 set p [open "| $apply_cmd" w]
 912                 fconfigure $p -translation binary -encoding binary
 913                 puts -nonewline $p $current_diff_header
 914                 puts -nonewline $p [$ui_diff get $s_lno $e_lno]
 915                 close $p} err]} {
 916                 error_popup "Failed to $mode selected hunk.\n\n$err"
 917                 unlock_index
 918                 return
 919         }
 920
 921         $ui_diff conf -state normal
 922         $ui_diff delete $s_lno $e_lno
 923         $ui_diff conf -state disabled
 924
 925         if {[$ui_diff get 1.0 end] eq "\n"} {
 926                 set o _
 927         } else {
 928                 set o ?
 929         }
 930
 931         if {$current_diff_side eq $ui_index} {
 932                 set mi ${o}M
 933         } elseif {[string index $mi 0] eq {_}} {
 934                 set mi M$o
 935         } else {
 936                 set mi ?$o
 937         }
 938         unlock_index
 939         display_file $current_diff_path $mi
 940         if {$o eq {_}} {
 941                 clear_diff
 942         }
 943 }
 944
 945 ######################################################################
 946 ##
 947 ## commit
 948
 949 proc load_last_commit {} {
 950         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 951         global repo_config
 952
 953         if {[llength $PARENT] == 0} {
 954                 error_popup {There is nothing to amend.
 955
 956 You are about to create the initial commit.
 957 There is no commit before this to amend.
 958 }
 959                 return
 960         }
 961
 962         repository_state curType curHEAD curMERGE_HEAD
 963         if {$curType eq {merge}} {
 964                 error_popup {Cannot amend while merging.
 965
 966 You are currently in the middle of a merge that
 967 has not been fully completed.  You cannot amend
 968 the prior commit unless you first abort the
 969 current merge activity.
 970 }
 971                 return
 972         }
 973
 974         set msg {}
 975         set parents [list]
 976         if {[catch {
 977                         set fd [open "| git cat-file commit $curHEAD" r]
 978                         fconfigure $fd -encoding binary -translation lf
 979                         if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
 980                                 set enc utf-8
 981                         }
 982                         while {[gets $fd line] > 0} {
 983                                 if {[string match {parent *} $line]} {
 984                                         lappend parents [string range $line 7 end]
 985                                 } elseif {[string match {encoding *} $line]} {
 986                                         set enc [string tolower [string range $line 9 end]]
 987                                 }
 988                         }
 989                         fconfigure $fd -encoding $enc
 990                         set msg [string trim [read $fd]]
 991                         close $fd
 992                 } err]} {
 993                 error_popup "Error loading commit data for amend:\n\n$err"
 994                 return
 995         }
 996
 997         set HEAD $curHEAD
 998         set PARENT $parents
 999         set MERGE_HEAD [list]
1000         switch -- [llength $parents] {
1001         0       {set commit_type amend-initial}
1002         1       {set commit_type amend}
1003         default {set commit_type amend-merge}
1004         }
1005
1006         $ui_comm delete 0.0 end
1007         $ui_comm insert end $msg
1008         $ui_comm edit reset
1009         $ui_comm edit modified false
1010         rescan {set ui_status_value {Ready.}}
1011 }
1012
1013 proc create_new_commit {} {
1014         global commit_type ui_comm
1015
1016         set commit_type normal
1017         $ui_comm delete 0.0 end
1018         $ui_comm edit reset
1019         $ui_comm edit modified false
1020         rescan {set ui_status_value {Ready.}}
1021 }
1022
1023 set GIT_COMMITTER_IDENT {}
1024
1025 proc committer_ident {} {
1026         global GIT_COMMITTER_IDENT
1027
1028         if {$GIT_COMMITTER_IDENT eq {}} {
1029                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
1030                         error_popup "Unable to obtain your identity:\n\n$err"
1031                         return {}
1032                 }
1033                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
1034                         $me me GIT_COMMITTER_IDENT]} {
1035                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
1036                         return {}
1037                 }
1038         }
1039
1040         return $GIT_COMMITTER_IDENT
1041 }
1042
1043 proc commit_tree {} {
1044         global HEAD commit_type file_states ui_comm repo_config
1045         global ui_status_value pch_error
1046
1047         if {[committer_ident] eq {}} return
1048         if {![lock_index update]} return
1049
1050         # -- Our in memory state should match the repository.
1051         #
1052         repository_state curType curHEAD curMERGE_HEAD
1053         if {[string match amend* $commit_type]
1054                 && $curType eq {normal}
1055                 && $curHEAD eq $HEAD} {
1056         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
1057                 info_popup {Last scanned state does not match repository state.
1058
1059 Another Git program has modified this repository
1060 since the last scan.  A rescan must be performed
1061 before another commit can be created.
1062
1063 The rescan will be automatically started now.
1064 }
1065                 unlock_index
1066                 rescan {set ui_status_value {Ready.}}
1067                 return
1068         }
1069
1070         # -- At least one file should differ in the index.
1071         #
1072         set files_ready 0
1073         foreach path [array names file_states] {
1074                 switch -glob -- [lindex $file_states($path) 0] {
1075                 _? {continue}
1076                 A? -
1077                 D? -
1078                 M? {set files_ready 1}
1079                 U? {
1080                         error_popup "Unmerged files cannot be committed.
1081
1082 File [short_path $path] has merge conflicts.
1083 You must resolve them and add the file before committing.
1084 "
1085                         unlock_index
1086                         return
1087                 }
1088                 default {
1089                         error_popup "Unknown file state [lindex $s 0] detected.
1090
1091 File [short_path $path] cannot be committed by this program.
1092 "
1093                 }
1094                 }
1095         }
1096         if {!$files_ready} {
1097                 info_popup {No changes to commit.
1098
1099 You must add at least 1 file before you can commit.
1100 }
1101                 unlock_index
1102                 return
1103         }
1104
1105         # -- A message is required.
1106         #
1107         set msg [string trim [$ui_comm get 1.0 end]]
1108         regsub -all -line {[ \t\r]+$} $msg {} msg
1109         if {$msg eq {}} {
1110                 error_popup {Please supply a commit message.
1111
1112 A good commit message has the following format:
1113
1114 - First line: Describe in one sentance what you did.
1115 - Second line: Blank
1116 - Remaining lines: Describe why this change is good.
1117 }
1118                 unlock_index
1119                 return
1120         }
1121
1122         # -- Run the pre-commit hook.
1123         #
1124         set pchook [gitdir hooks pre-commit]
1125
1126         # On Cygwin [file executable] might lie so we need to ask
1127         # the shell if the hook is executable.  Yes that's annoying.
1128         #
1129         if {[is_Cygwin] && [file isfile $pchook]} {
1130                 set pchook [list sh -c [concat \
1131                         "if test -x \"$pchook\";" \
1132                         "then exec \"$pchook\" 2>&1;" \
1133                         "fi"]]
1134         } elseif {[file executable $pchook]} {
1135                 set pchook [list $pchook |& cat]
1136         } else {
1137                 commit_writetree $curHEAD $msg
1138                 return
1139         }
1140
1141         set ui_status_value {Calling pre-commit hook...}
1142         set pch_error {}
1143         set fd_ph [open "| $pchook" r]
1144         fconfigure $fd_ph -blocking 0 -translation binary
1145         fileevent $fd_ph readable \
1146                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
1147 }
1148
1149 proc commit_prehook_wait {fd_ph curHEAD msg} {
1150         global pch_error ui_status_value
1151
1152         append pch_error [read $fd_ph]
1153         fconfigure $fd_ph -blocking 1
1154         if {[eof $fd_ph]} {
1155                 if {[catch {close $fd_ph}]} {
1156                         set ui_status_value {Commit declined by pre-commit hook.}
1157                         hook_failed_popup pre-commit $pch_error
1158                         unlock_index
1159                 } else {
1160                         commit_writetree $curHEAD $msg
1161                 }
1162                 set pch_error {}
1163                 return
1164         }
1165         fconfigure $fd_ph -blocking 0
1166 }
1167
1168 proc commit_writetree {curHEAD msg} {
1169         global ui_status_value
1170
1171         set ui_status_value {Committing changes...}
1172         set fd_wt [open "| git write-tree" r]
1173         fileevent $fd_wt readable \
1174                 [list commit_committree $fd_wt $curHEAD $msg]
1175 }
1176
1177 proc commit_committree {fd_wt curHEAD msg} {
1178         global HEAD PARENT MERGE_HEAD commit_type
1179         global single_commit all_heads current_branch
1180         global ui_status_value ui_comm selected_commit_type
1181         global file_states selected_paths rescan_active
1182         global repo_config
1183
1184         gets $fd_wt tree_id
1185         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
1186                 error_popup "write-tree failed:\n\n$err"
1187                 set ui_status_value {Commit failed.}
1188                 unlock_index
1189                 return
1190         }
1191
1192         # -- Build the message.
1193         #
1194         set msg_p [gitdir COMMIT_EDITMSG]
1195         set msg_wt [open $msg_p w]
1196         if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
1197                 set enc utf-8
1198         }
1199         fconfigure $msg_wt -encoding $enc -translation binary
1200         puts -nonewline $msg_wt $msg
1201         close $msg_wt
1202
1203         # -- Create the commit.
1204         #
1205         set cmd [list git commit-tree $tree_id]
1206         set parents [concat $PARENT $MERGE_HEAD]
1207         if {[llength $parents] > 0} {
1208                 foreach p $parents {
1209                         lappend cmd -p $p
1210                 }
1211         } else {
1212                 # git commit-tree writes to stderr during initial commit.
1213                 lappend cmd 2>/dev/null
1214         }
1215         lappend cmd <$msg_p
1216         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1217                 error_popup "commit-tree failed:\n\n$err"
1218                 set ui_status_value {Commit failed.}
1219                 unlock_index
1220                 return
1221         }
1222
1223         # -- Update the HEAD ref.
1224         #
1225         set reflogm commit
1226         if {$commit_type ne {normal}} {
1227                 append reflogm " ($commit_type)"
1228         }
1229         set i [string first "\n" $msg]
1230         if {$i >= 0} {
1231                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1232         } else {
1233                 append reflogm {: } $msg
1234         }
1235         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1236         if {[catch {eval exec $cmd} err]} {
1237                 error_popup "update-ref failed:\n\n$err"
1238                 set ui_status_value {Commit failed.}
1239                 unlock_index
1240                 return
1241         }
1242
1243         # -- Make sure our current branch exists.
1244         #
1245         if {$commit_type eq {initial}} {
1246                 lappend all_heads $current_branch
1247                 set all_heads [lsort -unique $all_heads]
1248                 populate_branch_menu
1249         }
1250
1251         # -- Cleanup after ourselves.
1252         #
1253         catch {file delete $msg_p}
1254         catch {file delete [gitdir MERGE_HEAD]}
1255         catch {file delete [gitdir MERGE_MSG]}
1256         catch {file delete [gitdir SQUASH_MSG]}
1257         catch {file delete [gitdir GITGUI_MSG]}
1258
1259         # -- Let rerere do its thing.
1260         #
1261         if {[file isdirectory [gitdir rr-cache]]} {
1262                 catch {exec git rerere}
1263         }
1264
1265         # -- Run the post-commit hook.
1266         #
1267         set pchook [gitdir hooks post-commit]
1268         if {[is_Cygwin] && [file isfile $pchook]} {
1269                 set pchook [list sh -c [concat \
1270                         "if test -x \"$pchook\";" \
1271                         "then exec \"$pchook\";" \
1272                         "fi"]]
1273         } elseif {![file executable $pchook]} {
1274                 set pchook {}
1275         }
1276         if {$pchook ne {}} {
1277                 catch {exec $pchook &}
1278         }
1279
1280         $ui_comm delete 0.0 end
1281         $ui_comm edit reset
1282         $ui_comm edit modified false
1283
1284         if {$single_commit} do_quit
1285
1286         # -- Update in memory status
1287         #
1288         set selected_commit_type new
1289         set commit_type normal
1290         set HEAD $cmt_id
1291         set PARENT $cmt_id
1292         set MERGE_HEAD [list]
1293
1294         foreach path [array names file_states] {
1295                 set s $file_states($path)
1296                 set m [lindex $s 0]
1297                 switch -glob -- $m {
1298                 _O -
1299                 _M -
1300                 _D {continue}
1301                 __ -
1302                 A_ -
1303                 M_ -
1304                 D_ {
1305                         unset file_states($path)
1306                         catch {unset selected_paths($path)}
1307                 }
1308                 DO {
1309                         set file_states($path) [list _O [lindex $s 1] {} {}]
1310                 }
1311                 AM -
1312                 AD -
1313                 MM -
1314                 MD {
1315                         set file_states($path) [list \
1316                                 _[string index $m 1] \
1317                                 [lindex $s 1] \
1318                                 [lindex $s 3] \
1319                                 {}]
1320                 }
1321                 }
1322         }
1323
1324         display_all_files
1325         unlock_index
1326         reshow_diff
1327         set ui_status_value \
1328                 "Changes committed as [string range $cmt_id 0 7]."
1329 }
1330
1331 ######################################################################
1332 ##
1333 ## fetch push
1334
1335 proc fetch_from {remote} {
1336         set w [new_console \
1337                 "fetch $remote" \
1338                 "Fetching new changes from $remote"]
1339         set cmd [list git fetch]
1340         lappend cmd $remote
1341         console_exec $w $cmd console_done
1342 }
1343
1344 proc push_to {remote} {
1345         set w [new_console \
1346                 "push $remote" \
1347                 "Pushing changes to $remote"]
1348         set cmd [list git push]
1349         lappend cmd -v
1350         lappend cmd $remote
1351         console_exec $w $cmd console_done
1352 }
1353
1354 ######################################################################
1355 ##
1356 ## ui helpers
1357
1358 proc mapicon {w state path} {
1359         global all_icons
1360
1361         if {[catch {set r $all_icons($state$w)}]} {
1362                 puts "error: no icon for $w state={$state} $path"
1363                 return file_plain
1364         }
1365         return $r
1366 }
1367
1368 proc mapdesc {state path} {
1369         global all_descs
1370
1371         if {[catch {set r $all_descs($state)}]} {
1372                 puts "error: no desc for state={$state} $path"
1373                 return $state
1374         }
1375         return $r
1376 }
1377
1378 proc escape_path {path} {
1379         regsub -all "\n" $path "\\n" path
1380         return $path
1381 }
1382
1383 proc short_path {path} {
1384         return [escape_path [lindex [file split $path] end]]
1385 }
1386
1387 set next_icon_id 0
1388 set null_sha1 [string repeat 0 40]
1389
1390 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1391         global file_states next_icon_id null_sha1
1392
1393         set s0 [string index $new_state 0]
1394         set s1 [string index $new_state 1]
1395
1396         if {[catch {set info $file_states($path)}]} {
1397                 set state __
1398                 set icon n[incr next_icon_id]
1399         } else {
1400                 set state [lindex $info 0]
1401                 set icon [lindex $info 1]
1402                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1403                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1404         }
1405
1406         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1407         elseif {$s0 eq {_}} {set s0 _}
1408
1409         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1410         elseif {$s1 eq {_}} {set s1 _}
1411
1412         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1413                 set head_info [list 0 $null_sha1]
1414         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1415                 && $head_info eq {}} {
1416                 set head_info $index_info
1417         }
1418
1419         set file_states($path) [list $s0$s1 $icon \
1420                 $head_info $index_info \
1421                 ]
1422         return $state
1423 }
1424
1425 proc display_file_helper {w path icon_name old_m new_m} {
1426         global file_lists
1427
1428         if {$new_m eq {_}} {
1429                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1430                 if {$lno >= 0} {
1431                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1432                         incr lno
1433                         $w conf -state normal
1434                         $w delete $lno.0 [expr {$lno + 1}].0
1435                         $w conf -state disabled
1436                 }
1437         } elseif {$old_m eq {_} && $new_m ne {_}} {
1438                 lappend file_lists($w) $path
1439                 set file_lists($w) [lsort -unique $file_lists($w)]
1440                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1441                 incr lno
1442                 $w conf -state normal
1443                 $w image create $lno.0 \
1444                         -align center -padx 5 -pady 1 \
1445                         -name $icon_name \
1446                         -image [mapicon $w $new_m $path]
1447                 $w insert $lno.1 "[escape_path $path]\n"
1448                 $w conf -state disabled
1449         } elseif {$old_m ne $new_m} {
1450                 $w conf -state normal
1451                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1452                 $w conf -state disabled
1453         }
1454 }
1455
1456 proc display_file {path state} {
1457         global file_states selected_paths
1458         global ui_index ui_workdir
1459
1460         set old_m [merge_state $path $state]
1461         set s $file_states($path)
1462         set new_m [lindex $s 0]
1463         set icon_name [lindex $s 1]
1464
1465         set o [string index $old_m 0]
1466         set n [string index $new_m 0]
1467         if {$o eq {U}} {
1468                 set o _
1469         }
1470         if {$n eq {U}} {
1471                 set n _
1472         }
1473         display_file_helper     $ui_index $path $icon_name $o $n
1474
1475         if {[string index $old_m 0] eq {U}} {
1476                 set o U
1477         } else {
1478                 set o [string index $old_m 1]
1479         }
1480         if {[string index $new_m 0] eq {U}} {
1481                 set n U
1482         } else {
1483                 set n [string index $new_m 1]
1484         }
1485         display_file_helper     $ui_workdir $path $icon_name $o $n
1486
1487         if {$new_m eq {__}} {
1488                 unset file_states($path)
1489                 catch {unset selected_paths($path)}
1490         }
1491 }
1492
1493 proc display_all_files_helper {w path icon_name m} {
1494         global file_lists
1495
1496         lappend file_lists($w) $path
1497         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1498         $w image create end \
1499                 -align center -padx 5 -pady 1 \
1500                 -name $icon_name \
1501                 -image [mapicon $w $m $path]
1502         $w insert end "[escape_path $path]\n"
1503 }
1504
1505 proc display_all_files {} {
1506         global ui_index ui_workdir
1507         global file_states file_lists
1508         global last_clicked
1509
1510         $ui_index conf -state normal
1511         $ui_workdir conf -state normal
1512
1513         $ui_index delete 0.0 end
1514         $ui_workdir delete 0.0 end
1515         set last_clicked {}
1516
1517         set file_lists($ui_index) [list]
1518         set file_lists($ui_workdir) [list]
1519
1520         foreach path [lsort [array names file_states]] {
1521                 set s $file_states($path)
1522                 set m [lindex $s 0]
1523                 set icon_name [lindex $s 1]
1524
1525                 set s [string index $m 0]
1526                 if {$s ne {U} && $s ne {_}} {
1527                         display_all_files_helper $ui_index $path \
1528                                 $icon_name $s
1529                 }
1530
1531                 if {[string index $m 0] eq {U}} {
1532                         set s U
1533                 } else {
1534                         set s [string index $m 1]
1535                 }
1536                 if {$s ne {_}} {
1537                         display_all_files_helper $ui_workdir $path \
1538                                 $icon_name $s
1539                 }
1540         }
1541
1542         $ui_index conf -state disabled
1543         $ui_workdir conf -state disabled
1544 }
1545
1546 proc update_indexinfo {msg pathList after} {
1547         global update_index_cp ui_status_value
1548
1549         if {![lock_index update]} return
1550
1551         set update_index_cp 0
1552         set pathList [lsort $pathList]
1553         set totalCnt [llength $pathList]
1554         set batch [expr {int($totalCnt * .01) + 1}]
1555         if {$batch > 25} {set batch 25}
1556
1557         set ui_status_value [format \
1558                 "$msg... %i/%i files (%.2f%%)" \
1559                 $update_index_cp \
1560                 $totalCnt \
1561                 0.0]
1562         set fd [open "| git update-index -z --index-info" w]
1563         fconfigure $fd \
1564                 -blocking 0 \
1565                 -buffering full \
1566                 -buffersize 512 \
1567                 -encoding binary \
1568                 -translation binary
1569         fileevent $fd writable [list \
1570                 write_update_indexinfo \
1571                 $fd \
1572                 $pathList \
1573                 $totalCnt \
1574                 $batch \
1575                 $msg \
1576                 $after \
1577                 ]
1578 }
1579
1580 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1581         global update_index_cp ui_status_value
1582         global file_states current_diff_path
1583
1584         if {$update_index_cp >= $totalCnt} {
1585                 close $fd
1586                 unlock_index
1587                 uplevel #0 $after
1588                 return
1589         }
1590
1591         for {set i $batch} \
1592                 {$update_index_cp < $totalCnt && $i > 0} \
1593                 {incr i -1} {
1594                 set path [lindex $pathList $update_index_cp]
1595                 incr update_index_cp
1596
1597                 set s $file_states($path)
1598                 switch -glob -- [lindex $s 0] {
1599                 A? {set new _O}
1600                 M? {set new _M}
1601                 D_ {set new _D}
1602                 D? {set new _?}
1603                 ?? {continue}
1604                 }
1605                 set info [lindex $s 2]
1606                 if {$info eq {}} continue
1607
1608                 puts -nonewline $fd "$info\t[encoding convertto $path]\0"
1609                 display_file $path $new
1610         }
1611
1612         set ui_status_value [format \
1613                 "$msg... %i/%i files (%.2f%%)" \
1614                 $update_index_cp \
1615                 $totalCnt \
1616                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1617 }
1618
1619 proc update_index {msg pathList after} {
1620         global update_index_cp ui_status_value
1621
1622         if {![lock_index update]} return
1623
1624         set update_index_cp 0
1625         set pathList [lsort $pathList]
1626         set totalCnt [llength $pathList]
1627         set batch [expr {int($totalCnt * .01) + 1}]
1628         if {$batch > 25} {set batch 25}
1629
1630         set ui_status_value [format \
1631                 "$msg... %i/%i files (%.2f%%)" \
1632                 $update_index_cp \
1633                 $totalCnt \
1634                 0.0]
1635         set fd [open "| git update-index --add --remove -z --stdin" w]
1636         fconfigure $fd \
1637                 -blocking 0 \
1638                 -buffering full \
1639                 -buffersize 512 \
1640                 -encoding binary \
1641                 -translation binary
1642         fileevent $fd writable [list \
1643                 write_update_index \
1644                 $fd \
1645                 $pathList \
1646                 $totalCnt \
1647                 $batch \
1648                 $msg \
1649                 $after \
1650                 ]
1651 }
1652
1653 proc write_update_index {fd pathList totalCnt batch msg after} {
1654         global update_index_cp ui_status_value
1655         global file_states current_diff_path
1656
1657         if {$update_index_cp >= $totalCnt} {
1658                 close $fd
1659                 unlock_index
1660                 uplevel #0 $after
1661                 return
1662         }
1663
1664         for {set i $batch} \
1665                 {$update_index_cp < $totalCnt && $i > 0} \
1666                 {incr i -1} {
1667                 set path [lindex $pathList $update_index_cp]
1668                 incr update_index_cp
1669
1670                 switch -glob -- [lindex $file_states($path) 0] {
1671                 AD {set new __}
1672                 ?D {set new D_}
1673                 _O -
1674                 AM {set new A_}
1675                 U? {
1676                         if {[file exists $path]} {
1677                                 set new M_
1678                         } else {
1679                                 set new D_
1680                         }
1681                 }
1682                 ?M {set new M_}
1683                 ?? {continue}
1684                 }
1685                 puts -nonewline $fd "[encoding convertto $path]\0"
1686                 display_file $path $new
1687         }
1688
1689         set ui_status_value [format \
1690                 "$msg... %i/%i files (%.2f%%)" \
1691                 $update_index_cp \
1692                 $totalCnt \
1693                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1694 }
1695
1696 proc checkout_index {msg pathList after} {
1697         global update_index_cp ui_status_value
1698
1699         if {![lock_index update]} return
1700
1701         set update_index_cp 0
1702         set pathList [lsort $pathList]
1703         set totalCnt [llength $pathList]
1704         set batch [expr {int($totalCnt * .01) + 1}]
1705         if {$batch > 25} {set batch 25}
1706
1707         set ui_status_value [format \
1708                 "$msg... %i/%i files (%.2f%%)" \
1709                 $update_index_cp \
1710                 $totalCnt \
1711                 0.0]
1712         set cmd [list git checkout-index]
1713         lappend cmd --index
1714         lappend cmd --quiet
1715         lappend cmd --force
1716         lappend cmd -z
1717         lappend cmd --stdin
1718         set fd [open "| $cmd " w]
1719         fconfigure $fd \
1720                 -blocking 0 \
1721                 -buffering full \
1722                 -buffersize 512 \
1723                 -encoding binary \
1724                 -translation binary
1725         fileevent $fd writable [list \
1726                 write_checkout_index \
1727                 $fd \
1728                 $pathList \
1729                 $totalCnt \
1730                 $batch \
1731                 $msg \
1732                 $after \
1733                 ]
1734 }
1735
1736 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1737         global update_index_cp ui_status_value
1738         global file_states current_diff_path
1739
1740         if {$update_index_cp >= $totalCnt} {
1741                 close $fd
1742                 unlock_index
1743                 uplevel #0 $after
1744                 return
1745         }
1746
1747         for {set i $batch} \
1748                 {$update_index_cp < $totalCnt && $i > 0} \
1749                 {incr i -1} {
1750                 set path [lindex $pathList $update_index_cp]
1751                 incr update_index_cp
1752                 switch -glob -- [lindex $file_states($path) 0] {
1753                 U? {continue}
1754                 ?M -
1755                 ?D {
1756                         puts -nonewline $fd "[encoding convertto $path]\0"
1757                         display_file $path ?_
1758                 }
1759                 }
1760         }
1761
1762         set ui_status_value [format \
1763                 "$msg... %i/%i files (%.2f%%)" \
1764                 $update_index_cp \
1765                 $totalCnt \
1766                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1767 }
1768
1769 ######################################################################
1770 ##
1771 ## branch management
1772
1773 proc is_tracking_branch {name} {
1774         global tracking_branches
1775
1776         if {![catch {set info $tracking_branches($name)}]} {
1777                 return 1
1778         }
1779         foreach t [array names tracking_branches] {
1780                 if {[string match {*/\*} $t] && [string match $t $name]} {
1781                         return 1
1782                 }
1783         }
1784         return 0
1785 }
1786
1787 proc load_all_heads {} {
1788         global all_heads
1789
1790         set all_heads [list]
1791         set fd [open "| git for-each-ref --format=%(refname) refs/heads" r]
1792         while {[gets $fd line] > 0} {
1793                 if {[is_tracking_branch $line]} continue
1794                 if {![regsub ^refs/heads/ $line {} name]} continue
1795                 lappend all_heads $name
1796         }
1797         close $fd
1798
1799         set all_heads [lsort $all_heads]
1800 }
1801
1802 proc populate_branch_menu {} {
1803         global all_heads disable_on_lock
1804
1805         set m .mbar.branch
1806         set last [$m index last]
1807         for {set i 0} {$i <= $last} {incr i} {
1808                 if {[$m type $i] eq {separator}} {
1809                         $m delete $i last
1810                         set new_dol [list]
1811                         foreach a $disable_on_lock {
1812                                 if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
1813                                         lappend new_dol $a
1814                                 }
1815                         }
1816                         set disable_on_lock $new_dol
1817                         break
1818                 }
1819         }
1820
1821         if {$all_heads ne {}} {
1822                 $m add separator
1823         }
1824         foreach b $all_heads {
1825                 $m add radiobutton \
1826                         -label $b \
1827                         -command [list switch_branch $b] \
1828                         -variable current_branch \
1829                         -value $b \
1830                         -font font_ui
1831                 lappend disable_on_lock \
1832                         [list $m entryconf [$m index last] -state]
1833         }
1834 }
1835
1836 proc all_tracking_branches {} {
1837         global tracking_branches
1838
1839         set all_trackings {}
1840         set cmd {}
1841         foreach name [array names tracking_branches] {
1842                 if {[regsub {/\*$} $name {} name]} {
1843                         lappend cmd $name
1844                 } else {
1845                         regsub ^refs/(heads|remotes)/ $name {} name
1846                         lappend all_trackings $name
1847                 }
1848         }
1849
1850         if {$cmd ne {}} {
1851                 set fd [open "| git for-each-ref --format=%(refname) $cmd" r]
1852                 while {[gets $fd name] > 0} {
1853                         regsub ^refs/(heads|remotes)/ $name {} name
1854                         lappend all_trackings $name
1855                 }
1856                 close $fd
1857         }
1858
1859         return [lsort -unique $all_trackings]
1860 }
1861
1862 proc do_create_branch_action {w} {
1863         global all_heads null_sha1 repo_config
1864         global create_branch_checkout create_branch_revtype
1865         global create_branch_head create_branch_trackinghead
1866         global create_branch_name create_branch_revexp
1867
1868         set newbranch $create_branch_name
1869         if {$newbranch eq {}
1870                 || $newbranch eq $repo_config(gui.newbranchtemplate)} {
1871                 tk_messageBox \
1872                         -icon error \
1873                         -type ok \
1874                         -title [wm title $w] \
1875                         -parent $w \
1876                         -message "Please supply a branch name."
1877                 focus $w.desc.name_t
1878                 return
1879         }
1880         if {![catch {exec git show-ref --verify -- "refs/heads/$newbranch"}]} {
1881                 tk_messageBox \
1882                         -icon error \
1883                         -type ok \
1884                         -title [wm title $w] \
1885                         -parent $w \
1886                         -message "Branch '$newbranch' already exists."
1887                 focus $w.desc.name_t
1888                 return
1889         }
1890         if {[catch {exec git check-ref-format "heads/$newbranch"}]} {
1891                 tk_messageBox \
1892                         -icon error \
1893                         -type ok \
1894                         -title [wm title $w] \
1895                         -parent $w \
1896                         -message "We do not like '$newbranch' as a branch name."
1897                 focus $w.desc.name_t
1898                 return
1899         }
1900
1901         set rev {}
1902         switch -- $create_branch_revtype {
1903         head {set rev $create_branch_head}
1904         tracking {set rev $create_branch_trackinghead}
1905         expression {set rev $create_branch_revexp}
1906         }
1907         if {[catch {set cmt [exec git rev-parse --verify "${rev}^0"]}]} {
1908                 tk_messageBox \
1909                         -icon error \
1910                         -type ok \
1911                         -title [wm title $w] \
1912                         -parent $w \
1913                         -message "Invalid starting revision: $rev"
1914                 return
1915         }
1916         set cmd [list git update-ref]
1917         lappend cmd -m
1918         lappend cmd "branch: Created from $rev"
1919         lappend cmd "refs/heads/$newbranch"
1920         lappend cmd $cmt
1921         lappend cmd $null_sha1
1922         if {[catch {eval exec $cmd} err]} {
1923                 tk_messageBox \
1924                         -icon error \
1925                         -type ok \
1926                         -title [wm title $w] \
1927                         -parent $w \
1928                         -message "Failed to create '$newbranch'.\n\n$err"
1929                 return
1930         }
1931
1932         lappend all_heads $newbranch
1933         set all_heads [lsort $all_heads]
1934         populate_branch_menu
1935         destroy $w
1936         if {$create_branch_checkout} {
1937                 switch_branch $newbranch
1938         }
1939 }
1940
1941 proc radio_selector {varname value args} {
1942         upvar #0 $varname var
1943         set var $value
1944 }
1945
1946 trace add variable create_branch_head write \
1947         [list radio_selector create_branch_revtype head]
1948 trace add variable create_branch_trackinghead write \
1949         [list radio_selector create_branch_revtype tracking]
1950
1951 trace add variable delete_branch_head write \
1952         [list radio_selector delete_branch_checktype head]
1953 trace add variable delete_branch_trackinghead write \
1954         [list radio_selector delete_branch_checktype tracking]
1955
1956 proc do_create_branch {} {
1957         global all_heads current_branch repo_config
1958         global create_branch_checkout create_branch_revtype
1959         global create_branch_head create_branch_trackinghead
1960         global create_branch_name create_branch_revexp
1961
1962         set w .branch_editor
1963         toplevel $w
1964         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1965
1966         label $w.header -text {Create New Branch} \
1967                 -font font_uibold
1968         pack $w.header -side top -fill x
1969
1970         frame $w.buttons
1971         button $w.buttons.create -text Create \
1972                 -font font_ui \
1973                 -default active \
1974                 -command [list do_create_branch_action $w]
1975         pack $w.buttons.create -side right
1976         button $w.buttons.cancel -text {Cancel} \
1977                 -font font_ui \
1978                 -command [list destroy $w]
1979         pack $w.buttons.cancel -side right -padx 5
1980         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1981
1982         labelframe $w.desc \
1983                 -text {Branch Description} \
1984                 -font font_ui
1985         label $w.desc.name_l -text {Name:} -font font_ui
1986         entry $w.desc.name_t \
1987                 -borderwidth 1 \
1988                 -relief sunken \
1989                 -width 40 \
1990                 -textvariable create_branch_name \
1991                 -font font_ui \
1992                 -validate key \
1993                 -validatecommand {
1994                         if {%d == 1 && [regexp {[~^:?*\[\0- ]} %S]} {return 0}
1995                         return 1
1996                 }
1997         grid $w.desc.name_l $w.desc.name_t -sticky we -padx {0 5}
1998         grid columnconfigure $w.desc 1 -weight 1
1999         pack $w.desc -anchor nw -fill x -pady 5 -padx 5
2000
2001         labelframe $w.from \
2002                 -text {Starting Revision} \
2003                 -font font_ui
2004         radiobutton $w.from.head_r \
2005                 -text {Local Branch:} \
2006                 -value head \
2007                 -variable create_branch_revtype \
2008                 -font font_ui
2009         eval tk_optionMenu $w.from.head_m create_branch_head $all_heads
2010         grid $w.from.head_r $w.from.head_m -sticky w
2011         set all_trackings [all_tracking_branches]
2012         if {$all_trackings ne {}} {
2013                 set create_branch_trackinghead [lindex $all_trackings 0]
2014                 radiobutton $w.from.tracking_r \
2015                         -text {Tracking Branch:} \
2016                         -value tracking \
2017                         -variable create_branch_revtype \
2018                         -font font_ui
2019                 eval tk_optionMenu $w.from.tracking_m \
2020                         create_branch_trackinghead \
2021                         $all_trackings
2022                 grid $w.from.tracking_r $w.from.tracking_m -sticky w
2023         }
2024         radiobutton $w.from.exp_r \
2025                 -text {Revision Expression:} \
2026                 -value expression \
2027                 -variable create_branch_revtype \
2028                 -font font_ui
2029         entry $w.from.exp_t \
2030                 -borderwidth 1 \
2031                 -relief sunken \
2032                 -width 50 \
2033                 -textvariable create_branch_revexp \
2034                 -font font_ui \
2035                 -validate key \
2036                 -validatecommand {
2037                         if {%d == 1 && [regexp {\s} %S]} {return 0}
2038                         if {%d == 1 && [string length %S] > 0} {
2039                                 set create_branch_revtype expression
2040                         }
2041                         return 1
2042                 }
2043         grid $w.from.exp_r $w.from.exp_t -sticky we -padx {0 5}
2044         grid columnconfigure $w.from 1 -weight 1
2045         pack $w.from -anchor nw -fill x -pady 5 -padx 5
2046
2047         labelframe $w.postActions \
2048                 -text {Post Creation Actions} \
2049                 -font font_ui
2050         checkbutton $w.postActions.checkout \
2051                 -text {Checkout after creation} \
2052                 -variable create_branch_checkout \
2053                 -font font_ui
2054         pack $w.postActions.checkout -anchor nw
2055         pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
2056
2057         set create_branch_checkout 1
2058         set create_branch_head $current_branch
2059         set create_branch_revtype head
2060         set create_branch_name $repo_config(gui.newbranchtemplate)
2061         set create_branch_revexp {}
2062
2063         bind $w <Visibility> "
2064                 grab $w
2065                 $w.desc.name_t icursor end
2066                 focus $w.desc.name_t
2067         "
2068         bind $w <Key-Escape> "destroy $w"
2069         bind $w <Key-Return> "do_create_branch_action $w;break"
2070         wm title $w "[appname] ([reponame]): Create Branch"
2071         tkwait window $w
2072 }
2073
2074 proc do_delete_branch_action {w} {
2075         global all_heads
2076         global delete_branch_checktype delete_branch_head delete_branch_trackinghead
2077
2078         set check_rev {}
2079         switch -- $delete_branch_checktype {
2080         head {set check_rev $delete_branch_head}
2081         tracking {set check_rev $delete_branch_trackinghead}
2082         always {set check_rev {:none}}
2083         }
2084         if {$check_rev eq {:none}} {
2085                 set check_cmt {}
2086         } elseif {[catch {set check_cmt [exec git rev-parse --verify "${check_rev}^0"]}]} {
2087                 tk_messageBox \
2088                         -icon error \
2089                         -type ok \
2090                         -title [wm title $w] \
2091                         -parent $w \
2092                         -message "Invalid check revision: $check_rev"
2093                 return
2094         }
2095
2096         set to_delete [list]
2097         set not_merged [list]
2098         foreach i [$w.list.l curselection] {
2099                 set b [$w.list.l get $i]
2100                 if {[catch {set o [exec git rev-parse --verify $b]}]} continue
2101                 if {$check_cmt ne {}} {
2102                         if {$b eq $check_rev} continue
2103                         if {[catch {set m [exec git merge-base $o $check_cmt]}]} continue
2104                         if {$o ne $m} {
2105                                 lappend not_merged $b
2106                                 continue
2107                         }
2108                 }
2109                 lappend to_delete [list $b $o]
2110         }
2111         if {$not_merged ne {}} {
2112                 set msg "The following branches are not completely merged into $check_rev:
2113
2114  - [join $not_merged "\n - "]"
2115                 tk_messageBox \
2116                         -icon info \
2117                         -type ok \
2118                         -title [wm title $w] \
2119                         -parent $w \
2120                         -message $msg
2121         }
2122         if {$to_delete eq {}} return
2123         if {$delete_branch_checktype eq {always}} {
2124                 set msg {Recovering deleted branches is difficult.
2125
2126 Delete the selected branches?}
2127                 if {[tk_messageBox \
2128                         -icon warning \
2129                         -type yesno \
2130                         -title [wm title $w] \
2131                         -parent $w \
2132                         -message $msg] ne yes} {
2133                         return
2134                 }
2135         }
2136
2137         set failed {}
2138         foreach i $to_delete {
2139                 set b [lindex $i 0]
2140                 set o [lindex $i 1]
2141                 if {[catch {exec git update-ref -d "refs/heads/$b" $o} err]} {
2142                         append failed " - $b: $err\n"
2143                 } else {
2144                         set x [lsearch -sorted -exact $all_heads $b]
2145                         if {$x >= 0} {
2146                                 set all_heads [lreplace $all_heads $x $x]
2147                         }
2148                 }
2149         }
2150
2151         if {$failed ne {}} {
2152                 tk_messageBox \
2153                         -icon error \
2154                         -type ok \
2155                         -title [wm title $w] \
2156                         -parent $w \
2157                         -message "Failed to delete branches:\n$failed"
2158         }
2159
2160         set all_heads [lsort $all_heads]
2161         populate_branch_menu
2162         destroy $w
2163 }
2164
2165 proc do_delete_branch {} {
2166         global all_heads tracking_branches current_branch
2167         global delete_branch_checktype delete_branch_head delete_branch_trackinghead
2168
2169         set w .branch_editor
2170         toplevel $w
2171         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2172
2173         label $w.header -text {Delete Local Branch} \
2174                 -font font_uibold
2175         pack $w.header -side top -fill x
2176
2177         frame $w.buttons
2178         button $w.buttons.create -text Delete \
2179                 -font font_ui \
2180                 -command [list do_delete_branch_action $w]
2181         pack $w.buttons.create -side right
2182         button $w.buttons.cancel -text {Cancel} \
2183                 -font font_ui \
2184                 -command [list destroy $w]
2185         pack $w.buttons.cancel -side right -padx 5
2186         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2187
2188         labelframe $w.list \
2189                 -text {Local Branches} \
2190                 -font font_ui
2191         listbox $w.list.l \
2192                 -height 10 \
2193                 -width 70 \
2194                 -selectmode extended \
2195                 -yscrollcommand [list $w.list.sby set] \
2196                 -font font_ui
2197         foreach h $all_heads {
2198                 if {$h ne $current_branch} {
2199                         $w.list.l insert end $h
2200                 }
2201         }
2202         scrollbar $w.list.sby -command [list $w.list.l yview]
2203         pack $w.list.sby -side right -fill y
2204         pack $w.list.l -side left -fill both -expand 1
2205         pack $w.list -fill both -expand 1 -pady 5 -padx 5
2206
2207         labelframe $w.validate \
2208                 -text {Delete Only If} \
2209                 -font font_ui
2210         radiobutton $w.validate.head_r \
2211                 -text {Merged Into Local Branch:} \
2212                 -value head \
2213                 -variable delete_branch_checktype \
2214                 -font font_ui
2215         eval tk_optionMenu $w.validate.head_m delete_branch_head $all_heads
2216         grid $w.validate.head_r $w.validate.head_m -sticky w
2217         set all_trackings [all_tracking_branches]
2218         if {$all_trackings ne {}} {
2219                 set delete_branch_trackinghead [lindex $all_trackings 0]
2220                 radiobutton $w.validate.tracking_r \
2221                         -text {Merged Into Tracking Branch:} \
2222                         -value tracking \
2223                         -variable delete_branch_checktype \
2224                         -font font_ui
2225                 eval tk_optionMenu $w.validate.tracking_m \
2226                         delete_branch_trackinghead \
2227                         $all_trackings
2228                 grid $w.validate.tracking_r $w.validate.tracking_m -sticky w
2229         }
2230         radiobutton $w.validate.always_r \
2231                 -text {Always (Do not perform merge checks)} \
2232                 -value always \
2233                 -variable delete_branch_checktype \
2234                 -font font_ui
2235         grid $w.validate.always_r -columnspan 2 -sticky w
2236         grid columnconfigure $w.validate 1 -weight 1
2237         pack $w.validate -anchor nw -fill x -pady 5 -padx 5
2238
2239         set delete_branch_head $current_branch
2240         set delete_branch_checktype head
2241
2242         bind $w <Visibility> "grab $w; focus $w"
2243         bind $w <Key-Escape> "destroy $w"
2244         wm title $w "[appname] ([reponame]): Delete Branch"
2245         tkwait window $w
2246 }
2247
2248 proc switch_branch {new_branch} {
2249         global HEAD commit_type current_branch repo_config
2250
2251         if {![lock_index switch]} return
2252
2253         # -- Our in memory state should match the repository.
2254         #
2255         repository_state curType curHEAD curMERGE_HEAD
2256         if {[string match amend* $commit_type]
2257                 && $curType eq {normal}
2258                 && $curHEAD eq $HEAD} {
2259         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
2260                 info_popup {Last scanned state does not match repository state.
2261
2262 Another Git program has modified this repository
2263 since the last scan.  A rescan must be performed
2264 before the current branch can be changed.
2265
2266 The rescan will be automatically started now.
2267 }
2268                 unlock_index
2269                 rescan {set ui_status_value {Ready.}}
2270                 return
2271         }
2272
2273         # -- Don't do a pointless switch.
2274         #
2275         if {$current_branch eq $new_branch} {
2276                 unlock_index
2277                 return
2278         }
2279
2280         if {$repo_config(gui.trustmtime) eq {true}} {
2281                 switch_branch_stage2 {} $new_branch
2282         } else {
2283                 set ui_status_value {Refreshing file status...}
2284                 set cmd [list git update-index]
2285                 lappend cmd -q
2286                 lappend cmd --unmerged
2287                 lappend cmd --ignore-missing
2288                 lappend cmd --refresh
2289                 set fd_rf [open "| $cmd" r]
2290                 fconfigure $fd_rf -blocking 0 -translation binary
2291                 fileevent $fd_rf readable \
2292                         [list switch_branch_stage2 $fd_rf $new_branch]
2293         }
2294 }
2295
2296 proc switch_branch_stage2 {fd_rf new_branch} {
2297         global ui_status_value HEAD
2298
2299         if {$fd_rf ne {}} {
2300                 read $fd_rf
2301                 if {![eof $fd_rf]} return
2302                 close $fd_rf
2303         }
2304
2305         set ui_status_value "Updating working directory to '$new_branch'..."
2306         set cmd [list git read-tree]
2307         lappend cmd -m
2308         lappend cmd -u
2309         lappend cmd --exclude-per-directory=.gitignore
2310         lappend cmd $HEAD
2311         lappend cmd $new_branch
2312         set fd_rt [open "| $cmd" r]
2313         fconfigure $fd_rt -blocking 0 -translation binary
2314         fileevent $fd_rt readable \
2315                 [list switch_branch_readtree_wait $fd_rt $new_branch]
2316 }
2317
2318 proc switch_branch_readtree_wait {fd_rt new_branch} {
2319         global selected_commit_type commit_type HEAD MERGE_HEAD PARENT
2320         global current_branch
2321         global ui_comm ui_status_value
2322
2323         # -- We never get interesting output on stdout; only stderr.
2324         #
2325         read $fd_rt
2326         fconfigure $fd_rt -blocking 1
2327         if {![eof $fd_rt]} {
2328                 fconfigure $fd_rt -blocking 0
2329                 return
2330         }
2331
2332         # -- The working directory wasn't in sync with the index and
2333         #    we'd have to overwrite something to make the switch. A
2334         #    merge is required.
2335         #
2336         if {[catch {close $fd_rt} err]} {
2337                 regsub {^fatal: } $err {} err
2338                 warn_popup "File level merge required.
2339
2340 $err
2341
2342 Staying on branch '$current_branch'."
2343                 set ui_status_value "Aborted checkout of '$new_branch' (file level merging is required)."
2344                 unlock_index
2345                 return
2346         }
2347
2348         # -- Update the symbolic ref.  Core git doesn't even check for failure
2349         #    here, it Just Works(tm).  If it doesn't we are in some really ugly
2350         #    state that is difficult to recover from within git-gui.
2351         #
2352         if {[catch {exec git symbolic-ref HEAD "refs/heads/$new_branch"} err]} {
2353                 error_popup "Failed to set current branch.
2354
2355 This working directory is only partially switched.
2356 We successfully updated your files, but failed to
2357 update an internal Git file.
2358
2359 This should not have occurred.  [appname] will now
2360 close and give up.
2361
2362 $err"
2363                 do_quit
2364                 return
2365         }
2366
2367         # -- Update our repository state.  If we were previously in amend mode
2368         #    we need to toss the current buffer and do a full rescan to update
2369         #    our file lists.  If we weren't in amend mode our file lists are
2370         #    accurate and we can avoid the rescan.
2371         #
2372         unlock_index
2373         set selected_commit_type new
2374         if {[string match amend* $commit_type]} {
2375                 $ui_comm delete 0.0 end
2376                 $ui_comm edit reset
2377                 $ui_comm edit modified false
2378                 rescan {set ui_status_value "Checked out branch '$current_branch'."}
2379         } else {
2380                 repository_state commit_type HEAD MERGE_HEAD
2381                 set PARENT $HEAD
2382                 set ui_status_value "Checked out branch '$current_branch'."
2383         }
2384 }
2385
2386 ######################################################################
2387 ##
2388 ## remote management
2389
2390 proc load_all_remotes {} {
2391         global repo_config
2392         global all_remotes tracking_branches
2393
2394         set all_remotes [list]
2395         array unset tracking_branches
2396
2397         set rm_dir [gitdir remotes]
2398         if {[file isdirectory $rm_dir]} {
2399                 set all_remotes [glob \
2400                         -types f \
2401                         -tails \
2402                         -nocomplain \
2403                         -directory $rm_dir *]
2404
2405                 foreach name $all_remotes {
2406                         catch {
2407                                 set fd [open [file join $rm_dir $name] r]
2408                                 while {[gets $fd line] >= 0} {
2409                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
2410                                                 $line line src dst]} continue
2411                                         if {![regexp ^refs/ $dst]} {
2412                                                 set dst "refs/heads/$dst"
2413                                         }
2414                                         set tracking_branches($dst) [list $name $src]
2415                                 }
2416                                 close $fd
2417                         }
2418                 }
2419         }
2420
2421         foreach line [array names repo_config remote.*.url] {
2422                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
2423                 lappend all_remotes $name
2424
2425                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
2426                         set fl {}
2427                 }
2428                 foreach line $fl {
2429                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
2430                         if {![regexp ^refs/ $dst]} {
2431                                 set dst "refs/heads/$dst"
2432                         }
2433                         set tracking_branches($dst) [list $name $src]
2434                 }
2435         }
2436
2437         set all_remotes [lsort -unique $all_remotes]
2438 }
2439
2440 proc populate_fetch_menu {} {
2441         global all_remotes repo_config
2442
2443         set m .mbar.fetch
2444         foreach r $all_remotes {
2445                 set enable 0
2446                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2447                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
2448                                 set enable 1
2449                         }
2450                 } else {
2451                         catch {
2452                                 set fd [open [gitdir remotes $r] r]
2453                                 while {[gets $fd n] >= 0} {
2454                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
2455                                                 set enable 1
2456                                                 break
2457                                         }
2458                                 }
2459                                 close $fd
2460                         }
2461                 }
2462
2463                 if {$enable} {
2464                         $m add command \
2465                                 -label "Fetch from $r..." \
2466                                 -command [list fetch_from $r] \
2467                                 -font font_ui
2468                 }
2469         }
2470 }
2471
2472 proc populate_push_menu {} {
2473         global all_remotes repo_config
2474
2475         set m .mbar.push
2476         set fast_count 0
2477         foreach r $all_remotes {
2478                 set enable 0
2479                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2480                         if {![catch {set a $repo_config(remote.$r.push)}]} {
2481                                 set enable 1
2482                         }
2483                 } else {
2484                         catch {
2485                                 set fd [open [gitdir remotes $r] r]
2486                                 while {[gets $fd n] >= 0} {
2487                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
2488                                                 set enable 1
2489                                                 break
2490                                         }
2491                                 }
2492                                 close $fd
2493                         }
2494                 }
2495
2496                 if {$enable} {
2497                         if {!$fast_count} {
2498                                 $m add separator
2499                         }
2500                         $m add command \
2501                                 -label "Push to $r..." \
2502                                 -command [list push_to $r] \
2503                                 -font font_ui
2504                         incr fast_count
2505                 }
2506         }
2507 }
2508
2509 proc start_push_anywhere_action {w} {
2510         global push_urltype push_remote push_url push_thin push_tags
2511
2512         set r_url {}
2513         switch -- $push_urltype {
2514         remote {set r_url $push_remote}
2515         url {set r_url $push_url}
2516         }
2517         if {$r_url eq {}} return
2518
2519         set cmd [list git push]
2520         lappend cmd -v
2521         if {$push_thin} {
2522                 lappend cmd --thin
2523         }
2524         if {$push_tags} {
2525                 lappend cmd --tags
2526         }
2527         lappend cmd $r_url
2528         set cnt 0
2529         foreach i [$w.source.l curselection] {
2530                 set b [$w.source.l get $i]
2531                 lappend cmd "refs/heads/$b:refs/heads/$b"
2532                 incr cnt
2533         }
2534         if {$cnt == 0} {
2535                 return
2536         } elseif {$cnt == 1} {
2537                 set unit branch
2538         } else {
2539                 set unit branches
2540         }
2541
2542         set cons [new_console "push $r_url" "Pushing $cnt $unit to $r_url"]
2543         console_exec $cons $cmd console_done
2544         destroy $w
2545 }
2546
2547 trace add variable push_remote write \
2548         [list radio_selector push_urltype remote]
2549
2550 proc do_push_anywhere {} {
2551         global all_heads all_remotes current_branch
2552         global push_urltype push_remote push_url push_thin push_tags
2553
2554         set w .push_setup
2555         toplevel $w
2556         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2557
2558         label $w.header -text {Push Branches} -font font_uibold
2559         pack $w.header -side top -fill x
2560
2561         frame $w.buttons
2562         button $w.buttons.create -text Push \
2563                 -font font_ui \
2564                 -command [list start_push_anywhere_action $w]
2565         pack $w.buttons.create -side right
2566         button $w.buttons.cancel -text {Cancel} \
2567                 -font font_ui \
2568                 -command [list destroy $w]
2569         pack $w.buttons.cancel -side right -padx 5
2570         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2571
2572         labelframe $w.source \
2573                 -text {Source Branches} \
2574                 -font font_ui
2575         listbox $w.source.l \
2576                 -height 10 \
2577                 -width 70 \
2578                 -selectmode extended \
2579                 -yscrollcommand [list $w.source.sby set] \
2580                 -font font_ui
2581         foreach h $all_heads {
2582                 $w.source.l insert end $h
2583                 if {$h eq $current_branch} {
2584                         $w.source.l select set end
2585                 }
2586         }
2587         scrollbar $w.source.sby -command [list $w.source.l yview]
2588         pack $w.source.sby -side right -fill y
2589         pack $w.source.l -side left -fill both -expand 1
2590         pack $w.source -fill both -expand 1 -pady 5 -padx 5
2591
2592         labelframe $w.dest \
2593                 -text {Destination Repository} \
2594                 -font font_ui
2595         if {$all_remotes ne {}} {
2596                 radiobutton $w.dest.remote_r \
2597                         -text {Remote:} \
2598                         -value remote \
2599                         -variable push_urltype \
2600                         -font font_ui
2601                 eval tk_optionMenu $w.dest.remote_m push_remote $all_remotes
2602                 grid $w.dest.remote_r $w.dest.remote_m -sticky w
2603                 if {[lsearch -sorted -exact $all_remotes origin] != -1} {
2604                         set push_remote origin
2605                 } else {
2606                         set push_remote [lindex $all_remotes 0]
2607                 }
2608                 set push_urltype remote
2609         } else {
2610                 set push_urltype url
2611         }
2612         radiobutton $w.dest.url_r \
2613                 -text {Arbitrary URL:} \
2614                 -value url \
2615                 -variable push_urltype \
2616                 -font font_ui
2617         entry $w.dest.url_t \
2618                 -borderwidth 1 \
2619                 -relief sunken \
2620                 -width 50 \
2621                 -textvariable push_url \
2622                 -font font_ui \
2623                 -validate key \
2624                 -validatecommand {
2625                         if {%d == 1 && [regexp {\s} %S]} {return 0}
2626                         if {%d == 1 && [string length %S] > 0} {
2627                                 set push_urltype url
2628                         }
2629                         return 1
2630                 }
2631         grid $w.dest.url_r $w.dest.url_t -sticky we -padx {0 5}
2632         grid columnconfigure $w.dest 1 -weight 1
2633         pack $w.dest -anchor nw -fill x -pady 5 -padx 5
2634
2635         labelframe $w.options \
2636                 -text {Transfer Options} \
2637                 -font font_ui
2638         checkbutton $w.options.thin \
2639                 -text {Use thin pack (for slow network connections)} \
2640                 -variable push_thin \
2641                 -font font_ui
2642         grid $w.options.thin -columnspan 2 -sticky w
2643         checkbutton $w.options.tags \
2644                 -text {Include tags} \
2645                 -variable push_tags \
2646                 -font font_ui
2647         grid $w.options.tags -columnspan 2 -sticky w
2648         grid columnconfigure $w.options 1 -weight 1
2649         pack $w.options -anchor nw -fill x -pady 5 -padx 5
2650
2651         set push_url {}
2652         set push_thin 0
2653         set push_tags 0
2654
2655         bind $w <Visibility> "grab $w"
2656         bind $w <Key-Escape> "destroy $w"
2657         wm title $w "[appname] ([reponame]): Push"
2658         tkwait window $w
2659 }
2660
2661 ######################################################################
2662 ##
2663 ## merge
2664
2665 proc can_merge {} {
2666         global HEAD commit_type file_states
2667
2668         if {[string match amend* $commit_type]} {
2669                 info_popup {Cannot merge while amending.
2670
2671 You must finish amending this commit before
2672 starting any type of merge.
2673 }
2674                 return 0
2675         }
2676
2677         if {[committer_ident] eq {}} {return 0}
2678         if {![lock_index merge]} {return 0}
2679
2680         # -- Our in memory state should match the repository.
2681         #
2682         repository_state curType curHEAD curMERGE_HEAD
2683         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
2684                 info_popup {Last scanned state does not match repository state.
2685
2686 Another Git program has modified this repository
2687 since the last scan.  A rescan must be performed
2688 before a merge can be performed.
2689
2690 The rescan will be automatically started now.
2691 }
2692                 unlock_index
2693                 rescan {set ui_status_value {Ready.}}
2694                 return 0
2695         }
2696
2697         foreach path [array names file_states] {
2698                 switch -glob -- [lindex $file_states($path) 0] {
2699                 _O {
2700                         continue; # and pray it works!
2701                 }
2702                 U? {
2703                         error_popup "You are in the middle of a conflicted merge.
2704
2705 File [short_path $path] has merge conflicts.
2706
2707 You must resolve them, add the file, and commit to
2708 complete the current merge.  Only then can you
2709 begin another merge.
2710 "
2711                         unlock_index
2712                         return 0
2713                 }
2714                 ?? {
2715                         error_popup "You are in the middle of a change.
2716
2717 File [short_path $path] is modified.
2718
2719 You should complete the current commit before
2720 starting a merge.  Doing so will help you abort
2721 a failed merge, should the need arise.
2722 "
2723                         unlock_index
2724                         return 0
2725                 }
2726                 }
2727         }
2728
2729         return 1
2730 }
2731
2732 proc visualize_local_merge {w} {
2733         set revs {}
2734         foreach i [$w.source.l curselection] {
2735                 lappend revs [$w.source.l get $i]
2736         }
2737         if {$revs eq {}} return
2738         lappend revs --not HEAD
2739         do_gitk $revs
2740 }
2741
2742 proc start_local_merge_action {w} {
2743         global HEAD ui_status_value current_branch
2744
2745         set cmd [list git merge]
2746         set names {}
2747         set revcnt 0
2748         foreach i [$w.source.l curselection] {
2749                 set b [$w.source.l get $i]
2750                 lappend cmd $b
2751                 lappend names $b
2752                 incr revcnt
2753         }
2754
2755         if {$revcnt == 0} {
2756                 return
2757         } elseif {$revcnt == 1} {
2758                 set unit branch
2759         } elseif {$revcnt <= 15} {
2760                 set unit branches
2761         } else {
2762                 tk_messageBox \
2763                         -icon error \
2764                         -type ok \
2765                         -title [wm title $w] \
2766                         -parent $w \
2767                         -message "Too many branches selected.
2768
2769 You have requested to merge $revcnt branches
2770 in an octopus merge.  This exceeds Git's
2771 internal limit of 15 branches per merge.
2772
2773 Please select fewer branches.  To merge more
2774 than 15 branches, merge the branches in batches.
2775 "
2776                 return
2777         }
2778
2779         set msg "Merging $current_branch, [join $names {, }]"
2780         set ui_status_value "$msg..."
2781         set cons [new_console "Merge" $msg]
2782         console_exec $cons $cmd [list finish_merge $revcnt]
2783         bind $w <Destroy> {}
2784         destroy $w
2785 }
2786
2787 proc finish_merge {revcnt w ok} {
2788         console_done $w $ok
2789         if {$ok} {
2790                 set msg {Merge completed successfully.}
2791         } else {
2792                 if {$revcnt != 1} {
2793                         info_popup "Octopus merge failed.
2794
2795 Your merge of $revcnt branches has failed.
2796
2797 There are file-level conflicts between the
2798 branches which must be resolved manually.
2799
2800 The working directory will now be reset.
2801
2802 You can attempt this merge again
2803 by merging only one branch at a time." $w
2804
2805                         set fd [open "| git read-tree --reset -u HEAD" r]
2806                         fconfigure $fd -blocking 0 -translation binary
2807                         fileevent $fd readable [list reset_hard_wait $fd]
2808                         set ui_status_value {Aborting... please wait...}
2809                         return
2810                 }
2811
2812                 set msg {Merge failed.  Conflict resolution is required.}
2813         }
2814         unlock_index
2815         rescan [list set ui_status_value $msg]
2816 }
2817
2818 proc do_local_merge {} {
2819         global current_branch
2820
2821         if {![can_merge]} return
2822
2823         set w .merge_setup
2824         toplevel $w
2825         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2826
2827         label $w.header \
2828                 -text "Merge Into $current_branch" \
2829                 -font font_uibold
2830         pack $w.header -side top -fill x
2831
2832         frame $w.buttons
2833         button $w.buttons.visualize -text Visualize \
2834                 -font font_ui \
2835                 -command [list visualize_local_merge $w]
2836         pack $w.buttons.visualize -side left
2837         button $w.buttons.create -text Merge \
2838                 -font font_ui \
2839                 -command [list start_local_merge_action $w]
2840         pack $w.buttons.create -side right
2841         button $w.buttons.cancel -text {Cancel} \
2842                 -font font_ui \
2843                 -command [list destroy $w]
2844         pack $w.buttons.cancel -side right -padx 5
2845         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2846
2847         labelframe $w.source \
2848                 -text {Source Branches} \
2849                 -font font_ui
2850         listbox $w.source.l \
2851                 -height 10 \
2852                 -width 70 \
2853                 -selectmode extended \
2854                 -yscrollcommand [list $w.source.sby set] \
2855                 -font font_ui
2856         scrollbar $w.source.sby -command [list $w.source.l yview]
2857         pack $w.source.sby -side right -fill y
2858         pack $w.source.l -side left -fill both -expand 1
2859         pack $w.source -fill both -expand 1 -pady 5 -padx 5
2860
2861         set cmd [list git for-each-ref]
2862         lappend cmd {--format=%(objectname) %(refname)}
2863         lappend cmd refs/heads
2864         lappend cmd refs/remotes
2865         set fr_fd [open "| $cmd" r]
2866         fconfigure $fr_fd -translation binary
2867         while {[gets $fr_fd line] > 0} {
2868                 set line [split $line { }]
2869                 set sha1([lindex $line 0]) [lindex $line 1]
2870         }
2871         close $fr_fd
2872
2873         set to_show {}
2874         set fr_fd [open "| git rev-list --all --not HEAD"]
2875         while {[gets $fr_fd line] > 0} {
2876                 if {[catch {set ref $sha1($line)}]} continue
2877                 regsub ^refs/(heads|remotes)/ $ref {} ref
2878                 lappend to_show $ref
2879         }
2880         close $fr_fd
2881
2882         foreach ref [lsort -unique $to_show] {
2883                 $w.source.l insert end $ref
2884         }
2885
2886         bind $w <Visibility> "grab $w"
2887         bind $w <Key-Escape> "unlock_index;destroy $w"
2888         bind $w <Destroy> unlock_index
2889         wm title $w "[appname] ([reponame]): Merge"
2890         tkwait window $w
2891 }
2892
2893 proc do_reset_hard {} {
2894         global HEAD commit_type file_states
2895
2896         if {[string match amend* $commit_type]} {
2897                 info_popup {Cannot abort while amending.
2898
2899 You must finish amending this commit.
2900 }
2901                 return
2902         }
2903
2904         if {![lock_index abort]} return
2905
2906         if {[string match *merge* $commit_type]} {
2907                 set op merge
2908         } else {
2909                 set op commit
2910         }
2911
2912         if {[ask_popup "Abort $op?
2913
2914 Aborting the current $op will cause
2915 *ALL* uncommitted changes to be lost.
2916
2917 Continue with aborting the current $op?"] eq {yes}} {
2918                 set fd [open "| git read-tree --reset -u HEAD" r]
2919                 fconfigure $fd -blocking 0 -translation binary
2920                 fileevent $fd readable [list reset_hard_wait $fd]
2921                 set ui_status_value {Aborting... please wait...}
2922         } else {
2923                 unlock_index
2924         }
2925 }
2926
2927 proc reset_hard_wait {fd} {
2928         global ui_comm
2929
2930         read $fd
2931         if {[eof $fd]} {
2932                 close $fd
2933                 unlock_index
2934
2935                 $ui_comm delete 0.0 end
2936                 $ui_comm edit modified false
2937
2938                 catch {file delete [gitdir MERGE_HEAD]}
2939                 catch {file delete [gitdir rr-cache MERGE_RR]}
2940                 catch {file delete [gitdir SQUASH_MSG]}
2941                 catch {file delete [gitdir MERGE_MSG]}
2942                 catch {file delete [gitdir GITGUI_MSG]}
2943
2944                 rescan {set ui_status_value {Abort completed.  Ready.}}
2945         }
2946 }
2947
2948 ######################################################################
2949 ##
2950 ## browser
2951
2952 set next_browser_id 0
2953
2954 proc new_browser {commit} {
2955         global next_browser_id cursor_ptr
2956         global browser_commit browser_status browser_stack browser_path browser_busy
2957
2958         set w .browser[incr next_browser_id]
2959         set w_list $w.list.l
2960         set browser_commit($w_list) $commit
2961         set browser_status($w_list) {Starting...}
2962         set browser_stack($w_list) {}
2963         set browser_path($w_list) $browser_commit($w_list):
2964         set browser_busy($w_list) 1
2965
2966         toplevel $w
2967         label $w.path -textvariable browser_path($w_list) \
2968                 -anchor w \
2969                 -justify left \
2970                 -borderwidth 1 \
2971                 -relief sunken \
2972                 -font font_uibold
2973         pack $w.path -anchor w -side top -fill x
2974
2975         frame $w.list
2976         text $w_list -background white -borderwidth 0 \
2977                 -cursor $cursor_ptr \
2978                 -state disabled \
2979                 -wrap none \
2980                 -height 20 \
2981                 -width 70 \
2982                 -xscrollcommand [list $w.list.sbx set] \
2983                 -yscrollcommand [list $w.list.sby set] \
2984                 -font font_ui
2985         $w_list tag conf in_sel \
2986                 -background [$w_list cget -foreground] \
2987                 -foreground [$w_list cget -background]
2988         scrollbar $w.list.sbx -orient h -command [list $w_list xview]
2989         scrollbar $w.list.sby -orient v -command [list $w_list yview]
2990         pack $w.list.sbx -side bottom -fill x
2991         pack $w.list.sby -side right -fill y
2992         pack $w_list -side left -fill both -expand 1
2993         pack $w.list -side top -fill both -expand 1
2994
2995         label $w.status -textvariable browser_status($w_list) \
2996                 -anchor w \
2997                 -justify left \
2998                 -borderwidth 1 \
2999                 -relief sunken \
3000                 -font font_ui
3001         pack $w.status -anchor w -side bottom -fill x
3002
3003         bind $w_list <Button-1>        "browser_click 0 $w_list @%x,%y;break"
3004         bind $w_list <Double-Button-1> "browser_click 1 $w_list @%x,%y;break"
3005
3006         bind $w <Visibility> "focus $w"
3007         bind $w <Destroy> "
3008                 array unset browser_buffer $w_list
3009                 array unset browser_files $w_list
3010                 array unset browser_status $w_list
3011                 array unset browser_stack $w_list
3012                 array unset browser_path $w_list
3013                 array unset browser_commit $w_list
3014                 array unset browser_busy $w_list
3015         "
3016         wm title $w "[appname] ([reponame]): File Browser"
3017         ls_tree $w_list $browser_commit($w_list) {}
3018 }
3019
3020 proc browser_click {was_double_click w pos} {
3021         global browser_files browser_status browser_path
3022         global browser_commit browser_stack browser_busy
3023
3024         if {$browser_busy($w)} return
3025         set lno [lindex [split [$w index $pos] .] 0]
3026         set info [lindex $browser_files($w) [expr {$lno - 1}]]
3027
3028         $w conf -state normal
3029         $w tag remove sel 0.0 end
3030         $w tag remove in_sel 0.0 end
3031         if {$info ne {}} {
3032                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
3033                 if {$was_double_click} {
3034                         switch -- [lindex $info 0] {
3035                         parent {
3036                                 set parent [lindex $browser_stack($w) end-1]
3037                                 set browser_stack($w) [lrange $browser_stack($w) 0 end-2]
3038                                 if {$browser_stack($w) eq {}} {
3039                                         regsub {:.*$} $browser_path($w) {:} browser_path($w)
3040                                 } else {
3041                                         regsub {/[^/]+$} $browser_path($w) {} browser_path($w)
3042                                 }
3043                                 set browser_status($w) "Loading $browser_path($w)..."
3044                                 ls_tree $w [lindex $parent 0] [lindex $parent 1]
3045                         }
3046                         tree {
3047                                 set name [lindex $info 2]
3048                                 set escn [escape_path $name]
3049                                 set browser_status($w) "Loading $escn..."
3050                                 append browser_path($w) $escn
3051                                 ls_tree $w [lindex $info 1] $name
3052                         }
3053                         blob {
3054                                 set name [lindex $info 2]
3055                                 set p {}
3056                                 foreach n $browser_stack($w) {
3057                                         append p [lindex $n 1]
3058                                 }
3059                                 append p $name
3060                                 show_blame $browser_commit($w) $p
3061                         }
3062                         }
3063                 }
3064         }
3065         $w conf -state disabled
3066 }
3067
3068 proc ls_tree {w tree_id name} {
3069         global browser_buffer browser_files browser_stack browser_busy
3070
3071         set browser_buffer($w) {}
3072         set browser_files($w) {}
3073         set browser_busy($w) 1
3074
3075         $w conf -state normal
3076         $w tag remove in_sel 0.0 end
3077         $w tag remove sel 0.0 end
3078         $w delete 0.0 end
3079         if {$browser_stack($w) ne {}} {
3080                 $w image create end \
3081                         -align center -padx 5 -pady 1 \
3082                         -name icon0 \
3083                         -image file_uplevel
3084                 $w insert end {[Up To Parent]}
3085                 lappend browser_files($w) parent
3086         }
3087         lappend browser_stack($w) [list $tree_id $name]
3088         $w conf -state disabled
3089
3090         set cmd [list git ls-tree -z $tree_id]
3091         set fd [open "| $cmd" r]
3092         fconfigure $fd -blocking 0 -translation binary -encoding binary
3093         fileevent $fd readable [list read_ls_tree $fd $w]
3094 }
3095
3096 proc read_ls_tree {fd w} {
3097         global browser_buffer browser_files browser_status browser_busy
3098
3099         if {![winfo exists $w]} {
3100                 catch {close $fd}
3101                 return
3102         }
3103
3104         append browser_buffer($w) [read $fd]
3105         set pck [split $browser_buffer($w) "\0"]
3106         set browser_buffer($w) [lindex $pck end]
3107
3108         set n [llength $browser_files($w)]
3109         $w conf -state normal
3110         foreach p [lrange $pck 0 end-1] {
3111                 set info [split $p "\t"]
3112                 set path [lindex $info 1]
3113                 set info [split [lindex $info 0] { }]
3114                 set type [lindex $info 1]
3115                 set object [lindex $info 2]
3116
3117                 switch -- $type {
3118                 blob {
3119                         set image file_mod
3120                 }
3121                 tree {
3122                         set image file_dir
3123                         append path /
3124                 }
3125                 default {
3126                         set image file_question
3127                 }
3128                 }
3129
3130                 if {$n > 0} {$w insert end "\n"}
3131                 $w image create end \
3132                         -align center -padx 5 -pady 1 \
3133                         -name icon[incr n] \
3134                         -image $image
3135                 $w insert end [escape_path $path]
3136                 lappend browser_files($w) [list $type $object $path]
3137         }
3138         $w conf -state disabled
3139
3140         if {[eof $fd]} {
3141                 close $fd
3142                 set browser_status($w) Ready.
3143                 set browser_busy($w) 0
3144                 array unset browser_buffer $w
3145         }
3146 }
3147
3148 proc show_blame {commit path} {
3149         global next_browser_id blame_status blame_data
3150
3151         set w .browser[incr next_browser_id]
3152         set blame_status($w) {Loading current file content...}
3153         set texts [list]
3154
3155         toplevel $w
3156         panedwindow $w.out -orient horizontal
3157
3158         label $w.path -text "$commit:$path" \
3159                 -anchor w \
3160                 -justify left \
3161                 -borderwidth 1 \
3162                 -relief sunken \
3163                 -font font_uibold
3164         pack $w.path -anchor w -side top -fill x
3165
3166         text $w.out.commit -background white -borderwidth 0 \
3167                 -state disabled \
3168                 -wrap none \
3169                 -height 40 \
3170                 -width 8 \
3171                 -font font_diff
3172         $w.out add $w.out.commit
3173         lappend texts $w.out.commit
3174
3175         text $w.out.author -background white -borderwidth 0 \
3176                 -state disabled \
3177                 -wrap none \
3178                 -height 40 \
3179                 -width 20 \
3180                 -font font_diff
3181         $w.out add $w.out.author
3182         lappend texts $w.out.author
3183
3184         text $w.out.date -background white -borderwidth 0 \
3185                 -state disabled \
3186                 -wrap none \
3187                 -height 40 \
3188                 -width [string length "yyyy-mm-dd hh:mm:ss"] \
3189                 -font font_diff
3190         $w.out add $w.out.date
3191         lappend texts $w.out.date
3192
3193         text $w.out.linenumber -background white -borderwidth 0 \
3194                 -state disabled \
3195                 -wrap none \
3196                 -height 40 \
3197                 -width 5 \
3198                 -font font_diff
3199         $w.out.linenumber tag conf linenumber -justify right
3200         $w.out add $w.out.linenumber
3201         lappend texts $w.out.linenumber
3202
3203         text $w.out.file -background white -borderwidth 0 \
3204                 -state disabled \
3205                 -wrap none \
3206                 -height 40 \
3207                 -width 80 \
3208                 -font font_diff
3209         $w.out add $w.out.file
3210         lappend texts $w.out.file
3211
3212         label $w.status -textvariable blame_status($w) \
3213                 -anchor w \
3214                 -justify left \
3215                 -borderwidth 1 \
3216                 -relief sunken \
3217                 -font font_ui
3218         pack $w.status -anchor w -side bottom -fill x
3219
3220         scrollbar $w.sby -orient v -command [list scrollbar2many $texts yview]
3221         pack $w.sby -side right -fill y
3222         pack $w.out -side left -fill both -expand 1
3223
3224         menu $w.ctxm -tearoff 0
3225         $w.ctxm add command -label "Copy Commit" \
3226                 -font font_ui \
3227                 -command "blame_copycommit $w \$cursorW @\$cursorX,\$cursorY"
3228
3229         foreach i $texts {
3230                 $i tag conf in_sel \
3231                         -background [$i cget -foreground] \
3232                         -foreground [$i cget -background]
3233                 $i conf -yscrollcommand [list many2scrollbar $texts yview $w.sby]
3234                 bind $i <Button-1> "blame_highlight $i @%x,%y $texts;break"
3235                 bind_button3 $i "
3236                         set cursorX %x
3237                         set cursorY %y
3238                         set cursorW %W
3239                         tk_popup $w.ctxm %X %Y
3240                 "
3241         }
3242
3243         bind $w <Visibility> "focus $w"
3244         bind $w <Destroy> "
3245                 array unset blame_status $w
3246                 array unset blame_data $w,*
3247         "
3248         wm title $w "[appname] ([reponame]): File Viewer"
3249
3250         set blame_data($w,total_lines) 0
3251         set cmd [list git cat-file blob "$commit:$path"]
3252         set fd [open "| $cmd" r]
3253         fconfigure $fd -blocking 0 -translation lf -encoding binary
3254         fileevent $fd readable [list read_blame_catfile $fd $w $commit $path \
3255                 $texts $w.out.linenumber $w.out.file]
3256 }
3257
3258 proc read_blame_catfile {fd w commit path texts w_lno w_file} {
3259         global blame_status blame_data
3260
3261         if {![winfo exists $w_file]} {
3262                 catch {close $fd}
3263                 return
3264         }
3265
3266         set n $blame_data($w,total_lines)
3267         foreach i $texts {$i conf -state normal}
3268         while {[gets $fd line] >= 0} {
3269                 regsub "\r\$" $line {} line
3270                 incr n
3271                 $w_lno insert end $n linenumber
3272                 $w_file insert end $line
3273                 foreach i $texts {$i insert end "\n"}
3274         }
3275         foreach i $texts {$i conf -state disabled}
3276         set blame_data($w,total_lines) $n
3277
3278         if {[eof $fd]} {
3279                 close $fd
3280                 set blame_status($w) {Loading annotations...}
3281                 set cmd [list git blame -M -C --incremental]
3282                 lappend cmd $commit -- $path
3283                 set fd [open "| $cmd" r]
3284                 fconfigure $fd -blocking 0 -translation lf -encoding binary
3285                 fileevent $fd readable "read_blame_incremental $fd $w $texts"
3286         }
3287 }
3288
3289 proc read_blame_incremental {fd w w_commit w_author w_date w_lno w_file} {
3290         global blame_status blame_data
3291
3292         if {![winfo exists $w_commit]} {
3293                 catch {close $fd}
3294                 return
3295         }
3296
3297         $w_commit conf -state normal
3298         $w_author conf -state normal
3299         $w_date conf -state normal
3300
3301         while {[gets $fd line] >= 0} {
3302                 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
3303                         commit original_line final_line line_count]} {
3304                         set blame_data($w,commit) $commit
3305                         set blame_data($w,original_line) $original_line
3306                         set blame_data($w,final_line) $final_line
3307                         set blame_data($w,line_count) $line_count
3308                 } elseif {[string match {filename *} $line]} {
3309                         set n $blame_data($w,line_count)
3310                         set lno $blame_data($w,final_line)
3311                         set file [string range $line 9 end]
3312                         set commit $blame_data($w,commit)
3313                         set abbrev [string range $commit 0 8]
3314
3315                         if {[catch {set author $blame_data($w,$commit,author)} err]} {
3316                         puts $err
3317                                 set author {}
3318                         }
3319
3320                         if {[catch {set atime $blame_data($w,$commit,author-time)}]} {
3321                                 set atime {}
3322                         } else {
3323                                 set atime [clock format $atime -format {%Y-%m-%d %T}]
3324                         }
3325
3326                         while {$n > 0} {
3327                                 $w_commit delete $lno.0 "$lno.0 lineend"
3328                                 $w_author delete $lno.0 "$lno.0 lineend"
3329                                 $w_date delete $lno.0 "$lno.0 lineend"
3330
3331                                 $w_commit insert $lno.0 $abbrev
3332                                 $w_author insert $lno.0 $author
3333                                 $w_date insert $lno.0 $atime
3334                                 set blame_data($w,line$lno,commit) $commit
3335
3336                                 incr n -1
3337                                 incr lno
3338                         }
3339                 } elseif {[regexp {^([a-z-]+) (.*)$} $line line header data]} {
3340                         set blame_data($w,$blame_data($w,commit),$header) $data
3341                 }
3342         }
3343
3344         $w_commit conf -state disabled
3345         $w_author conf -state disabled
3346         $w_date conf -state disabled
3347
3348         if {[eof $fd]} {
3349                 close $fd
3350                 set blame_status($w) {Annotation complete.}
3351         }
3352 }
3353
3354 proc blame_highlight {w pos args} {
3355         set lno [lindex [split [$w index $pos] .] 0]
3356         foreach i $args {
3357                 $i tag remove in_sel 0.0 end
3358         }
3359         if {$lno eq {}} return
3360         foreach i $args {
3361                 $i tag add in_sel $lno.0 "$lno.0 + 1 line"
3362         }
3363 }
3364
3365 proc blame_copycommit {w i pos} {
3366         global blame_data
3367         set lno [lindex [split [$i index $pos] .] 0]
3368         if {![catch {set commit $blame_data($w,line$lno,commit)}]} {
3369                 clipboard clear
3370                 clipboard append \
3371                         -format STRING \
3372                         -type STRING \
3373                         -- $commit
3374         }
3375 }
3376
3377 ######################################################################
3378 ##
3379 ## icons
3380
3381 set filemask {
3382 #define mask_width 14
3383 #define mask_height 15
3384 static unsigned char mask_bits[] = {
3385    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
3386    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
3387    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
3388 }
3389
3390 image create bitmap file_plain -background white -foreground black -data {
3391 #define plain_width 14
3392 #define plain_height 15
3393 static unsigned char plain_bits[] = {
3394    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
3395    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
3396    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
3397 } -maskdata $filemask
3398
3399 image create bitmap file_mod -background white -foreground blue -data {
3400 #define mod_width 14
3401 #define mod_height 15
3402 static unsigned char mod_bits[] = {
3403    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
3404    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
3405    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
3406 } -maskdata $filemask
3407
3408 image create bitmap file_fulltick -background white -foreground "#007000" -data {
3409 #define file_fulltick_width 14
3410 #define file_fulltick_height 15
3411 static unsigned char file_fulltick_bits[] = {
3412    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
3413    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
3414    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
3415 } -maskdata $filemask
3416
3417 image create bitmap file_parttick -background white -foreground "#005050" -data {
3418 #define parttick_width 14
3419 #define parttick_height 15
3420 static unsigned char parttick_bits[] = {
3421    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
3422    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
3423    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
3424 } -maskdata $filemask
3425
3426 image create bitmap file_question -background white -foreground black -data {
3427 #define file_question_width 14
3428 #define file_question_height 15
3429 static unsigned char file_question_bits[] = {
3430    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
3431    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
3432    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
3433 } -maskdata $filemask
3434
3435 image create bitmap file_removed -background white -foreground red -data {
3436 #define file_removed_width 14
3437 #define file_removed_height 15
3438 static unsigned char file_removed_bits[] = {
3439    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
3440    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
3441    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
3442 } -maskdata $filemask
3443
3444 image create bitmap file_merge -background white -foreground blue -data {
3445 #define file_merge_width 14
3446 #define file_merge_height 15
3447 static unsigned char file_merge_bits[] = {
3448    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
3449    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
3450    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
3451 } -maskdata $filemask
3452
3453 set file_dir_data {
3454 #define file_width 18
3455 #define file_height 18
3456 static unsigned char file_bits[] = {
3457   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xf8, 0x03, 0x00,
3458   0x0c, 0x03, 0x00, 0x04, 0xfe, 0x00, 0x06, 0x80, 0x00, 0xff, 0x9f, 0x00,
3459   0x03, 0x98, 0x00, 0x02, 0x90, 0x00, 0x06, 0xb0, 0x00, 0x04, 0xa0, 0x00,
3460   0x0c, 0xe0, 0x00, 0x08, 0xc0, 0x00, 0xf8, 0xff, 0x00, 0x00, 0x00, 0x00,
3461   0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
3462 }
3463 image create bitmap file_dir -background white -foreground blue \
3464         -data $file_dir_data -maskdata $file_dir_data
3465 unset file_dir_data
3466
3467 set file_uplevel_data {
3468 #define up_width 15
3469 #define up_height 15
3470 static unsigned char up_bits[] = {
3471   0x80, 0x00, 0xc0, 0x01, 0xe0, 0x03, 0xf0, 0x07, 0xf8, 0x0f, 0xfc, 0x1f,
3472   0xfe, 0x3f, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01,
3473   0xc0, 0x01, 0xc0, 0x01, 0x00, 0x00};
3474 }
3475 image create bitmap file_uplevel -background white -foreground red \
3476         -data $file_uplevel_data -maskdata $file_uplevel_data
3477 unset file_uplevel_data
3478
3479 set ui_index .vpane.files.index.list
3480 set ui_workdir .vpane.files.workdir.list
3481
3482 set all_icons(_$ui_index)   file_plain
3483 set all_icons(A$ui_index)   file_fulltick
3484 set all_icons(M$ui_index)   file_fulltick
3485 set all_icons(D$ui_index)   file_removed
3486 set all_icons(U$ui_index)   file_merge
3487
3488 set all_icons(_$ui_workdir) file_plain
3489 set all_icons(M$ui_workdir) file_mod
3490 set all_icons(D$ui_workdir) file_question
3491 set all_icons(U$ui_workdir) file_merge
3492 set all_icons(O$ui_workdir) file_plain
3493
3494 set max_status_desc 0
3495 foreach i {
3496                 {__ "Unmodified"}
3497
3498                 {_M "Modified, not staged"}
3499                 {M_ "Staged for commit"}
3500                 {MM "Portions staged for commit"}
3501                 {MD "Staged for commit, missing"}
3502
3503                 {_O "Untracked, not staged"}
3504                 {A_ "Staged for commit"}
3505                 {AM "Portions staged for commit"}
3506                 {AD "Staged for commit, missing"}
3507
3508                 {_D "Missing"}
3509                 {D_ "Staged for removal"}
3510                 {DO "Staged for removal, still present"}
3511
3512                 {U_ "Requires merge resolution"}
3513                 {UU "Requires merge resolution"}
3514                 {UM "Requires merge resolution"}
3515                 {UD "Requires merge resolution"}
3516         } {
3517         if {$max_status_desc < [string length [lindex $i 1]]} {
3518                 set max_status_desc [string length [lindex $i 1]]
3519         }
3520         set all_descs([lindex $i 0]) [lindex $i 1]
3521 }
3522 unset i
3523
3524 ######################################################################
3525 ##
3526 ## util
3527
3528 proc bind_button3 {w cmd} {
3529         bind $w <Any-Button-3> $cmd
3530         if {[is_MacOSX]} {
3531                 bind $w <Control-Button-1> $cmd
3532         }
3533 }
3534
3535 proc scrollbar2many {list mode args} {
3536         foreach w $list {eval $w $mode $args}
3537 }
3538
3539 proc many2scrollbar {list mode sb top bottom} {
3540         $sb set $top $bottom
3541         foreach w $list {$w $mode moveto $top}
3542 }
3543
3544 proc incr_font_size {font {amt 1}} {
3545         set sz [font configure $font -size]
3546         incr sz $amt
3547         font configure $font -size $sz
3548         font configure ${font}bold -size $sz
3549 }
3550
3551 proc hook_failed_popup {hook msg} {
3552         set w .hookfail
3553         toplevel $w
3554
3555         frame $w.m
3556         label $w.m.l1 -text "$hook hook failed:" \
3557                 -anchor w \
3558                 -justify left \
3559                 -font font_uibold
3560         text $w.m.t \
3561                 -background white -borderwidth 1 \
3562                 -relief sunken \
3563                 -width 80 -height 10 \
3564                 -font font_diff \
3565                 -yscrollcommand [list $w.m.sby set]
3566         label $w.m.l2 \
3567                 -text {You must correct the above errors before committing.} \
3568                 -anchor w \
3569                 -justify left \
3570                 -font font_uibold
3571         scrollbar $w.m.sby -command [list $w.m.t yview]
3572         pack $w.m.l1 -side top -fill x
3573         pack $w.m.l2 -side bottom -fill x
3574         pack $w.m.sby -side right -fill y
3575         pack $w.m.t -side left -fill both -expand 1
3576         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
3577
3578         $w.m.t insert 1.0 $msg
3579         $w.m.t conf -state disabled
3580
3581         button $w.ok -text OK \
3582                 -width 15 \
3583                 -font font_ui \
3584                 -command "destroy $w"
3585         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
3586
3587         bind $w <Visibility> "grab $w; focus $w"
3588         bind $w <Key-Return> "destroy $w"
3589         wm title $w "[appname] ([reponame]): error"
3590         tkwait window $w
3591 }
3592
3593 set next_console_id 0
3594
3595 proc new_console {short_title long_title} {
3596         global next_console_id console_data
3597         set w .console[incr next_console_id]
3598         set console_data($w) [list $short_title $long_title]
3599         return [console_init $w]
3600 }
3601
3602 proc console_init {w} {
3603         global console_cr console_data M1B
3604
3605         set console_cr($w) 1.0
3606         toplevel $w
3607         frame $w.m
3608         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
3609                 -anchor w \
3610                 -justify left \
3611                 -font font_uibold
3612         text $w.m.t \
3613                 -background white -borderwidth 1 \
3614                 -relief sunken \
3615                 -width 80 -height 10 \
3616                 -font font_diff \
3617                 -state disabled \
3618                 -yscrollcommand [list $w.m.sby set]
3619         label $w.m.s -text {Working... please wait...} \
3620                 -anchor w \
3621                 -justify left \
3622                 -font font_uibold
3623         scrollbar $w.m.sby -command [list $w.m.t yview]
3624         pack $w.m.l1 -side top -fill x
3625         pack $w.m.s -side bottom -fill x
3626         pack $w.m.sby -side right -fill y
3627         pack $w.m.t -side left -fill both -expand 1
3628         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
3629
3630         menu $w.ctxm -tearoff 0
3631         $w.ctxm add command -label "Copy" \
3632                 -font font_ui \
3633                 -command "tk_textCopy $w.m.t"
3634         $w.ctxm add command -label "Select All" \
3635                 -font font_ui \
3636                 -command "focus $w.m.t;$w.m.t tag add sel 0.0 end"
3637         $w.ctxm add command -label "Copy All" \
3638                 -font font_ui \
3639                 -command "
3640                         $w.m.t tag add sel 0.0 end
3641                         tk_textCopy $w.m.t
3642                         $w.m.t tag remove sel 0.0 end
3643                 "
3644
3645         button $w.ok -text {Close} \
3646                 -font font_ui \
3647                 -state disabled \
3648                 -command "destroy $w"
3649         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
3650
3651         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
3652         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
3653         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
3654         bind $w <Visibility> "focus $w"
3655         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
3656         return $w
3657 }
3658
3659 proc console_exec {w cmd after} {
3660         # -- Cygwin's Tcl tosses the enviroment when we exec our child.
3661         #    But most users need that so we have to relogin. :-(
3662         #
3663         if {[is_Cygwin]} {
3664                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
3665         }
3666
3667         # -- Tcl won't let us redirect both stdout and stderr to
3668         #    the same pipe.  So pass it through cat...
3669         #
3670         set cmd [concat | $cmd |& cat]
3671
3672         set fd_f [open $cmd r]
3673         fconfigure $fd_f -blocking 0 -translation binary
3674         fileevent $fd_f readable [list console_read $w $fd_f $after]
3675 }
3676
3677 proc console_read {w fd after} {
3678         global console_cr
3679
3680         set buf [read $fd]
3681         if {$buf ne {}} {
3682                 if {![winfo exists $w]} {console_init $w}
3683                 $w.m.t conf -state normal
3684                 set c 0
3685                 set n [string length $buf]
3686                 while {$c < $n} {
3687                         set cr [string first "\r" $buf $c]
3688                         set lf [string first "\n" $buf $c]
3689                         if {$cr < 0} {set cr [expr {$n + 1}]}
3690                         if {$lf < 0} {set lf [expr {$n + 1}]}
3691
3692                         if {$lf < $cr} {
3693                                 $w.m.t insert end [string range $buf $c $lf]
3694                                 set console_cr($w) [$w.m.t index {end -1c}]
3695                                 set c $lf
3696                                 incr c
3697                         } else {
3698                                 $w.m.t delete $console_cr($w) end
3699                                 $w.m.t insert end "\n"
3700                                 $w.m.t insert end [string range $buf $c $cr]
3701                                 set c $cr
3702                                 incr c
3703                         }
3704                 }
3705                 $w.m.t conf -state disabled
3706                 $w.m.t see end
3707         }
3708
3709         fconfigure $fd -blocking 1
3710         if {[eof $fd]} {
3711                 if {[catch {close $fd}]} {
3712                         set ok 0
3713                 } else {
3714                         set ok 1
3715                 }
3716                 uplevel #0 $after $w $ok
3717                 return
3718         }
3719         fconfigure $fd -blocking 0
3720 }
3721
3722 proc console_chain {cmdlist w {ok 1}} {
3723         if {$ok} {
3724                 if {[llength $cmdlist] == 0} {
3725                         console_done $w $ok
3726                         return
3727                 }
3728
3729                 set cmd [lindex $cmdlist 0]
3730                 set cmdlist [lrange $cmdlist 1 end]
3731
3732                 if {[lindex $cmd 0] eq {console_exec}} {
3733                         console_exec $w \
3734                                 [lindex $cmd 1] \
3735                                 [list console_chain $cmdlist]
3736                 } else {
3737                         uplevel #0 $cmd $cmdlist $w $ok
3738                 }
3739         } else {
3740                 console_done $w $ok
3741         }
3742 }
3743
3744 proc console_done {args} {
3745         global console_cr console_data
3746
3747         switch -- [llength $args] {
3748         2 {
3749                 set w [lindex $args 0]
3750                 set ok [lindex $args 1]
3751         }
3752         3 {
3753                 set w [lindex $args 1]
3754                 set ok [lindex $args 2]
3755         }
3756         default {
3757                 error "wrong number of args: console_done ?ignored? w ok"
3758         }
3759         }
3760
3761         if {$ok} {
3762                 if {[winfo exists $w]} {
3763                         $w.m.s conf -background green -text {Success}
3764                         $w.ok conf -state normal
3765                 }
3766         } else {
3767                 if {![winfo exists $w]} {
3768                         console_init $w
3769                 }
3770                 $w.m.s conf -background red -text {Error: Command Failed}
3771                 $w.ok conf -state normal
3772         }
3773
3774         array unset console_cr $w
3775         array unset console_data $w
3776 }
3777
3778 ######################################################################
3779 ##
3780 ## ui commands
3781
3782 set starting_gitk_msg {Starting gitk... please wait...}
3783
3784 proc do_gitk {revs} {
3785         global env ui_status_value starting_gitk_msg
3786
3787         # -- On Windows gitk is severly broken, and right now it seems like
3788         #    nobody cares about fixing it.  The only known workaround is to
3789         #    always delete ~/.gitk before starting the program.
3790         #
3791         if {[is_Windows]} {
3792                 catch {file delete [file join $env(HOME) .gitk]}
3793         }
3794
3795         # -- Always start gitk through whatever we were loaded with.  This
3796         #    lets us bypass using shell process on Windows systems.
3797         #
3798         set cmd [info nameofexecutable]
3799         lappend cmd [gitexec gitk]
3800         if {$revs ne {}} {
3801                 append cmd { }
3802                 append cmd $revs
3803         }
3804
3805         if {[catch {eval exec $cmd &} err]} {
3806                 error_popup "Failed to start gitk:\n\n$err"
3807         } else {
3808                 set ui_status_value $starting_gitk_msg
3809                 after 10000 {
3810                         if {$ui_status_value eq $starting_gitk_msg} {
3811                                 set ui_status_value {Ready.}
3812                         }
3813                 }
3814         }
3815 }
3816
3817 proc do_stats {} {
3818         set fd [open "| git count-objects -v" r]
3819         while {[gets $fd line] > 0} {
3820                 if {[regexp {^([^:]+): (\d+)$} $line _ name value]} {
3821                         set stats($name) $value
3822                 }
3823         }
3824         close $fd
3825
3826         set packed_sz 0
3827         foreach p [glob -directory [gitdir objects pack] \
3828                 -type f \
3829                 -nocomplain -- *] {
3830                 incr packed_sz [file size $p]
3831         }
3832         if {$packed_sz > 0} {
3833                 set stats(size-pack) [expr {$packed_sz / 1024}]
3834         }
3835
3836         set w .stats_view
3837         toplevel $w
3838         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
3839
3840         label $w.header -text {Database Statistics} \
3841                 -font font_uibold
3842         pack $w.header -side top -fill x
3843
3844         frame $w.buttons -border 1
3845         button $w.buttons.close -text Close \
3846                 -font font_ui \
3847                 -command [list destroy $w]
3848         button $w.buttons.gc -text {Compress Database} \
3849                 -font font_ui \
3850                 -command "destroy $w;do_gc"
3851         pack $w.buttons.close -side right
3852         pack $w.buttons.gc -side left
3853         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
3854
3855         frame $w.stat -borderwidth 1 -relief solid
3856         foreach s {
3857                 {count           {Number of loose objects}}
3858                 {size            {Disk space used by loose objects} { KiB}}
3859                 {in-pack         {Number of packed objects}}
3860                 {packs           {Number of packs}}
3861                 {size-pack       {Disk space used by packed objects} { KiB}}
3862                 {prune-packable  {Packed objects waiting for pruning}}
3863                 {garbage         {Garbage files}}
3864                 } {
3865                 set name [lindex $s 0]
3866                 set label [lindex $s 1]
3867                 if {[catch {set value $stats($name)}]} continue
3868                 if {[llength $s] > 2} {
3869                         set value "$value[lindex $s 2]"
3870                 }
3871
3872                 label $w.stat.l_$name -text "$label:" -anchor w -font font_ui
3873                 label $w.stat.v_$name -text $value -anchor w -font font_ui
3874                 grid $w.stat.l_$name $w.stat.v_$name -sticky we -padx {0 5}
3875         }
3876         pack $w.stat -pady 10 -padx 10
3877
3878         bind $w <Visibility> "grab $w; focus $w"
3879         bind $w <Key-Escape> [list destroy $w]
3880         bind $w <Key-Return> [list destroy $w]
3881         wm title $w "[appname] ([reponame]): Database Statistics"
3882         tkwait window $w
3883 }
3884
3885 proc do_gc {} {
3886         set w [new_console {gc} {Compressing the object database}]
3887         console_chain {
3888                 {console_exec {git pack-refs --prune}}
3889                 {console_exec {git reflog expire --all}}
3890                 {console_exec {git repack -a -d -l}}
3891                 {console_exec {git rerere gc}}
3892         } $w
3893 }
3894
3895 proc do_fsck_objects {} {
3896         set w [new_console {fsck-objects} \
3897                 {Verifying the object database with fsck-objects}]
3898         set cmd [list git fsck-objects]
3899         lappend cmd --full
3900         lappend cmd --cache
3901         lappend cmd --strict
3902         console_exec $w $cmd console_done
3903 }
3904
3905 set is_quitting 0
3906
3907 proc do_quit {} {
3908         global ui_comm is_quitting repo_config commit_type
3909
3910         if {$is_quitting} return
3911         set is_quitting 1
3912
3913         # -- Stash our current commit buffer.
3914         #
3915         set save [gitdir GITGUI_MSG]
3916         set msg [string trim [$ui_comm get 0.0 end]]
3917         regsub -all -line {[ \r\t]+$} $msg {} msg
3918         if {(![string match amend* $commit_type]
3919                 || [$ui_comm edit modified])
3920                 && $msg ne {}} {
3921                 catch {
3922                         set fd [open $save w]
3923                         puts -nonewline $fd $msg
3924                         close $fd
3925                 }
3926         } else {
3927                 catch {file delete $save}
3928         }
3929
3930         # -- Stash our current window geometry into this repository.
3931         #
3932         set cfg_geometry [list]
3933         lappend cfg_geometry [wm geometry .]
3934         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
3935         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
3936         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
3937                 set rc_geometry {}
3938         }
3939         if {$cfg_geometry ne $rc_geometry} {
3940                 catch {exec git repo-config gui.geometry $cfg_geometry}
3941         }
3942
3943         destroy .
3944 }
3945
3946 proc do_rescan {} {
3947         rescan {set ui_status_value {Ready.}}
3948 }
3949
3950 proc unstage_helper {txt paths} {
3951         global file_states current_diff_path
3952
3953         if {![lock_index begin-update]} return
3954
3955         set pathList [list]
3956         set after {}
3957         foreach path $paths {
3958                 switch -glob -- [lindex $file_states($path) 0] {
3959                 A? -
3960                 M? -
3961                 D? {
3962                         lappend pathList $path
3963                         if {$path eq $current_diff_path} {
3964                                 set after {reshow_diff;}
3965                         }
3966                 }
3967                 }
3968         }
3969         if {$pathList eq {}} {
3970                 unlock_index
3971         } else {
3972                 update_indexinfo \
3973                         $txt \
3974                         $pathList \
3975                         [concat $after {set ui_status_value {Ready.}}]
3976         }
3977 }
3978
3979 proc do_unstage_selection {} {
3980         global current_diff_path selected_paths
3981
3982         if {[array size selected_paths] > 0} {
3983                 unstage_helper \
3984                         {Unstaging selected files from commit} \
3985                         [array names selected_paths]
3986         } elseif {$current_diff_path ne {}} {
3987                 unstage_helper \
3988                         "Unstaging [short_path $current_diff_path] from commit" \
3989                         [list $current_diff_path]
3990         }
3991 }
3992
3993 proc add_helper {txt paths} {
3994         global file_states current_diff_path
3995
3996         if {![lock_index begin-update]} return
3997
3998         set pathList [list]
3999         set after {}
4000         foreach path $paths {
4001                 switch -glob -- [lindex $file_states($path) 0] {
4002                 _O -
4003                 ?M -
4004                 ?D -
4005                 U? {
4006                         lappend pathList $path
4007                         if {$path eq $current_diff_path} {
4008                                 set after {reshow_diff;}
4009                         }
4010                 }
4011                 }
4012         }
4013         if {$pathList eq {}} {
4014                 unlock_index
4015         } else {
4016                 update_index \
4017                         $txt \
4018                         $pathList \
4019                         [concat $after {set ui_status_value {Ready to commit.}}]
4020         }
4021 }
4022
4023 proc do_add_selection {} {
4024         global current_diff_path selected_paths
4025
4026         if {[array size selected_paths] > 0} {
4027                 add_helper \
4028                         {Adding selected files} \
4029                         [array names selected_paths]
4030         } elseif {$current_diff_path ne {}} {
4031                 add_helper \
4032                         "Adding [short_path $current_diff_path]" \
4033                         [list $current_diff_path]
4034         }
4035 }
4036
4037 proc do_add_all {} {
4038         global file_states
4039
4040         set paths [list]
4041         foreach path [array names file_states] {
4042                 switch -glob -- [lindex $file_states($path) 0] {
4043                 U? {continue}
4044                 ?M -
4045                 ?D {lappend paths $path}
4046                 }
4047         }
4048         add_helper {Adding all changed files} $paths
4049 }
4050
4051 proc revert_helper {txt paths} {
4052         global file_states current_diff_path
4053
4054         if {![lock_index begin-update]} return
4055
4056         set pathList [list]
4057         set after {}
4058         foreach path $paths {
4059                 switch -glob -- [lindex $file_states($path) 0] {
4060                 U? {continue}
4061                 ?M -
4062                 ?D {
4063                         lappend pathList $path
4064                         if {$path eq $current_diff_path} {
4065                                 set after {reshow_diff;}
4066                         }
4067                 }
4068                 }
4069         }
4070
4071         set n [llength $pathList]
4072         if {$n == 0} {
4073                 unlock_index
4074                 return
4075         } elseif {$n == 1} {
4076                 set s "[short_path [lindex $pathList]]"
4077         } else {
4078                 set s "these $n files"
4079         }
4080
4081         set reply [tk_dialog \
4082                 .confirm_revert \
4083                 "[appname] ([reponame])" \
4084                 "Revert changes in $s?
4085
4086 Any unadded changes will be permanently lost by the revert." \
4087                 question \
4088                 1 \
4089                 {Do Nothing} \
4090                 {Revert Changes} \
4091                 ]
4092         if {$reply == 1} {
4093                 checkout_index \
4094                         $txt \
4095                         $pathList \
4096                         [concat $after {set ui_status_value {Ready.}}]
4097         } else {
4098                 unlock_index
4099         }
4100 }
4101
4102 proc do_revert_selection {} {
4103         global current_diff_path selected_paths
4104
4105         if {[array size selected_paths] > 0} {
4106                 revert_helper \
4107                         {Reverting selected files} \
4108                         [array names selected_paths]
4109         } elseif {$current_diff_path ne {}} {
4110                 revert_helper \
4111                         "Reverting [short_path $current_diff_path]" \
4112                         [list $current_diff_path]
4113         }
4114 }
4115
4116 proc do_signoff {} {
4117         global ui_comm
4118
4119         set me [committer_ident]
4120         if {$me eq {}} return
4121
4122         set sob "Signed-off-by: $me"
4123         set last [$ui_comm get {end -1c linestart} {end -1c}]
4124         if {$last ne $sob} {
4125                 $ui_comm edit separator
4126                 if {$last ne {}
4127                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
4128                         $ui_comm insert end "\n"
4129                 }
4130                 $ui_comm insert end "\n$sob"
4131                 $ui_comm edit separator
4132                 $ui_comm see end
4133         }
4134 }
4135
4136 proc do_select_commit_type {} {
4137         global commit_type selected_commit_type
4138
4139         if {$selected_commit_type eq {new}
4140                 && [string match amend* $commit_type]} {
4141                 create_new_commit
4142         } elseif {$selected_commit_type eq {amend}
4143                 && ![string match amend* $commit_type]} {
4144                 load_last_commit
4145
4146                 # The amend request was rejected...
4147                 #
4148                 if {![string match amend* $commit_type]} {
4149                         set selected_commit_type new
4150                 }
4151         }
4152 }
4153
4154 proc do_commit {} {
4155         commit_tree
4156 }
4157
4158 proc do_about {} {
4159         global appvers copyright
4160         global tcl_patchLevel tk_patchLevel
4161
4162         set w .about_dialog
4163         toplevel $w
4164         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
4165
4166         label $w.header -text "About [appname]" \
4167                 -font font_uibold
4168         pack $w.header -side top -fill x
4169
4170         frame $w.buttons
4171         button $w.buttons.close -text {Close} \
4172                 -font font_ui \
4173                 -command [list destroy $w]
4174         pack $w.buttons.close -side right
4175         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
4176
4177         label $w.desc \
4178                 -text "[appname] - a commit creation tool for Git.
4179 $copyright" \
4180                 -padx 5 -pady 5 \
4181                 -justify left \
4182                 -anchor w \
4183                 -borderwidth 1 \
4184                 -relief solid \
4185                 -font font_ui
4186         pack $w.desc -side top -fill x -padx 5 -pady 5
4187
4188         set v {}
4189         append v "[appname] version $appvers\n"
4190         append v "[exec git version]\n"
4191         append v "\n"
4192         if {$tcl_patchLevel eq $tk_patchLevel} {
4193                 append v "Tcl/Tk version $tcl_patchLevel"
4194         } else {
4195                 append v "Tcl version $tcl_patchLevel"
4196                 append v ", Tk version $tk_patchLevel"
4197         }
4198
4199         label $w.vers \
4200                 -text $v \
4201                 -padx 5 -pady 5 \
4202                 -justify left \
4203                 -anchor w \
4204                 -borderwidth 1 \
4205                 -relief solid \
4206                 -font font_ui
4207         pack $w.vers -side top -fill x -padx 5 -pady 5
4208
4209         menu $w.ctxm -tearoff 0
4210         $w.ctxm add command \
4211                 -label {Copy} \
4212                 -font font_ui \
4213                 -command "
4214                 clipboard clear
4215                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
4216         "
4217
4218         bind $w <Visibility> "grab $w; focus $w"
4219         bind $w <Key-Escape> "destroy $w"
4220         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
4221         wm title $w "About [appname]"
4222         tkwait window $w
4223 }
4224
4225 proc do_options {} {
4226         global repo_config global_config font_descs
4227         global repo_config_new global_config_new
4228
4229         array unset repo_config_new
4230         array unset global_config_new
4231         foreach name [array names repo_config] {
4232                 set repo_config_new($name) $repo_config($name)
4233         }
4234         load_config 1
4235         foreach name [array names repo_config] {
4236                 switch -- $name {
4237                 gui.diffcontext {continue}
4238                 }
4239                 set repo_config_new($name) $repo_config($name)
4240         }
4241         foreach name [array names global_config] {
4242                 set global_config_new($name) $global_config($name)
4243         }
4244
4245         set w .options_editor
4246         toplevel $w
4247         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
4248
4249         label $w.header -text "[appname] Options" \
4250                 -font font_uibold
4251         pack $w.header -side top -fill x
4252
4253         frame $w.buttons
4254         button $w.buttons.restore -text {Restore Defaults} \
4255                 -font font_ui \
4256                 -command do_restore_defaults
4257         pack $w.buttons.restore -side left
4258         button $w.buttons.save -text Save \
4259                 -font font_ui \
4260                 -command [list do_save_config $w]
4261         pack $w.buttons.save -side right
4262         button $w.buttons.cancel -text {Cancel} \
4263                 -font font_ui \
4264                 -command [list destroy $w]
4265         pack $w.buttons.cancel -side right -padx 5
4266         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
4267
4268         labelframe $w.repo -text "[reponame] Repository" \
4269                 -font font_ui
4270         labelframe $w.global -text {Global (All Repositories)} \
4271                 -font font_ui
4272         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
4273         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
4274
4275         set optid 0
4276         foreach option {
4277                 {t user.name {User Name}}
4278                 {t user.email {Email Address}}
4279
4280                 {b merge.summary {Summarize Merge Commits}}
4281                 {i-1..5 merge.verbosity {Merge Verbosity}}
4282
4283                 {b gui.trustmtime  {Trust File Modification Timestamps}}
4284                 {i-1..99 gui.diffcontext {Number of Diff Context Lines}}
4285                 {t gui.newbranchtemplate {New Branch Name Template}}
4286                 } {
4287                 set type [lindex $option 0]
4288                 set name [lindex $option 1]
4289                 set text [lindex $option 2]
4290                 incr optid
4291                 foreach f {repo global} {
4292                         switch -glob -- $type {
4293                         b {
4294                                 checkbutton $w.$f.$optid -text $text \
4295                                         -variable ${f}_config_new($name) \
4296                                         -onvalue true \
4297                                         -offvalue false \
4298                                         -font font_ui
4299                                 pack $w.$f.$optid -side top -anchor w
4300                         }
4301                         i-* {
4302                                 regexp -- {-(\d+)\.\.(\d+)$} $type _junk min max
4303                                 frame $w.$f.$optid
4304                                 label $w.$f.$optid.l -text "$text:" -font font_ui
4305                                 pack $w.$f.$optid.l -side left -anchor w -fill x
4306                                 spinbox $w.$f.$optid.v \
4307                                         -textvariable ${f}_config_new($name) \
4308                                         -from $min \
4309                                         -to $max \
4310                                         -increment 1 \
4311                                         -width [expr {1 + [string length $max]}] \
4312                                         -font font_ui
4313                                 bind $w.$f.$optid.v <FocusIn> {%W selection range 0 end}
4314                                 pack $w.$f.$optid.v -side right -anchor e -padx 5
4315                                 pack $w.$f.$optid -side top -anchor w -fill x
4316                         }
4317                         t {
4318                                 frame $w.$f.$optid
4319                                 label $w.$f.$optid.l -text "$text:" -font font_ui
4320                                 entry $w.$f.$optid.v \
4321                                         -borderwidth 1 \
4322                                         -relief sunken \
4323                                         -width 20 \
4324                                         -textvariable ${f}_config_new($name) \
4325                                         -font font_ui
4326                                 pack $w.$f.$optid.l -side left -anchor w
4327                                 pack $w.$f.$optid.v -side left -anchor w \
4328                                         -fill x -expand 1 \
4329                                         -padx 5
4330                                 pack $w.$f.$optid -side top -anchor w -fill x
4331                         }
4332                         }
4333                 }
4334         }
4335
4336         set all_fonts [lsort [font families]]
4337         foreach option $font_descs {
4338                 set name [lindex $option 0]
4339                 set font [lindex $option 1]
4340                 set text [lindex $option 2]
4341
4342                 set global_config_new(gui.$font^^family) \
4343                         [font configure $font -family]
4344                 set global_config_new(gui.$font^^size) \
4345                         [font configure $font -size]
4346
4347                 frame $w.global.$name
4348                 label $w.global.$name.l -text "$text:" -font font_ui
4349                 pack $w.global.$name.l -side left -anchor w -fill x
4350                 eval tk_optionMenu $w.global.$name.family \
4351                         global_config_new(gui.$font^^family) \
4352                         $all_fonts
4353                 spinbox $w.global.$name.size \
4354                         -textvariable global_config_new(gui.$font^^size) \
4355                         -from 2 -to 80 -increment 1 \
4356                         -width 3 \
4357                         -font font_ui
4358                 bind $w.global.$name.size <FocusIn> {%W selection range 0 end}
4359                 pack $w.global.$name.size -side right -anchor e
4360                 pack $w.global.$name.family -side right -anchor e
4361                 pack $w.global.$name -side top -anchor w -fill x
4362         }
4363
4364         bind $w <Visibility> "grab $w; focus $w"
4365         bind $w <Key-Escape> "destroy $w"
4366         wm title $w "[appname] ([reponame]): Options"
4367         tkwait window $w
4368 }
4369
4370 proc do_restore_defaults {} {
4371         global font_descs default_config repo_config
4372         global repo_config_new global_config_new
4373
4374         foreach name [array names default_config] {
4375                 set repo_config_new($name) $default_config($name)
4376                 set global_config_new($name) $default_config($name)
4377         }
4378
4379         foreach option $font_descs {
4380                 set name [lindex $option 0]
4381                 set repo_config(gui.$name) $default_config(gui.$name)
4382         }
4383         apply_config
4384
4385         foreach option $font_descs {
4386                 set name [lindex $option 0]
4387                 set font [lindex $option 1]
4388                 set global_config_new(gui.$font^^family) \
4389                         [font configure $font -family]
4390                 set global_config_new(gui.$font^^size) \
4391                         [font configure $font -size]
4392         }
4393 }
4394
4395 proc do_save_config {w} {
4396         if {[catch {save_config} err]} {
4397                 error_popup "Failed to completely save options:\n\n$err"
4398         }
4399         reshow_diff
4400         destroy $w
4401 }
4402
4403 proc do_windows_shortcut {} {
4404         global argv0
4405
4406         set fn [tk_getSaveFile \
4407                 -parent . \
4408                 -title "[appname] ([reponame]): Create Desktop Icon" \
4409                 -initialfile "Git [reponame].bat"]
4410         if {$fn != {}} {
4411                 if {[catch {
4412                                 set fd [open $fn w]
4413                                 puts $fd "@ECHO Entering [reponame]"
4414                                 puts $fd "@ECHO Starting git-gui... please wait..."
4415                                 puts $fd "@SET PATH=[file normalize [gitexec]];%PATH%"
4416                                 puts $fd "@SET GIT_DIR=[file normalize [gitdir]]"
4417                                 puts -nonewline $fd "@\"[info nameofexecutable]\""
4418                                 puts $fd " \"[file normalize $argv0]\""
4419                                 close $fd
4420                         } err]} {
4421                         error_popup "Cannot write script:\n\n$err"
4422                 }
4423         }
4424 }
4425
4426 proc do_cygwin_shortcut {} {
4427         global argv0
4428
4429         if {[catch {
4430                 set desktop [exec cygpath \
4431                         --windows \
4432                         --absolute \
4433                         --long-name \
4434                         --desktop]
4435                 }]} {
4436                         set desktop .
4437         }
4438         set fn [tk_getSaveFile \
4439                 -parent . \
4440                 -title "[appname] ([reponame]): Create Desktop Icon" \
4441                 -initialdir $desktop \
4442                 -initialfile "Git [reponame].bat"]
4443         if {$fn != {}} {
4444                 if {[catch {
4445                                 set fd [open $fn w]
4446                                 set sh [exec cygpath \
4447                                         --windows \
4448                                         --absolute \
4449                                         /bin/sh]
4450                                 set me [exec cygpath \
4451                                         --unix \
4452                                         --absolute \
4453                                         $argv0]
4454                                 set gd [exec cygpath \
4455                                         --unix \
4456                                         --absolute \
4457                                         [gitdir]]
4458                                 set gw [exec cygpath \
4459                                         --windows \
4460                                         --absolute \
4461                                         [file dirname [gitdir]]]
4462                                 regsub -all ' $me "'\\''" me
4463                                 regsub -all ' $gd "'\\''" gd
4464                                 puts $fd "@ECHO Entering $gw"
4465                                 puts $fd "@ECHO Starting git-gui... please wait..."
4466                                 puts -nonewline $fd "@\"$sh\" --login -c \""
4467                                 puts -nonewline $fd "GIT_DIR='$gd'"
4468                                 puts -nonewline $fd " '$me'"
4469                                 puts $fd "&\""
4470                                 close $fd
4471                         } err]} {
4472                         error_popup "Cannot write script:\n\n$err"
4473                 }
4474         }
4475 }
4476
4477 proc do_macosx_app {} {
4478         global argv0 env
4479
4480         set fn [tk_getSaveFile \
4481                 -parent . \
4482                 -title "[appname] ([reponame]): Create Desktop Icon" \
4483                 -initialdir [file join $env(HOME) Desktop] \
4484                 -initialfile "Git [reponame].app"]
4485         if {$fn != {}} {
4486                 if {[catch {
4487                                 set Contents [file join $fn Contents]
4488                                 set MacOS [file join $Contents MacOS]
4489                                 set exe [file join $MacOS git-gui]
4490
4491                                 file mkdir $MacOS
4492
4493                                 set fd [open [file join $Contents Info.plist] w]
4494                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
4495 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
4496 <plist version="1.0">
4497 <dict>
4498         <key>CFBundleDevelopmentRegion</key>
4499         <string>English</string>
4500         <key>CFBundleExecutable</key>
4501         <string>git-gui</string>
4502         <key>CFBundleIdentifier</key>
4503         <string>org.spearce.git-gui</string>
4504         <key>CFBundleInfoDictionaryVersion</key>
4505         <string>6.0</string>
4506         <key>CFBundlePackageType</key>
4507         <string>APPL</string>
4508         <key>CFBundleSignature</key>
4509         <string>????</string>
4510         <key>CFBundleVersion</key>
4511         <string>1.0</string>
4512         <key>NSPrincipalClass</key>
4513         <string>NSApplication</string>
4514 </dict>
4515 </plist>}
4516                                 close $fd
4517
4518                                 set fd [open $exe w]
4519                                 set gd [file normalize [gitdir]]
4520                                 set ep [file normalize [gitexec]]
4521                                 regsub -all ' $gd "'\\''" gd
4522                                 regsub -all ' $ep "'\\''" ep
4523                                 puts $fd "#!/bin/sh"
4524                                 foreach name [array names env] {
4525                                         if {[string match GIT_* $name]} {
4526                                                 regsub -all ' $env($name) "'\\''" v
4527                                                 puts $fd "export $name='$v'"
4528                                         }
4529                                 }
4530                                 puts $fd "export PATH='$ep':\$PATH"
4531                                 puts $fd "export GIT_DIR='$gd'"
4532                                 puts $fd "exec [file normalize $argv0]"
4533                                 close $fd
4534
4535                                 file attributes $exe -permissions u+x,g+x,o+x
4536                         } err]} {
4537                         error_popup "Cannot write icon:\n\n$err"
4538                 }
4539         }
4540 }
4541
4542 proc toggle_or_diff {w x y} {
4543         global file_states file_lists current_diff_path ui_index ui_workdir
4544         global last_clicked selected_paths
4545
4546         set pos [split [$w index @$x,$y] .]
4547         set lno [lindex $pos 0]
4548         set col [lindex $pos 1]
4549         set path [lindex $file_lists($w) [expr {$lno - 1}]]
4550         if {$path eq {}} {
4551                 set last_clicked {}
4552                 return
4553         }
4554
4555         set last_clicked [list $w $lno]
4556         array unset selected_paths
4557         $ui_index tag remove in_sel 0.0 end
4558         $ui_workdir tag remove in_sel 0.0 end
4559
4560         if {$col == 0} {
4561                 if {$current_diff_path eq $path} {
4562                         set after {reshow_diff;}
4563                 } else {
4564                         set after {}
4565                 }
4566                 if {$w eq $ui_index} {
4567                         update_indexinfo \
4568                                 "Unstaging [short_path $path] from commit" \
4569                                 [list $path] \
4570                                 [concat $after {set ui_status_value {Ready.}}]
4571                 } elseif {$w eq $ui_workdir} {
4572                         update_index \
4573                                 "Adding [short_path $path]" \
4574                                 [list $path] \
4575                                 [concat $after {set ui_status_value {Ready.}}]
4576                 }
4577         } else {
4578                 show_diff $path $w $lno
4579         }
4580 }
4581
4582 proc add_one_to_selection {w x y} {
4583         global file_lists last_clicked selected_paths
4584
4585         set lno [lindex [split [$w index @$x,$y] .] 0]
4586         set path [lindex $file_lists($w) [expr {$lno - 1}]]
4587         if {$path eq {}} {
4588                 set last_clicked {}
4589                 return
4590         }
4591
4592         if {$last_clicked ne {}
4593                 && [lindex $last_clicked 0] ne $w} {
4594                 array unset selected_paths
4595                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
4596         }
4597
4598         set last_clicked [list $w $lno]
4599         if {[catch {set in_sel $selected_paths($path)}]} {
4600                 set in_sel 0
4601         }
4602         if {$in_sel} {
4603                 unset selected_paths($path)
4604                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
4605         } else {
4606                 set selected_paths($path) 1
4607                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
4608         }
4609 }
4610
4611 proc add_range_to_selection {w x y} {
4612         global file_lists last_clicked selected_paths
4613
4614         if {[lindex $last_clicked 0] ne $w} {
4615                 toggle_or_diff $w $x $y
4616                 return
4617         }
4618
4619         set lno [lindex [split [$w index @$x,$y] .] 0]
4620         set lc [lindex $last_clicked 1]
4621         if {$lc < $lno} {
4622                 set begin $lc
4623                 set end $lno
4624         } else {
4625                 set begin $lno
4626                 set end $lc
4627         }
4628
4629         foreach path [lrange $file_lists($w) \
4630                 [expr {$begin - 1}] \
4631                 [expr {$end - 1}]] {
4632                 set selected_paths($path) 1
4633         }
4634         $w tag add in_sel $begin.0 [expr {$end + 1}].0
4635 }
4636
4637 ######################################################################
4638 ##
4639 ## config defaults
4640
4641 set cursor_ptr arrow
4642 font create font_diff -family Courier -size 10
4643 font create font_ui
4644 catch {
4645         label .dummy
4646         eval font configure font_ui [font actual [.dummy cget -font]]
4647         destroy .dummy
4648 }
4649
4650 font create font_uibold
4651 font create font_diffbold
4652
4653 if {[is_Windows]} {
4654         set M1B Control
4655         set M1T Ctrl
4656 } elseif {[is_MacOSX]} {
4657         set M1B M1
4658         set M1T Cmd
4659 } else {
4660         set M1B M1
4661         set M1T M1
4662 }
4663
4664 proc apply_config {} {
4665         global repo_config font_descs
4666
4667         foreach option $font_descs {
4668                 set name [lindex $option 0]
4669                 set font [lindex $option 1]
4670                 if {[catch {
4671                         foreach {cn cv} $repo_config(gui.$name) {
4672                                 font configure $font $cn $cv
4673                         }
4674                         } err]} {
4675                         error_popup "Invalid font specified in gui.$name:\n\n$err"
4676                 }
4677                 foreach {cn cv} [font configure $font] {
4678                         font configure ${font}bold $cn $cv
4679                 }
4680                 font configure ${font}bold -weight bold
4681         }
4682 }
4683
4684 set default_config(merge.summary) false
4685 set default_config(merge.verbosity) 2
4686 set default_config(user.name) {}
4687 set default_config(user.email) {}
4688
4689 set default_config(gui.trustmtime) false
4690 set default_config(gui.diffcontext) 5
4691 set default_config(gui.newbranchtemplate) {}
4692 set default_config(gui.fontui) [font configure font_ui]
4693 set default_config(gui.fontdiff) [font configure font_diff]
4694 set font_descs {
4695         {fontui   font_ui   {Main Font}}
4696         {fontdiff font_diff {Diff/Console Font}}
4697 }
4698 load_config 0
4699 apply_config
4700
4701 ######################################################################
4702 ##
4703 ## ui construction
4704
4705 # -- Menu Bar
4706 #
4707 menu .mbar -tearoff 0
4708 .mbar add cascade -label Repository -menu .mbar.repository
4709 .mbar add cascade -label Edit -menu .mbar.edit
4710 if {!$single_commit} {
4711         .mbar add cascade -label Branch -menu .mbar.branch
4712 }
4713 .mbar add cascade -label Commit -menu .mbar.commit
4714 if {!$single_commit} {
4715         .mbar add cascade -label Merge -menu .mbar.merge
4716         .mbar add cascade -label Fetch -menu .mbar.fetch
4717         .mbar add cascade -label Push -menu .mbar.push
4718 }
4719 . configure -menu .mbar
4720
4721 # -- Repository Menu
4722 #
4723 menu .mbar.repository
4724
4725 .mbar.repository add command \
4726         -label {Browse Current Branch} \
4727         -command {new_browser $current_branch} \
4728         -font font_ui
4729 .mbar.repository add separator
4730
4731 .mbar.repository add command \
4732         -label {Visualize Current Branch} \
4733         -command {do_gitk {}} \
4734         -font font_ui
4735 .mbar.repository add command \
4736         -label {Visualize All Branches} \
4737         -command {do_gitk {--all}} \
4738         -font font_ui
4739 .mbar.repository add separator
4740
4741 if {!$single_commit} {
4742         .mbar.repository add command -label {Database Statistics} \
4743                 -command do_stats \
4744                 -font font_ui
4745
4746         .mbar.repository add command -label {Compress Database} \
4747                 -command do_gc \
4748                 -font font_ui
4749
4750         .mbar.repository add command -label {Verify Database} \
4751                 -command do_fsck_objects \
4752                 -font font_ui
4753
4754         .mbar.repository add separator
4755
4756         if {[is_Cygwin]} {
4757                 .mbar.repository add command \
4758                         -label {Create Desktop Icon} \
4759                         -command do_cygwin_shortcut \
4760                         -font font_ui
4761         } elseif {[is_Windows]} {
4762                 .mbar.repository add command \
4763                         -label {Create Desktop Icon} \
4764                         -command do_windows_shortcut \
4765                         -font font_ui
4766         } elseif {[is_MacOSX]} {
4767                 .mbar.repository add command \
4768                         -label {Create Desktop Icon} \
4769                         -command do_macosx_app \
4770                         -font font_ui
4771         }
4772 }
4773
4774 .mbar.repository add command -label Quit \
4775         -command do_quit \
4776         -accelerator $M1T-Q \
4777         -font font_ui
4778
4779 # -- Edit Menu
4780 #
4781 menu .mbar.edit
4782 .mbar.edit add command -label Undo \
4783         -command {catch {[focus] edit undo}} \
4784         -accelerator $M1T-Z \
4785         -font font_ui
4786 .mbar.edit add command -label Redo \
4787         -command {catch {[focus] edit redo}} \
4788         -accelerator $M1T-Y \
4789         -font font_ui
4790 .mbar.edit add separator
4791 .mbar.edit add command -label Cut \
4792         -command {catch {tk_textCut [focus]}} \
4793         -accelerator $M1T-X \
4794         -font font_ui
4795 .mbar.edit add command -label Copy \
4796         -command {catch {tk_textCopy [focus]}} \
4797         -accelerator $M1T-C \
4798         -font font_ui
4799 .mbar.edit add command -label Paste \
4800         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
4801         -accelerator $M1T-V \
4802         -font font_ui
4803 .mbar.edit add command -label Delete \
4804         -command {catch {[focus] delete sel.first sel.last}} \
4805         -accelerator Del \
4806         -font font_ui
4807 .mbar.edit add separator
4808 .mbar.edit add command -label {Select All} \
4809         -command {catch {[focus] tag add sel 0.0 end}} \
4810         -accelerator $M1T-A \
4811         -font font_ui
4812
4813 # -- Branch Menu
4814 #
4815 if {!$single_commit} {
4816         menu .mbar.branch
4817
4818         .mbar.branch add command -label {Create...} \
4819                 -command do_create_branch \
4820                 -accelerator $M1T-N \
4821                 -font font_ui
4822         lappend disable_on_lock [list .mbar.branch entryconf \
4823                 [.mbar.branch index last] -state]
4824
4825         .mbar.branch add command -label {Delete...} \
4826                 -command do_delete_branch \
4827                 -font font_ui
4828         lappend disable_on_lock [list .mbar.branch entryconf \
4829                 [.mbar.branch index last] -state]
4830 }
4831
4832 # -- Commit Menu
4833 #
4834 menu .mbar.commit
4835
4836 .mbar.commit add radiobutton \
4837         -label {New Commit} \
4838         -command do_select_commit_type \
4839         -variable selected_commit_type \
4840         -value new \
4841         -font font_ui
4842 lappend disable_on_lock \
4843         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4844
4845 .mbar.commit add radiobutton \
4846         -label {Amend Last Commit} \
4847         -command do_select_commit_type \
4848         -variable selected_commit_type \
4849         -value amend \
4850         -font font_ui
4851 lappend disable_on_lock \
4852         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4853
4854 .mbar.commit add separator
4855
4856 .mbar.commit add command -label Rescan \
4857         -command do_rescan \
4858         -accelerator F5 \
4859         -font font_ui
4860 lappend disable_on_lock \
4861         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4862
4863 .mbar.commit add command -label {Add To Commit} \
4864         -command do_add_selection \
4865         -font font_ui
4866 lappend disable_on_lock \
4867         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4868
4869 .mbar.commit add command -label {Add All To Commit} \
4870         -command do_add_all \
4871         -accelerator $M1T-I \
4872         -font font_ui
4873 lappend disable_on_lock \
4874         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4875
4876 .mbar.commit add command -label {Unstage From Commit} \
4877         -command do_unstage_selection \
4878         -font font_ui
4879 lappend disable_on_lock \
4880         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4881
4882 .mbar.commit add command -label {Revert Changes} \
4883         -command do_revert_selection \
4884         -font font_ui
4885 lappend disable_on_lock \
4886         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4887
4888 .mbar.commit add separator
4889
4890 .mbar.commit add command -label {Sign Off} \
4891         -command do_signoff \
4892         -accelerator $M1T-S \
4893         -font font_ui
4894
4895 .mbar.commit add command -label Commit \
4896         -command do_commit \
4897         -accelerator $M1T-Return \
4898         -font font_ui
4899 lappend disable_on_lock \
4900         [list .mbar.commit entryconf [.mbar.commit index last] -state]
4901
4902 if {[is_MacOSX]} {
4903         # -- Apple Menu (Mac OS X only)
4904         #
4905         .mbar add cascade -label Apple -menu .mbar.apple
4906         menu .mbar.apple
4907
4908         .mbar.apple add command -label "About [appname]" \
4909                 -command do_about \
4910                 -font font_ui
4911         .mbar.apple add command -label "[appname] Options..." \
4912                 -command do_options \
4913                 -font font_ui
4914 } else {
4915         # -- Edit Menu
4916         #
4917         .mbar.edit add separator
4918         .mbar.edit add command -label {Options...} \
4919                 -command do_options \
4920                 -font font_ui
4921
4922         # -- Tools Menu
4923         #
4924         if {[file exists /usr/local/miga/lib/gui-miga]
4925                 && [file exists .pvcsrc]} {
4926         proc do_miga {} {
4927                 global ui_status_value
4928                 if {![lock_index update]} return
4929                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
4930                 set miga_fd [open "|$cmd" r]
4931                 fconfigure $miga_fd -blocking 0
4932                 fileevent $miga_fd readable [list miga_done $miga_fd]
4933                 set ui_status_value {Running miga...}
4934         }
4935         proc miga_done {fd} {
4936                 read $fd 512
4937                 if {[eof $fd]} {
4938                         close $fd
4939                         unlock_index
4940                         rescan [list set ui_status_value {Ready.}]
4941                 }
4942         }
4943         .mbar add cascade -label Tools -menu .mbar.tools
4944         menu .mbar.tools
4945         .mbar.tools add command -label "Migrate" \
4946                 -command do_miga \
4947                 -font font_ui
4948         lappend disable_on_lock \
4949                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
4950         }
4951 }
4952
4953 # -- Help Menu
4954 #
4955 .mbar add cascade -label Help -menu .mbar.help
4956 menu .mbar.help
4957
4958 if {![is_MacOSX]} {
4959         .mbar.help add command -label "About [appname]" \
4960                 -command do_about \
4961                 -font font_ui
4962 }
4963
4964 set browser {}
4965 catch {set browser $repo_config(instaweb.browser)}
4966 set doc_path [file dirname [gitexec]]
4967 set doc_path [file join $doc_path Documentation index.html]
4968
4969 if {[is_Cygwin]} {
4970         set doc_path [exec cygpath --windows $doc_path]
4971 }
4972
4973 if {$browser eq {}} {
4974         if {[is_MacOSX]} {
4975                 set browser open
4976         } elseif {[is_Cygwin]} {
4977                 set program_files [file dirname [exec cygpath --windir]]
4978                 set program_files [file join $program_files {Program Files}]
4979                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
4980                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
4981                 if {[file exists $firefox]} {
4982                         set browser $firefox
4983                 } elseif {[file exists $ie]} {
4984                         set browser $ie
4985                 }
4986                 unset program_files firefox ie
4987         }
4988 }
4989
4990 if {[file isfile $doc_path]} {
4991         set doc_url "file:$doc_path"
4992 } else {
4993         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
4994 }
4995
4996 if {$browser ne {}} {
4997         .mbar.help add command -label {Online Documentation} \
4998                 -command [list exec $browser $doc_url &] \
4999                 -font font_ui
5000 }
5001 unset browser doc_path doc_url
5002
5003 # -- Branch Control
5004 #
5005 frame .branch \
5006         -borderwidth 1 \
5007         -relief sunken
5008 label .branch.l1 \
5009         -text {Current Branch:} \
5010         -anchor w \
5011         -justify left \
5012         -font font_ui
5013 label .branch.cb \
5014         -textvariable current_branch \
5015         -anchor w \
5016         -justify left \
5017         -font font_ui
5018 pack .branch.l1 -side left
5019 pack .branch.cb -side left -fill x
5020 pack .branch -side top -fill x
5021
5022 if {!$single_commit} {
5023         menu .mbar.merge
5024         .mbar.merge add command -label {Local Merge...} \
5025                 -command do_local_merge \
5026                 -font font_ui
5027         lappend disable_on_lock \
5028                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
5029         .mbar.merge add command -label {Abort Merge...} \
5030                 -command do_reset_hard \
5031                 -font font_ui
5032         lappend disable_on_lock \
5033                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
5034
5035
5036         menu .mbar.fetch
5037
5038         menu .mbar.push
5039         .mbar.push add command -label {Push...} \
5040                 -command do_push_anywhere \
5041                 -font font_ui
5042 }
5043
5044 # -- Main Window Layout
5045 #
5046 panedwindow .vpane -orient vertical
5047 panedwindow .vpane.files -orient horizontal
5048 .vpane add .vpane.files -sticky nsew -height 100 -width 200
5049 pack .vpane -anchor n -side top -fill both -expand 1
5050
5051 # -- Index File List
5052 #
5053 frame .vpane.files.index -height 100 -width 200
5054 label .vpane.files.index.title -text {Changes To Be Committed} \
5055         -background green \
5056         -font font_ui
5057 text $ui_index -background white -borderwidth 0 \
5058         -width 20 -height 10 \
5059         -wrap none \
5060         -font font_ui \
5061         -cursor $cursor_ptr \
5062         -xscrollcommand {.vpane.files.index.sx set} \
5063         -yscrollcommand {.vpane.files.index.sy set} \
5064         -state disabled
5065 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
5066 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
5067 pack .vpane.files.index.title -side top -fill x
5068 pack .vpane.files.index.sx -side bottom -fill x
5069 pack .vpane.files.index.sy -side right -fill y
5070 pack $ui_index -side left -fill both -expand 1
5071 .vpane.files add .vpane.files.index -sticky nsew
5072
5073 # -- Working Directory File List
5074 #
5075 frame .vpane.files.workdir -height 100 -width 200
5076 label .vpane.files.workdir.title -text {Changed But Not Updated} \
5077         -background red \
5078         -font font_ui
5079 text $ui_workdir -background white -borderwidth 0 \
5080         -width 20 -height 10 \
5081         -wrap none \
5082         -font font_ui \
5083         -cursor $cursor_ptr \
5084         -xscrollcommand {.vpane.files.workdir.sx set} \
5085         -yscrollcommand {.vpane.files.workdir.sy set} \
5086         -state disabled
5087 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
5088 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
5089 pack .vpane.files.workdir.title -side top -fill x
5090 pack .vpane.files.workdir.sx -side bottom -fill x
5091 pack .vpane.files.workdir.sy -side right -fill y
5092 pack $ui_workdir -side left -fill both -expand 1
5093 .vpane.files add .vpane.files.workdir -sticky nsew
5094
5095 foreach i [list $ui_index $ui_workdir] {
5096         $i tag conf in_diff -font font_uibold
5097         $i tag conf in_sel \
5098                 -background [$i cget -foreground] \
5099                 -foreground [$i cget -background]
5100 }
5101 unset i
5102
5103 # -- Diff and Commit Area
5104 #
5105 frame .vpane.lower -height 300 -width 400
5106 frame .vpane.lower.commarea
5107 frame .vpane.lower.diff -relief sunken -borderwidth 1
5108 pack .vpane.lower.commarea -side top -fill x
5109 pack .vpane.lower.diff -side bottom -fill both -expand 1
5110 .vpane add .vpane.lower -sticky nsew
5111
5112 # -- Commit Area Buttons
5113 #
5114 frame .vpane.lower.commarea.buttons
5115 label .vpane.lower.commarea.buttons.l -text {} \
5116         -anchor w \
5117         -justify left \
5118         -font font_ui
5119 pack .vpane.lower.commarea.buttons.l -side top -fill x
5120 pack .vpane.lower.commarea.buttons -side left -fill y
5121
5122 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
5123         -command do_rescan \
5124         -font font_ui
5125 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
5126 lappend disable_on_lock \
5127         {.vpane.lower.commarea.buttons.rescan conf -state}
5128
5129 button .vpane.lower.commarea.buttons.incall -text {Add All} \
5130         -command do_add_all \
5131         -font font_ui
5132 pack .vpane.lower.commarea.buttons.incall -side top -fill x
5133 lappend disable_on_lock \
5134         {.vpane.lower.commarea.buttons.incall conf -state}
5135
5136 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
5137         -command do_signoff \
5138         -font font_ui
5139 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
5140
5141 button .vpane.lower.commarea.buttons.commit -text {Commit} \
5142         -command do_commit \
5143         -font font_ui
5144 pack .vpane.lower.commarea.buttons.commit -side top -fill x
5145 lappend disable_on_lock \
5146         {.vpane.lower.commarea.buttons.commit conf -state}
5147
5148 # -- Commit Message Buffer
5149 #
5150 frame .vpane.lower.commarea.buffer
5151 frame .vpane.lower.commarea.buffer.header
5152 set ui_comm .vpane.lower.commarea.buffer.t
5153 set ui_coml .vpane.lower.commarea.buffer.header.l
5154 radiobutton .vpane.lower.commarea.buffer.header.new \
5155         -text {New Commit} \
5156         -command do_select_commit_type \
5157         -variable selected_commit_type \
5158         -value new \
5159         -font font_ui
5160 lappend disable_on_lock \
5161         [list .vpane.lower.commarea.buffer.header.new conf -state]
5162 radiobutton .vpane.lower.commarea.buffer.header.amend \
5163         -text {Amend Last Commit} \
5164         -command do_select_commit_type \
5165         -variable selected_commit_type \
5166         -value amend \
5167         -font font_ui
5168 lappend disable_on_lock \
5169         [list .vpane.lower.commarea.buffer.header.amend conf -state]
5170 label $ui_coml \
5171         -anchor w \
5172         -justify left \
5173         -font font_ui
5174 proc trace_commit_type {varname args} {
5175         global ui_coml commit_type
5176         switch -glob -- $commit_type {
5177         initial       {set txt {Initial Commit Message:}}
5178         amend         {set txt {Amended Commit Message:}}
5179         amend-initial {set txt {Amended Initial Commit Message:}}
5180         amend-merge   {set txt {Amended Merge Commit Message:}}
5181         merge         {set txt {Merge Commit Message:}}
5182         *             {set txt {Commit Message:}}
5183         }
5184         $ui_coml conf -text $txt
5185 }
5186 trace add variable commit_type write trace_commit_type
5187 pack $ui_coml -side left -fill x
5188 pack .vpane.lower.commarea.buffer.header.amend -side right
5189 pack .vpane.lower.commarea.buffer.header.new -side right
5190
5191 text $ui_comm -background white -borderwidth 1 \
5192         -undo true \
5193         -maxundo 20 \
5194         -autoseparators true \
5195         -relief sunken \
5196         -width 75 -height 9 -wrap none \
5197         -font font_diff \
5198         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
5199 scrollbar .vpane.lower.commarea.buffer.sby \
5200         -command [list $ui_comm yview]
5201 pack .vpane.lower.commarea.buffer.header -side top -fill x
5202 pack .vpane.lower.commarea.buffer.sby -side right -fill y
5203 pack $ui_comm -side left -fill y
5204 pack .vpane.lower.commarea.buffer -side left -fill y
5205
5206 # -- Commit Message Buffer Context Menu
5207 #
5208 set ctxm .vpane.lower.commarea.buffer.ctxm
5209 menu $ctxm -tearoff 0
5210 $ctxm add command \
5211         -label {Cut} \
5212         -font font_ui \
5213         -command {tk_textCut $ui_comm}
5214 $ctxm add command \
5215         -label {Copy} \
5216         -font font_ui \
5217         -command {tk_textCopy $ui_comm}
5218 $ctxm add command \
5219         -label {Paste} \
5220         -font font_ui \
5221         -command {tk_textPaste $ui_comm}
5222 $ctxm add command \
5223         -label {Delete} \
5224         -font font_ui \
5225         -command {$ui_comm delete sel.first sel.last}
5226 $ctxm add separator
5227 $ctxm add command \
5228         -label {Select All} \
5229         -font font_ui \
5230         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
5231 $ctxm add command \
5232         -label {Copy All} \
5233         -font font_ui \
5234         -command {
5235                 $ui_comm tag add sel 0.0 end
5236                 tk_textCopy $ui_comm
5237                 $ui_comm tag remove sel 0.0 end
5238         }
5239 $ctxm add separator
5240 $ctxm add command \
5241         -label {Sign Off} \
5242         -font font_ui \
5243         -command do_signoff
5244 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
5245
5246 # -- Diff Header
5247 #
5248 set current_diff_path {}
5249 set current_diff_side {}
5250 set diff_actions [list]
5251 proc trace_current_diff_path {varname args} {
5252         global current_diff_path diff_actions file_states
5253         if {$current_diff_path eq {}} {
5254                 set s {}
5255                 set f {}
5256                 set p {}
5257                 set o disabled
5258         } else {
5259                 set p $current_diff_path
5260                 set s [mapdesc [lindex $file_states($p) 0] $p]
5261                 set f {File:}
5262                 set p [escape_path $p]
5263                 set o normal
5264         }
5265
5266         .vpane.lower.diff.header.status configure -text $s
5267         .vpane.lower.diff.header.file configure -text $f
5268         .vpane.lower.diff.header.path configure -text $p
5269         foreach w $diff_actions {
5270                 uplevel #0 $w $o
5271         }
5272 }
5273 trace add variable current_diff_path write trace_current_diff_path
5274
5275 frame .vpane.lower.diff.header -background orange
5276 label .vpane.lower.diff.header.status \
5277         -background orange \
5278         -width $max_status_desc \
5279         -anchor w \
5280         -justify left \
5281         -font font_ui
5282 label .vpane.lower.diff.header.file \
5283         -background orange \
5284         -anchor w \
5285         -justify left \
5286         -font font_ui
5287 label .vpane.lower.diff.header.path \
5288         -background orange \
5289         -anchor w \
5290         -justify left \
5291         -font font_ui
5292 pack .vpane.lower.diff.header.status -side left
5293 pack .vpane.lower.diff.header.file -side left
5294 pack .vpane.lower.diff.header.path -fill x
5295 set ctxm .vpane.lower.diff.header.ctxm
5296 menu $ctxm -tearoff 0
5297 $ctxm add command \
5298         -label {Copy} \
5299         -font font_ui \
5300         -command {
5301                 clipboard clear
5302                 clipboard append \
5303                         -format STRING \
5304                         -type STRING \
5305                         -- $current_diff_path
5306         }
5307 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
5308 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
5309
5310 # -- Diff Body
5311 #
5312 frame .vpane.lower.diff.body
5313 set ui_diff .vpane.lower.diff.body.t
5314 text $ui_diff -background white -borderwidth 0 \
5315         -width 80 -height 15 -wrap none \
5316         -font font_diff \
5317         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
5318         -yscrollcommand {.vpane.lower.diff.body.sby set} \
5319         -state disabled
5320 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
5321         -command [list $ui_diff xview]
5322 scrollbar .vpane.lower.diff.body.sby -orient vertical \
5323         -command [list $ui_diff yview]
5324 pack .vpane.lower.diff.body.sbx -side bottom -fill x
5325 pack .vpane.lower.diff.body.sby -side right -fill y
5326 pack $ui_diff -side left -fill both -expand 1
5327 pack .vpane.lower.diff.header -side top -fill x
5328 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
5329
5330 $ui_diff tag conf d_cr -elide true
5331 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
5332 $ui_diff tag conf d_+ -foreground {#00a000}
5333 $ui_diff tag conf d_- -foreground red
5334
5335 $ui_diff tag conf d_++ -foreground {#00a000}
5336 $ui_diff tag conf d_-- -foreground red
5337 $ui_diff tag conf d_+s \
5338         -foreground {#00a000} \
5339         -background {#e2effa}
5340 $ui_diff tag conf d_-s \
5341         -foreground red \
5342         -background {#e2effa}
5343 $ui_diff tag conf d_s+ \
5344         -foreground {#00a000} \
5345         -background ivory1
5346 $ui_diff tag conf d_s- \
5347         -foreground red \
5348         -background ivory1
5349
5350 $ui_diff tag conf d<<<<<<< \
5351         -foreground orange \
5352         -font font_diffbold
5353 $ui_diff tag conf d======= \
5354         -foreground orange \
5355         -font font_diffbold
5356 $ui_diff tag conf d>>>>>>> \
5357         -foreground orange \
5358         -font font_diffbold
5359
5360 $ui_diff tag raise sel
5361
5362 # -- Diff Body Context Menu
5363 #
5364 set ctxm .vpane.lower.diff.body.ctxm
5365 menu $ctxm -tearoff 0
5366 $ctxm add command \
5367         -label {Refresh} \
5368         -font font_ui \
5369         -command reshow_diff
5370 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
5371 $ctxm add command \
5372         -label {Copy} \
5373         -font font_ui \
5374         -command {tk_textCopy $ui_diff}
5375 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
5376 $ctxm add command \
5377         -label {Select All} \
5378         -font font_ui \
5379         -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
5380 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
5381 $ctxm add command \
5382         -label {Copy All} \
5383         -font font_ui \
5384         -command {
5385                 $ui_diff tag add sel 0.0 end
5386                 tk_textCopy $ui_diff
5387                 $ui_diff tag remove sel 0.0 end
5388         }
5389 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
5390 $ctxm add separator
5391 $ctxm add command \
5392         -label {Apply/Reverse Hunk} \
5393         -font font_ui \
5394         -command {apply_hunk $cursorX $cursorY}
5395 set ui_diff_applyhunk [$ctxm index last]
5396 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
5397 $ctxm add separator
5398 $ctxm add command \
5399         -label {Decrease Font Size} \
5400         -font font_ui \
5401         -command {incr_font_size font_diff -1}
5402 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
5403 $ctxm add command \
5404         -label {Increase Font Size} \
5405         -font font_ui \
5406         -command {incr_font_size font_diff 1}
5407 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
5408 $ctxm add separator
5409 $ctxm add command \
5410         -label {Show Less Context} \
5411         -font font_ui \
5412         -command {if {$repo_config(gui.diffcontext) >= 2} {
5413                 incr repo_config(gui.diffcontext) -1
5414                 reshow_diff
5415         }}
5416 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
5417 $ctxm add command \
5418         -label {Show More Context} \
5419         -font font_ui \
5420         -command {
5421                 incr repo_config(gui.diffcontext)
5422                 reshow_diff
5423         }
5424 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
5425 $ctxm add separator
5426 $ctxm add command -label {Options...} \
5427         -font font_ui \
5428         -command do_options
5429 bind_button3 $ui_diff "
5430         set cursorX %x
5431         set cursorY %y
5432         if {\$ui_index eq \$current_diff_side} {
5433                 $ctxm entryconf $ui_diff_applyhunk -label {Unstage Hunk From Commit}
5434         } else {
5435                 $ctxm entryconf $ui_diff_applyhunk -label {Stage Hunk For Commit}
5436         }
5437         tk_popup $ctxm %X %Y
5438 "
5439 unset ui_diff_applyhunk
5440
5441 # -- Status Bar
5442 #
5443 set ui_status_value {Initializing...}
5444 label .status -textvariable ui_status_value \
5445         -anchor w \
5446         -justify left \
5447         -borderwidth 1 \
5448         -relief sunken \
5449         -font font_ui
5450 pack .status -anchor w -side bottom -fill x
5451
5452 # -- Load geometry
5453 #
5454 catch {
5455 set gm $repo_config(gui.geometry)
5456 wm geometry . [lindex $gm 0]
5457 .vpane sash place 0 \
5458         [lindex [.vpane sash coord 0] 0] \
5459         [lindex $gm 1]
5460 .vpane.files sash place 0 \
5461         [lindex $gm 2] \
5462         [lindex [.vpane.files sash coord 0] 1]
5463 unset gm
5464 }
5465
5466 # -- Key Bindings
5467 #
5468 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
5469 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
5470 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
5471 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
5472 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
5473 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
5474 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
5475 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
5476 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
5477 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
5478 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
5479
5480 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
5481 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
5482 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
5483 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
5484 bind $ui_diff <$M1B-Key-v> {break}
5485 bind $ui_diff <$M1B-Key-V> {break}
5486 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
5487 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
5488 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
5489 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
5490 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
5491 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
5492 bind $ui_diff <Button-1>   {focus %W}
5493
5494 if {!$single_commit} {
5495         bind . <$M1B-Key-n> do_create_branch
5496         bind . <$M1B-Key-N> do_create_branch
5497 }
5498
5499 bind .   <Destroy> do_quit
5500 bind all <Key-F5> do_rescan
5501 bind all <$M1B-Key-r> do_rescan
5502 bind all <$M1B-Key-R> do_rescan
5503 bind .   <$M1B-Key-s> do_signoff
5504 bind .   <$M1B-Key-S> do_signoff
5505 bind .   <$M1B-Key-i> do_add_all
5506 bind .   <$M1B-Key-I> do_add_all
5507 bind .   <$M1B-Key-Return> do_commit
5508 bind all <$M1B-Key-q> do_quit
5509 bind all <$M1B-Key-Q> do_quit
5510 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
5511 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
5512 foreach i [list $ui_index $ui_workdir] {
5513         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
5514         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
5515         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
5516 }
5517 unset i
5518
5519 set file_lists($ui_index) [list]
5520 set file_lists($ui_workdir) [list]
5521
5522 set HEAD {}
5523 set PARENT {}
5524 set MERGE_HEAD [list]
5525 set commit_type {}
5526 set empty_tree {}
5527 set current_branch {}
5528 set current_diff_path {}
5529 set selected_commit_type new
5530
5531 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
5532 focus -force $ui_comm
5533
5534 # -- Warn the user about environmental problems.  Cygwin's Tcl
5535 #    does *not* pass its env array onto any processes it spawns.
5536 #    This means that git processes get none of our environment.
5537 #
5538 if {[is_Cygwin]} {
5539         set ignored_env 0
5540         set suggest_user {}
5541         set msg "Possible environment issues exist.
5542
5543 The following environment variables are probably
5544 going to be ignored by any Git subprocess run
5545 by [appname]:
5546
5547 "
5548         foreach name [array names env] {
5549                 switch -regexp -- $name {
5550                 {^GIT_INDEX_FILE$} -
5551                 {^GIT_OBJECT_DIRECTORY$} -
5552                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
5553                 {^GIT_DIFF_OPTS$} -
5554                 {^GIT_EXTERNAL_DIFF$} -
5555                 {^GIT_PAGER$} -
5556                 {^GIT_TRACE$} -
5557                 {^GIT_CONFIG$} -
5558                 {^GIT_CONFIG_LOCAL$} -
5559                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
5560                         append msg " - $name\n"
5561                         incr ignored_env
5562                 }
5563                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
5564                         append msg " - $name\n"
5565                         incr ignored_env
5566                         set suggest_user $name
5567                 }
5568                 }
5569         }
5570         if {$ignored_env > 0} {
5571                 append msg "
5572 This is due to a known issue with the
5573 Tcl binary distributed by Cygwin."
5574
5575                 if {$suggest_user ne {}} {
5576                         append msg "
5577
5578 A good replacement for $suggest_user
5579 is placing values for the user.name and
5580 user.email settings into your personal
5581 ~/.gitconfig file.
5582 "
5583                 }
5584                 warn_popup $msg
5585         }
5586         unset ignored_env msg suggest_user name
5587 }
5588
5589 # -- Only initialize complex UI if we are going to stay running.
5590 #
5591 if {!$single_commit} {
5592         load_all_remotes
5593         load_all_heads
5594
5595         populate_branch_menu
5596         populate_fetch_menu
5597         populate_push_menu
5598 }
5599
5600 # -- Only suggest a gc run if we are going to stay running.
5601 #
5602 if {!$single_commit} {
5603         set object_limit 2000
5604         if {[is_Windows]} {set object_limit 200}
5605         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
5606         if {$objects_current >= $object_limit} {
5607                 if {[ask_popup \
5608                         "This repository currently has $objects_current loose objects.
5609
5610 To maintain optimal performance it is strongly
5611 recommended that you compress the database
5612 when more than $object_limit loose objects exist.
5613
5614 Compress the database now?"] eq yes} {
5615                         do_gc
5616                 }
5617         }
5618         unset object_limit _junk objects_current
5619 }
5620
5621 lock_index begin-read
5622 after 1 do_rescan