git.oblomov.eu Git - git/blob - contrib/completion/git-completion.zsh

   1 #compdef git gitk
   2
   3 # zsh completion wrapper for git
   4 #
   5 # Copyright (c) 2012-2013 Felipe Contreras <felipe.contreras@gmail.com>
   6 #
   7 # The recommended way to install this script is to make a copy of it as a
   8 # file named '_git' inside any directory in your fpath.
   9 #
  10 # For example, create a directory '~/.zsh/', copy this file to '~/.zsh/_git',
  11 # and then add the following to your ~/.zshrc file:
  12 #
  13 #  fpath=(~/.zsh $fpath)
  14 #
  15 # You need git's bash completion script installed. By default bash-completion's
  16 # location will be used (e.g. pkg-config --variable=completionsdir bash-completion).
  17 #
  18 # If your bash completion script is somewhere else, you can specify the
  19 # location in your ~/.zshrc:
  20 #
  21 #  zstyle ':completion:*:*:git:*' script ~/.git-completion.bash
  22 #
  23
  24 zstyle -T ':completion:*:*:git:*' tag-order && \
  25         zstyle ':completion:*:*:git:*' tag-order 'common-commands'
  26
  27 zstyle -s ":completion:*:*:git:*" script script
  28 if [ -z "$script" ]; then
  29         local -a locations
  30         local e bash_completion
  31
  32         bash_completion=$(pkg-config --variable=completionsdir bash-completion 2>/dev/null) ||
  33                 bash_completion='/usr/share/bash-completion/completions/'
  34
  35         locations=(
  36                 "$(dirname ${funcsourcetrace[1]%:*})"/git-completion.bash
  37                 "$HOME/.local/share/bash-completion/completions/git"
  38                 "$bash_completion/git"
  39                 '/etc/bash_completion.d/git' # old debian
  40                 )
  41         for e in $locations; do
  42                 test -f $e && script="$e" && break
  43         done
  44 fi
  45
  46 local old_complete="$functions[complete]"
  47 functions[complete]=:
  48 GIT_SOURCING_ZSH_COMPLETION=y . "$script"
  49 functions[complete]="$old_complete"
  50
  51 __gitcomp ()
  52 {
  53         emulate -L zsh
  54
  55         local cur_="${3-$cur}"
  56
  57         case "$cur_" in
  58         --*=)
  59                 ;;
  60         --no-*)
  61                 local c IFS=$' \t\n'
  62                 local -a array
  63                 for c in ${=1}; do
  64                         if [[ $c == "--" ]]; then
  65                                 continue
  66                         fi
  67                         c="$c${4-}"
  68                         case $c in
  69                         --*=|*.) ;;
  70                         *) c="$c " ;;
  71                         esac
  72                         array+=("$c")
  73                 done
  74                 compset -P '*[=:]'
  75                 compadd -Q -S '' -p "${2-}" -a -- array && _ret=0
  76                 ;;
  77         *)
  78                 local c IFS=$' \t\n'
  79                 local -a array
  80                 for c in ${=1}; do
  81                         if [[ $c == "--" ]]; then
  82                                 c="--no-...${4-}"
  83                                 array+=("$c ")
  84                                 break
  85                         fi
  86                         c="$c${4-}"
  87                         case $c in
  88                         --*=*|*.) ;;
  89                         *) c="$c " ;;
  90                         esac
  91                         array+=("$c")
  92                 done
  93                 compset -P '*[=:]'
  94                 compadd -Q -S '' -p "${2-}" -a -- array && _ret=0
  95                 ;;
  96         esac
  97 }
  98
  99 __gitcomp_direct ()
 100 {
 101         emulate -L zsh
 102
 103         compset -P '*[=:]'
 104         compadd -Q -S '' -- ${(f)1} && _ret=0
 105 }
 106
 107 __gitcomp_direct_append ()
 108 {
 109         __gitcomp_direct "$@"
 110 }
 111
 112 __gitcomp_nl ()
 113 {
 114         emulate -L zsh
 115
 116         compset -P '*[=:]'
 117         compadd -Q -S "${4- }" -p "${2-}" -- ${(f)1} && _ret=0
 118 }
 119
 120 __gitcomp_nl_append ()
 121 {
 122         __gitcomp_nl "$@"
 123 }
 124
 125 __gitcomp_file_direct ()
 126 {
 127         emulate -L zsh
 128
 129         compadd -f -- ${(f)1} && _ret=0
 130 }
 131
 132 __gitcomp_file ()
 133 {
 134         emulate -L zsh
 135
 136         compadd -f -p "${2-}" -- ${(f)1} && _ret=0
 137 }
 138
 139 __git_zsh_bash_func ()
 140 {
 141         emulate -L ksh
 142
 143         local command=$1
 144
 145         local completion_func="_git_${command//-/_}"
 146         declare -f $completion_func >/dev/null && $completion_func && return
 147
 148         local expansion=$(__git_aliased_command "$command")
 149         if [ -n "$expansion" ]; then
 150                 words[1]=$expansion
 151                 completion_func="_git_${expansion//-/_}"
 152                 declare -f $completion_func >/dev/null && $completion_func
 153         fi
 154 }
 155
 156 __git_zsh_cmd_common ()
 157 {
 158         local -a list
 159         list=(
 160         add:'add file contents to the index'
 161         bisect:'find by binary search the change that introduced a bug'
 162         branch:'list, create, or delete branches'
 163         checkout:'checkout a branch or paths to the working tree'
 164         clone:'clone a repository into a new directory'
 165         commit:'record changes to the repository'
 166         diff:'show changes between commits, commit and working tree, etc'
 167         fetch:'download objects and refs from another repository'
 168         grep:'print lines matching a pattern'
 169         init:'create an empty Git repository or reinitialize an existing one'
 170         log:'show commit logs'
 171         merge:'join two or more development histories together'
 172         mv:'move or rename a file, a directory, or a symlink'
 173         pull:'fetch from and merge with another repository or a local branch'
 174         push:'update remote refs along with associated objects'
 175         rebase:'forward-port local commits to the updated upstream head'
 176         reset:'reset current HEAD to the specified state'
 177         restore:'restore working tree files'
 178         rm:'remove files from the working tree and from the index'
 179         show:'show various types of objects'
 180         status:'show the working tree status'
 181         switch:'switch branches'
 182         tag:'create, list, delete or verify a tag object signed with GPG')
 183         _describe -t common-commands 'common commands' list && _ret=0
 184 }
 185
 186 __git_zsh_cmd_alias ()
 187 {
 188         local -a list
 189         list=(${${${(0)"$(git config -z --get-regexp '^alias\.')"}#alias.}%$'\n'*})
 190         _describe -t alias-commands 'aliases' list $* && _ret=0
 191 }
 192
 193 __git_zsh_cmd_all ()
 194 {
 195         local -a list
 196         emulate ksh -c __git_compute_all_commands
 197         list=( ${=__git_all_commands} )
 198         _describe -t all-commands 'all commands' list && _ret=0
 199 }
 200
 201 __git_zsh_main ()
 202 {
 203         local curcontext="$curcontext" state state_descr line
 204         typeset -A opt_args
 205         local -a orig_words
 206
 207         orig_words=( ${words[@]} )
 208
 209         _arguments -C \
 210                 '(-p --paginate --no-pager)'{-p,--paginate}'[pipe all output into ''less'']' \
 211                 '(-p --paginate)--no-pager[do not pipe git output into a pager]' \
 212                 '--git-dir=-[set the path to the repository]: :_directories' \
 213                 '--bare[treat the repository as a bare repository]' \
 214                 '(- :)--version[prints the git suite version]' \
 215                 '--exec-path=-[path to where your core git programs are installed]:: :_directories' \
 216                 '--html-path[print the path where git''s HTML documentation is installed]' \
 217                 '--info-path[print the path where the Info files are installed]' \
 218                 '--man-path[print the manpath (see `man(1)`) for the man pages]' \
 219                 '--work-tree=-[set the path to the working tree]: :_directories' \
 220                 '--namespace=-[set the git namespace]' \
 221                 '--no-replace-objects[do not use replacement refs to replace git objects]' \
 222                 '(- :)--help[prints the synopsis and a list of the most commonly used commands]: :->arg' \
 223                 '(-): :->command' \
 224                 '(-)*:: :->arg' && return
 225
 226         case $state in
 227         (command)
 228                 _alternative \
 229                          'alias-commands:alias:__git_zsh_cmd_alias' \
 230                          'common-commands:common:__git_zsh_cmd_common' \
 231                          'all-commands:all:__git_zsh_cmd_all' && _ret=0
 232                 ;;
 233         (arg)
 234                 local command="${words[1]}" __git_dir
 235
 236                 if (( $+opt_args[--bare] )); then
 237                         __git_dir='.'
 238                 else
 239                         __git_dir=${opt_args[--git-dir]}
 240                 fi
 241
 242                 (( $+opt_args[--help] )) && command='help'
 243
 244                 words=( ${orig_words[@]} )
 245
 246                 __git_zsh_bash_func $command
 247                 ;;
 248         esac
 249 }
 250
 251 _git ()
 252 {
 253         local _ret=1
 254         local cur cword prev
 255
 256         cur=${words[CURRENT]}
 257         prev=${words[CURRENT-1]}
 258         let cword=CURRENT-1
 259
 260         if (( $+functions[__${service}_zsh_main] )); then
 261                 __${service}_zsh_main
 262         elif (( $+functions[__${service}_main] )); then
 263                 emulate ksh -c __${service}_main
 264         elif (( $+functions[_${service}] )); then
 265                 emulate ksh -c _${service}
 266         elif (( $+functions[_${service//-/_}] )); then
 267                 emulate ksh -c _${service//-/_}
 268         fi
 269
 270         let _ret && _default && _ret=0
 271         return _ret
 272 }
 273
 274 _git