git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision $_repository
   8                 $_q $_authors $_authors_prog %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22 $Git::SVN::_minimize_url = 'unset';
  23
  24 if (! exists $ENV{SVN_SSH}) {
  25         if (exists $ENV{GIT_SSH}) {
  26                 $ENV{SVN_SSH} = $ENV{GIT_SSH};
  27                 if ($^O eq 'msys') {
  28                         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  29                         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  30                 }
  31         }
  32 }
  33
  34 $Git::SVN::Log::TZ = $ENV{TZ};
  35 $ENV{TZ} = 'UTC';
  36 $| = 1; # unbuffer STDOUT
  37
  38 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  39 sub _req_svn {
  40         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  41         require SVN::Ra;
  42         require SVN::Delta;
  43         if ($SVN::Core::VERSION lt '1.1.0') {
  44                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  45         }
  46 }
  47 my $can_compress = eval { require Compress::Zlib; 1};
  48 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  49 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  50 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  51 use Carp qw/croak/;
  52 use Digest::MD5;
  53 use IO::File qw//;
  54 use File::Basename qw/dirname basename/;
  55 use File::Path qw/mkpath/;
  56 use File::Spec;
  57 use File::Find;
  58 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  59 use IPC::Open3;
  60 use Git;
  61
  62 BEGIN {
  63         # import functions from Git into our packages, en masse
  64         no strict 'refs';
  65         foreach (qw/command command_oneline command_noisy command_output_pipe
  66                     command_input_pipe command_close_pipe
  67                     command_bidi_pipe command_close_bidi_pipe/) {
  68                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  69                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  70                         __PACKAGE__) {
  71                         *{"${package}::$_"} = \&{"Git::$_"};
  72                 }
  73         }
  74 }
  75
  76 my ($SVN);
  77
  78 $sha1 = qr/[a-f\d]{40}/;
  79 $sha1_short = qr/[a-f\d]{4,40}/;
  80 my ($_stdin, $_help, $_edit,
  81         $_message, $_file, $_branch_dest,
  82         $_template, $_shared,
  83         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
  84         $_merge, $_strategy, $_dry_run, $_local,
  85         $_prefix, $_no_checkout, $_url, $_verbose,
  86         $_git_format, $_commit_url, $_tag);
  87 $Git::SVN::_follow_parent = 1;
  88 $_q ||= 0;
  89 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  90                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  91                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  92                     'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
  93 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  94                 'authors-file|A=s' => \$_authors,
  95                 'authors-prog=s' => \$_authors_prog,
  96                 'repack:i' => \$Git::SVN::_repack,
  97                 'noMetadata' => \$Git::SVN::_no_metadata,
  98                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  99                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 100                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 101                 'no-checkout' => \$_no_checkout,
 102                 'quiet|q+' => \$_q,
 103                 'repack-flags|repack-args|repack-opts=s' =>
 104                    \$Git::SVN::_repack_flags,
 105                 'use-log-author' => \$Git::SVN::_use_log_author,
 106                 'add-author-from' => \$Git::SVN::_add_author_from,
 107                 'localtime' => \$Git::SVN::_localtime,
 108                 %remote_opts );
 109
 110 my ($_trunk, @_tags, @_branches, $_stdlayout);
 111 my %icv;
 112 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 113                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 114                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 115                   'stdlayout|s' => \$_stdlayout,
 116                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 117                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 118                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 119                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 120                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 121                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 122                   %remote_opts );
 123 my %cmt_opts = ( 'edit|e' => \$_edit,
 124                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 125                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 126                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 127                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 128 );
 129
 130 my %cmd = (
 131         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 132                         { 'revision|r=s' => \$_revision,
 133                           'fetch-all|all' => \$_fetch_all,
 134                           'parent|p' => \$_fetch_parent,
 135                            %fc_opts } ],
 136         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 137                         { 'revision|r=s' => \$_revision,
 138                            %fc_opts, %init_opts } ],
 139         init => [ \&cmd_init, "Initialize a repo for tracking" .
 140                           " (requires URL argument)",
 141                           \%init_opts ],
 142         'multi-init' => [ \&cmd_multi_init,
 143                           "Deprecated alias for ".
 144                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 145                           \%init_opts ],
 146         dcommit => [ \&cmd_dcommit,
 147                      'Commit several diffs to merge with upstream',
 148                         { 'merge|m|M' => \$_merge,
 149                           'strategy|s=s' => \$_strategy,
 150                           'verbose|v' => \$_verbose,
 151                           'dry-run|n' => \$_dry_run,
 152                           'fetch-all|all' => \$_fetch_all,
 153                           'commit-url=s' => \$_commit_url,
 154                           'revision|r=i' => \$_revision,
 155                           'no-rebase' => \$_no_rebase,
 156                         %cmt_opts, %fc_opts } ],
 157         branch => [ \&cmd_branch,
 158                     'Create a branch in the SVN repository',
 159                     { 'message|m=s' => \$_message,
 160                       'destination|d=s' => \$_branch_dest,
 161                       'dry-run|n' => \$_dry_run,
 162                       'tag|t' => \$_tag,
 163                       'username=s' => \$Git::SVN::Prompt::_username,
 164                       'commit-url=s' => \$_commit_url } ],
 165         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 166                  'Create a tag in the SVN repository',
 167                  { 'message|m=s' => \$_message,
 168                    'destination|d=s' => \$_branch_dest,
 169                    'dry-run|n' => \$_dry_run,
 170                    'username=s' => \$Git::SVN::Prompt::_username,
 171                    'commit-url=s' => \$_commit_url } ],
 172         'set-tree' => [ \&cmd_set_tree,
 173                         "Set an SVN repository to a git tree-ish",
 174                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 175         'create-ignore' => [ \&cmd_create_ignore,
 176                              'Create a .gitignore per svn:ignore',
 177                              { 'revision|r=i' => \$_revision
 178                              } ],
 179         'mkdirs' => [ \&cmd_mkdirs ,
 180                       "recreate empty directories after a checkout",
 181                       { 'revision|r=i' => \$_revision } ],
 182         'propget' => [ \&cmd_propget,
 183                        'Print the value of a property on a file or directory',
 184                        { 'revision|r=i' => \$_revision } ],
 185         'proplist' => [ \&cmd_proplist,
 186                        'List all properties of a file or directory',
 187                        { 'revision|r=i' => \$_revision } ],
 188         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 189                         { 'revision|r=i' => \$_revision
 190                         } ],
 191         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 192                         { 'revision|r=i' => \$_revision
 193                         } ],
 194         'multi-fetch' => [ \&cmd_multi_fetch,
 195                            "Deprecated alias for $0 fetch --all",
 196                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 197         'migrate' => [ sub { },
 198                        # no-op, we automatically run this anyways,
 199                        'Migrate configuration/metadata/layout from
 200                         previous versions of git-svn',
 201                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 202                          %remote_opts } ],
 203         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 204                         { 'limit=i' => \$Git::SVN::Log::limit,
 205                           'revision|r=s' => \$_revision,
 206                           'verbose|v' => \$Git::SVN::Log::verbose,
 207                           'incremental' => \$Git::SVN::Log::incremental,
 208                           'oneline' => \$Git::SVN::Log::oneline,
 209                           'show-commit' => \$Git::SVN::Log::show_commit,
 210                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 211                           'authors-file|A=s' => \$_authors,
 212                           'color' => \$Git::SVN::Log::color,
 213                           'pager=s' => \$Git::SVN::Log::pager
 214                         } ],
 215         'find-rev' => [ \&cmd_find_rev,
 216                         "Translate between SVN revision numbers and tree-ish",
 217                         {} ],
 218         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 219                         { 'merge|m|M' => \$_merge,
 220                           'verbose|v' => \$_verbose,
 221                           'strategy|s=s' => \$_strategy,
 222                           'local|l' => \$_local,
 223                           'fetch-all|all' => \$_fetch_all,
 224                           'dry-run|n' => \$_dry_run,
 225                           %fc_opts } ],
 226         'commit-diff' => [ \&cmd_commit_diff,
 227                            'Commit a diff between two trees',
 228                         { 'message|m=s' => \$_message,
 229                           'file|F=s' => \$_file,
 230                           'revision|r=s' => \$_revision,
 231                         %cmt_opts } ],
 232         'info' => [ \&cmd_info,
 233                     "Show info about the latest SVN revision
 234                      on the current branch",
 235                     { 'url' => \$_url, } ],
 236         'blame' => [ \&Git::SVN::Log::cmd_blame,
 237                     "Show what revision and author last modified each line of a file",
 238                     { 'git-format' => \$_git_format } ],
 239         'reset' => [ \&cmd_reset,
 240                      "Undo fetches back to the specified SVN revision",
 241                      { 'revision|r=s' => \$_revision,
 242                        'parent|p' => \$_fetch_parent } ],
 243         'gc' => [ \&cmd_gc,
 244                   "Compress unhandled.log files in .git/svn and remove " .
 245                   "index files in .git/svn",
 246                 {} ],
 247 );
 248
 249 my $cmd;
 250 for (my $i = 0; $i < @ARGV; $i++) {
 251         if (defined $cmd{$ARGV[$i]}) {
 252                 $cmd = $ARGV[$i];
 253                 splice @ARGV, $i, 1;
 254                 last;
 255         } elsif ($ARGV[$i] eq 'help') {
 256                 $cmd = $ARGV[$i+1];
 257                 usage(0);
 258         }
 259 };
 260
 261 # make sure we're always running at the top-level working directory
 262 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 263         unless (-d $ENV{GIT_DIR}) {
 264                 if ($git_dir_user_set) {
 265                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 266                             "but it is not a directory\n";
 267                 }
 268                 my $git_dir = delete $ENV{GIT_DIR};
 269                 my $cdup = undef;
 270                 git_cmd_try {
 271                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 272                         $git_dir = '.' unless ($cdup);
 273                         chomp $cdup if ($cdup);
 274                         $cdup = "." unless ($cdup && length $cdup);
 275                 } "Already at toplevel, but $git_dir not found\n";
 276                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 277                 unless (-d $git_dir) {
 278                         die "$git_dir still not found after going to ",
 279                             "'$cdup'\n";
 280                 }
 281                 $ENV{GIT_DIR} = $git_dir;
 282         }
 283         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 284 }
 285
 286 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 287
 288 read_git_config(\%opts);
 289 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 290         Getopt::Long::Configure('pass_through');
 291 }
 292 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 293                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 294                     'id|i=s' => \$Git::SVN::default_ref_id,
 295                     'svn-remote|remote|R=s' => sub {
 296                        $Git::SVN::no_reuse_existing = 1;
 297                        $Git::SVN::default_repo_id = $_[1] });
 298 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 299
 300 usage(0) if $_help;
 301 version() if $_version;
 302 usage(1) unless defined $cmd;
 303 load_authors() if $_authors;
 304 if (defined $_authors_prog) {
 305         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 306 }
 307
 308 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 309         Git::SVN::Migration::migration_check();
 310 }
 311 Git::SVN::init_vars();
 312 eval {
 313         Git::SVN::verify_remotes_sanity();
 314         $cmd{$cmd}->[0]->(@ARGV);
 315 };
 316 fatal $@ if $@;
 317 post_fetch_checkout();
 318 exit 0;
 319
 320 ####################### primary functions ######################
 321 sub usage {
 322         my $exit = shift || 0;
 323         my $fd = $exit ? \*STDERR : \*STDOUT;
 324         print $fd <<"";
 325 git-svn - bidirectional operations between a single Subversion tree and git
 326 Usage: git svn <command> [options] [arguments]\n
 327
 328         print $fd "Available commands:\n" unless $cmd;
 329
 330         foreach (sort keys %cmd) {
 331                 next if $cmd && $cmd ne $_;
 332                 next if /^multi-/; # don't show deprecated commands
 333                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 334                 foreach (sort keys %{$cmd{$_}->[2]}) {
 335                         # mixed-case options are for .git/config only
 336                         next if /[A-Z]/ && /^[a-z]+$/i;
 337                         # prints out arguments as they should be passed:
 338                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 339                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 340                                                         "--$_" : "-$_" }
 341                                                 split /\|/,$_)," $x\n";
 342                 }
 343         }
 344         print $fd <<"";
 345 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 346 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 347 one git repository and want to keep them separate.  See git-svn(1) for more
 348 information.
 349
 350         exit $exit;
 351 }
 352
 353 sub version {
 354         ::_req_svn();
 355         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 356         exit 0;
 357 }
 358
 359 sub do_git_init_db {
 360         unless (-d $ENV{GIT_DIR}) {
 361                 my @init_db = ('init');
 362                 push @init_db, "--template=$_template" if defined $_template;
 363                 if (defined $_shared) {
 364                         if ($_shared =~ /[a-z]/) {
 365                                 push @init_db, "--shared=$_shared";
 366                         } else {
 367                                 push @init_db, "--shared";
 368                         }
 369                 }
 370                 command_noisy(@init_db);
 371                 $_repository = Git->repository(Repository => ".git");
 372         }
 373         my $set;
 374         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 375         foreach my $i (keys %icv) {
 376                 die "'$set' and '$i' cannot both be set\n" if $set;
 377                 next unless defined $icv{$i};
 378                 command_noisy('config', "$pfx.$i", $icv{$i});
 379                 $set = $i;
 380         }
 381         my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
 382         command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
 383                 if defined $$ignore_regex;
 384 }
 385
 386 sub init_subdir {
 387         my $repo_path = shift or return;
 388         mkpath([$repo_path]) unless -d $repo_path;
 389         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 390         $ENV{GIT_DIR} = '.git';
 391         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 392 }
 393
 394 sub cmd_clone {
 395         my ($url, $path) = @_;
 396         if (!defined $path &&
 397             (defined $_trunk || @_branches || @_tags ||
 398              defined $_stdlayout) &&
 399             $url !~ m#^[a-z\+]+://#) {
 400                 $path = $url;
 401         }
 402         $path = basename($url) if !defined $path || !length $path;
 403         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 404         cmd_init($url, $path);
 405         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 406             if $_authors;
 407         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 408 }
 409
 410 sub cmd_init {
 411         if (defined $_stdlayout) {
 412                 $_trunk = 'trunk' if (!defined $_trunk);
 413                 @_tags = 'tags' if (! @_tags);
 414                 @_branches = 'branches' if (! @_branches);
 415         }
 416         if (defined $_trunk || @_branches || @_tags) {
 417                 return cmd_multi_init(@_);
 418         }
 419         my $url = shift or die "SVN repository location required ",
 420                                "as a command-line argument\n";
 421         $url = canonicalize_url($url);
 422         init_subdir(@_);
 423         do_git_init_db();
 424
 425         if ($Git::SVN::_minimize_url eq 'unset') {
 426                 $Git::SVN::_minimize_url = 0;
 427         }
 428
 429         Git::SVN->init($url);
 430 }
 431
 432 sub cmd_fetch {
 433         if (grep /^\d+=./, @_) {
 434                 die "'<rev>=<commit>' fetch arguments are ",
 435                     "no longer supported.\n";
 436         }
 437         my ($remote) = @_;
 438         if (@_ > 1) {
 439                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 440         }
 441         $Git::SVN::no_reuse_existing = undef;
 442         if ($_fetch_parent) {
 443                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 444                 unless ($gs) {
 445                         die "Unable to determine upstream SVN information from ",
 446                             "working tree history\n";
 447                 }
 448                 # just fetch, don't checkout.
 449                 $_no_checkout = 'true';
 450                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 451         } elsif ($_fetch_all) {
 452                 cmd_multi_fetch();
 453         } else {
 454                 $remote ||= $Git::SVN::default_repo_id;
 455                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 456         }
 457 }
 458
 459 sub cmd_set_tree {
 460         my (@commits) = @_;
 461         if ($_stdin || !@commits) {
 462                 print "Reading from stdin...\n";
 463                 @commits = ();
 464                 while (<STDIN>) {
 465                         if (/\b($sha1_short)\b/o) {
 466                                 unshift @commits, $1;
 467                         }
 468                 }
 469         }
 470         my @revs;
 471         foreach my $c (@commits) {
 472                 my @tmp = command('rev-parse',$c);
 473                 if (scalar @tmp == 1) {
 474                         push @revs, $tmp[0];
 475                 } elsif (scalar @tmp > 1) {
 476                         push @revs, reverse(command('rev-list',@tmp));
 477                 } else {
 478                         fatal "Failed to rev-parse $c";
 479                 }
 480         }
 481         my $gs = Git::SVN->new;
 482         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 483         $gs->fetch;
 484         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 485                 fatal "There are new revisions that were fetched ",
 486                       "and need to be merged (or acknowledged) ",
 487                       "before committing.\nlast rev: $r_last\n",
 488                       " current: $gs->{last_rev}";
 489         }
 490         $gs->set_tree($_) foreach @revs;
 491         print "Done committing ",scalar @revs," revisions to SVN\n";
 492         unlink $gs->{index};
 493 }
 494
 495 sub cmd_dcommit {
 496         my $head = shift;
 497         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 498                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 499                 . "or stash them with `git stash'.\n";
 500         $head ||= 'HEAD';
 501
 502         my $old_head;
 503         if ($head ne 'HEAD') {
 504                 $old_head = eval {
 505                         command_oneline([qw/symbolic-ref -q HEAD/])
 506                 };
 507                 if ($old_head) {
 508                         $old_head =~ s{^refs/heads/}{};
 509                 } else {
 510                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 511                 }
 512                 command(['checkout', $head], STDERR => 0);
 513         }
 514
 515         my @refs;
 516         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 517         unless ($gs) {
 518                 die "Unable to determine upstream SVN information from ",
 519                     "$head history.\nPerhaps the repository is empty.";
 520         }
 521
 522         if (defined $_commit_url) {
 523                 $url = $_commit_url;
 524         } else {
 525                 $url = eval { command_oneline('config', '--get',
 526                               "svn-remote.$gs->{repo_id}.commiturl") };
 527                 if (!$url) {
 528                         $url = $gs->full_url
 529                 }
 530         }
 531
 532         my $last_rev = $_revision if defined $_revision;
 533         if ($url) {
 534                 print "Committing to $url ...\n";
 535         }
 536         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 537         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 538                 warn "Attempting to commit more than one change while ",
 539                      "--no-rebase is enabled.\n",
 540                      "If these changes depend on each other, re-running ",
 541                      "without --no-rebase may be required."
 542         }
 543         my $expect_url = $url;
 544         Git::SVN::remove_username($expect_url);
 545         while (1) {
 546                 my $d = shift @$linear_refs or last;
 547                 unless (defined $last_rev) {
 548                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 549                         unless (defined $last_rev) {
 550                                 fatal "Unable to extract revision information ",
 551                                       "from commit $d~1";
 552                         }
 553                 }
 554                 if ($_dry_run) {
 555                         print "diff-tree $d~1 $d\n";
 556                 } else {
 557                         my $cmt_rev;
 558                         my %ed_opts = ( r => $last_rev,
 559                                         log => get_commit_entry($d)->{log},
 560                                         ra => Git::SVN::Ra->new($url),
 561                                         config => SVN::Core::config_get_config(
 562                                                 $Git::SVN::Ra::config_dir
 563                                         ),
 564                                         tree_a => "$d~1",
 565                                         tree_b => $d,
 566                                         editor_cb => sub {
 567                                                print "Committed r$_[0]\n";
 568                                                $cmt_rev = $_[0];
 569                                         },
 570                                         svn_path => '');
 571                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 572                                 print "No changes\n$d~1 == $d\n";
 573                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 574                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 575                                                                $parents->{$d};
 576                         }
 577                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 578                         $last_rev = $cmt_rev;
 579                         next if $_no_rebase;
 580
 581                         # we always want to rebase against the current HEAD,
 582                         # not any head that was passed to us
 583                         my @diff = command('diff-tree', $d,
 584                                            $gs->refname, '--');
 585                         my @finish;
 586                         if (@diff) {
 587                                 @finish = rebase_cmd();
 588                                 print STDERR "W: $d and ", $gs->refname,
 589                                              " differ, using @finish:\n",
 590                                              join("\n", @diff), "\n";
 591                         } else {
 592                                 print "No changes between current HEAD and ",
 593                                       $gs->refname,
 594                                       "\nResetting to the latest ",
 595                                       $gs->refname, "\n";
 596                                 @finish = qw/reset --mixed/;
 597                         }
 598                         command_noisy(@finish, $gs->refname);
 599                         if (@diff) {
 600                                 @refs = ();
 601                                 my ($url_, $rev_, $uuid_, $gs_) =
 602                                               working_head_info('HEAD', \@refs);
 603                                 my ($linear_refs_, $parents_) =
 604                                               linearize_history($gs_, \@refs);
 605                                 if (scalar(@$linear_refs) !=
 606                                     scalar(@$linear_refs_)) {
 607                                         fatal "# of revisions changed ",
 608                                           "\nbefore:\n",
 609                                           join("\n", @$linear_refs),
 610                                           "\n\nafter:\n",
 611                                           join("\n", @$linear_refs_), "\n",
 612                                           'If you are attempting to commit ',
 613                                           "merges, try running:\n\t",
 614                                           'git rebase --interactive',
 615                                           '--preserve-merges ',
 616                                           $gs->refname,
 617                                           "\nBefore dcommitting";
 618                                 }
 619                                 if ($url_ ne $expect_url) {
 620                                         if ($url_ eq $gs->metadata_url) {
 621                                                 print
 622                                                   "Accepting rewritten URL:",
 623                                                   " $url_\n";
 624                                         } else {
 625                                                 fatal
 626                                                   "URL mismatch after rebase:",
 627                                                   " $url_ != $expect_url";
 628                                         }
 629                                 }
 630                                 if ($uuid_ ne $uuid) {
 631                                         fatal "uuid mismatch after rebase: ",
 632                                               "$uuid_ != $uuid";
 633                                 }
 634                                 # remap parents
 635                                 my (%p, @l, $i);
 636                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 637                                         my $new = $linear_refs_->[$i] or next;
 638                                         $p{$new} =
 639                                                 $parents->{$linear_refs->[$i]};
 640                                         push @l, $new;
 641                                 }
 642                                 $parents = \%p;
 643                                 $linear_refs = \@l;
 644                         }
 645                 }
 646         }
 647
 648         if ($old_head) {
 649                 my $new_head = command_oneline(qw/rev-parse HEAD/);
 650                 my $new_is_symbolic = eval {
 651                         command_oneline(qw/symbolic-ref -q HEAD/);
 652                 };
 653                 if ($new_is_symbolic) {
 654                         print "dcommitted the branch ", $head, "\n";
 655                 } else {
 656                         print "dcommitted on a detached HEAD because you gave ",
 657                               "a revision argument.\n",
 658                               "The rewritten commit is: ", $new_head, "\n";
 659                 }
 660                 command(['checkout', $old_head], STDERR => 0);
 661         }
 662
 663         unlink $gs->{index};
 664 }
 665
 666 sub cmd_branch {
 667         my ($branch_name, $head) = @_;
 668
 669         unless (defined $branch_name && length $branch_name) {
 670                 die(($_tag ? "tag" : "branch") . " name required\n");
 671         }
 672         $head ||= 'HEAD';
 673
 674         my (undef, $rev, undef, $gs) = working_head_info($head);
 675         my $src = $gs->full_url;
 676
 677         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 678         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
 679         my $glob;
 680         if ($#{$allglobs} == 0) {
 681                 $glob = $allglobs->[0];
 682         } else {
 683                 unless(defined $_branch_dest) {
 684                         die "Multiple ",
 685                             $_tag ? "tag" : "branch",
 686                             " paths defined for Subversion repository.\n",
 687                             "You must specify where you want to create the ",
 688                             $_tag ? "tag" : "branch",
 689                             " with the --destination argument.\n";
 690                 }
 691                 foreach my $g (@{$allglobs}) {
 692                         # SVN::Git::Editor could probably be moved to Git.pm..
 693                         my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
 694                         if ($_branch_dest =~ /$re/) {
 695                                 $glob = $g;
 696                                 last;
 697                         }
 698                 }
 699                 unless (defined $glob) {
 700                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
 701                         foreach my $g (@{$allglobs}) {
 702                                 $g->{path}->{left} =~ /$dest_re/ or next;
 703                                 if (defined $glob) {
 704                                         die "Ambiguous destination: ",
 705                                             $_branch_dest, "\nmatches both '",
 706                                             $glob->{path}->{left}, "' and '",
 707                                             $g->{path}->{left}, "'\n";
 708                                 }
 709                                 $glob = $g;
 710                         }
 711                         unless (defined $glob) {
 712                                 die "Unknown ",
 713                                     $_tag ? "tag" : "branch",
 714                                     " destination $_branch_dest\n";
 715                         }
 716                 }
 717         }
 718         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 719         my $url;
 720         if (defined $_commit_url) {
 721                 $url = $_commit_url;
 722         } else {
 723                 $url = eval { command_oneline('config', '--get',
 724                         "svn-remote.$gs->{repo_id}.commiturl") };
 725                 if (!$url) {
 726                         $url = $remote->{url};
 727                 }
 728         }
 729         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
 730
 731         if ($dst =~ /^https:/ && $src =~ /^http:/) {
 732                 $src=~s/^http:/https:/;
 733         }
 734
 735         ::_req_svn();
 736
 737         my $ctx = SVN::Client->new(
 738                 auth    => Git::SVN::Ra::_auth_providers(),
 739                 log_msg => sub {
 740                         ${ $_[0] } = defined $_message
 741                                 ? $_message
 742                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 743                                 . $branch_name;
 744                 },
 745         );
 746
 747         eval {
 748                 $ctx->ls($dst, 'HEAD', 0);
 749         } and die "branch ${branch_name} already exists\n";
 750
 751         print "Copying ${src} at r${rev} to ${dst}...\n";
 752         $ctx->copy($src, $rev, $dst)
 753                 unless $_dry_run;
 754
 755         $gs->fetch_all;
 756 }
 757
 758 sub cmd_find_rev {
 759         my $revision_or_hash = shift or die "SVN or git revision required ",
 760                                             "as a command-line argument\n";
 761         my $result;
 762         if ($revision_or_hash =~ /^r\d+$/) {
 763                 my $head = shift;
 764                 $head ||= 'HEAD';
 765                 my @refs;
 766                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 767                 unless ($gs) {
 768                         die "Unable to determine upstream SVN information from ",
 769                             "$head history\n";
 770                 }
 771                 my $desired_revision = substr($revision_or_hash, 1);
 772                 $result = $gs->rev_map_get($desired_revision, $uuid);
 773         } else {
 774                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 775                 $result = $rev;
 776         }
 777         print "$result\n" if $result;
 778 }
 779
 780 sub cmd_rebase {
 781         command_noisy(qw/update-index --refresh/);
 782         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 783         unless ($gs) {
 784                 die "Unable to determine upstream SVN information from ",
 785                     "working tree history\n";
 786         }
 787         if ($_dry_run) {
 788                 print "Remote Branch: " . $gs->refname . "\n";
 789                 print "SVN URL: " . $url . "\n";
 790                 return;
 791         }
 792         if (command(qw/diff-index HEAD --/)) {
 793                 print STDERR "Cannot rebase with uncommited changes:\n";
 794                 command_noisy('status');
 795                 exit 1;
 796         }
 797         unless ($_local) {
 798                 # rebase will checkout for us, so no need to do it explicitly
 799                 $_no_checkout = 'true';
 800                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 801         }
 802         command_noisy(rebase_cmd(), $gs->refname);
 803         $gs->mkemptydirs;
 804 }
 805
 806 sub cmd_show_ignore {
 807         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 808         $gs ||= Git::SVN->new;
 809         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 810         $gs->prop_walk($gs->{path}, $r, sub {
 811                 my ($gs, $path, $props) = @_;
 812                 print STDOUT "\n# $path\n";
 813                 my $s = $props->{'svn:ignore'} or return;
 814                 $s =~ s/[\r\n]+/\n/g;
 815                 $s =~ s/^\n+//;
 816                 chomp $s;
 817                 $s =~ s#^#$path#gm;
 818                 print STDOUT "$s\n";
 819         });
 820 }
 821
 822 sub cmd_show_externals {
 823         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 824         $gs ||= Git::SVN->new;
 825         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 826         $gs->prop_walk($gs->{path}, $r, sub {
 827                 my ($gs, $path, $props) = @_;
 828                 print STDOUT "\n# $path\n";
 829                 my $s = $props->{'svn:externals'} or return;
 830                 $s =~ s/[\r\n]+/\n/g;
 831                 chomp $s;
 832                 $s =~ s#^#$path#gm;
 833                 print STDOUT "$s\n";
 834         });
 835 }
 836
 837 sub cmd_create_ignore {
 838         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 839         $gs ||= Git::SVN->new;
 840         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 841         $gs->prop_walk($gs->{path}, $r, sub {
 842                 my ($gs, $path, $props) = @_;
 843                 # $path is of the form /path/to/dir/
 844                 $path = '.' . $path;
 845                 # SVN can have attributes on empty directories,
 846                 # which git won't track
 847                 mkpath([$path]) unless -d $path;
 848                 my $ignore = $path . '.gitignore';
 849                 my $s = $props->{'svn:ignore'} or return;
 850                 open(GITIGNORE, '>', $ignore)
 851                   or fatal("Failed to open `$ignore' for writing: $!");
 852                 $s =~ s/[\r\n]+/\n/g;
 853                 $s =~ s/^\n+//;
 854                 chomp $s;
 855                 # Prefix all patterns so that the ignore doesn't apply
 856                 # to sub-directories.
 857                 $s =~ s#^#/#gm;
 858                 print GITIGNORE "$s\n";
 859                 close(GITIGNORE)
 860                   or fatal("Failed to close `$ignore': $!");
 861                 command_noisy('add', '-f', $ignore);
 862         });
 863 }
 864
 865 sub cmd_mkdirs {
 866         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 867         $gs ||= Git::SVN->new;
 868         $gs->mkemptydirs($_revision);
 869 }
 870
 871 sub canonicalize_path {
 872         my ($path) = @_;
 873         my $dot_slash_added = 0;
 874         if (substr($path, 0, 1) ne "/") {
 875                 $path = "./" . $path;
 876                 $dot_slash_added = 1;
 877         }
 878         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 879         # good reason), so let's do this manually.
 880         $path =~ s#/+#/#g;
 881         $path =~ s#/\.(?:/|$)#/#g;
 882         $path =~ s#/[^/]+/\.\.##g;
 883         $path =~ s#/$##g;
 884         $path =~ s#^\./## if $dot_slash_added;
 885         $path =~ s#^/##;
 886         $path =~ s#^\.$##;
 887         return $path;
 888 }
 889
 890 sub canonicalize_url {
 891         my ($url) = @_;
 892         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 893         return $url;
 894 }
 895
 896 # get_svnprops(PATH)
 897 # ------------------
 898 # Helper for cmd_propget and cmd_proplist below.
 899 sub get_svnprops {
 900         my $path = shift;
 901         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 902         $gs ||= Git::SVN->new;
 903
 904         # prefix THE PATH by the sub-directory from which the user
 905         # invoked us.
 906         $path = $cmd_dir_prefix . $path;
 907         fatal("No such file or directory: $path") unless -e $path;
 908         my $is_dir = -d $path ? 1 : 0;
 909         $path = $gs->{path} . '/' . $path;
 910
 911         # canonicalize the path (otherwise libsvn will abort or fail to
 912         # find the file)
 913         $path = canonicalize_path($path);
 914
 915         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 916         my $props;
 917         if ($is_dir) {
 918                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 919         }
 920         else {
 921                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 922         }
 923         return $props;
 924 }
 925
 926 # cmd_propget (PROP, PATH)
 927 # ------------------------
 928 # Print the SVN property PROP for PATH.
 929 sub cmd_propget {
 930         my ($prop, $path) = @_;
 931         $path = '.' if not defined $path;
 932         usage(1) if not defined $prop;
 933         my $props = get_svnprops($path);
 934         if (not defined $props->{$prop}) {
 935                 fatal("`$path' does not have a `$prop' SVN property.");
 936         }
 937         print $props->{$prop} . "\n";
 938 }
 939
 940 # cmd_proplist (PATH)
 941 # -------------------
 942 # Print the list of SVN properties for PATH.
 943 sub cmd_proplist {
 944         my $path = shift;
 945         $path = '.' if not defined $path;
 946         my $props = get_svnprops($path);
 947         print "Properties on '$path':\n";
 948         foreach (sort keys %{$props}) {
 949                 print "  $_\n";
 950         }
 951 }
 952
 953 sub cmd_multi_init {
 954         my $url = shift;
 955         unless (defined $_trunk || @_branches || @_tags) {
 956                 usage(1);
 957         }
 958
 959         $_prefix = '' unless defined $_prefix;
 960         if (defined $url) {
 961                 $url = canonicalize_url($url);
 962                 init_subdir(@_);
 963         }
 964         do_git_init_db();
 965         if (defined $_trunk) {
 966                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
 967                 # try both old-style and new-style lookups:
 968                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 969                 unless ($gs_trunk) {
 970                         my ($trunk_url, $trunk_path) =
 971                                               complete_svn_url($url, $_trunk);
 972                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 973                                                    undef, $trunk_ref);
 974                 }
 975         }
 976         return unless @_branches || @_tags;
 977         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 978         foreach my $path (@_branches) {
 979                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
 980         }
 981         foreach my $path (@_tags) {
 982                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
 983         }
 984 }
 985
 986 sub cmd_multi_fetch {
 987         $Git::SVN::no_reuse_existing = undef;
 988         my $remotes = Git::SVN::read_all_remotes();
 989         foreach my $repo_id (sort keys %$remotes) {
 990                 if ($remotes->{$repo_id}->{url}) {
 991                         Git::SVN::fetch_all($repo_id, $remotes);
 992                 }
 993         }
 994 }
 995
 996 # this command is special because it requires no metadata
 997 sub cmd_commit_diff {
 998         my ($ta, $tb, $url) = @_;
 999         my $usage = "Usage: $0 commit-diff -r<revision> ".
1000                     "<tree-ish> <tree-ish> [<URL>]";
1001         fatal($usage) if (!defined $ta || !defined $tb);
1002         my $svn_path = '';
1003         if (!defined $url) {
1004                 my $gs = eval { Git::SVN->new };
1005                 if (!$gs) {
1006                         fatal("Needed URL or usable git-svn --id in ",
1007                               "the command-line\n", $usage);
1008                 }
1009                 $url = $gs->{url};
1010                 $svn_path = $gs->{path};
1011         }
1012         unless (defined $_revision) {
1013                 fatal("-r|--revision is a required argument\n", $usage);
1014         }
1015         if (defined $_message && defined $_file) {
1016                 fatal("Both --message/-m and --file/-F specified ",
1017                       "for the commit message.\n",
1018                       "I have no idea what you mean");
1019         }
1020         if (defined $_file) {
1021                 $_message = file_to_s($_file);
1022         } else {
1023                 $_message ||= get_commit_entry($tb)->{log};
1024         }
1025         my $ra ||= Git::SVN::Ra->new($url);
1026         my $r = $_revision;
1027         if ($r eq 'HEAD') {
1028                 $r = $ra->get_latest_revnum;
1029         } elsif ($r !~ /^\d+$/) {
1030                 die "revision argument: $r not understood by git-svn\n";
1031         }
1032         my %ed_opts = ( r => $r,
1033                         log => $_message,
1034                         ra => $ra,
1035                         tree_a => $ta,
1036                         tree_b => $tb,
1037                         editor_cb => sub { print "Committed r$_[0]\n" },
1038                         svn_path => $svn_path );
1039         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1040                 print "No changes\n$ta == $tb\n";
1041         }
1042 }
1043
1044 sub escape_uri_only {
1045         my ($uri) = @_;
1046         my @tmp;
1047         foreach (split m{/}, $uri) {
1048                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1049                 push @tmp, $_;
1050         }
1051         join('/', @tmp);
1052 }
1053
1054 sub escape_url {
1055         my ($url) = @_;
1056         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1057                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1058                 $url = "$scheme://$domain$uri";
1059         }
1060         $url;
1061 }
1062
1063 sub cmd_info {
1064         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1065         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1066         if (exists $_[1]) {
1067                 die "Too many arguments specified\n";
1068         }
1069
1070         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1071
1072         if (!$file_type && !$diff_status) {
1073                 print STDERR "svn: '$path' is not under version control\n";
1074                 exit 1;
1075         }
1076
1077         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1078         unless ($gs) {
1079                 die "Unable to determine upstream SVN information from ",
1080                     "working tree history\n";
1081         }
1082
1083         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1084         $path = "." if $path eq "";
1085
1086         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1087
1088         if ($_url) {
1089                 print escape_url($full_url), "\n";
1090                 return;
1091         }
1092
1093         my $result = "Path: $path\n";
1094         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1095         $result .= "URL: " . escape_url($full_url) . "\n";
1096
1097         eval {
1098                 my $repos_root = $gs->repos_root;
1099                 Git::SVN::remove_username($repos_root);
1100                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1101         };
1102         if ($@) {
1103                 $result .= "Repository Root: (offline)\n";
1104         }
1105         ::_req_svn();
1106         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1107                 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1108         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1109
1110         $result .= "Node Kind: " .
1111                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1112
1113         my $schedule = $diff_status eq "A"
1114                        ? "add"
1115                        : ($diff_status eq "D" ? "delete" : "normal");
1116         $result .= "Schedule: $schedule\n";
1117
1118         if ($diff_status eq "A") {
1119                 print $result, "\n";
1120                 return;
1121         }
1122
1123         my ($lc_author, $lc_rev, $lc_date_utc);
1124         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1125         my $log = command_output_pipe(@args);
1126         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1127         while (<$log>) {
1128                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1129                         $lc_author = $1;
1130                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1131                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1132                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1133                 }
1134         }
1135         close $log;
1136
1137         Git::SVN::Log::set_local_timezone();
1138
1139         $result .= "Last Changed Author: $lc_author\n";
1140         $result .= "Last Changed Rev: $lc_rev\n";
1141         $result .= "Last Changed Date: " .
1142                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1143
1144         if ($file_type ne "dir") {
1145                 my $text_last_updated_date =
1146                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1147                 $result .=
1148                     "Text Last Updated: " .
1149                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1150                     "\n";
1151                 my $checksum;
1152                 if ($diff_status eq "D") {
1153                         my ($fh, $ctx) =
1154                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1155                         if ($file_type eq "link") {
1156                                 my $file_name = <$fh>;
1157                                 $checksum = md5sum("link $file_name");
1158                         } else {
1159                                 $checksum = md5sum($fh);
1160                         }
1161                         command_close_pipe($fh, $ctx);
1162                 } elsif ($file_type eq "link") {
1163                         my $file_name =
1164                             command(qw(cat-file blob), "HEAD:$path");
1165                         $checksum =
1166                             md5sum("link " . $file_name);
1167                 } else {
1168                         open FILE, "<", $path or die $!;
1169                         $checksum = md5sum(\*FILE);
1170                         close FILE or die $!;
1171                 }
1172                 $result .= "Checksum: " . $checksum . "\n";
1173         }
1174
1175         print $result, "\n";
1176 }
1177
1178 sub cmd_reset {
1179         my $target = shift || $_revision or die "SVN revision required\n";
1180         $target = $1 if $target =~ /^r(\d+)$/;
1181         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1182         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1183         unless ($gs) {
1184                 die "Unable to determine upstream SVN information from ".
1185                     "history\n";
1186         }
1187         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1188         die "Cannot find SVN revision $target\n" unless defined($c);
1189         $gs->rev_map_set($r, $c, 'reset', $uuid);
1190         print "r$r = $c ($gs->{ref_id})\n";
1191 }
1192
1193 sub cmd_gc {
1194         if (!$can_compress) {
1195                 warn "Compress::Zlib could not be found; unhandled.log " .
1196                      "files will not be compressed.\n";
1197         }
1198         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1199 }
1200
1201 ########################### utility functions #########################
1202
1203 sub rebase_cmd {
1204         my @cmd = qw/rebase/;
1205         push @cmd, '-v' if $_verbose;
1206         push @cmd, qw/--merge/ if $_merge;
1207         push @cmd, "--strategy=$_strategy" if $_strategy;
1208         @cmd;
1209 }
1210
1211 sub post_fetch_checkout {
1212         return if $_no_checkout;
1213         my $gs = $Git::SVN::_head or return;
1214         return if verify_ref('refs/heads/master^0');
1215
1216         # look for "trunk" ref if it exists
1217         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1218         my $fetch = $remote->{fetch};
1219         if ($fetch) {
1220                 foreach my $p (keys %$fetch) {
1221                         basename($fetch->{$p}) eq 'trunk' or next;
1222                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1223                         last;
1224                 }
1225         }
1226
1227         my $valid_head = verify_ref('HEAD^0');
1228         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1229         return if ($valid_head || !verify_ref('HEAD^0'));
1230
1231         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1232         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1233         return if -f $index;
1234
1235         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1236         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1237         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1238         print STDERR "Checked out HEAD:\n  ",
1239                      $gs->full_url, " r", $gs->last_rev, "\n";
1240         $gs->mkemptydirs($gs->last_rev);
1241 }
1242
1243 sub complete_svn_url {
1244         my ($url, $path) = @_;
1245         $path =~ s#/+$##;
1246         if ($path !~ m#^[a-z\+]+://#) {
1247                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1248                         fatal("E: '$path' is not a complete URL ",
1249                               "and a separate URL is not specified");
1250                 }
1251                 return ($url, $path);
1252         }
1253         return ($path, '');
1254 }
1255
1256 sub complete_url_ls_init {
1257         my ($ra, $repo_path, $switch, $pfx) = @_;
1258         unless ($repo_path) {
1259                 print STDERR "W: $switch not specified\n";
1260                 return;
1261         }
1262         $repo_path =~ s#/+$##;
1263         if ($repo_path =~ m#^[a-z\+]+://#) {
1264                 $ra = Git::SVN::Ra->new($repo_path);
1265                 $repo_path = '';
1266         } else {
1267                 $repo_path =~ s#^/+##;
1268                 unless ($ra) {
1269                         fatal("E: '$repo_path' is not a complete URL ",
1270                               "and a separate URL is not specified");
1271                 }
1272         }
1273         my $url = $ra->{url};
1274         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1275         my $k = "svn-remote.$gs->{repo_id}.url";
1276         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1277         if ($orig_url && ($orig_url ne $gs->{url})) {
1278                 die "$k already set: $orig_url\n",
1279                     "wanted to set to: $gs->{url}\n";
1280         }
1281         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1282         my $remote_path = "$gs->{path}/$repo_path";
1283         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1284         $remote_path =~ s#/+#/#g;
1285         $remote_path =~ s#^/##g;
1286         $remote_path .= "/*" if $remote_path !~ /\*/;
1287         my ($n) = ($switch =~ /^--(\w+)/);
1288         if (length $pfx && $pfx !~ m#/$#) {
1289                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1290         }
1291         command_noisy('config',
1292                       '--add',
1293                       "svn-remote.$gs->{repo_id}.$n",
1294                       "$remote_path:refs/remotes/$pfx*" .
1295                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1296 }
1297
1298 sub verify_ref {
1299         my ($ref) = @_;
1300         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1301                                { STDERR => 0 }); };
1302 }
1303
1304 sub get_tree_from_treeish {
1305         my ($treeish) = @_;
1306         # $treeish can be a symbolic ref, too:
1307         my $type = command_oneline(qw/cat-file -t/, $treeish);
1308         my $expected;
1309         while ($type eq 'tag') {
1310                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1311         }
1312         if ($type eq 'commit') {
1313                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1314                                                     $treeish))[0];
1315                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1316                 die "Unable to get tree from $treeish\n" unless $expected;
1317         } elsif ($type eq 'tree') {
1318                 $expected = $treeish;
1319         } else {
1320                 die "$treeish is a $type, expected tree, tag or commit\n";
1321         }
1322         return $expected;
1323 }
1324
1325 sub get_commit_entry {
1326         my ($treeish) = shift;
1327         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1328         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1329         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1330         open my $log_fh, '>', $commit_editmsg or croak $!;
1331
1332         my $type = command_oneline(qw/cat-file -t/, $treeish);
1333         if ($type eq 'commit' || $type eq 'tag') {
1334                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1335                                                          $type, $treeish);
1336                 my $in_msg = 0;
1337                 my $author;
1338                 my $saw_from = 0;
1339                 my $msgbuf = "";
1340                 while (<$msg_fh>) {
1341                         if (!$in_msg) {
1342                                 $in_msg = 1 if (/^\s*$/);
1343                                 $author = $1 if (/^author (.*>)/);
1344                         } elsif (/^git-svn-id: /) {
1345                                 # skip this for now, we regenerate the
1346                                 # correct one on re-fetch anyways
1347                                 # TODO: set *:merge properties or like...
1348                         } else {
1349                                 if (/^From:/ || /^Signed-off-by:/) {
1350                                         $saw_from = 1;
1351                                 }
1352                                 $msgbuf .= $_;
1353                         }
1354                 }
1355                 $msgbuf =~ s/\s+$//s;
1356                 if ($Git::SVN::_add_author_from && defined($author)
1357                     && !$saw_from) {
1358                         $msgbuf .= "\n\nFrom: $author";
1359                 }
1360                 print $log_fh $msgbuf or croak $!;
1361                 command_close_pipe($msg_fh, $ctx);
1362         }
1363         close $log_fh or croak $!;
1364
1365         if ($_edit || ($type eq 'tree')) {
1366                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1367                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1368         }
1369         rename $commit_editmsg, $commit_msg or croak $!;
1370         {
1371                 require Encode;
1372                 # SVN requires messages to be UTF-8 when entering the repo
1373                 local $/;
1374                 open $log_fh, '<', $commit_msg or croak $!;
1375                 binmode $log_fh;
1376                 chomp($log_entry{log} = <$log_fh>);
1377
1378                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1379                 my $msg = $log_entry{log};
1380
1381                 eval { $msg = Encode::decode($enc, $msg, 1) };
1382                 if ($@) {
1383                         die "Could not decode as $enc:\n", $msg,
1384                             "\nPerhaps you need to set i18n.commitencoding\n";
1385                 }
1386
1387                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1388                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1389
1390                 $log_entry{log} = $msg;
1391
1392                 close $log_fh or croak $!;
1393         }
1394         unlink $commit_msg;
1395         \%log_entry;
1396 }
1397
1398 sub s_to_file {
1399         my ($str, $file, $mode) = @_;
1400         open my $fd,'>',$file or croak $!;
1401         print $fd $str,"\n" or croak $!;
1402         close $fd or croak $!;
1403         chmod ($mode &~ umask, $file) if (defined $mode);
1404 }
1405
1406 sub file_to_s {
1407         my $file = shift;
1408         open my $fd,'<',$file or croak "$!: file: $file\n";
1409         local $/;
1410         my $ret = <$fd>;
1411         close $fd or croak $!;
1412         $ret =~ s/\s*$//s;
1413         return $ret;
1414 }
1415
1416 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1417 sub load_authors {
1418         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1419         my $log = $cmd eq 'log';
1420         while (<$authors>) {
1421                 chomp;
1422                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1423                 my ($user, $name, $email) = ($1, $2, $3);
1424                 if ($log) {
1425                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1426                 } else {
1427                         $users{$user} = [$name, $email];
1428                 }
1429         }
1430         close $authors or croak $!;
1431 }
1432
1433 # convert GetOpt::Long specs for use by git-config
1434 sub read_git_config {
1435         my $opts = shift;
1436         my @config_only;
1437         foreach my $o (keys %$opts) {
1438                 # if we have mixedCase and a long option-only, then
1439                 # it's a config-only variable that we don't need for
1440                 # the command-line.
1441                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1442                 my $v = $opts->{$o};
1443                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1444                 $key =~ s/-//g;
1445                 my $arg = 'git config';
1446                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1447                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1448                 if (ref $v eq 'ARRAY') {
1449                         chomp(my @tmp = `$arg --get-all svn.$key`);
1450                         @$v = @tmp if @tmp;
1451                 } else {
1452                         chomp(my $tmp = `$arg --get svn.$key`);
1453                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1454                                 $$v = $tmp;
1455                         }
1456                 }
1457         }
1458         delete @$opts{@config_only} if @config_only;
1459 }
1460
1461 sub extract_metadata {
1462         my $id = shift or return (undef, undef, undef);
1463         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1464                                                         \s([a-f\d\-]+)$/ix);
1465         if (!defined $rev || !$uuid || !$url) {
1466                 # some of the original repositories I made had
1467                 # identifiers like this:
1468                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1469         }
1470         return ($url, $rev, $uuid);
1471 }
1472
1473 sub cmt_metadata {
1474         return extract_metadata((grep(/^git-svn-id: /,
1475                 command(qw/cat-file commit/, shift)))[-1]);
1476 }
1477
1478 sub cmt_sha2rev_batch {
1479         my %s2r;
1480         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1481         my $list = shift;
1482
1483         foreach my $sha (@{$list}) {
1484                 my $first = 1;
1485                 my $size = 0;
1486                 print $out $sha, "\n";
1487
1488                 while (my $line = <$in>) {
1489                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1490                                 last;
1491                         } elsif ($first &&
1492                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1493                                 $first = 0;
1494                                 $size = $1;
1495                                 next;
1496                         } elsif ($line =~ /^(git-svn-id: )/) {
1497                                 my (undef, $rev, undef) =
1498                                                       extract_metadata($line);
1499                                 $s2r{$sha} = $rev;
1500                         }
1501
1502                         $size -= length($line);
1503                         last if ($size == 0);
1504                 }
1505         }
1506
1507         command_close_bidi_pipe($pid, $in, $out, $ctx);
1508
1509         return \%s2r;
1510 }
1511
1512 sub working_head_info {
1513         my ($head, $refs) = @_;
1514         my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1515         my ($fh, $ctx) = command_output_pipe(@args, $head);
1516         my $hash;
1517         my %max;
1518         while (<$fh>) {
1519                 if ( m{^commit ($::sha1)$} ) {
1520                         unshift @$refs, $hash if $hash and $refs;
1521                         $hash = $1;
1522                         next;
1523                 }
1524                 next unless s{^\s*(git-svn-id:)}{$1};
1525                 my ($url, $rev, $uuid) = extract_metadata($_);
1526                 if (defined $url && defined $rev) {
1527                         next if $max{$url} and $max{$url} < $rev;
1528                         if (my $gs = Git::SVN->find_by_url($url)) {
1529                                 my $c = $gs->rev_map_get($rev, $uuid);
1530                                 if ($c && $c eq $hash) {
1531                                         close $fh; # break the pipe
1532                                         return ($url, $rev, $uuid, $gs);
1533                                 } else {
1534                                         $max{$url} ||= $gs->rev_map_max;
1535                                 }
1536                         }
1537                 }
1538         }
1539         command_close_pipe($fh, $ctx);
1540         (undef, undef, undef, undef);
1541 }
1542
1543 sub read_commit_parents {
1544         my ($parents, $c) = @_;
1545         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1546         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1547         @{$parents->{$c}} = split(/ /, $p);
1548 }
1549
1550 sub linearize_history {
1551         my ($gs, $refs) = @_;
1552         my %parents;
1553         foreach my $c (@$refs) {
1554                 read_commit_parents(\%parents, $c);
1555         }
1556
1557         my @linear_refs;
1558         my %skip = ();
1559         my $last_svn_commit = $gs->last_commit;
1560         foreach my $c (reverse @$refs) {
1561                 next if $c eq $last_svn_commit;
1562                 last if $skip{$c};
1563
1564                 unshift @linear_refs, $c;
1565                 $skip{$c} = 1;
1566
1567                 # we only want the first parent to diff against for linear
1568                 # history, we save the rest to inject when we finalize the
1569                 # svn commit
1570                 my $fp_a = verify_ref("$c~1");
1571                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1572                 if (!$fp_a || !$fp_b) {
1573                         die "Commit $c\n",
1574                             "has no parent commit, and therefore ",
1575                             "nothing to diff against.\n",
1576                             "You should be working from a repository ",
1577                             "originally created by git-svn\n";
1578                 }
1579                 if ($fp_a ne $fp_b) {
1580                         die "$c~1 = $fp_a, however parsing commit $c ",
1581                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1582                 }
1583
1584                 foreach my $p (@{$parents{$c}}) {
1585                         $skip{$p} = 1;
1586                 }
1587         }
1588         (\@linear_refs, \%parents);
1589 }
1590
1591 sub find_file_type_and_diff_status {
1592         my ($path) = @_;
1593         return ('dir', '') if $path eq '';
1594
1595         my $diff_output =
1596             command_oneline(qw(diff --cached --name-status --), $path) || "";
1597         my $diff_status = (split(' ', $diff_output))[0] || "";
1598
1599         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1600
1601         return (undef, undef) if !$diff_status && !$ls_tree;
1602
1603         if ($diff_status eq "A") {
1604                 return ("link", $diff_status) if -l $path;
1605                 return ("dir", $diff_status) if -d $path;
1606                 return ("file", $diff_status);
1607         }
1608
1609         my $mode = (split(' ', $ls_tree))[0] || "";
1610
1611         return ("link", $diff_status) if $mode eq "120000";
1612         return ("dir", $diff_status) if $mode eq "040000";
1613         return ("file", $diff_status);
1614 }
1615
1616 sub md5sum {
1617         my $arg = shift;
1618         my $ref = ref $arg;
1619         my $md5 = Digest::MD5->new();
1620         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1621                 $md5->addfile($arg) or croak $!;
1622         } elsif ($ref eq 'SCALAR') {
1623                 $md5->add($$arg) or croak $!;
1624         } elsif (!$ref) {
1625                 $md5->add($arg) or croak $!;
1626         } else {
1627                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1628         }
1629         return $md5->hexdigest();
1630 }
1631
1632 sub gc_directory {
1633         if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1634                 my $out_filename = $_ . ".gz";
1635                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1636                 binmode $in_fh;
1637                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1638                                 die "Unable to open $out_filename: $!\n";
1639
1640                 my $res;
1641                 while ($res = sysread($in_fh, my $str, 1024)) {
1642                         $gz->gzwrite($str) or
1643                                 die "Unable to write: ".$gz->gzerror()."!\n";
1644                 }
1645                 unlink $_ or die "unlink $File::Find::name: $!\n";
1646         } elsif (-f $_ && basename($_) eq "index") {
1647                 unlink $_ or die "unlink $_: $!\n";
1648         }
1649 }
1650
1651 package Git::SVN;
1652 use strict;
1653 use warnings;
1654 use Fcntl qw/:DEFAULT :seek/;
1655 use constant rev_map_fmt => 'NH40';
1656 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1657             $_repack $_repack_flags $_use_svm_props $_head
1658             $_use_svnsync_props $no_reuse_existing $_minimize_url
1659             $_use_log_author $_add_author_from $_localtime/;
1660 use Carp qw/croak/;
1661 use File::Path qw/mkpath/;
1662 use File::Copy qw/copy/;
1663 use IPC::Open3;
1664 use Memoize;  # core since 5.8.0, Jul 2002
1665 use Memoize::Storable;
1666
1667 my ($_gc_nr, $_gc_period);
1668
1669 # properties that we do not log:
1670 my %SKIP_PROP;
1671 BEGIN {
1672         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1673                                         svn:special svn:executable
1674                                         svn:entry:committed-rev
1675                                         svn:entry:last-author
1676                                         svn:entry:uuid
1677                                         svn:entry:committed-date/;
1678
1679         # some options are read globally, but can be overridden locally
1680         # per [svn-remote "..."] section.  Command-line options will *NOT*
1681         # override options set in an [svn-remote "..."] section
1682         no strict 'refs';
1683         for my $option (qw/follow_parent no_metadata use_svm_props
1684                            use_svnsync_props/) {
1685                 my $key = $option;
1686                 $key =~ tr/_//d;
1687                 my $prop = "-$option";
1688                 *$option = sub {
1689                         my ($self) = @_;
1690                         return $self->{$prop} if exists $self->{$prop};
1691                         my $k = "svn-remote.$self->{repo_id}.$key";
1692                         eval { command_oneline(qw/config --get/, $k) };
1693                         if ($@) {
1694                                 $self->{$prop} = ${"Git::SVN::_$option"};
1695                         } else {
1696                                 my $v = command_oneline(qw/config --bool/,$k);
1697                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1698                         }
1699                         return $self->{$prop};
1700                 }
1701         }
1702 }
1703
1704
1705 my (%LOCKFILES, %INDEX_FILES);
1706 END {
1707         unlink keys %LOCKFILES if %LOCKFILES;
1708         unlink keys %INDEX_FILES if %INDEX_FILES;
1709 }
1710
1711 sub resolve_local_globs {
1712         my ($url, $fetch, $glob_spec) = @_;
1713         return unless defined $glob_spec;
1714         my $ref = $glob_spec->{ref};
1715         my $path = $glob_spec->{path};
1716         foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
1717                 next unless m#^$ref->{regex}$#;
1718                 my $p = $1;
1719                 my $pathname = desanitize_refname($path->full_path($p));
1720                 my $refname = desanitize_refname($ref->full_path($p));
1721                 if (my $existing = $fetch->{$pathname}) {
1722                         if ($existing ne $refname) {
1723                                 die "Refspec conflict:\n",
1724                                     "existing: $existing\n",
1725                                     " globbed: $refname\n";
1726                         }
1727                         my $u = (::cmt_metadata("$refname"))[0];
1728                         $u =~ s!^\Q$url\E(/|$)!! or die
1729                           "$refname: '$url' not found in '$u'\n";
1730                         if ($pathname ne $u) {
1731                                 warn "W: Refspec glob conflict ",
1732                                      "(ref: $refname):\n",
1733                                      "expected path: $pathname\n",
1734                                      "    real path: $u\n",
1735                                      "Continuing ahead with $u\n";
1736                                 next;
1737                         }
1738                 } else {
1739                         $fetch->{$pathname} = $refname;
1740                 }
1741         }
1742 }
1743
1744 sub parse_revision_argument {
1745         my ($base, $head) = @_;
1746         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1747                 return ($base, $head);
1748         }
1749         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1750         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1751         return ($head, $head) if ($::_revision eq 'HEAD');
1752         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1753         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1754         die "revision argument: $::_revision not understood by git-svn\n";
1755 }
1756
1757 sub fetch_all {
1758         my ($repo_id, $remotes) = @_;
1759         if (ref $repo_id) {
1760                 my $gs = $repo_id;
1761                 $repo_id = undef;
1762                 $repo_id = $gs->{repo_id};
1763         }
1764         $remotes ||= read_all_remotes();
1765         my $remote = $remotes->{$repo_id} or
1766                      die "[svn-remote \"$repo_id\"] unknown\n";
1767         my $fetch = $remote->{fetch};
1768         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1769         my (@gs, @globs);
1770         my $ra = Git::SVN::Ra->new($url);
1771         my $uuid = $ra->get_uuid;
1772         my $head = $ra->get_latest_revnum;
1773
1774         # ignore errors, $head revision may not even exist anymore
1775         eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
1776         warn "W: $@\n" if $@;
1777
1778         my $base = defined $fetch ? $head : 0;
1779
1780         # read the max revs for wildcard expansion (branches/*, tags/*)
1781         foreach my $t (qw/branches tags/) {
1782                 defined $remote->{$t} or next;
1783                 push @globs, @{$remote->{$t}};
1784
1785                 my $max_rev = eval { tmp_config(qw/--int --get/,
1786                                          "svn-remote.$repo_id.${t}-maxRev") };
1787                 if (defined $max_rev && ($max_rev < $base)) {
1788                         $base = $max_rev;
1789                 } elsif (!defined $max_rev) {
1790                         $base = 0;
1791                 }
1792         }
1793
1794         if ($fetch) {
1795                 foreach my $p (sort keys %$fetch) {
1796                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1797                         my $lr = $gs->rev_map_max;
1798                         if (defined $lr) {
1799                                 $base = $lr if ($lr < $base);
1800                         }
1801                         push @gs, $gs;
1802                 }
1803         }
1804
1805         ($base, $head) = parse_revision_argument($base, $head);
1806         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1807 }
1808
1809 sub read_all_remotes {
1810         my $r = {};
1811         my $use_svm_props = eval { command_oneline(qw/config --bool
1812             svn.useSvmProps/) };
1813         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1814         my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
1815         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1816                 if (m!^(.+)\.fetch=$svn_refspec$!) {
1817                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1818                         die("svn-remote.$remote: remote ref '$remote_ref' "
1819                             . "must start with 'refs/'\n")
1820                                 unless $remote_ref =~ m{^refs/};
1821                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1822                         $r->{$remote}->{svm} = {} if $use_svm_props;
1823                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1824                         $r->{$1}->{svm} = {};
1825                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1826                         $r->{$1}->{url} = $2;
1827                 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
1828                         my ($remote, $t, $local_ref, $remote_ref) =
1829                                                              ($1, $2, $3, $4);
1830                         die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
1831                             . "must start with 'refs/'\n")
1832                                 unless $remote_ref =~ m{^refs/};
1833                         my $rs = {
1834                             t => $t,
1835                             remote => $remote,
1836                             path => Git::SVN::GlobSpec->new($local_ref, 1),
1837                             ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
1838                         if (length($rs->{ref}->{right}) != 0) {
1839                                 die "The '*' glob character must be the last ",
1840                                     "character of '$remote_ref'\n";
1841                         }
1842                         push @{ $r->{$remote}->{$t} }, $rs;
1843                 }
1844         }
1845
1846         map {
1847                 if (defined $r->{$_}->{svm}) {
1848                         my $svm;
1849                         eval {
1850                                 my $section = "svn-remote.$_";
1851                                 $svm = {
1852                                         source => tmp_config('--get',
1853                                             "$section.svm-source"),
1854                                         replace => tmp_config('--get',
1855                                             "$section.svm-replace"),
1856                                 }
1857                         };
1858                         $r->{$_}->{svm} = $svm;
1859                 }
1860         } keys %$r;
1861
1862         $r;
1863 }
1864
1865 sub init_vars {
1866         $_gc_nr = $_gc_period = 1000;
1867         if (defined $_repack || defined $_repack_flags) {
1868                warn "Repack options are obsolete; they have no effect.\n";
1869         }
1870 }
1871
1872 sub verify_remotes_sanity {
1873         return unless -d $ENV{GIT_DIR};
1874         my %seen;
1875         foreach (command(qw/config -l/)) {
1876                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1877                         if ($seen{$1}) {
1878                                 die "Remote ref refs/remote/$1 is tracked by",
1879                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1880                                     "Please resolve this ambiguity in ",
1881                                     "your git configuration file before ",
1882                                     "continuing\n";
1883                         }
1884                         $seen{$1} = $_;
1885                 }
1886         }
1887 }
1888
1889 sub find_existing_remote {
1890         my ($url, $remotes) = @_;
1891         return undef if $no_reuse_existing;
1892         my $existing;
1893         foreach my $repo_id (keys %$remotes) {
1894                 my $u = $remotes->{$repo_id}->{url} or next;
1895                 next if $u ne $url;
1896                 $existing = $repo_id;
1897                 last;
1898         }
1899         $existing;
1900 }
1901
1902 sub init_remote_config {
1903         my ($self, $url, $no_write) = @_;
1904         $url =~ s!/+$!!; # strip trailing slash
1905         my $r = read_all_remotes();
1906         my $existing = find_existing_remote($url, $r);
1907         if ($existing) {
1908                 unless ($no_write) {
1909                         print STDERR "Using existing ",
1910                                      "[svn-remote \"$existing\"]\n";
1911                 }
1912                 $self->{repo_id} = $existing;
1913         } elsif ($_minimize_url) {
1914                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1915                 $existing = find_existing_remote($min_url, $r);
1916                 if ($existing) {
1917                         unless ($no_write) {
1918                                 print STDERR "Using existing ",
1919                                              "[svn-remote \"$existing\"]\n";
1920                         }
1921                         $self->{repo_id} = $existing;
1922                 }
1923                 if ($min_url ne $url) {
1924                         unless ($no_write) {
1925                                 print STDERR "Using higher level of URL: ",
1926                                              "$url => $min_url\n";
1927                         }
1928                         my $old_path = $self->{path};
1929                         $self->{path} = $url;
1930                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1931                         if (length $old_path) {
1932                                 $self->{path} .= "/$old_path";
1933                         }
1934                         $url = $min_url;
1935                 }
1936         }
1937         my $orig_url;
1938         if (!$existing) {
1939                 # verify that we aren't overwriting anything:
1940                 $orig_url = eval {
1941                         command_oneline('config', '--get',
1942                                         "svn-remote.$self->{repo_id}.url")
1943                 };
1944                 if ($orig_url && ($orig_url ne $url)) {
1945                         die "svn-remote.$self->{repo_id}.url already set: ",
1946                             "$orig_url\nwanted to set to: $url\n";
1947                 }
1948         }
1949         my ($xrepo_id, $xpath) = find_ref($self->refname);
1950         if (!$no_write && defined $xpath) {
1951                 die "svn-remote.$xrepo_id.fetch already set to track ",
1952                     "$xpath:", $self->refname, "\n";
1953         }
1954         unless ($no_write) {
1955                 command_noisy('config',
1956                               "svn-remote.$self->{repo_id}.url", $url);
1957                 $self->{path} =~ s{^/}{};
1958                 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1959                 command_noisy('config', '--add',
1960                               "svn-remote.$self->{repo_id}.fetch",
1961                               "$self->{path}:".$self->refname);
1962         }
1963         $self->{url} = $url;
1964 }
1965
1966 sub find_by_url { # repos_root and, path are optional
1967         my ($class, $full_url, $repos_root, $path) = @_;
1968
1969         return undef unless defined $full_url;
1970         remove_username($full_url);
1971         remove_username($repos_root) if defined $repos_root;
1972         my $remotes = read_all_remotes();
1973         if (defined $full_url && defined $repos_root && !defined $path) {
1974                 $path = $full_url;
1975                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1976         }
1977         foreach my $repo_id (keys %$remotes) {
1978                 my $u = $remotes->{$repo_id}->{url} or next;
1979                 remove_username($u);
1980                 next if defined $repos_root && $repos_root ne $u;
1981
1982                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1983                 foreach my $t (qw/branches tags/) {
1984                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1985                                 resolve_local_globs($u, $fetch, $globspec);
1986                         }
1987                 }
1988                 my $p = $path;
1989                 my $rwr = rewrite_root({repo_id => $repo_id});
1990                 my $svm = $remotes->{$repo_id}->{svm}
1991                         if defined $remotes->{$repo_id}->{svm};
1992                 unless (defined $p) {
1993                         $p = $full_url;
1994                         my $z = $u;
1995                         my $prefix = '';
1996                         if ($rwr) {
1997                                 $z = $rwr;
1998                                 remove_username($z);
1999                         } elsif (defined $svm) {
2000                                 $z = $svm->{source};
2001                                 $prefix = $svm->{replace};
2002                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
2003                                 $prefix =~ s#/$##;
2004                         }
2005                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
2006                 }
2007                 foreach my $f (keys %$fetch) {
2008                         next if $f ne $p;
2009                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
2010                 }
2011         }
2012         undef;
2013 }
2014
2015 sub init {
2016         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
2017         my $self = _new($class, $repo_id, $ref_id, $path);
2018         if (defined $url) {
2019                 $self->init_remote_config($url, $no_write);
2020         }
2021         $self;
2022 }
2023
2024 sub find_ref {
2025         my ($ref_id) = @_;
2026         foreach (command(qw/config -l/)) {
2027                 next unless m!^svn-remote\.(.+)\.fetch=
2028                               \s*(.*?)\s*:\s*(.+?)\s*$!x;
2029                 my ($repo_id, $path, $ref) = ($1, $2, $3);
2030                 if ($ref eq $ref_id) {
2031                         $path = '' if ($path =~ m#^\./?#);
2032                         return ($repo_id, $path);
2033                 }
2034         }
2035         (undef, undef, undef);
2036 }
2037
2038 sub new {
2039         my ($class, $ref_id, $repo_id, $path) = @_;
2040         if (defined $ref_id && !defined $repo_id && !defined $path) {
2041                 ($repo_id, $path) = find_ref($ref_id);
2042                 if (!defined $repo_id) {
2043                         die "Could not find a \"svn-remote.*.fetch\" key ",
2044                             "in the repository configuration matching: ",
2045                             "$ref_id\n";
2046                 }
2047         }
2048         my $self = _new($class, $repo_id, $ref_id, $path);
2049         if (!defined $self->{path} || !length $self->{path}) {
2050                 my $fetch = command_oneline('config', '--get',
2051                                             "svn-remote.$repo_id.fetch",
2052                                             ":$ref_id\$") or
2053                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
2054                          "\":$ref_id\$\" in config\n";
2055                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
2056         }
2057         $self->{url} = command_oneline('config', '--get',
2058                                        "svn-remote.$repo_id.url") or
2059                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
2060         $self->rebuild;
2061         $self;
2062 }
2063
2064 sub refname {
2065         my ($refname) = $_[0]->{ref_id} ;
2066
2067         # It cannot end with a slash /, we'll throw up on this because
2068         # SVN can't have directories with a slash in their name, either:
2069         if ($refname =~ m{/$}) {
2070                 die "ref: '$refname' ends with a trailing slash, this is ",
2071                     "not permitted by git nor Subversion\n";
2072         }
2073
2074         # It cannot have ASCII control character space, tilde ~, caret ^,
2075         # colon :, question-mark ?, asterisk *, space, or open bracket [
2076         # anywhere.
2077         #
2078         # Additionally, % must be escaped because it is used for escaping
2079         # and we want our escaped refname to be reversible
2080         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2081
2082         # no slash-separated component can begin with a dot .
2083         # /.* becomes /%2E*
2084         $refname =~ s{/\.}{/%2E}g;
2085
2086         # It cannot have two consecutive dots .. anywhere
2087         # .. becomes %2E%2E
2088         $refname =~ s{\.\.}{%2E%2E}g;
2089
2090         # trailing dots and .lock are not allowed
2091         # .$ becomes %2E and .lock becomes %2Elock
2092         $refname =~ s{\.(?=$|lock$)}{%2E};
2093
2094         # the sequence @{ is used to access the reflog
2095         # @{ becomes %40{
2096         $refname =~ s{\@\{}{%40\{}g;
2097
2098         return $refname;
2099 }
2100
2101 sub desanitize_refname {
2102         my ($refname) = @_;
2103         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2104         return $refname;
2105 }
2106
2107 sub svm_uuid {
2108         my ($self) = @_;
2109         return $self->{svm}->{uuid} if $self->svm;
2110         $self->ra;
2111         unless ($self->{svm}) {
2112                 die "SVM UUID not cached, and reading remotely failed\n";
2113         }
2114         $self->{svm}->{uuid};
2115 }
2116
2117 sub svm {
2118         my ($self) = @_;
2119         return $self->{svm} if $self->{svm};
2120         my $svm;
2121         # see if we have it in our config, first:
2122         eval {
2123                 my $section = "svn-remote.$self->{repo_id}";
2124                 $svm = {
2125                   source => tmp_config('--get', "$section.svm-source"),
2126                   uuid => tmp_config('--get', "$section.svm-uuid"),
2127                   replace => tmp_config('--get', "$section.svm-replace"),
2128                 }
2129         };
2130         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2131                 $self->{svm} = $svm;
2132         }
2133         $self->{svm};
2134 }
2135
2136 sub _set_svm_vars {
2137         my ($self, $ra) = @_;
2138         return $ra if $self->svm;
2139
2140         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2141                     "(svm:source, svm:uuid) ",
2142                     "from the following URLs:\n" );
2143         sub read_svm_props {
2144                 my ($self, $ra, $path, $r) = @_;
2145                 my $props = ($ra->get_dir($path, $r))[2];
2146                 my $src = $props->{'svm:source'};
2147                 my $uuid = $props->{'svm:uuid'};
2148                 return undef if (!$src || !$uuid);
2149
2150                 chomp($src, $uuid);
2151
2152                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2153                     or die "doesn't look right - svm:uuid is '$uuid'\n";
2154
2155                 # the '!' is used to mark the repos_root!/relative/path
2156                 $src =~ s{/?!/?}{/};
2157                 $src =~ s{/+$}{}; # no trailing slashes please
2158                 # username is of no interest
2159                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2160
2161                 my $replace = $ra->{url};
2162                 $replace .= "/$path" if length $path;
2163
2164                 my $section = "svn-remote.$self->{repo_id}";
2165                 tmp_config("$section.svm-source", $src);
2166                 tmp_config("$section.svm-replace", $replace);
2167                 tmp_config("$section.svm-uuid", $uuid);
2168                 $self->{svm} = {
2169                         source => $src,
2170                         uuid => $uuid,
2171                         replace => $replace
2172                 };
2173         }
2174
2175         my $r = $ra->get_latest_revnum;
2176         my $path = $self->{path};
2177         my %tried;
2178         while (length $path) {
2179                 unless ($tried{"$self->{url}/$path"}) {
2180                         return $ra if $self->read_svm_props($ra, $path, $r);
2181                         $tried{"$self->{url}/$path"} = 1;
2182                 }
2183                 $path =~ s#/?[^/]+$##;
2184         }
2185         die "Path: '$path' should be ''\n" if $path ne '';
2186         return $ra if $self->read_svm_props($ra, $path, $r);
2187         $tried{"$self->{url}/$path"} = 1;
2188
2189         if ($ra->{repos_root} eq $self->{url}) {
2190                 die @err, (map { "  $_\n" } keys %tried), "\n";
2191         }
2192
2193         # nope, make sure we're connected to the repository root:
2194         my $ok;
2195         my @tried_b;
2196         $path = $ra->{svn_path};
2197         $ra = Git::SVN::Ra->new($ra->{repos_root});
2198         while (length $path) {
2199                 unless ($tried{"$ra->{url}/$path"}) {
2200                         $ok = $self->read_svm_props($ra, $path, $r);
2201                         last if $ok;
2202                         $tried{"$ra->{url}/$path"} = 1;
2203                 }
2204                 $path =~ s#/?[^/]+$##;
2205         }
2206         die "Path: '$path' should be ''\n" if $path ne '';
2207         $ok ||= $self->read_svm_props($ra, $path, $r);
2208         $tried{"$ra->{url}/$path"} = 1;
2209         if (!$ok) {
2210                 die @err, (map { "  $_\n" } keys %tried), "\n";
2211         }
2212         Git::SVN::Ra->new($self->{url});
2213 }
2214
2215 sub svnsync {
2216         my ($self) = @_;
2217         return $self->{svnsync} if $self->{svnsync};
2218
2219         if ($self->no_metadata) {
2220                 die "Can't have both 'noMetadata' and ",
2221                     "'useSvnsyncProps' options set!\n";
2222         }
2223         if ($self->rewrite_root) {
2224                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2225                     "options set!\n";
2226         }
2227         if ($self->rewrite_uuid) {
2228                 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
2229                     "options set!\n";
2230         }
2231
2232         my $svnsync;
2233         # see if we have it in our config, first:
2234         eval {
2235                 my $section = "svn-remote.$self->{repo_id}";
2236
2237                 my $url = tmp_config('--get', "$section.svnsync-url");
2238                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2239                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2240
2241                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2242                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2243                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2244
2245                 $svnsync = { url => $url, uuid => $uuid }
2246         };
2247         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2248                 return $self->{svnsync} = $svnsync;
2249         }
2250
2251         my $err = "useSvnsyncProps set, but failed to read " .
2252                   "svnsync property: svn:sync-from-";
2253         my $rp = $self->ra->rev_proplist(0);
2254
2255         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2256         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2257                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2258
2259         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2260         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2261                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2262
2263         my $section = "svn-remote.$self->{repo_id}";
2264         tmp_config('--add', "$section.svnsync-uuid", $uuid);
2265         tmp_config('--add', "$section.svnsync-url", $url);
2266         return $self->{svnsync} = { url => $url, uuid => $uuid };
2267 }
2268
2269 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2270 # remote lookup (useful for 'git svn log').
2271 sub ra_uuid {
2272         my ($self) = @_;
2273         unless ($self->{ra_uuid}) {
2274                 my $key = "svn-remote.$self->{repo_id}.uuid";
2275                 my $uuid = eval { tmp_config('--get', $key) };
2276                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2277                         $self->{ra_uuid} = $uuid;
2278                 } else {
2279                         die "ra_uuid called without URL\n" unless $self->{url};
2280                         $self->{ra_uuid} = $self->ra->get_uuid;
2281                         tmp_config('--add', $key, $self->{ra_uuid});
2282                 }
2283         }
2284         $self->{ra_uuid};
2285 }
2286
2287 sub _set_repos_root {
2288         my ($self, $repos_root) = @_;
2289         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2290         $repos_root ||= $self->ra->{repos_root};
2291         tmp_config($k, $repos_root);
2292         $repos_root;
2293 }
2294
2295 sub repos_root {
2296         my ($self) = @_;
2297         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2298         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2299 }
2300
2301 sub ra {
2302         my ($self) = shift;
2303         my $ra = Git::SVN::Ra->new($self->{url});
2304         $self->_set_repos_root($ra->{repos_root});
2305         if ($self->use_svm_props && !$self->{svm}) {
2306                 if ($self->no_metadata) {
2307                         die "Can't have both 'noMetadata' and ",
2308                             "'useSvmProps' options set!\n";
2309                 } elsif ($self->use_svnsync_props) {
2310                         die "Can't have both 'useSvnsyncProps' and ",
2311                             "'useSvmProps' options set!\n";
2312                 }
2313                 $ra = $self->_set_svm_vars($ra);
2314                 $self->{-want_revprops} = 1;
2315         }
2316         $ra;
2317 }
2318
2319 # prop_walk(PATH, REV, SUB)
2320 # -------------------------
2321 # Recursively traverse PATH at revision REV and invoke SUB for each
2322 # directory that contains a SVN property.  SUB will be invoked as
2323 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2324 # Git::SVN, `path' the path to the directory where the properties
2325 # `props' were found.  The `path' will be relative to point of checkout,
2326 # that is, if url://repo/trunk is the current Git branch, and that
2327 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2328 # as `path' (note the trailing `/').
2329 sub prop_walk {
2330         my ($self, $path, $rev, $sub) = @_;
2331
2332         $path =~ s#^/##;
2333         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2334         $path =~ s#^/*#/#g;
2335         my $p = $path;
2336         # Strip the irrelevant part of the path.
2337         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2338         # Ensure the path is terminated by a `/'.
2339         $p =~ s#/*$#/#;
2340
2341         # The properties contain all the internal SVN stuff nobody
2342         # (usually) cares about.
2343         my $interesting_props = 0;
2344         foreach (keys %{$props}) {
2345                 # If it doesn't start with `svn:', it must be a
2346                 # user-defined property.
2347                 ++$interesting_props and next if $_ !~ /^svn:/;
2348                 # FIXME: Fragile, if SVN adds new public properties,
2349                 # this needs to be updated.
2350                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2351                                                  |eol-style|mime-type
2352                                                  |externals|needs-lock)$/x;
2353         }
2354         &$sub($self, $p, $props) if $interesting_props;
2355
2356         foreach (sort keys %$dirent) {
2357                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2358                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2359         }
2360 }
2361
2362 sub last_rev { ($_[0]->last_rev_commit)[0] }
2363 sub last_commit { ($_[0]->last_rev_commit)[1] }
2364
2365 # returns the newest SVN revision number and newest commit SHA1
2366 sub last_rev_commit {
2367         my ($self) = @_;
2368         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2369                 return ($self->{last_rev}, $self->{last_commit});
2370         }
2371         my $c = ::verify_ref($self->refname.'^0');
2372         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2373                 my $rev = (::cmt_metadata($c))[1];
2374                 if (defined $rev) {
2375                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2376                         return ($rev, $c);
2377                 }
2378         }
2379         my $map_path = $self->map_path;
2380         unless (-e $map_path) {
2381                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2382                 return (undef, undef);
2383         }
2384         my ($rev, $commit) = $self->rev_map_max(1);
2385         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2386         return ($rev, $commit);
2387 }
2388
2389 sub get_fetch_range {
2390         my ($self, $min, $max) = @_;
2391         $max ||= $self->ra->get_latest_revnum;
2392         $min ||= $self->rev_map_max;
2393         (++$min, $max);
2394 }
2395
2396 sub tmp_config {
2397         my (@args) = @_;
2398         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2399         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2400         if (! -f $config && -f $old_def_config) {
2401                 rename $old_def_config, $config or
2402                        die "Failed rename $old_def_config => $config: $!\n";
2403         }
2404         my $old_config = $ENV{GIT_CONFIG};
2405         $ENV{GIT_CONFIG} = $config;
2406         $@ = undef;
2407         my @ret = eval {
2408                 unless (-f $config) {
2409                         mkfile($config);
2410                         open my $fh, '>', $config or
2411                             die "Can't open $config: $!\n";
2412                         print $fh "; This file is used internally by ",
2413                                   "git-svn\n" or die
2414                                   "Couldn't write to $config: $!\n";
2415                         print $fh "; You should not have to edit it\n" or
2416                               die "Couldn't write to $config: $!\n";
2417                         close $fh or die "Couldn't close $config: $!\n";
2418                 }
2419                 command('config', @args);
2420         };
2421         my $err = $@;
2422         if (defined $old_config) {
2423                 $ENV{GIT_CONFIG} = $old_config;
2424         } else {
2425                 delete $ENV{GIT_CONFIG};
2426         }
2427         die $err if $err;
2428         wantarray ? @ret : $ret[0];
2429 }
2430
2431 sub tmp_index_do {
2432         my ($self, $sub) = @_;
2433         my $old_index = $ENV{GIT_INDEX_FILE};
2434         $ENV{GIT_INDEX_FILE} = $self->{index};
2435         $@ = undef;
2436         my @ret = eval {
2437                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2438                 mkpath([$dir]) unless -d $dir;
2439                 &$sub;
2440         };
2441         my $err = $@;
2442         if (defined $old_index) {
2443                 $ENV{GIT_INDEX_FILE} = $old_index;
2444         } else {
2445                 delete $ENV{GIT_INDEX_FILE};
2446         }
2447         die $err if $err;
2448         wantarray ? @ret : $ret[0];
2449 }
2450
2451 sub assert_index_clean {
2452         my ($self, $treeish) = @_;
2453
2454         $self->tmp_index_do(sub {
2455                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2456                 my $x = command_oneline('write-tree');
2457                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2458                            /^tree ($::sha1)/mo);
2459                 return if $y eq $x;
2460
2461                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2462                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2463                 command_noisy('read-tree', $treeish);
2464                 $x = command_oneline('write-tree');
2465                 if ($y ne $x) {
2466                         ::fatal "trees ($treeish) $y != $x\n",
2467                                 "Something is seriously wrong...";
2468                 }
2469         });
2470 }
2471
2472 sub get_commit_parents {
2473         my ($self, $log_entry) = @_;
2474         my (%seen, @ret, @tmp);
2475         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2476         if (my $ip = $self->{inject_parents}) {
2477                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2478                         push @tmp, $commit;
2479                 }
2480         }
2481         if (my $cur = ::verify_ref($self->refname.'^0')) {
2482                 push @tmp, $cur;
2483         }
2484         if (my $ipd = $self->{inject_parents_dcommit}) {
2485                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2486                         push @tmp, @$commit;
2487                 }
2488         }
2489         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2490         while (my $p = shift @tmp) {
2491                 next if $seen{$p};
2492                 $seen{$p} = 1;
2493                 push @ret, $p;
2494         }
2495         @ret;
2496 }
2497
2498 sub rewrite_root {
2499         my ($self) = @_;
2500         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2501         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2502         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2503         if ($rwr) {
2504                 $rwr =~ s#/+$##;
2505                 if ($rwr !~ m#^[a-z\+]+://#) {
2506                         die "$rwr is not a valid URL (key: $k)\n";
2507                 }
2508         }
2509         $self->{-rewrite_root} = $rwr;
2510 }
2511
2512 sub rewrite_uuid {
2513         my ($self) = @_;
2514         return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
2515         my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
2516         my $rwid = eval { command_oneline(qw/config --get/, $k) };
2517         if ($rwid) {
2518                 $rwid =~ s#/+$##;
2519                 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
2520                         die "$rwid is not a valid UUID (key: $k)\n";
2521                 }
2522         }
2523         $self->{-rewrite_uuid} = $rwid;
2524 }
2525
2526 sub metadata_url {
2527         my ($self) = @_;
2528         ($self->rewrite_root || $self->{url}) .
2529            (length $self->{path} ? '/' . $self->{path} : '');
2530 }
2531
2532 sub full_url {
2533         my ($self) = @_;
2534         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2535 }
2536
2537
2538 sub set_commit_header_env {
2539         my ($log_entry) = @_;
2540         my %env;
2541         foreach my $ned (qw/NAME EMAIL DATE/) {
2542                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2543                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2544                 }
2545         }
2546
2547         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2548         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2549         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2550
2551         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2552                                                 ? $log_entry->{commit_name}
2553                                                 : $log_entry->{name};
2554         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2555                                                 ? $log_entry->{commit_email}
2556                                                 : $log_entry->{email};
2557         \%env;
2558 }
2559
2560 sub restore_commit_header_env {
2561         my ($env) = @_;
2562         foreach my $ned (qw/NAME EMAIL DATE/) {
2563                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2564                         my $k = "GIT_${ac}_${ned}";
2565                         if (defined $env->{$k}) {
2566                                 $ENV{$k} = $env->{$k};
2567                         } else {
2568                                 delete $ENV{$k};
2569                         }
2570                 }
2571         }
2572 }
2573
2574 sub gc {
2575         command_noisy('gc', '--auto');
2576 };
2577
2578 sub do_git_commit {
2579         my ($self, $log_entry) = @_;
2580         my $lr = $self->last_rev;
2581         if (defined $lr && $lr >= $log_entry->{revision}) {
2582                 die "Last fetched revision of ", $self->refname,
2583                     " was r$lr, but we are about to fetch: ",
2584                     "r$log_entry->{revision}!\n";
2585         }
2586         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2587                 croak "$log_entry->{revision} = $c already exists! ",
2588                       "Why are we refetching it?\n";
2589         }
2590         my $old_env = set_commit_header_env($log_entry);
2591         my $tree = $log_entry->{tree};
2592         if (!defined $tree) {
2593                 $tree = $self->tmp_index_do(sub {
2594                                             command_oneline('write-tree') });
2595         }
2596         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2597
2598         my @exec = ('git', 'commit-tree', $tree);
2599         foreach ($self->get_commit_parents($log_entry)) {
2600                 push @exec, '-p', $_;
2601         }
2602         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2603                                                                    or croak $!;
2604         binmode $msg_fh;
2605
2606         # we always get UTF-8 from SVN, but we may want our commits in
2607         # a different encoding.
2608         if (my $enc = Git::config('i18n.commitencoding')) {
2609                 require Encode;
2610                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2611         }
2612         print $msg_fh $log_entry->{log} or croak $!;
2613         restore_commit_header_env($old_env);
2614         unless ($self->no_metadata) {
2615                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2616                               or croak $!;
2617         }
2618         $msg_fh->flush == 0 or croak $!;
2619         close $msg_fh or croak $!;
2620         chomp(my $commit = do { local $/; <$out_fh> });
2621         close $out_fh or croak $!;
2622         waitpid $pid, 0;
2623         croak $? if $?;
2624         if ($commit !~ /^$::sha1$/o) {
2625                 die "Failed to commit, invalid sha1: $commit\n";
2626         }
2627
2628         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2629
2630         $self->{last_rev} = $log_entry->{revision};
2631         $self->{last_commit} = $commit;
2632         print "r$log_entry->{revision}" unless $::_q > 1;
2633         if (defined $log_entry->{svm_revision}) {
2634                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2635                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2636                                    0, $self->svm_uuid);
2637         }
2638         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2639         if (--$_gc_nr == 0) {
2640                 $_gc_nr = $_gc_period;
2641                 gc();
2642         }
2643         return $commit;
2644 }
2645
2646 sub match_paths {
2647         my ($self, $paths, $r) = @_;
2648         return 1 if $self->{path} eq '';
2649         if (my $path = $paths->{"/$self->{path}"}) {
2650                 return ($path->{action} eq 'D') ? 0 : 1;
2651         }
2652         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2653         if (grep /$self->{path_regex}/, keys %$paths) {
2654                 return 1;
2655         }
2656         my $c = '';
2657         foreach (split m#/#, $self->{path}) {
2658                 $c .= "/$_";
2659                 next unless ($paths->{$c} &&
2660                              ($paths->{$c}->{action} =~ /^[AR]$/));
2661                 if ($self->ra->check_path($self->{path}, $r) ==
2662                     $SVN::Node::dir) {
2663                         return 1;
2664                 }
2665         }
2666         return 0;
2667 }
2668
2669 sub find_parent_branch {
2670         my ($self, $paths, $rev) = @_;
2671         return undef unless $self->follow_parent;
2672         unless (defined $paths) {
2673                 my $err_handler = $SVN::Error::handler;
2674                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2675                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2676                                    sub { $paths = $_[0] });
2677                 $SVN::Error::handler = $err_handler;
2678         }
2679         return undef unless defined $paths;
2680
2681         # look for a parent from another branch:
2682         my @b_path_components = split m#/#, $self->{path};
2683         my @a_path_components;
2684         my $i;
2685         while (@b_path_components) {
2686                 $i = $paths->{'/'.join('/', @b_path_components)};
2687                 last if $i && defined $i->{copyfrom_path};
2688                 unshift(@a_path_components, pop(@b_path_components));
2689         }
2690         return undef unless defined $i && defined $i->{copyfrom_path};
2691         my $branch_from = $i->{copyfrom_path};
2692         if (@a_path_components) {
2693                 print STDERR "branch_from: $branch_from => ";
2694                 $branch_from .= '/'.join('/', @a_path_components);
2695                 print STDERR $branch_from, "\n";
2696         }
2697         my $r = $i->{copyfrom_rev};
2698         my $repos_root = $self->ra->{repos_root};
2699         my $url = $self->ra->{url};
2700         my $new_url = $url . $branch_from;
2701         print STDERR  "Found possible branch point: ",
2702                       "$new_url => ", $self->full_url, ", $r\n"
2703                       unless $::_q > 1;
2704         $branch_from =~ s#^/##;
2705         my $gs = $self->other_gs($new_url, $url,
2706                                  $branch_from, $r, $self->{ref_id});
2707         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2708         {
2709                 my ($base, $head);
2710                 if (!defined $r0 || !defined $parent) {
2711                         ($base, $head) = parse_revision_argument(0, $r);
2712                 } else {
2713                         if ($r0 < $r) {
2714                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2715                                         0, 1, sub { $base = $_[1] - 1 });
2716                         }
2717                 }
2718                 if (defined $base && $base <= $r) {
2719                         $gs->fetch($base, $r);
2720                 }
2721                 ($r0, $parent) = $gs->find_rev_before($r, 1);
2722         }
2723         if (defined $r0 && defined $parent) {
2724                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
2725                              unless $::_q > 1;
2726                 my $ed;
2727                 if ($self->ra->can_do_switch) {
2728                         $self->assert_index_clean($parent);
2729                         print STDERR "Following parent with do_switch\n"
2730                                      unless $::_q > 1;
2731                         # do_switch works with svn/trunk >= r22312, but that
2732                         # is not included with SVN 1.4.3 (the latest version
2733                         # at the moment), so we can't rely on it
2734                         $self->{last_rev} = $r0;
2735                         $self->{last_commit} = $parent;
2736                         $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2737                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2738                                               $self->full_url, $ed)
2739                           or die "SVN connection failed somewhere...\n";
2740                 } elsif ($self->ra->trees_match($new_url, $r0,
2741                                                 $self->full_url, $rev)) {
2742                         print STDERR "Trees match:\n",
2743                                      "  $new_url\@$r0\n",
2744                                      "  ${\$self->full_url}\@$rev\n",
2745                                      "Following parent with no changes\n"
2746                                      unless $::_q > 1;
2747                         $self->tmp_index_do(sub {
2748                             command_noisy('read-tree', $parent);
2749                         });
2750                         $self->{last_commit} = $parent;
2751                 } else {
2752                         print STDERR "Following parent with do_update\n"
2753                                      unless $::_q > 1;
2754                         $ed = SVN::Git::Fetcher->new($self);
2755                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2756                           or die "SVN connection failed somewhere...\n";
2757                 }
2758                 print STDERR "Successfully followed parent\n" unless $::_q > 1;
2759                 return $self->make_log_entry($rev, [$parent], $ed);
2760         }
2761         return undef;
2762 }
2763
2764 sub do_fetch {
2765         my ($self, $paths, $rev) = @_;
2766         my $ed;
2767         my ($last_rev, @parents);
2768         if (my $lc = $self->last_commit) {
2769                 # we can have a branch that was deleted, then re-added
2770                 # under the same name but copied from another path, in
2771                 # which case we'll have multiple parents (we don't
2772                 # want to break the original ref, nor lose copypath info):
2773                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2774                         push @{$log_entry->{parents}}, $lc;
2775                         return $log_entry;
2776                 }
2777                 $ed = SVN::Git::Fetcher->new($self);
2778                 $last_rev = $self->{last_rev};
2779                 $ed->{c} = $lc;
2780                 @parents = ($lc);
2781         } else {
2782                 $last_rev = $rev;
2783                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2784                         return $log_entry;
2785                 }
2786                 $ed = SVN::Git::Fetcher->new($self);
2787         }
2788         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2789                 die "SVN connection failed somewhere...\n";
2790         }
2791         $self->make_log_entry($rev, \@parents, $ed);
2792 }
2793
2794 sub mkemptydirs {
2795         my ($self, $r) = @_;
2796
2797         sub scan {
2798                 my ($r, $empty_dirs, $line) = @_;
2799                 if (defined $r && $line =~ /^r(\d+)$/) {
2800                         return 0 if $1 > $r;
2801                 } elsif ($line =~ /^  \+empty_dir: (.+)$/) {
2802                         $empty_dirs->{$1} = 1;
2803                 } elsif ($line =~ /^  \-empty_dir: (.+)$/) {
2804                         my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
2805                         delete @$empty_dirs{@d};
2806                 }
2807                 1; # continue
2808         };
2809
2810         my %empty_dirs = ();
2811         my $gz_file = "$self->{dir}/unhandled.log.gz";
2812         if (-f $gz_file) {
2813                 if (!$can_compress) {
2814                         warn "Compress::Zlib could not be found; ",
2815                              "empty directories in $gz_file will not be read\n";
2816                 } else {
2817                         my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
2818                                 die "Unable to open $gz_file: $!\n";
2819                         my $line;
2820                         while ($gz->gzreadline($line) > 0) {
2821                                 scan($r, \%empty_dirs, $line) or last;
2822                         }
2823                         $gz->gzclose;
2824                 }
2825         }
2826
2827         if (open my $fh, '<', "$self->{dir}/unhandled.log") {
2828                 binmode $fh or croak "binmode: $!";
2829                 while (<$fh>) {
2830                         scan($r, \%empty_dirs, $_) or last;
2831                 }
2832                 close $fh;
2833         }
2834
2835         my $strip = qr/\A\Q$self->{path}\E(?:\/|$)/;
2836         foreach my $d (sort keys %empty_dirs) {
2837                 $d = uri_decode($d);
2838                 $d =~ s/$strip//;
2839                 next unless length($d);
2840                 next if -d $d;
2841                 if (-e $d) {
2842                         warn "$d exists but is not a directory\n";
2843                 } else {
2844                         print "creating empty directory: $d\n";
2845                         mkpath([$d]);
2846                 }
2847         }
2848 }
2849
2850 sub get_untracked {
2851         my ($self, $ed) = @_;
2852         my @out;
2853         my $h = $ed->{empty};
2854         foreach (sort keys %$h) {
2855                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2856                 push @out, "  $act: " . uri_encode($_);
2857                 warn "W: $act: $_\n";
2858         }
2859         foreach my $t (qw/dir_prop file_prop/) {
2860                 $h = $ed->{$t} or next;
2861                 foreach my $path (sort keys %$h) {
2862                         my $ppath = $path eq '' ? '.' : $path;
2863                         foreach my $prop (sort keys %{$h->{$path}}) {
2864                                 next if $SKIP_PROP{$prop};
2865                                 my $v = $h->{$path}->{$prop};
2866                                 my $t_ppath_prop = "$t: " .
2867                                                     uri_encode($ppath) . ' ' .
2868                                                     uri_encode($prop);
2869                                 if (defined $v) {
2870                                         push @out, "  +$t_ppath_prop " .
2871                                                    uri_encode($v);
2872                                 } else {
2873                                         push @out, "  -$t_ppath_prop";
2874                                 }
2875                         }
2876                 }
2877         }
2878         foreach my $t (qw/absent_file absent_directory/) {
2879                 $h = $ed->{$t} or next;
2880                 foreach my $parent (sort keys %$h) {
2881                         foreach my $path (sort @{$h->{$parent}}) {
2882                                 push @out, "  $t: " .
2883                                            uri_encode("$parent/$path");
2884                                 warn "W: $t: $parent/$path ",
2885                                      "Insufficient permissions?\n";
2886                         }
2887                 }
2888         }
2889         \@out;
2890 }
2891
2892 # parse_svn_date(DATE)
2893 # --------------------
2894 # Given a date (in UTC) from Subversion, return a string in the format
2895 # "<TZ Offset> <local date/time>" that Git will use.
2896 #
2897 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2898 # is true we'll convert it to the local timezone instead.
2899 sub parse_svn_date {
2900         my $date = shift || return '+0000 1970-01-01 00:00:00';
2901         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2902                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2903                                          croak "Unable to parse date: $date\n";
2904         my $parsed_date;    # Set next.
2905
2906         if ($Git::SVN::_localtime) {
2907                 # Translate the Subversion datetime to an epoch time.
2908                 # Begin by switching ourselves to $date's timezone, UTC.
2909                 my $old_env_TZ = $ENV{TZ};
2910                 $ENV{TZ} = 'UTC';
2911
2912                 my $epoch_in_UTC =
2913                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2914
2915                 # Determine our local timezone (including DST) at the
2916                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
2917                 # value of TZ, if any, at the time we were run.
2918                 if (defined $Git::SVN::Log::TZ) {
2919                         $ENV{TZ} = $Git::SVN::Log::TZ;
2920                 } else {
2921                         delete $ENV{TZ};
2922                 }
2923
2924                 my $our_TZ =
2925                     POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2926
2927                 # This converts $epoch_in_UTC into our local timezone.
2928                 my ($sec, $min, $hour, $mday, $mon, $year,
2929                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2930
2931                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2932                                        $our_TZ, $year + 1900, $mon + 1,
2933                                        $mday, $hour, $min, $sec);
2934
2935                 # Reset us to the timezone in effect when we entered
2936                 # this routine.
2937                 if (defined $old_env_TZ) {
2938                         $ENV{TZ} = $old_env_TZ;
2939                 } else {
2940                         delete $ENV{TZ};
2941                 }
2942         } else {
2943                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2944         }
2945
2946         return $parsed_date;
2947 }
2948
2949 sub other_gs {
2950         my ($self, $new_url, $url,
2951             $branch_from, $r, $old_ref_id) = @_;
2952         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2953         unless ($gs) {
2954                 my $ref_id = $old_ref_id;
2955                 $ref_id =~ s/\@\d+$//;
2956                 $ref_id .= "\@$r";
2957                 # just grow a tail if we're not unique enough :x
2958                 $ref_id .= '-' while find_ref($ref_id);
2959                 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
2960                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2961                 if ($u =~ s#^\Q$url\E(/|$)##) {
2962                         $p = $u;
2963                         $u = $url;
2964                         $repo_id = $self->{repo_id};
2965                 }
2966                 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2967         }
2968         $gs
2969 }
2970
2971 sub call_authors_prog {
2972         my ($orig_author) = @_;
2973         $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
2974         my $author = `$::_authors_prog $orig_author`;
2975         if ($? != 0) {
2976                 die "$::_authors_prog failed with exit code $?\n"
2977         }
2978         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
2979                 my ($name, $email) = ($1, $2);
2980                 $email = undef if length $2 == 0;
2981                 return [$name, $email];
2982         } else {
2983                 die "Author: $orig_author: $::_authors_prog returned "
2984                         . "invalid author format: $author\n";
2985         }
2986 }
2987
2988 sub check_author {
2989         my ($author) = @_;
2990         if (!defined $author || length $author == 0) {
2991                 $author = '(no author)';
2992         }
2993         if (!defined $::users{$author}) {
2994                 if (defined $::_authors_prog) {
2995                         $::users{$author} = call_authors_prog($author);
2996                 } elsif (defined $::_authors) {
2997                         die "Author: $author not defined in $::_authors file\n";
2998                 }
2999         }
3000         $author;
3001 }
3002
3003 sub find_extra_svk_parents {
3004         my ($self, $ed, $tickets, $parents) = @_;
3005         # aha!  svk:merge property changed...
3006         my @tickets = split "\n", $tickets;
3007         my @known_parents;
3008         for my $ticket ( @tickets ) {
3009                 my ($uuid, $path, $rev) = split /:/, $ticket;
3010                 if ( $uuid eq $self->ra_uuid ) {
3011                         my $url = $self->{url};
3012                         my $repos_root = $url;
3013                         my $branch_from = $path;
3014                         $branch_from =~ s{^/}{};
3015                         my $gs = $self->other_gs($repos_root."/".$branch_from,
3016                                                  $url,
3017                                                  $branch_from,
3018                                                  $rev,
3019                                                  $self->{ref_id});
3020                         if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
3021                                 # wahey!  we found it, but it might be
3022                                 # an old one (!)
3023                                 push @known_parents, [ $rev, $commit ];
3024                         }
3025                 }
3026         }
3027         # Ordering matters; highest-numbered commit merge tickets
3028         # first, as they may account for later merge ticket additions
3029         # or changes.
3030         @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
3031         for my $parent ( @known_parents ) {
3032                 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
3033                 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3034                 my $new;
3035                 while ( <$msg_fh> ) {
3036                         $new=1;last;
3037                 }
3038                 command_close_pipe($msg_fh, $ctx);
3039                 if ( $new ) {
3040                         print STDERR
3041                             "Found merge parent (svk:merge ticket): $parent\n";
3042                         push @$parents, $parent;
3043                 }
3044         }
3045 }
3046
3047 sub lookup_svn_merge {
3048         my $uuid = shift;
3049         my $url = shift;
3050         my $merge = shift;
3051
3052         my ($source, $revs) = split ":", $merge;
3053         my $path = $source;
3054         $path =~ s{^/}{};
3055         my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
3056         if ( !$gs ) {
3057                 warn "Couldn't find revmap for $url$source\n";
3058                 return;
3059         }
3060         my @ranges = split ",", $revs;
3061         my ($tip, $tip_commit);
3062         my @merged_commit_ranges;
3063         # find the tip
3064         for my $range ( @ranges ) {
3065                 my ($bottom, $top) = split "-", $range;
3066                 $top ||= $bottom;
3067                 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
3068                 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
3069
3070                 unless ($top_commit and $bottom_commit) {
3071                         warn "W:unknown path/rev in svn:mergeinfo "
3072                                 ."dirprop: $source:$range\n";
3073                         next;
3074                 }
3075
3076                 push @merged_commit_ranges,
3077                         "$bottom_commit^..$top_commit";
3078
3079                 if ( !defined $tip or $top > $tip ) {
3080                         $tip = $top;
3081                         $tip_commit = $top_commit;
3082                 }
3083         }
3084         return ($tip_commit, @merged_commit_ranges);
3085 }
3086
3087 sub _rev_list {
3088         my ($msg_fh, $ctx) = command_output_pipe(
3089                 "rev-list", @_,
3090                );
3091         my @rv;
3092         while ( <$msg_fh> ) {
3093                 chomp;
3094                 push @rv, $_;
3095         }
3096         command_close_pipe($msg_fh, $ctx);
3097         @rv;
3098 }
3099
3100 sub check_cherry_pick {
3101         my $base = shift;
3102         my $tip = shift;
3103         my @ranges = @_;
3104         my %commits = map { $_ => 1 }
3105                 _rev_list("--no-merges", $tip, "--not", $base);
3106         for my $range ( @ranges ) {
3107                 delete @commits{_rev_list($range)};
3108         }
3109         for my $commit (keys %commits) {
3110                 if (has_no_changes($commit)) {
3111                         delete $commits{$commit};
3112                 }
3113         }
3114         return (keys %commits);
3115 }
3116
3117 sub has_no_changes {
3118         my $commit = shift;
3119
3120         my @revs = split / /, command_oneline(
3121                 qw(rev-list --parents -1 -m), $commit);
3122
3123         # Commits with no parents, e.g. the start of a partial branch,
3124         # have changes by definition.
3125         return 1 if (@revs < 2);
3126
3127         # Commits with multiple parents, e.g a merge, have no changes
3128         # by definition.
3129         return 0 if (@revs > 2);
3130
3131         return (command_oneline("rev-parse", "$commit^{tree}") eq
3132                 command_oneline("rev-parse", "$commit~1^{tree}"));
3133 }
3134
3135 # The GIT_DIR environment variable is not always set until after the command
3136 # line arguments are processed, so we can't memoize in a BEGIN block.
3137 {
3138         my $memoized = 0;
3139
3140         sub memoize_svn_mergeinfo_functions {
3141                 return if $memoized;
3142                 $memoized = 1;
3143
3144                 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
3145                 mkpath([$cache_path]) unless -d $cache_path;
3146
3147                 tie my %lookup_svn_merge_cache => 'Memoize::Storable',
3148                     "$cache_path/lookup_svn_merge.db", 'nstore';
3149                 memoize 'lookup_svn_merge',
3150                         SCALAR_CACHE => 'FAULT',
3151                         LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
3152                 ;
3153
3154                 tie my %check_cherry_pick_cache => 'Memoize::Storable',
3155                     "$cache_path/check_cherry_pick.db", 'nstore';
3156                 memoize 'check_cherry_pick',
3157                         SCALAR_CACHE => 'FAULT',
3158                         LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
3159                 ;
3160
3161                 tie my %has_no_changes_cache => 'Memoize::Storable',
3162                     "$cache_path/has_no_changes.db", 'nstore';
3163                 memoize 'has_no_changes',
3164                         SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
3165                         LIST_CACHE => 'FAULT',
3166                 ;
3167         }
3168 }
3169
3170 sub parents_exclude {
3171         my $parents = shift;
3172         my @commits = @_;
3173         return unless @commits;
3174
3175         my @excluded;
3176         my $excluded;
3177         do {
3178                 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
3179                 $excluded = command_oneline(@cmd);
3180                 if ( $excluded ) {
3181                         my @new;
3182                         my $found;
3183                         for my $commit ( @commits ) {
3184                                 if ( $commit eq $excluded ) {
3185                                         push @excluded, $commit;
3186                                         $found++;
3187                                         last;
3188                                 }
3189                                 else {
3190                                         push @new, $commit;
3191                                 }
3192                         }
3193                         die "saw commit '$excluded' in rev-list output, "
3194                                 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
3195                                         unless $found;
3196                         @commits = @new;
3197                 }
3198         }
3199                 while ($excluded and @commits);
3200
3201         return @excluded;
3202 }
3203
3204
3205 # note: this function should only be called if the various dirprops
3206 # have actually changed
3207 sub find_extra_svn_parents {
3208         my ($self, $ed, $mergeinfo, $parents) = @_;
3209         # aha!  svk:merge property changed...
3210
3211         memoize_svn_mergeinfo_functions();
3212
3213         # We first search for merged tips which are not in our
3214         # history.  Then, we figure out which git revisions are in
3215         # that tip, but not this revision.  If all of those revisions
3216         # are now marked as merge, we can add the tip as a parent.
3217         my @merges = split "\n", $mergeinfo;
3218         my @merge_tips;
3219         my $url = $self->{url};
3220         my $uuid = $self->ra_uuid;
3221         my %ranges;
3222         for my $merge ( @merges ) {
3223                 my ($tip_commit, @ranges) =
3224                         lookup_svn_merge( $uuid, $url, $merge );
3225                 unless (!$tip_commit or
3226                                 grep { $_ eq $tip_commit } @$parents ) {
3227                         push @merge_tips, $tip_commit;
3228                         $ranges{$tip_commit} = \@ranges;
3229                 } else {
3230                         push @merge_tips, undef;
3231                 }
3232         }
3233
3234         my %excluded = map { $_ => 1 }
3235                 parents_exclude($parents, grep { defined } @merge_tips);
3236
3237         # check merge tips for new parents
3238         my @new_parents;
3239         for my $merge_tip ( @merge_tips ) {
3240                 my $spec = shift @merges;
3241                 next unless $merge_tip and $excluded{$merge_tip};
3242
3243                 my $ranges = $ranges{$merge_tip};
3244
3245                 # check out 'new' tips
3246                 my $merge_base;
3247                 eval {
3248                         $merge_base = command_oneline(
3249                                 "merge-base",
3250                                 @$parents, $merge_tip,
3251                         );
3252                 };
3253                 if ($@) {
3254                         die "An error occurred during merge-base"
3255                                 unless $@->isa("Git::Error::Command");
3256
3257                         warn "W: Cannot find common ancestor between ".
3258                              "@$parents and $merge_tip. Ignoring merge info.\n";
3259                         next;
3260                 }
3261
3262                 # double check that there are no missing non-merge commits
3263                 my (@incomplete) = check_cherry_pick(
3264                         $merge_base, $merge_tip,
3265                         @$ranges,
3266                        );
3267
3268                 if ( @incomplete ) {
3269                         warn "W:svn cherry-pick ignored ($spec) - missing "
3270                                 .@incomplete." commit(s) (eg $incomplete[0])\n";
3271                 } else {
3272                         warn
3273                                 "Found merge parent (svn:mergeinfo prop): ",
3274                                         $merge_tip, "\n";
3275                         push @new_parents, $merge_tip;
3276                 }
3277         }
3278
3279         # cater for merges which merge commits from multiple branches
3280         if ( @new_parents > 1 ) {
3281                 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
3282                         for ( my $j = 0; $j <= $#new_parents; $j++ ) {
3283                                 next if $i == $j;
3284                                 next unless $new_parents[$i];
3285                                 next unless $new_parents[$j];
3286                                 my $revs = command_oneline(
3287                                         "rev-list", "-1",
3288                                         "$new_parents[$i]..$new_parents[$j]",
3289                                        );
3290                                 if ( !$revs ) {
3291                                         undef($new_parents[$j]);
3292                                 }
3293                         }
3294                 }
3295         }
3296         push @$parents, grep { defined } @new_parents;
3297 }
3298
3299 sub make_log_entry {
3300         my ($self, $rev, $parents, $ed) = @_;
3301         my $untracked = $self->get_untracked($ed);
3302
3303         my @parents = @$parents;
3304         my $ps = $ed->{path_strip} || "";
3305         for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
3306                 my $props = $ed->{dir_prop}{$path};
3307                 if ( $props->{"svk:merge"} ) {
3308                         $self->find_extra_svk_parents
3309                                 ($ed, $props->{"svk:merge"}, \@parents);
3310                 }
3311                 if ( $props->{"svn:mergeinfo"} ) {
3312                         $self->find_extra_svn_parents
3313                                 ($ed,
3314                                  $props->{"svn:mergeinfo"},
3315                                  \@parents);
3316                 }
3317         }
3318
3319         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
3320         print $un "r$rev\n" or croak $!;
3321         print $un $_, "\n" foreach @$untracked;
3322         my %log_entry = ( parents => \@parents, revision => $rev,
3323                           log => '');
3324
3325         my $headrev;
3326         my $logged = delete $self->{logged_rev_props};
3327         if (!$logged || $self->{-want_revprops}) {
3328                 my $rp = $self->ra->rev_proplist($rev);
3329                 foreach (sort keys %$rp) {
3330                         my $v = $rp->{$_};
3331                         if (/^svn:(author|date|log)$/) {
3332                                 $log_entry{$1} = $v;
3333                         } elsif ($_ eq 'svm:headrev') {
3334                                 $headrev = $v;
3335                         } else {
3336                                 print $un "  rev_prop: ", uri_encode($_), ' ',
3337                                           uri_encode($v), "\n";
3338                         }
3339                 }
3340         } else {
3341                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
3342         }
3343         close $un or croak $!;
3344
3345         $log_entry{date} = parse_svn_date($log_entry{date});
3346         $log_entry{log} .= "\n";
3347         my $author = $log_entry{author} = check_author($log_entry{author});
3348         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
3349                                                        : ($author, undef);
3350
3351         my ($commit_name, $commit_email) = ($name, $email);
3352         if ($_use_log_author) {
3353                 my $name_field;
3354                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
3355                         $name_field = $1;
3356                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
3357                         $name_field = $1;
3358                 }
3359                 if (!defined $name_field) {
3360                         if (!defined $email) {
3361                                 $email = $name;
3362                         }
3363                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
3364                         ($name, $email) = ($1, $2);
3365                 } elsif ($name_field =~ /(.*)@/) {
3366                         ($name, $email) = ($1, $name_field);
3367                 } else {
3368                         ($name, $email) = ($name_field, $name_field);
3369                 }
3370         }
3371         if (defined $headrev && $self->use_svm_props) {
3372                 if ($self->rewrite_root) {
3373                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
3374                             "options set!\n";
3375                 }
3376                 if ($self->rewrite_uuid) {
3377                         die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
3378                             "options set!\n";
3379                 }
3380                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
3381                 # we don't want "SVM: initializing mirror for junk" ...
3382                 return undef if $r == 0;
3383                 my $svm = $self->svm;
3384                 if ($uuid ne $svm->{uuid}) {
3385                         die "UUID mismatch on SVM path:\n",
3386                             "expected: $svm->{uuid}\n",
3387                             "     got: $uuid\n";
3388                 }
3389                 my $full_url = $self->full_url;
3390                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
3391                              die "Failed to replace '$svm->{replace}' with ",
3392                                  "'$svm->{source}' in $full_url\n";
3393                 # throw away username for storing in records
3394                 remove_username($full_url);
3395                 $log_entry{metadata} = "$full_url\@$r $uuid";
3396                 $log_entry{svm_revision} = $r;
3397                 $email ||= "$author\@$uuid";
3398                 $commit_email ||= "$author\@$uuid";
3399         } elsif ($self->use_svnsync_props) {
3400                 my $full_url = $self->svnsync->{url};
3401                 $full_url .= "/$self->{path}" if length $self->{path};
3402                 remove_username($full_url);
3403                 my $uuid = $self->svnsync->{uuid};
3404                 $log_entry{metadata} = "$full_url\@$rev $uuid";
3405                 $email ||= "$author\@$uuid";
3406                 $commit_email ||= "$author\@$uuid";
3407         } else {
3408                 my $url = $self->metadata_url;
3409                 remove_username($url);
3410                 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
3411                 $log_entry{metadata} = "$url\@$rev " . $uuid;
3412                 $email ||= "$author\@" . $uuid;
3413                 $commit_email ||= "$author\@" . $uuid;
3414         }
3415         $log_entry{name} = $name;
3416         $log_entry{email} = $email;
3417         $log_entry{commit_name} = $commit_name;
3418         $log_entry{commit_email} = $commit_email;
3419         \%log_entry;
3420 }
3421
3422 sub fetch {
3423         my ($self, $min_rev, $max_rev, @parents) = @_;
3424         my ($last_rev, $last_commit) = $self->last_rev_commit;
3425         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
3426         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
3427 }
3428
3429 sub set_tree_cb {
3430         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
3431         $self->{inject_parents} = { $rev => $tree };
3432         $self->fetch(undef, undef);
3433 }
3434
3435 sub set_tree {
3436         my ($self, $tree) = (shift, shift);
3437         my $log_entry = ::get_commit_entry($tree);
3438         unless ($self->{last_rev}) {
3439                 ::fatal("Must have an existing revision to commit");
3440         }
3441         my %ed_opts = ( r => $self->{last_rev},
3442                         log => $log_entry->{log},
3443                         ra => $self->ra,
3444                         tree_a => $self->{last_commit},
3445                         tree_b => $tree,
3446                         editor_cb => sub {
3447                                $self->set_tree_cb($log_entry, $tree, @_) },
3448                         svn_path => $self->{path} );
3449         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
3450                 print "No changes\nr$self->{last_rev} = $tree\n";
3451         }
3452 }
3453
3454 sub rebuild_from_rev_db {
3455         my ($self, $path) = @_;
3456         my $r = -1;
3457         open my $fh, '<', $path or croak "open: $!";
3458         binmode $fh or croak "binmode: $!";
3459         while (<$fh>) {
3460                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3461                 chomp($_);
3462                 ++$r;
3463                 next if $_ eq ('0' x 40);
3464                 $self->rev_map_set($r, $_);
3465                 print "r$r = $_\n";
3466         }
3467         close $fh or croak "close: $!";
3468         unlink $path or croak "unlink: $!";
3469 }
3470
3471 sub rebuild {
3472         my ($self) = @_;
3473         my $map_path = $self->map_path;
3474         my $partial = (-e $map_path && ! -z $map_path);
3475         return unless ::verify_ref($self->refname.'^0');
3476         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3477                 my $rev_db = $self->rev_db_path;
3478                 $self->rebuild_from_rev_db($rev_db);
3479                 if ($self->use_svm_props) {
3480                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3481                         $self->rebuild_from_rev_db($svm_rev_db);
3482                 }
3483                 $self->unlink_rev_db_symlink;
3484                 return;
3485         }
3486         print "Rebuilding $map_path ...\n" if (!$partial);
3487         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3488                 (undef, undef));
3489         my ($log, $ctx) =
3490             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3491                                 ($head ? "$head.." : "") . $self->refname,
3492                                 '--');
3493         my $metadata_url = $self->metadata_url;
3494         remove_username($metadata_url);
3495         my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
3496         my $c;
3497         while (<$log>) {
3498                 if ( m{^commit ($::sha1)$} ) {
3499                         $c = $1;
3500                         next;
3501                 }
3502                 next unless s{^\s*(git-svn-id:)}{$1};
3503                 my ($url, $rev, $uuid) = ::extract_metadata($_);
3504                 remove_username($url);
3505
3506                 # ignore merges (from set-tree)
3507                 next if (!defined $rev || !$uuid);
3508
3509                 # if we merged or otherwise started elsewhere, this is
3510                 # how we break out of it
3511                 if (($uuid ne $svn_uuid) ||
3512                     ($metadata_url && $url && ($url ne $metadata_url))) {
3513                         next;
3514                 }
3515                 if ($partial && $head) {
3516                         print "Partial-rebuilding $map_path ...\n";
3517                         print "Currently at $base_rev = $head\n";
3518                         $head = undef;
3519                 }
3520
3521                 $self->rev_map_set($rev, $c);
3522                 print "r$rev = $c\n";
3523         }
3524         command_close_pipe($log, $ctx);
3525         print "Done rebuilding $map_path\n" if (!$partial || !$head);
3526         my $rev_db_path = $self->rev_db_path;
3527         if (-f $self->rev_db_path) {
3528                 unlink $self->rev_db_path or croak "unlink: $!";
3529         }
3530         $self->unlink_rev_db_symlink;
3531 }
3532
3533 # rev_map:
3534 # Tie::File seems to be prone to offset errors if revisions get sparse,
3535 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
3536 # one of my favorite modules is out :<  Next up would be one of the DBM
3537 # modules, but I'm not sure which is most portable...
3538 #
3539 # This is the replacement for the rev_db format, which was too big
3540 # and inefficient for large repositories with a lot of sparse history
3541 # (mainly tags)
3542 #
3543 # The format is this:
3544 #   - 24 bytes for every record,
3545 #     * 4 bytes for the integer representing an SVN revision number
3546 #     * 20 bytes representing the sha1 of a git commit
3547 #   - No empty padding records like the old format
3548 #     (except the last record, which can be overwritten)
3549 #   - new records are written append-only since SVN revision numbers
3550 #     increase monotonically
3551 #   - lookups on SVN revision number are done via a binary search
3552 #   - Piping the file to xxd -c24 is a good way of dumping it for
3553 #     viewing or editing (piped back through xxd -r), should the need
3554 #     ever arise.
3555 #   - The last record can be padding revision with an all-zero sha1
3556 #     This is used to optimize fetch performance when using multiple
3557 #     "fetch" directives in .git/config
3558 #
3559 # These files are disposable unless noMetadata or useSvmProps is set
3560
3561 sub _rev_map_set {
3562         my ($fh, $rev, $commit) = @_;
3563
3564         binmode $fh or croak "binmode: $!";
3565         my $size = (stat($fh))[7];
3566         ($size % 24) == 0 or croak "inconsistent size: $size";
3567
3568         my $wr_offset = 0;
3569         if ($size > 0) {
3570                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3571                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3572                 $read == 24 or croak "read only $read bytes (!= 24)";
3573                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3574                 if ($last_commit eq ('0' x40)) {
3575                         if ($size >= 48) {
3576                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3577                                 $read = sysread($fh, $buf, 24) or
3578                                     croak "read: $!";
3579                                 $read == 24 or
3580                                     croak "read only $read bytes (!= 24)";
3581                                 ($last_rev, $last_commit) =
3582                                     unpack(rev_map_fmt, $buf);
3583                                 if ($last_commit eq ('0' x40)) {
3584                                         croak "inconsistent .rev_map\n";
3585                                 }
3586                         }
3587                         if ($last_rev >= $rev) {
3588                                 croak "last_rev is higher!: $last_rev >= $rev";
3589                         }
3590                         $wr_offset = -24;
3591                 }
3592         }
3593         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3594         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3595           croak "write: $!";
3596 }
3597
3598 sub _rev_map_reset {
3599         my ($fh, $rev, $commit) = @_;
3600         my $c = _rev_map_get($fh, $rev);
3601         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3602         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3603         truncate $fh, $offset or croak "truncate: $!";
3604 }
3605
3606 sub mkfile {
3607         my ($path) = @_;
3608         unless (-e $path) {
3609                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3610                 mkpath([$dir]) unless -d $dir;
3611                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3612                 close $fh or die "Couldn't close (create) $path: $!\n";
3613         }
3614 }
3615
3616 sub rev_map_set {
3617         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3618         defined $commit or die "missing arg3\n";
3619         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3620         my $db = $self->map_path($uuid);
3621         my $db_lock = "$db.lock";
3622         my $sig;
3623         $update_ref ||= 0;
3624         if ($update_ref) {
3625                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3626                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3627         }
3628         mkfile($db);
3629
3630         $LOCKFILES{$db_lock} = 1;
3631         my $sync;
3632         # both of these options make our .rev_db file very, very important
3633         # and we can't afford to lose it because rebuild() won't work
3634         if ($self->use_svm_props || $self->no_metadata) {
3635                 $sync = 1;
3636                 copy($db, $db_lock) or die "rev_map_set(@_): ",
3637                                            "Failed to copy: ",
3638                                            "$db => $db_lock ($!)\n";
3639         } else {
3640                 rename $db, $db_lock or die "rev_map_set(@_): ",
3641                                             "Failed to rename: ",
3642                                             "$db => $db_lock ($!)\n";
3643         }
3644
3645         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3646              or croak "Couldn't open $db_lock: $!\n";
3647         $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3648                                  _rev_map_set($fh, $rev, $commit);
3649         if ($sync) {
3650                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3651                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3652         }
3653         close $fh or croak $!;
3654         if ($update_ref) {
3655                 $_head = $self;
3656                 my $note = "";
3657                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3658                 command_noisy('update-ref', '-m', "r$rev$note",
3659                               $self->refname, $commit);
3660         }
3661         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3662                                     "$db_lock => $db ($!)\n";
3663         delete $LOCKFILES{$db_lock};
3664         if ($update_ref) {
3665                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3666                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3667                 kill $sig, $$ if defined $sig;
3668         }
3669 }
3670
3671 # If want_commit, this will return an array of (rev, commit) where
3672 # commit _must_ be a valid commit in the archive.
3673 # Otherwise, it'll return the max revision (whether or not the
3674 # commit is valid or just a 0x40 placeholder).
3675 sub rev_map_max {
3676         my ($self, $want_commit) = @_;
3677         $self->rebuild;
3678         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3679         $want_commit ? ($r, $c) : $r;
3680 }
3681
3682 sub rev_map_max_norebuild {
3683         my ($self, $want_commit) = @_;
3684         my $map_path = $self->map_path;
3685         stat $map_path or return $want_commit ? (0, undef) : 0;
3686         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3687         binmode $fh or croak "binmode: $!";
3688         my $size = (stat($fh))[7];
3689         ($size % 24) == 0 or croak "inconsistent size: $size";
3690
3691         if ($size == 0) {
3692                 close $fh or croak "close: $!";
3693                 return $want_commit ? (0, undef) : 0;
3694         }
3695
3696         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3697         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3698         my ($r, $c) = unpack(rev_map_fmt, $buf);
3699         if ($want_commit && $c eq ('0' x40)) {
3700                 if ($size < 48) {
3701                         return $want_commit ? (0, undef) : 0;
3702                 }
3703                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3704                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3705                 ($r, $c) = unpack(rev_map_fmt, $buf);
3706                 if ($c eq ('0'x40)) {
3707                         croak "Penultimate record is all-zeroes in $map_path";
3708                 }
3709         }
3710         close $fh or croak "close: $!";
3711         $want_commit ? ($r, $c) : $r;
3712 }
3713
3714 sub rev_map_get {
3715         my ($self, $rev, $uuid) = @_;
3716         my $map_path = $self->map_path($uuid);
3717         return undef unless -e $map_path;
3718
3719         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3720         my $c = _rev_map_get($fh, $rev);
3721         close($fh) or croak "close: $!";
3722         $c
3723 }
3724
3725 sub _rev_map_get {
3726         my ($fh, $rev) = @_;
3727
3728         binmode $fh or croak "binmode: $!";
3729         my $size = (stat($fh))[7];
3730         ($size % 24) == 0 or croak "inconsistent size: $size";
3731
3732         if ($size == 0) {
3733                 return undef;
3734         }
3735
3736         my ($l, $u) = (0, $size - 24);
3737         my ($r, $c, $buf);
3738
3739         while ($l <= $u) {
3740                 my $i = int(($l/24 + $u/24) / 2) * 24;
3741                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3742                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3743                 my ($r, $c) = unpack(rev_map_fmt, $buf);
3744
3745                 if ($r < $rev) {
3746                         $l = $i + 24;
3747                 } elsif ($r > $rev) {
3748                         $u = $i - 24;
3749                 } else { # $r == $rev
3750                         return $c eq ('0' x 40) ? undef : $c;
3751                 }
3752         }
3753         undef;
3754 }
3755
3756 # Finds the first svn revision that exists on (if $eq_ok is true) or
3757 # before $rev for the current branch.  It will not search any lower
3758 # than $min_rev.  Returns the git commit hash and svn revision number
3759 # if found, else (undef, undef).
3760 sub find_rev_before {
3761         my ($self, $rev, $eq_ok, $min_rev) = @_;
3762         --$rev unless $eq_ok;
3763         $min_rev ||= 1;
3764         my $max_rev = $self->rev_map_max;
3765         $rev = $max_rev if ($rev > $max_rev);
3766         while ($rev >= $min_rev) {
3767                 if (my $c = $self->rev_map_get($rev)) {
3768                         return ($rev, $c);
3769                 }
3770                 --$rev;
3771         }
3772         return (undef, undef);
3773 }
3774
3775 # Finds the first svn revision that exists on (if $eq_ok is true) or
3776 # after $rev for the current branch.  It will not search any higher
3777 # than $max_rev.  Returns the git commit hash and svn revision number
3778 # if found, else (undef, undef).
3779 sub find_rev_after {
3780         my ($self, $rev, $eq_ok, $max_rev) = @_;
3781         ++$rev unless $eq_ok;
3782         $max_rev ||= $self->rev_map_max;
3783         while ($rev <= $max_rev) {
3784                 if (my $c = $self->rev_map_get($rev)) {
3785                         return ($rev, $c);
3786                 }
3787                 ++$rev;
3788         }
3789         return (undef, undef);
3790 }
3791
3792 sub _new {
3793         my ($class, $repo_id, $ref_id, $path) = @_;
3794         unless (defined $repo_id && length $repo_id) {
3795                 $repo_id = $Git::SVN::default_repo_id;
3796         }
3797         unless (defined $ref_id && length $ref_id) {
3798                 $_prefix = '' unless defined($_prefix);
3799                 $_[2] = $ref_id =
3800                              "refs/remotes/$_prefix$Git::SVN::default_ref_id";
3801         }
3802         $_[1] = $repo_id;
3803         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3804
3805         # Older repos imported by us used $GIT_DIR/svn/foo instead of
3806         # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
3807         if ($ref_id =~ m{^refs/remotes/(.*)}) {
3808                 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
3809                 if (-d $old_dir && ! -d $dir) {
3810                         $dir = $old_dir;
3811                 }
3812         }
3813
3814         $_[3] = $path = '' unless (defined $path);
3815         mkpath([$dir]);
3816         bless {
3817                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3818                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3819                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3820 }
3821
3822 # for read-only access of old .rev_db formats
3823 sub unlink_rev_db_symlink {
3824         my ($self) = @_;
3825         my $link = $self->rev_db_path;
3826         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3827         if (-l $link) {
3828                 unlink $link or croak "unlink: $link failed!";
3829         }
3830 }
3831
3832 sub rev_db_path {
3833         my ($self, $uuid) = @_;
3834         my $db_path = $self->map_path($uuid);
3835         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3836             or croak "map_path: $db_path does not contain '/.rev_map.' !";
3837         $db_path;
3838 }
3839
3840 # the new replacement for .rev_db
3841 sub map_path {
3842         my ($self, $uuid) = @_;
3843         $uuid ||= $self->ra_uuid;
3844         "$self->{map_root}.$uuid";
3845 }
3846
3847 sub uri_encode {
3848         my ($f) = @_;
3849         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3850         $f
3851 }
3852
3853 sub uri_decode {
3854         my ($f) = @_;
3855         $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
3856         $f
3857 }
3858
3859 sub remove_username {
3860         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3861 }
3862
3863 package Git::SVN::Prompt;
3864 use strict;
3865 use warnings;
3866 require SVN::Core;
3867 use vars qw/$_no_auth_cache $_username/;
3868
3869 sub simple {
3870         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3871         $may_save = undef if $_no_auth_cache;
3872         $default_username = $_username if defined $_username;
3873         if (defined $default_username && length $default_username) {
3874                 if (defined $realm && length $realm) {
3875                         print STDERR "Authentication realm: $realm\n";
3876                         STDERR->flush;
3877                 }
3878                 $cred->username($default_username);
3879         } else {
3880                 username($cred, $realm, $may_save, $pool);
3881         }
3882         $cred->password(_read_password("Password for '" .
3883                                        $cred->username . "': ", $realm));
3884         $cred->may_save($may_save);
3885         $SVN::_Core::SVN_NO_ERROR;
3886 }
3887
3888 sub ssl_server_trust {
3889         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3890         $may_save = undef if $_no_auth_cache;
3891         print STDERR "Error validating server certificate for '$realm':\n";
3892         {
3893                 no warnings 'once';
3894                 # All variables SVN::Auth::SSL::* are used only once,
3895                 # so we're shutting up Perl warnings about this.
3896                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3897                         print STDERR " - The certificate is not issued ",
3898                             "by a trusted authority. Use the\n",
3899                             "   fingerprint to validate ",
3900                             "the certificate manually!\n";
3901                 }
3902                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3903                         print STDERR " - The certificate hostname ",
3904                             "does not match.\n";
3905                 }
3906                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3907                         print STDERR " - The certificate is not yet valid.\n";
3908                 }
3909                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3910                         print STDERR " - The certificate has expired.\n";
3911                 }
3912                 if ($failures & $SVN::Auth::SSL::OTHER) {
3913                         print STDERR " - The certificate has ",
3914                             "an unknown error.\n";
3915                 }
3916         } # no warnings 'once'
3917         printf STDERR
3918                 "Certificate information:\n".
3919                 " - Hostname: %s\n".
3920                 " - Valid: from %s until %s\n".
3921                 " - Issuer: %s\n".
3922                 " - Fingerprint: %s\n",
3923                 map $cert_info->$_, qw(hostname valid_from valid_until
3924                                        issuer_dname fingerprint);
3925         my $choice;
3926 prompt:
3927         print STDERR $may_save ?
3928               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3929               "(R)eject or accept (t)emporarily? ";
3930         STDERR->flush;
3931         $choice = lc(substr(<STDIN> || 'R', 0, 1));
3932         if ($choice =~ /^t$/i) {
3933                 $cred->may_save(undef);
3934         } elsif ($choice =~ /^r$/i) {
3935                 return -1;
3936         } elsif ($may_save && $choice =~ /^p$/i) {
3937                 $cred->may_save($may_save);
3938         } else {
3939                 goto prompt;
3940         }
3941         $cred->accepted_failures($failures);
3942         $SVN::_Core::SVN_NO_ERROR;
3943 }
3944
3945 sub ssl_client_cert {
3946         my ($cred, $realm, $may_save, $pool) = @_;
3947         $may_save = undef if $_no_auth_cache;
3948         print STDERR "Client certificate filename: ";
3949         STDERR->flush;
3950         chomp(my $filename = <STDIN>);
3951         $cred->cert_file($filename);
3952         $cred->may_save($may_save);
3953         $SVN::_Core::SVN_NO_ERROR;
3954 }
3955
3956 sub ssl_client_cert_pw {
3957         my ($cred, $realm, $may_save, $pool) = @_;
3958         $may_save = undef if $_no_auth_cache;
3959         $cred->password(_read_password("Password: ", $realm));
3960         $cred->may_save($may_save);
3961         $SVN::_Core::SVN_NO_ERROR;
3962 }
3963
3964 sub username {
3965         my ($cred, $realm, $may_save, $pool) = @_;
3966         $may_save = undef if $_no_auth_cache;
3967         if (defined $realm && length $realm) {
3968                 print STDERR "Authentication realm: $realm\n";
3969         }
3970         my $username;
3971         if (defined $_username) {
3972                 $username = $_username;
3973         } else {
3974                 print STDERR "Username: ";
3975                 STDERR->flush;
3976                 chomp($username = <STDIN>);
3977         }
3978         $cred->username($username);
3979         $cred->may_save($may_save);
3980         $SVN::_Core::SVN_NO_ERROR;
3981 }
3982
3983 sub _read_password {
3984         my ($prompt, $realm) = @_;
3985         my $password = '';
3986         if (exists $ENV{GIT_ASKPASS}) {
3987                 open(PH, "-|", $ENV{GIT_ASKPASS}, $prompt);
3988                 $password = <PH>;
3989                 $password =~ s/[\012\015]//; # \n\r
3990                 close(PH);
3991         } else {
3992                 print STDERR $prompt;
3993                 STDERR->flush;
3994                 require Term::ReadKey;
3995                 Term::ReadKey::ReadMode('noecho');
3996                 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3997                         last if $key =~ /[\012\015]/; # \n\r
3998                         $password .= $key;
3999                 }
4000                 Term::ReadKey::ReadMode('restore');
4001                 print STDERR "\n";
4002                 STDERR->flush;
4003         }
4004         $password;
4005 }
4006
4007 package SVN::Git::Fetcher;
4008 use vars qw/@ISA/;
4009 use strict;
4010 use warnings;
4011 use Carp qw/croak/;
4012 use IO::File qw//;
4013 use vars qw/$_ignore_regex/;
4014
4015 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
4016 sub new {
4017         my ($class, $git_svn, $switch_path) = @_;
4018         my $self = SVN::Delta::Editor->new;
4019         bless $self, $class;
4020         if (exists $git_svn->{last_commit}) {
4021                 $self->{c} = $git_svn->{last_commit};
4022                 $self->{empty_symlinks} =
4023                                   _mark_empty_symlinks($git_svn, $switch_path);
4024         }
4025         $self->{ignore_regex} = eval { command_oneline('config', '--get',
4026                              "svn-remote.$git_svn->{repo_id}.ignore-paths") };
4027         $self->{empty} = {};
4028         $self->{dir_prop} = {};
4029         $self->{file_prop} = {};
4030         $self->{absent_dir} = {};
4031         $self->{absent_file} = {};
4032         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
4033         $self;
4034 }
4035
4036 # this uses the Ra object, so it must be called before do_{switch,update},
4037 # not inside them (when the Git::SVN::Fetcher object is passed) to
4038 # do_{switch,update}
4039 sub _mark_empty_symlinks {
4040         my ($git_svn, $switch_path) = @_;
4041         my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
4042         return {} if (!defined($bool)) || (defined($bool) && ! $bool);
4043
4044         my %ret;
4045         my ($rev, $cmt) = $git_svn->last_rev_commit;
4046         return {} unless ($rev && $cmt);
4047
4048         # allow the warning to be printed for each revision we fetch to
4049         # ensure the user sees it.  The user can also disable the workaround
4050         # on the repository even while git svn is running and the next
4051         # revision fetched will skip this expensive function.
4052         my $printed_warning;
4053         chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
4054         my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
4055         local $/ = "\0";
4056         my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
4057         $pfx .= '/' if length($pfx);
4058         while (<$ls>) {
4059                 chomp;
4060                 s/\A100644 blob $empty_blob\t//o or next;
4061                 unless ($printed_warning) {
4062                         print STDERR "Scanning for empty symlinks, ",
4063                                      "this may take a while if you have ",
4064                                      "many empty files\n",
4065                                      "You may disable this with `",
4066                                      "git config svn.brokenSymlinkWorkaround ",
4067                                      "false'.\n",
4068                                      "This may be done in a different ",
4069                                      "terminal without restarting ",
4070                                      "git svn\n";
4071                         $printed_warning = 1;
4072                 }
4073                 my $path = $_;
4074                 my (undef, $props) =
4075                                $git_svn->ra->get_file($pfx.$path, $rev, undef);
4076                 if ($props->{'svn:special'}) {
4077                         $ret{$path} = 1;
4078                 }
4079         }
4080         command_close_pipe($ls, $ctx);
4081         \%ret;
4082 }
4083
4084 # returns true if a given path is inside a ".git" directory
4085 sub in_dot_git {
4086         $_[0] =~ m{(?:^|/)\.git(?:/|$)};
4087 }
4088
4089 # return value: 0 -- don't ignore, 1 -- ignore
4090 sub is_path_ignored {
4091         my ($self, $path) = @_;
4092         return 1 if in_dot_git($path);
4093         return 1 if defined($self->{ignore_regex}) &&
4094                     $path =~ m!$self->{ignore_regex}!;
4095         return 0 unless defined($_ignore_regex);
4096         return 1 if $path =~ m!$_ignore_regex!o;
4097         return 0;
4098 }
4099
4100 sub set_path_strip {
4101         my ($self, $path) = @_;
4102         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
4103 }
4104
4105 sub open_root {
4106         { path => '' };
4107 }
4108
4109 sub open_directory {
4110         my ($self, $path, $pb, $rev) = @_;
4111         { path => $path };
4112 }
4113
4114 sub git_path {
4115         my ($self, $path) = @_;
4116         if ($self->{path_strip}) {
4117                 $path =~ s!$self->{path_strip}!! or
4118                   die "Failed to strip path '$path' ($self->{path_strip})\n";
4119         }
4120         $path;
4121 }
4122
4123 sub delete_entry {
4124         my ($self, $path, $rev, $pb) = @_;
4125         return undef if $self->is_path_ignored($path);
4126
4127         my $gpath = $self->git_path($path);
4128         return undef if ($gpath eq '');
4129
4130         # remove entire directories.
4131         my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4132                          =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
4133         if ($tree) {
4134                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4135                                                      -r --name-only -z/,
4136                                                      $tree);
4137                 local $/ = "\0";
4138                 while (<$ls>) {
4139                         chomp;
4140                         my $rmpath = "$gpath/$_";
4141                         $self->{gii}->remove($rmpath);
4142                         print "\tD\t$rmpath\n" unless $::_q;
4143                 }
4144                 print "\tD\t$gpath/\n" unless $::_q;
4145                 command_close_pipe($ls, $ctx);
4146         } else {
4147                 $self->{gii}->remove($gpath);
4148                 print "\tD\t$gpath\n" unless $::_q;
4149         }
4150         $self->{empty}->{$path} = 0;
4151         undef;
4152 }
4153
4154 sub open_file {
4155         my ($self, $path, $pb, $rev) = @_;
4156         my ($mode, $blob);
4157
4158         goto out if $self->is_path_ignored($path);
4159
4160         my $gpath = $self->git_path($path);
4161         ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4162                              =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
4163         unless (defined $mode && defined $blob) {
4164                 die "$path was not found in commit $self->{c} (r$rev)\n";
4165         }
4166         if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
4167                 $mode = '120000';
4168         }
4169 out:
4170         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
4171           pool => SVN::Pool->new, action => 'M' };
4172 }
4173
4174 sub add_file {
4175         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
4176         my $mode;
4177
4178         if (!$self->is_path_ignored($path)) {
4179                 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4180                 delete $self->{empty}->{$dir};
4181                 $mode = '100644';
4182         }
4183         { path => $path, mode_a => $mode, mode_b => $mode,
4184           pool => SVN::Pool->new, action => 'A' };
4185 }
4186
4187 sub add_directory {
4188         my ($self, $path, $cp_path, $cp_rev) = @_;
4189         goto out if $self->is_path_ignored($path);
4190         my $gpath = $self->git_path($path);
4191         if ($gpath eq '') {
4192                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4193                                                      -r --name-only -z/,
4194                                                      $self->{c});
4195                 local $/ = "\0";
4196                 while (<$ls>) {
4197                         chomp;
4198                         $self->{gii}->remove($_);
4199                         print "\tD\t$_\n" unless $::_q;
4200                 }
4201                 command_close_pipe($ls, $ctx);
4202                 $self->{empty}->{$path} = 0;
4203         }
4204         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4205         delete $self->{empty}->{$dir};
4206         $self->{empty}->{$path} = 1;
4207 out:
4208         { path => $path };
4209 }
4210
4211 sub change_dir_prop {
4212         my ($self, $db, $prop, $value) = @_;
4213         return undef if $self->is_path_ignored($db->{path});
4214         $self->{dir_prop}->{$db->{path}} ||= {};
4215         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
4216         undef;
4217 }
4218
4219 sub absent_directory {
4220         my ($self, $path, $pb) = @_;
4221         return undef if $self->is_path_ignored($path);
4222         $self->{absent_dir}->{$pb->{path}} ||= [];
4223         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
4224         undef;
4225 }
4226
4227 sub absent_file {
4228         my ($self, $path, $pb) = @_;
4229         return undef if $self->is_path_ignored($path);
4230         $self->{absent_file}->{$pb->{path}} ||= [];
4231         push @{$self->{absent_file}->{$pb->{path}}}, $path;
4232         undef;
4233 }
4234
4235 sub change_file_prop {
4236         my ($self, $fb, $prop, $value) = @_;
4237         return undef if $self->is_path_ignored($fb->{path});
4238         if ($prop eq 'svn:executable') {
4239                 if ($fb->{mode_b} != 120000) {
4240                         $fb->{mode_b} = defined $value ? 100755 : 100644;
4241                 }
4242         } elsif ($prop eq 'svn:special') {
4243                 $fb->{mode_b} = defined $value ? 120000 : 100644;
4244         } else {
4245                 $self->{file_prop}->{$fb->{path}} ||= {};
4246                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
4247         }
4248         undef;
4249 }
4250
4251 sub apply_textdelta {
4252         my ($self, $fb, $exp) = @_;
4253         return undef if $self->is_path_ignored($fb->{path});
4254         my $fh = $::_repository->temp_acquire('svn_delta');
4255         # $fh gets auto-closed() by SVN::TxDelta::apply(),
4256         # (but $base does not,) so dup() it for reading in close_file
4257         open my $dup, '<&', $fh or croak $!;
4258         my $base = $::_repository->temp_acquire('git_blob');
4259
4260         if ($fb->{blob}) {
4261                 my ($base_is_link, $size);
4262
4263                 if ($fb->{mode_a} eq '120000' &&
4264                     ! $self->{empty_symlinks}->{$fb->{path}}) {
4265                         print $base 'link ' or die "print $!\n";
4266                         $base_is_link = 1;
4267                 }
4268         retry:
4269                 $size = $::_repository->cat_blob($fb->{blob}, $base);
4270                 die "Failed to read object $fb->{blob}" if ($size < 0);
4271
4272                 if (defined $exp) {
4273                         seek $base, 0, 0 or croak $!;
4274                         my $got = ::md5sum($base);
4275                         if ($got ne $exp) {
4276                                 my $err = "Checksum mismatch: ".
4277                                        "$fb->{path} $fb->{blob}\n" .
4278                                        "expected: $exp\n" .
4279                                        "     got: $got\n";
4280                                 if ($base_is_link) {
4281                                         warn $err,
4282                                              "Retrying... (possibly ",
4283                                              "a bad symlink from SVN)\n";
4284                                         $::_repository->temp_reset($base);
4285                                         $base_is_link = 0;
4286                                         goto retry;
4287                                 }
4288                                 die $err;
4289                         }
4290                 }
4291         }
4292         seek $base, 0, 0 or croak $!;
4293         $fb->{fh} = $fh;
4294         $fb->{base} = $base;
4295         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
4296 }
4297
4298 sub close_file {
4299         my ($self, $fb, $exp) = @_;
4300         return undef if $self->is_path_ignored($fb->{path});
4301
4302         my $hash;
4303         my $path = $self->git_path($fb->{path});
4304         if (my $fh = $fb->{fh}) {
4305                 if (defined $exp) {
4306                         seek($fh, 0, 0) or croak $!;
4307                         my $got = ::md5sum($fh);
4308                         if ($got ne $exp) {
4309                                 die "Checksum mismatch: $path\n",
4310                                     "expected: $exp\n    got: $got\n";
4311                         }
4312                 }
4313                 if ($fb->{mode_b} == 120000) {
4314                         sysseek($fh, 0, 0) or croak $!;
4315                         my $rd = sysread($fh, my $buf, 5);
4316
4317                         if (!defined $rd) {
4318                                 croak "sysread: $!\n";
4319                         } elsif ($rd == 0) {
4320                                 warn "$path has mode 120000",
4321                                      " but it points to nothing\n",
4322                                      "converting to an empty file with mode",
4323                                      " 100644\n";
4324                                 $fb->{mode_b} = '100644';
4325                         } elsif ($buf ne 'link ') {
4326                                 warn "$path has mode 120000",
4327                                      " but is not a link\n";
4328                         } else {
4329                                 my $tmp_fh = $::_repository->temp_acquire(
4330                                         'svn_hash');
4331                                 my $res;
4332                                 while ($res = sysread($fh, my $str, 1024)) {
4333                                         my $out = syswrite($tmp_fh, $str, $res);
4334                                         defined($out) && $out == $res
4335                                                 or croak("write ",
4336                                                         Git::temp_path($tmp_fh),
4337                                                         ": $!\n");
4338                                 }
4339                                 defined $res or croak $!;
4340
4341                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
4342                                 Git::temp_release($tmp_fh, 1);
4343                         }
4344                 }
4345
4346                 $hash = $::_repository->hash_and_insert_object(
4347                                 Git::temp_path($fh));
4348                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
4349
4350                 Git::temp_release($fb->{base}, 1);
4351                 Git::temp_release($fh, 1);
4352         } else {
4353                 $hash = $fb->{blob} or die "no blob information\n";
4354         }
4355         $fb->{pool}->clear;
4356         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
4357         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
4358         undef;
4359 }
4360
4361 sub abort_edit {
4362         my $self = shift;
4363         $self->{nr} = $self->{gii}->{nr};
4364         delete $self->{gii};
4365         $self->SUPER::abort_edit(@_);
4366 }
4367
4368 sub close_edit {
4369         my $self = shift;
4370         $self->{git_commit_ok} = 1;
4371         $self->{nr} = $self->{gii}->{nr};
4372         delete $self->{gii};
4373         $self->SUPER::close_edit(@_);
4374 }
4375
4376 package SVN::Git::Editor;
4377 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
4378 use strict;
4379 use warnings;
4380 use Carp qw/croak/;
4381 use IO::File;
4382
4383 sub new {
4384         my ($class, $opts) = @_;
4385         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
4386                 die "$_ required!\n" unless (defined $opts->{$_});
4387         }
4388
4389         my $pool = SVN::Pool->new;
4390         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
4391         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
4392                                      $opts->{r}, $mods);
4393
4394         # $opts->{ra} functions should not be used after this:
4395         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
4396                                                 $opts->{editor_cb}, $pool);
4397         my $self = SVN::Delta::Editor->new(@ce, $pool);
4398         bless $self, $class;
4399         foreach (qw/svn_path r tree_a tree_b/) {
4400                 $self->{$_} = $opts->{$_};
4401         }
4402         $self->{url} = $opts->{ra}->{url};
4403         $self->{mods} = $mods;
4404         $self->{types} = $types;
4405         $self->{pool} = $pool;
4406         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
4407         $self->{rm} = { };
4408         $self->{path_prefix} = length $self->{svn_path} ?
4409                                "$self->{svn_path}/" : '';
4410         $self->{config} = $opts->{config};
4411         return $self;
4412 }
4413
4414 sub generate_diff {
4415         my ($tree_a, $tree_b) = @_;
4416         my @diff_tree = qw(diff-tree -z -r);
4417         if ($_cp_similarity) {
4418                 push @diff_tree, "-C$_cp_similarity";
4419         } else {
4420                 push @diff_tree, '-C';
4421         }
4422         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
4423         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
4424         push @diff_tree, $tree_a, $tree_b;
4425         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
4426         local $/ = "\0";
4427         my $state = 'meta';
4428         my @mods;
4429         while (<$diff_fh>) {
4430                 chomp $_; # this gets rid of the trailing "\0"
4431                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
4432                                         ($::sha1)\s($::sha1)\s
4433                                         ([MTCRAD])\d*$/xo) {
4434                         push @mods, {   mode_a => $1, mode_b => $2,
4435                                         sha1_a => $3, sha1_b => $4,
4436                                         chg => $5 };
4437                         if ($5 =~ /^(?:C|R)$/) {
4438                                 $state = 'file_a';
4439                         } else {
4440                                 $state = 'file_b';
4441                         }
4442                 } elsif ($state eq 'file_a') {
4443                         my $x = $mods[$#mods] or croak "Empty array\n";
4444                         if ($x->{chg} !~ /^(?:C|R)$/) {
4445                                 croak "Error parsing $_, $x->{chg}\n";
4446                         }
4447                         $x->{file_a} = $_;
4448                         $state = 'file_b';
4449                 } elsif ($state eq 'file_b') {
4450                         my $x = $mods[$#mods] or croak "Empty array\n";
4451                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
4452                                 croak "Error parsing $_, $x->{chg}\n";
4453                         }
4454                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
4455                                 croak "Error parsing $_, $x->{chg}\n";
4456                         }
4457                         $x->{file_b} = $_;
4458                         $state = 'meta';
4459                 } else {
4460                         croak "Error parsing $_\n";
4461                 }
4462         }
4463         command_close_pipe($diff_fh, $ctx);
4464         \@mods;
4465 }
4466
4467 sub check_diff_paths {
4468         my ($ra, $pfx, $rev, $mods) = @_;
4469         my %types;
4470         $pfx .= '/' if length $pfx;
4471
4472         sub type_diff_paths {
4473                 my ($ra, $types, $path, $rev) = @_;
4474                 my @p = split m#/+#, $path;
4475                 my $c = shift @p;
4476                 unless (defined $types->{$c}) {
4477                         $types->{$c} = $ra->check_path($c, $rev);
4478                 }
4479                 while (@p) {
4480                         $c .= '/' . shift @p;
4481                         next if defined $types->{$c};
4482                         $types->{$c} = $ra->check_path($c, $rev);
4483                 }
4484         }
4485
4486         foreach my $m (@$mods) {
4487                 foreach my $f (qw/file_a file_b/) {
4488                         next unless defined $m->{$f};
4489                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
4490                         if (length $pfx.$dir && ! defined $types{$dir}) {
4491                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
4492                         }
4493                 }
4494         }
4495         \%types;
4496 }
4497
4498 sub split_path {
4499         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
4500 }
4501
4502 sub repo_path {
4503         my ($self, $path) = @_;
4504         $self->{path_prefix}.(defined $path ? $path : '');
4505 }
4506
4507 sub url_path {
4508         my ($self, $path) = @_;
4509         if ($self->{url} =~ m#^https?://#) {
4510                 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4511         }
4512         $self->{url} . '/' . $self->repo_path($path);
4513 }
4514
4515 sub rmdirs {
4516         my ($self) = @_;
4517         my $rm = $self->{rm};
4518         delete $rm->{''}; # we never delete the url we're tracking
4519         return unless %$rm;
4520
4521         foreach (keys %$rm) {
4522                 my @d = split m#/#, $_;
4523                 my $c = shift @d;
4524                 $rm->{$c} = 1;
4525                 while (@d) {
4526                         $c .= '/' . shift @d;
4527                         $rm->{$c} = 1;
4528                 }
4529         }
4530         delete $rm->{$self->{svn_path}};
4531         delete $rm->{''}; # we never delete the url we're tracking
4532         return unless %$rm;
4533
4534         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4535                                              $self->{tree_b});
4536         local $/ = "\0";
4537         while (<$fh>) {
4538                 chomp;
4539                 my @dn = split m#/#, $_;
4540                 while (pop @dn) {
4541                         delete $rm->{join '/', @dn};
4542                 }
4543                 unless (%$rm) {
4544                         close $fh;
4545                         return;
4546                 }
4547         }
4548         command_close_pipe($fh, $ctx);
4549
4550         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4551         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4552                 $self->close_directory($bat->{$d}, $p);
4553                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4554                 print "\tD+\t$d/\n" unless $::_q;
4555                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4556                 delete $bat->{$d};
4557         }
4558 }
4559
4560 sub open_or_add_dir {
4561         my ($self, $full_path, $baton) = @_;
4562         my $t = $self->{types}->{$full_path};
4563         if (!defined $t) {
4564                 die "$full_path not known in r$self->{r} or we have a bug!\n";
4565         }
4566         {
4567                 no warnings 'once';
4568                 # SVN::Node::none and SVN::Node::file are used only once,
4569                 # so we're shutting up Perl's warnings about them.
4570                 if ($t == $SVN::Node::none) {
4571                         return $self->add_directory($full_path, $baton,
4572                             undef, -1, $self->{pool});
4573                 } elsif ($t == $SVN::Node::dir) {
4574                         return $self->open_directory($full_path, $baton,
4575                             $self->{r}, $self->{pool});
4576                 } # no warnings 'once'
4577                 print STDERR "$full_path already exists in repository at ",
4578                     "r$self->{r} and it is not a directory (",
4579                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4580         } # no warnings 'once'
4581         exit 1;
4582 }
4583
4584 sub ensure_path {
4585         my ($self, $path) = @_;
4586         my $bat = $self->{bat};
4587         my $repo_path = $self->repo_path($path);
4588         return $bat->{''} unless (length $repo_path);
4589         my @p = split m#/+#, $repo_path;
4590         my $c = shift @p;
4591         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4592         while (@p) {
4593                 my $c0 = $c;
4594                 $c .= '/' . shift @p;
4595                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4596         }
4597         return $bat->{$c};
4598 }
4599
4600 # Subroutine to convert a globbing pattern to a regular expression.
4601 # From perl cookbook.
4602 sub glob2pat {
4603         my $globstr = shift;
4604         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4605         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4606         return '^' . $globstr . '$';
4607 }
4608
4609 sub check_autoprop {
4610         my ($self, $pattern, $properties, $file, $fbat) = @_;
4611         # Convert the globbing pattern to a regular expression.
4612         my $regex = glob2pat($pattern);
4613         # Check if the pattern matches the file name.
4614         if($file =~ m/($regex)/) {
4615                 # Parse the list of properties to set.
4616                 my @props = split(/;/, $properties);
4617                 foreach my $prop (@props) {
4618                         # Parse 'name=value' syntax and set the property.
4619                         if ($prop =~ /([^=]+)=(.*)/) {
4620                                 my ($n,$v) = ($1,$2);
4621                                 for ($n, $v) {
4622                                         s/^\s+//; s/\s+$//;
4623                                 }
4624                                 $self->change_file_prop($fbat, $n, $v);
4625                         }
4626                 }
4627         }
4628 }
4629
4630 sub apply_autoprops {
4631         my ($self, $file, $fbat) = @_;
4632         my $conf_t = ${$self->{config}}{'config'};
4633         no warnings 'once';
4634         # Check [miscellany]/enable-auto-props in svn configuration.
4635         if (SVN::_Core::svn_config_get_bool(
4636                 $conf_t,
4637                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4638                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4639                 0)) {
4640                 # Auto-props are enabled.  Enumerate them to look for matches.
4641                 my $callback = sub {
4642                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
4643                 };
4644                 SVN::_Core::svn_config_enumerate(
4645                         $conf_t,
4646                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4647                         $callback);
4648         }
4649 }
4650
4651 sub A {
4652         my ($self, $m) = @_;
4653         my ($dir, $file) = split_path($m->{file_b});
4654         my $pbat = $self->ensure_path($dir);
4655         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4656                                         undef, -1);
4657         print "\tA\t$m->{file_b}\n" unless $::_q;
4658         $self->apply_autoprops($file, $fbat);
4659         $self->chg_file($fbat, $m);
4660         $self->close_file($fbat,undef,$self->{pool});
4661 }
4662
4663 sub C {
4664         my ($self, $m) = @_;
4665         my ($dir, $file) = split_path($m->{file_b});
4666         my $pbat = $self->ensure_path($dir);
4667         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4668                                 $self->url_path($m->{file_a}), $self->{r});
4669         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4670         $self->chg_file($fbat, $m);
4671         $self->close_file($fbat,undef,$self->{pool});
4672 }
4673
4674 sub delete_entry {
4675         my ($self, $path, $pbat) = @_;
4676         my $rpath = $self->repo_path($path);
4677         my ($dir, $file) = split_path($rpath);
4678         $self->{rm}->{$dir} = 1;
4679         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4680 }
4681
4682 sub R {
4683         my ($self, $m) = @_;
4684         my ($dir, $file) = split_path($m->{file_b});
4685         my $pbat = $self->ensure_path($dir);
4686         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4687                                 $self->url_path($m->{file_a}), $self->{r});
4688         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4689         $self->apply_autoprops($file, $fbat);
4690         $self->chg_file($fbat, $m);
4691         $self->close_file($fbat,undef,$self->{pool});
4692
4693         ($dir, $file) = split_path($m->{file_a});
4694         $pbat = $self->ensure_path($dir);
4695         $self->delete_entry($m->{file_a}, $pbat);
4696 }
4697
4698 sub M {
4699         my ($self, $m) = @_;
4700         my ($dir, $file) = split_path($m->{file_b});
4701         my $pbat = $self->ensure_path($dir);
4702         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4703                                 $pbat,$self->{r},$self->{pool});
4704         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4705         $self->chg_file($fbat, $m);
4706         $self->close_file($fbat,undef,$self->{pool});
4707 }
4708
4709 sub T { shift->M(@_) }
4710
4711 sub change_file_prop {
4712         my ($self, $fbat, $pname, $pval) = @_;
4713         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4714 }
4715
4716 sub _chg_file_get_blob ($$$$) {
4717         my ($self, $fbat, $m, $which) = @_;
4718         my $fh = $::_repository->temp_acquire("git_blob_$which");
4719         if ($m->{"mode_$which"} =~ /^120/) {
4720                 print $fh 'link ' or croak $!;
4721                 $self->change_file_prop($fbat,'svn:special','*');
4722         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4723                 $self->change_file_prop($fbat,'svn:special',undef);
4724         }
4725         my $blob = $m->{"sha1_$which"};
4726         return ($fh,) if ($blob =~ /^0{40}$/);
4727         my $size = $::_repository->cat_blob($blob, $fh);
4728         croak "Failed to read object $blob" if ($size < 0);
4729         $fh->flush == 0 or croak $!;
4730         seek $fh, 0, 0 or croak $!;
4731
4732         my $exp = ::md5sum($fh);
4733         seek $fh, 0, 0 or croak $!;
4734         return ($fh, $exp);
4735 }
4736
4737 sub chg_file {
4738         my ($self, $fbat, $m) = @_;
4739         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4740                 $self->change_file_prop($fbat,'svn:executable','*');
4741         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4742                 $self->change_file_prop($fbat,'svn:executable',undef);
4743         }
4744         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4745         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4746         my $pool = SVN::Pool->new;
4747         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4748         if (-s $fh_a) {
4749                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4750                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4751                 if (defined $res) {
4752                         die "Unexpected result from send_txstream: $res\n",
4753                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4754                 }
4755         } else {
4756                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4757                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4758                     if ($got ne $exp_b);
4759         }
4760         Git::temp_release($fh_b, 1);
4761         Git::temp_release($fh_a, 1);
4762         $pool->clear;
4763 }
4764
4765 sub D {
4766         my ($self, $m) = @_;
4767         my ($dir, $file) = split_path($m->{file_b});
4768         my $pbat = $self->ensure_path($dir);
4769         print "\tD\t$m->{file_b}\n" unless $::_q;
4770         $self->delete_entry($m->{file_b}, $pbat);
4771 }
4772
4773 sub close_edit {
4774         my ($self) = @_;
4775         my ($p,$bat) = ($self->{pool}, $self->{bat});
4776         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4777                 next if $_ eq '';
4778                 $self->close_directory($bat->{$_}, $p);
4779         }
4780         $self->close_directory($bat->{''}, $p);
4781         $self->SUPER::close_edit($p);
4782         $p->clear;
4783 }
4784
4785 sub abort_edit {
4786         my ($self) = @_;
4787         $self->SUPER::abort_edit($self->{pool});
4788 }
4789
4790 sub DESTROY {
4791         my $self = shift;
4792         $self->SUPER::DESTROY(@_);
4793         $self->{pool}->clear;
4794 }
4795
4796 # this drives the editor
4797 sub apply_diff {
4798         my ($self) = @_;
4799         my $mods = $self->{mods};
4800         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4801         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4802                 my $f = $m->{chg};
4803                 if (defined $o{$f}) {
4804                         $self->$f($m);
4805                 } else {
4806                         fatal("Invalid change type: $f");
4807                 }
4808         }
4809         $self->rmdirs if $_rmdir;
4810         if (@$mods == 0) {
4811                 $self->abort_edit;
4812         } else {
4813                 $self->close_edit;
4814         }
4815         return scalar @$mods;
4816 }
4817
4818 package Git::SVN::Ra;
4819 use vars qw/@ISA $config_dir $_log_window_size/;
4820 use strict;
4821 use warnings;
4822 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4823
4824 BEGIN {
4825         # enforce temporary pool usage for some simple functions
4826         no strict 'refs';
4827         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4828                       get_file/) {
4829                 my $SUPER = "SUPER::$f";
4830                 *$f = sub {
4831                         my $self = shift;
4832                         my $pool = SVN::Pool->new;
4833                         my @ret = $self->$SUPER(@_,$pool);
4834                         $pool->clear;
4835                         wantarray ? @ret : $ret[0];
4836                 };
4837         }
4838 }
4839
4840 sub _auth_providers () {
4841         [
4842           SVN::Client::get_simple_provider(),
4843           SVN::Client::get_ssl_server_trust_file_provider(),
4844           SVN::Client::get_simple_prompt_provider(
4845             \&Git::SVN::Prompt::simple, 2),
4846           SVN::Client::get_ssl_client_cert_file_provider(),
4847           SVN::Client::get_ssl_client_cert_prompt_provider(
4848             \&Git::SVN::Prompt::ssl_client_cert, 2),
4849           SVN::Client::get_ssl_client_cert_pw_file_provider(),
4850           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4851             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4852           SVN::Client::get_username_provider(),
4853           SVN::Client::get_ssl_server_trust_prompt_provider(
4854             \&Git::SVN::Prompt::ssl_server_trust),
4855           SVN::Client::get_username_prompt_provider(
4856             \&Git::SVN::Prompt::username, 2)
4857         ]
4858 }
4859
4860 sub escape_uri_only {
4861         my ($uri) = @_;
4862         my @tmp;
4863         foreach (split m{/}, $uri) {
4864                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4865                 push @tmp, $_;
4866         }
4867         join('/', @tmp);
4868 }
4869
4870 sub escape_url {
4871         my ($url) = @_;
4872         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4873                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4874                 $url = "$scheme://$domain$uri";
4875         }
4876         $url;
4877 }
4878
4879 sub new {
4880         my ($class, $url) = @_;
4881         $url =~ s!/+$!!;
4882         return $RA if ($RA && $RA->{url} eq $url);
4883
4884         ::_req_svn();
4885
4886         SVN::_Core::svn_config_ensure($config_dir, undef);
4887         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4888         my $config = SVN::Core::config_get_config($config_dir);
4889         $RA = undef;
4890         my $dont_store_passwords = 1;
4891         my $conf_t = ${$config}{'config'};
4892         {
4893                 no warnings 'once';
4894                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4895                 # produces warnings that variables are used only once.
4896                 # I had not found the better way to shut them up, so
4897                 # the warnings of type 'once' are disabled in this block.
4898                 if (SVN::_Core::svn_config_get_bool($conf_t,
4899                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4900                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4901                     1) == 0) {
4902                         SVN::_Core::svn_auth_set_parameter($baton,
4903                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4904                             bless (\$dont_store_passwords, "_p_void"));
4905                 }
4906                 if (SVN::_Core::svn_config_get_bool($conf_t,
4907                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4908                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4909                     1) == 0) {
4910                         $Git::SVN::Prompt::_no_auth_cache = 1;
4911                 }
4912         } # no warnings 'once'
4913         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4914                               config => $config,
4915                               pool => SVN::Pool->new,
4916                               auth_provider_callbacks => $callbacks);
4917         $self->{url} = $url;
4918         $self->{svn_path} = $url;
4919         $self->{repos_root} = $self->get_repos_root;
4920         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4921         $self->{cache} = { check_path => { r => 0, data => {} },
4922                            get_dir => { r => 0, data => {} } };
4923         $RA = bless $self, $class;
4924 }
4925
4926 sub check_path {
4927         my ($self, $path, $r) = @_;
4928         my $cache = $self->{cache}->{check_path};
4929         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4930                 return $cache->{data}->{$path};
4931         }
4932         my $pool = SVN::Pool->new;
4933         my $t = $self->SUPER::check_path($path, $r, $pool);
4934         $pool->clear;
4935         if ($r != $cache->{r}) {
4936                 %{$cache->{data}} = ();
4937                 $cache->{r} = $r;
4938         }
4939         $cache->{data}->{$path} = $t;
4940 }
4941
4942 sub get_dir {
4943         my ($self, $dir, $r) = @_;
4944         my $cache = $self->{cache}->{get_dir};
4945         if ($r == $cache->{r}) {
4946                 if (my $x = $cache->{data}->{$dir}) {
4947                         return wantarray ? @$x : $x->[0];
4948                 }
4949         }
4950         my $pool = SVN::Pool->new;
4951         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4952         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4953         $pool->clear;
4954         if ($r != $cache->{r}) {
4955                 %{$cache->{data}} = ();
4956                 $cache->{r} = $r;
4957         }
4958         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
4959         wantarray ? (\%dirents, $r, $props) : \%dirents;
4960 }
4961
4962 sub DESTROY {
4963         # do not call the real DESTROY since we store ourselves in $RA
4964 }
4965
4966 # get_log(paths, start, end, limit,
4967 #         discover_changed_paths, strict_node_history, receiver)
4968 sub get_log {
4969         my ($self, @args) = @_;
4970         my $pool = SVN::Pool->new;
4971
4972         # svn_log_changed_path_t objects passed to get_log are likely to be
4973         # overwritten even if only the refs are copied to an external variable,
4974         # so we should dup the structures in their entirety.  Using an
4975         # externally passed pool (instead of our temporary and quickly cleared
4976         # pool in Git::SVN::Ra) does not help matters at all...
4977         my $receiver = pop @args;
4978         my $prefix = "/".$self->{svn_path};
4979         $prefix =~ s#/+($)##;
4980         my $prefix_regex = qr#^\Q$prefix\E#;
4981         push(@args, sub {
4982                 my ($paths) = $_[0];
4983                 return &$receiver(@_) unless $paths;
4984                 $_[0] = ();
4985                 foreach my $p (keys %$paths) {
4986                         my $i = $paths->{$p};
4987                         # Make path relative to our url, not repos_root
4988                         $p =~ s/$prefix_regex//;
4989                         my %s = map { $_ => $i->$_; }
4990                                 qw/copyfrom_path copyfrom_rev action/;
4991                         if ($s{'copyfrom_path'}) {
4992                                 $s{'copyfrom_path'} =~ s/$prefix_regex//;
4993                         }
4994                         $_[0]{$p} = \%s;
4995                 }
4996                 &$receiver(@_);
4997         });
4998
4999
5000         # the limit parameter was not supported in SVN 1.1.x, so we
5001         # drop it.  Therefore, the receiver callback passed to it
5002         # is made aware of this limitation by being wrapped if
5003         # the limit passed to is being wrapped.
5004         if ($SVN::Core::VERSION le '1.2.0') {
5005                 my $limit = splice(@args, 3, 1);
5006                 if ($limit > 0) {
5007                         my $receiver = pop @args;
5008                         push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
5009                 }
5010         }
5011         my $ret = $self->SUPER::get_log(@args, $pool);
5012         $pool->clear;
5013         $ret;
5014 }
5015
5016 sub trees_match {
5017         my ($self, $url1, $rev1, $url2, $rev2) = @_;
5018         my $ctx = SVN::Client->new(auth => _auth_providers);
5019         my $out = IO::File->new_tmpfile;
5020
5021         # older SVN (1.1.x) doesn't take $pool as the last parameter for
5022         # $ctx->diff(), so we'll create a default one
5023         my $pool = SVN::Pool->new_default_sub;
5024
5025         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
5026         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
5027         $out->flush;
5028         my $ret = (($out->stat)[7] == 0);
5029         close $out or croak $!;
5030
5031         $ret;
5032 }
5033
5034 sub get_commit_editor {
5035         my ($self, $log, $cb, $pool) = @_;
5036         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
5037         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
5038 }
5039
5040 sub gs_do_update {
5041         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
5042         my $new = ($rev_a == $rev_b);
5043         my $path = $gs->{path};
5044
5045         if ($new && -e $gs->{index}) {
5046                 unlink $gs->{index} or die
5047                   "Couldn't unlink index: $gs->{index}: $!\n";
5048         }
5049         my $pool = SVN::Pool->new;
5050         $editor->set_path_strip($path);
5051         my (@pc) = split m#/#, $path;
5052         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
5053                                         1, $editor, $pool);
5054         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5055
5056         # Since we can't rely on svn_ra_reparent being available, we'll
5057         # just have to do some magic with set_path to make it so
5058         # we only want a partial path.
5059         my $sp = '';
5060         my $final = join('/', @pc);
5061         while (@pc) {
5062                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
5063                 $sp .= '/' if length $sp;
5064                 $sp .= shift @pc;
5065         }
5066         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
5067
5068         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
5069
5070         $reporter->finish_report($pool);
5071         $pool->clear;
5072         $editor->{git_commit_ok};
5073 }
5074
5075 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
5076 # svn_ra_reparent didn't work before 1.4)
5077 sub gs_do_switch {
5078         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
5079         my $path = $gs->{path};
5080         my $pool = SVN::Pool->new;
5081
5082         my $full_url = $self->{url};
5083         my $old_url = $full_url;
5084         $full_url .= '/' . $path if length $path;
5085         my ($ra, $reparented);
5086
5087         if ($old_url =~ m#^svn(\+ssh)?://# ||
5088             ($full_url =~ m#^https?://# &&
5089              escape_url($full_url) ne $full_url)) {
5090                 $_[0] = undef;
5091                 $self = undef;
5092                 $RA = undef;
5093                 $ra = Git::SVN::Ra->new($full_url);
5094                 $ra_invalid = 1;
5095         } elsif ($old_url ne $full_url) {
5096                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
5097                 $self->{url} = $full_url;
5098                 $reparented = 1;
5099         }
5100
5101         $ra ||= $self;
5102         $url_b = escape_url($url_b);
5103         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
5104         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5105         $reporter->set_path('', $rev_a, 0, @lock, $pool);
5106         $reporter->finish_report($pool);
5107
5108         if ($reparented) {
5109                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
5110                 $self->{url} = $old_url;
5111         }
5112
5113         $pool->clear;
5114         $editor->{git_commit_ok};
5115 }
5116
5117 sub longest_common_path {
5118         my ($gsv, $globs) = @_;
5119         my %common;
5120         my $common_max = scalar @$gsv;
5121
5122         foreach my $gs (@$gsv) {
5123                 my @tmp = split m#/#, $gs->{path};
5124                 my $p = '';
5125                 foreach (@tmp) {
5126                         $p .= length($p) ? "/$_" : $_;
5127                         $common{$p} ||= 0;
5128                         $common{$p}++;
5129                 }
5130         }
5131         $globs ||= [];
5132         $common_max += scalar @$globs;
5133         foreach my $glob (@$globs) {
5134                 my @tmp = split m#/#, $glob->{path}->{left};
5135                 my $p = '';
5136                 foreach (@tmp) {
5137                         $p .= length($p) ? "/$_" : $_;
5138                         $common{$p} ||= 0;
5139                         $common{$p}++;
5140                 }
5141         }
5142
5143         my $longest_path = '';
5144         foreach (sort {length $b <=> length $a} keys %common) {
5145                 if ($common{$_} == $common_max) {
5146                         $longest_path = $_;
5147                         last;
5148                 }
5149         }
5150         $longest_path;
5151 }
5152
5153 sub gs_fetch_loop_common {
5154         my ($self, $base, $head, $gsv, $globs) = @_;
5155         return if ($base > $head);
5156         my $inc = $_log_window_size;
5157         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
5158         my $longest_path = longest_common_path($gsv, $globs);
5159         my $ra_url = $self->{url};
5160         my $find_trailing_edge;
5161         while (1) {
5162                 my %revs;
5163                 my $err;
5164                 my $err_handler = $SVN::Error::handler;
5165                 $SVN::Error::handler = sub {
5166                         ($err) = @_;
5167                         skip_unknown_revs($err);
5168                 };
5169                 sub _cb {
5170                         my ($paths, $r, $author, $date, $log) = @_;
5171                         [ $paths,
5172                           { author => $author, date => $date, log => $log } ];
5173                 }
5174                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
5175                                sub { $revs{$_[1]} = _cb(@_) });
5176                 if ($err) {
5177                         print "Checked through r$max\r";
5178                 } else {
5179                         $find_trailing_edge = 1;
5180                 }
5181                 if ($err and $find_trailing_edge) {
5182                         print STDERR "Path '$longest_path' ",
5183                                      "was probably deleted:\n",
5184                                      $err->expanded_message,
5185                                      "\nWill attempt to follow ",
5186                                      "revisions r$min .. r$max ",
5187                                      "committed before the deletion\n";
5188                         my $hi = $max;
5189                         while (--$hi >= $min) {
5190                                 my $ok;
5191                                 $self->get_log([$longest_path], $min, $hi,
5192                                                0, 1, 1, sub {
5193                                                $ok = $_[1];
5194                                                $revs{$_[1]} = _cb(@_) });
5195                                 if ($ok) {
5196                                         print STDERR "r$min .. r$ok OK\n";
5197                                         last;
5198                                 }
5199                         }
5200                         $find_trailing_edge = 0;
5201                 }
5202                 $SVN::Error::handler = $err_handler;
5203
5204                 my %exists = map { $_->{path} => $_ } @$gsv;
5205                 foreach my $r (sort {$a <=> $b} keys %revs) {
5206                         my ($paths, $logged) = @{$revs{$r}};
5207
5208                         foreach my $gs ($self->match_globs(\%exists, $paths,
5209                                                            $globs, $r)) {
5210                                 if ($gs->rev_map_max >= $r) {
5211                                         next;
5212                                 }
5213                                 next unless $gs->match_paths($paths, $r);
5214                                 $gs->{logged_rev_props} = $logged;
5215                                 if (my $last_commit = $gs->last_commit) {
5216                                         $gs->assert_index_clean($last_commit);
5217                                 }
5218                                 my $log_entry = $gs->do_fetch($paths, $r);
5219                                 if ($log_entry) {
5220                                         $gs->do_git_commit($log_entry);
5221                                 }
5222                                 $INDEX_FILES{$gs->{index}} = 1;
5223                         }
5224                         foreach my $g (@$globs) {
5225                                 my $k = "svn-remote.$g->{remote}." .
5226                                         "$g->{t}-maxRev";
5227                                 Git::SVN::tmp_config($k, $r);
5228                         }
5229                         if ($ra_invalid) {
5230                                 $_[0] = undef;
5231                                 $self = undef;
5232                                 $RA = undef;
5233                                 $self = Git::SVN::Ra->new($ra_url);
5234                                 $ra_invalid = undef;
5235                         }
5236                 }
5237                 # pre-fill the .rev_db since it'll eventually get filled in
5238                 # with '0' x40 if something new gets committed
5239                 foreach my $gs (@$gsv) {
5240                         next if $gs->rev_map_max >= $max;
5241                         next if defined $gs->rev_map_get($max);
5242                         $gs->rev_map_set($max, 0 x40);
5243                 }
5244                 foreach my $g (@$globs) {
5245                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
5246                         Git::SVN::tmp_config($k, $max);
5247                 }
5248                 last if $max >= $head;
5249                 $min = $max + 1;
5250                 $max += $inc;
5251                 $max = $head if ($max > $head);
5252         }
5253         Git::SVN::gc();
5254 }
5255
5256 sub get_dir_globbed {
5257         my ($self, $left, $depth, $r) = @_;
5258
5259         my @x = eval { $self->get_dir($left, $r) };
5260         return unless scalar @x == 3;
5261         my $dirents = $x[0];
5262         my @finalents;
5263         foreach my $de (keys %$dirents) {
5264                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
5265                 if ($depth > 1) {
5266                         my @args = ("$left/$de", $depth - 1, $r);
5267                         foreach my $dir ($self->get_dir_globbed(@args)) {
5268                                 push @finalents, "$de/$dir";
5269                         }
5270                 } else {
5271                         push @finalents, $de;
5272                 }
5273         }
5274         @finalents;
5275 }
5276
5277 sub match_globs {
5278         my ($self, $exists, $paths, $globs, $r) = @_;
5279
5280         sub get_dir_check {
5281                 my ($self, $exists, $g, $r) = @_;
5282
5283                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
5284                                                   $g->{path}->{depth},
5285                                                   $r);
5286
5287                 foreach my $de (@dirs) {
5288                         my $p = $g->{path}->full_path($de);
5289                         next if $exists->{$p};
5290                         next if (length $g->{path}->{right} &&
5291                                  ($self->check_path($p, $r) !=
5292                                   $SVN::Node::dir));
5293                         next unless $p =~ /$g->{path}->{regex}/;
5294                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
5295                                          $g->{ref}->full_path($de), 1);
5296                 }
5297         }
5298         foreach my $g (@$globs) {
5299                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
5300                         if ($path->{action} =~ /^[AR]$/) {
5301                                 get_dir_check($self, $exists, $g, $r);
5302                         }
5303                 }
5304                 foreach (keys %$paths) {
5305                         if (/$g->{path}->{left_regex}/ &&
5306                             !/$g->{path}->{regex}/) {
5307                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
5308                                 get_dir_check($self, $exists, $g, $r);
5309                         }
5310                         next unless /$g->{path}->{regex}/;
5311                         my $p = $1;
5312                         my $pathname = $g->{path}->full_path($p);
5313                         next if $exists->{$pathname};
5314                         next if ($self->check_path($pathname, $r) !=
5315                                  $SVN::Node::dir);
5316                         $exists->{$pathname} = Git::SVN->init(
5317                                               $self->{url}, $pathname, undef,
5318                                               $g->{ref}->full_path($p), 1);
5319                 }
5320                 my $c = '';
5321                 foreach (split m#/#, $g->{path}->{left}) {
5322                         $c .= "/$_";
5323                         next unless ($paths->{$c} &&
5324                                      ($paths->{$c}->{action} =~ /^[AR]$/));
5325                         get_dir_check($self, $exists, $g, $r);
5326                 }
5327         }
5328         values %$exists;
5329 }
5330
5331 sub minimize_url {
5332         my ($self) = @_;
5333         return $self->{url} if ($self->{url} eq $self->{repos_root});
5334         my $url = $self->{repos_root};
5335         my @components = split(m!/!, $self->{svn_path});
5336         my $c = '';
5337         do {
5338                 $url .= "/$c" if length $c;
5339                 eval {
5340                         my $ra = (ref $self)->new($url);
5341                         my $latest = $ra->get_latest_revnum;
5342                         $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
5343                 };
5344         } while ($@ && ($c = shift @components));
5345         $url;
5346 }
5347
5348 sub can_do_switch {
5349         my $self = shift;
5350         unless (defined $can_do_switch) {
5351                 my $pool = SVN::Pool->new;
5352                 my $rep = eval {
5353                         $self->do_switch(1, '', 0, $self->{url},
5354                                          SVN::Delta::Editor->new, $pool);
5355                 };
5356                 if ($@) {
5357                         $can_do_switch = 0;
5358                 } else {
5359                         $rep->abort_report($pool);
5360                         $can_do_switch = 1;
5361                 }
5362                 $pool->clear;
5363         }
5364         $can_do_switch;
5365 }
5366
5367 sub skip_unknown_revs {
5368         my ($err) = @_;
5369         my $errno = $err->apr_err();
5370         # Maybe the branch we're tracking didn't
5371         # exist when the repo started, so it's
5372         # not an error if it doesn't, just continue
5373         #
5374         # Wonderfully consistent library, eh?
5375         # 160013 - svn:// and file://
5376         # 175002 - http(s)://
5377         # 175007 - http(s):// (this repo required authorization, too...)
5378         #   More codes may be discovered later...
5379         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
5380                 my $err_key = $err->expanded_message;
5381                 # revision numbers change every time, filter them out
5382                 $err_key =~ s/\d+/\0/g;
5383                 $err_key = "$errno\0$err_key";
5384                 unless ($ignored_err{$err_key}) {
5385                         warn "W: Ignoring error from SVN, path probably ",
5386                              "does not exist: ($errno): ",
5387                              $err->expanded_message,"\n";
5388                         warn "W: Do not be alarmed at the above message ",
5389                              "git-svn is just searching aggressively for ",
5390                              "old history.\n",
5391                              "This may take a while on large repositories\n";
5392                         $ignored_err{$err_key} = 1;
5393                 }
5394                 return;
5395         }
5396         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
5397 }
5398
5399 package Git::SVN::Log;
5400 use strict;
5401 use warnings;
5402 use POSIX qw/strftime/;
5403 use Time::Local;
5404 use constant commit_log_separator => ('-' x 72) . "\n";
5405 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
5406             %rusers $show_commit $incremental/;
5407 my $l_fmt;
5408
5409 sub cmt_showable {
5410         my ($c) = @_;
5411         return 1 if defined $c->{r};
5412
5413         # big commit message got truncated by the 16k pretty buffer in rev-list
5414         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
5415                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
5416                 @{$c->{l}} = ();
5417                 my @log = command(qw/cat-file commit/, $c->{c});
5418
5419                 # shift off the headers
5420                 shift @log while ($log[0] ne '');
5421                 shift @log;
5422
5423                 # TODO: make $c->{l} not have a trailing newline in the future
5424                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
5425
5426                 (undef, $c->{r}, undef) = ::extract_metadata(
5427                                 (grep(/^git-svn-id: /, @log))[-1]);
5428         }
5429         return defined $c->{r};
5430 }
5431
5432 sub log_use_color {
5433         return $color || Git->repository->get_colorbool('color.diff');
5434 }
5435
5436 sub git_svn_log_cmd {
5437         my ($r_min, $r_max, @args) = @_;
5438         my $head = 'HEAD';
5439         my (@files, @log_opts);
5440         foreach my $x (@args) {
5441                 if ($x eq '--' || @files) {
5442                         push @files, $x;
5443                 } else {
5444                         if (::verify_ref("$x^0")) {
5445                                 $head = $x;
5446                         } else {
5447                                 push @log_opts, $x;
5448                         }
5449                 }
5450         }
5451
5452         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
5453         $gs ||= Git::SVN->_new;
5454         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
5455                    $gs->refname);
5456         push @cmd, '-r' unless $non_recursive;
5457         push @cmd, qw/--raw --name-status/ if $verbose;
5458         push @cmd, '--color' if log_use_color();
5459         push @cmd, @log_opts;
5460         if (defined $r_max && $r_max == $r_min) {
5461                 push @cmd, '--max-count=1';
5462                 if (my $c = $gs->rev_map_get($r_max)) {
5463                         push @cmd, $c;
5464                 }
5465         } elsif (defined $r_max) {
5466                 if ($r_max < $r_min) {
5467                         ($r_min, $r_max) = ($r_max, $r_min);
5468                 }
5469                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
5470                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
5471                 # If there are no commits in the range, both $c_max and $c_min
5472                 # will be undefined.  If there is at least 1 commit in the
5473                 # range, both will be defined.
5474                 return () if !defined $c_min || !defined $c_max;
5475                 if ($c_min eq $c_max) {
5476                         push @cmd, '--max-count=1', $c_min;
5477                 } else {
5478                         push @cmd, '--boundary', "$c_min..$c_max";
5479                 }
5480         }
5481         return (@cmd, @files);
5482 }
5483
5484 # adapted from pager.c
5485 sub config_pager {
5486         if (! -t *STDOUT) {
5487                 $ENV{GIT_PAGER_IN_USE} = 'false';
5488                 $pager = undef;
5489                 return;
5490         }
5491         chomp($pager = command_oneline(qw(var GIT_PAGER)));
5492         if ($pager eq 'cat') {
5493                 $pager = undef;
5494         }
5495         $ENV{GIT_PAGER_IN_USE} = defined($pager);
5496 }
5497
5498 sub run_pager {
5499         return unless defined $pager;
5500         pipe my ($rfd, $wfd) or return;
5501         defined(my $pid = fork) or ::fatal "Can't fork: $!";
5502         if (!$pid) {
5503                 open STDOUT, '>&', $wfd or
5504                                      ::fatal "Can't redirect to stdout: $!";
5505                 return;
5506         }
5507         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5508         $ENV{LESS} ||= 'FRSX';
5509         exec $pager or ::fatal "Can't run pager: $! ($pager)";
5510 }
5511
5512 sub format_svn_date {
5513         # some systmes don't handle or mishandle %z, so be creative.
5514         my $t = shift || time;
5515         my $gm = timelocal(gmtime($t));
5516         my $sign = qw( + + - )[ $t <=> $gm ];
5517         my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5518         return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5519 }
5520
5521 sub parse_git_date {
5522         my ($t, $tz) = @_;
5523         # Date::Parse isn't in the standard Perl distro :(
5524         if ($tz =~ s/^\+//) {
5525                 $t += tz_to_s_offset($tz);
5526         } elsif ($tz =~ s/^\-//) {
5527                 $t -= tz_to_s_offset($tz);
5528         }
5529         return $t;
5530 }
5531
5532 sub set_local_timezone {
5533         if (defined $TZ) {
5534                 $ENV{TZ} = $TZ;
5535         } else {
5536                 delete $ENV{TZ};
5537         }
5538 }
5539
5540 sub tz_to_s_offset {
5541         my ($tz) = @_;
5542         $tz =~ s/(\d\d)$//;
5543         return ($1 * 60) + ($tz * 3600);
5544 }
5545
5546 sub get_author_info {
5547         my ($dest, $author, $t, $tz) = @_;
5548         $author =~ s/(?:^\s*|\s*$)//g;
5549         $dest->{a_raw} = $author;
5550         my $au;
5551         if ($::_authors) {
5552                 $au = $rusers{$author} || undef;
5553         }
5554         if (!$au) {
5555                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5556         }
5557         $dest->{t} = $t;
5558         $dest->{tz} = $tz;
5559         $dest->{a} = $au;
5560         $dest->{t_utc} = parse_git_date($t, $tz);
5561 }
5562
5563 sub process_commit {
5564         my ($c, $r_min, $r_max, $defer) = @_;
5565         if (defined $r_min && defined $r_max) {
5566                 if ($r_min == $c->{r} && $r_min == $r_max) {
5567                         show_commit($c);
5568                         return 0;
5569                 }
5570                 return 1 if $r_min == $r_max;
5571                 if ($r_min < $r_max) {
5572                         # we need to reverse the print order
5573                         return 0 if (defined $limit && --$limit < 0);
5574                         push @$defer, $c;
5575                         return 1;
5576                 }
5577                 if ($r_min != $r_max) {
5578                         return 1 if ($r_min < $c->{r});
5579                         return 1 if ($r_max > $c->{r});
5580                 }
5581         }
5582         return 0 if (defined $limit && --$limit < 0);
5583         show_commit($c);
5584         return 1;
5585 }
5586
5587 sub show_commit {
5588         my $c = shift;
5589         if ($oneline) {
5590                 my $x = "\n";
5591                 if (my $l = $c->{l}) {
5592                         while ($l->[0] =~ /^\s*$/) { shift @$l }
5593                         $x = $l->[0];
5594                 }
5595                 $l_fmt ||= 'A' . length($c->{r});
5596                 print 'r',pack($l_fmt, $c->{r}),' | ';
5597                 print "$c->{c} | " if $show_commit;
5598                 print $x;
5599         } else {
5600                 show_commit_normal($c);
5601         }
5602 }
5603
5604 sub show_commit_changed_paths {
5605         my ($c) = @_;
5606         return unless $c->{changed};
5607         print "Changed paths:\n", @{$c->{changed}};
5608 }
5609
5610 sub show_commit_normal {
5611         my ($c) = @_;
5612         print commit_log_separator, "r$c->{r} | ";
5613         print "$c->{c} | " if $show_commit;
5614         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5615         my $nr_line = 0;
5616
5617         if (my $l = $c->{l}) {
5618                 while ($l->[$#$l] eq "\n" && $#$l > 0
5619                                           && $l->[($#$l - 1)] eq "\n") {
5620                         pop @$l;
5621                 }
5622                 $nr_line = scalar @$l;
5623                 if (!$nr_line) {
5624                         print "1 line\n\n\n";
5625                 } else {
5626                         if ($nr_line == 1) {
5627                                 $nr_line = '1 line';
5628                         } else {
5629                                 $nr_line .= ' lines';
5630                         }
5631                         print $nr_line, "\n";
5632                         show_commit_changed_paths($c);
5633                         print "\n";
5634                         print $_ foreach @$l;
5635                 }
5636         } else {
5637                 print "1 line\n";
5638                 show_commit_changed_paths($c);
5639                 print "\n";
5640
5641         }
5642         foreach my $x (qw/raw stat diff/) {
5643                 if ($c->{$x}) {
5644                         print "\n";
5645                         print $_ foreach @{$c->{$x}}
5646                 }
5647         }
5648 }
5649
5650 sub cmd_show_log {
5651         my (@args) = @_;
5652         my ($r_min, $r_max);
5653         my $r_last = -1; # prevent dupes
5654         set_local_timezone();
5655         if (defined $::_revision) {
5656                 if ($::_revision =~ /^(\d+):(\d+)$/) {
5657                         ($r_min, $r_max) = ($1, $2);
5658                 } elsif ($::_revision =~ /^\d+$/) {
5659                         $r_min = $r_max = $::_revision;
5660                 } else {
5661                         ::fatal "-r$::_revision is not supported, use ",
5662                                 "standard 'git log' arguments instead";
5663                 }
5664         }
5665
5666         config_pager();
5667         @args = git_svn_log_cmd($r_min, $r_max, @args);
5668         if (!@args) {
5669                 print commit_log_separator unless $incremental || $oneline;
5670                 return;
5671         }
5672         my $log = command_output_pipe(@args);
5673         run_pager();
5674         my (@k, $c, $d, $stat);
5675         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5676         while (<$log>) {
5677                 if (/^${esc_color}commit -?($::sha1_short)/o) {
5678                         my $cmt = $1;
5679                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5680                                 $r_last = $c->{r};
5681                                 process_commit($c, $r_min, $r_max, \@k) or
5682                                                                 goto out;
5683                         }
5684                         $d = undef;
5685                         $c = { c => $cmt };
5686                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5687                         get_author_info($c, $1, $2, $3);
5688                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5689                         # ignore
5690                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5691                         push @{$c->{raw}}, $_;
5692                 } elsif (/^${esc_color}[ACRMDT]\t/) {
5693                         # we could add $SVN->{svn_path} here, but that requires
5694                         # remote access at the moment (repo_path_split)...
5695                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
5696                         push @{$c->{changed}}, $_;
5697                 } elsif (/^${esc_color}diff /o) {
5698                         $d = 1;
5699                         push @{$c->{diff}}, $_;
5700                 } elsif ($d) {
5701                         push @{$c->{diff}}, $_;
5702                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5703                           $esc_color*[\+\-]*$esc_color$/x) {
5704                         $stat = 1;
5705                         push @{$c->{stat}}, $_;
5706                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5707                         push @{$c->{stat}}, $_;
5708                         $stat = undef;
5709                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
5710                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5711                 } elsif (s/^${esc_color}    //o) {
5712                         push @{$c->{l}}, $_;
5713                 }
5714         }
5715         if ($c && defined $c->{r} && $c->{r} != $r_last) {
5716                 $r_last = $c->{r};
5717                 process_commit($c, $r_min, $r_max, \@k);
5718         }
5719         if (@k) {
5720                 ($r_min, $r_max) = ($r_max, $r_min);
5721                 process_commit($_, $r_min, $r_max) foreach reverse @k;
5722         }
5723 out:
5724         close $log;
5725         print commit_log_separator unless $incremental || $oneline;
5726 }
5727
5728 sub cmd_blame {
5729         my $path = pop;
5730
5731         config_pager();
5732         run_pager();
5733
5734         my ($fh, $ctx, $rev);
5735
5736         if ($_git_format) {
5737                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5738                 while (my $line = <$fh>) {
5739                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5740                                 # Uncommitted edits show up as a rev ID of
5741                                 # all zeros, which we can't look up with
5742                                 # cmt_metadata
5743                                 if ($1 !~ /^0+$/) {
5744                                         (undef, $rev, undef) =
5745                                                 ::cmt_metadata($1);
5746                                         $rev = '0' if (!$rev);
5747                                 } else {
5748                                         $rev = '0';
5749                                 }
5750                                 $rev = sprintf('%-10s', $rev);
5751                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5752                         }
5753                         print $line;
5754                 }
5755         } else {
5756                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5757                                                   '--', $path);
5758                 my ($sha1);
5759                 my %authors;
5760                 my @buffer;
5761                 my %dsha; #distinct sha keys
5762
5763                 while (my $line = <$fh>) {
5764                         push @buffer, $line;
5765                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5766                                 $dsha{$1} = 1;
5767                         }
5768                 }
5769
5770                 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5771
5772                 foreach my $line (@buffer) {
5773                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5774                                 $rev = $s2r->{$1};
5775                                 $rev = '0' if (!$rev)
5776                         }
5777                         elsif ($line =~ /^author (.*)/) {
5778                                 $authors{$rev} = $1;
5779                                 $authors{$rev} =~ s/\s/_/g;
5780                         }
5781                         elsif ($line =~ /^\t(.*)$/) {
5782                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5783                         }
5784                 }
5785         }
5786         command_close_pipe($fh, $ctx);
5787 }
5788
5789 package Git::SVN::Migration;
5790 # these version numbers do NOT correspond to actual version numbers
5791 # of git nor git-svn.  They are just relative.
5792 #
5793 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5794 #
5795 # v1 layout: .git/$id/info/url, refs/remotes/$id
5796 #
5797 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5798 #
5799 # v3 layout: .git/svn/$id, refs/remotes/$id
5800 #            - info/url may remain for backwards compatibility
5801 #            - this is what we migrate up to this layout automatically,
5802 #            - this will be used by git svn init on single branches
5803 # v3.1 layout (auto migrated):
5804 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5805 #              for backwards compatibility
5806 #
5807 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5808 #            - this is only created for newly multi-init-ed
5809 #              repositories.  Similar in spirit to the
5810 #              --use-separate-remotes option in git-clone (now default)
5811 #            - we do not automatically migrate to this (following
5812 #              the example set by core git)
5813 #
5814 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5815 #            - newer, more-efficient format that uses 24-bytes per record
5816 #              with no filler space.
5817 #            - use xxd -c24 < .rev_map.$UUID to view and debug
5818 #            - This is a one-way migration, repositories updated to the
5819 #              new format will not be able to use old git-svn without
5820 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
5821 #              possible if noMetadata or useSvmProps are set; but should
5822 #              be no problem for users that use the (sensible) defaults.
5823 use strict;
5824 use warnings;
5825 use Carp qw/croak/;
5826 use File::Path qw/mkpath/;
5827 use File::Basename qw/dirname basename/;
5828 use vars qw/$_minimize/;
5829
5830 sub migrate_from_v0 {
5831         my $git_dir = $ENV{GIT_DIR};
5832         return undef unless -d $git_dir;
5833         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5834         my $migrated = 0;
5835         while (<$fh>) {
5836                 chomp;
5837                 my ($id, $orig_ref) = ($_, $_);
5838                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5839                 next unless -f "$git_dir/$id/info/url";
5840                 my $new_ref = "refs/remotes/$id";
5841                 if (::verify_ref("$new_ref^0")) {
5842                         print STDERR "W: $orig_ref is probably an old ",
5843                                      "branch used by an ancient version of ",
5844                                      "git-svn.\n",
5845                                      "However, $new_ref also exists.\n",
5846                                      "We will not be able ",
5847                                      "to use this branch until this ",
5848                                      "ambiguity is resolved.\n";
5849                         next;
5850                 }
5851                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5852                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5853                 command_noisy('update-ref', $new_ref, $orig_ref);
5854                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5855                 $migrated++;
5856         }
5857         command_close_pipe($fh, $ctx);
5858         print STDERR "Done migrating from v0 layout...\n" if $migrated;
5859         $migrated;
5860 }
5861
5862 sub migrate_from_v1 {
5863         my $git_dir = $ENV{GIT_DIR};
5864         my $migrated = 0;
5865         return $migrated unless -d $git_dir;
5866         my $svn_dir = "$git_dir/svn";
5867
5868         # just in case somebody used 'svn' as their $id at some point...
5869         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5870
5871         print STDERR "Migrating from a git-svn v1 layout...\n";
5872         mkpath([$svn_dir]);
5873         print STDERR "Data from a previous version of git-svn exists, but\n\t",
5874                      "$svn_dir\n\t(required for this version ",
5875                      "($::VERSION) of git-svn) does not exist.\n";
5876         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5877         while (<$fh>) {
5878                 my $x = $_;
5879                 next unless $x =~ s#^refs/remotes/##;
5880                 chomp $x;
5881                 next unless -f "$git_dir/$x/info/url";
5882                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5883                 next unless $u;
5884                 my $dn = dirname("$git_dir/svn/$x");
5885                 mkpath([$dn]) unless -d $dn;
5886                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5887                         mkpath(["$git_dir/svn/svn"]);
5888                         print STDERR " - $git_dir/$x/info => ",
5889                                         "$git_dir/svn/$x/info\n";
5890                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5891                                croak "$!: $x";
5892                         # don't worry too much about these, they probably
5893                         # don't exist with repos this old (save for index,
5894                         # and we can easily regenerate that)
5895                         foreach my $f (qw/unhandled.log index .rev_db/) {
5896                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5897                         }
5898                 } else {
5899                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5900                         rename "$git_dir/$x", "$git_dir/svn/$x" or
5901                                croak "$!: $x";
5902                 }
5903                 $migrated++;
5904         }
5905         command_close_pipe($fh, $ctx);
5906         print STDERR "Done migrating from a git-svn v1 layout\n";
5907         $migrated;
5908 }
5909
5910 sub read_old_urls {
5911         my ($l_map, $pfx, $path) = @_;
5912         my @dir;
5913         foreach (<$path/*>) {
5914                 if (-r "$_/info/url") {
5915                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5916                         my $ref_id = $pfx . basename $_;
5917                         my $url = ::file_to_s("$_/info/url");
5918                         $l_map->{$ref_id} = $url;
5919                 } elsif (-d $_) {
5920                         push @dir, $_;
5921                 }
5922         }
5923         foreach (@dir) {
5924                 my $x = $_;
5925                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5926                 read_old_urls($l_map, $x, $_);
5927         }
5928 }
5929
5930 sub migrate_from_v2 {
5931         my @cfg = command(qw/config -l/);
5932         return if grep /^svn-remote\..+\.url=/, @cfg;
5933         my %l_map;
5934         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5935         my $migrated = 0;
5936
5937         foreach my $ref_id (sort keys %l_map) {
5938                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5939                 if ($@) {
5940                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5941                 }
5942                 $migrated++;
5943         }
5944         $migrated;
5945 }
5946
5947 sub minimize_connections {
5948         my $r = Git::SVN::read_all_remotes();
5949         my $new_urls = {};
5950         my $root_repos = {};
5951         foreach my $repo_id (keys %$r) {
5952                 my $url = $r->{$repo_id}->{url} or next;
5953                 my $fetch = $r->{$repo_id}->{fetch} or next;
5954                 my $ra = Git::SVN::Ra->new($url);
5955
5956                 # skip existing cases where we already connect to the root
5957                 if (($ra->{url} eq $ra->{repos_root}) ||
5958                     ($ra->{repos_root} eq $repo_id)) {
5959                         $root_repos->{$ra->{url}} = $repo_id;
5960                         next;
5961                 }
5962
5963                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
5964                 my $root_path = $ra->{url};
5965                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
5966                 foreach my $path (keys %$fetch) {
5967                         my $ref_id = $fetch->{$path};
5968                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
5969
5970                         # make sure we can read when connecting to
5971                         # a higher level of a repository
5972                         my ($last_rev, undef) = $gs->last_rev_commit;
5973                         if (!defined $last_rev) {
5974                                 $last_rev = eval {
5975                                         $root_ra->get_latest_revnum;
5976                                 };
5977                                 next if $@;
5978                         }
5979                         my $new = $root_path;
5980                         $new .= length $path ? "/$path" : '';
5981                         eval {
5982                                 $root_ra->get_log([$new], $last_rev, $last_rev,
5983                                                   0, 0, 1, sub { });
5984                         };
5985                         next if $@;
5986                         $new_urls->{$ra->{repos_root}}->{$new} =
5987                                 { ref_id => $ref_id,
5988                                   old_repo_id => $repo_id,
5989                                   old_path => $path };
5990                 }
5991         }
5992
5993         my @emptied;
5994         foreach my $url (keys %$new_urls) {
5995                 # see if we can re-use an existing [svn-remote "repo_id"]
5996                 # instead of creating a(n ugly) new section:
5997                 my $repo_id = $root_repos->{$url} || $url;
5998
5999                 my $fetch = $new_urls->{$url};
6000                 foreach my $path (keys %$fetch) {
6001                         my $x = $fetch->{$path};
6002                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
6003                         my $pfx = "svn-remote.$x->{old_repo_id}";
6004
6005                         my $old_fetch = quotemeta("$x->{old_path}:".
6006                                                   "$x->{ref_id}");
6007                         command_noisy(qw/config --unset/,
6008                                       "$pfx.fetch", '^'. $old_fetch . '$');
6009                         delete $r->{$x->{old_repo_id}}->
6010                                {fetch}->{$x->{old_path}};
6011                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
6012                                 command_noisy(qw/config --unset/,
6013                                               "$pfx.url");
6014                                 push @emptied, $x->{old_repo_id}
6015                         }
6016                 }
6017         }
6018         if (@emptied) {
6019                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
6020                 print STDERR <<EOF;
6021 The following [svn-remote] sections in your config file ($file) are empty
6022 and can be safely removed:
6023 EOF
6024                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
6025         }
6026 }
6027
6028 sub migration_check {
6029         migrate_from_v0();
6030         migrate_from_v1();
6031         migrate_from_v2();
6032         minimize_connections() if $_minimize;
6033 }
6034
6035 package Git::IndexInfo;
6036 use strict;
6037 use warnings;
6038 use Git qw/command_input_pipe command_close_pipe/;
6039
6040 sub new {
6041         my ($class) = @_;
6042         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
6043         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
6044 }
6045
6046 sub remove {
6047         my ($self, $path) = @_;
6048         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
6049                 return ++$self->{nr};
6050         }
6051         undef;
6052 }
6053
6054 sub update {
6055         my ($self, $mode, $hash, $path) = @_;
6056         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
6057                 return ++$self->{nr};
6058         }
6059         undef;
6060 }
6061
6062 sub DESTROY {
6063         my ($self) = @_;
6064         command_close_pipe($self->{gui}, $self->{ctx});
6065 }
6066
6067 package Git::SVN::GlobSpec;
6068 use strict;
6069 use warnings;
6070
6071 sub new {
6072         my ($class, $glob, $pattern_ok) = @_;
6073         my $re = $glob;
6074         $re =~ s!/+$!!g; # no need for trailing slashes
6075         my (@left, @right, @patterns);
6076         my $state = "left";
6077         my $die_msg = "Only one set of wildcard directories " .
6078                                 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
6079         for my $part (split(m|/|, $glob)) {
6080                 if ($part =~ /\*/ && $part ne "*") {
6081                         die "Invalid pattern in '$glob': $part\n";
6082                 } elsif ($pattern_ok && $part =~ /[{}]/ &&
6083                          $part !~ /^\{[^{}]+\}/) {
6084                         die "Invalid pattern in '$glob': $part\n";
6085                 }
6086                 if ($part eq "*") {
6087                         die $die_msg if $state eq "right";
6088                         $state = "pattern";
6089                         push(@patterns, "[^/]*");
6090                 } elsif ($pattern_ok && $part =~ /^\{(.*)\}$/) {
6091                         die $die_msg if $state eq "right";
6092                         $state = "pattern";
6093                         my $p = quotemeta($1);
6094                         $p =~ s/\\,/|/g;
6095                         push(@patterns, "(?:$p)");
6096                 } else {
6097                         if ($state eq "left") {
6098                                 push(@left, $part);
6099                         } else {
6100                                 push(@right, $part);
6101                                 $state = "right";
6102                         }
6103                 }
6104         }
6105         my $depth = @patterns;
6106         if ($depth == 0) {
6107                 die "One '*' is needed in glob: '$glob'\n";
6108         }
6109         my $left = join('/', @left);
6110         my $right = join('/', @right);
6111         $re = join('/', @patterns);
6112         $re = join('\/',
6113                    grep(length, quotemeta($left), "($re)", quotemeta($right)));
6114         my $left_re = qr/^\/\Q$left\E(\/|$)/;
6115         bless { left => $left, right => $right, left_regex => $left_re,
6116                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
6117 }
6118
6119 sub full_path {
6120         my ($self, $path) = @_;
6121         return (length $self->{left} ? "$self->{left}/" : '') .
6122                $path . (length $self->{right} ? "/$self->{right}" : '');
6123 }
6124
6125 __END__
6126
6127 Data structures:
6128
6129
6130 $remotes = { # returned by read_all_remotes()
6131         'svn' => {
6132                 # svn-remote.svn.url=https://svn.musicpd.org
6133                 url => 'https://svn.musicpd.org',
6134                 # svn-remote.svn.fetch=mpd/trunk:trunk
6135                 fetch => {
6136                         'mpd/trunk' => 'trunk',
6137                 },
6138                 # svn-remote.svn.tags=mpd/tags/*:tags/*
6139                 tags => {
6140                         path => {
6141                                 left => 'mpd/tags',
6142                                 right => '',
6143                                 regex => qr!mpd/tags/([^/]+)$!,
6144                                 glob => 'tags/*',
6145                         },
6146                         ref => {
6147                                 left => 'tags',
6148                                 right => '',
6149                                 regex => qr!tags/([^/]+)$!,
6150                                 glob => 'tags/*',
6151                         },
6152                 }
6153         }
6154 };
6155
6156 $log_entry hashref as returned by libsvn_log_entry()
6157 {
6158         log => 'whitespace-formatted log entry
6159 ',                                              # trailing newline is preserved
6160         revision => '8',                        # integer
6161         date => '2004-02-24T17:01:44.108345Z',  # commit date
6162         author => 'committer name'
6163 };
6164
6165
6166 # this is generated by generate_diff();
6167 @mods = array of diff-index line hashes, each element represents one line
6168         of diff-index output
6169
6170 diff-index line ($m hash)
6171 {
6172         mode_a => first column of diff-index output, no leading ':',
6173         mode_b => second column of diff-index output,
6174         sha1_b => sha1sum of the final blob,
6175         chg => change type [MCRADT],
6176         file_a => original file name of a file (iff chg is 'C' or 'R')
6177         file_b => new/current file name of a file (any chg)
6178 }
6179 ;
6180
6181 # retval of read_url_paths{,_all}();
6182 $l_map = {
6183         # repository root url
6184         'https://svn.musicpd.org' => {
6185                 # repository path               # GIT_SVN_ID
6186                 'mpd/trunk'             =>      'trunk',
6187                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
6188         },
6189 }
6190
6191 Notes:
6192         I don't trust the each() function on unless I created %hash myself
6193         because the internal iterator may not have started at base.