git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --annotate                     * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --compose-encoding      <str>  * Encoding to assume for introduction.
  60     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  61
  62   Sending:
  63     --envelope-sender       <str>  * Email envelope sender.
  64     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  65                                      is optional. Default 'localhost'.
  66     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  67     --smtp-server-port      <int>  * Outgoing SMTP server port.
  68     --smtp-user             <str>  * Username for SMTP-AUTH.
  69     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  70     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  71     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  72     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  73     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  74
  75   Automating:
  76     --identity              <str>  * Use the sendemail.<id> options.
  77     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  78     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  79     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  80     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  81     --[no-]suppress-from           * Send to self. Default off.
  82     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  83     --[no-]thread                  * Use In-Reply-To: field. Default on.
  84
  85   Administering:
  86     --confirm               <str>  * Confirm recipients before sending;
  87                                      auto, cc, compose, always, or never.
  88     --quiet                        * Output one line of info per email.
  89     --dry-run                      * Don't actually send the emails.
  90     --[no-]validate                * Perform patch sanity checks. Default on.
  91     --[no-]format-patch            * understand any non optional arguments as
  92                                      `git format-patch` ones.
  93     --force                        * Send even if safety checks would prevent it.
  94
  95 EOT
  96         exit(1);
  97 }
  98
  99 # most mail servers generate the Date: header, but not all...
 100 sub format_2822_time {
 101         my ($time) = @_;
 102         my @localtm = localtime($time);
 103         my @gmttm = gmtime($time);
 104         my $localmin = $localtm[1] + $localtm[2] * 60;
 105         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 106         if ($localtm[0] != $gmttm[0]) {
 107                 die "local zone differs from GMT by a non-minute interval\n";
 108         }
 109         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 110                 $localmin += 1440;
 111         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 112                 $localmin -= 1440;
 113         } elsif ($gmttm[6] != $localtm[6]) {
 114                 die "local time offset greater than or equal to 24 hours\n";
 115         }
 116         my $offset = $localmin - $gmtmin;
 117         my $offhour = $offset / 60;
 118         my $offmin = abs($offset % 60);
 119         if (abs($offhour) >= 24) {
 120                 die ("local time offset greater than or equal to 24 hours\n");
 121         }
 122
 123         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 124                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 125                        $localtm[3],
 126                        qw(Jan Feb Mar Apr May Jun
 127                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 128                        $localtm[5]+1900,
 129                        $localtm[2],
 130                        $localtm[1],
 131                        $localtm[0],
 132                        ($offset >= 0) ? '+' : '-',
 133                        abs($offhour),
 134                        $offmin,
 135                        );
 136 }
 137
 138 my $have_email_valid = eval { require Email::Valid; 1 };
 139 my $have_mail_address = eval { require Mail::Address; 1 };
 140 my $smtp;
 141 my $auth;
 142
 143 # Variables we fill in automatically, or via prompting:
 144 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 145         $initial_reply_to,$initial_subject,@files,
 146         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 147
 148 my $envelope_sender;
 149
 150 # Example reply to:
 151 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 152
 153 my $repo = eval { Git->repository() };
 154 my @repo = $repo ? ($repo) : ();
 155 my $term = eval {
 156         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 157                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 158                 : new Term::ReadLine 'git-send-email';
 159 };
 160 if ($@) {
 161         $term = new FakeTerm "$@: going non-interactive";
 162 }
 163
 164 # Behavior modification variables
 165 my ($quiet, $dry_run) = (0, 0);
 166 my $format_patch;
 167 my $compose_filename;
 168 my $force = 0;
 169
 170 # Handle interactive edition of files.
 171 my $multiedit;
 172 my $editor;
 173
 174 sub do_edit {
 175         if (!defined($editor)) {
 176                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 177         }
 178         if (defined($multiedit) && !$multiedit) {
 179                 map {
 180                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 181                         if (($? & 127) || ($? >> 8)) {
 182                                 die("the editor exited uncleanly, aborting everything");
 183                         }
 184                 } @_;
 185         } else {
 186                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 187                 if (($? & 127) || ($? >> 8)) {
 188                         die("the editor exited uncleanly, aborting everything");
 189                 }
 190         }
 191 }
 192
 193 # Variables with corresponding config settings
 194 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 195 my ($to_cmd, $cc_cmd);
 196 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 197 my ($smtp_authuser, $smtp_encryption);
 198 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 199 my ($validate, $confirm);
 200 my (@suppress_cc);
 201 my ($auto_8bit_encoding);
 202 my ($compose_encoding);
 203
 204 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 205
 206 my $not_set_by_user = "true but not set by the user";
 207
 208 my %config_bool_settings = (
 209     "thread" => [\$thread, 1],
 210     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 211     "suppressfrom" => [\$suppress_from, undef],
 212     "signedoffbycc" => [\$signed_off_by_cc, undef],
 213     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 214     "validate" => [\$validate, 1],
 215     "multiedit" => [\$multiedit, undef]
 216 );
 217
 218 my %config_settings = (
 219     "smtpserver" => \$smtp_server,
 220     "smtpserverport" => \$smtp_server_port,
 221     "smtpserveroption" => \@smtp_server_options,
 222     "smtpuser" => \$smtp_authuser,
 223     "smtppass" => \$smtp_authpass,
 224     "smtpdomain" => \$smtp_domain,
 225     "to" => \@initial_to,
 226     "tocmd" => \$to_cmd,
 227     "cc" => \@initial_cc,
 228     "cccmd" => \$cc_cmd,
 229     "aliasfiletype" => \$aliasfiletype,
 230     "bcc" => \@bcclist,
 231     "suppresscc" => \@suppress_cc,
 232     "envelopesender" => \$envelope_sender,
 233     "confirm"   => \$confirm,
 234     "from" => \$sender,
 235     "assume8bitencoding" => \$auto_8bit_encoding,
 236     "composeencoding" => \$compose_encoding,
 237 );
 238
 239 my %config_path_settings = (
 240     "aliasesfile" => \@alias_files,
 241 );
 242
 243 # Help users prepare for 1.7.0
 244 sub chain_reply_to {
 245         if (defined $chain_reply_to &&
 246             $chain_reply_to eq $not_set_by_user) {
 247                 print STDERR
 248                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 249                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 250                     "you want to keep --chain-reply-to as your default.\n";
 251                 $chain_reply_to = 0;
 252         }
 253         return $chain_reply_to;
 254 }
 255
 256 # Handle Uncouth Termination
 257 sub signal_handler {
 258
 259         # Make text normal
 260         print color("reset"), "\n";
 261
 262         # SMTP password masked
 263         system "stty echo";
 264
 265         # tmp files from --compose
 266         if (defined $compose_filename) {
 267                 if (-e $compose_filename) {
 268                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 269                 }
 270                 if (-e ($compose_filename . ".final")) {
 271                         print "'$compose_filename.final' contains the composed email.\n"
 272                 }
 273         }
 274
 275         exit;
 276 };
 277
 278 $SIG{TERM} = \&signal_handler;
 279 $SIG{INT}  = \&signal_handler;
 280
 281 # Begin by accumulating all the variables (defined above), that we will end up
 282 # needing, first, from the command line:
 283
 284 my $help;
 285 my $rc = GetOptions("h" => \$help,
 286                     "sender|from=s" => \$sender,
 287                     "in-reply-to=s" => \$initial_reply_to,
 288                     "subject=s" => \$initial_subject,
 289                     "to=s" => \@initial_to,
 290                     "to-cmd=s" => \$to_cmd,
 291                     "no-to" => \$no_to,
 292                     "cc=s" => \@initial_cc,
 293                     "no-cc" => \$no_cc,
 294                     "bcc=s" => \@bcclist,
 295                     "no-bcc" => \$no_bcc,
 296                     "chain-reply-to!" => \$chain_reply_to,
 297                     "smtp-server=s" => \$smtp_server,
 298                     "smtp-server-option=s" => \@smtp_server_options,
 299                     "smtp-server-port=s" => \$smtp_server_port,
 300                     "smtp-user=s" => \$smtp_authuser,
 301                     "smtp-pass:s" => \$smtp_authpass,
 302                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 303                     "smtp-encryption=s" => \$smtp_encryption,
 304                     "smtp-debug:i" => \$debug_net_smtp,
 305                     "smtp-domain:s" => \$smtp_domain,
 306                     "identity=s" => \$identity,
 307                     "annotate" => \$annotate,
 308                     "compose" => \$compose,
 309                     "quiet" => \$quiet,
 310                     "cc-cmd=s" => \$cc_cmd,
 311                     "suppress-from!" => \$suppress_from,
 312                     "suppress-cc=s" => \@suppress_cc,
 313                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 314                     "confirm=s" => \$confirm,
 315                     "dry-run" => \$dry_run,
 316                     "envelope-sender=s" => \$envelope_sender,
 317                     "thread!" => \$thread,
 318                     "validate!" => \$validate,
 319                     "format-patch!" => \$format_patch,
 320                     "8bit-encoding=s" => \$auto_8bit_encoding,
 321                     "compose-encoding=s" => \$compose_encoding,
 322                     "force" => \$force,
 323          );
 324
 325 usage() if $help;
 326 unless ($rc) {
 327     usage();
 328 }
 329
 330 die "Cannot run git format-patch from outside a repository\n"
 331         if $format_patch and not $repo;
 332
 333 # Now, let's fill any that aren't set in with defaults:
 334
 335 sub read_config {
 336         my ($prefix) = @_;
 337
 338         foreach my $setting (keys %config_bool_settings) {
 339                 my $target = $config_bool_settings{$setting}->[0];
 340                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 341         }
 342
 343         foreach my $setting (keys %config_path_settings) {
 344                 my $target = $config_path_settings{$setting};
 345                 if (ref($target) eq "ARRAY") {
 346                         unless (@$target) {
 347                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 348                                 @$target = @values if (@values && defined $values[0]);
 349                         }
 350                 }
 351                 else {
 352                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 353                 }
 354         }
 355
 356         foreach my $setting (keys %config_settings) {
 357                 my $target = $config_settings{$setting};
 358                 next if $setting eq "to" and defined $no_to;
 359                 next if $setting eq "cc" and defined $no_cc;
 360                 next if $setting eq "bcc" and defined $no_bcc;
 361                 if (ref($target) eq "ARRAY") {
 362                         unless (@$target) {
 363                                 my @values = Git::config(@repo, "$prefix.$setting");
 364                                 @$target = @values if (@values && defined $values[0]);
 365                         }
 366                 }
 367                 else {
 368                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 369                 }
 370         }
 371
 372         if (!defined $smtp_encryption) {
 373                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 374                 if (defined $enc) {
 375                         $smtp_encryption = $enc;
 376                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 377                         $smtp_encryption = 'ssl';
 378                 }
 379         }
 380 }
 381
 382 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 383 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 384 read_config("sendemail.$identity") if (defined $identity);
 385 read_config("sendemail");
 386
 387 # fall back on builtin bool defaults
 388 foreach my $setting (values %config_bool_settings) {
 389         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 390 }
 391
 392 # 'default' encryption is none -- this only prevents a warning
 393 $smtp_encryption = '' unless (defined $smtp_encryption);
 394
 395 # Set CC suppressions
 396 my(%suppress_cc);
 397 if (@suppress_cc) {
 398         foreach my $entry (@suppress_cc) {
 399                 die "Unknown --suppress-cc field: '$entry'\n"
 400                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 401                 $suppress_cc{$entry} = 1;
 402         }
 403 }
 404
 405 if ($suppress_cc{'all'}) {
 406         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 407                 $suppress_cc{$entry} = 1;
 408         }
 409         delete $suppress_cc{'all'};
 410 }
 411
 412 # If explicit old-style ones are specified, they trump --suppress-cc.
 413 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 414 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 415
 416 if ($suppress_cc{'body'}) {
 417         foreach my $entry (qw (sob bodycc)) {
 418                 $suppress_cc{$entry} = 1;
 419         }
 420         delete $suppress_cc{'body'};
 421 }
 422
 423 # Set confirm's default value
 424 my $confirm_unconfigured = !defined $confirm;
 425 if ($confirm_unconfigured) {
 426         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 427 };
 428 die "Unknown --confirm setting: '$confirm'\n"
 429         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 430
 431 # Debugging, print out the suppressions.
 432 if (0) {
 433         print "suppressions:\n";
 434         foreach my $entry (keys %suppress_cc) {
 435                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 436         }
 437 }
 438
 439 my ($repoauthor, $repocommitter);
 440 ($repoauthor) = Git::ident_person(@repo, 'author');
 441 ($repocommitter) = Git::ident_person(@repo, 'committer');
 442
 443 # Verify the user input
 444
 445 foreach my $entry (@initial_to) {
 446         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 447 }
 448
 449 foreach my $entry (@initial_cc) {
 450         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 451 }
 452
 453 foreach my $entry (@bcclist) {
 454         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 455 }
 456
 457 sub parse_address_line {
 458         if ($have_mail_address) {
 459                 return map { $_->format } Mail::Address->parse($_[0]);
 460         } else {
 461                 return split_addrs($_[0]);
 462         }
 463 }
 464
 465 sub split_addrs {
 466         return quotewords('\s*,\s*', 1, @_);
 467 }
 468
 469 my %aliases;
 470 my %parse_alias = (
 471         # multiline formats can be supported in the future
 472         mutt => sub { my $fh = shift; while (<$fh>) {
 473                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 474                         my ($alias, $addr) = ($1, $2);
 475                         $addr =~ s/#.*$//; # mutt allows # comments
 476                          # commas delimit multiple addresses
 477                         $aliases{$alias} = [ split_addrs($addr) ];
 478                 }}},
 479         mailrc => sub { my $fh = shift; while (<$fh>) {
 480                 if (/^alias\s+(\S+)\s+(.*)$/) {
 481                         # spaces delimit multiple addresses
 482                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 483                 }}},
 484         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 485                 for (my $x = ''; defined($x); $x = $_) {
 486                         chomp $x;
 487                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 488                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 489                         $aliases{$1} = [ split_addrs($2) ];
 490                 }},
 491         elm => sub  { my $fh = shift;
 492                       while (<$fh>) {
 493                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 494                               my ($alias, $addr) = ($1, $2);
 495                                $aliases{$alias} = [ split_addrs($addr) ];
 496                           }
 497                       } },
 498
 499         gnus => sub { my $fh = shift; while (<$fh>) {
 500                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 501                         $aliases{$1} = [ $2 ];
 502                 }}}
 503 );
 504
 505 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 506         foreach my $file (@alias_files) {
 507                 open my $fh, '<', $file or die "opening $file: $!\n";
 508                 $parse_alias{$aliasfiletype}->($fh);
 509                 close $fh;
 510         }
 511 }
 512
 513 ($sender) = expand_aliases($sender) if defined $sender;
 514
 515 # returns 1 if the conflict must be solved using it as a format-patch argument
 516 sub check_file_rev_conflict($) {
 517         return unless $repo;
 518         my $f = shift;
 519         try {
 520                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 521                 if (defined($format_patch)) {
 522                         return $format_patch;
 523                 }
 524                 die(<<EOF);
 525 File '$f' exists but it could also be the range of commits
 526 to produce patches for.  Please disambiguate by...
 527
 528     * Saying "./$f" if you mean a file; or
 529     * Giving --format-patch option if you mean a range.
 530 EOF
 531         } catch Git::Error::Command with {
 532                 return 0;
 533         }
 534 }
 535
 536 # Now that all the defaults are set, process the rest of the command line
 537 # arguments and collect up the files that need to be processed.
 538 my @rev_list_opts;
 539 while (defined(my $f = shift @ARGV)) {
 540         if ($f eq "--") {
 541                 push @rev_list_opts, "--", @ARGV;
 542                 @ARGV = ();
 543         } elsif (-d $f and !check_file_rev_conflict($f)) {
 544                 opendir my $dh, $f
 545                         or die "Failed to opendir $f: $!";
 546
 547                 push @files, grep { -f $_ } map { catfile($f, $_) }
 548                                 sort readdir $dh;
 549                 closedir $dh;
 550         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 551                 push @files, $f;
 552         } else {
 553                 push @rev_list_opts, $f;
 554         }
 555 }
 556
 557 if (@rev_list_opts) {
 558         die "Cannot run git format-patch from outside a repository\n"
 559                 unless $repo;
 560         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 561 }
 562
 563 if ($validate) {
 564         foreach my $f (@files) {
 565                 unless (-p $f) {
 566                         my $error = validate_patch($f);
 567                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 568                 }
 569         }
 570 }
 571
 572 if (@files) {
 573         unless ($quiet) {
 574                 print $_,"\n" for (@files);
 575         }
 576 } else {
 577         print STDERR "\nNo patch files specified!\n\n";
 578         usage();
 579 }
 580
 581 sub get_patch_subject {
 582         my $fn = shift;
 583         open (my $fh, '<', $fn);
 584         while (my $line = <$fh>) {
 585                 next unless ($line =~ /^Subject: (.*)$/);
 586                 close $fh;
 587                 return "GIT: $1\n";
 588         }
 589         close $fh;
 590         die "No subject line in $fn ?";
 591 }
 592
 593 if ($compose) {
 594         # Note that this does not need to be secure, but we will make a small
 595         # effort to have it be unique
 596         $compose_filename = ($repo ?
 597                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 598                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 599         open my $c, ">", $compose_filename
 600                 or die "Failed to open for writing $compose_filename: $!";
 601
 602
 603         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 604         my $tpl_subject = $initial_subject || '';
 605         my $tpl_reply_to = $initial_reply_to || '';
 606
 607         print $c <<EOT;
 608 From $tpl_sender # This line is ignored.
 609 GIT: Lines beginning in "GIT:" will be removed.
 610 GIT: Consider including an overall diffstat or table of contents
 611 GIT: for the patch you are writing.
 612 GIT:
 613 GIT: Clear the body content if you don't wish to send a summary.
 614 From: $tpl_sender
 615 Subject: $tpl_subject
 616 In-Reply-To: $tpl_reply_to
 617
 618 EOT
 619         for my $f (@files) {
 620                 print $c get_patch_subject($f);
 621         }
 622         close $c;
 623
 624         if ($annotate) {
 625                 do_edit($compose_filename, @files);
 626         } else {
 627                 do_edit($compose_filename);
 628         }
 629
 630         open my $c2, ">", $compose_filename . ".final"
 631                 or die "Failed to open $compose_filename.final : " . $!;
 632
 633         open $c, "<", $compose_filename
 634                 or die "Failed to open $compose_filename : " . $!;
 635
 636         my $need_8bit_cte = file_has_nonascii($compose_filename);
 637         my $in_body = 0;
 638         my $summary_empty = 1;
 639         if (!defined $compose_encoding) {
 640                 $compose_encoding = "UTF-8";
 641         }
 642         while(<$c>) {
 643                 next if m/^GIT:/;
 644                 if ($in_body) {
 645                         $summary_empty = 0 unless (/^\n$/);
 646                 } elsif (/^\n$/) {
 647                         $in_body = 1;
 648                         if ($need_8bit_cte) {
 649                                 print $c2 "MIME-Version: 1.0\n",
 650                                          "Content-Type: text/plain; ",
 651                                            "charset=$compose_encoding\n",
 652                                          "Content-Transfer-Encoding: 8bit\n";
 653                         }
 654                 } elsif (/^MIME-Version:/i) {
 655                         $need_8bit_cte = 0;
 656                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 657                         $initial_subject = $1;
 658                         my $subject = $initial_subject;
 659                         $_ = "Subject: " .
 660                                 quote_subject($subject, $compose_encoding) .
 661                                 "\n";
 662                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 663                         $initial_reply_to = $1;
 664                         next;
 665                 } elsif (/^From:\s*(.+)\s*$/i) {
 666                         $sender = $1;
 667                         next;
 668                 } elsif (/^(?:To|Cc|Bcc):/i) {
 669                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 670                         next;
 671                 }
 672                 print $c2 $_;
 673         }
 674         close $c;
 675         close $c2;
 676
 677         if ($summary_empty) {
 678                 print "Summary email is empty, skipping it\n";
 679                 $compose = -1;
 680         }
 681 } elsif ($annotate) {
 682         do_edit(@files);
 683 }
 684
 685 sub ask {
 686         my ($prompt, %arg) = @_;
 687         my $valid_re = $arg{valid_re};
 688         my $default = $arg{default};
 689         my $confirm_only = $arg{confirm_only};
 690         my $resp;
 691         my $i = 0;
 692         return defined $default ? $default : undef
 693                 unless defined $term->IN and defined fileno($term->IN) and
 694                        defined $term->OUT and defined fileno($term->OUT);
 695         while ($i++ < 10) {
 696                 $resp = $term->readline($prompt);
 697                 if (!defined $resp) { # EOF
 698                         print "\n";
 699                         return defined $default ? $default : undef;
 700                 }
 701                 if ($resp eq '' and defined $default) {
 702                         return $default;
 703                 }
 704                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 705                         return $resp;
 706                 }
 707                 if ($confirm_only) {
 708                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 709                         if (defined $yesno && $yesno =~ /y/i) {
 710                                 return $resp;
 711                         }
 712                 }
 713         }
 714         return undef;
 715 }
 716
 717 my %broken_encoding;
 718
 719 sub file_declares_8bit_cte {
 720         my $fn = shift;
 721         open (my $fh, '<', $fn);
 722         while (my $line = <$fh>) {
 723                 last if ($line =~ /^$/);
 724                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 725         }
 726         close $fh;
 727         return 0;
 728 }
 729
 730 foreach my $f (@files) {
 731         next unless (body_or_subject_has_nonascii($f)
 732                      && !file_declares_8bit_cte($f));
 733         $broken_encoding{$f} = 1;
 734 }
 735
 736 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 737         print "The following files are 8bit, but do not declare " .
 738                 "a Content-Transfer-Encoding.\n";
 739         foreach my $f (sort keys %broken_encoding) {
 740                 print "    $f\n";
 741         }
 742         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 743                                   default => "UTF-8");
 744 }
 745
 746 if (!$force) {
 747         for my $f (@files) {
 748                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 749                         die "Refusing to send because the patch\n\t$f\n"
 750                                 . "has the template subject '*** SUBJECT HERE ***'. "
 751                                 . "Pass --force if you really want to send.\n";
 752                 }
 753         }
 754 }
 755
 756 my $prompting = 0;
 757 if (!defined $sender) {
 758         $sender = $repoauthor || $repocommitter || '';
 759         $sender = ask("Who should the emails appear to be from? [$sender] ",
 760                       default => $sender,
 761                       valid_re => qr/\@.*\./, confirm_only => 1);
 762         print "Emails will be sent from: ", $sender, "\n";
 763         $prompting++;
 764 }
 765
 766 if (!@initial_to && !defined $to_cmd) {
 767         my $to = ask("Who should the emails be sent to (if any)? ",
 768                      default => "",
 769                      valid_re => qr/\@.*\./, confirm_only => 1);
 770         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 771         $prompting++;
 772 }
 773
 774 sub expand_aliases {
 775         return map { expand_one_alias($_) } @_;
 776 }
 777
 778 my %EXPANDED_ALIASES;
 779 sub expand_one_alias {
 780         my $alias = shift;
 781         if ($EXPANDED_ALIASES{$alias}) {
 782                 die "fatal: alias '$alias' expands to itself\n";
 783         }
 784         local $EXPANDED_ALIASES{$alias} = 1;
 785         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 786 }
 787
 788 @initial_to = expand_aliases(@initial_to);
 789 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 790 @initial_cc = expand_aliases(@initial_cc);
 791 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 792 @bcclist = expand_aliases(@bcclist);
 793 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 794
 795 if ($thread && !defined $initial_reply_to && $prompting) {
 796         $initial_reply_to = ask(
 797                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 798                 default => "",
 799                 valid_re => qr/\@.*\./, confirm_only => 1);
 800 }
 801 if (defined $initial_reply_to) {
 802         $initial_reply_to =~ s/^\s*<?//;
 803         $initial_reply_to =~ s/>?\s*$//;
 804         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 805 }
 806
 807 if (!defined $smtp_server) {
 808         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 809                 if (-x $_) {
 810                         $smtp_server = $_;
 811                         last;
 812                 }
 813         }
 814         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 815 }
 816
 817 if ($compose && $compose > 0) {
 818         @files = ($compose_filename . ".final", @files);
 819 }
 820
 821 # Variables we set as part of the loop over files
 822 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 823         $needs_confirm, $message_num, $ask_default);
 824
 825 sub extract_valid_address {
 826         my $address = shift;
 827         my $local_part_regexp = qr/[^<>"\s@]+/;
 828         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 829
 830         # check for a local address:
 831         return $address if ($address =~ /^($local_part_regexp)$/);
 832
 833         $address =~ s/^\s*<(.*)>\s*$/$1/;
 834         if ($have_email_valid) {
 835                 return scalar Email::Valid->address($address);
 836         }
 837
 838         # less robust/correct than the monster regexp in Email::Valid,
 839         # but still does a 99% job, and one less dependency
 840         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 841         return undef;
 842 }
 843
 844 sub extract_valid_address_or_die {
 845         my $address = shift;
 846         $address = extract_valid_address($address);
 847         die "error: unable to extract a valid address from: $address\n"
 848                 if !$address;
 849         return $address;
 850 }
 851
 852 sub validate_address {
 853         my $address = shift;
 854         while (!extract_valid_address($address)) {
 855                 print STDERR "error: unable to extract a valid address from: $address\n";
 856                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 857                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 858                         default => 'q');
 859                 if (/^d/i) {
 860                         return undef;
 861                 } elsif (/^q/i) {
 862                         cleanup_compose_files();
 863                         exit(0);
 864                 }
 865                 $address = ask("Who should the email be sent to (if any)? ",
 866                         default => "",
 867                         valid_re => qr/\@.*\./, confirm_only => 1);
 868         }
 869         return $address;
 870 }
 871
 872 sub validate_address_list {
 873         return (grep { defined $_ }
 874                 map { validate_address($_) } @_);
 875 }
 876
 877 # Usually don't need to change anything below here.
 878
 879 # we make a "fake" message id by taking the current number
 880 # of seconds since the beginning of Unix time and tacking on
 881 # a random number to the end, in case we are called quicker than
 882 # 1 second since the last time we were called.
 883
 884 # We'll setup a template for the message id, using the "from" address:
 885
 886 my ($message_id_stamp, $message_id_serial);
 887 sub make_message_id {
 888         my $uniq;
 889         if (!defined $message_id_stamp) {
 890                 $message_id_stamp = sprintf("%s-%s", time, $$);
 891                 $message_id_serial = 0;
 892         }
 893         $message_id_serial++;
 894         $uniq = "$message_id_stamp-$message_id_serial";
 895
 896         my $du_part;
 897         for ($sender, $repocommitter, $repoauthor) {
 898                 $du_part = extract_valid_address(sanitize_address($_));
 899                 last if (defined $du_part and $du_part ne '');
 900         }
 901         if (not defined $du_part or $du_part eq '') {
 902                 require Sys::Hostname;
 903                 $du_part = 'user@' . Sys::Hostname::hostname();
 904         }
 905         my $message_id_template = "<%s-git-send-email-%s>";
 906         $message_id = sprintf($message_id_template, $uniq, $du_part);
 907         #print "new message id = $message_id\n"; # Was useful for debugging
 908 }
 909
 910
 911
 912 $time = time - scalar $#files;
 913
 914 sub unquote_rfc2047 {
 915         local ($_) = @_;
 916         my $encoding;
 917         s{=\?([^?]+)\?q\?(.*?)\?=}{
 918                 $encoding = $1;
 919                 my $e = $2;
 920                 $e =~ s/_/ /g;
 921                 $e =~ s/=([0-9A-F]{2})/chr(hex($1))/eg;
 922                 $e;
 923         }eg;
 924         return wantarray ? ($_, $encoding) : $_;
 925 }
 926
 927 sub quote_rfc2047 {
 928         local $_ = shift;
 929         my $encoding = shift || 'UTF-8';
 930         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 931         s/(.*)/=\?$encoding\?q\?$1\?=/;
 932         return $_;
 933 }
 934
 935 sub is_rfc2047_quoted {
 936         my $s = shift;
 937         my $token = qr/[^][()<>@,;:"\/?.= \000-\037\177-\377]+/;
 938         my $encoded_text = qr/[!->@-~]+/;
 939         length($s) <= 75 &&
 940         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 941 }
 942
 943 sub subject_needs_rfc2047_quoting {
 944         my $s = shift;
 945
 946         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 947 }
 948
 949 sub quote_subject {
 950         local $subject = shift;
 951         my $encoding = shift || 'UTF-8';
 952
 953         if (subject_needs_rfc2047_quoting($subject)) {
 954                 return quote_rfc2047($subject, $encoding);
 955         }
 956         return $subject;
 957 }
 958
 959 # use the simplest quoting being able to handle the recipient
 960 sub sanitize_address {
 961         my ($recipient) = @_;
 962
 963         # remove garbage after email address
 964         $recipient =~ s/(.*>).*$/$1/;
 965
 966         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 967
 968         if (not $recipient_name) {
 969                 return $recipient;
 970         }
 971
 972         # if recipient_name is already quoted, do nothing
 973         if (is_rfc2047_quoted($recipient_name)) {
 974                 return $recipient;
 975         }
 976
 977         # rfc2047 is needed if a non-ascii char is included
 978         if ($recipient_name =~ /[^[:ascii:]]/) {
 979                 $recipient_name =~ s/^"(.*)"$/$1/;
 980                 $recipient_name = quote_rfc2047($recipient_name);
 981         }
 982
 983         # double quotes are needed if specials or CTLs are included
 984         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 985                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 986                 $recipient_name = qq["$recipient_name"];
 987         }
 988
 989         return "$recipient_name $recipient_addr";
 990
 991 }
 992
 993 sub sanitize_address_list {
 994         return (map { sanitize_address($_) } @_);
 995 }
 996
 997 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 998 #
 999 # Tightly configured MTAa require that a caller sends a real DNS
