git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 # From which subdir have we been invoked?
  14 my $cmd_dir_prefix = eval {
  15         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  16 } || '';
  17
  18 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  19 $ENV{GIT_DIR} ||= '.git';
  20 $Git::SVN::default_repo_id = 'svn';
  21 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  22 $Git::SVN::Ra::_log_window_size = 100;
  23 $Git::SVN::_minimize_url = 'unset';
  24
  25 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  26         $ENV{SVN_SSH} = $ENV{GIT_SSH};
  27 }
  28
  29 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  30         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  31         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  32 }
  33
  34 $Git::SVN::Log::TZ = $ENV{TZ};
  35 $ENV{TZ} = 'UTC';
  36 $| = 1; # unbuffer STDOUT
  37
  38 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  39 sub _req_svn {
  40         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  41         require SVN::Ra;
  42         require SVN::Delta;
  43         if ($SVN::Core::VERSION lt '1.1.0') {
  44                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  45         }
  46 }
  47 my $can_compress = eval { require Compress::Zlib; 1};
  48 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  49 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  50 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  51 use Carp qw/croak/;
  52 use Digest::MD5;
  53 use IO::File qw//;
  54 use File::Basename qw/dirname basename/;
  55 use File::Path qw/mkpath/;
  56 use File::Spec;
  57 use File::Find;
  58 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  59 use IPC::Open3;
  60 use Git;
  61 use Memoize;  # core since 5.8.0, Jul 2002
  62
  63 BEGIN {
  64         # import functions from Git into our packages, en masse
  65         no strict 'refs';
  66         foreach (qw/command command_oneline command_noisy command_output_pipe
  67                     command_input_pipe command_close_pipe
  68                     command_bidi_pipe command_close_bidi_pipe/) {
  69                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  70                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  71                         __PACKAGE__) {
  72                         *{"${package}::$_"} = \&{"Git::$_"};
  73                 }
  74         }
  75         Memoize::memoize 'Git::config';
  76         Memoize::memoize 'Git::config_bool';
  77 }
  78
  79 my ($SVN);
  80
  81 $sha1 = qr/[a-f\d]{40}/;
  82 $sha1_short = qr/[a-f\d]{4,40}/;
  83 my ($_stdin, $_help, $_edit,
  84         $_message, $_file, $_branch_dest,
  85         $_template, $_shared,
  86         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
  87         $_merge, $_strategy, $_dry_run, $_local,
  88         $_prefix, $_no_checkout, $_url, $_verbose,
  89         $_git_format, $_commit_url, $_tag, $_merge_info, $_interactive);
  90 $Git::SVN::_follow_parent = 1;
  91 $SVN::Git::Fetcher::_placeholder_filename = ".gitignore";
  92 $_q ||= 0;
  93 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  94                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  95                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  96                     'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex,
  97                     'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
  98 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  99                 'authors-file|A=s' => \$_authors,
 100                 'authors-prog=s' => \$_authors_prog,
 101                 'repack:i' => \$Git::SVN::_repack,
 102                 'noMetadata' => \$Git::SVN::_no_metadata,
 103                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 104                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 105                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 106                 'no-checkout' => \$_no_checkout,
 107                 'quiet|q+' => \$_q,
 108                 'repack-flags|repack-args|repack-opts=s' =>
 109                    \$Git::SVN::_repack_flags,
 110                 'use-log-author' => \$Git::SVN::_use_log_author,
 111                 'add-author-from' => \$Git::SVN::_add_author_from,
 112                 'localtime' => \$Git::SVN::_localtime,
 113                 %remote_opts );
 114
 115 my ($_trunk, @_tags, @_branches, $_stdlayout);
 116 my %icv;
 117 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 118                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 119                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 120                   'stdlayout|s' => \$_stdlayout,
 121                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 122                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 123                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 124                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 125                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 126                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 127                   %remote_opts );
 128 my %cmt_opts = ( 'edit|e' => \$_edit,
 129                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 130                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 131                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 132                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 133 );
 134
 135 my %cmd = (
 136         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 137                         { 'revision|r=s' => \$_revision,
 138                           'fetch-all|all' => \$_fetch_all,
 139                           'parent|p' => \$_fetch_parent,
 140                            %fc_opts } ],
 141         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 142                         { 'revision|r=s' => \$_revision,
 143                           'preserve-empty-dirs' =>
 144                                 \$SVN::Git::Fetcher::_preserve_empty_dirs,
 145                           'placeholder-filename=s' =>
 146                                 \$SVN::Git::Fetcher::_placeholder_filename,
 147                            %fc_opts, %init_opts } ],
 148         init => [ \&cmd_init, "Initialize a repo for tracking" .
 149                           " (requires URL argument)",
 150                           \%init_opts ],
 151         'multi-init' => [ \&cmd_multi_init,
 152                           "Deprecated alias for ".
 153                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 154                           \%init_opts ],
 155         dcommit => [ \&cmd_dcommit,
 156                      'Commit several diffs to merge with upstream',
 157                         { 'merge|m|M' => \$_merge,
 158                           'strategy|s=s' => \$_strategy,
 159                           'verbose|v' => \$_verbose,
 160                           'dry-run|n' => \$_dry_run,
 161                           'fetch-all|all' => \$_fetch_all,
 162                           'commit-url=s' => \$_commit_url,
 163                           'revision|r=i' => \$_revision,
 164                           'no-rebase' => \$_no_rebase,
 165                           'mergeinfo=s' => \$_merge_info,
 166                           'interactive|i' => \$_interactive,
 167                         %cmt_opts, %fc_opts } ],
 168         branch => [ \&cmd_branch,
 169                     'Create a branch in the SVN repository',
 170                     { 'message|m=s' => \$_message,
 171                       'destination|d=s' => \$_branch_dest,
 172                       'dry-run|n' => \$_dry_run,
 173                       'tag|t' => \$_tag,
 174                       'username=s' => \$Git::SVN::Prompt::_username,
 175                       'commit-url=s' => \$_commit_url } ],
 176         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 177                  'Create a tag in the SVN repository',
 178                  { 'message|m=s' => \$_message,
 179                    'destination|d=s' => \$_branch_dest,
 180                    'dry-run|n' => \$_dry_run,
 181                    'username=s' => \$Git::SVN::Prompt::_username,
 182                    'commit-url=s' => \$_commit_url } ],
 183         'set-tree' => [ \&cmd_set_tree,
 184                         "Set an SVN repository to a git tree-ish",
 185                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 186         'create-ignore' => [ \&cmd_create_ignore,
 187                              'Create a .gitignore per svn:ignore',
 188                              { 'revision|r=i' => \$_revision
 189                              } ],
 190         'mkdirs' => [ \&cmd_mkdirs ,
 191                       "recreate empty directories after a checkout",
 192                       { 'revision|r=i' => \$_revision } ],
 193         'propget' => [ \&cmd_propget,
 194                        'Print the value of a property on a file or directory',
 195                        { 'revision|r=i' => \$_revision } ],
 196         'proplist' => [ \&cmd_proplist,
 197                        'List all properties of a file or directory',
 198                        { 'revision|r=i' => \$_revision } ],
 199         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 200                         { 'revision|r=i' => \$_revision
 201                         } ],
 202         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 203                         { 'revision|r=i' => \$_revision
 204                         } ],
 205         'multi-fetch' => [ \&cmd_multi_fetch,
 206                            "Deprecated alias for $0 fetch --all",
 207                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 208         'migrate' => [ sub { },
 209                        # no-op, we automatically run this anyways,
 210                        'Migrate configuration/metadata/layout from
 211                         previous versions of git-svn',
 212                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 213                          %remote_opts } ],
 214         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 215                         { 'limit=i' => \$Git::SVN::Log::limit,
 216                           'revision|r=s' => \$_revision,
 217                           'verbose|v' => \$Git::SVN::Log::verbose,
 218                           'incremental' => \$Git::SVN::Log::incremental,
 219                           'oneline' => \$Git::SVN::Log::oneline,
 220                           'show-commit' => \$Git::SVN::Log::show_commit,
 221                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 222                           'authors-file|A=s' => \$_authors,
 223                           'color' => \$Git::SVN::Log::color,
 224                           'pager=s' => \$Git::SVN::Log::pager
 225                         } ],
 226         'find-rev' => [ \&cmd_find_rev,
 227                         "Translate between SVN revision numbers and tree-ish",
 228                         {} ],
 229         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 230                         { 'merge|m|M' => \$_merge,
 231                           'verbose|v' => \$_verbose,
 232                           'strategy|s=s' => \$_strategy,
 233                           'local|l' => \$_local,
 234                           'fetch-all|all' => \$_fetch_all,
 235                           'dry-run|n' => \$_dry_run,
 236                           %fc_opts } ],
 237         'commit-diff' => [ \&cmd_commit_diff,
 238                            'Commit a diff between two trees',
 239                         { 'message|m=s' => \$_message,
 240                           'file|F=s' => \$_file,
 241                           'revision|r=s' => \$_revision,
 242                         %cmt_opts } ],
 243         'info' => [ \&cmd_info,
 244                     "Show info about the latest SVN revision
 245                      on the current branch",
 246                     { 'url' => \$_url, } ],
 247         'blame' => [ \&Git::SVN::Log::cmd_blame,
 248                     "Show what revision and author last modified each line of a file",
 249                     { 'git-format' => \$_git_format } ],
 250         'reset' => [ \&cmd_reset,
 251                      "Undo fetches back to the specified SVN revision",
 252                      { 'revision|r=s' => \$_revision,
 253                        'parent|p' => \$_fetch_parent } ],
 254         'gc' => [ \&cmd_gc,
 255                   "Compress unhandled.log files in .git/svn and remove " .
 256                   "index files in .git/svn",
 257                 {} ],
 258 );
 259
 260 use Term::ReadLine;
 261 package FakeTerm;
 262 sub new {
 263         my ($class, $reason) = @_;
 264         return bless \$reason, shift;
 265 }
 266 sub readline {
 267         my $self = shift;
 268         die "Cannot use readline on FakeTerm: $$self";
 269 }
 270 package main;
 271
 272 my $term = eval {
 273         $ENV{"GIT_SVN_NOTTY"}
 274                 ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 275                 : new Term::ReadLine 'git-svn';
 276 };
 277 if ($@) {
 278         $term = new FakeTerm "$@: going non-interactive";
 279 }
 280
 281 my $cmd;
 282 for (my $i = 0; $i < @ARGV; $i++) {
 283         if (defined $cmd{$ARGV[$i]}) {
 284                 $cmd = $ARGV[$i];
 285                 splice @ARGV, $i, 1;
 286                 last;
 287         } elsif ($ARGV[$i] eq 'help') {
 288                 $cmd = $ARGV[$i+1];
 289                 usage(0);
 290         }
 291 };
 292
 293 # make sure we're always running at the top-level working directory
 294 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 295         unless (-d $ENV{GIT_DIR}) {
 296                 if ($git_dir_user_set) {
 297                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 298                             "but it is not a directory\n";
 299                 }
 300                 my $git_dir = delete $ENV{GIT_DIR};
 301                 my $cdup = undef;
 302                 git_cmd_try {
 303                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 304                         $git_dir = '.' unless ($cdup);
 305                         chomp $cdup if ($cdup);
 306                         $cdup = "." unless ($cdup && length $cdup);
 307                 } "Already at toplevel, but $git_dir not found\n";
 308                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 309                 unless (-d $git_dir) {
 310                         die "$git_dir still not found after going to ",
 311                             "'$cdup'\n";
 312                 }
 313                 $ENV{GIT_DIR} = $git_dir;
 314         }
 315         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 316 }
 317
 318 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 319
 320 read_git_config(\%opts);
 321 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 322         Getopt::Long::Configure('pass_through');
 323 }
 324 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 325                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 326                     'id|i=s' => \$Git::SVN::default_ref_id,
 327                     'svn-remote|remote|R=s' => sub {
 328                        $Git::SVN::no_reuse_existing = 1;
 329                        $Git::SVN::default_repo_id = $_[1] });
 330 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 331
 332 usage(0) if $_help;
 333 version() if $_version;
 334 usage(1) unless defined $cmd;
 335 load_authors() if $_authors;
 336 if (defined $_authors_prog) {
 337         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 338 }
 339
 340 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 341         Git::SVN::Migration::migration_check();
 342 }
 343 Git::SVN::init_vars();
 344 eval {
 345         Git::SVN::verify_remotes_sanity();
 346         $cmd{$cmd}->[0]->(@ARGV);
 347 };
 348 fatal $@ if $@;
 349 post_fetch_checkout();
 350 exit 0;
 351
 352 ####################### primary functions ######################
 353 sub usage {
 354         my $exit = shift || 0;
 355         my $fd = $exit ? \*STDERR : \*STDOUT;
 356         print $fd <<"";
 357 git-svn - bidirectional operations between a single Subversion tree and git
 358 Usage: git svn <command> [options] [arguments]\n
 359
 360         print $fd "Available commands:\n" unless $cmd;
 361
 362         foreach (sort keys %cmd) {
 363                 next if $cmd && $cmd ne $_;
 364                 next if /^multi-/; # don't show deprecated commands
 365                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 366                 foreach (sort keys %{$cmd{$_}->[2]}) {
 367                         # mixed-case options are for .git/config only
 368                         next if /[A-Z]/ && /^[a-z]+$/i;
 369                         # prints out arguments as they should be passed:
 370                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 371                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 372                                                         "--$_" : "-$_" }
 373                                                 split /\|/,$_)," $x\n";
 374                 }
 375         }
 376         print $fd <<"";
 377 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 378 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 379 one git repository and want to keep them separate.  See git-svn(1) for more
 380 information.
 381
 382         exit $exit;
 383 }
 384
 385 sub version {
 386         ::_req_svn();
 387         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 388         exit 0;
 389 }
 390
 391 sub ask {
 392         my ($prompt, %arg) = @_;
 393         my $valid_re = $arg{valid_re};
 394         my $default = $arg{default};
 395         my $resp;
 396         my $i = 0;
 397
 398         if ( !( defined($term->IN)
 399             && defined( fileno($term->IN) )
 400             && defined( $term->OUT )
 401             && defined( fileno($term->OUT) ) ) ){
 402                 return defined($default) ? $default : undef;
 403         }
 404
 405         while ($i++ < 10) {
 406                 $resp = $term->readline($prompt);
 407                 if (!defined $resp) { # EOF
 408                         print "\n";
 409                         return defined $default ? $default : undef;
 410                 }
 411                 if ($resp eq '' and defined $default) {
 412                         return $default;
 413                 }
 414                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 415                         return $resp;
 416                 }
 417         }
 418         return undef;
 419 }
 420
 421 sub do_git_init_db {
 422         unless (-d $ENV{GIT_DIR}) {
 423                 my @init_db = ('init');
 424                 push @init_db, "--template=$_template" if defined $_template;
 425                 if (defined $_shared) {
 426                         if ($_shared =~ /[a-z]/) {
 427                                 push @init_db, "--shared=$_shared";
 428                         } else {
 429                                 push @init_db, "--shared";
 430                         }
 431                 }
 432                 command_noisy(@init_db);
 433                 $_repository = Git->repository(Repository => ".git");
 434         }
 435         my $set;
 436         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 437         foreach my $i (keys %icv) {
 438                 die "'$set' and '$i' cannot both be set\n" if $set;
 439                 next unless defined $icv{$i};
 440                 command_noisy('config', "$pfx.$i", $icv{$i});
 441                 $set = $i;
 442         }
 443         my $ignore_paths_regex = \$SVN::Git::Fetcher::_ignore_regex;
 444         command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 445                 if defined $$ignore_paths_regex;
 446         my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 447         command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 448                 if defined $$ignore_refs_regex;
 449
 450         if (defined $SVN::Git::Fetcher::_preserve_empty_dirs) {
 451                 my $fname = \$SVN::Git::Fetcher::_placeholder_filename;
 452                 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 453                 command_noisy('config', "$pfx.placeholder-filename", $$fname);
 454         }
 455 }
 456
 457 sub init_subdir {
 458         my $repo_path = shift or return;
 459         mkpath([$repo_path]) unless -d $repo_path;
 460         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 461         $ENV{GIT_DIR} = '.git';
 462         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 463 }
 464
 465 sub cmd_clone {
 466         my ($url, $path) = @_;
 467         if (!defined $path &&
 468             (defined $_trunk || @_branches || @_tags ||
 469              defined $_stdlayout) &&
 470             $url !~ m#^[a-z\+]+://#) {
 471                 $path = $url;
 472         }
 473         $path = basename($url) if !defined $path || !length $path;
 474         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 475         cmd_init($url, $path);
 476         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 477             if $_authors;
 478         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 479 }
 480
 481 sub cmd_init {
 482         if (defined $_stdlayout) {
 483                 $_trunk = 'trunk' if (!defined $_trunk);
 484                 @_tags = 'tags' if (! @_tags);
 485                 @_branches = 'branches' if (! @_branches);
 486         }
 487         if (defined $_trunk || @_branches || @_tags) {
 488                 return cmd_multi_init(@_);
 489         }
 490         my $url = shift or die "SVN repository location required ",
 491                                "as a command-line argument\n";
 492         $url = canonicalize_url($url);
 493         init_subdir(@_);
 494         do_git_init_db();
 495
 496         if ($Git::SVN::_minimize_url eq 'unset') {
 497                 $Git::SVN::_minimize_url = 0;
 498         }
 499
 500         Git::SVN->init($url);
 501 }
 502
 503 sub cmd_fetch {
 504         if (grep /^\d+=./, @_) {
 505                 die "'<rev>=<commit>' fetch arguments are ",
 506                     "no longer supported.\n";
 507         }
 508         my ($remote) = @_;
 509         if (@_ > 1) {
 510                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 511         }
 512         $Git::SVN::no_reuse_existing = undef;
 513         if ($_fetch_parent) {
 514                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 515                 unless ($gs) {
 516                         die "Unable to determine upstream SVN information from ",
 517                             "working tree history\n";
 518                 }
 519                 # just fetch, don't checkout.
 520                 $_no_checkout = 'true';
 521                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 522         } elsif ($_fetch_all) {
 523                 cmd_multi_fetch();
 524         } else {
 525                 $remote ||= $Git::SVN::default_repo_id;
 526                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 527         }
 528 }
 529
 530 sub cmd_set_tree {
 531         my (@commits) = @_;
 532         if ($_stdin || !@commits) {
 533                 print "Reading from stdin...\n";
 534                 @commits = ();
 535                 while (<STDIN>) {
 536                         if (/\b($sha1_short)\b/o) {
 537                                 unshift @commits, $1;
 538                         }
 539                 }
 540         }
 541         my @revs;
 542         foreach my $c (@commits) {
 543                 my @tmp = command('rev-parse',$c);
 544                 if (scalar @tmp == 1) {
 545                         push @revs, $tmp[0];
 546                 } elsif (scalar @tmp > 1) {
 547                         push @revs, reverse(command('rev-list',@tmp));
 548                 } else {
 549                         fatal "Failed to rev-parse $c";
 550                 }
 551         }
 552         my $gs = Git::SVN->new;
 553         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 554         $gs->fetch;
 555         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 556                 fatal "There are new revisions that were fetched ",
 557                       "and need to be merged (or acknowledged) ",
 558                       "before committing.\nlast rev: $r_last\n",
 559                       " current: $gs->{last_rev}";
 560         }
 561         $gs->set_tree($_) foreach @revs;
 562         print "Done committing ",scalar @revs," revisions to SVN\n";
 563         unlink $gs->{index};
 564 }
 565
 566 sub split_merge_info_range {
 567         my ($range) = @_;
 568         if ($range =~ /(\d+)-(\d+)/) {
 569                 return (int($1), int($2));
 570         } else {
 571                 return (int($range), int($range));
 572         }
 573 }
 574
 575 sub combine_ranges {
 576         my ($in) = @_;
 577
 578         my @fnums = ();
 579         my @arr = split(/,/, $in);
 580         for my $element (@arr) {
 581                 my ($start, $end) = split_merge_info_range($element);
 582                 push @fnums, $start;
 583         }
 584
 585         my @sorted = @arr [ sort {
 586                 $fnums[$a] <=> $fnums[$b]
 587         } 0..$#arr ];
 588
 589         my @return = ();
 590         my $last = -1;
 591         my $first = -1;
 592         for my $element (@sorted) {
 593                 my ($start, $end) = split_merge_info_range($element);
 594
 595                 if ($last == -1) {
 596                         $first = $start;
 597                         $last = $end;
 598                         next;
 599                 }
 600                 if ($start <= $last+1) {
 601                         if ($end > $last) {
 602                                 $last = $end;
 603                         }
 604                         next;
 605                 }
 606                 if ($first == $last) {
 607                         push @return, "$first";
 608                 } else {
 609                         push @return, "$first-$last";
 610                 }
 611                 $first = $start;
 612                 $last = $end;
 613         }
 614
 615         if ($first != -1) {
 616                 if ($first == $last) {
 617                         push @return, "$first";
 618                 } else {
 619                         push @return, "$first-$last";
 620                 }
 621         }
 622
 623         return join(',', @return);
 624 }
 625
 626 sub merge_revs_into_hash {
 627         my ($hash, $minfo) = @_;
 628         my @lines = split(' ', $minfo);
 629
 630         for my $line (@lines) {
 631                 my ($branchpath, $revs) = split(/:/, $line);
 632
 633                 if (exists($hash->{$branchpath})) {
 634                         # Merge the two revision sets
 635                         my $combined = "$hash->{$branchpath},$revs";
 636                         $hash->{$branchpath} = combine_ranges($combined);
 637                 } else {
 638                         # Just do range combining for consolidation
 639                         $hash->{$branchpath} = combine_ranges($revs);
 640                 }
 641         }
 642 }
 643
 644 sub merge_merge_info {
 645         my ($mergeinfo_one, $mergeinfo_two) = @_;
 646         my %result_hash = ();
 647
 648         merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 649         merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 650
 651         my $result = '';
 652         # Sort below is for consistency's sake
 653         for my $branchname (sort keys(%result_hash)) {
 654                 my $revlist = $result_hash{$branchname};
 655                 $result .= "$branchname:$revlist\n"
 656         }
 657         return $result;
 658 }
 659
 660 sub populate_merge_info {
 661         my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 662
 663         my %parentshash;
 664         read_commit_parents(\%parentshash, $d);
 665         my @parents = @{$parentshash{$d}};
 666         if ($#parents > 0) {
 667                 # Merge commit
 668                 my $all_parents_ok = 1;
 669                 my $aggregate_mergeinfo = '';
 670                 my $rooturl = $gs->repos_root;
 671
 672                 if (defined($rewritten_parent)) {
 673                         # Replace first parent with newly-rewritten version
 674                         shift @parents;
 675                         unshift @parents, $rewritten_parent;
 676                 }
 677
 678                 foreach my $parent (@parents) {
 679                         my ($branchurl, $svnrev, $paruuid) =
 680                                 cmt_metadata($parent);
 681
 682                         unless (defined($svnrev)) {
 683                                 # Should have been caught be preflight check
 684                                 fatal "merge commit $d has ancestor $parent, but that change "
 685                      ."does not have git-svn metadata!";
 686                         }
 687                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 688                                 fatal "commit $parent git-svn metadata changed mid-run!";
 689                         }
 690                         my $branchpath = $1;
 691
 692                         my $ra = Git::SVN::Ra->new($branchurl);
 693                         my (undef, undef, $props) =
 694                                 $ra->get_dir(canonicalize_path("."), $svnrev);
 695                         my $par_mergeinfo = $props->{'svn:mergeinfo'};
 696                         unless (defined $par_mergeinfo) {
 697                                 $par_mergeinfo = '';
 698                         }
 699                         # Merge previous mergeinfo values
 700                         $aggregate_mergeinfo =
 701                                 merge_merge_info($aggregate_mergeinfo,
 702                                                                  $par_mergeinfo, 0);
 703
 704                         next if $parent eq $parents[0]; # Skip first parent
 705                         # Add new changes being placed in tree by merge
 706                         my @cmd = (qw/rev-list --reverse/,
 707                                            $parent, qw/--not/);
 708                         foreach my $par (@parents) {
 709                                 unless ($par eq $parent) {
 710                                         push @cmd, $par;
 711                                 }
 712                         }
 713                         my @revsin = ();
 714                         my ($revlist, $ctx) = command_output_pipe(@cmd);
 715                         while (<$revlist>) {
 716                                 my $irev = $_;
 717                                 chomp $irev;
 718                                 my (undef, $csvnrev, undef) =
 719                                         cmt_metadata($irev);
 720                                 unless (defined $csvnrev) {
 721                                         # A child is missing SVN annotations...
 722                                         # this might be OK, or might not be.
 723                                         warn "W:child $irev is merged into revision "
 724                                                  ."$d but does not have git-svn metadata. "
 725                                                  ."This means git-svn cannot determine the "
 726                                                  ."svn revision numbers to place into the "
 727                                                  ."svn:mergeinfo property. You must ensure "
 728                                                  ."a branch is entirely committed to "
 729                                                  ."SVN before merging it in order for "
 730                                                  ."svn:mergeinfo population to function "
 731                                                  ."properly";
 732                                 }
 733                                 push @revsin, $csvnrev;
 734                         }
 735                         command_close_pipe($revlist, $ctx);
 736
 737                         last unless $all_parents_ok;
 738
 739                         # We now have a list of all SVN revnos which are
 740                         # merged by this particular parent. Integrate them.
 741                         next if $#revsin == -1;
 742                         my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 743                         $aggregate_mergeinfo =
 744                                 merge_merge_info($aggregate_mergeinfo,
 745                                                                  $newmergeinfo, 1);
 746                 }
 747                 if ($all_parents_ok and $aggregate_mergeinfo) {
 748                         return $aggregate_mergeinfo;
 749                 }
 750         }
 751
 752         return undef;
 753 }
 754
 755 sub cmd_dcommit {
 756         my $head = shift;
 757         command_noisy(qw/update-index --refresh/);
 758         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 759                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 760                 . "or stash them with `git stash'.\n";
 761         $head ||= 'HEAD';
 762
 763         my $old_head;
 764         if ($head ne 'HEAD') {
 765                 $old_head = eval {
 766                         command_oneline([qw/symbolic-ref -q HEAD/])
 767                 };
 768                 if ($old_head) {
 769                         $old_head =~ s{^refs/heads/}{};
 770                 } else {
 771                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 772                 }
 773                 command(['checkout', $head], STDERR => 0);
 774         }
 775
 776         my @refs;
 777         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 778         unless ($gs) {
 779                 die "Unable to determine upstream SVN information from ",
 780                     "$head history.\nPerhaps the repository is empty.";
 781         }
 782
 783         if (defined $_commit_url) {
 784                 $url = $_commit_url;
 785         } else {
 786                 $url = eval { command_oneline('config', '--get',
 787                               "svn-remote.$gs->{repo_id}.commiturl") };
 788                 if (!$url) {
 789                         $url = $gs->full_pushurl
 790                 }
 791         }
 792
 793         my $last_rev = $_revision if defined $_revision;
 794         if ($url) {
 795                 print "Committing to $url ...\n";
 796         }
 797         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 798         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 799                 warn "Attempting to commit more than one change while ",
 800                      "--no-rebase is enabled.\n",
 801                      "If these changes depend on each other, re-running ",
 802                      "without --no-rebase may be required."
 803         }
 804
 805         if (defined $_interactive){
 806                 my $ask_default = "y";
 807                 foreach my $d (@$linear_refs){
 808                         my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 809                         while (<$fh>){
 810                                 print $_;
 811                         }
 812                         command_close_pipe($fh, $ctx);
 813                         $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 814                                  valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 815                                  default => $ask_default);
 816                         die "Commit this patch reply required" unless defined $_;
 817                         if (/^[nq]/i) {
 818                                 exit(0);
 819                         } elsif (/^a/i) {
 820                                 last;
 821                         }
 822                 }
 823         }
 824
 825         my $expect_url = $url;
 826
 827         my $push_merge_info = eval {
 828                 command_oneline(qw/config --get svn.pushmergeinfo/)
 829                 };
 830         if (not defined($push_merge_info)
 831                         or $push_merge_info eq "false"
 832                         or $push_merge_info eq "no"
 833                         or $push_merge_info eq "never") {
 834                 $push_merge_info = 0;
 835         }
 836
 837         unless (defined($_merge_info) || ! $push_merge_info) {
 838                 # Preflight check of changes to ensure no issues with mergeinfo
 839                 # This includes check for uncommitted-to-SVN parents
 840                 # (other than the first parent, which we will handle),
 841                 # information from different SVN repos, and paths
 842                 # which are not underneath this repository root.
 843                 my $rooturl = $gs->repos_root;
 844                 foreach my $d (@$linear_refs) {
 845                         my %parentshash;
 846                         read_commit_parents(\%parentshash, $d);
 847                         my @realparents = @{$parentshash{$d}};
 848                         if ($#realparents > 0) {
 849                                 # Merge commit
 850                                 shift @realparents; # Remove/ignore first parent
 851                                 foreach my $parent (@realparents) {
 852                                         my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 853                                         unless (defined $paruuid) {
 854                                                 # A parent is missing SVN annotations...
 855                                                 # abort the whole operation.
 856                                                 fatal "$parent is merged into revision $d, "
 857                                                          ."but does not have git-svn metadata. "
 858                                                          ."Either dcommit the branch or use a "
 859                                                          ."local cherry-pick, FF merge, or rebase "
 860                                                          ."instead of an explicit merge commit.";
 861                                         }
 862
 863                                         unless ($paruuid eq $uuid) {
 864                                                 # Parent has SVN metadata from different repository
 865                                                 fatal "merge parent $parent for change $d has "
 866                                                          ."git-svn uuid $paruuid, while current change "
 867                                                          ."has uuid $uuid!";
 868                                         }
 869
 870                                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 871                                                 # This branch is very strange indeed.
 872                                                 fatal "merge parent $parent for $d is on branch "
 873                                                          ."$branchurl, which is not under the "
 874                                                          ."git-svn root $rooturl!";
 875                                         }
 876                                 }
 877                         }
 878                 }
 879         }
 880
 881         my $rewritten_parent;
 882         Git::SVN::remove_username($expect_url);
 883         if (defined($_merge_info)) {
 884                 $_merge_info =~ tr{ }{\n};
 885         }
 886         while (1) {
 887                 my $d = shift @$linear_refs or last;
 888                 unless (defined $last_rev) {
 889                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 890                         unless (defined $last_rev) {
 891                                 fatal "Unable to extract revision information ",
 892                                       "from commit $d~1";
 893                         }
 894                 }
 895                 if ($_dry_run) {
 896                         print "diff-tree $d~1 $d\n";
 897                 } else {
 898                         my $cmt_rev;
 899
 900                         unless (defined($_merge_info) || ! $push_merge_info) {
 901                                 $_merge_info = populate_merge_info($d, $gs,
 902                                                              $uuid,
 903                                                              $linear_refs,
 904                                                              $rewritten_parent);
 905                         }
 906
 907                         my %ed_opts = ( r => $last_rev,
 908                                         log => get_commit_entry($d)->{log},
 909                                         ra => Git::SVN::Ra->new($url),
 910                                         config => SVN::Core::config_get_config(
 911                                                 $Git::SVN::Ra::config_dir
 912                                         ),
 913                                         tree_a => "$d~1",
 914                                         tree_b => $d,
 915                                         editor_cb => sub {
 916                                                print "Committed r$_[0]\n";
 917                                                $cmt_rev = $_[0];
 918                                         },
 919                                         mergeinfo => $_merge_info,
 920                                         svn_path => '');
 921                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 922                                 print "No changes\n$d~1 == $d\n";
 923                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 924                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 925                                                                $parents->{$d};
 926                         }
 927                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 928                         $last_rev = $cmt_rev;
 929                         next if $_no_rebase;
 930
 931                         # we always want to rebase against the current HEAD,
 932                         # not any head that was passed to us
 933                         my @diff = command('diff-tree', $d,
 934                                            $gs->refname, '--');
 935                         my @finish;
 936                         if (@diff) {
 937                                 @finish = rebase_cmd();
 938                                 print STDERR "W: $d and ", $gs->refname,
 939                                              " differ, using @finish:\n",
 940                                              join("\n", @diff), "\n";
 941                         } else {
 942                                 print "No changes between current HEAD and ",
 943                                       $gs->refname,
 944                                       "\nResetting to the latest ",
 945                                       $gs->refname, "\n";
 946                                 @finish = qw/reset --mixed/;
 947                         }
 948                         command_noisy(@finish, $gs->refname);
 949
 950                         $rewritten_parent = command_oneline(qw/rev-parse HEAD/);
 951
 952                         if (@diff) {
 953                                 @refs = ();
 954                                 my ($url_, $rev_, $uuid_, $gs_) =
 955                                               working_head_info('HEAD', \@refs);
 956                                 my ($linear_refs_, $parents_) =
 957                                               linearize_history($gs_, \@refs);
 958                                 if (scalar(@$linear_refs) !=
 959                                     scalar(@$linear_refs_)) {
 960                                         fatal "# of revisions changed ",
 961                                           "\nbefore:\n",
 962                                           join("\n", @$linear_refs),
 963                                           "\n\nafter:\n",
 964                                           join("\n", @$linear_refs_), "\n",
 965                                           'If you are attempting to commit ',
 966                                           "merges, try running:\n\t",
 967                                           'git rebase --interactive',
 968                                           '--preserve-merges ',
 969                                           $gs->refname,
 970                                           "\nBefore dcommitting";
 971                                 }
 972                                 if ($url_ ne $expect_url) {
 973                                         if ($url_ eq $gs->metadata_url) {
 974                                                 print
 975                                                   "Accepting rewritten URL:",
 976                                                   " $url_\n";
 977                                         } else {
 978                                                 fatal
 979                                                   "URL mismatch after rebase:",
 980                                                   " $url_ != $expect_url";
 981                                         }
 982                                 }
 983                                 if ($uuid_ ne $uuid) {
 984                                         fatal "uuid mismatch after rebase: ",
 985                                               "$uuid_ != $uuid";
 986                                 }
 987                                 # remap parents
 988                                 my (%p, @l, $i);
 989                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 990                                         my $new = $linear_refs_->[$i] or next;
 991                                         $p{$new} =
 992                                                 $parents->{$linear_refs->[$i]};
 993                                         push @l, $new;
 994                                 }
 995                                 $parents = \%p;
 996                                 $linear_refs = \@l;
 997                         }
 998                 }
 999         }
