git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]annotate                * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --compose-encoding      <str>  * Encoding to assume for introduction.
  60     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  61
  62   Sending:
  63     --envelope-sender       <str>  * Email envelope sender.
  64     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  65                                      is optional. Default 'localhost'.
  66     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  67     --smtp-server-port      <int>  * Outgoing SMTP server port.
  68     --smtp-user             <str>  * Username for SMTP-AUTH.
  69     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  70     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  71     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  72     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  73     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  74
  75   Automating:
  76     --identity              <str>  * Use the sendemail.<id> options.
  77     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  78     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  79     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  80     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  81     --[no-]suppress-from           * Send to self. Default off.
  82     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  83     --[no-]thread                  * Use In-Reply-To: field. Default on.
  84
  85   Administering:
  86     --confirm               <str>  * Confirm recipients before sending;
  87                                      auto, cc, compose, always, or never.
  88     --quiet                        * Output one line of info per email.
  89     --dry-run                      * Don't actually send the emails.
  90     --[no-]validate                * Perform patch sanity checks. Default on.
  91     --[no-]format-patch            * understand any non optional arguments as
  92                                      `git format-patch` ones.
  93     --force                        * Send even if safety checks would prevent it.
  94
  95 EOT
  96         exit(1);
  97 }
  98
  99 # most mail servers generate the Date: header, but not all...
 100 sub format_2822_time {
 101         my ($time) = @_;
 102         my @localtm = localtime($time);
 103         my @gmttm = gmtime($time);
 104         my $localmin = $localtm[1] + $localtm[2] * 60;
 105         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 106         if ($localtm[0] != $gmttm[0]) {
 107                 die "local zone differs from GMT by a non-minute interval\n";
 108         }
 109         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 110                 $localmin += 1440;
 111         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 112                 $localmin -= 1440;
 113         } elsif ($gmttm[6] != $localtm[6]) {
 114                 die "local time offset greater than or equal to 24 hours\n";
 115         }
 116         my $offset = $localmin - $gmtmin;
 117         my $offhour = $offset / 60;
 118         my $offmin = abs($offset % 60);
 119         if (abs($offhour) >= 24) {
 120                 die ("local time offset greater than or equal to 24 hours\n");
 121         }
 122
 123         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 124                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 125                        $localtm[3],
 126                        qw(Jan Feb Mar Apr May Jun
 127                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 128                        $localtm[5]+1900,
 129                        $localtm[2],
 130                        $localtm[1],
 131                        $localtm[0],
 132                        ($offset >= 0) ? '+' : '-',
 133                        abs($offhour),
 134                        $offmin,
 135                        );
 136 }
 137
 138 my $have_email_valid = eval { require Email::Valid; 1 };
 139 my $have_mail_address = eval { require Mail::Address; 1 };
 140 my $smtp;
 141 my $auth;
 142
 143 # Variables we fill in automatically, or via prompting:
 144 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 145         $initial_reply_to,$initial_subject,@files,
 146         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 147
 148 my $envelope_sender;
 149
 150 # Example reply to:
 151 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 152
 153 my $repo = eval { Git->repository() };
 154 my @repo = $repo ? ($repo) : ();
 155 my $term = eval {
 156         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 157                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 158                 : new Term::ReadLine 'git-send-email';
 159 };
 160 if ($@) {
 161         $term = new FakeTerm "$@: going non-interactive";
 162 }
 163
 164 # Behavior modification variables
 165 my ($quiet, $dry_run) = (0, 0);
 166 my $format_patch;
 167 my $compose_filename;
 168 my $force = 0;
 169
 170 # Handle interactive edition of files.
 171 my $multiedit;
 172 my $editor;
 173
 174 sub do_edit {
 175         if (!defined($editor)) {
 176                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 177         }
 178         if (defined($multiedit) && !$multiedit) {
 179                 map {
 180                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 181                         if (($? & 127) || ($? >> 8)) {
 182                                 die("the editor exited uncleanly, aborting everything");
 183                         }
 184                 } @_;
 185         } else {
 186                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 187                 if (($? & 127) || ($? >> 8)) {
 188                         die("the editor exited uncleanly, aborting everything");
 189                 }
 190         }
 191 }
 192
 193 # Variables with corresponding config settings
 194 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 195 my ($to_cmd, $cc_cmd);
 196 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 197 my ($smtp_authuser, $smtp_encryption);
 198 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 199 my ($validate, $confirm);
 200 my (@suppress_cc);
 201 my ($auto_8bit_encoding);
 202 my ($compose_encoding);
 203
 204 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 205
 206 my %config_bool_settings = (
 207     "thread" => [\$thread, 1],
 208     "chainreplyto" => [\$chain_reply_to, 0],
 209     "suppressfrom" => [\$suppress_from, undef],
 210     "signedoffbycc" => [\$signed_off_by_cc, undef],
 211     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 212     "validate" => [\$validate, 1],
 213     "multiedit" => [\$multiedit, undef],
 214     "annotate" => [\$annotate, undef]
 215 );
 216
 217 my %config_settings = (
 218     "smtpserver" => \$smtp_server,
 219     "smtpserverport" => \$smtp_server_port,
 220     "smtpserveroption" => \@smtp_server_options,
 221     "smtpuser" => \$smtp_authuser,
 222     "smtppass" => \$smtp_authpass,
 223     "smtpdomain" => \$smtp_domain,
 224     "to" => \@initial_to,
 225     "tocmd" => \$to_cmd,
 226     "cc" => \@initial_cc,
 227     "cccmd" => \$cc_cmd,
 228     "aliasfiletype" => \$aliasfiletype,
 229     "bcc" => \@bcclist,
 230     "suppresscc" => \@suppress_cc,
 231     "envelopesender" => \$envelope_sender,
 232     "confirm"   => \$confirm,
 233     "from" => \$sender,
 234     "assume8bitencoding" => \$auto_8bit_encoding,
 235     "composeencoding" => \$compose_encoding,
 236 );
 237
 238 my %config_path_settings = (
 239     "aliasesfile" => \@alias_files,
 240 );
 241
 242 # Handle Uncouth Termination
 243 sub signal_handler {
 244
 245         # Make text normal
 246         print color("reset"), "\n";
 247
 248         # SMTP password masked
 249         system "stty echo";
 250
 251         # tmp files from --compose
 252         if (defined $compose_filename) {
 253                 if (-e $compose_filename) {
 254                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 255                 }
 256                 if (-e ($compose_filename . ".final")) {
 257                         print "'$compose_filename.final' contains the composed email.\n"
 258                 }
 259         }
 260
 261         exit;
 262 };
 263
 264 $SIG{TERM} = \&signal_handler;
 265 $SIG{INT}  = \&signal_handler;
 266
 267 # Begin by accumulating all the variables (defined above), that we will end up
 268 # needing, first, from the command line:
 269
 270 my $help;
 271 my $rc = GetOptions("h" => \$help,
 272                     "sender|from=s" => \$sender,
 273                     "in-reply-to=s" => \$initial_reply_to,
 274                     "subject=s" => \$initial_subject,
 275                     "to=s" => \@initial_to,
 276                     "to-cmd=s" => \$to_cmd,
 277                     "no-to" => \$no_to,
 278                     "cc=s" => \@initial_cc,
 279                     "no-cc" => \$no_cc,
 280                     "bcc=s" => \@bcclist,
 281                     "no-bcc" => \$no_bcc,
 282                     "chain-reply-to!" => \$chain_reply_to,
 283                     "smtp-server=s" => \$smtp_server,
 284                     "smtp-server-option=s" => \@smtp_server_options,
 285                     "smtp-server-port=s" => \$smtp_server_port,
 286                     "smtp-user=s" => \$smtp_authuser,
 287                     "smtp-pass:s" => \$smtp_authpass,
 288                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 289                     "smtp-encryption=s" => \$smtp_encryption,
 290                     "smtp-debug:i" => \$debug_net_smtp,
 291                     "smtp-domain:s" => \$smtp_domain,
 292                     "identity=s" => \$identity,
 293                     "annotate!" => \$annotate,
 294                     "compose" => \$compose,
 295                     "quiet" => \$quiet,
 296                     "cc-cmd=s" => \$cc_cmd,
 297                     "suppress-from!" => \$suppress_from,
 298                     "suppress-cc=s" => \@suppress_cc,
 299                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 300                     "confirm=s" => \$confirm,
 301                     "dry-run" => \$dry_run,
 302                     "envelope-sender=s" => \$envelope_sender,
 303                     "thread!" => \$thread,
 304                     "validate!" => \$validate,
 305                     "format-patch!" => \$format_patch,
 306                     "8bit-encoding=s" => \$auto_8bit_encoding,
 307                     "compose-encoding=s" => \$compose_encoding,
 308                     "force" => \$force,
 309          );
 310
 311 usage() if $help;
 312 unless ($rc) {
 313     usage();
 314 }
 315
 316 die "Cannot run git format-patch from outside a repository\n"
 317         if $format_patch and not $repo;
 318
 319 # Now, let's fill any that aren't set in with defaults:
 320
 321 sub read_config {
 322         my ($prefix) = @_;
 323
 324         foreach my $setting (keys %config_bool_settings) {
 325                 my $target = $config_bool_settings{$setting}->[0];
 326                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 327         }
 328
 329         foreach my $setting (keys %config_path_settings) {
 330                 my $target = $config_path_settings{$setting};
 331                 if (ref($target) eq "ARRAY") {
 332                         unless (@$target) {
 333                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 334                                 @$target = @values if (@values && defined $values[0]);
 335                         }
 336                 }
 337                 else {
 338                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 339                 }
 340         }
 341
 342         foreach my $setting (keys %config_settings) {
 343                 my $target = $config_settings{$setting};
 344                 next if $setting eq "to" and defined $no_to;
 345                 next if $setting eq "cc" and defined $no_cc;
 346                 next if $setting eq "bcc" and defined $no_bcc;
 347                 if (ref($target) eq "ARRAY") {
 348                         unless (@$target) {
 349                                 my @values = Git::config(@repo, "$prefix.$setting");
 350                                 @$target = @values if (@values && defined $values[0]);
 351                         }
 352                 }
 353                 else {
 354                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 355                 }
 356         }
 357
 358         if (!defined $smtp_encryption) {
 359                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 360                 if (defined $enc) {
 361                         $smtp_encryption = $enc;
 362                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 363                         $smtp_encryption = 'ssl';
 364                 }
 365         }
 366 }
 367
 368 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 369 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 370 read_config("sendemail.$identity") if (defined $identity);
 371 read_config("sendemail");
 372
 373 # fall back on builtin bool defaults
 374 foreach my $setting (values %config_bool_settings) {
 375         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 376 }
 377
 378 # 'default' encryption is none -- this only prevents a warning
 379 $smtp_encryption = '' unless (defined $smtp_encryption);
 380
 381 # Set CC suppressions
 382 my(%suppress_cc);
 383 if (@suppress_cc) {
 384         foreach my $entry (@suppress_cc) {
 385                 die "Unknown --suppress-cc field: '$entry'\n"
 386                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 387                 $suppress_cc{$entry} = 1;
 388         }
 389 }
 390
 391 if ($suppress_cc{'all'}) {
 392         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 393                 $suppress_cc{$entry} = 1;
 394         }
 395         delete $suppress_cc{'all'};
 396 }
 397
 398 # If explicit old-style ones are specified, they trump --suppress-cc.
 399 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 400 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 401
 402 if ($suppress_cc{'body'}) {
 403         foreach my $entry (qw (sob bodycc)) {
 404                 $suppress_cc{$entry} = 1;
 405         }
 406         delete $suppress_cc{'body'};
 407 }
 408
 409 # Set confirm's default value
 410 my $confirm_unconfigured = !defined $confirm;
 411 if ($confirm_unconfigured) {
 412         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 413 };
 414 die "Unknown --confirm setting: '$confirm'\n"
 415         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 416
 417 # Debugging, print out the suppressions.
 418 if (0) {
 419         print "suppressions:\n";
 420         foreach my $entry (keys %suppress_cc) {
 421                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 422         }
 423 }
 424
 425 my ($repoauthor, $repocommitter);
 426 ($repoauthor) = Git::ident_person(@repo, 'author');
 427 ($repocommitter) = Git::ident_person(@repo, 'committer');
 428
 429 # Verify the user input
 430
 431 foreach my $entry (@initial_to) {
 432         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 433 }
 434
 435 foreach my $entry (@initial_cc) {
 436         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 437 }
 438
 439 foreach my $entry (@bcclist) {
 440         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 441 }
 442
 443 sub parse_address_line {
 444         if ($have_mail_address) {
 445                 return map { $_->format } Mail::Address->parse($_[0]);
 446         } else {
 447                 return split_addrs($_[0]);
 448         }
 449 }
 450
 451 sub split_addrs {
 452         return quotewords('\s*,\s*', 1, @_);
 453 }
 454
 455 my %aliases;
 456 my %parse_alias = (
 457         # multiline formats can be supported in the future
 458         mutt => sub { my $fh = shift; while (<$fh>) {
 459                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 460                         my ($alias, $addr) = ($1, $2);
 461                         $addr =~ s/#.*$//; # mutt allows # comments
 462                          # commas delimit multiple addresses
 463                         $aliases{$alias} = [ split_addrs($addr) ];
 464                 }}},
 465         mailrc => sub { my $fh = shift; while (<$fh>) {
 466                 if (/^alias\s+(\S+)\s+(.*)$/) {
 467                         # spaces delimit multiple addresses
 468                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 469                 }}},
 470         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 471                 for (my $x = ''; defined($x); $x = $_) {
 472                         chomp $x;
 473                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 474                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 475                         $aliases{$1} = [ split_addrs($2) ];
 476                 }},
 477         elm => sub  { my $fh = shift;
 478                       while (<$fh>) {
 479                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 480                               my ($alias, $addr) = ($1, $2);
 481                                $aliases{$alias} = [ split_addrs($addr) ];
 482                           }
 483                       } },
 484
 485         gnus => sub { my $fh = shift; while (<$fh>) {
 486                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 487                         $aliases{$1} = [ $2 ];
 488                 }}}
 489 );
 490
 491 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 492         foreach my $file (@alias_files) {
 493                 open my $fh, '<', $file or die "opening $file: $!\n";
 494                 $parse_alias{$aliasfiletype}->($fh);
 495                 close $fh;
 496         }
 497 }
 498
 499 ($sender) = expand_aliases($sender) if defined $sender;
 500
 501 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 502 # $f is a revision list specification to be passed to format-patch.
 503 sub is_format_patch_arg {
 504         return unless $repo;
 505         my $f = shift;
 506         try {
 507                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 508                 if (defined($format_patch)) {
 509                         return $format_patch;
 510                 }
 511                 die(<<EOF);
 512 File '$f' exists but it could also be the range of commits
 513 to produce patches for.  Please disambiguate by...
 514
 515     * Saying "./$f" if you mean a file; or
 516     * Giving --format-patch option if you mean a range.
 517 EOF
 518         } catch Git::Error::Command with {
 519                 # Not a valid revision.  Treat it as a filename.
 520                 return 0;
 521         }
 522 }
 523
 524 # Now that all the defaults are set, process the rest of the command line
 525 # arguments and collect up the files that need to be processed.
 526 my @rev_list_opts;
 527 while (defined(my $f = shift @ARGV)) {
 528         if ($f eq "--") {
 529                 push @rev_list_opts, "--", @ARGV;
 530                 @ARGV = ();
 531         } elsif (-d $f and !is_format_patch_arg($f)) {
 532                 opendir my $dh, $f
 533                         or die "Failed to opendir $f: $!";
 534
 535                 push @files, grep { -f $_ } map { catfile($f, $_) }
 536                                 sort readdir $dh;
 537                 closedir $dh;
 538         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 539                 push @files, $f;
 540         } else {
 541                 push @rev_list_opts, $f;
 542         }
 543 }
 544
 545 if (@rev_list_opts) {
 546         die "Cannot run git format-patch from outside a repository\n"
 547                 unless $repo;
 548         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 549 }
 550
 551 if ($validate) {
 552         foreach my $f (@files) {
 553                 unless (-p $f) {
 554                         my $error = validate_patch($f);
 555                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 556                 }
 557         }
 558 }
 559
 560 if (@files) {
 561         unless ($quiet) {
 562                 print $_,"\n" for (@files);
 563         }
 564 } else {
 565         print STDERR "\nNo patch files specified!\n\n";
 566         usage();
 567 }
 568
 569 sub get_patch_subject {
 570         my $fn = shift;
 571         open (my $fh, '<', $fn);
 572         while (my $line = <$fh>) {
 573                 next unless ($line =~ /^Subject: (.*)$/);
 574                 close $fh;
 575                 return "GIT: $1\n";
 576         }
 577         close $fh;
 578         die "No subject line in $fn ?";
 579 }
 580
 581 if ($compose) {
 582         # Note that this does not need to be secure, but we will make a small
 583         # effort to have it be unique
 584         $compose_filename = ($repo ?
 585                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 586                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 587         open my $c, ">", $compose_filename
 588                 or die "Failed to open for writing $compose_filename: $!";
 589
 590
 591         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 592         my $tpl_subject = $initial_subject || '';
 593         my $tpl_reply_to = $initial_reply_to || '';
 594
 595         print $c <<EOT;
 596 From $tpl_sender # This line is ignored.
 597 GIT: Lines beginning in "GIT:" will be removed.
 598 GIT: Consider including an overall diffstat or table of contents
 599 GIT: for the patch you are writing.
 600 GIT:
 601 GIT: Clear the body content if you don't wish to send a summary.
 602 From: $tpl_sender
 603 Subject: $tpl_subject
 604 In-Reply-To: $tpl_reply_to
 605
 606 EOT
 607         for my $f (@files) {
 608                 print $c get_patch_subject($f);
 609         }
 610         close $c;
 611
 612         if ($annotate) {
 613                 do_edit($compose_filename, @files);
 614         } else {
 615                 do_edit($compose_filename);
 616         }
 617
 618         open my $c2, ">", $compose_filename . ".final"
 619                 or die "Failed to open $compose_filename.final : " . $!;
 620
 621         open $c, "<", $compose_filename
 622                 or die "Failed to open $compose_filename : " . $!;
 623
 624         my $need_8bit_cte = file_has_nonascii($compose_filename);
 625         my $in_body = 0;
 626         my $summary_empty = 1;
 627         if (!defined $compose_encoding) {
 628                 $compose_encoding = "UTF-8";
 629         }
 630         while(<$c>) {
 631                 next if m/^GIT:/;
 632                 if ($in_body) {
 633                         $summary_empty = 0 unless (/^\n$/);
 634                 } elsif (/^\n$/) {
 635                         $in_body = 1;
 636                         if ($need_8bit_cte) {
 637                                 print $c2 "MIME-Version: 1.0\n",
 638                                          "Content-Type: text/plain; ",
 639                                            "charset=$compose_encoding\n",
 640                                          "Content-Transfer-Encoding: 8bit\n";
 641                         }
 642                 } elsif (/^MIME-Version:/i) {
 643                         $need_8bit_cte = 0;
 644                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 645                         $initial_subject = $1;
 646                         my $subject = $initial_subject;
 647                         $_ = "Subject: " .
 648                                 quote_subject($subject, $compose_encoding) .
 649                                 "\n";
 650                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 651                         $initial_reply_to = $1;
 652                         next;
 653                 } elsif (/^From:\s*(.+)\s*$/i) {
 654                         $sender = $1;
 655                         next;
 656                 } elsif (/^(?:To|Cc|Bcc):/i) {
 657                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 658                         next;
 659                 }
 660                 print $c2 $_;
 661         }
 662         close $c;
 663         close $c2;
 664
 665         if ($summary_empty) {
 666                 print "Summary email is empty, skipping it\n";
 667                 $compose = -1;
 668         }
 669 } elsif ($annotate) {
 670         do_edit(@files);
 671 }
 672
 673 sub ask {
 674         my ($prompt, %arg) = @_;
 675         my $valid_re = $arg{valid_re};
 676         my $default = $arg{default};
 677         my $confirm_only = $arg{confirm_only};
 678         my $resp;
 679         my $i = 0;
 680         return defined $default ? $default : undef
 681                 unless defined $term->IN and defined fileno($term->IN) and
 682                        defined $term->OUT and defined fileno($term->OUT);
 683         while ($i++ < 10) {
 684                 $resp = $term->readline($prompt);
 685                 if (!defined $resp) { # EOF
 686                         print "\n";
 687                         return defined $default ? $default : undef;
 688                 }
 689                 if ($resp eq '' and defined $default) {
 690                         return $default;
 691                 }
 692                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 693                         return $resp;
 694                 }
 695                 if ($confirm_only) {
 696                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 697                         if (defined $yesno && $yesno =~ /y/i) {
 698                                 return $resp;
 699                         }
 700                 }
 701         }
 702         return;
 703 }
 704
 705 my %broken_encoding;
 706
 707 sub file_declares_8bit_cte {
 708         my $fn = shift;
 709         open (my $fh, '<', $fn);
 710         while (my $line = <$fh>) {
 711                 last if ($line =~ /^$/);
 712                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 713         }
 714         close $fh;
 715         return 0;
 716 }
 717
 718 foreach my $f (@files) {
 719         next unless (body_or_subject_has_nonascii($f)
 720                      && !file_declares_8bit_cte($f));
 721         $broken_encoding{$f} = 1;
 722 }
 723
 724 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 725         print "The following files are 8bit, but do not declare " .
 726                 "a Content-Transfer-Encoding.\n";
 727         foreach my $f (sort keys %broken_encoding) {
 728                 print "    $f\n";
 729         }
 730         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 731                                   default => "UTF-8");
 732 }
 733
 734 if (!$force) {
 735         for my $f (@files) {
 736                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 737                         die "Refusing to send because the patch\n\t$f\n"
 738                                 . "has the template subject '*** SUBJECT HERE ***'. "
 739                                 . "Pass --force if you really want to send.\n";
 740                 }
 741         }
 742 }
 743
 744 if (!defined $sender) {
 745         $sender = $repoauthor || $repocommitter || '';
 746 }
 747
 748 # $sender could be an already sanitized address
 749 # (e.g. sendemail.from could be manually sanitized by user).
 750 # But it's a no-op to run sanitize_address on an already sanitized address.
 751 $sender = sanitize_address($sender);
 752
 753 my $prompting = 0;
 754 if (!@initial_to && !defined $to_cmd) {
 755         my $to = ask("Who should the emails be sent to (if any)? ",
 756                      default => "",
 757                      valid_re => qr/\@.*\./, confirm_only => 1);
 758         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 759         $prompting++;
 760 }
 761
 762 sub expand_aliases {
 763         return map { expand_one_alias($_) } @_;
 764 }
 765
 766 my %EXPANDED_ALIASES;
 767 sub expand_one_alias {
 768         my $alias = shift;
 769         if ($EXPANDED_ALIASES{$alias}) {
 770                 die "fatal: alias '$alias' expands to itself\n";
 771         }
 772         local $EXPANDED_ALIASES{$alias} = 1;
 773         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 774 }
 775
 776 @initial_to = expand_aliases(@initial_to);
 777 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 778 @initial_cc = expand_aliases(@initial_cc);
 779 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 780 @bcclist = expand_aliases(@bcclist);
 781 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 782
 783 if ($thread && !defined $initial_reply_to && $prompting) {
 784         $initial_reply_to = ask(
 785                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 786                 default => "",
 787                 valid_re => qr/\@.*\./, confirm_only => 1);
 788 }
 789 if (defined $initial_reply_to) {
 790         $initial_reply_to =~ s/^\s*<?//;
 791         $initial_reply_to =~ s/>?\s*$//;
 792         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 793 }
 794
 795 if (!defined $smtp_server) {
 796         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 797                 if (-x $_) {
 798                         $smtp_server = $_;
 799                         last;
 800                 }
 801         }
 802         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 803 }
 804
 805 if ($compose && $compose > 0) {
 806         @files = ($compose_filename . ".final", @files);
 807 }
 808
 809 # Variables we set as part of the loop over files
 810 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 811         $needs_confirm, $message_num, $ask_default);
 812
 813 sub extract_valid_address {
 814         my $address = shift;
 815         my $local_part_regexp = qr/[^<>"\s@]+/;
 816         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 817
 818         # check for a local address:
 819         return $address if ($address =~ /^($local_part_regexp)$/);
 820
 821         $address =~ s/^\s*<(.*)>\s*$/$1/;
 822         if ($have_email_valid) {
 823                 return scalar Email::Valid->address($address);
 824         }
 825
 826         # less robust/correct than the monster regexp in Email::Valid,
 827         # but still does a 99% job, and one less dependency
 828         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 829         return;
 830 }
 831
 832 sub extract_valid_address_or_die {
 833         my $address = shift;
 834         $address = extract_valid_address($address);
 835         die "error: unable to extract a valid address from: $address\n"
 836                 if !$address;
 837         return $address;
 838 }
 839
 840 sub validate_address {
 841         my $address = shift;
 842         while (!extract_valid_address($address)) {
 843                 print STDERR "error: unable to extract a valid address from: $address\n";
 844                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 845                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 846                         default => 'q');
 847                 if (/^d/i) {
 848                         return undef;
 849                 } elsif (/^q/i) {
 850                         cleanup_compose_files();
 851                         exit(0);
 852                 }
 853                 $address = ask("Who should the email be sent to (if any)? ",
 854                         default => "",
 855                         valid_re => qr/\@.*\./, confirm_only => 1);
 856         }
 857         return $address;
 858 }
 859
 860 sub validate_address_list {
 861         return (grep { defined $_ }
 862                 map { validate_address($_) } @_);
 863 }
 864
 865 # Usually don't need to change anything below here.
 866
 867 # we make a "fake" message id by taking the current number
 868 # of seconds since the beginning of Unix time and tacking on
 869 # a random number to the end, in case we are called quicker than
 870 # 1 second since the last time we were called.
 871
 872 # We'll setup a template for the message id, using the "from" address:
 873
 874 my ($message_id_stamp, $message_id_serial);
 875 sub make_message_id {
 876         my $uniq;
 877         if (!defined $message_id_stamp) {
 878                 $message_id_stamp = sprintf("%s-%s", time, $$);
 879                 $message_id_serial = 0;
 880         }
 881         $message_id_serial++;
 882         $uniq = "$message_id_stamp-$message_id_serial";
 883
 884         my $du_part;
 885         for ($sender, $repocommitter, $repoauthor) {
 886                 $du_part = extract_valid_address(sanitize_address($_));
 887                 last if (defined $du_part and $du_part ne '');
 888         }
 889         if (not defined $du_part or $du_part eq '') {
 890                 require Sys::Hostname;
 891                 $du_part = 'user@' . Sys::Hostname::hostname();
 892         }
 893         my $message_id_template = "<%s-git-send-email-%s>";
 894         $message_id = sprintf($message_id_template, $uniq, $du_part);
 895         #print "new message id = $message_id\n"; # Was useful for debugging
 896 }
 897
 898
 899
 900 $time = time - scalar $#files;
 901
 902 sub unquote_rfc2047 {
 903         local ($_) = @_;
 904         my $encoding;
 905         s{=\?([^?]+)\?q\?(.*?)\?=}{
 906                 $encoding = $1;
 907                 my $e = $2;
 908                 $e =~ s/_/ /g;
 909                 $e =~ s/=([0-9A-F]{2})/chr(hex($1))/eg;
 910                 $e;
 911         }eg;
 912         return wantarray ? ($_, $encoding) : $_;
 913 }
 914
 915 sub quote_rfc2047 {
 916         local $_ = shift;
 917         my $encoding = shift || 'UTF-8';
 918         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 919         s/(.*)/=\?$encoding\?q\?$1\?=/;
 920         return $_;
 921 }
 922
 923 sub is_rfc2047_quoted {
 924         my $s = shift;
 925         my $token = qr/[^][()<>@,;:"\/?.= \000-\037\177-\377]+/;
 926         my $encoded_text = qr/[!->@-~]+/;
 927         length($s) <= 75 &&
 928         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 929 }
 930
 931 sub subject_needs_rfc2047_quoting {
 932         my $s = shift;
 933
 934         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 935 }
 936
 937 sub quote_subject {
 938         local $subject = shift;
 939         my $encoding = shift || 'UTF-8';
 940
 941         if (subject_needs_rfc2047_quoting($subject)) {
 942                 return quote_rfc2047($subject, $encoding);
 943         }
 944         return $subject;
 945 }
 946
 947 # use the simplest quoting being able to handle the recipient
 948 sub sanitize_address {
 949         my ($recipient) = @_;
 950
 951         # remove garbage after email address
 952         $recipient =~ s/(.*>).*$/$1/;
 953
 954         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 955
 956         if (not $recipient_name) {
 957                 return $recipient;
 958         }
 959
 960         # if recipient_name is already quoted, do nothing
 961         if (is_rfc2047_quoted($recipient_name)) {
 962                 return $recipient;
 963         }
 964
 965         # rfc2047 is needed if a non-ascii char is included
 966         if ($recipient_name =~ /[^[:ascii:]]/) {
 967                 $recipient_name =~ s/^"(.*)"$/$1/;
 968                 $recipient_name = quote_rfc2047($recipient_name);
 969         }
 970
 971         # double quotes are needed if specials or CTLs are included
 972         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 973                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 974                 $recipient_name = qq["$recipient_name"];
 975         }
 976
 977         return "$recipient_name $recipient_addr";
 978
 979 }
 980
 981 sub sanitize_address_list {
 982         return (map { sanitize_address($_) } @_);
 983 }
 984
 985 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 986 #
 987 # Tightly configured MTAa require that a caller sends a real DNS
 988 # domain name that corresponds the IP address in the HELO/EHLO
 989 # handshake. This is used to verify the connection and prevent
 990 # spammers from trying to hide their identity. If the DNS and IP don't
 991 # match, the receiveing MTA may deny the connection.
 992 #
 993 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
 994 #
 995 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
 996 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
 997 #
 998 # This maildomain*() code is based on ideas in Perl library Test::Reporter
 999 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1000
