git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 package FakeTerm;
  28 sub new {
  29         my ($class, $reason) = @_;
  30         return bless \$reason, shift;
  31 }
  32 sub readline {
  33         my $self = shift;
  34         die "Cannot use readline on FakeTerm: $$self";
  35 }
  36 package main;
  37
  38
  39 sub usage {
  40         print <<EOT;
  41 git send-email [options] <file | directory>...
  42
  43   Composing:
  44     --from                  <str>  * Email From:
  45     --to                    <str>  * Email To:
  46     --cc                    <str>  * Email Cc:
  47     --bcc                   <str>  * Email Bcc:
  48     --subject               <str>  * Email "Subject:"
  49     --in-reply-to           <str>  * Email "In-Reply-To:"
  50     --compose                      * Open an editor for introduction.
  51
  52   Sending:
  53     --envelope-sender       <str>  * Email envelope sender.
  54     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  55                                      is optional. Default 'localhost'.
  56     --smtp-server-port      <int>  * Outgoing SMTP server port.
  57     --smtp-user             <str>  * Username for SMTP-AUTH.
  58     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  59     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  60     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  61
  62   Automating:
  63     --identity              <str>  * Use the sendemail.<id> options.
  64     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  65     --suppress-cc           <str>  * author, self, sob, cccmd, all.
  66     --[no-]signed-off-by-cc        * Send to Cc: and Signed-off-by:
  67                                      addresses. Default on.
  68     --[no-]suppress-from           * Send to self. Default off.
  69     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  70     --[no-]thread                  * Use In-Reply-To: field. Default on.
  71
  72   Administering:
  73     --quiet                        * Output one line of info per email.
  74     --dry-run                      * Don't actually send the emails.
  75     --[no-]validate                * Perform patch sanity checks. Default on.
  76
  77 EOT
  78         exit(1);
  79 }
  80
  81 # most mail servers generate the Date: header, but not all...
  82 sub format_2822_time {
  83         my ($time) = @_;
  84         my @localtm = localtime($time);
  85         my @gmttm = gmtime($time);
  86         my $localmin = $localtm[1] + $localtm[2] * 60;
  87         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  88         if ($localtm[0] != $gmttm[0]) {
  89                 die "local zone differs from GMT by a non-minute interval\n";
  90         }
  91         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
  92                 $localmin += 1440;
  93         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
  94                 $localmin -= 1440;
  95         } elsif ($gmttm[6] != $localtm[6]) {
  96                 die "local time offset greater than or equal to 24 hours\n";
  97         }
  98         my $offset = $localmin - $gmtmin;
  99         my $offhour = $offset / 60;
 100         my $offmin = abs($offset % 60);
 101         if (abs($offhour) >= 24) {
 102                 die ("local time offset greater than or equal to 24 hours\n");
 103         }
 104
 105         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 106                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 107                        $localtm[3],
 108                        qw(Jan Feb Mar Apr May Jun
 109                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 110                        $localtm[5]+1900,
 111                        $localtm[2],
 112                        $localtm[1],
 113                        $localtm[0],
 114                        ($offset >= 0) ? '+' : '-',
 115                        abs($offhour),
 116                        $offmin,
 117                        );
 118 }
 119
 120 my $have_email_valid = eval { require Email::Valid; 1 };
 121 my $smtp;
 122 my $auth;
 123
 124 sub unique_email_list(@);
 125 sub cleanup_compose_files();
 126
 127 # Variables we fill in automatically, or via prompting:
 128 my (@to,@cc,@initial_cc,@bcclist,@xh,
 129         $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
 130
 131 my $envelope_sender;
 132
 133 # Example reply to:
 134 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 135
 136 my $repo = eval { Git->repository() };
 137 my @repo = $repo ? ($repo) : ();
 138 my $term = eval {
 139         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 140                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 141                 : new Term::ReadLine 'git-send-email';
 142 };
 143 if ($@) {
 144         $term = new FakeTerm "$@: going non-interactive";
 145 }
 146
 147 # Behavior modification variables
 148 my ($quiet, $dry_run) = (0, 0);
 149 my $compose_filename = $repo->repo_path() . "/.gitsendemail.msg.$$";
 150
 151 # Variables with corresponding config settings
 152 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 153 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 154 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 155 my ($validate);
 156 my (@suppress_cc);
 157
 158 my %config_bool_settings = (
 159     "thread" => [\$thread, 1],
 160     "chainreplyto" => [\$chain_reply_to, 1],
 161     "suppressfrom" => [\$suppress_from, undef],
 162     "signedoffbycc" => [\$signed_off_by_cc, undef],
 163     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 164     "validate" => [\$validate, 1],
 165 );
 166
 167 my %config_settings = (
 168     "smtpserver" => \$smtp_server,
 169     "smtpserverport" => \$smtp_server_port,
 170     "smtpuser" => \$smtp_authuser,
 171     "smtppass" => \$smtp_authpass,
 172     "to" => \@to,
 173     "cc" => \@initial_cc,
 174     "cccmd" => \$cc_cmd,
 175     "aliasfiletype" => \$aliasfiletype,
 176     "bcc" => \@bcclist,
 177     "aliasesfile" => \@alias_files,
 178     "suppresscc" => \@suppress_cc,
 179     "envelopesender" => \$envelope_sender,
 180 );
 181
 182 # Handle Uncouth Termination
 183 sub signal_handler {
 184
 185         # Make text normal
 186         print color("reset"), "\n";
 187
 188         # SMTP password masked
 189         system "stty echo";
 190
 191         # tmp files from --compose
 192         if (-e $compose_filename) {
 193                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 194         }
 195         if (-e ($compose_filename . ".final")) {
 196                 print "'$compose_filename.final' contains the composed email.\n"
 197         }
 198
 199         exit;
 200 };
 201
 202 $SIG{TERM} = \&signal_handler;
 203 $SIG{INT}  = \&signal_handler;
 204
 205 # Begin by accumulating all the variables (defined above), that we will end up
 206 # needing, first, from the command line:
 207
 208 my $rc = GetOptions("sender|from=s" => \$sender,
 209                     "in-reply-to=s" => \$initial_reply_to,
 210                     "subject=s" => \$initial_subject,
 211                     "to=s" => \@to,
 212                     "cc=s" => \@initial_cc,
 213                     "bcc=s" => \@bcclist,
 214                     "chain-reply-to!" => \$chain_reply_to,
 215                     "smtp-server=s" => \$smtp_server,
 216                     "smtp-server-port=s" => \$smtp_server_port,
 217                     "smtp-user=s" => \$smtp_authuser,
 218                     "smtp-pass:s" => \$smtp_authpass,
 219                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 220                     "smtp-encryption=s" => \$smtp_encryption,
 221                     "identity=s" => \$identity,
 222                     "compose" => \$compose,
 223                     "quiet" => \$quiet,
 224                     "cc-cmd=s" => \$cc_cmd,
 225                     "suppress-from!" => \$suppress_from,
 226                     "suppress-cc=s" => \@suppress_cc,
 227                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 228                     "dry-run" => \$dry_run,
 229                     "envelope-sender=s" => \$envelope_sender,
 230                     "thread!" => \$thread,
 231                     "validate!" => \$validate,
 232          );
 233
 234 unless ($rc) {
 235     usage();
 236 }
 237
 238 # Now, let's fill any that aren't set in with defaults:
 239
 240 sub read_config {
 241         my ($prefix) = @_;
 242
 243         foreach my $setting (keys %config_bool_settings) {
 244                 my $target = $config_bool_settings{$setting}->[0];
 245                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 246         }
 247
 248         foreach my $setting (keys %config_settings) {
 249                 my $target = $config_settings{$setting};
 250                 if (ref($target) eq "ARRAY") {
 251                         unless (@$target) {
 252                                 my @values = Git::config(@repo, "$prefix.$setting");
 253                                 @$target = @values if (@values && defined $values[0]);
 254                         }
 255                 }
 256                 else {
 257                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 258                 }
 259         }
 260
 261         if (!defined $smtp_encryption) {
 262                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 263                 if (defined $enc) {
 264                         $smtp_encryption = $enc;
 265                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 266                         $smtp_encryption = 'ssl';
 267                 }
 268         }
 269 }
 270
 271 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 272 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 273 read_config("sendemail.$identity") if (defined $identity);
 274 read_config("sendemail");
 275
 276 # fall back on builtin bool defaults
 277 foreach my $setting (values %config_bool_settings) {
 278         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 279 }
 280
 281 # 'default' encryption is none -- this only prevents a warning
 282 $smtp_encryption = '' unless (defined $smtp_encryption);
 283
 284 # Set CC suppressions
 285 my(%suppress_cc);
 286 if (@suppress_cc) {
 287         foreach my $entry (@suppress_cc) {
 288                 die "Unknown --suppress-cc field: '$entry'\n"
 289                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 290                 $suppress_cc{$entry} = 1;
 291         }
 292 }
 293
 294 if ($suppress_cc{'all'}) {
 295         foreach my $entry (qw (ccmd cc author self sob)) {
 296                 $suppress_cc{$entry} = 1;
 297         }
 298         delete $suppress_cc{'all'};
 299 }
 300
 301 # If explicit old-style ones are specified, they trump --suppress-cc.
 302 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 303 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 304
 305 # Debugging, print out the suppressions.
 306 if (0) {
 307         print "suppressions:\n";
 308         foreach my $entry (keys %suppress_cc) {
 309                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 310         }
 311 }
 312
 313 my ($repoauthor, $repocommitter);
 314 ($repoauthor) = Git::ident_person(@repo, 'author');
 315 ($repocommitter) = Git::ident_person(@repo, 'committer');
 316
 317 # Verify the user input
 318
 319 foreach my $entry (@to) {
 320         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 321 }
 322
 323 foreach my $entry (@initial_cc) {
 324         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 325 }
 326
 327 foreach my $entry (@bcclist) {
 328         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 329 }
 330
 331 my %aliases;
 332 my %parse_alias = (
 333         # multiline formats can be supported in the future
 334         mutt => sub { my $fh = shift; while (<$fh>) {
 335                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 336                         my ($alias, $addr) = ($1, $2);
 337                         $addr =~ s/#.*$//; # mutt allows # comments
 338                          # commas delimit multiple addresses
 339                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 340                 }}},
 341         mailrc => sub { my $fh = shift; while (<$fh>) {
 342                 if (/^alias\s+(\S+)\s+(.*)$/) {
 343                         # spaces delimit multiple addresses
 344                         $aliases{$1} = [ split(/\s+/, $2) ];
 345                 }}},
 346         pine => sub { my $fh = shift; while (<$fh>) {
 347                 if (/^(\S+)\t.*\t(.*)$/) {
 348                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 349                 }}},
 350         gnus => sub { my $fh = shift; while (<$fh>) {
 351                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 352                         $aliases{$1} = [ $2 ];
 353                 }}}
 354 );
 355
 356 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 357         foreach my $file (@alias_files) {
 358                 open my $fh, '<', $file or die "opening $file: $!\n";
 359                 $parse_alias{$aliasfiletype}->($fh);
 360                 close $fh;
 361         }
 362 }
 363
 364 ($sender) = expand_aliases($sender) if defined $sender;
 365
 366 # Now that all the defaults are set, process the rest of the command line
 367 # arguments and collect up the files that need to be processed.
 368 for my $f (@ARGV) {
 369         if (-d $f) {
 370                 opendir(DH,$f)
 371                         or die "Failed to opendir $f: $!";
 372
 373                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 374                                 sort readdir(DH);
 375                 closedir(DH);
 376         } elsif (-f $f or -p $f) {
 377                 push @files, $f;
 378         } else {
 379                 print STDERR "Skipping $f - not found.\n";
 380         }
 381 }
 382
 383 if ($validate) {
 384         foreach my $f (@files) {
 385                 unless (-p $f) {
 386                         my $error = validate_patch($f);
 387                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 388                 }
 389         }
 390 }
 391
 392 if (@files) {
 393         unless ($quiet) {
 394                 print $_,"\n" for (@files);
 395         }
 396 } else {
 397         print STDERR "\nNo patch files specified!\n\n";
 398         usage();
 399 }
 400
 401 my $prompting = 0;
 402 if (!defined $sender) {
 403         $sender = $repoauthor || $repocommitter || '';
 404
 405         while (1) {
 406                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 407                 last if defined $_;
 408                 print "\n";
 409         }
 410
 411         $sender = $_ if ($_);
 412         print "Emails will be sent from: ", $sender, "\n";
 413         $prompting++;
 414 }
 415
 416 if (!@to) {
 417
 418
 419         while (1) {
 420                 $_ = $term->readline("Who should the emails be sent to? ", "");
 421                 last if defined $_;
 422                 print "\n";
 423         }
 424
 425         my $to = $_;
 426         push @to, split /,\s*/, $to;
 427         $prompting++;
 428 }
 429
 430 sub expand_aliases {
 431         my @cur = @_;
 432         my @last;
 433         do {
 434                 @last = @cur;
 435                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 436         } while (join(',',@cur) ne join(',',@last));
 437         return @cur;
 438 }
 439
 440 @to = expand_aliases(@to);
 441 @to = (map { sanitize_address($_) } @to);
 442 @initial_cc = expand_aliases(@initial_cc);
 443 @bcclist = expand_aliases(@bcclist);
 444
 445 if (!defined $initial_subject && $compose) {
 446         while (1) {
 447                 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
 448                 last if defined $_;
 449                 print "\n";
 450         }
 451
 452         $initial_subject = $_;
 453         $prompting++;
 454 }
 455
 456 if ($thread && !defined $initial_reply_to && $prompting) {
 457         while (1) {
 458                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 459                 last if defined $_;
 460                 print "\n";
 461         }
 462
 463         $initial_reply_to = $_;
 464 }
 465 if (defined $initial_reply_to) {
 466         $initial_reply_to =~ s/^\s*<?//;
 467         $initial_reply_to =~ s/>?\s*$//;
 468         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 469 }
 470
 471 if (!defined $smtp_server) {
 472         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 473                 if (-x $_) {
 474                         $smtp_server = $_;
 475                         last;
 476                 }
 477         }
 478         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 479 }
 480
 481 if ($compose) {
 482         # Note that this does not need to be secure, but we will make a small
 483         # effort to have it be unique
 484         open(C,">",$compose_filename)
 485                 or die "Failed to open for writing $compose_filename: $!";
 486         print C "From $sender # This line is ignored.\n";
 487         printf C "Subject: %s\n\n", $initial_subject;
 488         printf C <<EOT;
 489 GIT: Please enter your email below.
 490 GIT: Lines beginning in "GIT: " will be removed.
 491 GIT: Consider including an overall diffstat or table of contents
 492 GIT: for the patch you are writing.
 493
 494 EOT
 495         close(C);
 496
 497         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 498         system('sh', '-c', $editor.' "$@"', $editor, $compose_filename);
 499
 500         open(C2,">",$compose_filename . ".final")
 501                 or die "Failed to open $compose_filename.final : " . $!;
 502
 503         open(C,"<",$compose_filename)
 504                 or die "Failed to open $compose_filename : " . $!;
 505
 506         my $need_8bit_cte = file_has_nonascii($compose_filename);
 507         my $in_body = 0;
 508         while(<C>) {
 509                 next if m/^GIT: /;
 510                 if (!$in_body && /^\n$/) {
 511                         $in_body = 1;
 512                         if ($need_8bit_cte) {
 513                                 print C2 "MIME-Version: 1.0\n",
 514                                          "Content-Type: text/plain; ",
 515                                            "charset=utf-8\n",
 516                                          "Content-Transfer-Encoding: 8bit\n";
 517                         }
 518                 }
 519                 if (!$in_body && /^MIME-Version:/i) {
 520                         $need_8bit_cte = 0;
 521                 }
 522                 if (!$in_body && /^Subject: ?(.*)/i) {
 523                         my $subject = $1;
 524                         $_ = "Subject: " .
 525                                 ($subject =~ /[^[:ascii:]]/ ?
 526                                  quote_rfc2047($subject) :
 527                                  $subject) .
 528                                 "\n";
 529                 }
 530                 print C2 $_;
 531         }
 532         close(C);
 533         close(C2);
 534
 535         while (1) {
 536                 $_ = $term->readline("Send this email? (y|n) ");
 537                 last if defined $_;
 538                 print "\n";
 539         }
 540
 541         if (uc substr($_,0,1) ne 'Y') {
 542                 cleanup_compose_files();
 543                 exit(0);
 544         }
 545
 546         @files = ($compose_filename . ".final", @files);
 547 }
 548
 549 # Variables we set as part of the loop over files
 550 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 551
 552 sub extract_valid_address {
 553         my $address = shift;
 554         my $local_part_regexp = '[^<>"\s@]+';
 555         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 556
 557         # check for a local address:
 558         return $address if ($address =~ /^($local_part_regexp)$/);
 559
 560         $address =~ s/^\s*<(.*)>\s*$/$1/;
 561         if ($have_email_valid) {
 562                 return scalar Email::Valid->address($address);
 563         } else {
 564                 # less robust/correct than the monster regexp in Email::Valid,
 565                 # but still does a 99% job, and one less dependency
 566                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 567                 return $1;
 568         }
 569 }
 570
 571 # Usually don't need to change anything below here.
 572
 573 # we make a "fake" message id by taking the current number
 574 # of seconds since the beginning of Unix time and tacking on
 575 # a random number to the end, in case we are called quicker than
 576 # 1 second since the last time we were called.
 577
 578 # We'll setup a template for the message id, using the "from" address:
 579
 580 my ($message_id_stamp, $message_id_serial);
 581 sub make_message_id
 582 {
 583         my $uniq;
 584         if (!defined $message_id_stamp) {
 585                 $message_id_stamp = sprintf("%s-%s", time, $$);
 586                 $message_id_serial = 0;
 587         }
 588         $message_id_serial++;
 589         $uniq = "$message_id_stamp-$message_id_serial";
 590
 591         my $du_part;
 592         for ($sender, $repocommitter, $repoauthor) {
 593                 $du_part = extract_valid_address(sanitize_address($_));
 594                 last if (defined $du_part and $du_part ne '');
 595         }
 596         if (not defined $du_part or $du_part eq '') {
 597                 use Sys::Hostname qw();
 598                 $du_part = 'user@' . Sys::Hostname::hostname();
 599         }
 600         my $message_id_template = "<%s-git-send-email-%s>";
 601         $message_id = sprintf($message_id_template, $uniq, $du_part);
 602         #print "new message id = $message_id\n"; # Was useful for debugging
 603 }
 604
 605
 606
 607 $time = time - scalar $#files;
 608
 609 sub unquote_rfc2047 {
 610         local ($_) = @_;
 611         my $encoding;
 612         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 613                 $encoding = $1;
 614                 s/_/ /g;
 615                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 616         }
 617         return wantarray ? ($_, $encoding) : $_;
 618 }
 619
 620 sub quote_rfc2047 {
 621         local $_ = shift;
 622         my $encoding = shift || 'utf-8';
 623         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 624         s/(.*)/=\?$encoding\?q\?$1\?=/;
 625         return $_;
 626 }
 627
 628 # use the simplest quoting being able to handle the recipient
 629 sub sanitize_address
 630 {
 631         my ($recipient) = @_;
 632         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 633
 634         if (not $recipient_name) {
 635                 return "$recipient";
 636         }
 637
 638         # if recipient_name is already quoted, do nothing
 639         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 640                 return $recipient;
 641         }
 642
 643         # rfc2047 is needed if a non-ascii char is included
 644         if ($recipient_name =~ /[^[:ascii:]]/) {
 645                 $recipient_name = quote_rfc2047($recipient_name);
 646         }
 647
 648         # double quotes are needed if specials or CTLs are included
 649         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 650                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 651                 $recipient_name = "\"$recipient_name\"";
 652         }
 653
 654         return "$recipient_name $recipient_addr";
 655
 656 }
 657
 658 sub send_message
 659 {
 660         my @recipients = unique_email_list(@to);
 661         @cc = (grep { my $cc = extract_valid_address($_);
 662                       not grep { $cc eq $_ } @recipients
 663                     }
 664                map { sanitize_address($_) }
 665                @cc);
 666         my $to = join (",\n\t", @recipients);
 667         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 668         @recipients = (map { extract_valid_address($_) } @recipients);
 669         my $date = format_2822_time($time++);
 670         my $gitversion = '@@GIT_VERSION@@';
 671         if ($gitversion =~ m/..GIT_VERSION../) {
 672             $gitversion = Git::version();
 673         }
 674
 675         my $cc = join(", ", unique_email_list(@cc));
 676         my $ccline = "";
 677         if ($cc ne '') {
 678                 $ccline = "\nCc: $cc";
 679         }
 680         my $sanitized_sender = sanitize_address($sender);
 681         make_message_id() unless defined($message_id);
 682
 683         my $header = "From: $sanitized_sender
 684 To: $to${ccline}
 685 Subject: $subject
 686 Date: $date
 687 Message-Id: $message_id
 688 X-Mailer: git-send-email $gitversion
 689 ";
 690         if ($thread && $reply_to) {
 691
 692                 $header .= "In-Reply-To: $reply_to\n";
 693                 $header .= "References: $references\n";
 694         }
 695         if (@xh) {
 696                 $header .= join("\n", @xh) . "\n";
 697         }
 698
 699         my @sendmail_parameters = ('-i', @recipients);
 700         my $raw_from = $sanitized_sender;
 701         $raw_from = $envelope_sender if (defined $envelope_sender);
 702         $raw_from = extract_valid_address($raw_from);
 703         unshift (@sendmail_parameters,
 704                         '-f', $raw_from) if(defined $envelope_sender);
 705
 706         if ($dry_run) {
 707                 # We don't want to send the email.
 708         } elsif ($smtp_server =~ m#^/#) {
 709                 my $pid = open my $sm, '|-';
 710                 defined $pid or die $!;
 711                 if (!$pid) {
 712                         exec($smtp_server, @sendmail_parameters) or die $!;
 713                 }
 714                 print $sm "$header\n$message";
 715                 close $sm or die $?;
 716         } else {
 717
 718                 if (!defined $smtp_server) {
 719                         die "The required SMTP server is not properly defined."
 720                 }
 721
 722                 if ($smtp_encryption eq 'ssl') {
 723                         $smtp_server_port ||= 465; # ssmtp
 724                         require Net::SMTP::SSL;
 725                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 726                 }
 727                 else {
 728                         require Net::SMTP;
 729                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 730                                                  ? "$smtp_server:$smtp_server_port"
 731                                                  : $smtp_server);
 732                         if ($smtp_encryption eq 'tls') {
 733                                 require Net::SMTP::SSL;
 734                                 $smtp->command('STARTTLS');
 735                                 $smtp->response();
 736                                 if ($smtp->code == 220) {
 737                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 738                                                 or die "STARTTLS failed! ".$smtp->message;
 739                                         $smtp_encryption = '';
 740                                         # Send EHLO again to receive fresh
 741                                         # supported commands
 742                                         $smtp->hello();
 743                                 } else {
 744                                         die "Server does not support STARTTLS! ".$smtp->message;
 745                                 }
 746                         }
 747                 }
 748
 749                 if (!$smtp) {
 750                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 751                 }
 752
 753                 if (defined $smtp_authuser) {
 754
 755                         if (!defined $smtp_authpass) {
 756
 757                                 system "stty -echo";
 758
 759                                 do {
 760                                         print "Password: ";
 761                                         $_ = <STDIN>;
 762                                         print "\n";
 763                                 } while (!defined $_);
 764
 765                                 chomp($smtp_authpass = $_);
 766
 767                                 system "stty echo";
 768                         }
 769
 770                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 771                 }
 772
 773                 $smtp->mail( $raw_from ) or die $smtp->message;
 774                 $smtp->to( @recipients ) or die $smtp->message;
 775                 $smtp->data or die $smtp->message;
 776                 $smtp->datasend("$header\n$message") or die $smtp->message;
 777                 $smtp->dataend() or die $smtp->message;
 778                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 779         }
 780         if ($quiet) {
 781                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 782         } else {
 783                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 784                 if ($smtp_server !~ m#^/#) {
 785                         print "Server: $smtp_server\n";
 786                         print "MAIL FROM:<$raw_from>\n";
 787                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 788                 } else {
 789                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 790                 }
 791                 print $header, "\n";
 792                 if ($smtp) {
 793                         print "Result: ", $smtp->code, ' ',
 794                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 795                 } else {
 796                         print "Result: OK\n";
 797                 }
 798         }
 799 }
 800
 801 $reply_to = $initial_reply_to;
 802 $references = $initial_reply_to || '';
 803 $subject = $initial_subject;
 804
 805 foreach my $t (@files) {
 806         open(F,"<",$t) or die "can't open file $t";
 807
 808         my $author = undef;
 809         my $author_encoding;
 810         my $has_content_type;
 811         my $body_encoding;
 812         @cc = @initial_cc;
 813         @xh = ();
 814         my $input_format = undef;
 815         my $header_done = 0;
 816         $message = "";
 817         while(<F>) {
 818                 if (!$header_done) {
 819                         if (/^From /) {
 820                                 $input_format = 'mbox';
 821                                 next;
 822                         }
 823                         chomp;
 824                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 825                                 $input_format = 'mbox';
 826                         }
 827
 828                         if (defined $input_format && $input_format eq 'mbox') {
 829                                 if (/^Subject:\s+(.*)$/) {
 830                                         $subject = $1;
 831
 832                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 833                                         if (unquote_rfc2047($2) eq $sender) {
 834                                                 next if ($suppress_cc{'self'});
 835                                         }
 836                                         elsif ($1 eq 'From') {
 837                                                 ($author, $author_encoding)
 838                                                   = unquote_rfc2047($2);
 839                                                 next if ($suppress_cc{'author'});
 840                                         } else {
 841                                                 next if ($suppress_cc{'cc'});
 842                                         }
 843                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 844                                                 $2, $_) unless $quiet;
 845                                         push @cc, $2;
 846                                 }
 847                                 elsif (/^Content-type:/i) {
 848                                         $has_content_type = 1;
 849                                         if (/charset="?([^ "]+)/) {
 850                                                 $body_encoding = $1;
 851                                         }
 852                                         push @xh, $_;
 853                                 }
 854                                 elsif (/^Message-Id: (.*)/i) {
 855                                         $message_id = $1;
 856                                 }
 857                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 858                                         push @xh, $_;
 859                                 }
 860
 861                         } else {
 862                                 # In the traditional
 863                                 # "send lots of email" format,
 864                                 # line 1 = cc
 865                                 # line 2 = subject
 866                                 # So let's support that, too.
 867                                 $input_format = 'lots';
 868                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 869                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 870                                                 $_, $_) unless $quiet;
 871
 872                                         push @cc, $_;
 873
 874                                 } elsif (!defined $subject) {
 875                                         $subject = $_;
 876                                 }
 877                         }
 878
 879                         # A whitespace line will terminate the headers
 880                         if (m/^\s*$/) {
 881                                 $header_done = 1;
 882                         }
 883                 } else {
 884                         $message .=  $_;
 885                         if (/^(Signed-off-by|Cc): (.*)$/i) {
 886                                 next if ($suppress_cc{'sob'});
 887                                 chomp;
 888                                 my $c = $2;
 889                                 chomp $c;
 890                                 next if ($c eq $sender and $suppress_cc{'self'});
 891                                 push @cc, $c;
 892                                 printf("(sob) Adding cc: %s from line '%s'\n",
 893                                         $c, $_) unless $quiet;
 894                         }
 895                 }
 896         }
 897         close F;
 898
 899         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
 900                 open(F, "$cc_cmd $t |")
 901                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 902                 while(<F>) {
 903                         my $c = $_;
 904                         $c =~ s/^\s*//g;
 905                         $c =~ s/\n$//g;
 906                         next if ($c eq $sender and $suppress_from);
 907                         push @cc, $c;
 908                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 909                                 $c, $cc_cmd) unless $quiet;
 910                 }
 911                 close F
 912                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 913         }
 914
 915         if (defined $author) {
 916                 $message = "From: $author\n\n$message";
 917                 if (defined $author_encoding) {
 918                         if ($has_content_type) {
 919                                 if ($body_encoding eq $author_encoding) {
 920                                         # ok, we already have the right encoding
 921                                 }
 922                                 else {
 923                                         # uh oh, we should re-encode
 924                                 }
 925                         }
 926                         else {
 927                                 push @xh,
 928                                   'MIME-Version: 1.0',
 929                                   "Content-Type: text/plain; charset=$author_encoding",
 930                                   'Content-Transfer-Encoding: 8bit';
 931                         }
 932                 }
 933         }
 934
 935         send_message();
 936
 937         # set up for the next message
 938         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 939                 $reply_to = $message_id;
 940                 if (length $references > 0) {
 941                         $references .= "\n $message_id";
 942                 } else {
 943                         $references = "$message_id";
 944                 }
 945         }
 946         $message_id = undef;
 947 }
 948
 949 if ($compose) {
 950         cleanup_compose_files();
 951 }
 952
 953 sub cleanup_compose_files() {
 954         unlink($compose_filename, $compose_filename . ".final");
 955
 956 }
 957
 958 $smtp->quit if $smtp;
 959
 960 sub unique_email_list(@) {
 961         my %seen;
 962         my @emails;
 963
 964         foreach my $entry (@_) {
 965                 if (my $clean = extract_valid_address($entry)) {
 966                         $seen{$clean} ||= 0;
 967                         next if $seen{$clean}++;
 968                         push @emails, $entry;
 969                 } else {
 970                         print STDERR "W: unable to extract a valid address",
 971                                         " from: $entry\n";
 972                 }
 973         }
 974         return @emails;
 975 }
 976
 977 sub validate_patch {
 978         my $fn = shift;
 979         open(my $fh, '<', $fn)
 980                 or die "unable to open $fn: $!\n";
 981         while (my $line = <$fh>) {
 982                 if (length($line) > 998) {
 983                         return "$.: patch contains a line longer than 998 characters";
 984                 }
 985         }
 986         return undef;
 987 }
 988
 989 sub file_has_nonascii {
 990         my $fn = shift;
 991         open(my $fh, '<', $fn)
 992                 or die "unable to open $fn: $!\n";
 993         while (my $line = <$fh>) {
 994                 return 1 if $line =~ /[^[:ascii:]]/;
 995         }
 996         return 0;
 997 }