git.oblomov.eu Git - git/blob - git-gui/lib/commit.tcl

   1 # git-gui misc. commit reading/writing support
   2 # Copyright (C) 2006, 2007 Shawn Pearce
   3
   4 proc load_last_commit {} {
   5         global HEAD PARENT MERGE_HEAD commit_type ui_comm
   6         global repo_config
   7
   8         if {[llength $PARENT] == 0} {
   9                 error_popup [mc "There is nothing to amend.
  10
  11 You are about to create the initial commit.  There is no commit before this to amend.
  12 "]
  13                 return
  14         }
  15
  16         repository_state curType curHEAD curMERGE_HEAD
  17         if {$curType eq {merge}} {
  18                 error_popup [mc "Cannot amend while merging.
  19
  20 You are currently in the middle of a merge that has not been fully completed.  You cannot amend the prior commit unless you first abort the current merge activity.
  21 "]
  22                 return
  23         }
  24
  25         set msg {}
  26         set parents [list]
  27         if {[catch {
  28                         set fd [git_read cat-file commit $curHEAD]
  29                         fconfigure $fd -encoding binary -translation lf
  30                         if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
  31                                 set enc utf-8
  32                         }
  33                         while {[gets $fd line] > 0} {
  34                                 if {[string match {parent *} $line]} {
  35                                         lappend parents [string range $line 7 end]
  36                                 } elseif {[string match {encoding *} $line]} {
  37                                         set enc [string tolower [string range $line 9 end]]
  38                                 }
  39                         }
  40                         set msg [read $fd]
  41                         close $fd
  42
  43                         set enc [tcl_encoding $enc]
  44                         if {$enc ne {}} {
  45                                 set msg [encoding convertfrom $enc $msg]
  46                         }
  47                         set msg [string trim $msg]
  48                 } err]} {
  49                 error_popup [strcat [mc "Error loading commit data for amend:"] "\n\n$err"]
  50                 return
  51         }
  52
  53         set HEAD $curHEAD
  54         set PARENT $parents
  55         set MERGE_HEAD [list]
  56         switch -- [llength $parents] {
  57         0       {set commit_type amend-initial}
  58         1       {set commit_type amend}
  59         default {set commit_type amend-merge}
  60         }
  61
  62         $ui_comm delete 0.0 end
  63         $ui_comm insert end $msg
  64         $ui_comm edit reset
  65         $ui_comm edit modified false
  66         rescan ui_ready
  67 }
  68
  69 set GIT_COMMITTER_IDENT {}
  70
  71 proc committer_ident {} {
  72         global GIT_COMMITTER_IDENT
  73
  74         if {$GIT_COMMITTER_IDENT eq {}} {
  75                 if {[catch {set me [git var GIT_COMMITTER_IDENT]} err]} {
  76                         error_popup [strcat [mc "Unable to obtain your identity:"] "\n\n$err"]
  77                         return {}
  78                 }
  79                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
  80                         $me me GIT_COMMITTER_IDENT]} {
  81                         error_popup [strcat [mc "Invalid GIT_COMMITTER_IDENT:"] "\n\n$me"]
  82                         return {}
  83                 }
  84         }
  85
  86         return $GIT_COMMITTER_IDENT
  87 }
  88
  89 proc do_signoff {} {
  90         global ui_comm
  91
  92         set me [committer_ident]
  93         if {$me eq {}} return
  94
  95         set sob "Signed-off-by: $me"
  96         set last [$ui_comm get {end -1c linestart} {end -1c}]
  97         if {$last ne $sob} {
  98                 $ui_comm edit separator
  99                 if {$last ne {}
 100                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
 101                         $ui_comm insert end "\n"
 102                 }
 103                 $ui_comm insert end "\n$sob"
 104                 $ui_comm edit separator
 105                 $ui_comm see end
 106         }
 107 }
 108
 109 proc create_new_commit {} {
 110         global commit_type ui_comm
 111
 112         set commit_type normal
 113         $ui_comm delete 0.0 end
 114         $ui_comm edit reset
 115         $ui_comm edit modified false
 116         rescan ui_ready
 117 }
 118
 119 proc commit_tree {} {
 120         global HEAD commit_type file_states ui_comm repo_config
 121         global pch_error
 122
 123         if {[committer_ident] eq {}} return
 124         if {![lock_index update]} return
 125
 126         # -- Our in memory state should match the repository.
 127         #
 128         repository_state curType curHEAD curMERGE_HEAD
 129         if {[string match amend* $commit_type]
 130                 && $curType eq {normal}
 131                 && $curHEAD eq $HEAD} {
 132         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 133                 info_popup [mc "Last scanned state does not match repository state.
 134
 135 Another Git program has modified this repository since the last scan.  A rescan must be performed before another commit can be created.
 136
 137 The rescan will be automatically started now.
 138 "]
 139                 unlock_index
 140                 rescan ui_ready
 141                 return
 142         }
 143
 144         # -- At least one file should differ in the index.
 145         #
 146         set files_ready 0
 147         foreach path [array names file_states] {
 148                 switch -glob -- [lindex $file_states($path) 0] {
 149                 _? {continue}
 150                 A? -
 151                 D? -
 152                 T_ -
 153                 M? {set files_ready 1}
 154                 _U -
 155                 U? {
 156                         error_popup [mc "Unmerged files cannot be committed.
 157
 158 File %s has merge conflicts.  You must resolve them and stage the file before committing.
 159 " [short_path $path]]
 160                         unlock_index
 161                         return
 162                 }
 163                 default {
 164                         error_popup [mc "Unknown file state %s detected.
 165
 166 File %s cannot be committed by this program.
 167 " [lindex $s 0] [short_path $path]]
 168                 }
 169                 }
 170         }
 171         if {!$files_ready && ![string match *merge $curType] && ![is_enabled nocommit]} {
 172                 info_popup [mc "No changes to commit.
 173
 174 You must stage at least 1 file before you can commit.
 175 "]
 176                 unlock_index
 177                 return
 178         }
 179
 180         if {[is_enabled nocommitmsg]} { do_quit 0 }
 181
 182         # -- A message is required.
 183         #
 184         set msg [string trim [$ui_comm get 1.0 end]]
 185         regsub -all -line {[ \t\r]+$} $msg {} msg
 186         if {$msg eq {}} {
 187                 error_popup [mc "Please supply a commit message.
 188
 189 A good commit message has the following format:
 190
 191 - First line: Describe in one sentence what you did.
 192 - Second line: Blank
 193 - Remaining lines: Describe why this change is good.
 194 "]
 195                 unlock_index
 196                 return
 197         }
 198
 199         # -- Build the message file.
 200         #
 201         set msg_p [gitdir GITGUI_EDITMSG]
 202         set msg_wt [open $msg_p w]
 203         fconfigure $msg_wt -translation lf
 204         if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
 205                 set enc utf-8
 206         }
 207         set use_enc [tcl_encoding $enc]
 208         if {$use_enc ne {}} {
 209                 fconfigure $msg_wt -encoding $use_enc
 210         } else {
 211                 puts stderr [mc "warning: Tcl does not support encoding '%s'." $enc]
 212                 fconfigure $msg_wt -encoding utf-8
 213         }
 214         puts $msg_wt $msg
 215         close $msg_wt
 216
 217         if {[is_enabled nocommit]} { do_quit 0 }
 218
 219         # -- Run the pre-commit hook.
 220         #
 221         set fd_ph [githook_read pre-commit]
 222         if {$fd_ph eq {}} {
 223                 commit_commitmsg $curHEAD $msg_p
 224                 return
 225         }
 226
 227         ui_status [mc "Calling pre-commit hook..."]
 228         set pch_error {}
 229         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
 230         fileevent $fd_ph readable \
 231                 [list commit_prehook_wait $fd_ph $curHEAD $msg_p]
 232 }
 233
 234 proc commit_prehook_wait {fd_ph curHEAD msg_p} {
 235         global pch_error
 236
 237         append pch_error [read $fd_ph]
 238         fconfigure $fd_ph -blocking 1
 239         if {[eof $fd_ph]} {
 240                 if {[catch {close $fd_ph}]} {
 241                         catch {file delete $msg_p}
 242                         ui_status [mc "Commit declined by pre-commit hook."]
 243                         hook_failed_popup pre-commit $pch_error
 244                         unlock_index
 245                 } else {
 246                         commit_commitmsg $curHEAD $msg_p
 247                 }
 248                 set pch_error {}
 249                 return
 250         }
 251         fconfigure $fd_ph -blocking 0
 252 }
 253
 254 proc commit_commitmsg {curHEAD msg_p} {
 255         global pch_error
 256
 257         # -- Run the commit-msg hook.
 258         #
 259         set fd_ph [githook_read commit-msg $msg_p]
 260         if {$fd_ph eq {}} {
 261                 commit_writetree $curHEAD $msg_p
 262                 return
 263         }
 264
 265         ui_status [mc "Calling commit-msg hook..."]
 266         set pch_error {}
 267         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
 268         fileevent $fd_ph readable \
 269                 [list commit_commitmsg_wait $fd_ph $curHEAD $msg_p]
 270 }
 271
 272 proc commit_commitmsg_wait {fd_ph curHEAD msg_p} {
 273         global pch_error
 274
 275         append pch_error [read $fd_ph]
 276         fconfigure $fd_ph -blocking 1
 277         if {[eof $fd_ph]} {
 278                 if {[catch {close $fd_ph}]} {
 279                         catch {file delete $msg_p}
 280                         ui_status [mc "Commit declined by commit-msg hook."]
 281                         hook_failed_popup commit-msg $pch_error
 282                         unlock_index
 283                 } else {
 284                         commit_writetree $curHEAD $msg_p
 285                 }
 286                 set pch_error {}
 287                 return
 288         }
 289         fconfigure $fd_ph -blocking 0
 290 }
 291
 292 proc commit_writetree {curHEAD msg_p} {
 293         ui_status [mc "Committing changes..."]
 294         set fd_wt [git_read write-tree]
 295         fileevent $fd_wt readable \
 296                 [list commit_committree $fd_wt $curHEAD $msg_p]
 297 }
 298
 299 proc commit_committree {fd_wt curHEAD msg_p} {
 300         global HEAD PARENT MERGE_HEAD commit_type
 301         global current_branch
 302         global ui_comm selected_commit_type
 303         global file_states selected_paths rescan_active
 304         global repo_config
 305
 306         gets $fd_wt tree_id
 307         if {[catch {close $fd_wt} err]} {
 308                 catch {file delete $msg_p}
 309                 error_popup [strcat [mc "write-tree failed:"] "\n\n$err"]
 310                 ui_status [mc "Commit failed."]
 311                 unlock_index
 312                 return
 313         }
 314
 315         # -- Verify this wasn't an empty change.
 316         #
 317         if {$commit_type eq {normal}} {
 318                 set fd_ot [git_read cat-file commit $PARENT]
 319                 fconfigure $fd_ot -encoding binary -translation lf
 320                 set old_tree [gets $fd_ot]
 321                 close $fd_ot
 322
 323                 if {[string equal -length 5 {tree } $old_tree]
 324                         && [string length $old_tree] == 45} {
 325                         set old_tree [string range $old_tree 5 end]
 326                 } else {
 327                         error [mc "Commit %s appears to be corrupt" $PARENT]
 328                 }
 329
 330                 if {$tree_id eq $old_tree} {
 331                         catch {file delete $msg_p}
 332                         info_popup [mc "No changes to commit.
 333
 334 No files were modified by this commit and it was not a merge commit.
 335
 336 A rescan will be automatically started now.
 337 "]
 338                         unlock_index
 339                         rescan {ui_status [mc "No changes to commit."]}
 340                         return
 341                 }
 342         }
 343
 344         # -- Create the commit.
 345         #
 346         set cmd [list commit-tree $tree_id]
 347         foreach p [concat $PARENT $MERGE_HEAD] {
 348                 lappend cmd -p $p
 349         }
 350         lappend cmd <$msg_p
 351         if {[catch {set cmt_id [eval git $cmd]} err]} {
 352                 catch {file delete $msg_p}
 353                 error_popup [strcat [mc "commit-tree failed:"] "\n\n$err"]
 354                 ui_status [mc "Commit failed."]
 355                 unlock_index
 356                 return
 357         }
 358
 359         # -- Update the HEAD ref.
 360         #
 361         set reflogm commit
 362         if {$commit_type ne {normal}} {
 363                 append reflogm " ($commit_type)"
 364         }
 365         set msg_fd [open $msg_p r]
 366         gets $msg_fd subject
 367         close $msg_fd
 368         append reflogm {: } $subject
 369         if {[catch {
 370                         git update-ref -m $reflogm HEAD $cmt_id $curHEAD
 371                 } err]} {
 372                 catch {file delete $msg_p}
 373                 error_popup [strcat [mc "update-ref failed:"] "\n\n$err"]
 374                 ui_status [mc "Commit failed."]
 375                 unlock_index
 376                 return
 377         }
 378
 379         # -- Cleanup after ourselves.
 380         #
 381         catch {file delete $msg_p}
 382         catch {file delete [gitdir MERGE_HEAD]}
 383         catch {file delete [gitdir MERGE_MSG]}
 384         catch {file delete [gitdir SQUASH_MSG]}
 385         catch {file delete [gitdir GITGUI_MSG]}
 386
 387         # -- Let rerere do its thing.
 388         #
 389         if {[get_config rerere.enabled] eq {}} {
 390                 set rerere [file isdirectory [gitdir rr-cache]]
 391         } else {
 392                 set rerere [is_config_true rerere.enabled]
 393         }
 394         if {$rerere} {
 395                 catch {git rerere}
 396         }
 397
 398         # -- Run the post-commit hook.
 399         #
 400         set fd_ph [githook_read post-commit]
 401         if {$fd_ph ne {}} {
 402                 upvar #0 pch_error$cmt_id pc_err
 403                 set pc_err {}
 404                 fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
 405                 fileevent $fd_ph readable \
 406                         [list commit_postcommit_wait $fd_ph $cmt_id]
 407         }
 408
 409         $ui_comm delete 0.0 end
 410         $ui_comm edit reset
 411         $ui_comm edit modified false
 412         if {$::GITGUI_BCK_exists} {
 413                 catch {file delete [gitdir GITGUI_BCK]}
 414                 set ::GITGUI_BCK_exists 0
 415         }
 416
 417         if {[is_enabled singlecommit]} { do_quit 0 }
 418
 419         # -- Update in memory status
 420         #
 421         set selected_commit_type new
 422         set commit_type normal
 423         set HEAD $cmt_id
 424         set PARENT $cmt_id
 425         set MERGE_HEAD [list]
 426
 427         foreach path [array names file_states] {
 428                 set s $file_states($path)
 429                 set m [lindex $s 0]
 430                 switch -glob -- $m {
 431                 _O -
 432                 _M -
 433                 _D {continue}
 434                 __ -
 435                 A_ -
 436                 M_ -
 437                 T_ -
 438                 D_ {
 439                         unset file_states($path)
 440                         catch {unset selected_paths($path)}
 441                 }
 442                 DO {
 443                         set file_states($path) [list _O [lindex $s 1] {} {}]
 444                 }
 445                 AM -
 446                 AD -
 447                 MM -
 448                 MD {
 449                         set file_states($path) [list \
 450                                 _[string index $m 1] \
 451                                 [lindex $s 1] \
 452                                 [lindex $s 3] \
 453                                 {}]
 454                 }
 455                 }
 456         }
 457
 458         display_all_files
 459         unlock_index
 460         reshow_diff
 461         ui_status [mc "Created commit %s: %s" [string range $cmt_id 0 7] $subject]
 462 }
 463
 464 proc commit_postcommit_wait {fd_ph cmt_id} {
 465         upvar #0 pch_error$cmt_id pch_error
 466
 467         append pch_error [read $fd_ph]
 468         fconfigure $fd_ph -blocking 1
 469         if {[eof $fd_ph]} {
 470                 if {[catch {close $fd_ph}]} {
 471                         hook_failed_popup post-commit $pch_error 0
 472                 }
 473                 unset pch_error
 474                 return
 475         }
 476         fconfigure $fd_ph -blocking 0
 477 }