1000 # domain name that corresponds the IP address in the HELO/EHLO
1001 # handshake. This is used to verify the connection and prevent
1002 # spammers from trying to hide their identity. If the DNS and IP don't
1003 # match, the receiveing MTA may deny the connection.
1004 #
1005 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1006 #
1007 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1008 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1009 #
1010 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1011 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1012
1013 sub valid_fqdn {
1014         my $domain = shift;
1015         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1016 }
1017
1018 sub maildomain_net {
1019         my $maildomain;
1020
1021         if (eval { require Net::Domain; 1 }) {
1022                 my $domain = Net::Domain::domainname();
1023                 $maildomain = $domain if valid_fqdn($domain);
1024         }
1025
1026         return $maildomain;
1027 }
1028
1029 sub maildomain_mta {
1030         my $maildomain;
1031
1032         if (eval { require Net::SMTP; 1 }) {
1033                 for my $host (qw(mailhost localhost)) {
1034                         my $smtp = Net::SMTP->new($host);
1035                         if (defined $smtp) {
1036                                 my $domain = $smtp->domain;
1037                                 $smtp->quit;
1038
1039                                 $maildomain = $domain if valid_fqdn($domain);
1040
1041                                 last if $maildomain;
1042                         }
1043                 }
1044         }
1045
1046         return $maildomain;
1047 }
1048
1049 sub maildomain {
1050         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1051 }
1052
1053 # Returns 1 if the message was sent, and 0 otherwise.
1054 # In actuality, the whole program dies when there
1055 # is an error sending a message.
1056
1057 sub send_message {
1058         my @recipients = unique_email_list(@to);
1059         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1060                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1061                     }
1062                @cc);
1063         my $to = join (",\n\t", @recipients);
1064         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1065         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1066         my $date = format_2822_time($time++);
1067         my $gitversion = '@@GIT_VERSION@@';
1068         if ($gitversion =~ m/..GIT_VERSION../) {
1069             $gitversion = Git::version();
1070         }
1071
1072         my $cc = join(",\n\t", unique_email_list(@cc));
1073         my $ccline = "";
1074         if ($cc ne '') {
1075                 $ccline = "\nCc: $cc";
1076         }
1077         my $sanitized_sender = sanitize_address($sender);
1078         make_message_id() unless defined($message_id);
1079
1080         my $header = "From: $sanitized_sender
1081 To: $to${ccline}
1082 Subject: $subject
1083 Date: $date
1084 Message-Id: $message_id
1085 X-Mailer: git-send-email $gitversion
1086 ";
1087         if ($reply_to) {
1088
1089                 $header .= "In-Reply-To: $reply_to\n";
1090                 $header .= "References: $references\n";
1091         }
1092         if (@xh) {
1093                 $header .= join("\n", @xh) . "\n";
1094         }
1095
1096         my @sendmail_parameters = ('-i', @recipients);
1097         my $raw_from = $sanitized_sender;
1098         if (defined $envelope_sender && $envelope_sender ne "auto") {
1099                 $raw_from = $envelope_sender;
1100         }
1101         $raw_from = extract_valid_address($raw_from);
1102         unshift (@sendmail_parameters,
1103                         '-f', $raw_from) if(defined $envelope_sender);
1104
1105         if ($needs_confirm && !$dry_run) {
1106                 print "\n$header\n";
1107                 if ($needs_confirm eq "inform") {
1108                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1109                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1110                         print "    The Cc list above has been expanded by additional\n";
1111                         print "    addresses found in the patch commit message. By default\n";
1112                         print "    send-email prompts before sending whenever this occurs.\n";
1113                         print "    This behavior is controlled by the sendemail.confirm\n";
1114                         print "    configuration setting.\n";
1115                         print "\n";
1116                         print "    For additional information, run 'git send-email --help'.\n";
1117                         print "    To retain the current behavior, but squelch this message,\n";
1118                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1119                 }
1120                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1121                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1122                          default => $ask_default);
1123                 die "Send this email reply required" unless defined $_;
1124                 if (/^n/i) {
1125                         return 0;
1126                 } elsif (/^q/i) {
1127                         cleanup_compose_files();
1128                         exit(0);
1129                 } elsif (/^a/i) {
1130                         $confirm = 'never';
1131                 }
1132         }
1133
1134         unshift (@sendmail_parameters, @smtp_server_options);
1135
1136         if ($dry_run) {
1137                 # We don't want to send the email.
1138         } elsif ($smtp_server =~ m#^/#) {
1139                 my $pid = open my $sm, '|-';
1140                 defined $pid or die $!;
1141                 if (!$pid) {
1142                         exec($smtp_server, @sendmail_parameters) or die $!;
1143                 }
1144                 print $sm "$header\n$message";
1145                 close $sm or die $!;
1146         } else {
1147
1148                 if (!defined $smtp_server) {
1149                         die "The required SMTP server is not properly defined."
1150                 }
1151
1152                 if ($smtp_encryption eq 'ssl') {
1153                         $smtp_server_port ||= 465; # ssmtp
1154                         require Net::SMTP::SSL;
1155                         $smtp_domain ||= maildomain();
1156                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1157                                                       Hello => $smtp_domain,
1158                                                       Port => $smtp_server_port);
1159                 }
1160                 else {
1161                         require Net::SMTP;
1162                         $smtp_domain ||= maildomain();
1163                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1164                                                  ? "$smtp_server:$smtp_server_port"
1165                                                  : $smtp_server,
1166                                                  Hello => $smtp_domain,
1167                                                  Debug => $debug_net_smtp);
1168                         if ($smtp_encryption eq 'tls' && $smtp) {
1169                                 require Net::SMTP::SSL;
1170                                 $smtp->command('STARTTLS');
1171                                 $smtp->response();
1172                                 if ($smtp->code == 220) {
1173                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1174                                                 or die "STARTTLS failed! ".$smtp->message;
1175                                         $smtp_encryption = '';
1176                                         # Send EHLO again to receive fresh
1177                                         # supported commands
1178                                         $smtp->hello($smtp_domain);
1179                                 } else {
1180                                         die "Server does not support STARTTLS! ".$smtp->message;
1181                                 }
1182                         }
1183                 }
1184
1185                 if (!$smtp) {
1186                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1187                             "VALUES: server=$smtp_server ",
1188                             "encryption=$smtp_encryption ",
1189                             "hello=$smtp_domain",
1190                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1191                 }
1192
1193                 if (defined $smtp_authuser) {
1194                         # Workaround AUTH PLAIN/LOGIN interaction defect
1195                         # with Authen::SASL::Cyrus
1196                         eval {
1197                                 require Authen::SASL;
1198                                 Authen::SASL->import(qw(Perl));
1199                         };
1200
1201                         if (!defined $smtp_authpass) {
1202
1203                                 system "stty -echo";
1204
1205                                 do {
1206                                         print "Password: ";
1207                                         $_ = <STDIN>;
1208                                         print "\n";
1209                                 } while (!defined $_);
1210
1211                                 chomp($smtp_authpass = $_);
1212
1213                                 system "stty echo";
1214                         }
1215
1216                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1217                 }
1218
1219                 $smtp->mail( $raw_from ) or die $smtp->message;
1220                 $smtp->to( @recipients ) or die $smtp->message;
1221                 $smtp->data or die $smtp->message;
1222                 $smtp->datasend("$header\n$message") or die $smtp->message;
1223                 $smtp->dataend() or die $smtp->message;
1224                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1225         }
1226         if ($quiet) {
1227                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1228         } else {
1229                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1230                 if ($smtp_server !~ m#^/#) {
1231                         print "Server: $smtp_server\n";
1232                         print "MAIL FROM:<$raw_from>\n";
1233                         foreach my $entry (@recipients) {
1234                             print "RCPT TO:<$entry>\n";
1235                         }
1236                 } else {
1237                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1238                 }
1239                 print $header, "\n";
1240                 if ($smtp) {
1241                         print "Result: ", $smtp->code, ' ',
1242                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1243                 } else {
1244                         print "Result: OK\n";
1245                 }
1246         }
1247
1248         return 1;
1249 }
1250
1251 $reply_to = $initial_reply_to;
1252 $references = $initial_reply_to || '';
1253 $subject = $initial_subject;
1254 $message_num = 0;
1255
1256 foreach my $t (@files) {
1257         open my $fh, "<", $t or die "can't open file $t";
1258
1259         my $author = undef;
1260         my $author_encoding;
1261         my $has_content_type;
1262         my $body_encoding;
1263         @to = ();
1264         @cc = ();
1265         @xh = ();
1266         my $input_format = undef;
1267         my @header = ();
1268         $message = "";
1269         $message_num++;
1270         # First unfold multiline header fields
1271         while(<$fh>) {
1272                 last if /^\s*$/;
1273                 if (/^\s+\S/ and @header) {
1274                         chomp($header[$#header]);
1275                         s/^\s+/ /;
1276                         $header[$#header] .= $_;
1277             } else {
1278                         push(@header, $_);
1279                 }
1280         }
1281         # Now parse the header
1282         foreach(@header) {
1283                 if (/^From /) {
1284                         $input_format = 'mbox';
1285                         next;
1286                 }
1287                 chomp;
1288                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1289                         $input_format = 'mbox';
1290                 }
1291
1292                 if (defined $input_format && $input_format eq 'mbox') {
1293                         if (/^Subject:\s+(.*)$/) {
1294                                 $subject = $1;
1295                         }
1296                         elsif (/^From:\s+(.*)$/) {
1297                                 ($author, $author_encoding) = unquote_rfc2047($1);
1298                                 next if $suppress_cc{'author'};
1299                                 next if $suppress_cc{'self'} and $author eq $sender;
1300                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1301                                         $1, $_) unless $quiet;
1302                                 push @cc, $1;
1303                         }
1304                         elsif (/^To:\s+(.*)$/) {
1305                                 foreach my $addr (parse_address_line($1)) {
1306                                         printf("(mbox) Adding to: %s from line '%s'\n",
1307                                                 $addr, $_) unless $quiet;
1308                                         push @to, $addr;
1309                                 }
1310                         }
1311                         elsif (/^Cc:\s+(.*)$/) {
1312                                 foreach my $addr (parse_address_line($1)) {
1313                                         if (unquote_rfc2047($addr) eq $sender) {
1314                                                 next if ($suppress_cc{'self'});
1315                                         } else {
1316                                                 next if ($suppress_cc{'cc'});
1317                                         }
1318                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1319                                                 $addr, $_) unless $quiet;
1320                                         push @cc, $addr;
1321                                 }
1322                         }
1323                         elsif (/^Content-type:/i) {
1324                                 $has_content_type = 1;
1325                                 if (/charset="?([^ "]+)/) {
1326                                         $body_encoding = $1;
1327                                 }
1328                                 push @xh, $_;
1329                         }
1330                         elsif (/^Message-Id: (.*)/i) {
1331                                 $message_id = $1;
1332                         }
1333                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1334                                 push @xh, $_;
1335                         }
1336
1337                 } else {
1338                         # In the traditional
1339                         # "send lots of email" format,
1340                         # line 1 = cc
1341                         # line 2 = subject
1342                         # So let's support that, too.
1343                         $input_format = 'lots';
1344                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1345                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1346                                         $_, $_) unless $quiet;
1347                                 push @cc, $_;
1348                         } elsif (!defined $subject) {
1349                                 $subject = $_;
1350                         }
1351                 }
1352         }
1353         # Now parse the message body
1354         while(<$fh>) {
1355                 $message .=  $_;
1356                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1357                         chomp;
1358                         my ($what, $c) = ($1, $2);
1359                         chomp $c;
1360                         if ($c eq $sender) {
1361                                 next if ($suppress_cc{'self'});
1362                         } else {
1363                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1364                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1365                         }
1366                         push @cc, $c;
1367                         printf("(body) Adding cc: %s from line '%s'\n",
1368                                 $c, $_) unless $quiet;
1369                 }
1370         }
1371         close $fh;
1372
1373         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1374                 if defined $to_cmd;
1375         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1376                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1377
1378         if ($broken_encoding{$t} && !$has_content_type) {
1379                 $has_content_type = 1;
1380                 push @xh, "MIME-Version: 1.0",
1381                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1382                         "Content-Transfer-Encoding: 8bit";
1383                 $body_encoding = $auto_8bit_encoding;
1384         }
1385
1386         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1387                 $subject = quote_subject($subject, $auto_8bit_encoding);
1388         }
1389
1390         if (defined $author and $author ne $sender) {
1391                 $message = "From: $author\n\n$message";
1392                 if (defined $author_encoding) {
1393                         if ($has_content_type) {
1394                                 if ($body_encoding eq $author_encoding) {
1395                                         # ok, we already have the right encoding
1396                                 }
1397                                 else {
1398                                         # uh oh, we should re-encode
1399                                 }
1400                         }
1401                         else {
1402                                 $has_content_type = 1;
1403                                 push @xh,
1404                                   'MIME-Version: 1.0',
1405                                   "Content-Type: text/plain; charset=$author_encoding",
1406                                   'Content-Transfer-Encoding: 8bit';
1407                         }
1408                 }
1409         }
1410
1411         $needs_confirm = (
1412                 $confirm eq "always" or
1413                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1414                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1415         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1416
1417         @to = validate_address_list(sanitize_address_list(@to));
1418         @cc = validate_address_list(sanitize_address_list(@cc));
1419
1420         @to = (@initial_to, @to);
1421         @cc = (@initial_cc, @cc);
1422
1423         my $message_was_sent = send_message();
1424
1425         # set up for the next message
1426         if ($thread && $message_was_sent &&
1427                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0 ||
1428                 $message_num == 1)) {
1429                 $reply_to = $message_id;
1430                 if (length $references > 0) {
1431                         $references .= "\n $message_id";
1432                 } else {
1433                         $references = "$message_id";
1434                 }
1435         }
1436         $message_id = undef;
1437 }
1438
1439 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1440 # and return a results array
1441 sub recipients_cmd {
1442         my ($prefix, $what, $cmd, $file) = @_;
1443
1444         my $sanitized_sender = sanitize_address($sender);
1445         my @addresses = ();
1446         open my $fh, "$cmd \Q$file\E |"
1447             or die "($prefix) Could not execute '$cmd'";
1448         while (my $address = <$fh>) {
1449                 $address =~ s/^\s*//g;
1450                 $address =~ s/\s*$//g;
1451                 $address = sanitize_address($address);
1452                 next if ($address eq $sanitized_sender and $suppress_from);
1453                 push @addresses, $address;
1454                 printf("($prefix) Adding %s: %s from: '%s'\n",
1455                        $what, $address, $cmd) unless $quiet;
1456                 }
1457         close $fh
1458             or die "($prefix) failed to close pipe to '$cmd'";
1459         return @addresses;
1460 }
1461
1462 cleanup_compose_files();
1463
1464 sub cleanup_compose_files {
1465         unlink($compose_filename, $compose_filename . ".final") if $compose;
1466 }
1467
1468 $smtp->quit if $smtp;
1469
1470 sub unique_email_list {
1471         my %seen;
1472         my @emails;
1473
1474         foreach my $entry (@_) {
1475                 my $clean = extract_valid_address_or_die($entry);
1476                 $seen{$clean} ||= 0;
1477                 next if $seen{$clean}++;
1478                 push @emails, $entry;
1479         }
1480         return @emails;
1481 }
1482
1483 sub validate_patch {
1484         my $fn = shift;
1485         open(my $fh, '<', $fn)
1486                 or die "unable to open $fn: $!\n";
1487         while (my $line = <$fh>) {
1488                 if (length($line) > 998) {
1489                         return "$.: patch contains a line longer than 998 characters";
1490                 }
1491         }
1492         return undef;
1493 }
1494
1495 sub file_has_nonascii {
1496         my $fn = shift;
1497         open(my $fh, '<', $fn)
1498                 or die "unable to open $fn: $!\n";
1499         while (my $line = <$fh>) {
1500                 return 1 if $line =~ /[^[:ascii:]]/;
1501         }
1502         return 0;
1503 }
1504
1505 sub body_or_subject_has_nonascii {
1506         my $fn = shift;
1507         open(my $fh, '<', $fn)
1508                 or die "unable to open $fn: $!\n";
1509         while (my $line = <$fh>) {
1510                 last if $line =~ /^$/;
1511                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1512         }
1513         while (my $line = <$fh>) {
1514                 return 1 if $line =~ /[^[:ascii:]]/;
1515         }
1516         return 0;
1517 }