git.oblomov.eu Git - git/blob - git-cvsimport.perl

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Std;
  19 use File::Spec;
  20 use File::Temp qw(tempfile);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2);
  27 use IPC::Open2;
  28
  29 $SIG{'PIPE'}="IGNORE";
  30 $ENV{'TZ'}="UTC";
  31
  32 our($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A);
  33 my (%conv_author_name, %conv_author_email);
  34
  35 sub usage() {
  36         print STDERR <<END;
  37 Usage: ${\basename $0}     # fetch/update GIT from CVS
  38        [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
  39        [-p opts-for-cvsps] [-C GIT_repository] [-z fuzz] [-i] [-k] [-u]
  40        [-s subst] [-m] [-M regex] [CVS_module]
  41 END
  42         exit(1);
  43 }
  44
  45 sub read_author_info($) {
  46         my ($file) = @_;
  47         my $user;
  48         open my $f, '<', "$file" or die("Failed to open $file: $!\n");
  49
  50         while (<$f>) {
  51                 # Expected format is this:
  52                 #   exon=Andreas Ericsson <ae@op5.se>
  53                 if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
  54                         $user = $1;
  55                         $conv_author_name{$user} = $2;
  56                         $conv_author_email{$user} = $3;
  57                 }
  58                 # However, we also read from CVSROOT/users format
  59                 # to ease migration.
  60                 elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
  61                         my $mapped;
  62                         ($user, $mapped) = ($1, $3);
  63                         if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
  64                                 $conv_author_name{$user} = $1;
  65                                 $conv_author_email{$user} = $2;
  66                         }
  67                         elsif ($mapped =~ /^<?(.*)>?$/) {
  68                                 $conv_author_name{$user} = $user;
  69                                 $conv_author_email{$user} = $1;
  70                         }
  71                 }
  72                 # NEEDSWORK: Maybe warn on unrecognized lines?
  73         }
  74         close ($f);
  75 }
  76
  77 sub write_author_info($) {
  78         my ($file) = @_;
  79         open my $f, '>', $file or
  80           die("Failed to open $file for writing: $!");
  81
  82         foreach (keys %conv_author_name) {
  83                 print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
  84         }
  85         close ($f);
  86 }
  87
  88 getopts("hivmkuo:d:p:C:z:s:M:P:A:") or usage();
  89 usage if $opt_h;
  90
  91 @ARGV <= 1 or usage();
  92
  93 if($opt_d) {
  94         $ENV{"CVSROOT"} = $opt_d;
  95 } elsif(-f 'CVS/Root') {
  96         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
  97         $opt_d = <$f>;
  98         chomp $opt_d;
  99         close $f;
 100         $ENV{"CVSROOT"} = $opt_d;
 101 } elsif($ENV{"CVSROOT"}) {
 102         $opt_d = $ENV{"CVSROOT"};
 103 } else {
 104         die "CVSROOT needs to be set";
 105 }
 106 $opt_o ||= "origin";
 107 $opt_s ||= "-";
 108 my $git_tree = $opt_C;
 109 $git_tree ||= ".";
 110
 111 my $cvs_tree;
 112 if ($#ARGV == 0) {
 113         $cvs_tree = $ARGV[0];
 114 } elsif (-f 'CVS/Repository') {
 115         open my $f, '<', 'CVS/Repository' or
 116             die 'Failed to open CVS/Repository';
 117         $cvs_tree = <$f>;
 118         chomp $cvs_tree;
 119         close $f;
 120 } else {
 121         usage();
 122 }
 123
 124 our @mergerx = ();
 125 if ($opt_m) {
 126         @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
 127 }
 128 if ($opt_M) {
 129         push (@mergerx, qr/$opt_M/);
 130 }
 131
 132 select(STDERR); $|=1; select(STDOUT);
 133
 134
 135 package CVSconn;
 136 # Basic CVS dialog.
 137 # We're only interested in connecting and downloading, so ...
 138
 139 use File::Spec;
 140 use File::Temp qw(tempfile);
 141 use POSIX qw(strftime dup2);
 142
 143 sub new {
 144         my($what,$repo,$subdir) = @_;
 145         $what=ref($what) if ref($what);
 146
 147         my $self = {};
 148         $self->{'buffer'} = "";
 149         bless($self,$what);
 150
 151         $repo =~ s#/+$##;
 152         $self->{'fullrep'} = $repo;
 153         $self->conn();
 154
 155         $self->{'subdir'} = $subdir;
 156         $self->{'lines'} = undef;
 157
 158         return $self;
 159 }
 160
 161 sub conn {
 162         my $self = shift;
 163         my $repo = $self->{'fullrep'};
 164         if($repo =~ s/^:pserver:(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 165                 my($user,$pass,$serv,$port) = ($1,$2,$3,$4);
 166                 $user="anonymous" unless defined $user;
 167                 my $rr2 = "-";
 168                 unless($port) {
 169                         $rr2 = ":pserver:$user\@$serv:$repo";
 170                         $port=2401;
 171                 }
 172                 my $rr = ":pserver:$user\@$serv:$port$repo";
 173
 174                 unless($pass) {
 175                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 176                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 177                                 while(<H>) {
 178                                         chomp;
 179                                         s/^\/\d+\s+//;
 180                                         my ($w,$p) = split(/\s/,$_,2);
 181                                         if($w eq $rr or $w eq $rr2) {
 182                                                 $pass = $p;
 183                                                 last;
 184                                         }
 185                                 }
 186                         };
 187                 }
 188                 $pass="A" unless $pass;
 189
 190                 my $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 191                 die "Socket to $serv: $!\n" unless defined $s;
 192                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 193                         or die "Write to $serv: $!\n";
 194                 $s->flush();
 195
 196                 my $rep = <$s>;
 197
 198                 if($rep ne "I LOVE YOU\n") {
 199                         $rep="<unknown>" unless $rep;
 200                         die "AuthReply: $rep\n";
 201                 }
 202                 $self->{'socketo'} = $s;
 203                 $self->{'socketi'} = $s;
 204         } else { # local or ext: Fork off our own cvs server.
 205                 my $pr = IO::Pipe->new();
 206                 my $pw = IO::Pipe->new();
 207                 my $pid = fork();
 208                 die "Fork: $!\n" unless defined $pid;
 209                 my $cvs = 'cvs';
 210                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 211                 my $rsh = 'rsh';
 212                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 213
 214                 my @cvs = ($cvs, 'server');
 215                 my ($local, $user, $host);
 216                 $local = $repo =~ s/:local://;
 217                 if (!$local) {
 218                     $repo =~ s/:ext://;
 219                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 220                     ($user, $host) = ($1, $2);
 221                 }
 222                 if (!$local) {
 223                     if ($user) {
 224                         unshift @cvs, $rsh, '-l', $user, $host;
 225                     } else {
 226                         unshift @cvs, $rsh, $host;
 227                     }
 228                 }
 229
 230                 unless($pid) {
 231                         $pr->writer();
 232                         $pw->reader();
 233                         dup2($pw->fileno(),0);
 234                         dup2($pr->fileno(),1);
 235                         $pr->close();
 236                         $pw->close();
 237                         exec(@cvs);
 238                 }
 239                 $pw->writer();
 240                 $pr->reader();
 241                 $self->{'socketo'} = $pw;
 242                 $self->{'socketi'} = $pr;
 243         }
 244         $self->{'socketo'}->write("Root $repo\n");
 245
 246         # Trial and error says that this probably is the minimum set
 247         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 248
 249         $self->{'socketo'}->write("valid-requests\n");
 250         $self->{'socketo'}->flush();
 251
 252         chomp(my $rep=$self->readline());
 253         if($rep !~ s/^Valid-requests\s*//) {
 254                 $rep="<unknown>" unless $rep;
 255                 die "Expected Valid-requests from server, but got: $rep\n";
 256         }
 257         chomp(my $res=$self->readline());
 258         die "validReply: $res\n" if $res ne "ok";
 259
 260         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 261         $self->{'repo'} = $repo;
 262 }
 263
 264 sub readline {
 265         my($self) = @_;
 266         return $self->{'socketi'}->getline();
 267 }
 268
 269 sub _file {
 270         # Request a file with a given revision.
 271         # Trial and error says this is a good way to do it. :-/
 272         my($self,$fn,$rev) = @_;
 273         $self->{'socketo'}->write("Argument -N\n") or return undef;
 274         $self->{'socketo'}->write("Argument -P\n") or return undef;
 275         # -kk: Linus' version doesn't use it - defaults to off
 276         if ($opt_k) {
 277             $self->{'socketo'}->write("Argument -kk\n") or return undef;
 278         }
 279         $self->{'socketo'}->write("Argument -r\n") or return undef;
 280         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 281         $self->{'socketo'}->write("Argument --\n") or return undef;
 282         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 283         $self->{'socketo'}->write("Directory .\n") or return undef;
 284         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 285         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 286         $self->{'socketo'}->write("co\n") or return undef;
 287         $self->{'socketo'}->flush() or return undef;
 288         $self->{'lines'} = 0;
 289         return 1;
 290 }
 291 sub _line {
 292         # Read a line from the server.
 293         # ... except that 'line' may be an entire file. ;-)
 294         my($self, $fh) = @_;
 295         die "Not in lines" unless defined $self->{'lines'};
 296
 297         my $line;
 298         my $res=0;
 299         while(defined($line = $self->readline())) {
 300                 # M U gnupg-cvs-rep/AUTHORS
 301                 # Updated gnupg-cvs-rep/
 302                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 303                 # /AUTHORS/1.1///T1.1
 304                 # u=rw,g=rw,o=rw
 305                 # 0
 306                 # ok
 307
 308                 if($line =~ s/^(?:Created|Updated) //) {
 309                         $line = $self->readline(); # path
 310                         $line = $self->readline(); # Entries line
 311                         my $mode = $self->readline(); chomp $mode;
 312                         $self->{'mode'} = $mode;
 313                         defined (my $cnt = $self->readline())
 314                                 or die "EOF from server after 'Changed'\n";
 315                         chomp $cnt;
 316                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 317                         $line="";
 318                         $res=0;
 319                         while($cnt) {
 320                                 my $buf;
 321                                 my $num = $self->{'socketi'}->read($buf,$cnt);
 322                                 die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 323                                 print $fh $buf;
 324                                 $res += $num;
 325                                 $cnt -= $num;
 326                         }
 327                 } elsif($line =~ s/^ //) {
 328                         print $fh $line;
 329                         $res += length($line);
 330                 } elsif($line =~ /^M\b/) {
 331                         # output, do nothing
 332                 } elsif($line =~ /^Mbinary\b/) {
 333                         my $cnt;
 334                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 335                         chomp $cnt;
 336                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 337                         $line="";
 338                         while($cnt) {
 339                                 my $buf;
 340                                 my $num = $self->{'socketi'}->read($buf,$cnt);
 341                                 die "S: Mbinary $cnt: $num: $!\n" if not defined $num or $num<=0;
 342                                 print $fh $buf;
 343                                 $res += $num;
 344                                 $cnt -= $num;
 345                         }
 346                 } else {
 347                         chomp $line;
 348                         if($line eq "ok") {
 349                                 # print STDERR "S: ok (".length($res).")\n";
 350                                 return $res;
 351                         } elsif($line =~ s/^E //) {
 352                                 # print STDERR "S: $line\n";
 353                         } elsif($line =~ /^Remove-entry /i) {
 354                                 $line = $self->readline(); # filename
 355                                 $line = $self->readline(); # OK
 356                                 chomp $line;
 357                                 die "Unknown: $line" if $line ne "ok";
 358                                 return -1;
 359                         } else {
 360                                 die "Unknown: $line\n";
 361                         }
 362                 }
 363         }
 364 }
 365 sub file {
 366         my($self,$fn,$rev) = @_;
 367         my $res;
 368
 369         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 370                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 371
 372         $self->_file($fn,$rev) and $res = $self->_line($fh);
 373
 374         if (!defined $res) {
 375             # retry
 376             $self->conn();
 377             $self->_file($fn,$rev)
 378                     or die "No file command send\n";
 379             $res = $self->_line($fh);
 380             die "No input: $fn $rev\n" unless defined $res;
 381         }
 382         close ($fh);
 383
 384         if ($res eq '') {
 385             die "Looks like the server has gone away while fetching $fn $rev -- exiting!";
 386         }
 387
 388         return ($name, $res);
 389 }
 390
 391
 392 package main;
 393
 394 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 395
 396
 397 sub pdate($) {
 398         my($d) = @_;
 399         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 400                 or die "Unparseable date: $d\n";
 401         my $y=$1; $y-=1900 if $y>1900;
 402         return timegm($6||0,$5,$4,$3,$2-1,$y);
 403 }
 404
 405 sub pmode($) {
 406         my($mode) = @_;
 407         my $m = 0;
 408         my $mm = 0;
 409         my $um = 0;
 410         for my $x(split(//,$mode)) {
 411                 if($x eq ",") {
 412                         $m |= $mm&$um;
 413                         $mm = 0;
 414                         $um = 0;
 415                 } elsif($x eq "u") { $um |= 0700;
 416                 } elsif($x eq "g") { $um |= 0070;
 417                 } elsif($x eq "o") { $um |= 0007;
 418                 } elsif($x eq "r") { $mm |= 0444;
 419                 } elsif($x eq "w") { $mm |= 0222;
 420                 } elsif($x eq "x") { $mm |= 0111;
 421                 } elsif($x eq "=") { # do nothing
 422                 } else { die "Unknown mode: $mode\n";
 423                 }
 424         }
 425         $m |= $mm&$um;
 426         return $m;
 427 }
 428
 429 sub getwd() {
 430         my $pwd = `pwd`;
 431         chomp $pwd;
 432         return $pwd;
 433 }
 434
 435
 436 sub get_headref($$) {
 437     my $name    = shift;
 438     my $git_dir = shift;
 439     my $sha;
 440
 441     if (open(C,"$git_dir/refs/heads/$name")) {
 442         chomp($sha = <C>);
 443         close(C);
 444         length($sha) == 40
 445             or die "Cannot get head id for $name ($sha): $!\n";
 446     }
 447     return $sha;
 448 }
 449
 450
 451 -d $git_tree
 452         or mkdir($git_tree,0777)
 453         or die "Could not create $git_tree: $!";
 454 chdir($git_tree);
 455
 456 my $last_branch = "";
 457 my $orig_branch = "";
 458 my $forward_master = 0;
 459 my %branch_date;
 460
 461 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 462 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 463 $ENV{"GIT_DIR"} = $git_dir;
 464 my $orig_git_index;
 465 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 466 my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 467                                     DIR => File::Spec->tmpdir());
 468 close ($git_ih);
 469 $ENV{GIT_INDEX_FILE} = $git_index;
 470 unless(-d $git_dir) {
 471         system("git-init-db");
 472         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 473         system("git-read-tree");
 474         die "Cannot init an empty tree: $?\n" if $?;
 475
 476         $last_branch = $opt_o;
 477         $orig_branch = "";
 478 } else {
 479         -f "$git_dir/refs/heads/$opt_o"
 480                 or die "Branch '$opt_o' does not exist.\n".
 481                        "Either use the correct '-o branch' option,\n".
 482                        "or import to a new repository.\n";
 483
 484         open(F, "git-symbolic-ref HEAD |") or
 485                 die "Cannot run git-symbolic-ref: $!\n";
 486         chomp ($last_branch = <F>);
 487         $last_branch = basename($last_branch);
 488         close(F);
 489         unless($last_branch) {
 490                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 491                 $last_branch = "master";
 492         }
 493         $orig_branch = $last_branch;
 494         if (-f "$git_dir/CVS2GIT_HEAD") {
 495                 die <<EOM;
 496 CVS2GIT_HEAD exists.
 497 Make sure your working directory corresponds to HEAD and remove CVS2GIT_HEAD.
 498 You may need to run
 499
 500     git read-tree -m -u CVS2GIT_HEAD HEAD
 501 EOM
 502         }
 503         system('cp', "$git_dir/HEAD", "$git_dir/CVS2GIT_HEAD");
 504
 505         $forward_master =
 506             $opt_o ne 'master' && -f "$git_dir/refs/heads/master" &&
 507             system('cmp', '-s', "$git_dir/refs/heads/master",
 508                                 "$git_dir/refs/heads/$opt_o") == 0;
 509
 510         # populate index
 511         system('git-read-tree', $last_branch);
 512         die "read-tree failed: $?\n" if $?;
 513
 514         # Get the last import timestamps
 515         opendir(D,"$git_dir/refs/heads");
 516         while(defined(my $head = readdir(D))) {
 517                 next if $head =~ /^\./;
 518                 open(F,"$git_dir/refs/heads/$head")
 519                         or die "Bad head branch: $head: $!\n";
 520                 chomp(my $ftag = <F>);
 521                 close(F);
 522                 open(F,"git-cat-file commit $ftag |");
 523                 while(<F>) {
 524                         next unless /^author\s.*\s(\d+)\s[-+]\d{4}$/;
 525                         $branch_date{$head} = $1;
 526                         last;
 527                 }
 528                 close(F);
 529         }
 530         closedir(D);
 531 }
 532
 533 -d $git_dir
 534         or die "Could not create git subdir ($git_dir).\n";
 535
 536 # now we read (and possibly save) author-info as well
 537 -f "$git_dir/cvs-authors" and
 538   read_author_info("$git_dir/cvs-authors");
 539 if ($opt_A) {
 540         read_author_info($opt_A);
 541         write_author_info("$git_dir/cvs-authors");
 542 }
 543
 544 my $pid = open(CVS,"-|");
 545 die "Cannot fork: $!\n" unless defined $pid;
 546 unless($pid) {
 547         my @opt;
 548         @opt = split(/,/,$opt_p) if defined $opt_p;
 549         unshift @opt, '-z', $opt_z if defined $opt_z;
 550         unshift @opt, '-q'         unless defined $opt_v;
 551         unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 552                 push @opt, '--cvs-direct';
 553         }
 554         if ($opt_P) {
 555             exec("cat", $opt_P);
 556         } else {
 557             exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 558             die "Could not start cvsps: $!\n";
 559         }
 560 }
 561
 562
 563 ## cvsps output:
 564 #---------------------
 565 #PatchSet 314
 566 #Date: 1999/09/18 13:03:59
 567 #Author: wkoch
 568 #Branch: STABLE-BRANCH-1-0
 569 #Ancestor branch: HEAD
 570 #Tag: (none)
 571 #Log:
 572 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 573 #Members:
 574 #       README:1.57->1.57.2.1
 575 #       VERSION:1.96->1.96.2.1
 576 #
 577 #---------------------
 578
 579 my $state = 0;
 580
 581 my($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 582 my(@old,@new);
 583 my $commit = sub {
 584         my $pid;
 585         while(@old) {
 586                 my @o2;
 587                 if(@old > 55) {
 588                         @o2 = splice(@old,0,50);
 589                 } else {
 590                         @o2 = @old;
 591                         @old = ();
 592                 }
 593                 system("git-update-index","--force-remove","--",@o2);
 594                 die "Cannot remove files: $?\n" if $?;
 595         }
 596         while(@new) {
 597                 my @n2;
 598                 if(@new > 12) {
 599                         @n2 = splice(@new,0,10);
 600                 } else {
 601                         @n2 = @new;
 602                         @new = ();
 603                 }
 604                 system("git-update-index","--add",
 605                         (map { ('--cacheinfo', @$_) } @n2));
 606                 die "Cannot add files: $?\n" if $?;
 607         }
 608
 609         $pid = open(C,"-|");
 610         die "Cannot fork: $!" unless defined $pid;
 611         unless($pid) {
 612                 exec("git-write-tree");
 613                 die "Cannot exec git-write-tree: $!\n";
 614         }
 615         chomp(my $tree = <C>);
 616         length($tree) == 40
 617                 or die "Cannot get tree id ($tree): $!\n";
 618         close(C)
 619                 or die "Error running git-write-tree: $?\n";
 620         print "Tree ID $tree\n" if $opt_v;
 621
 622         my $parent = "";
 623         if(open(C,"$git_dir/refs/heads/$last_branch")) {
 624                 chomp($parent = <C>);
 625                 close(C);
 626                 length($parent) == 40
 627                         or die "Cannot get parent id ($parent): $!\n";
 628                 print "Parent ID $parent\n" if $opt_v;
 629         }
 630
 631         my $pr = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 632         my $pw = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 633         $pid = fork();
 634         die "Fork: $!\n" unless defined $pid;
 635         unless($pid) {
 636                 $pr->writer();
 637                 $pw->reader();
 638                 open(OUT,">&STDOUT");
 639                 dup2($pw->fileno(),0);
 640                 dup2($pr->fileno(),1);
 641                 $pr->close();
 642                 $pw->close();
 643
 644                 my @par = ();
 645                 @par = ("-p",$parent) if $parent;
 646
 647                 # loose detection of merges
 648                 # based on the commit msg
 649                 foreach my $rx (@mergerx) {
 650                         if ($logmsg =~ $rx) {
 651                                 my $mparent = $1;
 652                                 if ($mparent eq 'HEAD') { $mparent = $opt_o };
 653                                 if ( -e "$git_dir/refs/heads/$mparent") {
 654                                         $mparent = get_headref($mparent, $git_dir);
 655                                         push @par, '-p', $mparent;
 656                                         print OUT "Merge parent branch: $mparent\n" if $opt_v;
 657                                 }
 658                         }
 659                 }
 660
 661                 exec("env",
 662                         "GIT_AUTHOR_NAME=$author_name",
 663                         "GIT_AUTHOR_EMAIL=$author_email",
 664                         "GIT_AUTHOR_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 665                         "GIT_COMMITTER_NAME=$author_name",
 666                         "GIT_COMMITTER_EMAIL=$author_email",
 667                         "GIT_COMMITTER_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 668                         "git-commit-tree", $tree,@par);
 669                 die "Cannot exec git-commit-tree: $!\n";
 670         }
 671         $pw->writer();
 672         $pr->reader();
 673
 674         # compatibility with git2cvs
 675         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 676         $logmsg =~ s/[\s\n]+\z//;
 677
 678         print $pw "$logmsg\n"
 679                 or die "Error writing to git-commit-tree: $!\n";
 680         $pw->close();
 681
 682         print "Committed patch $patchset ($branch ".strftime("%Y-%m-%d %H:%M:%S",gmtime($date)).")\n" if $opt_v;
 683         chomp(my $cid = <$pr>);
 684         length($cid) == 40
 685                 or die "Cannot get commit id ($cid): $!\n";
 686         print "Commit ID $cid\n" if $opt_v;
 687         $pr->close();
 688
 689         waitpid($pid,0);
 690         die "Error running git-commit-tree: $?\n" if $?;
 691
 692         open(C,">$git_dir/refs/heads/$branch")
 693                 or die "Cannot open branch $branch for update: $!\n";
 694         print C "$cid\n"
 695                 or die "Cannot write branch $branch for update: $!\n";
 696         close(C)
 697                 or die "Cannot write branch $branch for update: $!\n";
 698
 699         if($tag) {
 700                 my($in, $out) = ('','');
 701                 my($xtag) = $tag;
 702                 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 703                 $xtag =~ tr/_/\./ if ( $opt_u );
 704                 $xtag =~ s/[\/]/$opt_s/g;
 705
 706                 my $pid = open2($in, $out, 'git-mktag');
 707                 print $out "object $cid\n".
 708                     "type commit\n".
 709                     "tag $xtag\n".
 710                     "tagger $author_name <$author_email>\n"
 711                     or die "Cannot create tag object $xtag: $!\n";
 712                 close($out)
 713                     or die "Cannot create tag object $xtag: $!\n";
 714
 715                 my $tagobj = <$in>;
 716                 chomp $tagobj;
 717
 718                 if ( !close($in) or waitpid($pid, 0) != $pid or
 719                      $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 720                     die "Cannot create tag object $xtag: $!\n";
 721                 }
 722
 723
 724                 open(C,">$git_dir/refs/tags/$xtag")
 725                         or die "Cannot create tag $xtag: $!\n";
 726                 print C "$tagobj\n"
 727                         or die "Cannot write tag $xtag: $!\n";
 728                 close(C)
 729                         or die "Cannot write tag $xtag: $!\n";
 730
 731                 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 732         }
 733 };
 734
 735 while(<CVS>) {
 736         chomp;
 737         if($state == 0 and /^-+$/) {
 738                 $state = 1;
 739         } elsif($state == 0) {
 740                 $state = 1;
 741                 redo;
 742         } elsif(($state==0 or $state==1) and s/^PatchSet\s+//) {
 743                 $patchset = 0+$_;
 744                 $state=2;
 745         } elsif($state == 2 and s/^Date:\s+//) {
 746                 $date = pdate($_);
 747                 unless($date) {
 748                         print STDERR "Could not parse date: $_\n";
 749                         $state=0;
 750                         next;
 751                 }
 752                 $state=3;
 753         } elsif($state == 3 and s/^Author:\s+//) {
 754                 s/\s+$//;
 755                 if (/^(.*?)\s+<(.*)>/) {
 756                     ($author_name, $author_email) = ($1, $2);
 757                 } elsif ($conv_author_name{$_}) {
 758                         $author_name = $conv_author_name{$_};
 759                         $author_email = $conv_author_email{$_};
 760                 } else {
 761                     $author_name = $author_email = $_;
 762                 }
 763                 $state = 4;
 764         } elsif($state == 4 and s/^Branch:\s+//) {
 765                 s/\s+$//;
 766                 s/[\/]/$opt_s/g;
 767                 $branch = $_;
 768                 $state = 5;
 769         } elsif($state == 5 and s/^Ancestor branch:\s+//) {
 770                 s/\s+$//;
 771                 $ancestor = $_;
 772                 $ancestor = $opt_o if $ancestor eq "HEAD";
 773                 $state = 6;
 774         } elsif($state == 5) {
 775                 $ancestor = undef;
 776                 $state = 6;
 777                 redo;
 778         } elsif($state == 6 and s/^Tag:\s+//) {
 779                 s/\s+$//;
 780                 if($_ eq "(none)") {
 781                         $tag = undef;
 782                 } else {
 783                         $tag = $_;
 784                 }
 785                 $state = 7;
 786         } elsif($state == 7 and /^Log:/) {
 787                 $logmsg = "";
 788                 $state = 8;
 789         } elsif($state == 8 and /^Members:/) {
 790                 $branch = $opt_o if $branch eq "HEAD";
 791                 if(defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 792                         # skip
 793                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 794                         $state = 11;
 795                         next;
 796                 }
 797                 if($ancestor) {
 798                         if(-f "$git_dir/refs/heads/$branch") {
 799                                 print STDERR "Branch $branch already exists!\n";
 800                                 $state=11;
 801                                 next;
 802                         }
 803                         unless(open(H,"$git_dir/refs/heads/$ancestor")) {
 804                                 print STDERR "Branch $ancestor does not exist!\n";
 805                                 $state=11;
 806                                 next;
 807                         }
 808                         chomp(my $id = <H>);
 809                         close(H);
 810                         unless(open(H,"> $git_dir/refs/heads/$branch")) {
 811                                 print STDERR "Could not create branch $branch: $!\n";
 812                                 $state=11;
 813                                 next;
 814                         }
 815                         print H "$id\n"
 816                                 or die "Could not write branch $branch: $!";
 817                         close(H)
 818                                 or die "Could not write branch $branch: $!";
 819                 }
 820                 if(($ancestor || $branch) ne $last_branch) {
 821                         print "Switching from $last_branch to $branch\n" if $opt_v;
 822                         system("git-read-tree", $branch);
 823                         die "read-tree failed: $?\n" if $?;
 824                 }
 825                 $last_branch = $branch if $branch ne $last_branch;
 826                 $state = 9;
 827         } elsif($state == 8) {
 828                 $logmsg .= "$_\n";
 829         } elsif($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 830 #       VERSION:1.96->1.96.2.1
 831                 my $init = ($2 eq "INITIAL");
 832                 my $fn = $1;
 833                 my $rev = $3;
 834                 $fn =~ s#^/+##;
 835                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 836                 if($size == -1) {
 837                         push(@old,$fn);
 838                         print "Drop $fn\n" if $opt_v;
 839                 } else {
 840                         print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 841                         open my $F, '-|', "git-hash-object -w $tmpname"
 842                                 or die "Cannot create object: $!\n";
 843                         my $sha = <$F>;
 844                         chomp $sha;
 845                         close $F;
 846                         my $mode = pmode($cvs->{'mode'});
 847                         push(@new,[$mode, $sha, $fn]); # may be resurrected!
 848                 }
 849                 unlink($tmpname);
 850         } elsif($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 851                 my $fn = $1;
 852                 $fn =~ s#^/+##;
 853                 push(@old,$fn);
 854                 print "Delete $fn\n" if $opt_v;
 855         } elsif($state == 9 and /^\s*$/) {
 856                 $state = 10;
 857         } elsif(($state == 9 or $state == 10) and /^-+$/) {
 858                 &$commit();
 859                 $state = 1;
 860         } elsif($state == 11 and /^-+$/) {
 861                 $state = 1;
 862         } elsif(/^-+$/) { # end of unknown-line processing
 863                 $state = 1;
 864         } elsif($state != 11) { # ignore stuff when skipping
 865                 print "* UNKNOWN LINE * $_\n";
 866         }
 867 }
 868 &$commit() if $branch and $state != 11;
 869
 870 unlink($git_index);
 871
 872 if (defined $orig_git_index) {
 873         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 874 } else {
 875         delete $ENV{GIT_INDEX_FILE};
 876 }
 877
 878 # Now switch back to the branch we were in before all of this happened
 879 if($orig_branch) {
 880         print "DONE\n" if $opt_v;
 881         system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 882                 if $forward_master;
 883         unless ($opt_i) {
 884                 system('git-read-tree', '-m', '-u', 'CVS2GIT_HEAD', 'HEAD');
 885                 die "read-tree failed: $?\n" if $?;
 886         }
 887 } else {
 888         $orig_branch = "master";
 889         print "DONE; creating $orig_branch branch\n" if $opt_v;
 890         system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 891                 unless -f "$git_dir/refs/heads/master";
 892         system('git-update-ref', 'HEAD', "$orig_branch");
 893         unless ($opt_i) {
 894                 system('git checkout');
 895                 die "checkout failed: $?\n" if $?;
 896         }
 897 }
 898 unlink("$git_dir/CVS2GIT_HEAD");