git.oblomov.eu Git - git/blob - git-gui/git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [string map [list (c) \u00a9] {
  14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, see <http://www.gnu.org/licenses/>.}]
  28
  29 ######################################################################
  30 ##
  31 ## Tcl/Tk sanity check
  32
  33 if {[catch {package require Tcl 8.4} err]
  34  || [catch {package require Tk  8.4} err]
  35 } {
  36         catch {wm withdraw .}
  37         tk_messageBox \
  38                 -icon error \
  39                 -type ok \
  40                 -title "git-gui: fatal error" \
  41                 -message $err
  42         exit 1
  43 }
  44
  45 catch {rename send {}} ; # What an evil concept...
  46
  47 ######################################################################
  48 ##
  49 ## locate our library
  50
  51 if { [info exists ::env(GIT_GUI_LIB_DIR) ] } {
  52         set oguilib $::env(GIT_GUI_LIB_DIR)
  53 } else {
  54         set oguilib {@@GITGUI_LIBDIR@@}
  55 }
  56 set oguirel {@@GITGUI_RELATIVE@@}
  57 if {$oguirel eq {1}} {
  58         set oguilib [file dirname [file normalize $argv0]]
  59         if {[file tail $oguilib] eq {git-core}} {
  60                 set oguilib [file dirname $oguilib]
  61         }
  62         set oguilib [file dirname $oguilib]
  63         set oguilib [file join $oguilib share git-gui lib]
  64         set oguimsg [file join $oguilib msgs]
  65 } elseif {[string match @@* $oguirel]} {
  66         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  67         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  68 } else {
  69         set oguimsg [file join $oguilib msgs]
  70 }
  71 unset oguirel
  72
  73 ######################################################################
  74 ##
  75 ## enable verbose loading?
  76
  77 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  78         unset _verbose
  79         rename auto_load real__auto_load
  80         proc auto_load {name args} {
  81                 puts stderr "auto_load $name"
  82                 return [uplevel 1 real__auto_load $name $args]
  83         }
  84         rename source real__source
  85         proc source {args} {
  86                 puts stderr "source    $args"
  87                 uplevel 1 [linsert $args 0 real__source]
  88         }
  89         if {[tk windowingsystem] eq "win32"} { console show }
  90 }
  91
  92 ######################################################################
  93 ##
  94 ## Internationalization (i18n) through msgcat and gettext. See
  95 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  96
  97 package require msgcat
  98
  99 # Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
 100 if {[tk windowingsystem] eq "win32"
 101         && [package vcompare [package provide msgcat] 1.4.4] < 0
 102 } then {
 103         proc _mc_update_locale {} {
 104                 set key {HKEY_CURRENT_USER\Control Panel\Desktop}
 105                 if {![catch {
 106                         package require registry
 107                         set uilocale [registry get $key "PreferredUILanguages"]
 108                         msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
 109                 } uilocale]} {
 110                         if {[string length $uilocale] > 0} {
 111                                 msgcat::mclocale $uilocale
 112                         }
 113                 }
 114         }
 115         _mc_update_locale
 116 }
 117
 118 proc _mc_trim {fmt} {
 119         set cmk [string first @@ $fmt]
 120         if {$cmk > 0} {
 121                 return [string range $fmt 0 [expr {$cmk - 1}]]
 122         }
 123         return $fmt
 124 }
 125
 126 proc mc {en_fmt args} {
 127         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 128         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 129                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 130         }
 131         return $msg
 132 }
 133
 134 proc strcat {args} {
 135         return [join $args {}]
 136 }
 137
 138 ::msgcat::mcload $oguimsg
 139 unset oguimsg
 140
 141 ######################################################################
 142 ##
 143 ## On Mac, bring the current Wish process window to front
 144
 145 if {[tk windowingsystem] eq "aqua"} {
 146         catch {
 147                 exec osascript -e [format {
 148                         tell application "System Events"
 149                                 set frontmost of processes whose unix id is %d to true
 150                         end tell
 151                 } [pid]]
 152         }
 153 }
 154
 155 ######################################################################
 156 ##
 157 ## read only globals
 158
 159 set _appname {Git Gui}
 160 set _gitdir {}
 161 set _gitworktree {}
 162 set _isbare {}
 163 set _gitexec {}
 164 set _githtmldir {}
 165 set _reponame {}
 166 set _iscygwin {}
 167 set _search_path {}
 168 set _shellpath {@@SHELL_PATH@@}
 169
 170 set _trace [lsearch -exact $argv --trace]
 171 if {$_trace >= 0} {
 172         set argv [lreplace $argv $_trace $_trace]
 173         set _trace 1
 174         if {[tk windowingsystem] eq "win32"} { console show }
 175 } else {
 176         set _trace 0
 177 }
 178
 179 # variable for the last merged branch (useful for a default when deleting
 180 # branches).
 181 set _last_merged_branch {}
 182
 183 proc shellpath {} {
 184         global _shellpath env
 185         if {[string match @@* $_shellpath]} {
 186                 if {[info exists env(SHELL)]} {
 187                         return $env(SHELL)
 188                 } else {
 189                         return /bin/sh
 190                 }
 191         }
 192         return $_shellpath
 193 }
 194
 195 proc appname {} {
 196         global _appname
 197         return $_appname
 198 }
 199
 200 proc gitdir {args} {
 201         global _gitdir
 202         if {$args eq {}} {
 203                 return $_gitdir
 204         }
 205         return [eval [list file join $_gitdir] $args]
 206 }
 207
 208 proc gitexec {args} {
 209         global _gitexec
 210         if {$_gitexec eq {}} {
 211                 if {[catch {set _gitexec [git --exec-path]} err]} {
 212                         error "Git not installed?\n\n$err"
 213                 }
 214                 if {[is_Cygwin]} {
 215                         set _gitexec [exec cygpath \
 216                                 --windows \
 217                                 --absolute \
 218                                 $_gitexec]
 219                 } else {
 220                         set _gitexec [file normalize $_gitexec]
 221                 }
 222         }
 223         if {$args eq {}} {
 224                 return $_gitexec
 225         }
 226         return [eval [list file join $_gitexec] $args]
 227 }
 228
 229 proc githtmldir {args} {
 230         global _githtmldir
 231         if {$_githtmldir eq {}} {
 232                 if {[catch {set _githtmldir [git --html-path]}]} {
 233                         # Git not installed or option not yet supported
 234                         return {}
 235                 }
 236                 if {[is_Cygwin]} {
 237                         set _githtmldir [exec cygpath \
 238                                 --windows \
 239                                 --absolute \
 240                                 $_githtmldir]
 241                 } else {
 242                         set _githtmldir [file normalize $_githtmldir]
 243                 }
 244         }
 245         if {$args eq {}} {
 246                 return $_githtmldir
 247         }
 248         return [eval [list file join $_githtmldir] $args]
 249 }
 250
 251 proc reponame {} {
 252         return $::_reponame
 253 }
 254
 255 proc is_MacOSX {} {
 256         if {[tk windowingsystem] eq {aqua}} {
 257                 return 1
 258         }
 259         return 0
 260 }
 261
 262 proc is_Windows {} {
 263         if {$::tcl_platform(platform) eq {windows}} {
 264                 return 1
 265         }
 266         return 0
 267 }
 268
 269 proc is_Cygwin {} {
 270         global _iscygwin
 271         if {$_iscygwin eq {}} {
 272                 if {$::tcl_platform(platform) eq {windows}} {
 273                         if {[catch {set p [exec cygpath --windir]} err]} {
 274                                 set _iscygwin 0
 275                         } else {
 276                                 set _iscygwin 1
 277                                 # Handle MSys2 which is only cygwin when MSYSTEM is MSYS.
 278                                 if {[info exists ::env(MSYSTEM)] && $::env(MSYSTEM) ne "MSYS"} {
 279                                         set _iscygwin 0
 280                                 }
 281                         }
 282                 } else {
 283                         set _iscygwin 0
 284                 }
 285         }
 286         return $_iscygwin
 287 }
 288
 289 proc is_enabled {option} {
 290         global enabled_options
 291         if {[catch {set on $enabled_options($option)}]} {return 0}
 292         return $on
 293 }
 294
 295 proc enable_option {option} {
 296         global enabled_options
 297         set enabled_options($option) 1
 298 }
 299
 300 proc disable_option {option} {
 301         global enabled_options
 302         set enabled_options($option) 0
 303 }
 304
 305 ######################################################################
 306 ##
 307 ## config
 308
 309 proc is_many_config {name} {
 310         switch -glob -- $name {
 311         gui.recentrepo -
 312         remote.*.fetch -
 313         remote.*.push
 314                 {return 1}
 315         *
 316                 {return 0}
 317         }
 318 }
 319
 320 proc is_config_true {name} {
 321         global repo_config
 322         if {[catch {set v $repo_config($name)}]} {
 323                 return 0
 324         }
 325         set v [string tolower $v]
 326         if {$v eq {} || $v eq {true} || $v eq {1} || $v eq {yes} || $v eq {on}} {
 327                 return 1
 328         } else {
 329                 return 0
 330         }
 331 }
 332
 333 proc is_config_false {name} {
 334         global repo_config
 335         if {[catch {set v $repo_config($name)}]} {
 336                 return 0
 337         }
 338         set v [string tolower $v]
 339         if {$v eq {false} || $v eq {0} || $v eq {no} || $v eq {off}} {
 340                 return 1
 341         } else {
 342                 return 0
 343         }
 344 }
 345
 346 proc get_config {name} {
 347         global repo_config
 348         if {[catch {set v $repo_config($name)}]} {
 349                 return {}
 350         } else {
 351                 return $v
 352         }
 353 }
 354
 355 proc is_bare {} {
 356         global _isbare
 357         global _gitdir
 358         global _gitworktree
 359
 360         if {$_isbare eq {}} {
 361                 if {[catch {
 362                         set _bare [git rev-parse --is-bare-repository]
 363                         switch  -- $_bare {
 364                         true { set _isbare 1 }
 365                         false { set _isbare 0}
 366                         default { throw }
 367                         }
 368                 }]} {
 369                         if {[is_config_true core.bare]
 370                                 || ($_gitworktree eq {}
 371                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 372                                 set _isbare 1
 373                         } else {
 374                                 set _isbare 0
 375                         }
 376                 }
 377         }
 378         return $_isbare
 379 }
 380
 381 ######################################################################
 382 ##
 383 ## handy utils
 384
 385 proc _trace_exec {cmd} {
 386         if {!$::_trace} return
 387         set d {}
 388         foreach v $cmd {
 389                 if {$d ne {}} {
 390                         append d { }
 391                 }
 392                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 393                         set v [sq $v]
 394                 }
 395                 append d $v
 396         }
 397         puts stderr $d
 398 }
 399
 400 #'"  fix poor old emacs font-lock mode
 401
 402 proc _git_cmd {name} {
 403         global _git_cmd_path
 404
 405         if {[catch {set v $_git_cmd_path($name)}]} {
 406                 switch -- $name {
 407                   version   -
 408                 --version   -
 409                 --exec-path { return [list $::_git $name] }
 410                 }
 411
 412                 set p [gitexec git-$name$::_search_exe]
 413                 if {[file exists $p]} {
 414                         set v [list $p]
 415                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 416                         # Try to determine what sort of magic will make
 417                         # git-$name go and do its thing, because native
 418                         # Tcl on Windows doesn't know it.
 419                         #
 420                         set p [gitexec git-$name]
 421                         set f [open $p r]
 422                         set s [gets $f]
 423                         close $f
 424
 425                         switch -glob -- [lindex $s 0] {
 426                         #!*sh     { set i sh     }
 427                         #!*perl   { set i perl   }
 428                         #!*python { set i python }
 429                         default   { error "git-$name is not supported: $s" }
 430                         }
 431
 432                         upvar #0 _$i interp
 433                         if {![info exists interp]} {
 434                                 set interp [_which $i]
 435                         }
 436                         if {$interp eq {}} {
 437                                 error "git-$name requires $i (not in PATH)"
 438                         }
 439                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 440                 } else {
 441                         # Assume it is builtin to git somehow and we
 442                         # aren't actually able to see a file for it.
 443                         #
 444                         set v [list $::_git $name]
 445                 }
 446                 set _git_cmd_path($name) $v
 447         }
 448         return $v
 449 }
 450
 451 proc _which {what args} {
 452         global env _search_exe _search_path
 453
 454         if {$_search_path eq {}} {
 455                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 456                         set _search_path [split [exec cygpath \
 457                                 --windows \
 458                                 --path \
 459                                 --absolute \
 460                                 $env(PATH)] {;}]
 461                         set _search_exe .exe
 462                 } elseif {[is_Windows]} {
 463                         set gitguidir [file dirname [info script]]
 464                         regsub -all ";" $gitguidir "\\;" gitguidir
 465                         set env(PATH) "$gitguidir;$env(PATH)"
 466                         set _search_path [split $env(PATH) {;}]
 467                         set _search_exe .exe
 468                 } else {
 469                         set _search_path [split $env(PATH) :]
 470                         set _search_exe {}
 471                 }
 472         }
 473
 474         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 475                 set suffix {}
 476         } else {
 477                 set suffix $_search_exe
 478         }
 479
 480         foreach p $_search_path {
 481                 set p [file join $p $what$suffix]
 482                 if {[file exists $p]} {
 483                         return [file normalize $p]
 484                 }
 485         }
 486         return {}
 487 }
 488
 489 # Test a file for a hashbang to identify executable scripts on Windows.
 490 proc is_shellscript {filename} {
 491         if {![file exists $filename]} {return 0}
 492         set f [open $filename r]
 493         fconfigure $f -encoding binary
 494         set magic [read $f 2]
 495         close $f
 496         return [expr {$magic eq "#!"}]
 497 }
 498
 499 # Run a command connected via pipes on stdout.
 500 # This is for use with textconv filters and uses sh -c "..." to allow it to
 501 # contain a command with arguments. On windows we must check for shell
 502 # scripts specifically otherwise just call the filter command.
 503 proc open_cmd_pipe {cmd path} {
 504         global env
 505         if {![file executable [shellpath]]} {
 506                 set exe [auto_execok [lindex $cmd 0]]
 507                 if {[is_shellscript [lindex $exe 0]]} {
 508                         set run [linsert [auto_execok sh] end -c "$cmd \"\$0\"" $path]
 509                 } else {
 510                         set run [concat $exe [lrange $cmd 1 end] $path]
 511                 }
 512         } else {
 513                 set run [list [shellpath] -c "$cmd \"\$0\"" $path]
 514         }
 515         return [open |$run r]
 516 }
 517
 518 proc _lappend_nice {cmd_var} {
 519         global _nice
 520         upvar $cmd_var cmd
 521
 522         if {![info exists _nice]} {
 523                 set _nice [_which nice]
 524                 if {[catch {exec $_nice git version}]} {
 525                         set _nice {}
 526                 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 527                         set _nice {}
 528                 }
 529         }
 530         if {$_nice ne {}} {
 531                 lappend cmd $_nice
 532         }
 533 }
 534
 535 proc git {args} {
 536         set fd [eval [list git_read] $args]
 537         fconfigure $fd -translation binary -encoding utf-8
 538         set result [string trimright [read $fd] "\n"]
 539         close $fd
 540         if {$::_trace} {
 541                 puts stderr "< $result"
 542         }
 543         return $result
 544 }
 545
 546 proc _open_stdout_stderr {cmd} {
 547         _trace_exec $cmd
 548         if {[catch {
 549                         set fd [open [concat [list | ] $cmd] r]
 550                 } err]} {
 551                 if {   [lindex $cmd end] eq {2>@1}
 552                     && $err eq {can not find channel named "1"}
 553                         } {
 554                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 555                         # redirect operator.  Fallback to |& cat for those.
 556                         # The command was not actually started, so its safe
 557                         # to try to start it a second time.
 558                         #
 559                         set fd [open [concat \
 560                                 [list | ] \
 561                                 [lrange $cmd 0 end-1] \
 562                                 [list |& cat] \
 563                                 ] r]
 564                 } else {
 565                         error $err
 566                 }
 567         }
 568         fconfigure $fd -eofchar {}
 569         return $fd
 570 }
 571
 572 proc git_read {args} {
 573         set opt [list]
 574
 575         while {1} {
 576                 switch -- [lindex $args 0] {
 577                 --nice {
 578                         _lappend_nice opt
 579                 }
 580
 581                 --stderr {
 582                         lappend args 2>@1
 583                 }
 584
 585                 default {
 586                         break
 587                 }
 588
 589                 }
 590
 591                 set args [lrange $args 1 end]
 592         }
 593
 594         set cmdp [_git_cmd [lindex $args 0]]
 595         set args [lrange $args 1 end]
 596
 597         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 598 }
 599
 600 proc git_write {args} {
 601         set opt [list]
 602
 603         while {1} {
 604                 switch -- [lindex $args 0] {
 605                 --nice {
 606                         _lappend_nice opt
 607                 }
 608
 609                 default {
 610                         break
 611                 }
 612
 613                 }
 614
 615                 set args [lrange $args 1 end]
 616         }
 617
 618         set cmdp [_git_cmd [lindex $args 0]]
 619         set args [lrange $args 1 end]
 620
 621         _trace_exec [concat $opt $cmdp $args]
 622         return [open [concat [list | ] $opt $cmdp $args] w]
 623 }
 624
 625 proc githook_read {hook_name args} {
 626         set pchook [gitdir hooks $hook_name]
 627         lappend args 2>@1
 628
 629         # On Windows [file executable] might lie so we need to ask
 630         # the shell if the hook is executable.  Yes that's annoying.
 631         #
 632         if {[is_Windows]} {
 633                 upvar #0 _sh interp
 634                 if {![info exists interp]} {
 635                         set interp [_which sh]
 636                 }
 637                 if {$interp eq {}} {
 638                         error "hook execution requires sh (not in PATH)"
 639                 }
 640
 641                 set scr {if test -x "$1";then exec "$@";fi}
 642                 set sh_c [list $interp -c $scr $interp $pchook]
 643                 return [_open_stdout_stderr [concat $sh_c $args]]
 644         }
 645
 646         if {[file executable $pchook]} {
 647                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 648         }
 649
 650         return {}
 651 }
 652
 653 proc kill_file_process {fd} {
 654         set process [pid $fd]
 655
 656         catch {
 657                 if {[is_Windows]} {
 658                         exec taskkill /pid $process
 659                 } else {
 660                         exec kill $process
 661                 }
 662         }
 663 }
 664
 665 proc gitattr {path attr default} {
 666         if {[catch {set r [git check-attr $attr -- $path]}]} {
 667                 set r unspecified
 668         } else {
 669                 set r [join [lrange [split $r :] 2 end] :]
 670                 regsub {^ } $r {} r
 671         }
 672         if {$r eq {unspecified}} {
 673                 return $default
 674         }
 675         return $r
 676 }
 677
 678 proc sq {value} {
 679         regsub -all ' $value "'\\''" value
 680         return "'$value'"
 681 }
 682
 683 proc load_current_branch {} {
 684         global current_branch is_detached
 685
 686         set fd [open [gitdir HEAD] r]
 687         if {[gets $fd ref] < 1} {
 688                 set ref {}
 689         }
 690         close $fd
 691
 692         set pfx {ref: refs/heads/}
 693         set len [string length $pfx]
 694         if {[string equal -length $len $pfx $ref]} {
 695                 # We're on a branch.  It might not exist.  But
 696                 # HEAD looks good enough to be a branch.
 697                 #
 698                 set current_branch [string range $ref $len end]
 699                 set is_detached 0
 700         } else {
 701                 # Assume this is a detached head.
 702                 #
 703                 set current_branch HEAD
 704                 set is_detached 1
 705         }
 706 }
 707
 708 auto_load tk_optionMenu
 709 rename tk_optionMenu real__tkOptionMenu
 710 proc tk_optionMenu {w varName args} {
 711         set m [eval real__tkOptionMenu $w $varName $args]
 712         $m configure -font font_ui
 713         $w configure -font font_ui
 714         return $m
 715 }
 716
 717 proc rmsel_tag {text} {
 718         $text tag conf sel \
 719                 -background [$text cget -background] \
 720                 -foreground [$text cget -foreground] \
 721                 -borderwidth 0
 722         $text tag conf in_sel -background lightgray
 723         bind $text <Motion> break
 724         return $text
 725 }
 726
 727 wm withdraw .
 728 set root_exists 0
 729 bind . <Visibility> {
 730         bind . <Visibility> {}
 731         set root_exists 1
 732 }
 733
 734 if {[is_Windows]} {
 735         wm iconbitmap . -default $oguilib/git-gui.ico
 736         set ::tk::AlwaysShowSelection 1
 737         bind . <Control-F2> {console show}
 738
 739         # Spoof an X11 display for SSH
 740         if {![info exists env(DISPLAY)]} {
 741                 set env(DISPLAY) :9999
 742         }
 743 } else {
 744         catch {
 745                 image create photo gitlogo -width 16 -height 16
 746
 747                 gitlogo put #33CC33 -to  7  0  9  2
 748                 gitlogo put #33CC33 -to  4  2 12  4
 749                 gitlogo put #33CC33 -to  7  4  9  6
 750                 gitlogo put #CC3333 -to  4  6 12  8
 751                 gitlogo put gray26  -to  4  9  6 10
 752                 gitlogo put gray26  -to  3 10  6 12
 753                 gitlogo put gray26  -to  8  9 13 11
 754                 gitlogo put gray26  -to  8 11 10 12
 755                 gitlogo put gray26  -to 11 11 13 14
 756                 gitlogo put gray26  -to  3 12  5 14
 757                 gitlogo put gray26  -to  5 13
 758                 gitlogo put gray26  -to 10 13
 759                 gitlogo put gray26  -to  4 14 12 15
 760                 gitlogo put gray26  -to  5 15 11 16
 761                 gitlogo redither
 762
 763                 image create photo gitlogo32 -width 32 -height 32
 764                 gitlogo32 copy gitlogo -zoom 2 2
 765
 766                 wm iconphoto . -default gitlogo gitlogo32
 767         }
 768 }
 769
 770 ######################################################################
 771 ##
 772 ## config defaults
 773
 774 set cursor_ptr arrow
 775 font create font_ui
 776 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 777         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 778         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 779 } else {
 780         font create font_diff -family Courier -size 10
 781         catch {
 782                 label .dummy
 783                 eval font configure font_ui [font actual [.dummy cget -font]]
 784                 destroy .dummy
 785         }
 786 }
 787
 788 font create font_uiitalic
 789 font create font_uibold
 790 font create font_diffbold
 791 font create font_diffitalic
 792
 793 foreach class {Button Checkbutton Entry Label
 794                 Labelframe Listbox Message
 795                 Radiobutton Spinbox Text} {
 796         option add *$class.font font_ui
 797 }
 798 if {![is_MacOSX]} {
 799         option add *Menu.font font_ui
 800         option add *Entry.borderWidth 1 startupFile
 801         option add *Entry.relief sunken startupFile
 802         option add *RadioButton.anchor w startupFile
 803 }
 804 unset class
 805
 806 if {[is_Windows] || [is_MacOSX]} {
 807         option add *Menu.tearOff 0
 808 }
 809
 810 if {[is_MacOSX]} {
 811         set M1B M1
 812         set M1T Cmd
 813 } else {
 814         set M1B Control
 815         set M1T Ctrl
 816 }
 817
 818 proc bind_button3 {w cmd} {
 819         bind $w <Any-Button-3> $cmd
 820         if {[is_MacOSX]} {
 821                 # Mac OS X sends Button-2 on right click through three-button mouse,
 822                 # or through trackpad right-clicking (two-finger touch + click).
 823                 bind $w <Any-Button-2> $cmd
 824                 bind $w <Control-Button-1> $cmd
 825         }
 826 }
 827
 828 proc apply_config {} {
 829         global repo_config font_descs
 830
 831         foreach option $font_descs {
 832                 set name [lindex $option 0]
 833                 set font [lindex $option 1]
 834                 if {[catch {
 835                         set need_weight 1
 836                         foreach {cn cv} $repo_config(gui.$name) {
 837                                 if {$cn eq {-weight}} {
 838                                         set need_weight 0
 839                                 }
 840                                 font configure $font $cn $cv
 841                         }
 842                         if {$need_weight} {
 843                                 font configure $font -weight normal
 844                         }
 845                         } err]} {
 846                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 847                 }
 848                 foreach {cn cv} [font configure $font] {
 849                         font configure ${font}bold $cn $cv
 850                         font configure ${font}italic $cn $cv
 851                 }
 852                 font configure ${font}bold -weight bold
 853                 font configure ${font}italic -slant italic
 854         }
 855
 856         global use_ttk NS
 857         set use_ttk 0
 858         set NS {}
 859         if {$repo_config(gui.usettk)} {
 860                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 861                 if {$use_ttk} {
 862                         set NS ttk
 863                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 864                         pave_toplevel .
 865                 }
 866         }
 867 }
 868
 869 set default_config(branch.autosetupmerge) true
 870 set default_config(merge.tool) {}
 871 set default_config(mergetool.keepbackup) true
 872 set default_config(merge.diffstat) true
 873 set default_config(merge.summary) false
 874 set default_config(merge.verbosity) 2
 875 set default_config(user.name) {}
 876 set default_config(user.email) {}
 877
 878 set default_config(gui.encoding) [encoding system]
 879 set default_config(gui.matchtrackingbranch) false
 880 set default_config(gui.textconv) true
 881 set default_config(gui.pruneduringfetch) false
 882 set default_config(gui.trustmtime) false
 883 set default_config(gui.fastcopyblame) false
 884 set default_config(gui.maxrecentrepo) 10
 885 set default_config(gui.copyblamethreshold) 40
 886 set default_config(gui.blamehistoryctx) 7
 887 set default_config(gui.diffcontext) 5
 888 set default_config(gui.diffopts) {}
 889 set default_config(gui.commitmsgwidth) 75
 890 set default_config(gui.newbranchtemplate) {}
 891 set default_config(gui.spellingdictionary) {}
 892 set default_config(gui.fontui) [font configure font_ui]
 893 set default_config(gui.fontdiff) [font configure font_diff]
 894 # TODO: this option should be added to the git-config documentation
 895 set default_config(gui.maxfilesdisplayed) 5000
 896 set default_config(gui.usettk) 1
 897 set default_config(gui.warndetachedcommit) 1
 898 set default_config(gui.tabsize) 8
 899 set font_descs {
 900         {fontui   font_ui   {mc "Main Font"}}
 901         {fontdiff font_diff {mc "Diff/Console Font"}}
 902 }
 903 set default_config(gui.stageuntracked) ask
 904 set default_config(gui.displayuntracked) true
 905
 906 ######################################################################
 907 ##
 908 ## find git
 909
 910 set _git  [_which git]
 911 if {$_git eq {}} {
 912         catch {wm withdraw .}
 913         tk_messageBox \
 914                 -icon error \
 915                 -type ok \
 916                 -title [mc "git-gui: fatal error"] \
 917                 -message [mc "Cannot find git in PATH."]
 918         exit 1
 919 }
 920
 921 ######################################################################
 922 ##
 923 ## version check
 924
 925 if {[catch {set _git_version [git --version]} err]} {
 926         catch {wm withdraw .}
 927         tk_messageBox \
 928                 -icon error \
 929                 -type ok \
 930                 -title [mc "git-gui: fatal error"] \
 931                 -message "Cannot determine Git version:
 932
 933 $err
 934
 935 [appname] requires Git 1.5.0 or later."
 936         exit 1
 937 }
 938 if {![regsub {^git version } $_git_version {} _git_version]} {
 939         catch {wm withdraw .}
 940         tk_messageBox \
 941                 -icon error \
 942                 -type ok \
 943                 -title [mc "git-gui: fatal error"] \
 944                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 945         exit 1
 946 }
 947
 948 proc get_trimmed_version {s} {
 949     set r {}
 950     foreach x [split $s -._] {
 951         if {[string is integer -strict $x]} {
 952             lappend r $x
 953         } else {
 954             break
 955         }
 956     }
 957     return [join $r .]
 958 }
 959 set _real_git_version $_git_version
 960 set _git_version [get_trimmed_version $_git_version]
 961
 962 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 963         catch {wm withdraw .}
 964         if {[tk_messageBox \
 965                 -icon warning \
 966                 -type yesno \
 967                 -default no \
 968                 -title "[appname]: warning" \
 969                  -message [mc "Git version cannot be determined.
 970
 971 %s claims it is version '%s'.
 972
 973 %s requires at least Git 1.5.0 or later.
 974
 975 Assume '%s' is version 1.5.0?
 976 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 977                 set _git_version 1.5.0
 978         } else {
 979                 exit 1
 980         }
 981 }
 982 unset _real_git_version
 983
 984 proc git-version {args} {
 985         global _git_version
 986
 987         switch [llength $args] {
 988         0 {
 989                 return $_git_version
 990         }
 991
 992         2 {
 993                 set op [lindex $args 0]
 994                 set vr [lindex $args 1]
 995                 set cm [package vcompare $_git_version $vr]
 996                 return [expr $cm $op 0]
 997         }
 998
 999         4 {
1000                 set type [lindex $args 0]
1001                 set name [lindex $args 1]
1002                 set parm [lindex $args 2]
1003                 set body [lindex $args 3]
1004
1005                 if {($type ne {proc} && $type ne {method})} {
1006                         error "Invalid arguments to git-version"
1007                 }
1008                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
1009                         error "Last arm of $type $name must be default"
1010                 }
1011
1012                 foreach {op vr cb} [lrange $body 0 end-2] {
1013                         if {[git-version $op $vr]} {
1014                                 return [uplevel [list $type $name $parm $cb]]
1015                         }
1016                 }
1017
1018                 return [uplevel [list $type $name $parm [lindex $body end]]]
1019         }
1020
1021         default {
1022                 error "git-version >= x"
1023         }
1024
1025         }
1026 }
1027
1028 if {[git-version < 1.5]} {
1029         catch {wm withdraw .}
1030         tk_messageBox \
1031                 -icon error \
1032                 -type ok \
1033                 -title [mc "git-gui: fatal error"] \
1034                 -message "[appname] requires Git 1.5.0 or later.
1035
1036 You are using [git-version]:
1037
1038 [git --version]"
1039         exit 1
1040 }
1041
1042 ######################################################################
1043 ##
1044 ## configure our library
1045
1046 set idx [file join $oguilib tclIndex]
1047 if {[catch {set fd [open $idx r]} err]} {
1048         catch {wm withdraw .}
1049         tk_messageBox \
1050                 -icon error \
1051                 -type ok \
1052                 -title [mc "git-gui: fatal error"] \
1053                 -message $err
1054         exit 1
1055 }
1056 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1057         set idx [list]
1058         while {[gets $fd n] >= 0} {
1059                 if {$n ne {} && ![string match #* $n]} {
1060                         lappend idx $n
1061                 }
1062         }
1063 } else {
1064         set idx {}
1065 }
1066 close $fd
1067
1068 if {$idx ne {}} {
1069         set loaded [list]
1070         foreach p $idx {
1071                 if {[lsearch -exact $loaded $p] >= 0} continue
1072                 source [file join $oguilib $p]
1073                 lappend loaded $p
1074         }
1075         unset loaded p
1076 } else {
1077         set auto_path [concat [list $oguilib] $auto_path]
1078 }
1079 unset -nocomplain idx fd
1080
1081 ######################################################################
1082 ##
1083 ## config file parsing
1084
1085 git-version proc _parse_config {arr_name args} {
1086         >= 1.5.3 {
1087                 upvar $arr_name arr
1088                 array unset arr
1089                 set buf {}
1090                 catch {
1091                         set fd_rc [eval \
1092                                 [list git_read config] \
1093                                 $args \
1094                                 [list --null --list]]
1095                         fconfigure $fd_rc -translation binary -encoding utf-8
1096                         set buf [read $fd_rc]
1097                         close $fd_rc
1098                 }
1099                 foreach line [split $buf "\0"] {
1100                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1101                                 if {[is_many_config $name]} {
1102                                         lappend arr($name) $value
1103                                 } else {
1104                                         set arr($name) $value
1105                                 }
1106                         } elseif {[regexp {^([^\n]+)$} $line line name]} {
1107                                 # no value given, but interpreting them as
1108                                 # boolean will be handled as true
1109                                 set arr($name) {}
1110                         }
1111                 }
1112         }
1113         default {
1114                 upvar $arr_name arr
1115                 array unset arr
1116                 catch {
1117                         set fd_rc [eval [list git_read config --list] $args]
1118                         while {[gets $fd_rc line] >= 0} {
1119                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1120                                         if {[is_many_config $name]} {
1121                                                 lappend arr($name) $value
1122                                         } else {
1123                                                 set arr($name) $value
1124                                         }
1125                                 } elseif {[regexp {^([^=]+)$} $line line name]} {
1126                                         # no value given, but interpreting them as
1127                                         # boolean will be handled as true
1128                                         set arr($name) {}
1129                                 }
1130                         }
1131                         close $fd_rc
1132                 }
1133         }
1134 }
1135
1136 proc load_config {include_global} {
1137         global repo_config global_config system_config default_config
1138
1139         if {$include_global} {
1140                 _parse_config system_config --system
1141                 _parse_config global_config --global
1142         }
1143         _parse_config repo_config
1144
1145         foreach name [array names default_config] {
1146                 if {[catch {set v $system_config($name)}]} {
1147                         set system_config($name) $default_config($name)
1148                 }
1149         }
1150         foreach name [array names system_config] {
1151                 if {[catch {set v $global_config($name)}]} {
1152                         set global_config($name) $system_config($name)
1153                 }
1154                 if {[catch {set v $repo_config($name)}]} {
1155                         set repo_config($name) $system_config($name)
1156                 }
1157         }
1158 }
1159
1160 ######################################################################
1161 ##
1162 ## feature option selection
1163
1164 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1165         unset _junk
1166 } else {
1167         set subcommand gui
1168 }
1169 if {$subcommand eq {gui.sh}} {
1170         set subcommand gui
1171 }
1172 if {$subcommand eq {gui} && [llength $argv] > 0} {
1173         set subcommand [lindex $argv 0]
1174         set argv [lrange $argv 1 end]
1175 }
1176
1177 enable_option multicommit
1178 enable_option branch
1179 enable_option transport
1180 disable_option bare
1181
1182 switch -- $subcommand {
1183 browser -
1184 blame {
1185         enable_option bare
1186
1187         disable_option multicommit
1188         disable_option branch
1189         disable_option transport
1190 }
1191 citool {
1192         enable_option singlecommit
1193         enable_option retcode
1194
1195         disable_option multicommit
1196         disable_option branch
1197         disable_option transport
1198
1199         while {[llength $argv] > 0} {
1200                 set a [lindex $argv 0]
1201                 switch -- $a {
1202                 --amend {
1203                         enable_option initialamend
1204                 }
1205                 --nocommit {
1206                         enable_option nocommit
1207                         enable_option nocommitmsg
1208                 }
1209                 --commitmsg {
1210                         disable_option nocommitmsg
1211                 }
1212                 default {
1213                         break
1214                 }
1215                 }
1216
1217                 set argv [lrange $argv 1 end]
1218         }
1219 }
1220 }
1221
1222 ######################################################################
1223 ##
1224 ## execution environment
1225
1226 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1227
1228 # Suggest our implementation of askpass, if none is set
1229 if {![info exists env(SSH_ASKPASS)]} {
1230         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1231 }
1232
1233 ######################################################################
1234 ##
1235 ## repository setup
1236
1237 set picked 0
1238 if {[catch {
1239                 set _gitdir $env(GIT_DIR)
1240                 set _prefix {}
1241                 }]
1242         && [catch {
1243                 # beware that from the .git dir this sets _gitdir to .
1244                 # and _prefix to the empty string
1245                 set _gitdir [git rev-parse --git-dir]
1246                 set _prefix [git rev-parse --show-prefix]
1247         } err]} {
1248         load_config 1
1249         apply_config
1250         choose_repository::pick
1251         set picked 1
1252 }
1253
1254 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1255 # run from the .git dir itself) lest the routines to find the worktree
1256 # get confused
1257 if {$_gitdir eq "."} {
1258         set _gitdir [pwd]
1259 }
1260
1261 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1262         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1263 }
1264 if {![file isdirectory $_gitdir]} {
1265         catch {wm withdraw .}
1266         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1267         exit 1
1268 }
1269 # _gitdir exists, so try loading the config
1270 load_config 0
1271 apply_config
1272
1273 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1274 if {[package vcompare $_git_version 1.7.0] >= 0} {
1275         if { [is_Cygwin] } {
1276                 catch {set _gitworktree [exec cygpath --windows [git rev-parse --show-toplevel]]}
1277         } else {
1278                 set _gitworktree [git rev-parse --show-toplevel]
1279         }
1280 } else {
1281         # try to set work tree from environment, core.worktree or use
1282         # cdup to obtain a relative path to the top of the worktree. If
1283         # run from the top, the ./ prefix ensures normalize expands pwd.
1284         if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1285                 set _gitworktree [get_config core.worktree]
1286                 if {$_gitworktree eq ""} {
1287                         set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1288                 }
1289         }
1290 }
1291
1292 if {$_prefix ne {}} {
1293         if {$_gitworktree eq {}} {
1294                 regsub -all {[^/]+/} $_prefix ../ cdup
1295         } else {
1296                 set cdup $_gitworktree
1297         }
1298         if {[catch {cd $cdup} err]} {
1299                 catch {wm withdraw .}
1300                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1301                 exit 1
1302         }
1303         set _gitworktree [pwd]
1304         unset cdup
1305 } elseif {![is_enabled bare]} {
1306         if {[is_bare]} {
1307                 catch {wm withdraw .}
1308                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1309                 exit 1
1310         }
1311         if {$_gitworktree eq {}} {
1312                 set _gitworktree [file dirname $_gitdir]
1313         }
1314         if {[catch {cd $_gitworktree} err]} {
1315                 catch {wm withdraw .}
1316                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1317                 exit 1
1318         }
1319         set _gitworktree [pwd]
1320 }
1321 set _reponame [file split [file normalize $_gitdir]]
1322 if {[lindex $_reponame end] eq {.git}} {
1323         set _reponame [lindex $_reponame end-1]
1324 } else {
1325         set _reponame [lindex $_reponame end]
1326 }
1327
1328 set env(GIT_DIR) $_gitdir
1329 set env(GIT_WORK_TREE) $_gitworktree
1330
1331 ######################################################################
1332 ##
1333 ## global init
1334
1335 set current_diff_path {}
1336 set current_diff_side {}
1337 set diff_actions [list]
1338
1339 set HEAD {}
1340 set PARENT {}
1341 set MERGE_HEAD [list]
1342 set commit_type {}
1343 set empty_tree {}
1344 set current_branch {}
1345 set is_detached 0
1346 set current_diff_path {}
1347 set is_3way_diff 0
1348 set is_submodule_diff 0
1349 set is_conflict_diff 0
1350 set selected_commit_type new
1351 set diff_empty_count 0
1352
1353 set nullid "0000000000000000000000000000000000000000"
1354 set nullid2 "0000000000000000000000000000000000000001"
1355
1356 ######################################################################
1357 ##
1358 ## task management
1359
1360 set rescan_active 0
1361 set diff_active 0
1362 set last_clicked {}
1363
1364 set disable_on_lock [list]
1365 set index_lock_type none
1366
1367 proc lock_index {type} {
1368         global index_lock_type disable_on_lock
1369
1370         if {$index_lock_type eq {none}} {
1371                 set index_lock_type $type
1372                 foreach w $disable_on_lock {
1373                         uplevel #0 $w disabled
1374                 }
1375                 return 1
1376         } elseif {$index_lock_type eq "begin-$type"} {
1377                 set index_lock_type $type
1378                 return 1
1379         }
1380         return 0
1381 }
1382
1383 proc unlock_index {} {
1384         global index_lock_type disable_on_lock
1385
1386         set index_lock_type none
1387         foreach w $disable_on_lock {
1388                 uplevel #0 $w normal
1389         }
1390 }
1391
1392 ######################################################################
1393 ##
1394 ## status
1395
1396 proc repository_state {ctvar hdvar mhvar} {
1397         global current_branch
1398         upvar $ctvar ct $hdvar hd $mhvar mh
1399
1400         set mh [list]
1401
1402         load_current_branch
1403         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1404                 set hd {}
1405                 set ct initial
1406                 return
1407         }
1408
1409         set merge_head [gitdir MERGE_HEAD]
1410         if {[file exists $merge_head]} {
1411                 set ct merge
1412                 set fd_mh [open $merge_head r]
1413                 while {[gets $fd_mh line] >= 0} {
1414                         lappend mh $line
1415                 }
1416                 close $fd_mh
1417                 return
1418         }
1419
1420         set ct normal
1421 }
1422
1423 proc PARENT {} {
1424         global PARENT empty_tree
1425
1426         set p [lindex $PARENT 0]
1427         if {$p ne {}} {
1428                 return $p
1429         }
1430         if {$empty_tree eq {}} {
1431                 set empty_tree [git mktree << {}]
1432         }
1433         return $empty_tree
1434 }
1435
1436 proc force_amend {} {
1437         global selected_commit_type
1438         global HEAD PARENT MERGE_HEAD commit_type
1439
1440         repository_state newType newHEAD newMERGE_HEAD
1441         set HEAD $newHEAD
1442         set PARENT $newHEAD
1443         set MERGE_HEAD $newMERGE_HEAD
1444         set commit_type $newType
1445
1446         set selected_commit_type amend
1447         do_select_commit_type
1448 }
1449
1450 proc rescan {after {honor_trustmtime 1}} {
1451         global HEAD PARENT MERGE_HEAD commit_type
1452         global ui_index ui_workdir ui_comm
1453         global rescan_active file_states
1454         global repo_config
1455
1456         if {$rescan_active > 0 || ![lock_index read]} return
1457
1458         repository_state newType newHEAD newMERGE_HEAD
1459         if {[string match amend* $commit_type]
1460                 && $newType eq {normal}
1461                 && $newHEAD eq $HEAD} {
1462         } else {
1463                 set HEAD $newHEAD
1464                 set PARENT $newHEAD
1465                 set MERGE_HEAD $newMERGE_HEAD
1466                 set commit_type $newType
1467         }
1468
1469         array unset file_states
1470
1471         if {!$::GITGUI_BCK_exists &&
1472                 (![$ui_comm edit modified]
1473                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1474                 if {[string match amend* $commit_type]} {
1475                 } elseif {[load_message GITGUI_MSG utf-8]} {
1476                 } elseif {[run_prepare_commit_msg_hook]} {
1477                 } elseif {[load_message MERGE_MSG]} {
1478                 } elseif {[load_message SQUASH_MSG]} {
1479                 }
1480                 $ui_comm edit reset
1481                 $ui_comm edit modified false
1482         }
1483
1484         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1485                 rescan_stage2 {} $after
1486         } else {
1487                 set rescan_active 1
1488                 ui_status [mc "Refreshing file status..."]
1489                 set fd_rf [git_read update-index \
1490                         -q \
1491                         --unmerged \
1492                         --ignore-missing \
1493                         --refresh \
1494                         ]
1495                 fconfigure $fd_rf -blocking 0 -translation binary
1496                 fileevent $fd_rf readable \
1497                         [list rescan_stage2 $fd_rf $after]
1498         }
1499 }
1500
1501 if {[is_Cygwin]} {
1502         set is_git_info_exclude {}
1503         proc have_info_exclude {} {
1504                 global is_git_info_exclude
1505
1506                 if {$is_git_info_exclude eq {}} {
1507                         if {[catch {exec test -f [gitdir info exclude]}]} {
1508                                 set is_git_info_exclude 0
1509                         } else {
1510                                 set is_git_info_exclude 1
1511                         }
1512                 }
1513                 return $is_git_info_exclude
1514         }
1515 } else {
1516         proc have_info_exclude {} {
1517                 return [file readable [gitdir info exclude]]
1518         }
1519 }
1520
1521 proc rescan_stage2 {fd after} {
1522         global rescan_active buf_rdi buf_rdf buf_rlo
1523
1524         if {$fd ne {}} {
1525                 read $fd
1526                 if {![eof $fd]} return
1527                 close $fd
1528         }
1529
1530         if {[package vcompare $::_git_version 1.6.3] >= 0} {
1531                 set ls_others [list --exclude-standard]
1532         } else {
1533                 set ls_others [list --exclude-per-directory=.gitignore]
1534                 if {[have_info_exclude]} {
1535                         lappend ls_others "--exclude-from=[gitdir info exclude]"
1536                 }
1537                 set user_exclude [get_config core.excludesfile]
1538                 if {$user_exclude ne {} && [file readable $user_exclude]} {
1539                         lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1540                 }
1541         }
1542
1543         set buf_rdi {}
1544         set buf_rdf {}
1545         set buf_rlo {}
1546
1547         set rescan_active 2
1548         ui_status [mc "Scanning for modified files ..."]
1549         if {[git-version >= "1.7.2"]} {
1550                 set fd_di [git_read diff-index --cached --ignore-submodules=dirty -z [PARENT]]
1551         } else {
1552                 set fd_di [git_read diff-index --cached -z [PARENT]]
1553         }
1554         set fd_df [git_read diff-files -z]
1555
1556         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1557         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1558
1559         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1560         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1561
1562         if {[is_config_true gui.displayuntracked]} {
1563                 set fd_lo [eval git_read ls-files --others -z $ls_others]
1564                 fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1565                 fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1566                 incr rescan_active
1567         }
1568 }
1569
1570 proc load_message {file {encoding {}}} {
1571         global ui_comm
1572
1573         set f [gitdir $file]
1574         if {[file isfile $f]} {
1575                 if {[catch {set fd [open $f r]}]} {
1576                         return 0
1577                 }
1578                 fconfigure $fd -eofchar {}
1579                 if {$encoding ne {}} {
1580                         fconfigure $fd -encoding $encoding
1581                 }
1582                 set content [string trim [read $fd]]
1583                 close $fd
1584                 regsub -all -line {[ \r\t]+$} $content {} content
1585                 $ui_comm delete 0.0 end
1586                 $ui_comm insert end $content
1587                 return 1
1588         }
1589         return 0
1590 }
1591
1592 proc run_prepare_commit_msg_hook {} {
1593         global pch_error
1594
1595         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1596         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1597         # empty file but existent file.
1598
1599         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1600
1601         if {[file isfile [gitdir MERGE_MSG]]} {
1602                 set pcm_source "merge"
1603                 set fd_mm [open [gitdir MERGE_MSG] r]
1604                 fconfigure $fd_mm -encoding utf-8
1605                 puts -nonewline $fd_pcm [read $fd_mm]
1606                 close $fd_mm
1607         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1608                 set pcm_source "squash"
1609                 set fd_sm [open [gitdir SQUASH_MSG] r]
1610                 fconfigure $fd_sm -encoding utf-8
1611                 puts -nonewline $fd_pcm [read $fd_sm]
1612                 close $fd_sm
1613         } else {
1614                 set pcm_source ""
1615         }
1616
1617         close $fd_pcm
1618
1619         set fd_ph [githook_read prepare-commit-msg \
1620                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1621         if {$fd_ph eq {}} {
1622                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1623                 return 0;
1624         }
1625
1626         ui_status [mc "Calling prepare-commit-msg hook..."]
1627         set pch_error {}
1628
1629         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1630         fileevent $fd_ph readable \
1631                 [list prepare_commit_msg_hook_wait $fd_ph]
1632
1633         return 1;
1634 }
1635
1636 proc prepare_commit_msg_hook_wait {fd_ph} {
1637         global pch_error
1638
1639         append pch_error [read $fd_ph]
1640         fconfigure $fd_ph -blocking 1
1641         if {[eof $fd_ph]} {
1642                 if {[catch {close $fd_ph}]} {
1643                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1644                         hook_failed_popup prepare-commit-msg $pch_error
1645                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1646                         exit 1
1647                 } else {
1648                         load_message PREPARE_COMMIT_MSG
1649                 }
1650                 set pch_error {}
1651                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1652                 return
1653         }
1654         fconfigure $fd_ph -blocking 0
1655         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1656 }
1657
1658 proc read_diff_index {fd after} {
1659         global buf_rdi
1660
1661         append buf_rdi [read $fd]
1662         set c 0
1663         set n [string length $buf_rdi]
1664         while {$c < $n} {
1665                 set z1 [string first "\0" $buf_rdi $c]
1666                 if {$z1 == -1} break
1667                 incr z1
1668                 set z2 [string first "\0" $buf_rdi $z1]
1669                 if {$z2 == -1} break
1670
1671                 incr c
1672                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1673                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1674                 merge_state \
1675                         [encoding convertfrom utf-8 $p] \
1676                         [lindex $i 4]? \
1677                         [list [lindex $i 0] [lindex $i 2]] \
1678                         [list]
1679                 set c $z2
1680                 incr c
1681         }
1682         if {$c < $n} {
1683                 set buf_rdi [string range $buf_rdi $c end]
1684         } else {
1685                 set buf_rdi {}
1686         }
1687
1688         rescan_done $fd buf_rdi $after
1689 }
1690
1691 proc read_diff_files {fd after} {
1692         global buf_rdf
1693
1694         append buf_rdf [read $fd]
1695         set c 0
1696         set n [string length $buf_rdf]
1697         while {$c < $n} {
1698                 set z1 [string first "\0" $buf_rdf $c]
1699                 if {$z1 == -1} break
1700                 incr z1
1701                 set z2 [string first "\0" $buf_rdf $z1]
1702                 if {$z2 == -1} break
1703
1704                 incr c
1705                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1706                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1707                 merge_state \
1708                         [encoding convertfrom utf-8 $p] \
1709                         ?[lindex $i 4] \
1710                         [list] \
1711                         [list [lindex $i 0] [lindex $i 2]]
1712                 set c $z2
1713                 incr c
1714         }
1715         if {$c < $n} {
1716                 set buf_rdf [string range $buf_rdf $c end]
1717         } else {
1718                 set buf_rdf {}
1719         }
1720
1721         rescan_done $fd buf_rdf $after
1722 }
1723
1724 proc read_ls_others {fd after} {
1725         global buf_rlo
1726
1727         append buf_rlo [read $fd]
1728         set pck [split $buf_rlo "\0"]
1729         set buf_rlo [lindex $pck end]
1730         foreach p [lrange $pck 0 end-1] {
1731                 set p [encoding convertfrom utf-8 $p]
1732                 if {[string index $p end] eq {/}} {
1733                         set p [string range $p 0 end-1]
1734                 }
1735                 merge_state $p ?O
1736         }
1737         rescan_done $fd buf_rlo $after
1738 }
1739
1740 proc rescan_done {fd buf after} {
1741         global rescan_active current_diff_path
1742         global file_states repo_config
1743         upvar $buf to_clear
1744
1745         if {![eof $fd]} return
1746         set to_clear {}
1747         close $fd
1748         if {[incr rescan_active -1] > 0} return
1749
1750         prune_selection
1751         unlock_index
1752         display_all_files
1753         if {$current_diff_path ne {}} { reshow_diff $after }
1754         if {$current_diff_path eq {}} { select_first_diff $after }
1755 }
1756
1757 proc prune_selection {} {
1758         global file_states selected_paths
1759
1760         foreach path [array names selected_paths] {
1761                 if {[catch {set still_here $file_states($path)}]} {
1762                         unset selected_paths($path)
1763                 }
1764         }
1765 }
1766
1767 ######################################################################
1768 ##
1769 ## ui helpers
1770
1771 proc mapicon {w state path} {
1772         global all_icons
1773
1774         if {[catch {set r $all_icons($state$w)}]} {
1775                 puts "error: no icon for $w state={$state} $path"
1776                 return file_plain
1777         }
1778         return $r
1779 }
1780
1781 proc mapdesc {state path} {
1782         global all_descs
1783
1784         if {[catch {set r $all_descs($state)}]} {
1785                 puts "error: no desc for state={$state} $path"
1786                 return $state
1787         }
1788         return $r
1789 }
1790
1791 proc ui_status {msg} {
1792         global main_status
1793         if {[info exists main_status]} {
1794                 $main_status show $msg
1795         }
1796 }
1797
1798 proc ui_ready {{test {}}} {
1799         global main_status
1800         if {[info exists main_status]} {
1801                 $main_status show [mc "Ready."] $test
1802         }
1803 }
1804
1805 proc escape_path {path} {
1806         regsub -all {\\} $path "\\\\" path
1807         regsub -all "\n" $path "\\n" path
1808         return $path
1809 }
1810
1811 proc short_path {path} {
1812         return [escape_path [lindex [file split $path] end]]
1813 }
1814
1815 set next_icon_id 0
1816 set null_sha1 [string repeat 0 40]
1817
1818 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1819         global file_states next_icon_id null_sha1
1820
1821         set s0 [string index $new_state 0]
1822         set s1 [string index $new_state 1]
1823
1824         if {[catch {set info $file_states($path)}]} {
1825                 set state __
1826                 set icon n[incr next_icon_id]
1827         } else {
1828                 set state [lindex $info 0]
1829                 set icon [lindex $info 1]
1830                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1831                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1832         }
1833
1834         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1835         elseif {$s0 eq {_}} {set s0 _}
1836
1837         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1838         elseif {$s1 eq {_}} {set s1 _}
1839
1840         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1841                 set head_info [list 0 $null_sha1]
1842         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1843                 && $head_info eq {}} {
1844                 set head_info $index_info
1845         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1846                 set index_info $head_info
1847                 set head_info {}
1848         }
1849
1850         set file_states($path) [list $s0$s1 $icon \
1851                 $head_info $index_info \
1852                 ]
1853         return $state
1854 }
1855
1856 proc display_file_helper {w path icon_name old_m new_m} {
1857         global file_lists
1858
1859         if {$new_m eq {_}} {
1860                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1861                 if {$lno >= 0} {
1862                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1863                         incr lno
1864                         $w conf -state normal
1865                         $w delete $lno.0 [expr {$lno + 1}].0
1866                         $w conf -state disabled
1867                 }
1868         } elseif {$old_m eq {_} && $new_m ne {_}} {
1869                 lappend file_lists($w) $path
1870                 set file_lists($w) [lsort -unique $file_lists($w)]
1871                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1872                 incr lno
1873                 $w conf -state normal
1874                 $w image create $lno.0 \
1875                         -align center -padx 5 -pady 1 \
1876                         -name $icon_name \
1877                         -image [mapicon $w $new_m $path]
1878                 $w insert $lno.1 "[escape_path $path]\n"
1879                 $w conf -state disabled
1880         } elseif {$old_m ne $new_m} {
1881                 $w conf -state normal
1882                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1883                 $w conf -state disabled
1884         }
1885 }
1886
1887 proc display_file {path state} {
1888         global file_states selected_paths
1889         global ui_index ui_workdir
1890
1891         set old_m [merge_state $path $state]
1892         set s $file_states($path)
1893         set new_m [lindex $s 0]
1894         set icon_name [lindex $s 1]
1895
1896         set o [string index $old_m 0]
1897         set n [string index $new_m 0]
1898         if {$o eq {U}} {
1899                 set o _
1900         }
1901         if {$n eq {U}} {
1902                 set n _
1903         }
1904         display_file_helper     $ui_index $path $icon_name $o $n
1905
1906         if {[string index $old_m 0] eq {U}} {
1907                 set o U
1908         } else {
1909                 set o [string index $old_m 1]
1910         }
1911         if {[string index $new_m 0] eq {U}} {
1912                 set n U
1913         } else {
1914                 set n [string index $new_m 1]
1915         }
1916         display_file_helper     $ui_workdir $path $icon_name $o $n
1917
1918         if {$new_m eq {__}} {
1919                 unset file_states($path)
1920                 catch {unset selected_paths($path)}
1921         }
1922 }
1923
1924 proc display_all_files_helper {w path icon_name m} {
1925         global file_lists
1926
1927         lappend file_lists($w) $path
1928         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1929         $w image create end \
1930                 -align center -padx 5 -pady 1 \
1931                 -name $icon_name \
1932                 -image [mapicon $w $m $path]
1933         $w insert end "[escape_path $path]\n"
1934 }
1935
1936 set files_warning 0
1937 proc display_all_files {} {
1938         global ui_index ui_workdir
1939         global file_states file_lists
1940         global last_clicked
1941         global files_warning
1942
1943         $ui_index conf -state normal
1944         $ui_workdir conf -state normal
1945
1946         $ui_index delete 0.0 end
1947         $ui_workdir delete 0.0 end
1948         set last_clicked {}
1949
1950         set file_lists($ui_index) [list]
1951         set file_lists($ui_workdir) [list]
1952
1953         set to_display [lsort [array names file_states]]
1954         set display_limit [get_config gui.maxfilesdisplayed]
1955         set displayed 0
1956         foreach path $to_display {
1957                 set s $file_states($path)
1958                 set m [lindex $s 0]
1959                 set icon_name [lindex $s 1]
1960
1961                 if {$displayed > $display_limit && [string index $m 1] eq {O} } {
1962                         if {!$files_warning} {
1963                                 # do not repeatedly warn:
1964                                 set files_warning 1
1965                                 info_popup [mc "Display limit (gui.maxfilesdisplayed = %s) reached, not showing all %s files." \
1966                                         $display_limit [llength $to_display]]
1967                         }
1968                         continue
1969                 }
1970
1971                 set s [string index $m 0]
1972                 if {$s ne {U} && $s ne {_}} {
1973                         display_all_files_helper $ui_index $path \
1974                                 $icon_name $s
1975                 }
1976
1977                 if {[string index $m 0] eq {U}} {
1978                         set s U
1979                 } else {
1980                         set s [string index $m 1]
1981                 }
1982                 if {$s ne {_}} {
1983                         display_all_files_helper $ui_workdir $path \
1984                                 $icon_name $s
1985                         incr displayed
1986                 }
1987         }
1988
1989         $ui_index conf -state disabled
1990         $ui_workdir conf -state disabled
1991 }
1992
1993 ######################################################################
1994 ##
1995 ## icons
1996
1997 set filemask {
1998 #define mask_width 14
1999 #define mask_height 15
2000 static unsigned char mask_bits[] = {
2001    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2002    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2003    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2004 }
2005
2006 image create bitmap file_plain -background white -foreground black -data {
2007 #define plain_width 14
2008 #define plain_height 15
2009 static unsigned char plain_bits[] = {
2010    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2011    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2012    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2013 } -maskdata $filemask
2014
2015 image create bitmap file_mod -background white -foreground blue -data {
2016 #define mod_width 14
2017 #define mod_height 15
2018 static unsigned char mod_bits[] = {
2019    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2020    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2021    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2022 } -maskdata $filemask
2023
2024 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2025 #define file_fulltick_width 14
2026 #define file_fulltick_height 15
2027 static unsigned char file_fulltick_bits[] = {
2028    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2029    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2030    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2031 } -maskdata $filemask
2032
2033 image create bitmap file_question -background white -foreground black -data {
2034 #define file_question_width 14
2035 #define file_question_height 15
2036 static unsigned char file_question_bits[] = {
2037    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2038    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2039    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2040 } -maskdata $filemask
2041
2042 image create bitmap file_removed -background white -foreground red -data {
2043 #define file_removed_width 14
2044 #define file_removed_height 15
2045 static unsigned char file_removed_bits[] = {
2046    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2047    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2048    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2049 } -maskdata $filemask
2050
2051 image create bitmap file_merge -background white -foreground blue -data {
2052 #define file_merge_width 14
2053 #define file_merge_height 15
2054 static unsigned char file_merge_bits[] = {
2055    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2056    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2057    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2058 } -maskdata $filemask
2059
2060 image create bitmap file_statechange -background white -foreground green -data {
2061 #define file_statechange_width 14
2062 #define file_statechange_height 15
2063 static unsigned char file_statechange_bits[] = {
2064    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
2065    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
2066    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2067 } -maskdata $filemask
2068
2069 set ui_index .vpane.files.index.list
2070 set ui_workdir .vpane.files.workdir.list
2071
2072 set all_icons(_$ui_index)   file_plain
2073 set all_icons(A$ui_index)   file_plain
2074 set all_icons(M$ui_index)   file_fulltick
2075 set all_icons(D$ui_index)   file_removed
2076 set all_icons(U$ui_index)   file_merge
2077 set all_icons(T$ui_index)   file_statechange
2078
2079 set all_icons(_$ui_workdir) file_plain
2080 set all_icons(M$ui_workdir) file_mod
2081 set all_icons(D$ui_workdir) file_question
2082 set all_icons(U$ui_workdir) file_merge
2083 set all_icons(O$ui_workdir) file_plain
2084 set all_icons(T$ui_workdir) file_statechange
2085
2086 set max_status_desc 0
2087 foreach i {
2088                 {__ {mc "Unmodified"}}
2089
2090                 {_M {mc "Modified, not staged"}}
2091                 {M_ {mc "Staged for commit"}}
2092                 {MM {mc "Portions staged for commit"}}
2093                 {MD {mc "Staged for commit, missing"}}
2094
2095                 {_T {mc "File type changed, not staged"}}
2096                 {MT {mc "File type changed, old type staged for commit"}}
2097                 {AT {mc "File type changed, old type staged for commit"}}
2098                 {T_ {mc "File type changed, staged"}}
2099                 {TM {mc "File type change staged, modification not staged"}}
2100                 {TD {mc "File type change staged, file missing"}}
2101
2102                 {_O {mc "Untracked, not staged"}}
2103                 {A_ {mc "Staged for commit"}}
2104                 {AM {mc "Portions staged for commit"}}
2105                 {AD {mc "Staged for commit, missing"}}
2106
2107                 {_D {mc "Missing"}}
2108                 {D_ {mc "Staged for removal"}}
2109                 {DO {mc "Staged for removal, still present"}}
2110
2111                 {_U {mc "Requires merge resolution"}}
2112                 {U_ {mc "Requires merge resolution"}}
2113                 {UU {mc "Requires merge resolution"}}
2114                 {UM {mc "Requires merge resolution"}}
2115                 {UD {mc "Requires merge resolution"}}
2116                 {UT {mc "Requires merge resolution"}}
2117         } {
2118         set text [eval [lindex $i 1]]
2119         if {$max_status_desc < [string length $text]} {
2120                 set max_status_desc [string length $text]
2121         }
2122         set all_descs([lindex $i 0]) $text
2123 }
2124 unset i
2125
2126 ######################################################################
2127 ##
2128 ## util
2129
2130 proc scrollbar2many {list mode args} {
2131         foreach w $list {eval $w $mode $args}
2132 }
2133
2134 proc many2scrollbar {list mode sb top bottom} {
2135         $sb set $top $bottom
2136         foreach w $list {$w $mode moveto $top}
2137 }
2138
2139 proc incr_font_size {font {amt 1}} {
2140         set sz [font configure $font -size]
2141         incr sz $amt
2142         font configure $font -size $sz
2143         font configure ${font}bold -size $sz
2144         font configure ${font}italic -size $sz
2145 }
2146
2147 ######################################################################
2148 ##
2149 ## ui commands
2150
2151 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2152
2153 proc do_gitk {revs {is_submodule false}} {
2154         global current_diff_path file_states current_diff_side ui_index
2155         global _gitdir _gitworktree
2156
2157         # -- Always start gitk through whatever we were loaded with.  This
2158         #    lets us bypass using shell process on Windows systems.
2159         #
2160         set exe [_which gitk -script]
2161         set cmd [list [info nameofexecutable] $exe]
2162         if {$exe eq {}} {
2163                 error_popup [mc "Couldn't find gitk in PATH"]
2164         } else {
2165                 global env
2166
2167                 set pwd [pwd]
2168
2169                 if {!$is_submodule} {
2170                         if {![is_bare]} {
2171                                 cd $_gitworktree
2172                         }
2173                 } else {
2174                         cd $current_diff_path
2175                         if {$revs eq {--}} {
2176                                 set s $file_states($current_diff_path)
2177                                 set old_sha1 {}
2178                                 set new_sha1 {}
2179                                 switch -glob -- [lindex $s 0] {
2180                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2181                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2182                                 MM {
2183                                         if {$current_diff_side eq $ui_index} {
2184                                                 set old_sha1 [lindex [lindex $s 2] 1]
2185                                                 set new_sha1 [lindex [lindex $s 3] 1]
2186                                         } else {
2187                                                 set old_sha1 [lindex [lindex $s 3] 1]
2188                                         }
2189                                 }
2190                                 }
2191                                 set revs $old_sha1...$new_sha1
2192                         }
2193                         # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2194                         # we've been using for the main repository, so unset them.
2195                         # TODO we could make life easier (start up faster?) for gitk
2196                         # by setting these to the appropriate values to allow gitk
2197                         # to skip the heuristics to find their proper value
2198                         unset env(GIT_DIR)
2199                         unset env(GIT_WORK_TREE)
2200                 }
2201                 eval exec $cmd $revs "--" "--" &
2202
2203                 set env(GIT_DIR) $_gitdir
2204                 set env(GIT_WORK_TREE) $_gitworktree
2205                 cd $pwd
2206
2207                 ui_status $::starting_gitk_msg
2208                 after 10000 {
2209                         ui_ready $starting_gitk_msg
2210                 }
2211         }
2212 }
2213
2214 proc do_git_gui {} {
2215         global current_diff_path
2216
2217         # -- Always start git gui through whatever we were loaded with.  This
2218         #    lets us bypass using shell process on Windows systems.
2219         #
2220         set exe [list [_which git]]
2221         if {$exe eq {}} {
2222                 error_popup [mc "Couldn't find git gui in PATH"]
2223         } else {
2224                 global env
2225                 global _gitdir _gitworktree
2226
2227                 # see note in do_gitk about unsetting these vars when
2228                 # running tools in a submodule
2229                 unset env(GIT_DIR)
2230                 unset env(GIT_WORK_TREE)
2231
2232                 set pwd [pwd]
2233                 cd $current_diff_path
2234
2235                 eval exec $exe gui &
2236
2237                 set env(GIT_DIR) $_gitdir
2238                 set env(GIT_WORK_TREE) $_gitworktree
2239                 cd $pwd
2240
2241                 ui_status $::starting_gitk_msg
2242                 after 10000 {
2243                         ui_ready $starting_gitk_msg
2244                 }
2245         }
2246 }
2247
2248 proc do_explore {} {
2249         global _gitworktree
2250         set explorer {}
2251         if {[is_Cygwin] || [is_Windows]} {
2252                 set explorer "explorer.exe"
2253         } elseif {[is_MacOSX]} {
2254                 set explorer "open"
2255         } else {
2256                 # freedesktop.org-conforming system is our best shot
2257                 set explorer "xdg-open"
2258         }
2259         eval exec $explorer [list [file nativename $_gitworktree]] &
2260 }
2261
2262 set is_quitting 0
2263 set ret_code    1
2264
2265 proc terminate_me {win} {
2266         global ret_code
2267         if {$win ne {.}} return
2268         exit $ret_code
2269 }
2270
2271 proc do_quit {{rc {1}}} {
2272         global ui_comm is_quitting repo_config commit_type
2273         global GITGUI_BCK_exists GITGUI_BCK_i
2274         global ui_comm_spell
2275         global ret_code use_ttk
2276
2277         if {$is_quitting} return
2278         set is_quitting 1
2279
2280         if {[winfo exists $ui_comm]} {
2281                 # -- Stash our current commit buffer.
2282                 #
2283                 set save [gitdir GITGUI_MSG]
2284                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2285                         file rename -force [gitdir GITGUI_BCK] $save
2286                         set GITGUI_BCK_exists 0
2287                 } else {
2288                         set msg [string trim [$ui_comm get 0.0 end]]
2289                         regsub -all -line {[ \r\t]+$} $msg {} msg
2290                         if {(![string match amend* $commit_type]
2291                                 || [$ui_comm edit modified])
2292                                 && $msg ne {}} {
2293                                 catch {
2294                                         set fd [open $save w]
2295                                         fconfigure $fd -encoding utf-8
2296                                         puts -nonewline $fd $msg
2297                                         close $fd
2298                                 }
2299                         } else {
2300                                 catch {file delete $save}
2301                         }
2302                 }
2303
2304                 # -- Cancel our spellchecker if its running.
2305                 #
2306                 if {[info exists ui_comm_spell]} {
2307                         $ui_comm_spell stop
2308                 }
2309
2310                 # -- Remove our editor backup, its not needed.
2311                 #
2312                 after cancel $GITGUI_BCK_i
2313                 if {$GITGUI_BCK_exists} {
2314                         catch {file delete [gitdir GITGUI_BCK]}
2315                 }
2316
2317                 # -- Stash our current window geometry into this repository.
2318                 #
2319                 set cfg_wmstate [wm state .]
2320                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2321                         set rc_wmstate {}
2322                 }
2323                 if {$cfg_wmstate ne $rc_wmstate} {
2324                         catch {git config gui.wmstate $cfg_wmstate}
2325                 }
2326                 if {$cfg_wmstate eq {zoomed}} {
2327                         # on Windows wm geometry will lie about window
2328                         # position (but not size) when window is zoomed
2329                         # restore the window before querying wm geometry
2330                         wm state . normal
2331                 }
2332                 set cfg_geometry [list]
2333                 lappend cfg_geometry [wm geometry .]
2334                 if {$use_ttk} {
2335                         lappend cfg_geometry [.vpane sashpos 0]
2336                         lappend cfg_geometry [.vpane.files sashpos 0]
2337                 } else {
2338                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2339                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2340                 }
2341                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2342                         set rc_geometry {}
2343                 }
2344                 if {$cfg_geometry ne $rc_geometry} {
2345                         catch {git config gui.geometry $cfg_geometry}
2346                 }
2347         }
2348
2349         set ret_code $rc
2350
2351         # Briefly enable send again, working around Tk bug
2352         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2353         tk appname [appname]
2354
2355         destroy .
2356 }
2357
2358 proc do_rescan {} {
2359         rescan ui_ready
2360 }
2361
2362 proc ui_do_rescan {} {
2363         rescan {force_first_diff ui_ready}
2364 }
2365
2366 proc do_commit {} {
2367         commit_tree
2368 }
2369
2370 proc next_diff {{after {}}} {
2371         global next_diff_p next_diff_w next_diff_i
2372         show_diff $next_diff_p $next_diff_w {} {} $after
2373 }
2374
2375 proc find_anchor_pos {lst name} {
2376         set lid [lsearch -sorted -exact $lst $name]
2377
2378         if {$lid == -1} {
2379                 set lid 0
2380                 foreach lname $lst {
2381                         if {$lname >= $name} break
2382                         incr lid
2383                 }
2384         }
2385
2386         return $lid
2387 }
2388
2389 proc find_file_from {flist idx delta path mmask} {
2390         global file_states
2391
2392         set len [llength $flist]
2393         while {$idx >= 0 && $idx < $len} {
2394                 set name [lindex $flist $idx]
2395
2396                 if {$name ne $path && [info exists file_states($name)]} {
2397                         set state [lindex $file_states($name) 0]
2398
2399                         if {$mmask eq {} || [regexp $mmask $state]} {
2400                                 return $idx
2401                         }
2402                 }
2403
2404                 incr idx $delta
2405         }
2406
2407         return {}
2408 }
2409
2410 proc find_next_diff {w path {lno {}} {mmask {}}} {
2411         global next_diff_p next_diff_w next_diff_i
2412         global file_lists ui_index ui_workdir
2413
2414         set flist $file_lists($w)
2415         if {$lno eq {}} {
2416                 set lno [find_anchor_pos $flist $path]
2417         } else {
2418                 incr lno -1
2419         }
2420
2421         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2422                 if {$w eq $ui_index} {
2423                         set mmask "^$mmask"
2424                 } else {
2425                         set mmask "$mmask\$"
2426                 }
2427         }
2428
2429         set idx [find_file_from $flist $lno 1 $path $mmask]
2430         if {$idx eq {}} {
2431                 incr lno -1
2432                 set idx [find_file_from $flist $lno -1 $path $mmask]
2433         }
2434
2435         if {$idx ne {}} {
2436                 set next_diff_w $w
2437                 set next_diff_p [lindex $flist $idx]
2438                 set next_diff_i [expr {$idx+1}]
2439                 return 1
2440         } else {
2441                 return 0
2442         }
2443 }
2444
2445 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2446         global current_diff_path
2447
2448         if {$path ne $current_diff_path} {
2449                 return {}
2450         } elseif {[find_next_diff $w $path $lno $mmask]} {
2451                 return {next_diff;}
2452         } else {
2453                 return {reshow_diff;}
2454         }
2455 }
2456
2457 proc select_first_diff {after} {
2458         global ui_workdir
2459
2460         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2461             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2462                 next_diff $after
2463         } else {
2464                 uplevel #0 $after
2465         }
2466 }
2467
2468 proc force_first_diff {after} {
2469         global ui_workdir current_diff_path file_states
2470
2471         if {[info exists file_states($current_diff_path)]} {
2472                 set state [lindex $file_states($current_diff_path) 0]
2473         } else {
2474                 set state {OO}
2475         }
2476
2477         set reselect 0
2478         if {[string first {U} $state] >= 0} {
2479                 # Already a conflict, do nothing
2480         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2481                 set reselect 1
2482         } elseif {[string index $state 1] ne {O}} {
2483                 # Already a diff & no conflicts, do nothing
2484         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2485                 set reselect 1
2486         }
2487
2488         if {$reselect} {
2489                 next_diff $after
2490         } else {
2491                 uplevel #0 $after
2492         }
2493 }
2494
2495 proc toggle_or_diff {mode w args} {
2496         global file_states file_lists current_diff_path ui_index ui_workdir
2497         global last_clicked selected_paths
2498
2499         if {$mode eq "click"} {
2500                 foreach {x y} $args break
2501                 set pos [split [$w index @$x,$y] .]
2502                 foreach {lno col} $pos break
2503         } else {
2504                 if {$mode eq "toggle"} {
2505                         if {$w eq $ui_workdir} {
2506                                 do_add_selection
2507                                 set last_clicked {}
2508                                 return
2509                         }
2510                         if {$w eq $ui_index} {
2511                                 do_unstage_selection
2512                                 set last_clicked {}
2513                                 return
2514                         }
2515                 }
2516
2517                 if {$last_clicked ne {}} {
2518                         set lno [lindex $last_clicked 1]
2519                 } else {
2520                         if {![info exists file_lists]
2521                                 || ![info exists file_lists($w)]
2522                                 || [llength $file_lists($w)] == 0} {
2523                                 set last_clicked {}
2524                                 return
2525                         }
2526                         set lno [expr {int([lindex [$w tag ranges in_diff] 0])}]
2527                 }
2528                 if {$mode eq "toggle"} {
2529                         set col 0; set y 2
2530                 } else {
2531                         incr lno [expr {$mode eq "up" ? -1 : 1}]
2532                         set col 1
2533                 }
2534         }
2535
2536         if {![info exists file_lists]
2537                 || ![info exists file_lists($w)]
2538                 || [llength $file_lists($w)] < $lno - 1} {
2539                 set path {}
2540         } else {
2541                 set path [lindex $file_lists($w) [expr {$lno - 1}]]
2542         }
2543         if {$path eq {}} {
2544                 set last_clicked {}
2545                 return
2546         }
2547
2548         set last_clicked [list $w $lno]
2549         focus $w
2550         array unset selected_paths
2551         $ui_index tag remove in_sel 0.0 end
2552         $ui_workdir tag remove in_sel 0.0 end
2553
2554         # Determine the state of the file
2555         if {[info exists file_states($path)]} {
2556                 set state [lindex $file_states($path) 0]
2557         } else {
2558                 set state {__}
2559         }
2560
2561         # Restage the file, or simply show the diff
2562         if {$col == 0 && $y > 1} {
2563                 # Conflicts need special handling
2564                 if {[string first {U} $state] >= 0} {
2565                         # $w must always be $ui_workdir, but...
2566                         if {$w ne $ui_workdir} { set lno {} }
2567                         merge_stage_workdir $path $lno
2568                         return
2569                 }
2570
2571                 if {[string index $state 1] eq {O}} {
2572                         set mmask {}
2573                 } else {
2574                         set mmask {[^O]}
2575                 }
2576
2577                 set after [next_diff_after_action $w $path $lno $mmask]
2578
2579                 if {$w eq $ui_index} {
2580                         update_indexinfo \
2581                                 "Unstaging [short_path $path] from commit" \
2582                                 [list $path] \
2583                                 [concat $after [list ui_ready]]
2584                 } elseif {$w eq $ui_workdir} {
2585                         update_index \
2586                                 "Adding [short_path $path]" \
2587                                 [list $path] \
2588                                 [concat $after [list ui_ready]]
2589                 }
2590         } else {
2591                 set selected_paths($path) 1
2592                 show_diff $path $w $lno
2593         }
2594 }
2595
2596 proc add_one_to_selection {w x y} {
2597         global file_lists last_clicked selected_paths
2598
2599         set lno [lindex [split [$w index @$x,$y] .] 0]
2600         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2601         if {$path eq {}} {
2602                 set last_clicked {}
2603                 return
2604         }
2605
2606         if {$last_clicked ne {}
2607                 && [lindex $last_clicked 0] ne $w} {
2608                 array unset selected_paths
2609                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2610         }
2611
2612         set last_clicked [list $w $lno]
2613         if {[catch {set in_sel $selected_paths($path)}]} {
2614                 set in_sel 0
2615         }
2616         if {$in_sel} {
2617                 unset selected_paths($path)
2618                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2619         } else {
2620                 set selected_paths($path) 1
2621                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2622         }
2623 }
2624
2625 proc add_range_to_selection {w x y} {
2626         global file_lists last_clicked selected_paths
2627
2628         if {[lindex $last_clicked 0] ne $w} {
2629                 toggle_or_diff click $w $x $y
2630                 return
2631         }
2632
2633         set lno [lindex [split [$w index @$x,$y] .] 0]
2634         set lc [lindex $last_clicked 1]
2635         if {$lc < $lno} {
2636                 set begin $lc
2637                 set end $lno
2638         } else {
2639                 set begin $lno
2640                 set end $lc
2641         }
2642
2643         foreach path [lrange $file_lists($w) \
2644                 [expr {$begin - 1}] \
2645                 [expr {$end - 1}]] {
2646                 set selected_paths($path) 1
2647         }
2648         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2649 }
2650
2651 proc show_more_context {} {
2652         global repo_config
2653         if {$repo_config(gui.diffcontext) < 99} {
2654                 incr repo_config(gui.diffcontext)
2655                 reshow_diff
2656         }
2657 }
2658
2659 proc show_less_context {} {
2660         global repo_config
2661         if {$repo_config(gui.diffcontext) > 1} {
2662                 incr repo_config(gui.diffcontext) -1
2663                 reshow_diff
2664         }
2665 }
2666
2667 ######################################################################
2668 ##
2669 ## ui construction
2670
2671 set ui_comm {}
2672
2673 # -- Menu Bar
2674 #
2675 menu .mbar -tearoff 0
2676 if {[is_MacOSX]} {
2677         # -- Apple Menu (Mac OS X only)
2678         #
2679         .mbar add cascade -label Apple -menu .mbar.apple
2680         menu .mbar.apple
2681 }
2682 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2683 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2684 if {[is_enabled branch]} {
2685         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2686 }
2687 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2688         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2689 }
2690 if {[is_enabled transport]} {
2691         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2692         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2693 }
2694 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2695         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2696 }
2697
2698 # -- Repository Menu
2699 #
2700 menu .mbar.repository
2701
2702 if {![is_bare]} {
2703         .mbar.repository add command \
2704                 -label [mc "Explore Working Copy"] \
2705                 -command {do_explore}
2706 }
2707
2708 if {[is_Windows]} {
2709         .mbar.repository add command \
2710                 -label [mc "Git Bash"] \
2711                 -command {eval exec [auto_execok start] \
2712                                           [list "Git Bash" bash --login -l &]}
2713 }
2714
2715 if {[is_Windows] || ![is_bare]} {
2716         .mbar.repository add separator
2717 }
2718
2719 .mbar.repository add command \
2720         -label [mc "Browse Current Branch's Files"] \
2721         -command {browser::new $current_branch}
2722 set ui_browse_current [.mbar.repository index last]
2723 .mbar.repository add command \
2724         -label [mc "Browse Branch Files..."] \
2725         -command browser_open::dialog
2726 .mbar.repository add separator
2727
2728 .mbar.repository add command \
2729         -label [mc "Visualize Current Branch's History"] \
2730         -command {do_gitk $current_branch}
2731 set ui_visualize_current [.mbar.repository index last]
2732 .mbar.repository add command \
2733         -label [mc "Visualize All Branch History"] \
2734         -command {do_gitk --all}
2735 .mbar.repository add separator
2736
2737 proc current_branch_write {args} {
2738         global current_branch
2739         .mbar.repository entryconf $::ui_browse_current \
2740                 -label [mc "Browse %s's Files" $current_branch]
2741         .mbar.repository entryconf $::ui_visualize_current \
2742                 -label [mc "Visualize %s's History" $current_branch]
2743 }
2744 trace add variable current_branch write current_branch_write
2745
2746 if {[is_enabled multicommit]} {
2747         .mbar.repository add command -label [mc "Database Statistics"] \
2748                 -command do_stats
2749
2750         .mbar.repository add command -label [mc "Compress Database"] \
2751                 -command do_gc
2752
2753         .mbar.repository add command -label [mc "Verify Database"] \
2754                 -command do_fsck_objects
2755
2756         .mbar.repository add separator
2757
2758         if {[is_Cygwin]} {
2759                 .mbar.repository add command \
2760                         -label [mc "Create Desktop Icon"] \
2761                         -command do_cygwin_shortcut
2762         } elseif {[is_Windows]} {
2763                 .mbar.repository add command \
2764                         -label [mc "Create Desktop Icon"] \
2765                         -command do_windows_shortcut
2766         } elseif {[is_MacOSX]} {
2767                 .mbar.repository add command \
2768                         -label [mc "Create Desktop Icon"] \
2769                         -command do_macosx_app
2770         }
2771 }
2772
2773 if {[is_MacOSX]} {
2774         proc ::tk::mac::Quit {args} { do_quit }
2775 } else {
2776         .mbar.repository add command -label [mc Quit] \
2777                 -command do_quit \
2778                 -accelerator $M1T-Q
2779 }
2780
2781 # -- Edit Menu
2782 #
2783 menu .mbar.edit
2784 .mbar.edit add command -label [mc Undo] \
2785         -command {catch {[focus] edit undo}} \
2786         -accelerator $M1T-Z
2787 .mbar.edit add command -label [mc Redo] \
2788         -command {catch {[focus] edit redo}} \
2789         -accelerator $M1T-Y
2790 .mbar.edit add separator
2791 .mbar.edit add command -label [mc Cut] \
2792         -command {catch {tk_textCut [focus]}} \
2793         -accelerator $M1T-X
2794 .mbar.edit add command -label [mc Copy] \
2795         -command {catch {tk_textCopy [focus]}} \
2796         -accelerator $M1T-C
2797 .mbar.edit add command -label [mc Paste] \
2798         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2799         -accelerator $M1T-V
2800 .mbar.edit add command -label [mc Delete] \
2801         -command {catch {[focus] delete sel.first sel.last}} \
2802         -accelerator Del
2803 .mbar.edit add separator
2804 .mbar.edit add command -label [mc "Select All"] \
2805         -command {catch {[focus] tag add sel 0.0 end}} \
2806         -accelerator $M1T-A
2807
2808 # -- Branch Menu
2809 #
2810 if {[is_enabled branch]} {
2811         menu .mbar.branch
2812
2813         .mbar.branch add command -label [mc "Create..."] \
2814                 -command branch_create::dialog \
2815                 -accelerator $M1T-N
2816         lappend disable_on_lock [list .mbar.branch entryconf \
2817                 [.mbar.branch index last] -state]
2818
2819         .mbar.branch add command -label [mc "Checkout..."] \
2820                 -command branch_checkout::dialog \
2821                 -accelerator $M1T-O
2822         lappend disable_on_lock [list .mbar.branch entryconf \
2823                 [.mbar.branch index last] -state]
2824
2825         .mbar.branch add command -label [mc "Rename..."] \
2826                 -command branch_rename::dialog
2827         lappend disable_on_lock [list .mbar.branch entryconf \
2828                 [.mbar.branch index last] -state]
2829
2830         .mbar.branch add command -label [mc "Delete..."] \
2831                 -command branch_delete::dialog
2832         lappend disable_on_lock [list .mbar.branch entryconf \
2833                 [.mbar.branch index last] -state]
2834
2835         .mbar.branch add command -label [mc "Reset..."] \
2836                 -command merge::reset_hard
2837         lappend disable_on_lock [list .mbar.branch entryconf \
2838                 [.mbar.branch index last] -state]
2839 }
2840
2841 # -- Commit Menu
2842 #
2843 proc commit_btn_caption {} {
2844         if {[is_enabled nocommit]} {
2845                 return [mc "Done"]
2846         } else {
2847                 return [mc Commit@@verb]
2848         }
2849 }
2850
2851 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2852         menu .mbar.commit
2853
2854         if {![is_enabled nocommit]} {
2855                 .mbar.commit add radiobutton \
2856                         -label [mc "New Commit"] \
2857                         -command do_select_commit_type \
2858                         -variable selected_commit_type \
2859                         -value new
2860                 lappend disable_on_lock \
2861                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2862
2863                 .mbar.commit add radiobutton \
2864                         -label [mc "Amend Last Commit"] \
2865                         -command do_select_commit_type \
2866                         -variable selected_commit_type \
2867                         -value amend
2868                 lappend disable_on_lock \
2869                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2870
2871                 .mbar.commit add separator
2872         }
2873
2874         .mbar.commit add command -label [mc Rescan] \
2875                 -command ui_do_rescan \
2876                 -accelerator F5
2877         lappend disable_on_lock \
2878                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2879
2880         .mbar.commit add command -label [mc "Stage To Commit"] \
2881                 -command do_add_selection \
2882                 -accelerator $M1T-T
2883         lappend disable_on_lock \
2884                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2885
2886         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2887                 -command do_add_all \
2888                 -accelerator $M1T-I
2889         lappend disable_on_lock \
2890                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2891
2892         .mbar.commit add command -label [mc "Unstage From Commit"] \
2893                 -command do_unstage_selection \
2894                 -accelerator $M1T-U
2895         lappend disable_on_lock \
2896                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2897
2898         .mbar.commit add command -label [mc "Revert Changes"] \
2899                 -command do_revert_selection \
2900                 -accelerator $M1T-J
2901         lappend disable_on_lock \
2902                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2903
2904         .mbar.commit add separator
2905
2906         .mbar.commit add command -label [mc "Show Less Context"] \
2907                 -command show_less_context \
2908                 -accelerator $M1T-\-
2909
2910         .mbar.commit add command -label [mc "Show More Context"] \
2911                 -command show_more_context \
2912                 -accelerator $M1T-=
2913
2914         .mbar.commit add separator
2915
2916         if {![is_enabled nocommitmsg]} {
2917                 .mbar.commit add command -label [mc "Sign Off"] \
2918                         -command do_signoff \
2919                         -accelerator $M1T-S
2920         }
2921
2922         .mbar.commit add command -label [commit_btn_caption] \
2923                 -command do_commit \
2924                 -accelerator $M1T-Return
2925         lappend disable_on_lock \
2926                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2927 }
2928
2929 # -- Merge Menu
2930 #
2931 if {[is_enabled branch]} {
2932         menu .mbar.merge
2933         .mbar.merge add command -label [mc "Local Merge..."] \
2934                 -command merge::dialog \
2935                 -accelerator $M1T-M
2936         lappend disable_on_lock \
2937                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2938         .mbar.merge add command -label [mc "Abort Merge..."] \
2939                 -command merge::reset_hard
2940         lappend disable_on_lock \
2941                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2942 }
2943
2944 # -- Transport Menu
2945 #
2946 if {[is_enabled transport]} {
2947         menu .mbar.remote
2948
2949         .mbar.remote add command \
2950                 -label [mc "Add..."] \
2951                 -command remote_add::dialog \
2952                 -accelerator $M1T-A
2953         .mbar.remote add command \
2954                 -label [mc "Push..."] \
2955                 -command do_push_anywhere \
2956                 -accelerator $M1T-P
2957         .mbar.remote add command \
2958                 -label [mc "Delete Branch..."] \
2959                 -command remote_branch_delete::dialog
2960 }
2961
2962 if {[is_MacOSX]} {
2963         proc ::tk::mac::ShowPreferences {} {do_options}
2964 } else {
2965         # -- Edit Menu
2966         #
2967         .mbar.edit add separator
2968         .mbar.edit add command -label [mc "Options..."] \
2969                 -command do_options
2970 }
2971
2972 # -- Tools Menu
2973 #
2974 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2975         set tools_menubar .mbar.tools
2976         menu $tools_menubar
2977         $tools_menubar add separator
2978         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2979         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2980         set tools_tailcnt 3
2981         if {[array names repo_config guitool.*.cmd] ne {}} {
2982                 tools_populate_all
2983         }
2984 }
2985
2986 # -- Help Menu
2987 #
2988 .mbar add cascade -label [mc Help] -menu .mbar.help
2989 menu .mbar.help
2990
2991 if {[is_MacOSX]} {
2992         .mbar.apple add command -label [mc "About %s" [appname]] \
2993                 -command do_about
2994         .mbar.apple add separator
2995 } else {
2996         .mbar.help add command -label [mc "About %s" [appname]] \
2997                 -command do_about
2998 }
2999 . configure -menu .mbar
3000
3001 set doc_path [githtmldir]
3002 if {$doc_path ne {}} {
3003         set doc_path [file join $doc_path index.html]
3004
3005         if {[is_Cygwin]} {
3006                 set doc_path [exec cygpath --mixed $doc_path]
3007         }
3008 }
3009
3010 if {[file isfile $doc_path]} {
3011         set doc_url "file:$doc_path"
3012 } else {
3013         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
3014 }
3015
3016 proc start_browser {url} {
3017         git "web--browse" $url
3018 }
3019
3020 .mbar.help add command -label [mc "Online Documentation"] \
3021         -command [list start_browser $doc_url]
3022
3023 .mbar.help add command -label [mc "Show SSH Key"] \
3024         -command do_ssh_key
3025
3026 unset doc_path doc_url
3027
3028 # -- Standard bindings
3029 #
3030 wm protocol . WM_DELETE_WINDOW do_quit
3031 bind all <$M1B-Key-q> do_quit
3032 bind all <$M1B-Key-Q> do_quit
3033 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3034 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3035
3036 set subcommand_args {}
3037 proc usage {} {
3038         set s "[mc usage:] $::argv0 $::subcommand $::subcommand_args"
3039         if {[tk windowingsystem] eq "win32"} {
3040                 wm withdraw .
3041                 tk_messageBox -icon info -message $s \
3042                         -title [mc "Usage"]
3043         } else {
3044                 puts stderr $s
3045         }
3046         exit 1
3047 }
3048
3049 proc normalize_relpath {path} {
3050         set elements {}
3051         foreach item [file split $path] {
3052                 if {$item eq {.}} continue
3053                 if {$item eq {..} && [llength $elements] > 0
3054                     && [lindex $elements end] ne {..}} {
3055                         set elements [lrange $elements 0 end-1]
3056                         continue
3057                 }
3058                 lappend elements $item
3059         }
3060         return [eval file join $elements]
3061 }
3062
3063 # -- Not a normal commit type invocation?  Do that instead!
3064 #
3065 switch -- $subcommand {
3066 browser -
3067 blame {
3068         if {$subcommand eq "blame"} {
3069                 set subcommand_args {[--line=<num>] rev? path}
3070         } else {
3071                 set subcommand_args {rev? path}
3072         }
3073         if {$argv eq {}} usage
3074         set head {}
3075         set path {}
3076         set jump_spec {}
3077         set is_path 0
3078         foreach a $argv {
3079                 set p [file join $_prefix $a]
3080
3081                 if {$is_path || [file exists $p]} {
3082                         if {$path ne {}} usage
3083                         set path [normalize_relpath $p]
3084                         break
3085                 } elseif {$a eq {--}} {
3086                         if {$path ne {}} {
3087                                 if {$head ne {}} usage
3088                                 set head $path
3089                                 set path {}
3090                         }
3091                         set is_path 1
3092                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
3093                         if {$jump_spec ne {} || $head ne {}} usage
3094                         set jump_spec [list $lnum]
3095                 } elseif {$head eq {}} {
3096                         if {$head ne {}} usage
3097                         set head $a
3098                         set is_path 1
3099                 } else {
3100                         usage
3101                 }
3102         }
3103         unset is_path
3104
3105         if {$head ne {} && $path eq {}} {
3106                 if {[string index $head 0] eq {/}} {
3107                         set path [normalize_relpath $head]
3108                         set head {}
3109                 } else {
3110                         set path [normalize_relpath $_prefix$head]
3111                         set head {}
3112                 }
3113         }
3114
3115         if {$head eq {}} {
3116                 load_current_branch
3117         } else {
3118                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
3119                         if {[catch {
3120                                         set head [git rev-parse --verify $head]
3121                                 } err]} {
3122                                 if {[tk windowingsystem] eq "win32"} {
3123                                         tk_messageBox -icon error -title [mc Error] -message $err
3124                                 } else {
3125                                         puts stderr $err
3126                                 }
3127                                 exit 1
3128                         }
3129                 }
3130                 set current_branch $head
3131         }
3132
3133         wm deiconify .
3134         switch -- $subcommand {
3135         browser {
3136                 if {$jump_spec ne {}} usage
3137                 if {$head eq {}} {
3138                         if {$path ne {} && [file isdirectory $path]} {
3139                                 set head $current_branch
3140                         } else {
3141                                 set head $path
3142                                 set path {}
3143                         }
3144                 }
3145                 browser::new $head $path
3146         }
3147         blame   {
3148                 if {$head eq {} && ![file exists $path]} {
3149                         catch {wm withdraw .}
3150                         tk_messageBox \
3151                                 -icon error \
3152                                 -type ok \
3153                                 -title [mc "git-gui: fatal error"] \
3154                                 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3155                         exit 1
3156                 }
3157                 blame::new $head $path $jump_spec
3158         }
3159         }
3160         return
3161 }
3162 citool -
3163 gui {
3164         if {[llength $argv] != 0} {
3165                 usage
3166         }
3167         # fall through to setup UI for commits
3168 }
3169 default {
3170         set err "[mc usage:] $argv0 \[{blame|browser|citool}\]"
3171         if {[tk windowingsystem] eq "win32"} {
3172                 wm withdraw .
3173                 tk_messageBox -icon error -message $err \
3174                         -title [mc "Usage"]
3175         } else {
3176                 puts stderr $err
3177         }
3178         exit 1
3179 }
3180 }
3181
3182 # -- Branch Control
3183 #
3184 ${NS}::frame .branch
3185 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3186 ${NS}::label .branch.l1 \
3187         -text [mc "Current Branch:"] \
3188         -anchor w \
3189         -justify left
3190 ${NS}::label .branch.cb \
3191         -textvariable current_branch \
3192         -anchor w \
3193         -justify left
3194 pack .branch.l1 -side left
3195 pack .branch.cb -side left -fill x
3196 pack .branch -side top -fill x
3197
3198 # -- Main Window Layout
3199 #
3200 ${NS}::panedwindow .vpane -orient horizontal
3201 ${NS}::panedwindow .vpane.files -orient vertical
3202 if {$use_ttk} {
3203         .vpane add .vpane.files
3204 } else {
3205         .vpane add .vpane.files -sticky nsew -height 100 -width 200
3206 }
3207 pack .vpane -anchor n -side top -fill both -expand 1
3208
3209 # -- Working Directory File List
3210
3211 textframe .vpane.files.workdir -height 100 -width 200
3212 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3213         -background lightsalmon -foreground black
3214 ttext $ui_workdir -background white -foreground black \
3215         -borderwidth 0 \
3216         -width 20 -height 10 \
3217         -wrap none \
3218         -takefocus 1 -highlightthickness 1\
3219         -cursor $cursor_ptr \
3220         -xscrollcommand {.vpane.files.workdir.sx set} \
3221         -yscrollcommand {.vpane.files.workdir.sy set} \
3222         -state disabled
3223 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3224 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3225 pack .vpane.files.workdir.title -side top -fill x
3226 pack .vpane.files.workdir.sx -side bottom -fill x
3227 pack .vpane.files.workdir.sy -side right -fill y
3228 pack $ui_workdir -side left -fill both -expand 1
3229
3230 # -- Index File List
3231 #
3232 textframe .vpane.files.index -height 100 -width 200
3233 tlabel .vpane.files.index.title \
3234         -text [mc "Staged Changes (Will Commit)"] \
3235         -background lightgreen -foreground black
3236 ttext $ui_index -background white -foreground black \
3237         -borderwidth 0 \
3238         -width 20 -height 10 \
3239         -wrap none \
3240         -takefocus 1 -highlightthickness 1\
3241         -cursor $cursor_ptr \
3242         -xscrollcommand {.vpane.files.index.sx set} \
3243         -yscrollcommand {.vpane.files.index.sy set} \
3244         -state disabled
3245 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3246 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3247 pack .vpane.files.index.title -side top -fill x
3248 pack .vpane.files.index.sx -side bottom -fill x
3249 pack .vpane.files.index.sy -side right -fill y
3250 pack $ui_index -side left -fill both -expand 1
3251
3252 # -- Insert the workdir and index into the panes
3253 #
3254 .vpane.files add .vpane.files.workdir
3255 .vpane.files add .vpane.files.index
3256 if {!$use_ttk} {
3257         .vpane.files paneconfigure .vpane.files.workdir -sticky news
3258         .vpane.files paneconfigure .vpane.files.index -sticky news
3259 }
3260
3261 foreach i [list $ui_index $ui_workdir] {
3262         rmsel_tag $i
3263         $i tag conf in_diff -background [$i tag cget in_sel -background]
3264 }
3265 unset i
3266
3267 # -- Diff and Commit Area
3268 #
3269 if {$have_tk85} {
3270         ${NS}::panedwindow .vpane.lower -orient vertical
3271         ${NS}::frame .vpane.lower.commarea
3272         ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1 -height 500
3273         .vpane.lower add .vpane.lower.diff
3274         .vpane.lower add .vpane.lower.commarea
3275         .vpane add .vpane.lower
3276         if {$use_ttk} {
3277                 .vpane.lower pane .vpane.lower.diff -weight 1
3278                 .vpane.lower pane .vpane.lower.commarea -weight 0
3279         } else {
3280                 .vpane.lower paneconfigure .vpane.lower.diff -stretch always
3281                 .vpane.lower paneconfigure .vpane.lower.commarea -stretch never
3282         }
3283 } else {
3284         frame .vpane.lower -height 300 -width 400
3285         frame .vpane.lower.commarea
3286         frame .vpane.lower.diff -relief sunken -borderwidth 1
3287         pack .vpane.lower.diff -fill both -expand 1
3288         pack .vpane.lower.commarea -side bottom -fill x
3289         .vpane add .vpane.lower
3290         .vpane paneconfigure .vpane.lower -sticky nsew
3291 }
3292
3293 # -- Commit Area Buttons
3294 #
3295 ${NS}::frame .vpane.lower.commarea.buttons
3296 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3297         -anchor w \
3298         -justify left
3299 pack .vpane.lower.commarea.buttons.l -side top -fill x
3300 pack .vpane.lower.commarea.buttons -side left -fill y
3301
3302 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3303         -command ui_do_rescan
3304 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3305 lappend disable_on_lock \
3306         {.vpane.lower.commarea.buttons.rescan conf -state}
3307
3308 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3309         -command do_add_all
3310 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3311 lappend disable_on_lock \
3312         {.vpane.lower.commarea.buttons.incall conf -state}
3313
3314 if {![is_enabled nocommitmsg]} {
3315         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3316                 -command do_signoff
3317         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3318 }
3319
3320 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3321         -command do_commit
3322 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3323 lappend disable_on_lock \
3324         {.vpane.lower.commarea.buttons.commit conf -state}
3325
3326 if {![is_enabled nocommit]} {
3327         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3328                 -command do_push_anywhere
3329         pack .vpane.lower.commarea.buttons.push -side top -fill x
3330 }
3331
3332 # -- Commit Message Buffer
3333 #
3334 ${NS}::frame .vpane.lower.commarea.buffer
3335 ${NS}::frame .vpane.lower.commarea.buffer.header
3336 set ui_comm .vpane.lower.commarea.buffer.frame.t
3337 set ui_coml .vpane.lower.commarea.buffer.header.l
3338
3339 if {![is_enabled nocommit]} {
3340         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3341                 -text [mc "New Commit"] \
3342                 -command do_select_commit_type \
3343                 -variable selected_commit_type \
3344                 -value new
3345         lappend disable_on_lock \
3346                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3347         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3348                 -text [mc "Amend Last Commit"] \
3349                 -command do_select_commit_type \
3350                 -variable selected_commit_type \
3351                 -value amend
3352         lappend disable_on_lock \
3353                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3354 }
3355
3356 ${NS}::label $ui_coml \
3357         -anchor w \
3358         -justify left
3359 proc trace_commit_type {varname args} {
3360         global ui_coml commit_type
3361         switch -glob -- $commit_type {
3362         initial       {set txt [mc "Initial Commit Message:"]}
3363         amend         {set txt [mc "Amended Commit Message:"]}
3364         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3365         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3366         merge         {set txt [mc "Merge Commit Message:"]}
3367         *             {set txt [mc "Commit Message:"]}
3368         }
3369         $ui_coml conf -text $txt
3370 }
3371 trace add variable commit_type write trace_commit_type
3372 pack $ui_coml -side left -fill x
3373
3374 if {![is_enabled nocommit]} {
3375         pack .vpane.lower.commarea.buffer.header.amend -side right
3376         pack .vpane.lower.commarea.buffer.header.new -side right
3377 }
3378
3379 textframe .vpane.lower.commarea.buffer.frame
3380 ttext $ui_comm -background white -foreground black \
3381         -borderwidth 1 \
3382         -undo true \
3383         -maxundo 20 \
3384         -autoseparators true \
3385         -takefocus 1 \
3386         -highlightthickness 1 \
3387         -relief sunken \
3388         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3389         -font font_diff \
3390         -yscrollcommand {.vpane.lower.commarea.buffer.frame.sby set}
3391 ${NS}::scrollbar .vpane.lower.commarea.buffer.frame.sby \
3392         -command [list $ui_comm yview]
3393
3394 pack .vpane.lower.commarea.buffer.frame.sby -side right -fill y
3395 pack $ui_comm -side left -fill y
3396 pack .vpane.lower.commarea.buffer.header -side top -fill x
3397 pack .vpane.lower.commarea.buffer.frame -side left -fill y
3398 pack .vpane.lower.commarea.buffer -side left -fill y
3399
3400 # -- Commit Message Buffer Context Menu
3401 #
3402 set ctxm .vpane.lower.commarea.buffer.ctxm
3403 menu $ctxm -tearoff 0
3404 $ctxm add command \
3405         -label [mc Cut] \
3406         -command {tk_textCut $ui_comm}
3407 $ctxm add command \
3408         -label [mc Copy] \
3409         -command {tk_textCopy $ui_comm}
3410 $ctxm add command \
3411         -label [mc Paste] \
3412         -command {tk_textPaste $ui_comm}
3413 $ctxm add command \
3414         -label [mc Delete] \
3415         -command {catch {$ui_comm delete sel.first sel.last}}
3416 $ctxm add separator
3417 $ctxm add command \
3418         -label [mc "Select All"] \
3419         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3420 $ctxm add command \
3421         -label [mc "Copy All"] \
3422         -command {
3423                 $ui_comm tag add sel 0.0 end
3424                 tk_textCopy $ui_comm
3425                 $ui_comm tag remove sel 0.0 end
3426         }
3427 $ctxm add separator
3428 $ctxm add command \
3429         -label [mc "Sign Off"] \
3430         -command do_signoff
3431 set ui_comm_ctxm $ctxm
3432
3433 # -- Diff Header
3434 #
3435 proc trace_current_diff_path {varname args} {
3436         global current_diff_path diff_actions file_states
3437         if {$current_diff_path eq {}} {
3438                 set s {}
3439                 set f {}
3440                 set p {}
3441                 set o disabled
3442         } else {
3443                 set p $current_diff_path
3444                 set s [mapdesc [lindex $file_states($p) 0] $p]
3445                 set f [mc "File:"]
3446                 set p [escape_path $p]
3447                 set o normal
3448         }
3449
3450         .vpane.lower.diff.header.status configure -text $s
3451         .vpane.lower.diff.header.file configure -text $f
3452         .vpane.lower.diff.header.path configure -text $p
3453         foreach w $diff_actions {
3454                 uplevel #0 $w $o
3455         }
3456 }
3457 trace add variable current_diff_path write trace_current_diff_path
3458
3459 gold_frame .vpane.lower.diff.header
3460 tlabel .vpane.lower.diff.header.status \
3461         -background gold \
3462         -foreground black \
3463         -width $max_status_desc \
3464         -anchor w \
3465         -justify left
3466 tlabel .vpane.lower.diff.header.file \
3467         -background gold \
3468         -foreground black \
3469         -anchor w \
3470         -justify left
3471 tlabel .vpane.lower.diff.header.path \
3472         -background gold \
3473         -foreground black \
3474         -anchor w \
3475         -justify left
3476 pack .vpane.lower.diff.header.status -side left
3477 pack .vpane.lower.diff.header.file -side left
3478 pack .vpane.lower.diff.header.path -fill x
3479 set ctxm .vpane.lower.diff.header.ctxm
3480 menu $ctxm -tearoff 0
3481 $ctxm add command \
3482         -label [mc Copy] \
3483         -command {
3484                 clipboard clear
3485                 clipboard append \
3486                         -format STRING \
3487                         -type STRING \
3488                         -- $current_diff_path
3489         }
3490 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3491 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3492
3493 # -- Diff Body
3494 #
3495 textframe .vpane.lower.diff.body
3496 set ui_diff .vpane.lower.diff.body.t
3497 ttext $ui_diff -background white -foreground black \
3498         -borderwidth 0 \
3499         -width 80 -height 5 -wrap none \
3500         -font font_diff \
3501         -takefocus 1 -highlightthickness 1 \
3502         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3503         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3504         -state disabled
3505 catch {$ui_diff configure -tabstyle wordprocessor}
3506 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3507         -command [list $ui_diff xview]
3508 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3509         -command [list $ui_diff yview]
3510 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3511 pack .vpane.lower.diff.body.sby -side right -fill y
3512 pack $ui_diff -side left -fill both -expand 1
3513 pack .vpane.lower.diff.header -side top -fill x
3514 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3515
3516 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3517         $ui_diff tag configure clr4$n -background $c
3518         $ui_diff tag configure clri4$n -foreground $c
3519         $ui_diff tag configure clr3$n -foreground $c
3520         $ui_diff tag configure clri3$n -background $c
3521 }
3522 $ui_diff tag configure clr1 -font font_diffbold
3523 $ui_diff tag configure clr4 -underline 1
3524
3525 $ui_diff tag conf d_info -foreground blue -font font_diffbold
3526
3527 $ui_diff tag conf d_cr -elide true
3528 $ui_diff tag conf d_@ -font font_diffbold
3529 $ui_diff tag conf d_+ -foreground {#00a000}
3530 $ui_diff tag conf d_- -foreground red
3531
3532 $ui_diff tag conf d_++ -foreground {#00a000}
3533 $ui_diff tag conf d_-- -foreground red
3534 $ui_diff tag conf d_+s \
3535         -foreground {#00a000} \
3536         -background {#e2effa}
3537 $ui_diff tag conf d_-s \
3538         -foreground red \
3539         -background {#e2effa}
3540 $ui_diff tag conf d_s+ \
3541         -foreground {#00a000} \
3542         -background ivory1
3543 $ui_diff tag conf d_s- \
3544         -foreground red \
3545         -background ivory1
3546
3547 $ui_diff tag conf d< \
3548         -foreground orange \
3549         -font font_diffbold
3550 $ui_diff tag conf d= \
3551         -foreground orange \
3552         -font font_diffbold
3553 $ui_diff tag conf d> \
3554         -foreground orange \
3555         -font font_diffbold
3556
3557 $ui_diff tag raise sel
3558
3559 # -- Diff Body Context Menu
3560 #
3561
3562 proc create_common_diff_popup {ctxm} {
3563         $ctxm add command \
3564                 -label [mc Refresh] \
3565                 -command reshow_diff
3566         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3567         $ctxm add command \
3568                 -label [mc Copy] \
3569                 -command {tk_textCopy $ui_diff}
3570         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3571         $ctxm add command \
3572                 -label [mc "Select All"] \
3573                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3574         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3575         $ctxm add command \
3576                 -label [mc "Copy All"] \
3577                 -command {
3578                         $ui_diff tag add sel 0.0 end
3579                         tk_textCopy $ui_diff
3580                         $ui_diff tag remove sel 0.0 end
3581                 }
3582         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3583         $ctxm add separator
3584         $ctxm add command \
3585                 -label [mc "Decrease Font Size"] \
3586                 -command {incr_font_size font_diff -1}
3587         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3588         $ctxm add command \
3589                 -label [mc "Increase Font Size"] \
3590                 -command {incr_font_size font_diff 1}
3591         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3592         $ctxm add separator
3593         set emenu $ctxm.enc
3594         menu $emenu
3595         build_encoding_menu $emenu [list force_diff_encoding]
3596         $ctxm add cascade \
3597                 -label [mc "Encoding"] \
3598                 -menu $emenu
3599         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3600         $ctxm add separator
3601         $ctxm add command -label [mc "Options..."] \
3602                 -command do_options
3603 }
3604
3605 set ctxm .vpane.lower.diff.body.ctxm
3606 menu $ctxm -tearoff 0
3607 $ctxm add command \
3608         -label [mc "Apply/Reverse Hunk"] \
3609         -command {apply_hunk $cursorX $cursorY}
3610 set ui_diff_applyhunk [$ctxm index last]
3611 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3612 $ctxm add command \
3613         -label [mc "Apply/Reverse Line"] \
3614         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3615 set ui_diff_applyline [$ctxm index last]
3616 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3617 $ctxm add separator
3618 $ctxm add command \
3619         -label [mc "Show Less Context"] \
3620         -command show_less_context
3621 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3622 $ctxm add command \
3623         -label [mc "Show More Context"] \
3624         -command show_more_context
3625 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3626 $ctxm add separator
3627 create_common_diff_popup $ctxm
3628
3629 set ctxmmg .vpane.lower.diff.body.ctxmmg
3630 menu $ctxmmg -tearoff 0
3631 $ctxmmg add command \
3632         -label [mc "Run Merge Tool"] \
3633         -command {merge_resolve_tool}
3634 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3635 $ctxmmg add separator
3636 $ctxmmg add command \
3637         -label [mc "Use Remote Version"] \
3638         -command {merge_resolve_one 3}
3639 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3640 $ctxmmg add command \
3641         -label [mc "Use Local Version"] \
3642         -command {merge_resolve_one 2}
3643 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3644 $ctxmmg add command \
3645         -label [mc "Revert To Base"] \
3646         -command {merge_resolve_one 1}
3647 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3648 $ctxmmg add separator
3649 $ctxmmg add command \
3650         -label [mc "Show Less Context"] \
3651         -command show_less_context
3652 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3653 $ctxmmg add command \
3654         -label [mc "Show More Context"] \
3655         -command show_more_context
3656 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3657 $ctxmmg add separator
3658 create_common_diff_popup $ctxmmg
3659
3660 set ctxmsm .vpane.lower.diff.body.ctxmsm
3661 menu $ctxmsm -tearoff 0
3662 $ctxmsm add command \
3663         -label [mc "Visualize These Changes In The Submodule"] \
3664         -command {do_gitk -- true}
3665 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3666 $ctxmsm add command \
3667         -label [mc "Visualize Current Branch History In The Submodule"] \
3668         -command {do_gitk {} true}
3669 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3670 $ctxmsm add command \
3671         -label [mc "Visualize All Branch History In The Submodule"] \
3672         -command {do_gitk --all true}
3673 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3674 $ctxmsm add separator
3675 $ctxmsm add command \
3676         -label [mc "Start git gui In The Submodule"] \
3677         -command {do_git_gui}
3678 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3679 $ctxmsm add separator
3680 create_common_diff_popup $ctxmsm
3681
3682 proc has_textconv {path} {
3683         if {[is_config_false gui.textconv]} {
3684                 return 0
3685         }
3686         set filter [gitattr $path diff set]
3687         set textconv [get_config [join [list diff $filter textconv] .]]
3688         if {$filter ne {set} && $textconv ne {}} {
3689                 return 1
3690         } else {
3691                 return 0
3692         }
3693 }
3694
3695 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3696         global current_diff_path file_states
3697         set ::cursorX $x
3698         set ::cursorY $y
3699         if {[info exists file_states($current_diff_path)]} {
3700                 set state [lindex $file_states($current_diff_path) 0]
3701         } else {
3702                 set state {__}
3703         }
3704         if {[string first {U} $state] >= 0} {
3705                 tk_popup $ctxmmg $X $Y
3706         } elseif {$::is_submodule_diff} {
3707                 tk_popup $ctxmsm $X $Y
3708         } else {
3709                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3710                 if {$::ui_index eq $::current_diff_side} {
3711                         set l [mc "Unstage Hunk From Commit"]
3712                         if {$has_range} {
3713                                 set t [mc "Unstage Lines From Commit"]
3714                         } else {
3715                                 set t [mc "Unstage Line From Commit"]
3716                         }
3717                 } else {
3718                         set l [mc "Stage Hunk For Commit"]
3719                         if {$has_range} {
3720                                 set t [mc "Stage Lines For Commit"]
3721                         } else {
3722                                 set t [mc "Stage Line For Commit"]
3723                         }
3724                 }
3725                 if {$::is_3way_diff
3726                         || $current_diff_path eq {}
3727                         || {__} eq $state
3728                         || {_O} eq $state
3729                         || [string match {?T} $state]
3730                         || [string match {T?} $state]
3731                         || [has_textconv $current_diff_path]} {
3732                         set s disabled
3733                 } else {
3734                         set s normal
3735                 }
3736                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3737                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3738                 tk_popup $ctxm $X $Y
3739         }
3740 }
3741 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3742
3743 # -- Status Bar
3744 #
3745 set main_status [::status_bar::new .status]
3746 pack .status -anchor w -side bottom -fill x
3747 $main_status show [mc "Initializing..."]
3748
3749 # -- Load geometry
3750 #
3751 proc on_ttk_pane_mapped {w pane pos} {
3752         bind $w <Map> {}
3753         after 0 [list after idle [list $w sashpos $pane $pos]]
3754 }
3755 proc on_tk_pane_mapped {w pane x y} {
3756         bind $w <Map> {}
3757         after 0 [list after idle [list $w sash place $pane $x $y]]
3758 }
3759 proc on_application_mapped {} {
3760         global repo_config use_ttk
3761         bind . <Map> {}
3762         set gm $repo_config(gui.geometry)
3763         if {$use_ttk} {
3764                 bind .vpane <Map> \
3765                     [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3766                 bind .vpane.files <Map> \
3767                     [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3768         } else {
3769                 bind .vpane <Map> \
3770                     [list on_tk_pane_mapped %W 0 \
3771                          [lindex $gm 1] \
3772                          [lindex [.vpane sash coord 0] 1]]
3773                 bind .vpane.files <Map> \
3774                     [list on_tk_pane_mapped %W 0 \
3775                          [lindex [.vpane.files sash coord 0] 0] \
3776                          [lindex $gm 2]]
3777         }
3778         wm geometry . [lindex $gm 0]
3779 }
3780 if {[info exists repo_config(gui.geometry)]} {
3781         bind . <Map> [list on_application_mapped]
3782         wm geometry . [lindex $repo_config(gui.geometry) 0]
3783 }
3784
3785 # -- Load window state
3786 #
3787 if {[info exists repo_config(gui.wmstate)]} {
3788         catch {wm state . $repo_config(gui.wmstate)}
3789 }
3790
3791 # -- Key Bindings
3792 #
3793 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3794 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3795 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3796 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3797 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3798 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3799 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3800 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3801 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3802 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3803 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3804 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3805 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3806 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3807 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3808 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3809 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3810 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3811 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3812 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3813 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3814 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3815
3816 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3817 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3818 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3819 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3820 bind $ui_diff <$M1B-Key-v> {break}
3821 bind $ui_diff <$M1B-Key-V> {break}
3822 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3823 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3824 bind $ui_diff <$M1B-Key-j> {do_revert_selection;break}
3825 bind $ui_diff <$M1B-Key-J> {do_revert_selection;break}
3826 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3827 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3828 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3829 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3830 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3831 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3832 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3833 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3834 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3835 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3836 bind $ui_diff <Button-1>   {focus %W}
3837
3838 if {[is_enabled branch]} {
3839         bind . <$M1B-Key-n> branch_create::dialog
3840         bind . <$M1B-Key-N> branch_create::dialog
3841         bind . <$M1B-Key-o> branch_checkout::dialog
3842         bind . <$M1B-Key-O> branch_checkout::dialog
3843         bind . <$M1B-Key-m> merge::dialog
3844         bind . <$M1B-Key-M> merge::dialog
3845 }
3846 if {[is_enabled transport]} {
3847         bind . <$M1B-Key-p> do_push_anywhere
3848         bind . <$M1B-Key-P> do_push_anywhere
3849 }
3850
3851 bind .   <Key-F5>     ui_do_rescan
3852 bind .   <$M1B-Key-r> ui_do_rescan
3853 bind .   <$M1B-Key-R> ui_do_rescan
3854 bind .   <$M1B-Key-s> do_signoff
3855 bind .   <$M1B-Key-S> do_signoff
3856 bind .   <$M1B-Key-t> { toggle_or_diff toggle %W }
3857 bind .   <$M1B-Key-T> { toggle_or_diff toggle %W }
3858 bind .   <$M1B-Key-u> { toggle_or_diff toggle %W }
3859 bind .   <$M1B-Key-U> { toggle_or_diff toggle %W }
3860 bind .   <$M1B-Key-j> do_revert_selection
3861 bind .   <$M1B-Key-J> do_revert_selection
3862 bind .   <$M1B-Key-i> do_add_all
3863 bind .   <$M1B-Key-I> do_add_all
3864 bind .   <$M1B-Key-minus> {show_less_context;break}
3865 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3866 bind .   <$M1B-Key-equal> {show_more_context;break}
3867 bind .   <$M1B-Key-plus> {show_more_context;break}
3868 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3869 bind .   <$M1B-Key-Return> do_commit
3870 bind .   <$M1B-Key-KP_Enter> do_commit
3871 foreach i [list $ui_index $ui_workdir] {
3872         bind $i <Button-1>       { toggle_or_diff click %W %x %y; break }
3873         bind $i <$M1B-Button-1>  { add_one_to_selection %W %x %y; break }
3874         bind $i <Shift-Button-1> { add_range_to_selection %W %x %y; break }
3875         bind $i <Key-Up>         { toggle_or_diff up %W; break }
3876         bind $i <Key-Down>       { toggle_or_diff down %W; break }
3877 }
3878 unset i
3879
3880 set file_lists($ui_index) [list]
3881 set file_lists($ui_workdir) [list]
3882
3883 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3884 focus -force $ui_comm
3885
3886 # -- Warn the user about environmental problems.  Cygwin's Tcl
3887 #    does *not* pass its env array onto any processes it spawns.
3888 #    This means that git processes get none of our environment.
3889 #
3890 if {[is_Cygwin]} {
3891         set ignored_env 0
3892         set suggest_user {}
3893         set msg [mc "Possible environment issues exist.
3894
3895 The following environment variables are probably
3896 going to be ignored by any Git subprocess run
3897 by %s:
3898
3899 " [appname]]
3900         foreach name [array names env] {
3901                 switch -regexp -- $name {
3902                 {^GIT_INDEX_FILE$} -
3903                 {^GIT_OBJECT_DIRECTORY$} -
3904                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3905                 {^GIT_DIFF_OPTS$} -
3906                 {^GIT_EXTERNAL_DIFF$} -
3907                 {^GIT_PAGER$} -
3908                 {^GIT_TRACE$} -
3909                 {^GIT_CONFIG$} -
3910                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3911                         append msg " - $name\n"
3912                         incr ignored_env
3913                 }
3914                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3915                         append msg " - $name\n"
3916                         incr ignored_env
3917                         set suggest_user $name
3918                 }
3919                 }
3920         }
3921         if {$ignored_env > 0} {
3922                 append msg [mc "
3923 This is due to a known issue with the
3924 Tcl binary distributed by Cygwin."]
3925
3926                 if {$suggest_user ne {}} {
3927                         append msg [mc "
3928
3929 A good replacement for %s
3930 is placing values for the user.name and
3931 user.email settings into your personal
3932 ~/.gitconfig file.
3933 " $suggest_user]
3934                 }
3935                 warn_popup $msg
3936         }
3937         unset ignored_env msg suggest_user name
3938 }
3939
3940 # -- Only initialize complex UI if we are going to stay running.
3941 #
3942 if {[is_enabled transport]} {
3943         load_all_remotes
3944
3945         set n [.mbar.remote index end]
3946         populate_remotes_menu
3947         set n [expr {[.mbar.remote index end] - $n}]
3948         if {$n > 0} {
3949                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3950                 .mbar.remote insert $n separator
3951         }
3952         unset n
3953 }
3954
3955 if {[winfo exists $ui_comm]} {
3956         set GITGUI_BCK_exists [load_message GITGUI_BCK utf-8]
3957
3958         # -- If both our backup and message files exist use the
3959         #    newer of the two files to initialize the buffer.
3960         #
3961         if {$GITGUI_BCK_exists} {
3962                 set m [gitdir GITGUI_MSG]
3963                 if {[file isfile $m]} {
3964                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3965                                 catch {file delete [gitdir GITGUI_MSG]}
3966                         } else {
3967                                 $ui_comm delete 0.0 end
3968                                 $ui_comm edit reset
3969                                 $ui_comm edit modified false
3970                                 catch {file delete [gitdir GITGUI_BCK]}
3971                                 set GITGUI_BCK_exists 0
3972                         }
3973                 }
3974                 unset m
3975         }
3976
3977         proc backup_commit_buffer {} {
3978                 global ui_comm GITGUI_BCK_exists
3979
3980                 set m [$ui_comm edit modified]
3981                 if {$m || $GITGUI_BCK_exists} {
3982                         set msg [string trim [$ui_comm get 0.0 end]]
3983                         regsub -all -line {[ \r\t]+$} $msg {} msg
3984
3985                         if {$msg eq {}} {
3986                                 if {$GITGUI_BCK_exists} {
3987                                         catch {file delete [gitdir GITGUI_BCK]}
3988                                         set GITGUI_BCK_exists 0
3989                                 }
3990                         } elseif {$m} {
3991                                 catch {
3992                                         set fd [open [gitdir GITGUI_BCK] w]
3993                                         fconfigure $fd -encoding utf-8
3994                                         puts -nonewline $fd $msg
3995                                         close $fd
3996                                         set GITGUI_BCK_exists 1
3997                                 }
3998                         }
3999
4000                         $ui_comm edit modified false
4001                 }
4002
4003                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
4004         }
4005
4006         backup_commit_buffer
4007
4008         # -- If the user has aspell available we can drive it
4009         #    in pipe mode to spellcheck the commit message.
4010         #
4011         set spell_cmd [list |]
4012         set spell_dict [get_config gui.spellingdictionary]
4013         lappend spell_cmd aspell
4014         if {$spell_dict ne {}} {
4015                 lappend spell_cmd --master=$spell_dict
4016         }
4017         lappend spell_cmd --mode=none
4018         lappend spell_cmd --encoding=utf-8
4019         lappend spell_cmd pipe
4020         if {$spell_dict eq {none}
4021          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
4022                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
4023         } else {
4024                 set ui_comm_spell [spellcheck::init \
4025                         $spell_fd \
4026                         $ui_comm \
4027                         $ui_comm_ctxm \
4028                 ]
4029         }
4030         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
4031 }
4032
4033 lock_index begin-read
4034 if {![winfo ismapped .]} {
4035         wm deiconify .
4036 }
4037 after 1 {
4038         if {[is_enabled initialamend]} {
4039                 force_amend
4040         } else {
4041                 do_rescan
4042         }
4043
4044         if {[is_enabled nocommitmsg]} {
4045                 $ui_comm configure -state disabled -background gray
4046         }
4047 }
4048 if {[is_enabled multicommit] && ![is_config_false gui.gcwarning]} {
4049         after 1000 hint_gc
4050 }
4051 if {[is_enabled retcode]} {
4052         bind . <Destroy> {+terminate_me %W}
4053 }
4054 if {$picked && [is_config_true gui.autoexplore]} {
4055         do_explore
4056 }
4057
4058 # Local variables:
4059 # mode: tcl
4060 # indent-tabs-mode: t
4061 # tab-width: 4
4062 # End: