git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $SVN_URL
   8                 $GIT_SVN_INDEX $GIT_SVN
   9                 $GIT_DIR $GIT_SVN_DIR $REVDB
  10                 $_follow_parent $sha1 $sha1_short $_revision
  11                 $_cp_remote $_upgrade $_rmdir $_q $_cp_similarity
  12                 $_find_copies_harder $_l $_authors %users/;
  13 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  14 $VERSION = '@@GIT_VERSION@@';
  15
  16 $ENV{GIT_DIR} ||= '.git';
  17 $Git::SVN::default_repo_id = 'git-svn';
  18 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  19
  20 my $LC_ALL = $ENV{LC_ALL};
  21 $Git::SVN::Log::TZ = $ENV{TZ};
  22 # make sure the svn binary gives consistent output between locales and TZs:
  23 $ENV{TZ} = 'UTC';
  24 $ENV{LC_ALL} = 'C';
  25 $| = 1; # unbuffer STDOUT
  26
  27 sub fatal (@) { print STDERR @_; exit 1 }
  28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  29 require SVN::Ra;
  30 require SVN::Delta;
  31 if ($SVN::Core::VERSION lt '1.1.0') {
  32         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
  33 }
  34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  37 use Carp qw/croak/;
  38 use IO::File qw//;
  39 use File::Basename qw/dirname basename/;
  40 use File::Path qw/mkpath/;
  41 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev pass_through/;
  42 use IPC::Open3;
  43 use Git;
  44
  45 BEGIN {
  46         my $s;
  47         foreach (qw/command command_oneline command_noisy command_output_pipe
  48                     command_input_pipe command_close_pipe/) {
  49                 $s .= "*SVN::Git::Editor::$_ = *SVN::Git::Fetcher::$_ = ".
  50                       "*Git::SVN::Migration::$_ = ".
  51                       "*Git::SVN::Log::$_ = *Git::SVN::$_ = *$_ = *Git::$_; ";
  52         }
  53         eval $s;
  54 }
  55
  56 my ($SVN);
  57
  58 my $_optimize_commits = 1 unless $ENV{GIT_SVN_NO_OPTIMIZE_COMMITS};
  59 $sha1 = qr/[a-f\d]{40}/;
  60 $sha1_short = qr/[a-f\d]{4,40}/;
  61 my ($_stdin, $_help, $_edit,
  62         $_repack, $_repack_nr, $_repack_flags,
  63         $_message, $_file, $_no_metadata,
  64         $_template, $_shared,
  65         $_version, $_upgrade,
  66         $_merge, $_strategy, $_dry_run,
  67         $_prefix);
  68
  69 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  70                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  71                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  72 my %fc_opts = ( 'follow-parent|follow' => \$_follow_parent,
  73                 'authors-file|A=s' => \$_authors,
  74                 'repack:i' => \$_repack,
  75                 'no-metadata' => \$_no_metadata,
  76                 'quiet|q' => \$_q,
  77                 'repack-flags|repack-args|repack-opts=s' => \$_repack_flags,
  78                 %remote_opts );
  79
  80 my ($_trunk, $_tags, $_branches);
  81 my %multi_opts = ( 'trunk|T=s' => \$_trunk,
  82                 'tags|t=s' => \$_tags,
  83                 'branches|b=s' => \$_branches );
  84 my %init_opts = ( 'template=s' => \$_template, 'shared' => \$_shared );
  85 my %cmt_opts = ( 'edit|e' => \$_edit,
  86                 'rmdir' => \$_rmdir,
  87                 'find-copies-harder' => \$_find_copies_harder,
  88                 'l=i' => \$_l,
  89                 'copy-similarity|C=i'=> \$_cp_similarity
  90 );
  91
  92 my %cmd = (
  93         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
  94                         { 'revision|r=s' => \$_revision, %fc_opts } ],
  95         init => [ \&cmd_init, "Initialize a repo for tracking" .
  96                           " (requires URL argument)",
  97                           \%init_opts ],
  98         dcommit => [ \&cmd_dcommit,
  99                      'Commit several diffs to merge with upstream',
 100                         { 'merge|m|M' => \$_merge,
 101                           'strategy|s=s' => \$_strategy,
 102                           'dry-run|n' => \$_dry_run,
 103                         %cmt_opts, %fc_opts } ],
 104         'set-tree' => [ \&cmd_set_tree,
 105                         "Set an SVN repository to a git tree-ish",
 106                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 107         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 108                         { 'revision|r=i' => \$_revision } ],
 109         rebuild => [ \&cmd_rebuild, "Rebuild git-svn metadata (after git clone)",
 110                         { 'copy-remote|remote=s' => \$_cp_remote,
 111                           'upgrade' => \$_upgrade } ],
 112         'multi-init' => [ \&cmd_multi_init,
 113                         'Initialize multiple trees (like git-svnimport)',
 114                         { %multi_opts, %init_opts, %remote_opts,
 115                          'revision|r=i' => \$_revision,
 116                          'prefix=s' => \$_prefix,
 117                         } ],
 118         'multi-fetch' => [ \&cmd_multi_fetch,
 119                         'Fetch multiple trees (like git-svnimport)',
 120                         \%fc_opts ],
 121         'migrate' => [ sub { },
 122                        # no-op, we automatically run this anyways,
 123                        'Migrate configuration/metadata/layout from
 124                         previous versions of git-svn',
 125                         \%remote_opts ],
 126         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 127                         { 'limit=i' => \$Git::SVN::Log::limit,
 128                           'revision|r=s' => \$_revision,
 129                           'verbose|v' => \$Git::SVN::Log::verbose,
 130                           'incremental' => \$Git::SVN::Log::incremental,
 131                           'oneline' => \$Git::SVN::Log::oneline,
 132                           'show-commit' => \$Git::SVN::Log::show_commit,
 133                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 134                           'authors-file|A=s' => \$_authors,
 135                           'color' => \$Git::SVN::Log::color,
 136                           'pager=s' => \$Git::SVN::Log::pager,
 137                         } ],
 138         'commit-diff' => [ \&cmd_commit_diff,
 139                            'Commit a diff between two trees',
 140                         { 'message|m=s' => \$_message,
 141                           'file|F=s' => \$_file,
 142                           'revision|r=s' => \$_revision,
 143                         %cmt_opts } ],
 144 );
 145
 146 my $cmd;
 147 for (my $i = 0; $i < @ARGV; $i++) {
 148         if (defined $cmd{$ARGV[$i]}) {
 149                 $cmd = $ARGV[$i];
 150                 splice @ARGV, $i, 1;
 151                 last;
 152         }
 153 };
 154
 155 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 156
 157 read_repo_config(\%opts);
 158 my $rv = GetOptions(%opts, 'help|H|h' => \$_help,
 159                                 'version|V' => \$_version,
 160                                 'minimize-connections' =>
 161                                   \$Git::SVN::Migration::_minimize,
 162                                 'id|i=s' => \$Git::SVN::default_ref_id);
 163 exit 1 if (!$rv && $cmd ne 'log');
 164
 165 usage(0) if $_help;
 166 version() if $_version;
 167 usage(1) unless defined $cmd;
 168 load_authors() if $_authors;
 169 unless ($cmd =~ /^(?:init|rebuild|multi-init|commit-diff)$/) {
 170         Git::SVN::Migration::migration_check();
 171 }
 172 eval {
 173         Git::SVN::verify_remotes_sanity();
 174         $cmd{$cmd}->[0]->(@ARGV);
 175 };
 176 fatal $@ if $@;
 177 exit 0;
 178
 179 ####################### primary functions ######################
 180 sub usage {
 181         my $exit = shift || 0;
 182         my $fd = $exit ? \*STDERR : \*STDOUT;
 183         print $fd <<"";
 184 git-svn - bidirectional operations between a single Subversion tree and git
 185 Usage: $0 <command> [options] [arguments]\n
 186
 187         print $fd "Available commands:\n" unless $cmd;
 188
 189         foreach (sort keys %cmd) {
 190                 next if $cmd && $cmd ne $_;
 191                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 192                 foreach (keys %{$cmd{$_}->[2]}) {
 193                         # prints out arguments as they should be passed:
 194                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 195                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 196                                                         "--$_" : "-$_" }
 197                                                 split /\|/,$_)," $x\n";
 198                 }
 199         }
 200         print $fd <<"";
 201 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 202 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 203 one git repository and want to keep them separate.  See git-svn(1) for more
 204 information.
 205
 206         exit $exit;
 207 }
 208
 209 sub version {
 210         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 211         exit 0;
 212 }
 213
 214 sub cmd_rebuild {
 215         my $url = shift;
 216         my $gs = $url ? Git::SVN->init($url)
 217                       : eval { Git::SVN->new };
 218         $gs ||= Git::SVN->_new;
 219         if (!verify_ref($gs->refname.'^0')) {
 220                 $gs->copy_remote_ref;
 221         }
 222
 223         my ($rev_list, $ctx) = command_output_pipe("rev-list", $gs->refname);
 224         my $latest;
 225         my $svn_uuid;
 226         while (<$rev_list>) {
 227                 chomp;
 228                 my $c = $_;
 229                 fatal "Non-SHA1: $c\n" unless $c =~ /^$sha1$/o;
 230                 my ($url, $rev, $uuid) = cmt_metadata($c);
 231
 232                 # ignore merges (from set-tree)
 233                 next if (!defined $rev || !$uuid);
 234
 235                 # if we merged or otherwise started elsewhere, this is
 236                 # how we break out of it
 237                 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
 238                     ($gs->{url} && $url && ($url ne $gs->{url}))) {
 239                         next;
 240                 }
 241
 242                 unless (defined $latest) {
 243                         if (!$gs->{url} && !$url) {
 244                                 fatal "SVN repository location required\n";
 245                         }
 246                         $gs = Git::SVN->init($url);
 247                         $latest = $rev;
 248                 }
 249                 $gs->rev_db_set($rev, $c);
 250                 print "r$rev = $c\n";
 251         }
 252         command_close_pipe($rev_list, $ctx);
 253 }
 254
 255 sub do_git_init_db {
 256         unless (-d $ENV{GIT_DIR}) {
 257                 my @init_db = ('init');
 258                 push @init_db, "--template=$_template" if defined $_template;
 259                 push @init_db, "--shared" if defined $_shared;
 260                 command_noisy(@init_db);
 261         }
 262 }
 263
 264 sub cmd_init {
 265         my $url = shift or die "SVN repository location required " .
 266                                 "as a command-line argument\n";
 267         if (my $repo_path = shift) {
 268                 unless (-d $repo_path) {
 269                         mkpath([$repo_path]);
 270                 }
 271                 chdir $repo_path or croak $!;
 272                 $ENV{GIT_DIR} = $repo_path . "/.git";
 273         }
 274         do_git_init_db();
 275
 276         Git::SVN->init($url);
 277 }
 278
 279 sub cmd_fetch {
 280         if (@_) {
 281                 die "Additional fetch arguments are no longer supported.\n",
 282                     "Use --follow-parent if you have moved/copied directories
 283                     instead.\n";
 284         }
 285         my $gs = Git::SVN->new;
 286         $gs->fetch;
 287         if ($gs->{last_commit} && !verify_ref('refs/heads/master^0')) {
 288                 command_noisy(qw(update-ref refs/heads/master),
 289                               $gs->{last_commit});
 290         }
 291 }
 292
 293 sub cmd_set_tree {
 294         my (@commits) = @_;
 295         if ($_stdin || !@commits) {
 296                 print "Reading from stdin...\n";
 297                 @commits = ();
 298                 while (<STDIN>) {
 299                         if (/\b($sha1_short)\b/o) {
 300                                 unshift @commits, $1;
 301                         }
 302                 }
 303         }
 304         my @revs;
 305         foreach my $c (@commits) {
 306                 my @tmp = command('rev-parse',$c);
 307                 if (scalar @tmp == 1) {
 308                         push @revs, $tmp[0];
 309                 } elsif (scalar @tmp > 1) {
 310                         push @revs, reverse(command('rev-list',@tmp));
 311                 } else {
 312                         fatal "Failed to rev-parse $c\n";
 313                 }
 314         }
 315         my $gs = Git::SVN->new;
 316         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 317         $gs->fetch;
 318         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 319                 fatal "There are new revisions that were fetched ",
 320                       "and need to be merged (or acknowledged) ",
 321                       "before committing.\nlast rev: $r_last\n",
 322                       " current: $gs->{last_rev}\n";
 323         }
 324         $gs->set_tree($_) foreach @revs;
 325         print "Done committing ",scalar @revs," revisions to SVN\n";
 326 }
 327
 328 sub cmd_dcommit {
 329         my $head = shift;
 330         my $gs = Git::SVN->new;
 331         $head ||= 'HEAD';
 332         my @refs = command(qw/rev-list --no-merges/, $gs->refname."..$head");
 333         my $last_rev;
 334         foreach my $d (reverse @refs) {
 335                 if (!verify_ref("$d~1")) {
 336                         fatal "Commit $d\n",
 337                               "has no parent commit, and therefore ",
 338                               "nothing to diff against.\n",
 339                               "You should be working from a repository ",
 340                               "originally created by git-svn\n";
 341                 }
 342                 unless (defined $last_rev) {
 343                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 344                         unless (defined $last_rev) {
 345                                 fatal "Unable to extract revision information ",
 346                                       "from commit $d~1\n";
 347                         }
 348                 }
 349                 if ($_dry_run) {
 350                         print "diff-tree $d~1 $d\n";
 351                 } else {
 352                         my $log = get_commit_entry($d)->{log};
 353                         my $ra = $gs->ra;
 354                         my $pool = SVN::Pool->new;
 355                         my %ed_opts = ( r => $last_rev,
 356                                         ra => $ra->dup,
 357                                         svn_path => $ra->{svn_path} );
 358                         my $ed = SVN::Git::Editor->new(\%ed_opts,
 359                                          $ra->get_commit_editor($log,
 360                                          sub { print "Committed r$_[0]\n";
 361                                                $last_rev = $_[0]; }),
 362                                          $pool);
 363                         my $mods = $ed->apply_diff("$d~1", $d);
 364                         if (@$mods == 0) {
 365                                 print "No changes\n$d~1 == $d\n";
 366                         }
 367                 }
 368         }
 369         return if $_dry_run;
 370         $gs->fetch;
 371         # we always want to rebase against the current HEAD, not any
 372         # head that was passed to us
 373         my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
 374         my @finish;
 375         if (@diff) {
 376                 @finish = qw/rebase/;
 377                 push @finish, qw/--merge/ if $_merge;
 378                 push @finish, "--strategy=$_strategy" if $_strategy;
 379                 print STDERR "W: HEAD and ", $gs->refname, " differ, ",
 380                              "using @finish:\n", "@diff";
 381         } else {
 382                 print "No changes between current HEAD and ",
 383                       $gs->refname, "\nResetting to the latest ",
 384                       $gs->refname, "\n";
 385                 @finish = qw/reset --mixed/;
 386         }
 387         command_noisy(@finish, $gs->refname);
 388 }
 389
 390 sub cmd_show_ignore {
 391         my $gs = Git::SVN->new;
 392         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 393         $gs->traverse_ignore(\*STDOUT, '', $r);
 394 }
 395
 396 sub cmd_multi_init {
 397         my $url = shift;
 398         unless (defined $_trunk || defined $_branches || defined $_tags) {
 399                 usage(1);
 400         }
 401         do_git_init_db();
 402         $_prefix = '' unless defined $_prefix;
 403         $url =~ s#/+$## if defined $url;
 404         if (defined $_trunk) {
 405                 my $trunk_ref = $_prefix . 'trunk';
 406                 # try both old-style and new-style lookups:
 407                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 408                 unless ($gs_trunk) {
 409                         my ($trunk_url, $trunk_path) =
 410                                               complete_svn_url($url, $_trunk);
 411                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 412                                                    undef, $trunk_ref);
 413                 }
 414         }
 415         return unless defined $_branches || defined $_tags;
 416         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 417         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 418         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 419 }
 420
 421 sub cmd_multi_fetch {
 422         my @gs;
 423         foreach (command(qw/config -l/)) {
 424                 next unless m!^svn-remote\.(.+)\.fetch=
 425                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
 426                 my ($repo_id, $path, $ref_id) = ($1, $2, $3);
 427                 push @gs, Git::SVN->new($ref_id, $repo_id, $path);
 428         }
 429         foreach (@gs) {
 430                 $_->fetch;
 431         }
 432 }
 433
 434 # this command is special because it requires no metadata
 435 sub cmd_commit_diff {
 436         my ($ta, $tb, $url) = @_;
 437         my $usage = "Usage: $0 commit-diff -r<revision> ".
 438                     "<tree-ish> <tree-ish> [<URL>]\n";
 439         fatal($usage) if (!defined $ta || !defined $tb);
 440         if (!defined $url) {
 441                 my $gs = eval { Git::SVN->new };
 442                 if (!$gs) {
 443                         fatal("Needed URL or usable git-svn --id in ",
 444                               "the command-line\n", $usage);
 445                 }
 446                 $url = $gs->{url};
 447         }
 448         unless (defined $_revision) {
 449                 fatal("-r|--revision is a required argument\n", $usage);
 450         }
 451         if (defined $_message && defined $_file) {
 452                 fatal("Both --message/-m and --file/-F specified ",
 453                       "for the commit message.\n",
 454                       "I have no idea what you mean\n");
 455         }
 456         if (defined $_file) {
 457                 $_message = file_to_s($_file);
 458         } else {
 459                 $_message ||= get_commit_entry($tb)->{log};
 460         }
 461         my $ra ||= Git::SVN::Ra->new($url);
 462         my $r = $_revision;
 463         if ($r eq 'HEAD') {
 464                 $r = $ra->get_latest_revnum;
 465         } elsif ($r !~ /^\d+$/) {
 466                 die "revision argument: $r not understood by git-svn\n";
 467         }
 468         my $pool = SVN::Pool->new;
 469         my %ed_opts = ( r => $r,
 470                         ra => $ra->dup,
 471                         svn_path => $ra->{svn_path} );
 472         my $ed = SVN::Git::Editor->new(\%ed_opts,
 473                                        $ra->get_commit_editor($_message,
 474                                          sub { print "Committed r$_[0]\n" }),
 475                                        $pool);
 476         my $mods = $ed->apply_diff($ta, $tb);
 477         if (@$mods == 0) {
 478                 print "No changes\n$ta == $tb\n";
 479         }
 480         $pool->clear;
 481 }
 482
 483 ########################### utility functions #########################
 484
 485 sub complete_svn_url {
 486         my ($url, $path) = @_;
 487         $path =~ s#/+$##;
 488         if ($path !~ m#^[a-z\+]+://#) {
 489                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
 490                         fatal("E: '$path' is not a complete URL ",
 491                               "and a separate URL is not specified\n");
 492                 }
 493                 return ($url, $path);
 494         }
 495         return ($path, '');
 496 }
 497
 498 sub complete_url_ls_init {
 499         my ($ra, $repo_path, $switch, $pfx) = @_;
 500         unless ($repo_path) {
 501                 print STDERR "W: $switch not specified\n";
 502                 return;
 503         }
 504         $repo_path =~ s#/+$##;
 505         if ($repo_path =~ m#^[a-z\+]+://#) {
 506                 $ra = Git::SVN::Ra->new($repo_path);
 507                 $repo_path = '';
 508         } else {
 509                 $repo_path =~ s#^/+##;
 510                 unless ($ra) {
 511                         fatal("E: '$repo_path' is not a complete URL ",
 512                               "and a separate URL is not specified\n");
 513                 }
 514         }
 515         my $r = defined $_revision ? $_revision : $ra->get_latest_revnum;
 516         my ($dirent, undef, undef) = $ra->get_dir($repo_path, $r);
 517         my $url = $ra->{url};
 518         foreach my $d (sort keys %$dirent) {
 519                 next if ($dirent->{$d}->kind != $SVN::Node::dir);
 520                 my $path =  "$repo_path/$d";
 521                 my $ref = "$pfx$d";
 522                 my $gs = eval { Git::SVN->new($ref) };
 523                 # don't try to init already existing refs
 524                 unless ($gs) {
 525                         print "init $url/$path => $ref\n";
 526                         Git::SVN->init($url, $path, undef, $ref);
 527                 }
 528         }
 529 }
 530
 531 sub verify_ref {
 532         my ($ref) = @_;
 533         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
 534                                { STDERR => 0 }); };
 535 }
 536
 537 sub get_tree_from_treeish {
 538         my ($treeish) = @_;
 539         # $treeish can be a symbolic ref, too:
 540         my $type = command_oneline(qw/cat-file -t/, $treeish);
 541         my $expected;
 542         while ($type eq 'tag') {
 543                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
 544         }
 545         if ($type eq 'commit') {
 546                 $expected = (grep /^tree /, command(qw/cat-file commit/,
 547                                                     $treeish))[0];
 548                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
 549                 die "Unable to get tree from $treeish\n" unless $expected;
 550         } elsif ($type eq 'tree') {
 551                 $expected = $treeish;
 552         } else {
 553                 die "$treeish is a $type, expected tree, tag or commit\n";
 554         }
 555         return $expected;
 556 }
 557
 558 sub get_commit_entry {
 559         my ($treeish) = shift;
 560         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
 561         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
 562         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
 563         open my $log_fh, '>', $commit_editmsg or croak $!;
 564
 565         my $type = command_oneline(qw/cat-file -t/, $treeish);
 566         if ($type eq 'commit' || $type eq 'tag') {
 567                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
 568                                                          $type, $treeish);
 569                 my $in_msg = 0;
 570                 while (<$msg_fh>) {
 571                         if (!$in_msg) {
 572                                 $in_msg = 1 if (/^\s*$/);
 573                         } elsif (/^git-svn-id: /) {
 574                                 # skip this for now, we regenerate the
 575                                 # correct one on re-fetch anyways
 576                                 # TODO: set *:merge properties or like...
 577                         } else {
 578                                 print $log_fh $_ or croak $!;
 579                         }
 580                 }
 581                 command_close_pipe($msg_fh, $ctx);
 582         }
 583         close $log_fh or croak $!;
 584
 585         if ($_edit || ($type eq 'tree')) {
 586                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
 587                 # TODO: strip out spaces, comments, like git-commit.sh
 588                 system($editor, $commit_editmsg);
 589         }
 590         rename $commit_editmsg, $commit_msg or croak $!;
 591         open $log_fh, '<', $commit_msg or croak $!;
 592         { local $/; chomp($log_entry{log} = <$log_fh>); }
 593         close $log_fh or croak $!;
 594         unlink $commit_msg;
 595         \%log_entry;
 596 }
 597
 598 sub s_to_file {
 599         my ($str, $file, $mode) = @_;
 600         open my $fd,'>',$file or croak $!;
 601         print $fd $str,"\n" or croak $!;
 602         close $fd or croak $!;
 603         chmod ($mode &~ umask, $file) if (defined $mode);
 604 }
 605
 606 sub file_to_s {
 607         my $file = shift;
 608         open my $fd,'<',$file or croak "$!: file: $file\n";
 609         local $/;
 610         my $ret = <$fd>;
 611         close $fd or croak $!;
 612         $ret =~ s/\s*$//s;
 613         return $ret;
 614 }
 615
 616 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
 617 sub load_authors {
 618         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
 619         my $log = $cmd eq 'log';
 620         while (<$authors>) {
 621                 chomp;
 622                 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
 623                 my ($user, $name, $email) = ($1, $2, $3);
 624                 if ($log) {
 625                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
 626                 } else {
 627                         $users{$user} = [$name, $email];
 628                 }
 629         }
 630         close $authors or croak $!;
 631 }
 632
 633 # convert GetOpt::Long specs for use by git-config
 634 sub read_repo_config {
 635         return unless -d $ENV{GIT_DIR};
 636         my $opts = shift;
 637         foreach my $o (keys %$opts) {
 638                 my $v = $opts->{$o};
 639                 my ($key) = ($o =~ /^([a-z\-]+)/);
 640                 $key =~ s/-//g;
 641                 my $arg = 'git-config';
 642                 $arg .= ' --int' if ($o =~ /[:=]i$/);
 643                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
 644                 if (ref $v eq 'ARRAY') {
 645                         chomp(my @tmp = `$arg --get-all svn.$key`);
 646                         @$v = @tmp if @tmp;
 647                 } else {
 648                         chomp(my $tmp = `$arg --get svn.$key`);
 649                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
 650                                 $$v = $tmp;
 651                         }
 652                 }
 653         }
 654 }
 655
 656 sub extract_metadata {
 657         my $id = shift or return (undef, undef, undef);
 658         my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
 659                                                         \s([a-f\d\-]+)$/x);
 660         if (!defined $rev || !$uuid || !$url) {
 661                 # some of the original repositories I made had
 662                 # identifiers like this:
 663                 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
 664         }
 665         return ($url, $rev, $uuid);
 666 }
 667
 668 sub cmt_metadata {
 669         return extract_metadata((grep(/^git-svn-id: /,
 670                 command(qw/cat-file commit/, shift)))[-1]);
 671 }
 672
 673 sub get_commit_time {
 674         my $cmt = shift;
 675         my $fh = command_output_pipe(qw/rev-list --pretty=raw -n1/, $cmt);
 676         while (<$fh>) {
 677                 /^committer\s(?:.+) (\d+) ([\-\+]?\d+)$/ or next;
 678                 my ($s, $tz) = ($1, $2);
 679                 if ($tz =~ s/^\+//) {
 680                         $s += tz_to_s_offset($tz);
 681                 } elsif ($tz =~ s/^\-//) {
 682                         $s -= tz_to_s_offset($tz);
 683                 }
 684                 close $fh;
 685                 return $s;
 686         }
 687         die "Can't get commit time for commit: $cmt\n";
 688 }
 689
 690 sub tz_to_s_offset {
 691         my ($tz) = @_;
 692         $tz =~ s/(\d\d)$//;
 693         return ($1 * 60) + ($tz * 3600);
 694 }
 695
 696 package Git::SVN;
 697 use strict;
 698 use warnings;
 699 use vars qw/$default_repo_id $default_ref_id/;
 700 use Carp qw/croak/;
 701 use File::Path qw/mkpath/;
 702 use IPC::Open3;
 703
 704 # properties that we do not log:
 705 my %SKIP_PROP;
 706 BEGIN {
 707         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
 708                                         svn:special svn:executable
 709                                         svn:entry:committed-rev
 710                                         svn:entry:last-author
 711                                         svn:entry:uuid
 712                                         svn:entry:committed-date/;
 713 }
 714
 715 sub read_all_remotes {
 716         my $r = {};
 717         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
 718                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
 719                         $r->{$1}->{fetch}->{$2} = $3;
 720                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
 721                         $r->{$1}->{url} = $2;
 722                 }
 723         }
 724         $r;
 725 }
 726
 727 sub verify_remotes_sanity {
 728         return unless -d $ENV{GIT_DIR};
 729         my %seen;
 730         foreach (command(qw/config -l/)) {
 731                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
 732                         if ($seen{$1}) {
 733                                 die "Remote ref refs/remote/$1 is tracked by",
 734                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
 735                                     "Please resolve this ambiguity in ",
 736                                     "your git configuration file before ",
 737                                     "continuing\n";
 738                         }
 739                         $seen{$1} = $_;
 740                 }
 741         }
 742 }
 743
 744 # we allow more chars than remotes2config.sh...
 745 sub sanitize_remote_name {
 746         my ($name) = @_;
 747         $name =~ tr{A-Za-z0-9:,/+-}{.}c;
 748         $name;
 749 }
 750
 751 sub find_existing_remote {
 752         my ($url, $remotes) = @_;
 753         my $existing;
 754         foreach my $repo_id (keys %$remotes) {
 755                 my $u = $remotes->{$repo_id}->{url} or next;
 756                 next if $u ne $url;
 757                 $existing = $repo_id;
 758                 last;
 759         }
 760         $existing;
 761 }
 762
 763 sub init_remote_config {
 764         my ($self, $url) = @_;
 765         $url =~ s!/+$!!; # strip trailing slash
 766         my $r = read_all_remotes();
 767         my $existing = find_existing_remote($url, $r);
 768         if ($existing) {
 769                 print STDERR "Using existing ",
 770                              "[svn-remote \"$existing\"]\n";
 771                 $self->{repo_id} = $existing;
 772         } else {
 773                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
 774                 $existing = find_existing_remote($min_url, $r);
 775                 if ($existing) {
 776                         print STDERR "Using existing ",
 777                                      "[svn-remote \"$existing\"]\n";
 778                         $self->{repo_id} = $existing;
 779                 }
 780                 if ($min_url ne $url) {
 781                         print STDERR "Using higher level of URL: ",
 782                                      "$url => $min_url\n";
 783                         my $old_path = $self->{path};
 784                         $self->{path} = $url;
 785                         $self->{path} =~ s!^\Q$min_url\E/*!!;
 786                         if (length $old_path) {
 787                                 $self->{path} .= "/$old_path";
 788                         }
 789                         $url = $min_url;
 790                 }
 791         }
 792         my $orig_url;
 793         if (!$existing) {
 794                 # verify that we aren't overwriting anything:
 795                 $orig_url = eval {
 796                         command_oneline('config', '--get',
 797                                         "svn-remote.$self->{repo_id}.url")
 798                 };
 799                 if ($orig_url && ($orig_url ne $url)) {
 800                         die "svn-remote.$self->{repo_id}.url already set: ",
 801                             "$orig_url\nwanted to set to: $url\n";
 802                 }
 803         }
 804         my ($xrepo_id, $xpath) = find_ref($self->refname);
 805         if (defined $xpath) {
 806                 die "svn-remote.$xrepo_id.fetch already set to track ",
 807                     "$xpath:refs/remotes/", $self->refname, "\n";
 808         }
 809         command_noisy('config',
 810                       "svn-remote.$self->{repo_id}.url", $url);
 811         command_noisy('config', '--add',
 812                       "svn-remote.$self->{repo_id}.fetch",
 813                       "$self->{path}:".$self->refname);
 814         $self->{url} = $url;
 815 }
 816
 817 sub init {
 818         my ($class, $url, $path, $repo_id, $ref_id) = @_;
 819         my $self = _new($class, $repo_id, $ref_id, $path);
 820         if (defined $url) {
 821                 $self->init_remote_config($url);
 822         }
 823         $self;
 824 }
 825
 826 sub find_ref {
 827         my ($ref_id) = @_;
 828         foreach (command(qw/config -l/)) {
 829                 next unless m!^svn-remote\.(.+)\.fetch=
 830                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
 831                 my ($repo_id, $path, $ref) = ($1, $2, $3);
 832                 if ($ref eq $ref_id) {
 833                         $path = '' if ($path =~ m#^\./?#);
 834                         return ($repo_id, $path);
 835                 }
 836         }
 837         (undef, undef, undef);
 838 }
 839
 840 sub new {
 841         my ($class, $ref_id, $repo_id, $path) = @_;
 842         if (defined $ref_id && !defined $repo_id && !defined $path) {
 843                 ($repo_id, $path) = find_ref($ref_id);
 844                 if (!defined $repo_id) {
 845                         die "Could not find a \"svn-remote.*.fetch\" key ",
 846                             "in the repository configuration matching: ",
 847                             "refs/remotes/$ref_id\n";
 848                 }
 849         }
 850         my $self = _new($class, $repo_id, $ref_id, $path);
 851         if (!defined $self->{path} || !length $self->{path}) {
 852                 my $fetch = command_oneline('config', '--get',
 853                                             "svn-remote.$repo_id.fetch",
 854                                             ":refs/remotes/$ref_id\$") or
 855                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
 856                          "\":refs/remotes/$ref_id\$\" in config\n";
 857                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
 858         }
 859         $self->{url} = command_oneline('config', '--get',
 860                                        "svn-remote.$repo_id.url") or
 861                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
 862         $self;
 863 }
 864
 865 sub refname { "refs/remotes/$_[0]->{ref_id}" }
 866
 867 sub ra {
 868         my ($self) = shift;
 869         $self->{ra} ||= Git::SVN::Ra->new($self->{url});
 870 }
 871
 872 sub rel_path {
 873         my ($self) = @_;
 874         my $repos_root = $self->ra->{repos_root};
 875         return $self->{path} if ($self->{url} eq $repos_root);
 876         my $url = $self->{url} .
 877                   (length $self->{path} ? "/$self->{path}" : $self->{path});
 878         $url =~ s!^\Q$repos_root\E/*!!g;
 879         $url;
 880 }
 881
 882 sub copy_remote_ref {
 883         my ($self) = @_;
 884         my $origin = $::_cp_remote ? $::_cp_remote : 'origin';
 885         my $ref = $self->refname;
 886         if (command('ls-remote', $origin, $ref)) {
 887                 command_noisy('fetch', $origin, "$ref:$ref");
 888         } elsif ($::_cp_remote && !$::_upgrade) {
 889                 die "Unable to find remote reference: $ref on $origin\n";
 890         }
 891 }
 892
 893 sub traverse_ignore {
 894         my ($self, $fh, $path, $r) = @_;
 895         $path =~ s#^/+##g;
 896         my ($dirent, undef, $props) = $self->ra->get_dir($path, $r);
 897         my $p = $path;
 898         $p =~ s#^\Q$self->{ra}->{svn_path}\E/##;
 899         print $fh length $p ? "\n# $p\n" : "\n# /\n";
 900         if (my $s = $props->{'svn:ignore'}) {
 901                 $s =~ s/[\r\n]+/\n/g;
 902                 chomp $s;
 903                 if (length $p == 0) {
 904                         $s =~ s#\n#\n/$p#g;
 905                         print $fh "/$s\n";
 906                 } else {
 907                         $s =~ s#\n#\n/$p/#g;
 908                         print $fh "/$p/$s\n";
 909                 }
 910         }
 911         foreach (sort keys %$dirent) {
 912                 next if $dirent->{$_}->kind != $SVN::Node::dir;
 913                 $self->traverse_ignore($fh, "$path/$_", $r);
 914         }
 915 }
 916
 917 # returns the newest SVN revision number and newest commit SHA1
 918 sub last_rev_commit {
 919         my ($self) = @_;
 920         if (defined $self->{last_rev} && defined $self->{last_commit}) {
 921                 return ($self->{last_rev}, $self->{last_commit});
 922         }
 923         my $c = ::verify_ref($self->refname.'^0');
 924         if ($c) {
 925                 my $rev = (::cmt_metadata($c))[1];
 926                 if (defined $rev) {
 927                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 928                         return ($rev, $c);
 929                 }
 930         }
 931         my $offset = -41; # from tail
 932         my $rl;
 933         open my $fh, '<', $self->{db_path} or
 934                                  croak "$self->{db_path} not readable: $!\n";
 935         seek $fh, $offset, 2;
 936         $rl = readline $fh;
 937         defined $rl or return (undef, undef);
 938         chomp $rl;
 939         while ($c ne $rl && tell $fh != 0) {
 940                 $offset -= 41;
 941                 seek $fh, $offset, 2;
 942                 $rl = readline $fh;
 943                 defined $rl or return (undef, undef);
 944                 chomp $rl;
 945         }
 946         my $rev = tell $fh;
 947         croak $! if ($rev < 0);
 948         $rev =  ($rev - 41) / 41;
 949         close $fh or croak $!;
 950         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 951         return ($rev, $c);
 952 }
 953
 954 sub parse_revision {
 955         my ($self, $base) = @_;
 956         my $head = $self->ra->get_latest_revnum;
 957         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
 958                 return ($base + 1, $head) if (defined $base);
 959                 return (0, $head);
 960         }
 961         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
 962         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
 963         if ($::_revision =~ /^BASE:(\d+)$/) {
 964                 return ($base + 1, $1) if (defined $base);
 965                 return (0, $head);
 966         }
 967         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
 968         die "revision argument: $::_revision not understood by git-svn\n",
 969                 "Try using the command-line svn client instead\n";
 970 }
 971
 972 sub tmp_index_do {
 973         my ($self, $sub) = @_;
 974         my $old_index = $ENV{GIT_INDEX_FILE};
 975         $ENV{GIT_INDEX_FILE} = $self->{index};
 976         my @ret = &$sub;
 977         if ($old_index) {
 978                 $ENV{GIT_INDEX_FILE} = $old_index;
 979         } else {
 980                 delete $ENV{GIT_INDEX_FILE};
 981         }
 982         wantarray ? @ret : $ret[0];
 983 }
 984
 985 sub assert_index_clean {
 986         my ($self, $treeish) = @_;
 987
 988         $self->tmp_index_do(sub {
 989                 command_noisy('read-tree', $treeish) unless -e $self->{index};
 990                 my $x = command_oneline('write-tree');
 991                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
 992                            /^tree ($::sha1)/mo);
 993                 if ($y ne $x) {
 994                         unlink $self->{index} or croak $!;
 995                         command_noisy('read-tree', $treeish);
 996                 }
 997                 $x = command_oneline('write-tree');
 998                 if ($y ne $x) {
 999                         ::fatal "trees ($treeish) $y != $x\n",
1000                                 "Something is seriously wrong...\n";
1001                 }
1002         });
1003 }
1004
1005 sub get_commit_parents {
1006         my ($self, $log_entry, @parents) = @_;
1007         my (%seen, @ret, @tmp);
1008         # commit parents can be conditionally bound to a particular
1009         # svn revision via: "svn_revno=commit_sha1", filter them out here:
1010         foreach my $p (@parents) {
1011                 next unless defined $p;
1012                 if ($p =~ /^(\d+)=($::sha1_short)$/o) {
1013                         push @tmp, $2 if $1 == $log_entry->{revision};
1014                 } else {
1015                         push @tmp, $p if $p =~ /^$::sha1_short$/o;
1016                 }
1017         }
1018         if (my $cur = ::verify_ref($self->refname.'^0')) {
1019                 push @tmp, $cur;
1020         }
1021         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
1022         while (my $p = shift @tmp) {
1023                 next if $seen{$p};
1024                 $seen{$p} = 1;
1025                 push @ret, $p;
1026                 # MAXPARENT is defined to 16 in commit-tree.c:
1027                 last if @ret >= 16;
1028         }
1029         if (@tmp) {
1030                 die "r$log_entry->{revision}: No room for parents:\n\t",
1031                     join("\n\t", @tmp), "\n";
1032         }
1033         @ret;
1034 }
1035
1036 sub full_url {
1037         my ($self) = @_;
1038         $self->ra->{url} . (length $self->{path} ? '/' . $self->{path} : '');
1039 }
1040
1041 sub do_git_commit {
1042         my ($self, $log_entry, @parents) = @_;
1043         if (my $c = $self->rev_db_get($log_entry->{revision})) {
1044                 croak "$log_entry->{revision} = $c already exists! ",
1045                       "Why are we refetching it?\n";
1046         }
1047         my $author = $log_entry->{author};
1048         my ($name, $email) = (defined $::users{$author} ? @{$::users{$author}}
1049                            : ($author, "$author\@".$self->ra->uuid));
1050         $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $name;
1051         $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} = $email;
1052         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1053
1054         my $tree = $log_entry->{tree};
1055         if (!defined $tree) {
1056                 $tree = $self->tmp_index_do(sub {
1057                                             command_oneline('write-tree') });
1058         }
1059         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1060
1061         my @exec = ('git-commit-tree', $tree);
1062         foreach ($self->get_commit_parents($log_entry, @parents)) {
1063                 push @exec, '-p', $_;
1064         }
1065         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1066                                                                    or croak $!;
1067         print $msg_fh $log_entry->{log} or croak $!;
1068         print $msg_fh "\ngit-svn-id: ", $self->full_url, '@',
1069                       $log_entry->{revision}, ' ',
1070                       $self->ra->uuid, "\n" or croak $!;
1071         $msg_fh->flush == 0 or croak $!;
1072         close $msg_fh or croak $!;
1073         chomp(my $commit = do { local $/; <$out_fh> });
1074         close $out_fh or croak $!;
1075         waitpid $pid, 0;
1076         croak $? if $?;
1077         if ($commit !~ /^$::sha1$/o) {
1078                 die "Failed to commit, invalid sha1: $commit\n";
1079         }
1080
1081         command_noisy('update-ref',$self->refname, $commit);
1082         $self->rev_db_set($log_entry->{revision}, $commit);
1083
1084         $self->{last_rev} = $log_entry->{revision};
1085         $self->{last_commit} = $commit;
1086         print "r$log_entry->{revision} = $commit\n";
1087         return $commit;
1088 }
1089
1090 sub revisions_eq {
1091         my ($self, $r0, $r1) = @_;
1092         return 1 if $r0 == $r1;
1093         my $nr = 0;
1094         $self->ra->get_log([$self->{path}], $r0, $r1,
1095                            0, 0, 1, sub { $nr++ });
1096         return 0 if ($nr > 1);
1097         return 1;
1098 }
1099
1100 sub find_parent_branch {
1101         my ($self, $paths, $rev) = @_;
1102         return undef unless $::_follow_parent;
1103
1104         # look for a parent from another branch:
1105         my @b_path_components = split m#/#, $self->rel_path;
1106         my @a_path_components;
1107         my $i;
1108         while (@b_path_components) {
1109                 $i = $paths->{'/'.join('/', @b_path_components)};
1110                 last if $i;
1111                 unshift(@a_path_components, pop(@b_path_components));
1112         }
1113         goto not_found unless defined $i;
1114         my $branch_from = $i->copyfrom_path or goto not_found;
1115         if (@a_path_components) {
1116                 print STDERR "branch_from: $branch_from => ";
1117                 $branch_from .= '/'.join('/', @a_path_components);
1118                 print STDERR $branch_from, "\n";
1119         }
1120         my $r = $i->copyfrom_rev;
1121         my $repos_root = $self->ra->{repos_root};
1122         my $url = $self->ra->{url};
1123         my $new_url = $repos_root . $branch_from;
1124         print STDERR  "Found possible branch point: ",
1125                       "$new_url => ", $self->full_url, ", $r\n";
1126         $branch_from =~ s#^/##;
1127         my $remotes = read_all_remotes();
1128         my $gs;
1129         foreach my $repo_id (keys %$remotes) {
1130                 my $u = $remotes->{$repo_id}->{url} or next;
1131                 next if $url ne $u;
1132                 my $fetch = $remotes->{$repo_id}->{fetch};
1133                 foreach my $f (keys %$fetch) {
1134                         next if $f ne $branch_from;
1135                         $gs = Git::SVN->new($fetch->{$f}, $repo_id, $f);
1136                         last;
1137                 }
1138                 last if $gs;
1139         }
1140         unless ($gs) {
1141                 my $ref_id = $branch_from;
1142                 $ref_id .= "\@$r" if find_ref($ref_id);
1143                 # just grow a tail if we're not unique enough :x
1144                 $ref_id .= '-' while find_ref($ref_id);
1145                 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id);
1146         }
1147         my ($r0, $parent) = $gs->find_rev_before($r, 1);
1148         if ($::_follow_parent && (!defined $r0 || !defined $parent)) {
1149                 $gs->ra->get_log([$gs->{path}], 0, $r, 0, 1, 1, sub {
1150                         my ($paths, $rev) = @_;
1151                         my $log_entry = eval { $gs->do_fetch($paths, $rev) };
1152                         $gs->do_git_commit($log_entry) if $log_entry;
1153                 });
1154                 ($r0, $parent) = $gs->last_rev_commit;
1155         }
1156         if (defined $r0 && defined $parent && $gs->revisions_eq($r0, $r)) {
1157                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1158                 $self->assert_index_clean($parent);
1159                 my $ed;
1160                 if ($self->ra->can_do_switch) {
1161                         print STDERR "Following parent with do_switch\n";
1162                         # do_switch works with svn/trunk >= r22312, but that
1163                         # is not included with SVN 1.4.2 (the latest version
1164                         # at the moment), so we can't rely on it
1165                         $self->{last_commit} = $parent;
1166                         $ed = SVN::Git::Fetcher->new($self);
1167                         $gs->ra->gs_do_switch($r0, $rev, $gs->{path}, 1,
1168                                               $self->full_url, $ed)
1169                           or die "SVN connection failed somewhere...\n";
1170                 } else {
1171                         print STDERR "Following parent with do_update\n";
1172                         $ed = SVN::Git::Fetcher->new($self);
1173                         $self->ra->gs_do_update($rev, $rev, $self->{path},
1174                                                 1, $ed)
1175                           or die "SVN connection failed somewhere...\n";
1176                 }
1177                 return $self->make_log_entry($rev, [$parent], $ed);
1178         }
1179 not_found:
1180         print STDERR "Branch parent for path: '/",
1181                      $self->rel_path, "' not found\n";
1182         return undef unless $paths;
1183         foreach my $x (sort keys %$paths) {
1184                 my $p = $paths->{$x};
1185                 print STDERR '  ', $p->action, '  ', $x;
1186                 if (my $cp_from = $p->copyfrom_path) {
1187                         print STDERR "(from $cp_from:", $p->copyfrom_rev, ')';
1188                 }
1189                 print STDERR "\n";
1190         }
1191         return undef;
1192 }
1193
1194 sub do_fetch {
1195         my ($self, $paths, $rev) = @_;
1196         my $ed;
1197         my ($last_rev, @parents);
1198         if ($self->{last_commit}) {
1199                 $ed = SVN::Git::Fetcher->new($self);
1200                 $last_rev = $self->{last_rev};
1201                 $ed->{c} = $self->{last_commit};
1202                 @parents = ($self->{last_commit});
1203         } else {
1204                 $last_rev = $rev;
1205                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1206                         return $log_entry;
1207                 }
1208                 $ed = SVN::Git::Fetcher->new($self);
1209         }
1210         unless ($self->ra->gs_do_update($last_rev, $rev,
1211                                         $self->{path}, 1, $ed)) {
1212                 die "SVN connection failed somewhere...\n";
1213         }
1214         $self->make_log_entry($rev, \@parents, $ed);
1215 }
1216
1217 sub get_untracked {
1218         my ($self, $ed) = @_;
1219         my @out;
1220         my $h = $ed->{empty};
1221         foreach (sort keys %$h) {
1222                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1223                 push @out, "  $act: " . uri_encode($_);
1224                 warn "W: $act: $_\n";
1225         }
1226         foreach my $t (qw/dir_prop file_prop/) {
1227                 $h = $ed->{$t} or next;
1228                 foreach my $path (sort keys %$h) {
1229                         my $ppath = $path eq '' ? '.' : $path;
1230                         foreach my $prop (sort keys %{$h->{$path}}) {
1231                                 next if $SKIP_PROP{$prop};
1232                                 my $v = $h->{$path}->{$prop};
1233                                 my $t_ppath_prop = "$t: " .
1234                                                     uri_encode($ppath) . ' ' .
1235                                                     uri_encode($prop);
1236                                 if (defined $v) {
1237                                         push @out, "  +$t_ppath_prop " .
1238                                                    uri_encode($v);
1239                                 } else {
1240                                         push @out, "  -$t_ppath_prop";
1241                                 }
1242                         }
1243                 }
1244         }
1245         foreach my $t (qw/absent_file absent_directory/) {
1246                 $h = $ed->{$t} or next;
1247                 foreach my $parent (sort keys %$h) {
1248                         foreach my $path (sort @{$h->{$parent}}) {
1249                                 push @out, "  $t: " .
1250                                            uri_encode("$parent/$path");
1251                                 warn "W: $t: $parent/$path ",
1252                                      "Insufficient permissions?\n";
1253                         }
1254                 }
1255         }
1256         \@out;
1257 }
1258
1259 sub parse_svn_date {
1260         my $date = shift || return '+0000 1970-01-01 00:00:00';
1261         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1262                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1263                                          croak "Unable to parse date: $date\n";
1264         "+0000 $Y-$m-$d $H:$M:$S";
1265 }
1266
1267 sub check_author {
1268         my ($author) = @_;
1269         if (!defined $author || length $author == 0) {
1270                 $author = '(no author)';
1271         }
1272         if (defined $::_authors && ! defined $::users{$author}) {
1273                 die "Author: $author not defined in $::_authors file\n";
1274         }
1275         $author;
1276 }
1277
1278 sub make_log_entry {
1279         my ($self, $rev, $parents, $ed) = @_;
1280         my $untracked = $self->get_untracked($ed);
1281
1282         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1283         print $un "r$rev\n" or croak $!;
1284         print $un $_, "\n" foreach @$untracked;
1285         my %log_entry = ( parents => $parents || [], revision => $rev,
1286                           log => '');
1287         my $rp = $self->ra->rev_proplist($rev);
1288         foreach (sort keys %$rp) {
1289                 my $v = $rp->{$_};
1290                 if (/^svn:(author|date|log)$/) {
1291                         $log_entry{$1} = $v;
1292                 } else {
1293                         print $un "  rev_prop: ", uri_encode($_), ' ',
1294                                   uri_encode($v), "\n";
1295                 }
1296         }
1297         close $un or croak $!;
1298
1299         delete $rp->{'svn:date'}; # this is the only revprop for r0
1300         return undef if ($ed->{nr} == 0 && scalar @$untracked == 0 &&
1301                          scalar keys %$rp == 0);
1302
1303         $log_entry{date} = parse_svn_date($log_entry{date});
1304         $log_entry{author} = check_author($log_entry{author});
1305         $log_entry{log} .= "\n";
1306         \%log_entry;
1307 }
1308
1309 sub fetch {
1310         my ($self, @parents) = @_;
1311         my ($last_rev, $last_commit) = $self->last_rev_commit;
1312         my ($base, $head) = $self->parse_revision($last_rev);
1313         return if ($base > $head);
1314         if (defined $last_commit) {
1315                 $self->assert_index_clean($last_commit);
1316         }
1317         my $inc = 1000;
1318         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
1319         my $err_handler = $SVN::Error::handler;
1320         $SVN::Error::handler = \&skip_unknown_revs;
1321         while (1) {
1322                 my @revs;
1323                 $self->ra->get_log([$self->{path}], $min, $max, 0, 1, 1, sub {
1324                         my ($paths, $rev, $author, $date, $log) = @_;
1325                         push @revs, [ $paths, $rev ] });
1326                 foreach (@revs) {
1327                         if (my $log_entry = $self->do_fetch(@$_)) {
1328                                 $self->do_git_commit($log_entry, @parents);
1329                         }
1330                 }
1331                 last if $max >= $head;
1332                 $min = $max + 1;
1333                 $max += $inc;
1334                 $max = $head if ($max > $head);
1335         }
1336         $SVN::Error::handler = $err_handler;
1337 }
1338
1339 sub set_tree_cb {
1340         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1341         # TODO: enable and test optimized commits:
1342         if (0 && $rev == ($self->{last_rev} + 1)) {
1343                 $log_entry->{revision} = $rev;
1344                 $log_entry->{author} = $author;
1345                 $self->do_git_commit($log_entry, "$rev=$tree");
1346         } else {
1347                 $self->fetch("$rev=$tree");
1348         }
1349 }
1350
1351 sub set_tree {
1352         my ($self, $tree) = (shift, shift);
1353         my $log_entry = ::get_commit_entry($tree);
1354         unless ($self->{last_rev}) {
1355                 fatal("Must have an existing revision to commit\n");
1356         }
1357         my $pool = SVN::Pool->new;
1358         my $ed = SVN::Git::Editor->new({ r => $self->{last_rev},
1359                                          ra => $self->ra->dup,
1360                                          svn_path => $self->ra->{svn_path}
1361                                        },
1362                                        $self->ra->get_commit_editor(
1363                                          $log_entry->{log}, sub {
1364                                            $self->set_tree_cb($log_entry,
1365                                                               $tree, @_);
1366                                        }),
1367                                        $pool);
1368         my $mods = $ed->apply_diff($self->{last_commit}, $tree);
1369         if (@$mods == 0) {
1370                 print "No changes\nr$self->{last_rev} = $tree\n";
1371         }
1372         $pool->clear;
1373 }
1374
1375 sub skip_unknown_revs {
1376         my ($err) = @_;
1377         my $errno = $err->apr_err();
1378         # Maybe the branch we're tracking didn't
1379         # exist when the repo started, so it's
1380         # not an error if it doesn't, just continue
1381         #
1382         # Wonderfully consistent library, eh?
1383         # 160013 - svn:// and file://
1384         # 175002 - http(s)://
1385         # 175007 - http(s):// (this repo required authorization, too...)
1386         #   More codes may be discovered later...
1387         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
1388                 return;
1389         }
1390         croak "Error from SVN, ($errno): ", $err->expanded_message,"\n";
1391 }
1392
1393 # rev_db:
1394 # Tie::File seems to be prone to offset errors if revisions get sparse,
1395 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
1396 # one of my favorite modules is out :<  Next up would be one of the DBM
1397 # modules, but I'm not sure which is most portable...  So I'll just
1398 # go with something that's plain-text, but still capable of
1399 # being randomly accessed.  So here's my ultra-simple fixed-width
1400 # database.  All records are 40 characters + "\n", so it's easy to seek
1401 # to a revision: (41 * rev) is the byte offset.
1402 # A record of 40 0s denotes an empty revision.
1403 # And yes, it's still pretty fast (faster than Tie::File).
1404
1405 sub rev_db_set {
1406         my ($self, $rev, $commit) = @_;
1407         length $commit == 40 or croak "arg3 must be a full SHA1 hexsum\n";
1408         open my $fh, '+<', $self->{db_path} or croak $!;
1409         my $offset = $rev * 41;
1410         # assume that append is the common case:
1411         seek $fh, 0, 2 or croak $!;
1412         my $pos = tell $fh;
1413         if ($pos < $offset) {
1414                 print $fh (('0' x 40),"\n") x (($offset - $pos) / 41)
1415                   or croak $!;
1416         }
1417         seek $fh, $offset, 0 or croak $!;
1418         print $fh $commit,"\n" or croak $!;
1419         close $fh or croak $!;
1420 }
1421
1422 sub rev_db_get {
1423         my ($self, $rev) = @_;
1424         my $ret;
1425         my $offset = $rev * 41;
1426         open my $fh, '<', $self->{db_path} or croak $!;
1427         if (seek $fh, $offset, 0) {
1428                 $ret = readline $fh;
1429                 if (defined $ret) {
1430                         chomp $ret;
1431                         $ret = undef if ($ret =~ /^0{40}$/);
1432                 }
1433         }
1434         close $fh or croak $!;
1435         $ret;
1436 }
1437
1438 sub find_rev_before {
1439         my ($self, $rev, $eq_ok) = @_;
1440         --$rev unless $eq_ok;
1441         while ($rev > 0) {
1442                 if (my $c = $self->rev_db_get($rev)) {
1443                         return ($rev, $c);
1444                 }
1445                 --$rev;
1446         }
1447         return (undef, undef);
1448 }
1449
1450 sub _new {
1451         my ($class, $repo_id, $ref_id, $path) = @_;
1452         unless (defined $repo_id && length $repo_id) {
1453                 $repo_id = $Git::SVN::default_repo_id;
1454         }
1455         unless (defined $ref_id && length $ref_id) {
1456                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
1457         }
1458         $_[1] = $repo_id = sanitize_remote_name($repo_id);
1459         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
1460         $_[3] = $path = '' unless (defined $path);
1461         mkpath([$dir]);
1462         unless (-f "$dir/.rev_db") {
1463                 open my $fh, '>>', "$dir/.rev_db" or croak $!;
1464                 close $fh or croak $!;
1465         }
1466         bless { ref_id => $ref_id, dir => $dir, index => "$dir/index",
1467                 path => $path,
1468                 db_path => "$dir/.rev_db", repo_id => $repo_id }, $class;
1469 }
1470
1471 sub uri_encode {
1472         my ($f) = @_;
1473         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1474         $f
1475 }
1476
1477 package Git::SVN::Prompt;
1478 use strict;
1479 use warnings;
1480 require SVN::Core;
1481 use vars qw/$_no_auth_cache $_username/;
1482
1483 sub simple {
1484         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
1485         $may_save = undef if $_no_auth_cache;
1486         $default_username = $_username if defined $_username;
1487         if (defined $default_username && length $default_username) {
1488                 if (defined $realm && length $realm) {
1489                         print STDERR "Authentication realm: $realm\n";
1490                         STDERR->flush;
1491                 }
1492                 $cred->username($default_username);
1493         } else {
1494                 username($cred, $realm, $may_save, $pool);
1495         }
1496         $cred->password(_read_password("Password for '" .
1497                                        $cred->username . "': ", $realm));
1498         $cred->may_save($may_save);
1499         $SVN::_Core::SVN_NO_ERROR;
1500 }
1501
1502 sub ssl_server_trust {
1503         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
1504         $may_save = undef if $_no_auth_cache;
1505         print STDERR "Error validating server certificate for '$realm':\n";
1506         if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
1507                 print STDERR " - The certificate is not issued by a trusted ",
1508                       "authority. Use the\n",
1509                       "   fingerprint to validate the certificate manually!\n";
1510         }
1511         if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
1512                 print STDERR " - The certificate hostname does not match.\n";
1513         }
1514         if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
1515                 print STDERR " - The certificate is not yet valid.\n";
1516         }
1517         if ($failures & $SVN::Auth::SSL::EXPIRED) {
1518                 print STDERR " - The certificate has expired.\n";
1519         }
1520         if ($failures & $SVN::Auth::SSL::OTHER) {
1521                 print STDERR " - The certificate has an unknown error.\n";
1522         }
1523         printf STDERR
1524                 "Certificate information:\n".
1525                 " - Hostname: %s\n".
1526                 " - Valid: from %s until %s\n".
1527                 " - Issuer: %s\n".
1528                 " - Fingerprint: %s\n",
1529                 map $cert_info->$_, qw(hostname valid_from valid_until
1530                                        issuer_dname fingerprint);
1531         my $choice;
1532 prompt:
1533         print STDERR $may_save ?
1534               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
1535               "(R)eject or accept (t)emporarily? ";
1536         STDERR->flush;
1537         $choice = lc(substr(<STDIN> || 'R', 0, 1));
1538         if ($choice =~ /^t$/i) {
1539                 $cred->may_save(undef);
1540         } elsif ($choice =~ /^r$/i) {
1541                 return -1;
1542         } elsif ($may_save && $choice =~ /^p$/i) {
1543                 $cred->may_save($may_save);
1544         } else {
1545                 goto prompt;
1546         }
1547         $cred->accepted_failures($failures);
1548         $SVN::_Core::SVN_NO_ERROR;
1549 }
1550
1551 sub ssl_client_cert {
1552         my ($cred, $realm, $may_save, $pool) = @_;
1553         $may_save = undef if $_no_auth_cache;
1554         print STDERR "Client certificate filename: ";
1555         STDERR->flush;
1556         chomp(my $filename = <STDIN>);
1557         $cred->cert_file($filename);
1558         $cred->may_save($may_save);
1559         $SVN::_Core::SVN_NO_ERROR;
1560 }
1561
1562 sub ssl_client_cert_pw {
1563         my ($cred, $realm, $may_save, $pool) = @_;
1564         $may_save = undef if $_no_auth_cache;
1565         $cred->password(_read_password("Password: ", $realm));
1566         $cred->may_save($may_save);
1567         $SVN::_Core::SVN_NO_ERROR;
1568 }
1569
1570 sub username {
1571         my ($cred, $realm, $may_save, $pool) = @_;
1572         $may_save = undef if $_no_auth_cache;
1573         if (defined $realm && length $realm) {
1574                 print STDERR "Authentication realm: $realm\n";
1575         }
1576         my $username;
1577         if (defined $_username) {
1578                 $username = $_username;
1579         } else {
1580                 print STDERR "Username: ";
1581                 STDERR->flush;
1582                 chomp($username = <STDIN>);
1583         }
1584         $cred->username($username);
1585         $cred->may_save($may_save);
1586         $SVN::_Core::SVN_NO_ERROR;
1587 }
1588
1589 sub _read_password {
1590         my ($prompt, $realm) = @_;
1591         print STDERR $prompt;
1592         STDERR->flush;
1593         require Term::ReadKey;
1594         Term::ReadKey::ReadMode('noecho');
1595         my $password = '';
1596         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
1597                 last if $key =~ /[\012\015]/; # \n\r
1598                 $password .= $key;
1599         }
1600         Term::ReadKey::ReadMode('restore');
1601         print STDERR "\n";
1602         STDERR->flush;
1603         $password;
1604 }
1605
1606 package main;
1607
1608 sub uri_encode {
1609         my ($f) = @_;
1610         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1611         $f
1612 }
1613
1614 sub uri_decode {
1615         my ($f) = @_;
1616         $f =~ tr/+/ /;
1617         $f =~ s/%([A-F0-9]{2})/chr hex($1)/ge;
1618         $f
1619 }
1620
1621 {
1622         my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
1623                                 $SVN::Node::dir.$SVN::Node::unknown.
1624                                 $SVN::Node::none.$SVN::Node::file.
1625                                 $SVN::Node::dir.$SVN::Node::unknown.
1626                                 $SVN::Auth::SSL::CNMISMATCH.
1627                                 $SVN::Auth::SSL::NOTYETVALID.
1628                                 $SVN::Auth::SSL::EXPIRED.
1629                                 $SVN::Auth::SSL::UNKNOWNCA.
1630                                 $SVN::Auth::SSL::OTHER;
1631 }
1632
1633 package SVN::Git::Fetcher;
1634 use vars qw/@ISA/;
1635 use strict;
1636 use warnings;
1637 use Carp qw/croak/;
1638 use IO::File qw//;
1639
1640 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
1641 sub new {
1642         my ($class, $git_svn) = @_;
1643         my $self = SVN::Delta::Editor->new;
1644         bless $self, $class;
1645         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
1646         $self->{empty} = {};
1647         $self->{dir_prop} = {};
1648         $self->{file_prop} = {};
1649         $self->{absent_dir} = {};
1650         $self->{absent_file} = {};
1651         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
1652         require Digest::MD5;
1653         $self;
1654 }
1655
1656 sub set_path_strip {
1657         my ($self, $path) = @_;
1658         $self->{path_strip} = qr/^\Q$path\E\/?/;
1659 }
1660
1661 sub open_root {
1662         { path => '' };
1663 }
1664
1665 sub open_directory {
1666         my ($self, $path, $pb, $rev) = @_;
1667         { path => $path };
1668 }
1669
1670 sub git_path {
1671         my ($self, $path) = @_;
1672         $path =~ s!$self->{path_strip}!! if $self->{path_strip};
1673         $path;
1674 }
1675
1676 sub delete_entry {
1677         my ($self, $path, $rev, $pb) = @_;
1678
1679         my $gpath = $self->git_path($path);
1680         # remove entire directories.
1681         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
1682                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
1683                                                      -r --name-only -z/,
1684                                                      $self->{c}, '--', $gpath);
1685                 local $/ = "\0";
1686                 while (<$ls>) {
1687                         chomp;
1688                         $self->{gii}->remove($_);
1689                         print "\tD\t$_\n" unless $self->{q};
1690                 }
1691                 print "\tD\t$gpath/\n" unless $self->{q};
1692                 command_close_pipe($ls, $ctx);
1693                 $self->{empty}->{$path} = 0
1694         } else {
1695                 $self->{gii}->remove($gpath);
1696                 print "\tD\t$gpath\n" unless $self->{q};
1697         }
1698         undef;
1699 }
1700
1701 sub open_file {
1702         my ($self, $path, $pb, $rev) = @_;
1703         my $gpath = $self->git_path($path);
1704         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
1705                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
1706         unless (defined $mode && defined $blob) {
1707                 die "$path was not found in commit $self->{c} (r$rev)\n";
1708         }
1709         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
1710           pool => SVN::Pool->new, action => 'M' };
1711 }
1712
1713 sub add_file {
1714         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
1715         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1716         delete $self->{empty}->{$dir};
1717         { path => $path, mode_a => 100644, mode_b => 100644,
1718           pool => SVN::Pool->new, action => 'A' };
1719 }
1720
1721 sub add_directory {
1722         my ($self, $path, $cp_path, $cp_rev) = @_;
1723         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1724         delete $self->{empty}->{$dir};
1725         $self->{empty}->{$path} = 1;
1726         { path => $path };
1727 }
1728
1729 sub change_dir_prop {
1730         my ($self, $db, $prop, $value) = @_;
1731         $self->{dir_prop}->{$db->{path}} ||= {};
1732         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
1733         undef;
1734 }
1735
1736 sub absent_directory {
1737         my ($self, $path, $pb) = @_;
1738         $self->{absent_dir}->{$pb->{path}} ||= [];
1739         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
1740         undef;
1741 }
1742
1743 sub absent_file {
1744         my ($self, $path, $pb) = @_;
1745         $self->{absent_file}->{$pb->{path}} ||= [];
1746         push @{$self->{absent_file}->{$pb->{path}}}, $path;
1747         undef;
1748 }
1749
1750 sub change_file_prop {
1751         my ($self, $fb, $prop, $value) = @_;
1752         if ($prop eq 'svn:executable') {
1753                 if ($fb->{mode_b} != 120000) {
1754                         $fb->{mode_b} = defined $value ? 100755 : 100644;
1755                 }
1756         } elsif ($prop eq 'svn:special') {
1757                 $fb->{mode_b} = defined $value ? 120000 : 100644;
1758         } else {
1759                 $self->{file_prop}->{$fb->{path}} ||= {};
1760                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
1761         }
1762         undef;
1763 }
1764
1765 sub apply_textdelta {
1766         my ($self, $fb, $exp) = @_;
1767         my $fh = IO::File->new_tmpfile;
1768         $fh->autoflush(1);
1769         # $fh gets auto-closed() by SVN::TxDelta::apply(),
1770         # (but $base does not,) so dup() it for reading in close_file
1771         open my $dup, '<&', $fh or croak $!;
1772         my $base = IO::File->new_tmpfile;
1773         $base->autoflush(1);
1774         if ($fb->{blob}) {
1775                 defined (my $pid = fork) or croak $!;
1776                 if (!$pid) {
1777                         open STDOUT, '>&', $base or croak $!;
1778                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
1779                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
1780                 }
1781                 waitpid $pid, 0;
1782                 croak $? if $?;
1783
1784                 if (defined $exp) {
1785                         seek $base, 0, 0 or croak $!;
1786                         my $md5 = Digest::MD5->new;
1787                         $md5->addfile($base);
1788                         my $got = $md5->hexdigest;
1789                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
1790                             "expected: $exp\n",
1791                             "     got: $got\n" if ($got ne $exp);
1792                 }
1793         }
1794         seek $base, 0, 0 or croak $!;
1795         $fb->{fh} = $dup;
1796         $fb->{base} = $base;
1797         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
1798 }
1799
1800 sub close_file {
1801         my ($self, $fb, $exp) = @_;
1802         my $hash;
1803         my $path = $self->git_path($fb->{path});
1804         if (my $fh = $fb->{fh}) {
1805                 seek($fh, 0, 0) or croak $!;
1806                 my $md5 = Digest::MD5->new;
1807                 $md5->addfile($fh);
1808                 my $got = $md5->hexdigest;
1809                 die "Checksum mismatch: $path\n",
1810                     "expected: $exp\n    got: $got\n" if ($got ne $exp);
1811                 seek($fh, 0, 0) or croak $!;
1812                 if ($fb->{mode_b} == 120000) {
1813                         read($fh, my $buf, 5) == 5 or croak $!;
1814                         $buf eq 'link ' or die "$path has mode 120000",
1815                                                "but is not a link\n";
1816                 }
1817                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
1818                 if (!$pid) {
1819                         open STDIN, '<&', $fh or croak $!;
1820                         exec qw/git-hash-object -w --stdin/ or croak $!;
1821                 }
1822                 chomp($hash = do { local $/; <$out> });
1823                 close $out or croak $!;
1824                 close $fh or croak $!;
1825                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
1826                 close $fb->{base} or croak $!;
1827         } else {
1828                 $hash = $fb->{blob} or die "no blob information\n";
1829         }
1830         $fb->{pool}->clear;
1831         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
1832         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $self->{q};
1833         undef;
1834 }
1835
1836 sub abort_edit {
1837         my $self = shift;
1838         $self->{nr} = $self->{gii}->{nr};
1839         delete $self->{gii};
1840         $self->SUPER::abort_edit(@_);
1841 }
1842
1843 sub close_edit {
1844         my $self = shift;
1845         $self->{git_commit_ok} = 1;
1846         $self->{nr} = $self->{gii}->{nr};
1847         delete $self->{gii};
1848         $self->SUPER::close_edit(@_);
1849 }
1850
1851 package SVN::Git::Editor;
1852 use vars qw/@ISA/;
1853 use strict;
1854 use warnings;
1855 use Carp qw/croak/;
1856 use IO::File;
1857
1858 sub new {
1859         my $class = shift;
1860         my $git_svn = shift;
1861         my $self = SVN::Delta::Editor->new(@_);
1862         bless $self, $class;
1863         foreach (qw/svn_path r ra/) {
1864                 die "$_ required!\n" unless (defined $git_svn->{$_});
1865                 $self->{$_} = $git_svn->{$_};
1866         }
1867         $self->{pool} = SVN::Pool->new;
1868         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
1869         $self->{rm} = { };
1870         require Digest::MD5;
1871         return $self;
1872 }
1873
1874 sub split_path {
1875         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
1876 }
1877
1878 sub repo_path {
1879         (defined $_[1] && length $_[1]) ? $_[1] : ''
1880 }
1881
1882 sub url_path {
1883         my ($self, $path) = @_;
1884         $self->{ra}->{url} . '/' . $self->repo_path($path);
1885 }
1886
1887 sub rmdirs {
1888         my ($self, $tree_b) = @_;
1889         my $rm = $self->{rm};
1890         delete $rm->{''}; # we never delete the url we're tracking
1891         return unless %$rm;
1892
1893         foreach (keys %$rm) {
1894                 my @d = split m#/#, $_;
1895                 my $c = shift @d;
1896                 $rm->{$c} = 1;
1897                 while (@d) {
1898                         $c .= '/' . shift @d;
1899                         $rm->{$c} = 1;
1900                 }
1901         }
1902         delete $rm->{$self->{svn_path}};
1903         delete $rm->{''}; # we never delete the url we're tracking
1904         return unless %$rm;
1905
1906         my ($fh, $ctx) = command_output_pipe(
1907                                    qw/ls-tree --name-only -r -z/, $tree_b);
1908         local $/ = "\0";
1909         while (<$fh>) {
1910                 chomp;
1911                 my @dn = split m#/#, $_;
1912                 while (pop @dn) {
1913                         delete $rm->{join '/', @dn};
1914                 }
1915                 unless (%$rm) {
1916                         close $fh;
1917                         return;
1918                 }
1919         }
1920         command_close_pipe($fh, $ctx);
1921
1922         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
1923         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
1924                 $self->close_directory($bat->{$d}, $p);
1925                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
1926                 print "\tD+\t$d/\n" unless $::_q;
1927                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
1928                 delete $bat->{$d};
1929         }
1930 }
1931
1932 sub open_or_add_dir {
1933         my ($self, $full_path, $baton) = @_;
1934         my $t = $self->{ra}->check_path($full_path, $self->{r});
1935         if ($t == $SVN::Node::none) {
1936                 return $self->add_directory($full_path, $baton,
1937                                                 undef, -1, $self->{pool});
1938         } elsif ($t == $SVN::Node::dir) {
1939                 return $self->open_directory($full_path, $baton,
1940                                                 $self->{r}, $self->{pool});
1941         }
1942         print STDERR "$full_path already exists in repository at ",
1943                 "r$self->{r} and it is not a directory (",
1944                 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
1945         exit 1;
1946 }
1947
1948 sub ensure_path {
1949         my ($self, $path) = @_;
1950         my $bat = $self->{bat};
1951         $path = $self->repo_path($path);
1952         return $bat->{''} unless (length $path);
1953         my @p = split m#/+#, $path;
1954         my $c = shift @p;
1955         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
1956         while (@p) {
1957                 my $c0 = $c;
1958                 $c .= '/' . shift @p;
1959                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
1960         }
1961         return $bat->{$c};
1962 }
1963
1964 sub A {
1965         my ($self, $m) = @_;
1966         my ($dir, $file) = split_path($m->{file_b});
1967         my $pbat = $self->ensure_path($dir);
1968         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
1969                                         undef, -1);
1970         print "\tA\t$m->{file_b}\n" unless $::_q;
1971         $self->chg_file($fbat, $m);
1972         $self->close_file($fbat,undef,$self->{pool});
1973 }
1974
1975 sub C {
1976         my ($self, $m) = @_;
1977         my ($dir, $file) = split_path($m->{file_b});
1978         my $pbat = $self->ensure_path($dir);
1979         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
1980                                 $self->url_path($m->{file_a}), $self->{r});
1981         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
1982         $self->chg_file($fbat, $m);
1983         $self->close_file($fbat,undef,$self->{pool});
1984 }
1985
1986 sub delete_entry {
1987         my ($self, $path, $pbat) = @_;
1988         my $rpath = $self->repo_path($path);
1989         my ($dir, $file) = split_path($rpath);
1990         $self->{rm}->{$dir} = 1;
1991         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
1992 }
1993
1994 sub R {
1995         my ($self, $m) = @_;
1996         my ($dir, $file) = split_path($m->{file_b});
1997         my $pbat = $self->ensure_path($dir);
1998         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
1999                                 $self->url_path($m->{file_a}), $self->{r});
2000         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2001         $self->chg_file($fbat, $m);
2002         $self->close_file($fbat,undef,$self->{pool});
2003
2004         ($dir, $file) = split_path($m->{file_a});
2005         $pbat = $self->ensure_path($dir);
2006         $self->delete_entry($m->{file_a}, $pbat);
2007 }
2008
2009 sub M {
2010         my ($self, $m) = @_;
2011         my ($dir, $file) = split_path($m->{file_b});
2012         my $pbat = $self->ensure_path($dir);
2013         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2014                                 $pbat,$self->{r},$self->{pool});
2015         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2016         $self->chg_file($fbat, $m);
2017         $self->close_file($fbat,undef,$self->{pool});
2018 }
2019
2020 sub T { shift->M(@_) }
2021
2022 sub change_file_prop {
2023         my ($self, $fbat, $pname, $pval) = @_;
2024         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2025 }
2026
2027 sub chg_file {
2028         my ($self, $fbat, $m) = @_;
2029         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2030                 $self->change_file_prop($fbat,'svn:executable','*');
2031         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2032                 $self->change_file_prop($fbat,'svn:executable',undef);
2033         }
2034         my $fh = IO::File->new_tmpfile or croak $!;
2035         if ($m->{mode_b} =~ /^120/) {
2036                 print $fh 'link ' or croak $!;
2037                 $self->change_file_prop($fbat,'svn:special','*');
2038         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2039                 $self->change_file_prop($fbat,'svn:special',undef);
2040         }
2041         defined(my $pid = fork) or croak $!;
2042         if (!$pid) {
2043                 open STDOUT, '>&', $fh or croak $!;
2044                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2045         }
2046         waitpid $pid, 0;
2047         croak $? if $?;
2048         $fh->flush == 0 or croak $!;
2049         seek $fh, 0, 0 or croak $!;
2050
2051         my $md5 = Digest::MD5->new;
2052         $md5->addfile($fh) or croak $!;
2053         seek $fh, 0, 0 or croak $!;
2054
2055         my $exp = $md5->hexdigest;
2056         my $pool = SVN::Pool->new;
2057         my $atd = $self->apply_textdelta($fbat, undef, $pool);
2058         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2059         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2060         $pool->clear;
2061
2062         close $fh or croak $!;
2063 }
2064
2065 sub D {
2066         my ($self, $m) = @_;
2067         my ($dir, $file) = split_path($m->{file_b});
2068         my $pbat = $self->ensure_path($dir);
2069         print "\tD\t$m->{file_b}\n" unless $::_q;
2070         $self->delete_entry($m->{file_b}, $pbat);
2071 }
2072
2073 sub close_edit {
2074         my ($self) = @_;
2075         my ($p,$bat) = ($self->{pool}, $self->{bat});
2076         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2077                 $self->close_directory($bat->{$_}, $p);
2078         }
2079         $self->SUPER::close_edit($p);
2080         $p->clear;
2081 }
2082
2083 sub abort_edit {
2084         my ($self) = @_;
2085         $self->SUPER::abort_edit($self->{pool});
2086         $self->{pool}->clear;
2087 }
2088
2089 # this drives the editor
2090 sub apply_diff {
2091         my ($self, $tree_a, $tree_b) = @_;
2092         my @diff_tree = qw(diff-tree -z -r);
2093         if ($::_cp_similarity) {
2094                 push @diff_tree, "-C$::_cp_similarity";
2095         } else {
2096                 push @diff_tree, '-C';
2097         }
2098         push @diff_tree, '--find-copies-harder' if $::_find_copies_harder;
2099         push @diff_tree, "-l$::_l" if defined $::_l;
2100         push @diff_tree, $tree_a, $tree_b;
2101         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
2102         my $nl = $/;
2103         local $/ = "\0";
2104         my $state = 'meta';
2105         my @mods;
2106         while (<$diff_fh>) {
2107                 chomp $_; # this gets rid of the trailing "\0"
2108                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
2109                                         $::sha1\s($::sha1)\s
2110                                         ([MTCRAD])\d*$/xo) {
2111                         push @mods, {   mode_a => $1, mode_b => $2,
2112                                         sha1_b => $3, chg => $4 };
2113                         if ($4 =~ /^(?:C|R)$/) {
2114                                 $state = 'file_a';
2115                         } else {
2116                                 $state = 'file_b';
2117                         }
2118                 } elsif ($state eq 'file_a') {
2119                         my $x = $mods[$#mods] or croak "Empty array\n";
2120                         if ($x->{chg} !~ /^(?:C|R)$/) {
2121                                 croak "Error parsing $_, $x->{chg}\n";
2122                         }
2123                         $x->{file_a} = $_;
2124                         $state = 'file_b';
2125                 } elsif ($state eq 'file_b') {
2126                         my $x = $mods[$#mods] or croak "Empty array\n";
2127                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
2128                                 croak "Error parsing $_, $x->{chg}\n";
2129                         }
2130                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
2131                                 croak "Error parsing $_, $x->{chg}\n";
2132                         }
2133                         $x->{file_b} = $_;
2134                         $state = 'meta';
2135                 } else {
2136                         croak "Error parsing $_\n";
2137                 }
2138         }
2139         command_close_pipe($diff_fh, $ctx);
2140         $/ = $nl;
2141
2142         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2143         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @mods) {
2144                 my $f = $m->{chg};
2145                 if (defined $o{$f}) {
2146                         $self->$f($m);
2147                 } else {
2148                         fatal("Invalid change type: $f\n");
2149                 }
2150         }
2151         $self->rmdirs($tree_b) if $::_rmdir;
2152         if (@mods == 0) {
2153                 $self->abort_edit;
2154         } else {
2155                 $self->close_edit;
2156         }
2157         \@mods;
2158 }
2159
2160 package Git::SVN::Ra;
2161 use vars qw/@ISA $config_dir/;
2162 use strict;
2163 use warnings;
2164 my ($can_do_switch);
2165 my %RA;
2166
2167 BEGIN {
2168         # enforce temporary pool usage for some simple functions
2169         my $e;
2170         foreach (qw/get_latest_revnum rev_proplist get_file
2171                     check_path get_dir get_uuid get_repos_root/) {
2172                 $e .= "sub $_ {
2173                         my \$self = shift;
2174                         my \$pool = SVN::Pool->new;
2175                         my \@ret = \$self->SUPER::$_(\@_,\$pool);
2176                         \$pool->clear;
2177                         wantarray ? \@ret : \$ret[0]; }\n";
2178         }
2179         eval $e;
2180 }
2181
2182 sub new {
2183         my ($class, $url) = @_;
2184         $url =~ s!/+$!!;
2185         return $RA{$url} if $RA{$url};
2186
2187         SVN::_Core::svn_config_ensure($config_dir, undef);
2188         my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2189             SVN::Client::get_simple_provider(),
2190             SVN::Client::get_ssl_server_trust_file_provider(),
2191             SVN::Client::get_simple_prompt_provider(
2192               \&Git::SVN::Prompt::simple, 2),
2193             SVN::Client::get_ssl_client_cert_prompt_provider(
2194               \&Git::SVN::Prompt::ssl_client_cert, 2),
2195             SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2196               \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
2197             SVN::Client::get_username_provider(),
2198             SVN::Client::get_ssl_server_trust_prompt_provider(
2199               \&Git::SVN::Prompt::ssl_server_trust),
2200             SVN::Client::get_username_prompt_provider(
2201               \&Git::SVN::Prompt::username, 2),
2202           ]);
2203         my $config = SVN::Core::config_get_config($config_dir);
2204         my $self = SVN::Ra->new(url => $url, auth => $baton,
2205                               config => $config,
2206                               pool => SVN::Pool->new,
2207                               auth_provider_callbacks => $callbacks);
2208         $self->{svn_path} = $url;
2209         $self->{repos_root} = $self->get_repos_root;
2210         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E/*##;
2211         $RA{$url} = bless $self, $class;
2212 }
2213
2214 sub DESTROY {
2215         # do not call the real DESTROY since we store ourselves in %RA
2216 }
2217
2218 sub dup {
2219         my ($self) = @_;
2220         my $dup = SVN::Ra->new(pool => SVN::Pool->new,
2221                                 map { $_ => $self->{$_} } qw/config url
2222                      auth auth_provider_callbacks repos_root svn_path/);
2223         bless $dup, ref $self;
2224 }
2225
2226 sub get_log {
2227         my ($self, @args) = @_;
2228         my $pool = SVN::Pool->new;
2229         $args[4]-- if $args[4] && ! $::_follow_parent;
2230         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
2231         my $ret = $self->SUPER::get_log(@args, $pool);
2232         $pool->clear;
2233         $ret;
2234 }
2235
2236 sub get_commit_editor {
2237         my ($self, $log, $cb, $pool) = @_;
2238         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
2239         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
2240 }
2241
2242 sub uuid {
2243         my ($self) = @_;
2244         $self->{uuid} ||= $self->get_uuid;
2245 }
2246
2247 sub gs_do_update {
2248         my ($self, $rev_a, $rev_b, $path, $recurse, $editor) = @_;
2249         my $pool = SVN::Pool->new;
2250         $editor->set_path_strip($path);
2251         my $reporter = $self->do_update($rev_b, $path, $recurse,
2252                                         $editor, $pool);
2253         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2254         my $new = ($rev_a == $rev_b);
2255         $reporter->set_path('', $rev_a, $new, @lock, $pool);
2256         $reporter->finish_report($pool);
2257         $pool->clear;
2258         $editor->{git_commit_ok};
2259 }
2260
2261 sub gs_do_switch {
2262         my ($self, $rev_a, $rev_b, $path, $recurse, $url_b, $editor) = @_;
2263         my $pool = SVN::Pool->new;
2264         $editor->set_path_strip($path);
2265         my $reporter = $self->do_switch($rev_b, $path, $recurse,
2266                                         $url_b, $editor, $pool);
2267         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2268         $reporter->set_path('', $rev_a, 0, @lock, $pool);
2269         $reporter->finish_report($pool);
2270         $pool->clear;
2271         $editor->{git_commit_ok};
2272 }
2273
2274 sub minimize_url {
2275         my ($self) = @_;
2276         return $self->{url} if ($self->{url} eq $self->{repos_root});
2277         my $url = $self->{repos_root};
2278         my @components = split(m!/!, $self->{svn_path});
2279         my $c = '';
2280         do {
2281                 $url .= "/$c" if length $c;
2282                 eval { (ref $self)->new($url)->get_latest_revnum };
2283         } while ($@ && ($c = shift @components));
2284         $url;
2285 }
2286
2287 sub can_do_switch {
2288         my $self = shift;
2289         unless (defined $can_do_switch) {
2290                 my $pool = SVN::Pool->new;
2291                 my $rep = eval {
2292                         $self->do_switch(1, '', 0, $self->{url},
2293                                          SVN::Delta::Editor->new, $pool);
2294                 };
2295                 if ($@) {
2296                         $can_do_switch = 0;
2297                 } else {
2298                         $rep->abort_report($pool);
2299                         $can_do_switch = 1;
2300                 }
2301                 $pool->clear;
2302         }
2303         $can_do_switch;
2304 }
2305
2306 package Git::SVN::Log;
2307 use strict;
2308 use warnings;
2309 use POSIX qw/strftime/;
2310 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
2311             %rusers $show_commit $incremental/;
2312 my $l_fmt;
2313
2314 sub cmt_showable {
2315         my ($c) = @_;
2316         return 1 if defined $c->{r};
2317         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
2318                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
2319                 my @log = command(qw/cat-file commit/, $c->{c});
2320                 shift @log while ($log[0] ne "\n");
2321                 shift @log;
2322                 @{$c->{l}} = grep !/^git-svn-id: /, @log;
2323
2324                 (undef, $c->{r}, undef) = ::extract_metadata(
2325                                 (grep(/^git-svn-id: /, @log))[-1]);
2326         }
2327         return defined $c->{r};
2328 }
2329
2330 sub log_use_color {
2331         return 1 if $color;
2332         my ($dc, $dcvar);
2333         $dcvar = 'color.diff';
2334         $dc = `git-config --get $dcvar`;
2335         if ($dc eq '') {
2336                 # nothing at all; fallback to "diff.color"
2337                 $dcvar = 'diff.color';
2338                 $dc = `git-config --get $dcvar`;
2339         }
2340         chomp($dc);
2341         if ($dc eq 'auto') {
2342                 my $pc;
2343                 $pc = `git-config --get color.pager`;
2344                 if ($pc eq '') {
2345                         # does not have it -- fallback to pager.color
2346                         $pc = `git-config --bool --get pager.color`;
2347                 }
2348                 else {
2349                         $pc = `git-config --bool --get color.pager`;
2350                         if ($?) {
2351                                 $pc = 'false';
2352                         }
2353                 }
2354                 chomp($pc);
2355                 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
2356                         return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
2357                 }
2358                 return 0;
2359         }
2360         return 0 if $dc eq 'never';
2361         return 1 if $dc eq 'always';
2362         chomp($dc = `git-config --bool --get $dcvar`);
2363         return ($dc eq 'true');
2364 }
2365
2366 sub git_svn_log_cmd {
2367         my ($r_min, $r_max) = @_;
2368         my $gs = Git::SVN->_new;
2369         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
2370                    $gs->refname);
2371         push @cmd, '-r' unless $non_recursive;
2372         push @cmd, qw/--raw --name-status/ if $verbose;
2373         push @cmd, '--color' if log_use_color();
2374         return @cmd unless defined $r_max;
2375         if ($r_max == $r_min) {
2376                 push @cmd, '--max-count=1';
2377                 if (my $c = $gs->rev_db_get($r_max)) {
2378                         push @cmd, $c;
2379                 }
2380         } else {
2381                 my ($c_min, $c_max);
2382                 $c_max = $gs->rev_db_get($r_max);
2383                 $c_min = $gs->rev_db_get($r_min);
2384                 if (defined $c_min && defined $c_max) {
2385                         if ($r_max > $r_max) {
2386                                 push @cmd, "$c_min..$c_max";
2387                         } else {
2388                                 push @cmd, "$c_max..$c_min";
2389                         }
2390                 } elsif ($r_max > $r_min) {
2391                         push @cmd, $c_max;
2392                 } else {
2393                         push @cmd, $c_min;
2394                 }
2395         }
2396         return @cmd;
2397 }
2398
2399 # adapted from pager.c
2400 sub config_pager {
2401         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
2402         if (!defined $pager) {
2403                 $pager = 'less';
2404         } elsif (length $pager == 0 || $pager eq 'cat') {
2405                 $pager = undef;
2406         }
2407 }
2408
2409 sub run_pager {
2410         return unless -t *STDOUT;
2411         pipe my $rfd, my $wfd or return;
2412         defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
2413         if (!$pid) {
2414                 open STDOUT, '>&', $wfd or
2415                                      ::fatal "Can't redirect to stdout: $!\n";
2416                 return;
2417         }
2418         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
2419         $ENV{LESS} ||= 'FRSX';
2420         exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
2421 }
2422
2423 sub get_author_info {
2424         my ($dest, $author, $t, $tz) = @_;
2425         $author =~ s/(?:^\s*|\s*$)//g;
2426         $dest->{a_raw} = $author;
2427         my $au;
2428         if ($::_authors) {
2429                 $au = $rusers{$author} || undef;
2430         }
2431         if (!$au) {
2432                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
2433         }
2434         $dest->{t} = $t;
2435         $dest->{tz} = $tz;
2436         $dest->{a} = $au;
2437         # Date::Parse isn't in the standard Perl distro :(
2438         if ($tz =~ s/^\+//) {
2439                 $t += ::tz_to_s_offset($tz);
2440         } elsif ($tz =~ s/^\-//) {
2441                 $t -= ::tz_to_s_offset($tz);
2442         }
2443         $dest->{t_utc} = $t;
2444 }
2445
2446 sub process_commit {
2447         my ($c, $r_min, $r_max, $defer) = @_;
2448         if (defined $r_min && defined $r_max) {
2449                 if ($r_min == $c->{r} && $r_min == $r_max) {
2450                         show_commit($c);
2451                         return 0;
2452                 }
2453                 return 1 if $r_min == $r_max;
2454                 if ($r_min < $r_max) {
2455                         # we need to reverse the print order
2456                         return 0 if (defined $limit && --$limit < 0);
2457                         push @$defer, $c;
2458                         return 1;
2459                 }
2460                 if ($r_min != $r_max) {
2461                         return 1 if ($r_min < $c->{r});
2462                         return 1 if ($r_max > $c->{r});
2463                 }
2464         }
2465         return 0 if (defined $limit && --$limit < 0);
2466         show_commit($c);
2467         return 1;
2468 }
2469
2470 sub show_commit {
2471         my $c = shift;
2472         if ($oneline) {
2473                 my $x = "\n";
2474                 if (my $l = $c->{l}) {
2475                         while ($l->[0] =~ /^\s*$/) { shift @$l }
2476                         $x = $l->[0];
2477                 }
2478                 $l_fmt ||= 'A' . length($c->{r});
2479                 print 'r',pack($l_fmt, $c->{r}),' | ';
2480                 print "$c->{c} | " if $show_commit;
2481                 print $x;
2482         } else {
2483                 show_commit_normal($c);
2484         }
2485 }
2486
2487 sub show_commit_changed_paths {
2488         my ($c) = @_;
2489         return unless $c->{changed};
2490         print "Changed paths:\n", @{$c->{changed}};
2491 }
2492
2493 sub show_commit_normal {
2494         my ($c) = @_;
2495         print '-' x72, "\nr$c->{r} | ";
2496         print "$c->{c} | " if $show_commit;
2497         print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
2498                                  localtime($c->{t_utc})), ' | ';
2499         my $nr_line = 0;
2500
2501         if (my $l = $c->{l}) {
2502                 while ($l->[$#$l] eq "\n" && $#$l > 0
2503                                           && $l->[($#$l - 1)] eq "\n") {
2504                         pop @$l;
2505                 }
2506                 $nr_line = scalar @$l;
2507                 if (!$nr_line) {
2508                         print "1 line\n\n\n";
2509                 } else {
2510                         if ($nr_line == 1) {
2511                                 $nr_line = '1 line';
2512                         } else {
2513                                 $nr_line .= ' lines';
2514                         }
2515                         print $nr_line, "\n";
2516                         show_commit_changed_paths($c);
2517                         print "\n";
2518                         print $_ foreach @$l;
2519                 }
2520         } else {
2521                 print "1 line\n";
2522                 show_commit_changed_paths($c);
2523                 print "\n";
2524
2525         }
2526         foreach my $x (qw/raw diff/) {
2527                 if ($c->{$x}) {
2528                         print "\n";
2529                         print $_ foreach @{$c->{$x}}
2530                 }
2531         }
2532 }
2533
2534 sub cmd_show_log {
2535         my (@args) = @_;
2536         my ($r_min, $r_max);
2537         my $r_last = -1; # prevent dupes
2538         if (defined $TZ) {
2539                 $ENV{TZ} = $TZ;
2540         } else {
2541                 delete $ENV{TZ};
2542         }
2543         if (defined $::_revision) {
2544                 if ($::_revision =~ /^(\d+):(\d+)$/) {
2545                         ($r_min, $r_max) = ($1, $2);
2546                 } elsif ($::_revision =~ /^\d+$/) {
2547                         $r_min = $r_max = $::_revision;
2548                 } else {
2549                         ::fatal "-r$::_revision is not supported, use ",
2550                                 "standard \'git log\' arguments instead\n";
2551                 }
2552         }
2553
2554         config_pager();
2555         @args = (git_svn_log_cmd($r_min, $r_max), @args);
2556         my $log = command_output_pipe(@args);
2557         run_pager();
2558         my (@k, $c, $d);
2559         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
2560         while (<$log>) {
2561                 if (/^${esc_color}commit ($::sha1_short)/o) {
2562                         my $cmt = $1;
2563                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
2564                                 $r_last = $c->{r};
2565                                 process_commit($c, $r_min, $r_max, \@k) or
2566                                                                 goto out;
2567                         }
2568                         $d = undef;
2569                         $c = { c => $cmt };
2570                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
2571                         get_author_info($c, $1, $2, $3);
2572                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
2573                         # ignore
2574                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
2575                         push @{$c->{raw}}, $_;
2576                 } elsif (/^${esc_color}[ACRMDT]\t/) {
2577                         # we could add $SVN->{svn_path} here, but that requires
2578                         # remote access at the moment (repo_path_split)...
2579                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
2580                         push @{$c->{changed}}, $_;
2581                 } elsif (/^${esc_color}diff /o) {
2582                         $d = 1;
2583                         push @{$c->{diff}}, $_;
2584                 } elsif ($d) {
2585                         push @{$c->{diff}}, $_;
2586                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
2587                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
2588                 } elsif (s/^${esc_color}    //o) {
2589                         push @{$c->{l}}, $_;
2590                 }
2591         }
2592         if ($c && defined $c->{r} && $c->{r} != $r_last) {
2593                 $r_last = $c->{r};
2594                 process_commit($c, $r_min, $r_max, \@k);
2595         }
2596         if (@k) {
2597                 my $swap = $r_max;
2598                 $r_max = $r_min;
2599                 $r_min = $swap;
2600                 process_commit($_, $r_min, $r_max) foreach reverse @k;
2601         }
2602 out:
2603         close $log;
2604         print '-' x72,"\n" unless $incremental || $oneline;
2605 }
2606
2607 package Git::SVN::Migration;
2608 # these version numbers do NOT correspond to actual version numbers
2609 # of git nor git-svn.  They are just relative.
2610 #
2611 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
2612 #
2613 # v1 layout: .git/$id/info/url, refs/remotes/$id
2614 #
2615 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
2616 #
2617 # v3 layout: .git/svn/$id, refs/remotes/$id
2618 #            - info/url may remain for backwards compatibility
2619 #            - this is what we migrate up to this layout automatically,
2620 #            - this will be used by git svn init on single branches
2621 #
2622 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
2623 #            - this is only created for newly multi-init-ed
2624 #              repositories.  Similar in spirit to the
2625 #              --use-separate-remotes option in git-clone (now default)
2626 #            - we do not automatically migrate to this (following
2627 #              the example set by core git)
2628 use strict;
2629 use warnings;
2630 use Carp qw/croak/;
2631 use File::Path qw/mkpath/;
2632 use File::Basename qw/dirname basename/;
2633 use vars qw/$_minimize/;
2634
2635 sub migrate_from_v0 {
2636         my $git_dir = $ENV{GIT_DIR};
2637         return undef unless -d $git_dir;
2638         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2639         my $migrated = 0;
2640         while (<$fh>) {
2641                 chomp;
2642                 my ($id, $orig_ref) = ($_, $_);
2643                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
2644                 next unless -f "$git_dir/$id/info/url";
2645                 my $new_ref = "refs/remotes/$id";
2646                 if (::verify_ref("$new_ref^0")) {
2647                         print STDERR "W: $orig_ref is probably an old ",
2648                                      "branch used by an ancient version of ",
2649                                      "git-svn.\n",
2650                                      "However, $new_ref also exists.\n",
2651                                      "We will not be able ",
2652                                      "to use this branch until this ",
2653                                      "ambiguity is resolved.\n";
2654                         next;
2655                 }
2656                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
2657                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
2658                 command_noisy('update-ref', $new_ref, $orig_ref);
2659                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
2660                 $migrated++;
2661         }
2662         command_close_pipe($fh, $ctx);
2663         print STDERR "Done migrating from v0 layout...\n" if $migrated;
2664         $migrated;
2665 }
2666
2667 sub migrate_from_v1 {
2668         my $git_dir = $ENV{GIT_DIR};
2669         my $migrated = 0;
2670         return $migrated unless -d $git_dir;
2671         my $svn_dir = "$git_dir/svn";
2672
2673         # just in case somebody used 'svn' as their $id at some point...
2674         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
2675
2676         print STDERR "Migrating from a git-svn v1 layout...\n";
2677         mkpath([$svn_dir]);
2678         print STDERR "Data from a previous version of git-svn exists, but\n\t",
2679                      "$svn_dir\n\t(required for this version ",
2680                      "($::VERSION) of git-svn) does not. exist\n";
2681         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2682         while (<$fh>) {
2683                 my $x = $_;
2684                 next unless $x =~ s#^refs/remotes/##;
2685                 chomp $x;
2686                 next unless -f "$git_dir/$x/info/url";
2687                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
2688                 next unless $u;
2689                 my $dn = dirname("$git_dir/svn/$x");
2690                 mkpath([$dn]) unless -d $dn;
2691                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
2692                         mkpath(["$git_dir/svn/svn"]);
2693                         print STDERR " - $git_dir/$x/info => ",
2694                                         "$git_dir/svn/$x/info\n";
2695                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
2696                                croak "$!: $x";
2697                         # don't worry too much about these, they probably
2698                         # don't exist with repos this old (save for index,
2699                         # and we can easily regenerate that)
2700                         foreach my $f (qw/unhandled.log index .rev_db/) {
2701                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
2702                         }
2703                 } else {
2704                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
2705                         rename "$git_dir/$x", "$git_dir/svn/$x" or
2706                                croak "$!: $x";
2707                 }
2708                 $migrated++;
2709         }
2710         command_close_pipe($fh, $ctx);
2711         print STDERR "Done migrating from a git-svn v1 layout\n";
2712         $migrated;
2713 }
2714
2715 sub read_old_urls {
2716         my ($l_map, $pfx, $path) = @_;
2717         my @dir;
2718         foreach (<$path/*>) {
2719                 if (-r "$_/info/url") {
2720                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
2721                         my $ref_id = $pfx . basename $_;
2722                         my $url = ::file_to_s("$_/info/url");
2723                         $l_map->{$ref_id} = $url;
2724                 } elsif (-d $_) {
2725                         push @dir, $_;
2726                 }
2727         }
2728         foreach (@dir) {
2729                 my $x = $_;
2730                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
2731                 read_old_urls($l_map, $x, $_);
2732         }
2733 }
2734
2735 sub migrate_from_v2 {
2736         my @cfg = command(qw/config -l/);
2737         return if grep /^svn-remote\..+\.url=/, @cfg;
2738         my %l_map;
2739         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
2740         my $migrated = 0;
2741
2742         foreach my $ref_id (sort keys %l_map) {
2743                 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
2744                 $migrated++;
2745         }
2746         $migrated;
2747 }
2748
2749 sub minimize_connections {
2750         my $r = Git::SVN::read_all_remotes();
2751         my $new_urls = {};
2752         my $root_repos = {};
2753         foreach my $repo_id (keys %$r) {
2754                 my $url = $r->{$repo_id}->{url} or next;
2755                 my $fetch = $r->{$repo_id}->{fetch} or next;
2756                 my $ra = Git::SVN::Ra->new($url);
2757
2758                 # skip existing cases where we already connect to the root
2759                 if (($ra->{url} eq $ra->{repos_root}) ||
2760                     (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
2761                      $repo_id)) {
2762                         $root_repos->{$ra->{url}} = $repo_id;
2763                         next;
2764                 }
2765
2766                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
2767                 my $root_path = $ra->{url};
2768                 $root_path =~ s#^\Q$ra->{repos_root}\E/*##;
2769                 foreach my $path (keys %$fetch) {
2770                         my $ref_id = $fetch->{$path};
2771                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
2772
2773                         # make sure we can read when connecting to
2774                         # a higher level of a repository
2775                         my ($last_rev, undef) = $gs->last_rev_commit;
2776                         if (!defined $last_rev) {
2777                                 $last_rev = eval {
2778                                         $root_ra->get_latest_revnum;
2779                                 };
2780                                 next if $@;
2781                         }
2782                         my $new = $root_path;
2783                         $new .= length $path ? "/$path" : '';
2784                         eval {
2785                                 $root_ra->get_log([$new], $last_rev, $last_rev,
2786                                                   0, 0, 1, sub { });
2787                         };
2788                         next if $@;
2789                         $new_urls->{$ra->{repos_root}}->{$new} =
2790                                 { ref_id => $ref_id,
2791                                   old_repo_id => $repo_id,
2792                                   old_path => $path };
2793                 }
2794         }
2795
2796         my @emptied;
2797         foreach my $url (keys %$new_urls) {
2798                 # see if we can re-use an existing [svn-remote "repo_id"]
2799                 # instead of creating a(n ugly) new section:
2800                 my $repo_id = $root_repos->{$url} ||
2801                               Git::SVN::sanitize_remote_name($url);
2802
2803                 my $fetch = $new_urls->{$url};
2804                 foreach my $path (keys %$fetch) {
2805                         my $x = $fetch->{$path};
2806                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
2807                         my $pfx = "svn-remote.$x->{old_repo_id}";
2808
2809                         my $old_fetch = quotemeta("$x->{old_path}:".
2810                                                   "refs/remotes/$x->{ref_id}");
2811                         command_noisy(qw/config --unset/,
2812                                       "$pfx.fetch", '^'. $old_fetch . '$');
2813                         delete $r->{$x->{old_repo_id}}->
2814                                {fetch}->{$x->{old_path}};
2815                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
2816                                 command_noisy(qw/config --unset/,
2817                                               "$pfx.url");
2818                                 push @emptied, $x->{old_repo_id}
2819                         }
2820                 }
2821         }
2822         if (@emptied) {
2823                 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
2824                            "$ENV{GIT_DIR}/config";
2825                 print STDERR <<EOF;
2826 The following [svn-remote] sections in your config file ($file) are empty
2827 and can be safely removed:
2828 EOF
2829                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
2830         }
2831 }
2832
2833 sub migration_check {
2834         migrate_from_v0();
2835         migrate_from_v1();
2836         migrate_from_v2();
2837         minimize_connections() if $_minimize;
2838 }
2839
2840 package Git::IndexInfo;
2841 use strict;
2842 use warnings;
2843 use Git qw/command_input_pipe command_close_pipe/;
2844
2845 sub new {
2846         my ($class) = @_;
2847         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
2848         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
2849 }
2850
2851 sub remove {
2852         my ($self, $path) = @_;
2853         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
2854                 return ++$self->{nr};
2855         }
2856         undef;
2857 }
2858
2859 sub update {
2860         my ($self, $mode, $hash, $path) = @_;
2861         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
2862                 return ++$self->{nr};
2863         }
2864         undef;
2865 }
2866
2867 sub DESTROY {
2868         my ($self) = @_;
2869         command_close_pipe($self->{gui}, $self->{ctx});
2870 }
2871
2872 __END__
2873
2874 Data structures:
2875
2876 $log_entry hashref as returned by libsvn_log_entry()
2877 {
2878         log => 'whitespace-formatted log entry
2879 ',                                              # trailing newline is preserved
2880         revision => '8',                        # integer
2881         date => '2004-02-24T17:01:44.108345Z',  # commit date
2882         author => 'committer name'
2883 };
2884
2885 @mods = array of diff-index line hashes, each element represents one line
2886         of diff-index output
2887
2888 diff-index line ($m hash)
2889 {
2890         mode_a => first column of diff-index output, no leading ':',
2891         mode_b => second column of diff-index output,
2892         sha1_b => sha1sum of the final blob,
2893         chg => change type [MCRADT],
2894         file_a => original file name of a file (iff chg is 'C' or 'R')
2895         file_b => new/current file name of a file (any chg)
2896 }
2897 ;
2898
2899 # retval of read_url_paths{,_all}();
2900 $l_map = {
2901         # repository root url
2902         'https://svn.musicpd.org' => {
2903                 # repository path               # GIT_SVN_ID
2904                 'mpd/trunk'             =>      'trunk',
2905                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2906         },
2907 }
2908
2909 Notes:
2910         I don't trust the each() function on unless I created %hash myself
2911         because the internal iterator may not have started at base.