git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision $_repository
   8                 $_q $_authors $_authors_prog %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22 $Git::SVN::_minimize_url = 'unset';
  23
  24 $Git::SVN::Log::TZ = $ENV{TZ};
  25 $ENV{TZ} = 'UTC';
  26 $| = 1; # unbuffer STDOUT
  27
  28 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  29 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  30 require SVN::Ra;
  31 require SVN::Delta;
  32 if ($SVN::Core::VERSION lt '1.1.0') {
  33         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  34 }
  35 my $can_compress = eval { require Compress::Zlib; 1};
  36 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  37 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  38 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  39 use Carp qw/croak/;
  40 use Digest::MD5;
  41 use IO::File qw//;
  42 use File::Basename qw/dirname basename/;
  43 use File::Path qw/mkpath/;
  44 use File::Spec;
  45 use File::Find;
  46 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  47 use IPC::Open3;
  48 use Git;
  49
  50 BEGIN {
  51         # import functions from Git into our packages, en masse
  52         no strict 'refs';
  53         foreach (qw/command command_oneline command_noisy command_output_pipe
  54                     command_input_pipe command_close_pipe
  55                     command_bidi_pipe command_close_bidi_pipe/) {
  56                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  57                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  58                         __PACKAGE__) {
  59                         *{"${package}::$_"} = \&{"Git::$_"};
  60                 }
  61         }
  62 }
  63
  64 my ($SVN);
  65
  66 $sha1 = qr/[a-f\d]{40}/;
  67 $sha1_short = qr/[a-f\d]{4,40}/;
  68 my ($_stdin, $_help, $_edit,
  69         $_message, $_file, $_branch_dest,
  70         $_template, $_shared,
  71         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
  72         $_merge, $_strategy, $_dry_run, $_local,
  73         $_prefix, $_no_checkout, $_url, $_verbose,
  74         $_git_format, $_commit_url, $_tag);
  75 $Git::SVN::_follow_parent = 1;
  76 $_q ||= 0;
  77 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  78                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  79                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  80                     'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
  81 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  82                 'authors-file|A=s' => \$_authors,
  83                 'authors-prog=s' => \$_authors_prog,
  84                 'repack:i' => \$Git::SVN::_repack,
  85                 'noMetadata' => \$Git::SVN::_no_metadata,
  86                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  87                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  88                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  89                 'no-checkout' => \$_no_checkout,
  90                 'quiet|q+' => \$_q,
  91                 'repack-flags|repack-args|repack-opts=s' =>
  92                    \$Git::SVN::_repack_flags,
  93                 'use-log-author' => \$Git::SVN::_use_log_author,
  94                 'add-author-from' => \$Git::SVN::_add_author_from,
  95                 'localtime' => \$Git::SVN::_localtime,
  96                 %remote_opts );
  97
  98 my ($_trunk, @_tags, @_branches, $_stdlayout);
  99 my %icv;
 100 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 101                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 102                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 103                   'stdlayout|s' => \$_stdlayout,
 104                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 105                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 106                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 107                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 108                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 109                   %remote_opts );
 110 my %cmt_opts = ( 'edit|e' => \$_edit,
 111                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 112                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 113                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 114                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 115 );
 116
 117 my %cmd = (
 118         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 119                         { 'revision|r=s' => \$_revision,
 120                           'fetch-all|all' => \$_fetch_all,
 121                           'parent|p' => \$_fetch_parent,
 122                            %fc_opts } ],
 123         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 124                         { 'revision|r=s' => \$_revision,
 125                            %fc_opts, %init_opts } ],
 126         init => [ \&cmd_init, "Initialize a repo for tracking" .
 127                           " (requires URL argument)",
 128                           \%init_opts ],
 129         'multi-init' => [ \&cmd_multi_init,
 130                           "Deprecated alias for ".
 131                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 132                           \%init_opts ],
 133         dcommit => [ \&cmd_dcommit,
 134                      'Commit several diffs to merge with upstream',
 135                         { 'merge|m|M' => \$_merge,
 136                           'strategy|s=s' => \$_strategy,
 137                           'verbose|v' => \$_verbose,
 138                           'dry-run|n' => \$_dry_run,
 139                           'fetch-all|all' => \$_fetch_all,
 140                           'commit-url=s' => \$_commit_url,
 141                           'revision|r=i' => \$_revision,
 142                           'no-rebase' => \$_no_rebase,
 143                         %cmt_opts, %fc_opts } ],
 144         branch => [ \&cmd_branch,
 145                     'Create a branch in the SVN repository',
 146                     { 'message|m=s' => \$_message,
 147                       'destination|d=s' => \$_branch_dest,
 148                       'dry-run|n' => \$_dry_run,
 149                       'tag|t' => \$_tag } ],
 150         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 151                  'Create a tag in the SVN repository',
 152                  { 'message|m=s' => \$_message,
 153                    'destination|d=s' => \$_branch_dest,
 154                    'dry-run|n' => \$_dry_run } ],
 155         'set-tree' => [ \&cmd_set_tree,
 156                         "Set an SVN repository to a git tree-ish",
 157                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 158         'create-ignore' => [ \&cmd_create_ignore,
 159                              'Create a .gitignore per svn:ignore',
 160                              { 'revision|r=i' => \$_revision
 161                              } ],
 162         'propget' => [ \&cmd_propget,
 163                        'Print the value of a property on a file or directory',
 164                        { 'revision|r=i' => \$_revision } ],
 165         'proplist' => [ \&cmd_proplist,
 166                        'List all properties of a file or directory',
 167                        { 'revision|r=i' => \$_revision } ],
 168         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 169                         { 'revision|r=i' => \$_revision
 170                         } ],
 171         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 172                         { 'revision|r=i' => \$_revision
 173                         } ],
 174         'multi-fetch' => [ \&cmd_multi_fetch,
 175                            "Deprecated alias for $0 fetch --all",
 176                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 177         'migrate' => [ sub { },
 178                        # no-op, we automatically run this anyways,
 179                        'Migrate configuration/metadata/layout from
 180                         previous versions of git-svn',
 181                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 182                          %remote_opts } ],
 183         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 184                         { 'limit=i' => \$Git::SVN::Log::limit,
 185                           'revision|r=s' => \$_revision,
 186                           'verbose|v' => \$Git::SVN::Log::verbose,
 187                           'incremental' => \$Git::SVN::Log::incremental,
 188                           'oneline' => \$Git::SVN::Log::oneline,
 189                           'show-commit' => \$Git::SVN::Log::show_commit,
 190                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 191                           'authors-file|A=s' => \$_authors,
 192                           'color' => \$Git::SVN::Log::color,
 193                           'pager=s' => \$Git::SVN::Log::pager
 194                         } ],
 195         'find-rev' => [ \&cmd_find_rev,
 196                         "Translate between SVN revision numbers and tree-ish",
 197                         {} ],
 198         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 199                         { 'merge|m|M' => \$_merge,
 200                           'verbose|v' => \$_verbose,
 201                           'strategy|s=s' => \$_strategy,
 202                           'local|l' => \$_local,
 203                           'fetch-all|all' => \$_fetch_all,
 204                           'dry-run|n' => \$_dry_run,
 205                           %fc_opts } ],
 206         'commit-diff' => [ \&cmd_commit_diff,
 207                            'Commit a diff between two trees',
 208                         { 'message|m=s' => \$_message,
 209                           'file|F=s' => \$_file,
 210                           'revision|r=s' => \$_revision,
 211                         %cmt_opts } ],
 212         'info' => [ \&cmd_info,
 213                     "Show info about the latest SVN revision
 214                      on the current branch",
 215                     { 'url' => \$_url, } ],
 216         'blame' => [ \&Git::SVN::Log::cmd_blame,
 217                     "Show what revision and author last modified each line of a file",
 218                     { 'git-format' => \$_git_format } ],
 219         'reset' => [ \&cmd_reset,
 220                      "Undo fetches back to the specified SVN revision",
 221                      { 'revision|r=s' => \$_revision,
 222                        'parent|p' => \$_fetch_parent } ],
 223         'gc' => [ \&cmd_gc,
 224                   "Compress unhandled.log files in .git/svn and remove " .
 225                   "index files in .git/svn",
 226                 {} ],
 227 );
 228
 229 my $cmd;
 230 for (my $i = 0; $i < @ARGV; $i++) {
 231         if (defined $cmd{$ARGV[$i]}) {
 232                 $cmd = $ARGV[$i];
 233                 splice @ARGV, $i, 1;
 234                 last;
 235         } elsif ($ARGV[$i] eq 'help') {
 236                 $cmd = $ARGV[$i+1];
 237                 usage(0);
 238         }
 239 };
 240
 241 # make sure we're always running at the top-level working directory
 242 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 243         unless (-d $ENV{GIT_DIR}) {
 244                 if ($git_dir_user_set) {
 245                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 246                             "but it is not a directory\n";
 247                 }
 248                 my $git_dir = delete $ENV{GIT_DIR};
 249                 my $cdup = undef;
 250                 git_cmd_try {
 251                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 252                         $git_dir = '.' unless ($cdup);
 253                         chomp $cdup if ($cdup);
 254                         $cdup = "." unless ($cdup && length $cdup);
 255                 } "Already at toplevel, but $git_dir not found\n";
 256                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 257                 unless (-d $git_dir) {
 258                         die "$git_dir still not found after going to ",
 259                             "'$cdup'\n";
 260                 }
 261                 $ENV{GIT_DIR} = $git_dir;
 262         }
 263         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 264 }
 265
 266 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 267
 268 read_repo_config(\%opts);
 269 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 270         Getopt::Long::Configure('pass_through');
 271 }
 272 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 273                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 274                     'id|i=s' => \$Git::SVN::default_ref_id,
 275                     'svn-remote|remote|R=s' => sub {
 276                        $Git::SVN::no_reuse_existing = 1;
 277                        $Git::SVN::default_repo_id = $_[1] });
 278 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 279
 280 usage(0) if $_help;
 281 version() if $_version;
 282 usage(1) unless defined $cmd;
 283 load_authors() if $_authors;
 284 if (defined $_authors_prog) {
 285         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 286 }
 287
 288 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 289         Git::SVN::Migration::migration_check();
 290 }
 291 Git::SVN::init_vars();
 292 eval {
 293         Git::SVN::verify_remotes_sanity();
 294         $cmd{$cmd}->[0]->(@ARGV);
 295 };
 296 fatal $@ if $@;
 297 post_fetch_checkout();
 298 exit 0;
 299
 300 ####################### primary functions ######################
 301 sub usage {
 302         my $exit = shift || 0;
 303         my $fd = $exit ? \*STDERR : \*STDOUT;
 304         print $fd <<"";
 305 git-svn - bidirectional operations between a single Subversion tree and git
 306 Usage: git svn <command> [options] [arguments]\n
 307
 308         print $fd "Available commands:\n" unless $cmd;
 309
 310         foreach (sort keys %cmd) {
 311                 next if $cmd && $cmd ne $_;
 312                 next if /^multi-/; # don't show deprecated commands
 313                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 314                 foreach (sort keys %{$cmd{$_}->[2]}) {
 315                         # mixed-case options are for .git/config only
 316                         next if /[A-Z]/ && /^[a-z]+$/i;
 317                         # prints out arguments as they should be passed:
 318                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 319                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 320                                                         "--$_" : "-$_" }
 321                                                 split /\|/,$_)," $x\n";
 322                 }
 323         }
 324         print $fd <<"";
 325 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 326 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 327 one git repository and want to keep them separate.  See git-svn(1) for more
 328 information.
 329
 330         exit $exit;
 331 }
 332
 333 sub version {
 334         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 335         exit 0;
 336 }
 337
 338 sub do_git_init_db {
 339         unless (-d $ENV{GIT_DIR}) {
 340                 my @init_db = ('init');
 341                 push @init_db, "--template=$_template" if defined $_template;
 342                 if (defined $_shared) {
 343                         if ($_shared =~ /[a-z]/) {
 344                                 push @init_db, "--shared=$_shared";
 345                         } else {
 346                                 push @init_db, "--shared";
 347                         }
 348                 }
 349                 command_noisy(@init_db);
 350                 $_repository = Git->repository(Repository => ".git");
 351         }
 352         command_noisy('config', 'core.autocrlf', 'false');
 353         my $set;
 354         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 355         foreach my $i (keys %icv) {
 356                 die "'$set' and '$i' cannot both be set\n" if $set;
 357                 next unless defined $icv{$i};
 358                 command_noisy('config', "$pfx.$i", $icv{$i});
 359                 $set = $i;
 360         }
 361         my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
 362         command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
 363                 if defined $$ignore_regex;
 364 }
 365
 366 sub init_subdir {
 367         my $repo_path = shift or return;
 368         mkpath([$repo_path]) unless -d $repo_path;
 369         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 370         $ENV{GIT_DIR} = '.git';
 371         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 372 }
 373
 374 sub cmd_clone {
 375         my ($url, $path) = @_;
 376         if (!defined $path &&
 377             (defined $_trunk || @_branches || @_tags ||
 378              defined $_stdlayout) &&
 379             $url !~ m#^[a-z\+]+://#) {
 380                 $path = $url;
 381         }
 382         $path = basename($url) if !defined $path || !length $path;
 383         cmd_init($url, $path);
 384         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 385         command_oneline('config', 'svn.authorsfile', $_authors) if $_authors;
 386 }
 387
 388 sub cmd_init {
 389         if (defined $_stdlayout) {
 390                 $_trunk = 'trunk' if (!defined $_trunk);
 391                 @_tags = 'tags' if (! @_tags);
 392                 @_branches = 'branches' if (! @_branches);
 393         }
 394         if (defined $_trunk || @_branches || @_tags) {
 395                 return cmd_multi_init(@_);
 396         }
 397         my $url = shift or die "SVN repository location required ",
 398                                "as a command-line argument\n";
 399         $url = canonicalize_url($url);
 400         init_subdir(@_);
 401         do_git_init_db();
 402
 403         if ($Git::SVN::_minimize_url eq 'unset') {
 404                 $Git::SVN::_minimize_url = 0;
 405         }
 406
 407         Git::SVN->init($url);
 408 }
 409
 410 sub cmd_fetch {
 411         if (grep /^\d+=./, @_) {
 412                 die "'<rev>=<commit>' fetch arguments are ",
 413                     "no longer supported.\n";
 414         }
 415         my ($remote) = @_;
 416         if (@_ > 1) {
 417                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 418         }
 419         if ($_fetch_parent) {
 420                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 421                 unless ($gs) {
 422                         die "Unable to determine upstream SVN information from ",
 423                             "working tree history\n";
 424                 }
 425                 # just fetch, don't checkout.
 426                 $_no_checkout = 'true';
 427                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 428         } elsif ($_fetch_all) {
 429                 cmd_multi_fetch();
 430         } else {
 431                 $remote ||= $Git::SVN::default_repo_id;
 432                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 433         }
 434 }
 435
 436 sub cmd_set_tree {
 437         my (@commits) = @_;
 438         if ($_stdin || !@commits) {
 439                 print "Reading from stdin...\n";
 440                 @commits = ();
 441                 while (<STDIN>) {
 442                         if (/\b($sha1_short)\b/o) {
 443                                 unshift @commits, $1;
 444                         }
 445                 }
 446         }
 447         my @revs;
 448         foreach my $c (@commits) {
 449                 my @tmp = command('rev-parse',$c);
 450                 if (scalar @tmp == 1) {
 451                         push @revs, $tmp[0];
 452                 } elsif (scalar @tmp > 1) {
 453                         push @revs, reverse(command('rev-list',@tmp));
 454                 } else {
 455                         fatal "Failed to rev-parse $c";
 456                 }
 457         }
 458         my $gs = Git::SVN->new;
 459         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 460         $gs->fetch;
 461         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 462                 fatal "There are new revisions that were fetched ",
 463                       "and need to be merged (or acknowledged) ",
 464                       "before committing.\nlast rev: $r_last\n",
 465                       " current: $gs->{last_rev}";
 466         }
 467         $gs->set_tree($_) foreach @revs;
 468         print "Done committing ",scalar @revs," revisions to SVN\n";
 469         unlink $gs->{index};
 470 }
 471
 472 sub cmd_dcommit {
 473         my $head = shift;
 474         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 475                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 476                 . "or stash them with `git stash'.\n";
 477         $head ||= 'HEAD';
 478
 479         my $old_head;
 480         if ($head ne 'HEAD') {
 481                 $old_head = eval {
 482                         command_oneline([qw/symbolic-ref -q HEAD/])
 483                 };
 484                 if ($old_head) {
 485                         $old_head =~ s{^refs/heads/}{};
 486                 } else {
 487                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 488                 }
 489                 command(['checkout', $head], STDERR => 0);
 490         }
 491
 492         my @refs;
 493         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 494         unless ($gs) {
 495                 die "Unable to determine upstream SVN information from ",
 496                     "$head history.\nPerhaps the repository is empty.";
 497         }
 498
 499         if (defined $_commit_url) {
 500                 $url = $_commit_url;
 501         } else {
 502                 $url = eval { command_oneline('config', '--get',
 503                               "svn-remote.$gs->{repo_id}.commiturl") };
 504                 if (!$url) {
 505                         $url = $gs->full_url
 506                 }
 507         }
 508
 509         my $last_rev = $_revision if defined $_revision;
 510         if ($url) {
 511                 print "Committing to $url ...\n";
 512         }
 513         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 514         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 515                 warn "Attempting to commit more than one change while ",
 516                      "--no-rebase is enabled.\n",
 517                      "If these changes depend on each other, re-running ",
 518                      "without --no-rebase may be required."
 519         }
 520         my $expect_url = $url;
 521         Git::SVN::remove_username($expect_url);
 522         while (1) {
 523                 my $d = shift @$linear_refs or last;
 524                 unless (defined $last_rev) {
 525                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 526                         unless (defined $last_rev) {
 527                                 fatal "Unable to extract revision information ",
 528                                       "from commit $d~1";
 529                         }
 530                 }
 531                 if ($_dry_run) {
 532                         print "diff-tree $d~1 $d\n";
 533                 } else {
 534                         my $cmt_rev;
 535                         my %ed_opts = ( r => $last_rev,
 536                                         log => get_commit_entry($d)->{log},
 537                                         ra => Git::SVN::Ra->new($url),
 538                                         config => SVN::Core::config_get_config(
 539                                                 $Git::SVN::Ra::config_dir
 540                                         ),
 541                                         tree_a => "$d~1",
 542                                         tree_b => $d,
 543                                         editor_cb => sub {
 544                                                print "Committed r$_[0]\n";
 545                                                $cmt_rev = $_[0];
 546                                         },
 547                                         svn_path => '');
 548                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 549                                 print "No changes\n$d~1 == $d\n";
 550                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 551                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 552                                                                $parents->{$d};
 553                         }
 554                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 555                         $last_rev = $cmt_rev;
 556                         next if $_no_rebase;
 557
 558                         # we always want to rebase against the current HEAD,
 559                         # not any head that was passed to us
 560                         my @diff = command('diff-tree', $d,
 561                                            $gs->refname, '--');
 562                         my @finish;
 563                         if (@diff) {
 564                                 @finish = rebase_cmd();
 565                                 print STDERR "W: $d and ", $gs->refname,
 566                                              " differ, using @finish:\n",
 567                                              join("\n", @diff), "\n";
 568                         } else {
 569                                 print "No changes between current HEAD and ",
 570                                       $gs->refname,
 571                                       "\nResetting to the latest ",
 572                                       $gs->refname, "\n";
 573                                 @finish = qw/reset --mixed/;
 574                         }
 575                         command_noisy(@finish, $gs->refname);
 576                         if (@diff) {
 577                                 @refs = ();
 578                                 my ($url_, $rev_, $uuid_, $gs_) =
 579                                               working_head_info('HEAD', \@refs);
 580                                 my ($linear_refs_, $parents_) =
 581                                               linearize_history($gs_, \@refs);
 582                                 if (scalar(@$linear_refs) !=
 583                                     scalar(@$linear_refs_)) {
 584                                         fatal "# of revisions changed ",
 585                                           "\nbefore:\n",
 586                                           join("\n", @$linear_refs),
 587                                           "\n\nafter:\n",
 588                                           join("\n", @$linear_refs_), "\n",
 589                                           'If you are attempting to commit ',
 590                                           "merges, try running:\n\t",
 591                                           'git rebase --interactive',
 592                                           '--preserve-merges ',
 593                                           $gs->refname,
 594                                           "\nBefore dcommitting";
 595                                 }
 596                                 if ($url_ ne $expect_url) {
 597                                         fatal "URL mismatch after rebase: ",
 598                                               "$url_ != $expect_url";
 599                                 }
 600                                 if ($uuid_ ne $uuid) {
 601                                         fatal "uuid mismatch after rebase: ",
 602                                               "$uuid_ != $uuid";
 603                                 }
 604                                 # remap parents
 605                                 my (%p, @l, $i);
 606                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 607                                         my $new = $linear_refs_->[$i] or next;
 608                                         $p{$new} =
 609                                                 $parents->{$linear_refs->[$i]};
 610                                         push @l, $new;
 611                                 }
 612                                 $parents = \%p;
 613                                 $linear_refs = \@l;
 614                         }
 615                 }
 616         }
 617
 618         if ($old_head) {
 619                 my $new_head = command_oneline(qw/rev-parse HEAD/);
 620                 my $new_is_symbolic = eval {
 621                         command_oneline(qw/symbolic-ref -q HEAD/);
 622                 };
 623                 if ($new_is_symbolic) {
 624                         print "dcommitted the branch ", $head, "\n";
 625                 } else {
 626                         print "dcommitted on a detached HEAD because you gave ",
 627                               "a revision argument.\n",
 628                               "The rewritten commit is: ", $new_head, "\n";
 629                 }
 630                 command(['checkout', $old_head], STDERR => 0);
 631         }
 632
 633         unlink $gs->{index};
 634 }
 635
 636 sub cmd_branch {
 637         my ($branch_name, $head) = @_;
 638
 639         unless (defined $branch_name && length $branch_name) {
 640                 die(($_tag ? "tag" : "branch") . " name required\n");
 641         }
 642         $head ||= 'HEAD';
 643
 644         my ($src, $rev, undef, $gs) = working_head_info($head);
 645
 646         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 647         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
 648         my $glob;
 649         if ($#{$allglobs} == 0) {
 650                 $glob = $allglobs->[0];
 651         } else {
 652                 unless(defined $_branch_dest) {
 653                         die "Multiple ",
 654                             $_tag ? "tag" : "branch",
 655                             " paths defined for Subversion repository.\n",
 656                             "You must specify where you want to create the ",
 657                             $_tag ? "tag" : "branch",
 658                             " with the --destination argument.\n";
 659                 }
 660                 foreach my $g (@{$allglobs}) {
 661                         # SVN::Git::Editor could probably be moved to Git.pm..
 662                         my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
 663                         if ($_branch_dest =~ /$re/) {
 664                                 $glob = $g;
 665                                 last;
 666                         }
 667                 }
 668                 unless (defined $glob) {
 669                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
 670                         foreach my $g (@{$allglobs}) {
 671                                 $g->{path}->{left} =~ /$dest_re/ or next;
 672                                 if (defined $glob) {
 673                                         die "Ambiguous destination: ",
 674                                             $_branch_dest, "\nmatches both '",
 675                                             $glob->{path}->{left}, "' and '",
 676                                             $g->{path}->{left}, "'\n";
 677                                 }
 678                                 $glob = $g;
 679                         }
 680                         unless (defined $glob) {
 681                                 die "Unknown ",
 682                                     $_tag ? "tag" : "branch",
 683                                     " destination $_branch_dest\n";
 684                         }
 685                 }
 686         }
 687         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 688         my $dst = join '/', $remote->{url}, $lft, $branch_name, ($rgt || ());
 689
 690         my $ctx = SVN::Client->new(
 691                 auth    => Git::SVN::Ra::_auth_providers(),
 692                 log_msg => sub {
 693                         ${ $_[0] } = defined $_message
 694                                 ? $_message
 695                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 696                                 . $branch_name;
 697                 },
 698         );
 699
 700         eval {
 701                 $ctx->ls($dst, 'HEAD', 0);
 702         } and die "branch ${branch_name} already exists\n";
 703
 704         print "Copying ${src} at r${rev} to ${dst}...\n";
 705         $ctx->copy($src, $rev, $dst)
 706                 unless $_dry_run;
 707
 708         $gs->fetch_all;
 709 }
 710
 711 sub cmd_find_rev {
 712         my $revision_or_hash = shift or die "SVN or git revision required ",
 713                                             "as a command-line argument\n";
 714         my $result;
 715         if ($revision_or_hash =~ /^r\d+$/) {
 716                 my $head = shift;
 717                 $head ||= 'HEAD';
 718                 my @refs;
 719                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 720                 unless ($gs) {
 721                         die "Unable to determine upstream SVN information from ",
 722                             "$head history\n";
 723                 }
 724                 my $desired_revision = substr($revision_or_hash, 1);
 725                 $result = $gs->rev_map_get($desired_revision, $uuid);
 726         } else {
 727                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 728                 $result = $rev;
 729         }
 730         print "$result\n" if $result;
 731 }
 732
 733 sub cmd_rebase {
 734         command_noisy(qw/update-index --refresh/);
 735         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 736         unless ($gs) {
 737                 die "Unable to determine upstream SVN information from ",
 738                     "working tree history\n";
 739         }
 740         if ($_dry_run) {
 741                 print "Remote Branch: " . $gs->refname . "\n";
 742                 print "SVN URL: " . $url . "\n";
 743                 return;
 744         }
 745         if (command(qw/diff-index HEAD --/)) {
 746                 print STDERR "Cannot rebase with uncommited changes:\n";
 747                 command_noisy('status');
 748                 exit 1;
 749         }
 750         unless ($_local) {
 751                 # rebase will checkout for us, so no need to do it explicitly
 752                 $_no_checkout = 'true';
 753                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 754         }
 755         command_noisy(rebase_cmd(), $gs->refname);
 756 }
 757
 758 sub cmd_show_ignore {
 759         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 760         $gs ||= Git::SVN->new;
 761         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 762         $gs->prop_walk($gs->{path}, $r, sub {
 763                 my ($gs, $path, $props) = @_;
 764                 print STDOUT "\n# $path\n";
 765                 my $s = $props->{'svn:ignore'} or return;
 766                 $s =~ s/[\r\n]+/\n/g;
 767                 $s =~ s/^\n+//;
 768                 chomp $s;
 769                 $s =~ s#^#$path#gm;
 770                 print STDOUT "$s\n";
 771         });
 772 }
 773
 774 sub cmd_show_externals {
 775         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 776         $gs ||= Git::SVN->new;
 777         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 778         $gs->prop_walk($gs->{path}, $r, sub {
 779                 my ($gs, $path, $props) = @_;
 780                 print STDOUT "\n# $path\n";
 781                 my $s = $props->{'svn:externals'} or return;
 782                 $s =~ s/[\r\n]+/\n/g;
 783                 chomp $s;
 784                 $s =~ s#^#$path#gm;
 785                 print STDOUT "$s\n";
 786         });
 787 }
 788
 789 sub cmd_create_ignore {
 790         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 791         $gs ||= Git::SVN->new;
 792         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 793         $gs->prop_walk($gs->{path}, $r, sub {
 794                 my ($gs, $path, $props) = @_;
 795                 # $path is of the form /path/to/dir/
 796                 $path = '.' . $path;
 797                 # SVN can have attributes on empty directories,
 798                 # which git won't track
 799                 mkpath([$path]) unless -d $path;
 800                 my $ignore = $path . '.gitignore';
 801                 my $s = $props->{'svn:ignore'} or return;
 802                 open(GITIGNORE, '>', $ignore)
 803                   or fatal("Failed to open `$ignore' for writing: $!");
 804                 $s =~ s/[\r\n]+/\n/g;
 805                 $s =~ s/^\n+//;
 806                 chomp $s;
 807                 # Prefix all patterns so that the ignore doesn't apply
 808                 # to sub-directories.
 809                 $s =~ s#^#/#gm;
 810                 print GITIGNORE "$s\n";
 811                 close(GITIGNORE)
 812                   or fatal("Failed to close `$ignore': $!");
 813                 command_noisy('add', '-f', $ignore);
 814         });
 815 }
 816
 817 sub canonicalize_path {
 818         my ($path) = @_;
 819         my $dot_slash_added = 0;
 820         if (substr($path, 0, 1) ne "/") {
 821                 $path = "./" . $path;
 822                 $dot_slash_added = 1;
 823         }
 824         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 825         # good reason), so let's do this manually.
 826         $path =~ s#/+#/#g;
 827         $path =~ s#/\.(?:/|$)#/#g;
 828         $path =~ s#/[^/]+/\.\.##g;
 829         $path =~ s#/$##g;
 830         $path =~ s#^\./## if $dot_slash_added;
 831         $path =~ s#^/##;
 832         $path =~ s#^\.$##;
 833         return $path;
 834 }
 835
 836 sub canonicalize_url {
 837         my ($url) = @_;
 838         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 839         return $url;
 840 }
 841
 842 # get_svnprops(PATH)
 843 # ------------------
 844 # Helper for cmd_propget and cmd_proplist below.
 845 sub get_svnprops {
 846         my $path = shift;
 847         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 848         $gs ||= Git::SVN->new;
 849
 850         # prefix THE PATH by the sub-directory from which the user
 851         # invoked us.
 852         $path = $cmd_dir_prefix . $path;
 853         fatal("No such file or directory: $path") unless -e $path;
 854         my $is_dir = -d $path ? 1 : 0;
 855         $path = $gs->{path} . '/' . $path;
 856
 857         # canonicalize the path (otherwise libsvn will abort or fail to
 858         # find the file)
 859         $path = canonicalize_path($path);
 860
 861         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 862         my $props;
 863         if ($is_dir) {
 864                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 865         }
 866         else {
 867                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 868         }
 869         return $props;
 870 }
 871
 872 # cmd_propget (PROP, PATH)
 873 # ------------------------
 874 # Print the SVN property PROP for PATH.
 875 sub cmd_propget {
 876         my ($prop, $path) = @_;
 877         $path = '.' if not defined $path;
 878         usage(1) if not defined $prop;
 879         my $props = get_svnprops($path);
 880         if (not defined $props->{$prop}) {
 881                 fatal("`$path' does not have a `$prop' SVN property.");
 882         }
 883         print $props->{$prop} . "\n";
 884 }
 885
 886 # cmd_proplist (PATH)
 887 # -------------------
 888 # Print the list of SVN properties for PATH.
 889 sub cmd_proplist {
 890         my $path = shift;
 891         $path = '.' if not defined $path;
 892         my $props = get_svnprops($path);
 893         print "Properties on '$path':\n";
 894         foreach (sort keys %{$props}) {
 895                 print "  $_\n";
 896         }
 897 }
 898
 899 sub cmd_multi_init {
 900         my $url = shift;
 901         unless (defined $_trunk || @_branches || @_tags) {
 902                 usage(1);
 903         }
 904
 905         $_prefix = '' unless defined $_prefix;
 906         if (defined $url) {
 907                 $url = canonicalize_url($url);
 908                 init_subdir(@_);
 909         }
 910         do_git_init_db();
 911         if (defined $_trunk) {
 912                 my $trunk_ref = $_prefix . 'trunk';
 913                 # try both old-style and new-style lookups:
 914                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 915                 unless ($gs_trunk) {
 916                         my ($trunk_url, $trunk_path) =
 917                                               complete_svn_url($url, $_trunk);
 918                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 919                                                    undef, $trunk_ref);
 920                 }
 921         }
 922         return unless @_branches || @_tags;
 923         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 924         foreach my $path (@_branches) {
 925                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
 926         }
 927         foreach my $path (@_tags) {
 928                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
 929         }
 930 }
 931
 932 sub cmd_multi_fetch {
 933         my $remotes = Git::SVN::read_all_remotes();
 934         foreach my $repo_id (sort keys %$remotes) {
 935                 if ($remotes->{$repo_id}->{url}) {
 936                         Git::SVN::fetch_all($repo_id, $remotes);
 937                 }
 938         }
 939 }
 940
 941 # this command is special because it requires no metadata
 942 sub cmd_commit_diff {
 943         my ($ta, $tb, $url) = @_;
 944         my $usage = "Usage: $0 commit-diff -r<revision> ".
 945                     "<tree-ish> <tree-ish> [<URL>]";
 946         fatal($usage) if (!defined $ta || !defined $tb);
 947         my $svn_path = '';
 948         if (!defined $url) {
 949                 my $gs = eval { Git::SVN->new };
 950                 if (!$gs) {
 951                         fatal("Needed URL or usable git-svn --id in ",
 952                               "the command-line\n", $usage);
 953                 }
 954                 $url = $gs->{url};
 955                 $svn_path = $gs->{path};
 956         }
 957         unless (defined $_revision) {
 958                 fatal("-r|--revision is a required argument\n", $usage);
 959         }
 960         if (defined $_message && defined $_file) {
 961                 fatal("Both --message/-m and --file/-F specified ",
 962                       "for the commit message.\n",
 963                       "I have no idea what you mean");
 964         }
 965         if (defined $_file) {
 966                 $_message = file_to_s($_file);
 967         } else {
 968                 $_message ||= get_commit_entry($tb)->{log};
 969         }
 970         my $ra ||= Git::SVN::Ra->new($url);
 971         my $r = $_revision;
 972         if ($r eq 'HEAD') {
 973                 $r = $ra->get_latest_revnum;
 974         } elsif ($r !~ /^\d+$/) {
 975                 die "revision argument: $r not understood by git-svn\n";
 976         }
 977         my %ed_opts = ( r => $r,
 978                         log => $_message,
 979                         ra => $ra,
 980                         tree_a => $ta,
 981                         tree_b => $tb,
 982                         editor_cb => sub { print "Committed r$_[0]\n" },
 983                         svn_path => $svn_path );
 984         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 985                 print "No changes\n$ta == $tb\n";
 986         }
 987 }
 988
 989 sub escape_uri_only {
 990         my ($uri) = @_;
 991         my @tmp;
 992         foreach (split m{/}, $uri) {
 993                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
 994                 push @tmp, $_;
 995         }
 996         join('/', @tmp);
 997 }
 998
 999 sub escape_url {
1000         my ($url) = @_;
1001         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1002                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1003                 $url = "$scheme://$domain$uri";
1004         }
1005         $url;
1006 }
1007
1008 sub cmd_info {
1009         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1010         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1011         if (exists $_[1]) {
1012                 die "Too many arguments specified\n";
1013         }
1014
1015         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1016
1017         if (!$file_type && !$diff_status) {
1018                 print STDERR "svn: '$path' is not under version control\n";
1019                 exit 1;
1020         }
1021
1022         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1023         unless ($gs) {
1024                 die "Unable to determine upstream SVN information from ",
1025                     "working tree history\n";
1026         }
1027
1028         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1029         $path = "." if $path eq "";
1030
1031         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1032
1033         if ($_url) {
1034                 print escape_url($full_url), "\n";
1035                 return;
1036         }
1037
1038         my $result = "Path: $path\n";
1039         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1040         $result .= "URL: " . escape_url($full_url) . "\n";
1041
1042         eval {
1043                 my $repos_root = $gs->repos_root;
1044                 Git::SVN::remove_username($repos_root);
1045                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1046         };
1047         if ($@) {
1048                 $result .= "Repository Root: (offline)\n";
1049         }
1050         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1051                 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1052         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1053
1054         $result .= "Node Kind: " .
1055                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1056
1057         my $schedule = $diff_status eq "A"
1058                        ? "add"
1059                        : ($diff_status eq "D" ? "delete" : "normal");
1060         $result .= "Schedule: $schedule\n";
1061
1062         if ($diff_status eq "A") {
1063                 print $result, "\n";
1064                 return;
1065         }
1066
1067         my ($lc_author, $lc_rev, $lc_date_utc);
1068         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1069         my $log = command_output_pipe(@args);
1070         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1071         while (<$log>) {
1072                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1073                         $lc_author = $1;
1074                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1075                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1076                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1077                 }
1078         }
1079         close $log;
1080
1081         Git::SVN::Log::set_local_timezone();
1082
1083         $result .= "Last Changed Author: $lc_author\n";
1084         $result .= "Last Changed Rev: $lc_rev\n";
1085         $result .= "Last Changed Date: " .
1086                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1087
1088         if ($file_type ne "dir") {
1089                 my $text_last_updated_date =
1090                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1091                 $result .=
1092                     "Text Last Updated: " .
1093                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1094                     "\n";
1095                 my $checksum;
1096                 if ($diff_status eq "D") {
1097                         my ($fh, $ctx) =
1098                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1099                         if ($file_type eq "link") {
1100                                 my $file_name = <$fh>;
1101                                 $checksum = md5sum("link $file_name");
1102                         } else {
1103                                 $checksum = md5sum($fh);
1104                         }
1105                         command_close_pipe($fh, $ctx);
1106                 } elsif ($file_type eq "link") {
1107                         my $file_name =
1108                             command(qw(cat-file blob), "HEAD:$path");
1109                         $checksum =
1110                             md5sum("link " . $file_name);
1111                 } else {
1112                         open FILE, "<", $path or die $!;
1113                         $checksum = md5sum(\*FILE);
1114                         close FILE or die $!;
1115                 }
1116                 $result .= "Checksum: " . $checksum . "\n";
1117         }
1118
1119         print $result, "\n";
1120 }
1121
1122 sub cmd_reset {
1123         my $target = shift || $_revision or die "SVN revision required\n";
1124         $target = $1 if $target =~ /^r(\d+)$/;
1125         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1126         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1127         unless ($gs) {
1128                 die "Unable to determine upstream SVN information from ".
1129                     "history\n";
1130         }
1131         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1132         $gs->rev_map_set($r, $c, 'reset', $uuid);
1133         print "r$r = $c ($gs->{ref_id})\n";
1134 }
1135
1136 sub cmd_gc {
1137         if (!$can_compress) {
1138                 warn "Compress::Zlib could not be found; unhandled.log " .
1139                      "files will not be compressed.\n";
1140         }
1141         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1142 }
1143
1144 ########################### utility functions #########################
1145
1146 sub rebase_cmd {
1147         my @cmd = qw/rebase/;
1148         push @cmd, '-v' if $_verbose;
1149         push @cmd, qw/--merge/ if $_merge;
1150         push @cmd, "--strategy=$_strategy" if $_strategy;
1151         @cmd;
1152 }
1153
1154 sub post_fetch_checkout {
1155         return if $_no_checkout;
1156         my $gs = $Git::SVN::_head or return;
1157         return if verify_ref('refs/heads/master^0');
1158
1159         # look for "trunk" ref if it exists
1160         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1161         my $fetch = $remote->{fetch};
1162         if ($fetch) {
1163                 foreach my $p (keys %$fetch) {
1164                         basename($fetch->{$p}) eq 'trunk' or next;
1165                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1166                         last;
1167                 }
1168         }
1169
1170         my $valid_head = verify_ref('HEAD^0');
1171         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1172         return if ($valid_head || !verify_ref('HEAD^0'));
1173
1174         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1175         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1176         return if -f $index;
1177
1178         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1179         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1180         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1181         print STDERR "Checked out HEAD:\n  ",
1182                      $gs->full_url, " r", $gs->last_rev, "\n";
1183 }
1184
1185 sub complete_svn_url {
1186         my ($url, $path) = @_;
1187         $path =~ s#/+$##;
1188         if ($path !~ m#^[a-z\+]+://#) {
1189                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1190                         fatal("E: '$path' is not a complete URL ",
1191                               "and a separate URL is not specified");
1192                 }
1193                 return ($url, $path);
1194         }
1195         return ($path, '');
1196 }
1197
1198 sub complete_url_ls_init {
1199         my ($ra, $repo_path, $switch, $pfx) = @_;
1200         unless ($repo_path) {
1201                 print STDERR "W: $switch not specified\n";
1202                 return;
1203         }
1204         $repo_path =~ s#/+$##;
1205         if ($repo_path =~ m#^[a-z\+]+://#) {
1206                 $ra = Git::SVN::Ra->new($repo_path);
1207                 $repo_path = '';
1208         } else {
1209                 $repo_path =~ s#^/+##;
1210                 unless ($ra) {
1211                         fatal("E: '$repo_path' is not a complete URL ",
1212                               "and a separate URL is not specified");
1213                 }
1214         }
1215         my $url = $ra->{url};
1216         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1217         my $k = "svn-remote.$gs->{repo_id}.url";
1218         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1219         if ($orig_url && ($orig_url ne $gs->{url})) {
1220                 die "$k already set: $orig_url\n",
1221                     "wanted to set to: $gs->{url}\n";
1222         }
1223         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1224         my $remote_path = "$gs->{path}/$repo_path";
1225         $remote_path =~ s#/+#/#g;
1226         $remote_path =~ s#^/##g;
1227         $remote_path .= "/*" if $remote_path !~ /\*/;
1228         my ($n) = ($switch =~ /^--(\w+)/);
1229         if (length $pfx && $pfx !~ m#/$#) {
1230                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1231         }
1232         command_noisy('config',
1233                       '--add',
1234                       "svn-remote.$gs->{repo_id}.$n",
1235                       "$remote_path:refs/remotes/$pfx*" .
1236                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1237 }
1238
1239 sub verify_ref {
1240         my ($ref) = @_;
1241         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1242                                { STDERR => 0 }); };
1243 }
1244
1245 sub get_tree_from_treeish {
1246         my ($treeish) = @_;
1247         # $treeish can be a symbolic ref, too:
1248         my $type = command_oneline(qw/cat-file -t/, $treeish);
1249         my $expected;
1250         while ($type eq 'tag') {
1251                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1252         }
1253         if ($type eq 'commit') {
1254                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1255                                                     $treeish))[0];
1256                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1257                 die "Unable to get tree from $treeish\n" unless $expected;
1258         } elsif ($type eq 'tree') {
1259                 $expected = $treeish;
1260         } else {
1261                 die "$treeish is a $type, expected tree, tag or commit\n";
1262         }
1263         return $expected;
1264 }
1265
1266 sub get_commit_entry {
1267         my ($treeish) = shift;
1268         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1269         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1270         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1271         open my $log_fh, '>', $commit_editmsg or croak $!;
1272
1273         my $type = command_oneline(qw/cat-file -t/, $treeish);
1274         if ($type eq 'commit' || $type eq 'tag') {
1275                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1276                                                          $type, $treeish);
1277                 my $in_msg = 0;
1278                 my $author;
1279                 my $saw_from = 0;
1280                 my $msgbuf = "";
1281                 while (<$msg_fh>) {
1282                         if (!$in_msg) {
1283                                 $in_msg = 1 if (/^\s*$/);
1284                                 $author = $1 if (/^author (.*>)/);
1285                         } elsif (/^git-svn-id: /) {
1286                                 # skip this for now, we regenerate the
1287                                 # correct one on re-fetch anyways
1288                                 # TODO: set *:merge properties or like...
1289                         } else {
1290                                 if (/^From:/ || /^Signed-off-by:/) {
1291                                         $saw_from = 1;
1292                                 }
1293                                 $msgbuf .= $_;
1294                         }
1295                 }
1296                 $msgbuf =~ s/\s+$//s;
1297                 if ($Git::SVN::_add_author_from && defined($author)
1298                     && !$saw_from) {
1299                         $msgbuf .= "\n\nFrom: $author";
1300                 }
1301                 print $log_fh $msgbuf or croak $!;
1302                 command_close_pipe($msg_fh, $ctx);
1303         }
1304         close $log_fh or croak $!;
1305
1306         if ($_edit || ($type eq 'tree')) {
1307                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1308                 # TODO: strip out spaces, comments, like git-commit.sh
1309                 system($editor, $commit_editmsg);
1310         }
1311         rename $commit_editmsg, $commit_msg or croak $!;
1312         {
1313                 require Encode;
1314                 # SVN requires messages to be UTF-8 when entering the repo
1315                 local $/;
1316                 open $log_fh, '<', $commit_msg or croak $!;
1317                 binmode $log_fh;
1318                 chomp($log_entry{log} = <$log_fh>);
1319
1320                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1321                 my $msg = $log_entry{log};
1322
1323                 eval { $msg = Encode::decode($enc, $msg, 1) };
1324                 if ($@) {
1325                         die "Could not decode as $enc:\n", $msg,
1326                             "\nPerhaps you need to set i18n.commitencoding\n";
1327                 }
1328
1329                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1330                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1331
1332                 $log_entry{log} = $msg;
1333
1334                 close $log_fh or croak $!;
1335         }
1336         unlink $commit_msg;
1337         \%log_entry;
1338 }
1339
1340 sub s_to_file {
1341         my ($str, $file, $mode) = @_;
1342         open my $fd,'>',$file or croak $!;
1343         print $fd $str,"\n" or croak $!;
1344         close $fd or croak $!;
1345         chmod ($mode &~ umask, $file) if (defined $mode);
1346 }
1347
1348 sub file_to_s {
1349         my $file = shift;
1350         open my $fd,'<',$file or croak "$!: file: $file\n";
1351         local $/;
1352         my $ret = <$fd>;
1353         close $fd or croak $!;
1354         $ret =~ s/\s*$//s;
1355         return $ret;
1356 }
1357
1358 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1359 sub load_authors {
1360         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1361         my $log = $cmd eq 'log';
1362         while (<$authors>) {
1363                 chomp;
1364                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1365                 my ($user, $name, $email) = ($1, $2, $3);
1366                 if ($log) {
1367                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1368                 } else {
1369                         $users{$user} = [$name, $email];
1370                 }
1371         }
1372         close $authors or croak $!;
1373 }
1374
1375 # convert GetOpt::Long specs for use by git-config
1376 sub read_repo_config {
1377         return unless -d $ENV{GIT_DIR};
1378         my $opts = shift;
1379         my @config_only;
1380         foreach my $o (keys %$opts) {
1381                 # if we have mixedCase and a long option-only, then
1382                 # it's a config-only variable that we don't need for
1383                 # the command-line.
1384                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1385                 my $v = $opts->{$o};
1386                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1387                 $key =~ s/-//g;
1388                 my $arg = 'git config';
1389                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1390                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1391                 if (ref $v eq 'ARRAY') {
1392                         chomp(my @tmp = `$arg --get-all svn.$key`);
1393                         @$v = @tmp if @tmp;
1394                 } else {
1395                         chomp(my $tmp = `$arg --get svn.$key`);
1396                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1397                                 $$v = $tmp;
1398                         }
1399                 }
1400         }
1401         delete @$opts{@config_only} if @config_only;
1402 }
1403
1404 sub extract_metadata {
1405         my $id = shift or return (undef, undef, undef);
1406         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1407                                                         \s([a-f\d\-]+)$/ix);
1408         if (!defined $rev || !$uuid || !$url) {
1409                 # some of the original repositories I made had
1410                 # identifiers like this:
1411                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1412         }
1413         return ($url, $rev, $uuid);
1414 }
1415
1416 sub cmt_metadata {
1417         return extract_metadata((grep(/^git-svn-id: /,
1418                 command(qw/cat-file commit/, shift)))[-1]);
1419 }
1420
1421 sub cmt_sha2rev_batch {
1422         my %s2r;
1423         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1424         my $list = shift;
1425
1426         foreach my $sha (@{$list}) {
1427                 my $first = 1;
1428                 my $size = 0;
1429                 print $out $sha, "\n";
1430
1431                 while (my $line = <$in>) {
1432                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1433                                 last;
1434                         } elsif ($first &&
1435                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1436                                 $first = 0;
1437                                 $size = $1;
1438                                 next;
1439                         } elsif ($line =~ /^(git-svn-id: )/) {
1440                                 my (undef, $rev, undef) =
1441                                                       extract_metadata($line);
1442                                 $s2r{$sha} = $rev;
1443                         }
1444
1445                         $size -= length($line);
1446                         last if ($size == 0);
1447                 }
1448         }
1449
1450         command_close_bidi_pipe($pid, $in, $out, $ctx);
1451
1452         return \%s2r;
1453 }
1454
1455 sub working_head_info {
1456         my ($head, $refs) = @_;
1457         my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1458         my ($fh, $ctx) = command_output_pipe(@args, $head);
1459         my $hash;
1460         my %max;
1461         while (<$fh>) {
1462                 if ( m{^commit ($::sha1)$} ) {
1463                         unshift @$refs, $hash if $hash and $refs;
1464                         $hash = $1;
1465                         next;
1466                 }
1467                 next unless s{^\s*(git-svn-id:)}{$1};
1468                 my ($url, $rev, $uuid) = extract_metadata($_);
1469                 if (defined $url && defined $rev) {
1470                         next if $max{$url} and $max{$url} < $rev;
1471                         if (my $gs = Git::SVN->find_by_url($url)) {
1472                                 my $c = $gs->rev_map_get($rev, $uuid);
1473                                 if ($c && $c eq $hash) {
1474                                         close $fh; # break the pipe
1475                                         return ($url, $rev, $uuid, $gs);
1476                                 } else {
1477                                         $max{$url} ||= $gs->rev_map_max;
1478                                 }
1479                         }
1480                 }
1481         }
1482         command_close_pipe($fh, $ctx);
1483         (undef, undef, undef, undef);
1484 }
1485
1486 sub read_commit_parents {
1487         my ($parents, $c) = @_;
1488         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1489         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1490         @{$parents->{$c}} = split(/ /, $p);
1491 }
1492
1493 sub linearize_history {
1494         my ($gs, $refs) = @_;
1495         my %parents;
1496         foreach my $c (@$refs) {
1497                 read_commit_parents(\%parents, $c);
1498         }
1499
1500         my @linear_refs;
1501         my %skip = ();
1502         my $last_svn_commit = $gs->last_commit;
1503         foreach my $c (reverse @$refs) {
1504                 next if $c eq $last_svn_commit;
1505                 last if $skip{$c};
1506
1507                 unshift @linear_refs, $c;
1508                 $skip{$c} = 1;
1509
1510                 # we only want the first parent to diff against for linear
1511                 # history, we save the rest to inject when we finalize the
1512                 # svn commit
1513                 my $fp_a = verify_ref("$c~1");
1514                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1515                 if (!$fp_a || !$fp_b) {
1516                         die "Commit $c\n",
1517                             "has no parent commit, and therefore ",
1518                             "nothing to diff against.\n",
1519                             "You should be working from a repository ",
1520                             "originally created by git-svn\n";
1521                 }
1522                 if ($fp_a ne $fp_b) {
1523                         die "$c~1 = $fp_a, however parsing commit $c ",
1524                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1525                 }
1526
1527                 foreach my $p (@{$parents{$c}}) {
1528                         $skip{$p} = 1;
1529                 }
1530         }
1531         (\@linear_refs, \%parents);
1532 }
1533
1534 sub find_file_type_and_diff_status {
1535         my ($path) = @_;
1536         return ('dir', '') if $path eq '';
1537
1538         my $diff_output =
1539             command_oneline(qw(diff --cached --name-status --), $path) || "";
1540         my $diff_status = (split(' ', $diff_output))[0] || "";
1541
1542         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1543
1544         return (undef, undef) if !$diff_status && !$ls_tree;
1545
1546         if ($diff_status eq "A") {
1547                 return ("link", $diff_status) if -l $path;
1548                 return ("dir", $diff_status) if -d $path;
1549                 return ("file", $diff_status);
1550         }
1551
1552         my $mode = (split(' ', $ls_tree))[0] || "";
1553
1554         return ("link", $diff_status) if $mode eq "120000";
1555         return ("dir", $diff_status) if $mode eq "040000";
1556         return ("file", $diff_status);
1557 }
1558
1559 sub md5sum {
1560         my $arg = shift;
1561         my $ref = ref $arg;
1562         my $md5 = Digest::MD5->new();
1563         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1564                 $md5->addfile($arg) or croak $!;
1565         } elsif ($ref eq 'SCALAR') {
1566                 $md5->add($$arg) or croak $!;
1567         } elsif (!$ref) {
1568                 $md5->add($arg) or croak $!;
1569         } else {
1570                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1571         }
1572         return $md5->hexdigest();
1573 }
1574
1575 sub gc_directory {
1576         if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1577                 my $out_filename = $_ . ".gz";
1578                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1579                 binmode $in_fh;
1580                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1581                                 die "Unable to open $out_filename: $!\n";
1582
1583                 my $res;
1584                 while ($res = sysread($in_fh, my $str, 1024)) {
1585                         $gz->gzwrite($str) or
1586                                 die "Unable to write: ".$gz->gzerror()."!\n";
1587                 }
1588                 unlink $_ or die "unlink $File::Find::name: $!\n";
1589         } elsif (-f $_ && basename($_) eq "index") {
1590                 unlink $_ or die "unlink $_: $!\n";
1591         }
1592 }
1593
1594 package Git::SVN;
1595 use strict;
1596 use warnings;
1597 use Fcntl qw/:DEFAULT :seek/;
1598 use constant rev_map_fmt => 'NH40';
1599 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1600             $_repack $_repack_flags $_use_svm_props $_head
1601             $_use_svnsync_props $no_reuse_existing $_minimize_url
1602             $_use_log_author $_add_author_from $_localtime/;
1603 use Carp qw/croak/;
1604 use File::Path qw/mkpath/;
1605 use File::Copy qw/copy/;
1606 use IPC::Open3;
1607
1608 my ($_gc_nr, $_gc_period);
1609
1610 # properties that we do not log:
1611 my %SKIP_PROP;
1612 BEGIN {
1613         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1614                                         svn:special svn:executable
1615                                         svn:entry:committed-rev
1616                                         svn:entry:last-author
1617                                         svn:entry:uuid
1618                                         svn:entry:committed-date/;
1619
1620         # some options are read globally, but can be overridden locally
1621         # per [svn-remote "..."] section.  Command-line options will *NOT*
1622         # override options set in an [svn-remote "..."] section
1623         no strict 'refs';
1624         for my $option (qw/follow_parent no_metadata use_svm_props
1625                            use_svnsync_props/) {
1626                 my $key = $option;
1627                 $key =~ tr/_//d;
1628                 my $prop = "-$option";
1629                 *$option = sub {
1630                         my ($self) = @_;
1631                         return $self->{$prop} if exists $self->{$prop};
1632                         my $k = "svn-remote.$self->{repo_id}.$key";
1633                         eval { command_oneline(qw/config --get/, $k) };
1634                         if ($@) {
1635                                 $self->{$prop} = ${"Git::SVN::_$option"};
1636                         } else {
1637                                 my $v = command_oneline(qw/config --bool/,$k);
1638                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1639                         }
1640                         return $self->{$prop};
1641                 }
1642         }
1643 }
1644
1645
1646 my (%LOCKFILES, %INDEX_FILES);
1647 END {
1648         unlink keys %LOCKFILES if %LOCKFILES;
1649         unlink keys %INDEX_FILES if %INDEX_FILES;
1650 }
1651
1652 sub resolve_local_globs {
1653         my ($url, $fetch, $glob_spec) = @_;
1654         return unless defined $glob_spec;
1655         my $ref = $glob_spec->{ref};
1656         my $path = $glob_spec->{path};
1657         foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1658                 next unless m#^refs/remotes/$ref->{regex}$#;
1659                 my $p = $1;
1660                 my $pathname = desanitize_refname($path->full_path($p));
1661                 my $refname = desanitize_refname($ref->full_path($p));
1662                 if (my $existing = $fetch->{$pathname}) {
1663                         if ($existing ne $refname) {
1664                                 die "Refspec conflict:\n",
1665                                     "existing: refs/remotes/$existing\n",
1666                                     " globbed: refs/remotes/$refname\n";
1667                         }
1668                         my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1669                         $u =~ s!^\Q$url\E(/|$)!! or die
1670                           "refs/remotes/$refname: '$url' not found in '$u'\n";
1671                         if ($pathname ne $u) {
1672                                 warn "W: Refspec glob conflict ",
1673                                      "(ref: refs/remotes/$refname):\n",
1674                                      "expected path: $pathname\n",
1675                                      "    real path: $u\n",
1676                                      "Continuing ahead with $u\n";
1677                                 next;
1678                         }
1679                 } else {
1680                         $fetch->{$pathname} = $refname;
1681                 }
1682         }
1683 }
1684
1685 sub parse_revision_argument {
1686         my ($base, $head) = @_;
1687         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1688                 return ($base, $head);
1689         }
1690         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1691         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1692         return ($head, $head) if ($::_revision eq 'HEAD');
1693         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1694         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1695         die "revision argument: $::_revision not understood by git-svn\n";
1696 }
1697
1698 sub fetch_all {
1699         my ($repo_id, $remotes) = @_;
1700         if (ref $repo_id) {
1701                 my $gs = $repo_id;
1702                 $repo_id = undef;
1703                 $repo_id = $gs->{repo_id};
1704         }
1705         $remotes ||= read_all_remotes();
1706         my $remote = $remotes->{$repo_id} or
1707                      die "[svn-remote \"$repo_id\"] unknown\n";
1708         my $fetch = $remote->{fetch};
1709         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1710         my (@gs, @globs);
1711         my $ra = Git::SVN::Ra->new($url);
1712         my $uuid = $ra->get_uuid;
1713         my $head = $ra->get_latest_revnum;
1714         $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] });
1715         my $base = defined $fetch ? $head : 0;
1716
1717         # read the max revs for wildcard expansion (branches/*, tags/*)
1718         foreach my $t (qw/branches tags/) {
1719                 defined $remote->{$t} or next;
1720                 push @globs, @{$remote->{$t}};
1721
1722                 my $max_rev = eval { tmp_config(qw/--int --get/,
1723                                          "svn-remote.$repo_id.${t}-maxRev") };
1724                 if (defined $max_rev && ($max_rev < $base)) {
1725                         $base = $max_rev;
1726                 } elsif (!defined $max_rev) {
1727                         $base = 0;
1728                 }
1729         }
1730
1731         if ($fetch) {
1732                 foreach my $p (sort keys %$fetch) {
1733                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1734                         my $lr = $gs->rev_map_max;
1735                         if (defined $lr) {
1736                                 $base = $lr if ($lr < $base);
1737                         }
1738                         push @gs, $gs;
1739                 }
1740         }
1741
1742         ($base, $head) = parse_revision_argument($base, $head);
1743         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1744 }
1745
1746 sub read_all_remotes {
1747         my $r = {};
1748         my $use_svm_props = eval { command_oneline(qw/config --bool
1749             svn.useSvmProps/) };
1750         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1751         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1752                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*(.+)\s*$!) {
1753                         my ($remote, $local_ref, $_remote_ref) = ($1, $2, $3);
1754                         die("svn-remote.$remote: remote ref '$_remote_ref' "
1755                             . "must start with 'refs/remotes/'\n")
1756                                 unless $_remote_ref =~ m{^refs/remotes/(.+)};
1757                         my $remote_ref = $1;
1758                         $local_ref =~ s{^/}{};
1759                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1760                         $r->{$remote}->{svm} = {} if $use_svm_props;
1761                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1762                         $r->{$1}->{svm} = {};
1763                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1764                         $r->{$1}->{url} = $2;
1765                 } elsif (m!^(.+)\.(branches|tags)=
1766                            (.*):refs/remotes/(.+)\s*$/!x) {
1767                         my ($p, $g) = ($3, $4);
1768                         my $rs = {
1769                             t => $2,
1770                             remote => $1,
1771                             path => Git::SVN::GlobSpec->new($p),
1772                             ref => Git::SVN::GlobSpec->new($g) };
1773                         if (length($rs->{ref}->{right}) != 0) {
1774                                 die "The '*' glob character must be the last ",
1775                                     "character of '$g'\n";
1776                         }
1777                         push @{ $r->{$1}->{$2} }, $rs;
1778                 }
1779         }
1780
1781         map {
1782                 if (defined $r->{$_}->{svm}) {
1783                         my $svm;
1784                         eval {
1785                                 my $section = "svn-remote.$_";
1786                                 $svm = {
1787                                         source => tmp_config('--get',
1788                                             "$section.svm-source"),
1789                                         replace => tmp_config('--get',
1790                                             "$section.svm-replace"),
1791                                 }
1792                         };
1793                         $r->{$_}->{svm} = $svm;
1794                 }
1795         } keys %$r;
1796
1797         $r;
1798 }
1799
1800 sub init_vars {
1801         $_gc_nr = $_gc_period = 1000;
1802         if (defined $_repack || defined $_repack_flags) {
1803                warn "Repack options are obsolete; they have no effect.\n";
1804         }
1805 }
1806
1807 sub verify_remotes_sanity {
1808         return unless -d $ENV{GIT_DIR};
1809         my %seen;
1810         foreach (command(qw/config -l/)) {
1811                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1812                         if ($seen{$1}) {
1813                                 die "Remote ref refs/remote/$1 is tracked by",
1814                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1815                                     "Please resolve this ambiguity in ",
1816                                     "your git configuration file before ",
1817                                     "continuing\n";
1818                         }
1819                         $seen{$1} = $_;
1820                 }
1821         }
1822 }
1823
1824 sub find_existing_remote {
1825         my ($url, $remotes) = @_;
1826         return undef if $no_reuse_existing;
1827         my $existing;
1828         foreach my $repo_id (keys %$remotes) {
1829                 my $u = $remotes->{$repo_id}->{url} or next;
1830                 next if $u ne $url;
1831                 $existing = $repo_id;
1832                 last;
1833         }
1834         $existing;
1835 }
1836
1837 sub init_remote_config {
1838         my ($self, $url, $no_write) = @_;
1839         $url =~ s!/+$!!; # strip trailing slash
1840         my $r = read_all_remotes();
1841         my $existing = find_existing_remote($url, $r);
1842         if ($existing) {
1843                 unless ($no_write) {
1844                         print STDERR "Using existing ",
1845                                      "[svn-remote \"$existing\"]\n";
1846                 }
1847                 $self->{repo_id} = $existing;
1848         } elsif ($_minimize_url) {
1849                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1850                 $existing = find_existing_remote($min_url, $r);
1851                 if ($existing) {
1852                         unless ($no_write) {
1853                                 print STDERR "Using existing ",
1854                                              "[svn-remote \"$existing\"]\n";
1855                         }
1856                         $self->{repo_id} = $existing;
1857                 }
1858                 if ($min_url ne $url) {
1859                         unless ($no_write) {
1860                                 print STDERR "Using higher level of URL: ",
1861                                              "$url => $min_url\n";
1862                         }
1863                         my $old_path = $self->{path};
1864                         $self->{path} = $url;
1865                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1866                         if (length $old_path) {
1867                                 $self->{path} .= "/$old_path";
1868                         }
1869                         $url = $min_url;
1870                 }
1871         }
1872         my $orig_url;
1873         if (!$existing) {
1874                 # verify that we aren't overwriting anything:
1875                 $orig_url = eval {
1876                         command_oneline('config', '--get',
1877                                         "svn-remote.$self->{repo_id}.url")
1878                 };
1879                 if ($orig_url && ($orig_url ne $url)) {
1880                         die "svn-remote.$self->{repo_id}.url already set: ",
1881                             "$orig_url\nwanted to set to: $url\n";
1882                 }
1883         }
1884         my ($xrepo_id, $xpath) = find_ref($self->refname);
1885         if (defined $xpath) {
1886                 die "svn-remote.$xrepo_id.fetch already set to track ",
1887                     "$xpath:refs/remotes/", $self->refname, "\n";
1888         }
1889         unless ($no_write) {
1890                 command_noisy('config',
1891                               "svn-remote.$self->{repo_id}.url", $url);
1892                 $self->{path} =~ s{^/}{};
1893                 command_noisy('config', '--add',
1894                               "svn-remote.$self->{repo_id}.fetch",
1895                               "$self->{path}:".$self->refname);
1896         }
1897         $self->{url} = $url;
1898 }
1899
1900 sub find_by_url { # repos_root and, path are optional
1901         my ($class, $full_url, $repos_root, $path) = @_;
1902
1903         return undef unless defined $full_url;
1904         remove_username($full_url);
1905         remove_username($repos_root) if defined $repos_root;
1906         my $remotes = read_all_remotes();
1907         if (defined $full_url && defined $repos_root && !defined $path) {
1908                 $path = $full_url;
1909                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1910         }
1911         foreach my $repo_id (keys %$remotes) {
1912                 my $u = $remotes->{$repo_id}->{url} or next;
1913                 remove_username($u);
1914                 next if defined $repos_root && $repos_root ne $u;
1915
1916                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1917                 foreach my $t (qw/branches tags/) {
1918                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1919                                 resolve_local_globs($u, $fetch, $globspec);
1920                         }
1921                 }
1922                 my $p = $path;
1923                 my $rwr = rewrite_root({repo_id => $repo_id});
1924                 my $svm = $remotes->{$repo_id}->{svm}
1925                         if defined $remotes->{$repo_id}->{svm};
1926                 unless (defined $p) {
1927                         $p = $full_url;
1928                         my $z = $u;
1929                         my $prefix = '';
1930                         if ($rwr) {
1931                                 $z = $rwr;
1932                                 remove_username($z);
1933                         } elsif (defined $svm) {
1934                                 $z = $svm->{source};
1935                                 $prefix = $svm->{replace};
1936                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
1937                                 $prefix =~ s#/$##;
1938                         }
1939                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
1940                 }
1941                 foreach my $f (keys %$fetch) {
1942                         next if $f ne $p;
1943                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1944                 }
1945         }
1946         undef;
1947 }
1948
1949 sub init {
1950         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1951         my $self = _new($class, $repo_id, $ref_id, $path);
1952         if (defined $url) {
1953                 $self->init_remote_config($url, $no_write);
1954         }
1955         $self;
1956 }
1957
1958 sub find_ref {
1959         my ($ref_id) = @_;
1960         foreach (command(qw/config -l/)) {
1961                 next unless m!^svn-remote\.(.+)\.fetch=
1962                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1963                 my ($repo_id, $path, $ref) = ($1, $2, $3);
1964                 if ($ref eq $ref_id) {
1965                         $path = '' if ($path =~ m#^\./?#);
1966                         return ($repo_id, $path);
1967                 }
1968         }
1969         (undef, undef, undef);
1970 }
1971
1972 sub new {
1973         my ($class, $ref_id, $repo_id, $path) = @_;
1974         if (defined $ref_id && !defined $repo_id && !defined $path) {
1975                 ($repo_id, $path) = find_ref($ref_id);
1976                 if (!defined $repo_id) {
1977                         die "Could not find a \"svn-remote.*.fetch\" key ",
1978                             "in the repository configuration matching: ",
1979                             "refs/remotes/$ref_id\n";
1980                 }
1981         }
1982         my $self = _new($class, $repo_id, $ref_id, $path);
1983         if (!defined $self->{path} || !length $self->{path}) {
1984                 my $fetch = command_oneline('config', '--get',
1985                                             "svn-remote.$repo_id.fetch",
1986                                             ":refs/remotes/$ref_id\$") or
1987                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1988                          "\":refs/remotes/$ref_id\$\" in config\n";
1989                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1990         }
1991         $self->{url} = command_oneline('config', '--get',
1992                                        "svn-remote.$repo_id.url") or
1993                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1994         $self->rebuild;
1995         $self;
1996 }
1997
1998 sub refname {
1999         my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
2000
2001         # It cannot end with a slash /, we'll throw up on this because
2002         # SVN can't have directories with a slash in their name, either:
2003         if ($refname =~ m{/$}) {
2004                 die "ref: '$refname' ends with a trailing slash, this is ",
2005                     "not permitted by git nor Subversion\n";
2006         }
2007
2008         # It cannot have ASCII control character space, tilde ~, caret ^,
2009         # colon :, question-mark ?, asterisk *, space, or open bracket [
2010         # anywhere.
2011         #
2012         # Additionally, % must be escaped because it is used for escaping
2013         # and we want our escaped refname to be reversible
2014         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2015
2016         # no slash-separated component can begin with a dot .
2017         # /.* becomes /%2E*
2018         $refname =~ s{/\.}{/%2E}g;
2019
2020         # It cannot have two consecutive dots .. anywhere
2021         # .. becomes %2E%2E
2022         $refname =~ s{\.\.}{%2E%2E}g;
2023
2024         return $refname;
2025 }
2026
2027 sub desanitize_refname {
2028         my ($refname) = @_;
2029         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2030         return $refname;
2031 }
2032
2033 sub svm_uuid {
2034         my ($self) = @_;
2035         return $self->{svm}->{uuid} if $self->svm;
2036         $self->ra;
2037         unless ($self->{svm}) {
2038                 die "SVM UUID not cached, and reading remotely failed\n";
2039         }
2040         $self->{svm}->{uuid};
2041 }
2042
2043 sub svm {
2044         my ($self) = @_;
2045         return $self->{svm} if $self->{svm};
2046         my $svm;
2047         # see if we have it in our config, first:
2048         eval {
2049                 my $section = "svn-remote.$self->{repo_id}";
2050                 $svm = {
2051                   source => tmp_config('--get', "$section.svm-source"),
2052                   uuid => tmp_config('--get', "$section.svm-uuid"),
2053                   replace => tmp_config('--get', "$section.svm-replace"),
2054                 }
2055         };
2056         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2057                 $self->{svm} = $svm;
2058         }
2059         $self->{svm};
2060 }
2061
2062 sub _set_svm_vars {
2063         my ($self, $ra) = @_;
2064         return $ra if $self->svm;
2065
2066         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2067                     "(svm:source, svm:uuid) ",
2068                     "from the following URLs:\n" );
2069         sub read_svm_props {
2070                 my ($self, $ra, $path, $r) = @_;
2071                 my $props = ($ra->get_dir($path, $r))[2];
2072                 my $src = $props->{'svm:source'};
2073                 my $uuid = $props->{'svm:uuid'};
2074                 return undef if (!$src || !$uuid);
2075
2076                 chomp($src, $uuid);
2077
2078                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2079                     or die "doesn't look right - svm:uuid is '$uuid'\n";
2080
2081                 # the '!' is used to mark the repos_root!/relative/path
2082                 $src =~ s{/?!/?}{/};
2083                 $src =~ s{/+$}{}; # no trailing slashes please
2084                 # username is of no interest
2085                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2086
2087                 my $replace = $ra->{url};
2088                 $replace .= "/$path" if length $path;
2089
2090                 my $section = "svn-remote.$self->{repo_id}";
2091                 tmp_config("$section.svm-source", $src);
2092                 tmp_config("$section.svm-replace", $replace);
2093                 tmp_config("$section.svm-uuid", $uuid);
2094                 $self->{svm} = {
2095                         source => $src,
2096                         uuid => $uuid,
2097                         replace => $replace
2098                 };
2099         }
2100
2101         my $r = $ra->get_latest_revnum;
2102         my $path = $self->{path};
2103         my %tried;
2104         while (length $path) {
2105                 unless ($tried{"$self->{url}/$path"}) {
2106                         return $ra if $self->read_svm_props($ra, $path, $r);
2107                         $tried{"$self->{url}/$path"} = 1;
2108                 }
2109                 $path =~ s#/?[^/]+$##;
2110         }
2111         die "Path: '$path' should be ''\n" if $path ne '';
2112         return $ra if $self->read_svm_props($ra, $path, $r);
2113         $tried{"$self->{url}/$path"} = 1;
2114
2115         if ($ra->{repos_root} eq $self->{url}) {
2116                 die @err, (map { "  $_\n" } keys %tried), "\n";
2117         }
2118
2119         # nope, make sure we're connected to the repository root:
2120         my $ok;
2121         my @tried_b;
2122         $path = $ra->{svn_path};
2123         $ra = Git::SVN::Ra->new($ra->{repos_root});
2124         while (length $path) {
2125                 unless ($tried{"$ra->{url}/$path"}) {
2126                         $ok = $self->read_svm_props($ra, $path, $r);
2127                         last if $ok;
2128                         $tried{"$ra->{url}/$path"} = 1;
2129                 }
2130                 $path =~ s#/?[^/]+$##;
2131         }
2132         die "Path: '$path' should be ''\n" if $path ne '';
2133         $ok ||= $self->read_svm_props($ra, $path, $r);
2134         $tried{"$ra->{url}/$path"} = 1;
2135         if (!$ok) {
2136                 die @err, (map { "  $_\n" } keys %tried), "\n";
2137         }
2138         Git::SVN::Ra->new($self->{url});
2139 }
2140
2141 sub svnsync {
2142         my ($self) = @_;
2143         return $self->{svnsync} if $self->{svnsync};
2144
2145         if ($self->no_metadata) {
2146                 die "Can't have both 'noMetadata' and ",
2147                     "'useSvnsyncProps' options set!\n";
2148         }
2149         if ($self->rewrite_root) {
2150                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2151                     "options set!\n";
2152         }
2153
2154         my $svnsync;
2155         # see if we have it in our config, first:
2156         eval {
2157                 my $section = "svn-remote.$self->{repo_id}";
2158
2159                 my $url = tmp_config('--get', "$section.svnsync-url");
2160                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2161                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2162
2163                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2164                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2165                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2166
2167                 $svnsync = { url => $url, uuid => $uuid }
2168         };
2169         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2170                 return $self->{svnsync} = $svnsync;
2171         }
2172
2173         my $err = "useSvnsyncProps set, but failed to read " .
2174                   "svnsync property: svn:sync-from-";
2175         my $rp = $self->ra->rev_proplist(0);
2176
2177         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2178         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2179                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2180
2181         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2182         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2183                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2184
2185         my $section = "svn-remote.$self->{repo_id}";
2186         tmp_config('--add', "$section.svnsync-uuid", $uuid);
2187         tmp_config('--add', "$section.svnsync-url", $url);
2188         return $self->{svnsync} = { url => $url, uuid => $uuid };
2189 }
2190
2191 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2192 # remote lookup (useful for 'git svn log').
2193 sub ra_uuid {
2194         my ($self) = @_;
2195         unless ($self->{ra_uuid}) {
2196                 my $key = "svn-remote.$self->{repo_id}.uuid";
2197                 my $uuid = eval { tmp_config('--get', $key) };
2198                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2199                         $self->{ra_uuid} = $uuid;
2200                 } else {
2201                         die "ra_uuid called without URL\n" unless $self->{url};
2202                         $self->{ra_uuid} = $self->ra->get_uuid;
2203                         tmp_config('--add', $key, $self->{ra_uuid});
2204                 }
2205         }
2206         $self->{ra_uuid};
2207 }
2208
2209 sub _set_repos_root {
2210         my ($self, $repos_root) = @_;
2211         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2212         $repos_root ||= $self->ra->{repos_root};
2213         tmp_config($k, $repos_root);
2214         $repos_root;
2215 }
2216
2217 sub repos_root {
2218         my ($self) = @_;
2219         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2220         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2221 }
2222
2223 sub ra {
2224         my ($self) = shift;
2225         my $ra = Git::SVN::Ra->new($self->{url});
2226         $self->_set_repos_root($ra->{repos_root});
2227         if ($self->use_svm_props && !$self->{svm}) {
2228                 if ($self->no_metadata) {
2229                         die "Can't have both 'noMetadata' and ",
2230                             "'useSvmProps' options set!\n";
2231                 } elsif ($self->use_svnsync_props) {
2232                         die "Can't have both 'useSvnsyncProps' and ",
2233                             "'useSvmProps' options set!\n";
2234                 }
2235                 $ra = $self->_set_svm_vars($ra);
2236                 $self->{-want_revprops} = 1;
2237         }
2238         $ra;
2239 }
2240
2241 # prop_walk(PATH, REV, SUB)
2242 # -------------------------
2243 # Recursively traverse PATH at revision REV and invoke SUB for each
2244 # directory that contains a SVN property.  SUB will be invoked as
2245 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2246 # Git::SVN, `path' the path to the directory where the properties
2247 # `props' were found.  The `path' will be relative to point of checkout,
2248 # that is, if url://repo/trunk is the current Git branch, and that
2249 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2250 # as `path' (note the trailing `/').
2251 sub prop_walk {
2252         my ($self, $path, $rev, $sub) = @_;
2253
2254         $path =~ s#^/##;
2255         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2256         $path =~ s#^/*#/#g;
2257         my $p = $path;
2258         # Strip the irrelevant part of the path.
2259         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2260         # Ensure the path is terminated by a `/'.
2261         $p =~ s#/*$#/#;
2262
2263         # The properties contain all the internal SVN stuff nobody
2264         # (usually) cares about.
2265         my $interesting_props = 0;
2266         foreach (keys %{$props}) {
2267                 # If it doesn't start with `svn:', it must be a
2268                 # user-defined property.
2269                 ++$interesting_props and next if $_ !~ /^svn:/;
2270                 # FIXME: Fragile, if SVN adds new public properties,
2271                 # this needs to be updated.
2272                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2273                                                  |eol-style|mime-type
2274                                                  |externals|needs-lock)$/x;
2275         }
2276         &$sub($self, $p, $props) if $interesting_props;
2277
2278         foreach (sort keys %$dirent) {
2279                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2280                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2281         }
2282 }
2283
2284 sub last_rev { ($_[0]->last_rev_commit)[0] }
2285 sub last_commit { ($_[0]->last_rev_commit)[1] }
2286
2287 # returns the newest SVN revision number and newest commit SHA1
2288 sub last_rev_commit {
2289         my ($self) = @_;
2290         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2291                 return ($self->{last_rev}, $self->{last_commit});
2292         }
2293         my $c = ::verify_ref($self->refname.'^0');
2294         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2295                 my $rev = (::cmt_metadata($c))[1];
2296                 if (defined $rev) {
2297                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2298                         return ($rev, $c);
2299                 }
2300         }
2301         my $map_path = $self->map_path;
2302         unless (-e $map_path) {
2303                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2304                 return (undef, undef);
2305         }
2306         my ($rev, $commit) = $self->rev_map_max(1);
2307         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2308         return ($rev, $commit);
2309 }
2310
2311 sub get_fetch_range {
2312         my ($self, $min, $max) = @_;
2313         $max ||= $self->ra->get_latest_revnum;
2314         $min ||= $self->rev_map_max;
2315         (++$min, $max);
2316 }
2317
2318 sub tmp_config {
2319         my (@args) = @_;
2320         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2321         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2322         if (! -f $config && -f $old_def_config) {
2323                 rename $old_def_config, $config or
2324                        die "Failed rename $old_def_config => $config: $!\n";
2325         }
2326         my $old_config = $ENV{GIT_CONFIG};
2327         $ENV{GIT_CONFIG} = $config;
2328         $@ = undef;
2329         my @ret = eval {
2330                 unless (-f $config) {
2331                         mkfile($config);
2332                         open my $fh, '>', $config or
2333                             die "Can't open $config: $!\n";
2334                         print $fh "; This file is used internally by ",
2335                                   "git-svn\n" or die
2336                                   "Couldn't write to $config: $!\n";
2337                         print $fh "; You should not have to edit it\n" or
2338                               die "Couldn't write to $config: $!\n";
2339                         close $fh or die "Couldn't close $config: $!\n";
2340                 }
2341                 command('config', @args);
2342         };
2343         my $err = $@;
2344         if (defined $old_config) {
2345                 $ENV{GIT_CONFIG} = $old_config;
2346         } else {
2347                 delete $ENV{GIT_CONFIG};
2348         }
2349         die $err if $err;
2350         wantarray ? @ret : $ret[0];
2351 }
2352
2353 sub tmp_index_do {
2354         my ($self, $sub) = @_;
2355         my $old_index = $ENV{GIT_INDEX_FILE};
2356         $ENV{GIT_INDEX_FILE} = $self->{index};
2357         $@ = undef;
2358         my @ret = eval {
2359                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2360                 mkpath([$dir]) unless -d $dir;
2361                 &$sub;
2362         };
2363         my $err = $@;
2364         if (defined $old_index) {
2365                 $ENV{GIT_INDEX_FILE} = $old_index;
2366         } else {
2367                 delete $ENV{GIT_INDEX_FILE};
2368         }
2369         die $err if $err;
2370         wantarray ? @ret : $ret[0];
2371 }
2372
2373 sub assert_index_clean {
2374         my ($self, $treeish) = @_;
2375
2376         $self->tmp_index_do(sub {
2377                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2378                 my $x = command_oneline('write-tree');
2379                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2380                            /^tree ($::sha1)/mo);
2381                 return if $y eq $x;
2382
2383                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2384                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2385                 command_noisy('read-tree', $treeish);
2386                 $x = command_oneline('write-tree');
2387                 if ($y ne $x) {
2388                         ::fatal "trees ($treeish) $y != $x\n",
2389                                 "Something is seriously wrong...";
2390                 }
2391         });
2392 }
2393
2394 sub get_commit_parents {
2395         my ($self, $log_entry) = @_;
2396         my (%seen, @ret, @tmp);
2397         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2398         if (my $ip = $self->{inject_parents}) {
2399                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2400                         push @tmp, $commit;
2401                 }
2402         }
2403         if (my $cur = ::verify_ref($self->refname.'^0')) {
2404                 push @tmp, $cur;
2405         }
2406         if (my $ipd = $self->{inject_parents_dcommit}) {
2407                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2408                         push @tmp, @$commit;
2409                 }
2410         }
2411         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2412         while (my $p = shift @tmp) {
2413                 next if $seen{$p};
2414                 $seen{$p} = 1;
2415                 push @ret, $p;
2416                 # MAXPARENT is defined to 16 in commit-tree.c:
2417                 last if @ret >= 16;
2418         }
2419         if (@tmp) {
2420                 die "r$log_entry->{revision}: No room for parents:\n\t",
2421                     join("\n\t", @tmp), "\n";
2422         }
2423         @ret;
2424 }
2425
2426 sub rewrite_root {
2427         my ($self) = @_;
2428         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2429         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2430         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2431         if ($rwr) {
2432                 $rwr =~ s#/+$##;
2433                 if ($rwr !~ m#^[a-z\+]+://#) {
2434                         die "$rwr is not a valid URL (key: $k)\n";
2435                 }
2436         }
2437         $self->{-rewrite_root} = $rwr;
2438 }
2439
2440 sub metadata_url {
2441         my ($self) = @_;
2442         ($self->rewrite_root || $self->{url}) .
2443            (length $self->{path} ? '/' . $self->{path} : '');
2444 }
2445
2446 sub full_url {
2447         my ($self) = @_;
2448         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2449 }
2450
2451
2452 sub set_commit_header_env {
2453         my ($log_entry) = @_;
2454         my %env;
2455         foreach my $ned (qw/NAME EMAIL DATE/) {
2456                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2457                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2458                 }
2459         }
2460
2461         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2462         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2463         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2464
2465         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2466                                                 ? $log_entry->{commit_name}
2467                                                 : $log_entry->{name};
2468         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2469                                                 ? $log_entry->{commit_email}
2470                                                 : $log_entry->{email};
2471         \%env;
2472 }
2473
2474 sub restore_commit_header_env {
2475         my ($env) = @_;
2476         foreach my $ned (qw/NAME EMAIL DATE/) {
2477                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2478                         my $k = "GIT_${ac}_${ned}";
2479                         if (defined $env->{$k}) {
2480                                 $ENV{$k} = $env->{$k};
2481                         } else {
2482                                 delete $ENV{$k};
2483                         }
2484                 }
2485         }
2486 }
2487
2488 sub gc {
2489         command_noisy('gc', '--auto');
2490 };
2491
2492 sub do_git_commit {
2493         my ($self, $log_entry) = @_;
2494         my $lr = $self->last_rev;
2495         if (defined $lr && $lr >= $log_entry->{revision}) {
2496                 die "Last fetched revision of ", $self->refname,
2497                     " was r$lr, but we are about to fetch: ",
2498                     "r$log_entry->{revision}!\n";
2499         }
2500         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2501                 croak "$log_entry->{revision} = $c already exists! ",
2502                       "Why are we refetching it?\n";
2503         }
2504         my $old_env = set_commit_header_env($log_entry);
2505         my $tree = $log_entry->{tree};
2506         if (!defined $tree) {
2507                 $tree = $self->tmp_index_do(sub {
2508                                             command_oneline('write-tree') });
2509         }
2510         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2511
2512         my @exec = ('git', 'commit-tree', $tree);
2513         foreach ($self->get_commit_parents($log_entry)) {
2514                 push @exec, '-p', $_;
2515         }
2516         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2517                                                                    or croak $!;
2518         binmode $msg_fh;
2519
2520         # we always get UTF-8 from SVN, but we may want our commits in
2521         # a different encoding.
2522         if (my $enc = Git::config('i18n.commitencoding')) {
2523                 require Encode;
2524                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2525         }
2526         print $msg_fh $log_entry->{log} or croak $!;
2527         restore_commit_header_env($old_env);
2528         unless ($self->no_metadata) {
2529                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2530                               or croak $!;
2531         }
2532         $msg_fh->flush == 0 or croak $!;
2533         close $msg_fh or croak $!;
2534         chomp(my $commit = do { local $/; <$out_fh> });
2535         close $out_fh or croak $!;
2536         waitpid $pid, 0;
2537         croak $? if $?;
2538         if ($commit !~ /^$::sha1$/o) {
2539                 die "Failed to commit, invalid sha1: $commit\n";
2540         }
2541
2542         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2543
2544         $self->{last_rev} = $log_entry->{revision};
2545         $self->{last_commit} = $commit;
2546         print "r$log_entry->{revision}" unless $::_q > 1;
2547         if (defined $log_entry->{svm_revision}) {
2548                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2549                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2550                                    0, $self->svm_uuid);
2551         }
2552         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2553         if (--$_gc_nr == 0) {
2554                 $_gc_nr = $_gc_period;
2555                 gc();
2556         }
2557         return $commit;
2558 }
2559
2560 sub match_paths {
2561         my ($self, $paths, $r) = @_;
2562         return 1 if $self->{path} eq '';
2563         if (my $path = $paths->{"/$self->{path}"}) {
2564                 return ($path->{action} eq 'D') ? 0 : 1;
2565         }
2566         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2567         if (grep /$self->{path_regex}/, keys %$paths) {
2568                 return 1;
2569         }
2570         my $c = '';
2571         foreach (split m#/#, $self->{path}) {
2572                 $c .= "/$_";
2573                 next unless ($paths->{$c} &&
2574                              ($paths->{$c}->{action} =~ /^[AR]$/));
2575                 if ($self->ra->check_path($self->{path}, $r) ==
2576                     $SVN::Node::dir) {
2577                         return 1;
2578                 }
2579         }
2580         return 0;
2581 }
2582
2583 sub find_parent_branch {
2584         my ($self, $paths, $rev) = @_;
2585         return undef unless $self->follow_parent;
2586         unless (defined $paths) {
2587                 my $err_handler = $SVN::Error::handler;
2588                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2589                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2590                                    sub { $paths = $_[0] });
2591                 $SVN::Error::handler = $err_handler;
2592         }
2593         return undef unless defined $paths;
2594
2595         # look for a parent from another branch:
2596         my @b_path_components = split m#/#, $self->{path};
2597         my @a_path_components;
2598         my $i;
2599         while (@b_path_components) {
2600                 $i = $paths->{'/'.join('/', @b_path_components)};
2601                 last if $i && defined $i->{copyfrom_path};
2602                 unshift(@a_path_components, pop(@b_path_components));
2603         }
2604         return undef unless defined $i && defined $i->{copyfrom_path};
2605         my $branch_from = $i->{copyfrom_path};
2606         if (@a_path_components) {
2607                 print STDERR "branch_from: $branch_from => ";
2608                 $branch_from .= '/'.join('/', @a_path_components);
2609                 print STDERR $branch_from, "\n";
2610         }
2611         my $r = $i->{copyfrom_rev};
2612         my $repos_root = $self->ra->{repos_root};
2613         my $url = $self->ra->{url};
2614         my $new_url = $url . $branch_from;
2615         print STDERR  "Found possible branch point: ",
2616                       "$new_url => ", $self->full_url, ", $r\n";
2617         $branch_from =~ s#^/##;
2618         my $gs = $self->other_gs($new_url, $url,
2619                                  $branch_from, $r, $self->{ref_id});
2620         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2621         {
2622                 my ($base, $head);
2623                 if (!defined $r0 || !defined $parent) {
2624                         ($base, $head) = parse_revision_argument(0, $r);
2625                 } else {
2626                         if ($r0 < $r) {
2627                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2628                                         0, 1, sub { $base = $_[1] - 1 });
2629                         }
2630                 }
2631                 if (defined $base && $base <= $r) {
2632                         $gs->fetch($base, $r);
2633                 }
2634                 ($r0, $parent) = $gs->find_rev_before($r, 1);
2635         }
2636         if (defined $r0 && defined $parent) {
2637                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2638                 my $ed;
2639                 if ($self->ra->can_do_switch) {
2640                         $self->assert_index_clean($parent);
2641                         print STDERR "Following parent with do_switch\n";
2642                         # do_switch works with svn/trunk >= r22312, but that
2643                         # is not included with SVN 1.4.3 (the latest version
2644                         # at the moment), so we can't rely on it
2645                         $self->{last_rev} = $r0;
2646                         $self->{last_commit} = $parent;
2647                         $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2648                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2649                                               $self->full_url, $ed)
2650                           or die "SVN connection failed somewhere...\n";
2651                 } elsif ($self->ra->trees_match($new_url, $r0,
2652                                                 $self->full_url, $rev)) {
2653                         print STDERR "Trees match:\n",
2654                                      "  $new_url\@$r0\n",
2655                                      "  ${\$self->full_url}\@$rev\n",
2656                                      "Following parent with no changes\n";
2657                         $self->tmp_index_do(sub {
2658                             command_noisy('read-tree', $parent);
2659                         });
2660                         $self->{last_commit} = $parent;
2661                 } else {
2662                         print STDERR "Following parent with do_update\n";
2663                         $ed = SVN::Git::Fetcher->new($self);
2664                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2665                           or die "SVN connection failed somewhere...\n";
2666                 }
2667                 print STDERR "Successfully followed parent\n";
2668                 return $self->make_log_entry($rev, [$parent], $ed);
2669         }
2670         return undef;
2671 }
2672
2673 sub do_fetch {
2674         my ($self, $paths, $rev) = @_;
2675         my $ed;
2676         my ($last_rev, @parents);
2677         if (my $lc = $self->last_commit) {
2678                 # we can have a branch that was deleted, then re-added
2679                 # under the same name but copied from another path, in
2680                 # which case we'll have multiple parents (we don't
2681                 # want to break the original ref, nor lose copypath info):
2682                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2683                         push @{$log_entry->{parents}}, $lc;
2684                         return $log_entry;
2685                 }
2686                 $ed = SVN::Git::Fetcher->new($self);
2687                 $last_rev = $self->{last_rev};
2688                 $ed->{c} = $lc;
2689                 @parents = ($lc);
2690         } else {
2691                 $last_rev = $rev;
2692                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2693                         return $log_entry;
2694                 }
2695                 $ed = SVN::Git::Fetcher->new($self);
2696         }
2697         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2698                 die "SVN connection failed somewhere...\n";
2699         }
2700         $self->make_log_entry($rev, \@parents, $ed);
2701 }
2702
2703 sub get_untracked {
2704         my ($self, $ed) = @_;
2705         my @out;
2706         my $h = $ed->{empty};
2707         foreach (sort keys %$h) {
2708                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2709                 push @out, "  $act: " . uri_encode($_);
2710                 warn "W: $act: $_\n";
2711         }
2712         foreach my $t (qw/dir_prop file_prop/) {
2713                 $h = $ed->{$t} or next;
2714                 foreach my $path (sort keys %$h) {
2715                         my $ppath = $path eq '' ? '.' : $path;
2716                         foreach my $prop (sort keys %{$h->{$path}}) {
2717                                 next if $SKIP_PROP{$prop};
2718                                 my $v = $h->{$path}->{$prop};
2719                                 my $t_ppath_prop = "$t: " .
2720                                                     uri_encode($ppath) . ' ' .
2721                                                     uri_encode($prop);
2722                                 if (defined $v) {
2723                                         push @out, "  +$t_ppath_prop " .
2724                                                    uri_encode($v);
2725                                 } else {
2726                                         push @out, "  -$t_ppath_prop";
2727                                 }
2728                         }
2729                 }
2730         }
2731         foreach my $t (qw/absent_file absent_directory/) {
2732                 $h = $ed->{$t} or next;
2733                 foreach my $parent (sort keys %$h) {
2734                         foreach my $path (sort @{$h->{$parent}}) {
2735                                 push @out, "  $t: " .
2736                                            uri_encode("$parent/$path");
2737                                 warn "W: $t: $parent/$path ",
2738                                      "Insufficient permissions?\n";
2739                         }
2740                 }
2741         }
2742         \@out;
2743 }
2744
2745 # parse_svn_date(DATE)
2746 # --------------------
2747 # Given a date (in UTC) from Subversion, return a string in the format
2748 # "<TZ Offset> <local date/time>" that Git will use.
2749 #
2750 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2751 # is true we'll convert it to the local timezone instead.
2752 sub parse_svn_date {
2753         my $date = shift || return '+0000 1970-01-01 00:00:00';
2754         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2755                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2756                                          croak "Unable to parse date: $date\n";
2757         my $parsed_date;    # Set next.
2758
2759         if ($Git::SVN::_localtime) {
2760                 # Translate the Subversion datetime to an epoch time.
2761                 # Begin by switching ourselves to $date's timezone, UTC.
2762                 my $old_env_TZ = $ENV{TZ};
2763                 $ENV{TZ} = 'UTC';
2764
2765                 my $epoch_in_UTC =
2766                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2767
2768                 # Determine our local timezone (including DST) at the
2769                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
2770                 # value of TZ, if any, at the time we were run.
2771                 if (defined $Git::SVN::Log::TZ) {
2772                         $ENV{TZ} = $Git::SVN::Log::TZ;
2773                 } else {
2774                         delete $ENV{TZ};
2775                 }
2776
2777                 my $our_TZ =
2778                     POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2779
2780                 # This converts $epoch_in_UTC into our local timezone.
2781                 my ($sec, $min, $hour, $mday, $mon, $year,
2782                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2783
2784                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2785                                        $our_TZ, $year + 1900, $mon + 1,
2786                                        $mday, $hour, $min, $sec);
2787
2788                 # Reset us to the timezone in effect when we entered
2789                 # this routine.
2790                 if (defined $old_env_TZ) {
2791                         $ENV{TZ} = $old_env_TZ;
2792                 } else {
2793                         delete $ENV{TZ};
2794                 }
2795         } else {
2796                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2797         }
2798
2799         return $parsed_date;
2800 }
2801
2802 sub other_gs {
2803         my ($self, $new_url, $url,
2804             $branch_from, $r, $old_ref_id) = @_;
2805         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2806         unless ($gs) {
2807                 my $ref_id = $old_ref_id;
2808                 $ref_id =~ s/\@\d+$//;
2809                 $ref_id .= "\@$r";
2810                 # just grow a tail if we're not unique enough :x
2811                 $ref_id .= '-' while find_ref($ref_id);
2812                 print STDERR "Initializing parent: $ref_id\n";
2813                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2814                 if ($u =~ s#^\Q$url\E(/|$)##) {
2815                         $p = $u;
2816                         $u = $url;
2817                         $repo_id = $self->{repo_id};
2818                 }
2819                 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2820         }
2821         $gs
2822 }
2823
2824 sub call_authors_prog {
2825         my ($orig_author) = @_;
2826         my $author = `$::_authors_prog $orig_author`;
2827         if ($? != 0) {
2828                 die "$::_authors_prog failed with exit code $?\n"
2829         }
2830         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
2831                 my ($name, $email) = ($1, $2);
2832                 $email = undef if length $2 == 0;
2833                 return [$name, $email];
2834         } else {
2835                 die "Author: $orig_author: $::_authors_prog returned "
2836                         . "invalid author format: $author\n";
2837         }
2838 }
2839
2840 sub check_author {
2841         my ($author) = @_;
2842         if (!defined $author || length $author == 0) {
2843                 $author = '(no author)';
2844         }
2845         if (!defined $::users{$author}) {
2846                 if (defined $::_authors_prog) {
2847                         $::users{$author} = call_authors_prog($author);
2848                 } elsif (defined $::_authors) {
2849                         die "Author: $author not defined in $::_authors file\n";
2850                 }
2851         }
2852         $author;
2853 }
2854
2855 sub make_log_entry {
2856         my ($self, $rev, $parents, $ed) = @_;
2857         my $untracked = $self->get_untracked($ed);
2858
2859         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2860         print $un "r$rev\n" or croak $!;
2861         print $un $_, "\n" foreach @$untracked;
2862         my %log_entry = ( parents => $parents || [], revision => $rev,
2863                           log => '');
2864
2865         my $headrev;
2866         my $logged = delete $self->{logged_rev_props};
2867         if (!$logged || $self->{-want_revprops}) {
2868                 my $rp = $self->ra->rev_proplist($rev);
2869                 foreach (sort keys %$rp) {
2870                         my $v = $rp->{$_};
2871                         if (/^svn:(author|date|log)$/) {
2872                                 $log_entry{$1} = $v;
2873                         } elsif ($_ eq 'svm:headrev') {
2874                                 $headrev = $v;
2875                         } else {
2876                                 print $un "  rev_prop: ", uri_encode($_), ' ',
2877                                           uri_encode($v), "\n";
2878                         }
2879                 }
2880         } else {
2881                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2882         }
2883         close $un or croak $!;
2884
2885         $log_entry{date} = parse_svn_date($log_entry{date});
2886         $log_entry{log} .= "\n";
2887         my $author = $log_entry{author} = check_author($log_entry{author});
2888         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2889                                                        : ($author, undef);
2890
2891         my ($commit_name, $commit_email) = ($name, $email);
2892         if ($_use_log_author) {
2893                 my $name_field;
2894                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2895                         $name_field = $1;
2896                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2897                         $name_field = $1;
2898                 }
2899                 if (!defined $name_field) {
2900                         if (!defined $email) {
2901                                 $email = $name;
2902                         }
2903                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2904                         ($name, $email) = ($1, $2);
2905                 } elsif ($name_field =~ /(.*)@/) {
2906                         ($name, $email) = ($1, $name_field);
2907                 } else {
2908                         ($name, $email) = ($name_field, $name_field);
2909                 }
2910         }
2911         if (defined $headrev && $self->use_svm_props) {
2912                 if ($self->rewrite_root) {
2913                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2914                             "options set!\n";
2915                 }
2916                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
2917                 # we don't want "SVM: initializing mirror for junk" ...
2918                 return undef if $r == 0;
2919                 my $svm = $self->svm;
2920                 if ($uuid ne $svm->{uuid}) {
2921                         die "UUID mismatch on SVM path:\n",
2922                             "expected: $svm->{uuid}\n",
2923                             "     got: $uuid\n";
2924                 }
2925                 my $full_url = $self->full_url;
2926                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2927                              die "Failed to replace '$svm->{replace}' with ",
2928                                  "'$svm->{source}' in $full_url\n";
2929                 # throw away username for storing in records
2930                 remove_username($full_url);
2931                 $log_entry{metadata} = "$full_url\@$r $uuid";
2932                 $log_entry{svm_revision} = $r;
2933                 $email ||= "$author\@$uuid";
2934                 $commit_email ||= "$author\@$uuid";
2935         } elsif ($self->use_svnsync_props) {
2936                 my $full_url = $self->svnsync->{url};
2937                 $full_url .= "/$self->{path}" if length $self->{path};
2938                 remove_username($full_url);
2939                 my $uuid = $self->svnsync->{uuid};
2940                 $log_entry{metadata} = "$full_url\@$rev $uuid";
2941                 $email ||= "$author\@$uuid";
2942                 $commit_email ||= "$author\@$uuid";
2943         } else {
2944                 my $url = $self->metadata_url;
2945                 remove_username($url);
2946                 $log_entry{metadata} = "$url\@$rev " .
2947                                        $self->ra->get_uuid;
2948                 $email ||= "$author\@" . $self->ra->get_uuid;
2949                 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2950         }
2951         $log_entry{name} = $name;
2952         $log_entry{email} = $email;
2953         $log_entry{commit_name} = $commit_name;
2954         $log_entry{commit_email} = $commit_email;
2955         \%log_entry;
2956 }
2957
2958 sub fetch {
2959         my ($self, $min_rev, $max_rev, @parents) = @_;
2960         my ($last_rev, $last_commit) = $self->last_rev_commit;
2961         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2962         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2963 }
2964
2965 sub set_tree_cb {
2966         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2967         $self->{inject_parents} = { $rev => $tree };
2968         $self->fetch(undef, undef);
2969 }
2970
2971 sub set_tree {
2972         my ($self, $tree) = (shift, shift);
2973         my $log_entry = ::get_commit_entry($tree);
2974         unless ($self->{last_rev}) {
2975                 ::fatal("Must have an existing revision to commit");
2976         }
2977         my %ed_opts = ( r => $self->{last_rev},
2978                         log => $log_entry->{log},
2979                         ra => $self->ra,
2980                         tree_a => $self->{last_commit},
2981                         tree_b => $tree,
2982                         editor_cb => sub {
2983                                $self->set_tree_cb($log_entry, $tree, @_) },
2984                         svn_path => $self->{path} );
2985         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2986                 print "No changes\nr$self->{last_rev} = $tree\n";
2987         }
2988 }
2989
2990 sub rebuild_from_rev_db {
2991         my ($self, $path) = @_;
2992         my $r = -1;
2993         open my $fh, '<', $path or croak "open: $!";
2994         binmode $fh or croak "binmode: $!";
2995         while (<$fh>) {
2996                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2997                 chomp($_);
2998                 ++$r;
2999                 next if $_ eq ('0' x 40);
3000                 $self->rev_map_set($r, $_);
3001                 print "r$r = $_\n";
3002         }
3003         close $fh or croak "close: $!";
3004         unlink $path or croak "unlink: $!";
3005 }
3006
3007 sub rebuild {
3008         my ($self) = @_;
3009         my $map_path = $self->map_path;
3010         my $partial = (-e $map_path && ! -z $map_path);
3011         return unless ::verify_ref($self->refname.'^0');
3012         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3013                 my $rev_db = $self->rev_db_path;
3014                 $self->rebuild_from_rev_db($rev_db);
3015                 if ($self->use_svm_props) {
3016                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3017                         $self->rebuild_from_rev_db($svm_rev_db);
3018                 }
3019                 $self->unlink_rev_db_symlink;
3020                 return;
3021         }
3022         print "Rebuilding $map_path ...\n" if (!$partial);
3023         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3024                 (undef, undef));
3025         my ($log, $ctx) =
3026             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3027                                 ($head ? "$head.." : "") . $self->refname,
3028                                 '--');
3029         my $metadata_url = $self->metadata_url;
3030         remove_username($metadata_url);
3031         my $svn_uuid = $self->ra_uuid;
3032         my $c;
3033         while (<$log>) {
3034                 if ( m{^commit ($::sha1)$} ) {
3035                         $c = $1;
3036                         next;
3037                 }
3038                 next unless s{^\s*(git-svn-id:)}{$1};
3039                 my ($url, $rev, $uuid) = ::extract_metadata($_);
3040                 remove_username($url);
3041
3042                 # ignore merges (from set-tree)
3043                 next if (!defined $rev || !$uuid);
3044
3045                 # if we merged or otherwise started elsewhere, this is
3046                 # how we break out of it
3047                 if (($uuid ne $svn_uuid) ||
3048                     ($metadata_url && $url && ($url ne $metadata_url))) {
3049                         next;
3050                 }
3051                 if ($partial && $head) {
3052                         print "Partial-rebuilding $map_path ...\n";
3053                         print "Currently at $base_rev = $head\n";
3054                         $head = undef;
3055                 }
3056
3057                 $self->rev_map_set($rev, $c);
3058                 print "r$rev = $c\n";
3059         }
3060         command_close_pipe($log, $ctx);
3061         print "Done rebuilding $map_path\n" if (!$partial || !$head);
3062         my $rev_db_path = $self->rev_db_path;
3063         if (-f $self->rev_db_path) {
3064                 unlink $self->rev_db_path or croak "unlink: $!";
3065         }
3066         $self->unlink_rev_db_symlink;
3067 }
3068
3069 # rev_map:
3070 # Tie::File seems to be prone to offset errors if revisions get sparse,
3071 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
3072 # one of my favorite modules is out :<  Next up would be one of the DBM
3073 # modules, but I'm not sure which is most portable...
3074 #
3075 # This is the replacement for the rev_db format, which was too big
3076 # and inefficient for large repositories with a lot of sparse history
3077 # (mainly tags)
3078 #
3079 # The format is this:
3080 #   - 24 bytes for every record,
3081 #     * 4 bytes for the integer representing an SVN revision number
3082 #     * 20 bytes representing the sha1 of a git commit
3083 #   - No empty padding records like the old format
3084 #     (except the last record, which can be overwritten)
3085 #   - new records are written append-only since SVN revision numbers
3086 #     increase monotonically
3087 #   - lookups on SVN revision number are done via a binary search
3088 #   - Piping the file to xxd -c24 is a good way of dumping it for
3089 #     viewing or editing (piped back through xxd -r), should the need
3090 #     ever arise.
3091 #   - The last record can be padding revision with an all-zero sha1
3092 #     This is used to optimize fetch performance when using multiple
3093 #     "fetch" directives in .git/config
3094 #
3095 # These files are disposable unless noMetadata or useSvmProps is set
3096
3097 sub _rev_map_set {
3098         my ($fh, $rev, $commit) = @_;
3099
3100         binmode $fh or croak "binmode: $!";
3101         my $size = (stat($fh))[7];
3102         ($size % 24) == 0 or croak "inconsistent size: $size";
3103
3104         my $wr_offset = 0;
3105         if ($size > 0) {
3106                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3107                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3108                 $read == 24 or croak "read only $read bytes (!= 24)";
3109                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3110                 if ($last_commit eq ('0' x40)) {
3111                         if ($size >= 48) {
3112                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3113                                 $read = sysread($fh, $buf, 24) or
3114                                     croak "read: $!";
3115                                 $read == 24 or
3116                                     croak "read only $read bytes (!= 24)";
3117                                 ($last_rev, $last_commit) =
3118                                     unpack(rev_map_fmt, $buf);
3119                                 if ($last_commit eq ('0' x40)) {
3120                                         croak "inconsistent .rev_map\n";
3121                                 }
3122                         }
3123                         if ($last_rev >= $rev) {
3124                                 croak "last_rev is higher!: $last_rev >= $rev";
3125                         }
3126                         $wr_offset = -24;
3127                 }
3128         }
3129         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3130         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3131           croak "write: $!";
3132 }
3133
3134 sub _rev_map_reset {
3135         my ($fh, $rev, $commit) = @_;
3136         my $c = _rev_map_get($fh, $rev);
3137         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3138         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3139         truncate $fh, $offset or croak "truncate: $!";
3140 }
3141
3142 sub mkfile {
3143         my ($path) = @_;
3144         unless (-e $path) {
3145                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3146                 mkpath([$dir]) unless -d $dir;
3147                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3148                 close $fh or die "Couldn't close (create) $path: $!\n";
3149         }
3150 }
3151
3152 sub rev_map_set {
3153         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3154         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3155         my $db = $self->map_path($uuid);
3156         my $db_lock = "$db.lock";
3157         my $sig;
3158         $update_ref ||= 0;
3159         if ($update_ref) {
3160                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3161                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3162         }
3163         mkfile($db);
3164
3165         $LOCKFILES{$db_lock} = 1;
3166         my $sync;
3167         # both of these options make our .rev_db file very, very important
3168         # and we can't afford to lose it because rebuild() won't work
3169         if ($self->use_svm_props || $self->no_metadata) {
3170                 $sync = 1;
3171                 copy($db, $db_lock) or die "rev_map_set(@_): ",
3172                                            "Failed to copy: ",
3173                                            "$db => $db_lock ($!)\n";
3174         } else {
3175                 rename $db, $db_lock or die "rev_map_set(@_): ",
3176                                             "Failed to rename: ",
3177                                             "$db => $db_lock ($!)\n";
3178         }
3179
3180         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3181              or croak "Couldn't open $db_lock: $!\n";
3182         $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3183                                  _rev_map_set($fh, $rev, $commit);
3184         if ($sync) {
3185                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3186                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3187         }
3188         close $fh or croak $!;
3189         if ($update_ref) {
3190                 $_head = $self;
3191                 my $note = "";
3192                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3193                 command_noisy('update-ref', '-m', "r$rev$note",
3194                               $self->refname, $commit);
3195         }
3196         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3197                                     "$db_lock => $db ($!)\n";
3198         delete $LOCKFILES{$db_lock};
3199         if ($update_ref) {
3200                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3201                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3202                 kill $sig, $$ if defined $sig;
3203         }
3204 }
3205
3206 # If want_commit, this will return an array of (rev, commit) where
3207 # commit _must_ be a valid commit in the archive.
3208 # Otherwise, it'll return the max revision (whether or not the
3209 # commit is valid or just a 0x40 placeholder).
3210 sub rev_map_max {
3211         my ($self, $want_commit) = @_;
3212         $self->rebuild;
3213         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3214         $want_commit ? ($r, $c) : $r;
3215 }
3216
3217 sub rev_map_max_norebuild {
3218         my ($self, $want_commit) = @_;
3219         my $map_path = $self->map_path;
3220         stat $map_path or return $want_commit ? (0, undef) : 0;
3221         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3222         binmode $fh or croak "binmode: $!";
3223         my $size = (stat($fh))[7];
3224         ($size % 24) == 0 or croak "inconsistent size: $size";
3225
3226         if ($size == 0) {
3227                 close $fh or croak "close: $!";
3228                 return $want_commit ? (0, undef) : 0;
3229         }
3230
3231         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3232         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3233         my ($r, $c) = unpack(rev_map_fmt, $buf);
3234         if ($want_commit && $c eq ('0' x40)) {
3235                 if ($size < 48) {
3236                         return $want_commit ? (0, undef) : 0;
3237                 }
3238                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3239                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3240                 ($r, $c) = unpack(rev_map_fmt, $buf);
3241                 if ($c eq ('0'x40)) {
3242                         croak "Penultimate record is all-zeroes in $map_path";
3243                 }
3244         }
3245         close $fh or croak "close: $!";
3246         $want_commit ? ($r, $c) : $r;
3247 }
3248
3249 sub rev_map_get {
3250         my ($self, $rev, $uuid) = @_;
3251         my $map_path = $self->map_path($uuid);
3252         return undef unless -e $map_path;
3253
3254         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3255         my $c = _rev_map_get($fh, $rev);
3256         close($fh) or croak "close: $!";
3257         $c
3258 }
3259
3260 sub _rev_map_get {
3261         my ($fh, $rev) = @_;
3262
3263         binmode $fh or croak "binmode: $!";
3264         my $size = (stat($fh))[7];
3265         ($size % 24) == 0 or croak "inconsistent size: $size";
3266
3267         if ($size == 0) {
3268                 return undef;
3269         }
3270
3271         my ($l, $u) = (0, $size - 24);
3272         my ($r, $c, $buf);
3273
3274         while ($l <= $u) {
3275                 my $i = int(($l/24 + $u/24) / 2) * 24;
3276                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3277                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3278                 my ($r, $c) = unpack('NH40', $buf);
3279
3280                 if ($r < $rev) {
3281                         $l = $i + 24;
3282                 } elsif ($r > $rev) {
3283                         $u = $i - 24;
3284                 } else { # $r == $rev
3285                         return $c eq ('0' x 40) ? undef : $c;
3286                 }
3287         }
3288         undef;
3289 }
3290
3291 # Finds the first svn revision that exists on (if $eq_ok is true) or
3292 # before $rev for the current branch.  It will not search any lower
3293 # than $min_rev.  Returns the git commit hash and svn revision number
3294 # if found, else (undef, undef).
3295 sub find_rev_before {
3296         my ($self, $rev, $eq_ok, $min_rev) = @_;
3297         --$rev unless $eq_ok;
3298         $min_rev ||= 1;
3299         my $max_rev = $self->rev_map_max;
3300         $rev = $max_rev if ($rev > $max_rev);
3301         while ($rev >= $min_rev) {
3302                 if (my $c = $self->rev_map_get($rev)) {
3303                         return ($rev, $c);
3304                 }
3305                 --$rev;
3306         }
3307         return (undef, undef);
3308 }
3309
3310 # Finds the first svn revision that exists on (if $eq_ok is true) or
3311 # after $rev for the current branch.  It will not search any higher
3312 # than $max_rev.  Returns the git commit hash and svn revision number
3313 # if found, else (undef, undef).
3314 sub find_rev_after {
3315         my ($self, $rev, $eq_ok, $max_rev) = @_;
3316         ++$rev unless $eq_ok;
3317         $max_rev ||= $self->rev_map_max;
3318         while ($rev <= $max_rev) {
3319                 if (my $c = $self->rev_map_get($rev)) {
3320                         return ($rev, $c);
3321                 }
3322                 ++$rev;
3323         }
3324         return (undef, undef);
3325 }
3326
3327 sub _new {
3328         my ($class, $repo_id, $ref_id, $path) = @_;
3329         unless (defined $repo_id && length $repo_id) {
3330                 $repo_id = $Git::SVN::default_repo_id;
3331         }
3332         unless (defined $ref_id && length $ref_id) {
3333                 $_prefix = '' unless defined($_prefix);
3334                 $_[2] = $ref_id = $_prefix . $Git::SVN::default_ref_id;
3335         }
3336         $_[1] = $repo_id;
3337         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3338         $_[3] = $path = '' unless (defined $path);
3339         mkpath(["$ENV{GIT_DIR}/svn"]);
3340         bless {
3341                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3342                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3343                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3344 }
3345
3346 # for read-only access of old .rev_db formats
3347 sub unlink_rev_db_symlink {
3348         my ($self) = @_;
3349         my $link = $self->rev_db_path;
3350         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3351         if (-l $link) {
3352                 unlink $link or croak "unlink: $link failed!";
3353         }
3354 }
3355
3356 sub rev_db_path {
3357         my ($self, $uuid) = @_;
3358         my $db_path = $self->map_path($uuid);
3359         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3360             or croak "map_path: $db_path does not contain '/.rev_map.' !";
3361         $db_path;
3362 }
3363
3364 # the new replacement for .rev_db
3365 sub map_path {
3366         my ($self, $uuid) = @_;
3367         $uuid ||= $self->ra_uuid;
3368         "$self->{map_root}.$uuid";
3369 }
3370
3371 sub uri_encode {
3372         my ($f) = @_;
3373         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3374         $f
3375 }
3376
3377 sub remove_username {
3378         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3379 }
3380
3381 package Git::SVN::Prompt;
3382 use strict;
3383 use warnings;
3384 require SVN::Core;
3385 use vars qw/$_no_auth_cache $_username/;
3386
3387 sub simple {
3388         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3389         $may_save = undef if $_no_auth_cache;
3390         $default_username = $_username if defined $_username;
3391         if (defined $default_username && length $default_username) {
3392                 if (defined $realm && length $realm) {
3393                         print STDERR "Authentication realm: $realm\n";
3394                         STDERR->flush;
3395                 }
3396                 $cred->username($default_username);
3397         } else {
3398                 username($cred, $realm, $may_save, $pool);
3399         }
3400         $cred->password(_read_password("Password for '" .
3401                                        $cred->username . "': ", $realm));
3402         $cred->may_save($may_save);
3403         $SVN::_Core::SVN_NO_ERROR;
3404 }
3405
3406 sub ssl_server_trust {
3407         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3408         $may_save = undef if $_no_auth_cache;
3409         print STDERR "Error validating server certificate for '$realm':\n";
3410         {
3411                 no warnings 'once';
3412                 # All variables SVN::Auth::SSL::* are used only once,
3413                 # so we're shutting up Perl warnings about this.
3414                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3415                         print STDERR " - The certificate is not issued ",
3416                             "by a trusted authority. Use the\n",
3417                             "   fingerprint to validate ",
3418                             "the certificate manually!\n";
3419                 }
3420                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3421                         print STDERR " - The certificate hostname ",
3422                             "does not match.\n";
3423                 }
3424                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3425                         print STDERR " - The certificate is not yet valid.\n";
3426                 }
3427                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3428                         print STDERR " - The certificate has expired.\n";
3429                 }
3430                 if ($failures & $SVN::Auth::SSL::OTHER) {
3431                         print STDERR " - The certificate has ",
3432                             "an unknown error.\n";
3433                 }
3434         } # no warnings 'once'
3435         printf STDERR
3436                 "Certificate information:\n".
3437                 " - Hostname: %s\n".
3438                 " - Valid: from %s until %s\n".
3439                 " - Issuer: %s\n".
3440                 " - Fingerprint: %s\n",
3441                 map $cert_info->$_, qw(hostname valid_from valid_until
3442                                        issuer_dname fingerprint);
3443         my $choice;
3444 prompt:
3445         print STDERR $may_save ?
3446               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3447               "(R)eject or accept (t)emporarily? ";
3448         STDERR->flush;
3449         $choice = lc(substr(<STDIN> || 'R', 0, 1));
3450         if ($choice =~ /^t$/i) {
3451                 $cred->may_save(undef);
3452         } elsif ($choice =~ /^r$/i) {
3453                 return -1;
3454         } elsif ($may_save && $choice =~ /^p$/i) {
3455                 $cred->may_save($may_save);
3456         } else {
3457                 goto prompt;
3458         }
3459         $cred->accepted_failures($failures);
3460         $SVN::_Core::SVN_NO_ERROR;
3461 }
3462
3463 sub ssl_client_cert {
3464         my ($cred, $realm, $may_save, $pool) = @_;
3465         $may_save = undef if $_no_auth_cache;
3466         print STDERR "Client certificate filename: ";
3467         STDERR->flush;
3468         chomp(my $filename = <STDIN>);
3469         $cred->cert_file($filename);
3470         $cred->may_save($may_save);
3471         $SVN::_Core::SVN_NO_ERROR;
3472 }
3473
3474 sub ssl_client_cert_pw {
3475         my ($cred, $realm, $may_save, $pool) = @_;
3476         $may_save = undef if $_no_auth_cache;
3477         $cred->password(_read_password("Password: ", $realm));
3478         $cred->may_save($may_save);
3479         $SVN::_Core::SVN_NO_ERROR;
3480 }
3481
3482 sub username {
3483         my ($cred, $realm, $may_save, $pool) = @_;
3484         $may_save = undef if $_no_auth_cache;
3485         if (defined $realm && length $realm) {
3486                 print STDERR "Authentication realm: $realm\n";
3487         }
3488         my $username;
3489         if (defined $_username) {
3490                 $username = $_username;
3491         } else {
3492                 print STDERR "Username: ";
3493                 STDERR->flush;
3494                 chomp($username = <STDIN>);
3495         }
3496         $cred->username($username);
3497         $cred->may_save($may_save);
3498         $SVN::_Core::SVN_NO_ERROR;
3499 }
3500
3501 sub _read_password {
3502         my ($prompt, $realm) = @_;
3503         print STDERR $prompt;
3504         STDERR->flush;
3505         require Term::ReadKey;
3506         Term::ReadKey::ReadMode('noecho');
3507         my $password = '';
3508         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3509                 last if $key =~ /[\012\015]/; # \n\r
3510                 $password .= $key;
3511         }
3512         Term::ReadKey::ReadMode('restore');
3513         print STDERR "\n";
3514         STDERR->flush;
3515         $password;
3516 }
3517
3518 package SVN::Git::Fetcher;
3519 use vars qw/@ISA/;
3520 use strict;
3521 use warnings;
3522 use Carp qw/croak/;
3523 use File::Temp qw/tempfile/;
3524 use IO::File qw//;
3525 use vars qw/$_ignore_regex/;
3526
3527 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3528 sub new {
3529         my ($class, $git_svn, $switch_path) = @_;
3530         my $self = SVN::Delta::Editor->new;
3531         bless $self, $class;
3532         if (exists $git_svn->{last_commit}) {
3533                 $self->{c} = $git_svn->{last_commit};
3534                 $self->{empty_symlinks} =
3535                                   _mark_empty_symlinks($git_svn, $switch_path);
3536         }
3537         $self->{ignore_regex} = eval { command_oneline('config', '--get',
3538                              "svn-remote.$git_svn->{repo_id}.ignore-paths") };
3539         $self->{empty} = {};
3540         $self->{dir_prop} = {};
3541         $self->{file_prop} = {};
3542         $self->{absent_dir} = {};
3543         $self->{absent_file} = {};
3544         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3545         $self;
3546 }
3547
3548 # this uses the Ra object, so it must be called before do_{switch,update},
3549 # not inside them (when the Git::SVN::Fetcher object is passed) to
3550 # do_{switch,update}
3551 sub _mark_empty_symlinks {
3552         my ($git_svn, $switch_path) = @_;
3553         my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
3554         return {} if (!defined($bool)) || (defined($bool) && ! $bool);
3555
3556         my %ret;
3557         my ($rev, $cmt) = $git_svn->last_rev_commit;
3558         return {} unless ($rev && $cmt);
3559
3560         # allow the warning to be printed for each revision we fetch to
3561         # ensure the user sees it.  The user can also disable the workaround
3562         # on the repository even while git svn is running and the next
3563         # revision fetched will skip this expensive function.
3564         my $printed_warning;
3565         chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
3566         my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
3567         local $/ = "\0";
3568         my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
3569         $pfx .= '/' if length($pfx);
3570         while (<$ls>) {
3571                 chomp;
3572                 s/\A100644 blob $empty_blob\t//o or next;
3573                 unless ($printed_warning) {
3574                         print STDERR "Scanning for empty symlinks, ",
3575                                      "this may take a while if you have ",
3576                                      "many empty files\n",
3577                                      "You may disable this with `",
3578                                      "git config svn.brokenSymlinkWorkaround ",
3579                                      "false'.\n",
3580                                      "This may be done in a different ",
3581                                      "terminal without restarting ",
3582                                      "git svn\n";
3583                         $printed_warning = 1;
3584                 }
3585                 my $path = $_;
3586                 my (undef, $props) =
3587                                $git_svn->ra->get_file($pfx.$path, $rev, undef);
3588                 if ($props->{'svn:special'}) {
3589                         $ret{$path} = 1;
3590                 }
3591         }
3592         command_close_pipe($ls, $ctx);
3593         \%ret;
3594 }
3595
3596 # returns true if a given path is inside a ".git" directory
3597 sub in_dot_git {
3598         $_[0] =~ m{(?:^|/)\.git(?:/|$)};
3599 }
3600
3601 # return value: 0 -- don't ignore, 1 -- ignore
3602 sub is_path_ignored {
3603         my ($self, $path) = @_;
3604         return 1 if in_dot_git($path);
3605         return 1 if defined($self->{ignore_regex}) &&
3606                     $path =~ m!$self->{ignore_regex}!;
3607         return 0 unless defined($_ignore_regex);
3608         return 1 if $path =~ m!$_ignore_regex!o;
3609         return 0;
3610 }
3611
3612 sub set_path_strip {
3613         my ($self, $path) = @_;
3614         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3615 }
3616
3617 sub open_root {
3618         { path => '' };
3619 }
3620
3621 sub open_directory {
3622         my ($self, $path, $pb, $rev) = @_;
3623         { path => $path };
3624 }
3625
3626 sub git_path {
3627         my ($self, $path) = @_;
3628         if ($self->{path_strip}) {
3629                 $path =~ s!$self->{path_strip}!! or
3630                   die "Failed to strip path '$path' ($self->{path_strip})\n";
3631         }
3632         $path;
3633 }
3634
3635 sub delete_entry {
3636         my ($self, $path, $rev, $pb) = @_;
3637         return undef if $self->is_path_ignored($path);
3638
3639         my $gpath = $self->git_path($path);
3640         return undef if ($gpath eq '');
3641
3642         # remove entire directories.
3643         my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3644                          =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
3645         if ($tree) {
3646                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3647                                                      -r --name-only -z/,
3648                                                      $tree);
3649                 local $/ = "\0";
3650                 while (<$ls>) {
3651                         chomp;
3652                         my $rmpath = "$gpath/$_";
3653                         $self->{gii}->remove($rmpath);
3654                         print "\tD\t$rmpath\n" unless $::_q;
3655                 }
3656                 print "\tD\t$gpath/\n" unless $::_q;
3657                 command_close_pipe($ls, $ctx);
3658                 $self->{empty}->{$path} = 0
3659         } else {
3660                 $self->{gii}->remove($gpath);
3661                 print "\tD\t$gpath\n" unless $::_q;
3662         }
3663         undef;
3664 }
3665
3666 sub open_file {
3667         my ($self, $path, $pb, $rev) = @_;
3668         my ($mode, $blob);
3669
3670         goto out if $self->is_path_ignored($path);
3671
3672         my $gpath = $self->git_path($path);
3673         ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3674                              =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
3675         unless (defined $mode && defined $blob) {
3676                 die "$path was not found in commit $self->{c} (r$rev)\n";
3677         }
3678         if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
3679                 $mode = '120000';
3680         }
3681 out:
3682         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3683           pool => SVN::Pool->new, action => 'M' };
3684 }
3685
3686 sub add_file {
3687         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3688         my $mode;
3689
3690         if (!$self->is_path_ignored($path)) {
3691                 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3692                 delete $self->{empty}->{$dir};
3693                 $mode = '100644';
3694         }
3695         { path => $path, mode_a => $mode, mode_b => $mode,
3696           pool => SVN::Pool->new, action => 'A' };
3697 }
3698
3699 sub add_directory {
3700         my ($self, $path, $cp_path, $cp_rev) = @_;
3701         goto out if $self->is_path_ignored($path);
3702         my $gpath = $self->git_path($path);
3703         if ($gpath eq '') {
3704                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3705                                                      -r --name-only -z/,
3706                                                      $self->{c});
3707                 local $/ = "\0";
3708                 while (<$ls>) {
3709                         chomp;
3710                         $self->{gii}->remove($_);
3711                         print "\tD\t$_\n" unless $::_q;
3712                 }
3713                 command_close_pipe($ls, $ctx);
3714                 $self->{empty}->{$path} = 0;
3715         }
3716         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3717         delete $self->{empty}->{$dir};
3718         $self->{empty}->{$path} = 1;
3719 out:
3720         { path => $path };
3721 }
3722
3723 sub change_dir_prop {
3724         my ($self, $db, $prop, $value) = @_;
3725         return undef if $self->is_path_ignored($db->{path});
3726         $self->{dir_prop}->{$db->{path}} ||= {};
3727         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3728         undef;
3729 }
3730
3731 sub absent_directory {
3732         my ($self, $path, $pb) = @_;
3733         return undef if $self->is_path_ignored($path);
3734         $self->{absent_dir}->{$pb->{path}} ||= [];
3735         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3736         undef;
3737 }
3738
3739 sub absent_file {
3740         my ($self, $path, $pb) = @_;
3741         return undef if $self->is_path_ignored($path);
3742         $self->{absent_file}->{$pb->{path}} ||= [];
3743         push @{$self->{absent_file}->{$pb->{path}}}, $path;
3744         undef;
3745 }
3746
3747 sub change_file_prop {
3748         my ($self, $fb, $prop, $value) = @_;
3749         return undef if $self->is_path_ignored($fb->{path});
3750         if ($prop eq 'svn:executable') {
3751                 if ($fb->{mode_b} != 120000) {
3752                         $fb->{mode_b} = defined $value ? 100755 : 100644;
3753                 }
3754         } elsif ($prop eq 'svn:special') {
3755                 $fb->{mode_b} = defined $value ? 120000 : 100644;
3756         } else {
3757                 $self->{file_prop}->{$fb->{path}} ||= {};
3758                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3759         }
3760         undef;
3761 }
3762
3763 sub apply_textdelta {
3764         my ($self, $fb, $exp) = @_;
3765         return undef if $self->is_path_ignored($fb->{path});
3766         my $fh = $::_repository->temp_acquire('svn_delta');
3767         # $fh gets auto-closed() by SVN::TxDelta::apply(),
3768         # (but $base does not,) so dup() it for reading in close_file
3769         open my $dup, '<&', $fh or croak $!;
3770         my $base = $::_repository->temp_acquire('git_blob');
3771
3772         if ($fb->{blob}) {
3773                 my ($base_is_link, $size);
3774
3775                 if ($fb->{mode_a} eq '120000' &&
3776                     ! $self->{empty_symlinks}->{$fb->{path}}) {
3777                         print $base 'link ' or die "print $!\n";
3778                         $base_is_link = 1;
3779                 }
3780         retry:
3781                 $size = $::_repository->cat_blob($fb->{blob}, $base);
3782                 die "Failed to read object $fb->{blob}" if ($size < 0);
3783
3784                 if (defined $exp) {
3785                         seek $base, 0, 0 or croak $!;
3786                         my $got = ::md5sum($base);
3787                         if ($got ne $exp) {
3788                                 my $err = "Checksum mismatch: ".
3789                                        "$fb->{path} $fb->{blob}\n" .
3790                                        "expected: $exp\n" .
3791                                        "     got: $got\n";
3792                                 if ($base_is_link) {
3793                                         warn $err,
3794                                              "Retrying... (possibly ",
3795                                              "a bad symlink from SVN)\n";
3796                                         $::_repository->temp_reset($base);
3797                                         $base_is_link = 0;
3798                                         goto retry;
3799                                 }
3800                                 die $err;
3801                         }
3802                 }
3803         }
3804         seek $base, 0, 0 or croak $!;
3805         $fb->{fh} = $fh;
3806         $fb->{base} = $base;
3807         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
3808 }
3809
3810 sub close_file {
3811         my ($self, $fb, $exp) = @_;
3812         return undef if $self->is_path_ignored($fb->{path});
3813
3814         my $hash;
3815         my $path = $self->git_path($fb->{path});
3816         if (my $fh = $fb->{fh}) {
3817                 if (defined $exp) {
3818                         seek($fh, 0, 0) or croak $!;
3819                         my $got = ::md5sum($fh);
3820                         if ($got ne $exp) {
3821                                 die "Checksum mismatch: $path\n",
3822                                     "expected: $exp\n    got: $got\n";
3823                         }
3824                 }
3825                 if ($fb->{mode_b} == 120000) {
3826                         sysseek($fh, 0, 0) or croak $!;
3827                         my $rd = sysread($fh, my $buf, 5);
3828
3829                         if (!defined $rd) {
3830                                 croak "sysread: $!\n";
3831                         } elsif ($rd == 0) {
3832                                 warn "$path has mode 120000",
3833                                      " but it points to nothing\n",
3834                                      "converting to an empty file with mode",
3835                                      " 100644\n";
3836                                 $fb->{mode_b} = '100644';
3837                         } elsif ($buf ne 'link ') {
3838                                 warn "$path has mode 120000",
3839                                      " but is not a link\n";
3840                         } else {
3841                                 my $tmp_fh = $::_repository->temp_acquire(
3842                                         'svn_hash');
3843                                 my $res;
3844                                 while ($res = sysread($fh, my $str, 1024)) {
3845                                         my $out = syswrite($tmp_fh, $str, $res);
3846                                         defined($out) && $out == $res
3847                                                 or croak("write ",
3848                                                         Git::temp_path($tmp_fh),
3849                                                         ": $!\n");
3850                                 }
3851                                 defined $res or croak $!;
3852
3853                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
3854                                 Git::temp_release($tmp_fh, 1);
3855                         }
3856                 }
3857
3858                 $hash = $::_repository->hash_and_insert_object(
3859                                 Git::temp_path($fh));
3860                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3861
3862                 Git::temp_release($fb->{base}, 1);
3863                 Git::temp_release($fh, 1);
3864         } else {
3865                 $hash = $fb->{blob} or die "no blob information\n";
3866         }
3867         $fb->{pool}->clear;
3868         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3869         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3870         undef;
3871 }
3872
3873 sub abort_edit {
3874         my $self = shift;
3875         $self->{nr} = $self->{gii}->{nr};
3876         delete $self->{gii};
3877         $self->SUPER::abort_edit(@_);
3878 }
3879
3880 sub close_edit {
3881         my $self = shift;
3882         $self->{git_commit_ok} = 1;
3883         $self->{nr} = $self->{gii}->{nr};
3884         delete $self->{gii};
3885         $self->SUPER::close_edit(@_);
3886 }
3887
3888 package SVN::Git::Editor;
3889 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3890 use strict;
3891 use warnings;
3892 use Carp qw/croak/;
3893 use IO::File;
3894
3895 sub new {
3896         my ($class, $opts) = @_;
3897         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3898                 die "$_ required!\n" unless (defined $opts->{$_});
3899         }
3900
3901         my $pool = SVN::Pool->new;
3902         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3903         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3904                                      $opts->{r}, $mods);
3905
3906         # $opts->{ra} functions should not be used after this:
3907         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
3908                                                 $opts->{editor_cb}, $pool);
3909         my $self = SVN::Delta::Editor->new(@ce, $pool);
3910         bless $self, $class;
3911         foreach (qw/svn_path r tree_a tree_b/) {
3912                 $self->{$_} = $opts->{$_};
3913         }
3914         $self->{url} = $opts->{ra}->{url};
3915         $self->{mods} = $mods;
3916         $self->{types} = $types;
3917         $self->{pool} = $pool;
3918         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3919         $self->{rm} = { };
3920         $self->{path_prefix} = length $self->{svn_path} ?
3921                                "$self->{svn_path}/" : '';
3922         $self->{config} = $opts->{config};
3923         return $self;
3924 }
3925
3926 sub generate_diff {
3927         my ($tree_a, $tree_b) = @_;
3928         my @diff_tree = qw(diff-tree -z -r);
3929         if ($_cp_similarity) {
3930                 push @diff_tree, "-C$_cp_similarity";
3931         } else {
3932                 push @diff_tree, '-C';
3933         }
3934         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3935         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3936         push @diff_tree, $tree_a, $tree_b;
3937         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3938         local $/ = "\0";
3939         my $state = 'meta';
3940         my @mods;
3941         while (<$diff_fh>) {
3942                 chomp $_; # this gets rid of the trailing "\0"
3943                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3944                                         ($::sha1)\s($::sha1)\s
3945                                         ([MTCRAD])\d*$/xo) {
3946                         push @mods, {   mode_a => $1, mode_b => $2,
3947                                         sha1_a => $3, sha1_b => $4,
3948                                         chg => $5 };
3949                         if ($5 =~ /^(?:C|R)$/) {
3950                                 $state = 'file_a';
3951                         } else {
3952                                 $state = 'file_b';
3953                         }
3954                 } elsif ($state eq 'file_a') {
3955                         my $x = $mods[$#mods] or croak "Empty array\n";
3956                         if ($x->{chg} !~ /^(?:C|R)$/) {
3957                                 croak "Error parsing $_, $x->{chg}\n";
3958                         }
3959                         $x->{file_a} = $_;
3960                         $state = 'file_b';
3961                 } elsif ($state eq 'file_b') {
3962                         my $x = $mods[$#mods] or croak "Empty array\n";
3963                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3964                                 croak "Error parsing $_, $x->{chg}\n";
3965                         }
3966                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3967                                 croak "Error parsing $_, $x->{chg}\n";
3968                         }
3969                         $x->{file_b} = $_;
3970                         $state = 'meta';
3971                 } else {
3972                         croak "Error parsing $_\n";
3973                 }
3974         }
3975         command_close_pipe($diff_fh, $ctx);
3976         \@mods;
3977 }
3978
3979 sub check_diff_paths {
3980         my ($ra, $pfx, $rev, $mods) = @_;
3981         my %types;
3982         $pfx .= '/' if length $pfx;
3983
3984         sub type_diff_paths {
3985                 my ($ra, $types, $path, $rev) = @_;
3986                 my @p = split m#/+#, $path;
3987                 my $c = shift @p;
3988                 unless (defined $types->{$c}) {
3989                         $types->{$c} = $ra->check_path($c, $rev);
3990                 }
3991                 while (@p) {
3992                         $c .= '/' . shift @p;
3993                         next if defined $types->{$c};
3994                         $types->{$c} = $ra->check_path($c, $rev);
3995                 }
3996         }
3997
3998         foreach my $m (@$mods) {
3999                 foreach my $f (qw/file_a file_b/) {
4000                         next unless defined $m->{$f};
4001                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
4002                         if (length $pfx.$dir && ! defined $types{$dir}) {
4003                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
4004                         }
4005                 }
4006         }
4007         \%types;
4008 }
4009
4010 sub split_path {
4011         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
4012 }
4013
4014 sub repo_path {
4015         my ($self, $path) = @_;
4016         $self->{path_prefix}.(defined $path ? $path : '');
4017 }
4018
4019 sub url_path {
4020         my ($self, $path) = @_;
4021         if ($self->{url} =~ m#^https?://#) {
4022                 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4023         }
4024         $self->{url} . '/' . $self->repo_path($path);
4025 }
4026
4027 sub rmdirs {
4028         my ($self) = @_;
4029         my $rm = $self->{rm};
4030         delete $rm->{''}; # we never delete the url we're tracking
4031         return unless %$rm;
4032
4033         foreach (keys %$rm) {
4034                 my @d = split m#/#, $_;
4035                 my $c = shift @d;
4036                 $rm->{$c} = 1;
4037                 while (@d) {
4038                         $c .= '/' . shift @d;
4039                         $rm->{$c} = 1;
4040                 }
4041         }
4042         delete $rm->{$self->{svn_path}};
4043         delete $rm->{''}; # we never delete the url we're tracking
4044         return unless %$rm;
4045
4046         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4047                                              $self->{tree_b});
4048         local $/ = "\0";
4049         while (<$fh>) {
4050                 chomp;
4051                 my @dn = split m#/#, $_;
4052                 while (pop @dn) {
4053                         delete $rm->{join '/', @dn};
4054                 }
4055                 unless (%$rm) {
4056                         close $fh;
4057                         return;
4058                 }
4059         }
4060         command_close_pipe($fh, $ctx);
4061
4062         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4063         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4064                 $self->close_directory($bat->{$d}, $p);
4065                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4066                 print "\tD+\t$d/\n" unless $::_q;
4067                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4068                 delete $bat->{$d};
4069         }
4070 }
4071
4072 sub open_or_add_dir {
4073         my ($self, $full_path, $baton) = @_;
4074         my $t = $self->{types}->{$full_path};
4075         if (!defined $t) {
4076                 die "$full_path not known in r$self->{r} or we have a bug!\n";
4077         }
4078         {
4079                 no warnings 'once';
4080                 # SVN::Node::none and SVN::Node::file are used only once,
4081                 # so we're shutting up Perl's warnings about them.
4082                 if ($t == $SVN::Node::none) {
4083                         return $self->add_directory($full_path, $baton,
4084                             undef, -1, $self->{pool});
4085                 } elsif ($t == $SVN::Node::dir) {
4086                         return $self->open_directory($full_path, $baton,
4087                             $self->{r}, $self->{pool});
4088                 } # no warnings 'once'
4089                 print STDERR "$full_path already exists in repository at ",
4090                     "r$self->{r} and it is not a directory (",
4091                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4092         } # no warnings 'once'
4093         exit 1;
4094 }
4095
4096 sub ensure_path {
4097         my ($self, $path) = @_;
4098         my $bat = $self->{bat};
4099         my $repo_path = $self->repo_path($path);
4100         return $bat->{''} unless (length $repo_path);
4101         my @p = split m#/+#, $repo_path;
4102         my $c = shift @p;
4103         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4104         while (@p) {
4105                 my $c0 = $c;
4106                 $c .= '/' . shift @p;
4107                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4108         }
4109         return $bat->{$c};
4110 }
4111
4112 # Subroutine to convert a globbing pattern to a regular expression.
4113 # From perl cookbook.
4114 sub glob2pat {
4115         my $globstr = shift;
4116         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4117         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4118         return '^' . $globstr . '$';
4119 }
4120
4121 sub check_autoprop {
4122         my ($self, $pattern, $properties, $file, $fbat) = @_;
4123         # Convert the globbing pattern to a regular expression.
4124         my $regex = glob2pat($pattern);
4125         # Check if the pattern matches the file name.
4126         if($file =~ m/($regex)/) {
4127                 # Parse the list of properties to set.
4128                 my @props = split(/;/, $properties);
4129                 foreach my $prop (@props) {
4130                         # Parse 'name=value' syntax and set the property.
4131                         if ($prop =~ /([^=]+)=(.*)/) {
4132                                 my ($n,$v) = ($1,$2);
4133                                 for ($n, $v) {
4134                                         s/^\s+//; s/\s+$//;
4135                                 }
4136                                 $self->change_file_prop($fbat, $n, $v);
4137                         }
4138                 }
4139         }
4140 }
4141
4142 sub apply_autoprops {
4143         my ($self, $file, $fbat) = @_;
4144         my $conf_t = ${$self->{config}}{'config'};
4145         no warnings 'once';
4146         # Check [miscellany]/enable-auto-props in svn configuration.
4147         if (SVN::_Core::svn_config_get_bool(
4148                 $conf_t,
4149                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4150                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4151                 0)) {
4152                 # Auto-props are enabled.  Enumerate them to look for matches.
4153                 my $callback = sub {
4154                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
4155                 };
4156                 SVN::_Core::svn_config_enumerate(
4157                         $conf_t,
4158                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4159                         $callback);
4160         }
4161 }
4162
4163 sub A {
4164         my ($self, $m) = @_;
4165         my ($dir, $file) = split_path($m->{file_b});
4166         my $pbat = $self->ensure_path($dir);
4167         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4168                                         undef, -1);
4169         print "\tA\t$m->{file_b}\n" unless $::_q;
4170         $self->apply_autoprops($file, $fbat);
4171         $self->chg_file($fbat, $m);
4172         $self->close_file($fbat,undef,$self->{pool});
4173 }
4174
4175 sub C {
4176         my ($self, $m) = @_;
4177         my ($dir, $file) = split_path($m->{file_b});
4178         my $pbat = $self->ensure_path($dir);
4179         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4180                                 $self->url_path($m->{file_a}), $self->{r});
4181         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4182         $self->chg_file($fbat, $m);
4183         $self->close_file($fbat,undef,$self->{pool});
4184 }
4185
4186 sub delete_entry {
4187         my ($self, $path, $pbat) = @_;
4188         my $rpath = $self->repo_path($path);
4189         my ($dir, $file) = split_path($rpath);
4190         $self->{rm}->{$dir} = 1;
4191         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4192 }
4193
4194 sub R {
4195         my ($self, $m) = @_;
4196         my ($dir, $file) = split_path($m->{file_b});
4197         my $pbat = $self->ensure_path($dir);
4198         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4199                                 $self->url_path($m->{file_a}), $self->{r});
4200         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4201         $self->apply_autoprops($file, $fbat);
4202         $self->chg_file($fbat, $m);
4203         $self->close_file($fbat,undef,$self->{pool});
4204
4205         ($dir, $file) = split_path($m->{file_a});
4206         $pbat = $self->ensure_path($dir);
4207         $self->delete_entry($m->{file_a}, $pbat);
4208 }
4209
4210 sub M {
4211         my ($self, $m) = @_;
4212         my ($dir, $file) = split_path($m->{file_b});
4213         my $pbat = $self->ensure_path($dir);
4214         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4215                                 $pbat,$self->{r},$self->{pool});
4216         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4217         $self->chg_file($fbat, $m);
4218         $self->close_file($fbat,undef,$self->{pool});
4219 }
4220
4221 sub T { shift->M(@_) }
4222
4223 sub change_file_prop {
4224         my ($self, $fbat, $pname, $pval) = @_;
4225         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4226 }
4227
4228 sub _chg_file_get_blob ($$$$) {
4229         my ($self, $fbat, $m, $which) = @_;
4230         my $fh = $::_repository->temp_acquire("git_blob_$which");
4231         if ($m->{"mode_$which"} =~ /^120/) {
4232                 print $fh 'link ' or croak $!;
4233                 $self->change_file_prop($fbat,'svn:special','*');
4234         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4235                 $self->change_file_prop($fbat,'svn:special',undef);
4236         }
4237         my $blob = $m->{"sha1_$which"};
4238         return ($fh,) if ($blob =~ /^0{40}$/);
4239         my $size = $::_repository->cat_blob($blob, $fh);
4240         croak "Failed to read object $blob" if ($size < 0);
4241         $fh->flush == 0 or croak $!;
4242         seek $fh, 0, 0 or croak $!;
4243
4244         my $exp = ::md5sum($fh);
4245         seek $fh, 0, 0 or croak $!;
4246         return ($fh, $exp);
4247 }
4248
4249 sub chg_file {
4250         my ($self, $fbat, $m) = @_;
4251         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4252                 $self->change_file_prop($fbat,'svn:executable','*');
4253         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4254                 $self->change_file_prop($fbat,'svn:executable',undef);
4255         }
4256         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4257         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4258         my $pool = SVN::Pool->new;
4259         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4260         if (-s $fh_a) {
4261                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4262                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4263                 if (defined $res) {
4264                         die "Unexpected result from send_txstream: $res\n",
4265                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4266                 }
4267         } else {
4268                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4269                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4270                     if ($got ne $exp_b);
4271         }
4272         Git::temp_release($fh_b, 1);
4273         Git::temp_release($fh_a, 1);
4274         $pool->clear;
4275 }
4276
4277 sub D {
4278         my ($self, $m) = @_;
4279         my ($dir, $file) = split_path($m->{file_b});
4280         my $pbat = $self->ensure_path($dir);
4281         print "\tD\t$m->{file_b}\n" unless $::_q;
4282         $self->delete_entry($m->{file_b}, $pbat);
4283 }
4284
4285 sub close_edit {
4286         my ($self) = @_;
4287         my ($p,$bat) = ($self->{pool}, $self->{bat});
4288         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4289                 next if $_ eq '';
4290                 $self->close_directory($bat->{$_}, $p);
4291         }
4292         $self->close_directory($bat->{''}, $p);
4293         $self->SUPER::close_edit($p);
4294         $p->clear;
4295 }
4296
4297 sub abort_edit {
4298         my ($self) = @_;
4299         $self->SUPER::abort_edit($self->{pool});
4300 }
4301
4302 sub DESTROY {
4303         my $self = shift;
4304         $self->SUPER::DESTROY(@_);
4305         $self->{pool}->clear;
4306 }
4307
4308 # this drives the editor
4309 sub apply_diff {
4310         my ($self) = @_;
4311         my $mods = $self->{mods};
4312         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4313         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4314                 my $f = $m->{chg};
4315                 if (defined $o{$f}) {
4316                         $self->$f($m);
4317                 } else {
4318                         fatal("Invalid change type: $f");
4319                 }
4320         }
4321         $self->rmdirs if $_rmdir;
4322         if (@$mods == 0) {
4323                 $self->abort_edit;
4324         } else {
4325                 $self->close_edit;
4326         }
4327         return scalar @$mods;
4328 }
4329
4330 package Git::SVN::Ra;
4331 use vars qw/@ISA $config_dir $_log_window_size/;
4332 use strict;
4333 use warnings;
4334 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4335
4336 BEGIN {
4337         # enforce temporary pool usage for some simple functions
4338         no strict 'refs';
4339         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4340                       get_file/) {
4341                 my $SUPER = "SUPER::$f";
4342                 *$f = sub {
4343                         my $self = shift;
4344                         my $pool = SVN::Pool->new;
4345                         my @ret = $self->$SUPER(@_,$pool);
4346                         $pool->clear;
4347                         wantarray ? @ret : $ret[0];
4348                 };
4349         }
4350 }
4351
4352 sub _auth_providers () {
4353         [
4354           SVN::Client::get_simple_provider(),
4355           SVN::Client::get_ssl_server_trust_file_provider(),
4356           SVN::Client::get_simple_prompt_provider(
4357             \&Git::SVN::Prompt::simple, 2),
4358           SVN::Client::get_ssl_client_cert_file_provider(),
4359           SVN::Client::get_ssl_client_cert_prompt_provider(
4360             \&Git::SVN::Prompt::ssl_client_cert, 2),
4361           SVN::Client::get_ssl_client_cert_pw_file_provider(),
4362           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4363             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4364           SVN::Client::get_username_provider(),
4365           SVN::Client::get_ssl_server_trust_prompt_provider(
4366             \&Git::SVN::Prompt::ssl_server_trust),
4367           SVN::Client::get_username_prompt_provider(
4368             \&Git::SVN::Prompt::username, 2)
4369         ]
4370 }
4371
4372 sub escape_uri_only {
4373         my ($uri) = @_;
4374         my @tmp;
4375         foreach (split m{/}, $uri) {
4376                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4377                 push @tmp, $_;
4378         }
4379         join('/', @tmp);
4380 }
4381
4382 sub escape_url {
4383         my ($url) = @_;
4384         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4385                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4386                 $url = "$scheme://$domain$uri";
4387         }
4388         $url;
4389 }
4390
4391 sub new {
4392         my ($class, $url) = @_;
4393         $url =~ s!/+$!!;
4394         return $RA if ($RA && $RA->{url} eq $url);
4395
4396         SVN::_Core::svn_config_ensure($config_dir, undef);
4397         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4398         my $config = SVN::Core::config_get_config($config_dir);
4399         $RA = undef;
4400         my $dont_store_passwords = 1;
4401         my $conf_t = ${$config}{'config'};
4402         {
4403                 no warnings 'once';
4404                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4405                 # produces warnings that variables are used only once.
4406                 # I had not found the better way to shut them up, so
4407                 # the warnings of type 'once' are disabled in this block.
4408                 if (SVN::_Core::svn_config_get_bool($conf_t,
4409                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4410                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4411                     1) == 0) {
4412                         SVN::_Core::svn_auth_set_parameter($baton,
4413                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4414                             bless (\$dont_store_passwords, "_p_void"));
4415                 }
4416                 if (SVN::_Core::svn_config_get_bool($conf_t,
4417                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4418                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4419                     1) == 0) {
4420                         $Git::SVN::Prompt::_no_auth_cache = 1;
4421                 }
4422         } # no warnings 'once'
4423         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4424                               config => $config,
4425                               pool => SVN::Pool->new,
4426                               auth_provider_callbacks => $callbacks);
4427         $self->{url} = $url;
4428         $self->{svn_path} = $url;
4429         $self->{repos_root} = $self->get_repos_root;
4430         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4431         $self->{cache} = { check_path => { r => 0, data => {} },
4432                            get_dir => { r => 0, data => {} } };
4433         $RA = bless $self, $class;
4434 }
4435
4436 sub check_path {
4437         my ($self, $path, $r) = @_;
4438         my $cache = $self->{cache}->{check_path};
4439         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4440                 return $cache->{data}->{$path};
4441         }
4442         my $pool = SVN::Pool->new;
4443         my $t = $self->SUPER::check_path($path, $r, $pool);
4444         $pool->clear;
4445         if ($r != $cache->{r}) {
4446                 %{$cache->{data}} = ();
4447                 $cache->{r} = $r;
4448         }
4449         $cache->{data}->{$path} = $t;
4450 }
4451
4452 sub get_dir {
4453         my ($self, $dir, $r) = @_;
4454         my $cache = $self->{cache}->{get_dir};
4455         if ($r == $cache->{r}) {
4456                 if (my $x = $cache->{data}->{$dir}) {
4457                         return wantarray ? @$x : $x->[0];
4458                 }
4459         }
4460         my $pool = SVN::Pool->new;
4461         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4462         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4463         $pool->clear;
4464         if ($r != $cache->{r}) {
4465                 %{$cache->{data}} = ();
4466                 $cache->{r} = $r;
4467         }
4468         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
4469         wantarray ? (\%dirents, $r, $props) : \%dirents;
4470 }
4471
4472 sub DESTROY {
4473         # do not call the real DESTROY since we store ourselves in $RA
4474 }
4475
4476 # get_log(paths, start, end, limit,
4477 #         discover_changed_paths, strict_node_history, receiver)
4478 sub get_log {
4479         my ($self, @args) = @_;
4480         my $pool = SVN::Pool->new;
4481
4482         # svn_log_changed_path_t objects passed to get_log are likely to be
4483         # overwritten even if only the refs are copied to an external variable,
4484         # so we should dup the structures in their entirety.  Using an
4485         # externally passed pool (instead of our temporary and quickly cleared
4486         # pool in Git::SVN::Ra) does not help matters at all...
4487         my $receiver = pop @args;
4488         my $prefix = "/".$self->{svn_path};
4489         $prefix =~ s#/+($)##;
4490         my $prefix_regex = qr#^\Q$prefix\E#;
4491         push(@args, sub {
4492                 my ($paths) = $_[0];
4493                 return &$receiver(@_) unless $paths;
4494                 $_[0] = ();
4495                 foreach my $p (keys %$paths) {
4496                         my $i = $paths->{$p};
4497                         # Make path relative to our url, not repos_root
4498                         $p =~ s/$prefix_regex//;
4499                         my %s = map { $_ => $i->$_; }
4500                                 qw/copyfrom_path copyfrom_rev action/;
4501                         if ($s{'copyfrom_path'}) {
4502                                 $s{'copyfrom_path'} =~ s/$prefix_regex//;
4503                         }
4504                         $_[0]{$p} = \%s;
4505                 }
4506                 &$receiver(@_);
4507         });
4508
4509
4510         # the limit parameter was not supported in SVN 1.1.x, so we
4511         # drop it.  Therefore, the receiver callback passed to it
4512         # is made aware of this limitation by being wrapped if
4513         # the limit passed to is being wrapped.
4514         if ($SVN::Core::VERSION le '1.2.0') {
4515                 my $limit = splice(@args, 3, 1);
4516                 if ($limit > 0) {
4517                         my $receiver = pop @args;
4518                         push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
4519                 }
4520         }
4521         my $ret = $self->SUPER::get_log(@args, $pool);
4522         $pool->clear;
4523         $ret;
4524 }
4525
4526 sub trees_match {
4527         my ($self, $url1, $rev1, $url2, $rev2) = @_;
4528         my $ctx = SVN::Client->new(auth => _auth_providers);
4529         my $out = IO::File->new_tmpfile;
4530
4531         # older SVN (1.1.x) doesn't take $pool as the last parameter for
4532         # $ctx->diff(), so we'll create a default one
4533         my $pool = SVN::Pool->new_default_sub;
4534
4535         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
4536         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
4537         $out->flush;
4538         my $ret = (($out->stat)[7] == 0);
4539         close $out or croak $!;
4540
4541         $ret;
4542 }
4543
4544 sub get_commit_editor {
4545         my ($self, $log, $cb, $pool) = @_;
4546         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
4547         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
4548 }
4549
4550 sub gs_do_update {
4551         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
4552         my $new = ($rev_a == $rev_b);
4553         my $path = $gs->{path};
4554
4555         if ($new && -e $gs->{index}) {
4556                 unlink $gs->{index} or die
4557                   "Couldn't unlink index: $gs->{index}: $!\n";
4558         }
4559         my $pool = SVN::Pool->new;
4560         $editor->set_path_strip($path);
4561         my (@pc) = split m#/#, $path;
4562         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
4563                                         1, $editor, $pool);
4564         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4565
4566         # Since we can't rely on svn_ra_reparent being available, we'll
4567         # just have to do some magic with set_path to make it so
4568         # we only want a partial path.
4569         my $sp = '';
4570         my $final = join('/', @pc);
4571         while (@pc) {
4572                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
4573                 $sp .= '/' if length $sp;
4574                 $sp .= shift @pc;
4575         }
4576         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
4577
4578         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
4579
4580         $reporter->finish_report($pool);
4581         $pool->clear;
4582         $editor->{git_commit_ok};
4583 }
4584
4585 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
4586 # svn_ra_reparent didn't work before 1.4)
4587 sub gs_do_switch {
4588         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
4589         my $path = $gs->{path};
4590         my $pool = SVN::Pool->new;
4591
4592         my $full_url = $self->{url};
4593         my $old_url = $full_url;
4594         $full_url .= '/' . $path if length $path;
4595         my ($ra, $reparented);
4596
4597         if ($old_url =~ m#^svn(\+ssh)?://# ||
4598             ($full_url =~ m#^https?://# &&
4599              escape_url($full_url) ne $full_url)) {
4600                 $_[0] = undef;
4601                 $self = undef;
4602                 $RA = undef;
4603                 $ra = Git::SVN::Ra->new($full_url);
4604                 $ra_invalid = 1;
4605         } elsif ($old_url ne $full_url) {
4606                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
4607                 $self->{url} = $full_url;
4608                 $reparented = 1;
4609         }
4610
4611         $ra ||= $self;
4612         $url_b = escape_url($url_b);
4613         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
4614         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4615         $reporter->set_path('', $rev_a, 0, @lock, $pool);
4616         $reporter->finish_report($pool);
4617
4618         if ($reparented) {
4619                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
4620                 $self->{url} = $old_url;
4621         }
4622
4623         $pool->clear;
4624         $editor->{git_commit_ok};
4625 }
4626
4627 sub longest_common_path {
4628         my ($gsv, $globs) = @_;
4629         my %common;
4630         my $common_max = scalar @$gsv;
4631
4632         foreach my $gs (@$gsv) {
4633                 my @tmp = split m#/#, $gs->{path};
4634                 my $p = '';
4635                 foreach (@tmp) {
4636                         $p .= length($p) ? "/$_" : $_;
4637                         $common{$p} ||= 0;
4638                         $common{$p}++;
4639                 }
4640         }
4641         $globs ||= [];
4642         $common_max += scalar @$globs;
4643         foreach my $glob (@$globs) {
4644                 my @tmp = split m#/#, $glob->{path}->{left};
4645                 my $p = '';
4646                 foreach (@tmp) {
4647                         $p .= length($p) ? "/$_" : $_;
4648                         $common{$p} ||= 0;
4649                         $common{$p}++;
4650                 }
4651         }
4652
4653         my $longest_path = '';
4654         foreach (sort {length $b <=> length $a} keys %common) {
4655                 if ($common{$_} == $common_max) {
4656                         $longest_path = $_;
4657                         last;
4658                 }
4659         }
4660         $longest_path;
4661 }
4662
4663 sub gs_fetch_loop_common {
4664         my ($self, $base, $head, $gsv, $globs) = @_;
4665         return if ($base > $head);
4666         my $inc = $_log_window_size;
4667         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
4668         my $longest_path = longest_common_path($gsv, $globs);
4669         my $ra_url = $self->{url};
4670         my $find_trailing_edge;
4671         while (1) {
4672                 my %revs;
4673                 my $err;
4674                 my $err_handler = $SVN::Error::handler;
4675                 $SVN::Error::handler = sub {
4676                         ($err) = @_;
4677                         skip_unknown_revs($err);
4678                 };
4679                 sub _cb {
4680                         my ($paths, $r, $author, $date, $log) = @_;
4681                         [ $paths,
4682                           { author => $author, date => $date, log => $log } ];
4683                 }
4684                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
4685                                sub { $revs{$_[1]} = _cb(@_) });
4686                 if ($err) {
4687                         print "Checked through r$max\r";
4688                 } else {
4689                         $find_trailing_edge = 1;
4690                 }
4691                 if ($err and $find_trailing_edge) {
4692                         print STDERR "Path '$longest_path' ",
4693                                      "was probably deleted:\n",
4694                                      $err->expanded_message,
4695                                      "\nWill attempt to follow ",
4696                                      "revisions r$min .. r$max ",
4697                                      "committed before the deletion\n";
4698                         my $hi = $max;
4699                         while (--$hi >= $min) {
4700                                 my $ok;
4701                                 $self->get_log([$longest_path], $min, $hi,
4702                                                0, 1, 1, sub {
4703                                                $ok = $_[1];
4704                                                $revs{$_[1]} = _cb(@_) });
4705                                 if ($ok) {
4706                                         print STDERR "r$min .. r$ok OK\n";
4707                                         last;
4708                                 }
4709                         }
4710                         $find_trailing_edge = 0;
4711                 }
4712                 $SVN::Error::handler = $err_handler;
4713
4714                 my %exists = map { $_->{path} => $_ } @$gsv;
4715                 foreach my $r (sort {$a <=> $b} keys %revs) {
4716                         my ($paths, $logged) = @{$revs{$r}};
4717
4718                         foreach my $gs ($self->match_globs(\%exists, $paths,
4719                                                            $globs, $r)) {
4720                                 if ($gs->rev_map_max >= $r) {
4721                                         next;
4722                                 }
4723                                 next unless $gs->match_paths($paths, $r);
4724                                 $gs->{logged_rev_props} = $logged;
4725                                 if (my $last_commit = $gs->last_commit) {
4726                                         $gs->assert_index_clean($last_commit);
4727                                 }
4728                                 my $log_entry = $gs->do_fetch($paths, $r);
4729                                 if ($log_entry) {
4730                                         $gs->do_git_commit($log_entry);
4731                                 }
4732                                 $INDEX_FILES{$gs->{index}} = 1;
4733                         }
4734                         foreach my $g (@$globs) {
4735                                 my $k = "svn-remote.$g->{remote}." .
4736                                         "$g->{t}-maxRev";
4737                                 Git::SVN::tmp_config($k, $r);
4738                         }
4739                         if ($ra_invalid) {
4740                                 $_[0] = undef;
4741                                 $self = undef;
4742                                 $RA = undef;
4743                                 $self = Git::SVN::Ra->new($ra_url);
4744                                 $ra_invalid = undef;
4745                         }
4746                 }
4747                 # pre-fill the .rev_db since it'll eventually get filled in
4748                 # with '0' x40 if something new gets committed
4749                 foreach my $gs (@$gsv) {
4750                         next if $gs->rev_map_max >= $max;
4751                         next if defined $gs->rev_map_get($max);
4752                         $gs->rev_map_set($max, 0 x40);
4753                 }
4754                 foreach my $g (@$globs) {
4755                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
4756                         Git::SVN::tmp_config($k, $max);
4757                 }
4758                 last if $max >= $head;
4759                 $min = $max + 1;
4760                 $max += $inc;
4761                 $max = $head if ($max > $head);
4762         }
4763         Git::SVN::gc();
4764 }
4765
4766 sub get_dir_globbed {
4767         my ($self, $left, $depth, $r) = @_;
4768
4769         my @x = eval { $self->get_dir($left, $r) };
4770         return unless scalar @x == 3;
4771         my $dirents = $x[0];
4772         my @finalents;
4773         foreach my $de (keys %$dirents) {
4774                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4775                 if ($depth > 1) {
4776                         my @args = ("$left/$de", $depth - 1, $r);
4777                         foreach my $dir ($self->get_dir_globbed(@args)) {
4778                                 push @finalents, "$de/$dir";
4779                         }
4780                 } else {
4781                         push @finalents, $de;
4782                 }
4783         }
4784         @finalents;
4785 }
4786
4787 sub match_globs {
4788         my ($self, $exists, $paths, $globs, $r) = @_;
4789
4790         sub get_dir_check {
4791                 my ($self, $exists, $g, $r) = @_;
4792
4793                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
4794                                                   $g->{path}->{depth},
4795                                                   $r);
4796
4797                 foreach my $de (@dirs) {
4798                         my $p = $g->{path}->full_path($de);
4799                         next if $exists->{$p};
4800                         next if (length $g->{path}->{right} &&
4801                                  ($self->check_path($p, $r) !=
4802                                   $SVN::Node::dir));
4803                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4804                                          $g->{ref}->full_path($de), 1);
4805                 }
4806         }
4807         foreach my $g (@$globs) {
4808                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4809                         if ($path->{action} =~ /^[AR]$/) {
4810                                 get_dir_check($self, $exists, $g, $r);
4811                         }
4812                 }
4813                 foreach (keys %$paths) {
4814                         if (/$g->{path}->{left_regex}/ &&
4815                             !/$g->{path}->{regex}/) {
4816                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
4817                                 get_dir_check($self, $exists, $g, $r);
4818                         }
4819                         next unless /$g->{path}->{regex}/;
4820                         my $p = $1;
4821                         my $pathname = $g->{path}->full_path($p);
4822                         next if $exists->{$pathname};
4823                         next if ($self->check_path($pathname, $r) !=
4824                                  $SVN::Node::dir);
4825                         $exists->{$pathname} = Git::SVN->init(
4826                                               $self->{url}, $pathname, undef,
4827                                               $g->{ref}->full_path($p), 1);
4828                 }
4829                 my $c = '';
4830                 foreach (split m#/#, $g->{path}->{left}) {
4831                         $c .= "/$_";
4832                         next unless ($paths->{$c} &&
4833                                      ($paths->{$c}->{action} =~ /^[AR]$/));
4834                         get_dir_check($self, $exists, $g, $r);
4835                 }
4836         }
4837         values %$exists;
4838 }
4839
4840 sub minimize_url {
4841         my ($self) = @_;
4842         return $self->{url} if ($self->{url} eq $self->{repos_root});
4843         my $url = $self->{repos_root};
4844         my @components = split(m!/!, $self->{svn_path});
4845         my $c = '';
4846         do {
4847                 $url .= "/$c" if length $c;
4848                 eval {
4849                         my $ra = (ref $self)->new($url);
4850                         my $latest = $ra->get_latest_revnum;
4851                         $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
4852                 };
4853         } while ($@ && ($c = shift @components));
4854         $url;
4855 }
4856
4857 sub can_do_switch {
4858         my $self = shift;
4859         unless (defined $can_do_switch) {
4860                 my $pool = SVN::Pool->new;
4861                 my $rep = eval {
4862                         $self->do_switch(1, '', 0, $self->{url},
4863                                          SVN::Delta::Editor->new, $pool);
4864                 };
4865                 if ($@) {
4866                         $can_do_switch = 0;
4867                 } else {
4868                         $rep->abort_report($pool);
4869                         $can_do_switch = 1;
4870                 }
4871                 $pool->clear;
4872         }
4873         $can_do_switch;
4874 }
4875
4876 sub skip_unknown_revs {
4877         my ($err) = @_;
4878         my $errno = $err->apr_err();
4879         # Maybe the branch we're tracking didn't
4880         # exist when the repo started, so it's
4881         # not an error if it doesn't, just continue
4882         #
4883         # Wonderfully consistent library, eh?
4884         # 160013 - svn:// and file://
4885         # 175002 - http(s)://
4886         # 175007 - http(s):// (this repo required authorization, too...)
4887         #   More codes may be discovered later...
4888         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4889                 my $err_key = $err->expanded_message;
4890                 # revision numbers change every time, filter them out
4891                 $err_key =~ s/\d+/\0/g;
4892                 $err_key = "$errno\0$err_key";
4893                 unless ($ignored_err{$err_key}) {
4894                         warn "W: Ignoring error from SVN, path probably ",
4895                              "does not exist: ($errno): ",
4896                              $err->expanded_message,"\n";
4897                         warn "W: Do not be alarmed at the above message ",
4898                              "git-svn is just searching aggressively for ",
4899                              "old history.\n",
4900                              "This may take a while on large repositories\n";
4901                         $ignored_err{$err_key} = 1;
4902                 }
4903                 return;
4904         }
4905         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4906 }
4907
4908 package Git::SVN::Log;
4909 use strict;
4910 use warnings;
4911 use POSIX qw/strftime/;
4912 use Time::Local;
4913 use constant commit_log_separator => ('-' x 72) . "\n";
4914 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4915             %rusers $show_commit $incremental/;
4916 my $l_fmt;
4917
4918 sub cmt_showable {
4919         my ($c) = @_;
4920         return 1 if defined $c->{r};
4921
4922         # big commit message got truncated by the 16k pretty buffer in rev-list
4923         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4924                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4925                 @{$c->{l}} = ();
4926                 my @log = command(qw/cat-file commit/, $c->{c});
4927
4928                 # shift off the headers
4929                 shift @log while ($log[0] ne '');
4930                 shift @log;
4931
4932                 # TODO: make $c->{l} not have a trailing newline in the future
4933                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4934
4935                 (undef, $c->{r}, undef) = ::extract_metadata(
4936                                 (grep(/^git-svn-id: /, @log))[-1]);
4937         }
4938         return defined $c->{r};
4939 }
4940
4941 sub log_use_color {
4942         return $color || Git->repository->get_colorbool('color.diff');
4943 }
4944
4945 sub git_svn_log_cmd {
4946         my ($r_min, $r_max, @args) = @_;
4947         my $head = 'HEAD';
4948         my (@files, @log_opts);
4949         foreach my $x (@args) {
4950                 if ($x eq '--' || @files) {
4951                         push @files, $x;
4952                 } else {
4953                         if (::verify_ref("$x^0")) {
4954                                 $head = $x;
4955                         } else {
4956                                 push @log_opts, $x;
4957                         }
4958                 }
4959         }
4960
4961         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4962         $gs ||= Git::SVN->_new;
4963         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4964                    $gs->refname);
4965         push @cmd, '-r' unless $non_recursive;
4966         push @cmd, qw/--raw --name-status/ if $verbose;
4967         push @cmd, '--color' if log_use_color();
4968         push @cmd, @log_opts;
4969         if (defined $r_max && $r_max == $r_min) {
4970                 push @cmd, '--max-count=1';
4971                 if (my $c = $gs->rev_map_get($r_max)) {
4972                         push @cmd, $c;
4973                 }
4974         } elsif (defined $r_max) {
4975                 if ($r_max < $r_min) {
4976                         ($r_min, $r_max) = ($r_max, $r_min);
4977                 }
4978                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4979                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4980                 # If there are no commits in the range, both $c_max and $c_min
4981                 # will be undefined.  If there is at least 1 commit in the
4982                 # range, both will be defined.
4983                 return () if !defined $c_min || !defined $c_max;
4984                 if ($c_min eq $c_max) {
4985                         push @cmd, '--max-count=1', $c_min;
4986                 } else {
4987                         push @cmd, '--boundary', "$c_min..$c_max";
4988                 }
4989         }
4990         return (@cmd, @files);
4991 }
4992
4993 # adapted from pager.c
4994 sub config_pager {
4995         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4996         if (!defined $pager) {
4997                 $pager = 'less';
4998         } elsif (length $pager == 0 || $pager eq 'cat') {
4999                 $pager = undef;
5000         }
5001         $ENV{GIT_PAGER_IN_USE} = defined($pager);
5002 }
5003
5004 sub run_pager {
5005         return unless -t *STDOUT && defined $pager;
5006         pipe my ($rfd, $wfd) or return;
5007         defined(my $pid = fork) or ::fatal "Can't fork: $!";
5008         if (!$pid) {
5009                 open STDOUT, '>&', $wfd or
5010                                      ::fatal "Can't redirect to stdout: $!";
5011                 return;
5012         }
5013         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5014         $ENV{LESS} ||= 'FRSX';
5015         exec $pager or ::fatal "Can't run pager: $! ($pager)";
5016 }
5017
5018 sub format_svn_date {
5019         # some systmes don't handle or mishandle %z, so be creative.
5020         my $t = shift || time;
5021         my $gm = timelocal(gmtime($t));
5022         my $sign = qw( + + - )[ $t <=> $gm ];
5023         my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5024         return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5025 }
5026
5027 sub parse_git_date {
5028         my ($t, $tz) = @_;
5029         # Date::Parse isn't in the standard Perl distro :(
5030         if ($tz =~ s/^\+//) {
5031                 $t += tz_to_s_offset($tz);
5032         } elsif ($tz =~ s/^\-//) {
5033                 $t -= tz_to_s_offset($tz);
5034         }
5035         return $t;
5036 }
5037
5038 sub set_local_timezone {
5039         if (defined $TZ) {
5040                 $ENV{TZ} = $TZ;
5041         } else {
5042                 delete $ENV{TZ};
5043         }
5044 }
5045
5046 sub tz_to_s_offset {
5047         my ($tz) = @_;
5048         $tz =~ s/(\d\d)$//;
5049         return ($1 * 60) + ($tz * 3600);
5050 }
5051
5052 sub get_author_info {
5053         my ($dest, $author, $t, $tz) = @_;
5054         $author =~ s/(?:^\s*|\s*$)//g;
5055         $dest->{a_raw} = $author;
5056         my $au;
5057         if ($::_authors) {
5058                 $au = $rusers{$author} || undef;
5059         }
5060         if (!$au) {
5061                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5062         }
5063         $dest->{t} = $t;
5064         $dest->{tz} = $tz;
5065         $dest->{a} = $au;
5066         $dest->{t_utc} = parse_git_date($t, $tz);
5067 }
5068
5069 sub process_commit {
5070         my ($c, $r_min, $r_max, $defer) = @_;
5071         if (defined $r_min && defined $r_max) {
5072                 if ($r_min == $c->{r} && $r_min == $r_max) {
5073                         show_commit($c);
5074                         return 0;
5075                 }
5076                 return 1 if $r_min == $r_max;
5077                 if ($r_min < $r_max) {
5078                         # we need to reverse the print order
5079                         return 0 if (defined $limit && --$limit < 0);
5080                         push @$defer, $c;
5081                         return 1;
5082                 }
5083                 if ($r_min != $r_max) {
5084                         return 1 if ($r_min < $c->{r});
5085                         return 1 if ($r_max > $c->{r});
5086                 }
5087         }
5088         return 0 if (defined $limit && --$limit < 0);
5089         show_commit($c);
5090         return 1;
5091 }
5092
5093 sub show_commit {
5094         my $c = shift;
5095         if ($oneline) {
5096                 my $x = "\n";
5097                 if (my $l = $c->{l}) {
5098                         while ($l->[0] =~ /^\s*$/) { shift @$l }
5099                         $x = $l->[0];
5100                 }
5101                 $l_fmt ||= 'A' . length($c->{r});
5102                 print 'r',pack($l_fmt, $c->{r}),' | ';
5103                 print "$c->{c} | " if $show_commit;
5104                 print $x;
5105         } else {
5106                 show_commit_normal($c);
5107         }
5108 }
5109
5110 sub show_commit_changed_paths {
5111         my ($c) = @_;
5112         return unless $c->{changed};
5113         print "Changed paths:\n", @{$c->{changed}};
5114 }
5115
5116 sub show_commit_normal {
5117         my ($c) = @_;
5118         print commit_log_separator, "r$c->{r} | ";
5119         print "$c->{c} | " if $show_commit;
5120         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5121         my $nr_line = 0;
5122
5123         if (my $l = $c->{l}) {
5124                 while ($l->[$#$l] eq "\n" && $#$l > 0
5125                                           && $l->[($#$l - 1)] eq "\n") {
5126                         pop @$l;
5127                 }
5128                 $nr_line = scalar @$l;
5129                 if (!$nr_line) {
5130                         print "1 line\n\n\n";
5131                 } else {
5132                         if ($nr_line == 1) {
5133                                 $nr_line = '1 line';
5134                         } else {
5135                                 $nr_line .= ' lines';
5136                         }
5137                         print $nr_line, "\n";
5138                         show_commit_changed_paths($c);
5139                         print "\n";
5140                         print $_ foreach @$l;
5141                 }
5142         } else {
5143                 print "1 line\n";
5144                 show_commit_changed_paths($c);
5145                 print "\n";
5146
5147         }
5148         foreach my $x (qw/raw stat diff/) {
5149                 if ($c->{$x}) {
5150                         print "\n";
5151                         print $_ foreach @{$c->{$x}}
5152                 }
5153         }
5154 }
5155
5156 sub cmd_show_log {
5157         my (@args) = @_;
5158         my ($r_min, $r_max);
5159         my $r_last = -1; # prevent dupes
5160         set_local_timezone();
5161         if (defined $::_revision) {
5162                 if ($::_revision =~ /^(\d+):(\d+)$/) {
5163                         ($r_min, $r_max) = ($1, $2);
5164                 } elsif ($::_revision =~ /^\d+$/) {
5165                         $r_min = $r_max = $::_revision;
5166                 } else {
5167                         ::fatal "-r$::_revision is not supported, use ",
5168                                 "standard 'git log' arguments instead";
5169                 }
5170         }
5171
5172         config_pager();
5173         @args = git_svn_log_cmd($r_min, $r_max, @args);
5174         if (!@args) {
5175                 print commit_log_separator unless $incremental || $oneline;
5176                 return;
5177         }
5178         my $log = command_output_pipe(@args);
5179         run_pager();
5180         my (@k, $c, $d, $stat);
5181         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5182         while (<$log>) {
5183                 if (/^${esc_color}commit -?($::sha1_short)/o) {
5184                         my $cmt = $1;
5185                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5186                                 $r_last = $c->{r};
5187                                 process_commit($c, $r_min, $r_max, \@k) or
5188                                                                 goto out;
5189                         }
5190                         $d = undef;
5191                         $c = { c => $cmt };
5192                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5193                         get_author_info($c, $1, $2, $3);
5194                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5195                         # ignore
5196                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5197                         push @{$c->{raw}}, $_;
5198                 } elsif (/^${esc_color}[ACRMDT]\t/) {
5199                         # we could add $SVN->{svn_path} here, but that requires
5200                         # remote access at the moment (repo_path_split)...
5201                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
5202                         push @{$c->{changed}}, $_;
5203                 } elsif (/^${esc_color}diff /o) {
5204                         $d = 1;
5205                         push @{$c->{diff}}, $_;
5206                 } elsif ($d) {
5207                         push @{$c->{diff}}, $_;
5208                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5209                           $esc_color*[\+\-]*$esc_color$/x) {
5210                         $stat = 1;
5211                         push @{$c->{stat}}, $_;
5212                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5213                         push @{$c->{stat}}, $_;
5214                         $stat = undef;
5215                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
5216                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5217                 } elsif (s/^${esc_color}    //o) {
5218                         push @{$c->{l}}, $_;
5219                 }
5220         }
5221         if ($c && defined $c->{r} && $c->{r} != $r_last) {
5222                 $r_last = $c->{r};
5223                 process_commit($c, $r_min, $r_max, \@k);
5224         }
5225         if (@k) {
5226                 ($r_min, $r_max) = ($r_max, $r_min);
5227                 process_commit($_, $r_min, $r_max) foreach reverse @k;
5228         }
5229 out:
5230         close $log;
5231         print commit_log_separator unless $incremental || $oneline;
5232 }
5233
5234 sub cmd_blame {
5235         my $path = pop;
5236
5237         config_pager();
5238         run_pager();
5239
5240         my ($fh, $ctx, $rev);
5241
5242         if ($_git_format) {
5243                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5244                 while (my $line = <$fh>) {
5245                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5246                                 # Uncommitted edits show up as a rev ID of
5247                                 # all zeros, which we can't look up with
5248                                 # cmt_metadata
5249                                 if ($1 !~ /^0+$/) {
5250                                         (undef, $rev, undef) =
5251                                                 ::cmt_metadata($1);
5252                                         $rev = '0' if (!$rev);
5253                                 } else {
5254                                         $rev = '0';
5255                                 }
5256                                 $rev = sprintf('%-10s', $rev);
5257                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5258                         }
5259                         print $line;
5260                 }
5261         } else {
5262                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5263                                                   '--', $path);
5264                 my ($sha1);
5265                 my %authors;
5266                 my @buffer;
5267                 my %dsha; #distinct sha keys
5268
5269                 while (my $line = <$fh>) {
5270                         push @buffer, $line;
5271                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5272                                 $dsha{$1} = 1;
5273                         }
5274                 }
5275
5276                 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5277
5278                 foreach my $line (@buffer) {
5279                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5280                                 $rev = $s2r->{$1};
5281                                 $rev = '0' if (!$rev)
5282                         }
5283                         elsif ($line =~ /^author (.*)/) {
5284                                 $authors{$rev} = $1;
5285                                 $authors{$rev} =~ s/\s/_/g;
5286                         }
5287                         elsif ($line =~ /^\t(.*)$/) {
5288                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5289                         }
5290                 }
5291         }
5292         command_close_pipe($fh, $ctx);
5293 }
5294
5295 package Git::SVN::Migration;
5296 # these version numbers do NOT correspond to actual version numbers
5297 # of git nor git-svn.  They are just relative.
5298 #
5299 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5300 #
5301 # v1 layout: .git/$id/info/url, refs/remotes/$id
5302 #
5303 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5304 #
5305 # v3 layout: .git/svn/$id, refs/remotes/$id
5306 #            - info/url may remain for backwards compatibility
5307 #            - this is what we migrate up to this layout automatically,
5308 #            - this will be used by git svn init on single branches
5309 # v3.1 layout (auto migrated):
5310 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5311 #              for backwards compatibility
5312 #
5313 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5314 #            - this is only created for newly multi-init-ed
5315 #              repositories.  Similar in spirit to the
5316 #              --use-separate-remotes option in git-clone (now default)
5317 #            - we do not automatically migrate to this (following
5318 #              the example set by core git)
5319 #
5320 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5321 #            - newer, more-efficient format that uses 24-bytes per record
5322 #              with no filler space.
5323 #            - use xxd -c24 < .rev_map.$UUID to view and debug
5324 #            - This is a one-way migration, repositories updated to the
5325 #              new format will not be able to use old git-svn without
5326 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
5327 #              possible if noMetadata or useSvmProps are set; but should
5328 #              be no problem for users that use the (sensible) defaults.
5329 use strict;
5330 use warnings;
5331 use Carp qw/croak/;
5332 use File::Path qw/mkpath/;
5333 use File::Basename qw/dirname basename/;
5334 use vars qw/$_minimize/;
5335
5336 sub migrate_from_v0 {
5337         my $git_dir = $ENV{GIT_DIR};
5338         return undef unless -d $git_dir;
5339         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5340         my $migrated = 0;
5341         while (<$fh>) {
5342                 chomp;
5343                 my ($id, $orig_ref) = ($_, $_);
5344                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5345                 next unless -f "$git_dir/$id/info/url";
5346                 my $new_ref = "refs/remotes/$id";
5347                 if (::verify_ref("$new_ref^0")) {
5348                         print STDERR "W: $orig_ref is probably an old ",
5349                                      "branch used by an ancient version of ",
5350                                      "git-svn.\n",
5351                                      "However, $new_ref also exists.\n",
5352                                      "We will not be able ",
5353                                      "to use this branch until this ",
5354                                      "ambiguity is resolved.\n";
5355                         next;
5356                 }
5357                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5358                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5359                 command_noisy('update-ref', $new_ref, $orig_ref);
5360                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5361                 $migrated++;
5362         }
5363         command_close_pipe($fh, $ctx);
5364         print STDERR "Done migrating from v0 layout...\n" if $migrated;
5365         $migrated;
5366 }
5367
5368 sub migrate_from_v1 {
5369         my $git_dir = $ENV{GIT_DIR};
5370         my $migrated = 0;
5371         return $migrated unless -d $git_dir;
5372         my $svn_dir = "$git_dir/svn";
5373
5374         # just in case somebody used 'svn' as their $id at some point...
5375         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5376
5377         print STDERR "Migrating from a git-svn v1 layout...\n";
5378         mkpath([$svn_dir]);
5379         print STDERR "Data from a previous version of git-svn exists, but\n\t",
5380                      "$svn_dir\n\t(required for this version ",
5381                      "($::VERSION) of git-svn) does not exist.\n";
5382         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5383         while (<$fh>) {
5384                 my $x = $_;
5385                 next unless $x =~ s#^refs/remotes/##;
5386                 chomp $x;
5387                 next unless -f "$git_dir/$x/info/url";
5388                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5389                 next unless $u;
5390                 my $dn = dirname("$git_dir/svn/$x");
5391                 mkpath([$dn]) unless -d $dn;
5392                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5393                         mkpath(["$git_dir/svn/svn"]);
5394                         print STDERR " - $git_dir/$x/info => ",
5395                                         "$git_dir/svn/$x/info\n";
5396                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5397                                croak "$!: $x";
5398                         # don't worry too much about these, they probably
5399                         # don't exist with repos this old (save for index,
5400                         # and we can easily regenerate that)
5401                         foreach my $f (qw/unhandled.log index .rev_db/) {
5402                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5403                         }
5404                 } else {
5405                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5406                         rename "$git_dir/$x", "$git_dir/svn/$x" or
5407                                croak "$!: $x";
5408                 }
5409                 $migrated++;
5410         }
5411         command_close_pipe($fh, $ctx);
5412         print STDERR "Done migrating from a git-svn v1 layout\n";
5413         $migrated;
5414 }
5415
5416 sub read_old_urls {
5417         my ($l_map, $pfx, $path) = @_;
5418         my @dir;
5419         foreach (<$path/*>) {
5420                 if (-r "$_/info/url") {
5421                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5422                         my $ref_id = $pfx . basename $_;
5423                         my $url = ::file_to_s("$_/info/url");
5424                         $l_map->{$ref_id} = $url;
5425                 } elsif (-d $_) {
5426                         push @dir, $_;
5427                 }
5428         }
5429         foreach (@dir) {
5430                 my $x = $_;
5431                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5432                 read_old_urls($l_map, $x, $_);
5433         }
5434 }
5435
5436 sub migrate_from_v2 {
5437         my @cfg = command(qw/config -l/);
5438         return if grep /^svn-remote\..+\.url=/, @cfg;
5439         my %l_map;
5440         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5441         my $migrated = 0;
5442
5443         foreach my $ref_id (sort keys %l_map) {
5444                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5445                 if ($@) {
5446                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5447                 }
5448                 $migrated++;
5449         }
5450         $migrated;
5451 }
5452
5453 sub minimize_connections {
5454         my $r = Git::SVN::read_all_remotes();
5455         my $new_urls = {};
5456         my $root_repos = {};
5457         foreach my $repo_id (keys %$r) {
5458                 my $url = $r->{$repo_id}->{url} or next;
5459                 my $fetch = $r->{$repo_id}->{fetch} or next;
5460                 my $ra = Git::SVN::Ra->new($url);
5461
5462                 # skip existing cases where we already connect to the root
5463                 if (($ra->{url} eq $ra->{repos_root}) ||
5464                     ($ra->{repos_root} eq $repo_id)) {
5465                         $root_repos->{$ra->{url}} = $repo_id;
5466                         next;
5467                 }
5468
5469                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
5470                 my $root_path = $ra->{url};
5471                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
5472                 foreach my $path (keys %$fetch) {
5473                         my $ref_id = $fetch->{$path};
5474                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
5475
5476                         # make sure we can read when connecting to
5477                         # a higher level of a repository
5478                         my ($last_rev, undef) = $gs->last_rev_commit;
5479                         if (!defined $last_rev) {
5480                                 $last_rev = eval {
5481                                         $root_ra->get_latest_revnum;
5482                                 };
5483                                 next if $@;
5484                         }
5485                         my $new = $root_path;
5486                         $new .= length $path ? "/$path" : '';
5487                         eval {
5488                                 $root_ra->get_log([$new], $last_rev, $last_rev,
5489                                                   0, 0, 1, sub { });
5490                         };
5491                         next if $@;
5492                         $new_urls->{$ra->{repos_root}}->{$new} =
5493                                 { ref_id => $ref_id,
5494                                   old_repo_id => $repo_id,
5495                                   old_path => $path };
5496                 }
5497         }
5498
5499         my @emptied;
5500         foreach my $url (keys %$new_urls) {
5501                 # see if we can re-use an existing [svn-remote "repo_id"]
5502                 # instead of creating a(n ugly) new section:
5503                 my $repo_id = $root_repos->{$url} || $url;
5504
5505                 my $fetch = $new_urls->{$url};
5506                 foreach my $path (keys %$fetch) {
5507                         my $x = $fetch->{$path};
5508                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
5509                         my $pfx = "svn-remote.$x->{old_repo_id}";
5510
5511                         my $old_fetch = quotemeta("$x->{old_path}:".
5512                                                   "refs/remotes/$x->{ref_id}");
5513                         command_noisy(qw/config --unset/,
5514                                       "$pfx.fetch", '^'. $old_fetch . '$');
5515                         delete $r->{$x->{old_repo_id}}->
5516                                {fetch}->{$x->{old_path}};
5517                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
5518                                 command_noisy(qw/config --unset/,
5519                                               "$pfx.url");
5520                                 push @emptied, $x->{old_repo_id}
5521                         }
5522                 }
5523         }
5524         if (@emptied) {
5525                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
5526                 print STDERR <<EOF;
5527 The following [svn-remote] sections in your config file ($file) are empty
5528 and can be safely removed:
5529 EOF
5530                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
5531         }
5532 }
5533
5534 sub migration_check {
5535         migrate_from_v0();
5536         migrate_from_v1();
5537         migrate_from_v2();
5538         minimize_connections() if $_minimize;
5539 }
5540
5541 package Git::IndexInfo;
5542 use strict;
5543 use warnings;
5544 use Git qw/command_input_pipe command_close_pipe/;
5545
5546 sub new {
5547         my ($class) = @_;
5548         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
5549         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
5550 }
5551
5552 sub remove {
5553         my ($self, $path) = @_;
5554         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
5555                 return ++$self->{nr};
5556         }
5557         undef;
5558 }
5559
5560 sub update {
5561         my ($self, $mode, $hash, $path) = @_;
5562         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
5563                 return ++$self->{nr};
5564         }
5565         undef;
5566 }
5567
5568 sub DESTROY {
5569         my ($self) = @_;
5570         command_close_pipe($self->{gui}, $self->{ctx});
5571 }
5572
5573 package Git::SVN::GlobSpec;
5574 use strict;
5575 use warnings;
5576
5577 sub new {
5578         my ($class, $glob) = @_;
5579         my $re = $glob;
5580         $re =~ s!/+$!!g; # no need for trailing slashes
5581         $re =~ m!^([^*]*)(\*(?:/\*)*)([^*]*)$!;
5582         my $temp = $re;
5583         my ($left, $right) = ($1, $3);
5584         $re = $2;
5585         my $depth = $re =~ tr/*/*/;
5586         if ($depth != $temp =~ tr/*/*/) {
5587                 die "Only one set of wildcard directories " .
5588                         "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
5589         }
5590         if ($depth == 0) {
5591                 die "One '*' is needed for glob: '$glob'\n";
5592         }
5593         $re =~ s!\*!\[^/\]*!g;
5594         $re = quotemeta($left) . "($re)" . quotemeta($right);
5595         if (length $left && !($left =~ s!/+$!!g)) {
5596                 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
5597         }
5598         if (length $right && !($right =~ s!^/+!!g)) {
5599                 die "Missing leading '/' on right side of: '$glob' ($right)\n";
5600         }
5601         my $left_re = qr/^\/\Q$left\E(\/|$)/;
5602         bless { left => $left, right => $right, left_regex => $left_re,
5603                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
5604 }
5605
5606 sub full_path {
5607         my ($self, $path) = @_;
5608         return (length $self->{left} ? "$self->{left}/" : '') .
5609                $path . (length $self->{right} ? "/$self->{right}" : '');
5610 }
5611
5612 __END__
5613
5614 Data structures:
5615
5616
5617 $remotes = { # returned by read_all_remotes()
5618         'svn' => {
5619                 # svn-remote.svn.url=https://svn.musicpd.org
5620                 url => 'https://svn.musicpd.org',
5621                 # svn-remote.svn.fetch=mpd/trunk:trunk
5622                 fetch => {
5623                         'mpd/trunk' => 'trunk',
5624                 },
5625                 # svn-remote.svn.tags=mpd/tags/*:tags/*
5626                 tags => {
5627                         path => {
5628                                 left => 'mpd/tags',
5629                                 right => '',
5630                                 regex => qr!mpd/tags/([^/]+)$!,
5631                                 glob => 'tags/*',
5632                         },
5633                         ref => {
5634                                 left => 'tags',
5635                                 right => '',
5636                                 regex => qr!tags/([^/]+)$!,
5637                                 glob => 'tags/*',
5638                         },
5639                 }
5640         }
5641 };
5642
5643 $log_entry hashref as returned by libsvn_log_entry()
5644 {
5645         log => 'whitespace-formatted log entry
5646 ',                                              # trailing newline is preserved
5647         revision => '8',                        # integer
5648         date => '2004-02-24T17:01:44.108345Z',  # commit date
5649         author => 'committer name'
5650 };
5651
5652
5653 # this is generated by generate_diff();
5654 @mods = array of diff-index line hashes, each element represents one line
5655         of diff-index output
5656
5657 diff-index line ($m hash)
5658 {
5659         mode_a => first column of diff-index output, no leading ':',
5660         mode_b => second column of diff-index output,
5661         sha1_b => sha1sum of the final blob,
5662         chg => change type [MCRADT],
5663         file_a => original file name of a file (iff chg is 'C' or 'R')
5664         file_b => new/current file name of a file (any chg)
5665 }
5666 ;
5667
5668 # retval of read_url_paths{,_all}();
5669 $l_map = {
5670         # repository root url
5671         'https://svn.musicpd.org' => {
5672                 # repository path               # GIT_SVN_ID
5673                 'mpd/trunk'             =>      'trunk',
5674                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
5675         },
5676 }
5677
5678 Notes:
5679         I don't trust the each() function on unless I created %hash myself
5680         because the internal iterator may not have started at base.