git.oblomov.eu Git - git/blob - contrib/completion/git-completion.zsh

   1 #compdef git gitk
   2
   3 # zsh completion wrapper for git
   4 #
   5 # Copyright (c) 2012-2013 Felipe Contreras <felipe.contreras@gmail.com>
   6 #
   7 # The recommended way to install this script is to make a copy of it as a
   8 # file named '_git' inside any directory in your fpath.
   9 #
  10 # For example, create a directory '~/.zsh/', copy this file to '~/.zsh/_git',
  11 # and then add the following to your ~/.zshrc file:
  12 #
  13 #  fpath=(~/.zsh $fpath)
  14 #
  15 # You need git's bash completion script installed. By default bash-completion's
  16 # location will be used (e.g. pkg-config --variable=completionsdir bash-completion).
  17 #
  18 # If your bash completion script is somewhere else, you can specify the
  19 # location in your ~/.zshrc:
  20 #
  21 #  zstyle ':completion:*:*:git:*' script ~/.git-completion.bash
  22 #
  23
  24 zstyle -T ':completion:*:*:git:*' tag-order && \
  25         zstyle ':completion:*:*:git:*' tag-order 'common-commands'
  26
  27 zstyle -s ":completion:*:*:git:*" script script
  28 if [ -z "$script" ]; then
  29         local -a locations
  30         local e bash_completion
  31
  32         bash_completion=$(pkg-config --variable=completionsdir bash-completion 2>/dev/null) ||
  33                 bash_completion='/usr/share/bash-completion/completions/'
  34
  35         locations=(
  36                 "$(dirname ${funcsourcetrace[1]%:*})"/git-completion.bash
  37                 "$HOME/.local/share/bash-completion/completions/git"
  38                 "$bash_completion/git"
  39                 '/etc/bash_completion.d/git' # old debian
  40                 )
  41         for e in $locations; do
  42                 test -f $e && script="$e" && break
  43         done
  44 fi
  45
  46 local old_complete="$functions[complete]"
  47 functions[complete]=:
  48 GIT_SOURCING_ZSH_COMPLETION=y . "$script"
  49 functions[complete]="$old_complete"
  50
  51 __gitcomp ()
  52 {
  53         emulate -L zsh
  54
  55         local cur_="${3-$cur}"
  56
  57         case "$cur_" in
  58         --*=)
  59                 ;;
  60         --no-*)
  61                 local c IFS=$' \t\n'
  62                 local -a array
  63                 for c in ${=1}; do
  64                         if [[ $c == "--" ]]; then
  65                                 continue
  66                         fi
  67                         c="$c${4-}"
  68                         case $c in
  69                         --*=|*.) ;;
  70                         *) c="$c " ;;
  71                         esac
  72                         array+=("$c")
  73                 done
  74                 compset -P '*[=:]'
  75                 compadd -Q -S '' -p "${2-}" -a -- array && _ret=0
  76                 ;;
  77         *)
  78                 local c IFS=$' \t\n'
  79                 local -a array
  80                 for c in ${=1}; do
  81                         if [[ $c == "--" ]]; then
  82                                 c="--no-...${4-}"
  83                                 array+=("$c ")
  84                                 break
  85                         fi
  86                         c="$c${4-}"
  87                         case $c in
  88                         --*=*|*.) ;;
  89                         *) c="$c " ;;
  90                         esac
  91                         array+=("$c")
  92                 done
  93                 compset -P '*[=:]'
  94                 compadd -Q -S '' -p "${2-}" -a -- array && _ret=0
  95                 ;;
  96         esac
  97 }
  98
  99 __gitcomp_direct ()
 100 {
 101         emulate -L zsh
 102
 103         local IFS=$'\n'
 104         compset -P '*[=:]'
 105         compadd -Q -- ${${=1}% } && _ret=0
 106 }
 107
 108 __gitcomp_direct_append ()
 109 {
 110         __gitcomp_direct "$@"
 111 }
 112
 113 __gitcomp_nl ()
 114 {
 115         emulate -L zsh
 116
 117         local IFS=$'\n'
 118         compset -P '*[=:]'
 119         compadd -Q -S "${4- }" -p "${2-}" -- ${=1} && _ret=0
 120 }
 121
 122 __gitcomp_nl_append ()
 123 {
 124         emulate -L zsh
 125
 126         local IFS=$'\n'
 127         compset -P '*[=:]'
 128         compadd -Q -S "${4- }" -p "${2-}" -- ${=1} && _ret=0
 129 }
 130
 131 __gitcomp_file_direct ()
 132 {
 133         emulate -L zsh
 134
 135         local IFS=$'\n'
 136         compadd -f -- ${=1} && _ret=0
 137 }
 138
 139 __gitcomp_file ()
 140 {
 141         emulate -L zsh
 142
 143         local IFS=$'\n'
 144         compadd -p "${2-}" -f -- ${=1} && _ret=0
 145 }
 146
 147 __git_zsh_bash_func ()
 148 {
 149         emulate -L ksh
 150
 151         local command=$1
 152
 153         local completion_func="_git_${command//-/_}"
 154         declare -f $completion_func >/dev/null && $completion_func && return
 155
 156         local expansion=$(__git_aliased_command "$command")
 157         if [ -n "$expansion" ]; then
 158                 words[1]=$expansion
 159                 completion_func="_git_${expansion//-/_}"
 160                 declare -f $completion_func >/dev/null && $completion_func
 161         fi
 162 }
 163
 164 __git_zsh_cmd_common ()
 165 {
 166         local -a list
 167         list=(
 168         add:'add file contents to the index'
 169         bisect:'find by binary search the change that introduced a bug'
 170         branch:'list, create, or delete branches'
 171         checkout:'checkout a branch or paths to the working tree'
 172         clone:'clone a repository into a new directory'
 173         commit:'record changes to the repository'
 174         diff:'show changes between commits, commit and working tree, etc'
 175         fetch:'download objects and refs from another repository'
 176         grep:'print lines matching a pattern'
 177         init:'create an empty Git repository or reinitialize an existing one'
 178         log:'show commit logs'
 179         merge:'join two or more development histories together'
 180         mv:'move or rename a file, a directory, or a symlink'
 181         pull:'fetch from and merge with another repository or a local branch'
 182         push:'update remote refs along with associated objects'
 183         rebase:'forward-port local commits to the updated upstream head'
 184         reset:'reset current HEAD to the specified state'
 185         restore:'restore working tree files'
 186         rm:'remove files from the working tree and from the index'
 187         show:'show various types of objects'
 188         status:'show the working tree status'
 189         switch:'switch branches'
 190         tag:'create, list, delete or verify a tag object signed with GPG')
 191         _describe -t common-commands 'common commands' list && _ret=0
 192 }
 193
 194 __git_zsh_cmd_alias ()
 195 {
 196         local -a list
 197         list=(${${${(0)"$(git config -z --get-regexp '^alias\.')"}#alias.}%$'\n'*})
 198         _describe -t alias-commands 'aliases' list $* && _ret=0
 199 }
 200
 201 __git_zsh_cmd_all ()
 202 {
 203         local -a list
 204         emulate ksh -c __git_compute_all_commands
 205         list=( ${=__git_all_commands} )
 206         _describe -t all-commands 'all commands' list && _ret=0
 207 }
 208
 209 __git_zsh_main ()
 210 {
 211         local curcontext="$curcontext" state state_descr line
 212         typeset -A opt_args
 213         local -a orig_words
 214
 215         orig_words=( ${words[@]} )
 216
 217         _arguments -C \
 218                 '(-p --paginate --no-pager)'{-p,--paginate}'[pipe all output into ''less'']' \
 219                 '(-p --paginate)--no-pager[do not pipe git output into a pager]' \
 220                 '--git-dir=-[set the path to the repository]: :_directories' \
 221                 '--bare[treat the repository as a bare repository]' \
 222                 '(- :)--version[prints the git suite version]' \
 223                 '--exec-path=-[path to where your core git programs are installed]:: :_directories' \
 224                 '--html-path[print the path where git''s HTML documentation is installed]' \
 225                 '--info-path[print the path where the Info files are installed]' \
 226                 '--man-path[print the manpath (see `man(1)`) for the man pages]' \
 227                 '--work-tree=-[set the path to the working tree]: :_directories' \
 228                 '--namespace=-[set the git namespace]' \
 229                 '--no-replace-objects[do not use replacement refs to replace git objects]' \
 230                 '(- :)--help[prints the synopsis and a list of the most commonly used commands]: :->arg' \
 231                 '(-): :->command' \
 232                 '(-)*:: :->arg' && return
 233
 234         case $state in
 235         (command)
 236                 _alternative \
 237                          'alias-commands:alias:__git_zsh_cmd_alias' \
 238                          'common-commands:common:__git_zsh_cmd_common' \
 239                          'all-commands:all:__git_zsh_cmd_all' && _ret=0
 240                 ;;
 241         (arg)
 242                 local command="${words[1]}" __git_dir
 243
 244                 if (( $+opt_args[--bare] )); then
 245                         __git_dir='.'
 246                 else
 247                         __git_dir=${opt_args[--git-dir]}
 248                 fi
 249
 250                 (( $+opt_args[--help] )) && command='help'
 251
 252                 words=( ${orig_words[@]} )
 253
 254                 __git_zsh_bash_func $command
 255                 ;;
 256         esac
 257 }
 258
 259 _git ()
 260 {
 261         local _ret=1
 262         local cur cword prev
 263
 264         cur=${words[CURRENT]}
 265         prev=${words[CURRENT-1]}
 266         let cword=CURRENT-1
 267
 268         if (( $+functions[__${service}_zsh_main] )); then
 269                 __${service}_zsh_main
 270         elif (( $+functions[__${service}_main] )); then
 271                 emulate ksh -c __${service}_main
 272         elif (( $+functions[_${service}] )); then
 273                 emulate ksh -c _${service}
 274         elif (( $+functions[_${service//-/_}] )); then
 275                 emulate ksh -c _${service//-/_}
 276         fi
 277
 278         let _ret && _default && _ret=0
 279         return _ret
 280 }
 281
 282 _git