git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Mail::Sendmail qw(sendmail %mailcfg);
  23 use Getopt::Long;
  24 use Data::Dumper;
  25 use Email::Valid;
  26
  27 sub unique_email_list(@);
  28 sub cleanup_compose_files();
  29
  30 # Constants (essentially)
  31 my $compose_filename = ".msg.$$";
  32
  33 # Variables we fill in automatically, or via prompting:
  34 my (@to,@cc,@initial_cc,$initial_reply_to,$initial_subject,@files,$from,$compose);
  35
  36 # Behavior modification variables
  37 my ($chain_reply_to, $smtp_server, $quiet, $suppress_from, $no_signed_off_cc) = (1, "localhost", 0, 0, 0);
  38
  39 # Example reply to:
  40 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
  41
  42 my $term = new Term::ReadLine 'git-send-email';
  43
  44 # Begin by accumulating all the variables (defined above), that we will end up
  45 # needing, first, from the command line:
  46
  47 my $rc = GetOptions("from=s" => \$from,
  48                     "in-reply-to=s" => \$initial_reply_to,
  49                     "subject=s" => \$initial_subject,
  50                     "to=s" => \@to,
  51                     "cc=s" => \@initial_cc,
  52                     "chain-reply-to!" => \$chain_reply_to,
  53                     "smtp-server=s" => \$smtp_server,
  54                     "compose" => \$compose,
  55                     "quiet" => \$quiet,
  56                     "suppress-from" => \$suppress_from,
  57                     "no-signed-off-cc|no-signed-off-by-cc" => \$no_signed_off_cc,
  58          );
  59
  60 # Now, let's fill any that aren't set in with defaults:
  61
  62 sub gitvar {
  63     my ($var) = @_;
  64     my $fh;
  65     my $pid = open($fh, '-|');
  66     die "$!" unless defined $pid;
  67     if (!$pid) {
  68         exec('git-var', $var) or die "$!";
  69     }
  70     my ($val) = <$fh>;
  71     close $fh or die "$!";
  72     chomp($val);
  73     return $val;
  74 }
  75
  76 sub gitvar_ident {
  77     my ($name) = @_;
  78     my $val = gitvar($name);
  79     my @field = split(/\s+/, $val);
  80     return join(' ', @field[0...(@field-3)]);
  81 }
  82
  83 my ($author) = gitvar_ident('GIT_AUTHOR_IDENT');
  84 my ($committer) = gitvar_ident('GIT_COMMITTER_IDENT');
  85
  86 my $prompting = 0;
  87 if (!defined $from) {
  88         $from = $author || $committer;
  89         do {
  90                 $_ = $term->readline("Who should the emails appear to be from? ",
  91                         $from);
  92         } while (!defined $_);
  93
  94         $from = $_;
  95         print "Emails will be sent from: ", $from, "\n";
  96         $prompting++;
  97 }
  98
  99 if (!@to) {
 100         do {
 101                 $_ = $term->readline("Who should the emails be sent to? ",
 102                                 "");
 103         } while (!defined $_);
 104         my $to = $_;
 105         push @to, split /,/, $to;
 106         $prompting++;
 107 }
 108
 109 if (!defined $initial_subject && $compose) {
 110         do {
 111                 $_ = $term->readline("What subject should the emails start with? ",
 112                         $initial_subject);
 113         } while (!defined $_);
 114         $initial_subject = $_;
 115         $prompting++;
 116 }
 117
 118 if (!defined $initial_reply_to && $prompting) {
 119         do {
 120                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 121                         $initial_reply_to);
 122         } while (!defined $_);
 123
 124         $initial_reply_to = $_;
 125         $initial_reply_to =~ s/(^\s+|\s+$)//g;
 126 }
 127
 128 if (!defined $smtp_server) {
 129         $smtp_server = "localhost";
 130 }
 131
 132 if ($compose) {
 133         # Note that this does not need to be secure, but we will make a small
 134         # effort to have it be unique
 135         open(C,">",$compose_filename)
 136                 or die "Failed to open for writing $compose_filename: $!";
 137         print C "From $from # This line is ignored.\n";
 138         printf C "Subject: %s\n\n", $initial_subject;
 139         printf C <<EOT;
 140 GIT: Please enter your email below.
 141 GIT: Lines beginning in "GIT: " will be removed.
 142 GIT: Consider including an overall diffstat or table of contents
 143 GIT: for the patch you are writing.
 144
 145 EOT
 146         close(C);
 147
 148         my $editor = $ENV{EDITOR};
 149         $editor = 'vi' unless defined $editor;
 150         system($editor, $compose_filename);
 151
 152         open(C2,">",$compose_filename . ".final")
 153                 or die "Failed to open $compose_filename.final : " . $!;
 154
 155         open(C,"<",$compose_filename)
 156                 or die "Failed to open $compose_filename : " . $!;
 157
 158         while(<C>) {
 159                 next if m/^GIT: /;
 160                 print C2 $_;
 161         }
 162         close(C);
 163         close(C2);
 164
 165         do {
 166                 $_ = $term->readline("Send this email? (y|n) ");
 167         } while (!defined $_);
 168
 169         if (uc substr($_,0,1) ne 'Y') {
 170                 cleanup_compose_files();
 171                 exit(0);
 172         }
 173
 174         @files = ($compose_filename . ".final");
 175 }
 176
 177
 178 # Now that all the defaults are set, process the rest of the command line
 179 # arguments and collect up the files that need to be processed.
 180 for my $f (@ARGV) {
 181         if (-d $f) {
 182                 opendir(DH,$f)
 183                         or die "Failed to opendir $f: $!";
 184
 185                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 186                                 sort readdir(DH);
 187
 188         } elsif (-f $f) {
 189                 push @files, $f;
 190
 191         } else {
 192                 print STDERR "Skipping $f - not found.\n";
 193         }
 194 }
 195
 196 if (@files) {
 197         unless ($quiet) {
 198                 print $_,"\n" for (@files);
 199         }
 200 } else {
 201         print <<EOT;
 202 git-send-email [options] <file | directory> [... file | directory ]
 203 Options:
 204    --from         Specify the "From:" line of the email to be sent.
 205
 206    --to           Specify the primary "To:" line of the email.
 207
 208    --cc           Specify an initial "Cc:" list for the entire series
 209                   of emails.
 210
 211    --compose      Use \$EDITOR to edit an introductory message for the
 212                   patch series.
 213
 214    --subject      Specify the initial "Subject:" line.
 215                   Only necessary if --compose is also set.  If --compose
 216                   is not set, this will be prompted for.
 217
 218    --in-reply-to  Specify the first "In-Reply-To:" header line.
 219                   Only used if --compose is also set.  If --compose is not
 220                   set, this will be prompted for.
 221
 222    --chain-reply-to If set, the replies will all be to the previous
 223                   email sent, rather than to the first email sent.
 224                   Defaults to on.
 225
 226    --no-signed-off-cc Suppress the automatic addition of email addresses
 227                  that appear in a Signed-off-by: line, to the cc: list.
 228                  Note: Using this option is not recommended.
 229
 230    --smtp-server  If set, specifies the outgoing SMTP server to use.
 231                   Defaults to localhost.
 232
 233   --suppress-from Supress sending emails to yourself if your address
 234                   appears in a From: line.
 235
 236    --quiet      Make git-send-email less verbose.  One line per email should be
 237                 all that is output.
 238
 239 Error: Please specify a file or a directory on the command line.
 240 EOT
 241         exit(1);
 242 }
 243
 244 # Variables we set as part of the loop over files
 245 our ($message_id, $cc, %mail, $subject, $reply_to, $message);
 246
 247
 248 # Usually don't need to change anything below here.
 249
 250 # we make a "fake" message id by taking the current number
 251 # of seconds since the beginning of Unix time and tacking on
 252 # a random number to the end, in case we are called quicker than
 253 # 1 second since the last time we were called.
 254
 255 # We'll setup a template for the message id, using the "from" address:
 256 my $message_id_from = Email::Valid->address($from);
 257 my $message_id_template = "<%s-git-send-email-$message_id_from>";
 258
 259 sub make_message_id
 260 {
 261         my $date = `date "+\%s"`;
 262         chomp($date);
 263         my $pseudo_rand = int (rand(4200));
 264         $message_id = sprintf $message_id_template, "$date$pseudo_rand";
 265         #print "new message id = $message_id\n"; # Was useful for debugging
 266 }
 267
 268
 269
 270 $cc = "";
 271
 272 sub send_message
 273 {
 274         my $to = join (", ", unique_email_list(@to));
 275
 276         %mail = (       To      =>      $to,
 277                         From    =>      $from,
 278                         CC      =>      $cc,
 279                         Subject =>      $subject,
 280                         Message =>      $message,
 281                         'Reply-to'      =>      $from,
 282                         'In-Reply-To'   =>      $reply_to,
 283                         'Message-ID'    =>      $message_id,
 284                         'X-Mailer'      =>      "git-send-email",
 285                 );
 286
 287         $mail{smtp} = $smtp_server;
 288         $mailcfg{mime} = 0;
 289
 290         #print Data::Dumper->Dump([\%mail],[qw(*mail)]);
 291
 292         sendmail(%mail) or die $Mail::Sendmail::error;
 293
 294         if ($quiet) {
 295                 printf "Sent %s\n", $subject;
 296         } else {
 297                 print "OK. Log says:\n", $Mail::Sendmail::log;
 298                 print "\n\n"
 299         }
 300 }
 301
 302
 303 $reply_to = $initial_reply_to;
 304 make_message_id();
 305 $subject = $initial_subject;
 306
 307 foreach my $t (@files) {
 308         open(F,"<",$t) or die "can't open file $t";
 309
 310         my $author_not_sender = undef;
 311         @cc = @initial_cc;
 312         my $found_mbox = 0;
 313         my $header_done = 0;
 314         $message = "";
 315         while(<F>) {
 316                 if (!$header_done) {
 317                         $found_mbox = 1, next if (/^From /);
 318                         chomp;
 319
 320                         if ($found_mbox) {
 321                                 if (/^Subject:\s+(.*)$/) {
 322                                         $subject = $1;
 323
 324                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 325                                         if ($2 eq $from) {
 326                                                 next if ($suppress_from);
 327                                         }
 328                                         else {
 329                                                 $author_not_sender = $2;
 330                                         }
 331                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 332                                                 $2, $_) unless $quiet;
 333                                         push @cc, $2;
 334                                 }
 335
 336                         } else {
 337                                 # In the traditional
 338                                 # "send lots of email" format,
 339                                 # line 1 = cc
 340                                 # line 2 = subject
 341                                 # So let's support that, too.
 342                                 if (@cc == 0) {
 343                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 344                                                 $_, $_) unless $quiet;
 345
 346                                         push @cc, $_;
 347
 348                                 } elsif (!defined $subject) {
 349                                         $subject = $_;
 350                                 }
 351                         }
 352
 353                         # A whitespace line will terminate the headers
 354                         if (m/^\s*$/) {
 355                                 $header_done = 1;
 356                         }
 357                 } else {
 358                         $message .=  $_;
 359                         if (/^Signed-off-by: (.*)$/i && !$no_signed_off_cc) {
 360                                 my $c = $1;
 361                                 chomp $c;
 362                                 push @cc, $c;
 363                                 printf("(sob) Adding cc: %s from line '%s'\n",
 364                                         $c, $_) unless $quiet;
 365                         }
 366                 }
 367         }
 368         close F;
 369         if (defined $author_not_sender) {
 370                 $message = "From: $author_not_sender\n\n$message";
 371         }
 372
 373         $cc = join(", ", unique_email_list(@cc));
 374
 375         send_message();
 376
 377         # set up for the next message
 378         if ($chain_reply_to || length($reply_to) == 0) {
 379                 $reply_to = $message_id;
 380         }
 381         make_message_id();
 382 }
 383
 384 if ($compose) {
 385         cleanup_compose_files();
 386 }
 387
 388 sub cleanup_compose_files() {
 389         unlink($compose_filename, $compose_filename . ".final");
 390
 391 }
 392
 393
 394
 395 sub unique_email_list(@) {
 396         my %seen;
 397         my @emails;
 398
 399         foreach my $entry (@_) {
 400                 my $clean = Email::Valid->address($entry);
 401                 next if $seen{$clean}++;
 402                 push @emails, $entry;
 403         }
 404         return @emails;
 405 }