1001 sub valid_fqdn {
1002         my $domain = shift;
1003         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1004 }
1005
1006 sub maildomain_net {
1007         my $maildomain;
1008
1009         if (eval { require Net::Domain; 1 }) {
1010                 my $domain = Net::Domain::domainname();
1011                 $maildomain = $domain if valid_fqdn($domain);
1012         }
1013
1014         return $maildomain;
1015 }
1016
1017 sub maildomain_mta {
1018         my $maildomain;
1019
1020         if (eval { require Net::SMTP; 1 }) {
1021                 for my $host (qw(mailhost localhost)) {
1022                         my $smtp = Net::SMTP->new($host);
1023                         if (defined $smtp) {
1024                                 my $domain = $smtp->domain;
1025                                 $smtp->quit;
1026
1027                                 $maildomain = $domain if valid_fqdn($domain);
1028
1029                                 last if $maildomain;
1030                         }
1031                 }
1032         }
1033
1034         return $maildomain;
1035 }
1036
1037 sub maildomain {
1038         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1039 }
1040
1041 sub smtp_host_string {
1042         if (defined $smtp_server_port) {
1043                 return "$smtp_server:$smtp_server_port";
1044         } else {
1045                 return $smtp_server;
1046         }
1047 }
1048
1049 # Returns 1 if authentication succeeded or was not necessary
1050 # (smtp_user was not specified), and 0 otherwise.
1051
1052 sub smtp_auth_maybe {
1053         if (!defined $smtp_authuser || $auth) {
1054                 return 1;
1055         }
1056
1057         # Workaround AUTH PLAIN/LOGIN interaction defect
1058         # with Authen::SASL::Cyrus
1059         eval {
1060                 require Authen::SASL;
1061                 Authen::SASL->import(qw(Perl));
1062         };
1063
1064         # TODO: Authentication may fail not because credentials were
1065         # invalid but due to other reasons, in which we should not
1066         # reject credentials.
1067         $auth = Git::credential({
1068                 'protocol' => 'smtp',
1069                 'host' => smtp_host_string(),
1070                 'username' => $smtp_authuser,
1071                 # if there's no password, "git credential fill" will
1072                 # give us one, otherwise it'll just pass this one.
1073                 'password' => $smtp_authpass
1074         }, sub {
1075                 my $cred = shift;
1076                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1077         });
1078
1079         return $auth;
1080 }
1081
1082 # Returns 1 if the message was sent, and 0 otherwise.
1083 # In actuality, the whole program dies when there
1084 # is an error sending a message.
1085
1086 sub send_message {
1087         my @recipients = unique_email_list(@to);
1088         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1089                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1090                     }
1091                @cc);
1092         my $to = join (",\n\t", @recipients);
1093         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1094         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1095         my $date = format_2822_time($time++);
1096         my $gitversion = '@@GIT_VERSION@@';
1097         if ($gitversion =~ m/..GIT_VERSION../) {
1098             $gitversion = Git::version();
1099         }
1100
1101         my $cc = join(",\n\t", unique_email_list(@cc));
1102         my $ccline = "";
1103         if ($cc ne '') {
1104                 $ccline = "\nCc: $cc";
1105         }
1106         make_message_id() unless defined($message_id);
1107
1108         my $header = "From: $sender
1109 To: $to${ccline}
1110 Subject: $subject
1111 Date: $date
1112 Message-Id: $message_id
1113 X-Mailer: git-send-email $gitversion
1114 ";
1115         if ($reply_to) {
1116
1117                 $header .= "In-Reply-To: $reply_to\n";
1118                 $header .= "References: $references\n";
1119         }
1120         if (@xh) {
1121                 $header .= join("\n", @xh) . "\n";
1122         }
1123
1124         my @sendmail_parameters = ('-i', @recipients);
1125         my $raw_from = $sender;
1126         if (defined $envelope_sender && $envelope_sender ne "auto") {
1127                 $raw_from = $envelope_sender;
1128         }
1129         $raw_from = extract_valid_address($raw_from);
1130         unshift (@sendmail_parameters,
1131                         '-f', $raw_from) if(defined $envelope_sender);
1132
1133         if ($needs_confirm && !$dry_run) {
1134                 print "\n$header\n";
1135                 if ($needs_confirm eq "inform") {
1136                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1137                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1138                         print "    The Cc list above has been expanded by additional\n";
1139                         print "    addresses found in the patch commit message. By default\n";
1140                         print "    send-email prompts before sending whenever this occurs.\n";
1141                         print "    This behavior is controlled by the sendemail.confirm\n";
1142                         print "    configuration setting.\n";
1143                         print "\n";
1144                         print "    For additional information, run 'git send-email --help'.\n";
1145                         print "    To retain the current behavior, but squelch this message,\n";
1146                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1147                 }
1148                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1149                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1150                          default => $ask_default);
1151                 die "Send this email reply required" unless defined $_;
1152                 if (/^n/i) {
1153                         return 0;
1154                 } elsif (/^q/i) {
1155                         cleanup_compose_files();
1156                         exit(0);
1157                 } elsif (/^a/i) {
1158                         $confirm = 'never';
1159                 }
1160         }
1161
1162         unshift (@sendmail_parameters, @smtp_server_options);
1163
1164         if ($dry_run) {
1165                 # We don't want to send the email.
1166         } elsif ($smtp_server =~ m#^/#) {
1167                 my $pid = open my $sm, '|-';
1168                 defined $pid or die $!;
1169                 if (!$pid) {
1170                         exec($smtp_server, @sendmail_parameters) or die $!;
1171                 }
1172                 print $sm "$header\n$message";
1173                 close $sm or die $!;
1174         } else {
1175
1176                 if (!defined $smtp_server) {
1177                         die "The required SMTP server is not properly defined."
1178                 }
1179
1180                 if ($smtp_encryption eq 'ssl') {
1181                         $smtp_server_port ||= 465; # ssmtp
1182                         require Net::SMTP::SSL;
1183                         $smtp_domain ||= maildomain();
1184                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1185                                                       Hello => $smtp_domain,
1186                                                       Port => $smtp_server_port);
1187                 }
1188                 else {
1189                         require Net::SMTP;
1190                         $smtp_domain ||= maildomain();
1191                         $smtp ||= Net::SMTP->new(smtp_host_string(),
1192                                                  Hello => $smtp_domain,
1193                                                  Debug => $debug_net_smtp);
1194                         if ($smtp_encryption eq 'tls' && $smtp) {
1195                                 require Net::SMTP::SSL;
1196                                 $smtp->command('STARTTLS');
1197                                 $smtp->response();
1198                                 if ($smtp->code == 220) {
1199                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1200                                                 or die "STARTTLS failed! ".$smtp->message;
1201                                         $smtp_encryption = '';
1202                                         # Send EHLO again to receive fresh
1203                                         # supported commands
1204                                         $smtp->hello($smtp_domain);
1205                                 } else {
1206                                         die "Server does not support STARTTLS! ".$smtp->message;
1207                                 }
1208                         }
1209                 }
1210
1211                 if (!$smtp) {
1212                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1213                             "VALUES: server=$smtp_server ",
1214                             "encryption=$smtp_encryption ",
1215                             "hello=$smtp_domain",
1216                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1217                 }
1218
1219                 smtp_auth_maybe or die $smtp->message;
1220
1221                 $smtp->mail( $raw_from ) or die $smtp->message;
1222                 $smtp->to( @recipients ) or die $smtp->message;
1223                 $smtp->data or die $smtp->message;
1224                 $smtp->datasend("$header\n$message") or die $smtp->message;
1225                 $smtp->dataend() or die $smtp->message;
1226                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1227         }
1228         if ($quiet) {
1229                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1230         } else {
1231                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1232                 if ($smtp_server !~ m#^/#) {
1233                         print "Server: $smtp_server\n";
1234                         print "MAIL FROM:<$raw_from>\n";
1235                         foreach my $entry (@recipients) {
1236                             print "RCPT TO:<$entry>\n";
1237                         }
1238                 } else {
1239                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1240                 }
1241                 print $header, "\n";
1242                 if ($smtp) {
1243                         print "Result: ", $smtp->code, ' ',
1244                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1245                 } else {
1246                         print "Result: OK\n";
1247                 }
1248         }
1249
1250         return 1;
1251 }
1252
1253 $reply_to = $initial_reply_to;
1254 $references = $initial_reply_to || '';
1255 $subject = $initial_subject;
1256 $message_num = 0;
1257
1258 foreach my $t (@files) {
1259         open my $fh, "<", $t or die "can't open file $t";
1260
1261         my $author = undef;
1262         my $author_encoding;
1263         my $has_content_type;
1264         my $body_encoding;
1265         @to = ();
1266         @cc = ();
1267         @xh = ();
1268         my $input_format = undef;
1269         my @header = ();
1270         $message = "";
1271         $message_num++;
1272         # First unfold multiline header fields
1273         while(<$fh>) {
1274                 last if /^\s*$/;
1275                 if (/^\s+\S/ and @header) {
1276                         chomp($header[$#header]);
1277                         s/^\s+/ /;
1278                         $header[$#header] .= $_;
1279             } else {
1280                         push(@header, $_);
1281                 }
1282         }
1283         # Now parse the header
1284         foreach(@header) {
1285                 if (/^From /) {
1286                         $input_format = 'mbox';
1287                         next;
1288                 }
1289                 chomp;
1290                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1291                         $input_format = 'mbox';
1292                 }
1293
1294                 if (defined $input_format && $input_format eq 'mbox') {
1295                         if (/^Subject:\s+(.*)$/i) {
1296                                 $subject = $1;
1297                         }
1298                         elsif (/^From:\s+(.*)$/i) {
1299                                 ($author, $author_encoding) = unquote_rfc2047($1);
1300                                 my $sauthor = sanitize_address($author);
1301                                 next if $suppress_cc{'author'};
1302                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1303                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1304                                         $1, $_) unless $quiet;
1305                                 push @cc, $1;
1306                         }
1307                         elsif (/^To:\s+(.*)$/i) {
1308                                 foreach my $addr (parse_address_line($1)) {
1309                                         printf("(mbox) Adding to: %s from line '%s'\n",
1310                                                 $addr, $_) unless $quiet;
1311                                         push @to, $addr;
1312                                 }
1313                         }
1314                         elsif (/^Cc:\s+(.*)$/i) {
1315                                 foreach my $addr (parse_address_line($1)) {
1316                                         my $qaddr = unquote_rfc2047($addr);
1317                                         my $saddr = sanitize_address($qaddr);
1318                                         if ($saddr eq $sender) {
1319                                                 next if ($suppress_cc{'self'});
1320                                         } else {
1321                                                 next if ($suppress_cc{'cc'});
1322                                         }
1323                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1324                                                 $addr, $_) unless $quiet;
1325                                         push @cc, $addr;
1326                                 }
1327                         }
1328                         elsif (/^Content-type:/i) {
1329                                 $has_content_type = 1;
1330                                 if (/charset="?([^ "]+)/) {
1331                                         $body_encoding = $1;
1332                                 }
1333                                 push @xh, $_;
1334                         }
1335                         elsif (/^Message-Id: (.*)/i) {
1336                                 $message_id = $1;
1337                         }
1338                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1339                                 push @xh, $_;
1340                         }
1341
1342                 } else {
1343                         # In the traditional
1344                         # "send lots of email" format,
1345                         # line 1 = cc
1346                         # line 2 = subject
1347                         # So let's support that, too.
1348                         $input_format = 'lots';
1349                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1350                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1351                                         $_, $_) unless $quiet;
1352                                 push @cc, $_;
1353                         } elsif (!defined $subject) {
1354                                 $subject = $_;
1355                         }
1356                 }
1357         }
1358         # Now parse the message body
1359         while(<$fh>) {
1360                 $message .=  $_;
1361                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1362                         chomp;
1363                         my ($what, $c) = ($1, $2);
1364                         chomp $c;
1365                         my $sc = sanitize_address($c);
1366                         if ($sc eq $sender) {
1367                                 next if ($suppress_cc{'self'});
1368                         } else {
1369                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1370                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1371                         }
1372                         push @cc, $c;
1373                         printf("(body) Adding cc: %s from line '%s'\n",
1374                                 $c, $_) unless $quiet;
1375                 }
1376         }
1377         close $fh;
1378
1379         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1380                 if defined $to_cmd;
1381         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1382                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1383
1384         if ($broken_encoding{$t} && !$has_content_type) {
1385                 $has_content_type = 1;
1386                 push @xh, "MIME-Version: 1.0",
1387                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1388                         "Content-Transfer-Encoding: 8bit";
1389                 $body_encoding = $auto_8bit_encoding;
1390         }
1391
1392         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1393                 $subject = quote_subject($subject, $auto_8bit_encoding);
1394         }
1395
1396         if (defined $author and $author ne $sender) {
1397                 $message = "From: $author\n\n$message";
1398                 if (defined $author_encoding) {
1399                         if ($has_content_type) {
1400                                 if ($body_encoding eq $author_encoding) {
1401                                         # ok, we already have the right encoding
1402                                 }
1403                                 else {
1404                                         # uh oh, we should re-encode
1405                                 }
1406                         }
1407                         else {
1408                                 $has_content_type = 1;
1409                                 push @xh,
1410                                   'MIME-Version: 1.0',
1411                                   "Content-Type: text/plain; charset=$author_encoding",
1412                                   'Content-Transfer-Encoding: 8bit';
1413                         }
1414                 }
1415         }
1416
1417         $needs_confirm = (
1418                 $confirm eq "always" or
1419                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1420                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1421         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1422
1423         @to = validate_address_list(sanitize_address_list(@to));
1424         @cc = validate_address_list(sanitize_address_list(@cc));
1425
1426         @to = (@initial_to, @to);
1427         @cc = (@initial_cc, @cc);
1428
1429         my $message_was_sent = send_message();
1430
1431         # set up for the next message
1432         if ($thread && $message_was_sent &&
1433                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1434                 $message_num == 1)) {
1435                 $reply_to = $message_id;
1436                 if (length $references > 0) {
1437                         $references .= "\n $message_id";
1438                 } else {
1439                         $references = "$message_id";
1440                 }
1441         }
1442         $message_id = undef;
1443 }
1444
1445 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1446 # and return a results array
1447 sub recipients_cmd {
1448         my ($prefix, $what, $cmd, $file) = @_;
1449
1450         my @addresses = ();
1451         open my $fh, "-|", "$cmd \Q$file\E"
1452             or die "($prefix) Could not execute '$cmd'";
1453         while (my $address = <$fh>) {
1454                 $address =~ s/^\s*//g;
1455                 $address =~ s/\s*$//g;
1456                 $address = sanitize_address($address);
1457                 next if ($address eq $sender and $suppress_cc{'self'});
1458                 push @addresses, $address;
1459                 printf("($prefix) Adding %s: %s from: '%s'\n",
1460                        $what, $address, $cmd) unless $quiet;
1461                 }
1462         close $fh
1463             or die "($prefix) failed to close pipe to '$cmd'";
1464         return @addresses;
1465 }
1466
1467 cleanup_compose_files();
1468
1469 sub cleanup_compose_files {
1470         unlink($compose_filename, $compose_filename . ".final") if $compose;
1471 }
1472
1473 $smtp->quit if $smtp;
1474
1475 sub unique_email_list {
1476         my %seen;
1477         my @emails;
1478
1479         foreach my $entry (@_) {
1480                 my $clean = extract_valid_address_or_die($entry);
1481                 $seen{$clean} ||= 0;
1482                 next if $seen{$clean}++;
1483                 push @emails, $entry;
1484         }
1485         return @emails;
1486 }
1487
1488 sub validate_patch {
1489         my $fn = shift;
1490         open(my $fh, '<', $fn)
1491                 or die "unable to open $fn: $!\n";
1492         while (my $line = <$fh>) {
1493                 if (length($line) > 998) {
1494                         return "$.: patch contains a line longer than 998 characters";
1495                 }
1496         }
1497         return;
1498 }
1499
1500 sub file_has_nonascii {
1501         my $fn = shift;
1502         open(my $fh, '<', $fn)
1503                 or die "unable to open $fn: $!\n";
1504         while (my $line = <$fh>) {
1505                 return 1 if $line =~ /[^[:ascii:]]/;
1506         }
1507         return 0;
1508 }
1509
1510 sub body_or_subject_has_nonascii {
1511         my $fn = shift;
1512         open(my $fh, '<', $fn)
1513                 or die "unable to open $fn: $!\n";
1514         while (my $line = <$fh>) {
1515                 last if $line =~ /^$/;
1516                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1517         }
1518         while (my $line = <$fh>) {
1519                 return 1 if $line =~ /[^[:ascii:]]/;
1520         }
1521         return 0;
1522 }