git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24
  25 # most mail servers generate the Date: header, but not all...
  26 $ENV{LC_ALL} = 'C';
  27 use POSIX qw/strftime/;
  28
  29 my $have_email_valid = eval { require Email::Valid; 1 };
  30 my $smtp;
  31
  32 sub unique_email_list(@);
  33 sub cleanup_compose_files();
  34
  35 # Constants (essentially)
  36 my $compose_filename = ".msg.$$";
  37
  38 # Variables we fill in automatically, or via prompting:
  39 my (@to,@cc,@initial_cc,@bcclist,
  40         $initial_reply_to,$initial_subject,@files,$from,$compose,$time);
  41
  42 # Behavior modification variables
  43 my ($chain_reply_to, $quiet, $suppress_from, $no_signed_off_cc) = (1, 0, 0, 0);
  44 my $smtp_server;
  45
  46 # Example reply to:
  47 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
  48
  49 my $term = new Term::ReadLine 'git-send-email';
  50
  51 # Begin by accumulating all the variables (defined above), that we will end up
  52 # needing, first, from the command line:
  53
  54 my $rc = GetOptions("from=s" => \$from,
  55                     "in-reply-to=s" => \$initial_reply_to,
  56                     "subject=s" => \$initial_subject,
  57                     "to=s" => \@to,
  58                     "cc=s" => \@initial_cc,
  59                     "bcc=s" => \@bcclist,
  60                     "chain-reply-to!" => \$chain_reply_to,
  61                     "smtp-server=s" => \$smtp_server,
  62                     "compose" => \$compose,
  63                     "quiet" => \$quiet,
  64                     "suppress-from" => \$suppress_from,
  65                     "no-signed-off-cc|no-signed-off-by-cc" => \$no_signed_off_cc,
  66          );
  67
  68 # Now, let's fill any that aren't set in with defaults:
  69
  70 sub gitvar {
  71     my ($var) = @_;
  72     my $fh;
  73     my $pid = open($fh, '-|');
  74     die "$!" unless defined $pid;
  75     if (!$pid) {
  76         exec('git-var', $var) or die "$!";
  77     }
  78     my ($val) = <$fh>;
  79     close $fh or die "$!";
  80     chomp($val);
  81     return $val;
  82 }
  83
  84 sub gitvar_ident {
  85     my ($name) = @_;
  86     my $val = gitvar($name);
  87     my @field = split(/\s+/, $val);
  88     return join(' ', @field[0...(@field-3)]);
  89 }
  90
  91 my ($author) = gitvar_ident('GIT_AUTHOR_IDENT');
  92 my ($committer) = gitvar_ident('GIT_COMMITTER_IDENT');
  93
  94 my %aliases;
  95 chomp(my @alias_files = `git-repo-config --get-all sendemail.aliasesfile`);
  96 chomp(my $aliasfiletype = `git-repo-config sendemail.aliasfiletype`);
  97 my %parse_alias = (
  98         # multiline formats can be supported in the future
  99         mutt => sub { my $fh = shift; while (<$fh>) {
 100                 if (/^alias\s+(\S+)\s+(.*)$/) {
 101                         my ($alias, $addr) = ($1, $2);
 102                         $addr =~ s/#.*$//; # mutt allows # comments
 103                          # commas delimit multiple addresses
 104                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 105                 }}},
 106         mailrc => sub { my $fh = shift; while (<$fh>) {
 107                 if (/^alias\s+(\S+)\s+(.*)$/) {
 108                         # spaces delimit multiple addresses
 109                         $aliases{$1} = [ split(/\s+/, $2) ];
 110                 }}},
 111         pine => sub { my $fh = shift; while (<$fh>) {
 112                 if (/^(\S+)\s+(.*)$/) {
 113                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 114                 }}},
 115         gnus => sub { my $fh = shift; while (<$fh>) {
 116                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 117                         $aliases{$1} = [ $2 ];
 118                 }}}
 119 );
 120
 121 if (@alias_files && defined $parse_alias{$aliasfiletype}) {
 122         foreach my $file (@alias_files) {
 123                 open my $fh, '<', $file or die "opening $file: $!\n";
 124                 $parse_alias{$aliasfiletype}->($fh);
 125                 close $fh;
 126         }
 127 }
 128
 129 my $prompting = 0;
 130 if (!defined $from) {
 131         $from = $author || $committer;
 132         do {
 133                 $_ = $term->readline("Who should the emails appear to be from? ",
 134                         $from);
 135         } while (!defined $_);
 136
 137         $from = $_;
 138         print "Emails will be sent from: ", $from, "\n";
 139         $prompting++;
 140 }
 141
 142 if (!@to) {
 143         do {
 144                 $_ = $term->readline("Who should the emails be sent to? ",
 145                                 "");
 146         } while (!defined $_);
 147         my $to = $_;
 148         push @to, split /,/, $to;
 149         $prompting++;
 150 }
 151
 152 sub expand_aliases {
 153         my @cur = @_;
 154         my @last;
 155         do {
 156                 @last = @cur;
 157                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 158         } while (join(',',@cur) ne join(',',@last));
 159         return @cur;
 160 }
 161
 162 @to = expand_aliases(@to);
 163 @initial_cc = expand_aliases(@initial_cc);
 164 @bcclist = expand_aliases(@bcclist);
 165
 166 if (!defined $initial_subject && $compose) {
 167         do {
 168                 $_ = $term->readline("What subject should the emails start with? ",
 169                         $initial_subject);
 170         } while (!defined $_);
 171         $initial_subject = $_;
 172         $prompting++;
 173 }
 174
 175 if (!defined $initial_reply_to && $prompting) {
 176         do {
 177                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 178                         $initial_reply_to);
 179         } while (!defined $_);
 180
 181         $initial_reply_to = $_;
 182         $initial_reply_to =~ s/(^\s+|\s+$)//g;
 183 }
 184
 185 if (!$smtp_server) {
 186         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 187                 if (-x $_) {
 188                         $smtp_server = $_;
 189                         last;
 190                 }
 191         }
 192         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 193 }
 194
 195 if ($compose) {
 196         # Note that this does not need to be secure, but we will make a small
 197         # effort to have it be unique
 198         open(C,">",$compose_filename)
 199                 or die "Failed to open for writing $compose_filename: $!";
 200         print C "From $from # This line is ignored.\n";
 201         printf C "Subject: %s\n\n", $initial_subject;
 202         printf C <<EOT;
 203 GIT: Please enter your email below.
 204 GIT: Lines beginning in "GIT: " will be removed.
 205 GIT: Consider including an overall diffstat or table of contents
 206 GIT: for the patch you are writing.
 207
 208 EOT
 209         close(C);
 210
 211         my $editor = $ENV{EDITOR};
 212         $editor = 'vi' unless defined $editor;
 213         system($editor, $compose_filename);
 214
 215         open(C2,">",$compose_filename . ".final")
 216                 or die "Failed to open $compose_filename.final : " . $!;
 217
 218         open(C,"<",$compose_filename)
 219                 or die "Failed to open $compose_filename : " . $!;
 220
 221         while(<C>) {
 222                 next if m/^GIT: /;
 223                 print C2 $_;
 224         }
 225         close(C);
 226         close(C2);
 227
 228         do {
 229                 $_ = $term->readline("Send this email? (y|n) ");
 230         } while (!defined $_);
 231
 232         if (uc substr($_,0,1) ne 'Y') {
 233                 cleanup_compose_files();
 234                 exit(0);
 235         }
 236
 237         @files = ($compose_filename . ".final");
 238 }
 239
 240
 241 # Now that all the defaults are set, process the rest of the command line
 242 # arguments and collect up the files that need to be processed.
 243 for my $f (@ARGV) {
 244         if (-d $f) {
 245                 opendir(DH,$f)
 246                         or die "Failed to opendir $f: $!";
 247
 248                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 249                                 sort readdir(DH);
 250
 251         } elsif (-f $f) {
 252                 push @files, $f;
 253
 254         } else {
 255                 print STDERR "Skipping $f - not found.\n";
 256         }
 257 }
 258
 259 if (@files) {
 260         unless ($quiet) {
 261                 print $_,"\n" for (@files);
 262         }
 263 } else {
 264         print <<EOT;
 265 git-send-email [options] <file | directory> [... file | directory ]
 266 Options:
 267    --from         Specify the "From:" line of the email to be sent.
 268
 269    --to           Specify the primary "To:" line of the email.
 270
 271    --cc           Specify an initial "Cc:" list for the entire series
 272                   of emails.
 273
 274    --bcc          Specify a list of email addresses that should be Bcc:
 275                   on all the emails.
 276
 277    --compose      Use \$EDITOR to edit an introductory message for the
 278                   patch series.
 279
 280    --subject      Specify the initial "Subject:" line.
 281                   Only necessary if --compose is also set.  If --compose
 282                   is not set, this will be prompted for.
 283
 284    --in-reply-to  Specify the first "In-Reply-To:" header line.
 285                   Only used if --compose is also set.  If --compose is not
 286                   set, this will be prompted for.
 287
 288    --chain-reply-to If set, the replies will all be to the previous
 289                   email sent, rather than to the first email sent.
 290                   Defaults to on.
 291
 292    --no-signed-off-cc Suppress the automatic addition of email addresses
 293                  that appear in a Signed-off-by: line, to the cc: list.
 294                  Note: Using this option is not recommended.
 295
 296    --smtp-server  If set, specifies the outgoing SMTP server to use.
 297                   Defaults to localhost.
 298
 299   --suppress-from Supress sending emails to yourself if your address
 300                   appears in a From: line.
 301
 302    --quiet      Make git-send-email less verbose.  One line per email should be
 303                 all that is output.
 304
 305 Error: Please specify a file or a directory on the command line.
 306 EOT
 307         exit(1);
 308 }
 309
 310 # Variables we set as part of the loop over files
 311 our ($message_id, $cc, %mail, $subject, $reply_to, $references, $message);
 312
 313 sub extract_valid_address {
 314         my $address = shift;
 315         my $local_part_regexp = '[^<>"\s@]+';
 316         my $domain_regexp = '[^.<>"\s@]+\.[^<>"\s@]+';
 317
 318         # check for a local address:
 319         return $address if ($address =~ /^($local_part_regexp)$/);
 320
 321         if ($have_email_valid) {
 322                 return scalar Email::Valid->address($address);
 323         } else {
 324                 # less robust/correct than the monster regexp in Email::Valid,
 325                 # but still does a 99% job, and one less dependency
 326                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 327                 return $1;
 328         }
 329 }
 330
 331 # Usually don't need to change anything below here.
 332
 333 # we make a "fake" message id by taking the current number
 334 # of seconds since the beginning of Unix time and tacking on
 335 # a random number to the end, in case we are called quicker than
 336 # 1 second since the last time we were called.
 337
 338 # We'll setup a template for the message id, using the "from" address:
 339 my $message_id_from = extract_valid_address($from);
 340 my $message_id_template = "<%s-git-send-email-$message_id_from>";
 341
 342 sub make_message_id
 343 {
 344         my $date = time;
 345         my $pseudo_rand = int (rand(4200));
 346         $message_id = sprintf $message_id_template, "$date$pseudo_rand";
 347         #print "new message id = $message_id\n"; # Was useful for debugging
 348 }
 349
 350
 351
 352 $cc = "";
 353 $time = time - scalar $#files;
 354
 355 sub send_message
 356 {
 357         my @recipients = unique_email_list(@to);
 358         my $to = join (",\n\t", @recipients);
 359         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 360         my $date = strftime('%a, %d %b %Y %H:%M:%S %z', localtime($time++));
 361         my $gitversion = '@@GIT_VERSION@@';
 362         if ($gitversion =~ m/..GIT_VERSION../) {
 363             $gitversion = `git --version`;
 364             chomp $gitversion;
 365             # keep only what's after the last space
 366             $gitversion =~ s/^.* //;
 367         }
 368
 369         my $header = "From: $from
 370 To: $to
 371 Cc: $cc
 372 Subject: $subject
 373 Reply-To: $from
 374 Date: $date
 375 Message-Id: $message_id
 376 X-Mailer: git-send-email $gitversion
 377 ";
 378         if ($reply_to) {
 379
 380                 $header .= "In-Reply-To: $reply_to\n";
 381                 $header .= "References: $references\n";
 382         }
 383
 384         if ($smtp_server =~ m#^/#) {
 385                 my $pid = open my $sm, '|-';
 386                 defined $pid or die $!;
 387                 if (!$pid) {
 388                         exec($smtp_server,'-i',
 389                              map { extract_valid_address($_) }
 390                              @recipients) or die $!;
 391                 }
 392                 print $sm "$header\n$message";
 393                 close $sm or die $?;
 394         } else {
 395                 require Net::SMTP;
 396                 $smtp ||= Net::SMTP->new( $smtp_server );
 397                 $smtp->mail( $from ) or die $smtp->message;
 398                 $smtp->to( @recipients ) or die $smtp->message;
 399                 $smtp->data or die $smtp->message;
 400                 $smtp->datasend("$header\n$message") or die $smtp->message;
 401                 $smtp->dataend() or die $smtp->message;
 402                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 403         }
 404         if ($quiet) {
 405                 printf "Sent %s\n", $subject;
 406         } else {
 407                 print "OK. Log says:\nDate: $date\n";
 408                 if ($smtp) {
 409                         print "Server: $smtp_server\n";
 410                 } else {
 411                         print "Sendmail: $smtp_server\n";
 412                 }
 413                 print "From: $from\nSubject: $subject\nCc: $cc\nTo: $to\n\n";
 414                 if ($smtp) {
 415                         print "Result: ", $smtp->code, ' ',
 416                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 417                 } else {
 418                         print "Result: OK\n";
 419                 }
 420         }
 421 }
 422
 423 $reply_to = $initial_reply_to;
 424 $references = $initial_reply_to || '';
 425 make_message_id();
 426 $subject = $initial_subject;
 427
 428 foreach my $t (@files) {
 429         open(F,"<",$t) or die "can't open file $t";
 430
 431         my $author_not_sender = undef;
 432         @cc = @initial_cc;
 433         my $found_mbox = 0;
 434         my $header_done = 0;
 435         $message = "";
 436         while(<F>) {
 437                 if (!$header_done) {
 438                         $found_mbox = 1, next if (/^From /);
 439                         chomp;
 440
 441                         if ($found_mbox) {
 442                                 if (/^Subject:\s+(.*)$/) {
 443                                         $subject = $1;
 444
 445                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 446                                         if ($2 eq $from) {
 447                                                 next if ($suppress_from);
 448                                         }
 449                                         else {
 450                                                 $author_not_sender = $2;
 451                                         }
 452                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 453                                                 $2, $_) unless $quiet;
 454                                         push @cc, $2;
 455                                 }
 456
 457                         } else {
 458                                 # In the traditional
 459                                 # "send lots of email" format,
 460                                 # line 1 = cc
 461                                 # line 2 = subject
 462                                 # So let's support that, too.
 463                                 if (@cc == 0) {
 464                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 465                                                 $_, $_) unless $quiet;
 466
 467                                         push @cc, $_;
 468
 469                                 } elsif (!defined $subject) {
 470                                         $subject = $_;
 471                                 }
 472                         }
 473
 474                         # A whitespace line will terminate the headers
 475                         if (m/^\s*$/) {
 476                                 $header_done = 1;
 477                         }
 478                 } else {
 479                         $message .=  $_;
 480                         if (/^Signed-off-by: (.*)$/i && !$no_signed_off_cc) {
 481                                 my $c = $1;
 482                                 chomp $c;
 483                                 push @cc, $c;
 484                                 printf("(sob) Adding cc: %s from line '%s'\n",
 485                                         $c, $_) unless $quiet;
 486                         }
 487                 }
 488         }
 489         close F;
 490         if (defined $author_not_sender) {
 491                 $message = "From: $author_not_sender\n\n$message";
 492         }
 493
 494         $cc = join(", ", unique_email_list(@cc));
 495
 496         send_message();
 497
 498         # set up for the next message
 499         if ($chain_reply_to || length($reply_to) == 0) {
 500                 $reply_to = $message_id;
 501                 if (length $references > 0) {
 502                         $references .= " $message_id";
 503                 } else {
 504                         $references = "$message_id";
 505                 }
 506         }
 507         make_message_id();
 508 }
 509
 510 if ($compose) {
 511         cleanup_compose_files();
 512 }
 513
 514 sub cleanup_compose_files() {
 515         unlink($compose_filename, $compose_filename . ".final");
 516
 517 }
 518
 519 $smtp->quit if $smtp;
 520
 521 sub unique_email_list(@) {
 522         my %seen;
 523         my @emails;
 524
 525         foreach my $entry (@_) {
 526                 if (my $clean = extract_valid_address($entry)) {
 527                         $seen{$clean} ||= 0;
 528                         next if $seen{$clean}++;
 529                         push @emails, $entry;
 530                 } else {
 531                         print STDERR "W: unable to extract a valid address",
 532                                         " from: $entry\n";
 533                 }
 534         }
 535         return @emails;
 536 }