git.oblomov.eu Git - git/blob - gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101 # URI of GIT logo (72x27 size)
 102 our $logo = "++GITWEB_LOGO++";
 103 # URI of GIT favicon, assumed to be image/png type
 104 our $favicon = "++GITWEB_FAVICON++";
 105 # URI of gitweb.js (JavaScript code for gitweb)
 106 our $javascript = "++GITWEB_JS++";
 107
 108 # URI and label (title) of GIT logo link
 109 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 110 #our $logo_label = "git documentation";
 111 our $logo_url = "http://git-scm.com/";
 112 our $logo_label = "git homepage";
 113
 114 # source of projects list
 115 our $projects_list = "++GITWEB_LIST++";
 116
 117 # the width (in characters) of the projects list "Description" column
 118 our $projects_list_description_width = 25;
 119
 120 # group projects by category on the projects list
 121 # (enabled if this variable evaluates to true)
 122 our $projects_list_group_categories = 0;
 123
 124 # default category if none specified
 125 # (leave the empty string for no category)
 126 our $project_list_default_category = "";
 127
 128 # default order of projects list
 129 # valid values are none, project, descr, owner, and age
 130 our $default_projects_order = "project";
 131
 132 # show repository only if this file exists
 133 # (only effective if this variable evaluates to true)
 134 our $export_ok = "++GITWEB_EXPORT_OK++";
 135
 136 # show repository only if this subroutine returns true
 137 # when given the path to the project, for example:
 138 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 139 our $export_auth_hook = undef;
 140
 141 # only allow viewing of repositories also shown on the overview page
 142 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 143
 144 # list of git base URLs used for URL to where fetch project from,
 145 # i.e. full URL is "$git_base_url/$project"
 146 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 147
 148 # default blob_plain mimetype and default charset for text/plain blob
 149 our $default_blob_plain_mimetype = 'text/plain';
 150 our $default_text_plain_charset  = undef;
 151
 152 # file to use for guessing MIME types before trying /etc/mime.types
 153 # (relative to the current git repository)
 154 our $mimetypes_file = undef;
 155
 156 # assume this charset if line contains non-UTF-8 characters;
 157 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 158 # for which encoding all byte sequences are valid, for example
 159 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 160 # could be even 'utf-8' for the old behavior)
 161 our $fallback_encoding = 'latin1';
 162
 163 # rename detection options for git-diff and git-diff-tree
 164 # - default is '-M', with the cost proportional to
 165 #   (number of removed files) * (number of new files).
 166 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 167 #   (number of changed files + number of removed files) * (number of new files)
 168 # - even more costly is '-C', '--find-copies-harder' with cost
 169 #   (number of files in the original tree) * (number of new files)
 170 # - one might want to include '-B' option, e.g. '-B', '-M'
 171 our @diff_opts = ('-M'); # taken from git_commit
 172
 173 # Disables features that would allow repository owners to inject script into
 174 # the gitweb domain.
 175 our $prevent_xss = 0;
 176
 177 # Path to the highlight executable to use (must be the one from
 178 # http://www.andre-simon.de due to assumptions about parameters and output).
 179 # Useful if highlight is not installed on your webserver's PATH.
 180 # [Default: highlight]
 181 our $highlight_bin = "++HIGHLIGHT_BIN++";
 182
 183 # information about snapshot formats that gitweb is capable of serving
 184 our %known_snapshot_formats = (
 185         # name => {
 186         #       'display' => display name,
 187         #       'type' => mime type,
 188         #       'suffix' => filename suffix,
 189         #       'format' => --format for git-archive,
 190         #       'compressor' => [compressor command and arguments]
 191         #                       (array reference, optional)
 192         #       'disabled' => boolean (optional)}
 193         #
 194         'tgz' => {
 195                 'display' => 'tar.gz',
 196                 'type' => 'application/x-gzip',
 197                 'suffix' => '.tar.gz',
 198                 'format' => 'tar',
 199                 'compressor' => ['gzip', '-n']},
 200
 201         'tbz2' => {
 202                 'display' => 'tar.bz2',
 203                 'type' => 'application/x-bzip2',
 204                 'suffix' => '.tar.bz2',
 205                 'format' => 'tar',
 206                 'compressor' => ['bzip2']},
 207
 208         'txz' => {
 209                 'display' => 'tar.xz',
 210                 'type' => 'application/x-xz',
 211                 'suffix' => '.tar.xz',
 212                 'format' => 'tar',
 213                 'compressor' => ['xz'],
 214                 'disabled' => 1},
 215
 216         'zip' => {
 217                 'display' => 'zip',
 218                 'type' => 'application/x-zip',
 219                 'suffix' => '.zip',
 220                 'format' => 'zip'},
 221 );
 222
 223 # Aliases so we understand old gitweb.snapshot values in repository
 224 # configuration.
 225 our %known_snapshot_format_aliases = (
 226         'gzip'  => 'tgz',
 227         'bzip2' => 'tbz2',
 228         'xz'    => 'txz',
 229
 230         # backward compatibility: legacy gitweb config support
 231         'x-gzip' => undef, 'gz' => undef,
 232         'x-bzip2' => undef, 'bz2' => undef,
 233         'x-zip' => undef, '' => undef,
 234 );
 235
 236 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 237 # are changed, it may be appropriate to change these values too via
 238 # $GITWEB_CONFIG.
 239 our %avatar_size = (
 240         'default' => 16,
 241         'double'  => 32
 242 );
 243
 244 # Used to set the maximum load that we will still respond to gitweb queries.
 245 # If server load exceed this value then return "503 server busy" error.
 246 # If gitweb cannot determined server load, it is taken to be 0.
 247 # Leave it undefined (or set to 'undef') to turn off load checking.
 248 our $maxload = 300;
 249
 250 # configuration for 'highlight' (http://www.andre-simon.de/)
 251 # match by basename
 252 our %highlight_basename = (
 253         #'Program' => 'py',
 254         #'Library' => 'py',
 255         'SConstruct' => 'py', # SCons equivalent of Makefile
 256         'Makefile' => 'make',
 257 );
 258 # match by extension
 259 our %highlight_ext = (
 260         # main extensions, defining name of syntax;
 261         # see files in /usr/share/highlight/langDefs/ directory
 262         map { $_ => $_ }
 263                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 264         # alternate extensions, see /etc/highlight/filetypes.conf
 265         'h' => 'c',
 266         map { $_ => 'sh'  } qw(bash zsh ksh),
 267         map { $_ => 'cpp' } qw(cxx c++ cc),
 268         map { $_ => 'php' } qw(php3 php4 php5 phps),
 269         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 270         map { $_ => 'make'} qw(mak mk),
 271         map { $_ => 'xml' } qw(xhtml html htm),
 272 );
 273
 274 # You define site-wide feature defaults here; override them with
 275 # $GITWEB_CONFIG as necessary.
 276 our %feature = (
 277         # feature => {
 278         #       'sub' => feature-sub (subroutine),
 279         #       'override' => allow-override (boolean),
 280         #       'default' => [ default options...] (array reference)}
 281         #
 282         # if feature is overridable (it means that allow-override has true value),
 283         # then feature-sub will be called with default options as parameters;
 284         # return value of feature-sub indicates if to enable specified feature
 285         #
 286         # if there is no 'sub' key (no feature-sub), then feature cannot be
 287         # overridden
 288         #
 289         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 290         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 291         # is enabled
 292
 293         # Enable the 'blame' blob view, showing the last commit that modified
 294         # each line in the file. This can be very CPU-intensive.
 295
 296         # To enable system wide have in $GITWEB_CONFIG
 297         # $feature{'blame'}{'default'} = [1];
 298         # To have project specific config enable override in $GITWEB_CONFIG
 299         # $feature{'blame'}{'override'} = 1;
 300         # and in project config gitweb.blame = 0|1;
 301         'blame' => {
 302                 'sub' => sub { feature_bool('blame', @_) },
 303                 'override' => 0,
 304                 'default' => [0]},
 305
 306         # Enable the 'snapshot' link, providing a compressed archive of any
 307         # tree. This can potentially generate high traffic if you have large
 308         # project.
 309
 310         # Value is a list of formats defined in %known_snapshot_formats that
 311         # you wish to offer.
 312         # To disable system wide have in $GITWEB_CONFIG
 313         # $feature{'snapshot'}{'default'} = [];
 314         # To have project specific config enable override in $GITWEB_CONFIG
 315         # $feature{'snapshot'}{'override'} = 1;
 316         # and in project config, a comma-separated list of formats or "none"
 317         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 318         'snapshot' => {
 319                 'sub' => \&feature_snapshot,
 320                 'override' => 0,
 321                 'default' => ['tgz']},
 322
 323         # Enable text search, which will list the commits which match author,
 324         # committer or commit text to a given string.  Enabled by default.
 325         # Project specific override is not supported.
 326         #
 327         # Note that this controls all search features, which means that if
 328         # it is disabled, then 'grep' and 'pickaxe' search would also be
 329         # disabled.
 330         'search' => {
 331                 'override' => 0,
 332                 'default' => [1]},
 333
 334         # Enable grep search, which will list the files in currently selected
 335         # tree containing the given string. Enabled by default. This can be
 336         # potentially CPU-intensive, of course.
 337         # Note that you need to have 'search' feature enabled too.
 338
 339         # To enable system wide have in $GITWEB_CONFIG
 340         # $feature{'grep'}{'default'} = [1];
 341         # To have project specific config enable override in $GITWEB_CONFIG
 342         # $feature{'grep'}{'override'} = 1;
 343         # and in project config gitweb.grep = 0|1;
 344         'grep' => {
 345                 'sub' => sub { feature_bool('grep', @_) },
 346                 'override' => 0,
 347                 'default' => [1]},
 348
 349         # Enable the pickaxe search, which will list the commits that modified
 350         # a given string in a file. This can be practical and quite faster
 351         # alternative to 'blame', but still potentially CPU-intensive.
 352         # Note that you need to have 'search' feature enabled too.
 353
 354         # To enable system wide have in $GITWEB_CONFIG
 355         # $feature{'pickaxe'}{'default'} = [1];
 356         # To have project specific config enable override in $GITWEB_CONFIG
 357         # $feature{'pickaxe'}{'override'} = 1;
 358         # and in project config gitweb.pickaxe = 0|1;
 359         'pickaxe' => {
 360                 'sub' => sub { feature_bool('pickaxe', @_) },
 361                 'override' => 0,
 362                 'default' => [1]},
 363
 364         # Enable showing size of blobs in a 'tree' view, in a separate
 365         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 366
 367         # To disable system wide have in $GITWEB_CONFIG
 368         # $feature{'show-sizes'}{'default'} = [0];
 369         # To have project specific config enable override in $GITWEB_CONFIG
 370         # $feature{'show-sizes'}{'override'} = 1;
 371         # and in project config gitweb.showsizes = 0|1;
 372         'show-sizes' => {
 373                 'sub' => sub { feature_bool('showsizes', @_) },
 374                 'override' => 0,
 375                 'default' => [1]},
 376
 377         # Make gitweb use an alternative format of the URLs which can be
 378         # more readable and natural-looking: project name is embedded
 379         # directly in the path and the query string contains other
 380         # auxiliary information. All gitweb installations recognize
 381         # URL in either format; this configures in which formats gitweb
 382         # generates links.
 383
 384         # To enable system wide have in $GITWEB_CONFIG
 385         # $feature{'pathinfo'}{'default'} = [1];
 386         # Project specific override is not supported.
 387
 388         # Note that you will need to change the default location of CSS,
 389         # favicon, logo and possibly other files to an absolute URL. Also,
 390         # if gitweb.cgi serves as your indexfile, you will need to force
 391         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 392         'pathinfo' => {
 393                 'override' => 0,
 394                 'default' => [0]},
 395
 396         # Make gitweb consider projects in project root subdirectories
 397         # to be forks of existing projects. Given project $projname.git,
 398         # projects matching $projname/*.git will not be shown in the main
 399         # projects list, instead a '+' mark will be added to $projname
 400         # there and a 'forks' view will be enabled for the project, listing
 401         # all the forks. If project list is taken from a file, forks have
 402         # to be listed after the main project.
 403
 404         # To enable system wide have in $GITWEB_CONFIG
 405         # $feature{'forks'}{'default'} = [1];
 406         # Project specific override is not supported.
 407         'forks' => {
 408                 'override' => 0,
 409                 'default' => [0]},
 410
 411         # Insert custom links to the action bar of all project pages.
 412         # This enables you mainly to link to third-party scripts integrating
 413         # into gitweb; e.g. git-browser for graphical history representation
 414         # or custom web-based repository administration interface.
 415
 416         # The 'default' value consists of a list of triplets in the form
 417         # (label, link, position) where position is the label after which
 418         # to insert the link and link is a format string where %n expands
 419         # to the project name, %f to the project path within the filesystem,
 420         # %h to the current hash (h gitweb parameter) and %b to the current
 421         # hash base (hb gitweb parameter); %% expands to %.
 422
 423         # To enable system wide have in $GITWEB_CONFIG e.g.
 424         # $feature{'actions'}{'default'} = [('graphiclog',
 425         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 426         # Project specific override is not supported.
 427         'actions' => {
 428                 'override' => 0,
 429                 'default' => []},
 430
 431         # Allow gitweb scan project content tags of project repository,
 432         # and display the popular Web 2.0-ish "tag cloud" near the projects
 433         # list.  Note that this is something COMPLETELY different from the
 434         # normal Git tags.
 435
 436         # gitweb by itself can show existing tags, but it does not handle
 437         # tagging itself; you need to do it externally, outside gitweb.
 438         # The format is described in git_get_project_ctags() subroutine.
 439         # You may want to install the HTML::TagCloud Perl module to get
 440         # a pretty tag cloud instead of just a list of tags.
 441
 442         # To enable system wide have in $GITWEB_CONFIG
 443         # $feature{'ctags'}{'default'} = [1];
 444         # Project specific override is not supported.
 445
 446         # In the future whether ctags editing is enabled might depend
 447         # on the value, but using 1 should always mean no editing of ctags.
 448         'ctags' => {
 449                 'override' => 0,
 450                 'default' => [0]},
 451
 452         # The maximum number of patches in a patchset generated in patch
 453         # view. Set this to 0 or undef to disable patch view, or to a
 454         # negative number to remove any limit.
 455
 456         # To disable system wide have in $GITWEB_CONFIG
 457         # $feature{'patches'}{'default'} = [0];
 458         # To have project specific config enable override in $GITWEB_CONFIG
 459         # $feature{'patches'}{'override'} = 1;
 460         # and in project config gitweb.patches = 0|n;
 461         # where n is the maximum number of patches allowed in a patchset.
 462         'patches' => {
 463                 'sub' => \&feature_patches,
 464                 'override' => 0,
 465                 'default' => [16]},
 466
 467         # Avatar support. When this feature is enabled, views such as
 468         # shortlog or commit will display an avatar associated with
 469         # the email of the committer(s) and/or author(s).
 470
 471         # Currently available providers are gravatar and picon.
 472         # If an unknown provider is specified, the feature is disabled.
 473
 474         # Gravatar depends on Digest::MD5.
 475         # Picon currently relies on the indiana.edu database.
 476
 477         # To enable system wide have in $GITWEB_CONFIG
 478         # $feature{'avatar'}{'default'} = ['<provider>'];
 479         # where <provider> is either gravatar or picon.
 480         # To have project specific config enable override in $GITWEB_CONFIG
 481         # $feature{'avatar'}{'override'} = 1;
 482         # and in project config gitweb.avatar = <provider>;
 483         'avatar' => {
 484                 'sub' => \&feature_avatar,
 485                 'override' => 0,
 486                 'default' => ['']},
 487
 488         # Enable displaying how much time and how many git commands
 489         # it took to generate and display page.  Disabled by default.
 490         # Project specific override is not supported.
 491         'timed' => {
 492                 'override' => 0,
 493                 'default' => [0]},
 494
 495         # Enable turning some links into links to actions which require
 496         # JavaScript to run (like 'blame_incremental').  Not enabled by
 497         # default.  Project specific override is currently not supported.
 498         'javascript-actions' => {
 499                 'override' => 0,
 500                 'default' => [0]},
 501
 502         # Enable and configure ability to change common timezone for dates
 503         # in gitweb output via JavaScript.  Enabled by default.
 504         # Project specific override is not supported.
 505         'javascript-timezone' => {
 506                 'override' => 0,
 507                 'default' => [
 508                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 509                                      # or undef to turn off this feature
 510                         'gitweb_tz', # name of cookie where to store selected timezone
 511                         'datetime',  # CSS class used to mark up dates for manipulation
 512                 ]},
 513
 514         # Syntax highlighting support. This is based on Daniel Svensson's
 515         # and Sham Chukoury's work in gitweb-xmms2.git.
 516         # It requires the 'highlight' program present in $PATH,
 517         # and therefore is disabled by default.
 518
 519         # To enable system wide have in $GITWEB_CONFIG
 520         # $feature{'highlight'}{'default'} = [1];
 521
 522         'highlight' => {
 523                 'sub' => sub { feature_bool('highlight', @_) },
 524                 'override' => 0,
 525                 'default' => [0]},
 526
 527         # Enable displaying of remote heads in the heads list
 528
 529         # To enable system wide have in $GITWEB_CONFIG
 530         # $feature{'remote_heads'}{'default'} = [1];
 531         # To have project specific config enable override in $GITWEB_CONFIG
 532         # $feature{'remote_heads'}{'override'} = 1;
 533         # and in project config gitweb.remote_heads = 0|1;
 534         'remote_heads' => {
 535                 'sub' => sub { feature_bool('remote_heads', @_) },
 536                 'override' => 0,
 537                 'default' => [0]},
 538 );
 539
 540 sub gitweb_get_feature {
 541         my ($name) = @_;
 542         return unless exists $feature{$name};
 543         my ($sub, $override, @defaults) = (
 544                 $feature{$name}{'sub'},
 545                 $feature{$name}{'override'},
 546                 @{$feature{$name}{'default'}});
 547         # project specific override is possible only if we have project
 548         our $git_dir; # global variable, declared later
 549         if (!$override || !defined $git_dir) {
 550                 return @defaults;
 551         }
 552         if (!defined $sub) {
 553                 warn "feature $name is not overridable";
 554                 return @defaults;
 555         }
 556         return $sub->(@defaults);
 557 }
 558
 559 # A wrapper to check if a given feature is enabled.
 560 # With this, you can say
 561 #
 562 #   my $bool_feat = gitweb_check_feature('bool_feat');
 563 #   gitweb_check_feature('bool_feat') or somecode;
 564 #
 565 # instead of
 566 #
 567 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 568 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 569 #
 570 sub gitweb_check_feature {
 571         return (gitweb_get_feature(@_))[0];
 572 }
 573
 574
 575 sub feature_bool {
 576         my $key = shift;
 577         my ($val) = git_get_project_config($key, '--bool');
 578
 579         if (!defined $val) {
 580                 return ($_[0]);
 581         } elsif ($val eq 'true') {
 582                 return (1);
 583         } elsif ($val eq 'false') {
 584                 return (0);
 585         }
 586 }
 587
 588 sub feature_snapshot {
 589         my (@fmts) = @_;
 590
 591         my ($val) = git_get_project_config('snapshot');
 592
 593         if ($val) {
 594                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 595         }
 596
 597         return @fmts;
 598 }
 599
 600 sub feature_patches {
 601         my @val = (git_get_project_config('patches', '--int'));
 602
 603         if (@val) {
 604                 return @val;
 605         }
 606
 607         return ($_[0]);
 608 }
 609
 610 sub feature_avatar {
 611         my @val = (git_get_project_config('avatar'));
 612
 613         return @val ? @val : @_;
 614 }
 615
 616 # checking HEAD file with -e is fragile if the repository was
 617 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 618 # and then pruned.
 619 sub check_head_link {
 620         my ($dir) = @_;
 621         my $headfile = "$dir/HEAD";
 622         return ((-e $headfile) ||
 623                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 624 }
 625
 626 sub check_export_ok {
 627         my ($dir) = @_;
 628         return (check_head_link($dir) &&
 629                 (!$export_ok || -e "$dir/$export_ok") &&
 630                 (!$export_auth_hook || $export_auth_hook->($dir)));
 631 }
 632
 633 # process alternate names for backward compatibility
 634 # filter out unsupported (unknown) snapshot formats
 635 sub filter_snapshot_fmts {
 636         my @fmts = @_;
 637
 638         @fmts = map {
 639                 exists $known_snapshot_format_aliases{$_} ?
 640                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 641         @fmts = grep {
 642                 exists $known_snapshot_formats{$_} &&
 643                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 644 }
 645
 646 # If it is set to code reference, it is code that it is to be run once per
 647 # request, allowing updating configurations that change with each request,
 648 # while running other code in config file only once.
 649 #
 650 # Otherwise, if it is false then gitweb would process config file only once;
 651 # if it is true then gitweb config would be run for each request.
 652 our $per_request_config = 1;
 653
 654 # read and parse gitweb config file given by its parameter.
 655 # returns true on success, false on recoverable error, allowing
 656 # to chain this subroutine, using first file that exists.
 657 # dies on errors during parsing config file, as it is unrecoverable.
 658 sub read_config_file {
 659         my $filename = shift;
 660         return unless defined $filename;
 661         # die if there are errors parsing config file
 662         if (-e $filename) {
 663                 do $filename;
 664                 die $@ if $@;
 665                 return 1;
 666         }
 667         return;
 668 }
 669
 670 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 671 sub evaluate_gitweb_config {
 672         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 673         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 674         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 675
 676         # Protect agains duplications of file names, to not read config twice.
 677         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 678         # there possibility of duplication of filename there doesn't matter.
 679         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 680         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 681
 682         # Common system-wide settings for convenience.
 683         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 684         read_config_file($GITWEB_CONFIG_COMMON);
 685
 686         # Use first config file that exists.  This means use the per-instance
 687         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 688         read_config_file($GITWEB_CONFIG) and return;
 689         read_config_file($GITWEB_CONFIG_SYSTEM);
 690 }
 691
 692 # Get loadavg of system, to compare against $maxload.
 693 # Currently it requires '/proc/loadavg' present to get loadavg;
 694 # if it is not present it returns 0, which means no load checking.
 695 sub get_loadavg {
 696         if( -e '/proc/loadavg' ){
 697                 open my $fd, '<', '/proc/loadavg'
 698                         or return 0;
 699                 my @load = split(/\s+/, scalar <$fd>);
 700                 close $fd;
 701
 702                 # The first three columns measure CPU and IO utilization of the last one,
 703                 # five, and 10 minute periods.  The fourth column shows the number of
 704                 # currently running processes and the total number of processes in the m/n
 705                 # format.  The last column displays the last process ID used.
 706                 return $load[0] || 0;
 707         }
 708         # additional checks for load average should go here for things that don't export
 709         # /proc/loadavg
 710
 711         return 0;
 712 }
 713
 714 # version of the core git binary
 715 our $git_version;
 716 sub evaluate_git_version {
 717         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 718         $number_of_git_cmds++;
 719 }
 720
 721 sub check_loadavg {
 722         if (defined $maxload && get_loadavg() > $maxload) {
 723                 die_error(503, "The load average on the server is too high");
 724         }
 725 }
 726
 727 # ======================================================================
 728 # input validation and dispatch
 729
 730 # input parameters can be collected from a variety of sources (presently, CGI
 731 # and PATH_INFO), so we define an %input_params hash that collects them all
 732 # together during validation: this allows subsequent uses (e.g. href()) to be
 733 # agnostic of the parameter origin
 734
 735 our %input_params = ();
 736
 737 # input parameters are stored with the long parameter name as key. This will
 738 # also be used in the href subroutine to convert parameters to their CGI
 739 # equivalent, and since the href() usage is the most frequent one, we store
 740 # the name -> CGI key mapping here, instead of the reverse.
 741 #
 742 # XXX: Warning: If you touch this, check the search form for updating,
 743 # too.
 744
 745 our @cgi_param_mapping = (
 746         project => "p",
 747         action => "a",
 748         file_name => "f",
 749         file_parent => "fp",
 750         hash => "h",
 751         hash_parent => "hp",
 752         hash_base => "hb",
 753         hash_parent_base => "hpb",
 754         page => "pg",
 755         order => "o",
 756         searchtext => "s",
 757         searchtype => "st",
 758         snapshot_format => "sf",
 759         extra_options => "opt",
 760         search_use_regexp => "sr",
 761         ctag => "by_tag",
 762         diff_style => "ds",
 763         project_filter => "pf",
 764         # this must be last entry (for manipulation from JavaScript)
 765         javascript => "js"
 766 );
 767 our %cgi_param_mapping = @cgi_param_mapping;
 768
 769 # we will also need to know the possible actions, for validation
 770 our %actions = (
 771         "blame" => \&git_blame,
 772         "blame_incremental" => \&git_blame_incremental,
 773         "blame_data" => \&git_blame_data,
 774         "blobdiff" => \&git_blobdiff,
 775         "blobdiff_plain" => \&git_blobdiff_plain,
 776         "blob" => \&git_blob,
 777         "blob_plain" => \&git_blob_plain,
 778         "commitdiff" => \&git_commitdiff,
 779         "commitdiff_plain" => \&git_commitdiff_plain,
 780         "commit" => \&git_commit,
 781         "forks" => \&git_forks,
 782         "heads" => \&git_heads,
 783         "history" => \&git_history,
 784         "log" => \&git_log,
 785         "patch" => \&git_patch,
 786         "patches" => \&git_patches,
 787         "remotes" => \&git_remotes,
 788         "rss" => \&git_rss,
 789         "atom" => \&git_atom,
 790         "search" => \&git_search,
 791         "search_help" => \&git_search_help,
 792         "shortlog" => \&git_shortlog,
 793         "summary" => \&git_summary,
 794         "tag" => \&git_tag,
 795         "tags" => \&git_tags,
 796         "tree" => \&git_tree,
 797         "snapshot" => \&git_snapshot,
 798         "object" => \&git_object,
 799         # those below don't need $project
 800         "opml" => \&git_opml,
 801         "project_list" => \&git_project_list,
 802         "project_index" => \&git_project_index,
 803 );
 804
 805 # finally, we have the hash of allowed extra_options for the commands that
 806 # allow them
 807 our %allowed_options = (
 808         "--no-merges" => [ qw(rss atom log shortlog history) ],
 809 );
 810
 811 # fill %input_params with the CGI parameters. All values except for 'opt'
 812 # should be single values, but opt can be an array. We should probably
 813 # build an array of parameters that can be multi-valued, but since for the time
 814 # being it's only this one, we just single it out
 815 sub evaluate_query_params {
 816         our $cgi;
 817
 818         while (my ($name, $symbol) = each %cgi_param_mapping) {
 819                 if ($symbol eq 'opt') {
 820                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->param($symbol) ];
 821                 } else {
 822                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 823                 }
 824         }
 825 }
 826
 827 # now read PATH_INFO and update the parameter list for missing parameters
 828 sub evaluate_path_info {
 829         return if defined $input_params{'project'};
 830         return if !$path_info;
 831         $path_info =~ s,^/+,,;
 832         return if !$path_info;
 833
 834         # find which part of PATH_INFO is project
 835         my $project = $path_info;
 836         $project =~ s,/+$,,;
 837         while ($project && !check_head_link("$projectroot/$project")) {
 838                 $project =~ s,/*[^/]*$,,;
 839         }
 840         return unless $project;
 841         $input_params{'project'} = $project;
 842
 843         # do not change any parameters if an action is given using the query string
 844         return if $input_params{'action'};
 845         $path_info =~ s,^\Q$project\E/*,,;
 846
 847         # next, check if we have an action
 848         my $action = $path_info;
 849         $action =~ s,/.*$,,;
 850         if (exists $actions{$action}) {
 851                 $path_info =~ s,^$action/*,,;
 852                 $input_params{'action'} = $action;
 853         }
 854
 855         # list of actions that want hash_base instead of hash, but can have no
 856         # pathname (f) parameter
 857         my @wants_base = (
 858                 'tree',
 859                 'history',
 860         );
 861
 862         # we want to catch, among others
 863         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 864         my ($parentrefname, $parentpathname, $refname, $pathname) =
 865                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 866
 867         # first, analyze the 'current' part
 868         if (defined $pathname) {
 869                 # we got "branch:filename" or "branch:dir/"
 870                 # we could use git_get_type(branch:pathname), but:
 871                 # - it needs $git_dir
 872                 # - it does a git() call
 873                 # - the convention of terminating directories with a slash
 874                 #   makes it superfluous
 875                 # - embedding the action in the PATH_INFO would make it even
 876                 #   more superfluous
 877                 $pathname =~ s,^/+,,;
 878                 if (!$pathname || substr($pathname, -1) eq "/") {
 879                         $input_params{'action'} ||= "tree";
 880                         $pathname =~ s,/$,,;
 881                 } else {
 882                         # the default action depends on whether we had parent info
 883                         # or not
 884                         if ($parentrefname) {
 885                                 $input_params{'action'} ||= "blobdiff_plain";
 886                         } else {
 887                                 $input_params{'action'} ||= "blob_plain";
 888                         }
 889                 }
 890                 $input_params{'hash_base'} ||= $refname;
 891                 $input_params{'file_name'} ||= $pathname;
 892         } elsif (defined $refname) {
 893                 # we got "branch". In this case we have to choose if we have to
 894                 # set hash or hash_base.
 895                 #
 896                 # Most of the actions without a pathname only want hash to be
 897                 # set, except for the ones specified in @wants_base that want
 898                 # hash_base instead. It should also be noted that hand-crafted
 899                 # links having 'history' as an action and no pathname or hash
 900                 # set will fail, but that happens regardless of PATH_INFO.
 901                 if (defined $parentrefname) {
 902                         # if there is parent let the default be 'shortlog' action
 903                         # (for http://git.example.com/repo.git/A..B links); if there
 904                         # is no parent, dispatch will detect type of object and set
 905                         # action appropriately if required (if action is not set)
 906                         $input_params{'action'} ||= "shortlog";
 907                 }
 908                 if ($input_params{'action'} &&
 909                     grep { $_ eq $input_params{'action'} } @wants_base) {
 910                         $input_params{'hash_base'} ||= $refname;
 911                 } else {
 912                         $input_params{'hash'} ||= $refname;
 913                 }
 914         }
 915
 916         # next, handle the 'parent' part, if present
 917         if (defined $parentrefname) {
 918                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 919                 # someproject/blobdiff/oldrev..newrev:/filename
 920                 if ($parentpathname) {
 921                         $parentpathname =~ s,^/+,,;
 922                         $parentpathname =~ s,/$,,;
 923                         $input_params{'file_parent'} ||= $parentpathname;
 924                 } else {
 925                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 926                 }
 927                 # we assume that hash_parent_base is wanted if a path was specified,
 928                 # or if the action wants hash_base instead of hash
 929                 if (defined $input_params{'file_parent'} ||
 930                         grep { $_ eq $input_params{'action'} } @wants_base) {
 931                         $input_params{'hash_parent_base'} ||= $parentrefname;
 932                 } else {
 933                         $input_params{'hash_parent'} ||= $parentrefname;
 934                 }
 935         }
 936
 937         # for the snapshot action, we allow URLs in the form
 938         # $project/snapshot/$hash.ext
 939         # where .ext determines the snapshot and gets removed from the
 940         # passed $refname to provide the $hash.
 941         #
 942         # To be able to tell that $refname includes the format extension, we
 943         # require the following two conditions to be satisfied:
 944         # - the hash input parameter MUST have been set from the $refname part
 945         #   of the URL (i.e. they must be equal)
 946         # - the snapshot format MUST NOT have been defined already (e.g. from
 947         #   CGI parameter sf)
 948         # It's also useless to try any matching unless $refname has a dot,
 949         # so we check for that too
 950         if (defined $input_params{'action'} &&
 951                 $input_params{'action'} eq 'snapshot' &&
 952                 defined $refname && index($refname, '.') != -1 &&
 953                 $refname eq $input_params{'hash'} &&
 954                 !defined $input_params{'snapshot_format'}) {
 955                 # We loop over the known snapshot formats, checking for
 956                 # extensions. Allowed extensions are both the defined suffix
 957                 # (which includes the initial dot already) and the snapshot
 958                 # format key itself, with a prepended dot
 959                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 960                         my $hash = $refname;
 961                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 962                                 next;
 963                         }
 964                         my $sfx = $1;
 965                         # a valid suffix was found, so set the snapshot format
 966                         # and reset the hash parameter
 967                         $input_params{'snapshot_format'} = $fmt;
 968                         $input_params{'hash'} = $hash;
 969                         # we also set the format suffix to the one requested
 970                         # in the URL: this way a request for e.g. .tgz returns
 971                         # a .tgz instead of a .tar.gz
 972                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 973                         last;
 974                 }
 975         }
 976 }
 977
 978 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 979      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 980      $searchtext, $search_regexp, $project_filter);
 981 sub evaluate_and_validate_params {
 982         our $action = $input_params{'action'};
 983         if (defined $action) {
 984                 if (!validate_action($action)) {
 985                         die_error(400, "Invalid action parameter");
 986                 }
 987         }
 988
 989         # parameters which are pathnames
 990         our $project = $input_params{'project'};
 991         if (defined $project) {
 992                 if (!validate_project($project)) {
 993                         undef $project;
 994                         die_error(404, "No such project");
 995                 }
 996         }
 997
 998         our $project_filter = $input_params{'project_filter'};
 999         if (defined $project_filter) {
1000                 if (!validate_pathname($project_filter)) {
1001                         die_error(404, "Invalid project_filter parameter");
1002                 }
1003         }
1004
1005         our $file_name = $input_params{'file_name'};
1006         if (defined $file_name) {
1007                 if (!validate_pathname($file_name)) {
1008                         die_error(400, "Invalid file parameter");
1009                 }
1010         }
1011
1012         our $file_parent = $input_params{'file_parent'};
1013         if (defined $file_parent) {
1014                 if (!validate_pathname($file_parent)) {
1015                         die_error(400, "Invalid file parent parameter");
1016                 }
1017         }
1018
1019         # parameters which are refnames
1020         our $hash = $input_params{'hash'};
1021         if (defined $hash) {
1022                 if (!validate_refname($hash)) {
1023                         die_error(400, "Invalid hash parameter");
1024                 }
1025         }
1026
1027         our $hash_parent = $input_params{'hash_parent'};
1028         if (defined $hash_parent) {
1029                 if (!validate_refname($hash_parent)) {
1030                         die_error(400, "Invalid hash parent parameter");
1031                 }
1032         }
1033
1034         our $hash_base = $input_params{'hash_base'};
1035         if (defined $hash_base) {
1036                 if (!validate_refname($hash_base)) {
1037                         die_error(400, "Invalid hash base parameter");
1038                 }
1039         }
1040
1041         our @extra_options = @{$input_params{'extra_options'}};
1042         # @extra_options is always defined, since it can only be (currently) set from
1043         # CGI, and $cgi->param() returns the empty array in array context if the param
1044         # is not set
1045         foreach my $opt (@extra_options) {
1046                 if (not exists $allowed_options{$opt}) {
1047                         die_error(400, "Invalid option parameter");
1048                 }
1049                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1050                         die_error(400, "Invalid option parameter for this action");
1051                 }
1052         }
1053
1054         our $hash_parent_base = $input_params{'hash_parent_base'};
1055         if (defined $hash_parent_base) {
1056                 if (!validate_refname($hash_parent_base)) {
1057                         die_error(400, "Invalid hash parent base parameter");
1058                 }
1059         }
1060
1061         # other parameters
1062         our $page = $input_params{'page'};
1063         if (defined $page) {
1064                 if ($page =~ m/[^0-9]/) {
1065                         die_error(400, "Invalid page parameter");
1066                 }
1067         }
1068
1069         our $searchtype = $input_params{'searchtype'};
1070         if (defined $searchtype) {
1071                 if ($searchtype =~ m/[^a-z]/) {
1072                         die_error(400, "Invalid searchtype parameter");
1073                 }
1074         }
1075
1076         our $search_use_regexp = $input_params{'search_use_regexp'};
1077
1078         our $searchtext = $input_params{'searchtext'};
1079         our $search_regexp;
1080         if (defined $searchtext) {
1081                 if (length($searchtext) < 2) {
1082                         die_error(403, "At least two characters are required for search parameter");
1083                 }
1084                 if ($search_use_regexp) {
1085                         $search_regexp = $searchtext;
1086                         if (!eval { qr/$search_regexp/; 1; }) {
1087                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1088                                 die_error(400, "Invalid search regexp '$search_regexp'",
1089                                           esc_html($error));
1090                         }
1091                 } else {
1092                         $search_regexp = quotemeta $searchtext;
1093                 }
1094         }
1095 }
1096
1097 # path to the current git repository
1098 our $git_dir;
1099 sub evaluate_git_dir {
1100         our $git_dir = "$projectroot/$project" if $project;
1101 }
1102
1103 our (@snapshot_fmts, $git_avatar);
1104 sub configure_gitweb_features {
1105         # list of supported snapshot formats
1106         our @snapshot_fmts = gitweb_get_feature('snapshot');
1107         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1108
1109         # check that the avatar feature is set to a known provider name,
1110         # and for each provider check if the dependencies are satisfied.
1111         # if the provider name is invalid or the dependencies are not met,
1112         # reset $git_avatar to the empty string.
1113         our ($git_avatar) = gitweb_get_feature('avatar');
1114         if ($git_avatar eq 'gravatar') {
1115                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1116         } elsif ($git_avatar eq 'picon') {
1117                 # no dependencies
1118         } else {
1119                 $git_avatar = '';
1120         }
1121 }
1122
1123 # custom error handler: 'die <message>' is Internal Server Error
1124 sub handle_errors_html {
1125         my $msg = shift; # it is already HTML escaped
1126
1127         # to avoid infinite loop where error occurs in die_error,
1128         # change handler to default handler, disabling handle_errors_html
1129         set_message("Error occured when inside die_error:\n$msg");
1130
1131         # you cannot jump out of die_error when called as error handler;
1132         # the subroutine set via CGI::Carp::set_message is called _after_
1133         # HTTP headers are already written, so it cannot write them itself
1134         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1135 }
1136 set_message(\&handle_errors_html);
1137
1138 # dispatch
1139 sub dispatch {
1140         if (!defined $action) {
1141                 if (defined $hash) {
1142                         $action = git_get_type($hash);
1143                         $action or die_error(404, "Object does not exist");
1144                 } elsif (defined $hash_base && defined $file_name) {
1145                         $action = git_get_type("$hash_base:$file_name");
1146                         $action or die_error(404, "File or directory does not exist");
1147                 } elsif (defined $project) {
1148                         $action = 'summary';
1149                 } else {
1150                         $action = 'project_list';
1151                 }
1152         }
1153         if (!defined($actions{$action})) {
1154                 die_error(400, "Unknown action");
1155         }
1156         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1157             !$project) {
1158                 die_error(400, "Project needed");
1159         }
1160         $actions{$action}->();
1161 }
1162
1163 sub reset_timer {
1164         our $t0 = [ gettimeofday() ]
1165                 if defined $t0;
1166         our $number_of_git_cmds = 0;
1167 }
1168
1169 our $first_request = 1;
1170 sub run_request {
1171         reset_timer();
1172
1173         evaluate_uri();
1174         if ($first_request) {
1175                 evaluate_gitweb_config();
1176                 evaluate_git_version();
1177         }
1178         if ($per_request_config) {
1179                 if (ref($per_request_config) eq 'CODE') {
1180                         $per_request_config->();
1181                 } elsif (!$first_request) {
1182                         evaluate_gitweb_config();
1183                 }
1184         }
1185         check_loadavg();
1186
1187         # $projectroot and $projects_list might be set in gitweb config file
1188         $projects_list ||= $projectroot;
1189
1190         evaluate_query_params();
1191         evaluate_path_info();
1192         evaluate_and_validate_params();
1193         evaluate_git_dir();
1194
1195         configure_gitweb_features();
1196
1197         dispatch();
1198 }
1199
1200 our $is_last_request = sub { 1 };
1201 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1202 our $CGI = 'CGI';
1203 our $cgi;
1204 sub configure_as_fcgi {
1205         require CGI::Fast;
1206         our $CGI = 'CGI::Fast';
1207
1208         my $request_number = 0;
1209         # let each child service 100 requests
1210         our $is_last_request = sub { ++$request_number > 100 };
1211 }
1212 sub evaluate_argv {
1213         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1214         configure_as_fcgi()
1215                 if $script_name =~ /\.fcgi$/;
1216
1217         return unless (@ARGV);
1218
1219         require Getopt::Long;
1220         Getopt::Long::GetOptions(
1221                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1222                 'nproc|n=i' => sub {
1223                         my ($arg, $val) = @_;
1224                         return unless eval { require FCGI::ProcManager; 1; };
1225                         my $proc_manager = FCGI::ProcManager->new({
1226                                 n_processes => $val,
1227                         });
1228                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1229                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1230                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1231                 },
1232         );
1233 }
1234
1235 sub run {
1236         evaluate_argv();
1237
1238         $first_request = 1;
1239         $pre_listen_hook->()
1240                 if $pre_listen_hook;
1241
1242  REQUEST:
1243         while ($cgi = $CGI->new()) {
1244                 $pre_dispatch_hook->()
1245                         if $pre_dispatch_hook;
1246
1247                 run_request();
1248
1249                 $post_dispatch_hook->()
1250                         if $post_dispatch_hook;
1251                 $first_request = 0;
1252
1253                 last REQUEST if ($is_last_request->());
1254         }
1255
1256  DONE_GITWEB:
1257         1;
1258 }
1259
1260 run();
1261
1262 if (defined caller) {
1263         # wrapped in a subroutine processing requests,
1264         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1265         return;
1266 } else {
1267         # pure CGI script, serving single request
1268         exit;
1269 }
1270
1271 ## ======================================================================
1272 ## action links
1273
1274 # possible values of extra options
1275 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1276 # -replay => 1      - start from a current view (replay with modifications)
1277 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1278 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1279 sub href {
1280         my %params = @_;
1281         # default is to use -absolute url() i.e. $my_uri
1282         my $href = $params{-full} ? $my_url : $my_uri;
1283
1284         # implicit -replay, must be first of implicit params
1285         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1286
1287         $params{'project'} = $project unless exists $params{'project'};
1288
1289         if ($params{-replay}) {
1290                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1291                         if (!exists $params{$name}) {
1292                                 $params{$name} = $input_params{$name};
1293                         }
1294                 }
1295         }
1296
1297         my $use_pathinfo = gitweb_check_feature('pathinfo');
1298         if (defined $params{'project'} &&
1299             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1300                 # try to put as many parameters as possible in PATH_INFO:
1301                 #   - project name
1302                 #   - action
1303                 #   - hash_parent or hash_parent_base:/file_parent
1304                 #   - hash or hash_base:/filename
1305                 #   - the snapshot_format as an appropriate suffix
1306
1307                 # When the script is the root DirectoryIndex for the domain,
1308                 # $href here would be something like http://gitweb.example.com/
1309                 # Thus, we strip any trailing / from $href, to spare us double
1310                 # slashes in the final URL
1311                 $href =~ s,/$,,;
1312
1313                 # Then add the project name, if present
1314                 $href .= "/".esc_path_info($params{'project'});
1315                 delete $params{'project'};
1316
1317                 # since we destructively absorb parameters, we keep this
1318                 # boolean that remembers if we're handling a snapshot
1319                 my $is_snapshot = $params{'action'} eq 'snapshot';
1320
1321                 # Summary just uses the project path URL, any other action is
1322                 # added to the URL
1323                 if (defined $params{'action'}) {
1324                         $href .= "/".esc_path_info($params{'action'})
1325                                 unless $params{'action'} eq 'summary';
1326                         delete $params{'action'};
1327                 }
1328
1329                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1330                 # stripping nonexistent or useless pieces
1331                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1332                         || $params{'hash_parent'} || $params{'hash'});
1333                 if (defined $params{'hash_base'}) {
1334                         if (defined $params{'hash_parent_base'}) {
1335                                 $href .= esc_path_info($params{'hash_parent_base'});
1336                                 # skip the file_parent if it's the same as the file_name
1337                                 if (defined $params{'file_parent'}) {
1338                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1339                                                 delete $params{'file_parent'};
1340                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1341                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1342                                                 delete $params{'file_parent'};
1343                                         }
1344                                 }
1345                                 $href .= "..";
1346                                 delete $params{'hash_parent'};
1347                                 delete $params{'hash_parent_base'};
1348                         } elsif (defined $params{'hash_parent'}) {
1349                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1350                                 delete $params{'hash_parent'};
1351                         }
1352
1353                         $href .= esc_path_info($params{'hash_base'});
1354                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1355                                 $href .= ":/".esc_path_info($params{'file_name'});
1356                                 delete $params{'file_name'};
1357                         }
1358                         delete $params{'hash'};
1359                         delete $params{'hash_base'};
1360                 } elsif (defined $params{'hash'}) {
1361                         $href .= esc_path_info($params{'hash'});
1362                         delete $params{'hash'};
1363                 }
1364
1365                 # If the action was a snapshot, we can absorb the
1366                 # snapshot_format parameter too
1367                 if ($is_snapshot) {
1368                         my $fmt = $params{'snapshot_format'};
1369                         # snapshot_format should always be defined when href()
1370                         # is called, but just in case some code forgets, we
1371                         # fall back to the default
1372                         $fmt ||= $snapshot_fmts[0];
1373                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1374                         delete $params{'snapshot_format'};
1375                 }
1376         }
1377
1378         # now encode the parameters explicitly
1379         my @result = ();
1380         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1381                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1382                 if (defined $params{$name}) {
1383                         if (ref($params{$name}) eq "ARRAY") {
1384                                 foreach my $par (@{$params{$name}}) {
1385                                         push @result, $symbol . "=" . esc_param($par);
1386                                 }
1387                         } else {
1388                                 push @result, $symbol . "=" . esc_param($params{$name});
1389                         }
1390                 }
1391         }
1392         $href .= "?" . join(';', @result) if scalar @result;
1393
1394         # final transformation: trailing spaces must be escaped (URI-encoded)
1395         $href =~ s/(\s+)$/CGI::escape($1)/e;
1396
1397         if ($params{-anchor}) {
1398                 $href .= "#".esc_param($params{-anchor});
1399         }
1400
1401         return $href;
1402 }
1403
1404
1405 ## ======================================================================
1406 ## validation, quoting/unquoting and escaping
1407
1408 sub validate_action {
1409         my $input = shift || return undef;
1410         return undef unless exists $actions{$input};
1411         return $input;
1412 }
1413
1414 sub validate_project {
1415         my $input = shift || return undef;
1416         if (!validate_pathname($input) ||
1417                 !(-d "$projectroot/$input") ||
1418                 !check_export_ok("$projectroot/$input") ||
1419                 ($strict_export && !project_in_list($input))) {
1420                 return undef;
1421         } else {
1422                 return $input;
1423         }
1424 }
1425
1426 sub validate_pathname {
1427         my $input = shift || return undef;
1428
1429         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1430         # at the beginning, at the end, and between slashes.
1431         # also this catches doubled slashes
1432         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1433                 return undef;
1434         }
1435         # no null characters
1436         if ($input =~ m!\0!) {
1437                 return undef;
1438         }
1439         return $input;
1440 }
1441
1442 sub validate_refname {
1443         my $input = shift || return undef;
1444
1445         # textual hashes are O.K.
1446         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1447                 return $input;
1448         }
1449         # it must be correct pathname
1450         $input = validate_pathname($input)
1451                 or return undef;
1452         # restrictions on ref name according to git-check-ref-format
1453         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1454                 return undef;
1455         }
1456         return $input;
1457 }
1458
1459 # decode sequences of octets in utf8 into Perl's internal form,
1460 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1461 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1462 sub to_utf8 {
1463         my $str = shift;
1464         return undef unless defined $str;
1465
1466         if (utf8::is_utf8($str) || utf8::decode($str)) {
1467                 return $str;
1468         } else {
1469                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1470         }
1471 }
1472
1473 # quote unsafe chars, but keep the slash, even when it's not
1474 # correct, but quoted slashes look too horrible in bookmarks
1475 sub esc_param {
1476         my $str = shift;
1477         return undef unless defined $str;
1478         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1479         $str =~ s/ /\+/g;
1480         return $str;
1481 }
1482
1483 # the quoting rules for path_info fragment are slightly different
1484 sub esc_path_info {
1485         my $str = shift;
1486         return undef unless defined $str;
1487
1488         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1489         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1490
1491         return $str;
1492 }
1493
1494 # quote unsafe chars in whole URL, so some characters cannot be quoted
1495 sub esc_url {
1496         my $str = shift;
1497         return undef unless defined $str;
1498         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1499         $str =~ s/ /\+/g;
1500         return $str;
1501 }
1502
1503 # quote unsafe characters in HTML attributes
1504 sub esc_attr {
1505
1506         # for XHTML conformance escaping '"' to '&quot;' is not enough
1507         return esc_html(@_);
1508 }
1509
1510 # replace invalid utf8 character with SUBSTITUTION sequence
1511 sub esc_html {
1512         my $str = shift;
1513         my %opts = @_;
1514
1515         return undef unless defined $str;
1516
1517         $str = to_utf8($str);
1518         $str = $cgi->escapeHTML($str);
1519         if ($opts{'-nbsp'}) {
1520                 $str =~ s/ /&nbsp;/g;
1521         }
1522         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1523         return $str;
1524 }
1525
1526 # quote control characters and escape filename to HTML
1527 sub esc_path {
1528         my $str = shift;
1529         my %opts = @_;
1530
1531         return undef unless defined $str;
1532
1533         $str = to_utf8($str);
1534         $str = $cgi->escapeHTML($str);
1535         if ($opts{'-nbsp'}) {
1536                 $str =~ s/ /&nbsp;/g;
1537         }
1538         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1539         return $str;
1540 }
1541
1542 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1543 sub sanitize {
1544         my $str = shift;
1545
1546         return undef unless defined $str;
1547
1548         $str = to_utf8($str);
1549         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1550         return $str;
1551 }
1552
1553 # Make control characters "printable", using character escape codes (CEC)
1554 sub quot_cec {
1555         my $cntrl = shift;
1556         my %opts = @_;
1557         my %es = ( # character escape codes, aka escape sequences
1558                 "\t" => '\t',   # tab            (HT)
1559                 "\n" => '\n',   # line feed      (LF)
1560                 "\r" => '\r',   # carrige return (CR)
1561                 "\f" => '\f',   # form feed      (FF)
1562                 "\b" => '\b',   # backspace      (BS)
1563                 "\a" => '\a',   # alarm (bell)   (BEL)
1564                 "\e" => '\e',   # escape         (ESC)
1565                 "\013" => '\v', # vertical tab   (VT)
1566                 "\000" => '\0', # nul character  (NUL)
1567         );
1568         my $chr = ( (exists $es{$cntrl})
1569                     ? $es{$cntrl}
1570                     : sprintf('\%2x', ord($cntrl)) );
1571         if ($opts{-nohtml}) {
1572                 return $chr;
1573         } else {
1574                 return "<span class=\"cntrl\">$chr</span>";
1575         }
1576 }
1577
1578 # Alternatively use unicode control pictures codepoints,
1579 # Unicode "printable representation" (PR)
1580 sub quot_upr {
1581         my $cntrl = shift;
1582         my %opts = @_;
1583
1584         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1585         if ($opts{-nohtml}) {
1586                 return $chr;
1587         } else {
1588                 return "<span class=\"cntrl\">$chr</span>";
1589         }
1590 }
1591
1592 # git may return quoted and escaped filenames
1593 sub unquote {
1594         my $str = shift;
1595
1596         sub unq {
1597                 my $seq = shift;
1598                 my %es = ( # character escape codes, aka escape sequences
1599                         't' => "\t",   # tab            (HT, TAB)
1600                         'n' => "\n",   # newline        (NL)
1601                         'r' => "\r",   # return         (CR)
1602                         'f' => "\f",   # form feed      (FF)
1603                         'b' => "\b",   # backspace      (BS)
1604                         'a' => "\a",   # alarm (bell)   (BEL)
1605                         'e' => "\e",   # escape         (ESC)
1606                         'v' => "\013", # vertical tab   (VT)
1607                 );
1608
1609                 if ($seq =~ m/^[0-7]{1,3}$/) {
1610                         # octal char sequence
1611                         return chr(oct($seq));
1612                 } elsif (exists $es{$seq}) {
1613                         # C escape sequence, aka character escape code
1614                         return $es{$seq};
1615                 }
1616                 # quoted ordinary character
1617                 return $seq;
1618         }
1619
1620         if ($str =~ m/^"(.*)"$/) {
1621                 # needs unquoting
1622                 $str = $1;
1623                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1624         }
1625         return $str;
1626 }
1627
1628 # escape tabs (convert tabs to spaces)
1629 sub untabify {
1630         my $line = shift;
1631
1632         while ((my $pos = index($line, "\t")) != -1) {
1633                 if (my $count = (8 - ($pos % 8))) {
1634                         my $spaces = ' ' x $count;
1635                         $line =~ s/\t/$spaces/;
1636                 }
1637         }
1638
1639         return $line;
1640 }
1641
1642 sub project_in_list {
1643         my $project = shift;
1644         my @list = git_get_projects_list();
1645         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1646 }
1647
1648 ## ----------------------------------------------------------------------
1649 ## HTML aware string manipulation
1650
1651 # Try to chop given string on a word boundary between position
1652 # $len and $len+$add_len. If there is no word boundary there,
1653 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1654 # (marking chopped part) would be longer than given string.
1655 sub chop_str {
1656         my $str = shift;
1657         my $len = shift;
1658         my $add_len = shift || 10;
1659         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1660
1661         # Make sure perl knows it is utf8 encoded so we don't
1662         # cut in the middle of a utf8 multibyte char.
1663         $str = to_utf8($str);
1664
1665         # allow only $len chars, but don't cut a word if it would fit in $add_len
1666         # if it doesn't fit, cut it if it's still longer than the dots we would add
1667         # remove chopped character entities entirely
1668
1669         # when chopping in the middle, distribute $len into left and right part
1670         # return early if chopping wouldn't make string shorter
1671         if ($where eq 'center') {
1672                 return $str if ($len + 5 >= length($str)); # filler is length 5
1673                 $len = int($len/2);
1674         } else {
1675                 return $str if ($len + 4 >= length($str)); # filler is length 4
1676         }
1677
1678         # regexps: ending and beginning with word part up to $add_len
1679         my $endre = qr/.{$len}\w{0,$add_len}/;
1680         my $begre = qr/\w{0,$add_len}.{$len}/;
1681
1682         if ($where eq 'left') {
1683                 $str =~ m/^(.*?)($begre)$/;
1684                 my ($lead, $body) = ($1, $2);
1685                 if (length($lead) > 4) {
1686                         $lead = " ...";
1687                 }
1688                 return "$lead$body";
1689
1690         } elsif ($where eq 'center') {
1691                 $str =~ m/^($endre)(.*)$/;
1692                 my ($left, $str)  = ($1, $2);
1693                 $str =~ m/^(.*?)($begre)$/;
1694                 my ($mid, $right) = ($1, $2);
1695                 if (length($mid) > 5) {
1696                         $mid = " ... ";
1697                 }
1698                 return "$left$mid$right";
1699
1700         } else {
1701                 $str =~ m/^($endre)(.*)$/;
1702                 my $body = $1;
1703                 my $tail = $2;
1704                 if (length($tail) > 4) {
1705                         $tail = "... ";
1706                 }
1707                 return "$body$tail";
1708         }
1709 }
1710
1711 # takes the same arguments as chop_str, but also wraps a <span> around the
1712 # result with a title attribute if it does get chopped. Additionally, the
1713 # string is HTML-escaped.
1714 sub chop_and_escape_str {
1715         my ($str) = @_;
1716
1717         my $chopped = chop_str(@_);
1718         $str = to_utf8($str);
1719         if ($chopped eq $str) {
1720                 return esc_html($chopped);
1721         } else {
1722                 $str =~ s/[[:cntrl:]]/?/g;
1723                 return $cgi->span({-title=>$str}, esc_html($chopped));
1724         }
1725 }
1726
1727 # Highlight selected fragments of string, using given CSS class,
1728 # and escape HTML.  It is assumed that fragments do not overlap.
1729 # Regions are passed as list of pairs (array references).
1730 #
1731 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1732 # '<span class="mark">foo</span>bar'
1733 sub esc_html_hl_regions {
1734         my ($str, $css_class, @sel) = @_;
1735         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1736         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1737         return esc_html($str, %opts) unless @sel;
1738
1739         my $out = '';
1740         my $pos = 0;
1741
1742         for my $s (@sel) {
1743                 my ($begin, $end) = @$s;
1744
1745                 # Don't create empty <span> elements.
1746                 next if $end <= $begin;
1747
1748                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1749                                        %opts);
1750
1751                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1752                         if ($begin - $pos > 0);
1753                 $out .= $cgi->span({-class => $css_class}, $escaped);
1754
1755                 $pos = $end;
1756         }
1757         $out .= esc_html(substr($str, $pos), %opts)
1758                 if ($pos < length($str));
1759
1760         return $out;
1761 }
1762
1763 # return positions of beginning and end of each match
1764 sub matchpos_list {
1765         my ($str, $regexp) = @_;
1766         return unless (defined $str && defined $regexp);
1767
1768         my @matches;
1769         while ($str =~ /$regexp/g) {
1770                 push @matches, [$-[0], $+[0]];
1771         }
1772         return @matches;
1773 }
1774
1775 # highlight match (if any), and escape HTML
1776 sub esc_html_match_hl {
1777         my ($str, $regexp) = @_;
1778         return esc_html($str) unless defined $regexp;
1779
1780         my @matches = matchpos_list($str, $regexp);
1781         return esc_html($str) unless @matches;
1782
1783         return esc_html_hl_regions($str, 'match', @matches);
1784 }
1785
1786
1787 # highlight match (if any) of shortened string, and escape HTML
1788 sub esc_html_match_hl_chopped {
1789         my ($str, $chopped, $regexp) = @_;
1790         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1791
1792         my @matches = matchpos_list($str, $regexp);
1793         return esc_html($chopped) unless @matches;
1794
1795         # filter matches so that we mark chopped string
1796         my $tail = "... "; # see chop_str
1797         unless ($chopped =~ s/\Q$tail\E$//) {
1798                 $tail = '';
1799         }
1800         my $chop_len = length($chopped);
1801         my $tail_len = length($tail);
1802         my @filtered;
1803
1804         for my $m (@matches) {
1805                 if ($m->[0] > $chop_len) {
1806                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1807                         last;
1808                 } elsif ($m->[1] > $chop_len) {
1809                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1810                         last;
1811                 }
1812                 push @filtered, $m;
1813         }
1814
1815         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1816 }
1817
1818 ## ----------------------------------------------------------------------
1819 ## functions returning short strings
1820
1821 # CSS class for given age value (in seconds)
1822 sub age_class {
1823         my $age = shift;
1824
1825         if (!defined $age) {
1826                 return "noage";
1827         } elsif ($age < 60*60*2) {
1828                 return "age0";
1829         } elsif ($age < 60*60*24*2) {
1830                 return "age1";
1831         } else {
1832                 return "age2";
1833         }
1834 }
1835
1836 # convert age in seconds to "nn units ago" string
1837 sub age_string {
1838         my $age = shift;
1839         my $age_str;
1840
1841         if ($age > 60*60*24*365*2) {
1842                 $age_str = (int $age/60/60/24/365);
1843                 $age_str .= " years ago";
1844         } elsif ($age > 60*60*24*(365/12)*2) {
1845                 $age_str = int $age/60/60/24/(365/12);
1846                 $age_str .= " months ago";
1847         } elsif ($age > 60*60*24*7*2) {
1848                 $age_str = int $age/60/60/24/7;
1849                 $age_str .= " weeks ago";
1850         } elsif ($age > 60*60*24*2) {
1851                 $age_str = int $age/60/60/24;
1852                 $age_str .= " days ago";
1853         } elsif ($age > 60*60*2) {
1854                 $age_str = int $age/60/60;
1855                 $age_str .= " hours ago";
1856         } elsif ($age > 60*2) {
1857                 $age_str = int $age/60;
1858                 $age_str .= " min ago";
1859         } elsif ($age > 2) {
1860                 $age_str = int $age;
1861                 $age_str .= " sec ago";
1862         } else {
1863                 $age_str .= " right now";
1864         }
1865         return $age_str;
1866 }
1867
1868 use constant {
1869         S_IFINVALID => 0030000,
1870         S_IFGITLINK => 0160000,
1871 };
1872
1873 # submodule/subproject, a commit object reference
1874 sub S_ISGITLINK {
1875         my $mode = shift;
1876
1877         return (($mode & S_IFMT) == S_IFGITLINK)
1878 }
1879
1880 # convert file mode in octal to symbolic file mode string
1881 sub mode_str {
1882         my $mode = oct shift;
1883
1884         if (S_ISGITLINK($mode)) {
1885                 return 'm---------';
1886         } elsif (S_ISDIR($mode & S_IFMT)) {
1887                 return 'drwxr-xr-x';
1888         } elsif (S_ISLNK($mode)) {
1889                 return 'lrwxrwxrwx';
1890         } elsif (S_ISREG($mode)) {
1891                 # git cares only about the executable bit
1892                 if ($mode & S_IXUSR) {
1893                         return '-rwxr-xr-x';
1894                 } else {
1895                         return '-rw-r--r--';
1896                 };
1897         } else {
1898                 return '----------';
1899         }
1900 }
1901
1902 # convert file mode in octal to file type string
1903 sub file_type {
1904         my $mode = shift;
1905
1906         if ($mode !~ m/^[0-7]+$/) {
1907                 return $mode;
1908         } else {
1909                 $mode = oct $mode;
1910         }
1911
1912         if (S_ISGITLINK($mode)) {
1913                 return "submodule";
1914         } elsif (S_ISDIR($mode & S_IFMT)) {
1915                 return "directory";
1916         } elsif (S_ISLNK($mode)) {
1917                 return "symlink";
1918         } elsif (S_ISREG($mode)) {
1919                 return "file";
1920         } else {
1921                 return "unknown";
1922         }
1923 }
1924
1925 # convert file mode in octal to file type description string
1926 sub file_type_long {
1927         my $mode = shift;
1928
1929         if ($mode !~ m/^[0-7]+$/) {
1930                 return $mode;
1931         } else {
1932                 $mode = oct $mode;
1933         }
1934
1935         if (S_ISGITLINK($mode)) {
1936                 return "submodule";
1937         } elsif (S_ISDIR($mode & S_IFMT)) {
1938                 return "directory";
1939         } elsif (S_ISLNK($mode)) {
1940                 return "symlink";
1941         } elsif (S_ISREG($mode)) {
1942                 if ($mode & S_IXUSR) {
1943                         return "executable";
1944                 } else {
1945                         return "file";
1946                 };
1947         } else {
1948                 return "unknown";
1949         }
1950 }
1951
1952
1953 ## ----------------------------------------------------------------------
1954 ## functions returning short HTML fragments, or transforming HTML fragments
1955 ## which don't belong to other sections
1956
1957 # format line of commit message.
1958 sub format_log_line_html {
1959         my $line = shift;
1960
1961         $line = esc_html($line, -nbsp=>1);
1962         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1963                 $cgi->a({-href => href(action=>"object", hash=>$1),
1964                                         -class => "text"}, $1);
1965         }eg;
1966
1967         return $line;
1968 }
1969
1970 # format marker of refs pointing to given object
1971
1972 # the destination action is chosen based on object type and current context:
1973 # - for annotated tags, we choose the tag view unless it's the current view
1974 #   already, in which case we go to shortlog view
1975 # - for other refs, we keep the current view if we're in history, shortlog or
1976 #   log view, and select shortlog otherwise
1977 sub format_ref_marker {
1978         my ($refs, $id) = @_;
1979         my $markers = '';
1980
1981         if (defined $refs->{$id}) {
1982                 foreach my $ref (@{$refs->{$id}}) {
1983                         # this code exploits the fact that non-lightweight tags are the
1984                         # only indirect objects, and that they are the only objects for which
1985                         # we want to use tag instead of shortlog as action
1986                         my ($type, $name) = qw();
1987                         my $indirect = ($ref =~ s/\^\{\}$//);
1988                         # e.g. tags/v2.6.11 or heads/next
1989                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1990                                 $type = $1;
1991                                 $name = $2;
1992                         } else {
1993                                 $type = "ref";
1994                                 $name = $ref;
1995                         }
1996
1997                         my $class = $type;
1998                         $class .= " indirect" if $indirect;
1999
2000                         my $dest_action = "shortlog";
2001
2002                         if ($indirect) {
2003                                 $dest_action = "tag" unless $action eq "tag";
2004                         } elsif ($action =~ /^(history|(short)?log)$/) {
2005                                 $dest_action = $action;
2006                         }
2007
2008                         my $dest = "";
2009                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2010                         $dest .= $ref;
2011
2012                         my $link = $cgi->a({
2013                                 -href => href(
2014                                         action=>$dest_action,
2015                                         hash=>$dest
2016                                 )}, $name);
2017
2018                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2019                                 $link . "</span>";
2020                 }
2021         }
2022
2023         if ($markers) {
2024                 return ' <span class="refs">'. $markers . '</span>';
2025         } else {
2026                 return "";
2027         }
2028 }
2029
2030 # format, perhaps shortened and with markers, title line
2031 sub format_subject_html {
2032         my ($long, $short, $href, $extra) = @_;
2033         $extra = '' unless defined($extra);
2034
2035         if (length($short) < length($long)) {
2036                 $long =~ s/[[:cntrl:]]/?/g;
2037                 return $cgi->a({-href => $href, -class => "list subject",
2038                                 -title => to_utf8($long)},
2039                        esc_html($short)) . $extra;
2040         } else {
2041                 return $cgi->a({-href => $href, -class => "list subject"},
2042                        esc_html($long)) . $extra;
2043         }
2044 }
2045
2046 # Rather than recomputing the url for an email multiple times, we cache it
2047 # after the first hit. This gives a visible benefit in views where the avatar
2048 # for the same email is used repeatedly (e.g. shortlog).
2049 # The cache is shared by all avatar engines (currently gravatar only), which
2050 # are free to use it as preferred. Since only one avatar engine is used for any
2051 # given page, there's no risk for cache conflicts.
2052 our %avatar_cache = ();
2053
2054 # Compute the picon url for a given email, by using the picon search service over at
2055 # http://www.cs.indiana.edu/picons/search.html
2056 sub picon_url {
2057         my $email = lc shift;
2058         if (!$avatar_cache{$email}) {
2059                 my ($user, $domain) = split('@', $email);
2060                 $avatar_cache{$email} =
2061                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2062                         "$domain/$user/" .
2063                         "users+domains+unknown/up/single";
2064         }
2065         return $avatar_cache{$email};
2066 }
2067
2068 # Compute the gravatar url for a given email, if it's not in the cache already.
2069 # Gravatar stores only the part of the URL before the size, since that's the
2070 # one computationally more expensive. This also allows reuse of the cache for
2071 # different sizes (for this particular engine).
2072 sub gravatar_url {
2073         my $email = lc shift;
2074         my $size = shift;
2075         $avatar_cache{$email} ||=
2076                 "http://www.gravatar.com/avatar/" .
2077                         Digest::MD5::md5_hex($email) . "?s=";
2078         return $avatar_cache{$email} . $size;
2079 }
2080
2081 # Insert an avatar for the given $email at the given $size if the feature
2082 # is enabled.
2083 sub git_get_avatar {
2084         my ($email, %opts) = @_;
2085         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2086         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2087         $opts{-size} ||= 'default';
2088         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2089         my $url = "";
2090         if ($git_avatar eq 'gravatar') {
2091                 $url = gravatar_url($email, $size);
2092         } elsif ($git_avatar eq 'picon') {
2093                 $url = picon_url($email);
2094         }
2095         # Other providers can be added by extending the if chain, defining $url
2096         # as needed. If no variant puts something in $url, we assume avatars
2097         # are completely disabled/unavailable.
2098         if ($url) {
2099                 return $pre_white .
2100                        "<img width=\"$size\" " .
2101                             "class=\"avatar\" " .
2102                             "src=\"".esc_url($url)."\" " .
2103                             "alt=\"\" " .
2104                        "/>" . $post_white;
2105         } else {
2106                 return "";
2107         }
2108 }
2109
2110 sub format_search_author {
2111         my ($author, $searchtype, $displaytext) = @_;
2112         my $have_search = gitweb_check_feature('search');
2113
2114         if ($have_search) {
2115                 my $performed = "";
2116                 if ($searchtype eq 'author') {
2117                         $performed = "authored";
2118                 } elsif ($searchtype eq 'committer') {
2119                         $performed = "committed";
2120                 }
2121
2122                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2123                                 searchtext=>$author,
2124                                 searchtype=>$searchtype), class=>"list",
2125                                 title=>"Search for commits $performed by $author"},
2126                                 $displaytext);
2127
2128         } else {
2129                 return $displaytext;
2130         }
2131 }
2132
2133 # format the author name of the given commit with the given tag
2134 # the author name is chopped and escaped according to the other
2135 # optional parameters (see chop_str).
2136 sub format_author_html {
2137         my $tag = shift;
2138         my $co = shift;
2139         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2140         return "<$tag class=\"author\">" .
2141                format_search_author($co->{'author_name'}, "author",
2142                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2143                        $author) .
2144                "</$tag>";
2145 }
2146
2147 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2148 sub format_git_diff_header_line {
2149         my $line = shift;
2150         my $diffinfo = shift;
2151         my ($from, $to) = @_;
2152
2153         if ($diffinfo->{'nparents'}) {
2154                 # combined diff
2155                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2156                 if ($to->{'href'}) {
2157                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2158                                          esc_path($to->{'file'}));
2159                 } else { # file was deleted (no href)
2160                         $line .= esc_path($to->{'file'});
2161                 }
2162         } else {
2163                 # "ordinary" diff
2164                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2165                 if ($from->{'href'}) {
2166                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2167                                          'a/' . esc_path($from->{'file'}));
2168                 } else { # file was added (no href)
2169                         $line .= 'a/' . esc_path($from->{'file'});
2170                 }
2171                 $line .= ' ';
2172                 if ($to->{'href'}) {
2173                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2174                                          'b/' . esc_path($to->{'file'}));
2175                 } else { # file was deleted
2176                         $line .= 'b/' . esc_path($to->{'file'});
2177                 }
2178         }
2179
2180         return "<div class=\"diff header\">$line</div>\n";
2181 }
2182
2183 # format extended diff header line, before patch itself
2184 sub format_extended_diff_header_line {
2185         my $line = shift;
2186         my $diffinfo = shift;
2187         my ($from, $to) = @_;
2188
2189         # match <path>
2190         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2191                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2192                                        esc_path($from->{'file'}));
2193         }
2194         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2195                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2196                                  esc_path($to->{'file'}));
2197         }
2198         # match single <mode>
2199         if ($line =~ m/\s(\d{6})$/) {
2200                 $line .= '<span class="info"> (' .
2201                          file_type_long($1) .
2202                          ')</span>';
2203         }
2204         # match <hash>
2205         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2206                 # can match only for combined diff
2207                 $line = 'index ';
2208                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2209                         if ($from->{'href'}[$i]) {
2210                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2211                                                   -class=>"hash"},
2212                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2213                         } else {
2214                                 $line .= '0' x 7;
2215                         }
2216                         # separator
2217                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2218                 }
2219                 $line .= '..';
2220                 if ($to->{'href'}) {
2221                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2222                                          substr($diffinfo->{'to_id'},0,7));
2223                 } else {
2224                         $line .= '0' x 7;
2225                 }
2226
2227         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2228                 # can match only for ordinary diff
2229                 my ($from_link, $to_link);
2230                 if ($from->{'href'}) {
2231                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2232                                              substr($diffinfo->{'from_id'},0,7));
2233                 } else {
2234                         $from_link = '0' x 7;
2235                 }
2236                 if ($to->{'href'}) {
2237                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2238                                            substr($diffinfo->{'to_id'},0,7));
2239                 } else {
2240                         $to_link = '0' x 7;
2241                 }
2242                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2243                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2244         }
2245
2246         return $line . "<br/>\n";
2247 }
2248
2249 # format from-file/to-file diff header
2250 sub format_diff_from_to_header {
2251         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2252         my $line;
2253         my $result = '';
2254
2255         $line = $from_line;
2256         #assert($line =~ m/^---/) if DEBUG;
2257         # no extra formatting for "^--- /dev/null"
2258         if (! $diffinfo->{'nparents'}) {
2259                 # ordinary (single parent) diff
2260                 if ($line =~ m!^--- "?a/!) {
2261                         if ($from->{'href'}) {
2262                                 $line = '--- a/' .
2263                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2264                                                 esc_path($from->{'file'}));
2265                         } else {
2266                                 $line = '--- a/' .
2267                                         esc_path($from->{'file'});
2268                         }
2269                 }
2270                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2271
2272         } else {
2273                 # combined diff (merge commit)
2274                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2275                         if ($from->{'href'}[$i]) {
2276                                 $line = '--- ' .
2277                                         $cgi->a({-href=>href(action=>"blobdiff",
2278                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2279                                                              hash_parent_base=>$parents[$i],
2280                                                              file_parent=>$from->{'file'}[$i],
2281                                                              hash=>$diffinfo->{'to_id'},
2282                                                              hash_base=>$hash,
2283                                                              file_name=>$to->{'file'}),
2284                                                  -class=>"path",
2285                                                  -title=>"diff" . ($i+1)},
2286                                                 $i+1) .
2287                                         '/' .
2288                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2289                                                 esc_path($from->{'file'}[$i]));
2290                         } else {
2291                                 $line = '--- /dev/null';
2292                         }
2293                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2294                 }
2295         }
2296
2297         $line = $to_line;
2298         #assert($line =~ m/^\+\+\+/) if DEBUG;
2299         # no extra formatting for "^+++ /dev/null"
2300         if ($line =~ m!^\+\+\+ "?b/!) {
2301                 if ($to->{'href'}) {
2302                         $line = '+++ b/' .
2303                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2304                                         esc_path($to->{'file'}));
2305                 } else {
2306                         $line = '+++ b/' .
2307                                 esc_path($to->{'file'});
2308                 }
2309         }
2310         $result .= qq!<div class="diff to_file">$line</div>\n!;
2311
2312         return $result;
2313 }
2314
2315 # create note for patch simplified by combined diff
2316 sub format_diff_cc_simplified {
2317         my ($diffinfo, @parents) = @_;
2318         my $result = '';
2319
2320         $result .= "<div class=\"diff header\">" .
2321                    "diff --cc ";
2322         if (!is_deleted($diffinfo)) {
2323                 $result .= $cgi->a({-href => href(action=>"blob",
2324                                                   hash_base=>$hash,
2325                                                   hash=>$diffinfo->{'to_id'},
2326                                                   file_name=>$diffinfo->{'to_file'}),
2327                                     -class => "path"},
2328                                    esc_path($diffinfo->{'to_file'}));
2329         } else {
2330                 $result .= esc_path($diffinfo->{'to_file'});
2331         }
2332         $result .= "</div>\n" . # class="diff header"
2333                    "<div class=\"diff nodifferences\">" .
2334                    "Simple merge" .
2335                    "</div>\n"; # class="diff nodifferences"
2336
2337         return $result;
2338 }
2339
2340 sub diff_line_class {
2341         my ($line, $from, $to) = @_;
2342
2343         # ordinary diff
2344         my $num_sign = 1;
2345         # combined diff
2346         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2347                 $num_sign = scalar @{$from->{'href'}};
2348         }
2349
2350         my @diff_line_classifier = (
2351                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2352                 { regexp => qr/^\\/,               class => "incomplete"  },
2353                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2354                 # classifier for context must come before classifier add/rem,
2355                 # or we would have to use more complicated regexp, for example
2356                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2357                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2358                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2359         );
2360         for my $clsfy (@diff_line_classifier) {
2361                 return $clsfy->{'class'}
2362                         if ($line =~ $clsfy->{'regexp'});
2363         }
2364
2365         # fallback
2366         return "";
2367 }
2368
2369 # assumes that $from and $to are defined and correctly filled,
2370 # and that $line holds a line of chunk header for unified diff
2371 sub format_unidiff_chunk_header {
2372         my ($line, $from, $to) = @_;
2373
2374         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2375                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2376
2377         $from_lines = 0 unless defined $from_lines;
2378         $to_lines   = 0 unless defined $to_lines;
2379
2380         if ($from->{'href'}) {
2381                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2382                                      -class=>"list"}, $from_text);
2383         }
2384         if ($to->{'href'}) {
2385                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2386                                      -class=>"list"}, $to_text);
2387         }
2388         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2389                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2390         return $line;
2391 }
2392
2393 # assumes that $from and $to are defined and correctly filled,
2394 # and that $line holds a line of chunk header for combined diff
2395 sub format_cc_diff_chunk_header {
2396         my ($line, $from, $to) = @_;
2397
2398         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2399         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2400
2401         @from_text = split(' ', $ranges);
2402         for (my $i = 0; $i < @from_text; ++$i) {
2403                 ($from_start[$i], $from_nlines[$i]) =
2404                         (split(',', substr($from_text[$i], 1)), 0);
2405         }
2406
2407         $to_text   = pop @from_text;
2408         $to_start  = pop @from_start;
2409         $to_nlines = pop @from_nlines;
2410
2411         $line = "<span class=\"chunk_info\">$prefix ";
2412         for (my $i = 0; $i < @from_text; ++$i) {
2413                 if ($from->{'href'}[$i]) {
2414                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2415                                           -class=>"list"}, $from_text[$i]);
2416                 } else {
2417                         $line .= $from_text[$i];
2418                 }
2419                 $line .= " ";
2420         }
2421         if ($to->{'href'}) {
2422                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2423                                   -class=>"list"}, $to_text);
2424         } else {
2425                 $line .= $to_text;
2426         }
2427         $line .= " $prefix</span>" .
2428                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2429         return $line;
2430 }
2431
2432 # process patch (diff) line (not to be used for diff headers),
2433 # returning class and HTML-formatted (but not wrapped) line
2434 sub process_diff_line {
2435         my $line = shift;
2436         my ($from, $to) = @_;
2437
2438         my $diff_class = diff_line_class($line, $from, $to);
2439
2440         chomp $line;
2441         $line = untabify($line);
2442
2443         if ($from && $to && $line =~ m/^\@{2} /) {
2444                 $line = format_unidiff_chunk_header($line, $from, $to);
2445                 return $diff_class, $line;
2446
2447         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2448                 $line = format_cc_diff_chunk_header($line, $from, $to);
2449                 return $diff_class, $line;
2450
2451         }
2452         return $diff_class, esc_html($line, -nbsp=>1);
2453 }
2454
2455 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2456 # linked.  Pass the hash of the tree/commit to snapshot.
2457 sub format_snapshot_links {
2458         my ($hash) = @_;
2459         my $num_fmts = @snapshot_fmts;
2460         if ($num_fmts > 1) {
2461                 # A parenthesized list of links bearing format names.
2462                 # e.g. "snapshot (_tar.gz_ _zip_)"
2463                 return "snapshot (" . join(' ', map
2464                         $cgi->a({
2465                                 -href => href(
2466                                         action=>"snapshot",
2467                                         hash=>$hash,
2468                                         snapshot_format=>$_
2469                                 )
2470                         }, $known_snapshot_formats{$_}{'display'})
2471                 , @snapshot_fmts) . ")";
2472         } elsif ($num_fmts == 1) {
2473                 # A single "snapshot" link whose tooltip bears the format name.
2474                 # i.e. "_snapshot_"
2475                 my ($fmt) = @snapshot_fmts;
2476                 return
2477                         $cgi->a({
2478                                 -href => href(
2479                                         action=>"snapshot",
2480                                         hash=>$hash,
2481                                         snapshot_format=>$fmt
2482                                 ),
2483                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2484                         }, "snapshot");
2485         } else { # $num_fmts == 0
2486                 return undef;
2487         }
2488 }
2489
2490 ## ......................................................................
2491 ## functions returning values to be passed, perhaps after some
2492 ## transformation, to other functions; e.g. returning arguments to href()
2493
2494 # returns hash to be passed to href to generate gitweb URL
2495 # in -title key it returns description of link
2496 sub get_feed_info {
2497         my $format = shift || 'Atom';
2498         my %res = (action => lc($format));
2499
2500         # feed links are possible only for project views
2501         return unless (defined $project);
2502         # some views should link to OPML, or to generic project feed,
2503         # or don't have specific feed yet (so they should use generic)
2504         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2505
2506         my $branch;
2507         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2508         # from tag links; this also makes possible to detect branch links
2509         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2510             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2511                 $branch = $1;
2512         }
2513         # find log type for feed description (title)
2514         my $type = 'log';
2515         if (defined $file_name) {
2516                 $type  = "history of $file_name";
2517                 $type .= "/" if ($action eq 'tree');
2518                 $type .= " on '$branch'" if (defined $branch);
2519         } else {
2520                 $type = "log of $branch" if (defined $branch);
2521         }
2522
2523         $res{-title} = $type;
2524         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2525         $res{'file_name'} = $file_name;
2526
2527         return %res;
2528 }
2529
2530 ## ----------------------------------------------------------------------
2531 ## git utility subroutines, invoking git commands
2532
2533 # returns path to the core git executable and the --git-dir parameter as list
2534 sub git_cmd {
2535         $number_of_git_cmds++;
2536         return $GIT, '--git-dir='.$git_dir;
2537 }
2538
2539 # quote the given arguments for passing them to the shell
2540 # quote_command("command", "arg 1", "arg with ' and ! characters")
2541 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2542 # Try to avoid using this function wherever possible.
2543 sub quote_command {
2544         return join(' ',
2545                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2546 }
2547
2548 # get HEAD ref of given project as hash
2549 sub git_get_head_hash {
2550         return git_get_full_hash(shift, 'HEAD');
2551 }
2552
2553 sub git_get_full_hash {
2554         return git_get_hash(@_);
2555 }
2556
2557 sub git_get_short_hash {
2558         return git_get_hash(@_, '--short=7');
2559 }
2560
2561 sub git_get_hash {
2562         my ($project, $hash, @options) = @_;
2563         my $o_git_dir = $git_dir;
2564         my $retval = undef;
2565         $git_dir = "$projectroot/$project";
2566         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2567             '--verify', '-q', @options, $hash) {
2568                 $retval = <$fd>;
2569                 chomp $retval if defined $retval;
2570                 close $fd;
2571         }
2572         if (defined $o_git_dir) {
2573                 $git_dir = $o_git_dir;
2574         }
2575         return $retval;
2576 }
2577
2578 # get type of given object
2579 sub git_get_type {
2580         my $hash = shift;
2581
2582         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2583         my $type = <$fd>;
2584         close $fd or return;
2585         chomp $type;
2586         return $type;
2587 }
2588
2589 # repository configuration
2590 our $config_file = '';
2591 our %config;
2592
2593 # store multiple values for single key as anonymous array reference
2594 # single values stored directly in the hash, not as [ <value> ]
2595 sub hash_set_multi {
2596         my ($hash, $key, $value) = @_;
2597
2598         if (!exists $hash->{$key}) {
2599                 $hash->{$key} = $value;
2600         } elsif (!ref $hash->{$key}) {
2601                 $hash->{$key} = [ $hash->{$key}, $value ];
2602         } else {
2603                 push @{$hash->{$key}}, $value;
2604         }
2605 }
2606
2607 # return hash of git project configuration
2608 # optionally limited to some section, e.g. 'gitweb'
2609 sub git_parse_project_config {
2610         my $section_regexp = shift;
2611         my %config;
2612
2613         local $/ = "\0";
2614
2615         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2616                 or return;
2617
2618         while (my $keyval = <$fh>) {
2619                 chomp $keyval;
2620                 my ($key, $value) = split(/\n/, $keyval, 2);
2621
2622                 hash_set_multi(\%config, $key, $value)
2623                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2624         }
2625         close $fh;
2626
2627         return %config;
2628 }
2629
2630 # convert config value to boolean: 'true' or 'false'
2631 # no value, number > 0, 'true' and 'yes' values are true
2632 # rest of values are treated as false (never as error)
2633 sub config_to_bool {
2634         my $val = shift;
2635
2636         return 1 if !defined $val;             # section.key
2637
2638         # strip leading and trailing whitespace
2639         $val =~ s/^\s+//;
2640         $val =~ s/\s+$//;
2641
2642         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2643                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2644 }
2645
2646 # convert config value to simple decimal number
2647 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2648 # to be multiplied by 1024, 1048576, or 1073741824
2649 sub config_to_int {
2650         my $val = shift;
2651
2652         # strip leading and trailing whitespace
2653         $val =~ s/^\s+//;
2654         $val =~ s/\s+$//;
2655
2656         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2657                 $unit = lc($unit);
2658                 # unknown unit is treated as 1
2659                 return $num * ($unit eq 'g' ? 1073741824 :
2660                                $unit eq 'm' ?    1048576 :
2661                                $unit eq 'k' ?       1024 : 1);
2662         }
2663         return $val;
2664 }
2665
2666 # convert config value to array reference, if needed
2667 sub config_to_multi {
2668         my $val = shift;
2669
2670         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2671 }
2672
2673 sub git_get_project_config {
2674         my ($key, $type) = @_;
2675
2676         return unless defined $git_dir;
2677
2678         # key sanity check
2679         return unless ($key);
2680         # only subsection, if exists, is case sensitive,
2681         # and not lowercased by 'git config -z -l'
2682         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2683                 $key = join(".", lc($hi), $mi, lc($lo));
2684         } else {
2685                 $key = lc($key);
2686         }
2687         $key =~ s/^gitweb\.//;
2688         return if ($key =~ m/\W/);
2689
2690         # type sanity check
2691         if (defined $type) {
2692                 $type =~ s/^--//;
2693                 $type = undef
2694                         unless ($type eq 'bool' || $type eq 'int');
2695         }
2696
2697         # get config
2698         if (!defined $config_file ||
2699             $config_file ne "$git_dir/config") {
2700                 %config = git_parse_project_config('gitweb');
2701                 $config_file = "$git_dir/config";
2702         }
2703
2704         # check if config variable (key) exists
2705         return unless exists $config{"gitweb.$key"};
2706
2707         # ensure given type
2708         if (!defined $type) {
2709                 return $config{"gitweb.$key"};
2710         } elsif ($type eq 'bool') {
2711                 # backward compatibility: 'git config --bool' returns true/false
2712                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2713         } elsif ($type eq 'int') {
2714                 return config_to_int($config{"gitweb.$key"});
2715         }
2716         return $config{"gitweb.$key"};
2717 }
2718
2719 # get hash of given path at given ref
2720 sub git_get_hash_by_path {
2721         my $base = shift;
2722         my $path = shift || return undef;
2723         my $type = shift;
2724
2725         $path =~ s,/+$,,;
2726
2727         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2728                 or die_error(500, "Open git-ls-tree failed");
2729         my $line = <$fd>;
2730         close $fd or return undef;
2731
2732         if (!defined $line) {
2733                 # there is no tree or hash given by $path at $base
2734                 return undef;
2735         }
2736
2737         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2738         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2739         if (defined $type && $type ne $2) {
2740                 # type doesn't match
2741                 return undef;
2742         }
2743         return $3;
2744 }
2745
2746 # get path of entry with given hash at given tree-ish (ref)
2747 # used to get 'from' filename for combined diff (merge commit) for renames
2748 sub git_get_path_by_hash {
2749         my $base = shift || return;
2750         my $hash = shift || return;
2751
2752         local $/ = "\0";
2753
2754         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2755                 or return undef;
2756         while (my $line = <$fd>) {
2757                 chomp $line;
2758
2759                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2760                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2761                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2762                         close $fd;
2763                         return $1;
2764                 }
2765         }
2766         close $fd;
2767         return undef;
2768 }
2769
2770 ## ......................................................................
2771 ## git utility functions, directly accessing git repository
2772
2773 # get the value of config variable either from file named as the variable
2774 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2775 # configuration variable in the repository config file.
2776 sub git_get_file_or_project_config {
2777         my ($path, $name) = @_;
2778
2779         $git_dir = "$projectroot/$path";
2780         open my $fd, '<', "$git_dir/$name"
2781                 or return git_get_project_config($name);
2782         my $conf = <$fd>;
2783         close $fd;
2784         if (defined $conf) {
2785                 chomp $conf;
2786         }
2787         return $conf;
2788 }
2789
2790 sub git_get_project_description {
2791         my $path = shift;
2792         return git_get_file_or_project_config($path, 'description');
2793 }
2794
2795 sub git_get_project_category {
2796         my $path = shift;
2797         return git_get_file_or_project_config($path, 'category');
2798 }
2799
2800
2801 # supported formats:
2802 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2803 #   - if its contents is a number, use it as tag weight,
2804 #   - otherwise add a tag with weight 1
2805 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2806 #   the same value multiple times increases tag weight
2807 # * `gitweb.ctag' multi-valued repo config variable
2808 sub git_get_project_ctags {
2809         my $project = shift;
2810         my $ctags = {};
2811
2812         $git_dir = "$projectroot/$project";
2813         if (opendir my $dh, "$git_dir/ctags") {
2814                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2815                 foreach my $tagfile (@files) {
2816                         open my $ct, '<', $tagfile
2817                                 or next;
2818                         my $val = <$ct>;
2819                         chomp $val if $val;
2820                         close $ct;
2821
2822                         (my $ctag = $tagfile) =~ s#.*/##;
2823                         if ($val =~ /^\d+$/) {
2824                                 $ctags->{$ctag} = $val;
2825                         } else {
2826                                 $ctags->{$ctag} = 1;
2827                         }
2828                 }
2829                 closedir $dh;
2830
2831         } elsif (open my $fh, '<', "$git_dir/ctags") {
2832                 while (my $line = <$fh>) {
2833                         chomp $line;
2834                         $ctags->{$line}++ if $line;
2835                 }
2836                 close $fh;
2837
2838         } else {
2839                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2840                 foreach my $tag (@$taglist) {
2841                         $ctags->{$tag}++;
2842                 }
2843         }
2844
2845         return $ctags;
2846 }
2847
2848 # return hash, where keys are content tags ('ctags'),
2849 # and values are sum of weights of given tag in every project
2850 sub git_gather_all_ctags {
2851         my $projects = shift;
2852         my $ctags = {};
2853
2854         foreach my $p (@$projects) {
2855                 foreach my $ct (keys %{$p->{'ctags'}}) {
2856                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2857                 }
2858         }
2859
2860         return $ctags;
2861 }
2862
2863 sub git_populate_project_tagcloud {
2864         my $ctags = shift;
2865
2866         # First, merge different-cased tags; tags vote on casing
2867         my %ctags_lc;
2868         foreach (keys %$ctags) {
2869                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2870                 if (not $ctags_lc{lc $_}->{topcount}
2871                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2872                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2873                         $ctags_lc{lc $_}->{topname} = $_;
2874                 }
2875         }
2876
2877         my $cloud;
2878         my $matched = $input_params{'ctag'};
2879         if (eval { require HTML::TagCloud; 1; }) {
2880                 $cloud = HTML::TagCloud->new;
2881                 foreach my $ctag (sort keys %ctags_lc) {
2882                         # Pad the title with spaces so that the cloud looks
2883                         # less crammed.
2884                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2885                         $title =~ s/ /&nbsp;/g;
2886                         $title =~ s/^/&nbsp;/g;
2887                         $title =~ s/$/&nbsp;/g;
2888                         if (defined $matched && $matched eq $ctag) {
2889                                 $title = qq(<span class="match">$title</span>);
2890                         }
2891                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2892                                     $ctags_lc{$ctag}->{count});
2893                 }
2894         } else {
2895                 $cloud = {};
2896                 foreach my $ctag (keys %ctags_lc) {
2897                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2898                         if (defined $matched && $matched eq $ctag) {
2899                                 $title = qq(<span class="match">$title</span>);
2900                         }
2901                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2902                         $cloud->{$ctag}{ctag} =
2903                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2904                 }
2905         }
2906         return $cloud;
2907 }
2908
2909 sub git_show_project_tagcloud {
2910         my ($cloud, $count) = @_;
2911         if (ref $cloud eq 'HTML::TagCloud') {
2912                 return $cloud->html_and_css($count);
2913         } else {
2914                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2915                 return
2916                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2917                         join (', ', map {
2918                                 $cloud->{$_}->{'ctag'}
2919                         } splice(@tags, 0, $count)) .
2920                         '</div>';
2921         }
2922 }
2923
2924 sub git_get_project_url_list {
2925         my $path = shift;
2926
2927         $git_dir = "$projectroot/$path";
2928         open my $fd, '<', "$git_dir/cloneurl"
2929                 or return wantarray ?
2930                 @{ config_to_multi(git_get_project_config('url')) } :
2931                    config_to_multi(git_get_project_config('url'));
2932         my @git_project_url_list = map { chomp; $_ } <$fd>;
2933         close $fd;
2934
2935         return wantarray ? @git_project_url_list : \@git_project_url_list;
2936 }
2937
2938 sub git_get_projects_list {
2939         my $filter = shift || '';
2940         my $paranoid = shift;
2941         my @list;
2942
2943         if (-d $projects_list) {
2944                 # search in directory
2945                 my $dir = $projects_list;
2946                 # remove the trailing "/"
2947                 $dir =~ s!/+$!!;
2948                 my $pfxlen = length("$dir");
2949                 my $pfxdepth = ($dir =~ tr!/!!);
2950                 # when filtering, search only given subdirectory
2951                 if ($filter && !$paranoid) {
2952                         $dir .= "/$filter";
2953                         $dir =~ s!/+$!!;
2954                 }
2955
2956                 File::Find::find({
2957                         follow_fast => 1, # follow symbolic links
2958                         follow_skip => 2, # ignore duplicates
2959                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2960                         wanted => sub {
2961                                 # global variables
2962                                 our $project_maxdepth;
2963                                 our $projectroot;
2964                                 # skip project-list toplevel, if we get it.
2965                                 return if (m!^[/.]$!);
2966                                 # only directories can be git repositories
2967                                 return unless (-d $_);
2968                                 # don't traverse too deep (Find is super slow on os x)
2969                                 # $project_maxdepth excludes depth of $projectroot
2970                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2971                                         $File::Find::prune = 1;
2972                                         return;
2973                                 }
2974
2975                                 my $path = substr($File::Find::name, $pfxlen + 1);
2976                                 # paranoidly only filter here
2977                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
2978                                         next;
2979                                 }
2980                                 # we check related file in $projectroot
2981                                 if (check_export_ok("$projectroot/$path")) {
2982                                         push @list, { path => $path };
2983                                         $File::Find::prune = 1;
2984                                 }
2985                         },
2986                 }, "$dir");
2987
2988         } elsif (-f $projects_list) {
2989                 # read from file(url-encoded):
2990                 # 'git%2Fgit.git Linus+Torvalds'
2991                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2992                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2993                 open my $fd, '<', $projects_list or return;
2994         PROJECT:
2995                 while (my $line = <$fd>) {
2996                         chomp $line;
2997                         my ($path, $owner) = split ' ', $line;
2998                         $path = unescape($path);
2999                         $owner = unescape($owner);
3000                         if (!defined $path) {
3001                                 next;
3002                         }
3003                         # if $filter is rpovided, check if $path begins with $filter
3004                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3005                                 next;
3006                         }
3007                         if (check_export_ok("$projectroot/$path")) {
3008                                 my $pr = {
3009                                         path => $path,
3010                                         owner => to_utf8($owner),
3011                                 };
3012                                 push @list, $pr;
3013                         }
3014                 }
3015                 close $fd;
3016         }
3017         return @list;
3018 }
3019
3020 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3021 # as side effects it sets 'forks' field to list of forks for forked projects
3022 sub filter_forks_from_projects_list {
3023         my $projects = shift;
3024
3025         my %trie; # prefix tree of directories (path components)
3026         # generate trie out of those directories that might contain forks
3027         foreach my $pr (@$projects) {
3028                 my $path = $pr->{'path'};
3029                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3030                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3031                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3032                 next unless (-d "$projectroot/$path"); # containing directory exists
3033                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3034
3035                 # add to trie
3036                 my @dirs = split('/', $path);
3037                 # walk the trie, until either runs out of components or out of trie
3038                 my $ref = \%trie;
3039                 while (scalar @dirs &&
3040                        exists($ref->{$dirs[0]})) {
3041                         $ref = $ref->{shift @dirs};
3042                 }
3043                 # create rest of trie structure from rest of components
3044                 foreach my $dir (@dirs) {
3045                         $ref = $ref->{$dir} = {};
3046                 }
3047                 # create end marker, store $pr as a data
3048                 $ref->{''} = $pr if (!exists $ref->{''});
3049         }
3050
3051         # filter out forks, by finding shortest prefix match for paths
3052         my @filtered;
3053  PROJECT:
3054         foreach my $pr (@$projects) {
3055                 # trie lookup
3056                 my $ref = \%trie;
3057         DIR:
3058                 foreach my $dir (split('/', $pr->{'path'})) {
3059                         if (exists $ref->{''}) {
3060                                 # found [shortest] prefix, is a fork - skip it
3061                                 push @{$ref->{''}{'forks'}}, $pr;
3062                                 next PROJECT;
3063                         }
3064                         if (!exists $ref->{$dir}) {
3065                                 # not in trie, cannot have prefix, not a fork
3066                                 push @filtered, $pr;
3067                                 next PROJECT;
3068                         }
3069                         # If the dir is there, we just walk one step down the trie.
3070                         $ref = $ref->{$dir};
3071                 }
3072                 # we ran out of trie
3073                 # (shouldn't happen: it's either no match, or end marker)
3074                 push @filtered, $pr;
3075         }
3076
3077         return @filtered;
3078 }
3079
3080 # note: fill_project_list_info must be run first,
3081 # for 'descr_long' and 'ctags' to be filled
3082 sub search_projects_list {
3083         my ($projlist, %opts) = @_;
3084         my $tagfilter  = $opts{'tagfilter'};
3085         my $search_re = $opts{'search_regexp'};
3086
3087         return @$projlist
3088                 unless ($tagfilter || $search_re);
3089
3090         # searching projects require filling to be run before it;
3091         fill_project_list_info($projlist,
3092                                $tagfilter  ? 'ctags' : (),
3093                                $search_re ? ('path', 'descr') : ());
3094         my @projects;
3095  PROJECT:
3096         foreach my $pr (@$projlist) {
3097
3098                 if ($tagfilter) {
3099                         next unless ref($pr->{'ctags'}) eq 'HASH';
3100                         next unless
3101                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3102                 }
3103
3104                 if ($search_re) {
3105                         next unless
3106                                 $pr->{'path'} =~ /$search_re/ ||
3107                                 $pr->{'descr_long'} =~ /$search_re/;
3108                 }
3109
3110                 push @projects, $pr;
3111         }
3112
3113         return @projects;
3114 }
3115
3116 our $gitweb_project_owner = undef;
3117 sub git_get_project_list_from_file {
3118
3119         return if (defined $gitweb_project_owner);
3120
3121         $gitweb_project_owner = {};
3122         # read from file (url-encoded):
3123         # 'git%2Fgit.git Linus+Torvalds'
3124         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3125         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3126         if (-f $projects_list) {
3127                 open(my $fd, '<', $projects_list);
3128                 while (my $line = <$fd>) {
3129                         chomp $line;
3130                         my ($pr, $ow) = split ' ', $line;
3131                         $pr = unescape($pr);
3132                         $ow = unescape($ow);
3133                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3134                 }
3135                 close $fd;
3136         }
3137 }
3138
3139 sub git_get_project_owner {
3140         my $project = shift;
3141         my $owner;
3142
3143         return undef unless $project;
3144         $git_dir = "$projectroot/$project";
3145
3146         if (!defined $gitweb_project_owner) {
3147                 git_get_project_list_from_file();
3148         }
3149
3150         if (exists $gitweb_project_owner->{$project}) {
3151                 $owner = $gitweb_project_owner->{$project};
3152         }
3153         if (!defined $owner){
3154                 $owner = git_get_project_config('owner');
3155         }
3156         if (!defined $owner) {
3157                 $owner = get_file_owner("$git_dir");
3158         }
3159
3160         return $owner;
3161 }
3162
3163 sub git_get_last_activity {
3164         my ($path) = @_;
3165         my $fd;
3166
3167         $git_dir = "$projectroot/$path";
3168         open($fd, "-|", git_cmd(), 'for-each-ref',
3169              '--format=%(committer)',
3170              '--sort=-committerdate',
3171              '--count=1',
3172              'refs/heads') or return;
3173         my $most_recent = <$fd>;
3174         close $fd or return;
3175         if (defined $most_recent &&
3176             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3177                 my $timestamp = $1;
3178                 my $age = time - $timestamp;
3179                 return ($age, age_string($age));
3180         }
3181         return (undef, undef);
3182 }
3183
3184 # Implementation note: when a single remote is wanted, we cannot use 'git
3185 # remote show -n' because that command always work (assuming it's a remote URL
3186 # if it's not defined), and we cannot use 'git remote show' because that would
3187 # try to make a network roundtrip. So the only way to find if that particular
3188 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3189 # and when we find what we want.
3190 sub git_get_remotes_list {
3191         my $wanted = shift;
3192         my %remotes = ();
3193
3194         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3195         return unless $fd;
3196         while (my $remote = <$fd>) {
3197                 chomp $remote;
3198                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3199                 next if $wanted and not $remote eq $wanted;
3200                 my ($url, $key) = ($1, $2);
3201
3202                 $remotes{$remote} ||= { 'heads' => () };
3203                 $remotes{$remote}{$key} = $url;
3204         }
3205         close $fd or return;
3206         return wantarray ? %remotes : \%remotes;
3207 }
3208
3209 # Takes a hash of remotes as first parameter and fills it by adding the
3210 # available remote heads for each of the indicated remotes.
3211 sub fill_remote_heads {
3212         my $remotes = shift;
3213         my @heads = map { "remotes/$_" } keys %$remotes;
3214         my @remoteheads = git_get_heads_list(undef, @heads);
3215         foreach my $remote (keys %$remotes) {
3216                 $remotes->{$remote}{'heads'} = [ grep {
3217                         $_->{'name'} =~ s!^$remote/!!
3218                         } @remoteheads ];
3219         }
3220 }
3221
3222 sub git_get_references {
3223         my $type = shift || "";
3224         my %refs;
3225         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3226         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3227         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3228                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3229                 or return;
3230
3231         while (my $line = <$fd>) {
3232                 chomp $line;
3233                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3234                         if (defined $refs{$1}) {
3235                                 push @{$refs{$1}}, $2;
3236                         } else {
3237                                 $refs{$1} = [ $2 ];
3238                         }
3239                 }
3240         }
3241         close $fd or return;
3242         return \%refs;
3243 }
3244
3245 sub git_get_rev_name_tags {
3246         my $hash = shift || return undef;
3247
3248         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3249                 or return;
3250         my $name_rev = <$fd>;
3251         close $fd;
3252
3253         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3254                 return $1;
3255         } else {
3256                 # catches also '$hash undefined' output
3257                 return undef;
3258         }
3259 }
3260
3261 ## ----------------------------------------------------------------------
3262 ## parse to hash functions
3263
3264 sub parse_date {
3265         my $epoch = shift;
3266         my $tz = shift || "-0000";
3267
3268         my %date;
3269         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3270         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3271         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3272         $date{'hour'} = $hour;
3273         $date{'minute'} = $min;
3274         $date{'mday'} = $mday;
3275         $date{'day'} = $days[$wday];
3276         $date{'month'} = $months[$mon];
3277         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3278                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3279         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3280                              $mday, $months[$mon], $hour ,$min;
3281         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3282                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3283
3284         my ($tz_sign, $tz_hour, $tz_min) =
3285                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3286         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3287         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3288         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3289         $date{'hour_local'} = $hour;
3290         $date{'minute_local'} = $min;
3291         $date{'tz_local'} = $tz;
3292         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3293                                   1900+$year, $mon+1, $mday,
3294                                   $hour, $min, $sec, $tz);
3295         return %date;
3296 }
3297
3298 sub parse_tag {
3299         my $tag_id = shift;
3300         my %tag;
3301         my @comment;
3302
3303         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3304         $tag{'id'} = $tag_id;
3305         while (my $line = <$fd>) {
3306                 chomp $line;
3307                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3308                         $tag{'object'} = $1;
3309                 } elsif ($line =~ m/^type (.+)$/) {
3310                         $tag{'type'} = $1;
3311                 } elsif ($line =~ m/^tag (.+)$/) {
3312                         $tag{'name'} = $1;
3313                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3314                         $tag{'author'} = $1;
3315                         $tag{'author_epoch'} = $2;
3316                         $tag{'author_tz'} = $3;
3317                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3318                                 $tag{'author_name'}  = $1;
3319                                 $tag{'author_email'} = $2;
3320                         } else {
3321                                 $tag{'author_name'} = $tag{'author'};
3322                         }
3323                 } elsif ($line =~ m/--BEGIN/) {
3324                         push @comment, $line;
3325                         last;
3326                 } elsif ($line eq "") {
3327                         last;
3328                 }
3329         }
3330         push @comment, <$fd>;
3331         $tag{'comment'} = \@comment;
3332         close $fd or return;
3333         if (!defined $tag{'name'}) {
3334                 return
3335         };
3336         return %tag
3337 }
3338
3339 sub parse_commit_text {
3340         my ($commit_text, $withparents) = @_;
3341         my @commit_lines = split '\n', $commit_text;
3342         my %co;
3343
3344         pop @commit_lines; # Remove '\0'
3345
3346         if (! @commit_lines) {
3347                 return;
3348         }
3349
3350         my $header = shift @commit_lines;
3351         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3352                 return;
3353         }
3354         ($co{'id'}, my @parents) = split ' ', $header;
3355         while (my $line = shift @commit_lines) {
3356                 last if $line eq "\n";
3357                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3358                         $co{'tree'} = $1;
3359                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3360                         push @parents, $1;
3361                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3362                         $co{'author'} = to_utf8($1);
3363                         $co{'author_epoch'} = $2;
3364                         $co{'author_tz'} = $3;
3365                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3366                                 $co{'author_name'}  = $1;
3367                                 $co{'author_email'} = $2;
3368                         } else {
3369                                 $co{'author_name'} = $co{'author'};
3370                         }
3371                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3372                         $co{'committer'} = to_utf8($1);
3373                         $co{'committer_epoch'} = $2;
3374                         $co{'committer_tz'} = $3;
3375                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3376                                 $co{'committer_name'}  = $1;
3377                                 $co{'committer_email'} = $2;
3378                         } else {
3379                                 $co{'committer_name'} = $co{'committer'};
3380                         }
3381                 }
3382         }
3383         if (!defined $co{'tree'}) {
3384                 return;
3385         };
3386         $co{'parents'} = \@parents;
3387         $co{'parent'} = $parents[0];
3388
3389         foreach my $title (@commit_lines) {
3390                 $title =~ s/^    //;
3391                 if ($title ne "") {
3392                         $co{'title'} = chop_str($title, 80, 5);
3393                         # remove leading stuff of merges to make the interesting part visible
3394                         if (length($title) > 50) {
3395                                 $title =~ s/^Automatic //;
3396                                 $title =~ s/^merge (of|with) /Merge ... /i;
3397                                 if (length($title) > 50) {
3398                                         $title =~ s/(http|rsync):\/\///;
3399                                 }
3400                                 if (length($title) > 50) {
3401                                         $title =~ s/(master|www|rsync)\.//;
3402                                 }
3403                                 if (length($title) > 50) {
3404                                         $title =~ s/kernel.org:?//;
3405                                 }
3406                                 if (length($title) > 50) {
3407                                         $title =~ s/\/pub\/scm//;
3408                                 }
3409                         }
3410                         $co{'title_short'} = chop_str($title, 50, 5);
3411                         last;
3412                 }
3413         }
3414         if (! defined $co{'title'} || $co{'title'} eq "") {
3415                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3416         }
3417         # remove added spaces
3418         foreach my $line (@commit_lines) {
3419                 $line =~ s/^    //;
3420         }
3421         $co{'comment'} = \@commit_lines;
3422
3423         my $age = time - $co{'committer_epoch'};
3424         $co{'age'} = $age;
3425         $co{'age_string'} = age_string($age);
3426         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3427         if ($age > 60*60*24*7*2) {
3428                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3429                 $co{'age_string_age'} = $co{'age_string'};
3430         } else {
3431                 $co{'age_string_date'} = $co{'age_string'};
3432                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3433         }
3434         return %co;
3435 }
3436
3437 sub parse_commit {
3438         my ($commit_id) = @_;
3439         my %co;
3440
3441         local $/ = "\0";
3442
3443         open my $fd, "-|", git_cmd(), "rev-list",
3444                 "--parents",
3445                 "--header",
3446                 "--max-count=1",
3447                 $commit_id,
3448                 "--",
3449                 or die_error(500, "Open git-rev-list failed");
3450         %co = parse_commit_text(<$fd>, 1);
3451         close $fd;
3452
3453         return %co;
3454 }
3455
3456 sub parse_commits {
3457         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3458         my @cos;
3459
3460         $maxcount ||= 1;
3461         $skip ||= 0;
3462
3463         local $/ = "\0";
3464
3465         open my $fd, "-|", git_cmd(), "rev-list",
3466                 "--header",
3467                 @args,
3468                 ("--max-count=" . $maxcount),
3469                 ("--skip=" . $skip),
3470                 @extra_options,
3471                 $commit_id,
3472                 "--",
3473                 ($filename ? ($filename) : ())
3474                 or die_error(500, "Open git-rev-list failed");
3475         while (my $line = <$fd>) {
3476                 my %co = parse_commit_text($line);
3477                 push @cos, \%co;
3478         }
3479         close $fd;
3480
3481         return wantarray ? @cos : \@cos;
3482 }
3483
3484 # parse line of git-diff-tree "raw" output
3485 sub parse_difftree_raw_line {
3486         my $line = shift;
3487         my %res;
3488
3489         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3490         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3491         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3492                 $res{'from_mode'} = $1;
3493                 $res{'to_mode'} = $2;
3494                 $res{'from_id'} = $3;
3495                 $res{'to_id'} = $4;
3496                 $res{'status'} = $5;
3497                 $res{'similarity'} = $6;
3498                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3499                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3500                 } else {
3501                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3502                 }
3503         }
3504         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3505         # combined diff (for merge commit)
3506         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3507                 $res{'nparents'}  = length($1);
3508                 $res{'from_mode'} = [ split(' ', $2) ];
3509                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3510                 $res{'from_id'} = [ split(' ', $3) ];
3511                 $res{'to_id'} = pop @{$res{'from_id'}};
3512                 $res{'status'} = [ split('', $4) ];
3513                 $res{'to_file'} = unquote($5);
3514         }
3515         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3516         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3517                 $res{'commit'} = $1;
3518         }
3519
3520         return wantarray ? %res : \%res;
3521 }
3522
3523 # wrapper: return parsed line of git-diff-tree "raw" output
3524 # (the argument might be raw line, or parsed info)
3525 sub parsed_difftree_line {
3526         my $line_or_ref = shift;
3527
3528         if (ref($line_or_ref) eq "HASH") {
3529                 # pre-parsed (or generated by hand)
3530                 return $line_or_ref;
3531         } else {
3532                 return parse_difftree_raw_line($line_or_ref);
3533         }
3534 }
3535
3536 # parse line of git-ls-tree output
3537 sub parse_ls_tree_line {
3538         my $line = shift;
3539         my %opts = @_;
3540         my %res;
3541
3542         if ($opts{'-l'}) {
3543                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3544                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3545
3546                 $res{'mode'} = $1;
3547                 $res{'type'} = $2;
3548                 $res{'hash'} = $3;
3549                 $res{'size'} = $4;
3550                 if ($opts{'-z'}) {
3551                         $res{'name'} = $5;
3552                 } else {
3553                         $res{'name'} = unquote($5);
3554                 }
3555         } else {
3556                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3557                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3558
3559                 $res{'mode'} = $1;
3560                 $res{'type'} = $2;
3561                 $res{'hash'} = $3;
3562                 if ($opts{'-z'}) {
3563                         $res{'name'} = $4;
3564                 } else {
3565                         $res{'name'} = unquote($4);
3566                 }
3567         }
3568
3569         return wantarray ? %res : \%res;
3570 }
3571
3572 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3573 sub parse_from_to_diffinfo {
3574         my ($diffinfo, $from, $to, @parents) = @_;
3575
3576         if ($diffinfo->{'nparents'}) {
3577                 # combined diff
3578                 $from->{'file'} = [];
3579                 $from->{'href'} = [];
3580                 fill_from_file_info($diffinfo, @parents)
3581                         unless exists $diffinfo->{'from_file'};
3582                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3583                         $from->{'file'}[$i] =
3584                                 defined $diffinfo->{'from_file'}[$i] ?
3585                                         $diffinfo->{'from_file'}[$i] :
3586                                         $diffinfo->{'to_file'};
3587                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3588                                 $from->{'href'}[$i] = href(action=>"blob",
3589                                                            hash_base=>$parents[$i],
3590                                                            hash=>$diffinfo->{'from_id'}[$i],
3591                                                            file_name=>$from->{'file'}[$i]);
3592                         } else {
3593                                 $from->{'href'}[$i] = undef;
3594                         }
3595                 }
3596         } else {
3597                 # ordinary (not combined) diff
3598                 $from->{'file'} = $diffinfo->{'from_file'};
3599                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3600                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3601                                                hash=>$diffinfo->{'from_id'},
3602                                                file_name=>$from->{'file'});
3603                 } else {
3604                         delete $from->{'href'};
3605                 }
3606         }
3607
3608         $to->{'file'} = $diffinfo->{'to_file'};
3609         if (!is_deleted($diffinfo)) { # file exists in result
3610                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3611                                      hash=>$diffinfo->{'to_id'},
3612                                      file_name=>$to->{'file'});
3613         } else {
3614                 delete $to->{'href'};
3615         }
3616 }
3617
3618 ## ......................................................................
3619 ## parse to array of hashes functions
3620
3621 sub git_get_heads_list {
3622         my ($limit, @classes) = @_;
3623         @classes = ('heads') unless @classes;
3624         my @patterns = map { "refs/$_" } @classes;
3625         my @headslist;
3626
3627         open my $fd, '-|', git_cmd(), 'for-each-ref',
3628                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3629                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3630                 @patterns
3631                 or return;
3632         while (my $line = <$fd>) {
3633                 my %ref_item;
3634
3635                 chomp $line;
3636                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3637                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3638                 my ($committer, $epoch, $tz) =
3639                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3640                 $ref_item{'fullname'}  = $name;
3641                 $name =~ s!^refs/(?:head|remote)s/!!;
3642
3643                 $ref_item{'name'}  = $name;
3644                 $ref_item{'id'}    = $hash;
3645                 $ref_item{'title'} = $title || '(no commit message)';
3646                 $ref_item{'epoch'} = $epoch;
3647                 if ($epoch) {
3648                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3649                 } else {
3650                         $ref_item{'age'} = "unknown";
3651                 }
3652
3653                 push @headslist, \%ref_item;
3654         }
3655         close $fd;
3656
3657         return wantarray ? @headslist : \@headslist;
3658 }
3659
3660 sub git_get_tags_list {
3661         my $limit = shift;
3662         my @tagslist;
3663
3664         open my $fd, '-|', git_cmd(), 'for-each-ref',
3665                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3666                 '--format=%(objectname) %(objecttype) %(refname) '.
3667                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3668                 'refs/tags'
3669                 or return;
3670         while (my $line = <$fd>) {
3671                 my %ref_item;
3672
3673                 chomp $line;
3674                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3675                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3676                 my ($creator, $epoch, $tz) =
3677                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3678                 $ref_item{'fullname'} = $name;
3679                 $name =~ s!^refs/tags/!!;
3680
3681                 $ref_item{'type'} = $type;
3682                 $ref_item{'id'} = $id;
3683                 $ref_item{'name'} = $name;
3684                 if ($type eq "tag") {
3685                         $ref_item{'subject'} = $title;
3686                         $ref_item{'reftype'} = $reftype;
3687                         $ref_item{'refid'}   = $refid;
3688                 } else {
3689                         $ref_item{'reftype'} = $type;
3690                         $ref_item{'refid'}   = $id;
3691                 }
3692
3693                 if ($type eq "tag" || $type eq "commit") {
3694                         $ref_item{'epoch'} = $epoch;
3695                         if ($epoch) {
3696                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3697                         } else {
3698                                 $ref_item{'age'} = "unknown";
3699                         }
3700                 }
3701
3702                 push @tagslist, \%ref_item;
3703         }
3704         close $fd;
3705
3706         return wantarray ? @tagslist : \@tagslist;
3707 }
3708
3709 ## ----------------------------------------------------------------------
3710 ## filesystem-related functions
3711
3712 sub get_file_owner {
3713         my $path = shift;
3714
3715         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3716         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3717         if (!defined $gcos) {
3718                 return undef;
3719         }
3720         my $owner = $gcos;
3721         $owner =~ s/[,;].*$//;
3722         return to_utf8($owner);
3723 }
3724
3725 # assume that file exists
3726 sub insert_file {
3727         my $filename = shift;
3728
3729         open my $fd, '<', $filename;
3730         print map { to_utf8($_) } <$fd>;
3731         close $fd;
3732 }
3733
3734 ## ......................................................................
3735 ## mimetype related functions
3736
3737 sub mimetype_guess_file {
3738         my $filename = shift;
3739         my $mimemap = shift;
3740         -r $mimemap or return undef;
3741
3742         my %mimemap;
3743         open(my $mh, '<', $mimemap) or return undef;
3744         while (<$mh>) {
3745                 next if m/^#/; # skip comments
3746                 my ($mimetype, @exts) = split(/\s+/);
3747                 foreach my $ext (@exts) {
3748                         $mimemap{$ext} = $mimetype;
3749                 }
3750         }
3751         close($mh);
3752
3753         $filename =~ /\.([^.]*)$/;
3754         return $mimemap{$1};
3755 }
3756
3757 sub mimetype_guess {
3758         my $filename = shift;
3759         my $mime;
3760         $filename =~ /\./ or return undef;
3761
3762         if ($mimetypes_file) {
3763                 my $file = $mimetypes_file;
3764                 if ($file !~ m!^/!) { # if it is relative path
3765                         # it is relative to project
3766                         $file = "$projectroot/$project/$file";
3767                 }
3768                 $mime = mimetype_guess_file($filename, $file);
3769         }
3770         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3771         return $mime;
3772 }
3773
3774 sub blob_mimetype {
3775         my $fd = shift;
3776         my $filename = shift;
3777
3778         if ($filename) {
3779                 my $mime = mimetype_guess($filename);
3780                 $mime and return $mime;
3781         }
3782
3783         # just in case
3784         return $default_blob_plain_mimetype unless $fd;
3785
3786         if (-T $fd) {
3787                 return 'text/plain';
3788         } elsif (! $filename) {
3789                 return 'application/octet-stream';
3790         } elsif ($filename =~ m/\.png$/i) {
3791                 return 'image/png';
3792         } elsif ($filename =~ m/\.gif$/i) {
3793                 return 'image/gif';
3794         } elsif ($filename =~ m/\.jpe?g$/i) {
3795                 return 'image/jpeg';
3796         } else {
3797                 return 'application/octet-stream';
3798         }
3799 }
3800
3801 sub blob_contenttype {
3802         my ($fd, $file_name, $type) = @_;
3803
3804         $type ||= blob_mimetype($fd, $file_name);
3805         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3806                 $type .= "; charset=$default_text_plain_charset";
3807         }
3808
3809         return $type;
3810 }
3811
3812 # guess file syntax for syntax highlighting; return undef if no highlighting
3813 # the name of syntax can (in the future) depend on syntax highlighter used
3814 sub guess_file_syntax {
3815         my ($highlight, $mimetype, $file_name) = @_;
3816         return undef unless ($highlight && defined $file_name);
3817         my $basename = basename($file_name, '.in');
3818         return $highlight_basename{$basename}
3819                 if exists $highlight_basename{$basename};
3820
3821         $basename =~ /\.([^.]*)$/;
3822         my $ext = $1 or return undef;
3823         return $highlight_ext{$ext}
3824                 if exists $highlight_ext{$ext};
3825
3826         return undef;
3827 }
3828
3829 # run highlighter and return FD of its output,
3830 # or return original FD if no highlighting
3831 sub run_highlighter {
3832         my ($fd, $highlight, $syntax) = @_;
3833         return $fd unless ($highlight && defined $syntax);
3834
3835         close $fd;
3836         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3837                   quote_command($highlight_bin).
3838                   " --replace-tabs=8 --fragment --syntax $syntax |"
3839                 or die_error(500, "Couldn't open file or run syntax highlighter");
3840         return $fd;
3841 }
3842
3843 ## ======================================================================
3844 ## functions printing HTML: header, footer, error page
3845
3846 sub get_page_title {
3847         my $title = to_utf8($site_name);
3848
3849         unless (defined $project) {
3850                 if (defined $project_filter) {
3851                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3852                 }
3853                 return $title;
3854         }
3855         $title .= " - " . to_utf8($project);
3856
3857         return $title unless (defined $action);
3858         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3859
3860         return $title unless (defined $file_name);
3861         $title .= " - " . esc_path($file_name);
3862         if ($action eq "tree" && $file_name !~ m|/$|) {
3863                 $title .= "/";
3864         }
3865
3866         return $title;
3867 }
3868
3869 sub get_content_type_html {
3870         # require explicit support from the UA if we are to send the page as
3871         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3872         # we have to do this because MSIE sometimes globs '*/*', pretending to
3873         # support xhtml+xml but choking when it gets what it asked for.
3874         if (defined $cgi->http('HTTP_ACCEPT') &&
3875             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3876             $cgi->Accept('application/xhtml+xml') != 0) {
3877                 return 'application/xhtml+xml';
3878         } else {
3879                 return 'text/html';
3880         }
3881 }
3882
3883 sub print_feed_meta {
3884         if (defined $project) {
3885                 my %href_params = get_feed_info();
3886                 if (!exists $href_params{'-title'}) {
3887                         $href_params{'-title'} = 'log';
3888                 }
3889
3890                 foreach my $format (qw(RSS Atom)) {
3891                         my $type = lc($format);
3892                         my %link_attr = (
3893                                 '-rel' => 'alternate',
3894                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3895                                 '-type' => "application/$type+xml"
3896                         );
3897
3898                         $href_params{'action'} = $type;
3899                         $link_attr{'-href'} = href(%href_params);
3900                         print "<link ".
3901                               "rel=\"$link_attr{'-rel'}\" ".
3902                               "title=\"$link_attr{'-title'}\" ".
3903                               "href=\"$link_attr{'-href'}\" ".
3904                               "type=\"$link_attr{'-type'}\" ".
3905                               "/>\n";
3906
3907                         $href_params{'extra_options'} = '--no-merges';
3908                         $link_attr{'-href'} = href(%href_params);
3909                         $link_attr{'-title'} .= ' (no merges)';
3910                         print "<link ".
3911                               "rel=\"$link_attr{'-rel'}\" ".
3912                               "title=\"$link_attr{'-title'}\" ".
3913                               "href=\"$link_attr{'-href'}\" ".
3914                               "type=\"$link_attr{'-type'}\" ".
3915                               "/>\n";
3916                 }
3917
3918         } else {
3919                 printf('<link rel="alternate" title="%s projects list" '.
3920                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3921                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3922                 printf('<link rel="alternate" title="%s projects feeds" '.
3923                        'href="%s" type="text/x-opml" />'."\n",
3924                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3925         }
3926 }
3927
3928 sub print_header_links {
3929         my $status = shift;
3930
3931         # print out each stylesheet that exist, providing backwards capability
3932         # for those people who defined $stylesheet in a config file
3933         if (defined $stylesheet) {
3934                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3935         } else {
3936                 foreach my $stylesheet (@stylesheets) {
3937                         next unless $stylesheet;
3938                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3939                 }
3940         }
3941         print_feed_meta()
3942                 if ($status eq '200 OK');
3943         if (defined $favicon) {
3944                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3945         }
3946 }
3947
3948 sub print_nav_breadcrumbs_path {
3949         my $dirprefix = undef;
3950         while (my $part = shift) {
3951                 $dirprefix .= "/" if defined $dirprefix;
3952                 $dirprefix .= $part;
3953                 print $cgi->a({-href => href(project => undef,
3954                                              project_filter => $dirprefix,
3955                                              action => "project_list")},
3956                               esc_html($part)) . " / ";
3957         }
3958 }
3959
3960 sub print_nav_breadcrumbs {
3961         my %opts = @_;
3962
3963         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3964         if (defined $project) {
3965                 my @dirname = split '/', $project;
3966                 my $projectbasename = pop @dirname;
3967                 print_nav_breadcrumbs_path(@dirname);
3968                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
3969                 if (defined $action) {
3970                         my $action_print = $action ;
3971                         if (defined $opts{-action_extra}) {
3972                                 $action_print = $cgi->a({-href => href(action=>$action)},
3973                                         $action);
3974                         }
3975                         print " / $action_print";
3976                 }
3977                 if (defined $opts{-action_extra}) {
3978                         print " / $opts{-action_extra}";
3979                 }
3980                 print "\n";
3981         } elsif (defined $project_filter) {
3982                 print_nav_breadcrumbs_path(split '/', $project_filter);
3983         }
3984 }
3985
3986 sub print_search_form {
3987         if (!defined $searchtext) {
3988                 $searchtext = "";
3989         }
3990         my $search_hash;
3991         if (defined $hash_base) {
3992                 $search_hash = $hash_base;
3993         } elsif (defined $hash) {
3994                 $search_hash = $hash;
3995         } else {
3996                 $search_hash = "HEAD";
3997         }
3998         my $action = $my_uri;
3999         my $use_pathinfo = gitweb_check_feature('pathinfo');
4000         if ($use_pathinfo) {
4001                 $action .= "/".esc_url($project);
4002         }
4003         print $cgi->startform(-method => "get", -action => $action) .
4004               "<div class=\"search\">\n" .
4005               (!$use_pathinfo &&
4006               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4007               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4008               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4009               $cgi->popup_menu(-name => 'st', -default => 'commit',
4010                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4011               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
4012               " search:\n",
4013               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4014               "<span title=\"Extended regular expression\">" .
4015               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4016                              -checked => $search_use_regexp) .
4017               "</span>" .
4018               "</div>" .
4019               $cgi->end_form() . "\n";
4020 }
4021
4022 sub git_header_html {
4023         my $status = shift || "200 OK";
4024         my $expires = shift;
4025         my %opts = @_;
4026
4027         my $title = get_page_title();
4028         my $content_type = get_content_type_html();
4029         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4030                            -status=> $status, -expires => $expires)
4031                 unless ($opts{'-no_http_header'});
4032         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4033         print <<EOF;
4034 <?xml version="1.0" encoding="utf-8"?>
4035 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4036 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4037 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4038 <!-- git core binaries version $git_version -->
4039 <head>
4040 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4041 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4042 <meta name="robots" content="index, nofollow"/>
4043 <title>$title</title>
4044 EOF
4045         # the stylesheet, favicon etc urls won't work correctly with path_info
4046         # unless we set the appropriate base URL
4047         if ($ENV{'PATH_INFO'}) {
4048                 print "<base href=\"".esc_url($base_url)."\" />\n";
4049         }
4050         print_header_links($status);
4051
4052         if (defined $site_html_head_string) {
4053                 print to_utf8($site_html_head_string);
4054         }
4055
4056         print "</head>\n" .
4057               "<body>\n";
4058
4059         if (defined $site_header && -f $site_header) {
4060                 insert_file($site_header);
4061         }
4062
4063         print "<div class=\"page_header\">\n";
4064         if (defined $logo) {
4065                 print $cgi->a({-href => esc_url($logo_url),
4066                                -title => $logo_label},
4067                               $cgi->img({-src => esc_url($logo),
4068                                          -width => 72, -height => 27,
4069                                          -alt => "git",
4070                                          -class => "logo"}));
4071         }
4072         print_nav_breadcrumbs(%opts);
4073         print "</div>\n";
4074
4075         my $have_search = gitweb_check_feature('search');
4076         if (defined $project && $have_search) {
4077                 print_search_form();
4078         }
4079 }
4080
4081 sub git_footer_html {
4082         my $feed_class = 'rss_logo';
4083
4084         print "<div class=\"page_footer\">\n";
4085         if (defined $project) {
4086                 my $descr = git_get_project_description($project);
4087                 if (defined $descr) {
4088                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4089                 }
4090
4091                 my %href_params = get_feed_info();
4092                 if (!%href_params) {
4093                         $feed_class .= ' generic';
4094                 }
4095                 $href_params{'-title'} ||= 'log';
4096
4097                 foreach my $format (qw(RSS Atom)) {
4098                         $href_params{'action'} = lc($format);
4099                         print $cgi->a({-href => href(%href_params),
4100                                       -title => "$href_params{'-title'} $format feed",
4101                                       -class => $feed_class}, $format)."\n";
4102                 }
4103
4104         } else {
4105                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4106                                              project_filter => $project_filter),
4107                               -class => $feed_class}, "OPML") . " ";
4108                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4109                                              project_filter => $project_filter),
4110                               -class => $feed_class}, "TXT") . "\n";
4111         }
4112         print "</div>\n"; # class="page_footer"
4113
4114         if (defined $t0 && gitweb_check_feature('timed')) {
4115                 print "<div id=\"generating_info\">\n";
4116                 print 'This page took '.
4117                       '<span id="generating_time" class="time_span">'.
4118                       tv_interval($t0, [ gettimeofday() ]).
4119                       ' seconds </span>'.
4120                       ' and '.
4121                       '<span id="generating_cmd">'.
4122                       $number_of_git_cmds.
4123                       '</span> git commands '.
4124                       " to generate.\n";
4125                 print "</div>\n"; # class="page_footer"
4126         }
4127
4128         if (defined $site_footer && -f $site_footer) {
4129                 insert_file($site_footer);
4130         }
4131
4132         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4133         if (defined $action &&
4134             $action eq 'blame_incremental') {
4135                 print qq!<script type="text/javascript">\n!.
4136                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4137                       qq!           "!. href() .qq!");\n!.
4138                       qq!</script>\n!;
4139         } else {
4140                 my ($jstimezone, $tz_cookie, $datetime_class) =
4141                         gitweb_get_feature('javascript-timezone');
4142
4143                 print qq!<script type="text/javascript">\n!.
4144                       qq!window.onload = function () {\n!;
4145                 if (gitweb_check_feature('javascript-actions')) {
4146                         print qq!       fixLinks();\n!;
4147                 }
4148                 if ($jstimezone && $tz_cookie && $datetime_class) {
4149                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4150                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4151                 }
4152                 print qq!};\n!.
4153                       qq!</script>\n!;
4154         }
4155
4156         print "</body>\n" .
4157               "</html>";
4158 }
4159
4160 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4161 # Example: die_error(404, 'Hash not found')
4162 # By convention, use the following status codes (as defined in RFC 2616):
4163 # 400: Invalid or missing CGI parameters, or
4164 #      requested object exists but has wrong type.
4165 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4166 #      this server or project.
4167 # 404: Requested object/revision/project doesn't exist.
4168 # 500: The server isn't configured properly, or
4169 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4170 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4171 # 503: The server is currently unavailable (because it is overloaded,
4172 #      or down for maintenance).  Generally, this is a temporary state.
4173 sub die_error {
4174         my $status = shift || 500;
4175         my $error = esc_html(shift) || "Internal Server Error";
4176         my $extra = shift;
4177         my %opts = @_;
4178
4179         my %http_responses = (
4180                 400 => '400 Bad Request',
4181                 403 => '403 Forbidden',
4182                 404 => '404 Not Found',
4183                 500 => '500 Internal Server Error',
4184                 503 => '503 Service Unavailable',
4185         );
4186         git_header_html($http_responses{$status}, undef, %opts);
4187         print <<EOF;
4188 <div class="page_body">
4189 <br /><br />
4190 $status - $error
4191 <br />
4192 EOF
4193         if (defined $extra) {
4194                 print "<hr />\n" .
4195                       "$extra\n";
4196         }
4197         print "</div>\n";
4198
4199         git_footer_html();
4200         goto DONE_GITWEB
4201                 unless ($opts{'-error_handler'});
4202 }
4203
4204 ## ----------------------------------------------------------------------
4205 ## functions printing or outputting HTML: navigation
4206
4207 sub git_print_page_nav {
4208         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4209         $extra = '' if !defined $extra; # pager or formats
4210
4211         my @navs = qw(summary shortlog log commit commitdiff tree);
4212         if ($suppress) {
4213                 @navs = grep { $_ ne $suppress } @navs;
4214         }
4215
4216         my %arg = map { $_ => {action=>$_} } @navs;
4217         if (defined $head) {
4218                 for (qw(commit commitdiff)) {
4219                         $arg{$_}{'hash'} = $head;
4220                 }
4221                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4222                         for (qw(shortlog log)) {
4223                                 $arg{$_}{'hash'} = $head;
4224                         }
4225                 }
4226         }
4227
4228         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4229         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4230
4231         my @actions = gitweb_get_feature('actions');
4232         my %repl = (
4233                 '%' => '%',
4234                 'n' => $project,         # project name
4235                 'f' => $git_dir,         # project path within filesystem
4236                 'h' => $treehead || '',  # current hash ('h' parameter)
4237                 'b' => $treebase || '',  # hash base ('hb' parameter)
4238         );
4239         while (@actions) {
4240                 my ($label, $link, $pos) = splice(@actions,0,3);
4241                 # insert
4242                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4243                 # munch munch
4244                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4245                 $arg{$label}{'_href'} = $link;
4246         }
4247
4248         print "<div class=\"page_nav\">\n" .
4249                 (join " | ",
4250                  map { $_ eq $current ?
4251                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4252                  } @navs);
4253         print "<br/>\n$extra<br/>\n" .
4254               "</div>\n";
4255 }
4256
4257 # returns a submenu for the nagivation of the refs views (tags, heads,
4258 # remotes) with the current view disabled and the remotes view only
4259 # available if the feature is enabled
4260 sub format_ref_views {
4261         my ($current) = @_;
4262         my @ref_views = qw{tags heads};
4263         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4264         return join " | ", map {
4265                 $_ eq $current ? $_ :
4266                 $cgi->a({-href => href(action=>$_)}, $_)
4267         } @ref_views
4268 }
4269
4270 sub format_paging_nav {
4271         my ($action, $page, $has_next_link) = @_;
4272         my $paging_nav;
4273
4274
4275         if ($page > 0) {
4276                 $paging_nav .=
4277                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4278                         " &sdot; " .
4279                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4280                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4281         } else {
4282                 $paging_nav .= "first &sdot; prev";
4283         }
4284
4285         if ($has_next_link) {
4286                 $paging_nav .= " &sdot; " .
4287                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4288                                  -accesskey => "n", -title => "Alt-n"}, "next");
4289         } else {
4290                 $paging_nav .= " &sdot; next";
4291         }
4292
4293         return $paging_nav;
4294 }
4295
4296 ## ......................................................................
4297 ## functions printing or outputting HTML: div
4298
4299 sub git_print_header_div {
4300         my ($action, $title, $hash, $hash_base) = @_;
4301         my %args = ();
4302
4303         $args{'action'} = $action;
4304         $args{'hash'} = $hash if $hash;
4305         $args{'hash_base'} = $hash_base if $hash_base;
4306
4307         print "<div class=\"header\">\n" .
4308               $cgi->a({-href => href(%args), -class => "title"},
4309               $title ? $title : $action) .
4310               "\n</div>\n";
4311 }
4312
4313 sub format_repo_url {
4314         my ($name, $url) = @_;
4315         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4316 }
4317
4318 # Group output by placing it in a DIV element and adding a header.
4319 # Options for start_div() can be provided by passing a hash reference as the
4320 # first parameter to the function.
4321 # Options to git_print_header_div() can be provided by passing an array
4322 # reference. This must follow the options to start_div if they are present.
4323 # The content can be a scalar, which is output as-is, a scalar reference, which
4324 # is output after html escaping, an IO handle passed either as *handle or
4325 # *handle{IO}, or a function reference. In the latter case all following
4326 # parameters will be taken as argument to the content function call.
4327 sub git_print_section {
4328         my ($div_args, $header_args, $content);
4329         my $arg = shift;
4330         if (ref($arg) eq 'HASH') {
4331                 $div_args = $arg;
4332                 $arg = shift;
4333         }
4334         if (ref($arg) eq 'ARRAY') {
4335                 $header_args = $arg;
4336                 $arg = shift;
4337         }
4338         $content = $arg;
4339
4340         print $cgi->start_div($div_args);
4341         git_print_header_div(@$header_args);
4342
4343         if (ref($content) eq 'CODE') {
4344                 $content->(@_);
4345         } elsif (ref($content) eq 'SCALAR') {
4346                 print esc_html($$content);
4347         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4348                 print <$content>;
4349         } elsif (!ref($content) && defined($content)) {
4350                 print $content;
4351         }
4352
4353         print $cgi->end_div;
4354 }
4355
4356 sub format_timestamp_html {
4357         my $date = shift;
4358         my $strtime = $date->{'rfc2822'};
4359
4360         my (undef, undef, $datetime_class) =
4361                 gitweb_get_feature('javascript-timezone');
4362         if ($datetime_class) {
4363                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4364         }
4365
4366         my $localtime_format = '(%02d:%02d %s)';
4367         if ($date->{'hour_local'} < 6) {
4368                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4369         }
4370         $strtime .= ' ' .
4371                     sprintf($localtime_format,
4372                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4373
4374         return $strtime;
4375 }
4376
4377 # Outputs the author name and date in long form
4378 sub git_print_authorship {
4379         my $co = shift;
4380         my %opts = @_;
4381         my $tag = $opts{-tag} || 'div';
4382         my $author = $co->{'author_name'};
4383
4384         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4385         print "<$tag class=\"author_date\">" .
4386               format_search_author($author, "author", esc_html($author)) .
4387               " [".format_timestamp_html(\%ad)."]".
4388               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4389               "</$tag>\n";
4390 }
4391
4392 # Outputs table rows containing the full author or committer information,
4393 # in the format expected for 'commit' view (& similar).
4394 # Parameters are a commit hash reference, followed by the list of people
4395 # to output information for. If the list is empty it defaults to both
4396 # author and committer.
4397 sub git_print_authorship_rows {
4398         my $co = shift;
4399         # too bad we can't use @people = @_ || ('author', 'committer')
4400         my @people = @_;
4401         @people = ('author', 'committer') unless @people;
4402         foreach my $who (@people) {
4403                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4404                 print "<tr><td>$who</td><td>" .
4405                       format_search_author($co->{"${who}_name"}, $who,
4406                                            esc_html($co->{"${who}_name"})) . " " .
4407                       format_search_author($co->{"${who}_email"}, $who,
4408                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4409                       "</td><td rowspan=\"2\">" .
4410                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4411                       "</td></tr>\n" .
4412                       "<tr>" .
4413                       "<td></td><td>" .
4414                       format_timestamp_html(\%wd) .
4415                       "</td>" .
4416                       "</tr>\n";
4417         }
4418 }
4419
4420 sub git_print_page_path {
4421         my $name = shift;
4422         my $type = shift;
4423         my $hb = shift;
4424
4425
4426         print "<div class=\"page_path\">";
4427         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4428                       -title => 'tree root'}, to_utf8("[$project]"));
4429         print " / ";
4430         if (defined $name) {
4431                 my @dirname = split '/', $name;
4432                 my $basename = pop @dirname;
4433                 my $fullname = '';
4434
4435                 foreach my $dir (@dirname) {
4436                         $fullname .= ($fullname ? '/' : '') . $dir;
4437                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4438                                                      hash_base=>$hb),
4439                                       -title => $fullname}, esc_path($dir));
4440                         print " / ";
4441                 }
4442                 if (defined $type && $type eq 'blob') {
4443                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4444                                                      hash_base=>$hb),
4445                                       -title => $name}, esc_path($basename));
4446                 } elsif (defined $type && $type eq 'tree') {
4447                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4448                                                      hash_base=>$hb),
4449                                       -title => $name}, esc_path($basename));
4450                         print " / ";
4451                 } else {
4452                         print esc_path($basename);
4453                 }
4454         }
4455         print "<br/></div>\n";
4456 }
4457
4458 sub git_print_log {
4459         my $log = shift;
4460         my %opts = @_;
4461
4462         if ($opts{'-remove_title'}) {
4463                 # remove title, i.e. first line of log
4464                 shift @$log;
4465         }
4466         # remove leading empty lines
4467         while (defined $log->[0] && $log->[0] eq "") {
4468                 shift @$log;
4469         }
4470
4471         # print log
4472         my $signoff = 0;
4473         my $empty = 0;
4474         foreach my $line (@$log) {
4475                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4476                         $signoff = 1;
4477                         $empty = 0;
4478                         if (! $opts{'-remove_signoff'}) {
4479                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4480                                 next;
4481                         } else {
4482                                 # remove signoff lines
4483                                 next;
4484                         }
4485                 } else {
4486                         $signoff = 0;
4487                 }
4488
4489                 # print only one empty line
4490                 # do not print empty line after signoff
4491                 if ($line eq "") {
4492                         next if ($empty || $signoff);
4493                         $empty = 1;
4494                 } else {
4495                         $empty = 0;
4496                 }
4497
4498                 print format_log_line_html($line) . "<br/>\n";
4499         }
4500
4501         if ($opts{'-final_empty_line'}) {
4502                 # end with single empty line
4503                 print "<br/>\n" unless $empty;
4504         }
4505 }
4506
4507 # return link target (what link points to)
4508 sub git_get_link_target {
4509         my $hash = shift;
4510         my $link_target;
4511
4512         # read link
4513         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4514                 or return;
4515         {
4516                 local $/ = undef;
4517                 $link_target = <$fd>;
4518         }
4519         close $fd
4520                 or return;
4521
4522         return $link_target;
4523 }
4524
4525 # given link target, and the directory (basedir) the link is in,
4526 # return target of link relative to top directory (top tree);
4527 # return undef if it is not possible (including absolute links).
4528 sub normalize_link_target {
4529         my ($link_target, $basedir) = @_;
4530
4531         # absolute symlinks (beginning with '/') cannot be normalized
4532         return if (substr($link_target, 0, 1) eq '/');
4533
4534         # normalize link target to path from top (root) tree (dir)
4535         my $path;
4536         if ($basedir) {
4537                 $path = $basedir . '/' . $link_target;
4538         } else {
4539                 # we are in top (root) tree (dir)
4540                 $path = $link_target;
4541         }
4542
4543         # remove //, /./, and /../
4544         my @path_parts;
4545         foreach my $part (split('/', $path)) {
4546                 # discard '.' and ''
4547                 next if (!$part || $part eq '.');
4548                 # handle '..'
4549                 if ($part eq '..') {
4550                         if (@path_parts) {
4551                                 pop @path_parts;
4552                         } else {
4553                                 # link leads outside repository (outside top dir)
4554                                 return;
4555                         }
4556                 } else {
4557                         push @path_parts, $part;
4558                 }
4559         }
4560         $path = join('/', @path_parts);
4561
4562         return $path;
4563 }
4564
4565 # print tree entry (row of git_tree), but without encompassing <tr> element
4566 sub git_print_tree_entry {
4567         my ($t, $basedir, $hash_base, $have_blame) = @_;
4568
4569         my %base_key = ();
4570         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4571
4572         # The format of a table row is: mode list link.  Where mode is
4573         # the mode of the entry, list is the name of the entry, an href,
4574         # and link is the action links of the entry.
4575
4576         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4577         if (exists $t->{'size'}) {
4578                 print "<td class=\"size\">$t->{'size'}</td>\n";
4579         }
4580         if ($t->{'type'} eq "blob") {
4581                 print "<td class=\"list\">" .
4582                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4583                                                file_name=>"$basedir$t->{'name'}", %base_key),
4584                                 -class => "list"}, esc_path($t->{'name'}));
4585                 if (S_ISLNK(oct $t->{'mode'})) {
4586                         my $link_target = git_get_link_target($t->{'hash'});
4587                         if ($link_target) {
4588                                 my $norm_target = normalize_link_target($link_target, $basedir);
4589                                 if (defined $norm_target) {
4590                                         print " -> " .
4591                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4592                                                                      file_name=>$norm_target),
4593                                                        -title => $norm_target}, esc_path($link_target));
4594                                 } else {
4595                                         print " -> " . esc_path($link_target);
4596                                 }
4597                         }
4598                 }
4599                 print "</td>\n";
4600                 print "<td class=\"link\">";
4601                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4602                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4603                               "blob");
4604                 if ($have_blame) {
4605                         print " | " .
4606                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4607                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4608                                       "blame");
4609                 }
4610                 if (defined $hash_base) {
4611                         print " | " .
4612                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4613                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4614                                       "history");
4615                 }
4616                 print " | " .
4617                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4618                                                file_name=>"$basedir$t->{'name'}")},
4619                                 "raw");
4620                 print "</td>\n";
4621
4622         } elsif ($t->{'type'} eq "tree") {
4623                 print "<td class=\"list\">";
4624                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4625                                              file_name=>"$basedir$t->{'name'}",
4626                                              %base_key)},
4627                               esc_path($t->{'name'}));
4628                 print "</td>\n";
4629                 print "<td class=\"link\">";
4630                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4631                                              file_name=>"$basedir$t->{'name'}",
4632                                              %base_key)},
4633                               "tree");
4634                 if (defined $hash_base) {
4635                         print " | " .
4636                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4637                                                      file_name=>"$basedir$t->{'name'}")},
4638                                       "history");
4639                 }
4640                 print "</td>\n";
4641         } else {
4642                 # unknown object: we can only present history for it
4643                 # (this includes 'commit' object, i.e. submodule support)
4644                 print "<td class=\"list\">" .
4645                       esc_path($t->{'name'}) .
4646                       "</td>\n";
4647                 print "<td class=\"link\">";
4648                 if (defined $hash_base) {
4649                         print $cgi->a({-href => href(action=>"history",
4650                                                      hash_base=>$hash_base,
4651                                                      file_name=>"$basedir$t->{'name'}")},
4652                                       "history");
4653                 }
4654                 print "</td>\n";
4655         }
4656 }
4657
4658 ## ......................................................................
4659 ## functions printing large fragments of HTML
4660
4661 # get pre-image filenames for merge (combined) diff
4662 sub fill_from_file_info {
4663         my ($diff, @parents) = @_;
4664
4665         $diff->{'from_file'} = [ ];
4666         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4667         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4668                 if ($diff->{'status'}[$i] eq 'R' ||
4669                     $diff->{'status'}[$i] eq 'C') {
4670                         $diff->{'from_file'}[$i] =
4671                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4672                 }
4673         }
4674
4675         return $diff;
4676 }
4677
4678 # is current raw difftree line of file deletion
4679 sub is_deleted {
4680         my $diffinfo = shift;
4681
4682         return $diffinfo->{'to_id'} eq ('0' x 40);
4683 }
4684
4685 # does patch correspond to [previous] difftree raw line
4686 # $diffinfo  - hashref of parsed raw diff format
4687 # $patchinfo - hashref of parsed patch diff format
4688 #              (the same keys as in $diffinfo)
4689 sub is_patch_split {
4690         my ($diffinfo, $patchinfo) = @_;
4691
4692         return defined $diffinfo && defined $patchinfo
4693                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4694 }
4695
4696
4697 sub git_difftree_body {
4698         my ($difftree, $hash, @parents) = @_;
4699         my ($parent) = $parents[0];
4700         my $have_blame = gitweb_check_feature('blame');
4701         print "<div class=\"list_head\">\n";
4702         if ($#{$difftree} > 10) {
4703                 print(($#{$difftree} + 1) . " files changed:\n");
4704         }
4705         print "</div>\n";
4706
4707         print "<table class=\"" .
4708               (@parents > 1 ? "combined " : "") .
4709               "diff_tree\">\n";
4710
4711         # header only for combined diff in 'commitdiff' view
4712         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4713         if ($has_header) {
4714                 # table header
4715                 print "<thead><tr>\n" .
4716                        "<th></th><th></th>\n"; # filename, patchN link
4717                 for (my $i = 0; $i < @parents; $i++) {
4718                         my $par = $parents[$i];
4719                         print "<th>" .
4720                               $cgi->a({-href => href(action=>"commitdiff",
4721                                                      hash=>$hash, hash_parent=>$par),
4722                                        -title => 'commitdiff to parent number ' .
4723                                                   ($i+1) . ': ' . substr($par,0,7)},
4724                                       $i+1) .
4725                               "&nbsp;</th>\n";
4726                 }
4727                 print "</tr></thead>\n<tbody>\n";
4728         }
4729
4730         my $alternate = 1;
4731         my $patchno = 0;
4732         foreach my $line (@{$difftree}) {
4733                 my $diff = parsed_difftree_line($line);
4734
4735                 if ($alternate) {
4736                         print "<tr class=\"dark\">\n";
4737                 } else {
4738                         print "<tr class=\"light\">\n";
4739                 }
4740                 $alternate ^= 1;
4741
4742                 if (exists $diff->{'nparents'}) { # combined diff
4743
4744                         fill_from_file_info($diff, @parents)
4745                                 unless exists $diff->{'from_file'};
4746
4747                         if (!is_deleted($diff)) {
4748                                 # file exists in the result (child) commit
4749                                 print "<td>" .
4750                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4751                                                              file_name=>$diff->{'to_file'},
4752                                                              hash_base=>$hash),
4753                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4754                                       "</td>\n";
4755                         } else {
4756                                 print "<td>" .
4757                                       esc_path($diff->{'to_file'}) .
4758                                       "</td>\n";
4759                         }
4760
4761                         if ($action eq 'commitdiff') {
4762                                 # link to patch
4763                                 $patchno++;
4764                                 print "<td class=\"link\">" .
4765                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4766                                               "patch") .
4767                                       " | " .
4768                                       "</td>\n";
4769                         }
4770
4771                         my $has_history = 0;
4772                         my $not_deleted = 0;
4773                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4774                                 my $hash_parent = $parents[$i];
4775                                 my $from_hash = $diff->{'from_id'}[$i];
4776                                 my $from_path = $diff->{'from_file'}[$i];
4777                                 my $status = $diff->{'status'}[$i];
4778
4779                                 $has_history ||= ($status ne 'A');
4780                                 $not_deleted ||= ($status ne 'D');
4781
4782                                 if ($status eq 'A') {
4783                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4784                                 } elsif ($status eq 'D') {
4785                                         print "<td class=\"link\">" .
4786                                               $cgi->a({-href => href(action=>"blob",
4787                                                                      hash_base=>$hash,
4788                                                                      hash=>$from_hash,
4789                                                                      file_name=>$from_path)},
4790                                                       "blob" . ($i+1)) .
4791                                               " | </td>\n";
4792                                 } else {
4793                                         if ($diff->{'to_id'} eq $from_hash) {
4794                                                 print "<td class=\"link nochange\">";
4795                                         } else {
4796                                                 print "<td class=\"link\">";
4797                                         }
4798                                         print $cgi->a({-href => href(action=>"blobdiff",
4799                                                                      hash=>$diff->{'to_id'},
4800                                                                      hash_parent=>$from_hash,
4801                                                                      hash_base=>$hash,
4802                                                                      hash_parent_base=>$hash_parent,
4803                                                                      file_name=>$diff->{'to_file'},
4804                                                                      file_parent=>$from_path)},
4805                                                       "diff" . ($i+1)) .
4806                                               " | </td>\n";
4807                                 }
4808                         }
4809
4810                         print "<td class=\"link\">";
4811                         if ($not_deleted) {
4812                                 print $cgi->a({-href => href(action=>"blob",
4813                                                              hash=>$diff->{'to_id'},
4814                                                              file_name=>$diff->{'to_file'},
4815                                                              hash_base=>$hash)},
4816                                               "blob");
4817                                 print " | " if ($has_history);
4818                         }
4819                         if ($has_history) {
4820                                 print $cgi->a({-href => href(action=>"history",
4821                                                              file_name=>$diff->{'to_file'},
4822                                                              hash_base=>$hash)},
4823                                               "history");
4824                         }
4825                         print "</td>\n";
4826
4827                         print "</tr>\n";
4828                         next; # instead of 'else' clause, to avoid extra indent
4829                 }
4830                 # else ordinary diff
4831
4832                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4833                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4834                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4835                         $to_mode_oct = oct $diff->{'to_mode'};
4836                         if (S_ISREG($to_mode_oct)) { # only for regular file
4837                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4838                         }
4839                         $to_file_type = file_type($diff->{'to_mode'});
4840                 }
4841                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4842                         $from_mode_oct = oct $diff->{'from_mode'};
4843                         if (S_ISREG($from_mode_oct)) { # only for regular file
4844                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4845                         }
4846                         $from_file_type = file_type($diff->{'from_mode'});
4847                 }
4848
4849                 if ($diff->{'status'} eq "A") { # created
4850                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4851                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4852                         $mode_chng   .= "]</span>";
4853                         print "<td>";
4854                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4855                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4856                                       -class => "list"}, esc_path($diff->{'file'}));
4857                         print "</td>\n";
4858                         print "<td>$mode_chng</td>\n";
4859                         print "<td class=\"link\">";
4860                         if ($action eq 'commitdiff') {
4861                                 # link to patch
4862                                 $patchno++;
4863                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4864                                               "patch") .
4865                                       " | ";
4866                         }
4867                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4868                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4869                                       "blob");
4870                         print "</td>\n";
4871
4872                 } elsif ($diff->{'status'} eq "D") { # deleted
4873                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4874                         print "<td>";
4875                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4876                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4877                                        -class => "list"}, esc_path($diff->{'file'}));
4878                         print "</td>\n";
4879                         print "<td>$mode_chng</td>\n";
4880                         print "<td class=\"link\">";
4881                         if ($action eq 'commitdiff') {
4882                                 # link to patch
4883                                 $patchno++;
4884                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4885                                               "patch") .
4886                                       " | ";
4887                         }
4888                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4889                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4890                                       "blob") . " | ";
4891                         if ($have_blame) {
4892                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4893                                                              file_name=>$diff->{'file'})},
4894                                               "blame") . " | ";
4895                         }
4896                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4897                                                      file_name=>$diff->{'file'})},
4898                                       "history");
4899                         print "</td>\n";
4900
4901                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4902                         my $mode_chnge = "";
4903                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4904                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4905                                 if ($from_file_type ne $to_file_type) {
4906                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4907                                 }
4908                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4909                                         if ($from_mode_str && $to_mode_str) {
4910                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4911                                         } elsif ($to_mode_str) {
4912                                                 $mode_chnge .= " mode: $to_mode_str";
4913                                         }
4914                                 }
4915                                 $mode_chnge .= "]</span>\n";
4916                         }
4917                         print "<td>";
4918                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4919                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4920                                       -class => "list"}, esc_path($diff->{'file'}));
4921                         print "</td>\n";
4922                         print "<td>$mode_chnge</td>\n";
4923                         print "<td class=\"link\">";
4924                         if ($action eq 'commitdiff') {
4925                                 # link to patch
4926                                 $patchno++;
4927                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4928                                               "patch") .
4929                                       " | ";
4930                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4931                                 # "commit" view and modified file (not onlu mode changed)
4932                                 print $cgi->a({-href => href(action=>"blobdiff",
4933                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4934                                                              hash_base=>$hash, hash_parent_base=>$parent,
4935                                                              file_name=>$diff->{'file'})},
4936                                               "diff") .
4937                                       " | ";
4938                         }
4939                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4940                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4941                                        "blob") . " | ";
4942                         if ($have_blame) {
4943                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4944                                                              file_name=>$diff->{'file'})},
4945                                               "blame") . " | ";
4946                         }
4947                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4948                                                      file_name=>$diff->{'file'})},
4949                                       "history");
4950                         print "</td>\n";
4951
4952                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4953                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4954                         my $nstatus = $status_name{$diff->{'status'}};
4955                         my $mode_chng = "";
4956                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4957                                 # mode also for directories, so we cannot use $to_mode_str
4958                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4959                         }
4960                         print "<td>" .
4961                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4962                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4963                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4964                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4965                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4966                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4967                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4968                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4969                               "<td class=\"link\">";
4970                         if ($action eq 'commitdiff') {
4971                                 # link to patch
4972                                 $patchno++;
4973                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4974                                               "patch") .
4975                                       " | ";
4976                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4977                                 # "commit" view and modified file (not only pure rename or copy)
4978                                 print $cgi->a({-href => href(action=>"blobdiff",
4979                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4980                                                              hash_base=>$hash, hash_parent_base=>$parent,
4981                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4982                                               "diff") .
4983                                       " | ";
4984                         }
4985                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4986                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4987                                       "blob") . " | ";
4988                         if ($have_blame) {
4989                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4990                                                              file_name=>$diff->{'to_file'})},
4991                                               "blame") . " | ";
4992                         }
4993                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4994                                                     file_name=>$diff->{'to_file'})},
4995                                       "history");
4996                         print "</td>\n";
4997
4998                 } # we should not encounter Unmerged (U) or Unknown (X) status
4999                 print "</tr>\n";
5000         }
5001         print "</tbody>" if $has_header;
5002         print "</table>\n";
5003 }
5004
5005 # Print context lines and then rem/add lines in a side-by-side manner.
5006 sub print_sidebyside_diff_lines {
5007         my ($ctx, $rem, $add) = @_;
5008
5009         # print context block before add/rem block
5010         if (@$ctx) {
5011                 print join '',
5012                         '<div class="chunk_block ctx">',
5013                                 '<div class="old">',
5014                                 @$ctx,
5015                                 '</div>',
5016                                 '<div class="new">',
5017                                 @$ctx,
5018                                 '</div>',
5019                         '</div>';
5020         }
5021
5022         if (!@$add) {
5023                 # pure removal
5024                 print join '',
5025                         '<div class="chunk_block rem">',
5026                                 '<div class="old">',
5027                                 @$rem,
5028                                 '</div>',
5029                         '</div>';
5030         } elsif (!@$rem) {
5031                 # pure addition
5032                 print join '',
5033                         '<div class="chunk_block add">',
5034                                 '<div class="new">',
5035                                 @$add,
5036                                 '</div>',
5037                         '</div>';
5038         } else {
5039                 print join '',
5040                         '<div class="chunk_block chg">',
5041                                 '<div class="old">',
5042                                 @$rem,
5043                                 '</div>',
5044                                 '<div class="new">',
5045                                 @$add,
5046                                 '</div>',
5047                         '</div>';
5048         }
5049 }
5050
5051 sub print_sidebyside_diff_chunk {
5052         my @chunk = @_;
5053         my (@ctx, @rem, @add);
5054
5055         return unless @chunk;
5056
5057         # incomplete last line might be among removed or added lines,
5058         # or both, or among context lines: find which
5059         for (my $i = 1; $i < @chunk; $i++) {
5060                 if ($chunk[$i][0] eq 'incomplete') {
5061                         $chunk[$i][0] = $chunk[$i-1][0];
5062                 }
5063         }
5064
5065         # guardian
5066         push @chunk, ["", ""];
5067
5068         foreach my $line_info (@chunk) {
5069                 my ($class, $line) = @$line_info;
5070
5071                 # print chunk headers
5072                 if ($class && $class eq 'chunk_header') {
5073                         print $line;
5074                         next;
5075                 }
5076
5077                 ## print from accumulator when have some add/rem lines or end
5078                 # of chunk (flush context lines)
5079                 if (!$class || ((@rem || @add) && $class eq 'ctx')) {
5080                         print_sidebyside_diff_lines(\@ctx, \@rem, \@add);
5081                         @ctx = @rem = @add = ();
5082                 }
5083
5084                 ## adding lines to accumulator
5085                 # guardian value
5086                 last unless $line;
5087                 # rem, add or change
5088                 if ($class eq 'rem') {
5089                         push @rem, $line;
5090                 } elsif ($class eq 'add') {
5091                         push @add, $line;
5092                 }
5093                 # context line
5094                 if ($class eq 'ctx') {
5095                         push @ctx, $line;
5096                 }
5097         }
5098 }
5099
5100 sub git_patchset_body {
5101         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5102         my ($hash_parent) = $hash_parents[0];
5103
5104         my $is_combined = (@hash_parents > 1);
5105         my $patch_idx = 0;
5106         my $patch_number = 0;
5107         my $patch_line;
5108         my $diffinfo;
5109         my $to_name;
5110         my (%from, %to);
5111         my @chunk; # for side-by-side diff
5112
5113         print "<div class=\"patchset\">\n";
5114
5115         # skip to first patch
5116         while ($patch_line = <$fd>) {
5117                 chomp $patch_line;
5118
5119                 last if ($patch_line =~ m/^diff /);
5120         }
5121
5122  PATCH:
5123         while ($patch_line) {
5124
5125                 # parse "git diff" header line
5126                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5127                         # $1 is from_name, which we do not use
5128                         $to_name = unquote($2);
5129                         $to_name =~ s!^b/!!;
5130                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5131                         # $1 is 'cc' or 'combined', which we do not use
5132                         $to_name = unquote($2);
5133                 } else {
5134                         $to_name = undef;
5135                 }
5136
5137                 # check if current patch belong to current raw line
5138                 # and parse raw git-diff line if needed
5139                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5140                         # this is continuation of a split patch
5141                         print "<div class=\"patch cont\">\n";
5142                 } else {
5143                         # advance raw git-diff output if needed
5144                         $patch_idx++ if defined $diffinfo;
5145
5146                         # read and prepare patch information
5147                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5148
5149                         # compact combined diff output can have some patches skipped
5150                         # find which patch (using pathname of result) we are at now;
5151                         if ($is_combined) {
5152                                 while ($to_name ne $diffinfo->{'to_file'}) {
5153                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5154                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5155                                               "</div>\n";  # class="patch"
5156
5157                                         $patch_idx++;
5158                                         $patch_number++;
5159
5160                                         last if $patch_idx > $#$difftree;
5161                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5162                                 }
5163                         }
5164
5165                         # modifies %from, %to hashes
5166                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5167
5168                         # this is first patch for raw difftree line with $patch_idx index
5169                         # we index @$difftree array from 0, but number patches from 1
5170                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5171                 }
5172
5173                 # git diff header
5174                 #assert($patch_line =~ m/^diff /) if DEBUG;
5175                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5176                 $patch_number++;
5177                 # print "git diff" header
5178                 print format_git_diff_header_line($patch_line, $diffinfo,
5179                                                   \%from, \%to);
5180
5181                 # print extended diff header
5182                 print "<div class=\"diff extended_header\">\n";
5183         EXTENDED_HEADER:
5184                 while ($patch_line = <$fd>) {
5185                         chomp $patch_line;
5186
5187                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5188
5189                         print format_extended_diff_header_line($patch_line, $diffinfo,
5190                                                                \%from, \%to);
5191                 }
5192                 print "</div>\n"; # class="diff extended_header"
5193
5194                 # from-file/to-file diff header
5195                 if (! $patch_line) {
5196                         print "</div>\n"; # class="patch"
5197                         last PATCH;
5198                 }
5199                 next PATCH if ($patch_line =~ m/^diff /);
5200                 #assert($patch_line =~ m/^---/) if DEBUG;
5201
5202                 my $last_patch_line = $patch_line;
5203                 $patch_line = <$fd>;
5204                 chomp $patch_line;
5205                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5206
5207                 print format_diff_from_to_header($last_patch_line, $patch_line,
5208                                                  $diffinfo, \%from, \%to,
5209                                                  @hash_parents);
5210
5211                 # the patch itself
5212         LINE:
5213                 while ($patch_line = <$fd>) {
5214                         chomp $patch_line;
5215
5216                         next PATCH if ($patch_line =~ m/^diff /);
5217
5218                         my ($class, $line) = process_diff_line($patch_line, \%from, \%to);
5219                         my $diff_classes = "diff";
5220                         $diff_classes .= " $class" if ($class);
5221                         $line = "<div class=\"$diff_classes\">$line</div>\n";
5222
5223                         if ($diff_style eq 'sidebyside' && !$is_combined) {
5224                                 if ($class eq 'chunk_header') {
5225                                         print_sidebyside_diff_chunk(@chunk);
5226                                         @chunk = ( [ $class, $line ] );
5227                                 } else {
5228                                         push @chunk, [ $class, $line ];
5229                                 }
5230                         } else {
5231                                 # default 'inline' style and unknown styles
5232                                 print $line;
5233                         }
5234                 }
5235
5236         } continue {
5237                 if (@chunk) {
5238                         print_sidebyside_diff_chunk(@chunk);
5239                         @chunk = ();
5240                 }
5241                 print "</div>\n"; # class="patch"
5242         }
5243
5244         # for compact combined (--cc) format, with chunk and patch simplification
5245         # the patchset might be empty, but there might be unprocessed raw lines
5246         for (++$patch_idx if $patch_number > 0;
5247              $patch_idx < @$difftree;
5248              ++$patch_idx) {
5249                 # read and prepare patch information
5250                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5251
5252                 # generate anchor for "patch" links in difftree / whatchanged part
5253                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5254                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5255                       "</div>\n";  # class="patch"
5256
5257                 $patch_number++;
5258         }
5259
5260         if ($patch_number == 0) {
5261                 if (@hash_parents > 1) {
5262                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5263                 } else {
5264                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5265                 }
5266         }
5267
5268         print "</div>\n"; # class="patchset"
5269 }
5270
5271 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5272
5273 sub git_project_search_form {
5274         my ($searchtext, $search_use_regexp) = @_;
5275
5276         my $limit = '';
5277         if ($project_filter) {
5278                 $limit = " in '$project_filter/'";
5279         }
5280
5281         print "<div class=\"projsearch\">\n";
5282         print $cgi->startform(-method => 'get', -action => $my_uri) .
5283               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5284         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5285                 if (defined $project_filter);
5286         print $cgi->textfield(-name => 's', -value => $searchtext,
5287                               -title => "Search project by name and description$limit",
5288                               -size => 60) . "\n" .
5289               "<span title=\"Extended regular expression\">" .
5290               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5291                              -checked => $search_use_regexp) .
5292               "</span>\n" .
5293               $cgi->submit(-name => 'btnS', -value => 'Search') .
5294               $cgi->end_form() . "\n" .
5295               $cgi->a({-href => href(project => undef, searchtext => undef,
5296                                      project_filter => $project_filter)},
5297                       esc_html("List all projects$limit")) . "<br />\n";
5298         print "</div>\n";
5299 }
5300
5301 # entry for given @keys needs filling if at least one of keys in list
5302 # is not present in %$project_info
5303 sub project_info_needs_filling {
5304         my ($project_info, @keys) = @_;
5305
5306         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5307         foreach my $key (@keys) {
5308                 if (!exists $project_info->{$key}) {
5309                         return 1;
5310                 }
5311         }
5312         return;
5313 }
5314
5315 # fills project list info (age, description, owner, category, forks, etc.)
5316 # for each project in the list, removing invalid projects from
5317 # returned list, or fill only specified info.
5318 #
5319 # Invalid projects are removed from the returned list if and only if you
5320 # ask 'age' or 'age_string' to be filled, because they are the only fields
5321 # that run unconditionally git command that requires repository, and
5322 # therefore do always check if project repository is invalid.
5323 #
5324 # USAGE:
5325 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5326 #   ensures that 'descr_long' and 'ctags' fields are filled
5327 # * @project_list = fill_project_list_info(\@project_list)
5328 #   ensures that all fields are filled (and invalid projects removed)
5329 #
5330 # NOTE: modifies $projlist, but does not remove entries from it
5331 sub fill_project_list_info {
5332         my ($projlist, @wanted_keys) = @_;
5333         my @projects;
5334         my $filter_set = sub { return @_; };
5335         if (@wanted_keys) {
5336                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5337                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5338         }
5339
5340         my $show_ctags = gitweb_check_feature('ctags');
5341  PROJECT:
5342         foreach my $pr (@$projlist) {
5343                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5344                         my (@activity) = git_get_last_activity($pr->{'path'});
5345                         unless (@activity) {
5346                                 next PROJECT;
5347                         }
5348                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5349                 }
5350                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5351                         my $descr = git_get_project_description($pr->{'path'}) || "";
5352                         $descr = to_utf8($descr);
5353                         $pr->{'descr_long'} = $descr;
5354                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5355                 }
5356                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5357                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5358                 }
5359                 if ($show_ctags &&
5360                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5361                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5362                 }
5363                 if ($projects_list_group_categories &&
5364                     project_info_needs_filling($pr, $filter_set->('category'))) {
5365                         my $cat = git_get_project_category($pr->{'path'}) ||
5366                                                            $project_list_default_category;
5367                         $pr->{'category'} = to_utf8($cat);
5368                 }
5369
5370                 push @projects, $pr;
5371         }
5372
5373         return @projects;
5374 }
5375
5376 sub sort_projects_list {
5377         my ($projlist, $order) = @_;
5378         my @projects;
5379
5380         my %order_info = (
5381                 project => { key => 'path', type => 'str' },
5382                 descr => { key => 'descr_long', type => 'str' },
5383                 owner => { key => 'owner', type => 'str' },
5384                 age => { key => 'age', type => 'num' }
5385         );
5386         my $oi = $order_info{$order};
5387         return @$projlist unless defined $oi;
5388         if ($oi->{'type'} eq 'str') {
5389                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5390         } else {
5391                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5392         }
5393
5394         return @projects;
5395 }
5396
5397 # returns a hash of categories, containing the list of project
5398 # belonging to each category
5399 sub build_projlist_by_category {
5400         my ($projlist, $from, $to) = @_;
5401         my %categories;
5402
5403         $from = 0 unless defined $from;
5404         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5405
5406         for (my $i = $from; $i <= $to; $i++) {
5407                 my $pr = $projlist->[$i];
5408                 push @{$categories{ $pr->{'category'} }}, $pr;
5409         }
5410
5411         return wantarray ? %categories : \%categories;
5412 }
5413
5414 # print 'sort by' <th> element, generating 'sort by $name' replay link
5415 # if that order is not selected
5416 sub print_sort_th {
5417         print format_sort_th(@_);
5418 }
5419
5420 sub format_sort_th {
5421         my ($name, $order, $header) = @_;
5422         my $sort_th = "";
5423         $header ||= ucfirst($name);
5424
5425         if ($order eq $name) {
5426                 $sort_th .= "<th>$header</th>\n";
5427         } else {
5428                 $sort_th .= "<th>" .
5429                             $cgi->a({-href => href(-replay=>1, order=>$name),
5430                                      -class => "header"}, $header) .
5431                             "</th>\n";
5432         }
5433
5434         return $sort_th;
5435 }
5436
5437 sub git_project_list_rows {
5438         my ($projlist, $from, $to, $check_forks) = @_;
5439
5440         $from = 0 unless defined $from;
5441         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5442
5443         my $alternate = 1;
5444         for (my $i = $from; $i <= $to; $i++) {
5445                 my $pr = $projlist->[$i];
5446
5447                 if ($alternate) {
5448                         print "<tr class=\"dark\">\n";
5449                 } else {
5450                         print "<tr class=\"light\">\n";
5451                 }
5452                 $alternate ^= 1;
5453
5454                 if ($check_forks) {
5455                         print "<td>";
5456                         if ($pr->{'forks'}) {
5457                                 my $nforks = scalar @{$pr->{'forks'}};
5458                                 if ($nforks > 0) {
5459                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5460                                                        -title => "$nforks forks"}, "+");
5461                                 } else {
5462                                         print $cgi->span({-title => "$nforks forks"}, "+");
5463                                 }
5464                         }
5465                         print "</td>\n";
5466                 }
5467                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5468                                         -class => "list"},
5469                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5470                       "</td>\n" .
5471                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5472                                         -class => "list",
5473                                         -title => $pr->{'descr_long'}},
5474                                         $search_regexp
5475                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5476                                                                     $pr->{'descr'}, $search_regexp)
5477                                         : esc_html($pr->{'descr'})) .
5478                       "</td>\n" .
5479                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5480                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5481                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5482                       "<td class=\"link\">" .
5483                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5484                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5485                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5486                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5487                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5488                       "</td>\n" .
5489                       "</tr>\n";
5490         }
5491 }
5492
5493 sub git_project_list_body {
5494         # actually uses global variable $project
5495         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5496         my @projects = @$projlist;
5497
5498         my $check_forks = gitweb_check_feature('forks');
5499         my $show_ctags  = gitweb_check_feature('ctags');
5500         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5501         $check_forks = undef
5502                 if ($tagfilter || $search_regexp);
5503
5504         # filtering out forks before filling info allows to do less work
5505         @projects = filter_forks_from_projects_list(\@projects)
5506                 if ($check_forks);
5507         # search_projects_list pre-fills required info
5508         @projects = search_projects_list(\@projects,
5509                                          'search_regexp' => $search_regexp,
5510                                          'tagfilter'  => $tagfilter)
5511                 if ($tagfilter || $search_regexp);
5512         # fill the rest
5513         @projects = fill_project_list_info(\@projects);
5514
5515         $order ||= $default_projects_order;
5516         $from = 0 unless defined $from;
5517         $to = $#projects if (!defined $to || $#projects < $to);
5518
5519         # short circuit
5520         if ($from > $to) {
5521                 print "<center>\n".
5522                       "<b>No such projects found</b><br />\n".
5523                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5524                       "</center>\n<br />\n";
5525                 return;
5526         }
5527
5528         @projects = sort_projects_list(\@projects, $order);
5529
5530         if ($show_ctags) {
5531                 my $ctags = git_gather_all_ctags(\@projects);
5532                 my $cloud = git_populate_project_tagcloud($ctags);
5533                 print git_show_project_tagcloud($cloud, 64);
5534         }
5535
5536         print "<table class=\"project_list\">\n";
5537         unless ($no_header) {
5538                 print "<tr>\n";
5539                 if ($check_forks) {
5540                         print "<th></th>\n";
5541                 }
5542                 print_sort_th('project', $order, 'Project');
5543                 print_sort_th('descr', $order, 'Description');
5544                 print_sort_th('owner', $order, 'Owner');
5545                 print_sort_th('age', $order, 'Last Change');
5546                 print "<th></th>\n" . # for links
5547                       "</tr>\n";
5548         }
5549
5550         if ($projects_list_group_categories) {
5551                 # only display categories with projects in the $from-$to window
5552                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5553                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5554                 foreach my $cat (sort keys %categories) {
5555                         unless ($cat eq "") {
5556                                 print "<tr>\n";
5557                                 if ($check_forks) {
5558                                         print "<td></td>\n";
5559                                 }
5560                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5561                                 print "</tr>\n";
5562                         }
5563
5564                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5565                 }
5566         } else {
5567                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5568         }
5569
5570         if (defined $extra) {
5571                 print "<tr>\n";
5572                 if ($check_forks) {
5573                         print "<td></td>\n";
5574                 }
5575                 print "<td colspan=\"5\">$extra</td>\n" .
5576                       "</tr>\n";
5577         }
5578         print "</table>\n";
5579 }
5580
5581 sub git_log_body {
5582         # uses global variable $project
5583         my ($commitlist, $from, $to, $refs, $extra) = @_;
5584
5585         $from = 0 unless defined $from;
5586         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5587
5588         for (my $i = 0; $i <= $to; $i++) {
5589                 my %co = %{$commitlist->[$i]};
5590                 next if !%co;
5591                 my $commit = $co{'id'};
5592                 my $ref = format_ref_marker($refs, $commit);
5593                 git_print_header_div('commit',
5594                                "<span class=\"age\">$co{'age_string'}</span>" .
5595                                esc_html($co{'title'}) . $ref,
5596                                $commit);
5597                 print "<div class=\"title_text\">\n" .
5598                       "<div class=\"log_link\">\n" .
5599                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5600                       " | " .
5601                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5602                       " | " .
5603                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5604                       "<br/>\n" .
5605                       "</div>\n";
5606                       git_print_authorship(\%co, -tag => 'span');
5607                       print "<br/>\n</div>\n";
5608
5609                 print "<div class=\"log_body\">\n";
5610                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5611                 print "</div>\n";
5612         }
5613         if ($extra) {
5614                 print "<div class=\"page_nav\">\n";
5615                 print "$extra\n";
5616                 print "</div>\n";
5617         }
5618 }
5619
5620 sub git_shortlog_body {
5621         # uses global variable $project
5622         my ($commitlist, $from, $to, $refs, $extra) = @_;
5623
5624         $from = 0 unless defined $from;
5625         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5626
5627         print "<table class=\"shortlog\">\n";
5628         my $alternate = 1;
5629         for (my $i = $from; $i <= $to; $i++) {
5630                 my %co = %{$commitlist->[$i]};
5631                 my $commit = $co{'id'};
5632                 my $ref = format_ref_marker($refs, $commit);
5633                 if ($alternate) {
5634                         print "<tr class=\"dark\">\n";
5635                 } else {
5636                         print "<tr class=\"light\">\n";
5637                 }
5638                 $alternate ^= 1;
5639                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5640                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5641                       format_author_html('td', \%co, 10) . "<td>";
5642                 print format_subject_html($co{'title'}, $co{'title_short'},
5643                                           href(action=>"commit", hash=>$commit), $ref);
5644                 print "</td>\n" .
5645                       "<td class=\"link\">" .
5646                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5647                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5648                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5649                 my $snapshot_links = format_snapshot_links($commit);
5650                 if (defined $snapshot_links) {
5651                         print " | " . $snapshot_links;
5652                 }
5653                 print "</td>\n" .
5654                       "</tr>\n";
5655         }
5656         if (defined $extra) {
5657                 print "<tr>\n" .
5658                       "<td colspan=\"4\">$extra</td>\n" .
5659                       "</tr>\n";
5660         }
5661         print "</table>\n";
5662 }
5663
5664 sub git_history_body {
5665         # Warning: assumes constant type (blob or tree) during history
5666         my ($commitlist, $from, $to, $refs, $extra,
5667             $file_name, $file_hash, $ftype) = @_;
5668
5669         $from = 0 unless defined $from;
5670         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5671
5672         print "<table class=\"history\">\n";
5673         my $alternate = 1;
5674         for (my $i = $from; $i <= $to; $i++) {
5675                 my %co = %{$commitlist->[$i]};
5676                 if (!%co) {
5677                         next;
5678                 }
5679                 my $commit = $co{'id'};
5680
5681                 my $ref = format_ref_marker($refs, $commit);
5682
5683                 if ($alternate) {
5684                         print "<tr class=\"dark\">\n";
5685                 } else {
5686                         print "<tr class=\"light\">\n";
5687                 }
5688                 $alternate ^= 1;
5689                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5690         # shortlog:   format_author_html('td', \%co, 10)
5691                       format_author_html('td', \%co, 15, 3) . "<td>";
5692                 # originally git_history used chop_str($co{'title'}, 50)
5693                 print format_subject_html($co{'title'}, $co{'title_short'},
5694                                           href(action=>"commit", hash=>$commit), $ref);
5695                 print "</td>\n" .
5696                       "<td class=\"link\">" .
5697                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5698                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5699
5700                 if ($ftype eq 'blob') {
5701                         my $blob_current = $file_hash;
5702                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5703                         if (defined $blob_current && defined $blob_parent &&
5704                                         $blob_current ne $blob_parent) {
5705                                 print " | " .
5706                                         $cgi->a({-href => href(action=>"blobdiff",
5707                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5708                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5709                                                                file_name=>$file_name)},
5710                                                 "diff to current");
5711                         }
5712                 }
5713                 print "</td>\n" .
5714                       "</tr>\n";
5715         }
5716         if (defined $extra) {
5717                 print "<tr>\n" .
5718                       "<td colspan=\"4\">$extra</td>\n" .
5719                       "</tr>\n";
5720         }
5721         print "</table>\n";
5722 }
5723
5724 sub git_tags_body {
5725         # uses global variable $project
5726         my ($taglist, $from, $to, $extra) = @_;
5727         $from = 0 unless defined $from;
5728         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5729
5730         print "<table class=\"tags\">\n";
5731         my $alternate = 1;
5732         for (my $i = $from; $i <= $to; $i++) {
5733                 my $entry = $taglist->[$i];
5734                 my %tag = %$entry;
5735                 my $comment = $tag{'subject'};
5736                 my $comment_short;
5737                 if (defined $comment) {
5738                         $comment_short = chop_str($comment, 30, 5);
5739                 }
5740                 if ($alternate) {
5741                         print "<tr class=\"dark\">\n";
5742                 } else {
5743                         print "<tr class=\"light\">\n";
5744                 }
5745                 $alternate ^= 1;
5746                 if (defined $tag{'age'}) {
5747                         print "<td><i>$tag{'age'}</i></td>\n";
5748                 } else {
5749                         print "<td></td>\n";
5750                 }
5751                 print "<td>" .
5752                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5753                                -class => "list name"}, esc_html($tag{'name'})) .
5754                       "</td>\n" .
5755                       "<td>";
5756                 if (defined $comment) {
5757                         print format_subject_html($comment, $comment_short,
5758                                                   href(action=>"tag", hash=>$tag{'id'}));
5759                 }
5760                 print "</td>\n" .
5761                       "<td class=\"selflink\">";
5762                 if ($tag{'type'} eq "tag") {
5763                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5764                 } else {
5765                         print "&nbsp;";
5766                 }
5767                 print "</td>\n" .
5768                       "<td class=\"link\">" . " | " .
5769                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5770                 if ($tag{'reftype'} eq "commit") {
5771                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5772                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5773                 } elsif ($tag{'reftype'} eq "blob") {
5774                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5775                 }
5776                 print "</td>\n" .
5777                       "</tr>";
5778         }
5779         if (defined $extra) {
5780                 print "<tr>\n" .
5781                       "<td colspan=\"5\">$extra</td>\n" .
5782                       "</tr>\n";
5783         }
5784         print "</table>\n";
5785 }
5786
5787 sub git_heads_body {
5788         # uses global variable $project
5789         my ($headlist, $head_at, $from, $to, $extra) = @_;
5790         $from = 0 unless defined $from;
5791         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5792
5793         print "<table class=\"heads\">\n";
5794         my $alternate = 1;
5795         for (my $i = $from; $i <= $to; $i++) {
5796                 my $entry = $headlist->[$i];
5797                 my %ref = %$entry;
5798                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
5799                 if ($alternate) {
5800                         print "<tr class=\"dark\">\n";
5801                 } else {
5802                         print "<tr class=\"light\">\n";
5803                 }
5804                 $alternate ^= 1;
5805                 print "<td><i>$ref{'age'}</i></td>\n" .
5806                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5807                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5808                                -class => "list name"},esc_html($ref{'name'})) .
5809                       "</td>\n" .
5810                       "<td class=\"link\">" .
5811                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5812                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5813                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5814                       "</td>\n" .
5815                       "</tr>";
5816         }
5817         if (defined $extra) {
5818                 print "<tr>\n" .
5819                       "<td colspan=\"3\">$extra</td>\n" .
5820                       "</tr>\n";
5821         }
5822         print "</table>\n";
5823 }
5824
5825 # Display a single remote block
5826 sub git_remote_block {
5827         my ($remote, $rdata, $limit, $head) = @_;
5828
5829         my $heads = $rdata->{'heads'};
5830         my $fetch = $rdata->{'fetch'};
5831         my $push = $rdata->{'push'};
5832
5833         my $urls_table = "<table class=\"projects_list\">\n" ;
5834
5835         if (defined $fetch) {
5836                 if ($fetch eq $push) {
5837                         $urls_table .= format_repo_url("URL", $fetch);
5838                 } else {
5839                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5840                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5841                 }
5842         } elsif (defined $push) {
5843                 $urls_table .= format_repo_url("Push URL", $push);
5844         } else {
5845                 $urls_table .= format_repo_url("", "No remote URL");
5846         }
5847
5848         $urls_table .= "</table>\n";
5849
5850         my $dots;
5851         if (defined $limit && $limit < @$heads) {
5852                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5853         }
5854
5855         print $urls_table;
5856         git_heads_body($heads, $head, 0, $limit, $dots);
5857 }
5858
5859 # Display a list of remote names with the respective fetch and push URLs
5860 sub git_remotes_list {
5861         my ($remotedata, $limit) = @_;
5862         print "<table class=\"heads\">\n";
5863         my $alternate = 1;
5864         my @remotes = sort keys %$remotedata;
5865
5866         my $limited = $limit && $limit < @remotes;
5867
5868         $#remotes = $limit - 1 if $limited;
5869
5870         while (my $remote = shift @remotes) {
5871                 my $rdata = $remotedata->{$remote};
5872                 my $fetch = $rdata->{'fetch'};
5873                 my $push = $rdata->{'push'};
5874                 if ($alternate) {
5875                         print "<tr class=\"dark\">\n";
5876                 } else {
5877                         print "<tr class=\"light\">\n";
5878                 }
5879                 $alternate ^= 1;
5880                 print "<td>" .
5881                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5882                                -class=> "list name"},esc_html($remote)) .
5883                       "</td>";
5884                 print "<td class=\"link\">" .
5885                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5886                       " | " .
5887                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5888                       "</td>";
5889
5890                 print "</tr>\n";
5891         }
5892
5893         if ($limited) {
5894                 print "<tr>\n" .
5895                       "<td colspan=\"3\">" .
5896                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5897                       "</td>\n" . "</tr>\n";
5898         }
5899
5900         print "</table>";
5901 }
5902
5903 # Display remote heads grouped by remote, unless there are too many
5904 # remotes, in which case we only display the remote names
5905 sub git_remotes_body {
5906         my ($remotedata, $limit, $head) = @_;
5907         if ($limit and $limit < keys %$remotedata) {
5908                 git_remotes_list($remotedata, $limit);
5909         } else {
5910                 fill_remote_heads($remotedata);
5911                 while (my ($remote, $rdata) = each %$remotedata) {
5912                         git_print_section({-class=>"remote", -id=>$remote},
5913                                 ["remotes", $remote, $remote], sub {
5914                                         git_remote_block($remote, $rdata, $limit, $head);
5915                                 });
5916                 }
5917         }
5918 }
5919
5920 sub git_search_message {
5921         my %co = @_;
5922
5923         my $greptype;
5924         if ($searchtype eq 'commit') {
5925                 $greptype = "--grep=";
5926         } elsif ($searchtype eq 'author') {
5927                 $greptype = "--author=";
5928         } elsif ($searchtype eq 'committer') {
5929                 $greptype = "--committer=";
5930         }
5931         $greptype .= $searchtext;
5932         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5933                                        $greptype, '--regexp-ignore-case',
5934                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5935
5936         my $paging_nav = '';
5937         if ($page > 0) {
5938                 $paging_nav .=
5939                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5940                                 "first") .
5941                         " &sdot; " .
5942                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5943                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5944         } else {
5945                 $paging_nav .= "first &sdot; prev";
5946         }
5947         my $next_link = '';
5948         if ($#commitlist >= 100) {
5949                 $next_link =
5950                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5951                                  -accesskey => "n", -title => "Alt-n"}, "next");
5952                 $paging_nav .= " &sdot; $next_link";
5953         } else {
5954                 $paging_nav .= " &sdot; next";
5955         }
5956
5957         git_header_html();
5958
5959         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5960         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5961         if ($page == 0 && !@commitlist) {
5962                 print "<p>No match.</p>\n";
5963         } else {
5964                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5965         }
5966
5967         git_footer_html();
5968 }
5969
5970 sub git_search_changes {
5971         my %co = @_;
5972
5973         local $/ = "\n";
5974         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5975                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5976                 ($search_use_regexp ? '--pickaxe-regex' : ())
5977                         or die_error(500, "Open git-log failed");
5978
5979         git_header_html();
5980
5981         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5982         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5983
5984         print "<table class=\"pickaxe search\">\n";
5985         my $alternate = 1;
5986         undef %co;
5987         my @files;
5988         while (my $line = <$fd>) {
5989                 chomp $line;
5990                 next unless $line;
5991
5992                 my %set = parse_difftree_raw_line($line);
5993                 if (defined $set{'commit'}) {
5994                         # finish previous commit
5995                         if (%co) {
5996                                 print "</td>\n" .
5997                                       "<td class=\"link\">" .
5998                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5999                                               "commit") .
6000                                       " | " .
6001                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6002                                                              hash_base=>$co{'id'})},
6003                                               "tree") .
6004                                       "</td>\n" .
6005                                       "</tr>\n";
6006                         }
6007
6008                         if ($alternate) {
6009                                 print "<tr class=\"dark\">\n";
6010                         } else {
6011                                 print "<tr class=\"light\">\n";
6012                         }
6013                         $alternate ^= 1;
6014                         %co = parse_commit($set{'commit'});
6015                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6016                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6017                               "<td><i>$author</i></td>\n" .
6018                               "<td>" .
6019                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6020                                       -class => "list subject"},
6021                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6022                 } elsif (defined $set{'to_id'}) {
6023                         next if ($set{'to_id'} =~ m/^0{40}$/);
6024
6025                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6026                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6027                                       -class => "list"},
6028                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6029                               "<br/>\n";
6030                 }
6031         }
6032         close $fd;
6033
6034         # finish last commit (warning: repetition!)
6035         if (%co) {
6036                 print "</td>\n" .
6037                       "<td class=\"link\">" .
6038                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6039                               "commit") .
6040                       " | " .
6041                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6042                                              hash_base=>$co{'id'})},
6043                               "tree") .
6044                       "</td>\n" .
6045                       "</tr>\n";
6046         }
6047
6048         print "</table>\n";
6049
6050         git_footer_html();
6051 }
6052
6053 sub git_search_files {
6054         my %co = @_;
6055
6056         local $/ = "\n";
6057         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6058                 $search_use_regexp ? ('-E', '-i') : '-F',
6059                 $searchtext, $co{'tree'}
6060                         or die_error(500, "Open git-grep failed");
6061
6062         git_header_html();
6063
6064         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6065         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6066
6067         print "<table class=\"grep_search\">\n";
6068         my $alternate = 1;
6069         my $matches = 0;
6070         my $lastfile = '';
6071         my $file_href;
6072         while (my $line = <$fd>) {
6073                 chomp $line;
6074                 my ($file, $lno, $ltext, $binary);
6075                 last if ($matches++ > 1000);
6076                 if ($line =~ /^Binary file (.+) matches$/) {
6077                         $file = $1;
6078                         $binary = 1;
6079                 } else {
6080                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6081                         $file =~ s/^$co{'tree'}://;
6082                 }
6083                 if ($file ne $lastfile) {
6084                         $lastfile and print "</td></tr>\n";
6085                         if ($alternate++) {
6086                                 print "<tr class=\"dark\">\n";
6087                         } else {
6088                                 print "<tr class=\"light\">\n";
6089                         }
6090                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6091                                           file_name=>$file);
6092                         print "<td class=\"list\">".
6093                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6094                         print "</td><td>\n";
6095                         $lastfile = $file;
6096                 }
6097                 if ($binary) {
6098                         print "<div class=\"binary\">Binary file</div>\n";
6099                 } else {
6100                         $ltext = untabify($ltext);
6101                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6102                                 $ltext = esc_html($1, -nbsp=>1);
6103                                 $ltext .= '<span class="match">';
6104                                 $ltext .= esc_html($2, -nbsp=>1);
6105                                 $ltext .= '</span>';
6106                                 $ltext .= esc_html($3, -nbsp=>1);
6107                         } else {
6108                                 $ltext = esc_html($ltext, -nbsp=>1);
6109                         }
6110                         print "<div class=\"pre\">" .
6111                                 $cgi->a({-href => $file_href.'#l'.$lno,
6112                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6113                                 ' ' .  $ltext . "</div>\n";
6114                 }
6115         }
6116         if ($lastfile) {
6117                 print "</td></tr>\n";
6118                 if ($matches > 1000) {
6119                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6120                 }
6121         } else {
6122                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6123         }
6124         close $fd;
6125
6126         print "</table>\n";
6127
6128         git_footer_html();
6129 }
6130
6131 sub git_search_grep_body {
6132         my ($commitlist, $from, $to, $extra) = @_;
6133         $from = 0 unless defined $from;
6134         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6135
6136         print "<table class=\"commit_search\">\n";
6137         my $alternate = 1;
6138         for (my $i = $from; $i <= $to; $i++) {
6139                 my %co = %{$commitlist->[$i]};
6140                 if (!%co) {
6141                         next;
6142                 }
6143                 my $commit = $co{'id'};
6144                 if ($alternate) {
6145                         print "<tr class=\"dark\">\n";
6146                 } else {
6147                         print "<tr class=\"light\">\n";
6148                 }
6149                 $alternate ^= 1;
6150                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6151                       format_author_html('td', \%co, 15, 5) .
6152                       "<td>" .
6153                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6154                                -class => "list subject"},
6155                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6156                 my $comment = $co{'comment'};
6157                 foreach my $line (@$comment) {
6158                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6159                                 my ($lead, $match, $trail) = ($1, $2, $3);
6160                                 $match = chop_str($match, 70, 5, 'center');
6161                                 my $contextlen = int((80 - length($match))/2);
6162                                 $contextlen = 30 if ($contextlen > 30);
6163                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6164                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6165
6166                                 $lead  = esc_html($lead);
6167                                 $match = esc_html($match);
6168                                 $trail = esc_html($trail);
6169
6170                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6171                         }
6172                 }
6173                 print "</td>\n" .
6174                       "<td class=\"link\">" .
6175                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6176                       " | " .
6177                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6178                       " | " .
6179                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6180                 print "</td>\n" .
6181                       "</tr>\n";
6182         }
6183         if (defined $extra) {
6184                 print "<tr>\n" .
6185                       "<td colspan=\"3\">$extra</td>\n" .
6186                       "</tr>\n";
6187         }
6188         print "</table>\n";
6189 }
6190
6191 ## ======================================================================
6192 ## ======================================================================
6193 ## actions
6194
6195 sub git_project_list {
6196         my $order = $input_params{'order'};
6197         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6198                 die_error(400, "Unknown order parameter");
6199         }
6200
6201         my @list = git_get_projects_list($project_filter, $strict_export);
6202         if (!@list) {
6203                 die_error(404, "No projects found");
6204         }
6205
6206         git_header_html();
6207         if (defined $home_text && -f $home_text) {
6208                 print "<div class=\"index_include\">\n";
6209                 insert_file($home_text);
6210                 print "</div>\n";
6211         }
6212
6213         git_project_search_form($searchtext, $search_use_regexp);
6214         git_project_list_body(\@list, $order);
6215         git_footer_html();
6216 }
6217
6218 sub git_forks {
6219         my $order = $input_params{'order'};
6220         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6221                 die_error(400, "Unknown order parameter");
6222         }
6223
6224         my $filter = $project;
6225         $filter =~ s/\.git$//;
6226         my @list = git_get_projects_list($filter);
6227         if (!@list) {
6228                 die_error(404, "No forks found");
6229         }
6230
6231         git_header_html();
6232         git_print_page_nav('','');
6233         git_print_header_div('summary', "$project forks");
6234         git_project_list_body(\@list, $order);
6235         git_footer_html();
6236 }
6237
6238 sub git_project_index {
6239         my @projects = git_get_projects_list($project_filter, $strict_export);
6240         if (!@projects) {
6241                 die_error(404, "No projects found");
6242         }
6243
6244         print $cgi->header(
6245                 -type => 'text/plain',
6246                 -charset => 'utf-8',
6247                 -content_disposition => 'inline; filename="index.aux"');
6248
6249         foreach my $pr (@projects) {
6250                 if (!exists $pr->{'owner'}) {
6251                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6252                 }
6253
6254                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6255                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6256                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6257                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6258                 $path  =~ s/ /\+/g;
6259                 $owner =~ s/ /\+/g;
6260
6261                 print "$path $owner\n";
6262         }
6263 }
6264
6265 sub git_summary {
6266         my $descr = git_get_project_description($project) || "none";
6267         my %co = parse_commit("HEAD");
6268         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6269         my $head = $co{'id'};
6270         my $remote_heads = gitweb_check_feature('remote_heads');
6271
6272         my $owner = git_get_project_owner($project);
6273
6274         my $refs = git_get_references();
6275         # These get_*_list functions return one more to allow us to see if
6276         # there are more ...
6277         my @taglist  = git_get_tags_list(16);
6278         my @headlist = git_get_heads_list(16);
6279         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6280         my @forklist;
6281         my $check_forks = gitweb_check_feature('forks');
6282
6283         if ($check_forks) {
6284                 # find forks of a project
6285                 my $filter = $project;
6286                 $filter =~ s/\.git$//;
6287                 @forklist = git_get_projects_list($filter);
6288                 # filter out forks of forks
6289                 @forklist = filter_forks_from_projects_list(\@forklist)
6290                         if (@forklist);
6291         }
6292
6293         git_header_html();
6294         git_print_page_nav('summary','', $head);
6295
6296         print "<div class=\"title\">&nbsp;</div>\n";
6297         print "<table class=\"projects_list\">\n" .
6298               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
6299               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6300         if (defined $cd{'rfc2822'}) {
6301                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6302                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6303         }
6304
6305         # use per project git URL list in $projectroot/$project/cloneurl
6306         # or make project git URL from git base URL and project name
6307         my $url_tag = "URL";
6308         my @url_list = git_get_project_url_list($project);
6309         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6310         foreach my $git_url (@url_list) {
6311                 next unless $git_url;
6312                 print format_repo_url($url_tag, $git_url);
6313                 $url_tag = "";
6314         }
6315
6316         # Tag cloud
6317         my $show_ctags = gitweb_check_feature('ctags');
6318         if ($show_ctags) {
6319                 my $ctags = git_get_project_ctags($project);
6320                 if (%$ctags) {
6321                         # without ability to add tags, don't show if there are none
6322                         my $cloud = git_populate_project_tagcloud($ctags);
6323                         print "<tr id=\"metadata_ctags\">" .
6324                               "<td>content tags</td>" .
6325                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6326                               "</tr>\n";
6327                 }
6328         }
6329
6330         print "</table>\n";
6331
6332         # If XSS prevention is on, we don't include README.html.
6333         # TODO: Allow a readme in some safe format.
6334         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6335                 print "<div class=\"title\">readme</div>\n" .
6336                       "<div class=\"readme\">\n";
6337                 insert_file("$projectroot/$project/README.html");
6338                 print "\n</div>\n"; # class="readme"
6339         }
6340
6341         # we need to request one more than 16 (0..15) to check if
6342         # those 16 are all
6343         my @commitlist = $head ? parse_commits($head, 17) : ();
6344         if (@commitlist) {
6345                 git_print_header_div('shortlog');
6346                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6347                                   $#commitlist <=  15 ? undef :
6348                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6349         }
6350
6351         if (@taglist) {
6352                 git_print_header_div('tags');
6353                 git_tags_body(\@taglist, 0, 15,
6354                               $#taglist <=  15 ? undef :
6355                               $cgi->a({-href => href(action=>"tags")}, "..."));
6356         }
6357
6358         if (@headlist) {
6359                 git_print_header_div('heads');
6360                 git_heads_body(\@headlist, $head, 0, 15,
6361                                $#headlist <= 15 ? undef :
6362                                $cgi->a({-href => href(action=>"heads")}, "..."));
6363         }
6364
6365         if (%remotedata) {
6366                 git_print_header_div('remotes');
6367                 git_remotes_body(\%remotedata, 15, $head);
6368         }
6369
6370         if (@forklist) {
6371                 git_print_header_div('forks');
6372                 git_project_list_body(\@forklist, 'age', 0, 15,
6373                                       $#forklist <= 15 ? undef :
6374                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6375                                       'no_header');
6376         }
6377
6378         git_footer_html();
6379 }
6380
6381 sub git_tag {
6382         my %tag = parse_tag($hash);
6383
6384         if (! %tag) {
6385                 die_error(404, "Unknown tag object");
6386         }
6387
6388         my $head = git_get_head_hash($project);
6389         git_header_html();
6390         git_print_page_nav('','', $head,undef,$head);
6391         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6392         print "<div class=\"title_text\">\n" .
6393               "<table class=\"object_header\">\n" .
6394               "<tr>\n" .
6395               "<td>object</td>\n" .
6396               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6397                                $tag{'object'}) . "</td>\n" .
6398               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6399                                               $tag{'type'}) . "</td>\n" .
6400               "</tr>\n";
6401         if (defined($tag{'author'})) {
6402                 git_print_authorship_rows(\%tag, 'author');
6403         }
6404         print "</table>\n\n" .
6405               "</div>\n";
6406         print "<div class=\"page_body\">";
6407         my $comment = $tag{'comment'};
6408         foreach my $line (@$comment) {
6409                 chomp $line;
6410                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6411         }
6412         print "</div>\n";
6413         git_footer_html();
6414 }
6415
6416 sub git_blame_common {
6417         my $format = shift || 'porcelain';
6418         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6419                 $format = 'incremental';
6420                 $action = 'blame_incremental'; # for page title etc
6421         }
6422
6423         # permissions
6424         gitweb_check_feature('blame')
6425                 or die_error(403, "Blame view not allowed");
6426
6427         # error checking
6428         die_error(400, "No file name given") unless $file_name;
6429         $hash_base ||= git_get_head_hash($project);
6430         die_error(404, "Couldn't find base commit") unless $hash_base;
6431         my %co = parse_commit($hash_base)
6432                 or die_error(404, "Commit not found");
6433         my $ftype = "blob";
6434         if (!defined $hash) {
6435                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6436                         or die_error(404, "Error looking up file");
6437         } else {
6438                 $ftype = git_get_type($hash);
6439                 if ($ftype !~ "blob") {
6440                         die_error(400, "Object is not a blob");
6441                 }
6442         }
6443
6444         my $fd;
6445         if ($format eq 'incremental') {
6446                 # get file contents (as base)
6447                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6448                         or die_error(500, "Open git-cat-file failed");
6449         } elsif ($format eq 'data') {
6450                 # run git-blame --incremental
6451                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6452                         $hash_base, "--", $file_name
6453                         or die_error(500, "Open git-blame --incremental failed");
6454         } else {
6455                 # run git-blame --porcelain
6456                 open $fd, "-|", git_cmd(), "blame", '-p',
6457                         $hash_base, '--', $file_name
6458                         or die_error(500, "Open git-blame --porcelain failed");
6459         }
6460
6461         # incremental blame data returns early
6462         if ($format eq 'data') {
6463                 print $cgi->header(
6464                         -type=>"text/plain", -charset => "utf-8",
6465                         -status=> "200 OK");
6466                 local $| = 1; # output autoflush
6467                 while (my $line = <$fd>) {
6468                         print to_utf8($line);
6469                 }
6470                 close $fd
6471                         or print "ERROR $!\n";
6472
6473                 print 'END';
6474                 if (defined $t0 && gitweb_check_feature('timed')) {
6475                         print ' '.
6476                               tv_interval($t0, [ gettimeofday() ]).
6477                               ' '.$number_of_git_cmds;
6478                 }
6479                 print "\n";
6480
6481                 return;
6482         }
6483
6484         # page header
6485         git_header_html();
6486         my $formats_nav =
6487                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6488                         "blob") .
6489                 " | ";
6490         if ($format eq 'incremental') {
6491                 $formats_nav .=
6492                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6493                                 "blame") . " (non-incremental)";
6494         } else {
6495                 $formats_nav .=
6496                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6497                                 "blame") . " (incremental)";
6498         }
6499         $formats_nav .=
6500                 " | " .
6501                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6502                         "history") .
6503                 " | " .
6504                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6505                         "HEAD");
6506         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6507         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6508         git_print_page_path($file_name, $ftype, $hash_base);
6509
6510         # page body
6511         if ($format eq 'incremental') {
6512                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6513                       "This page requires JavaScript to run.\n Use ".
6514                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6515                               'this page').
6516                       " instead.\n".
6517                       "</b></center></div>\n</noscript>\n";
6518
6519                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6520         }
6521
6522         print qq!<div class="page_body">\n!;
6523         print qq!<div id="progress_info">... / ...</div>\n!
6524                 if ($format eq 'incremental');
6525         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6526               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6527               qq!<thead>\n!.
6528               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6529               qq!</thead>\n!.
6530               qq!<tbody>\n!;
6531
6532         my @rev_color = qw(light dark);
6533         my $num_colors = scalar(@rev_color);
6534         my $current_color = 0;
6535
6536         if ($format eq 'incremental') {
6537                 my $color_class = $rev_color[$current_color];
6538
6539                 #contents of a file
6540                 my $linenr = 0;
6541         LINE:
6542                 while (my $line = <$fd>) {
6543                         chomp $line;
6544                         $linenr++;
6545
6546                         print qq!<tr id="l$linenr" class="$color_class">!.
6547                               qq!<td class="sha1"><a href=""> </a></td>!.
6548                               qq!<td class="linenr">!.
6549                               qq!<a class="linenr" href="">$linenr</a></td>!;
6550                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6551                         print qq!</tr>\n!;
6552                 }
6553
6554         } else { # porcelain, i.e. ordinary blame
6555                 my %metainfo = (); # saves information about commits
6556
6557                 # blame data
6558         LINE:
6559                 while (my $line = <$fd>) {
6560                         chomp $line;
6561                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6562                         # no <lines in group> for subsequent lines in group of lines
6563                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6564                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6565                         if (!exists $metainfo{$full_rev}) {
6566                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6567                         }
6568                         my $meta = $metainfo{$full_rev};
6569                         my $data;
6570                         while ($data = <$fd>) {
6571                                 chomp $data;
6572                                 last if ($data =~ s/^\t//); # contents of line
6573                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6574                                         $meta->{$1} = $2 unless exists $meta->{$1};
6575                                 }
6576                                 if ($data =~ /^previous /) {
6577                                         $meta->{'nprevious'}++;
6578                                 }
6579                         }
6580                         my $short_rev = substr($full_rev, 0, 8);
6581                         my $author = $meta->{'author'};
6582                         my %date =
6583                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6584                         my $date = $date{'iso-tz'};
6585                         if ($group_size) {
6586                                 $current_color = ($current_color + 1) % $num_colors;
6587                         }
6588                         my $tr_class = $rev_color[$current_color];
6589                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6590                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6591                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6592                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6593                         if ($group_size) {
6594                                 print "<td class=\"sha1\"";
6595                                 print " title=\"". esc_html($author) . ", $date\"";
6596                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6597                                 print ">";
6598                                 print $cgi->a({-href => href(action=>"commit",
6599                                                              hash=>$full_rev,
6600                                                              file_name=>$file_name)},
6601                                               esc_html($short_rev));
6602                                 if ($group_size >= 2) {
6603                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6604                                         if (@author_initials) {
6605                                                 print "<br />" .
6606                                                       esc_html(join('', @author_initials));
6607                                                 #           or join('.', ...)
6608                                         }
6609                                 }
6610                                 print "</td>\n";
6611                         }
6612                         # 'previous' <sha1 of parent commit> <filename at commit>
6613                         if (exists $meta->{'previous'} &&
6614                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6615                                 $meta->{'parent'} = $1;
6616                                 $meta->{'file_parent'} = unquote($2);
6617                         }
6618                         my $linenr_commit =
6619                                 exists($meta->{'parent'}) ?
6620                                 $meta->{'parent'} : $full_rev;
6621                         my $linenr_filename =
6622                                 exists($meta->{'file_parent'}) ?
6623                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6624                         my $blamed = href(action => 'blame',
6625                                           file_name => $linenr_filename,
6626                                           hash_base => $linenr_commit);
6627                         print "<td class=\"linenr\">";
6628                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6629                                         -class => "linenr" },
6630                                       esc_html($lineno));
6631                         print "</td>";
6632                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6633                         print "</tr>\n";
6634                 } # end while
6635
6636         }
6637
6638         # footer
6639         print "</tbody>\n".
6640               "</table>\n"; # class="blame"
6641         print "</div>\n";   # class="blame_body"
6642         close $fd
6643                 or print "Reading blob failed\n";
6644
6645         git_footer_html();
6646 }
6647
6648 sub git_blame {
6649         git_blame_common();
6650 }
6651
6652 sub git_blame_incremental {
6653         git_blame_common('incremental');
6654 }
6655
6656 sub git_blame_data {
6657         git_blame_common('data');
6658 }
6659
6660 sub git_tags {
6661         my $head = git_get_head_hash($project);
6662         git_header_html();
6663         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6664         git_print_header_div('summary', $project);
6665
6666         my @tagslist = git_get_tags_list();
6667         if (@tagslist) {
6668                 git_tags_body(\@tagslist);
6669         }
6670         git_footer_html();
6671 }
6672
6673 sub git_heads {
6674         my $head = git_get_head_hash($project);
6675         git_header_html();
6676         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6677         git_print_header_div('summary', $project);
6678
6679         my @headslist = git_get_heads_list();
6680         if (@headslist) {
6681                 git_heads_body(\@headslist, $head);
6682         }
6683         git_footer_html();
6684 }
6685
6686 # used both for single remote view and for list of all the remotes
6687 sub git_remotes {
6688         gitweb_check_feature('remote_heads')
6689                 or die_error(403, "Remote heads view is disabled");
6690
6691         my $head = git_get_head_hash($project);
6692         my $remote = $input_params{'hash'};
6693
6694         my $remotedata = git_get_remotes_list($remote);
6695         die_error(500, "Unable to get remote information") unless defined $remotedata;
6696
6697         unless (%$remotedata) {
6698                 die_error(404, defined $remote ?
6699                         "Remote $remote not found" :
6700                         "No remotes found");
6701         }
6702
6703         git_header_html(undef, undef, -action_extra => $remote);
6704         git_print_page_nav('', '',  $head, undef, $head,
6705                 format_ref_views($remote ? '' : 'remotes'));
6706
6707         fill_remote_heads($remotedata);
6708         if (defined $remote) {
6709                 git_print_header_div('remotes', "$remote remote for $project");
6710                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6711         } else {
6712                 git_print_header_div('summary', "$project remotes");
6713                 git_remotes_body($remotedata, undef, $head);
6714         }
6715
6716         git_footer_html();
6717 }
6718
6719 sub git_blob_plain {
6720         my $type = shift;
6721         my $expires;
6722
6723         if (!defined $hash) {
6724                 if (defined $file_name) {
6725                         my $base = $hash_base || git_get_head_hash($project);
6726                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6727                                 or die_error(404, "Cannot find file");
6728                 } else {
6729                         die_error(400, "No file name defined");
6730                 }
6731         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6732                 # blobs defined by non-textual hash id's can be cached
6733                 $expires = "+1d";
6734         }
6735
6736         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6737                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6738
6739         # content-type (can include charset)
6740         $type = blob_contenttype($fd, $file_name, $type);
6741
6742         # "save as" filename, even when no $file_name is given
6743         my $save_as = "$hash";
6744         if (defined $file_name) {
6745                 $save_as = $file_name;
6746         } elsif ($type =~ m/^text\//) {
6747                 $save_as .= '.txt';
6748         }
6749
6750         # With XSS prevention on, blobs of all types except a few known safe
6751         # ones are served with "Content-Disposition: attachment" to make sure
6752         # they don't run in our security domain.  For certain image types,
6753         # blob view writes an <img> tag referring to blob_plain view, and we
6754         # want to be sure not to break that by serving the image as an
6755         # attachment (though Firefox 3 doesn't seem to care).
6756         my $sandbox = $prevent_xss &&
6757                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6758
6759         # serve text/* as text/plain
6760         if ($prevent_xss &&
6761             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6762              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6763                 my $rest = $1;
6764                 $rest = defined $rest ? $rest : '';
6765                 $type = "text/plain$rest";
6766         }
6767
6768         print $cgi->header(
6769                 -type => $type,
6770                 -expires => $expires,
6771                 -content_disposition =>
6772                         ($sandbox ? 'attachment' : 'inline')
6773                         . '; filename="' . $save_as . '"');
6774         local $/ = undef;
6775         binmode STDOUT, ':raw';
6776         print <$fd>;
6777         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6778         close $fd;
6779 }
6780
6781 sub git_blob {
6782         my $expires;
6783
6784         if (!defined $hash) {
6785                 if (defined $file_name) {
6786                         my $base = $hash_base || git_get_head_hash($project);
6787                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6788                                 or die_error(404, "Cannot find file");
6789                 } else {
6790                         die_error(400, "No file name defined");
6791                 }
6792         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6793                 # blobs defined by non-textual hash id's can be cached
6794                 $expires = "+1d";
6795         }
6796
6797         my $have_blame = gitweb_check_feature('blame');
6798         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6799                 or die_error(500, "Couldn't cat $file_name, $hash");
6800         my $mimetype = blob_mimetype($fd, $file_name);
6801         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6802         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6803                 close $fd;
6804                 return git_blob_plain($mimetype);
6805         }
6806         # we can have blame only for text/* mimetype
6807         $have_blame &&= ($mimetype =~ m!^text/!);
6808
6809         my $highlight = gitweb_check_feature('highlight');
6810         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6811         $fd = run_highlighter($fd, $highlight, $syntax)
6812                 if $syntax;
6813
6814         git_header_html(undef, $expires);
6815         my $formats_nav = '';
6816         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6817                 if (defined $file_name) {
6818                         if ($have_blame) {
6819                                 $formats_nav .=
6820                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6821                                                 "blame") .
6822                                         " | ";
6823                         }
6824                         $formats_nav .=
6825                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6826                                         "history") .
6827                                 " | " .
6828                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6829                                         "raw") .
6830                                 " | " .
6831                                 $cgi->a({-href => href(action=>"blob",
6832                                                        hash_base=>"HEAD", file_name=>$file_name)},
6833                                         "HEAD");
6834                 } else {
6835                         $formats_nav .=
6836                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6837                                         "raw");
6838                 }
6839                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6840                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6841         } else {
6842                 print "<div class=\"page_nav\">\n" .
6843                       "<br/><br/></div>\n" .
6844                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6845         }
6846         git_print_page_path($file_name, "blob", $hash_base);
6847         print "<div class=\"page_body\">\n";
6848         if ($mimetype =~ m!^image/!) {
6849                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6850                 if ($file_name) {
6851                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6852                 }
6853                 print qq! src="! .
6854                       href(action=>"blob_plain", hash=>$hash,
6855                            hash_base=>$hash_base, file_name=>$file_name) .
6856                       qq!" />\n!;
6857         } else {
6858                 my $nr;
6859                 while (my $line = <$fd>) {
6860                         chomp $line;
6861                         $nr++;
6862                         $line = untabify($line);
6863                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6864                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6865                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6866                 }
6867         }
6868         close $fd
6869                 or print "Reading blob failed.\n";
6870         print "</div>";
6871         git_footer_html();
6872 }
6873
6874 sub git_tree {
6875         if (!defined $hash_base) {
6876                 $hash_base = "HEAD";
6877         }
6878         if (!defined $hash) {
6879                 if (defined $file_name) {
6880                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6881                 } else {
6882                         $hash = $hash_base;
6883                 }
6884         }
6885         die_error(404, "No such tree") unless defined($hash);
6886
6887         my $show_sizes = gitweb_check_feature('show-sizes');
6888         my $have_blame = gitweb_check_feature('blame');
6889
6890         my @entries = ();
6891         {
6892                 local $/ = "\0";
6893                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6894                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6895                         or die_error(500, "Open git-ls-tree failed");
6896                 @entries = map { chomp; $_ } <$fd>;
6897                 close $fd
6898                         or die_error(404, "Reading tree failed");
6899         }
6900
6901         my $refs = git_get_references();
6902         my $ref = format_ref_marker($refs, $hash_base);
6903         git_header_html();
6904         my $basedir = '';
6905         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6906                 my @views_nav = ();
6907                 if (defined $file_name) {
6908                         push @views_nav,
6909                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6910                                         "history"),
6911                                 $cgi->a({-href => href(action=>"tree",
6912                                                        hash_base=>"HEAD", file_name=>$file_name)},
6913                                         "HEAD"),
6914                 }
6915                 my $snapshot_links = format_snapshot_links($hash);
6916                 if (defined $snapshot_links) {
6917                         # FIXME: Should be available when we have no hash base as well.
6918                         push @views_nav, $snapshot_links;
6919                 }
6920                 git_print_page_nav('tree','', $hash_base, undef, undef,
6921                                    join(' | ', @views_nav));
6922                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6923         } else {
6924                 undef $hash_base;
6925                 print "<div class=\"page_nav\">\n";
6926                 print "<br/><br/></div>\n";
6927                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6928         }
6929         if (defined $file_name) {
6930                 $basedir = $file_name;
6931                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6932                         $basedir .= '/';
6933                 }
6934                 git_print_page_path($file_name, 'tree', $hash_base);
6935         }
6936         print "<div class=\"page_body\">\n";
6937         print "<table class=\"tree\">\n";
6938         my $alternate = 1;
6939         # '..' (top directory) link if possible
6940         if (defined $hash_base &&
6941             defined $file_name && $file_name =~ m![^/]+$!) {
6942                 if ($alternate) {
6943                         print "<tr class=\"dark\">\n";
6944                 } else {
6945                         print "<tr class=\"light\">\n";
6946                 }
6947                 $alternate ^= 1;
6948
6949                 my $up = $file_name;
6950                 $up =~ s!/?[^/]+$!!;
6951                 undef $up unless $up;
6952                 # based on git_print_tree_entry
6953                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6954                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6955                 print '<td class="list">';
6956                 print $cgi->a({-href => href(action=>"tree",
6957                                              hash_base=>$hash_base,
6958                                              file_name=>$up)},
6959                               "..");
6960                 print "</td>\n";
6961                 print "<td class=\"link\"></td>\n";
6962
6963                 print "</tr>\n";
6964         }
6965         foreach my $line (@entries) {
6966                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6967
6968                 if ($alternate) {
6969                         print "<tr class=\"dark\">\n";
6970                 } else {
6971                         print "<tr class=\"light\">\n";
6972                 }
6973                 $alternate ^= 1;
6974
6975                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6976
6977                 print "</tr>\n";
6978         }
6979         print "</table>\n" .
6980               "</div>";
6981         git_footer_html();
6982 }
6983
6984 sub snapshot_name {
6985         my ($project, $hash) = @_;
6986
6987         # path/to/project.git  -> project
6988         # path/to/project/.git -> project
6989         my $name = to_utf8($project);
6990         $name =~ s,([^/])/*\.git$,$1,;
6991         $name = basename($name);
6992         # sanitize name
6993         $name =~ s/[[:cntrl:]]/?/g;
6994
6995         my $ver = $hash;
6996         if ($hash =~ /^[0-9a-fA-F]+$/) {
6997                 # shorten SHA-1 hash
6998                 my $full_hash = git_get_full_hash($project, $hash);
6999                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7000                         $ver = git_get_short_hash($project, $hash);
7001                 }
7002         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7003                 # tags don't need shortened SHA-1 hash
7004                 $ver = $1;
7005         } else {
7006                 # branches and other need shortened SHA-1 hash
7007                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
7008                         $ver = $1;
7009                 }
7010                 $ver .= '-' . git_get_short_hash($project, $hash);
7011         }
7012         # in case of hierarchical branch names
7013         $ver =~ s!/!.!g;
7014
7015         # name = project-version_string
7016         $name = "$name-$ver";
7017
7018         return wantarray ? ($name, $name) : $name;
7019 }
7020
7021 sub git_snapshot {
7022         my $format = $input_params{'snapshot_format'};
7023         if (!@snapshot_fmts) {
7024                 die_error(403, "Snapshots not allowed");
7025         }
7026         # default to first supported snapshot format
7027         $format ||= $snapshot_fmts[0];
7028         if ($format !~ m/^[a-z0-9]+$/) {
7029                 die_error(400, "Invalid snapshot format parameter");
7030         } elsif (!exists($known_snapshot_formats{$format})) {
7031                 die_error(400, "Unknown snapshot format");
7032         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7033                 die_error(403, "Snapshot format not allowed");
7034         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7035                 die_error(403, "Unsupported snapshot format");
7036         }
7037
7038         my $type = git_get_type("$hash^{}");
7039         if (!$type) {
7040                 die_error(404, 'Object does not exist');
7041         }  elsif ($type eq 'blob') {
7042                 die_error(400, 'Object is not a tree-ish');
7043         }
7044
7045         my ($name, $prefix) = snapshot_name($project, $hash);
7046         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7047         my $cmd = quote_command(
7048                 git_cmd(), 'archive',
7049                 "--format=$known_snapshot_formats{$format}{'format'}",
7050                 "--prefix=$prefix/", $hash);
7051         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7052                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7053         }
7054
7055         $filename =~ s/(["\\])/\\$1/g;
7056         print $cgi->header(
7057                 -type => $known_snapshot_formats{$format}{'type'},
7058                 -content_disposition => 'inline; filename="' . $filename . '"',
7059                 -status => '200 OK');
7060
7061         open my $fd, "-|", $cmd
7062                 or die_error(500, "Execute git-archive failed");
7063         binmode STDOUT, ':raw';
7064         print <$fd>;
7065         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7066         close $fd;
7067 }
7068
7069 sub git_log_generic {
7070         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7071
7072         my $head = git_get_head_hash($project);
7073         if (!defined $base) {
7074                 $base = $head;
7075         }
7076         if (!defined $page) {
7077                 $page = 0;
7078         }
7079         my $refs = git_get_references();
7080
7081         my $commit_hash = $base;
7082         if (defined $parent) {
7083                 $commit_hash = "$parent..$base";
7084         }
7085         my @commitlist =
7086                 parse_commits($commit_hash, 101, (100 * $page),
7087                               defined $file_name ? ($file_name, "--full-history") : ());
7088
7089         my $ftype;
7090         if (!defined $file_hash && defined $file_name) {
7091                 # some commits could have deleted file in question,
7092                 # and not have it in tree, but one of them has to have it
7093                 for (my $i = 0; $i < @commitlist; $i++) {
7094                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7095                         last if defined $file_hash;
7096                 }
7097         }
7098         if (defined $file_hash) {
7099                 $ftype = git_get_type($file_hash);
7100         }
7101         if (defined $file_name && !defined $ftype) {
7102                 die_error(500, "Unknown type of object");
7103         }
7104         my %co;
7105         if (defined $file_name) {
7106                 %co = parse_commit($base)
7107                         or die_error(404, "Unknown commit object");
7108         }
7109
7110
7111         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7112         my $next_link = '';
7113         if ($#commitlist >= 100) {
7114                 $next_link =
7115                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7116                                  -accesskey => "n", -title => "Alt-n"}, "next");
7117         }
7118         my $patch_max = gitweb_get_feature('patches');
7119         if ($patch_max && !defined $file_name) {
7120                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7121                         $paging_nav .= " &sdot; " .
7122                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7123                                         "patches");
7124                 }
7125         }
7126
7127         git_header_html();
7128         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7129         if (defined $file_name) {
7130                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7131         } else {
7132                 git_print_header_div('summary', $project)
7133         }
7134         git_print_page_path($file_name, $ftype, $hash_base)
7135                 if (defined $file_name);
7136
7137         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7138                      $file_name, $file_hash, $ftype);
7139
7140         git_footer_html();
7141 }
7142
7143 sub git_log {
7144         git_log_generic('log', \&git_log_body,
7145                         $hash, $hash_parent);
7146 }
7147
7148 sub git_commit {
7149         $hash ||= $hash_base || "HEAD";
7150         my %co = parse_commit($hash)
7151             or die_error(404, "Unknown commit object");
7152
7153         my $parent  = $co{'parent'};
7154         my $parents = $co{'parents'}; # listref
7155
7156         # we need to prepare $formats_nav before any parameter munging
7157         my $formats_nav;
7158         if (!defined $parent) {
7159                 # --root commitdiff
7160                 $formats_nav .= '(initial)';
7161         } elsif (@$parents == 1) {
7162                 # single parent commit
7163                 $formats_nav .=
7164                         '(parent: ' .
7165                         $cgi->a({-href => href(action=>"commit",
7166                                                hash=>$parent)},
7167                                 esc_html(substr($parent, 0, 7))) .
7168                         ')';
7169         } else {
7170                 # merge commit
7171                 $formats_nav .=
7172                         '(merge: ' .
7173                         join(' ', map {
7174                                 $cgi->a({-href => href(action=>"commit",
7175                                                        hash=>$_)},
7176                                         esc_html(substr($_, 0, 7)));
7177                         } @$parents ) .
7178                         ')';
7179         }
7180         if (gitweb_check_feature('patches') && @$parents <= 1) {
7181                 $formats_nav .= " | " .
7182                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7183                                 "patch");
7184         }
7185
7186         if (!defined $parent) {
7187                 $parent = "--root";
7188         }
7189         my @difftree;
7190         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7191                 @diff_opts,
7192                 (@$parents <= 1 ? $parent : '-c'),
7193                 $hash, "--"
7194                 or die_error(500, "Open git-diff-tree failed");
7195         @difftree = map { chomp; $_ } <$fd>;
7196         close $fd or die_error(404, "Reading git-diff-tree failed");
7197
7198         # non-textual hash id's can be cached
7199         my $expires;
7200         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7201                 $expires = "+1d";
7202         }
7203         my $refs = git_get_references();
7204         my $ref = format_ref_marker($refs, $co{'id'});
7205
7206         git_header_html(undef, $expires);
7207         git_print_page_nav('commit', '',
7208                            $hash, $co{'tree'}, $hash,
7209                            $formats_nav);
7210
7211         if (defined $co{'parent'}) {
7212                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7213         } else {
7214                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7215         }
7216         print "<div class=\"title_text\">\n" .
7217               "<table class=\"object_header\">\n";
7218         git_print_authorship_rows(\%co);
7219         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7220         print "<tr>" .
7221               "<td>tree</td>" .
7222               "<td class=\"sha1\">" .
7223               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7224                        class => "list"}, $co{'tree'}) .
7225               "</td>" .
7226               "<td class=\"link\">" .
7227               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7228                       "tree");
7229         my $snapshot_links = format_snapshot_links($hash);
7230         if (defined $snapshot_links) {
7231                 print " | " . $snapshot_links;
7232         }
7233         print "</td>" .
7234               "</tr>\n";
7235
7236         foreach my $par (@$parents) {
7237                 print "<tr>" .
7238                       "<td>parent</td>" .
7239                       "<td class=\"sha1\">" .
7240                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7241                                class => "list"}, $par) .
7242                       "</td>" .
7243                       "<td class=\"link\">" .
7244                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7245                       " | " .
7246                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7247                       "</td>" .
7248                       "</tr>\n";
7249         }
7250         print "</table>".
7251               "</div>\n";
7252
7253         print "<div class=\"page_body\">\n";
7254         git_print_log($co{'comment'});
7255         print "</div>\n";
7256
7257         git_difftree_body(\@difftree, $hash, @$parents);
7258
7259         git_footer_html();
7260 }
7261
7262 sub git_object {
7263         # object is defined by:
7264         # - hash or hash_base alone
7265         # - hash_base and file_name
7266         my $type;
7267
7268         # - hash or hash_base alone
7269         if ($hash || ($hash_base && !defined $file_name)) {
7270                 my $object_id = $hash || $hash_base;
7271
7272                 open my $fd, "-|", quote_command(
7273                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7274                         or die_error(404, "Object does not exist");
7275                 $type = <$fd>;
7276                 chomp $type;
7277                 close $fd
7278                         or die_error(404, "Object does not exist");
7279
7280         # - hash_base and file_name
7281         } elsif ($hash_base && defined $file_name) {
7282                 $file_name =~ s,/+$,,;
7283
7284                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7285                         or die_error(404, "Base object does not exist");
7286
7287                 # here errors should not hapen
7288                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7289                         or die_error(500, "Open git-ls-tree failed");
7290                 my $line = <$fd>;
7291                 close $fd;
7292
7293                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7294                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7295                         die_error(404, "File or directory for given base does not exist");
7296                 }
7297                 $type = $2;
7298                 $hash = $3;
7299         } else {
7300                 die_error(400, "Not enough information to find object");
7301         }
7302
7303         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7304                                           hash=>$hash, hash_base=>$hash_base,
7305                                           file_name=>$file_name),
7306                              -status => '302 Found');
7307 }
7308
7309 sub git_blobdiff {
7310         my $format = shift || 'html';
7311         my $diff_style = $input_params{'diff_style'} || 'inline';
7312
7313         my $fd;
7314         my @difftree;
7315         my %diffinfo;
7316         my $expires;
7317
7318         # preparing $fd and %diffinfo for git_patchset_body
7319         # new style URI
7320         if (defined $hash_base && defined $hash_parent_base) {
7321                 if (defined $file_name) {
7322                         # read raw output
7323                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7324                                 $hash_parent_base, $hash_base,
7325                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7326                                 or die_error(500, "Open git-diff-tree failed");
7327                         @difftree = map { chomp; $_ } <$fd>;
7328                         close $fd
7329                                 or die_error(404, "Reading git-diff-tree failed");
7330                         @difftree
7331                                 or die_error(404, "Blob diff not found");
7332
7333                 } elsif (defined $hash &&
7334                          $hash =~ /[0-9a-fA-F]{40}/) {
7335                         # try to find filename from $hash
7336
7337                         # read filtered raw output
7338                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7339                                 $hash_parent_base, $hash_base, "--"
7340                                 or die_error(500, "Open git-diff-tree failed");
7341                         @difftree =
7342                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7343                                 # $hash == to_id
7344                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7345                                 map { chomp; $_ } <$fd>;
7346                         close $fd
7347                                 or die_error(404, "Reading git-diff-tree failed");
7348                         @difftree
7349                                 or die_error(404, "Blob diff not found");
7350
7351                 } else {
7352                         die_error(400, "Missing one of the blob diff parameters");
7353                 }
7354
7355                 if (@difftree > 1) {
7356                         die_error(400, "Ambiguous blob diff specification");
7357                 }
7358
7359                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7360                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7361                 $file_name   ||= $diffinfo{'to_file'};
7362
7363                 $hash_parent ||= $diffinfo{'from_id'};
7364                 $hash        ||= $diffinfo{'to_id'};
7365
7366                 # non-textual hash id's can be cached
7367                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7368                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7369                         $expires = '+1d';
7370                 }
7371
7372                 # open patch output
7373                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7374                         '-p', ($format eq 'html' ? "--full-index" : ()),
7375                         $hash_parent_base, $hash_base,
7376                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7377                         or die_error(500, "Open git-diff-tree failed");
7378         }
7379
7380         # old/legacy style URI -- not generated anymore since 1.4.3.
7381         if (!%diffinfo) {
7382                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7383         }
7384
7385         # header
7386         if ($format eq 'html') {
7387                 my $formats_nav =
7388                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7389                                 "raw");
7390                 $formats_nav .= diff_style_nav($diff_style);
7391                 git_header_html(undef, $expires);
7392                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7393                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7394                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7395                 } else {
7396                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7397                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7398                 }
7399                 if (defined $file_name) {
7400                         git_print_page_path($file_name, "blob", $hash_base);
7401                 } else {
7402                         print "<div class=\"page_path\"></div>\n";
7403                 }
7404
7405         } elsif ($format eq 'plain') {
7406                 print $cgi->header(
7407                         -type => 'text/plain',
7408                         -charset => 'utf-8',
7409                         -expires => $expires,
7410                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7411
7412                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7413
7414         } else {
7415                 die_error(400, "Unknown blobdiff format");
7416         }
7417
7418         # patch
7419         if ($format eq 'html') {
7420                 print "<div class=\"page_body\">\n";
7421
7422                 git_patchset_body($fd, $diff_style,
7423                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7424                 close $fd;
7425
7426                 print "</div>\n"; # class="page_body"
7427                 git_footer_html();
7428
7429         } else {
7430                 while (my $line = <$fd>) {
7431                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7432                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7433
7434                         print $line;
7435
7436                         last if $line =~ m!^\+\+\+!;
7437                 }
7438                 local $/ = undef;
7439                 print <$fd>;
7440                 close $fd;
7441         }
7442 }
7443
7444 sub git_blobdiff_plain {
7445         git_blobdiff('plain');
7446 }
7447
7448 # assumes that it is added as later part of already existing navigation,
7449 # so it returns "| foo | bar" rather than just "foo | bar"
7450 sub diff_style_nav {
7451         my ($diff_style, $is_combined) = @_;
7452         $diff_style ||= 'inline';
7453
7454         return "" if ($is_combined);
7455
7456         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7457         my %styles = @styles;
7458         @styles =
7459                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7460
7461         return join '',
7462                 map { " | ".$_ }
7463                 map {
7464                         $_ eq $diff_style ? $styles{$_} :
7465                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7466                 } @styles;
7467 }
7468
7469 sub git_commitdiff {
7470         my %params = @_;
7471         my $format = $params{-format} || 'html';
7472         my $diff_style = $input_params{'diff_style'} || 'inline';
7473
7474         my ($patch_max) = gitweb_get_feature('patches');
7475         if ($format eq 'patch') {
7476                 die_error(403, "Patch view not allowed") unless $patch_max;
7477         }
7478
7479         $hash ||= $hash_base || "HEAD";
7480         my %co = parse_commit($hash)
7481             or die_error(404, "Unknown commit object");
7482
7483         # choose format for commitdiff for merge
7484         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7485                 $hash_parent = '--cc';
7486         }
7487         # we need to prepare $formats_nav before almost any parameter munging
7488         my $formats_nav;
7489         if ($format eq 'html') {
7490                 $formats_nav =
7491                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7492                                 "raw");
7493                 if ($patch_max && @{$co{'parents'}} <= 1) {
7494                         $formats_nav .= " | " .
7495                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7496                                         "patch");
7497                 }
7498                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7499
7500                 if (defined $hash_parent &&
7501                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7502                         # commitdiff with two commits given
7503                         my $hash_parent_short = $hash_parent;
7504                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7505                                 $hash_parent_short = substr($hash_parent, 0, 7);
7506                         }
7507                         $formats_nav .=
7508                                 ' (from';
7509                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7510                                 if ($co{'parents'}[$i] eq $hash_parent) {
7511                                         $formats_nav .= ' parent ' . ($i+1);
7512                                         last;
7513                                 }
7514                         }
7515                         $formats_nav .= ': ' .
7516                                 $cgi->a({-href => href(-replay=>1,
7517                                                        hash=>$hash_parent, hash_base=>undef)},
7518                                         esc_html($hash_parent_short)) .
7519                                 ')';
7520                 } elsif (!$co{'parent'}) {
7521                         # --root commitdiff
7522                         $formats_nav .= ' (initial)';
7523                 } elsif (scalar @{$co{'parents'}} == 1) {
7524                         # single parent commit
7525                         $formats_nav .=
7526                                 ' (parent: ' .
7527                                 $cgi->a({-href => href(-replay=>1,
7528                                                        hash=>$co{'parent'}, hash_base=>undef)},
7529                                         esc_html(substr($co{'parent'}, 0, 7))) .
7530                                 ')';
7531                 } else {
7532                         # merge commit
7533                         if ($hash_parent eq '--cc') {
7534                                 $formats_nav .= ' | ' .
7535                                         $cgi->a({-href => href(-replay=>1,
7536                                                                hash=>$hash, hash_parent=>'-c')},
7537                                                 'combined');
7538                         } else { # $hash_parent eq '-c'
7539                                 $formats_nav .= ' | ' .
7540                                         $cgi->a({-href => href(-replay=>1,
7541                                                                hash=>$hash, hash_parent=>'--cc')},
7542                                                 'compact');
7543                         }
7544                         $formats_nav .=
7545                                 ' (merge: ' .
7546                                 join(' ', map {
7547                                         $cgi->a({-href => href(-replay=>1,
7548                                                                hash=>$_, hash_base=>undef)},
7549                                                 esc_html(substr($_, 0, 7)));
7550                                 } @{$co{'parents'}} ) .
7551                                 ')';
7552                 }
7553         }
7554
7555         my $hash_parent_param = $hash_parent;
7556         if (!defined $hash_parent_param) {
7557                 # --cc for multiple parents, --root for parentless
7558                 $hash_parent_param =
7559                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7560         }
7561
7562         # read commitdiff
7563         my $fd;
7564         my @difftree;
7565         if ($format eq 'html') {
7566                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7567                         "--no-commit-id", "--patch-with-raw", "--full-index",
7568                         $hash_parent_param, $hash, "--"
7569                         or die_error(500, "Open git-diff-tree failed");
7570
7571                 while (my $line = <$fd>) {
7572                         chomp $line;
7573                         # empty line ends raw part of diff-tree output
7574                         last unless $line;
7575                         push @difftree, scalar parse_difftree_raw_line($line);
7576                 }
7577
7578         } elsif ($format eq 'plain') {
7579                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7580                         '-p', $hash_parent_param, $hash, "--"
7581                         or die_error(500, "Open git-diff-tree failed");
7582         } elsif ($format eq 'patch') {
7583                 # For commit ranges, we limit the output to the number of
7584                 # patches specified in the 'patches' feature.
7585                 # For single commits, we limit the output to a single patch,
7586                 # diverging from the git-format-patch default.
7587                 my @commit_spec = ();
7588                 if ($hash_parent) {
7589                         if ($patch_max > 0) {
7590                                 push @commit_spec, "-$patch_max";
7591                         }
7592                         push @commit_spec, '-n', "$hash_parent..$hash";
7593                 } else {
7594                         if ($params{-single}) {
7595                                 push @commit_spec, '-1';
7596                         } else {
7597                                 if ($patch_max > 0) {
7598                                         push @commit_spec, "-$patch_max";
7599                                 }
7600                                 push @commit_spec, "-n";
7601                         }
7602                         push @commit_spec, '--root', $hash;
7603                 }
7604                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7605                         '--encoding=utf8', '--stdout', @commit_spec
7606                         or die_error(500, "Open git-format-patch failed");
7607         } else {
7608                 die_error(400, "Unknown commitdiff format");
7609         }
7610
7611         # non-textual hash id's can be cached
7612         my $expires;
7613         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7614                 $expires = "+1d";
7615         }
7616
7617         # write commit message
7618         if ($format eq 'html') {
7619                 my $refs = git_get_references();
7620                 my $ref = format_ref_marker($refs, $co{'id'});
7621
7622                 git_header_html(undef, $expires);
7623                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7624                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7625                 print "<div class=\"title_text\">\n" .
7626                       "<table class=\"object_header\">\n";
7627                 git_print_authorship_rows(\%co);
7628                 print "</table>".
7629                       "</div>\n";
7630                 print "<div class=\"page_body\">\n";
7631                 if (@{$co{'comment'}} > 1) {
7632                         print "<div class=\"log\">\n";
7633                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7634                         print "</div>\n"; # class="log"
7635                 }
7636
7637         } elsif ($format eq 'plain') {
7638                 my $refs = git_get_references("tags");
7639                 my $tagname = git_get_rev_name_tags($hash);
7640                 my $filename = basename($project) . "-$hash.patch";
7641
7642                 print $cgi->header(
7643                         -type => 'text/plain',
7644                         -charset => 'utf-8',
7645                         -expires => $expires,
7646                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7647                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7648                 print "From: " . to_utf8($co{'author'}) . "\n";
7649                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7650                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7651
7652                 print "X-Git-Tag: $tagname\n" if $tagname;
7653                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7654
7655                 foreach my $line (@{$co{'comment'}}) {
7656                         print to_utf8($line) . "\n";
7657                 }
7658                 print "---\n\n";
7659         } elsif ($format eq 'patch') {
7660                 my $filename = basename($project) . "-$hash.patch";
7661
7662                 print $cgi->header(
7663                         -type => 'text/plain',
7664                         -charset => 'utf-8',
7665                         -expires => $expires,
7666                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7667         }
7668
7669         # write patch
7670         if ($format eq 'html') {
7671                 my $use_parents = !defined $hash_parent ||
7672                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7673                 git_difftree_body(\@difftree, $hash,
7674                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7675                 print "<br/>\n";
7676
7677                 git_patchset_body($fd, $diff_style,
7678                                   \@difftree, $hash,
7679                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7680                 close $fd;
7681                 print "</div>\n"; # class="page_body"
7682                 git_footer_html();
7683
7684         } elsif ($format eq 'plain') {
7685                 local $/ = undef;
7686                 print <$fd>;
7687                 close $fd
7688                         or print "Reading git-diff-tree failed\n";
7689         } elsif ($format eq 'patch') {
7690                 local $/ = undef;
7691                 print <$fd>;
7692                 close $fd
7693                         or print "Reading git-format-patch failed\n";
7694         }
7695 }
7696
7697 sub git_commitdiff_plain {
7698         git_commitdiff(-format => 'plain');
7699 }
7700
7701 # format-patch-style patches
7702 sub git_patch {
7703         git_commitdiff(-format => 'patch', -single => 1);
7704 }
7705
7706 sub git_patches {
7707         git_commitdiff(-format => 'patch');
7708 }
7709
7710 sub git_history {
7711         git_log_generic('history', \&git_history_body,
7712                         $hash_base, $hash_parent_base,
7713                         $file_name, $hash);
7714 }
7715
7716 sub git_search {
7717         $searchtype ||= 'commit';
7718
7719         # check if appropriate features are enabled
7720         gitweb_check_feature('search')
7721                 or die_error(403, "Search is disabled");
7722         if ($searchtype eq 'pickaxe') {
7723                 # pickaxe may take all resources of your box and run for several minutes
7724                 # with every query - so decide by yourself how public you make this feature
7725                 gitweb_check_feature('pickaxe')
7726                         or die_error(403, "Pickaxe search is disabled");
7727         }
7728         if ($searchtype eq 'grep') {
7729                 # grep search might be potentially CPU-intensive, too
7730                 gitweb_check_feature('grep')
7731                         or die_error(403, "Grep search is disabled");
7732         }
7733
7734         if (!defined $searchtext) {
7735                 die_error(400, "Text field is empty");
7736         }
7737         if (!defined $hash) {
7738                 $hash = git_get_head_hash($project);
7739         }
7740         my %co = parse_commit($hash);
7741         if (!%co) {
7742                 die_error(404, "Unknown commit object");
7743         }
7744         if (!defined $page) {
7745                 $page = 0;
7746         }
7747
7748         if ($searchtype eq 'commit' ||
7749             $searchtype eq 'author' ||
7750             $searchtype eq 'committer') {
7751                 git_search_message(%co);
7752         } elsif ($searchtype eq 'pickaxe') {
7753                 git_search_changes(%co);
7754         } elsif ($searchtype eq 'grep') {
7755                 git_search_files(%co);
7756         } else {
7757                 die_error(400, "Unknown search type");
7758         }
7759 }
7760
7761 sub git_search_help {
7762         git_header_html();
7763         git_print_page_nav('','', $hash,$hash,$hash);
7764         print <<EOT;
7765 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7766 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7767 the pattern entered is recognized as the POSIX extended
7768 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7769 insensitive).</p>
7770 <dl>
7771 <dt><b>commit</b></dt>
7772 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7773 EOT
7774         my $have_grep = gitweb_check_feature('grep');
7775         if ($have_grep) {
7776                 print <<EOT;
7777 <dt><b>grep</b></dt>
7778 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7779     a different one) are searched for the given pattern. On large trees, this search can take
7780 a while and put some strain on the server, so please use it with some consideration. Note that
7781 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7782 case-sensitive.</dd>
7783 EOT
7784         }
7785         print <<EOT;
7786 <dt><b>author</b></dt>
7787 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7788 <dt><b>committer</b></dt>
7789 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7790 EOT
7791         my $have_pickaxe = gitweb_check_feature('pickaxe');
7792         if ($have_pickaxe) {
7793                 print <<EOT;
7794 <dt><b>pickaxe</b></dt>
7795 <dd>All commits that caused the string to appear or disappear from any file (changes that
7796 added, removed or "modified" the string) will be listed. This search can take a while and
7797 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7798 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7799 EOT
7800         }
7801         print "</dl>\n";
7802         git_footer_html();
7803 }
7804
7805 sub git_shortlog {
7806         git_log_generic('shortlog', \&git_shortlog_body,
7807                         $hash, $hash_parent);
7808 }
7809
7810 ## ......................................................................
7811 ## feeds (RSS, Atom; OPML)
7812
7813 sub git_feed {
7814         my $format = shift || 'atom';
7815         my $have_blame = gitweb_check_feature('blame');
7816
7817         # Atom: http://www.atomenabled.org/developers/syndication/
7818         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7819         if ($format ne 'rss' && $format ne 'atom') {
7820                 die_error(400, "Unknown web feed format");
7821         }
7822
7823         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7824         my $head = $hash || 'HEAD';
7825         my @commitlist = parse_commits($head, 150, 0, $file_name);
7826
7827         my %latest_commit;
7828         my %latest_date;
7829         my $content_type = "application/$format+xml";
7830         if (defined $cgi->http('HTTP_ACCEPT') &&
7831                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7832                 # browser (feed reader) prefers text/xml
7833                 $content_type = 'text/xml';
7834         }
7835         if (defined($commitlist[0])) {
7836                 %latest_commit = %{$commitlist[0]};
7837                 my $latest_epoch = $latest_commit{'committer_epoch'};
7838                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7839                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7840                 if (defined $if_modified) {
7841                         my $since;
7842                         if (eval { require HTTP::Date; 1; }) {
7843                                 $since = HTTP::Date::str2time($if_modified);
7844                         } elsif (eval { require Time::ParseDate; 1; }) {
7845                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7846                         }
7847                         if (defined $since && $latest_epoch <= $since) {
7848                                 print $cgi->header(
7849                                         -type => $content_type,
7850                                         -charset => 'utf-8',
7851                                         -last_modified => $latest_date{'rfc2822'},
7852                                         -status => '304 Not Modified');
7853                                 return;
7854                         }
7855                 }
7856                 print $cgi->header(
7857                         -type => $content_type,
7858                         -charset => 'utf-8',
7859                         -last_modified => $latest_date{'rfc2822'});
7860         } else {
7861                 print $cgi->header(
7862                         -type => $content_type,
7863                         -charset => 'utf-8');
7864         }
7865
7866         # Optimization: skip generating the body if client asks only
7867         # for Last-Modified date.
7868         return if ($cgi->request_method() eq 'HEAD');
7869
7870         # header variables
7871         my $title = "$site_name - $project/$action";
7872         my $feed_type = 'log';
7873         if (defined $hash) {
7874                 $title .= " - '$hash'";
7875                 $feed_type = 'branch log';
7876                 if (defined $file_name) {
7877                         $title .= " :: $file_name";
7878                         $feed_type = 'history';
7879                 }
7880         } elsif (defined $file_name) {
7881                 $title .= " - $file_name";
7882                 $feed_type = 'history';
7883         }
7884         $title .= " $feed_type";
7885         my $descr = git_get_project_description($project);
7886         if (defined $descr) {
7887                 $descr = esc_html($descr);
7888         } else {
7889                 $descr = "$project " .
7890                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7891                          " feed";
7892         }
7893         my $owner = git_get_project_owner($project);
7894         $owner = esc_html($owner);
7895
7896         #header
7897         my $alt_url;
7898         if (defined $file_name) {
7899                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7900         } elsif (defined $hash) {
7901                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7902         } else {
7903                 $alt_url = href(-full=>1, action=>"summary");
7904         }
7905         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7906         if ($format eq 'rss') {
7907                 print <<XML;
7908 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7909 <channel>
7910 XML
7911                 print "<title>$title</title>\n" .
7912                       "<link>$alt_url</link>\n" .
7913                       "<description>$descr</description>\n" .
7914                       "<language>en</language>\n" .
7915                       # project owner is responsible for 'editorial' content
7916                       "<managingEditor>$owner</managingEditor>\n";
7917                 if (defined $logo || defined $favicon) {
7918                         # prefer the logo to the favicon, since RSS
7919                         # doesn't allow both
7920                         my $img = esc_url($logo || $favicon);
7921                         print "<image>\n" .
7922                               "<url>$img</url>\n" .
7923                               "<title>$title</title>\n" .
7924                               "<link>$alt_url</link>\n" .
7925                               "</image>\n";
7926                 }
7927                 if (%latest_date) {
7928                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7929                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7930                 }
7931                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7932         } elsif ($format eq 'atom') {
7933                 print <<XML;
7934 <feed xmlns="http://www.w3.org/2005/Atom">
7935 XML
7936                 print "<title>$title</title>\n" .
7937                       "<subtitle>$descr</subtitle>\n" .
7938                       '<link rel="alternate" type="text/html" href="' .
7939                       $alt_url . '" />' . "\n" .
7940                       '<link rel="self" type="' . $content_type . '" href="' .
7941                       $cgi->self_url() . '" />' . "\n" .
7942                       "<id>" . href(-full=>1) . "</id>\n" .
7943                       # use project owner for feed author
7944                       "<author><name>$owner</name></author>\n";
7945                 if (defined $favicon) {
7946                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7947                 }
7948                 if (defined $logo) {
7949                         # not twice as wide as tall: 72 x 27 pixels
7950                         print "<logo>" . esc_url($logo) . "</logo>\n";
7951                 }
7952                 if (! %latest_date) {
7953                         # dummy date to keep the feed valid until commits trickle in:
7954                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7955                 } else {
7956                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7957                 }
7958                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7959         }
7960
7961         # contents
7962         for (my $i = 0; $i <= $#commitlist; $i++) {
7963                 my %co = %{$commitlist[$i]};
7964                 my $commit = $co{'id'};
7965                 # we read 150, we always show 30 and the ones more recent than 48 hours
7966                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7967                         last;
7968                 }
7969                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7970
7971                 # get list of changed files
7972                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7973                         $co{'parent'} || "--root",
7974                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7975                         or next;
7976                 my @difftree = map { chomp; $_ } <$fd>;
7977                 close $fd
7978                         or next;
7979
7980                 # print element (entry, item)
7981                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7982                 if ($format eq 'rss') {
7983                         print "<item>\n" .
7984                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7985                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7986                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7987                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7988                               "<link>$co_url</link>\n" .
7989                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7990                               "<content:encoded>" .
7991                               "<![CDATA[\n";
7992                 } elsif ($format eq 'atom') {
7993                         print "<entry>\n" .
7994                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7995                               "<updated>$cd{'iso-8601'}</updated>\n" .
7996                               "<author>\n" .
7997                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7998                         if ($co{'author_email'}) {
7999                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8000                         }
8001                         print "</author>\n" .
8002                               # use committer for contributor
8003                               "<contributor>\n" .
8004                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8005                         if ($co{'committer_email'}) {
8006                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8007                         }
8008                         print "</contributor>\n" .
8009                               "<published>$cd{'iso-8601'}</published>\n" .
8010                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
8011                               "<id>$co_url</id>\n" .
8012                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8013                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8014                 }
8015                 my $comment = $co{'comment'};
8016                 print "<pre>\n";
8017                 foreach my $line (@$comment) {
8018                         $line = esc_html($line);
8019                         print "$line\n";
8020                 }
8021                 print "</pre><ul>\n";
8022                 foreach my $difftree_line (@difftree) {
8023                         my %difftree = parse_difftree_raw_line($difftree_line);
8024                         next if !$difftree{'from_id'};
8025
8026                         my $file = $difftree{'file'} || $difftree{'to_file'};
8027
8028                         print "<li>" .
8029                               "[" .
8030                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8031                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8032                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8033                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8034                                       -title => "diff"}, 'D');
8035                         if ($have_blame) {
8036                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8037                                                              file_name=>$file, hash_base=>$commit),
8038                                               -title => "blame"}, 'B');
8039                         }
8040                         # if this is not a feed of a file history
8041                         if (!defined $file_name || $file_name ne $file) {
8042                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8043                                                              file_name=>$file, hash=>$commit),
8044                                               -title => "history"}, 'H');
8045                         }
8046                         $file = esc_path($file);
8047                         print "] ".
8048                               "$file</li>\n";
8049                 }
8050                 if ($format eq 'rss') {
8051                         print "</ul>]]>\n" .
8052                               "</content:encoded>\n" .
8053                               "</item>\n";
8054                 } elsif ($format eq 'atom') {
8055                         print "</ul>\n</div>\n" .
8056                               "</content>\n" .
8057                               "</entry>\n";
8058                 }
8059         }
8060
8061         # end of feed
8062         if ($format eq 'rss') {
8063                 print "</channel>\n</rss>\n";
8064         } elsif ($format eq 'atom') {
8065                 print "</feed>\n";
8066         }
8067 }
8068
8069 sub git_rss {
8070         git_feed('rss');
8071 }
8072
8073 sub git_atom {
8074         git_feed('atom');
8075 }
8076
8077 sub git_opml {
8078         my @list = git_get_projects_list($project_filter, $strict_export);
8079         if (!@list) {
8080                 die_error(404, "No projects found");
8081         }
8082
8083         print $cgi->header(
8084                 -type => 'text/xml',
8085                 -charset => 'utf-8',
8086                 -content_disposition => 'inline; filename="opml.xml"');
8087
8088         my $title = esc_html($site_name);
8089         my $filter = " within subdirectory ";
8090         if (defined $project_filter) {
8091                 $filter .= esc_html($project_filter);
8092         } else {
8093                 $filter = "";
8094         }
8095         print <<XML;
8096 <?xml version="1.0" encoding="utf-8"?>
8097 <opml version="1.0">
8098 <head>
8099   <title>$title OPML Export$filter</title>
8100 </head>
8101 <body>
8102 <outline text="git RSS feeds">
8103 XML
8104
8105         foreach my $pr (@list) {
8106                 my %proj = %$pr;
8107                 my $head = git_get_head_hash($proj{'path'});
8108                 if (!defined $head) {
8109                         next;
8110                 }
8111                 $git_dir = "$projectroot/$proj{'path'}";
8112                 my %co = parse_commit($head);
8113                 if (!%co) {
8114                         next;
8115                 }
8116
8117                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8118                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8119                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8120                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8121         }
8122         print <<XML;
8123 </outline>
8124 </body>
8125 </opml>
8126 XML
8127 }