git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision $_repository
   8                 $_q $_authors $_authors_prog %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22 $Git::SVN::_minimize_url = 'unset';
  23
  24 if (! exists $ENV{SVN_SSH}) {
  25         if (exists $ENV{GIT_SSH}) {
  26                 $ENV{SVN_SSH} = $ENV{GIT_SSH};
  27                 if ($^O eq 'msys') {
  28                         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  29                         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  30                 }
  31         }
  32 }
  33
  34 $Git::SVN::Log::TZ = $ENV{TZ};
  35 $ENV{TZ} = 'UTC';
  36 $| = 1; # unbuffer STDOUT
  37
  38 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  39 sub _req_svn {
  40         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  41         require SVN::Ra;
  42         require SVN::Delta;
  43         if ($SVN::Core::VERSION lt '1.1.0') {
  44                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  45         }
  46 }
  47 my $can_compress = eval { require Compress::Zlib; 1};
  48 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  49 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  50 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  51 use Carp qw/croak/;
  52 use Digest::MD5;
  53 use IO::File qw//;
  54 use File::Basename qw/dirname basename/;
  55 use File::Path qw/mkpath/;
  56 use File::Spec;
  57 use File::Find;
  58 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  59 use IPC::Open3;
  60 use Git;
  61
  62 BEGIN {
  63         # import functions from Git into our packages, en masse
  64         no strict 'refs';
  65         foreach (qw/command command_oneline command_noisy command_output_pipe
  66                     command_input_pipe command_close_pipe
  67                     command_bidi_pipe command_close_bidi_pipe/) {
  68                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  69                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  70                         __PACKAGE__) {
  71                         *{"${package}::$_"} = \&{"Git::$_"};
  72                 }
  73         }
  74 }
  75
  76 my ($SVN);
  77
  78 $sha1 = qr/[a-f\d]{40}/;
  79 $sha1_short = qr/[a-f\d]{4,40}/;
  80 my ($_stdin, $_help, $_edit,
  81         $_message, $_file, $_branch_dest,
  82         $_template, $_shared,
  83         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
  84         $_merge, $_strategy, $_dry_run, $_local,
  85         $_prefix, $_no_checkout, $_url, $_verbose,
  86         $_git_format, $_commit_url, $_tag);
  87 $Git::SVN::_follow_parent = 1;
  88 $_q ||= 0;
  89 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  90                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  91                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  92                     'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
  93 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  94                 'authors-file|A=s' => \$_authors,
  95                 'authors-prog=s' => \$_authors_prog,
  96                 'repack:i' => \$Git::SVN::_repack,
  97                 'noMetadata' => \$Git::SVN::_no_metadata,
  98                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  99                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 100                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 101                 'no-checkout' => \$_no_checkout,
 102                 'quiet|q+' => \$_q,
 103                 'repack-flags|repack-args|repack-opts=s' =>
 104                    \$Git::SVN::_repack_flags,
 105                 'use-log-author' => \$Git::SVN::_use_log_author,
 106                 'add-author-from' => \$Git::SVN::_add_author_from,
 107                 'localtime' => \$Git::SVN::_localtime,
 108                 %remote_opts );
 109
 110 my ($_trunk, @_tags, @_branches, $_stdlayout);
 111 my %icv;
 112 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 113                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 114                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 115                   'stdlayout|s' => \$_stdlayout,
 116                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 117                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 118                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 119                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 120                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 121                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 122                   %remote_opts );
 123 my %cmt_opts = ( 'edit|e' => \$_edit,
 124                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 125                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 126                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 127                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 128 );
 129
 130 my %cmd = (
 131         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 132                         { 'revision|r=s' => \$_revision,
 133                           'fetch-all|all' => \$_fetch_all,
 134                           'parent|p' => \$_fetch_parent,
 135                            %fc_opts } ],
 136         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 137                         { 'revision|r=s' => \$_revision,
 138                            %fc_opts, %init_opts } ],
 139         init => [ \&cmd_init, "Initialize a repo for tracking" .
 140                           " (requires URL argument)",
 141                           \%init_opts ],
 142         'multi-init' => [ \&cmd_multi_init,
 143                           "Deprecated alias for ".
 144                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 145                           \%init_opts ],
 146         dcommit => [ \&cmd_dcommit,
 147                      'Commit several diffs to merge with upstream',
 148                         { 'merge|m|M' => \$_merge,
 149                           'strategy|s=s' => \$_strategy,
 150                           'verbose|v' => \$_verbose,
 151                           'dry-run|n' => \$_dry_run,
 152                           'fetch-all|all' => \$_fetch_all,
 153                           'commit-url=s' => \$_commit_url,
 154                           'revision|r=i' => \$_revision,
 155                           'no-rebase' => \$_no_rebase,
 156                         %cmt_opts, %fc_opts } ],
 157         branch => [ \&cmd_branch,
 158                     'Create a branch in the SVN repository',
 159                     { 'message|m=s' => \$_message,
 160                       'destination|d=s' => \$_branch_dest,
 161                       'dry-run|n' => \$_dry_run,
 162                       'tag|t' => \$_tag,
 163                       'username=s' => \$Git::SVN::Prompt::_username,
 164                       'commit-url=s' => \$_commit_url } ],
 165         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 166                  'Create a tag in the SVN repository',
 167                  { 'message|m=s' => \$_message,
 168                    'destination|d=s' => \$_branch_dest,
 169                    'dry-run|n' => \$_dry_run,
 170                    'username=s' => \$Git::SVN::Prompt::_username,
 171                    'commit-url=s' => \$_commit_url } ],
 172         'set-tree' => [ \&cmd_set_tree,
 173                         "Set an SVN repository to a git tree-ish",
 174                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 175         'create-ignore' => [ \&cmd_create_ignore,
 176                              'Create a .gitignore per svn:ignore',
 177                              { 'revision|r=i' => \$_revision
 178                              } ],
 179         'mkdirs' => [ \&cmd_mkdirs ,
 180                       "recreate empty directories after a checkout",
 181                       { 'revision|r=i' => \$_revision } ],
 182         'propget' => [ \&cmd_propget,
 183                        'Print the value of a property on a file or directory',
 184                        { 'revision|r=i' => \$_revision } ],
 185         'proplist' => [ \&cmd_proplist,
 186                        'List all properties of a file or directory',
 187                        { 'revision|r=i' => \$_revision } ],
 188         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 189                         { 'revision|r=i' => \$_revision
 190                         } ],
 191         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 192                         { 'revision|r=i' => \$_revision
 193                         } ],
 194         'multi-fetch' => [ \&cmd_multi_fetch,
 195                            "Deprecated alias for $0 fetch --all",
 196                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 197         'migrate' => [ sub { },
 198                        # no-op, we automatically run this anyways,
 199                        'Migrate configuration/metadata/layout from
 200                         previous versions of git-svn',
 201                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 202                          %remote_opts } ],
 203         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 204                         { 'limit=i' => \$Git::SVN::Log::limit,
 205                           'revision|r=s' => \$_revision,
 206                           'verbose|v' => \$Git::SVN::Log::verbose,
 207                           'incremental' => \$Git::SVN::Log::incremental,
 208                           'oneline' => \$Git::SVN::Log::oneline,
 209                           'show-commit' => \$Git::SVN::Log::show_commit,
 210                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 211                           'authors-file|A=s' => \$_authors,
 212                           'color' => \$Git::SVN::Log::color,
 213                           'pager=s' => \$Git::SVN::Log::pager
 214                         } ],
 215         'find-rev' => [ \&cmd_find_rev,
 216                         "Translate between SVN revision numbers and tree-ish",
 217                         {} ],
 218         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 219                         { 'merge|m|M' => \$_merge,
 220                           'verbose|v' => \$_verbose,
 221                           'strategy|s=s' => \$_strategy,
 222                           'local|l' => \$_local,
 223                           'fetch-all|all' => \$_fetch_all,
 224                           'dry-run|n' => \$_dry_run,
 225                           %fc_opts } ],
 226         'commit-diff' => [ \&cmd_commit_diff,
 227                            'Commit a diff between two trees',
 228                         { 'message|m=s' => \$_message,
 229                           'file|F=s' => \$_file,
 230                           'revision|r=s' => \$_revision,
 231                         %cmt_opts } ],
 232         'info' => [ \&cmd_info,
 233                     "Show info about the latest SVN revision
 234                      on the current branch",
 235                     { 'url' => \$_url, } ],
 236         'blame' => [ \&Git::SVN::Log::cmd_blame,
 237                     "Show what revision and author last modified each line of a file",
 238                     { 'git-format' => \$_git_format } ],
 239         'reset' => [ \&cmd_reset,
 240                      "Undo fetches back to the specified SVN revision",
 241                      { 'revision|r=s' => \$_revision,
 242                        'parent|p' => \$_fetch_parent } ],
 243         'gc' => [ \&cmd_gc,
 244                   "Compress unhandled.log files in .git/svn and remove " .
 245                   "index files in .git/svn",
 246                 {} ],
 247 );
 248
 249 my $cmd;
 250 for (my $i = 0; $i < @ARGV; $i++) {
 251         if (defined $cmd{$ARGV[$i]}) {
 252                 $cmd = $ARGV[$i];
 253                 splice @ARGV, $i, 1;
 254                 last;
 255         } elsif ($ARGV[$i] eq 'help') {
 256                 $cmd = $ARGV[$i+1];
 257                 usage(0);
 258         }
 259 };
 260
 261 # make sure we're always running at the top-level working directory
 262 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 263         unless (-d $ENV{GIT_DIR}) {
 264                 if ($git_dir_user_set) {
 265                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 266                             "but it is not a directory\n";
 267                 }
 268                 my $git_dir = delete $ENV{GIT_DIR};
 269                 my $cdup = undef;
 270                 git_cmd_try {
 271                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 272                         $git_dir = '.' unless ($cdup);
 273                         chomp $cdup if ($cdup);
 274                         $cdup = "." unless ($cdup && length $cdup);
 275                 } "Already at toplevel, but $git_dir not found\n";
 276                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 277                 unless (-d $git_dir) {
 278                         die "$git_dir still not found after going to ",
 279                             "'$cdup'\n";
 280                 }
 281                 $ENV{GIT_DIR} = $git_dir;
 282         }
 283         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 284 }
 285
 286 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 287
 288 read_git_config(\%opts);
 289 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 290         Getopt::Long::Configure('pass_through');
 291 }
 292 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 293                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 294                     'id|i=s' => \$Git::SVN::default_ref_id,
 295                     'svn-remote|remote|R=s' => sub {
 296                        $Git::SVN::no_reuse_existing = 1;
 297                        $Git::SVN::default_repo_id = $_[1] });
 298 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 299
 300 usage(0) if $_help;
 301 version() if $_version;
 302 usage(1) unless defined $cmd;
 303 load_authors() if $_authors;
 304 if (defined $_authors_prog) {
 305         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 306 }
 307
 308 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 309         Git::SVN::Migration::migration_check();
 310 }
 311 Git::SVN::init_vars();
 312 eval {
 313         Git::SVN::verify_remotes_sanity();
 314         $cmd{$cmd}->[0]->(@ARGV);
 315 };
 316 fatal $@ if $@;
 317 post_fetch_checkout();
 318 exit 0;
 319
 320 ####################### primary functions ######################
 321 sub usage {
 322         my $exit = shift || 0;
 323         my $fd = $exit ? \*STDERR : \*STDOUT;
 324         print $fd <<"";
 325 git-svn - bidirectional operations between a single Subversion tree and git
 326 Usage: git svn <command> [options] [arguments]\n
 327
 328         print $fd "Available commands:\n" unless $cmd;
 329
 330         foreach (sort keys %cmd) {
 331                 next if $cmd && $cmd ne $_;
 332                 next if /^multi-/; # don't show deprecated commands
 333                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 334                 foreach (sort keys %{$cmd{$_}->[2]}) {
 335                         # mixed-case options are for .git/config only
 336                         next if /[A-Z]/ && /^[a-z]+$/i;
 337                         # prints out arguments as they should be passed:
 338                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 339                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 340                                                         "--$_" : "-$_" }
 341                                                 split /\|/,$_)," $x\n";
 342                 }
 343         }
 344         print $fd <<"";
 345 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 346 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 347 one git repository and want to keep them separate.  See git-svn(1) for more
 348 information.
 349
 350         exit $exit;
 351 }
 352
 353 sub version {
 354         ::_req_svn();
 355         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 356         exit 0;
 357 }
 358
 359 sub do_git_init_db {
 360         unless (-d $ENV{GIT_DIR}) {
 361                 my @init_db = ('init');
 362                 push @init_db, "--template=$_template" if defined $_template;
 363                 if (defined $_shared) {
 364                         if ($_shared =~ /[a-z]/) {
 365                                 push @init_db, "--shared=$_shared";
 366                         } else {
 367                                 push @init_db, "--shared";
 368                         }
 369                 }
 370                 command_noisy(@init_db);
 371                 $_repository = Git->repository(Repository => ".git");
 372         }
 373         my $set;
 374         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 375         foreach my $i (keys %icv) {
 376                 die "'$set' and '$i' cannot both be set\n" if $set;
 377                 next unless defined $icv{$i};
 378                 command_noisy('config', "$pfx.$i", $icv{$i});
 379                 $set = $i;
 380         }
 381         my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
 382         command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
 383                 if defined $$ignore_regex;
 384 }
 385
 386 sub init_subdir {
 387         my $repo_path = shift or return;
 388         mkpath([$repo_path]) unless -d $repo_path;
 389         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 390         $ENV{GIT_DIR} = '.git';
 391         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 392 }
 393
 394 sub cmd_clone {
 395         my ($url, $path) = @_;
 396         if (!defined $path &&
 397             (defined $_trunk || @_branches || @_tags ||
 398              defined $_stdlayout) &&
 399             $url !~ m#^[a-z\+]+://#) {
 400                 $path = $url;
 401         }
 402         $path = basename($url) if !defined $path || !length $path;
 403         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 404         cmd_init($url, $path);
 405         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 406             if $_authors;
 407         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 408 }
 409
 410 sub cmd_init {
 411         if (defined $_stdlayout) {
 412                 $_trunk = 'trunk' if (!defined $_trunk);
 413                 @_tags = 'tags' if (! @_tags);
 414                 @_branches = 'branches' if (! @_branches);
 415         }
 416         if (defined $_trunk || @_branches || @_tags) {
 417                 return cmd_multi_init(@_);
 418         }
 419         my $url = shift or die "SVN repository location required ",
 420                                "as a command-line argument\n";
 421         $url = canonicalize_url($url);
 422         init_subdir(@_);
 423         do_git_init_db();
 424
 425         if ($Git::SVN::_minimize_url eq 'unset') {
 426                 $Git::SVN::_minimize_url = 0;
 427         }
 428
 429         Git::SVN->init($url);
 430 }
 431
 432 sub cmd_fetch {
 433         if (grep /^\d+=./, @_) {
 434                 die "'<rev>=<commit>' fetch arguments are ",
 435                     "no longer supported.\n";
 436         }
 437         my ($remote) = @_;
 438         if (@_ > 1) {
 439                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 440         }
 441         $Git::SVN::no_reuse_existing = undef;
 442         if ($_fetch_parent) {
 443                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 444                 unless ($gs) {
 445                         die "Unable to determine upstream SVN information from ",
 446                             "working tree history\n";
 447                 }
 448                 # just fetch, don't checkout.
 449                 $_no_checkout = 'true';
 450                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 451         } elsif ($_fetch_all) {
 452                 cmd_multi_fetch();
 453         } else {
 454                 $remote ||= $Git::SVN::default_repo_id;
 455                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 456         }
 457 }
 458
 459 sub cmd_set_tree {
 460         my (@commits) = @_;
 461         if ($_stdin || !@commits) {
 462                 print "Reading from stdin...\n";
 463                 @commits = ();
 464                 while (<STDIN>) {
 465                         if (/\b($sha1_short)\b/o) {
 466                                 unshift @commits, $1;
 467                         }
 468                 }
 469         }
 470         my @revs;
 471         foreach my $c (@commits) {
 472                 my @tmp = command('rev-parse',$c);
 473                 if (scalar @tmp == 1) {
 474                         push @revs, $tmp[0];
 475                 } elsif (scalar @tmp > 1) {
 476                         push @revs, reverse(command('rev-list',@tmp));
 477                 } else {
 478                         fatal "Failed to rev-parse $c";
 479                 }
 480         }
 481         my $gs = Git::SVN->new;
 482         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 483         $gs->fetch;
 484         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 485                 fatal "There are new revisions that were fetched ",
 486                       "and need to be merged (or acknowledged) ",
 487                       "before committing.\nlast rev: $r_last\n",
 488                       " current: $gs->{last_rev}";
 489         }
 490         $gs->set_tree($_) foreach @revs;
 491         print "Done committing ",scalar @revs," revisions to SVN\n";
 492         unlink $gs->{index};
 493 }
 494
 495 sub cmd_dcommit {
 496         my $head = shift;
 497         command_noisy(qw/update-index --refresh/);
 498         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 499                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 500                 . "or stash them with `git stash'.\n";
 501         $head ||= 'HEAD';
 502
 503         my $old_head;
 504         if ($head ne 'HEAD') {
 505                 $old_head = eval {
 506                         command_oneline([qw/symbolic-ref -q HEAD/])
 507                 };
 508                 if ($old_head) {
 509                         $old_head =~ s{^refs/heads/}{};
 510                 } else {
 511                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 512                 }
 513                 command(['checkout', $head], STDERR => 0);
 514         }
 515
 516         my @refs;
 517         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 518         unless ($gs) {
 519                 die "Unable to determine upstream SVN information from ",
 520                     "$head history.\nPerhaps the repository is empty.";
 521         }
 522
 523         if (defined $_commit_url) {
 524                 $url = $_commit_url;
 525         } else {
 526                 $url = eval { command_oneline('config', '--get',
 527                               "svn-remote.$gs->{repo_id}.commiturl") };
 528                 if (!$url) {
 529                         $url = $gs->full_url
 530                 }
 531         }
 532
 533         my $last_rev = $_revision if defined $_revision;
 534         if ($url) {
 535                 print "Committing to $url ...\n";
 536         }
 537         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 538         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 539                 warn "Attempting to commit more than one change while ",
 540                      "--no-rebase is enabled.\n",
 541                      "If these changes depend on each other, re-running ",
 542                      "without --no-rebase may be required."
 543         }
 544         my $expect_url = $url;
 545         Git::SVN::remove_username($expect_url);
 546         while (1) {
 547                 my $d = shift @$linear_refs or last;
 548                 unless (defined $last_rev) {
 549                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 550                         unless (defined $last_rev) {
 551                                 fatal "Unable to extract revision information ",
 552                                       "from commit $d~1";
 553                         }
 554                 }
 555                 if ($_dry_run) {
 556                         print "diff-tree $d~1 $d\n";
 557                 } else {
 558                         my $cmt_rev;
 559                         my %ed_opts = ( r => $last_rev,
 560                                         log => get_commit_entry($d)->{log},
 561                                         ra => Git::SVN::Ra->new($url),
 562                                         config => SVN::Core::config_get_config(
 563                                                 $Git::SVN::Ra::config_dir
 564                                         ),
 565                                         tree_a => "$d~1",
 566                                         tree_b => $d,
 567                                         editor_cb => sub {
 568                                                print "Committed r$_[0]\n";
 569                                                $cmt_rev = $_[0];
 570                                         },
 571                                         svn_path => '');
 572                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 573                                 print "No changes\n$d~1 == $d\n";
 574                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 575                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 576                                                                $parents->{$d};
 577                         }
 578                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 579                         $last_rev = $cmt_rev;
 580                         next if $_no_rebase;
 581
 582                         # we always want to rebase against the current HEAD,
 583                         # not any head that was passed to us
 584                         my @diff = command('diff-tree', $d,
 585                                            $gs->refname, '--');
 586                         my @finish;
 587                         if (@diff) {
 588                                 @finish = rebase_cmd();
 589                                 print STDERR "W: $d and ", $gs->refname,
 590                                              " differ, using @finish:\n",
 591                                              join("\n", @diff), "\n";
 592                         } else {
 593                                 print "No changes between current HEAD and ",
 594                                       $gs->refname,
 595                                       "\nResetting to the latest ",
 596                                       $gs->refname, "\n";
 597                                 @finish = qw/reset --mixed/;
 598                         }
 599                         command_noisy(@finish, $gs->refname);
 600                         if (@diff) {
 601                                 @refs = ();
 602                                 my ($url_, $rev_, $uuid_, $gs_) =
 603                                               working_head_info('HEAD', \@refs);
 604                                 my ($linear_refs_, $parents_) =
 605                                               linearize_history($gs_, \@refs);
 606                                 if (scalar(@$linear_refs) !=
 607                                     scalar(@$linear_refs_)) {
 608                                         fatal "# of revisions changed ",
 609                                           "\nbefore:\n",
 610                                           join("\n", @$linear_refs),
 611                                           "\n\nafter:\n",
 612                                           join("\n", @$linear_refs_), "\n",
 613                                           'If you are attempting to commit ',
 614                                           "merges, try running:\n\t",
 615                                           'git rebase --interactive',
 616                                           '--preserve-merges ',
 617                                           $gs->refname,
 618                                           "\nBefore dcommitting";
 619                                 }
 620                                 if ($url_ ne $expect_url) {
 621                                         if ($url_ eq $gs->metadata_url) {
 622                                                 print
 623                                                   "Accepting rewritten URL:",
 624                                                   " $url_\n";
 625                                         } else {
 626                                                 fatal
 627                                                   "URL mismatch after rebase:",
 628                                                   " $url_ != $expect_url";
 629                                         }
 630                                 }
 631                                 if ($uuid_ ne $uuid) {
 632                                         fatal "uuid mismatch after rebase: ",
 633                                               "$uuid_ != $uuid";
 634                                 }
 635                                 # remap parents
 636                                 my (%p, @l, $i);
 637                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 638                                         my $new = $linear_refs_->[$i] or next;
 639                                         $p{$new} =
 640                                                 $parents->{$linear_refs->[$i]};
 641                                         push @l, $new;
 642                                 }
 643                                 $parents = \%p;
 644                                 $linear_refs = \@l;
 645                         }
 646                 }
 647         }
 648
 649         if ($old_head) {
 650                 my $new_head = command_oneline(qw/rev-parse HEAD/);
 651                 my $new_is_symbolic = eval {
 652                         command_oneline(qw/symbolic-ref -q HEAD/);
 653                 };
 654                 if ($new_is_symbolic) {
 655                         print "dcommitted the branch ", $head, "\n";
 656                 } else {
 657                         print "dcommitted on a detached HEAD because you gave ",
 658                               "a revision argument.\n",
 659                               "The rewritten commit is: ", $new_head, "\n";
 660                 }
 661                 command(['checkout', $old_head], STDERR => 0);
 662         }
 663
 664         unlink $gs->{index};
 665 }
 666
 667 sub cmd_branch {
 668         my ($branch_name, $head) = @_;
 669
 670         unless (defined $branch_name && length $branch_name) {
 671                 die(($_tag ? "tag" : "branch") . " name required\n");
 672         }
 673         $head ||= 'HEAD';
 674
 675         my (undef, $rev, undef, $gs) = working_head_info($head);
 676         my $src = $gs->full_url;
 677
 678         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 679         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
 680         my $glob;
 681         if ($#{$allglobs} == 0) {
 682                 $glob = $allglobs->[0];
 683         } else {
 684                 unless(defined $_branch_dest) {
 685                         die "Multiple ",
 686                             $_tag ? "tag" : "branch",
 687                             " paths defined for Subversion repository.\n",
 688                             "You must specify where you want to create the ",
 689                             $_tag ? "tag" : "branch",
 690                             " with the --destination argument.\n";
 691                 }
 692                 foreach my $g (@{$allglobs}) {
 693                         # SVN::Git::Editor could probably be moved to Git.pm..
 694                         my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
 695                         if ($_branch_dest =~ /$re/) {
 696                                 $glob = $g;
 697                                 last;
 698                         }
 699                 }
 700                 unless (defined $glob) {
 701                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
 702                         foreach my $g (@{$allglobs}) {
 703                                 $g->{path}->{left} =~ /$dest_re/ or next;
 704                                 if (defined $glob) {
 705                                         die "Ambiguous destination: ",
 706                                             $_branch_dest, "\nmatches both '",
 707                                             $glob->{path}->{left}, "' and '",
 708                                             $g->{path}->{left}, "'\n";
 709                                 }
 710                                 $glob = $g;
 711                         }
 712                         unless (defined $glob) {
 713                                 die "Unknown ",
 714                                     $_tag ? "tag" : "branch",
 715                                     " destination $_branch_dest\n";
 716                         }
 717                 }
 718         }
 719         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 720         my $url;
 721         if (defined $_commit_url) {
 722                 $url = $_commit_url;
 723         } else {
 724                 $url = eval { command_oneline('config', '--get',
 725                         "svn-remote.$gs->{repo_id}.commiturl") };
 726                 if (!$url) {
 727                         $url = $remote->{url};
 728                 }
 729         }
 730         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
 731
 732         if ($dst =~ /^https:/ && $src =~ /^http:/) {
 733                 $src=~s/^http:/https:/;
 734         }
 735
 736         ::_req_svn();
 737
 738         my $ctx = SVN::Client->new(
 739                 auth    => Git::SVN::Ra::_auth_providers(),
 740                 log_msg => sub {
 741                         ${ $_[0] } = defined $_message
 742                                 ? $_message
 743                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 744                                 . $branch_name;
 745                 },
 746         );
 747
 748         eval {
 749                 $ctx->ls($dst, 'HEAD', 0);
 750         } and die "branch ${branch_name} already exists\n";
 751
 752         print "Copying ${src} at r${rev} to ${dst}...\n";
 753         $ctx->copy($src, $rev, $dst)
 754                 unless $_dry_run;
 755
 756         $gs->fetch_all;
 757 }
 758
 759 sub cmd_find_rev {
 760         my $revision_or_hash = shift or die "SVN or git revision required ",
 761                                             "as a command-line argument\n";
 762         my $result;
 763         if ($revision_or_hash =~ /^r\d+$/) {
 764                 my $head = shift;
 765                 $head ||= 'HEAD';
 766                 my @refs;
 767                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 768                 unless ($gs) {
 769                         die "Unable to determine upstream SVN information from ",
 770                             "$head history\n";
 771                 }
 772                 my $desired_revision = substr($revision_or_hash, 1);
 773                 $result = $gs->rev_map_get($desired_revision, $uuid);
 774         } else {
 775                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 776                 $result = $rev;
 777         }
 778         print "$result\n" if $result;
 779 }
 780
 781 sub cmd_rebase {
 782         command_noisy(qw/update-index --refresh/);
 783         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 784         unless ($gs) {
 785                 die "Unable to determine upstream SVN information from ",
 786                     "working tree history\n";
 787         }
 788         if ($_dry_run) {
 789                 print "Remote Branch: " . $gs->refname . "\n";
 790                 print "SVN URL: " . $url . "\n";
 791                 return;
 792         }
 793         if (command(qw/diff-index HEAD --/)) {
 794                 print STDERR "Cannot rebase with uncommited changes:\n";
 795                 command_noisy('status');
 796                 exit 1;
 797         }
 798         unless ($_local) {
 799                 # rebase will checkout for us, so no need to do it explicitly
 800                 $_no_checkout = 'true';
 801                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 802         }
 803         command_noisy(rebase_cmd(), $gs->refname);
 804         $gs->mkemptydirs;
 805 }
 806
 807 sub cmd_show_ignore {
 808         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 809         $gs ||= Git::SVN->new;
 810         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 811         $gs->prop_walk($gs->{path}, $r, sub {
 812                 my ($gs, $path, $props) = @_;
 813                 print STDOUT "\n# $path\n";
 814                 my $s = $props->{'svn:ignore'} or return;
 815                 $s =~ s/[\r\n]+/\n/g;
 816                 $s =~ s/^\n+//;
 817                 chomp $s;
 818                 $s =~ s#^#$path#gm;
 819                 print STDOUT "$s\n";
 820         });
 821 }
 822
 823 sub cmd_show_externals {
 824         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 825         $gs ||= Git::SVN->new;
 826         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 827         $gs->prop_walk($gs->{path}, $r, sub {
 828                 my ($gs, $path, $props) = @_;
 829                 print STDOUT "\n# $path\n";
 830                 my $s = $props->{'svn:externals'} or return;
 831                 $s =~ s/[\r\n]+/\n/g;
 832                 chomp $s;
 833                 $s =~ s#^#$path#gm;
 834                 print STDOUT "$s\n";
 835         });
 836 }
 837
 838 sub cmd_create_ignore {
 839         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 840         $gs ||= Git::SVN->new;
 841         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 842         $gs->prop_walk($gs->{path}, $r, sub {
 843                 my ($gs, $path, $props) = @_;
 844                 # $path is of the form /path/to/dir/
 845                 $path = '.' . $path;
 846                 # SVN can have attributes on empty directories,
 847                 # which git won't track
 848                 mkpath([$path]) unless -d $path;
 849                 my $ignore = $path . '.gitignore';
 850                 my $s = $props->{'svn:ignore'} or return;
 851                 open(GITIGNORE, '>', $ignore)
 852                   or fatal("Failed to open `$ignore' for writing: $!");
 853                 $s =~ s/[\r\n]+/\n/g;
 854                 $s =~ s/^\n+//;
 855                 chomp $s;
 856                 # Prefix all patterns so that the ignore doesn't apply
 857                 # to sub-directories.
 858                 $s =~ s#^#/#gm;
 859                 print GITIGNORE "$s\n";
 860                 close(GITIGNORE)
 861                   or fatal("Failed to close `$ignore': $!");
 862                 command_noisy('add', '-f', $ignore);
 863         });
 864 }
 865
 866 sub cmd_mkdirs {
 867         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 868         $gs ||= Git::SVN->new;
 869         $gs->mkemptydirs($_revision);
 870 }
 871
 872 sub canonicalize_path {
 873         my ($path) = @_;
 874         my $dot_slash_added = 0;
 875         if (substr($path, 0, 1) ne "/") {
 876                 $path = "./" . $path;
 877                 $dot_slash_added = 1;
 878         }
 879         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 880         # good reason), so let's do this manually.
 881         $path =~ s#/+#/#g;
 882         $path =~ s#/\.(?:/|$)#/#g;
 883         $path =~ s#/[^/]+/\.\.##g;
 884         $path =~ s#/$##g;
 885         $path =~ s#^\./## if $dot_slash_added;
 886         $path =~ s#^/##;
 887         $path =~ s#^\.$##;
 888         return $path;
 889 }
 890
 891 sub canonicalize_url {
 892         my ($url) = @_;
 893         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 894         return $url;
 895 }
 896
 897 # get_svnprops(PATH)
 898 # ------------------
 899 # Helper for cmd_propget and cmd_proplist below.
 900 sub get_svnprops {
 901         my $path = shift;
 902         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 903         $gs ||= Git::SVN->new;
 904
 905         # prefix THE PATH by the sub-directory from which the user
 906         # invoked us.
 907         $path = $cmd_dir_prefix . $path;
 908         fatal("No such file or directory: $path") unless -e $path;
 909         my $is_dir = -d $path ? 1 : 0;
 910         $path = $gs->{path} . '/' . $path;
 911
 912         # canonicalize the path (otherwise libsvn will abort or fail to
 913         # find the file)
 914         $path = canonicalize_path($path);
 915
 916         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 917         my $props;
 918         if ($is_dir) {
 919                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 920         }
 921         else {
 922                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 923         }
 924         return $props;
 925 }
 926
 927 # cmd_propget (PROP, PATH)
 928 # ------------------------
 929 # Print the SVN property PROP for PATH.
 930 sub cmd_propget {
 931         my ($prop, $path) = @_;
 932         $path = '.' if not defined $path;
 933         usage(1) if not defined $prop;
 934         my $props = get_svnprops($path);
 935         if (not defined $props->{$prop}) {
 936                 fatal("`$path' does not have a `$prop' SVN property.");
 937         }
 938         print $props->{$prop} . "\n";
 939 }
 940
 941 # cmd_proplist (PATH)
 942 # -------------------
 943 # Print the list of SVN properties for PATH.
 944 sub cmd_proplist {
 945         my $path = shift;
 946         $path = '.' if not defined $path;
 947         my $props = get_svnprops($path);
 948         print "Properties on '$path':\n";
 949         foreach (sort keys %{$props}) {
 950                 print "  $_\n";
 951         }
 952 }
 953
 954 sub cmd_multi_init {
 955         my $url = shift;
 956         unless (defined $_trunk || @_branches || @_tags) {
 957                 usage(1);
 958         }
 959
 960         $_prefix = '' unless defined $_prefix;
 961         if (defined $url) {
 962                 $url = canonicalize_url($url);
 963                 init_subdir(@_);
 964         }
 965         do_git_init_db();
 966         if (defined $_trunk) {
 967                 $_trunk =~ s#^/+##;
 968                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
 969                 # try both old-style and new-style lookups:
 970                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 971                 unless ($gs_trunk) {
 972                         my ($trunk_url, $trunk_path) =
 973                                               complete_svn_url($url, $_trunk);
 974                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 975                                                    undef, $trunk_ref);
 976                 }
 977         }
 978         return unless @_branches || @_tags;
 979         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 980         foreach my $path (@_branches) {
 981                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
 982         }
 983         foreach my $path (@_tags) {
 984                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
 985         }
 986 }
 987
 988 sub cmd_multi_fetch {
 989         $Git::SVN::no_reuse_existing = undef;
 990         my $remotes = Git::SVN::read_all_remotes();
 991         foreach my $repo_id (sort keys %$remotes) {
 992                 if ($remotes->{$repo_id}->{url}) {
 993                         Git::SVN::fetch_all($repo_id, $remotes);
 994                 }
 995         }
 996 }
 997
 998 # this command is special because it requires no metadata
 999 sub cmd_commit_diff {
1000         my ($ta, $tb, $url) = @_;
1001         my $usage = "Usage: $0 commit-diff -r<revision> ".
1002                     "<tree-ish> <tree-ish> [<URL>]";
1003         fatal($usage) if (!defined $ta || !defined $tb);
1004         my $svn_path = '';
1005         if (!defined $url) {
1006                 my $gs = eval { Git::SVN->new };
1007                 if (!$gs) {
1008                         fatal("Needed URL or usable git-svn --id in ",
1009                               "the command-line\n", $usage);
1010                 }
1011                 $url = $gs->{url};
1012                 $svn_path = $gs->{path};
1013         }
1014         unless (defined $_revision) {
1015                 fatal("-r|--revision is a required argument\n", $usage);
1016         }
1017         if (defined $_message && defined $_file) {
1018                 fatal("Both --message/-m and --file/-F specified ",
1019                       "for the commit message.\n",
1020                       "I have no idea what you mean");
1021         }
1022         if (defined $_file) {
1023                 $_message = file_to_s($_file);
1024         } else {
1025                 $_message ||= get_commit_entry($tb)->{log};
1026         }
1027         my $ra ||= Git::SVN::Ra->new($url);
1028         my $r = $_revision;
1029         if ($r eq 'HEAD') {
1030                 $r = $ra->get_latest_revnum;
1031         } elsif ($r !~ /^\d+$/) {
1032                 die "revision argument: $r not understood by git-svn\n";
1033         }
1034         my %ed_opts = ( r => $r,
1035                         log => $_message,
1036                         ra => $ra,
1037                         tree_a => $ta,
1038                         tree_b => $tb,
1039                         editor_cb => sub { print "Committed r$_[0]\n" },
1040                         svn_path => $svn_path );
1041         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1042                 print "No changes\n$ta == $tb\n";
1043         }
1044 }
1045
1046 sub escape_uri_only {
1047         my ($uri) = @_;
1048         my @tmp;
1049         foreach (split m{/}, $uri) {
1050                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1051                 push @tmp, $_;
1052         }
1053         join('/', @tmp);
1054 }
1055
1056 sub escape_url {
1057         my ($url) = @_;
1058         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1059                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1060                 $url = "$scheme://$domain$uri";
1061         }
1062         $url;
1063 }
1064
1065 sub cmd_info {
1066         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1067         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1068         if (exists $_[1]) {
1069                 die "Too many arguments specified\n";
1070         }
1071
1072         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1073
1074         if (!$file_type && !$diff_status) {
1075                 print STDERR "svn: '$path' is not under version control\n";
1076                 exit 1;
1077         }
1078
1079         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1080         unless ($gs) {
1081                 die "Unable to determine upstream SVN information from ",
1082                     "working tree history\n";
1083         }
1084
1085         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1086         $path = "." if $path eq "";
1087
1088         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1089
1090         if ($_url) {
1091                 print escape_url($full_url), "\n";
1092                 return;
1093         }
1094
1095         my $result = "Path: $path\n";
1096         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1097         $result .= "URL: " . escape_url($full_url) . "\n";
1098
1099         eval {
1100                 my $repos_root = $gs->repos_root;
1101                 Git::SVN::remove_username($repos_root);
1102                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1103         };
1104         if ($@) {
1105                 $result .= "Repository Root: (offline)\n";
1106         }
1107         ::_req_svn();
1108         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1109                 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1110         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1111
1112         $result .= "Node Kind: " .
1113                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1114
1115         my $schedule = $diff_status eq "A"
1116                        ? "add"
1117                        : ($diff_status eq "D" ? "delete" : "normal");
1118         $result .= "Schedule: $schedule\n";
1119
1120         if ($diff_status eq "A") {
1121                 print $result, "\n";
1122                 return;
1123         }
1124
1125         my ($lc_author, $lc_rev, $lc_date_utc);
1126         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1127         my $log = command_output_pipe(@args);
1128         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1129         while (<$log>) {
1130                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1131                         $lc_author = $1;
1132                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1133                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1134                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1135                 }
1136         }
1137         close $log;
1138
1139         Git::SVN::Log::set_local_timezone();
1140
1141         $result .= "Last Changed Author: $lc_author\n";
1142         $result .= "Last Changed Rev: $lc_rev\n";
1143         $result .= "Last Changed Date: " .
1144                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1145
1146         if ($file_type ne "dir") {
1147                 my $text_last_updated_date =
1148                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1149                 $result .=
1150                     "Text Last Updated: " .
1151                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1152                     "\n";
1153                 my $checksum;
1154                 if ($diff_status eq "D") {
1155                         my ($fh, $ctx) =
1156                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1157                         if ($file_type eq "link") {
1158                                 my $file_name = <$fh>;
1159                                 $checksum = md5sum("link $file_name");
1160                         } else {
1161                                 $checksum = md5sum($fh);
1162                         }
1163                         command_close_pipe($fh, $ctx);
1164                 } elsif ($file_type eq "link") {
1165                         my $file_name =
1166                             command(qw(cat-file blob), "HEAD:$path");
1167                         $checksum =
1168                             md5sum("link " . $file_name);
1169                 } else {
1170                         open FILE, "<", $path or die $!;
1171                         $checksum = md5sum(\*FILE);
1172                         close FILE or die $!;
1173                 }
1174                 $result .= "Checksum: " . $checksum . "\n";
1175         }
1176
1177         print $result, "\n";
1178 }
1179
1180 sub cmd_reset {
1181         my $target = shift || $_revision or die "SVN revision required\n";
1182         $target = $1 if $target =~ /^r(\d+)$/;
1183         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1184         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1185         unless ($gs) {
1186                 die "Unable to determine upstream SVN information from ".
1187                     "history\n";
1188         }
1189         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1190         die "Cannot find SVN revision $target\n" unless defined($c);
1191         $gs->rev_map_set($r, $c, 'reset', $uuid);
1192         print "r$r = $c ($gs->{ref_id})\n";
1193 }
1194
1195 sub cmd_gc {
1196         if (!$can_compress) {
1197                 warn "Compress::Zlib could not be found; unhandled.log " .
1198                      "files will not be compressed.\n";
1199         }
1200         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1201 }
1202
1203 ########################### utility functions #########################
1204
1205 sub rebase_cmd {
1206         my @cmd = qw/rebase/;
1207         push @cmd, '-v' if $_verbose;
1208         push @cmd, qw/--merge/ if $_merge;
1209         push @cmd, "--strategy=$_strategy" if $_strategy;
1210         @cmd;
1211 }
1212
1213 sub post_fetch_checkout {
1214         return if $_no_checkout;
1215         my $gs = $Git::SVN::_head or return;
1216         return if verify_ref('refs/heads/master^0');
1217
1218         # look for "trunk" ref if it exists
1219         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1220         my $fetch = $remote->{fetch};
1221         if ($fetch) {
1222                 foreach my $p (keys %$fetch) {
1223                         basename($fetch->{$p}) eq 'trunk' or next;
1224                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1225                         last;
1226                 }
1227         }
1228
1229         my $valid_head = verify_ref('HEAD^0');
1230         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1231         return if ($valid_head || !verify_ref('HEAD^0'));
1232
1233         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1234         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1235         return if -f $index;
1236
1237         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1238         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1239         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1240         print STDERR "Checked out HEAD:\n  ",
1241                      $gs->full_url, " r", $gs->last_rev, "\n";
1242         $gs->mkemptydirs($gs->last_rev);
1243 }
1244
1245 sub complete_svn_url {
1246         my ($url, $path) = @_;
1247         $path =~ s#/+$##;
1248         if ($path !~ m#^[a-z\+]+://#) {
1249                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1250                         fatal("E: '$path' is not a complete URL ",
1251                               "and a separate URL is not specified");
1252                 }
1253                 return ($url, $path);
1254         }
1255         return ($path, '');
1256 }
1257
1258 sub complete_url_ls_init {
1259         my ($ra, $repo_path, $switch, $pfx) = @_;
1260         unless ($repo_path) {
1261                 print STDERR "W: $switch not specified\n";
1262                 return;
1263         }
1264         $repo_path =~ s#/+$##;
1265         if ($repo_path =~ m#^[a-z\+]+://#) {
1266                 $ra = Git::SVN::Ra->new($repo_path);
1267                 $repo_path = '';
1268         } else {
1269                 $repo_path =~ s#^/+##;
1270                 unless ($ra) {
1271                         fatal("E: '$repo_path' is not a complete URL ",
1272                               "and a separate URL is not specified");
1273                 }
1274         }
1275         my $url = $ra->{url};
1276         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1277         my $k = "svn-remote.$gs->{repo_id}.url";
1278         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1279         if ($orig_url && ($orig_url ne $gs->{url})) {
1280                 die "$k already set: $orig_url\n",
1281                     "wanted to set to: $gs->{url}\n";
1282         }
1283         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1284         my $remote_path = "$gs->{path}/$repo_path";
1285         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1286         $remote_path =~ s#/+#/#g;
1287         $remote_path =~ s#^/##g;
1288         $remote_path .= "/*" if $remote_path !~ /\*/;
1289         my ($n) = ($switch =~ /^--(\w+)/);
1290         if (length $pfx && $pfx !~ m#/$#) {
1291                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1292         }
1293         command_noisy('config',
1294                       '--add',
1295                       "svn-remote.$gs->{repo_id}.$n",
1296                       "$remote_path:refs/remotes/$pfx*" .
1297                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1298 }
1299
1300 sub verify_ref {
1301         my ($ref) = @_;
1302         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1303                                { STDERR => 0 }); };
1304 }
1305
1306 sub get_tree_from_treeish {
1307         my ($treeish) = @_;
1308         # $treeish can be a symbolic ref, too:
1309         my $type = command_oneline(qw/cat-file -t/, $treeish);
1310         my $expected;
1311         while ($type eq 'tag') {
1312                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1313         }
1314         if ($type eq 'commit') {
1315                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1316                                                     $treeish))[0];
1317                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1318                 die "Unable to get tree from $treeish\n" unless $expected;
1319         } elsif ($type eq 'tree') {
1320                 $expected = $treeish;
1321         } else {
1322                 die "$treeish is a $type, expected tree, tag or commit\n";
1323         }
1324         return $expected;
1325 }
1326
1327 sub get_commit_entry {
1328         my ($treeish) = shift;
1329         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1330         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1331         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1332         open my $log_fh, '>', $commit_editmsg or croak $!;
1333
1334         my $type = command_oneline(qw/cat-file -t/, $treeish);
1335         if ($type eq 'commit' || $type eq 'tag') {
1336                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1337                                                          $type, $treeish);
1338                 my $in_msg = 0;
1339                 my $author;
1340                 my $saw_from = 0;
1341                 my $msgbuf = "";
1342                 while (<$msg_fh>) {
1343                         if (!$in_msg) {
1344                                 $in_msg = 1 if (/^\s*$/);
1345                                 $author = $1 if (/^author (.*>)/);
1346                         } elsif (/^git-svn-id: /) {
1347                                 # skip this for now, we regenerate the
1348                                 # correct one on re-fetch anyways
1349                                 # TODO: set *:merge properties or like...
1350                         } else {
1351                                 if (/^From:/ || /^Signed-off-by:/) {
1352                                         $saw_from = 1;
1353                                 }
1354                                 $msgbuf .= $_;
1355                         }
1356                 }
1357                 $msgbuf =~ s/\s+$//s;
1358                 if ($Git::SVN::_add_author_from && defined($author)
1359                     && !$saw_from) {
1360                         $msgbuf .= "\n\nFrom: $author";
1361                 }
1362                 print $log_fh $msgbuf or croak $!;
1363                 command_close_pipe($msg_fh, $ctx);
1364         }
1365         close $log_fh or croak $!;
1366
1367         if ($_edit || ($type eq 'tree')) {
1368                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1369                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1370         }
1371         rename $commit_editmsg, $commit_msg or croak $!;
1372         {
1373                 require Encode;
1374                 # SVN requires messages to be UTF-8 when entering the repo
1375                 local $/;
1376                 open $log_fh, '<', $commit_msg or croak $!;
1377                 binmode $log_fh;
1378                 chomp($log_entry{log} = <$log_fh>);
1379
1380                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1381                 my $msg = $log_entry{log};
1382
1383                 eval { $msg = Encode::decode($enc, $msg, 1) };
1384                 if ($@) {
1385                         die "Could not decode as $enc:\n", $msg,
1386                             "\nPerhaps you need to set i18n.commitencoding\n";
1387                 }
1388
1389                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1390                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1391
1392                 $log_entry{log} = $msg;
1393
1394                 close $log_fh or croak $!;
1395         }
1396         unlink $commit_msg;
1397         \%log_entry;
1398 }
1399
1400 sub s_to_file {
1401         my ($str, $file, $mode) = @_;
1402         open my $fd,'>',$file or croak $!;
1403         print $fd $str,"\n" or croak $!;
1404         close $fd or croak $!;
1405         chmod ($mode &~ umask, $file) if (defined $mode);
1406 }
1407
1408 sub file_to_s {
1409         my $file = shift;
1410         open my $fd,'<',$file or croak "$!: file: $file\n";
1411         local $/;
1412         my $ret = <$fd>;
1413         close $fd or croak $!;
1414         $ret =~ s/\s*$//s;
1415         return $ret;
1416 }
1417
1418 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1419 sub load_authors {
1420         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1421         my $log = $cmd eq 'log';
1422         while (<$authors>) {
1423                 chomp;
1424                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1425                 my ($user, $name, $email) = ($1, $2, $3);
1426                 if ($log) {
1427                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1428                 } else {
1429                         $users{$user} = [$name, $email];
1430                 }
1431         }
1432         close $authors or croak $!;
1433 }
1434
1435 # convert GetOpt::Long specs for use by git-config
1436 sub read_git_config {
1437         my $opts = shift;
1438         my @config_only;
1439         foreach my $o (keys %$opts) {
1440                 # if we have mixedCase and a long option-only, then
1441                 # it's a config-only variable that we don't need for
1442                 # the command-line.
1443                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1444                 my $v = $opts->{$o};
1445                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1446                 $key =~ s/-//g;
1447                 my $arg = 'git config';
1448                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1449                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1450                 if (ref $v eq 'ARRAY') {
1451                         chomp(my @tmp = `$arg --get-all svn.$key`);
1452                         @$v = @tmp if @tmp;
1453                 } else {
1454                         chomp(my $tmp = `$arg --get svn.$key`);
1455                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1456                                 $$v = $tmp;
1457                         }
1458                 }
1459         }
1460         delete @$opts{@config_only} if @config_only;
1461 }
1462
1463 sub extract_metadata {
1464         my $id = shift or return (undef, undef, undef);
1465         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1466                                                         \s([a-f\d\-]+)$/ix);
1467         if (!defined $rev || !$uuid || !$url) {
1468                 # some of the original repositories I made had
1469                 # identifiers like this:
1470                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1471         }
1472         return ($url, $rev, $uuid);
1473 }
1474
1475 sub cmt_metadata {
1476         return extract_metadata((grep(/^git-svn-id: /,
1477                 command(qw/cat-file commit/, shift)))[-1]);
1478 }
1479
1480 sub cmt_sha2rev_batch {
1481         my %s2r;
1482         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1483         my $list = shift;
1484
1485         foreach my $sha (@{$list}) {
1486                 my $first = 1;
1487                 my $size = 0;
1488                 print $out $sha, "\n";
1489
1490                 while (my $line = <$in>) {
1491                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1492                                 last;
1493                         } elsif ($first &&
1494                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1495                                 $first = 0;
1496                                 $size = $1;
1497                                 next;
1498                         } elsif ($line =~ /^(git-svn-id: )/) {
1499                                 my (undef, $rev, undef) =
1500                                                       extract_metadata($line);
1501                                 $s2r{$sha} = $rev;
1502                         }
1503
1504                         $size -= length($line);
1505                         last if ($size == 0);
1506                 }
1507         }
1508
1509         command_close_bidi_pipe($pid, $in, $out, $ctx);
1510
1511         return \%s2r;
1512 }
1513
1514 sub working_head_info {
1515         my ($head, $refs) = @_;
1516         my @args = qw/log --no-color --no-decorate --first-parent
1517                       --pretty=medium/;
1518         my ($fh, $ctx) = command_output_pipe(@args, $head);
1519         my $hash;
1520         my %max;
1521         while (<$fh>) {
1522                 if ( m{^commit ($::sha1)$} ) {
1523                         unshift @$refs, $hash if $hash and $refs;
1524                         $hash = $1;
1525                         next;
1526                 }
1527                 next unless s{^\s*(git-svn-id:)}{$1};
1528                 my ($url, $rev, $uuid) = extract_metadata($_);
1529                 if (defined $url && defined $rev) {
1530                         next if $max{$url} and $max{$url} < $rev;
1531                         if (my $gs = Git::SVN->find_by_url($url)) {
1532                                 my $c = $gs->rev_map_get($rev, $uuid);
1533                                 if ($c && $c eq $hash) {
1534                                         close $fh; # break the pipe
1535                                         return ($url, $rev, $uuid, $gs);
1536                                 } else {
1537                                         $max{$url} ||= $gs->rev_map_max;
1538                                 }
1539                         }
1540                 }
1541         }
1542         command_close_pipe($fh, $ctx);
1543         (undef, undef, undef, undef);
1544 }
1545
1546 sub read_commit_parents {
1547         my ($parents, $c) = @_;
1548         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1549         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1550         @{$parents->{$c}} = split(/ /, $p);
1551 }
1552
1553 sub linearize_history {
1554         my ($gs, $refs) = @_;
1555         my %parents;
1556         foreach my $c (@$refs) {
1557                 read_commit_parents(\%parents, $c);
1558         }
1559
1560         my @linear_refs;
1561         my %skip = ();
1562         my $last_svn_commit = $gs->last_commit;
1563         foreach my $c (reverse @$refs) {
1564                 next if $c eq $last_svn_commit;
1565                 last if $skip{$c};
1566
1567                 unshift @linear_refs, $c;
1568                 $skip{$c} = 1;
1569
1570                 # we only want the first parent to diff against for linear
1571                 # history, we save the rest to inject when we finalize the
1572                 # svn commit
1573                 my $fp_a = verify_ref("$c~1");
1574                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1575                 if (!$fp_a || !$fp_b) {
1576                         die "Commit $c\n",
1577                             "has no parent commit, and therefore ",
1578                             "nothing to diff against.\n",
1579                             "You should be working from a repository ",
1580                             "originally created by git-svn\n";
1581                 }
1582                 if ($fp_a ne $fp_b) {
1583                         die "$c~1 = $fp_a, however parsing commit $c ",
1584                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1585                 }
1586
1587                 foreach my $p (@{$parents{$c}}) {
1588                         $skip{$p} = 1;
1589                 }
1590         }
1591         (\@linear_refs, \%parents);
1592 }
1593
1594 sub find_file_type_and_diff_status {
1595         my ($path) = @_;
1596         return ('dir', '') if $path eq '';
1597
1598         my $diff_output =
1599             command_oneline(qw(diff --cached --name-status --), $path) || "";
1600         my $diff_status = (split(' ', $diff_output))[0] || "";
1601
1602         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1603
1604         return (undef, undef) if !$diff_status && !$ls_tree;
1605
1606         if ($diff_status eq "A") {
1607                 return ("link", $diff_status) if -l $path;
1608                 return ("dir", $diff_status) if -d $path;
1609                 return ("file", $diff_status);
1610         }
1611
1612         my $mode = (split(' ', $ls_tree))[0] || "";
1613
1614         return ("link", $diff_status) if $mode eq "120000";
1615         return ("dir", $diff_status) if $mode eq "040000";
1616         return ("file", $diff_status);
1617 }
1618
1619 sub md5sum {
1620         my $arg = shift;
1621         my $ref = ref $arg;
1622         my $md5 = Digest::MD5->new();
1623         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1624                 $md5->addfile($arg) or croak $!;
1625         } elsif ($ref eq 'SCALAR') {
1626                 $md5->add($$arg) or croak $!;
1627         } elsif (!$ref) {
1628                 $md5->add($arg) or croak $!;
1629         } else {
1630                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1631         }
1632         return $md5->hexdigest();
1633 }
1634
1635 sub gc_directory {
1636         if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1637                 my $out_filename = $_ . ".gz";
1638                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1639                 binmode $in_fh;
1640                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1641                                 die "Unable to open $out_filename: $!\n";
1642
1643                 my $res;
1644                 while ($res = sysread($in_fh, my $str, 1024)) {
1645                         $gz->gzwrite($str) or
1646                                 die "Unable to write: ".$gz->gzerror()."!\n";
1647                 }
1648                 unlink $_ or die "unlink $File::Find::name: $!\n";
1649         } elsif (-f $_ && basename($_) eq "index") {
1650                 unlink $_ or die "unlink $_: $!\n";
1651         }
1652 }
1653
1654 package Git::SVN;
1655 use strict;
1656 use warnings;
1657 use Fcntl qw/:DEFAULT :seek/;
1658 use constant rev_map_fmt => 'NH40';
1659 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1660             $_repack $_repack_flags $_use_svm_props $_head
1661             $_use_svnsync_props $no_reuse_existing $_minimize_url
1662             $_use_log_author $_add_author_from $_localtime/;
1663 use Carp qw/croak/;
1664 use File::Path qw/mkpath/;
1665 use File::Copy qw/copy/;
1666 use IPC::Open3;
1667 use Memoize;  # core since 5.8.0, Jul 2002
1668 use Memoize::Storable;
1669
1670 my ($_gc_nr, $_gc_period);
1671
1672 # properties that we do not log:
1673 my %SKIP_PROP;
1674 BEGIN {
1675         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1676                                         svn:special svn:executable
1677                                         svn:entry:committed-rev
1678                                         svn:entry:last-author
1679                                         svn:entry:uuid
1680                                         svn:entry:committed-date/;
1681
1682         # some options are read globally, but can be overridden locally
1683         # per [svn-remote "..."] section.  Command-line options will *NOT*
1684         # override options set in an [svn-remote "..."] section
1685         no strict 'refs';
1686         for my $option (qw/follow_parent no_metadata use_svm_props
1687                            use_svnsync_props/) {
1688                 my $key = $option;
1689                 $key =~ tr/_//d;
1690                 my $prop = "-$option";
1691                 *$option = sub {
1692                         my ($self) = @_;
1693                         return $self->{$prop} if exists $self->{$prop};
1694                         my $k = "svn-remote.$self->{repo_id}.$key";
1695                         eval { command_oneline(qw/config --get/, $k) };
1696                         if ($@) {
1697                                 $self->{$prop} = ${"Git::SVN::_$option"};
1698                         } else {
1699                                 my $v = command_oneline(qw/config --bool/,$k);
1700                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1701                         }
1702                         return $self->{$prop};
1703                 }
1704         }
1705 }
1706
1707
1708 my (%LOCKFILES, %INDEX_FILES);
1709 END {
1710         unlink keys %LOCKFILES if %LOCKFILES;
1711         unlink keys %INDEX_FILES if %INDEX_FILES;
1712 }
1713
1714 sub resolve_local_globs {
1715         my ($url, $fetch, $glob_spec) = @_;
1716         return unless defined $glob_spec;
1717         my $ref = $glob_spec->{ref};
1718         my $path = $glob_spec->{path};
1719         foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
1720                 next unless m#^$ref->{regex}$#;
1721                 my $p = $1;
1722                 my $pathname = desanitize_refname($path->full_path($p));
1723                 my $refname = desanitize_refname($ref->full_path($p));
1724                 if (my $existing = $fetch->{$pathname}) {
1725                         if ($existing ne $refname) {
1726                                 die "Refspec conflict:\n",
1727                                     "existing: $existing\n",
1728                                     " globbed: $refname\n";
1729                         }
1730                         my $u = (::cmt_metadata("$refname"))[0];
1731                         $u =~ s!^\Q$url\E(/|$)!! or die
1732                           "$refname: '$url' not found in '$u'\n";
1733                         if ($pathname ne $u) {
1734                                 warn "W: Refspec glob conflict ",
1735                                      "(ref: $refname):\n",
1736                                      "expected path: $pathname\n",
1737                                      "    real path: $u\n",
1738                                      "Continuing ahead with $u\n";
1739                                 next;
1740                         }
1741                 } else {
1742                         $fetch->{$pathname} = $refname;
1743                 }
1744         }
1745 }
1746
1747 sub parse_revision_argument {
1748         my ($base, $head) = @_;
1749         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1750                 return ($base, $head);
1751         }
1752         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1753         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1754         return ($head, $head) if ($::_revision eq 'HEAD');
1755         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1756         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1757         die "revision argument: $::_revision not understood by git-svn\n";
1758 }
1759
1760 sub fetch_all {
1761         my ($repo_id, $remotes) = @_;
1762         if (ref $repo_id) {
1763                 my $gs = $repo_id;
1764                 $repo_id = undef;
1765                 $repo_id = $gs->{repo_id};
1766         }
1767         $remotes ||= read_all_remotes();
1768         my $remote = $remotes->{$repo_id} or
1769                      die "[svn-remote \"$repo_id\"] unknown\n";
1770         my $fetch = $remote->{fetch};
1771         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1772         my (@gs, @globs);
1773         my $ra = Git::SVN::Ra->new($url);
1774         my $uuid = $ra->get_uuid;
1775         my $head = $ra->get_latest_revnum;
1776
1777         # ignore errors, $head revision may not even exist anymore
1778         eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
1779         warn "W: $@\n" if $@;
1780
1781         my $base = defined $fetch ? $head : 0;
1782
1783         # read the max revs for wildcard expansion (branches/*, tags/*)
1784         foreach my $t (qw/branches tags/) {
1785                 defined $remote->{$t} or next;
1786                 push @globs, @{$remote->{$t}};
1787
1788                 my $max_rev = eval { tmp_config(qw/--int --get/,
1789                                          "svn-remote.$repo_id.${t}-maxRev") };
1790                 if (defined $max_rev && ($max_rev < $base)) {
1791                         $base = $max_rev;
1792                 } elsif (!defined $max_rev) {
1793                         $base = 0;
1794                 }
1795         }
1796
1797         if ($fetch) {
1798                 foreach my $p (sort keys %$fetch) {
1799                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1800                         my $lr = $gs->rev_map_max;
1801                         if (defined $lr) {
1802                                 $base = $lr if ($lr < $base);
1803                         }
1804                         push @gs, $gs;
1805                 }
1806         }
1807
1808         ($base, $head) = parse_revision_argument($base, $head);
1809         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1810 }
1811
1812 sub read_all_remotes {
1813         my $r = {};
1814         my $use_svm_props = eval { command_oneline(qw/config --bool
1815             svn.useSvmProps/) };
1816         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1817         my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
1818         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1819                 if (m!^(.+)\.fetch=$svn_refspec$!) {
1820                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1821                         die("svn-remote.$remote: remote ref '$remote_ref' "
1822                             . "must start with 'refs/'\n")
1823                                 unless $remote_ref =~ m{^refs/};
1824                         $local_ref = uri_decode($local_ref);
1825                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1826                         $r->{$remote}->{svm} = {} if $use_svm_props;
1827                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1828                         $r->{$1}->{svm} = {};
1829                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1830                         $r->{$1}->{url} = $2;
1831                 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
1832                         my ($remote, $t, $local_ref, $remote_ref) =
1833                                                              ($1, $2, $3, $4);
1834                         die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
1835                             . "must start with 'refs/'\n")
1836                                 unless $remote_ref =~ m{^refs/};
1837                         $local_ref = uri_decode($local_ref);
1838                         my $rs = {
1839                             t => $t,
1840                             remote => $remote,
1841                             path => Git::SVN::GlobSpec->new($local_ref, 1),
1842                             ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
1843                         if (length($rs->{ref}->{right}) != 0) {
1844                                 die "The '*' glob character must be the last ",
1845                                     "character of '$remote_ref'\n";
1846                         }
1847                         push @{ $r->{$remote}->{$t} }, $rs;
1848                 }
1849         }
1850
1851         map {
1852                 if (defined $r->{$_}->{svm}) {
1853                         my $svm;
1854                         eval {
1855                                 my $section = "svn-remote.$_";
1856                                 $svm = {
1857                                         source => tmp_config('--get',
1858                                             "$section.svm-source"),
1859                                         replace => tmp_config('--get',
1860                                             "$section.svm-replace"),
1861                                 }
1862                         };
1863                         $r->{$_}->{svm} = $svm;
1864                 }
1865         } keys %$r;
1866
1867         $r;
1868 }
1869
1870 sub init_vars {
1871         $_gc_nr = $_gc_period = 1000;
1872         if (defined $_repack || defined $_repack_flags) {
1873                warn "Repack options are obsolete; they have no effect.\n";
1874         }
1875 }
1876
1877 sub verify_remotes_sanity {
1878         return unless -d $ENV{GIT_DIR};
1879         my %seen;
1880         foreach (command(qw/config -l/)) {
1881                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1882                         if ($seen{$1}) {
1883                                 die "Remote ref refs/remote/$1 is tracked by",
1884                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1885                                     "Please resolve this ambiguity in ",
1886                                     "your git configuration file before ",
1887                                     "continuing\n";
1888                         }
1889                         $seen{$1} = $_;
1890                 }
1891         }
1892 }
1893
1894 sub find_existing_remote {
1895         my ($url, $remotes) = @_;
1896         return undef if $no_reuse_existing;
1897         my $existing;
1898         foreach my $repo_id (keys %$remotes) {
1899                 my $u = $remotes->{$repo_id}->{url} or next;
1900                 next if $u ne $url;
1901                 $existing = $repo_id;
1902                 last;
1903         }
1904         $existing;
1905 }
1906
1907 sub init_remote_config {
1908         my ($self, $url, $no_write) = @_;
1909         $url =~ s!/+$!!; # strip trailing slash
1910         my $r = read_all_remotes();
1911         my $existing = find_existing_remote($url, $r);
1912         if ($existing) {
1913                 unless ($no_write) {
1914                         print STDERR "Using existing ",
1915                                      "[svn-remote \"$existing\"]\n";
1916                 }
1917                 $self->{repo_id} = $existing;
1918         } elsif ($_minimize_url) {
1919                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1920                 $existing = find_existing_remote($min_url, $r);
1921                 if ($existing) {
1922                         unless ($no_write) {
1923                                 print STDERR "Using existing ",
1924                                              "[svn-remote \"$existing\"]\n";
1925                         }
1926                         $self->{repo_id} = $existing;
1927                 }
1928                 if ($min_url ne $url) {
1929                         unless ($no_write) {
1930                                 print STDERR "Using higher level of URL: ",
1931                                              "$url => $min_url\n";
1932                         }
1933                         my $old_path = $self->{path};
1934                         $self->{path} = $url;
1935                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1936                         if (length $old_path) {
1937                                 $self->{path} .= "/$old_path";
1938                         }
1939                         $url = $min_url;
1940                 }
1941         }
1942         my $orig_url;
1943         if (!$existing) {
1944                 # verify that we aren't overwriting anything:
1945                 $orig_url = eval {
1946                         command_oneline('config', '--get',
1947                                         "svn-remote.$self->{repo_id}.url")
1948                 };
1949                 if ($orig_url && ($orig_url ne $url)) {
1950                         die "svn-remote.$self->{repo_id}.url already set: ",
1951                             "$orig_url\nwanted to set to: $url\n";
1952                 }
1953         }
1954         my ($xrepo_id, $xpath) = find_ref($self->refname);
1955         if (!$no_write && defined $xpath) {
1956                 die "svn-remote.$xrepo_id.fetch already set to track ",
1957                     "$xpath:", $self->refname, "\n";
1958         }
1959         unless ($no_write) {
1960                 command_noisy('config',
1961                               "svn-remote.$self->{repo_id}.url", $url);
1962                 $self->{path} =~ s{^/}{};
1963                 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1964                 command_noisy('config', '--add',
1965                               "svn-remote.$self->{repo_id}.fetch",
1966                               "$self->{path}:".$self->refname);
1967         }
1968         $self->{url} = $url;
1969 }
1970
1971 sub find_by_url { # repos_root and, path are optional
1972         my ($class, $full_url, $repos_root, $path) = @_;
1973
1974         return undef unless defined $full_url;
1975         remove_username($full_url);
1976         remove_username($repos_root) if defined $repos_root;
1977         my $remotes = read_all_remotes();
1978         if (defined $full_url && defined $repos_root && !defined $path) {
1979                 $path = $full_url;
1980                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1981         }
1982         foreach my $repo_id (keys %$remotes) {
1983                 my $u = $remotes->{$repo_id}->{url} or next;
1984                 remove_username($u);
1985                 next if defined $repos_root && $repos_root ne $u;
1986
1987                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1988                 foreach my $t (qw/branches tags/) {
1989                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1990                                 resolve_local_globs($u, $fetch, $globspec);
1991                         }
1992                 }
1993                 my $p = $path;
1994                 my $rwr = rewrite_root({repo_id => $repo_id});
1995                 my $svm = $remotes->{$repo_id}->{svm}
1996                         if defined $remotes->{$repo_id}->{svm};
1997                 unless (defined $p) {
1998                         $p = $full_url;
1999                         my $z = $u;
2000                         my $prefix = '';
2001                         if ($rwr) {
2002                                 $z = $rwr;
2003                                 remove_username($z);
2004                         } elsif (defined $svm) {
2005                                 $z = $svm->{source};
2006                                 $prefix = $svm->{replace};
2007                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
2008                                 $prefix =~ s#/$##;
2009                         }
2010                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
2011                 }
2012                 foreach my $f (keys %$fetch) {
2013                         next if $f ne $p;
2014                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
2015                 }
2016         }
2017         undef;
2018 }
2019
2020 sub init {
2021         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
2022         my $self = _new($class, $repo_id, $ref_id, $path);
2023         if (defined $url) {
2024                 $self->init_remote_config($url, $no_write);
2025         }
2026         $self;
2027 }
2028
2029 sub find_ref {
2030         my ($ref_id) = @_;
2031         foreach (command(qw/config -l/)) {
2032                 next unless m!^svn-remote\.(.+)\.fetch=
2033                               \s*(.*?)\s*:\s*(.+?)\s*$!x;
2034                 my ($repo_id, $path, $ref) = ($1, $2, $3);
2035                 if ($ref eq $ref_id) {
2036                         $path = '' if ($path =~ m#^\./?#);
2037                         return ($repo_id, $path);
2038                 }
2039         }
2040         (undef, undef, undef);
2041 }
2042
2043 sub new {
2044         my ($class, $ref_id, $repo_id, $path) = @_;
2045         if (defined $ref_id && !defined $repo_id && !defined $path) {
2046                 ($repo_id, $path) = find_ref($ref_id);
2047                 if (!defined $repo_id) {
2048                         die "Could not find a \"svn-remote.*.fetch\" key ",
2049                             "in the repository configuration matching: ",
2050                             "$ref_id\n";
2051                 }
2052         }
2053         my $self = _new($class, $repo_id, $ref_id, $path);
2054         if (!defined $self->{path} || !length $self->{path}) {
2055                 my $fetch = command_oneline('config', '--get',
2056                                             "svn-remote.$repo_id.fetch",
2057                                             ":$ref_id\$") or
2058                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
2059                          "\":$ref_id\$\" in config\n";
2060                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
2061         }
2062         $self->{path} =~ s{/+}{/}g;
2063         $self->{path} =~ s{\A/}{};
2064         $self->{path} =~ s{/\z}{};
2065         $self->{url} = command_oneline('config', '--get',
2066                                        "svn-remote.$repo_id.url") or
2067                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
2068         $self->rebuild;
2069         $self;
2070 }
2071
2072 sub refname {
2073         my ($refname) = $_[0]->{ref_id} ;
2074
2075         # It cannot end with a slash /, we'll throw up on this because
2076         # SVN can't have directories with a slash in their name, either:
2077         if ($refname =~ m{/$}) {
2078                 die "ref: '$refname' ends with a trailing slash, this is ",
2079                     "not permitted by git nor Subversion\n";
2080         }
2081
2082         # It cannot have ASCII control character space, tilde ~, caret ^,
2083         # colon :, question-mark ?, asterisk *, space, or open bracket [
2084         # anywhere.
2085         #
2086         # Additionally, % must be escaped because it is used for escaping
2087         # and we want our escaped refname to be reversible
2088         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2089
2090         # no slash-separated component can begin with a dot .
2091         # /.* becomes /%2E*
2092         $refname =~ s{/\.}{/%2E}g;
2093
2094         # It cannot have two consecutive dots .. anywhere
2095         # .. becomes %2E%2E
2096         $refname =~ s{\.\.}{%2E%2E}g;
2097
2098         # trailing dots and .lock are not allowed
2099         # .$ becomes %2E and .lock becomes %2Elock
2100         $refname =~ s{\.(?=$|lock$)}{%2E};
2101
2102         # the sequence @{ is used to access the reflog
2103         # @{ becomes %40{
2104         $refname =~ s{\@\{}{%40\{}g;
2105
2106         return $refname;
2107 }
2108
2109 sub desanitize_refname {
2110         my ($refname) = @_;
2111         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2112         return $refname;
2113 }
2114
2115 sub svm_uuid {
2116         my ($self) = @_;
2117         return $self->{svm}->{uuid} if $self->svm;
2118         $self->ra;
2119         unless ($self->{svm}) {
2120                 die "SVM UUID not cached, and reading remotely failed\n";
2121         }
2122         $self->{svm}->{uuid};
2123 }
2124
2125 sub svm {
2126         my ($self) = @_;
2127         return $self->{svm} if $self->{svm};
2128         my $svm;
2129         # see if we have it in our config, first:
2130         eval {
2131                 my $section = "svn-remote.$self->{repo_id}";
2132                 $svm = {
2133                   source => tmp_config('--get', "$section.svm-source"),
2134                   uuid => tmp_config('--get', "$section.svm-uuid"),
2135                   replace => tmp_config('--get', "$section.svm-replace"),
2136                 }
2137         };
2138         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2139                 $self->{svm} = $svm;
2140         }
2141         $self->{svm};
2142 }
2143
2144 sub _set_svm_vars {
2145         my ($self, $ra) = @_;
2146         return $ra if $self->svm;
2147
2148         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2149                     "(svm:source, svm:uuid) ",
2150                     "from the following URLs:\n" );
2151         sub read_svm_props {
2152                 my ($self, $ra, $path, $r) = @_;
2153                 my $props = ($ra->get_dir($path, $r))[2];
2154                 my $src = $props->{'svm:source'};
2155                 my $uuid = $props->{'svm:uuid'};
2156                 return undef if (!$src || !$uuid);
2157
2158                 chomp($src, $uuid);
2159
2160                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2161                     or die "doesn't look right - svm:uuid is '$uuid'\n";
2162
2163                 # the '!' is used to mark the repos_root!/relative/path
2164                 $src =~ s{/?!/?}{/};
2165                 $src =~ s{/+$}{}; # no trailing slashes please
2166                 # username is of no interest
2167                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2168
2169                 my $replace = $ra->{url};
2170                 $replace .= "/$path" if length $path;
2171
2172                 my $section = "svn-remote.$self->{repo_id}";
2173                 tmp_config("$section.svm-source", $src);
2174                 tmp_config("$section.svm-replace", $replace);
2175                 tmp_config("$section.svm-uuid", $uuid);
2176                 $self->{svm} = {
2177                         source => $src,
2178                         uuid => $uuid,
2179                         replace => $replace
2180                 };
2181         }
2182
2183         my $r = $ra->get_latest_revnum;
2184         my $path = $self->{path};
2185         my %tried;
2186         while (length $path) {
2187                 unless ($tried{"$self->{url}/$path"}) {
2188                         return $ra if $self->read_svm_props($ra, $path, $r);
2189                         $tried{"$self->{url}/$path"} = 1;
2190                 }
2191                 $path =~ s#/?[^/]+$##;
2192         }
2193         die "Path: '$path' should be ''\n" if $path ne '';
2194         return $ra if $self->read_svm_props($ra, $path, $r);
2195         $tried{"$self->{url}/$path"} = 1;
2196
2197         if ($ra->{repos_root} eq $self->{url}) {
2198                 die @err, (map { "  $_\n" } keys %tried), "\n";
2199         }
2200
2201         # nope, make sure we're connected to the repository root:
2202         my $ok;
2203         my @tried_b;
2204         $path = $ra->{svn_path};
2205         $ra = Git::SVN::Ra->new($ra->{repos_root});
2206         while (length $path) {
2207                 unless ($tried{"$ra->{url}/$path"}) {
2208                         $ok = $self->read_svm_props($ra, $path, $r);
2209                         last if $ok;
2210                         $tried{"$ra->{url}/$path"} = 1;
2211                 }
2212                 $path =~ s#/?[^/]+$##;
2213         }
2214         die "Path: '$path' should be ''\n" if $path ne '';
2215         $ok ||= $self->read_svm_props($ra, $path, $r);
2216         $tried{"$ra->{url}/$path"} = 1;
2217         if (!$ok) {
2218                 die @err, (map { "  $_\n" } keys %tried), "\n";
2219         }
2220         Git::SVN::Ra->new($self->{url});
2221 }
2222
2223 sub svnsync {
2224         my ($self) = @_;
2225         return $self->{svnsync} if $self->{svnsync};
2226
2227         if ($self->no_metadata) {
2228                 die "Can't have both 'noMetadata' and ",
2229                     "'useSvnsyncProps' options set!\n";
2230         }
2231         if ($self->rewrite_root) {
2232                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2233                     "options set!\n";
2234         }
2235         if ($self->rewrite_uuid) {
2236                 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
2237                     "options set!\n";
2238         }
2239
2240         my $svnsync;
2241         # see if we have it in our config, first:
2242         eval {
2243                 my $section = "svn-remote.$self->{repo_id}";
2244
2245                 my $url = tmp_config('--get', "$section.svnsync-url");
2246                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2247                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2248
2249                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2250                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2251                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2252
2253                 $svnsync = { url => $url, uuid => $uuid }
2254         };
2255         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2256                 return $self->{svnsync} = $svnsync;
2257         }
2258
2259         my $err = "useSvnsyncProps set, but failed to read " .
2260                   "svnsync property: svn:sync-from-";
2261         my $rp = $self->ra->rev_proplist(0);
2262
2263         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2264         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2265                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2266
2267         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2268         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2269                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2270
2271         my $section = "svn-remote.$self->{repo_id}";
2272         tmp_config('--add', "$section.svnsync-uuid", $uuid);
2273         tmp_config('--add', "$section.svnsync-url", $url);
2274         return $self->{svnsync} = { url => $url, uuid => $uuid };
2275 }
2276
2277 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2278 # remote lookup (useful for 'git svn log').
2279 sub ra_uuid {
2280         my ($self) = @_;
2281         unless ($self->{ra_uuid}) {
2282                 my $key = "svn-remote.$self->{repo_id}.uuid";
2283                 my $uuid = eval { tmp_config('--get', $key) };
2284                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2285                         $self->{ra_uuid} = $uuid;
2286                 } else {
2287                         die "ra_uuid called without URL\n" unless $self->{url};
2288                         $self->{ra_uuid} = $self->ra->get_uuid;
2289                         tmp_config('--add', $key, $self->{ra_uuid});
2290                 }
2291         }
2292         $self->{ra_uuid};
2293 }
2294
2295 sub _set_repos_root {
2296         my ($self, $repos_root) = @_;
2297         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2298         $repos_root ||= $self->ra->{repos_root};
2299         tmp_config($k, $repos_root);
2300         $repos_root;
2301 }
2302
2303 sub repos_root {
2304         my ($self) = @_;
2305         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2306         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2307 }
2308
2309 sub ra {
2310         my ($self) = shift;
2311         my $ra = Git::SVN::Ra->new($self->{url});
2312         $self->_set_repos_root($ra->{repos_root});
2313         if ($self->use_svm_props && !$self->{svm}) {
2314                 if ($self->no_metadata) {
2315                         die "Can't have both 'noMetadata' and ",
2316                             "'useSvmProps' options set!\n";
2317                 } elsif ($self->use_svnsync_props) {
2318                         die "Can't have both 'useSvnsyncProps' and ",
2319                             "'useSvmProps' options set!\n";
2320                 }
2321                 $ra = $self->_set_svm_vars($ra);
2322                 $self->{-want_revprops} = 1;
2323         }
2324         $ra;
2325 }
2326
2327 # prop_walk(PATH, REV, SUB)
2328 # -------------------------
2329 # Recursively traverse PATH at revision REV and invoke SUB for each
2330 # directory that contains a SVN property.  SUB will be invoked as
2331 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2332 # Git::SVN, `path' the path to the directory where the properties
2333 # `props' were found.  The `path' will be relative to point of checkout,
2334 # that is, if url://repo/trunk is the current Git branch, and that
2335 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2336 # as `path' (note the trailing `/').
2337 sub prop_walk {
2338         my ($self, $path, $rev, $sub) = @_;
2339
2340         $path =~ s#^/##;
2341         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2342         $path =~ s#^/*#/#g;
2343         my $p = $path;
2344         # Strip the irrelevant part of the path.
2345         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2346         # Ensure the path is terminated by a `/'.
2347         $p =~ s#/*$#/#;
2348
2349         # The properties contain all the internal SVN stuff nobody
2350         # (usually) cares about.
2351         my $interesting_props = 0;
2352         foreach (keys %{$props}) {
2353                 # If it doesn't start with `svn:', it must be a
2354                 # user-defined property.
2355                 ++$interesting_props and next if $_ !~ /^svn:/;
2356                 # FIXME: Fragile, if SVN adds new public properties,
2357                 # this needs to be updated.
2358                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2359                                                  |eol-style|mime-type
2360                                                  |externals|needs-lock)$/x;
2361         }
2362         &$sub($self, $p, $props) if $interesting_props;
2363
2364         foreach (sort keys %$dirent) {
2365                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2366                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2367         }
2368 }
2369
2370 sub last_rev { ($_[0]->last_rev_commit)[0] }
2371 sub last_commit { ($_[0]->last_rev_commit)[1] }
2372
2373 # returns the newest SVN revision number and newest commit SHA1
2374 sub last_rev_commit {
2375         my ($self) = @_;
2376         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2377                 return ($self->{last_rev}, $self->{last_commit});
2378         }
2379         my $c = ::verify_ref($self->refname.'^0');
2380         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2381                 my $rev = (::cmt_metadata($c))[1];
2382                 if (defined $rev) {
2383                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2384                         return ($rev, $c);
2385                 }
2386         }
2387         my $map_path = $self->map_path;
2388         unless (-e $map_path) {
2389                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2390                 return (undef, undef);
2391         }
2392         my ($rev, $commit) = $self->rev_map_max(1);
2393         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2394         return ($rev, $commit);
2395 }
2396
2397 sub get_fetch_range {
2398         my ($self, $min, $max) = @_;
2399         $max ||= $self->ra->get_latest_revnum;
2400         $min ||= $self->rev_map_max;
2401         (++$min, $max);
2402 }
2403
2404 sub tmp_config {
2405         my (@args) = @_;
2406         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2407         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2408         if (! -f $config && -f $old_def_config) {
2409                 rename $old_def_config, $config or
2410                        die "Failed rename $old_def_config => $config: $!\n";
2411         }
2412         my $old_config = $ENV{GIT_CONFIG};
2413         $ENV{GIT_CONFIG} = $config;
2414         $@ = undef;
2415         my @ret = eval {
2416                 unless (-f $config) {
2417                         mkfile($config);
2418                         open my $fh, '>', $config or
2419                             die "Can't open $config: $!\n";
2420                         print $fh "; This file is used internally by ",
2421                                   "git-svn\n" or die
2422                                   "Couldn't write to $config: $!\n";
2423                         print $fh "; You should not have to edit it\n" or
2424                               die "Couldn't write to $config: $!\n";
2425                         close $fh or die "Couldn't close $config: $!\n";
2426                 }
2427                 command('config', @args);
2428         };
2429         my $err = $@;
2430         if (defined $old_config) {
2431                 $ENV{GIT_CONFIG} = $old_config;
2432         } else {
2433                 delete $ENV{GIT_CONFIG};
2434         }
2435         die $err if $err;
2436         wantarray ? @ret : $ret[0];
2437 }
2438
2439 sub tmp_index_do {
2440         my ($self, $sub) = @_;
2441         my $old_index = $ENV{GIT_INDEX_FILE};
2442         $ENV{GIT_INDEX_FILE} = $self->{index};
2443         $@ = undef;
2444         my @ret = eval {
2445                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2446                 mkpath([$dir]) unless -d $dir;
2447                 &$sub;
2448         };
2449         my $err = $@;
2450         if (defined $old_index) {
2451                 $ENV{GIT_INDEX_FILE} = $old_index;
2452         } else {
2453                 delete $ENV{GIT_INDEX_FILE};
2454         }
2455         die $err if $err;
2456         wantarray ? @ret : $ret[0];
2457 }
2458
2459 sub assert_index_clean {
2460         my ($self, $treeish) = @_;
2461
2462         $self->tmp_index_do(sub {
2463                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2464                 my $x = command_oneline('write-tree');
2465                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2466                            /^tree ($::sha1)/mo);
2467                 return if $y eq $x;
2468
2469                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2470                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2471                 command_noisy('read-tree', $treeish);
2472                 $x = command_oneline('write-tree');
2473                 if ($y ne $x) {
2474                         ::fatal "trees ($treeish) $y != $x\n",
2475                                 "Something is seriously wrong...";
2476                 }
2477         });
2478 }
2479
2480 sub get_commit_parents {
2481         my ($self, $log_entry) = @_;
2482         my (%seen, @ret, @tmp);
2483         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2484         if (my $ip = $self->{inject_parents}) {
2485                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2486                         push @tmp, $commit;
2487                 }
2488         }
2489         if (my $cur = ::verify_ref($self->refname.'^0')) {
2490                 push @tmp, $cur;
2491         }
2492         if (my $ipd = $self->{inject_parents_dcommit}) {
2493                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2494                         push @tmp, @$commit;
2495                 }
2496         }
2497         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2498         while (my $p = shift @tmp) {
2499                 next if $seen{$p};
2500                 $seen{$p} = 1;
2501                 push @ret, $p;
2502         }
2503         @ret;
2504 }
2505
2506 sub rewrite_root {
2507         my ($self) = @_;
2508         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2509         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2510         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2511         if ($rwr) {
2512                 $rwr =~ s#/+$##;
2513                 if ($rwr !~ m#^[a-z\+]+://#) {
2514                         die "$rwr is not a valid URL (key: $k)\n";
2515                 }
2516         }
2517         $self->{-rewrite_root} = $rwr;
2518 }
2519
2520 sub rewrite_uuid {
2521         my ($self) = @_;
2522         return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
2523         my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
2524         my $rwid = eval { command_oneline(qw/config --get/, $k) };
2525         if ($rwid) {
2526                 $rwid =~ s#/+$##;
2527                 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
2528                         die "$rwid is not a valid UUID (key: $k)\n";
2529                 }
2530         }
2531         $self->{-rewrite_uuid} = $rwid;
2532 }
2533
2534 sub metadata_url {
2535         my ($self) = @_;
2536         ($self->rewrite_root || $self->{url}) .
2537            (length $self->{path} ? '/' . $self->{path} : '');
2538 }
2539
2540 sub full_url {
2541         my ($self) = @_;
2542         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2543 }
2544
2545
2546 sub set_commit_header_env {
2547         my ($log_entry) = @_;
2548         my %env;
2549         foreach my $ned (qw/NAME EMAIL DATE/) {
2550                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2551                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2552                 }
2553         }
2554
2555         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2556         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2557         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2558
2559         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2560                                                 ? $log_entry->{commit_name}
2561                                                 : $log_entry->{name};
2562         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2563                                                 ? $log_entry->{commit_email}
2564                                                 : $log_entry->{email};
2565         \%env;
2566 }
2567
2568 sub restore_commit_header_env {
2569         my ($env) = @_;
2570         foreach my $ned (qw/NAME EMAIL DATE/) {
2571                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2572                         my $k = "GIT_${ac}_${ned}";
2573                         if (defined $env->{$k}) {
2574                                 $ENV{$k} = $env->{$k};
2575                         } else {
2576                                 delete $ENV{$k};
2577                         }
2578                 }
2579         }
2580 }
2581
2582 sub gc {
2583         command_noisy('gc', '--auto');
2584 };
2585
2586 sub do_git_commit {
2587         my ($self, $log_entry) = @_;
2588         my $lr = $self->last_rev;
2589         if (defined $lr && $lr >= $log_entry->{revision}) {
2590                 die "Last fetched revision of ", $self->refname,
2591                     " was r$lr, but we are about to fetch: ",
2592                     "r$log_entry->{revision}!\n";
2593         }
2594         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2595                 croak "$log_entry->{revision} = $c already exists! ",
2596                       "Why are we refetching it?\n";
2597         }
2598         my $old_env = set_commit_header_env($log_entry);
2599         my $tree = $log_entry->{tree};
2600         if (!defined $tree) {
2601                 $tree = $self->tmp_index_do(sub {
2602                                             command_oneline('write-tree') });
2603         }
2604         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2605
2606         my @exec = ('git', 'commit-tree', $tree);
2607         foreach ($self->get_commit_parents($log_entry)) {
2608                 push @exec, '-p', $_;
2609         }
2610         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2611                                                                    or croak $!;
2612         binmode $msg_fh;
2613
2614         # we always get UTF-8 from SVN, but we may want our commits in
2615         # a different encoding.
2616         if (my $enc = Git::config('i18n.commitencoding')) {
2617                 require Encode;
2618                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2619         }
2620         print $msg_fh $log_entry->{log} or croak $!;
2621         restore_commit_header_env($old_env);
2622         unless ($self->no_metadata) {
2623                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2624                               or croak $!;
2625         }
2626         $msg_fh->flush == 0 or croak $!;
2627         close $msg_fh or croak $!;
2628         chomp(my $commit = do { local $/; <$out_fh> });
2629         close $out_fh or croak $!;
2630         waitpid $pid, 0;
2631         croak $? if $?;
2632         if ($commit !~ /^$::sha1$/o) {
2633                 die "Failed to commit, invalid sha1: $commit\n";
2634         }
2635
2636         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2637
2638         $self->{last_rev} = $log_entry->{revision};
2639         $self->{last_commit} = $commit;
2640         print "r$log_entry->{revision}" unless $::_q > 1;
2641         if (defined $log_entry->{svm_revision}) {
2642                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2643                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2644                                    0, $self->svm_uuid);
2645         }
2646         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2647         if (--$_gc_nr == 0) {
2648                 $_gc_nr = $_gc_period;
2649                 gc();
2650         }
2651         return $commit;
2652 }
2653
2654 sub match_paths {
2655         my ($self, $paths, $r) = @_;
2656         return 1 if $self->{path} eq '';
2657         if (my $path = $paths->{"/$self->{path}"}) {
2658                 return ($path->{action} eq 'D') ? 0 : 1;
2659         }
2660         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2661         if (grep /$self->{path_regex}/, keys %$paths) {
2662                 return 1;
2663         }
2664         my $c = '';
2665         foreach (split m#/#, $self->{path}) {
2666                 $c .= "/$_";
2667                 next unless ($paths->{$c} &&
2668                              ($paths->{$c}->{action} =~ /^[AR]$/));
2669                 if ($self->ra->check_path($self->{path}, $r) ==
2670                     $SVN::Node::dir) {
2671                         return 1;
2672                 }
2673         }
2674         return 0;
2675 }
2676
2677 sub find_parent_branch {
2678         my ($self, $paths, $rev) = @_;
2679         return undef unless $self->follow_parent;
2680         unless (defined $paths) {
2681                 my $err_handler = $SVN::Error::handler;
2682                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2683                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2684                                    sub { $paths = $_[0] });
2685                 $SVN::Error::handler = $err_handler;
2686         }
2687         return undef unless defined $paths;
2688
2689         # look for a parent from another branch:
2690         my @b_path_components = split m#/#, $self->{path};
2691         my @a_path_components;
2692         my $i;
2693         while (@b_path_components) {
2694                 $i = $paths->{'/'.join('/', @b_path_components)};
2695                 last if $i && defined $i->{copyfrom_path};
2696                 unshift(@a_path_components, pop(@b_path_components));
2697         }
2698         return undef unless defined $i && defined $i->{copyfrom_path};
2699         my $branch_from = $i->{copyfrom_path};
2700         if (@a_path_components) {
2701                 print STDERR "branch_from: $branch_from => ";
2702                 $branch_from .= '/'.join('/', @a_path_components);
2703                 print STDERR $branch_from, "\n";
2704         }
2705         my $r = $i->{copyfrom_rev};
2706         my $repos_root = $self->ra->{repos_root};
2707         my $url = $self->ra->{url};
2708         my $new_url = $url . $branch_from;
2709         print STDERR  "Found possible branch point: ",
2710                       "$new_url => ", $self->full_url, ", $r\n"
2711                       unless $::_q > 1;
2712         $branch_from =~ s#^/##;
2713         my $gs = $self->other_gs($new_url, $url,
2714                                  $branch_from, $r, $self->{ref_id});
2715         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2716         {
2717                 my ($base, $head);
2718                 if (!defined $r0 || !defined $parent) {
2719                         ($base, $head) = parse_revision_argument(0, $r);
2720                 } else {
2721                         if ($r0 < $r) {
2722                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2723                                         0, 1, sub { $base = $_[1] - 1 });
2724                         }
2725                 }
2726                 if (defined $base && $base <= $r) {
2727                         $gs->fetch($base, $r);
2728                 }
2729                 ($r0, $parent) = $gs->find_rev_before($r, 1);
2730         }
2731         if (defined $r0 && defined $parent) {
2732                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
2733                              unless $::_q > 1;
2734                 my $ed;
2735                 if ($self->ra->can_do_switch) {
2736                         $self->assert_index_clean($parent);
2737                         print STDERR "Following parent with do_switch\n"
2738                                      unless $::_q > 1;
2739                         # do_switch works with svn/trunk >= r22312, but that
2740                         # is not included with SVN 1.4.3 (the latest version
2741                         # at the moment), so we can't rely on it
2742                         $self->{last_rev} = $r0;
2743                         $self->{last_commit} = $parent;
2744                         $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2745                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2746                                               $self->full_url, $ed)
2747                           or die "SVN connection failed somewhere...\n";
2748                 } elsif ($self->ra->trees_match($new_url, $r0,
2749                                                 $self->full_url, $rev)) {
2750                         print STDERR "Trees match:\n",
2751                                      "  $new_url\@$r0\n",
2752                                      "  ${\$self->full_url}\@$rev\n",
2753                                      "Following parent with no changes\n"
2754                                      unless $::_q > 1;
2755                         $self->tmp_index_do(sub {
2756                             command_noisy('read-tree', $parent);
2757                         });
2758                         $self->{last_commit} = $parent;
2759                 } else {
2760                         print STDERR "Following parent with do_update\n"
2761                                      unless $::_q > 1;
2762                         $ed = SVN::Git::Fetcher->new($self);
2763                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2764                           or die "SVN connection failed somewhere...\n";
2765                 }
2766                 print STDERR "Successfully followed parent\n" unless $::_q > 1;
2767                 return $self->make_log_entry($rev, [$parent], $ed);
2768         }
2769         return undef;
2770 }
2771
2772 sub do_fetch {
2773         my ($self, $paths, $rev) = @_;
2774         my $ed;
2775         my ($last_rev, @parents);
2776         if (my $lc = $self->last_commit) {
2777                 # we can have a branch that was deleted, then re-added
2778                 # under the same name but copied from another path, in
2779                 # which case we'll have multiple parents (we don't
2780                 # want to break the original ref, nor lose copypath info):
2781                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2782                         push @{$log_entry->{parents}}, $lc;
2783                         return $log_entry;
2784                 }
2785                 $ed = SVN::Git::Fetcher->new($self);
2786                 $last_rev = $self->{last_rev};
2787                 $ed->{c} = $lc;
2788                 @parents = ($lc);
2789         } else {
2790                 $last_rev = $rev;
2791                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2792                         return $log_entry;
2793                 }
2794                 $ed = SVN::Git::Fetcher->new($self);
2795         }
2796         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2797                 die "SVN connection failed somewhere...\n";
2798         }
2799         $self->make_log_entry($rev, \@parents, $ed);
2800 }
2801
2802 sub mkemptydirs {
2803         my ($self, $r) = @_;
2804
2805         sub scan {
2806                 my ($r, $empty_dirs, $line) = @_;
2807                 if (defined $r && $line =~ /^r(\d+)$/) {
2808                         return 0 if $1 > $r;
2809                 } elsif ($line =~ /^  \+empty_dir: (.+)$/) {
2810                         $empty_dirs->{$1} = 1;
2811                 } elsif ($line =~ /^  \-empty_dir: (.+)$/) {
2812                         my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
2813                         delete @$empty_dirs{@d};
2814                 }
2815                 1; # continue
2816         };
2817
2818         my %empty_dirs = ();
2819         my $gz_file = "$self->{dir}/unhandled.log.gz";
2820         if (-f $gz_file) {
2821                 if (!$can_compress) {
2822                         warn "Compress::Zlib could not be found; ",
2823                              "empty directories in $gz_file will not be read\n";
2824                 } else {
2825                         my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
2826                                 die "Unable to open $gz_file: $!\n";
2827                         my $line;
2828                         while ($gz->gzreadline($line) > 0) {
2829                                 scan($r, \%empty_dirs, $line) or last;
2830                         }
2831                         $gz->gzclose;
2832                 }
2833         }
2834
2835         if (open my $fh, '<', "$self->{dir}/unhandled.log") {
2836                 binmode $fh or croak "binmode: $!";
2837                 while (<$fh>) {
2838                         scan($r, \%empty_dirs, $_) or last;
2839                 }
2840                 close $fh;
2841         }
2842
2843         my $strip = qr/\A\Q$self->{path}\E(?:\/|$)/;
2844         foreach my $d (sort keys %empty_dirs) {
2845                 $d = uri_decode($d);
2846                 $d =~ s/$strip//;
2847                 next unless length($d);
2848                 next if -d $d;
2849                 if (-e $d) {
2850                         warn "$d exists but is not a directory\n";
2851                 } else {
2852                         print "creating empty directory: $d\n";
2853                         mkpath([$d]);
2854                 }
2855         }
2856 }
2857
2858 sub get_untracked {
2859         my ($self, $ed) = @_;
2860         my @out;
2861         my $h = $ed->{empty};
2862         foreach (sort keys %$h) {
2863                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2864                 push @out, "  $act: " . uri_encode($_);
2865                 warn "W: $act: $_\n";
2866         }
2867         foreach my $t (qw/dir_prop file_prop/) {
2868                 $h = $ed->{$t} or next;
2869                 foreach my $path (sort keys %$h) {
2870                         my $ppath = $path eq '' ? '.' : $path;
2871                         foreach my $prop (sort keys %{$h->{$path}}) {
2872                                 next if $SKIP_PROP{$prop};
2873                                 my $v = $h->{$path}->{$prop};
2874                                 my $t_ppath_prop = "$t: " .
2875                                                     uri_encode($ppath) . ' ' .
2876                                                     uri_encode($prop);
2877                                 if (defined $v) {
2878                                         push @out, "  +$t_ppath_prop " .
2879                                                    uri_encode($v);
2880                                 } else {
2881                                         push @out, "  -$t_ppath_prop";
2882                                 }
2883                         }
2884                 }
2885         }
2886         foreach my $t (qw/absent_file absent_directory/) {
2887                 $h = $ed->{$t} or next;
2888                 foreach my $parent (sort keys %$h) {
2889                         foreach my $path (sort @{$h->{$parent}}) {
2890                                 push @out, "  $t: " .
2891                                            uri_encode("$parent/$path");
2892                                 warn "W: $t: $parent/$path ",
2893                                      "Insufficient permissions?\n";
2894                         }
2895                 }
2896         }
2897         \@out;
2898 }
2899
2900 # parse_svn_date(DATE)
2901 # --------------------
2902 # Given a date (in UTC) from Subversion, return a string in the format
2903 # "<TZ Offset> <local date/time>" that Git will use.
2904 #
2905 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2906 # is true we'll convert it to the local timezone instead.
2907 sub parse_svn_date {
2908         my $date = shift || return '+0000 1970-01-01 00:00:00';
2909         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2910                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2911                                          croak "Unable to parse date: $date\n";
2912         my $parsed_date;    # Set next.
2913
2914         if ($Git::SVN::_localtime) {
2915                 # Translate the Subversion datetime to an epoch time.
2916                 # Begin by switching ourselves to $date's timezone, UTC.
2917                 my $old_env_TZ = $ENV{TZ};
2918                 $ENV{TZ} = 'UTC';
2919
2920                 my $epoch_in_UTC =
2921                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2922
2923                 # Determine our local timezone (including DST) at the
2924                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
2925                 # value of TZ, if any, at the time we were run.
2926                 if (defined $Git::SVN::Log::TZ) {
2927                         $ENV{TZ} = $Git::SVN::Log::TZ;
2928                 } else {
2929                         delete $ENV{TZ};
2930                 }
2931
2932                 my $our_TZ =
2933                     POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2934
2935                 # This converts $epoch_in_UTC into our local timezone.
2936                 my ($sec, $min, $hour, $mday, $mon, $year,
2937                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2938
2939                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2940                                        $our_TZ, $year + 1900, $mon + 1,
2941                                        $mday, $hour, $min, $sec);
2942
2943                 # Reset us to the timezone in effect when we entered
2944                 # this routine.
2945                 if (defined $old_env_TZ) {
2946                         $ENV{TZ} = $old_env_TZ;
2947                 } else {
2948                         delete $ENV{TZ};
2949                 }
2950         } else {
2951                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2952         }
2953
2954         return $parsed_date;
2955 }
2956
2957 sub other_gs {
2958         my ($self, $new_url, $url,
2959             $branch_from, $r, $old_ref_id) = @_;
2960         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2961         unless ($gs) {
2962                 my $ref_id = $old_ref_id;
2963                 $ref_id =~ s/\@\d+-*$//;
2964                 $ref_id .= "\@$r";
2965                 # just grow a tail if we're not unique enough :x
2966                 $ref_id .= '-' while find_ref($ref_id);
2967                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2968                 if ($u =~ s#^\Q$url\E(/|$)##) {
2969                         $p = $u;
2970                         $u = $url;
2971                         $repo_id = $self->{repo_id};
2972                 }
2973                 while (1) {
2974                         # It is possible to tag two different subdirectories at
2975                         # the same revision.  If the url for an existing ref
2976                         # does not match, we must either find a ref with a
2977                         # matching url or create a new ref by growing a tail.
2978                         $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2979                         my (undef, $max_commit) = $gs->rev_map_max(1);
2980                         last if (!$max_commit);
2981                         my ($url) = ::cmt_metadata($max_commit);
2982                         last if ($url eq $gs->full_url);
2983                         $ref_id .= '-';
2984                 }
2985                 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
2986         }
2987         $gs
2988 }
2989
2990 sub call_authors_prog {
2991         my ($orig_author) = @_;
2992         $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
2993         my $author = `$::_authors_prog $orig_author`;
2994         if ($? != 0) {
2995                 die "$::_authors_prog failed with exit code $?\n"
2996         }
2997         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
2998                 my ($name, $email) = ($1, $2);
2999                 $email = undef if length $2 == 0;
3000                 return [$name, $email];
3001         } else {
3002                 die "Author: $orig_author: $::_authors_prog returned "
3003                         . "invalid author format: $author\n";
3004         }
3005 }
3006
3007 sub check_author {
3008         my ($author) = @_;
3009         if (!defined $author || length $author == 0) {
3010                 $author = '(no author)';
3011         }
3012         if (!defined $::users{$author}) {
3013                 if (defined $::_authors_prog) {
3014                         $::users{$author} = call_authors_prog($author);
3015                 } elsif (defined $::_authors) {
3016                         die "Author: $author not defined in $::_authors file\n";
3017                 }
3018         }
3019         $author;
3020 }
3021
3022 sub find_extra_svk_parents {
3023         my ($self, $ed, $tickets, $parents) = @_;
3024         # aha!  svk:merge property changed...
3025         my @tickets = split "\n", $tickets;
3026         my @known_parents;
3027         for my $ticket ( @tickets ) {
3028                 my ($uuid, $path, $rev) = split /:/, $ticket;
3029                 if ( $uuid eq $self->ra_uuid ) {
3030                         my $url = $self->{url};
3031                         my $repos_root = $url;
3032                         my $branch_from = $path;
3033                         $branch_from =~ s{^/}{};
3034                         my $gs = $self->other_gs($repos_root."/".$branch_from,
3035                                                  $url,
3036                                                  $branch_from,
3037                                                  $rev,
3038                                                  $self->{ref_id});
3039                         if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
3040                                 # wahey!  we found it, but it might be
3041                                 # an old one (!)
3042                                 push @known_parents, [ $rev, $commit ];
3043                         }
3044                 }
3045         }
3046         # Ordering matters; highest-numbered commit merge tickets
3047         # first, as they may account for later merge ticket additions
3048         # or changes.
3049         @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
3050         for my $parent ( @known_parents ) {
3051                 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
3052                 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3053                 my $new;
3054                 while ( <$msg_fh> ) {
3055                         $new=1;last;
3056                 }
3057                 command_close_pipe($msg_fh, $ctx);
3058                 if ( $new ) {
3059                         print STDERR
3060                             "Found merge parent (svk:merge ticket): $parent\n";
3061                         push @$parents, $parent;
3062                 }
3063         }
3064 }
3065
3066 sub lookup_svn_merge {
3067         my $uuid = shift;
3068         my $url = shift;
3069         my $merge = shift;
3070
3071         my ($source, $revs) = split ":", $merge;
3072         my $path = $source;
3073         $path =~ s{^/}{};
3074         my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
3075         if ( !$gs ) {
3076                 warn "Couldn't find revmap for $url$source\n";
3077                 return;
3078         }
3079         my @ranges = split ",", $revs;
3080         my ($tip, $tip_commit);
3081         my @merged_commit_ranges;
3082         # find the tip
3083         for my $range ( @ranges ) {
3084                 my ($bottom, $top) = split "-", $range;
3085                 $top ||= $bottom;
3086                 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
3087                 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
3088
3089                 unless ($top_commit and $bottom_commit) {
3090                         warn "W:unknown path/rev in svn:mergeinfo "
3091                                 ."dirprop: $source:$range\n";
3092                         next;
3093                 }
3094
3095                 push @merged_commit_ranges,
3096                         "$bottom_commit^..$top_commit";
3097
3098                 if ( !defined $tip or $top > $tip ) {
3099                         $tip = $top;
3100                         $tip_commit = $top_commit;
3101                 }
3102         }
3103         return ($tip_commit, @merged_commit_ranges);
3104 }
3105
3106 sub _rev_list {
3107         my ($msg_fh, $ctx) = command_output_pipe(
3108                 "rev-list", @_,
3109                );
3110         my @rv;
3111         while ( <$msg_fh> ) {
3112                 chomp;
3113                 push @rv, $_;
3114         }
3115         command_close_pipe($msg_fh, $ctx);
3116         @rv;
3117 }
3118
3119 sub check_cherry_pick {
3120         my $base = shift;
3121         my $tip = shift;
3122         my $parents = shift;
3123         my @ranges = @_;
3124         my %commits = map { $_ => 1 }
3125                 _rev_list("--no-merges", $tip, "--not", $base, @$parents);
3126         for my $range ( @ranges ) {
3127                 delete @commits{_rev_list($range)};
3128         }
3129         for my $commit (keys %commits) {
3130                 if (has_no_changes($commit)) {
3131                         delete $commits{$commit};
3132                 }
3133         }
3134         return (keys %commits);
3135 }
3136
3137 sub has_no_changes {
3138         my $commit = shift;
3139
3140         my @revs = split / /, command_oneline(
3141                 qw(rev-list --parents -1 -m), $commit);
3142
3143         # Commits with no parents, e.g. the start of a partial branch,
3144         # have changes by definition.
3145         return 1 if (@revs < 2);
3146
3147         # Commits with multiple parents, e.g a merge, have no changes
3148         # by definition.
3149         return 0 if (@revs > 2);
3150
3151         return (command_oneline("rev-parse", "$commit^{tree}") eq
3152                 command_oneline("rev-parse", "$commit~1^{tree}"));
3153 }
3154
3155 # The GIT_DIR environment variable is not always set until after the command
3156 # line arguments are processed, so we can't memoize in a BEGIN block.
3157 {
3158         my $memoized = 0;
3159
3160         sub memoize_svn_mergeinfo_functions {
3161                 return if $memoized;
3162                 $memoized = 1;
3163
3164                 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
3165                 mkpath([$cache_path]) unless -d $cache_path;
3166
3167                 tie my %lookup_svn_merge_cache => 'Memoize::Storable',
3168                     "$cache_path/lookup_svn_merge.db", 'nstore';
3169                 memoize 'lookup_svn_merge',
3170                         SCALAR_CACHE => 'FAULT',
3171                         LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
3172                 ;
3173
3174                 tie my %check_cherry_pick_cache => 'Memoize::Storable',
3175                     "$cache_path/check_cherry_pick.db", 'nstore';
3176                 memoize 'check_cherry_pick',
3177                         SCALAR_CACHE => 'FAULT',
3178                         LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
3179                 ;
3180
3181                 tie my %has_no_changes_cache => 'Memoize::Storable',
3182                     "$cache_path/has_no_changes.db", 'nstore';
3183                 memoize 'has_no_changes',
3184                         SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
3185                         LIST_CACHE => 'FAULT',
3186                 ;
3187         }
3188
3189         sub unmemoize_svn_mergeinfo_functions {
3190                 return if not $memoized;
3191                 $memoized = 0;
3192
3193                 Memoize::unmemoize 'lookup_svn_merge';
3194                 Memoize::unmemoize 'check_cherry_pick';
3195                 Memoize::unmemoize 'has_no_changes';
3196         }
3197 }
3198
3199 END {
3200         # Force cache writeout explicitly instead of waiting for
3201         # global destruction to avoid segfault in Storable:
3202         # http://rt.cpan.org/Public/Bug/Display.html?id=36087
3203         unmemoize_svn_mergeinfo_functions();
3204 }
3205
3206 sub parents_exclude {
3207         my $parents = shift;
3208         my @commits = @_;
3209         return unless @commits;
3210
3211         my @excluded;
3212         my $excluded;
3213         do {
3214                 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
3215                 $excluded = command_oneline(@cmd);
3216                 if ( $excluded ) {
3217                         my @new;
3218                         my $found;
3219                         for my $commit ( @commits ) {
3220                                 if ( $commit eq $excluded ) {
3221                                         push @excluded, $commit;
3222                                         $found++;
3223                                         last;
3224                                 }
3225                                 else {
3226                                         push @new, $commit;
3227                                 }
3228                         }
3229                         die "saw commit '$excluded' in rev-list output, "
3230                                 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
3231                                         unless $found;
3232                         @commits = @new;
3233                 }
3234         }
3235                 while ($excluded and @commits);
3236
3237         return @excluded;
3238 }
3239
3240
3241 # note: this function should only be called if the various dirprops
3242 # have actually changed
3243 sub find_extra_svn_parents {
3244         my ($self, $ed, $mergeinfo, $parents) = @_;
3245         # aha!  svk:merge property changed...
3246
3247         memoize_svn_mergeinfo_functions();
3248
3249         # We first search for merged tips which are not in our
3250         # history.  Then, we figure out which git revisions are in
3251         # that tip, but not this revision.  If all of those revisions
3252         # are now marked as merge, we can add the tip as a parent.
3253         my @merges = split "\n", $mergeinfo;
3254         my @merge_tips;
3255         my $url = $self->{url};
3256         my $uuid = $self->ra_uuid;
3257         my %ranges;
3258         for my $merge ( @merges ) {
3259                 my ($tip_commit, @ranges) =
3260                         lookup_svn_merge( $uuid, $url, $merge );
3261                 unless (!$tip_commit or
3262                                 grep { $_ eq $tip_commit } @$parents ) {
3263                         push @merge_tips, $tip_commit;
3264                         $ranges{$tip_commit} = \@ranges;
3265                 } else {
3266                         push @merge_tips, undef;
3267                 }
3268         }
3269
3270         my %excluded = map { $_ => 1 }
3271                 parents_exclude($parents, grep { defined } @merge_tips);
3272
3273         # check merge tips for new parents
3274         my @new_parents;
3275         for my $merge_tip ( @merge_tips ) {
3276                 my $spec = shift @merges;
3277                 next unless $merge_tip and $excluded{$merge_tip};
3278
3279                 my $ranges = $ranges{$merge_tip};
3280
3281                 # check out 'new' tips
3282                 my $merge_base;
3283                 eval {
3284                         $merge_base = command_oneline(
3285                                 "merge-base",
3286                                 @$parents, $merge_tip,
3287                         );
3288                 };
3289                 if ($@) {
3290                         die "An error occurred during merge-base"
3291                                 unless $@->isa("Git::Error::Command");
3292
3293                         warn "W: Cannot find common ancestor between ".
3294                              "@$parents and $merge_tip. Ignoring merge info.\n";
3295                         next;
3296                 }
3297
3298                 # double check that there are no missing non-merge commits
3299                 my (@incomplete) = check_cherry_pick(
3300                         $merge_base, $merge_tip,
3301                         $parents,
3302                         @$ranges,
3303                        );
3304
3305                 if ( @incomplete ) {
3306                         warn "W:svn cherry-pick ignored ($spec) - missing "
3307                                 .@incomplete." commit(s) (eg $incomplete[0])\n";
3308                 } else {
3309                         warn
3310                                 "Found merge parent (svn:mergeinfo prop): ",
3311                                         $merge_tip, "\n";
3312                         push @new_parents, $merge_tip;
3313                 }
3314         }
3315
3316         # cater for merges which merge commits from multiple branches
3317         if ( @new_parents > 1 ) {
3318                 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
3319                         for ( my $j = 0; $j <= $#new_parents; $j++ ) {
3320                                 next if $i == $j;
3321                                 next unless $new_parents[$i];
3322                                 next unless $new_parents[$j];
3323                                 my $revs = command_oneline(
3324                                         "rev-list", "-1",
3325                                         "$new_parents[$i]..$new_parents[$j]",
3326                                        );
3327                                 if ( !$revs ) {
3328                                         undef($new_parents[$j]);
3329                                 }
3330                         }
3331                 }
3332         }
3333         push @$parents, grep { defined } @new_parents;
3334 }
3335
3336 sub make_log_entry {
3337         my ($self, $rev, $parents, $ed) = @_;
3338         my $untracked = $self->get_untracked($ed);
3339
3340         my @parents = @$parents;
3341         my $ps = $ed->{path_strip} || "";
3342         for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
3343                 my $props = $ed->{dir_prop}{$path};
3344                 if ( $props->{"svk:merge"} ) {
3345                         $self->find_extra_svk_parents
3346                                 ($ed, $props->{"svk:merge"}, \@parents);
3347                 }
3348                 if ( $props->{"svn:mergeinfo"} ) {
3349                         $self->find_extra_svn_parents
3350                                 ($ed,
3351                                  $props->{"svn:mergeinfo"},
3352                                  \@parents);
3353                 }
3354         }
3355
3356         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
3357         print $un "r$rev\n" or croak $!;
3358         print $un $_, "\n" foreach @$untracked;
3359         my %log_entry = ( parents => \@parents, revision => $rev,
3360                           log => '');
3361
3362         my $headrev;
3363         my $logged = delete $self->{logged_rev_props};
3364         if (!$logged || $self->{-want_revprops}) {
3365                 my $rp = $self->ra->rev_proplist($rev);
3366                 foreach (sort keys %$rp) {
3367                         my $v = $rp->{$_};
3368                         if (/^svn:(author|date|log)$/) {
3369                                 $log_entry{$1} = $v;
3370                         } elsif ($_ eq 'svm:headrev') {
3371                                 $headrev = $v;
3372                         } else {
3373                                 print $un "  rev_prop: ", uri_encode($_), ' ',
3374                                           uri_encode($v), "\n";
3375                         }
3376                 }
3377         } else {
3378                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
3379         }
3380         close $un or croak $!;
3381
3382         $log_entry{date} = parse_svn_date($log_entry{date});
3383         $log_entry{log} .= "\n";
3384         my $author = $log_entry{author} = check_author($log_entry{author});
3385         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
3386                                                        : ($author, undef);
3387
3388         my ($commit_name, $commit_email) = ($name, $email);
3389         if ($_use_log_author) {
3390                 my $name_field;
3391                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
3392                         $name_field = $1;
3393                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
3394                         $name_field = $1;
3395                 }
3396                 if (!defined $name_field) {
3397                         if (!defined $email) {
3398                                 $email = $name;
3399                         }
3400                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
3401                         ($name, $email) = ($1, $2);
3402                 } elsif ($name_field =~ /(.*)@/) {
3403                         ($name, $email) = ($1, $name_field);
3404                 } else {
3405                         ($name, $email) = ($name_field, $name_field);
3406                 }
3407         }
3408         if (defined $headrev && $self->use_svm_props) {
3409                 if ($self->rewrite_root) {
3410                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
3411                             "options set!\n";
3412                 }
3413                 if ($self->rewrite_uuid) {
3414                         die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
3415                             "options set!\n";
3416                 }
3417                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
3418                 # we don't want "SVM: initializing mirror for junk" ...
3419                 return undef if $r == 0;
3420                 my $svm = $self->svm;
3421                 if ($uuid ne $svm->{uuid}) {
3422                         die "UUID mismatch on SVM path:\n",
3423                             "expected: $svm->{uuid}\n",
3424                             "     got: $uuid\n";
3425                 }
3426                 my $full_url = $self->full_url;
3427                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
3428                              die "Failed to replace '$svm->{replace}' with ",
3429                                  "'$svm->{source}' in $full_url\n";
3430                 # throw away username for storing in records
3431                 remove_username($full_url);
3432                 $log_entry{metadata} = "$full_url\@$r $uuid";
3433                 $log_entry{svm_revision} = $r;
3434                 $email ||= "$author\@$uuid";
3435                 $commit_email ||= "$author\@$uuid";
3436         } elsif ($self->use_svnsync_props) {
3437                 my $full_url = $self->svnsync->{url};
3438                 $full_url .= "/$self->{path}" if length $self->{path};
3439                 remove_username($full_url);
3440                 my $uuid = $self->svnsync->{uuid};
3441                 $log_entry{metadata} = "$full_url\@$rev $uuid";
3442                 $email ||= "$author\@$uuid";
3443                 $commit_email ||= "$author\@$uuid";
3444         } else {
3445                 my $url = $self->metadata_url;
3446                 remove_username($url);
3447                 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
3448                 $log_entry{metadata} = "$url\@$rev " . $uuid;
3449                 $email ||= "$author\@" . $uuid;
3450                 $commit_email ||= "$author\@" . $uuid;
3451         }
3452         $log_entry{name} = $name;
3453         $log_entry{email} = $email;
3454         $log_entry{commit_name} = $commit_name;
3455         $log_entry{commit_email} = $commit_email;
3456         \%log_entry;
3457 }
3458
3459 sub fetch {
3460         my ($self, $min_rev, $max_rev, @parents) = @_;
3461         my ($last_rev, $last_commit) = $self->last_rev_commit;
3462         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
3463         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
3464 }
3465
3466 sub set_tree_cb {
3467         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
3468         $self->{inject_parents} = { $rev => $tree };
3469         $self->fetch(undef, undef);
3470 }
3471
3472 sub set_tree {
3473         my ($self, $tree) = (shift, shift);
3474         my $log_entry = ::get_commit_entry($tree);
3475         unless ($self->{last_rev}) {
3476                 ::fatal("Must have an existing revision to commit");
3477         }
3478         my %ed_opts = ( r => $self->{last_rev},
3479                         log => $log_entry->{log},
3480                         ra => $self->ra,
3481                         tree_a => $self->{last_commit},
3482                         tree_b => $tree,
3483                         editor_cb => sub {
3484                                $self->set_tree_cb($log_entry, $tree, @_) },
3485                         svn_path => $self->{path} );
3486         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
3487                 print "No changes\nr$self->{last_rev} = $tree\n";
3488         }
3489 }
3490
3491 sub rebuild_from_rev_db {
3492         my ($self, $path) = @_;
3493         my $r = -1;
3494         open my $fh, '<', $path or croak "open: $!";
3495         binmode $fh or croak "binmode: $!";
3496         while (<$fh>) {
3497                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3498                 chomp($_);
3499                 ++$r;
3500                 next if $_ eq ('0' x 40);
3501                 $self->rev_map_set($r, $_);
3502                 print "r$r = $_\n";
3503         }
3504         close $fh or croak "close: $!";
3505         unlink $path or croak "unlink: $!";
3506 }
3507
3508 sub rebuild {
3509         my ($self) = @_;
3510         my $map_path = $self->map_path;
3511         my $partial = (-e $map_path && ! -z $map_path);
3512         return unless ::verify_ref($self->refname.'^0');
3513         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3514                 my $rev_db = $self->rev_db_path;
3515                 $self->rebuild_from_rev_db($rev_db);
3516                 if ($self->use_svm_props) {
3517                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3518                         $self->rebuild_from_rev_db($svm_rev_db);
3519                 }
3520                 $self->unlink_rev_db_symlink;
3521                 return;
3522         }
3523         print "Rebuilding $map_path ...\n" if (!$partial);
3524         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3525                 (undef, undef));
3526         my ($log, $ctx) =
3527             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3528                                 ($head ? "$head.." : "") . $self->refname,
3529                                 '--');
3530         my $metadata_url = $self->metadata_url;
3531         remove_username($metadata_url);
3532         my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
3533         my $c;
3534         while (<$log>) {
3535                 if ( m{^commit ($::sha1)$} ) {
3536                         $c = $1;
3537                         next;
3538                 }
3539                 next unless s{^\s*(git-svn-id:)}{$1};
3540                 my ($url, $rev, $uuid) = ::extract_metadata($_);
3541                 remove_username($url);
3542
3543                 # ignore merges (from set-tree)
3544                 next if (!defined $rev || !$uuid);
3545
3546                 # if we merged or otherwise started elsewhere, this is
3547                 # how we break out of it
3548                 if (($uuid ne $svn_uuid) ||
3549                     ($metadata_url && $url && ($url ne $metadata_url))) {
3550                         next;
3551                 }
3552                 if ($partial && $head) {
3553                         print "Partial-rebuilding $map_path ...\n";
3554                         print "Currently at $base_rev = $head\n";
3555                         $head = undef;
3556                 }
3557
3558                 $self->rev_map_set($rev, $c);
3559                 print "r$rev = $c\n";
3560         }
3561         command_close_pipe($log, $ctx);
3562         print "Done rebuilding $map_path\n" if (!$partial || !$head);
3563         my $rev_db_path = $self->rev_db_path;
3564         if (-f $self->rev_db_path) {
3565                 unlink $self->rev_db_path or croak "unlink: $!";
3566         }
3567         $self->unlink_rev_db_symlink;
3568 }
3569
3570 # rev_map:
3571 # Tie::File seems to be prone to offset errors if revisions get sparse,
3572 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
3573 # one of my favorite modules is out :<  Next up would be one of the DBM
3574 # modules, but I'm not sure which is most portable...
3575 #
3576 # This is the replacement for the rev_db format, which was too big
3577 # and inefficient for large repositories with a lot of sparse history
3578 # (mainly tags)
3579 #
3580 # The format is this:
3581 #   - 24 bytes for every record,
3582 #     * 4 bytes for the integer representing an SVN revision number
3583 #     * 20 bytes representing the sha1 of a git commit
3584 #   - No empty padding records like the old format
3585 #     (except the last record, which can be overwritten)
3586 #   - new records are written append-only since SVN revision numbers
3587 #     increase monotonically
3588 #   - lookups on SVN revision number are done via a binary search
3589 #   - Piping the file to xxd -c24 is a good way of dumping it for
3590 #     viewing or editing (piped back through xxd -r), should the need
3591 #     ever arise.
3592 #   - The last record can be padding revision with an all-zero sha1
3593 #     This is used to optimize fetch performance when using multiple
3594 #     "fetch" directives in .git/config
3595 #
3596 # These files are disposable unless noMetadata or useSvmProps is set
3597
3598 sub _rev_map_set {
3599         my ($fh, $rev, $commit) = @_;
3600
3601         binmode $fh or croak "binmode: $!";
3602         my $size = (stat($fh))[7];
3603         ($size % 24) == 0 or croak "inconsistent size: $size";
3604
3605         my $wr_offset = 0;
3606         if ($size > 0) {
3607                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3608                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3609                 $read == 24 or croak "read only $read bytes (!= 24)";
3610                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3611                 if ($last_commit eq ('0' x40)) {
3612                         if ($size >= 48) {
3613                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3614                                 $read = sysread($fh, $buf, 24) or
3615                                     croak "read: $!";
3616                                 $read == 24 or
3617                                     croak "read only $read bytes (!= 24)";
3618                                 ($last_rev, $last_commit) =
3619                                     unpack(rev_map_fmt, $buf);
3620                                 if ($last_commit eq ('0' x40)) {
3621                                         croak "inconsistent .rev_map\n";
3622                                 }
3623                         }
3624                         if ($last_rev >= $rev) {
3625                                 croak "last_rev is higher!: $last_rev >= $rev";
3626                         }
3627                         $wr_offset = -24;
3628                 }
3629         }
3630         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3631         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3632           croak "write: $!";
3633 }
3634
3635 sub _rev_map_reset {
3636         my ($fh, $rev, $commit) = @_;
3637         my $c = _rev_map_get($fh, $rev);
3638         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3639         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3640         truncate $fh, $offset or croak "truncate: $!";
3641 }
3642
3643 sub mkfile {
3644         my ($path) = @_;
3645         unless (-e $path) {
3646                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3647                 mkpath([$dir]) unless -d $dir;
3648                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3649                 close $fh or die "Couldn't close (create) $path: $!\n";
3650         }
3651 }
3652
3653 sub rev_map_set {
3654         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3655         defined $commit or die "missing arg3\n";
3656         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3657         my $db = $self->map_path($uuid);
3658         my $db_lock = "$db.lock";
3659         my $sig;
3660         $update_ref ||= 0;
3661         if ($update_ref) {
3662                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3663                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3664         }
3665         mkfile($db);
3666
3667         $LOCKFILES{$db_lock} = 1;
3668         my $sync;
3669         # both of these options make our .rev_db file very, very important
3670         # and we can't afford to lose it because rebuild() won't work
3671         if ($self->use_svm_props || $self->no_metadata) {
3672                 $sync = 1;
3673                 copy($db, $db_lock) or die "rev_map_set(@_): ",
3674                                            "Failed to copy: ",
3675                                            "$db => $db_lock ($!)\n";
3676         } else {
3677                 rename $db, $db_lock or die "rev_map_set(@_): ",
3678                                             "Failed to rename: ",
3679                                             "$db => $db_lock ($!)\n";
3680         }
3681
3682         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3683              or croak "Couldn't open $db_lock: $!\n";
3684         $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3685                                  _rev_map_set($fh, $rev, $commit);
3686         if ($sync) {
3687                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3688                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3689         }
3690         close $fh or croak $!;
3691         if ($update_ref) {
3692                 $_head = $self;
3693                 my $note = "";
3694                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3695                 command_noisy('update-ref', '-m', "r$rev$note",
3696                               $self->refname, $commit);
3697         }
3698         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3699                                     "$db_lock => $db ($!)\n";
3700         delete $LOCKFILES{$db_lock};
3701         if ($update_ref) {
3702                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3703                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3704                 kill $sig, $$ if defined $sig;
3705         }
3706 }
3707
3708 # If want_commit, this will return an array of (rev, commit) where
3709 # commit _must_ be a valid commit in the archive.
3710 # Otherwise, it'll return the max revision (whether or not the
3711 # commit is valid or just a 0x40 placeholder).
3712 sub rev_map_max {
3713         my ($self, $want_commit) = @_;
3714         $self->rebuild;
3715         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3716         $want_commit ? ($r, $c) : $r;
3717 }
3718
3719 sub rev_map_max_norebuild {
3720         my ($self, $want_commit) = @_;
3721         my $map_path = $self->map_path;
3722         stat $map_path or return $want_commit ? (0, undef) : 0;
3723         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3724         binmode $fh or croak "binmode: $!";
3725         my $size = (stat($fh))[7];
3726         ($size % 24) == 0 or croak "inconsistent size: $size";
3727
3728         if ($size == 0) {
3729                 close $fh or croak "close: $!";
3730                 return $want_commit ? (0, undef) : 0;
3731         }
3732
3733         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3734         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3735         my ($r, $c) = unpack(rev_map_fmt, $buf);
3736         if ($want_commit && $c eq ('0' x40)) {
3737                 if ($size < 48) {
3738                         return $want_commit ? (0, undef) : 0;
3739                 }
3740                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3741                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3742                 ($r, $c) = unpack(rev_map_fmt, $buf);
3743                 if ($c eq ('0'x40)) {
3744                         croak "Penultimate record is all-zeroes in $map_path";
3745                 }
3746         }
3747         close $fh or croak "close: $!";
3748         $want_commit ? ($r, $c) : $r;
3749 }
3750
3751 sub rev_map_get {
3752         my ($self, $rev, $uuid) = @_;
3753         my $map_path = $self->map_path($uuid);
3754         return undef unless -e $map_path;
3755
3756         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3757         my $c = _rev_map_get($fh, $rev);
3758         close($fh) or croak "close: $!";
3759         $c
3760 }
3761
3762 sub _rev_map_get {
3763         my ($fh, $rev) = @_;
3764
3765         binmode $fh or croak "binmode: $!";
3766         my $size = (stat($fh))[7];
3767         ($size % 24) == 0 or croak "inconsistent size: $size";
3768
3769         if ($size == 0) {
3770                 return undef;
3771         }
3772
3773         my ($l, $u) = (0, $size - 24);
3774         my ($r, $c, $buf);
3775
3776         while ($l <= $u) {
3777                 my $i = int(($l/24 + $u/24) / 2) * 24;
3778                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3779                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3780                 my ($r, $c) = unpack(rev_map_fmt, $buf);
3781
3782                 if ($r < $rev) {
3783                         $l = $i + 24;
3784                 } elsif ($r > $rev) {
3785                         $u = $i - 24;
3786                 } else { # $r == $rev
3787                         return $c eq ('0' x 40) ? undef : $c;
3788                 }
3789         }
3790         undef;
3791 }
3792
3793 # Finds the first svn revision that exists on (if $eq_ok is true) or
3794 # before $rev for the current branch.  It will not search any lower
3795 # than $min_rev.  Returns the git commit hash and svn revision number
3796 # if found, else (undef, undef).
3797 sub find_rev_before {
3798         my ($self, $rev, $eq_ok, $min_rev) = @_;
3799         --$rev unless $eq_ok;
3800         $min_rev ||= 1;
3801         my $max_rev = $self->rev_map_max;
3802         $rev = $max_rev if ($rev > $max_rev);
3803         while ($rev >= $min_rev) {
3804                 if (my $c = $self->rev_map_get($rev)) {
3805                         return ($rev, $c);
3806                 }
3807                 --$rev;
3808         }
3809         return (undef, undef);
3810 }
3811
3812 # Finds the first svn revision that exists on (if $eq_ok is true) or
3813 # after $rev for the current branch.  It will not search any higher
3814 # than $max_rev.  Returns the git commit hash and svn revision number
3815 # if found, else (undef, undef).
3816 sub find_rev_after {
3817         my ($self, $rev, $eq_ok, $max_rev) = @_;
3818         ++$rev unless $eq_ok;
3819         $max_rev ||= $self->rev_map_max;
3820         while ($rev <= $max_rev) {
3821                 if (my $c = $self->rev_map_get($rev)) {
3822                         return ($rev, $c);
3823                 }
3824                 ++$rev;
3825         }
3826         return (undef, undef);
3827 }
3828
3829 sub _new {
3830         my ($class, $repo_id, $ref_id, $path) = @_;
3831         unless (defined $repo_id && length $repo_id) {
3832                 $repo_id = $Git::SVN::default_repo_id;
3833         }
3834         unless (defined $ref_id && length $ref_id) {
3835                 $_prefix = '' unless defined($_prefix);
3836                 $_[2] = $ref_id =
3837                              "refs/remotes/$_prefix$Git::SVN::default_ref_id";
3838         }
3839         $_[1] = $repo_id;
3840         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3841
3842         # Older repos imported by us used $GIT_DIR/svn/foo instead of
3843         # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
3844         if ($ref_id =~ m{^refs/remotes/(.*)}) {
3845                 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
3846                 if (-d $old_dir && ! -d $dir) {
3847                         $dir = $old_dir;
3848                 }
3849         }
3850
3851         $_[3] = $path = '' unless (defined $path);
3852         mkpath([$dir]);
3853         bless {
3854                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3855                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3856                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3857 }
3858
3859 # for read-only access of old .rev_db formats
3860 sub unlink_rev_db_symlink {
3861         my ($self) = @_;
3862         my $link = $self->rev_db_path;
3863         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3864         if (-l $link) {
3865                 unlink $link or croak "unlink: $link failed!";
3866         }
3867 }
3868
3869 sub rev_db_path {
3870         my ($self, $uuid) = @_;
3871         my $db_path = $self->map_path($uuid);
3872         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3873             or croak "map_path: $db_path does not contain '/.rev_map.' !";
3874         $db_path;
3875 }
3876
3877 # the new replacement for .rev_db
3878 sub map_path {
3879         my ($self, $uuid) = @_;
3880         $uuid ||= $self->ra_uuid;
3881         "$self->{map_root}.$uuid";
3882 }
3883
3884 sub uri_encode {
3885         my ($f) = @_;
3886         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3887         $f
3888 }
3889
3890 sub uri_decode {
3891         my ($f) = @_;
3892         $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
3893         $f
3894 }
3895
3896 sub remove_username {
3897         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3898 }
3899
3900 package Git::SVN::Prompt;
3901 use strict;
3902 use warnings;
3903 require SVN::Core;
3904 use vars qw/$_no_auth_cache $_username/;
3905
3906 sub simple {
3907         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3908         $may_save = undef if $_no_auth_cache;
3909         $default_username = $_username if defined $_username;
3910         if (defined $default_username && length $default_username) {
3911                 if (defined $realm && length $realm) {
3912                         print STDERR "Authentication realm: $realm\n";
3913                         STDERR->flush;
3914                 }
3915                 $cred->username($default_username);
3916         } else {
3917                 username($cred, $realm, $may_save, $pool);
3918         }
3919         $cred->password(_read_password("Password for '" .
3920                                        $cred->username . "': ", $realm));
3921         $cred->may_save($may_save);
3922         $SVN::_Core::SVN_NO_ERROR;
3923 }
3924
3925 sub ssl_server_trust {
3926         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3927         $may_save = undef if $_no_auth_cache;
3928         print STDERR "Error validating server certificate for '$realm':\n";
3929         {
3930                 no warnings 'once';
3931                 # All variables SVN::Auth::SSL::* are used only once,
3932                 # so we're shutting up Perl warnings about this.
3933                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3934                         print STDERR " - The certificate is not issued ",
3935                             "by a trusted authority. Use the\n",
3936                             "   fingerprint to validate ",
3937                             "the certificate manually!\n";
3938                 }
3939                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3940                         print STDERR " - The certificate hostname ",
3941                             "does not match.\n";
3942                 }
3943                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3944                         print STDERR " - The certificate is not yet valid.\n";
3945                 }
3946                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3947                         print STDERR " - The certificate has expired.\n";
3948                 }
3949                 if ($failures & $SVN::Auth::SSL::OTHER) {
3950                         print STDERR " - The certificate has ",
3951                             "an unknown error.\n";
3952                 }
3953         } # no warnings 'once'
3954         printf STDERR
3955                 "Certificate information:\n".
3956                 " - Hostname: %s\n".
3957                 " - Valid: from %s until %s\n".
3958                 " - Issuer: %s\n".
3959                 " - Fingerprint: %s\n",
3960                 map $cert_info->$_, qw(hostname valid_from valid_until
3961                                        issuer_dname fingerprint);
3962         my $choice;
3963 prompt:
3964         print STDERR $may_save ?
3965               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3966               "(R)eject or accept (t)emporarily? ";
3967         STDERR->flush;
3968         $choice = lc(substr(<STDIN> || 'R', 0, 1));
3969         if ($choice =~ /^t$/i) {
3970                 $cred->may_save(undef);
3971         } elsif ($choice =~ /^r$/i) {
3972                 return -1;
3973         } elsif ($may_save && $choice =~ /^p$/i) {
3974                 $cred->may_save($may_save);
3975         } else {
3976                 goto prompt;
3977         }
3978         $cred->accepted_failures($failures);
3979         $SVN::_Core::SVN_NO_ERROR;
3980 }
3981
3982 sub ssl_client_cert {
3983         my ($cred, $realm, $may_save, $pool) = @_;
3984         $may_save = undef if $_no_auth_cache;
3985         print STDERR "Client certificate filename: ";
3986         STDERR->flush;
3987         chomp(my $filename = <STDIN>);
3988         $cred->cert_file($filename);
3989         $cred->may_save($may_save);
3990         $SVN::_Core::SVN_NO_ERROR;
3991 }
3992
3993 sub ssl_client_cert_pw {
3994         my ($cred, $realm, $may_save, $pool) = @_;
3995         $may_save = undef if $_no_auth_cache;
3996         $cred->password(_read_password("Password: ", $realm));
3997         $cred->may_save($may_save);
3998         $SVN::_Core::SVN_NO_ERROR;
3999 }
4000
4001 sub username {
4002         my ($cred, $realm, $may_save, $pool) = @_;
4003         $may_save = undef if $_no_auth_cache;
4004         if (defined $realm && length $realm) {
4005                 print STDERR "Authentication realm: $realm\n";
4006         }
4007         my $username;
4008         if (defined $_username) {
4009                 $username = $_username;
4010         } else {
4011                 print STDERR "Username: ";
4012                 STDERR->flush;
4013                 chomp($username = <STDIN>);
4014         }
4015         $cred->username($username);
4016         $cred->may_save($may_save);
4017         $SVN::_Core::SVN_NO_ERROR;
4018 }
4019
4020 sub _read_password {
4021         my ($prompt, $realm) = @_;
4022         my $password = '';
4023         if (exists $ENV{GIT_ASKPASS}) {
4024                 open(PH, "-|", $ENV{GIT_ASKPASS}, $prompt);
4025                 $password = <PH>;
4026                 $password =~ s/[\012\015]//; # \n\r
4027                 close(PH);
4028         } else {
4029                 print STDERR $prompt;
4030                 STDERR->flush;
4031                 require Term::ReadKey;
4032                 Term::ReadKey::ReadMode('noecho');
4033                 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
4034                         last if $key =~ /[\012\015]/; # \n\r
4035                         $password .= $key;
4036                 }
4037                 Term::ReadKey::ReadMode('restore');
4038                 print STDERR "\n";
4039                 STDERR->flush;
4040         }
4041         $password;
4042 }
4043
4044 package SVN::Git::Fetcher;
4045 use vars qw/@ISA/;
4046 use strict;
4047 use warnings;
4048 use Carp qw/croak/;
4049 use IO::File qw//;
4050 use vars qw/$_ignore_regex/;
4051
4052 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
4053 sub new {
4054         my ($class, $git_svn, $switch_path) = @_;
4055         my $self = SVN::Delta::Editor->new;
4056         bless $self, $class;
4057         if (exists $git_svn->{last_commit}) {
4058                 $self->{c} = $git_svn->{last_commit};
4059                 $self->{empty_symlinks} =
4060                                   _mark_empty_symlinks($git_svn, $switch_path);
4061         }
4062         $self->{ignore_regex} = eval { command_oneline('config', '--get',
4063                              "svn-remote.$git_svn->{repo_id}.ignore-paths") };
4064         $self->{empty} = {};
4065         $self->{dir_prop} = {};
4066         $self->{file_prop} = {};
4067         $self->{absent_dir} = {};
4068         $self->{absent_file} = {};
4069         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
4070         $self->{pathnameencoding} = Git::config('svn.pathnameencoding');
4071         $self;
4072 }
4073
4074 # this uses the Ra object, so it must be called before do_{switch,update},
4075 # not inside them (when the Git::SVN::Fetcher object is passed) to
4076 # do_{switch,update}
4077 sub _mark_empty_symlinks {
4078         my ($git_svn, $switch_path) = @_;
4079         my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
4080         return {} if (!defined($bool)) || (defined($bool) && ! $bool);
4081
4082         my %ret;
4083         my ($rev, $cmt) = $git_svn->last_rev_commit;
4084         return {} unless ($rev && $cmt);
4085
4086         # allow the warning to be printed for each revision we fetch to
4087         # ensure the user sees it.  The user can also disable the workaround
4088         # on the repository even while git svn is running and the next
4089         # revision fetched will skip this expensive function.
4090         my $printed_warning;
4091         chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
4092         my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
4093         local $/ = "\0";
4094         my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
4095         $pfx .= '/' if length($pfx);
4096         while (<$ls>) {
4097                 chomp;
4098                 s/\A100644 blob $empty_blob\t//o or next;
4099                 unless ($printed_warning) {
4100                         print STDERR "Scanning for empty symlinks, ",
4101                                      "this may take a while if you have ",
4102                                      "many empty files\n",
4103                                      "You may disable this with `",
4104                                      "git config svn.brokenSymlinkWorkaround ",
4105                                      "false'.\n",
4106                                      "This may be done in a different ",
4107                                      "terminal without restarting ",
4108                                      "git svn\n";
4109                         $printed_warning = 1;
4110                 }
4111                 my $path = $_;
4112                 my (undef, $props) =
4113                                $git_svn->ra->get_file($pfx.$path, $rev, undef);
4114                 if ($props->{'svn:special'}) {
4115                         $ret{$path} = 1;
4116                 }
4117         }
4118         command_close_pipe($ls, $ctx);
4119         \%ret;
4120 }
4121
4122 # returns true if a given path is inside a ".git" directory
4123 sub in_dot_git {
4124         $_[0] =~ m{(?:^|/)\.git(?:/|$)};
4125 }
4126
4127 # return value: 0 -- don't ignore, 1 -- ignore
4128 sub is_path_ignored {
4129         my ($self, $path) = @_;
4130         return 1 if in_dot_git($path);
4131         return 1 if defined($self->{ignore_regex}) &&
4132                     $path =~ m!$self->{ignore_regex}!;
4133         return 0 unless defined($_ignore_regex);
4134         return 1 if $path =~ m!$_ignore_regex!o;
4135         return 0;
4136 }
4137
4138 sub set_path_strip {
4139         my ($self, $path) = @_;
4140         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
4141 }
4142
4143 sub open_root {
4144         { path => '' };
4145 }
4146
4147 sub open_directory {
4148         my ($self, $path, $pb, $rev) = @_;
4149         { path => $path };
4150 }
4151
4152 sub git_path {
4153         my ($self, $path) = @_;
4154         if (my $enc = $self->{pathnameencoding}) {
4155                 require Encode;
4156                 Encode::from_to($path, 'UTF-8', $enc);
4157         }
4158         if ($self->{path_strip}) {
4159                 $path =~ s!$self->{path_strip}!! or
4160                   die "Failed to strip path '$path' ($self->{path_strip})\n";
4161         }
4162         $path;
4163 }
4164
4165 sub delete_entry {
4166         my ($self, $path, $rev, $pb) = @_;
4167         return undef if $self->is_path_ignored($path);
4168
4169         my $gpath = $self->git_path($path);
4170         return undef if ($gpath eq '');
4171
4172         # remove entire directories.
4173         my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4174                          =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
4175         if ($tree) {
4176                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4177                                                      -r --name-only -z/,
4178                                                      $tree);
4179                 local $/ = "\0";
4180                 while (<$ls>) {
4181                         chomp;
4182                         my $rmpath = "$gpath/$_";
4183                         $self->{gii}->remove($rmpath);
4184                         print "\tD\t$rmpath\n" unless $::_q;
4185                 }
4186                 print "\tD\t$gpath/\n" unless $::_q;
4187                 command_close_pipe($ls, $ctx);
4188         } else {
4189                 $self->{gii}->remove($gpath);
4190                 print "\tD\t$gpath\n" unless $::_q;
4191         }
4192         $self->{empty}->{$path} = 0;
4193         undef;
4194 }
4195
4196 sub open_file {
4197         my ($self, $path, $pb, $rev) = @_;
4198         my ($mode, $blob);
4199
4200         goto out if $self->is_path_ignored($path);
4201
4202         my $gpath = $self->git_path($path);
4203         ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4204                              =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
4205         unless (defined $mode && defined $blob) {
4206                 die "$path was not found in commit $self->{c} (r$rev)\n";
4207         }
4208         if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
4209                 $mode = '120000';
4210         }
4211 out:
4212         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
4213           pool => SVN::Pool->new, action => 'M' };
4214 }
4215
4216 sub add_file {
4217         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
4218         my $mode;
4219
4220         if (!$self->is_path_ignored($path)) {
4221                 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4222                 delete $self->{empty}->{$dir};
4223                 $mode = '100644';
4224         }
4225         { path => $path, mode_a => $mode, mode_b => $mode,
4226           pool => SVN::Pool->new, action => 'A' };
4227 }
4228
4229 sub add_directory {
4230         my ($self, $path, $cp_path, $cp_rev) = @_;
4231         goto out if $self->is_path_ignored($path);
4232         my $gpath = $self->git_path($path);
4233         if ($gpath eq '') {
4234                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4235                                                      -r --name-only -z/,
4236                                                      $self->{c});
4237                 local $/ = "\0";
4238                 while (<$ls>) {
4239                         chomp;
4240                         $self->{gii}->remove($_);
4241                         print "\tD\t$_\n" unless $::_q;
4242                 }
4243                 command_close_pipe($ls, $ctx);
4244                 $self->{empty}->{$path} = 0;
4245         }
4246         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4247         delete $self->{empty}->{$dir};
4248         $self->{empty}->{$path} = 1;
4249 out:
4250         { path => $path };
4251 }
4252
4253 sub change_dir_prop {
4254         my ($self, $db, $prop, $value) = @_;
4255         return undef if $self->is_path_ignored($db->{path});
4256         $self->{dir_prop}->{$db->{path}} ||= {};
4257         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
4258         undef;
4259 }
4260
4261 sub absent_directory {
4262         my ($self, $path, $pb) = @_;
4263         return undef if $self->is_path_ignored($path);
4264         $self->{absent_dir}->{$pb->{path}} ||= [];
4265         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
4266         undef;
4267 }
4268
4269 sub absent_file {
4270         my ($self, $path, $pb) = @_;
4271         return undef if $self->is_path_ignored($path);
4272         $self->{absent_file}->{$pb->{path}} ||= [];
4273         push @{$self->{absent_file}->{$pb->{path}}}, $path;
4274         undef;
4275 }
4276
4277 sub change_file_prop {
4278         my ($self, $fb, $prop, $value) = @_;
4279         return undef if $self->is_path_ignored($fb->{path});
4280         if ($prop eq 'svn:executable') {
4281                 if ($fb->{mode_b} != 120000) {
4282                         $fb->{mode_b} = defined $value ? 100755 : 100644;
4283                 }
4284         } elsif ($prop eq 'svn:special') {
4285                 $fb->{mode_b} = defined $value ? 120000 : 100644;
4286         } else {
4287                 $self->{file_prop}->{$fb->{path}} ||= {};
4288                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
4289         }
4290         undef;
4291 }
4292
4293 sub apply_textdelta {
4294         my ($self, $fb, $exp) = @_;
4295         return undef if $self->is_path_ignored($fb->{path});
4296         my $fh = $::_repository->temp_acquire('svn_delta');
4297         # $fh gets auto-closed() by SVN::TxDelta::apply(),
4298         # (but $base does not,) so dup() it for reading in close_file
4299         open my $dup, '<&', $fh or croak $!;
4300         my $base = $::_repository->temp_acquire('git_blob');
4301
4302         if ($fb->{blob}) {
4303                 my ($base_is_link, $size);
4304
4305                 if ($fb->{mode_a} eq '120000' &&
4306                     ! $self->{empty_symlinks}->{$fb->{path}}) {
4307                         print $base 'link ' or die "print $!\n";
4308                         $base_is_link = 1;
4309                 }
4310         retry:
4311                 $size = $::_repository->cat_blob($fb->{blob}, $base);
4312                 die "Failed to read object $fb->{blob}" if ($size < 0);
4313
4314                 if (defined $exp) {
4315                         seek $base, 0, 0 or croak $!;
4316                         my $got = ::md5sum($base);
4317                         if ($got ne $exp) {
4318                                 my $err = "Checksum mismatch: ".
4319                                        "$fb->{path} $fb->{blob}\n" .
4320                                        "expected: $exp\n" .
4321                                        "     got: $got\n";
4322                                 if ($base_is_link) {
4323                                         warn $err,
4324                                              "Retrying... (possibly ",
4325                                              "a bad symlink from SVN)\n";
4326                                         $::_repository->temp_reset($base);
4327                                         $base_is_link = 0;
4328                                         goto retry;
4329                                 }
4330                                 die $err;
4331                         }
4332                 }
4333         }
4334         seek $base, 0, 0 or croak $!;
4335         $fb->{fh} = $fh;
4336         $fb->{base} = $base;
4337         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
4338 }
4339
4340 sub close_file {
4341         my ($self, $fb, $exp) = @_;
4342         return undef if $self->is_path_ignored($fb->{path});
4343
4344         my $hash;
4345         my $path = $self->git_path($fb->{path});
4346         if (my $fh = $fb->{fh}) {
4347                 if (defined $exp) {
4348                         seek($fh, 0, 0) or croak $!;
4349                         my $got = ::md5sum($fh);
4350                         if ($got ne $exp) {
4351                                 die "Checksum mismatch: $path\n",
4352                                     "expected: $exp\n    got: $got\n";
4353                         }
4354                 }
4355                 if ($fb->{mode_b} == 120000) {
4356                         sysseek($fh, 0, 0) or croak $!;
4357                         my $rd = sysread($fh, my $buf, 5);
4358
4359                         if (!defined $rd) {
4360                                 croak "sysread: $!\n";
4361                         } elsif ($rd == 0) {
4362                                 warn "$path has mode 120000",
4363                                      " but it points to nothing\n",
4364                                      "converting to an empty file with mode",
4365                                      " 100644\n";
4366                                 $fb->{mode_b} = '100644';
4367                         } elsif ($buf ne 'link ') {
4368                                 warn "$path has mode 120000",
4369                                      " but is not a link\n";
4370                         } else {
4371                                 my $tmp_fh = $::_repository->temp_acquire(
4372                                         'svn_hash');
4373                                 my $res;
4374                                 while ($res = sysread($fh, my $str, 1024)) {
4375                                         my $out = syswrite($tmp_fh, $str, $res);
4376                                         defined($out) && $out == $res
4377                                                 or croak("write ",
4378                                                         Git::temp_path($tmp_fh),
4379                                                         ": $!\n");
4380                                 }
4381                                 defined $res or croak $!;
4382
4383                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
4384                                 Git::temp_release($tmp_fh, 1);
4385                         }
4386                 }
4387
4388                 $hash = $::_repository->hash_and_insert_object(
4389                                 Git::temp_path($fh));
4390                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
4391
4392                 Git::temp_release($fb->{base}, 1);
4393                 Git::temp_release($fh, 1);
4394         } else {
4395                 $hash = $fb->{blob} or die "no blob information\n";
4396         }
4397         $fb->{pool}->clear;
4398         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
4399         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
4400         undef;
4401 }
4402
4403 sub abort_edit {
4404         my $self = shift;
4405         $self->{nr} = $self->{gii}->{nr};
4406         delete $self->{gii};
4407         $self->SUPER::abort_edit(@_);
4408 }
4409
4410 sub close_edit {
4411         my $self = shift;
4412         $self->{git_commit_ok} = 1;
4413         $self->{nr} = $self->{gii}->{nr};
4414         delete $self->{gii};
4415         $self->SUPER::close_edit(@_);
4416 }
4417
4418 package SVN::Git::Editor;
4419 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
4420 use strict;
4421 use warnings;
4422 use Carp qw/croak/;
4423 use IO::File;
4424
4425 sub new {
4426         my ($class, $opts) = @_;
4427         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
4428                 die "$_ required!\n" unless (defined $opts->{$_});
4429         }
4430
4431         my $pool = SVN::Pool->new;
4432         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
4433         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
4434                                      $opts->{r}, $mods);
4435
4436         # $opts->{ra} functions should not be used after this:
4437         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
4438                                                 $opts->{editor_cb}, $pool);
4439         my $self = SVN::Delta::Editor->new(@ce, $pool);
4440         bless $self, $class;
4441         foreach (qw/svn_path r tree_a tree_b/) {
4442                 $self->{$_} = $opts->{$_};
4443         }
4444         $self->{url} = $opts->{ra}->{url};
4445         $self->{mods} = $mods;
4446         $self->{types} = $types;
4447         $self->{pool} = $pool;
4448         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
4449         $self->{rm} = { };
4450         $self->{path_prefix} = length $self->{svn_path} ?
4451                                "$self->{svn_path}/" : '';
4452         $self->{config} = $opts->{config};
4453         return $self;
4454 }
4455
4456 sub generate_diff {
4457         my ($tree_a, $tree_b) = @_;
4458         my @diff_tree = qw(diff-tree -z -r);
4459         if ($_cp_similarity) {
4460                 push @diff_tree, "-C$_cp_similarity";
4461         } else {
4462                 push @diff_tree, '-C';
4463         }
4464         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
4465         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
4466         push @diff_tree, $tree_a, $tree_b;
4467         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
4468         local $/ = "\0";
4469         my $state = 'meta';
4470         my @mods;
4471         while (<$diff_fh>) {
4472                 chomp $_; # this gets rid of the trailing "\0"
4473                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
4474                                         ($::sha1)\s($::sha1)\s
4475                                         ([MTCRAD])\d*$/xo) {
4476                         push @mods, {   mode_a => $1, mode_b => $2,
4477                                         sha1_a => $3, sha1_b => $4,
4478                                         chg => $5 };
4479                         if ($5 =~ /^(?:C|R)$/) {
4480                                 $state = 'file_a';
4481                         } else {
4482                                 $state = 'file_b';
4483                         }
4484                 } elsif ($state eq 'file_a') {
4485                         my $x = $mods[$#mods] or croak "Empty array\n";
4486                         if ($x->{chg} !~ /^(?:C|R)$/) {
4487                                 croak "Error parsing $_, $x->{chg}\n";
4488                         }
4489                         $x->{file_a} = $_;
4490                         $state = 'file_b';
4491                 } elsif ($state eq 'file_b') {
4492                         my $x = $mods[$#mods] or croak "Empty array\n";
4493                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
4494                                 croak "Error parsing $_, $x->{chg}\n";
4495                         }
4496                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
4497                                 croak "Error parsing $_, $x->{chg}\n";
4498                         }
4499                         $x->{file_b} = $_;
4500                         $state = 'meta';
4501                 } else {
4502                         croak "Error parsing $_\n";
4503                 }
4504         }
4505         command_close_pipe($diff_fh, $ctx);
4506         \@mods;
4507 }
4508
4509 sub check_diff_paths {
4510         my ($ra, $pfx, $rev, $mods) = @_;
4511         my %types;
4512         $pfx .= '/' if length $pfx;
4513
4514         sub type_diff_paths {
4515                 my ($ra, $types, $path, $rev) = @_;
4516                 my @p = split m#/+#, $path;
4517                 my $c = shift @p;
4518                 unless (defined $types->{$c}) {
4519                         $types->{$c} = $ra->check_path($c, $rev);
4520                 }
4521                 while (@p) {
4522                         $c .= '/' . shift @p;
4523                         next if defined $types->{$c};
4524                         $types->{$c} = $ra->check_path($c, $rev);
4525                 }
4526         }
4527
4528         foreach my $m (@$mods) {
4529                 foreach my $f (qw/file_a file_b/) {
4530                         next unless defined $m->{$f};
4531                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
4532                         if (length $pfx.$dir && ! defined $types{$dir}) {
4533                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
4534                         }
4535                 }
4536         }
4537         \%types;
4538 }
4539
4540 sub split_path {
4541         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
4542 }
4543
4544 sub repo_path {
4545         my ($self, $path) = @_;
4546         if (my $enc = $self->{pathnameencoding}) {
4547                 require Encode;
4548                 Encode::from_to($path, $enc, 'UTF-8');
4549         }
4550         $self->{path_prefix}.(defined $path ? $path : '');
4551 }
4552
4553 sub url_path {
4554         my ($self, $path) = @_;
4555         if ($self->{url} =~ m#^https?://#) {
4556                 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4557         }
4558         $self->{url} . '/' . $self->repo_path($path);
4559 }
4560
4561 sub rmdirs {
4562         my ($self) = @_;
4563         my $rm = $self->{rm};
4564         delete $rm->{''}; # we never delete the url we're tracking
4565         return unless %$rm;
4566
4567         foreach (keys %$rm) {
4568                 my @d = split m#/#, $_;
4569                 my $c = shift @d;
4570                 $rm->{$c} = 1;
4571                 while (@d) {
4572                         $c .= '/' . shift @d;
4573                         $rm->{$c} = 1;
4574                 }
4575         }
4576         delete $rm->{$self->{svn_path}};
4577         delete $rm->{''}; # we never delete the url we're tracking
4578         return unless %$rm;
4579
4580         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4581                                              $self->{tree_b});
4582         local $/ = "\0";
4583         while (<$fh>) {
4584                 chomp;
4585                 my @dn = split m#/#, $_;
4586                 while (pop @dn) {
4587                         delete $rm->{join '/', @dn};
4588                 }
4589                 unless (%$rm) {
4590                         close $fh;
4591                         return;
4592                 }
4593         }
4594         command_close_pipe($fh, $ctx);
4595
4596         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4597         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4598                 $self->close_directory($bat->{$d}, $p);
4599                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4600                 print "\tD+\t$d/\n" unless $::_q;
4601                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4602                 delete $bat->{$d};
4603         }
4604 }
4605
4606 sub open_or_add_dir {
4607         my ($self, $full_path, $baton) = @_;
4608         my $t = $self->{types}->{$full_path};
4609         if (!defined $t) {
4610                 die "$full_path not known in r$self->{r} or we have a bug!\n";
4611         }
4612         {
4613                 no warnings 'once';
4614                 # SVN::Node::none and SVN::Node::file are used only once,
4615                 # so we're shutting up Perl's warnings about them.
4616                 if ($t == $SVN::Node::none) {
4617                         return $self->add_directory($full_path, $baton,
4618                             undef, -1, $self->{pool});
4619                 } elsif ($t == $SVN::Node::dir) {
4620                         return $self->open_directory($full_path, $baton,
4621                             $self->{r}, $self->{pool});
4622                 } # no warnings 'once'
4623                 print STDERR "$full_path already exists in repository at ",
4624                     "r$self->{r} and it is not a directory (",
4625                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4626         } # no warnings 'once'
4627         exit 1;
4628 }
4629
4630 sub ensure_path {
4631         my ($self, $path) = @_;
4632         my $bat = $self->{bat};
4633         my $repo_path = $self->repo_path($path);
4634         return $bat->{''} unless (length $repo_path);
4635         my @p = split m#/+#, $repo_path;
4636         my $c = shift @p;
4637         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4638         while (@p) {
4639                 my $c0 = $c;
4640                 $c .= '/' . shift @p;
4641                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4642         }
4643         return $bat->{$c};
4644 }
4645
4646 # Subroutine to convert a globbing pattern to a regular expression.
4647 # From perl cookbook.
4648 sub glob2pat {
4649         my $globstr = shift;
4650         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4651         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4652         return '^' . $globstr . '$';
4653 }
4654
4655 sub check_autoprop {
4656         my ($self, $pattern, $properties, $file, $fbat) = @_;
4657         # Convert the globbing pattern to a regular expression.
4658         my $regex = glob2pat($pattern);
4659         # Check if the pattern matches the file name.
4660         if($file =~ m/($regex)/) {
4661                 # Parse the list of properties to set.
4662                 my @props = split(/;/, $properties);
4663                 foreach my $prop (@props) {
4664                         # Parse 'name=value' syntax and set the property.
4665                         if ($prop =~ /([^=]+)=(.*)/) {
4666                                 my ($n,$v) = ($1,$2);
4667                                 for ($n, $v) {
4668                                         s/^\s+//; s/\s+$//;
4669                                 }
4670                                 $self->change_file_prop($fbat, $n, $v);
4671                         }
4672                 }
4673         }
4674 }
4675
4676 sub apply_autoprops {
4677         my ($self, $file, $fbat) = @_;
4678         my $conf_t = ${$self->{config}}{'config'};
4679         no warnings 'once';
4680         # Check [miscellany]/enable-auto-props in svn configuration.
4681         if (SVN::_Core::svn_config_get_bool(
4682                 $conf_t,
4683                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4684                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4685                 0)) {
4686                 # Auto-props are enabled.  Enumerate them to look for matches.
4687                 my $callback = sub {
4688                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
4689                 };
4690                 SVN::_Core::svn_config_enumerate(
4691                         $conf_t,
4692                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4693                         $callback);
4694         }
4695 }
4696
4697 sub A {
4698         my ($self, $m) = @_;
4699         my ($dir, $file) = split_path($m->{file_b});
4700         my $pbat = $self->ensure_path($dir);
4701         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4702                                         undef, -1);
4703         print "\tA\t$m->{file_b}\n" unless $::_q;
4704         $self->apply_autoprops($file, $fbat);
4705         $self->chg_file($fbat, $m);
4706         $self->close_file($fbat,undef,$self->{pool});
4707 }
4708
4709 sub C {
4710         my ($self, $m) = @_;
4711         my ($dir, $file) = split_path($m->{file_b});
4712         my $pbat = $self->ensure_path($dir);
4713         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4714                                 $self->url_path($m->{file_a}), $self->{r});
4715         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4716         $self->chg_file($fbat, $m);
4717         $self->close_file($fbat,undef,$self->{pool});
4718 }
4719
4720 sub delete_entry {
4721         my ($self, $path, $pbat) = @_;
4722         my $rpath = $self->repo_path($path);
4723         my ($dir, $file) = split_path($rpath);
4724         $self->{rm}->{$dir} = 1;
4725         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4726 }
4727
4728 sub R {
4729         my ($self, $m) = @_;
4730         my ($dir, $file) = split_path($m->{file_b});
4731         my $pbat = $self->ensure_path($dir);
4732         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4733                                 $self->url_path($m->{file_a}), $self->{r});
4734         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4735         $self->apply_autoprops($file, $fbat);
4736         $self->chg_file($fbat, $m);
4737         $self->close_file($fbat,undef,$self->{pool});
4738
4739         ($dir, $file) = split_path($m->{file_a});
4740         $pbat = $self->ensure_path($dir);
4741         $self->delete_entry($m->{file_a}, $pbat);
4742 }
4743
4744 sub M {
4745         my ($self, $m) = @_;
4746         my ($dir, $file) = split_path($m->{file_b});
4747         my $pbat = $self->ensure_path($dir);
4748         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4749                                 $pbat,$self->{r},$self->{pool});
4750         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4751         $self->chg_file($fbat, $m);
4752         $self->close_file($fbat,undef,$self->{pool});
4753 }
4754
4755 sub T { shift->M(@_) }
4756
4757 sub change_file_prop {
4758         my ($self, $fbat, $pname, $pval) = @_;
4759         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4760 }
4761
4762 sub _chg_file_get_blob ($$$$) {
4763         my ($self, $fbat, $m, $which) = @_;
4764         my $fh = $::_repository->temp_acquire("git_blob_$which");
4765         if ($m->{"mode_$which"} =~ /^120/) {
4766                 print $fh 'link ' or croak $!;
4767                 $self->change_file_prop($fbat,'svn:special','*');
4768         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4769                 $self->change_file_prop($fbat,'svn:special',undef);
4770         }
4771         my $blob = $m->{"sha1_$which"};
4772         return ($fh,) if ($blob =~ /^0{40}$/);
4773         my $size = $::_repository->cat_blob($blob, $fh);
4774         croak "Failed to read object $blob" if ($size < 0);
4775         $fh->flush == 0 or croak $!;
4776         seek $fh, 0, 0 or croak $!;
4777
4778         my $exp = ::md5sum($fh);
4779         seek $fh, 0, 0 or croak $!;
4780         return ($fh, $exp);
4781 }
4782
4783 sub chg_file {
4784         my ($self, $fbat, $m) = @_;
4785         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4786                 $self->change_file_prop($fbat,'svn:executable','*');
4787         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4788                 $self->change_file_prop($fbat,'svn:executable',undef);
4789         }
4790         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4791         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4792         my $pool = SVN::Pool->new;
4793         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4794         if (-s $fh_a) {
4795                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4796                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4797                 if (defined $res) {
4798                         die "Unexpected result from send_txstream: $res\n",
4799                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4800                 }
4801         } else {
4802                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4803                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4804                     if ($got ne $exp_b);
4805         }
4806         Git::temp_release($fh_b, 1);
4807         Git::temp_release($fh_a, 1);
4808         $pool->clear;
4809 }
4810
4811 sub D {
4812         my ($self, $m) = @_;
4813         my ($dir, $file) = split_path($m->{file_b});
4814         my $pbat = $self->ensure_path($dir);
4815         print "\tD\t$m->{file_b}\n" unless $::_q;
4816         $self->delete_entry($m->{file_b}, $pbat);
4817 }
4818
4819 sub close_edit {
4820         my ($self) = @_;
4821         my ($p,$bat) = ($self->{pool}, $self->{bat});
4822         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4823                 next if $_ eq '';
4824                 $self->close_directory($bat->{$_}, $p);
4825         }
4826         $self->close_directory($bat->{''}, $p);
4827         $self->SUPER::close_edit($p);
4828         $p->clear;
4829 }
4830
4831 sub abort_edit {
4832         my ($self) = @_;
4833         $self->SUPER::abort_edit($self->{pool});
4834 }
4835
4836 sub DESTROY {
4837         my $self = shift;
4838         $self->SUPER::DESTROY(@_);
4839         $self->{pool}->clear;
4840 }
4841
4842 # this drives the editor
4843 sub apply_diff {
4844         my ($self) = @_;
4845         my $mods = $self->{mods};
4846         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4847         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4848                 my $f = $m->{chg};
4849                 if (defined $o{$f}) {
4850                         $self->$f($m);
4851                 } else {
4852                         fatal("Invalid change type: $f");
4853                 }
4854         }
4855         $self->rmdirs if $_rmdir;
4856         if (@$mods == 0) {
4857                 $self->abort_edit;
4858         } else {
4859                 $self->close_edit;
4860         }
4861         return scalar @$mods;
4862 }
4863
4864 package Git::SVN::Ra;
4865 use vars qw/@ISA $config_dir $_log_window_size/;
4866 use strict;
4867 use warnings;
4868 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4869
4870 BEGIN {
4871         # enforce temporary pool usage for some simple functions
4872         no strict 'refs';
4873         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4874                       get_file/) {
4875                 my $SUPER = "SUPER::$f";
4876                 *$f = sub {
4877                         my $self = shift;
4878                         my $pool = SVN::Pool->new;
4879                         my @ret = $self->$SUPER(@_,$pool);
4880                         $pool->clear;
4881                         wantarray ? @ret : $ret[0];
4882                 };
4883         }
4884 }
4885
4886 sub _auth_providers () {
4887         [
4888           SVN::Client::get_simple_provider(),
4889           SVN::Client::get_ssl_server_trust_file_provider(),
4890           SVN::Client::get_simple_prompt_provider(
4891             \&Git::SVN::Prompt::simple, 2),
4892           SVN::Client::get_ssl_client_cert_file_provider(),
4893           SVN::Client::get_ssl_client_cert_prompt_provider(
4894             \&Git::SVN::Prompt::ssl_client_cert, 2),
4895           SVN::Client::get_ssl_client_cert_pw_file_provider(),
4896           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4897             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4898           SVN::Client::get_username_provider(),
4899           SVN::Client::get_ssl_server_trust_prompt_provider(
4900             \&Git::SVN::Prompt::ssl_server_trust),
4901           SVN::Client::get_username_prompt_provider(
4902             \&Git::SVN::Prompt::username, 2)
4903         ]
4904 }
4905
4906 sub escape_uri_only {
4907         my ($uri) = @_;
4908         my @tmp;
4909         foreach (split m{/}, $uri) {
4910                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4911                 push @tmp, $_;
4912         }
4913         join('/', @tmp);
4914 }
4915
4916 sub escape_url {
4917         my ($url) = @_;
4918         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4919                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4920                 $url = "$scheme://$domain$uri";
4921         }
4922         $url;
4923 }
4924
4925 sub new {
4926         my ($class, $url) = @_;
4927         $url =~ s!/+$!!;
4928         return $RA if ($RA && $RA->{url} eq $url);
4929
4930         ::_req_svn();
4931
4932         SVN::_Core::svn_config_ensure($config_dir, undef);
4933         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4934         my $config = SVN::Core::config_get_config($config_dir);
4935         $RA = undef;
4936         my $dont_store_passwords = 1;
4937         my $conf_t = ${$config}{'config'};
4938         {
4939                 no warnings 'once';
4940                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4941                 # produces warnings that variables are used only once.
4942                 # I had not found the better way to shut them up, so
4943                 # the warnings of type 'once' are disabled in this block.
4944                 if (SVN::_Core::svn_config_get_bool($conf_t,
4945                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4946                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4947                     1) == 0) {
4948                         SVN::_Core::svn_auth_set_parameter($baton,
4949                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4950                             bless (\$dont_store_passwords, "_p_void"));
4951                 }
4952                 if (SVN::_Core::svn_config_get_bool($conf_t,
4953                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4954                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4955                     1) == 0) {
4956                         $Git::SVN::Prompt::_no_auth_cache = 1;
4957                 }
4958         } # no warnings 'once'
4959         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4960                               config => $config,
4961                               pool => SVN::Pool->new,
4962                               auth_provider_callbacks => $callbacks);
4963         $self->{url} = $url;
4964         $self->{svn_path} = $url;
4965         $self->{repos_root} = $self->get_repos_root;
4966         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4967         $self->{cache} = { check_path => { r => 0, data => {} },
4968                            get_dir => { r => 0, data => {} } };
4969         $RA = bless $self, $class;
4970 }
4971
4972 sub check_path {
4973         my ($self, $path, $r) = @_;
4974         my $cache = $self->{cache}->{check_path};
4975         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4976                 return $cache->{data}->{$path};
4977         }
4978         my $pool = SVN::Pool->new;
4979         my $t = $self->SUPER::check_path($path, $r, $pool);
4980         $pool->clear;
4981         if ($r != $cache->{r}) {
4982                 %{$cache->{data}} = ();
4983                 $cache->{r} = $r;
4984         }
4985         $cache->{data}->{$path} = $t;
4986 }
4987
4988 sub get_dir {
4989         my ($self, $dir, $r) = @_;
4990         my $cache = $self->{cache}->{get_dir};
4991         if ($r == $cache->{r}) {
4992                 if (my $x = $cache->{data}->{$dir}) {
4993                         return wantarray ? @$x : $x->[0];
4994                 }
4995         }
4996         my $pool = SVN::Pool->new;
4997         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4998         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4999         $pool->clear;
5000         if ($r != $cache->{r}) {
5001                 %{$cache->{data}} = ();
5002                 $cache->{r} = $r;
5003         }
5004         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
5005         wantarray ? (\%dirents, $r, $props) : \%dirents;
5006 }
5007
5008 sub DESTROY {
5009         # do not call the real DESTROY since we store ourselves in $RA
5010 }
5011
5012 # get_log(paths, start, end, limit,
5013 #         discover_changed_paths, strict_node_history, receiver)
5014 sub get_log {
5015         my ($self, @args) = @_;
5016         my $pool = SVN::Pool->new;
5017
5018         # svn_log_changed_path_t objects passed to get_log are likely to be
5019         # overwritten even if only the refs are copied to an external variable,
5020         # so we should dup the structures in their entirety.  Using an
5021         # externally passed pool (instead of our temporary and quickly cleared
5022         # pool in Git::SVN::Ra) does not help matters at all...
5023         my $receiver = pop @args;
5024         my $prefix = "/".$self->{svn_path};
5025         $prefix =~ s#/+($)##;
5026         my $prefix_regex = qr#^\Q$prefix\E#;
5027         push(@args, sub {
5028                 my ($paths) = $_[0];
5029                 return &$receiver(@_) unless $paths;
5030                 $_[0] = ();
5031                 foreach my $p (keys %$paths) {
5032                         my $i = $paths->{$p};
5033                         # Make path relative to our url, not repos_root
5034                         $p =~ s/$prefix_regex//;
5035                         my %s = map { $_ => $i->$_; }
5036                                 qw/copyfrom_path copyfrom_rev action/;
5037                         if ($s{'copyfrom_path'}) {
5038                                 $s{'copyfrom_path'} =~ s/$prefix_regex//;
5039                         }
5040                         $_[0]{$p} = \%s;
5041                 }
5042                 &$receiver(@_);
5043         });
5044
5045
5046         # the limit parameter was not supported in SVN 1.1.x, so we
5047         # drop it.  Therefore, the receiver callback passed to it
5048         # is made aware of this limitation by being wrapped if
5049         # the limit passed to is being wrapped.
5050         if ($SVN::Core::VERSION le '1.2.0') {
5051                 my $limit = splice(@args, 3, 1);
5052                 if ($limit > 0) {
5053                         my $receiver = pop @args;
5054                         push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
5055                 }
5056         }
5057         my $ret = $self->SUPER::get_log(@args, $pool);
5058         $pool->clear;
5059         $ret;
5060 }
5061
5062 sub trees_match {
5063         my ($self, $url1, $rev1, $url2, $rev2) = @_;
5064         my $ctx = SVN::Client->new(auth => _auth_providers);
5065         my $out = IO::File->new_tmpfile;
5066
5067         # older SVN (1.1.x) doesn't take $pool as the last parameter for
5068         # $ctx->diff(), so we'll create a default one
5069         my $pool = SVN::Pool->new_default_sub;
5070
5071         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
5072         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
5073         $out->flush;
5074         my $ret = (($out->stat)[7] == 0);
5075         close $out or croak $!;
5076
5077         $ret;
5078 }
5079
5080 sub get_commit_editor {
5081         my ($self, $log, $cb, $pool) = @_;
5082         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
5083         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
5084 }
5085
5086 sub gs_do_update {
5087         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
5088         my $new = ($rev_a == $rev_b);
5089         my $path = $gs->{path};
5090
5091         if ($new && -e $gs->{index}) {
5092                 unlink $gs->{index} or die
5093                   "Couldn't unlink index: $gs->{index}: $!\n";
5094         }
5095         my $pool = SVN::Pool->new;
5096         $editor->set_path_strip($path);
5097         my (@pc) = split m#/#, $path;
5098         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
5099                                         1, $editor, $pool);
5100         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5101
5102         # Since we can't rely on svn_ra_reparent being available, we'll
5103         # just have to do some magic with set_path to make it so
5104         # we only want a partial path.
5105         my $sp = '';
5106         my $final = join('/', @pc);
5107         while (@pc) {
5108                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
5109                 $sp .= '/' if length $sp;
5110                 $sp .= shift @pc;
5111         }
5112         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
5113
5114         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
5115
5116         $reporter->finish_report($pool);
5117         $pool->clear;
5118         $editor->{git_commit_ok};
5119 }
5120
5121 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
5122 # svn_ra_reparent didn't work before 1.4)
5123 sub gs_do_switch {
5124         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
5125         my $path = $gs->{path};
5126         my $pool = SVN::Pool->new;
5127
5128         my $full_url = $self->{url};
5129         my $old_url = $full_url;
5130         $full_url .= '/' . $path if length $path;
5131         my ($ra, $reparented);
5132
5133         if ($old_url =~ m#^svn(\+ssh)?://# ||
5134             ($full_url =~ m#^https?://# &&
5135              escape_url($full_url) ne $full_url)) {
5136                 $_[0] = undef;
5137                 $self = undef;
5138                 $RA = undef;
5139                 $ra = Git::SVN::Ra->new($full_url);
5140                 $ra_invalid = 1;
5141         } elsif ($old_url ne $full_url) {
5142                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
5143                 $self->{url} = $full_url;
5144                 $reparented = 1;
5145         }
5146
5147         $ra ||= $self;
5148         $url_b = escape_url($url_b);
5149         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
5150         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5151         $reporter->set_path('', $rev_a, 0, @lock, $pool);
5152         $reporter->finish_report($pool);
5153
5154         if ($reparented) {
5155                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
5156                 $self->{url} = $old_url;
5157         }
5158
5159         $pool->clear;
5160         $editor->{git_commit_ok};
5161 }
5162
5163 sub longest_common_path {
5164         my ($gsv, $globs) = @_;
5165         my %common;
5166         my $common_max = scalar @$gsv;
5167
5168         foreach my $gs (@$gsv) {
5169                 my @tmp = split m#/#, $gs->{path};
5170                 my $p = '';
5171                 foreach (@tmp) {
5172                         $p .= length($p) ? "/$_" : $_;
5173                         $common{$p} ||= 0;
5174                         $common{$p}++;
5175                 }
5176         }
5177         $globs ||= [];
5178         $common_max += scalar @$globs;
5179         foreach my $glob (@$globs) {
5180                 my @tmp = split m#/#, $glob->{path}->{left};
5181                 my $p = '';
5182                 foreach (@tmp) {
5183                         $p .= length($p) ? "/$_" : $_;
5184                         $common{$p} ||= 0;
5185                         $common{$p}++;
5186                 }
5187         }
5188
5189         my $longest_path = '';
5190         foreach (sort {length $b <=> length $a} keys %common) {
5191                 if ($common{$_} == $common_max) {
5192                         $longest_path = $_;
5193                         last;
5194                 }
5195         }
5196         $longest_path;
5197 }
5198
5199 sub gs_fetch_loop_common {
5200         my ($self, $base, $head, $gsv, $globs) = @_;
5201         return if ($base > $head);
5202         my $inc = $_log_window_size;
5203         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
5204         my $longest_path = longest_common_path($gsv, $globs);
5205         my $ra_url = $self->{url};
5206         my $find_trailing_edge;
5207         while (1) {
5208                 my %revs;
5209                 my $err;
5210                 my $err_handler = $SVN::Error::handler;
5211                 $SVN::Error::handler = sub {
5212                         ($err) = @_;
5213                         skip_unknown_revs($err);
5214                 };
5215                 sub _cb {
5216                         my ($paths, $r, $author, $date, $log) = @_;
5217                         [ $paths,
5218                           { author => $author, date => $date, log => $log } ];
5219                 }
5220                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
5221                                sub { $revs{$_[1]} = _cb(@_) });
5222                 if ($err) {
5223                         print "Checked through r$max\r";
5224                 } else {
5225                         $find_trailing_edge = 1;
5226                 }
5227                 if ($err and $find_trailing_edge) {
5228                         print STDERR "Path '$longest_path' ",
5229                                      "was probably deleted:\n",
5230                                      $err->expanded_message,
5231                                      "\nWill attempt to follow ",
5232                                      "revisions r$min .. r$max ",
5233                                      "committed before the deletion\n";
5234                         my $hi = $max;
5235                         while (--$hi >= $min) {
5236                                 my $ok;
5237                                 $self->get_log([$longest_path], $min, $hi,
5238                                                0, 1, 1, sub {
5239                                                $ok = $_[1];
5240                                                $revs{$_[1]} = _cb(@_) });
5241                                 if ($ok) {
5242                                         print STDERR "r$min .. r$ok OK\n";
5243                                         last;
5244                                 }
5245                         }
5246                         $find_trailing_edge = 0;
5247                 }
5248                 $SVN::Error::handler = $err_handler;
5249
5250                 my %exists = map { $_->{path} => $_ } @$gsv;
5251                 foreach my $r (sort {$a <=> $b} keys %revs) {
5252                         my ($paths, $logged) = @{$revs{$r}};
5253
5254                         foreach my $gs ($self->match_globs(\%exists, $paths,
5255                                                            $globs, $r)) {
5256                                 if ($gs->rev_map_max >= $r) {
5257                                         next;
5258                                 }
5259                                 next unless $gs->match_paths($paths, $r);
5260                                 $gs->{logged_rev_props} = $logged;
5261                                 if (my $last_commit = $gs->last_commit) {
5262                                         $gs->assert_index_clean($last_commit);
5263                                 }
5264                                 my $log_entry = $gs->do_fetch($paths, $r);
5265                                 if ($log_entry) {
5266                                         $gs->do_git_commit($log_entry);
5267                                 }
5268                                 $INDEX_FILES{$gs->{index}} = 1;
5269                         }
5270                         foreach my $g (@$globs) {
5271                                 my $k = "svn-remote.$g->{remote}." .
5272                                         "$g->{t}-maxRev";
5273                                 Git::SVN::tmp_config($k, $r);
5274                         }
5275                         if ($ra_invalid) {
5276                                 $_[0] = undef;
5277                                 $self = undef;
5278                                 $RA = undef;
5279                                 $self = Git::SVN::Ra->new($ra_url);
5280                                 $ra_invalid = undef;
5281                         }
5282                 }
5283                 # pre-fill the .rev_db since it'll eventually get filled in
5284                 # with '0' x40 if something new gets committed
5285                 foreach my $gs (@$gsv) {
5286                         next if $gs->rev_map_max >= $max;
5287                         next if defined $gs->rev_map_get($max);
5288                         $gs->rev_map_set($max, 0 x40);
5289                 }
5290                 foreach my $g (@$globs) {
5291                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
5292                         Git::SVN::tmp_config($k, $max);
5293                 }
5294                 last if $max >= $head;
5295                 $min = $max + 1;
5296                 $max += $inc;
5297                 $max = $head if ($max > $head);
5298         }
5299         Git::SVN::gc();
5300 }
5301
5302 sub get_dir_globbed {
5303         my ($self, $left, $depth, $r) = @_;
5304
5305         my @x = eval { $self->get_dir($left, $r) };
5306         return unless scalar @x == 3;
5307         my $dirents = $x[0];
5308         my @finalents;
5309         foreach my $de (keys %$dirents) {
5310                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
5311                 if ($depth > 1) {
5312                         my @args = ("$left/$de", $depth - 1, $r);
5313                         foreach my $dir ($self->get_dir_globbed(@args)) {
5314                                 push @finalents, "$de/$dir";
5315                         }
5316                 } else {
5317                         push @finalents, $de;
5318                 }
5319         }
5320         @finalents;
5321 }
5322
5323 sub match_globs {
5324         my ($self, $exists, $paths, $globs, $r) = @_;
5325
5326         sub get_dir_check {
5327                 my ($self, $exists, $g, $r) = @_;
5328
5329                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
5330                                                   $g->{path}->{depth},
5331                                                   $r);
5332
5333                 foreach my $de (@dirs) {
5334                         my $p = $g->{path}->full_path($de);
5335                         next if $exists->{$p};
5336                         next if (length $g->{path}->{right} &&
5337                                  ($self->check_path($p, $r) !=
5338                                   $SVN::Node::dir));
5339                         next unless $p =~ /$g->{path}->{regex}/;
5340                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
5341                                          $g->{ref}->full_path($de), 1);
5342                 }
5343         }
5344         foreach my $g (@$globs) {
5345                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
5346                         if ($path->{action} =~ /^[AR]$/) {
5347                                 get_dir_check($self, $exists, $g, $r);
5348                         }
5349                 }
5350                 foreach (keys %$paths) {
5351                         if (/$g->{path}->{left_regex}/ &&
5352                             !/$g->{path}->{regex}/) {
5353                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
5354                                 get_dir_check($self, $exists, $g, $r);
5355                         }
5356                         next unless /$g->{path}->{regex}/;
5357                         my $p = $1;
5358                         my $pathname = $g->{path}->full_path($p);
5359                         next if $exists->{$pathname};
5360                         next if ($self->check_path($pathname, $r) !=
5361                                  $SVN::Node::dir);
5362                         $exists->{$pathname} = Git::SVN->init(
5363                                               $self->{url}, $pathname, undef,
5364                                               $g->{ref}->full_path($p), 1);
5365                 }
5366                 my $c = '';
5367                 foreach (split m#/#, $g->{path}->{left}) {
5368                         $c .= "/$_";
5369                         next unless ($paths->{$c} &&
5370                                      ($paths->{$c}->{action} =~ /^[AR]$/));
5371                         get_dir_check($self, $exists, $g, $r);
5372                 }
5373         }
5374         values %$exists;
5375 }
5376
5377 sub minimize_url {
5378         my ($self) = @_;
5379         return $self->{url} if ($self->{url} eq $self->{repos_root});
5380         my $url = $self->{repos_root};
5381         my @components = split(m!/!, $self->{svn_path});
5382         my $c = '';
5383         do {
5384                 $url .= "/$c" if length $c;
5385                 eval {
5386                         my $ra = (ref $self)->new($url);
5387                         my $latest = $ra->get_latest_revnum;
5388                         $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
5389                 };
5390         } while ($@ && ($c = shift @components));
5391         $url;
5392 }
5393
5394 sub can_do_switch {
5395         my $self = shift;
5396         unless (defined $can_do_switch) {
5397                 my $pool = SVN::Pool->new;
5398                 my $rep = eval {
5399                         $self->do_switch(1, '', 0, $self->{url},
5400                                          SVN::Delta::Editor->new, $pool);
5401                 };
5402                 if ($@) {
5403                         $can_do_switch = 0;
5404                 } else {
5405                         $rep->abort_report($pool);
5406                         $can_do_switch = 1;
5407                 }
5408                 $pool->clear;
5409         }
5410         $can_do_switch;
5411 }
5412
5413 sub skip_unknown_revs {
5414         my ($err) = @_;
5415         my $errno = $err->apr_err();
5416         # Maybe the branch we're tracking didn't
5417         # exist when the repo started, so it's
5418         # not an error if it doesn't, just continue
5419         #
5420         # Wonderfully consistent library, eh?
5421         # 160013 - svn:// and file://
5422         # 175002 - http(s)://
5423         # 175007 - http(s):// (this repo required authorization, too...)
5424         #   More codes may be discovered later...
5425         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
5426                 my $err_key = $err->expanded_message;
5427                 # revision numbers change every time, filter them out
5428                 $err_key =~ s/\d+/\0/g;
5429                 $err_key = "$errno\0$err_key";
5430                 unless ($ignored_err{$err_key}) {
5431                         warn "W: Ignoring error from SVN, path probably ",
5432                              "does not exist: ($errno): ",
5433                              $err->expanded_message,"\n";
5434                         warn "W: Do not be alarmed at the above message ",
5435                              "git-svn is just searching aggressively for ",
5436                              "old history.\n",
5437                              "This may take a while on large repositories\n";
5438                         $ignored_err{$err_key} = 1;
5439                 }
5440                 return;
5441         }
5442         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
5443 }
5444
5445 package Git::SVN::Log;
5446 use strict;
5447 use warnings;
5448 use POSIX qw/strftime/;
5449 use Time::Local;
5450 use constant commit_log_separator => ('-' x 72) . "\n";
5451 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
5452             %rusers $show_commit $incremental/;
5453 my $l_fmt;
5454
5455 sub cmt_showable {
5456         my ($c) = @_;
5457         return 1 if defined $c->{r};
5458
5459         # big commit message got truncated by the 16k pretty buffer in rev-list
5460         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
5461                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
5462                 @{$c->{l}} = ();
5463                 my @log = command(qw/cat-file commit/, $c->{c});
5464
5465                 # shift off the headers
5466                 shift @log while ($log[0] ne '');
5467                 shift @log;
5468
5469                 # TODO: make $c->{l} not have a trailing newline in the future
5470                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
5471
5472                 (undef, $c->{r}, undef) = ::extract_metadata(
5473                                 (grep(/^git-svn-id: /, @log))[-1]);
5474         }
5475         return defined $c->{r};
5476 }
5477
5478 sub log_use_color {
5479         return $color || Git->repository->get_colorbool('color.diff');
5480 }
5481
5482 sub git_svn_log_cmd {
5483         my ($r_min, $r_max, @args) = @_;
5484         my $head = 'HEAD';
5485         my (@files, @log_opts);
5486         foreach my $x (@args) {
5487                 if ($x eq '--' || @files) {
5488                         push @files, $x;
5489                 } else {
5490                         if (::verify_ref("$x^0")) {
5491                                 $head = $x;
5492                         } else {
5493                                 push @log_opts, $x;
5494                         }
5495                 }
5496         }
5497
5498         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
5499         $gs ||= Git::SVN->_new;
5500         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
5501                    $gs->refname);
5502         push @cmd, '-r' unless $non_recursive;
5503         push @cmd, qw/--raw --name-status/ if $verbose;
5504         push @cmd, '--color' if log_use_color();
5505         push @cmd, @log_opts;
5506         if (defined $r_max && $r_max == $r_min) {
5507                 push @cmd, '--max-count=1';
5508                 if (my $c = $gs->rev_map_get($r_max)) {
5509                         push @cmd, $c;
5510                 }
5511         } elsif (defined $r_max) {
5512                 if ($r_max < $r_min) {
5513                         ($r_min, $r_max) = ($r_max, $r_min);
5514                 }
5515                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
5516                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
5517                 # If there are no commits in the range, both $c_max and $c_min
5518                 # will be undefined.  If there is at least 1 commit in the
5519                 # range, both will be defined.
5520                 return () if !defined $c_min || !defined $c_max;
5521                 if ($c_min eq $c_max) {
5522                         push @cmd, '--max-count=1', $c_min;
5523                 } else {
5524                         push @cmd, '--boundary', "$c_min..$c_max";
5525                 }
5526         }
5527         return (@cmd, @files);
5528 }
5529
5530 # adapted from pager.c
5531 sub config_pager {
5532         if (! -t *STDOUT) {
5533                 $ENV{GIT_PAGER_IN_USE} = 'false';
5534                 $pager = undef;
5535                 return;
5536         }
5537         chomp($pager = command_oneline(qw(var GIT_PAGER)));
5538         if ($pager eq 'cat') {
5539                 $pager = undef;
5540         }
5541         $ENV{GIT_PAGER_IN_USE} = defined($pager);
5542 }
5543
5544 sub run_pager {
5545         return unless defined $pager;
5546         pipe my ($rfd, $wfd) or return;
5547         defined(my $pid = fork) or ::fatal "Can't fork: $!";
5548         if (!$pid) {
5549                 open STDOUT, '>&', $wfd or
5550                                      ::fatal "Can't redirect to stdout: $!";
5551                 return;
5552         }
5553         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5554         $ENV{LESS} ||= 'FRSX';
5555         exec $pager or ::fatal "Can't run pager: $! ($pager)";
5556 }
5557
5558 sub format_svn_date {
5559         # some systmes don't handle or mishandle %z, so be creative.
5560         my $t = shift || time;
5561         my $gm = timelocal(gmtime($t));
5562         my $sign = qw( + + - )[ $t <=> $gm ];
5563         my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5564         return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5565 }
5566
5567 sub parse_git_date {
5568         my ($t, $tz) = @_;
5569         # Date::Parse isn't in the standard Perl distro :(
5570         if ($tz =~ s/^\+//) {
5571                 $t += tz_to_s_offset($tz);
5572         } elsif ($tz =~ s/^\-//) {
5573                 $t -= tz_to_s_offset($tz);
5574         }
5575         return $t;
5576 }
5577
5578 sub set_local_timezone {
5579         if (defined $TZ) {
5580                 $ENV{TZ} = $TZ;
5581         } else {
5582                 delete $ENV{TZ};
5583         }
5584 }
5585
5586 sub tz_to_s_offset {
5587         my ($tz) = @_;
5588         $tz =~ s/(\d\d)$//;
5589         return ($1 * 60) + ($tz * 3600);
5590 }
5591
5592 sub get_author_info {
5593         my ($dest, $author, $t, $tz) = @_;
5594         $author =~ s/(?:^\s*|\s*$)//g;
5595         $dest->{a_raw} = $author;
5596         my $au;
5597         if ($::_authors) {
5598                 $au = $rusers{$author} || undef;
5599         }
5600         if (!$au) {
5601                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5602         }
5603         $dest->{t} = $t;
5604         $dest->{tz} = $tz;
5605         $dest->{a} = $au;
5606         $dest->{t_utc} = parse_git_date($t, $tz);
5607 }
5608
5609 sub process_commit {
5610         my ($c, $r_min, $r_max, $defer) = @_;
5611         if (defined $r_min && defined $r_max) {
5612                 if ($r_min == $c->{r} && $r_min == $r_max) {
5613                         show_commit($c);
5614                         return 0;
5615                 }
5616                 return 1 if $r_min == $r_max;
5617                 if ($r_min < $r_max) {
5618                         # we need to reverse the print order
5619                         return 0 if (defined $limit && --$limit < 0);
5620                         push @$defer, $c;
5621                         return 1;
5622                 }
5623                 if ($r_min != $r_max) {
5624                         return 1 if ($r_min < $c->{r});
5625                         return 1 if ($r_max > $c->{r});
5626                 }
5627         }
5628         return 0 if (defined $limit && --$limit < 0);
5629         show_commit($c);
5630         return 1;
5631 }
5632
5633 sub show_commit {
5634         my $c = shift;
5635         if ($oneline) {
5636                 my $x = "\n";
5637                 if (my $l = $c->{l}) {
5638                         while ($l->[0] =~ /^\s*$/) { shift @$l }
5639                         $x = $l->[0];
5640                 }
5641                 $l_fmt ||= 'A' . length($c->{r});
5642                 print 'r',pack($l_fmt, $c->{r}),' | ';
5643                 print "$c->{c} | " if $show_commit;
5644                 print $x;
5645         } else {
5646                 show_commit_normal($c);
5647         }
5648 }
5649
5650 sub show_commit_changed_paths {
5651         my ($c) = @_;
5652         return unless $c->{changed};
5653         print "Changed paths:\n", @{$c->{changed}};
5654 }
5655
5656 sub show_commit_normal {
5657         my ($c) = @_;
5658         print commit_log_separator, "r$c->{r} | ";
5659         print "$c->{c} | " if $show_commit;
5660         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5661         my $nr_line = 0;
5662
5663         if (my $l = $c->{l}) {
5664                 while ($l->[$#$l] eq "\n" && $#$l > 0
5665                                           && $l->[($#$l - 1)] eq "\n") {
5666                         pop @$l;
5667                 }
5668                 $nr_line = scalar @$l;
5669                 if (!$nr_line) {
5670                         print "1 line\n\n\n";
5671                 } else {
5672                         if ($nr_line == 1) {
5673                                 $nr_line = '1 line';
5674                         } else {
5675                                 $nr_line .= ' lines';
5676                         }
5677                         print $nr_line, "\n";
5678                         show_commit_changed_paths($c);
5679                         print "\n";
5680                         print $_ foreach @$l;
5681                 }
5682         } else {
5683                 print "1 line\n";
5684                 show_commit_changed_paths($c);
5685                 print "\n";
5686
5687         }
5688         foreach my $x (qw/raw stat diff/) {
5689                 if ($c->{$x}) {
5690                         print "\n";
5691                         print $_ foreach @{$c->{$x}}
5692                 }
5693         }
5694 }
5695
5696 sub cmd_show_log {
5697         my (@args) = @_;
5698         my ($r_min, $r_max);
5699         my $r_last = -1; # prevent dupes
5700         set_local_timezone();
5701         if (defined $::_revision) {
5702                 if ($::_revision =~ /^(\d+):(\d+)$/) {
5703                         ($r_min, $r_max) = ($1, $2);
5704                 } elsif ($::_revision =~ /^\d+$/) {
5705                         $r_min = $r_max = $::_revision;
5706                 } else {
5707                         ::fatal "-r$::_revision is not supported, use ",
5708                                 "standard 'git log' arguments instead";
5709                 }
5710         }
5711
5712         config_pager();
5713         @args = git_svn_log_cmd($r_min, $r_max, @args);
5714         if (!@args) {
5715                 print commit_log_separator unless $incremental || $oneline;
5716                 return;
5717         }
5718         my $log = command_output_pipe(@args);
5719         run_pager();
5720         my (@k, $c, $d, $stat);
5721         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5722         while (<$log>) {
5723                 if (/^${esc_color}commit -?($::sha1_short)/o) {
5724                         my $cmt = $1;
5725                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5726                                 $r_last = $c->{r};
5727                                 process_commit($c, $r_min, $r_max, \@k) or
5728                                                                 goto out;
5729                         }
5730                         $d = undef;
5731                         $c = { c => $cmt };
5732                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5733                         get_author_info($c, $1, $2, $3);
5734                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5735                         # ignore
5736                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5737                         push @{$c->{raw}}, $_;
5738                 } elsif (/^${esc_color}[ACRMDT]\t/) {
5739                         # we could add $SVN->{svn_path} here, but that requires
5740                         # remote access at the moment (repo_path_split)...
5741                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
5742                         push @{$c->{changed}}, $_;
5743                 } elsif (/^${esc_color}diff /o) {
5744                         $d = 1;
5745                         push @{$c->{diff}}, $_;
5746                 } elsif ($d) {
5747                         push @{$c->{diff}}, $_;
5748                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5749                           $esc_color*[\+\-]*$esc_color$/x) {
5750                         $stat = 1;
5751                         push @{$c->{stat}}, $_;
5752                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5753                         push @{$c->{stat}}, $_;
5754                         $stat = undef;
5755                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
5756                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5757                 } elsif (s/^${esc_color}    //o) {
5758                         push @{$c->{l}}, $_;
5759                 }
5760         }
5761         if ($c && defined $c->{r} && $c->{r} != $r_last) {
5762                 $r_last = $c->{r};
5763                 process_commit($c, $r_min, $r_max, \@k);
5764         }
5765         if (@k) {
5766                 ($r_min, $r_max) = ($r_max, $r_min);
5767                 process_commit($_, $r_min, $r_max) foreach reverse @k;
5768         }
5769 out:
5770         close $log;
5771         print commit_log_separator unless $incremental || $oneline;
5772 }
5773
5774 sub cmd_blame {
5775         my $path = pop;
5776
5777         config_pager();
5778         run_pager();
5779
5780         my ($fh, $ctx, $rev);
5781
5782         if ($_git_format) {
5783                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5784                 while (my $line = <$fh>) {
5785                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5786                                 # Uncommitted edits show up as a rev ID of
5787                                 # all zeros, which we can't look up with
5788                                 # cmt_metadata
5789                                 if ($1 !~ /^0+$/) {
5790                                         (undef, $rev, undef) =
5791                                                 ::cmt_metadata($1);
5792                                         $rev = '0' if (!$rev);
5793                                 } else {
5794                                         $rev = '0';
5795                                 }
5796                                 $rev = sprintf('%-10s', $rev);
5797                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5798                         }
5799                         print $line;
5800                 }
5801         } else {
5802                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5803                                                   '--', $path);
5804                 my ($sha1);
5805                 my %authors;
5806                 my @buffer;
5807                 my %dsha; #distinct sha keys
5808
5809                 while (my $line = <$fh>) {
5810                         push @buffer, $line;
5811                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5812                                 $dsha{$1} = 1;
5813                         }
5814                 }
5815
5816                 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5817
5818                 foreach my $line (@buffer) {
5819                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5820                                 $rev = $s2r->{$1};
5821                                 $rev = '0' if (!$rev)
5822                         }
5823                         elsif ($line =~ /^author (.*)/) {
5824                                 $authors{$rev} = $1;
5825                                 $authors{$rev} =~ s/\s/_/g;
5826                         }
5827                         elsif ($line =~ /^\t(.*)$/) {
5828                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5829                         }
5830                 }
5831         }
5832         command_close_pipe($fh, $ctx);
5833 }
5834
5835 package Git::SVN::Migration;
5836 # these version numbers do NOT correspond to actual version numbers
5837 # of git nor git-svn.  They are just relative.
5838 #
5839 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5840 #
5841 # v1 layout: .git/$id/info/url, refs/remotes/$id
5842 #
5843 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5844 #
5845 # v3 layout: .git/svn/$id, refs/remotes/$id
5846 #            - info/url may remain for backwards compatibility
5847 #            - this is what we migrate up to this layout automatically,
5848 #            - this will be used by git svn init on single branches
5849 # v3.1 layout (auto migrated):
5850 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5851 #              for backwards compatibility
5852 #
5853 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5854 #            - this is only created for newly multi-init-ed
5855 #              repositories.  Similar in spirit to the
5856 #              --use-separate-remotes option in git-clone (now default)
5857 #            - we do not automatically migrate to this (following
5858 #              the example set by core git)
5859 #
5860 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5861 #            - newer, more-efficient format that uses 24-bytes per record
5862 #              with no filler space.
5863 #            - use xxd -c24 < .rev_map.$UUID to view and debug
5864 #            - This is a one-way migration, repositories updated to the
5865 #              new format will not be able to use old git-svn without
5866 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
5867 #              possible if noMetadata or useSvmProps are set; but should
5868 #              be no problem for users that use the (sensible) defaults.
5869 use strict;
5870 use warnings;
5871 use Carp qw/croak/;
5872 use File::Path qw/mkpath/;
5873 use File::Basename qw/dirname basename/;
5874 use vars qw/$_minimize/;
5875
5876 sub migrate_from_v0 {
5877         my $git_dir = $ENV{GIT_DIR};
5878         return undef unless -d $git_dir;
5879         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5880         my $migrated = 0;
5881         while (<$fh>) {
5882                 chomp;
5883                 my ($id, $orig_ref) = ($_, $_);
5884                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5885                 next unless -f "$git_dir/$id/info/url";
5886                 my $new_ref = "refs/remotes/$id";
5887                 if (::verify_ref("$new_ref^0")) {
5888                         print STDERR "W: $orig_ref is probably an old ",
5889                                      "branch used by an ancient version of ",
5890                                      "git-svn.\n",
5891                                      "However, $new_ref also exists.\n",
5892                                      "We will not be able ",
5893                                      "to use this branch until this ",
5894                                      "ambiguity is resolved.\n";
5895                         next;
5896                 }
5897                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5898                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5899                 command_noisy('update-ref', $new_ref, $orig_ref);
5900                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5901                 $migrated++;
5902         }
5903         command_close_pipe($fh, $ctx);
5904         print STDERR "Done migrating from v0 layout...\n" if $migrated;
5905         $migrated;
5906 }
5907
5908 sub migrate_from_v1 {
5909         my $git_dir = $ENV{GIT_DIR};
5910         my $migrated = 0;
5911         return $migrated unless -d $git_dir;
5912         my $svn_dir = "$git_dir/svn";
5913
5914         # just in case somebody used 'svn' as their $id at some point...
5915         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5916
5917         print STDERR "Migrating from a git-svn v1 layout...\n";
5918         mkpath([$svn_dir]);
5919         print STDERR "Data from a previous version of git-svn exists, but\n\t",
5920                      "$svn_dir\n\t(required for this version ",
5921                      "($::VERSION) of git-svn) does not exist.\n";
5922         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5923         while (<$fh>) {
5924                 my $x = $_;
5925                 next unless $x =~ s#^refs/remotes/##;
5926                 chomp $x;
5927                 next unless -f "$git_dir/$x/info/url";
5928                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5929                 next unless $u;
5930                 my $dn = dirname("$git_dir/svn/$x");
5931                 mkpath([$dn]) unless -d $dn;
5932                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5933                         mkpath(["$git_dir/svn/svn"]);
5934                         print STDERR " - $git_dir/$x/info => ",
5935                                         "$git_dir/svn/$x/info\n";
5936                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5937                                croak "$!: $x";
5938                         # don't worry too much about these, they probably
5939                         # don't exist with repos this old (save for index,
5940                         # and we can easily regenerate that)
5941                         foreach my $f (qw/unhandled.log index .rev_db/) {
5942                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5943                         }
5944                 } else {
5945                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5946                         rename "$git_dir/$x", "$git_dir/svn/$x" or
5947                                croak "$!: $x";
5948                 }
5949                 $migrated++;
5950         }
5951         command_close_pipe($fh, $ctx);
5952         print STDERR "Done migrating from a git-svn v1 layout\n";
5953         $migrated;
5954 }
5955
5956 sub read_old_urls {
5957         my ($l_map, $pfx, $path) = @_;
5958         my @dir;
5959         foreach (<$path/*>) {
5960                 if (-r "$_/info/url") {
5961                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5962                         my $ref_id = $pfx . basename $_;
5963                         my $url = ::file_to_s("$_/info/url");
5964                         $l_map->{$ref_id} = $url;
5965                 } elsif (-d $_) {
5966                         push @dir, $_;
5967                 }
5968         }
5969         foreach (@dir) {
5970                 my $x = $_;
5971                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5972                 read_old_urls($l_map, $x, $_);
5973         }
5974 }
5975
5976 sub migrate_from_v2 {
5977         my @cfg = command(qw/config -l/);
5978         return if grep /^svn-remote\..+\.url=/, @cfg;
5979         my %l_map;
5980         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5981         my $migrated = 0;
5982
5983         foreach my $ref_id (sort keys %l_map) {
5984                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5985                 if ($@) {
5986                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5987                 }
5988                 $migrated++;
5989         }
5990         $migrated;
5991 }
5992
5993 sub minimize_connections {
5994         my $r = Git::SVN::read_all_remotes();
5995         my $new_urls = {};
5996         my $root_repos = {};
5997         foreach my $repo_id (keys %$r) {
5998                 my $url = $r->{$repo_id}->{url} or next;
5999                 my $fetch = $r->{$repo_id}->{fetch} or next;
6000                 my $ra = Git::SVN::Ra->new($url);
6001
6002                 # skip existing cases where we already connect to the root
6003                 if (($ra->{url} eq $ra->{repos_root}) ||
6004                     ($ra->{repos_root} eq $repo_id)) {
6005                         $root_repos->{$ra->{url}} = $repo_id;
6006                         next;
6007                 }
6008
6009                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
6010                 my $root_path = $ra->{url};
6011                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
6012                 foreach my $path (keys %$fetch) {
6013                         my $ref_id = $fetch->{$path};
6014                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
6015
6016                         # make sure we can read when connecting to
6017                         # a higher level of a repository
6018                         my ($last_rev, undef) = $gs->last_rev_commit;
6019                         if (!defined $last_rev) {
6020                                 $last_rev = eval {
6021                                         $root_ra->get_latest_revnum;
6022                                 };
6023                                 next if $@;
6024                         }
6025                         my $new = $root_path;
6026                         $new .= length $path ? "/$path" : '';
6027                         eval {
6028                                 $root_ra->get_log([$new], $last_rev, $last_rev,
6029                                                   0, 0, 1, sub { });
6030                         };
6031                         next if $@;
6032                         $new_urls->{$ra->{repos_root}}->{$new} =
6033                                 { ref_id => $ref_id,
6034                                   old_repo_id => $repo_id,
6035                                   old_path => $path };
6036                 }
6037         }
6038
6039         my @emptied;
6040         foreach my $url (keys %$new_urls) {
6041                 # see if we can re-use an existing [svn-remote "repo_id"]
6042                 # instead of creating a(n ugly) new section:
6043                 my $repo_id = $root_repos->{$url} || $url;
6044
6045                 my $fetch = $new_urls->{$url};
6046                 foreach my $path (keys %$fetch) {
6047                         my $x = $fetch->{$path};
6048                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
6049                         my $pfx = "svn-remote.$x->{old_repo_id}";
6050
6051                         my $old_fetch = quotemeta("$x->{old_path}:".
6052                                                   "$x->{ref_id}");
6053                         command_noisy(qw/config --unset/,
6054                                       "$pfx.fetch", '^'. $old_fetch . '$');
6055                         delete $r->{$x->{old_repo_id}}->
6056                                {fetch}->{$x->{old_path}};
6057                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
6058                                 command_noisy(qw/config --unset/,
6059                                               "$pfx.url");
6060                                 push @emptied, $x->{old_repo_id}
6061                         }
6062                 }
6063         }
6064         if (@emptied) {
6065                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
6066                 print STDERR <<EOF;
6067 The following [svn-remote] sections in your config file ($file) are empty
6068 and can be safely removed:
6069 EOF
6070                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
6071         }
6072 }
6073
6074 sub migration_check {
6075         migrate_from_v0();
6076         migrate_from_v1();
6077         migrate_from_v2();
6078         minimize_connections() if $_minimize;
6079 }
6080
6081 package Git::IndexInfo;
6082 use strict;
6083 use warnings;
6084 use Git qw/command_input_pipe command_close_pipe/;
6085
6086 sub new {
6087         my ($class) = @_;
6088         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
6089         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
6090 }
6091
6092 sub remove {
6093         my ($self, $path) = @_;
6094         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
6095                 return ++$self->{nr};
6096         }
6097         undef;
6098 }
6099
6100 sub update {
6101         my ($self, $mode, $hash, $path) = @_;
6102         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
6103                 return ++$self->{nr};
6104         }
6105         undef;
6106 }
6107
6108 sub DESTROY {
6109         my ($self) = @_;
6110         command_close_pipe($self->{gui}, $self->{ctx});
6111 }
6112
6113 package Git::SVN::GlobSpec;
6114 use strict;
6115 use warnings;
6116
6117 sub new {
6118         my ($class, $glob, $pattern_ok) = @_;
6119         my $re = $glob;
6120         $re =~ s!/+$!!g; # no need for trailing slashes
6121         my (@left, @right, @patterns);
6122         my $state = "left";
6123         my $die_msg = "Only one set of wildcard directories " .
6124                                 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
6125         for my $part (split(m|/|, $glob)) {
6126                 if ($part =~ /\*/ && $part ne "*") {
6127                         die "Invalid pattern in '$glob': $part\n";
6128                 } elsif ($pattern_ok && $part =~ /[{}]/ &&
6129                          $part !~ /^\{[^{}]+\}/) {
6130                         die "Invalid pattern in '$glob': $part\n";
6131                 }
6132                 if ($part eq "*") {
6133                         die $die_msg if $state eq "right";
6134                         $state = "pattern";
6135                         push(@patterns, "[^/]*");
6136                 } elsif ($pattern_ok && $part =~ /^\{(.*)\}$/) {
6137                         die $die_msg if $state eq "right";
6138                         $state = "pattern";
6139                         my $p = quotemeta($1);
6140                         $p =~ s/\\,/|/g;
6141                         push(@patterns, "(?:$p)");
6142                 } else {
6143                         if ($state eq "left") {
6144                                 push(@left, $part);
6145                         } else {
6146                                 push(@right, $part);
6147                                 $state = "right";
6148                         }
6149                 }
6150         }
6151         my $depth = @patterns;
6152         if ($depth == 0) {
6153                 die "One '*' is needed in glob: '$glob'\n";
6154         }
6155         my $left = join('/', @left);
6156         my $right = join('/', @right);
6157         $re = join('/', @patterns);
6158         $re = join('\/',
6159                    grep(length, quotemeta($left), "($re)", quotemeta($right)));
6160         my $left_re = qr/^\/\Q$left\E(\/|$)/;
6161         bless { left => $left, right => $right, left_regex => $left_re,
6162                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
6163 }
6164
6165 sub full_path {
6166         my ($self, $path) = @_;
6167         return (length $self->{left} ? "$self->{left}/" : '') .
6168                $path . (length $self->{right} ? "/$self->{right}" : '');
6169 }
6170
6171 __END__
6172
6173 Data structures:
6174
6175
6176 $remotes = { # returned by read_all_remotes()
6177         'svn' => {
6178                 # svn-remote.svn.url=https://svn.musicpd.org
6179                 url => 'https://svn.musicpd.org',
6180                 # svn-remote.svn.fetch=mpd/trunk:trunk
6181                 fetch => {
6182                         'mpd/trunk' => 'trunk',
6183                 },
6184                 # svn-remote.svn.tags=mpd/tags/*:tags/*
6185                 tags => {
6186                         path => {
6187                                 left => 'mpd/tags',
6188                                 right => '',
6189                                 regex => qr!mpd/tags/([^/]+)$!,
6190                                 glob => 'tags/*',
6191                         },
6192                         ref => {
6193                                 left => 'tags',
6194                                 right => '',
6195                                 regex => qr!tags/([^/]+)$!,
6196                                 glob => 'tags/*',
6197                         },
6198                 }
6199         }
6200 };
6201
6202 $log_entry hashref as returned by libsvn_log_entry()
6203 {
6204         log => 'whitespace-formatted log entry
6205 ',                                              # trailing newline is preserved
6206         revision => '8',                        # integer
6207         date => '2004-02-24T17:01:44.108345Z',  # commit date
6208         author => 'committer name'
6209 };
6210
6211
6212 # this is generated by generate_diff();
6213 @mods = array of diff-index line hashes, each element represents one line
6214         of diff-index output
6215
6216 diff-index line ($m hash)
6217 {
6218         mode_a => first column of diff-index output, no leading ':',
6219         mode_b => second column of diff-index output,
6220         sha1_b => sha1sum of the final blob,
6221         chg => change type [MCRADT],
6222         file_a => original file name of a file (iff chg is 'C' or 'R')
6223         file_b => new/current file name of a file (any chg)
6224 }
6225 ;
6226
6227 # retval of read_url_paths{,_all}();
6228 $l_map = {
6229         # repository root url
6230         'https://svn.musicpd.org' => {
6231                 # repository path               # GIT_SVN_ID
6232                 'mpd/trunk'             =>      'trunk',
6233                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
6234         },
6235 }
6236
6237 Notes:
6238         I don't trust the each() function on unless I created %hash myself
6239         because the internal iterator may not have started at base.