git.oblomov.eu Git - git/blob - perl/Git/SVN/Utils.pm

   1 package Git::SVN::Utils;
   2
   3 use strict;
   4 use warnings;
   5
   6 use SVN::Core;
   7
   8 use base qw(Exporter);
   9
  10 our @EXPORT_OK = qw(
  11         fatal
  12         can_compress
  13         canonicalize_path
  14         canonicalize_url
  15         join_paths
  16 );
  17
  18
  19 =head1 NAME
  20
  21 Git::SVN::Utils - utility functions used across Git::SVN
  22
  23 =head1 SYNOPSIS
  24
  25     use Git::SVN::Utils qw(functions to import);
  26
  27 =head1 DESCRIPTION
  28
  29 This module contains functions which are useful across many different
  30 parts of Git::SVN.  Mostly it's a place to put utility functions
  31 rather than duplicate the code or have classes grabbing at other
  32 classes.
  33
  34 =head1 FUNCTIONS
  35
  36 All functions can be imported only on request.
  37
  38 =head3 fatal
  39
  40     fatal(@message);
  41
  42 Display a message and exit with a fatal error code.
  43
  44 =cut
  45
  46 # Note: not certain why this is in use instead of die.  Probably because
  47 # the exit code of die is 255?  Doesn't appear to be used consistently.
  48 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  49
  50
  51 =head3 can_compress
  52
  53     my $can_compress = can_compress;
  54
  55 Returns true if Compress::Zlib is available, false otherwise.
  56
  57 =cut
  58
  59 my $can_compress;
  60 sub can_compress {
  61         return $can_compress if defined $can_compress;
  62
  63         return $can_compress = eval { require Compress::Zlib; };
  64 }
  65
  66
  67 =head3 canonicalize_path
  68
  69     my $canoncalized_path = canonicalize_path($path);
  70
  71 Converts $path into a canonical form which is safe to pass to the SVN
  72 API as a file path.
  73
  74 =cut
  75
  76 # Turn foo/../bar into bar
  77 sub _collapse_dotdot {
  78         my $path = shift;
  79
  80         1 while $path =~ s{/[^/]+/+\.\.}{};
  81         1 while $path =~ s{[^/]+/+\.\./}{};
  82         1 while $path =~ s{[^/]+/+\.\.}{};
  83
  84         return $path;
  85 }
  86
  87
  88 sub canonicalize_path {
  89         my ($path) = @_;
  90         my $dot_slash_added = 0;
  91         if (substr($path, 0, 1) ne "/") {
  92                 $path = "./" . $path;
  93                 $dot_slash_added = 1;
  94         }
  95         # File::Spec->canonpath doesn't collapse x/../y into y (for a
  96         # good reason), so let's do this manually.
  97         $path =~ s#/+#/#g;
  98         $path =~ s#/\.(?:/|$)#/#g;
  99         $path = _collapse_dotdot($path);
 100         $path =~ s#/$##g;
 101         $path =~ s#^\./## if $dot_slash_added;
 102         $path =~ s#^/##;
 103         $path =~ s#^\.$##;
 104         return $path;
 105 }
 106
 107
 108 =head3 canonicalize_url
 109
 110     my $canonicalized_url = canonicalize_url($url);
 111
 112 Converts $url into a canonical form which is safe to pass to the SVN
 113 API as a URL.
 114
 115 =cut
 116
 117 sub canonicalize_url {
 118         my $url = shift;
 119
 120         # The 1.7 way to do it
 121         if ( defined &SVN::_Core::svn_uri_canonicalize ) {
 122                 return SVN::_Core::svn_uri_canonicalize($url);
 123         }
 124         # There wasn't a 1.6 way to do it, so we do it ourself.
 125         else {
 126                 return _canonicalize_url_ourselves($url);
 127         }
 128 }
 129
 130
 131 sub _canonicalize_url_ourselves {
 132         my ($url) = @_;
 133         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 134         return $url;
 135 }
 136
 137
 138 =head3 join_paths
 139
 140     my $new_path = join_paths(@paths);
 141
 142 Appends @paths together into a single path.  Any empty paths are ignored.
 143
 144 =cut
 145
 146 sub join_paths {
 147         my @paths = @_;
 148
 149         @paths = grep { defined $_ && length $_ } @paths;
 150
 151         return '' unless @paths;
 152         return $paths[0] if @paths == 1;
 153
 154         my $new_path = shift @paths;
 155         $new_path =~ s{/+$}{};
 156
 157         my $last_path = pop @paths;
 158         $last_path =~ s{^/+}{};
 159
 160         for my $path (@paths) {
 161                 $path =~ s{^/+}{};
 162                 $path =~ s{/+$}{};
 163                 $new_path .= "/$path";
 164         }
 165
 166         return $new_path .= "/$last_path";
 167 }
 168
 169 1;