git.oblomov.eu Git - git/blob - contrib/mw-to-git/git-remote-mediawiki.perl

   1 #! /usr/bin/perl
   2
   3 # Copyright (C) 2011
   4 #     Jérémie Nikaes <jeremie.nikaes@ensimag.imag.fr>
   5 #     Arnaud Lacurie <arnaud.lacurie@ensimag.imag.fr>
   6 #     Claire Fousse <claire.fousse@ensimag.imag.fr>
   7 #     David Amouyal <david.amouyal@ensimag.imag.fr>
   8 #     Matthieu Moy <matthieu.moy@grenoble-inp.fr>
   9 # License: GPL v2 or later
  10
  11 # Gateway between Git and MediaWiki.
  12 # Documentation & bugtracker: https://github.com/moy/Git-Mediawiki/
  13
  14 use strict;
  15 use MediaWiki::API;
  16 use Git;
  17 use DateTime::Format::ISO8601;
  18 use warnings;
  19
  20 # By default, use UTF-8 to communicate with Git and the user
  21 binmode STDERR, ":encoding(UTF-8)";
  22 binmode STDOUT, ":encoding(UTF-8)";
  23
  24 use URI::Escape;
  25 use IPC::Open2;
  26
  27 # Mediawiki filenames can contain forward slashes. This variable decides by which pattern they should be replaced
  28 use constant SLASH_REPLACEMENT => "%2F";
  29
  30 # It's not always possible to delete pages (may require some
  31 # privileges). Deleted pages are replaced with this content.
  32 use constant DELETED_CONTENT => "[[Category:Deleted]]\n";
  33
  34 # It's not possible to create empty pages. New empty files in Git are
  35 # sent with this content instead.
  36 use constant EMPTY_CONTENT => "<!-- empty page -->\n";
  37
  38 # used to reflect file creation or deletion in diff.
  39 use constant NULL_SHA1 => "0000000000000000000000000000000000000000";
  40
  41 # Used on Git's side to reflect empty edit messages on the wiki
  42 use constant EMPTY_MESSAGE => '*Empty MediaWiki Message*';
  43
  44 my $remotename = $ARGV[0];
  45 my $url = $ARGV[1];
  46
  47 # Accept both space-separated and multiple keys in config file.
  48 # Spaces should be written as _ anyway because we'll use chomp.
  49 my @tracked_pages = split(/[ \n]/, run_git("config --get-all remote.". $remotename .".pages"));
  50 chomp(@tracked_pages);
  51
  52 # Just like @tracked_pages, but for MediaWiki categories.
  53 my @tracked_categories = split(/[ \n]/, run_git("config --get-all remote.". $remotename .".categories"));
  54 chomp(@tracked_categories);
  55
  56 # Import media files on pull
  57 my $import_media = run_git("config --get --bool remote.". $remotename .".mediaimport");
  58 chomp($import_media);
  59 $import_media = ($import_media eq "true");
  60
  61 # Export media files on push
  62 my $export_media = run_git("config --get --bool remote.". $remotename .".mediaexport");
  63 chomp($export_media);
  64 $export_media = !($export_media eq "false");
  65
  66 my $wiki_login = run_git("config --get remote.". $remotename .".mwLogin");
  67 # Note: mwPassword is discourraged. Use the credential system instead.
  68 my $wiki_passwd = run_git("config --get remote.". $remotename .".mwPassword");
  69 my $wiki_domain = run_git("config --get remote.". $remotename .".mwDomain");
  70 chomp($wiki_login);
  71 chomp($wiki_passwd);
  72 chomp($wiki_domain);
  73
  74 # Import only last revisions (both for clone and fetch)
  75 my $shallow_import = run_git("config --get --bool remote.". $remotename .".shallow");
  76 chomp($shallow_import);
  77 $shallow_import = ($shallow_import eq "true");
  78
  79 # Fetch (clone and pull) by revisions instead of by pages. This behavior
  80 # is more efficient when we have a wiki with lots of pages and we fetch
  81 # the revisions quite often so that they concern only few pages.
  82 # Possible values:
  83 # - by_rev: perform one query per new revision on the remote wiki
  84 # - by_page: query each tracked page for new revision
  85 my $fetch_strategy = run_git("config --get remote.$remotename.fetchStrategy");
  86 unless ($fetch_strategy) {
  87         $fetch_strategy = run_git("config --get mediawiki.fetchStrategy");
  88 }
  89 chomp($fetch_strategy);
  90 unless ($fetch_strategy) {
  91         $fetch_strategy = "by_page";
  92 }
  93
  94 # Remember the timestamp corresponding to a revision id.
  95 my %basetimestamps;
  96
  97 # Dumb push: don't update notes and mediawiki ref to reflect the last push.
  98 #
  99 # Configurable with mediawiki.dumbPush, or per-remote with
 100 # remote.<remotename>.dumbPush.
 101 #
 102 # This means the user will have to re-import the just-pushed
 103 # revisions. On the other hand, this means that the Git revisions
 104 # corresponding to MediaWiki revisions are all imported from the wiki,
 105 # regardless of whether they were initially created in Git or from the
 106 # web interface, hence all users will get the same history (i.e. if
 107 # the push from Git to MediaWiki loses some information, everybody
 108 # will get the history with information lost). If the import is
 109 # deterministic, this means everybody gets the same sha1 for each
 110 # MediaWiki revision.
 111 my $dumb_push = run_git("config --get --bool remote.$remotename.dumbPush");
 112 unless ($dumb_push) {
 113         $dumb_push = run_git("config --get --bool mediawiki.dumbPush");
 114 }
 115 chomp($dumb_push);
 116 $dumb_push = ($dumb_push eq "true");
 117
 118 my $wiki_name = $url;
 119 $wiki_name =~ s{[^/]*://}{};
 120 # If URL is like http://user:password@example.com/, we clearly don't
 121 # want the password in $wiki_name. While we're there, also remove user
 122 # and '@' sign, to avoid author like MWUser@HTTPUser@host.com
 123 $wiki_name =~ s/^.*@//;
 124
 125 # Commands parser
 126 my @cmd;
 127 while (<STDIN>) {
 128         chomp;
 129         @cmd = split(/ /);
 130         if (defined($cmd[0])) {
 131                 # Line not blank
 132                 if ($cmd[0] eq "capabilities") {
 133                         die("Too many arguments for capabilities\n") if (defined($cmd[1]));
 134                         mw_capabilities();
 135                 } elsif ($cmd[0] eq "list") {
 136                         die("Too many arguments for list\n") if (defined($cmd[2]));
 137                         mw_list($cmd[1]);
 138                 } elsif ($cmd[0] eq "import") {
 139                         die("Invalid arguments for import\n") if ($cmd[1] eq "" || defined($cmd[2]));
 140                         mw_import($cmd[1]);
 141                 } elsif ($cmd[0] eq "option") {
 142                         die("Too many arguments for option\n") if ($cmd[1] eq "" || $cmd[2] eq "" || defined($cmd[3]));
 143                         mw_option($cmd[1],$cmd[2]);
 144                 } elsif ($cmd[0] eq "push") {
 145                         mw_push($cmd[1]);
 146                 } else {
 147                         print STDERR "Unknown command. Aborting...\n";
 148                         last;
 149                 }
 150         } else {
 151                 # blank line: we should terminate
 152                 last;
 153         }
 154
 155         BEGIN { $| = 1 } # flush STDOUT, to make sure the previous
 156                          # command is fully processed.
 157 }
 158
 159 ########################## Functions ##############################
 160
 161 # MediaWiki API instance, created lazily.
 162 my $mediawiki;
 163
 164 sub mw_connect_maybe {
 165         if ($mediawiki) {
 166                 return;
 167         }
 168         $mediawiki = MediaWiki::API->new;
 169         $mediawiki->{config}->{api_url} = "$url/api.php";
 170         if ($wiki_login) {
 171                 my %credential = (
 172                         'url' => $url,
 173                         'username' => $wiki_login,
 174                         'password' => $wiki_passwd
 175                 );
 176                 Git::credential(\%credential);
 177                 my $request = {lgname => $credential{username},
 178                                lgpassword => $credential{password},
 179                                lgdomain => $wiki_domain};
 180                 if ($mediawiki->login($request)) {
 181                         Git::credential(\%credential, 'approve');
 182                         print STDERR "Logged in mediawiki user \"$credential{username}\".\n";
 183                 } else {
 184                         print STDERR "Failed to log in mediawiki user \"$credential{username}\" on $url\n";
 185                         print STDERR "  (error " .
 186                                 $mediawiki->{error}->{code} . ': ' .
 187                                 $mediawiki->{error}->{details} . ")\n";
 188                         Git::credential(\%credential, 'reject');
 189                         exit 1;
 190                 }
 191         }
 192         return;
 193 }
 194
 195 sub fatal_mw_error {
 196         my $action = shift;
 197         print STDERR "fatal: could not $action.\n";
 198         print STDERR "fatal: '$url' does not appear to be a mediawiki\n";
 199         if ($url =~ /^https/) {
 200                 print STDERR "fatal: make sure '$url/api.php' is a valid page\n";
 201                 print STDERR "fatal: and the SSL certificate is correct.\n";
 202         } else {
 203                 print STDERR "fatal: make sure '$url/api.php' is a valid page.\n";
 204         }
 205         print STDERR "fatal: (error " .
 206             $mediawiki->{error}->{code} . ': ' .
 207             $mediawiki->{error}->{details} . ")\n";
 208         exit 1;
 209 }
 210
 211 ## Functions for listing pages on the remote wiki
 212 sub get_mw_tracked_pages {
 213         my $pages = shift;
 214         get_mw_page_list(\@tracked_pages, $pages);
 215         return;
 216 }
 217
 218 sub get_mw_page_list {
 219         my $page_list = shift;
 220         my $pages = shift;
 221         my @some_pages = @$page_list;
 222         while (@some_pages) {
 223                 my $last_page = 50;
 224                 if ($#some_pages < $last_page) {
 225                         $last_page = $#some_pages;
 226                 }
 227                 my @slice = @some_pages[0..$last_page];
 228                 get_mw_first_pages(\@slice, $pages);
 229                 @some_pages = @some_pages[51..$#some_pages];
 230         }
 231         return;
 232 }
 233
 234 sub get_mw_tracked_categories {
 235         my $pages = shift;
 236         foreach my $category (@tracked_categories) {
 237                 if (index($category, ':') < 0) {
 238                         # Mediawiki requires the Category
 239                         # prefix, but let's not force the user
 240                         # to specify it.
 241                         $category = "Category:" . $category;
 242                 }
 243                 my $mw_pages = $mediawiki->list( {
 244                         action => 'query',
 245                         list => 'categorymembers',
 246                         cmtitle => $category,
 247                         cmlimit => 'max' } )
 248                         || die $mediawiki->{error}->{code} . ': '
 249                                 . $mediawiki->{error}->{details} . "\n";
 250                 foreach my $page (@{$mw_pages}) {
 251                         $pages->{$page->{title}} = $page;
 252                 }
 253         }
 254         return;
 255 }
 256
 257 sub get_mw_all_pages {
 258         my $pages = shift;
 259         # No user-provided list, get the list of pages from the API.
 260         my $mw_pages = $mediawiki->list({
 261                 action => 'query',
 262                 list => 'allpages',
 263                 aplimit => 'max'
 264         });
 265         if (!defined($mw_pages)) {
 266                 fatal_mw_error("get the list of wiki pages");
 267         }
 268         foreach my $page (@{$mw_pages}) {
 269                 $pages->{$page->{title}} = $page;
 270         }
 271         return;
 272 }
 273
 274 # queries the wiki for a set of pages. Meant to be used within a loop
 275 # querying the wiki for slices of page list.
 276 sub get_mw_first_pages {
 277         my $some_pages = shift;
 278         my @some_pages = @{$some_pages};
 279
 280         my $pages = shift;
 281
 282         # pattern 'page1|page2|...' required by the API
 283         my $titles = join('|', @some_pages);
 284
 285         my $mw_pages = $mediawiki->api({
 286                 action => 'query',
 287                 titles => $titles,
 288         });
 289         if (!defined($mw_pages)) {
 290                 fatal_mw_error("query the list of wiki pages");
 291         }
 292         while (my ($id, $page) = each(%{$mw_pages->{query}->{pages}})) {
 293                 if ($id < 0) {
 294                         print STDERR "Warning: page $page->{title} not found on wiki\n";
 295                 } else {
 296                         $pages->{$page->{title}} = $page;
 297                 }
 298         }
 299         return;
 300 }
 301
 302 # Get the list of pages to be fetched according to configuration.
 303 sub get_mw_pages {
 304         mw_connect_maybe();
 305
 306         print STDERR "Listing pages on remote wiki...\n";
 307
 308         my %pages; # hash on page titles to avoid duplicates
 309         my $user_defined;
 310         if (@tracked_pages) {
 311                 $user_defined = 1;
 312                 # The user provided a list of pages titles, but we
 313                 # still need to query the API to get the page IDs.
 314                 get_mw_tracked_pages(\%pages);
 315         }
 316         if (@tracked_categories) {
 317                 $user_defined = 1;
 318                 get_mw_tracked_categories(\%pages);
 319         }
 320         if (!$user_defined) {
 321                 get_mw_all_pages(\%pages);
 322         }
 323         if ($import_media) {
 324                 print STDERR "Getting media files for selected pages...\n";
 325                 if ($user_defined) {
 326                         get_linked_mediafiles(\%pages);
 327                 } else {
 328                         get_all_mediafiles(\%pages);
 329                 }
 330         }
 331         print STDERR (scalar keys %pages) . " pages found.\n";
 332         return %pages;
 333 }
 334
 335 # usage: $out = run_git("command args");
 336 #        $out = run_git("command args", "raw"); # don't interpret output as UTF-8.
 337 sub run_git {
 338         my $args = shift;
 339         my $encoding = (shift || "encoding(UTF-8)");
 340         open(my $git, "-|:$encoding", "git " . $args);
 341         my $res = do { local $/; <$git> };
 342         close($git);
 343
 344         return $res;
 345 }
 346
 347
 348 sub get_all_mediafiles {
 349         my $pages = shift;
 350         # Attach list of all pages for media files from the API,
 351         # they are in a different namespace, only one namespace
 352         # can be queried at the same moment
 353         my $mw_pages = $mediawiki->list({
 354                 action => 'query',
 355                 list => 'allpages',
 356                 apnamespace => get_mw_namespace_id("File"),
 357                 aplimit => 'max'
 358         });
 359         if (!defined($mw_pages)) {
 360                 print STDERR "fatal: could not get the list of pages for media files.\n";
 361                 print STDERR "fatal: '$url' does not appear to be a mediawiki\n";
 362                 print STDERR "fatal: make sure '$url/api.php' is a valid page.\n";
 363                 exit 1;
 364         }
 365         foreach my $page (@{$mw_pages}) {
 366                 $pages->{$page->{title}} = $page;
 367         }
 368         return;
 369 }
 370
 371 sub get_linked_mediafiles {
 372         my $pages = shift;
 373         my @titles = map { $_->{title} } values(%{$pages});
 374
 375         # The query is split in small batches because of the MW API limit of
 376         # the number of links to be returned (500 links max).
 377         my $batch = 10;
 378         while (@titles) {
 379                 if ($#titles < $batch) {
 380                         $batch = $#titles;
 381                 }
 382                 my @slice = @titles[0..$batch];
 383
 384                 # pattern 'page1|page2|...' required by the API
 385                 my $mw_titles = join('|', @slice);
 386
 387                 # Media files could be included or linked from
 388                 # a page, get all related
 389                 my $query = {
 390                         action => 'query',
 391                         prop => 'links|images',
 392                         titles => $mw_titles,
 393                         plnamespace => get_mw_namespace_id("File"),
 394                         pllimit => 'max'
 395                 };
 396                 my $result = $mediawiki->api($query);
 397
 398                 while (my ($id, $page) = each(%{$result->{query}->{pages}})) {
 399                         my @media_titles;
 400                         if (defined($page->{links})) {
 401                                 my @link_titles
 402                                     = map { $_->{title} } @{$page->{links}};
 403                                 push(@media_titles, @link_titles);
 404                         }
 405                         if (defined($page->{images})) {
 406                                 my @image_titles
 407                                     = map { $_->{title} } @{$page->{images}};
 408                                 push(@media_titles, @image_titles);
 409                         }
 410                         if (@media_titles) {
 411                                 get_mw_page_list(\@media_titles, $pages);
 412                         }
 413                 }
 414
 415                 @titles = @titles[($batch+1)..$#titles];
 416         }
 417         return;
 418 }
 419
 420 sub get_mw_mediafile_for_page_revision {
 421         # Name of the file on Wiki, with the prefix.
 422         my $filename = shift;
 423         my $timestamp = shift;
 424         my %mediafile;
 425
 426         # Search if on a media file with given timestamp exists on
 427         # MediaWiki. In that case download the file.
 428         my $query = {
 429                 action => 'query',
 430                 prop => 'imageinfo',
 431                 titles => "File:" . $filename,
 432                 iistart => $timestamp,
 433                 iiend => $timestamp,
 434                 iiprop => 'timestamp|archivename|url',
 435                 iilimit => 1
 436         };
 437         my $result = $mediawiki->api($query);
 438
 439         my ($fileid, $file) = each( %{$result->{query}->{pages}} );
 440         # If not defined it means there is no revision of the file for
 441         # given timestamp.
 442         if (defined($file->{imageinfo})) {
 443                 $mediafile{title} = $filename;
 444
 445                 my $fileinfo = pop(@{$file->{imageinfo}});
 446                 $mediafile{timestamp} = $fileinfo->{timestamp};
 447                 # Mediawiki::API's download function doesn't support https URLs
 448                 # and can't download old versions of files.
 449                 print STDERR "\tDownloading file $mediafile{title}, version $mediafile{timestamp}\n";
 450                 $mediafile{content} = download_mw_mediafile($fileinfo->{url});
 451         }
 452         return %mediafile;
 453 }
 454
 455 sub download_mw_mediafile {
 456         my $download_url = shift;
 457
 458         my $response = $mediawiki->{ua}->get($download_url);
 459         if ($response->code == 200) {
 460                 return $response->decoded_content;
 461         } else {
 462                 print STDERR "Error downloading mediafile from :\n";
 463                 print STDERR "URL: $download_url\n";
 464                 print STDERR "Server response: " . $response->code . " " . $response->message . "\n";
 465                 exit 1;
 466         }
 467 }
 468
 469 sub get_last_local_revision {
 470         # Get note regarding last mediawiki revision
 471         my $note = run_git("notes --ref=$remotename/mediawiki show refs/mediawiki/$remotename/master 2>/dev/null");
 472         my @note_info = split(/ /, $note);
 473
 474         my $lastrevision_number;
 475         if (!(defined($note_info[0]) && $note_info[0] eq "mediawiki_revision:")) {
 476                 print STDERR "No previous mediawiki revision found";
 477                 $lastrevision_number = 0;
 478         } else {
 479                 # Notes are formatted : mediawiki_revision: #number
 480                 $lastrevision_number = $note_info[1];
 481                 chomp($lastrevision_number);
 482                 print STDERR "Last local mediawiki revision found is $lastrevision_number";
 483         }
 484         return $lastrevision_number;
 485 }
 486
 487 # Get the last remote revision without taking in account which pages are
 488 # tracked or not. This function makes a single request to the wiki thus
 489 # avoid a loop onto all tracked pages. This is useful for the fetch-by-rev
 490 # option.
 491 sub get_last_global_remote_rev {
 492         mw_connect_maybe();
 493
 494         my $query = {
 495                 action => 'query',
 496                 list => 'recentchanges',
 497                 prop => 'revisions',
 498                 rclimit => '1',
 499                 rcdir => 'older',
 500         };
 501         my $result = $mediawiki->api($query);
 502         return $result->{query}->{recentchanges}[0]->{revid};
 503 }
 504
 505 # Get the last remote revision concerning the tracked pages and the tracked
 506 # categories.
 507 sub get_last_remote_revision {
 508         mw_connect_maybe();
 509
 510         my %pages_hash = get_mw_pages();
 511         my @pages = values(%pages_hash);
 512
 513         my $max_rev_num = 0;
 514
 515         print STDERR "Getting last revision id on tracked pages...\n";
 516
 517         foreach my $page (@pages) {
 518                 my $id = $page->{pageid};
 519
 520                 my $query = {
 521                         action => 'query',
 522                         prop => 'revisions',
 523                         rvprop => 'ids|timestamp',
 524                         pageids => $id,
 525                 };
 526
 527                 my $result = $mediawiki->api($query);
 528
 529                 my $lastrev = pop(@{$result->{query}->{pages}->{$id}->{revisions}});
 530
 531                 $basetimestamps{$lastrev->{revid}} = $lastrev->{timestamp};
 532
 533                 $max_rev_num = ($lastrev->{revid} > $max_rev_num ? $lastrev->{revid} : $max_rev_num);
 534         }
 535
 536         print STDERR "Last remote revision found is $max_rev_num.\n";
 537         return $max_rev_num;
 538 }
 539
 540 # Clean content before sending it to MediaWiki
 541 sub mediawiki_clean {
 542         my $string = shift;
 543         my $page_created = shift;
 544         # Mediawiki does not allow blank space at the end of a page and ends with a single \n.
 545         # This function right trims a string and adds a \n at the end to follow this rule
 546         $string =~ s/\s+$//;
 547         if ($string eq "" && $page_created) {
 548                 # Creating empty pages is forbidden.
 549                 $string = EMPTY_CONTENT;
 550         }
 551         return $string."\n";
 552 }
 553
 554 # Filter applied on MediaWiki data before adding them to Git
 555 sub mediawiki_smudge {
 556         my $string = shift;
 557         if ($string eq EMPTY_CONTENT) {
 558                 $string = "";
 559         }
 560         # This \n is important. This is due to mediawiki's way to handle end of files.
 561         return $string."\n";
 562 }
 563
 564 sub mediawiki_clean_filename {
 565         my $filename = shift;
 566         $filename =~ s{@{[SLASH_REPLACEMENT]}}{/}g;
 567         # [, ], |, {, and } are forbidden by MediaWiki, even URL-encoded.
 568         # Do a variant of URL-encoding, i.e. looks like URL-encoding,
 569         # but with _ added to prevent MediaWiki from thinking this is
 570         # an actual special character.
 571         $filename =~ s/[\[\]\{\}\|]/sprintf("_%%_%x", ord($&))/ge;
 572         # If we use the uri escape before
 573         # we should unescape here, before anything
 574
 575         return $filename;
 576 }
 577
 578 sub mediawiki_smudge_filename {
 579         my $filename = shift;
 580         $filename =~ s{/}{@{[SLASH_REPLACEMENT]}}g;
 581         $filename =~ s/ /_/g;
 582         # Decode forbidden characters encoded in mediawiki_clean_filename
 583         $filename =~ s/_%_([0-9a-fA-F][0-9a-fA-F])/sprintf("%c", hex($1))/ge;
 584         return $filename;
 585 }
 586
 587 sub literal_data {
 588         my ($content) = @_;
 589         print STDOUT "data ", bytes::length($content), "\n", $content;
 590         return;
 591 }
 592
 593 sub literal_data_raw {
 594         # Output possibly binary content.
 595         my ($content) = @_;
 596         # Avoid confusion between size in bytes and in characters
 597         utf8::downgrade($content);
 598         binmode STDOUT, ":raw";
 599         print STDOUT "data ", bytes::length($content), "\n", $content;
 600         binmode STDOUT, ":encoding(UTF-8)";
 601         return;
 602 }
 603
 604 sub mw_capabilities {
 605         # Revisions are imported to the private namespace
 606         # refs/mediawiki/$remotename/ by the helper and fetched into
 607         # refs/remotes/$remotename later by fetch.
 608         print STDOUT "refspec refs/heads/*:refs/mediawiki/$remotename/*\n";
 609         print STDOUT "import\n";
 610         print STDOUT "list\n";
 611         print STDOUT "push\n";
 612         print STDOUT "\n";
 613         return;
 614 }
 615
 616 sub mw_list {
 617         # MediaWiki do not have branches, we consider one branch arbitrarily
 618         # called master, and HEAD pointing to it.
 619         print STDOUT "? refs/heads/master\n";
 620         print STDOUT "\@refs/heads/master HEAD\n";
 621         print STDOUT "\n";
 622         return;
 623 }
 624
 625 sub mw_option {
 626         print STDERR "remote-helper command 'option $_[0]' not yet implemented\n";
 627         print STDOUT "unsupported\n";
 628         return;
 629 }
 630
 631 sub fetch_mw_revisions_for_page {
 632         my $page = shift;
 633         my $id = shift;
 634         my $fetch_from = shift;
 635         my @page_revs = ();
 636         my $query = {
 637                 action => 'query',
 638                 prop => 'revisions',
 639                 rvprop => 'ids',
 640                 rvdir => 'newer',
 641                 rvstartid => $fetch_from,
 642                 rvlimit => 500,
 643                 pageids => $id,
 644         };
 645
 646         my $revnum = 0;
 647         # Get 500 revisions at a time due to the mediawiki api limit
 648         while (1) {
 649                 my $result = $mediawiki->api($query);
 650
 651                 # Parse each of those 500 revisions
 652                 foreach my $revision (@{$result->{query}->{pages}->{$id}->{revisions}}) {
 653                         my $page_rev_ids;
 654                         $page_rev_ids->{pageid} = $page->{pageid};
 655                         $page_rev_ids->{revid} = $revision->{revid};
 656                         push(@page_revs, $page_rev_ids);
 657                         $revnum++;
 658                 }
 659                 last unless $result->{'query-continue'};
 660                 $query->{rvstartid} = $result->{'query-continue'}->{revisions}->{rvstartid};
 661         }
 662         if ($shallow_import && @page_revs) {
 663                 print STDERR "  Found 1 revision (shallow import).\n";
 664                 @page_revs = sort {$b->{revid} <=> $a->{revid}} (@page_revs);
 665                 return $page_revs[0];
 666         }
 667         print STDERR "  Found ", $revnum, " revision(s).\n";
 668         return @page_revs;
 669 }
 670
 671 sub fetch_mw_revisions {
 672         my $pages = shift; my @pages = @{$pages};
 673         my $fetch_from = shift;
 674
 675         my @revisions = ();
 676         my $n = 1;
 677         foreach my $page (@pages) {
 678                 my $id = $page->{pageid};
 679
 680                 print STDERR "page $n/", scalar(@pages), ": ". $page->{title} ."\n";
 681                 $n++;
 682                 my @page_revs = fetch_mw_revisions_for_page($page, $id, $fetch_from);
 683                 @revisions = (@page_revs, @revisions);
 684         }
 685
 686         return ($n, @revisions);
 687 }
 688
 689 sub fe_escape_path {
 690     my $path = shift;
 691     $path =~ s/\\/\\\\/g;
 692     $path =~ s/"/\\"/g;
 693     $path =~ s/\n/\\n/g;
 694     return '"' . $path . '"';
 695 }
 696
 697 sub import_file_revision {
 698         my $commit = shift;
 699         my %commit = %{$commit};
 700         my $full_import = shift;
 701         my $n = shift;
 702         my $mediafile = shift;
 703         my %mediafile;
 704         if ($mediafile) {
 705                 %mediafile = %{$mediafile};
 706         }
 707
 708         my $title = $commit{title};
 709         my $comment = $commit{comment};
 710         my $content = $commit{content};
 711         my $author = $commit{author};
 712         my $date = $commit{date};
 713
 714         print STDOUT "commit refs/mediawiki/$remotename/master\n";
 715         print STDOUT "mark :$n\n";
 716         print STDOUT "committer $author <$author\@$wiki_name> ", $date->epoch, " +0000\n";
 717         literal_data($comment);
 718
 719         # If it's not a clone, we need to know where to start from
 720         if (!$full_import && $n == 1) {
 721                 print STDOUT "from refs/mediawiki/$remotename/master^0\n";
 722         }
 723         if ($content ne DELETED_CONTENT) {
 724                 print STDOUT "M 644 inline " .
 725                     fe_escape_path($title . ".mw") . "\n";
 726                 literal_data($content);
 727                 if (%mediafile) {
 728                         print STDOUT "M 644 inline "
 729                             . fe_escape_path($mediafile{title}) . "\n";
 730                         literal_data_raw($mediafile{content});
 731                 }
 732                 print STDOUT "\n\n";
 733         } else {
 734                 print STDOUT "D " . fe_escape_path($title . ".mw") . "\n";
 735         }
 736
 737         # mediawiki revision number in the git note
 738         if ($full_import && $n == 1) {
 739                 print STDOUT "reset refs/notes/$remotename/mediawiki\n";
 740         }
 741         print STDOUT "commit refs/notes/$remotename/mediawiki\n";
 742         print STDOUT "committer $author <$author\@$wiki_name> ", $date->epoch, " +0000\n";
 743         literal_data("Note added by git-mediawiki during import");
 744         if (!$full_import && $n == 1) {
 745                 print STDOUT "from refs/notes/$remotename/mediawiki^0\n";
 746         }
 747         print STDOUT "N inline :$n\n";
 748         literal_data("mediawiki_revision: " . $commit{mw_revision});
 749         print STDOUT "\n\n";
 750         return;
 751 }
 752
 753 # parse a sequence of
 754 # <cmd> <arg1>
 755 # <cmd> <arg2>
 756 # \n
 757 # (like batch sequence of import and sequence of push statements)
 758 sub get_more_refs {
 759         my $cmd = shift;
 760         my @refs;
 761         while (1) {
 762                 my $line = <STDIN>;
 763                 if ($line =~ /^$cmd (.*)$/) {
 764                         push(@refs, $1);
 765                 } elsif ($line eq "\n") {
 766                         return @refs;
 767                 } else {
 768                         die("Invalid command in a '$cmd' batch: $_\n");
 769                 }
 770         }
 771         return;
 772 }
 773
 774 sub mw_import {
 775         # multiple import commands can follow each other.
 776         my @refs = (shift, get_more_refs("import"));
 777         foreach my $ref (@refs) {
 778                 mw_import_ref($ref);
 779         }
 780         print STDOUT "done\n";
 781         return;
 782 }
 783
 784 sub mw_import_ref {
 785         my $ref = shift;
 786         # The remote helper will call "import HEAD" and
 787         # "import refs/heads/master".
 788         # Since HEAD is a symbolic ref to master (by convention,
 789         # followed by the output of the command "list" that we gave),
 790         # we don't need to do anything in this case.
 791         if ($ref eq "HEAD") {
 792                 return;
 793         }
 794
 795         mw_connect_maybe();
 796
 797         print STDERR "Searching revisions...\n";
 798         my $last_local = get_last_local_revision();
 799         my $fetch_from = $last_local + 1;
 800         if ($fetch_from == 1) {
 801                 print STDERR ", fetching from beginning.\n";
 802         } else {
 803                 print STDERR ", fetching from here.\n";
 804         }
 805
 806         my $n = 0;
 807         if ($fetch_strategy eq "by_rev") {
 808                 print STDERR "Fetching & writing export data by revs...\n";
 809                 $n = mw_import_ref_by_revs($fetch_from);
 810         } elsif ($fetch_strategy eq "by_page") {
 811                 print STDERR "Fetching & writing export data by pages...\n";
 812                 $n = mw_import_ref_by_pages($fetch_from);
 813         } else {
 814                 print STDERR "fatal: invalid fetch strategy \"$fetch_strategy\".\n";
 815                 print STDERR "Check your configuration variables remote.$remotename.fetchStrategy and mediawiki.fetchStrategy\n";
 816                 exit 1;
 817         }
 818
 819         if ($fetch_from == 1 && $n == 0) {
 820                 print STDERR "You appear to have cloned an empty MediaWiki.\n";
 821                 # Something has to be done remote-helper side. If nothing is done, an error is
 822                 # thrown saying that HEAD is referring to unknown object 0000000000000000000
 823                 # and the clone fails.
 824         }
 825         return;
 826 }
 827
 828 sub mw_import_ref_by_pages {
 829
 830         my $fetch_from = shift;
 831         my %pages_hash = get_mw_pages();
 832         my @pages = values(%pages_hash);
 833
 834         my ($n, @revisions) = fetch_mw_revisions(\@pages, $fetch_from);
 835
 836         @revisions = sort {$a->{revid} <=> $b->{revid}} @revisions;
 837         my @revision_ids = map { $_->{revid} } @revisions;
 838
 839         return mw_import_revids($fetch_from, \@revision_ids, \%pages_hash);
 840 }
 841
 842 sub mw_import_ref_by_revs {
 843
 844         my $fetch_from = shift;
 845         my %pages_hash = get_mw_pages();
 846
 847         my $last_remote = get_last_global_remote_rev();
 848         my @revision_ids = $fetch_from..$last_remote;
 849         return mw_import_revids($fetch_from, \@revision_ids, \%pages_hash);
 850 }
 851
 852 # Import revisions given in second argument (array of integers).
 853 # Only pages appearing in the third argument (hash indexed by page titles)
 854 # will be imported.
 855 sub mw_import_revids {
 856         my $fetch_from = shift;
 857         my $revision_ids = shift;
 858         my $pages = shift;
 859
 860         my $n = 0;
 861         my $n_actual = 0;
 862         my $last_timestamp = 0; # Placeholer in case $rev->timestamp is undefined
 863
 864         foreach my $pagerevid (@$revision_ids) {
 865                 # Count page even if we skip it, since we display
 866                 # $n/$total and $total includes skipped pages.
 867                 $n++;
 868
 869                 # fetch the content of the pages
 870                 my $query = {
 871                         action => 'query',
 872                         prop => 'revisions',
 873                         rvprop => 'content|timestamp|comment|user|ids',
 874                         revids => $pagerevid,
 875                 };
 876
 877                 my $result = $mediawiki->api($query);
 878
 879                 if (!$result) {
 880                         die "Failed to retrieve modified page for revision $pagerevid\n";
 881                 }
 882
 883                 if (defined($result->{query}->{badrevids}->{$pagerevid})) {
 884                         # The revision id does not exist on the remote wiki.
 885                         next;
 886                 }
 887
 888                 if (!defined($result->{query}->{pages})) {
 889                         die "Invalid revision $pagerevid.\n";
 890                 }
 891
 892                 my @result_pages = values(%{$result->{query}->{pages}});
 893                 my $result_page = $result_pages[0];
 894                 my $rev = $result_pages[0]->{revisions}->[0];
 895
 896                 my $page_title = $result_page->{title};
 897
 898                 if (!exists($pages->{$page_title})) {
 899                         print STDERR "$n/", scalar(@$revision_ids),
 900                                 ": Skipping revision #$rev->{revid} of $page_title\n";
 901                         next;
 902                 }
 903
 904                 $n_actual++;
 905
 906                 my %commit;
 907                 $commit{author} = $rev->{user} || 'Anonymous';
 908                 $commit{comment} = $rev->{comment} || EMPTY_MESSAGE;
 909                 $commit{title} = mediawiki_smudge_filename($page_title);
 910                 $commit{mw_revision} = $rev->{revid};
 911                 $commit{content} = mediawiki_smudge($rev->{'*'});
 912
 913                 if (!defined($rev->{timestamp})) {
 914                         $last_timestamp++;
 915                 } else {
 916                         $last_timestamp = $rev->{timestamp};
 917                 }
 918                 $commit{date} = DateTime::Format::ISO8601->parse_datetime($last_timestamp);
 919
 920                 # Differentiates classic pages and media files.
 921                 my ($namespace, $filename) = $page_title =~ /^([^:]*):(.*)$/;
 922                 my %mediafile;
 923                 if ($namespace) {
 924                         my $id = get_mw_namespace_id($namespace);
 925                         if ($id && $id == get_mw_namespace_id("File")) {
 926                                 %mediafile = get_mw_mediafile_for_page_revision($filename, $rev->{timestamp});
 927                         }
 928                 }
 929                 # If this is a revision of the media page for new version
 930                 # of a file do one common commit for both file and media page.
 931                 # Else do commit only for that page.
 932                 print STDERR "$n/", scalar(@$revision_ids), ": Revision #$rev->{revid} of $commit{title}\n";
 933                 import_file_revision(\%commit, ($fetch_from == 1), $n_actual, \%mediafile);
 934         }
 935
 936         return $n_actual;
 937 }
 938
 939 sub error_non_fast_forward {
 940         my $advice = run_git("config --bool advice.pushNonFastForward");
 941         chomp($advice);
 942         if ($advice ne "false") {
 943                 # Native git-push would show this after the summary.
 944                 # We can't ask it to display it cleanly, so print it
 945                 # ourselves before.
 946                 print STDERR "To prevent you from losing history, non-fast-forward updates were rejected\n";
 947                 print STDERR "Merge the remote changes (e.g. 'git pull') before pushing again. See the\n";
 948                 print STDERR "'Note about fast-forwards' section of 'git push --help' for details.\n";
 949         }
 950         print STDOUT "error $_[0] \"non-fast-forward\"\n";
 951         return 0;
 952 }
 953
 954 sub mw_upload_file {
 955         my $complete_file_name = shift;
 956         my $new_sha1 = shift;
 957         my $extension = shift;
 958         my $file_deleted = shift;
 959         my $summary = shift;
 960         my $newrevid;
 961         my $path = "File:" . $complete_file_name;
 962         my %hashFiles = get_allowed_file_extensions();
 963         if (!exists($hashFiles{$extension})) {
 964                 print STDERR "$complete_file_name is not a permitted file on this wiki.\n";
 965                 print STDERR "Check the configuration of file uploads in your mediawiki.\n";
 966                 return $newrevid;
 967         }
 968         # Deleting and uploading a file requires a priviledged user
 969         if ($file_deleted) {
 970                 mw_connect_maybe();
 971                 my $query = {
 972                         action => 'delete',
 973                         title => $path,
 974                         reason => $summary
 975                 };
 976                 if (!$mediawiki->edit($query)) {
 977                         print STDERR "Failed to delete file on remote wiki\n";
 978                         print STDERR "Check your permissions on the remote site. Error code:\n";
 979                         print STDERR $mediawiki->{error}->{code} . ':' . $mediawiki->{error}->{details};
 980                         exit 1;
 981                 }
 982         } else {
 983                 # Don't let perl try to interpret file content as UTF-8 => use "raw"
 984                 my $content = run_git("cat-file blob $new_sha1", "raw");
 985                 if ($content ne "") {
 986                         mw_connect_maybe();
 987                         $mediawiki->{config}->{upload_url} =
 988                                 "$url/index.php/Special:Upload";
 989                         $mediawiki->edit({
 990                                 action => 'upload',
 991                                 filename => $complete_file_name,
 992                                 comment => $summary,
 993                                 file => [undef,
 994                                          $complete_file_name,
 995                                          Content => $content],
 996                                 ignorewarnings => 1,
 997                         }, {
 998                                 skip_encoding => 1
 999                         } ) || die $mediawiki->{error}->{code} . ':'
1000                                  . $mediawiki->{error}->{details} . "\n";
1001                         my $last_file_page = $mediawiki->get_page({title => $path});
1002                         $newrevid = $last_file_page->{revid};
1003                         print STDERR "Pushed file: $new_sha1 - $complete_file_name.\n";
1004                 } else {
1005                         print STDERR "Empty file $complete_file_name not pushed.\n";
1006                 }
1007         }
1008         return $newrevid;
1009 }
1010
1011 sub mw_push_file {
1012         my $diff_info = shift;
1013         # $diff_info contains a string in this format:
1014         # 100644 100644 <sha1_of_blob_before_commit> <sha1_of_blob_now> <status>
1015         my @diff_info_split = split(/[ \t]/, $diff_info);
1016
1017         # Filename, including .mw extension
1018         my $complete_file_name = shift;
1019         # Commit message
1020         my $summary = shift;
1021         # MediaWiki revision number. Keep the previous one by default,
1022         # in case there's no edit to perform.
1023         my $oldrevid = shift;
1024         my $newrevid;
1025
1026         if ($summary eq EMPTY_MESSAGE) {
1027                 $summary = '';
1028         }
1029
1030         my $new_sha1 = $diff_info_split[3];
1031         my $old_sha1 = $diff_info_split[2];
1032         my $page_created = ($old_sha1 eq NULL_SHA1);
1033         my $page_deleted = ($new_sha1 eq NULL_SHA1);
1034         $complete_file_name = mediawiki_clean_filename($complete_file_name);
1035
1036         my ($title, $extension) = $complete_file_name =~ /^(.*)\.([^\.]*)$/;
1037         if (!defined($extension)) {
1038                 $extension = "";
1039         }
1040         if ($extension eq "mw") {
1041                 my $ns = get_mw_namespace_id_for_page($complete_file_name);
1042                 if ($ns && $ns == get_mw_namespace_id("File") && (!$export_media)) {
1043                         print STDERR "Ignoring media file related page: $complete_file_name\n";
1044                         return ($oldrevid, "ok");
1045                 }
1046                 my $file_content;
1047                 if ($page_deleted) {
1048                         # Deleting a page usually requires
1049                         # special privileges. A common
1050                         # convention is to replace the page
1051                         # with this content instead:
1052                         $file_content = DELETED_CONTENT;
1053                 } else {
1054                         $file_content = run_git("cat-file blob $new_sha1");
1055                 }
1056
1057                 mw_connect_maybe();
1058
1059                 my $result = $mediawiki->edit( {
1060                         action => 'edit',
1061                         summary => $summary,
1062                         title => $title,
1063                         basetimestamp => $basetimestamps{$oldrevid},
1064                         text => mediawiki_clean($file_content, $page_created),
1065                                   }, {
1066                                           skip_encoding => 1 # Helps with names with accentuated characters
1067                                   });
1068                 if (!$result) {
1069                         if ($mediawiki->{error}->{code} == 3) {
1070                                 # edit conflicts, considered as non-fast-forward
1071                                 print STDERR 'Warning: Error ' .
1072                                     $mediawiki->{error}->{code} .
1073                                     ' from mediwiki: ' . $mediawiki->{error}->{details} .
1074                                     ".\n";
1075                                 return ($oldrevid, "non-fast-forward");
1076                         } else {
1077                                 # Other errors. Shouldn't happen => just die()
1078                                 die 'Fatal: Error ' .
1079                                     $mediawiki->{error}->{code} .
1080                                     ' from mediwiki: ' . $mediawiki->{error}->{details} . "\n";
1081                         }
1082                 }
1083                 $newrevid = $result->{edit}->{newrevid};
1084                 print STDERR "Pushed file: $new_sha1 - $title\n";
1085         } elsif ($export_media) {
1086                 $newrevid = mw_upload_file($complete_file_name, $new_sha1,
1087                                            $extension, $page_deleted,
1088                                            $summary);
1089         } else {
1090                 print STDERR "Ignoring media file $title\n";
1091         }
1092         $newrevid = ($newrevid or $oldrevid);
1093         return ($newrevid, "ok");
1094 }
1095
1096 sub mw_push {
1097         # multiple push statements can follow each other
1098         my @refsspecs = (shift, get_more_refs("push"));
1099         my $pushed;
1100         for my $refspec (@refsspecs) {
1101                 my ($force, $local, $remote) = $refspec =~ /^(\+)?([^:]*):([^:]*)$/
1102                     or die("Invalid refspec for push. Expected <src>:<dst> or +<src>:<dst>\n");
1103                 if ($force) {
1104                         print STDERR "Warning: forced push not allowed on a MediaWiki.\n";
1105                 }
1106                 if ($local eq "") {
1107                         print STDERR "Cannot delete remote branch on a MediaWiki\n";
1108                         print STDOUT "error $remote cannot delete\n";
1109                         next;
1110                 }
1111                 if ($remote ne "refs/heads/master") {
1112                         print STDERR "Only push to the branch 'master' is supported on a MediaWiki\n";
1113                         print STDOUT "error $remote only master allowed\n";
1114                         next;
1115                 }
1116                 if (mw_push_revision($local, $remote)) {
1117                         $pushed = 1;
1118                 }
1119         }
1120
1121         # Notify Git that the push is done
1122         print STDOUT "\n";
1123
1124         if ($pushed && $dumb_push) {
1125                 print STDERR "Just pushed some revisions to MediaWiki.\n";
1126                 print STDERR "The pushed revisions now have to be re-imported, and your current branch\n";
1127                 print STDERR "needs to be updated with these re-imported commits. You can do this with\n";
1128                 print STDERR "\n";
1129                 print STDERR "  git pull --rebase\n";
1130                 print STDERR "\n";
1131         }
1132         return;
1133 }
1134
1135 sub mw_push_revision {
1136         my $local = shift;
1137         my $remote = shift; # actually, this has to be "refs/heads/master" at this point.
1138         my $last_local_revid = get_last_local_revision();
1139         print STDERR ".\n"; # Finish sentence started by get_last_local_revision()
1140         my $last_remote_revid = get_last_remote_revision();
1141         my $mw_revision = $last_remote_revid;
1142
1143         # Get sha1 of commit pointed by local HEAD
1144         my $HEAD_sha1 = run_git("rev-parse $local 2>/dev/null"); chomp($HEAD_sha1);
1145         # Get sha1 of commit pointed by remotes/$remotename/master
1146         my $remoteorigin_sha1 = run_git("rev-parse refs/remotes/$remotename/master 2>/dev/null");
1147         chomp($remoteorigin_sha1);
1148
1149         if ($last_local_revid > 0 &&
1150             $last_local_revid < $last_remote_revid) {
1151                 return error_non_fast_forward($remote);
1152         }
1153
1154         if ($HEAD_sha1 eq $remoteorigin_sha1) {
1155                 # nothing to push
1156                 return 0;
1157         }
1158
1159         # Get every commit in between HEAD and refs/remotes/origin/master,
1160         # including HEAD and refs/remotes/origin/master
1161         my @commit_pairs = ();
1162         if ($last_local_revid > 0) {
1163                 my $parsed_sha1 = $remoteorigin_sha1;
1164                 # Find a path from last MediaWiki commit to pushed commit
1165                 print STDERR "Computing path from local to remote ...\n";
1166                 my @local_ancestry = split(/\n/, run_git("rev-list --boundary --parents $local ^$parsed_sha1"));
1167                 my %local_ancestry;
1168                 foreach my $line (@local_ancestry) {
1169                         if (my ($child, $parents) = $line =~ /^-?([a-f0-9]+) ([a-f0-9 ]+)/) {
1170                                 foreach my $parent (split(/ /, $parents)) {
1171                                         $local_ancestry{$parent} = $child;
1172                                 }
1173                         } elsif (!$line =~ /^([a-f0-9]+)/) {
1174                                 die "Unexpected output from git rev-list: $line\n";
1175                         }
1176                 }
1177                 while ($parsed_sha1 ne $HEAD_sha1) {
1178                         my $child = $local_ancestry{$parsed_sha1};
1179                         if (!$child) {
1180                                 printf STDERR "Cannot find a path in history from remote commit to last commit\n";
1181                                 return error_non_fast_forward($remote);
1182                         }
1183                         push(@commit_pairs, [$parsed_sha1, $child]);
1184                         $parsed_sha1 = $child;
1185                 }
1186         } else {
1187                 # No remote mediawiki revision. Export the whole
1188                 # history (linearized with --first-parent)
1189                 print STDERR "Warning: no common ancestor, pushing complete history\n";
1190                 my $history = run_git("rev-list --first-parent --children $local");
1191                 my @history = split(/\n/, $history);
1192                 @history = @history[1..$#history];
1193                 foreach my $line (reverse @history) {
1194                         my @commit_info_split = split(/[ \n]/, $line);
1195                         push(@commit_pairs, \@commit_info_split);
1196                 }
1197         }
1198
1199         foreach my $commit_info_split (@commit_pairs) {
1200                 my $sha1_child = @{$commit_info_split}[0];
1201                 my $sha1_commit = @{$commit_info_split}[1];
1202                 my $diff_infos = run_git("diff-tree -r --raw -z $sha1_child $sha1_commit");
1203                 # TODO: we could detect rename, and encode them with a #redirect on the wiki.
1204                 # TODO: for now, it's just a delete+add
1205                 my @diff_info_list = split(/\0/, $diff_infos);
1206                 # Keep the subject line of the commit message as mediawiki comment for the revision
1207                 my $commit_msg = run_git("log --no-walk --format=\"%s\" $sha1_commit");
1208                 chomp($commit_msg);
1209                 # Push every blob
1210                 while (@diff_info_list) {
1211                         my $status;
1212                         # git diff-tree -z gives an output like
1213                         # <metadata>\0<filename1>\0
1214                         # <metadata>\0<filename2>\0
1215                         # and we've split on \0.
1216                         my $info = shift(@diff_info_list);
1217                         my $file = shift(@diff_info_list);
1218                         ($mw_revision, $status) = mw_push_file($info, $file, $commit_msg, $mw_revision);
1219                         if ($status eq "non-fast-forward") {
1220                                 # we may already have sent part of the
1221                                 # commit to MediaWiki, but it's too
1222                                 # late to cancel it. Stop the push in
1223                                 # the middle, but still give an
1224                                 # accurate error message.
1225                                 return error_non_fast_forward($remote);
1226                         }
1227                         if ($status ne "ok") {
1228                                 die("Unknown error from mw_push_file()\n");
1229                         }
1230                 }
1231                 unless ($dumb_push) {
1232                         run_git("notes --ref=$remotename/mediawiki add -f -m \"mediawiki_revision: $mw_revision\" $sha1_commit");
1233                         run_git("update-ref -m \"Git-MediaWiki push\" refs/mediawiki/$remotename/master $sha1_commit $sha1_child");
1234                 }
1235         }
1236
1237         print STDOUT "ok $remote\n";
1238         return 1;
1239 }
1240
1241 sub get_allowed_file_extensions {
1242         mw_connect_maybe();
1243
1244         my $query = {
1245                 action => 'query',
1246                 meta => 'siteinfo',
1247                 siprop => 'fileextensions'
1248                 };
1249         my $result = $mediawiki->api($query);
1250         my @file_extensions = map { $_->{ext}} @{$result->{query}->{fileextensions}};
1251         my %hashFile = map { $_ => 1 } @file_extensions;
1252
1253         return %hashFile;
1254 }
1255
1256 # In memory cache for MediaWiki namespace ids.
1257 my %namespace_id;
1258
1259 # Namespaces whose id is cached in the configuration file
1260 # (to avoid duplicates)
1261 my %cached_mw_namespace_id;
1262
1263 # Return MediaWiki id for a canonical namespace name.
1264 # Ex.: "File", "Project".
1265 sub get_mw_namespace_id {
1266         mw_connect_maybe();
1267         my $name = shift;
1268
1269         if (!exists $namespace_id{$name}) {
1270                 # Look at configuration file, if the record for that namespace is
1271                 # already cached. Namespaces are stored in form:
1272                 # "Name_of_namespace:Id_namespace", ex.: "File:6".
1273                 my @temp = split(/\n/, run_git("config --get-all remote."
1274                                                 . $remotename .".namespaceCache"));
1275                 chomp(@temp);
1276                 foreach my $ns (@temp) {
1277                         my ($n, $id) = split(/:/, $ns);
1278                         if ($id eq 'notANameSpace') {
1279                                 $namespace_id{$n} = {is_namespace => 0};
1280                         } else {
1281                                 $namespace_id{$n} = {is_namespace => 1, id => $id};
1282                         }
1283                         $cached_mw_namespace_id{$n} = 1;
1284                 }
1285         }
1286
1287         if (!exists $namespace_id{$name}) {
1288                 print STDERR "Namespace $name not found in cache, querying the wiki ...\n";
1289                 # NS not found => get namespace id from MW and store it in
1290                 # configuration file.
1291                 my $query = {
1292                         action => 'query',
1293                         meta => 'siteinfo',
1294                         siprop => 'namespaces'
1295                 };
1296                 my $result = $mediawiki->api($query);
1297
1298                 while (my ($id, $ns) = each(%{$result->{query}->{namespaces}})) {
1299                         if (defined($ns->{id}) && defined($ns->{canonical})) {
1300                                 $namespace_id{$ns->{canonical}} = {is_namespace => 1, id => $ns->{id}};
1301                                 if ($ns->{'*'}) {
1302                                         # alias (e.g. french Fichier: as alias for canonical File:)
1303                                         $namespace_id{$ns->{'*'}} = {is_namespace => 1, id => $ns->{id}};
1304                                 }
1305                         }
1306                 }
1307         }
1308
1309         my $ns = $namespace_id{$name};
1310         my $id;
1311
1312         unless (defined $ns) {
1313                 print STDERR "No such namespace $name on MediaWiki.\n";
1314                 $ns = {is_namespace => 0};
1315                 $namespace_id{$name} = $ns;
1316         }
1317
1318         if ($ns->{is_namespace}) {
1319                 $id = $ns->{id};
1320         }
1321
1322         # Store "notANameSpace" as special value for inexisting namespaces
1323         my $store_id = ($id || 'notANameSpace');
1324
1325         # Store explicitely requested namespaces on disk
1326         if (!exists $cached_mw_namespace_id{$name}) {
1327                 run_git("config --add remote.". $remotename
1328                         .".namespaceCache \"". $name .":". $store_id ."\"");
1329                 $cached_mw_namespace_id{$name} = 1;
1330         }
1331         return $id;
1332 }
1333
1334 sub get_mw_namespace_id_for_page {
1335         my $namespace = shift;
1336         if ($namespace =~ /^([^:]*):/) {
1337                 return get_mw_namespace_id($namespace);
1338         } else {
1339                 return;
1340         }
1341 }