git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision $_repository
   8                 $_q $_authors $_authors_prog %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22 $Git::SVN::_minimize_url = 'unset';
  23
  24 if (! exists $ENV{SVN_SSH}) {
  25         if (exists $ENV{GIT_SSH}) {
  26                 $ENV{SVN_SSH} = $ENV{GIT_SSH};
  27                 if ($^O eq 'msys') {
  28                         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  29                         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  30                 }
  31         }
  32 }
  33
  34 $Git::SVN::Log::TZ = $ENV{TZ};
  35 $ENV{TZ} = 'UTC';
  36 $| = 1; # unbuffer STDOUT
  37
  38 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  39 sub _req_svn {
  40         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  41         require SVN::Ra;
  42         require SVN::Delta;
  43         if ($SVN::Core::VERSION lt '1.1.0') {
  44                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  45         }
  46 }
  47 my $can_compress = eval { require Compress::Zlib; 1};
  48 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  49 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  50 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  51 use Carp qw/croak/;
  52 use Digest::MD5;
  53 use IO::File qw//;
  54 use File::Basename qw/dirname basename/;
  55 use File::Path qw/mkpath/;
  56 use File::Spec;
  57 use File::Find;
  58 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  59 use IPC::Open3;
  60 use Git;
  61
  62 BEGIN {
  63         # import functions from Git into our packages, en masse
  64         no strict 'refs';
  65         foreach (qw/command command_oneline command_noisy command_output_pipe
  66                     command_input_pipe command_close_pipe
  67                     command_bidi_pipe command_close_bidi_pipe/) {
  68                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  69                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  70                         __PACKAGE__) {
  71                         *{"${package}::$_"} = \&{"Git::$_"};
  72                 }
  73         }
  74 }
  75
  76 my ($SVN);
  77
  78 $sha1 = qr/[a-f\d]{40}/;
  79 $sha1_short = qr/[a-f\d]{4,40}/;
  80 my ($_stdin, $_help, $_edit,
  81         $_message, $_file, $_branch_dest,
  82         $_template, $_shared,
  83         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
  84         $_merge, $_strategy, $_dry_run, $_local,
  85         $_prefix, $_no_checkout, $_url, $_verbose,
  86         $_git_format, $_commit_url, $_tag);
  87 $Git::SVN::_follow_parent = 1;
  88 $_q ||= 0;
  89 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  90                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  91                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  92                     'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
  93 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  94                 'authors-file|A=s' => \$_authors,
  95                 'authors-prog=s' => \$_authors_prog,
  96                 'repack:i' => \$Git::SVN::_repack,
  97                 'noMetadata' => \$Git::SVN::_no_metadata,
  98                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  99                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 100                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 101                 'no-checkout' => \$_no_checkout,
 102                 'quiet|q+' => \$_q,
 103                 'repack-flags|repack-args|repack-opts=s' =>
 104                    \$Git::SVN::_repack_flags,
 105                 'use-log-author' => \$Git::SVN::_use_log_author,
 106                 'add-author-from' => \$Git::SVN::_add_author_from,
 107                 'localtime' => \$Git::SVN::_localtime,
 108                 %remote_opts );
 109
 110 my ($_trunk, @_tags, @_branches, $_stdlayout);
 111 my %icv;
 112 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 113                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 114                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 115                   'stdlayout|s' => \$_stdlayout,
 116                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 117                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 118                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 119                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 120                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 121                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 122                   %remote_opts );
 123 my %cmt_opts = ( 'edit|e' => \$_edit,
 124                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 125                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 126                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 127                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 128 );
 129
 130 my %cmd = (
 131         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 132                         { 'revision|r=s' => \$_revision,
 133                           'fetch-all|all' => \$_fetch_all,
 134                           'parent|p' => \$_fetch_parent,
 135                            %fc_opts } ],
 136         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 137                         { 'revision|r=s' => \$_revision,
 138                            %fc_opts, %init_opts } ],
 139         init => [ \&cmd_init, "Initialize a repo for tracking" .
 140                           " (requires URL argument)",
 141                           \%init_opts ],
 142         'multi-init' => [ \&cmd_multi_init,
 143                           "Deprecated alias for ".
 144                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 145                           \%init_opts ],
 146         dcommit => [ \&cmd_dcommit,
 147                      'Commit several diffs to merge with upstream',
 148                         { 'merge|m|M' => \$_merge,
 149                           'strategy|s=s' => \$_strategy,
 150                           'verbose|v' => \$_verbose,
 151                           'dry-run|n' => \$_dry_run,
 152                           'fetch-all|all' => \$_fetch_all,
 153                           'commit-url=s' => \$_commit_url,
 154                           'revision|r=i' => \$_revision,
 155                           'no-rebase' => \$_no_rebase,
 156                         %cmt_opts, %fc_opts } ],
 157         branch => [ \&cmd_branch,
 158                     'Create a branch in the SVN repository',
 159                     { 'message|m=s' => \$_message,
 160                       'destination|d=s' => \$_branch_dest,
 161                       'dry-run|n' => \$_dry_run,
 162                       'tag|t' => \$_tag,
 163                       'username=s' => \$Git::SVN::Prompt::_username,
 164                       'commit-url=s' => \$_commit_url } ],
 165         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 166                  'Create a tag in the SVN repository',
 167                  { 'message|m=s' => \$_message,
 168                    'destination|d=s' => \$_branch_dest,
 169                    'dry-run|n' => \$_dry_run,
 170                    'username=s' => \$Git::SVN::Prompt::_username,
 171                    'commit-url=s' => \$_commit_url } ],
 172         'set-tree' => [ \&cmd_set_tree,
 173                         "Set an SVN repository to a git tree-ish",
 174                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 175         'create-ignore' => [ \&cmd_create_ignore,
 176                              'Create a .gitignore per svn:ignore',
 177                              { 'revision|r=i' => \$_revision
 178                              } ],
 179         'mkdirs' => [ \&cmd_mkdirs ,
 180                       "recreate empty directories after a checkout",
 181                       { 'revision|r=i' => \$_revision } ],
 182         'propget' => [ \&cmd_propget,
 183                        'Print the value of a property on a file or directory',
 184                        { 'revision|r=i' => \$_revision } ],
 185         'proplist' => [ \&cmd_proplist,
 186                        'List all properties of a file or directory',
 187                        { 'revision|r=i' => \$_revision } ],
 188         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 189                         { 'revision|r=i' => \$_revision
 190                         } ],
 191         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 192                         { 'revision|r=i' => \$_revision
 193                         } ],
 194         'multi-fetch' => [ \&cmd_multi_fetch,
 195                            "Deprecated alias for $0 fetch --all",
 196                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 197         'migrate' => [ sub { },
 198                        # no-op, we automatically run this anyways,
 199                        'Migrate configuration/metadata/layout from
 200                         previous versions of git-svn',
 201                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 202                          %remote_opts } ],
 203         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 204                         { 'limit=i' => \$Git::SVN::Log::limit,
 205                           'revision|r=s' => \$_revision,
 206                           'verbose|v' => \$Git::SVN::Log::verbose,
 207                           'incremental' => \$Git::SVN::Log::incremental,
 208                           'oneline' => \$Git::SVN::Log::oneline,
 209                           'show-commit' => \$Git::SVN::Log::show_commit,
 210                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 211                           'authors-file|A=s' => \$_authors,
 212                           'color' => \$Git::SVN::Log::color,
 213                           'pager=s' => \$Git::SVN::Log::pager
 214                         } ],
 215         'find-rev' => [ \&cmd_find_rev,
 216                         "Translate between SVN revision numbers and tree-ish",
 217                         {} ],
 218         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 219                         { 'merge|m|M' => \$_merge,
 220                           'verbose|v' => \$_verbose,
 221                           'strategy|s=s' => \$_strategy,
 222                           'local|l' => \$_local,
 223                           'fetch-all|all' => \$_fetch_all,
 224                           'dry-run|n' => \$_dry_run,
 225                           %fc_opts } ],
 226         'commit-diff' => [ \&cmd_commit_diff,
 227                            'Commit a diff between two trees',
 228                         { 'message|m=s' => \$_message,
 229                           'file|F=s' => \$_file,
 230                           'revision|r=s' => \$_revision,
 231                         %cmt_opts } ],
 232         'info' => [ \&cmd_info,
 233                     "Show info about the latest SVN revision
 234                      on the current branch",
 235                     { 'url' => \$_url, } ],
 236         'blame' => [ \&Git::SVN::Log::cmd_blame,
 237                     "Show what revision and author last modified each line of a file",
 238                     { 'git-format' => \$_git_format } ],
 239         'reset' => [ \&cmd_reset,
 240                      "Undo fetches back to the specified SVN revision",
 241                      { 'revision|r=s' => \$_revision,
 242                        'parent|p' => \$_fetch_parent } ],
 243         'gc' => [ \&cmd_gc,
 244                   "Compress unhandled.log files in .git/svn and remove " .
 245                   "index files in .git/svn",
 246                 {} ],
 247 );
 248
 249 my $cmd;
 250 for (my $i = 0; $i < @ARGV; $i++) {
 251         if (defined $cmd{$ARGV[$i]}) {
 252                 $cmd = $ARGV[$i];
 253                 splice @ARGV, $i, 1;
 254                 last;
 255         } elsif ($ARGV[$i] eq 'help') {
 256                 $cmd = $ARGV[$i+1];
 257                 usage(0);
 258         }
 259 };
 260
 261 # make sure we're always running at the top-level working directory
 262 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 263         unless (-d $ENV{GIT_DIR}) {
 264                 if ($git_dir_user_set) {
 265                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 266                             "but it is not a directory\n";
 267                 }
 268                 my $git_dir = delete $ENV{GIT_DIR};
 269                 my $cdup = undef;
 270                 git_cmd_try {
 271                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 272                         $git_dir = '.' unless ($cdup);
 273                         chomp $cdup if ($cdup);
 274                         $cdup = "." unless ($cdup && length $cdup);
 275                 } "Already at toplevel, but $git_dir not found\n";
 276                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 277                 unless (-d $git_dir) {
 278                         die "$git_dir still not found after going to ",
 279                             "'$cdup'\n";
 280                 }
 281                 $ENV{GIT_DIR} = $git_dir;
 282         }
 283         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 284 }
 285
 286 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 287
 288 read_git_config(\%opts);
 289 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 290         Getopt::Long::Configure('pass_through');
 291 }
 292 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 293                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 294                     'id|i=s' => \$Git::SVN::default_ref_id,
 295                     'svn-remote|remote|R=s' => sub {
 296                        $Git::SVN::no_reuse_existing = 1;
 297                        $Git::SVN::default_repo_id = $_[1] });
 298 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 299
 300 usage(0) if $_help;
 301 version() if $_version;
 302 usage(1) unless defined $cmd;
 303 load_authors() if $_authors;
 304 if (defined $_authors_prog) {
 305         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 306 }
 307
 308 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 309         Git::SVN::Migration::migration_check();
 310 }
 311 Git::SVN::init_vars();
 312 eval {
 313         Git::SVN::verify_remotes_sanity();
 314         $cmd{$cmd}->[0]->(@ARGV);
 315 };
 316 fatal $@ if $@;
 317 post_fetch_checkout();
 318 exit 0;
 319
 320 ####################### primary functions ######################
 321 sub usage {
 322         my $exit = shift || 0;
 323         my $fd = $exit ? \*STDERR : \*STDOUT;
 324         print $fd <<"";
 325 git-svn - bidirectional operations between a single Subversion tree and git
 326 Usage: git svn <command> [options] [arguments]\n
 327
 328         print $fd "Available commands:\n" unless $cmd;
 329
 330         foreach (sort keys %cmd) {
 331                 next if $cmd && $cmd ne $_;
 332                 next if /^multi-/; # don't show deprecated commands
 333                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 334                 foreach (sort keys %{$cmd{$_}->[2]}) {
 335                         # mixed-case options are for .git/config only
 336                         next if /[A-Z]/ && /^[a-z]+$/i;
 337                         # prints out arguments as they should be passed:
 338                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 339                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 340                                                         "--$_" : "-$_" }
 341                                                 split /\|/,$_)," $x\n";
 342                 }
 343         }
 344         print $fd <<"";
 345 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 346 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 347 one git repository and want to keep them separate.  See git-svn(1) for more
 348 information.
 349
 350         exit $exit;
 351 }
 352
 353 sub version {
 354         ::_req_svn();
 355         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 356         exit 0;
 357 }
 358
 359 sub do_git_init_db {
 360         unless (-d $ENV{GIT_DIR}) {
 361                 my @init_db = ('init');
 362                 push @init_db, "--template=$_template" if defined $_template;
 363                 if (defined $_shared) {
 364                         if ($_shared =~ /[a-z]/) {
 365                                 push @init_db, "--shared=$_shared";
 366                         } else {
 367                                 push @init_db, "--shared";
 368                         }
 369                 }
 370                 command_noisy(@init_db);
 371                 $_repository = Git->repository(Repository => ".git");
 372         }
 373         my $set;
 374         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 375         foreach my $i (keys %icv) {
 376                 die "'$set' and '$i' cannot both be set\n" if $set;
 377                 next unless defined $icv{$i};
 378                 command_noisy('config', "$pfx.$i", $icv{$i});
 379                 $set = $i;
 380         }
 381         my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
 382         command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
 383                 if defined $$ignore_regex;
 384 }
 385
 386 sub init_subdir {
 387         my $repo_path = shift or return;
 388         mkpath([$repo_path]) unless -d $repo_path;
 389         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 390         $ENV{GIT_DIR} = '.git';
 391         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 392 }
 393
 394 sub cmd_clone {
 395         my ($url, $path) = @_;
 396         if (!defined $path &&
 397             (defined $_trunk || @_branches || @_tags ||
 398              defined $_stdlayout) &&
 399             $url !~ m#^[a-z\+]+://#) {
 400                 $path = $url;
 401         }
 402         $path = basename($url) if !defined $path || !length $path;
 403         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 404         cmd_init($url, $path);
 405         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 406             if $_authors;
 407         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 408 }
 409
 410 sub cmd_init {
 411         if (defined $_stdlayout) {
 412                 $_trunk = 'trunk' if (!defined $_trunk);
 413                 @_tags = 'tags' if (! @_tags);
 414                 @_branches = 'branches' if (! @_branches);
 415         }
 416         if (defined $_trunk || @_branches || @_tags) {
 417                 return cmd_multi_init(@_);
 418         }
 419         my $url = shift or die "SVN repository location required ",
 420                                "as a command-line argument\n";
 421         $url = canonicalize_url($url);
 422         init_subdir(@_);
 423         do_git_init_db();
 424
 425         if ($Git::SVN::_minimize_url eq 'unset') {
 426                 $Git::SVN::_minimize_url = 0;
 427         }
 428
 429         Git::SVN->init($url);
 430 }
 431
 432 sub cmd_fetch {
 433         if (grep /^\d+=./, @_) {
 434                 die "'<rev>=<commit>' fetch arguments are ",
 435                     "no longer supported.\n";
 436         }
 437         my ($remote) = @_;
 438         if (@_ > 1) {
 439                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 440         }
 441         $Git::SVN::no_reuse_existing = undef;
 442         if ($_fetch_parent) {
 443                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 444                 unless ($gs) {
 445                         die "Unable to determine upstream SVN information from ",
 446                             "working tree history\n";
 447                 }
 448                 # just fetch, don't checkout.
 449                 $_no_checkout = 'true';
 450                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 451         } elsif ($_fetch_all) {
 452                 cmd_multi_fetch();
 453         } else {
 454                 $remote ||= $Git::SVN::default_repo_id;
 455                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 456         }
 457 }
 458
 459 sub cmd_set_tree {
 460         my (@commits) = @_;
 461         if ($_stdin || !@commits) {
 462                 print "Reading from stdin...\n";
 463                 @commits = ();
 464                 while (<STDIN>) {
 465                         if (/\b($sha1_short)\b/o) {
 466                                 unshift @commits, $1;
 467                         }
 468                 }
 469         }
 470         my @revs;
 471         foreach my $c (@commits) {
 472                 my @tmp = command('rev-parse',$c);
 473                 if (scalar @tmp == 1) {
 474                         push @revs, $tmp[0];
 475                 } elsif (scalar @tmp > 1) {
 476                         push @revs, reverse(command('rev-list',@tmp));
 477                 } else {
 478                         fatal "Failed to rev-parse $c";
 479                 }
 480         }
 481         my $gs = Git::SVN->new;
 482         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 483         $gs->fetch;
 484         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 485                 fatal "There are new revisions that were fetched ",
 486                       "and need to be merged (or acknowledged) ",
 487                       "before committing.\nlast rev: $r_last\n",
 488                       " current: $gs->{last_rev}";
 489         }
 490         $gs->set_tree($_) foreach @revs;
 491         print "Done committing ",scalar @revs," revisions to SVN\n";
 492         unlink $gs->{index};
 493 }
 494
 495 sub cmd_dcommit {
 496         my $head = shift;
 497         command_noisy(qw/update-index --refresh/);
 498         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 499                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 500                 . "or stash them with `git stash'.\n";
 501         $head ||= 'HEAD';
 502
 503         my $old_head;
 504         if ($head ne 'HEAD') {
 505                 $old_head = eval {
 506                         command_oneline([qw/symbolic-ref -q HEAD/])
 507                 };
 508                 if ($old_head) {
 509                         $old_head =~ s{^refs/heads/}{};
 510                 } else {
 511                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 512                 }
 513                 command(['checkout', $head], STDERR => 0);
 514         }
 515
 516         my @refs;
 517         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 518         unless ($gs) {
 519                 die "Unable to determine upstream SVN information from ",
 520                     "$head history.\nPerhaps the repository is empty.";
 521         }
 522
 523         if (defined $_commit_url) {
 524                 $url = $_commit_url;
 525         } else {
 526                 $url = eval { command_oneline('config', '--get',
 527                               "svn-remote.$gs->{repo_id}.commiturl") };
 528                 if (!$url) {
 529                         $url = $gs->full_url
 530                 }
 531         }
 532
 533         my $last_rev = $_revision if defined $_revision;
 534         if ($url) {
 535                 print "Committing to $url ...\n";
 536         }
 537         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 538         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 539                 warn "Attempting to commit more than one change while ",
 540                      "--no-rebase is enabled.\n",
 541                      "If these changes depend on each other, re-running ",
 542                      "without --no-rebase may be required."
 543         }
 544         my $expect_url = $url;
 545         Git::SVN::remove_username($expect_url);
 546         while (1) {
 547                 my $d = shift @$linear_refs or last;
 548                 unless (defined $last_rev) {
 549                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 550                         unless (defined $last_rev) {
 551                                 fatal "Unable to extract revision information ",
 552                                       "from commit $d~1";
 553                         }
 554                 }
 555                 if ($_dry_run) {
 556                         print "diff-tree $d~1 $d\n";
 557                 } else {
 558                         my $cmt_rev;
 559                         my %ed_opts = ( r => $last_rev,
 560                                         log => get_commit_entry($d)->{log},
 561                                         ra => Git::SVN::Ra->new($url),
 562                                         config => SVN::Core::config_get_config(
 563                                                 $Git::SVN::Ra::config_dir
 564                                         ),
 565                                         tree_a => "$d~1",
 566                                         tree_b => $d,
 567                                         editor_cb => sub {
 568                                                print "Committed r$_[0]\n";
 569                                                $cmt_rev = $_[0];
 570                                         },
 571                                         svn_path => '');
 572                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 573                                 print "No changes\n$d~1 == $d\n";
 574                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 575                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 576                                                                $parents->{$d};
 577                         }
 578                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 579                         $last_rev = $cmt_rev;
 580                         next if $_no_rebase;
 581
 582                         # we always want to rebase against the current HEAD,
 583                         # not any head that was passed to us
 584                         my @diff = command('diff-tree', $d,
 585                                            $gs->refname, '--');
 586                         my @finish;
 587                         if (@diff) {
 588                                 @finish = rebase_cmd();
 589                                 print STDERR "W: $d and ", $gs->refname,
 590                                              " differ, using @finish:\n",
 591                                              join("\n", @diff), "\n";
 592                         } else {
 593                                 print "No changes between current HEAD and ",
 594                                       $gs->refname,
 595                                       "\nResetting to the latest ",
 596                                       $gs->refname, "\n";
 597                                 @finish = qw/reset --mixed/;
 598                         }
 599                         command_noisy(@finish, $gs->refname);
 600                         if (@diff) {
 601                                 @refs = ();
 602                                 my ($url_, $rev_, $uuid_, $gs_) =
 603                                               working_head_info('HEAD', \@refs);
 604                                 my ($linear_refs_, $parents_) =
 605                                               linearize_history($gs_, \@refs);
 606                                 if (scalar(@$linear_refs) !=
 607                                     scalar(@$linear_refs_)) {
 608                                         fatal "# of revisions changed ",
 609                                           "\nbefore:\n",
 610                                           join("\n", @$linear_refs),
 611                                           "\n\nafter:\n",
 612                                           join("\n", @$linear_refs_), "\n",
 613                                           'If you are attempting to commit ',
 614                                           "merges, try running:\n\t",
 615                                           'git rebase --interactive',
 616                                           '--preserve-merges ',
 617                                           $gs->refname,
 618                                           "\nBefore dcommitting";
 619                                 }
 620                                 if ($url_ ne $expect_url) {
 621                                         if ($url_ eq $gs->metadata_url) {
 622                                                 print
 623                                                   "Accepting rewritten URL:",
 624                                                   " $url_\n";
 625                                         } else {
 626                                                 fatal
 627                                                   "URL mismatch after rebase:",
 628                                                   " $url_ != $expect_url";
 629                                         }
 630                                 }
 631                                 if ($uuid_ ne $uuid) {
 632                                         fatal "uuid mismatch after rebase: ",
 633                                               "$uuid_ != $uuid";
 634                                 }
 635                                 # remap parents
 636                                 my (%p, @l, $i);
 637                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 638                                         my $new = $linear_refs_->[$i] or next;
 639                                         $p{$new} =
 640                                                 $parents->{$linear_refs->[$i]};
 641                                         push @l, $new;
 642                                 }
 643                                 $parents = \%p;
 644                                 $linear_refs = \@l;
 645                         }
 646                 }
 647         }
 648
 649         if ($old_head) {
 650                 my $new_head = command_oneline(qw/rev-parse HEAD/);
 651                 my $new_is_symbolic = eval {
 652                         command_oneline(qw/symbolic-ref -q HEAD/);
 653                 };
 654                 if ($new_is_symbolic) {
 655                         print "dcommitted the branch ", $head, "\n";
 656                 } else {
 657                         print "dcommitted on a detached HEAD because you gave ",
 658                               "a revision argument.\n",
 659                               "The rewritten commit is: ", $new_head, "\n";
 660                 }
 661                 command(['checkout', $old_head], STDERR => 0);
 662         }
 663
 664         unlink $gs->{index};
 665 }
 666
 667 sub cmd_branch {
 668         my ($branch_name, $head) = @_;
 669
 670         unless (defined $branch_name && length $branch_name) {
 671                 die(($_tag ? "tag" : "branch") . " name required\n");
 672         }
 673         $head ||= 'HEAD';
 674
 675         my (undef, $rev, undef, $gs) = working_head_info($head);
 676         my $src = $gs->full_url;
 677
 678         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 679         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
 680         my $glob;
 681         if ($#{$allglobs} == 0) {
 682                 $glob = $allglobs->[0];
 683         } else {
 684                 unless(defined $_branch_dest) {
 685                         die "Multiple ",
 686                             $_tag ? "tag" : "branch",
 687                             " paths defined for Subversion repository.\n",
 688                             "You must specify where you want to create the ",
 689                             $_tag ? "tag" : "branch",
 690                             " with the --destination argument.\n";
 691                 }
 692                 foreach my $g (@{$allglobs}) {
 693                         # SVN::Git::Editor could probably be moved to Git.pm..
 694                         my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
 695                         if ($_branch_dest =~ /$re/) {
 696                                 $glob = $g;
 697                                 last;
 698                         }
 699                 }
 700                 unless (defined $glob) {
 701                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
 702                         foreach my $g (@{$allglobs}) {
 703                                 $g->{path}->{left} =~ /$dest_re/ or next;
 704                                 if (defined $glob) {
 705                                         die "Ambiguous destination: ",
 706                                             $_branch_dest, "\nmatches both '",
 707                                             $glob->{path}->{left}, "' and '",
 708                                             $g->{path}->{left}, "'\n";
 709                                 }
 710                                 $glob = $g;
 711                         }
 712                         unless (defined $glob) {
 713                                 die "Unknown ",
 714                                     $_tag ? "tag" : "branch",
 715                                     " destination $_branch_dest\n";
 716                         }
 717                 }
 718         }
 719         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 720         my $url;
 721         if (defined $_commit_url) {
 722                 $url = $_commit_url;
 723         } else {
 724                 $url = eval { command_oneline('config', '--get',
 725                         "svn-remote.$gs->{repo_id}.commiturl") };
 726                 if (!$url) {
 727                         $url = $remote->{url};
 728                 }
 729         }
 730         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
 731
 732         if ($dst =~ /^https:/ && $src =~ /^http:/) {
 733                 $src=~s/^http:/https:/;
 734         }
 735
 736         ::_req_svn();
 737
 738         my $ctx = SVN::Client->new(
 739                 auth    => Git::SVN::Ra::_auth_providers(),
 740                 log_msg => sub {
 741                         ${ $_[0] } = defined $_message
 742                                 ? $_message
 743                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 744                                 . $branch_name;
 745                 },
 746         );
 747
 748         eval {
 749                 $ctx->ls($dst, 'HEAD', 0);
 750         } and die "branch ${branch_name} already exists\n";
 751
 752         print "Copying ${src} at r${rev} to ${dst}...\n";
 753         $ctx->copy($src, $rev, $dst)
 754                 unless $_dry_run;
 755
 756         $gs->fetch_all;
 757 }
 758
 759 sub cmd_find_rev {
 760         my $revision_or_hash = shift or die "SVN or git revision required ",
 761                                             "as a command-line argument\n";
 762         my $result;
 763         if ($revision_or_hash =~ /^r\d+$/) {
 764                 my $head = shift;
 765                 $head ||= 'HEAD';
 766                 my @refs;
 767                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 768                 unless ($gs) {
 769                         die "Unable to determine upstream SVN information from ",
 770                             "$head history\n";
 771                 }
 772                 my $desired_revision = substr($revision_or_hash, 1);
 773                 $result = $gs->rev_map_get($desired_revision, $uuid);
 774         } else {
 775                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 776                 $result = $rev;
 777         }
 778         print "$result\n" if $result;
 779 }
 780
 781 sub cmd_rebase {
 782         command_noisy(qw/update-index --refresh/);
 783         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 784         unless ($gs) {
 785                 die "Unable to determine upstream SVN information from ",
 786                     "working tree history\n";
 787         }
 788         if ($_dry_run) {
 789                 print "Remote Branch: " . $gs->refname . "\n";
 790                 print "SVN URL: " . $url . "\n";
 791                 return;
 792         }
 793         if (command(qw/diff-index HEAD --/)) {
 794                 print STDERR "Cannot rebase with uncommited changes:\n";
 795                 command_noisy('status');
 796                 exit 1;
 797         }
 798         unless ($_local) {
 799                 # rebase will checkout for us, so no need to do it explicitly
 800                 $_no_checkout = 'true';
 801                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 802         }
 803         command_noisy(rebase_cmd(), $gs->refname);
 804         $gs->mkemptydirs;
 805 }
 806
 807 sub cmd_show_ignore {
 808         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 809         $gs ||= Git::SVN->new;
 810         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 811         $gs->prop_walk($gs->{path}, $r, sub {
 812                 my ($gs, $path, $props) = @_;
 813                 print STDOUT "\n# $path\n";
 814                 my $s = $props->{'svn:ignore'} or return;
 815                 $s =~ s/[\r\n]+/\n/g;
 816                 $s =~ s/^\n+//;
 817                 chomp $s;
 818                 $s =~ s#^#$path#gm;
 819                 print STDOUT "$s\n";
 820         });
 821 }
 822
 823 sub cmd_show_externals {
 824         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 825         $gs ||= Git::SVN->new;
 826         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 827         $gs->prop_walk($gs->{path}, $r, sub {
 828                 my ($gs, $path, $props) = @_;
 829                 print STDOUT "\n# $path\n";
 830                 my $s = $props->{'svn:externals'} or return;
 831                 $s =~ s/[\r\n]+/\n/g;
 832                 chomp $s;
 833                 $s =~ s#^#$path#gm;
 834                 print STDOUT "$s\n";
 835         });
 836 }
 837
 838 sub cmd_create_ignore {
 839         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 840         $gs ||= Git::SVN->new;
 841         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 842         $gs->prop_walk($gs->{path}, $r, sub {
 843                 my ($gs, $path, $props) = @_;
 844                 # $path is of the form /path/to/dir/
 845                 $path = '.' . $path;
 846                 # SVN can have attributes on empty directories,
 847                 # which git won't track
 848                 mkpath([$path]) unless -d $path;
 849                 my $ignore = $path . '.gitignore';
 850                 my $s = $props->{'svn:ignore'} or return;
 851                 open(GITIGNORE, '>', $ignore)
 852                   or fatal("Failed to open `$ignore' for writing: $!");
 853                 $s =~ s/[\r\n]+/\n/g;
 854                 $s =~ s/^\n+//;
 855                 chomp $s;
 856                 # Prefix all patterns so that the ignore doesn't apply
 857                 # to sub-directories.
 858                 $s =~ s#^#/#gm;
 859                 print GITIGNORE "$s\n";
 860                 close(GITIGNORE)
 861                   or fatal("Failed to close `$ignore': $!");
 862                 command_noisy('add', '-f', $ignore);
 863         });
 864 }
 865
 866 sub cmd_mkdirs {
 867         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 868         $gs ||= Git::SVN->new;
 869         $gs->mkemptydirs($_revision);
 870 }
 871
 872 sub canonicalize_path {
 873         my ($path) = @_;
 874         my $dot_slash_added = 0;
 875         if (substr($path, 0, 1) ne "/") {
 876                 $path = "./" . $path;
 877                 $dot_slash_added = 1;
 878         }
 879         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 880         # good reason), so let's do this manually.
 881         $path =~ s#/+#/#g;
 882         $path =~ s#/\.(?:/|$)#/#g;
 883         $path =~ s#/[^/]+/\.\.##g;
 884         $path =~ s#/$##g;
 885         $path =~ s#^\./## if $dot_slash_added;
 886         $path =~ s#^/##;
 887         $path =~ s#^\.$##;
 888         return $path;
 889 }
 890
 891 sub canonicalize_url {
 892         my ($url) = @_;
 893         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 894         return $url;
 895 }
 896
 897 # get_svnprops(PATH)
 898 # ------------------
 899 # Helper for cmd_propget and cmd_proplist below.
 900 sub get_svnprops {
 901         my $path = shift;
 902         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 903         $gs ||= Git::SVN->new;
 904
 905         # prefix THE PATH by the sub-directory from which the user
 906         # invoked us.
 907         $path = $cmd_dir_prefix . $path;
 908         fatal("No such file or directory: $path") unless -e $path;
 909         my $is_dir = -d $path ? 1 : 0;
 910         $path = $gs->{path} . '/' . $path;
 911
 912         # canonicalize the path (otherwise libsvn will abort or fail to
 913         # find the file)
 914         $path = canonicalize_path($path);
 915
 916         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 917         my $props;
 918         if ($is_dir) {
 919                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 920         }
 921         else {
 922                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 923         }
 924         return $props;
 925 }
 926
 927 # cmd_propget (PROP, PATH)
 928 # ------------------------
 929 # Print the SVN property PROP for PATH.
 930 sub cmd_propget {
 931         my ($prop, $path) = @_;
 932         $path = '.' if not defined $path;
 933         usage(1) if not defined $prop;
 934         my $props = get_svnprops($path);
 935         if (not defined $props->{$prop}) {
 936                 fatal("`$path' does not have a `$prop' SVN property.");
 937         }
 938         print $props->{$prop} . "\n";
 939 }
 940
 941 # cmd_proplist (PATH)
 942 # -------------------
 943 # Print the list of SVN properties for PATH.
 944 sub cmd_proplist {
 945         my $path = shift;
 946         $path = '.' if not defined $path;
 947         my $props = get_svnprops($path);
 948         print "Properties on '$path':\n";
 949         foreach (sort keys %{$props}) {
 950                 print "  $_\n";
 951         }
 952 }
 953
 954 sub cmd_multi_init {
 955         my $url = shift;
 956         unless (defined $_trunk || @_branches || @_tags) {
 957                 usage(1);
 958         }
 959
 960         $_prefix = '' unless defined $_prefix;
 961         if (defined $url) {
 962                 $url = canonicalize_url($url);
 963                 init_subdir(@_);
 964         }
 965         do_git_init_db();
 966         if (defined $_trunk) {
 967                 $_trunk =~ s#^/+##;
 968                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
 969                 # try both old-style and new-style lookups:
 970                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 971                 unless ($gs_trunk) {
 972                         my ($trunk_url, $trunk_path) =
 973                                               complete_svn_url($url, $_trunk);
 974                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 975                                                    undef, $trunk_ref);
 976                 }
 977         }
 978         return unless @_branches || @_tags;
 979         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 980         foreach my $path (@_branches) {
 981                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
 982         }
 983         foreach my $path (@_tags) {
 984                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
 985         }
 986 }
 987
 988 sub cmd_multi_fetch {
 989         $Git::SVN::no_reuse_existing = undef;
 990         my $remotes = Git::SVN::read_all_remotes();
 991         foreach my $repo_id (sort keys %$remotes) {
 992                 if ($remotes->{$repo_id}->{url}) {
 993                         Git::SVN::fetch_all($repo_id, $remotes);
 994                 }
 995         }
 996 }
 997
 998 # this command is special because it requires no metadata
 999 sub cmd_commit_diff {
1000         my ($ta, $tb, $url) = @_;
1001         my $usage = "Usage: $0 commit-diff -r<revision> ".
1002                     "<tree-ish> <tree-ish> [<URL>]";
1003         fatal($usage) if (!defined $ta || !defined $tb);
1004         my $svn_path = '';
1005         if (!defined $url) {
1006                 my $gs = eval { Git::SVN->new };
1007                 if (!$gs) {
1008                         fatal("Needed URL or usable git-svn --id in ",
1009                               "the command-line\n", $usage);
1010                 }
1011                 $url = $gs->{url};
1012                 $svn_path = $gs->{path};
1013         }
1014         unless (defined $_revision) {
1015                 fatal("-r|--revision is a required argument\n", $usage);
1016         }
1017         if (defined $_message && defined $_file) {
1018                 fatal("Both --message/-m and --file/-F specified ",
1019                       "for the commit message.\n",
1020                       "I have no idea what you mean");
1021         }
1022         if (defined $_file) {
1023                 $_message = file_to_s($_file);
1024         } else {
1025                 $_message ||= get_commit_entry($tb)->{log};
1026         }
1027         my $ra ||= Git::SVN::Ra->new($url);
1028         my $r = $_revision;
1029         if ($r eq 'HEAD') {
1030                 $r = $ra->get_latest_revnum;
1031         } elsif ($r !~ /^\d+$/) {
1032                 die "revision argument: $r not understood by git-svn\n";
1033         }
1034         my %ed_opts = ( r => $r,
1035                         log => $_message,
1036                         ra => $ra,
1037                         tree_a => $ta,
1038                         tree_b => $tb,
1039                         editor_cb => sub { print "Committed r$_[0]\n" },
1040                         svn_path => $svn_path );
1041         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1042                 print "No changes\n$ta == $tb\n";
1043         }
1044 }
1045
1046 sub escape_uri_only {
1047         my ($uri) = @_;
1048         my @tmp;
1049         foreach (split m{/}, $uri) {
1050                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1051                 push @tmp, $_;
1052         }
1053         join('/', @tmp);
1054 }
1055
1056 sub escape_url {
1057         my ($url) = @_;
1058         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1059                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1060                 $url = "$scheme://$domain$uri";
1061         }
1062         $url;
1063 }
1064
1065 sub cmd_info {
1066         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1067         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1068         if (exists $_[1]) {
1069                 die "Too many arguments specified\n";
1070         }
1071
1072         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1073
1074         if (!$file_type && !$diff_status) {
1075                 print STDERR "svn: '$path' is not under version control\n";
1076                 exit 1;
1077         }
1078
1079         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1080         unless ($gs) {
1081                 die "Unable to determine upstream SVN information from ",
1082                     "working tree history\n";
1083         }
1084
1085         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1086         $path = "." if $path eq "";
1087
1088         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1089
1090         if ($_url) {
1091                 print escape_url($full_url), "\n";
1092                 return;
1093         }
1094
1095         my $result = "Path: $path\n";
1096         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1097         $result .= "URL: " . escape_url($full_url) . "\n";
1098
1099         eval {
1100                 my $repos_root = $gs->repos_root;
1101                 Git::SVN::remove_username($repos_root);
1102                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1103         };
1104         if ($@) {
1105                 $result .= "Repository Root: (offline)\n";
1106         }
1107         ::_req_svn();
1108         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1109                 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1110         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1111
1112         $result .= "Node Kind: " .
1113                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1114
1115         my $schedule = $diff_status eq "A"
1116                        ? "add"
1117                        : ($diff_status eq "D" ? "delete" : "normal");
1118         $result .= "Schedule: $schedule\n";
1119
1120         if ($diff_status eq "A") {
1121                 print $result, "\n";
1122                 return;
1123         }
1124
1125         my ($lc_author, $lc_rev, $lc_date_utc);
1126         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1127         my $log = command_output_pipe(@args);
1128         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1129         while (<$log>) {
1130                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1131                         $lc_author = $1;
1132                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1133                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1134                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1135                 }
1136         }
1137         close $log;
1138
1139         Git::SVN::Log::set_local_timezone();
1140
1141         $result .= "Last Changed Author: $lc_author\n";
1142         $result .= "Last Changed Rev: $lc_rev\n";
1143         $result .= "Last Changed Date: " .
1144                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1145
1146         if ($file_type ne "dir") {
1147                 my $text_last_updated_date =
1148                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1149                 $result .=
1150                     "Text Last Updated: " .
1151                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1152                     "\n";
1153                 my $checksum;
1154                 if ($diff_status eq "D") {
1155                         my ($fh, $ctx) =
1156                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1157                         if ($file_type eq "link") {
1158                                 my $file_name = <$fh>;
1159                                 $checksum = md5sum("link $file_name");
1160                         } else {
1161                                 $checksum = md5sum($fh);
1162                         }
1163                         command_close_pipe($fh, $ctx);
1164                 } elsif ($file_type eq "link") {
1165                         my $file_name =
1166                             command(qw(cat-file blob), "HEAD:$path");
1167                         $checksum =
1168                             md5sum("link " . $file_name);
1169                 } else {
1170                         open FILE, "<", $path or die $!;
1171                         $checksum = md5sum(\*FILE);
1172                         close FILE or die $!;
1173                 }
1174                 $result .= "Checksum: " . $checksum . "\n";
1175         }
1176
1177         print $result, "\n";
1178 }
1179
1180 sub cmd_reset {
1181         my $target = shift || $_revision or die "SVN revision required\n";
1182         $target = $1 if $target =~ /^r(\d+)$/;
1183         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1184         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1185         unless ($gs) {
1186                 die "Unable to determine upstream SVN information from ".
1187                     "history\n";
1188         }
1189         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1190         die "Cannot find SVN revision $target\n" unless defined($c);
1191         $gs->rev_map_set($r, $c, 'reset', $uuid);
1192         print "r$r = $c ($gs->{ref_id})\n";
1193 }
1194
1195 sub cmd_gc {
1196         if (!$can_compress) {
1197                 warn "Compress::Zlib could not be found; unhandled.log " .
1198                      "files will not be compressed.\n";
1199         }
1200         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1201 }
1202
1203 ########################### utility functions #########################
1204
1205 sub rebase_cmd {
1206         my @cmd = qw/rebase/;
1207         push @cmd, '-v' if $_verbose;
1208         push @cmd, qw/--merge/ if $_merge;
1209         push @cmd, "--strategy=$_strategy" if $_strategy;
1210         @cmd;
1211 }
1212
1213 sub post_fetch_checkout {
1214         return if $_no_checkout;
1215         my $gs = $Git::SVN::_head or return;
1216         return if verify_ref('refs/heads/master^0');
1217
1218         # look for "trunk" ref if it exists
1219         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1220         my $fetch = $remote->{fetch};
1221         if ($fetch) {
1222                 foreach my $p (keys %$fetch) {
1223                         basename($fetch->{$p}) eq 'trunk' or next;
1224                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1225                         last;
1226                 }
1227         }
1228
1229         my $valid_head = verify_ref('HEAD^0');
1230         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1231         return if ($valid_head || !verify_ref('HEAD^0'));
1232
1233         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1234         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1235         return if -f $index;
1236
1237         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1238         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1239         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1240         print STDERR "Checked out HEAD:\n  ",
1241                      $gs->full_url, " r", $gs->last_rev, "\n";
1242         $gs->mkemptydirs($gs->last_rev);
1243 }
1244
1245 sub complete_svn_url {
1246         my ($url, $path) = @_;
1247         $path =~ s#/+$##;
1248         if ($path !~ m#^[a-z\+]+://#) {
1249                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1250                         fatal("E: '$path' is not a complete URL ",
1251                               "and a separate URL is not specified");
1252                 }
1253                 return ($url, $path);
1254         }
1255         return ($path, '');
1256 }
1257
1258 sub complete_url_ls_init {
1259         my ($ra, $repo_path, $switch, $pfx) = @_;
1260         unless ($repo_path) {
1261                 print STDERR "W: $switch not specified\n";
1262                 return;
1263         }
1264         $repo_path =~ s#/+$##;
1265         if ($repo_path =~ m#^[a-z\+]+://#) {
1266                 $ra = Git::SVN::Ra->new($repo_path);
1267                 $repo_path = '';
1268         } else {
1269                 $repo_path =~ s#^/+##;
1270                 unless ($ra) {
1271                         fatal("E: '$repo_path' is not a complete URL ",
1272                               "and a separate URL is not specified");
1273                 }
1274         }
1275         my $url = $ra->{url};
1276         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1277         my $k = "svn-remote.$gs->{repo_id}.url";
1278         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1279         if ($orig_url && ($orig_url ne $gs->{url})) {
1280                 die "$k already set: $orig_url\n",
1281                     "wanted to set to: $gs->{url}\n";
1282         }
1283         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1284         my $remote_path = "$gs->{path}/$repo_path";
1285         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1286         $remote_path =~ s#/+#/#g;
1287         $remote_path =~ s#^/##g;
1288         $remote_path .= "/*" if $remote_path !~ /\*/;
1289         my ($n) = ($switch =~ /^--(\w+)/);
1290         if (length $pfx && $pfx !~ m#/$#) {
1291                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1292         }
1293         command_noisy('config',
1294                       '--add',
1295                       "svn-remote.$gs->{repo_id}.$n",
1296                       "$remote_path:refs/remotes/$pfx*" .
1297                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1298 }
1299
1300 sub verify_ref {
1301         my ($ref) = @_;
1302         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1303                                { STDERR => 0 }); };
1304 }
1305
1306 sub get_tree_from_treeish {
1307         my ($treeish) = @_;
1308         # $treeish can be a symbolic ref, too:
1309         my $type = command_oneline(qw/cat-file -t/, $treeish);
1310         my $expected;
1311         while ($type eq 'tag') {
1312                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1313         }
1314         if ($type eq 'commit') {
1315                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1316                                                     $treeish))[0];
1317                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1318                 die "Unable to get tree from $treeish\n" unless $expected;
1319         } elsif ($type eq 'tree') {
1320                 $expected = $treeish;
1321         } else {
1322                 die "$treeish is a $type, expected tree, tag or commit\n";
1323         }
1324         return $expected;
1325 }
1326
1327 sub get_commit_entry {
1328         my ($treeish) = shift;
1329         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1330         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1331         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1332         open my $log_fh, '>', $commit_editmsg or croak $!;
1333
1334         my $type = command_oneline(qw/cat-file -t/, $treeish);
1335         if ($type eq 'commit' || $type eq 'tag') {
1336                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1337                                                          $type, $treeish);
1338                 my $in_msg = 0;
1339                 my $author;
1340                 my $saw_from = 0;
1341                 my $msgbuf = "";
1342                 while (<$msg_fh>) {
1343                         if (!$in_msg) {
1344                                 $in_msg = 1 if (/^\s*$/);
1345                                 $author = $1 if (/^author (.*>)/);
1346                         } elsif (/^git-svn-id: /) {
1347                                 # skip this for now, we regenerate the
1348                                 # correct one on re-fetch anyways
1349                                 # TODO: set *:merge properties or like...
1350                         } else {
1351                                 if (/^From:/ || /^Signed-off-by:/) {
1352                                         $saw_from = 1;
1353                                 }
1354                                 $msgbuf .= $_;
1355                         }
1356                 }
1357                 $msgbuf =~ s/\s+$//s;
1358                 if ($Git::SVN::_add_author_from && defined($author)
1359                     && !$saw_from) {
1360                         $msgbuf .= "\n\nFrom: $author";
1361                 }
1362                 print $log_fh $msgbuf or croak $!;
1363                 command_close_pipe($msg_fh, $ctx);
1364         }
1365         close $log_fh or croak $!;
1366
1367         if ($_edit || ($type eq 'tree')) {
1368                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1369                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1370         }
1371         rename $commit_editmsg, $commit_msg or croak $!;
1372         {
1373                 require Encode;
1374                 # SVN requires messages to be UTF-8 when entering the repo
1375                 local $/;
1376                 open $log_fh, '<', $commit_msg or croak $!;
1377                 binmode $log_fh;
1378                 chomp($log_entry{log} = <$log_fh>);
1379
1380                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1381                 my $msg = $log_entry{log};
1382
1383                 eval { $msg = Encode::decode($enc, $msg, 1) };
1384                 if ($@) {
1385                         die "Could not decode as $enc:\n", $msg,
1386                             "\nPerhaps you need to set i18n.commitencoding\n";
1387                 }
1388
1389                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1390                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1391
1392                 $log_entry{log} = $msg;
1393
1394                 close $log_fh or croak $!;
1395         }
1396         unlink $commit_msg;
1397         \%log_entry;
1398 }
1399
1400 sub s_to_file {
1401         my ($str, $file, $mode) = @_;
1402         open my $fd,'>',$file or croak $!;
1403         print $fd $str,"\n" or croak $!;
1404         close $fd or croak $!;
1405         chmod ($mode &~ umask, $file) if (defined $mode);
1406 }
1407
1408 sub file_to_s {
1409         my $file = shift;
1410         open my $fd,'<',$file or croak "$!: file: $file\n";
1411         local $/;
1412         my $ret = <$fd>;
1413         close $fd or croak $!;
1414         $ret =~ s/\s*$//s;
1415         return $ret;
1416 }
1417
1418 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1419 sub load_authors {
1420         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1421         my $log = $cmd eq 'log';
1422         while (<$authors>) {
1423                 chomp;
1424                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1425                 my ($user, $name, $email) = ($1, $2, $3);
1426                 if ($log) {
1427                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1428                 } else {
1429                         $users{$user} = [$name, $email];
1430                 }
1431         }
1432         close $authors or croak $!;
1433 }
1434
1435 # convert GetOpt::Long specs for use by git-config
1436 sub read_git_config {
1437         my $opts = shift;
1438         my @config_only;
1439         foreach my $o (keys %$opts) {
1440                 # if we have mixedCase and a long option-only, then
1441                 # it's a config-only variable that we don't need for
1442                 # the command-line.
1443                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1444                 my $v = $opts->{$o};
1445                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1446                 $key =~ s/-//g;
1447                 my $arg = 'git config';
1448                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1449                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1450                 if (ref $v eq 'ARRAY') {
1451                         chomp(my @tmp = `$arg --get-all svn.$key`);
1452                         @$v = @tmp if @tmp;
1453                 } else {
1454                         chomp(my $tmp = `$arg --get svn.$key`);
1455                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1456                                 $$v = $tmp;
1457                         }
1458                 }
1459         }
1460         delete @$opts{@config_only} if @config_only;
1461 }
1462
1463 sub extract_metadata {
1464         my $id = shift or return (undef, undef, undef);
1465         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1466                                                         \s([a-f\d\-]+)$/ix);
1467         if (!defined $rev || !$uuid || !$url) {
1468                 # some of the original repositories I made had
1469                 # identifiers like this:
1470                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1471         }
1472         return ($url, $rev, $uuid);
1473 }
1474
1475 sub cmt_metadata {
1476         return extract_metadata((grep(/^git-svn-id: /,
1477                 command(qw/cat-file commit/, shift)))[-1]);
1478 }
1479
1480 sub cmt_sha2rev_batch {
1481         my %s2r;
1482         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1483         my $list = shift;
1484
1485         foreach my $sha (@{$list}) {
1486                 my $first = 1;
1487                 my $size = 0;
1488                 print $out $sha, "\n";
1489
1490                 while (my $line = <$in>) {
1491                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1492                                 last;
1493                         } elsif ($first &&
1494                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1495                                 $first = 0;
1496                                 $size = $1;
1497                                 next;
1498                         } elsif ($line =~ /^(git-svn-id: )/) {
1499                                 my (undef, $rev, undef) =
1500                                                       extract_metadata($line);
1501                                 $s2r{$sha} = $rev;
1502                         }
1503
1504                         $size -= length($line);
1505                         last if ($size == 0);
1506                 }
1507         }
1508
1509         command_close_bidi_pipe($pid, $in, $out, $ctx);
1510
1511         return \%s2r;
1512 }
1513
1514 sub working_head_info {
1515         my ($head, $refs) = @_;
1516         my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1517         my ($fh, $ctx) = command_output_pipe(@args, $head);
1518         my $hash;
1519         my %max;
1520         while (<$fh>) {
1521                 if ( m{^commit ($::sha1)$} ) {
1522                         unshift @$refs, $hash if $hash and $refs;
1523                         $hash = $1;
1524                         next;
1525                 }
1526                 next unless s{^\s*(git-svn-id:)}{$1};
1527                 my ($url, $rev, $uuid) = extract_metadata($_);
1528                 if (defined $url && defined $rev) {
1529                         next if $max{$url} and $max{$url} < $rev;
1530                         if (my $gs = Git::SVN->find_by_url($url)) {
1531                                 my $c = $gs->rev_map_get($rev, $uuid);
1532                                 if ($c && $c eq $hash) {
1533                                         close $fh; # break the pipe
1534                                         return ($url, $rev, $uuid, $gs);
1535                                 } else {
1536                                         $max{$url} ||= $gs->rev_map_max;
1537                                 }
1538                         }
1539                 }
1540         }
1541         command_close_pipe($fh, $ctx);
1542         (undef, undef, undef, undef);
1543 }
1544
1545 sub read_commit_parents {
1546         my ($parents, $c) = @_;
1547         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1548         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1549         @{$parents->{$c}} = split(/ /, $p);
1550 }
1551
1552 sub linearize_history {
1553         my ($gs, $refs) = @_;
1554         my %parents;
1555         foreach my $c (@$refs) {
1556                 read_commit_parents(\%parents, $c);
1557         }
1558
1559         my @linear_refs;
1560         my %skip = ();
1561         my $last_svn_commit = $gs->last_commit;
1562         foreach my $c (reverse @$refs) {
1563                 next if $c eq $last_svn_commit;
1564                 last if $skip{$c};
1565
1566                 unshift @linear_refs, $c;
1567                 $skip{$c} = 1;
1568
1569                 # we only want the first parent to diff against for linear
1570                 # history, we save the rest to inject when we finalize the
1571                 # svn commit
1572                 my $fp_a = verify_ref("$c~1");
1573                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1574                 if (!$fp_a || !$fp_b) {
1575                         die "Commit $c\n",
1576                             "has no parent commit, and therefore ",
1577                             "nothing to diff against.\n",
1578                             "You should be working from a repository ",
1579                             "originally created by git-svn\n";
1580                 }
1581                 if ($fp_a ne $fp_b) {
1582                         die "$c~1 = $fp_a, however parsing commit $c ",
1583                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1584                 }
1585
1586                 foreach my $p (@{$parents{$c}}) {
1587                         $skip{$p} = 1;
1588                 }
1589         }
1590         (\@linear_refs, \%parents);
1591 }
1592
1593 sub find_file_type_and_diff_status {
1594         my ($path) = @_;
1595         return ('dir', '') if $path eq '';
1596
1597         my $diff_output =
1598             command_oneline(qw(diff --cached --name-status --), $path) || "";
1599         my $diff_status = (split(' ', $diff_output))[0] || "";
1600
1601         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1602
1603         return (undef, undef) if !$diff_status && !$ls_tree;
1604
1605         if ($diff_status eq "A") {
1606                 return ("link", $diff_status) if -l $path;
1607                 return ("dir", $diff_status) if -d $path;
1608                 return ("file", $diff_status);
1609         }
1610
1611         my $mode = (split(' ', $ls_tree))[0] || "";
1612
1613         return ("link", $diff_status) if $mode eq "120000";
1614         return ("dir", $diff_status) if $mode eq "040000";
1615         return ("file", $diff_status);
1616 }
1617
1618 sub md5sum {
1619         my $arg = shift;
1620         my $ref = ref $arg;
1621         my $md5 = Digest::MD5->new();
1622         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1623                 $md5->addfile($arg) or croak $!;
1624         } elsif ($ref eq 'SCALAR') {
1625                 $md5->add($$arg) or croak $!;
1626         } elsif (!$ref) {
1627                 $md5->add($arg) or croak $!;
1628         } else {
1629                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1630         }
1631         return $md5->hexdigest();
1632 }
1633
1634 sub gc_directory {
1635         if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1636                 my $out_filename = $_ . ".gz";
1637                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1638                 binmode $in_fh;
1639                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1640                                 die "Unable to open $out_filename: $!\n";
1641
1642                 my $res;
1643                 while ($res = sysread($in_fh, my $str, 1024)) {
1644                         $gz->gzwrite($str) or
1645                                 die "Unable to write: ".$gz->gzerror()."!\n";
1646                 }
1647                 unlink $_ or die "unlink $File::Find::name: $!\n";
1648         } elsif (-f $_ && basename($_) eq "index") {
1649                 unlink $_ or die "unlink $_: $!\n";
1650         }
1651 }
1652
1653 package Git::SVN;
1654 use strict;
1655 use warnings;
1656 use Fcntl qw/:DEFAULT :seek/;
1657 use constant rev_map_fmt => 'NH40';
1658 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1659             $_repack $_repack_flags $_use_svm_props $_head
1660             $_use_svnsync_props $no_reuse_existing $_minimize_url
1661             $_use_log_author $_add_author_from $_localtime/;
1662 use Carp qw/croak/;
1663 use File::Path qw/mkpath/;
1664 use File::Copy qw/copy/;
1665 use IPC::Open3;
1666 use Memoize;  # core since 5.8.0, Jul 2002
1667 use Memoize::Storable;
1668
1669 my ($_gc_nr, $_gc_period);
1670
1671 # properties that we do not log:
1672 my %SKIP_PROP;
1673 BEGIN {
1674         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1675                                         svn:special svn:executable
1676                                         svn:entry:committed-rev
1677                                         svn:entry:last-author
1678                                         svn:entry:uuid
1679                                         svn:entry:committed-date/;
1680
1681         # some options are read globally, but can be overridden locally
1682         # per [svn-remote "..."] section.  Command-line options will *NOT*
1683         # override options set in an [svn-remote "..."] section
1684         no strict 'refs';
1685         for my $option (qw/follow_parent no_metadata use_svm_props
1686                            use_svnsync_props/) {
1687                 my $key = $option;
1688                 $key =~ tr/_//d;
1689                 my $prop = "-$option";
1690                 *$option = sub {
1691                         my ($self) = @_;
1692                         return $self->{$prop} if exists $self->{$prop};
1693                         my $k = "svn-remote.$self->{repo_id}.$key";
1694                         eval { command_oneline(qw/config --get/, $k) };
1695                         if ($@) {
1696                                 $self->{$prop} = ${"Git::SVN::_$option"};
1697                         } else {
1698                                 my $v = command_oneline(qw/config --bool/,$k);
1699                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1700                         }
1701                         return $self->{$prop};
1702                 }
1703         }
1704 }
1705
1706
1707 my (%LOCKFILES, %INDEX_FILES);
1708 END {
1709         unlink keys %LOCKFILES if %LOCKFILES;
1710         unlink keys %INDEX_FILES if %INDEX_FILES;
1711 }
1712
1713 sub resolve_local_globs {
1714         my ($url, $fetch, $glob_spec) = @_;
1715         return unless defined $glob_spec;
1716         my $ref = $glob_spec->{ref};
1717         my $path = $glob_spec->{path};
1718         foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
1719                 next unless m#^$ref->{regex}$#;
1720                 my $p = $1;
1721                 my $pathname = desanitize_refname($path->full_path($p));
1722                 my $refname = desanitize_refname($ref->full_path($p));
1723                 if (my $existing = $fetch->{$pathname}) {
1724                         if ($existing ne $refname) {
1725                                 die "Refspec conflict:\n",
1726                                     "existing: $existing\n",
1727                                     " globbed: $refname\n";
1728                         }
1729                         my $u = (::cmt_metadata("$refname"))[0];
1730                         $u =~ s!^\Q$url\E(/|$)!! or die
1731                           "$refname: '$url' not found in '$u'\n";
1732                         if ($pathname ne $u) {
1733                                 warn "W: Refspec glob conflict ",
1734                                      "(ref: $refname):\n",
1735                                      "expected path: $pathname\n",
1736                                      "    real path: $u\n",
1737                                      "Continuing ahead with $u\n";
1738                                 next;
1739                         }
1740                 } else {
1741                         $fetch->{$pathname} = $refname;
1742                 }
1743         }
1744 }
1745
1746 sub parse_revision_argument {
1747         my ($base, $head) = @_;
1748         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1749                 return ($base, $head);
1750         }
1751         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1752         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1753         return ($head, $head) if ($::_revision eq 'HEAD');
1754         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1755         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1756         die "revision argument: $::_revision not understood by git-svn\n";
1757 }
1758
1759 sub fetch_all {
1760         my ($repo_id, $remotes) = @_;
1761         if (ref $repo_id) {
1762                 my $gs = $repo_id;
1763                 $repo_id = undef;
1764                 $repo_id = $gs->{repo_id};
1765         }
1766         $remotes ||= read_all_remotes();
1767         my $remote = $remotes->{$repo_id} or
1768                      die "[svn-remote \"$repo_id\"] unknown\n";
1769         my $fetch = $remote->{fetch};
1770         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1771         my (@gs, @globs);
1772         my $ra = Git::SVN::Ra->new($url);
1773         my $uuid = $ra->get_uuid;
1774         my $head = $ra->get_latest_revnum;
1775
1776         # ignore errors, $head revision may not even exist anymore
1777         eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
1778         warn "W: $@\n" if $@;
1779
1780         my $base = defined $fetch ? $head : 0;
1781
1782         # read the max revs for wildcard expansion (branches/*, tags/*)
1783         foreach my $t (qw/branches tags/) {
1784                 defined $remote->{$t} or next;
1785                 push @globs, @{$remote->{$t}};
1786
1787                 my $max_rev = eval { tmp_config(qw/--int --get/,
1788                                          "svn-remote.$repo_id.${t}-maxRev") };
1789                 if (defined $max_rev && ($max_rev < $base)) {
1790                         $base = $max_rev;
1791                 } elsif (!defined $max_rev) {
1792                         $base = 0;
1793                 }
1794         }
1795
1796         if ($fetch) {
1797                 foreach my $p (sort keys %$fetch) {
1798                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1799                         my $lr = $gs->rev_map_max;
1800                         if (defined $lr) {
1801                                 $base = $lr if ($lr < $base);
1802                         }
1803                         push @gs, $gs;
1804                 }
1805         }
1806
1807         ($base, $head) = parse_revision_argument($base, $head);
1808         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1809 }
1810
1811 sub read_all_remotes {
1812         my $r = {};
1813         my $use_svm_props = eval { command_oneline(qw/config --bool
1814             svn.useSvmProps/) };
1815         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1816         my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
1817         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1818                 if (m!^(.+)\.fetch=$svn_refspec$!) {
1819                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1820                         die("svn-remote.$remote: remote ref '$remote_ref' "
1821                             . "must start with 'refs/'\n")
1822                                 unless $remote_ref =~ m{^refs/};
1823                         $local_ref = uri_decode($local_ref);
1824                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1825                         $r->{$remote}->{svm} = {} if $use_svm_props;
1826                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1827                         $r->{$1}->{svm} = {};
1828                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1829                         $r->{$1}->{url} = $2;
1830                 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
1831                         my ($remote, $t, $local_ref, $remote_ref) =
1832                                                              ($1, $2, $3, $4);
1833                         die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
1834                             . "must start with 'refs/'\n")
1835                                 unless $remote_ref =~ m{^refs/};
1836                         $local_ref = uri_decode($local_ref);
1837                         my $rs = {
1838                             t => $t,
1839                             remote => $remote,
1840                             path => Git::SVN::GlobSpec->new($local_ref, 1),
1841                             ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
1842                         if (length($rs->{ref}->{right}) != 0) {
1843                                 die "The '*' glob character must be the last ",
1844                                     "character of '$remote_ref'\n";
1845                         }
1846                         push @{ $r->{$remote}->{$t} }, $rs;
1847                 }
1848         }
1849
1850         map {
1851                 if (defined $r->{$_}->{svm}) {
1852                         my $svm;
1853                         eval {
1854                                 my $section = "svn-remote.$_";
1855                                 $svm = {
1856                                         source => tmp_config('--get',
1857                                             "$section.svm-source"),
1858                                         replace => tmp_config('--get',
1859                                             "$section.svm-replace"),
1860                                 }
1861                         };
1862                         $r->{$_}->{svm} = $svm;
1863                 }
1864         } keys %$r;
1865
1866         $r;
1867 }
1868
1869 sub init_vars {
1870         $_gc_nr = $_gc_period = 1000;
1871         if (defined $_repack || defined $_repack_flags) {
1872                warn "Repack options are obsolete; they have no effect.\n";
1873         }
1874 }
1875
1876 sub verify_remotes_sanity {
1877         return unless -d $ENV{GIT_DIR};
1878         my %seen;
1879         foreach (command(qw/config -l/)) {
1880                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1881                         if ($seen{$1}) {
1882                                 die "Remote ref refs/remote/$1 is tracked by",
1883                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1884                                     "Please resolve this ambiguity in ",
1885                                     "your git configuration file before ",
1886                                     "continuing\n";
1887                         }
1888                         $seen{$1} = $_;
1889                 }
1890         }
1891 }
1892
1893 sub find_existing_remote {
1894         my ($url, $remotes) = @_;
1895         return undef if $no_reuse_existing;
1896         my $existing;
1897         foreach my $repo_id (keys %$remotes) {
1898                 my $u = $remotes->{$repo_id}->{url} or next;
1899                 next if $u ne $url;
1900                 $existing = $repo_id;
1901                 last;
1902         }
1903         $existing;
1904 }
1905
1906 sub init_remote_config {
1907         my ($self, $url, $no_write) = @_;
1908         $url =~ s!/+$!!; # strip trailing slash
1909         my $r = read_all_remotes();
1910         my $existing = find_existing_remote($url, $r);
1911         if ($existing) {
1912                 unless ($no_write) {
1913                         print STDERR "Using existing ",
1914                                      "[svn-remote \"$existing\"]\n";
1915                 }
1916                 $self->{repo_id} = $existing;
1917         } elsif ($_minimize_url) {
1918                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1919                 $existing = find_existing_remote($min_url, $r);
1920                 if ($existing) {
1921                         unless ($no_write) {
1922                                 print STDERR "Using existing ",
1923                                              "[svn-remote \"$existing\"]\n";
1924                         }
1925                         $self->{repo_id} = $existing;
1926                 }
1927                 if ($min_url ne $url) {
1928                         unless ($no_write) {
1929                                 print STDERR "Using higher level of URL: ",
1930                                              "$url => $min_url\n";
1931                         }
1932                         my $old_path = $self->{path};
1933                         $self->{path} = $url;
1934                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1935                         if (length $old_path) {
1936                                 $self->{path} .= "/$old_path";
1937                         }
1938                         $url = $min_url;
1939                 }
1940         }
1941         my $orig_url;
1942         if (!$existing) {
1943                 # verify that we aren't overwriting anything:
1944                 $orig_url = eval {
1945                         command_oneline('config', '--get',
1946                                         "svn-remote.$self->{repo_id}.url")
1947                 };
1948                 if ($orig_url && ($orig_url ne $url)) {
1949                         die "svn-remote.$self->{repo_id}.url already set: ",
1950                             "$orig_url\nwanted to set to: $url\n";
1951                 }
1952         }
1953         my ($xrepo_id, $xpath) = find_ref($self->refname);
1954         if (!$no_write && defined $xpath) {
1955                 die "svn-remote.$xrepo_id.fetch already set to track ",
1956                     "$xpath:", $self->refname, "\n";
1957         }
1958         unless ($no_write) {
1959                 command_noisy('config',
1960                               "svn-remote.$self->{repo_id}.url", $url);
1961                 $self->{path} =~ s{^/}{};
1962                 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1963                 command_noisy('config', '--add',
1964                               "svn-remote.$self->{repo_id}.fetch",
1965                               "$self->{path}:".$self->refname);
1966         }
1967         $self->{url} = $url;
1968 }
1969
1970 sub find_by_url { # repos_root and, path are optional
1971         my ($class, $full_url, $repos_root, $path) = @_;
1972
1973         return undef unless defined $full_url;
1974         remove_username($full_url);
1975         remove_username($repos_root) if defined $repos_root;
1976         my $remotes = read_all_remotes();
1977         if (defined $full_url && defined $repos_root && !defined $path) {
1978                 $path = $full_url;
1979                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1980         }
1981         foreach my $repo_id (keys %$remotes) {
1982                 my $u = $remotes->{$repo_id}->{url} or next;
1983                 remove_username($u);
1984                 next if defined $repos_root && $repos_root ne $u;
1985
1986                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1987                 foreach my $t (qw/branches tags/) {
1988                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1989                                 resolve_local_globs($u, $fetch, $globspec);
1990                         }
1991                 }
1992                 my $p = $path;
1993                 my $rwr = rewrite_root({repo_id => $repo_id});
1994                 my $svm = $remotes->{$repo_id}->{svm}
1995                         if defined $remotes->{$repo_id}->{svm};
1996                 unless (defined $p) {
1997                         $p = $full_url;
1998                         my $z = $u;
1999                         my $prefix = '';
2000                         if ($rwr) {
2001                                 $z = $rwr;
2002                                 remove_username($z);
2003                         } elsif (defined $svm) {
2004                                 $z = $svm->{source};
2005                                 $prefix = $svm->{replace};
2006                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
2007                                 $prefix =~ s#/$##;
2008                         }
2009                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
2010                 }
2011                 foreach my $f (keys %$fetch) {
2012                         next if $f ne $p;
2013                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
2014                 }
2015         }
2016         undef;
2017 }
2018
2019 sub init {
2020         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
2021         my $self = _new($class, $repo_id, $ref_id, $path);
2022         if (defined $url) {
2023                 $self->init_remote_config($url, $no_write);
2024         }
2025         $self;
2026 }
2027
2028 sub find_ref {
2029         my ($ref_id) = @_;
2030         foreach (command(qw/config -l/)) {
2031                 next unless m!^svn-remote\.(.+)\.fetch=
2032                               \s*(.*?)\s*:\s*(.+?)\s*$!x;
2033                 my ($repo_id, $path, $ref) = ($1, $2, $3);
2034                 if ($ref eq $ref_id) {
2035                         $path = '' if ($path =~ m#^\./?#);
2036                         return ($repo_id, $path);
2037                 }
2038         }
2039         (undef, undef, undef);
2040 }
2041
2042 sub new {
2043         my ($class, $ref_id, $repo_id, $path) = @_;
2044         if (defined $ref_id && !defined $repo_id && !defined $path) {
2045                 ($repo_id, $path) = find_ref($ref_id);
2046                 if (!defined $repo_id) {
2047                         die "Could not find a \"svn-remote.*.fetch\" key ",
2048                             "in the repository configuration matching: ",
2049                             "$ref_id\n";
2050                 }
2051         }
2052         my $self = _new($class, $repo_id, $ref_id, $path);
2053         if (!defined $self->{path} || !length $self->{path}) {
2054                 my $fetch = command_oneline('config', '--get',
2055                                             "svn-remote.$repo_id.fetch",
2056                                             ":$ref_id\$") or
2057                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
2058                          "\":$ref_id\$\" in config\n";
2059                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
2060         }
2061         $self->{path} =~ s{/+}{/}g;
2062         $self->{path} =~ s{\A/}{};
2063         $self->{path} =~ s{/\z}{};
2064         $self->{url} = command_oneline('config', '--get',
2065                                        "svn-remote.$repo_id.url") or
2066                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
2067         $self->rebuild;
2068         $self;
2069 }
2070
2071 sub refname {
2072         my ($refname) = $_[0]->{ref_id} ;
2073
2074         # It cannot end with a slash /, we'll throw up on this because
2075         # SVN can't have directories with a slash in their name, either:
2076         if ($refname =~ m{/$}) {
2077                 die "ref: '$refname' ends with a trailing slash, this is ",
2078                     "not permitted by git nor Subversion\n";
2079         }
2080
2081         # It cannot have ASCII control character space, tilde ~, caret ^,
2082         # colon :, question-mark ?, asterisk *, space, or open bracket [
2083         # anywhere.
2084         #
2085         # Additionally, % must be escaped because it is used for escaping
2086         # and we want our escaped refname to be reversible
2087         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2088
2089         # no slash-separated component can begin with a dot .
2090         # /.* becomes /%2E*
2091         $refname =~ s{/\.}{/%2E}g;
2092
2093         # It cannot have two consecutive dots .. anywhere
2094         # .. becomes %2E%2E
2095         $refname =~ s{\.\.}{%2E%2E}g;
2096
2097         # trailing dots and .lock are not allowed
2098         # .$ becomes %2E and .lock becomes %2Elock
2099         $refname =~ s{\.(?=$|lock$)}{%2E};
2100
2101         # the sequence @{ is used to access the reflog
2102         # @{ becomes %40{
2103         $refname =~ s{\@\{}{%40\{}g;
2104
2105         return $refname;
2106 }
2107
2108 sub desanitize_refname {
2109         my ($refname) = @_;
2110         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2111         return $refname;
2112 }
2113
2114 sub svm_uuid {
2115         my ($self) = @_;
2116         return $self->{svm}->{uuid} if $self->svm;
2117         $self->ra;
2118         unless ($self->{svm}) {
2119                 die "SVM UUID not cached, and reading remotely failed\n";
2120         }
2121         $self->{svm}->{uuid};
2122 }
2123
2124 sub svm {
2125         my ($self) = @_;
2126         return $self->{svm} if $self->{svm};
2127         my $svm;
2128         # see if we have it in our config, first:
2129         eval {
2130                 my $section = "svn-remote.$self->{repo_id}";
2131                 $svm = {
2132                   source => tmp_config('--get', "$section.svm-source"),
2133                   uuid => tmp_config('--get', "$section.svm-uuid"),
2134                   replace => tmp_config('--get', "$section.svm-replace"),
2135                 }
2136         };
2137         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2138                 $self->{svm} = $svm;
2139         }
2140         $self->{svm};
2141 }
2142
2143 sub _set_svm_vars {
2144         my ($self, $ra) = @_;
2145         return $ra if $self->svm;
2146
2147         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2148                     "(svm:source, svm:uuid) ",
2149                     "from the following URLs:\n" );
2150         sub read_svm_props {
2151                 my ($self, $ra, $path, $r) = @_;
2152                 my $props = ($ra->get_dir($path, $r))[2];
2153                 my $src = $props->{'svm:source'};
2154                 my $uuid = $props->{'svm:uuid'};
2155                 return undef if (!$src || !$uuid);
2156
2157                 chomp($src, $uuid);
2158
2159                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2160                     or die "doesn't look right - svm:uuid is '$uuid'\n";
2161
2162                 # the '!' is used to mark the repos_root!/relative/path
2163                 $src =~ s{/?!/?}{/};
2164                 $src =~ s{/+$}{}; # no trailing slashes please
2165                 # username is of no interest
2166                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2167
2168                 my $replace = $ra->{url};
2169                 $replace .= "/$path" if length $path;
2170
2171                 my $section = "svn-remote.$self->{repo_id}";
2172                 tmp_config("$section.svm-source", $src);
2173                 tmp_config("$section.svm-replace", $replace);
2174                 tmp_config("$section.svm-uuid", $uuid);
2175                 $self->{svm} = {
2176                         source => $src,
2177                         uuid => $uuid,
2178                         replace => $replace
2179                 };
2180         }
2181
2182         my $r = $ra->get_latest_revnum;
2183         my $path = $self->{path};
2184         my %tried;
2185         while (length $path) {
2186                 unless ($tried{"$self->{url}/$path"}) {
2187                         return $ra if $self->read_svm_props($ra, $path, $r);
2188                         $tried{"$self->{url}/$path"} = 1;
2189                 }
2190                 $path =~ s#/?[^/]+$##;
2191         }
2192         die "Path: '$path' should be ''\n" if $path ne '';
2193         return $ra if $self->read_svm_props($ra, $path, $r);
2194         $tried{"$self->{url}/$path"} = 1;
2195
2196         if ($ra->{repos_root} eq $self->{url}) {
2197                 die @err, (map { "  $_\n" } keys %tried), "\n";
2198         }
2199
2200         # nope, make sure we're connected to the repository root:
2201         my $ok;
2202         my @tried_b;
2203         $path = $ra->{svn_path};
2204         $ra = Git::SVN::Ra->new($ra->{repos_root});
2205         while (length $path) {
2206                 unless ($tried{"$ra->{url}/$path"}) {
2207                         $ok = $self->read_svm_props($ra, $path, $r);
2208                         last if $ok;
2209                         $tried{"$ra->{url}/$path"} = 1;
2210                 }
2211                 $path =~ s#/?[^/]+$##;
2212         }
2213         die "Path: '$path' should be ''\n" if $path ne '';
2214         $ok ||= $self->read_svm_props($ra, $path, $r);
2215         $tried{"$ra->{url}/$path"} = 1;
2216         if (!$ok) {
2217                 die @err, (map { "  $_\n" } keys %tried), "\n";
2218         }
2219         Git::SVN::Ra->new($self->{url});
2220 }
2221
2222 sub svnsync {
2223         my ($self) = @_;
2224         return $self->{svnsync} if $self->{svnsync};
2225
2226         if ($self->no_metadata) {
2227                 die "Can't have both 'noMetadata' and ",
2228                     "'useSvnsyncProps' options set!\n";
2229         }
2230         if ($self->rewrite_root) {
2231                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2232                     "options set!\n";
2233         }
2234         if ($self->rewrite_uuid) {
2235                 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
2236                     "options set!\n";
2237         }
2238
2239         my $svnsync;
2240         # see if we have it in our config, first:
2241         eval {
2242                 my $section = "svn-remote.$self->{repo_id}";
2243
2244                 my $url = tmp_config('--get', "$section.svnsync-url");
2245                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2246                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2247
2248                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2249                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2250                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2251
2252                 $svnsync = { url => $url, uuid => $uuid }
2253         };
2254         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2255                 return $self->{svnsync} = $svnsync;
2256         }
2257
2258         my $err = "useSvnsyncProps set, but failed to read " .
2259                   "svnsync property: svn:sync-from-";
2260         my $rp = $self->ra->rev_proplist(0);
2261
2262         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2263         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2264                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2265
2266         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2267         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2268                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2269
2270         my $section = "svn-remote.$self->{repo_id}";
2271         tmp_config('--add', "$section.svnsync-uuid", $uuid);
2272         tmp_config('--add', "$section.svnsync-url", $url);
2273         return $self->{svnsync} = { url => $url, uuid => $uuid };
2274 }
2275
2276 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2277 # remote lookup (useful for 'git svn log').
2278 sub ra_uuid {
2279         my ($self) = @_;
2280         unless ($self->{ra_uuid}) {
2281                 my $key = "svn-remote.$self->{repo_id}.uuid";
2282                 my $uuid = eval { tmp_config('--get', $key) };
2283                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2284                         $self->{ra_uuid} = $uuid;
2285                 } else {
2286                         die "ra_uuid called without URL\n" unless $self->{url};
2287                         $self->{ra_uuid} = $self->ra->get_uuid;
2288                         tmp_config('--add', $key, $self->{ra_uuid});
2289                 }
2290         }
2291         $self->{ra_uuid};
2292 }
2293
2294 sub _set_repos_root {
2295         my ($self, $repos_root) = @_;
2296         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2297         $repos_root ||= $self->ra->{repos_root};
2298         tmp_config($k, $repos_root);
2299         $repos_root;
2300 }
2301
2302 sub repos_root {
2303         my ($self) = @_;
2304         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2305         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2306 }
2307
2308 sub ra {
2309         my ($self) = shift;
2310         my $ra = Git::SVN::Ra->new($self->{url});
2311         $self->_set_repos_root($ra->{repos_root});
2312         if ($self->use_svm_props && !$self->{svm}) {
2313                 if ($self->no_metadata) {
2314                         die "Can't have both 'noMetadata' and ",
2315                             "'useSvmProps' options set!\n";
2316                 } elsif ($self->use_svnsync_props) {
2317                         die "Can't have both 'useSvnsyncProps' and ",
2318                             "'useSvmProps' options set!\n";
2319                 }
2320                 $ra = $self->_set_svm_vars($ra);
2321                 $self->{-want_revprops} = 1;
2322         }
2323         $ra;
2324 }
2325
2326 # prop_walk(PATH, REV, SUB)
2327 # -------------------------
2328 # Recursively traverse PATH at revision REV and invoke SUB for each
2329 # directory that contains a SVN property.  SUB will be invoked as
2330 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2331 # Git::SVN, `path' the path to the directory where the properties
2332 # `props' were found.  The `path' will be relative to point of checkout,
2333 # that is, if url://repo/trunk is the current Git branch, and that
2334 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2335 # as `path' (note the trailing `/').
2336 sub prop_walk {
2337         my ($self, $path, $rev, $sub) = @_;
2338
2339         $path =~ s#^/##;
2340         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2341         $path =~ s#^/*#/#g;
2342         my $p = $path;
2343         # Strip the irrelevant part of the path.
2344         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2345         # Ensure the path is terminated by a `/'.
2346         $p =~ s#/*$#/#;
2347
2348         # The properties contain all the internal SVN stuff nobody
2349         # (usually) cares about.
2350         my $interesting_props = 0;
2351         foreach (keys %{$props}) {
2352                 # If it doesn't start with `svn:', it must be a
2353                 # user-defined property.
2354                 ++$interesting_props and next if $_ !~ /^svn:/;
2355                 # FIXME: Fragile, if SVN adds new public properties,
2356                 # this needs to be updated.
2357                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2358                                                  |eol-style|mime-type
2359                                                  |externals|needs-lock)$/x;
2360         }
2361         &$sub($self, $p, $props) if $interesting_props;
2362
2363         foreach (sort keys %$dirent) {
2364                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2365                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2366         }
2367 }
2368
2369 sub last_rev { ($_[0]->last_rev_commit)[0] }
2370 sub last_commit { ($_[0]->last_rev_commit)[1] }
2371
2372 # returns the newest SVN revision number and newest commit SHA1
2373 sub last_rev_commit {
2374         my ($self) = @_;
2375         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2376                 return ($self->{last_rev}, $self->{last_commit});
2377         }
2378         my $c = ::verify_ref($self->refname.'^0');
2379         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2380                 my $rev = (::cmt_metadata($c))[1];
2381                 if (defined $rev) {
2382                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2383                         return ($rev, $c);
2384                 }
2385         }
2386         my $map_path = $self->map_path;
2387         unless (-e $map_path) {
2388                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2389                 return (undef, undef);
2390         }
2391         my ($rev, $commit) = $self->rev_map_max(1);
2392         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2393         return ($rev, $commit);
2394 }
2395
2396 sub get_fetch_range {
2397         my ($self, $min, $max) = @_;
2398         $max ||= $self->ra->get_latest_revnum;
2399         $min ||= $self->rev_map_max;
2400         (++$min, $max);
2401 }
2402
2403 sub tmp_config {
2404         my (@args) = @_;
2405         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2406         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2407         if (! -f $config && -f $old_def_config) {
2408                 rename $old_def_config, $config or
2409                        die "Failed rename $old_def_config => $config: $!\n";
2410         }
2411         my $old_config = $ENV{GIT_CONFIG};
2412         $ENV{GIT_CONFIG} = $config;
2413         $@ = undef;
2414         my @ret = eval {
2415                 unless (-f $config) {
2416                         mkfile($config);
2417                         open my $fh, '>', $config or
2418                             die "Can't open $config: $!\n";
2419                         print $fh "; This file is used internally by ",
2420                                   "git-svn\n" or die
2421                                   "Couldn't write to $config: $!\n";
2422                         print $fh "; You should not have to edit it\n" or
2423                               die "Couldn't write to $config: $!\n";
2424                         close $fh or die "Couldn't close $config: $!\n";
2425                 }
2426                 command('config', @args);
2427         };
2428         my $err = $@;
2429         if (defined $old_config) {
2430                 $ENV{GIT_CONFIG} = $old_config;
2431         } else {
2432                 delete $ENV{GIT_CONFIG};
2433         }
2434         die $err if $err;
2435         wantarray ? @ret : $ret[0];
2436 }
2437
2438 sub tmp_index_do {
2439         my ($self, $sub) = @_;
2440         my $old_index = $ENV{GIT_INDEX_FILE};
2441         $ENV{GIT_INDEX_FILE} = $self->{index};
2442         $@ = undef;
2443         my @ret = eval {
2444                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2445                 mkpath([$dir]) unless -d $dir;
2446                 &$sub;
2447         };
2448         my $err = $@;
2449         if (defined $old_index) {
2450                 $ENV{GIT_INDEX_FILE} = $old_index;
2451         } else {
2452                 delete $ENV{GIT_INDEX_FILE};
2453         }
2454         die $err if $err;
2455         wantarray ? @ret : $ret[0];
2456 }
2457
2458 sub assert_index_clean {
2459         my ($self, $treeish) = @_;
2460
2461         $self->tmp_index_do(sub {
2462                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2463                 my $x = command_oneline('write-tree');
2464                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2465                            /^tree ($::sha1)/mo);
2466                 return if $y eq $x;
2467
2468                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2469                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2470                 command_noisy('read-tree', $treeish);
2471                 $x = command_oneline('write-tree');
2472                 if ($y ne $x) {
2473                         ::fatal "trees ($treeish) $y != $x\n",
2474                                 "Something is seriously wrong...";
2475                 }
2476         });
2477 }
2478
2479 sub get_commit_parents {
2480         my ($self, $log_entry) = @_;
2481         my (%seen, @ret, @tmp);
2482         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2483         if (my $ip = $self->{inject_parents}) {
2484                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2485                         push @tmp, $commit;
2486                 }
2487         }
2488         if (my $cur = ::verify_ref($self->refname.'^0')) {
2489                 push @tmp, $cur;
2490         }
2491         if (my $ipd = $self->{inject_parents_dcommit}) {
2492                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2493                         push @tmp, @$commit;
2494                 }
2495         }
2496         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2497         while (my $p = shift @tmp) {
2498                 next if $seen{$p};
2499                 $seen{$p} = 1;
2500                 push @ret, $p;
2501         }
2502         @ret;
2503 }
2504
2505 sub rewrite_root {
2506         my ($self) = @_;
2507         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2508         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2509         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2510         if ($rwr) {
2511                 $rwr =~ s#/+$##;
2512                 if ($rwr !~ m#^[a-z\+]+://#) {
2513                         die "$rwr is not a valid URL (key: $k)\n";
2514                 }
2515         }
2516         $self->{-rewrite_root} = $rwr;
2517 }
2518
2519 sub rewrite_uuid {
2520         my ($self) = @_;
2521         return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
2522         my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
2523         my $rwid = eval { command_oneline(qw/config --get/, $k) };
2524         if ($rwid) {
2525                 $rwid =~ s#/+$##;
2526                 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
2527                         die "$rwid is not a valid UUID (key: $k)\n";
2528                 }
2529         }
2530         $self->{-rewrite_uuid} = $rwid;
2531 }
2532
2533 sub metadata_url {
2534         my ($self) = @_;
2535         ($self->rewrite_root || $self->{url}) .
2536            (length $self->{path} ? '/' . $self->{path} : '');
2537 }
2538
2539 sub full_url {
2540         my ($self) = @_;
2541         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2542 }
2543
2544
2545 sub set_commit_header_env {
2546         my ($log_entry) = @_;
2547         my %env;
2548         foreach my $ned (qw/NAME EMAIL DATE/) {
2549                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2550                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2551                 }
2552         }
2553
2554         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2555         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2556         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2557
2558         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2559                                                 ? $log_entry->{commit_name}
2560                                                 : $log_entry->{name};
2561         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2562                                                 ? $log_entry->{commit_email}
2563                                                 : $log_entry->{email};
2564         \%env;
2565 }
2566
2567 sub restore_commit_header_env {
2568         my ($env) = @_;
2569         foreach my $ned (qw/NAME EMAIL DATE/) {
2570                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2571                         my $k = "GIT_${ac}_${ned}";
2572                         if (defined $env->{$k}) {
2573                                 $ENV{$k} = $env->{$k};
2574                         } else {
2575                                 delete $ENV{$k};
2576                         }
2577                 }
2578         }
2579 }
2580
2581 sub gc {
2582         command_noisy('gc', '--auto');
2583 };
2584
2585 sub do_git_commit {
2586         my ($self, $log_entry) = @_;
2587         my $lr = $self->last_rev;
2588         if (defined $lr && $lr >= $log_entry->{revision}) {
2589                 die "Last fetched revision of ", $self->refname,
2590                     " was r$lr, but we are about to fetch: ",
2591                     "r$log_entry->{revision}!\n";
2592         }
2593         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2594                 croak "$log_entry->{revision} = $c already exists! ",
2595                       "Why are we refetching it?\n";
2596         }
2597         my $old_env = set_commit_header_env($log_entry);
2598         my $tree = $log_entry->{tree};
2599         if (!defined $tree) {
2600                 $tree = $self->tmp_index_do(sub {
2601                                             command_oneline('write-tree') });
2602         }
2603         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2604
2605         my @exec = ('git', 'commit-tree', $tree);
2606         foreach ($self->get_commit_parents($log_entry)) {
2607                 push @exec, '-p', $_;
2608         }
2609         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2610                                                                    or croak $!;
2611         binmode $msg_fh;
2612
2613         # we always get UTF-8 from SVN, but we may want our commits in
2614         # a different encoding.
2615         if (my $enc = Git::config('i18n.commitencoding')) {
2616                 require Encode;
2617                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2618         }
2619         print $msg_fh $log_entry->{log} or croak $!;
2620         restore_commit_header_env($old_env);
2621         unless ($self->no_metadata) {
2622                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2623                               or croak $!;
2624         }
2625         $msg_fh->flush == 0 or croak $!;
2626         close $msg_fh or croak $!;
2627         chomp(my $commit = do { local $/; <$out_fh> });
2628         close $out_fh or croak $!;
2629         waitpid $pid, 0;
2630         croak $? if $?;
2631         if ($commit !~ /^$::sha1$/o) {
2632                 die "Failed to commit, invalid sha1: $commit\n";
2633         }
2634
2635         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2636
2637         $self->{last_rev} = $log_entry->{revision};
2638         $self->{last_commit} = $commit;
2639         print "r$log_entry->{revision}" unless $::_q > 1;
2640         if (defined $log_entry->{svm_revision}) {
2641                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2642                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2643                                    0, $self->svm_uuid);
2644         }
2645         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2646         if (--$_gc_nr == 0) {
2647                 $_gc_nr = $_gc_period;
2648                 gc();
2649         }
2650         return $commit;
2651 }
2652
2653 sub match_paths {
2654         my ($self, $paths, $r) = @_;
2655         return 1 if $self->{path} eq '';
2656         if (my $path = $paths->{"/$self->{path}"}) {
2657                 return ($path->{action} eq 'D') ? 0 : 1;
2658         }
2659         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2660         if (grep /$self->{path_regex}/, keys %$paths) {
2661                 return 1;
2662         }
2663         my $c = '';
2664         foreach (split m#/#, $self->{path}) {
2665                 $c .= "/$_";
2666                 next unless ($paths->{$c} &&
2667                              ($paths->{$c}->{action} =~ /^[AR]$/));
2668                 if ($self->ra->check_path($self->{path}, $r) ==
2669                     $SVN::Node::dir) {
2670                         return 1;
2671                 }
2672         }
2673         return 0;
2674 }
2675
2676 sub find_parent_branch {
2677         my ($self, $paths, $rev) = @_;
2678         return undef unless $self->follow_parent;
2679         unless (defined $paths) {
2680                 my $err_handler = $SVN::Error::handler;
2681                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2682                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2683                                    sub { $paths = $_[0] });
2684                 $SVN::Error::handler = $err_handler;
2685         }
2686         return undef unless defined $paths;
2687
2688         # look for a parent from another branch:
2689         my @b_path_components = split m#/#, $self->{path};
2690         my @a_path_components;
2691         my $i;
2692         while (@b_path_components) {
2693                 $i = $paths->{'/'.join('/', @b_path_components)};
2694                 last if $i && defined $i->{copyfrom_path};
2695                 unshift(@a_path_components, pop(@b_path_components));
2696         }
2697         return undef unless defined $i && defined $i->{copyfrom_path};
2698         my $branch_from = $i->{copyfrom_path};
2699         if (@a_path_components) {
2700                 print STDERR "branch_from: $branch_from => ";
2701                 $branch_from .= '/'.join('/', @a_path_components);
2702                 print STDERR $branch_from, "\n";
2703         }
2704         my $r = $i->{copyfrom_rev};
2705         my $repos_root = $self->ra->{repos_root};
2706         my $url = $self->ra->{url};
2707         my $new_url = $url . $branch_from;
2708         print STDERR  "Found possible branch point: ",
2709                       "$new_url => ", $self->full_url, ", $r\n"
2710                       unless $::_q > 1;
2711         $branch_from =~ s#^/##;
2712         my $gs = $self->other_gs($new_url, $url,
2713                                  $branch_from, $r, $self->{ref_id});
2714         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2715         {
2716                 my ($base, $head);
2717                 if (!defined $r0 || !defined $parent) {
2718                         ($base, $head) = parse_revision_argument(0, $r);
2719                 } else {
2720                         if ($r0 < $r) {
2721                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2722                                         0, 1, sub { $base = $_[1] - 1 });
2723                         }
2724                 }
2725                 if (defined $base && $base <= $r) {
2726                         $gs->fetch($base, $r);
2727                 }
2728                 ($r0, $parent) = $gs->find_rev_before($r, 1);
2729         }
2730         if (defined $r0 && defined $parent) {
2731                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
2732                              unless $::_q > 1;
2733                 my $ed;
2734                 if ($self->ra->can_do_switch) {
2735                         $self->assert_index_clean($parent);
2736                         print STDERR "Following parent with do_switch\n"
2737                                      unless $::_q > 1;
2738                         # do_switch works with svn/trunk >= r22312, but that
2739                         # is not included with SVN 1.4.3 (the latest version
2740                         # at the moment), so we can't rely on it
2741                         $self->{last_rev} = $r0;
2742                         $self->{last_commit} = $parent;
2743                         $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2744                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2745                                               $self->full_url, $ed)
2746                           or die "SVN connection failed somewhere...\n";
2747                 } elsif ($self->ra->trees_match($new_url, $r0,
2748                                                 $self->full_url, $rev)) {
2749                         print STDERR "Trees match:\n",
2750                                      "  $new_url\@$r0\n",
2751                                      "  ${\$self->full_url}\@$rev\n",
2752                                      "Following parent with no changes\n"
2753                                      unless $::_q > 1;
2754                         $self->tmp_index_do(sub {
2755                             command_noisy('read-tree', $parent);
2756                         });
2757                         $self->{last_commit} = $parent;
2758                 } else {
2759                         print STDERR "Following parent with do_update\n"
2760                                      unless $::_q > 1;
2761                         $ed = SVN::Git::Fetcher->new($self);
2762                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2763                           or die "SVN connection failed somewhere...\n";
2764                 }
2765                 print STDERR "Successfully followed parent\n" unless $::_q > 1;
2766                 return $self->make_log_entry($rev, [$parent], $ed);
2767         }
2768         return undef;
2769 }
2770
2771 sub do_fetch {
2772         my ($self, $paths, $rev) = @_;
2773         my $ed;
2774         my ($last_rev, @parents);
2775         if (my $lc = $self->last_commit) {
2776                 # we can have a branch that was deleted, then re-added
2777                 # under the same name but copied from another path, in
2778                 # which case we'll have multiple parents (we don't
2779                 # want to break the original ref, nor lose copypath info):
2780                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2781                         push @{$log_entry->{parents}}, $lc;
2782                         return $log_entry;
2783                 }
2784                 $ed = SVN::Git::Fetcher->new($self);
2785                 $last_rev = $self->{last_rev};
2786                 $ed->{c} = $lc;
2787                 @parents = ($lc);
2788         } else {
2789                 $last_rev = $rev;
2790                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2791                         return $log_entry;
2792                 }
2793                 $ed = SVN::Git::Fetcher->new($self);
2794         }
2795         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2796                 die "SVN connection failed somewhere...\n";
2797         }
2798         $self->make_log_entry($rev, \@parents, $ed);
2799 }
2800
2801 sub mkemptydirs {
2802         my ($self, $r) = @_;
2803
2804         sub scan {
2805                 my ($r, $empty_dirs, $line) = @_;
2806                 if (defined $r && $line =~ /^r(\d+)$/) {
2807                         return 0 if $1 > $r;
2808                 } elsif ($line =~ /^  \+empty_dir: (.+)$/) {
2809                         $empty_dirs->{$1} = 1;
2810                 } elsif ($line =~ /^  \-empty_dir: (.+)$/) {
2811                         my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
2812                         delete @$empty_dirs{@d};
2813                 }
2814                 1; # continue
2815         };
2816
2817         my %empty_dirs = ();
2818         my $gz_file = "$self->{dir}/unhandled.log.gz";
2819         if (-f $gz_file) {
2820                 if (!$can_compress) {
2821                         warn "Compress::Zlib could not be found; ",
2822                              "empty directories in $gz_file will not be read\n";
2823                 } else {
2824                         my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
2825                                 die "Unable to open $gz_file: $!\n";
2826                         my $line;
2827                         while ($gz->gzreadline($line) > 0) {
2828                                 scan($r, \%empty_dirs, $line) or last;
2829                         }
2830                         $gz->gzclose;
2831                 }
2832         }
2833
2834         if (open my $fh, '<', "$self->{dir}/unhandled.log") {
2835                 binmode $fh or croak "binmode: $!";
2836                 while (<$fh>) {
2837                         scan($r, \%empty_dirs, $_) or last;
2838                 }
2839                 close $fh;
2840         }
2841
2842         my $strip = qr/\A\Q$self->{path}\E(?:\/|$)/;
2843         foreach my $d (sort keys %empty_dirs) {
2844                 $d = uri_decode($d);
2845                 $d =~ s/$strip//;
2846                 next unless length($d);
2847                 next if -d $d;
2848                 if (-e $d) {
2849                         warn "$d exists but is not a directory\n";
2850                 } else {
2851                         print "creating empty directory: $d\n";
2852                         mkpath([$d]);
2853                 }
2854         }
2855 }
2856
2857 sub get_untracked {
2858         my ($self, $ed) = @_;
2859         my @out;
2860         my $h = $ed->{empty};
2861         foreach (sort keys %$h) {
2862                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2863                 push @out, "  $act: " . uri_encode($_);
2864                 warn "W: $act: $_\n";
2865         }
2866         foreach my $t (qw/dir_prop file_prop/) {
2867                 $h = $ed->{$t} or next;
2868                 foreach my $path (sort keys %$h) {
2869                         my $ppath = $path eq '' ? '.' : $path;
2870                         foreach my $prop (sort keys %{$h->{$path}}) {
2871                                 next if $SKIP_PROP{$prop};
2872                                 my $v = $h->{$path}->{$prop};
2873                                 my $t_ppath_prop = "$t: " .
2874                                                     uri_encode($ppath) . ' ' .
2875                                                     uri_encode($prop);
2876                                 if (defined $v) {
2877                                         push @out, "  +$t_ppath_prop " .
2878                                                    uri_encode($v);
2879                                 } else {
2880                                         push @out, "  -$t_ppath_prop";
2881                                 }
2882                         }
2883                 }
2884         }
2885         foreach my $t (qw/absent_file absent_directory/) {
2886                 $h = $ed->{$t} or next;
2887                 foreach my $parent (sort keys %$h) {
2888                         foreach my $path (sort @{$h->{$parent}}) {
2889                                 push @out, "  $t: " .
2890                                            uri_encode("$parent/$path");
2891                                 warn "W: $t: $parent/$path ",
2892                                      "Insufficient permissions?\n";
2893                         }
2894                 }
2895         }
2896         \@out;
2897 }
2898
2899 # parse_svn_date(DATE)
2900 # --------------------
2901 # Given a date (in UTC) from Subversion, return a string in the format
2902 # "<TZ Offset> <local date/time>" that Git will use.
2903 #
2904 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2905 # is true we'll convert it to the local timezone instead.
2906 sub parse_svn_date {
2907         my $date = shift || return '+0000 1970-01-01 00:00:00';
2908         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2909                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2910                                          croak "Unable to parse date: $date\n";
2911         my $parsed_date;    # Set next.
2912
2913         if ($Git::SVN::_localtime) {
2914                 # Translate the Subversion datetime to an epoch time.
2915                 # Begin by switching ourselves to $date's timezone, UTC.
2916                 my $old_env_TZ = $ENV{TZ};
2917                 $ENV{TZ} = 'UTC';
2918
2919                 my $epoch_in_UTC =
2920                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2921
2922                 # Determine our local timezone (including DST) at the
2923                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
2924                 # value of TZ, if any, at the time we were run.
2925                 if (defined $Git::SVN::Log::TZ) {
2926                         $ENV{TZ} = $Git::SVN::Log::TZ;
2927                 } else {
2928                         delete $ENV{TZ};
2929                 }
2930
2931                 my $our_TZ =
2932                     POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2933
2934                 # This converts $epoch_in_UTC into our local timezone.
2935                 my ($sec, $min, $hour, $mday, $mon, $year,
2936                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2937
2938                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2939                                        $our_TZ, $year + 1900, $mon + 1,
2940                                        $mday, $hour, $min, $sec);
2941
2942                 # Reset us to the timezone in effect when we entered
2943                 # this routine.
2944                 if (defined $old_env_TZ) {
2945                         $ENV{TZ} = $old_env_TZ;
2946                 } else {
2947                         delete $ENV{TZ};
2948                 }
2949         } else {
2950                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2951         }
2952
2953         return $parsed_date;
2954 }
2955
2956 sub other_gs {
2957         my ($self, $new_url, $url,
2958             $branch_from, $r, $old_ref_id) = @_;
2959         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2960         unless ($gs) {
2961                 my $ref_id = $old_ref_id;
2962                 $ref_id =~ s/\@\d+-*$//;
2963                 $ref_id .= "\@$r";
2964                 # just grow a tail if we're not unique enough :x
2965                 $ref_id .= '-' while find_ref($ref_id);
2966                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2967                 if ($u =~ s#^\Q$url\E(/|$)##) {
2968                         $p = $u;
2969                         $u = $url;
2970                         $repo_id = $self->{repo_id};
2971                 }
2972                 while (1) {
2973                         # It is possible to tag two different subdirectories at
2974                         # the same revision.  If the url for an existing ref
2975                         # does not match, we must either find a ref with a
2976                         # matching url or create a new ref by growing a tail.
2977                         $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2978                         my (undef, $max_commit) = $gs->rev_map_max(1);
2979                         last if (!$max_commit);
2980                         my ($url) = ::cmt_metadata($max_commit);
2981                         last if ($url eq $gs->full_url);
2982                         $ref_id .= '-';
2983                 }
2984                 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
2985         }
2986         $gs
2987 }
2988
2989 sub call_authors_prog {
2990         my ($orig_author) = @_;
2991         $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
2992         my $author = `$::_authors_prog $orig_author`;
2993         if ($? != 0) {
2994                 die "$::_authors_prog failed with exit code $?\n"
2995         }
2996         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
2997                 my ($name, $email) = ($1, $2);
2998                 $email = undef if length $2 == 0;
2999                 return [$name, $email];
3000         } else {
3001                 die "Author: $orig_author: $::_authors_prog returned "
3002                         . "invalid author format: $author\n";
3003         }
3004 }
3005
3006 sub check_author {
3007         my ($author) = @_;
3008         if (!defined $author || length $author == 0) {
3009                 $author = '(no author)';
3010         }
3011         if (!defined $::users{$author}) {
3012                 if (defined $::_authors_prog) {
3013                         $::users{$author} = call_authors_prog($author);
3014                 } elsif (defined $::_authors) {
3015                         die "Author: $author not defined in $::_authors file\n";
3016                 }
3017         }
3018         $author;
3019 }
3020
3021 sub find_extra_svk_parents {
3022         my ($self, $ed, $tickets, $parents) = @_;
3023         # aha!  svk:merge property changed...
3024         my @tickets = split "\n", $tickets;
3025         my @known_parents;
3026         for my $ticket ( @tickets ) {
3027                 my ($uuid, $path, $rev) = split /:/, $ticket;
3028                 if ( $uuid eq $self->ra_uuid ) {
3029                         my $url = $self->{url};
3030                         my $repos_root = $url;
3031                         my $branch_from = $path;
3032                         $branch_from =~ s{^/}{};
3033                         my $gs = $self->other_gs($repos_root."/".$branch_from,
3034                                                  $url,
3035                                                  $branch_from,
3036                                                  $rev,
3037                                                  $self->{ref_id});
3038                         if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
3039                                 # wahey!  we found it, but it might be
3040                                 # an old one (!)
3041                                 push @known_parents, [ $rev, $commit ];
3042                         }
3043                 }
3044         }
3045         # Ordering matters; highest-numbered commit merge tickets
3046         # first, as they may account for later merge ticket additions
3047         # or changes.
3048         @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
3049         for my $parent ( @known_parents ) {
3050                 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
3051                 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3052                 my $new;
3053                 while ( <$msg_fh> ) {
3054                         $new=1;last;
3055                 }
3056                 command_close_pipe($msg_fh, $ctx);
3057                 if ( $new ) {
3058                         print STDERR
3059                             "Found merge parent (svk:merge ticket): $parent\n";
3060                         push @$parents, $parent;
3061                 }
3062         }
3063 }
3064
3065 sub lookup_svn_merge {
3066         my $uuid = shift;
3067         my $url = shift;
3068         my $merge = shift;
3069
3070         my ($source, $revs) = split ":", $merge;
3071         my $path = $source;
3072         $path =~ s{^/}{};
3073         my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
3074         if ( !$gs ) {
3075                 warn "Couldn't find revmap for $url$source\n";
3076                 return;
3077         }
3078         my @ranges = split ",", $revs;
3079         my ($tip, $tip_commit);
3080         my @merged_commit_ranges;
3081         # find the tip
3082         for my $range ( @ranges ) {
3083                 my ($bottom, $top) = split "-", $range;
3084                 $top ||= $bottom;
3085                 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
3086                 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
3087
3088                 unless ($top_commit and $bottom_commit) {
3089                         warn "W:unknown path/rev in svn:mergeinfo "
3090                                 ."dirprop: $source:$range\n";
3091                         next;
3092                 }
3093
3094                 push @merged_commit_ranges,
3095                         "$bottom_commit^..$top_commit";
3096
3097                 if ( !defined $tip or $top > $tip ) {
3098                         $tip = $top;
3099                         $tip_commit = $top_commit;
3100                 }
3101         }
3102         return ($tip_commit, @merged_commit_ranges);
3103 }
3104
3105 sub _rev_list {
3106         my ($msg_fh, $ctx) = command_output_pipe(
3107                 "rev-list", @_,
3108                );
3109         my @rv;
3110         while ( <$msg_fh> ) {
3111                 chomp;
3112                 push @rv, $_;
3113         }
3114         command_close_pipe($msg_fh, $ctx);
3115         @rv;
3116 }
3117
3118 sub check_cherry_pick {
3119         my $base = shift;
3120         my $tip = shift;
3121         my @ranges = @_;
3122         my %commits = map { $_ => 1 }
3123                 _rev_list("--no-merges", $tip, "--not", $base);
3124         for my $range ( @ranges ) {
3125                 delete @commits{_rev_list($range)};
3126         }
3127         for my $commit (keys %commits) {
3128                 if (has_no_changes($commit)) {
3129                         delete $commits{$commit};
3130                 }
3131         }
3132         return (keys %commits);
3133 }
3134
3135 sub has_no_changes {
3136         my $commit = shift;
3137
3138         my @revs = split / /, command_oneline(
3139                 qw(rev-list --parents -1 -m), $commit);
3140
3141         # Commits with no parents, e.g. the start of a partial branch,
3142         # have changes by definition.
3143         return 1 if (@revs < 2);
3144
3145         # Commits with multiple parents, e.g a merge, have no changes
3146         # by definition.
3147         return 0 if (@revs > 2);
3148
3149         return (command_oneline("rev-parse", "$commit^{tree}") eq
3150                 command_oneline("rev-parse", "$commit~1^{tree}"));
3151 }
3152
3153 # The GIT_DIR environment variable is not always set until after the command
3154 # line arguments are processed, so we can't memoize in a BEGIN block.
3155 {
3156         my $memoized = 0;
3157
3158         sub memoize_svn_mergeinfo_functions {
3159                 return if $memoized;
3160                 $memoized = 1;
3161
3162                 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
3163                 mkpath([$cache_path]) unless -d $cache_path;
3164
3165                 tie my %lookup_svn_merge_cache => 'Memoize::Storable',
3166                     "$cache_path/lookup_svn_merge.db", 'nstore';
3167                 memoize 'lookup_svn_merge',
3168                         SCALAR_CACHE => 'FAULT',
3169                         LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
3170                 ;
3171
3172                 tie my %check_cherry_pick_cache => 'Memoize::Storable',
3173                     "$cache_path/check_cherry_pick.db", 'nstore';
3174                 memoize 'check_cherry_pick',
3175                         SCALAR_CACHE => 'FAULT',
3176                         LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
3177                 ;
3178
3179                 tie my %has_no_changes_cache => 'Memoize::Storable',
3180                     "$cache_path/has_no_changes.db", 'nstore';
3181                 memoize 'has_no_changes',
3182                         SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
3183                         LIST_CACHE => 'FAULT',
3184                 ;
3185         }
3186
3187         sub unmemoize_svn_mergeinfo_functions {
3188                 return if not $memoized;
3189                 $memoized = 0;
3190
3191                 Memoize::unmemoize 'lookup_svn_merge';
3192                 Memoize::unmemoize 'check_cherry_pick';
3193                 Memoize::unmemoize 'has_no_changes';
3194         }
3195 }
3196
3197 END {
3198         # Force cache writeout explicitly instead of waiting for
3199         # global destruction to avoid segfault in Storable:
3200         # http://rt.cpan.org/Public/Bug/Display.html?id=36087
3201         unmemoize_svn_mergeinfo_functions();
3202 }
3203
3204 sub parents_exclude {
3205         my $parents = shift;
3206         my @commits = @_;
3207         return unless @commits;
3208
3209         my @excluded;
3210         my $excluded;
3211         do {
3212                 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
3213                 $excluded = command_oneline(@cmd);
3214                 if ( $excluded ) {
3215                         my @new;
3216                         my $found;
3217                         for my $commit ( @commits ) {
3218                                 if ( $commit eq $excluded ) {
3219                                         push @excluded, $commit;
3220                                         $found++;
3221                                         last;
3222                                 }
3223                                 else {
3224                                         push @new, $commit;
3225                                 }
3226                         }
3227                         die "saw commit '$excluded' in rev-list output, "
3228                                 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
3229                                         unless $found;
3230                         @commits = @new;
3231                 }
3232         }
3233                 while ($excluded and @commits);
3234
3235         return @excluded;
3236 }
3237
3238
3239 # note: this function should only be called if the various dirprops
3240 # have actually changed
3241 sub find_extra_svn_parents {
3242         my ($self, $ed, $mergeinfo, $parents) = @_;
3243         # aha!  svk:merge property changed...
3244
3245         memoize_svn_mergeinfo_functions();
3246
3247         # We first search for merged tips which are not in our
3248         # history.  Then, we figure out which git revisions are in
3249         # that tip, but not this revision.  If all of those revisions
3250         # are now marked as merge, we can add the tip as a parent.
3251         my @merges = split "\n", $mergeinfo;
3252         my @merge_tips;
3253         my $url = $self->{url};
3254         my $uuid = $self->ra_uuid;
3255         my %ranges;
3256         for my $merge ( @merges ) {
3257                 my ($tip_commit, @ranges) =
3258                         lookup_svn_merge( $uuid, $url, $merge );
3259                 unless (!$tip_commit or
3260                                 grep { $_ eq $tip_commit } @$parents ) {
3261                         push @merge_tips, $tip_commit;
3262                         $ranges{$tip_commit} = \@ranges;
3263                 } else {
3264                         push @merge_tips, undef;
3265                 }
3266         }
3267
3268         my %excluded = map { $_ => 1 }
3269                 parents_exclude($parents, grep { defined } @merge_tips);
3270
3271         # check merge tips for new parents
3272         my @new_parents;
3273         for my $merge_tip ( @merge_tips ) {
3274                 my $spec = shift @merges;
3275                 next unless $merge_tip and $excluded{$merge_tip};
3276
3277                 my $ranges = $ranges{$merge_tip};
3278
3279                 # check out 'new' tips
3280                 my $merge_base;
3281                 eval {
3282                         $merge_base = command_oneline(
3283                                 "merge-base",
3284                                 @$parents, $merge_tip,
3285                         );
3286                 };
3287                 if ($@) {
3288                         die "An error occurred during merge-base"
3289                                 unless $@->isa("Git::Error::Command");
3290
3291                         warn "W: Cannot find common ancestor between ".
3292                              "@$parents and $merge_tip. Ignoring merge info.\n";
3293                         next;
3294                 }
3295
3296                 # double check that there are no missing non-merge commits
3297                 my (@incomplete) = check_cherry_pick(
3298                         $merge_base, $merge_tip,
3299                         @$ranges,
3300                        );
3301
3302                 if ( @incomplete ) {
3303                         warn "W:svn cherry-pick ignored ($spec) - missing "
3304                                 .@incomplete." commit(s) (eg $incomplete[0])\n";
3305                 } else {
3306                         warn
3307                                 "Found merge parent (svn:mergeinfo prop): ",
3308                                         $merge_tip, "\n";
3309                         push @new_parents, $merge_tip;
3310                 }
3311         }
3312
3313         # cater for merges which merge commits from multiple branches
3314         if ( @new_parents > 1 ) {
3315                 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
3316                         for ( my $j = 0; $j <= $#new_parents; $j++ ) {
3317                                 next if $i == $j;
3318                                 next unless $new_parents[$i];
3319                                 next unless $new_parents[$j];
3320                                 my $revs = command_oneline(
3321                                         "rev-list", "-1",
3322                                         "$new_parents[$i]..$new_parents[$j]",
3323                                        );
3324                                 if ( !$revs ) {
3325                                         undef($new_parents[$j]);
3326                                 }
3327                         }
3328                 }
3329         }
3330         push @$parents, grep { defined } @new_parents;
3331 }
3332
3333 sub make_log_entry {
3334         my ($self, $rev, $parents, $ed) = @_;
3335         my $untracked = $self->get_untracked($ed);
3336
3337         my @parents = @$parents;
3338         my $ps = $ed->{path_strip} || "";
3339         for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
3340                 my $props = $ed->{dir_prop}{$path};
3341                 if ( $props->{"svk:merge"} ) {
3342                         $self->find_extra_svk_parents
3343                                 ($ed, $props->{"svk:merge"}, \@parents);
3344                 }
3345                 if ( $props->{"svn:mergeinfo"} ) {
3346                         $self->find_extra_svn_parents
3347                                 ($ed,
3348                                  $props->{"svn:mergeinfo"},
3349                                  \@parents);
3350                 }
3351         }
3352
3353         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
3354         print $un "r$rev\n" or croak $!;
3355         print $un $_, "\n" foreach @$untracked;
3356         my %log_entry = ( parents => \@parents, revision => $rev,
3357                           log => '');
3358
3359         my $headrev;
3360         my $logged = delete $self->{logged_rev_props};
3361         if (!$logged || $self->{-want_revprops}) {
3362                 my $rp = $self->ra->rev_proplist($rev);
3363                 foreach (sort keys %$rp) {
3364                         my $v = $rp->{$_};
3365                         if (/^svn:(author|date|log)$/) {
3366                                 $log_entry{$1} = $v;
3367                         } elsif ($_ eq 'svm:headrev') {
3368                                 $headrev = $v;
3369                         } else {
3370                                 print $un "  rev_prop: ", uri_encode($_), ' ',
3371                                           uri_encode($v), "\n";
3372                         }
3373                 }
3374         } else {
3375                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
3376         }
3377         close $un or croak $!;
3378
3379         $log_entry{date} = parse_svn_date($log_entry{date});
3380         $log_entry{log} .= "\n";
3381         my $author = $log_entry{author} = check_author($log_entry{author});
3382         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
3383                                                        : ($author, undef);
3384
3385         my ($commit_name, $commit_email) = ($name, $email);
3386         if ($_use_log_author) {
3387                 my $name_field;
3388                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
3389                         $name_field = $1;
3390                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
3391                         $name_field = $1;
3392                 }
3393                 if (!defined $name_field) {
3394                         if (!defined $email) {
3395                                 $email = $name;
3396                         }
3397                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
3398                         ($name, $email) = ($1, $2);
3399                 } elsif ($name_field =~ /(.*)@/) {
3400                         ($name, $email) = ($1, $name_field);
3401                 } else {
3402                         ($name, $email) = ($name_field, $name_field);
3403                 }
3404         }
3405         if (defined $headrev && $self->use_svm_props) {
3406                 if ($self->rewrite_root) {
3407                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
3408                             "options set!\n";
3409                 }
3410                 if ($self->rewrite_uuid) {
3411                         die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
3412                             "options set!\n";
3413                 }
3414                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
3415                 # we don't want "SVM: initializing mirror for junk" ...
3416                 return undef if $r == 0;
3417                 my $svm = $self->svm;
3418                 if ($uuid ne $svm->{uuid}) {
3419                         die "UUID mismatch on SVM path:\n",
3420                             "expected: $svm->{uuid}\n",
3421                             "     got: $uuid\n";
3422                 }
3423                 my $full_url = $self->full_url;
3424                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
3425                              die "Failed to replace '$svm->{replace}' with ",
3426                                  "'$svm->{source}' in $full_url\n";
3427                 # throw away username for storing in records
3428                 remove_username($full_url);
3429                 $log_entry{metadata} = "$full_url\@$r $uuid";
3430                 $log_entry{svm_revision} = $r;
3431                 $email ||= "$author\@$uuid";
3432                 $commit_email ||= "$author\@$uuid";
3433         } elsif ($self->use_svnsync_props) {
3434                 my $full_url = $self->svnsync->{url};
3435                 $full_url .= "/$self->{path}" if length $self->{path};
3436                 remove_username($full_url);
3437                 my $uuid = $self->svnsync->{uuid};
3438                 $log_entry{metadata} = "$full_url\@$rev $uuid";
3439                 $email ||= "$author\@$uuid";
3440                 $commit_email ||= "$author\@$uuid";
3441         } else {
3442                 my $url = $self->metadata_url;
3443                 remove_username($url);
3444                 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
3445                 $log_entry{metadata} = "$url\@$rev " . $uuid;
3446                 $email ||= "$author\@" . $uuid;
3447                 $commit_email ||= "$author\@" . $uuid;
3448         }
3449         $log_entry{name} = $name;
3450         $log_entry{email} = $email;
3451         $log_entry{commit_name} = $commit_name;
3452         $log_entry{commit_email} = $commit_email;
3453         \%log_entry;
3454 }
3455
3456 sub fetch {
3457         my ($self, $min_rev, $max_rev, @parents) = @_;
3458         my ($last_rev, $last_commit) = $self->last_rev_commit;
3459         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
3460         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
3461 }
3462
3463 sub set_tree_cb {
3464         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
3465         $self->{inject_parents} = { $rev => $tree };
3466         $self->fetch(undef, undef);
3467 }
3468
3469 sub set_tree {
3470         my ($self, $tree) = (shift, shift);
3471         my $log_entry = ::get_commit_entry($tree);
3472         unless ($self->{last_rev}) {
3473                 ::fatal("Must have an existing revision to commit");
3474         }
3475         my %ed_opts = ( r => $self->{last_rev},
3476                         log => $log_entry->{log},
3477                         ra => $self->ra,
3478                         tree_a => $self->{last_commit},
3479                         tree_b => $tree,
3480                         editor_cb => sub {
3481                                $self->set_tree_cb($log_entry, $tree, @_) },
3482                         svn_path => $self->{path} );
3483         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
3484                 print "No changes\nr$self->{last_rev} = $tree\n";
3485         }
3486 }
3487
3488 sub rebuild_from_rev_db {
3489         my ($self, $path) = @_;
3490         my $r = -1;
3491         open my $fh, '<', $path or croak "open: $!";
3492         binmode $fh or croak "binmode: $!";
3493         while (<$fh>) {
3494                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3495                 chomp($_);
3496                 ++$r;
3497                 next if $_ eq ('0' x 40);
3498                 $self->rev_map_set($r, $_);
3499                 print "r$r = $_\n";
3500         }
3501         close $fh or croak "close: $!";
3502         unlink $path or croak "unlink: $!";
3503 }
3504
3505 sub rebuild {
3506         my ($self) = @_;
3507         my $map_path = $self->map_path;
3508         my $partial = (-e $map_path && ! -z $map_path);
3509         return unless ::verify_ref($self->refname.'^0');
3510         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3511                 my $rev_db = $self->rev_db_path;
3512                 $self->rebuild_from_rev_db($rev_db);
3513                 if ($self->use_svm_props) {
3514                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3515                         $self->rebuild_from_rev_db($svm_rev_db);
3516                 }
3517                 $self->unlink_rev_db_symlink;
3518                 return;
3519         }
3520         print "Rebuilding $map_path ...\n" if (!$partial);
3521         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3522                 (undef, undef));
3523         my ($log, $ctx) =
3524             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3525                                 ($head ? "$head.." : "") . $self->refname,
3526                                 '--');
3527         my $metadata_url = $self->metadata_url;
3528         remove_username($metadata_url);
3529         my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
3530         my $c;
3531         while (<$log>) {
3532                 if ( m{^commit ($::sha1)$} ) {
3533                         $c = $1;
3534                         next;
3535                 }
3536                 next unless s{^\s*(git-svn-id:)}{$1};
3537                 my ($url, $rev, $uuid) = ::extract_metadata($_);
3538                 remove_username($url);
3539
3540                 # ignore merges (from set-tree)
3541                 next if (!defined $rev || !$uuid);
3542
3543                 # if we merged or otherwise started elsewhere, this is
3544                 # how we break out of it
3545                 if (($uuid ne $svn_uuid) ||
3546                     ($metadata_url && $url && ($url ne $metadata_url))) {
3547                         next;
3548                 }
3549                 if ($partial && $head) {
3550                         print "Partial-rebuilding $map_path ...\n";
3551                         print "Currently at $base_rev = $head\n";
3552                         $head = undef;
3553                 }
3554
3555                 $self->rev_map_set($rev, $c);
3556                 print "r$rev = $c\n";
3557         }
3558         command_close_pipe($log, $ctx);
3559         print "Done rebuilding $map_path\n" if (!$partial || !$head);
3560         my $rev_db_path = $self->rev_db_path;
3561         if (-f $self->rev_db_path) {
3562                 unlink $self->rev_db_path or croak "unlink: $!";
3563         }
3564         $self->unlink_rev_db_symlink;
3565 }
3566
3567 # rev_map:
3568 # Tie::File seems to be prone to offset errors if revisions get sparse,
3569 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
3570 # one of my favorite modules is out :<  Next up would be one of the DBM
3571 # modules, but I'm not sure which is most portable...
3572 #
3573 # This is the replacement for the rev_db format, which was too big
3574 # and inefficient for large repositories with a lot of sparse history
3575 # (mainly tags)
3576 #
3577 # The format is this:
3578 #   - 24 bytes for every record,
3579 #     * 4 bytes for the integer representing an SVN revision number
3580 #     * 20 bytes representing the sha1 of a git commit
3581 #   - No empty padding records like the old format
3582 #     (except the last record, which can be overwritten)
3583 #   - new records are written append-only since SVN revision numbers
3584 #     increase monotonically
3585 #   - lookups on SVN revision number are done via a binary search
3586 #   - Piping the file to xxd -c24 is a good way of dumping it for
3587 #     viewing or editing (piped back through xxd -r), should the need
3588 #     ever arise.
3589 #   - The last record can be padding revision with an all-zero sha1
3590 #     This is used to optimize fetch performance when using multiple
3591 #     "fetch" directives in .git/config
3592 #
3593 # These files are disposable unless noMetadata or useSvmProps is set
3594
3595 sub _rev_map_set {
3596         my ($fh, $rev, $commit) = @_;
3597
3598         binmode $fh or croak "binmode: $!";
3599         my $size = (stat($fh))[7];
3600         ($size % 24) == 0 or croak "inconsistent size: $size";
3601
3602         my $wr_offset = 0;
3603         if ($size > 0) {
3604                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3605                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3606                 $read == 24 or croak "read only $read bytes (!= 24)";
3607                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3608                 if ($last_commit eq ('0' x40)) {
3609                         if ($size >= 48) {
3610                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3611                                 $read = sysread($fh, $buf, 24) or
3612                                     croak "read: $!";
3613                                 $read == 24 or
3614                                     croak "read only $read bytes (!= 24)";
3615                                 ($last_rev, $last_commit) =
3616                                     unpack(rev_map_fmt, $buf);
3617                                 if ($last_commit eq ('0' x40)) {
3618                                         croak "inconsistent .rev_map\n";
3619                                 }
3620                         }
3621                         if ($last_rev >= $rev) {
3622                                 croak "last_rev is higher!: $last_rev >= $rev";
3623                         }
3624                         $wr_offset = -24;
3625                 }
3626         }
3627         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3628         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3629           croak "write: $!";
3630 }
3631
3632 sub _rev_map_reset {
3633         my ($fh, $rev, $commit) = @_;
3634         my $c = _rev_map_get($fh, $rev);
3635         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3636         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3637         truncate $fh, $offset or croak "truncate: $!";
3638 }
3639
3640 sub mkfile {
3641         my ($path) = @_;
3642         unless (-e $path) {
3643                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3644                 mkpath([$dir]) unless -d $dir;
3645                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3646                 close $fh or die "Couldn't close (create) $path: $!\n";
3647         }
3648 }
3649
3650 sub rev_map_set {
3651         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3652         defined $commit or die "missing arg3\n";
3653         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3654         my $db = $self->map_path($uuid);
3655         my $db_lock = "$db.lock";
3656         my $sig;
3657         $update_ref ||= 0;
3658         if ($update_ref) {
3659                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3660                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3661         }
3662         mkfile($db);
3663
3664         $LOCKFILES{$db_lock} = 1;
3665         my $sync;
3666         # both of these options make our .rev_db file very, very important
3667         # and we can't afford to lose it because rebuild() won't work
3668         if ($self->use_svm_props || $self->no_metadata) {
3669                 $sync = 1;
3670                 copy($db, $db_lock) or die "rev_map_set(@_): ",
3671                                            "Failed to copy: ",
3672                                            "$db => $db_lock ($!)\n";
3673         } else {
3674                 rename $db, $db_lock or die "rev_map_set(@_): ",
3675                                             "Failed to rename: ",
3676                                             "$db => $db_lock ($!)\n";
3677         }
3678
3679         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3680              or croak "Couldn't open $db_lock: $!\n";
3681         $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3682                                  _rev_map_set($fh, $rev, $commit);
3683         if ($sync) {
3684                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3685                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3686         }
3687         close $fh or croak $!;
3688         if ($update_ref) {
3689                 $_head = $self;
3690                 my $note = "";
3691                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3692                 command_noisy('update-ref', '-m', "r$rev$note",
3693                               $self->refname, $commit);
3694         }
3695         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3696                                     "$db_lock => $db ($!)\n";
3697         delete $LOCKFILES{$db_lock};
3698         if ($update_ref) {
3699                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3700                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3701                 kill $sig, $$ if defined $sig;
3702         }
3703 }
3704
3705 # If want_commit, this will return an array of (rev, commit) where
3706 # commit _must_ be a valid commit in the archive.
3707 # Otherwise, it'll return the max revision (whether or not the
3708 # commit is valid or just a 0x40 placeholder).
3709 sub rev_map_max {
3710         my ($self, $want_commit) = @_;
3711         $self->rebuild;
3712         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3713         $want_commit ? ($r, $c) : $r;
3714 }
3715
3716 sub rev_map_max_norebuild {
3717         my ($self, $want_commit) = @_;
3718         my $map_path = $self->map_path;
3719         stat $map_path or return $want_commit ? (0, undef) : 0;
3720         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3721         binmode $fh or croak "binmode: $!";
3722         my $size = (stat($fh))[7];
3723         ($size % 24) == 0 or croak "inconsistent size: $size";
3724
3725         if ($size == 0) {
3726                 close $fh or croak "close: $!";
3727                 return $want_commit ? (0, undef) : 0;
3728         }
3729
3730         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3731         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3732         my ($r, $c) = unpack(rev_map_fmt, $buf);
3733         if ($want_commit && $c eq ('0' x40)) {
3734                 if ($size < 48) {
3735                         return $want_commit ? (0, undef) : 0;
3736                 }
3737                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3738                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3739                 ($r, $c) = unpack(rev_map_fmt, $buf);
3740                 if ($c eq ('0'x40)) {
3741                         croak "Penultimate record is all-zeroes in $map_path";
3742                 }
3743         }
3744         close $fh or croak "close: $!";
3745         $want_commit ? ($r, $c) : $r;
3746 }
3747
3748 sub rev_map_get {
3749         my ($self, $rev, $uuid) = @_;
3750         my $map_path = $self->map_path($uuid);
3751         return undef unless -e $map_path;
3752
3753         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3754         my $c = _rev_map_get($fh, $rev);
3755         close($fh) or croak "close: $!";
3756         $c
3757 }
3758
3759 sub _rev_map_get {
3760         my ($fh, $rev) = @_;
3761
3762         binmode $fh or croak "binmode: $!";
3763         my $size = (stat($fh))[7];
3764         ($size % 24) == 0 or croak "inconsistent size: $size";
3765
3766         if ($size == 0) {
3767                 return undef;
3768         }
3769
3770         my ($l, $u) = (0, $size - 24);
3771         my ($r, $c, $buf);
3772
3773         while ($l <= $u) {
3774                 my $i = int(($l/24 + $u/24) / 2) * 24;
3775                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3776                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3777                 my ($r, $c) = unpack(rev_map_fmt, $buf);
3778
3779                 if ($r < $rev) {
3780                         $l = $i + 24;
3781                 } elsif ($r > $rev) {
3782                         $u = $i - 24;
3783                 } else { # $r == $rev
3784                         return $c eq ('0' x 40) ? undef : $c;
3785                 }
3786         }
3787         undef;
3788 }
3789
3790 # Finds the first svn revision that exists on (if $eq_ok is true) or
3791 # before $rev for the current branch.  It will not search any lower
3792 # than $min_rev.  Returns the git commit hash and svn revision number
3793 # if found, else (undef, undef).
3794 sub find_rev_before {
3795         my ($self, $rev, $eq_ok, $min_rev) = @_;
3796         --$rev unless $eq_ok;
3797         $min_rev ||= 1;
3798         my $max_rev = $self->rev_map_max;
3799         $rev = $max_rev if ($rev > $max_rev);
3800         while ($rev >= $min_rev) {
3801                 if (my $c = $self->rev_map_get($rev)) {
3802                         return ($rev, $c);
3803                 }
3804                 --$rev;
3805         }
3806         return (undef, undef);
3807 }
3808
3809 # Finds the first svn revision that exists on (if $eq_ok is true) or
3810 # after $rev for the current branch.  It will not search any higher
3811 # than $max_rev.  Returns the git commit hash and svn revision number
3812 # if found, else (undef, undef).
3813 sub find_rev_after {
3814         my ($self, $rev, $eq_ok, $max_rev) = @_;
3815         ++$rev unless $eq_ok;
3816         $max_rev ||= $self->rev_map_max;
3817         while ($rev <= $max_rev) {
3818                 if (my $c = $self->rev_map_get($rev)) {
3819                         return ($rev, $c);
3820                 }
3821                 ++$rev;
3822         }
3823         return (undef, undef);
3824 }
3825
3826 sub _new {
3827         my ($class, $repo_id, $ref_id, $path) = @_;
3828         unless (defined $repo_id && length $repo_id) {
3829                 $repo_id = $Git::SVN::default_repo_id;
3830         }
3831         unless (defined $ref_id && length $ref_id) {
3832                 $_prefix = '' unless defined($_prefix);
3833                 $_[2] = $ref_id =
3834                              "refs/remotes/$_prefix$Git::SVN::default_ref_id";
3835         }
3836         $_[1] = $repo_id;
3837         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3838
3839         # Older repos imported by us used $GIT_DIR/svn/foo instead of
3840         # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
3841         if ($ref_id =~ m{^refs/remotes/(.*)}) {
3842                 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
3843                 if (-d $old_dir && ! -d $dir) {
3844                         $dir = $old_dir;
3845                 }
3846         }
3847
3848         $_[3] = $path = '' unless (defined $path);
3849         mkpath([$dir]);
3850         bless {
3851                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3852                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3853                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3854 }
3855
3856 # for read-only access of old .rev_db formats
3857 sub unlink_rev_db_symlink {
3858         my ($self) = @_;
3859         my $link = $self->rev_db_path;
3860         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3861         if (-l $link) {
3862                 unlink $link or croak "unlink: $link failed!";
3863         }
3864 }
3865
3866 sub rev_db_path {
3867         my ($self, $uuid) = @_;
3868         my $db_path = $self->map_path($uuid);
3869         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3870             or croak "map_path: $db_path does not contain '/.rev_map.' !";
3871         $db_path;
3872 }
3873
3874 # the new replacement for .rev_db
3875 sub map_path {
3876         my ($self, $uuid) = @_;
3877         $uuid ||= $self->ra_uuid;
3878         "$self->{map_root}.$uuid";
3879 }
3880
3881 sub uri_encode {
3882         my ($f) = @_;
3883         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3884         $f
3885 }
3886
3887 sub uri_decode {
3888         my ($f) = @_;
3889         $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
3890         $f
3891 }
3892
3893 sub remove_username {
3894         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3895 }
3896
3897 package Git::SVN::Prompt;
3898 use strict;
3899 use warnings;
3900 require SVN::Core;
3901 use vars qw/$_no_auth_cache $_username/;
3902
3903 sub simple {
3904         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3905         $may_save = undef if $_no_auth_cache;
3906         $default_username = $_username if defined $_username;
3907         if (defined $default_username && length $default_username) {
3908                 if (defined $realm && length $realm) {
3909                         print STDERR "Authentication realm: $realm\n";
3910                         STDERR->flush;
3911                 }
3912                 $cred->username($default_username);
3913         } else {
3914                 username($cred, $realm, $may_save, $pool);
3915         }
3916         $cred->password(_read_password("Password for '" .
3917                                        $cred->username . "': ", $realm));
3918         $cred->may_save($may_save);
3919         $SVN::_Core::SVN_NO_ERROR;
3920 }
3921
3922 sub ssl_server_trust {
3923         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3924         $may_save = undef if $_no_auth_cache;
3925         print STDERR "Error validating server certificate for '$realm':\n";
3926         {
3927                 no warnings 'once';
3928                 # All variables SVN::Auth::SSL::* are used only once,
3929                 # so we're shutting up Perl warnings about this.
3930                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3931                         print STDERR " - The certificate is not issued ",
3932                             "by a trusted authority. Use the\n",
3933                             "   fingerprint to validate ",
3934                             "the certificate manually!\n";
3935                 }
3936                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3937                         print STDERR " - The certificate hostname ",
3938                             "does not match.\n";
3939                 }
3940                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3941                         print STDERR " - The certificate is not yet valid.\n";
3942                 }
3943                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3944                         print STDERR " - The certificate has expired.\n";
3945                 }
3946                 if ($failures & $SVN::Auth::SSL::OTHER) {
3947                         print STDERR " - The certificate has ",
3948                             "an unknown error.\n";
3949                 }
3950         } # no warnings 'once'
3951         printf STDERR
3952                 "Certificate information:\n".
3953                 " - Hostname: %s\n".
3954                 " - Valid: from %s until %s\n".
3955                 " - Issuer: %s\n".
3956                 " - Fingerprint: %s\n",
3957                 map $cert_info->$_, qw(hostname valid_from valid_until
3958                                        issuer_dname fingerprint);
3959         my $choice;
3960 prompt:
3961         print STDERR $may_save ?
3962               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3963               "(R)eject or accept (t)emporarily? ";
3964         STDERR->flush;
3965         $choice = lc(substr(<STDIN> || 'R', 0, 1));
3966         if ($choice =~ /^t$/i) {
3967                 $cred->may_save(undef);
3968         } elsif ($choice =~ /^r$/i) {
3969                 return -1;
3970         } elsif ($may_save && $choice =~ /^p$/i) {
3971                 $cred->may_save($may_save);
3972         } else {
3973                 goto prompt;
3974         }
3975         $cred->accepted_failures($failures);
3976         $SVN::_Core::SVN_NO_ERROR;
3977 }
3978
3979 sub ssl_client_cert {
3980         my ($cred, $realm, $may_save, $pool) = @_;
3981         $may_save = undef if $_no_auth_cache;
3982         print STDERR "Client certificate filename: ";
3983         STDERR->flush;
3984         chomp(my $filename = <STDIN>);
3985         $cred->cert_file($filename);
3986         $cred->may_save($may_save);
3987         $SVN::_Core::SVN_NO_ERROR;
3988 }
3989
3990 sub ssl_client_cert_pw {
3991         my ($cred, $realm, $may_save, $pool) = @_;
3992         $may_save = undef if $_no_auth_cache;
3993         $cred->password(_read_password("Password: ", $realm));
3994         $cred->may_save($may_save);
3995         $SVN::_Core::SVN_NO_ERROR;
3996 }
3997
3998 sub username {
3999         my ($cred, $realm, $may_save, $pool) = @_;
4000         $may_save = undef if $_no_auth_cache;
4001         if (defined $realm && length $realm) {
4002                 print STDERR "Authentication realm: $realm\n";
4003         }
4004         my $username;
4005         if (defined $_username) {
4006                 $username = $_username;
4007         } else {
4008                 print STDERR "Username: ";
4009                 STDERR->flush;
4010                 chomp($username = <STDIN>);
4011         }
4012         $cred->username($username);
4013         $cred->may_save($may_save);
4014         $SVN::_Core::SVN_NO_ERROR;
4015 }
4016
4017 sub _read_password {
4018         my ($prompt, $realm) = @_;
4019         my $password = '';
4020         if (exists $ENV{GIT_ASKPASS}) {
4021                 open(PH, "-|", $ENV{GIT_ASKPASS}, $prompt);
4022                 $password = <PH>;
4023                 $password =~ s/[\012\015]//; # \n\r
4024                 close(PH);
4025         } else {
4026                 print STDERR $prompt;
4027                 STDERR->flush;
4028                 require Term::ReadKey;
4029                 Term::ReadKey::ReadMode('noecho');
4030                 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
4031                         last if $key =~ /[\012\015]/; # \n\r
4032                         $password .= $key;
4033                 }
4034                 Term::ReadKey::ReadMode('restore');
4035                 print STDERR "\n";
4036                 STDERR->flush;
4037         }
4038         $password;
4039 }
4040
4041 package SVN::Git::Fetcher;
4042 use vars qw/@ISA/;
4043 use strict;
4044 use warnings;
4045 use Carp qw/croak/;
4046 use IO::File qw//;
4047 use vars qw/$_ignore_regex/;
4048
4049 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
4050 sub new {
4051         my ($class, $git_svn, $switch_path) = @_;
4052         my $self = SVN::Delta::Editor->new;
4053         bless $self, $class;
4054         if (exists $git_svn->{last_commit}) {
4055                 $self->{c} = $git_svn->{last_commit};
4056                 $self->{empty_symlinks} =
4057                                   _mark_empty_symlinks($git_svn, $switch_path);
4058         }
4059         $self->{ignore_regex} = eval { command_oneline('config', '--get',
4060                              "svn-remote.$git_svn->{repo_id}.ignore-paths") };
4061         $self->{empty} = {};
4062         $self->{dir_prop} = {};
4063         $self->{file_prop} = {};
4064         $self->{absent_dir} = {};
4065         $self->{absent_file} = {};
4066         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
4067         $self->{pathnameencoding} = Git::config('svn.pathnameencoding');
4068         $self;
4069 }
4070
4071 # this uses the Ra object, so it must be called before do_{switch,update},
4072 # not inside them (when the Git::SVN::Fetcher object is passed) to
4073 # do_{switch,update}
4074 sub _mark_empty_symlinks {
4075         my ($git_svn, $switch_path) = @_;
4076         my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
4077         return {} if (!defined($bool)) || (defined($bool) && ! $bool);
4078
4079         my %ret;
4080         my ($rev, $cmt) = $git_svn->last_rev_commit;
4081         return {} unless ($rev && $cmt);
4082
4083         # allow the warning to be printed for each revision we fetch to
4084         # ensure the user sees it.  The user can also disable the workaround
4085         # on the repository even while git svn is running and the next
4086         # revision fetched will skip this expensive function.
4087         my $printed_warning;
4088         chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
4089         my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
4090         local $/ = "\0";
4091         my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
4092         $pfx .= '/' if length($pfx);
4093         while (<$ls>) {
4094                 chomp;
4095                 s/\A100644 blob $empty_blob\t//o or next;
4096                 unless ($printed_warning) {
4097                         print STDERR "Scanning for empty symlinks, ",
4098                                      "this may take a while if you have ",
4099                                      "many empty files\n",
4100                                      "You may disable this with `",
4101                                      "git config svn.brokenSymlinkWorkaround ",
4102                                      "false'.\n",
4103                                      "This may be done in a different ",
4104                                      "terminal without restarting ",
4105                                      "git svn\n";
4106                         $printed_warning = 1;
4107                 }
4108                 my $path = $_;
4109                 my (undef, $props) =
4110                                $git_svn->ra->get_file($pfx.$path, $rev, undef);
4111                 if ($props->{'svn:special'}) {
4112                         $ret{$path} = 1;
4113                 }
4114         }
4115         command_close_pipe($ls, $ctx);
4116         \%ret;
4117 }
4118
4119 # returns true if a given path is inside a ".git" directory
4120 sub in_dot_git {
4121         $_[0] =~ m{(?:^|/)\.git(?:/|$)};
4122 }
4123
4124 # return value: 0 -- don't ignore, 1 -- ignore
4125 sub is_path_ignored {
4126         my ($self, $path) = @_;
4127         return 1 if in_dot_git($path);
4128         return 1 if defined($self->{ignore_regex}) &&
4129                     $path =~ m!$self->{ignore_regex}!;
4130         return 0 unless defined($_ignore_regex);
4131         return 1 if $path =~ m!$_ignore_regex!o;
4132         return 0;
4133 }
4134
4135 sub set_path_strip {
4136         my ($self, $path) = @_;
4137         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
4138 }
4139
4140 sub open_root {
4141         { path => '' };
4142 }
4143
4144 sub open_directory {
4145         my ($self, $path, $pb, $rev) = @_;
4146         { path => $path };
4147 }
4148
4149 sub git_path {
4150         my ($self, $path) = @_;
4151         if (my $enc = $self->{pathnameencoding}) {
4152                 require Encode;
4153                 Encode::from_to($path, 'UTF-8', $enc);
4154         }
4155         if ($self->{path_strip}) {
4156                 $path =~ s!$self->{path_strip}!! or
4157                   die "Failed to strip path '$path' ($self->{path_strip})\n";
4158         }
4159         $path;
4160 }
4161
4162 sub delete_entry {
4163         my ($self, $path, $rev, $pb) = @_;
4164         return undef if $self->is_path_ignored($path);
4165
4166         my $gpath = $self->git_path($path);
4167         return undef if ($gpath eq '');
4168
4169         # remove entire directories.
4170         my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4171                          =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
4172         if ($tree) {
4173                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4174                                                      -r --name-only -z/,
4175                                                      $tree);
4176                 local $/ = "\0";
4177                 while (<$ls>) {
4178                         chomp;
4179                         my $rmpath = "$gpath/$_";
4180                         $self->{gii}->remove($rmpath);
4181                         print "\tD\t$rmpath\n" unless $::_q;
4182                 }
4183                 print "\tD\t$gpath/\n" unless $::_q;
4184                 command_close_pipe($ls, $ctx);
4185         } else {
4186                 $self->{gii}->remove($gpath);
4187                 print "\tD\t$gpath\n" unless $::_q;
4188         }
4189         $self->{empty}->{$path} = 0;
4190         undef;
4191 }
4192
4193 sub open_file {
4194         my ($self, $path, $pb, $rev) = @_;
4195         my ($mode, $blob);
4196
4197         goto out if $self->is_path_ignored($path);
4198
4199         my $gpath = $self->git_path($path);
4200         ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4201                              =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
4202         unless (defined $mode && defined $blob) {
4203                 die "$path was not found in commit $self->{c} (r$rev)\n";
4204         }
4205         if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
4206                 $mode = '120000';
4207         }
4208 out:
4209         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
4210           pool => SVN::Pool->new, action => 'M' };
4211 }
4212
4213 sub add_file {
4214         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
4215         my $mode;
4216
4217         if (!$self->is_path_ignored($path)) {
4218                 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4219                 delete $self->{empty}->{$dir};
4220                 $mode = '100644';
4221         }
4222         { path => $path, mode_a => $mode, mode_b => $mode,
4223           pool => SVN::Pool->new, action => 'A' };
4224 }
4225
4226 sub add_directory {
4227         my ($self, $path, $cp_path, $cp_rev) = @_;
4228         goto out if $self->is_path_ignored($path);
4229         my $gpath = $self->git_path($path);
4230         if ($gpath eq '') {
4231                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4232                                                      -r --name-only -z/,
4233                                                      $self->{c});
4234                 local $/ = "\0";
4235                 while (<$ls>) {
4236                         chomp;
4237                         $self->{gii}->remove($_);
4238                         print "\tD\t$_\n" unless $::_q;
4239                 }
4240                 command_close_pipe($ls, $ctx);
4241                 $self->{empty}->{$path} = 0;
4242         }
4243         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4244         delete $self->{empty}->{$dir};
4245         $self->{empty}->{$path} = 1;
4246 out:
4247         { path => $path };
4248 }
4249
4250 sub change_dir_prop {
4251         my ($self, $db, $prop, $value) = @_;
4252         return undef if $self->is_path_ignored($db->{path});
4253         $self->{dir_prop}->{$db->{path}} ||= {};
4254         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
4255         undef;
4256 }
4257
4258 sub absent_directory {
4259         my ($self, $path, $pb) = @_;
4260         return undef if $self->is_path_ignored($path);
4261         $self->{absent_dir}->{$pb->{path}} ||= [];
4262         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
4263         undef;
4264 }
4265
4266 sub absent_file {
4267         my ($self, $path, $pb) = @_;
4268         return undef if $self->is_path_ignored($path);
4269         $self->{absent_file}->{$pb->{path}} ||= [];
4270         push @{$self->{absent_file}->{$pb->{path}}}, $path;
4271         undef;
4272 }
4273
4274 sub change_file_prop {
4275         my ($self, $fb, $prop, $value) = @_;
4276         return undef if $self->is_path_ignored($fb->{path});
4277         if ($prop eq 'svn:executable') {
4278                 if ($fb->{mode_b} != 120000) {
4279                         $fb->{mode_b} = defined $value ? 100755 : 100644;
4280                 }
4281         } elsif ($prop eq 'svn:special') {
4282                 $fb->{mode_b} = defined $value ? 120000 : 100644;
4283         } else {
4284                 $self->{file_prop}->{$fb->{path}} ||= {};
4285                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
4286         }
4287         undef;
4288 }
4289
4290 sub apply_textdelta {
4291         my ($self, $fb, $exp) = @_;
4292         return undef if $self->is_path_ignored($fb->{path});
4293         my $fh = $::_repository->temp_acquire('svn_delta');
4294         # $fh gets auto-closed() by SVN::TxDelta::apply(),
4295         # (but $base does not,) so dup() it for reading in close_file
4296         open my $dup, '<&', $fh or croak $!;
4297         my $base = $::_repository->temp_acquire('git_blob');
4298
4299         if ($fb->{blob}) {
4300                 my ($base_is_link, $size);
4301
4302                 if ($fb->{mode_a} eq '120000' &&
4303                     ! $self->{empty_symlinks}->{$fb->{path}}) {
4304                         print $base 'link ' or die "print $!\n";
4305                         $base_is_link = 1;
4306                 }
4307         retry:
4308                 $size = $::_repository->cat_blob($fb->{blob}, $base);
4309                 die "Failed to read object $fb->{blob}" if ($size < 0);
4310
4311                 if (defined $exp) {
4312                         seek $base, 0, 0 or croak $!;
4313                         my $got = ::md5sum($base);
4314                         if ($got ne $exp) {
4315                                 my $err = "Checksum mismatch: ".
4316                                        "$fb->{path} $fb->{blob}\n" .
4317                                        "expected: $exp\n" .
4318                                        "     got: $got\n";
4319                                 if ($base_is_link) {
4320                                         warn $err,
4321                                              "Retrying... (possibly ",
4322                                              "a bad symlink from SVN)\n";
4323                                         $::_repository->temp_reset($base);
4324                                         $base_is_link = 0;
4325                                         goto retry;
4326                                 }
4327                                 die $err;
4328                         }
4329                 }
4330         }
4331         seek $base, 0, 0 or croak $!;
4332         $fb->{fh} = $fh;
4333         $fb->{base} = $base;
4334         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
4335 }
4336
4337 sub close_file {
4338         my ($self, $fb, $exp) = @_;
4339         return undef if $self->is_path_ignored($fb->{path});
4340
4341         my $hash;
4342         my $path = $self->git_path($fb->{path});
4343         if (my $fh = $fb->{fh}) {
4344                 if (defined $exp) {
4345                         seek($fh, 0, 0) or croak $!;
4346                         my $got = ::md5sum($fh);
4347                         if ($got ne $exp) {
4348                                 die "Checksum mismatch: $path\n",
4349                                     "expected: $exp\n    got: $got\n";
4350                         }
4351                 }
4352                 if ($fb->{mode_b} == 120000) {
4353                         sysseek($fh, 0, 0) or croak $!;
4354                         my $rd = sysread($fh, my $buf, 5);
4355
4356                         if (!defined $rd) {
4357                                 croak "sysread: $!\n";
4358                         } elsif ($rd == 0) {
4359                                 warn "$path has mode 120000",
4360                                      " but it points to nothing\n",
4361                                      "converting to an empty file with mode",
4362                                      " 100644\n";
4363                                 $fb->{mode_b} = '100644';
4364                         } elsif ($buf ne 'link ') {
4365                                 warn "$path has mode 120000",
4366                                      " but is not a link\n";
4367                         } else {
4368                                 my $tmp_fh = $::_repository->temp_acquire(
4369                                         'svn_hash');
4370                                 my $res;
4371                                 while ($res = sysread($fh, my $str, 1024)) {
4372                                         my $out = syswrite($tmp_fh, $str, $res);
4373                                         defined($out) && $out == $res
4374                                                 or croak("write ",
4375                                                         Git::temp_path($tmp_fh),
4376                                                         ": $!\n");
4377                                 }
4378                                 defined $res or croak $!;
4379
4380                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
4381                                 Git::temp_release($tmp_fh, 1);
4382                         }
4383                 }
4384
4385                 $hash = $::_repository->hash_and_insert_object(
4386                                 Git::temp_path($fh));
4387                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
4388
4389                 Git::temp_release($fb->{base}, 1);
4390                 Git::temp_release($fh, 1);
4391         } else {
4392                 $hash = $fb->{blob} or die "no blob information\n";
4393         }
4394         $fb->{pool}->clear;
4395         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
4396         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
4397         undef;
4398 }
4399
4400 sub abort_edit {
4401         my $self = shift;
4402         $self->{nr} = $self->{gii}->{nr};
4403         delete $self->{gii};
4404         $self->SUPER::abort_edit(@_);
4405 }
4406
4407 sub close_edit {
4408         my $self = shift;
4409         $self->{git_commit_ok} = 1;
4410         $self->{nr} = $self->{gii}->{nr};
4411         delete $self->{gii};
4412         $self->SUPER::close_edit(@_);
4413 }
4414
4415 package SVN::Git::Editor;
4416 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
4417 use strict;
4418 use warnings;
4419 use Carp qw/croak/;
4420 use IO::File;
4421
4422 sub new {
4423         my ($class, $opts) = @_;
4424         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
4425                 die "$_ required!\n" unless (defined $opts->{$_});
4426         }
4427
4428         my $pool = SVN::Pool->new;
4429         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
4430         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
4431                                      $opts->{r}, $mods);
4432
4433         # $opts->{ra} functions should not be used after this:
4434         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
4435                                                 $opts->{editor_cb}, $pool);
4436         my $self = SVN::Delta::Editor->new(@ce, $pool);
4437         bless $self, $class;
4438         foreach (qw/svn_path r tree_a tree_b/) {
4439                 $self->{$_} = $opts->{$_};
4440         }
4441         $self->{url} = $opts->{ra}->{url};
4442         $self->{mods} = $mods;
4443         $self->{types} = $types;
4444         $self->{pool} = $pool;
4445         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
4446         $self->{rm} = { };
4447         $self->{path_prefix} = length $self->{svn_path} ?
4448                                "$self->{svn_path}/" : '';
4449         $self->{config} = $opts->{config};
4450         return $self;
4451 }
4452
4453 sub generate_diff {
4454         my ($tree_a, $tree_b) = @_;
4455         my @diff_tree = qw(diff-tree -z -r);
4456         if ($_cp_similarity) {
4457                 push @diff_tree, "-C$_cp_similarity";
4458         } else {
4459                 push @diff_tree, '-C';
4460         }
4461         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
4462         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
4463         push @diff_tree, $tree_a, $tree_b;
4464         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
4465         local $/ = "\0";
4466         my $state = 'meta';
4467         my @mods;
4468         while (<$diff_fh>) {
4469                 chomp $_; # this gets rid of the trailing "\0"
4470                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
4471                                         ($::sha1)\s($::sha1)\s
4472                                         ([MTCRAD])\d*$/xo) {
4473                         push @mods, {   mode_a => $1, mode_b => $2,
4474                                         sha1_a => $3, sha1_b => $4,
4475                                         chg => $5 };
4476                         if ($5 =~ /^(?:C|R)$/) {
4477                                 $state = 'file_a';
4478                         } else {
4479                                 $state = 'file_b';
4480                         }
4481                 } elsif ($state eq 'file_a') {
4482                         my $x = $mods[$#mods] or croak "Empty array\n";
4483                         if ($x->{chg} !~ /^(?:C|R)$/) {
4484                                 croak "Error parsing $_, $x->{chg}\n";
4485                         }
4486                         $x->{file_a} = $_;
4487                         $state = 'file_b';
4488                 } elsif ($state eq 'file_b') {
4489                         my $x = $mods[$#mods] or croak "Empty array\n";
4490                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
4491                                 croak "Error parsing $_, $x->{chg}\n";
4492                         }
4493                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
4494                                 croak "Error parsing $_, $x->{chg}\n";
4495                         }
4496                         $x->{file_b} = $_;
4497                         $state = 'meta';
4498                 } else {
4499                         croak "Error parsing $_\n";
4500                 }
4501         }
4502         command_close_pipe($diff_fh, $ctx);
4503         \@mods;
4504 }
4505
4506 sub check_diff_paths {
4507         my ($ra, $pfx, $rev, $mods) = @_;
4508         my %types;
4509         $pfx .= '/' if length $pfx;
4510
4511         sub type_diff_paths {
4512                 my ($ra, $types, $path, $rev) = @_;
4513                 my @p = split m#/+#, $path;
4514                 my $c = shift @p;
4515                 unless (defined $types->{$c}) {
4516                         $types->{$c} = $ra->check_path($c, $rev);
4517                 }
4518                 while (@p) {
4519                         $c .= '/' . shift @p;
4520                         next if defined $types->{$c};
4521                         $types->{$c} = $ra->check_path($c, $rev);
4522                 }
4523         }
4524
4525         foreach my $m (@$mods) {
4526                 foreach my $f (qw/file_a file_b/) {
4527                         next unless defined $m->{$f};
4528                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
4529                         if (length $pfx.$dir && ! defined $types{$dir}) {
4530                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
4531                         }
4532                 }
4533         }
4534         \%types;
4535 }
4536
4537 sub split_path {
4538         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
4539 }
4540
4541 sub repo_path {
4542         my ($self, $path) = @_;
4543         if (my $enc = $self->{pathnameencoding}) {
4544                 require Encode;
4545                 Encode::from_to($path, $enc, 'UTF-8');
4546         }
4547         $self->{path_prefix}.(defined $path ? $path : '');
4548 }
4549
4550 sub url_path {
4551         my ($self, $path) = @_;
4552         if ($self->{url} =~ m#^https?://#) {
4553                 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4554         }
4555         $self->{url} . '/' . $self->repo_path($path);
4556 }
4557
4558 sub rmdirs {
4559         my ($self) = @_;
4560         my $rm = $self->{rm};
4561         delete $rm->{''}; # we never delete the url we're tracking
4562         return unless %$rm;
4563
4564         foreach (keys %$rm) {
4565                 my @d = split m#/#, $_;
4566                 my $c = shift @d;
4567                 $rm->{$c} = 1;
4568                 while (@d) {
4569                         $c .= '/' . shift @d;
4570                         $rm->{$c} = 1;
4571                 }
4572         }
4573         delete $rm->{$self->{svn_path}};
4574         delete $rm->{''}; # we never delete the url we're tracking
4575         return unless %$rm;
4576
4577         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4578                                              $self->{tree_b});
4579         local $/ = "\0";
4580         while (<$fh>) {
4581                 chomp;
4582                 my @dn = split m#/#, $_;
4583                 while (pop @dn) {
4584                         delete $rm->{join '/', @dn};
4585                 }
4586                 unless (%$rm) {
4587                         close $fh;
4588                         return;
4589                 }
4590         }
4591         command_close_pipe($fh, $ctx);
4592
4593         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4594         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4595                 $self->close_directory($bat->{$d}, $p);
4596                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4597                 print "\tD+\t$d/\n" unless $::_q;
4598                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4599                 delete $bat->{$d};
4600         }
4601 }
4602
4603 sub open_or_add_dir {
4604         my ($self, $full_path, $baton) = @_;
4605         my $t = $self->{types}->{$full_path};
4606         if (!defined $t) {
4607                 die "$full_path not known in r$self->{r} or we have a bug!\n";
4608         }
4609         {
4610                 no warnings 'once';
4611                 # SVN::Node::none and SVN::Node::file are used only once,
4612                 # so we're shutting up Perl's warnings about them.
4613                 if ($t == $SVN::Node::none) {
4614                         return $self->add_directory($full_path, $baton,
4615                             undef, -1, $self->{pool});
4616                 } elsif ($t == $SVN::Node::dir) {
4617                         return $self->open_directory($full_path, $baton,
4618                             $self->{r}, $self->{pool});
4619                 } # no warnings 'once'
4620                 print STDERR "$full_path already exists in repository at ",
4621                     "r$self->{r} and it is not a directory (",
4622                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4623         } # no warnings 'once'
4624         exit 1;
4625 }
4626
4627 sub ensure_path {
4628         my ($self, $path) = @_;
4629         my $bat = $self->{bat};
4630         my $repo_path = $self->repo_path($path);
4631         return $bat->{''} unless (length $repo_path);
4632         my @p = split m#/+#, $repo_path;
4633         my $c = shift @p;
4634         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4635         while (@p) {
4636                 my $c0 = $c;
4637                 $c .= '/' . shift @p;
4638                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4639         }
4640         return $bat->{$c};
4641 }
4642
4643 # Subroutine to convert a globbing pattern to a regular expression.
4644 # From perl cookbook.
4645 sub glob2pat {
4646         my $globstr = shift;
4647         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4648         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4649         return '^' . $globstr . '$';
4650 }
4651
4652 sub check_autoprop {
4653         my ($self, $pattern, $properties, $file, $fbat) = @_;
4654         # Convert the globbing pattern to a regular expression.
4655         my $regex = glob2pat($pattern);
4656         # Check if the pattern matches the file name.
4657         if($file =~ m/($regex)/) {
4658                 # Parse the list of properties to set.
4659                 my @props = split(/;/, $properties);
4660                 foreach my $prop (@props) {
4661                         # Parse 'name=value' syntax and set the property.
4662                         if ($prop =~ /([^=]+)=(.*)/) {
4663                                 my ($n,$v) = ($1,$2);
4664                                 for ($n, $v) {
4665                                         s/^\s+//; s/\s+$//;
4666                                 }
4667                                 $self->change_file_prop($fbat, $n, $v);
4668                         }
4669                 }
4670         }
4671 }
4672
4673 sub apply_autoprops {
4674         my ($self, $file, $fbat) = @_;
4675         my $conf_t = ${$self->{config}}{'config'};
4676         no warnings 'once';
4677         # Check [miscellany]/enable-auto-props in svn configuration.
4678         if (SVN::_Core::svn_config_get_bool(
4679                 $conf_t,
4680                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4681                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4682                 0)) {
4683                 # Auto-props are enabled.  Enumerate them to look for matches.
4684                 my $callback = sub {
4685                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
4686                 };
4687                 SVN::_Core::svn_config_enumerate(
4688                         $conf_t,
4689                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4690                         $callback);
4691         }
4692 }
4693
4694 sub A {
4695         my ($self, $m) = @_;
4696         my ($dir, $file) = split_path($m->{file_b});
4697         my $pbat = $self->ensure_path($dir);
4698         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4699                                         undef, -1);
4700         print "\tA\t$m->{file_b}\n" unless $::_q;
4701         $self->apply_autoprops($file, $fbat);
4702         $self->chg_file($fbat, $m);
4703         $self->close_file($fbat,undef,$self->{pool});
4704 }
4705
4706 sub C {
4707         my ($self, $m) = @_;
4708         my ($dir, $file) = split_path($m->{file_b});
4709         my $pbat = $self->ensure_path($dir);
4710         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4711                                 $self->url_path($m->{file_a}), $self->{r});
4712         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4713         $self->chg_file($fbat, $m);
4714         $self->close_file($fbat,undef,$self->{pool});
4715 }
4716
4717 sub delete_entry {
4718         my ($self, $path, $pbat) = @_;
4719         my $rpath = $self->repo_path($path);
4720         my ($dir, $file) = split_path($rpath);
4721         $self->{rm}->{$dir} = 1;
4722         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4723 }
4724
4725 sub R {
4726         my ($self, $m) = @_;
4727         my ($dir, $file) = split_path($m->{file_b});
4728         my $pbat = $self->ensure_path($dir);
4729         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4730                                 $self->url_path($m->{file_a}), $self->{r});
4731         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4732         $self->apply_autoprops($file, $fbat);
4733         $self->chg_file($fbat, $m);
4734         $self->close_file($fbat,undef,$self->{pool});
4735
4736         ($dir, $file) = split_path($m->{file_a});
4737         $pbat = $self->ensure_path($dir);
4738         $self->delete_entry($m->{file_a}, $pbat);
4739 }
4740
4741 sub M {
4742         my ($self, $m) = @_;
4743         my ($dir, $file) = split_path($m->{file_b});
4744         my $pbat = $self->ensure_path($dir);
4745         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4746                                 $pbat,$self->{r},$self->{pool});
4747         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4748         $self->chg_file($fbat, $m);
4749         $self->close_file($fbat,undef,$self->{pool});
4750 }
4751
4752 sub T { shift->M(@_) }
4753
4754 sub change_file_prop {
4755         my ($self, $fbat, $pname, $pval) = @_;
4756         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4757 }
4758
4759 sub _chg_file_get_blob ($$$$) {
4760         my ($self, $fbat, $m, $which) = @_;
4761         my $fh = $::_repository->temp_acquire("git_blob_$which");
4762         if ($m->{"mode_$which"} =~ /^120/) {
4763                 print $fh 'link ' or croak $!;
4764                 $self->change_file_prop($fbat,'svn:special','*');
4765         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4766                 $self->change_file_prop($fbat,'svn:special',undef);
4767         }
4768         my $blob = $m->{"sha1_$which"};
4769         return ($fh,) if ($blob =~ /^0{40}$/);
4770         my $size = $::_repository->cat_blob($blob, $fh);
4771         croak "Failed to read object $blob" if ($size < 0);
4772         $fh->flush == 0 or croak $!;
4773         seek $fh, 0, 0 or croak $!;
4774
4775         my $exp = ::md5sum($fh);
4776         seek $fh, 0, 0 or croak $!;
4777         return ($fh, $exp);
4778 }
4779
4780 sub chg_file {
4781         my ($self, $fbat, $m) = @_;
4782         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4783                 $self->change_file_prop($fbat,'svn:executable','*');
4784         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4785                 $self->change_file_prop($fbat,'svn:executable',undef);
4786         }
4787         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4788         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4789         my $pool = SVN::Pool->new;
4790         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4791         if (-s $fh_a) {
4792                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4793                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4794                 if (defined $res) {
4795                         die "Unexpected result from send_txstream: $res\n",
4796                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4797                 }
4798         } else {
4799                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4800                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4801                     if ($got ne $exp_b);
4802         }
4803         Git::temp_release($fh_b, 1);
4804         Git::temp_release($fh_a, 1);
4805         $pool->clear;
4806 }
4807
4808 sub D {
4809         my ($self, $m) = @_;
4810         my ($dir, $file) = split_path($m->{file_b});
4811         my $pbat = $self->ensure_path($dir);
4812         print "\tD\t$m->{file_b}\n" unless $::_q;
4813         $self->delete_entry($m->{file_b}, $pbat);
4814 }
4815
4816 sub close_edit {
4817         my ($self) = @_;
4818         my ($p,$bat) = ($self->{pool}, $self->{bat});
4819         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4820                 next if $_ eq '';
4821                 $self->close_directory($bat->{$_}, $p);
4822         }
4823         $self->close_directory($bat->{''}, $p);
4824         $self->SUPER::close_edit($p);
4825         $p->clear;
4826 }
4827
4828 sub abort_edit {
4829         my ($self) = @_;
4830         $self->SUPER::abort_edit($self->{pool});
4831 }
4832
4833 sub DESTROY {
4834         my $self = shift;
4835         $self->SUPER::DESTROY(@_);
4836         $self->{pool}->clear;
4837 }
4838
4839 # this drives the editor
4840 sub apply_diff {
4841         my ($self) = @_;
4842         my $mods = $self->{mods};
4843         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4844         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4845                 my $f = $m->{chg};
4846                 if (defined $o{$f}) {
4847                         $self->$f($m);
4848                 } else {
4849                         fatal("Invalid change type: $f");
4850                 }
4851         }
4852         $self->rmdirs if $_rmdir;
4853         if (@$mods == 0) {
4854                 $self->abort_edit;
4855         } else {
4856                 $self->close_edit;
4857         }
4858         return scalar @$mods;
4859 }
4860
4861 package Git::SVN::Ra;
4862 use vars qw/@ISA $config_dir $_log_window_size/;
4863 use strict;
4864 use warnings;
4865 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4866
4867 BEGIN {
4868         # enforce temporary pool usage for some simple functions
4869         no strict 'refs';
4870         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4871                       get_file/) {
4872                 my $SUPER = "SUPER::$f";
4873                 *$f = sub {
4874                         my $self = shift;
4875                         my $pool = SVN::Pool->new;
4876                         my @ret = $self->$SUPER(@_,$pool);
4877                         $pool->clear;
4878                         wantarray ? @ret : $ret[0];
4879                 };
4880         }
4881 }
4882
4883 sub _auth_providers () {
4884         [
4885           SVN::Client::get_simple_provider(),
4886           SVN::Client::get_ssl_server_trust_file_provider(),
4887           SVN::Client::get_simple_prompt_provider(
4888             \&Git::SVN::Prompt::simple, 2),
4889           SVN::Client::get_ssl_client_cert_file_provider(),
4890           SVN::Client::get_ssl_client_cert_prompt_provider(
4891             \&Git::SVN::Prompt::ssl_client_cert, 2),
4892           SVN::Client::get_ssl_client_cert_pw_file_provider(),
4893           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4894             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4895           SVN::Client::get_username_provider(),
4896           SVN::Client::get_ssl_server_trust_prompt_provider(
4897             \&Git::SVN::Prompt::ssl_server_trust),
4898           SVN::Client::get_username_prompt_provider(
4899             \&Git::SVN::Prompt::username, 2)
4900         ]
4901 }
4902
4903 sub escape_uri_only {
4904         my ($uri) = @_;
4905         my @tmp;
4906         foreach (split m{/}, $uri) {
4907                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4908                 push @tmp, $_;
4909         }
4910         join('/', @tmp);
4911 }
4912
4913 sub escape_url {
4914         my ($url) = @_;
4915         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4916                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4917                 $url = "$scheme://$domain$uri";
4918         }
4919         $url;
4920 }
4921
4922 sub new {
4923         my ($class, $url) = @_;
4924         $url =~ s!/+$!!;
4925         return $RA if ($RA && $RA->{url} eq $url);
4926
4927         ::_req_svn();
4928
4929         SVN::_Core::svn_config_ensure($config_dir, undef);
4930         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4931         my $config = SVN::Core::config_get_config($config_dir);
4932         $RA = undef;
4933         my $dont_store_passwords = 1;
4934         my $conf_t = ${$config}{'config'};
4935         {
4936                 no warnings 'once';
4937                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4938                 # produces warnings that variables are used only once.
4939                 # I had not found the better way to shut them up, so
4940                 # the warnings of type 'once' are disabled in this block.
4941                 if (SVN::_Core::svn_config_get_bool($conf_t,
4942                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4943                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4944                     1) == 0) {
4945                         SVN::_Core::svn_auth_set_parameter($baton,
4946                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4947                             bless (\$dont_store_passwords, "_p_void"));
4948                 }
4949                 if (SVN::_Core::svn_config_get_bool($conf_t,
4950                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4951                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4952                     1) == 0) {
4953                         $Git::SVN::Prompt::_no_auth_cache = 1;
4954                 }
4955         } # no warnings 'once'
4956         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4957                               config => $config,
4958                               pool => SVN::Pool->new,
4959                               auth_provider_callbacks => $callbacks);
4960         $self->{url} = $url;
4961         $self->{svn_path} = $url;
4962         $self->{repos_root} = $self->get_repos_root;
4963         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4964         $self->{cache} = { check_path => { r => 0, data => {} },
4965                            get_dir => { r => 0, data => {} } };
4966         $RA = bless $self, $class;
4967 }
4968
4969 sub check_path {
4970         my ($self, $path, $r) = @_;
4971         my $cache = $self->{cache}->{check_path};
4972         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4973                 return $cache->{data}->{$path};
4974         }
4975         my $pool = SVN::Pool->new;
4976         my $t = $self->SUPER::check_path($path, $r, $pool);
4977         $pool->clear;
4978         if ($r != $cache->{r}) {
4979                 %{$cache->{data}} = ();
4980                 $cache->{r} = $r;
4981         }
4982         $cache->{data}->{$path} = $t;
4983 }
4984
4985 sub get_dir {
4986         my ($self, $dir, $r) = @_;
4987         my $cache = $self->{cache}->{get_dir};
4988         if ($r == $cache->{r}) {
4989                 if (my $x = $cache->{data}->{$dir}) {
4990                         return wantarray ? @$x : $x->[0];
4991                 }
4992         }
4993         my $pool = SVN::Pool->new;
4994         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4995         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4996         $pool->clear;
4997         if ($r != $cache->{r}) {
4998                 %{$cache->{data}} = ();
4999                 $cache->{r} = $r;
5000         }
5001         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
5002         wantarray ? (\%dirents, $r, $props) : \%dirents;
5003 }
5004
5005 sub DESTROY {
5006         # do not call the real DESTROY since we store ourselves in $RA
5007 }
5008
5009 # get_log(paths, start, end, limit,
5010 #         discover_changed_paths, strict_node_history, receiver)
5011 sub get_log {
5012         my ($self, @args) = @_;
5013         my $pool = SVN::Pool->new;
5014
5015         # svn_log_changed_path_t objects passed to get_log are likely to be
5016         # overwritten even if only the refs are copied to an external variable,
5017         # so we should dup the structures in their entirety.  Using an
5018         # externally passed pool (instead of our temporary and quickly cleared
5019         # pool in Git::SVN::Ra) does not help matters at all...
5020         my $receiver = pop @args;
5021         my $prefix = "/".$self->{svn_path};
5022         $prefix =~ s#/+($)##;
5023         my $prefix_regex = qr#^\Q$prefix\E#;
5024         push(@args, sub {
5025                 my ($paths) = $_[0];
5026                 return &$receiver(@_) unless $paths;
5027                 $_[0] = ();
5028                 foreach my $p (keys %$paths) {
5029                         my $i = $paths->{$p};
5030                         # Make path relative to our url, not repos_root
5031                         $p =~ s/$prefix_regex//;
5032                         my %s = map { $_ => $i->$_; }
5033                                 qw/copyfrom_path copyfrom_rev action/;
5034                         if ($s{'copyfrom_path'}) {
5035                                 $s{'copyfrom_path'} =~ s/$prefix_regex//;
5036                         }
5037                         $_[0]{$p} = \%s;
5038                 }
5039                 &$receiver(@_);
5040         });
5041
5042
5043         # the limit parameter was not supported in SVN 1.1.x, so we
5044         # drop it.  Therefore, the receiver callback passed to it
5045         # is made aware of this limitation by being wrapped if
5046         # the limit passed to is being wrapped.
5047         if ($SVN::Core::VERSION le '1.2.0') {
5048                 my $limit = splice(@args, 3, 1);
5049                 if ($limit > 0) {
5050                         my $receiver = pop @args;
5051                         push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
5052                 }
5053         }
5054         my $ret = $self->SUPER::get_log(@args, $pool);
5055         $pool->clear;
5056         $ret;
5057 }
5058
5059 sub trees_match {
5060         my ($self, $url1, $rev1, $url2, $rev2) = @_;
5061         my $ctx = SVN::Client->new(auth => _auth_providers);
5062         my $out = IO::File->new_tmpfile;
5063
5064         # older SVN (1.1.x) doesn't take $pool as the last parameter for
5065         # $ctx->diff(), so we'll create a default one
5066         my $pool = SVN::Pool->new_default_sub;
5067
5068         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
5069         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
5070         $out->flush;
5071         my $ret = (($out->stat)[7] == 0);
5072         close $out or croak $!;
5073
5074         $ret;
5075 }
5076
5077 sub get_commit_editor {
5078         my ($self, $log, $cb, $pool) = @_;
5079         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
5080         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
5081 }
5082
5083 sub gs_do_update {
5084         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
5085         my $new = ($rev_a == $rev_b);
5086         my $path = $gs->{path};
5087
5088         if ($new && -e $gs->{index}) {
5089                 unlink $gs->{index} or die
5090                   "Couldn't unlink index: $gs->{index}: $!\n";
5091         }
5092         my $pool = SVN::Pool->new;
5093         $editor->set_path_strip($path);
5094         my (@pc) = split m#/#, $path;
5095         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
5096                                         1, $editor, $pool);
5097         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5098
5099         # Since we can't rely on svn_ra_reparent being available, we'll
5100         # just have to do some magic with set_path to make it so
5101         # we only want a partial path.
5102         my $sp = '';
5103         my $final = join('/', @pc);
5104         while (@pc) {
5105                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
5106                 $sp .= '/' if length $sp;
5107                 $sp .= shift @pc;
5108         }
5109         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
5110
5111         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
5112
5113         $reporter->finish_report($pool);
5114         $pool->clear;
5115         $editor->{git_commit_ok};
5116 }
5117
5118 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
5119 # svn_ra_reparent didn't work before 1.4)
5120 sub gs_do_switch {
5121         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
5122         my $path = $gs->{path};
5123         my $pool = SVN::Pool->new;
5124
5125         my $full_url = $self->{url};
5126         my $old_url = $full_url;
5127         $full_url .= '/' . $path if length $path;
5128         my ($ra, $reparented);
5129
5130         if ($old_url =~ m#^svn(\+ssh)?://# ||
5131             ($full_url =~ m#^https?://# &&
5132              escape_url($full_url) ne $full_url)) {
5133                 $_[0] = undef;
5134                 $self = undef;
5135                 $RA = undef;
5136                 $ra = Git::SVN::Ra->new($full_url);
5137                 $ra_invalid = 1;
5138         } elsif ($old_url ne $full_url) {
5139                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
5140                 $self->{url} = $full_url;
5141                 $reparented = 1;
5142         }
5143
5144         $ra ||= $self;
5145         $url_b = escape_url($url_b);
5146         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
5147         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5148         $reporter->set_path('', $rev_a, 0, @lock, $pool);
5149         $reporter->finish_report($pool);
5150
5151         if ($reparented) {
5152                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
5153                 $self->{url} = $old_url;
5154         }
5155
5156         $pool->clear;
5157         $editor->{git_commit_ok};
5158 }
5159
5160 sub longest_common_path {
5161         my ($gsv, $globs) = @_;
5162         my %common;
5163         my $common_max = scalar @$gsv;
5164
5165         foreach my $gs (@$gsv) {
5166                 my @tmp = split m#/#, $gs->{path};
5167                 my $p = '';
5168                 foreach (@tmp) {
5169                         $p .= length($p) ? "/$_" : $_;
5170                         $common{$p} ||= 0;
5171                         $common{$p}++;
5172                 }
5173         }
5174         $globs ||= [];
5175         $common_max += scalar @$globs;
5176         foreach my $glob (@$globs) {
5177                 my @tmp = split m#/#, $glob->{path}->{left};
5178                 my $p = '';
5179                 foreach (@tmp) {
5180                         $p .= length($p) ? "/$_" : $_;
5181                         $common{$p} ||= 0;
5182                         $common{$p}++;
5183                 }
5184         }
5185
5186         my $longest_path = '';
5187         foreach (sort {length $b <=> length $a} keys %common) {
5188                 if ($common{$_} == $common_max) {
5189                         $longest_path = $_;
5190                         last;
5191                 }
5192         }
5193         $longest_path;
5194 }
5195
5196 sub gs_fetch_loop_common {
5197         my ($self, $base, $head, $gsv, $globs) = @_;
5198         return if ($base > $head);
5199         my $inc = $_log_window_size;
5200         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
5201         my $longest_path = longest_common_path($gsv, $globs);
5202         my $ra_url = $self->{url};
5203         my $find_trailing_edge;
5204         while (1) {
5205                 my %revs;
5206                 my $err;
5207                 my $err_handler = $SVN::Error::handler;
5208                 $SVN::Error::handler = sub {
5209                         ($err) = @_;
5210                         skip_unknown_revs($err);
5211                 };
5212                 sub _cb {
5213                         my ($paths, $r, $author, $date, $log) = @_;
5214                         [ $paths,
5215                           { author => $author, date => $date, log => $log } ];
5216                 }
5217                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
5218                                sub { $revs{$_[1]} = _cb(@_) });
5219                 if ($err) {
5220                         print "Checked through r$max\r";
5221                 } else {
5222                         $find_trailing_edge = 1;
5223                 }
5224                 if ($err and $find_trailing_edge) {
5225                         print STDERR "Path '$longest_path' ",
5226                                      "was probably deleted:\n",
5227                                      $err->expanded_message,
5228                                      "\nWill attempt to follow ",
5229                                      "revisions r$min .. r$max ",
5230                                      "committed before the deletion\n";
5231                         my $hi = $max;
5232                         while (--$hi >= $min) {
5233                                 my $ok;
5234                                 $self->get_log([$longest_path], $min, $hi,
5235                                                0, 1, 1, sub {
5236                                                $ok = $_[1];
5237                                                $revs{$_[1]} = _cb(@_) });
5238                                 if ($ok) {
5239                                         print STDERR "r$min .. r$ok OK\n";
5240                                         last;
5241                                 }
5242                         }
5243                         $find_trailing_edge = 0;
5244                 }
5245                 $SVN::Error::handler = $err_handler;
5246
5247                 my %exists = map { $_->{path} => $_ } @$gsv;
5248                 foreach my $r (sort {$a <=> $b} keys %revs) {
5249                         my ($paths, $logged) = @{$revs{$r}};
5250
5251                         foreach my $gs ($self->match_globs(\%exists, $paths,
5252                                                            $globs, $r)) {
5253                                 if ($gs->rev_map_max >= $r) {
5254                                         next;
5255                                 }
5256                                 next unless $gs->match_paths($paths, $r);
5257                                 $gs->{logged_rev_props} = $logged;
5258                                 if (my $last_commit = $gs->last_commit) {
5259                                         $gs->assert_index_clean($last_commit);
5260                                 }
5261                                 my $log_entry = $gs->do_fetch($paths, $r);
5262                                 if ($log_entry) {
5263                                         $gs->do_git_commit($log_entry);
5264                                 }
5265                                 $INDEX_FILES{$gs->{index}} = 1;
5266                         }
5267                         foreach my $g (@$globs) {
5268                                 my $k = "svn-remote.$g->{remote}." .
5269                                         "$g->{t}-maxRev";
5270                                 Git::SVN::tmp_config($k, $r);
5271                         }
5272                         if ($ra_invalid) {
5273                                 $_[0] = undef;
5274                                 $self = undef;
5275                                 $RA = undef;
5276                                 $self = Git::SVN::Ra->new($ra_url);
5277                                 $ra_invalid = undef;
5278                         }
5279                 }
5280                 # pre-fill the .rev_db since it'll eventually get filled in
5281                 # with '0' x40 if something new gets committed
5282                 foreach my $gs (@$gsv) {
5283                         next if $gs->rev_map_max >= $max;
5284                         next if defined $gs->rev_map_get($max);
5285                         $gs->rev_map_set($max, 0 x40);
5286                 }
5287                 foreach my $g (@$globs) {
5288                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
5289                         Git::SVN::tmp_config($k, $max);
5290                 }
5291                 last if $max >= $head;
5292                 $min = $max + 1;
5293                 $max += $inc;
5294                 $max = $head if ($max > $head);
5295         }
5296         Git::SVN::gc();
5297 }
5298
5299 sub get_dir_globbed {
5300         my ($self, $left, $depth, $r) = @_;
5301
5302         my @x = eval { $self->get_dir($left, $r) };
5303         return unless scalar @x == 3;
5304         my $dirents = $x[0];
5305         my @finalents;
5306         foreach my $de (keys %$dirents) {
5307                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
5308                 if ($depth > 1) {
5309                         my @args = ("$left/$de", $depth - 1, $r);
5310                         foreach my $dir ($self->get_dir_globbed(@args)) {
5311                                 push @finalents, "$de/$dir";
5312                         }
5313                 } else {
5314                         push @finalents, $de;
5315                 }
5316         }
5317         @finalents;
5318 }
5319
5320 sub match_globs {
5321         my ($self, $exists, $paths, $globs, $r) = @_;
5322
5323         sub get_dir_check {
5324                 my ($self, $exists, $g, $r) = @_;
5325
5326                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
5327                                                   $g->{path}->{depth},
5328                                                   $r);
5329
5330                 foreach my $de (@dirs) {
5331                         my $p = $g->{path}->full_path($de);
5332                         next if $exists->{$p};
5333                         next if (length $g->{path}->{right} &&
5334                                  ($self->check_path($p, $r) !=
5335                                   $SVN::Node::dir));
5336                         next unless $p =~ /$g->{path}->{regex}/;
5337                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
5338                                          $g->{ref}->full_path($de), 1);
5339                 }
5340         }
5341         foreach my $g (@$globs) {
5342                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
5343                         if ($path->{action} =~ /^[AR]$/) {
5344                                 get_dir_check($self, $exists, $g, $r);
5345                         }
5346                 }
5347                 foreach (keys %$paths) {
5348                         if (/$g->{path}->{left_regex}/ &&
5349                             !/$g->{path}->{regex}/) {
5350                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
5351                                 get_dir_check($self, $exists, $g, $r);
5352                         }
5353                         next unless /$g->{path}->{regex}/;
5354                         my $p = $1;
5355                         my $pathname = $g->{path}->full_path($p);
5356                         next if $exists->{$pathname};
5357                         next if ($self->check_path($pathname, $r) !=
5358                                  $SVN::Node::dir);
5359                         $exists->{$pathname} = Git::SVN->init(
5360                                               $self->{url}, $pathname, undef,
5361                                               $g->{ref}->full_path($p), 1);
5362                 }
5363                 my $c = '';
5364                 foreach (split m#/#, $g->{path}->{left}) {
5365                         $c .= "/$_";
5366                         next unless ($paths->{$c} &&
5367                                      ($paths->{$c}->{action} =~ /^[AR]$/));
5368                         get_dir_check($self, $exists, $g, $r);
5369                 }
5370         }
5371         values %$exists;
5372 }
5373
5374 sub minimize_url {
5375         my ($self) = @_;
5376         return $self->{url} if ($self->{url} eq $self->{repos_root});
5377         my $url = $self->{repos_root};
5378         my @components = split(m!/!, $self->{svn_path});
5379         my $c = '';
5380         do {
5381                 $url .= "/$c" if length $c;
5382                 eval {
5383                         my $ra = (ref $self)->new($url);
5384                         my $latest = $ra->get_latest_revnum;
5385                         $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
5386                 };
5387         } while ($@ && ($c = shift @components));
5388         $url;
5389 }
5390
5391 sub can_do_switch {
5392         my $self = shift;
5393         unless (defined $can_do_switch) {
5394                 my $pool = SVN::Pool->new;
5395                 my $rep = eval {
5396                         $self->do_switch(1, '', 0, $self->{url},
5397                                          SVN::Delta::Editor->new, $pool);
5398                 };
5399                 if ($@) {
5400                         $can_do_switch = 0;
5401                 } else {
5402                         $rep->abort_report($pool);
5403                         $can_do_switch = 1;
5404                 }
5405                 $pool->clear;
5406         }
5407         $can_do_switch;
5408 }
5409
5410 sub skip_unknown_revs {
5411         my ($err) = @_;
5412         my $errno = $err->apr_err();
5413         # Maybe the branch we're tracking didn't
5414         # exist when the repo started, so it's
5415         # not an error if it doesn't, just continue
5416         #
5417         # Wonderfully consistent library, eh?
5418         # 160013 - svn:// and file://
5419         # 175002 - http(s)://
5420         # 175007 - http(s):// (this repo required authorization, too...)
5421         #   More codes may be discovered later...
5422         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
5423                 my $err_key = $err->expanded_message;
5424                 # revision numbers change every time, filter them out
5425                 $err_key =~ s/\d+/\0/g;
5426                 $err_key = "$errno\0$err_key";
5427                 unless ($ignored_err{$err_key}) {
5428                         warn "W: Ignoring error from SVN, path probably ",
5429                              "does not exist: ($errno): ",
5430                              $err->expanded_message,"\n";
5431                         warn "W: Do not be alarmed at the above message ",
5432                              "git-svn is just searching aggressively for ",
5433                              "old history.\n",
5434                              "This may take a while on large repositories\n";
5435                         $ignored_err{$err_key} = 1;
5436                 }
5437                 return;
5438         }
5439         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
5440 }
5441
5442 package Git::SVN::Log;
5443 use strict;
5444 use warnings;
5445 use POSIX qw/strftime/;
5446 use Time::Local;
5447 use constant commit_log_separator => ('-' x 72) . "\n";
5448 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
5449             %rusers $show_commit $incremental/;
5450 my $l_fmt;
5451
5452 sub cmt_showable {
5453         my ($c) = @_;
5454         return 1 if defined $c->{r};
5455
5456         # big commit message got truncated by the 16k pretty buffer in rev-list
5457         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
5458                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
5459                 @{$c->{l}} = ();
5460                 my @log = command(qw/cat-file commit/, $c->{c});
5461
5462                 # shift off the headers
5463                 shift @log while ($log[0] ne '');
5464                 shift @log;
5465
5466                 # TODO: make $c->{l} not have a trailing newline in the future
5467                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
5468
5469                 (undef, $c->{r}, undef) = ::extract_metadata(
5470                                 (grep(/^git-svn-id: /, @log))[-1]);
5471         }
5472         return defined $c->{r};
5473 }
5474
5475 sub log_use_color {
5476         return $color || Git->repository->get_colorbool('color.diff');
5477 }
5478
5479 sub git_svn_log_cmd {
5480         my ($r_min, $r_max, @args) = @_;
5481         my $head = 'HEAD';
5482         my (@files, @log_opts);
5483         foreach my $x (@args) {
5484                 if ($x eq '--' || @files) {
5485                         push @files, $x;
5486                 } else {
5487                         if (::verify_ref("$x^0")) {
5488                                 $head = $x;
5489                         } else {
5490                                 push @log_opts, $x;
5491                         }
5492                 }
5493         }
5494
5495         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
5496         $gs ||= Git::SVN->_new;
5497         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
5498                    $gs->refname);
5499         push @cmd, '-r' unless $non_recursive;
5500         push @cmd, qw/--raw --name-status/ if $verbose;
5501         push @cmd, '--color' if log_use_color();
5502         push @cmd, @log_opts;
5503         if (defined $r_max && $r_max == $r_min) {
5504                 push @cmd, '--max-count=1';
5505                 if (my $c = $gs->rev_map_get($r_max)) {
5506                         push @cmd, $c;
5507                 }
5508         } elsif (defined $r_max) {
5509                 if ($r_max < $r_min) {
5510                         ($r_min, $r_max) = ($r_max, $r_min);
5511                 }
5512                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
5513                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
5514                 # If there are no commits in the range, both $c_max and $c_min
5515                 # will be undefined.  If there is at least 1 commit in the
5516                 # range, both will be defined.
5517                 return () if !defined $c_min || !defined $c_max;
5518                 if ($c_min eq $c_max) {
5519                         push @cmd, '--max-count=1', $c_min;
5520                 } else {
5521                         push @cmd, '--boundary', "$c_min..$c_max";
5522                 }
5523         }
5524         return (@cmd, @files);
5525 }
5526
5527 # adapted from pager.c
5528 sub config_pager {
5529         if (! -t *STDOUT) {
5530                 $ENV{GIT_PAGER_IN_USE} = 'false';
5531                 $pager = undef;
5532                 return;
5533         }
5534         chomp($pager = command_oneline(qw(var GIT_PAGER)));
5535         if ($pager eq 'cat') {
5536                 $pager = undef;
5537         }
5538         $ENV{GIT_PAGER_IN_USE} = defined($pager);
5539 }
5540
5541 sub run_pager {
5542         return unless defined $pager;
5543         pipe my ($rfd, $wfd) or return;
5544         defined(my $pid = fork) or ::fatal "Can't fork: $!";
5545         if (!$pid) {
5546                 open STDOUT, '>&', $wfd or
5547                                      ::fatal "Can't redirect to stdout: $!";
5548                 return;
5549         }
5550         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5551         $ENV{LESS} ||= 'FRSX';
5552         exec $pager or ::fatal "Can't run pager: $! ($pager)";
5553 }
5554
5555 sub format_svn_date {
5556         # some systmes don't handle or mishandle %z, so be creative.
5557         my $t = shift || time;
5558         my $gm = timelocal(gmtime($t));
5559         my $sign = qw( + + - )[ $t <=> $gm ];
5560         my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5561         return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5562 }
5563
5564 sub parse_git_date {
5565         my ($t, $tz) = @_;
5566         # Date::Parse isn't in the standard Perl distro :(
5567         if ($tz =~ s/^\+//) {
5568                 $t += tz_to_s_offset($tz);
5569         } elsif ($tz =~ s/^\-//) {
5570                 $t -= tz_to_s_offset($tz);
5571         }
5572         return $t;
5573 }
5574
5575 sub set_local_timezone {
5576         if (defined $TZ) {
5577                 $ENV{TZ} = $TZ;
5578         } else {
5579                 delete $ENV{TZ};
5580         }
5581 }
5582
5583 sub tz_to_s_offset {
5584         my ($tz) = @_;
5585         $tz =~ s/(\d\d)$//;
5586         return ($1 * 60) + ($tz * 3600);
5587 }
5588
5589 sub get_author_info {
5590         my ($dest, $author, $t, $tz) = @_;
5591         $author =~ s/(?:^\s*|\s*$)//g;
5592         $dest->{a_raw} = $author;
5593         my $au;
5594         if ($::_authors) {
5595                 $au = $rusers{$author} || undef;
5596         }
5597         if (!$au) {
5598                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5599         }
5600         $dest->{t} = $t;
5601         $dest->{tz} = $tz;
5602         $dest->{a} = $au;
5603         $dest->{t_utc} = parse_git_date($t, $tz);
5604 }
5605
5606 sub process_commit {
5607         my ($c, $r_min, $r_max, $defer) = @_;
5608         if (defined $r_min && defined $r_max) {
5609                 if ($r_min == $c->{r} && $r_min == $r_max) {
5610                         show_commit($c);
5611                         return 0;
5612                 }
5613                 return 1 if $r_min == $r_max;
5614                 if ($r_min < $r_max) {
5615                         # we need to reverse the print order
5616                         return 0 if (defined $limit && --$limit < 0);
5617                         push @$defer, $c;
5618                         return 1;
5619                 }
5620                 if ($r_min != $r_max) {
5621                         return 1 if ($r_min < $c->{r});
5622                         return 1 if ($r_max > $c->{r});
5623                 }
5624         }
5625         return 0 if (defined $limit && --$limit < 0);
5626         show_commit($c);
5627         return 1;
5628 }
5629
5630 sub show_commit {
5631         my $c = shift;
5632         if ($oneline) {
5633                 my $x = "\n";
5634                 if (my $l = $c->{l}) {
5635                         while ($l->[0] =~ /^\s*$/) { shift @$l }
5636                         $x = $l->[0];
5637                 }
5638                 $l_fmt ||= 'A' . length($c->{r});
5639                 print 'r',pack($l_fmt, $c->{r}),' | ';
5640                 print "$c->{c} | " if $show_commit;
5641                 print $x;
5642         } else {
5643                 show_commit_normal($c);
5644         }
5645 }
5646
5647 sub show_commit_changed_paths {
5648         my ($c) = @_;
5649         return unless $c->{changed};
5650         print "Changed paths:\n", @{$c->{changed}};
5651 }
5652
5653 sub show_commit_normal {
5654         my ($c) = @_;
5655         print commit_log_separator, "r$c->{r} | ";
5656         print "$c->{c} | " if $show_commit;
5657         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5658         my $nr_line = 0;
5659
5660         if (my $l = $c->{l}) {
5661                 while ($l->[$#$l] eq "\n" && $#$l > 0
5662                                           && $l->[($#$l - 1)] eq "\n") {
5663                         pop @$l;
5664                 }
5665                 $nr_line = scalar @$l;
5666                 if (!$nr_line) {
5667                         print "1 line\n\n\n";
5668                 } else {
5669                         if ($nr_line == 1) {
5670                                 $nr_line = '1 line';
5671                         } else {
5672                                 $nr_line .= ' lines';
5673                         }
5674                         print $nr_line, "\n";
5675                         show_commit_changed_paths($c);
5676                         print "\n";
5677                         print $_ foreach @$l;
5678                 }
5679         } else {
5680                 print "1 line\n";
5681                 show_commit_changed_paths($c);
5682                 print "\n";
5683
5684         }
5685         foreach my $x (qw/raw stat diff/) {
5686                 if ($c->{$x}) {
5687                         print "\n";
5688                         print $_ foreach @{$c->{$x}}
5689                 }
5690         }
5691 }
5692
5693 sub cmd_show_log {
5694         my (@args) = @_;
5695         my ($r_min, $r_max);
5696         my $r_last = -1; # prevent dupes
5697         set_local_timezone();
5698         if (defined $::_revision) {
5699                 if ($::_revision =~ /^(\d+):(\d+)$/) {
5700                         ($r_min, $r_max) = ($1, $2);
5701                 } elsif ($::_revision =~ /^\d+$/) {
5702                         $r_min = $r_max = $::_revision;
5703                 } else {
5704                         ::fatal "-r$::_revision is not supported, use ",
5705                                 "standard 'git log' arguments instead";
5706                 }
5707         }
5708
5709         config_pager();
5710         @args = git_svn_log_cmd($r_min, $r_max, @args);
5711         if (!@args) {
5712                 print commit_log_separator unless $incremental || $oneline;
5713                 return;
5714         }
5715         my $log = command_output_pipe(@args);
5716         run_pager();
5717         my (@k, $c, $d, $stat);
5718         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5719         while (<$log>) {
5720                 if (/^${esc_color}commit -?($::sha1_short)/o) {
5721                         my $cmt = $1;
5722                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5723                                 $r_last = $c->{r};
5724                                 process_commit($c, $r_min, $r_max, \@k) or
5725                                                                 goto out;
5726                         }
5727                         $d = undef;
5728                         $c = { c => $cmt };
5729                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5730                         get_author_info($c, $1, $2, $3);
5731                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5732                         # ignore
5733                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5734                         push @{$c->{raw}}, $_;
5735                 } elsif (/^${esc_color}[ACRMDT]\t/) {
5736                         # we could add $SVN->{svn_path} here, but that requires
5737                         # remote access at the moment (repo_path_split)...
5738                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
5739                         push @{$c->{changed}}, $_;
5740                 } elsif (/^${esc_color}diff /o) {
5741                         $d = 1;
5742                         push @{$c->{diff}}, $_;
5743                 } elsif ($d) {
5744                         push @{$c->{diff}}, $_;
5745                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5746                           $esc_color*[\+\-]*$esc_color$/x) {
5747                         $stat = 1;
5748                         push @{$c->{stat}}, $_;
5749                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5750                         push @{$c->{stat}}, $_;
5751                         $stat = undef;
5752                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
5753                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5754                 } elsif (s/^${esc_color}    //o) {
5755                         push @{$c->{l}}, $_;
5756                 }
5757         }
5758         if ($c && defined $c->{r} && $c->{r} != $r_last) {
5759                 $r_last = $c->{r};
5760                 process_commit($c, $r_min, $r_max, \@k);
5761         }
5762         if (@k) {
5763                 ($r_min, $r_max) = ($r_max, $r_min);
5764                 process_commit($_, $r_min, $r_max) foreach reverse @k;
5765         }
5766 out:
5767         close $log;
5768         print commit_log_separator unless $incremental || $oneline;
5769 }
5770
5771 sub cmd_blame {
5772         my $path = pop;
5773
5774         config_pager();
5775         run_pager();
5776
5777         my ($fh, $ctx, $rev);
5778
5779         if ($_git_format) {
5780                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5781                 while (my $line = <$fh>) {
5782                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5783                                 # Uncommitted edits show up as a rev ID of
5784                                 # all zeros, which we can't look up with
5785                                 # cmt_metadata
5786                                 if ($1 !~ /^0+$/) {
5787                                         (undef, $rev, undef) =
5788                                                 ::cmt_metadata($1);
5789                                         $rev = '0' if (!$rev);
5790                                 } else {
5791                                         $rev = '0';
5792                                 }
5793                                 $rev = sprintf('%-10s', $rev);
5794                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5795                         }
5796                         print $line;
5797                 }
5798         } else {
5799                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5800                                                   '--', $path);
5801                 my ($sha1);
5802                 my %authors;
5803                 my @buffer;
5804                 my %dsha; #distinct sha keys
5805
5806                 while (my $line = <$fh>) {
5807                         push @buffer, $line;
5808                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5809                                 $dsha{$1} = 1;
5810                         }
5811                 }
5812
5813                 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5814
5815                 foreach my $line (@buffer) {
5816                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5817                                 $rev = $s2r->{$1};
5818                                 $rev = '0' if (!$rev)
5819                         }
5820                         elsif ($line =~ /^author (.*)/) {
5821                                 $authors{$rev} = $1;
5822                                 $authors{$rev} =~ s/\s/_/g;
5823                         }
5824                         elsif ($line =~ /^\t(.*)$/) {
5825                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5826                         }
5827                 }
5828         }
5829         command_close_pipe($fh, $ctx);
5830 }
5831
5832 package Git::SVN::Migration;
5833 # these version numbers do NOT correspond to actual version numbers
5834 # of git nor git-svn.  They are just relative.
5835 #
5836 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5837 #
5838 # v1 layout: .git/$id/info/url, refs/remotes/$id
5839 #
5840 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5841 #
5842 # v3 layout: .git/svn/$id, refs/remotes/$id
5843 #            - info/url may remain for backwards compatibility
5844 #            - this is what we migrate up to this layout automatically,
5845 #            - this will be used by git svn init on single branches
5846 # v3.1 layout (auto migrated):
5847 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5848 #              for backwards compatibility
5849 #
5850 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5851 #            - this is only created for newly multi-init-ed
5852 #              repositories.  Similar in spirit to the
5853 #              --use-separate-remotes option in git-clone (now default)
5854 #            - we do not automatically migrate to this (following
5855 #              the example set by core git)
5856 #
5857 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5858 #            - newer, more-efficient format that uses 24-bytes per record
5859 #              with no filler space.
5860 #            - use xxd -c24 < .rev_map.$UUID to view and debug
5861 #            - This is a one-way migration, repositories updated to the
5862 #              new format will not be able to use old git-svn without
5863 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
5864 #              possible if noMetadata or useSvmProps are set; but should
5865 #              be no problem for users that use the (sensible) defaults.
5866 use strict;
5867 use warnings;
5868 use Carp qw/croak/;
5869 use File::Path qw/mkpath/;
5870 use File::Basename qw/dirname basename/;
5871 use vars qw/$_minimize/;
5872
5873 sub migrate_from_v0 {
5874         my $git_dir = $ENV{GIT_DIR};
5875         return undef unless -d $git_dir;
5876         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5877         my $migrated = 0;
5878         while (<$fh>) {
5879                 chomp;
5880                 my ($id, $orig_ref) = ($_, $_);
5881                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5882                 next unless -f "$git_dir/$id/info/url";
5883                 my $new_ref = "refs/remotes/$id";
5884                 if (::verify_ref("$new_ref^0")) {
5885                         print STDERR "W: $orig_ref is probably an old ",
5886                                      "branch used by an ancient version of ",
5887                                      "git-svn.\n",
5888                                      "However, $new_ref also exists.\n",
5889                                      "We will not be able ",
5890                                      "to use this branch until this ",
5891                                      "ambiguity is resolved.\n";
5892                         next;
5893                 }
5894                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5895                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5896                 command_noisy('update-ref', $new_ref, $orig_ref);
5897                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5898                 $migrated++;
5899         }
5900         command_close_pipe($fh, $ctx);
5901         print STDERR "Done migrating from v0 layout...\n" if $migrated;
5902         $migrated;
5903 }
5904
5905 sub migrate_from_v1 {
5906         my $git_dir = $ENV{GIT_DIR};
5907         my $migrated = 0;
5908         return $migrated unless -d $git_dir;
5909         my $svn_dir = "$git_dir/svn";
5910
5911         # just in case somebody used 'svn' as their $id at some point...
5912         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5913
5914         print STDERR "Migrating from a git-svn v1 layout...\n";
5915         mkpath([$svn_dir]);
5916         print STDERR "Data from a previous version of git-svn exists, but\n\t",
5917                      "$svn_dir\n\t(required for this version ",
5918                      "($::VERSION) of git-svn) does not exist.\n";
5919         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5920         while (<$fh>) {
5921                 my $x = $_;
5922                 next unless $x =~ s#^refs/remotes/##;
5923                 chomp $x;
5924                 next unless -f "$git_dir/$x/info/url";
5925                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5926                 next unless $u;
5927                 my $dn = dirname("$git_dir/svn/$x");
5928                 mkpath([$dn]) unless -d $dn;
5929                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5930                         mkpath(["$git_dir/svn/svn"]);
5931                         print STDERR " - $git_dir/$x/info => ",
5932                                         "$git_dir/svn/$x/info\n";
5933                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5934                                croak "$!: $x";
5935                         # don't worry too much about these, they probably
5936                         # don't exist with repos this old (save for index,
5937                         # and we can easily regenerate that)
5938                         foreach my $f (qw/unhandled.log index .rev_db/) {
5939                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5940                         }
5941                 } else {
5942                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5943                         rename "$git_dir/$x", "$git_dir/svn/$x" or
5944                                croak "$!: $x";
5945                 }
5946                 $migrated++;
5947         }
5948         command_close_pipe($fh, $ctx);
5949         print STDERR "Done migrating from a git-svn v1 layout\n";
5950         $migrated;
5951 }
5952
5953 sub read_old_urls {
5954         my ($l_map, $pfx, $path) = @_;
5955         my @dir;
5956         foreach (<$path/*>) {
5957                 if (-r "$_/info/url") {
5958                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5959                         my $ref_id = $pfx . basename $_;
5960                         my $url = ::file_to_s("$_/info/url");
5961                         $l_map->{$ref_id} = $url;
5962                 } elsif (-d $_) {
5963                         push @dir, $_;
5964                 }
5965         }
5966         foreach (@dir) {
5967                 my $x = $_;
5968                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5969                 read_old_urls($l_map, $x, $_);
5970         }
5971 }
5972
5973 sub migrate_from_v2 {
5974         my @cfg = command(qw/config -l/);
5975         return if grep /^svn-remote\..+\.url=/, @cfg;
5976         my %l_map;
5977         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5978         my $migrated = 0;
5979
5980         foreach my $ref_id (sort keys %l_map) {
5981                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5982                 if ($@) {
5983                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5984                 }
5985                 $migrated++;
5986         }
5987         $migrated;
5988 }
5989
5990 sub minimize_connections {
5991         my $r = Git::SVN::read_all_remotes();
5992         my $new_urls = {};
5993         my $root_repos = {};
5994         foreach my $repo_id (keys %$r) {
5995                 my $url = $r->{$repo_id}->{url} or next;
5996                 my $fetch = $r->{$repo_id}->{fetch} or next;
5997                 my $ra = Git::SVN::Ra->new($url);
5998
5999                 # skip existing cases where we already connect to the root
6000                 if (($ra->{url} eq $ra->{repos_root}) ||
6001                     ($ra->{repos_root} eq $repo_id)) {
6002                         $root_repos->{$ra->{url}} = $repo_id;
6003                         next;
6004                 }
6005
6006                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
6007                 my $root_path = $ra->{url};
6008                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
6009                 foreach my $path (keys %$fetch) {
6010                         my $ref_id = $fetch->{$path};
6011                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
6012
6013                         # make sure we can read when connecting to
6014                         # a higher level of a repository
6015                         my ($last_rev, undef) = $gs->last_rev_commit;
6016                         if (!defined $last_rev) {
6017                                 $last_rev = eval {
6018                                         $root_ra->get_latest_revnum;
6019                                 };
6020                                 next if $@;
6021                         }
6022                         my $new = $root_path;
6023                         $new .= length $path ? "/$path" : '';
6024                         eval {
6025                                 $root_ra->get_log([$new], $last_rev, $last_rev,
6026                                                   0, 0, 1, sub { });
6027                         };
6028                         next if $@;
6029                         $new_urls->{$ra->{repos_root}}->{$new} =
6030                                 { ref_id => $ref_id,
6031                                   old_repo_id => $repo_id,
6032                                   old_path => $path };
6033                 }
6034         }
6035
6036         my @emptied;
6037         foreach my $url (keys %$new_urls) {
6038                 # see if we can re-use an existing [svn-remote "repo_id"]
6039                 # instead of creating a(n ugly) new section:
6040                 my $repo_id = $root_repos->{$url} || $url;
6041
6042                 my $fetch = $new_urls->{$url};
6043                 foreach my $path (keys %$fetch) {
6044                         my $x = $fetch->{$path};
6045                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
6046                         my $pfx = "svn-remote.$x->{old_repo_id}";
6047
6048                         my $old_fetch = quotemeta("$x->{old_path}:".
6049                                                   "$x->{ref_id}");
6050                         command_noisy(qw/config --unset/,
6051                                       "$pfx.fetch", '^'. $old_fetch . '$');
6052                         delete $r->{$x->{old_repo_id}}->
6053                                {fetch}->{$x->{old_path}};
6054                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
6055                                 command_noisy(qw/config --unset/,
6056                                               "$pfx.url");
6057                                 push @emptied, $x->{old_repo_id}
6058                         }
6059                 }
6060         }
6061         if (@emptied) {
6062                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
6063                 print STDERR <<EOF;
6064 The following [svn-remote] sections in your config file ($file) are empty
6065 and can be safely removed:
6066 EOF
6067                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
6068         }
6069 }
6070
6071 sub migration_check {
6072         migrate_from_v0();
6073         migrate_from_v1();
6074         migrate_from_v2();
6075         minimize_connections() if $_minimize;
6076 }
6077
6078 package Git::IndexInfo;
6079 use strict;
6080 use warnings;
6081 use Git qw/command_input_pipe command_close_pipe/;
6082
6083 sub new {
6084         my ($class) = @_;
6085         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
6086         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
6087 }
6088
6089 sub remove {
6090         my ($self, $path) = @_;
6091         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
6092                 return ++$self->{nr};
6093         }
6094         undef;
6095 }
6096
6097 sub update {
6098         my ($self, $mode, $hash, $path) = @_;
6099         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
6100                 return ++$self->{nr};
6101         }
6102         undef;
6103 }
6104
6105 sub DESTROY {
6106         my ($self) = @_;
6107         command_close_pipe($self->{gui}, $self->{ctx});
6108 }
6109
6110 package Git::SVN::GlobSpec;
6111 use strict;
6112 use warnings;
6113
6114 sub new {
6115         my ($class, $glob, $pattern_ok) = @_;
6116         my $re = $glob;
6117         $re =~ s!/+$!!g; # no need for trailing slashes
6118         my (@left, @right, @patterns);
6119         my $state = "left";
6120         my $die_msg = "Only one set of wildcard directories " .
6121                                 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
6122         for my $part (split(m|/|, $glob)) {
6123                 if ($part =~ /\*/ && $part ne "*") {
6124                         die "Invalid pattern in '$glob': $part\n";
6125                 } elsif ($pattern_ok && $part =~ /[{}]/ &&
6126                          $part !~ /^\{[^{}]+\}/) {
6127                         die "Invalid pattern in '$glob': $part\n";
6128                 }
6129                 if ($part eq "*") {
6130                         die $die_msg if $state eq "right";
6131                         $state = "pattern";
6132                         push(@patterns, "[^/]*");
6133                 } elsif ($pattern_ok && $part =~ /^\{(.*)\}$/) {
6134                         die $die_msg if $state eq "right";
6135                         $state = "pattern";
6136                         my $p = quotemeta($1);
6137                         $p =~ s/\\,/|/g;
6138                         push(@patterns, "(?:$p)");
6139                 } else {
6140                         if ($state eq "left") {
6141                                 push(@left, $part);
6142                         } else {
6143                                 push(@right, $part);
6144                                 $state = "right";
6145                         }
6146                 }
6147         }
6148         my $depth = @patterns;
6149         if ($depth == 0) {
6150                 die "One '*' is needed in glob: '$glob'\n";
6151         }
6152         my $left = join('/', @left);
6153         my $right = join('/', @right);
6154         $re = join('/', @patterns);
6155         $re = join('\/',
6156                    grep(length, quotemeta($left), "($re)", quotemeta($right)));
6157         my $left_re = qr/^\/\Q$left\E(\/|$)/;
6158         bless { left => $left, right => $right, left_regex => $left_re,
6159                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
6160 }
6161
6162 sub full_path {
6163         my ($self, $path) = @_;
6164         return (length $self->{left} ? "$self->{left}/" : '') .
6165                $path . (length $self->{right} ? "/$self->{right}" : '');
6166 }
6167
6168 __END__
6169
6170 Data structures:
6171
6172
6173 $remotes = { # returned by read_all_remotes()
6174         'svn' => {
6175                 # svn-remote.svn.url=https://svn.musicpd.org
6176                 url => 'https://svn.musicpd.org',
6177                 # svn-remote.svn.fetch=mpd/trunk:trunk
6178                 fetch => {
6179                         'mpd/trunk' => 'trunk',
6180                 },
6181                 # svn-remote.svn.tags=mpd/tags/*:tags/*
6182                 tags => {
6183                         path => {
6184                                 left => 'mpd/tags',
6185                                 right => '',
6186                                 regex => qr!mpd/tags/([^/]+)$!,
6187                                 glob => 'tags/*',
6188                         },
6189                         ref => {
6190                                 left => 'tags',
6191                                 right => '',
6192                                 regex => qr!tags/([^/]+)$!,
6193                                 glob => 'tags/*',
6194                         },
6195                 }
6196         }
6197 };
6198
6199 $log_entry hashref as returned by libsvn_log_entry()
6200 {
6201         log => 'whitespace-formatted log entry
6202 ',                                              # trailing newline is preserved
6203         revision => '8',                        # integer
6204         date => '2004-02-24T17:01:44.108345Z',  # commit date
6205         author => 'committer name'
6206 };
6207
6208
6209 # this is generated by generate_diff();
6210 @mods = array of diff-index line hashes, each element represents one line
6211         of diff-index output
6212
6213 diff-index line ($m hash)
6214 {
6215         mode_a => first column of diff-index output, no leading ':',
6216         mode_b => second column of diff-index output,
6217         sha1_b => sha1sum of the final blob,
6218         chg => change type [MCRADT],
6219         file_a => original file name of a file (iff chg is 'C' or 'R')
6220         file_b => new/current file name of a file (any chg)
6221 }
6222 ;
6223
6224 # retval of read_url_paths{,_all}();
6225 $l_map = {
6226         # repository root url
6227         'https://svn.musicpd.org' => {
6228                 # repository path               # GIT_SVN_ID
6229                 'mpd/trunk'             =>      'trunk',
6230                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
6231         },
6232 }
6233
6234 Notes:
6235         I don't trust the each() function on unless I created %hash myself
6236         because the internal iterator may not have started at base.