git.oblomov.eu Git - git/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [1.4.1], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22
  23
  24 ## Checks for programs.
  25 AC_MSG_NOTICE([CHECKS for programs])
  26 #
  27 AC_PROG_CC
  28 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
  29 AC_CHECK_TOOL(AR, ar, :)
  30 AC_CHECK_PROGS(TAR, [gtar tar])
  31 #
  32 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
  33
  34
  35 ## Checks for libraries.
  36 AC_MSG_NOTICE([CHECKS for libraries])
  37 #
  38 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
  39 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
  40 AC_CHECK_LIB([ssl], [SHA1_Init],[],
  41 [AC_CHECK_LIB([crypto], [SHA1_INIT],
  42  [GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=YesPlease)],
  43  [GIT_CONF_APPEND_LINE(NO_OPENSSL=YesPlease)])])
  44 #
  45 # Define NO_CURL if you do not have curl installed.  git-http-pull and
  46 # git-http-push are not built, and you cannot use http:// and https://
  47 # transports.
  48 AC_CHECK_LIB([curl], [curl_global_init],[],
  49 [GIT_CONF_APPEND_LINE(NO_CURL=YesPlease)])
  50 #
  51 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
  52 # not built, and you cannot push using http:// and https:// transports.
  53 AC_CHECK_LIB([expat], [XML_ParserCreate],[],
  54 [GIT_CONF_APPEND_LINE(NO_EXPAT=YesPlease)])
  55 #
  56 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
  57 AC_CHECK_LIB([c], [iconv],[],
  58 [AC_CHECK_LIB([iconv],[iconv],
  59  [GIT_CONF_APPEND_LINE(NEEDS_LIBICONV=YesPlease)],[])])
  60 #
  61 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
  62 # Patrick Mauritz).
  63 AC_CHECK_LIB([c], [socket],[],
  64 [AC_CHECK_LIB([socket],[socket],
  65  [GIT_CONF_APPEND_LINE(NEEDS_SOCKET=YesPlease)],[])])
  66
  67
  68 ## Checks for header files.
  69
  70
  71 ## Checks for typedefs, structures, and compiler characteristics.
  72 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
  73 #
  74 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
  75 AC_CHECK_MEMBER(struct dirent.d_ino,[],
  76 [GIT_CONF_APPEND_LINE(NO_D_INO_IN_DIRENT=YesPlease)],
  77 [#include <dirent.h>])
  78 #
  79 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
  80 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
  81 AC_CHECK_MEMBER(struct dirent.d_type,[],
  82 [GIT_CONF_APPEND_LINE(NO_D_TYPE_IN_DIRENT=YesPlease)],
  83 [#include <dirent.h>])
  84 #
  85 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
  86 # sockaddr_storage.
  87 AC_CHECK_TYPE(struct sockaddr_storage,[],
  88 [GIT_CONF_APPEND_LINE(NO_SOCKADDR_STORAGE=YesPlease)],
  89 [#include <netinet/in.h>])
  90
  91
  92 ## Checks for library functions.
  93 ## (in default C library and libraries checked by AC_CHECK_LIB)
  94 AC_MSG_NOTICE([CHECKS for library functions])
  95 #
  96 # Define NO_STRCASESTR if you don't have strcasestr.
  97 AC_CHECK_FUNC(strcasestr,[],
  98 [GIT_CONF_APPEND_LINE(NO_STRCASESTR=YesPlease)])
  99 #
 100 # Define NO_STRLCPY if you don't have strlcpy.
 101 AC_CHECK_FUNC(strlcpy,[],
 102 [GIT_CONF_APPEND_LINE(NO_STRLCPY=YesPlease)])
 103 #
 104 # Define NO_SETENV if you don't have setenv in the C library.
 105 AC_CHECK_FUNC(setenv,[],
 106 [GIT_CONF_APPEND_LINE(NO_SETENV=YesPlease)])
 107 #
 108 # Define NO_MMAP if you want to avoid mmap.
 109 #
 110 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 111 #
 112 # Define NO_ICONV if your libc does not properly support iconv.
 113
 114
 115 ## Other checks.
 116 # Define USE_PIC if you need the main git objects to be built with -fPIC
 117 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 118 #
 119 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 120 # Enable it on Windows.  By default, symrefs are still used.
 121 #
 122 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 123 #
 124 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 125 # a missing newline at the end of the file.
 126
 127
 128 ## Site configuration
 129 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 130 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interopability
 131 # tests.  These tests take up a significant amount of the total test time
 132 # but are not needed unless you plan to talk to SVN repos.
 133 #
 134 # Define MOZILLA_SHA1 environment variable when running make to make use of
 135 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 136 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 137 # choice) has very fast version optimized for i586.
 138 #
 139 # Define PPC_SHA1 environment variable when running make to make use of
 140 # a bundled SHA1 routine optimized for PowerPC.
 141 #
 142 # Define ARM_SHA1 environment variable when running make to make use of
 143 # a bundled SHA1 routine optimized for ARM.
 144 #
 145 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 146 # This also implies MOZILLA_SHA1.
 147 #
 148 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 149 # git-http-push are not built, and you cannot use http:// and https://
 150 # transports.
 151 #
 152 # Define CURLDIR=/foo/bar if your curl header and library files are in
 153 # /foo/bar/include and /foo/bar/lib directories.
 154 #
 155 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 156 # not built, and you cannot push using http:// and https:// transports.
 157 #
 158 # Define NO_MMAP if you want to avoid mmap.
 159 #
 160 # Define NO_PYTHON if you want to loose all benefits of the recursive merge.
 161 #
 162 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 163 # Define COLLISION_CHECK below if you believe that SHA1's
 164 # 1461501637330902918203684832716283019655932542976 hashes do not give you
 165 # sufficient guarantee that no collisions between objects will ever happen.
 166 #
 167 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 168 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 169 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 170 # randomly break unless your underlying filesystem supports those sub-second
 171 # times (my ext3 doesn't).
 172 #
 173 # Define USE_STDEV below if you want git to care about the underlying device
 174 # change being considered an inode change from the update-cache perspective.
 175
 176
 177 ## Output files
 178 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 179 AC_OUTPUT
 180
 181
 182 ## Cleanup
 183 rm -f "${config_append}"