git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Net::SMTP;
  25
  26 # most mail servers generate the Date: header, but not all...
  27 $ENV{LC_ALL} = 'C';
  28 use POSIX qw/strftime/;
  29
  30 my $have_email_valid = eval { require Email::Valid; 1 };
  31 my $smtp;
  32
  33 sub unique_email_list(@);
  34 sub cleanup_compose_files();
  35
  36 # Constants (essentially)
  37 my $compose_filename = ".msg.$$";
  38
  39 # Variables we fill in automatically, or via prompting:
  40 my (@to,@cc,@initial_cc,$initial_reply_to,$initial_subject,@files,$from,$compose,$time);
  41
  42 # Behavior modification variables
  43 my ($chain_reply_to, $quiet, $suppress_from, $no_signed_off_cc) = (1, 0, 0, 0);
  44 my $smtp_server;
  45
  46 # Example reply to:
  47 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
  48
  49 my $term = new Term::ReadLine 'git-send-email';
  50
  51 # Begin by accumulating all the variables (defined above), that we will end up
  52 # needing, first, from the command line:
  53
  54 my $rc = GetOptions("from=s" => \$from,
  55                     "in-reply-to=s" => \$initial_reply_to,
  56                     "subject=s" => \$initial_subject,
  57                     "to=s" => \@to,
  58                     "cc=s" => \@initial_cc,
  59                     "chain-reply-to!" => \$chain_reply_to,
  60                     "smtp-server=s" => \$smtp_server,
  61                     "compose" => \$compose,
  62                     "quiet" => \$quiet,
  63                     "suppress-from" => \$suppress_from,
  64                     "no-signed-off-cc|no-signed-off-by-cc" => \$no_signed_off_cc,
  65          );
  66
  67 # Now, let's fill any that aren't set in with defaults:
  68
  69 sub gitvar {
  70     my ($var) = @_;
  71     my $fh;
  72     my $pid = open($fh, '-|');
  73     die "$!" unless defined $pid;
  74     if (!$pid) {
  75         exec('git-var', $var) or die "$!";
  76     }
  77     my ($val) = <$fh>;
  78     close $fh or die "$!";
  79     chomp($val);
  80     return $val;
  81 }
  82
  83 sub gitvar_ident {
  84     my ($name) = @_;
  85     my $val = gitvar($name);
  86     my @field = split(/\s+/, $val);
  87     return join(' ', @field[0...(@field-3)]);
  88 }
  89
  90 my ($author) = gitvar_ident('GIT_AUTHOR_IDENT');
  91 my ($committer) = gitvar_ident('GIT_COMMITTER_IDENT');
  92
  93 my %aliases;
  94 chomp(my @alias_files = `git-repo-config --get-all sendemail.aliasesfile`);
  95 chomp(my $aliasfiletype = `git-repo-config sendemail.aliasfiletype`);
  96 my %parse_alias = (
  97         # multiline formats can be supported in the future
  98         mutt => sub { my $fh = shift; while (<$fh>) {
  99                 if (/^alias\s+(\S+)\s+(.*)$/) {
 100                         my ($alias, $addr) = ($1, $2);
 101                         $addr =~ s/#.*$//; # mutt allows # comments
 102                          # commas delimit multiple addresses
 103                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 104                 }}},
 105         mailrc => sub { my $fh = shift; while (<$fh>) {
 106                 if (/^alias\s+(\S+)\s+(.*)$/) {
 107                         # spaces delimit multiple addresses
 108                         $aliases{$1} = [ split(/\s+/, $2) ];
 109                 }}},
 110         pine => sub { my $fh = shift; while (<$fh>) {
 111                 if (/^(\S+)\s+(.*)$/) {
 112                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 113                 }}},
 114         gnus => sub { my $fh = shift; while (<$fh>) {
 115                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 116                         $aliases{$1} = [ $2 ];
 117                 }}}
 118 );
 119
 120 if (@alias_files && defined $parse_alias{$aliasfiletype}) {
 121         foreach my $file (@alias_files) {
 122                 open my $fh, '<', $file or die "opening $file: $!\n";
 123                 $parse_alias{$aliasfiletype}->($fh);
 124                 close $fh;
 125         }
 126 }
 127
 128 my $prompting = 0;
 129 if (!defined $from) {
 130         $from = $author || $committer;
 131         do {
 132                 $_ = $term->readline("Who should the emails appear to be from? ",
 133                         $from);
 134         } while (!defined $_);
 135
 136         $from = $_;
 137         print "Emails will be sent from: ", $from, "\n";
 138         $prompting++;
 139 }
 140
 141 if (!@to) {
 142         do {
 143                 $_ = $term->readline("Who should the emails be sent to? ",
 144                                 "");
 145         } while (!defined $_);
 146         my $to = $_;
 147         push @to, split /,/, $to;
 148         $prompting++;
 149 }
 150
 151 sub expand_aliases {
 152         my @cur = @_;
 153         my @last;
 154         do {
 155                 @last = @cur;
 156                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 157         } while (join(',',@cur) ne join(',',@last));
 158         return @cur;
 159 }
 160
 161 @to = expand_aliases(@to);
 162 @initial_cc = expand_aliases(@initial_cc);
 163
 164 if (!defined $initial_subject && $compose) {
 165         do {
 166                 $_ = $term->readline("What subject should the emails start with? ",
 167                         $initial_subject);
 168         } while (!defined $_);
 169         $initial_subject = $_;
 170         $prompting++;
 171 }
 172
 173 if (!defined $initial_reply_to && $prompting) {
 174         do {
 175                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 176                         $initial_reply_to);
 177         } while (!defined $_);
 178
 179         $initial_reply_to = $_;
 180         $initial_reply_to =~ s/(^\s+|\s+$)//g;
 181 }
 182
 183 if (!$smtp_server) {
 184         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 185                 if (-x $_) {
 186                         $smtp_server = $_;
 187                         last;
 188                 }
 189         }
 190         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 191 }
 192
 193 if ($compose) {
 194         # Note that this does not need to be secure, but we will make a small
 195         # effort to have it be unique
 196         open(C,">",$compose_filename)
 197                 or die "Failed to open for writing $compose_filename: $!";
 198         print C "From $from # This line is ignored.\n";
 199         printf C "Subject: %s\n\n", $initial_subject;
 200         printf C <<EOT;
 201 GIT: Please enter your email below.
 202 GIT: Lines beginning in "GIT: " will be removed.
 203 GIT: Consider including an overall diffstat or table of contents
 204 GIT: for the patch you are writing.
 205
 206 EOT
 207         close(C);
 208
 209         my $editor = $ENV{EDITOR};
 210         $editor = 'vi' unless defined $editor;
 211         system($editor, $compose_filename);
 212
 213         open(C2,">",$compose_filename . ".final")
 214                 or die "Failed to open $compose_filename.final : " . $!;
 215
 216         open(C,"<",$compose_filename)
 217                 or die "Failed to open $compose_filename : " . $!;
 218
 219         while(<C>) {
 220                 next if m/^GIT: /;
 221                 print C2 $_;
 222         }
 223         close(C);
 224         close(C2);
 225
 226         do {
 227                 $_ = $term->readline("Send this email? (y|n) ");
 228         } while (!defined $_);
 229
 230         if (uc substr($_,0,1) ne 'Y') {
 231                 cleanup_compose_files();
 232                 exit(0);
 233         }
 234
 235         @files = ($compose_filename . ".final");
 236 }
 237
 238
 239 # Now that all the defaults are set, process the rest of the command line
 240 # arguments and collect up the files that need to be processed.
 241 for my $f (@ARGV) {
 242         if (-d $f) {
 243                 opendir(DH,$f)
 244                         or die "Failed to opendir $f: $!";
 245
 246                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 247                                 sort readdir(DH);
 248
 249         } elsif (-f $f) {
 250                 push @files, $f;
 251
 252         } else {
 253                 print STDERR "Skipping $f - not found.\n";
 254         }
 255 }
 256
 257 if (@files) {
 258         unless ($quiet) {
 259                 print $_,"\n" for (@files);
 260         }
 261 } else {
 262         print <<EOT;
 263 git-send-email [options] <file | directory> [... file | directory ]
 264 Options:
 265    --from         Specify the "From:" line of the email to be sent.
 266
 267    --to           Specify the primary "To:" line of the email.
 268
 269    --cc           Specify an initial "Cc:" list for the entire series
 270                   of emails.
 271
 272    --compose      Use \$EDITOR to edit an introductory message for the
 273                   patch series.
 274
 275    --subject      Specify the initial "Subject:" line.
 276                   Only necessary if --compose is also set.  If --compose
 277                   is not set, this will be prompted for.
 278
 279    --in-reply-to  Specify the first "In-Reply-To:" header line.
 280                   Only used if --compose is also set.  If --compose is not
 281                   set, this will be prompted for.
 282
 283    --chain-reply-to If set, the replies will all be to the previous
 284                   email sent, rather than to the first email sent.
 285                   Defaults to on.
 286
 287    --no-signed-off-cc Suppress the automatic addition of email addresses
 288                  that appear in a Signed-off-by: line, to the cc: list.
 289                  Note: Using this option is not recommended.
 290
 291    --smtp-server  If set, specifies the outgoing SMTP server to use.
 292                   Defaults to localhost.
 293
 294   --suppress-from Supress sending emails to yourself if your address
 295                   appears in a From: line.
 296
 297    --quiet      Make git-send-email less verbose.  One line per email should be
 298                 all that is output.
 299
 300 Error: Please specify a file or a directory on the command line.
 301 EOT
 302         exit(1);
 303 }
 304
 305 # Variables we set as part of the loop over files
 306 our ($message_id, $cc, %mail, $subject, $reply_to, $message);
 307
 308 sub extract_valid_address {
 309         my $address = shift;
 310
 311         # check for a local address:
 312         return $address if ($address =~ /^([\w\-]+)$/);
 313
 314         if ($have_email_valid) {
 315                 return Email::Valid->address($address);
 316         } else {
 317                 # less robust/correct than the monster regexp in Email::Valid,
 318                 # but still does a 99% job, and one less dependency
 319                 return ($address =~ /([^\"<>\s]+@[^<>\s]+)/);
 320         }
 321 }
 322
 323 # Usually don't need to change anything below here.
 324
 325 # we make a "fake" message id by taking the current number
 326 # of seconds since the beginning of Unix time and tacking on
 327 # a random number to the end, in case we are called quicker than
 328 # 1 second since the last time we were called.
 329
 330 # We'll setup a template for the message id, using the "from" address:
 331 my $message_id_from = extract_valid_address($from);
 332 my $message_id_template = "<%s-git-send-email-$message_id_from>";
 333
 334 sub make_message_id
 335 {
 336         my $date = time;
 337         my $pseudo_rand = int (rand(4200));
 338         $message_id = sprintf $message_id_template, "$date$pseudo_rand";
 339         #print "new message id = $message_id\n"; # Was useful for debugging
 340 }
 341
 342
 343
 344 $cc = "";
 345 $time = time - scalar $#files;
 346
 347 sub send_message
 348 {
 349         my @recipients = unique_email_list(@to);
 350         my $to = join (",\n\t", @recipients);
 351         @recipients = unique_email_list(@recipients,@cc);
 352         my $date = strftime('%a, %d %b %Y %H:%M:%S %z', localtime($time++));
 353         my $gitversion = '@@GIT_VERSION@@';
 354         if ($gitversion =~ m/..GIT_VERSION../) {
 355             $gitversion = `git --version`;
 356             chomp $gitversion;
 357             # keep only what's after the last space
 358             $gitversion =~ s/^.* //;
 359         }
 360
 361         my $header = "From: $from
 362 To: $to
 363 Cc: $cc
 364 Subject: $subject
 365 Reply-To: $from
 366 Date: $date
 367 Message-Id: $message_id
 368 X-Mailer: git-send-email $gitversion
 369 ";
 370         $header .= "In-Reply-To: $reply_to\n" if $reply_to;
 371
 372         if ($smtp_server =~ m#^/#) {
 373                 my $pid = open my $sm, '|-';
 374                 defined $pid or die $!;
 375                 if (!$pid) {
 376                         exec($smtp_server,'-i',@recipients) or die $!;
 377                 }
 378                 print $sm "$header\n$message";
 379                 close $sm or die $?;
 380         } else {
 381                 $smtp ||= Net::SMTP->new( $smtp_server );
 382                 $smtp->mail( $from ) or die $smtp->message;
 383                 $smtp->to( @recipients ) or die $smtp->message;
 384                 $smtp->data or die $smtp->message;
 385                 $smtp->datasend("$header\n$message") or die $smtp->message;
 386                 $smtp->dataend() or die $smtp->message;
 387                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 388         }
 389         if ($quiet) {
 390                 printf "Sent %s\n", $subject;
 391         } else {
 392                 print "OK. Log says:\nDate: $date\n";
 393                 if ($smtp) {
 394                         print "Server: $smtp_server\n";
 395                 } else {
 396                         print "Sendmail: $smtp_server\n";
 397                 }
 398                 print "From: $from\nSubject: $subject\nCc: $cc\nTo: $to\n\n";
 399                 if ($smtp) {
 400                         print "Result: ", $smtp->code, ' ',
 401                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 402                 } else {
 403                         print "Result: OK\n";
 404                 }
 405         }
 406 }
 407
 408 $reply_to = $initial_reply_to;
 409 make_message_id();
 410 $subject = $initial_subject;
 411
 412 foreach my $t (@files) {
 413         open(F,"<",$t) or die "can't open file $t";
 414
 415         my $author_not_sender = undef;
 416         @cc = @initial_cc;
 417         my $found_mbox = 0;
 418         my $header_done = 0;
 419         $message = "";
 420         while(<F>) {
 421                 if (!$header_done) {
 422                         $found_mbox = 1, next if (/^From /);
 423                         chomp;
 424
 425                         if ($found_mbox) {
 426                                 if (/^Subject:\s+(.*)$/) {
 427                                         $subject = $1;
 428
 429                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 430                                         if ($2 eq $from) {
 431                                                 next if ($suppress_from);
 432                                         }
 433                                         else {
 434                                                 $author_not_sender = $2;
 435                                         }
 436                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 437                                                 $2, $_) unless $quiet;
 438                                         push @cc, $2;
 439                                 }
 440
 441                         } else {
 442                                 # In the traditional
 443                                 # "send lots of email" format,
 444                                 # line 1 = cc
 445                                 # line 2 = subject
 446                                 # So let's support that, too.
 447                                 if (@cc == 0) {
 448                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 449                                                 $_, $_) unless $quiet;
 450
 451                                         push @cc, $_;
 452
 453                                 } elsif (!defined $subject) {
 454                                         $subject = $_;
 455                                 }
 456                         }
 457
 458                         # A whitespace line will terminate the headers
 459                         if (m/^\s*$/) {
 460                                 $header_done = 1;
 461                         }
 462                 } else {
 463                         $message .=  $_;
 464                         if (/^Signed-off-by: (.*)$/i && !$no_signed_off_cc) {
 465                                 my $c = $1;
 466                                 chomp $c;
 467                                 push @cc, $c;
 468                                 printf("(sob) Adding cc: %s from line '%s'\n",
 469                                         $c, $_) unless $quiet;
 470                         }
 471                 }
 472         }
 473         close F;
 474         if (defined $author_not_sender) {
 475                 $message = "From: $author_not_sender\n\n$message";
 476         }
 477
 478         $cc = join(", ", unique_email_list(@cc));
 479
 480         send_message();
 481
 482         # set up for the next message
 483         if ($chain_reply_to || length($reply_to) == 0) {
 484                 $reply_to = $message_id;
 485         }
 486         make_message_id();
 487 }
 488
 489 if ($compose) {
 490         cleanup_compose_files();
 491 }
 492
 493 sub cleanup_compose_files() {
 494         unlink($compose_filename, $compose_filename . ".final");
 495
 496 }
 497
 498 $smtp->quit if $smtp;
 499
 500 sub unique_email_list(@) {
 501         my %seen;
 502         my @emails;
 503
 504         foreach my $entry (@_) {
 505                 if (my $clean = extract_valid_address($entry)) {
 506                         $seen{$clean} ||= 0;
 507                         next if $seen{$clean}++;
 508                         push @emails, $entry;
 509                 } else {
 510                         print STDERR "W: unable to extract a valid address",
 511                                         " from: $entry\n";
 512                 }
 513         }
 514         return @emails;
 515 }