git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 use Carp qw/croak/;
  14 use Digest::MD5;
  15 use IO::File qw//;
  16 use File::Basename qw/dirname basename/;
  17 use File::Path qw/mkpath/;
  18 use File::Spec;
  19 use File::Find;
  20 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  21 use IPC::Open3;
  22 use Memoize;
  23
  24 use Git::SVN;
  25 use Git::SVN::Editor;
  26 use Git::SVN::Fetcher;
  27 use Git::SVN::Ra;
  28 use Git::SVN::Prompt;
  29 use Git::SVN::Log;
  30 use Git::SVN::Migration;
  31
  32 use Git::SVN::Utils qw(
  33         fatal
  34         can_compress
  35         canonicalize_path
  36         canonicalize_url
  37         join_paths
  38         add_path_to_url
  39 );
  40
  41 use Git qw(
  42         git_cmd_try
  43         command
  44         command_oneline
  45         command_noisy
  46         command_output_pipe
  47         command_close_pipe
  48         command_bidi_pipe
  49         command_close_bidi_pipe
  50 );
  51
  52 BEGIN {
  53         Memoize::memoize 'Git::config';
  54         Memoize::memoize 'Git::config_bool';
  55 }
  56
  57
  58 # From which subdir have we been invoked?
  59 my $cmd_dir_prefix = eval {
  60         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  61 } || '';
  62
  63 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  64 $ENV{GIT_DIR} ||= '.git';
  65 $Git::SVN::Ra::_log_window_size = 100;
  66
  67 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  68         $ENV{SVN_SSH} = $ENV{GIT_SSH};
  69 }
  70
  71 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  72         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  73         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  74 }
  75
  76 $Git::SVN::Log::TZ = $ENV{TZ};
  77 $ENV{TZ} = 'UTC';
  78 $| = 1; # unbuffer STDOUT
  79
  80 # All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  81 # repository decides to close the connection which we expect to be kept alive.
  82 $SIG{PIPE} = 'IGNORE';
  83
  84 # Given a dot separated version number, "subtract" it from
  85 # the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  86 # is at least at the version the caller asked for.
  87 sub compare_svn_version {
  88         my (@ours) = split(/\./, $SVN::Core::VERSION);
  89         my (@theirs) = split(/\./, $_[0]);
  90         my ($i, $diff);
  91
  92         for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  93                 $diff = $ours[$i] - $theirs[$i];
  94                 return $diff if ($diff);
  95         }
  96         return 1 if ($i < @ours);
  97         return -1 if ($i < @theirs);
  98         return 0;
  99 }
 100
 101 sub _req_svn {
 102         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
 103         require SVN::Ra;
 104         require SVN::Delta;
 105         if (::compare_svn_version('1.1.0') < 0) {
 106                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
 107         }
 108 }
 109
 110 $sha1 = qr/[a-f\d]{40}/;
 111 $sha1_short = qr/[a-f\d]{4,40}/;
 112 my ($_stdin, $_help, $_edit,
 113         $_message, $_file, $_branch_dest,
 114         $_template, $_shared,
 115         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 116         $_merge, $_strategy, $_preserve_merges, $_dry_run, $_local,
 117         $_prefix, $_no_checkout, $_url, $_verbose,
 118         $_commit_url, $_tag, $_merge_info, $_interactive);
 119
 120 # This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 121 sub opt_prefix { return $_prefix || '' }
 122
 123 $Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 124 $_q ||= 0;
 125 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 126                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
 127                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 128                     'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 129                     'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 130 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 131                 'authors-file|A=s' => \$_authors,
 132                 'authors-prog=s' => \$_authors_prog,
 133                 'repack:i' => \$Git::SVN::_repack,
 134                 'noMetadata' => \$Git::SVN::_no_metadata,
 135                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 136                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 137                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 138                 'no-checkout' => \$_no_checkout,
 139                 'quiet|q+' => \$_q,
 140                 'repack-flags|repack-args|repack-opts=s' =>
 141                    \$Git::SVN::_repack_flags,
 142                 'use-log-author' => \$Git::SVN::_use_log_author,
 143                 'add-author-from' => \$Git::SVN::_add_author_from,
 144                 'localtime' => \$Git::SVN::_localtime,
 145                 %remote_opts );
 146
 147 my ($_trunk, @_tags, @_branches, $_stdlayout);
 148 my %icv;
 149 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 150                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 151                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 152                   'stdlayout|s' => \$_stdlayout,
 153                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 154                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 155                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 156                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 157                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 158                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 159                   %remote_opts );
 160 my %cmt_opts = ( 'edit|e' => \$_edit,
 161                 'rmdir' => \$Git::SVN::Editor::_rmdir,
 162                 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 163                 'l=i' => \$Git::SVN::Editor::_rename_limit,
 164                 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 165 );
 166
 167 my %cmd = (
 168         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 169                         { 'revision|r=s' => \$_revision,
 170                           'fetch-all|all' => \$_fetch_all,
 171                           'parent|p' => \$_fetch_parent,
 172                            %fc_opts } ],
 173         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 174                         { 'revision|r=s' => \$_revision,
 175                           'preserve-empty-dirs' =>
 176                                 \$Git::SVN::Fetcher::_preserve_empty_dirs,
 177                           'placeholder-filename=s' =>
 178                                 \$Git::SVN::Fetcher::_placeholder_filename,
 179                            %fc_opts, %init_opts } ],
 180         init => [ \&cmd_init, "Initialize a repo for tracking" .
 181                           " (requires URL argument)",
 182                           \%init_opts ],
 183         'multi-init' => [ \&cmd_multi_init,
 184                           "Deprecated alias for ".
 185                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 186                           \%init_opts ],
 187         dcommit => [ \&cmd_dcommit,
 188                      'Commit several diffs to merge with upstream',
 189                         { 'merge|m|M' => \$_merge,
 190                           'strategy|s=s' => \$_strategy,
 191                           'verbose|v' => \$_verbose,
 192                           'dry-run|n' => \$_dry_run,
 193                           'fetch-all|all' => \$_fetch_all,
 194                           'commit-url=s' => \$_commit_url,
 195                           'revision|r=i' => \$_revision,
 196                           'no-rebase' => \$_no_rebase,
 197                           'mergeinfo=s' => \$_merge_info,
 198                           'interactive|i' => \$_interactive,
 199                         %cmt_opts, %fc_opts } ],
 200         branch => [ \&cmd_branch,
 201                     'Create a branch in the SVN repository',
 202                     { 'message|m=s' => \$_message,
 203                       'destination|d=s' => \$_branch_dest,
 204                       'dry-run|n' => \$_dry_run,
 205                       'tag|t' => \$_tag,
 206                       'username=s' => \$Git::SVN::Prompt::_username,
 207                       'commit-url=s' => \$_commit_url } ],
 208         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 209                  'Create a tag in the SVN repository',
 210                  { 'message|m=s' => \$_message,
 211                    'destination|d=s' => \$_branch_dest,
 212                    'dry-run|n' => \$_dry_run,
 213                    'username=s' => \$Git::SVN::Prompt::_username,
 214                    'commit-url=s' => \$_commit_url } ],
 215         'set-tree' => [ \&cmd_set_tree,
 216                         "Set an SVN repository to a git tree-ish",
 217                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 218         'create-ignore' => [ \&cmd_create_ignore,
 219                              'Create a .gitignore per svn:ignore',
 220                              { 'revision|r=i' => \$_revision
 221                              } ],
 222         'mkdirs' => [ \&cmd_mkdirs ,
 223                       "recreate empty directories after a checkout",
 224                       { 'revision|r=i' => \$_revision } ],
 225         'propget' => [ \&cmd_propget,
 226                        'Print the value of a property on a file or directory',
 227                        { 'revision|r=i' => \$_revision } ],
 228         'proplist' => [ \&cmd_proplist,
 229                        'List all properties of a file or directory',
 230                        { 'revision|r=i' => \$_revision } ],
 231         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 232                         { 'revision|r=i' => \$_revision
 233                         } ],
 234         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 235                         { 'revision|r=i' => \$_revision
 236                         } ],
 237         'multi-fetch' => [ \&cmd_multi_fetch,
 238                            "Deprecated alias for $0 fetch --all",
 239                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 240         'migrate' => [ sub { },
 241                        # no-op, we automatically run this anyways,
 242                        'Migrate configuration/metadata/layout from
 243                         previous versions of git-svn',
 244                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 245                          %remote_opts } ],
 246         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 247                         { 'limit=i' => \$Git::SVN::Log::limit,
 248                           'revision|r=s' => \$_revision,
 249                           'verbose|v' => \$Git::SVN::Log::verbose,
 250                           'incremental' => \$Git::SVN::Log::incremental,
 251                           'oneline' => \$Git::SVN::Log::oneline,
 252                           'show-commit' => \$Git::SVN::Log::show_commit,
 253                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 254                           'authors-file|A=s' => \$_authors,
 255                           'color' => \$Git::SVN::Log::color,
 256                           'pager=s' => \$Git::SVN::Log::pager
 257                         } ],
 258         'find-rev' => [ \&cmd_find_rev,
 259                         "Translate between SVN revision numbers and tree-ish",
 260                         {} ],
 261         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 262                         { 'merge|m|M' => \$_merge,
 263                           'verbose|v' => \$_verbose,
 264                           'strategy|s=s' => \$_strategy,
 265                           'local|l' => \$_local,
 266                           'fetch-all|all' => \$_fetch_all,
 267                           'dry-run|n' => \$_dry_run,
 268                           'preserve-merges|p' => \$_preserve_merges,
 269                           %fc_opts } ],
 270         'commit-diff' => [ \&cmd_commit_diff,
 271                            'Commit a diff between two trees',
 272                         { 'message|m=s' => \$_message,
 273                           'file|F=s' => \$_file,
 274                           'revision|r=s' => \$_revision,
 275                         %cmt_opts } ],
 276         'info' => [ \&cmd_info,
 277                     "Show info about the latest SVN revision
 278                      on the current branch",
 279                     { 'url' => \$_url, } ],
 280         'blame' => [ \&Git::SVN::Log::cmd_blame,
 281                     "Show what revision and author last modified each line of a file",
 282                     { 'git-format' => \$Git::SVN::Log::_git_format } ],
 283         'reset' => [ \&cmd_reset,
 284                      "Undo fetches back to the specified SVN revision",
 285                      { 'revision|r=s' => \$_revision,
 286                        'parent|p' => \$_fetch_parent } ],
 287         'gc' => [ \&cmd_gc,
 288                   "Compress unhandled.log files in .git/svn and remove " .
 289                   "index files in .git/svn",
 290                 {} ],
 291 );
 292
 293 use Term::ReadLine;
 294 package FakeTerm;
 295 sub new {
 296         my ($class, $reason) = @_;
 297         return bless \$reason, shift;
 298 }
 299 sub readline {
 300         my $self = shift;
 301         die "Cannot use readline on FakeTerm: $$self";
 302 }
 303 package main;
 304
 305 my $term = eval {
 306         $ENV{"GIT_SVN_NOTTY"}
 307                 ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 308                 : new Term::ReadLine 'git-svn';
 309 };
 310 if ($@) {
 311         $term = new FakeTerm "$@: going non-interactive";
 312 }
 313
 314 my $cmd;
 315 for (my $i = 0; $i < @ARGV; $i++) {
 316         if (defined $cmd{$ARGV[$i]}) {
 317                 $cmd = $ARGV[$i];
 318                 splice @ARGV, $i, 1;
 319                 last;
 320         } elsif ($ARGV[$i] eq 'help') {
 321                 $cmd = $ARGV[$i+1];
 322                 usage(0);
 323         }
 324 };
 325
 326 # make sure we're always running at the top-level working directory
 327 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 328         unless (-d $ENV{GIT_DIR}) {
 329                 if ($git_dir_user_set) {
 330                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 331                             "but it is not a directory\n";
 332                 }
 333                 my $git_dir = delete $ENV{GIT_DIR};
 334                 my $cdup = undef;
 335                 git_cmd_try {
 336                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 337                         $git_dir = '.' unless ($cdup);
 338                         chomp $cdup if ($cdup);
 339                         $cdup = "." unless ($cdup && length $cdup);
 340                 } "Already at toplevel, but $git_dir not found\n";
 341                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 342                 unless (-d $git_dir) {
 343                         die "$git_dir still not found after going to ",
 344                             "'$cdup'\n";
 345                 }
 346                 $ENV{GIT_DIR} = $git_dir;
 347         }
 348         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 349 }
 350
 351 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 352
 353 read_git_config(\%opts);
 354 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 355         Getopt::Long::Configure('pass_through');
 356 }
 357 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 358                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 359                     'id|i=s' => \$Git::SVN::default_ref_id,
 360                     'svn-remote|remote|R=s' => sub {
 361                        $Git::SVN::no_reuse_existing = 1;
 362                        $Git::SVN::default_repo_id = $_[1] });
 363 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 364
 365 usage(0) if $_help;
 366 version() if $_version;
 367 usage(1) unless defined $cmd;
 368 load_authors() if $_authors;
 369 if (defined $_authors_prog) {
 370         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 371 }
 372
 373 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 374         Git::SVN::Migration::migration_check();
 375 }
 376 Git::SVN::init_vars();
 377 eval {
 378         Git::SVN::verify_remotes_sanity();
 379         $cmd{$cmd}->[0]->(@ARGV);
 380         post_fetch_checkout();
 381 };
 382 fatal $@ if $@;
 383 exit 0;
 384
 385 ####################### primary functions ######################
 386 sub usage {
 387         my $exit = shift || 0;
 388         my $fd = $exit ? \*STDERR : \*STDOUT;
 389         print $fd <<"";
 390 git-svn - bidirectional operations between a single Subversion tree and git
 391 Usage: git svn <command> [options] [arguments]\n
 392
 393         print $fd "Available commands:\n" unless $cmd;
 394
 395         foreach (sort keys %cmd) {
 396                 next if $cmd && $cmd ne $_;
 397                 next if /^multi-/; # don't show deprecated commands
 398                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 399                 foreach (sort keys %{$cmd{$_}->[2]}) {
 400                         # mixed-case options are for .git/config only
 401                         next if /[A-Z]/ && /^[a-z]+$/i;
 402                         # prints out arguments as they should be passed:
 403                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 404                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 405                                                         "--$_" : "-$_" }
 406                                                 split /\|/,$_)," $x\n";
 407                 }
 408         }
 409         print $fd <<"";
 410 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 411 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 412 one git repository and want to keep them separate.  See git-svn(1) for more
 413 information.
 414
 415         exit $exit;
 416 }
 417
 418 sub version {
 419         ::_req_svn();
 420         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 421         exit 0;
 422 }
 423
 424 sub ask {
 425         my ($prompt, %arg) = @_;
 426         my $valid_re = $arg{valid_re};
 427         my $default = $arg{default};
 428         my $resp;
 429         my $i = 0;
 430
 431         if ( !( defined($term->IN)
 432             && defined( fileno($term->IN) )
 433             && defined( $term->OUT )
 434             && defined( fileno($term->OUT) ) ) ){
 435                 return defined($default) ? $default : undef;
 436         }
 437
 438         while ($i++ < 10) {
 439                 $resp = $term->readline($prompt);
 440                 if (!defined $resp) { # EOF
 441                         print "\n";
 442                         return defined $default ? $default : undef;
 443                 }
 444                 if ($resp eq '' and defined $default) {
 445                         return $default;
 446                 }
 447                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 448                         return $resp;
 449                 }
 450         }
 451         return undef;
 452 }
 453
 454 sub do_git_init_db {
 455         unless (-d $ENV{GIT_DIR}) {
 456                 my @init_db = ('init');
 457                 push @init_db, "--template=$_template" if defined $_template;
 458                 if (defined $_shared) {
 459                         if ($_shared =~ /[a-z]/) {
 460                                 push @init_db, "--shared=$_shared";
 461                         } else {
 462                                 push @init_db, "--shared";
 463                         }
 464                 }
 465                 command_noisy(@init_db);
 466                 $_repository = Git->repository(Repository => ".git");
 467         }
 468         my $set;
 469         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 470         foreach my $i (keys %icv) {
 471                 die "'$set' and '$i' cannot both be set\n" if $set;
 472                 next unless defined $icv{$i};
 473                 command_noisy('config', "$pfx.$i", $icv{$i});
 474                 $set = $i;
 475         }
 476         my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 477         command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 478                 if defined $$ignore_paths_regex;
 479         my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 480         command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 481                 if defined $$ignore_refs_regex;
 482
 483         if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 484                 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 485                 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 486                 command_noisy('config', "$pfx.placeholder-filename", $$fname);
 487         }
 488 }
 489
 490 sub init_subdir {
 491         my $repo_path = shift or return;
 492         mkpath([$repo_path]) unless -d $repo_path;
 493         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 494         $ENV{GIT_DIR} = '.git';
 495         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 496 }
 497
 498 sub cmd_clone {
 499         my ($url, $path) = @_;
 500         if (!defined $path &&
 501             (defined $_trunk || @_branches || @_tags ||
 502              defined $_stdlayout) &&
 503             $url !~ m#^[a-z\+]+://#) {
 504                 $path = $url;
 505         }
 506         $path = basename($url) if !defined $path || !length $path;
 507         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 508         cmd_init($url, $path);
 509         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 510             if $_authors;
 511         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 512 }
 513
 514 sub cmd_init {
 515         if (defined $_stdlayout) {
 516                 $_trunk = 'trunk' if (!defined $_trunk);
 517                 @_tags = 'tags' if (! @_tags);
 518                 @_branches = 'branches' if (! @_branches);
 519         }
 520         if (defined $_trunk || @_branches || @_tags) {
 521                 return cmd_multi_init(@_);
 522         }
 523         my $url = shift or die "SVN repository location required ",
 524                                "as a command-line argument\n";
 525         $url = canonicalize_url($url);
 526         init_subdir(@_);
 527         do_git_init_db();
 528
 529         if ($Git::SVN::_minimize_url eq 'unset') {
 530                 $Git::SVN::_minimize_url = 0;
 531         }
 532
 533         Git::SVN->init($url);
 534 }
 535
 536 sub cmd_fetch {
 537         if (grep /^\d+=./, @_) {
 538                 die "'<rev>=<commit>' fetch arguments are ",
 539                     "no longer supported.\n";
 540         }
 541         my ($remote) = @_;
 542         if (@_ > 1) {
 543                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 544         }
 545         $Git::SVN::no_reuse_existing = undef;
 546         if ($_fetch_parent) {
 547                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 548                 unless ($gs) {
 549                         die "Unable to determine upstream SVN information from ",
 550                             "working tree history\n";
 551                 }
 552                 # just fetch, don't checkout.
 553                 $_no_checkout = 'true';
 554                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 555         } elsif ($_fetch_all) {
 556                 cmd_multi_fetch();
 557         } else {
 558                 $remote ||= $Git::SVN::default_repo_id;
 559                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 560         }
 561 }
 562
 563 sub cmd_set_tree {
 564         my (@commits) = @_;
 565         if ($_stdin || !@commits) {
 566                 print "Reading from stdin...\n";
 567                 @commits = ();
 568                 while (<STDIN>) {
 569                         if (/\b($sha1_short)\b/o) {
 570                                 unshift @commits, $1;
 571                         }
 572                 }
 573         }
 574         my @revs;
 575         foreach my $c (@commits) {
 576                 my @tmp = command('rev-parse',$c);
 577                 if (scalar @tmp == 1) {
 578                         push @revs, $tmp[0];
 579                 } elsif (scalar @tmp > 1) {
 580                         push @revs, reverse(command('rev-list',@tmp));
 581                 } else {
 582                         fatal "Failed to rev-parse $c";
 583                 }
 584         }
 585         my $gs = Git::SVN->new;
 586         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 587         $gs->fetch;
 588         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 589                 fatal "There are new revisions that were fetched ",
 590                       "and need to be merged (or acknowledged) ",
 591                       "before committing.\nlast rev: $r_last\n",
 592                       " current: $gs->{last_rev}";
 593         }
 594         $gs->set_tree($_) foreach @revs;
 595         print "Done committing ",scalar @revs," revisions to SVN\n";
 596         unlink $gs->{index};
 597 }
 598
 599 sub split_merge_info_range {
 600         my ($range) = @_;
 601         if ($range =~ /(\d+)-(\d+)/) {
 602                 return (int($1), int($2));
 603         } else {
 604                 return (int($range), int($range));
 605         }
 606 }
 607
 608 sub combine_ranges {
 609         my ($in) = @_;
 610
 611         my @fnums = ();
 612         my @arr = split(/,/, $in);
 613         for my $element (@arr) {
 614                 my ($start, $end) = split_merge_info_range($element);
 615                 push @fnums, $start;
 616         }
 617
 618         my @sorted = @arr [ sort {
 619                 $fnums[$a] <=> $fnums[$b]
 620         } 0..$#arr ];
 621
 622         my @return = ();
 623         my $last = -1;
 624         my $first = -1;
 625         for my $element (@sorted) {
 626                 my ($start, $end) = split_merge_info_range($element);
 627
 628                 if ($last == -1) {
 629                         $first = $start;
 630                         $last = $end;
 631                         next;
 632                 }
 633                 if ($start <= $last+1) {
 634                         if ($end > $last) {
 635                                 $last = $end;
 636                         }
 637                         next;
 638                 }
 639                 if ($first == $last) {
 640                         push @return, "$first";
 641                 } else {
 642                         push @return, "$first-$last";
 643                 }
 644                 $first = $start;
 645                 $last = $end;
 646         }
 647
 648         if ($first != -1) {
 649                 if ($first == $last) {
 650                         push @return, "$first";
 651                 } else {
 652                         push @return, "$first-$last";
 653                 }
 654         }
 655
 656         return join(',', @return);
 657 }
 658
 659 sub merge_revs_into_hash {
 660         my ($hash, $minfo) = @_;
 661         my @lines = split(' ', $minfo);
 662
 663         for my $line (@lines) {
 664                 my ($branchpath, $revs) = split(/:/, $line);
 665
 666                 if (exists($hash->{$branchpath})) {
 667                         # Merge the two revision sets
 668                         my $combined = "$hash->{$branchpath},$revs";
 669                         $hash->{$branchpath} = combine_ranges($combined);
 670                 } else {
 671                         # Just do range combining for consolidation
 672                         $hash->{$branchpath} = combine_ranges($revs);
 673                 }
 674         }
 675 }
 676
 677 sub merge_merge_info {
 678         my ($mergeinfo_one, $mergeinfo_two) = @_;
 679         my %result_hash = ();
 680
 681         merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 682         merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 683
 684         my $result = '';
 685         # Sort below is for consistency's sake
 686         for my $branchname (sort keys(%result_hash)) {
 687                 my $revlist = $result_hash{$branchname};
 688                 $result .= "$branchname:$revlist\n"
 689         }
 690         return $result;
 691 }
 692
 693 sub populate_merge_info {
 694         my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 695
 696         my %parentshash;
 697         read_commit_parents(\%parentshash, $d);
 698         my @parents = @{$parentshash{$d}};
 699         if ($#parents > 0) {
 700                 # Merge commit
 701                 my $all_parents_ok = 1;
 702                 my $aggregate_mergeinfo = '';
 703                 my $rooturl = $gs->repos_root;
 704
 705                 if (defined($rewritten_parent)) {
 706                         # Replace first parent with newly-rewritten version
 707                         shift @parents;
 708                         unshift @parents, $rewritten_parent;
 709                 }
 710
 711                 foreach my $parent (@parents) {
 712                         my ($branchurl, $svnrev, $paruuid) =
 713                                 cmt_metadata($parent);
 714
 715                         unless (defined($svnrev)) {
 716                                 # Should have been caught be preflight check
 717                                 fatal "merge commit $d has ancestor $parent, but that change "
 718                      ."does not have git-svn metadata!";
 719                         }
 720                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 721                                 fatal "commit $parent git-svn metadata changed mid-run!";
 722                         }
 723                         my $branchpath = $1;
 724
 725                         my $ra = Git::SVN::Ra->new($branchurl);
 726                         my (undef, undef, $props) =
 727                                 $ra->get_dir(canonicalize_path("."), $svnrev);
 728                         my $par_mergeinfo = $props->{'svn:mergeinfo'};
 729                         unless (defined $par_mergeinfo) {
 730                                 $par_mergeinfo = '';
 731                         }
 732                         # Merge previous mergeinfo values
 733                         $aggregate_mergeinfo =
 734                                 merge_merge_info($aggregate_mergeinfo,
 735                                                                  $par_mergeinfo, 0);
 736
 737                         next if $parent eq $parents[0]; # Skip first parent
 738                         # Add new changes being placed in tree by merge
 739                         my @cmd = (qw/rev-list --reverse/,
 740                                            $parent, qw/--not/);
 741                         foreach my $par (@parents) {
 742                                 unless ($par eq $parent) {
 743                                         push @cmd, $par;
 744                                 }
 745                         }
 746                         my @revsin = ();
 747                         my ($revlist, $ctx) = command_output_pipe(@cmd);
 748                         while (<$revlist>) {
 749                                 my $irev = $_;
 750                                 chomp $irev;
 751                                 my (undef, $csvnrev, undef) =
 752                                         cmt_metadata($irev);
 753                                 unless (defined $csvnrev) {
 754                                         # A child is missing SVN annotations...
 755                                         # this might be OK, or might not be.
 756                                         warn "W:child $irev is merged into revision "
 757                                                  ."$d but does not have git-svn metadata. "
 758                                                  ."This means git-svn cannot determine the "
 759                                                  ."svn revision numbers to place into the "
 760                                                  ."svn:mergeinfo property. You must ensure "
 761                                                  ."a branch is entirely committed to "
 762                                                  ."SVN before merging it in order for "
 763                                                  ."svn:mergeinfo population to function "
 764                                                  ."properly";
 765                                 }
 766                                 push @revsin, $csvnrev;
 767                         }
 768                         command_close_pipe($revlist, $ctx);
 769
 770                         last unless $all_parents_ok;
 771
 772                         # We now have a list of all SVN revnos which are
 773                         # merged by this particular parent. Integrate them.
 774                         next if $#revsin == -1;
 775                         my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 776                         $aggregate_mergeinfo =
 777                                 merge_merge_info($aggregate_mergeinfo,
 778                                                                  $newmergeinfo, 1);
 779                 }
 780                 if ($all_parents_ok and $aggregate_mergeinfo) {
 781                         return $aggregate_mergeinfo;
 782                 }
 783         }
 784
 785         return undef;
 786 }
 787
 788 sub cmd_dcommit {
 789         my $head = shift;
 790         command_noisy(qw/update-index --refresh/);
 791         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 792                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 793                 . "or stash them with `git stash'.\n";
 794         $head ||= 'HEAD';
 795
 796         my $old_head;
 797         if ($head ne 'HEAD') {
 798                 $old_head = eval {
 799                         command_oneline([qw/symbolic-ref -q HEAD/])
 800                 };
 801                 if ($old_head) {
 802                         $old_head =~ s{^refs/heads/}{};
 803                 } else {
 804                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 805                 }
 806                 command(['checkout', $head], STDERR => 0);
 807         }
 808
 809         my @refs;
 810         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 811         unless ($gs) {
 812                 die "Unable to determine upstream SVN information from ",
 813                     "$head history.\nPerhaps the repository is empty.";
 814         }
 815
 816         if (defined $_commit_url) {
 817                 $url = $_commit_url;
 818         } else {
 819                 $url = eval { command_oneline('config', '--get',
 820                               "svn-remote.$gs->{repo_id}.commiturl") };
 821                 if (!$url) {
 822                         $url = $gs->full_pushurl
 823                 }
 824         }
 825
 826         my $last_rev = $_revision if defined $_revision;
 827         if ($url) {
 828                 print "Committing to $url ...\n";
 829         }
 830         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 831         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 832                 warn "Attempting to commit more than one change while ",
 833                      "--no-rebase is enabled.\n",
 834                      "If these changes depend on each other, re-running ",
 835                      "without --no-rebase may be required."
 836         }
 837
 838         if (defined $_interactive){
 839                 my $ask_default = "y";
 840                 foreach my $d (@$linear_refs){
 841                         my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 842                         while (<$fh>){
 843                                 print $_;
 844                         }
 845                         command_close_pipe($fh, $ctx);
 846                         $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 847                                  valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 848                                  default => $ask_default);
 849                         die "Commit this patch reply required" unless defined $_;
 850                         if (/^[nq]/i) {
 851                                 exit(0);
 852                         } elsif (/^a/i) {
 853                                 last;
 854                         }
 855                 }
 856         }
 857
 858         my $expect_url = $url;
 859
 860         my $push_merge_info = eval {
 861                 command_oneline(qw/config --get svn.pushmergeinfo/)
 862                 };
 863         if (not defined($push_merge_info)
 864                         or $push_merge_info eq "false"
 865                         or $push_merge_info eq "no"
 866                         or $push_merge_info eq "never") {
 867                 $push_merge_info = 0;
 868         }
 869
 870         unless (defined($_merge_info) || ! $push_merge_info) {
 871                 # Preflight check of changes to ensure no issues with mergeinfo
 872                 # This includes check for uncommitted-to-SVN parents
 873                 # (other than the first parent, which we will handle),
 874                 # information from different SVN repos, and paths
 875                 # which are not underneath this repository root.
 876                 my $rooturl = $gs->repos_root;
 877                 foreach my $d (@$linear_refs) {
 878                         my %parentshash;
 879                         read_commit_parents(\%parentshash, $d);
 880                         my @realparents = @{$parentshash{$d}};
 881                         if ($#realparents > 0) {
 882                                 # Merge commit
 883                                 shift @realparents; # Remove/ignore first parent
 884                                 foreach my $parent (@realparents) {
 885                                         my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 886                                         unless (defined $paruuid) {
 887                                                 # A parent is missing SVN annotations...
 888                                                 # abort the whole operation.
 889                                                 fatal "$parent is merged into revision $d, "
 890                                                          ."but does not have git-svn metadata. "
 891                                                          ."Either dcommit the branch or use a "
 892                                                          ."local cherry-pick, FF merge, or rebase "
 893                                                          ."instead of an explicit merge commit.";
 894                                         }
 895
 896                                         unless ($paruuid eq $uuid) {
 897                                                 # Parent has SVN metadata from different repository
 898                                                 fatal "merge parent $parent for change $d has "
 899                                                          ."git-svn uuid $paruuid, while current change "
 900                                                          ."has uuid $uuid!";
 901                                         }
 902
 903                                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 904                                                 # This branch is very strange indeed.
 905                                                 fatal "merge parent $parent for $d is on branch "
 906                                                          ."$branchurl, which is not under the "
 907                                                          ."git-svn root $rooturl!";
 908                                         }
 909                                 }
 910                         }
 911                 }
 912         }
 913
 914         my $rewritten_parent;
 915         Git::SVN::remove_username($expect_url);
 916         if (defined($_merge_info)) {
 917                 $_merge_info =~ tr{ }{\n};
 918         }
 919         while (1) {
 920                 my $d = shift @$linear_refs or last;
 921                 unless (defined $last_rev) {
 922                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 923                         unless (defined $last_rev) {
 924                                 fatal "Unable to extract revision information ",
 925                                       "from commit $d~1";
 926                         }
 927                 }
 928                 if ($_dry_run) {
 929                         print "diff-tree $d~1 $d\n";
 930                 } else {
 931                         my $cmt_rev;
 932
 933                         unless (defined($_merge_info) || ! $push_merge_info) {
 934                                 $_merge_info = populate_merge_info($d, $gs,
 935                                                              $uuid,
 936                                                              $linear_refs,
 937                                                              $rewritten_parent);
 938                         }
 939
 940                         my %ed_opts = ( r => $last_rev,
 941                                         log => get_commit_entry($d)->{log},
 942                                         ra => Git::SVN::Ra->new($url),
 943                                         config => SVN::Core::config_get_config(
 944                                                 $Git::SVN::Ra::config_dir
 945                                         ),
 946                                         tree_a => "$d~1",
 947                                         tree_b => $d,
 948                                         editor_cb => sub {
 949                                                print "Committed r$_[0]\n";
 950                                                $cmt_rev = $_[0];
 951                                         },
 952                                         mergeinfo => $_merge_info,
 953                                         svn_path => '');
 954                         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
 955                                 print "No changes\n$d~1 == $d\n";
 956                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 957                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 958                                                                $parents->{$d};
 959                         }
 960                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 961                         $last_rev = $cmt_rev;
 962                         next if $_no_rebase;
 963
 964                         # we always want to rebase against the current HEAD,
 965                         # not any head that was passed to us
 966                         my @diff = command('diff-tree', $d,
 967                                            $gs->refname, '--');
 968                         my @finish;
 969                         if (@diff) {
 970                                 @finish = rebase_cmd();
 971                                 print STDERR "W: $d and ", $gs->refname,
 972                                              " differ, using @finish:\n",
 973                                              join("\n", @diff), "\n";
 974                         } else {
 975                                 print "No changes between current HEAD and ",
 976                                       $gs->refname,
 977                                       "\nResetting to the latest ",
 978                                       $gs->refname, "\n";
 979                                 @finish = qw/reset --mixed/;
 980                         }
 981                         command_noisy(@finish, $gs->refname);
 982
 983                         $rewritten_parent = command_oneline(qw/rev-parse HEAD/);
 984
 985                         if (@diff) {
 986                                 @refs = ();
 987                                 my ($url_, $rev_, $uuid_, $gs_) =
 988                                               working_head_info('HEAD', \@refs);
 989                                 my ($linear_refs_, $parents_) =
 990                                               linearize_history($gs_, \@refs);
 991                                 if (scalar(@$linear_refs) !=
 992                                     scalar(@$linear_refs_)) {
 993                                         fatal "# of revisions changed ",
 994                                           "\nbefore:\n",
 995                                           join("\n", @$linear_refs),
 996                                           "\n\nafter:\n",
 997                                           join("\n", @$linear_refs_), "\n",
 998                                           'If you are attempting to commit ',
 999                                           "merges, try running:\n\t",
1000                                           'git rebase --interactive',
1001                                           '--preserve-merges ',
1002                                           $gs->refname,
1003                                           "\nBefore dcommitting";
1004                                 }
1005                                 if ($url_ ne $expect_url) {
1006                                         if ($url_ eq $gs->metadata_url) {
1007                                                 print
1008                                                   "Accepting rewritten URL:",
1009                                                   " $url_\n";
1010                                         } else {
1011                                                 fatal
1012                                                   "URL mismatch after rebase:",
1013                                                   " $url_ != $expect_url";
1014                                         }
1015                                 }
1016                                 if ($uuid_ ne $uuid) {
1017                                         fatal "uuid mismatch after rebase: ",
1018                                               "$uuid_ != $uuid";
1019                                 }
1020                                 # remap parents
1021                                 my (%p, @l, $i);
1022                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1023                                         my $new = $linear_refs_->[$i] or next;
1024                                         $p{$new} =
1025                                                 $parents->{$linear_refs->[$i]};
1026                                         push @l, $new;
1027                                 }
1028                                 $parents = \%p;
1029                                 $linear_refs = \@l;
1030                         }
1031                 }
1032         }
1033
1034         if ($old_head) {
1035                 my $new_head = command_oneline(qw/rev-parse HEAD/);
1036                 my $new_is_symbolic = eval {
1037                         command_oneline(qw/symbolic-ref -q HEAD/);
1038                 };
1039                 if ($new_is_symbolic) {
1040                         print "dcommitted the branch ", $head, "\n";
1041                 } else {
1042                         print "dcommitted on a detached HEAD because you gave ",
1043                               "a revision argument.\n",
1044                               "The rewritten commit is: ", $new_head, "\n";
1045                 }
1046                 command(['checkout', $old_head], STDERR => 0);
1047         }
1048
1049         unlink $gs->{index};
1050 }
1051
1052 sub cmd_branch {
1053         my ($branch_name, $head) = @_;
1054
1055         unless (defined $branch_name && length $branch_name) {
1056                 die(($_tag ? "tag" : "branch") . " name required\n");
1057         }
1058         $head ||= 'HEAD';
1059
1060         my (undef, $rev, undef, $gs) = working_head_info($head);
1061         my $src = $gs->full_pushurl;
1062
1063         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1064         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1065         my $glob;
1066         if ($#{$allglobs} == 0) {
1067                 $glob = $allglobs->[0];
1068         } else {
1069                 unless(defined $_branch_dest) {
1070                         die "Multiple ",
1071                             $_tag ? "tag" : "branch",
1072                             " paths defined for Subversion repository.\n",
1073                             "You must specify where you want to create the ",
1074                             $_tag ? "tag" : "branch",
1075                             " with the --destination argument.\n";
1076                 }
1077                 foreach my $g (@{$allglobs}) {
1078                         my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1079                         if ($_branch_dest =~ /$re/) {
1080                                 $glob = $g;
1081                                 last;
1082                         }
1083                 }
1084                 unless (defined $glob) {
1085                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1086                         foreach my $g (@{$allglobs}) {
1087                                 $g->{path}->{left} =~ /$dest_re/ or next;
1088                                 if (defined $glob) {
1089                                         die "Ambiguous destination: ",
1090                                             $_branch_dest, "\nmatches both '",
1091                                             $glob->{path}->{left}, "' and '",
1092                                             $g->{path}->{left}, "'\n";
1093                                 }
1094                                 $glob = $g;
1095                         }
1096                         unless (defined $glob) {
1097                                 die "Unknown ",
1098                                     $_tag ? "tag" : "branch",
1099                                     " destination $_branch_dest\n";
1100                         }
1101                 }
1102         }
1103         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1104         my $url;
1105         if (defined $_commit_url) {
1106                 $url = $_commit_url;
1107         } else {
1108                 $url = eval { command_oneline('config', '--get',
1109                         "svn-remote.$gs->{repo_id}.commiturl") };
1110                 if (!$url) {
1111                         $url = $remote->{pushurl} || $remote->{url};
1112                 }
1113         }
1114         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1115
1116         if ($dst =~ /^https:/ && $src =~ /^http:/) {
1117                 $src=~s/^http:/https:/;
1118         }
1119
1120         ::_req_svn();
1121
1122         my $ctx = SVN::Client->new(
1123                 auth    => Git::SVN::Ra::_auth_providers(),
1124                 log_msg => sub {
1125                         ${ $_[0] } = defined $_message
1126                                 ? $_message
1127                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1128                                 . $branch_name;
1129                 },
1130         );
1131
1132         eval {
1133                 $ctx->ls($dst, 'HEAD', 0);
1134         } and die "branch ${branch_name} already exists\n";
1135
1136         print "Copying ${src} at r${rev} to ${dst}...\n";
1137         $ctx->copy($src, $rev, $dst)
1138                 unless $_dry_run;
1139
1140         $gs->fetch_all;
1141 }
1142
1143 sub cmd_find_rev {
1144         my $revision_or_hash = shift or die "SVN or git revision required ",
1145                                             "as a command-line argument\n";
1146         my $result;
1147         if ($revision_or_hash =~ /^r\d+$/) {
1148                 my $head = shift;
1149                 $head ||= 'HEAD';
1150                 my @refs;
1151                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1152                 unless ($gs) {
1153                         die "Unable to determine upstream SVN information from ",
1154                             "$head history\n";
1155                 }
1156                 my $desired_revision = substr($revision_or_hash, 1);
1157                 $result = $gs->rev_map_get($desired_revision, $uuid);
1158         } else {
1159                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1160                 $result = $rev;
1161         }
1162         print "$result\n" if $result;
1163 }
1164
1165 sub auto_create_empty_directories {
1166         my ($gs) = @_;
1167         my $var = eval { command_oneline('config', '--get', '--bool',
1168                                          "svn-remote.$gs->{repo_id}.automkdirs") };
1169         # By default, create empty directories by consulting the unhandled log,
1170         # but allow setting it to 'false' to skip it.
1171         return !($var && $var eq 'false');
1172 }
1173
1174 sub cmd_rebase {
1175         command_noisy(qw/update-index --refresh/);
1176         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1177         unless ($gs) {
1178                 die "Unable to determine upstream SVN information from ",
1179                     "working tree history\n";
1180         }
1181         if ($_dry_run) {
1182                 print "Remote Branch: " . $gs->refname . "\n";
1183                 print "SVN URL: " . $url . "\n";
1184                 return;
1185         }
1186         if (command(qw/diff-index HEAD --/)) {
1187                 print STDERR "Cannot rebase with uncommited changes:\n";
1188                 command_noisy('status');
1189                 exit 1;
1190         }
1191         unless ($_local) {
1192                 # rebase will checkout for us, so no need to do it explicitly
1193                 $_no_checkout = 'true';
1194                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1195         }
1196         command_noisy(rebase_cmd(), $gs->refname);
1197         if (auto_create_empty_directories($gs)) {
1198                 $gs->mkemptydirs;
1199         }
1200 }
1201
1202 sub cmd_show_ignore {
1203         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1204         $gs ||= Git::SVN->new;
1205         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1206         $gs->prop_walk($gs->path, $r, sub {
1207                 my ($gs, $path, $props) = @_;
1208                 print STDOUT "\n# $path\n";
1209                 my $s = $props->{'svn:ignore'} or return;
1210                 $s =~ s/[\r\n]+/\n/g;
1211                 $s =~ s/^\n+//;
1212                 chomp $s;
1213                 $s =~ s#^#$path#gm;
1214                 print STDOUT "$s\n";
1215         });
1216 }
1217
1218 sub cmd_show_externals {
1219         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1220         $gs ||= Git::SVN->new;
1221         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1222         $gs->prop_walk($gs->path, $r, sub {
1223                 my ($gs, $path, $props) = @_;
1224                 print STDOUT "\n# $path\n";
1225                 my $s = $props->{'svn:externals'} or return;
1226                 $s =~ s/[\r\n]+/\n/g;
1227                 chomp $s;
1228                 $s =~ s#^#$path#gm;
1229                 print STDOUT "$s\n";
1230         });
1231 }
1232
1233 sub cmd_create_ignore {
1234         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1235         $gs ||= Git::SVN->new;
1236         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1237         $gs->prop_walk($gs->path, $r, sub {
1238                 my ($gs, $path, $props) = @_;
1239                 # $path is of the form /path/to/dir/
1240                 $path = '.' . $path;
1241                 # SVN can have attributes on empty directories,
1242                 # which git won't track
1243                 mkpath([$path]) unless -d $path;
1244                 my $ignore = $path . '.gitignore';
1245                 my $s = $props->{'svn:ignore'} or return;
1246                 open(GITIGNORE, '>', $ignore)
1247                   or fatal("Failed to open `$ignore' for writing: $!");
1248                 $s =~ s/[\r\n]+/\n/g;
1249                 $s =~ s/^\n+//;
1250                 chomp $s;
1251                 # Prefix all patterns so that the ignore doesn't apply
1252                 # to sub-directories.
1253                 $s =~ s#^#/#gm;
1254                 print GITIGNORE "$s\n";
1255                 close(GITIGNORE)
1256                   or fatal("Failed to close `$ignore': $!");
1257                 command_noisy('add', '-f', $ignore);
1258         });
1259 }
1260
1261 sub cmd_mkdirs {
1262         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1263         $gs ||= Git::SVN->new;
1264         $gs->mkemptydirs($_revision);
1265 }
1266
1267 # get_svnprops(PATH)
1268 # ------------------
1269 # Helper for cmd_propget and cmd_proplist below.
1270 sub get_svnprops {
1271         my $path = shift;
1272         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1273         $gs ||= Git::SVN->new;
1274
1275         # prefix THE PATH by the sub-directory from which the user
1276         # invoked us.
1277         $path = $cmd_dir_prefix . $path;
1278         fatal("No such file or directory: $path") unless -e $path;
1279         my $is_dir = -d $path ? 1 : 0;
1280         $path = join_paths($gs->{path}, $path);
1281
1282         # canonicalize the path (otherwise libsvn will abort or fail to
1283         # find the file)
1284         $path = canonicalize_path($path);
1285
1286         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1287         my $props;
1288         if ($is_dir) {
1289                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1290         }
1291         else {
1292                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1293         }
1294         return $props;
1295 }
1296
1297 # cmd_propget (PROP, PATH)
1298 # ------------------------
1299 # Print the SVN property PROP for PATH.
1300 sub cmd_propget {
1301         my ($prop, $path) = @_;
1302         $path = '.' if not defined $path;
1303         usage(1) if not defined $prop;
1304         my $props = get_svnprops($path);
1305         if (not defined $props->{$prop}) {
1306                 fatal("`$path' does not have a `$prop' SVN property.");
1307         }
1308         print $props->{$prop} . "\n";
1309 }
1310
1311 # cmd_proplist (PATH)
1312 # -------------------
1313 # Print the list of SVN properties for PATH.
1314 sub cmd_proplist {
1315         my $path = shift;
1316         $path = '.' if not defined $path;
1317         my $props = get_svnprops($path);
1318         print "Properties on '$path':\n";
1319         foreach (sort keys %{$props}) {
1320                 print "  $_\n";
1321         }
1322 }
1323
1324 sub cmd_multi_init {
1325         my $url = shift;
1326         unless (defined $_trunk || @_branches || @_tags) {
1327                 usage(1);
1328         }
1329
1330         $_prefix = '' unless defined $_prefix;
1331         if (defined $url) {
1332                 $url = canonicalize_url($url);
1333                 init_subdir(@_);
1334         }
1335         do_git_init_db();
1336         if (defined $_trunk) {
1337                 $_trunk =~ s#^/+##;
1338                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1339                 # try both old-style and new-style lookups:
1340                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1341                 unless ($gs_trunk) {
1342                         my ($trunk_url, $trunk_path) =
1343                                               complete_svn_url($url, $_trunk);
1344                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1345                                                    undef, $trunk_ref);
1346                 }
1347         }
1348         return unless @_branches || @_tags;
1349         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1350         foreach my $path (@_branches) {
1351                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1352         }
1353         foreach my $path (@_tags) {
1354                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1355         }
1356 }
1357
1358 sub cmd_multi_fetch {
1359         $Git::SVN::no_reuse_existing = undef;
1360         my $remotes = Git::SVN::read_all_remotes();
1361         foreach my $repo_id (sort keys %$remotes) {
1362                 if ($remotes->{$repo_id}->{url}) {
1363                         Git::SVN::fetch_all($repo_id, $remotes);
1364                 }
1365         }
1366 }
1367
1368 # this command is special because it requires no metadata
1369 sub cmd_commit_diff {
1370         my ($ta, $tb, $url) = @_;
1371         my $usage = "Usage: $0 commit-diff -r<revision> ".
1372                     "<tree-ish> <tree-ish> [<URL>]";
1373         fatal($usage) if (!defined $ta || !defined $tb);
1374         my $svn_path = '';
1375         if (!defined $url) {
1376                 my $gs = eval { Git::SVN->new };
1377                 if (!$gs) {
1378                         fatal("Needed URL or usable git-svn --id in ",
1379                               "the command-line\n", $usage);
1380                 }
1381                 $url = $gs->url;
1382                 $svn_path = $gs->path;
1383         }
1384         unless (defined $_revision) {
1385                 fatal("-r|--revision is a required argument\n", $usage);
1386         }
1387         if (defined $_message && defined $_file) {
1388                 fatal("Both --message/-m and --file/-F specified ",
1389                       "for the commit message.\n",
1390                       "I have no idea what you mean");
1391         }
1392         if (defined $_file) {
1393                 $_message = file_to_s($_file);
1394         } else {
1395                 $_message ||= get_commit_entry($tb)->{log};
1396         }
1397         my $ra ||= Git::SVN::Ra->new($url);
1398         my $r = $_revision;
1399         if ($r eq 'HEAD') {
1400                 $r = $ra->get_latest_revnum;
1401         } elsif ($r !~ /^\d+$/) {
1402                 die "revision argument: $r not understood by git-svn\n";
1403         }
1404         my %ed_opts = ( r => $r,
1405                         log => $_message,
1406                         ra => $ra,
1407                         tree_a => $ta,
1408                         tree_b => $tb,
1409                         editor_cb => sub { print "Committed r$_[0]\n" },
1410                         svn_path => $svn_path );
1411         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1412                 print "No changes\n$ta == $tb\n";
1413         }
1414 }
1415
1416
1417 sub cmd_info {
1418         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1419         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1420         if (exists $_[1]) {
1421                 die "Too many arguments specified\n";
1422         }
1423
1424         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1425
1426         if (!$file_type && !$diff_status) {
1427                 print STDERR "svn: '$path' is not under version control\n";
1428                 exit 1;
1429         }
1430
1431         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1432         unless ($gs) {
1433                 die "Unable to determine upstream SVN information from ",
1434                     "working tree history\n";
1435         }
1436
1437         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1438         $path = "." if $path eq "";
1439
1440         my $full_url = canonicalize_url( add_path_to_url( $url, $fullpath ) );
1441
1442         if ($_url) {
1443                 print "$full_url\n";
1444                 return;
1445         }
1446
1447         my $result = "Path: $path\n";
1448         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1449         $result .= "URL: $full_url\n";
1450
1451         eval {
1452                 my $repos_root = $gs->repos_root;
1453                 Git::SVN::remove_username($repos_root);
1454                 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1455         };
1456         if ($@) {
1457                 $result .= "Repository Root: (offline)\n";
1458         }
1459         ::_req_svn();
1460         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1461                 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1462         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1463
1464         $result .= "Node Kind: " .
1465                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1466
1467         my $schedule = $diff_status eq "A"
1468                        ? "add"
1469                        : ($diff_status eq "D" ? "delete" : "normal");
1470         $result .= "Schedule: $schedule\n";
1471
1472         if ($diff_status eq "A") {
1473                 print $result, "\n";
1474                 return;
1475         }
1476
1477         my ($lc_author, $lc_rev, $lc_date_utc);
1478         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1479         my $log = command_output_pipe(@args);
1480         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1481         while (<$log>) {
1482                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1483                         $lc_author = $1;
1484                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1485                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1486                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1487                 }
1488         }
1489         close $log;
1490
1491         Git::SVN::Log::set_local_timezone();
1492
1493         $result .= "Last Changed Author: $lc_author\n";
1494         $result .= "Last Changed Rev: $lc_rev\n";
1495         $result .= "Last Changed Date: " .
1496                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1497
1498         if ($file_type ne "dir") {
1499                 my $text_last_updated_date =
1500                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1501                 $result .=
1502                     "Text Last Updated: " .
1503                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1504                     "\n";
1505                 my $checksum;
1506                 if ($diff_status eq "D") {
1507                         my ($fh, $ctx) =
1508                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1509                         if ($file_type eq "link") {
1510                                 my $file_name = <$fh>;
1511                                 $checksum = md5sum("link $file_name");
1512                         } else {
1513                                 $checksum = md5sum($fh);
1514                         }
1515                         command_close_pipe($fh, $ctx);
1516                 } elsif ($file_type eq "link") {
1517                         my $file_name =
1518                             command(qw(cat-file blob), "HEAD:$path");
1519                         $checksum =
1520                             md5sum("link " . $file_name);
1521                 } else {
1522                         open FILE, "<", $path or die $!;
1523                         $checksum = md5sum(\*FILE);
1524                         close FILE or die $!;
1525                 }
1526                 $result .= "Checksum: " . $checksum . "\n";
1527         }
1528
1529         print $result, "\n";
1530 }
1531
1532 sub cmd_reset {
1533         my $target = shift || $_revision or die "SVN revision required\n";
1534         $target = $1 if $target =~ /^r(\d+)$/;
1535         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1536         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1537         unless ($gs) {
1538                 die "Unable to determine upstream SVN information from ".
1539                     "history\n";
1540         }
1541         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1542         die "Cannot find SVN revision $target\n" unless defined($c);
1543         $gs->rev_map_set($r, $c, 'reset', $uuid);
1544         print "r$r = $c ($gs->{ref_id})\n";
1545 }
1546
1547 sub cmd_gc {
1548         if (!can_compress()) {
1549                 warn "Compress::Zlib could not be found; unhandled.log " .
1550                      "files will not be compressed.\n";
1551         }
1552         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1553 }
1554
1555 ########################### utility functions #########################
1556
1557 sub rebase_cmd {
1558         my @cmd = qw/rebase/;
1559         push @cmd, '-v' if $_verbose;
1560         push @cmd, qw/--merge/ if $_merge;
1561         push @cmd, "--strategy=$_strategy" if $_strategy;
1562         push @cmd, "--preserve-merges" if $_preserve_merges;
1563         @cmd;
1564 }
1565
1566 sub post_fetch_checkout {
1567         return if $_no_checkout;
1568         return if verify_ref('HEAD^0');
1569         my $gs = $Git::SVN::_head or return;
1570
1571         # look for "trunk" ref if it exists
1572         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1573         my $fetch = $remote->{fetch};
1574         if ($fetch) {
1575                 foreach my $p (keys %$fetch) {
1576                         basename($fetch->{$p}) eq 'trunk' or next;
1577                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1578                         last;
1579                 }
1580         }
1581
1582         command_noisy(qw(update-ref HEAD), $gs->refname);
1583         return unless verify_ref('HEAD^0');
1584
1585         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1586         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1587         return if -f $index;
1588
1589         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1590         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1591         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1592         print STDERR "Checked out HEAD:\n  ",
1593                      $gs->full_url, " r", $gs->last_rev, "\n";
1594         if (auto_create_empty_directories($gs)) {
1595                 $gs->mkemptydirs($gs->last_rev);
1596         }
1597 }
1598
1599 sub complete_svn_url {
1600         my ($url, $path) = @_;
1601         $path =~ s#/+$##;
1602
1603         # If the path is not a URL...
1604         if ($path !~ m#^[a-z\+]+://#) {
1605                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1606                         fatal("E: '$path' is not a complete URL ",
1607                               "and a separate URL is not specified");
1608                 }
1609                 return ($url, $path);
1610         }
1611         return ($path, '');
1612 }
1613
1614 sub complete_url_ls_init {
1615         my ($ra, $repo_path, $switch, $pfx) = @_;
1616         unless ($repo_path) {
1617                 print STDERR "W: $switch not specified\n";
1618                 return;
1619         }
1620         $repo_path =~ s#/+$##;
1621         if ($repo_path =~ m#^[a-z\+]+://#) {
1622                 $ra = Git::SVN::Ra->new($repo_path);
1623                 $repo_path = '';
1624         } else {
1625                 $repo_path =~ s#^/+##;
1626                 unless ($ra) {
1627                         fatal("E: '$repo_path' is not a complete URL ",
1628                               "and a separate URL is not specified");
1629                 }
1630         }
1631         my $url = $ra->url;
1632         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1633         my $k = "svn-remote.$gs->{repo_id}.url";
1634         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1635         if ($orig_url && ($orig_url ne $gs->url)) {
1636                 die "$k already set: $orig_url\n",
1637                     "wanted to set to: $gs->url\n";
1638         }
1639         command_oneline('config', $k, $gs->url) unless $orig_url;
1640
1641         my $remote_path = $gs->path . "/$repo_path";
1642         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1643         $remote_path =~ s#/+#/#g;
1644         $remote_path =~ s#^/##g;
1645         $remote_path .= "/*" if $remote_path !~ /\*/;
1646         my ($n) = ($switch =~ /^--(\w+)/);
1647         if (length $pfx && $pfx !~ m#/$#) {
1648                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1649         }
1650         command_noisy('config',
1651                       '--add',
1652                       "svn-remote.$gs->{repo_id}.$n",
1653                       "$remote_path:refs/remotes/$pfx*" .
1654                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1655 }
1656
1657 sub verify_ref {
1658         my ($ref) = @_;
1659         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1660                                { STDERR => 0 }); };
1661 }
1662
1663 sub get_tree_from_treeish {
1664         my ($treeish) = @_;
1665         # $treeish can be a symbolic ref, too:
1666         my $type = command_oneline(qw/cat-file -t/, $treeish);
1667         my $expected;
1668         while ($type eq 'tag') {
1669                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1670         }
1671         if ($type eq 'commit') {
1672                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1673                                                     $treeish))[0];
1674                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1675                 die "Unable to get tree from $treeish\n" unless $expected;
1676         } elsif ($type eq 'tree') {
1677                 $expected = $treeish;
1678         } else {
1679                 die "$treeish is a $type, expected tree, tag or commit\n";
1680         }
1681         return $expected;
1682 }
1683
1684 sub get_commit_entry {
1685         my ($treeish) = shift;
1686         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1687         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1688         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1689         open my $log_fh, '>', $commit_editmsg or croak $!;
1690
1691         my $type = command_oneline(qw/cat-file -t/, $treeish);
1692         if ($type eq 'commit' || $type eq 'tag') {
1693                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1694                                                          $type, $treeish);
1695                 my $in_msg = 0;
1696                 my $author;
1697                 my $saw_from = 0;
1698                 my $msgbuf = "";
1699                 while (<$msg_fh>) {
1700                         if (!$in_msg) {
1701                                 $in_msg = 1 if (/^\s*$/);
1702                                 $author = $1 if (/^author (.*>)/);
1703                         } elsif (/^git-svn-id: /) {
1704                                 # skip this for now, we regenerate the
1705                                 # correct one on re-fetch anyways
1706                                 # TODO: set *:merge properties or like...
1707                         } else {
1708                                 if (/^From:/ || /^Signed-off-by:/) {
1709                                         $saw_from = 1;
1710                                 }
1711                                 $msgbuf .= $_;
1712                         }
1713                 }
1714                 $msgbuf =~ s/\s+$//s;
1715                 if ($Git::SVN::_add_author_from && defined($author)
1716                     && !$saw_from) {
1717                         $msgbuf .= "\n\nFrom: $author";
1718                 }
1719                 print $log_fh $msgbuf or croak $!;
1720                 command_close_pipe($msg_fh, $ctx);
1721         }
1722         close $log_fh or croak $!;
1723
1724         if ($_edit || ($type eq 'tree')) {
1725                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1726                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1727         }
1728         rename $commit_editmsg, $commit_msg or croak $!;
1729         {
1730                 require Encode;
1731                 # SVN requires messages to be UTF-8 when entering the repo
1732                 local $/;
1733                 open $log_fh, '<', $commit_msg or croak $!;
1734                 binmode $log_fh;
1735                 chomp($log_entry{log} = <$log_fh>);
1736
1737                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1738                 my $msg = $log_entry{log};
1739
1740                 eval { $msg = Encode::decode($enc, $msg, 1) };
1741                 if ($@) {
1742                         die "Could not decode as $enc:\n", $msg,
1743                             "\nPerhaps you need to set i18n.commitencoding\n";
1744                 }
1745
1746                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1747                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1748
1749                 $log_entry{log} = $msg;
1750
1751                 close $log_fh or croak $!;
1752         }
1753         unlink $commit_msg;
1754         \%log_entry;
1755 }
1756
1757 sub s_to_file {
1758         my ($str, $file, $mode) = @_;
1759         open my $fd,'>',$file or croak $!;
1760         print $fd $str,"\n" or croak $!;
1761         close $fd or croak $!;
1762         chmod ($mode &~ umask, $file) if (defined $mode);
1763 }
1764
1765 sub file_to_s {
1766         my $file = shift;
1767         open my $fd,'<',$file or croak "$!: file: $file\n";
1768         local $/;
1769         my $ret = <$fd>;
1770         close $fd or croak $!;
1771         $ret =~ s/\s*$//s;
1772         return $ret;
1773 }
1774
1775 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1776 sub load_authors {
1777         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1778         my $log = $cmd eq 'log';
1779         while (<$authors>) {
1780                 chomp;
1781                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1782                 my ($user, $name, $email) = ($1, $2, $3);
1783                 if ($log) {
1784                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1785                 } else {
1786                         $users{$user} = [$name, $email];
1787                 }
1788         }
1789         close $authors or croak $!;
1790 }
1791
1792 # convert GetOpt::Long specs for use by git-config
1793 sub read_git_config {
1794         my $opts = shift;
1795         my @config_only;
1796         foreach my $o (keys %$opts) {
1797                 # if we have mixedCase and a long option-only, then
1798                 # it's a config-only variable that we don't need for
1799                 # the command-line.
1800                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1801                 my $v = $opts->{$o};
1802                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1803                 $key =~ s/-//g;
1804                 my $arg = 'git config';
1805                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1806                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1807                 if (ref $v eq 'ARRAY') {
1808                         chomp(my @tmp = `$arg --get-all svn.$key`);
1809                         @$v = @tmp if @tmp;
1810                 } else {
1811                         chomp(my $tmp = `$arg --get svn.$key`);
1812                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1813                                 $$v = $tmp;
1814                         }
1815                 }
1816         }
1817         delete @$opts{@config_only} if @config_only;
1818 }
1819
1820 sub extract_metadata {
1821         my $id = shift or return (undef, undef, undef);
1822         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1823                                                         \s([a-f\d\-]+)$/ix);
1824         if (!defined $rev || !$uuid || !$url) {
1825                 # some of the original repositories I made had
1826                 # identifiers like this:
1827                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1828         }
1829         return ($url, $rev, $uuid);
1830 }
1831
1832 sub cmt_metadata {
1833         return extract_metadata((grep(/^git-svn-id: /,
1834                 command(qw/cat-file commit/, shift)))[-1]);
1835 }
1836
1837 sub cmt_sha2rev_batch {
1838         my %s2r;
1839         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1840         my $list = shift;
1841
1842         foreach my $sha (@{$list}) {
1843                 my $first = 1;
1844                 my $size = 0;
1845                 print $out $sha, "\n";
1846
1847                 while (my $line = <$in>) {
1848                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1849                                 last;
1850                         } elsif ($first &&
1851                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1852                                 $first = 0;
1853                                 $size = $1;
1854                                 next;
1855                         } elsif ($line =~ /^(git-svn-id: )/) {
1856                                 my (undef, $rev, undef) =
1857                                                       extract_metadata($line);
1858                                 $s2r{$sha} = $rev;
1859                         }
1860
1861                         $size -= length($line);
1862                         last if ($size == 0);
1863                 }
1864         }
1865
1866         command_close_bidi_pipe($pid, $in, $out, $ctx);
1867
1868         return \%s2r;
1869 }
1870
1871 sub working_head_info {
1872         my ($head, $refs) = @_;
1873         my @args = qw/rev-list --first-parent --pretty=medium/;
1874         my ($fh, $ctx) = command_output_pipe(@args, $head);
1875         my $hash;
1876         my %max;
1877         while (<$fh>) {
1878                 if ( m{^commit ($::sha1)$} ) {
1879                         unshift @$refs, $hash if $hash and $refs;
1880                         $hash = $1;
1881                         next;
1882                 }
1883                 next unless s{^\s*(git-svn-id:)}{$1};
1884                 my ($url, $rev, $uuid) = extract_metadata($_);
1885                 if (defined $url && defined $rev) {
1886                         next if $max{$url} and $max{$url} < $rev;
1887                         if (my $gs = Git::SVN->find_by_url($url)) {
1888                                 my $c = $gs->rev_map_get($rev, $uuid);
1889                                 if ($c && $c eq $hash) {
1890                                         close $fh; # break the pipe
1891                                         return ($url, $rev, $uuid, $gs);
1892                                 } else {
1893                                         $max{$url} ||= $gs->rev_map_max;
1894                                 }
1895                         }
1896                 }
1897         }
1898         command_close_pipe($fh, $ctx);
1899         (undef, undef, undef, undef);
1900 }
1901
1902 sub read_commit_parents {
1903         my ($parents, $c) = @_;
1904         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1905         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1906         @{$parents->{$c}} = split(/ /, $p);
1907 }
1908
1909 sub linearize_history {
1910         my ($gs, $refs) = @_;
1911         my %parents;
1912         foreach my $c (@$refs) {
1913                 read_commit_parents(\%parents, $c);
1914         }
1915
1916         my @linear_refs;
1917         my %skip = ();
1918         my $last_svn_commit = $gs->last_commit;
1919         foreach my $c (reverse @$refs) {
1920                 next if $c eq $last_svn_commit;
1921                 last if $skip{$c};
1922
1923                 unshift @linear_refs, $c;
1924                 $skip{$c} = 1;
1925
1926                 # we only want the first parent to diff against for linear
1927                 # history, we save the rest to inject when we finalize the
1928                 # svn commit
1929                 my $fp_a = verify_ref("$c~1");
1930                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1931                 if (!$fp_a || !$fp_b) {
1932                         die "Commit $c\n",
1933                             "has no parent commit, and therefore ",
1934                             "nothing to diff against.\n",
1935                             "You should be working from a repository ",
1936                             "originally created by git-svn\n";
1937                 }
1938                 if ($fp_a ne $fp_b) {
1939                         die "$c~1 = $fp_a, however parsing commit $c ",
1940                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1941                 }
1942
1943                 foreach my $p (@{$parents{$c}}) {
1944                         $skip{$p} = 1;
1945                 }
1946         }
1947         (\@linear_refs, \%parents);
1948 }
1949
1950 sub find_file_type_and_diff_status {
1951         my ($path) = @_;
1952         return ('dir', '') if $path eq '';
1953
1954         my $diff_output =
1955             command_oneline(qw(diff --cached --name-status --), $path) || "";
1956         my $diff_status = (split(' ', $diff_output))[0] || "";
1957
1958         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1959
1960         return (undef, undef) if !$diff_status && !$ls_tree;
1961
1962         if ($diff_status eq "A") {
1963                 return ("link", $diff_status) if -l $path;
1964                 return ("dir", $diff_status) if -d $path;
1965                 return ("file", $diff_status);
1966         }
1967
1968         my $mode = (split(' ', $ls_tree))[0] || "";
1969
1970         return ("link", $diff_status) if $mode eq "120000";
1971         return ("dir", $diff_status) if $mode eq "040000";
1972         return ("file", $diff_status);
1973 }
1974
1975 sub md5sum {
1976         my $arg = shift;
1977         my $ref = ref $arg;
1978         my $md5 = Digest::MD5->new();
1979         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1980                 $md5->addfile($arg) or croak $!;
1981         } elsif ($ref eq 'SCALAR') {
1982                 $md5->add($$arg) or croak $!;
1983         } elsif (!$ref) {
1984                 $md5->add($arg) or croak $!;
1985         } else {
1986                 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1987         }
1988         return $md5->hexdigest();
1989 }
1990
1991 sub gc_directory {
1992         if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
1993                 my $out_filename = $_ . ".gz";
1994                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1995                 binmode $in_fh;
1996                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1997                                 die "Unable to open $out_filename: $!\n";
1998
1999                 my $res;
2000                 while ($res = sysread($in_fh, my $str, 1024)) {
2001                         $gz->gzwrite($str) or
2002                                 die "Unable to write: ".$gz->gzerror()."!\n";
2003                 }
2004                 unlink $_ or die "unlink $File::Find::name: $!\n";
2005         } elsif (-f $_ && basename($_) eq "index") {
2006                 unlink $_ or die "unlink $_: $!\n";
2007         }
2008 }
2009
2010 __END__
2011
2012 Data structures:
2013
2014
2015 $remotes = { # returned by read_all_remotes()
2016         'svn' => {
2017                 # svn-remote.svn.url=https://svn.musicpd.org
2018                 url => 'https://svn.musicpd.org',
2019                 # svn-remote.svn.fetch=mpd/trunk:trunk
2020                 fetch => {
2021                         'mpd/trunk' => 'trunk',
2022                 },
2023                 # svn-remote.svn.tags=mpd/tags/*:tags/*
2024                 tags => {
2025                         path => {
2026                                 left => 'mpd/tags',
2027                                 right => '',
2028                                 regex => qr!mpd/tags/([^/]+)$!,
2029                                 glob => 'tags/*',
2030                         },
2031                         ref => {
2032                                 left => 'tags',
2033                                 right => '',
2034                                 regex => qr!tags/([^/]+)$!,
2035                                 glob => 'tags/*',
2036                         },
2037                 }
2038         }
2039 };
2040
2041 $log_entry hashref as returned by libsvn_log_entry()
2042 {
2043         log => 'whitespace-formatted log entry
2044 ',                                              # trailing newline is preserved
2045         revision => '8',                        # integer
2046         date => '2004-02-24T17:01:44.108345Z',  # commit date
2047         author => 'committer name'
2048 };
2049
2050
2051 # this is generated by generate_diff();
2052 @mods = array of diff-index line hashes, each element represents one line
2053         of diff-index output
2054
2055 diff-index line ($m hash)
2056 {
2057         mode_a => first column of diff-index output, no leading ':',
2058         mode_b => second column of diff-index output,
2059         sha1_b => sha1sum of the final blob,
2060         chg => change type [MCRADT],
2061         file_a => original file name of a file (iff chg is 'C' or 'R')
2062         file_b => new/current file name of a file (any chg)
2063 }
2064 ;
2065
2066 # retval of read_url_paths{,_all}();
2067 $l_map = {
2068         # repository root url
2069         'https://svn.musicpd.org' => {
2070                 # repository path               # GIT_SVN_ID
2071                 'mpd/trunk'             =>      'trunk',
2072                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2073         },
2074 }
2075
2076 Notes:
2077         I don't trust the each() function on unless I created %hash myself
2078         because the internal iterator may not have started at base.