git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision $_repository
   8                 $_q $_authors %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22
  23 $Git::SVN::Log::TZ = $ENV{TZ};
  24 $ENV{TZ} = 'UTC';
  25 $| = 1; # unbuffer STDOUT
  26
  27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  29 require SVN::Ra;
  30 require SVN::Delta;
  31 if ($SVN::Core::VERSION lt '1.1.0') {
  32         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  33 }
  34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  37 use Carp qw/croak/;
  38 use Digest::MD5;
  39 use IO::File qw//;
  40 use File::Basename qw/dirname basename/;
  41 use File::Path qw/mkpath/;
  42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  43 use IPC::Open3;
  44 use Git;
  45
  46 BEGIN {
  47         # import functions from Git into our packages, en masse
  48         no strict 'refs';
  49         foreach (qw/command command_oneline command_noisy command_output_pipe
  50                     command_input_pipe command_close_pipe/) {
  51                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  52                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  53                         __PACKAGE__) {
  54                         *{"${package}::$_"} = \&{"Git::$_"};
  55                 }
  56         }
  57 }
  58
  59 my ($SVN);
  60
  61 $sha1 = qr/[a-f\d]{40}/;
  62 $sha1_short = qr/[a-f\d]{4,40}/;
  63 my ($_stdin, $_help, $_edit,
  64         $_message, $_file,
  65         $_template, $_shared,
  66         $_version, $_fetch_all, $_no_rebase,
  67         $_merge, $_strategy, $_dry_run, $_local,
  68         $_prefix, $_no_checkout, $_url, $_verbose,
  69         $_git_format, $_commit_url, $_tag);
  70 $Git::SVN::_follow_parent = 1;
  71 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  72                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  73                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  74 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  75                 'authors-file|A=s' => \$_authors,
  76                 'repack:i' => \$Git::SVN::_repack,
  77                 'noMetadata' => \$Git::SVN::_no_metadata,
  78                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  79                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  80                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  81                 'no-checkout' => \$_no_checkout,
  82                 'quiet|q' => \$_q,
  83                 'repack-flags|repack-args|repack-opts=s' =>
  84                    \$Git::SVN::_repack_flags,
  85                 'use-log-author' => \$Git::SVN::_use_log_author,
  86                 'add-author-from' => \$Git::SVN::_add_author_from,
  87                 %remote_opts );
  88
  89 my ($_trunk, $_tags, $_branches, $_stdlayout);
  90 my %icv;
  91 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
  92                   'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
  93                   'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
  94                   'stdlayout|s' => \$_stdlayout,
  95                   'minimize-url|m' => \$Git::SVN::_minimize_url,
  96                   'no-metadata' => sub { $icv{noMetadata} = 1 },
  97                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
  98                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
  99                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 100                   %remote_opts );
 101 my %cmt_opts = ( 'edit|e' => \$_edit,
 102                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 103                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 104                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 105                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 106 );
 107
 108 my %cmd = (
 109         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 110                         { 'revision|r=s' => \$_revision,
 111                           'fetch-all|all' => \$_fetch_all,
 112                            %fc_opts } ],
 113         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 114                         { 'revision|r=s' => \$_revision,
 115                            %fc_opts, %init_opts } ],
 116         init => [ \&cmd_init, "Initialize a repo for tracking" .
 117                           " (requires URL argument)",
 118                           \%init_opts ],
 119         'multi-init' => [ \&cmd_multi_init,
 120                           "Deprecated alias for ".
 121                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 122                           \%init_opts ],
 123         dcommit => [ \&cmd_dcommit,
 124                      'Commit several diffs to merge with upstream',
 125                         { 'merge|m|M' => \$_merge,
 126                           'strategy|s=s' => \$_strategy,
 127                           'verbose|v' => \$_verbose,
 128                           'dry-run|n' => \$_dry_run,
 129                           'fetch-all|all' => \$_fetch_all,
 130                           'commit-url=s' => \$_commit_url,
 131                           'revision|r=i' => \$_revision,
 132                           'no-rebase' => \$_no_rebase,
 133                         %cmt_opts, %fc_opts } ],
 134         branch => [ \&cmd_branch,
 135                     'Create a branch in the SVN repository',
 136                     { 'message|m=s' => \$_message,
 137                       'dry-run|n' => \$_dry_run,
 138                       'tag|t' => \$_tag } ],
 139         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 140                  'Create a tag in the SVN repository',
 141                  { 'message|m=s' => \$_message,
 142                    'dry-run|n' => \$_dry_run } ],
 143         'set-tree' => [ \&cmd_set_tree,
 144                         "Set an SVN repository to a git tree-ish",
 145                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 146         'create-ignore' => [ \&cmd_create_ignore,
 147                              'Create a .gitignore per svn:ignore',
 148                              { 'revision|r=i' => \$_revision
 149                              } ],
 150         'propget' => [ \&cmd_propget,
 151                        'Print the value of a property on a file or directory',
 152                        { 'revision|r=i' => \$_revision } ],
 153         'proplist' => [ \&cmd_proplist,
 154                        'List all properties of a file or directory',
 155                        { 'revision|r=i' => \$_revision } ],
 156         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 157                         { 'revision|r=i' => \$_revision
 158                         } ],
 159         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 160                         { 'revision|r=i' => \$_revision
 161                         } ],
 162         'multi-fetch' => [ \&cmd_multi_fetch,
 163                            "Deprecated alias for $0 fetch --all",
 164                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 165         'migrate' => [ sub { },
 166                        # no-op, we automatically run this anyways,
 167                        'Migrate configuration/metadata/layout from
 168                         previous versions of git-svn',
 169                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 170                          %remote_opts } ],
 171         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 172                         { 'limit=i' => \$Git::SVN::Log::limit,
 173                           'revision|r=s' => \$_revision,
 174                           'verbose|v' => \$Git::SVN::Log::verbose,
 175                           'incremental' => \$Git::SVN::Log::incremental,
 176                           'oneline' => \$Git::SVN::Log::oneline,
 177                           'show-commit' => \$Git::SVN::Log::show_commit,
 178                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 179                           'authors-file|A=s' => \$_authors,
 180                           'color' => \$Git::SVN::Log::color,
 181                           'pager=s' => \$Git::SVN::Log::pager
 182                         } ],
 183         'find-rev' => [ \&cmd_find_rev,
 184                         "Translate between SVN revision numbers and tree-ish",
 185                         {} ],
 186         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 187                         { 'merge|m|M' => \$_merge,
 188                           'verbose|v' => \$_verbose,
 189                           'strategy|s=s' => \$_strategy,
 190                           'local|l' => \$_local,
 191                           'fetch-all|all' => \$_fetch_all,
 192                           'dry-run|n' => \$_dry_run,
 193                           %fc_opts } ],
 194         'commit-diff' => [ \&cmd_commit_diff,
 195                            'Commit a diff between two trees',
 196                         { 'message|m=s' => \$_message,
 197                           'file|F=s' => \$_file,
 198                           'revision|r=s' => \$_revision,
 199                         %cmt_opts } ],
 200         'info' => [ \&cmd_info,
 201                     "Show info about the latest SVN revision
 202                      on the current branch",
 203                     { 'url' => \$_url, } ],
 204         'blame' => [ \&Git::SVN::Log::cmd_blame,
 205                     "Show what revision and author last modified each line of a file",
 206                     { 'git-format' => \$_git_format } ],
 207 );
 208
 209 my $cmd;
 210 for (my $i = 0; $i < @ARGV; $i++) {
 211         if (defined $cmd{$ARGV[$i]}) {
 212                 $cmd = $ARGV[$i];
 213                 splice @ARGV, $i, 1;
 214                 last;
 215         }
 216 };
 217
 218 # make sure we're always running at the top-level working directory
 219 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 220         unless (-d $ENV{GIT_DIR}) {
 221                 if ($git_dir_user_set) {
 222                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 223                             "but it is not a directory\n";
 224                 }
 225                 my $git_dir = delete $ENV{GIT_DIR};
 226                 my $cdup = undef;
 227                 git_cmd_try {
 228                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 229                         $git_dir = '.' unless ($cdup);
 230                         chomp $cdup if ($cdup);
 231                         $cdup = "." unless ($cdup && length $cdup);
 232                 } "Already at toplevel, but $git_dir not found\n";
 233                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 234                 unless (-d $git_dir) {
 235                         die "$git_dir still not found after going to ",
 236                             "'$cdup'\n";
 237                 }
 238                 $ENV{GIT_DIR} = $git_dir;
 239         }
 240         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 241 }
 242
 243 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 244
 245 read_repo_config(\%opts);
 246 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 247         Getopt::Long::Configure('pass_through');
 248 }
 249 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 250                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 251                     'id|i=s' => \$Git::SVN::default_ref_id,
 252                     'svn-remote|remote|R=s' => sub {
 253                        $Git::SVN::no_reuse_existing = 1;
 254                        $Git::SVN::default_repo_id = $_[1] });
 255 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 256
 257 usage(0) if $_help;
 258 version() if $_version;
 259 usage(1) unless defined $cmd;
 260 load_authors() if $_authors;
 261
 262 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 263         Git::SVN::Migration::migration_check();
 264 }
 265 Git::SVN::init_vars();
 266 eval {
 267         Git::SVN::verify_remotes_sanity();
 268         $cmd{$cmd}->[0]->(@ARGV);
 269 };
 270 fatal $@ if $@;
 271 post_fetch_checkout();
 272 exit 0;
 273
 274 ####################### primary functions ######################
 275 sub usage {
 276         my $exit = shift || 0;
 277         my $fd = $exit ? \*STDERR : \*STDOUT;
 278         print $fd <<"";
 279 git-svn - bidirectional operations between a single Subversion tree and git
 280 Usage: git svn <command> [options] [arguments]\n
 281
 282         print $fd "Available commands:\n" unless $cmd;
 283
 284         foreach (sort keys %cmd) {
 285                 next if $cmd && $cmd ne $_;
 286                 next if /^multi-/; # don't show deprecated commands
 287                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 288                 foreach (sort keys %{$cmd{$_}->[2]}) {
 289                         # mixed-case options are for .git/config only
 290                         next if /[A-Z]/ && /^[a-z]+$/i;
 291                         # prints out arguments as they should be passed:
 292                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 293                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 294                                                         "--$_" : "-$_" }
 295                                                 split /\|/,$_)," $x\n";
 296                 }
 297         }
 298         print $fd <<"";
 299 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 300 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 301 one git repository and want to keep them separate.  See git-svn(1) for more
 302 information.
 303
 304         exit $exit;
 305 }
 306
 307 sub version {
 308         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 309         exit 0;
 310 }
 311
 312 sub do_git_init_db {
 313         unless (-d $ENV{GIT_DIR}) {
 314                 my @init_db = ('init');
 315                 push @init_db, "--template=$_template" if defined $_template;
 316                 if (defined $_shared) {
 317                         if ($_shared =~ /[a-z]/) {
 318                                 push @init_db, "--shared=$_shared";
 319                         } else {
 320                                 push @init_db, "--shared";
 321                         }
 322                 }
 323                 command_noisy(@init_db);
 324                 $_repository = Git->repository(Repository => ".git");
 325         }
 326         my $set;
 327         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 328         foreach my $i (keys %icv) {
 329                 die "'$set' and '$i' cannot both be set\n" if $set;
 330                 next unless defined $icv{$i};
 331                 command_noisy('config', "$pfx.$i", $icv{$i});
 332                 $set = $i;
 333         }
 334 }
 335
 336 sub init_subdir {
 337         my $repo_path = shift or return;
 338         mkpath([$repo_path]) unless -d $repo_path;
 339         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 340         $ENV{GIT_DIR} = '.git';
 341         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 342 }
 343
 344 sub cmd_clone {
 345         my ($url, $path) = @_;
 346         if (!defined $path &&
 347             (defined $_trunk || defined $_branches || defined $_tags ||
 348              defined $_stdlayout) &&
 349             $url !~ m#^[a-z\+]+://#) {
 350                 $path = $url;
 351         }
 352         $path = basename($url) if !defined $path || !length $path;
 353         cmd_init($url, $path);
 354         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 355 }
 356
 357 sub cmd_init {
 358         if (defined $_stdlayout) {
 359                 $_trunk = 'trunk' if (!defined $_trunk);
 360                 $_tags = 'tags' if (!defined $_tags);
 361                 $_branches = 'branches' if (!defined $_branches);
 362         }
 363         if (defined $_trunk || defined $_branches || defined $_tags) {
 364                 return cmd_multi_init(@_);
 365         }
 366         my $url = shift or die "SVN repository location required ",
 367                                "as a command-line argument\n";
 368         init_subdir(@_);
 369         do_git_init_db();
 370
 371         Git::SVN->init($url);
 372 }
 373
 374 sub cmd_fetch {
 375         if (grep /^\d+=./, @_) {
 376                 die "'<rev>=<commit>' fetch arguments are ",
 377                     "no longer supported.\n";
 378         }
 379         my ($remote) = @_;
 380         if (@_ > 1) {
 381                 die "Usage: $0 fetch [--all] [svn-remote]\n";
 382         }
 383         $remote ||= $Git::SVN::default_repo_id;
 384         if ($_fetch_all) {
 385                 cmd_multi_fetch();
 386         } else {
 387                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 388         }
 389 }
 390
 391 sub cmd_set_tree {
 392         my (@commits) = @_;
 393         if ($_stdin || !@commits) {
 394                 print "Reading from stdin...\n";
 395                 @commits = ();
 396                 while (<STDIN>) {
 397                         if (/\b($sha1_short)\b/o) {
 398                                 unshift @commits, $1;
 399                         }
 400                 }
 401         }
 402         my @revs;
 403         foreach my $c (@commits) {
 404                 my @tmp = command('rev-parse',$c);
 405                 if (scalar @tmp == 1) {
 406                         push @revs, $tmp[0];
 407                 } elsif (scalar @tmp > 1) {
 408                         push @revs, reverse(command('rev-list',@tmp));
 409                 } else {
 410                         fatal "Failed to rev-parse $c";
 411                 }
 412         }
 413         my $gs = Git::SVN->new;
 414         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 415         $gs->fetch;
 416         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 417                 fatal "There are new revisions that were fetched ",
 418                       "and need to be merged (or acknowledged) ",
 419                       "before committing.\nlast rev: $r_last\n",
 420                       " current: $gs->{last_rev}";
 421         }
 422         $gs->set_tree($_) foreach @revs;
 423         print "Done committing ",scalar @revs," revisions to SVN\n";
 424         unlink $gs->{index};
 425 }
 426
 427 sub cmd_dcommit {
 428         my $head = shift;
 429         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 430                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 431                 . "or stash them with `git stash'.\n";
 432         $head ||= 'HEAD';
 433         my @refs;
 434         my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
 435         unless ($gs) {
 436                 die "Unable to determine upstream SVN information from ",
 437                     "$head history.\nPerhaps the repository is empty.";
 438         }
 439         $url = defined $_commit_url ? $_commit_url : $gs->full_url;
 440         my $last_rev = $_revision if defined $_revision;
 441         if ($url) {
 442                 print "Committing to $url ...\n";
 443         }
 444         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 445         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 446                 warn "Attempting to commit more than one change while ",
 447                      "--no-rebase is enabled.\n",
 448                      "If these changes depend on each other, re-running ",
 449                      "without --no-rebase may be required."
 450         }
 451         my $expect_url = $url;
 452         Git::SVN::remove_username($expect_url);
 453         while (1) {
 454                 my $d = shift @$linear_refs or last;
 455                 unless (defined $last_rev) {
 456                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 457                         unless (defined $last_rev) {
 458                                 fatal "Unable to extract revision information ",
 459                                       "from commit $d~1";
 460                         }
 461                 }
 462                 if ($_dry_run) {
 463                         print "diff-tree $d~1 $d\n";
 464                 } else {
 465                         my $cmt_rev;
 466                         my %ed_opts = ( r => $last_rev,
 467                                         log => get_commit_entry($d)->{log},
 468                                         ra => Git::SVN::Ra->new($url),
 469                                         config => SVN::Core::config_get_config(
 470                                                 $Git::SVN::Ra::config_dir
 471                                         ),
 472                                         tree_a => "$d~1",
 473                                         tree_b => $d,
 474                                         editor_cb => sub {
 475                                                print "Committed r$_[0]\n";
 476                                                $cmt_rev = $_[0];
 477                                         },
 478                                         svn_path => '');
 479                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 480                                 print "No changes\n$d~1 == $d\n";
 481                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 482                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 483                                                                $parents->{$d};
 484                         }
 485                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 486                         $last_rev = $cmt_rev;
 487                         next if $_no_rebase;
 488
 489                         # we always want to rebase against the current HEAD,
 490                         # not any head that was passed to us
 491                         my @diff = command('diff-tree', $d,
 492                                            $gs->refname, '--');
 493                         my @finish;
 494                         if (@diff) {
 495                                 @finish = rebase_cmd();
 496                                 print STDERR "W: $d and ", $gs->refname,
 497                                              " differ, using @finish:\n",
 498                                              join("\n", @diff), "\n";
 499                         } else {
 500                                 print "No changes between current HEAD and ",
 501                                       $gs->refname,
 502                                       "\nResetting to the latest ",
 503                                       $gs->refname, "\n";
 504                                 @finish = qw/reset --mixed/;
 505                         }
 506                         command_noisy(@finish, $gs->refname);
 507                         if (@diff) {
 508                                 @refs = ();
 509                                 my ($url_, $rev_, $uuid_, $gs_) =
 510                                               working_head_info($head, \@refs);
 511                                 my ($linear_refs_, $parents_) =
 512                                               linearize_history($gs_, \@refs);
 513                                 if (scalar(@$linear_refs) !=
 514                                     scalar(@$linear_refs_)) {
 515                                         fatal "# of revisions changed ",
 516                                           "\nbefore:\n",
 517                                           join("\n", @$linear_refs),
 518                                           "\n\nafter:\n",
 519                                           join("\n", @$linear_refs_), "\n",
 520                                           'If you are attempting to commit ',
 521                                           "merges, try running:\n\t",
 522                                           'git rebase --interactive',
 523                                           '--preserve-merges ',
 524                                           $gs->refname,
 525                                           "\nBefore dcommitting";
 526                                 }
 527                                 if ($url_ ne $expect_url) {
 528                                         fatal "URL mismatch after rebase: ",
 529                                               "$url_ != $expect_url";
 530                                 }
 531                                 if ($uuid_ ne $uuid) {
 532                                         fatal "uuid mismatch after rebase: ",
 533                                               "$uuid_ != $uuid";
 534                                 }
 535                                 # remap parents
 536                                 my (%p, @l, $i);
 537                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 538                                         my $new = $linear_refs_->[$i] or next;
 539                                         $p{$new} =
 540                                                 $parents->{$linear_refs->[$i]};
 541                                         push @l, $new;
 542                                 }
 543                                 $parents = \%p;
 544                                 $linear_refs = \@l;
 545                         }
 546                 }
 547         }
 548         unlink $gs->{index};
 549 }
 550
 551 sub cmd_branch {
 552         my ($branch_name, $head) = @_;
 553
 554         unless (defined $branch_name && length $branch_name) {
 555                 die(($_tag ? "tag" : "branch") . " name required\n");
 556         }
 557         $head ||= 'HEAD';
 558
 559         my ($src, $rev, undef, $gs) = working_head_info($head);
 560
 561         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 562         my $glob = $remote->{ $_tag ? 'tags' : 'branches' };
 563         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 564         my $dst = join '/', $remote->{url}, $lft, $branch_name, ($rgt || ());
 565
 566         my $ctx = SVN::Client->new(
 567                 auth    => Git::SVN::Ra::_auth_providers(),
 568                 log_msg => sub {
 569                         ${ $_[0] } = defined $_message
 570                                 ? $_message
 571                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 572                                 . $branch_name;
 573                 },
 574         );
 575
 576         eval {
 577                 $ctx->ls($dst, 'HEAD', 0);
 578         } and die "branch ${branch_name} already exists\n";
 579
 580         print "Copying ${src} at r${rev} to ${dst}...\n";
 581         $ctx->copy($src, $rev, $dst)
 582                 unless $_dry_run;
 583
 584         $gs->fetch_all;
 585 }
 586
 587 sub cmd_find_rev {
 588         my $revision_or_hash = shift or die "SVN or git revision required ",
 589                                             "as a command-line argument\n";
 590         my $result;
 591         if ($revision_or_hash =~ /^r\d+$/) {
 592                 my $head = shift;
 593                 $head ||= 'HEAD';
 594                 my @refs;
 595                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 596                 unless ($gs) {
 597                         die "Unable to determine upstream SVN information from ",
 598                             "$head history\n";
 599                 }
 600                 my $desired_revision = substr($revision_or_hash, 1);
 601                 $result = $gs->rev_map_get($desired_revision, $uuid);
 602         } else {
 603                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 604                 $result = $rev;
 605         }
 606         print "$result\n" if $result;
 607 }
 608
 609 sub cmd_rebase {
 610         command_noisy(qw/update-index --refresh/);
 611         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 612         unless ($gs) {
 613                 die "Unable to determine upstream SVN information from ",
 614                     "working tree history\n";
 615         }
 616         if ($_dry_run) {
 617                 print "Remote Branch: " . $gs->refname . "\n";
 618                 print "SVN URL: " . $url . "\n";
 619                 return;
 620         }
 621         if (command(qw/diff-index HEAD --/)) {
 622                 print STDERR "Cannot rebase with uncommited changes:\n";
 623                 command_noisy('status');
 624                 exit 1;
 625         }
 626         unless ($_local) {
 627                 # rebase will checkout for us, so no need to do it explicitly
 628                 $_no_checkout = 'true';
 629                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 630         }
 631         command_noisy(rebase_cmd(), $gs->refname);
 632 }
 633
 634 sub cmd_show_ignore {
 635         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 636         $gs ||= Git::SVN->new;
 637         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 638         $gs->prop_walk($gs->{path}, $r, sub {
 639                 my ($gs, $path, $props) = @_;
 640                 print STDOUT "\n# $path\n";
 641                 my $s = $props->{'svn:ignore'} or return;
 642                 $s =~ s/[\r\n]+/\n/g;
 643                 chomp $s;
 644                 $s =~ s#^#$path#gm;
 645                 print STDOUT "$s\n";
 646         });
 647 }
 648
 649 sub cmd_show_externals {
 650         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 651         $gs ||= Git::SVN->new;
 652         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 653         $gs->prop_walk($gs->{path}, $r, sub {
 654                 my ($gs, $path, $props) = @_;
 655                 print STDOUT "\n# $path\n";
 656                 my $s = $props->{'svn:externals'} or return;
 657                 $s =~ s/[\r\n]+/\n/g;
 658                 chomp $s;
 659                 $s =~ s#^#$path#gm;
 660                 print STDOUT "$s\n";
 661         });
 662 }
 663
 664 sub cmd_create_ignore {
 665         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 666         $gs ||= Git::SVN->new;
 667         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 668         $gs->prop_walk($gs->{path}, $r, sub {
 669                 my ($gs, $path, $props) = @_;
 670                 # $path is of the form /path/to/dir/
 671                 my $ignore = '.' . $path . '.gitignore';
 672                 my $s = $props->{'svn:ignore'} or return;
 673                 open(GITIGNORE, '>', $ignore)
 674                   or fatal("Failed to open `$ignore' for writing: $!");
 675                 $s =~ s/[\r\n]+/\n/g;
 676                 chomp $s;
 677                 # Prefix all patterns so that the ignore doesn't apply
 678                 # to sub-directories.
 679                 $s =~ s#^#/#gm;
 680                 print GITIGNORE "$s\n";
 681                 close(GITIGNORE)
 682                   or fatal("Failed to close `$ignore': $!");
 683                 command_noisy('add', '-f', $ignore);
 684         });
 685 }
 686
 687 sub canonicalize_path {
 688         my ($path) = @_;
 689         my $dot_slash_added = 0;
 690         if (substr($path, 0, 1) ne "/") {
 691                 $path = "./" . $path;
 692                 $dot_slash_added = 1;
 693         }
 694         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 695         # good reason), so let's do this manually.
 696         $path =~ s#/+#/#g;
 697         $path =~ s#/\.(?:/|$)#/#g;
 698         $path =~ s#/[^/]+/\.\.##g;
 699         $path =~ s#/$##g;
 700         $path =~ s#^\./## if $dot_slash_added;
 701         $path =~ s#^/##;
 702         $path =~ s#^\.$##;
 703         return $path;
 704 }
 705
 706 # get_svnprops(PATH)
 707 # ------------------
 708 # Helper for cmd_propget and cmd_proplist below.
 709 sub get_svnprops {
 710         my $path = shift;
 711         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 712         $gs ||= Git::SVN->new;
 713
 714         # prefix THE PATH by the sub-directory from which the user
 715         # invoked us.
 716         $path = $cmd_dir_prefix . $path;
 717         fatal("No such file or directory: $path") unless -e $path;
 718         my $is_dir = -d $path ? 1 : 0;
 719         $path = $gs->{path} . '/' . $path;
 720
 721         # canonicalize the path (otherwise libsvn will abort or fail to
 722         # find the file)
 723         $path = canonicalize_path($path);
 724
 725         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 726         my $props;
 727         if ($is_dir) {
 728                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 729         }
 730         else {
 731                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 732         }
 733         return $props;
 734 }
 735
 736 # cmd_propget (PROP, PATH)
 737 # ------------------------
 738 # Print the SVN property PROP for PATH.
 739 sub cmd_propget {
 740         my ($prop, $path) = @_;
 741         $path = '.' if not defined $path;
 742         usage(1) if not defined $prop;
 743         my $props = get_svnprops($path);
 744         if (not defined $props->{$prop}) {
 745                 fatal("`$path' does not have a `$prop' SVN property.");
 746         }
 747         print $props->{$prop} . "\n";
 748 }
 749
 750 # cmd_proplist (PATH)
 751 # -------------------
 752 # Print the list of SVN properties for PATH.
 753 sub cmd_proplist {
 754         my $path = shift;
 755         $path = '.' if not defined $path;
 756         my $props = get_svnprops($path);
 757         print "Properties on '$path':\n";
 758         foreach (sort keys %{$props}) {
 759                 print "  $_\n";
 760         }
 761 }
 762
 763 sub cmd_multi_init {
 764         my $url = shift;
 765         unless (defined $_trunk || defined $_branches || defined $_tags) {
 766                 usage(1);
 767         }
 768
 769         # there are currently some bugs that prevent multi-init/multi-fetch
 770         # setups from working well without this.
 771         $Git::SVN::_minimize_url = 1;
 772
 773         $_prefix = '' unless defined $_prefix;
 774         if (defined $url) {
 775                 $url =~ s#/+$##;
 776                 init_subdir(@_);
 777         }
 778         do_git_init_db();
 779         if (defined $_trunk) {
 780                 my $trunk_ref = $_prefix . 'trunk';
 781                 # try both old-style and new-style lookups:
 782                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 783                 unless ($gs_trunk) {
 784                         my ($trunk_url, $trunk_path) =
 785                                               complete_svn_url($url, $_trunk);
 786                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 787                                                    undef, $trunk_ref);
 788                 }
 789         }
 790         return unless defined $_branches || defined $_tags;
 791         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 792         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 793         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 794 }
 795
 796 sub cmd_multi_fetch {
 797         my $remotes = Git::SVN::read_all_remotes();
 798         foreach my $repo_id (sort keys %$remotes) {
 799                 if ($remotes->{$repo_id}->{url}) {
 800                         Git::SVN::fetch_all($repo_id, $remotes);
 801                 }
 802         }
 803 }
 804
 805 # this command is special because it requires no metadata
 806 sub cmd_commit_diff {
 807         my ($ta, $tb, $url) = @_;
 808         my $usage = "Usage: $0 commit-diff -r<revision> ".
 809                     "<tree-ish> <tree-ish> [<URL>]";
 810         fatal($usage) if (!defined $ta || !defined $tb);
 811         my $svn_path = '';
 812         if (!defined $url) {
 813                 my $gs = eval { Git::SVN->new };
 814                 if (!$gs) {
 815                         fatal("Needed URL or usable git-svn --id in ",
 816                               "the command-line\n", $usage);
 817                 }
 818                 $url = $gs->{url};
 819                 $svn_path = $gs->{path};
 820         }
 821         unless (defined $_revision) {
 822                 fatal("-r|--revision is a required argument\n", $usage);
 823         }
 824         if (defined $_message && defined $_file) {
 825                 fatal("Both --message/-m and --file/-F specified ",
 826                       "for the commit message.\n",
 827                       "I have no idea what you mean");
 828         }
 829         if (defined $_file) {
 830                 $_message = file_to_s($_file);
 831         } else {
 832                 $_message ||= get_commit_entry($tb)->{log};
 833         }
 834         my $ra ||= Git::SVN::Ra->new($url);
 835         my $r = $_revision;
 836         if ($r eq 'HEAD') {
 837                 $r = $ra->get_latest_revnum;
 838         } elsif ($r !~ /^\d+$/) {
 839                 die "revision argument: $r not understood by git-svn\n";
 840         }
 841         my %ed_opts = ( r => $r,
 842                         log => $_message,
 843                         ra => $ra,
 844                         tree_a => $ta,
 845                         tree_b => $tb,
 846                         editor_cb => sub { print "Committed r$_[0]\n" },
 847                         svn_path => $svn_path );
 848         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 849                 print "No changes\n$ta == $tb\n";
 850         }
 851 }
 852
 853 sub escape_uri_only {
 854         my ($uri) = @_;
 855         my @tmp;
 856         foreach (split m{/}, $uri) {
 857                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
 858                 push @tmp, $_;
 859         }
 860         join('/', @tmp);
 861 }
 862
 863 sub escape_url {
 864         my ($url) = @_;
 865         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
 866                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
 867                 $url = "$scheme://$domain$uri";
 868         }
 869         $url;
 870 }
 871
 872 sub cmd_info {
 873         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
 874         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
 875         if (exists $_[1]) {
 876                 die "Too many arguments specified\n";
 877         }
 878
 879         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
 880
 881         if (!$file_type && !$diff_status) {
 882                 print STDERR "svn: '$path' is not under version control\n";
 883                 exit 1;
 884         }
 885
 886         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 887         unless ($gs) {
 888                 die "Unable to determine upstream SVN information from ",
 889                     "working tree history\n";
 890         }
 891
 892         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
 893         $path = "." if $path eq "";
 894
 895         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
 896
 897         if ($_url) {
 898                 print escape_url($full_url), "\n";
 899                 return;
 900         }
 901
 902         my $result = "Path: $path\n";
 903         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
 904         $result .= "URL: " . escape_url($full_url) . "\n";
 905
 906         eval {
 907                 my $repos_root = $gs->repos_root;
 908                 Git::SVN::remove_username($repos_root);
 909                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
 910         };
 911         if ($@) {
 912                 $result .= "Repository Root: (offline)\n";
 913         }
 914         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
 915         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
 916
 917         $result .= "Node Kind: " .
 918                    ($file_type eq "dir" ? "directory" : "file") . "\n";
 919
 920         my $schedule = $diff_status eq "A"
 921                        ? "add"
 922                        : ($diff_status eq "D" ? "delete" : "normal");
 923         $result .= "Schedule: $schedule\n";
 924
 925         if ($diff_status eq "A") {
 926                 print $result, "\n";
 927                 return;
 928         }
 929
 930         my ($lc_author, $lc_rev, $lc_date_utc);
 931         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
 932         my $log = command_output_pipe(@args);
 933         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
 934         while (<$log>) {
 935                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
 936                         $lc_author = $1;
 937                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
 938                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
 939                         (undef, $lc_rev, undef) = ::extract_metadata($1);
 940                 }
 941         }
 942         close $log;
 943
 944         Git::SVN::Log::set_local_timezone();
 945
 946         $result .= "Last Changed Author: $lc_author\n";
 947         $result .= "Last Changed Rev: $lc_rev\n";
 948         $result .= "Last Changed Date: " .
 949                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
 950
 951         if ($file_type ne "dir") {
 952                 my $text_last_updated_date =
 953                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
 954                 $result .=
 955                     "Text Last Updated: " .
 956                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
 957                     "\n";
 958                 my $checksum;
 959                 if ($diff_status eq "D") {
 960                         my ($fh, $ctx) =
 961                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
 962                         if ($file_type eq "link") {
 963                                 my $file_name = <$fh>;
 964                                 $checksum = md5sum("link $file_name");
 965                         } else {
 966                                 $checksum = md5sum($fh);
 967                         }
 968                         command_close_pipe($fh, $ctx);
 969                 } elsif ($file_type eq "link") {
 970                         my $file_name =
 971                             command(qw(cat-file blob), "HEAD:$path");
 972                         $checksum =
 973                             md5sum("link " . $file_name);
 974                 } else {
 975                         open FILE, "<", $path or die $!;
 976                         $checksum = md5sum(\*FILE);
 977                         close FILE or die $!;
 978                 }
 979                 $result .= "Checksum: " . $checksum . "\n";
 980         }
 981
 982         print $result, "\n";
 983 }
 984
 985 ########################### utility functions #########################
 986
 987 sub rebase_cmd {
 988         my @cmd = qw/rebase/;
 989         push @cmd, '-v' if $_verbose;
 990         push @cmd, qw/--merge/ if $_merge;
 991         push @cmd, "--strategy=$_strategy" if $_strategy;
 992         @cmd;
 993 }
 994
 995 sub post_fetch_checkout {
 996         return if $_no_checkout;
 997         my $gs = $Git::SVN::_head or return;
 998         return if verify_ref('refs/heads/master^0');
 999
1000         my $valid_head = verify_ref('HEAD^0');
1001         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1002         return if ($valid_head || !verify_ref('HEAD^0'));
1003
1004         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1005         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1006         return if -f $index;
1007
1008         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1009         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1010         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1011         print STDERR "Checked out HEAD:\n  ",
1012                      $gs->full_url, " r", $gs->last_rev, "\n";
1013 }
1014
1015 sub complete_svn_url {
1016         my ($url, $path) = @_;
1017         $path =~ s#/+$##;
1018         if ($path !~ m#^[a-z\+]+://#) {
1019                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1020                         fatal("E: '$path' is not a complete URL ",
1021                               "and a separate URL is not specified");
1022                 }
1023                 return ($url, $path);
1024         }
1025         return ($path, '');
1026 }
1027
1028 sub complete_url_ls_init {
1029         my ($ra, $repo_path, $switch, $pfx) = @_;
1030         unless ($repo_path) {
1031                 print STDERR "W: $switch not specified\n";
1032                 return;
1033         }
1034         $repo_path =~ s#/+$##;
1035         if ($repo_path =~ m#^[a-z\+]+://#) {
1036                 $ra = Git::SVN::Ra->new($repo_path);
1037                 $repo_path = '';
1038         } else {
1039                 $repo_path =~ s#^/+##;
1040                 unless ($ra) {
1041                         fatal("E: '$repo_path' is not a complete URL ",
1042                               "and a separate URL is not specified");
1043                 }
1044         }
1045         my $url = $ra->{url};
1046         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1047         my $k = "svn-remote.$gs->{repo_id}.url";
1048         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1049         if ($orig_url && ($orig_url ne $gs->{url})) {
1050                 die "$k already set: $orig_url\n",
1051                     "wanted to set to: $gs->{url}\n";
1052         }
1053         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1054         my $remote_path = "$ra->{svn_path}/$repo_path";
1055         $remote_path =~ s#/+#/#g;
1056         $remote_path =~ s#^/##g;
1057         $remote_path .= "/*" if $remote_path !~ /\*/;
1058         my ($n) = ($switch =~ /^--(\w+)/);
1059         if (length $pfx && $pfx !~ m#/$#) {
1060                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1061         }
1062         command_noisy('config',
1063                       "svn-remote.$gs->{repo_id}.$n",
1064                       "$remote_path:refs/remotes/$pfx*" .
1065                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1066 }
1067
1068 sub verify_ref {
1069         my ($ref) = @_;
1070         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1071                                { STDERR => 0 }); };
1072 }
1073
1074 sub get_tree_from_treeish {
1075         my ($treeish) = @_;
1076         # $treeish can be a symbolic ref, too:
1077         my $type = command_oneline(qw/cat-file -t/, $treeish);
1078         my $expected;
1079         while ($type eq 'tag') {
1080                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1081         }
1082         if ($type eq 'commit') {
1083                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1084                                                     $treeish))[0];
1085                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1086                 die "Unable to get tree from $treeish\n" unless $expected;
1087         } elsif ($type eq 'tree') {
1088                 $expected = $treeish;
1089         } else {
1090                 die "$treeish is a $type, expected tree, tag or commit\n";
1091         }
1092         return $expected;
1093 }
1094
1095 sub get_commit_entry {
1096         my ($treeish) = shift;
1097         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1098         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1099         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1100         open my $log_fh, '>', $commit_editmsg or croak $!;
1101
1102         my $type = command_oneline(qw/cat-file -t/, $treeish);
1103         if ($type eq 'commit' || $type eq 'tag') {
1104                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1105                                                          $type, $treeish);
1106                 my $in_msg = 0;
1107                 my $author;
1108                 my $saw_from = 0;
1109                 my $msgbuf = "";
1110                 while (<$msg_fh>) {
1111                         if (!$in_msg) {
1112                                 $in_msg = 1 if (/^\s*$/);
1113                                 $author = $1 if (/^author (.*>)/);
1114                         } elsif (/^git-svn-id: /) {
1115                                 # skip this for now, we regenerate the
1116                                 # correct one on re-fetch anyways
1117                                 # TODO: set *:merge properties or like...
1118                         } else {
1119                                 if (/^From:/ || /^Signed-off-by:/) {
1120                                         $saw_from = 1;
1121                                 }
1122                                 $msgbuf .= $_;
1123                         }
1124                 }
1125                 $msgbuf =~ s/\s+$//s;
1126                 if ($Git::SVN::_add_author_from && defined($author)
1127                     && !$saw_from) {
1128                         $msgbuf .= "\n\nFrom: $author";
1129                 }
1130                 print $log_fh $msgbuf or croak $!;
1131                 command_close_pipe($msg_fh, $ctx);
1132         }
1133         close $log_fh or croak $!;
1134
1135         if ($_edit || ($type eq 'tree')) {
1136                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1137                 # TODO: strip out spaces, comments, like git-commit.sh
1138                 system($editor, $commit_editmsg);
1139         }
1140         rename $commit_editmsg, $commit_msg or croak $!;
1141         {
1142                 # SVN requires messages to be UTF-8 when entering the repo
1143                 local $/;
1144                 open $log_fh, '<', $commit_msg or croak $!;
1145                 binmode $log_fh;
1146                 chomp($log_entry{log} = <$log_fh>);
1147
1148                 if (my $enc = Git::config('i18n.commitencoding')) {
1149                         require Encode;
1150                         Encode::from_to($log_entry{log}, $enc, 'UTF-8');
1151                 }
1152                 close $log_fh or croak $!;
1153         }
1154         unlink $commit_msg;
1155         \%log_entry;
1156 }
1157
1158 sub s_to_file {
1159         my ($str, $file, $mode) = @_;
1160         open my $fd,'>',$file or croak $!;
1161         print $fd $str,"\n" or croak $!;
1162         close $fd or croak $!;
1163         chmod ($mode &~ umask, $file) if (defined $mode);
1164 }
1165
1166 sub file_to_s {
1167         my $file = shift;
1168         open my $fd,'<',$file or croak "$!: file: $file\n";
1169         local $/;
1170         my $ret = <$fd>;
1171         close $fd or croak $!;
1172         $ret =~ s/\s*$//s;
1173         return $ret;
1174 }
1175
1176 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1177 sub load_authors {
1178         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1179         my $log = $cmd eq 'log';
1180         while (<$authors>) {
1181                 chomp;
1182                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1183                 my ($user, $name, $email) = ($1, $2, $3);
1184                 if ($log) {
1185                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1186                 } else {
1187                         $users{$user} = [$name, $email];
1188                 }
1189         }
1190         close $authors or croak $!;
1191 }
1192
1193 # convert GetOpt::Long specs for use by git-config
1194 sub read_repo_config {
1195         return unless -d $ENV{GIT_DIR};
1196         my $opts = shift;
1197         my @config_only;
1198         foreach my $o (keys %$opts) {
1199                 # if we have mixedCase and a long option-only, then
1200                 # it's a config-only variable that we don't need for
1201                 # the command-line.
1202                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1203                 my $v = $opts->{$o};
1204                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1205                 $key =~ s/-//g;
1206                 my $arg = 'git config';
1207                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1208                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1209                 if (ref $v eq 'ARRAY') {
1210                         chomp(my @tmp = `$arg --get-all svn.$key`);
1211                         @$v = @tmp if @tmp;
1212                 } else {
1213                         chomp(my $tmp = `$arg --get svn.$key`);
1214                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1215                                 $$v = $tmp;
1216                         }
1217                 }
1218         }
1219         delete @$opts{@config_only} if @config_only;
1220 }
1221
1222 sub extract_metadata {
1223         my $id = shift or return (undef, undef, undef);
1224         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1225                                                         \s([a-f\d\-]+)$/x);
1226         if (!defined $rev || !$uuid || !$url) {
1227                 # some of the original repositories I made had
1228                 # identifiers like this:
1229                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1230         }
1231         return ($url, $rev, $uuid);
1232 }
1233
1234 sub cmt_metadata {
1235         return extract_metadata((grep(/^git-svn-id: /,
1236                 command(qw/cat-file commit/, shift)))[-1]);
1237 }
1238
1239 sub working_head_info {
1240         my ($head, $refs) = @_;
1241         my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1242         my ($fh, $ctx) = command_output_pipe(@args, $head);
1243         my $hash;
1244         my %max;
1245         while (<$fh>) {
1246                 if ( m{^commit ($::sha1)$} ) {
1247                         unshift @$refs, $hash if $hash and $refs;
1248                         $hash = $1;
1249                         next;
1250                 }
1251                 next unless s{^\s*(git-svn-id:)}{$1};
1252                 my ($url, $rev, $uuid) = extract_metadata($_);
1253                 if (defined $url && defined $rev) {
1254                         next if $max{$url} and $max{$url} < $rev;
1255                         if (my $gs = Git::SVN->find_by_url($url)) {
1256                                 my $c = $gs->rev_map_get($rev, $uuid);
1257                                 if ($c && $c eq $hash) {
1258                                         close $fh; # break the pipe
1259                                         return ($url, $rev, $uuid, $gs);
1260                                 } else {
1261                                         $max{$url} ||= $gs->rev_map_max;
1262                                 }
1263                         }
1264                 }
1265         }
1266         command_close_pipe($fh, $ctx);
1267         (undef, undef, undef, undef);
1268 }
1269
1270 sub read_commit_parents {
1271         my ($parents, $c) = @_;
1272         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1273         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1274         @{$parents->{$c}} = split(/ /, $p);
1275 }
1276
1277 sub linearize_history {
1278         my ($gs, $refs) = @_;
1279         my %parents;
1280         foreach my $c (@$refs) {
1281                 read_commit_parents(\%parents, $c);
1282         }
1283
1284         my @linear_refs;
1285         my %skip = ();
1286         my $last_svn_commit = $gs->last_commit;
1287         foreach my $c (reverse @$refs) {
1288                 next if $c eq $last_svn_commit;
1289                 last if $skip{$c};
1290
1291                 unshift @linear_refs, $c;
1292                 $skip{$c} = 1;
1293
1294                 # we only want the first parent to diff against for linear
1295                 # history, we save the rest to inject when we finalize the
1296                 # svn commit
1297                 my $fp_a = verify_ref("$c~1");
1298                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1299                 if (!$fp_a || !$fp_b) {
1300                         die "Commit $c\n",
1301                             "has no parent commit, and therefore ",
1302                             "nothing to diff against.\n",
1303                             "You should be working from a repository ",
1304                             "originally created by git-svn\n";
1305                 }
1306                 if ($fp_a ne $fp_b) {
1307                         die "$c~1 = $fp_a, however parsing commit $c ",
1308                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1309                 }
1310
1311                 foreach my $p (@{$parents{$c}}) {
1312                         $skip{$p} = 1;
1313                 }
1314         }
1315         (\@linear_refs, \%parents);
1316 }
1317
1318 sub find_file_type_and_diff_status {
1319         my ($path) = @_;
1320         return ('dir', '') if $path eq '';
1321
1322         my $diff_output =
1323             command_oneline(qw(diff --cached --name-status --), $path) || "";
1324         my $diff_status = (split(' ', $diff_output))[0] || "";
1325
1326         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1327
1328         return (undef, undef) if !$diff_status && !$ls_tree;
1329
1330         if ($diff_status eq "A") {
1331                 return ("link", $diff_status) if -l $path;
1332                 return ("dir", $diff_status) if -d $path;
1333                 return ("file", $diff_status);
1334         }
1335
1336         my $mode = (split(' ', $ls_tree))[0] || "";
1337
1338         return ("link", $diff_status) if $mode eq "120000";
1339         return ("dir", $diff_status) if $mode eq "040000";
1340         return ("file", $diff_status);
1341 }
1342
1343 sub md5sum {
1344         my $arg = shift;
1345         my $ref = ref $arg;
1346         my $md5 = Digest::MD5->new();
1347         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1348                 $md5->addfile($arg) or croak $!;
1349         } elsif ($ref eq 'SCALAR') {
1350                 $md5->add($$arg) or croak $!;
1351         } elsif (!$ref) {
1352                 $md5->add($arg) or croak $!;
1353         } else {
1354                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1355         }
1356         return $md5->hexdigest();
1357 }
1358
1359 package Git::SVN;
1360 use strict;
1361 use warnings;
1362 use Fcntl qw/:DEFAULT :seek/;
1363 use constant rev_map_fmt => 'NH40';
1364 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1365             $_repack $_repack_flags $_use_svm_props $_head
1366             $_use_svnsync_props $no_reuse_existing $_minimize_url
1367             $_use_log_author $_add_author_from/;
1368 use Carp qw/croak/;
1369 use File::Path qw/mkpath/;
1370 use File::Copy qw/copy/;
1371 use IPC::Open3;
1372
1373 my ($_gc_nr, $_gc_period);
1374
1375 # properties that we do not log:
1376 my %SKIP_PROP;
1377 BEGIN {
1378         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1379                                         svn:special svn:executable
1380                                         svn:entry:committed-rev
1381                                         svn:entry:last-author
1382                                         svn:entry:uuid
1383                                         svn:entry:committed-date/;
1384
1385         # some options are read globally, but can be overridden locally
1386         # per [svn-remote "..."] section.  Command-line options will *NOT*
1387         # override options set in an [svn-remote "..."] section
1388         no strict 'refs';
1389         for my $option (qw/follow_parent no_metadata use_svm_props
1390                            use_svnsync_props/) {
1391                 my $key = $option;
1392                 $key =~ tr/_//d;
1393                 my $prop = "-$option";
1394                 *$option = sub {
1395                         my ($self) = @_;
1396                         return $self->{$prop} if exists $self->{$prop};
1397                         my $k = "svn-remote.$self->{repo_id}.$key";
1398                         eval { command_oneline(qw/config --get/, $k) };
1399                         if ($@) {
1400                                 $self->{$prop} = ${"Git::SVN::_$option"};
1401                         } else {
1402                                 my $v = command_oneline(qw/config --bool/,$k);
1403                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1404                         }
1405                         return $self->{$prop};
1406                 }
1407         }
1408 }
1409
1410
1411 my (%LOCKFILES, %INDEX_FILES);
1412 END {
1413         unlink keys %LOCKFILES if %LOCKFILES;
1414         unlink keys %INDEX_FILES if %INDEX_FILES;
1415 }
1416
1417 sub resolve_local_globs {
1418         my ($url, $fetch, $glob_spec) = @_;
1419         return unless defined $glob_spec;
1420         my $ref = $glob_spec->{ref};
1421         my $path = $glob_spec->{path};
1422         foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1423                 next unless m#^refs/remotes/$ref->{regex}$#;
1424                 my $p = $1;
1425                 my $pathname = desanitize_refname($path->full_path($p));
1426                 my $refname = desanitize_refname($ref->full_path($p));
1427                 if (my $existing = $fetch->{$pathname}) {
1428                         if ($existing ne $refname) {
1429                                 die "Refspec conflict:\n",
1430                                     "existing: refs/remotes/$existing\n",
1431                                     " globbed: refs/remotes/$refname\n";
1432                         }
1433                         my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1434                         $u =~ s!^\Q$url\E(/|$)!! or die
1435                           "refs/remotes/$refname: '$url' not found in '$u'\n";
1436                         if ($pathname ne $u) {
1437                                 warn "W: Refspec glob conflict ",
1438                                      "(ref: refs/remotes/$refname):\n",
1439                                      "expected path: $pathname\n",
1440                                      "    real path: $u\n",
1441                                      "Continuing ahead with $u\n";
1442                                 next;
1443                         }
1444                 } else {
1445                         $fetch->{$pathname} = $refname;
1446                 }
1447         }
1448 }
1449
1450 sub parse_revision_argument {
1451         my ($base, $head) = @_;
1452         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1453                 return ($base, $head);
1454         }
1455         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1456         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1457         return ($head, $head) if ($::_revision eq 'HEAD');
1458         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1459         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1460         die "revision argument: $::_revision not understood by git-svn\n";
1461 }
1462
1463 sub fetch_all {
1464         my ($repo_id, $remotes) = @_;
1465         if (ref $repo_id) {
1466                 my $gs = $repo_id;
1467                 $repo_id = undef;
1468                 $repo_id = $gs->{repo_id};
1469         }
1470         $remotes ||= read_all_remotes();
1471         my $remote = $remotes->{$repo_id} or
1472                      die "[svn-remote \"$repo_id\"] unknown\n";
1473         my $fetch = $remote->{fetch};
1474         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1475         my (@gs, @globs);
1476         my $ra = Git::SVN::Ra->new($url);
1477         my $uuid = $ra->get_uuid;
1478         my $head = $ra->get_latest_revnum;
1479         my $base = defined $fetch ? $head : 0;
1480
1481         # read the max revs for wildcard expansion (branches/*, tags/*)
1482         foreach my $t (qw/branches tags/) {
1483                 defined $remote->{$t} or next;
1484                 push @globs, $remote->{$t};
1485                 my $max_rev = eval { tmp_config(qw/--int --get/,
1486                                          "svn-remote.$repo_id.${t}-maxRev") };
1487                 if (defined $max_rev && ($max_rev < $base)) {
1488                         $base = $max_rev;
1489                 } elsif (!defined $max_rev) {
1490                         $base = 0;
1491                 }
1492         }
1493
1494         if ($fetch) {
1495                 foreach my $p (sort keys %$fetch) {
1496                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1497                         my $lr = $gs->rev_map_max;
1498                         if (defined $lr) {
1499                                 $base = $lr if ($lr < $base);
1500                         }
1501                         push @gs, $gs;
1502                 }
1503         }
1504
1505         ($base, $head) = parse_revision_argument($base, $head);
1506         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1507 }
1508
1509 sub read_all_remotes {
1510         my $r = {};
1511         my $use_svm_props = eval { command_oneline(qw/config --bool
1512             svn.useSvmProps/) };
1513         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1514         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1515                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*(.+)\s*$!) {
1516                         my ($remote, $local_ref, $_remote_ref) = ($1, $2, $3);
1517                         die("svn-remote.$remote: remote ref '$_remote_ref' "
1518                             . "must start with 'refs/remotes/'\n")
1519                                 unless $_remote_ref =~ m{^refs/remotes/(.+)};
1520                         my $remote_ref = $1;
1521                         $local_ref =~ s{^/}{};
1522                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1523                         $r->{$remote}->{svm} = {} if $use_svm_props;
1524                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1525                         $r->{$1}->{svm} = {};
1526                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1527                         $r->{$1}->{url} = $2;
1528                 } elsif (m!^(.+)\.(branches|tags)=
1529                            (.*):refs/remotes/(.+)\s*$/!x) {
1530                         my ($p, $g) = ($3, $4);
1531                         my $rs = $r->{$1}->{$2} = {
1532                                           t => $2,
1533                                           remote => $1,
1534                                           path => Git::SVN::GlobSpec->new($p),
1535                                           ref => Git::SVN::GlobSpec->new($g) };
1536                         if (length($rs->{ref}->{right}) != 0) {
1537                                 die "The '*' glob character must be the last ",
1538                                     "character of '$g'\n";
1539                         }
1540                 }
1541         }
1542
1543         map {
1544                 if (defined $r->{$_}->{svm}) {
1545                         my $svm;
1546                         eval {
1547                                 my $section = "svn-remote.$_";
1548                                 $svm = {
1549                                         source => tmp_config('--get',
1550                                             "$section.svm-source"),
1551                                         replace => tmp_config('--get',
1552                                             "$section.svm-replace"),
1553                                 }
1554                         };
1555                         $r->{$_}->{svm} = $svm;
1556                 }
1557         } keys %$r;
1558
1559         $r;
1560 }
1561
1562 sub init_vars {
1563         $_gc_nr = $_gc_period = 1000;
1564         if (defined $_repack || defined $_repack_flags) {
1565                warn "Repack options are obsolete; they have no effect.\n";
1566         }
1567 }
1568
1569 sub verify_remotes_sanity {
1570         return unless -d $ENV{GIT_DIR};
1571         my %seen;
1572         foreach (command(qw/config -l/)) {
1573                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1574                         if ($seen{$1}) {
1575                                 die "Remote ref refs/remote/$1 is tracked by",
1576                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1577                                     "Please resolve this ambiguity in ",
1578                                     "your git configuration file before ",
1579                                     "continuing\n";
1580                         }
1581                         $seen{$1} = $_;
1582                 }
1583         }
1584 }
1585
1586 sub find_existing_remote {
1587         my ($url, $remotes) = @_;
1588         return undef if $no_reuse_existing;
1589         my $existing;
1590         foreach my $repo_id (keys %$remotes) {
1591                 my $u = $remotes->{$repo_id}->{url} or next;
1592                 next if $u ne $url;
1593                 $existing = $repo_id;
1594                 last;
1595         }
1596         $existing;
1597 }
1598
1599 sub init_remote_config {
1600         my ($self, $url, $no_write) = @_;
1601         $url =~ s!/+$!!; # strip trailing slash
1602         my $r = read_all_remotes();
1603         my $existing = find_existing_remote($url, $r);
1604         if ($existing) {
1605                 unless ($no_write) {
1606                         print STDERR "Using existing ",
1607                                      "[svn-remote \"$existing\"]\n";
1608                 }
1609                 $self->{repo_id} = $existing;
1610         } elsif ($_minimize_url) {
1611                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1612                 $existing = find_existing_remote($min_url, $r);
1613                 if ($existing) {
1614                         unless ($no_write) {
1615                                 print STDERR "Using existing ",
1616                                              "[svn-remote \"$existing\"]\n";
1617                         }
1618                         $self->{repo_id} = $existing;
1619                 }
1620                 if ($min_url ne $url) {
1621                         unless ($no_write) {
1622                                 print STDERR "Using higher level of URL: ",
1623                                              "$url => $min_url\n";
1624                         }
1625                         my $old_path = $self->{path};
1626                         $self->{path} = $url;
1627                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1628                         if (length $old_path) {
1629                                 $self->{path} .= "/$old_path";
1630                         }
1631                         $url = $min_url;
1632                 }
1633         }
1634         my $orig_url;
1635         if (!$existing) {
1636                 # verify that we aren't overwriting anything:
1637                 $orig_url = eval {
1638                         command_oneline('config', '--get',
1639                                         "svn-remote.$self->{repo_id}.url")
1640                 };
1641                 if ($orig_url && ($orig_url ne $url)) {
1642                         die "svn-remote.$self->{repo_id}.url already set: ",
1643                             "$orig_url\nwanted to set to: $url\n";
1644                 }
1645         }
1646         my ($xrepo_id, $xpath) = find_ref($self->refname);
1647         if (defined $xpath) {
1648                 die "svn-remote.$xrepo_id.fetch already set to track ",
1649                     "$xpath:refs/remotes/", $self->refname, "\n";
1650         }
1651         unless ($no_write) {
1652                 command_noisy('config',
1653                               "svn-remote.$self->{repo_id}.url", $url);
1654                 $self->{path} =~ s{^/}{};
1655                 command_noisy('config', '--add',
1656                               "svn-remote.$self->{repo_id}.fetch",
1657                               "$self->{path}:".$self->refname);
1658         }
1659         $self->{url} = $url;
1660 }
1661
1662 sub find_by_url { # repos_root and, path are optional
1663         my ($class, $full_url, $repos_root, $path) = @_;
1664
1665         return undef unless defined $full_url;
1666         remove_username($full_url);
1667         remove_username($repos_root) if defined $repos_root;
1668         my $remotes = read_all_remotes();
1669         if (defined $full_url && defined $repos_root && !defined $path) {
1670                 $path = $full_url;
1671                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1672         }
1673         foreach my $repo_id (keys %$remotes) {
1674                 my $u = $remotes->{$repo_id}->{url} or next;
1675                 remove_username($u);
1676                 next if defined $repos_root && $repos_root ne $u;
1677
1678                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1679                 foreach (qw/branches tags/) {
1680                         resolve_local_globs($u, $fetch,
1681                                             $remotes->{$repo_id}->{$_});
1682                 }
1683                 my $p = $path;
1684                 my $rwr = rewrite_root({repo_id => $repo_id});
1685                 my $svm = $remotes->{$repo_id}->{svm}
1686                         if defined $remotes->{$repo_id}->{svm};
1687                 unless (defined $p) {
1688                         $p = $full_url;
1689                         my $z = $u;
1690                         my $prefix = '';
1691                         if ($rwr) {
1692                                 $z = $rwr;
1693                         } elsif (defined $svm) {
1694                                 $z = $svm->{source};
1695                                 $prefix = $svm->{replace};
1696                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
1697                                 $prefix =~ s#/$##;
1698                         }
1699                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
1700                 }
1701                 foreach my $f (keys %$fetch) {
1702                         next if $f ne $p;
1703                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1704                 }
1705         }
1706         undef;
1707 }
1708
1709 sub init {
1710         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1711         my $self = _new($class, $repo_id, $ref_id, $path);
1712         if (defined $url) {
1713                 $self->init_remote_config($url, $no_write);
1714         }
1715         $self;
1716 }
1717
1718 sub find_ref {
1719         my ($ref_id) = @_;
1720         foreach (command(qw/config -l/)) {
1721                 next unless m!^svn-remote\.(.+)\.fetch=
1722                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1723                 my ($repo_id, $path, $ref) = ($1, $2, $3);
1724                 if ($ref eq $ref_id) {
1725                         $path = '' if ($path =~ m#^\./?#);
1726                         return ($repo_id, $path);
1727                 }
1728         }
1729         (undef, undef, undef);
1730 }
1731
1732 sub new {
1733         my ($class, $ref_id, $repo_id, $path) = @_;
1734         if (defined $ref_id && !defined $repo_id && !defined $path) {
1735                 ($repo_id, $path) = find_ref($ref_id);
1736                 if (!defined $repo_id) {
1737                         die "Could not find a \"svn-remote.*.fetch\" key ",
1738                             "in the repository configuration matching: ",
1739                             "refs/remotes/$ref_id\n";
1740                 }
1741         }
1742         my $self = _new($class, $repo_id, $ref_id, $path);
1743         if (!defined $self->{path} || !length $self->{path}) {
1744                 my $fetch = command_oneline('config', '--get',
1745                                             "svn-remote.$repo_id.fetch",
1746                                             ":refs/remotes/$ref_id\$") or
1747                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1748                          "\":refs/remotes/$ref_id\$\" in config\n";
1749                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1750         }
1751         $self->{url} = command_oneline('config', '--get',
1752                                        "svn-remote.$repo_id.url") or
1753                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1754         $self->rebuild;
1755         $self;
1756 }
1757
1758 sub refname {
1759         my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1760
1761         # It cannot end with a slash /, we'll throw up on this because
1762         # SVN can't have directories with a slash in their name, either:
1763         if ($refname =~ m{/$}) {
1764                 die "ref: '$refname' ends with a trailing slash, this is ",
1765                     "not permitted by git nor Subversion\n";
1766         }
1767
1768         # It cannot have ASCII control character space, tilde ~, caret ^,
1769         # colon :, question-mark ?, asterisk *, space, or open bracket [
1770         # anywhere.
1771         #
1772         # Additionally, % must be escaped because it is used for escaping
1773         # and we want our escaped refname to be reversible
1774         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1775
1776         # no slash-separated component can begin with a dot .
1777         # /.* becomes /%2E*
1778         $refname =~ s{/\.}{/%2E}g;
1779
1780         # It cannot have two consecutive dots .. anywhere
1781         # .. becomes %2E%2E
1782         $refname =~ s{\.\.}{%2E%2E}g;
1783
1784         return $refname;
1785 }
1786
1787 sub desanitize_refname {
1788         my ($refname) = @_;
1789         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1790         return $refname;
1791 }
1792
1793 sub svm_uuid {
1794         my ($self) = @_;
1795         return $self->{svm}->{uuid} if $self->svm;
1796         $self->ra;
1797         unless ($self->{svm}) {
1798                 die "SVM UUID not cached, and reading remotely failed\n";
1799         }
1800         $self->{svm}->{uuid};
1801 }
1802
1803 sub svm {
1804         my ($self) = @_;
1805         return $self->{svm} if $self->{svm};
1806         my $svm;
1807         # see if we have it in our config, first:
1808         eval {
1809                 my $section = "svn-remote.$self->{repo_id}";
1810                 $svm = {
1811                   source => tmp_config('--get', "$section.svm-source"),
1812                   uuid => tmp_config('--get', "$section.svm-uuid"),
1813                   replace => tmp_config('--get', "$section.svm-replace"),
1814                 }
1815         };
1816         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1817                 $self->{svm} = $svm;
1818         }
1819         $self->{svm};
1820 }
1821
1822 sub _set_svm_vars {
1823         my ($self, $ra) = @_;
1824         return $ra if $self->svm;
1825
1826         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1827                     "(svm:source, svm:uuid) ",
1828                     "from the following URLs:\n" );
1829         sub read_svm_props {
1830                 my ($self, $ra, $path, $r) = @_;
1831                 my $props = ($ra->get_dir($path, $r))[2];
1832                 my $src = $props->{'svm:source'};
1833                 my $uuid = $props->{'svm:uuid'};
1834                 return undef if (!$src || !$uuid);
1835
1836                 chomp($src, $uuid);
1837
1838                 $uuid =~ m{^[0-9a-f\-]{30,}$}
1839                     or die "doesn't look right - svm:uuid is '$uuid'\n";
1840
1841                 # the '!' is used to mark the repos_root!/relative/path
1842                 $src =~ s{/?!/?}{/};
1843                 $src =~ s{/+$}{}; # no trailing slashes please
1844                 # username is of no interest
1845                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1846
1847                 my $replace = $ra->{url};
1848                 $replace .= "/$path" if length $path;
1849
1850                 my $section = "svn-remote.$self->{repo_id}";
1851                 tmp_config("$section.svm-source", $src);
1852                 tmp_config("$section.svm-replace", $replace);
1853                 tmp_config("$section.svm-uuid", $uuid);
1854                 $self->{svm} = {
1855                         source => $src,
1856                         uuid => $uuid,
1857                         replace => $replace
1858                 };
1859         }
1860
1861         my $r = $ra->get_latest_revnum;
1862         my $path = $self->{path};
1863         my %tried;
1864         while (length $path) {
1865                 unless ($tried{"$self->{url}/$path"}) {
1866                         return $ra if $self->read_svm_props($ra, $path, $r);
1867                         $tried{"$self->{url}/$path"} = 1;
1868                 }
1869                 $path =~ s#/?[^/]+$##;
1870         }
1871         die "Path: '$path' should be ''\n" if $path ne '';
1872         return $ra if $self->read_svm_props($ra, $path, $r);
1873         $tried{"$self->{url}/$path"} = 1;
1874
1875         if ($ra->{repos_root} eq $self->{url}) {
1876                 die @err, (map { "  $_\n" } keys %tried), "\n";
1877         }
1878
1879         # nope, make sure we're connected to the repository root:
1880         my $ok;
1881         my @tried_b;
1882         $path = $ra->{svn_path};
1883         $ra = Git::SVN::Ra->new($ra->{repos_root});
1884         while (length $path) {
1885                 unless ($tried{"$ra->{url}/$path"}) {
1886                         $ok = $self->read_svm_props($ra, $path, $r);
1887                         last if $ok;
1888                         $tried{"$ra->{url}/$path"} = 1;
1889                 }
1890                 $path =~ s#/?[^/]+$##;
1891         }
1892         die "Path: '$path' should be ''\n" if $path ne '';
1893         $ok ||= $self->read_svm_props($ra, $path, $r);
1894         $tried{"$ra->{url}/$path"} = 1;
1895         if (!$ok) {
1896                 die @err, (map { "  $_\n" } keys %tried), "\n";
1897         }
1898         Git::SVN::Ra->new($self->{url});
1899 }
1900
1901 sub svnsync {
1902         my ($self) = @_;
1903         return $self->{svnsync} if $self->{svnsync};
1904
1905         if ($self->no_metadata) {
1906                 die "Can't have both 'noMetadata' and ",
1907                     "'useSvnsyncProps' options set!\n";
1908         }
1909         if ($self->rewrite_root) {
1910                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1911                     "options set!\n";
1912         }
1913
1914         my $svnsync;
1915         # see if we have it in our config, first:
1916         eval {
1917                 my $section = "svn-remote.$self->{repo_id}";
1918
1919                 my $url = tmp_config('--get', "$section.svnsync-url");
1920                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1921                    die "doesn't look right - svn:sync-from-url is '$url'\n";
1922
1923                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1924                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1925                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1926
1927                 $svnsync = { url => $url, uuid => $uuid }
1928         };
1929         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1930                 return $self->{svnsync} = $svnsync;
1931         }
1932
1933         my $err = "useSvnsyncProps set, but failed to read " .
1934                   "svnsync property: svn:sync-from-";
1935         my $rp = $self->ra->rev_proplist(0);
1936
1937         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1938         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1939                    die "doesn't look right - svn:sync-from-url is '$url'\n";
1940
1941         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1942         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1943                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1944
1945         my $section = "svn-remote.$self->{repo_id}";
1946         tmp_config('--add', "$section.svnsync-uuid", $uuid);
1947         tmp_config('--add', "$section.svnsync-url", $url);
1948         return $self->{svnsync} = { url => $url, uuid => $uuid };
1949 }
1950
1951 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1952 # remote lookup (useful for 'git svn log').
1953 sub ra_uuid {
1954         my ($self) = @_;
1955         unless ($self->{ra_uuid}) {
1956                 my $key = "svn-remote.$self->{repo_id}.uuid";
1957                 my $uuid = eval { tmp_config('--get', $key) };
1958                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1959                         $self->{ra_uuid} = $uuid;
1960                 } else {
1961                         die "ra_uuid called without URL\n" unless $self->{url};
1962                         $self->{ra_uuid} = $self->ra->get_uuid;
1963                         tmp_config('--add', $key, $self->{ra_uuid});
1964                 }
1965         }
1966         $self->{ra_uuid};
1967 }
1968
1969 sub _set_repos_root {
1970         my ($self, $repos_root) = @_;
1971         my $k = "svn-remote.$self->{repo_id}.reposRoot";
1972         $repos_root ||= $self->ra->{repos_root};
1973         tmp_config($k, $repos_root);
1974         $repos_root;
1975 }
1976
1977 sub repos_root {
1978         my ($self) = @_;
1979         my $k = "svn-remote.$self->{repo_id}.reposRoot";
1980         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1981 }
1982
1983 sub ra {
1984         my ($self) = shift;
1985         my $ra = Git::SVN::Ra->new($self->{url});
1986         $self->_set_repos_root($ra->{repos_root});
1987         if ($self->use_svm_props && !$self->{svm}) {
1988                 if ($self->no_metadata) {
1989                         die "Can't have both 'noMetadata' and ",
1990                             "'useSvmProps' options set!\n";
1991                 } elsif ($self->use_svnsync_props) {
1992                         die "Can't have both 'useSvnsyncProps' and ",
1993                             "'useSvmProps' options set!\n";
1994                 }
1995                 $ra = $self->_set_svm_vars($ra);
1996                 $self->{-want_revprops} = 1;
1997         }
1998         $ra;
1999 }
2000
2001 sub rel_path {
2002         my ($self) = @_;
2003         my $repos_root = $self->ra->{repos_root};
2004         return $self->{path} if ($self->{url} eq $repos_root);
2005         my $url = $self->{url} .
2006                   (length $self->{path} ? "/$self->{path}" : $self->{path});
2007         $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
2008         $url;
2009 }
2010
2011 # prop_walk(PATH, REV, SUB)
2012 # -------------------------
2013 # Recursively traverse PATH at revision REV and invoke SUB for each
2014 # directory that contains a SVN property.  SUB will be invoked as
2015 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2016 # Git::SVN, `path' the path to the directory where the properties
2017 # `props' were found.  The `path' will be relative to point of checkout,
2018 # that is, if url://repo/trunk is the current Git branch, and that
2019 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2020 # as `path' (note the trailing `/').
2021 sub prop_walk {
2022         my ($self, $path, $rev, $sub) = @_;
2023
2024         $path =~ s#^/##;
2025         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2026         $path =~ s#^/*#/#g;
2027         my $p = $path;
2028         # Strip the irrelevant part of the path.
2029         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2030         # Ensure the path is terminated by a `/'.
2031         $p =~ s#/*$#/#;
2032
2033         # The properties contain all the internal SVN stuff nobody
2034         # (usually) cares about.
2035         my $interesting_props = 0;
2036         foreach (keys %{$props}) {
2037                 # If it doesn't start with `svn:', it must be a
2038                 # user-defined property.
2039                 ++$interesting_props and next if $_ !~ /^svn:/;
2040                 # FIXME: Fragile, if SVN adds new public properties,
2041                 # this needs to be updated.
2042                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2043                                                  |eol-style|mime-type
2044                                                  |externals|needs-lock)$/x;
2045         }
2046         &$sub($self, $p, $props) if $interesting_props;
2047
2048         foreach (sort keys %$dirent) {
2049                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2050                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2051         }
2052 }
2053
2054 sub last_rev { ($_[0]->last_rev_commit)[0] }
2055 sub last_commit { ($_[0]->last_rev_commit)[1] }
2056
2057 # returns the newest SVN revision number and newest commit SHA1
2058 sub last_rev_commit {
2059         my ($self) = @_;
2060         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2061                 return ($self->{last_rev}, $self->{last_commit});
2062         }
2063         my $c = ::verify_ref($self->refname.'^0');
2064         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2065                 my $rev = (::cmt_metadata($c))[1];
2066                 if (defined $rev) {
2067                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2068                         return ($rev, $c);
2069                 }
2070         }
2071         my $map_path = $self->map_path;
2072         unless (-e $map_path) {
2073                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2074                 return (undef, undef);
2075         }
2076         my ($rev, $commit) = $self->rev_map_max(1);
2077         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2078         return ($rev, $commit);
2079 }
2080
2081 sub get_fetch_range {
2082         my ($self, $min, $max) = @_;
2083         $max ||= $self->ra->get_latest_revnum;
2084         $min ||= $self->rev_map_max;
2085         (++$min, $max);
2086 }
2087
2088 sub tmp_config {
2089         my (@args) = @_;
2090         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2091         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2092         if (! -f $config && -f $old_def_config) {
2093                 rename $old_def_config, $config or
2094                        die "Failed rename $old_def_config => $config: $!\n";
2095         }
2096         my $old_config = $ENV{GIT_CONFIG};
2097         $ENV{GIT_CONFIG} = $config;
2098         $@ = undef;
2099         my @ret = eval {
2100                 unless (-f $config) {
2101                         mkfile($config);
2102                         open my $fh, '>', $config or
2103                             die "Can't open $config: $!\n";
2104                         print $fh "; This file is used internally by ",
2105                                   "git-svn\n" or die
2106                                   "Couldn't write to $config: $!\n";
2107                         print $fh "; You should not have to edit it\n" or
2108                               die "Couldn't write to $config: $!\n";
2109                         close $fh or die "Couldn't close $config: $!\n";
2110                 }
2111                 command('config', @args);
2112         };
2113         my $err = $@;
2114         if (defined $old_config) {
2115                 $ENV{GIT_CONFIG} = $old_config;
2116         } else {
2117                 delete $ENV{GIT_CONFIG};
2118         }
2119         die $err if $err;
2120         wantarray ? @ret : $ret[0];
2121 }
2122
2123 sub tmp_index_do {
2124         my ($self, $sub) = @_;
2125         my $old_index = $ENV{GIT_INDEX_FILE};
2126         $ENV{GIT_INDEX_FILE} = $self->{index};
2127         $@ = undef;
2128         my @ret = eval {
2129                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2130                 mkpath([$dir]) unless -d $dir;
2131                 &$sub;
2132         };
2133         my $err = $@;
2134         if (defined $old_index) {
2135                 $ENV{GIT_INDEX_FILE} = $old_index;
2136         } else {
2137                 delete $ENV{GIT_INDEX_FILE};
2138         }
2139         die $err if $err;
2140         wantarray ? @ret : $ret[0];
2141 }
2142
2143 sub assert_index_clean {
2144         my ($self, $treeish) = @_;
2145
2146         $self->tmp_index_do(sub {
2147                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2148                 my $x = command_oneline('write-tree');
2149                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2150                            /^tree ($::sha1)/mo);
2151                 return if $y eq $x;
2152
2153                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2154                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2155                 command_noisy('read-tree', $treeish);
2156                 $x = command_oneline('write-tree');
2157                 if ($y ne $x) {
2158                         ::fatal "trees ($treeish) $y != $x\n",
2159                                 "Something is seriously wrong...";
2160                 }
2161         });
2162 }
2163
2164 sub get_commit_parents {
2165         my ($self, $log_entry) = @_;
2166         my (%seen, @ret, @tmp);
2167         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2168         if (my $ip = $self->{inject_parents}) {
2169                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2170                         push @tmp, $commit;
2171                 }
2172         }
2173         if (my $cur = ::verify_ref($self->refname.'^0')) {
2174                 push @tmp, $cur;
2175         }
2176         if (my $ipd = $self->{inject_parents_dcommit}) {
2177                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2178                         push @tmp, @$commit;
2179                 }
2180         }
2181         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2182         while (my $p = shift @tmp) {
2183                 next if $seen{$p};
2184                 $seen{$p} = 1;
2185                 push @ret, $p;
2186                 # MAXPARENT is defined to 16 in commit-tree.c:
2187                 last if @ret >= 16;
2188         }
2189         if (@tmp) {
2190                 die "r$log_entry->{revision}: No room for parents:\n\t",
2191                     join("\n\t", @tmp), "\n";
2192         }
2193         @ret;
2194 }
2195
2196 sub rewrite_root {
2197         my ($self) = @_;
2198         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2199         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2200         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2201         if ($rwr) {
2202                 $rwr =~ s#/+$##;
2203                 if ($rwr !~ m#^[a-z\+]+://#) {
2204                         die "$rwr is not a valid URL (key: $k)\n";
2205                 }
2206         }
2207         $self->{-rewrite_root} = $rwr;
2208 }
2209
2210 sub metadata_url {
2211         my ($self) = @_;
2212         ($self->rewrite_root || $self->{url}) .
2213            (length $self->{path} ? '/' . $self->{path} : '');
2214 }
2215
2216 sub full_url {
2217         my ($self) = @_;
2218         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2219 }
2220
2221
2222 sub set_commit_header_env {
2223         my ($log_entry) = @_;
2224         my %env;
2225         foreach my $ned (qw/NAME EMAIL DATE/) {
2226                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2227                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2228                 }
2229         }
2230
2231         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2232         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2233         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2234
2235         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2236                                                 ? $log_entry->{commit_name}
2237                                                 : $log_entry->{name};
2238         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2239                                                 ? $log_entry->{commit_email}
2240                                                 : $log_entry->{email};
2241         \%env;
2242 }
2243
2244 sub restore_commit_header_env {
2245         my ($env) = @_;
2246         foreach my $ned (qw/NAME EMAIL DATE/) {
2247                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2248                         my $k = "GIT_${ac}_${ned}";
2249                         if (defined $env->{$k}) {
2250                                 $ENV{$k} = $env->{$k};
2251                         } else {
2252                                 delete $ENV{$k};
2253                         }
2254                 }
2255         }
2256 }
2257
2258 sub gc {
2259         command_noisy('gc', '--auto');
2260 };
2261
2262 sub do_git_commit {
2263         my ($self, $log_entry) = @_;
2264         my $lr = $self->last_rev;
2265         if (defined $lr && $lr >= $log_entry->{revision}) {
2266                 die "Last fetched revision of ", $self->refname,
2267                     " was r$lr, but we are about to fetch: ",
2268                     "r$log_entry->{revision}!\n";
2269         }
2270         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2271                 croak "$log_entry->{revision} = $c already exists! ",
2272                       "Why are we refetching it?\n";
2273         }
2274         my $old_env = set_commit_header_env($log_entry);
2275         my $tree = $log_entry->{tree};
2276         if (!defined $tree) {
2277                 $tree = $self->tmp_index_do(sub {
2278                                             command_oneline('write-tree') });
2279         }
2280         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2281
2282         my @exec = ('git', 'commit-tree', $tree);
2283         foreach ($self->get_commit_parents($log_entry)) {
2284                 push @exec, '-p', $_;
2285         }
2286         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2287                                                                    or croak $!;
2288         binmode $msg_fh;
2289
2290         # we always get UTF-8 from SVN, but we may want our commits in
2291         # a different encoding.
2292         if (my $enc = Git::config('i18n.commitencoding')) {
2293                 require Encode;
2294                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2295         }
2296         print $msg_fh $log_entry->{log} or croak $!;
2297         restore_commit_header_env($old_env);
2298         unless ($self->no_metadata) {
2299                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2300                               or croak $!;
2301         }
2302         $msg_fh->flush == 0 or croak $!;
2303         close $msg_fh or croak $!;
2304         chomp(my $commit = do { local $/; <$out_fh> });
2305         close $out_fh or croak $!;
2306         waitpid $pid, 0;
2307         croak $? if $?;
2308         if ($commit !~ /^$::sha1$/o) {
2309                 die "Failed to commit, invalid sha1: $commit\n";
2310         }
2311
2312         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2313
2314         $self->{last_rev} = $log_entry->{revision};
2315         $self->{last_commit} = $commit;
2316         print "r$log_entry->{revision}";
2317         if (defined $log_entry->{svm_revision}) {
2318                  print " (\@$log_entry->{svm_revision})";
2319                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2320                                    0, $self->svm_uuid);
2321         }
2322         print " = $commit ($self->{ref_id})\n";
2323         if (--$_gc_nr == 0) {
2324                 $_gc_nr = $_gc_period;
2325                 gc();
2326         }
2327         return $commit;
2328 }
2329
2330 sub match_paths {
2331         my ($self, $paths, $r) = @_;
2332         return 1 if $self->{path} eq '';
2333         if (my $path = $paths->{"/$self->{path}"}) {
2334                 return ($path->{action} eq 'D') ? 0 : 1;
2335         }
2336         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2337         if (grep /$self->{path_regex}/, keys %$paths) {
2338                 return 1;
2339         }
2340         my $c = '';
2341         foreach (split m#/#, $self->{path}) {
2342                 $c .= "/$_";
2343                 next unless ($paths->{$c} &&
2344                              ($paths->{$c}->{action} =~ /^[AR]$/));
2345                 if ($self->ra->check_path($self->{path}, $r) ==
2346                     $SVN::Node::dir) {
2347                         return 1;
2348                 }
2349         }
2350         return 0;
2351 }
2352
2353 sub find_parent_branch {
2354         my ($self, $paths, $rev) = @_;
2355         return undef unless $self->follow_parent;
2356         unless (defined $paths) {
2357                 my $err_handler = $SVN::Error::handler;
2358                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2359                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2360                                    $paths =
2361                                       Git::SVN::Ra::dup_changed_paths($_[0]) });
2362                 $SVN::Error::handler = $err_handler;
2363         }
2364         return undef unless defined $paths;
2365
2366         # look for a parent from another branch:
2367         my @b_path_components = split m#/#, $self->rel_path;
2368         my @a_path_components;
2369         my $i;
2370         while (@b_path_components) {
2371                 $i = $paths->{'/'.join('/', @b_path_components)};
2372                 last if $i && defined $i->{copyfrom_path};
2373                 unshift(@a_path_components, pop(@b_path_components));
2374         }
2375         return undef unless defined $i && defined $i->{copyfrom_path};
2376         my $branch_from = $i->{copyfrom_path};
2377         if (@a_path_components) {
2378                 print STDERR "branch_from: $branch_from => ";
2379                 $branch_from .= '/'.join('/', @a_path_components);
2380                 print STDERR $branch_from, "\n";
2381         }
2382         my $r = $i->{copyfrom_rev};
2383         my $repos_root = $self->ra->{repos_root};
2384         my $url = $self->ra->{url};
2385         my $new_url = $repos_root . $branch_from;
2386         print STDERR  "Found possible branch point: ",
2387                       "$new_url => ", $self->full_url, ", $r\n";
2388         $branch_from =~ s#^/##;
2389         my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2390         unless ($gs) {
2391                 my $ref_id = $self->{ref_id};
2392                 $ref_id =~ s/\@\d+$//;
2393                 $ref_id .= "\@$r";
2394                 # just grow a tail if we're not unique enough :x
2395                 $ref_id .= '-' while find_ref($ref_id);
2396                 print STDERR "Initializing parent: $ref_id\n";
2397                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2398                 if ($u =~ s#^\Q$url\E(/|$)##) {
2399                         $p = $u;
2400                         $u = $url;
2401                         $repo_id = $self->{repo_id};
2402                 }
2403                 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2404         }
2405         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2406         {
2407                 my ($base, $head);
2408                 if (!defined $r0 || !defined $parent) {
2409                         ($base, $head) = parse_revision_argument(0, $r);
2410                 } else {
2411                         if ($r0 < $r) {
2412                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2413                                         0, 1, sub { $base = $_[1] - 1 });
2414                         }
2415                 }
2416                 if (defined $base && $base <= $r) {
2417                         $gs->fetch($base, $r);
2418                 }
2419                 ($r0, $parent) = $gs->find_rev_before($r, 1);
2420         }
2421         if (defined $r0 && defined $parent) {
2422                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2423                 my $ed;
2424                 if ($self->ra->can_do_switch) {
2425                         $self->assert_index_clean($parent);
2426                         print STDERR "Following parent with do_switch\n";
2427                         # do_switch works with svn/trunk >= r22312, but that
2428                         # is not included with SVN 1.4.3 (the latest version
2429                         # at the moment), so we can't rely on it
2430                         $self->{last_commit} = $parent;
2431                         $ed = SVN::Git::Fetcher->new($self);
2432                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2433                                               $self->full_url, $ed)
2434                           or die "SVN connection failed somewhere...\n";
2435                 } elsif ($self->ra->trees_match($new_url, $r0,
2436                                                 $self->full_url, $rev)) {
2437                         print STDERR "Trees match:\n",
2438                                      "  $new_url\@$r0\n",
2439                                      "  ${\$self->full_url}\@$rev\n",
2440                                      "Following parent with no changes\n";
2441                         $self->tmp_index_do(sub {
2442                             command_noisy('read-tree', $parent);
2443                         });
2444                         $self->{last_commit} = $parent;
2445                 } else {
2446                         print STDERR "Following parent with do_update\n";
2447                         $ed = SVN::Git::Fetcher->new($self);
2448                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2449                           or die "SVN connection failed somewhere...\n";
2450                 }
2451                 print STDERR "Successfully followed parent\n";
2452                 return $self->make_log_entry($rev, [$parent], $ed);
2453         }
2454         return undef;
2455 }
2456
2457 sub do_fetch {
2458         my ($self, $paths, $rev) = @_;
2459         my $ed;
2460         my ($last_rev, @parents);
2461         if (my $lc = $self->last_commit) {
2462                 # we can have a branch that was deleted, then re-added
2463                 # under the same name but copied from another path, in
2464                 # which case we'll have multiple parents (we don't
2465                 # want to break the original ref, nor lose copypath info):
2466                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2467                         push @{$log_entry->{parents}}, $lc;
2468                         return $log_entry;
2469                 }
2470                 $ed = SVN::Git::Fetcher->new($self);
2471                 $last_rev = $self->{last_rev};
2472                 $ed->{c} = $lc;
2473                 @parents = ($lc);
2474         } else {
2475                 $last_rev = $rev;
2476                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2477                         return $log_entry;
2478                 }
2479                 $ed = SVN::Git::Fetcher->new($self);
2480         }
2481         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2482                 die "SVN connection failed somewhere...\n";
2483         }
2484         $self->make_log_entry($rev, \@parents, $ed);
2485 }
2486
2487 sub get_untracked {
2488         my ($self, $ed) = @_;
2489         my @out;
2490         my $h = $ed->{empty};
2491         foreach (sort keys %$h) {
2492                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2493                 push @out, "  $act: " . uri_encode($_);
2494                 warn "W: $act: $_\n";
2495         }
2496         foreach my $t (qw/dir_prop file_prop/) {
2497                 $h = $ed->{$t} or next;
2498                 foreach my $path (sort keys %$h) {
2499                         my $ppath = $path eq '' ? '.' : $path;
2500                         foreach my $prop (sort keys %{$h->{$path}}) {
2501                                 next if $SKIP_PROP{$prop};
2502                                 my $v = $h->{$path}->{$prop};
2503                                 my $t_ppath_prop = "$t: " .
2504                                                     uri_encode($ppath) . ' ' .
2505                                                     uri_encode($prop);
2506                                 if (defined $v) {
2507                                         push @out, "  +$t_ppath_prop " .
2508                                                    uri_encode($v);
2509                                 } else {
2510                                         push @out, "  -$t_ppath_prop";
2511                                 }
2512                         }
2513                 }
2514         }
2515         foreach my $t (qw/absent_file absent_directory/) {
2516                 $h = $ed->{$t} or next;
2517                 foreach my $parent (sort keys %$h) {
2518                         foreach my $path (sort @{$h->{$parent}}) {
2519                                 push @out, "  $t: " .
2520                                            uri_encode("$parent/$path");
2521                                 warn "W: $t: $parent/$path ",
2522                                      "Insufficient permissions?\n";
2523                         }
2524                 }
2525         }
2526         \@out;
2527 }
2528
2529 sub parse_svn_date {
2530         my $date = shift || return '+0000 1970-01-01 00:00:00';
2531         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2532                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2533                                          croak "Unable to parse date: $date\n";
2534         "+0000 $Y-$m-$d $H:$M:$S";
2535 }
2536
2537 sub check_author {
2538         my ($author) = @_;
2539         if (!defined $author || length $author == 0) {
2540                 $author = '(no author)';
2541         } elsif (defined $::_authors && ! defined $::users{$author}) {
2542                 die "Author: $author not defined in $::_authors file\n";
2543         }
2544         $author;
2545 }
2546
2547 sub make_log_entry {
2548         my ($self, $rev, $parents, $ed) = @_;
2549         my $untracked = $self->get_untracked($ed);
2550
2551         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2552         print $un "r$rev\n" or croak $!;
2553         print $un $_, "\n" foreach @$untracked;
2554         my %log_entry = ( parents => $parents || [], revision => $rev,
2555                           log => '');
2556
2557         my $headrev;
2558         my $logged = delete $self->{logged_rev_props};
2559         if (!$logged || $self->{-want_revprops}) {
2560                 my $rp = $self->ra->rev_proplist($rev);
2561                 foreach (sort keys %$rp) {
2562                         my $v = $rp->{$_};
2563                         if (/^svn:(author|date|log)$/) {
2564                                 $log_entry{$1} = $v;
2565                         } elsif ($_ eq 'svm:headrev') {
2566                                 $headrev = $v;
2567                         } else {
2568                                 print $un "  rev_prop: ", uri_encode($_), ' ',
2569                                           uri_encode($v), "\n";
2570                         }
2571                 }
2572         } else {
2573                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2574         }
2575         close $un or croak $!;
2576
2577         $log_entry{date} = parse_svn_date($log_entry{date});
2578         $log_entry{log} .= "\n";
2579         my $author = $log_entry{author} = check_author($log_entry{author});
2580         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2581                                                        : ($author, undef);
2582
2583         my ($commit_name, $commit_email) = ($name, $email);
2584         if ($_use_log_author) {
2585                 my $name_field;
2586                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2587                         $name_field = $1;
2588                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2589                         $name_field = $1;
2590                 }
2591                 if (!defined $name_field) {
2592                         if (!defined $email) {
2593                                 $email = $name;
2594                         }
2595                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2596                         ($name, $email) = ($1, $2);
2597                 } elsif ($name_field =~ /(.*)@/) {
2598                         ($name, $email) = ($1, $name_field);
2599                 } else {
2600                         ($name, $email) = ($name_field, $name_field);
2601                 }
2602         }
2603         if (defined $headrev && $self->use_svm_props) {
2604                 if ($self->rewrite_root) {
2605                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2606                             "options set!\n";
2607                 }
2608                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2609                 # we don't want "SVM: initializing mirror for junk" ...
2610                 return undef if $r == 0;
2611                 my $svm = $self->svm;
2612                 if ($uuid ne $svm->{uuid}) {
2613                         die "UUID mismatch on SVM path:\n",
2614                             "expected: $svm->{uuid}\n",
2615                             "     got: $uuid\n";
2616                 }
2617                 my $full_url = $self->full_url;
2618                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2619                              die "Failed to replace '$svm->{replace}' with ",
2620                                  "'$svm->{source}' in $full_url\n";
2621                 # throw away username for storing in records
2622                 remove_username($full_url);
2623                 $log_entry{metadata} = "$full_url\@$r $uuid";
2624                 $log_entry{svm_revision} = $r;
2625                 $email ||= "$author\@$uuid";
2626                 $commit_email ||= "$author\@$uuid";
2627         } elsif ($self->use_svnsync_props) {
2628                 my $full_url = $self->svnsync->{url};
2629                 $full_url .= "/$self->{path}" if length $self->{path};
2630                 remove_username($full_url);
2631                 my $uuid = $self->svnsync->{uuid};
2632                 $log_entry{metadata} = "$full_url\@$rev $uuid";
2633                 $email ||= "$author\@$uuid";
2634                 $commit_email ||= "$author\@$uuid";
2635         } else {
2636                 my $url = $self->metadata_url;
2637                 remove_username($url);
2638                 $log_entry{metadata} = "$url\@$rev " .
2639                                        $self->ra->get_uuid;
2640                 $email ||= "$author\@" . $self->ra->get_uuid;
2641                 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2642         }
2643         $log_entry{name} = $name;
2644         $log_entry{email} = $email;
2645         $log_entry{commit_name} = $commit_name;
2646         $log_entry{commit_email} = $commit_email;
2647         \%log_entry;
2648 }
2649
2650 sub fetch {
2651         my ($self, $min_rev, $max_rev, @parents) = @_;
2652         my ($last_rev, $last_commit) = $self->last_rev_commit;
2653         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2654         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2655 }
2656
2657 sub set_tree_cb {
2658         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2659         $self->{inject_parents} = { $rev => $tree };
2660         $self->fetch(undef, undef);
2661 }
2662
2663 sub set_tree {
2664         my ($self, $tree) = (shift, shift);
2665         my $log_entry = ::get_commit_entry($tree);
2666         unless ($self->{last_rev}) {
2667                 ::fatal("Must have an existing revision to commit");
2668         }
2669         my %ed_opts = ( r => $self->{last_rev},
2670                         log => $log_entry->{log},
2671                         ra => $self->ra,
2672                         tree_a => $self->{last_commit},
2673                         tree_b => $tree,
2674                         editor_cb => sub {
2675                                $self->set_tree_cb($log_entry, $tree, @_) },
2676                         svn_path => $self->{path} );
2677         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2678                 print "No changes\nr$self->{last_rev} = $tree\n";
2679         }
2680 }
2681
2682 sub rebuild_from_rev_db {
2683         my ($self, $path) = @_;
2684         my $r = -1;
2685         open my $fh, '<', $path or croak "open: $!";
2686         binmode $fh or croak "binmode: $!";
2687         while (<$fh>) {
2688                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2689                 chomp($_);
2690                 ++$r;
2691                 next if $_ eq ('0' x 40);
2692                 $self->rev_map_set($r, $_);
2693                 print "r$r = $_\n";
2694         }
2695         close $fh or croak "close: $!";
2696         unlink $path or croak "unlink: $!";
2697 }
2698
2699 sub rebuild {
2700         my ($self) = @_;
2701         my $map_path = $self->map_path;
2702         my $partial = (-e $map_path && ! -z $map_path);
2703         return unless ::verify_ref($self->refname.'^0');
2704         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
2705                 my $rev_db = $self->rev_db_path;
2706                 $self->rebuild_from_rev_db($rev_db);
2707                 if ($self->use_svm_props) {
2708                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2709                         $self->rebuild_from_rev_db($svm_rev_db);
2710                 }
2711                 $self->unlink_rev_db_symlink;
2712                 return;
2713         }
2714         print "Rebuilding $map_path ...\n" if (!$partial);
2715         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
2716                 (undef, undef));
2717         my ($log, $ctx) =
2718             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2719                                 ($head ? "$head.." : "") . $self->refname,
2720                                 '--');
2721         my $metadata_url = $self->metadata_url;
2722         remove_username($metadata_url);
2723         my $svn_uuid = $self->ra_uuid;
2724         my $c;
2725         while (<$log>) {
2726                 if ( m{^commit ($::sha1)$} ) {
2727                         $c = $1;
2728                         next;
2729                 }
2730                 next unless s{^\s*(git-svn-id:)}{$1};
2731                 my ($url, $rev, $uuid) = ::extract_metadata($_);
2732                 remove_username($url);
2733
2734                 # ignore merges (from set-tree)
2735                 next if (!defined $rev || !$uuid);
2736
2737                 # if we merged or otherwise started elsewhere, this is
2738                 # how we break out of it
2739                 if (($uuid ne $svn_uuid) ||
2740                     ($metadata_url && $url && ($url ne $metadata_url))) {
2741                         next;
2742                 }
2743                 if ($partial && $head) {
2744                         print "Partial-rebuilding $map_path ...\n";
2745                         print "Currently at $base_rev = $head\n";
2746                         $head = undef;
2747                 }
2748
2749                 $self->rev_map_set($rev, $c);
2750                 print "r$rev = $c\n";
2751         }
2752         command_close_pipe($log, $ctx);
2753         print "Done rebuilding $map_path\n" if (!$partial || !$head);
2754         my $rev_db_path = $self->rev_db_path;
2755         if (-f $self->rev_db_path) {
2756                 unlink $self->rev_db_path or croak "unlink: $!";
2757         }
2758         $self->unlink_rev_db_symlink;
2759 }
2760
2761 # rev_map:
2762 # Tie::File seems to be prone to offset errors if revisions get sparse,
2763 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
2764 # one of my favorite modules is out :<  Next up would be one of the DBM
2765 # modules, but I'm not sure which is most portable...
2766 #
2767 # This is the replacement for the rev_db format, which was too big
2768 # and inefficient for large repositories with a lot of sparse history
2769 # (mainly tags)
2770 #
2771 # The format is this:
2772 #   - 24 bytes for every record,
2773 #     * 4 bytes for the integer representing an SVN revision number
2774 #     * 20 bytes representing the sha1 of a git commit
2775 #   - No empty padding records like the old format
2776 #     (except the last record, which can be overwritten)
2777 #   - new records are written append-only since SVN revision numbers
2778 #     increase monotonically
2779 #   - lookups on SVN revision number are done via a binary search
2780 #   - Piping the file to xxd -c24 is a good way of dumping it for
2781 #     viewing or editing (piped back through xxd -r), should the need
2782 #     ever arise.
2783 #   - The last record can be padding revision with an all-zero sha1
2784 #     This is used to optimize fetch performance when using multiple
2785 #     "fetch" directives in .git/config
2786 #
2787 # These files are disposable unless noMetadata or useSvmProps is set
2788
2789 sub _rev_map_set {
2790         my ($fh, $rev, $commit) = @_;
2791
2792         binmode $fh or croak "binmode: $!";
2793         my $size = (stat($fh))[7];
2794         ($size % 24) == 0 or croak "inconsistent size: $size";
2795
2796         my $wr_offset = 0;
2797         if ($size > 0) {
2798                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2799                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2800                 $read == 24 or croak "read only $read bytes (!= 24)";
2801                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2802                 if ($last_commit eq ('0' x40)) {
2803                         if ($size >= 48) {
2804                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2805                                 $read = sysread($fh, $buf, 24) or
2806                                     croak "read: $!";
2807                                 $read == 24 or
2808                                     croak "read only $read bytes (!= 24)";
2809                                 ($last_rev, $last_commit) =
2810                                     unpack(rev_map_fmt, $buf);
2811                                 if ($last_commit eq ('0' x40)) {
2812                                         croak "inconsistent .rev_map\n";
2813                                 }
2814                         }
2815                         if ($last_rev >= $rev) {
2816                                 croak "last_rev is higher!: $last_rev >= $rev";
2817                         }
2818                         $wr_offset = -24;
2819                 }
2820         }
2821         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2822         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2823           croak "write: $!";
2824 }
2825
2826 sub mkfile {
2827         my ($path) = @_;
2828         unless (-e $path) {
2829                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2830                 mkpath([$dir]) unless -d $dir;
2831                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2832                 close $fh or die "Couldn't close (create) $path: $!\n";
2833         }
2834 }
2835
2836 sub rev_map_set {
2837         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2838         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2839         my $db = $self->map_path($uuid);
2840         my $db_lock = "$db.lock";
2841         my $sig;
2842         if ($update_ref) {
2843                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2844                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2845         }
2846         mkfile($db);
2847
2848         $LOCKFILES{$db_lock} = 1;
2849         my $sync;
2850         # both of these options make our .rev_db file very, very important
2851         # and we can't afford to lose it because rebuild() won't work
2852         if ($self->use_svm_props || $self->no_metadata) {
2853                 $sync = 1;
2854                 copy($db, $db_lock) or die "rev_map_set(@_): ",
2855                                            "Failed to copy: ",
2856                                            "$db => $db_lock ($!)\n";
2857         } else {
2858                 rename $db, $db_lock or die "rev_map_set(@_): ",
2859                                             "Failed to rename: ",
2860                                             "$db => $db_lock ($!)\n";
2861         }
2862
2863         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2864              or croak "Couldn't open $db_lock: $!\n";
2865         _rev_map_set($fh, $rev, $commit);
2866         if ($sync) {
2867                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2868                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2869         }
2870         close $fh or croak $!;
2871         if ($update_ref) {
2872                 $_head = $self;
2873                 command_noisy('update-ref', '-m', "r$rev",
2874                               $self->refname, $commit);
2875         }
2876         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2877                                     "$db_lock => $db ($!)\n";
2878         delete $LOCKFILES{$db_lock};
2879         if ($update_ref) {
2880                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2881                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2882                 kill $sig, $$ if defined $sig;
2883         }
2884 }
2885
2886 # If want_commit, this will return an array of (rev, commit) where
2887 # commit _must_ be a valid commit in the archive.
2888 # Otherwise, it'll return the max revision (whether or not the
2889 # commit is valid or just a 0x40 placeholder).
2890 sub rev_map_max {
2891         my ($self, $want_commit) = @_;
2892         $self->rebuild;
2893         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
2894         $want_commit ? ($r, $c) : $r;
2895 }
2896
2897 sub rev_map_max_norebuild {
2898         my ($self, $want_commit) = @_;
2899         my $map_path = $self->map_path;
2900         stat $map_path or return $want_commit ? (0, undef) : 0;
2901         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2902         binmode $fh or croak "binmode: $!";
2903         my $size = (stat($fh))[7];
2904         ($size % 24) == 0 or croak "inconsistent size: $size";
2905
2906         if ($size == 0) {
2907                 close $fh or croak "close: $!";
2908                 return $want_commit ? (0, undef) : 0;
2909         }
2910
2911         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2912         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2913         my ($r, $c) = unpack(rev_map_fmt, $buf);
2914         if ($want_commit && $c eq ('0' x40)) {
2915                 if ($size < 48) {
2916                         return $want_commit ? (0, undef) : 0;
2917                 }
2918                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2919                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2920                 ($r, $c) = unpack(rev_map_fmt, $buf);
2921                 if ($c eq ('0'x40)) {
2922                         croak "Penultimate record is all-zeroes in $map_path";
2923                 }
2924         }
2925         close $fh or croak "close: $!";
2926         $want_commit ? ($r, $c) : $r;
2927 }
2928
2929 sub rev_map_get {
2930         my ($self, $rev, $uuid) = @_;
2931         my $map_path = $self->map_path($uuid);
2932         return undef unless -e $map_path;
2933
2934         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2935         binmode $fh or croak "binmode: $!";
2936         my $size = (stat($fh))[7];
2937         ($size % 24) == 0 or croak "inconsistent size: $size";
2938
2939         if ($size == 0) {
2940                 close $fh or croak "close: $fh";
2941                 return undef;
2942         }
2943
2944         my ($l, $u) = (0, $size - 24);
2945         my ($r, $c, $buf);
2946
2947         while ($l <= $u) {
2948                 my $i = int(($l/24 + $u/24) / 2) * 24;
2949                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2950                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2951                 my ($r, $c) = unpack('NH40', $buf);
2952
2953                 if ($r < $rev) {
2954                         $l = $i + 24;
2955                 } elsif ($r > $rev) {
2956                         $u = $i - 24;
2957                 } else { # $r == $rev
2958                         close($fh) or croak "close: $!";
2959                         return $c eq ('0' x 40) ? undef : $c;
2960                 }
2961         }
2962         close($fh) or croak "close: $!";
2963         undef;
2964 }
2965
2966 # Finds the first svn revision that exists on (if $eq_ok is true) or
2967 # before $rev for the current branch.  It will not search any lower
2968 # than $min_rev.  Returns the git commit hash and svn revision number
2969 # if found, else (undef, undef).
2970 sub find_rev_before {
2971         my ($self, $rev, $eq_ok, $min_rev) = @_;
2972         --$rev unless $eq_ok;
2973         $min_rev ||= 1;
2974         while ($rev >= $min_rev) {
2975                 if (my $c = $self->rev_map_get($rev)) {
2976                         return ($rev, $c);
2977                 }
2978                 --$rev;
2979         }
2980         return (undef, undef);
2981 }
2982
2983 # Finds the first svn revision that exists on (if $eq_ok is true) or
2984 # after $rev for the current branch.  It will not search any higher
2985 # than $max_rev.  Returns the git commit hash and svn revision number
2986 # if found, else (undef, undef).
2987 sub find_rev_after {
2988         my ($self, $rev, $eq_ok, $max_rev) = @_;
2989         ++$rev unless $eq_ok;
2990         $max_rev ||= $self->rev_map_max;
2991         while ($rev <= $max_rev) {
2992                 if (my $c = $self->rev_map_get($rev)) {
2993                         return ($rev, $c);
2994                 }
2995                 ++$rev;
2996         }
2997         return (undef, undef);
2998 }
2999
3000 sub _new {
3001         my ($class, $repo_id, $ref_id, $path) = @_;
3002         unless (defined $repo_id && length $repo_id) {
3003                 $repo_id = $Git::SVN::default_repo_id;
3004         }
3005         unless (defined $ref_id && length $ref_id) {
3006                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
3007         }
3008         $_[1] = $repo_id;
3009         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3010         $_[3] = $path = '' unless (defined $path);
3011         mkpath(["$ENV{GIT_DIR}/svn"]);
3012         bless {
3013                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3014                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3015                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3016 }
3017
3018 # for read-only access of old .rev_db formats
3019 sub unlink_rev_db_symlink {
3020         my ($self) = @_;
3021         my $link = $self->rev_db_path;
3022         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3023         if (-l $link) {
3024                 unlink $link or croak "unlink: $link failed!";
3025         }
3026 }
3027
3028 sub rev_db_path {
3029         my ($self, $uuid) = @_;
3030         my $db_path = $self->map_path($uuid);
3031         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3032             or croak "map_path: $db_path does not contain '/.rev_map.' !";
3033         $db_path;
3034 }
3035
3036 # the new replacement for .rev_db
3037 sub map_path {
3038         my ($self, $uuid) = @_;
3039         $uuid ||= $self->ra_uuid;
3040         "$self->{map_root}.$uuid";
3041 }
3042
3043 sub uri_encode {
3044         my ($f) = @_;
3045         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3046         $f
3047 }
3048
3049 sub remove_username {
3050         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3051 }
3052
3053 package Git::SVN::Prompt;
3054 use strict;
3055 use warnings;
3056 require SVN::Core;
3057 use vars qw/$_no_auth_cache $_username/;
3058
3059 sub simple {
3060         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3061         $may_save = undef if $_no_auth_cache;
3062         $default_username = $_username if defined $_username;
3063         if (defined $default_username && length $default_username) {
3064                 if (defined $realm && length $realm) {
3065                         print STDERR "Authentication realm: $realm\n";
3066                         STDERR->flush;
3067                 }
3068                 $cred->username($default_username);
3069         } else {
3070                 username($cred, $realm, $may_save, $pool);
3071         }
3072         $cred->password(_read_password("Password for '" .
3073                                        $cred->username . "': ", $realm));
3074         $cred->may_save($may_save);
3075         $SVN::_Core::SVN_NO_ERROR;
3076 }
3077
3078 sub ssl_server_trust {
3079         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3080         $may_save = undef if $_no_auth_cache;
3081         print STDERR "Error validating server certificate for '$realm':\n";
3082         {
3083                 no warnings 'once';
3084                 # All variables SVN::Auth::SSL::* are used only once,
3085                 # so we're shutting up Perl warnings about this.
3086                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3087                         print STDERR " - The certificate is not issued ",
3088                             "by a trusted authority. Use the\n",
3089                             "   fingerprint to validate ",
3090                             "the certificate manually!\n";
3091                 }
3092                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3093                         print STDERR " - The certificate hostname ",
3094                             "does not match.\n";
3095                 }
3096                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3097                         print STDERR " - The certificate is not yet valid.\n";
3098                 }
3099                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3100                         print STDERR " - The certificate has expired.\n";
3101                 }
3102                 if ($failures & $SVN::Auth::SSL::OTHER) {
3103                         print STDERR " - The certificate has ",
3104                             "an unknown error.\n";
3105                 }
3106         } # no warnings 'once'
3107         printf STDERR
3108                 "Certificate information:\n".
3109                 " - Hostname: %s\n".
3110                 " - Valid: from %s until %s\n".
3111                 " - Issuer: %s\n".
3112                 " - Fingerprint: %s\n",
3113                 map $cert_info->$_, qw(hostname valid_from valid_until
3114                                        issuer_dname fingerprint);
3115         my $choice;
3116 prompt:
3117         print STDERR $may_save ?
3118               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3119               "(R)eject or accept (t)emporarily? ";
3120         STDERR->flush;
3121         $choice = lc(substr(<STDIN> || 'R', 0, 1));
3122         if ($choice =~ /^t$/i) {
3123                 $cred->may_save(undef);
3124         } elsif ($choice =~ /^r$/i) {
3125                 return -1;
3126         } elsif ($may_save && $choice =~ /^p$/i) {
3127                 $cred->may_save($may_save);
3128         } else {
3129                 goto prompt;
3130         }
3131         $cred->accepted_failures($failures);
3132         $SVN::_Core::SVN_NO_ERROR;
3133 }
3134
3135 sub ssl_client_cert {
3136         my ($cred, $realm, $may_save, $pool) = @_;
3137         $may_save = undef if $_no_auth_cache;
3138         print STDERR "Client certificate filename: ";
3139         STDERR->flush;
3140         chomp(my $filename = <STDIN>);
3141         $cred->cert_file($filename);
3142         $cred->may_save($may_save);
3143         $SVN::_Core::SVN_NO_ERROR;
3144 }
3145
3146 sub ssl_client_cert_pw {
3147         my ($cred, $realm, $may_save, $pool) = @_;
3148         $may_save = undef if $_no_auth_cache;
3149         $cred->password(_read_password("Password: ", $realm));
3150         $cred->may_save($may_save);
3151         $SVN::_Core::SVN_NO_ERROR;
3152 }
3153
3154 sub username {
3155         my ($cred, $realm, $may_save, $pool) = @_;
3156         $may_save = undef if $_no_auth_cache;
3157         if (defined $realm && length $realm) {
3158                 print STDERR "Authentication realm: $realm\n";
3159         }
3160         my $username;
3161         if (defined $_username) {
3162                 $username = $_username;
3163         } else {
3164                 print STDERR "Username: ";
3165                 STDERR->flush;
3166                 chomp($username = <STDIN>);
3167         }
3168         $cred->username($username);
3169         $cred->may_save($may_save);
3170         $SVN::_Core::SVN_NO_ERROR;
3171 }
3172
3173 sub _read_password {
3174         my ($prompt, $realm) = @_;
3175         print STDERR $prompt;
3176         STDERR->flush;
3177         require Term::ReadKey;
3178         Term::ReadKey::ReadMode('noecho');
3179         my $password = '';
3180         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3181                 last if $key =~ /[\012\015]/; # \n\r
3182                 $password .= $key;
3183         }
3184         Term::ReadKey::ReadMode('restore');
3185         print STDERR "\n";
3186         STDERR->flush;
3187         $password;
3188 }
3189
3190 package SVN::Git::Fetcher;
3191 use vars qw/@ISA/;
3192 use strict;
3193 use warnings;
3194 use Carp qw/croak/;
3195 use File::Temp qw/tempfile/;
3196 use IO::File qw//;
3197
3198 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3199 sub new {
3200         my ($class, $git_svn) = @_;
3201         my $self = SVN::Delta::Editor->new;
3202         bless $self, $class;
3203         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3204         $self->{empty} = {};
3205         $self->{dir_prop} = {};
3206         $self->{file_prop} = {};
3207         $self->{absent_dir} = {};
3208         $self->{absent_file} = {};
3209         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3210         $self;
3211 }
3212
3213 sub set_path_strip {
3214         my ($self, $path) = @_;
3215         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3216 }
3217
3218 sub open_root {
3219         { path => '' };
3220 }
3221
3222 sub open_directory {
3223         my ($self, $path, $pb, $rev) = @_;
3224         { path => $path };
3225 }
3226
3227 sub git_path {
3228         my ($self, $path) = @_;
3229         if ($self->{path_strip}) {
3230                 $path =~ s!$self->{path_strip}!! or
3231                   die "Failed to strip path '$path' ($self->{path_strip})\n";
3232         }
3233         $path;
3234 }
3235
3236 sub delete_entry {
3237         my ($self, $path, $rev, $pb) = @_;
3238
3239         my $gpath = $self->git_path($path);
3240         return undef if ($gpath eq '');
3241
3242         # remove entire directories.
3243         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3244                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3245                                                      -r --name-only -z/,
3246                                                      $self->{c}, '--', $gpath);
3247                 local $/ = "\0";
3248                 while (<$ls>) {
3249                         chomp;
3250                         $self->{gii}->remove($_);
3251                         print "\tD\t$_\n" unless $::_q;
3252                 }
3253                 print "\tD\t$gpath/\n" unless $::_q;
3254                 command_close_pipe($ls, $ctx);
3255                 $self->{empty}->{$path} = 0
3256         } else {
3257                 $self->{gii}->remove($gpath);
3258                 print "\tD\t$gpath\n" unless $::_q;
3259         }
3260         undef;
3261 }
3262
3263 sub open_file {
3264         my ($self, $path, $pb, $rev) = @_;
3265         my $gpath = $self->git_path($path);
3266         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3267                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3268         unless (defined $mode && defined $blob) {
3269                 die "$path was not found in commit $self->{c} (r$rev)\n";
3270         }
3271         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3272           pool => SVN::Pool->new, action => 'M' };
3273 }
3274
3275 sub add_file {
3276         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3277         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3278         delete $self->{empty}->{$dir};
3279         { path => $path, mode_a => 100644, mode_b => 100644,
3280           pool => SVN::Pool->new, action => 'A' };
3281 }
3282
3283 sub add_directory {
3284         my ($self, $path, $cp_path, $cp_rev) = @_;
3285         my $gpath = $self->git_path($path);
3286         if ($gpath eq '') {
3287                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3288                                                      -r --name-only -z/,
3289                                                      $self->{c});
3290                 local $/ = "\0";
3291                 while (<$ls>) {
3292                         chomp;
3293                         $self->{gii}->remove($_);
3294                         print "\tD\t$_\n" unless $::_q;
3295                 }
3296                 command_close_pipe($ls, $ctx);
3297                 $self->{empty}->{$path} = 0;
3298         }
3299         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3300         delete $self->{empty}->{$dir};
3301         $self->{empty}->{$path} = 1;
3302         { path => $path };
3303 }
3304
3305 sub change_dir_prop {
3306         my ($self, $db, $prop, $value) = @_;
3307         $self->{dir_prop}->{$db->{path}} ||= {};
3308         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3309         undef;
3310 }
3311
3312 sub absent_directory {
3313         my ($self, $path, $pb) = @_;
3314         $self->{absent_dir}->{$pb->{path}} ||= [];
3315         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3316         undef;
3317 }
3318
3319 sub absent_file {
3320         my ($self, $path, $pb) = @_;
3321         $self->{absent_file}->{$pb->{path}} ||= [];
3322         push @{$self->{absent_file}->{$pb->{path}}}, $path;
3323         undef;
3324 }
3325
3326 sub change_file_prop {
3327         my ($self, $fb, $prop, $value) = @_;
3328         if ($prop eq 'svn:executable') {
3329                 if ($fb->{mode_b} != 120000) {
3330                         $fb->{mode_b} = defined $value ? 100755 : 100644;
3331                 }
3332         } elsif ($prop eq 'svn:special') {
3333                 $fb->{mode_b} = defined $value ? 120000 : 100644;
3334         } else {
3335                 $self->{file_prop}->{$fb->{path}} ||= {};
3336                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3337         }
3338         undef;
3339 }
3340
3341 sub apply_textdelta {
3342         my ($self, $fb, $exp) = @_;
3343         my $fh = $::_repository->temp_acquire('svn_delta');
3344         # $fh gets auto-closed() by SVN::TxDelta::apply(),
3345         # (but $base does not,) so dup() it for reading in close_file
3346         open my $dup, '<&', $fh or croak $!;
3347         my $base = $::_repository->temp_acquire('git_blob');
3348         if ($fb->{blob}) {
3349                 print $base 'link ' if ($fb->{mode_a} == 120000);
3350                 my $size = $::_repository->cat_blob($fb->{blob}, $base);
3351                 die "Failed to read object $fb->{blob}" if ($size < 0);
3352
3353                 if (defined $exp) {
3354                         seek $base, 0, 0 or croak $!;
3355                         my $got = ::md5sum($base);
3356                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3357                             "expected: $exp\n",
3358                             "     got: $got\n" if ($got ne $exp);
3359                 }
3360         }
3361         seek $base, 0, 0 or croak $!;
3362         $fb->{fh} = $fh;
3363         $fb->{base} = $base;
3364         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
3365 }
3366
3367 sub close_file {
3368         my ($self, $fb, $exp) = @_;
3369         my $hash;
3370         my $path = $self->git_path($fb->{path});
3371         if (my $fh = $fb->{fh}) {
3372                 if (defined $exp) {
3373                         seek($fh, 0, 0) or croak $!;
3374                         my $got = ::md5sum($fh);
3375                         if ($got ne $exp) {
3376                                 die "Checksum mismatch: $path\n",
3377                                     "expected: $exp\n    got: $got\n";
3378                         }
3379                 }
3380                 if ($fb->{mode_b} == 120000) {
3381                         sysseek($fh, 0, 0) or croak $!;
3382                         sysread($fh, my $buf, 5) == 5 or croak $!;
3383
3384                         unless ($buf eq 'link ') {
3385                                 warn "$path has mode 120000",
3386                                                 " but is not a link\n";
3387                         } else {
3388                                 my $tmp_fh = $::_repository->temp_acquire(
3389                                         'svn_hash');
3390                                 my $res;
3391                                 while ($res = sysread($fh, my $str, 1024)) {
3392                                         my $out = syswrite($tmp_fh, $str, $res);
3393                                         defined($out) && $out == $res
3394                                                 or croak("write ",
3395                                                         Git::temp_path($tmp_fh),
3396                                                         ": $!\n");
3397                                 }
3398                                 defined $res or croak $!;
3399
3400                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
3401                                 Git::temp_release($tmp_fh, 1);
3402                         }
3403                 }
3404
3405                 $hash = $::_repository->hash_and_insert_object(
3406                                 Git::temp_path($fh));
3407                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3408
3409                 Git::temp_release($fb->{base}, 1);
3410                 Git::temp_release($fh, 1);
3411         } else {
3412                 $hash = $fb->{blob} or die "no blob information\n";
3413         }
3414         $fb->{pool}->clear;
3415         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3416         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3417         undef;
3418 }
3419
3420 sub abort_edit {
3421         my $self = shift;
3422         $self->{nr} = $self->{gii}->{nr};
3423         delete $self->{gii};
3424         $self->SUPER::abort_edit(@_);
3425 }
3426
3427 sub close_edit {
3428         my $self = shift;
3429         $self->{git_commit_ok} = 1;
3430         $self->{nr} = $self->{gii}->{nr};
3431         delete $self->{gii};
3432         $self->SUPER::close_edit(@_);
3433 }
3434
3435 package SVN::Git::Editor;
3436 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3437 use strict;
3438 use warnings;
3439 use Carp qw/croak/;
3440 use IO::File;
3441
3442 sub new {
3443         my ($class, $opts) = @_;
3444         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3445                 die "$_ required!\n" unless (defined $opts->{$_});
3446         }
3447
3448         my $pool = SVN::Pool->new;
3449         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3450         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3451                                      $opts->{r}, $mods);
3452
3453         # $opts->{ra} functions should not be used after this:
3454         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
3455                                                 $opts->{editor_cb}, $pool);
3456         my $self = SVN::Delta::Editor->new(@ce, $pool);
3457         bless $self, $class;
3458         foreach (qw/svn_path r tree_a tree_b/) {
3459                 $self->{$_} = $opts->{$_};
3460         }
3461         $self->{url} = $opts->{ra}->{url};
3462         $self->{mods} = $mods;
3463         $self->{types} = $types;
3464         $self->{pool} = $pool;
3465         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3466         $self->{rm} = { };
3467         $self->{path_prefix} = length $self->{svn_path} ?
3468                                "$self->{svn_path}/" : '';
3469         $self->{config} = $opts->{config};
3470         return $self;
3471 }
3472
3473 sub generate_diff {
3474         my ($tree_a, $tree_b) = @_;
3475         my @diff_tree = qw(diff-tree -z -r);
3476         if ($_cp_similarity) {
3477                 push @diff_tree, "-C$_cp_similarity";
3478         } else {
3479                 push @diff_tree, '-C';
3480         }
3481         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3482         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3483         push @diff_tree, $tree_a, $tree_b;
3484         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3485         local $/ = "\0";
3486         my $state = 'meta';
3487         my @mods;
3488         while (<$diff_fh>) {
3489                 chomp $_; # this gets rid of the trailing "\0"
3490                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3491                                         ($::sha1)\s($::sha1)\s
3492                                         ([MTCRAD])\d*$/xo) {
3493                         push @mods, {   mode_a => $1, mode_b => $2,
3494                                         sha1_a => $3, sha1_b => $4,
3495                                         chg => $5 };
3496                         if ($5 =~ /^(?:C|R)$/) {
3497                                 $state = 'file_a';
3498                         } else {
3499                                 $state = 'file_b';
3500                         }
3501                 } elsif ($state eq 'file_a') {
3502                         my $x = $mods[$#mods] or croak "Empty array\n";
3503                         if ($x->{chg} !~ /^(?:C|R)$/) {
3504                                 croak "Error parsing $_, $x->{chg}\n";
3505                         }
3506                         $x->{file_a} = $_;
3507                         $state = 'file_b';
3508                 } elsif ($state eq 'file_b') {
3509                         my $x = $mods[$#mods] or croak "Empty array\n";
3510                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3511                                 croak "Error parsing $_, $x->{chg}\n";
3512                         }
3513                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3514                                 croak "Error parsing $_, $x->{chg}\n";
3515                         }
3516                         $x->{file_b} = $_;
3517                         $state = 'meta';
3518                 } else {
3519                         croak "Error parsing $_\n";
3520                 }
3521         }
3522         command_close_pipe($diff_fh, $ctx);
3523         \@mods;
3524 }
3525
3526 sub check_diff_paths {
3527         my ($ra, $pfx, $rev, $mods) = @_;
3528         my %types;
3529         $pfx .= '/' if length $pfx;
3530
3531         sub type_diff_paths {
3532                 my ($ra, $types, $path, $rev) = @_;
3533                 my @p = split m#/+#, $path;
3534                 my $c = shift @p;
3535                 unless (defined $types->{$c}) {
3536                         $types->{$c} = $ra->check_path($c, $rev);
3537                 }
3538                 while (@p) {
3539                         $c .= '/' . shift @p;
3540                         next if defined $types->{$c};
3541                         $types->{$c} = $ra->check_path($c, $rev);
3542                 }
3543         }
3544
3545         foreach my $m (@$mods) {
3546                 foreach my $f (qw/file_a file_b/) {
3547                         next unless defined $m->{$f};
3548                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3549                         if (length $pfx.$dir && ! defined $types{$dir}) {
3550                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3551                         }
3552                 }
3553         }
3554         \%types;
3555 }
3556
3557 sub split_path {
3558         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3559 }
3560
3561 sub repo_path {
3562         my ($self, $path) = @_;
3563         $self->{path_prefix}.(defined $path ? $path : '');
3564 }
3565
3566 sub url_path {
3567         my ($self, $path) = @_;
3568         if ($self->{url} =~ m#^https?://#) {
3569                 $path =~ s/([^~a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3570         }
3571         $self->{url} . '/' . $self->repo_path($path);
3572 }
3573
3574 sub rmdirs {
3575         my ($self) = @_;
3576         my $rm = $self->{rm};
3577         delete $rm->{''}; # we never delete the url we're tracking
3578         return unless %$rm;
3579
3580         foreach (keys %$rm) {
3581                 my @d = split m#/#, $_;
3582                 my $c = shift @d;
3583                 $rm->{$c} = 1;
3584                 while (@d) {
3585                         $c .= '/' . shift @d;
3586                         $rm->{$c} = 1;
3587                 }
3588         }
3589         delete $rm->{$self->{svn_path}};
3590         delete $rm->{''}; # we never delete the url we're tracking
3591         return unless %$rm;
3592
3593         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3594                                              $self->{tree_b});
3595         local $/ = "\0";
3596         while (<$fh>) {
3597                 chomp;
3598                 my @dn = split m#/#, $_;
3599                 while (pop @dn) {
3600                         delete $rm->{join '/', @dn};
3601                 }
3602                 unless (%$rm) {
3603                         close $fh;
3604                         return;
3605                 }
3606         }
3607         command_close_pipe($fh, $ctx);
3608
3609         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3610         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3611                 $self->close_directory($bat->{$d}, $p);
3612                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3613                 print "\tD+\t$d/\n" unless $::_q;
3614                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3615                 delete $bat->{$d};
3616         }
3617 }
3618
3619 sub open_or_add_dir {
3620         my ($self, $full_path, $baton) = @_;
3621         my $t = $self->{types}->{$full_path};
3622         if (!defined $t) {
3623                 die "$full_path not known in r$self->{r} or we have a bug!\n";
3624         }
3625         {
3626                 no warnings 'once';
3627                 # SVN::Node::none and SVN::Node::file are used only once,
3628                 # so we're shutting up Perl's warnings about them.
3629                 if ($t == $SVN::Node::none) {
3630                         return $self->add_directory($full_path, $baton,
3631                             undef, -1, $self->{pool});
3632                 } elsif ($t == $SVN::Node::dir) {
3633                         return $self->open_directory($full_path, $baton,
3634                             $self->{r}, $self->{pool});
3635                 } # no warnings 'once'
3636                 print STDERR "$full_path already exists in repository at ",
3637                     "r$self->{r} and it is not a directory (",
3638                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3639         } # no warnings 'once'
3640         exit 1;
3641 }
3642
3643 sub ensure_path {
3644         my ($self, $path) = @_;
3645         my $bat = $self->{bat};
3646         my $repo_path = $self->repo_path($path);
3647         return $bat->{''} unless (length $repo_path);
3648         my @p = split m#/+#, $repo_path;
3649         my $c = shift @p;
3650         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3651         while (@p) {
3652                 my $c0 = $c;
3653                 $c .= '/' . shift @p;
3654                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3655         }
3656         return $bat->{$c};
3657 }
3658
3659 # Subroutine to convert a globbing pattern to a regular expression.
3660 # From perl cookbook.
3661 sub glob2pat {
3662         my $globstr = shift;
3663         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
3664         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
3665         return '^' . $globstr . '$';
3666 }
3667
3668 sub check_autoprop {
3669         my ($self, $pattern, $properties, $file, $fbat) = @_;
3670         # Convert the globbing pattern to a regular expression.
3671         my $regex = glob2pat($pattern);
3672         # Check if the pattern matches the file name.
3673         if($file =~ m/($regex)/) {
3674                 # Parse the list of properties to set.
3675                 my @props = split(/;/, $properties);
3676                 foreach my $prop (@props) {
3677                         # Parse 'name=value' syntax and set the property.
3678                         if ($prop =~ /([^=]+)=(.*)/) {
3679                                 my ($n,$v) = ($1,$2);
3680                                 for ($n, $v) {
3681                                         s/^\s+//; s/\s+$//;
3682                                 }
3683                                 $self->change_file_prop($fbat, $n, $v);
3684                         }
3685                 }
3686         }
3687 }
3688
3689 sub apply_autoprops {
3690         my ($self, $file, $fbat) = @_;
3691         my $conf_t = ${$self->{config}}{'config'};
3692         no warnings 'once';
3693         # Check [miscellany]/enable-auto-props in svn configuration.
3694         if (SVN::_Core::svn_config_get_bool(
3695                 $conf_t,
3696                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
3697                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
3698                 0)) {
3699                 # Auto-props are enabled.  Enumerate them to look for matches.
3700                 my $callback = sub {
3701                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
3702                 };
3703                 SVN::_Core::svn_config_enumerate(
3704                         $conf_t,
3705                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
3706                         $callback);
3707         }
3708 }
3709
3710 sub A {
3711         my ($self, $m) = @_;
3712         my ($dir, $file) = split_path($m->{file_b});
3713         my $pbat = $self->ensure_path($dir);
3714         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3715                                         undef, -1);
3716         print "\tA\t$m->{file_b}\n" unless $::_q;
3717         $self->apply_autoprops($file, $fbat);
3718         $self->chg_file($fbat, $m);
3719         $self->close_file($fbat,undef,$self->{pool});
3720 }
3721
3722 sub C {
3723         my ($self, $m) = @_;
3724         my ($dir, $file) = split_path($m->{file_b});
3725         my $pbat = $self->ensure_path($dir);
3726         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3727                                 $self->url_path($m->{file_a}), $self->{r});
3728         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3729         $self->chg_file($fbat, $m);
3730         $self->close_file($fbat,undef,$self->{pool});
3731 }
3732
3733 sub delete_entry {
3734         my ($self, $path, $pbat) = @_;
3735         my $rpath = $self->repo_path($path);
3736         my ($dir, $file) = split_path($rpath);
3737         $self->{rm}->{$dir} = 1;
3738         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3739 }
3740
3741 sub R {
3742         my ($self, $m) = @_;
3743         my ($dir, $file) = split_path($m->{file_b});
3744         my $pbat = $self->ensure_path($dir);
3745         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3746                                 $self->url_path($m->{file_a}), $self->{r});
3747         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3748         $self->apply_autoprops($file, $fbat);
3749         $self->chg_file($fbat, $m);
3750         $self->close_file($fbat,undef,$self->{pool});
3751
3752         ($dir, $file) = split_path($m->{file_a});
3753         $pbat = $self->ensure_path($dir);
3754         $self->delete_entry($m->{file_a}, $pbat);
3755 }
3756
3757 sub M {
3758         my ($self, $m) = @_;
3759         my ($dir, $file) = split_path($m->{file_b});
3760         my $pbat = $self->ensure_path($dir);
3761         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3762                                 $pbat,$self->{r},$self->{pool});
3763         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3764         $self->chg_file($fbat, $m);
3765         $self->close_file($fbat,undef,$self->{pool});
3766 }
3767
3768 sub T { shift->M(@_) }
3769
3770 sub change_file_prop {
3771         my ($self, $fbat, $pname, $pval) = @_;
3772         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3773 }
3774
3775 sub _chg_file_get_blob ($$$$) {
3776         my ($self, $fbat, $m, $which) = @_;
3777         my $fh = $::_repository->temp_acquire("git_blob_$which");
3778         if ($m->{"mode_$which"} =~ /^120/) {
3779                 print $fh 'link ' or croak $!;
3780                 $self->change_file_prop($fbat,'svn:special','*');
3781         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
3782                 $self->change_file_prop($fbat,'svn:special',undef);
3783         }
3784         my $blob = $m->{"sha1_$which"};
3785         return ($fh,) if ($blob =~ /^0{40}$/);
3786         my $size = $::_repository->cat_blob($blob, $fh);
3787         croak "Failed to read object $blob" if ($size < 0);
3788         $fh->flush == 0 or croak $!;
3789         seek $fh, 0, 0 or croak $!;
3790
3791         my $exp = ::md5sum($fh);
3792         seek $fh, 0, 0 or croak $!;
3793         return ($fh, $exp);
3794 }
3795
3796 sub chg_file {
3797         my ($self, $fbat, $m) = @_;
3798         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3799                 $self->change_file_prop($fbat,'svn:executable','*');
3800         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3801                 $self->change_file_prop($fbat,'svn:executable',undef);
3802         }
3803         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
3804         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
3805         my $pool = SVN::Pool->new;
3806         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
3807         if (-s $fh_a) {
3808                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
3809                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
3810                 if (defined $res) {
3811                         die "Unexpected result from send_txstream: $res\n",
3812                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
3813                 }
3814         } else {
3815                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
3816                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
3817                     if ($got ne $exp_b);
3818         }
3819         Git::temp_release($fh_b, 1);
3820         Git::temp_release($fh_a, 1);
3821         $pool->clear;
3822 }
3823
3824 sub D {
3825         my ($self, $m) = @_;
3826         my ($dir, $file) = split_path($m->{file_b});
3827         my $pbat = $self->ensure_path($dir);
3828         print "\tD\t$m->{file_b}\n" unless $::_q;
3829         $self->delete_entry($m->{file_b}, $pbat);
3830 }
3831
3832 sub close_edit {
3833         my ($self) = @_;
3834         my ($p,$bat) = ($self->{pool}, $self->{bat});
3835         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3836                 next if $_ eq '';
3837                 $self->close_directory($bat->{$_}, $p);
3838         }
3839         $self->close_directory($bat->{''}, $p);
3840         $self->SUPER::close_edit($p);
3841         $p->clear;
3842 }
3843
3844 sub abort_edit {
3845         my ($self) = @_;
3846         $self->SUPER::abort_edit($self->{pool});
3847 }
3848
3849 sub DESTROY {
3850         my $self = shift;
3851         $self->SUPER::DESTROY(@_);
3852         $self->{pool}->clear;
3853 }
3854
3855 # this drives the editor
3856 sub apply_diff {
3857         my ($self) = @_;
3858         my $mods = $self->{mods};
3859         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3860         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3861                 my $f = $m->{chg};
3862                 if (defined $o{$f}) {
3863                         $self->$f($m);
3864                 } else {
3865                         fatal("Invalid change type: $f");
3866                 }
3867         }
3868         $self->rmdirs if $_rmdir;
3869         if (@$mods == 0) {
3870                 $self->abort_edit;
3871         } else {
3872                 $self->close_edit;
3873         }
3874         return scalar @$mods;
3875 }
3876
3877 package Git::SVN::Ra;
3878 use vars qw/@ISA $config_dir $_log_window_size/;
3879 use strict;
3880 use warnings;
3881 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3882
3883 BEGIN {
3884         # enforce temporary pool usage for some simple functions
3885         no strict 'refs';
3886         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3887                 my $SUPER = "SUPER::$f";
3888                 *$f = sub {
3889                         my $self = shift;
3890                         my $pool = SVN::Pool->new;
3891                         my @ret = $self->$SUPER(@_,$pool);
3892                         $pool->clear;
3893                         wantarray ? @ret : $ret[0];
3894                 };
3895         }
3896 }
3897
3898 sub _auth_providers () {
3899         [
3900           SVN::Client::get_simple_provider(),
3901           SVN::Client::get_ssl_server_trust_file_provider(),
3902           SVN::Client::get_simple_prompt_provider(
3903             \&Git::SVN::Prompt::simple, 2),
3904           SVN::Client::get_ssl_client_cert_file_provider(),
3905           SVN::Client::get_ssl_client_cert_prompt_provider(
3906             \&Git::SVN::Prompt::ssl_client_cert, 2),
3907           SVN::Client::get_ssl_client_cert_pw_file_provider(),
3908           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3909             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3910           SVN::Client::get_username_provider(),
3911           SVN::Client::get_ssl_server_trust_prompt_provider(
3912             \&Git::SVN::Prompt::ssl_server_trust),
3913           SVN::Client::get_username_prompt_provider(
3914             \&Git::SVN::Prompt::username, 2)
3915         ]
3916 }
3917
3918 sub escape_uri_only {
3919         my ($uri) = @_;
3920         my @tmp;
3921         foreach (split m{/}, $uri) {
3922                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
3923                 push @tmp, $_;
3924         }
3925         join('/', @tmp);
3926 }
3927
3928 sub escape_url {
3929         my ($url) = @_;
3930         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3931                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3932                 $url = "$scheme://$domain$uri";
3933         }
3934         $url;
3935 }
3936
3937 sub new {
3938         my ($class, $url) = @_;
3939         $url =~ s!/+$!!;
3940         return $RA if ($RA && $RA->{url} eq $url);
3941
3942         SVN::_Core::svn_config_ensure($config_dir, undef);
3943         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3944         my $config = SVN::Core::config_get_config($config_dir);
3945         $RA = undef;
3946         my $dont_store_passwords = 1;
3947         my $conf_t = ${$config}{'config'};
3948         {
3949                 no warnings 'once';
3950                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3951                 # produces warnings that variables are used only once.
3952                 # I had not found the better way to shut them up, so
3953                 # the warnings of type 'once' are disabled in this block.
3954                 if (SVN::_Core::svn_config_get_bool($conf_t,
3955                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3956                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3957                     1) == 0) {
3958                         SVN::_Core::svn_auth_set_parameter($baton,
3959                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3960                             bless (\$dont_store_passwords, "_p_void"));
3961                 }
3962                 if (SVN::_Core::svn_config_get_bool($conf_t,
3963                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3964                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3965                     1) == 0) {
3966                         $Git::SVN::Prompt::_no_auth_cache = 1;
3967                 }
3968         } # no warnings 'once'
3969         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3970                               config => $config,
3971                               pool => SVN::Pool->new,
3972                               auth_provider_callbacks => $callbacks);
3973         $self->{url} = $url;
3974         $self->{svn_path} = $url;
3975         $self->{repos_root} = $self->get_repos_root;
3976         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3977         $self->{cache} = { check_path => { r => 0, data => {} },
3978                            get_dir => { r => 0, data => {} } };
3979         $RA = bless $self, $class;
3980 }
3981
3982 sub check_path {
3983         my ($self, $path, $r) = @_;
3984         my $cache = $self->{cache}->{check_path};
3985         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3986                 return $cache->{data}->{$path};
3987         }
3988         my $pool = SVN::Pool->new;
3989         my $t = $self->SUPER::check_path($path, $r, $pool);
3990         $pool->clear;
3991         if ($r != $cache->{r}) {
3992                 %{$cache->{data}} = ();
3993                 $cache->{r} = $r;
3994         }
3995         $cache->{data}->{$path} = $t;
3996 }
3997
3998 sub get_dir {
3999         my ($self, $dir, $r) = @_;
4000         my $cache = $self->{cache}->{get_dir};
4001         if ($r == $cache->{r}) {
4002                 if (my $x = $cache->{data}->{$dir}) {
4003                         return wantarray ? @$x : $x->[0];
4004                 }
4005         }
4006         my $pool = SVN::Pool->new;
4007         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4008         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4009         $pool->clear;
4010         if ($r != $cache->{r}) {
4011                 %{$cache->{data}} = ();
4012                 $cache->{r} = $r;
4013         }
4014         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
4015         wantarray ? (\%dirents, $r, $props) : \%dirents;
4016 }
4017
4018 sub DESTROY {
4019         # do not call the real DESTROY since we store ourselves in $RA
4020 }
4021
4022 sub get_log {
4023         my ($self, @args) = @_;
4024         my $pool = SVN::Pool->new;
4025         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
4026         my $ret = $self->SUPER::get_log(@args, $pool);
4027         $pool->clear;
4028         $ret;
4029 }
4030
4031 sub trees_match {
4032         my ($self, $url1, $rev1, $url2, $rev2) = @_;
4033         my $ctx = SVN::Client->new(auth => _auth_providers);
4034         my $out = IO::File->new_tmpfile;
4035
4036         # older SVN (1.1.x) doesn't take $pool as the last parameter for
4037         # $ctx->diff(), so we'll create a default one
4038         my $pool = SVN::Pool->new_default_sub;
4039
4040         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
4041         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
4042         $out->flush;
4043         my $ret = (($out->stat)[7] == 0);
4044         close $out or croak $!;
4045
4046         $ret;
4047 }
4048
4049 sub get_commit_editor {
4050         my ($self, $log, $cb, $pool) = @_;
4051         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
4052         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
4053 }
4054
4055 sub gs_do_update {
4056         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
4057         my $new = ($rev_a == $rev_b);
4058         my $path = $gs->{path};
4059
4060         if ($new && -e $gs->{index}) {
4061                 unlink $gs->{index} or die
4062                   "Couldn't unlink index: $gs->{index}: $!\n";
4063         }
4064         my $pool = SVN::Pool->new;
4065         $editor->set_path_strip($path);
4066         my (@pc) = split m#/#, $path;
4067         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
4068                                         1, $editor, $pool);
4069         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4070
4071         # Since we can't rely on svn_ra_reparent being available, we'll
4072         # just have to do some magic with set_path to make it so
4073         # we only want a partial path.
4074         my $sp = '';
4075         my $final = join('/', @pc);
4076         while (@pc) {
4077                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
4078                 $sp .= '/' if length $sp;
4079                 $sp .= shift @pc;
4080         }
4081         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
4082
4083         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
4084
4085         $reporter->finish_report($pool);
4086         $pool->clear;
4087         $editor->{git_commit_ok};
4088 }
4089
4090 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
4091 # svn_ra_reparent didn't work before 1.4)
4092 sub gs_do_switch {
4093         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
4094         my $path = $gs->{path};
4095         my $pool = SVN::Pool->new;
4096
4097         my $full_url = $self->{url};
4098         my $old_url = $full_url;
4099         $full_url .= '/' . escape_uri_only($path) if length $path;
4100         my ($ra, $reparented);
4101
4102         if ($old_url =~ m#^svn(\+ssh)?://#) {
4103                 $_[0] = undef;
4104                 $self = undef;
4105                 $RA = undef;
4106                 $ra = Git::SVN::Ra->new($full_url);
4107                 $ra_invalid = 1;
4108         } elsif ($old_url ne $full_url) {
4109                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
4110                 $self->{url} = $full_url;
4111                 $reparented = 1;
4112         }
4113
4114         $ra ||= $self;
4115         $url_b = escape_url($url_b);
4116         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
4117         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4118         $reporter->set_path('', $rev_a, 0, @lock, $pool);
4119         $reporter->finish_report($pool);
4120
4121         if ($reparented) {
4122                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
4123                 $self->{url} = $old_url;
4124         }
4125
4126         $pool->clear;
4127         $editor->{git_commit_ok};
4128 }
4129
4130 sub longest_common_path {
4131         my ($gsv, $globs) = @_;
4132         my %common;
4133         my $common_max = scalar @$gsv;
4134
4135         foreach my $gs (@$gsv) {
4136                 my @tmp = split m#/#, $gs->{path};
4137                 my $p = '';
4138                 foreach (@tmp) {
4139                         $p .= length($p) ? "/$_" : $_;
4140                         $common{$p} ||= 0;
4141                         $common{$p}++;
4142                 }
4143         }
4144         $globs ||= [];
4145         $common_max += scalar @$globs;
4146         foreach my $glob (@$globs) {
4147                 my @tmp = split m#/#, $glob->{path}->{left};
4148                 my $p = '';
4149                 foreach (@tmp) {
4150                         $p .= length($p) ? "/$_" : $_;
4151                         $common{$p} ||= 0;
4152                         $common{$p}++;
4153                 }
4154         }
4155
4156         my $longest_path = '';
4157         foreach (sort {length $b <=> length $a} keys %common) {
4158                 if ($common{$_} == $common_max) {
4159                         $longest_path = $_;
4160                         last;
4161                 }
4162         }
4163         $longest_path;
4164 }
4165
4166 sub gs_fetch_loop_common {
4167         my ($self, $base, $head, $gsv, $globs) = @_;
4168         return if ($base > $head);
4169         my $inc = $_log_window_size;
4170         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
4171         my $longest_path = longest_common_path($gsv, $globs);
4172         my $ra_url = $self->{url};
4173         while (1) {
4174                 my %revs;
4175                 my $err;
4176                 my $err_handler = $SVN::Error::handler;
4177                 $SVN::Error::handler = sub {
4178                         ($err) = @_;
4179                         skip_unknown_revs($err);
4180                 };
4181                 sub _cb {
4182                         my ($paths, $r, $author, $date, $log) = @_;
4183                         [ dup_changed_paths($paths),
4184                           { author => $author, date => $date, log => $log } ];
4185                 }
4186                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
4187                                sub { $revs{$_[1]} = _cb(@_) });
4188                 if ($err && $max >= $head) {
4189                         print STDERR "Path '$longest_path' ",
4190                                      "was probably deleted:\n",
4191                                      $err->expanded_message,
4192                                      "\nWill attempt to follow ",
4193                                      "revisions r$min .. r$max ",
4194                                      "committed before the deletion\n";
4195                         my $hi = $max;
4196                         while (--$hi >= $min) {
4197                                 my $ok;
4198                                 $self->get_log([$longest_path], $min, $hi,
4199                                                0, 1, 1, sub {
4200                                                $ok ||= $_[1];
4201                                                $revs{$_[1]} = _cb(@_) });
4202                                 if ($ok) {
4203                                         print STDERR "r$min .. r$ok OK\n";
4204                                         last;
4205                                 }
4206                         }
4207                 }
4208                 $SVN::Error::handler = $err_handler;
4209
4210                 my %exists = map { $_->{path} => $_ } @$gsv;
4211                 foreach my $r (sort {$a <=> $b} keys %revs) {
4212                         my ($paths, $logged) = @{$revs{$r}};
4213
4214                         foreach my $gs ($self->match_globs(\%exists, $paths,
4215                                                            $globs, $r)) {
4216                                 if ($gs->rev_map_max >= $r) {
4217                                         next;
4218                                 }
4219                                 next unless $gs->match_paths($paths, $r);
4220                                 $gs->{logged_rev_props} = $logged;
4221                                 if (my $last_commit = $gs->last_commit) {
4222                                         $gs->assert_index_clean($last_commit);
4223                                 }
4224                                 my $log_entry = $gs->do_fetch($paths, $r);
4225                                 if ($log_entry) {
4226                                         $gs->do_git_commit($log_entry);
4227                                 }
4228                                 $INDEX_FILES{$gs->{index}} = 1;
4229                         }
4230                         foreach my $g (@$globs) {
4231                                 my $k = "svn-remote.$g->{remote}." .
4232                                         "$g->{t}-maxRev";
4233                                 Git::SVN::tmp_config($k, $r);
4234                         }
4235                         if ($ra_invalid) {
4236                                 $_[0] = undef;
4237                                 $self = undef;
4238                                 $RA = undef;
4239                                 $self = Git::SVN::Ra->new($ra_url);
4240                                 $ra_invalid = undef;
4241                         }
4242                 }
4243                 # pre-fill the .rev_db since it'll eventually get filled in
4244                 # with '0' x40 if something new gets committed
4245                 foreach my $gs (@$gsv) {
4246                         next if $gs->rev_map_max >= $max;
4247                         next if defined $gs->rev_map_get($max);
4248                         $gs->rev_map_set($max, 0 x40);
4249                 }
4250                 foreach my $g (@$globs) {
4251                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
4252                         Git::SVN::tmp_config($k, $max);
4253                 }
4254                 last if $max >= $head;
4255                 $min = $max + 1;
4256                 $max += $inc;
4257                 $max = $head if ($max > $head);
4258         }
4259         Git::SVN::gc();
4260 }
4261
4262 sub get_dir_globbed {
4263         my ($self, $left, $depth, $r) = @_;
4264
4265         my @x = eval { $self->get_dir($left, $r) };
4266         return unless scalar @x == 3;
4267         my $dirents = $x[0];
4268         my @finalents;
4269         foreach my $de (keys %$dirents) {
4270                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4271                 if ($depth > 1) {
4272                         my @args = ("$left/$de", $depth - 1, $r);
4273                         foreach my $dir ($self->get_dir_globbed(@args)) {
4274                                 push @finalents, "$de/$dir";
4275                         }
4276                 } else {
4277                         push @finalents, $de;
4278                 }
4279         }
4280         @finalents;
4281 }
4282
4283 sub match_globs {
4284         my ($self, $exists, $paths, $globs, $r) = @_;
4285
4286         sub get_dir_check {
4287                 my ($self, $exists, $g, $r) = @_;
4288
4289                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
4290                                                   $g->{path}->{depth},
4291                                                   $r);
4292
4293                 foreach my $de (@dirs) {
4294                         my $p = $g->{path}->full_path($de);
4295                         next if $exists->{$p};
4296                         next if (length $g->{path}->{right} &&
4297                                  ($self->check_path($p, $r) !=
4298                                   $SVN::Node::dir));
4299                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4300                                          $g->{ref}->full_path($de), 1);
4301                 }
4302         }
4303         foreach my $g (@$globs) {
4304                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4305                         if ($path->{action} =~ /^[AR]$/) {
4306                                 get_dir_check($self, $exists, $g, $r);
4307                         }
4308                 }
4309                 foreach (keys %$paths) {
4310                         if (/$g->{path}->{left_regex}/ &&
4311                             !/$g->{path}->{regex}/) {
4312                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
4313                                 get_dir_check($self, $exists, $g, $r);
4314                         }
4315                         next unless /$g->{path}->{regex}/;
4316                         my $p = $1;
4317                         my $pathname = $g->{path}->full_path($p);
4318                         next if $exists->{$pathname};
4319                         next if ($self->check_path($pathname, $r) !=
4320                                  $SVN::Node::dir);
4321                         $exists->{$pathname} = Git::SVN->init(
4322                                               $self->{url}, $pathname, undef,
4323                                               $g->{ref}->full_path($p), 1);
4324                 }
4325                 my $c = '';
4326                 foreach (split m#/#, $g->{path}->{left}) {
4327                         $c .= "/$_";
4328                         next unless ($paths->{$c} &&
4329                                      ($paths->{$c}->{action} =~ /^[AR]$/));
4330                         get_dir_check($self, $exists, $g, $r);
4331                 }
4332         }
4333         values %$exists;
4334 }
4335
4336 sub minimize_url {
4337         my ($self) = @_;
4338         return $self->{url} if ($self->{url} eq $self->{repos_root});
4339         my $url = $self->{repos_root};
4340         my @components = split(m!/!, $self->{svn_path});
4341         my $c = '';
4342         do {
4343                 $url .= "/$c" if length $c;
4344                 eval { (ref $self)->new($url)->get_latest_revnum };
4345         } while ($@ && ($c = shift @components));
4346         $url;
4347 }
4348
4349 sub can_do_switch {
4350         my $self = shift;
4351         unless (defined $can_do_switch) {
4352                 my $pool = SVN::Pool->new;
4353                 my $rep = eval {
4354                         $self->do_switch(1, '', 0, $self->{url},
4355                                          SVN::Delta::Editor->new, $pool);
4356                 };
4357                 if ($@) {
4358                         $can_do_switch = 0;
4359                 } else {
4360                         $rep->abort_report($pool);
4361                         $can_do_switch = 1;
4362                 }
4363                 $pool->clear;
4364         }
4365         $can_do_switch;
4366 }
4367
4368 sub skip_unknown_revs {
4369         my ($err) = @_;
4370         my $errno = $err->apr_err();
4371         # Maybe the branch we're tracking didn't
4372         # exist when the repo started, so it's
4373         # not an error if it doesn't, just continue
4374         #
4375         # Wonderfully consistent library, eh?
4376         # 160013 - svn:// and file://
4377         # 175002 - http(s)://
4378         # 175007 - http(s):// (this repo required authorization, too...)
4379         #   More codes may be discovered later...
4380         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4381                 my $err_key = $err->expanded_message;
4382                 # revision numbers change every time, filter them out
4383                 $err_key =~ s/\d+/\0/g;
4384                 $err_key = "$errno\0$err_key";
4385                 unless ($ignored_err{$err_key}) {
4386                         warn "W: Ignoring error from SVN, path probably ",
4387                              "does not exist: ($errno): ",
4388                              $err->expanded_message,"\n";
4389                         warn "W: Do not be alarmed at the above message ",
4390                              "git-svn is just searching aggressively for ",
4391                              "old history.\n",
4392                              "This may take a while on large repositories\n";
4393                         $ignored_err{$err_key} = 1;
4394                 }
4395                 return;
4396         }
4397         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4398 }
4399
4400 # svn_log_changed_path_t objects passed to get_log are likely to be
4401 # overwritten even if only the refs are copied to an external variable,
4402 # so we should dup the structures in their entirety.  Using an externally
4403 # passed pool (instead of our temporary and quickly cleared pool in
4404 # Git::SVN::Ra) does not help matters at all...
4405 sub dup_changed_paths {
4406         my ($paths) = @_;
4407         return undef unless $paths;
4408         my %ret;
4409         foreach my $p (keys %$paths) {
4410                 my $i = $paths->{$p};
4411                 my %s = map { $_ => $i->$_ }
4412                               qw/copyfrom_path copyfrom_rev action/;
4413                 $ret{$p} = \%s;
4414         }
4415         \%ret;
4416 }
4417
4418 package Git::SVN::Log;
4419 use strict;
4420 use warnings;
4421 use POSIX qw/strftime/;
4422 use constant commit_log_separator => ('-' x 72) . "\n";
4423 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4424             %rusers $show_commit $incremental/;
4425 my $l_fmt;
4426
4427 sub cmt_showable {
4428         my ($c) = @_;
4429         return 1 if defined $c->{r};
4430
4431         # big commit message got truncated by the 16k pretty buffer in rev-list
4432         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4433                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4434                 @{$c->{l}} = ();
4435                 my @log = command(qw/cat-file commit/, $c->{c});
4436
4437                 # shift off the headers
4438                 shift @log while ($log[0] ne '');
4439                 shift @log;
4440
4441                 # TODO: make $c->{l} not have a trailing newline in the future
4442                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4443
4444                 (undef, $c->{r}, undef) = ::extract_metadata(
4445                                 (grep(/^git-svn-id: /, @log))[-1]);
4446         }
4447         return defined $c->{r};
4448 }
4449
4450 sub log_use_color {
4451         return $color || Git->repository->get_colorbool('color.diff');
4452 }
4453
4454 sub git_svn_log_cmd {
4455         my ($r_min, $r_max, @args) = @_;
4456         my $head = 'HEAD';
4457         my (@files, @log_opts);
4458         foreach my $x (@args) {
4459                 if ($x eq '--' || @files) {
4460                         push @files, $x;
4461                 } else {
4462                         if (::verify_ref("$x^0")) {
4463                                 $head = $x;
4464                         } else {
4465                                 push @log_opts, $x;
4466                         }
4467                 }
4468         }
4469
4470         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4471         $gs ||= Git::SVN->_new;
4472         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4473                    $gs->refname);
4474         push @cmd, '-r' unless $non_recursive;
4475         push @cmd, qw/--raw --name-status/ if $verbose;
4476         push @cmd, '--color' if log_use_color();
4477         push @cmd, @log_opts;
4478         if (defined $r_max && $r_max == $r_min) {
4479                 push @cmd, '--max-count=1';
4480                 if (my $c = $gs->rev_map_get($r_max)) {
4481                         push @cmd, $c;
4482                 }
4483         } elsif (defined $r_max) {
4484                 if ($r_max < $r_min) {
4485                         ($r_min, $r_max) = ($r_max, $r_min);
4486                 }
4487                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4488                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4489                 # If there are no commits in the range, both $c_max and $c_min
4490                 # will be undefined.  If there is at least 1 commit in the
4491                 # range, both will be defined.
4492                 return () if !defined $c_min || !defined $c_max;
4493                 if ($c_min eq $c_max) {
4494                         push @cmd, '--max-count=1', $c_min;
4495                 } else {
4496                         push @cmd, '--boundary', "$c_min..$c_max";
4497                 }
4498         }
4499         return (@cmd, @files);
4500 }
4501
4502 # adapted from pager.c
4503 sub config_pager {
4504         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4505         if (!defined $pager) {
4506                 $pager = 'less';
4507         } elsif (length $pager == 0 || $pager eq 'cat') {
4508                 $pager = undef;
4509         }
4510         $ENV{GIT_PAGER_IN_USE} = defined($pager);
4511 }
4512
4513 sub run_pager {
4514         return unless -t *STDOUT && defined $pager;
4515         pipe my ($rfd, $wfd) or return;
4516         defined(my $pid = fork) or ::fatal "Can't fork: $!";
4517         if (!$pid) {
4518                 open STDOUT, '>&', $wfd or
4519                                      ::fatal "Can't redirect to stdout: $!";
4520                 return;
4521         }
4522         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4523         $ENV{LESS} ||= 'FRSX';
4524         exec $pager or ::fatal "Can't run pager: $! ($pager)";
4525 }
4526
4527 sub format_svn_date {
4528         return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4529 }
4530
4531 sub parse_git_date {
4532         my ($t, $tz) = @_;
4533         # Date::Parse isn't in the standard Perl distro :(
4534         if ($tz =~ s/^\+//) {
4535                 $t += tz_to_s_offset($tz);
4536         } elsif ($tz =~ s/^\-//) {
4537                 $t -= tz_to_s_offset($tz);
4538         }
4539         return $t;
4540 }
4541
4542 sub set_local_timezone {
4543         if (defined $TZ) {
4544                 $ENV{TZ} = $TZ;
4545         } else {
4546                 delete $ENV{TZ};
4547         }
4548 }
4549
4550 sub tz_to_s_offset {
4551         my ($tz) = @_;
4552         $tz =~ s/(\d\d)$//;
4553         return ($1 * 60) + ($tz * 3600);
4554 }
4555
4556 sub get_author_info {
4557         my ($dest, $author, $t, $tz) = @_;
4558         $author =~ s/(?:^\s*|\s*$)//g;
4559         $dest->{a_raw} = $author;
4560         my $au;
4561         if ($::_authors) {
4562                 $au = $rusers{$author} || undef;
4563         }
4564         if (!$au) {
4565                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4566         }
4567         $dest->{t} = $t;
4568         $dest->{tz} = $tz;
4569         $dest->{a} = $au;
4570         $dest->{t_utc} = parse_git_date($t, $tz);
4571 }
4572
4573 sub process_commit {
4574         my ($c, $r_min, $r_max, $defer) = @_;
4575         if (defined $r_min && defined $r_max) {
4576                 if ($r_min == $c->{r} && $r_min == $r_max) {
4577                         show_commit($c);
4578                         return 0;
4579                 }
4580                 return 1 if $r_min == $r_max;
4581                 if ($r_min < $r_max) {
4582                         # we need to reverse the print order
4583                         return 0 if (defined $limit && --$limit < 0);
4584                         push @$defer, $c;
4585                         return 1;
4586                 }
4587                 if ($r_min != $r_max) {
4588                         return 1 if ($r_min < $c->{r});
4589                         return 1 if ($r_max > $c->{r});
4590                 }
4591         }
4592         return 0 if (defined $limit && --$limit < 0);
4593         show_commit($c);
4594         return 1;
4595 }
4596
4597 sub show_commit {
4598         my $c = shift;
4599         if ($oneline) {
4600                 my $x = "\n";
4601                 if (my $l = $c->{l}) {
4602                         while ($l->[0] =~ /^\s*$/) { shift @$l }
4603                         $x = $l->[0];
4604                 }
4605                 $l_fmt ||= 'A' . length($c->{r});
4606                 print 'r',pack($l_fmt, $c->{r}),' | ';
4607                 print "$c->{c} | " if $show_commit;
4608                 print $x;
4609         } else {
4610                 show_commit_normal($c);
4611         }
4612 }
4613
4614 sub show_commit_changed_paths {
4615         my ($c) = @_;
4616         return unless $c->{changed};
4617         print "Changed paths:\n", @{$c->{changed}};
4618 }
4619
4620 sub show_commit_normal {
4621         my ($c) = @_;
4622         print commit_log_separator, "r$c->{r} | ";
4623         print "$c->{c} | " if $show_commit;
4624         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4625         my $nr_line = 0;
4626
4627         if (my $l = $c->{l}) {
4628                 while ($l->[$#$l] eq "\n" && $#$l > 0
4629                                           && $l->[($#$l - 1)] eq "\n") {
4630                         pop @$l;
4631                 }
4632                 $nr_line = scalar @$l;
4633                 if (!$nr_line) {
4634                         print "1 line\n\n\n";
4635                 } else {
4636                         if ($nr_line == 1) {
4637                                 $nr_line = '1 line';
4638                         } else {
4639                                 $nr_line .= ' lines';
4640                         }
4641                         print $nr_line, "\n";
4642                         show_commit_changed_paths($c);
4643                         print "\n";
4644                         print $_ foreach @$l;
4645                 }
4646         } else {
4647                 print "1 line\n";
4648                 show_commit_changed_paths($c);
4649                 print "\n";
4650
4651         }
4652         foreach my $x (qw/raw stat diff/) {
4653                 if ($c->{$x}) {
4654                         print "\n";
4655                         print $_ foreach @{$c->{$x}}
4656                 }
4657         }
4658 }
4659
4660 sub cmd_show_log {
4661         my (@args) = @_;
4662         my ($r_min, $r_max);
4663         my $r_last = -1; # prevent dupes
4664         set_local_timezone();
4665         if (defined $::_revision) {
4666                 if ($::_revision =~ /^(\d+):(\d+)$/) {
4667                         ($r_min, $r_max) = ($1, $2);
4668                 } elsif ($::_revision =~ /^\d+$/) {
4669                         $r_min = $r_max = $::_revision;
4670                 } else {
4671                         ::fatal "-r$::_revision is not supported, use ",
4672                                 "standard 'git log' arguments instead";
4673                 }
4674         }
4675
4676         config_pager();
4677         @args = git_svn_log_cmd($r_min, $r_max, @args);
4678         if (!@args) {
4679                 print commit_log_separator unless $incremental || $oneline;
4680                 return;
4681         }
4682         my $log = command_output_pipe(@args);
4683         run_pager();
4684         my (@k, $c, $d, $stat);
4685         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4686         while (<$log>) {
4687                 if (/^${esc_color}commit -?($::sha1_short)/o) {
4688                         my $cmt = $1;
4689                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4690                                 $r_last = $c->{r};
4691                                 process_commit($c, $r_min, $r_max, \@k) or
4692                                                                 goto out;
4693                         }
4694                         $d = undef;
4695                         $c = { c => $cmt };
4696                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4697                         get_author_info($c, $1, $2, $3);
4698                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4699                         # ignore
4700                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4701                         push @{$c->{raw}}, $_;
4702                 } elsif (/^${esc_color}[ACRMDT]\t/) {
4703                         # we could add $SVN->{svn_path} here, but that requires
4704                         # remote access at the moment (repo_path_split)...
4705                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
4706                         push @{$c->{changed}}, $_;
4707                 } elsif (/^${esc_color}diff /o) {
4708                         $d = 1;
4709                         push @{$c->{diff}}, $_;
4710                 } elsif ($d) {
4711                         push @{$c->{diff}}, $_;
4712                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4713                           $esc_color*[\+\-]*$esc_color$/x) {
4714                         $stat = 1;
4715                         push @{$c->{stat}}, $_;
4716                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4717                         push @{$c->{stat}}, $_;
4718                         $stat = undef;
4719                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
4720                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4721                 } elsif (s/^${esc_color}    //o) {
4722                         push @{$c->{l}}, $_;
4723                 }
4724         }
4725         if ($c && defined $c->{r} && $c->{r} != $r_last) {
4726                 $r_last = $c->{r};
4727                 process_commit($c, $r_min, $r_max, \@k);
4728         }
4729         if (@k) {
4730                 ($r_min, $r_max) = ($r_max, $r_min);
4731                 process_commit($_, $r_min, $r_max) foreach reverse @k;
4732         }
4733 out:
4734         close $log;
4735         print commit_log_separator unless $incremental || $oneline;
4736 }
4737
4738 sub cmd_blame {
4739         my $path = pop;
4740
4741         config_pager();
4742         run_pager();
4743
4744         my ($fh, $ctx, $rev);
4745
4746         if ($_git_format) {
4747                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
4748                 while (my $line = <$fh>) {
4749                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
4750                                 # Uncommitted edits show up as a rev ID of
4751                                 # all zeros, which we can't look up with
4752                                 # cmt_metadata
4753                                 if ($1 !~ /^0+$/) {
4754                                         (undef, $rev, undef) =
4755                                                 ::cmt_metadata($1);
4756                                         $rev = '0' if (!$rev);
4757                                 } else {
4758                                         $rev = '0';
4759                                 }
4760                                 $rev = sprintf('%-10s', $rev);
4761                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
4762                         }
4763                         print $line;
4764                 }
4765         } else {
4766                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
4767                                                   '--', $path);
4768                 my ($sha1);
4769                 my %authors;
4770                 while (my $line = <$fh>) {
4771                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
4772                                 $sha1 = $1;
4773                                 (undef, $rev, undef) = ::cmt_metadata($1);
4774                                 $rev = '0' if (!$rev);
4775                         }
4776                         elsif ($line =~ /^author (.*)/) {
4777                                 $authors{$rev} = $1;
4778                                 $authors{$rev} =~ s/\s/_/g;
4779                         }
4780                         elsif ($line =~ /^\t(.*)$/) {
4781                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
4782                         }
4783                 }
4784         }
4785         command_close_pipe($fh, $ctx);
4786 }
4787
4788 package Git::SVN::Migration;
4789 # these version numbers do NOT correspond to actual version numbers
4790 # of git nor git-svn.  They are just relative.
4791 #
4792 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4793 #
4794 # v1 layout: .git/$id/info/url, refs/remotes/$id
4795 #
4796 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4797 #
4798 # v3 layout: .git/svn/$id, refs/remotes/$id
4799 #            - info/url may remain for backwards compatibility
4800 #            - this is what we migrate up to this layout automatically,
4801 #            - this will be used by git svn init on single branches
4802 # v3.1 layout (auto migrated):
4803 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4804 #              for backwards compatibility
4805 #
4806 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4807 #            - this is only created for newly multi-init-ed
4808 #              repositories.  Similar in spirit to the
4809 #              --use-separate-remotes option in git-clone (now default)
4810 #            - we do not automatically migrate to this (following
4811 #              the example set by core git)
4812 #
4813 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4814 #            - newer, more-efficient format that uses 24-bytes per record
4815 #              with no filler space.
4816 #            - use xxd -c24 < .rev_map.$UUID to view and debug
4817 #            - This is a one-way migration, repositories updated to the
4818 #              new format will not be able to use old git-svn without
4819 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
4820 #              possible if noMetadata or useSvmProps are set; but should
4821 #              be no problem for users that use the (sensible) defaults.
4822 use strict;
4823 use warnings;
4824 use Carp qw/croak/;
4825 use File::Path qw/mkpath/;
4826 use File::Basename qw/dirname basename/;
4827 use vars qw/$_minimize/;
4828
4829 sub migrate_from_v0 {
4830         my $git_dir = $ENV{GIT_DIR};
4831         return undef unless -d $git_dir;
4832         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4833         my $migrated = 0;
4834         while (<$fh>) {
4835                 chomp;
4836                 my ($id, $orig_ref) = ($_, $_);
4837                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4838                 next unless -f "$git_dir/$id/info/url";
4839                 my $new_ref = "refs/remotes/$id";
4840                 if (::verify_ref("$new_ref^0")) {
4841                         print STDERR "W: $orig_ref is probably an old ",
4842                                      "branch used by an ancient version of ",
4843                                      "git-svn.\n",
4844                                      "However, $new_ref also exists.\n",
4845                                      "We will not be able ",
4846                                      "to use this branch until this ",
4847                                      "ambiguity is resolved.\n";
4848                         next;
4849                 }
4850                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4851                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4852                 command_noisy('update-ref', $new_ref, $orig_ref);
4853                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4854                 $migrated++;
4855         }
4856         command_close_pipe($fh, $ctx);
4857         print STDERR "Done migrating from v0 layout...\n" if $migrated;
4858         $migrated;
4859 }
4860
4861 sub migrate_from_v1 {
4862         my $git_dir = $ENV{GIT_DIR};
4863         my $migrated = 0;
4864         return $migrated unless -d $git_dir;
4865         my $svn_dir = "$git_dir/svn";
4866
4867         # just in case somebody used 'svn' as their $id at some point...
4868         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4869
4870         print STDERR "Migrating from a git-svn v1 layout...\n";
4871         mkpath([$svn_dir]);
4872         print STDERR "Data from a previous version of git-svn exists, but\n\t",
4873                      "$svn_dir\n\t(required for this version ",
4874                      "($::VERSION) of git-svn) does not exist.\n";
4875         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4876         while (<$fh>) {
4877                 my $x = $_;
4878                 next unless $x =~ s#^refs/remotes/##;
4879                 chomp $x;
4880                 next unless -f "$git_dir/$x/info/url";
4881                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4882                 next unless $u;
4883                 my $dn = dirname("$git_dir/svn/$x");
4884                 mkpath([$dn]) unless -d $dn;
4885                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4886                         mkpath(["$git_dir/svn/svn"]);
4887                         print STDERR " - $git_dir/$x/info => ",
4888                                         "$git_dir/svn/$x/info\n";
4889                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4890                                croak "$!: $x";
4891                         # don't worry too much about these, they probably
4892                         # don't exist with repos this old (save for index,
4893                         # and we can easily regenerate that)
4894                         foreach my $f (qw/unhandled.log index .rev_db/) {
4895                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4896                         }
4897                 } else {
4898                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4899                         rename "$git_dir/$x", "$git_dir/svn/$x" or
4900                                croak "$!: $x";
4901                 }
4902                 $migrated++;
4903         }
4904         command_close_pipe($fh, $ctx);
4905         print STDERR "Done migrating from a git-svn v1 layout\n";
4906         $migrated;
4907 }
4908
4909 sub read_old_urls {
4910         my ($l_map, $pfx, $path) = @_;
4911         my @dir;
4912         foreach (<$path/*>) {
4913                 if (-r "$_/info/url") {
4914                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4915                         my $ref_id = $pfx . basename $_;
4916                         my $url = ::file_to_s("$_/info/url");
4917                         $l_map->{$ref_id} = $url;
4918                 } elsif (-d $_) {
4919                         push @dir, $_;
4920                 }
4921         }
4922         foreach (@dir) {
4923                 my $x = $_;
4924                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4925                 read_old_urls($l_map, $x, $_);
4926         }
4927 }
4928
4929 sub migrate_from_v2 {
4930         my @cfg = command(qw/config -l/);
4931         return if grep /^svn-remote\..+\.url=/, @cfg;
4932         my %l_map;
4933         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4934         my $migrated = 0;
4935
4936         foreach my $ref_id (sort keys %l_map) {
4937                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4938                 if ($@) {
4939                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4940                 }
4941                 $migrated++;
4942         }
4943         $migrated;
4944 }
4945
4946 sub minimize_connections {
4947         my $r = Git::SVN::read_all_remotes();
4948         my $new_urls = {};
4949         my $root_repos = {};
4950         foreach my $repo_id (keys %$r) {
4951                 my $url = $r->{$repo_id}->{url} or next;
4952                 my $fetch = $r->{$repo_id}->{fetch} or next;
4953                 my $ra = Git::SVN::Ra->new($url);
4954
4955                 # skip existing cases where we already connect to the root
4956                 if (($ra->{url} eq $ra->{repos_root}) ||
4957                     ($ra->{repos_root} eq $repo_id)) {
4958                         $root_repos->{$ra->{url}} = $repo_id;
4959                         next;
4960                 }
4961
4962                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4963                 my $root_path = $ra->{url};
4964                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4965                 foreach my $path (keys %$fetch) {
4966                         my $ref_id = $fetch->{$path};
4967                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4968
4969                         # make sure we can read when connecting to
4970                         # a higher level of a repository
4971                         my ($last_rev, undef) = $gs->last_rev_commit;
4972                         if (!defined $last_rev) {
4973                                 $last_rev = eval {
4974                                         $root_ra->get_latest_revnum;
4975                                 };
4976                                 next if $@;
4977                         }
4978                         my $new = $root_path;
4979                         $new .= length $path ? "/$path" : '';
4980                         eval {
4981                                 $root_ra->get_log([$new], $last_rev, $last_rev,
4982                                                   0, 0, 1, sub { });
4983                         };
4984                         next if $@;
4985                         $new_urls->{$ra->{repos_root}}->{$new} =
4986                                 { ref_id => $ref_id,
4987                                   old_repo_id => $repo_id,
4988                                   old_path => $path };
4989                 }
4990         }
4991
4992         my @emptied;
4993         foreach my $url (keys %$new_urls) {
4994                 # see if we can re-use an existing [svn-remote "repo_id"]
4995                 # instead of creating a(n ugly) new section:
4996                 my $repo_id = $root_repos->{$url} || $url;
4997
4998                 my $fetch = $new_urls->{$url};
4999                 foreach my $path (keys %$fetch) {
5000                         my $x = $fetch->{$path};
5001                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
5002                         my $pfx = "svn-remote.$x->{old_repo_id}";
5003
5004                         my $old_fetch = quotemeta("$x->{old_path}:".
5005                                                   "refs/remotes/$x->{ref_id}");
5006                         command_noisy(qw/config --unset/,
5007                                       "$pfx.fetch", '^'. $old_fetch . '$');
5008                         delete $r->{$x->{old_repo_id}}->
5009                                {fetch}->{$x->{old_path}};
5010                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
5011                                 command_noisy(qw/config --unset/,
5012                                               "$pfx.url");
5013                                 push @emptied, $x->{old_repo_id}
5014                         }
5015                 }
5016         }
5017         if (@emptied) {
5018                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
5019                 print STDERR <<EOF;
5020 The following [svn-remote] sections in your config file ($file) are empty
5021 and can be safely removed:
5022 EOF
5023                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
5024         }
5025 }
5026
5027 sub migration_check {
5028         migrate_from_v0();
5029         migrate_from_v1();
5030         migrate_from_v2();
5031         minimize_connections() if $_minimize;
5032 }
5033
5034 package Git::IndexInfo;
5035 use strict;
5036 use warnings;
5037 use Git qw/command_input_pipe command_close_pipe/;
5038
5039 sub new {
5040         my ($class) = @_;
5041         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
5042         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
5043 }
5044
5045 sub remove {
5046         my ($self, $path) = @_;
5047         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
5048                 return ++$self->{nr};
5049         }
5050         undef;
5051 }
5052
5053 sub update {
5054         my ($self, $mode, $hash, $path) = @_;
5055         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
5056                 return ++$self->{nr};
5057         }
5058         undef;
5059 }
5060
5061 sub DESTROY {
5062         my ($self) = @_;
5063         command_close_pipe($self->{gui}, $self->{ctx});
5064 }
5065
5066 package Git::SVN::GlobSpec;
5067 use strict;
5068 use warnings;
5069
5070 sub new {
5071         my ($class, $glob) = @_;
5072         my $re = $glob;
5073         $re =~ s!/+$!!g; # no need for trailing slashes
5074         $re =~ m!^([^*]*)(\*(?:/\*)*)([^*]*)$!;
5075         my $temp = $re;
5076         my ($left, $right) = ($1, $3);
5077         $re = $2;
5078         my $depth = $re =~ tr/*/*/;
5079         if ($depth != $temp =~ tr/*/*/) {
5080                 die "Only one set of wildcard directories " .
5081                         "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
5082         }
5083         if ($depth == 0) {
5084                 die "One '*' is needed for glob: '$glob'\n";
5085         }
5086         $re =~ s!\*!\[^/\]*!g;
5087         $re = quotemeta($left) . "($re)" . quotemeta($right);
5088         if (length $left && !($left =~ s!/+$!!g)) {
5089                 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
5090         }
5091         if (length $right && !($right =~ s!^/+!!g)) {
5092                 die "Missing leading '/' on right side of: '$glob' ($right)\n";
5093         }
5094         my $left_re = qr/^\/\Q$left\E(\/|$)/;
5095         bless { left => $left, right => $right, left_regex => $left_re,
5096                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
5097 }
5098
5099 sub full_path {
5100         my ($self, $path) = @_;
5101         return (length $self->{left} ? "$self->{left}/" : '') .
5102                $path . (length $self->{right} ? "/$self->{right}" : '');
5103 }
5104
5105 __END__
5106
5107 Data structures:
5108
5109
5110 $remotes = { # returned by read_all_remotes()
5111         'svn' => {
5112                 # svn-remote.svn.url=https://svn.musicpd.org
5113                 url => 'https://svn.musicpd.org',
5114                 # svn-remote.svn.fetch=mpd/trunk:trunk
5115                 fetch => {
5116                         'mpd/trunk' => 'trunk',
5117                 },
5118                 # svn-remote.svn.tags=mpd/tags/*:tags/*
5119                 tags => {
5120                         path => {
5121                                 left => 'mpd/tags',
5122                                 right => '',
5123                                 regex => qr!mpd/tags/([^/]+)$!,
5124                                 glob => 'tags/*',
5125                         },
5126                         ref => {
5127                                 left => 'tags',
5128                                 right => '',
5129                                 regex => qr!tags/([^/]+)$!,
5130                                 glob => 'tags/*',
5131                         },
5132                 }
5133         }
5134 };
5135
5136 $log_entry hashref as returned by libsvn_log_entry()
5137 {
5138         log => 'whitespace-formatted log entry
5139 ',                                              # trailing newline is preserved
5140         revision => '8',                        # integer
5141         date => '2004-02-24T17:01:44.108345Z',  # commit date
5142         author => 'committer name'
5143 };
5144
5145
5146 # this is generated by generate_diff();
5147 @mods = array of diff-index line hashes, each element represents one line
5148         of diff-index output
5149
5150 diff-index line ($m hash)
5151 {
5152         mode_a => first column of diff-index output, no leading ':',
5153         mode_b => second column of diff-index output,
5154         sha1_b => sha1sum of the final blob,
5155         chg => change type [MCRADT],
5156         file_a => original file name of a file (iff chg is 'C' or 'R')
5157         file_b => new/current file name of a file (any chg)
5158 }
5159 ;
5160
5161 # retval of read_url_paths{,_all}();
5162 $l_map = {
5163         # repository root url
5164         'https://svn.musicpd.org' => {
5165                 # repository path               # GIT_SVN_ID
5166                 'mpd/trunk'             =>      'trunk',
5167                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
5168         },
5169 }
5170
5171 Notes:
5172         I don't trust the each() function on unless I created %hash myself
5173         because the internal iterator may not have started at base.