1000
1001         if ($old_head) {
1002                 my $new_head = command_oneline(qw/rev-parse HEAD/);
1003                 my $new_is_symbolic = eval {
1004                         command_oneline(qw/symbolic-ref -q HEAD/);
1005                 };
1006                 if ($new_is_symbolic) {
1007                         print "dcommitted the branch ", $head, "\n";
1008                 } else {
1009                         print "dcommitted on a detached HEAD because you gave ",
1010                               "a revision argument.\n",
1011                               "The rewritten commit is: ", $new_head, "\n";
1012                 }
1013                 command(['checkout', $old_head], STDERR => 0);
1014         }
1015
1016         unlink $gs->{index};
1017 }
1018
1019 sub cmd_branch {
1020         my ($branch_name, $head) = @_;
1021
1022         unless (defined $branch_name && length $branch_name) {
1023                 die(($_tag ? "tag" : "branch") . " name required\n");
1024         }
1025         $head ||= 'HEAD';
1026
1027         my (undef, $rev, undef, $gs) = working_head_info($head);
1028         my $src = $gs->full_pushurl;
1029
1030         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1031         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1032         my $glob;
1033         if ($#{$allglobs} == 0) {
1034                 $glob = $allglobs->[0];
1035         } else {
1036                 unless(defined $_branch_dest) {
1037                         die "Multiple ",
1038                             $_tag ? "tag" : "branch",
1039                             " paths defined for Subversion repository.\n",
1040                             "You must specify where you want to create the ",
1041                             $_tag ? "tag" : "branch",
1042                             " with the --destination argument.\n";
1043                 }
1044                 foreach my $g (@{$allglobs}) {
1045                         # SVN::Git::Editor could probably be moved to Git.pm..
1046                         my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
1047                         if ($_branch_dest =~ /$re/) {
1048                                 $glob = $g;
1049                                 last;
1050                         }
1051                 }
1052                 unless (defined $glob) {
1053                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1054                         foreach my $g (@{$allglobs}) {
1055                                 $g->{path}->{left} =~ /$dest_re/ or next;
1056                                 if (defined $glob) {
1057                                         die "Ambiguous destination: ",
1058                                             $_branch_dest, "\nmatches both '",
1059                                             $glob->{path}->{left}, "' and '",
1060                                             $g->{path}->{left}, "'\n";
1061                                 }
1062                                 $glob = $g;
1063                         }
1064                         unless (defined $glob) {
1065                                 die "Unknown ",
1066                                     $_tag ? "tag" : "branch",
1067                                     " destination $_branch_dest\n";
1068                         }
1069                 }
1070         }
1071         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1072         my $url;
1073         if (defined $_commit_url) {
1074                 $url = $_commit_url;
1075         } else {
1076                 $url = eval { command_oneline('config', '--get',
1077                         "svn-remote.$gs->{repo_id}.commiturl") };
1078                 if (!$url) {
1079                         $url = $remote->{pushurl} || $remote->{url};
1080                 }
1081         }
1082         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1083
1084         if ($dst =~ /^https:/ && $src =~ /^http:/) {
1085                 $src=~s/^http:/https:/;
1086         }
1087
1088         ::_req_svn();
1089
1090         my $ctx = SVN::Client->new(
1091                 auth    => Git::SVN::Ra::_auth_providers(),
1092                 log_msg => sub {
1093                         ${ $_[0] } = defined $_message
1094                                 ? $_message
1095                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1096                                 . $branch_name;
1097                 },
1098         );
1099
1100         eval {
1101                 $ctx->ls($dst, 'HEAD', 0);
1102         } and die "branch ${branch_name} already exists\n";
1103
1104         print "Copying ${src} at r${rev} to ${dst}...\n";
1105         $ctx->copy($src, $rev, $dst)
1106                 unless $_dry_run;
1107
1108         $gs->fetch_all;
1109 }
1110
1111 sub cmd_find_rev {
1112         my $revision_or_hash = shift or die "SVN or git revision required ",
1113                                             "as a command-line argument\n";
1114         my $result;
1115         if ($revision_or_hash =~ /^r\d+$/) {
1116                 my $head = shift;
1117                 $head ||= 'HEAD';
1118                 my @refs;
1119                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1120                 unless ($gs) {
1121                         die "Unable to determine upstream SVN information from ",
1122                             "$head history\n";
1123                 }
1124                 my $desired_revision = substr($revision_or_hash, 1);
1125                 $result = $gs->rev_map_get($desired_revision, $uuid);
1126         } else {
1127                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1128                 $result = $rev;
1129         }
1130         print "$result\n" if $result;
1131 }
1132
1133 sub auto_create_empty_directories {
1134         my ($gs) = @_;
1135         my $var = eval { command_oneline('config', '--get', '--bool',
1136                                          "svn-remote.$gs->{repo_id}.automkdirs") };
1137         # By default, create empty directories by consulting the unhandled log,
1138         # but allow setting it to 'false' to skip it.
1139         return !($var && $var eq 'false');
1140 }
1141
1142 sub cmd_rebase {
1143         command_noisy(qw/update-index --refresh/);
1144         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1145         unless ($gs) {
1146                 die "Unable to determine upstream SVN information from ",
1147                     "working tree history\n";
1148         }
1149         if ($_dry_run) {
1150                 print "Remote Branch: " . $gs->refname . "\n";
1151                 print "SVN URL: " . $url . "\n";
1152                 return;
1153         }
1154         if (command(qw/diff-index HEAD --/)) {
1155                 print STDERR "Cannot rebase with uncommited changes:\n";
1156                 command_noisy('status');
1157                 exit 1;
1158         }
1159         unless ($_local) {
1160                 # rebase will checkout for us, so no need to do it explicitly
1161                 $_no_checkout = 'true';
1162                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1163         }
1164         command_noisy(rebase_cmd(), $gs->refname);
1165         if (auto_create_empty_directories($gs)) {
1166                 $gs->mkemptydirs;
1167         }
1168 }
1169
1170 sub cmd_show_ignore {
1171         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1172         $gs ||= Git::SVN->new;
1173         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1174         $gs->prop_walk($gs->{path}, $r, sub {
1175                 my ($gs, $path, $props) = @_;
1176                 print STDOUT "\n# $path\n";
1177                 my $s = $props->{'svn:ignore'} or return;
1178                 $s =~ s/[\r\n]+/\n/g;
1179                 $s =~ s/^\n+//;
1180                 chomp $s;
1181                 $s =~ s#^#$path#gm;
1182                 print STDOUT "$s\n";
1183         });
1184 }
1185
1186 sub cmd_show_externals {
1187         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1188         $gs ||= Git::SVN->new;
1189         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1190         $gs->prop_walk($gs->{path}, $r, sub {
1191                 my ($gs, $path, $props) = @_;
1192                 print STDOUT "\n# $path\n";
1193                 my $s = $props->{'svn:externals'} or return;
1194                 $s =~ s/[\r\n]+/\n/g;
1195                 chomp $s;
1196                 $s =~ s#^#$path#gm;
1197                 print STDOUT "$s\n";
1198         });
1199 }
1200
1201 sub cmd_create_ignore {
1202         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1203         $gs ||= Git::SVN->new;
1204         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1205         $gs->prop_walk($gs->{path}, $r, sub {
1206                 my ($gs, $path, $props) = @_;
1207                 # $path is of the form /path/to/dir/
1208                 $path = '.' . $path;
1209                 # SVN can have attributes on empty directories,
1210                 # which git won't track
1211                 mkpath([$path]) unless -d $path;
1212                 my $ignore = $path . '.gitignore';
1213                 my $s = $props->{'svn:ignore'} or return;
1214                 open(GITIGNORE, '>', $ignore)
1215                   or fatal("Failed to open `$ignore' for writing: $!");
1216                 $s =~ s/[\r\n]+/\n/g;
1217                 $s =~ s/^\n+//;
1218                 chomp $s;
1219                 # Prefix all patterns so that the ignore doesn't apply
1220                 # to sub-directories.
1221                 $s =~ s#^#/#gm;
1222                 print GITIGNORE "$s\n";
1223                 close(GITIGNORE)
1224                   or fatal("Failed to close `$ignore': $!");
1225                 command_noisy('add', '-f', $ignore);
1226         });
1227 }
1228
1229 sub cmd_mkdirs {
1230         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1231         $gs ||= Git::SVN->new;
1232         $gs->mkemptydirs($_revision);
1233 }
1234
1235 sub canonicalize_path {
1236         my ($path) = @_;
1237         my $dot_slash_added = 0;
1238         if (substr($path, 0, 1) ne "/") {
1239                 $path = "./" . $path;
1240                 $dot_slash_added = 1;
1241         }
1242         # File::Spec->canonpath doesn't collapse x/../y into y (for a
1243         # good reason), so let's do this manually.
1244         $path =~ s#/+#/#g;
1245         $path =~ s#/\.(?:/|$)#/#g;
1246         $path =~ s#/[^/]+/\.\.##g;
1247         $path =~ s#/$##g;
1248         $path =~ s#^\./## if $dot_slash_added;
1249         $path =~ s#^/##;
1250         $path =~ s#^\.$##;
1251         return $path;
1252 }
1253
1254 sub canonicalize_url {
1255         my ($url) = @_;
1256         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
1257         return $url;
1258 }
1259
1260 # get_svnprops(PATH)
1261 # ------------------
1262 # Helper for cmd_propget and cmd_proplist below.
1263 sub get_svnprops {
1264         my $path = shift;
1265         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1266         $gs ||= Git::SVN->new;
1267
1268         # prefix THE PATH by the sub-directory from which the user
1269         # invoked us.
1270         $path = $cmd_dir_prefix . $path;
1271         fatal("No such file or directory: $path") unless -e $path;
1272         my $is_dir = -d $path ? 1 : 0;
1273         $path = $gs->{path} . '/' . $path;
1274
1275         # canonicalize the path (otherwise libsvn will abort or fail to
1276         # find the file)
1277         $path = canonicalize_path($path);
1278
1279         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1280         my $props;
1281         if ($is_dir) {
1282                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1283         }
1284         else {
1285                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1286         }
1287         return $props;
1288 }
1289
1290 # cmd_propget (PROP, PATH)
1291 # ------------------------
1292 # Print the SVN property PROP for PATH.
1293 sub cmd_propget {
1294         my ($prop, $path) = @_;
1295         $path = '.' if not defined $path;
1296         usage(1) if not defined $prop;
1297         my $props = get_svnprops($path);
1298         if (not defined $props->{$prop}) {
1299                 fatal("`$path' does not have a `$prop' SVN property.");
1300         }
1301         print $props->{$prop} . "\n";
1302 }
1303
1304 # cmd_proplist (PATH)
1305 # -------------------
1306 # Print the list of SVN properties for PATH.
1307 sub cmd_proplist {
1308         my $path = shift;
1309         $path = '.' if not defined $path;
1310         my $props = get_svnprops($path);
1311         print "Properties on '$path':\n";
1312         foreach (sort keys %{$props}) {
1313                 print "  $_\n";
1314         }
1315 }
1316
1317 sub cmd_multi_init {
1318         my $url = shift;
1319         unless (defined $_trunk || @_branches || @_tags) {
1320                 usage(1);
1321         }
1322
1323         $_prefix = '' unless defined $_prefix;
1324         if (defined $url) {
1325                 $url = canonicalize_url($url);
1326                 init_subdir(@_);
1327         }
1328         do_git_init_db();
1329         if (defined $_trunk) {
1330                 $_trunk =~ s#^/+##;
1331                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1332                 # try both old-style and new-style lookups:
1333                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1334                 unless ($gs_trunk) {
1335                         my ($trunk_url, $trunk_path) =
1336                                               complete_svn_url($url, $_trunk);
1337                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1338                                                    undef, $trunk_ref);
1339                 }
1340         }
1341         return unless @_branches || @_tags;
1342         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1343         foreach my $path (@_branches) {
1344                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1345         }
1346         foreach my $path (@_tags) {
1347                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1348         }
1349 }
1350
1351 sub cmd_multi_fetch {
1352         $Git::SVN::no_reuse_existing = undef;
1353         my $remotes = Git::SVN::read_all_remotes();
1354         foreach my $repo_id (sort keys %$remotes) {
1355                 if ($remotes->{$repo_id}->{url}) {
1356                         Git::SVN::fetch_all($repo_id, $remotes);
1357                 }
1358         }
1359 }
1360
1361 # this command is special because it requires no metadata
1362 sub cmd_commit_diff {
1363         my ($ta, $tb, $url) = @_;
1364         my $usage = "Usage: $0 commit-diff -r<revision> ".
1365                     "<tree-ish> <tree-ish> [<URL>]";
1366         fatal($usage) if (!defined $ta || !defined $tb);
1367         my $svn_path = '';
1368         if (!defined $url) {
1369                 my $gs = eval { Git::SVN->new };
1370                 if (!$gs) {
1371                         fatal("Needed URL or usable git-svn --id in ",
1372                               "the command-line\n", $usage);
1373                 }
1374                 $url = $gs->{url};
1375                 $svn_path = $gs->{path};
1376         }
1377         unless (defined $_revision) {
1378                 fatal("-r|--revision is a required argument\n", $usage);
1379         }
1380         if (defined $_message && defined $_file) {
1381                 fatal("Both --message/-m and --file/-F specified ",
1382                       "for the commit message.\n",
1383                       "I have no idea what you mean");
1384         }
1385         if (defined $_file) {
1386                 $_message = file_to_s($_file);
1387         } else {
1388                 $_message ||= get_commit_entry($tb)->{log};
1389         }
1390         my $ra ||= Git::SVN::Ra->new($url);
1391         my $r = $_revision;
1392         if ($r eq 'HEAD') {
1393                 $r = $ra->get_latest_revnum;
1394         } elsif ($r !~ /^\d+$/) {
1395                 die "revision argument: $r not understood by git-svn\n";
1396         }
1397         my %ed_opts = ( r => $r,
1398                         log => $_message,
1399                         ra => $ra,
1400                         tree_a => $ta,
1401                         tree_b => $tb,
1402                         editor_cb => sub { print "Committed r$_[0]\n" },
1403                         svn_path => $svn_path );
1404         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1405                 print "No changes\n$ta == $tb\n";
1406         }
1407 }
1408
1409 sub escape_uri_only {
1410         my ($uri) = @_;
1411         my @tmp;
1412         foreach (split m{/}, $uri) {
1413                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1414                 push @tmp, $_;
1415         }
1416         join('/', @tmp);
1417 }
1418
1419 sub escape_url {
1420         my ($url) = @_;
1421         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1422                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1423                 $url = "$scheme://$domain$uri";
1424         }
1425         $url;
1426 }
1427
1428 sub cmd_info {
1429         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1430         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1431         if (exists $_[1]) {
1432                 die "Too many arguments specified\n";
1433         }
1434
1435         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1436
1437         if (!$file_type && !$diff_status) {
1438                 print STDERR "svn: '$path' is not under version control\n";
1439                 exit 1;
1440         }
1441
1442         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1443         unless ($gs) {
1444                 die "Unable to determine upstream SVN information from ",
1445                     "working tree history\n";
1446         }
1447
1448         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1449         $path = "." if $path eq "";
1450
1451         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1452
1453         if ($_url) {
1454                 print escape_url($full_url), "\n";
1455                 return;
1456         }
1457
1458         my $result = "Path: $path\n";
1459         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1460         $result .= "URL: " . escape_url($full_url) . "\n";
1461
1462         eval {
1463                 my $repos_root = $gs->repos_root;
1464                 Git::SVN::remove_username($repos_root);
1465                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1466         };
1467         if ($@) {
1468                 $result .= "Repository Root: (offline)\n";
1469         }
1470         ::_req_svn();
1471         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1472                 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1473         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1474
1475         $result .= "Node Kind: " .
1476                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1477
1478         my $schedule = $diff_status eq "A"
1479                        ? "add"
1480                        : ($diff_status eq "D" ? "delete" : "normal");
1481         $result .= "Schedule: $schedule\n";
1482
1483         if ($diff_status eq "A") {
1484                 print $result, "\n";
1485                 return;
1486         }
1487
1488         my ($lc_author, $lc_rev, $lc_date_utc);
1489         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1490         my $log = command_output_pipe(@args);
1491         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1492         while (<$log>) {
1493                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1494                         $lc_author = $1;
1495                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1496                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1497                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1498                 }
1499         }
1500         close $log;
1501
1502         Git::SVN::Log::set_local_timezone();
1503
1504         $result .= "Last Changed Author: $lc_author\n";
1505         $result .= "Last Changed Rev: $lc_rev\n";
1506         $result .= "Last Changed Date: " .
1507                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1508
1509         if ($file_type ne "dir") {
1510                 my $text_last_updated_date =
1511                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1512                 $result .=
1513                     "Text Last Updated: " .
1514                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1515                     "\n";
1516                 my $checksum;
1517                 if ($diff_status eq "D") {
1518                         my ($fh, $ctx) =
1519                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1520                         if ($file_type eq "link") {
1521                                 my $file_name = <$fh>;
1522                                 $checksum = md5sum("link $file_name");
1523                         } else {
1524                                 $checksum = md5sum($fh);
1525                         }
1526                         command_close_pipe($fh, $ctx);
1527                 } elsif ($file_type eq "link") {
1528                         my $file_name =
1529                             command(qw(cat-file blob), "HEAD:$path");
1530                         $checksum =
1531                             md5sum("link " . $file_name);
1532                 } else {
1533                         open FILE, "<", $path or die $!;
1534                         $checksum = md5sum(\*FILE);
1535                         close FILE or die $!;
1536                 }
1537                 $result .= "Checksum: " . $checksum . "\n";
1538         }
1539
1540         print $result, "\n";
1541 }
1542
1543 sub cmd_reset {
1544         my $target = shift || $_revision or die "SVN revision required\n";
1545         $target = $1 if $target =~ /^r(\d+)$/;
1546         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1547         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1548         unless ($gs) {
1549                 die "Unable to determine upstream SVN information from ".
1550                     "history\n";
1551         }
1552         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1553         die "Cannot find SVN revision $target\n" unless defined($c);
1554         $gs->rev_map_set($r, $c, 'reset', $uuid);
1555         print "r$r = $c ($gs->{ref_id})\n";
1556 }
1557
1558 sub cmd_gc {
1559         if (!$can_compress) {
1560                 warn "Compress::Zlib could not be found; unhandled.log " .
1561                      "files will not be compressed.\n";
1562         }
1563         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1564 }
1565
1566 ########################### utility functions #########################
1567
1568 sub rebase_cmd {
1569         my @cmd = qw/rebase/;
1570         push @cmd, '-v' if $_verbose;
1571         push @cmd, qw/--merge/ if $_merge;
1572         push @cmd, "--strategy=$_strategy" if $_strategy;
1573         @cmd;
1574 }
1575
1576 sub post_fetch_checkout {
1577         return if $_no_checkout;
1578         my $gs = $Git::SVN::_head or return;
1579         return if verify_ref('refs/heads/master^0');
1580
1581         # look for "trunk" ref if it exists
1582         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1583         my $fetch = $remote->{fetch};
1584         if ($fetch) {
1585                 foreach my $p (keys %$fetch) {
1586                         basename($fetch->{$p}) eq 'trunk' or next;
1587                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1588                         last;
1589                 }
1590         }
1591
1592         my $valid_head = verify_ref('HEAD^0');
1593         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1594         return if ($valid_head || !verify_ref('HEAD^0'));
1595
1596         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1597         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1598         return if -f $index;
1599
1600         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1601         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1602         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1603         print STDERR "Checked out HEAD:\n  ",
1604                      $gs->full_url, " r", $gs->last_rev, "\n";
1605         if (auto_create_empty_directories($gs)) {
1606                 $gs->mkemptydirs($gs->last_rev);
1607         }
1608 }
1609
1610 sub complete_svn_url {
1611         my ($url, $path) = @_;
1612         $path =~ s#/+$##;
1613         if ($path !~ m#^[a-z\+]+://#) {
1614                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1615                         fatal("E: '$path' is not a complete URL ",
1616                               "and a separate URL is not specified");
1617                 }
1618                 return ($url, $path);
1619         }
1620         return ($path, '');
1621 }
1622
1623 sub complete_url_ls_init {
1624         my ($ra, $repo_path, $switch, $pfx) = @_;
1625         unless ($repo_path) {
1626                 print STDERR "W: $switch not specified\n";
1627                 return;
1628         }
1629         $repo_path =~ s#/+$##;
1630         if ($repo_path =~ m#^[a-z\+]+://#) {
1631                 $ra = Git::SVN::Ra->new($repo_path);
1632                 $repo_path = '';
1633         } else {
1634                 $repo_path =~ s#^/+##;
1635                 unless ($ra) {
1636                         fatal("E: '$repo_path' is not a complete URL ",
1637                               "and a separate URL is not specified");
1638                 }
1639         }
1640         my $url = $ra->{url};
1641         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1642         my $k = "svn-remote.$gs->{repo_id}.url";
1643         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1644         if ($orig_url && ($orig_url ne $gs->{url})) {
1645                 die "$k already set: $orig_url\n",
1646                     "wanted to set to: $gs->{url}\n";
1647         }
1648         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1649         my $remote_path = "$gs->{path}/$repo_path";
1650         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1651         $remote_path =~ s#/+#/#g;
1652         $remote_path =~ s#^/##g;
1653         $remote_path .= "/*" if $remote_path !~ /\*/;
1654         my ($n) = ($switch =~ /^--(\w+)/);
1655         if (length $pfx && $pfx !~ m#/$#) {
1656                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1657         }
1658         command_noisy('config',
1659                       '--add',
1660                       "svn-remote.$gs->{repo_id}.$n",
1661                       "$remote_path:refs/remotes/$pfx*" .
1662                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1663 }
1664
1665 sub verify_ref {
1666         my ($ref) = @_;
1667         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1668                                { STDERR => 0 }); };
1669 }
1670
1671 sub get_tree_from_treeish {
1672         my ($treeish) = @_;
1673         # $treeish can be a symbolic ref, too:
1674         my $type = command_oneline(qw/cat-file -t/, $treeish);
1675         my $expected;
1676         while ($type eq 'tag') {
1677                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1678         }
1679         if ($type eq 'commit') {
1680                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1681                                                     $treeish))[0];
1682                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1683                 die "Unable to get tree from $treeish\n" unless $expected;
1684         } elsif ($type eq 'tree') {
1685                 $expected = $treeish;
1686         } else {
1687                 die "$treeish is a $type, expected tree, tag or commit\n";
1688         }
1689         return $expected;
1690 }
1691
1692 sub get_commit_entry {
1693         my ($treeish) = shift;
1694         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1695         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1696         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1697         open my $log_fh, '>', $commit_editmsg or croak $!;
1698
1699         my $type = command_oneline(qw/cat-file -t/, $treeish);
1700         if ($type eq 'commit' || $type eq 'tag') {
1701                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1702                                                          $type, $treeish);
1703                 my $in_msg = 0;
1704                 my $author;
1705                 my $saw_from = 0;
1706                 my $msgbuf = "";
1707                 while (<$msg_fh>) {
1708                         if (!$in_msg) {
1709                                 $in_msg = 1 if (/^\s*$/);
1710                                 $author = $1 if (/^author (.*>)/);
1711                         } elsif (/^git-svn-id: /) {
1712                                 # skip this for now, we regenerate the
1713                                 # correct one on re-fetch anyways
1714                                 # TODO: set *:merge properties or like...
1715                         } else {
1716                                 if (/^From:/ || /^Signed-off-by:/) {
1717                                         $saw_from = 1;
1718                                 }
1719                                 $msgbuf .= $_;
1720                         }
1721                 }
1722                 $msgbuf =~ s/\s+$//s;
1723                 if ($Git::SVN::_add_author_from && defined($author)
1724                     && !$saw_from) {
1725                         $msgbuf .= "\n\nFrom: $author";
1726                 }
1727                 print $log_fh $msgbuf or croak $!;
1728                 command_close_pipe($msg_fh, $ctx);
1729         }
1730         close $log_fh or croak $!;
1731
1732         if ($_edit || ($type eq 'tree')) {
1733                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1734                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1735         }
1736         rename $commit_editmsg, $commit_msg or croak $!;
1737         {
1738                 require Encode;
1739                 # SVN requires messages to be UTF-8 when entering the repo
1740                 local $/;
1741                 open $log_fh, '<', $commit_msg or croak $!;
1742                 binmode $log_fh;
1743                 chomp($log_entry{log} = <$log_fh>);
1744
1745                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1746                 my $msg = $log_entry{log};
1747
1748                 eval { $msg = Encode::decode($enc, $msg, 1) };
1749                 if ($@) {
1750                         die "Could not decode as $enc:\n", $msg,
1751                             "\nPerhaps you need to set i18n.commitencoding\n";
1752                 }
1753
1754                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1755                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1756
1757                 $log_entry{log} = $msg;
1758
1759                 close $log_fh or croak $!;
1760         }
1761         unlink $commit_msg;
1762         \%log_entry;
1763 }
1764
1765 sub s_to_file {
1766         my ($str, $file, $mode) = @_;
1767         open my $fd,'>',$file or croak $!;
1768         print $fd $str,"\n" or croak $!;
1769         close $fd or croak $!;
1770         chmod ($mode &~ umask, $file) if (defined $mode);
1771 }
1772
1773 sub file_to_s {
1774         my $file = shift;
1775         open my $fd,'<',$file or croak "$!: file: $file\n";
1776         local $/;
1777         my $ret = <$fd>;
1778         close $fd or croak $!;
1779         $ret =~ s/\s*$//s;
1780         return $ret;
1781 }
1782
1783 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1784 sub load_authors {
1785         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1786         my $log = $cmd eq 'log';
1787         while (<$authors>) {
1788                 chomp;
1789                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1790                 my ($user, $name, $email) = ($1, $2, $3);
1791                 if ($log) {
1792                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1793                 } else {
1794                         $users{$user} = [$name, $email];
1795                 }
1796         }
1797         close $authors or croak $!;
1798 }
1799
1800 # convert GetOpt::Long specs for use by git-config
1801 sub read_git_config {
1802         my $opts = shift;
1803         my @config_only;
1804         foreach my $o (keys %$opts) {
1805                 # if we have mixedCase and a long option-only, then
1806                 # it's a config-only variable that we don't need for
1807                 # the command-line.
1808                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1809                 my $v = $opts->{$o};
1810                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1811                 $key =~ s/-//g;
1812                 my $arg = 'git config';
1813                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1814                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1815                 if (ref $v eq 'ARRAY') {
1816                         chomp(my @tmp = `$arg --get-all svn.$key`);
1817                         @$v = @tmp if @tmp;
1818                 } else {
1819                         chomp(my $tmp = `$arg --get svn.$key`);
1820                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1821                                 $$v = $tmp;
1822                         }
1823                 }
1824         }
1825         delete @$opts{@config_only} if @config_only;
1826 }
1827
1828 sub extract_metadata {
1829         my $id = shift or return (undef, undef, undef);
1830         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1831                                                         \s([a-f\d\-]+)$/ix);
1832         if (!defined $rev || !$uuid || !$url) {
1833                 # some of the original repositories I made had
1834                 # identifiers like this:
1835                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1836         }
1837         return ($url, $rev, $uuid);
1838 }
1839
1840 sub cmt_metadata {
1841         return extract_metadata((grep(/^git-svn-id: /,
1842                 command(qw/cat-file commit/, shift)))[-1]);
1843 }
1844
1845 sub cmt_sha2rev_batch {
1846         my %s2r;
1847         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1848         my $list = shift;
1849
1850         foreach my $sha (@{$list}) {
1851                 my $first = 1;
1852                 my $size = 0;
1853                 print $out $sha, "\n";
1854
1855                 while (my $line = <$in>) {
1856                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1857                                 last;
1858                         } elsif ($first &&
1859                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1860                                 $first = 0;
1861                                 $size = $1;
1862                                 next;
1863                         } elsif ($line =~ /^(git-svn-id: )/) {
1864                                 my (undef, $rev, undef) =
1865                                                       extract_metadata($line);
1866                                 $s2r{$sha} = $rev;
1867                         }
1868
1869                         $size -= length($line);
1870                         last if ($size == 0);
1871                 }
1872         }
1873
1874         command_close_bidi_pipe($pid, $in, $out, $ctx);
1875
1876         return \%s2r;
1877 }
1878
1879 sub working_head_info {
1880         my ($head, $refs) = @_;
1881         my @args = qw/rev-list --first-parent --pretty=medium/;
1882         my ($fh, $ctx) = command_output_pipe(@args, $head);
1883         my $hash;
1884         my %max;
1885         while (<$fh>) {
1886                 if ( m{^commit ($::sha1)$} ) {
1887                         unshift @$refs, $hash if $hash and $refs;
1888                         $hash = $1;
1889                         next;
1890                 }
1891                 next unless s{^\s*(git-svn-id:)}{$1};
1892                 my ($url, $rev, $uuid) = extract_metadata($_);
1893                 if (defined $url && defined $rev) {
1894                         next if $max{$url} and $max{$url} < $rev;
1895                         if (my $gs = Git::SVN->find_by_url($url)) {
1896                                 my $c = $gs->rev_map_get($rev, $uuid);
1897                                 if ($c && $c eq $hash) {
1898                                         close $fh; # break the pipe
1899                                         return ($url, $rev, $uuid, $gs);
1900                                 } else {
1901                                         $max{$url} ||= $gs->rev_map_max;
1902                                 }
1903                         }
1904                 }
1905         }
1906         command_close_pipe($fh, $ctx);
1907         (undef, undef, undef, undef);
1908 }
1909
1910 sub read_commit_parents {
1911         my ($parents, $c) = @_;
1912         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1913         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1914         @{$parents->{$c}} = split(/ /, $p);
1915 }
1916
1917 sub linearize_history {
1918         my ($gs, $refs) = @_;
1919         my %parents;
1920         foreach my $c (@$refs) {
1921                 read_commit_parents(\%parents, $c);
1922         }
1923
1924         my @linear_refs;
1925         my %skip = ();
1926         my $last_svn_commit = $gs->last_commit;
1927         foreach my $c (reverse @$refs) {
1928                 next if $c eq $last_svn_commit;
1929                 last if $skip{$c};
1930
1931                 unshift @linear_refs, $c;
1932                 $skip{$c} = 1;
1933
1934                 # we only want the first parent to diff against for linear
1935                 # history, we save the rest to inject when we finalize the
1936                 # svn commit
1937                 my $fp_a = verify_ref("$c~1");
1938                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1939                 if (!$fp_a || !$fp_b) {
1940                         die "Commit $c\n",
1941                             "has no parent commit, and therefore ",
1942                             "nothing to diff against.\n",
1943                             "You should be working from a repository ",
1944                             "originally created by git-svn\n";
1945                 }
1946                 if ($fp_a ne $fp_b) {
1947                         die "$c~1 = $fp_a, however parsing commit $c ",
1948                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1949                 }
1950
1951                 foreach my $p (@{$parents{$c}}) {
1952                         $skip{$p} = 1;
1953                 }
1954         }
1955         (\@linear_refs, \%parents);
1956 }
1957
1958 sub find_file_type_and_diff_status {
1959         my ($path) = @_;
1960         return ('dir', '') if $path eq '';
1961
1962         my $diff_output =
1963             command_oneline(qw(diff --cached --name-status --), $path) || "";
1964         my $diff_status = (split(' ', $diff_output))[0] || "";
1965
1966         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1967
1968         return (undef, undef) if !$diff_status && !$ls_tree;
1969
1970         if ($diff_status eq "A") {
1971                 return ("link", $diff_status) if -l $path;
1972                 return ("dir", $diff_status) if -d $path;
1973                 return ("file", $diff_status);
1974         }
1975
1976         my $mode = (split(' ', $ls_tree))[0] || "";
1977
1978         return ("link", $diff_status) if $mode eq "120000";
1979         return ("dir", $diff_status) if $mode eq "040000";
1980         return ("file", $diff_status);
1981 }
1982
1983 sub md5sum {
1984         my $arg = shift;
1985         my $ref = ref $arg;
1986         my $md5 = Digest::MD5->new();
1987         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1988                 $md5->addfile($arg) or croak $!;
1989         } elsif ($ref eq 'SCALAR') {
1990                 $md5->add($$arg) or croak $!;
1991         } elsif (!$ref) {
1992                 $md5->add($arg) or croak $!;
1993         } else {
1994                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1995         }
1996         return $md5->hexdigest();
1997 }
1998
1999 sub gc_directory {
2000         if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
2001                 my $out_filename = $_ . ".gz";
2002                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2003                 binmode $in_fh;
2004                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2005                                 die "Unable to open $out_filename: $!\n";
2006
2007                 my $res;
2008                 while ($res = sysread($in_fh, my $str, 1024)) {
2009                         $gz->gzwrite($str) or
2010                                 die "Unable to write: ".$gz->gzerror()."!\n";
2011                 }
2012                 unlink $_ or die "unlink $File::Find::name: $!\n";
2013         } elsif (-f $_ && basename($_) eq "index") {
2014                 unlink $_ or die "unlink $_: $!\n";
2015         }
2016 }
2017
2018 package Git::SVN;
2019 use strict;
2020 use warnings;
2021 use Fcntl qw/:DEFAULT :seek/;
2022 use constant rev_map_fmt => 'NH40';
2023 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
2024             $_repack $_repack_flags $_use_svm_props $_head
2025             $_use_svnsync_props $no_reuse_existing $_minimize_url
2026             $_use_log_author $_add_author_from $_localtime/;
2027 use Carp qw/croak/;
2028 use File::Path qw/mkpath/;
2029 use File::Copy qw/copy/;
2030 use IPC::Open3;
2031 use Time::Local;
2032 use Memoize;  # core since 5.8.0, Jul 2002
2033 use Memoize::Storable;
2034
2035 my ($_gc_nr, $_gc_period);
2036
2037 # properties that we do not log:
2038 my %SKIP_PROP;
2039 BEGIN {
2040         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
2041                                         svn:special svn:executable
2042                                         svn:entry:committed-rev
2043                                         svn:entry:last-author
2044                                         svn:entry:uuid
2045                                         svn:entry:committed-date/;
2046
2047         # some options are read globally, but can be overridden locally
2048         # per [svn-remote "..."] section.  Command-line options will *NOT*
2049         # override options set in an [svn-remote "..."] section
2050         no strict 'refs';
2051         for my $option (qw/follow_parent no_metadata use_svm_props
2052                            use_svnsync_props/) {
2053                 my $key = $option;
2054                 $key =~ tr/_//d;
2055                 my $prop = "-$option";
2056                 *$option = sub {
2057                         my ($self) = @_;
2058                         return $self->{$prop} if exists $self->{$prop};
2059                         my $k = "svn-remote.$self->{repo_id}.$key";
2060                         eval { command_oneline(qw/config --get/, $k) };
2061                         if ($@) {
2062                                 $self->{$prop} = ${"Git::SVN::_$option"};
2063                         } else {
2064                                 my $v = command_oneline(qw/config --bool/,$k);
2065                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
2066                         }
2067                         return $self->{$prop};
2068                 }
2069         }
2070 }
2071
2072
2073 my (%LOCKFILES, %INDEX_FILES);
2074 END {
2075         unlink keys %LOCKFILES if %LOCKFILES;
2076         unlink keys %INDEX_FILES if %INDEX_FILES;
2077 }
2078
2079 sub resolve_local_globs {
2080         my ($url, $fetch, $glob_spec) = @_;
2081         return unless defined $glob_spec;
2082         my $ref = $glob_spec->{ref};
2083         my $path = $glob_spec->{path};
2084         foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
2085                 next unless m#^$ref->{regex}$#;
2086                 my $p = $1;
2087                 my $pathname = desanitize_refname($path->full_path($p));
2088                 my $refname = desanitize_refname($ref->full_path($p));
2089                 if (my $existing = $fetch->{$pathname}) {
2090                         if ($existing ne $refname) {
2091                                 die "Refspec conflict:\n",
2092                                     "existing: $existing\n",
2093                                     " globbed: $refname\n";
2094                         }
2095                         my $u = (::cmt_metadata("$refname"))[0];
2096                         $u =~ s!^\Q$url\E(/|$)!! or die
2097                           "$refname: '$url' not found in '$u'\n";
2098                         if ($pathname ne $u) {
2099                                 warn "W: Refspec glob conflict ",
2100                                      "(ref: $refname):\n",
2101                                      "expected path: $pathname\n",
2102                                      "    real path: $u\n",
2103                                      "Continuing ahead with $u\n";
2104                                 next;
2105                         }
2106                 } else {
2107                         $fetch->{$pathname} = $refname;
2108                 }
2109         }
2110 }
2111
2112 sub parse_revision_argument {
2113         my ($base, $head) = @_;
2114         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
2115                 return ($base, $head);
2116         }
2117         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
2118         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
2119         return ($head, $head) if ($::_revision eq 'HEAD');
2120         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
2121         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
2122         die "revision argument: $::_revision not understood by git-svn\n";
2123 }
2124
2125 sub fetch_all {
2126         my ($repo_id, $remotes) = @_;
2127         if (ref $repo_id) {
2128                 my $gs = $repo_id;
2129                 $repo_id = undef;
2130                 $repo_id = $gs->{repo_id};
2131         }
2132         $remotes ||= read_all_remotes();
2133         my $remote = $remotes->{$repo_id} or
2134                      die "[svn-remote \"$repo_id\"] unknown\n";
2135         my $fetch = $remote->{fetch};
2136         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
2137         my (@gs, @globs);
2138         my $ra = Git::SVN::Ra->new($url);
2139         my $uuid = $ra->get_uuid;
2140         my $head = $ra->get_latest_revnum;
2141
2142         # ignore errors, $head revision may not even exist anymore
2143         eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
2144         warn "W: $@\n" if $@;
2145
2146         my $base = defined $fetch ? $head : 0;
2147
2148         # read the max revs for wildcard expansion (branches/*, tags/*)
2149         foreach my $t (qw/branches tags/) {
2150                 defined $remote->{$t} or next;
2151                 push @globs, @{$remote->{$t}};
2152
2153                 my $max_rev = eval { tmp_config(qw/--int --get/,
2154                                          "svn-remote.$repo_id.${t}-maxRev") };
2155                 if (defined $max_rev && ($max_rev < $base)) {
2156                         $base = $max_rev;
2157                 } elsif (!defined $max_rev) {
2158                         $base = 0;
2159                 }
2160         }
2161
2162         if ($fetch) {
2163                 foreach my $p (sort keys %$fetch) {
2164                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
2165                         my $lr = $gs->rev_map_max;
2166                         if (defined $lr) {
2167                                 $base = $lr if ($lr < $base);
2168                         }
2169                         push @gs, $gs;
2170                 }
2171         }
2172
2173         ($base, $head) = parse_revision_argument($base, $head);
2174         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
2175 }
2176
2177 sub read_all_remotes {
2178         my $r = {};
2179         my $use_svm_props = eval { command_oneline(qw/config --bool
2180             svn.useSvmProps/) };
2181         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
2182         my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
2183         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
2184                 if (m!^(.+)\.fetch=$svn_refspec$!) {
2185                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
2186                         die("svn-remote.$remote: remote ref '$remote_ref' "
2187                             . "must start with 'refs/'\n")
2188                                 unless $remote_ref =~ m{^refs/};
2189                         $local_ref = uri_decode($local_ref);
2190                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
2191                         $r->{$remote}->{svm} = {} if $use_svm_props;
2192                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
2193                         $r->{$1}->{svm} = {};
2194                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
2195                         $r->{$1}->{url} = $2;
2196                 } elsif (m!^(.+)\.pushurl=\s*(.*)\s*$!) {
2197                         $r->{$1}->{pushurl} = $2;
2198                 } elsif (m!^(.+)\.ignore-refs=\s*(.*)\s*$!) {
2199                         $r->{$1}->{ignore_refs_regex} = $2;
2200                 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
2201                         my ($remote, $t, $local_ref, $remote_ref) =
2202                                                              ($1, $2, $3, $4);
2203                         die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
2204                             . "must start with 'refs/'\n")
2205                                 unless $remote_ref =~ m{^refs/};
2206                         $local_ref = uri_decode($local_ref);
2207                         my $rs = {
2208                             t => $t,
2209                             remote => $remote,
2210                             path => Git::SVN::GlobSpec->new($local_ref, 1),
2211                             ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
2212                         if (length($rs->{ref}->{right}) != 0) {
2213                                 die "The '*' glob character must be the last ",
2214                                     "character of '$remote_ref'\n";
2215                         }
2216                         push @{ $r->{$remote}->{$t} }, $rs;
2217                 }
2218         }
2219
2220         map {
2221                 if (defined $r->{$_}->{svm}) {
2222                         my $svm;
2223                         eval {
2224                                 my $section = "svn-remote.$_";
2225                                 $svm = {
2226                                         source => tmp_config('--get',
2227                                             "$section.svm-source"),
2228                                         replace => tmp_config('--get',
2229                                             "$section.svm-replace"),
2230                                 }
2231                         };
2232                         $r->{$_}->{svm} = $svm;
2233                 }
2234         } keys %$r;
2235
2236         foreach my $remote (keys %$r) {
2237                 foreach ( grep { defined $_ }
2238                           map { $r->{$remote}->{$_} } qw(branches tags) ) {
2239                         foreach my $rs ( @$_ ) {
2240                                 $rs->{ignore_refs_regex} =
2241                                     $r->{$remote}->{ignore_refs_regex};
2242                         }
2243                 }
2244         }
2245
2246         $r;
2247 }
2248
2249 sub init_vars {
2250         $_gc_nr = $_gc_period = 1000;
2251         if (defined $_repack || defined $_repack_flags) {
2252                warn "Repack options are obsolete; they have no effect.\n";
2253         }
2254 }
2255
2256 sub verify_remotes_sanity {
2257         return unless -d $ENV{GIT_DIR};
2258         my %seen;
2259         foreach (command(qw/config -l/)) {
2260                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
2261                         if ($seen{$1}) {
2262                                 die "Remote ref refs/remote/$1 is tracked by",
2263                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
2264                                     "Please resolve this ambiguity in ",
2265                                     "your git configuration file before ",
2266                                     "continuing\n";
2267                         }
2268                         $seen{$1} = $_;
2269                 }
2270         }
2271 }
2272
2273 sub find_existing_remote {
2274         my ($url, $remotes) = @_;
2275         return undef if $no_reuse_existing;
2276         my $existing;
2277         foreach my $repo_id (keys %$remotes) {
2278                 my $u = $remotes->{$repo_id}->{url} or next;
2279                 next if $u ne $url;
2280                 $existing = $repo_id;
2281                 last;
2282         }
2283         $existing;
2284 }
2285
2286 sub init_remote_config {
2287         my ($self, $url, $no_write) = @_;
2288         $url =~ s!/+$!!; # strip trailing slash
2289         my $r = read_all_remotes();
2290         my $existing = find_existing_remote($url, $r);
2291         if ($existing) {
2292                 unless ($no_write) {
2293                         print STDERR "Using existing ",
2294                                      "[svn-remote \"$existing\"]\n";
2295                 }
2296                 $self->{repo_id} = $existing;
2297         } elsif ($_minimize_url) {
2298                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
2299                 $existing = find_existing_remote($min_url, $r);
2300                 if ($existing) {
2301                         unless ($no_write) {
2302                                 print STDERR "Using existing ",
2303                                              "[svn-remote \"$existing\"]\n";
2304                         }
2305                         $self->{repo_id} = $existing;
2306                 }
2307                 if ($min_url ne $url) {
2308                         unless ($no_write) {
2309                                 print STDERR "Using higher level of URL: ",
2310                                              "$url => $min_url\n";
2311                         }
2312                         my $old_path = $self->{path};
2313                         $self->{path} = $url;
2314                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
2315                         if (length $old_path) {
2316                                 $self->{path} .= "/$old_path";
2317                         }
2318                         $url = $min_url;
2319                 }
2320         }
2321         my $orig_url;
2322         if (!$existing) {
2323                 # verify that we aren't overwriting anything:
2324                 $orig_url = eval {
2325                         command_oneline('config', '--get',
2326                                         "svn-remote.$self->{repo_id}.url")
2327                 };
2328                 if ($orig_url && ($orig_url ne $url)) {
2329                         die "svn-remote.$self->{repo_id}.url already set: ",
2330                             "$orig_url\nwanted to set to: $url\n";
2331                 }
2332         }
2333         my ($xrepo_id, $xpath) = find_ref($self->refname);
2334         if (!$no_write && defined $xpath) {
2335                 die "svn-remote.$xrepo_id.fetch already set to track ",
2336                     "$xpath:", $self->refname, "\n";
2337         }
2338         unless ($no_write) {
2339                 command_noisy('config',
2340                               "svn-remote.$self->{repo_id}.url", $url);
2341                 $self->{path} =~ s{^/}{};
2342                 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
2343                 command_noisy('config', '--add',
2344                               "svn-remote.$self->{repo_id}.fetch",
2345                               "$self->{path}:".$self->refname);
2346         }
2347         $self->{url} = $url;
2348 }
2349
2350 sub find_by_url { # repos_root and, path are optional
2351         my ($class, $full_url, $repos_root, $path) = @_;
2352
2353         return undef unless defined $full_url;
2354         remove_username($full_url);
2355         remove_username($repos_root) if defined $repos_root;
2356         my $remotes = read_all_remotes();
2357         if (defined $full_url && defined $repos_root && !defined $path) {
2358                 $path = $full_url;
2359                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
2360         }
2361         foreach my $repo_id (keys %$remotes) {
2362                 my $u = $remotes->{$repo_id}->{url} or next;
2363                 remove_username($u);
2364                 next if defined $repos_root && $repos_root ne $u;
2365
2366                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
2367                 foreach my $t (qw/branches tags/) {
2368                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
2369                                 resolve_local_globs($u, $fetch, $globspec);
2370                         }
2371                 }
2372                 my $p = $path;
2373                 my $rwr = rewrite_root({repo_id => $repo_id});
2374                 my $svm = $remotes->{$repo_id}->{svm}
2375                         if defined $remotes->{$repo_id}->{svm};
2376                 unless (defined $p) {
2377                         $p = $full_url;
2378                         my $z = $u;
2379                         my $prefix = '';
2380                         if ($rwr) {
2381                                 $z = $rwr;
2382                                 remove_username($z);
2383                         } elsif (defined $svm) {
2384                                 $z = $svm->{source};
2385                                 $prefix = $svm->{replace};
2386                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
2387                                 $prefix =~ s#/$##;
2388                         }
2389                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
2390                 }
2391                 foreach my $f (keys %$fetch) {
2392                         next if $f ne $p;
2393                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
2394                 }
2395         }
2396         undef;
2397 }
2398
2399 sub init {
2400         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
2401         my $self = _new($class, $repo_id, $ref_id, $path);
2402         if (defined $url) {
2403                 $self->init_remote_config($url, $no_write);
2404         }
2405         $self;
2406 }
2407
2408 sub find_ref {
2409         my ($ref_id) = @_;
2410         foreach (command(qw/config -l/)) {
2411                 next unless m!^svn-remote\.(.+)\.fetch=
2412                               \s*(.*?)\s*:\s*(.+?)\s*$!x;
2413                 my ($repo_id, $path, $ref) = ($1, $2, $3);
2414                 if ($ref eq $ref_id) {
2415                         $path = '' if ($path =~ m#^\./?#);
2416                         return ($repo_id, $path);
2417                 }
2418         }
2419         (undef, undef, undef);
2420 }
2421
2422 sub new {
2423         my ($class, $ref_id, $repo_id, $path) = @_;
2424         if (defined $ref_id && !defined $repo_id && !defined $path) {
2425                 ($repo_id, $path) = find_ref($ref_id);
2426                 if (!defined $repo_id) {
2427                         die "Could not find a \"svn-remote.*.fetch\" key ",
2428                             "in the repository configuration matching: ",
2429                             "$ref_id\n";
2430                 }
2431         }
2432         my $self = _new($class, $repo_id, $ref_id, $path);
2433         if (!defined $self->{path} || !length $self->{path}) {
2434                 my $fetch = command_oneline('config', '--get',
2435                                             "svn-remote.$repo_id.fetch",
2436                                             ":$ref_id\$") or
2437                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
2438                          "\":$ref_id\$\" in config\n";
2439                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
2440         }
2441         $self->{path} =~ s{/+}{/}g;
2442         $self->{path} =~ s{\A/}{};
2443         $self->{path} =~ s{/\z}{};
2444         $self->{url} = command_oneline('config', '--get',
2445                                        "svn-remote.$repo_id.url") or
2446                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
2447         $self->{pushurl} = eval { command_oneline('config', '--get',
2448                                   "svn-remote.$repo_id.pushurl") };
2449         $self->rebuild;
2450         $self;
2451 }
2452
2453 sub refname {
2454         my ($refname) = $_[0]->{ref_id} ;
2455
2456         # It cannot end with a slash /, we'll throw up on this because
2457         # SVN can't have directories with a slash in their name, either:
2458         if ($refname =~ m{/$}) {
2459                 die "ref: '$refname' ends with a trailing slash, this is ",
2460                     "not permitted by git nor Subversion\n";
2461         }
2462
2463         # It cannot have ASCII control character space, tilde ~, caret ^,
2464         # colon :, question-mark ?, asterisk *, space, or open bracket [
2465         # anywhere.
2466         #
2467         # Additionally, % must be escaped because it is used for escaping
2468         # and we want our escaped refname to be reversible
2469         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2470
2471         # no slash-separated component can begin with a dot .
2472         # /.* becomes /%2E*
2473         $refname =~ s{/\.}{/%2E}g;
2474
2475         # It cannot have two consecutive dots .. anywhere
2476         # .. becomes %2E%2E
2477         $refname =~ s{\.\.}{%2E%2E}g;
2478
2479         # trailing dots and .lock are not allowed
2480         # .$ becomes %2E and .lock becomes %2Elock
2481         $refname =~ s{\.(?=$|lock$)}{%2E};
2482
2483         # the sequence @{ is used to access the reflog
2484         # @{ becomes %40{
2485         $refname =~ s{\@\{}{%40\{}g;
2486
2487         return $refname;
2488 }
2489
2490 sub desanitize_refname {
2491         my ($refname) = @_;
2492         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2493         return $refname;
2494 }
2495
2496 sub svm_uuid {
2497         my ($self) = @_;
2498         return $self->{svm}->{uuid} if $self->svm;
2499         $self->ra;
2500         unless ($self->{svm}) {
2501                 die "SVM UUID not cached, and reading remotely failed\n";
2502         }
2503         $self->{svm}->{uuid};
2504 }
2505
2506 sub svm {
2507         my ($self) = @_;
2508         return $self->{svm} if $self->{svm};
2509         my $svm;
2510         # see if we have it in our config, first:
2511         eval {
2512                 my $section = "svn-remote.$self->{repo_id}";
2513                 $svm = {
2514                   source => tmp_config('--get', "$section.svm-source"),
2515                   uuid => tmp_config('--get', "$section.svm-uuid"),
2516                   replace => tmp_config('--get', "$section.svm-replace"),
2517                 }
2518         };
2519         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2520                 $self->{svm} = $svm;
2521         }
2522         $self->{svm};
2523 }
2524
2525 sub _set_svm_vars {
2526         my ($self, $ra) = @_;
2527         return $ra if $self->svm;
2528
2529         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2530                     "(svm:source, svm:uuid) ",
2531                     "from the following URLs:\n" );
2532         sub read_svm_props {
2533                 my ($self, $ra, $path, $r) = @_;
2534                 my $props = ($ra->get_dir($path, $r))[2];
2535                 my $src = $props->{'svm:source'};
2536                 my $uuid = $props->{'svm:uuid'};
2537                 return undef if (!$src || !$uuid);
2538
2539                 chomp($src, $uuid);
2540
2541                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2542                     or die "doesn't look right - svm:uuid is '$uuid'\n";
2543
2544                 # the '!' is used to mark the repos_root!/relative/path
2545                 $src =~ s{/?!/?}{/};
2546                 $src =~ s{/+$}{}; # no trailing slashes please
2547                 # username is of no interest
2548                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2549
2550                 my $replace = $ra->{url};
2551                 $replace .= "/$path" if length $path;
2552
2553                 my $section = "svn-remote.$self->{repo_id}";
2554                 tmp_config("$section.svm-source", $src);
2555                 tmp_config("$section.svm-replace", $replace);
2556                 tmp_config("$section.svm-uuid", $uuid);
2557                 $self->{svm} = {
2558                         source => $src,
2559                         uuid => $uuid,
2560                         replace => $replace
2561                 };
2562         }
2563
2564         my $r = $ra->get_latest_revnum;
2565         my $path = $self->{path};
2566         my %tried;
2567         while (length $path) {
2568                 unless ($tried{"$self->{url}/$path"}) {
2569                         return $ra if $self->read_svm_props($ra, $path, $r);
2570                         $tried{"$self->{url}/$path"} = 1;
2571                 }
2572                 $path =~ s#/?[^/]+$##;
2573         }
2574         die "Path: '$path' should be ''\n" if $path ne '';
2575         return $ra if $self->read_svm_props($ra, $path, $r);
2576         $tried{"$self->{url}/$path"} = 1;
2577
2578         if ($ra->{repos_root} eq $self->{url}) {
2579                 die @err, (map { "  $_\n" } keys %tried), "\n";
2580         }
2581
2582         # nope, make sure we're connected to the repository root:
2583         my $ok;
2584         my @tried_b;
2585         $path = $ra->{svn_path};
2586         $ra = Git::SVN::Ra->new($ra->{repos_root});
2587         while (length $path) {
2588                 unless ($tried{"$ra->{url}/$path"}) {
2589                         $ok = $self->read_svm_props($ra, $path, $r);
2590                         last if $ok;
2591                         $tried{"$ra->{url}/$path"} = 1;
2592                 }
2593                 $path =~ s#/?[^/]+$##;
2594         }
2595         die "Path: '$path' should be ''\n" if $path ne '';
2596         $ok ||= $self->read_svm_props($ra, $path, $r);
2597         $tried{"$ra->{url}/$path"} = 1;
2598         if (!$ok) {
2599                 die @err, (map { "  $_\n" } keys %tried), "\n";
2600         }
2601         Git::SVN::Ra->new($self->{url});
2602 }
2603
2604 sub svnsync {
2605         my ($self) = @_;
2606         return $self->{svnsync} if $self->{svnsync};
2607
2608         if ($self->no_metadata) {
2609                 die "Can't have both 'noMetadata' and ",
2610                     "'useSvnsyncProps' options set!\n";
2611         }
2612         if ($self->rewrite_root) {
2613                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2614                     "options set!\n";
2615         }
2616         if ($self->rewrite_uuid) {
2617                 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
2618                     "options set!\n";
2619         }
2620
2621         my $svnsync;
2622         # see if we have it in our config, first:
2623         eval {
2624                 my $section = "svn-remote.$self->{repo_id}";
2625
2626                 my $url = tmp_config('--get', "$section.svnsync-url");
2627                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2628                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2629
2630                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2631                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2632                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2633
2634                 $svnsync = { url => $url, uuid => $uuid }
2635         };
2636         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2637                 return $self->{svnsync} = $svnsync;
2638         }
2639
2640         my $err = "useSvnsyncProps set, but failed to read " .
2641                   "svnsync property: svn:sync-from-";
2642         my $rp = $self->ra->rev_proplist(0);
2643
2644         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2645         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2646                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2647
2648         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2649         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2650                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2651
2652         my $section = "svn-remote.$self->{repo_id}";
2653         tmp_config('--add', "$section.svnsync-uuid", $uuid);
2654         tmp_config('--add', "$section.svnsync-url", $url);
2655         return $self->{svnsync} = { url => $url, uuid => $uuid };
2656 }
2657
2658 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2659 # remote lookup (useful for 'git svn log').
2660 sub ra_uuid {
2661         my ($self) = @_;
2662         unless ($self->{ra_uuid}) {
2663                 my $key = "svn-remote.$self->{repo_id}.uuid";
2664                 my $uuid = eval { tmp_config('--get', $key) };
2665                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2666                         $self->{ra_uuid} = $uuid;
2667                 } else {
2668                         die "ra_uuid called without URL\n" unless $self->{url};
2669                         $self->{ra_uuid} = $self->ra->get_uuid;
2670                         tmp_config('--add', $key, $self->{ra_uuid});
2671                 }
2672         }
2673         $self->{ra_uuid};
2674 }
2675
2676 sub _set_repos_root {
2677         my ($self, $repos_root) = @_;
2678         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2679         $repos_root ||= $self->ra->{repos_root};
2680         tmp_config($k, $repos_root);
2681         $repos_root;
2682 }
2683
2684 sub repos_root {
2685         my ($self) = @_;
2686         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2687         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2688 }
2689
2690 sub ra {
2691         my ($self) = shift;
2692         my $ra = Git::SVN::Ra->new($self->{url});
2693         $self->_set_repos_root($ra->{repos_root});
2694         if ($self->use_svm_props && !$self->{svm}) {
2695                 if ($self->no_metadata) {
2696                         die "Can't have both 'noMetadata' and ",
2697                             "'useSvmProps' options set!\n";
2698                 } elsif ($self->use_svnsync_props) {
2699                         die "Can't have both 'useSvnsyncProps' and ",
2700                             "'useSvmProps' options set!\n";
2701                 }
2702                 $ra = $self->_set_svm_vars($ra);
2703                 $self->{-want_revprops} = 1;
2704         }
2705         $ra;
2706 }
2707
2708 # prop_walk(PATH, REV, SUB)
2709 # -------------------------
2710 # Recursively traverse PATH at revision REV and invoke SUB for each
2711 # directory that contains a SVN property.  SUB will be invoked as
2712 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2713 # Git::SVN, `path' the path to the directory where the properties
2714 # `props' were found.  The `path' will be relative to point of checkout,
2715 # that is, if url://repo/trunk is the current Git branch, and that
2716 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2717 # as `path' (note the trailing `/').
2718 sub prop_walk {
2719         my ($self, $path, $rev, $sub) = @_;
2720
2721         $path =~ s#^/##;
2722         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2723         $path =~ s#^/*#/#g;
2724         my $p = $path;
2725         # Strip the irrelevant part of the path.
2726         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2727         # Ensure the path is terminated by a `/'.
2728         $p =~ s#/*$#/#;
2729
2730         # The properties contain all the internal SVN stuff nobody
2731         # (usually) cares about.
2732         my $interesting_props = 0;
2733         foreach (keys %{$props}) {
2734                 # If it doesn't start with `svn:', it must be a
2735                 # user-defined property.
2736                 ++$interesting_props and next if $_ !~ /^svn:/;
2737                 # FIXME: Fragile, if SVN adds new public properties,
2738                 # this needs to be updated.
2739                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2740                                                  |eol-style|mime-type
2741                                                  |externals|needs-lock)$/x;
2742         }
2743         &$sub($self, $p, $props) if $interesting_props;
2744
2745         foreach (sort keys %$dirent) {
2746                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2747                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2748         }
2749 }
2750
2751 sub last_rev { ($_[0]->last_rev_commit)[0] }
2752 sub last_commit { ($_[0]->last_rev_commit)[1] }
2753
2754 # returns the newest SVN revision number and newest commit SHA1
2755 sub last_rev_commit {
2756         my ($self) = @_;
2757         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2758                 return ($self->{last_rev}, $self->{last_commit});
2759         }
2760         my $c = ::verify_ref($self->refname.'^0');
2761         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2762                 my $rev = (::cmt_metadata($c))[1];
2763                 if (defined $rev) {
2764                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2765                         return ($rev, $c);
2766                 }
2767         }
2768         my $map_path = $self->map_path;
2769         unless (-e $map_path) {
2770                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2771                 return (undef, undef);
2772         }
2773         my ($rev, $commit) = $self->rev_map_max(1);
2774         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2775         return ($rev, $commit);
2776 }
2777
2778 sub get_fetch_range {
2779         my ($self, $min, $max) = @_;
2780         $max ||= $self->ra->get_latest_revnum;
2781         $min ||= $self->rev_map_max;
2782         (++$min, $max);
2783 }
2784
2785 sub tmp_config {
2786         my (@args) = @_;
2787         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2788         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2789         if (! -f $config && -f $old_def_config) {
2790                 rename $old_def_config, $config or
2791                        die "Failed rename $old_def_config => $config: $!\n";
2792         }
2793         my $old_config = $ENV{GIT_CONFIG};
2794         $ENV{GIT_CONFIG} = $config;
2795         $@ = undef;
2796         my @ret = eval {
2797                 unless (-f $config) {
2798                         mkfile($config);
2799                         open my $fh, '>', $config or
2800                             die "Can't open $config: $!\n";
2801                         print $fh "; This file is used internally by ",
2802                                   "git-svn\n" or die
2803                                   "Couldn't write to $config: $!\n";
2804                         print $fh "; You should not have to edit it\n" or
2805                               die "Couldn't write to $config: $!\n";
2806                         close $fh or die "Couldn't close $config: $!\n";
2807                 }
2808                 command('config', @args);
2809         };
2810         my $err = $@;
2811         if (defined $old_config) {
2812                 $ENV{GIT_CONFIG} = $old_config;
2813         } else {
2814                 delete $ENV{GIT_CONFIG};
2815         }
2816         die $err if $err;
2817         wantarray ? @ret : $ret[0];
2818 }
2819
2820 sub tmp_index_do {
2821         my ($self, $sub) = @_;
2822         my $old_index = $ENV{GIT_INDEX_FILE};
2823         $ENV{GIT_INDEX_FILE} = $self->{index};
2824         $@ = undef;
2825         my @ret = eval {
2826                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2827                 mkpath([$dir]) unless -d $dir;
2828                 &$sub;
2829         };
2830         my $err = $@;
2831         if (defined $old_index) {
2832                 $ENV{GIT_INDEX_FILE} = $old_index;
2833         } else {
2834                 delete $ENV{GIT_INDEX_FILE};
2835         }
2836         die $err if $err;
2837         wantarray ? @ret : $ret[0];
2838 }
2839
2840 sub assert_index_clean {
2841         my ($self, $treeish) = @_;
2842
2843         $self->tmp_index_do(sub {
2844                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2845                 my $x = command_oneline('write-tree');
2846                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2847                            /^tree ($::sha1)/mo);
2848                 return if $y eq $x;
2849
2850                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2851                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2852                 command_noisy('read-tree', $treeish);
2853                 $x = command_oneline('write-tree');
2854                 if ($y ne $x) {
2855                         ::fatal "trees ($treeish) $y != $x\n",
2856                                 "Something is seriously wrong...";
2857                 }
2858         });
2859 }
2860
2861 sub get_commit_parents {
2862         my ($self, $log_entry) = @_;
2863         my (%seen, @ret, @tmp);
2864         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2865         if (my $ip = $self->{inject_parents}) {
2866                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2867                         push @tmp, $commit;
2868                 }
2869         }
2870         if (my $cur = ::verify_ref($self->refname.'^0')) {
2871                 push @tmp, $cur;
2872         }
2873         if (my $ipd = $self->{inject_parents_dcommit}) {
2874                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2875                         push @tmp, @$commit;
2876                 }
2877         }
2878         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2879         while (my $p = shift @tmp) {
2880                 next if $seen{$p};
2881                 $seen{$p} = 1;
2882                 push @ret, $p;
2883         }
2884         @ret;
2885 }
2886
2887 sub rewrite_root {
2888         my ($self) = @_;
2889         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2890         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2891         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2892         if ($rwr) {
2893                 $rwr =~ s#/+$##;
2894                 if ($rwr !~ m#^[a-z\+]+://#) {
2895                         die "$rwr is not a valid URL (key: $k)\n";
2896                 }
2897         }
2898         $self->{-rewrite_root} = $rwr;
2899 }
2900
2901 sub rewrite_uuid {
2902         my ($self) = @_;
2903         return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
2904         my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
2905         my $rwid = eval { command_oneline(qw/config --get/, $k) };
2906         if ($rwid) {
2907                 $rwid =~ s#/+$##;
2908                 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
2909                         die "$rwid is not a valid UUID (key: $k)\n";
2910                 }
2911         }
2912         $self->{-rewrite_uuid} = $rwid;
2913 }
2914
2915 sub metadata_url {
2916         my ($self) = @_;
2917         ($self->rewrite_root || $self->{url}) .
2918            (length $self->{path} ? '/' . $self->{path} : '');
2919 }
2920
2921 sub full_url {
2922         my ($self) = @_;
2923         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2924 }
2925
2926 sub full_pushurl {
2927         my ($self) = @_;
2928         if ($self->{pushurl}) {
2929                 return $self->{pushurl} . (length $self->{path} ? '/' .
2930                        $self->{path} : '');
2931         } else {
2932                 return $self->full_url;
2933         }
2934 }
2935
2936 sub set_commit_header_env {
2937         my ($log_entry) = @_;
2938         my %env;
2939         foreach my $ned (qw/NAME EMAIL DATE/) {
2940                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2941                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2942                 }
2943         }
2944
2945         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2946         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2947         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2948
2949         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2950                                                 ? $log_entry->{commit_name}
2951                                                 : $log_entry->{name};
2952         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2953                                                 ? $log_entry->{commit_email}
2954                                                 : $log_entry->{email};
2955         \%env;
2956 }
2957
2958 sub restore_commit_header_env {
2959         my ($env) = @_;
2960         foreach my $ned (qw/NAME EMAIL DATE/) {
2961                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2962                         my $k = "GIT_${ac}_${ned}";
2963                         if (defined $env->{$k}) {
2964                                 $ENV{$k} = $env->{$k};
2965                         } else {
2966                                 delete $ENV{$k};
2967                         }
2968                 }
2969         }
2970 }
2971
2972 sub gc {
2973         command_noisy('gc', '--auto');
2974 };
2975
2976 sub do_git_commit {
2977         my ($self, $log_entry) = @_;
2978         my $lr = $self->last_rev;
2979         if (defined $lr && $lr >= $log_entry->{revision}) {
2980                 die "Last fetched revision of ", $self->refname,
2981                     " was r$lr, but we are about to fetch: ",
2982                     "r$log_entry->{revision}!\n";
2983         }
2984         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2985                 croak "$log_entry->{revision} = $c already exists! ",
2986                       "Why are we refetching it?\n";
2987         }
2988         my $old_env = set_commit_header_env($log_entry);
2989         my $tree = $log_entry->{tree};
2990         if (!defined $tree) {
2991                 $tree = $self->tmp_index_do(sub {
2992                                             command_oneline('write-tree') });
2993         }
2994         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2995
2996         my @exec = ('git', 'commit-tree', $tree);
2997         foreach ($self->get_commit_parents($log_entry)) {
2998                 push @exec, '-p', $_;
2999         }
3000         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
3001                                                                    or croak $!;
3002         binmode $msg_fh;
3003
3004         # we always get UTF-8 from SVN, but we may want our commits in
3005         # a different encoding.
3006         if (my $enc = Git::config('i18n.commitencoding')) {
3007                 require Encode;
3008                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
3009         }
3010         print $msg_fh $log_entry->{log} or croak $!;
3011         restore_commit_header_env($old_env);
3012         unless ($self->no_metadata) {
3013                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
3014                               or croak $!;
3015         }
3016         $msg_fh->flush == 0 or croak $!;
3017         close $msg_fh or croak $!;
3018         chomp(my $commit = do { local $/; <$out_fh> });
3019         close $out_fh or croak $!;
3020         waitpid $pid, 0;
3021         croak $? if $?;
3022         if ($commit !~ /^$::sha1$/o) {
3023                 die "Failed to commit, invalid sha1: $commit\n";
3024         }
3025
3026         $self->rev_map_set($log_entry->{revision}, $commit, 1);
3027
3028         $self->{last_rev} = $log_entry->{revision};
3029         $self->{last_commit} = $commit;
3030         print "r$log_entry->{revision}" unless $::_q > 1;
3031         if (defined $log_entry->{svm_revision}) {
3032                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
3033                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
3034                                    0, $self->svm_uuid);
3035         }
3036         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
3037         if (--$_gc_nr == 0) {
3038                 $_gc_nr = $_gc_period;
3039                 gc();
3040         }
3041         return $commit;
3042 }
3043
3044 sub match_paths {
3045         my ($self, $paths, $r) = @_;
3046         return 1 if $self->{path} eq '';
3047         if (my $path = $paths->{"/$self->{path}"}) {
3048                 return ($path->{action} eq 'D') ? 0 : 1;
3049         }
3050         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
3051         if (grep /$self->{path_regex}/, keys %$paths) {
3052                 return 1;
3053         }
3054         my $c = '';
3055         foreach (split m#/#, $self->{path}) {
3056                 $c .= "/$_";
3057                 next unless ($paths->{$c} &&
3058                              ($paths->{$c}->{action} =~ /^[AR]$/));
3059                 if ($self->ra->check_path($self->{path}, $r) ==
3060                     $SVN::Node::dir) {
3061                         return 1;
3062                 }
3063         }
3064         return 0;
3065 }
3066
3067 sub find_parent_branch {
3068         my ($self, $paths, $rev) = @_;
3069         return undef unless $self->follow_parent;
3070         unless (defined $paths) {
3071                 my $err_handler = $SVN::Error::handler;
3072                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
3073                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
3074                                    sub { $paths = $_[0] });
3075                 $SVN::Error::handler = $err_handler;
3076         }
3077         return undef unless defined $paths;
3078
3079         # look for a parent from another branch:
3080         my @b_path_components = split m#/#, $self->{path};
3081         my @a_path_components;
3082         my $i;
3083         while (@b_path_components) {
3084                 $i = $paths->{'/'.join('/', @b_path_components)};
3085                 last if $i && defined $i->{copyfrom_path};
3086                 unshift(@a_path_components, pop(@b_path_components));
3087         }
3088         return undef unless defined $i && defined $i->{copyfrom_path};
3089         my $branch_from = $i->{copyfrom_path};
3090         if (@a_path_components) {
3091                 print STDERR "branch_from: $branch_from => ";
3092                 $branch_from .= '/'.join('/', @a_path_components);
3093                 print STDERR $branch_from, "\n";
3094         }
3095         my $r = $i->{copyfrom_rev};
3096         my $repos_root = $self->ra->{repos_root};
3097         my $url = $self->ra->{url};
3098         my $new_url = $url . $branch_from;
3099         print STDERR  "Found possible branch point: ",
3100                       "$new_url => ", $self->full_url, ", $r\n"
3101                       unless $::_q > 1;
3102         $branch_from =~ s#^/##;
3103         my $gs = $self->other_gs($new_url, $url,
3104                                  $branch_from, $r, $self->{ref_id});
3105         my ($r0, $parent) = $gs->find_rev_before($r, 1);
3106         {
3107                 my ($base, $head);
3108                 if (!defined $r0 || !defined $parent) {
3109                         ($base, $head) = parse_revision_argument(0, $r);
3110                 } else {
3111                         if ($r0 < $r) {
3112                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
3113                                         0, 1, sub { $base = $_[1] - 1 });
3114                         }
3115                 }
3116                 if (defined $base && $base <= $r) {
3117                         $gs->fetch($base, $r);
3118                 }
3119                 ($r0, $parent) = $gs->find_rev_before($r, 1);
3120         }
3121         if (defined $r0 && defined $parent) {
3122                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
3123                              unless $::_q > 1;
3124                 my $ed;
3125                 if ($self->ra->can_do_switch) {
3126                         $self->assert_index_clean($parent);
3127                         print STDERR "Following parent with do_switch\n"
3128                                      unless $::_q > 1;
3129                         # do_switch works with svn/trunk >= r22312, but that
3130                         # is not included with SVN 1.4.3 (the latest version
3131                         # at the moment), so we can't rely on it
3132                         $self->{last_rev} = $r0;
3133                         $self->{last_commit} = $parent;
3134                         $ed = SVN::Git::Fetcher->new($self, $gs->{path});
3135                         $gs->ra->gs_do_switch($r0, $rev, $gs,
3136                                               $self->full_url, $ed)
3137                           or die "SVN connection failed somewhere...\n";
3138                 } elsif ($self->ra->trees_match($new_url, $r0,
3139                                                 $self->full_url, $rev)) {
3140                         print STDERR "Trees match:\n",
3141                                      "  $new_url\@$r0\n",
3142                                      "  ${\$self->full_url}\@$rev\n",
3143                                      "Following parent with no changes\n"
3144                                      unless $::_q > 1;
3145                         $self->tmp_index_do(sub {
3146                             command_noisy('read-tree', $parent);
3147                         });
3148                         $self->{last_commit} = $parent;
3149                 } else {
3150                         print STDERR "Following parent with do_update\n"
3151                                      unless $::_q > 1;
3152                         $ed = SVN::Git::Fetcher->new($self);
3153                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
3154                           or die "SVN connection failed somewhere...\n";
3155                 }
3156                 print STDERR "Successfully followed parent\n" unless $::_q > 1;
3157                 return $self->make_log_entry($rev, [$parent], $ed);
3158         }
3159         return undef;
3160 }
3161
3162 sub do_fetch {
3163         my ($self, $paths, $rev) = @_;
3164         my $ed;
3165         my ($last_rev, @parents);
3166         if (my $lc = $self->last_commit) {
3167                 # we can have a branch that was deleted, then re-added
3168                 # under the same name but copied from another path, in
3169                 # which case we'll have multiple parents (we don't
3170                 # want to break the original ref, nor lose copypath info):
3171                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
3172                         push @{$log_entry->{parents}}, $lc;
3173                         return $log_entry;
3174                 }
3175                 $ed = SVN::Git::Fetcher->new($self);
3176                 $last_rev = $self->{last_rev};
3177                 $ed->{c} = $lc;
3178                 @parents = ($lc);
3179         } else {
3180                 $last_rev = $rev;
3181                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
3182                         return $log_entry;
3183                 }
3184                 $ed = SVN::Git::Fetcher->new($self);
3185         }
3186         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
3187                 die "SVN connection failed somewhere...\n";
3188         }
3189         $self->make_log_entry($rev, \@parents, $ed);
3190 }
3191
3192 sub mkemptydirs {
3193         my ($self, $r) = @_;
3194
3195         sub scan {
3196                 my ($r, $empty_dirs, $line) = @_;
3197                 if (defined $r && $line =~ /^r(\d+)$/) {
3198                         return 0 if $1 > $r;
3199                 } elsif ($line =~ /^  \+empty_dir: (.+)$/) {
3200                         $empty_dirs->{$1} = 1;
3201                 } elsif ($line =~ /^  \-empty_dir: (.+)$/) {
3202                         my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
3203                         delete @$empty_dirs{@d};
3204                 }
3205                 1; # continue
3206         };
3207
3208         my %empty_dirs = ();
3209         my $gz_file = "$self->{dir}/unhandled.log.gz";
3210         if (-f $gz_file) {
3211                 if (!$can_compress) {
3212                         warn "Compress::Zlib could not be found; ",
3213                              "empty directories in $gz_file will not be read\n";
3214                 } else {
3215                         my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
3216                                 die "Unable to open $gz_file: $!\n";
3217                         my $line;
3218                         while ($gz->gzreadline($line) > 0) {
3219                                 scan($r, \%empty_dirs, $line) or last;
3220                         }
3221                         $gz->gzclose;
3222                 }
3223         }
3224
3225         if (open my $fh, '<', "$self->{dir}/unhandled.log") {
3226                 binmode $fh or croak "binmode: $!";
3227                 while (<$fh>) {
3228                         scan($r, \%empty_dirs, $_) or last;
3229                 }
3230                 close $fh;
3231         }
3232
3233         my $strip = qr/\A\Q$self->{path}\E(?:\/|$)/;
3234         foreach my $d (sort keys %empty_dirs) {
3235                 $d = uri_decode($d);
3236                 $d =~ s/$strip//;
3237                 next unless length($d);
3238                 next if -d $d;
3239                 if (-e $d) {
3240                         warn "$d exists but is not a directory\n";
3241                 } else {
3242                         print "creating empty directory: $d\n";
3243                         mkpath([$d]);
3244                 }
3245         }
3246 }
3247
3248 sub get_untracked {
3249         my ($self, $ed) = @_;
3250         my @out;
3251         my $h = $ed->{empty};
3252         foreach (sort keys %$h) {
3253                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
3254                 push @out, "  $act: " . uri_encode($_);
3255                 warn "W: $act: $_\n";
3256         }
3257         foreach my $t (qw/dir_prop file_prop/) {
3258                 $h = $ed->{$t} or next;
3259                 foreach my $path (sort keys %$h) {
3260                         my $ppath = $path eq '' ? '.' : $path;
3261                         foreach my $prop (sort keys %{$h->{$path}}) {
3262                                 next if $SKIP_PROP{$prop};
3263                                 my $v = $h->{$path}->{$prop};
3264                                 my $t_ppath_prop = "$t: " .
3265                                                     uri_encode($ppath) . ' ' .
3266                                                     uri_encode($prop);
3267                                 if (defined $v) {
3268                                         push @out, "  +$t_ppath_prop " .
3269                                                    uri_encode($v);
3270                                 } else {
3271                                         push @out, "  -$t_ppath_prop";
3272                                 }
3273                         }
3274                 }
3275         }
3276         foreach my $t (qw/absent_file absent_directory/) {
3277                 $h = $ed->{$t} or next;
3278                 foreach my $parent (sort keys %$h) {
3279                         foreach my $path (sort @{$h->{$parent}}) {
3280                                 push @out, "  $t: " .
3281                                            uri_encode("$parent/$path");
3282                                 warn "W: $t: $parent/$path ",
3283                                      "Insufficient permissions?\n";
3284                         }
3285                 }
3286         }
3287         \@out;
3288 }
3289
3290 sub get_tz {
3291         # some systmes don't handle or mishandle %z, so be creative.
3292         my $t = shift || time;
3293         my $gm = timelocal(gmtime($t));
3294         my $sign = qw( + + - )[ $t <=> $gm ];
3295         return sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
3296 }
3297
3298 # parse_svn_date(DATE)
3299 # --------------------
3300 # Given a date (in UTC) from Subversion, return a string in the format
3301 # "<TZ Offset> <local date/time>" that Git will use.
3302 #
3303 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
3304 # is true we'll convert it to the local timezone instead.
3305 sub parse_svn_date {
3306         my $date = shift || return '+0000 1970-01-01 00:00:00';
3307         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
3308                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
3309                                          croak "Unable to parse date: $date\n";
3310         my $parsed_date;    # Set next.
3311
3312         if ($Git::SVN::_localtime) {
3313                 # Translate the Subversion datetime to an epoch time.
3314                 # Begin by switching ourselves to $date's timezone, UTC.
3315                 my $old_env_TZ = $ENV{TZ};
3316                 $ENV{TZ} = 'UTC';
3317
3318                 my $epoch_in_UTC =
3319                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
3320
3321                 # Determine our local timezone (including DST) at the
3322                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
3323                 # value of TZ, if any, at the time we were run.
3324                 if (defined $Git::SVN::Log::TZ) {
3325                         $ENV{TZ} = $Git::SVN::Log::TZ;
3326                 } else {
3327                         delete $ENV{TZ};
3328                 }
3329
3330                 my $our_TZ = get_tz();
3331
3332                 # This converts $epoch_in_UTC into our local timezone.
3333                 my ($sec, $min, $hour, $mday, $mon, $year,
3334                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
3335
3336                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
3337                                        $our_TZ, $year + 1900, $mon + 1,
3338                                        $mday, $hour, $min, $sec);
3339
3340                 # Reset us to the timezone in effect when we entered
3341                 # this routine.
3342                 if (defined $old_env_TZ) {
3343                         $ENV{TZ} = $old_env_TZ;
3344                 } else {
3345                         delete $ENV{TZ};
3346                 }
3347         } else {
3348                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
3349         }
3350
3351         return $parsed_date;
3352 }
3353
3354 sub other_gs {
3355         my ($self, $new_url, $url,
3356             $branch_from, $r, $old_ref_id) = @_;
3357         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
3358         unless ($gs) {
3359                 my $ref_id = $old_ref_id;
3360                 $ref_id =~ s/\@\d+-*$//;
3361                 $ref_id .= "\@$r";
3362                 # just grow a tail if we're not unique enough :x
3363                 $ref_id .= '-' while find_ref($ref_id);
3364                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
3365                 if ($u =~ s#^\Q$url\E(/|$)##) {
3366                         $p = $u;
3367                         $u = $url;
3368                         $repo_id = $self->{repo_id};
3369                 }
3370                 while (1) {
3371                         # It is possible to tag two different subdirectories at
3372                         # the same revision.  If the url for an existing ref
3373                         # does not match, we must either find a ref with a
3374                         # matching url or create a new ref by growing a tail.
3375                         $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
3376                         my (undef, $max_commit) = $gs->rev_map_max(1);
3377                         last if (!$max_commit);
3378                         my ($url) = ::cmt_metadata($max_commit);
3379                         last if ($url eq $gs->metadata_url);
3380                         $ref_id .= '-';
3381                 }
3382                 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
3383         }
3384         $gs
3385 }
3386
3387 sub call_authors_prog {
3388         my ($orig_author) = @_;
3389         $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
3390         my $author = `$::_authors_prog $orig_author`;
3391         if ($? != 0) {
3392                 die "$::_authors_prog failed with exit code $?\n"
3393         }
3394         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
3395                 my ($name, $email) = ($1, $2);
3396                 $email = undef if length $2 == 0;
3397                 return [$name, $email];
3398         } else {
3399                 die "Author: $orig_author: $::_authors_prog returned "
3400                         . "invalid author format: $author\n";
3401         }
3402 }
3403
3404 sub check_author {
3405         my ($author) = @_;
3406         if (!defined $author || length $author == 0) {
3407                 $author = '(no author)';
3408         }
3409         if (!defined $::users{$author}) {
3410                 if (defined $::_authors_prog) {
3411                         $::users{$author} = call_authors_prog($author);
3412                 } elsif (defined $::_authors) {
3413                         die "Author: $author not defined in $::_authors file\n";
3414                 }
3415         }
3416         $author;
3417 }
3418
3419 sub find_extra_svk_parents {
3420         my ($self, $ed, $tickets, $parents) = @_;
3421         # aha!  svk:merge property changed...
3422         my @tickets = split "\n", $tickets;
3423         my @known_parents;
3424         for my $ticket ( @tickets ) {
3425                 my ($uuid, $path, $rev) = split /:/, $ticket;
3426                 if ( $uuid eq $self->ra_uuid ) {
3427                         my $url = $self->{url};
3428                         my $repos_root = $url;
3429                         my $branch_from = $path;
3430                         $branch_from =~ s{^/}{};
3431                         my $gs = $self->other_gs($repos_root."/".$branch_from,
3432                                                  $url,
3433                                                  $branch_from,
3434                                                  $rev,
3435                                                  $self->{ref_id});
3436                         if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
3437                                 # wahey!  we found it, but it might be
3438                                 # an old one (!)
3439                                 push @known_parents, [ $rev, $commit ];
3440                         }
3441                 }
3442         }
3443         # Ordering matters; highest-numbered commit merge tickets
3444         # first, as they may account for later merge ticket additions
3445         # or changes.
3446         @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
3447         for my $parent ( @known_parents ) {
3448                 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
3449                 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3450                 my $new;
3451                 while ( <$msg_fh> ) {
3452                         $new=1;last;
3453                 }
3454                 command_close_pipe($msg_fh, $ctx);
3455                 if ( $new ) {
3456                         print STDERR
3457                             "Found merge parent (svk:merge ticket): $parent\n";
3458                         push @$parents, $parent;
3459                 }
3460         }
3461 }
3462
3463 sub lookup_svn_merge {
3464         my $uuid = shift;
3465         my $url = shift;
3466         my $merge = shift;
3467
3468         my ($source, $revs) = split ":", $merge;
3469         my $path = $source;
3470         $path =~ s{^/}{};
3471         my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
3472         if ( !$gs ) {
3473                 warn "Couldn't find revmap for $url$source\n";
3474                 return;
3475         }
3476         my @ranges = split ",", $revs;
3477         my ($tip, $tip_commit);
3478         my @merged_commit_ranges;
3479         # find the tip
3480         for my $range ( @ranges ) {
3481                 my ($bottom, $top) = split "-", $range;
3482                 $top ||= $bottom;
3483                 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
3484                 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
3485
3486                 unless ($top_commit and $bottom_commit) {
3487                         warn "W:unknown path/rev in svn:mergeinfo "
3488                                 ."dirprop: $source:$range\n";
3489                         next;
3490                 }
3491
3492                 if (scalar(command('rev-parse', "$bottom_commit^@"))) {
3493                         push @merged_commit_ranges,
3494                              "$bottom_commit^..$top_commit";
3495                 } else {
3496                         push @merged_commit_ranges, "$top_commit";
3497                 }
3498
3499                 if ( !defined $tip or $top > $tip ) {
3500                         $tip = $top;
3501                         $tip_commit = $top_commit;
3502                 }
3503         }
3504         return ($tip_commit, @merged_commit_ranges);
3505 }
3506
3507 sub _rev_list {
3508         my ($msg_fh, $ctx) = command_output_pipe(
3509                 "rev-list", @_,
3510                );
3511         my @rv;
3512         while ( <$msg_fh> ) {
3513                 chomp;
3514                 push @rv, $_;
3515         }
3516         command_close_pipe($msg_fh, $ctx);
3517         @rv;
3518 }
3519
3520 sub check_cherry_pick {
3521         my $base = shift;
3522         my $tip = shift;
3523         my $parents = shift;
3524         my @ranges = @_;
3525         my %commits = map { $_ => 1 }
3526                 _rev_list("--no-merges", $tip, "--not", $base, @$parents, "--");
3527         for my $range ( @ranges ) {
3528                 delete @commits{_rev_list($range, "--")};
3529         }
3530         for my $commit (keys %commits) {
3531                 if (has_no_changes($commit)) {
3532                         delete $commits{$commit};
3533                 }
3534         }
3535         return (keys %commits);
3536 }
3537
3538 sub has_no_changes {
3539         my $commit = shift;
3540
3541         my @revs = split / /, command_oneline(
3542                 qw(rev-list --parents -1 -m), $commit);
3543
3544         # Commits with no parents, e.g. the start of a partial branch,
3545         # have changes by definition.
3546         return 1 if (@revs < 2);
3547
3548         # Commits with multiple parents, e.g a merge, have no changes
3549         # by definition.
3550         return 0 if (@revs > 2);
3551
3552         return (command_oneline("rev-parse", "$commit^{tree}") eq
3553                 command_oneline("rev-parse", "$commit~1^{tree}"));
3554 }
3555
3556 # The GIT_DIR environment variable is not always set until after the command
3557 # line arguments are processed, so we can't memoize in a BEGIN block.
3558 {
3559         my $memoized = 0;
3560
3561         sub memoize_svn_mergeinfo_functions {
3562                 return if $memoized;
3563                 $memoized = 1;
3564
3565                 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
3566                 mkpath([$cache_path]) unless -d $cache_path;
3567
3568                 tie my %lookup_svn_merge_cache => 'Memoize::Storable',
3569                     "$cache_path/lookup_svn_merge.db", 'nstore';
3570                 memoize 'lookup_svn_merge',
3571                         SCALAR_CACHE => 'FAULT',
3572                         LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
3573                 ;
3574
3575                 tie my %check_cherry_pick_cache => 'Memoize::Storable',
3576                     "$cache_path/check_cherry_pick.db", 'nstore';
3577                 memoize 'check_cherry_pick',
3578                         SCALAR_CACHE => 'FAULT',
3579                         LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
3580                 ;
3581
3582                 tie my %has_no_changes_cache => 'Memoize::Storable',
3583                     "$cache_path/has_no_changes.db", 'nstore';
3584                 memoize 'has_no_changes',
3585                         SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
3586                         LIST_CACHE => 'FAULT',
3587                 ;
3588         }
3589
3590         sub unmemoize_svn_mergeinfo_functions {
3591                 return if not $memoized;
3592                 $memoized = 0;
3593
3594                 Memoize::unmemoize 'lookup_svn_merge';
3595                 Memoize::unmemoize 'check_cherry_pick';
3596                 Memoize::unmemoize 'has_no_changes';
3597         }
3598
3599         Memoize::memoize 'Git::SVN::repos_root';
3600 }
3601
3602 END {
3603         # Force cache writeout explicitly instead of waiting for
3604         # global destruction to avoid segfault in Storable:
3605         # http://rt.cpan.org/Public/Bug/Display.html?id=36087
3606         unmemoize_svn_mergeinfo_functions();
3607 }
3608
3609 sub parents_exclude {
3610         my $parents = shift;
3611         my @commits = @_;
3612         return unless @commits;
3613
3614         my @excluded;
3615         my $excluded;
3616         do {
3617                 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
3618                 $excluded = command_oneline(@cmd);
3619                 if ( $excluded ) {
3620                         my @new;
3621                         my $found;
3622                         for my $commit ( @commits ) {
3623                                 if ( $commit eq $excluded ) {
3624                                         push @excluded, $commit;
3625                                         $found++;
3626                                         last;
3627                                 }
3628                                 else {
3629                                         push @new, $commit;
3630                                 }
3631                         }
3632                         die "saw commit '$excluded' in rev-list output, "
3633                                 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
3634                                         unless $found;
3635                         @commits = @new;
3636                 }
3637         }
3638                 while ($excluded and @commits);
3639
3640         return @excluded;
3641 }
3642
3643
3644 # note: this function should only be called if the various dirprops
3645 # have actually changed
3646 sub find_extra_svn_parents {
3647         my ($self, $ed, $mergeinfo, $parents) = @_;
3648         # aha!  svk:merge property changed...
3649
3650         memoize_svn_mergeinfo_functions();
3651
3652         # We first search for merged tips which are not in our
3653         # history.  Then, we figure out which git revisions are in
3654         # that tip, but not this revision.  If all of those revisions
3655         # are now marked as merge, we can add the tip as a parent.
3656         my @merges = split "\n", $mergeinfo;
3657         my @merge_tips;
3658         my $url = $self->{url};
3659         my $uuid = $self->ra_uuid;
3660         my %ranges;
3661         for my $merge ( @merges ) {
3662                 my ($tip_commit, @ranges) =
3663                         lookup_svn_merge( $uuid, $url, $merge );
3664                 unless (!$tip_commit or
3665                                 grep { $_ eq $tip_commit } @$parents ) {
3666                         push @merge_tips, $tip_commit;
3667                         $ranges{$tip_commit} = \@ranges;
3668                 } else {
3669                         push @merge_tips, undef;
3670                 }
3671         }
3672
3673         my %excluded = map { $_ => 1 }
3674                 parents_exclude($parents, grep { defined } @merge_tips);
3675
3676         # check merge tips for new parents
3677         my @new_parents;
3678         for my $merge_tip ( @merge_tips ) {
3679                 my $spec = shift @merges;
3680                 next unless $merge_tip and $excluded{$merge_tip};
3681
3682                 my $ranges = $ranges{$merge_tip};
3683
3684                 # check out 'new' tips
3685                 my $merge_base;
3686                 eval {
3687                         $merge_base = command_oneline(
3688                                 "merge-base",
3689                                 @$parents, $merge_tip,
3690                         );
3691                 };
3692                 if ($@) {
3693                         die "An error occurred during merge-base"
3694                                 unless $@->isa("Git::Error::Command");
3695
3696                         warn "W: Cannot find common ancestor between ".
3697                              "@$parents and $merge_tip. Ignoring merge info.\n";
3698                         next;
3699                 }
3700
3701                 # double check that there are no missing non-merge commits
3702                 my (@incomplete) = check_cherry_pick(
3703                         $merge_base, $merge_tip,
3704                         $parents,
3705                         @$ranges,
3706                        );
3707
3708                 if ( @incomplete ) {
3709                         warn "W:svn cherry-pick ignored ($spec) - missing "
3710                                 .@incomplete." commit(s) (eg $incomplete[0])\n";
3711                 } else {
3712                         warn
3713                                 "Found merge parent (svn:mergeinfo prop): ",
3714                                         $merge_tip, "\n";
3715                         push @new_parents, $merge_tip;
3716                 }
3717         }
3718
3719         # cater for merges which merge commits from multiple branches
3720         if ( @new_parents > 1 ) {
3721                 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
3722                         for ( my $j = 0; $j <= $#new_parents; $j++ ) {
3723                                 next if $i == $j;
3724                                 next unless $new_parents[$i];
3725                                 next unless $new_parents[$j];
3726                                 my $revs = command_oneline(
3727                                         "rev-list", "-1",
3728                                         "$new_parents[$i]..$new_parents[$j]",
3729                                        );
3730                                 if ( !$revs ) {
3731                                         undef($new_parents[$j]);
3732                                 }
3733                         }
3734                 }
3735         }
3736         push @$parents, grep { defined } @new_parents;
3737 }
3738
3739 sub make_log_entry {
3740         my ($self, $rev, $parents, $ed) = @_;
3741         my $untracked = $self->get_untracked($ed);
3742
3743         my @parents = @$parents;
3744         my $ps = $ed->{path_strip} || "";
3745         for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
3746                 my $props = $ed->{dir_prop}{$path};
3747                 if ( $props->{"svk:merge"} ) {
3748                         $self->find_extra_svk_parents
3749                                 ($ed, $props->{"svk:merge"}, \@parents);
3750                 }
3751                 if ( $props->{"svn:mergeinfo"} ) {
3752                         $self->find_extra_svn_parents
3753                                 ($ed,
3754                                  $props->{"svn:mergeinfo"},
3755                                  \@parents);
3756                 }
3757         }
3758
3759         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
3760         print $un "r$rev\n" or croak $!;
3761         print $un $_, "\n" foreach @$untracked;
3762         my %log_entry = ( parents => \@parents, revision => $rev,
3763                           log => '');
3764
3765         my $headrev;
3766         my $logged = delete $self->{logged_rev_props};
3767         if (!$logged || $self->{-want_revprops}) {
3768                 my $rp = $self->ra->rev_proplist($rev);
3769                 foreach (sort keys %$rp) {
3770                         my $v = $rp->{$_};
3771                         if (/^svn:(author|date|log)$/) {
3772                                 $log_entry{$1} = $v;
3773                         } elsif ($_ eq 'svm:headrev') {
3774                                 $headrev = $v;
3775                         } else {
3776                                 print $un "  rev_prop: ", uri_encode($_), ' ',
3777                                           uri_encode($v), "\n";
3778                         }
3779                 }
3780         } else {
3781                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
3782         }
3783         close $un or croak $!;
3784
3785         $log_entry{date} = parse_svn_date($log_entry{date});
3786         $log_entry{log} .= "\n";
3787         my $author = $log_entry{author} = check_author($log_entry{author});
3788         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
3789                                                        : ($author, undef);
3790
3791         my ($commit_name, $commit_email) = ($name, $email);
3792         if ($_use_log_author) {
3793                 my $name_field;
3794                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
3795                         $name_field = $1;
3796                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
3797                         $name_field = $1;
3798                 }
3799                 if (!defined $name_field) {
3800                         if (!defined $email) {
3801                                 $email = $name;
3802                         }
3803                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
3804                         ($name, $email) = ($1, $2);
3805                 } elsif ($name_field =~ /(.*)@/) {
3806                         ($name, $email) = ($1, $name_field);
3807                 } else {
3808                         ($name, $email) = ($name_field, $name_field);
3809                 }
3810         }
3811         if (defined $headrev && $self->use_svm_props) {
3812                 if ($self->rewrite_root) {
3813                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
3814                             "options set!\n";
3815                 }
3816                 if ($self->rewrite_uuid) {
3817                         die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
3818                             "options set!\n";
3819                 }
3820                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
3821                 # we don't want "SVM: initializing mirror for junk" ...
3822                 return undef if $r == 0;
3823                 my $svm = $self->svm;
3824                 if ($uuid ne $svm->{uuid}) {
3825                         die "UUID mismatch on SVM path:\n",
3826                             "expected: $svm->{uuid}\n",
3827                             "     got: $uuid\n";
3828                 }
3829                 my $full_url = $self->full_url;
3830                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
3831                              die "Failed to replace '$svm->{replace}' with ",
3832                                  "'$svm->{source}' in $full_url\n";
3833                 # throw away username for storing in records
3834                 remove_username($full_url);
3835                 $log_entry{metadata} = "$full_url\@$r $uuid";
3836                 $log_entry{svm_revision} = $r;
3837                 $email ||= "$author\@$uuid";
3838                 $commit_email ||= "$author\@$uuid";
3839         } elsif ($self->use_svnsync_props) {
3840                 my $full_url = $self->svnsync->{url};
3841                 $full_url .= "/$self->{path}" if length $self->{path};
3842                 remove_username($full_url);
3843                 my $uuid = $self->svnsync->{uuid};
3844                 $log_entry{metadata} = "$full_url\@$rev $uuid";
3845                 $email ||= "$author\@$uuid";
3846                 $commit_email ||= "$author\@$uuid";
3847         } else {
3848                 my $url = $self->metadata_url;
3849                 remove_username($url);
3850                 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
3851                 $log_entry{metadata} = "$url\@$rev " . $uuid;
3852                 $email ||= "$author\@" . $uuid;
3853                 $commit_email ||= "$author\@" . $uuid;
3854         }
3855         $log_entry{name} = $name;
3856         $log_entry{email} = $email;
3857         $log_entry{commit_name} = $commit_name;
3858         $log_entry{commit_email} = $commit_email;
3859         \%log_entry;
3860 }
3861
3862 sub fetch {
3863         my ($self, $min_rev, $max_rev, @parents) = @_;
3864         my ($last_rev, $last_commit) = $self->last_rev_commit;
3865         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
3866         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
3867 }
3868
3869 sub set_tree_cb {
3870         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
3871         $self->{inject_parents} = { $rev => $tree };
3872         $self->fetch(undef, undef);
3873 }
3874
3875 sub set_tree {
3876         my ($self, $tree) = (shift, shift);
3877         my $log_entry = ::get_commit_entry($tree);
3878         unless ($self->{last_rev}) {
3879                 ::fatal("Must have an existing revision to commit");
3880         }
3881         my %ed_opts = ( r => $self->{last_rev},
3882                         log => $log_entry->{log},
3883                         ra => $self->ra,
3884                         tree_a => $self->{last_commit},
3885                         tree_b => $tree,
3886                         editor_cb => sub {
3887                                $self->set_tree_cb($log_entry, $tree, @_) },
3888                         svn_path => $self->{path} );
3889         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
3890                 print "No changes\nr$self->{last_rev} = $tree\n";
3891         }
3892 }
3893
3894 sub rebuild_from_rev_db {
3895         my ($self, $path) = @_;
3896         my $r = -1;
3897         open my $fh, '<', $path or croak "open: $!";
3898         binmode $fh or croak "binmode: $!";
3899         while (<$fh>) {
3900                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3901                 chomp($_);
3902                 ++$r;
3903                 next if $_ eq ('0' x 40);
3904                 $self->rev_map_set($r, $_);
3905                 print "r$r = $_\n";
3906         }
3907         close $fh or croak "close: $!";
3908         unlink $path or croak "unlink: $!";
3909 }
3910
3911 sub rebuild {
3912         my ($self) = @_;
3913         my $map_path = $self->map_path;
3914         my $partial = (-e $map_path && ! -z $map_path);
3915         return unless ::verify_ref($self->refname.'^0');
3916         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3917                 my $rev_db = $self->rev_db_path;
3918                 $self->rebuild_from_rev_db($rev_db);
3919                 if ($self->use_svm_props) {
3920                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3921                         $self->rebuild_from_rev_db($svm_rev_db);
3922                 }
3923                 $self->unlink_rev_db_symlink;
3924                 return;
3925         }
3926         print "Rebuilding $map_path ...\n" if (!$partial);
3927         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3928                 (undef, undef));
3929         my ($log, $ctx) =
3930             command_output_pipe(qw/rev-list --pretty=raw --reverse/,
3931                                 ($head ? "$head.." : "") . $self->refname,
3932                                 '--');
3933         my $metadata_url = $self->metadata_url;
3934         remove_username($metadata_url);
3935         my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
3936         my $c;
3937         while (<$log>) {
3938                 if ( m{^commit ($::sha1)$} ) {
3939                         $c = $1;
3940                         next;
3941                 }
3942                 next unless s{^\s*(git-svn-id:)}{$1};
3943                 my ($url, $rev, $uuid) = ::extract_metadata($_);
3944                 remove_username($url);
3945
3946                 # ignore merges (from set-tree)
3947                 next if (!defined $rev || !$uuid);
3948
3949                 # if we merged or otherwise started elsewhere, this is
3950                 # how we break out of it
3951                 if (($uuid ne $svn_uuid) ||
3952                     ($metadata_url && $url && ($url ne $metadata_url))) {
3953                         next;
3954                 }
3955                 if ($partial && $head) {
3956                         print "Partial-rebuilding $map_path ...\n";
3957                         print "Currently at $base_rev = $head\n";
3958                         $head = undef;
3959                 }
3960
3961                 $self->rev_map_set($rev, $c);
3962                 print "r$rev = $c\n";
3963         }
3964         command_close_pipe($log, $ctx);
3965         print "Done rebuilding $map_path\n" if (!$partial || !$head);
3966         my $rev_db_path = $self->rev_db_path;
3967         if (-f $self->rev_db_path) {
3968                 unlink $self->rev_db_path or croak "unlink: $!";
3969         }
3970         $self->unlink_rev_db_symlink;
3971 }
3972
3973 # rev_map:
3974 # Tie::File seems to be prone to offset errors if revisions get sparse,
3975 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
3976 # one of my favorite modules is out :<  Next up would be one of the DBM
3977 # modules, but I'm not sure which is most portable...
3978 #
3979 # This is the replacement for the rev_db format, which was too big
3980 # and inefficient for large repositories with a lot of sparse history
3981 # (mainly tags)
3982 #
3983 # The format is this:
3984 #   - 24 bytes for every record,
3985 #     * 4 bytes for the integer representing an SVN revision number
3986 #     * 20 bytes representing the sha1 of a git commit
3987 #   - No empty padding records like the old format
3988 #     (except the last record, which can be overwritten)
3989 #   - new records are written append-only since SVN revision numbers
3990 #     increase monotonically
3991 #   - lookups on SVN revision number are done via a binary search
3992 #   - Piping the file to xxd -c24 is a good way of dumping it for
3993 #     viewing or editing (piped back through xxd -r), should the need
3994 #     ever arise.
3995 #   - The last record can be padding revision with an all-zero sha1
3996 #     This is used to optimize fetch performance when using multiple
3997 #     "fetch" directives in .git/config
3998 #
3999 # These files are disposable unless noMetadata or useSvmProps is set
4000
4001 sub _rev_map_set {
4002         my ($fh, $rev, $commit) = @_;
4003
4004         binmode $fh or croak "binmode: $!";
4005         my $size = (stat($fh))[7];
4006         ($size % 24) == 0 or croak "inconsistent size: $size";
4007
4008         my $wr_offset = 0;
4009         if ($size > 0) {
4010                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
4011                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
4012                 $read == 24 or croak "read only $read bytes (!= 24)";
4013                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
4014                 if ($last_commit eq ('0' x40)) {
4015                         if ($size >= 48) {
4016                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
4017                                 $read = sysread($fh, $buf, 24) or
4018                                     croak "read: $!";
4019                                 $read == 24 or
4020                                     croak "read only $read bytes (!= 24)";
4021                                 ($last_rev, $last_commit) =
4022                                     unpack(rev_map_fmt, $buf);
4023                                 if ($last_commit eq ('0' x40)) {
4024                                         croak "inconsistent .rev_map\n";
4025                                 }
4026                         }
4027                         if ($last_rev >= $rev) {
4028                                 croak "last_rev is higher!: $last_rev >= $rev";
4029                         }
4030                         $wr_offset = -24;
4031                 }
4032         }
4033         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
4034         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
4035           croak "write: $!";
4036 }
4037
4038 sub _rev_map_reset {
4039         my ($fh, $rev, $commit) = @_;
4040         my $c = _rev_map_get($fh, $rev);
4041         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
4042         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
4043         truncate $fh, $offset or croak "truncate: $!";
4044 }
4045
4046 sub mkfile {
4047         my ($path) = @_;
4048         unless (-e $path) {
4049                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
4050                 mkpath([$dir]) unless -d $dir;
4051                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
4052                 close $fh or die "Couldn't close (create) $path: $!\n";
4053         }
4054 }
4055
4056 sub rev_map_set {
4057         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
4058         defined $commit or die "missing arg3\n";
4059         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
4060         my $db = $self->map_path($uuid);
4061         my $db_lock = "$db.lock";
4062         my $sig;
4063         $update_ref ||= 0;
4064         if ($update_ref) {
4065                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
4066                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
4067         }
4068         mkfile($db);
4069
4070         $LOCKFILES{$db_lock} = 1;
4071         my $sync;
4072         # both of these options make our .rev_db file very, very important
4073         # and we can't afford to lose it because rebuild() won't work
4074         if ($self->use_svm_props || $self->no_metadata) {
4075                 $sync = 1;
4076                 copy($db, $db_lock) or die "rev_map_set(@_): ",
4077                                            "Failed to copy: ",
4078                                            "$db => $db_lock ($!)\n";
4079         } else {
4080                 rename $db, $db_lock or die "rev_map_set(@_): ",
4081                                             "Failed to rename: ",
4082                                             "$db => $db_lock ($!)\n";
4083         }
4084
4085         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
4086              or croak "Couldn't open $db_lock: $!\n";
4087         $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
4088                                  _rev_map_set($fh, $rev, $commit);
4089         if ($sync) {
4090                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
4091                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
4092         }
4093         close $fh or croak $!;
4094         if ($update_ref) {
4095                 $_head = $self;
4096                 my $note = "";
4097                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
4098                 command_noisy('update-ref', '-m', "r$rev$note",
4099                               $self->refname, $commit);
4100         }
4101         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
4102                                     "$db_lock => $db ($!)\n";
4103         delete $LOCKFILES{$db_lock};
4104         if ($update_ref) {
4105                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
4106                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
4107                 kill $sig, $$ if defined $sig;
4108         }
4109 }
4110
4111 # If want_commit, this will return an array of (rev, commit) where
4112 # commit _must_ be a valid commit in the archive.
4113 # Otherwise, it'll return the max revision (whether or not the
4114 # commit is valid or just a 0x40 placeholder).
4115 sub rev_map_max {
4116         my ($self, $want_commit) = @_;
4117         $self->rebuild;
4118         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
4119         $want_commit ? ($r, $c) : $r;
4120 }
4121
4122 sub rev_map_max_norebuild {
4123         my ($self, $want_commit) = @_;
4124         my $map_path = $self->map_path;
4125         stat $map_path or return $want_commit ? (0, undef) : 0;
4126         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
4127         binmode $fh or croak "binmode: $!";
4128         my $size = (stat($fh))[7];
4129         ($size % 24) == 0 or croak "inconsistent size: $size";
4130
4131         if ($size == 0) {
4132                 close $fh or croak "close: $!";
4133                 return $want_commit ? (0, undef) : 0;
4134         }
4135
4136         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
4137         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
4138         my ($r, $c) = unpack(rev_map_fmt, $buf);
4139         if ($want_commit && $c eq ('0' x40)) {
4140                 if ($size < 48) {
4141                         return $want_commit ? (0, undef) : 0;
4142                 }
4143                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
4144                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
4145                 ($r, $c) = unpack(rev_map_fmt, $buf);
4146                 if ($c eq ('0'x40)) {
4147                         croak "Penultimate record is all-zeroes in $map_path";
4148                 }
4149         }
4150         close $fh or croak "close: $!";
4151         $want_commit ? ($r, $c) : $r;
4152 }
4153
4154 sub rev_map_get {
4155         my ($self, $rev, $uuid) = @_;
4156         my $map_path = $self->map_path($uuid);
4157         return undef unless -e $map_path;
4158
4159         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
4160         my $c = _rev_map_get($fh, $rev);
4161         close($fh) or croak "close: $!";
4162         $c
4163 }
4164
4165 sub _rev_map_get {
4166         my ($fh, $rev) = @_;
4167
4168         binmode $fh or croak "binmode: $!";
4169         my $size = (stat($fh))[7];
4170         ($size % 24) == 0 or croak "inconsistent size: $size";
4171
4172         if ($size == 0) {
4173                 return undef;
4174         }
4175
4176         my ($l, $u) = (0, $size - 24);
4177         my ($r, $c, $buf);
4178
4179         while ($l <= $u) {
4180                 my $i = int(($l/24 + $u/24) / 2) * 24;
4181                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
4182                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
4183                 my ($r, $c) = unpack(rev_map_fmt, $buf);
4184
4185                 if ($r < $rev) {
4186                         $l = $i + 24;
4187                 } elsif ($r > $rev) {
4188                         $u = $i - 24;
4189                 } else { # $r == $rev
4190                         return $c eq ('0' x 40) ? undef : $c;
4191                 }
4192         }
4193         undef;
4194 }
4195
4196 # Finds the first svn revision that exists on (if $eq_ok is true) or
4197 # before $rev for the current branch.  It will not search any lower
4198 # than $min_rev.  Returns the git commit hash and svn revision number
4199 # if found, else (undef, undef).
4200 sub find_rev_before {
4201         my ($self, $rev, $eq_ok, $min_rev) = @_;
4202         --$rev unless $eq_ok;
4203         $min_rev ||= 1;
4204         my $max_rev = $self->rev_map_max;
4205         $rev = $max_rev if ($rev > $max_rev);
4206         while ($rev >= $min_rev) {
4207                 if (my $c = $self->rev_map_get($rev)) {
4208                         return ($rev, $c);
4209                 }
4210                 --$rev;
4211         }
4212         return (undef, undef);
4213 }
4214
4215 # Finds the first svn revision that exists on (if $eq_ok is true) or
4216 # after $rev for the current branch.  It will not search any higher
4217 # than $max_rev.  Returns the git commit hash and svn revision number
4218 # if found, else (undef, undef).
4219 sub find_rev_after {
4220         my ($self, $rev, $eq_ok, $max_rev) = @_;
4221         ++$rev unless $eq_ok;
4222         $max_rev ||= $self->rev_map_max;
4223         while ($rev <= $max_rev) {
4224                 if (my $c = $self->rev_map_get($rev)) {
4225                         return ($rev, $c);
4226                 }
4227                 ++$rev;
4228         }
4229         return (undef, undef);
4230 }
4231
4232 sub _new {
4233         my ($class, $repo_id, $ref_id, $path) = @_;
4234         unless (defined $repo_id && length $repo_id) {
4235                 $repo_id = $Git::SVN::default_repo_id;
4236         }
4237         unless (defined $ref_id && length $ref_id) {
4238                 $_prefix = '' unless defined($_prefix);
4239                 $_[2] = $ref_id =
4240                              "refs/remotes/$_prefix$Git::SVN::default_ref_id";
4241         }
4242         $_[1] = $repo_id;
4243         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
4244
4245         # Older repos imported by us used $GIT_DIR/svn/foo instead of
4246         # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
4247         if ($ref_id =~ m{^refs/remotes/(.*)}) {
4248                 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
4249                 if (-d $old_dir && ! -d $dir) {
4250                         $dir = $old_dir;
4251                 }
4252         }
4253
4254         $_[3] = $path = '' unless (defined $path);
4255         mkpath([$dir]);
4256         bless {
4257                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
4258                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
4259                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
4260 }
4261
4262 # for read-only access of old .rev_db formats
4263 sub unlink_rev_db_symlink {
4264         my ($self) = @_;
4265         my $link = $self->rev_db_path;
4266         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
4267         if (-l $link) {
4268                 unlink $link or croak "unlink: $link failed!";
4269         }
4270 }
4271
4272 sub rev_db_path {
4273         my ($self, $uuid) = @_;
4274         my $db_path = $self->map_path($uuid);
4275         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
4276             or croak "map_path: $db_path does not contain '/.rev_map.' !";
4277         $db_path;
4278 }
4279
4280 # the new replacement for .rev_db
4281 sub map_path {
4282         my ($self, $uuid) = @_;
4283         $uuid ||= $self->ra_uuid;
4284         "$self->{map_root}.$uuid";
4285 }
4286
4287 sub uri_encode {
4288         my ($f) = @_;
4289         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
4290         $f
4291 }
4292
4293 sub uri_decode {
4294         my ($f) = @_;
4295         $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
4296         $f
4297 }
4298
4299 sub remove_username {
4300         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
4301 }
4302
4303 package Git::SVN::Prompt;
4304 use strict;
4305 use warnings;
4306 require SVN::Core;
4307 use vars qw/$_no_auth_cache $_username/;
4308
4309 sub simple {
4310         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
4311         $may_save = undef if $_no_auth_cache;
4312         $default_username = $_username if defined $_username;
4313         if (defined $default_username && length $default_username) {
4314                 if (defined $realm && length $realm) {
4315                         print STDERR "Authentication realm: $realm\n";
4316                         STDERR->flush;
4317                 }
4318                 $cred->username($default_username);
4319         } else {
4320                 username($cred, $realm, $may_save, $pool);
4321         }
4322         $cred->password(_read_password("Password for '" .
4323                                        $cred->username . "': ", $realm));
4324         $cred->may_save($may_save);
4325         $SVN::_Core::SVN_NO_ERROR;
4326 }
4327
4328 sub ssl_server_trust {
4329         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
4330         $may_save = undef if $_no_auth_cache;
4331         print STDERR "Error validating server certificate for '$realm':\n";
4332         {
4333                 no warnings 'once';
4334                 # All variables SVN::Auth::SSL::* are used only once,
4335                 # so we're shutting up Perl warnings about this.
4336                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
4337                         print STDERR " - The certificate is not issued ",
4338                             "by a trusted authority. Use the\n",
4339                             "   fingerprint to validate ",
4340                             "the certificate manually!\n";
4341                 }
4342                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
4343                         print STDERR " - The certificate hostname ",
4344                             "does not match.\n";
4345                 }
4346                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
4347                         print STDERR " - The certificate is not yet valid.\n";
4348                 }
4349                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
4350                         print STDERR " - The certificate has expired.\n";
4351                 }
4352                 if ($failures & $SVN::Auth::SSL::OTHER) {
4353                         print STDERR " - The certificate has ",
4354                             "an unknown error.\n";
4355                 }
4356         } # no warnings 'once'
4357         printf STDERR
4358                 "Certificate information:\n".
4359                 " - Hostname: %s\n".
4360                 " - Valid: from %s until %s\n".
4361                 " - Issuer: %s\n".
4362                 " - Fingerprint: %s\n",
4363                 map $cert_info->$_, qw(hostname valid_from valid_until
4364                                        issuer_dname fingerprint);
4365         my $choice;
4366 prompt:
4367         print STDERR $may_save ?
4368               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
4369               "(R)eject or accept (t)emporarily? ";
4370         STDERR->flush;
4371         $choice = lc(substr(<STDIN> || 'R', 0, 1));
4372         if ($choice =~ /^t$/i) {
4373                 $cred->may_save(undef);
4374         } elsif ($choice =~ /^r$/i) {
4375                 return -1;
4376         } elsif ($may_save && $choice =~ /^p$/i) {
4377                 $cred->may_save($may_save);
4378         } else {
4379                 goto prompt;
4380         }
4381         $cred->accepted_failures($failures);
4382         $SVN::_Core::SVN_NO_ERROR;
4383 }
4384
4385 sub ssl_client_cert {
4386         my ($cred, $realm, $may_save, $pool) = @_;
4387         $may_save = undef if $_no_auth_cache;
4388         print STDERR "Client certificate filename: ";
4389         STDERR->flush;
4390         chomp(my $filename = <STDIN>);
4391         $cred->cert_file($filename);
4392         $cred->may_save($may_save);
4393         $SVN::_Core::SVN_NO_ERROR;
4394 }
4395
4396 sub ssl_client_cert_pw {
4397         my ($cred, $realm, $may_save, $pool) = @_;
4398         $may_save = undef if $_no_auth_cache;
4399         $cred->password(_read_password("Password: ", $realm));
4400         $cred->may_save($may_save);
4401         $SVN::_Core::SVN_NO_ERROR;
4402 }
4403
4404 sub username {
4405         my ($cred, $realm, $may_save, $pool) = @_;
4406         $may_save = undef if $_no_auth_cache;
4407         if (defined $realm && length $realm) {
4408                 print STDERR "Authentication realm: $realm\n";
4409         }
4410         my $username;
4411         if (defined $_username) {
4412                 $username = $_username;
4413         } else {
4414                 print STDERR "Username: ";
4415                 STDERR->flush;
4416                 chomp($username = <STDIN>);
4417         }
4418         $cred->username($username);
4419         $cred->may_save($may_save);
4420         $SVN::_Core::SVN_NO_ERROR;
4421 }
4422
4423 sub _read_password {
4424         my ($prompt, $realm) = @_;
4425         my $password = '';
4426         if (exists $ENV{GIT_ASKPASS}) {
4427                 open(PH, "-|", $ENV{GIT_ASKPASS}, $prompt);
4428                 $password = <PH>;
4429                 $password =~ s/[\012\015]//; # \n\r
4430                 close(PH);
4431         } else {
4432                 print STDERR $prompt;
4433                 STDERR->flush;
4434                 require Term::ReadKey;
4435                 Term::ReadKey::ReadMode('noecho');
4436                 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
4437                         last if $key =~ /[\012\015]/; # \n\r
4438                         $password .= $key;
4439                 }
4440                 Term::ReadKey::ReadMode('restore');
4441                 print STDERR "\n";
4442                 STDERR->flush;
4443         }
4444         $password;
4445 }
4446
4447 package SVN::Git::Fetcher;
4448 use vars qw/@ISA $_ignore_regex $_preserve_empty_dirs $_placeholder_filename
4449             @deleted_gpath %added_placeholder $repo_id/;
4450 use strict;
4451 use warnings;
4452 use Carp qw/croak/;
4453 use File::Basename qw/dirname/;
4454 use IO::File qw//;
4455
4456 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
4457 sub new {
4458         my ($class, $git_svn, $switch_path) = @_;
4459         my $self = SVN::Delta::Editor->new;
4460         bless $self, $class;
4461         if (exists $git_svn->{last_commit}) {
4462                 $self->{c} = $git_svn->{last_commit};
4463                 $self->{empty_symlinks} =
4464                                   _mark_empty_symlinks($git_svn, $switch_path);
4465         }
4466
4467         # some options are read globally, but can be overridden locally
4468         # per [svn-remote "..."] section.  Command-line options will *NOT*
4469         # override options set in an [svn-remote "..."] section
4470         $repo_id = $git_svn->{repo_id};
4471         my $k = "svn-remote.$repo_id.ignore-paths";
4472         my $v = eval { command_oneline('config', '--get', $k) };
4473         $self->{ignore_regex} = $v;
4474
4475         $k = "svn-remote.$repo_id.preserve-empty-dirs";
4476         $v = eval { command_oneline('config', '--get', '--bool', $k) };
4477         if ($v && $v eq 'true') {
4478                 $_preserve_empty_dirs = 1;
4479                 $k = "svn-remote.$repo_id.placeholder-filename";
4480                 $v = eval { command_oneline('config', '--get', $k) };
4481                 $_placeholder_filename = $v;
4482         }
4483
4484         # Load the list of placeholder files added during previous invocations.
4485         $k = "svn-remote.$repo_id.added-placeholder";
4486         $v = eval { command_oneline('config', '--get-all', $k) };
4487         if ($_preserve_empty_dirs && $v) {
4488                 # command() prints errors to stderr, so we only call it if
4489                 # command_oneline() succeeded.
4490                 my @v = command('config', '--get-all', $k);
4491                 $added_placeholder{ dirname($_) } = $_ foreach @v;
4492         }
4493
4494         $self->{empty} = {};
4495         $self->{dir_prop} = {};
4496         $self->{file_prop} = {};
4497         $self->{absent_dir} = {};
4498         $self->{absent_file} = {};
4499         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
4500         $self->{pathnameencoding} = Git::config('svn.pathnameencoding');
4501         $self;
4502 }
4503
4504 # this uses the Ra object, so it must be called before do_{switch,update},
4505 # not inside them (when the Git::SVN::Fetcher object is passed) to
4506 # do_{switch,update}
4507 sub _mark_empty_symlinks {
4508         my ($git_svn, $switch_path) = @_;
4509         my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
4510         return {} if (!defined($bool)) || (defined($bool) && ! $bool);
4511
4512         my %ret;
4513         my ($rev, $cmt) = $git_svn->last_rev_commit;
4514         return {} unless ($rev && $cmt);
4515
4516         # allow the warning to be printed for each revision we fetch to
4517         # ensure the user sees it.  The user can also disable the workaround
4518         # on the repository even while git svn is running and the next
4519         # revision fetched will skip this expensive function.
4520         my $printed_warning;
4521         chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
4522         my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
4523         local $/ = "\0";
4524         my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
4525         $pfx .= '/' if length($pfx);
4526         while (<$ls>) {
4527                 chomp;
4528                 s/\A100644 blob $empty_blob\t//o or next;
4529                 unless ($printed_warning) {
4530                         print STDERR "Scanning for empty symlinks, ",
4531                                      "this may take a while if you have ",
4532                                      "many empty files\n",
4533                                      "You may disable this with `",
4534                                      "git config svn.brokenSymlinkWorkaround ",
4535                                      "false'.\n",
4536                                      "This may be done in a different ",
4537                                      "terminal without restarting ",
4538                                      "git svn\n";
4539                         $printed_warning = 1;
4540                 }
4541                 my $path = $_;
4542                 my (undef, $props) =
4543                                $git_svn->ra->get_file($pfx.$path, $rev, undef);
4544                 if ($props->{'svn:special'}) {
4545                         $ret{$path} = 1;
4546                 }
4547         }
4548         command_close_pipe($ls, $ctx);
4549         \%ret;
4550 }
4551
4552 # returns true if a given path is inside a ".git" directory
4553 sub in_dot_git {
4554         $_[0] =~ m{(?:^|/)\.git(?:/|$)};
4555 }
4556
4557 # return value: 0 -- don't ignore, 1 -- ignore
4558 sub is_path_ignored {
4559         my ($self, $path) = @_;
4560         return 1 if in_dot_git($path);
4561         return 1 if defined($self->{ignore_regex}) &&
4562                     $path =~ m!$self->{ignore_regex}!;
4563         return 0 unless defined($_ignore_regex);
4564         return 1 if $path =~ m!$_ignore_regex!o;
4565         return 0;
4566 }
4567
4568 sub set_path_strip {
4569         my ($self, $path) = @_;
4570         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
4571 }
4572
4573 sub open_root {
4574         { path => '' };
4575 }
4576
4577 sub open_directory {
4578         my ($self, $path, $pb, $rev) = @_;
4579         { path => $path };
4580 }
4581
4582 sub git_path {
4583         my ($self, $path) = @_;
4584         if (my $enc = $self->{pathnameencoding}) {
4585                 require Encode;
4586                 Encode::from_to($path, 'UTF-8', $enc);
4587         }
4588         if ($self->{path_strip}) {
4589                 $path =~ s!$self->{path_strip}!! or
4590                   die "Failed to strip path '$path' ($self->{path_strip})\n";
4591         }
4592         $path;
4593 }
4594
4595 sub delete_entry {
4596         my ($self, $path, $rev, $pb) = @_;
4597         return undef if $self->is_path_ignored($path);
4598
4599         my $gpath = $self->git_path($path);
4600         return undef if ($gpath eq '');
4601
4602         # remove entire directories.
4603         my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4604                          =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
4605         if ($tree) {
4606                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4607                                                      -r --name-only -z/,
4608                                                      $tree);
4609                 local $/ = "\0";
4610                 while (<$ls>) {
4611                         chomp;
4612                         my $rmpath = "$gpath/$_";
4613                         $self->{gii}->remove($rmpath);
4614                         print "\tD\t$rmpath\n" unless $::_q;
4615                 }
4616                 print "\tD\t$gpath/\n" unless $::_q;
4617                 command_close_pipe($ls, $ctx);
4618         } else {
4619                 $self->{gii}->remove($gpath);
4620                 print "\tD\t$gpath\n" unless $::_q;
4621         }
4622         # Don't add to @deleted_gpath if we're deleting a placeholder file.
4623         push @deleted_gpath, $gpath unless $added_placeholder{dirname($path)};
4624         $self->{empty}->{$path} = 0;
4625         undef;
4626 }
4627
4628 sub open_file {
4629         my ($self, $path, $pb, $rev) = @_;
4630         my ($mode, $blob);
4631
4632         goto out if $self->is_path_ignored($path);
4633
4634         my $gpath = $self->git_path($path);
4635         ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4636                              =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
4637         unless (defined $mode && defined $blob) {
4638                 die "$path was not found in commit $self->{c} (r$rev)\n";
4639         }
4640         if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
4641                 $mode = '120000';
4642         }
4643 out:
4644         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
4645           pool => SVN::Pool->new, action => 'M' };
4646 }
4647
4648 sub add_file {
4649         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
4650         my $mode;
4651
4652         if (!$self->is_path_ignored($path)) {
4653                 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4654                 delete $self->{empty}->{$dir};
4655                 $mode = '100644';
4656
4657                 if ($added_placeholder{$dir}) {
4658                         # Remove our placeholder file, if we created one.
4659                         delete_entry($self, $added_placeholder{$dir})
4660                                 unless $path eq $added_placeholder{$dir};
4661                         delete $added_placeholder{$dir}
4662                 }
4663         }
4664
4665         { path => $path, mode_a => $mode, mode_b => $mode,
4666           pool => SVN::Pool->new, action => 'A' };
4667 }
4668
4669 sub add_directory {
4670         my ($self, $path, $cp_path, $cp_rev) = @_;
4671         goto out if $self->is_path_ignored($path);
4672         my $gpath = $self->git_path($path);
4673         if ($gpath eq '') {
4674                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4675                                                      -r --name-only -z/,
4676                                                      $self->{c});
4677                 local $/ = "\0";
4678                 while (<$ls>) {
4679                         chomp;
4680                         $self->{gii}->remove($_);
4681                         print "\tD\t$_\n" unless $::_q;
4682                         push @deleted_gpath, $gpath;
4683                 }
4684                 command_close_pipe($ls, $ctx);
4685                 $self->{empty}->{$path} = 0;
4686         }
4687         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4688         delete $self->{empty}->{$dir};
4689         $self->{empty}->{$path} = 1;
4690
4691         if ($added_placeholder{$dir}) {
4692                 # Remove our placeholder file, if we created one.
4693                 delete_entry($self, $added_placeholder{$dir});
4694                 delete $added_placeholder{$dir}
4695         }
4696
4697 out:
4698         { path => $path };
4699 }
4700
4701 sub change_dir_prop {
4702         my ($self, $db, $prop, $value) = @_;
4703         return undef if $self->is_path_ignored($db->{path});
4704         $self->{dir_prop}->{$db->{path}} ||= {};
4705         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
4706         undef;
4707 }
4708
4709 sub absent_directory {
4710         my ($self, $path, $pb) = @_;
4711         return undef if $self->is_path_ignored($path);
4712         $self->{absent_dir}->{$pb->{path}} ||= [];
4713         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
4714         undef;
4715 }
4716
4717 sub absent_file {
4718         my ($self, $path, $pb) = @_;
4719         return undef if $self->is_path_ignored($path);
4720         $self->{absent_file}->{$pb->{path}} ||= [];
4721         push @{$self->{absent_file}->{$pb->{path}}}, $path;
4722         undef;
4723 }
4724
4725 sub change_file_prop {
4726         my ($self, $fb, $prop, $value) = @_;
4727         return undef if $self->is_path_ignored($fb->{path});
4728         if ($prop eq 'svn:executable') {
4729                 if ($fb->{mode_b} != 120000) {
4730                         $fb->{mode_b} = defined $value ? 100755 : 100644;
4731                 }
4732         } elsif ($prop eq 'svn:special') {
4733                 $fb->{mode_b} = defined $value ? 120000 : 100644;
4734         } else {
4735                 $self->{file_prop}->{$fb->{path}} ||= {};
4736                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
4737         }
4738         undef;
4739 }
4740
4741 sub apply_textdelta {
4742         my ($self, $fb, $exp) = @_;
4743         return undef if $self->is_path_ignored($fb->{path});
4744         my $fh = $::_repository->temp_acquire('svn_delta');
4745         # $fh gets auto-closed() by SVN::TxDelta::apply(),
4746         # (but $base does not,) so dup() it for reading in close_file
4747         open my $dup, '<&', $fh or croak $!;
4748         my $base = $::_repository->temp_acquire('git_blob');
4749
4750         if ($fb->{blob}) {
4751                 my ($base_is_link, $size);
4752
4753                 if ($fb->{mode_a} eq '120000' &&
4754                     ! $self->{empty_symlinks}->{$fb->{path}}) {
4755                         print $base 'link ' or die "print $!\n";
4756                         $base_is_link = 1;
4757                 }
4758         retry:
4759                 $size = $::_repository->cat_blob($fb->{blob}, $base);
4760                 die "Failed to read object $fb->{blob}" if ($size < 0);
4761
4762                 if (defined $exp) {
4763                         seek $base, 0, 0 or croak $!;
4764                         my $got = ::md5sum($base);
4765                         if ($got ne $exp) {
4766                                 my $err = "Checksum mismatch: ".
4767                                        "$fb->{path} $fb->{blob}\n" .
4768                                        "expected: $exp\n" .
4769                                        "     got: $got\n";
4770                                 if ($base_is_link) {
4771                                         warn $err,
4772                                              "Retrying... (possibly ",
4773                                              "a bad symlink from SVN)\n";
4774                                         $::_repository->temp_reset($base);
4775                                         $base_is_link = 0;
4776                                         goto retry;
4777                                 }
4778                                 die $err;
4779                         }
4780                 }
4781         }
4782         seek $base, 0, 0 or croak $!;
4783         $fb->{fh} = $fh;
4784         $fb->{base} = $base;
4785         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
4786 }
4787
4788 sub close_file {
4789         my ($self, $fb, $exp) = @_;
4790         return undef if $self->is_path_ignored($fb->{path});
4791
4792         my $hash;
4793         my $path = $self->git_path($fb->{path});
4794         if (my $fh = $fb->{fh}) {
4795                 if (defined $exp) {
4796                         seek($fh, 0, 0) or croak $!;
4797                         my $got = ::md5sum($fh);
4798                         if ($got ne $exp) {
4799                                 die "Checksum mismatch: $path\n",
4800                                     "expected: $exp\n    got: $got\n";
4801                         }
4802                 }
4803                 if ($fb->{mode_b} == 120000) {
4804                         sysseek($fh, 0, 0) or croak $!;
4805                         my $rd = sysread($fh, my $buf, 5);
4806
4807                         if (!defined $rd) {
4808                                 croak "sysread: $!\n";
4809                         } elsif ($rd == 0) {
4810                                 warn "$path has mode 120000",
4811                                      " but it points to nothing\n",
4812                                      "converting to an empty file with mode",
4813                                      " 100644\n";
4814                                 $fb->{mode_b} = '100644';
4815                         } elsif ($buf ne 'link ') {
4816                                 warn "$path has mode 120000",
4817                                      " but is not a link\n";
4818                         } else {
4819                                 my $tmp_fh = $::_repository->temp_acquire(
4820                                         'svn_hash');
4821                                 my $res;
4822                                 while ($res = sysread($fh, my $str, 1024)) {
4823                                         my $out = syswrite($tmp_fh, $str, $res);
4824                                         defined($out) && $out == $res
4825                                                 or croak("write ",
4826                                                         Git::temp_path($tmp_fh),
4827                                                         ": $!\n");
4828                                 }
4829                                 defined $res or croak $!;
4830
4831                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
4832                                 Git::temp_release($tmp_fh, 1);
4833                         }
4834                 }
4835
4836                 $hash = $::_repository->hash_and_insert_object(
4837                                 Git::temp_path($fh));
4838                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
4839
4840                 Git::temp_release($fb->{base}, 1);
4841                 Git::temp_release($fh, 1);
4842         } else {
4843                 $hash = $fb->{blob} or die "no blob information\n";
4844         }
4845         $fb->{pool}->clear;
4846         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
4847         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
4848         undef;
4849 }
4850
4851 sub abort_edit {
4852         my $self = shift;
4853         $self->{nr} = $self->{gii}->{nr};
4854         delete $self->{gii};
4855         $self->SUPER::abort_edit(@_);
4856 }
4857
4858 sub close_edit {
4859         my $self = shift;
4860
4861         if ($_preserve_empty_dirs) {
4862                 my @empty_dirs;
4863
4864                 # Any entry flagged as empty that also has an associated
4865                 # dir_prop represents a newly created empty directory.
4866                 foreach my $i (keys %{$self->{empty}}) {
4867                         push @empty_dirs, $i if exists $self->{dir_prop}->{$i};
4868                 }
4869
4870                 # Search for directories that have become empty due subsequent
4871                 # file deletes.
4872                 push @empty_dirs, $self->find_empty_directories();
4873
4874                 # Finally, add a placeholder file to each empty directory.
4875                 $self->add_placeholder_file($_) foreach (@empty_dirs);
4876
4877                 $self->stash_placeholder_list();
4878         }
4879
4880         $self->{git_commit_ok} = 1;
4881         $self->{nr} = $self->{gii}->{nr};
4882         delete $self->{gii};
4883         $self->SUPER::close_edit(@_);
4884 }
4885
4886 sub find_empty_directories {
4887         my ($self) = @_;
4888         my @empty_dirs;
4889         my %dirs = map { dirname($_) => 1 } @deleted_gpath;
4890
4891         foreach my $dir (sort keys %dirs) {
4892                 next if $dir eq ".";
4893
4894                 # If there have been any additions to this directory, there is
4895                 # no reason to check if it is empty.
4896                 my $skip_added = 0;
4897                 foreach my $t (qw/dir_prop file_prop/) {
4898                         foreach my $path (keys %{ $self->{$t} }) {
4899                                 if (exists $self->{$t}->{dirname($path)}) {
4900                                         $skip_added = 1;
4901                                         last;
4902                                 }
4903                         }
4904                         last if $skip_added;
4905                 }
4906                 next if $skip_added;
4907
4908                 # Use `git ls-tree` to get the filenames of this directory
4909                 # that existed prior to this particular commit.
4910                 my $ls = command('ls-tree', '-z', '--name-only',
4911                                  $self->{c}, "$dir/");
4912                 my %files = map { $_ => 1 } split(/\0/, $ls);
4913
4914                 # Remove the filenames that were deleted during this commit.
4915                 delete $files{$_} foreach (@deleted_gpath);
4916
4917                 # Report the directory if there are no filenames left.
4918                 push @empty_dirs, $dir unless (scalar %files);
4919         }
4920         @empty_dirs;
4921 }
4922
4923 sub add_placeholder_file {
4924         my ($self, $dir) = @_;
4925         my $path = "$dir/$_placeholder_filename";
4926         my $gpath = $self->git_path($path);
4927
4928         my $fh = $::_repository->temp_acquire($gpath);
4929         my $hash = $::_repository->hash_and_insert_object(Git::temp_path($fh));
4930         Git::temp_release($fh, 1);
4931         $self->{gii}->update('100644', $hash, $gpath) or croak $!;
4932
4933         # The directory should no longer be considered empty.
4934         delete $self->{empty}->{$dir} if exists $self->{empty}->{$dir};
4935
4936         # Keep track of any placeholder files we create.
4937         $added_placeholder{$dir} = $path;
4938 }
4939
4940 sub stash_placeholder_list {
4941         my ($self) = @_;
4942         my $k = "svn-remote.$repo_id.added-placeholder";
4943         my $v = eval { command_oneline('config', '--get-all', $k) };
4944         command_noisy('config', '--unset-all', $k) if $v;
4945         foreach (values %added_placeholder) {
4946                 command_noisy('config', '--add', $k, $_);
4947         }
4948 }
4949
4950 package SVN::Git::Editor;
4951 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
4952 use strict;
4953 use warnings;
4954 use Carp qw/croak/;
4955 use IO::File;
4956
4957 sub new {
4958         my ($class, $opts) = @_;
4959         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
4960                 die "$_ required!\n" unless (defined $opts->{$_});
4961         }
4962
4963         my $pool = SVN::Pool->new;
4964         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
4965         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
4966                                      $opts->{r}, $mods);
4967
4968         # $opts->{ra} functions should not be used after this:
4969         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
4970                                                 $opts->{editor_cb}, $pool);
4971         my $self = SVN::Delta::Editor->new(@ce, $pool);
4972         bless $self, $class;
4973         foreach (qw/svn_path r tree_a tree_b/) {
4974                 $self->{$_} = $opts->{$_};
4975         }
4976         $self->{url} = $opts->{ra}->{url};
4977         $self->{mods} = $mods;
4978         $self->{types} = $types;
4979         $self->{pool} = $pool;
4980         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
4981         $self->{rm} = { };
4982         $self->{path_prefix} = length $self->{svn_path} ?
4983                                "$self->{svn_path}/" : '';
4984         $self->{config} = $opts->{config};
4985         $self->{mergeinfo} = $opts->{mergeinfo};
4986         return $self;
4987 }
4988
4989 sub generate_diff {
4990         my ($tree_a, $tree_b) = @_;
4991         my @diff_tree = qw(diff-tree -z -r);
4992         if ($_cp_similarity) {
4993                 push @diff_tree, "-C$_cp_similarity";
4994         } else {
4995                 push @diff_tree, '-C';
4996         }
4997         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
4998         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
4999         push @diff_tree, $tree_a, $tree_b;
5000         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
5001         local $/ = "\0";
5002         my $state = 'meta';
5003         my @mods;
5004         while (<$diff_fh>) {
5005                 chomp $_; # this gets rid of the trailing "\0"
5006                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
5007                                         ($::sha1)\s($::sha1)\s
5008                                         ([MTCRAD])\d*$/xo) {
5009                         push @mods, {   mode_a => $1, mode_b => $2,
5010                                         sha1_a => $3, sha1_b => $4,
5011                                         chg => $5 };
5012                         if ($5 =~ /^(?:C|R)$/) {
5013                                 $state = 'file_a';
5014                         } else {
5015                                 $state = 'file_b';
5016                         }
5017                 } elsif ($state eq 'file_a') {
5018                         my $x = $mods[$#mods] or croak "Empty array\n";
5019                         if ($x->{chg} !~ /^(?:C|R)$/) {
5020                                 croak "Error parsing $_, $x->{chg}\n";
5021                         }
5022                         $x->{file_a} = $_;
5023                         $state = 'file_b';
5024                 } elsif ($state eq 'file_b') {
5025                         my $x = $mods[$#mods] or croak "Empty array\n";
5026                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
5027                                 croak "Error parsing $_, $x->{chg}\n";
5028                         }
5029                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
5030                                 croak "Error parsing $_, $x->{chg}\n";
5031                         }
5032                         $x->{file_b} = $_;
5033                         $state = 'meta';
5034                 } else {
5035                         croak "Error parsing $_\n";
5036                 }
5037         }
5038         command_close_pipe($diff_fh, $ctx);
5039         \@mods;
5040 }
5041
5042 sub check_diff_paths {
5043         my ($ra, $pfx, $rev, $mods) = @_;
5044         my %types;
5045         $pfx .= '/' if length $pfx;
5046
5047         sub type_diff_paths {
5048                 my ($ra, $types, $path, $rev) = @_;
5049                 my @p = split m#/+#, $path;
5050                 my $c = shift @p;
5051                 unless (defined $types->{$c}) {
5052                         $types->{$c} = $ra->check_path($c, $rev);
5053                 }
5054                 while (@p) {
5055                         $c .= '/' . shift @p;
5056                         next if defined $types->{$c};
5057                         $types->{$c} = $ra->check_path($c, $rev);
5058                 }
5059         }
5060
5061         foreach my $m (@$mods) {
5062                 foreach my $f (qw/file_a file_b/) {
5063                         next unless defined $m->{$f};
5064                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
5065                         if (length $pfx.$dir && ! defined $types{$dir}) {
5066                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
5067                         }
5068                 }
5069         }
5070         \%types;
5071 }
5072
5073 sub split_path {
5074         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
5075 }
5076
5077 sub repo_path {
5078         my ($self, $path) = @_;
5079         if (my $enc = $self->{pathnameencoding}) {
5080                 require Encode;
5081                 Encode::from_to($path, $enc, 'UTF-8');
5082         }
5083         $self->{path_prefix}.(defined $path ? $path : '');
5084 }
5085
5086 sub url_path {
5087         my ($self, $path) = @_;
5088         if ($self->{url} =~ m#^https?://#) {
5089                 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
5090         }
5091         $self->{url} . '/' . $self->repo_path($path);
5092 }
5093
5094 sub rmdirs {
5095         my ($self) = @_;
5096         my $rm = $self->{rm};
5097         delete $rm->{''}; # we never delete the url we're tracking
5098         return unless %$rm;
5099
5100         foreach (keys %$rm) {
5101                 my @d = split m#/#, $_;
5102                 my $c = shift @d;
5103                 $rm->{$c} = 1;
5104                 while (@d) {
5105                         $c .= '/' . shift @d;
5106                         $rm->{$c} = 1;
5107                 }
5108         }
5109         delete $rm->{$self->{svn_path}};
5110         delete $rm->{''}; # we never delete the url we're tracking
5111         return unless %$rm;
5112
5113         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
5114                                              $self->{tree_b});
5115         local $/ = "\0";
5116         while (<$fh>) {
5117                 chomp;
5118                 my @dn = split m#/#, $_;
5119                 while (pop @dn) {
5120                         delete $rm->{join '/', @dn};
5121                 }
5122                 unless (%$rm) {
5123                         close $fh;
5124                         return;
5125                 }
5126         }
5127         command_close_pipe($fh, $ctx);
5128
5129         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
5130         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
5131                 $self->close_directory($bat->{$d}, $p);
5132                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
5133                 print "\tD+\t$d/\n" unless $::_q;
5134                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
5135                 delete $bat->{$d};
5136         }
5137 }
5138
5139 sub open_or_add_dir {
5140         my ($self, $full_path, $baton, $deletions) = @_;
5141         my $t = $self->{types}->{$full_path};
5142         if (!defined $t) {
5143                 die "$full_path not known in r$self->{r} or we have a bug!\n";
5144         }
5145         {
5146                 no warnings 'once';
5147                 # SVN::Node::none and SVN::Node::file are used only once,
5148                 # so we're shutting up Perl's warnings about them.
5149                 if ($t == $SVN::Node::none || defined($deletions->{$full_path})) {
5150                         return $self->add_directory($full_path, $baton,
5151                             undef, -1, $self->{pool});
5152                 } elsif ($t == $SVN::Node::dir) {
5153                         return $self->open_directory($full_path, $baton,
5154                             $self->{r}, $self->{pool});
5155                 } # no warnings 'once'
5156                 print STDERR "$full_path already exists in repository at ",
5157                     "r$self->{r} and it is not a directory (",
5158                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
5159         } # no warnings 'once'
5160         exit 1;
5161 }
5162
5163 sub ensure_path {
5164         my ($self, $path, $deletions) = @_;
5165         my $bat = $self->{bat};
5166         my $repo_path = $self->repo_path($path);
5167         return $bat->{''} unless (length $repo_path);
5168
5169         my @p = split m#/+#, $repo_path;
5170         my $c = shift @p;
5171         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''}, $deletions);
5172         while (@p) {
5173                 my $c0 = $c;
5174                 $c .= '/' . shift @p;
5175                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0}, $deletions);
5176         }
5177         return $bat->{$c};
5178 }
5179
5180 # Subroutine to convert a globbing pattern to a regular expression.
5181 # From perl cookbook.
5182 sub glob2pat {
5183         my $globstr = shift;
5184         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
5185         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
5186         return '^' . $globstr . '$';
5187 }
5188
5189 sub check_autoprop {
5190         my ($self, $pattern, $properties, $file, $fbat) = @_;
5191         # Convert the globbing pattern to a regular expression.
5192         my $regex = glob2pat($pattern);
5193         # Check if the pattern matches the file name.
5194         if($file =~ m/($regex)/) {
5195                 # Parse the list of properties to set.
5196                 my @props = split(/;/, $properties);
5197                 foreach my $prop (@props) {
5198                         # Parse 'name=value' syntax and set the property.
5199                         if ($prop =~ /([^=]+)=(.*)/) {
5200                                 my ($n,$v) = ($1,$2);
5201                                 for ($n, $v) {
5202                                         s/^\s+//; s/\s+$//;
5203                                 }
5204                                 $self->change_file_prop($fbat, $n, $v);
5205                         }
5206                 }
5207         }
5208 }
5209
5210 sub apply_autoprops {
5211         my ($self, $file, $fbat) = @_;
5212         my $conf_t = ${$self->{config}}{'config'};
5213         no warnings 'once';
5214         # Check [miscellany]/enable-auto-props in svn configuration.
5215         if (SVN::_Core::svn_config_get_bool(
5216                 $conf_t,
5217                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
5218                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
5219                 0)) {
5220                 # Auto-props are enabled.  Enumerate them to look for matches.
5221                 my $callback = sub {
5222                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
5223                 };
5224                 SVN::_Core::svn_config_enumerate(
5225                         $conf_t,
5226                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
5227                         $callback);
5228         }
5229 }
5230
5231 sub A {
5232         my ($self, $m, $deletions) = @_;
5233         my ($dir, $file) = split_path($m->{file_b});
5234         my $pbat = $self->ensure_path($dir, $deletions);
5235         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
5236                                         undef, -1);
5237         print "\tA\t$m->{file_b}\n" unless $::_q;
5238         $self->apply_autoprops($file, $fbat);
5239         $self->chg_file($fbat, $m);
5240         $self->close_file($fbat,undef,$self->{pool});
5241 }
5242
5243 sub C {
5244         my ($self, $m, $deletions) = @_;
5245         my ($dir, $file) = split_path($m->{file_b});
5246         my $pbat = $self->ensure_path($dir, $deletions);
5247         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
5248                                 $self->url_path($m->{file_a}), $self->{r});
5249         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
5250         $self->chg_file($fbat, $m);
5251         $self->close_file($fbat,undef,$self->{pool});
5252 }
5253
5254 sub delete_entry {
5255         my ($self, $path, $pbat) = @_;
5256         my $rpath = $self->repo_path($path);
5257         my ($dir, $file) = split_path($rpath);
5258         $self->{rm}->{$dir} = 1;
5259         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
5260 }
5261
5262 sub R {
5263         my ($self, $m, $deletions) = @_;
5264         my ($dir, $file) = split_path($m->{file_b});
5265         my $pbat = $self->ensure_path($dir, $deletions);
5266         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
5267                                 $self->url_path($m->{file_a}), $self->{r});
5268         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
5269         $self->apply_autoprops($file, $fbat);
5270         $self->chg_file($fbat, $m);
5271         $self->close_file($fbat,undef,$self->{pool});
5272
5273         ($dir, $file) = split_path($m->{file_a});
5274         $pbat = $self->ensure_path($dir, $deletions);
5275         $self->delete_entry($m->{file_a}, $pbat);
5276 }
5277
5278 sub M {
5279         my ($self, $m, $deletions) = @_;
5280         my ($dir, $file) = split_path($m->{file_b});
5281         my $pbat = $self->ensure_path($dir, $deletions);
5282         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
5283                                 $pbat,$self->{r},$self->{pool});
5284         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
5285         $self->chg_file($fbat, $m);
5286         $self->close_file($fbat,undef,$self->{pool});
5287 }
5288
5289 sub T { shift->M(@_) }
5290
5291 sub change_file_prop {
5292         my ($self, $fbat, $pname, $pval) = @_;
5293         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
5294 }
5295
5296 sub change_dir_prop {
5297         my ($self, $pbat, $pname, $pval) = @_;
5298         $self->SUPER::change_dir_prop($pbat, $pname, $pval, $self->{pool});
5299 }
5300
5301 sub _chg_file_get_blob ($$$$) {
5302         my ($self, $fbat, $m, $which) = @_;
5303         my $fh = $::_repository->temp_acquire("git_blob_$which");
5304         if ($m->{"mode_$which"} =~ /^120/) {
5305                 print $fh 'link ' or croak $!;
5306                 $self->change_file_prop($fbat,'svn:special','*');
5307         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
5308                 $self->change_file_prop($fbat,'svn:special',undef);
5309         }
5310         my $blob = $m->{"sha1_$which"};
5311         return ($fh,) if ($blob =~ /^0{40}$/);
5312         my $size = $::_repository->cat_blob($blob, $fh);
5313         croak "Failed to read object $blob" if ($size < 0);
5314         $fh->flush == 0 or croak $!;
5315         seek $fh, 0, 0 or croak $!;
5316
5317         my $exp = ::md5sum($fh);
5318         seek $fh, 0, 0 or croak $!;
5319         return ($fh, $exp);
5320 }
5321
5322 sub chg_file {
5323         my ($self, $fbat, $m) = @_;
5324         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
5325                 $self->change_file_prop($fbat,'svn:executable','*');
5326         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
5327                 $self->change_file_prop($fbat,'svn:executable',undef);
5328         }
5329         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
5330         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
5331         my $pool = SVN::Pool->new;
5332         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
5333         if (-s $fh_a) {
5334                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
5335                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
5336                 if (defined $res) {
5337                         die "Unexpected result from send_txstream: $res\n",
5338                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
5339                 }
5340         } else {
5341                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
5342                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
5343                     if ($got ne $exp_b);
5344         }
5345         Git::temp_release($fh_b, 1);
5346         Git::temp_release($fh_a, 1);
5347         $pool->clear;
5348 }
5349
5350 sub D {
5351         my ($self, $m, $deletions) = @_;
5352         my ($dir, $file) = split_path($m->{file_b});
5353         my $pbat = $self->ensure_path($dir, $deletions);
5354         print "\tD\t$m->{file_b}\n" unless $::_q;
5355         $self->delete_entry($m->{file_b}, $pbat);
5356 }
5357
5358 sub close_edit {
5359         my ($self) = @_;
5360         my ($p,$bat) = ($self->{pool}, $self->{bat});
5361         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
5362                 next if $_ eq '';
5363                 $self->close_directory($bat->{$_}, $p);
5364         }
5365         $self->close_directory($bat->{''}, $p);
5366         $self->SUPER::close_edit($p);
5367         $p->clear;
5368 }
5369
5370 sub abort_edit {
5371         my ($self) = @_;
5372         $self->SUPER::abort_edit($self->{pool});
5373 }
5374
5375 sub DESTROY {
5376         my $self = shift;
5377         $self->SUPER::DESTROY(@_);
5378         $self->{pool}->clear;
5379 }
5380
5381 # this drives the editor
5382 sub apply_diff {
5383         my ($self) = @_;
5384         my $mods = $self->{mods};
5385         my %o = ( D => 0, C => 1, R => 2, A => 3, M => 4, T => 5 );
5386         my %deletions;
5387
5388         foreach my $m (@$mods) {
5389                 if ($m->{chg} eq "D") {
5390                         $deletions{$m->{file_b}} = 1;
5391                 }
5392         }
5393
5394         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
5395                 my $f = $m->{chg};
5396                 if (defined $o{$f}) {
5397                         $self->$f($m, \%deletions);
5398                 } else {
5399                         fatal("Invalid change type: $f");
5400                 }
5401         }
5402
5403         if (defined($self->{mergeinfo})) {
5404                 $self->change_dir_prop($self->{bat}{''}, "svn:mergeinfo",
5405                                        $self->{mergeinfo});
5406         }
5407         $self->rmdirs if $_rmdir;
5408         if (@$mods == 0 && !defined($self->{mergeinfo})) {
5409                 $self->abort_edit;
5410         } else {
5411                 $self->close_edit;
5412         }
5413         return scalar @$mods;
5414 }
5415
5416 package Git::SVN::Ra;
5417 use vars qw/@ISA $config_dir $_ignore_refs_regex $_log_window_size/;
5418 use strict;
5419 use warnings;
5420 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
5421
5422 BEGIN {
5423         # enforce temporary pool usage for some simple functions
5424         no strict 'refs';
5425         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
5426                       get_file/) {
5427                 my $SUPER = "SUPER::$f";
5428                 *$f = sub {
5429                         my $self = shift;
5430                         my $pool = SVN::Pool->new;
5431                         my @ret = $self->$SUPER(@_,$pool);
5432                         $pool->clear;
5433                         wantarray ? @ret : $ret[0];
5434                 };
5435         }
5436 }
5437
5438 sub _auth_providers () {
5439         [
5440           SVN::Client::get_simple_provider(),
5441           SVN::Client::get_ssl_server_trust_file_provider(),
5442           SVN::Client::get_simple_prompt_provider(
5443             \&Git::SVN::Prompt::simple, 2),
5444           SVN::Client::get_ssl_client_cert_file_provider(),
5445           SVN::Client::get_ssl_client_cert_prompt_provider(
5446             \&Git::SVN::Prompt::ssl_client_cert, 2),
5447           SVN::Client::get_ssl_client_cert_pw_file_provider(),
5448           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
5449             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
5450           SVN::Client::get_username_provider(),
5451           SVN::Client::get_ssl_server_trust_prompt_provider(
5452             \&Git::SVN::Prompt::ssl_server_trust),
5453           SVN::Client::get_username_prompt_provider(
5454             \&Git::SVN::Prompt::username, 2)
5455         ]
5456 }
5457
5458 sub escape_uri_only {
5459         my ($uri) = @_;
5460         my @tmp;
5461         foreach (split m{/}, $uri) {
5462                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
5463                 push @tmp, $_;
5464         }
5465         join('/', @tmp);
5466 }
5467
5468 sub escape_url {
5469         my ($url) = @_;
5470         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
5471                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
5472                 $url = "$scheme://$domain$uri";
5473         }
5474         $url;
5475 }
5476
5477 sub new {
5478         my ($class, $url) = @_;
5479         $url =~ s!/+$!!;
5480         return $RA if ($RA && $RA->{url} eq $url);
5481
5482         ::_req_svn();
5483
5484         SVN::_Core::svn_config_ensure($config_dir, undef);
5485         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
5486         my $config = SVN::Core::config_get_config($config_dir);
5487         $RA = undef;
5488         my $dont_store_passwords = 1;
5489         my $conf_t = ${$config}{'config'};
5490         {
5491                 no warnings 'once';
5492                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
5493                 # produces warnings that variables are used only once.
5494                 # I had not found the better way to shut them up, so
5495                 # the warnings of type 'once' are disabled in this block.
5496                 if (SVN::_Core::svn_config_get_bool($conf_t,
5497                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
5498                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
5499                     1) == 0) {
5500                         SVN::_Core::svn_auth_set_parameter($baton,
5501                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
5502                             bless (\$dont_store_passwords, "_p_void"));
5503                 }
5504                 if (SVN::_Core::svn_config_get_bool($conf_t,
5505                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
5506                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
5507                     1) == 0) {
5508                         $Git::SVN::Prompt::_no_auth_cache = 1;
5509                 }
5510         } # no warnings 'once'
5511         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
5512                               config => $config,
5513                               pool => SVN::Pool->new,
5514                               auth_provider_callbacks => $callbacks);
5515         $self->{url} = $url;
5516         $self->{svn_path} = $url;
5517         $self->{repos_root} = $self->get_repos_root;
5518         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
5519         $self->{cache} = { check_path => { r => 0, data => {} },
5520                            get_dir => { r => 0, data => {} } };
5521         $RA = bless $self, $class;
5522 }
5523
5524 sub check_path {
5525         my ($self, $path, $r) = @_;
5526         my $cache = $self->{cache}->{check_path};
5527         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
5528                 return $cache->{data}->{$path};
5529         }
5530         my $pool = SVN::Pool->new;
5531         my $t = $self->SUPER::check_path($path, $r, $pool);
5532         $pool->clear;
5533         if ($r != $cache->{r}) {
5534                 %{$cache->{data}} = ();
5535                 $cache->{r} = $r;
5536         }
5537         $cache->{data}->{$path} = $t;
5538 }
5539
5540 sub get_dir {
5541         my ($self, $dir, $r) = @_;
5542         my $cache = $self->{cache}->{get_dir};
5543         if ($r == $cache->{r}) {
5544                 if (my $x = $cache->{data}->{$dir}) {
5545                         return wantarray ? @$x : $x->[0];
5546                 }
5547         }
5548         my $pool = SVN::Pool->new;
5549         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
5550         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
5551         $pool->clear;
5552         if ($r != $cache->{r}) {
5553                 %{$cache->{data}} = ();
5554                 $cache->{r} = $r;
5555         }
5556         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
5557         wantarray ? (\%dirents, $r, $props) : \%dirents;
5558 }
5559
5560 sub DESTROY {
5561         # do not call the real DESTROY since we store ourselves in $RA
5562 }
5563
5564 # get_log(paths, start, end, limit,
5565 #         discover_changed_paths, strict_node_history, receiver)
5566 sub get_log {
5567         my ($self, @args) = @_;
5568         my $pool = SVN::Pool->new;
5569
5570         # svn_log_changed_path_t objects passed to get_log are likely to be
5571         # overwritten even if only the refs are copied to an external variable,
5572         # so we should dup the structures in their entirety.  Using an
5573         # externally passed pool (instead of our temporary and quickly cleared
5574         # pool in Git::SVN::Ra) does not help matters at all...
5575         my $receiver = pop @args;
5576         my $prefix = "/".$self->{svn_path};
5577         $prefix =~ s#/+($)##;
5578         my $prefix_regex = qr#^\Q$prefix\E#;
5579         push(@args, sub {
5580                 my ($paths) = $_[0];
5581                 return &$receiver(@_) unless $paths;
5582                 $_[0] = ();
5583                 foreach my $p (keys %$paths) {
5584                         my $i = $paths->{$p};
5585                         # Make path relative to our url, not repos_root
5586                         $p =~ s/$prefix_regex//;
5587                         my %s = map { $_ => $i->$_; }
5588                                 qw/copyfrom_path copyfrom_rev action/;
5589                         if ($s{'copyfrom_path'}) {
5590                                 $s{'copyfrom_path'} =~ s/$prefix_regex//;
5591                         }
5592                         $_[0]{$p} = \%s;
5593                 }
5594                 &$receiver(@_);
5595         });
5596
5597
5598         # the limit parameter was not supported in SVN 1.1.x, so we
5599         # drop it.  Therefore, the receiver callback passed to it
5600         # is made aware of this limitation by being wrapped if
5601         # the limit passed to is being wrapped.
5602         if ($SVN::Core::VERSION le '1.2.0') {
5603                 my $limit = splice(@args, 3, 1);
5604                 if ($limit > 0) {
5605                         my $receiver = pop @args;
5606                         push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
5607                 }
5608         }
5609         my $ret = $self->SUPER::get_log(@args, $pool);
5610         $pool->clear;
5611         $ret;
5612 }
5613
5614 sub trees_match {
5615         my ($self, $url1, $rev1, $url2, $rev2) = @_;
5616         my $ctx = SVN::Client->new(auth => _auth_providers);
5617         my $out = IO::File->new_tmpfile;
5618
5619         # older SVN (1.1.x) doesn't take $pool as the last parameter for
5620         # $ctx->diff(), so we'll create a default one
5621         my $pool = SVN::Pool->new_default_sub;
5622
5623         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
5624         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
5625         $out->flush;
5626         my $ret = (($out->stat)[7] == 0);
5627         close $out or croak $!;
5628
5629         $ret;
5630 }
5631
5632 sub get_commit_editor {
5633         my ($self, $log, $cb, $pool) = @_;
5634         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
5635         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
5636 }
5637
5638 sub gs_do_update {
5639         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
5640         my $new = ($rev_a == $rev_b);
5641         my $path = $gs->{path};
5642
5643         if ($new && -e $gs->{index}) {
5644                 unlink $gs->{index} or die
5645                   "Couldn't unlink index: $gs->{index}: $!\n";
5646         }
5647         my $pool = SVN::Pool->new;
5648         $editor->set_path_strip($path);
5649         my (@pc) = split m#/#, $path;
5650         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
5651                                         1, $editor, $pool);
5652         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5653
5654         # Since we can't rely on svn_ra_reparent being available, we'll
5655         # just have to do some magic with set_path to make it so
5656         # we only want a partial path.
5657         my $sp = '';
5658         my $final = join('/', @pc);
5659         while (@pc) {
5660                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
5661                 $sp .= '/' if length $sp;
5662                 $sp .= shift @pc;
5663         }
5664         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
5665
5666         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
5667
5668         $reporter->finish_report($pool);
5669         $pool->clear;
5670         $editor->{git_commit_ok};
5671 }
5672
5673 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
5674 # svn_ra_reparent didn't work before 1.4)
5675 sub gs_do_switch {
5676         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
5677         my $path = $gs->{path};
5678         my $pool = SVN::Pool->new;
5679
5680         my $full_url = $self->{url};
5681         my $old_url = $full_url;
5682         $full_url .= '/' . $path if length $path;
5683         my ($ra, $reparented);
5684
5685         if ($old_url =~ m#^svn(\+ssh)?://# ||
5686             ($full_url =~ m#^https?://# &&
5687              escape_url($full_url) ne $full_url)) {
5688                 $_[0] = undef;
5689                 $self = undef;
5690                 $RA = undef;
5691                 $ra = Git::SVN::Ra->new($full_url);
5692                 $ra_invalid = 1;
5693         } elsif ($old_url ne $full_url) {
5694                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
5695                 $self->{url} = $full_url;
5696                 $reparented = 1;
5697         }
5698
5699         $ra ||= $self;
5700         $url_b = escape_url($url_b);
5701         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
5702         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5703         $reporter->set_path('', $rev_a, 0, @lock, $pool);
5704         $reporter->finish_report($pool);
5705
5706         if ($reparented) {
5707                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
5708                 $self->{url} = $old_url;
5709         }
5710
5711         $pool->clear;
5712         $editor->{git_commit_ok};
5713 }
5714
5715 sub longest_common_path {
5716         my ($gsv, $globs) = @_;
5717         my %common;
5718         my $common_max = scalar @$gsv;
5719
5720         foreach my $gs (@$gsv) {
5721                 my @tmp = split m#/#, $gs->{path};
5722                 my $p = '';
5723                 foreach (@tmp) {
5724                         $p .= length($p) ? "/$_" : $_;
5725                         $common{$p} ||= 0;
5726                         $common{$p}++;
5727                 }
5728         }
5729         $globs ||= [];
5730         $common_max += scalar @$globs;
5731         foreach my $glob (@$globs) {
5732                 my @tmp = split m#/#, $glob->{path}->{left};
5733                 my $p = '';
5734                 foreach (@tmp) {
5735                         $p .= length($p) ? "/$_" : $_;
5736                         $common{$p} ||= 0;
5737                         $common{$p}++;
5738                 }
5739         }
5740
5741         my $longest_path = '';
5742         foreach (sort {length $b <=> length $a} keys %common) {
5743                 if ($common{$_} == $common_max) {
5744                         $longest_path = $_;
5745                         last;
5746                 }
5747         }
5748         $longest_path;
5749 }
5750
5751 sub gs_fetch_loop_common {
5752         my ($self, $base, $head, $gsv, $globs) = @_;
5753         return if ($base > $head);
5754         my $inc = $_log_window_size;
5755         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
5756         my $longest_path = longest_common_path($gsv, $globs);
5757         my $ra_url = $self->{url};
5758         my $find_trailing_edge;
5759         while (1) {
5760                 my %revs;
5761                 my $err;
5762                 my $err_handler = $SVN::Error::handler;
5763                 $SVN::Error::handler = sub {
5764                         ($err) = @_;
5765                         skip_unknown_revs($err);
5766                 };
5767                 sub _cb {
5768                         my ($paths, $r, $author, $date, $log) = @_;
5769                         [ $paths,
5770                           { author => $author, date => $date, log => $log } ];
5771                 }
5772                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
5773                                sub { $revs{$_[1]} = _cb(@_) });
5774                 if ($err) {
5775                         print "Checked through r$max\r";
5776                 } else {
5777                         $find_trailing_edge = 1;
5778                 }
5779                 if ($err and $find_trailing_edge) {
5780                         print STDERR "Path '$longest_path' ",
5781                                      "was probably deleted:\n",
5782                                      $err->expanded_message,
5783                                      "\nWill attempt to follow ",
5784                                      "revisions r$min .. r$max ",
5785                                      "committed before the deletion\n";
5786                         my $hi = $max;
5787                         while (--$hi >= $min) {
5788                                 my $ok;
5789                                 $self->get_log([$longest_path], $min, $hi,
5790                                                0, 1, 1, sub {
5791                                                $ok = $_[1];
5792                                                $revs{$_[1]} = _cb(@_) });
5793                                 if ($ok) {
5794                                         print STDERR "r$min .. r$ok OK\n";
5795                                         last;
5796                                 }
5797                         }
5798                         $find_trailing_edge = 0;
5799                 }
5800                 $SVN::Error::handler = $err_handler;
5801
5802                 my %exists = map { $_->{path} => $_ } @$gsv;
5803                 foreach my $r (sort {$a <=> $b} keys %revs) {
5804                         my ($paths, $logged) = @{$revs{$r}};
5805
5806                         foreach my $gs ($self->match_globs(\%exists, $paths,
5807                                                            $globs, $r)) {
5808                                 if ($gs->rev_map_max >= $r) {
5809                                         next;
5810                                 }
5811                                 next unless $gs->match_paths($paths, $r);
5812                                 $gs->{logged_rev_props} = $logged;
5813                                 if (my $last_commit = $gs->last_commit) {
5814                                         $gs->assert_index_clean($last_commit);
5815                                 }
5816                                 my $log_entry = $gs->do_fetch($paths, $r);
5817                                 if ($log_entry) {
5818                                         $gs->do_git_commit($log_entry);
5819                                 }
5820                                 $INDEX_FILES{$gs->{index}} = 1;
5821                         }
5822                         foreach my $g (@$globs) {
5823                                 my $k = "svn-remote.$g->{remote}." .
5824                                         "$g->{t}-maxRev";
5825                                 Git::SVN::tmp_config($k, $r);
5826                         }
5827                         if ($ra_invalid) {
5828                                 $_[0] = undef;
5829                                 $self = undef;
5830                                 $RA = undef;
5831                                 $self = Git::SVN::Ra->new($ra_url);
5832                                 $ra_invalid = undef;
5833                         }
5834                 }
5835                 # pre-fill the .rev_db since it'll eventually get filled in
5836                 # with '0' x40 if something new gets committed
5837                 foreach my $gs (@$gsv) {
5838                         next if $gs->rev_map_max >= $max;
5839                         next if defined $gs->rev_map_get($max);
5840                         $gs->rev_map_set($max, 0 x40);
5841                 }
5842                 foreach my $g (@$globs) {
5843                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
5844                         Git::SVN::tmp_config($k, $max);
5845                 }
5846                 last if $max >= $head;
5847                 $min = $max + 1;
5848                 $max += $inc;
5849                 $max = $head if ($max > $head);
5850         }
5851         Git::SVN::gc();
5852 }
5853
5854 sub get_dir_globbed {
5855         my ($self, $left, $depth, $r) = @_;
5856
5857         my @x = eval { $self->get_dir($left, $r) };
5858         return unless scalar @x == 3;
5859         my $dirents = $x[0];
5860         my @finalents;
5861         foreach my $de (keys %$dirents) {
5862                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
5863                 if ($depth > 1) {
5864                         my @args = ("$left/$de", $depth - 1, $r);
5865                         foreach my $dir ($self->get_dir_globbed(@args)) {
5866                                 push @finalents, "$de/$dir";
5867                         }
5868                 } else {
5869                         push @finalents, $de;
5870                 }
5871         }
5872         @finalents;
5873 }
5874
5875 # return value: 0 -- don't ignore, 1 -- ignore
5876 sub is_ref_ignored {
5877         my ($g, $p) = @_;
5878         my $refname = $g->{ref}->full_path($p);
5879         return 1 if defined($g->{ignore_refs_regex}) &&
5880                     $refname =~ m!$g->{ignore_refs_regex}!;
5881         return 0 unless defined($_ignore_refs_regex);
5882         return 1 if $refname =~ m!$_ignore_refs_regex!o;
5883         return 0;
5884 }
5885
5886 sub match_globs {
5887         my ($self, $exists, $paths, $globs, $r) = @_;
5888
5889         sub get_dir_check {
5890                 my ($self, $exists, $g, $r) = @_;
5891
5892                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
5893                                                   $g->{path}->{depth},
5894                                                   $r);
5895
5896                 foreach my $de (@dirs) {
5897                         my $p = $g->{path}->full_path($de);
5898                         next if $exists->{$p};
5899                         next if (length $g->{path}->{right} &&
5900                                  ($self->check_path($p, $r) !=
5901                                   $SVN::Node::dir));
5902                         next unless $p =~ /$g->{path}->{regex}/;
5903                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
5904                                          $g->{ref}->full_path($de), 1);
5905                 }
5906         }
5907         foreach my $g (@$globs) {
5908                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
5909                         if ($path->{action} =~ /^[AR]$/) {
5910                                 get_dir_check($self, $exists, $g, $r);
5911                         }
5912                 }
5913                 foreach (keys %$paths) {
5914                         if (/$g->{path}->{left_regex}/ &&
5915                             !/$g->{path}->{regex}/) {
5916                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
5917                                 get_dir_check($self, $exists, $g, $r);
5918                         }
5919                         next unless /$g->{path}->{regex}/;
5920                         my $p = $1;
5921                         my $pathname = $g->{path}->full_path($p);
5922                         next if is_ref_ignored($g, $p);
5923                         next if $exists->{$pathname};
5924                         next if ($self->check_path($pathname, $r) !=
5925                                  $SVN::Node::dir);
5926                         $exists->{$pathname} = Git::SVN->init(
5927                                               $self->{url}, $pathname, undef,
5928                                               $g->{ref}->full_path($p), 1);
5929                 }
5930                 my $c = '';
5931                 foreach (split m#/#, $g->{path}->{left}) {
5932                         $c .= "/$_";
5933                         next unless ($paths->{$c} &&
5934                                      ($paths->{$c}->{action} =~ /^[AR]$/));
5935                         get_dir_check($self, $exists, $g, $r);
5936                 }
5937         }
5938         values %$exists;
5939 }
5940
5941 sub minimize_url {
5942         my ($self) = @_;
5943         return $self->{url} if ($self->{url} eq $self->{repos_root});
5944         my $url = $self->{repos_root};
5945         my @components = split(m!/!, $self->{svn_path});
5946         my $c = '';
5947         do {
5948                 $url .= "/$c" if length $c;
5949                 eval {
5950                         my $ra = (ref $self)->new($url);
5951                         my $latest = $ra->get_latest_revnum;
5952                         $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
5953                 };
5954         } while ($@ && ($c = shift @components));
5955         $url;
5956 }
5957
5958 sub can_do_switch {
5959         my $self = shift;
5960         unless (defined $can_do_switch) {
5961                 my $pool = SVN::Pool->new;
5962                 my $rep = eval {
5963                         $self->do_switch(1, '', 0, $self->{url},
5964                                          SVN::Delta::Editor->new, $pool);
5965                 };
5966                 if ($@) {
5967                         $can_do_switch = 0;
5968                 } else {
5969                         $rep->abort_report($pool);
5970                         $can_do_switch = 1;
5971                 }
5972                 $pool->clear;
5973         }
5974         $can_do_switch;
5975 }
5976
5977 sub skip_unknown_revs {
5978         my ($err) = @_;
5979         my $errno = $err->apr_err();
5980         # Maybe the branch we're tracking didn't
5981         # exist when the repo started, so it's
5982         # not an error if it doesn't, just continue
5983         #
5984         # Wonderfully consistent library, eh?
5985         # 160013 - svn:// and file://
5986         # 175002 - http(s)://
5987         # 175007 - http(s):// (this repo required authorization, too...)
5988         #   More codes may be discovered later...
5989         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
5990                 my $err_key = $err->expanded_message;
5991                 # revision numbers change every time, filter them out
5992                 $err_key =~ s/\d+/\0/g;
5993                 $err_key = "$errno\0$err_key";
5994                 unless ($ignored_err{$err_key}) {
5995                         warn "W: Ignoring error from SVN, path probably ",
5996                              "does not exist: ($errno): ",
5997                              $err->expanded_message,"\n";
5998                         warn "W: Do not be alarmed at the above message ",
5999                              "git-svn is just searching aggressively for ",
6000                              "old history.\n",
6001                              "This may take a while on large repositories\n";
6002                         $ignored_err{$err_key} = 1;
6003                 }
6004                 return;
6005         }
6006         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
6007 }
6008
6009 package Git::SVN::Log;
6010 use strict;
6011 use warnings;
6012 use POSIX qw/strftime/;
6013 use constant commit_log_separator => ('-' x 72) . "\n";
6014 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
6015             %rusers $show_commit $incremental/;
6016 my $l_fmt;
6017
6018 sub cmt_showable {
6019         my ($c) = @_;
6020         return 1 if defined $c->{r};
6021
6022         # big commit message got truncated by the 16k pretty buffer in rev-list
6023         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
6024                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
6025                 @{$c->{l}} = ();
6026                 my @log = command(qw/cat-file commit/, $c->{c});
6027
6028                 # shift off the headers
6029                 shift @log while ($log[0] ne '');
6030                 shift @log;
6031
6032                 # TODO: make $c->{l} not have a trailing newline in the future
6033                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
6034
6035                 (undef, $c->{r}, undef) = ::extract_metadata(
6036                                 (grep(/^git-svn-id: /, @log))[-1]);
6037         }
6038         return defined $c->{r};
6039 }
6040
6041 sub log_use_color {
6042         return $color || Git->repository->get_colorbool('color.diff');
6043 }
6044
6045 sub git_svn_log_cmd {
6046         my ($r_min, $r_max, @args) = @_;
6047         my $head = 'HEAD';
6048         my (@files, @log_opts);
6049         foreach my $x (@args) {
6050                 if ($x eq '--' || @files) {
6051                         push @files, $x;
6052                 } else {
6053                         if (::verify_ref("$x^0")) {
6054                                 $head = $x;
6055                         } else {
6056                                 push @log_opts, $x;
6057                         }
6058                 }
6059         }
6060
6061         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
6062         $gs ||= Git::SVN->_new;
6063         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
6064                    $gs->refname);
6065         push @cmd, '-r' unless $non_recursive;
6066         push @cmd, qw/--raw --name-status/ if $verbose;
6067         push @cmd, '--color' if log_use_color();
6068         push @cmd, @log_opts;
6069         if (defined $r_max && $r_max == $r_min) {
6070                 push @cmd, '--max-count=1';
6071                 if (my $c = $gs->rev_map_get($r_max)) {
6072                         push @cmd, $c;
6073                 }
6074         } elsif (defined $r_max) {
6075                 if ($r_max < $r_min) {
6076                         ($r_min, $r_max) = ($r_max, $r_min);
6077                 }
6078                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
6079                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
6080                 # If there are no commits in the range, both $c_max and $c_min
6081                 # will be undefined.  If there is at least 1 commit in the
6082                 # range, both will be defined.
6083                 return () if !defined $c_min || !defined $c_max;
6084                 if ($c_min eq $c_max) {
6085                         push @cmd, '--max-count=1', $c_min;
6086                 } else {
6087                         push @cmd, '--boundary', "$c_min..$c_max";
6088                 }
6089         }
6090         return (@cmd, @files);
6091 }
6092
6093 # adapted from pager.c
6094 sub config_pager {
6095         if (! -t *STDOUT) {
6096                 $ENV{GIT_PAGER_IN_USE} = 'false';
6097                 $pager = undef;
6098                 return;
6099         }
6100         chomp($pager = command_oneline(qw(var GIT_PAGER)));
6101         if ($pager eq 'cat') {
6102                 $pager = undef;
6103         }
6104         $ENV{GIT_PAGER_IN_USE} = defined($pager);
6105 }
6106
6107 sub run_pager {
6108         return unless defined $pager;
6109         pipe my ($rfd, $wfd) or return;
6110         defined(my $pid = fork) or ::fatal "Can't fork: $!";
6111         if (!$pid) {
6112                 open STDOUT, '>&', $wfd or
6113                                      ::fatal "Can't redirect to stdout: $!";
6114                 return;
6115         }
6116         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
6117         $ENV{LESS} ||= 'FRSX';
6118         exec $pager or ::fatal "Can't run pager: $! ($pager)";
6119 }
6120
6121 sub format_svn_date {
6122         my $t = shift || time;
6123         my $gmoff = Git::SVN::get_tz($t);
6124         return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
6125 }
6126
6127 sub parse_git_date {
6128         my ($t, $tz) = @_;
6129         # Date::Parse isn't in the standard Perl distro :(
6130         if ($tz =~ s/^\+//) {
6131                 $t += tz_to_s_offset($tz);
6132         } elsif ($tz =~ s/^\-//) {
6133                 $t -= tz_to_s_offset($tz);
6134         }
6135         return $t;
6136 }
6137
6138 sub set_local_timezone {
6139         if (defined $TZ) {
6140                 $ENV{TZ} = $TZ;
6141         } else {
6142                 delete $ENV{TZ};
6143         }
6144 }
6145
6146 sub tz_to_s_offset {
6147         my ($tz) = @_;
6148         $tz =~ s/(\d\d)$//;
6149         return ($1 * 60) + ($tz * 3600);
6150 }
6151
6152 sub get_author_info {
6153         my ($dest, $author, $t, $tz) = @_;
6154         $author =~ s/(?:^\s*|\s*$)//g;
6155         $dest->{a_raw} = $author;
6156         my $au;
6157         if ($::_authors) {
6158                 $au = $rusers{$author} || undef;
6159         }
6160         if (!$au) {
6161                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
6162         }
6163         $dest->{t} = $t;
6164         $dest->{tz} = $tz;
6165         $dest->{a} = $au;
6166         $dest->{t_utc} = parse_git_date($t, $tz);
6167 }
6168
6169 sub process_commit {
6170         my ($c, $r_min, $r_max, $defer) = @_;
6171         if (defined $r_min && defined $r_max) {
6172                 if ($r_min == $c->{r} && $r_min == $r_max) {
6173                         show_commit($c);
6174                         return 0;
6175                 }
6176                 return 1 if $r_min == $r_max;
6177                 if ($r_min < $r_max) {
6178                         # we need to reverse the print order
6179                         return 0 if (defined $limit && --$limit < 0);
6180                         push @$defer, $c;
6181                         return 1;
6182                 }
6183                 if ($r_min != $r_max) {
6184                         return 1 if ($r_min < $c->{r});
6185                         return 1 if ($r_max > $c->{r});
6186                 }
6187         }
6188         return 0 if (defined $limit && --$limit < 0);
6189         show_commit($c);
6190         return 1;
6191 }
6192
6193 sub show_commit {
6194         my $c = shift;
6195         if ($oneline) {
6196                 my $x = "\n";
6197                 if (my $l = $c->{l}) {
6198                         while ($l->[0] =~ /^\s*$/) { shift @$l }
6199                         $x = $l->[0];
6200                 }
6201                 $l_fmt ||= 'A' . length($c->{r});
6202                 print 'r',pack($l_fmt, $c->{r}),' | ';
6203                 print "$c->{c} | " if $show_commit;
6204                 print $x;
6205         } else {
6206                 show_commit_normal($c);
6207         }
6208 }
6209
6210 sub show_commit_changed_paths {
6211         my ($c) = @_;
6212         return unless $c->{changed};
6213         print "Changed paths:\n", @{$c->{changed}};
6214 }
6215
6216 sub show_commit_normal {
6217         my ($c) = @_;
6218         print commit_log_separator, "r$c->{r} | ";
6219         print "$c->{c} | " if $show_commit;
6220         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
6221         my $nr_line = 0;
6222
6223         if (my $l = $c->{l}) {
6224                 while ($l->[$#$l] eq "\n" && $#$l > 0
6225                                           && $l->[($#$l - 1)] eq "\n") {
6226                         pop @$l;
6227                 }
6228                 $nr_line = scalar @$l;
6229                 if (!$nr_line) {
6230                         print "1 line\n\n\n";
6231                 } else {
6232                         if ($nr_line == 1) {
6233                                 $nr_line = '1 line';
6234                         } else {
6235                                 $nr_line .= ' lines';
6236                         }
6237                         print $nr_line, "\n";
6238                         show_commit_changed_paths($c);
6239                         print "\n";
6240                         print $_ foreach @$l;
6241                 }
6242         } else {
6243                 print "1 line\n";
6244                 show_commit_changed_paths($c);
6245                 print "\n";
6246
6247         }
6248         foreach my $x (qw/raw stat diff/) {
6249                 if ($c->{$x}) {
6250                         print "\n";
6251                         print $_ foreach @{$c->{$x}}
6252                 }
6253         }
6254 }
6255
6256 sub cmd_show_log {
6257         my (@args) = @_;
6258         my ($r_min, $r_max);
6259         my $r_last = -1; # prevent dupes
6260         set_local_timezone();
6261         if (defined $::_revision) {
6262                 if ($::_revision =~ /^(\d+):(\d+)$/) {
6263                         ($r_min, $r_max) = ($1, $2);
6264                 } elsif ($::_revision =~ /^\d+$/) {
6265                         $r_min = $r_max = $::_revision;
6266                 } else {
6267                         ::fatal "-r$::_revision is not supported, use ",
6268                                 "standard 'git log' arguments instead";
6269                 }
6270         }
6271
6272         config_pager();
6273         @args = git_svn_log_cmd($r_min, $r_max, @args);
6274         if (!@args) {
6275                 print commit_log_separator unless $incremental || $oneline;
6276                 return;
6277         }
6278         my $log = command_output_pipe(@args);
6279         run_pager();
6280         my (@k, $c, $d, $stat);
6281         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
6282         while (<$log>) {
6283                 if (/^${esc_color}commit (?:- )?($::sha1_short)/o) {
6284                         my $cmt = $1;
6285                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
6286                                 $r_last = $c->{r};
6287                                 process_commit($c, $r_min, $r_max, \@k) or
6288                                                                 goto out;
6289                         }
6290                         $d = undef;
6291                         $c = { c => $cmt };
6292                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
6293                         get_author_info($c, $1, $2, $3);
6294                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
6295                         # ignore
6296                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
6297                         push @{$c->{raw}}, $_;
6298                 } elsif (/^${esc_color}[ACRMDT]\t/) {
6299                         # we could add $SVN->{svn_path} here, but that requires
6300                         # remote access at the moment (repo_path_split)...
6301                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
6302                         push @{$c->{changed}}, $_;
6303                 } elsif (/^${esc_color}diff /o) {
6304                         $d = 1;
6305                         push @{$c->{diff}}, $_;
6306                 } elsif ($d) {
6307                         push @{$c->{diff}}, $_;
6308                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
6309                           $esc_color*[\+\-]*$esc_color$/x) {
6310                         $stat = 1;
6311                         push @{$c->{stat}}, $_;
6312                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
6313                         push @{$c->{stat}}, $_;
6314                         $stat = undef;
6315                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
6316                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
6317                 } elsif (s/^${esc_color}    //o) {
6318                         push @{$c->{l}}, $_;
6319                 }
6320         }
6321         if ($c && defined $c->{r} && $c->{r} != $r_last) {
6322                 $r_last = $c->{r};
6323                 process_commit($c, $r_min, $r_max, \@k);
6324         }
6325         if (@k) {
6326                 ($r_min, $r_max) = ($r_max, $r_min);
6327                 process_commit($_, $r_min, $r_max) foreach reverse @k;
6328         }
6329 out:
6330         close $log;
6331         print commit_log_separator unless $incremental || $oneline;
6332 }
6333
6334 sub cmd_blame {
6335         my $path = pop;
6336
6337         config_pager();
6338         run_pager();
6339
6340         my ($fh, $ctx, $rev);
6341
6342         if ($_git_format) {
6343                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
6344                 while (my $line = <$fh>) {
6345                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
6346                                 # Uncommitted edits show up as a rev ID of
6347                                 # all zeros, which we can't look up with
6348                                 # cmt_metadata
6349                                 if ($1 !~ /^0+$/) {
6350                                         (undef, $rev, undef) =
6351                                                 ::cmt_metadata($1);
6352                                         $rev = '0' if (!$rev);
6353                                 } else {
6354                                         $rev = '0';
6355                                 }
6356                                 $rev = sprintf('%-10s', $rev);
6357                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
6358                         }
6359                         print $line;
6360                 }
6361         } else {
6362                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
6363                                                   '--', $path);
6364                 my ($sha1);
6365                 my %authors;
6366                 my @buffer;
6367                 my %dsha; #distinct sha keys
6368
6369                 while (my $line = <$fh>) {
6370                         push @buffer, $line;
6371                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
6372                                 $dsha{$1} = 1;
6373                         }
6374                 }
6375
6376                 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
6377
6378                 foreach my $line (@buffer) {
6379                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
6380                                 $rev = $s2r->{$1};
6381                                 $rev = '0' if (!$rev)
6382                         }
6383                         elsif ($line =~ /^author (.*)/) {
6384                                 $authors{$rev} = $1;
6385                                 $authors{$rev} =~ s/\s/_/g;
6386                         }
6387                         elsif ($line =~ /^\t(.*)$/) {
6388                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
6389                         }
6390                 }
6391         }
6392         command_close_pipe($fh, $ctx);
6393 }
6394
6395 package Git::SVN::Migration;
6396 # these version numbers do NOT correspond to actual version numbers
6397 # of git nor git-svn.  They are just relative.
6398 #
6399 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
6400 #
6401 # v1 layout: .git/$id/info/url, refs/remotes/$id
6402 #
6403 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
6404 #
6405 # v3 layout: .git/svn/$id, refs/remotes/$id
6406 #            - info/url may remain for backwards compatibility
6407 #            - this is what we migrate up to this layout automatically,
6408 #            - this will be used by git svn init on single branches
6409 # v3.1 layout (auto migrated):
6410 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
6411 #              for backwards compatibility
6412 #
6413 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
6414 #            - this is only created for newly multi-init-ed
6415 #              repositories.  Similar in spirit to the
6416 #              --use-separate-remotes option in git-clone (now default)
6417 #            - we do not automatically migrate to this (following
6418 #              the example set by core git)
6419 #
6420 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
6421 #            - newer, more-efficient format that uses 24-bytes per record
6422 #              with no filler space.
6423 #            - use xxd -c24 < .rev_map.$UUID to view and debug
6424 #            - This is a one-way migration, repositories updated to the
6425 #              new format will not be able to use old git-svn without
6426 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
6427 #              possible if noMetadata or useSvmProps are set; but should
6428 #              be no problem for users that use the (sensible) defaults.
6429 use strict;
6430 use warnings;
6431 use Carp qw/croak/;
6432 use File::Path qw/mkpath/;
6433 use File::Basename qw/dirname basename/;
6434 use vars qw/$_minimize/;
6435
6436 sub migrate_from_v0 {
6437         my $git_dir = $ENV{GIT_DIR};
6438         return undef unless -d $git_dir;
6439         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
6440         my $migrated = 0;
6441         while (<$fh>) {
6442                 chomp;
6443                 my ($id, $orig_ref) = ($_, $_);
6444                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
6445                 next unless -f "$git_dir/$id/info/url";
6446                 my $new_ref = "refs/remotes/$id";
6447                 if (::verify_ref("$new_ref^0")) {
6448                         print STDERR "W: $orig_ref is probably an old ",
6449                                      "branch used by an ancient version of ",
6450                                      "git-svn.\n",
6451                                      "However, $new_ref also exists.\n",
6452                                      "We will not be able ",
6453                                      "to use this branch until this ",
6454                                      "ambiguity is resolved.\n";
6455                         next;
6456                 }
6457                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
6458                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
6459                 command_noisy('update-ref', $new_ref, $orig_ref);
6460                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
6461                 $migrated++;
6462         }
6463         command_close_pipe($fh, $ctx);
6464         print STDERR "Done migrating from v0 layout...\n" if $migrated;
6465         $migrated;
6466 }
6467
6468 sub migrate_from_v1 {
6469         my $git_dir = $ENV{GIT_DIR};
6470         my $migrated = 0;
6471         return $migrated unless -d $git_dir;
6472         my $svn_dir = "$git_dir/svn";
6473
6474         # just in case somebody used 'svn' as their $id at some point...
6475         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
6476
6477         print STDERR "Migrating from a git-svn v1 layout...\n";
6478         mkpath([$svn_dir]);
6479         print STDERR "Data from a previous version of git-svn exists, but\n\t",
6480                      "$svn_dir\n\t(required for this version ",
6481                      "($::VERSION) of git-svn) does not exist.\n";
6482         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
6483         while (<$fh>) {
6484                 my $x = $_;
6485                 next unless $x =~ s#^refs/remotes/##;
6486                 chomp $x;
6487                 next unless -f "$git_dir/$x/info/url";
6488                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
6489                 next unless $u;
6490                 my $dn = dirname("$git_dir/svn/$x");
6491                 mkpath([$dn]) unless -d $dn;
6492                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
6493                         mkpath(["$git_dir/svn/svn"]);
6494                         print STDERR " - $git_dir/$x/info => ",
6495                                         "$git_dir/svn/$x/info\n";
6496                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
6497                                croak "$!: $x";
6498                         # don't worry too much about these, they probably
6499                         # don't exist with repos this old (save for index,
6500                         # and we can easily regenerate that)
6501                         foreach my $f (qw/unhandled.log index .rev_db/) {
6502                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
6503                         }
6504                 } else {
6505                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
6506                         rename "$git_dir/$x", "$git_dir/svn/$x" or
6507                                croak "$!: $x";
6508                 }
6509                 $migrated++;
6510         }
6511         command_close_pipe($fh, $ctx);
6512         print STDERR "Done migrating from a git-svn v1 layout\n";
6513         $migrated;
6514 }
6515
6516 sub read_old_urls {
6517         my ($l_map, $pfx, $path) = @_;
6518         my @dir;
6519         foreach (<$path/*>) {
6520                 if (-r "$_/info/url") {
6521                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
6522                         my $ref_id = $pfx . basename $_;
6523                         my $url = ::file_to_s("$_/info/url");
6524                         $l_map->{$ref_id} = $url;
6525                 } elsif (-d $_) {
6526                         push @dir, $_;
6527                 }
6528         }
6529         foreach (@dir) {
6530                 my $x = $_;
6531                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
6532                 read_old_urls($l_map, $x, $_);
6533         }
6534 }
6535
6536 sub migrate_from_v2 {
6537         my @cfg = command(qw/config -l/);
6538         return if grep /^svn-remote\..+\.url=/, @cfg;
6539         my %l_map;
6540         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
6541         my $migrated = 0;
6542
6543         foreach my $ref_id (sort keys %l_map) {
6544                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
6545                 if ($@) {
6546                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
6547                 }
6548                 $migrated++;
6549         }
6550         $migrated;
6551 }
6552
6553 sub minimize_connections {
6554         my $r = Git::SVN::read_all_remotes();
6555         my $new_urls = {};
6556         my $root_repos = {};
6557         foreach my $repo_id (keys %$r) {
6558                 my $url = $r->{$repo_id}->{url} or next;
6559                 my $fetch = $r->{$repo_id}->{fetch} or next;
6560                 my $ra = Git::SVN::Ra->new($url);
6561
6562                 # skip existing cases where we already connect to the root
6563                 if (($ra->{url} eq $ra->{repos_root}) ||
6564                     ($ra->{repos_root} eq $repo_id)) {
6565                         $root_repos->{$ra->{url}} = $repo_id;
6566                         next;
6567                 }
6568
6569                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
6570                 my $root_path = $ra->{url};
6571                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
6572                 foreach my $path (keys %$fetch) {
6573                         my $ref_id = $fetch->{$path};
6574                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
6575
6576                         # make sure we can read when connecting to
6577                         # a higher level of a repository
6578                         my ($last_rev, undef) = $gs->last_rev_commit;
6579                         if (!defined $last_rev) {
6580                                 $last_rev = eval {
6581                                         $root_ra->get_latest_revnum;
6582                                 };
6583                                 next if $@;
6584                         }
6585                         my $new = $root_path;
6586                         $new .= length $path ? "/$path" : '';
6587                         eval {
6588                                 $root_ra->get_log([$new], $last_rev, $last_rev,
6589                                                   0, 0, 1, sub { });
6590                         };
6591                         next if $@;
6592                         $new_urls->{$ra->{repos_root}}->{$new} =
6593                                 { ref_id => $ref_id,
6594                                   old_repo_id => $repo_id,
6595                                   old_path => $path };
6596                 }
6597         }
6598
6599         my @emptied;
6600         foreach my $url (keys %$new_urls) {
6601                 # see if we can re-use an existing [svn-remote "repo_id"]
6602                 # instead of creating a(n ugly) new section:
6603                 my $repo_id = $root_repos->{$url} || $url;
6604
6605                 my $fetch = $new_urls->{$url};
6606                 foreach my $path (keys %$fetch) {
6607                         my $x = $fetch->{$path};
6608                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
6609                         my $pfx = "svn-remote.$x->{old_repo_id}";
6610
6611                         my $old_fetch = quotemeta("$x->{old_path}:".
6612                                                   "$x->{ref_id}");
6613                         command_noisy(qw/config --unset/,
6614                                       "$pfx.fetch", '^'. $old_fetch . '$');
6615                         delete $r->{$x->{old_repo_id}}->
6616                                {fetch}->{$x->{old_path}};
6617                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
6618                                 command_noisy(qw/config --unset/,
6619                                               "$pfx.url");
6620                                 push @emptied, $x->{old_repo_id}
6621                         }
6622                 }
6623         }
6624         if (@emptied) {
6625                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
6626                 print STDERR <<EOF;
6627 The following [svn-remote] sections in your config file ($file) are empty
6628 and can be safely removed:
6629 EOF
6630                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
6631         }
6632 }
6633
6634 sub migration_check {
6635         migrate_from_v0();
6636         migrate_from_v1();
6637         migrate_from_v2();
6638         minimize_connections() if $_minimize;
6639 }
6640
6641 package Git::IndexInfo;
6642 use strict;
6643 use warnings;
6644 use Git qw/command_input_pipe command_close_pipe/;
6645
6646 sub new {
6647         my ($class) = @_;
6648         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
6649         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
6650 }
6651
6652 sub remove {
6653         my ($self, $path) = @_;
6654         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
6655                 return ++$self->{nr};
6656         }
6657         undef;
6658 }
6659
6660 sub update {
6661         my ($self, $mode, $hash, $path) = @_;
6662         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
6663                 return ++$self->{nr};
6664         }
6665         undef;
6666 }
6667
6668 sub DESTROY {
6669         my ($self) = @_;
6670         command_close_pipe($self->{gui}, $self->{ctx});
6671 }
6672
6673 package Git::SVN::GlobSpec;
6674 use strict;
6675 use warnings;
6676
6677 sub new {
6678         my ($class, $glob, $pattern_ok) = @_;
6679         my $re = $glob;
6680         $re =~ s!/+$!!g; # no need for trailing slashes
6681         my (@left, @right, @patterns);
6682         my $state = "left";
6683         my $die_msg = "Only one set of wildcard directories " .
6684                                 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
6685         for my $part (split(m|/|, $glob)) {
6686                 if ($part =~ /\*/ && $part ne "*") {
6687                         die "Invalid pattern in '$glob': $part\n";
6688                 } elsif ($pattern_ok && $part =~ /[{}]/ &&
6689                          $part !~ /^\{[^{}]+\}/) {
6690                         die "Invalid pattern in '$glob': $part\n";
6691                 }
6692                 if ($part eq "*") {
6693                         die $die_msg if $state eq "right";
6694                         $state = "pattern";
6695                         push(@patterns, "[^/]*");
6696                 } elsif ($pattern_ok && $part =~ /^\{(.*)\}$/) {
6697                         die $die_msg if $state eq "right";
6698                         $state = "pattern";
6699                         my $p = quotemeta($1);
6700                         $p =~ s/\\,/|/g;
6701                         push(@patterns, "(?:$p)");
6702                 } else {
6703                         if ($state eq "left") {
6704                                 push(@left, $part);
6705                         } else {
6706                                 push(@right, $part);
6707                                 $state = "right";
6708                         }
6709                 }
6710         }
6711         my $depth = @patterns;
6712         if ($depth == 0) {
6713                 die "One '*' is needed in glob: '$glob'\n";
6714         }
6715         my $left = join('/', @left);
6716         my $right = join('/', @right);
6717         $re = join('/', @patterns);
6718         $re = join('\/',
6719                    grep(length, quotemeta($left), "($re)", quotemeta($right)));
6720         my $left_re = qr/^\/\Q$left\E(\/|$)/;
6721         bless { left => $left, right => $right, left_regex => $left_re,
6722                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
6723 }
6724
6725 sub full_path {
6726         my ($self, $path) = @_;
6727         return (length $self->{left} ? "$self->{left}/" : '') .
6728                $path . (length $self->{right} ? "/$self->{right}" : '');
6729 }
6730
6731 __END__
6732
6733 Data structures:
6734
6735
6736 $remotes = { # returned by read_all_remotes()
6737         'svn' => {
6738                 # svn-remote.svn.url=https://svn.musicpd.org
6739                 url => 'https://svn.musicpd.org',
6740                 # svn-remote.svn.fetch=mpd/trunk:trunk
6741                 fetch => {
6742                         'mpd/trunk' => 'trunk',
6743                 },
6744                 # svn-remote.svn.tags=mpd/tags/*:tags/*
6745                 tags => {
6746                         path => {
6747                                 left => 'mpd/tags',
6748                                 right => '',
6749                                 regex => qr!mpd/tags/([^/]+)$!,
6750                                 glob => 'tags/*',
6751                         },
6752                         ref => {
6753                                 left => 'tags',
6754                                 right => '',
6755                                 regex => qr!tags/([^/]+)$!,
6756                                 glob => 'tags/*',
6757                         },
6758                 }
6759         }
6760 };
6761
6762 $log_entry hashref as returned by libsvn_log_entry()
6763 {
6764         log => 'whitespace-formatted log entry
6765 ',                                              # trailing newline is preserved
6766         revision => '8',                        # integer
6767         date => '2004-02-24T17:01:44.108345Z',  # commit date
6768         author => 'committer name'
6769 };
6770
6771
6772 # this is generated by generate_diff();
6773 @mods = array of diff-index line hashes, each element represents one line
6774         of diff-index output
6775
6776 diff-index line ($m hash)
6777 {
6778         mode_a => first column of diff-index output, no leading ':',
6779         mode_b => second column of diff-index output,
6780         sha1_b => sha1sum of the final blob,
6781         chg => change type [MCRADT],
6782         file_a => original file name of a file (iff chg is 'C' or 'R')
6783         file_b => new/current file name of a file (any chg)
6784 }
6785 ;
6786
6787 # retval of read_url_paths{,_all}();
6788 $l_map = {
6789         # repository root url
6790         'https://svn.musicpd.org' => {
6791                 # repository path               # GIT_SVN_ID
6792                 'mpd/trunk'             =>      'trunk',
6793                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
6794         },
6795 }
6796
6797 Notes:
6798         I don't trust the each() function on unless I created %hash myself
6799         because the internal iterator may not have started at base.