git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision
   8                 $_q $_authors %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22
  23 $Git::SVN::Log::TZ = $ENV{TZ};
  24 $ENV{TZ} = 'UTC';
  25 $| = 1; # unbuffer STDOUT
  26
  27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  29 require SVN::Ra;
  30 require SVN::Delta;
  31 if ($SVN::Core::VERSION lt '1.1.0') {
  32         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  33 }
  34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  37 use Carp qw/croak/;
  38 use Digest::MD5;
  39 use IO::File qw//;
  40 use File::Basename qw/dirname basename/;
  41 use File::Path qw/mkpath/;
  42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  43 use IPC::Open3;
  44 use Git;
  45
  46 BEGIN {
  47         # import functions from Git into our packages, en masse
  48         no strict 'refs';
  49         foreach (qw/command command_oneline command_noisy command_output_pipe
  50                     command_input_pipe command_close_pipe/) {
  51                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  52                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  53                         __PACKAGE__) {
  54                         *{"${package}::$_"} = \&{"Git::$_"};
  55                 }
  56         }
  57 }
  58
  59 my ($SVN);
  60
  61 $sha1 = qr/[a-f\d]{40}/;
  62 $sha1_short = qr/[a-f\d]{4,40}/;
  63 my ($_stdin, $_help, $_edit,
  64         $_message, $_file,
  65         $_template, $_shared,
  66         $_version, $_fetch_all, $_no_rebase,
  67         $_merge, $_strategy, $_dry_run, $_local,
  68         $_prefix, $_no_checkout, $_url, $_verbose);
  69 $Git::SVN::_follow_parent = 1;
  70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  71                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  72                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  74                 'authors-file|A=s' => \$_authors,
  75                 'repack:i' => \$Git::SVN::_repack,
  76                 'noMetadata' => \$Git::SVN::_no_metadata,
  77                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  78                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  79                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  80                 'no-checkout' => \$_no_checkout,
  81                 'quiet|q' => \$_q,
  82                 'repack-flags|repack-args|repack-opts=s' =>
  83                    \$Git::SVN::_repack_flags,
  84                 'use-log-author' => \$Git::SVN::_use_log_author,
  85                 %remote_opts );
  86
  87 my ($_trunk, $_tags, $_branches, $_stdlayout);
  88 my %icv;
  89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
  90                   'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
  91                   'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
  92                   'stdlayout|s' => \$_stdlayout,
  93                   'minimize-url|m' => \$Git::SVN::_minimize_url,
  94                   'no-metadata' => sub { $icv{noMetadata} = 1 },
  95                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
  96                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
  97                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
  98                   %remote_opts );
  99 my %cmt_opts = ( 'edit|e' => \$_edit,
 100                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 101                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 102                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 103                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 104 );
 105
 106 my %cmd = (
 107         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 108                         { 'revision|r=s' => \$_revision,
 109                           'fetch-all|all' => \$_fetch_all,
 110                            %fc_opts } ],
 111         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 112                         { 'revision|r=s' => \$_revision,
 113                            %fc_opts, %init_opts } ],
 114         init => [ \&cmd_init, "Initialize a repo for tracking" .
 115                           " (requires URL argument)",
 116                           \%init_opts ],
 117         'multi-init' => [ \&cmd_multi_init,
 118                           "Deprecated alias for ".
 119                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 120                           \%init_opts ],
 121         dcommit => [ \&cmd_dcommit,
 122                      'Commit several diffs to merge with upstream',
 123                         { 'merge|m|M' => \$_merge,
 124                           'strategy|s=s' => \$_strategy,
 125                           'verbose|v' => \$_verbose,
 126                           'dry-run|n' => \$_dry_run,
 127                           'fetch-all|all' => \$_fetch_all,
 128                           'no-rebase' => \$_no_rebase,
 129                         %cmt_opts, %fc_opts } ],
 130         'set-tree' => [ \&cmd_set_tree,
 131                         "Set an SVN repository to a git tree-ish",
 132                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 133         'create-ignore' => [ \&cmd_create_ignore,
 134                              'Create a .gitignore per svn:ignore',
 135                              { 'revision|r=i' => \$_revision
 136                              } ],
 137         'propget' => [ \&cmd_propget,
 138                        'Print the value of a property on a file or directory',
 139                        { 'revision|r=i' => \$_revision } ],
 140         'proplist' => [ \&cmd_proplist,
 141                        'List all properties of a file or directory',
 142                        { 'revision|r=i' => \$_revision } ],
 143         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 144                         { 'revision|r=i' => \$_revision
 145                         } ],
 146         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 147                         { 'revision|r=i' => \$_revision
 148                         } ],
 149         'multi-fetch' => [ \&cmd_multi_fetch,
 150                            "Deprecated alias for $0 fetch --all",
 151                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 152         'migrate' => [ sub { },
 153                        # no-op, we automatically run this anyways,
 154                        'Migrate configuration/metadata/layout from
 155                         previous versions of git-svn',
 156                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 157                          %remote_opts } ],
 158         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 159                         { 'limit=i' => \$Git::SVN::Log::limit,
 160                           'revision|r=s' => \$_revision,
 161                           'verbose|v' => \$Git::SVN::Log::verbose,
 162                           'incremental' => \$Git::SVN::Log::incremental,
 163                           'oneline' => \$Git::SVN::Log::oneline,
 164                           'show-commit' => \$Git::SVN::Log::show_commit,
 165                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 166                           'authors-file|A=s' => \$_authors,
 167                           'color' => \$Git::SVN::Log::color,
 168                           'pager=s' => \$Git::SVN::Log::pager
 169                         } ],
 170         'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
 171                         {} ],
 172         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 173                         { 'merge|m|M' => \$_merge,
 174                           'verbose|v' => \$_verbose,
 175                           'strategy|s=s' => \$_strategy,
 176                           'local|l' => \$_local,
 177                           'fetch-all|all' => \$_fetch_all,
 178                           %fc_opts } ],
 179         'commit-diff' => [ \&cmd_commit_diff,
 180                            'Commit a diff between two trees',
 181                         { 'message|m=s' => \$_message,
 182                           'file|F=s' => \$_file,
 183                           'revision|r=s' => \$_revision,
 184                         %cmt_opts } ],
 185         'info' => [ \&cmd_info,
 186                     "Show info about the latest SVN revision
 187                      on the current branch",
 188                     { 'url' => \$_url, } ],
 189 );
 190
 191 my $cmd;
 192 for (my $i = 0; $i < @ARGV; $i++) {
 193         if (defined $cmd{$ARGV[$i]}) {
 194                 $cmd = $ARGV[$i];
 195                 splice @ARGV, $i, 1;
 196                 last;
 197         }
 198 };
 199
 200 # make sure we're always running
 201 unless ($cmd =~ /(?:clone|init|multi-init)$/) {
 202         unless (-d $ENV{GIT_DIR}) {
 203                 if ($git_dir_user_set) {
 204                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 205                             "but it is not a directory\n";
 206                 }
 207                 my $git_dir = delete $ENV{GIT_DIR};
 208                 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
 209                 unless (length $cdup) {
 210                         die "Already at toplevel, but $git_dir ",
 211                             "not found '$cdup'\n";
 212                 }
 213                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 214                 unless (-d $git_dir) {
 215                         die "$git_dir still not found after going to ",
 216                             "'$cdup'\n";
 217                 }
 218                 $ENV{GIT_DIR} = $git_dir;
 219         }
 220 }
 221
 222 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 223
 224 read_repo_config(\%opts);
 225 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
 226 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 227                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 228                     'id|i=s' => \$Git::SVN::default_ref_id,
 229                     'svn-remote|remote|R=s' => sub {
 230                        $Git::SVN::no_reuse_existing = 1;
 231                        $Git::SVN::default_repo_id = $_[1] });
 232 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 233
 234 usage(0) if $_help;
 235 version() if $_version;
 236 usage(1) unless defined $cmd;
 237 load_authors() if $_authors;
 238
 239 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 240         Git::SVN::Migration::migration_check();
 241 }
 242 Git::SVN::init_vars();
 243 eval {
 244         Git::SVN::verify_remotes_sanity();
 245         $cmd{$cmd}->[0]->(@ARGV);
 246 };
 247 fatal $@ if $@;
 248 post_fetch_checkout();
 249 exit 0;
 250
 251 ####################### primary functions ######################
 252 sub usage {
 253         my $exit = shift || 0;
 254         my $fd = $exit ? \*STDERR : \*STDOUT;
 255         print $fd <<"";
 256 git-svn - bidirectional operations between a single Subversion tree and git
 257 Usage: $0 <command> [options] [arguments]\n
 258
 259         print $fd "Available commands:\n" unless $cmd;
 260
 261         foreach (sort keys %cmd) {
 262                 next if $cmd && $cmd ne $_;
 263                 next if /^multi-/; # don't show deprecated commands
 264                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 265                 foreach (sort keys %{$cmd{$_}->[2]}) {
 266                         # mixed-case options are for .git/config only
 267                         next if /[A-Z]/ && /^[a-z]+$/i;
 268                         # prints out arguments as they should be passed:
 269                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 270                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 271                                                         "--$_" : "-$_" }
 272                                                 split /\|/,$_)," $x\n";
 273                 }
 274         }
 275         print $fd <<"";
 276 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 277 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 278 one git repository and want to keep them separate.  See git-svn(1) for more
 279 information.
 280
 281         exit $exit;
 282 }
 283
 284 sub version {
 285         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 286         exit 0;
 287 }
 288
 289 sub do_git_init_db {
 290         unless (-d $ENV{GIT_DIR}) {
 291                 my @init_db = ('init');
 292                 push @init_db, "--template=$_template" if defined $_template;
 293                 if (defined $_shared) {
 294                         if ($_shared =~ /[a-z]/) {
 295                                 push @init_db, "--shared=$_shared";
 296                         } else {
 297                                 push @init_db, "--shared";
 298                         }
 299                 }
 300                 command_noisy(@init_db);
 301         }
 302         my $set;
 303         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 304         foreach my $i (keys %icv) {
 305                 die "'$set' and '$i' cannot both be set\n" if $set;
 306                 next unless defined $icv{$i};
 307                 command_noisy('config', "$pfx.$i", $icv{$i});
 308                 $set = $i;
 309         }
 310 }
 311
 312 sub init_subdir {
 313         my $repo_path = shift or return;
 314         mkpath([$repo_path]) unless -d $repo_path;
 315         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 316         $ENV{GIT_DIR} = '.git';
 317 }
 318
 319 sub cmd_clone {
 320         my ($url, $path) = @_;
 321         if (!defined $path &&
 322             (defined $_trunk || defined $_branches || defined $_tags ||
 323              defined $_stdlayout) &&
 324             $url !~ m#^[a-z\+]+://#) {
 325                 $path = $url;
 326         }
 327         $path = basename($url) if !defined $path || !length $path;
 328         cmd_init($url, $path);
 329         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 330 }
 331
 332 sub cmd_init {
 333         if (defined $_stdlayout) {
 334                 $_trunk = 'trunk' if (!defined $_trunk);
 335                 $_tags = 'tags' if (!defined $_tags);
 336                 $_branches = 'branches' if (!defined $_branches);
 337         }
 338         if (defined $_trunk || defined $_branches || defined $_tags) {
 339                 return cmd_multi_init(@_);
 340         }
 341         my $url = shift or die "SVN repository location required ",
 342                                "as a command-line argument\n";
 343         init_subdir(@_);
 344         do_git_init_db();
 345
 346         Git::SVN->init($url);
 347 }
 348
 349 sub cmd_fetch {
 350         if (grep /^\d+=./, @_) {
 351                 die "'<rev>=<commit>' fetch arguments are ",
 352                     "no longer supported.\n";
 353         }
 354         my ($remote) = @_;
 355         if (@_ > 1) {
 356                 die "Usage: $0 fetch [--all] [svn-remote]\n";
 357         }
 358         $remote ||= $Git::SVN::default_repo_id;
 359         if ($_fetch_all) {
 360                 cmd_multi_fetch();
 361         } else {
 362                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 363         }
 364 }
 365
 366 sub cmd_set_tree {
 367         my (@commits) = @_;
 368         if ($_stdin || !@commits) {
 369                 print "Reading from stdin...\n";
 370                 @commits = ();
 371                 while (<STDIN>) {
 372                         if (/\b($sha1_short)\b/o) {
 373                                 unshift @commits, $1;
 374                         }
 375                 }
 376         }
 377         my @revs;
 378         foreach my $c (@commits) {
 379                 my @tmp = command('rev-parse',$c);
 380                 if (scalar @tmp == 1) {
 381                         push @revs, $tmp[0];
 382                 } elsif (scalar @tmp > 1) {
 383                         push @revs, reverse(command('rev-list',@tmp));
 384                 } else {
 385                         fatal "Failed to rev-parse $c";
 386                 }
 387         }
 388         my $gs = Git::SVN->new;
 389         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 390         $gs->fetch;
 391         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 392                 fatal "There are new revisions that were fetched ",
 393                       "and need to be merged (or acknowledged) ",
 394                       "before committing.\nlast rev: $r_last\n",
 395                       " current: $gs->{last_rev}";
 396         }
 397         $gs->set_tree($_) foreach @revs;
 398         print "Done committing ",scalar @revs," revisions to SVN\n";
 399 }
 400
 401 sub cmd_dcommit {
 402         my $head = shift;
 403         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 404                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 405                 . "or stash them with `git stash'.\n";
 406         $head ||= 'HEAD';
 407         my @refs;
 408         my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
 409         print "Committing to $url ...\n";
 410         unless ($gs) {
 411                 die "Unable to determine upstream SVN information from ",
 412                     "$head history\n";
 413         }
 414         my $last_rev;
 415         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 416         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 417                 warn "Attempting to commit more than one change while ",
 418                      "--no-rebase is enabled.\n",
 419                      "If these changes depend on each other, re-running ",
 420                      "without --no-rebase will be required."
 421         }
 422         while (1) {
 423                 my $d = shift @$linear_refs or last;
 424                 unless (defined $last_rev) {
 425                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 426                         unless (defined $last_rev) {
 427                                 fatal "Unable to extract revision information ",
 428                                       "from commit $d~1";
 429                         }
 430                 }
 431                 if ($_dry_run) {
 432                         print "diff-tree $d~1 $d\n";
 433                 } else {
 434                         my $cmt_rev;
 435                         my %ed_opts = ( r => $last_rev,
 436                                         log => get_commit_entry($d)->{log},
 437                                         ra => Git::SVN::Ra->new($gs->full_url),
 438                                         config => SVN::Core::config_get_config(
 439                                                 $Git::SVN::Ra::config_dir
 440                                         ),
 441                                         tree_a => "$d~1",
 442                                         tree_b => $d,
 443                                         editor_cb => sub {
 444                                                print "Committed r$_[0]\n";
 445                                                $cmt_rev = $_[0];
 446                                         },
 447                                         svn_path => '');
 448                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 449                                 print "No changes\n$d~1 == $d\n";
 450                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 451                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 452                                                                $parents->{$d};
 453                         }
 454                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 455                         next if $_no_rebase;
 456
 457                         # we always want to rebase against the current HEAD,
 458                         # not any head that was passed to us
 459                         my @diff = command('diff-tree', $d,
 460                                            $gs->refname, '--');
 461                         my @finish;
 462                         if (@diff) {
 463                                 @finish = rebase_cmd();
 464                                 print STDERR "W: $d and ", $gs->refname,
 465                                              " differ, using @finish:\n",
 466                                              join("\n", @diff), "\n";
 467                         } else {
 468                                 print "No changes between current HEAD and ",
 469                                       $gs->refname,
 470                                       "\nResetting to the latest ",
 471                                       $gs->refname, "\n";
 472                                 @finish = qw/reset --mixed/;
 473                         }
 474                         command_noisy(@finish, $gs->refname);
 475                         if (@diff) {
 476                                 @refs = ();
 477                                 my ($url_, $rev_, $uuid_, $gs_) =
 478                                               working_head_info($head, \@refs);
 479                                 my ($linear_refs_, $parents_) =
 480                                               linearize_history($gs_, \@refs);
 481                                 if (scalar(@$linear_refs) !=
 482                                     scalar(@$linear_refs_)) {
 483                                         fatal "# of revisions changed ",
 484                                           "\nbefore:\n",
 485                                           join("\n", @$linear_refs),
 486                                           "\n\nafter:\n",
 487                                           join("\n", @$linear_refs_), "\n",
 488                                           'If you are attempting to commit ',
 489                                           "merges, try running:\n\t",
 490                                           'git rebase --interactive',
 491                                           '--preserve-merges ',
 492                                           $gs->refname,
 493                                           "\nBefore dcommitting";
 494                                 }
 495                                 if ($url_ ne $url) {
 496                                         fatal "URL mismatch after rebase: ",
 497                                               "$url_ != $url";
 498                                 }
 499                                 if ($uuid_ ne $uuid) {
 500                                         fatal "uuid mismatch after rebase: ",
 501                                               "$uuid_ != $uuid";
 502                                 }
 503                                 # remap parents
 504                                 my (%p, @l, $i);
 505                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 506                                         my $new = $linear_refs_->[$i] or next;
 507                                         $p{$new} =
 508                                                 $parents->{$linear_refs->[$i]};
 509                                         push @l, $new;
 510                                 }
 511                                 $parents = \%p;
 512                                 $linear_refs = \@l;
 513                         }
 514                         $last_rev = $cmt_rev;
 515                 }
 516         }
 517 }
 518
 519 sub cmd_find_rev {
 520         my $revision_or_hash = shift;
 521         my $result;
 522         if ($revision_or_hash =~ /^r\d+$/) {
 523                 my $head = shift;
 524                 $head ||= 'HEAD';
 525                 my @refs;
 526                 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
 527                 unless ($gs) {
 528                         die "Unable to determine upstream SVN information from ",
 529                             "$head history\n";
 530                 }
 531                 my $desired_revision = substr($revision_or_hash, 1);
 532                 $result = $gs->rev_map_get($desired_revision);
 533         } else {
 534                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 535                 $result = $rev;
 536         }
 537         print "$result\n" if $result;
 538 }
 539
 540 sub cmd_rebase {
 541         command_noisy(qw/update-index --refresh/);
 542         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 543         unless ($gs) {
 544                 die "Unable to determine upstream SVN information from ",
 545                     "working tree history\n";
 546         }
 547         if (command(qw/diff-index HEAD --/)) {
 548                 print STDERR "Cannot rebase with uncommited changes:\n";
 549                 command_noisy('status');
 550                 exit 1;
 551         }
 552         unless ($_local) {
 553                 # rebase will checkout for us, so no need to do it explicitly
 554                 $_no_checkout = 'true';
 555                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 556         }
 557         command_noisy(rebase_cmd(), $gs->refname);
 558 }
 559
 560 sub cmd_show_ignore {
 561         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 562         $gs ||= Git::SVN->new;
 563         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 564         $gs->prop_walk($gs->{path}, $r, sub {
 565                 my ($gs, $path, $props) = @_;
 566                 print STDOUT "\n# $path\n";
 567                 my $s = $props->{'svn:ignore'} or return;
 568                 $s =~ s/[\r\n]+/\n/g;
 569                 chomp $s;
 570                 $s =~ s#^#$path#gm;
 571                 print STDOUT "$s\n";
 572         });
 573 }
 574
 575 sub cmd_show_externals {
 576         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 577         $gs ||= Git::SVN->new;
 578         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 579         $gs->prop_walk($gs->{path}, $r, sub {
 580                 my ($gs, $path, $props) = @_;
 581                 print STDOUT "\n# $path\n";
 582                 my $s = $props->{'svn:externals'} or return;
 583                 $s =~ s/[\r\n]+/\n/g;
 584                 chomp $s;
 585                 $s =~ s#^#$path#gm;
 586                 print STDOUT "$s\n";
 587         });
 588 }
 589
 590 sub cmd_create_ignore {
 591         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 592         $gs ||= Git::SVN->new;
 593         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 594         $gs->prop_walk($gs->{path}, $r, sub {
 595                 my ($gs, $path, $props) = @_;
 596                 # $path is of the form /path/to/dir/
 597                 my $ignore = '.' . $path . '.gitignore';
 598                 my $s = $props->{'svn:ignore'} or return;
 599                 open(GITIGNORE, '>', $ignore)
 600                   or fatal("Failed to open `$ignore' for writing: $!");
 601                 $s =~ s/[\r\n]+/\n/g;
 602                 chomp $s;
 603                 # Prefix all patterns so that the ignore doesn't apply
 604                 # to sub-directories.
 605                 $s =~ s#^#/#gm;
 606                 print GITIGNORE "$s\n";
 607                 close(GITIGNORE)
 608                   or fatal("Failed to close `$ignore': $!");
 609                 command_noisy('add', $ignore);
 610         });
 611 }
 612
 613 sub canonicalize_path {
 614         my ($path) = @_;
 615         my $dot_slash_added = 0;
 616         if (substr($path, 0, 1) ne "/") {
 617                 $path = "./" . $path;
 618                 $dot_slash_added = 1;
 619         }
 620         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 621         # good reason), so let's do this manually.
 622         $path =~ s#/+#/#g;
 623         $path =~ s#/\.(?:/|$)#/#g;
 624         $path =~ s#/[^/]+/\.\.##g;
 625         $path =~ s#/$##g;
 626         $path =~ s#^\./## if $dot_slash_added;
 627         return $path;
 628 }
 629
 630 # get_svnprops(PATH)
 631 # ------------------
 632 # Helper for cmd_propget and cmd_proplist below.
 633 sub get_svnprops {
 634         my $path = shift;
 635         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 636         $gs ||= Git::SVN->new;
 637
 638         # prefix THE PATH by the sub-directory from which the user
 639         # invoked us.
 640         $path = $cmd_dir_prefix . $path;
 641         fatal("No such file or directory: $path") unless -e $path;
 642         my $is_dir = -d $path ? 1 : 0;
 643         $path = $gs->{path} . '/' . $path;
 644
 645         # canonicalize the path (otherwise libsvn will abort or fail to
 646         # find the file)
 647         $path = canonicalize_path($path);
 648
 649         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 650         my $props;
 651         if ($is_dir) {
 652                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 653         }
 654         else {
 655                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 656         }
 657         return $props;
 658 }
 659
 660 # cmd_propget (PROP, PATH)
 661 # ------------------------
 662 # Print the SVN property PROP for PATH.
 663 sub cmd_propget {
 664         my ($prop, $path) = @_;
 665         $path = '.' if not defined $path;
 666         usage(1) if not defined $prop;
 667         my $props = get_svnprops($path);
 668         if (not defined $props->{$prop}) {
 669                 fatal("`$path' does not have a `$prop' SVN property.");
 670         }
 671         print $props->{$prop} . "\n";
 672 }
 673
 674 # cmd_proplist (PATH)
 675 # -------------------
 676 # Print the list of SVN properties for PATH.
 677 sub cmd_proplist {
 678         my $path = shift;
 679         $path = '.' if not defined $path;
 680         my $props = get_svnprops($path);
 681         print "Properties on '$path':\n";
 682         foreach (sort keys %{$props}) {
 683                 print "  $_\n";
 684         }
 685 }
 686
 687 sub cmd_multi_init {
 688         my $url = shift;
 689         unless (defined $_trunk || defined $_branches || defined $_tags) {
 690                 usage(1);
 691         }
 692
 693         # there are currently some bugs that prevent multi-init/multi-fetch
 694         # setups from working well without this.
 695         $Git::SVN::_minimize_url = 1;
 696
 697         $_prefix = '' unless defined $_prefix;
 698         if (defined $url) {
 699                 $url =~ s#/+$##;
 700                 init_subdir(@_);
 701         }
 702         do_git_init_db();
 703         if (defined $_trunk) {
 704                 my $trunk_ref = $_prefix . 'trunk';
 705                 # try both old-style and new-style lookups:
 706                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 707                 unless ($gs_trunk) {
 708                         my ($trunk_url, $trunk_path) =
 709                                               complete_svn_url($url, $_trunk);
 710                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 711                                                    undef, $trunk_ref);
 712                 }
 713         }
 714         return unless defined $_branches || defined $_tags;
 715         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 716         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 717         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 718 }
 719
 720 sub cmd_multi_fetch {
 721         my $remotes = Git::SVN::read_all_remotes();
 722         foreach my $repo_id (sort keys %$remotes) {
 723                 if ($remotes->{$repo_id}->{url}) {
 724                         Git::SVN::fetch_all($repo_id, $remotes);
 725                 }
 726         }
 727 }
 728
 729 # this command is special because it requires no metadata
 730 sub cmd_commit_diff {
 731         my ($ta, $tb, $url) = @_;
 732         my $usage = "Usage: $0 commit-diff -r<revision> ".
 733                     "<tree-ish> <tree-ish> [<URL>]";
 734         fatal($usage) if (!defined $ta || !defined $tb);
 735         my $svn_path;
 736         if (!defined $url) {
 737                 my $gs = eval { Git::SVN->new };
 738                 if (!$gs) {
 739                         fatal("Needed URL or usable git-svn --id in ",
 740                               "the command-line\n", $usage);
 741                 }
 742                 $url = $gs->{url};
 743                 $svn_path = $gs->{path};
 744         }
 745         unless (defined $_revision) {
 746                 fatal("-r|--revision is a required argument\n", $usage);
 747         }
 748         if (defined $_message && defined $_file) {
 749                 fatal("Both --message/-m and --file/-F specified ",
 750                       "for the commit message.\n",
 751                       "I have no idea what you mean");
 752         }
 753         if (defined $_file) {
 754                 $_message = file_to_s($_file);
 755         } else {
 756                 $_message ||= get_commit_entry($tb)->{log};
 757         }
 758         my $ra ||= Git::SVN::Ra->new($url);
 759         $svn_path ||= $ra->{svn_path};
 760         my $r = $_revision;
 761         if ($r eq 'HEAD') {
 762                 $r = $ra->get_latest_revnum;
 763         } elsif ($r !~ /^\d+$/) {
 764                 die "revision argument: $r not understood by git-svn\n";
 765         }
 766         my %ed_opts = ( r => $r,
 767                         log => $_message,
 768                         ra => $ra,
 769                         tree_a => $ta,
 770                         tree_b => $tb,
 771                         editor_cb => sub { print "Committed r$_[0]\n" },
 772                         svn_path => $svn_path );
 773         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 774                 print "No changes\n$ta == $tb\n";
 775         }
 776 }
 777
 778 sub cmd_info {
 779         my $path = canonicalize_path(shift or ".");
 780         unless (scalar(@_) == 0) {
 781                 die "Too many arguments specified\n";
 782         }
 783
 784         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
 785
 786         if (!$file_type && !$diff_status) {
 787                 print STDERR "$path:  (Not a versioned resource)\n\n";
 788                 return;
 789         }
 790
 791         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 792         unless ($gs) {
 793                 die "Unable to determine upstream SVN information from ",
 794                     "working tree history\n";
 795         }
 796         my $full_url = $url . ($path eq "." ? "" : "/$path");
 797
 798         if ($_url) {
 799                 print $full_url, "\n";
 800                 return;
 801         }
 802
 803         my $result = "Path: $path\n";
 804         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
 805         $result .= "URL: " . $full_url . "\n";
 806
 807         eval {
 808                 my $repos_root = $gs->repos_root;
 809                 Git::SVN::remove_username($repos_root);
 810                 $result .= "Repository Root: $repos_root\n";
 811         };
 812         if ($@) {
 813                 $result .= "Repository Root: (offline)\n";
 814         }
 815         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
 816         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
 817
 818         $result .= "Node Kind: " .
 819                    ($file_type eq "dir" ? "directory" : "file") . "\n";
 820
 821         my $schedule = $diff_status eq "A"
 822                        ? "add"
 823                        : ($diff_status eq "D" ? "delete" : "normal");
 824         $result .= "Schedule: $schedule\n";
 825
 826         if ($diff_status eq "A") {
 827                 print $result, "\n";
 828                 return;
 829         }
 830
 831         my ($lc_author, $lc_rev, $lc_date_utc);
 832         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
 833         my $log = command_output_pipe(@args);
 834         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
 835         while (<$log>) {
 836                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
 837                         $lc_author = $1;
 838                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
 839                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
 840                         (undef, $lc_rev, undef) = ::extract_metadata($1);
 841                 }
 842         }
 843         close $log;
 844
 845         Git::SVN::Log::set_local_timezone();
 846
 847         $result .= "Last Changed Author: $lc_author\n";
 848         $result .= "Last Changed Rev: $lc_rev\n";
 849         $result .= "Last Changed Date: " .
 850                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
 851
 852         if ($file_type ne "dir") {
 853                 my $text_last_updated_date =
 854                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
 855                 $result .=
 856                     "Text Last Updated: " .
 857                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
 858                     "\n";
 859                 my $checksum;
 860                 if ($diff_status eq "D") {
 861                         my ($fh, $ctx) =
 862                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
 863                         if ($file_type eq "link") {
 864                                 my $file_name = <$fh>;
 865                                 $checksum = md5sum("link $file_name");
 866                         } else {
 867                                 $checksum = md5sum($fh);
 868                         }
 869                         command_close_pipe($fh, $ctx);
 870                 } elsif ($file_type eq "link") {
 871                         my $file_name =
 872                             command(qw(cat-file blob), "HEAD:$path");
 873                         $checksum =
 874                             md5sum("link " . $file_name);
 875                 } else {
 876                         open FILE, "<", $path or die $!;
 877                         $checksum = md5sum(\*FILE);
 878                         close FILE or die $!;
 879                 }
 880                 $result .= "Checksum: " . $checksum . "\n";
 881         }
 882
 883         print $result, "\n";
 884 }
 885
 886 ########################### utility functions #########################
 887
 888 sub rebase_cmd {
 889         my @cmd = qw/rebase/;
 890         push @cmd, '-v' if $_verbose;
 891         push @cmd, qw/--merge/ if $_merge;
 892         push @cmd, "--strategy=$_strategy" if $_strategy;
 893         @cmd;
 894 }
 895
 896 sub post_fetch_checkout {
 897         return if $_no_checkout;
 898         my $gs = $Git::SVN::_head or return;
 899         return if verify_ref('refs/heads/master^0');
 900
 901         my $valid_head = verify_ref('HEAD^0');
 902         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
 903         return if ($valid_head || !verify_ref('HEAD^0'));
 904
 905         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
 906         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
 907         return if -f $index;
 908
 909         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
 910         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
 911         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
 912         print STDERR "Checked out HEAD:\n  ",
 913                      $gs->full_url, " r", $gs->last_rev, "\n";
 914 }
 915
 916 sub complete_svn_url {
 917         my ($url, $path) = @_;
 918         $path =~ s#/+$##;
 919         if ($path !~ m#^[a-z\+]+://#) {
 920                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
 921                         fatal("E: '$path' is not a complete URL ",
 922                               "and a separate URL is not specified");
 923                 }
 924                 return ($url, $path);
 925         }
 926         return ($path, '');
 927 }
 928
 929 sub complete_url_ls_init {
 930         my ($ra, $repo_path, $switch, $pfx) = @_;
 931         unless ($repo_path) {
 932                 print STDERR "W: $switch not specified\n";
 933                 return;
 934         }
 935         $repo_path =~ s#/+$##;
 936         if ($repo_path =~ m#^[a-z\+]+://#) {
 937                 $ra = Git::SVN::Ra->new($repo_path);
 938                 $repo_path = '';
 939         } else {
 940                 $repo_path =~ s#^/+##;
 941                 unless ($ra) {
 942                         fatal("E: '$repo_path' is not a complete URL ",
 943                               "and a separate URL is not specified");
 944                 }
 945         }
 946         my $url = $ra->{url};
 947         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
 948         my $k = "svn-remote.$gs->{repo_id}.url";
 949         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
 950         if ($orig_url && ($orig_url ne $gs->{url})) {
 951                 die "$k already set: $orig_url\n",
 952                     "wanted to set to: $gs->{url}\n";
 953         }
 954         command_oneline('config', $k, $gs->{url}) unless $orig_url;
 955         my $remote_path = "$ra->{svn_path}/$repo_path/*";
 956         $remote_path =~ s#/+#/#g;
 957         $remote_path =~ s#^/##g;
 958         my ($n) = ($switch =~ /^--(\w+)/);
 959         if (length $pfx && $pfx !~ m#/$#) {
 960                 die "--prefix='$pfx' must have a trailing slash '/'\n";
 961         }
 962         command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
 963                                 "$remote_path:refs/remotes/$pfx*");
 964 }
 965
 966 sub verify_ref {
 967         my ($ref) = @_;
 968         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
 969                                { STDERR => 0 }); };
 970 }
 971
 972 sub get_tree_from_treeish {
 973         my ($treeish) = @_;
 974         # $treeish can be a symbolic ref, too:
 975         my $type = command_oneline(qw/cat-file -t/, $treeish);
 976         my $expected;
 977         while ($type eq 'tag') {
 978                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
 979         }
 980         if ($type eq 'commit') {
 981                 $expected = (grep /^tree /, command(qw/cat-file commit/,
 982                                                     $treeish))[0];
 983                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
 984                 die "Unable to get tree from $treeish\n" unless $expected;
 985         } elsif ($type eq 'tree') {
 986                 $expected = $treeish;
 987         } else {
 988                 die "$treeish is a $type, expected tree, tag or commit\n";
 989         }
 990         return $expected;
 991 }
 992
 993 sub get_commit_entry {
 994         my ($treeish) = shift;
 995         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
 996         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
 997         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
 998         open my $log_fh, '>', $commit_editmsg or croak $!;
 999
1000         my $type = command_oneline(qw/cat-file -t/, $treeish);
1001         if ($type eq 'commit' || $type eq 'tag') {
1002                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1003                                                          $type, $treeish);
1004                 my $in_msg = 0;
1005                 while (<$msg_fh>) {
1006                         if (!$in_msg) {
1007                                 $in_msg = 1 if (/^\s*$/);
1008                         } elsif (/^git-svn-id: /) {
1009                                 # skip this for now, we regenerate the
1010                                 # correct one on re-fetch anyways
1011                                 # TODO: set *:merge properties or like...
1012                         } else {
1013                                 print $log_fh $_ or croak $!;
1014                         }
1015                 }
1016                 command_close_pipe($msg_fh, $ctx);
1017         }
1018         close $log_fh or croak $!;
1019
1020         if ($_edit || ($type eq 'tree')) {
1021                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1022                 # TODO: strip out spaces, comments, like git-commit.sh
1023                 system($editor, $commit_editmsg);
1024         }
1025         rename $commit_editmsg, $commit_msg or croak $!;
1026         open $log_fh, '<', $commit_msg or croak $!;
1027         { local $/; chomp($log_entry{log} = <$log_fh>); }
1028         close $log_fh or croak $!;
1029         unlink $commit_msg;
1030         \%log_entry;
1031 }
1032
1033 sub s_to_file {
1034         my ($str, $file, $mode) = @_;
1035         open my $fd,'>',$file or croak $!;
1036         print $fd $str,"\n" or croak $!;
1037         close $fd or croak $!;
1038         chmod ($mode &~ umask, $file) if (defined $mode);
1039 }
1040
1041 sub file_to_s {
1042         my $file = shift;
1043         open my $fd,'<',$file or croak "$!: file: $file\n";
1044         local $/;
1045         my $ret = <$fd>;
1046         close $fd or croak $!;
1047         $ret =~ s/\s*$//s;
1048         return $ret;
1049 }
1050
1051 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1052 sub load_authors {
1053         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1054         my $log = $cmd eq 'log';
1055         while (<$authors>) {
1056                 chomp;
1057                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1058                 my ($user, $name, $email) = ($1, $2, $3);
1059                 if ($log) {
1060                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1061                 } else {
1062                         $users{$user} = [$name, $email];
1063                 }
1064         }
1065         close $authors or croak $!;
1066 }
1067
1068 # convert GetOpt::Long specs for use by git-config
1069 sub read_repo_config {
1070         return unless -d $ENV{GIT_DIR};
1071         my $opts = shift;
1072         my @config_only;
1073         foreach my $o (keys %$opts) {
1074                 # if we have mixedCase and a long option-only, then
1075                 # it's a config-only variable that we don't need for
1076                 # the command-line.
1077                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1078                 my $v = $opts->{$o};
1079                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1080                 $key =~ s/-//g;
1081                 my $arg = 'git-config';
1082                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1083                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1084                 if (ref $v eq 'ARRAY') {
1085                         chomp(my @tmp = `$arg --get-all svn.$key`);
1086                         @$v = @tmp if @tmp;
1087                 } else {
1088                         chomp(my $tmp = `$arg --get svn.$key`);
1089                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1090                                 $$v = $tmp;
1091                         }
1092                 }
1093         }
1094         delete @$opts{@config_only} if @config_only;
1095 }
1096
1097 sub extract_metadata {
1098         my $id = shift or return (undef, undef, undef);
1099         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1100                                                         \s([a-f\d\-]+)$/x);
1101         if (!defined $rev || !$uuid || !$url) {
1102                 # some of the original repositories I made had
1103                 # identifiers like this:
1104                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1105         }
1106         return ($url, $rev, $uuid);
1107 }
1108
1109 sub cmt_metadata {
1110         return extract_metadata((grep(/^git-svn-id: /,
1111                 command(qw/cat-file commit/, shift)))[-1]);
1112 }
1113
1114 sub working_head_info {
1115         my ($head, $refs) = @_;
1116         my @args = ('log', '--no-color', '--first-parent');
1117         my ($fh, $ctx) = command_output_pipe(@args, $head);
1118         my $hash;
1119         my %max;
1120         while (<$fh>) {
1121                 if ( m{^commit ($::sha1)$} ) {
1122                         unshift @$refs, $hash if $hash and $refs;
1123                         $hash = $1;
1124                         next;
1125                 }
1126                 next unless s{^\s*(git-svn-id:)}{$1};
1127                 my ($url, $rev, $uuid) = extract_metadata($_);
1128                 if (defined $url && defined $rev) {
1129                         next if $max{$url} and $max{$url} < $rev;
1130                         if (my $gs = Git::SVN->find_by_url($url)) {
1131                                 my $c = $gs->rev_map_get($rev);
1132                                 if ($c && $c eq $hash) {
1133                                         close $fh; # break the pipe
1134                                         return ($url, $rev, $uuid, $gs);
1135                                 } else {
1136                                         $max{$url} ||= $gs->rev_map_max;
1137                                 }
1138                         }
1139                 }
1140         }
1141         command_close_pipe($fh, $ctx);
1142         (undef, undef, undef, undef);
1143 }
1144
1145 sub read_commit_parents {
1146         my ($parents, $c) = @_;
1147         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1148         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1149         @{$parents->{$c}} = split(/ /, $p);
1150 }
1151
1152 sub linearize_history {
1153         my ($gs, $refs) = @_;
1154         my %parents;
1155         foreach my $c (@$refs) {
1156                 read_commit_parents(\%parents, $c);
1157         }
1158
1159         my @linear_refs;
1160         my %skip = ();
1161         my $last_svn_commit = $gs->last_commit;
1162         foreach my $c (reverse @$refs) {
1163                 next if $c eq $last_svn_commit;
1164                 last if $skip{$c};
1165
1166                 unshift @linear_refs, $c;
1167                 $skip{$c} = 1;
1168
1169                 # we only want the first parent to diff against for linear
1170                 # history, we save the rest to inject when we finalize the
1171                 # svn commit
1172                 my $fp_a = verify_ref("$c~1");
1173                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1174                 if (!$fp_a || !$fp_b) {
1175                         die "Commit $c\n",
1176                             "has no parent commit, and therefore ",
1177                             "nothing to diff against.\n",
1178                             "You should be working from a repository ",
1179                             "originally created by git-svn\n";
1180                 }
1181                 if ($fp_a ne $fp_b) {
1182                         die "$c~1 = $fp_a, however parsing commit $c ",
1183                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1184                 }
1185
1186                 foreach my $p (@{$parents{$c}}) {
1187                         $skip{$p} = 1;
1188                 }
1189         }
1190         (\@linear_refs, \%parents);
1191 }
1192
1193 sub find_file_type_and_diff_status {
1194         my ($path) = @_;
1195         return ('dir', '') if $path eq '.';
1196
1197         my $diff_output =
1198             command_oneline(qw(diff --cached --name-status --), $path) || "";
1199         my $diff_status = (split(' ', $diff_output))[0] || "";
1200
1201         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1202
1203         return (undef, undef) if !$diff_status && !$ls_tree;
1204
1205         if ($diff_status eq "A") {
1206                 return ("link", $diff_status) if -l $path;
1207                 return ("dir", $diff_status) if -d $path;
1208                 return ("file", $diff_status);
1209         }
1210
1211         my $mode = (split(' ', $ls_tree))[0] || "";
1212
1213         return ("link", $diff_status) if $mode eq "120000";
1214         return ("dir", $diff_status) if $mode eq "040000";
1215         return ("file", $diff_status);
1216 }
1217
1218 sub md5sum {
1219         my $arg = shift;
1220         my $ref = ref $arg;
1221         my $md5 = Digest::MD5->new();
1222         if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1223                 $md5->addfile($arg) or croak $!;
1224         } elsif ($ref eq 'SCALAR') {
1225                 $md5->add($$arg) or croak $!;
1226         } elsif (!$ref) {
1227                 $md5->add($arg) or croak $!;
1228         } else {
1229                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1230         }
1231         return $md5->hexdigest();
1232 }
1233
1234 package Git::SVN;
1235 use strict;
1236 use warnings;
1237 use Fcntl qw/:DEFAULT :seek/;
1238 use constant rev_map_fmt => 'NH40';
1239 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1240             $_repack $_repack_flags $_use_svm_props $_head
1241             $_use_svnsync_props $no_reuse_existing $_minimize_url
1242             $_use_log_author/;
1243 use Carp qw/croak/;
1244 use File::Path qw/mkpath/;
1245 use File::Copy qw/copy/;
1246 use IPC::Open3;
1247
1248 my $_repack_nr;
1249 # properties that we do not log:
1250 my %SKIP_PROP;
1251 BEGIN {
1252         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1253                                         svn:special svn:executable
1254                                         svn:entry:committed-rev
1255                                         svn:entry:last-author
1256                                         svn:entry:uuid
1257                                         svn:entry:committed-date/;
1258
1259         # some options are read globally, but can be overridden locally
1260         # per [svn-remote "..."] section.  Command-line options will *NOT*
1261         # override options set in an [svn-remote "..."] section
1262         no strict 'refs';
1263         for my $option (qw/follow_parent no_metadata use_svm_props
1264                            use_svnsync_props/) {
1265                 my $key = $option;
1266                 $key =~ tr/_//d;
1267                 my $prop = "-$option";
1268                 *$option = sub {
1269                         my ($self) = @_;
1270                         return $self->{$prop} if exists $self->{$prop};
1271                         my $k = "svn-remote.$self->{repo_id}.$key";
1272                         eval { command_oneline(qw/config --get/, $k) };
1273                         if ($@) {
1274                                 $self->{$prop} = ${"Git::SVN::_$option"};
1275                         } else {
1276                                 my $v = command_oneline(qw/config --bool/,$k);
1277                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1278                         }
1279                         return $self->{$prop};
1280                 }
1281         }
1282 }
1283
1284 my %LOCKFILES;
1285 END { unlink keys %LOCKFILES if %LOCKFILES }
1286
1287 sub resolve_local_globs {
1288         my ($url, $fetch, $glob_spec) = @_;
1289         return unless defined $glob_spec;
1290         my $ref = $glob_spec->{ref};
1291         my $path = $glob_spec->{path};
1292         foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1293                 next unless m#^refs/remotes/$ref->{regex}$#;
1294                 my $p = $1;
1295                 my $pathname = desanitize_refname($path->full_path($p));
1296                 my $refname = desanitize_refname($ref->full_path($p));
1297                 if (my $existing = $fetch->{$pathname}) {
1298                         if ($existing ne $refname) {
1299                                 die "Refspec conflict:\n",
1300                                     "existing: refs/remotes/$existing\n",
1301                                     " globbed: refs/remotes/$refname\n";
1302                         }
1303                         my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1304                         $u =~ s!^\Q$url\E(/|$)!! or die
1305                           "refs/remotes/$refname: '$url' not found in '$u'\n";
1306                         if ($pathname ne $u) {
1307                                 warn "W: Refspec glob conflict ",
1308                                      "(ref: refs/remotes/$refname):\n",
1309                                      "expected path: $pathname\n",
1310                                      "    real path: $u\n",
1311                                      "Continuing ahead with $u\n";
1312                                 next;
1313                         }
1314                 } else {
1315                         $fetch->{$pathname} = $refname;
1316                 }
1317         }
1318 }
1319
1320 sub parse_revision_argument {
1321         my ($base, $head) = @_;
1322         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1323                 return ($base, $head);
1324         }
1325         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1326         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1327         return ($head, $head) if ($::_revision eq 'HEAD');
1328         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1329         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1330         die "revision argument: $::_revision not understood by git-svn\n";
1331 }
1332
1333 sub fetch_all {
1334         my ($repo_id, $remotes) = @_;
1335         if (ref $repo_id) {
1336                 my $gs = $repo_id;
1337                 $repo_id = undef;
1338                 $repo_id = $gs->{repo_id};
1339         }
1340         $remotes ||= read_all_remotes();
1341         my $remote = $remotes->{$repo_id} or
1342                      die "[svn-remote \"$repo_id\"] unknown\n";
1343         my $fetch = $remote->{fetch};
1344         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1345         my (@gs, @globs);
1346         my $ra = Git::SVN::Ra->new($url);
1347         my $uuid = $ra->get_uuid;
1348         my $head = $ra->get_latest_revnum;
1349         my $base = defined $fetch ? $head : 0;
1350
1351         # read the max revs for wildcard expansion (branches/*, tags/*)
1352         foreach my $t (qw/branches tags/) {
1353                 defined $remote->{$t} or next;
1354                 push @globs, $remote->{$t};
1355                 my $max_rev = eval { tmp_config(qw/--int --get/,
1356                                          "svn-remote.$repo_id.${t}-maxRev") };
1357                 if (defined $max_rev && ($max_rev < $base)) {
1358                         $base = $max_rev;
1359                 } elsif (!defined $max_rev) {
1360                         $base = 0;
1361                 }
1362         }
1363
1364         if ($fetch) {
1365                 foreach my $p (sort keys %$fetch) {
1366                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1367                         my $lr = $gs->rev_map_max;
1368                         if (defined $lr) {
1369                                 $base = $lr if ($lr < $base);
1370                         }
1371                         push @gs, $gs;
1372                 }
1373         }
1374
1375         ($base, $head) = parse_revision_argument($base, $head);
1376         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1377 }
1378
1379 sub read_all_remotes {
1380         my $r = {};
1381         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1382                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1383                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1384                         $local_ref =~ s{^/}{};
1385                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1386                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1387                         $r->{$1}->{url} = $2;
1388                 } elsif (m!^(.+)\.(branches|tags)=
1389                            (.*):refs/remotes/(.+)\s*$/!x) {
1390                         my ($p, $g) = ($3, $4);
1391                         my $rs = $r->{$1}->{$2} = {
1392                                           t => $2,
1393                                           remote => $1,
1394                                           path => Git::SVN::GlobSpec->new($p),
1395                                           ref => Git::SVN::GlobSpec->new($g) };
1396                         if (length($rs->{ref}->{right}) != 0) {
1397                                 die "The '*' glob character must be the last ",
1398                                     "character of '$g'\n";
1399                         }
1400                 }
1401         }
1402         $r;
1403 }
1404
1405 sub init_vars {
1406         if (defined $_repack) {
1407                 $_repack = 1000 if ($_repack <= 0);
1408                 $_repack_nr = $_repack;
1409                 $_repack_flags ||= '-d';
1410         }
1411 }
1412
1413 sub verify_remotes_sanity {
1414         return unless -d $ENV{GIT_DIR};
1415         my %seen;
1416         foreach (command(qw/config -l/)) {
1417                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1418                         if ($seen{$1}) {
1419                                 die "Remote ref refs/remote/$1 is tracked by",
1420                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1421                                     "Please resolve this ambiguity in ",
1422                                     "your git configuration file before ",
1423                                     "continuing\n";
1424                         }
1425                         $seen{$1} = $_;
1426                 }
1427         }
1428 }
1429
1430 # we allow more chars than remotes2config.sh...
1431 sub sanitize_remote_name {
1432         my ($name) = @_;
1433         $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1434         $name;
1435 }
1436
1437 sub find_existing_remote {
1438         my ($url, $remotes) = @_;
1439         return undef if $no_reuse_existing;
1440         my $existing;
1441         foreach my $repo_id (keys %$remotes) {
1442                 my $u = $remotes->{$repo_id}->{url} or next;
1443                 next if $u ne $url;
1444                 $existing = $repo_id;
1445                 last;
1446         }
1447         $existing;
1448 }
1449
1450 sub init_remote_config {
1451         my ($self, $url, $no_write) = @_;
1452         $url =~ s!/+$!!; # strip trailing slash
1453         my $r = read_all_remotes();
1454         my $existing = find_existing_remote($url, $r);
1455         if ($existing) {
1456                 unless ($no_write) {
1457                         print STDERR "Using existing ",
1458                                      "[svn-remote \"$existing\"]\n";
1459                 }
1460                 $self->{repo_id} = $existing;
1461         } elsif ($_minimize_url) {
1462                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1463                 $existing = find_existing_remote($min_url, $r);
1464                 if ($existing) {
1465                         unless ($no_write) {
1466                                 print STDERR "Using existing ",
1467                                              "[svn-remote \"$existing\"]\n";
1468                         }
1469                         $self->{repo_id} = $existing;
1470                 }
1471                 if ($min_url ne $url) {
1472                         unless ($no_write) {
1473                                 print STDERR "Using higher level of URL: ",
1474                                              "$url => $min_url\n";
1475                         }
1476                         my $old_path = $self->{path};
1477                         $self->{path} = $url;
1478                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1479                         if (length $old_path) {
1480                                 $self->{path} .= "/$old_path";
1481                         }
1482                         $url = $min_url;
1483                 }
1484         }
1485         my $orig_url;
1486         if (!$existing) {
1487                 # verify that we aren't overwriting anything:
1488                 $orig_url = eval {
1489                         command_oneline('config', '--get',
1490                                         "svn-remote.$self->{repo_id}.url")
1491                 };
1492                 if ($orig_url && ($orig_url ne $url)) {
1493                         die "svn-remote.$self->{repo_id}.url already set: ",
1494                             "$orig_url\nwanted to set to: $url\n";
1495                 }
1496         }
1497         my ($xrepo_id, $xpath) = find_ref($self->refname);
1498         if (defined $xpath) {
1499                 die "svn-remote.$xrepo_id.fetch already set to track ",
1500                     "$xpath:refs/remotes/", $self->refname, "\n";
1501         }
1502         unless ($no_write) {
1503                 command_noisy('config',
1504                               "svn-remote.$self->{repo_id}.url", $url);
1505                 $self->{path} =~ s{^/}{};
1506                 command_noisy('config', '--add',
1507                               "svn-remote.$self->{repo_id}.fetch",
1508                               "$self->{path}:".$self->refname);
1509         }
1510         $self->{url} = $url;
1511 }
1512
1513 sub find_by_url { # repos_root and, path are optional
1514         my ($class, $full_url, $repos_root, $path) = @_;
1515
1516         return undef unless defined $full_url;
1517         remove_username($full_url);
1518         remove_username($repos_root) if defined $repos_root;
1519         my $remotes = read_all_remotes();
1520         if (defined $full_url && defined $repos_root && !defined $path) {
1521                 $path = $full_url;
1522                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1523         }
1524         foreach my $repo_id (keys %$remotes) {
1525                 my $u = $remotes->{$repo_id}->{url} or next;
1526                 remove_username($u);
1527                 next if defined $repos_root && $repos_root ne $u;
1528
1529                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1530                 foreach (qw/branches tags/) {
1531                         resolve_local_globs($u, $fetch,
1532                                             $remotes->{$repo_id}->{$_});
1533                 }
1534                 my $p = $path;
1535                 unless (defined $p) {
1536                         $p = $full_url;
1537                         $p =~ s#^\Q$u\E(?:/|$)## or next;
1538                 }
1539                 foreach my $f (keys %$fetch) {
1540                         next if $f ne $p;
1541                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1542                 }
1543         }
1544         undef;
1545 }
1546
1547 sub init {
1548         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1549         my $self = _new($class, $repo_id, $ref_id, $path);
1550         if (defined $url) {
1551                 $self->init_remote_config($url, $no_write);
1552         }
1553         $self;
1554 }
1555
1556 sub find_ref {
1557         my ($ref_id) = @_;
1558         foreach (command(qw/config -l/)) {
1559                 next unless m!^svn-remote\.(.+)\.fetch=
1560                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1561                 my ($repo_id, $path, $ref) = ($1, $2, $3);
1562                 if ($ref eq $ref_id) {
1563                         $path = '' if ($path =~ m#^\./?#);
1564                         return ($repo_id, $path);
1565                 }
1566         }
1567         (undef, undef, undef);
1568 }
1569
1570 sub new {
1571         my ($class, $ref_id, $repo_id, $path) = @_;
1572         if (defined $ref_id && !defined $repo_id && !defined $path) {
1573                 ($repo_id, $path) = find_ref($ref_id);
1574                 if (!defined $repo_id) {
1575                         die "Could not find a \"svn-remote.*.fetch\" key ",
1576                             "in the repository configuration matching: ",
1577                             "refs/remotes/$ref_id\n";
1578                 }
1579         }
1580         my $self = _new($class, $repo_id, $ref_id, $path);
1581         if (!defined $self->{path} || !length $self->{path}) {
1582                 my $fetch = command_oneline('config', '--get',
1583                                             "svn-remote.$repo_id.fetch",
1584                                             ":refs/remotes/$ref_id\$") or
1585                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1586                          "\":refs/remotes/$ref_id\$\" in config\n";
1587                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1588         }
1589         $self->{url} = command_oneline('config', '--get',
1590                                        "svn-remote.$repo_id.url") or
1591                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1592         $self->rebuild;
1593         $self;
1594 }
1595
1596 sub refname {
1597         my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1598
1599         # It cannot end with a slash /, we'll throw up on this because
1600         # SVN can't have directories with a slash in their name, either:
1601         if ($refname =~ m{/$}) {
1602                 die "ref: '$refname' ends with a trailing slash, this is ",
1603                     "not permitted by git nor Subversion\n";
1604         }
1605
1606         # It cannot have ASCII control character space, tilde ~, caret ^,
1607         # colon :, question-mark ?, asterisk *, space, or open bracket [
1608         # anywhere.
1609         #
1610         # Additionally, % must be escaped because it is used for escaping
1611         # and we want our escaped refname to be reversible
1612         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1613
1614         # no slash-separated component can begin with a dot .
1615         # /.* becomes /%2E*
1616         $refname =~ s{/\.}{/%2E}g;
1617
1618         # It cannot have two consecutive dots .. anywhere
1619         # .. becomes %2E%2E
1620         $refname =~ s{\.\.}{%2E%2E}g;
1621
1622         return $refname;
1623 }
1624
1625 sub desanitize_refname {
1626         my ($refname) = @_;
1627         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1628         return $refname;
1629 }
1630
1631 sub svm_uuid {
1632         my ($self) = @_;
1633         return $self->{svm}->{uuid} if $self->svm;
1634         $self->ra;
1635         unless ($self->{svm}) {
1636                 die "SVM UUID not cached, and reading remotely failed\n";
1637         }
1638         $self->{svm}->{uuid};
1639 }
1640
1641 sub svm {
1642         my ($self) = @_;
1643         return $self->{svm} if $self->{svm};
1644         my $svm;
1645         # see if we have it in our config, first:
1646         eval {
1647                 my $section = "svn-remote.$self->{repo_id}";
1648                 $svm = {
1649                   source => tmp_config('--get', "$section.svm-source"),
1650                   uuid => tmp_config('--get', "$section.svm-uuid"),
1651                   replace => tmp_config('--get', "$section.svm-replace"),
1652                 }
1653         };
1654         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1655                 $self->{svm} = $svm;
1656         }
1657         $self->{svm};
1658 }
1659
1660 sub _set_svm_vars {
1661         my ($self, $ra) = @_;
1662         return $ra if $self->svm;
1663
1664         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1665                     "(svm:source, svm:uuid) ",
1666                     "from the following URLs:\n" );
1667         sub read_svm_props {
1668                 my ($self, $ra, $path, $r) = @_;
1669                 my $props = ($ra->get_dir($path, $r))[2];
1670                 my $src = $props->{'svm:source'};
1671                 my $uuid = $props->{'svm:uuid'};
1672                 return undef if (!$src || !$uuid);
1673
1674                 chomp($src, $uuid);
1675
1676                 $uuid =~ m{^[0-9a-f\-]{30,}$}
1677                     or die "doesn't look right - svm:uuid is '$uuid'\n";
1678
1679                 # the '!' is used to mark the repos_root!/relative/path
1680                 $src =~ s{/?!/?}{/};
1681                 $src =~ s{/+$}{}; # no trailing slashes please
1682                 # username is of no interest
1683                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1684
1685                 my $replace = $ra->{url};
1686                 $replace .= "/$path" if length $path;
1687
1688                 my $section = "svn-remote.$self->{repo_id}";
1689                 tmp_config("$section.svm-source", $src);
1690                 tmp_config("$section.svm-replace", $replace);
1691                 tmp_config("$section.svm-uuid", $uuid);
1692                 $self->{svm} = {
1693                         source => $src,
1694                         uuid => $uuid,
1695                         replace => $replace
1696                 };
1697         }
1698
1699         my $r = $ra->get_latest_revnum;
1700         my $path = $self->{path};
1701         my %tried;
1702         while (length $path) {
1703                 unless ($tried{"$self->{url}/$path"}) {
1704                         return $ra if $self->read_svm_props($ra, $path, $r);
1705                         $tried{"$self->{url}/$path"} = 1;
1706                 }
1707                 $path =~ s#/?[^/]+$##;
1708         }
1709         die "Path: '$path' should be ''\n" if $path ne '';
1710         return $ra if $self->read_svm_props($ra, $path, $r);
1711         $tried{"$self->{url}/$path"} = 1;
1712
1713         if ($ra->{repos_root} eq $self->{url}) {
1714                 die @err, (map { "  $_\n" } keys %tried), "\n";
1715         }
1716
1717         # nope, make sure we're connected to the repository root:
1718         my $ok;
1719         my @tried_b;
1720         $path = $ra->{svn_path};
1721         $ra = Git::SVN::Ra->new($ra->{repos_root});
1722         while (length $path) {
1723                 unless ($tried{"$ra->{url}/$path"}) {
1724                         $ok = $self->read_svm_props($ra, $path, $r);
1725                         last if $ok;
1726                         $tried{"$ra->{url}/$path"} = 1;
1727                 }
1728                 $path =~ s#/?[^/]+$##;
1729         }
1730         die "Path: '$path' should be ''\n" if $path ne '';
1731         $ok ||= $self->read_svm_props($ra, $path, $r);
1732         $tried{"$ra->{url}/$path"} = 1;
1733         if (!$ok) {
1734                 die @err, (map { "  $_\n" } keys %tried), "\n";
1735         }
1736         Git::SVN::Ra->new($self->{url});
1737 }
1738
1739 sub svnsync {
1740         my ($self) = @_;
1741         return $self->{svnsync} if $self->{svnsync};
1742
1743         if ($self->no_metadata) {
1744                 die "Can't have both 'noMetadata' and ",
1745                     "'useSvnsyncProps' options set!\n";
1746         }
1747         if ($self->rewrite_root) {
1748                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1749                     "options set!\n";
1750         }
1751
1752         my $svnsync;
1753         # see if we have it in our config, first:
1754         eval {
1755                 my $section = "svn-remote.$self->{repo_id}";
1756                 $svnsync = {
1757                   url => tmp_config('--get', "$section.svnsync-url"),
1758                   uuid => tmp_config('--get', "$section.svnsync-uuid"),
1759                 }
1760         };
1761         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1762                 return $self->{svnsync} = $svnsync;
1763         }
1764
1765         my $err = "useSvnsyncProps set, but failed to read " .
1766                   "svnsync property: svn:sync-from-";
1767         my $rp = $self->ra->rev_proplist(0);
1768
1769         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1770         $url =~ m{^[a-z\+]+://} or
1771                    die "doesn't look right - svn:sync-from-url is '$url'\n";
1772
1773         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1774         $uuid =~ m{^[0-9a-f\-]{30,}$} or
1775                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1776
1777         my $section = "svn-remote.$self->{repo_id}";
1778         tmp_config('--add', "$section.svnsync-uuid", $uuid);
1779         tmp_config('--add', "$section.svnsync-url", $url);
1780         return $self->{svnsync} = { url => $url, uuid => $uuid };
1781 }
1782
1783 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1784 # remote lookup (useful for 'git svn log').
1785 sub ra_uuid {
1786         my ($self) = @_;
1787         unless ($self->{ra_uuid}) {
1788                 my $key = "svn-remote.$self->{repo_id}.uuid";
1789                 my $uuid = eval { tmp_config('--get', $key) };
1790                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1791                         $self->{ra_uuid} = $uuid;
1792                 } else {
1793                         die "ra_uuid called without URL\n" unless $self->{url};
1794                         $self->{ra_uuid} = $self->ra->get_uuid;
1795                         tmp_config('--add', $key, $self->{ra_uuid});
1796                 }
1797         }
1798         $self->{ra_uuid};
1799 }
1800
1801 sub _set_repos_root {
1802         my ($self, $repos_root) = @_;
1803         my $k = "svn-remote.$self->{repo_id}.reposRoot";
1804         $repos_root ||= $self->ra->{repos_root};
1805         tmp_config($k, $repos_root);
1806         $repos_root;
1807 }
1808
1809 sub repos_root {
1810         my ($self) = @_;
1811         my $k = "svn-remote.$self->{repo_id}.reposRoot";
1812         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1813 }
1814
1815 sub ra {
1816         my ($self) = shift;
1817         my $ra = Git::SVN::Ra->new($self->{url});
1818         $self->_set_repos_root($ra->{repos_root});
1819         if ($self->use_svm_props && !$self->{svm}) {
1820                 if ($self->no_metadata) {
1821                         die "Can't have both 'noMetadata' and ",
1822                             "'useSvmProps' options set!\n";
1823                 } elsif ($self->use_svnsync_props) {
1824                         die "Can't have both 'useSvnsyncProps' and ",
1825                             "'useSvmProps' options set!\n";
1826                 }
1827                 $ra = $self->_set_svm_vars($ra);
1828                 $self->{-want_revprops} = 1;
1829         }
1830         $ra;
1831 }
1832
1833 sub rel_path {
1834         my ($self) = @_;
1835         my $repos_root = $self->ra->{repos_root};
1836         return $self->{path} if ($self->{url} eq $repos_root);
1837         my $url = $self->{url} .
1838                   (length $self->{path} ? "/$self->{path}" : $self->{path});
1839         $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1840         $url;
1841 }
1842
1843 # prop_walk(PATH, REV, SUB)
1844 # -------------------------
1845 # Recursively traverse PATH at revision REV and invoke SUB for each
1846 # directory that contains a SVN property.  SUB will be invoked as
1847 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
1848 # Git::SVN, `path' the path to the directory where the properties
1849 # `props' were found.  The `path' will be relative to point of checkout,
1850 # that is, if url://repo/trunk is the current Git branch, and that
1851 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1852 # as `path' (note the trailing `/').
1853 sub prop_walk {
1854         my ($self, $path, $rev, $sub) = @_;
1855
1856         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1857         $path =~ s#^/*#/#g;
1858         my $p = $path;
1859         # Strip the irrelevant part of the path.
1860         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1861         # Ensure the path is terminated by a `/'.
1862         $p =~ s#/*$#/#;
1863
1864         # The properties contain all the internal SVN stuff nobody
1865         # (usually) cares about.
1866         my $interesting_props = 0;
1867         foreach (keys %{$props}) {
1868                 # If it doesn't start with `svn:', it must be a
1869                 # user-defined property.
1870                 ++$interesting_props and next if $_ !~ /^svn:/;
1871                 # FIXME: Fragile, if SVN adds new public properties,
1872                 # this needs to be updated.
1873                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1874                                                  |eol-style|mime-type
1875                                                  |externals|needs-lock)$/x;
1876         }
1877         &$sub($self, $p, $props) if $interesting_props;
1878
1879         foreach (sort keys %$dirent) {
1880                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1881                 $self->prop_walk($path . '/' . $_, $rev, $sub);
1882         }
1883 }
1884
1885 sub last_rev { ($_[0]->last_rev_commit)[0] }
1886 sub last_commit { ($_[0]->last_rev_commit)[1] }
1887
1888 # returns the newest SVN revision number and newest commit SHA1
1889 sub last_rev_commit {
1890         my ($self) = @_;
1891         if (defined $self->{last_rev} && defined $self->{last_commit}) {
1892                 return ($self->{last_rev}, $self->{last_commit});
1893         }
1894         my $c = ::verify_ref($self->refname.'^0');
1895         if ($c && !$self->use_svm_props && !$self->no_metadata) {
1896                 my $rev = (::cmt_metadata($c))[1];
1897                 if (defined $rev) {
1898                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1899                         return ($rev, $c);
1900                 }
1901         }
1902         my $map_path = $self->map_path;
1903         unless (-e $map_path) {
1904                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1905                 return (undef, undef);
1906         }
1907         my ($rev, $commit) = $self->rev_map_max(1);
1908         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1909         return ($rev, $commit);
1910 }
1911
1912 sub get_fetch_range {
1913         my ($self, $min, $max) = @_;
1914         $max ||= $self->ra->get_latest_revnum;
1915         $min ||= $self->rev_map_max;
1916         (++$min, $max);
1917 }
1918
1919 sub tmp_config {
1920         my (@args) = @_;
1921         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1922         my $config = "$ENV{GIT_DIR}/svn/.metadata";
1923         if (! -f $config && -f $old_def_config) {
1924                 rename $old_def_config, $config or
1925                        die "Failed rename $old_def_config => $config: $!\n";
1926         }
1927         my $old_config = $ENV{GIT_CONFIG};
1928         $ENV{GIT_CONFIG} = $config;
1929         $@ = undef;
1930         my @ret = eval {
1931                 unless (-f $config) {
1932                         mkfile($config);
1933                         open my $fh, '>', $config or
1934                             die "Can't open $config: $!\n";
1935                         print $fh "; This file is used internally by ",
1936                                   "git-svn\n" or die
1937                                   "Couldn't write to $config: $!\n";
1938                         print $fh "; You should not have to edit it\n" or
1939                               die "Couldn't write to $config: $!\n";
1940                         close $fh or die "Couldn't close $config: $!\n";
1941                 }
1942                 command('config', @args);
1943         };
1944         my $err = $@;
1945         if (defined $old_config) {
1946                 $ENV{GIT_CONFIG} = $old_config;
1947         } else {
1948                 delete $ENV{GIT_CONFIG};
1949         }
1950         die $err if $err;
1951         wantarray ? @ret : $ret[0];
1952 }
1953
1954 sub tmp_index_do {
1955         my ($self, $sub) = @_;
1956         my $old_index = $ENV{GIT_INDEX_FILE};
1957         $ENV{GIT_INDEX_FILE} = $self->{index};
1958         $@ = undef;
1959         my @ret = eval {
1960                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1961                 mkpath([$dir]) unless -d $dir;
1962                 &$sub;
1963         };
1964         my $err = $@;
1965         if (defined $old_index) {
1966                 $ENV{GIT_INDEX_FILE} = $old_index;
1967         } else {
1968                 delete $ENV{GIT_INDEX_FILE};
1969         }
1970         die $err if $err;
1971         wantarray ? @ret : $ret[0];
1972 }
1973
1974 sub assert_index_clean {
1975         my ($self, $treeish) = @_;
1976
1977         $self->tmp_index_do(sub {
1978                 command_noisy('read-tree', $treeish) unless -e $self->{index};
1979                 my $x = command_oneline('write-tree');
1980                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1981                            /^tree ($::sha1)/mo);
1982                 return if $y eq $x;
1983
1984                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
1985                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
1986                 command_noisy('read-tree', $treeish);
1987                 $x = command_oneline('write-tree');
1988                 if ($y ne $x) {
1989                         ::fatal "trees ($treeish) $y != $x\n",
1990                                 "Something is seriously wrong...";
1991                 }
1992         });
1993 }
1994
1995 sub get_commit_parents {
1996         my ($self, $log_entry) = @_;
1997         my (%seen, @ret, @tmp);
1998         # legacy support for 'set-tree'; this is only used by set_tree_cb:
1999         if (my $ip = $self->{inject_parents}) {
2000                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2001                         push @tmp, $commit;
2002                 }
2003         }
2004         if (my $cur = ::verify_ref($self->refname.'^0')) {
2005                 push @tmp, $cur;
2006         }
2007         if (my $ipd = $self->{inject_parents_dcommit}) {
2008                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2009                         push @tmp, @$commit;
2010                 }
2011         }
2012         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2013         while (my $p = shift @tmp) {
2014                 next if $seen{$p};
2015                 $seen{$p} = 1;
2016                 push @ret, $p;
2017                 # MAXPARENT is defined to 16 in commit-tree.c:
2018                 last if @ret >= 16;
2019         }
2020         if (@tmp) {
2021                 die "r$log_entry->{revision}: No room for parents:\n\t",
2022                     join("\n\t", @tmp), "\n";
2023         }
2024         @ret;
2025 }
2026
2027 sub rewrite_root {
2028         my ($self) = @_;
2029         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2030         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2031         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2032         if ($rwr) {
2033                 $rwr =~ s#/+$##;
2034                 if ($rwr !~ m#^[a-z\+]+://#) {
2035                         die "$rwr is not a valid URL (key: $k)\n";
2036                 }
2037         }
2038         $self->{-rewrite_root} = $rwr;
2039 }
2040
2041 sub metadata_url {
2042         my ($self) = @_;
2043         ($self->rewrite_root || $self->{url}) .
2044            (length $self->{path} ? '/' . $self->{path} : '');
2045 }
2046
2047 sub full_url {
2048         my ($self) = @_;
2049         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2050 }
2051
2052 sub do_git_commit {
2053         my ($self, $log_entry) = @_;
2054         my $lr = $self->last_rev;
2055         if (defined $lr && $lr >= $log_entry->{revision}) {
2056                 die "Last fetched revision of ", $self->refname,
2057                     " was r$lr, but we are about to fetch: ",
2058                     "r$log_entry->{revision}!\n";
2059         }
2060         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2061                 croak "$log_entry->{revision} = $c already exists! ",
2062                       "Why are we refetching it?\n";
2063         }
2064         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2065         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2066         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2067
2068         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2069                                                 ? $log_entry->{commit_name}
2070                                                 : $log_entry->{name};
2071         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2072                                                 ? $log_entry->{commit_email}
2073                                                 : $log_entry->{email};
2074
2075         my $tree = $log_entry->{tree};
2076         if (!defined $tree) {
2077                 $tree = $self->tmp_index_do(sub {
2078                                             command_oneline('write-tree') });
2079         }
2080         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2081
2082         my @exec = ('git-commit-tree', $tree);
2083         foreach ($self->get_commit_parents($log_entry)) {
2084                 push @exec, '-p', $_;
2085         }
2086         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2087                                                                    or croak $!;
2088         print $msg_fh $log_entry->{log} or croak $!;
2089         unless ($self->no_metadata) {
2090                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2091                               or croak $!;
2092         }
2093         $msg_fh->flush == 0 or croak $!;
2094         close $msg_fh or croak $!;
2095         chomp(my $commit = do { local $/; <$out_fh> });
2096         close $out_fh or croak $!;
2097         waitpid $pid, 0;
2098         croak $? if $?;
2099         if ($commit !~ /^$::sha1$/o) {
2100                 die "Failed to commit, invalid sha1: $commit\n";
2101         }
2102
2103         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2104
2105         $self->{last_rev} = $log_entry->{revision};
2106         $self->{last_commit} = $commit;
2107         print "r$log_entry->{revision}";
2108         if (defined $log_entry->{svm_revision}) {
2109                  print " (\@$log_entry->{svm_revision})";
2110                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2111                                    0, $self->svm_uuid);
2112         }
2113         print " = $commit ($self->{ref_id})\n";
2114         if (defined $_repack && (--$_repack_nr == 0)) {
2115                 $_repack_nr = $_repack;
2116                 # repack doesn't use any arguments with spaces in them, does it?
2117                 print "Running git repack $_repack_flags ...\n";
2118                 command_noisy('repack', split(/\s+/, $_repack_flags));
2119                 print "Done repacking\n";
2120         }
2121         return $commit;
2122 }
2123
2124 sub match_paths {
2125         my ($self, $paths, $r) = @_;
2126         return 1 if $self->{path} eq '';
2127         if (my $path = $paths->{"/$self->{path}"}) {
2128                 return ($path->{action} eq 'D') ? 0 : 1;
2129         }
2130         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2131         if (grep /$self->{path_regex}/, keys %$paths) {
2132                 return 1;
2133         }
2134         my $c = '';
2135         foreach (split m#/#, $self->{path}) {
2136                 $c .= "/$_";
2137                 next unless ($paths->{$c} &&
2138                              ($paths->{$c}->{action} =~ /^[AR]$/));
2139                 if ($self->ra->check_path($self->{path}, $r) ==
2140                     $SVN::Node::dir) {
2141                         return 1;
2142                 }
2143         }
2144         return 0;
2145 }
2146
2147 sub find_parent_branch {
2148         my ($self, $paths, $rev) = @_;
2149         return undef unless $self->follow_parent;
2150         unless (defined $paths) {
2151                 my $err_handler = $SVN::Error::handler;
2152                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2153                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2154                                    $paths =
2155                                       Git::SVN::Ra::dup_changed_paths($_[0]) });
2156                 $SVN::Error::handler = $err_handler;
2157         }
2158         return undef unless defined $paths;
2159
2160         # look for a parent from another branch:
2161         my @b_path_components = split m#/#, $self->rel_path;
2162         my @a_path_components;
2163         my $i;
2164         while (@b_path_components) {
2165                 $i = $paths->{'/'.join('/', @b_path_components)};
2166                 last if $i && defined $i->{copyfrom_path};
2167                 unshift(@a_path_components, pop(@b_path_components));
2168         }
2169         return undef unless defined $i && defined $i->{copyfrom_path};
2170         my $branch_from = $i->{copyfrom_path};
2171         if (@a_path_components) {
2172                 print STDERR "branch_from: $branch_from => ";
2173                 $branch_from .= '/'.join('/', @a_path_components);
2174                 print STDERR $branch_from, "\n";
2175         }
2176         my $r = $i->{copyfrom_rev};
2177         my $repos_root = $self->ra->{repos_root};
2178         my $url = $self->ra->{url};
2179         my $new_url = $repos_root . $branch_from;
2180         print STDERR  "Found possible branch point: ",
2181                       "$new_url => ", $self->full_url, ", $r\n";
2182         $branch_from =~ s#^/##;
2183         my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2184         unless ($gs) {
2185                 my $ref_id = $self->{ref_id};
2186                 $ref_id =~ s/\@\d+$//;
2187                 $ref_id .= "\@$r";
2188                 # just grow a tail if we're not unique enough :x
2189                 $ref_id .= '-' while find_ref($ref_id);
2190                 print STDERR "Initializing parent: $ref_id\n";
2191                 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
2192         }
2193         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2194         if (!defined $r0 || !defined $parent) {
2195                 my ($base, $head) = parse_revision_argument(0, $r);
2196                 if ($base <= $r) {
2197                         $gs->fetch($base, $r);
2198                 }
2199                 ($r0, $parent) = $gs->last_rev_commit;
2200         }
2201         if (defined $r0 && defined $parent) {
2202                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2203                 my $ed;
2204                 if ($self->ra->can_do_switch) {
2205                         $self->assert_index_clean($parent);
2206                         print STDERR "Following parent with do_switch\n";
2207                         # do_switch works with svn/trunk >= r22312, but that
2208                         # is not included with SVN 1.4.3 (the latest version
2209                         # at the moment), so we can't rely on it
2210                         $self->{last_commit} = $parent;
2211                         $ed = SVN::Git::Fetcher->new($self);
2212                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2213                                               $self->full_url, $ed)
2214                           or die "SVN connection failed somewhere...\n";
2215                 } elsif ($self->ra->trees_match($new_url, $r0,
2216                                                 $self->full_url, $rev)) {
2217                         print STDERR "Trees match:\n",
2218                                      "  $new_url\@$r0\n",
2219                                      "  ${\$self->full_url}\@$rev\n",
2220                                      "Following parent with no changes\n";
2221                         $self->tmp_index_do(sub {
2222                             command_noisy('read-tree', $parent);
2223                         });
2224                         $self->{last_commit} = $parent;
2225                 } else {
2226                         print STDERR "Following parent with do_update\n";
2227                         $ed = SVN::Git::Fetcher->new($self);
2228                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2229                           or die "SVN connection failed somewhere...\n";
2230                 }
2231                 print STDERR "Successfully followed parent\n";
2232                 return $self->make_log_entry($rev, [$parent], $ed);
2233         }
2234         return undef;
2235 }
2236
2237 sub do_fetch {
2238         my ($self, $paths, $rev) = @_;
2239         my $ed;
2240         my ($last_rev, @parents);
2241         if (my $lc = $self->last_commit) {
2242                 # we can have a branch that was deleted, then re-added
2243                 # under the same name but copied from another path, in
2244                 # which case we'll have multiple parents (we don't
2245                 # want to break the original ref, nor lose copypath info):
2246                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2247                         push @{$log_entry->{parents}}, $lc;
2248                         return $log_entry;
2249                 }
2250                 $ed = SVN::Git::Fetcher->new($self);
2251                 $last_rev = $self->{last_rev};
2252                 $ed->{c} = $lc;
2253                 @parents = ($lc);
2254         } else {
2255                 $last_rev = $rev;
2256                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2257                         return $log_entry;
2258                 }
2259                 $ed = SVN::Git::Fetcher->new($self);
2260         }
2261         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2262                 die "SVN connection failed somewhere...\n";
2263         }
2264         $self->make_log_entry($rev, \@parents, $ed);
2265 }
2266
2267 sub get_untracked {
2268         my ($self, $ed) = @_;
2269         my @out;
2270         my $h = $ed->{empty};
2271         foreach (sort keys %$h) {
2272                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2273                 push @out, "  $act: " . uri_encode($_);
2274                 warn "W: $act: $_\n";
2275         }
2276         foreach my $t (qw/dir_prop file_prop/) {
2277                 $h = $ed->{$t} or next;
2278                 foreach my $path (sort keys %$h) {
2279                         my $ppath = $path eq '' ? '.' : $path;
2280                         foreach my $prop (sort keys %{$h->{$path}}) {
2281                                 next if $SKIP_PROP{$prop};
2282                                 my $v = $h->{$path}->{$prop};
2283                                 my $t_ppath_prop = "$t: " .
2284                                                     uri_encode($ppath) . ' ' .
2285                                                     uri_encode($prop);
2286                                 if (defined $v) {
2287                                         push @out, "  +$t_ppath_prop " .
2288                                                    uri_encode($v);
2289                                 } else {
2290                                         push @out, "  -$t_ppath_prop";
2291                                 }
2292                         }
2293                 }
2294         }
2295         foreach my $t (qw/absent_file absent_directory/) {
2296                 $h = $ed->{$t} or next;
2297                 foreach my $parent (sort keys %$h) {
2298                         foreach my $path (sort @{$h->{$parent}}) {
2299                                 push @out, "  $t: " .
2300                                            uri_encode("$parent/$path");
2301                                 warn "W: $t: $parent/$path ",
2302                                      "Insufficient permissions?\n";
2303                         }
2304                 }
2305         }
2306         \@out;
2307 }
2308
2309 sub parse_svn_date {
2310         my $date = shift || return '+0000 1970-01-01 00:00:00';
2311         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2312                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2313                                          croak "Unable to parse date: $date\n";
2314         "+0000 $Y-$m-$d $H:$M:$S";
2315 }
2316
2317 sub check_author {
2318         my ($author) = @_;
2319         if (!defined $author || length $author == 0) {
2320                 $author = '(no author)';
2321         }
2322         if (defined $::_authors && ! defined $::users{$author}) {
2323                 die "Author: $author not defined in $::_authors file\n";
2324         }
2325         $author;
2326 }
2327
2328 sub make_log_entry {
2329         my ($self, $rev, $parents, $ed) = @_;
2330         my $untracked = $self->get_untracked($ed);
2331
2332         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2333         print $un "r$rev\n" or croak $!;
2334         print $un $_, "\n" foreach @$untracked;
2335         my %log_entry = ( parents => $parents || [], revision => $rev,
2336                           log => '');
2337
2338         my $headrev;
2339         my $logged = delete $self->{logged_rev_props};
2340         if (!$logged || $self->{-want_revprops}) {
2341                 my $rp = $self->ra->rev_proplist($rev);
2342                 foreach (sort keys %$rp) {
2343                         my $v = $rp->{$_};
2344                         if (/^svn:(author|date|log)$/) {
2345                                 $log_entry{$1} = $v;
2346                         } elsif ($_ eq 'svm:headrev') {
2347                                 $headrev = $v;
2348                         } else {
2349                                 print $un "  rev_prop: ", uri_encode($_), ' ',
2350                                           uri_encode($v), "\n";
2351                         }
2352                 }
2353         } else {
2354                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2355         }
2356         close $un or croak $!;
2357
2358         $log_entry{date} = parse_svn_date($log_entry{date});
2359         $log_entry{log} .= "\n";
2360         my $author = $log_entry{author} = check_author($log_entry{author});
2361         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2362                                                        : ($author, undef);
2363
2364         my ($commit_name, $commit_email) = ($name, $email);
2365         if ($_use_log_author) {
2366                 if ($log_entry{log} =~ /From:\s+(.*?)\s+<(.*)>\s*\n/) {
2367                         ($name, $email) = ($1, $2);
2368                 } elsif ($log_entry{log} =~
2369                                       /Signed-off-by:\s+(.*?)\s+<(.*)>\s*\n/) {
2370                         ($name, $email) = ($1, $2);
2371                 }
2372         }
2373         if (defined $headrev && $self->use_svm_props) {
2374                 if ($self->rewrite_root) {
2375                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2376                             "options set!\n";
2377                 }
2378                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2379                 # we don't want "SVM: initializing mirror for junk" ...
2380                 return undef if $r == 0;
2381                 my $svm = $self->svm;
2382                 if ($uuid ne $svm->{uuid}) {
2383                         die "UUID mismatch on SVM path:\n",
2384                             "expected: $svm->{uuid}\n",
2385                             "     got: $uuid\n";
2386                 }
2387                 my $full_url = $self->full_url;
2388                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2389                              die "Failed to replace '$svm->{replace}' with ",
2390                                  "'$svm->{source}' in $full_url\n";
2391                 # throw away username for storing in records
2392                 remove_username($full_url);
2393                 $log_entry{metadata} = "$full_url\@$r $uuid";
2394                 $log_entry{svm_revision} = $r;
2395                 $email ||= "$author\@$uuid";
2396                 $commit_email ||= "$author\@$uuid";
2397         } elsif ($self->use_svnsync_props) {
2398                 my $full_url = $self->svnsync->{url};
2399                 $full_url .= "/$self->{path}" if length $self->{path};
2400                 remove_username($full_url);
2401                 my $uuid = $self->svnsync->{uuid};
2402                 $log_entry{metadata} = "$full_url\@$rev $uuid";
2403                 $email ||= "$author\@$uuid";
2404                 $commit_email ||= "$author\@$uuid";
2405         } else {
2406                 my $url = $self->metadata_url;
2407                 remove_username($url);
2408                 $log_entry{metadata} = "$url\@$rev " .
2409                                        $self->ra->get_uuid;
2410                 $email ||= "$author\@" . $self->ra->get_uuid;
2411                 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2412         }
2413         $log_entry{name} = $name;
2414         $log_entry{email} = $email;
2415         $log_entry{commit_name} = $commit_name;
2416         $log_entry{commit_email} = $commit_email;
2417         \%log_entry;
2418 }
2419
2420 sub fetch {
2421         my ($self, $min_rev, $max_rev, @parents) = @_;
2422         my ($last_rev, $last_commit) = $self->last_rev_commit;
2423         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2424         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2425 }
2426
2427 sub set_tree_cb {
2428         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2429         $self->{inject_parents} = { $rev => $tree };
2430         $self->fetch(undef, undef);
2431 }
2432
2433 sub set_tree {
2434         my ($self, $tree) = (shift, shift);
2435         my $log_entry = ::get_commit_entry($tree);
2436         unless ($self->{last_rev}) {
2437                 fatal("Must have an existing revision to commit");
2438         }
2439         my %ed_opts = ( r => $self->{last_rev},
2440                         log => $log_entry->{log},
2441                         ra => $self->ra,
2442                         tree_a => $self->{last_commit},
2443                         tree_b => $tree,
2444                         editor_cb => sub {
2445                                $self->set_tree_cb($log_entry, $tree, @_) },
2446                         svn_path => $self->{path} );
2447         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2448                 print "No changes\nr$self->{last_rev} = $tree\n";
2449         }
2450 }
2451
2452 sub rebuild_from_rev_db {
2453         my ($self, $path) = @_;
2454         my $r = -1;
2455         open my $fh, '<', $path or croak "open: $!";
2456         while (<$fh>) {
2457                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2458                 chomp($_);
2459                 ++$r;
2460                 next if $_ eq ('0' x 40);
2461                 $self->rev_map_set($r, $_);
2462                 print "r$r = $_\n";
2463         }
2464         close $fh or croak "close: $!";
2465         unlink $path or croak "unlink: $!";
2466 }
2467
2468 sub rebuild {
2469         my ($self) = @_;
2470         my $map_path = $self->map_path;
2471         return if (-e $map_path && ! -z $map_path);
2472         return unless ::verify_ref($self->refname.'^0');
2473         if ($self->use_svm_props || $self->no_metadata) {
2474                 my $rev_db = $self->rev_db_path;
2475                 $self->rebuild_from_rev_db($rev_db);
2476                 if ($self->use_svm_props) {
2477                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2478                         $self->rebuild_from_rev_db($svm_rev_db);
2479                 }
2480                 $self->unlink_rev_db_symlink;
2481                 return;
2482         }
2483         print "Rebuilding $map_path ...\n";
2484         my ($log, $ctx) =
2485             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2486                                 $self->refname, '--');
2487         my $full_url = $self->full_url;
2488         remove_username($full_url);
2489         my $svn_uuid = $self->ra_uuid;
2490         my $c;
2491         while (<$log>) {
2492                 if ( m{^commit ($::sha1)$} ) {
2493                         $c = $1;
2494                         next;
2495                 }
2496                 next unless s{^\s*(git-svn-id:)}{$1};
2497                 my ($url, $rev, $uuid) = ::extract_metadata($_);
2498                 remove_username($url);
2499
2500                 # ignore merges (from set-tree)
2501                 next if (!defined $rev || !$uuid);
2502
2503                 # if we merged or otherwise started elsewhere, this is
2504                 # how we break out of it
2505                 if (($uuid ne $svn_uuid) ||
2506                     ($full_url && $url && ($url ne $full_url))) {
2507                         next;
2508                 }
2509
2510                 $self->rev_map_set($rev, $c);
2511                 print "r$rev = $c\n";
2512         }
2513         command_close_pipe($log, $ctx);
2514         print "Done rebuilding $map_path\n";
2515         my $rev_db_path = $self->rev_db_path;
2516         if (-f $self->rev_db_path) {
2517                 unlink $self->rev_db_path or croak "unlink: $!";
2518         }
2519         $self->unlink_rev_db_symlink;
2520 }
2521
2522 # rev_map:
2523 # Tie::File seems to be prone to offset errors if revisions get sparse,
2524 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
2525 # one of my favorite modules is out :<  Next up would be one of the DBM
2526 # modules, but I'm not sure which is most portable...
2527 #
2528 # This is the replacement for the rev_db format, which was too big
2529 # and inefficient for large repositories with a lot of sparse history
2530 # (mainly tags)
2531 #
2532 # The format is this:
2533 #   - 24 bytes for every record,
2534 #     * 4 bytes for the integer representing an SVN revision number
2535 #     * 20 bytes representing the sha1 of a git commit
2536 #   - No empty padding records like the old format
2537 #     (except the last record, which can be overwritten)
2538 #   - new records are written append-only since SVN revision numbers
2539 #     increase monotonically
2540 #   - lookups on SVN revision number are done via a binary search
2541 #   - Piping the file to xxd -c24 is a good way of dumping it for
2542 #     viewing or editing (piped back through xxd -r), should the need
2543 #     ever arise.
2544 #   - The last record can be padding revision with an all-zero sha1
2545 #     This is used to optimize fetch performance when using multiple
2546 #     "fetch" directives in .git/config
2547 #
2548 # These files are disposable unless noMetadata or useSvmProps is set
2549
2550 sub _rev_map_set {
2551         my ($fh, $rev, $commit) = @_;
2552
2553         my $size = (stat($fh))[7];
2554         ($size % 24) == 0 or croak "inconsistent size: $size";
2555
2556         my $wr_offset = 0;
2557         if ($size > 0) {
2558                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2559                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2560                 $read == 24 or croak "read only $read bytes (!= 24)";
2561                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2562                 if ($last_commit eq ('0' x40)) {
2563                         if ($size >= 48) {
2564                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2565                                 $read = sysread($fh, $buf, 24) or
2566                                     croak "read: $!";
2567                                 $read == 24 or
2568                                     croak "read only $read bytes (!= 24)";
2569                                 ($last_rev, $last_commit) =
2570                                     unpack(rev_map_fmt, $buf);
2571                                 if ($last_commit eq ('0' x40)) {
2572                                         croak "inconsistent .rev_map\n";
2573                                 }
2574                         }
2575                         if ($last_rev >= $rev) {
2576                                 croak "last_rev is higher!: $last_rev >= $rev";
2577                         }
2578                         $wr_offset = -24;
2579                 }
2580         }
2581         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2582         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2583           croak "write: $!";
2584 }
2585
2586 sub mkfile {
2587         my ($path) = @_;
2588         unless (-e $path) {
2589                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2590                 mkpath([$dir]) unless -d $dir;
2591                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2592                 close $fh or die "Couldn't close (create) $path: $!\n";
2593         }
2594 }
2595
2596 sub rev_map_set {
2597         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2598         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2599         my $db = $self->map_path($uuid);
2600         my $db_lock = "$db.lock";
2601         my $sig;
2602         if ($update_ref) {
2603                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2604                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2605         }
2606         mkfile($db);
2607
2608         $LOCKFILES{$db_lock} = 1;
2609         my $sync;
2610         # both of these options make our .rev_db file very, very important
2611         # and we can't afford to lose it because rebuild() won't work
2612         if ($self->use_svm_props || $self->no_metadata) {
2613                 $sync = 1;
2614                 copy($db, $db_lock) or die "rev_map_set(@_): ",
2615                                            "Failed to copy: ",
2616                                            "$db => $db_lock ($!)\n";
2617         } else {
2618                 rename $db, $db_lock or die "rev_map_set(@_): ",
2619                                             "Failed to rename: ",
2620                                             "$db => $db_lock ($!)\n";
2621         }
2622
2623         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2624              or croak "Couldn't open $db_lock: $!\n";
2625         _rev_map_set($fh, $rev, $commit);
2626         if ($sync) {
2627                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2628                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2629         }
2630         close $fh or croak $!;
2631         if ($update_ref) {
2632                 $_head = $self;
2633                 command_noisy('update-ref', '-m', "r$rev",
2634                               $self->refname, $commit);
2635         }
2636         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2637                                     "$db_lock => $db ($!)\n";
2638         delete $LOCKFILES{$db_lock};
2639         if ($update_ref) {
2640                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2641                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2642                 kill $sig, $$ if defined $sig;
2643         }
2644 }
2645
2646 # If want_commit, this will return an array of (rev, commit) where
2647 # commit _must_ be a valid commit in the archive.
2648 # Otherwise, it'll return the max revision (whether or not the
2649 # commit is valid or just a 0x40 placeholder).
2650 sub rev_map_max {
2651         my ($self, $want_commit) = @_;
2652         $self->rebuild;
2653         my $map_path = $self->map_path;
2654         stat $map_path or return $want_commit ? (0, undef) : 0;
2655         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2656         my $size = (stat($fh))[7];
2657         ($size % 24) == 0 or croak "inconsistent size: $size";
2658
2659         if ($size == 0) {
2660                 close $fh or croak "close: $!";
2661                 return $want_commit ? (0, undef) : 0;
2662         }
2663
2664         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2665         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2666         my ($r, $c) = unpack(rev_map_fmt, $buf);
2667         if ($want_commit && $c eq ('0' x40)) {
2668                 if ($size < 48) {
2669                         return $want_commit ? (0, undef) : 0;
2670                 }
2671                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2672                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2673                 ($r, $c) = unpack(rev_map_fmt, $buf);
2674                 if ($c eq ('0'x40)) {
2675                         croak "Penultimate record is all-zeroes in $map_path";
2676                 }
2677         }
2678         close $fh or croak "close: $!";
2679         $want_commit ? ($r, $c) : $r;
2680 }
2681
2682 sub rev_map_get {
2683         my ($self, $rev, $uuid) = @_;
2684         my $map_path = $self->map_path($uuid);
2685         return undef unless -e $map_path;
2686
2687         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2688         my $size = (stat($fh))[7];
2689         ($size % 24) == 0 or croak "inconsistent size: $size";
2690
2691         if ($size == 0) {
2692                 close $fh or croak "close: $fh";
2693                 return undef;
2694         }
2695
2696         my ($l, $u) = (0, $size - 24);
2697         my ($r, $c, $buf);
2698
2699         while ($l <= $u) {
2700                 my $i = int(($l/24 + $u/24) / 2) * 24;
2701                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2702                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2703                 my ($r, $c) = unpack('NH40', $buf);
2704
2705                 if ($r < $rev) {
2706                         $l = $i + 24;
2707                 } elsif ($r > $rev) {
2708                         $u = $i - 24;
2709                 } else { # $r == $rev
2710                         close($fh) or croak "close: $!";
2711                         return $c eq ('0' x 40) ? undef : $c;
2712                 }
2713         }
2714         close($fh) or croak "close: $!";
2715         undef;
2716 }
2717
2718 # Finds the first svn revision that exists on (if $eq_ok is true) or
2719 # before $rev for the current branch.  It will not search any lower
2720 # than $min_rev.  Returns the git commit hash and svn revision number
2721 # if found, else (undef, undef).
2722 sub find_rev_before {
2723         my ($self, $rev, $eq_ok, $min_rev) = @_;
2724         --$rev unless $eq_ok;
2725         $min_rev ||= 1;
2726         while ($rev >= $min_rev) {
2727                 if (my $c = $self->rev_map_get($rev)) {
2728                         return ($rev, $c);
2729                 }
2730                 --$rev;
2731         }
2732         return (undef, undef);
2733 }
2734
2735 # Finds the first svn revision that exists on (if $eq_ok is true) or
2736 # after $rev for the current branch.  It will not search any higher
2737 # than $max_rev.  Returns the git commit hash and svn revision number
2738 # if found, else (undef, undef).
2739 sub find_rev_after {
2740         my ($self, $rev, $eq_ok, $max_rev) = @_;
2741         ++$rev unless $eq_ok;
2742         $max_rev ||= $self->rev_map_max;
2743         while ($rev <= $max_rev) {
2744                 if (my $c = $self->rev_map_get($rev)) {
2745                         return ($rev, $c);
2746                 }
2747                 ++$rev;
2748         }
2749         return (undef, undef);
2750 }
2751
2752 sub _new {
2753         my ($class, $repo_id, $ref_id, $path) = @_;
2754         unless (defined $repo_id && length $repo_id) {
2755                 $repo_id = $Git::SVN::default_repo_id;
2756         }
2757         unless (defined $ref_id && length $ref_id) {
2758                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2759         }
2760         $_[1] = $repo_id = sanitize_remote_name($repo_id);
2761         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2762         $_[3] = $path = '' unless (defined $path);
2763         mkpath(["$ENV{GIT_DIR}/svn"]);
2764         bless {
2765                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2766                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2767                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2768 }
2769
2770 # for read-only access of old .rev_db formats
2771 sub unlink_rev_db_symlink {
2772         my ($self) = @_;
2773         my $link = $self->rev_db_path;
2774         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2775         if (-l $link) {
2776                 unlink $link or croak "unlink: $link failed!";
2777         }
2778 }
2779
2780 sub rev_db_path {
2781         my ($self, $uuid) = @_;
2782         my $db_path = $self->map_path($uuid);
2783         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2784             or croak "map_path: $db_path does not contain '/.rev_map.' !";
2785         $db_path;
2786 }
2787
2788 # the new replacement for .rev_db
2789 sub map_path {
2790         my ($self, $uuid) = @_;
2791         $uuid ||= $self->ra_uuid;
2792         "$self->{map_root}.$uuid";
2793 }
2794
2795 sub uri_encode {
2796         my ($f) = @_;
2797         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2798         $f
2799 }
2800
2801 sub remove_username {
2802         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2803 }
2804
2805 package Git::SVN::Prompt;
2806 use strict;
2807 use warnings;
2808 require SVN::Core;
2809 use vars qw/$_no_auth_cache $_username/;
2810
2811 sub simple {
2812         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2813         $may_save = undef if $_no_auth_cache;
2814         $default_username = $_username if defined $_username;
2815         if (defined $default_username && length $default_username) {
2816                 if (defined $realm && length $realm) {
2817                         print STDERR "Authentication realm: $realm\n";
2818                         STDERR->flush;
2819                 }
2820                 $cred->username($default_username);
2821         } else {
2822                 username($cred, $realm, $may_save, $pool);
2823         }
2824         $cred->password(_read_password("Password for '" .
2825                                        $cred->username . "': ", $realm));
2826         $cred->may_save($may_save);
2827         $SVN::_Core::SVN_NO_ERROR;
2828 }
2829
2830 sub ssl_server_trust {
2831         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2832         $may_save = undef if $_no_auth_cache;
2833         print STDERR "Error validating server certificate for '$realm':\n";
2834         {
2835                 no warnings 'once';
2836                 # All variables SVN::Auth::SSL::* are used only once,
2837                 # so we're shutting up Perl warnings about this.
2838                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2839                         print STDERR " - The certificate is not issued ",
2840                             "by a trusted authority. Use the\n",
2841                             "   fingerprint to validate ",
2842                             "the certificate manually!\n";
2843                 }
2844                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2845                         print STDERR " - The certificate hostname ",
2846                             "does not match.\n";
2847                 }
2848                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2849                         print STDERR " - The certificate is not yet valid.\n";
2850                 }
2851                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2852                         print STDERR " - The certificate has expired.\n";
2853                 }
2854                 if ($failures & $SVN::Auth::SSL::OTHER) {
2855                         print STDERR " - The certificate has ",
2856                             "an unknown error.\n";
2857                 }
2858         } # no warnings 'once'
2859         printf STDERR
2860                 "Certificate information:\n".
2861                 " - Hostname: %s\n".
2862                 " - Valid: from %s until %s\n".
2863                 " - Issuer: %s\n".
2864                 " - Fingerprint: %s\n",
2865                 map $cert_info->$_, qw(hostname valid_from valid_until
2866                                        issuer_dname fingerprint);
2867         my $choice;
2868 prompt:
2869         print STDERR $may_save ?
2870               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2871               "(R)eject or accept (t)emporarily? ";
2872         STDERR->flush;
2873         $choice = lc(substr(<STDIN> || 'R', 0, 1));
2874         if ($choice =~ /^t$/i) {
2875                 $cred->may_save(undef);
2876         } elsif ($choice =~ /^r$/i) {
2877                 return -1;
2878         } elsif ($may_save && $choice =~ /^p$/i) {
2879                 $cred->may_save($may_save);
2880         } else {
2881                 goto prompt;
2882         }
2883         $cred->accepted_failures($failures);
2884         $SVN::_Core::SVN_NO_ERROR;
2885 }
2886
2887 sub ssl_client_cert {
2888         my ($cred, $realm, $may_save, $pool) = @_;
2889         $may_save = undef if $_no_auth_cache;
2890         print STDERR "Client certificate filename: ";
2891         STDERR->flush;
2892         chomp(my $filename = <STDIN>);
2893         $cred->cert_file($filename);
2894         $cred->may_save($may_save);
2895         $SVN::_Core::SVN_NO_ERROR;
2896 }
2897
2898 sub ssl_client_cert_pw {
2899         my ($cred, $realm, $may_save, $pool) = @_;
2900         $may_save = undef if $_no_auth_cache;
2901         $cred->password(_read_password("Password: ", $realm));
2902         $cred->may_save($may_save);
2903         $SVN::_Core::SVN_NO_ERROR;
2904 }
2905
2906 sub username {
2907         my ($cred, $realm, $may_save, $pool) = @_;
2908         $may_save = undef if $_no_auth_cache;
2909         if (defined $realm && length $realm) {
2910                 print STDERR "Authentication realm: $realm\n";
2911         }
2912         my $username;
2913         if (defined $_username) {
2914                 $username = $_username;
2915         } else {
2916                 print STDERR "Username: ";
2917                 STDERR->flush;
2918                 chomp($username = <STDIN>);
2919         }
2920         $cred->username($username);
2921         $cred->may_save($may_save);
2922         $SVN::_Core::SVN_NO_ERROR;
2923 }
2924
2925 sub _read_password {
2926         my ($prompt, $realm) = @_;
2927         print STDERR $prompt;
2928         STDERR->flush;
2929         require Term::ReadKey;
2930         Term::ReadKey::ReadMode('noecho');
2931         my $password = '';
2932         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2933                 last if $key =~ /[\012\015]/; # \n\r
2934                 $password .= $key;
2935         }
2936         Term::ReadKey::ReadMode('restore');
2937         print STDERR "\n";
2938         STDERR->flush;
2939         $password;
2940 }
2941
2942 package SVN::Git::Fetcher;
2943 use vars qw/@ISA/;
2944 use strict;
2945 use warnings;
2946 use Carp qw/croak/;
2947 use IO::File qw//;
2948
2949 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2950 sub new {
2951         my ($class, $git_svn) = @_;
2952         my $self = SVN::Delta::Editor->new;
2953         bless $self, $class;
2954         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
2955         $self->{empty} = {};
2956         $self->{dir_prop} = {};
2957         $self->{file_prop} = {};
2958         $self->{absent_dir} = {};
2959         $self->{absent_file} = {};
2960         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
2961         $self;
2962 }
2963
2964 sub set_path_strip {
2965         my ($self, $path) = @_;
2966         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
2967 }
2968
2969 sub open_root {
2970         { path => '' };
2971 }
2972
2973 sub open_directory {
2974         my ($self, $path, $pb, $rev) = @_;
2975         { path => $path };
2976 }
2977
2978 sub git_path {
2979         my ($self, $path) = @_;
2980         if ($self->{path_strip}) {
2981                 $path =~ s!$self->{path_strip}!! or
2982                   die "Failed to strip path '$path' ($self->{path_strip})\n";
2983         }
2984         $path;
2985 }
2986
2987 sub delete_entry {
2988         my ($self, $path, $rev, $pb) = @_;
2989
2990         my $gpath = $self->git_path($path);
2991         return undef if ($gpath eq '');
2992
2993         # remove entire directories.
2994         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
2995                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
2996                                                      -r --name-only -z/,
2997                                                      $self->{c}, '--', $gpath);
2998                 local $/ = "\0";
2999                 while (<$ls>) {
3000                         chomp;
3001                         $self->{gii}->remove($_);
3002                         print "\tD\t$_\n" unless $::_q;
3003                 }
3004                 print "\tD\t$gpath/\n" unless $::_q;
3005                 command_close_pipe($ls, $ctx);
3006                 $self->{empty}->{$path} = 0
3007         } else {
3008                 $self->{gii}->remove($gpath);
3009                 print "\tD\t$gpath\n" unless $::_q;
3010         }
3011         undef;
3012 }
3013
3014 sub open_file {
3015         my ($self, $path, $pb, $rev) = @_;
3016         my $gpath = $self->git_path($path);
3017         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3018                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3019         unless (defined $mode && defined $blob) {
3020                 die "$path was not found in commit $self->{c} (r$rev)\n";
3021         }
3022         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3023           pool => SVN::Pool->new, action => 'M' };
3024 }
3025
3026 sub add_file {
3027         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3028         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3029         delete $self->{empty}->{$dir};
3030         { path => $path, mode_a => 100644, mode_b => 100644,
3031           pool => SVN::Pool->new, action => 'A' };
3032 }
3033
3034 sub add_directory {
3035         my ($self, $path, $cp_path, $cp_rev) = @_;
3036         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3037         delete $self->{empty}->{$dir};
3038         $self->{empty}->{$path} = 1;
3039         { path => $path };
3040 }
3041
3042 sub change_dir_prop {
3043         my ($self, $db, $prop, $value) = @_;
3044         $self->{dir_prop}->{$db->{path}} ||= {};
3045         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3046         undef;
3047 }
3048
3049 sub absent_directory {
3050         my ($self, $path, $pb) = @_;
3051         $self->{absent_dir}->{$pb->{path}} ||= [];
3052         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3053         undef;
3054 }
3055
3056 sub absent_file {
3057         my ($self, $path, $pb) = @_;
3058         $self->{absent_file}->{$pb->{path}} ||= [];
3059         push @{$self->{absent_file}->{$pb->{path}}}, $path;
3060         undef;
3061 }
3062
3063 sub change_file_prop {
3064         my ($self, $fb, $prop, $value) = @_;
3065         if ($prop eq 'svn:executable') {
3066                 if ($fb->{mode_b} != 120000) {
3067                         $fb->{mode_b} = defined $value ? 100755 : 100644;
3068                 }
3069         } elsif ($prop eq 'svn:special') {
3070                 $fb->{mode_b} = defined $value ? 120000 : 100644;
3071         } else {
3072                 $self->{file_prop}->{$fb->{path}} ||= {};
3073                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3074         }
3075         undef;
3076 }
3077
3078 sub apply_textdelta {
3079         my ($self, $fb, $exp) = @_;
3080         my $fh = IO::File->new_tmpfile;
3081         $fh->autoflush(1);
3082         # $fh gets auto-closed() by SVN::TxDelta::apply(),
3083         # (but $base does not,) so dup() it for reading in close_file
3084         open my $dup, '<&', $fh or croak $!;
3085         my $base = IO::File->new_tmpfile;
3086         $base->autoflush(1);
3087         if ($fb->{blob}) {
3088                 defined (my $pid = fork) or croak $!;
3089                 if (!$pid) {
3090                         open STDOUT, '>&', $base or croak $!;
3091                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3092                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3093                 }
3094                 waitpid $pid, 0;
3095                 croak $? if $?;
3096
3097                 if (defined $exp) {
3098                         seek $base, 0, 0 or croak $!;
3099                         my $got = ::md5sum($base);
3100                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3101                             "expected: $exp\n",
3102                             "     got: $got\n" if ($got ne $exp);
3103                 }
3104         }
3105         seek $base, 0, 0 or croak $!;
3106         $fb->{fh} = $dup;
3107         $fb->{base} = $base;
3108         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3109 }
3110
3111 sub close_file {
3112         my ($self, $fb, $exp) = @_;
3113         my $hash;
3114         my $path = $self->git_path($fb->{path});
3115         if (my $fh = $fb->{fh}) {
3116                 if (defined $exp) {
3117                         seek($fh, 0, 0) or croak $!;
3118                         my $got = ::md5sum($fh);
3119                         if ($got ne $exp) {
3120                                 die "Checksum mismatch: $path\n",
3121                                     "expected: $exp\n    got: $got\n";
3122                         }
3123                 }
3124                 sysseek($fh, 0, 0) or croak $!;
3125                 if ($fb->{mode_b} == 120000) {
3126                         sysread($fh, my $buf, 5) == 5 or croak $!;
3127                         $buf eq 'link ' or die "$path has mode 120000",
3128                                                "but is not a link\n";
3129                 }
3130                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3131                 if (!$pid) {
3132                         open STDIN, '<&', $fh or croak $!;
3133                         exec qw/git-hash-object -w --stdin/ or croak $!;
3134                 }
3135                 chomp($hash = do { local $/; <$out> });
3136                 close $out or croak $!;
3137                 close $fh or croak $!;
3138                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3139                 close $fb->{base} or croak $!;
3140         } else {
3141                 $hash = $fb->{blob} or die "no blob information\n";
3142         }
3143         $fb->{pool}->clear;
3144         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3145         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3146         undef;
3147 }
3148
3149 sub abort_edit {
3150         my $self = shift;
3151         $self->{nr} = $self->{gii}->{nr};
3152         delete $self->{gii};
3153         $self->SUPER::abort_edit(@_);
3154 }
3155
3156 sub close_edit {
3157         my $self = shift;
3158         $self->{git_commit_ok} = 1;
3159         $self->{nr} = $self->{gii}->{nr};
3160         delete $self->{gii};
3161         $self->SUPER::close_edit(@_);
3162 }
3163
3164 package SVN::Git::Editor;
3165 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3166 use strict;
3167 use warnings;
3168 use Carp qw/croak/;
3169 use IO::File;
3170
3171 sub new {
3172         my ($class, $opts) = @_;
3173         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3174                 die "$_ required!\n" unless (defined $opts->{$_});
3175         }
3176
3177         my $pool = SVN::Pool->new;
3178         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3179         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3180                                      $opts->{r}, $mods);
3181
3182         # $opts->{ra} functions should not be used after this:
3183         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
3184                                                 $opts->{editor_cb}, $pool);
3185         my $self = SVN::Delta::Editor->new(@ce, $pool);
3186         bless $self, $class;
3187         foreach (qw/svn_path r tree_a tree_b/) {
3188                 $self->{$_} = $opts->{$_};
3189         }
3190         $self->{url} = $opts->{ra}->{url};
3191         $self->{mods} = $mods;
3192         $self->{types} = $types;
3193         $self->{pool} = $pool;
3194         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3195         $self->{rm} = { };
3196         $self->{path_prefix} = length $self->{svn_path} ?
3197                                "$self->{svn_path}/" : '';
3198         return $self;
3199 }
3200
3201 sub generate_diff {
3202         my ($tree_a, $tree_b) = @_;
3203         my @diff_tree = qw(diff-tree -z -r);
3204         if ($_cp_similarity) {
3205                 push @diff_tree, "-C$_cp_similarity";
3206         } else {
3207                 push @diff_tree, '-C';
3208         }
3209         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3210         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3211         push @diff_tree, $tree_a, $tree_b;
3212         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3213         local $/ = "\0";
3214         my $state = 'meta';
3215         my @mods;
3216         while (<$diff_fh>) {
3217                 chomp $_; # this gets rid of the trailing "\0"
3218                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3219                                         $::sha1\s($::sha1)\s
3220                                         ([MTCRAD])\d*$/xo) {
3221                         push @mods, {   mode_a => $1, mode_b => $2,
3222                                         sha1_b => $3, chg => $4 };
3223                         if ($4 =~ /^(?:C|R)$/) {
3224                                 $state = 'file_a';
3225                         } else {
3226                                 $state = 'file_b';
3227                         }
3228                 } elsif ($state eq 'file_a') {
3229                         my $x = $mods[$#mods] or croak "Empty array\n";
3230                         if ($x->{chg} !~ /^(?:C|R)$/) {
3231                                 croak "Error parsing $_, $x->{chg}\n";
3232                         }
3233                         $x->{file_a} = $_;
3234                         $state = 'file_b';
3235                 } elsif ($state eq 'file_b') {
3236                         my $x = $mods[$#mods] or croak "Empty array\n";
3237                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3238                                 croak "Error parsing $_, $x->{chg}\n";
3239                         }
3240                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3241                                 croak "Error parsing $_, $x->{chg}\n";
3242                         }
3243                         $x->{file_b} = $_;
3244                         $state = 'meta';
3245                 } else {
3246                         croak "Error parsing $_\n";
3247                 }
3248         }
3249         command_close_pipe($diff_fh, $ctx);
3250         \@mods;
3251 }
3252
3253 sub check_diff_paths {
3254         my ($ra, $pfx, $rev, $mods) = @_;
3255         my %types;
3256         $pfx .= '/' if length $pfx;
3257
3258         sub type_diff_paths {
3259                 my ($ra, $types, $path, $rev) = @_;
3260                 my @p = split m#/+#, $path;
3261                 my $c = shift @p;
3262                 unless (defined $types->{$c}) {
3263                         $types->{$c} = $ra->check_path($c, $rev);
3264                 }
3265                 while (@p) {
3266                         $c .= '/' . shift @p;
3267                         next if defined $types->{$c};
3268                         $types->{$c} = $ra->check_path($c, $rev);
3269                 }
3270         }
3271
3272         foreach my $m (@$mods) {
3273                 foreach my $f (qw/file_a file_b/) {
3274                         next unless defined $m->{$f};
3275                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3276                         if (length $pfx.$dir && ! defined $types{$dir}) {
3277                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3278                         }
3279                 }
3280         }
3281         \%types;
3282 }
3283
3284 sub split_path {
3285         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3286 }
3287
3288 sub repo_path {
3289         my ($self, $path) = @_;
3290         $self->{path_prefix}.(defined $path ? $path : '');
3291 }
3292
3293 sub url_path {
3294         my ($self, $path) = @_;
3295         if ($self->{url} =~ m#^https?://#) {
3296                 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3297         }
3298         $self->{url} . '/' . $self->repo_path($path);
3299 }
3300
3301 sub rmdirs {
3302         my ($self) = @_;
3303         my $rm = $self->{rm};
3304         delete $rm->{''}; # we never delete the url we're tracking
3305         return unless %$rm;
3306
3307         foreach (keys %$rm) {
3308                 my @d = split m#/#, $_;
3309                 my $c = shift @d;
3310                 $rm->{$c} = 1;
3311                 while (@d) {
3312                         $c .= '/' . shift @d;
3313                         $rm->{$c} = 1;
3314                 }
3315         }
3316         delete $rm->{$self->{svn_path}};
3317         delete $rm->{''}; # we never delete the url we're tracking
3318         return unless %$rm;
3319
3320         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3321                                              $self->{tree_b});
3322         local $/ = "\0";
3323         while (<$fh>) {
3324                 chomp;
3325                 my @dn = split m#/#, $_;
3326                 while (pop @dn) {
3327                         delete $rm->{join '/', @dn};
3328                 }
3329                 unless (%$rm) {
3330                         close $fh;
3331                         return;
3332                 }
3333         }
3334         command_close_pipe($fh, $ctx);
3335
3336         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3337         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3338                 $self->close_directory($bat->{$d}, $p);
3339                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3340                 print "\tD+\t$d/\n" unless $::_q;
3341                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3342                 delete $bat->{$d};
3343         }
3344 }
3345
3346 sub open_or_add_dir {
3347         my ($self, $full_path, $baton) = @_;
3348         my $t = $self->{types}->{$full_path};
3349         if (!defined $t) {
3350                 die "$full_path not known in r$self->{r} or we have a bug!\n";
3351         }
3352         {
3353                 no warnings 'once';
3354                 # SVN::Node::none and SVN::Node::file are used only once,
3355                 # so we're shutting up Perl's warnings about them.
3356                 if ($t == $SVN::Node::none) {
3357                         return $self->add_directory($full_path, $baton,
3358                             undef, -1, $self->{pool});
3359                 } elsif ($t == $SVN::Node::dir) {
3360                         return $self->open_directory($full_path, $baton,
3361                             $self->{r}, $self->{pool});
3362                 } # no warnings 'once'
3363                 print STDERR "$full_path already exists in repository at ",
3364                     "r$self->{r} and it is not a directory (",
3365                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3366         } # no warnings 'once'
3367         exit 1;
3368 }
3369
3370 sub ensure_path {
3371         my ($self, $path) = @_;
3372         my $bat = $self->{bat};
3373         my $repo_path = $self->repo_path($path);
3374         return $bat->{''} unless (length $repo_path);
3375         my @p = split m#/+#, $repo_path;
3376         my $c = shift @p;
3377         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3378         while (@p) {
3379                 my $c0 = $c;
3380                 $c .= '/' . shift @p;
3381                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3382         }
3383         return $bat->{$c};
3384 }
3385
3386 sub A {
3387         my ($self, $m) = @_;
3388         my ($dir, $file) = split_path($m->{file_b});
3389         my $pbat = $self->ensure_path($dir);
3390         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3391                                         undef, -1);
3392         print "\tA\t$m->{file_b}\n" unless $::_q;
3393         $self->chg_file($fbat, $m);
3394         $self->close_file($fbat,undef,$self->{pool});
3395 }
3396
3397 sub C {
3398         my ($self, $m) = @_;
3399         my ($dir, $file) = split_path($m->{file_b});
3400         my $pbat = $self->ensure_path($dir);
3401         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3402                                 $self->url_path($m->{file_a}), $self->{r});
3403         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3404         $self->chg_file($fbat, $m);
3405         $self->close_file($fbat,undef,$self->{pool});
3406 }
3407
3408 sub delete_entry {
3409         my ($self, $path, $pbat) = @_;
3410         my $rpath = $self->repo_path($path);
3411         my ($dir, $file) = split_path($rpath);
3412         $self->{rm}->{$dir} = 1;
3413         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3414 }
3415
3416 sub R {
3417         my ($self, $m) = @_;
3418         my ($dir, $file) = split_path($m->{file_b});
3419         my $pbat = $self->ensure_path($dir);
3420         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3421                                 $self->url_path($m->{file_a}), $self->{r});
3422         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3423         $self->chg_file($fbat, $m);
3424         $self->close_file($fbat,undef,$self->{pool});
3425
3426         ($dir, $file) = split_path($m->{file_a});
3427         $pbat = $self->ensure_path($dir);
3428         $self->delete_entry($m->{file_a}, $pbat);
3429 }
3430
3431 sub M {
3432         my ($self, $m) = @_;
3433         my ($dir, $file) = split_path($m->{file_b});
3434         my $pbat = $self->ensure_path($dir);
3435         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3436                                 $pbat,$self->{r},$self->{pool});
3437         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3438         $self->chg_file($fbat, $m);
3439         $self->close_file($fbat,undef,$self->{pool});
3440 }
3441
3442 sub T { shift->M(@_) }
3443
3444 sub change_file_prop {
3445         my ($self, $fbat, $pname, $pval) = @_;
3446         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3447 }
3448
3449 sub chg_file {
3450         my ($self, $fbat, $m) = @_;
3451         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3452                 $self->change_file_prop($fbat,'svn:executable','*');
3453         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3454                 $self->change_file_prop($fbat,'svn:executable',undef);
3455         }
3456         my $fh = IO::File->new_tmpfile or croak $!;
3457         if ($m->{mode_b} =~ /^120/) {
3458                 print $fh 'link ' or croak $!;
3459                 $self->change_file_prop($fbat,'svn:special','*');
3460         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3461                 $self->change_file_prop($fbat,'svn:special',undef);
3462         }
3463         defined(my $pid = fork) or croak $!;
3464         if (!$pid) {
3465                 open STDOUT, '>&', $fh or croak $!;
3466                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3467         }
3468         waitpid $pid, 0;
3469         croak $? if $?;
3470         $fh->flush == 0 or croak $!;
3471         seek $fh, 0, 0 or croak $!;
3472
3473         my $exp = ::md5sum($fh);
3474         seek $fh, 0, 0 or croak $!;
3475
3476         my $pool = SVN::Pool->new;
3477         my $atd = $self->apply_textdelta($fbat, undef, $pool);
3478         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3479         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3480         $pool->clear;
3481
3482         close $fh or croak $!;
3483 }
3484
3485 sub D {
3486         my ($self, $m) = @_;
3487         my ($dir, $file) = split_path($m->{file_b});
3488         my $pbat = $self->ensure_path($dir);
3489         print "\tD\t$m->{file_b}\n" unless $::_q;
3490         $self->delete_entry($m->{file_b}, $pbat);
3491 }
3492
3493 sub close_edit {
3494         my ($self) = @_;
3495         my ($p,$bat) = ($self->{pool}, $self->{bat});
3496         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3497                 next if $_ eq '';
3498                 $self->close_directory($bat->{$_}, $p);
3499         }
3500         $self->close_directory($bat->{''}, $p);
3501         $self->SUPER::close_edit($p);
3502         $p->clear;
3503 }
3504
3505 sub abort_edit {
3506         my ($self) = @_;
3507         $self->SUPER::abort_edit($self->{pool});
3508 }
3509
3510 sub DESTROY {
3511         my $self = shift;
3512         $self->SUPER::DESTROY(@_);
3513         $self->{pool}->clear;
3514 }
3515
3516 # this drives the editor
3517 sub apply_diff {
3518         my ($self) = @_;
3519         my $mods = $self->{mods};
3520         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3521         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3522                 my $f = $m->{chg};
3523                 if (defined $o{$f}) {
3524                         $self->$f($m);
3525                 } else {
3526                         fatal("Invalid change type: $f");
3527                 }
3528         }
3529         $self->rmdirs if $_rmdir;
3530         if (@$mods == 0) {
3531                 $self->abort_edit;
3532         } else {
3533                 $self->close_edit;
3534         }
3535         return scalar @$mods;
3536 }
3537
3538 package Git::SVN::Ra;
3539 use vars qw/@ISA $config_dir $_log_window_size/;
3540 use strict;
3541 use warnings;
3542 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3543
3544 BEGIN {
3545         # enforce temporary pool usage for some simple functions
3546         no strict 'refs';
3547         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3548                 my $SUPER = "SUPER::$f";
3549                 *$f = sub {
3550                         my $self = shift;
3551                         my $pool = SVN::Pool->new;
3552                         my @ret = $self->$SUPER(@_,$pool);
3553                         $pool->clear;
3554                         wantarray ? @ret : $ret[0];
3555                 };
3556         }
3557 }
3558
3559 sub _auth_providers () {
3560         [
3561           SVN::Client::get_simple_provider(),
3562           SVN::Client::get_ssl_server_trust_file_provider(),
3563           SVN::Client::get_simple_prompt_provider(
3564             \&Git::SVN::Prompt::simple, 2),
3565           SVN::Client::get_ssl_client_cert_file_provider(),
3566           SVN::Client::get_ssl_client_cert_prompt_provider(
3567             \&Git::SVN::Prompt::ssl_client_cert, 2),
3568           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3569             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3570           SVN::Client::get_username_provider(),
3571           SVN::Client::get_ssl_server_trust_prompt_provider(
3572             \&Git::SVN::Prompt::ssl_server_trust),
3573           SVN::Client::get_username_prompt_provider(
3574             \&Git::SVN::Prompt::username, 2)
3575         ]
3576 }
3577
3578 sub escape_uri_only {
3579         my ($uri) = @_;
3580         my @tmp;
3581         foreach (split m{/}, $uri) {
3582                 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3583                 push @tmp, $_;
3584         }
3585         join('/', @tmp);
3586 }
3587
3588 sub escape_url {
3589         my ($url) = @_;
3590         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3591                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3592                 $url = "$scheme://$domain$uri";
3593         }
3594         $url;
3595 }
3596
3597 sub new {
3598         my ($class, $url) = @_;
3599         $url =~ s!/+$!!;
3600         return $RA if ($RA && $RA->{url} eq $url);
3601
3602         SVN::_Core::svn_config_ensure($config_dir, undef);
3603         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3604         my $config = SVN::Core::config_get_config($config_dir);
3605         $RA = undef;
3606         my $dont_store_passwords = 1;
3607         my $conf_t = ${$config}{'config'};
3608         {
3609                 no warnings 'once';
3610                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3611                 # produces warnings that variables are used only once.
3612                 # I had not found the better way to shut them up, so
3613                 # the warnings of type 'once' are disabled in this block.
3614                 if (SVN::_Core::svn_config_get_bool($conf_t,
3615                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3616                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3617                     1) == 0) {
3618                         SVN::_Core::svn_auth_set_parameter($baton,
3619                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3620                             bless (\$dont_store_passwords, "_p_void"));
3621                 }
3622                 if (SVN::_Core::svn_config_get_bool($conf_t,
3623                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3624                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3625                     1) == 0) {
3626                         $Git::SVN::Prompt::_no_auth_cache = 1;
3627                 }
3628         } # no warnings 'once'
3629         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3630                               config => $config,
3631                               pool => SVN::Pool->new,
3632                               auth_provider_callbacks => $callbacks);
3633         $self->{url} = $url;
3634         $self->{svn_path} = $url;
3635         $self->{repos_root} = $self->get_repos_root;
3636         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3637         $self->{cache} = { check_path => { r => 0, data => {} },
3638                            get_dir => { r => 0, data => {} } };
3639         $RA = bless $self, $class;
3640 }
3641
3642 sub check_path {
3643         my ($self, $path, $r) = @_;
3644         my $cache = $self->{cache}->{check_path};
3645         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3646                 return $cache->{data}->{$path};
3647         }
3648         my $pool = SVN::Pool->new;
3649         my $t = $self->SUPER::check_path($path, $r, $pool);
3650         $pool->clear;
3651         if ($r != $cache->{r}) {
3652                 %{$cache->{data}} = ();
3653                 $cache->{r} = $r;
3654         }
3655         $cache->{data}->{$path} = $t;
3656 }
3657
3658 sub get_dir {
3659         my ($self, $dir, $r) = @_;
3660         my $cache = $self->{cache}->{get_dir};
3661         if ($r == $cache->{r}) {
3662                 if (my $x = $cache->{data}->{$dir}) {
3663                         return wantarray ? @$x : $x->[0];
3664                 }
3665         }
3666         my $pool = SVN::Pool->new;
3667         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3668         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3669         $pool->clear;
3670         if ($r != $cache->{r}) {
3671                 %{$cache->{data}} = ();
3672                 $cache->{r} = $r;
3673         }
3674         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3675         wantarray ? (\%dirents, $r, $props) : \%dirents;
3676 }
3677
3678 sub DESTROY {
3679         # do not call the real DESTROY since we store ourselves in $RA
3680 }
3681
3682 sub get_log {
3683         my ($self, @args) = @_;
3684         my $pool = SVN::Pool->new;
3685         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3686         my $ret = $self->SUPER::get_log(@args, $pool);
3687         $pool->clear;
3688         $ret;
3689 }
3690
3691 sub trees_match {
3692         my ($self, $url1, $rev1, $url2, $rev2) = @_;
3693         my $ctx = SVN::Client->new(auth => _auth_providers);
3694         my $out = IO::File->new_tmpfile;
3695
3696         # older SVN (1.1.x) doesn't take $pool as the last parameter for
3697         # $ctx->diff(), so we'll create a default one
3698         my $pool = SVN::Pool->new_default_sub;
3699
3700         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3701         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3702         $out->flush;
3703         my $ret = (($out->stat)[7] == 0);
3704         close $out or croak $!;
3705
3706         $ret;
3707 }
3708
3709 sub get_commit_editor {
3710         my ($self, $log, $cb, $pool) = @_;
3711         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3712         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3713 }
3714
3715 sub gs_do_update {
3716         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3717         my $new = ($rev_a == $rev_b);
3718         my $path = $gs->{path};
3719
3720         if ($new && -e $gs->{index}) {
3721                 unlink $gs->{index} or die
3722                   "Couldn't unlink index: $gs->{index}: $!\n";
3723         }
3724         my $pool = SVN::Pool->new;
3725         $editor->set_path_strip($path);
3726         my (@pc) = split m#/#, $path;
3727         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3728                                         1, $editor, $pool);
3729         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3730
3731         # Since we can't rely on svn_ra_reparent being available, we'll
3732         # just have to do some magic with set_path to make it so
3733         # we only want a partial path.
3734         my $sp = '';
3735         my $final = join('/', @pc);
3736         while (@pc) {
3737                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3738                 $sp .= '/' if length $sp;
3739                 $sp .= shift @pc;
3740         }
3741         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3742
3743         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3744
3745         $reporter->finish_report($pool);
3746         $pool->clear;
3747         $editor->{git_commit_ok};
3748 }
3749
3750 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3751 # svn_ra_reparent didn't work before 1.4)
3752 sub gs_do_switch {
3753         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3754         my $path = $gs->{path};
3755         my $pool = SVN::Pool->new;
3756
3757         my $full_url = $self->{url};
3758         my $old_url = $full_url;
3759         $full_url .= '/' . escape_uri_only($path) if length $path;
3760         my ($ra, $reparented);
3761         if ($old_url ne $full_url) {
3762                 if ($old_url !~ m#^svn(\+ssh)?://#) {
3763                         SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3764                                                   $pool);
3765                         $self->{url} = $full_url;
3766                         $reparented = 1;
3767                 } else {
3768                         $_[0] = undef;
3769                         $self = undef;
3770                         $RA = undef;
3771                         $ra = Git::SVN::Ra->new($full_url);
3772                         $ra_invalid = 1;
3773                 }
3774         }
3775         $ra ||= $self;
3776         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3777         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3778         $reporter->set_path('', $rev_a, 0, @lock, $pool);
3779         $reporter->finish_report($pool);
3780
3781         if ($reparented) {
3782                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3783                 $self->{url} = $old_url;
3784         }
3785
3786         $pool->clear;
3787         $editor->{git_commit_ok};
3788 }
3789
3790 sub longest_common_path {
3791         my ($gsv, $globs) = @_;
3792         my %common;
3793         my $common_max = scalar @$gsv;
3794
3795         foreach my $gs (@$gsv) {
3796                 my @tmp = split m#/#, $gs->{path};
3797                 my $p = '';
3798                 foreach (@tmp) {
3799                         $p .= length($p) ? "/$_" : $_;
3800                         $common{$p} ||= 0;
3801                         $common{$p}++;
3802                 }
3803         }
3804         $globs ||= [];
3805         $common_max += scalar @$globs;
3806         foreach my $glob (@$globs) {
3807                 my @tmp = split m#/#, $glob->{path}->{left};
3808                 my $p = '';
3809                 foreach (@tmp) {
3810                         $p .= length($p) ? "/$_" : $_;
3811                         $common{$p} ||= 0;
3812                         $common{$p}++;
3813                 }
3814         }
3815
3816         my $longest_path = '';
3817         foreach (sort {length $b <=> length $a} keys %common) {
3818                 if ($common{$_} == $common_max) {
3819                         $longest_path = $_;
3820                         last;
3821                 }
3822         }
3823         $longest_path;
3824 }
3825
3826 sub gs_fetch_loop_common {
3827         my ($self, $base, $head, $gsv, $globs) = @_;
3828         return if ($base > $head);
3829         my $inc = $_log_window_size;
3830         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3831         my $longest_path = longest_common_path($gsv, $globs);
3832         my $ra_url = $self->{url};
3833         while (1) {
3834                 my %revs;
3835                 my $err;
3836                 my $err_handler = $SVN::Error::handler;
3837                 $SVN::Error::handler = sub {
3838                         ($err) = @_;
3839                         skip_unknown_revs($err);
3840                 };
3841                 sub _cb {
3842                         my ($paths, $r, $author, $date, $log) = @_;
3843                         [ dup_changed_paths($paths),
3844                           { author => $author, date => $date, log => $log } ];
3845                 }
3846                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3847                                sub { $revs{$_[1]} = _cb(@_) });
3848                 if ($err && $max >= $head) {
3849                         print STDERR "Path '$longest_path' ",
3850                                      "was probably deleted:\n",
3851                                      $err->expanded_message,
3852                                      "\nWill attempt to follow ",
3853                                      "revisions r$min .. r$max ",
3854                                      "committed before the deletion\n";
3855                         my $hi = $max;
3856                         while (--$hi >= $min) {
3857                                 my $ok;
3858                                 $self->get_log([$longest_path], $min, $hi,
3859                                                0, 1, 1, sub {
3860                                                $ok ||= $_[1];
3861                                                $revs{$_[1]} = _cb(@_) });
3862                                 if ($ok) {
3863                                         print STDERR "r$min .. r$ok OK\n";
3864                                         last;
3865                                 }
3866                         }
3867                 }
3868                 $SVN::Error::handler = $err_handler;
3869
3870                 my %exists = map { $_->{path} => $_ } @$gsv;
3871                 foreach my $r (sort {$a <=> $b} keys %revs) {
3872                         my ($paths, $logged) = @{$revs{$r}};
3873
3874                         foreach my $gs ($self->match_globs(\%exists, $paths,
3875                                                            $globs, $r)) {
3876                                 if ($gs->rev_map_max >= $r) {
3877                                         next;
3878                                 }
3879                                 next unless $gs->match_paths($paths, $r);
3880                                 $gs->{logged_rev_props} = $logged;
3881                                 if (my $last_commit = $gs->last_commit) {
3882                                         $gs->assert_index_clean($last_commit);
3883                                 }
3884                                 my $log_entry = $gs->do_fetch($paths, $r);
3885                                 if ($log_entry) {
3886                                         $gs->do_git_commit($log_entry);
3887                                 }
3888                         }
3889                         foreach my $g (@$globs) {
3890                                 my $k = "svn-remote.$g->{remote}." .
3891                                         "$g->{t}-maxRev";
3892                                 Git::SVN::tmp_config($k, $r);
3893                         }
3894                         if ($ra_invalid) {
3895                                 $_[0] = undef;
3896                                 $self = undef;
3897                                 $RA = undef;
3898                                 $self = Git::SVN::Ra->new($ra_url);
3899                                 $ra_invalid = undef;
3900                         }
3901                 }
3902                 # pre-fill the .rev_db since it'll eventually get filled in
3903                 # with '0' x40 if something new gets committed
3904                 foreach my $gs (@$gsv) {
3905                         next if $gs->rev_map_max >= $max;
3906                         next if defined $gs->rev_map_get($max);
3907                         $gs->rev_map_set($max, 0 x40);
3908                 }
3909                 foreach my $g (@$globs) {
3910                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3911                         Git::SVN::tmp_config($k, $max);
3912                 }
3913                 last if $max >= $head;
3914                 $min = $max + 1;
3915                 $max += $inc;
3916                 $max = $head if ($max > $head);
3917         }
3918 }
3919
3920 sub match_globs {
3921         my ($self, $exists, $paths, $globs, $r) = @_;
3922
3923         sub get_dir_check {
3924                 my ($self, $exists, $g, $r) = @_;
3925                 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
3926                 return unless scalar @x == 3;
3927                 my $dirents = $x[0];
3928                 foreach my $de (keys %$dirents) {
3929                         next if $dirents->{$de}->{kind} != $SVN::Node::dir;
3930                         my $p = $g->{path}->full_path($de);
3931                         next if $exists->{$p};
3932                         next if (length $g->{path}->{right} &&
3933                                  ($self->check_path($p, $r) !=
3934                                   $SVN::Node::dir));
3935                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
3936                                          $g->{ref}->full_path($de), 1);
3937                 }
3938         }
3939         foreach my $g (@$globs) {
3940                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
3941                         if ($path->{action} =~ /^[AR]$/) {
3942                                 get_dir_check($self, $exists, $g, $r);
3943                         }
3944                 }
3945                 foreach (keys %$paths) {
3946                         if (/$g->{path}->{left_regex}/ &&
3947                             !/$g->{path}->{regex}/) {
3948                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
3949                                 get_dir_check($self, $exists, $g, $r);
3950                         }
3951                         next unless /$g->{path}->{regex}/;
3952                         my $p = $1;
3953                         my $pathname = $g->{path}->full_path($p);
3954                         next if $exists->{$pathname};
3955                         next if ($self->check_path($pathname, $r) !=
3956                                  $SVN::Node::dir);
3957                         $exists->{$pathname} = Git::SVN->init(
3958                                               $self->{url}, $pathname, undef,
3959                                               $g->{ref}->full_path($p), 1);
3960                 }
3961                 my $c = '';
3962                 foreach (split m#/#, $g->{path}->{left}) {
3963                         $c .= "/$_";
3964                         next unless ($paths->{$c} &&
3965                                      ($paths->{$c}->{action} =~ /^[AR]$/));
3966                         get_dir_check($self, $exists, $g, $r);
3967                 }
3968         }
3969         values %$exists;
3970 }
3971
3972 sub minimize_url {
3973         my ($self) = @_;
3974         return $self->{url} if ($self->{url} eq $self->{repos_root});
3975         my $url = $self->{repos_root};
3976         my @components = split(m!/!, $self->{svn_path});
3977         my $c = '';
3978         do {
3979                 $url .= "/$c" if length $c;
3980                 eval { (ref $self)->new($url)->get_latest_revnum };
3981         } while ($@ && ($c = shift @components));
3982         $url;
3983 }
3984
3985 sub can_do_switch {
3986         my $self = shift;
3987         unless (defined $can_do_switch) {
3988                 my $pool = SVN::Pool->new;
3989                 my $rep = eval {
3990                         $self->do_switch(1, '', 0, $self->{url},
3991                                          SVN::Delta::Editor->new, $pool);
3992                 };
3993                 if ($@) {
3994                         $can_do_switch = 0;
3995                 } else {
3996                         $rep->abort_report($pool);
3997                         $can_do_switch = 1;
3998                 }
3999                 $pool->clear;
4000         }
4001         $can_do_switch;
4002 }
4003
4004 sub skip_unknown_revs {
4005         my ($err) = @_;
4006         my $errno = $err->apr_err();
4007         # Maybe the branch we're tracking didn't
4008         # exist when the repo started, so it's
4009         # not an error if it doesn't, just continue
4010         #
4011         # Wonderfully consistent library, eh?
4012         # 160013 - svn:// and file://
4013         # 175002 - http(s)://
4014         # 175007 - http(s):// (this repo required authorization, too...)
4015         #   More codes may be discovered later...
4016         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4017                 my $err_key = $err->expanded_message;
4018                 # revision numbers change every time, filter them out
4019                 $err_key =~ s/\d+/\0/g;
4020                 $err_key = "$errno\0$err_key";
4021                 unless ($ignored_err{$err_key}) {
4022                         warn "W: Ignoring error from SVN, path probably ",
4023                              "does not exist: ($errno): ",
4024                              $err->expanded_message,"\n";
4025                         $ignored_err{$err_key} = 1;
4026                 }
4027                 return;
4028         }
4029         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4030 }
4031
4032 # svn_log_changed_path_t objects passed to get_log are likely to be
4033 # overwritten even if only the refs are copied to an external variable,
4034 # so we should dup the structures in their entirety.  Using an externally
4035 # passed pool (instead of our temporary and quickly cleared pool in
4036 # Git::SVN::Ra) does not help matters at all...
4037 sub dup_changed_paths {
4038         my ($paths) = @_;
4039         return undef unless $paths;
4040         my %ret;
4041         foreach my $p (keys %$paths) {
4042                 my $i = $paths->{$p};
4043                 my %s = map { $_ => $i->$_ }
4044                               qw/copyfrom_path copyfrom_rev action/;
4045                 $ret{$p} = \%s;
4046         }
4047         \%ret;
4048 }
4049
4050 package Git::SVN::Log;
4051 use strict;
4052 use warnings;
4053 use POSIX qw/strftime/;
4054 use constant commit_log_separator => ('-' x 72) . "\n";
4055 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4056             %rusers $show_commit $incremental/;
4057 my $l_fmt;
4058
4059 sub cmt_showable {
4060         my ($c) = @_;
4061         return 1 if defined $c->{r};
4062
4063         # big commit message got truncated by the 16k pretty buffer in rev-list
4064         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4065                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4066                 @{$c->{l}} = ();
4067                 my @log = command(qw/cat-file commit/, $c->{c});
4068
4069                 # shift off the headers
4070                 shift @log while ($log[0] ne '');
4071                 shift @log;
4072
4073                 # TODO: make $c->{l} not have a trailing newline in the future
4074                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4075
4076                 (undef, $c->{r}, undef) = ::extract_metadata(
4077                                 (grep(/^git-svn-id: /, @log))[-1]);
4078         }
4079         return defined $c->{r};
4080 }
4081
4082 sub log_use_color {
4083         return $color || Git->repository->get_colorbool('color.diff');
4084 }
4085
4086 sub git_svn_log_cmd {
4087         my ($r_min, $r_max, @args) = @_;
4088         my $head = 'HEAD';
4089         my (@files, @log_opts);
4090         foreach my $x (@args) {
4091                 if ($x eq '--' || @files) {
4092                         push @files, $x;
4093                 } else {
4094                         if (::verify_ref("$x^0")) {
4095                                 $head = $x;
4096                         } else {
4097                                 push @log_opts, $x;
4098                         }
4099                 }
4100         }
4101
4102         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4103         $gs ||= Git::SVN->_new;
4104         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4105                    $gs->refname);
4106         push @cmd, '-r' unless $non_recursive;
4107         push @cmd, qw/--raw --name-status/ if $verbose;
4108         push @cmd, '--color' if log_use_color();
4109         push @cmd, @log_opts;
4110         if (defined $r_max && $r_max == $r_min) {
4111                 push @cmd, '--max-count=1';
4112                 if (my $c = $gs->rev_map_get($r_max)) {
4113                         push @cmd, $c;
4114                 }
4115         } elsif (defined $r_max) {
4116                 if ($r_max < $r_min) {
4117                         ($r_min, $r_max) = ($r_max, $r_min);
4118                 }
4119                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4120                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4121                 # If there are no commits in the range, both $c_max and $c_min
4122                 # will be undefined.  If there is at least 1 commit in the
4123                 # range, both will be defined.
4124                 return () if !defined $c_min || !defined $c_max;
4125                 if ($c_min eq $c_max) {
4126                         push @cmd, '--max-count=1', $c_min;
4127                 } else {
4128                         push @cmd, '--boundary', "$c_min..$c_max";
4129                 }
4130         }
4131         return (@cmd, @files);
4132 }
4133
4134 # adapted from pager.c
4135 sub config_pager {
4136         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4137         if (!defined $pager) {
4138                 $pager = 'less';
4139         } elsif (length $pager == 0 || $pager eq 'cat') {
4140                 $pager = undef;
4141         }
4142         $ENV{GIT_PAGER_IN_USE} = defined($pager);
4143 }
4144
4145 sub run_pager {
4146         return unless -t *STDOUT && defined $pager;
4147         pipe my $rfd, my $wfd or return;
4148         defined(my $pid = fork) or ::fatal "Can't fork: $!";
4149         if (!$pid) {
4150                 open STDOUT, '>&', $wfd or
4151                                      ::fatal "Can't redirect to stdout: $!";
4152                 return;
4153         }
4154         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4155         $ENV{LESS} ||= 'FRSX';
4156         exec $pager or ::fatal "Can't run pager: $! ($pager)";
4157 }
4158
4159 sub format_svn_date {
4160         return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4161 }
4162
4163 sub parse_git_date {
4164         my ($t, $tz) = @_;
4165         # Date::Parse isn't in the standard Perl distro :(
4166         if ($tz =~ s/^\+//) {
4167                 $t += tz_to_s_offset($tz);
4168         } elsif ($tz =~ s/^\-//) {
4169                 $t -= tz_to_s_offset($tz);
4170         }
4171         return $t;
4172 }
4173
4174 sub set_local_timezone {
4175         if (defined $TZ) {
4176                 $ENV{TZ} = $TZ;
4177         } else {
4178                 delete $ENV{TZ};
4179         }
4180 }
4181
4182 sub tz_to_s_offset {
4183         my ($tz) = @_;
4184         $tz =~ s/(\d\d)$//;
4185         return ($1 * 60) + ($tz * 3600);
4186 }
4187
4188 sub get_author_info {
4189         my ($dest, $author, $t, $tz) = @_;
4190         $author =~ s/(?:^\s*|\s*$)//g;
4191         $dest->{a_raw} = $author;
4192         my $au;
4193         if ($::_authors) {
4194                 $au = $rusers{$author} || undef;
4195         }
4196         if (!$au) {
4197                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4198         }
4199         $dest->{t} = $t;
4200         $dest->{tz} = $tz;
4201         $dest->{a} = $au;
4202         $dest->{t_utc} = parse_git_date($t, $tz);
4203 }
4204
4205 sub process_commit {
4206         my ($c, $r_min, $r_max, $defer) = @_;
4207         if (defined $r_min && defined $r_max) {
4208                 if ($r_min == $c->{r} && $r_min == $r_max) {
4209                         show_commit($c);
4210                         return 0;
4211                 }
4212                 return 1 if $r_min == $r_max;
4213                 if ($r_min < $r_max) {
4214                         # we need to reverse the print order
4215                         return 0 if (defined $limit && --$limit < 0);
4216                         push @$defer, $c;
4217                         return 1;
4218                 }
4219                 if ($r_min != $r_max) {
4220                         return 1 if ($r_min < $c->{r});
4221                         return 1 if ($r_max > $c->{r});
4222                 }
4223         }
4224         return 0 if (defined $limit && --$limit < 0);
4225         show_commit($c);
4226         return 1;
4227 }
4228
4229 sub show_commit {
4230         my $c = shift;
4231         if ($oneline) {
4232                 my $x = "\n";
4233                 if (my $l = $c->{l}) {
4234                         while ($l->[0] =~ /^\s*$/) { shift @$l }
4235                         $x = $l->[0];
4236                 }
4237                 $l_fmt ||= 'A' . length($c->{r});
4238                 print 'r',pack($l_fmt, $c->{r}),' | ';
4239                 print "$c->{c} | " if $show_commit;
4240                 print $x;
4241         } else {
4242                 show_commit_normal($c);
4243         }
4244 }
4245
4246 sub show_commit_changed_paths {
4247         my ($c) = @_;
4248         return unless $c->{changed};
4249         print "Changed paths:\n", @{$c->{changed}};
4250 }
4251
4252 sub show_commit_normal {
4253         my ($c) = @_;
4254         print commit_log_separator, "r$c->{r} | ";
4255         print "$c->{c} | " if $show_commit;
4256         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4257         my $nr_line = 0;
4258
4259         if (my $l = $c->{l}) {
4260                 while ($l->[$#$l] eq "\n" && $#$l > 0
4261                                           && $l->[($#$l - 1)] eq "\n") {
4262                         pop @$l;
4263                 }
4264                 $nr_line = scalar @$l;
4265                 if (!$nr_line) {
4266                         print "1 line\n\n\n";
4267                 } else {
4268                         if ($nr_line == 1) {
4269                                 $nr_line = '1 line';
4270                         } else {
4271                                 $nr_line .= ' lines';
4272                         }
4273                         print $nr_line, "\n";
4274                         show_commit_changed_paths($c);
4275                         print "\n";
4276                         print $_ foreach @$l;
4277                 }
4278         } else {
4279                 print "1 line\n";
4280                 show_commit_changed_paths($c);
4281                 print "\n";
4282
4283         }
4284         foreach my $x (qw/raw stat diff/) {
4285                 if ($c->{$x}) {
4286                         print "\n";
4287                         print $_ foreach @{$c->{$x}}
4288                 }
4289         }
4290 }
4291
4292 sub cmd_show_log {
4293         my (@args) = @_;
4294         my ($r_min, $r_max);
4295         my $r_last = -1; # prevent dupes
4296         set_local_timezone();
4297         if (defined $::_revision) {
4298                 if ($::_revision =~ /^(\d+):(\d+)$/) {
4299                         ($r_min, $r_max) = ($1, $2);
4300                 } elsif ($::_revision =~ /^\d+$/) {
4301                         $r_min = $r_max = $::_revision;
4302                 } else {
4303                         ::fatal "-r$::_revision is not supported, use ",
4304                                 "standard 'git log' arguments instead";
4305                 }
4306         }
4307
4308         config_pager();
4309         @args = git_svn_log_cmd($r_min, $r_max, @args);
4310         if (!@args) {
4311                 print commit_log_separator unless $incremental || $oneline;
4312                 return;
4313         }
4314         my $log = command_output_pipe(@args);
4315         run_pager();
4316         my (@k, $c, $d, $stat);
4317         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4318         while (<$log>) {
4319                 if (/^${esc_color}commit -?($::sha1_short)/o) {
4320                         my $cmt = $1;
4321                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4322                                 $r_last = $c->{r};
4323                                 process_commit($c, $r_min, $r_max, \@k) or
4324                                                                 goto out;
4325                         }
4326                         $d = undef;
4327                         $c = { c => $cmt };
4328                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4329                         get_author_info($c, $1, $2, $3);
4330                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4331                         # ignore
4332                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4333                         push @{$c->{raw}}, $_;
4334                 } elsif (/^${esc_color}[ACRMDT]\t/) {
4335                         # we could add $SVN->{svn_path} here, but that requires
4336                         # remote access at the moment (repo_path_split)...
4337                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
4338                         push @{$c->{changed}}, $_;
4339                 } elsif (/^${esc_color}diff /o) {
4340                         $d = 1;
4341                         push @{$c->{diff}}, $_;
4342                 } elsif ($d) {
4343                         push @{$c->{diff}}, $_;
4344                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4345                           $esc_color*[\+\-]*$esc_color$/x) {
4346                         $stat = 1;
4347                         push @{$c->{stat}}, $_;
4348                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4349                         push @{$c->{stat}}, $_;
4350                         $stat = undef;
4351                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
4352                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4353                 } elsif (s/^${esc_color}    //o) {
4354                         push @{$c->{l}}, $_;
4355                 }
4356         }
4357         if ($c && defined $c->{r} && $c->{r} != $r_last) {
4358                 $r_last = $c->{r};
4359                 process_commit($c, $r_min, $r_max, \@k);
4360         }
4361         if (@k) {
4362                 ($r_min, $r_max) = ($r_max, $r_min);
4363                 process_commit($_, $r_min, $r_max) foreach reverse @k;
4364         }
4365 out:
4366         close $log;
4367         print commit_log_separator unless $incremental || $oneline;
4368 }
4369
4370 package Git::SVN::Migration;
4371 # these version numbers do NOT correspond to actual version numbers
4372 # of git nor git-svn.  They are just relative.
4373 #
4374 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4375 #
4376 # v1 layout: .git/$id/info/url, refs/remotes/$id
4377 #
4378 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4379 #
4380 # v3 layout: .git/svn/$id, refs/remotes/$id
4381 #            - info/url may remain for backwards compatibility
4382 #            - this is what we migrate up to this layout automatically,
4383 #            - this will be used by git svn init on single branches
4384 # v3.1 layout (auto migrated):
4385 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4386 #              for backwards compatibility
4387 #
4388 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4389 #            - this is only created for newly multi-init-ed
4390 #              repositories.  Similar in spirit to the
4391 #              --use-separate-remotes option in git-clone (now default)
4392 #            - we do not automatically migrate to this (following
4393 #              the example set by core git)
4394 #
4395 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4396 #            - newer, more-efficient format that uses 24-bytes per record
4397 #              with no filler space.
4398 #            - use xxd -c24 < .rev_map.$UUID to view and debug
4399 #            - This is a one-way migration, repositories updated to the
4400 #              new format will not be able to use old git-svn without
4401 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
4402 #              possible if noMetadata or useSvmProps are set; but should
4403 #              be no problem for users that use the (sensible) defaults.
4404 use strict;
4405 use warnings;
4406 use Carp qw/croak/;
4407 use File::Path qw/mkpath/;
4408 use File::Basename qw/dirname basename/;
4409 use vars qw/$_minimize/;
4410
4411 sub migrate_from_v0 {
4412         my $git_dir = $ENV{GIT_DIR};
4413         return undef unless -d $git_dir;
4414         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4415         my $migrated = 0;
4416         while (<$fh>) {
4417                 chomp;
4418                 my ($id, $orig_ref) = ($_, $_);
4419                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4420                 next unless -f "$git_dir/$id/info/url";
4421                 my $new_ref = "refs/remotes/$id";
4422                 if (::verify_ref("$new_ref^0")) {
4423                         print STDERR "W: $orig_ref is probably an old ",
4424                                      "branch used by an ancient version of ",
4425                                      "git-svn.\n",
4426                                      "However, $new_ref also exists.\n",
4427                                      "We will not be able ",
4428                                      "to use this branch until this ",
4429                                      "ambiguity is resolved.\n";
4430                         next;
4431                 }
4432                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4433                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4434                 command_noisy('update-ref', $new_ref, $orig_ref);
4435                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4436                 $migrated++;
4437         }
4438         command_close_pipe($fh, $ctx);
4439         print STDERR "Done migrating from v0 layout...\n" if $migrated;
4440         $migrated;
4441 }
4442
4443 sub migrate_from_v1 {
4444         my $git_dir = $ENV{GIT_DIR};
4445         my $migrated = 0;
4446         return $migrated unless -d $git_dir;
4447         my $svn_dir = "$git_dir/svn";
4448
4449         # just in case somebody used 'svn' as their $id at some point...
4450         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4451
4452         print STDERR "Migrating from a git-svn v1 layout...\n";
4453         mkpath([$svn_dir]);
4454         print STDERR "Data from a previous version of git-svn exists, but\n\t",
4455                      "$svn_dir\n\t(required for this version ",
4456                      "($::VERSION) of git-svn) does not. exist\n";
4457         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4458         while (<$fh>) {
4459                 my $x = $_;
4460                 next unless $x =~ s#^refs/remotes/##;
4461                 chomp $x;
4462                 next unless -f "$git_dir/$x/info/url";
4463                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4464                 next unless $u;
4465                 my $dn = dirname("$git_dir/svn/$x");
4466                 mkpath([$dn]) unless -d $dn;
4467                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4468                         mkpath(["$git_dir/svn/svn"]);
4469                         print STDERR " - $git_dir/$x/info => ",
4470                                         "$git_dir/svn/$x/info\n";
4471                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4472                                croak "$!: $x";
4473                         # don't worry too much about these, they probably
4474                         # don't exist with repos this old (save for index,
4475                         # and we can easily regenerate that)
4476                         foreach my $f (qw/unhandled.log index .rev_db/) {
4477                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4478                         }
4479                 } else {
4480                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4481                         rename "$git_dir/$x", "$git_dir/svn/$x" or
4482                                croak "$!: $x";
4483                 }
4484                 $migrated++;
4485         }
4486         command_close_pipe($fh, $ctx);
4487         print STDERR "Done migrating from a git-svn v1 layout\n";
4488         $migrated;
4489 }
4490
4491 sub read_old_urls {
4492         my ($l_map, $pfx, $path) = @_;
4493         my @dir;
4494         foreach (<$path/*>) {
4495                 if (-r "$_/info/url") {
4496                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4497                         my $ref_id = $pfx . basename $_;
4498                         my $url = ::file_to_s("$_/info/url");
4499                         $l_map->{$ref_id} = $url;
4500                 } elsif (-d $_) {
4501                         push @dir, $_;
4502                 }
4503         }
4504         foreach (@dir) {
4505                 my $x = $_;
4506                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4507                 read_old_urls($l_map, $x, $_);
4508         }
4509 }
4510
4511 sub migrate_from_v2 {
4512         my @cfg = command(qw/config -l/);
4513         return if grep /^svn-remote\..+\.url=/, @cfg;
4514         my %l_map;
4515         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4516         my $migrated = 0;
4517
4518         foreach my $ref_id (sort keys %l_map) {
4519                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4520                 if ($@) {
4521                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4522                 }
4523                 $migrated++;
4524         }
4525         $migrated;
4526 }
4527
4528 sub minimize_connections {
4529         my $r = Git::SVN::read_all_remotes();
4530         my $new_urls = {};
4531         my $root_repos = {};
4532         foreach my $repo_id (keys %$r) {
4533                 my $url = $r->{$repo_id}->{url} or next;
4534                 my $fetch = $r->{$repo_id}->{fetch} or next;
4535                 my $ra = Git::SVN::Ra->new($url);
4536
4537                 # skip existing cases where we already connect to the root
4538                 if (($ra->{url} eq $ra->{repos_root}) ||
4539                     (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4540                      $repo_id)) {
4541                         $root_repos->{$ra->{url}} = $repo_id;
4542                         next;
4543                 }
4544
4545                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4546                 my $root_path = $ra->{url};
4547                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4548                 foreach my $path (keys %$fetch) {
4549                         my $ref_id = $fetch->{$path};
4550                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4551
4552                         # make sure we can read when connecting to
4553                         # a higher level of a repository
4554                         my ($last_rev, undef) = $gs->last_rev_commit;
4555                         if (!defined $last_rev) {
4556                                 $last_rev = eval {
4557                                         $root_ra->get_latest_revnum;
4558                                 };
4559                                 next if $@;
4560                         }
4561                         my $new = $root_path;
4562                         $new .= length $path ? "/$path" : '';
4563                         eval {
4564                                 $root_ra->get_log([$new], $last_rev, $last_rev,
4565                                                   0, 0, 1, sub { });
4566                         };
4567                         next if $@;
4568                         $new_urls->{$ra->{repos_root}}->{$new} =
4569                                 { ref_id => $ref_id,
4570                                   old_repo_id => $repo_id,
4571                                   old_path => $path };
4572                 }
4573         }
4574
4575         my @emptied;
4576         foreach my $url (keys %$new_urls) {
4577                 # see if we can re-use an existing [svn-remote "repo_id"]
4578                 # instead of creating a(n ugly) new section:
4579                 my $repo_id = $root_repos->{$url} ||
4580                               Git::SVN::sanitize_remote_name($url);
4581
4582                 my $fetch = $new_urls->{$url};
4583                 foreach my $path (keys %$fetch) {
4584                         my $x = $fetch->{$path};
4585                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4586                         my $pfx = "svn-remote.$x->{old_repo_id}";
4587
4588                         my $old_fetch = quotemeta("$x->{old_path}:".
4589                                                   "refs/remotes/$x->{ref_id}");
4590                         command_noisy(qw/config --unset/,
4591                                       "$pfx.fetch", '^'. $old_fetch . '$');
4592                         delete $r->{$x->{old_repo_id}}->
4593                                {fetch}->{$x->{old_path}};
4594                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4595                                 command_noisy(qw/config --unset/,
4596                                               "$pfx.url");
4597                                 push @emptied, $x->{old_repo_id}
4598                         }
4599                 }
4600         }
4601         if (@emptied) {
4602                 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4603                            "$ENV{GIT_DIR}/config";
4604                 print STDERR <<EOF;
4605 The following [svn-remote] sections in your config file ($file) are empty
4606 and can be safely removed:
4607 EOF
4608                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4609         }
4610 }
4611
4612 sub migration_check {
4613         migrate_from_v0();
4614         migrate_from_v1();
4615         migrate_from_v2();
4616         minimize_connections() if $_minimize;
4617 }
4618
4619 package Git::IndexInfo;
4620 use strict;
4621 use warnings;
4622 use Git qw/command_input_pipe command_close_pipe/;
4623
4624 sub new {
4625         my ($class) = @_;
4626         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4627         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4628 }
4629
4630 sub remove {
4631         my ($self, $path) = @_;
4632         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4633                 return ++$self->{nr};
4634         }
4635         undef;
4636 }
4637
4638 sub update {
4639         my ($self, $mode, $hash, $path) = @_;
4640         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4641                 return ++$self->{nr};
4642         }
4643         undef;
4644 }
4645
4646 sub DESTROY {
4647         my ($self) = @_;
4648         command_close_pipe($self->{gui}, $self->{ctx});
4649 }
4650
4651 package Git::SVN::GlobSpec;
4652 use strict;
4653 use warnings;
4654
4655 sub new {
4656         my ($class, $glob) = @_;
4657         my $re = $glob;
4658         $re =~ s!/+$!!g; # no need for trailing slashes
4659         my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4660         my ($left, $right) = ($1, $2);
4661         if ($nr > 1) {
4662                 die "Only one '*' wildcard expansion ",
4663                     "is supported (got $nr): '$glob'\n";
4664         } elsif ($nr == 0) {
4665                 die "One '*' is needed for glob: '$glob'\n";
4666         }
4667         $re = quotemeta($left) . $re . quotemeta($right);
4668         if (length $left && !($left =~ s!/+$!!g)) {
4669                 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4670         }
4671         if (length $right && !($right =~ s!^/+!!g)) {
4672                 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4673         }
4674         my $left_re = qr/^\/\Q$left\E(\/|$)/;
4675         bless { left => $left, right => $right, left_regex => $left_re,
4676                 regex => qr/$re/, glob => $glob }, $class;
4677 }
4678
4679 sub full_path {
4680         my ($self, $path) = @_;
4681         return (length $self->{left} ? "$self->{left}/" : '') .
4682                $path . (length $self->{right} ? "/$self->{right}" : '');
4683 }
4684
4685 __END__
4686
4687 Data structures:
4688
4689
4690 $remotes = { # returned by read_all_remotes()
4691         'svn' => {
4692                 # svn-remote.svn.url=https://svn.musicpd.org
4693                 url => 'https://svn.musicpd.org',
4694                 # svn-remote.svn.fetch=mpd/trunk:trunk
4695                 fetch => {
4696                         'mpd/trunk' => 'trunk',
4697                 },
4698                 # svn-remote.svn.tags=mpd/tags/*:tags/*
4699                 tags => {
4700                         path => {
4701                                 left => 'mpd/tags',
4702                                 right => '',
4703                                 regex => qr!mpd/tags/([^/]+)$!,
4704                                 glob => 'tags/*',
4705                         },
4706                         ref => {
4707                                 left => 'tags',
4708                                 right => '',
4709                                 regex => qr!tags/([^/]+)$!,
4710                                 glob => 'tags/*',
4711                         },
4712                 }
4713         }
4714 };
4715
4716 $log_entry hashref as returned by libsvn_log_entry()
4717 {
4718         log => 'whitespace-formatted log entry
4719 ',                                              # trailing newline is preserved
4720         revision => '8',                        # integer
4721         date => '2004-02-24T17:01:44.108345Z',  # commit date
4722         author => 'committer name'
4723 };
4724
4725
4726 # this is generated by generate_diff();
4727 @mods = array of diff-index line hashes, each element represents one line
4728         of diff-index output
4729
4730 diff-index line ($m hash)
4731 {
4732         mode_a => first column of diff-index output, no leading ':',
4733         mode_b => second column of diff-index output,
4734         sha1_b => sha1sum of the final blob,
4735         chg => change type [MCRADT],
4736         file_a => original file name of a file (iff chg is 'C' or 'R')
4737         file_b => new/current file name of a file (any chg)
4738 }
4739 ;
4740
4741 # retval of read_url_paths{,_all}();
4742 $l_map = {
4743         # repository root url
4744         'https://svn.musicpd.org' => {
4745                 # repository path               # GIT_SVN_ID
4746                 'mpd/trunk'             =>      'trunk',
4747                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
4748         },
4749 }
4750
4751 Notes:
4752         I don't trust the each() function on unless I created %hash myself
4753         because the internal iterator may not have started at base.