git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 $SIG{INT} = sub { print color("reset"), "\n"; exit };
  28
  29 package FakeTerm;
  30 sub new {
  31         my ($class, $reason) = @_;
  32         return bless \$reason, shift;
  33 }
  34 sub readline {
  35         my $self = shift;
  36         die "Cannot use readline on FakeTerm: $$self";
  37 }
  38 package main;
  39
  40
  41 sub usage {
  42         print <<EOT;
  43 git-send-email [options] <file | directory>...
  44 Options:
  45    --from         Specify the "From:" line of the email to be sent.
  46
  47    --to           Specify the primary "To:" line of the email.
  48
  49    --cc           Specify an initial "Cc:" list for the entire series
  50                   of emails.
  51
  52    --cc-cmd       Specify a command to execute per file which adds
  53                   per file specific cc address entries
  54
  55    --bcc          Specify a list of email addresses that should be Bcc:
  56                   on all the emails.
  57
  58    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  59                   an introductory message for the patch series.
  60
  61    --subject      Specify the initial "Subject:" line.
  62                   Only necessary if --compose is also set.  If --compose
  63                   is not set, this will be prompted for.
  64
  65    --in-reply-to  Specify the first "In-Reply-To:" header line.
  66                   Only used if --compose is also set.  If --compose is not
  67                   set, this will be prompted for.
  68
  69    --chain-reply-to If set, the replies will all be to the previous
  70                   email sent, rather than to the first email sent.
  71                   Defaults to on.
  72
  73    --signed-off-cc Automatically add email addresses that appear in
  74                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  75
  76    --identity     The configuration identity, a subsection to prioritise over
  77                   the default section.
  78
  79    --smtp-server  If set, specifies the outgoing SMTP server to use.
  80                   Defaults to localhost.  Port number can be specified here with
  81                   hostname:port format or by using --smtp-server-port option.
  82
  83    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  84
  85    --smtp-user    The username for SMTP-AUTH.
  86
  87    --smtp-pass    The password for SMTP-AUTH.
  88
  89    --smtp-ssl     If set, connects to the SMTP server using SSL.
  90
  91    --suppress-from Suppress sending emails to yourself. Defaults to off.
  92
  93    --thread       Specify that the "In-Reply-To:" header should be set on all
  94                   emails. Defaults to on.
  95
  96    --quiet        Make git-send-email less verbose.  One line per email
  97                   should be all that is output.
  98
  99    --dry-run      Do everything except actually send the emails.
 100
 101    --envelope-sender    Specify the envelope sender used to send the emails.
 102
 103 EOT
 104         exit(1);
 105 }
 106
 107 # most mail servers generate the Date: header, but not all...
 108 sub format_2822_time {
 109         my ($time) = @_;
 110         my @localtm = localtime($time);
 111         my @gmttm = gmtime($time);
 112         my $localmin = $localtm[1] + $localtm[2] * 60;
 113         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 114         if ($localtm[0] != $gmttm[0]) {
 115                 die "local zone differs from GMT by a non-minute interval\n";
 116         }
 117         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 118                 $localmin += 1440;
 119         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 120                 $localmin -= 1440;
 121         } elsif ($gmttm[6] != $localtm[6]) {
 122                 die "local time offset greater than or equal to 24 hours\n";
 123         }
 124         my $offset = $localmin - $gmtmin;
 125         my $offhour = $offset / 60;
 126         my $offmin = abs($offset % 60);
 127         if (abs($offhour) >= 24) {
 128                 die ("local time offset greater than or equal to 24 hours\n");
 129         }
 130
 131         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 132                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 133                        $localtm[3],
 134                        qw(Jan Feb Mar Apr May Jun
 135                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 136                        $localtm[5]+1900,
 137                        $localtm[2],
 138                        $localtm[1],
 139                        $localtm[0],
 140                        ($offset >= 0) ? '+' : '-',
 141                        abs($offhour),
 142                        $offmin,
 143                        );
 144 }
 145
 146 my $have_email_valid = eval { require Email::Valid; 1 };
 147 my $smtp;
 148
 149 sub unique_email_list(@);
 150 sub cleanup_compose_files();
 151
 152 # Constants (essentially)
 153 my $compose_filename = ".msg.$$";
 154
 155 # Variables we fill in automatically, or via prompting:
 156 my (@to,@cc,@initial_cc,@bcclist,@xh,
 157         $initial_reply_to,$initial_subject,@files,$author,$sender,$compose,$time);
 158
 159 my $envelope_sender;
 160
 161 # Example reply to:
 162 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 163
 164 my $repo = Git->repository();
 165 my $term = eval {
 166         new Term::ReadLine 'git-send-email';
 167 };
 168 if ($@) {
 169         $term = new FakeTerm "$@: going non-interactive";
 170 }
 171
 172 # Behavior modification variables
 173 my ($quiet, $dry_run) = (0, 0);
 174
 175 # Variables with corresponding config settings
 176 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 177 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_authpass, $smtp_ssl);
 178 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 179
 180 my %config_bool_settings = (
 181     "thread" => [\$thread, 1],
 182     "chainreplyto" => [\$chain_reply_to, 1],
 183     "suppressfrom" => [\$suppress_from, 0],
 184     "signedoffcc" => [\$signed_off_cc, 1],
 185     "smtpssl" => [\$smtp_ssl, 0],
 186 );
 187
 188 my %config_settings = (
 189     "smtpserver" => \$smtp_server,
 190     "smtpserverport" => \$smtp_server_port,
 191     "smtpuser" => \$smtp_authuser,
 192     "smtppass" => \$smtp_authpass,
 193     "to" => \@to,
 194     "cccmd" => \$cc_cmd,
 195     "aliasfiletype" => \$aliasfiletype,
 196     "bcc" => \@bcclist,
 197     "aliasesfile" => \@alias_files,
 198 );
 199
 200 # Begin by accumulating all the variables (defined above), that we will end up
 201 # needing, first, from the command line:
 202
 203 my $rc = GetOptions("sender|from=s" => \$sender,
 204                     "in-reply-to=s" => \$initial_reply_to,
 205                     "subject=s" => \$initial_subject,
 206                     "to=s" => \@to,
 207                     "cc=s" => \@initial_cc,
 208                     "bcc=s" => \@bcclist,
 209                     "chain-reply-to!" => \$chain_reply_to,
 210                     "smtp-server=s" => \$smtp_server,
 211                     "smtp-server-port=s" => \$smtp_server_port,
 212                     "smtp-user=s" => \$smtp_authuser,
 213                     "smtp-pass=s" => \$smtp_authpass,
 214                     "smtp-ssl!" => \$smtp_ssl,
 215                     "identity=s" => \$identity,
 216                     "compose" => \$compose,
 217                     "quiet" => \$quiet,
 218                     "cc-cmd=s" => \$cc_cmd,
 219                     "suppress-from!" => \$suppress_from,
 220                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 221                     "dry-run" => \$dry_run,
 222                     "envelope-sender=s" => \$envelope_sender,
 223                     "thread!" => \$thread,
 224          );
 225
 226 unless ($rc) {
 227     usage();
 228 }
 229
 230 # Now, let's fill any that aren't set in with defaults:
 231
 232 sub read_config {
 233         my ($prefix) = @_;
 234
 235         foreach my $setting (keys %config_bool_settings) {
 236                 my $target = $config_bool_settings{$setting}->[0];
 237                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 238         }
 239
 240         foreach my $setting (keys %config_settings) {
 241                 my $target = $config_settings{$setting};
 242                 if (ref($target) eq "ARRAY") {
 243                         unless (@$target) {
 244                                 my @values = $repo->config("$prefix.$setting");
 245                                 @$target = @values if (@values && defined $values[0]);
 246                         }
 247                 }
 248                 else {
 249                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 250                 }
 251         }
 252 }
 253
 254 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 255 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 256 read_config("sendemail.$identity") if (defined $identity);
 257 read_config("sendemail");
 258
 259 # fall back on builtin bool defaults
 260 foreach my $setting (values %config_bool_settings) {
 261         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 262 }
 263
 264 my ($repoauthor) = $repo->ident_person('author');
 265 my ($repocommitter) = $repo->ident_person('committer');
 266
 267 # Verify the user input
 268
 269 foreach my $entry (@to) {
 270         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 271 }
 272
 273 foreach my $entry (@initial_cc) {
 274         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 275 }
 276
 277 foreach my $entry (@bcclist) {
 278         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 279 }
 280
 281 my %aliases;
 282 my %parse_alias = (
 283         # multiline formats can be supported in the future
 284         mutt => sub { my $fh = shift; while (<$fh>) {
 285                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 286                         my ($alias, $addr) = ($1, $2);
 287                         $addr =~ s/#.*$//; # mutt allows # comments
 288                          # commas delimit multiple addresses
 289                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 290                 }}},
 291         mailrc => sub { my $fh = shift; while (<$fh>) {
 292                 if (/^alias\s+(\S+)\s+(.*)$/) {
 293                         # spaces delimit multiple addresses
 294                         $aliases{$1} = [ split(/\s+/, $2) ];
 295                 }}},
 296         pine => sub { my $fh = shift; while (<$fh>) {
 297                 if (/^(\S+)\t.*\t(.*)$/) {
 298                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 299                 }}},
 300         gnus => sub { my $fh = shift; while (<$fh>) {
 301                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 302                         $aliases{$1} = [ $2 ];
 303                 }}}
 304 );
 305
 306 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 307         foreach my $file (@alias_files) {
 308                 open my $fh, '<', $file or die "opening $file: $!\n";
 309                 $parse_alias{$aliasfiletype}->($fh);
 310                 close $fh;
 311         }
 312 }
 313
 314 ($sender) = expand_aliases($sender) if defined $sender;
 315
 316 my $prompting = 0;
 317 if (!defined $sender) {
 318         $sender = $repoauthor || $repocommitter;
 319         do {
 320                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 321         } while (!defined $_);
 322
 323         $sender = $_ if ($_);
 324         print "Emails will be sent from: ", $sender, "\n";
 325         $prompting++;
 326 }
 327
 328 if (!@to) {
 329         do {
 330                 $_ = $term->readline("Who should the emails be sent to? ",
 331                                 "");
 332         } while (!defined $_);
 333         my $to = $_;
 334         push @to, split /,/, $to;
 335         $prompting++;
 336 }
 337
 338 sub expand_aliases {
 339         my @cur = @_;
 340         my @last;
 341         do {
 342                 @last = @cur;
 343                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 344         } while (join(',',@cur) ne join(',',@last));
 345         return @cur;
 346 }
 347
 348 @to = expand_aliases(@to);
 349 @to = (map { sanitize_address($_) } @to);
 350 @initial_cc = expand_aliases(@initial_cc);
 351 @bcclist = expand_aliases(@bcclist);
 352
 353 if (!defined $initial_subject && $compose) {
 354         do {
 355                 $_ = $term->readline("What subject should the initial email start with? ",
 356                         $initial_subject);
 357         } while (!defined $_);
 358         $initial_subject = $_;
 359         $prompting++;
 360 }
 361
 362 if ($thread && !defined $initial_reply_to && $prompting) {
 363         do {
 364                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 365                         $initial_reply_to);
 366         } while (!defined $_);
 367
 368         $initial_reply_to = $_;
 369         $initial_reply_to =~ s/^\s+<?/</;
 370         $initial_reply_to =~ s/>?\s+$/>/;
 371 }
 372
 373 if (!defined $smtp_server) {
 374         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 375                 if (-x $_) {
 376                         $smtp_server = $_;
 377                         last;
 378                 }
 379         }
 380         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 381 }
 382
 383 if ($compose) {
 384         # Note that this does not need to be secure, but we will make a small
 385         # effort to have it be unique
 386         open(C,">",$compose_filename)
 387                 or die "Failed to open for writing $compose_filename: $!";
 388         print C "From $sender # This line is ignored.\n";
 389         printf C "Subject: %s\n\n", $initial_subject;
 390         printf C <<EOT;
 391 GIT: Please enter your email below.
 392 GIT: Lines beginning in "GIT: " will be removed.
 393 GIT: Consider including an overall diffstat or table of contents
 394 GIT: for the patch you are writing.
 395
 396 EOT
 397         close(C);
 398
 399         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 400         system($editor, $compose_filename);
 401
 402         open(C2,">",$compose_filename . ".final")
 403                 or die "Failed to open $compose_filename.final : " . $!;
 404
 405         open(C,"<",$compose_filename)
 406                 or die "Failed to open $compose_filename : " . $!;
 407
 408         while(<C>) {
 409                 next if m/^GIT: /;
 410                 print C2 $_;
 411         }
 412         close(C);
 413         close(C2);
 414
 415         do {
 416                 $_ = $term->readline("Send this email? (y|n) ");
 417         } while (!defined $_);
 418
 419         if (uc substr($_,0,1) ne 'Y') {
 420                 cleanup_compose_files();
 421                 exit(0);
 422         }
 423
 424         @files = ($compose_filename . ".final");
 425 }
 426
 427
 428 # Now that all the defaults are set, process the rest of the command line
 429 # arguments and collect up the files that need to be processed.
 430 for my $f (@ARGV) {
 431         if (-d $f) {
 432                 opendir(DH,$f)
 433                         or die "Failed to opendir $f: $!";
 434
 435                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 436                                 sort readdir(DH);
 437
 438         } elsif (-f $f) {
 439                 push @files, $f;
 440
 441         } else {
 442                 print STDERR "Skipping $f - not found.\n";
 443         }
 444 }
 445
 446 if (@files) {
 447         unless ($quiet) {
 448                 print $_,"\n" for (@files);
 449         }
 450 } else {
 451         print STDERR "\nNo patch files specified!\n\n";
 452         usage();
 453 }
 454
 455 # Variables we set as part of the loop over files
 456 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 457
 458 sub extract_valid_address {
 459         my $address = shift;
 460         my $local_part_regexp = '[^<>"\s@]+';
 461         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 462
 463         # check for a local address:
 464         return $address if ($address =~ /^($local_part_regexp)$/);
 465
 466         $address =~ s/^\s*<(.*)>\s*$/$1/;
 467         if ($have_email_valid) {
 468                 return scalar Email::Valid->address($address);
 469         } else {
 470                 # less robust/correct than the monster regexp in Email::Valid,
 471                 # but still does a 99% job, and one less dependency
 472                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 473                 return $1;
 474         }
 475 }
 476
 477 # Usually don't need to change anything below here.
 478
 479 # we make a "fake" message id by taking the current number
 480 # of seconds since the beginning of Unix time and tacking on
 481 # a random number to the end, in case we are called quicker than
 482 # 1 second since the last time we were called.
 483
 484 # We'll setup a template for the message id, using the "from" address:
 485
 486 my ($message_id_stamp, $message_id_serial);
 487 sub make_message_id
 488 {
 489         my $uniq;
 490         if (!defined $message_id_stamp) {
 491                 $message_id_stamp = sprintf("%s-%s", time, $$);
 492                 $message_id_serial = 0;
 493         }
 494         $message_id_serial++;
 495         $uniq = "$message_id_stamp-$message_id_serial";
 496
 497         my $du_part;
 498         for ($sender, $repocommitter, $repoauthor) {
 499                 $du_part = extract_valid_address(sanitize_address($_));
 500                 last if (defined $du_part and $du_part ne '');
 501         }
 502         if (not defined $du_part or $du_part eq '') {
 503                 use Sys::Hostname qw();
 504                 $du_part = 'user@' . Sys::Hostname::hostname();
 505         }
 506         my $message_id_template = "<%s-git-send-email-%s>";
 507         $message_id = sprintf($message_id_template, $uniq, $du_part);
 508         #print "new message id = $message_id\n"; # Was useful for debugging
 509 }
 510
 511
 512
 513 $time = time - scalar $#files;
 514
 515 sub unquote_rfc2047 {
 516         local ($_) = @_;
 517         my $encoding;
 518         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 519                 $encoding = $1;
 520                 s/_/ /g;
 521                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 522         }
 523         return wantarray ? ($_, $encoding) : $_;
 524 }
 525
 526 # use the simplest quoting being able to handle the recipient
 527 sub sanitize_address
 528 {
 529         my ($recipient) = @_;
 530         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 531
 532         if (not $recipient_name) {
 533                 return "$recipient";
 534         }
 535
 536         # if recipient_name is already quoted, do nothing
 537         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 538                 return $recipient;
 539         }
 540
 541         # rfc2047 is needed if a non-ascii char is included
 542         if ($recipient_name =~ /[^[:ascii:]]/) {
 543                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 544                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 545         }
 546
 547         # double quotes are needed if specials or CTLs are included
 548         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 549                 $recipient_name =~ s/(["\\\r])/\\$1/;
 550                 $recipient_name = "\"$recipient_name\"";
 551         }
 552
 553         return "$recipient_name $recipient_addr";
 554
 555 }
 556
 557 sub send_message
 558 {
 559         my @recipients = unique_email_list(@to);
 560         @cc = (map { sanitize_address($_) } @cc);
 561         my $to = join (",\n\t", @recipients);
 562         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 563         @recipients = (map { extract_valid_address($_) } @recipients);
 564         my $date = format_2822_time($time++);
 565         my $gitversion = '@@GIT_VERSION@@';
 566         if ($gitversion =~ m/..GIT_VERSION../) {
 567             $gitversion = Git::version();
 568         }
 569
 570         my $cc = join(", ", unique_email_list(@cc));
 571         my $ccline = "";
 572         if ($cc ne '') {
 573                 $ccline = "\nCc: $cc";
 574         }
 575         my $sanitized_sender = sanitize_address($sender);
 576         make_message_id();
 577
 578         my $header = "From: $sanitized_sender
 579 To: $to${ccline}
 580 Subject: $subject
 581 Date: $date
 582 Message-Id: $message_id
 583 X-Mailer: git-send-email $gitversion
 584 ";
 585         if ($thread && $reply_to) {
 586
 587                 $header .= "In-Reply-To: $reply_to\n";
 588                 $header .= "References: $references\n";
 589         }
 590         if (@xh) {
 591                 $header .= join("\n", @xh) . "\n";
 592         }
 593
 594         my @sendmail_parameters = ('-i', @recipients);
 595         my $raw_from = $sanitized_sender;
 596         $raw_from = $envelope_sender if (defined $envelope_sender);
 597         $raw_from = extract_valid_address($raw_from);
 598         unshift (@sendmail_parameters,
 599                         '-f', $raw_from) if(defined $envelope_sender);
 600
 601         if ($dry_run) {
 602                 # We don't want to send the email.
 603         } elsif ($smtp_server =~ m#^/#) {
 604                 my $pid = open my $sm, '|-';
 605                 defined $pid or die $!;
 606                 if (!$pid) {
 607                         exec($smtp_server, @sendmail_parameters) or die $!;
 608                 }
 609                 print $sm "$header\n$message";
 610                 close $sm or die $?;
 611         } else {
 612
 613                 if (!defined $smtp_server) {
 614                         die "The required SMTP server is not properly defined."
 615                 }
 616
 617                 if ($smtp_ssl) {
 618                         $smtp_server_port ||= 465; # ssmtp
 619                         require Net::SMTP::SSL;
 620                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 621                 }
 622                 else {
 623                         require Net::SMTP;
 624                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 625                                                  ? "$smtp_server:$smtp_server_port"
 626                                                  : $smtp_server);
 627                 }
 628
 629                 if (!$smtp) {
 630                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 631                 }
 632
 633                 if ((defined $smtp_authuser) && (defined $smtp_authpass)) {
 634                         $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 635                 }
 636                 $smtp->mail( $raw_from ) or die $smtp->message;
 637                 $smtp->to( @recipients ) or die $smtp->message;
 638                 $smtp->data or die $smtp->message;
 639                 $smtp->datasend("$header\n$message") or die $smtp->message;
 640                 $smtp->dataend() or die $smtp->message;
 641                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 642         }
 643         if ($quiet) {
 644                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 645         } else {
 646                 print (($dry_run ? "Dry-" : "")."OK. Log says:\nDate: $date\n");
 647                 if ($smtp_server !~ m#^/#) {
 648                         print "Server: $smtp_server\n";
 649                         print "MAIL FROM:<$raw_from>\n";
 650                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 651                 } else {
 652                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 653                 }
 654                 print "From: $sanitized_sender\nSubject: $subject\nCc: $cc\nTo: $to\n\n";
 655                 if ($smtp) {
 656                         print "Result: ", $smtp->code, ' ',
 657                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 658                 } else {
 659                         print "Result: OK\n";
 660                 }
 661         }
 662 }
 663
 664 $reply_to = $initial_reply_to;
 665 $references = $initial_reply_to || '';
 666 $subject = $initial_subject;
 667
 668 foreach my $t (@files) {
 669         open(F,"<",$t) or die "can't open file $t";
 670
 671         my $author = undef;
 672         my $author_encoding;
 673         my $has_content_type;
 674         my $body_encoding;
 675         @cc = @initial_cc;
 676         @xh = ();
 677         my $input_format = undef;
 678         my $header_done = 0;
 679         $message = "";
 680         while(<F>) {
 681                 if (!$header_done) {
 682                         if (/^From /) {
 683                                 $input_format = 'mbox';
 684                                 next;
 685                         }
 686                         chomp;
 687                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 688                                 $input_format = 'mbox';
 689                         }
 690
 691                         if (defined $input_format && $input_format eq 'mbox') {
 692                                 if (/^Subject:\s+(.*)$/) {
 693                                         $subject = $1;
 694
 695                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 696                                         if (unquote_rfc2047($2) eq $sender) {
 697                                                 next if ($suppress_from);
 698                                         }
 699                                         elsif ($1 eq 'From') {
 700                                                 ($author, $author_encoding)
 701                                                   = unquote_rfc2047($2);
 702                                         }
 703                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 704                                                 $2, $_) unless $quiet;
 705                                         push @cc, $2;
 706                                 }
 707                                 elsif (/^Content-type:/i) {
 708                                         $has_content_type = 1;
 709                                         if (/charset="?[^ "]+/) {
 710                                                 $body_encoding = $1;
 711                                         }
 712                                         push @xh, $_;
 713                                 }
 714                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 715                                         push @xh, $_;
 716                                 }
 717
 718                         } else {
 719                                 # In the traditional
 720                                 # "send lots of email" format,
 721                                 # line 1 = cc
 722                                 # line 2 = subject
 723                                 # So let's support that, too.
 724                                 $input_format = 'lots';
 725                                 if (@cc == 0) {
 726                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 727                                                 $_, $_) unless $quiet;
 728
 729                                         push @cc, $_;
 730
 731                                 } elsif (!defined $subject) {
 732                                         $subject = $_;
 733                                 }
 734                         }
 735
 736                         # A whitespace line will terminate the headers
 737                         if (m/^\s*$/) {
 738                                 $header_done = 1;
 739                         }
 740                 } else {
 741                         $message .=  $_;
 742                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 743                                 my $c = $2;
 744                                 chomp $c;
 745                                 next if ($c eq $sender and $suppress_from);
 746                                 push @cc, $c;
 747                                 printf("(sob) Adding cc: %s from line '%s'\n",
 748                                         $c, $_) unless $quiet;
 749                         }
 750                 }
 751         }
 752         close F;
 753
 754         if (defined $cc_cmd) {
 755                 open(F, "$cc_cmd $t |")
 756                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 757                 while(<F>) {
 758                         my $c = $_;
 759                         $c =~ s/^\s*//g;
 760                         $c =~ s/\n$//g;
 761                         next if ($c eq $sender and $suppress_from);
 762                         push @cc, $c;
 763                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 764                                 $c, $cc_cmd) unless $quiet;
 765                 }
 766                 close F
 767                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 768         }
 769
 770         if (defined $author) {
 771                 $message = "From: $author\n\n$message";
 772                 if (defined $author_encoding) {
 773                         if ($has_content_type) {
 774                                 if ($body_encoding eq $author_encoding) {
 775                                         # ok, we already have the right encoding
 776                                 }
 777                                 else {
 778                                         # uh oh, we should re-encode
 779                                 }
 780                         }
 781                         else {
 782                                 push @xh,
 783                                   'MIME-Version: 1.0',
 784                                   "Content-Type: text/plain; charset=$author_encoding";
 785                         }
 786                 }
 787         }
 788
 789         send_message();
 790
 791         # set up for the next message
 792         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 793                 $reply_to = $message_id;
 794                 if (length $references > 0) {
 795                         $references .= "\n $message_id";
 796                 } else {
 797                         $references = "$message_id";
 798                 }
 799         }
 800 }
 801
 802 if ($compose) {
 803         cleanup_compose_files();
 804 }
 805
 806 sub cleanup_compose_files() {
 807         unlink($compose_filename, $compose_filename . ".final");
 808
 809 }
 810
 811 $smtp->quit if $smtp;
 812
 813 sub unique_email_list(@) {
 814         my %seen;
 815         my @emails;
 816
 817         foreach my $entry (@_) {
 818                 if (my $clean = extract_valid_address($entry)) {
 819                         $seen{$clean} ||= 0;
 820                         next if $seen{$clean}++;
 821                         push @emails, $entry;
 822                 } else {
 823                         print STDERR "W: unable to extract a valid address",
 824                                         " from: $entry\n";
 825                 }
 826         }
 827         return @emails;
 828 }