git.oblomov.eu Git - git/blob - git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitexec {}
 125 set _reponame {}
 126 set _iscygwin {}
 127 set _search_path {}
 128
 129 set _trace [lsearch -exact $argv --trace]
 130 if {$_trace >= 0} {
 131         set argv [lreplace $argv $_trace $_trace]
 132         set _trace 1
 133 } else {
 134         set _trace 0
 135 }
 136
 137 proc appname {} {
 138         global _appname
 139         return $_appname
 140 }
 141
 142 proc gitdir {args} {
 143         global _gitdir
 144         if {$args eq {}} {
 145                 return $_gitdir
 146         }
 147         return [eval [list file join $_gitdir] $args]
 148 }
 149
 150 proc gitexec {args} {
 151         global _gitexec
 152         if {$_gitexec eq {}} {
 153                 if {[catch {set _gitexec [git --exec-path]} err]} {
 154                         error "Git not installed?\n\n$err"
 155                 }
 156                 if {[is_Cygwin]} {
 157                         set _gitexec [exec cygpath \
 158                                 --windows \
 159                                 --absolute \
 160                                 $_gitexec]
 161                 } else {
 162                         set _gitexec [file normalize $_gitexec]
 163                 }
 164         }
 165         if {$args eq {}} {
 166                 return $_gitexec
 167         }
 168         return [eval [list file join $_gitexec] $args]
 169 }
 170
 171 proc reponame {} {
 172         return $::_reponame
 173 }
 174
 175 proc is_MacOSX {} {
 176         if {[tk windowingsystem] eq {aqua}} {
 177                 return 1
 178         }
 179         return 0
 180 }
 181
 182 proc is_Windows {} {
 183         if {$::tcl_platform(platform) eq {windows}} {
 184                 return 1
 185         }
 186         return 0
 187 }
 188
 189 proc is_Cygwin {} {
 190         global _iscygwin
 191         if {$_iscygwin eq {}} {
 192                 if {$::tcl_platform(platform) eq {windows}} {
 193                         if {[catch {set p [exec cygpath --windir]} err]} {
 194                                 set _iscygwin 0
 195                         } else {
 196                                 set _iscygwin 1
 197                         }
 198                 } else {
 199                         set _iscygwin 0
 200                 }
 201         }
 202         return $_iscygwin
 203 }
 204
 205 proc is_enabled {option} {
 206         global enabled_options
 207         if {[catch {set on $enabled_options($option)}]} {return 0}
 208         return $on
 209 }
 210
 211 proc enable_option {option} {
 212         global enabled_options
 213         set enabled_options($option) 1
 214 }
 215
 216 proc disable_option {option} {
 217         global enabled_options
 218         set enabled_options($option) 0
 219 }
 220
 221 ######################################################################
 222 ##
 223 ## config
 224
 225 proc is_many_config {name} {
 226         switch -glob -- $name {
 227         gui.recentrepo -
 228         remote.*.fetch -
 229         remote.*.push
 230                 {return 1}
 231         *
 232                 {return 0}
 233         }
 234 }
 235
 236 proc is_config_true {name} {
 237         global repo_config
 238         if {[catch {set v $repo_config($name)}]} {
 239                 return 0
 240         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 241                 return 1
 242         } else {
 243                 return 0
 244         }
 245 }
 246
 247 proc get_config {name} {
 248         global repo_config
 249         if {[catch {set v $repo_config($name)}]} {
 250                 return {}
 251         } else {
 252                 return $v
 253         }
 254 }
 255
 256 ######################################################################
 257 ##
 258 ## handy utils
 259
 260 proc _trace_exec {cmd} {
 261         if {!$::_trace} return
 262         set d {}
 263         foreach v $cmd {
 264                 if {$d ne {}} {
 265                         append d { }
 266                 }
 267                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 268                         set v [sq $v]
 269                 }
 270                 append d $v
 271         }
 272         puts stderr $d
 273 }
 274
 275 proc _git_cmd {name} {
 276         global _git_cmd_path
 277
 278         if {[catch {set v $_git_cmd_path($name)}]} {
 279                 switch -- $name {
 280                   version   -
 281                 --version   -
 282                 --exec-path { return [list $::_git $name] }
 283                 }
 284
 285                 set p [gitexec git-$name$::_search_exe]
 286                 if {[file exists $p]} {
 287                         set v [list $p]
 288                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 289                         # Try to determine what sort of magic will make
 290                         # git-$name go and do its thing, because native
 291                         # Tcl on Windows doesn't know it.
 292                         #
 293                         set p [gitexec git-$name]
 294                         set f [open $p r]
 295                         set s [gets $f]
 296                         close $f
 297
 298                         switch -glob -- [lindex $s 0] {
 299                         #!*sh     { set i sh     }
 300                         #!*perl   { set i perl   }
 301                         #!*python { set i python }
 302                         default   { error "git-$name is not supported: $s" }
 303                         }
 304
 305                         upvar #0 _$i interp
 306                         if {![info exists interp]} {
 307                                 set interp [_which $i]
 308                         }
 309                         if {$interp eq {}} {
 310                                 error "git-$name requires $i (not in PATH)"
 311                         }
 312                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 313                 } else {
 314                         # Assume it is builtin to git somehow and we
 315                         # aren't actually able to see a file for it.
 316                         #
 317                         set v [list $::_git $name]
 318                 }
 319                 set _git_cmd_path($name) $v
 320         }
 321         return $v
 322 }
 323
 324 proc _which {what args} {
 325         global env _search_exe _search_path
 326
 327         if {$_search_path eq {}} {
 328                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 329                         set _search_path [split [exec cygpath \
 330                                 --windows \
 331                                 --path \
 332                                 --absolute \
 333                                 $env(PATH)] {;}]
 334                         set _search_exe .exe
 335                 } elseif {[is_Windows]} {
 336                         set gitguidir [file dirname [info script]]
 337                         regsub -all ";" $gitguidir "\\;" gitguidir
 338                         set env(PATH) "$gitguidir;$env(PATH)"
 339                         set _search_path [split $env(PATH) {;}]
 340                         set _search_exe .exe
 341                 } else {
 342                         set _search_path [split $env(PATH) :]
 343                         set _search_exe {}
 344                 }
 345         }
 346
 347         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 348                 set suffix {}
 349         } else {
 350                 set suffix $_search_exe
 351         }
 352
 353         foreach p $_search_path {
 354                 set p [file join $p $what$suffix]
 355                 if {[file exists $p]} {
 356                         return [file normalize $p]
 357                 }
 358         }
 359         return {}
 360 }
 361
 362 proc _lappend_nice {cmd_var} {
 363         global _nice
 364         upvar $cmd_var cmd
 365
 366         if {![info exists _nice]} {
 367                 set _nice [_which nice]
 368         }
 369         if {$_nice ne {}} {
 370                 lappend cmd $_nice
 371         }
 372 }
 373
 374 proc git {args} {
 375         set opt [list]
 376
 377         while {1} {
 378                 switch -- [lindex $args 0] {
 379                 --nice {
 380                         _lappend_nice opt
 381                 }
 382
 383                 default {
 384                         break
 385                 }
 386
 387                 }
 388
 389                 set args [lrange $args 1 end]
 390         }
 391
 392         set cmdp [_git_cmd [lindex $args 0]]
 393         set args [lrange $args 1 end]
 394
 395         _trace_exec [concat $opt $cmdp $args]
 396         set result [eval exec $opt $cmdp $args]
 397         if {$::_trace} {
 398                 puts stderr "< $result"
 399         }
 400         return $result
 401 }
 402
 403 proc _open_stdout_stderr {cmd} {
 404         _trace_exec $cmd
 405         if {[catch {
 406                         set fd [open [concat [list | ] $cmd] r]
 407                 } err]} {
 408                 if {   [lindex $cmd end] eq {2>@1}
 409                     && $err eq {can not find channel named "1"}
 410                         } {
 411                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 412                         # redirect operator.  Fallback to |& cat for those.
 413                         # The command was not actually started, so its safe
 414                         # to try to start it a second time.
 415                         #
 416                         set fd [open [concat \
 417                                 [list | ] \
 418                                 [lrange $cmd 0 end-1] \
 419                                 [list |& cat] \
 420                                 ] r]
 421                 } else {
 422                         error $err
 423                 }
 424         }
 425         fconfigure $fd -eofchar {}
 426         return $fd
 427 }
 428
 429 proc git_read {args} {
 430         set opt [list]
 431
 432         while {1} {
 433                 switch -- [lindex $args 0] {
 434                 --nice {
 435                         _lappend_nice opt
 436                 }
 437
 438                 --stderr {
 439                         lappend args 2>@1
 440                 }
 441
 442                 default {
 443                         break
 444                 }
 445
 446                 }
 447
 448                 set args [lrange $args 1 end]
 449         }
 450
 451         set cmdp [_git_cmd [lindex $args 0]]
 452         set args [lrange $args 1 end]
 453
 454         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 455 }
 456
 457 proc git_write {args} {
 458         set opt [list]
 459
 460         while {1} {
 461                 switch -- [lindex $args 0] {
 462                 --nice {
 463                         _lappend_nice opt
 464                 }
 465
 466                 default {
 467                         break
 468                 }
 469
 470                 }
 471
 472                 set args [lrange $args 1 end]
 473         }
 474
 475         set cmdp [_git_cmd [lindex $args 0]]
 476         set args [lrange $args 1 end]
 477
 478         _trace_exec [concat $opt $cmdp $args]
 479         return [open [concat [list | ] $opt $cmdp $args] w]
 480 }
 481
 482 proc githook_read {hook_name args} {
 483         set pchook [gitdir hooks $hook_name]
 484         lappend args 2>@1
 485
 486         # On Windows [file executable] might lie so we need to ask
 487         # the shell if the hook is executable.  Yes that's annoying.
 488         #
 489         if {[is_Windows]} {
 490                 upvar #0 _sh interp
 491                 if {![info exists interp]} {
 492                         set interp [_which sh]
 493                 }
 494                 if {$interp eq {}} {
 495                         error "hook execution requires sh (not in PATH)"
 496                 }
 497
 498                 set scr {if test -x "$1";then exec "$@";fi}
 499                 set sh_c [list $interp -c $scr $interp $pchook]
 500                 return [_open_stdout_stderr [concat $sh_c $args]]
 501         }
 502
 503         if {[file executable $pchook]} {
 504                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 505         }
 506
 507         return {}
 508 }
 509
 510 proc kill_file_process {fd} {
 511         set process [pid $fd]
 512
 513         catch {
 514                 if {[is_Windows]} {
 515                         # Use a Cygwin-specific flag to allow killing
 516                         # native Windows processes
 517                         exec kill -f $process
 518                 } else {
 519                         exec kill $process
 520                 }
 521         }
 522 }
 523
 524 proc gitattr {path attr default} {
 525         if {[catch {set r [git check-attr $attr -- $path]}]} {
 526                 set r unspecified
 527         } else {
 528                 set r [join [lrange [split $r :] 2 end] :]
 529                 regsub {^ } $r {} r
 530         }
 531         if {$r eq {unspecified}} {
 532                 return $default
 533         }
 534         return $r
 535 }
 536
 537 proc sq {value} {
 538         regsub -all ' $value "'\\''" value
 539         return "'$value'"
 540 }
 541
 542 proc load_current_branch {} {
 543         global current_branch is_detached
 544
 545         set fd [open [gitdir HEAD] r]
 546         if {[gets $fd ref] < 1} {
 547                 set ref {}
 548         }
 549         close $fd
 550
 551         set pfx {ref: refs/heads/}
 552         set len [string length $pfx]
 553         if {[string equal -length $len $pfx $ref]} {
 554                 # We're on a branch.  It might not exist.  But
 555                 # HEAD looks good enough to be a branch.
 556                 #
 557                 set current_branch [string range $ref $len end]
 558                 set is_detached 0
 559         } else {
 560                 # Assume this is a detached head.
 561                 #
 562                 set current_branch HEAD
 563                 set is_detached 1
 564         }
 565 }
 566
 567 auto_load tk_optionMenu
 568 rename tk_optionMenu real__tkOptionMenu
 569 proc tk_optionMenu {w varName args} {
 570         set m [eval real__tkOptionMenu $w $varName $args]
 571         $m configure -font font_ui
 572         $w configure -font font_ui
 573         return $m
 574 }
 575
 576 proc rmsel_tag {text} {
 577         $text tag conf sel \
 578                 -background [$text cget -background] \
 579                 -foreground [$text cget -foreground] \
 580                 -borderwidth 0
 581         $text tag conf in_sel -background lightgray
 582         bind $text <Motion> break
 583         return $text
 584 }
 585
 586 set root_exists 0
 587 bind . <Visibility> {
 588         bind . <Visibility> {}
 589         set root_exists 1
 590 }
 591
 592 if {[is_Windows]} {
 593         wm iconbitmap . -default $oguilib/git-gui.ico
 594 }
 595
 596 ######################################################################
 597 ##
 598 ## config defaults
 599
 600 set cursor_ptr arrow
 601 font create font_diff -family Courier -size 10
 602 font create font_ui
 603 catch {
 604         label .dummy
 605         eval font configure font_ui [font actual [.dummy cget -font]]
 606         destroy .dummy
 607 }
 608
 609 font create font_uiitalic
 610 font create font_uibold
 611 font create font_diffbold
 612 font create font_diffitalic
 613
 614 foreach class {Button Checkbutton Entry Label
 615                 Labelframe Listbox Menu Message
 616                 Radiobutton Spinbox Text} {
 617         option add *$class.font font_ui
 618 }
 619 unset class
 620
 621 if {[is_Windows] || [is_MacOSX]} {
 622         option add *Menu.tearOff 0
 623 }
 624
 625 if {[is_MacOSX]} {
 626         set M1B M1
 627         set M1T Cmd
 628 } else {
 629         set M1B Control
 630         set M1T Ctrl
 631 }
 632
 633 proc bind_button3 {w cmd} {
 634         bind $w <Any-Button-3> $cmd
 635         if {[is_MacOSX]} {
 636                 # Mac OS X sends Button-2 on right click through three-button mouse,
 637                 # or through trackpad right-clicking (two-finger touch + click).
 638                 bind $w <Any-Button-2> $cmd
 639                 bind $w <Control-Button-1> $cmd
 640         }
 641 }
 642
 643 proc apply_config {} {
 644         global repo_config font_descs
 645
 646         foreach option $font_descs {
 647                 set name [lindex $option 0]
 648                 set font [lindex $option 1]
 649                 if {[catch {
 650                         set need_weight 1
 651                         foreach {cn cv} $repo_config(gui.$name) {
 652                                 if {$cn eq {-weight}} {
 653                                         set need_weight 0
 654                                 }
 655                                 font configure $font $cn $cv
 656                         }
 657                         if {$need_weight} {
 658                                 font configure $font -weight normal
 659                         }
 660                         } err]} {
 661                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 662                 }
 663                 foreach {cn cv} [font configure $font] {
 664                         font configure ${font}bold $cn $cv
 665                         font configure ${font}italic $cn $cv
 666                 }
 667                 font configure ${font}bold -weight bold
 668                 font configure ${font}italic -slant italic
 669         }
 670 }
 671
 672 set default_config(branch.autosetupmerge) true
 673 set default_config(merge.tool) {}
 674 set default_config(merge.keepbackup) true
 675 set default_config(merge.diffstat) true
 676 set default_config(merge.summary) false
 677 set default_config(merge.verbosity) 2
 678 set default_config(user.name) {}
 679 set default_config(user.email) {}
 680
 681 set default_config(gui.encoding) [encoding system]
 682 set default_config(gui.matchtrackingbranch) false
 683 set default_config(gui.pruneduringfetch) false
 684 set default_config(gui.trustmtime) false
 685 set default_config(gui.fastcopyblame) false
 686 set default_config(gui.copyblamethreshold) 40
 687 set default_config(gui.blamehistoryctx) 7
 688 set default_config(gui.diffcontext) 5
 689 set default_config(gui.commitmsgwidth) 75
 690 set default_config(gui.newbranchtemplate) {}
 691 set default_config(gui.spellingdictionary) {}
 692 set default_config(gui.fontui) [font configure font_ui]
 693 set default_config(gui.fontdiff) [font configure font_diff]
 694 set font_descs {
 695         {fontui   font_ui   {mc "Main Font"}}
 696         {fontdiff font_diff {mc "Diff/Console Font"}}
 697 }
 698
 699 ######################################################################
 700 ##
 701 ## find git
 702
 703 set _git  [_which git]
 704 if {$_git eq {}} {
 705         catch {wm withdraw .}
 706         tk_messageBox \
 707                 -icon error \
 708                 -type ok \
 709                 -title [mc "git-gui: fatal error"] \
 710                 -message [mc "Cannot find git in PATH."]
 711         exit 1
 712 }
 713
 714 ######################################################################
 715 ##
 716 ## version check
 717
 718 if {[catch {set _git_version [git --version]} err]} {
 719         catch {wm withdraw .}
 720         tk_messageBox \
 721                 -icon error \
 722                 -type ok \
 723                 -title [mc "git-gui: fatal error"] \
 724                 -message "Cannot determine Git version:
 725
 726 $err
 727
 728 [appname] requires Git 1.5.0 or later."
 729         exit 1
 730 }
 731 if {![regsub {^git version } $_git_version {} _git_version]} {
 732         catch {wm withdraw .}
 733         tk_messageBox \
 734                 -icon error \
 735                 -type ok \
 736                 -title [mc "git-gui: fatal error"] \
 737                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 738         exit 1
 739 }
 740
 741 set _real_git_version $_git_version
 742 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 743 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 744 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 745 regsub {\.GIT$} $_git_version {} _git_version
 746 regsub {\.[a-zA-Z]+\.[0-9]+$} $_git_version {} _git_version
 747
 748 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 749         catch {wm withdraw .}
 750         if {[tk_messageBox \
 751                 -icon warning \
 752                 -type yesno \
 753                 -default no \
 754                 -title "[appname]: warning" \
 755                  -message [mc "Git version cannot be determined.
 756
 757 %s claims it is version '%s'.
 758
 759 %s requires at least Git 1.5.0 or later.
 760
 761 Assume '%s' is version 1.5.0?
 762 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 763                 set _git_version 1.5.0
 764         } else {
 765                 exit 1
 766         }
 767 }
 768 unset _real_git_version
 769
 770 proc git-version {args} {
 771         global _git_version
 772
 773         switch [llength $args] {
 774         0 {
 775                 return $_git_version
 776         }
 777
 778         2 {
 779                 set op [lindex $args 0]
 780                 set vr [lindex $args 1]
 781                 set cm [package vcompare $_git_version $vr]
 782                 return [expr $cm $op 0]
 783         }
 784
 785         4 {
 786                 set type [lindex $args 0]
 787                 set name [lindex $args 1]
 788                 set parm [lindex $args 2]
 789                 set body [lindex $args 3]
 790
 791                 if {($type ne {proc} && $type ne {method})} {
 792                         error "Invalid arguments to git-version"
 793                 }
 794                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 795                         error "Last arm of $type $name must be default"
 796                 }
 797
 798                 foreach {op vr cb} [lrange $body 0 end-2] {
 799                         if {[git-version $op $vr]} {
 800                                 return [uplevel [list $type $name $parm $cb]]
 801                         }
 802                 }
 803
 804                 return [uplevel [list $type $name $parm [lindex $body end]]]
 805         }
 806
 807         default {
 808                 error "git-version >= x"
 809         }
 810
 811         }
 812 }
 813
 814 if {[git-version < 1.5]} {
 815         catch {wm withdraw .}
 816         tk_messageBox \
 817                 -icon error \
 818                 -type ok \
 819                 -title [mc "git-gui: fatal error"] \
 820                 -message "[appname] requires Git 1.5.0 or later.
 821
 822 You are using [git-version]:
 823
 824 [git --version]"
 825         exit 1
 826 }
 827
 828 ######################################################################
 829 ##
 830 ## configure our library
 831
 832 set idx [file join $oguilib tclIndex]
 833 if {[catch {set fd [open $idx r]} err]} {
 834         catch {wm withdraw .}
 835         tk_messageBox \
 836                 -icon error \
 837                 -type ok \
 838                 -title [mc "git-gui: fatal error"] \
 839                 -message $err
 840         exit 1
 841 }
 842 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 843         set idx [list]
 844         while {[gets $fd n] >= 0} {
 845                 if {$n ne {} && ![string match #* $n]} {
 846                         lappend idx $n
 847                 }
 848         }
 849 } else {
 850         set idx {}
 851 }
 852 close $fd
 853
 854 if {$idx ne {}} {
 855         set loaded [list]
 856         foreach p $idx {
 857                 if {[lsearch -exact $loaded $p] >= 0} continue
 858                 source [file join $oguilib $p]
 859                 lappend loaded $p
 860         }
 861         unset loaded p
 862 } else {
 863         set auto_path [concat [list $oguilib] $auto_path]
 864 }
 865 unset -nocomplain idx fd
 866
 867 ######################################################################
 868 ##
 869 ## config file parsing
 870
 871 git-version proc _parse_config {arr_name args} {
 872         >= 1.5.3 {
 873                 upvar $arr_name arr
 874                 array unset arr
 875                 set buf {}
 876                 catch {
 877                         set fd_rc [eval \
 878                                 [list git_read config] \
 879                                 $args \
 880                                 [list --null --list]]
 881                         fconfigure $fd_rc -translation binary
 882                         set buf [read $fd_rc]
 883                         close $fd_rc
 884                 }
 885                 foreach line [split $buf "\0"] {
 886                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 887                                 if {[is_many_config $name]} {
 888                                         lappend arr($name) $value
 889                                 } else {
 890                                         set arr($name) $value
 891                                 }
 892                         }
 893                 }
 894         }
 895         default {
 896                 upvar $arr_name arr
 897                 array unset arr
 898                 catch {
 899                         set fd_rc [eval [list git_read config --list] $args]
 900                         while {[gets $fd_rc line] >= 0} {
 901                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 902                                         if {[is_many_config $name]} {
 903                                                 lappend arr($name) $value
 904                                         } else {
 905                                                 set arr($name) $value
 906                                         }
 907                                 }
 908                         }
 909                         close $fd_rc
 910                 }
 911         }
 912 }
 913
 914 proc load_config {include_global} {
 915         global repo_config global_config default_config
 916
 917         if {$include_global} {
 918                 _parse_config global_config --global
 919         }
 920         _parse_config repo_config
 921
 922         foreach name [array names default_config] {
 923                 if {[catch {set v $global_config($name)}]} {
 924                         set global_config($name) $default_config($name)
 925                 }
 926                 if {[catch {set v $repo_config($name)}]} {
 927                         set repo_config($name) $default_config($name)
 928                 }
 929         }
 930 }
 931
 932 ######################################################################
 933 ##
 934 ## feature option selection
 935
 936 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 937         unset _junk
 938 } else {
 939         set subcommand gui
 940 }
 941 if {$subcommand eq {gui.sh}} {
 942         set subcommand gui
 943 }
 944 if {$subcommand eq {gui} && [llength $argv] > 0} {
 945         set subcommand [lindex $argv 0]
 946         set argv [lrange $argv 1 end]
 947 }
 948
 949 enable_option multicommit
 950 enable_option branch
 951 enable_option transport
 952 disable_option bare
 953
 954 switch -- $subcommand {
 955 browser -
 956 blame {
 957         enable_option bare
 958
 959         disable_option multicommit
 960         disable_option branch
 961         disable_option transport
 962 }
 963 citool {
 964         enable_option singlecommit
 965         enable_option retcode
 966
 967         disable_option multicommit
 968         disable_option branch
 969         disable_option transport
 970
 971         while {[llength $argv] > 0} {
 972                 set a [lindex $argv 0]
 973                 switch -- $a {
 974                 --amend {
 975                         enable_option initialamend
 976                 }
 977                 --nocommit {
 978                         enable_option nocommit
 979                         enable_option nocommitmsg
 980                 }
 981                 --commitmsg {
 982                         disable_option nocommitmsg
 983                 }
 984                 default {
 985                         break
 986                 }
 987                 }
 988
 989                 set argv [lrange $argv 1 end]
 990         }
 991 }
 992 }
 993
 994 ######################################################################
 995 ##
 996 ## repository setup
 997
 998 if {[catch {
 999                 set _gitdir $env(GIT_DIR)
1000                 set _prefix {}
1001                 }]
1002         && [catch {
1003                 set _gitdir [git rev-parse --git-dir]
1004                 set _prefix [git rev-parse --show-prefix]
1005         } err]} {
1006         load_config 1
1007         apply_config
1008         choose_repository::pick
1009 }
1010 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1011         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1012 }
1013 if {![file isdirectory $_gitdir]} {
1014         catch {wm withdraw .}
1015         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1016         exit 1
1017 }
1018 if {$_prefix ne {}} {
1019         regsub -all {[^/]+/} $_prefix ../ cdup
1020         if {[catch {cd $cdup} err]} {
1021                 catch {wm withdraw .}
1022                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1023                 exit 1
1024         }
1025         unset cdup
1026 } elseif {![is_enabled bare]} {
1027         if {[lindex [file split $_gitdir] end] ne {.git}} {
1028                 catch {wm withdraw .}
1029                 error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
1030                 exit 1
1031         }
1032         if {[catch {cd [file dirname $_gitdir]} err]} {
1033                 catch {wm withdraw .}
1034                 error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
1035                 exit 1
1036         }
1037 }
1038 set _reponame [file split [file normalize $_gitdir]]
1039 if {[lindex $_reponame end] eq {.git}} {
1040         set _reponame [lindex $_reponame end-1]
1041 } else {
1042         set _reponame [lindex $_reponame end]
1043 }
1044
1045 ######################################################################
1046 ##
1047 ## global init
1048
1049 set current_diff_path {}
1050 set current_diff_side {}
1051 set diff_actions [list]
1052
1053 set HEAD {}
1054 set PARENT {}
1055 set MERGE_HEAD [list]
1056 set commit_type {}
1057 set empty_tree {}
1058 set current_branch {}
1059 set is_detached 0
1060 set current_diff_path {}
1061 set is_3way_diff 0
1062 set selected_commit_type new
1063
1064 set nullid "0000000000000000000000000000000000000000"
1065 set nullid2 "0000000000000000000000000000000000000001"
1066
1067 ######################################################################
1068 ##
1069 ## task management
1070
1071 set rescan_active 0
1072 set diff_active 0
1073 set last_clicked {}
1074
1075 set disable_on_lock [list]
1076 set index_lock_type none
1077
1078 proc lock_index {type} {
1079         global index_lock_type disable_on_lock
1080
1081         if {$index_lock_type eq {none}} {
1082                 set index_lock_type $type
1083                 foreach w $disable_on_lock {
1084                         uplevel #0 $w disabled
1085                 }
1086                 return 1
1087         } elseif {$index_lock_type eq "begin-$type"} {
1088                 set index_lock_type $type
1089                 return 1
1090         }
1091         return 0
1092 }
1093
1094 proc unlock_index {} {
1095         global index_lock_type disable_on_lock
1096
1097         set index_lock_type none
1098         foreach w $disable_on_lock {
1099                 uplevel #0 $w normal
1100         }
1101 }
1102
1103 ######################################################################
1104 ##
1105 ## status
1106
1107 proc repository_state {ctvar hdvar mhvar} {
1108         global current_branch
1109         upvar $ctvar ct $hdvar hd $mhvar mh
1110
1111         set mh [list]
1112
1113         load_current_branch
1114         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1115                 set hd {}
1116                 set ct initial
1117                 return
1118         }
1119
1120         set merge_head [gitdir MERGE_HEAD]
1121         if {[file exists $merge_head]} {
1122                 set ct merge
1123                 set fd_mh [open $merge_head r]
1124                 while {[gets $fd_mh line] >= 0} {
1125                         lappend mh $line
1126                 }
1127                 close $fd_mh
1128                 return
1129         }
1130
1131         set ct normal
1132 }
1133
1134 proc PARENT {} {
1135         global PARENT empty_tree
1136
1137         set p [lindex $PARENT 0]
1138         if {$p ne {}} {
1139                 return $p
1140         }
1141         if {$empty_tree eq {}} {
1142                 set empty_tree [git mktree << {}]
1143         }
1144         return $empty_tree
1145 }
1146
1147 proc force_amend {} {
1148         global selected_commit_type
1149         global HEAD PARENT MERGE_HEAD commit_type
1150
1151         repository_state newType newHEAD newMERGE_HEAD
1152         set HEAD $newHEAD
1153         set PARENT $newHEAD
1154         set MERGE_HEAD $newMERGE_HEAD
1155         set commit_type $newType
1156
1157         set selected_commit_type amend
1158         do_select_commit_type
1159 }
1160
1161 proc rescan {after {honor_trustmtime 1}} {
1162         global HEAD PARENT MERGE_HEAD commit_type
1163         global ui_index ui_workdir ui_comm
1164         global rescan_active file_states
1165         global repo_config
1166
1167         if {$rescan_active > 0 || ![lock_index read]} return
1168
1169         repository_state newType newHEAD newMERGE_HEAD
1170         if {[string match amend* $commit_type]
1171                 && $newType eq {normal}
1172                 && $newHEAD eq $HEAD} {
1173         } else {
1174                 set HEAD $newHEAD
1175                 set PARENT $newHEAD
1176                 set MERGE_HEAD $newMERGE_HEAD
1177                 set commit_type $newType
1178         }
1179
1180         array unset file_states
1181
1182         if {!$::GITGUI_BCK_exists &&
1183                 (![$ui_comm edit modified]
1184                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1185                 if {[string match amend* $commit_type]} {
1186                 } elseif {[load_message GITGUI_MSG]} {
1187                 } elseif {[run_prepare_commit_msg_hook]} {
1188                 } elseif {[load_message MERGE_MSG]} {
1189                 } elseif {[load_message SQUASH_MSG]} {
1190                 }
1191                 $ui_comm edit reset
1192                 $ui_comm edit modified false
1193         }
1194
1195         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1196                 rescan_stage2 {} $after
1197         } else {
1198                 set rescan_active 1
1199                 ui_status [mc "Refreshing file status..."]
1200                 set fd_rf [git_read update-index \
1201                         -q \
1202                         --unmerged \
1203                         --ignore-missing \
1204                         --refresh \
1205                         ]
1206                 fconfigure $fd_rf -blocking 0 -translation binary
1207                 fileevent $fd_rf readable \
1208                         [list rescan_stage2 $fd_rf $after]
1209         }
1210 }
1211
1212 if {[is_Cygwin]} {
1213         set is_git_info_exclude {}
1214         proc have_info_exclude {} {
1215                 global is_git_info_exclude
1216
1217                 if {$is_git_info_exclude eq {}} {
1218                         if {[catch {exec test -f [gitdir info exclude]}]} {
1219                                 set is_git_info_exclude 0
1220                         } else {
1221                                 set is_git_info_exclude 1
1222                         }
1223                 }
1224                 return $is_git_info_exclude
1225         }
1226 } else {
1227         proc have_info_exclude {} {
1228                 return [file readable [gitdir info exclude]]
1229         }
1230 }
1231
1232 proc rescan_stage2 {fd after} {
1233         global rescan_active buf_rdi buf_rdf buf_rlo
1234
1235         if {$fd ne {}} {
1236                 read $fd
1237                 if {![eof $fd]} return
1238                 close $fd
1239         }
1240
1241         set ls_others [list --exclude-per-directory=.gitignore]
1242         if {[have_info_exclude]} {
1243                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1244         }
1245         set user_exclude [get_config core.excludesfile]
1246         if {$user_exclude ne {} && [file readable $user_exclude]} {
1247                 lappend ls_others "--exclude-from=$user_exclude"
1248         }
1249
1250         set buf_rdi {}
1251         set buf_rdf {}
1252         set buf_rlo {}
1253
1254         set rescan_active 3
1255         ui_status [mc "Scanning for modified files ..."]
1256         set fd_di [git_read diff-index --cached -z [PARENT]]
1257         set fd_df [git_read diff-files -z]
1258         set fd_lo [eval git_read ls-files --others -z $ls_others]
1259
1260         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1261         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1262         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1263         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1264         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1265         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1266 }
1267
1268 proc load_message {file} {
1269         global ui_comm
1270
1271         set f [gitdir $file]
1272         if {[file isfile $f]} {
1273                 if {[catch {set fd [open $f r]}]} {
1274                         return 0
1275                 }
1276                 fconfigure $fd -eofchar {}
1277                 set content [string trim [read $fd]]
1278                 close $fd
1279                 regsub -all -line {[ \r\t]+$} $content {} content
1280                 $ui_comm delete 0.0 end
1281                 $ui_comm insert end $content
1282                 return 1
1283         }
1284         return 0
1285 }
1286
1287 proc run_prepare_commit_msg_hook {} {
1288         global pch_error
1289
1290         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1291         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1292         # empty file but existant file.
1293
1294         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1295
1296         if {[file isfile [gitdir MERGE_MSG]]} {
1297                 set pcm_source "merge"
1298                 set fd_mm [open [gitdir MERGE_MSG] r]
1299                 puts -nonewline $fd_pcm [read $fd_mm]
1300                 close $fd_mm
1301         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1302                 set pcm_source "squash"
1303                 set fd_sm [open [gitdir SQUASH_MSG] r]
1304                 puts -nonewline $fd_pcm [read $fd_sm]
1305                 close $fd_sm
1306         } else {
1307                 set pcm_source ""
1308         }
1309
1310         close $fd_pcm
1311
1312         set fd_ph [githook_read prepare-commit-msg \
1313                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1314         if {$fd_ph eq {}} {
1315                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1316                 return 0;
1317         }
1318
1319         ui_status [mc "Calling prepare-commit-msg hook..."]
1320         set pch_error {}
1321
1322         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1323         fileevent $fd_ph readable \
1324                 [list prepare_commit_msg_hook_wait $fd_ph]
1325
1326         return 1;
1327 }
1328
1329 proc prepare_commit_msg_hook_wait {fd_ph} {
1330         global pch_error
1331
1332         append pch_error [read $fd_ph]
1333         fconfigure $fd_ph -blocking 1
1334         if {[eof $fd_ph]} {
1335                 if {[catch {close $fd_ph}]} {
1336                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1337                         hook_failed_popup prepare-commit-msg $pch_error
1338                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1339                         exit 1
1340                 } else {
1341                         load_message PREPARE_COMMIT_MSG
1342                 }
1343                 set pch_error {}
1344                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1345                 return
1346         }
1347         fconfigure $fd_ph -blocking 0
1348         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1349 }
1350
1351 proc read_diff_index {fd after} {
1352         global buf_rdi
1353
1354         append buf_rdi [read $fd]
1355         set c 0
1356         set n [string length $buf_rdi]
1357         while {$c < $n} {
1358                 set z1 [string first "\0" $buf_rdi $c]
1359                 if {$z1 == -1} break
1360                 incr z1
1361                 set z2 [string first "\0" $buf_rdi $z1]
1362                 if {$z2 == -1} break
1363
1364                 incr c
1365                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1366                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1367                 merge_state \
1368                         [encoding convertfrom $p] \
1369                         [lindex $i 4]? \
1370                         [list [lindex $i 0] [lindex $i 2]] \
1371                         [list]
1372                 set c $z2
1373                 incr c
1374         }
1375         if {$c < $n} {
1376                 set buf_rdi [string range $buf_rdi $c end]
1377         } else {
1378                 set buf_rdi {}
1379         }
1380
1381         rescan_done $fd buf_rdi $after
1382 }
1383
1384 proc read_diff_files {fd after} {
1385         global buf_rdf
1386
1387         append buf_rdf [read $fd]
1388         set c 0
1389         set n [string length $buf_rdf]
1390         while {$c < $n} {
1391                 set z1 [string first "\0" $buf_rdf $c]
1392                 if {$z1 == -1} break
1393                 incr z1
1394                 set z2 [string first "\0" $buf_rdf $z1]
1395                 if {$z2 == -1} break
1396
1397                 incr c
1398                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1399                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1400                 merge_state \
1401                         [encoding convertfrom $p] \
1402                         ?[lindex $i 4] \
1403                         [list] \
1404                         [list [lindex $i 0] [lindex $i 2]]
1405                 set c $z2
1406                 incr c
1407         }
1408         if {$c < $n} {
1409                 set buf_rdf [string range $buf_rdf $c end]
1410         } else {
1411                 set buf_rdf {}
1412         }
1413
1414         rescan_done $fd buf_rdf $after
1415 }
1416
1417 proc read_ls_others {fd after} {
1418         global buf_rlo
1419
1420         append buf_rlo [read $fd]
1421         set pck [split $buf_rlo "\0"]
1422         set buf_rlo [lindex $pck end]
1423         foreach p [lrange $pck 0 end-1] {
1424                 set p [encoding convertfrom $p]
1425                 if {[string index $p end] eq {/}} {
1426                         set p [string range $p 0 end-1]
1427                 }
1428                 merge_state $p ?O
1429         }
1430         rescan_done $fd buf_rlo $after
1431 }
1432
1433 proc rescan_done {fd buf after} {
1434         global rescan_active current_diff_path
1435         global file_states repo_config
1436         upvar $buf to_clear
1437
1438         if {![eof $fd]} return
1439         set to_clear {}
1440         close $fd
1441         if {[incr rescan_active -1] > 0} return
1442
1443         prune_selection
1444         unlock_index
1445         display_all_files
1446         if {$current_diff_path ne {}} reshow_diff
1447         if {$current_diff_path eq {}} select_first_diff
1448
1449         uplevel #0 $after
1450 }
1451
1452 proc prune_selection {} {
1453         global file_states selected_paths
1454
1455         foreach path [array names selected_paths] {
1456                 if {[catch {set still_here $file_states($path)}]} {
1457                         unset selected_paths($path)
1458                 }
1459         }
1460 }
1461
1462 ######################################################################
1463 ##
1464 ## ui helpers
1465
1466 proc mapicon {w state path} {
1467         global all_icons
1468
1469         if {[catch {set r $all_icons($state$w)}]} {
1470                 puts "error: no icon for $w state={$state} $path"
1471                 return file_plain
1472         }
1473         return $r
1474 }
1475
1476 proc mapdesc {state path} {
1477         global all_descs
1478
1479         if {[catch {set r $all_descs($state)}]} {
1480                 puts "error: no desc for state={$state} $path"
1481                 return $state
1482         }
1483         return $r
1484 }
1485
1486 proc ui_status {msg} {
1487         global main_status
1488         if {[info exists main_status]} {
1489                 $main_status show $msg
1490         }
1491 }
1492
1493 proc ui_ready {{test {}}} {
1494         global main_status
1495         if {[info exists main_status]} {
1496                 $main_status show [mc "Ready."] $test
1497         }
1498 }
1499
1500 proc escape_path {path} {
1501         regsub -all {\\} $path "\\\\" path
1502         regsub -all "\n" $path "\\n" path
1503         return $path
1504 }
1505
1506 proc short_path {path} {
1507         return [escape_path [lindex [file split $path] end]]
1508 }
1509
1510 set next_icon_id 0
1511 set null_sha1 [string repeat 0 40]
1512
1513 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1514         global file_states next_icon_id null_sha1
1515
1516         set s0 [string index $new_state 0]
1517         set s1 [string index $new_state 1]
1518
1519         if {[catch {set info $file_states($path)}]} {
1520                 set state __
1521                 set icon n[incr next_icon_id]
1522         } else {
1523                 set state [lindex $info 0]
1524                 set icon [lindex $info 1]
1525                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1526                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1527         }
1528
1529         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1530         elseif {$s0 eq {_}} {set s0 _}
1531
1532         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1533         elseif {$s1 eq {_}} {set s1 _}
1534
1535         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1536                 set head_info [list 0 $null_sha1]
1537         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1538                 && $head_info eq {}} {
1539                 set head_info $index_info
1540         }
1541
1542         set file_states($path) [list $s0$s1 $icon \
1543                 $head_info $index_info \
1544                 ]
1545         return $state
1546 }
1547
1548 proc display_file_helper {w path icon_name old_m new_m} {
1549         global file_lists
1550
1551         if {$new_m eq {_}} {
1552                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1553                 if {$lno >= 0} {
1554                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1555                         incr lno
1556                         $w conf -state normal
1557                         $w delete $lno.0 [expr {$lno + 1}].0
1558                         $w conf -state disabled
1559                 }
1560         } elseif {$old_m eq {_} && $new_m ne {_}} {
1561                 lappend file_lists($w) $path
1562                 set file_lists($w) [lsort -unique $file_lists($w)]
1563                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1564                 incr lno
1565                 $w conf -state normal
1566                 $w image create $lno.0 \
1567                         -align center -padx 5 -pady 1 \
1568                         -name $icon_name \
1569                         -image [mapicon $w $new_m $path]
1570                 $w insert $lno.1 "[escape_path $path]\n"
1571                 $w conf -state disabled
1572         } elseif {$old_m ne $new_m} {
1573                 $w conf -state normal
1574                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1575                 $w conf -state disabled
1576         }
1577 }
1578
1579 proc display_file {path state} {
1580         global file_states selected_paths
1581         global ui_index ui_workdir
1582
1583         set old_m [merge_state $path $state]
1584         set s $file_states($path)
1585         set new_m [lindex $s 0]
1586         set icon_name [lindex $s 1]
1587
1588         set o [string index $old_m 0]
1589         set n [string index $new_m 0]
1590         if {$o eq {U}} {
1591                 set o _
1592         }
1593         if {$n eq {U}} {
1594                 set n _
1595         }
1596         display_file_helper     $ui_index $path $icon_name $o $n
1597
1598         if {[string index $old_m 0] eq {U}} {
1599                 set o U
1600         } else {
1601                 set o [string index $old_m 1]
1602         }
1603         if {[string index $new_m 0] eq {U}} {
1604                 set n U
1605         } else {
1606                 set n [string index $new_m 1]
1607         }
1608         display_file_helper     $ui_workdir $path $icon_name $o $n
1609
1610         if {$new_m eq {__}} {
1611                 unset file_states($path)
1612                 catch {unset selected_paths($path)}
1613         }
1614 }
1615
1616 proc display_all_files_helper {w path icon_name m} {
1617         global file_lists
1618
1619         lappend file_lists($w) $path
1620         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1621         $w image create end \
1622                 -align center -padx 5 -pady 1 \
1623                 -name $icon_name \
1624                 -image [mapicon $w $m $path]
1625         $w insert end "[escape_path $path]\n"
1626 }
1627
1628 proc display_all_files {} {
1629         global ui_index ui_workdir
1630         global file_states file_lists
1631         global last_clicked
1632
1633         $ui_index conf -state normal
1634         $ui_workdir conf -state normal
1635
1636         $ui_index delete 0.0 end
1637         $ui_workdir delete 0.0 end
1638         set last_clicked {}
1639
1640         set file_lists($ui_index) [list]
1641         set file_lists($ui_workdir) [list]
1642
1643         foreach path [lsort [array names file_states]] {
1644                 set s $file_states($path)
1645                 set m [lindex $s 0]
1646                 set icon_name [lindex $s 1]
1647
1648                 set s [string index $m 0]
1649                 if {$s ne {U} && $s ne {_}} {
1650                         display_all_files_helper $ui_index $path \
1651                                 $icon_name $s
1652                 }
1653
1654                 if {[string index $m 0] eq {U}} {
1655                         set s U
1656                 } else {
1657                         set s [string index $m 1]
1658                 }
1659                 if {$s ne {_}} {
1660                         display_all_files_helper $ui_workdir $path \
1661                                 $icon_name $s
1662                 }
1663         }
1664
1665         $ui_index conf -state disabled
1666         $ui_workdir conf -state disabled
1667 }
1668
1669 ######################################################################
1670 ##
1671 ## icons
1672
1673 set filemask {
1674 #define mask_width 14
1675 #define mask_height 15
1676 static unsigned char mask_bits[] = {
1677    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1678    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1679    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1680 }
1681
1682 image create bitmap file_plain -background white -foreground black -data {
1683 #define plain_width 14
1684 #define plain_height 15
1685 static unsigned char plain_bits[] = {
1686    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1687    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1688    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1689 } -maskdata $filemask
1690
1691 image create bitmap file_mod -background white -foreground blue -data {
1692 #define mod_width 14
1693 #define mod_height 15
1694 static unsigned char mod_bits[] = {
1695    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1696    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1697    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1698 } -maskdata $filemask
1699
1700 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1701 #define file_fulltick_width 14
1702 #define file_fulltick_height 15
1703 static unsigned char file_fulltick_bits[] = {
1704    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1705    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1706    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1707 } -maskdata $filemask
1708
1709 image create bitmap file_parttick -background white -foreground "#005050" -data {
1710 #define parttick_width 14
1711 #define parttick_height 15
1712 static unsigned char parttick_bits[] = {
1713    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1714    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1715    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1716 } -maskdata $filemask
1717
1718 image create bitmap file_question -background white -foreground black -data {
1719 #define file_question_width 14
1720 #define file_question_height 15
1721 static unsigned char file_question_bits[] = {
1722    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1723    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1724    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1725 } -maskdata $filemask
1726
1727 image create bitmap file_removed -background white -foreground red -data {
1728 #define file_removed_width 14
1729 #define file_removed_height 15
1730 static unsigned char file_removed_bits[] = {
1731    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1732    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1733    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1734 } -maskdata $filemask
1735
1736 image create bitmap file_merge -background white -foreground blue -data {
1737 #define file_merge_width 14
1738 #define file_merge_height 15
1739 static unsigned char file_merge_bits[] = {
1740    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1741    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1742    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1743 } -maskdata $filemask
1744
1745 image create bitmap file_statechange -background white -foreground green -data {
1746 #define file_merge_width 14
1747 #define file_merge_height 15
1748 static unsigned char file_statechange_bits[] = {
1749    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1750    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1751    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1752 } -maskdata $filemask
1753
1754 set ui_index .vpane.files.index.list
1755 set ui_workdir .vpane.files.workdir.list
1756
1757 set all_icons(_$ui_index)   file_plain
1758 set all_icons(A$ui_index)   file_fulltick
1759 set all_icons(M$ui_index)   file_fulltick
1760 set all_icons(D$ui_index)   file_removed
1761 set all_icons(U$ui_index)   file_merge
1762 set all_icons(T$ui_index)   file_statechange
1763
1764 set all_icons(_$ui_workdir) file_plain
1765 set all_icons(M$ui_workdir) file_mod
1766 set all_icons(D$ui_workdir) file_question
1767 set all_icons(U$ui_workdir) file_merge
1768 set all_icons(O$ui_workdir) file_plain
1769 set all_icons(T$ui_workdir) file_statechange
1770
1771 set max_status_desc 0
1772 foreach i {
1773                 {__ {mc "Unmodified"}}
1774
1775                 {_M {mc "Modified, not staged"}}
1776                 {M_ {mc "Staged for commit"}}
1777                 {MM {mc "Portions staged for commit"}}
1778                 {MD {mc "Staged for commit, missing"}}
1779
1780                 {_T {mc "File type changed, not staged"}}
1781                 {T_ {mc "File type changed, staged"}}
1782
1783                 {_O {mc "Untracked, not staged"}}
1784                 {A_ {mc "Staged for commit"}}
1785                 {AM {mc "Portions staged for commit"}}
1786                 {AD {mc "Staged for commit, missing"}}
1787
1788                 {_D {mc "Missing"}}
1789                 {D_ {mc "Staged for removal"}}
1790                 {DO {mc "Staged for removal, still present"}}
1791
1792                 {_U {mc "Requires merge resolution"}}
1793                 {U_ {mc "Requires merge resolution"}}
1794                 {UU {mc "Requires merge resolution"}}
1795                 {UM {mc "Requires merge resolution"}}
1796                 {UD {mc "Requires merge resolution"}}
1797                 {UT {mc "Requires merge resolution"}}
1798         } {
1799         set text [eval [lindex $i 1]]
1800         if {$max_status_desc < [string length $text]} {
1801                 set max_status_desc [string length $text]
1802         }
1803         set all_descs([lindex $i 0]) $text
1804 }
1805 unset i
1806
1807 ######################################################################
1808 ##
1809 ## util
1810
1811 proc scrollbar2many {list mode args} {
1812         foreach w $list {eval $w $mode $args}
1813 }
1814
1815 proc many2scrollbar {list mode sb top bottom} {
1816         $sb set $top $bottom
1817         foreach w $list {$w $mode moveto $top}
1818 }
1819
1820 proc incr_font_size {font {amt 1}} {
1821         set sz [font configure $font -size]
1822         incr sz $amt
1823         font configure $font -size $sz
1824         font configure ${font}bold -size $sz
1825         font configure ${font}italic -size $sz
1826 }
1827
1828 ######################################################################
1829 ##
1830 ## ui commands
1831
1832 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1833
1834 proc do_gitk {revs} {
1835         # -- Always start gitk through whatever we were loaded with.  This
1836         #    lets us bypass using shell process on Windows systems.
1837         #
1838         set exe [_which gitk -script]
1839         set cmd [list [info nameofexecutable] $exe]
1840         if {$exe eq {}} {
1841                 error_popup [mc "Couldn't find gitk in PATH"]
1842         } else {
1843                 global env
1844
1845                 if {[info exists env(GIT_DIR)]} {
1846                         set old_GIT_DIR $env(GIT_DIR)
1847                 } else {
1848                         set old_GIT_DIR {}
1849                 }
1850
1851                 set pwd [pwd]
1852                 cd [file dirname [gitdir]]
1853                 set env(GIT_DIR) [file tail [gitdir]]
1854
1855                 eval exec $cmd $revs &
1856
1857                 if {$old_GIT_DIR eq {}} {
1858                         unset env(GIT_DIR)
1859                 } else {
1860                         set env(GIT_DIR) $old_GIT_DIR
1861                 }
1862                 cd $pwd
1863
1864                 ui_status $::starting_gitk_msg
1865                 after 10000 {
1866                         ui_ready $starting_gitk_msg
1867                 }
1868         }
1869 }
1870
1871 set is_quitting 0
1872 set ret_code    1
1873
1874 proc terminate_me {win} {
1875         global ret_code
1876         if {$win ne {.}} return
1877         exit $ret_code
1878 }
1879
1880 proc do_quit {{rc {1}}} {
1881         global ui_comm is_quitting repo_config commit_type
1882         global GITGUI_BCK_exists GITGUI_BCK_i
1883         global ui_comm_spell
1884         global ret_code
1885
1886         if {$is_quitting} return
1887         set is_quitting 1
1888
1889         if {[winfo exists $ui_comm]} {
1890                 # -- Stash our current commit buffer.
1891                 #
1892                 set save [gitdir GITGUI_MSG]
1893                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1894                         file rename -force [gitdir GITGUI_BCK] $save
1895                         set GITGUI_BCK_exists 0
1896                 } else {
1897                         set msg [string trim [$ui_comm get 0.0 end]]
1898                         regsub -all -line {[ \r\t]+$} $msg {} msg
1899                         if {(![string match amend* $commit_type]
1900                                 || [$ui_comm edit modified])
1901                                 && $msg ne {}} {
1902                                 catch {
1903                                         set fd [open $save w]
1904                                         puts -nonewline $fd $msg
1905                                         close $fd
1906                                 }
1907                         } else {
1908                                 catch {file delete $save}
1909                         }
1910                 }
1911
1912                 # -- Cancel our spellchecker if its running.
1913                 #
1914                 if {[info exists ui_comm_spell]} {
1915                         $ui_comm_spell stop
1916                 }
1917
1918                 # -- Remove our editor backup, its not needed.
1919                 #
1920                 after cancel $GITGUI_BCK_i
1921                 if {$GITGUI_BCK_exists} {
1922                         catch {file delete [gitdir GITGUI_BCK]}
1923                 }
1924
1925                 # -- Stash our current window geometry into this repository.
1926                 #
1927                 set cfg_geometry [list]
1928                 lappend cfg_geometry [wm geometry .]
1929                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
1930                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
1931                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1932                         set rc_geometry {}
1933                 }
1934                 if {$cfg_geometry ne $rc_geometry} {
1935                         catch {git config gui.geometry $cfg_geometry}
1936                 }
1937         }
1938
1939         set ret_code $rc
1940         destroy .
1941 }
1942
1943 proc do_rescan {} {
1944         rescan ui_ready
1945 }
1946
1947 proc ui_do_rescan {} {
1948         rescan {force_first_diff; ui_ready}
1949 }
1950
1951 proc do_commit {} {
1952         commit_tree
1953 }
1954
1955 proc next_diff {} {
1956         global next_diff_p next_diff_w next_diff_i
1957         show_diff $next_diff_p $next_diff_w {}
1958 }
1959
1960 proc find_anchor_pos {lst name} {
1961         set lid [lsearch -sorted -exact $lst $name]
1962
1963         if {$lid == -1} {
1964                 set lid 0
1965                 foreach lname $lst {
1966                         if {$lname >= $name} break
1967                         incr lid
1968                 }
1969         }
1970
1971         return $lid
1972 }
1973
1974 proc find_file_from {flist idx delta path mmask} {
1975         global file_states
1976
1977         set len [llength $flist]
1978         while {$idx >= 0 && $idx < $len} {
1979                 set name [lindex $flist $idx]
1980
1981                 if {$name ne $path && [info exists file_states($name)]} {
1982                         set state [lindex $file_states($name) 0]
1983
1984                         if {$mmask eq {} || [regexp $mmask $state]} {
1985                                 return $idx
1986                         }
1987                 }
1988
1989                 incr idx $delta
1990         }
1991
1992         return {}
1993 }
1994
1995 proc find_next_diff {w path {lno {}} {mmask {}}} {
1996         global next_diff_p next_diff_w next_diff_i
1997         global file_lists ui_index ui_workdir
1998
1999         set flist $file_lists($w)
2000         if {$lno eq {}} {
2001                 set lno [find_anchor_pos $flist $path]
2002         } else {
2003                 incr lno -1
2004         }
2005
2006         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2007                 if {$w eq $ui_index} {
2008                         set mmask "^$mmask"
2009                 } else {
2010                         set mmask "$mmask\$"
2011                 }
2012         }
2013
2014         set idx [find_file_from $flist $lno 1 $path $mmask]
2015         if {$idx eq {}} {
2016                 incr lno -1
2017                 set idx [find_file_from $flist $lno -1 $path $mmask]
2018         }
2019
2020         if {$idx ne {}} {
2021                 set next_diff_w $w
2022                 set next_diff_p [lindex $flist $idx]
2023                 set next_diff_i [expr {$idx+1}]
2024                 return 1
2025         } else {
2026                 return 0
2027         }
2028 }
2029
2030 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2031         global current_diff_path
2032
2033         if {$path ne $current_diff_path} {
2034                 return {}
2035         } elseif {[find_next_diff $w $path $lno $mmask]} {
2036                 return {next_diff;}
2037         } else {
2038                 return {reshow_diff;}
2039         }
2040 }
2041
2042 proc select_first_diff {} {
2043         global ui_workdir
2044
2045         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2046             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2047                 next_diff
2048         }
2049 }
2050
2051 proc force_first_diff {} {
2052         global current_diff_path
2053
2054         if {[info exists file_states($current_diff_path)]} {
2055                 set state [lindex $file_states($current_diff_path) 0]
2056
2057                 if {[string index $state 1] ne {O}} return
2058         }
2059
2060         select_first_diff
2061 }
2062
2063 proc toggle_or_diff {w x y} {
2064         global file_states file_lists current_diff_path ui_index ui_workdir
2065         global last_clicked selected_paths
2066
2067         set pos [split [$w index @$x,$y] .]
2068         set lno [lindex $pos 0]
2069         set col [lindex $pos 1]
2070         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2071         if {$path eq {}} {
2072                 set last_clicked {}
2073                 return
2074         }
2075
2076         set last_clicked [list $w $lno]
2077         array unset selected_paths
2078         $ui_index tag remove in_sel 0.0 end
2079         $ui_workdir tag remove in_sel 0.0 end
2080
2081         # Do not stage files with conflicts
2082         if {[info exists file_states($path)]} {
2083                 set state [lindex $file_states($path) 0]
2084         } else {
2085                 set state {__}
2086         }
2087
2088         if {[string first {U} $state] >= 0} {
2089                 set col 1
2090         }
2091
2092         # Restage the file, or simply show the diff
2093         if {$col == 0 && $y > 1} {
2094                 if {[string index $state 1] eq {O}} {
2095                         set mmask {}
2096                 } else {
2097                         set mmask {[^O]}
2098                 }
2099
2100                 set after [next_diff_after_action $w $path $lno $mmask]
2101
2102                 if {$w eq $ui_index} {
2103                         update_indexinfo \
2104                                 "Unstaging [short_path $path] from commit" \
2105                                 [list $path] \
2106                                 [concat $after [list ui_ready]]
2107                 } elseif {$w eq $ui_workdir} {
2108                         update_index \
2109                                 "Adding [short_path $path]" \
2110                                 [list $path] \
2111                                 [concat $after [list ui_ready]]
2112                 }
2113         } else {
2114                 show_diff $path $w $lno
2115         }
2116 }
2117
2118 proc add_one_to_selection {w x y} {
2119         global file_lists last_clicked selected_paths
2120
2121         set lno [lindex [split [$w index @$x,$y] .] 0]
2122         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2123         if {$path eq {}} {
2124                 set last_clicked {}
2125                 return
2126         }
2127
2128         if {$last_clicked ne {}
2129                 && [lindex $last_clicked 0] ne $w} {
2130                 array unset selected_paths
2131                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2132         }
2133
2134         set last_clicked [list $w $lno]
2135         if {[catch {set in_sel $selected_paths($path)}]} {
2136                 set in_sel 0
2137         }
2138         if {$in_sel} {
2139                 unset selected_paths($path)
2140                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2141         } else {
2142                 set selected_paths($path) 1
2143                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2144         }
2145 }
2146
2147 proc add_range_to_selection {w x y} {
2148         global file_lists last_clicked selected_paths
2149
2150         if {[lindex $last_clicked 0] ne $w} {
2151                 toggle_or_diff $w $x $y
2152                 return
2153         }
2154
2155         set lno [lindex [split [$w index @$x,$y] .] 0]
2156         set lc [lindex $last_clicked 1]
2157         if {$lc < $lno} {
2158                 set begin $lc
2159                 set end $lno
2160         } else {
2161                 set begin $lno
2162                 set end $lc
2163         }
2164
2165         foreach path [lrange $file_lists($w) \
2166                 [expr {$begin - 1}] \
2167                 [expr {$end - 1}]] {
2168                 set selected_paths($path) 1
2169         }
2170         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2171 }
2172
2173 proc show_more_context {} {
2174         global repo_config
2175         if {$repo_config(gui.diffcontext) < 99} {
2176                 incr repo_config(gui.diffcontext)
2177                 reshow_diff
2178         }
2179 }
2180
2181 proc show_less_context {} {
2182         global repo_config
2183         if {$repo_config(gui.diffcontext) > 1} {
2184                 incr repo_config(gui.diffcontext) -1
2185                 reshow_diff
2186         }
2187 }
2188
2189 ######################################################################
2190 ##
2191 ## ui construction
2192
2193 load_config 0
2194 apply_config
2195 set ui_comm {}
2196
2197 # -- Menu Bar
2198 #
2199 menu .mbar -tearoff 0
2200 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2201 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2202 if {[is_enabled branch]} {
2203         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2204 }
2205 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2206         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2207 }
2208 if {[is_enabled transport]} {
2209         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2210         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2211 }
2212 . configure -menu .mbar
2213
2214 # -- Repository Menu
2215 #
2216 menu .mbar.repository
2217
2218 .mbar.repository add command \
2219         -label [mc "Browse Current Branch's Files"] \
2220         -command {browser::new $current_branch}
2221 set ui_browse_current [.mbar.repository index last]
2222 .mbar.repository add command \
2223         -label [mc "Browse Branch Files..."] \
2224         -command browser_open::dialog
2225 .mbar.repository add separator
2226
2227 .mbar.repository add command \
2228         -label [mc "Visualize Current Branch's History"] \
2229         -command {do_gitk $current_branch}
2230 set ui_visualize_current [.mbar.repository index last]
2231 .mbar.repository add command \
2232         -label [mc "Visualize All Branch History"] \
2233         -command {do_gitk --all}
2234 .mbar.repository add separator
2235
2236 proc current_branch_write {args} {
2237         global current_branch
2238         .mbar.repository entryconf $::ui_browse_current \
2239                 -label [mc "Browse %s's Files" $current_branch]
2240         .mbar.repository entryconf $::ui_visualize_current \
2241                 -label [mc "Visualize %s's History" $current_branch]
2242 }
2243 trace add variable current_branch write current_branch_write
2244
2245 if {[is_enabled multicommit]} {
2246         .mbar.repository add command -label [mc "Database Statistics"] \
2247                 -command do_stats
2248
2249         .mbar.repository add command -label [mc "Compress Database"] \
2250                 -command do_gc
2251
2252         .mbar.repository add command -label [mc "Verify Database"] \
2253                 -command do_fsck_objects
2254
2255         .mbar.repository add separator
2256
2257         if {[is_Cygwin]} {
2258                 .mbar.repository add command \
2259                         -label [mc "Create Desktop Icon"] \
2260                         -command do_cygwin_shortcut
2261         } elseif {[is_Windows]} {
2262                 .mbar.repository add command \
2263                         -label [mc "Create Desktop Icon"] \
2264                         -command do_windows_shortcut
2265         } elseif {[is_MacOSX]} {
2266                 .mbar.repository add command \
2267                         -label [mc "Create Desktop Icon"] \
2268                         -command do_macosx_app
2269         }
2270 }
2271
2272 if {[is_MacOSX]} {
2273         proc ::tk::mac::Quit {args} { do_quit }
2274 } else {
2275         .mbar.repository add command -label [mc Quit] \
2276                 -command do_quit \
2277                 -accelerator $M1T-Q
2278 }
2279
2280 # -- Edit Menu
2281 #
2282 menu .mbar.edit
2283 .mbar.edit add command -label [mc Undo] \
2284         -command {catch {[focus] edit undo}} \
2285         -accelerator $M1T-Z
2286 .mbar.edit add command -label [mc Redo] \
2287         -command {catch {[focus] edit redo}} \
2288         -accelerator $M1T-Y
2289 .mbar.edit add separator
2290 .mbar.edit add command -label [mc Cut] \
2291         -command {catch {tk_textCut [focus]}} \
2292         -accelerator $M1T-X
2293 .mbar.edit add command -label [mc Copy] \
2294         -command {catch {tk_textCopy [focus]}} \
2295         -accelerator $M1T-C
2296 .mbar.edit add command -label [mc Paste] \
2297         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2298         -accelerator $M1T-V
2299 .mbar.edit add command -label [mc Delete] \
2300         -command {catch {[focus] delete sel.first sel.last}} \
2301         -accelerator Del
2302 .mbar.edit add separator
2303 .mbar.edit add command -label [mc "Select All"] \
2304         -command {catch {[focus] tag add sel 0.0 end}} \
2305         -accelerator $M1T-A
2306
2307 # -- Branch Menu
2308 #
2309 if {[is_enabled branch]} {
2310         menu .mbar.branch
2311
2312         .mbar.branch add command -label [mc "Create..."] \
2313                 -command branch_create::dialog \
2314                 -accelerator $M1T-N
2315         lappend disable_on_lock [list .mbar.branch entryconf \
2316                 [.mbar.branch index last] -state]
2317
2318         .mbar.branch add command -label [mc "Checkout..."] \
2319                 -command branch_checkout::dialog \
2320                 -accelerator $M1T-O
2321         lappend disable_on_lock [list .mbar.branch entryconf \
2322                 [.mbar.branch index last] -state]
2323
2324         .mbar.branch add command -label [mc "Rename..."] \
2325                 -command branch_rename::dialog
2326         lappend disable_on_lock [list .mbar.branch entryconf \
2327                 [.mbar.branch index last] -state]
2328
2329         .mbar.branch add command -label [mc "Delete..."] \
2330                 -command branch_delete::dialog
2331         lappend disable_on_lock [list .mbar.branch entryconf \
2332                 [.mbar.branch index last] -state]
2333
2334         .mbar.branch add command -label [mc "Reset..."] \
2335                 -command merge::reset_hard
2336         lappend disable_on_lock [list .mbar.branch entryconf \
2337                 [.mbar.branch index last] -state]
2338 }
2339
2340 # -- Commit Menu
2341 #
2342 proc commit_btn_caption {} {
2343         if {[is_enabled nocommit]} {
2344                 return [mc "Done"]
2345         } else {
2346                 return [mc Commit@@verb]
2347         }
2348 }
2349
2350 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2351         menu .mbar.commit
2352
2353         if {![is_enabled nocommit]} {
2354                 .mbar.commit add radiobutton \
2355                         -label [mc "New Commit"] \
2356                         -command do_select_commit_type \
2357                         -variable selected_commit_type \
2358                         -value new
2359                 lappend disable_on_lock \
2360                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2361
2362                 .mbar.commit add radiobutton \
2363                         -label [mc "Amend Last Commit"] \
2364                         -command do_select_commit_type \
2365                         -variable selected_commit_type \
2366                         -value amend
2367                 lappend disable_on_lock \
2368                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2369
2370                 .mbar.commit add separator
2371         }
2372
2373         .mbar.commit add command -label [mc Rescan] \
2374                 -command ui_do_rescan \
2375                 -accelerator F5
2376         lappend disable_on_lock \
2377                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2378
2379         .mbar.commit add command -label [mc "Stage To Commit"] \
2380                 -command do_add_selection \
2381                 -accelerator $M1T-T
2382         lappend disable_on_lock \
2383                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2384
2385         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2386                 -command do_add_all \
2387                 -accelerator $M1T-I
2388         lappend disable_on_lock \
2389                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2390
2391         .mbar.commit add command -label [mc "Unstage From Commit"] \
2392                 -command do_unstage_selection
2393         lappend disable_on_lock \
2394                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2395
2396         .mbar.commit add command -label [mc "Revert Changes"] \
2397                 -command do_revert_selection
2398         lappend disable_on_lock \
2399                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2400
2401         .mbar.commit add separator
2402
2403         .mbar.commit add command -label [mc "Show Less Context"] \
2404                 -command show_less_context \
2405                 -accelerator $M1T-\-
2406
2407         .mbar.commit add command -label [mc "Show More Context"] \
2408                 -command show_more_context \
2409                 -accelerator $M1T-=
2410
2411         .mbar.commit add separator
2412
2413         if {![is_enabled nocommit]} {
2414                 .mbar.commit add command -label [mc "Sign Off"] \
2415                         -command do_signoff \
2416                         -accelerator $M1T-S
2417         }
2418
2419         .mbar.commit add command -label [commit_btn_caption] \
2420                 -command do_commit \
2421                 -accelerator $M1T-Return
2422         lappend disable_on_lock \
2423                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2424 }
2425
2426 # -- Merge Menu
2427 #
2428 if {[is_enabled branch]} {
2429         menu .mbar.merge
2430         .mbar.merge add command -label [mc "Local Merge..."] \
2431                 -command merge::dialog \
2432                 -accelerator $M1T-M
2433         lappend disable_on_lock \
2434                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2435         .mbar.merge add command -label [mc "Abort Merge..."] \
2436                 -command merge::reset_hard
2437         lappend disable_on_lock \
2438                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2439 }
2440
2441 # -- Transport Menu
2442 #
2443 if {[is_enabled transport]} {
2444         menu .mbar.remote
2445
2446         .mbar.remote add command \
2447                 -label [mc "Push..."] \
2448                 -command do_push_anywhere \
2449                 -accelerator $M1T-P
2450         .mbar.remote add command \
2451                 -label [mc "Delete..."] \
2452                 -command remote_branch_delete::dialog
2453 }
2454
2455 if {[is_MacOSX]} {
2456         # -- Apple Menu (Mac OS X only)
2457         #
2458         .mbar add cascade -label Apple -menu .mbar.apple
2459         menu .mbar.apple
2460
2461         .mbar.apple add command -label [mc "About %s" [appname]] \
2462                 -command do_about
2463         .mbar.apple add separator
2464         .mbar.apple add command \
2465                 -label [mc "Preferences..."] \
2466                 -command do_options \
2467                 -accelerator $M1T-,
2468         bind . <$M1B-,> do_options
2469 } else {
2470         # -- Edit Menu
2471         #
2472         .mbar.edit add separator
2473         .mbar.edit add command -label [mc "Options..."] \
2474                 -command do_options
2475 }
2476
2477 # -- Help Menu
2478 #
2479 .mbar add cascade -label [mc Help] -menu .mbar.help
2480 menu .mbar.help
2481
2482 if {![is_MacOSX]} {
2483         .mbar.help add command -label [mc "About %s" [appname]] \
2484                 -command do_about
2485 }
2486
2487 set browser {}
2488 catch {set browser $repo_config(instaweb.browser)}
2489 set doc_path [file dirname [gitexec]]
2490 set doc_path [file join $doc_path Documentation index.html]
2491
2492 if {[is_Cygwin]} {
2493         set doc_path [exec cygpath --mixed $doc_path]
2494 }
2495
2496 if {$browser eq {}} {
2497         if {[is_MacOSX]} {
2498                 set browser open
2499         } elseif {[is_Cygwin]} {
2500                 set program_files [file dirname [exec cygpath --windir]]
2501                 set program_files [file join $program_files {Program Files}]
2502                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
2503                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
2504                 if {[file exists $firefox]} {
2505                         set browser $firefox
2506                 } elseif {[file exists $ie]} {
2507                         set browser $ie
2508                 }
2509                 unset program_files firefox ie
2510         }
2511 }
2512
2513 if {[file isfile $doc_path]} {
2514         set doc_url "file:$doc_path"
2515 } else {
2516         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2517 }
2518
2519 if {$browser ne {}} {
2520         .mbar.help add command -label [mc "Online Documentation"] \
2521                 -command [list exec $browser $doc_url &]
2522 }
2523 unset browser doc_path doc_url
2524
2525 # -- Standard bindings
2526 #
2527 wm protocol . WM_DELETE_WINDOW do_quit
2528 bind all <$M1B-Key-q> do_quit
2529 bind all <$M1B-Key-Q> do_quit
2530 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2531 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2532
2533 set subcommand_args {}
2534 proc usage {} {
2535         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2536         exit 1
2537 }
2538
2539 # -- Not a normal commit type invocation?  Do that instead!
2540 #
2541 switch -- $subcommand {
2542 browser -
2543 blame {
2544         if {$subcommand eq "blame"} {
2545                 set subcommand_args {[--line=<num>] rev? path}
2546         } else {
2547                 set subcommand_args {rev? path}
2548         }
2549         if {$argv eq {}} usage
2550         set head {}
2551         set path {}
2552         set jump_spec {}
2553         set is_path 0
2554         foreach a $argv {
2555                 if {$is_path || [file exists $_prefix$a]} {
2556                         if {$path ne {}} usage
2557                         set path $_prefix$a
2558                         break
2559                 } elseif {$a eq {--}} {
2560                         if {$path ne {}} {
2561                                 if {$head ne {}} usage
2562                                 set head $path
2563                                 set path {}
2564                         }
2565                         set is_path 1
2566                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2567                         if {$jump_spec ne {} || $head ne {}} usage
2568                         set jump_spec [list $lnum]
2569                 } elseif {$head eq {}} {
2570                         if {$head ne {}} usage
2571                         set head $a
2572                         set is_path 1
2573                 } else {
2574                         usage
2575                 }
2576         }
2577         unset is_path
2578
2579         if {$head ne {} && $path eq {}} {
2580                 set path $_prefix$head
2581                 set head {}
2582         }
2583
2584         if {$head eq {}} {
2585                 load_current_branch
2586         } else {
2587                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2588                         if {[catch {
2589                                         set head [git rev-parse --verify $head]
2590                                 } err]} {
2591                                 puts stderr $err
2592                                 exit 1
2593                         }
2594                 }
2595                 set current_branch $head
2596         }
2597
2598         switch -- $subcommand {
2599         browser {
2600                 if {$jump_spec ne {}} usage
2601                 if {$head eq {}} {
2602                         if {$path ne {} && [file isdirectory $path]} {
2603                                 set head $current_branch
2604                         } else {
2605                                 set head $path
2606                                 set path {}
2607                         }
2608                 }
2609                 browser::new $head $path
2610         }
2611         blame   {
2612                 if {$head eq {} && ![file exists $path]} {
2613                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2614                         exit 1
2615                 }
2616                 blame::new $head $path $jump_spec
2617         }
2618         }
2619         return
2620 }
2621 citool -
2622 gui {
2623         if {[llength $argv] != 0} {
2624                 puts -nonewline stderr "usage: $argv0"
2625                 if {$subcommand ne {gui}
2626                         && [file tail $argv0] ne "git-$subcommand"} {
2627                         puts -nonewline stderr " $subcommand"
2628                 }
2629                 puts stderr {}
2630                 exit 1
2631         }
2632         # fall through to setup UI for commits
2633 }
2634 default {
2635         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2636         exit 1
2637 }
2638 }
2639
2640 # -- Branch Control
2641 #
2642 frame .branch \
2643         -borderwidth 1 \
2644         -relief sunken
2645 label .branch.l1 \
2646         -text [mc "Current Branch:"] \
2647         -anchor w \
2648         -justify left
2649 label .branch.cb \
2650         -textvariable current_branch \
2651         -anchor w \
2652         -justify left
2653 pack .branch.l1 -side left
2654 pack .branch.cb -side left -fill x
2655 pack .branch -side top -fill x
2656
2657 # -- Main Window Layout
2658 #
2659 panedwindow .vpane -orient horizontal
2660 panedwindow .vpane.files -orient vertical
2661 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2662 pack .vpane -anchor n -side top -fill both -expand 1
2663
2664 # -- Index File List
2665 #
2666 frame .vpane.files.index -height 100 -width 200
2667 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2668         -background lightgreen -foreground black
2669 text $ui_index -background white -foreground black \
2670         -borderwidth 0 \
2671         -width 20 -height 10 \
2672         -wrap none \
2673         -cursor $cursor_ptr \
2674         -xscrollcommand {.vpane.files.index.sx set} \
2675         -yscrollcommand {.vpane.files.index.sy set} \
2676         -state disabled
2677 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2678 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2679 pack .vpane.files.index.title -side top -fill x
2680 pack .vpane.files.index.sx -side bottom -fill x
2681 pack .vpane.files.index.sy -side right -fill y
2682 pack $ui_index -side left -fill both -expand 1
2683
2684 # -- Working Directory File List
2685 #
2686 frame .vpane.files.workdir -height 100 -width 200
2687 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2688         -background lightsalmon -foreground black
2689 text $ui_workdir -background white -foreground black \
2690         -borderwidth 0 \
2691         -width 20 -height 10 \
2692         -wrap none \
2693         -cursor $cursor_ptr \
2694         -xscrollcommand {.vpane.files.workdir.sx set} \
2695         -yscrollcommand {.vpane.files.workdir.sy set} \
2696         -state disabled
2697 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2698 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2699 pack .vpane.files.workdir.title -side top -fill x
2700 pack .vpane.files.workdir.sx -side bottom -fill x
2701 pack .vpane.files.workdir.sy -side right -fill y
2702 pack $ui_workdir -side left -fill both -expand 1
2703
2704 .vpane.files add .vpane.files.workdir -sticky nsew
2705 .vpane.files add .vpane.files.index -sticky nsew
2706
2707 foreach i [list $ui_index $ui_workdir] {
2708         rmsel_tag $i
2709         $i tag conf in_diff -background [$i tag cget in_sel -background]
2710 }
2711 unset i
2712
2713 # -- Diff and Commit Area
2714 #
2715 frame .vpane.lower -height 300 -width 400
2716 frame .vpane.lower.commarea
2717 frame .vpane.lower.diff -relief sunken -borderwidth 1
2718 pack .vpane.lower.diff -fill both -expand 1
2719 pack .vpane.lower.commarea -side bottom -fill x
2720 .vpane add .vpane.lower -sticky nsew
2721
2722 # -- Commit Area Buttons
2723 #
2724 frame .vpane.lower.commarea.buttons
2725 label .vpane.lower.commarea.buttons.l -text {} \
2726         -anchor w \
2727         -justify left
2728 pack .vpane.lower.commarea.buttons.l -side top -fill x
2729 pack .vpane.lower.commarea.buttons -side left -fill y
2730
2731 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2732         -command ui_do_rescan
2733 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2734 lappend disable_on_lock \
2735         {.vpane.lower.commarea.buttons.rescan conf -state}
2736
2737 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2738         -command do_add_all
2739 pack .vpane.lower.commarea.buttons.incall -side top -fill x
2740 lappend disable_on_lock \
2741         {.vpane.lower.commarea.buttons.incall conf -state}
2742
2743 if {![is_enabled nocommit]} {
2744         button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2745                 -command do_signoff
2746         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2747 }
2748
2749 button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
2750         -command do_commit
2751 pack .vpane.lower.commarea.buttons.commit -side top -fill x
2752 lappend disable_on_lock \
2753         {.vpane.lower.commarea.buttons.commit conf -state}
2754
2755 if {![is_enabled nocommit]} {
2756         button .vpane.lower.commarea.buttons.push -text [mc Push] \
2757                 -command do_push_anywhere
2758         pack .vpane.lower.commarea.buttons.push -side top -fill x
2759 }
2760
2761 # -- Commit Message Buffer
2762 #
2763 frame .vpane.lower.commarea.buffer
2764 frame .vpane.lower.commarea.buffer.header
2765 set ui_comm .vpane.lower.commarea.buffer.t
2766 set ui_coml .vpane.lower.commarea.buffer.header.l
2767
2768 if {![is_enabled nocommit]} {
2769         radiobutton .vpane.lower.commarea.buffer.header.new \
2770                 -text [mc "New Commit"] \
2771                 -command do_select_commit_type \
2772                 -variable selected_commit_type \
2773                 -value new
2774         lappend disable_on_lock \
2775                 [list .vpane.lower.commarea.buffer.header.new conf -state]
2776         radiobutton .vpane.lower.commarea.buffer.header.amend \
2777                 -text [mc "Amend Last Commit"] \
2778                 -command do_select_commit_type \
2779                 -variable selected_commit_type \
2780                 -value amend
2781         lappend disable_on_lock \
2782                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
2783 }
2784
2785 label $ui_coml \
2786         -anchor w \
2787         -justify left
2788 proc trace_commit_type {varname args} {
2789         global ui_coml commit_type
2790         switch -glob -- $commit_type {
2791         initial       {set txt [mc "Initial Commit Message:"]}
2792         amend         {set txt [mc "Amended Commit Message:"]}
2793         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2794         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2795         merge         {set txt [mc "Merge Commit Message:"]}
2796         *             {set txt [mc "Commit Message:"]}
2797         }
2798         $ui_coml conf -text $txt
2799 }
2800 trace add variable commit_type write trace_commit_type
2801 pack $ui_coml -side left -fill x
2802
2803 if {![is_enabled nocommit]} {
2804         pack .vpane.lower.commarea.buffer.header.amend -side right
2805         pack .vpane.lower.commarea.buffer.header.new -side right
2806 }
2807
2808 text $ui_comm -background white -foreground black \
2809         -borderwidth 1 \
2810         -undo true \
2811         -maxundo 20 \
2812         -autoseparators true \
2813         -relief sunken \
2814         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2815         -font font_diff \
2816         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2817 scrollbar .vpane.lower.commarea.buffer.sby \
2818         -command [list $ui_comm yview]
2819 pack .vpane.lower.commarea.buffer.header -side top -fill x
2820 pack .vpane.lower.commarea.buffer.sby -side right -fill y
2821 pack $ui_comm -side left -fill y
2822 pack .vpane.lower.commarea.buffer -side left -fill y
2823
2824 # -- Commit Message Buffer Context Menu
2825 #
2826 set ctxm .vpane.lower.commarea.buffer.ctxm
2827 menu $ctxm -tearoff 0
2828 $ctxm add command \
2829         -label [mc Cut] \
2830         -command {tk_textCut $ui_comm}
2831 $ctxm add command \
2832         -label [mc Copy] \
2833         -command {tk_textCopy $ui_comm}
2834 $ctxm add command \
2835         -label [mc Paste] \
2836         -command {tk_textPaste $ui_comm}
2837 $ctxm add command \
2838         -label [mc Delete] \
2839         -command {$ui_comm delete sel.first sel.last}
2840 $ctxm add separator
2841 $ctxm add command \
2842         -label [mc "Select All"] \
2843         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2844 $ctxm add command \
2845         -label [mc "Copy All"] \
2846         -command {
2847                 $ui_comm tag add sel 0.0 end
2848                 tk_textCopy $ui_comm
2849                 $ui_comm tag remove sel 0.0 end
2850         }
2851 $ctxm add separator
2852 $ctxm add command \
2853         -label [mc "Sign Off"] \
2854         -command do_signoff
2855 set ui_comm_ctxm $ctxm
2856
2857 # -- Diff Header
2858 #
2859 proc trace_current_diff_path {varname args} {
2860         global current_diff_path diff_actions file_states
2861         if {$current_diff_path eq {}} {
2862                 set s {}
2863                 set f {}
2864                 set p {}
2865                 set o disabled
2866         } else {
2867                 set p $current_diff_path
2868                 set s [mapdesc [lindex $file_states($p) 0] $p]
2869                 set f [mc "File:"]
2870                 set p [escape_path $p]
2871                 set o normal
2872         }
2873
2874         .vpane.lower.diff.header.status configure -text $s
2875         .vpane.lower.diff.header.file configure -text $f
2876         .vpane.lower.diff.header.path configure -text $p
2877         foreach w $diff_actions {
2878                 uplevel #0 $w $o
2879         }
2880 }
2881 trace add variable current_diff_path write trace_current_diff_path
2882
2883 frame .vpane.lower.diff.header -background gold
2884 label .vpane.lower.diff.header.status \
2885         -background gold \
2886         -foreground black \
2887         -width $max_status_desc \
2888         -anchor w \
2889         -justify left
2890 label .vpane.lower.diff.header.file \
2891         -background gold \
2892         -foreground black \
2893         -anchor w \
2894         -justify left
2895 label .vpane.lower.diff.header.path \
2896         -background gold \
2897         -foreground black \
2898         -anchor w \
2899         -justify left
2900 pack .vpane.lower.diff.header.status -side left
2901 pack .vpane.lower.diff.header.file -side left
2902 pack .vpane.lower.diff.header.path -fill x
2903 set ctxm .vpane.lower.diff.header.ctxm
2904 menu $ctxm -tearoff 0
2905 $ctxm add command \
2906         -label [mc Copy] \
2907         -command {
2908                 clipboard clear
2909                 clipboard append \
2910                         -format STRING \
2911                         -type STRING \
2912                         -- $current_diff_path
2913         }
2914 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2915 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2916
2917 # -- Diff Body
2918 #
2919 frame .vpane.lower.diff.body
2920 set ui_diff .vpane.lower.diff.body.t
2921 text $ui_diff -background white -foreground black \
2922         -borderwidth 0 \
2923         -width 80 -height 15 -wrap none \
2924         -font font_diff \
2925         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2926         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2927         -state disabled
2928 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2929         -command [list $ui_diff xview]
2930 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2931         -command [list $ui_diff yview]
2932 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2933 pack .vpane.lower.diff.body.sby -side right -fill y
2934 pack $ui_diff -side left -fill both -expand 1
2935 pack .vpane.lower.diff.header -side top -fill x
2936 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2937
2938 $ui_diff tag conf d_cr -elide true
2939 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2940 $ui_diff tag conf d_+ -foreground {#00a000}
2941 $ui_diff tag conf d_- -foreground red
2942
2943 $ui_diff tag conf d_++ -foreground {#00a000}
2944 $ui_diff tag conf d_-- -foreground red
2945 $ui_diff tag conf d_+s \
2946         -foreground {#00a000} \
2947         -background {#e2effa}
2948 $ui_diff tag conf d_-s \
2949         -foreground red \
2950         -background {#e2effa}
2951 $ui_diff tag conf d_s+ \
2952         -foreground {#00a000} \
2953         -background ivory1
2954 $ui_diff tag conf d_s- \
2955         -foreground red \
2956         -background ivory1
2957
2958 $ui_diff tag conf d<<<<<<< \
2959         -foreground orange \
2960         -font font_diffbold
2961 $ui_diff tag conf d======= \
2962         -foreground orange \
2963         -font font_diffbold
2964 $ui_diff tag conf d>>>>>>> \
2965         -foreground orange \
2966         -font font_diffbold
2967
2968 $ui_diff tag raise sel
2969
2970 # -- Diff Body Context Menu
2971 #
2972
2973 proc create_common_diff_popup {ctxm} {
2974         $ctxm add command \
2975                 -label [mc "Show Less Context"] \
2976                 -command show_less_context
2977         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2978         $ctxm add command \
2979                 -label [mc "Show More Context"] \
2980                 -command show_more_context
2981         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2982         $ctxm add separator
2983         $ctxm add command \
2984                 -label [mc Refresh] \
2985                 -command reshow_diff
2986         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2987         $ctxm add command \
2988                 -label [mc Copy] \
2989                 -command {tk_textCopy $ui_diff}
2990         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2991         $ctxm add command \
2992                 -label [mc "Select All"] \
2993                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2994         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2995         $ctxm add command \
2996                 -label [mc "Copy All"] \
2997                 -command {
2998                         $ui_diff tag add sel 0.0 end
2999                         tk_textCopy $ui_diff
3000                         $ui_diff tag remove sel 0.0 end
3001                 }
3002         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3003         $ctxm add separator
3004         $ctxm add command \
3005                 -label [mc "Decrease Font Size"] \
3006                 -command {incr_font_size font_diff -1}
3007         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3008         $ctxm add command \
3009                 -label [mc "Increase Font Size"] \
3010                 -command {incr_font_size font_diff 1}
3011         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3012         $ctxm add separator
3013         set emenu $ctxm.enc
3014         menu $emenu
3015         build_encoding_menu $emenu [list force_diff_encoding]
3016         $ctxm add cascade \
3017                 -label [mc "Encoding"] \
3018                 -menu $emenu
3019         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3020         $ctxm add separator
3021         $ctxm add command -label [mc "Options..."] \
3022                 -command do_options
3023 }
3024
3025 set ctxm .vpane.lower.diff.body.ctxm
3026 menu $ctxm -tearoff 0
3027 $ctxm add command \
3028         -label [mc "Apply/Reverse Hunk"] \
3029         -command {apply_hunk $cursorX $cursorY}
3030 set ui_diff_applyhunk [$ctxm index last]
3031 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3032 $ctxm add command \
3033         -label [mc "Apply/Reverse Line"] \
3034         -command {apply_line $cursorX $cursorY; do_rescan}
3035 set ui_diff_applyline [$ctxm index last]
3036 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3037 $ctxm add separator
3038 create_common_diff_popup $ctxm
3039
3040 set ctxmmg .vpane.lower.diff.body.ctxmmg
3041 menu $ctxmmg -tearoff 0
3042 $ctxmmg add command \
3043         -label [mc "Run Merge Tool"] \
3044         -command {merge_resolve_tool}
3045 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3046 $ctxmmg add separator
3047 $ctxmmg add command \
3048         -label [mc "Use Remote Version"] \
3049         -command {merge_resolve_one 3}
3050 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3051 $ctxmmg add command \
3052         -label [mc "Use Local Version"] \
3053         -command {merge_resolve_one 2}
3054 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3055 $ctxmmg add command \
3056         -label [mc "Revert To Base"] \
3057         -command {merge_resolve_one 1}
3058 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3059 $ctxmmg add separator
3060 $ctxmmg add command \
3061         -label [mc "Stage Working Copy"] \
3062         -command {merge_resolve_one 0}
3063 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3064 $ctxmmg add separator
3065 create_common_diff_popup $ctxmmg
3066
3067 proc popup_diff_menu {ctxm ctxmmg x y X Y} {
3068         global current_diff_path file_states
3069         set ::cursorX $x
3070         set ::cursorY $y
3071         if {[info exists file_states($current_diff_path)]} {
3072                 set state [lindex $file_states($current_diff_path) 0]
3073         } else {
3074                 set state {__}
3075         }
3076         if {[string first {U} $state] >= 0} {
3077                 tk_popup $ctxmmg $X $Y
3078         } else {
3079                 if {$::ui_index eq $::current_diff_side} {
3080                         set l [mc "Unstage Hunk From Commit"]
3081                         set t [mc "Unstage Line From Commit"]
3082                 } else {
3083                         set l [mc "Stage Hunk For Commit"]
3084                         set t [mc "Stage Line For Commit"]
3085                 }
3086                 if {$::is_3way_diff
3087                         || $current_diff_path eq {}
3088                         || {__} eq $state
3089                         || {_O} eq $state
3090                         || {_T} eq $state
3091                         || {T_} eq $state} {
3092                         set s disabled
3093                 } else {
3094                         set s normal
3095                 }
3096                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3097                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3098                 tk_popup $ctxm $X $Y
3099         }
3100 }
3101 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg %x %y %X %Y]
3102
3103 # -- Status Bar
3104 #
3105 set main_status [::status_bar::new .status]
3106 pack .status -anchor w -side bottom -fill x
3107 $main_status show [mc "Initializing..."]
3108
3109 # -- Load geometry
3110 #
3111 catch {
3112 set gm $repo_config(gui.geometry)
3113 wm geometry . [lindex $gm 0]
3114 .vpane sash place 0 \
3115         [lindex $gm 1] \
3116         [lindex [.vpane sash coord 0] 1]
3117 .vpane.files sash place 0 \
3118         [lindex [.vpane.files sash coord 0] 0] \
3119         [lindex $gm 2]
3120 unset gm
3121 }
3122
3123 # -- Key Bindings
3124 #
3125 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3126 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3127 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3128 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3129 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3130 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3131 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3132 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3133 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3134 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3135 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3136 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3137 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3138 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3139 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3140 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3141 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3142 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3143
3144 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3145 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3146 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3147 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3148 bind $ui_diff <$M1B-Key-v> {break}
3149 bind $ui_diff <$M1B-Key-V> {break}
3150 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3151 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3152 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3153 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3154 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3155 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3156 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3157 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3158 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3159 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3160 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3161 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3162 bind $ui_diff <Button-1>   {focus %W}
3163
3164 if {[is_enabled branch]} {
3165         bind . <$M1B-Key-n> branch_create::dialog
3166         bind . <$M1B-Key-N> branch_create::dialog
3167         bind . <$M1B-Key-o> branch_checkout::dialog
3168         bind . <$M1B-Key-O> branch_checkout::dialog
3169         bind . <$M1B-Key-m> merge::dialog
3170         bind . <$M1B-Key-M> merge::dialog
3171 }
3172 if {[is_enabled transport]} {
3173         bind . <$M1B-Key-p> do_push_anywhere
3174         bind . <$M1B-Key-P> do_push_anywhere
3175 }
3176
3177 bind .   <Key-F5>     ui_do_rescan
3178 bind .   <$M1B-Key-r> ui_do_rescan
3179 bind .   <$M1B-Key-R> ui_do_rescan
3180 bind .   <$M1B-Key-s> do_signoff
3181 bind .   <$M1B-Key-S> do_signoff
3182 bind .   <$M1B-Key-t> do_add_selection
3183 bind .   <$M1B-Key-T> do_add_selection
3184 bind .   <$M1B-Key-i> do_add_all
3185 bind .   <$M1B-Key-I> do_add_all
3186 bind .   <$M1B-Key-minus> {show_less_context;break}
3187 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3188 bind .   <$M1B-Key-equal> {show_more_context;break}
3189 bind .   <$M1B-Key-plus> {show_more_context;break}
3190 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3191 bind .   <$M1B-Key-Return> do_commit
3192 foreach i [list $ui_index $ui_workdir] {
3193         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3194         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3195         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3196 }
3197 unset i
3198
3199 set file_lists($ui_index) [list]
3200 set file_lists($ui_workdir) [list]
3201
3202 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
3203 focus -force $ui_comm
3204
3205 # -- Warn the user about environmental problems.  Cygwin's Tcl
3206 #    does *not* pass its env array onto any processes it spawns.
3207 #    This means that git processes get none of our environment.
3208 #
3209 if {[is_Cygwin]} {
3210         set ignored_env 0
3211         set suggest_user {}
3212         set msg [mc "Possible environment issues exist.
3213
3214 The following environment variables are probably
3215 going to be ignored by any Git subprocess run
3216 by %s:
3217
3218 " [appname]]
3219         foreach name [array names env] {
3220                 switch -regexp -- $name {
3221                 {^GIT_INDEX_FILE$} -
3222                 {^GIT_OBJECT_DIRECTORY$} -
3223                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3224                 {^GIT_DIFF_OPTS$} -
3225                 {^GIT_EXTERNAL_DIFF$} -
3226                 {^GIT_PAGER$} -
3227                 {^GIT_TRACE$} -
3228                 {^GIT_CONFIG$} -
3229                 {^GIT_CONFIG_LOCAL$} -
3230                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3231                         append msg " - $name\n"
3232                         incr ignored_env
3233                 }
3234                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3235                         append msg " - $name\n"
3236                         incr ignored_env
3237                         set suggest_user $name
3238                 }
3239                 }
3240         }
3241         if {$ignored_env > 0} {
3242                 append msg [mc "
3243 This is due to a known issue with the
3244 Tcl binary distributed by Cygwin."]
3245
3246                 if {$suggest_user ne {}} {
3247                         append msg [mc "
3248
3249 A good replacement for %s
3250 is placing values for the user.name and
3251 user.email settings into your personal
3252 ~/.gitconfig file.
3253 " $suggest_user]
3254                 }
3255                 warn_popup $msg
3256         }
3257         unset ignored_env msg suggest_user name
3258 }
3259
3260 # -- Only initialize complex UI if we are going to stay running.
3261 #
3262 if {[is_enabled transport]} {
3263         load_all_remotes
3264
3265         set n [.mbar.remote index end]
3266         populate_push_menu
3267         populate_fetch_menu
3268         set n [expr {[.mbar.remote index end] - $n}]
3269         if {$n > 0} {
3270                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3271                 .mbar.remote insert $n separator
3272         }
3273         unset n
3274 }
3275
3276 if {[winfo exists $ui_comm]} {
3277         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3278
3279         # -- If both our backup and message files exist use the
3280         #    newer of the two files to initialize the buffer.
3281         #
3282         if {$GITGUI_BCK_exists} {
3283                 set m [gitdir GITGUI_MSG]
3284                 if {[file isfile $m]} {
3285                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3286                                 catch {file delete [gitdir GITGUI_MSG]}
3287                         } else {
3288                                 $ui_comm delete 0.0 end
3289                                 $ui_comm edit reset
3290                                 $ui_comm edit modified false
3291                                 catch {file delete [gitdir GITGUI_BCK]}
3292                                 set GITGUI_BCK_exists 0
3293                         }
3294                 }
3295                 unset m
3296         }
3297
3298         proc backup_commit_buffer {} {
3299                 global ui_comm GITGUI_BCK_exists
3300
3301                 set m [$ui_comm edit modified]
3302                 if {$m || $GITGUI_BCK_exists} {
3303                         set msg [string trim [$ui_comm get 0.0 end]]
3304                         regsub -all -line {[ \r\t]+$} $msg {} msg
3305
3306                         if {$msg eq {}} {
3307                                 if {$GITGUI_BCK_exists} {
3308                                         catch {file delete [gitdir GITGUI_BCK]}
3309                                         set GITGUI_BCK_exists 0
3310                                 }
3311                         } elseif {$m} {
3312                                 catch {
3313                                         set fd [open [gitdir GITGUI_BCK] w]
3314                                         puts -nonewline $fd $msg
3315                                         close $fd
3316                                         set GITGUI_BCK_exists 1
3317                                 }
3318                         }
3319
3320                         $ui_comm edit modified false
3321                 }
3322
3323                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3324         }
3325
3326         backup_commit_buffer
3327
3328         # -- If the user has aspell available we can drive it
3329         #    in pipe mode to spellcheck the commit message.
3330         #
3331         set spell_cmd [list |]
3332         set spell_dict [get_config gui.spellingdictionary]
3333         lappend spell_cmd aspell
3334         if {$spell_dict ne {}} {
3335                 lappend spell_cmd --master=$spell_dict
3336         }
3337         lappend spell_cmd --mode=none
3338         lappend spell_cmd --encoding=utf-8
3339         lappend spell_cmd pipe
3340         if {$spell_dict eq {none}
3341          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3342                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3343         } else {
3344                 set ui_comm_spell [spellcheck::init \
3345                         $spell_fd \
3346                         $ui_comm \
3347                         $ui_comm_ctxm \
3348                 ]
3349         }
3350         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3351 }
3352
3353 lock_index begin-read
3354 if {![winfo ismapped .]} {
3355         wm deiconify .
3356 }
3357 after 1 {
3358         if {[is_enabled initialamend]} {
3359                 force_amend
3360         } else {
3361                 do_rescan
3362         }
3363
3364         if {[is_enabled nocommitmsg]} {
3365                 $ui_comm configure -state disabled -background gray
3366         }
3367 }
3368 if {[is_enabled multicommit]} {
3369         after 1000 hint_gc
3370 }
3371 if {[is_enabled retcode]} {
3372         bind . <Destroy> {+terminate_me %W}
3373 }