git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  72     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  73     --[no-]suppress-from           * Send to self. Default off.
  74     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  75     --[no-]thread                  * Use In-Reply-To: field. Default on.
  76
  77   Administering:
  78     --confirm               <str>  * Confirm recipients before sending;
  79                                      auto, cc, compose, always, or never.
  80     --quiet                        * Output one line of info per email.
  81     --dry-run                      * Don't actually send the emails.
  82     --[no-]validate                * Perform patch sanity checks. Default on.
  83     --[no-]format-patch            * understand any non optional arguments as
  84                                      `git format-patch` ones.
  85
  86 EOT
  87         exit(1);
  88 }
  89
  90 # most mail servers generate the Date: header, but not all...
  91 sub format_2822_time {
  92         my ($time) = @_;
  93         my @localtm = localtime($time);
  94         my @gmttm = gmtime($time);
  95         my $localmin = $localtm[1] + $localtm[2] * 60;
  96         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  97         if ($localtm[0] != $gmttm[0]) {
  98                 die "local zone differs from GMT by a non-minute interval\n";
  99         }
 100         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 101                 $localmin += 1440;
 102         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 103                 $localmin -= 1440;
 104         } elsif ($gmttm[6] != $localtm[6]) {
 105                 die "local time offset greater than or equal to 24 hours\n";
 106         }
 107         my $offset = $localmin - $gmtmin;
 108         my $offhour = $offset / 60;
 109         my $offmin = abs($offset % 60);
 110         if (abs($offhour) >= 24) {
 111                 die ("local time offset greater than or equal to 24 hours\n");
 112         }
 113
 114         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 115                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 116                        $localtm[3],
 117                        qw(Jan Feb Mar Apr May Jun
 118                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 119                        $localtm[5]+1900,
 120                        $localtm[2],
 121                        $localtm[1],
 122                        $localtm[0],
 123                        ($offset >= 0) ? '+' : '-',
 124                        abs($offhour),
 125                        $offmin,
 126                        );
 127 }
 128
 129 my $have_email_valid = eval { require Email::Valid; 1 };
 130 my $have_mail_address = eval { require Mail::Address; 1 };
 131 my $smtp;
 132 my $auth;
 133
 134 sub unique_email_list(@);
 135 sub cleanup_compose_files();
 136
 137 # Variables we fill in automatically, or via prompting:
 138 my (@to,@cc,@initial_cc,@bcclist,@xh,
 139         $initial_reply_to,$initial_subject,@files,
 140         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 141
 142 my $envelope_sender;
 143
 144 # Example reply to:
 145 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 146
 147 my $repo = eval { Git->repository() };
 148 my @repo = $repo ? ($repo) : ();
 149 my $term = eval {
 150         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 151                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 152                 : new Term::ReadLine 'git-send-email';
 153 };
 154 if ($@) {
 155         $term = new FakeTerm "$@: going non-interactive";
 156 }
 157
 158 # Behavior modification variables
 159 my ($quiet, $dry_run) = (0, 0);
 160 my $format_patch;
 161 my $compose_filename;
 162
 163 # Handle interactive edition of files.
 164 my $multiedit;
 165 my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 166 sub do_edit {
 167         if (defined($multiedit) && !$multiedit) {
 168                 map {
 169                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 170                         if (($? & 127) || ($? >> 8)) {
 171                                 die("the editor exited uncleanly, aborting everything");
 172                         }
 173                 } @_;
 174         } else {
 175                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 176                 if (($? & 127) || ($? >> 8)) {
 177                         die("the editor exited uncleanly, aborting everything");
 178                 }
 179         }
 180 }
 181
 182 # Variables with corresponding config settings
 183 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 184 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 185 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 186 my ($validate, $confirm);
 187 my (@suppress_cc);
 188
 189 my %config_bool_settings = (
 190     "thread" => [\$thread, 1],
 191     "chainreplyto" => [\$chain_reply_to, 1],
 192     "suppressfrom" => [\$suppress_from, undef],
 193     "signedoffbycc" => [\$signed_off_by_cc, undef],
 194     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 195     "validate" => [\$validate, 1],
 196 );
 197
 198 my %config_settings = (
 199     "smtpserver" => \$smtp_server,
 200     "smtpserverport" => \$smtp_server_port,
 201     "smtpuser" => \$smtp_authuser,
 202     "smtppass" => \$smtp_authpass,
 203     "to" => \@to,
 204     "cc" => \@initial_cc,
 205     "cccmd" => \$cc_cmd,
 206     "aliasfiletype" => \$aliasfiletype,
 207     "bcc" => \@bcclist,
 208     "aliasesfile" => \@alias_files,
 209     "suppresscc" => \@suppress_cc,
 210     "envelopesender" => \$envelope_sender,
 211     "multiedit" => \$multiedit,
 212     "confirm"   => \$confirm,
 213 );
 214
 215 # Handle Uncouth Termination
 216 sub signal_handler {
 217
 218         # Make text normal
 219         print color("reset"), "\n";
 220
 221         # SMTP password masked
 222         system "stty echo";
 223
 224         # tmp files from --compose
 225         if (defined $compose_filename) {
 226                 if (-e $compose_filename) {
 227                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 228                 }
 229                 if (-e ($compose_filename . ".final")) {
 230                         print "'$compose_filename.final' contains the composed email.\n"
 231                 }
 232         }
 233
 234         exit;
 235 };
 236
 237 $SIG{TERM} = \&signal_handler;
 238 $SIG{INT}  = \&signal_handler;
 239
 240 # Begin by accumulating all the variables (defined above), that we will end up
 241 # needing, first, from the command line:
 242
 243 my $rc = GetOptions("sender|from=s" => \$sender,
 244                     "in-reply-to=s" => \$initial_reply_to,
 245                     "subject=s" => \$initial_subject,
 246                     "to=s" => \@to,
 247                     "cc=s" => \@initial_cc,
 248                     "bcc=s" => \@bcclist,
 249                     "chain-reply-to!" => \$chain_reply_to,
 250                     "smtp-server=s" => \$smtp_server,
 251                     "smtp-server-port=s" => \$smtp_server_port,
 252                     "smtp-user=s" => \$smtp_authuser,
 253                     "smtp-pass:s" => \$smtp_authpass,
 254                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 255                     "smtp-encryption=s" => \$smtp_encryption,
 256                     "identity=s" => \$identity,
 257                     "annotate" => \$annotate,
 258                     "compose" => \$compose,
 259                     "quiet" => \$quiet,
 260                     "cc-cmd=s" => \$cc_cmd,
 261                     "suppress-from!" => \$suppress_from,
 262                     "suppress-cc=s" => \@suppress_cc,
 263                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 264                     "confirm=s" => \$confirm,
 265                     "dry-run" => \$dry_run,
 266                     "envelope-sender=s" => \$envelope_sender,
 267                     "thread!" => \$thread,
 268                     "validate!" => \$validate,
 269                     "format-patch!" => \$format_patch,
 270          );
 271
 272 unless ($rc) {
 273     usage();
 274 }
 275
 276 die "Cannot run git format-patch from outside a repository\n"
 277         if $format_patch and not $repo;
 278
 279 # Now, let's fill any that aren't set in with defaults:
 280
 281 sub read_config {
 282         my ($prefix) = @_;
 283
 284         foreach my $setting (keys %config_bool_settings) {
 285                 my $target = $config_bool_settings{$setting}->[0];
 286                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 287         }
 288
 289         foreach my $setting (keys %config_settings) {
 290                 my $target = $config_settings{$setting};
 291                 if (ref($target) eq "ARRAY") {
 292                         unless (@$target) {
 293                                 my @values = Git::config(@repo, "$prefix.$setting");
 294                                 @$target = @values if (@values && defined $values[0]);
 295                         }
 296                 }
 297                 else {
 298                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 299                 }
 300         }
 301
 302         if (!defined $smtp_encryption) {
 303                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 304                 if (defined $enc) {
 305                         $smtp_encryption = $enc;
 306                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 307                         $smtp_encryption = 'ssl';
 308                 }
 309         }
 310 }
 311
 312 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 313 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 314 read_config("sendemail.$identity") if (defined $identity);
 315 read_config("sendemail");
 316
 317 # fall back on builtin bool defaults
 318 foreach my $setting (values %config_bool_settings) {
 319         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 320 }
 321
 322 # 'default' encryption is none -- this only prevents a warning
 323 $smtp_encryption = '' unless (defined $smtp_encryption);
 324
 325 # Set CC suppressions
 326 my(%suppress_cc);
 327 if (@suppress_cc) {
 328         foreach my $entry (@suppress_cc) {
 329                 die "Unknown --suppress-cc field: '$entry'\n"
 330                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 331                 $suppress_cc{$entry} = 1;
 332         }
 333 }
 334
 335 if ($suppress_cc{'all'}) {
 336         foreach my $entry (qw (ccmd cc author self sob body bodycc)) {
 337                 $suppress_cc{$entry} = 1;
 338         }
 339         delete $suppress_cc{'all'};
 340 }
 341
 342 # If explicit old-style ones are specified, they trump --suppress-cc.
 343 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 344 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 345
 346 if ($suppress_cc{'body'}) {
 347         foreach my $entry (qw (sob bodycc)) {
 348                 $suppress_cc{$entry} = 1;
 349         }
 350         delete $suppress_cc{'body'};
 351 }
 352
 353 # Set confirm's default value
 354 my $confirm_unconfigured = !defined $confirm;
 355 if ($confirm_unconfigured) {
 356         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 357 };
 358 die "Unknown --confirm setting: '$confirm'\n"
 359         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 360
 361 # Debugging, print out the suppressions.
 362 if (0) {
 363         print "suppressions:\n";
 364         foreach my $entry (keys %suppress_cc) {
 365                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 366         }
 367 }
 368
 369 my ($repoauthor, $repocommitter);
 370 ($repoauthor) = Git::ident_person(@repo, 'author');
 371 ($repocommitter) = Git::ident_person(@repo, 'committer');
 372
 373 # Verify the user input
 374
 375 foreach my $entry (@to) {
 376         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 377 }
 378
 379 foreach my $entry (@initial_cc) {
 380         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 381 }
 382
 383 foreach my $entry (@bcclist) {
 384         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 385 }
 386
 387 sub parse_address_line {
 388         if ($have_mail_address) {
 389                 return map { $_->format } Mail::Address->parse($_[0]);
 390         } else {
 391                 return split_addrs($_[0]);
 392         }
 393 }
 394
 395 sub split_addrs {
 396         return quotewords('\s*,\s*', 1, @_);
 397 }
 398
 399 my %aliases;
 400 my %parse_alias = (
 401         # multiline formats can be supported in the future
 402         mutt => sub { my $fh = shift; while (<$fh>) {
 403                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 404                         my ($alias, $addr) = ($1, $2);
 405                         $addr =~ s/#.*$//; # mutt allows # comments
 406                          # commas delimit multiple addresses
 407                         $aliases{$alias} = [ split_addrs($addr) ];
 408                 }}},
 409         mailrc => sub { my $fh = shift; while (<$fh>) {
 410                 if (/^alias\s+(\S+)\s+(.*)$/) {
 411                         # spaces delimit multiple addresses
 412                         $aliases{$1} = [ split(/\s+/, $2) ];
 413                 }}},
 414         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 415                 for (my $x = ''; defined($x); $x = $_) {
 416                         chomp $x;
 417                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 418                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 419                         $aliases{$1} = [ split_addrs($2) ];
 420                 }},
 421         gnus => sub { my $fh = shift; while (<$fh>) {
 422                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 423                         $aliases{$1} = [ $2 ];
 424                 }}}
 425 );
 426
 427 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 428         foreach my $file (@alias_files) {
 429                 open my $fh, '<', $file or die "opening $file: $!\n";
 430                 $parse_alias{$aliasfiletype}->($fh);
 431                 close $fh;
 432         }
 433 }
 434
 435 ($sender) = expand_aliases($sender) if defined $sender;
 436
 437 # returns 1 if the conflict must be solved using it as a format-patch argument
 438 sub check_file_rev_conflict($) {
 439         return unless $repo;
 440         my $f = shift;
 441         try {
 442                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 443                 if (defined($format_patch)) {
 444                         print "foo\n";
 445                         return $format_patch;
 446                 }
 447                 die(<<EOF);
 448 File '$f' exists but it could also be the range of commits
 449 to produce patches for.  Please disambiguate by...
 450
 451     * Saying "./$f" if you mean a file; or
 452     * Giving --format-patch option if you mean a range.
 453 EOF
 454         } catch Git::Error::Command with {
 455                 return 0;
 456         }
 457 }
 458
 459 # Now that all the defaults are set, process the rest of the command line
 460 # arguments and collect up the files that need to be processed.
 461 my @rev_list_opts;
 462 while (defined(my $f = shift @ARGV)) {
 463         if ($f eq "--") {
 464                 push @rev_list_opts, "--", @ARGV;
 465                 @ARGV = ();
 466         } elsif (-d $f and !check_file_rev_conflict($f)) {
 467                 opendir(DH,$f)
 468                         or die "Failed to opendir $f: $!";
 469
 470                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 471                                 sort readdir(DH);
 472                 closedir(DH);
 473         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 474                 push @files, $f;
 475         } else {
 476                 push @rev_list_opts, $f;
 477         }
 478 }
 479
 480 if (@rev_list_opts) {
 481         die "Cannot run git format-patch from outside a repository\n"
 482                 unless $repo;
 483         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 484 }
 485
 486 if ($validate) {
 487         foreach my $f (@files) {
 488                 unless (-p $f) {
 489                         my $error = validate_patch($f);
 490                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 491                 }
 492         }
 493 }
 494
 495 if (@files) {
 496         unless ($quiet) {
 497                 print $_,"\n" for (@files);
 498         }
 499 } else {
 500         print STDERR "\nNo patch files specified!\n\n";
 501         usage();
 502 }
 503
 504 sub get_patch_subject($) {
 505         my $fn = shift;
 506         open (my $fh, '<', $fn);
 507         while (my $line = <$fh>) {
 508                 next unless ($line =~ /^Subject: (.*)$/);
 509                 close $fh;
 510                 return "GIT: $1\n";
 511         }
 512         close $fh;
 513         die "No subject line in $fn ?";
 514 }
 515
 516 if ($compose) {
 517         # Note that this does not need to be secure, but we will make a small
 518         # effort to have it be unique
 519         $compose_filename = ($repo ?
 520                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 521                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 522         open(C,">",$compose_filename)
 523                 or die "Failed to open for writing $compose_filename: $!";
 524
 525
 526         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 527         my $tpl_subject = $initial_subject || '';
 528         my $tpl_reply_to = $initial_reply_to || '';
 529
 530         print C <<EOT;
 531 From $tpl_sender # This line is ignored.
 532 GIT: Lines beginning in "GIT:" will be removed.
 533 GIT: Consider including an overall diffstat or table of contents
 534 GIT: for the patch you are writing.
 535 GIT:
 536 GIT: Clear the body content if you don't wish to send a summary.
 537 From: $tpl_sender
 538 Subject: $tpl_subject
 539 In-Reply-To: $tpl_reply_to
 540
 541 EOT
 542         for my $f (@files) {
 543                 print C get_patch_subject($f);
 544         }
 545         close(C);
 546
 547         if ($annotate) {
 548                 do_edit($compose_filename, @files);
 549         } else {
 550                 do_edit($compose_filename);
 551         }
 552
 553         open(C2,">",$compose_filename . ".final")
 554                 or die "Failed to open $compose_filename.final : " . $!;
 555
 556         open(C,"<",$compose_filename)
 557                 or die "Failed to open $compose_filename : " . $!;
 558
 559         my $need_8bit_cte = file_has_nonascii($compose_filename);
 560         my $in_body = 0;
 561         my $summary_empty = 1;
 562         while(<C>) {
 563                 next if m/^GIT:/;
 564                 if ($in_body) {
 565                         $summary_empty = 0 unless (/^\n$/);
 566                 } elsif (/^\n$/) {
 567                         $in_body = 1;
 568                         if ($need_8bit_cte) {
 569                                 print C2 "MIME-Version: 1.0\n",
 570                                          "Content-Type: text/plain; ",
 571                                            "charset=utf-8\n",
 572                                          "Content-Transfer-Encoding: 8bit\n";
 573                         }
 574                 } elsif (/^MIME-Version:/i) {
 575                         $need_8bit_cte = 0;
 576                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 577                         $initial_subject = $1;
 578                         my $subject = $initial_subject;
 579                         $_ = "Subject: " .
 580                                 ($subject =~ /[^[:ascii:]]/ ?
 581                                  quote_rfc2047($subject) :
 582                                  $subject) .
 583                                 "\n";
 584                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 585                         $initial_reply_to = $1;
 586                         next;
 587                 } elsif (/^From:\s*(.+)\s*$/i) {
 588                         $sender = $1;
 589                         next;
 590                 } elsif (/^(?:To|Cc|Bcc):/i) {
 591                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 592                         next;
 593                 }
 594                 print C2 $_;
 595         }
 596         close(C);
 597         close(C2);
 598
 599         if ($summary_empty) {
 600                 print "Summary email is empty, skipping it\n";
 601                 $compose = -1;
 602         }
 603 } elsif ($annotate) {
 604         do_edit(@files);
 605 }
 606
 607 sub ask {
 608         my ($prompt, %arg) = @_;
 609         my $valid_re = $arg{valid_re};
 610         my $default = $arg{default};
 611         my $resp;
 612         my $i = 0;
 613         return defined $default ? $default : undef
 614                 unless defined $term->IN and defined fileno($term->IN) and
 615                        defined $term->OUT and defined fileno($term->OUT);
 616         while ($i++ < 10) {
 617                 $resp = $term->readline($prompt);
 618                 if (!defined $resp) { # EOF
 619                         print "\n";
 620                         return defined $default ? $default : undef;
 621                 }
 622                 if ($resp eq '' and defined $default) {
 623                         return $default;
 624                 }
 625                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 626                         return $resp;
 627                 }
 628         }
 629         return undef;
 630 }
 631
 632 my $prompting = 0;
 633 if (!defined $sender) {
 634         $sender = $repoauthor || $repocommitter || '';
 635         $sender = ask("Who should the emails appear to be from? [$sender] ",
 636                       default => $sender);
 637         print "Emails will be sent from: ", $sender, "\n";
 638         $prompting++;
 639 }
 640
 641 if (!@to) {
 642         my $to = ask("Who should the emails be sent to? ");
 643         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 644         $prompting++;
 645 }
 646
 647 sub expand_aliases {
 648         my @cur = @_;
 649         my @last;
 650         do {
 651                 @last = @cur;
 652                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 653         } while (join(',',@cur) ne join(',',@last));
 654         return @cur;
 655 }
 656
 657 @to = expand_aliases(@to);
 658 @to = (map { sanitize_address($_) } @to);
 659 @initial_cc = expand_aliases(@initial_cc);
 660 @bcclist = expand_aliases(@bcclist);
 661
 662 if ($thread && !defined $initial_reply_to && $prompting) {
 663         $initial_reply_to = ask(
 664                 "Message-ID to be used as In-Reply-To for the first email? ");
 665 }
 666 if (defined $initial_reply_to) {
 667         $initial_reply_to =~ s/^\s*<?//;
 668         $initial_reply_to =~ s/>?\s*$//;
 669         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 670 }
 671
 672 if (!defined $smtp_server) {
 673         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 674                 if (-x $_) {
 675                         $smtp_server = $_;
 676                         last;
 677                 }
 678         }
 679         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 680 }
 681
 682 if ($compose && $compose > 0) {
 683         @files = ($compose_filename . ".final", @files);
 684 }
 685
 686 # Variables we set as part of the loop over files
 687 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 688         $needs_confirm, $message_num, $ask_default);
 689
 690 sub extract_valid_address {
 691         my $address = shift;
 692         my $local_part_regexp = '[^<>"\s@]+';
 693         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 694
 695         # check for a local address:
 696         return $address if ($address =~ /^($local_part_regexp)$/);
 697
 698         $address =~ s/^\s*<(.*)>\s*$/$1/;
 699         if ($have_email_valid) {
 700                 return scalar Email::Valid->address($address);
 701         } else {
 702                 # less robust/correct than the monster regexp in Email::Valid,
 703                 # but still does a 99% job, and one less dependency
 704                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 705                 return $1;
 706         }
 707 }
 708
 709 # Usually don't need to change anything below here.
 710
 711 # we make a "fake" message id by taking the current number
 712 # of seconds since the beginning of Unix time and tacking on
 713 # a random number to the end, in case we are called quicker than
 714 # 1 second since the last time we were called.
 715
 716 # We'll setup a template for the message id, using the "from" address:
 717
 718 my ($message_id_stamp, $message_id_serial);
 719 sub make_message_id
 720 {
 721         my $uniq;
 722         if (!defined $message_id_stamp) {
 723                 $message_id_stamp = sprintf("%s-%s", time, $$);
 724                 $message_id_serial = 0;
 725         }
 726         $message_id_serial++;
 727         $uniq = "$message_id_stamp-$message_id_serial";
 728
 729         my $du_part;
 730         for ($sender, $repocommitter, $repoauthor) {
 731                 $du_part = extract_valid_address(sanitize_address($_));
 732                 last if (defined $du_part and $du_part ne '');
 733         }
 734         if (not defined $du_part or $du_part eq '') {
 735                 use Sys::Hostname qw();
 736                 $du_part = 'user@' . Sys::Hostname::hostname();
 737         }
 738         my $message_id_template = "<%s-git-send-email-%s>";
 739         $message_id = sprintf($message_id_template, $uniq, $du_part);
 740         #print "new message id = $message_id\n"; # Was useful for debugging
 741 }
 742
 743
 744
 745 $time = time - scalar $#files;
 746
 747 sub unquote_rfc2047 {
 748         local ($_) = @_;
 749         my $encoding;
 750         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 751                 $encoding = $1;
 752                 s/_/ /g;
 753                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 754         }
 755         return wantarray ? ($_, $encoding) : $_;
 756 }
 757
 758 sub quote_rfc2047 {
 759         local $_ = shift;
 760         my $encoding = shift || 'utf-8';
 761         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 762         s/(.*)/=\?$encoding\?q\?$1\?=/;
 763         return $_;
 764 }
 765
 766 # use the simplest quoting being able to handle the recipient
 767 sub sanitize_address
 768 {
 769         my ($recipient) = @_;
 770         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 771
 772         if (not $recipient_name) {
 773                 return "$recipient";
 774         }
 775
 776         # if recipient_name is already quoted, do nothing
 777         if ($recipient_name =~ /^("[[:ascii:]]*"|=\?utf-8\?q\?.*\?=)$/) {
 778                 return $recipient;
 779         }
 780
 781         # rfc2047 is needed if a non-ascii char is included
 782         if ($recipient_name =~ /[^[:ascii:]]/) {
 783                 $recipient_name =~ s/^"(.*)"$/$1/;
 784                 $recipient_name = quote_rfc2047($recipient_name);
 785         }
 786
 787         # double quotes are needed if specials or CTLs are included
 788         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 789                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 790                 $recipient_name = "\"$recipient_name\"";
 791         }
 792
 793         return "$recipient_name $recipient_addr";
 794
 795 }
 796
 797 # Returns 1 if the message was sent, and 0 otherwise.
 798 # In actuality, the whole program dies when a there
 799 # is an error sending a message.
 800
 801 sub send_message
 802 {
 803         my @recipients = unique_email_list(@to);
 804         @cc = (grep { my $cc = extract_valid_address($_);
 805                       not grep { $cc eq $_ } @recipients
 806                     }
 807                map { sanitize_address($_) }
 808                @cc);
 809         my $to = join (",\n\t", @recipients);
 810         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 811         @recipients = (map { extract_valid_address($_) } @recipients);
 812         my $date = format_2822_time($time++);
 813         my $gitversion = '@@GIT_VERSION@@';
 814         if ($gitversion =~ m/..GIT_VERSION../) {
 815             $gitversion = Git::version();
 816         }
 817
 818         my $cc = join(", ", unique_email_list(@cc));
 819         my $ccline = "";
 820         if ($cc ne '') {
 821                 $ccline = "\nCc: $cc";
 822         }
 823         my $sanitized_sender = sanitize_address($sender);
 824         make_message_id() unless defined($message_id);
 825
 826         my $header = "From: $sanitized_sender
 827 To: $to${ccline}
 828 Subject: $subject
 829 Date: $date
 830 Message-Id: $message_id
 831 X-Mailer: git-send-email $gitversion
 832 ";
 833         if ($reply_to) {
 834
 835                 $header .= "In-Reply-To: $reply_to\n";
 836                 $header .= "References: $references\n";
 837         }
 838         if (@xh) {
 839                 $header .= join("\n", @xh) . "\n";
 840         }
 841
 842         my @sendmail_parameters = ('-i', @recipients);
 843         my $raw_from = $sanitized_sender;
 844         $raw_from = $envelope_sender if (defined $envelope_sender);
 845         $raw_from = extract_valid_address($raw_from);
 846         unshift (@sendmail_parameters,
 847                         '-f', $raw_from) if(defined $envelope_sender);
 848
 849         if ($needs_confirm && !$dry_run) {
 850                 print "\n$header\n";
 851                 if ($needs_confirm eq "inform") {
 852                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 853                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 854                         print "    The Cc list above has been expanded by additional\n";
 855                         print "    addresses found in the patch commit message. By default\n";
 856                         print "    send-email prompts before sending whenever this occurs.\n";
 857                         print "    This behavior is controlled by the sendemail.confirm\n";
 858                         print "    configuration setting.\n";
 859                         print "\n";
 860                         print "    For additional information, run 'git send-email --help'.\n";
 861                         print "    To retain the current behavior, but squelch this message,\n";
 862                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 863                 }
 864                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 865                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 866                          default => $ask_default);
 867                 die "Send this email reply required" unless defined $_;
 868                 if (/^n/i) {
 869                         return 0;
 870                 } elsif (/^q/i) {
 871                         cleanup_compose_files();
 872                         exit(0);
 873                 } elsif (/^a/i) {
 874                         $confirm = 'never';
 875                 }
 876         }
 877
 878         if ($dry_run) {
 879                 # We don't want to send the email.
 880         } elsif ($smtp_server =~ m#^/#) {
 881                 my $pid = open my $sm, '|-';
 882                 defined $pid or die $!;
 883                 if (!$pid) {
 884                         exec($smtp_server, @sendmail_parameters) or die $!;
 885                 }
 886                 print $sm "$header\n$message";
 887                 close $sm or die $?;
 888         } else {
 889
 890                 if (!defined $smtp_server) {
 891                         die "The required SMTP server is not properly defined."
 892                 }
 893
 894                 if ($smtp_encryption eq 'ssl') {
 895                         $smtp_server_port ||= 465; # ssmtp
 896                         require Net::SMTP::SSL;
 897                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 898                 }
 899                 else {
 900                         require Net::SMTP;
 901                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 902                                                  ? "$smtp_server:$smtp_server_port"
 903                                                  : $smtp_server);
 904                         if ($smtp_encryption eq 'tls') {
 905                                 require Net::SMTP::SSL;
 906                                 $smtp->command('STARTTLS');
 907                                 $smtp->response();
 908                                 if ($smtp->code == 220) {
 909                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 910                                                 or die "STARTTLS failed! ".$smtp->message;
 911                                         $smtp_encryption = '';
 912                                         # Send EHLO again to receive fresh
 913                                         # supported commands
 914                                         $smtp->hello();
 915                                 } else {
 916                                         die "Server does not support STARTTLS! ".$smtp->message;
 917                                 }
 918                         }
 919                 }
 920
 921                 if (!$smtp) {
 922                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 923                 }
 924
 925                 if (defined $smtp_authuser) {
 926
 927                         if (!defined $smtp_authpass) {
 928
 929                                 system "stty -echo";
 930
 931                                 do {
 932                                         print "Password: ";
 933                                         $_ = <STDIN>;
 934                                         print "\n";
 935                                 } while (!defined $_);
 936
 937                                 chomp($smtp_authpass = $_);
 938
 939                                 system "stty echo";
 940                         }
 941
 942                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 943                 }
 944
 945                 $smtp->mail( $raw_from ) or die $smtp->message;
 946                 $smtp->to( @recipients ) or die $smtp->message;
 947                 $smtp->data or die $smtp->message;
 948                 $smtp->datasend("$header\n$message") or die $smtp->message;
 949                 $smtp->dataend() or die $smtp->message;
 950                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
 951         }
 952         if ($quiet) {
 953                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 954         } else {
 955                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 956                 if ($smtp_server !~ m#^/#) {
 957                         print "Server: $smtp_server\n";
 958                         print "MAIL FROM:<$raw_from>\n";
 959                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 960                 } else {
 961                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 962                 }
 963                 print $header, "\n";
 964                 if ($smtp) {
 965                         print "Result: ", $smtp->code, ' ',
 966                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 967                 } else {
 968                         print "Result: OK\n";
 969                 }
 970         }
 971
 972         return 1;
 973 }
 974
 975 $reply_to = $initial_reply_to;
 976 $references = $initial_reply_to || '';
 977 $subject = $initial_subject;
 978 $message_num = 0;
 979
 980 foreach my $t (@files) {
 981         open(F,"<",$t) or die "can't open file $t";
 982
 983         my $author = undef;
 984         my $author_encoding;
 985         my $has_content_type;
 986         my $body_encoding;
 987         @cc = ();
 988         @xh = ();
 989         my $input_format = undef;
 990         my @header = ();
 991         $message = "";
 992         $message_num++;
 993         # First unfold multiline header fields
 994         while(<F>) {
 995                 last if /^\s*$/;
 996                 if (/^\s+\S/ and @header) {
 997                         chomp($header[$#header]);
 998                         s/^\s+/ /;
 999                         $header[$#header] .= $_;
1000             } else {
1001                         push(@header, $_);
1002                 }
1003         }
1004         # Now parse the header
1005         foreach(@header) {
1006                 if (/^From /) {
1007                         $input_format = 'mbox';
1008                         next;
1009                 }
1010                 chomp;
1011                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1012                         $input_format = 'mbox';
1013                 }
1014
1015                 if (defined $input_format && $input_format eq 'mbox') {
1016                         if (/^Subject:\s+(.*)$/) {
1017                                 $subject = $1;
1018                         }
1019                         elsif (/^From:\s+(.*)$/) {
1020                                 ($author, $author_encoding) = unquote_rfc2047($1);
1021                                 next if $suppress_cc{'author'};
1022                                 next if $suppress_cc{'self'} and $author eq $sender;
1023                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1024                                         $1, $_) unless $quiet;
1025                                 push @cc, $1;
1026                         }
1027                         elsif (/^Cc:\s+(.*)$/) {
1028                                 foreach my $addr (parse_address_line($1)) {
1029                                         if (unquote_rfc2047($addr) eq $sender) {
1030                                                 next if ($suppress_cc{'self'});
1031                                         } else {
1032                                                 next if ($suppress_cc{'cc'});
1033                                         }
1034                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1035                                                 $addr, $_) unless $quiet;
1036                                         push @cc, $addr;
1037                                 }
1038                         }
1039                         elsif (/^Content-type:/i) {
1040                                 $has_content_type = 1;
1041                                 if (/charset="?([^ "]+)/) {
1042                                         $body_encoding = $1;
1043                                 }
1044                                 push @xh, $_;
1045                         }
1046                         elsif (/^Message-Id: (.*)/i) {
1047                                 $message_id = $1;
1048                         }
1049                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1050                                 push @xh, $_;
1051                         }
1052
1053                 } else {
1054                         # In the traditional
1055                         # "send lots of email" format,
1056                         # line 1 = cc
1057                         # line 2 = subject
1058                         # So let's support that, too.
1059                         $input_format = 'lots';
1060                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1061                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1062                                         $_, $_) unless $quiet;
1063                                 push @cc, $_;
1064                         } elsif (!defined $subject) {
1065                                 $subject = $_;
1066                         }
1067                 }
1068         }
1069         # Now parse the message body
1070         while(<F>) {
1071                 $message .=  $_;
1072                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1073                         chomp;
1074                         my ($what, $c) = ($1, $2);
1075                         chomp $c;
1076                         if ($c eq $sender) {
1077                                 next if ($suppress_cc{'self'});
1078                         } else {
1079                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1080                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1081                         }
1082                         push @cc, $c;
1083                         printf("(body) Adding cc: %s from line '%s'\n",
1084                                 $c, $_) unless $quiet;
1085                 }
1086         }
1087         close F;
1088
1089         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1090                 open(F, "$cc_cmd $t |")
1091                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1092                 while(<F>) {
1093                         my $c = $_;
1094                         $c =~ s/^\s*//g;
1095                         $c =~ s/\n$//g;
1096                         next if ($c eq $sender and $suppress_from);
1097                         push @cc, $c;
1098                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1099                                 $c, $cc_cmd) unless $quiet;
1100                 }
1101                 close F
1102                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1103         }
1104
1105         if (defined $author and $author ne $sender) {
1106                 $message = "From: $author\n\n$message";
1107                 if (defined $author_encoding) {
1108                         if ($has_content_type) {
1109                                 if ($body_encoding eq $author_encoding) {
1110                                         # ok, we already have the right encoding
1111                                 }
1112                                 else {
1113                                         # uh oh, we should re-encode
1114                                 }
1115                         }
1116                         else {
1117                                 push @xh,
1118                                   'MIME-Version: 1.0',
1119                                   "Content-Type: text/plain; charset=$author_encoding",
1120                                   'Content-Transfer-Encoding: 8bit';
1121                         }
1122                 }
1123         }
1124
1125         $needs_confirm = (
1126                 $confirm eq "always" or
1127                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1128                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1129         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1130
1131         @cc = (@initial_cc, @cc);
1132
1133         my $message_was_sent = send_message();
1134
1135         # set up for the next message
1136         if ($message_was_sent and $chain_reply_to || not defined $reply_to || length($reply_to) == 0) {
1137                 $reply_to = $message_id;
1138                 if (length $references > 0) {
1139                         $references .= "\n $message_id";
1140                 } else {
1141                         $references = "$message_id";
1142                 }
1143         }
1144         $message_id = undef;
1145 }
1146
1147 cleanup_compose_files();
1148
1149 sub cleanup_compose_files() {
1150         unlink($compose_filename, $compose_filename . ".final") if $compose;
1151 }
1152
1153 $smtp->quit if $smtp;
1154
1155 sub unique_email_list(@) {
1156         my %seen;
1157         my @emails;
1158
1159         foreach my $entry (@_) {
1160                 if (my $clean = extract_valid_address($entry)) {
1161                         $seen{$clean} ||= 0;
1162                         next if $seen{$clean}++;
1163                         push @emails, $entry;
1164                 } else {
1165                         print STDERR "W: unable to extract a valid address",
1166                                         " from: $entry\n";
1167                 }
1168         }
1169         return @emails;
1170 }
1171
1172 sub validate_patch {
1173         my $fn = shift;
1174         open(my $fh, '<', $fn)
1175                 or die "unable to open $fn: $!\n";
1176         while (my $line = <$fh>) {
1177                 if (length($line) > 998) {
1178                         return "$.: patch contains a line longer than 998 characters";
1179                 }
1180         }
1181         return undef;
1182 }
1183
1184 sub file_has_nonascii {
1185         my $fn = shift;
1186         open(my $fh, '<', $fn)
1187                 or die "unable to open $fn: $!\n";
1188         while (my $line = <$fh>) {
1189                 return 1 if $line =~ /[^[:ascii:]]/;
1190         }
1191         return 0;
1192 }