git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 # From which subdir have we been invoked?
  14 my $cmd_dir_prefix = eval {
  15         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  16 } || '';
  17
  18 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  19 $ENV{GIT_DIR} ||= '.git';
  20 $Git::SVN::default_repo_id = 'svn';
  21 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  22 $Git::SVN::Ra::_log_window_size = 100;
  23 $Git::SVN::_minimize_url = 'unset';
  24
  25 if (! exists $ENV{SVN_SSH}) {
  26         if (exists $ENV{GIT_SSH}) {
  27                 $ENV{SVN_SSH} = $ENV{GIT_SSH};
  28                 if ($^O eq 'msys') {
  29                         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  30                         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  31                 }
  32         }
  33 }
  34
  35 $Git::SVN::Log::TZ = $ENV{TZ};
  36 $ENV{TZ} = 'UTC';
  37 $| = 1; # unbuffer STDOUT
  38
  39 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  40 sub _req_svn {
  41         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  42         require SVN::Ra;
  43         require SVN::Delta;
  44         if ($SVN::Core::VERSION lt '1.1.0') {
  45                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  46         }
  47 }
  48 my $can_compress = eval { require Compress::Zlib; 1};
  49 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  50 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  51 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  52 use Carp qw/croak/;
  53 use Digest::MD5;
  54 use IO::File qw//;
  55 use File::Basename qw/dirname basename/;
  56 use File::Path qw/mkpath/;
  57 use File::Spec;
  58 use File::Find;
  59 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  60 use IPC::Open3;
  61 use Git;
  62 use Memoize;  # core since 5.8.0, Jul 2002
  63
  64 BEGIN {
  65         # import functions from Git into our packages, en masse
  66         no strict 'refs';
  67         foreach (qw/command command_oneline command_noisy command_output_pipe
  68                     command_input_pipe command_close_pipe
  69                     command_bidi_pipe command_close_bidi_pipe/) {
  70                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  71                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  72                         __PACKAGE__) {
  73                         *{"${package}::$_"} = \&{"Git::$_"};
  74                 }
  75         }
  76         Memoize::memoize 'Git::config';
  77         Memoize::memoize 'Git::config_bool';
  78 }
  79
  80 my ($SVN);
  81
  82 $sha1 = qr/[a-f\d]{40}/;
  83 $sha1_short = qr/[a-f\d]{4,40}/;
  84 my ($_stdin, $_help, $_edit,
  85         $_message, $_file, $_branch_dest,
  86         $_template, $_shared,
  87         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
  88         $_merge, $_strategy, $_dry_run, $_local,
  89         $_prefix, $_no_checkout, $_url, $_verbose,
  90         $_git_format, $_commit_url, $_tag, $_merge_info);
  91 $Git::SVN::_follow_parent = 1;
  92 $_q ||= 0;
  93 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  94                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  95                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  96                     'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
  97 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  98                 'authors-file|A=s' => \$_authors,
  99                 'authors-prog=s' => \$_authors_prog,
 100                 'repack:i' => \$Git::SVN::_repack,
 101                 'noMetadata' => \$Git::SVN::_no_metadata,
 102                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 103                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 104                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 105                 'no-checkout' => \$_no_checkout,
 106                 'quiet|q+' => \$_q,
 107                 'repack-flags|repack-args|repack-opts=s' =>
 108                    \$Git::SVN::_repack_flags,
 109                 'use-log-author' => \$Git::SVN::_use_log_author,
 110                 'add-author-from' => \$Git::SVN::_add_author_from,
 111                 'localtime' => \$Git::SVN::_localtime,
 112                 %remote_opts );
 113
 114 my ($_trunk, @_tags, @_branches, $_stdlayout);
 115 my %icv;
 116 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 117                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 118                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 119                   'stdlayout|s' => \$_stdlayout,
 120                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 121                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 122                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 123                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 124                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 125                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 126                   %remote_opts );
 127 my %cmt_opts = ( 'edit|e' => \$_edit,
 128                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 129                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 130                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 131                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 132 );
 133
 134 my %cmd = (
 135         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 136                         { 'revision|r=s' => \$_revision,
 137                           'fetch-all|all' => \$_fetch_all,
 138                           'parent|p' => \$_fetch_parent,
 139                            %fc_opts } ],
 140         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 141                         { 'revision|r=s' => \$_revision,
 142                            %fc_opts, %init_opts } ],
 143         init => [ \&cmd_init, "Initialize a repo for tracking" .
 144                           " (requires URL argument)",
 145                           \%init_opts ],
 146         'multi-init' => [ \&cmd_multi_init,
 147                           "Deprecated alias for ".
 148                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 149                           \%init_opts ],
 150         dcommit => [ \&cmd_dcommit,
 151                      'Commit several diffs to merge with upstream',
 152                         { 'merge|m|M' => \$_merge,
 153                           'strategy|s=s' => \$_strategy,
 154                           'verbose|v' => \$_verbose,
 155                           'dry-run|n' => \$_dry_run,
 156                           'fetch-all|all' => \$_fetch_all,
 157                           'commit-url=s' => \$_commit_url,
 158                           'revision|r=i' => \$_revision,
 159                           'no-rebase' => \$_no_rebase,
 160                           'mergeinfo=s' => \$_merge_info,
 161                         %cmt_opts, %fc_opts } ],
 162         branch => [ \&cmd_branch,
 163                     'Create a branch in the SVN repository',
 164                     { 'message|m=s' => \$_message,
 165                       'destination|d=s' => \$_branch_dest,
 166                       'dry-run|n' => \$_dry_run,
 167                       'tag|t' => \$_tag,
 168                       'username=s' => \$Git::SVN::Prompt::_username,
 169                       'commit-url=s' => \$_commit_url } ],
 170         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 171                  'Create a tag in the SVN repository',
 172                  { 'message|m=s' => \$_message,
 173                    'destination|d=s' => \$_branch_dest,
 174                    'dry-run|n' => \$_dry_run,
 175                    'username=s' => \$Git::SVN::Prompt::_username,
 176                    'commit-url=s' => \$_commit_url } ],
 177         'set-tree' => [ \&cmd_set_tree,
 178                         "Set an SVN repository to a git tree-ish",
 179                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 180         'create-ignore' => [ \&cmd_create_ignore,
 181                              'Create a .gitignore per svn:ignore',
 182                              { 'revision|r=i' => \$_revision
 183                              } ],
 184         'mkdirs' => [ \&cmd_mkdirs ,
 185                       "recreate empty directories after a checkout",
 186                       { 'revision|r=i' => \$_revision } ],
 187         'propget' => [ \&cmd_propget,
 188                        'Print the value of a property on a file or directory',
 189                        { 'revision|r=i' => \$_revision } ],
 190         'proplist' => [ \&cmd_proplist,
 191                        'List all properties of a file or directory',
 192                        { 'revision|r=i' => \$_revision } ],
 193         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 194                         { 'revision|r=i' => \$_revision
 195                         } ],
 196         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 197                         { 'revision|r=i' => \$_revision
 198                         } ],
 199         'multi-fetch' => [ \&cmd_multi_fetch,
 200                            "Deprecated alias for $0 fetch --all",
 201                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 202         'migrate' => [ sub { },
 203                        # no-op, we automatically run this anyways,
 204                        'Migrate configuration/metadata/layout from
 205                         previous versions of git-svn',
 206                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 207                          %remote_opts } ],
 208         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 209                         { 'limit=i' => \$Git::SVN::Log::limit,
 210                           'revision|r=s' => \$_revision,
 211                           'verbose|v' => \$Git::SVN::Log::verbose,
 212                           'incremental' => \$Git::SVN::Log::incremental,
 213                           'oneline' => \$Git::SVN::Log::oneline,
 214                           'show-commit' => \$Git::SVN::Log::show_commit,
 215                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 216                           'authors-file|A=s' => \$_authors,
 217                           'color' => \$Git::SVN::Log::color,
 218                           'pager=s' => \$Git::SVN::Log::pager
 219                         } ],
 220         'find-rev' => [ \&cmd_find_rev,
 221                         "Translate between SVN revision numbers and tree-ish",
 222                         {} ],
 223         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 224                         { 'merge|m|M' => \$_merge,
 225                           'verbose|v' => \$_verbose,
 226                           'strategy|s=s' => \$_strategy,
 227                           'local|l' => \$_local,
 228                           'fetch-all|all' => \$_fetch_all,
 229                           'dry-run|n' => \$_dry_run,
 230                           %fc_opts } ],
 231         'commit-diff' => [ \&cmd_commit_diff,
 232                            'Commit a diff between two trees',
 233                         { 'message|m=s' => \$_message,
 234                           'file|F=s' => \$_file,
 235                           'revision|r=s' => \$_revision,
 236                         %cmt_opts } ],
 237         'info' => [ \&cmd_info,
 238                     "Show info about the latest SVN revision
 239                      on the current branch",
 240                     { 'url' => \$_url, } ],
 241         'blame' => [ \&Git::SVN::Log::cmd_blame,
 242                     "Show what revision and author last modified each line of a file",
 243                     { 'git-format' => \$_git_format } ],
 244         'reset' => [ \&cmd_reset,
 245                      "Undo fetches back to the specified SVN revision",
 246                      { 'revision|r=s' => \$_revision,
 247                        'parent|p' => \$_fetch_parent } ],
 248         'gc' => [ \&cmd_gc,
 249                   "Compress unhandled.log files in .git/svn and remove " .
 250                   "index files in .git/svn",
 251                 {} ],
 252 );
 253
 254 my $cmd;
 255 for (my $i = 0; $i < @ARGV; $i++) {
 256         if (defined $cmd{$ARGV[$i]}) {
 257                 $cmd = $ARGV[$i];
 258                 splice @ARGV, $i, 1;
 259                 last;
 260         } elsif ($ARGV[$i] eq 'help') {
 261                 $cmd = $ARGV[$i+1];
 262                 usage(0);
 263         }
 264 };
 265
 266 # make sure we're always running at the top-level working directory
 267 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 268         unless (-d $ENV{GIT_DIR}) {
 269                 if ($git_dir_user_set) {
 270                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 271                             "but it is not a directory\n";
 272                 }
 273                 my $git_dir = delete $ENV{GIT_DIR};
 274                 my $cdup = undef;
 275                 git_cmd_try {
 276                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 277                         $git_dir = '.' unless ($cdup);
 278                         chomp $cdup if ($cdup);
 279                         $cdup = "." unless ($cdup && length $cdup);
 280                 } "Already at toplevel, but $git_dir not found\n";
 281                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 282                 unless (-d $git_dir) {
 283                         die "$git_dir still not found after going to ",
 284                             "'$cdup'\n";
 285                 }
 286                 $ENV{GIT_DIR} = $git_dir;
 287         }
 288         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 289 }
 290
 291 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 292
 293 read_git_config(\%opts);
 294 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 295         Getopt::Long::Configure('pass_through');
 296 }
 297 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 298                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 299                     'id|i=s' => \$Git::SVN::default_ref_id,
 300                     'svn-remote|remote|R=s' => sub {
 301                        $Git::SVN::no_reuse_existing = 1;
 302                        $Git::SVN::default_repo_id = $_[1] });
 303 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 304
 305 usage(0) if $_help;
 306 version() if $_version;
 307 usage(1) unless defined $cmd;
 308 load_authors() if $_authors;
 309 if (defined $_authors_prog) {
 310         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 311 }
 312
 313 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 314         Git::SVN::Migration::migration_check();
 315 }
 316 Git::SVN::init_vars();
 317 eval {
 318         Git::SVN::verify_remotes_sanity();
 319         $cmd{$cmd}->[0]->(@ARGV);
 320 };
 321 fatal $@ if $@;
 322 post_fetch_checkout();
 323 exit 0;
 324
 325 ####################### primary functions ######################
 326 sub usage {
 327         my $exit = shift || 0;
 328         my $fd = $exit ? \*STDERR : \*STDOUT;
 329         print $fd <<"";
 330 git-svn - bidirectional operations between a single Subversion tree and git
 331 Usage: git svn <command> [options] [arguments]\n
 332
 333         print $fd "Available commands:\n" unless $cmd;
 334
 335         foreach (sort keys %cmd) {
 336                 next if $cmd && $cmd ne $_;
 337                 next if /^multi-/; # don't show deprecated commands
 338                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 339                 foreach (sort keys %{$cmd{$_}->[2]}) {
 340                         # mixed-case options are for .git/config only
 341                         next if /[A-Z]/ && /^[a-z]+$/i;
 342                         # prints out arguments as they should be passed:
 343                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 344                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 345                                                         "--$_" : "-$_" }
 346                                                 split /\|/,$_)," $x\n";
 347                 }
 348         }
 349         print $fd <<"";
 350 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 351 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 352 one git repository and want to keep them separate.  See git-svn(1) for more
 353 information.
 354
 355         exit $exit;
 356 }
 357
 358 sub version {
 359         ::_req_svn();
 360         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 361         exit 0;
 362 }
 363
 364 sub do_git_init_db {
 365         unless (-d $ENV{GIT_DIR}) {
 366                 my @init_db = ('init');
 367                 push @init_db, "--template=$_template" if defined $_template;
 368                 if (defined $_shared) {
 369                         if ($_shared =~ /[a-z]/) {
 370                                 push @init_db, "--shared=$_shared";
 371                         } else {
 372                                 push @init_db, "--shared";
 373                         }
 374                 }
 375                 command_noisy(@init_db);
 376                 $_repository = Git->repository(Repository => ".git");
 377         }
 378         my $set;
 379         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 380         foreach my $i (keys %icv) {
 381                 die "'$set' and '$i' cannot both be set\n" if $set;
 382                 next unless defined $icv{$i};
 383                 command_noisy('config', "$pfx.$i", $icv{$i});
 384                 $set = $i;
 385         }
 386         my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
 387         command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
 388                 if defined $$ignore_regex;
 389 }
 390
 391 sub init_subdir {
 392         my $repo_path = shift or return;
 393         mkpath([$repo_path]) unless -d $repo_path;
 394         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 395         $ENV{GIT_DIR} = '.git';
 396         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 397 }
 398
 399 sub cmd_clone {
 400         my ($url, $path) = @_;
 401         if (!defined $path &&
 402             (defined $_trunk || @_branches || @_tags ||
 403              defined $_stdlayout) &&
 404             $url !~ m#^[a-z\+]+://#) {
 405                 $path = $url;
 406         }
 407         $path = basename($url) if !defined $path || !length $path;
 408         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 409         cmd_init($url, $path);
 410         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 411             if $_authors;
 412         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 413 }
 414
 415 sub cmd_init {
 416         if (defined $_stdlayout) {
 417                 $_trunk = 'trunk' if (!defined $_trunk);
 418                 @_tags = 'tags' if (! @_tags);
 419                 @_branches = 'branches' if (! @_branches);
 420         }
 421         if (defined $_trunk || @_branches || @_tags) {
 422                 return cmd_multi_init(@_);
 423         }
 424         my $url = shift or die "SVN repository location required ",
 425                                "as a command-line argument\n";
 426         $url = canonicalize_url($url);
 427         init_subdir(@_);
 428         do_git_init_db();
 429
 430         if ($Git::SVN::_minimize_url eq 'unset') {
 431                 $Git::SVN::_minimize_url = 0;
 432         }
 433
 434         Git::SVN->init($url);
 435 }
 436
 437 sub cmd_fetch {
 438         if (grep /^\d+=./, @_) {
 439                 die "'<rev>=<commit>' fetch arguments are ",
 440                     "no longer supported.\n";
 441         }
 442         my ($remote) = @_;
 443         if (@_ > 1) {
 444                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 445         }
 446         $Git::SVN::no_reuse_existing = undef;
 447         if ($_fetch_parent) {
 448                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 449                 unless ($gs) {
 450                         die "Unable to determine upstream SVN information from ",
 451                             "working tree history\n";
 452                 }
 453                 # just fetch, don't checkout.
 454                 $_no_checkout = 'true';
 455                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 456         } elsif ($_fetch_all) {
 457                 cmd_multi_fetch();
 458         } else {
 459                 $remote ||= $Git::SVN::default_repo_id;
 460                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 461         }
 462 }
 463
 464 sub cmd_set_tree {
 465         my (@commits) = @_;
 466         if ($_stdin || !@commits) {
 467                 print "Reading from stdin...\n";
 468                 @commits = ();
 469                 while (<STDIN>) {
 470                         if (/\b($sha1_short)\b/o) {
 471                                 unshift @commits, $1;
 472                         }
 473                 }
 474         }
 475         my @revs;
 476         foreach my $c (@commits) {
 477                 my @tmp = command('rev-parse',$c);
 478                 if (scalar @tmp == 1) {
 479                         push @revs, $tmp[0];
 480                 } elsif (scalar @tmp > 1) {
 481                         push @revs, reverse(command('rev-list',@tmp));
 482                 } else {
 483                         fatal "Failed to rev-parse $c";
 484                 }
 485         }
 486         my $gs = Git::SVN->new;
 487         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 488         $gs->fetch;
 489         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 490                 fatal "There are new revisions that were fetched ",
 491                       "and need to be merged (or acknowledged) ",
 492                       "before committing.\nlast rev: $r_last\n",
 493                       " current: $gs->{last_rev}";
 494         }
 495         $gs->set_tree($_) foreach @revs;
 496         print "Done committing ",scalar @revs," revisions to SVN\n";
 497         unlink $gs->{index};
 498 }
 499
 500 sub cmd_dcommit {
 501         my $head = shift;
 502         command_noisy(qw/update-index --refresh/);
 503         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 504                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 505                 . "or stash them with `git stash'.\n";
 506         $head ||= 'HEAD';
 507
 508         my $old_head;
 509         if ($head ne 'HEAD') {
 510                 $old_head = eval {
 511                         command_oneline([qw/symbolic-ref -q HEAD/])
 512                 };
 513                 if ($old_head) {
 514                         $old_head =~ s{^refs/heads/}{};
 515                 } else {
 516                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 517                 }
 518                 command(['checkout', $head], STDERR => 0);
 519         }
 520
 521         my @refs;
 522         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 523         unless ($gs) {
 524                 die "Unable to determine upstream SVN information from ",
 525                     "$head history.\nPerhaps the repository is empty.";
 526         }
 527
 528         if (defined $_commit_url) {
 529                 $url = $_commit_url;
 530         } else {
 531                 $url = eval { command_oneline('config', '--get',
 532                               "svn-remote.$gs->{repo_id}.commiturl") };
 533                 if (!$url) {
 534                         $url = $gs->full_pushurl
 535                 }
 536         }
 537
 538         my $last_rev = $_revision if defined $_revision;
 539         if ($url) {
 540                 print "Committing to $url ...\n";
 541         }
 542         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 543         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 544                 warn "Attempting to commit more than one change while ",
 545                      "--no-rebase is enabled.\n",
 546                      "If these changes depend on each other, re-running ",
 547                      "without --no-rebase may be required."
 548         }
 549         my $expect_url = $url;
 550         Git::SVN::remove_username($expect_url);
 551         while (1) {
 552                 my $d = shift @$linear_refs or last;
 553                 unless (defined $last_rev) {
 554                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 555                         unless (defined $last_rev) {
 556                                 fatal "Unable to extract revision information ",
 557                                       "from commit $d~1";
 558                         }
 559                 }
 560                 if ($_dry_run) {
 561                         print "diff-tree $d~1 $d\n";
 562                 } else {
 563                         my $cmt_rev;
 564                         my %ed_opts = ( r => $last_rev,
 565                                         log => get_commit_entry($d)->{log},
 566                                         ra => Git::SVN::Ra->new($url),
 567                                         config => SVN::Core::config_get_config(
 568                                                 $Git::SVN::Ra::config_dir
 569                                         ),
 570                                         tree_a => "$d~1",
 571                                         tree_b => $d,
 572                                         editor_cb => sub {
 573                                                print "Committed r$_[0]\n";
 574                                                $cmt_rev = $_[0];
 575                                         },
 576                                         mergeinfo => $_merge_info,
 577                                         svn_path => '');
 578                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 579                                 print "No changes\n$d~1 == $d\n";
 580                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 581                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 582                                                                $parents->{$d};
 583                         }
 584                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 585                         $last_rev = $cmt_rev;
 586                         next if $_no_rebase;
 587
 588                         # we always want to rebase against the current HEAD,
 589                         # not any head that was passed to us
 590                         my @diff = command('diff-tree', $d,
 591                                            $gs->refname, '--');
 592                         my @finish;
 593                         if (@diff) {
 594                                 @finish = rebase_cmd();
 595                                 print STDERR "W: $d and ", $gs->refname,
 596                                              " differ, using @finish:\n",
 597                                              join("\n", @diff), "\n";
 598                         } else {
 599                                 print "No changes between current HEAD and ",
 600                                       $gs->refname,
 601                                       "\nResetting to the latest ",
 602                                       $gs->refname, "\n";
 603                                 @finish = qw/reset --mixed/;
 604                         }
 605                         command_noisy(@finish, $gs->refname);
 606                         if (@diff) {
 607                                 @refs = ();
 608                                 my ($url_, $rev_, $uuid_, $gs_) =
 609                                               working_head_info('HEAD', \@refs);
 610                                 my ($linear_refs_, $parents_) =
 611                                               linearize_history($gs_, \@refs);
 612                                 if (scalar(@$linear_refs) !=
 613                                     scalar(@$linear_refs_)) {
 614                                         fatal "# of revisions changed ",
 615                                           "\nbefore:\n",
 616                                           join("\n", @$linear_refs),
 617                                           "\n\nafter:\n",
 618                                           join("\n", @$linear_refs_), "\n",
 619                                           'If you are attempting to commit ',
 620                                           "merges, try running:\n\t",
 621                                           'git rebase --interactive',
 622                                           '--preserve-merges ',
 623                                           $gs->refname,
 624                                           "\nBefore dcommitting";
 625                                 }
 626                                 if ($url_ ne $expect_url) {
 627                                         if ($url_ eq $gs->metadata_url) {
 628                                                 print
 629                                                   "Accepting rewritten URL:",
 630                                                   " $url_\n";
 631                                         } else {
 632                                                 fatal
 633                                                   "URL mismatch after rebase:",
 634                                                   " $url_ != $expect_url";
 635                                         }
 636                                 }
 637                                 if ($uuid_ ne $uuid) {
 638                                         fatal "uuid mismatch after rebase: ",
 639                                               "$uuid_ != $uuid";
 640                                 }
 641                                 # remap parents
 642                                 my (%p, @l, $i);
 643                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 644                                         my $new = $linear_refs_->[$i] or next;
 645                                         $p{$new} =
 646                                                 $parents->{$linear_refs->[$i]};
 647                                         push @l, $new;
 648                                 }
 649                                 $parents = \%p;
 650                                 $linear_refs = \@l;
 651                         }
 652                 }
 653         }
 654
 655         if ($old_head) {
 656                 my $new_head = command_oneline(qw/rev-parse HEAD/);
 657                 my $new_is_symbolic = eval {
 658                         command_oneline(qw/symbolic-ref -q HEAD/);
 659                 };
 660                 if ($new_is_symbolic) {
 661                         print "dcommitted the branch ", $head, "\n";
 662                 } else {
 663                         print "dcommitted on a detached HEAD because you gave ",
 664                               "a revision argument.\n",
 665                               "The rewritten commit is: ", $new_head, "\n";
 666                 }
 667                 command(['checkout', $old_head], STDERR => 0);
 668         }
 669
 670         unlink $gs->{index};
 671 }
 672
 673 sub cmd_branch {
 674         my ($branch_name, $head) = @_;
 675
 676         unless (defined $branch_name && length $branch_name) {
 677                 die(($_tag ? "tag" : "branch") . " name required\n");
 678         }
 679         $head ||= 'HEAD';
 680
 681         my (undef, $rev, undef, $gs) = working_head_info($head);
 682         my $src = $gs->full_pushurl;
 683
 684         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 685         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
 686         my $glob;
 687         if ($#{$allglobs} == 0) {
 688                 $glob = $allglobs->[0];
 689         } else {
 690                 unless(defined $_branch_dest) {
 691                         die "Multiple ",
 692                             $_tag ? "tag" : "branch",
 693                             " paths defined for Subversion repository.\n",
 694                             "You must specify where you want to create the ",
 695                             $_tag ? "tag" : "branch",
 696                             " with the --destination argument.\n";
 697                 }
 698                 foreach my $g (@{$allglobs}) {
 699                         # SVN::Git::Editor could probably be moved to Git.pm..
 700                         my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
 701                         if ($_branch_dest =~ /$re/) {
 702                                 $glob = $g;
 703                                 last;
 704                         }
 705                 }
 706                 unless (defined $glob) {
 707                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
 708                         foreach my $g (@{$allglobs}) {
 709                                 $g->{path}->{left} =~ /$dest_re/ or next;
 710                                 if (defined $glob) {
 711                                         die "Ambiguous destination: ",
 712                                             $_branch_dest, "\nmatches both '",
 713                                             $glob->{path}->{left}, "' and '",
 714                                             $g->{path}->{left}, "'\n";
 715                                 }
 716                                 $glob = $g;
 717                         }
 718                         unless (defined $glob) {
 719                                 die "Unknown ",
 720                                     $_tag ? "tag" : "branch",
 721                                     " destination $_branch_dest\n";
 722                         }
 723                 }
 724         }
 725         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 726         my $url;
 727         if (defined $_commit_url) {
 728                 $url = $_commit_url;
 729         } else {
 730                 $url = eval { command_oneline('config', '--get',
 731                         "svn-remote.$gs->{repo_id}.commiturl") };
 732                 if (!$url) {
 733                         $url = $remote->{pushurl} || $remote->{url};
 734                 }
 735         }
 736         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
 737
 738         if ($dst =~ /^https:/ && $src =~ /^http:/) {
 739                 $src=~s/^http:/https:/;
 740         }
 741
 742         ::_req_svn();
 743
 744         my $ctx = SVN::Client->new(
 745                 auth    => Git::SVN::Ra::_auth_providers(),
 746                 log_msg => sub {
 747                         ${ $_[0] } = defined $_message
 748                                 ? $_message
 749                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 750                                 . $branch_name;
 751                 },
 752         );
 753
 754         eval {
 755                 $ctx->ls($dst, 'HEAD', 0);
 756         } and die "branch ${branch_name} already exists\n";
 757
 758         print "Copying ${src} at r${rev} to ${dst}...\n";
 759         $ctx->copy($src, $rev, $dst)
 760                 unless $_dry_run;
 761
 762         $gs->fetch_all;
 763 }
 764
 765 sub cmd_find_rev {
 766         my $revision_or_hash = shift or die "SVN or git revision required ",
 767                                             "as a command-line argument\n";
 768         my $result;
 769         if ($revision_or_hash =~ /^r\d+$/) {
 770                 my $head = shift;
 771                 $head ||= 'HEAD';
 772                 my @refs;
 773                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 774                 unless ($gs) {
 775                         die "Unable to determine upstream SVN information from ",
 776                             "$head history\n";
 777                 }
 778                 my $desired_revision = substr($revision_or_hash, 1);
 779                 $result = $gs->rev_map_get($desired_revision, $uuid);
 780         } else {
 781                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 782                 $result = $rev;
 783         }
 784         print "$result\n" if $result;
 785 }
 786
 787 sub auto_create_empty_directories {
 788         my ($gs) = @_;
 789         my $var = eval { command_oneline('config', '--get', '--bool',
 790                                          "svn-remote.$gs->{repo_id}.automkdirs") };
 791         # By default, create empty directories by consulting the unhandled log,
 792         # but allow setting it to 'false' to skip it.
 793         return !($var && $var eq 'false');
 794 }
 795
 796 sub cmd_rebase {
 797         command_noisy(qw/update-index --refresh/);
 798         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 799         unless ($gs) {
 800                 die "Unable to determine upstream SVN information from ",
 801                     "working tree history\n";
 802         }
 803         if ($_dry_run) {
 804                 print "Remote Branch: " . $gs->refname . "\n";
 805                 print "SVN URL: " . $url . "\n";
 806                 return;
 807         }
 808         if (command(qw/diff-index HEAD --/)) {
 809                 print STDERR "Cannot rebase with uncommited changes:\n";
 810                 command_noisy('status');
 811                 exit 1;
 812         }
 813         unless ($_local) {
 814                 # rebase will checkout for us, so no need to do it explicitly
 815                 $_no_checkout = 'true';
 816                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 817         }
 818         command_noisy(rebase_cmd(), $gs->refname);
 819         if (auto_create_empty_directories($gs)) {
 820                 $gs->mkemptydirs;
 821         }
 822 }
 823
 824 sub cmd_show_ignore {
 825         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 826         $gs ||= Git::SVN->new;
 827         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 828         $gs->prop_walk($gs->{path}, $r, sub {
 829                 my ($gs, $path, $props) = @_;
 830                 print STDOUT "\n# $path\n";
 831                 my $s = $props->{'svn:ignore'} or return;
 832                 $s =~ s/[\r\n]+/\n/g;
 833                 $s =~ s/^\n+//;
 834                 chomp $s;
 835                 $s =~ s#^#$path#gm;
 836                 print STDOUT "$s\n";
 837         });
 838 }
 839
 840 sub cmd_show_externals {
 841         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 842         $gs ||= Git::SVN->new;
 843         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 844         $gs->prop_walk($gs->{path}, $r, sub {
 845                 my ($gs, $path, $props) = @_;
 846                 print STDOUT "\n# $path\n";
 847                 my $s = $props->{'svn:externals'} or return;
 848                 $s =~ s/[\r\n]+/\n/g;
 849                 chomp $s;
 850                 $s =~ s#^#$path#gm;
 851                 print STDOUT "$s\n";
 852         });
 853 }
 854
 855 sub cmd_create_ignore {
 856         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 857         $gs ||= Git::SVN->new;
 858         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 859         $gs->prop_walk($gs->{path}, $r, sub {
 860                 my ($gs, $path, $props) = @_;
 861                 # $path is of the form /path/to/dir/
 862                 $path = '.' . $path;
 863                 # SVN can have attributes on empty directories,
 864                 # which git won't track
 865                 mkpath([$path]) unless -d $path;
 866                 my $ignore = $path . '.gitignore';
 867                 my $s = $props->{'svn:ignore'} or return;
 868                 open(GITIGNORE, '>', $ignore)
 869                   or fatal("Failed to open `$ignore' for writing: $!");
 870                 $s =~ s/[\r\n]+/\n/g;
 871                 $s =~ s/^\n+//;
 872                 chomp $s;
 873                 # Prefix all patterns so that the ignore doesn't apply
 874                 # to sub-directories.
 875                 $s =~ s#^#/#gm;
 876                 print GITIGNORE "$s\n";
 877                 close(GITIGNORE)
 878                   or fatal("Failed to close `$ignore': $!");
 879                 command_noisy('add', '-f', $ignore);
 880         });
 881 }
 882
 883 sub cmd_mkdirs {
 884         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 885         $gs ||= Git::SVN->new;
 886         $gs->mkemptydirs($_revision);
 887 }
 888
 889 sub canonicalize_path {
 890         my ($path) = @_;
 891         my $dot_slash_added = 0;
 892         if (substr($path, 0, 1) ne "/") {
 893                 $path = "./" . $path;
 894                 $dot_slash_added = 1;
 895         }
 896         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 897         # good reason), so let's do this manually.
 898         $path =~ s#/+#/#g;
 899         $path =~ s#/\.(?:/|$)#/#g;
 900         $path =~ s#/[^/]+/\.\.##g;
 901         $path =~ s#/$##g;
 902         $path =~ s#^\./## if $dot_slash_added;
 903         $path =~ s#^/##;
 904         $path =~ s#^\.$##;
 905         return $path;
 906 }
 907
 908 sub canonicalize_url {
 909         my ($url) = @_;
 910         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 911         return $url;
 912 }
 913
 914 # get_svnprops(PATH)
 915 # ------------------
 916 # Helper for cmd_propget and cmd_proplist below.
 917 sub get_svnprops {
 918         my $path = shift;
 919         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 920         $gs ||= Git::SVN->new;
 921
 922         # prefix THE PATH by the sub-directory from which the user
 923         # invoked us.
 924         $path = $cmd_dir_prefix . $path;
 925         fatal("No such file or directory: $path") unless -e $path;
 926         my $is_dir = -d $path ? 1 : 0;
 927         $path = $gs->{path} . '/' . $path;
 928
 929         # canonicalize the path (otherwise libsvn will abort or fail to
 930         # find the file)
 931         $path = canonicalize_path($path);
 932
 933         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 934         my $props;
 935         if ($is_dir) {
 936                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 937         }
 938         else {
 939                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 940         }
 941         return $props;
 942 }
 943
 944 # cmd_propget (PROP, PATH)
 945 # ------------------------
 946 # Print the SVN property PROP for PATH.
 947 sub cmd_propget {
 948         my ($prop, $path) = @_;
 949         $path = '.' if not defined $path;
 950         usage(1) if not defined $prop;
 951         my $props = get_svnprops($path);
 952         if (not defined $props->{$prop}) {
 953                 fatal("`$path' does not have a `$prop' SVN property.");
 954         }
 955         print $props->{$prop} . "\n";
 956 }
 957
 958 # cmd_proplist (PATH)
 959 # -------------------
 960 # Print the list of SVN properties for PATH.
 961 sub cmd_proplist {
 962         my $path = shift;
 963         $path = '.' if not defined $path;
 964         my $props = get_svnprops($path);
 965         print "Properties on '$path':\n";
 966         foreach (sort keys %{$props}) {
 967                 print "  $_\n";
 968         }
 969 }
 970
 971 sub cmd_multi_init {
 972         my $url = shift;
 973         unless (defined $_trunk || @_branches || @_tags) {
 974                 usage(1);
 975         }
 976
 977         $_prefix = '' unless defined $_prefix;
 978         if (defined $url) {
 979                 $url = canonicalize_url($url);
 980                 init_subdir(@_);
 981         }
 982         do_git_init_db();
 983         if (defined $_trunk) {
 984                 $_trunk =~ s#^/+##;
 985                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
 986                 # try both old-style and new-style lookups:
 987                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 988                 unless ($gs_trunk) {
 989                         my ($trunk_url, $trunk_path) =
 990                                               complete_svn_url($url, $_trunk);
 991                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 992                                                    undef, $trunk_ref);
 993                 }
 994         }
 995         return unless @_branches || @_tags;
 996         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 997         foreach my $path (@_branches) {
 998                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
 999         }
1000         foreach my $path (@_tags) {
1001                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1002         }
1003 }
1004
1005 sub cmd_multi_fetch {
1006         $Git::SVN::no_reuse_existing = undef;
1007         my $remotes = Git::SVN::read_all_remotes();
1008         foreach my $repo_id (sort keys %$remotes) {
1009                 if ($remotes->{$repo_id}->{url}) {
1010                         Git::SVN::fetch_all($repo_id, $remotes);
1011                 }
1012         }
1013 }
1014
1015 # this command is special because it requires no metadata
1016 sub cmd_commit_diff {
1017         my ($ta, $tb, $url) = @_;
1018         my $usage = "Usage: $0 commit-diff -r<revision> ".
1019                     "<tree-ish> <tree-ish> [<URL>]";
1020         fatal($usage) if (!defined $ta || !defined $tb);
1021         my $svn_path = '';
1022         if (!defined $url) {
1023                 my $gs = eval { Git::SVN->new };
1024                 if (!$gs) {
1025                         fatal("Needed URL or usable git-svn --id in ",
1026                               "the command-line\n", $usage);
1027                 }
1028                 $url = $gs->{url};
1029                 $svn_path = $gs->{path};
1030         }
1031         unless (defined $_revision) {
1032                 fatal("-r|--revision is a required argument\n", $usage);
1033         }
1034         if (defined $_message && defined $_file) {
1035                 fatal("Both --message/-m and --file/-F specified ",
1036                       "for the commit message.\n",
1037                       "I have no idea what you mean");
1038         }
1039         if (defined $_file) {
1040                 $_message = file_to_s($_file);
1041         } else {
1042                 $_message ||= get_commit_entry($tb)->{log};
1043         }
1044         my $ra ||= Git::SVN::Ra->new($url);
1045         my $r = $_revision;
1046         if ($r eq 'HEAD') {
1047                 $r = $ra->get_latest_revnum;
1048         } elsif ($r !~ /^\d+$/) {
1049                 die "revision argument: $r not understood by git-svn\n";
1050         }
1051         my %ed_opts = ( r => $r,
1052                         log => $_message,
1053                         ra => $ra,
1054                         tree_a => $ta,
1055                         tree_b => $tb,
1056                         editor_cb => sub { print "Committed r$_[0]\n" },
1057                         svn_path => $svn_path );
1058         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1059                 print "No changes\n$ta == $tb\n";
1060         }
1061 }
1062
1063 sub escape_uri_only {
1064         my ($uri) = @_;
1065         my @tmp;
1066         foreach (split m{/}, $uri) {
1067                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1068                 push @tmp, $_;
1069         }
1070         join('/', @tmp);
1071 }
1072
1073 sub escape_url {
1074         my ($url) = @_;
1075         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1076                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1077                 $url = "$scheme://$domain$uri";
1078         }
1079         $url;
1080 }
1081
1082 sub cmd_info {
1083         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1084         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1085         if (exists $_[1]) {
1086                 die "Too many arguments specified\n";
1087         }
1088
1089         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1090
1091         if (!$file_type && !$diff_status) {
1092                 print STDERR "svn: '$path' is not under version control\n";
1093                 exit 1;
1094         }
1095
1096         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1097         unless ($gs) {
1098                 die "Unable to determine upstream SVN information from ",
1099                     "working tree history\n";
1100         }
1101
1102         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1103         $path = "." if $path eq "";
1104
1105         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1106
1107         if ($_url) {
1108                 print escape_url($full_url), "\n";
1109                 return;
1110         }
1111
1112         my $result = "Path: $path\n";
1113         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1114         $result .= "URL: " . escape_url($full_url) . "\n";
1115
1116         eval {
1117                 my $repos_root = $gs->repos_root;
1118                 Git::SVN::remove_username($repos_root);
1119                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1120         };
1121         if ($@) {
1122                 $result .= "Repository Root: (offline)\n";
1123         }
1124         ::_req_svn();
1125         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1126                 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1127         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1128
1129         $result .= "Node Kind: " .
1130                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1131
1132         my $schedule = $diff_status eq "A"
1133                        ? "add"
1134                        : ($diff_status eq "D" ? "delete" : "normal");
1135         $result .= "Schedule: $schedule\n";
1136
1137         if ($diff_status eq "A") {
1138                 print $result, "\n";
1139                 return;
1140         }
1141
1142         my ($lc_author, $lc_rev, $lc_date_utc);
1143         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1144         my $log = command_output_pipe(@args);
1145         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1146         while (<$log>) {
1147                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1148                         $lc_author = $1;
1149                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1150                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1151                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1152                 }
1153         }
1154         close $log;
1155
1156         Git::SVN::Log::set_local_timezone();
1157
1158         $result .= "Last Changed Author: $lc_author\n";
1159         $result .= "Last Changed Rev: $lc_rev\n";
1160         $result .= "Last Changed Date: " .
1161                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1162
1163         if ($file_type ne "dir") {
1164                 my $text_last_updated_date =
1165                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1166                 $result .=
1167                     "Text Last Updated: " .
1168                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1169                     "\n";
1170                 my $checksum;
1171                 if ($diff_status eq "D") {
1172                         my ($fh, $ctx) =
1173                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1174                         if ($file_type eq "link") {
1175                                 my $file_name = <$fh>;
1176                                 $checksum = md5sum("link $file_name");
1177                         } else {
1178                                 $checksum = md5sum($fh);
1179                         }
1180                         command_close_pipe($fh, $ctx);
1181                 } elsif ($file_type eq "link") {
1182                         my $file_name =
1183                             command(qw(cat-file blob), "HEAD:$path");
1184                         $checksum =
1185                             md5sum("link " . $file_name);
1186                 } else {
1187                         open FILE, "<", $path or die $!;
1188                         $checksum = md5sum(\*FILE);
1189                         close FILE or die $!;
1190                 }
1191                 $result .= "Checksum: " . $checksum . "\n";
1192         }
1193
1194         print $result, "\n";
1195 }
1196
1197 sub cmd_reset {
1198         my $target = shift || $_revision or die "SVN revision required\n";
1199         $target = $1 if $target =~ /^r(\d+)$/;
1200         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1201         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1202         unless ($gs) {
1203                 die "Unable to determine upstream SVN information from ".
1204                     "history\n";
1205         }
1206         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1207         die "Cannot find SVN revision $target\n" unless defined($c);
1208         $gs->rev_map_set($r, $c, 'reset', $uuid);
1209         print "r$r = $c ($gs->{ref_id})\n";
1210 }
1211
1212 sub cmd_gc {
1213         if (!$can_compress) {
1214                 warn "Compress::Zlib could not be found; unhandled.log " .
1215                      "files will not be compressed.\n";
1216         }
1217         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1218 }
1219
1220 ########################### utility functions #########################
1221
1222 sub rebase_cmd {
1223         my @cmd = qw/rebase/;
1224         push @cmd, '-v' if $_verbose;
1225         push @cmd, qw/--merge/ if $_merge;
1226         push @cmd, "--strategy=$_strategy" if $_strategy;
1227         @cmd;
1228 }
1229
1230 sub post_fetch_checkout {
1231         return if $_no_checkout;
1232         my $gs = $Git::SVN::_head or return;
1233         return if verify_ref('refs/heads/master^0');
1234
1235         # look for "trunk" ref if it exists
1236         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1237         my $fetch = $remote->{fetch};
1238         if ($fetch) {
1239                 foreach my $p (keys %$fetch) {
1240                         basename($fetch->{$p}) eq 'trunk' or next;
1241                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1242                         last;
1243                 }
1244         }
1245
1246         my $valid_head = verify_ref('HEAD^0');
1247         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1248         return if ($valid_head || !verify_ref('HEAD^0'));
1249
1250         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1251         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1252         return if -f $index;
1253
1254         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1255         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1256         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1257         print STDERR "Checked out HEAD:\n  ",
1258                      $gs->full_url, " r", $gs->last_rev, "\n";
1259         if (auto_create_empty_directories($gs)) {
1260                 $gs->mkemptydirs($gs->last_rev);
1261         }
1262 }
1263
1264 sub complete_svn_url {
1265         my ($url, $path) = @_;
1266         $path =~ s#/+$##;
1267         if ($path !~ m#^[a-z\+]+://#) {
1268                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1269                         fatal("E: '$path' is not a complete URL ",
1270                               "and a separate URL is not specified");
1271                 }
1272                 return ($url, $path);
1273         }
1274         return ($path, '');
1275 }
1276
1277 sub complete_url_ls_init {
1278         my ($ra, $repo_path, $switch, $pfx) = @_;
1279         unless ($repo_path) {
1280                 print STDERR "W: $switch not specified\n";
1281                 return;
1282         }
1283         $repo_path =~ s#/+$##;
1284         if ($repo_path =~ m#^[a-z\+]+://#) {
1285                 $ra = Git::SVN::Ra->new($repo_path);
1286                 $repo_path = '';
1287         } else {
1288                 $repo_path =~ s#^/+##;
1289                 unless ($ra) {
1290                         fatal("E: '$repo_path' is not a complete URL ",
1291                               "and a separate URL is not specified");
1292                 }
1293         }
1294         my $url = $ra->{url};
1295         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1296         my $k = "svn-remote.$gs->{repo_id}.url";
1297         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1298         if ($orig_url && ($orig_url ne $gs->{url})) {
1299                 die "$k already set: $orig_url\n",
1300                     "wanted to set to: $gs->{url}\n";
1301         }
1302         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1303         my $remote_path = "$gs->{path}/$repo_path";
1304         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1305         $remote_path =~ s#/+#/#g;
1306         $remote_path =~ s#^/##g;
1307         $remote_path .= "/*" if $remote_path !~ /\*/;
1308         my ($n) = ($switch =~ /^--(\w+)/);
1309         if (length $pfx && $pfx !~ m#/$#) {
1310                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1311         }
1312         command_noisy('config',
1313                       '--add',
1314                       "svn-remote.$gs->{repo_id}.$n",
1315                       "$remote_path:refs/remotes/$pfx*" .
1316                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1317 }
1318
1319 sub verify_ref {
1320         my ($ref) = @_;
1321         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1322                                { STDERR => 0 }); };
1323 }
1324
1325 sub get_tree_from_treeish {
1326         my ($treeish) = @_;
1327         # $treeish can be a symbolic ref, too:
1328         my $type = command_oneline(qw/cat-file -t/, $treeish);
1329         my $expected;
1330         while ($type eq 'tag') {
1331                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1332         }
1333         if ($type eq 'commit') {
1334                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1335                                                     $treeish))[0];
1336                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1337                 die "Unable to get tree from $treeish\n" unless $expected;
1338         } elsif ($type eq 'tree') {
1339                 $expected = $treeish;
1340         } else {
1341                 die "$treeish is a $type, expected tree, tag or commit\n";
1342         }
1343         return $expected;
1344 }
1345
1346 sub get_commit_entry {
1347         my ($treeish) = shift;
1348         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1349         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1350         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1351         open my $log_fh, '>', $commit_editmsg or croak $!;
1352
1353         my $type = command_oneline(qw/cat-file -t/, $treeish);
1354         if ($type eq 'commit' || $type eq 'tag') {
1355                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1356                                                          $type, $treeish);
1357                 my $in_msg = 0;
1358                 my $author;
1359                 my $saw_from = 0;
1360                 my $msgbuf = "";
1361                 while (<$msg_fh>) {
1362                         if (!$in_msg) {
1363                                 $in_msg = 1 if (/^\s*$/);
1364                                 $author = $1 if (/^author (.*>)/);
1365                         } elsif (/^git-svn-id: /) {
1366                                 # skip this for now, we regenerate the
1367                                 # correct one on re-fetch anyways
1368                                 # TODO: set *:merge properties or like...
1369                         } else {
1370                                 if (/^From:/ || /^Signed-off-by:/) {
1371                                         $saw_from = 1;
1372                                 }
1373                                 $msgbuf .= $_;
1374                         }
1375                 }
1376                 $msgbuf =~ s/\s+$//s;
1377                 if ($Git::SVN::_add_author_from && defined($author)
1378                     && !$saw_from) {
1379                         $msgbuf .= "\n\nFrom: $author";
1380                 }
1381                 print $log_fh $msgbuf or croak $!;
1382                 command_close_pipe($msg_fh, $ctx);
1383         }
1384         close $log_fh or croak $!;
1385
1386         if ($_edit || ($type eq 'tree')) {
1387                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1388                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1389         }
1390         rename $commit_editmsg, $commit_msg or croak $!;
1391         {
1392                 require Encode;
1393                 # SVN requires messages to be UTF-8 when entering the repo
1394                 local $/;
1395                 open $log_fh, '<', $commit_msg or croak $!;
1396                 binmode $log_fh;
1397                 chomp($log_entry{log} = <$log_fh>);
1398
1399                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1400                 my $msg = $log_entry{log};
1401
1402                 eval { $msg = Encode::decode($enc, $msg, 1) };
1403                 if ($@) {
1404                         die "Could not decode as $enc:\n", $msg,
1405                             "\nPerhaps you need to set i18n.commitencoding\n";
1406                 }
1407
1408                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1409                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1410
1411                 $log_entry{log} = $msg;
1412
1413                 close $log_fh or croak $!;
1414         }
1415         unlink $commit_msg;
1416         \%log_entry;
1417 }
1418
1419 sub s_to_file {
1420         my ($str, $file, $mode) = @_;
1421         open my $fd,'>',$file or croak $!;
1422         print $fd $str,"\n" or croak $!;
1423         close $fd or croak $!;
1424         chmod ($mode &~ umask, $file) if (defined $mode);
1425 }
1426
1427 sub file_to_s {
1428         my $file = shift;
1429         open my $fd,'<',$file or croak "$!: file: $file\n";
1430         local $/;
1431         my $ret = <$fd>;
1432         close $fd or croak $!;
1433         $ret =~ s/\s*$//s;
1434         return $ret;
1435 }
1436
1437 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1438 sub load_authors {
1439         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1440         my $log = $cmd eq 'log';
1441         while (<$authors>) {
1442                 chomp;
1443                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1444                 my ($user, $name, $email) = ($1, $2, $3);
1445                 if ($log) {
1446                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1447                 } else {
1448                         $users{$user} = [$name, $email];
1449                 }
1450         }
1451         close $authors or croak $!;
1452 }
1453
1454 # convert GetOpt::Long specs for use by git-config
1455 sub read_git_config {
1456         my $opts = shift;
1457         my @config_only;
1458         foreach my $o (keys %$opts) {
1459                 # if we have mixedCase and a long option-only, then
1460                 # it's a config-only variable that we don't need for
1461                 # the command-line.
1462                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1463                 my $v = $opts->{$o};
1464                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1465                 $key =~ s/-//g;
1466                 my $arg = 'git config';
1467                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1468                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1469                 if (ref $v eq 'ARRAY') {
1470                         chomp(my @tmp = `$arg --get-all svn.$key`);
1471                         @$v = @tmp if @tmp;
1472                 } else {
1473                         chomp(my $tmp = `$arg --get svn.$key`);
1474                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1475                                 $$v = $tmp;
1476                         }
1477                 }
1478         }
1479         delete @$opts{@config_only} if @config_only;
1480 }
1481
1482 sub extract_metadata {
1483         my $id = shift or return (undef, undef, undef);
1484         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1485                                                         \s([a-f\d\-]+)$/ix);
1486         if (!defined $rev || !$uuid || !$url) {
1487                 # some of the original repositories I made had
1488                 # identifiers like this:
1489                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1490         }
1491         return ($url, $rev, $uuid);
1492 }
1493
1494 sub cmt_metadata {
1495         return extract_metadata((grep(/^git-svn-id: /,
1496                 command(qw/cat-file commit/, shift)))[-1]);
1497 }
1498
1499 sub cmt_sha2rev_batch {
1500         my %s2r;
1501         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1502         my $list = shift;
1503
1504         foreach my $sha (@{$list}) {
1505                 my $first = 1;
1506                 my $size = 0;
1507                 print $out $sha, "\n";
1508
1509                 while (my $line = <$in>) {
1510                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1511                                 last;
1512                         } elsif ($first &&
1513                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1514                                 $first = 0;
1515                                 $size = $1;
1516                                 next;
1517                         } elsif ($line =~ /^(git-svn-id: )/) {
1518                                 my (undef, $rev, undef) =
1519                                                       extract_metadata($line);
1520                                 $s2r{$sha} = $rev;
1521                         }
1522
1523                         $size -= length($line);
1524                         last if ($size == 0);
1525                 }
1526         }
1527
1528         command_close_bidi_pipe($pid, $in, $out, $ctx);
1529
1530         return \%s2r;
1531 }
1532
1533 sub working_head_info {
1534         my ($head, $refs) = @_;
1535         my @args = qw/log --no-color --no-decorate --first-parent
1536                       --pretty=medium/;
1537         my ($fh, $ctx) = command_output_pipe(@args, $head);
1538         my $hash;
1539         my %max;
1540         while (<$fh>) {
1541                 if ( m{^commit ($::sha1)$} ) {
1542                         unshift @$refs, $hash if $hash and $refs;
1543                         $hash = $1;
1544                         next;
1545                 }
1546                 next unless s{^\s*(git-svn-id:)}{$1};
1547                 my ($url, $rev, $uuid) = extract_metadata($_);
1548                 if (defined $url && defined $rev) {
1549                         next if $max{$url} and $max{$url} < $rev;
1550                         if (my $gs = Git::SVN->find_by_url($url)) {
1551                                 my $c = $gs->rev_map_get($rev, $uuid);
1552                                 if ($c && $c eq $hash) {
1553                                         close $fh; # break the pipe
1554                                         return ($url, $rev, $uuid, $gs);
1555                                 } else {
1556                                         $max{$url} ||= $gs->rev_map_max;
1557                                 }
1558                         }
1559                 }
1560         }
1561         command_close_pipe($fh, $ctx);
1562         (undef, undef, undef, undef);
1563 }
1564
1565 sub read_commit_parents {
1566         my ($parents, $c) = @_;
1567         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1568         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1569         @{$parents->{$c}} = split(/ /, $p);
1570 }
1571
1572 sub linearize_history {
1573         my ($gs, $refs) = @_;
1574         my %parents;
1575         foreach my $c (@$refs) {
1576                 read_commit_parents(\%parents, $c);
1577         }
1578
1579         my @linear_refs;
1580         my %skip = ();
1581         my $last_svn_commit = $gs->last_commit;
1582         foreach my $c (reverse @$refs) {
1583                 next if $c eq $last_svn_commit;
1584                 last if $skip{$c};
1585
1586                 unshift @linear_refs, $c;
1587                 $skip{$c} = 1;
1588
1589                 # we only want the first parent to diff against for linear
1590                 # history, we save the rest to inject when we finalize the
1591                 # svn commit
1592                 my $fp_a = verify_ref("$c~1");
1593                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1594                 if (!$fp_a || !$fp_b) {
1595                         die "Commit $c\n",
1596                             "has no parent commit, and therefore ",
1597                             "nothing to diff against.\n",
1598                             "You should be working from a repository ",
1599                             "originally created by git-svn\n";
1600                 }
1601                 if ($fp_a ne $fp_b) {
1602                         die "$c~1 = $fp_a, however parsing commit $c ",
1603                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1604                 }
1605
1606                 foreach my $p (@{$parents{$c}}) {
1607                         $skip{$p} = 1;
1608                 }
1609         }
1610         (\@linear_refs, \%parents);
1611 }
1612
1613 sub find_file_type_and_diff_status {
1614         my ($path) = @_;
1615         return ('dir', '') if $path eq '';
1616
1617         my $diff_output =
1618             command_oneline(qw(diff --cached --name-status --), $path) || "";
1619         my $diff_status = (split(' ', $diff_output))[0] || "";
1620
1621         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1622
1623         return (undef, undef) if !$diff_status && !$ls_tree;
1624
1625         if ($diff_status eq "A") {
1626                 return ("link", $diff_status) if -l $path;
1627                 return ("dir", $diff_status) if -d $path;
1628                 return ("file", $diff_status);
1629         }
1630
1631         my $mode = (split(' ', $ls_tree))[0] || "";
1632
1633         return ("link", $diff_status) if $mode eq "120000";
1634         return ("dir", $diff_status) if $mode eq "040000";
1635         return ("file", $diff_status);
1636 }
1637
1638 sub md5sum {
1639         my $arg = shift;
1640         my $ref = ref $arg;
1641         my $md5 = Digest::MD5->new();
1642         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1643                 $md5->addfile($arg) or croak $!;
1644         } elsif ($ref eq 'SCALAR') {
1645                 $md5->add($$arg) or croak $!;
1646         } elsif (!$ref) {
1647                 $md5->add($arg) or croak $!;
1648         } else {
1649                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1650         }
1651         return $md5->hexdigest();
1652 }
1653
1654 sub gc_directory {
1655         if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1656                 my $out_filename = $_ . ".gz";
1657                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1658                 binmode $in_fh;
1659                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1660                                 die "Unable to open $out_filename: $!\n";
1661
1662                 my $res;
1663                 while ($res = sysread($in_fh, my $str, 1024)) {
1664                         $gz->gzwrite($str) or
1665                                 die "Unable to write: ".$gz->gzerror()."!\n";
1666                 }
1667                 unlink $_ or die "unlink $File::Find::name: $!\n";
1668         } elsif (-f $_ && basename($_) eq "index") {
1669                 unlink $_ or die "unlink $_: $!\n";
1670         }
1671 }
1672
1673 package Git::SVN;
1674 use strict;
1675 use warnings;
1676 use Fcntl qw/:DEFAULT :seek/;
1677 use constant rev_map_fmt => 'NH40';
1678 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1679             $_repack $_repack_flags $_use_svm_props $_head
1680             $_use_svnsync_props $no_reuse_existing $_minimize_url
1681             $_use_log_author $_add_author_from $_localtime/;
1682 use Carp qw/croak/;
1683 use File::Path qw/mkpath/;
1684 use File::Copy qw/copy/;
1685 use IPC::Open3;
1686 use Memoize;  # core since 5.8.0, Jul 2002
1687 use Memoize::Storable;
1688
1689 my ($_gc_nr, $_gc_period);
1690
1691 # properties that we do not log:
1692 my %SKIP_PROP;
1693 BEGIN {
1694         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1695                                         svn:special svn:executable
1696                                         svn:entry:committed-rev
1697                                         svn:entry:last-author
1698                                         svn:entry:uuid
1699                                         svn:entry:committed-date/;
1700
1701         # some options are read globally, but can be overridden locally
1702         # per [svn-remote "..."] section.  Command-line options will *NOT*
1703         # override options set in an [svn-remote "..."] section
1704         no strict 'refs';
1705         for my $option (qw/follow_parent no_metadata use_svm_props
1706                            use_svnsync_props/) {
1707                 my $key = $option;
1708                 $key =~ tr/_//d;
1709                 my $prop = "-$option";
1710                 *$option = sub {
1711                         my ($self) = @_;
1712                         return $self->{$prop} if exists $self->{$prop};
1713                         my $k = "svn-remote.$self->{repo_id}.$key";
1714                         eval { command_oneline(qw/config --get/, $k) };
1715                         if ($@) {
1716                                 $self->{$prop} = ${"Git::SVN::_$option"};
1717                         } else {
1718                                 my $v = command_oneline(qw/config --bool/,$k);
1719                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1720                         }
1721                         return $self->{$prop};
1722                 }
1723         }
1724 }
1725
1726
1727 my (%LOCKFILES, %INDEX_FILES);
1728 END {
1729         unlink keys %LOCKFILES if %LOCKFILES;
1730         unlink keys %INDEX_FILES if %INDEX_FILES;
1731 }
1732
1733 sub resolve_local_globs {
1734         my ($url, $fetch, $glob_spec) = @_;
1735         return unless defined $glob_spec;
1736         my $ref = $glob_spec->{ref};
1737         my $path = $glob_spec->{path};
1738         foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
1739                 next unless m#^$ref->{regex}$#;
1740                 my $p = $1;
1741                 my $pathname = desanitize_refname($path->full_path($p));
1742                 my $refname = desanitize_refname($ref->full_path($p));
1743                 if (my $existing = $fetch->{$pathname}) {
1744                         if ($existing ne $refname) {
1745                                 die "Refspec conflict:\n",
1746                                     "existing: $existing\n",
1747                                     " globbed: $refname\n";
1748                         }
1749                         my $u = (::cmt_metadata("$refname"))[0];
1750                         $u =~ s!^\Q$url\E(/|$)!! or die
1751                           "$refname: '$url' not found in '$u'\n";
1752                         if ($pathname ne $u) {
1753                                 warn "W: Refspec glob conflict ",
1754                                      "(ref: $refname):\n",
1755                                      "expected path: $pathname\n",
1756                                      "    real path: $u\n",
1757                                      "Continuing ahead with $u\n";
1758                                 next;
1759                         }
1760                 } else {
1761                         $fetch->{$pathname} = $refname;
1762                 }
1763         }
1764 }
1765
1766 sub parse_revision_argument {
1767         my ($base, $head) = @_;
1768         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1769                 return ($base, $head);
1770         }
1771         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1772         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1773         return ($head, $head) if ($::_revision eq 'HEAD');
1774         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1775         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1776         die "revision argument: $::_revision not understood by git-svn\n";
1777 }
1778
1779 sub fetch_all {
1780         my ($repo_id, $remotes) = @_;
1781         if (ref $repo_id) {
1782                 my $gs = $repo_id;
1783                 $repo_id = undef;
1784                 $repo_id = $gs->{repo_id};
1785         }
1786         $remotes ||= read_all_remotes();
1787         my $remote = $remotes->{$repo_id} or
1788                      die "[svn-remote \"$repo_id\"] unknown\n";
1789         my $fetch = $remote->{fetch};
1790         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1791         my (@gs, @globs);
1792         my $ra = Git::SVN::Ra->new($url);
1793         my $uuid = $ra->get_uuid;
1794         my $head = $ra->get_latest_revnum;
1795
1796         # ignore errors, $head revision may not even exist anymore
1797         eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
1798         warn "W: $@\n" if $@;
1799
1800         my $base = defined $fetch ? $head : 0;
1801
1802         # read the max revs for wildcard expansion (branches/*, tags/*)
1803         foreach my $t (qw/branches tags/) {
1804                 defined $remote->{$t} or next;
1805                 push @globs, @{$remote->{$t}};
1806
1807                 my $max_rev = eval { tmp_config(qw/--int --get/,
1808                                          "svn-remote.$repo_id.${t}-maxRev") };
1809                 if (defined $max_rev && ($max_rev < $base)) {
1810                         $base = $max_rev;
1811                 } elsif (!defined $max_rev) {
1812                         $base = 0;
1813                 }
1814         }
1815
1816         if ($fetch) {
1817                 foreach my $p (sort keys %$fetch) {
1818                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1819                         my $lr = $gs->rev_map_max;
1820                         if (defined $lr) {
1821                                 $base = $lr if ($lr < $base);
1822                         }
1823                         push @gs, $gs;
1824                 }
1825         }
1826
1827         ($base, $head) = parse_revision_argument($base, $head);
1828         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1829 }
1830
1831 sub read_all_remotes {
1832         my $r = {};
1833         my $use_svm_props = eval { command_oneline(qw/config --bool
1834             svn.useSvmProps/) };
1835         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1836         my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
1837         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1838                 if (m!^(.+)\.fetch=$svn_refspec$!) {
1839                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1840                         die("svn-remote.$remote: remote ref '$remote_ref' "
1841                             . "must start with 'refs/'\n")
1842                                 unless $remote_ref =~ m{^refs/};
1843                         $local_ref = uri_decode($local_ref);
1844                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1845                         $r->{$remote}->{svm} = {} if $use_svm_props;
1846                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1847                         $r->{$1}->{svm} = {};
1848                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1849                         $r->{$1}->{url} = $2;
1850                 } elsif (m!^(.+)\.pushurl=\s*(.*)\s*$!) {
1851                         $r->{$1}->{pushurl} = $2;
1852                 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
1853                         my ($remote, $t, $local_ref, $remote_ref) =
1854                                                              ($1, $2, $3, $4);
1855                         die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
1856                             . "must start with 'refs/'\n")
1857                                 unless $remote_ref =~ m{^refs/};
1858                         $local_ref = uri_decode($local_ref);
1859                         my $rs = {
1860                             t => $t,
1861                             remote => $remote,
1862                             path => Git::SVN::GlobSpec->new($local_ref, 1),
1863                             ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
1864                         if (length($rs->{ref}->{right}) != 0) {
1865                                 die "The '*' glob character must be the last ",
1866                                     "character of '$remote_ref'\n";
1867                         }
1868                         push @{ $r->{$remote}->{$t} }, $rs;
1869                 }
1870         }
1871
1872         map {
1873                 if (defined $r->{$_}->{svm}) {
1874                         my $svm;
1875                         eval {
1876                                 my $section = "svn-remote.$_";
1877                                 $svm = {
1878                                         source => tmp_config('--get',
1879                                             "$section.svm-source"),
1880                                         replace => tmp_config('--get',
1881                                             "$section.svm-replace"),
1882                                 }
1883                         };
1884                         $r->{$_}->{svm} = $svm;
1885                 }
1886         } keys %$r;
1887
1888         $r;
1889 }
1890
1891 sub init_vars {
1892         $_gc_nr = $_gc_period = 1000;
1893         if (defined $_repack || defined $_repack_flags) {
1894                warn "Repack options are obsolete; they have no effect.\n";
1895         }
1896 }
1897
1898 sub verify_remotes_sanity {
1899         return unless -d $ENV{GIT_DIR};
1900         my %seen;
1901         foreach (command(qw/config -l/)) {
1902                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1903                         if ($seen{$1}) {
1904                                 die "Remote ref refs/remote/$1 is tracked by",
1905                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1906                                     "Please resolve this ambiguity in ",
1907                                     "your git configuration file before ",
1908                                     "continuing\n";
1909                         }
1910                         $seen{$1} = $_;
1911                 }
1912         }
1913 }
1914
1915 sub find_existing_remote {
1916         my ($url, $remotes) = @_;
1917         return undef if $no_reuse_existing;
1918         my $existing;
1919         foreach my $repo_id (keys %$remotes) {
1920                 my $u = $remotes->{$repo_id}->{url} or next;
1921                 next if $u ne $url;
1922                 $existing = $repo_id;
1923                 last;
1924         }
1925         $existing;
1926 }
1927
1928 sub init_remote_config {
1929         my ($self, $url, $no_write) = @_;
1930         $url =~ s!/+$!!; # strip trailing slash
1931         my $r = read_all_remotes();
1932         my $existing = find_existing_remote($url, $r);
1933         if ($existing) {
1934                 unless ($no_write) {
1935                         print STDERR "Using existing ",
1936                                      "[svn-remote \"$existing\"]\n";
1937                 }
1938                 $self->{repo_id} = $existing;
1939         } elsif ($_minimize_url) {
1940                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1941                 $existing = find_existing_remote($min_url, $r);
1942                 if ($existing) {
1943                         unless ($no_write) {
1944                                 print STDERR "Using existing ",
1945                                              "[svn-remote \"$existing\"]\n";
1946                         }
1947                         $self->{repo_id} = $existing;
1948                 }
1949                 if ($min_url ne $url) {
1950                         unless ($no_write) {
1951                                 print STDERR "Using higher level of URL: ",
1952                                              "$url => $min_url\n";
1953                         }
1954                         my $old_path = $self->{path};
1955                         $self->{path} = $url;
1956                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1957                         if (length $old_path) {
1958                                 $self->{path} .= "/$old_path";
1959                         }
1960                         $url = $min_url;
1961                 }
1962         }
1963         my $orig_url;
1964         if (!$existing) {
1965                 # verify that we aren't overwriting anything:
1966                 $orig_url = eval {
1967                         command_oneline('config', '--get',
1968                                         "svn-remote.$self->{repo_id}.url")
1969                 };
1970                 if ($orig_url && ($orig_url ne $url)) {
1971                         die "svn-remote.$self->{repo_id}.url already set: ",
1972                             "$orig_url\nwanted to set to: $url\n";
1973                 }
1974         }
1975         my ($xrepo_id, $xpath) = find_ref($self->refname);
1976         if (!$no_write && defined $xpath) {
1977                 die "svn-remote.$xrepo_id.fetch already set to track ",
1978                     "$xpath:", $self->refname, "\n";
1979         }
1980         unless ($no_write) {
1981                 command_noisy('config',
1982                               "svn-remote.$self->{repo_id}.url", $url);
1983                 $self->{path} =~ s{^/}{};
1984                 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1985                 command_noisy('config', '--add',
1986                               "svn-remote.$self->{repo_id}.fetch",
1987                               "$self->{path}:".$self->refname);
1988         }
1989         $self->{url} = $url;
1990 }
1991
1992 sub find_by_url { # repos_root and, path are optional
1993         my ($class, $full_url, $repos_root, $path) = @_;
1994
1995         return undef unless defined $full_url;
1996         remove_username($full_url);
1997         remove_username($repos_root) if defined $repos_root;
1998         my $remotes = read_all_remotes();
1999         if (defined $full_url && defined $repos_root && !defined $path) {
2000                 $path = $full_url;
2001                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
2002         }
2003         foreach my $repo_id (keys %$remotes) {
2004                 my $u = $remotes->{$repo_id}->{url} or next;
2005                 remove_username($u);
2006                 next if defined $repos_root && $repos_root ne $u;
2007
2008                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
2009                 foreach my $t (qw/branches tags/) {
2010                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
2011                                 resolve_local_globs($u, $fetch, $globspec);
2012                         }
2013                 }
2014                 my $p = $path;
2015                 my $rwr = rewrite_root({repo_id => $repo_id});
2016                 my $svm = $remotes->{$repo_id}->{svm}
2017                         if defined $remotes->{$repo_id}->{svm};
2018                 unless (defined $p) {
2019                         $p = $full_url;
2020                         my $z = $u;
2021                         my $prefix = '';
2022                         if ($rwr) {
2023                                 $z = $rwr;
2024                                 remove_username($z);
2025                         } elsif (defined $svm) {
2026                                 $z = $svm->{source};
2027                                 $prefix = $svm->{replace};
2028                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
2029                                 $prefix =~ s#/$##;
2030                         }
2031                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
2032                 }
2033                 foreach my $f (keys %$fetch) {
2034                         next if $f ne $p;
2035                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
2036                 }
2037         }
2038         undef;
2039 }
2040
2041 sub init {
2042         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
2043         my $self = _new($class, $repo_id, $ref_id, $path);
2044         if (defined $url) {
2045                 $self->init_remote_config($url, $no_write);
2046         }
2047         $self;
2048 }
2049
2050 sub find_ref {
2051         my ($ref_id) = @_;
2052         foreach (command(qw/config -l/)) {
2053                 next unless m!^svn-remote\.(.+)\.fetch=
2054                               \s*(.*?)\s*:\s*(.+?)\s*$!x;
2055                 my ($repo_id, $path, $ref) = ($1, $2, $3);
2056                 if ($ref eq $ref_id) {
2057                         $path = '' if ($path =~ m#^\./?#);
2058                         return ($repo_id, $path);
2059                 }
2060         }
2061         (undef, undef, undef);
2062 }
2063
2064 sub new {
2065         my ($class, $ref_id, $repo_id, $path) = @_;
2066         if (defined $ref_id && !defined $repo_id && !defined $path) {
2067                 ($repo_id, $path) = find_ref($ref_id);
2068                 if (!defined $repo_id) {
2069                         die "Could not find a \"svn-remote.*.fetch\" key ",
2070                             "in the repository configuration matching: ",
2071                             "$ref_id\n";
2072                 }
2073         }
2074         my $self = _new($class, $repo_id, $ref_id, $path);
2075         if (!defined $self->{path} || !length $self->{path}) {
2076                 my $fetch = command_oneline('config', '--get',
2077                                             "svn-remote.$repo_id.fetch",
2078                                             ":$ref_id\$") or
2079                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
2080                          "\":$ref_id\$\" in config\n";
2081                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
2082         }
2083         $self->{path} =~ s{/+}{/}g;
2084         $self->{path} =~ s{\A/}{};
2085         $self->{path} =~ s{/\z}{};
2086         $self->{url} = command_oneline('config', '--get',
2087                                        "svn-remote.$repo_id.url") or
2088                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
2089         $self->{pushurl} = eval { command_oneline('config', '--get',
2090                                   "svn-remote.$repo_id.pushurl") };
2091         $self->rebuild;
2092         $self;
2093 }
2094
2095 sub refname {
2096         my ($refname) = $_[0]->{ref_id} ;
2097
2098         # It cannot end with a slash /, we'll throw up on this because
2099         # SVN can't have directories with a slash in their name, either:
2100         if ($refname =~ m{/$}) {
2101                 die "ref: '$refname' ends with a trailing slash, this is ",
2102                     "not permitted by git nor Subversion\n";
2103         }
2104
2105         # It cannot have ASCII control character space, tilde ~, caret ^,
2106         # colon :, question-mark ?, asterisk *, space, or open bracket [
2107         # anywhere.
2108         #
2109         # Additionally, % must be escaped because it is used for escaping
2110         # and we want our escaped refname to be reversible
2111         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2112
2113         # no slash-separated component can begin with a dot .
2114         # /.* becomes /%2E*
2115         $refname =~ s{/\.}{/%2E}g;
2116
2117         # It cannot have two consecutive dots .. anywhere
2118         # .. becomes %2E%2E
2119         $refname =~ s{\.\.}{%2E%2E}g;
2120
2121         # trailing dots and .lock are not allowed
2122         # .$ becomes %2E and .lock becomes %2Elock
2123         $refname =~ s{\.(?=$|lock$)}{%2E};
2124
2125         # the sequence @{ is used to access the reflog
2126         # @{ becomes %40{
2127         $refname =~ s{\@\{}{%40\{}g;
2128
2129         return $refname;
2130 }
2131
2132 sub desanitize_refname {
2133         my ($refname) = @_;
2134         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2135         return $refname;
2136 }
2137
2138 sub svm_uuid {
2139         my ($self) = @_;
2140         return $self->{svm}->{uuid} if $self->svm;
2141         $self->ra;
2142         unless ($self->{svm}) {
2143                 die "SVM UUID not cached, and reading remotely failed\n";
2144         }
2145         $self->{svm}->{uuid};
2146 }
2147
2148 sub svm {
2149         my ($self) = @_;
2150         return $self->{svm} if $self->{svm};
2151         my $svm;
2152         # see if we have it in our config, first:
2153         eval {
2154                 my $section = "svn-remote.$self->{repo_id}";
2155                 $svm = {
2156                   source => tmp_config('--get', "$section.svm-source"),
2157                   uuid => tmp_config('--get', "$section.svm-uuid"),
2158                   replace => tmp_config('--get', "$section.svm-replace"),
2159                 }
2160         };
2161         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2162                 $self->{svm} = $svm;
2163         }
2164         $self->{svm};
2165 }
2166
2167 sub _set_svm_vars {
2168         my ($self, $ra) = @_;
2169         return $ra if $self->svm;
2170
2171         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2172                     "(svm:source, svm:uuid) ",
2173                     "from the following URLs:\n" );
2174         sub read_svm_props {
2175                 my ($self, $ra, $path, $r) = @_;
2176                 my $props = ($ra->get_dir($path, $r))[2];
2177                 my $src = $props->{'svm:source'};
2178                 my $uuid = $props->{'svm:uuid'};
2179                 return undef if (!$src || !$uuid);
2180
2181                 chomp($src, $uuid);
2182
2183                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2184                     or die "doesn't look right - svm:uuid is '$uuid'\n";
2185
2186                 # the '!' is used to mark the repos_root!/relative/path
2187                 $src =~ s{/?!/?}{/};
2188                 $src =~ s{/+$}{}; # no trailing slashes please
2189                 # username is of no interest
2190                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2191
2192                 my $replace = $ra->{url};
2193                 $replace .= "/$path" if length $path;
2194
2195                 my $section = "svn-remote.$self->{repo_id}";
2196                 tmp_config("$section.svm-source", $src);
2197                 tmp_config("$section.svm-replace", $replace);
2198                 tmp_config("$section.svm-uuid", $uuid);
2199                 $self->{svm} = {
2200                         source => $src,
2201                         uuid => $uuid,
2202                         replace => $replace
2203                 };
2204         }
2205
2206         my $r = $ra->get_latest_revnum;
2207         my $path = $self->{path};
2208         my %tried;
2209         while (length $path) {
2210                 unless ($tried{"$self->{url}/$path"}) {
2211                         return $ra if $self->read_svm_props($ra, $path, $r);
2212                         $tried{"$self->{url}/$path"} = 1;
2213                 }
2214                 $path =~ s#/?[^/]+$##;
2215         }
2216         die "Path: '$path' should be ''\n" if $path ne '';
2217         return $ra if $self->read_svm_props($ra, $path, $r);
2218         $tried{"$self->{url}/$path"} = 1;
2219
2220         if ($ra->{repos_root} eq $self->{url}) {
2221                 die @err, (map { "  $_\n" } keys %tried), "\n";
2222         }
2223
2224         # nope, make sure we're connected to the repository root:
2225         my $ok;
2226         my @tried_b;
2227         $path = $ra->{svn_path};
2228         $ra = Git::SVN::Ra->new($ra->{repos_root});
2229         while (length $path) {
2230                 unless ($tried{"$ra->{url}/$path"}) {
2231                         $ok = $self->read_svm_props($ra, $path, $r);
2232                         last if $ok;
2233                         $tried{"$ra->{url}/$path"} = 1;
2234                 }
2235                 $path =~ s#/?[^/]+$##;
2236         }
2237         die "Path: '$path' should be ''\n" if $path ne '';
2238         $ok ||= $self->read_svm_props($ra, $path, $r);
2239         $tried{"$ra->{url}/$path"} = 1;
2240         if (!$ok) {
2241                 die @err, (map { "  $_\n" } keys %tried), "\n";
2242         }
2243         Git::SVN::Ra->new($self->{url});
2244 }
2245
2246 sub svnsync {
2247         my ($self) = @_;
2248         return $self->{svnsync} if $self->{svnsync};
2249
2250         if ($self->no_metadata) {
2251                 die "Can't have both 'noMetadata' and ",
2252                     "'useSvnsyncProps' options set!\n";
2253         }
2254         if ($self->rewrite_root) {
2255                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2256                     "options set!\n";
2257         }
2258         if ($self->rewrite_uuid) {
2259                 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
2260                     "options set!\n";
2261         }
2262
2263         my $svnsync;
2264         # see if we have it in our config, first:
2265         eval {
2266                 my $section = "svn-remote.$self->{repo_id}";
2267
2268                 my $url = tmp_config('--get', "$section.svnsync-url");
2269                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2270                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2271
2272                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2273                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2274                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2275
2276                 $svnsync = { url => $url, uuid => $uuid }
2277         };
2278         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2279                 return $self->{svnsync} = $svnsync;
2280         }
2281
2282         my $err = "useSvnsyncProps set, but failed to read " .
2283                   "svnsync property: svn:sync-from-";
2284         my $rp = $self->ra->rev_proplist(0);
2285
2286         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2287         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2288                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2289
2290         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2291         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2292                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2293
2294         my $section = "svn-remote.$self->{repo_id}";
2295         tmp_config('--add', "$section.svnsync-uuid", $uuid);
2296         tmp_config('--add', "$section.svnsync-url", $url);
2297         return $self->{svnsync} = { url => $url, uuid => $uuid };
2298 }
2299
2300 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2301 # remote lookup (useful for 'git svn log').
2302 sub ra_uuid {
2303         my ($self) = @_;
2304         unless ($self->{ra_uuid}) {
2305                 my $key = "svn-remote.$self->{repo_id}.uuid";
2306                 my $uuid = eval { tmp_config('--get', $key) };
2307                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2308                         $self->{ra_uuid} = $uuid;
2309                 } else {
2310                         die "ra_uuid called without URL\n" unless $self->{url};
2311                         $self->{ra_uuid} = $self->ra->get_uuid;
2312                         tmp_config('--add', $key, $self->{ra_uuid});
2313                 }
2314         }
2315         $self->{ra_uuid};
2316 }
2317
2318 sub _set_repos_root {
2319         my ($self, $repos_root) = @_;
2320         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2321         $repos_root ||= $self->ra->{repos_root};
2322         tmp_config($k, $repos_root);
2323         $repos_root;
2324 }
2325
2326 sub repos_root {
2327         my ($self) = @_;
2328         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2329         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2330 }
2331
2332 sub ra {
2333         my ($self) = shift;
2334         my $ra = Git::SVN::Ra->new($self->{url});
2335         $self->_set_repos_root($ra->{repos_root});
2336         if ($self->use_svm_props && !$self->{svm}) {
2337                 if ($self->no_metadata) {
2338                         die "Can't have both 'noMetadata' and ",
2339                             "'useSvmProps' options set!\n";
2340                 } elsif ($self->use_svnsync_props) {
2341                         die "Can't have both 'useSvnsyncProps' and ",
2342                             "'useSvmProps' options set!\n";
2343                 }
2344                 $ra = $self->_set_svm_vars($ra);
2345                 $self->{-want_revprops} = 1;
2346         }
2347         $ra;
2348 }
2349
2350 # prop_walk(PATH, REV, SUB)
2351 # -------------------------
2352 # Recursively traverse PATH at revision REV and invoke SUB for each
2353 # directory that contains a SVN property.  SUB will be invoked as
2354 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2355 # Git::SVN, `path' the path to the directory where the properties
2356 # `props' were found.  The `path' will be relative to point of checkout,
2357 # that is, if url://repo/trunk is the current Git branch, and that
2358 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2359 # as `path' (note the trailing `/').
2360 sub prop_walk {
2361         my ($self, $path, $rev, $sub) = @_;
2362
2363         $path =~ s#^/##;
2364         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2365         $path =~ s#^/*#/#g;
2366         my $p = $path;
2367         # Strip the irrelevant part of the path.
2368         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2369         # Ensure the path is terminated by a `/'.
2370         $p =~ s#/*$#/#;
2371
2372         # The properties contain all the internal SVN stuff nobody
2373         # (usually) cares about.
2374         my $interesting_props = 0;
2375         foreach (keys %{$props}) {
2376                 # If it doesn't start with `svn:', it must be a
2377                 # user-defined property.
2378                 ++$interesting_props and next if $_ !~ /^svn:/;
2379                 # FIXME: Fragile, if SVN adds new public properties,
2380                 # this needs to be updated.
2381                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2382                                                  |eol-style|mime-type
2383                                                  |externals|needs-lock)$/x;
2384         }
2385         &$sub($self, $p, $props) if $interesting_props;
2386
2387         foreach (sort keys %$dirent) {
2388                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2389                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2390         }
2391 }
2392
2393 sub last_rev { ($_[0]->last_rev_commit)[0] }
2394 sub last_commit { ($_[0]->last_rev_commit)[1] }
2395
2396 # returns the newest SVN revision number and newest commit SHA1
2397 sub last_rev_commit {
2398         my ($self) = @_;
2399         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2400                 return ($self->{last_rev}, $self->{last_commit});
2401         }
2402         my $c = ::verify_ref($self->refname.'^0');
2403         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2404                 my $rev = (::cmt_metadata($c))[1];
2405                 if (defined $rev) {
2406                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2407                         return ($rev, $c);
2408                 }
2409         }
2410         my $map_path = $self->map_path;
2411         unless (-e $map_path) {
2412                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2413                 return (undef, undef);
2414         }
2415         my ($rev, $commit) = $self->rev_map_max(1);
2416         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2417         return ($rev, $commit);
2418 }
2419
2420 sub get_fetch_range {
2421         my ($self, $min, $max) = @_;
2422         $max ||= $self->ra->get_latest_revnum;
2423         $min ||= $self->rev_map_max;
2424         (++$min, $max);
2425 }
2426
2427 sub tmp_config {
2428         my (@args) = @_;
2429         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2430         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2431         if (! -f $config && -f $old_def_config) {
2432                 rename $old_def_config, $config or
2433                        die "Failed rename $old_def_config => $config: $!\n";
2434         }
2435         my $old_config = $ENV{GIT_CONFIG};
2436         $ENV{GIT_CONFIG} = $config;
2437         $@ = undef;
2438         my @ret = eval {
2439                 unless (-f $config) {
2440                         mkfile($config);
2441                         open my $fh, '>', $config or
2442                             die "Can't open $config: $!\n";
2443                         print $fh "; This file is used internally by ",
2444                                   "git-svn\n" or die
2445                                   "Couldn't write to $config: $!\n";
2446                         print $fh "; You should not have to edit it\n" or
2447                               die "Couldn't write to $config: $!\n";
2448                         close $fh or die "Couldn't close $config: $!\n";
2449                 }
2450                 command('config', @args);
2451         };
2452         my $err = $@;
2453         if (defined $old_config) {
2454                 $ENV{GIT_CONFIG} = $old_config;
2455         } else {
2456                 delete $ENV{GIT_CONFIG};
2457         }
2458         die $err if $err;
2459         wantarray ? @ret : $ret[0];
2460 }
2461
2462 sub tmp_index_do {
2463         my ($self, $sub) = @_;
2464         my $old_index = $ENV{GIT_INDEX_FILE};
2465         $ENV{GIT_INDEX_FILE} = $self->{index};
2466         $@ = undef;
2467         my @ret = eval {
2468                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2469                 mkpath([$dir]) unless -d $dir;
2470                 &$sub;
2471         };
2472         my $err = $@;
2473         if (defined $old_index) {
2474                 $ENV{GIT_INDEX_FILE} = $old_index;
2475         } else {
2476                 delete $ENV{GIT_INDEX_FILE};
2477         }
2478         die $err if $err;
2479         wantarray ? @ret : $ret[0];
2480 }
2481
2482 sub assert_index_clean {
2483         my ($self, $treeish) = @_;
2484
2485         $self->tmp_index_do(sub {
2486                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2487                 my $x = command_oneline('write-tree');
2488                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2489                            /^tree ($::sha1)/mo);
2490                 return if $y eq $x;
2491
2492                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2493                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2494                 command_noisy('read-tree', $treeish);
2495                 $x = command_oneline('write-tree');
2496                 if ($y ne $x) {
2497                         ::fatal "trees ($treeish) $y != $x\n",
2498                                 "Something is seriously wrong...";
2499                 }
2500         });
2501 }
2502
2503 sub get_commit_parents {
2504         my ($self, $log_entry) = @_;
2505         my (%seen, @ret, @tmp);
2506         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2507         if (my $ip = $self->{inject_parents}) {
2508                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2509                         push @tmp, $commit;
2510                 }
2511         }
2512         if (my $cur = ::verify_ref($self->refname.'^0')) {
2513                 push @tmp, $cur;
2514         }
2515         if (my $ipd = $self->{inject_parents_dcommit}) {
2516                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2517                         push @tmp, @$commit;
2518                 }
2519         }
2520         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2521         while (my $p = shift @tmp) {
2522                 next if $seen{$p};
2523                 $seen{$p} = 1;
2524                 push @ret, $p;
2525         }
2526         @ret;
2527 }
2528
2529 sub rewrite_root {
2530         my ($self) = @_;
2531         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2532         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2533         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2534         if ($rwr) {
2535                 $rwr =~ s#/+$##;
2536                 if ($rwr !~ m#^[a-z\+]+://#) {
2537                         die "$rwr is not a valid URL (key: $k)\n";
2538                 }
2539         }
2540         $self->{-rewrite_root} = $rwr;
2541 }
2542
2543 sub rewrite_uuid {
2544         my ($self) = @_;
2545         return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
2546         my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
2547         my $rwid = eval { command_oneline(qw/config --get/, $k) };
2548         if ($rwid) {
2549                 $rwid =~ s#/+$##;
2550                 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
2551                         die "$rwid is not a valid UUID (key: $k)\n";
2552                 }
2553         }
2554         $self->{-rewrite_uuid} = $rwid;
2555 }
2556
2557 sub metadata_url {
2558         my ($self) = @_;
2559         ($self->rewrite_root || $self->{url}) .
2560            (length $self->{path} ? '/' . $self->{path} : '');
2561 }
2562
2563 sub full_url {
2564         my ($self) = @_;
2565         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2566 }
2567
2568 sub full_pushurl {
2569         my ($self) = @_;
2570         if ($self->{pushurl}) {
2571                 return $self->{pushurl} . (length $self->{path} ? '/' .
2572                        $self->{path} : '');
2573         } else {
2574                 return $self->full_url;
2575         }
2576 }
2577
2578 sub set_commit_header_env {
2579         my ($log_entry) = @_;
2580         my %env;
2581         foreach my $ned (qw/NAME EMAIL DATE/) {
2582                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2583                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2584                 }
2585         }
2586
2587         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2588         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2589         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2590
2591         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2592                                                 ? $log_entry->{commit_name}
2593                                                 : $log_entry->{name};
2594         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2595                                                 ? $log_entry->{commit_email}
2596                                                 : $log_entry->{email};
2597         \%env;
2598 }
2599
2600 sub restore_commit_header_env {
2601         my ($env) = @_;
2602         foreach my $ned (qw/NAME EMAIL DATE/) {
2603                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2604                         my $k = "GIT_${ac}_${ned}";
2605                         if (defined $env->{$k}) {
2606                                 $ENV{$k} = $env->{$k};
2607                         } else {
2608                                 delete $ENV{$k};
2609                         }
2610                 }
2611         }
2612 }
2613
2614 sub gc {
2615         command_noisy('gc', '--auto');
2616 };
2617
2618 sub do_git_commit {
2619         my ($self, $log_entry) = @_;
2620         my $lr = $self->last_rev;
2621         if (defined $lr && $lr >= $log_entry->{revision}) {
2622                 die "Last fetched revision of ", $self->refname,
2623                     " was r$lr, but we are about to fetch: ",
2624                     "r$log_entry->{revision}!\n";
2625         }
2626         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2627                 croak "$log_entry->{revision} = $c already exists! ",
2628                       "Why are we refetching it?\n";
2629         }
2630         my $old_env = set_commit_header_env($log_entry);
2631         my $tree = $log_entry->{tree};
2632         if (!defined $tree) {
2633                 $tree = $self->tmp_index_do(sub {
2634                                             command_oneline('write-tree') });
2635         }
2636         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2637
2638         my @exec = ('git', 'commit-tree', $tree);
2639         foreach ($self->get_commit_parents($log_entry)) {
2640                 push @exec, '-p', $_;
2641         }
2642         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2643                                                                    or croak $!;
2644         binmode $msg_fh;
2645
2646         # we always get UTF-8 from SVN, but we may want our commits in
2647         # a different encoding.
2648         if (my $enc = Git::config('i18n.commitencoding')) {
2649                 require Encode;
2650                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2651         }
2652         print $msg_fh $log_entry->{log} or croak $!;
2653         restore_commit_header_env($old_env);
2654         unless ($self->no_metadata) {
2655                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2656                               or croak $!;
2657         }
2658         $msg_fh->flush == 0 or croak $!;
2659         close $msg_fh or croak $!;
2660         chomp(my $commit = do { local $/; <$out_fh> });
2661         close $out_fh or croak $!;
2662         waitpid $pid, 0;
2663         croak $? if $?;
2664         if ($commit !~ /^$::sha1$/o) {
2665                 die "Failed to commit, invalid sha1: $commit\n";
2666         }
2667
2668         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2669
2670         $self->{last_rev} = $log_entry->{revision};
2671         $self->{last_commit} = $commit;
2672         print "r$log_entry->{revision}" unless $::_q > 1;
2673         if (defined $log_entry->{svm_revision}) {
2674                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2675                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2676                                    0, $self->svm_uuid);
2677         }
2678         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2679         if (--$_gc_nr == 0) {
2680                 $_gc_nr = $_gc_period;
2681                 gc();
2682         }
2683         return $commit;
2684 }
2685
2686 sub match_paths {
2687         my ($self, $paths, $r) = @_;
2688         return 1 if $self->{path} eq '';
2689         if (my $path = $paths->{"/$self->{path}"}) {
2690                 return ($path->{action} eq 'D') ? 0 : 1;
2691         }
2692         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2693         if (grep /$self->{path_regex}/, keys %$paths) {
2694                 return 1;
2695         }
2696         my $c = '';
2697         foreach (split m#/#, $self->{path}) {
2698                 $c .= "/$_";
2699                 next unless ($paths->{$c} &&
2700                              ($paths->{$c}->{action} =~ /^[AR]$/));
2701                 if ($self->ra->check_path($self->{path}, $r) ==
2702                     $SVN::Node::dir) {
2703                         return 1;
2704                 }
2705         }
2706         return 0;
2707 }
2708
2709 sub find_parent_branch {
2710         my ($self, $paths, $rev) = @_;
2711         return undef unless $self->follow_parent;
2712         unless (defined $paths) {
2713                 my $err_handler = $SVN::Error::handler;
2714                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2715                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2716                                    sub { $paths = $_[0] });
2717                 $SVN::Error::handler = $err_handler;
2718         }
2719         return undef unless defined $paths;
2720
2721         # look for a parent from another branch:
2722         my @b_path_components = split m#/#, $self->{path};
2723         my @a_path_components;
2724         my $i;
2725         while (@b_path_components) {
2726                 $i = $paths->{'/'.join('/', @b_path_components)};
2727                 last if $i && defined $i->{copyfrom_path};
2728                 unshift(@a_path_components, pop(@b_path_components));
2729         }
2730         return undef unless defined $i && defined $i->{copyfrom_path};
2731         my $branch_from = $i->{copyfrom_path};
2732         if (@a_path_components) {
2733                 print STDERR "branch_from: $branch_from => ";
2734                 $branch_from .= '/'.join('/', @a_path_components);
2735                 print STDERR $branch_from, "\n";
2736         }
2737         my $r = $i->{copyfrom_rev};
2738         my $repos_root = $self->ra->{repos_root};
2739         my $url = $self->ra->{url};
2740         my $new_url = $url . $branch_from;
2741         print STDERR  "Found possible branch point: ",
2742                       "$new_url => ", $self->full_url, ", $r\n"
2743                       unless $::_q > 1;
2744         $branch_from =~ s#^/##;
2745         my $gs = $self->other_gs($new_url, $url,
2746                                  $branch_from, $r, $self->{ref_id});
2747         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2748         {
2749                 my ($base, $head);
2750                 if (!defined $r0 || !defined $parent) {
2751                         ($base, $head) = parse_revision_argument(0, $r);
2752                 } else {
2753                         if ($r0 < $r) {
2754                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2755                                         0, 1, sub { $base = $_[1] - 1 });
2756                         }
2757                 }
2758                 if (defined $base && $base <= $r) {
2759                         $gs->fetch($base, $r);
2760                 }
2761                 ($r0, $parent) = $gs->find_rev_before($r, 1);
2762         }
2763         if (defined $r0 && defined $parent) {
2764                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
2765                              unless $::_q > 1;
2766                 my $ed;
2767                 if ($self->ra->can_do_switch) {
2768                         $self->assert_index_clean($parent);
2769                         print STDERR "Following parent with do_switch\n"
2770                                      unless $::_q > 1;
2771                         # do_switch works with svn/trunk >= r22312, but that
2772                         # is not included with SVN 1.4.3 (the latest version
2773                         # at the moment), so we can't rely on it
2774                         $self->{last_rev} = $r0;
2775                         $self->{last_commit} = $parent;
2776                         $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2777                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2778                                               $self->full_url, $ed)
2779                           or die "SVN connection failed somewhere...\n";
2780                 } elsif ($self->ra->trees_match($new_url, $r0,
2781                                                 $self->full_url, $rev)) {
2782                         print STDERR "Trees match:\n",
2783                                      "  $new_url\@$r0\n",
2784                                      "  ${\$self->full_url}\@$rev\n",
2785                                      "Following parent with no changes\n"
2786                                      unless $::_q > 1;
2787                         $self->tmp_index_do(sub {
2788                             command_noisy('read-tree', $parent);
2789                         });
2790                         $self->{last_commit} = $parent;
2791                 } else {
2792                         print STDERR "Following parent with do_update\n"
2793                                      unless $::_q > 1;
2794                         $ed = SVN::Git::Fetcher->new($self);
2795                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2796                           or die "SVN connection failed somewhere...\n";
2797                 }
2798                 print STDERR "Successfully followed parent\n" unless $::_q > 1;
2799                 return $self->make_log_entry($rev, [$parent], $ed);
2800         }
2801         return undef;
2802 }
2803
2804 sub do_fetch {
2805         my ($self, $paths, $rev) = @_;
2806         my $ed;
2807         my ($last_rev, @parents);
2808         if (my $lc = $self->last_commit) {
2809                 # we can have a branch that was deleted, then re-added
2810                 # under the same name but copied from another path, in
2811                 # which case we'll have multiple parents (we don't
2812                 # want to break the original ref, nor lose copypath info):
2813                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2814                         push @{$log_entry->{parents}}, $lc;
2815                         return $log_entry;
2816                 }
2817                 $ed = SVN::Git::Fetcher->new($self);
2818                 $last_rev = $self->{last_rev};
2819                 $ed->{c} = $lc;
2820                 @parents = ($lc);
2821         } else {
2822                 $last_rev = $rev;
2823                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2824                         return $log_entry;
2825                 }
2826                 $ed = SVN::Git::Fetcher->new($self);
2827         }
2828         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2829                 die "SVN connection failed somewhere...\n";
2830         }
2831         $self->make_log_entry($rev, \@parents, $ed);
2832 }
2833
2834 sub mkemptydirs {
2835         my ($self, $r) = @_;
2836
2837         sub scan {
2838                 my ($r, $empty_dirs, $line) = @_;
2839                 if (defined $r && $line =~ /^r(\d+)$/) {
2840                         return 0 if $1 > $r;
2841                 } elsif ($line =~ /^  \+empty_dir: (.+)$/) {
2842                         $empty_dirs->{$1} = 1;
2843                 } elsif ($line =~ /^  \-empty_dir: (.+)$/) {
2844                         my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
2845                         delete @$empty_dirs{@d};
2846                 }
2847                 1; # continue
2848         };
2849
2850         my %empty_dirs = ();
2851         my $gz_file = "$self->{dir}/unhandled.log.gz";
2852         if (-f $gz_file) {
2853                 if (!$can_compress) {
2854                         warn "Compress::Zlib could not be found; ",
2855                              "empty directories in $gz_file will not be read\n";
2856                 } else {
2857                         my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
2858                                 die "Unable to open $gz_file: $!\n";
2859                         my $line;
2860                         while ($gz->gzreadline($line) > 0) {
2861                                 scan($r, \%empty_dirs, $line) or last;
2862                         }
2863                         $gz->gzclose;
2864                 }
2865         }
2866
2867         if (open my $fh, '<', "$self->{dir}/unhandled.log") {
2868                 binmode $fh or croak "binmode: $!";
2869                 while (<$fh>) {
2870                         scan($r, \%empty_dirs, $_) or last;
2871                 }
2872                 close $fh;
2873         }
2874
2875         my $strip = qr/\A\Q$self->{path}\E(?:\/|$)/;
2876         foreach my $d (sort keys %empty_dirs) {
2877                 $d = uri_decode($d);
2878                 $d =~ s/$strip//;
2879                 next unless length($d);
2880                 next if -d $d;
2881                 if (-e $d) {
2882                         warn "$d exists but is not a directory\n";
2883                 } else {
2884                         print "creating empty directory: $d\n";
2885                         mkpath([$d]);
2886                 }
2887         }
2888 }
2889
2890 sub get_untracked {
2891         my ($self, $ed) = @_;
2892         my @out;
2893         my $h = $ed->{empty};
2894         foreach (sort keys %$h) {
2895                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2896                 push @out, "  $act: " . uri_encode($_);
2897                 warn "W: $act: $_\n";
2898         }
2899         foreach my $t (qw/dir_prop file_prop/) {
2900                 $h = $ed->{$t} or next;
2901                 foreach my $path (sort keys %$h) {
2902                         my $ppath = $path eq '' ? '.' : $path;
2903                         foreach my $prop (sort keys %{$h->{$path}}) {
2904                                 next if $SKIP_PROP{$prop};
2905                                 my $v = $h->{$path}->{$prop};
2906                                 my $t_ppath_prop = "$t: " .
2907                                                     uri_encode($ppath) . ' ' .
2908                                                     uri_encode($prop);
2909                                 if (defined $v) {
2910                                         push @out, "  +$t_ppath_prop " .
2911                                                    uri_encode($v);
2912                                 } else {
2913                                         push @out, "  -$t_ppath_prop";
2914                                 }
2915                         }
2916                 }
2917         }
2918         foreach my $t (qw/absent_file absent_directory/) {
2919                 $h = $ed->{$t} or next;
2920                 foreach my $parent (sort keys %$h) {
2921                         foreach my $path (sort @{$h->{$parent}}) {
2922                                 push @out, "  $t: " .
2923                                            uri_encode("$parent/$path");
2924                                 warn "W: $t: $parent/$path ",
2925                                      "Insufficient permissions?\n";
2926                         }
2927                 }
2928         }
2929         \@out;
2930 }
2931
2932 # parse_svn_date(DATE)
2933 # --------------------
2934 # Given a date (in UTC) from Subversion, return a string in the format
2935 # "<TZ Offset> <local date/time>" that Git will use.
2936 #
2937 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2938 # is true we'll convert it to the local timezone instead.
2939 sub parse_svn_date {
2940         my $date = shift || return '+0000 1970-01-01 00:00:00';
2941         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2942                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2943                                          croak "Unable to parse date: $date\n";
2944         my $parsed_date;    # Set next.
2945
2946         if ($Git::SVN::_localtime) {
2947                 # Translate the Subversion datetime to an epoch time.
2948                 # Begin by switching ourselves to $date's timezone, UTC.
2949                 my $old_env_TZ = $ENV{TZ};
2950                 $ENV{TZ} = 'UTC';
2951
2952                 my $epoch_in_UTC =
2953                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2954
2955                 # Determine our local timezone (including DST) at the
2956                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
2957                 # value of TZ, if any, at the time we were run.
2958                 if (defined $Git::SVN::Log::TZ) {
2959                         $ENV{TZ} = $Git::SVN::Log::TZ;
2960                 } else {
2961                         delete $ENV{TZ};
2962                 }
2963
2964                 my $our_TZ =
2965                     POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2966
2967                 # This converts $epoch_in_UTC into our local timezone.
2968                 my ($sec, $min, $hour, $mday, $mon, $year,
2969                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2970
2971                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2972                                        $our_TZ, $year + 1900, $mon + 1,
2973                                        $mday, $hour, $min, $sec);
2974
2975                 # Reset us to the timezone in effect when we entered
2976                 # this routine.
2977                 if (defined $old_env_TZ) {
2978                         $ENV{TZ} = $old_env_TZ;
2979                 } else {
2980                         delete $ENV{TZ};
2981                 }
2982         } else {
2983                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2984         }
2985
2986         return $parsed_date;
2987 }
2988
2989 sub other_gs {
2990         my ($self, $new_url, $url,
2991             $branch_from, $r, $old_ref_id) = @_;
2992         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2993         unless ($gs) {
2994                 my $ref_id = $old_ref_id;
2995                 $ref_id =~ s/\@\d+-*$//;
2996                 $ref_id .= "\@$r";
2997                 # just grow a tail if we're not unique enough :x
2998                 $ref_id .= '-' while find_ref($ref_id);
2999                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
3000                 if ($u =~ s#^\Q$url\E(/|$)##) {
3001                         $p = $u;
3002                         $u = $url;
3003                         $repo_id = $self->{repo_id};
3004                 }
3005                 while (1) {
3006                         # It is possible to tag two different subdirectories at
3007                         # the same revision.  If the url for an existing ref
3008                         # does not match, we must either find a ref with a
3009                         # matching url or create a new ref by growing a tail.
3010                         $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
3011                         my (undef, $max_commit) = $gs->rev_map_max(1);
3012                         last if (!$max_commit);
3013                         my ($url) = ::cmt_metadata($max_commit);
3014                         last if ($url eq $gs->full_url);
3015                         $ref_id .= '-';
3016                 }
3017                 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
3018         }
3019         $gs
3020 }
3021
3022 sub call_authors_prog {
3023         my ($orig_author) = @_;
3024         $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
3025         my $author = `$::_authors_prog $orig_author`;
3026         if ($? != 0) {
3027                 die "$::_authors_prog failed with exit code $?\n"
3028         }
3029         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
3030                 my ($name, $email) = ($1, $2);
3031                 $email = undef if length $2 == 0;
3032                 return [$name, $email];
3033         } else {
3034                 die "Author: $orig_author: $::_authors_prog returned "
3035                         . "invalid author format: $author\n";
3036         }
3037 }
3038
3039 sub check_author {
3040         my ($author) = @_;
3041         if (!defined $author || length $author == 0) {
3042                 $author = '(no author)';
3043         }
3044         if (!defined $::users{$author}) {
3045                 if (defined $::_authors_prog) {
3046                         $::users{$author} = call_authors_prog($author);
3047                 } elsif (defined $::_authors) {
3048                         die "Author: $author not defined in $::_authors file\n";
3049                 }
3050         }
3051         $author;
3052 }
3053
3054 sub find_extra_svk_parents {
3055         my ($self, $ed, $tickets, $parents) = @_;
3056         # aha!  svk:merge property changed...
3057         my @tickets = split "\n", $tickets;
3058         my @known_parents;
3059         for my $ticket ( @tickets ) {
3060                 my ($uuid, $path, $rev) = split /:/, $ticket;
3061                 if ( $uuid eq $self->ra_uuid ) {
3062                         my $url = $self->{url};
3063                         my $repos_root = $url;
3064                         my $branch_from = $path;
3065                         $branch_from =~ s{^/}{};
3066                         my $gs = $self->other_gs($repos_root."/".$branch_from,
3067                                                  $url,
3068                                                  $branch_from,
3069                                                  $rev,
3070                                                  $self->{ref_id});
3071                         if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
3072                                 # wahey!  we found it, but it might be
3073                                 # an old one (!)
3074                                 push @known_parents, [ $rev, $commit ];
3075                         }
3076                 }
3077         }
3078         # Ordering matters; highest-numbered commit merge tickets
3079         # first, as they may account for later merge ticket additions
3080         # or changes.
3081         @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
3082         for my $parent ( @known_parents ) {
3083                 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
3084                 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3085                 my $new;
3086                 while ( <$msg_fh> ) {
3087                         $new=1;last;
3088                 }
3089                 command_close_pipe($msg_fh, $ctx);
3090                 if ( $new ) {
3091                         print STDERR
3092                             "Found merge parent (svk:merge ticket): $parent\n";
3093                         push @$parents, $parent;
3094                 }
3095         }
3096 }
3097
3098 sub lookup_svn_merge {
3099         my $uuid = shift;
3100         my $url = shift;
3101         my $merge = shift;
3102
3103         my ($source, $revs) = split ":", $merge;
3104         my $path = $source;
3105         $path =~ s{^/}{};
3106         my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
3107         if ( !$gs ) {
3108                 warn "Couldn't find revmap for $url$source\n";
3109                 return;
3110         }
3111         my @ranges = split ",", $revs;
3112         my ($tip, $tip_commit);
3113         my @merged_commit_ranges;
3114         # find the tip
3115         for my $range ( @ranges ) {
3116                 my ($bottom, $top) = split "-", $range;
3117                 $top ||= $bottom;
3118                 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
3119                 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
3120
3121                 unless ($top_commit and $bottom_commit) {
3122                         warn "W:unknown path/rev in svn:mergeinfo "
3123                                 ."dirprop: $source:$range\n";
3124                         next;
3125                 }
3126
3127                 if (scalar(command('rev-parse', "$bottom_commit^@"))) {
3128                         push @merged_commit_ranges,
3129                              "$bottom_commit^..$top_commit";
3130                 } else {
3131                         push @merged_commit_ranges, "$top_commit";
3132                 }
3133
3134                 if ( !defined $tip or $top > $tip ) {
3135                         $tip = $top;
3136                         $tip_commit = $top_commit;
3137                 }
3138         }
3139         return ($tip_commit, @merged_commit_ranges);
3140 }
3141
3142 sub _rev_list {
3143         my ($msg_fh, $ctx) = command_output_pipe(
3144                 "rev-list", @_,
3145                );
3146         my @rv;
3147         while ( <$msg_fh> ) {
3148                 chomp;
3149                 push @rv, $_;
3150         }
3151         command_close_pipe($msg_fh, $ctx);
3152         @rv;
3153 }
3154
3155 sub check_cherry_pick {
3156         my $base = shift;
3157         my $tip = shift;
3158         my $parents = shift;
3159         my @ranges = @_;
3160         my %commits = map { $_ => 1 }
3161                 _rev_list("--no-merges", $tip, "--not", $base, @$parents, "--");
3162         for my $range ( @ranges ) {
3163                 delete @commits{_rev_list($range, "--")};
3164         }
3165         for my $commit (keys %commits) {
3166                 if (has_no_changes($commit)) {
3167                         delete $commits{$commit};
3168                 }
3169         }
3170         return (keys %commits);
3171 }
3172
3173 sub has_no_changes {
3174         my $commit = shift;
3175
3176         my @revs = split / /, command_oneline(
3177                 qw(rev-list --parents -1 -m), $commit);
3178
3179         # Commits with no parents, e.g. the start of a partial branch,
3180         # have changes by definition.
3181         return 1 if (@revs < 2);
3182
3183         # Commits with multiple parents, e.g a merge, have no changes
3184         # by definition.
3185         return 0 if (@revs > 2);
3186
3187         return (command_oneline("rev-parse", "$commit^{tree}") eq
3188                 command_oneline("rev-parse", "$commit~1^{tree}"));
3189 }
3190
3191 # The GIT_DIR environment variable is not always set until after the command
3192 # line arguments are processed, so we can't memoize in a BEGIN block.
3193 {
3194         my $memoized = 0;
3195
3196         sub memoize_svn_mergeinfo_functions {
3197                 return if $memoized;
3198                 $memoized = 1;
3199
3200                 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
3201                 mkpath([$cache_path]) unless -d $cache_path;
3202
3203                 tie my %lookup_svn_merge_cache => 'Memoize::Storable',
3204                     "$cache_path/lookup_svn_merge.db", 'nstore';
3205                 memoize 'lookup_svn_merge',
3206                         SCALAR_CACHE => 'FAULT',
3207                         LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
3208                 ;
3209
3210                 tie my %check_cherry_pick_cache => 'Memoize::Storable',
3211                     "$cache_path/check_cherry_pick.db", 'nstore';
3212                 memoize 'check_cherry_pick',
3213                         SCALAR_CACHE => 'FAULT',
3214                         LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
3215                 ;
3216
3217                 tie my %has_no_changes_cache => 'Memoize::Storable',
3218                     "$cache_path/has_no_changes.db", 'nstore';
3219                 memoize 'has_no_changes',
3220                         SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
3221                         LIST_CACHE => 'FAULT',
3222                 ;
3223         }
3224
3225         sub unmemoize_svn_mergeinfo_functions {
3226                 return if not $memoized;
3227                 $memoized = 0;
3228
3229                 Memoize::unmemoize 'lookup_svn_merge';
3230                 Memoize::unmemoize 'check_cherry_pick';
3231                 Memoize::unmemoize 'has_no_changes';
3232         }
3233
3234         Memoize::memoize 'Git::SVN::repos_root';
3235 }
3236
3237 END {
3238         # Force cache writeout explicitly instead of waiting for
3239         # global destruction to avoid segfault in Storable:
3240         # http://rt.cpan.org/Public/Bug/Display.html?id=36087
3241         unmemoize_svn_mergeinfo_functions();
3242 }
3243
3244 sub parents_exclude {
3245         my $parents = shift;
3246         my @commits = @_;
3247         return unless @commits;
3248
3249         my @excluded;
3250         my $excluded;
3251         do {
3252                 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
3253                 $excluded = command_oneline(@cmd);
3254                 if ( $excluded ) {
3255                         my @new;
3256                         my $found;
3257                         for my $commit ( @commits ) {
3258                                 if ( $commit eq $excluded ) {
3259                                         push @excluded, $commit;
3260                                         $found++;
3261                                         last;
3262                                 }
3263                                 else {
3264                                         push @new, $commit;
3265                                 }
3266                         }
3267                         die "saw commit '$excluded' in rev-list output, "
3268                                 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
3269                                         unless $found;
3270                         @commits = @new;
3271                 }
3272         }
3273                 while ($excluded and @commits);
3274
3275         return @excluded;
3276 }
3277
3278
3279 # note: this function should only be called if the various dirprops
3280 # have actually changed
3281 sub find_extra_svn_parents {
3282         my ($self, $ed, $mergeinfo, $parents) = @_;
3283         # aha!  svk:merge property changed...
3284
3285         memoize_svn_mergeinfo_functions();
3286
3287         # We first search for merged tips which are not in our
3288         # history.  Then, we figure out which git revisions are in
3289         # that tip, but not this revision.  If all of those revisions
3290         # are now marked as merge, we can add the tip as a parent.
3291         my @merges = split "\n", $mergeinfo;
3292         my @merge_tips;
3293         my $url = $self->{url};
3294         my $uuid = $self->ra_uuid;
3295         my %ranges;
3296         for my $merge ( @merges ) {
3297                 my ($tip_commit, @ranges) =
3298                         lookup_svn_merge( $uuid, $url, $merge );
3299                 unless (!$tip_commit or
3300                                 grep { $_ eq $tip_commit } @$parents ) {
3301                         push @merge_tips, $tip_commit;
3302                         $ranges{$tip_commit} = \@ranges;
3303                 } else {
3304                         push @merge_tips, undef;
3305                 }
3306         }
3307
3308         my %excluded = map { $_ => 1 }
3309                 parents_exclude($parents, grep { defined } @merge_tips);
3310
3311         # check merge tips for new parents
3312         my @new_parents;
3313         for my $merge_tip ( @merge_tips ) {
3314                 my $spec = shift @merges;
3315                 next unless $merge_tip and $excluded{$merge_tip};
3316
3317                 my $ranges = $ranges{$merge_tip};
3318
3319                 # check out 'new' tips
3320                 my $merge_base;
3321                 eval {
3322                         $merge_base = command_oneline(
3323                                 "merge-base",
3324                                 @$parents, $merge_tip,
3325                         );
3326                 };
3327                 if ($@) {
3328                         die "An error occurred during merge-base"
3329                                 unless $@->isa("Git::Error::Command");
3330
3331                         warn "W: Cannot find common ancestor between ".
3332                              "@$parents and $merge_tip. Ignoring merge info.\n";
3333                         next;
3334                 }
3335
3336                 # double check that there are no missing non-merge commits
3337                 my (@incomplete) = check_cherry_pick(
3338                         $merge_base, $merge_tip,
3339                         $parents,
3340                         @$ranges,
3341                        );
3342
3343                 if ( @incomplete ) {
3344                         warn "W:svn cherry-pick ignored ($spec) - missing "
3345                                 .@incomplete." commit(s) (eg $incomplete[0])\n";
3346                 } else {
3347                         warn
3348                                 "Found merge parent (svn:mergeinfo prop): ",
3349                                         $merge_tip, "\n";
3350                         push @new_parents, $merge_tip;
3351                 }
3352         }
3353
3354         # cater for merges which merge commits from multiple branches
3355         if ( @new_parents > 1 ) {
3356                 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
3357                         for ( my $j = 0; $j <= $#new_parents; $j++ ) {
3358                                 next if $i == $j;
3359                                 next unless $new_parents[$i];
3360                                 next unless $new_parents[$j];
3361                                 my $revs = command_oneline(
3362                                         "rev-list", "-1",
3363                                         "$new_parents[$i]..$new_parents[$j]",
3364                                        );
3365                                 if ( !$revs ) {
3366                                         undef($new_parents[$j]);
3367                                 }
3368                         }
3369                 }
3370         }
3371         push @$parents, grep { defined } @new_parents;
3372 }
3373
3374 sub make_log_entry {
3375         my ($self, $rev, $parents, $ed) = @_;
3376         my $untracked = $self->get_untracked($ed);
3377
3378         my @parents = @$parents;
3379         my $ps = $ed->{path_strip} || "";
3380         for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
3381                 my $props = $ed->{dir_prop}{$path};
3382                 if ( $props->{"svk:merge"} ) {
3383                         $self->find_extra_svk_parents
3384                                 ($ed, $props->{"svk:merge"}, \@parents);
3385                 }
3386                 if ( $props->{"svn:mergeinfo"} ) {
3387                         $self->find_extra_svn_parents
3388                                 ($ed,
3389                                  $props->{"svn:mergeinfo"},
3390                                  \@parents);
3391                 }
3392         }
3393
3394         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
3395         print $un "r$rev\n" or croak $!;
3396         print $un $_, "\n" foreach @$untracked;
3397         my %log_entry = ( parents => \@parents, revision => $rev,
3398                           log => '');
3399
3400         my $headrev;
3401         my $logged = delete $self->{logged_rev_props};
3402         if (!$logged || $self->{-want_revprops}) {
3403                 my $rp = $self->ra->rev_proplist($rev);
3404                 foreach (sort keys %$rp) {
3405                         my $v = $rp->{$_};
3406                         if (/^svn:(author|date|log)$/) {
3407                                 $log_entry{$1} = $v;
3408                         } elsif ($_ eq 'svm:headrev') {
3409                                 $headrev = $v;
3410                         } else {
3411                                 print $un "  rev_prop: ", uri_encode($_), ' ',
3412                                           uri_encode($v), "\n";
3413                         }
3414                 }
3415         } else {
3416                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
3417         }
3418         close $un or croak $!;
3419
3420         $log_entry{date} = parse_svn_date($log_entry{date});
3421         $log_entry{log} .= "\n";
3422         my $author = $log_entry{author} = check_author($log_entry{author});
3423         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
3424                                                        : ($author, undef);
3425
3426         my ($commit_name, $commit_email) = ($name, $email);
3427         if ($_use_log_author) {
3428                 my $name_field;
3429                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
3430                         $name_field = $1;
3431                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
3432                         $name_field = $1;
3433                 }
3434                 if (!defined $name_field) {
3435                         if (!defined $email) {
3436                                 $email = $name;
3437                         }
3438                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
3439                         ($name, $email) = ($1, $2);
3440                 } elsif ($name_field =~ /(.*)@/) {
3441                         ($name, $email) = ($1, $name_field);
3442                 } else {
3443                         ($name, $email) = ($name_field, $name_field);
3444                 }
3445         }
3446         if (defined $headrev && $self->use_svm_props) {
3447                 if ($self->rewrite_root) {
3448                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
3449                             "options set!\n";
3450                 }
3451                 if ($self->rewrite_uuid) {
3452                         die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
3453                             "options set!\n";
3454                 }
3455                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
3456                 # we don't want "SVM: initializing mirror for junk" ...
3457                 return undef if $r == 0;
3458                 my $svm = $self->svm;
3459                 if ($uuid ne $svm->{uuid}) {
3460                         die "UUID mismatch on SVM path:\n",
3461                             "expected: $svm->{uuid}\n",
3462                             "     got: $uuid\n";
3463                 }
3464                 my $full_url = $self->full_url;
3465                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
3466                              die "Failed to replace '$svm->{replace}' with ",
3467                                  "'$svm->{source}' in $full_url\n";
3468                 # throw away username for storing in records
3469                 remove_username($full_url);
3470                 $log_entry{metadata} = "$full_url\@$r $uuid";
3471                 $log_entry{svm_revision} = $r;
3472                 $email ||= "$author\@$uuid";
3473                 $commit_email ||= "$author\@$uuid";
3474         } elsif ($self->use_svnsync_props) {
3475                 my $full_url = $self->svnsync->{url};
3476                 $full_url .= "/$self->{path}" if length $self->{path};
3477                 remove_username($full_url);
3478                 my $uuid = $self->svnsync->{uuid};
3479                 $log_entry{metadata} = "$full_url\@$rev $uuid";
3480                 $email ||= "$author\@$uuid";
3481                 $commit_email ||= "$author\@$uuid";
3482         } else {
3483                 my $url = $self->metadata_url;
3484                 remove_username($url);
3485                 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
3486                 $log_entry{metadata} = "$url\@$rev " . $uuid;
3487                 $email ||= "$author\@" . $uuid;
3488                 $commit_email ||= "$author\@" . $uuid;
3489         }
3490         $log_entry{name} = $name;
3491         $log_entry{email} = $email;
3492         $log_entry{commit_name} = $commit_name;
3493         $log_entry{commit_email} = $commit_email;
3494         \%log_entry;
3495 }
3496
3497 sub fetch {
3498         my ($self, $min_rev, $max_rev, @parents) = @_;
3499         my ($last_rev, $last_commit) = $self->last_rev_commit;
3500         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
3501         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
3502 }
3503
3504 sub set_tree_cb {
3505         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
3506         $self->{inject_parents} = { $rev => $tree };
3507         $self->fetch(undef, undef);
3508 }
3509
3510 sub set_tree {
3511         my ($self, $tree) = (shift, shift);
3512         my $log_entry = ::get_commit_entry($tree);
3513         unless ($self->{last_rev}) {
3514                 ::fatal("Must have an existing revision to commit");
3515         }
3516         my %ed_opts = ( r => $self->{last_rev},
3517                         log => $log_entry->{log},
3518                         ra => $self->ra,
3519                         tree_a => $self->{last_commit},
3520                         tree_b => $tree,
3521                         editor_cb => sub {
3522                                $self->set_tree_cb($log_entry, $tree, @_) },
3523                         svn_path => $self->{path} );
3524         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
3525                 print "No changes\nr$self->{last_rev} = $tree\n";
3526         }
3527 }
3528
3529 sub rebuild_from_rev_db {
3530         my ($self, $path) = @_;
3531         my $r = -1;
3532         open my $fh, '<', $path or croak "open: $!";
3533         binmode $fh or croak "binmode: $!";
3534         while (<$fh>) {
3535                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3536                 chomp($_);
3537                 ++$r;
3538                 next if $_ eq ('0' x 40);
3539                 $self->rev_map_set($r, $_);
3540                 print "r$r = $_\n";
3541         }
3542         close $fh or croak "close: $!";
3543         unlink $path or croak "unlink: $!";
3544 }
3545
3546 sub rebuild {
3547         my ($self) = @_;
3548         my $map_path = $self->map_path;
3549         my $partial = (-e $map_path && ! -z $map_path);
3550         return unless ::verify_ref($self->refname.'^0');
3551         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3552                 my $rev_db = $self->rev_db_path;
3553                 $self->rebuild_from_rev_db($rev_db);
3554                 if ($self->use_svm_props) {
3555                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3556                         $self->rebuild_from_rev_db($svm_rev_db);
3557                 }
3558                 $self->unlink_rev_db_symlink;
3559                 return;
3560         }
3561         print "Rebuilding $map_path ...\n" if (!$partial);
3562         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3563                 (undef, undef));
3564         my ($log, $ctx) =
3565             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3566                                 ($head ? "$head.." : "") . $self->refname,
3567                                 '--');
3568         my $metadata_url = $self->metadata_url;
3569         remove_username($metadata_url);
3570         my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
3571         my $c;
3572         while (<$log>) {
3573                 if ( m{^commit ($::sha1)$} ) {
3574                         $c = $1;
3575                         next;
3576                 }
3577                 next unless s{^\s*(git-svn-id:)}{$1};
3578                 my ($url, $rev, $uuid) = ::extract_metadata($_);
3579                 remove_username($url);
3580
3581                 # ignore merges (from set-tree)
3582                 next if (!defined $rev || !$uuid);
3583
3584                 # if we merged or otherwise started elsewhere, this is
3585                 # how we break out of it
3586                 if (($uuid ne $svn_uuid) ||
3587                     ($metadata_url && $url && ($url ne $metadata_url))) {
3588                         next;
3589                 }
3590                 if ($partial && $head) {
3591                         print "Partial-rebuilding $map_path ...\n";
3592                         print "Currently at $base_rev = $head\n";
3593                         $head = undef;
3594                 }
3595
3596                 $self->rev_map_set($rev, $c);
3597                 print "r$rev = $c\n";
3598         }
3599         command_close_pipe($log, $ctx);
3600         print "Done rebuilding $map_path\n" if (!$partial || !$head);
3601         my $rev_db_path = $self->rev_db_path;
3602         if (-f $self->rev_db_path) {
3603                 unlink $self->rev_db_path or croak "unlink: $!";
3604         }
3605         $self->unlink_rev_db_symlink;
3606 }
3607
3608 # rev_map:
3609 # Tie::File seems to be prone to offset errors if revisions get sparse,
3610 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
3611 # one of my favorite modules is out :<  Next up would be one of the DBM
3612 # modules, but I'm not sure which is most portable...
3613 #
3614 # This is the replacement for the rev_db format, which was too big
3615 # and inefficient for large repositories with a lot of sparse history
3616 # (mainly tags)
3617 #
3618 # The format is this:
3619 #   - 24 bytes for every record,
3620 #     * 4 bytes for the integer representing an SVN revision number
3621 #     * 20 bytes representing the sha1 of a git commit
3622 #   - No empty padding records like the old format
3623 #     (except the last record, which can be overwritten)
3624 #   - new records are written append-only since SVN revision numbers
3625 #     increase monotonically
3626 #   - lookups on SVN revision number are done via a binary search
3627 #   - Piping the file to xxd -c24 is a good way of dumping it for
3628 #     viewing or editing (piped back through xxd -r), should the need
3629 #     ever arise.
3630 #   - The last record can be padding revision with an all-zero sha1
3631 #     This is used to optimize fetch performance when using multiple
3632 #     "fetch" directives in .git/config
3633 #
3634 # These files are disposable unless noMetadata or useSvmProps is set
3635
3636 sub _rev_map_set {
3637         my ($fh, $rev, $commit) = @_;
3638
3639         binmode $fh or croak "binmode: $!";
3640         my $size = (stat($fh))[7];
3641         ($size % 24) == 0 or croak "inconsistent size: $size";
3642
3643         my $wr_offset = 0;
3644         if ($size > 0) {
3645                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3646                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3647                 $read == 24 or croak "read only $read bytes (!= 24)";
3648                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3649                 if ($last_commit eq ('0' x40)) {
3650                         if ($size >= 48) {
3651                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3652                                 $read = sysread($fh, $buf, 24) or
3653                                     croak "read: $!";
3654                                 $read == 24 or
3655                                     croak "read only $read bytes (!= 24)";
3656                                 ($last_rev, $last_commit) =
3657                                     unpack(rev_map_fmt, $buf);
3658                                 if ($last_commit eq ('0' x40)) {
3659                                         croak "inconsistent .rev_map\n";
3660                                 }
3661                         }
3662                         if ($last_rev >= $rev) {
3663                                 croak "last_rev is higher!: $last_rev >= $rev";
3664                         }
3665                         $wr_offset = -24;
3666                 }
3667         }
3668         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3669         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3670           croak "write: $!";
3671 }
3672
3673 sub _rev_map_reset {
3674         my ($fh, $rev, $commit) = @_;
3675         my $c = _rev_map_get($fh, $rev);
3676         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3677         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3678         truncate $fh, $offset or croak "truncate: $!";
3679 }
3680
3681 sub mkfile {
3682         my ($path) = @_;
3683         unless (-e $path) {
3684                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3685                 mkpath([$dir]) unless -d $dir;
3686                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3687                 close $fh or die "Couldn't close (create) $path: $!\n";
3688         }
3689 }
3690
3691 sub rev_map_set {
3692         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3693         defined $commit or die "missing arg3\n";
3694         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3695         my $db = $self->map_path($uuid);
3696         my $db_lock = "$db.lock";
3697         my $sig;
3698         $update_ref ||= 0;
3699         if ($update_ref) {
3700                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3701                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3702         }
3703         mkfile($db);
3704
3705         $LOCKFILES{$db_lock} = 1;
3706         my $sync;
3707         # both of these options make our .rev_db file very, very important
3708         # and we can't afford to lose it because rebuild() won't work
3709         if ($self->use_svm_props || $self->no_metadata) {
3710                 $sync = 1;
3711                 copy($db, $db_lock) or die "rev_map_set(@_): ",
3712                                            "Failed to copy: ",
3713                                            "$db => $db_lock ($!)\n";
3714         } else {
3715                 rename $db, $db_lock or die "rev_map_set(@_): ",
3716                                             "Failed to rename: ",
3717                                             "$db => $db_lock ($!)\n";
3718         }
3719
3720         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3721              or croak "Couldn't open $db_lock: $!\n";
3722         $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3723                                  _rev_map_set($fh, $rev, $commit);
3724         if ($sync) {
3725                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3726                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3727         }
3728         close $fh or croak $!;
3729         if ($update_ref) {
3730                 $_head = $self;
3731                 my $note = "";
3732                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3733                 command_noisy('update-ref', '-m', "r$rev$note",
3734                               $self->refname, $commit);
3735         }
3736         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3737                                     "$db_lock => $db ($!)\n";
3738         delete $LOCKFILES{$db_lock};
3739         if ($update_ref) {
3740                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3741                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3742                 kill $sig, $$ if defined $sig;
3743         }
3744 }
3745
3746 # If want_commit, this will return an array of (rev, commit) where
3747 # commit _must_ be a valid commit in the archive.
3748 # Otherwise, it'll return the max revision (whether or not the
3749 # commit is valid or just a 0x40 placeholder).
3750 sub rev_map_max {
3751         my ($self, $want_commit) = @_;
3752         $self->rebuild;
3753         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3754         $want_commit ? ($r, $c) : $r;
3755 }
3756
3757 sub rev_map_max_norebuild {
3758         my ($self, $want_commit) = @_;
3759         my $map_path = $self->map_path;
3760         stat $map_path or return $want_commit ? (0, undef) : 0;
3761         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3762         binmode $fh or croak "binmode: $!";
3763         my $size = (stat($fh))[7];
3764         ($size % 24) == 0 or croak "inconsistent size: $size";
3765
3766         if ($size == 0) {
3767                 close $fh or croak "close: $!";
3768                 return $want_commit ? (0, undef) : 0;
3769         }
3770
3771         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3772         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3773         my ($r, $c) = unpack(rev_map_fmt, $buf);
3774         if ($want_commit && $c eq ('0' x40)) {
3775                 if ($size < 48) {
3776                         return $want_commit ? (0, undef) : 0;
3777                 }
3778                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3779                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3780                 ($r, $c) = unpack(rev_map_fmt, $buf);
3781                 if ($c eq ('0'x40)) {
3782                         croak "Penultimate record is all-zeroes in $map_path";
3783                 }
3784         }
3785         close $fh or croak "close: $!";
3786         $want_commit ? ($r, $c) : $r;
3787 }
3788
3789 sub rev_map_get {
3790         my ($self, $rev, $uuid) = @_;
3791         my $map_path = $self->map_path($uuid);
3792         return undef unless -e $map_path;
3793
3794         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3795         my $c = _rev_map_get($fh, $rev);
3796         close($fh) or croak "close: $!";
3797         $c
3798 }
3799
3800 sub _rev_map_get {
3801         my ($fh, $rev) = @_;
3802
3803         binmode $fh or croak "binmode: $!";
3804         my $size = (stat($fh))[7];
3805         ($size % 24) == 0 or croak "inconsistent size: $size";
3806
3807         if ($size == 0) {
3808                 return undef;
3809         }
3810
3811         my ($l, $u) = (0, $size - 24);
3812         my ($r, $c, $buf);
3813
3814         while ($l <= $u) {
3815                 my $i = int(($l/24 + $u/24) / 2) * 24;
3816                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3817                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3818                 my ($r, $c) = unpack(rev_map_fmt, $buf);
3819
3820                 if ($r < $rev) {
3821                         $l = $i + 24;
3822                 } elsif ($r > $rev) {
3823                         $u = $i - 24;
3824                 } else { # $r == $rev
3825                         return $c eq ('0' x 40) ? undef : $c;
3826                 }
3827         }
3828         undef;
3829 }
3830
3831 # Finds the first svn revision that exists on (if $eq_ok is true) or
3832 # before $rev for the current branch.  It will not search any lower
3833 # than $min_rev.  Returns the git commit hash and svn revision number
3834 # if found, else (undef, undef).
3835 sub find_rev_before {
3836         my ($self, $rev, $eq_ok, $min_rev) = @_;
3837         --$rev unless $eq_ok;
3838         $min_rev ||= 1;
3839         my $max_rev = $self->rev_map_max;
3840         $rev = $max_rev if ($rev > $max_rev);
3841         while ($rev >= $min_rev) {
3842                 if (my $c = $self->rev_map_get($rev)) {
3843                         return ($rev, $c);
3844                 }
3845                 --$rev;
3846         }
3847         return (undef, undef);
3848 }
3849
3850 # Finds the first svn revision that exists on (if $eq_ok is true) or
3851 # after $rev for the current branch.  It will not search any higher
3852 # than $max_rev.  Returns the git commit hash and svn revision number
3853 # if found, else (undef, undef).
3854 sub find_rev_after {
3855         my ($self, $rev, $eq_ok, $max_rev) = @_;
3856         ++$rev unless $eq_ok;
3857         $max_rev ||= $self->rev_map_max;
3858         while ($rev <= $max_rev) {
3859                 if (my $c = $self->rev_map_get($rev)) {
3860                         return ($rev, $c);
3861                 }
3862                 ++$rev;
3863         }
3864         return (undef, undef);
3865 }
3866
3867 sub _new {
3868         my ($class, $repo_id, $ref_id, $path) = @_;
3869         unless (defined $repo_id && length $repo_id) {
3870                 $repo_id = $Git::SVN::default_repo_id;
3871         }
3872         unless (defined $ref_id && length $ref_id) {
3873                 $_prefix = '' unless defined($_prefix);
3874                 $_[2] = $ref_id =
3875                              "refs/remotes/$_prefix$Git::SVN::default_ref_id";
3876         }
3877         $_[1] = $repo_id;
3878         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3879
3880         # Older repos imported by us used $GIT_DIR/svn/foo instead of
3881         # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
3882         if ($ref_id =~ m{^refs/remotes/(.*)}) {
3883                 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
3884                 if (-d $old_dir && ! -d $dir) {
3885                         $dir = $old_dir;
3886                 }
3887         }
3888
3889         $_[3] = $path = '' unless (defined $path);
3890         mkpath([$dir]);
3891         bless {
3892                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3893                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3894                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3895 }
3896
3897 # for read-only access of old .rev_db formats
3898 sub unlink_rev_db_symlink {
3899         my ($self) = @_;
3900         my $link = $self->rev_db_path;
3901         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3902         if (-l $link) {
3903                 unlink $link or croak "unlink: $link failed!";
3904         }
3905 }
3906
3907 sub rev_db_path {
3908         my ($self, $uuid) = @_;
3909         my $db_path = $self->map_path($uuid);
3910         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3911             or croak "map_path: $db_path does not contain '/.rev_map.' !";
3912         $db_path;
3913 }
3914
3915 # the new replacement for .rev_db
3916 sub map_path {
3917         my ($self, $uuid) = @_;
3918         $uuid ||= $self->ra_uuid;
3919         "$self->{map_root}.$uuid";
3920 }
3921
3922 sub uri_encode {
3923         my ($f) = @_;
3924         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3925         $f
3926 }
3927
3928 sub uri_decode {
3929         my ($f) = @_;
3930         $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
3931         $f
3932 }
3933
3934 sub remove_username {
3935         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3936 }
3937
3938 package Git::SVN::Prompt;
3939 use strict;
3940 use warnings;
3941 require SVN::Core;
3942 use vars qw/$_no_auth_cache $_username/;
3943
3944 sub simple {
3945         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3946         $may_save = undef if $_no_auth_cache;
3947         $default_username = $_username if defined $_username;
3948         if (defined $default_username && length $default_username) {
3949                 if (defined $realm && length $realm) {
3950                         print STDERR "Authentication realm: $realm\n";
3951                         STDERR->flush;
3952                 }
3953                 $cred->username($default_username);
3954         } else {
3955                 username($cred, $realm, $may_save, $pool);
3956         }
3957         $cred->password(_read_password("Password for '" .
3958                                        $cred->username . "': ", $realm));
3959         $cred->may_save($may_save);
3960         $SVN::_Core::SVN_NO_ERROR;
3961 }
3962
3963 sub ssl_server_trust {
3964         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3965         $may_save = undef if $_no_auth_cache;
3966         print STDERR "Error validating server certificate for '$realm':\n";
3967         {
3968                 no warnings 'once';
3969                 # All variables SVN::Auth::SSL::* are used only once,
3970                 # so we're shutting up Perl warnings about this.
3971                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3972                         print STDERR " - The certificate is not issued ",
3973                             "by a trusted authority. Use the\n",
3974                             "   fingerprint to validate ",
3975                             "the certificate manually!\n";
3976                 }
3977                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3978                         print STDERR " - The certificate hostname ",
3979                             "does not match.\n";
3980                 }
3981                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3982                         print STDERR " - The certificate is not yet valid.\n";
3983                 }
3984                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3985                         print STDERR " - The certificate has expired.\n";
3986                 }
3987                 if ($failures & $SVN::Auth::SSL::OTHER) {
3988                         print STDERR " - The certificate has ",
3989                             "an unknown error.\n";
3990                 }
3991         } # no warnings 'once'
3992         printf STDERR
3993                 "Certificate information:\n".
3994                 " - Hostname: %s\n".
3995                 " - Valid: from %s until %s\n".
3996                 " - Issuer: %s\n".
3997                 " - Fingerprint: %s\n",
3998                 map $cert_info->$_, qw(hostname valid_from valid_until
3999                                        issuer_dname fingerprint);
4000         my $choice;
4001 prompt:
4002         print STDERR $may_save ?
4003               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
4004               "(R)eject or accept (t)emporarily? ";
4005         STDERR->flush;
4006         $choice = lc(substr(<STDIN> || 'R', 0, 1));
4007         if ($choice =~ /^t$/i) {
4008                 $cred->may_save(undef);
4009         } elsif ($choice =~ /^r$/i) {
4010                 return -1;
4011         } elsif ($may_save && $choice =~ /^p$/i) {
4012                 $cred->may_save($may_save);
4013         } else {
4014                 goto prompt;
4015         }
4016         $cred->accepted_failures($failures);
4017         $SVN::_Core::SVN_NO_ERROR;
4018 }
4019
4020 sub ssl_client_cert {
4021         my ($cred, $realm, $may_save, $pool) = @_;
4022         $may_save = undef if $_no_auth_cache;
4023         print STDERR "Client certificate filename: ";
4024         STDERR->flush;
4025         chomp(my $filename = <STDIN>);
4026         $cred->cert_file($filename);
4027         $cred->may_save($may_save);
4028         $SVN::_Core::SVN_NO_ERROR;
4029 }
4030
4031 sub ssl_client_cert_pw {
4032         my ($cred, $realm, $may_save, $pool) = @_;
4033         $may_save = undef if $_no_auth_cache;
4034         $cred->password(_read_password("Password: ", $realm));
4035         $cred->may_save($may_save);
4036         $SVN::_Core::SVN_NO_ERROR;
4037 }
4038
4039 sub username {
4040         my ($cred, $realm, $may_save, $pool) = @_;
4041         $may_save = undef if $_no_auth_cache;
4042         if (defined $realm && length $realm) {
4043                 print STDERR "Authentication realm: $realm\n";
4044         }
4045         my $username;
4046         if (defined $_username) {
4047                 $username = $_username;
4048         } else {
4049                 print STDERR "Username: ";
4050                 STDERR->flush;
4051                 chomp($username = <STDIN>);
4052         }
4053         $cred->username($username);
4054         $cred->may_save($may_save);
4055         $SVN::_Core::SVN_NO_ERROR;
4056 }
4057
4058 sub _read_password {
4059         my ($prompt, $realm) = @_;
4060         my $password = '';
4061         if (exists $ENV{GIT_ASKPASS}) {
4062                 open(PH, "-|", $ENV{GIT_ASKPASS}, $prompt);
4063                 $password = <PH>;
4064                 $password =~ s/[\012\015]//; # \n\r
4065                 close(PH);
4066         } else {
4067                 print STDERR $prompt;
4068                 STDERR->flush;
4069                 require Term::ReadKey;
4070                 Term::ReadKey::ReadMode('noecho');
4071                 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
4072                         last if $key =~ /[\012\015]/; # \n\r
4073                         $password .= $key;
4074                 }
4075                 Term::ReadKey::ReadMode('restore');
4076                 print STDERR "\n";
4077                 STDERR->flush;
4078         }
4079         $password;
4080 }
4081
4082 package SVN::Git::Fetcher;
4083 use vars qw/@ISA/;
4084 use strict;
4085 use warnings;
4086 use Carp qw/croak/;
4087 use IO::File qw//;
4088 use vars qw/$_ignore_regex/;
4089
4090 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
4091 sub new {
4092         my ($class, $git_svn, $switch_path) = @_;
4093         my $self = SVN::Delta::Editor->new;
4094         bless $self, $class;
4095         if (exists $git_svn->{last_commit}) {
4096                 $self->{c} = $git_svn->{last_commit};
4097                 $self->{empty_symlinks} =
4098                                   _mark_empty_symlinks($git_svn, $switch_path);
4099         }
4100         $self->{ignore_regex} = eval { command_oneline('config', '--get',
4101                              "svn-remote.$git_svn->{repo_id}.ignore-paths") };
4102         $self->{empty} = {};
4103         $self->{dir_prop} = {};
4104         $self->{file_prop} = {};
4105         $self->{absent_dir} = {};
4106         $self->{absent_file} = {};
4107         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
4108         $self->{pathnameencoding} = Git::config('svn.pathnameencoding');
4109         $self;
4110 }
4111
4112 # this uses the Ra object, so it must be called before do_{switch,update},
4113 # not inside them (when the Git::SVN::Fetcher object is passed) to
4114 # do_{switch,update}
4115 sub _mark_empty_symlinks {
4116         my ($git_svn, $switch_path) = @_;
4117         my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
4118         return {} if (!defined($bool)) || (defined($bool) && ! $bool);
4119
4120         my %ret;
4121         my ($rev, $cmt) = $git_svn->last_rev_commit;
4122         return {} unless ($rev && $cmt);
4123
4124         # allow the warning to be printed for each revision we fetch to
4125         # ensure the user sees it.  The user can also disable the workaround
4126         # on the repository even while git svn is running and the next
4127         # revision fetched will skip this expensive function.
4128         my $printed_warning;
4129         chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
4130         my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
4131         local $/ = "\0";
4132         my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
4133         $pfx .= '/' if length($pfx);
4134         while (<$ls>) {
4135                 chomp;
4136                 s/\A100644 blob $empty_blob\t//o or next;
4137                 unless ($printed_warning) {
4138                         print STDERR "Scanning for empty symlinks, ",
4139                                      "this may take a while if you have ",
4140                                      "many empty files\n",
4141                                      "You may disable this with `",
4142                                      "git config svn.brokenSymlinkWorkaround ",
4143                                      "false'.\n",
4144                                      "This may be done in a different ",
4145                                      "terminal without restarting ",
4146                                      "git svn\n";
4147                         $printed_warning = 1;
4148                 }
4149                 my $path = $_;
4150                 my (undef, $props) =
4151                                $git_svn->ra->get_file($pfx.$path, $rev, undef);
4152                 if ($props->{'svn:special'}) {
4153                         $ret{$path} = 1;
4154                 }
4155         }
4156         command_close_pipe($ls, $ctx);
4157         \%ret;
4158 }
4159
4160 # returns true if a given path is inside a ".git" directory
4161 sub in_dot_git {
4162         $_[0] =~ m{(?:^|/)\.git(?:/|$)};
4163 }
4164
4165 # return value: 0 -- don't ignore, 1 -- ignore
4166 sub is_path_ignored {
4167         my ($self, $path) = @_;
4168         return 1 if in_dot_git($path);
4169         return 1 if defined($self->{ignore_regex}) &&
4170                     $path =~ m!$self->{ignore_regex}!;
4171         return 0 unless defined($_ignore_regex);
4172         return 1 if $path =~ m!$_ignore_regex!o;
4173         return 0;
4174 }
4175
4176 sub set_path_strip {
4177         my ($self, $path) = @_;
4178         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
4179 }
4180
4181 sub open_root {
4182         { path => '' };
4183 }
4184
4185 sub open_directory {
4186         my ($self, $path, $pb, $rev) = @_;
4187         { path => $path };
4188 }
4189
4190 sub git_path {
4191         my ($self, $path) = @_;
4192         if (my $enc = $self->{pathnameencoding}) {
4193                 require Encode;
4194                 Encode::from_to($path, 'UTF-8', $enc);
4195         }
4196         if ($self->{path_strip}) {
4197                 $path =~ s!$self->{path_strip}!! or
4198                   die "Failed to strip path '$path' ($self->{path_strip})\n";
4199         }
4200         $path;
4201 }
4202
4203 sub delete_entry {
4204         my ($self, $path, $rev, $pb) = @_;
4205         return undef if $self->is_path_ignored($path);
4206
4207         my $gpath = $self->git_path($path);
4208         return undef if ($gpath eq '');
4209
4210         # remove entire directories.
4211         my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4212                          =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
4213         if ($tree) {
4214                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4215                                                      -r --name-only -z/,
4216                                                      $tree);
4217                 local $/ = "\0";
4218                 while (<$ls>) {
4219                         chomp;
4220                         my $rmpath = "$gpath/$_";
4221                         $self->{gii}->remove($rmpath);
4222                         print "\tD\t$rmpath\n" unless $::_q;
4223                 }
4224                 print "\tD\t$gpath/\n" unless $::_q;
4225                 command_close_pipe($ls, $ctx);
4226         } else {
4227                 $self->{gii}->remove($gpath);
4228                 print "\tD\t$gpath\n" unless $::_q;
4229         }
4230         $self->{empty}->{$path} = 0;
4231         undef;
4232 }
4233
4234 sub open_file {
4235         my ($self, $path, $pb, $rev) = @_;
4236         my ($mode, $blob);
4237
4238         goto out if $self->is_path_ignored($path);
4239
4240         my $gpath = $self->git_path($path);
4241         ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4242                              =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
4243         unless (defined $mode && defined $blob) {
4244                 die "$path was not found in commit $self->{c} (r$rev)\n";
4245         }
4246         if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
4247                 $mode = '120000';
4248         }
4249 out:
4250         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
4251           pool => SVN::Pool->new, action => 'M' };
4252 }
4253
4254 sub add_file {
4255         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
4256         my $mode;
4257
4258         if (!$self->is_path_ignored($path)) {
4259                 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4260                 delete $self->{empty}->{$dir};
4261                 $mode = '100644';
4262         }
4263         { path => $path, mode_a => $mode, mode_b => $mode,
4264           pool => SVN::Pool->new, action => 'A' };
4265 }
4266
4267 sub add_directory {
4268         my ($self, $path, $cp_path, $cp_rev) = @_;
4269         goto out if $self->is_path_ignored($path);
4270         my $gpath = $self->git_path($path);
4271         if ($gpath eq '') {
4272                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4273                                                      -r --name-only -z/,
4274                                                      $self->{c});
4275                 local $/ = "\0";
4276                 while (<$ls>) {
4277                         chomp;
4278                         $self->{gii}->remove($_);
4279                         print "\tD\t$_\n" unless $::_q;
4280                 }
4281                 command_close_pipe($ls, $ctx);
4282                 $self->{empty}->{$path} = 0;
4283         }
4284         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4285         delete $self->{empty}->{$dir};
4286         $self->{empty}->{$path} = 1;
4287 out:
4288         { path => $path };
4289 }
4290
4291 sub change_dir_prop {
4292         my ($self, $db, $prop, $value) = @_;
4293         return undef if $self->is_path_ignored($db->{path});
4294         $self->{dir_prop}->{$db->{path}} ||= {};
4295         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
4296         undef;
4297 }
4298
4299 sub absent_directory {
4300         my ($self, $path, $pb) = @_;
4301         return undef if $self->is_path_ignored($path);
4302         $self->{absent_dir}->{$pb->{path}} ||= [];
4303         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
4304         undef;
4305 }
4306
4307 sub absent_file {
4308         my ($self, $path, $pb) = @_;
4309         return undef if $self->is_path_ignored($path);
4310         $self->{absent_file}->{$pb->{path}} ||= [];
4311         push @{$self->{absent_file}->{$pb->{path}}}, $path;
4312         undef;
4313 }
4314
4315 sub change_file_prop {
4316         my ($self, $fb, $prop, $value) = @_;
4317         return undef if $self->is_path_ignored($fb->{path});
4318         if ($prop eq 'svn:executable') {
4319                 if ($fb->{mode_b} != 120000) {
4320                         $fb->{mode_b} = defined $value ? 100755 : 100644;
4321                 }
4322         } elsif ($prop eq 'svn:special') {
4323                 $fb->{mode_b} = defined $value ? 120000 : 100644;
4324         } else {
4325                 $self->{file_prop}->{$fb->{path}} ||= {};
4326                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
4327         }
4328         undef;
4329 }
4330
4331 sub apply_textdelta {
4332         my ($self, $fb, $exp) = @_;
4333         return undef if $self->is_path_ignored($fb->{path});
4334         my $fh = $::_repository->temp_acquire('svn_delta');
4335         # $fh gets auto-closed() by SVN::TxDelta::apply(),
4336         # (but $base does not,) so dup() it for reading in close_file
4337         open my $dup, '<&', $fh or croak $!;
4338         my $base = $::_repository->temp_acquire('git_blob');
4339
4340         if ($fb->{blob}) {
4341                 my ($base_is_link, $size);
4342
4343                 if ($fb->{mode_a} eq '120000' &&
4344                     ! $self->{empty_symlinks}->{$fb->{path}}) {
4345                         print $base 'link ' or die "print $!\n";
4346                         $base_is_link = 1;
4347                 }
4348         retry:
4349                 $size = $::_repository->cat_blob($fb->{blob}, $base);
4350                 die "Failed to read object $fb->{blob}" if ($size < 0);
4351
4352                 if (defined $exp) {
4353                         seek $base, 0, 0 or croak $!;
4354                         my $got = ::md5sum($base);
4355                         if ($got ne $exp) {
4356                                 my $err = "Checksum mismatch: ".
4357                                        "$fb->{path} $fb->{blob}\n" .
4358                                        "expected: $exp\n" .
4359                                        "     got: $got\n";
4360                                 if ($base_is_link) {
4361                                         warn $err,
4362                                              "Retrying... (possibly ",
4363                                              "a bad symlink from SVN)\n";
4364                                         $::_repository->temp_reset($base);
4365                                         $base_is_link = 0;
4366                                         goto retry;
4367                                 }
4368                                 die $err;
4369                         }
4370                 }
4371         }
4372         seek $base, 0, 0 or croak $!;
4373         $fb->{fh} = $fh;
4374         $fb->{base} = $base;
4375         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
4376 }
4377
4378 sub close_file {
4379         my ($self, $fb, $exp) = @_;
4380         return undef if $self->is_path_ignored($fb->{path});
4381
4382         my $hash;
4383         my $path = $self->git_path($fb->{path});
4384         if (my $fh = $fb->{fh}) {
4385                 if (defined $exp) {
4386                         seek($fh, 0, 0) or croak $!;
4387                         my $got = ::md5sum($fh);
4388                         if ($got ne $exp) {
4389                                 die "Checksum mismatch: $path\n",
4390                                     "expected: $exp\n    got: $got\n";
4391                         }
4392                 }
4393                 if ($fb->{mode_b} == 120000) {
4394                         sysseek($fh, 0, 0) or croak $!;
4395                         my $rd = sysread($fh, my $buf, 5);
4396
4397                         if (!defined $rd) {
4398                                 croak "sysread: $!\n";
4399                         } elsif ($rd == 0) {
4400                                 warn "$path has mode 120000",
4401                                      " but it points to nothing\n",
4402                                      "converting to an empty file with mode",
4403                                      " 100644\n";
4404                                 $fb->{mode_b} = '100644';
4405                         } elsif ($buf ne 'link ') {
4406                                 warn "$path has mode 120000",
4407                                      " but is not a link\n";
4408                         } else {
4409                                 my $tmp_fh = $::_repository->temp_acquire(
4410                                         'svn_hash');
4411                                 my $res;
4412                                 while ($res = sysread($fh, my $str, 1024)) {
4413                                         my $out = syswrite($tmp_fh, $str, $res);
4414                                         defined($out) && $out == $res
4415                                                 or croak("write ",
4416                                                         Git::temp_path($tmp_fh),
4417                                                         ": $!\n");
4418                                 }
4419                                 defined $res or croak $!;
4420
4421                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
4422                                 Git::temp_release($tmp_fh, 1);
4423                         }
4424                 }
4425
4426                 $hash = $::_repository->hash_and_insert_object(
4427                                 Git::temp_path($fh));
4428                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
4429
4430                 Git::temp_release($fb->{base}, 1);
4431                 Git::temp_release($fh, 1);
4432         } else {
4433                 $hash = $fb->{blob} or die "no blob information\n";
4434         }
4435         $fb->{pool}->clear;
4436         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
4437         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
4438         undef;
4439 }
4440
4441 sub abort_edit {
4442         my $self = shift;
4443         $self->{nr} = $self->{gii}->{nr};
4444         delete $self->{gii};
4445         $self->SUPER::abort_edit(@_);
4446 }
4447
4448 sub close_edit {
4449         my $self = shift;
4450         $self->{git_commit_ok} = 1;
4451         $self->{nr} = $self->{gii}->{nr};
4452         delete $self->{gii};
4453         $self->SUPER::close_edit(@_);
4454 }
4455
4456 package SVN::Git::Editor;
4457 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
4458 use strict;
4459 use warnings;
4460 use Carp qw/croak/;
4461 use IO::File;
4462
4463 sub new {
4464         my ($class, $opts) = @_;
4465         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
4466                 die "$_ required!\n" unless (defined $opts->{$_});
4467         }
4468
4469         my $pool = SVN::Pool->new;
4470         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
4471         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
4472                                      $opts->{r}, $mods);
4473
4474         # $opts->{ra} functions should not be used after this:
4475         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
4476                                                 $opts->{editor_cb}, $pool);
4477         my $self = SVN::Delta::Editor->new(@ce, $pool);
4478         bless $self, $class;
4479         foreach (qw/svn_path r tree_a tree_b/) {
4480                 $self->{$_} = $opts->{$_};
4481         }
4482         $self->{url} = $opts->{ra}->{url};
4483         $self->{mods} = $mods;
4484         $self->{types} = $types;
4485         $self->{pool} = $pool;
4486         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
4487         $self->{rm} = { };
4488         $self->{path_prefix} = length $self->{svn_path} ?
4489                                "$self->{svn_path}/" : '';
4490         $self->{config} = $opts->{config};
4491         $self->{mergeinfo} = $opts->{mergeinfo};
4492         return $self;
4493 }
4494
4495 sub generate_diff {
4496         my ($tree_a, $tree_b) = @_;
4497         my @diff_tree = qw(diff-tree -z -r);
4498         if ($_cp_similarity) {
4499                 push @diff_tree, "-C$_cp_similarity";
4500         } else {
4501                 push @diff_tree, '-C';
4502         }
4503         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
4504         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
4505         push @diff_tree, $tree_a, $tree_b;
4506         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
4507         local $/ = "\0";
4508         my $state = 'meta';
4509         my @mods;
4510         while (<$diff_fh>) {
4511                 chomp $_; # this gets rid of the trailing "\0"
4512                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
4513                                         ($::sha1)\s($::sha1)\s
4514                                         ([MTCRAD])\d*$/xo) {
4515                         push @mods, {   mode_a => $1, mode_b => $2,
4516                                         sha1_a => $3, sha1_b => $4,
4517                                         chg => $5 };
4518                         if ($5 =~ /^(?:C|R)$/) {
4519                                 $state = 'file_a';
4520                         } else {
4521                                 $state = 'file_b';
4522                         }
4523                 } elsif ($state eq 'file_a') {
4524                         my $x = $mods[$#mods] or croak "Empty array\n";
4525                         if ($x->{chg} !~ /^(?:C|R)$/) {
4526                                 croak "Error parsing $_, $x->{chg}\n";
4527                         }
4528                         $x->{file_a} = $_;
4529                         $state = 'file_b';
4530                 } elsif ($state eq 'file_b') {
4531                         my $x = $mods[$#mods] or croak "Empty array\n";
4532                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
4533                                 croak "Error parsing $_, $x->{chg}\n";
4534                         }
4535                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
4536                                 croak "Error parsing $_, $x->{chg}\n";
4537                         }
4538                         $x->{file_b} = $_;
4539                         $state = 'meta';
4540                 } else {
4541                         croak "Error parsing $_\n";
4542                 }
4543         }
4544         command_close_pipe($diff_fh, $ctx);
4545         \@mods;
4546 }
4547
4548 sub check_diff_paths {
4549         my ($ra, $pfx, $rev, $mods) = @_;
4550         my %types;
4551         $pfx .= '/' if length $pfx;
4552
4553         sub type_diff_paths {
4554                 my ($ra, $types, $path, $rev) = @_;
4555                 my @p = split m#/+#, $path;
4556                 my $c = shift @p;
4557                 unless (defined $types->{$c}) {
4558                         $types->{$c} = $ra->check_path($c, $rev);
4559                 }
4560                 while (@p) {
4561                         $c .= '/' . shift @p;
4562                         next if defined $types->{$c};
4563                         $types->{$c} = $ra->check_path($c, $rev);
4564                 }
4565         }
4566
4567         foreach my $m (@$mods) {
4568                 foreach my $f (qw/file_a file_b/) {
4569                         next unless defined $m->{$f};
4570                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
4571                         if (length $pfx.$dir && ! defined $types{$dir}) {
4572                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
4573                         }
4574                 }
4575         }
4576         \%types;
4577 }
4578
4579 sub split_path {
4580         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
4581 }
4582
4583 sub repo_path {
4584         my ($self, $path) = @_;
4585         if (my $enc = $self->{pathnameencoding}) {
4586                 require Encode;
4587                 Encode::from_to($path, $enc, 'UTF-8');
4588         }
4589         $self->{path_prefix}.(defined $path ? $path : '');
4590 }
4591
4592 sub url_path {
4593         my ($self, $path) = @_;
4594         if ($self->{url} =~ m#^https?://#) {
4595                 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4596         }
4597         $self->{url} . '/' . $self->repo_path($path);
4598 }
4599
4600 sub rmdirs {
4601         my ($self) = @_;
4602         my $rm = $self->{rm};
4603         delete $rm->{''}; # we never delete the url we're tracking
4604         return unless %$rm;
4605
4606         foreach (keys %$rm) {
4607                 my @d = split m#/#, $_;
4608                 my $c = shift @d;
4609                 $rm->{$c} = 1;
4610                 while (@d) {
4611                         $c .= '/' . shift @d;
4612                         $rm->{$c} = 1;
4613                 }
4614         }
4615         delete $rm->{$self->{svn_path}};
4616         delete $rm->{''}; # we never delete the url we're tracking
4617         return unless %$rm;
4618
4619         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4620                                              $self->{tree_b});
4621         local $/ = "\0";
4622         while (<$fh>) {
4623                 chomp;
4624                 my @dn = split m#/#, $_;
4625                 while (pop @dn) {
4626                         delete $rm->{join '/', @dn};
4627                 }
4628                 unless (%$rm) {
4629                         close $fh;
4630                         return;
4631                 }
4632         }
4633         command_close_pipe($fh, $ctx);
4634
4635         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4636         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4637                 $self->close_directory($bat->{$d}, $p);
4638                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4639                 print "\tD+\t$d/\n" unless $::_q;
4640                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4641                 delete $bat->{$d};
4642         }
4643 }
4644
4645 sub open_or_add_dir {
4646         my ($self, $full_path, $baton) = @_;
4647         my $t = $self->{types}->{$full_path};
4648         if (!defined $t) {
4649                 die "$full_path not known in r$self->{r} or we have a bug!\n";
4650         }
4651         {
4652                 no warnings 'once';
4653                 # SVN::Node::none and SVN::Node::file are used only once,
4654                 # so we're shutting up Perl's warnings about them.
4655                 if ($t == $SVN::Node::none) {
4656                         return $self->add_directory($full_path, $baton,
4657                             undef, -1, $self->{pool});
4658                 } elsif ($t == $SVN::Node::dir) {
4659                         return $self->open_directory($full_path, $baton,
4660                             $self->{r}, $self->{pool});
4661                 } # no warnings 'once'
4662                 print STDERR "$full_path already exists in repository at ",
4663                     "r$self->{r} and it is not a directory (",
4664                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4665         } # no warnings 'once'
4666         exit 1;
4667 }
4668
4669 sub ensure_path {
4670         my ($self, $path) = @_;
4671         my $bat = $self->{bat};
4672         my $repo_path = $self->repo_path($path);
4673         return $bat->{''} unless (length $repo_path);
4674         my @p = split m#/+#, $repo_path;
4675         my $c = shift @p;
4676         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4677         while (@p) {
4678                 my $c0 = $c;
4679                 $c .= '/' . shift @p;
4680                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4681         }
4682         return $bat->{$c};
4683 }
4684
4685 # Subroutine to convert a globbing pattern to a regular expression.
4686 # From perl cookbook.
4687 sub glob2pat {
4688         my $globstr = shift;
4689         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4690         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4691         return '^' . $globstr . '$';
4692 }
4693
4694 sub check_autoprop {
4695         my ($self, $pattern, $properties, $file, $fbat) = @_;
4696         # Convert the globbing pattern to a regular expression.
4697         my $regex = glob2pat($pattern);
4698         # Check if the pattern matches the file name.
4699         if($file =~ m/($regex)/) {
4700                 # Parse the list of properties to set.
4701                 my @props = split(/;/, $properties);
4702                 foreach my $prop (@props) {
4703                         # Parse 'name=value' syntax and set the property.
4704                         if ($prop =~ /([^=]+)=(.*)/) {
4705                                 my ($n,$v) = ($1,$2);
4706                                 for ($n, $v) {
4707                                         s/^\s+//; s/\s+$//;
4708                                 }
4709                                 $self->change_file_prop($fbat, $n, $v);
4710                         }
4711                 }
4712         }
4713 }
4714
4715 sub apply_autoprops {
4716         my ($self, $file, $fbat) = @_;
4717         my $conf_t = ${$self->{config}}{'config'};
4718         no warnings 'once';
4719         # Check [miscellany]/enable-auto-props in svn configuration.
4720         if (SVN::_Core::svn_config_get_bool(
4721                 $conf_t,
4722                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4723                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4724                 0)) {
4725                 # Auto-props are enabled.  Enumerate them to look for matches.
4726                 my $callback = sub {
4727                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
4728                 };
4729                 SVN::_Core::svn_config_enumerate(
4730                         $conf_t,
4731                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4732                         $callback);
4733         }
4734 }
4735
4736 sub A {
4737         my ($self, $m) = @_;
4738         my ($dir, $file) = split_path($m->{file_b});
4739         my $pbat = $self->ensure_path($dir);
4740         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4741                                         undef, -1);
4742         print "\tA\t$m->{file_b}\n" unless $::_q;
4743         $self->apply_autoprops($file, $fbat);
4744         $self->chg_file($fbat, $m);
4745         $self->close_file($fbat,undef,$self->{pool});
4746 }
4747
4748 sub C {
4749         my ($self, $m) = @_;
4750         my ($dir, $file) = split_path($m->{file_b});
4751         my $pbat = $self->ensure_path($dir);
4752         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4753                                 $self->url_path($m->{file_a}), $self->{r});
4754         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4755         $self->chg_file($fbat, $m);
4756         $self->close_file($fbat,undef,$self->{pool});
4757 }
4758
4759 sub delete_entry {
4760         my ($self, $path, $pbat) = @_;
4761         my $rpath = $self->repo_path($path);
4762         my ($dir, $file) = split_path($rpath);
4763         $self->{rm}->{$dir} = 1;
4764         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4765 }
4766
4767 sub R {
4768         my ($self, $m) = @_;
4769         my ($dir, $file) = split_path($m->{file_b});
4770         my $pbat = $self->ensure_path($dir);
4771         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4772                                 $self->url_path($m->{file_a}), $self->{r});
4773         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4774         $self->apply_autoprops($file, $fbat);
4775         $self->chg_file($fbat, $m);
4776         $self->close_file($fbat,undef,$self->{pool});
4777
4778         ($dir, $file) = split_path($m->{file_a});
4779         $pbat = $self->ensure_path($dir);
4780         $self->delete_entry($m->{file_a}, $pbat);
4781 }
4782
4783 sub M {
4784         my ($self, $m) = @_;
4785         my ($dir, $file) = split_path($m->{file_b});
4786         my $pbat = $self->ensure_path($dir);
4787         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4788                                 $pbat,$self->{r},$self->{pool});
4789         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4790         $self->chg_file($fbat, $m);
4791         $self->close_file($fbat,undef,$self->{pool});
4792 }
4793
4794 sub T { shift->M(@_) }
4795
4796 sub change_file_prop {
4797         my ($self, $fbat, $pname, $pval) = @_;
4798         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4799 }
4800
4801 sub change_dir_prop {
4802         my ($self, $pbat, $pname, $pval) = @_;
4803         $self->SUPER::change_dir_prop($pbat, $pname, $pval, $self->{pool});
4804 }
4805
4806 sub _chg_file_get_blob ($$$$) {
4807         my ($self, $fbat, $m, $which) = @_;
4808         my $fh = $::_repository->temp_acquire("git_blob_$which");
4809         if ($m->{"mode_$which"} =~ /^120/) {
4810                 print $fh 'link ' or croak $!;
4811                 $self->change_file_prop($fbat,'svn:special','*');
4812         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4813                 $self->change_file_prop($fbat,'svn:special',undef);
4814         }
4815         my $blob = $m->{"sha1_$which"};
4816         return ($fh,) if ($blob =~ /^0{40}$/);
4817         my $size = $::_repository->cat_blob($blob, $fh);
4818         croak "Failed to read object $blob" if ($size < 0);
4819         $fh->flush == 0 or croak $!;
4820         seek $fh, 0, 0 or croak $!;
4821
4822         my $exp = ::md5sum($fh);
4823         seek $fh, 0, 0 or croak $!;
4824         return ($fh, $exp);
4825 }
4826
4827 sub chg_file {
4828         my ($self, $fbat, $m) = @_;
4829         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4830                 $self->change_file_prop($fbat,'svn:executable','*');
4831         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4832                 $self->change_file_prop($fbat,'svn:executable',undef);
4833         }
4834         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4835         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4836         my $pool = SVN::Pool->new;
4837         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4838         if (-s $fh_a) {
4839                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4840                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4841                 if (defined $res) {
4842                         die "Unexpected result from send_txstream: $res\n",
4843                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4844                 }
4845         } else {
4846                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4847                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4848                     if ($got ne $exp_b);
4849         }
4850         Git::temp_release($fh_b, 1);
4851         Git::temp_release($fh_a, 1);
4852         $pool->clear;
4853 }
4854
4855 sub D {
4856         my ($self, $m) = @_;
4857         my ($dir, $file) = split_path($m->{file_b});
4858         my $pbat = $self->ensure_path($dir);
4859         print "\tD\t$m->{file_b}\n" unless $::_q;
4860         $self->delete_entry($m->{file_b}, $pbat);
4861 }
4862
4863 sub close_edit {
4864         my ($self) = @_;
4865         my ($p,$bat) = ($self->{pool}, $self->{bat});
4866         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4867                 next if $_ eq '';
4868                 $self->close_directory($bat->{$_}, $p);
4869         }
4870         $self->close_directory($bat->{''}, $p);
4871         $self->SUPER::close_edit($p);
4872         $p->clear;
4873 }
4874
4875 sub abort_edit {
4876         my ($self) = @_;
4877         $self->SUPER::abort_edit($self->{pool});
4878 }
4879
4880 sub DESTROY {
4881         my $self = shift;
4882         $self->SUPER::DESTROY(@_);
4883         $self->{pool}->clear;
4884 }
4885
4886 # this drives the editor
4887 sub apply_diff {
4888         my ($self) = @_;
4889         my $mods = $self->{mods};
4890         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4891         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4892                 my $f = $m->{chg};
4893                 if (defined $o{$f}) {
4894                         $self->$f($m);
4895                 } else {
4896                         fatal("Invalid change type: $f");
4897                 }
4898         }
4899
4900         if (defined($self->{mergeinfo})) {
4901                 $self->change_dir_prop($self->{bat}{''}, "svn:mergeinfo",
4902                                        $self->{mergeinfo});
4903         }
4904         $self->rmdirs if $_rmdir;
4905         if (@$mods == 0) {
4906                 $self->abort_edit;
4907         } else {
4908                 $self->close_edit;
4909         }
4910         return scalar @$mods;
4911 }
4912
4913 package Git::SVN::Ra;
4914 use vars qw/@ISA $config_dir $_log_window_size/;
4915 use strict;
4916 use warnings;
4917 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4918
4919 BEGIN {
4920         # enforce temporary pool usage for some simple functions
4921         no strict 'refs';
4922         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4923                       get_file/) {
4924                 my $SUPER = "SUPER::$f";
4925                 *$f = sub {
4926                         my $self = shift;
4927                         my $pool = SVN::Pool->new;
4928                         my @ret = $self->$SUPER(@_,$pool);
4929                         $pool->clear;
4930                         wantarray ? @ret : $ret[0];
4931                 };
4932         }
4933 }
4934
4935 sub _auth_providers () {
4936         [
4937           SVN::Client::get_simple_provider(),
4938           SVN::Client::get_ssl_server_trust_file_provider(),
4939           SVN::Client::get_simple_prompt_provider(
4940             \&Git::SVN::Prompt::simple, 2),
4941           SVN::Client::get_ssl_client_cert_file_provider(),
4942           SVN::Client::get_ssl_client_cert_prompt_provider(
4943             \&Git::SVN::Prompt::ssl_client_cert, 2),
4944           SVN::Client::get_ssl_client_cert_pw_file_provider(),
4945           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4946             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4947           SVN::Client::get_username_provider(),
4948           SVN::Client::get_ssl_server_trust_prompt_provider(
4949             \&Git::SVN::Prompt::ssl_server_trust),
4950           SVN::Client::get_username_prompt_provider(
4951             \&Git::SVN::Prompt::username, 2)
4952         ]
4953 }
4954
4955 sub escape_uri_only {
4956         my ($uri) = @_;
4957         my @tmp;
4958         foreach (split m{/}, $uri) {
4959                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4960                 push @tmp, $_;
4961         }
4962         join('/', @tmp);
4963 }
4964
4965 sub escape_url {
4966         my ($url) = @_;
4967         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4968                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4969                 $url = "$scheme://$domain$uri";
4970         }
4971         $url;
4972 }
4973
4974 sub new {
4975         my ($class, $url) = @_;
4976         $url =~ s!/+$!!;
4977         return $RA if ($RA && $RA->{url} eq $url);
4978
4979         ::_req_svn();
4980
4981         SVN::_Core::svn_config_ensure($config_dir, undef);
4982         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4983         my $config = SVN::Core::config_get_config($config_dir);
4984         $RA = undef;
4985         my $dont_store_passwords = 1;
4986         my $conf_t = ${$config}{'config'};
4987         {
4988                 no warnings 'once';
4989                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4990                 # produces warnings that variables are used only once.
4991                 # I had not found the better way to shut them up, so
4992                 # the warnings of type 'once' are disabled in this block.
4993                 if (SVN::_Core::svn_config_get_bool($conf_t,
4994                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4995                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4996                     1) == 0) {
4997                         SVN::_Core::svn_auth_set_parameter($baton,
4998                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4999                             bless (\$dont_store_passwords, "_p_void"));
5000                 }
5001                 if (SVN::_Core::svn_config_get_bool($conf_t,
5002                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
5003                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
5004                     1) == 0) {
5005                         $Git::SVN::Prompt::_no_auth_cache = 1;
5006                 }
5007         } # no warnings 'once'
5008         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
5009                               config => $config,
5010                               pool => SVN::Pool->new,
5011                               auth_provider_callbacks => $callbacks);
5012         $self->{url} = $url;
5013         $self->{svn_path} = $url;
5014         $self->{repos_root} = $self->get_repos_root;
5015         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
5016         $self->{cache} = { check_path => { r => 0, data => {} },
5017                            get_dir => { r => 0, data => {} } };
5018         $RA = bless $self, $class;
5019 }
5020
5021 sub check_path {
5022         my ($self, $path, $r) = @_;
5023         my $cache = $self->{cache}->{check_path};
5024         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
5025                 return $cache->{data}->{$path};
5026         }
5027         my $pool = SVN::Pool->new;
5028         my $t = $self->SUPER::check_path($path, $r, $pool);
5029         $pool->clear;
5030         if ($r != $cache->{r}) {
5031                 %{$cache->{data}} = ();
5032                 $cache->{r} = $r;
5033         }
5034         $cache->{data}->{$path} = $t;
5035 }
5036
5037 sub get_dir {
5038         my ($self, $dir, $r) = @_;
5039         my $cache = $self->{cache}->{get_dir};
5040         if ($r == $cache->{r}) {
5041                 if (my $x = $cache->{data}->{$dir}) {
5042                         return wantarray ? @$x : $x->[0];
5043                 }
5044         }
5045         my $pool = SVN::Pool->new;
5046         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
5047         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
5048         $pool->clear;
5049         if ($r != $cache->{r}) {
5050                 %{$cache->{data}} = ();
5051                 $cache->{r} = $r;
5052         }
5053         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
5054         wantarray ? (\%dirents, $r, $props) : \%dirents;
5055 }
5056
5057 sub DESTROY {
5058         # do not call the real DESTROY since we store ourselves in $RA
5059 }
5060
5061 # get_log(paths, start, end, limit,
5062 #         discover_changed_paths, strict_node_history, receiver)
5063 sub get_log {
5064         my ($self, @args) = @_;
5065         my $pool = SVN::Pool->new;
5066
5067         # svn_log_changed_path_t objects passed to get_log are likely to be
5068         # overwritten even if only the refs are copied to an external variable,
5069         # so we should dup the structures in their entirety.  Using an
5070         # externally passed pool (instead of our temporary and quickly cleared
5071         # pool in Git::SVN::Ra) does not help matters at all...
5072         my $receiver = pop @args;
5073         my $prefix = "/".$self->{svn_path};
5074         $prefix =~ s#/+($)##;
5075         my $prefix_regex = qr#^\Q$prefix\E#;
5076         push(@args, sub {
5077                 my ($paths) = $_[0];
5078                 return &$receiver(@_) unless $paths;
5079                 $_[0] = ();
5080                 foreach my $p (keys %$paths) {
5081                         my $i = $paths->{$p};
5082                         # Make path relative to our url, not repos_root
5083                         $p =~ s/$prefix_regex//;
5084                         my %s = map { $_ => $i->$_; }
5085                                 qw/copyfrom_path copyfrom_rev action/;
5086                         if ($s{'copyfrom_path'}) {
5087                                 $s{'copyfrom_path'} =~ s/$prefix_regex//;
5088                         }
5089                         $_[0]{$p} = \%s;
5090                 }
5091                 &$receiver(@_);
5092         });
5093
5094
5095         # the limit parameter was not supported in SVN 1.1.x, so we
5096         # drop it.  Therefore, the receiver callback passed to it
5097         # is made aware of this limitation by being wrapped if
5098         # the limit passed to is being wrapped.
5099         if ($SVN::Core::VERSION le '1.2.0') {
5100                 my $limit = splice(@args, 3, 1);
5101                 if ($limit > 0) {
5102                         my $receiver = pop @args;
5103                         push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
5104                 }
5105         }
5106         my $ret = $self->SUPER::get_log(@args, $pool);
5107         $pool->clear;
5108         $ret;
5109 }
5110
5111 sub trees_match {
5112         my ($self, $url1, $rev1, $url2, $rev2) = @_;
5113         my $ctx = SVN::Client->new(auth => _auth_providers);
5114         my $out = IO::File->new_tmpfile;
5115
5116         # older SVN (1.1.x) doesn't take $pool as the last parameter for
5117         # $ctx->diff(), so we'll create a default one
5118         my $pool = SVN::Pool->new_default_sub;
5119
5120         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
5121         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
5122         $out->flush;
5123         my $ret = (($out->stat)[7] == 0);
5124         close $out or croak $!;
5125
5126         $ret;
5127 }
5128
5129 sub get_commit_editor {
5130         my ($self, $log, $cb, $pool) = @_;
5131         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
5132         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
5133 }
5134
5135 sub gs_do_update {
5136         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
5137         my $new = ($rev_a == $rev_b);
5138         my $path = $gs->{path};
5139
5140         if ($new && -e $gs->{index}) {
5141                 unlink $gs->{index} or die
5142                   "Couldn't unlink index: $gs->{index}: $!\n";
5143         }
5144         my $pool = SVN::Pool->new;
5145         $editor->set_path_strip($path);
5146         my (@pc) = split m#/#, $path;
5147         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
5148                                         1, $editor, $pool);
5149         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5150
5151         # Since we can't rely on svn_ra_reparent being available, we'll
5152         # just have to do some magic with set_path to make it so
5153         # we only want a partial path.
5154         my $sp = '';
5155         my $final = join('/', @pc);
5156         while (@pc) {
5157                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
5158                 $sp .= '/' if length $sp;
5159                 $sp .= shift @pc;
5160         }
5161         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
5162
5163         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
5164
5165         $reporter->finish_report($pool);
5166         $pool->clear;
5167         $editor->{git_commit_ok};
5168 }
5169
5170 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
5171 # svn_ra_reparent didn't work before 1.4)
5172 sub gs_do_switch {
5173         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
5174         my $path = $gs->{path};
5175         my $pool = SVN::Pool->new;
5176
5177         my $full_url = $self->{url};
5178         my $old_url = $full_url;
5179         $full_url .= '/' . $path if length $path;
5180         my ($ra, $reparented);
5181
5182         if ($old_url =~ m#^svn(\+ssh)?://# ||
5183             ($full_url =~ m#^https?://# &&
5184              escape_url($full_url) ne $full_url)) {
5185                 $_[0] = undef;
5186                 $self = undef;
5187                 $RA = undef;
5188                 $ra = Git::SVN::Ra->new($full_url);
5189                 $ra_invalid = 1;
5190         } elsif ($old_url ne $full_url) {
5191                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
5192                 $self->{url} = $full_url;
5193                 $reparented = 1;
5194         }
5195
5196         $ra ||= $self;
5197         $url_b = escape_url($url_b);
5198         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
5199         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5200         $reporter->set_path('', $rev_a, 0, @lock, $pool);
5201         $reporter->finish_report($pool);
5202
5203         if ($reparented) {
5204                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
5205                 $self->{url} = $old_url;
5206         }
5207
5208         $pool->clear;
5209         $editor->{git_commit_ok};
5210 }
5211
5212 sub longest_common_path {
5213         my ($gsv, $globs) = @_;
5214         my %common;
5215         my $common_max = scalar @$gsv;
5216
5217         foreach my $gs (@$gsv) {
5218                 my @tmp = split m#/#, $gs->{path};
5219                 my $p = '';
5220                 foreach (@tmp) {
5221                         $p .= length($p) ? "/$_" : $_;
5222                         $common{$p} ||= 0;
5223                         $common{$p}++;
5224                 }
5225         }
5226         $globs ||= [];
5227         $common_max += scalar @$globs;
5228         foreach my $glob (@$globs) {
5229                 my @tmp = split m#/#, $glob->{path}->{left};
5230                 my $p = '';
5231                 foreach (@tmp) {
5232                         $p .= length($p) ? "/$_" : $_;
5233                         $common{$p} ||= 0;
5234                         $common{$p}++;
5235                 }
5236         }
5237
5238         my $longest_path = '';
5239         foreach (sort {length $b <=> length $a} keys %common) {
5240                 if ($common{$_} == $common_max) {
5241                         $longest_path = $_;
5242                         last;
5243                 }
5244         }
5245         $longest_path;
5246 }
5247
5248 sub gs_fetch_loop_common {
5249         my ($self, $base, $head, $gsv, $globs) = @_;
5250         return if ($base > $head);
5251         my $inc = $_log_window_size;
5252         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
5253         my $longest_path = longest_common_path($gsv, $globs);
5254         my $ra_url = $self->{url};
5255         my $find_trailing_edge;
5256         while (1) {
5257                 my %revs;
5258                 my $err;
5259                 my $err_handler = $SVN::Error::handler;
5260                 $SVN::Error::handler = sub {
5261                         ($err) = @_;
5262                         skip_unknown_revs($err);
5263                 };
5264                 sub _cb {
5265                         my ($paths, $r, $author, $date, $log) = @_;
5266                         [ $paths,
5267                           { author => $author, date => $date, log => $log } ];
5268                 }
5269                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
5270                                sub { $revs{$_[1]} = _cb(@_) });
5271                 if ($err) {
5272                         print "Checked through r$max\r";
5273                 } else {
5274                         $find_trailing_edge = 1;
5275                 }
5276                 if ($err and $find_trailing_edge) {
5277                         print STDERR "Path '$longest_path' ",
5278                                      "was probably deleted:\n",
5279                                      $err->expanded_message,
5280                                      "\nWill attempt to follow ",
5281                                      "revisions r$min .. r$max ",
5282                                      "committed before the deletion\n";
5283                         my $hi = $max;
5284                         while (--$hi >= $min) {
5285                                 my $ok;
5286                                 $self->get_log([$longest_path], $min, $hi,
5287                                                0, 1, 1, sub {
5288                                                $ok = $_[1];
5289                                                $revs{$_[1]} = _cb(@_) });
5290                                 if ($ok) {
5291                                         print STDERR "r$min .. r$ok OK\n";
5292                                         last;
5293                                 }
5294                         }
5295                         $find_trailing_edge = 0;
5296                 }
5297                 $SVN::Error::handler = $err_handler;
5298
5299                 my %exists = map { $_->{path} => $_ } @$gsv;
5300                 foreach my $r (sort {$a <=> $b} keys %revs) {
5301                         my ($paths, $logged) = @{$revs{$r}};
5302
5303                         foreach my $gs ($self->match_globs(\%exists, $paths,
5304                                                            $globs, $r)) {
5305                                 if ($gs->rev_map_max >= $r) {
5306                                         next;
5307                                 }
5308                                 next unless $gs->match_paths($paths, $r);
5309                                 $gs->{logged_rev_props} = $logged;
5310                                 if (my $last_commit = $gs->last_commit) {
5311                                         $gs->assert_index_clean($last_commit);
5312                                 }
5313                                 my $log_entry = $gs->do_fetch($paths, $r);
5314                                 if ($log_entry) {
5315                                         $gs->do_git_commit($log_entry);
5316                                 }
5317                                 $INDEX_FILES{$gs->{index}} = 1;
5318                         }
5319                         foreach my $g (@$globs) {
5320                                 my $k = "svn-remote.$g->{remote}." .
5321                                         "$g->{t}-maxRev";
5322                                 Git::SVN::tmp_config($k, $r);
5323                         }
5324                         if ($ra_invalid) {
5325                                 $_[0] = undef;
5326                                 $self = undef;
5327                                 $RA = undef;
5328                                 $self = Git::SVN::Ra->new($ra_url);
5329                                 $ra_invalid = undef;
5330                         }
5331                 }
5332                 # pre-fill the .rev_db since it'll eventually get filled in
5333                 # with '0' x40 if something new gets committed
5334                 foreach my $gs (@$gsv) {
5335                         next if $gs->rev_map_max >= $max;
5336                         next if defined $gs->rev_map_get($max);
5337                         $gs->rev_map_set($max, 0 x40);
5338                 }
5339                 foreach my $g (@$globs) {
5340                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
5341                         Git::SVN::tmp_config($k, $max);
5342                 }
5343                 last if $max >= $head;
5344                 $min = $max + 1;
5345                 $max += $inc;
5346                 $max = $head if ($max > $head);
5347         }
5348         Git::SVN::gc();
5349 }
5350
5351 sub get_dir_globbed {
5352         my ($self, $left, $depth, $r) = @_;
5353
5354         my @x = eval { $self->get_dir($left, $r) };
5355         return unless scalar @x == 3;
5356         my $dirents = $x[0];
5357         my @finalents;
5358         foreach my $de (keys %$dirents) {
5359                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
5360                 if ($depth > 1) {
5361                         my @args = ("$left/$de", $depth - 1, $r);
5362                         foreach my $dir ($self->get_dir_globbed(@args)) {
5363                                 push @finalents, "$de/$dir";
5364                         }
5365                 } else {
5366                         push @finalents, $de;
5367                 }
5368         }
5369         @finalents;
5370 }
5371
5372 sub match_globs {
5373         my ($self, $exists, $paths, $globs, $r) = @_;
5374
5375         sub get_dir_check {
5376                 my ($self, $exists, $g, $r) = @_;
5377
5378                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
5379                                                   $g->{path}->{depth},
5380                                                   $r);
5381
5382                 foreach my $de (@dirs) {
5383                         my $p = $g->{path}->full_path($de);
5384                         next if $exists->{$p};
5385                         next if (length $g->{path}->{right} &&
5386                                  ($self->check_path($p, $r) !=
5387                                   $SVN::Node::dir));
5388                         next unless $p =~ /$g->{path}->{regex}/;
5389                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
5390                                          $g->{ref}->full_path($de), 1);
5391                 }
5392         }
5393         foreach my $g (@$globs) {
5394                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
5395                         if ($path->{action} =~ /^[AR]$/) {
5396                                 get_dir_check($self, $exists, $g, $r);
5397                         }
5398                 }
5399                 foreach (keys %$paths) {
5400                         if (/$g->{path}->{left_regex}/ &&
5401                             !/$g->{path}->{regex}/) {
5402                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
5403                                 get_dir_check($self, $exists, $g, $r);
5404                         }
5405                         next unless /$g->{path}->{regex}/;
5406                         my $p = $1;
5407                         my $pathname = $g->{path}->full_path($p);
5408                         next if $exists->{$pathname};
5409                         next if ($self->check_path($pathname, $r) !=
5410                                  $SVN::Node::dir);
5411                         $exists->{$pathname} = Git::SVN->init(
5412                                               $self->{url}, $pathname, undef,
5413                                               $g->{ref}->full_path($p), 1);
5414                 }
5415                 my $c = '';
5416                 foreach (split m#/#, $g->{path}->{left}) {
5417                         $c .= "/$_";
5418                         next unless ($paths->{$c} &&
5419                                      ($paths->{$c}->{action} =~ /^[AR]$/));
5420                         get_dir_check($self, $exists, $g, $r);
5421                 }
5422         }
5423         values %$exists;
5424 }
5425
5426 sub minimize_url {
5427         my ($self) = @_;
5428         return $self->{url} if ($self->{url} eq $self->{repos_root});
5429         my $url = $self->{repos_root};
5430         my @components = split(m!/!, $self->{svn_path});
5431         my $c = '';
5432         do {
5433                 $url .= "/$c" if length $c;
5434                 eval {
5435                         my $ra = (ref $self)->new($url);
5436                         my $latest = $ra->get_latest_revnum;
5437                         $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
5438                 };
5439         } while ($@ && ($c = shift @components));
5440         $url;
5441 }
5442
5443 sub can_do_switch {
5444         my $self = shift;
5445         unless (defined $can_do_switch) {
5446                 my $pool = SVN::Pool->new;
5447                 my $rep = eval {
5448                         $self->do_switch(1, '', 0, $self->{url},
5449                                          SVN::Delta::Editor->new, $pool);
5450                 };
5451                 if ($@) {
5452                         $can_do_switch = 0;
5453                 } else {
5454                         $rep->abort_report($pool);
5455                         $can_do_switch = 1;
5456                 }
5457                 $pool->clear;
5458         }
5459         $can_do_switch;
5460 }
5461
5462 sub skip_unknown_revs {
5463         my ($err) = @_;
5464         my $errno = $err->apr_err();
5465         # Maybe the branch we're tracking didn't
5466         # exist when the repo started, so it's
5467         # not an error if it doesn't, just continue
5468         #
5469         # Wonderfully consistent library, eh?
5470         # 160013 - svn:// and file://
5471         # 175002 - http(s)://
5472         # 175007 - http(s):// (this repo required authorization, too...)
5473         #   More codes may be discovered later...
5474         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
5475                 my $err_key = $err->expanded_message;
5476                 # revision numbers change every time, filter them out
5477                 $err_key =~ s/\d+/\0/g;
5478                 $err_key = "$errno\0$err_key";
5479                 unless ($ignored_err{$err_key}) {
5480                         warn "W: Ignoring error from SVN, path probably ",
5481                              "does not exist: ($errno): ",
5482                              $err->expanded_message,"\n";
5483                         warn "W: Do not be alarmed at the above message ",
5484                              "git-svn is just searching aggressively for ",
5485                              "old history.\n",
5486                              "This may take a while on large repositories\n";
5487                         $ignored_err{$err_key} = 1;
5488                 }
5489                 return;
5490         }
5491         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
5492 }
5493
5494 package Git::SVN::Log;
5495 use strict;
5496 use warnings;
5497 use POSIX qw/strftime/;
5498 use Time::Local;
5499 use constant commit_log_separator => ('-' x 72) . "\n";
5500 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
5501             %rusers $show_commit $incremental/;
5502 my $l_fmt;
5503
5504 sub cmt_showable {
5505         my ($c) = @_;
5506         return 1 if defined $c->{r};
5507
5508         # big commit message got truncated by the 16k pretty buffer in rev-list
5509         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
5510                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
5511                 @{$c->{l}} = ();
5512                 my @log = command(qw/cat-file commit/, $c->{c});
5513
5514                 # shift off the headers
5515                 shift @log while ($log[0] ne '');
5516                 shift @log;
5517
5518                 # TODO: make $c->{l} not have a trailing newline in the future
5519                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
5520
5521                 (undef, $c->{r}, undef) = ::extract_metadata(
5522                                 (grep(/^git-svn-id: /, @log))[-1]);
5523         }
5524         return defined $c->{r};
5525 }
5526
5527 sub log_use_color {
5528         return $color || Git->repository->get_colorbool('color.diff');
5529 }
5530
5531 sub git_svn_log_cmd {
5532         my ($r_min, $r_max, @args) = @_;
5533         my $head = 'HEAD';
5534         my (@files, @log_opts);
5535         foreach my $x (@args) {
5536                 if ($x eq '--' || @files) {
5537                         push @files, $x;
5538                 } else {
5539                         if (::verify_ref("$x^0")) {
5540                                 $head = $x;
5541                         } else {
5542                                 push @log_opts, $x;
5543                         }
5544                 }
5545         }
5546
5547         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
5548         $gs ||= Git::SVN->_new;
5549         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
5550                    $gs->refname);
5551         push @cmd, '-r' unless $non_recursive;
5552         push @cmd, qw/--raw --name-status/ if $verbose;
5553         push @cmd, '--color' if log_use_color();
5554         push @cmd, @log_opts;
5555         if (defined $r_max && $r_max == $r_min) {
5556                 push @cmd, '--max-count=1';
5557                 if (my $c = $gs->rev_map_get($r_max)) {
5558                         push @cmd, $c;
5559                 }
5560         } elsif (defined $r_max) {
5561                 if ($r_max < $r_min) {
5562                         ($r_min, $r_max) = ($r_max, $r_min);
5563                 }
5564                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
5565                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
5566                 # If there are no commits in the range, both $c_max and $c_min
5567                 # will be undefined.  If there is at least 1 commit in the
5568                 # range, both will be defined.
5569                 return () if !defined $c_min || !defined $c_max;
5570                 if ($c_min eq $c_max) {
5571                         push @cmd, '--max-count=1', $c_min;
5572                 } else {
5573                         push @cmd, '--boundary', "$c_min..$c_max";
5574                 }
5575         }
5576         return (@cmd, @files);
5577 }
5578
5579 # adapted from pager.c
5580 sub config_pager {
5581         if (! -t *STDOUT) {
5582                 $ENV{GIT_PAGER_IN_USE} = 'false';
5583                 $pager = undef;
5584                 return;
5585         }
5586         chomp($pager = command_oneline(qw(var GIT_PAGER)));
5587         if ($pager eq 'cat') {
5588                 $pager = undef;
5589         }
5590         $ENV{GIT_PAGER_IN_USE} = defined($pager);
5591 }
5592
5593 sub run_pager {
5594         return unless defined $pager;
5595         pipe my ($rfd, $wfd) or return;
5596         defined(my $pid = fork) or ::fatal "Can't fork: $!";
5597         if (!$pid) {
5598                 open STDOUT, '>&', $wfd or
5599                                      ::fatal "Can't redirect to stdout: $!";
5600                 return;
5601         }
5602         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5603         $ENV{LESS} ||= 'FRSX';
5604         exec $pager or ::fatal "Can't run pager: $! ($pager)";
5605 }
5606
5607 sub format_svn_date {
5608         # some systmes don't handle or mishandle %z, so be creative.
5609         my $t = shift || time;
5610         my $gm = timelocal(gmtime($t));
5611         my $sign = qw( + + - )[ $t <=> $gm ];
5612         my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5613         return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5614 }
5615
5616 sub parse_git_date {
5617         my ($t, $tz) = @_;
5618         # Date::Parse isn't in the standard Perl distro :(
5619         if ($tz =~ s/^\+//) {
5620                 $t += tz_to_s_offset($tz);
5621         } elsif ($tz =~ s/^\-//) {
5622                 $t -= tz_to_s_offset($tz);
5623         }
5624         return $t;
5625 }
5626
5627 sub set_local_timezone {
5628         if (defined $TZ) {
5629                 $ENV{TZ} = $TZ;
5630         } else {
5631                 delete $ENV{TZ};
5632         }
5633 }
5634
5635 sub tz_to_s_offset {
5636         my ($tz) = @_;
5637         $tz =~ s/(\d\d)$//;
5638         return ($1 * 60) + ($tz * 3600);
5639 }
5640
5641 sub get_author_info {
5642         my ($dest, $author, $t, $tz) = @_;
5643         $author =~ s/(?:^\s*|\s*$)//g;
5644         $dest->{a_raw} = $author;
5645         my $au;
5646         if ($::_authors) {
5647                 $au = $rusers{$author} || undef;
5648         }
5649         if (!$au) {
5650                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5651         }
5652         $dest->{t} = $t;
5653         $dest->{tz} = $tz;
5654         $dest->{a} = $au;
5655         $dest->{t_utc} = parse_git_date($t, $tz);
5656 }
5657
5658 sub process_commit {
5659         my ($c, $r_min, $r_max, $defer) = @_;
5660         if (defined $r_min && defined $r_max) {
5661                 if ($r_min == $c->{r} && $r_min == $r_max) {
5662                         show_commit($c);
5663                         return 0;
5664                 }
5665                 return 1 if $r_min == $r_max;
5666                 if ($r_min < $r_max) {
5667                         # we need to reverse the print order
5668                         return 0 if (defined $limit && --$limit < 0);
5669                         push @$defer, $c;
5670                         return 1;
5671                 }
5672                 if ($r_min != $r_max) {
5673                         return 1 if ($r_min < $c->{r});
5674                         return 1 if ($r_max > $c->{r});
5675                 }
5676         }
5677         return 0 if (defined $limit && --$limit < 0);
5678         show_commit($c);
5679         return 1;
5680 }
5681
5682 sub show_commit {
5683         my $c = shift;
5684         if ($oneline) {
5685                 my $x = "\n";
5686                 if (my $l = $c->{l}) {
5687                         while ($l->[0] =~ /^\s*$/) { shift @$l }
5688                         $x = $l->[0];
5689                 }
5690                 $l_fmt ||= 'A' . length($c->{r});
5691                 print 'r',pack($l_fmt, $c->{r}),' | ';
5692                 print "$c->{c} | " if $show_commit;
5693                 print $x;
5694         } else {
5695                 show_commit_normal($c);
5696         }
5697 }
5698
5699 sub show_commit_changed_paths {
5700         my ($c) = @_;
5701         return unless $c->{changed};
5702         print "Changed paths:\n", @{$c->{changed}};
5703 }
5704
5705 sub show_commit_normal {
5706         my ($c) = @_;
5707         print commit_log_separator, "r$c->{r} | ";
5708         print "$c->{c} | " if $show_commit;
5709         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5710         my $nr_line = 0;
5711
5712         if (my $l = $c->{l}) {
5713                 while ($l->[$#$l] eq "\n" && $#$l > 0
5714                                           && $l->[($#$l - 1)] eq "\n") {
5715                         pop @$l;
5716                 }
5717                 $nr_line = scalar @$l;
5718                 if (!$nr_line) {
5719                         print "1 line\n\n\n";
5720                 } else {
5721                         if ($nr_line == 1) {
5722                                 $nr_line = '1 line';
5723                         } else {
5724                                 $nr_line .= ' lines';
5725                         }
5726                         print $nr_line, "\n";
5727                         show_commit_changed_paths($c);
5728                         print "\n";
5729                         print $_ foreach @$l;
5730                 }
5731         } else {
5732                 print "1 line\n";
5733                 show_commit_changed_paths($c);
5734                 print "\n";
5735
5736         }
5737         foreach my $x (qw/raw stat diff/) {
5738                 if ($c->{$x}) {
5739                         print "\n";
5740                         print $_ foreach @{$c->{$x}}
5741                 }
5742         }
5743 }
5744
5745 sub cmd_show_log {
5746         my (@args) = @_;
5747         my ($r_min, $r_max);
5748         my $r_last = -1; # prevent dupes
5749         set_local_timezone();
5750         if (defined $::_revision) {
5751                 if ($::_revision =~ /^(\d+):(\d+)$/) {
5752                         ($r_min, $r_max) = ($1, $2);
5753                 } elsif ($::_revision =~ /^\d+$/) {
5754                         $r_min = $r_max = $::_revision;
5755                 } else {
5756                         ::fatal "-r$::_revision is not supported, use ",
5757                                 "standard 'git log' arguments instead";
5758                 }
5759         }
5760
5761         config_pager();
5762         @args = git_svn_log_cmd($r_min, $r_max, @args);
5763         if (!@args) {
5764                 print commit_log_separator unless $incremental || $oneline;
5765                 return;
5766         }
5767         my $log = command_output_pipe(@args);
5768         run_pager();
5769         my (@k, $c, $d, $stat);
5770         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5771         while (<$log>) {
5772                 if (/^${esc_color}commit (?:- )?($::sha1_short)/o) {
5773                         my $cmt = $1;
5774                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5775                                 $r_last = $c->{r};
5776                                 process_commit($c, $r_min, $r_max, \@k) or
5777                                                                 goto out;
5778                         }
5779                         $d = undef;
5780                         $c = { c => $cmt };
5781                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5782                         get_author_info($c, $1, $2, $3);
5783                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5784                         # ignore
5785                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5786                         push @{$c->{raw}}, $_;
5787                 } elsif (/^${esc_color}[ACRMDT]\t/) {
5788                         # we could add $SVN->{svn_path} here, but that requires
5789                         # remote access at the moment (repo_path_split)...
5790                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
5791                         push @{$c->{changed}}, $_;
5792                 } elsif (/^${esc_color}diff /o) {
5793                         $d = 1;
5794                         push @{$c->{diff}}, $_;
5795                 } elsif ($d) {
5796                         push @{$c->{diff}}, $_;
5797                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5798                           $esc_color*[\+\-]*$esc_color$/x) {
5799                         $stat = 1;
5800                         push @{$c->{stat}}, $_;
5801                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5802                         push @{$c->{stat}}, $_;
5803                         $stat = undef;
5804                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
5805                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5806                 } elsif (s/^${esc_color}    //o) {
5807                         push @{$c->{l}}, $_;
5808                 }
5809         }
5810         if ($c && defined $c->{r} && $c->{r} != $r_last) {
5811                 $r_last = $c->{r};
5812                 process_commit($c, $r_min, $r_max, \@k);
5813         }
5814         if (@k) {
5815                 ($r_min, $r_max) = ($r_max, $r_min);
5816                 process_commit($_, $r_min, $r_max) foreach reverse @k;
5817         }
5818 out:
5819         close $log;
5820         print commit_log_separator unless $incremental || $oneline;
5821 }
5822
5823 sub cmd_blame {
5824         my $path = pop;
5825
5826         config_pager();
5827         run_pager();
5828
5829         my ($fh, $ctx, $rev);
5830
5831         if ($_git_format) {
5832                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5833                 while (my $line = <$fh>) {
5834                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5835                                 # Uncommitted edits show up as a rev ID of
5836                                 # all zeros, which we can't look up with
5837                                 # cmt_metadata
5838                                 if ($1 !~ /^0+$/) {
5839                                         (undef, $rev, undef) =
5840                                                 ::cmt_metadata($1);
5841                                         $rev = '0' if (!$rev);
5842                                 } else {
5843                                         $rev = '0';
5844                                 }
5845                                 $rev = sprintf('%-10s', $rev);
5846                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5847                         }
5848                         print $line;
5849                 }
5850         } else {
5851                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5852                                                   '--', $path);
5853                 my ($sha1);
5854                 my %authors;
5855                 my @buffer;
5856                 my %dsha; #distinct sha keys
5857
5858                 while (my $line = <$fh>) {
5859                         push @buffer, $line;
5860                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5861                                 $dsha{$1} = 1;
5862                         }
5863                 }
5864
5865                 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5866
5867                 foreach my $line (@buffer) {
5868                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5869                                 $rev = $s2r->{$1};
5870                                 $rev = '0' if (!$rev)
5871                         }
5872                         elsif ($line =~ /^author (.*)/) {
5873                                 $authors{$rev} = $1;
5874                                 $authors{$rev} =~ s/\s/_/g;
5875                         }
5876                         elsif ($line =~ /^\t(.*)$/) {
5877                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5878                         }
5879                 }
5880         }
5881         command_close_pipe($fh, $ctx);
5882 }
5883
5884 package Git::SVN::Migration;
5885 # these version numbers do NOT correspond to actual version numbers
5886 # of git nor git-svn.  They are just relative.
5887 #
5888 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5889 #
5890 # v1 layout: .git/$id/info/url, refs/remotes/$id
5891 #
5892 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5893 #
5894 # v3 layout: .git/svn/$id, refs/remotes/$id
5895 #            - info/url may remain for backwards compatibility
5896 #            - this is what we migrate up to this layout automatically,
5897 #            - this will be used by git svn init on single branches
5898 # v3.1 layout (auto migrated):
5899 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5900 #              for backwards compatibility
5901 #
5902 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5903 #            - this is only created for newly multi-init-ed
5904 #              repositories.  Similar in spirit to the
5905 #              --use-separate-remotes option in git-clone (now default)
5906 #            - we do not automatically migrate to this (following
5907 #              the example set by core git)
5908 #
5909 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5910 #            - newer, more-efficient format that uses 24-bytes per record
5911 #              with no filler space.
5912 #            - use xxd -c24 < .rev_map.$UUID to view and debug
5913 #            - This is a one-way migration, repositories updated to the
5914 #              new format will not be able to use old git-svn without
5915 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
5916 #              possible if noMetadata or useSvmProps are set; but should
5917 #              be no problem for users that use the (sensible) defaults.
5918 use strict;
5919 use warnings;
5920 use Carp qw/croak/;
5921 use File::Path qw/mkpath/;
5922 use File::Basename qw/dirname basename/;
5923 use vars qw/$_minimize/;
5924
5925 sub migrate_from_v0 {
5926         my $git_dir = $ENV{GIT_DIR};
5927         return undef unless -d $git_dir;
5928         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5929         my $migrated = 0;
5930         while (<$fh>) {
5931                 chomp;
5932                 my ($id, $orig_ref) = ($_, $_);
5933                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5934                 next unless -f "$git_dir/$id/info/url";
5935                 my $new_ref = "refs/remotes/$id";
5936                 if (::verify_ref("$new_ref^0")) {
5937                         print STDERR "W: $orig_ref is probably an old ",
5938                                      "branch used by an ancient version of ",
5939                                      "git-svn.\n",
5940                                      "However, $new_ref also exists.\n",
5941                                      "We will not be able ",
5942                                      "to use this branch until this ",
5943                                      "ambiguity is resolved.\n";
5944                         next;
5945                 }
5946                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5947                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5948                 command_noisy('update-ref', $new_ref, $orig_ref);
5949                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5950                 $migrated++;
5951         }
5952         command_close_pipe($fh, $ctx);
5953         print STDERR "Done migrating from v0 layout...\n" if $migrated;
5954         $migrated;
5955 }
5956
5957 sub migrate_from_v1 {
5958         my $git_dir = $ENV{GIT_DIR};
5959         my $migrated = 0;
5960         return $migrated unless -d $git_dir;
5961         my $svn_dir = "$git_dir/svn";
5962
5963         # just in case somebody used 'svn' as their $id at some point...
5964         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5965
5966         print STDERR "Migrating from a git-svn v1 layout...\n";
5967         mkpath([$svn_dir]);
5968         print STDERR "Data from a previous version of git-svn exists, but\n\t",
5969                      "$svn_dir\n\t(required for this version ",
5970                      "($::VERSION) of git-svn) does not exist.\n";
5971         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5972         while (<$fh>) {
5973                 my $x = $_;
5974                 next unless $x =~ s#^refs/remotes/##;
5975                 chomp $x;
5976                 next unless -f "$git_dir/$x/info/url";
5977                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5978                 next unless $u;
5979                 my $dn = dirname("$git_dir/svn/$x");
5980                 mkpath([$dn]) unless -d $dn;
5981                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5982                         mkpath(["$git_dir/svn/svn"]);
5983                         print STDERR " - $git_dir/$x/info => ",
5984                                         "$git_dir/svn/$x/info\n";
5985                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5986                                croak "$!: $x";
5987                         # don't worry too much about these, they probably
5988                         # don't exist with repos this old (save for index,
5989                         # and we can easily regenerate that)
5990                         foreach my $f (qw/unhandled.log index .rev_db/) {
5991                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5992                         }
5993                 } else {
5994                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5995                         rename "$git_dir/$x", "$git_dir/svn/$x" or
5996                                croak "$!: $x";
5997                 }
5998                 $migrated++;
5999         }
6000         command_close_pipe($fh, $ctx);
6001         print STDERR "Done migrating from a git-svn v1 layout\n";
6002         $migrated;
6003 }
6004
6005 sub read_old_urls {
6006         my ($l_map, $pfx, $path) = @_;
6007         my @dir;
6008         foreach (<$path/*>) {
6009                 if (-r "$_/info/url") {
6010                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
6011                         my $ref_id = $pfx . basename $_;
6012                         my $url = ::file_to_s("$_/info/url");
6013                         $l_map->{$ref_id} = $url;
6014                 } elsif (-d $_) {
6015                         push @dir, $_;
6016                 }
6017         }
6018         foreach (@dir) {
6019                 my $x = $_;
6020                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
6021                 read_old_urls($l_map, $x, $_);
6022         }
6023 }
6024
6025 sub migrate_from_v2 {
6026         my @cfg = command(qw/config -l/);
6027         return if grep /^svn-remote\..+\.url=/, @cfg;
6028         my %l_map;
6029         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
6030         my $migrated = 0;
6031
6032         foreach my $ref_id (sort keys %l_map) {
6033                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
6034                 if ($@) {
6035                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
6036                 }
6037                 $migrated++;
6038         }
6039         $migrated;
6040 }
6041
6042 sub minimize_connections {
6043         my $r = Git::SVN::read_all_remotes();
6044         my $new_urls = {};
6045         my $root_repos = {};
6046         foreach my $repo_id (keys %$r) {
6047                 my $url = $r->{$repo_id}->{url} or next;
6048                 my $fetch = $r->{$repo_id}->{fetch} or next;
6049                 my $ra = Git::SVN::Ra->new($url);
6050
6051                 # skip existing cases where we already connect to the root
6052                 if (($ra->{url} eq $ra->{repos_root}) ||
6053                     ($ra->{repos_root} eq $repo_id)) {
6054                         $root_repos->{$ra->{url}} = $repo_id;
6055                         next;
6056                 }
6057
6058                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
6059                 my $root_path = $ra->{url};
6060                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
6061                 foreach my $path (keys %$fetch) {
6062                         my $ref_id = $fetch->{$path};
6063                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
6064
6065                         # make sure we can read when connecting to
6066                         # a higher level of a repository
6067                         my ($last_rev, undef) = $gs->last_rev_commit;
6068                         if (!defined $last_rev) {
6069                                 $last_rev = eval {
6070                                         $root_ra->get_latest_revnum;
6071                                 };
6072                                 next if $@;
6073                         }
6074                         my $new = $root_path;
6075                         $new .= length $path ? "/$path" : '';
6076                         eval {
6077                                 $root_ra->get_log([$new], $last_rev, $last_rev,
6078                                                   0, 0, 1, sub { });
6079                         };
6080                         next if $@;
6081                         $new_urls->{$ra->{repos_root}}->{$new} =
6082                                 { ref_id => $ref_id,
6083                                   old_repo_id => $repo_id,
6084                                   old_path => $path };
6085                 }
6086         }
6087
6088         my @emptied;
6089         foreach my $url (keys %$new_urls) {
6090                 # see if we can re-use an existing [svn-remote "repo_id"]
6091                 # instead of creating a(n ugly) new section:
6092                 my $repo_id = $root_repos->{$url} || $url;
6093
6094                 my $fetch = $new_urls->{$url};
6095                 foreach my $path (keys %$fetch) {
6096                         my $x = $fetch->{$path};
6097                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
6098                         my $pfx = "svn-remote.$x->{old_repo_id}";
6099
6100                         my $old_fetch = quotemeta("$x->{old_path}:".
6101                                                   "$x->{ref_id}");
6102                         command_noisy(qw/config --unset/,
6103                                       "$pfx.fetch", '^'. $old_fetch . '$');
6104                         delete $r->{$x->{old_repo_id}}->
6105                                {fetch}->{$x->{old_path}};
6106                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
6107                                 command_noisy(qw/config --unset/,
6108                                               "$pfx.url");
6109                                 push @emptied, $x->{old_repo_id}
6110                         }
6111                 }
6112         }
6113         if (@emptied) {
6114                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
6115                 print STDERR <<EOF;
6116 The following [svn-remote] sections in your config file ($file) are empty
6117 and can be safely removed:
6118 EOF
6119                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
6120         }
6121 }
6122
6123 sub migration_check {
6124         migrate_from_v0();
6125         migrate_from_v1();
6126         migrate_from_v2();
6127         minimize_connections() if $_minimize;
6128 }
6129
6130 package Git::IndexInfo;
6131 use strict;
6132 use warnings;
6133 use Git qw/command_input_pipe command_close_pipe/;
6134
6135 sub new {
6136         my ($class) = @_;
6137         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
6138         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
6139 }
6140
6141 sub remove {
6142         my ($self, $path) = @_;
6143         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
6144                 return ++$self->{nr};
6145         }
6146         undef;
6147 }
6148
6149 sub update {
6150         my ($self, $mode, $hash, $path) = @_;
6151         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
6152                 return ++$self->{nr};
6153         }
6154         undef;
6155 }
6156
6157 sub DESTROY {
6158         my ($self) = @_;
6159         command_close_pipe($self->{gui}, $self->{ctx});
6160 }
6161
6162 package Git::SVN::GlobSpec;
6163 use strict;
6164 use warnings;
6165
6166 sub new {
6167         my ($class, $glob, $pattern_ok) = @_;
6168         my $re = $glob;
6169         $re =~ s!/+$!!g; # no need for trailing slashes
6170         my (@left, @right, @patterns);
6171         my $state = "left";
6172         my $die_msg = "Only one set of wildcard directories " .
6173                                 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
6174         for my $part (split(m|/|, $glob)) {
6175                 if ($part =~ /\*/ && $part ne "*") {
6176                         die "Invalid pattern in '$glob': $part\n";
6177                 } elsif ($pattern_ok && $part =~ /[{}]/ &&
6178                          $part !~ /^\{[^{}]+\}/) {
6179                         die "Invalid pattern in '$glob': $part\n";
6180                 }
6181                 if ($part eq "*") {
6182                         die $die_msg if $state eq "right";
6183                         $state = "pattern";
6184                         push(@patterns, "[^/]*");
6185                 } elsif ($pattern_ok && $part =~ /^\{(.*)\}$/) {
6186                         die $die_msg if $state eq "right";
6187                         $state = "pattern";
6188                         my $p = quotemeta($1);
6189                         $p =~ s/\\,/|/g;
6190                         push(@patterns, "(?:$p)");
6191                 } else {
6192                         if ($state eq "left") {
6193                                 push(@left, $part);
6194                         } else {
6195                                 push(@right, $part);
6196                                 $state = "right";
6197                         }
6198                 }
6199         }
6200         my $depth = @patterns;
6201         if ($depth == 0) {
6202                 die "One '*' is needed in glob: '$glob'\n";
6203         }
6204         my $left = join('/', @left);
6205         my $right = join('/', @right);
6206         $re = join('/', @patterns);
6207         $re = join('\/',
6208                    grep(length, quotemeta($left), "($re)", quotemeta($right)));
6209         my $left_re = qr/^\/\Q$left\E(\/|$)/;
6210         bless { left => $left, right => $right, left_regex => $left_re,
6211                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
6212 }
6213
6214 sub full_path {
6215         my ($self, $path) = @_;
6216         return (length $self->{left} ? "$self->{left}/" : '') .
6217                $path . (length $self->{right} ? "/$self->{right}" : '');
6218 }
6219
6220 __END__
6221
6222 Data structures:
6223
6224
6225 $remotes = { # returned by read_all_remotes()
6226         'svn' => {
6227                 # svn-remote.svn.url=https://svn.musicpd.org
6228                 url => 'https://svn.musicpd.org',
6229                 # svn-remote.svn.fetch=mpd/trunk:trunk
6230                 fetch => {
6231                         'mpd/trunk' => 'trunk',
6232                 },
6233                 # svn-remote.svn.tags=mpd/tags/*:tags/*
6234                 tags => {
6235                         path => {
6236                                 left => 'mpd/tags',
6237                                 right => '',
6238                                 regex => qr!mpd/tags/([^/]+)$!,
6239                                 glob => 'tags/*',
6240                         },
6241                         ref => {
6242                                 left => 'tags',
6243                                 right => '',
6244                                 regex => qr!tags/([^/]+)$!,
6245                                 glob => 'tags/*',
6246                         },
6247                 }
6248         }
6249 };
6250
6251 $log_entry hashref as returned by libsvn_log_entry()
6252 {
6253         log => 'whitespace-formatted log entry
6254 ',                                              # trailing newline is preserved
6255         revision => '8',                        # integer
6256         date => '2004-02-24T17:01:44.108345Z',  # commit date
6257         author => 'committer name'
6258 };
6259
6260
6261 # this is generated by generate_diff();
6262 @mods = array of diff-index line hashes, each element represents one line
6263         of diff-index output
6264
6265 diff-index line ($m hash)
6266 {
6267         mode_a => first column of diff-index output, no leading ':',
6268         mode_b => second column of diff-index output,
6269         sha1_b => sha1sum of the final blob,
6270         chg => change type [MCRADT],
6271         file_a => original file name of a file (iff chg is 'C' or 'R')
6272         file_b => new/current file name of a file (any chg)
6273 }
6274 ;
6275
6276 # retval of read_url_paths{,_all}();
6277 $l_map = {
6278         # repository root url
6279         'https://svn.musicpd.org' => {
6280                 # repository path               # GIT_SVN_ID
6281                 'mpd/trunk'             =>      'trunk',
6282                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
6283         },
6284 }
6285
6286 Notes:
6287         I don't trust the each() function on unless I created %hash myself
6288         because the internal iterator may not have started at base.