git.oblomov.eu Git - git/blob - git-gui/git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [string map [list (c) \u00a9] {
  14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title "git-gui: fatal error" \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86         if {[tk windowingsystem] eq "win32"} { console show }
  87 }
  88
  89 ######################################################################
  90 ##
  91 ## Internationalization (i18n) through msgcat and gettext. See
  92 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  93
  94 package require msgcat
  95
  96 # Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
  97 if {[tk windowingsystem] eq "win32"
  98         && [package vcompare [package provide msgcat] 1.4.4] < 0
  99 } then {
 100         proc _mc_update_locale {} {
 101                 set key {HKEY_CURRENT_USER\Control Panel\Desktop}
 102                 if {![catch {
 103                         package require registry
 104                         set uilocale [registry get $key "PreferredUILanguages"]
 105                         msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
 106                 } uilocale]} {
 107                         if {[string length $uilocale] > 0} {
 108                                 msgcat::mclocale $uilocale
 109                         }
 110                 }
 111         }
 112         _mc_update_locale
 113 }
 114
 115 proc _mc_trim {fmt} {
 116         set cmk [string first @@ $fmt]
 117         if {$cmk > 0} {
 118                 return [string range $fmt 0 [expr {$cmk - 1}]]
 119         }
 120         return $fmt
 121 }
 122
 123 proc mc {en_fmt args} {
 124         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 125         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 126                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 127         }
 128         return $msg
 129 }
 130
 131 proc strcat {args} {
 132         return [join $args {}]
 133 }
 134
 135 ::msgcat::mcload $oguimsg
 136 unset oguimsg
 137
 138 ######################################################################
 139 ##
 140 ## On Mac, bring the current Wish process window to front
 141
 142 if {[tk windowingsystem] eq "aqua"} {
 143         catch {
 144                 exec osascript -e [format {
 145                         tell application "System Events"
 146                                 set frontmost of processes whose unix id is %d to true
 147                         end tell
 148                 } [pid]]
 149         }
 150 }
 151
 152 ######################################################################
 153 ##
 154 ## read only globals
 155
 156 set _appname {Git Gui}
 157 set _gitdir {}
 158 set _gitworktree {}
 159 set _isbare {}
 160 set _gitexec {}
 161 set _githtmldir {}
 162 set _reponame {}
 163 set _iscygwin {}
 164 set _search_path {}
 165 set _shellpath {@@SHELL_PATH@@}
 166
 167 set _trace [lsearch -exact $argv --trace]
 168 if {$_trace >= 0} {
 169         set argv [lreplace $argv $_trace $_trace]
 170         set _trace 1
 171         if {[tk windowingsystem] eq "win32"} { console show }
 172 } else {
 173         set _trace 0
 174 }
 175
 176 # variable for the last merged branch (useful for a default when deleting
 177 # branches).
 178 set _last_merged_branch {}
 179
 180 proc shellpath {} {
 181         global _shellpath env
 182         if {[string match @@* $_shellpath]} {
 183                 if {[info exists env(SHELL)]} {
 184                         return $env(SHELL)
 185                 } else {
 186                         return /bin/sh
 187                 }
 188         }
 189         return $_shellpath
 190 }
 191
 192 proc appname {} {
 193         global _appname
 194         return $_appname
 195 }
 196
 197 proc gitdir {args} {
 198         global _gitdir
 199         if {$args eq {}} {
 200                 return $_gitdir
 201         }
 202         return [eval [list file join $_gitdir] $args]
 203 }
 204
 205 proc gitexec {args} {
 206         global _gitexec
 207         if {$_gitexec eq {}} {
 208                 if {[catch {set _gitexec [git --exec-path]} err]} {
 209                         error "Git not installed?\n\n$err"
 210                 }
 211                 if {[is_Cygwin]} {
 212                         set _gitexec [exec cygpath \
 213                                 --windows \
 214                                 --absolute \
 215                                 $_gitexec]
 216                 } else {
 217                         set _gitexec [file normalize $_gitexec]
 218                 }
 219         }
 220         if {$args eq {}} {
 221                 return $_gitexec
 222         }
 223         return [eval [list file join $_gitexec] $args]
 224 }
 225
 226 proc githtmldir {args} {
 227         global _githtmldir
 228         if {$_githtmldir eq {}} {
 229                 if {[catch {set _githtmldir [git --html-path]}]} {
 230                         # Git not installed or option not yet supported
 231                         return {}
 232                 }
 233                 if {[is_Cygwin]} {
 234                         set _githtmldir [exec cygpath \
 235                                 --windows \
 236                                 --absolute \
 237                                 $_githtmldir]
 238                 } else {
 239                         set _githtmldir [file normalize $_githtmldir]
 240                 }
 241         }
 242         if {$args eq {}} {
 243                 return $_githtmldir
 244         }
 245         return [eval [list file join $_githtmldir] $args]
 246 }
 247
 248 proc reponame {} {
 249         return $::_reponame
 250 }
 251
 252 proc is_MacOSX {} {
 253         if {[tk windowingsystem] eq {aqua}} {
 254                 return 1
 255         }
 256         return 0
 257 }
 258
 259 proc is_Windows {} {
 260         if {$::tcl_platform(platform) eq {windows}} {
 261                 return 1
 262         }
 263         return 0
 264 }
 265
 266 proc is_Cygwin {} {
 267         global _iscygwin
 268         if {$_iscygwin eq {}} {
 269                 if {$::tcl_platform(platform) eq {windows}} {
 270                         if {[catch {set p [exec cygpath --windir]} err]} {
 271                                 set _iscygwin 0
 272                         } else {
 273                                 set _iscygwin 1
 274                         }
 275                 } else {
 276                         set _iscygwin 0
 277                 }
 278         }
 279         return $_iscygwin
 280 }
 281
 282 proc is_enabled {option} {
 283         global enabled_options
 284         if {[catch {set on $enabled_options($option)}]} {return 0}
 285         return $on
 286 }
 287
 288 proc enable_option {option} {
 289         global enabled_options
 290         set enabled_options($option) 1
 291 }
 292
 293 proc disable_option {option} {
 294         global enabled_options
 295         set enabled_options($option) 0
 296 }
 297
 298 ######################################################################
 299 ##
 300 ## config
 301
 302 proc is_many_config {name} {
 303         switch -glob -- $name {
 304         gui.recentrepo -
 305         remote.*.fetch -
 306         remote.*.push
 307                 {return 1}
 308         *
 309                 {return 0}
 310         }
 311 }
 312
 313 proc is_config_true {name} {
 314         global repo_config
 315         if {[catch {set v $repo_config($name)}]} {
 316                 return 0
 317         }
 318         set v [string tolower $v]
 319         if {$v eq {} || $v eq {true} || $v eq {1} || $v eq {yes} || $v eq {on}} {
 320                 return 1
 321         } else {
 322                 return 0
 323         }
 324 }
 325
 326 proc is_config_false {name} {
 327         global repo_config
 328         if {[catch {set v $repo_config($name)}]} {
 329                 return 0
 330         }
 331         set v [string tolower $v]
 332         if {$v eq {false} || $v eq {0} || $v eq {no} || $v eq {off}} {
 333                 return 1
 334         } else {
 335                 return 0
 336         }
 337 }
 338
 339 proc get_config {name} {
 340         global repo_config
 341         if {[catch {set v $repo_config($name)}]} {
 342                 return {}
 343         } else {
 344                 return $v
 345         }
 346 }
 347
 348 proc is_bare {} {
 349         global _isbare
 350         global _gitdir
 351         global _gitworktree
 352
 353         if {$_isbare eq {}} {
 354                 if {[catch {
 355                         set _bare [git rev-parse --is-bare-repository]
 356                         switch  -- $_bare {
 357                         true { set _isbare 1 }
 358                         false { set _isbare 0}
 359                         default { throw }
 360                         }
 361                 }]} {
 362                         if {[is_config_true core.bare]
 363                                 || ($_gitworktree eq {}
 364                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 365                                 set _isbare 1
 366                         } else {
 367                                 set _isbare 0
 368                         }
 369                 }
 370         }
 371         return $_isbare
 372 }
 373
 374 ######################################################################
 375 ##
 376 ## handy utils
 377
 378 proc _trace_exec {cmd} {
 379         if {!$::_trace} return
 380         set d {}
 381         foreach v $cmd {
 382                 if {$d ne {}} {
 383                         append d { }
 384                 }
 385                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 386                         set v [sq $v]
 387                 }
 388                 append d $v
 389         }
 390         puts stderr $d
 391 }
 392
 393 #'"  fix poor old emacs font-lock mode
 394
 395 proc _git_cmd {name} {
 396         global _git_cmd_path
 397
 398         if {[catch {set v $_git_cmd_path($name)}]} {
 399                 switch -- $name {
 400                   version   -
 401                 --version   -
 402                 --exec-path { return [list $::_git $name] }
 403                 }
 404
 405                 set p [gitexec git-$name$::_search_exe]
 406                 if {[file exists $p]} {
 407                         set v [list $p]
 408                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 409                         # Try to determine what sort of magic will make
 410                         # git-$name go and do its thing, because native
 411                         # Tcl on Windows doesn't know it.
 412                         #
 413                         set p [gitexec git-$name]
 414                         set f [open $p r]
 415                         set s [gets $f]
 416                         close $f
 417
 418                         switch -glob -- [lindex $s 0] {
 419                         #!*sh     { set i sh     }
 420                         #!*perl   { set i perl   }
 421                         #!*python { set i python }
 422                         default   { error "git-$name is not supported: $s" }
 423                         }
 424
 425                         upvar #0 _$i interp
 426                         if {![info exists interp]} {
 427                                 set interp [_which $i]
 428                         }
 429                         if {$interp eq {}} {
 430                                 error "git-$name requires $i (not in PATH)"
 431                         }
 432                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 433                 } else {
 434                         # Assume it is builtin to git somehow and we
 435                         # aren't actually able to see a file for it.
 436                         #
 437                         set v [list $::_git $name]
 438                 }
 439                 set _git_cmd_path($name) $v
 440         }
 441         return $v
 442 }
 443
 444 proc _which {what args} {
 445         global env _search_exe _search_path
 446
 447         if {$_search_path eq {}} {
 448                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 449                         set _search_path [split [exec cygpath \
 450                                 --windows \
 451                                 --path \
 452                                 --absolute \
 453                                 $env(PATH)] {;}]
 454                         set _search_exe .exe
 455                 } elseif {[is_Windows]} {
 456                         set gitguidir [file dirname [info script]]
 457                         regsub -all ";" $gitguidir "\\;" gitguidir
 458                         set env(PATH) "$gitguidir;$env(PATH)"
 459                         set _search_path [split $env(PATH) {;}]
 460                         set _search_exe .exe
 461                 } else {
 462                         set _search_path [split $env(PATH) :]
 463                         set _search_exe {}
 464                 }
 465         }
 466
 467         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 468                 set suffix {}
 469         } else {
 470                 set suffix $_search_exe
 471         }
 472
 473         foreach p $_search_path {
 474                 set p [file join $p $what$suffix]
 475                 if {[file exists $p]} {
 476                         return [file normalize $p]
 477                 }
 478         }
 479         return {}
 480 }
 481
 482 # Test a file for a hashbang to identify executable scripts on Windows.
 483 proc is_shellscript {filename} {
 484         if {![file exists $filename]} {return 0}
 485         set f [open $filename r]
 486         fconfigure $f -encoding binary
 487         set magic [read $f 2]
 488         close $f
 489         return [expr {$magic eq "#!"}]
 490 }
 491
 492 # Run a command connected via pipes on stdout.
 493 # This is for use with textconv filters and uses sh -c "..." to allow it to
 494 # contain a command with arguments. On windows we must check for shell
 495 # scripts specifically otherwise just call the filter command.
 496 proc open_cmd_pipe {cmd path} {
 497         global env
 498         if {![file executable [shellpath]]} {
 499                 set exe [auto_execok [lindex $cmd 0]]
 500                 if {[is_shellscript [lindex $exe 0]]} {
 501                         set run [linsert [auto_execok sh] end -c "$cmd \"\$0\"" $path]
 502                 } else {
 503                         set run [concat $exe [lrange $cmd 1 end] $path]
 504                 }
 505         } else {
 506                 set run [list [shellpath] -c "$cmd \"\$0\"" $path]
 507         }
 508         return [open |$run r]
 509 }
 510
 511 proc _lappend_nice {cmd_var} {
 512         global _nice
 513         upvar $cmd_var cmd
 514
 515         if {![info exists _nice]} {
 516                 set _nice [_which nice]
 517                 if {[catch {exec $_nice git version}]} {
 518                         set _nice {}
 519                 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 520                         set _nice {}
 521                 }
 522         }
 523         if {$_nice ne {}} {
 524                 lappend cmd $_nice
 525         }
 526 }
 527
 528 proc git {args} {
 529         set opt [list]
 530
 531         while {1} {
 532                 switch -- [lindex $args 0] {
 533                 --nice {
 534                         _lappend_nice opt
 535                 }
 536
 537                 default {
 538                         break
 539                 }
 540
 541                 }
 542
 543                 set args [lrange $args 1 end]
 544         }
 545
 546         set cmdp [_git_cmd [lindex $args 0]]
 547         set args [lrange $args 1 end]
 548
 549         _trace_exec [concat $opt $cmdp $args]
 550         set result [eval exec $opt $cmdp $args]
 551         if {$::_trace} {
 552                 puts stderr "< $result"
 553         }
 554         return $result
 555 }
 556
 557 proc _open_stdout_stderr {cmd} {
 558         _trace_exec $cmd
 559         if {[catch {
 560                         set fd [open [concat [list | ] $cmd] r]
 561                 } err]} {
 562                 if {   [lindex $cmd end] eq {2>@1}
 563                     && $err eq {can not find channel named "1"}
 564                         } {
 565                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 566                         # redirect operator.  Fallback to |& cat for those.
 567                         # The command was not actually started, so its safe
 568                         # to try to start it a second time.
 569                         #
 570                         set fd [open [concat \
 571                                 [list | ] \
 572                                 [lrange $cmd 0 end-1] \
 573                                 [list |& cat] \
 574                                 ] r]
 575                 } else {
 576                         error $err
 577                 }
 578         }
 579         fconfigure $fd -eofchar {}
 580         return $fd
 581 }
 582
 583 proc git_read {args} {
 584         set opt [list]
 585
 586         while {1} {
 587                 switch -- [lindex $args 0] {
 588                 --nice {
 589                         _lappend_nice opt
 590                 }
 591
 592                 --stderr {
 593                         lappend args 2>@1
 594                 }
 595
 596                 default {
 597                         break
 598                 }
 599
 600                 }
 601
 602                 set args [lrange $args 1 end]
 603         }
 604
 605         set cmdp [_git_cmd [lindex $args 0]]
 606         set args [lrange $args 1 end]
 607
 608         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 609 }
 610
 611 proc git_write {args} {
 612         set opt [list]
 613
 614         while {1} {
 615                 switch -- [lindex $args 0] {
 616                 --nice {
 617                         _lappend_nice opt
 618                 }
 619
 620                 default {
 621                         break
 622                 }
 623
 624                 }
 625
 626                 set args [lrange $args 1 end]
 627         }
 628
 629         set cmdp [_git_cmd [lindex $args 0]]
 630         set args [lrange $args 1 end]
 631
 632         _trace_exec [concat $opt $cmdp $args]
 633         return [open [concat [list | ] $opt $cmdp $args] w]
 634 }
 635
 636 proc githook_read {hook_name args} {
 637         set pchook [gitdir hooks $hook_name]
 638         lappend args 2>@1
 639
 640         # On Windows [file executable] might lie so we need to ask
 641         # the shell if the hook is executable.  Yes that's annoying.
 642         #
 643         if {[is_Windows]} {
 644                 upvar #0 _sh interp
 645                 if {![info exists interp]} {
 646                         set interp [_which sh]
 647                 }
 648                 if {$interp eq {}} {
 649                         error "hook execution requires sh (not in PATH)"
 650                 }
 651
 652                 set scr {if test -x "$1";then exec "$@";fi}
 653                 set sh_c [list $interp -c $scr $interp $pchook]
 654                 return [_open_stdout_stderr [concat $sh_c $args]]
 655         }
 656
 657         if {[file executable $pchook]} {
 658                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 659         }
 660
 661         return {}
 662 }
 663
 664 proc kill_file_process {fd} {
 665         set process [pid $fd]
 666
 667         catch {
 668                 if {[is_Windows]} {
 669                         # Use a Cygwin-specific flag to allow killing
 670                         # native Windows processes
 671                         exec kill -f $process
 672                 } else {
 673                         exec kill $process
 674                 }
 675         }
 676 }
 677
 678 proc gitattr {path attr default} {
 679         if {[catch {set r [git check-attr $attr -- $path]}]} {
 680                 set r unspecified
 681         } else {
 682                 set r [join [lrange [split $r :] 2 end] :]
 683                 regsub {^ } $r {} r
 684         }
 685         if {$r eq {unspecified}} {
 686                 return $default
 687         }
 688         return $r
 689 }
 690
 691 proc sq {value} {
 692         regsub -all ' $value "'\\''" value
 693         return "'$value'"
 694 }
 695
 696 proc load_current_branch {} {
 697         global current_branch is_detached
 698
 699         set fd [open [gitdir HEAD] r]
 700         if {[gets $fd ref] < 1} {
 701                 set ref {}
 702         }
 703         close $fd
 704
 705         set pfx {ref: refs/heads/}
 706         set len [string length $pfx]
 707         if {[string equal -length $len $pfx $ref]} {
 708                 # We're on a branch.  It might not exist.  But
 709                 # HEAD looks good enough to be a branch.
 710                 #
 711                 set current_branch [string range $ref $len end]
 712                 set is_detached 0
 713         } else {
 714                 # Assume this is a detached head.
 715                 #
 716                 set current_branch HEAD
 717                 set is_detached 1
 718         }
 719 }
 720
 721 auto_load tk_optionMenu
 722 rename tk_optionMenu real__tkOptionMenu
 723 proc tk_optionMenu {w varName args} {
 724         set m [eval real__tkOptionMenu $w $varName $args]
 725         $m configure -font font_ui
 726         $w configure -font font_ui
 727         return $m
 728 }
 729
 730 proc rmsel_tag {text} {
 731         $text tag conf sel \
 732                 -background [$text cget -background] \
 733                 -foreground [$text cget -foreground] \
 734                 -borderwidth 0
 735         $text tag conf in_sel -background lightgray
 736         bind $text <Motion> break
 737         return $text
 738 }
 739
 740 wm withdraw .
 741 set root_exists 0
 742 bind . <Visibility> {
 743         bind . <Visibility> {}
 744         set root_exists 1
 745 }
 746
 747 if {[is_Windows]} {
 748         wm iconbitmap . -default $oguilib/git-gui.ico
 749         set ::tk::AlwaysShowSelection 1
 750         bind . <Control-F2> {console show}
 751
 752         # Spoof an X11 display for SSH
 753         if {![info exists env(DISPLAY)]} {
 754                 set env(DISPLAY) :9999
 755         }
 756 } else {
 757         catch {
 758                 image create photo gitlogo -width 16 -height 16
 759
 760                 gitlogo put #33CC33 -to  7  0  9  2
 761                 gitlogo put #33CC33 -to  4  2 12  4
 762                 gitlogo put #33CC33 -to  7  4  9  6
 763                 gitlogo put #CC3333 -to  4  6 12  8
 764                 gitlogo put gray26  -to  4  9  6 10
 765                 gitlogo put gray26  -to  3 10  6 12
 766                 gitlogo put gray26  -to  8  9 13 11
 767                 gitlogo put gray26  -to  8 11 10 12
 768                 gitlogo put gray26  -to 11 11 13 14
 769                 gitlogo put gray26  -to  3 12  5 14
 770                 gitlogo put gray26  -to  5 13
 771                 gitlogo put gray26  -to 10 13
 772                 gitlogo put gray26  -to  4 14 12 15
 773                 gitlogo put gray26  -to  5 15 11 16
 774                 gitlogo redither
 775
 776                 image create photo gitlogo32 -width 32 -height 32
 777                 gitlogo32 copy gitlogo -zoom 2 2
 778
 779                 wm iconphoto . -default gitlogo gitlogo32
 780         }
 781 }
 782
 783 ######################################################################
 784 ##
 785 ## config defaults
 786
 787 set cursor_ptr arrow
 788 font create font_ui
 789 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 790         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 791         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 792 } else {
 793         font create font_diff -family Courier -size 10
 794         catch {
 795                 label .dummy
 796                 eval font configure font_ui [font actual [.dummy cget -font]]
 797                 destroy .dummy
 798         }
 799 }
 800
 801 font create font_uiitalic
 802 font create font_uibold
 803 font create font_diffbold
 804 font create font_diffitalic
 805
 806 foreach class {Button Checkbutton Entry Label
 807                 Labelframe Listbox Message
 808                 Radiobutton Spinbox Text} {
 809         option add *$class.font font_ui
 810 }
 811 if {![is_MacOSX]} {
 812         option add *Menu.font font_ui
 813         option add *Entry.borderWidth 1 startupFile
 814         option add *Entry.relief sunken startupFile
 815         option add *RadioButton.anchor w startupFile
 816 }
 817 unset class
 818
 819 if {[is_Windows] || [is_MacOSX]} {
 820         option add *Menu.tearOff 0
 821 }
 822
 823 if {[is_MacOSX]} {
 824         set M1B M1
 825         set M1T Cmd
 826 } else {
 827         set M1B Control
 828         set M1T Ctrl
 829 }
 830
 831 proc bind_button3 {w cmd} {
 832         bind $w <Any-Button-3> $cmd
 833         if {[is_MacOSX]} {
 834                 # Mac OS X sends Button-2 on right click through three-button mouse,
 835                 # or through trackpad right-clicking (two-finger touch + click).
 836                 bind $w <Any-Button-2> $cmd
 837                 bind $w <Control-Button-1> $cmd
 838         }
 839 }
 840
 841 proc apply_config {} {
 842         global repo_config font_descs
 843
 844         foreach option $font_descs {
 845                 set name [lindex $option 0]
 846                 set font [lindex $option 1]
 847                 if {[catch {
 848                         set need_weight 1
 849                         foreach {cn cv} $repo_config(gui.$name) {
 850                                 if {$cn eq {-weight}} {
 851                                         set need_weight 0
 852                                 }
 853                                 font configure $font $cn $cv
 854                         }
 855                         if {$need_weight} {
 856                                 font configure $font -weight normal
 857                         }
 858                         } err]} {
 859                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 860                 }
 861                 foreach {cn cv} [font configure $font] {
 862                         font configure ${font}bold $cn $cv
 863                         font configure ${font}italic $cn $cv
 864                 }
 865                 font configure ${font}bold -weight bold
 866                 font configure ${font}italic -slant italic
 867         }
 868
 869         global use_ttk NS
 870         set use_ttk 0
 871         set NS {}
 872         if {$repo_config(gui.usettk)} {
 873                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 874                 if {$use_ttk} {
 875                         set NS ttk
 876                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 877                         pave_toplevel .
 878                 }
 879         }
 880 }
 881
 882 set default_config(branch.autosetupmerge) true
 883 set default_config(merge.tool) {}
 884 set default_config(mergetool.keepbackup) true
 885 set default_config(merge.diffstat) true
 886 set default_config(merge.summary) false
 887 set default_config(merge.verbosity) 2
 888 set default_config(user.name) {}
 889 set default_config(user.email) {}
 890
 891 set default_config(gui.encoding) [encoding system]
 892 set default_config(gui.matchtrackingbranch) false
 893 set default_config(gui.textconv) true
 894 set default_config(gui.pruneduringfetch) false
 895 set default_config(gui.trustmtime) false
 896 set default_config(gui.fastcopyblame) false
 897 set default_config(gui.maxrecentrepo) 10
 898 set default_config(gui.copyblamethreshold) 40
 899 set default_config(gui.blamehistoryctx) 7
 900 set default_config(gui.diffcontext) 5
 901 set default_config(gui.diffopts) {}
 902 set default_config(gui.commitmsgwidth) 75
 903 set default_config(gui.newbranchtemplate) {}
 904 set default_config(gui.spellingdictionary) {}
 905 set default_config(gui.fontui) [font configure font_ui]
 906 set default_config(gui.fontdiff) [font configure font_diff]
 907 # TODO: this option should be added to the git-config documentation
 908 set default_config(gui.maxfilesdisplayed) 5000
 909 set default_config(gui.usettk) 1
 910 set default_config(gui.warndetachedcommit) 1
 911 set font_descs {
 912         {fontui   font_ui   {mc "Main Font"}}
 913         {fontdiff font_diff {mc "Diff/Console Font"}}
 914 }
 915 set default_config(gui.stageuntracked) ask
 916 set default_config(gui.displayuntracked) true
 917
 918 ######################################################################
 919 ##
 920 ## find git
 921
 922 set _git  [_which git]
 923 if {$_git eq {}} {
 924         catch {wm withdraw .}
 925         tk_messageBox \
 926                 -icon error \
 927                 -type ok \
 928                 -title [mc "git-gui: fatal error"] \
 929                 -message [mc "Cannot find git in PATH."]
 930         exit 1
 931 }
 932
 933 ######################################################################
 934 ##
 935 ## version check
 936
 937 if {[catch {set _git_version [git --version]} err]} {
 938         catch {wm withdraw .}
 939         tk_messageBox \
 940                 -icon error \
 941                 -type ok \
 942                 -title [mc "git-gui: fatal error"] \
 943                 -message "Cannot determine Git version:
 944
 945 $err
 946
 947 [appname] requires Git 1.5.0 or later."
 948         exit 1
 949 }
 950 if {![regsub {^git version } $_git_version {} _git_version]} {
 951         catch {wm withdraw .}
 952         tk_messageBox \
 953                 -icon error \
 954                 -type ok \
 955                 -title [mc "git-gui: fatal error"] \
 956                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 957         exit 1
 958 }
 959
 960 proc get_trimmed_version {s} {
 961     set r {}
 962     foreach x [split $s -._] {
 963         if {[string is integer -strict $x]} {
 964             lappend r $x
 965         } else {
 966             break
 967         }
 968     }
 969     return [join $r .]
 970 }
 971 set _real_git_version $_git_version
 972 set _git_version [get_trimmed_version $_git_version]
 973
 974 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 975         catch {wm withdraw .}
 976         if {[tk_messageBox \
 977                 -icon warning \
 978                 -type yesno \
 979                 -default no \
 980                 -title "[appname]: warning" \
 981                  -message [mc "Git version cannot be determined.
 982
 983 %s claims it is version '%s'.
 984
 985 %s requires at least Git 1.5.0 or later.
 986
 987 Assume '%s' is version 1.5.0?
 988 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 989                 set _git_version 1.5.0
 990         } else {
 991                 exit 1
 992         }
 993 }
 994 unset _real_git_version
 995
 996 proc git-version {args} {
 997         global _git_version
 998
 999         switch [llength $args] {
1000         0 {
1001                 return $_git_version
1002         }
1003
1004         2 {
1005                 set op [lindex $args 0]
1006                 set vr [lindex $args 1]
1007                 set cm [package vcompare $_git_version $vr]
1008                 return [expr $cm $op 0]
1009         }
1010
1011         4 {
1012                 set type [lindex $args 0]
1013                 set name [lindex $args 1]
1014                 set parm [lindex $args 2]
1015                 set body [lindex $args 3]
1016
1017                 if {($type ne {proc} && $type ne {method})} {
1018                         error "Invalid arguments to git-version"
1019                 }
1020                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
1021                         error "Last arm of $type $name must be default"
1022                 }
1023
1024                 foreach {op vr cb} [lrange $body 0 end-2] {
1025                         if {[git-version $op $vr]} {
1026                                 return [uplevel [list $type $name $parm $cb]]
1027                         }
1028                 }
1029
1030                 return [uplevel [list $type $name $parm [lindex $body end]]]
1031         }
1032
1033         default {
1034                 error "git-version >= x"
1035         }
1036
1037         }
1038 }
1039
1040 if {[git-version < 1.5]} {
1041         catch {wm withdraw .}
1042         tk_messageBox \
1043                 -icon error \
1044                 -type ok \
1045                 -title [mc "git-gui: fatal error"] \
1046                 -message "[appname] requires Git 1.5.0 or later.
1047
1048 You are using [git-version]:
1049
1050 [git --version]"
1051         exit 1
1052 }
1053
1054 ######################################################################
1055 ##
1056 ## configure our library
1057
1058 set idx [file join $oguilib tclIndex]
1059 if {[catch {set fd [open $idx r]} err]} {
1060         catch {wm withdraw .}
1061         tk_messageBox \
1062                 -icon error \
1063                 -type ok \
1064                 -title [mc "git-gui: fatal error"] \
1065                 -message $err
1066         exit 1
1067 }
1068 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1069         set idx [list]
1070         while {[gets $fd n] >= 0} {
1071                 if {$n ne {} && ![string match #* $n]} {
1072                         lappend idx $n
1073                 }
1074         }
1075 } else {
1076         set idx {}
1077 }
1078 close $fd
1079
1080 if {$idx ne {}} {
1081         set loaded [list]
1082         foreach p $idx {
1083                 if {[lsearch -exact $loaded $p] >= 0} continue
1084                 source [file join $oguilib $p]
1085                 lappend loaded $p
1086         }
1087         unset loaded p
1088 } else {
1089         set auto_path [concat [list $oguilib] $auto_path]
1090 }
1091 unset -nocomplain idx fd
1092
1093 ######################################################################
1094 ##
1095 ## config file parsing
1096
1097 git-version proc _parse_config {arr_name args} {
1098         >= 1.5.3 {
1099                 upvar $arr_name arr
1100                 array unset arr
1101                 set buf {}
1102                 catch {
1103                         set fd_rc [eval \
1104                                 [list git_read config] \
1105                                 $args \
1106                                 [list --null --list]]
1107                         fconfigure $fd_rc -translation binary
1108                         set buf [read $fd_rc]
1109                         close $fd_rc
1110                 }
1111                 foreach line [split $buf "\0"] {
1112                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1113                                 if {[is_many_config $name]} {
1114                                         lappend arr($name) $value
1115                                 } else {
1116                                         set arr($name) $value
1117                                 }
1118                         } elseif {[regexp {^([^\n]+)$} $line line name]} {
1119                                 # no value given, but interpreting them as
1120                                 # boolean will be handled as true
1121                                 set arr($name) {}
1122                         }
1123                 }
1124         }
1125         default {
1126                 upvar $arr_name arr
1127                 array unset arr
1128                 catch {
1129                         set fd_rc [eval [list git_read config --list] $args]
1130                         while {[gets $fd_rc line] >= 0} {
1131                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1132                                         if {[is_many_config $name]} {
1133                                                 lappend arr($name) $value
1134                                         } else {
1135                                                 set arr($name) $value
1136                                         }
1137                                 } elseif {[regexp {^([^=]+)$} $line line name]} {
1138                                         # no value given, but interpreting them as
1139                                         # boolean will be handled as true
1140                                         set arr($name) {}
1141                                 }
1142                         }
1143                         close $fd_rc
1144                 }
1145         }
1146 }
1147
1148 proc load_config {include_global} {
1149         global repo_config global_config system_config default_config
1150
1151         if {$include_global} {
1152                 _parse_config system_config --system
1153                 _parse_config global_config --global
1154         }
1155         _parse_config repo_config
1156
1157         foreach name [array names default_config] {
1158                 if {[catch {set v $system_config($name)}]} {
1159                         set system_config($name) $default_config($name)
1160                 }
1161         }
1162         foreach name [array names system_config] {
1163                 if {[catch {set v $global_config($name)}]} {
1164                         set global_config($name) $system_config($name)
1165                 }
1166                 if {[catch {set v $repo_config($name)}]} {
1167                         set repo_config($name) $system_config($name)
1168                 }
1169         }
1170 }
1171
1172 ######################################################################
1173 ##
1174 ## feature option selection
1175
1176 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1177         unset _junk
1178 } else {
1179         set subcommand gui
1180 }
1181 if {$subcommand eq {gui.sh}} {
1182         set subcommand gui
1183 }
1184 if {$subcommand eq {gui} && [llength $argv] > 0} {
1185         set subcommand [lindex $argv 0]
1186         set argv [lrange $argv 1 end]
1187 }
1188
1189 enable_option multicommit
1190 enable_option branch
1191 enable_option transport
1192 disable_option bare
1193
1194 switch -- $subcommand {
1195 browser -
1196 blame {
1197         enable_option bare
1198
1199         disable_option multicommit
1200         disable_option branch
1201         disable_option transport
1202 }
1203 citool {
1204         enable_option singlecommit
1205         enable_option retcode
1206
1207         disable_option multicommit
1208         disable_option branch
1209         disable_option transport
1210
1211         while {[llength $argv] > 0} {
1212                 set a [lindex $argv 0]
1213                 switch -- $a {
1214                 --amend {
1215                         enable_option initialamend
1216                 }
1217                 --nocommit {
1218                         enable_option nocommit
1219                         enable_option nocommitmsg
1220                 }
1221                 --commitmsg {
1222                         disable_option nocommitmsg
1223                 }
1224                 default {
1225                         break
1226                 }
1227                 }
1228
1229                 set argv [lrange $argv 1 end]
1230         }
1231 }
1232 }
1233
1234 ######################################################################
1235 ##
1236 ## execution environment
1237
1238 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1239
1240 # Suggest our implementation of askpass, if none is set
1241 if {![info exists env(SSH_ASKPASS)]} {
1242         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1243 }
1244
1245 ######################################################################
1246 ##
1247 ## repository setup
1248
1249 set picked 0
1250 if {[catch {
1251                 set _gitdir $env(GIT_DIR)
1252                 set _prefix {}
1253                 }]
1254         && [catch {
1255                 # beware that from the .git dir this sets _gitdir to .
1256                 # and _prefix to the empty string
1257                 set _gitdir [git rev-parse --git-dir]
1258                 set _prefix [git rev-parse --show-prefix]
1259         } err]} {
1260         load_config 1
1261         apply_config
1262         choose_repository::pick
1263         set picked 1
1264 }
1265
1266 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1267 # run from the .git dir itself) lest the routines to find the worktree
1268 # get confused
1269 if {$_gitdir eq "."} {
1270         set _gitdir [pwd]
1271 }
1272
1273 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1274         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1275 }
1276 if {![file isdirectory $_gitdir]} {
1277         catch {wm withdraw .}
1278         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1279         exit 1
1280 }
1281 # _gitdir exists, so try loading the config
1282 load_config 0
1283 apply_config
1284
1285 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1286 if {[package vsatisfies $_git_version 1.7.0-]} {
1287         if { [is_Cygwin] } {
1288                 catch {set _gitworktree [exec cygpath --windows [git rev-parse --show-toplevel]]}
1289         } else {
1290                 set _gitworktree [git rev-parse --show-toplevel]
1291         }
1292 } else {
1293         # try to set work tree from environment, core.worktree or use
1294         # cdup to obtain a relative path to the top of the worktree. If
1295         # run from the top, the ./ prefix ensures normalize expands pwd.
1296         if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1297                 set _gitworktree [get_config core.worktree]
1298                 if {$_gitworktree eq ""} {
1299                         set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1300                 }
1301         }
1302 }
1303
1304 if {$_prefix ne {}} {
1305         if {$_gitworktree eq {}} {
1306                 regsub -all {[^/]+/} $_prefix ../ cdup
1307         } else {
1308                 set cdup $_gitworktree
1309         }
1310         if {[catch {cd $cdup} err]} {
1311                 catch {wm withdraw .}
1312                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1313                 exit 1
1314         }
1315         set _gitworktree [pwd]
1316         unset cdup
1317 } elseif {![is_enabled bare]} {
1318         if {[is_bare]} {
1319                 catch {wm withdraw .}
1320                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1321                 exit 1
1322         }
1323         if {$_gitworktree eq {}} {
1324                 set _gitworktree [file dirname $_gitdir]
1325         }
1326         if {[catch {cd $_gitworktree} err]} {
1327                 catch {wm withdraw .}
1328                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1329                 exit 1
1330         }
1331         set _gitworktree [pwd]
1332 }
1333 set _reponame [file split [file normalize $_gitdir]]
1334 if {[lindex $_reponame end] eq {.git}} {
1335         set _reponame [lindex $_reponame end-1]
1336 } else {
1337         set _reponame [lindex $_reponame end]
1338 }
1339
1340 set env(GIT_DIR) $_gitdir
1341 set env(GIT_WORK_TREE) $_gitworktree
1342
1343 ######################################################################
1344 ##
1345 ## global init
1346
1347 set current_diff_path {}
1348 set current_diff_side {}
1349 set diff_actions [list]
1350
1351 set HEAD {}
1352 set PARENT {}
1353 set MERGE_HEAD [list]
1354 set commit_type {}
1355 set empty_tree {}
1356 set current_branch {}
1357 set is_detached 0
1358 set current_diff_path {}
1359 set is_3way_diff 0
1360 set is_submodule_diff 0
1361 set is_conflict_diff 0
1362 set selected_commit_type new
1363 set diff_empty_count 0
1364
1365 set nullid "0000000000000000000000000000000000000000"
1366 set nullid2 "0000000000000000000000000000000000000001"
1367
1368 ######################################################################
1369 ##
1370 ## task management
1371
1372 set rescan_active 0
1373 set diff_active 0
1374 set last_clicked {}
1375
1376 set disable_on_lock [list]
1377 set index_lock_type none
1378
1379 proc lock_index {type} {
1380         global index_lock_type disable_on_lock
1381
1382         if {$index_lock_type eq {none}} {
1383                 set index_lock_type $type
1384                 foreach w $disable_on_lock {
1385                         uplevel #0 $w disabled
1386                 }
1387                 return 1
1388         } elseif {$index_lock_type eq "begin-$type"} {
1389                 set index_lock_type $type
1390                 return 1
1391         }
1392         return 0
1393 }
1394
1395 proc unlock_index {} {
1396         global index_lock_type disable_on_lock
1397
1398         set index_lock_type none
1399         foreach w $disable_on_lock {
1400                 uplevel #0 $w normal
1401         }
1402 }
1403
1404 ######################################################################
1405 ##
1406 ## status
1407
1408 proc repository_state {ctvar hdvar mhvar} {
1409         global current_branch
1410         upvar $ctvar ct $hdvar hd $mhvar mh
1411
1412         set mh [list]
1413
1414         load_current_branch
1415         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1416                 set hd {}
1417                 set ct initial
1418                 return
1419         }
1420
1421         set merge_head [gitdir MERGE_HEAD]
1422         if {[file exists $merge_head]} {
1423                 set ct merge
1424                 set fd_mh [open $merge_head r]
1425                 while {[gets $fd_mh line] >= 0} {
1426                         lappend mh $line
1427                 }
1428                 close $fd_mh
1429                 return
1430         }
1431
1432         set ct normal
1433 }
1434
1435 proc PARENT {} {
1436         global PARENT empty_tree
1437
1438         set p [lindex $PARENT 0]
1439         if {$p ne {}} {
1440                 return $p
1441         }
1442         if {$empty_tree eq {}} {
1443                 set empty_tree [git mktree << {}]
1444         }
1445         return $empty_tree
1446 }
1447
1448 proc force_amend {} {
1449         global selected_commit_type
1450         global HEAD PARENT MERGE_HEAD commit_type
1451
1452         repository_state newType newHEAD newMERGE_HEAD
1453         set HEAD $newHEAD
1454         set PARENT $newHEAD
1455         set MERGE_HEAD $newMERGE_HEAD
1456         set commit_type $newType
1457
1458         set selected_commit_type amend
1459         do_select_commit_type
1460 }
1461
1462 proc rescan {after {honor_trustmtime 1}} {
1463         global HEAD PARENT MERGE_HEAD commit_type
1464         global ui_index ui_workdir ui_comm
1465         global rescan_active file_states
1466         global repo_config
1467
1468         if {$rescan_active > 0 || ![lock_index read]} return
1469
1470         repository_state newType newHEAD newMERGE_HEAD
1471         if {[string match amend* $commit_type]
1472                 && $newType eq {normal}
1473                 && $newHEAD eq $HEAD} {
1474         } else {
1475                 set HEAD $newHEAD
1476                 set PARENT $newHEAD
1477                 set MERGE_HEAD $newMERGE_HEAD
1478                 set commit_type $newType
1479         }
1480
1481         array unset file_states
1482
1483         if {!$::GITGUI_BCK_exists &&
1484                 (![$ui_comm edit modified]
1485                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1486                 if {[string match amend* $commit_type]} {
1487                 } elseif {[load_message GITGUI_MSG utf-8]} {
1488                 } elseif {[run_prepare_commit_msg_hook]} {
1489                 } elseif {[load_message MERGE_MSG]} {
1490                 } elseif {[load_message SQUASH_MSG]} {
1491                 }
1492                 $ui_comm edit reset
1493                 $ui_comm edit modified false
1494         }
1495
1496         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1497                 rescan_stage2 {} $after
1498         } else {
1499                 set rescan_active 1
1500                 ui_status [mc "Refreshing file status..."]
1501                 set fd_rf [git_read update-index \
1502                         -q \
1503                         --unmerged \
1504                         --ignore-missing \
1505                         --refresh \
1506                         ]
1507                 fconfigure $fd_rf -blocking 0 -translation binary
1508                 fileevent $fd_rf readable \
1509                         [list rescan_stage2 $fd_rf $after]
1510         }
1511 }
1512
1513 if {[is_Cygwin]} {
1514         set is_git_info_exclude {}
1515         proc have_info_exclude {} {
1516                 global is_git_info_exclude
1517
1518                 if {$is_git_info_exclude eq {}} {
1519                         if {[catch {exec test -f [gitdir info exclude]}]} {
1520                                 set is_git_info_exclude 0
1521                         } else {
1522                                 set is_git_info_exclude 1
1523                         }
1524                 }
1525                 return $is_git_info_exclude
1526         }
1527 } else {
1528         proc have_info_exclude {} {
1529                 return [file readable [gitdir info exclude]]
1530         }
1531 }
1532
1533 proc rescan_stage2 {fd after} {
1534         global rescan_active buf_rdi buf_rdf buf_rlo
1535
1536         if {$fd ne {}} {
1537                 read $fd
1538                 if {![eof $fd]} return
1539                 close $fd
1540         }
1541
1542         if {[package vsatisfies $::_git_version 1.6.3-]} {
1543                 set ls_others [list --exclude-standard]
1544         } else {
1545                 set ls_others [list --exclude-per-directory=.gitignore]
1546                 if {[have_info_exclude]} {
1547                         lappend ls_others "--exclude-from=[gitdir info exclude]"
1548                 }
1549                 set user_exclude [get_config core.excludesfile]
1550                 if {$user_exclude ne {} && [file readable $user_exclude]} {
1551                         lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1552                 }
1553         }
1554
1555         set buf_rdi {}
1556         set buf_rdf {}
1557         set buf_rlo {}
1558
1559         set rescan_active 2
1560         ui_status [mc "Scanning for modified files ..."]
1561         if {[git-version >= "1.7.2"]} {
1562                 set fd_di [git_read diff-index --cached --ignore-submodules=dirty -z [PARENT]]
1563         } else {
1564                 set fd_di [git_read diff-index --cached -z [PARENT]]
1565         }
1566         set fd_df [git_read diff-files -z]
1567
1568         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1569         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1570
1571         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1572         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1573
1574         if {[is_config_true gui.displayuntracked]} {
1575                 set fd_lo [eval git_read ls-files --others -z $ls_others]
1576                 fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1577                 fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1578                 incr rescan_active
1579         }
1580 }
1581
1582 proc load_message {file {encoding {}}} {
1583         global ui_comm
1584
1585         set f [gitdir $file]
1586         if {[file isfile $f]} {
1587                 if {[catch {set fd [open $f r]}]} {
1588                         return 0
1589                 }
1590                 fconfigure $fd -eofchar {}
1591                 if {$encoding ne {}} {
1592                         fconfigure $fd -encoding $encoding
1593                 }
1594                 set content [string trim [read $fd]]
1595                 close $fd
1596                 regsub -all -line {[ \r\t]+$} $content {} content
1597                 $ui_comm delete 0.0 end
1598                 $ui_comm insert end $content
1599                 return 1
1600         }
1601         return 0
1602 }
1603
1604 proc run_prepare_commit_msg_hook {} {
1605         global pch_error
1606
1607         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1608         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1609         # empty file but existent file.
1610
1611         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1612
1613         if {[file isfile [gitdir MERGE_MSG]]} {
1614                 set pcm_source "merge"
1615                 set fd_mm [open [gitdir MERGE_MSG] r]
1616                 puts -nonewline $fd_pcm [read $fd_mm]
1617                 close $fd_mm
1618         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1619                 set pcm_source "squash"
1620                 set fd_sm [open [gitdir SQUASH_MSG] r]
1621                 puts -nonewline $fd_pcm [read $fd_sm]
1622                 close $fd_sm
1623         } else {
1624                 set pcm_source ""
1625         }
1626
1627         close $fd_pcm
1628
1629         set fd_ph [githook_read prepare-commit-msg \
1630                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1631         if {$fd_ph eq {}} {
1632                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1633                 return 0;
1634         }
1635
1636         ui_status [mc "Calling prepare-commit-msg hook..."]
1637         set pch_error {}
1638
1639         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1640         fileevent $fd_ph readable \
1641                 [list prepare_commit_msg_hook_wait $fd_ph]
1642
1643         return 1;
1644 }
1645
1646 proc prepare_commit_msg_hook_wait {fd_ph} {
1647         global pch_error
1648
1649         append pch_error [read $fd_ph]
1650         fconfigure $fd_ph -blocking 1
1651         if {[eof $fd_ph]} {
1652                 if {[catch {close $fd_ph}]} {
1653                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1654                         hook_failed_popup prepare-commit-msg $pch_error
1655                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1656                         exit 1
1657                 } else {
1658                         load_message PREPARE_COMMIT_MSG
1659                 }
1660                 set pch_error {}
1661                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1662                 return
1663         }
1664         fconfigure $fd_ph -blocking 0
1665         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1666 }
1667
1668 proc read_diff_index {fd after} {
1669         global buf_rdi
1670
1671         append buf_rdi [read $fd]
1672         set c 0
1673         set n [string length $buf_rdi]
1674         while {$c < $n} {
1675                 set z1 [string first "\0" $buf_rdi $c]
1676                 if {$z1 == -1} break
1677                 incr z1
1678                 set z2 [string first "\0" $buf_rdi $z1]
1679                 if {$z2 == -1} break
1680
1681                 incr c
1682                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1683                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1684                 merge_state \
1685                         [encoding convertfrom $p] \
1686                         [lindex $i 4]? \
1687                         [list [lindex $i 0] [lindex $i 2]] \
1688                         [list]
1689                 set c $z2
1690                 incr c
1691         }
1692         if {$c < $n} {
1693                 set buf_rdi [string range $buf_rdi $c end]
1694         } else {
1695                 set buf_rdi {}
1696         }
1697
1698         rescan_done $fd buf_rdi $after
1699 }
1700
1701 proc read_diff_files {fd after} {
1702         global buf_rdf
1703
1704         append buf_rdf [read $fd]
1705         set c 0
1706         set n [string length $buf_rdf]
1707         while {$c < $n} {
1708                 set z1 [string first "\0" $buf_rdf $c]
1709                 if {$z1 == -1} break
1710                 incr z1
1711                 set z2 [string first "\0" $buf_rdf $z1]
1712                 if {$z2 == -1} break
1713
1714                 incr c
1715                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1716                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1717                 merge_state \
1718                         [encoding convertfrom $p] \
1719                         ?[lindex $i 4] \
1720                         [list] \
1721                         [list [lindex $i 0] [lindex $i 2]]
1722                 set c $z2
1723                 incr c
1724         }
1725         if {$c < $n} {
1726                 set buf_rdf [string range $buf_rdf $c end]
1727         } else {
1728                 set buf_rdf {}
1729         }
1730
1731         rescan_done $fd buf_rdf $after
1732 }
1733
1734 proc read_ls_others {fd after} {
1735         global buf_rlo
1736
1737         append buf_rlo [read $fd]
1738         set pck [split $buf_rlo "\0"]
1739         set buf_rlo [lindex $pck end]
1740         foreach p [lrange $pck 0 end-1] {
1741                 set p [encoding convertfrom $p]
1742                 if {[string index $p end] eq {/}} {
1743                         set p [string range $p 0 end-1]
1744                 }
1745                 merge_state $p ?O
1746         }
1747         rescan_done $fd buf_rlo $after
1748 }
1749
1750 proc rescan_done {fd buf after} {
1751         global rescan_active current_diff_path
1752         global file_states repo_config
1753         upvar $buf to_clear
1754
1755         if {![eof $fd]} return
1756         set to_clear {}
1757         close $fd
1758         if {[incr rescan_active -1] > 0} return
1759
1760         prune_selection
1761         unlock_index
1762         display_all_files
1763         if {$current_diff_path ne {}} { reshow_diff $after }
1764         if {$current_diff_path eq {}} { select_first_diff $after }
1765 }
1766
1767 proc prune_selection {} {
1768         global file_states selected_paths
1769
1770         foreach path [array names selected_paths] {
1771                 if {[catch {set still_here $file_states($path)}]} {
1772                         unset selected_paths($path)
1773                 }
1774         }
1775 }
1776
1777 ######################################################################
1778 ##
1779 ## ui helpers
1780
1781 proc mapicon {w state path} {
1782         global all_icons
1783
1784         if {[catch {set r $all_icons($state$w)}]} {
1785                 puts "error: no icon for $w state={$state} $path"
1786                 return file_plain
1787         }
1788         return $r
1789 }
1790
1791 proc mapdesc {state path} {
1792         global all_descs
1793
1794         if {[catch {set r $all_descs($state)}]} {
1795                 puts "error: no desc for state={$state} $path"
1796                 return $state
1797         }
1798         return $r
1799 }
1800
1801 proc ui_status {msg} {
1802         global main_status
1803         if {[info exists main_status]} {
1804                 $main_status show $msg
1805         }
1806 }
1807
1808 proc ui_ready {{test {}}} {
1809         global main_status
1810         if {[info exists main_status]} {
1811                 $main_status show [mc "Ready."] $test
1812         }
1813 }
1814
1815 proc escape_path {path} {
1816         regsub -all {\\} $path "\\\\" path
1817         regsub -all "\n" $path "\\n" path
1818         return $path
1819 }
1820
1821 proc short_path {path} {
1822         return [escape_path [lindex [file split $path] end]]
1823 }
1824
1825 set next_icon_id 0
1826 set null_sha1 [string repeat 0 40]
1827
1828 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1829         global file_states next_icon_id null_sha1
1830
1831         set s0 [string index $new_state 0]
1832         set s1 [string index $new_state 1]
1833
1834         if {[catch {set info $file_states($path)}]} {
1835                 set state __
1836                 set icon n[incr next_icon_id]
1837         } else {
1838                 set state [lindex $info 0]
1839                 set icon [lindex $info 1]
1840                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1841                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1842         }
1843
1844         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1845         elseif {$s0 eq {_}} {set s0 _}
1846
1847         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1848         elseif {$s1 eq {_}} {set s1 _}
1849
1850         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1851                 set head_info [list 0 $null_sha1]
1852         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1853                 && $head_info eq {}} {
1854                 set head_info $index_info
1855         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1856                 set index_info $head_info
1857                 set head_info {}
1858         }
1859
1860         set file_states($path) [list $s0$s1 $icon \
1861                 $head_info $index_info \
1862                 ]
1863         return $state
1864 }
1865
1866 proc display_file_helper {w path icon_name old_m new_m} {
1867         global file_lists
1868
1869         if {$new_m eq {_}} {
1870                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1871                 if {$lno >= 0} {
1872                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1873                         incr lno
1874                         $w conf -state normal
1875                         $w delete $lno.0 [expr {$lno + 1}].0
1876                         $w conf -state disabled
1877                 }
1878         } elseif {$old_m eq {_} && $new_m ne {_}} {
1879                 lappend file_lists($w) $path
1880                 set file_lists($w) [lsort -unique $file_lists($w)]
1881                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1882                 incr lno
1883                 $w conf -state normal
1884                 $w image create $lno.0 \
1885                         -align center -padx 5 -pady 1 \
1886                         -name $icon_name \
1887                         -image [mapicon $w $new_m $path]
1888                 $w insert $lno.1 "[escape_path $path]\n"
1889                 $w conf -state disabled
1890         } elseif {$old_m ne $new_m} {
1891                 $w conf -state normal
1892                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1893                 $w conf -state disabled
1894         }
1895 }
1896
1897 proc display_file {path state} {
1898         global file_states selected_paths
1899         global ui_index ui_workdir
1900
1901         set old_m [merge_state $path $state]
1902         set s $file_states($path)
1903         set new_m [lindex $s 0]
1904         set icon_name [lindex $s 1]
1905
1906         set o [string index $old_m 0]
1907         set n [string index $new_m 0]
1908         if {$o eq {U}} {
1909                 set o _
1910         }
1911         if {$n eq {U}} {
1912                 set n _
1913         }
1914         display_file_helper     $ui_index $path $icon_name $o $n
1915
1916         if {[string index $old_m 0] eq {U}} {
1917                 set o U
1918         } else {
1919                 set o [string index $old_m 1]
1920         }
1921         if {[string index $new_m 0] eq {U}} {
1922                 set n U
1923         } else {
1924                 set n [string index $new_m 1]
1925         }
1926         display_file_helper     $ui_workdir $path $icon_name $o $n
1927
1928         if {$new_m eq {__}} {
1929                 unset file_states($path)
1930                 catch {unset selected_paths($path)}
1931         }
1932 }
1933
1934 proc display_all_files_helper {w path icon_name m} {
1935         global file_lists
1936
1937         lappend file_lists($w) $path
1938         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1939         $w image create end \
1940                 -align center -padx 5 -pady 1 \
1941                 -name $icon_name \
1942                 -image [mapicon $w $m $path]
1943         $w insert end "[escape_path $path]\n"
1944 }
1945
1946 set files_warning 0
1947 proc display_all_files {} {
1948         global ui_index ui_workdir
1949         global file_states file_lists
1950         global last_clicked
1951         global files_warning
1952
1953         $ui_index conf -state normal
1954         $ui_workdir conf -state normal
1955
1956         $ui_index delete 0.0 end
1957         $ui_workdir delete 0.0 end
1958         set last_clicked {}
1959
1960         set file_lists($ui_index) [list]
1961         set file_lists($ui_workdir) [list]
1962
1963         set to_display [lsort [array names file_states]]
1964         set display_limit [get_config gui.maxfilesdisplayed]
1965         if {[llength $to_display] > $display_limit} {
1966                 if {!$files_warning} {
1967                         # do not repeatedly warn:
1968                         set files_warning 1
1969                         info_popup [mc "Displaying only %s of %s files." \
1970                                 $display_limit [llength $to_display]]
1971                 }
1972                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1973         }
1974         foreach path $to_display {
1975                 set s $file_states($path)
1976                 set m [lindex $s 0]
1977                 set icon_name [lindex $s 1]
1978
1979                 set s [string index $m 0]
1980                 if {$s ne {U} && $s ne {_}} {
1981                         display_all_files_helper $ui_index $path \
1982                                 $icon_name $s
1983                 }
1984
1985                 if {[string index $m 0] eq {U}} {
1986                         set s U
1987                 } else {
1988                         set s [string index $m 1]
1989                 }
1990                 if {$s ne {_}} {
1991                         display_all_files_helper $ui_workdir $path \
1992                                 $icon_name $s
1993                 }
1994         }
1995
1996         $ui_index conf -state disabled
1997         $ui_workdir conf -state disabled
1998 }
1999
2000 ######################################################################
2001 ##
2002 ## icons
2003
2004 set filemask {
2005 #define mask_width 14
2006 #define mask_height 15
2007 static unsigned char mask_bits[] = {
2008    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2009    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2010    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2011 }
2012
2013 image create bitmap file_plain -background white -foreground black -data {
2014 #define plain_width 14
2015 #define plain_height 15
2016 static unsigned char plain_bits[] = {
2017    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2018    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2019    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2020 } -maskdata $filemask
2021
2022 image create bitmap file_mod -background white -foreground blue -data {
2023 #define mod_width 14
2024 #define mod_height 15
2025 static unsigned char mod_bits[] = {
2026    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2027    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2028    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2029 } -maskdata $filemask
2030
2031 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2032 #define file_fulltick_width 14
2033 #define file_fulltick_height 15
2034 static unsigned char file_fulltick_bits[] = {
2035    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2036    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2037    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2038 } -maskdata $filemask
2039
2040 image create bitmap file_question -background white -foreground black -data {
2041 #define file_question_width 14
2042 #define file_question_height 15
2043 static unsigned char file_question_bits[] = {
2044    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2045    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2046    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2047 } -maskdata $filemask
2048
2049 image create bitmap file_removed -background white -foreground red -data {
2050 #define file_removed_width 14
2051 #define file_removed_height 15
2052 static unsigned char file_removed_bits[] = {
2053    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2054    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2055    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2056 } -maskdata $filemask
2057
2058 image create bitmap file_merge -background white -foreground blue -data {
2059 #define file_merge_width 14
2060 #define file_merge_height 15
2061 static unsigned char file_merge_bits[] = {
2062    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2063    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2064    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2065 } -maskdata $filemask
2066
2067 image create bitmap file_statechange -background white -foreground green -data {
2068 #define file_statechange_width 14
2069 #define file_statechange_height 15
2070 static unsigned char file_statechange_bits[] = {
2071    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
2072    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
2073    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2074 } -maskdata $filemask
2075
2076 set ui_index .vpane.files.index.list
2077 set ui_workdir .vpane.files.workdir.list
2078
2079 set all_icons(_$ui_index)   file_plain
2080 set all_icons(A$ui_index)   file_plain
2081 set all_icons(M$ui_index)   file_fulltick
2082 set all_icons(D$ui_index)   file_removed
2083 set all_icons(U$ui_index)   file_merge
2084 set all_icons(T$ui_index)   file_statechange
2085
2086 set all_icons(_$ui_workdir) file_plain
2087 set all_icons(M$ui_workdir) file_mod
2088 set all_icons(D$ui_workdir) file_question
2089 set all_icons(U$ui_workdir) file_merge
2090 set all_icons(O$ui_workdir) file_plain
2091 set all_icons(T$ui_workdir) file_statechange
2092
2093 set max_status_desc 0
2094 foreach i {
2095                 {__ {mc "Unmodified"}}
2096
2097                 {_M {mc "Modified, not staged"}}
2098                 {M_ {mc "Staged for commit"}}
2099                 {MM {mc "Portions staged for commit"}}
2100                 {MD {mc "Staged for commit, missing"}}
2101
2102                 {_T {mc "File type changed, not staged"}}
2103                 {MT {mc "File type changed, old type staged for commit"}}
2104                 {AT {mc "File type changed, old type staged for commit"}}
2105                 {T_ {mc "File type changed, staged"}}
2106                 {TM {mc "File type change staged, modification not staged"}}
2107                 {TD {mc "File type change staged, file missing"}}
2108
2109                 {_O {mc "Untracked, not staged"}}
2110                 {A_ {mc "Staged for commit"}}
2111                 {AM {mc "Portions staged for commit"}}
2112                 {AD {mc "Staged for commit, missing"}}
2113
2114                 {_D {mc "Missing"}}
2115                 {D_ {mc "Staged for removal"}}
2116                 {DO {mc "Staged for removal, still present"}}
2117
2118                 {_U {mc "Requires merge resolution"}}
2119                 {U_ {mc "Requires merge resolution"}}
2120                 {UU {mc "Requires merge resolution"}}
2121                 {UM {mc "Requires merge resolution"}}
2122                 {UD {mc "Requires merge resolution"}}
2123                 {UT {mc "Requires merge resolution"}}
2124         } {
2125         set text [eval [lindex $i 1]]
2126         if {$max_status_desc < [string length $text]} {
2127                 set max_status_desc [string length $text]
2128         }
2129         set all_descs([lindex $i 0]) $text
2130 }
2131 unset i
2132
2133 ######################################################################
2134 ##
2135 ## util
2136
2137 proc scrollbar2many {list mode args} {
2138         foreach w $list {eval $w $mode $args}
2139 }
2140
2141 proc many2scrollbar {list mode sb top bottom} {
2142         $sb set $top $bottom
2143         foreach w $list {$w $mode moveto $top}
2144 }
2145
2146 proc incr_font_size {font {amt 1}} {
2147         set sz [font configure $font -size]
2148         incr sz $amt
2149         font configure $font -size $sz
2150         font configure ${font}bold -size $sz
2151         font configure ${font}italic -size $sz
2152 }
2153
2154 ######################################################################
2155 ##
2156 ## ui commands
2157
2158 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2159
2160 proc do_gitk {revs {is_submodule false}} {
2161         global current_diff_path file_states current_diff_side ui_index
2162         global _gitdir _gitworktree
2163
2164         # -- Always start gitk through whatever we were loaded with.  This
2165         #    lets us bypass using shell process on Windows systems.
2166         #
2167         set exe [_which gitk -script]
2168         set cmd [list [info nameofexecutable] $exe]
2169         if {$exe eq {}} {
2170                 error_popup [mc "Couldn't find gitk in PATH"]
2171         } else {
2172                 global env
2173
2174                 set pwd [pwd]
2175
2176                 if {!$is_submodule} {
2177                         if {![is_bare]} {
2178                                 cd $_gitworktree
2179                         }
2180                 } else {
2181                         cd $current_diff_path
2182                         if {$revs eq {--}} {
2183                                 set s $file_states($current_diff_path)
2184                                 set old_sha1 {}
2185                                 set new_sha1 {}
2186                                 switch -glob -- [lindex $s 0] {
2187                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2188                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2189                                 MM {
2190                                         if {$current_diff_side eq $ui_index} {
2191                                                 set old_sha1 [lindex [lindex $s 2] 1]
2192                                                 set new_sha1 [lindex [lindex $s 3] 1]
2193                                         } else {
2194                                                 set old_sha1 [lindex [lindex $s 3] 1]
2195                                         }
2196                                 }
2197                                 }
2198                                 set revs $old_sha1...$new_sha1
2199                         }
2200                         # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2201                         # we've been using for the main repository, so unset them.
2202                         # TODO we could make life easier (start up faster?) for gitk
2203                         # by setting these to the appropriate values to allow gitk
2204                         # to skip the heuristics to find their proper value
2205                         unset env(GIT_DIR)
2206                         unset env(GIT_WORK_TREE)
2207                 }
2208                 eval exec $cmd $revs "--" "--" &
2209
2210                 set env(GIT_DIR) $_gitdir
2211                 set env(GIT_WORK_TREE) $_gitworktree
2212                 cd $pwd
2213
2214                 ui_status $::starting_gitk_msg
2215                 after 10000 {
2216                         ui_ready $starting_gitk_msg
2217                 }
2218         }
2219 }
2220
2221 proc do_git_gui {} {
2222         global current_diff_path
2223
2224         # -- Always start git gui through whatever we were loaded with.  This
2225         #    lets us bypass using shell process on Windows systems.
2226         #
2227         set exe [list [_which git]]
2228         if {$exe eq {}} {
2229                 error_popup [mc "Couldn't find git gui in PATH"]
2230         } else {
2231                 global env
2232                 global _gitdir _gitworktree
2233
2234                 # see note in do_gitk about unsetting these vars when
2235                 # running tools in a submodule
2236                 unset env(GIT_DIR)
2237                 unset env(GIT_WORK_TREE)
2238
2239                 set pwd [pwd]
2240                 cd $current_diff_path
2241
2242                 eval exec $exe gui &
2243
2244                 set env(GIT_DIR) $_gitdir
2245                 set env(GIT_WORK_TREE) $_gitworktree
2246                 cd $pwd
2247
2248                 ui_status $::starting_gitk_msg
2249                 after 10000 {
2250                         ui_ready $starting_gitk_msg
2251                 }
2252         }
2253 }
2254
2255 proc do_explore {} {
2256         global _gitworktree
2257         set explorer {}
2258         if {[is_Cygwin] || [is_Windows]} {
2259                 set explorer "explorer.exe"
2260         } elseif {[is_MacOSX]} {
2261                 set explorer "open"
2262         } else {
2263                 # freedesktop.org-conforming system is our best shot
2264                 set explorer "xdg-open"
2265         }
2266         eval exec $explorer [list [file nativename $_gitworktree]] &
2267 }
2268
2269 set is_quitting 0
2270 set ret_code    1
2271
2272 proc terminate_me {win} {
2273         global ret_code
2274         if {$win ne {.}} return
2275         exit $ret_code
2276 }
2277
2278 proc do_quit {{rc {1}}} {
2279         global ui_comm is_quitting repo_config commit_type
2280         global GITGUI_BCK_exists GITGUI_BCK_i
2281         global ui_comm_spell
2282         global ret_code use_ttk
2283
2284         if {$is_quitting} return
2285         set is_quitting 1
2286
2287         if {[winfo exists $ui_comm]} {
2288                 # -- Stash our current commit buffer.
2289                 #
2290                 set save [gitdir GITGUI_MSG]
2291                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2292                         file rename -force [gitdir GITGUI_BCK] $save
2293                         set GITGUI_BCK_exists 0
2294                 } else {
2295                         set msg [string trim [$ui_comm get 0.0 end]]
2296                         regsub -all -line {[ \r\t]+$} $msg {} msg
2297                         if {(![string match amend* $commit_type]
2298                                 || [$ui_comm edit modified])
2299                                 && $msg ne {}} {
2300                                 catch {
2301                                         set fd [open $save w]
2302                                         fconfigure $fd -encoding utf-8
2303                                         puts -nonewline $fd $msg
2304                                         close $fd
2305                                 }
2306                         } else {
2307                                 catch {file delete $save}
2308                         }
2309                 }
2310
2311                 # -- Cancel our spellchecker if its running.
2312                 #
2313                 if {[info exists ui_comm_spell]} {
2314                         $ui_comm_spell stop
2315                 }
2316
2317                 # -- Remove our editor backup, its not needed.
2318                 #
2319                 after cancel $GITGUI_BCK_i
2320                 if {$GITGUI_BCK_exists} {
2321                         catch {file delete [gitdir GITGUI_BCK]}
2322                 }
2323
2324                 # -- Stash our current window geometry into this repository.
2325                 #
2326                 set cfg_wmstate [wm state .]
2327                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2328                         set rc_wmstate {}
2329                 }
2330                 if {$cfg_wmstate ne $rc_wmstate} {
2331                         catch {git config gui.wmstate $cfg_wmstate}
2332                 }
2333                 if {$cfg_wmstate eq {zoomed}} {
2334                         # on Windows wm geometry will lie about window
2335                         # position (but not size) when window is zoomed
2336                         # restore the window before querying wm geometry
2337                         wm state . normal
2338                 }
2339                 set cfg_geometry [list]
2340                 lappend cfg_geometry [wm geometry .]
2341                 if {$use_ttk} {
2342                         lappend cfg_geometry [.vpane sashpos 0]
2343                         lappend cfg_geometry [.vpane.files sashpos 0]
2344                 } else {
2345                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2346                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2347                 }
2348                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2349                         set rc_geometry {}
2350                 }
2351                 if {$cfg_geometry ne $rc_geometry} {
2352                         catch {git config gui.geometry $cfg_geometry}
2353                 }
2354         }
2355
2356         set ret_code $rc
2357
2358         # Briefly enable send again, working around Tk bug
2359         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2360         tk appname [appname]
2361
2362         destroy .
2363 }
2364
2365 proc do_rescan {} {
2366         rescan ui_ready
2367 }
2368
2369 proc ui_do_rescan {} {
2370         rescan {force_first_diff ui_ready}
2371 }
2372
2373 proc do_commit {} {
2374         commit_tree
2375 }
2376
2377 proc next_diff {{after {}}} {
2378         global next_diff_p next_diff_w next_diff_i
2379         show_diff $next_diff_p $next_diff_w {} {} $after
2380 }
2381
2382 proc find_anchor_pos {lst name} {
2383         set lid [lsearch -sorted -exact $lst $name]
2384
2385         if {$lid == -1} {
2386                 set lid 0
2387                 foreach lname $lst {
2388                         if {$lname >= $name} break
2389                         incr lid
2390                 }
2391         }
2392
2393         return $lid
2394 }
2395
2396 proc find_file_from {flist idx delta path mmask} {
2397         global file_states
2398
2399         set len [llength $flist]
2400         while {$idx >= 0 && $idx < $len} {
2401                 set name [lindex $flist $idx]
2402
2403                 if {$name ne $path && [info exists file_states($name)]} {
2404                         set state [lindex $file_states($name) 0]
2405
2406                         if {$mmask eq {} || [regexp $mmask $state]} {
2407                                 return $idx
2408                         }
2409                 }
2410
2411                 incr idx $delta
2412         }
2413
2414         return {}
2415 }
2416
2417 proc find_next_diff {w path {lno {}} {mmask {}}} {
2418         global next_diff_p next_diff_w next_diff_i
2419         global file_lists ui_index ui_workdir
2420
2421         set flist $file_lists($w)
2422         if {$lno eq {}} {
2423                 set lno [find_anchor_pos $flist $path]
2424         } else {
2425                 incr lno -1
2426         }
2427
2428         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2429                 if {$w eq $ui_index} {
2430                         set mmask "^$mmask"
2431                 } else {
2432                         set mmask "$mmask\$"
2433                 }
2434         }
2435
2436         set idx [find_file_from $flist $lno 1 $path $mmask]
2437         if {$idx eq {}} {
2438                 incr lno -1
2439                 set idx [find_file_from $flist $lno -1 $path $mmask]
2440         }
2441
2442         if {$idx ne {}} {
2443                 set next_diff_w $w
2444                 set next_diff_p [lindex $flist $idx]
2445                 set next_diff_i [expr {$idx+1}]
2446                 return 1
2447         } else {
2448                 return 0
2449         }
2450 }
2451
2452 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2453         global current_diff_path
2454
2455         if {$path ne $current_diff_path} {
2456                 return {}
2457         } elseif {[find_next_diff $w $path $lno $mmask]} {
2458                 return {next_diff;}
2459         } else {
2460                 return {reshow_diff;}
2461         }
2462 }
2463
2464 proc select_first_diff {after} {
2465         global ui_workdir
2466
2467         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2468             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2469                 next_diff $after
2470         } else {
2471                 uplevel #0 $after
2472         }
2473 }
2474
2475 proc force_first_diff {after} {
2476         global ui_workdir current_diff_path file_states
2477
2478         if {[info exists file_states($current_diff_path)]} {
2479                 set state [lindex $file_states($current_diff_path) 0]
2480         } else {
2481                 set state {OO}
2482         }
2483
2484         set reselect 0
2485         if {[string first {U} $state] >= 0} {
2486                 # Already a conflict, do nothing
2487         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2488                 set reselect 1
2489         } elseif {[string index $state 1] ne {O}} {
2490                 # Already a diff & no conflicts, do nothing
2491         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2492                 set reselect 1
2493         }
2494
2495         if {$reselect} {
2496                 next_diff $after
2497         } else {
2498                 uplevel #0 $after
2499         }
2500 }
2501
2502 proc toggle_or_diff {w x y} {
2503         global file_states file_lists current_diff_path ui_index ui_workdir
2504         global last_clicked selected_paths
2505
2506         set pos [split [$w index @$x,$y] .]
2507         set lno [lindex $pos 0]
2508         set col [lindex $pos 1]
2509         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2510         if {$path eq {}} {
2511                 set last_clicked {}
2512                 return
2513         }
2514
2515         set last_clicked [list $w $lno]
2516         array unset selected_paths
2517         $ui_index tag remove in_sel 0.0 end
2518         $ui_workdir tag remove in_sel 0.0 end
2519
2520         # Determine the state of the file
2521         if {[info exists file_states($path)]} {
2522                 set state [lindex $file_states($path) 0]
2523         } else {
2524                 set state {__}
2525         }
2526
2527         # Restage the file, or simply show the diff
2528         if {$col == 0 && $y > 1} {
2529                 # Conflicts need special handling
2530                 if {[string first {U} $state] >= 0} {
2531                         # $w must always be $ui_workdir, but...
2532                         if {$w ne $ui_workdir} { set lno {} }
2533                         merge_stage_workdir $path $lno
2534                         return
2535                 }
2536
2537                 if {[string index $state 1] eq {O}} {
2538                         set mmask {}
2539                 } else {
2540                         set mmask {[^O]}
2541                 }
2542
2543                 set after [next_diff_after_action $w $path $lno $mmask]
2544
2545                 if {$w eq $ui_index} {
2546                         update_indexinfo \
2547                                 "Unstaging [short_path $path] from commit" \
2548                                 [list $path] \
2549                                 [concat $after [list ui_ready]]
2550                 } elseif {$w eq $ui_workdir} {
2551                         update_index \
2552                                 "Adding [short_path $path]" \
2553                                 [list $path] \
2554                                 [concat $after [list ui_ready]]
2555                 }
2556         } else {
2557                 set selected_paths($path) 1
2558                 show_diff $path $w $lno
2559         }
2560 }
2561
2562 proc add_one_to_selection {w x y} {
2563         global file_lists last_clicked selected_paths
2564
2565         set lno [lindex [split [$w index @$x,$y] .] 0]
2566         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2567         if {$path eq {}} {
2568                 set last_clicked {}
2569                 return
2570         }
2571
2572         if {$last_clicked ne {}
2573                 && [lindex $last_clicked 0] ne $w} {
2574                 array unset selected_paths
2575                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2576         }
2577
2578         set last_clicked [list $w $lno]
2579         if {[catch {set in_sel $selected_paths($path)}]} {
2580                 set in_sel 0
2581         }
2582         if {$in_sel} {
2583                 unset selected_paths($path)
2584                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2585         } else {
2586                 set selected_paths($path) 1
2587                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2588         }
2589 }
2590
2591 proc add_range_to_selection {w x y} {
2592         global file_lists last_clicked selected_paths
2593
2594         if {[lindex $last_clicked 0] ne $w} {
2595                 toggle_or_diff $w $x $y
2596                 return
2597         }
2598
2599         set lno [lindex [split [$w index @$x,$y] .] 0]
2600         set lc [lindex $last_clicked 1]
2601         if {$lc < $lno} {
2602                 set begin $lc
2603                 set end $lno
2604         } else {
2605                 set begin $lno
2606                 set end $lc
2607         }
2608
2609         foreach path [lrange $file_lists($w) \
2610                 [expr {$begin - 1}] \
2611                 [expr {$end - 1}]] {
2612                 set selected_paths($path) 1
2613         }
2614         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2615 }
2616
2617 proc show_more_context {} {
2618         global repo_config
2619         if {$repo_config(gui.diffcontext) < 99} {
2620                 incr repo_config(gui.diffcontext)
2621                 reshow_diff
2622         }
2623 }
2624
2625 proc show_less_context {} {
2626         global repo_config
2627         if {$repo_config(gui.diffcontext) > 1} {
2628                 incr repo_config(gui.diffcontext) -1
2629                 reshow_diff
2630         }
2631 }
2632
2633 ######################################################################
2634 ##
2635 ## ui construction
2636
2637 set ui_comm {}
2638
2639 # -- Menu Bar
2640 #
2641 menu .mbar -tearoff 0
2642 if {[is_MacOSX]} {
2643         # -- Apple Menu (Mac OS X only)
2644         #
2645         .mbar add cascade -label Apple -menu .mbar.apple
2646         menu .mbar.apple
2647 }
2648 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2649 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2650 if {[is_enabled branch]} {
2651         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2652 }
2653 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2654         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2655 }
2656 if {[is_enabled transport]} {
2657         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2658         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2659 }
2660 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2661         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2662 }
2663
2664 # -- Repository Menu
2665 #
2666 menu .mbar.repository
2667
2668 if {![is_bare]} {
2669         .mbar.repository add command \
2670                 -label [mc "Explore Working Copy"] \
2671                 -command {do_explore}
2672 }
2673
2674 if {[is_Windows]} {
2675         .mbar.repository add command \
2676                 -label [mc "Git Bash"] \
2677                 -command {eval exec [auto_execok start] \
2678                                           [list "Git Bash" bash --login -l &]}
2679 }
2680
2681 if {[is_Windows] || ![is_bare]} {
2682         .mbar.repository add separator
2683 }
2684
2685 .mbar.repository add command \
2686         -label [mc "Browse Current Branch's Files"] \
2687         -command {browser::new $current_branch}
2688 set ui_browse_current [.mbar.repository index last]
2689 .mbar.repository add command \
2690         -label [mc "Browse Branch Files..."] \
2691         -command browser_open::dialog
2692 .mbar.repository add separator
2693
2694 .mbar.repository add command \
2695         -label [mc "Visualize Current Branch's History"] \
2696         -command {do_gitk $current_branch}
2697 set ui_visualize_current [.mbar.repository index last]
2698 .mbar.repository add command \
2699         -label [mc "Visualize All Branch History"] \
2700         -command {do_gitk --all}
2701 .mbar.repository add separator
2702
2703 proc current_branch_write {args} {
2704         global current_branch
2705         .mbar.repository entryconf $::ui_browse_current \
2706                 -label [mc "Browse %s's Files" $current_branch]
2707         .mbar.repository entryconf $::ui_visualize_current \
2708                 -label [mc "Visualize %s's History" $current_branch]
2709 }
2710 trace add variable current_branch write current_branch_write
2711
2712 if {[is_enabled multicommit]} {
2713         .mbar.repository add command -label [mc "Database Statistics"] \
2714                 -command do_stats
2715
2716         .mbar.repository add command -label [mc "Compress Database"] \
2717                 -command do_gc
2718
2719         .mbar.repository add command -label [mc "Verify Database"] \
2720                 -command do_fsck_objects
2721
2722         .mbar.repository add separator
2723
2724         if {[is_Cygwin]} {
2725                 .mbar.repository add command \
2726                         -label [mc "Create Desktop Icon"] \
2727                         -command do_cygwin_shortcut
2728         } elseif {[is_Windows]} {
2729                 .mbar.repository add command \
2730                         -label [mc "Create Desktop Icon"] \
2731                         -command do_windows_shortcut
2732         } elseif {[is_MacOSX]} {
2733                 .mbar.repository add command \
2734                         -label [mc "Create Desktop Icon"] \
2735                         -command do_macosx_app
2736         }
2737 }
2738
2739 if {[is_MacOSX]} {
2740         proc ::tk::mac::Quit {args} { do_quit }
2741 } else {
2742         .mbar.repository add command -label [mc Quit] \
2743                 -command do_quit \
2744                 -accelerator $M1T-Q
2745 }
2746
2747 # -- Edit Menu
2748 #
2749 menu .mbar.edit
2750 .mbar.edit add command -label [mc Undo] \
2751         -command {catch {[focus] edit undo}} \
2752         -accelerator $M1T-Z
2753 .mbar.edit add command -label [mc Redo] \
2754         -command {catch {[focus] edit redo}} \
2755         -accelerator $M1T-Y
2756 .mbar.edit add separator
2757 .mbar.edit add command -label [mc Cut] \
2758         -command {catch {tk_textCut [focus]}} \
2759         -accelerator $M1T-X
2760 .mbar.edit add command -label [mc Copy] \
2761         -command {catch {tk_textCopy [focus]}} \
2762         -accelerator $M1T-C
2763 .mbar.edit add command -label [mc Paste] \
2764         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2765         -accelerator $M1T-V
2766 .mbar.edit add command -label [mc Delete] \
2767         -command {catch {[focus] delete sel.first sel.last}} \
2768         -accelerator Del
2769 .mbar.edit add separator
2770 .mbar.edit add command -label [mc "Select All"] \
2771         -command {catch {[focus] tag add sel 0.0 end}} \
2772         -accelerator $M1T-A
2773
2774 # -- Branch Menu
2775 #
2776 if {[is_enabled branch]} {
2777         menu .mbar.branch
2778
2779         .mbar.branch add command -label [mc "Create..."] \
2780                 -command branch_create::dialog \
2781                 -accelerator $M1T-N
2782         lappend disable_on_lock [list .mbar.branch entryconf \
2783                 [.mbar.branch index last] -state]
2784
2785         .mbar.branch add command -label [mc "Checkout..."] \
2786                 -command branch_checkout::dialog \
2787                 -accelerator $M1T-O
2788         lappend disable_on_lock [list .mbar.branch entryconf \
2789                 [.mbar.branch index last] -state]
2790
2791         .mbar.branch add command -label [mc "Rename..."] \
2792                 -command branch_rename::dialog
2793         lappend disable_on_lock [list .mbar.branch entryconf \
2794                 [.mbar.branch index last] -state]
2795
2796         .mbar.branch add command -label [mc "Delete..."] \
2797                 -command branch_delete::dialog
2798         lappend disable_on_lock [list .mbar.branch entryconf \
2799                 [.mbar.branch index last] -state]
2800
2801         .mbar.branch add command -label [mc "Reset..."] \
2802                 -command merge::reset_hard
2803         lappend disable_on_lock [list .mbar.branch entryconf \
2804                 [.mbar.branch index last] -state]
2805 }
2806
2807 # -- Commit Menu
2808 #
2809 proc commit_btn_caption {} {
2810         if {[is_enabled nocommit]} {
2811                 return [mc "Done"]
2812         } else {
2813                 return [mc Commit@@verb]
2814         }
2815 }
2816
2817 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2818         menu .mbar.commit
2819
2820         if {![is_enabled nocommit]} {
2821                 .mbar.commit add radiobutton \
2822                         -label [mc "New Commit"] \
2823                         -command do_select_commit_type \
2824                         -variable selected_commit_type \
2825                         -value new
2826                 lappend disable_on_lock \
2827                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2828
2829                 .mbar.commit add radiobutton \
2830                         -label [mc "Amend Last Commit"] \
2831                         -command do_select_commit_type \
2832                         -variable selected_commit_type \
2833                         -value amend
2834                 lappend disable_on_lock \
2835                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2836
2837                 .mbar.commit add separator
2838         }
2839
2840         .mbar.commit add command -label [mc Rescan] \
2841                 -command ui_do_rescan \
2842                 -accelerator F5
2843         lappend disable_on_lock \
2844                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2845
2846         .mbar.commit add command -label [mc "Stage To Commit"] \
2847                 -command do_add_selection \
2848                 -accelerator $M1T-T
2849         lappend disable_on_lock \
2850                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2851
2852         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2853                 -command do_add_all \
2854                 -accelerator $M1T-I
2855         lappend disable_on_lock \
2856                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2857
2858         .mbar.commit add command -label [mc "Unstage From Commit"] \
2859                 -command do_unstage_selection \
2860                 -accelerator $M1T-U
2861         lappend disable_on_lock \
2862                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2863
2864         .mbar.commit add command -label [mc "Revert Changes"] \
2865                 -command do_revert_selection \
2866                 -accelerator $M1T-J
2867         lappend disable_on_lock \
2868                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2869
2870         .mbar.commit add separator
2871
2872         .mbar.commit add command -label [mc "Show Less Context"] \
2873                 -command show_less_context \
2874                 -accelerator $M1T-\-
2875
2876         .mbar.commit add command -label [mc "Show More Context"] \
2877                 -command show_more_context \
2878                 -accelerator $M1T-=
2879
2880         .mbar.commit add separator
2881
2882         if {![is_enabled nocommitmsg]} {
2883                 .mbar.commit add command -label [mc "Sign Off"] \
2884                         -command do_signoff \
2885                         -accelerator $M1T-S
2886         }
2887
2888         .mbar.commit add command -label [commit_btn_caption] \
2889                 -command do_commit \
2890                 -accelerator $M1T-Return
2891         lappend disable_on_lock \
2892                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2893 }
2894
2895 # -- Merge Menu
2896 #
2897 if {[is_enabled branch]} {
2898         menu .mbar.merge
2899         .mbar.merge add command -label [mc "Local Merge..."] \
2900                 -command merge::dialog \
2901                 -accelerator $M1T-M
2902         lappend disable_on_lock \
2903                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2904         .mbar.merge add command -label [mc "Abort Merge..."] \
2905                 -command merge::reset_hard
2906         lappend disable_on_lock \
2907                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2908 }
2909
2910 # -- Transport Menu
2911 #
2912 if {[is_enabled transport]} {
2913         menu .mbar.remote
2914
2915         .mbar.remote add command \
2916                 -label [mc "Add..."] \
2917                 -command remote_add::dialog \
2918                 -accelerator $M1T-A
2919         .mbar.remote add command \
2920                 -label [mc "Push..."] \
2921                 -command do_push_anywhere \
2922                 -accelerator $M1T-P
2923         .mbar.remote add command \
2924                 -label [mc "Delete Branch..."] \
2925                 -command remote_branch_delete::dialog
2926 }
2927
2928 if {[is_MacOSX]} {
2929         proc ::tk::mac::ShowPreferences {} {do_options}
2930 } else {
2931         # -- Edit Menu
2932         #
2933         .mbar.edit add separator
2934         .mbar.edit add command -label [mc "Options..."] \
2935                 -command do_options
2936 }
2937
2938 # -- Tools Menu
2939 #
2940 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2941         set tools_menubar .mbar.tools
2942         menu $tools_menubar
2943         $tools_menubar add separator
2944         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2945         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2946         set tools_tailcnt 3
2947         if {[array names repo_config guitool.*.cmd] ne {}} {
2948                 tools_populate_all
2949         }
2950 }
2951
2952 # -- Help Menu
2953 #
2954 .mbar add cascade -label [mc Help] -menu .mbar.help
2955 menu .mbar.help
2956
2957 if {[is_MacOSX]} {
2958         .mbar.apple add command -label [mc "About %s" [appname]] \
2959                 -command do_about
2960         .mbar.apple add separator
2961 } else {
2962         .mbar.help add command -label [mc "About %s" [appname]] \
2963                 -command do_about
2964 }
2965 . configure -menu .mbar
2966
2967 set doc_path [githtmldir]
2968 if {$doc_path ne {}} {
2969         set doc_path [file join $doc_path index.html]
2970
2971         if {[is_Cygwin]} {
2972                 set doc_path [exec cygpath --mixed $doc_path]
2973         }
2974 }
2975
2976 if {[file isfile $doc_path]} {
2977         set doc_url "file:$doc_path"
2978 } else {
2979         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2980 }
2981
2982 proc start_browser {url} {
2983         git "web--browse" $url
2984 }
2985
2986 .mbar.help add command -label [mc "Online Documentation"] \
2987         -command [list start_browser $doc_url]
2988
2989 .mbar.help add command -label [mc "Show SSH Key"] \
2990         -command do_ssh_key
2991
2992 unset doc_path doc_url
2993
2994 # -- Standard bindings
2995 #
2996 wm protocol . WM_DELETE_WINDOW do_quit
2997 bind all <$M1B-Key-q> do_quit
2998 bind all <$M1B-Key-Q> do_quit
2999 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3000 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3001
3002 set subcommand_args {}
3003 proc usage {} {
3004         set s "usage: $::argv0 $::subcommand $::subcommand_args"
3005         if {[tk windowingsystem] eq "win32"} {
3006                 wm withdraw .
3007                 tk_messageBox -icon info -message $s \
3008                         -title [mc "Usage"]
3009         } else {
3010                 puts stderr $s
3011         }
3012         exit 1
3013 }
3014
3015 proc normalize_relpath {path} {
3016         set elements {}
3017         foreach item [file split $path] {
3018                 if {$item eq {.}} continue
3019                 if {$item eq {..} && [llength $elements] > 0
3020                     && [lindex $elements end] ne {..}} {
3021                         set elements [lrange $elements 0 end-1]
3022                         continue
3023                 }
3024                 lappend elements $item
3025         }
3026         return [eval file join $elements]
3027 }
3028
3029 # -- Not a normal commit type invocation?  Do that instead!
3030 #
3031 switch -- $subcommand {
3032 browser -
3033 blame {
3034         if {$subcommand eq "blame"} {
3035                 set subcommand_args {[--line=<num>] rev? path}
3036         } else {
3037                 set subcommand_args {rev? path}
3038         }
3039         if {$argv eq {}} usage
3040         set head {}
3041         set path {}
3042         set jump_spec {}
3043         set is_path 0
3044         foreach a $argv {
3045                 set p [file join $_prefix $a]
3046
3047                 if {$is_path || [file exists $p]} {
3048                         if {$path ne {}} usage
3049                         set path [normalize_relpath $p]
3050                         break
3051                 } elseif {$a eq {--}} {
3052                         if {$path ne {}} {
3053                                 if {$head ne {}} usage
3054                                 set head $path
3055                                 set path {}
3056                         }
3057                         set is_path 1
3058                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
3059                         if {$jump_spec ne {} || $head ne {}} usage
3060                         set jump_spec [list $lnum]
3061                 } elseif {$head eq {}} {
3062                         if {$head ne {}} usage
3063                         set head $a
3064                         set is_path 1
3065                 } else {
3066                         usage
3067                 }
3068         }
3069         unset is_path
3070
3071         if {$head ne {} && $path eq {}} {
3072                 if {[string index $head 0] eq {/}} {
3073                         set path [normalize_relpath $head]
3074                         set head {}
3075                 } else {
3076                         set path [normalize_relpath $_prefix$head]
3077                         set head {}
3078                 }
3079         }
3080
3081         if {$head eq {}} {
3082                 load_current_branch
3083         } else {
3084                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
3085                         if {[catch {
3086                                         set head [git rev-parse --verify $head]
3087                                 } err]} {
3088                                 if {[tk windowingsystem] eq "win32"} {
3089                                         tk_messageBox -icon error -title [mc Error] -message $err
3090                                 } else {
3091                                         puts stderr $err
3092                                 }
3093                                 exit 1
3094                         }
3095                 }
3096                 set current_branch $head
3097         }
3098
3099         wm deiconify .
3100         switch -- $subcommand {
3101         browser {
3102                 if {$jump_spec ne {}} usage
3103                 if {$head eq {}} {
3104                         if {$path ne {} && [file isdirectory $path]} {
3105                                 set head $current_branch
3106                         } else {
3107                                 set head $path
3108                                 set path {}
3109                         }
3110                 }
3111                 browser::new $head $path
3112         }
3113         blame   {
3114                 if {$head eq {} && ![file exists $path]} {
3115                         catch {wm withdraw .}
3116                         tk_messageBox \
3117                                 -icon error \
3118                                 -type ok \
3119                                 -title [mc "git-gui: fatal error"] \
3120                                 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3121                         exit 1
3122                 }
3123                 blame::new $head $path $jump_spec
3124         }
3125         }
3126         return
3127 }
3128 citool -
3129 gui {
3130         if {[llength $argv] != 0} {
3131                 usage
3132         }
3133         # fall through to setup UI for commits
3134 }
3135 default {
3136         set err "usage: $argv0 \[{blame|browser|citool}\]"
3137         if {[tk windowingsystem] eq "win32"} {
3138                 wm withdraw .
3139                 tk_messageBox -icon error -message $err \
3140                         -title [mc "Usage"]
3141         } else {
3142                 puts stderr $err
3143         }
3144         exit 1
3145 }
3146 }
3147
3148 # -- Branch Control
3149 #
3150 ${NS}::frame .branch
3151 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3152 ${NS}::label .branch.l1 \
3153         -text [mc "Current Branch:"] \
3154         -anchor w \
3155         -justify left
3156 ${NS}::label .branch.cb \
3157         -textvariable current_branch \
3158         -anchor w \
3159         -justify left
3160 pack .branch.l1 -side left
3161 pack .branch.cb -side left -fill x
3162 pack .branch -side top -fill x
3163
3164 # -- Main Window Layout
3165 #
3166 ${NS}::panedwindow .vpane -orient horizontal
3167 ${NS}::panedwindow .vpane.files -orient vertical
3168 if {$use_ttk} {
3169         .vpane add .vpane.files
3170 } else {
3171         .vpane add .vpane.files -sticky nsew -height 100 -width 200
3172 }
3173 pack .vpane -anchor n -side top -fill both -expand 1
3174
3175 # -- Index File List
3176 #
3177 ${NS}::frame .vpane.files.index -height 100 -width 200
3178 tlabel .vpane.files.index.title \
3179         -text [mc "Staged Changes (Will Commit)"] \
3180         -background lightgreen -foreground black
3181 text $ui_index -background white -foreground black \
3182         -borderwidth 0 \
3183         -width 20 -height 10 \
3184         -wrap none \
3185         -cursor $cursor_ptr \
3186         -xscrollcommand {.vpane.files.index.sx set} \
3187         -yscrollcommand {.vpane.files.index.sy set} \
3188         -state disabled
3189 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3190 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3191 pack .vpane.files.index.title -side top -fill x
3192 pack .vpane.files.index.sx -side bottom -fill x
3193 pack .vpane.files.index.sy -side right -fill y
3194 pack $ui_index -side left -fill both -expand 1
3195
3196 # -- Working Directory File List
3197 #
3198 ${NS}::frame .vpane.files.workdir -height 100 -width 200
3199 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3200         -background lightsalmon -foreground black
3201 text $ui_workdir -background white -foreground black \
3202         -borderwidth 0 \
3203         -width 20 -height 10 \
3204         -wrap none \
3205         -cursor $cursor_ptr \
3206         -xscrollcommand {.vpane.files.workdir.sx set} \
3207         -yscrollcommand {.vpane.files.workdir.sy set} \
3208         -state disabled
3209 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3210 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3211 pack .vpane.files.workdir.title -side top -fill x
3212 pack .vpane.files.workdir.sx -side bottom -fill x
3213 pack .vpane.files.workdir.sy -side right -fill y
3214 pack $ui_workdir -side left -fill both -expand 1
3215
3216 .vpane.files add .vpane.files.workdir
3217 .vpane.files add .vpane.files.index
3218 if {!$use_ttk} {
3219         .vpane.files paneconfigure .vpane.files.workdir -sticky news
3220         .vpane.files paneconfigure .vpane.files.index -sticky news
3221 }
3222
3223 foreach i [list $ui_index $ui_workdir] {
3224         rmsel_tag $i
3225         $i tag conf in_diff -background [$i tag cget in_sel -background]
3226 }
3227 unset i
3228
3229 # -- Diff and Commit Area
3230 #
3231 if {$have_tk85} {
3232         ${NS}::panedwindow .vpane.lower -orient vertical
3233         ${NS}::frame .vpane.lower.commarea
3234         ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1 -height 500
3235         .vpane.lower add .vpane.lower.diff
3236         .vpane.lower add .vpane.lower.commarea
3237         .vpane add .vpane.lower
3238         if {$use_ttk} {
3239                 .vpane.lower pane .vpane.lower.diff -weight 1
3240                 .vpane.lower pane .vpane.lower.commarea -weight 0
3241         } else {
3242                 .vpane.lower paneconfigure .vpane.lower.diff -stretch always
3243                 .vpane.lower paneconfigure .vpane.lower.commarea -stretch never
3244         }
3245 } else {
3246         frame .vpane.lower -height 300 -width 400
3247         frame .vpane.lower.commarea
3248         frame .vpane.lower.diff -relief sunken -borderwidth 1
3249         pack .vpane.lower.diff -fill both -expand 1
3250         pack .vpane.lower.commarea -side bottom -fill x
3251         .vpane add .vpane.lower
3252         .vpane paneconfigure .vpane.lower -sticky nsew
3253 }
3254
3255 # -- Commit Area Buttons
3256 #
3257 ${NS}::frame .vpane.lower.commarea.buttons
3258 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3259         -anchor w \
3260         -justify left
3261 pack .vpane.lower.commarea.buttons.l -side top -fill x
3262 pack .vpane.lower.commarea.buttons -side left -fill y
3263
3264 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3265         -command ui_do_rescan
3266 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3267 lappend disable_on_lock \
3268         {.vpane.lower.commarea.buttons.rescan conf -state}
3269
3270 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3271         -command do_add_all
3272 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3273 lappend disable_on_lock \
3274         {.vpane.lower.commarea.buttons.incall conf -state}
3275
3276 if {![is_enabled nocommitmsg]} {
3277         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3278                 -command do_signoff
3279         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3280 }
3281
3282 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3283         -command do_commit
3284 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3285 lappend disable_on_lock \
3286         {.vpane.lower.commarea.buttons.commit conf -state}
3287
3288 if {![is_enabled nocommit]} {
3289         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3290                 -command do_push_anywhere
3291         pack .vpane.lower.commarea.buttons.push -side top -fill x
3292 }
3293
3294 # -- Commit Message Buffer
3295 #
3296 ${NS}::frame .vpane.lower.commarea.buffer
3297 ${NS}::frame .vpane.lower.commarea.buffer.header
3298 set ui_comm .vpane.lower.commarea.buffer.t
3299 set ui_coml .vpane.lower.commarea.buffer.header.l
3300
3301 if {![is_enabled nocommit]} {
3302         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3303                 -text [mc "New Commit"] \
3304                 -command do_select_commit_type \
3305                 -variable selected_commit_type \
3306                 -value new
3307         lappend disable_on_lock \
3308                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3309         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3310                 -text [mc "Amend Last Commit"] \
3311                 -command do_select_commit_type \
3312                 -variable selected_commit_type \
3313                 -value amend
3314         lappend disable_on_lock \
3315                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3316 }
3317
3318 ${NS}::label $ui_coml \
3319         -anchor w \
3320         -justify left
3321 proc trace_commit_type {varname args} {
3322         global ui_coml commit_type
3323         switch -glob -- $commit_type {
3324         initial       {set txt [mc "Initial Commit Message:"]}
3325         amend         {set txt [mc "Amended Commit Message:"]}
3326         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3327         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3328         merge         {set txt [mc "Merge Commit Message:"]}
3329         *             {set txt [mc "Commit Message:"]}
3330         }
3331         $ui_coml conf -text $txt
3332 }
3333 trace add variable commit_type write trace_commit_type
3334 pack $ui_coml -side left -fill x
3335
3336 if {![is_enabled nocommit]} {
3337         pack .vpane.lower.commarea.buffer.header.amend -side right
3338         pack .vpane.lower.commarea.buffer.header.new -side right
3339 }
3340
3341 text $ui_comm -background white -foreground black \
3342         -borderwidth 1 \
3343         -undo true \
3344         -maxundo 20 \
3345         -autoseparators true \
3346         -relief sunken \
3347         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3348         -font font_diff \
3349         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3350 ${NS}::scrollbar .vpane.lower.commarea.buffer.sby \
3351         -command [list $ui_comm yview]
3352 pack .vpane.lower.commarea.buffer.header -side top -fill x
3353 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3354 pack $ui_comm -side left -fill y
3355 pack .vpane.lower.commarea.buffer -side left -fill y
3356
3357 # -- Commit Message Buffer Context Menu
3358 #
3359 set ctxm .vpane.lower.commarea.buffer.ctxm
3360 menu $ctxm -tearoff 0
3361 $ctxm add command \
3362         -label [mc Cut] \
3363         -command {tk_textCut $ui_comm}
3364 $ctxm add command \
3365         -label [mc Copy] \
3366         -command {tk_textCopy $ui_comm}
3367 $ctxm add command \
3368         -label [mc Paste] \
3369         -command {tk_textPaste $ui_comm}
3370 $ctxm add command \
3371         -label [mc Delete] \
3372         -command {catch {$ui_comm delete sel.first sel.last}}
3373 $ctxm add separator
3374 $ctxm add command \
3375         -label [mc "Select All"] \
3376         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3377 $ctxm add command \
3378         -label [mc "Copy All"] \
3379         -command {
3380                 $ui_comm tag add sel 0.0 end
3381                 tk_textCopy $ui_comm
3382                 $ui_comm tag remove sel 0.0 end
3383         }
3384 $ctxm add separator
3385 $ctxm add command \
3386         -label [mc "Sign Off"] \
3387         -command do_signoff
3388 set ui_comm_ctxm $ctxm
3389
3390 # -- Diff Header
3391 #
3392 proc trace_current_diff_path {varname args} {
3393         global current_diff_path diff_actions file_states
3394         if {$current_diff_path eq {}} {
3395                 set s {}
3396                 set f {}
3397                 set p {}
3398                 set o disabled
3399         } else {
3400                 set p $current_diff_path
3401                 set s [mapdesc [lindex $file_states($p) 0] $p]
3402                 set f [mc "File:"]
3403                 set p [escape_path $p]
3404                 set o normal
3405         }
3406
3407         .vpane.lower.diff.header.status configure -text $s
3408         .vpane.lower.diff.header.file configure -text $f
3409         .vpane.lower.diff.header.path configure -text $p
3410         foreach w $diff_actions {
3411                 uplevel #0 $w $o
3412         }
3413 }
3414 trace add variable current_diff_path write trace_current_diff_path
3415
3416 gold_frame .vpane.lower.diff.header
3417 tlabel .vpane.lower.diff.header.status \
3418         -background gold \
3419         -foreground black \
3420         -width $max_status_desc \
3421         -anchor w \
3422         -justify left
3423 tlabel .vpane.lower.diff.header.file \
3424         -background gold \
3425         -foreground black \
3426         -anchor w \
3427         -justify left
3428 tlabel .vpane.lower.diff.header.path \
3429         -background gold \
3430         -foreground black \
3431         -anchor w \
3432         -justify left
3433 pack .vpane.lower.diff.header.status -side left
3434 pack .vpane.lower.diff.header.file -side left
3435 pack .vpane.lower.diff.header.path -fill x
3436 set ctxm .vpane.lower.diff.header.ctxm
3437 menu $ctxm -tearoff 0
3438 $ctxm add command \
3439         -label [mc Copy] \
3440         -command {
3441                 clipboard clear
3442                 clipboard append \
3443                         -format STRING \
3444                         -type STRING \
3445                         -- $current_diff_path
3446         }
3447 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3448 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3449
3450 # -- Diff Body
3451 #
3452 ${NS}::frame .vpane.lower.diff.body
3453 set ui_diff .vpane.lower.diff.body.t
3454 text $ui_diff -background white -foreground black \
3455         -borderwidth 0 \
3456         -width 80 -height 5 -wrap none \
3457         -font font_diff \
3458         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3459         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3460         -state disabled
3461 catch {$ui_diff configure -tabstyle wordprocessor}
3462 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3463         -command [list $ui_diff xview]
3464 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3465         -command [list $ui_diff yview]
3466 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3467 pack .vpane.lower.diff.body.sby -side right -fill y
3468 pack $ui_diff -side left -fill both -expand 1
3469 pack .vpane.lower.diff.header -side top -fill x
3470 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3471
3472 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3473         $ui_diff tag configure clr4$n -background $c
3474         $ui_diff tag configure clri4$n -foreground $c
3475         $ui_diff tag configure clr3$n -foreground $c
3476         $ui_diff tag configure clri3$n -background $c
3477 }
3478 $ui_diff tag configure clr1 -font font_diffbold
3479 $ui_diff tag configure clr4 -underline 1
3480
3481 $ui_diff tag conf d_info -foreground blue -font font_diffbold
3482
3483 $ui_diff tag conf d_cr -elide true
3484 $ui_diff tag conf d_@ -font font_diffbold
3485 $ui_diff tag conf d_+ -foreground {#00a000}
3486 $ui_diff tag conf d_- -foreground red
3487
3488 $ui_diff tag conf d_++ -foreground {#00a000}
3489 $ui_diff tag conf d_-- -foreground red
3490 $ui_diff tag conf d_+s \
3491         -foreground {#00a000} \
3492         -background {#e2effa}
3493 $ui_diff tag conf d_-s \
3494         -foreground red \
3495         -background {#e2effa}
3496 $ui_diff tag conf d_s+ \
3497         -foreground {#00a000} \
3498         -background ivory1
3499 $ui_diff tag conf d_s- \
3500         -foreground red \
3501         -background ivory1
3502
3503 $ui_diff tag conf d< \
3504         -foreground orange \
3505         -font font_diffbold
3506 $ui_diff tag conf d= \
3507         -foreground orange \
3508         -font font_diffbold
3509 $ui_diff tag conf d> \
3510         -foreground orange \
3511         -font font_diffbold
3512
3513 $ui_diff tag raise sel
3514
3515 # -- Diff Body Context Menu
3516 #
3517
3518 proc create_common_diff_popup {ctxm} {
3519         $ctxm add command \
3520                 -label [mc Refresh] \
3521                 -command reshow_diff
3522         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3523         $ctxm add command \
3524                 -label [mc Copy] \
3525                 -command {tk_textCopy $ui_diff}
3526         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3527         $ctxm add command \
3528                 -label [mc "Select All"] \
3529                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3530         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3531         $ctxm add command \
3532                 -label [mc "Copy All"] \
3533                 -command {
3534                         $ui_diff tag add sel 0.0 end
3535                         tk_textCopy $ui_diff
3536                         $ui_diff tag remove sel 0.0 end
3537                 }
3538         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3539         $ctxm add separator
3540         $ctxm add command \
3541                 -label [mc "Decrease Font Size"] \
3542                 -command {incr_font_size font_diff -1}
3543         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3544         $ctxm add command \
3545                 -label [mc "Increase Font Size"] \
3546                 -command {incr_font_size font_diff 1}
3547         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3548         $ctxm add separator
3549         set emenu $ctxm.enc
3550         menu $emenu
3551         build_encoding_menu $emenu [list force_diff_encoding]
3552         $ctxm add cascade \
3553                 -label [mc "Encoding"] \
3554                 -menu $emenu
3555         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3556         $ctxm add separator
3557         $ctxm add command -label [mc "Options..."] \
3558                 -command do_options
3559 }
3560
3561 set ctxm .vpane.lower.diff.body.ctxm
3562 menu $ctxm -tearoff 0
3563 $ctxm add command \
3564         -label [mc "Apply/Reverse Hunk"] \
3565         -command {apply_hunk $cursorX $cursorY}
3566 set ui_diff_applyhunk [$ctxm index last]
3567 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3568 $ctxm add command \
3569         -label [mc "Apply/Reverse Line"] \
3570         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3571 set ui_diff_applyline [$ctxm index last]
3572 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3573 $ctxm add separator
3574 $ctxm add command \
3575         -label [mc "Show Less Context"] \
3576         -command show_less_context
3577 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3578 $ctxm add command \
3579         -label [mc "Show More Context"] \
3580         -command show_more_context
3581 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3582 $ctxm add separator
3583 create_common_diff_popup $ctxm
3584
3585 set ctxmmg .vpane.lower.diff.body.ctxmmg
3586 menu $ctxmmg -tearoff 0
3587 $ctxmmg add command \
3588         -label [mc "Run Merge Tool"] \
3589         -command {merge_resolve_tool}
3590 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3591 $ctxmmg add separator
3592 $ctxmmg add command \
3593         -label [mc "Use Remote Version"] \
3594         -command {merge_resolve_one 3}
3595 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3596 $ctxmmg add command \
3597         -label [mc "Use Local Version"] \
3598         -command {merge_resolve_one 2}
3599 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3600 $ctxmmg add command \
3601         -label [mc "Revert To Base"] \
3602         -command {merge_resolve_one 1}
3603 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3604 $ctxmmg add separator
3605 $ctxmmg add command \
3606         -label [mc "Show Less Context"] \
3607         -command show_less_context
3608 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3609 $ctxmmg add command \
3610         -label [mc "Show More Context"] \
3611         -command show_more_context
3612 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3613 $ctxmmg add separator
3614 create_common_diff_popup $ctxmmg
3615
3616 set ctxmsm .vpane.lower.diff.body.ctxmsm
3617 menu $ctxmsm -tearoff 0
3618 $ctxmsm add command \
3619         -label [mc "Visualize These Changes In The Submodule"] \
3620         -command {do_gitk -- true}
3621 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3622 $ctxmsm add command \
3623         -label [mc "Visualize Current Branch History In The Submodule"] \
3624         -command {do_gitk {} true}
3625 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3626 $ctxmsm add command \
3627         -label [mc "Visualize All Branch History In The Submodule"] \
3628         -command {do_gitk --all true}
3629 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3630 $ctxmsm add separator
3631 $ctxmsm add command \
3632         -label [mc "Start git gui In The Submodule"] \
3633         -command {do_git_gui}
3634 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3635 $ctxmsm add separator
3636 create_common_diff_popup $ctxmsm
3637
3638 proc has_textconv {path} {
3639         if {[is_config_false gui.textconv]} {
3640                 return 0
3641         }
3642         set filter [gitattr $path diff set]
3643         set textconv [get_config [join [list diff $filter textconv] .]]
3644         if {$filter ne {set} && $textconv ne {}} {
3645                 return 1
3646         } else {
3647                 return 0
3648         }
3649 }
3650
3651 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3652         global current_diff_path file_states
3653         set ::cursorX $x
3654         set ::cursorY $y
3655         if {[info exists file_states($current_diff_path)]} {
3656                 set state [lindex $file_states($current_diff_path) 0]
3657         } else {
3658                 set state {__}
3659         }
3660         if {[string first {U} $state] >= 0} {
3661                 tk_popup $ctxmmg $X $Y
3662         } elseif {$::is_submodule_diff} {
3663                 tk_popup $ctxmsm $X $Y
3664         } else {
3665                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3666                 if {$::ui_index eq $::current_diff_side} {
3667                         set l [mc "Unstage Hunk From Commit"]
3668                         if {$has_range} {
3669                                 set t [mc "Unstage Lines From Commit"]
3670                         } else {
3671                                 set t [mc "Unstage Line From Commit"]
3672                         }
3673                 } else {
3674                         set l [mc "Stage Hunk For Commit"]
3675                         if {$has_range} {
3676                                 set t [mc "Stage Lines For Commit"]
3677                         } else {
3678                                 set t [mc "Stage Line For Commit"]
3679                         }
3680                 }
3681                 if {$::is_3way_diff
3682                         || $current_diff_path eq {}
3683                         || {__} eq $state
3684                         || {_O} eq $state
3685                         || [string match {?T} $state]
3686                         || [string match {T?} $state]
3687                         || [has_textconv $current_diff_path]} {
3688                         set s disabled
3689                 } else {
3690                         set s normal
3691                 }
3692                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3693                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3694                 tk_popup $ctxm $X $Y
3695         }
3696 }
3697 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3698
3699 # -- Status Bar
3700 #
3701 set main_status [::status_bar::new .status]
3702 pack .status -anchor w -side bottom -fill x
3703 $main_status show [mc "Initializing..."]
3704
3705 # -- Load geometry
3706 #
3707 proc on_ttk_pane_mapped {w pane pos} {
3708         bind $w <Map> {}
3709         after 0 [list after idle [list $w sashpos $pane $pos]]
3710 }
3711 proc on_tk_pane_mapped {w pane x y} {
3712         bind $w <Map> {}
3713         after 0 [list after idle [list $w sash place $pane $x $y]]
3714 }
3715 proc on_application_mapped {} {
3716         global repo_config use_ttk
3717         bind . <Map> {}
3718         set gm $repo_config(gui.geometry)
3719         if {$use_ttk} {
3720                 bind .vpane <Map> \
3721                     [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3722                 bind .vpane.files <Map> \
3723                     [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3724         } else {
3725                 bind .vpane <Map> \
3726                     [list on_tk_pane_mapped %W 0 \
3727                          [lindex $gm 1] \
3728                          [lindex [.vpane sash coord 0] 1]]
3729                 bind .vpane.files <Map> \
3730                     [list on_tk_pane_mapped %W 0 \
3731                          [lindex [.vpane.files sash coord 0] 0] \
3732                          [lindex $gm 2]]
3733         }
3734         wm geometry . [lindex $gm 0]
3735 }
3736 if {[info exists repo_config(gui.geometry)]} {
3737         bind . <Map> [list on_application_mapped]
3738         wm geometry . [lindex $repo_config(gui.geometry) 0]
3739 }
3740
3741 # -- Load window state
3742 #
3743 if {[info exists repo_config(gui.wmstate)]} {
3744         catch {wm state . $repo_config(gui.wmstate)}
3745 }
3746
3747 # -- Key Bindings
3748 #
3749 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3750 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3751 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3752 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3753 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3754 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3755 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3756 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3757 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3758 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3759 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3760 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3761 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3762 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3763 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3764 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3765 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3766 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3767 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3768 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3769 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3770 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3771
3772 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3773 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3774 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3775 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3776 bind $ui_diff <$M1B-Key-v> {break}
3777 bind $ui_diff <$M1B-Key-V> {break}
3778 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3779 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3780 bind $ui_diff <$M1B-Key-j> {do_revert_selection;break}
3781 bind $ui_diff <$M1B-Key-J> {do_revert_selection;break}
3782 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3783 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3784 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3785 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3786 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3787 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3788 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3789 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3790 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3791 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3792 bind $ui_diff <Button-1>   {focus %W}
3793
3794 if {[is_enabled branch]} {
3795         bind . <$M1B-Key-n> branch_create::dialog
3796         bind . <$M1B-Key-N> branch_create::dialog
3797         bind . <$M1B-Key-o> branch_checkout::dialog
3798         bind . <$M1B-Key-O> branch_checkout::dialog
3799         bind . <$M1B-Key-m> merge::dialog
3800         bind . <$M1B-Key-M> merge::dialog
3801 }
3802 if {[is_enabled transport]} {
3803         bind . <$M1B-Key-p> do_push_anywhere
3804         bind . <$M1B-Key-P> do_push_anywhere
3805 }
3806
3807 bind .   <Key-F5>     ui_do_rescan
3808 bind .   <$M1B-Key-r> ui_do_rescan
3809 bind .   <$M1B-Key-R> ui_do_rescan
3810 bind .   <$M1B-Key-s> do_signoff
3811 bind .   <$M1B-Key-S> do_signoff
3812 bind .   <$M1B-Key-t> do_add_selection
3813 bind .   <$M1B-Key-T> do_add_selection
3814 bind .   <$M1B-Key-u> do_unstage_selection
3815 bind .   <$M1B-Key-U> do_unstage_selection
3816 bind .   <$M1B-Key-j> do_revert_selection
3817 bind .   <$M1B-Key-J> do_revert_selection
3818 bind .   <$M1B-Key-i> do_add_all
3819 bind .   <$M1B-Key-I> do_add_all
3820 bind .   <$M1B-Key-minus> {show_less_context;break}
3821 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3822 bind .   <$M1B-Key-equal> {show_more_context;break}
3823 bind .   <$M1B-Key-plus> {show_more_context;break}
3824 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3825 bind .   <$M1B-Key-Return> do_commit
3826 foreach i [list $ui_index $ui_workdir] {
3827         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3828         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3829         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3830 }
3831 unset i
3832
3833 set file_lists($ui_index) [list]
3834 set file_lists($ui_workdir) [list]
3835
3836 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3837 focus -force $ui_comm
3838
3839 # -- Warn the user about environmental problems.  Cygwin's Tcl
3840 #    does *not* pass its env array onto any processes it spawns.
3841 #    This means that git processes get none of our environment.
3842 #
3843 if {[is_Cygwin]} {
3844         set ignored_env 0
3845         set suggest_user {}
3846         set msg [mc "Possible environment issues exist.
3847
3848 The following environment variables are probably
3849 going to be ignored by any Git subprocess run
3850 by %s:
3851
3852 " [appname]]
3853         foreach name [array names env] {
3854                 switch -regexp -- $name {
3855                 {^GIT_INDEX_FILE$} -
3856                 {^GIT_OBJECT_DIRECTORY$} -
3857                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3858                 {^GIT_DIFF_OPTS$} -
3859                 {^GIT_EXTERNAL_DIFF$} -
3860                 {^GIT_PAGER$} -
3861                 {^GIT_TRACE$} -
3862                 {^GIT_CONFIG$} -
3863                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3864                         append msg " - $name\n"
3865                         incr ignored_env
3866                 }
3867                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3868                         append msg " - $name\n"
3869                         incr ignored_env
3870                         set suggest_user $name
3871                 }
3872                 }
3873         }
3874         if {$ignored_env > 0} {
3875                 append msg [mc "
3876 This is due to a known issue with the
3877 Tcl binary distributed by Cygwin."]
3878
3879                 if {$suggest_user ne {}} {
3880                         append msg [mc "
3881
3882 A good replacement for %s
3883 is placing values for the user.name and
3884 user.email settings into your personal
3885 ~/.gitconfig file.
3886 " $suggest_user]
3887                 }
3888                 warn_popup $msg
3889         }
3890         unset ignored_env msg suggest_user name
3891 }
3892
3893 # -- Only initialize complex UI if we are going to stay running.
3894 #
3895 if {[is_enabled transport]} {
3896         load_all_remotes
3897
3898         set n [.mbar.remote index end]
3899         populate_remotes_menu
3900         set n [expr {[.mbar.remote index end] - $n}]
3901         if {$n > 0} {
3902                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3903                 .mbar.remote insert $n separator
3904         }
3905         unset n
3906 }
3907
3908 if {[winfo exists $ui_comm]} {
3909         set GITGUI_BCK_exists [load_message GITGUI_BCK utf-8]
3910
3911         # -- If both our backup and message files exist use the
3912         #    newer of the two files to initialize the buffer.
3913         #
3914         if {$GITGUI_BCK_exists} {
3915                 set m [gitdir GITGUI_MSG]
3916                 if {[file isfile $m]} {
3917                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3918                                 catch {file delete [gitdir GITGUI_MSG]}
3919                         } else {
3920                                 $ui_comm delete 0.0 end
3921                                 $ui_comm edit reset
3922                                 $ui_comm edit modified false
3923                                 catch {file delete [gitdir GITGUI_BCK]}
3924                                 set GITGUI_BCK_exists 0
3925                         }
3926                 }
3927                 unset m
3928         }
3929
3930         proc backup_commit_buffer {} {
3931                 global ui_comm GITGUI_BCK_exists
3932
3933                 set m [$ui_comm edit modified]
3934                 if {$m || $GITGUI_BCK_exists} {
3935                         set msg [string trim [$ui_comm get 0.0 end]]
3936                         regsub -all -line {[ \r\t]+$} $msg {} msg
3937
3938                         if {$msg eq {}} {
3939                                 if {$GITGUI_BCK_exists} {
3940                                         catch {file delete [gitdir GITGUI_BCK]}
3941                                         set GITGUI_BCK_exists 0
3942                                 }
3943                         } elseif {$m} {
3944                                 catch {
3945                                         set fd [open [gitdir GITGUI_BCK] w]
3946                                         fconfigure $fd -encoding utf-8
3947                                         puts -nonewline $fd $msg
3948                                         close $fd
3949                                         set GITGUI_BCK_exists 1
3950                                 }
3951                         }
3952
3953                         $ui_comm edit modified false
3954                 }
3955
3956                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3957         }
3958
3959         backup_commit_buffer
3960
3961         # -- If the user has aspell available we can drive it
3962         #    in pipe mode to spellcheck the commit message.
3963         #
3964         set spell_cmd [list |]
3965         set spell_dict [get_config gui.spellingdictionary]
3966         lappend spell_cmd aspell
3967         if {$spell_dict ne {}} {
3968                 lappend spell_cmd --master=$spell_dict
3969         }
3970         lappend spell_cmd --mode=none
3971         lappend spell_cmd --encoding=utf-8
3972         lappend spell_cmd pipe
3973         if {$spell_dict eq {none}
3974          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3975                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3976         } else {
3977                 set ui_comm_spell [spellcheck::init \
3978                         $spell_fd \
3979                         $ui_comm \
3980                         $ui_comm_ctxm \
3981                 ]
3982         }
3983         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3984 }
3985
3986 lock_index begin-read
3987 if {![winfo ismapped .]} {
3988         wm deiconify .
3989 }
3990 after 1 {
3991         if {[is_enabled initialamend]} {
3992                 force_amend
3993         } else {
3994                 do_rescan
3995         }
3996
3997         if {[is_enabled nocommitmsg]} {
3998                 $ui_comm configure -state disabled -background gray
3999         }
4000 }
4001 if {[is_enabled multicommit] && ![is_config_false gui.gcwarning]} {
4002         after 1000 hint_gc
4003 }
4004 if {[is_enabled retcode]} {
4005         bind . <Destroy> {+terminate_me %W}
4006 }
4007 if {$picked && [is_config_true gui.autoexplore]} {
4008         do_explore
4009 }
4010
4011 # Local variables:
4012 # mode: tcl
4013 # indent-tabs-mode: t
4014 # tab-width: 4
4015 # End: